lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "main.hh"
  38 #include "misc.hh"
  39 #include "lily-lexer.hh"
  40 #include "lily-parser.hh"
  41 #include "paper-book.hh"
  42 #include "output-def.hh"
  43 #include "scm-hash.hh"
  44 #include "scm-option.hh"
  45 #include "score.hh"
  46 #include "text-item.hh"
  47 #include "warn.hh"
  48
  49 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  50
  51 Music *property_op_to_music (SCM op);
  52 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  53 SCM get_next_unique_context_id ();
  54 SCM get_next_unique_lyrics_context_id ();
  55
  56 #define YYERROR_VERBOSE 1
  57
  58 #define YYPARSE_PARAM my_lily_parser
  59 #define YYLEX_PARAM my_lily_parser
  60 #define THIS\
  61         ((Lily_parser *) my_lily_parser)
  62
  63 #define yyerror THIS->parser_error
  64
  65 /* We use custom location type: Input objects */
  66 #define YYLTYPE Input
  67 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  68         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  69
  70
  71 /* Add symbols to the TAGS field of a music object.  */
  72
  73 void
  74 tag_music (Music *m, SCM tag, Input ip)
  75 {
  76         SCM tags = m->get_property ("tags");
  77         if (scm_is_symbol (tag))
  78                 tags = scm_cons (tag, tags);
  79         else if (ly_c_list_p (tag))
  80                 tags = ly_append2 (tag, tags);
  81         else
  82                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  83
  84         m->set_property ("tags", tags);
  85 }
  86
  87 bool
  88 is_regular_identifier (SCM id)
  89 {
  90   String str = ly_scm2string (id);
  91   char const *s = str.to_str0 ();
  92
  93   bool v = true;
  94 #if 0
  95   isalpha (*s);
  96   s++;
  97 #endif
  98   while (*s && v)
  99    {
 100         v = v && isalnum (*s);
 101         s++;
 102    }
 103   return v;
 104 }
 105
 106
 107 SCM
 108 get_first_context_id (SCM type, Music *m)
 109 {
 110         SCM id = m->get_property ("context-id");
 111         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
 112             && scm_is_string (m->get_property ("context-id"))
 113             && scm_c_string_length (id) > 0)
 114         {
 115                 return id;
 116         }
 117         return SCM_EOL;
 118 }
 119
 120 SCM
 121 make_simple_markup (SCM a)
 122 {
 123         SCM simple = ly_lily_module_constant ("simple-markup");
 124         return scm_list_2 (simple, a);
 125 }
 126
 127 bool
 128 is_duration (int t)
 129 {
 130   return t && t == 1 << intlog2 (t);
 131 }
 132
 133 void
 134 set_music_properties (Music *p, SCM a)
 135 {
 136   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 137         p->internal_set_property (scm_caar (k), scm_cdar (k));
 138 }
 139
 140 SCM
 141 make_chord_step (int step, int alter)
 142 {
 143         if (step == 7)
 144                 alter += FLAT;
 145
 146         while (step < 0)
 147                 step += 7;
 148         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 149         return m.smobbed_copy ();
 150 }
 151
 152
 153 SCM
 154 make_chord (SCM pitch, SCM dur, SCM modification_list)
 155 {
 156         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
 157         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 158         scm_gc_protect_object (ch);
 159         return ch;
 160 }
 161
 162 /* Todo: actually also use apply iso. call too ...  */
 163 bool
 164 ly_input_procedure_p (SCM x)
 165 {
 166         return ly_c_procedure_p (x)
 167                 || (scm_is_pair (x) && ly_c_procedure_p (scm_car (x)));
 168 }
 169
 170 Music*
 171 set_property_music (SCM sym, SCM value)
 172 {
 173         Music *p = MY_MAKE_MUSIC ("PropertySet");
 174         p->set_property ("symbol", sym);
 175         p->set_property ("value", value);
 176         return p;
 177 }
 178
 179 Music*
 180 make_music_relative (Pitch start, Music *music)
 181 {
 182         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 183         relative->set_property ("element", music->self_scm ());
 184
 185         Pitch last = music->to_relative_octave (start);
 186         if (lily_1_8_relative)
 187                 music->set_property ("last-pitch", last.smobbed_copy ());
 188         return relative;
 189 }
 190
 191 Music*
 192 make_lyric_combine_music (SCM name, Music *music)
 193 {
 194         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 195         combine->set_property ("element", music->self_scm ());
 196         combine->set_property ("associated-context", name);
 197         return combine;
 198 }
 199
 200 %}
 201
 202 /* We use SCMs to do strings, because it saves us the trouble of
 203 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 204 of the parse stack onto the heap. */
 205
 206 %left ADDLYRICS
 207
 208 %union {
 209         Book *book;
 210         Output_def *outputdef;
 211         SCM scm;
 212         String *string;
 213         Music *music;
 214         Score *score;
 215         int i;
 216 }
 217 %{
 218
 219 int
 220 yylex (YYSTYPE *s, YYLTYPE *l, void *v)
 221 {
 222         Lily_parser *pars = (Lily_parser*) v;
 223         Lily_lexer *lex = pars->lexer_;
 224
 225         lex->lexval = (void*) s;
 226         lex->lexloc = l;
 227         lex->prepare_for_next_token ();
 228         return lex->yylex ();
 229 }
 230
 231
 232 %}
 233
 234 %expect 1
 235
 236 /* One shift/reduce problem
 237
 238 1.  \repeat
 239         \repeat .. \alternative
 240
 241     \repeat { \repeat .. \alternative }
 242
 243 or
 244
 245     \repeat { \repeat } \alternative
 246 */
 247
 248
 249 %pure_parser
 250 %locations
 251
 252 %token ACCEPTS
 253 %token ADDQUOTE
 254 %token LYRICSTO
 255 %token ALIAS
 256 %token ALTERNATIVE
 257 %token BAR
 258 %token BOOK
 259 %token CHANGE
 260 %token CHORDMODIFIERS
 261 %token CHORDS
 262 %token CHORDMODE
 263 %token DOUBLE_ANGLE_OPEN
 264 %token DOUBLE_ANGLE_CLOSE
 265 %token CLEF
 266 %token COMMANDSPANREQUEST
 267 %token CONSISTS
 268 %token CONTEXT
 269 %token DEFAULT
 270 %token DENIES
 271 %token DESCRIPTION
 272 %token EXTENDER
 273 %token FIGURES
 274 %token FIGUREMODE
 275 %token FIGURE_OPEN FIGURE_CLOSE
 276 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 277 %token GROBDESCRIPTIONS
 278 %token HEADER
 279 %token HYPHEN
 280 %token INVALID
 281 %token KEY
 282 %token LAYOUT
 283 %token LYRICS
 284 %token LYRIC_MARKUP
 285 %token LYRICMODE
 286 %token MARK
 287 %token MIDI
 288 %token MULTI_MEASURE_REST
 289 %token NAME
 290 %token NEWCONTEXT
 291 %token NOTEMODE
 292 %token OBJECTID
 293 %token OCTAVE
 294 %token ONCE
 295 %token OVERRIDE SET REVERT
 296 %token PAPER
 297 %token PARTIAL
 298 %token QUOTE
 299 %token RELATIVE
 300 %token REMOVE
 301 %token REPEAT
 302 %token REST
 303 %token SCM_T
 304 %token SCORE
 305 %token SEQUENTIAL
 306 %token ADDLYRICS
 307 %token SIMULTANEOUS
 308 %token SKIP
 309 %token SPANREQUEST
 310 %token TAG
 311 %token TEMPO
 312 %token TIMES
 313 %token TIME_T
 314 %token TRANSPOSE
 315 %token TRANSPOSITION
 316 %token TYPE
 317 %token UNSET
 318 %token WITH
 319 %token MARKUP
 320
 321 /* escaped */
 322 /* FIXME: this sucks.  The user will get to see these names:
 323     syntax error, unexpected E_CHAR:
 324                 \
 325                  %%
 326   */
 327
 328 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 329 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 330 %token E_BACKSLASH
 331 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 332 %token FIGURE_SPACE
 333
 334 %token <i>      DIGIT
 335 %token <i>      UNSIGNED
 336 %token <i> E_UNSIGNED
 337 %token <id>     IDENTIFIER
 338 %token <scm>    CHORDMODIFIER_PITCH
 339 %token <scm>    DRUM_PITCH
 340 %token <scm>    DURATION_IDENTIFIER
 341 %token <scm>    EVENT_IDENTIFIER
 342 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 343 %token <scm>    NOTENAME_PITCH
 344 %token <scm>    NUMBER_IDENTIFIER
 345 %token <scm>    OUTPUT_DEF_IDENTIFIER
 346 %token <scm>    RESTNAME
 347 %token <scm> LYRICS_STRING
 348 %token <scm>    SCM_T
 349 %token <scm>    SCORE_IDENTIFIER
 350 %token <scm>    STRING
 351 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 352 %token <scm>    TONICNAME_PITCH
 353 %token <scm>    CHORD_MODIFIER
 354 %token <scm>    FRACTION
 355 %token <scm>   REAL
 356 %token <scm> MARKUP_HEAD_EMPTY
 357 %token <scm> MARKUP_HEAD_MARKUP0
 358 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 359 %token <scm> MARKUP_HEAD_SCM0
 360 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 361 %token <scm> MARKUP_HEAD_SCM0_SCM1
 362 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 363 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 364 %token <scm> LYRIC_MARKUP_IDENTIFIER MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 365 %token <scm> MUSIC_FUNCTION
 366 %token <scm> MUSIC_FUNCTION_MUSIC
 367 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 368 %token <scm> MUSIC_FUNCTION_SCM
 369 %token <scm> MUSIC_FUNCTION_SCM_SCM
 370 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 371 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 372 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 373 %token <scm> MUSIC_FUNCTION_MARKUP
 374 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 375 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 376 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 377 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 378
 379 %token DRUMS
 380 %token DRUMMODE
 381
 382
 383 %type <book>    book_block book_body
 384 %type <i>       bare_int  bare_unsigned
 385 %type <i>       exclamations questions dots optional_rest
 386 %type <i>       script_dir
 387 %type <i>       sub_quotes sup_quotes
 388 %type <i>       tremolo_type
 389 %type <i>       bass_mod
 390
 391 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 392 %type <music>   Grouped_music_list
 393 %type <music>   Music Sequential_music Simultaneous_music
 394 %type <music>   Repeated_music
 395 %type <music>   command_req
 396 %type <music>   gen_text_def direction_less_event direction_reqd_event
 397 %type <music>   music_property_def context_change
 398 %type <music>   note_chord_element chord_body chord_body_element
 399 %type <music>   post_event tagged_post_event
 400 %type <music>   relative_music re_rhythmed_music
 401 %type <music>   simple_element event_chord command_element
 402 %type <music>   string_number_event
 403 %type <music>   toplevel_music
 404 %type <music>   tempo_event
 405
 406 %type <outputdef>       output_def_body output_def_head
 407 %type <outputdef> output_def paper_block
 408
 409 %type <scm>     assignment_id
 410 %type <scm>     Music_list
 411 %type <scm>     chord_body_elements
 412 %type <scm>     chord_item chord_items chord_separator new_chord
 413 %type <scm>     context_def_spec_block context_def_spec_body
 414 %type <scm>     context_mod context_def_mod optional_context_mod
 415 %type <scm>     context_prop_spec
 416 %type <scm>     direction_less_char
 417 %type <scm>     duration_length fraction
 418 %type <scm>     embedded_scm scalar
 419 %type <scm>     identifier_init
 420 %type <scm>     lilypond_header lilypond_header_body
 421 %type <scm>     new_lyrics
 422 %type <scm>     post_events
 423 %type <scm>     property_operation
 424 %type <scm>     script_abbreviation
 425 %type <scm>     simple_string
 426 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 427 %type <scm>     steno_tonic_pitch
 428 %type <scm>     step_number step_numbers
 429 %type <scm>     string bare_number number_expression number_term number_factor
 430 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 431 %type <scm>     context_mod_list
 432 %type <scm>     octave_check
 433 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 434 %type <scm>     Generic_prefix_music_scm
 435 %type <scm>     lyric_element
 436 %type <scm>     Alternative_music
 437 %type <scm>     full_markup lyric_markup
 438 %type <scm>     markup_list markup_composed_list markup_braced_list markup_braced_list_body
 439 %type <scm>     markup_head_1_item markup_head_1_list markup simple_markup markup_top
 440 %type <scm>     mode_changing_head
 441 %type <scm>     mode_changing_head_with_context
 442 %type <scm>     object_id_setting
 443
 444 %type <score>   score_block score_body
 445
 446
 447 %left '-' '+'
 448
 449 /* We don't assign precedence to / and *, because we might need varied
 450 prec levels in different prods */
 451
 452 %left UNARY_MINUS
 453
 454 %%
 455
 456 lilypond:       /* empty */
 457         | lilypond toplevel_expression {
 458         }
 459         | lilypond assignment {
 460         }
 461         | lilypond error {
 462                 THIS->error_level_ = 1;
 463         }
 464         | lilypond INVALID      {
 465                 THIS->error_level_ = 1;
 466         }
 467         ;
 468
 469
 470 object_id_setting:
 471         OBJECTID STRING { $$ = $2; }
 472         ;
 473
 474 toplevel_expression:
 475         lilypond_header {
 476                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 477         }
 478         | add_quote {
 479
 480         }
 481         | book_block {
 482                 Book *book = $1;
 483                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 484                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 485                 scm_gc_unprotect_object (book->self_scm ());
 486         }
 487         | score_block {
 488                 Score *score = $1;
 489
 490                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 491                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 492                 scm_gc_unprotect_object (score->self_scm ());
 493         }
 494         | toplevel_music {
 495                 Music *music = $1;
 496                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 497                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 498                 scm_gc_unprotect_object (music->self_scm ());
 499         }
 500         | full_markup {
 501                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 502                 scm_call_2 (proc, THIS->self_scm (), $1);
 503         }
 504         | output_def {
 505                 SCM id = SCM_EOL;
 506                 Output_def * od = $1;
 507
 508                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 509                         id = ly_symbol2scm ("$defaultpaper");
 510                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 511                         id = ly_symbol2scm ("$defaultmidi");
 512                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 513                         id = ly_symbol2scm ("$defaultlayout");
 514
 515                 THIS->lexer_->set_identifier (id, od->self_scm ());
 516                 scm_gc_unprotect_object (od->self_scm ());
 517         }
 518         ;
 519
 520 toplevel_music:
 521         Composite_music {
 522         }
 523         ;
 524
 525 embedded_scm:
 526         SCM_T
 527         | SCM_IDENTIFIER
 528         ;
 529
 530
 531 lilypond_header_body:
 532         {
 533                 $$ = ly_make_anonymous_module (be_safe_global);
 534                 THIS->lexer_->add_scope ($$);
 535         }
 536         | lilypond_header_body assignment  {
 537
 538         }
 539         ;
 540
 541 lilypond_header:
 542         HEADER '{' lilypond_header_body '}'     {
 543                 $$ = THIS->lexer_->remove_scope ();
 544         }
 545         ;
 546
 547 /*
 548         DECLARATIONS
 549 */
 550 assignment_id:
 551         STRING          { $$ = $1; }
 552         | LYRICS_STRING { $$ = $1; }
 553         ;
 554
 555 assignment:
 556         assignment_id '=' identifier_init  {
 557                 if (! is_regular_identifier ($1))
 558                 {
 559                         @1.warning (_ ("Identifier should have alphabetic characters only"));
 560                 }
 561
 562                 THIS->lexer_->set_identifier ($1, $3);
 563
 564 /*
 565  TODO: devise standard for protection in parser.
 566
 567   The parser stack lives on the C-stack, which means that
 568 all objects can be unprotected as soon as they're here.
 569
 570 */
 571         }
 572         | embedded_scm { }
 573         ;
 574
 575
 576 identifier_init:
 577         score_block {
 578                 $$ = $1->self_scm ();
 579                 scm_gc_unprotect_object ($$);
 580         }
 581         | output_def {
 582                 $$ = $1->self_scm ();
 583                 scm_gc_unprotect_object ($$);
 584         }
 585         | context_def_spec_block {
 586                 $$ = $1;
 587         }
 588         | Music  {
 589                 $$ = $1->self_scm ();
 590                 scm_gc_unprotect_object ($$);
 591         }
 592         | post_event {
 593                 $$ = $1->self_scm ();
 594                 scm_gc_unprotect_object ($$);
 595         }
 596         | number_expression {
 597                 $$ = $1;
 598         }
 599         | string {
 600                 $$ = $1;
 601         }
 602         | embedded_scm {
 603                 $$ = $1;
 604         }
 605         | full_markup {
 606                 $$ = $1;
 607         }
 608         | DIGIT {
 609                 $$ = scm_int2num ($1);
 610         }
 611         ;
 612
 613 context_def_spec_block:
 614         CONTEXT '{' context_def_spec_body '}'
 615                 {
 616                 $$ = $3;
 617         }
 618         ;
 619
 620 context_def_spec_body:
 621         /**/ {
 622                 $$ = Context_def::make_scm ();
 623                 unsmob_context_def ($$)->set_spot (@$);
 624         }
 625         | CONTEXT_DEF_IDENTIFIER {
 626                 $$ = $1;
 627                 unsmob_context_def ($$)->set_spot (@$);
 628         }
 629         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 630                 Context_def*td = unsmob_context_def ($$);
 631
 632                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 633                         SCM tag = scm_caar (p);
 634
 635                         /* TODO: should make new tag "grob-definition" ? */
 636                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 637                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 638                 }
 639         }
 640         | context_def_spec_body context_mod {
 641                 unsmob_context_def ($$)->add_context_mod ($2);
 642         }
 643         ;
 644
 645
 646
 647 book_block:
 648         BOOK '{' book_body '}'  {
 649                 $$ = $3;
 650         }
 651         ;
 652
 653 /* FIXME:
 654    * Use 'handlers' like for toplevel-* stuff?
 655    * grok \layout and \midi?  */
 656 book_body:
 657         {
 658                 $$ = new Book;
 659                 $$->set_spot (@$);
 660                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 661                 scm_gc_unprotect_object ($$->paper_->self_scm ());
 662                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 663         }
 664         | book_body paper_block {
 665                 $$->paper_ = $2;
 666                 scm_gc_unprotect_object ($2->self_scm ());
 667         }
 668         | book_body score_block {
 669                 SCM s = $2->self_scm ();
 670                 $$->add_score (s);
 671                 scm_gc_unprotect_object (s);
 672         }
 673         | book_body full_markup {
 674                 $$->add_score ($2);
 675         }
 676         | book_body lilypond_header {
 677                 $$->header_ = $2;
 678         }
 679         | book_body error {
 680                 $$->paper_ = 0;
 681                 $$->scores_ = SCM_EOL;
 682         }
 683         | book_body object_id_setting {
 684                 $$->user_key_ = ly_scm2string ($2);
 685         }
 686         ;
 687
 688 score_block:
 689         SCORE '{' score_body '}'        {
 690                 $$ = $3;
 691         }
 692         ;
 693
 694 score_body:
 695         /**/    {
 696                 $$ = new Score;
 697                 $$->set_spot (@$);
 698         }
 699         | SCORE_IDENTIFIER {
 700                 $$ = new Score ( *unsmob_score ($1));
 701                 $$->set_spot (@$);
 702         }
 703         | score_body object_id_setting {
 704                 $$->user_key_ = ly_scm2string ($2);
 705         }
 706         | score_body Music {
 707                 SCM m = $2->self_scm ();
 708                 scm_gc_unprotect_object (m);
 709                 $$->set_music (m, THIS->self_scm ());
 710         }
 711         | score_body lilypond_header    {
 712                 $$->header_ = $2;
 713         }
 714         | score_body output_def {
 715                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 716                 {
 717                         THIS->parser_error (@2, _("\\paper cannot be in \\score. Use \\layout instead"));
 718
 719                 }
 720                 else
 721                 {
 722                         $$->defs_.push ($2);
 723                 }
 724                 scm_gc_unprotect_object ($2->self_scm ());
 725         }
 726         | score_body error {
 727                 $$->error_found_ = true;
 728         }
 729         ;
 730
 731
 732 /*
 733         OUTPUT DEF
 734 */
 735
 736 paper_block:
 737         output_def {
 738                 $$ = $1;
 739                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 740                 {
 741                         THIS->parser_error (@1, _("Need \\paper for paper block."));
 742                         $$ = get_paper (THIS);
 743                 }
 744         }
 745         ;
 746
 747
 748 output_def:
 749         output_def_body '}' {
 750                 $$ = $1;
 751
 752                 THIS->lexer_->remove_scope ();
 753                 THIS->lexer_->pop_state ();
 754         }
 755         ;
 756
 757 output_def_head:
 758         PAPER {
 759                 $$ = get_paper (THIS);
 760                 $$->input_origin_ = @$;
 761                 THIS->lexer_->add_scope ($$->scope_);
 762         }
 763         | MIDI    {
 764                 Output_def *p = get_midi (THIS);
 765                 $$ = p;
 766                 THIS->lexer_->add_scope (p->scope_);
 767         }
 768         | LAYOUT        {
 769                 Output_def *p = get_layout (THIS);
 770
 771                 THIS->lexer_->add_scope (p->scope_);
 772                 $$ = p;
 773         }
 774         ;
 775
 776
 777 output_def_body:
 778         output_def_head '{' {
 779                 $$ = $1;
 780                 $$->input_origin_.set_spot (@$);
 781                 THIS->lexer_->push_initial_state ();
 782         }
 783         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 784                 scm_gc_unprotect_object ($1->self_scm ());
 785                 Output_def *o = unsmob_output_def ($3);
 786                 o->input_origin_.set_spot (@$);
 787                 $$ = o;
 788                 THIS->lexer_->remove_scope ();
 789                 THIS->lexer_->add_scope (o->scope_);
 790                 THIS->lexer_->push_initial_state ();
 791         }
 792         | output_def_body assignment  {
 793
 794         }
 795         | output_def_body context_def_spec_block        {
 796                 assign_context_def ($$, $2);
 797         }
 798         | output_def_body tempo_event  {
 799                 /*
 800                         junk this ? there already is tempo stuff in
 801                         music.
 802                 */
 803                 int m = scm_to_int ($2->get_property ("metronome-count"));
 804                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 805                 set_tempo ($$, d->get_length (), m);
 806                 scm_gc_unprotect_object ($2->self_scm ());
 807         }
 808         | output_def_body error {
 809
 810         }
 811         ;
 812
 813 tempo_event:
 814         TEMPO steno_duration '=' bare_unsigned  {
 815                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 816                 $$->set_property ("tempo-unit", $2);
 817                 $$->set_property ("metronome-count", scm_int2num ( $4));
 818         }
 819         ;
 820
 821 /*
 822 The representation of a  list is the
 823
 824   (LIST . LAST-CONS)
 825
 826  to have efficient append.  */
 827
 828 Music_list:
 829         /* empty */ {
 830                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 831         }
 832         | Music_list Music {
 833                 SCM s = $$;
 834                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 835                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 836
 837                 if (scm_is_pair (scm_cdr (s)))
 838                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 839                 else
 840                         scm_set_car_x (s, c); /* set first cons */
 841                 scm_set_cdr_x (s, c);  /* remember last cell */
 842         }
 843         | Music_list embedded_scm {
 844
 845         }
 846         | Music_list error {
 847                 Music * m = MY_MAKE_MUSIC("Music");
 848                 // ugh. code dup
 849                 m->set_property ("error-found", SCM_BOOL_T);
 850                 SCM s = $$;
 851                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 852                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 853
 854                 if (scm_is_pair (scm_cdr (s)))
 855                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 856                 else
 857                         scm_set_car_x (s, c); /* set first cons */
 858                 scm_set_cdr_x (s, c);  /* remember last cell */
 859         }
 860         ;
 861
 862 Music:
 863         Simple_music
 864         | Composite_music
 865         ;
 866
 867 Alternative_music:
 868         /* empty */ {
 869                 $$ = SCM_EOL;
 870         }
 871         | ALTERNATIVE '{' Music_list '}' {
 872                 $$ = $3;
 873         }
 874         ;
 875
 876
 877 Repeated_music:
 878         REPEAT simple_string bare_unsigned Music Alternative_music
 879         {
 880                 Music *beg = $4;
 881                 int times = $3;
 882                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 883                 if (times < scm_ilength (alts)) {
 884                   unsmob_music (scm_car (alts))
 885                     ->origin ()->warning (
 886                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 887                   alts = ly_truncate_list (times, alts);
 888                 }
 889
 890
 891                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 892
 893                 SCM mus = scm_call_1 (proc, $2);
 894                 scm_gc_protect_object (mus); // UGH.
 895                 Music *r = unsmob_music (mus);
 896                 if (beg)
 897                         {
 898                         r-> set_property ("element", beg->self_scm ());
 899                         scm_gc_unprotect_object (beg->self_scm ());
 900                         }
 901                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 902
 903                 r-> set_property ("elements",alts);
 904                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 905                         /*
 906                         TODO: move this code to Scheme.
 907                         */
 908
 909                         /*
 910                         we can not get durations and other stuff correct down the line, so we have to
 911                         add to the duration log here.
 912                         */
 913                         SCM func = ly_lily_module_constant ("shift-duration-log");
 914
 915                         int dots = ($3 % 3) ? 0 : 1;
 916                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 917
 918
 919                         if ($4->is_mus_type ("sequential-music"))
 920                         {
 921                                 int list_len = scm_ilength ($4->get_property ("elements"));
 922                                 if (list_len != 2)
 923                                         $4->origin ()->warning ("Chord tremolo must have 2 elements.");
 924                                 shift -= 1;
 925                                 r->compress (Moment (Rational (1, list_len)));
 926                         }
 927                         scm_call_3 (func, r->self_scm (), scm_int2num (shift), scm_int2num (dots));
 928
 929                 }
 930                 r->set_spot (*$4->origin ());
 931
 932                 $$ = r;
 933         }
 934         ;
 935
 936 Sequential_music:
 937         SEQUENTIAL '{' Music_list '}'           {
 938                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 939                 $$->set_property ("elements", scm_car ($3));
 940                 $$->set_spot (@$);
 941         }
 942         | '{' Music_list '}'            {
 943                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 944                 $$->set_property ("elements", scm_car ($2));
 945                 $$->set_spot (@$);
 946         }
 947         ;
 948
 949 Simultaneous_music:
 950         SIMULTANEOUS '{' Music_list '}'{
 951                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 952                 $$->set_property ("elements", scm_car ($3));
 953                 $$->set_spot (@$);
 954
 955         }
 956         | simul_open Music_list simul_close     {
 957                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 958                 $$->set_property ("elements", scm_car ($2));
 959                 $$->set_spot (@$);
 960         }
 961         ;
 962
 963 Simple_music:
 964         event_chord             { $$ = $1; }
 965         | MUSIC_IDENTIFIER {
 966                 $$ = unsmob_music ($1);
 967         }
 968         | music_property_def
 969         | context_change
 970         ;
 971
 972
 973 optional_context_mod:
 974         /**/ { $$ = SCM_EOL; }
 975         | WITH { THIS->lexer_->push_initial_state (); }
 976         '{' context_mod_list '}'
 977         {
 978                 THIS->lexer_->pop_state ();
 979                 $$ = $4;
 980         }
 981         ;
 982
 983 context_mod_list:
 984         /* */  { $$ = SCM_EOL; }
 985         | context_mod_list context_mod  {
 986                  $$ = scm_cons ($2, $1);
 987         }
 988         ;
 989
 990
 991 Composite_music:
 992         Prefix_composite_music { $$ = $1; }
 993         | Grouped_music_list { $$ = $1; }
 994         ;
 995
 996 Grouped_music_list:
 997         Simultaneous_music              { $$ = $1; }
 998         | Sequential_music              { $$ = $1; }
 999         ;
1000
1001 Generic_prefix_music_scm:
1002         MUSIC_FUNCTION {
1003                 $$ = scm_list_2 ($1, make_input (@$));
1004         }
1005         | MUSIC_FUNCTION_SCM embedded_scm {
1006                 $$ = scm_list_3 ($1, make_input (@$), $2);
1007         }
1008         | MUSIC_FUNCTION_MARKUP full_markup {
1009                 $$ = scm_list_3 ($1, make_input (@$), $2);
1010         }
1011         | MUSIC_FUNCTION_MUSIC Music {
1012                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1013                 scm_gc_unprotect_object ($2->self_scm ());
1014         }
1015         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm Music {
1016                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1017                 scm_gc_unprotect_object ($3->self_scm ());
1018         }
1019         | MUSIC_FUNCTION_SCM_SCM embedded_scm embedded_scm {
1020                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1021         }
1022         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm Music {
1023                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1024         }
1025         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1026                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1027                 scm_gc_unprotect_object ($3->self_scm ());
1028         }
1029         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1030                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1031         }
1032         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1033                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1034                 scm_gc_unprotect_object ($2->self_scm ());
1035                 scm_gc_unprotect_object ($3->self_scm ());
1036         }
1037         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC embedded_scm Music Music {
1038                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1039                 scm_gc_unprotect_object ($4->self_scm ());
1040                 scm_gc_unprotect_object ($3->self_scm ());
1041         }
1042         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1043                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1044                 scm_gc_unprotect_object ($3->self_scm ());
1045                 scm_gc_unprotect_object ($4->self_scm ());
1046         }
1047         ;
1048
1049 Generic_prefix_music:
1050         Generic_prefix_music_scm {
1051                 SCM func = scm_car ($1);
1052                 Input *loc = unsmob_input (scm_cadr ($1));
1053                 SCM args = scm_cddr ($1);
1054                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1055
1056                 SCM type_check_proc = ly_lily_module_constant ("type-check-list");
1057                 bool ok  = true;
1058
1059                 if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr ($1), sig, args)))
1060                 {
1061                         THIS->error_level_ = 1;
1062                         ok = false;
1063                 }
1064
1065                 SCM m = SCM_EOL;
1066                 if (ok)
1067                         m = scm_apply_0 (func, scm_cons (THIS->self_scm(),
1068                                                          scm_cdr ($1)));
1069
1070                 if (unsmob_music (m))
1071                         {
1072                         $$ = unsmob_music (m);
1073                         scm_gc_protect_object (m);
1074                         }
1075                 else
1076                         {
1077                         if (ok)
1078                                 loc->error (_ ("Music head function should return Music object."));
1079                         $$ = MY_MAKE_MUSIC ("Music");
1080                         }
1081                 $$->set_spot (*loc);
1082         }
1083         ;
1084
1085
1086 Prefix_composite_music:
1087         Generic_prefix_music {
1088                 $$ = $1;
1089         }
1090         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1091                 $$ = context_spec_music ($2, $4, $6, $5);
1092
1093         }
1094         | CONTEXT simple_string optional_context_mod Music {
1095                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1096         }
1097         | NEWCONTEXT simple_string optional_context_mod Music {
1098                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1099                         $3);
1100         }
1101
1102         | TIMES fraction Music
1103
1104         {
1105                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1106                 Music *mp = $3;
1107
1108                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1109                 $$->set_spot (@$);
1110
1111                 $$->set_property ("element", mp->self_scm ());
1112                 scm_gc_unprotect_object (mp->self_scm ());
1113                 $$->set_property ("numerator", scm_int2num (n));
1114                 $$->set_property ("denominator", scm_int2num (d));
1115                 $$->compress (Moment (Rational (n,d)));
1116
1117         }
1118         | Repeated_music                { $$ = $1; }
1119         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1120                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1121                 Music *p = $4;
1122                 Pitch from = *unsmob_pitch ($2);
1123                 Pitch to = *unsmob_pitch ($3);
1124
1125                 p->transpose (pitch_interval (from, to));
1126                 $$->set_property ("element", p->self_scm ());
1127                 scm_gc_unprotect_object (p->self_scm ());
1128         }
1129         | mode_changing_head Grouped_music_list {
1130                 if ($1 == ly_symbol2scm ("chords"))
1131                 {
1132                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1133                   chm->set_property ("element", $2->self_scm ());
1134                   $$ = chm;
1135                   scm_gc_unprotect_object ($2->self_scm ());
1136                 }
1137                 else
1138                 {
1139                   $$ = $2;
1140                 }
1141                 THIS->lexer_->pop_state ();
1142         }
1143         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1144                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1145                                          $3, $2);
1146                 if ($1 == ly_symbol2scm ("ChordNames"))
1147                 {
1148                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1149                   chm->set_property ("element", $$->self_scm ());
1150                   scm_gc_unprotect_object ($$->self_scm ());
1151                   $$ = chm;
1152                 }
1153                 THIS->lexer_->pop_state ();
1154         }
1155         | relative_music        { $$ = $1; }
1156         | re_rhythmed_music     { $$ = $1; }
1157         | TAG embedded_scm Music {
1158                 tag_music ($3, $2, @$);
1159                 $$ = $3;
1160         }
1161         ;
1162
1163 mode_changing_head:
1164         NOTEMODE {
1165                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1166                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1167
1168                 $$ = ly_symbol2scm ("notes");
1169         }
1170         | DRUMMODE
1171                 {
1172                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1173                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1174
1175                 $$ = ly_symbol2scm ("drums");
1176         }
1177         | FIGUREMODE {
1178                 THIS->lexer_->push_figuredbass_state ();
1179
1180                 $$ = ly_symbol2scm ("figures");
1181         }
1182         | CHORDMODE {
1183                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1184                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1185                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1186                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1187                 $$ = ly_symbol2scm ("chords");
1188
1189         }
1190         | LYRICMODE
1191                 { THIS->lexer_->push_lyric_state ();
1192                 $$ = ly_symbol2scm ("lyrics");
1193         }
1194         ;
1195
1196 mode_changing_head_with_context:
1197         DRUMS {
1198                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1199                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1200
1201                 $$ = ly_symbol2scm ("DrumStaff");
1202         }
1203         | FIGURES {
1204                 THIS->lexer_->push_figuredbass_state ();
1205
1206                 $$ = ly_symbol2scm ("FiguredBass");
1207         }
1208         | CHORDS {
1209                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1210                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1211                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1212                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1213                 $$ = ly_symbol2scm ("ChordNames");
1214         }
1215         | LYRICS
1216                 { THIS->lexer_->push_lyric_state ();
1217                 $$ = ly_symbol2scm ("Lyrics");
1218         }
1219         ;
1220
1221
1222 relative_music:
1223         RELATIVE absolute_pitch Music {
1224                 Music *m = $3;
1225                 Pitch start = *unsmob_pitch ($2);
1226                 $$ = make_music_relative (start, m);
1227                 scm_gc_unprotect_object (m->self_scm ());
1228         }
1229         | RELATIVE Composite_music {
1230                 Music *m = $2;
1231
1232                 Pitch middle_c (0, 0, 0);
1233                 $$ = make_music_relative (middle_c, m);
1234                 scm_gc_unprotect_object (m->self_scm ());
1235         }
1236         ;
1237
1238 new_lyrics:
1239         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1240         /*cont */
1241         Grouped_music_list {
1242         /* Can also use Music at the expensive of two S/Rs similar to
1243            \repeat \alternative */
1244                 THIS->lexer_->pop_state ();
1245
1246                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1247         }
1248         | new_lyrics ADDLYRICS {
1249                 THIS->lexer_->push_lyric_state ();
1250         } Grouped_music_list {
1251                 THIS->lexer_->pop_state ();
1252                 $$ = scm_cons ($4->self_scm (), $1);
1253         }
1254         ;
1255
1256 re_rhythmed_music:
1257         Grouped_music_list new_lyrics {
1258                 Music * voice = $1;
1259                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1260                 if (!scm_is_string (name))
1261                 {
1262                         name = get_next_unique_lyrics_context_id ();
1263                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1264                                                     name,
1265                                                     voice, SCM_EOL);
1266                 }
1267
1268                 SCM context = scm_makfrom0str ("Lyrics");
1269                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1270
1271                 SCM lst = SCM_EOL;
1272                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1273                 {
1274                         Music *music = unsmob_music (scm_car (s));
1275                         Music *com = make_lyric_combine_music (name, music);
1276                         Music *csm = context_spec_music (context,
1277                                 get_next_unique_context_id (), com, SCM_EOL);
1278                         lst = scm_cons (csm->self_scm (), lst);
1279                 }
1280                 all->set_property ("elements", scm_cons (voice->self_scm (),
1281                         lst));
1282                 $$ = all;
1283                 scm_gc_unprotect_object (voice->self_scm ());
1284         }
1285         | LYRICSTO simple_string {
1286                 THIS->lexer_->push_lyric_state ();
1287         } Music {
1288                 THIS->lexer_->pop_state ();
1289                 Music *music = $4;
1290                 SCM name = $2;
1291                 $$ = make_lyric_combine_music (name, music);
1292                 scm_gc_unprotect_object (music->self_scm ());
1293         }
1294         ;
1295
1296 context_change:
1297         CHANGE STRING '=' STRING  {
1298                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1299                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1300                 t-> set_property ("change-to-id", $4);
1301
1302                 $$ = t;
1303                 $$->set_spot (@$);
1304         }
1305         ;
1306
1307 property_operation:
1308         STRING '=' scalar {
1309                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1310                         scm_string_to_symbol ($1), $3);
1311         }
1312         | UNSET simple_string {
1313                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1314                         scm_string_to_symbol ($2));
1315         }
1316         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1317                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1318                         scm_string_to_symbol ($2), $3, $5);
1319         }
1320         | REVERT simple_string embedded_scm {
1321                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1322                         scm_string_to_symbol ($2), $3);
1323         }
1324         ;
1325
1326 context_def_mod:
1327         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1328         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1329
1330         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1331         | DENIES { $$ = ly_symbol2scm ("denies"); }
1332
1333         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1334         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1335         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1336         | NAME { $$ = ly_symbol2scm ("context-name"); }
1337         ;
1338
1339 context_mod:
1340         property_operation { $$ = $1; }
1341         | context_def_mod STRING {
1342                 $$ = scm_list_2 ($1, $2);
1343         }
1344         ;
1345
1346 context_prop_spec:
1347         simple_string {
1348                 if (!is_regular_identifier ($1))
1349                 {
1350                         @$.error (_("Grob name should be alphanumeric"));
1351                 }
1352
1353                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1354                         scm_string_to_symbol ($1));
1355         }
1356         | simple_string '.' simple_string {
1357                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1358                         scm_string_to_symbol ($3));
1359         }
1360         ;
1361
1362 music_property_def:
1363         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1364                 $$ = property_op_to_music (scm_list_4 (
1365                         ly_symbol2scm ("poppush"),
1366                         scm_cadr ($2),
1367                         $3, $5));
1368                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1369         }
1370         | REVERT context_prop_spec embedded_scm {
1371                 $$ = property_op_to_music (scm_list_3 (
1372                         ly_symbol2scm ("pop"),
1373                         scm_cadr ($2),
1374                         $3));
1375
1376                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1377         }
1378         | SET context_prop_spec '=' scalar {
1379                 $$ = property_op_to_music (scm_list_3 (
1380                         ly_symbol2scm ("assign"),
1381                         scm_cadr ($2),
1382                         $4));
1383                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1384         }
1385         | UNSET context_prop_spec {
1386                 $$ = property_op_to_music (scm_list_2 (
1387                         ly_symbol2scm ("unset"),
1388                         scm_cadr ($2)));
1389                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1390         }
1391         | ONCE music_property_def {
1392                 SCM e = $2->get_property ("element");
1393                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1394                 $$ = $2;
1395
1396         }
1397         ;
1398
1399
1400 string:
1401         STRING {
1402                 $$ = $1;
1403         }
1404         | STRING_IDENTIFIER {
1405                 $$ = $1;
1406         }
1407         | string '+' string {
1408                 $$ = scm_string_append (scm_list_2 ($1, $3));
1409         }
1410         ;
1411
1412 simple_string: STRING {
1413                 $$ = $1;
1414         }
1415         | LYRICS_STRING {
1416                 $$ = $1;
1417         }
1418         ;
1419
1420 scalar: string {
1421                 $$ = $1;
1422         }
1423         | LYRICS_STRING {
1424                 $$ = $1;
1425         }
1426         | bare_int {
1427                 $$ = scm_int2num ($1);
1428         }
1429         | embedded_scm {
1430                 $$ = $1;
1431         }
1432         | full_markup {
1433                 $$ = $1;
1434         }
1435         | DIGIT {
1436                 $$ = scm_int2num ($1);
1437         }
1438         ;
1439
1440 /*
1441
1442 pre_events doesn't contain anything. It is a trick:
1443
1444 Adding pre_events to the simple_element
1445 makes the choice between
1446
1447   string:  STRING
1448
1449 and
1450
1451   simple_element: STRING
1452
1453 a single shift/reduction conflict.
1454
1455 nevertheless, this is not very clean, and we should find a different
1456 solution.
1457
1458 */
1459 pre_events: /* empty */
1460         ;
1461
1462 event_chord:
1463         pre_events simple_element post_events   {
1464                 SCM elts = $2-> get_property ("elements");
1465
1466                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1467
1468                 $2->set_property ("elements", elts);
1469                 /* why is this giving wrong start location? -ns
1470                  * $2->set_spot (@$); */
1471                 Input i;
1472                 i.set_location (@2, @3);
1473                 $2->set_spot (i);
1474                 $$ = $2;
1475         }
1476         | command_element
1477         | note_chord_element
1478         ;
1479
1480
1481 note_chord_element:
1482         chord_body optional_notemode_duration post_events
1483         {
1484                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1485                 SCM es = $1->get_property ("elements");
1486                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1487
1488                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1489                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1490                 es = ly_append2 (es, postevs);
1491
1492                 $1-> set_property ("elements", es);
1493                 $1->set_spot (@$);
1494                 $$ = $1;
1495         }
1496         ;
1497
1498 chord_open: '<'
1499         ;
1500
1501 chord_close: '>'
1502         ;
1503
1504 simul_open: DOUBLE_ANGLE_OPEN
1505         ;
1506
1507 simul_close: DOUBLE_ANGLE_CLOSE
1508         ;
1509
1510 chord_body:
1511         chord_open chord_body_elements chord_close
1512         {
1513                 $$ = MY_MAKE_MUSIC ("EventChord");
1514                 $$->set_spot (@$);
1515                 $$->set_property ("elements",
1516                         scm_reverse_x ($2, SCM_EOL));
1517         }
1518         ;
1519
1520 chord_body_elements:
1521         /* empty */             { $$ = SCM_EOL; }
1522         | chord_body_elements chord_body_element {
1523                 $$ = scm_cons ($2->self_scm (), $1);
1524                 scm_gc_unprotect_object ($2->self_scm ());
1525         }
1526         ;
1527
1528 chord_body_element:
1529         pitch exclamations questions octave_check post_events
1530         {
1531                 int q = $3;
1532                 int ex = $2;
1533                 SCM check = $4;
1534                 SCM post = $5;
1535
1536                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1537                 n->set_property ("pitch", $1);
1538                 n->set_spot (@$);
1539                 if (q % 2)
1540                         n->set_property ("cautionary", SCM_BOOL_T);
1541                 if (ex % 2 || q % 2)
1542                         n->set_property ("force-accidental", SCM_BOOL_T);
1543
1544                 if (scm_is_pair (post)) {
1545                         SCM arts = scm_reverse_x (post, SCM_EOL);
1546                         n->set_property ("articulations", arts);
1547                 }
1548                 if (scm_is_number (check))
1549                 {
1550                         int q = scm_to_int (check);
1551                         n->set_property ("absolute-octave", scm_int2num (q-1));
1552                 }
1553
1554
1555                 $$ = n;
1556         }
1557         | DRUM_PITCH post_events {
1558                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1559                 n->set_property ("duration", $2);
1560                 n->set_property ("drum-type", $1);
1561                 n->set_spot (@$);
1562
1563                 if (scm_is_pair ($2)) {
1564                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1565                         n->set_property ("articulations", arts);
1566                 }
1567                 $$ = n;
1568         }
1569         ;
1570
1571 add_quote:
1572         ADDQUOTE string Music {
1573                 SCM adder = ly_lily_module_constant ("add-quotable");
1574
1575                 scm_call_2 (adder, $2, $3->self_scm ());
1576                 scm_gc_unprotect_object ($3->self_scm ());
1577         }
1578         ;
1579
1580 command_element:
1581         command_req {
1582                 $$ = MY_MAKE_MUSIC ("EventChord");
1583                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1584                 scm_gc_unprotect_object ($1->self_scm ());
1585
1586                 $$-> set_spot (@$);
1587                 $1-> set_spot (@$);
1588         }
1589         | SKIP duration_length {
1590                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1591                 skip->set_property ("duration", $2);
1592                 skip->set_spot (@$);
1593                 $$ = skip;
1594         }
1595         | OCTAVE pitch {
1596                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1597                 $$ = m;
1598                 $$->set_spot (@$);
1599                 $$->set_property ("pitch", $2);
1600         }
1601         | E_LEFTSQUARE {
1602                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1603                 m->set_property ("span-direction", scm_int2num (START));
1604                 m->set_spot (@$);
1605
1606                 $$ = MY_MAKE_MUSIC ("EventChord");
1607                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1608                 scm_gc_unprotect_object (m->self_scm ());
1609                 $$->set_spot (@$);
1610         }
1611         | E_RIGHTSQUARE {
1612                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1613                 m->set_property ("span-direction", scm_int2num (STOP));
1614                 m->set_spot (@$);
1615
1616                 $$ = MY_MAKE_MUSIC ("EventChord");
1617                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1618                 $$->set_spot (@$);
1619                 scm_gc_unprotect_object (m->self_scm ());
1620         }
1621         | E_BACKSLASH {
1622                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1623                 $$->set_spot (@$);
1624         }
1625         | '|'      {
1626                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1627
1628                 if (Music * m = unsmob_music (pipe))
1629                         $$ = m->clone ();
1630                 else
1631                         $$ = MY_MAKE_MUSIC ("BarCheck");
1632
1633                 $$->set_spot (@$);
1634         }
1635         | TRANSPOSITION pitch {
1636                 Pitch middle_c;
1637                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1638                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1639                                          sounds_as_c.smobbed_copy());
1640                 $$->set_spot (@$);
1641                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1642                         $$, SCM_EOL);
1643         }
1644         | BAR STRING                    {
1645                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1646
1647                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1648                                         t, SCM_EOL);
1649                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1650                 $$->set_spot (@$);
1651                 t->set_spot (@$);
1652         }
1653         | PARTIAL duration_length       {
1654                 Moment m = - unsmob_duration ($2)->get_length ();
1655                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1656                 p->set_spot (@$);
1657                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1658                                         p, SCM_EOL);
1659                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1660                                         p, SCM_EOL);
1661                 $$ = p;
1662         }
1663         | CLEF STRING  {
1664                 SCM proc = ly_lily_module_constant ("make-clef-set");
1665
1666                 SCM result = scm_call_1 (proc, $2);
1667                 scm_gc_protect_object (result);
1668                 $$ = unsmob_music (result);
1669         }
1670         | TIME_T fraction  {
1671                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1672
1673                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1674                 scm_gc_protect_object (result);
1675                 $$ = unsmob_music (result);
1676         }
1677         | MARK scalar {
1678                 SCM proc = ly_lily_module_constant ("make-mark-set");
1679
1680                 SCM result = scm_call_1 (proc, $2);
1681                 scm_gc_protect_object (result);
1682                 $$ = unsmob_music (result);
1683         }
1684         ;
1685
1686 command_req:
1687         E_TILDE {
1688                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1689         }
1690         | MARK DEFAULT  {
1691                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1692                 $$ = m;
1693         }
1694         | tempo_event {
1695                 $$ = $1;
1696         }
1697         | KEY DEFAULT {
1698                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1699                 $$ = key;
1700         }
1701         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1702
1703                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1704                 if (scm_ilength ($3) > 0)
1705                 {
1706                         key->set_property ("pitch-alist", $3);
1707                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1708                         key->transpose (* unsmob_pitch ($2));
1709                 } else {
1710                         THIS->parser_error (@3, _ ("Second argument must be pitch list."));
1711                 }
1712
1713                 $$ = key;
1714         }
1715         ;
1716
1717
1718 post_events:
1719         /* empty */ {
1720                 $$ = SCM_EOL;
1721         }
1722         | post_events post_event {
1723                 $2->set_spot (@2);
1724                 $$ = scm_cons ($2->self_scm (), $$);
1725                 scm_gc_unprotect_object ($2->self_scm ());
1726         }
1727         | post_events tagged_post_event {
1728                 $2 -> set_spot (@2);
1729                 $$ = scm_cons ($2->self_scm (), $$);
1730                 scm_gc_unprotect_object ($2->self_scm ());
1731         }
1732         ;
1733
1734
1735 tagged_post_event:
1736         '-' TAG embedded_scm post_event {
1737                 tag_music ($4, $3, @$);
1738                 $$ = $4;
1739         }
1740         ;
1741
1742
1743 post_event:
1744         direction_less_event {
1745                 $$ = $1;
1746         }
1747         | HYPHEN {
1748                 if (!THIS->lexer_->is_lyric_state ())
1749                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
1750                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1751         }
1752         | EXTENDER {
1753                 if (!THIS->lexer_->is_lyric_state ())
1754                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
1755                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1756         }
1757         | script_dir direction_reqd_event {
1758                 if ($1)
1759                         $2->set_property ("direction", scm_int2num ($1));
1760                 $$ = $2;
1761         }
1762         | script_dir direction_less_event {
1763                 if ($1)
1764                         $2->set_property ("direction", scm_int2num ($1));
1765                 $$ = $2;
1766         }
1767         | string_number_event
1768         ;
1769
1770 string_number_event:
1771         E_UNSIGNED {
1772                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1773                 s->set_property ("string-number", scm_int2num ($1));
1774                 s->set_spot (@$);
1775                 $$ = s;
1776         }
1777         ;
1778
1779 direction_less_char:
1780         '['  {
1781                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1782         }
1783         | ']'  {
1784                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1785         }
1786         | '~'  {
1787                 $$ = ly_symbol2scm ("tildeSymbol");
1788         }
1789         | '('  {
1790                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1791         }
1792         | ')'  {
1793                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1794         }
1795         | E_EXCLAMATION  {
1796                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1797         }
1798         | E_OPEN  {
1799                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1800         }
1801         | E_CLOSE  {
1802                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1803         }
1804         | E_BIGGER  {
1805                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1806         }
1807         | E_SMALLER  {
1808                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1809         }
1810         ;
1811
1812 direction_less_event:
1813         direction_less_char {
1814                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1815                 Music * m = 0;
1816                 if (unsmob_music (predefd))
1817                 {
1818                         m = unsmob_music (predefd)->clone ();
1819                 }
1820                 else
1821                 {
1822                         m = MY_MAKE_MUSIC ("Music");
1823                 }
1824                 m->set_spot (@$);
1825                 $$ = m;
1826         }
1827         | EVENT_IDENTIFIER      {
1828                 $$ = unsmob_music ($1);
1829         }
1830         | tremolo_type  {
1831                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1832                a->set_spot (@$);
1833                a->set_property ("tremolo-type", scm_int2num ($1));
1834                $$ = a;
1835         }
1836         ;
1837
1838 direction_reqd_event:
1839         gen_text_def {
1840                 $$ = $1;
1841         }
1842         | script_abbreviation {
1843                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1844                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1845                 if (scm_is_string (s))
1846                         a->set_property ("articulation-type", s);
1847                 else THIS->parser_error (@1, _ ("Expecting string as script definition"));
1848                 $$ = a;
1849         }
1850         ;
1851
1852 octave_check:
1853         /**/ { $$ = SCM_EOL; }
1854         | '='  { $$ = scm_int2num (0); }
1855         | '=' sub_quotes { $$ = scm_int2num ($2); }
1856         | '=' sup_quotes { $$ = scm_int2num ($2); }
1857         ;
1858
1859 sup_quotes:
1860         '\'' {
1861                 $$ = 1;
1862         }
1863         | sup_quotes '\'' {
1864                 $$ ++;
1865         }
1866         ;
1867
1868 sub_quotes:
1869         ',' {
1870                 $$ = 1;
1871         }
1872         | sub_quotes ',' {
1873                 $$++;
1874         }
1875         ;
1876
1877 steno_pitch:
1878         NOTENAME_PITCH  {
1879                 $$ = $1;
1880         }
1881         | NOTENAME_PITCH sup_quotes     {
1882                 Pitch p = *unsmob_pitch ($1);
1883                 p = p.transposed (Pitch ($2,0,0));
1884                 $$ = p.smobbed_copy ();
1885         }
1886         | NOTENAME_PITCH sub_quotes      {
1887                 Pitch p =* unsmob_pitch ($1);
1888                 p = p.transposed (Pitch (-$2,0,0));
1889                 $$ = p.smobbed_copy ();
1890         }
1891         ;
1892
1893 /*
1894 ugh. duplication
1895 */
1896
1897 steno_tonic_pitch:
1898         TONICNAME_PITCH {
1899                 $$ = $1;
1900         }
1901         | TONICNAME_PITCH sup_quotes    {
1902                 Pitch p = *unsmob_pitch ($1);
1903                 p = p.transposed (Pitch ($2,0,0));
1904                 $$ = p.smobbed_copy ();
1905         }
1906         | TONICNAME_PITCH sub_quotes     {
1907                 Pitch p =* unsmob_pitch ($1);
1908
1909                 p = p.transposed (Pitch (-$2,0,0));
1910                 $$ = p.smobbed_copy ();
1911         }
1912         ;
1913
1914 pitch:
1915         steno_pitch {
1916                 $$ = $1;
1917         }
1918         ;
1919
1920 pitch_also_in_chords:
1921         pitch
1922         | steno_tonic_pitch
1923         ;
1924
1925 gen_text_def:
1926         full_markup {
1927                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1928                 t->set_property ("text", $1);
1929                 t->set_spot (@$);
1930                 $$ = t;
1931         }
1932         | string {
1933                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1934                 t->set_property ("text",
1935                         make_simple_markup ($1));
1936                 t->set_spot (@$);
1937                 $$ = t;
1938
1939         }
1940         | DIGIT {
1941                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1942                 t->set_property ("digit", scm_int2num ($1));
1943                 t->set_spot (@$);
1944                 $$ = t;
1945         }
1946         ;
1947
1948 script_abbreviation:
1949         '^'             {
1950                 $$ = scm_makfrom0str ("Hat");
1951         }
1952         | '+'           {
1953                 $$ = scm_makfrom0str ("Plus");
1954         }
1955         | '-'           {
1956                 $$ = scm_makfrom0str ("Dash");
1957         }
1958         | '|'           {
1959                 $$ = scm_makfrom0str ("Bar");
1960         }
1961         | '>'           {
1962                 $$ = scm_makfrom0str ("Larger");
1963         }
1964         | '.'           {
1965                 $$ = scm_makfrom0str ("Dot");
1966         }
1967         | '_' {
1968                 $$ = scm_makfrom0str ("Underscore");
1969         }
1970         ;
1971
1972 script_dir:
1973         '_'     { $$ = DOWN; }
1974         | '^'   { $$ = UP; }
1975         | '-'   { $$ = CENTER; }
1976         ;
1977
1978
1979 absolute_pitch:
1980         steno_pitch     {
1981                 $$ = $1;
1982         }
1983         ;
1984
1985 duration_length:
1986         multiplied_duration {
1987                 $$ = $1;
1988         }
1989         ;
1990
1991 optional_notemode_duration:
1992         {
1993                 Duration dd = THIS->default_duration_;
1994                 $$ = dd.smobbed_copy ();
1995
1996                 THIS->beam_check ($$);
1997         }
1998         | multiplied_duration   {
1999                 $$ = $1;
2000                 THIS->default_duration_ = *unsmob_duration ($$);
2001
2002                 THIS->beam_check ($$);
2003         }
2004         ;
2005
2006 steno_duration:
2007         bare_unsigned dots              {
2008                 int len = 0;
2009                 if (!is_duration ($1))
2010                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
2011                 else
2012                         len = intlog2 ($1);
2013
2014                 $$ = Duration (len, $2).smobbed_copy ();
2015         }
2016         | DURATION_IDENTIFIER dots      {
2017                 Duration *d = unsmob_duration ($1);
2018                 Duration k (d->duration_log (), d->dot_count () + $2);
2019                 *d = k;
2020                 $$ = $1;
2021         }
2022         ;
2023
2024 multiplied_duration:
2025         steno_duration {
2026                 $$ = $1;
2027         }
2028         | multiplied_duration '*' bare_unsigned {
2029                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2030         }
2031         | multiplied_duration '*' FRACTION {
2032                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2033
2034                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2035         }
2036         ;
2037
2038 fraction:
2039         FRACTION { $$ = $1; }
2040         | UNSIGNED '/' UNSIGNED {
2041                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2042         }
2043         ;
2044
2045 dots:
2046         /* empty */     {
2047                 $$ = 0;
2048         }
2049         | dots '.' {
2050                 $$ ++;
2051         }
2052         ;
2053
2054 tremolo_type:
2055         ':'     {
2056                 $$ = 0;
2057         }
2058         | ':' bare_unsigned {
2059                 if (!is_duration ($2))
2060                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2061                 $$ = $2;
2062         }
2063         ;
2064
2065 bass_number:
2066         DIGIT   {
2067                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2068                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2069                                 $$);
2070         }
2071         | UNSIGNED {
2072                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2073                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2074                                 $$);
2075         }
2076         | STRING { $$ = $1; }
2077         ;
2078
2079 bass_mod:
2080         '-'     { $$ = -2; }
2081         | '+'   { $$ = 2; }
2082         | '!'   { $$ = 0; }
2083         ;
2084
2085 bass_figure:
2086         FIGURE_SPACE {
2087                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2088                 $$ = bfr->self_scm ();
2089                 scm_gc_unprotect_object ($$);
2090         }
2091         | bass_number  {
2092                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2093                 $$ = bfr->self_scm ();
2094
2095                 bfr->set_property ("figure", $1);
2096
2097                 scm_gc_unprotect_object ($$);
2098         }
2099         | bass_figure bass_mod {
2100                 Music *m = unsmob_music ($1);
2101                 if ($2) {
2102                         SCM salter = m->get_property ("alteration");
2103                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2104                         m->set_property ("alteration",
2105                                 scm_int2num (alter + $2));
2106                 } else {
2107                         m->set_property ("alteration", scm_int2num (0));
2108                 }
2109         }
2110         ;
2111
2112 br_bass_figure:
2113         '[' bass_figure {
2114                 $$ = $2;
2115                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2116         }
2117         | bass_figure   {
2118                 $$ = $1;
2119         }
2120         | br_bass_figure ']' {
2121                 $$ = $1;
2122                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2123         }
2124         ;
2125
2126 figure_list:
2127         /**/            {
2128                 $$ = SCM_EOL;
2129         }
2130         | figure_list br_bass_figure {
2131                 $$ = scm_cons ($2, $1);
2132         }
2133         ;
2134
2135 figure_spec:
2136         FIGURE_OPEN figure_list FIGURE_CLOSE {
2137                 Music *m = MY_MAKE_MUSIC ("EventChord");
2138                 $2 = scm_reverse_x ($2, SCM_EOL);
2139                 m->set_property ("elements", $2);
2140                 $$ = m->self_scm ();
2141         }
2142         ;
2143
2144
2145 optional_rest:
2146         /**/   { $$ = 0; }
2147         | REST { $$ = 1; }
2148         ;
2149
2150 simple_element:
2151         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2152                 if (!THIS->lexer_->is_note_state ())
2153                         THIS->parser_error (@1, _ ("Have to be in Note mode for notes"));
2154
2155                 Music *n = 0;
2156                 if ($6)
2157                         n = MY_MAKE_MUSIC ("RestEvent");
2158                 else
2159                         n = MY_MAKE_MUSIC ("NoteEvent");
2160
2161                 n->set_property ("pitch", $1);
2162                 n->set_property ("duration", $5);
2163
2164                 if (scm_is_number ($4))
2165                 {
2166                         int q = scm_to_int ($4);
2167                         n->set_property ("absolute-octave", scm_int2num (q-1));
2168                 }
2169
2170                 if ($3 % 2)
2171                         n->set_property ("cautionary", SCM_BOOL_T);
2172                 if ($2 % 2 || $3 % 2)
2173                         n->set_property ("force-accidental", SCM_BOOL_T);
2174
2175                 Music *v = MY_MAKE_MUSIC ("EventChord");
2176                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2177                 scm_gc_unprotect_object (n->self_scm ());
2178
2179                 v->set_spot (@$);
2180                 n->set_spot (@$);
2181                 $$ = v;
2182         }
2183         | DRUM_PITCH optional_notemode_duration {
2184                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2185                 n->set_property ("duration", $2);
2186                 n->set_property ("drum-type", $1);
2187
2188                 Music *v = MY_MAKE_MUSIC ("EventChord");
2189                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2190                 scm_gc_unprotect_object (n->self_scm ());
2191                 v->set_spot (@$);
2192                 n->set_spot (@$);
2193                 $$ = v;
2194
2195         }
2196         | figure_spec optional_notemode_duration {
2197                 Music *m = unsmob_music ($1);
2198                 m->set_spot (@$);
2199                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2200                 {
2201                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2202                 }
2203                 $$ = m;
2204         }
2205         | RESTNAME optional_notemode_duration           {
2206                 Music *ev = 0;
2207                 if (ly_scm2string ($1) == "s") {
2208                         /* Space */
2209                         ev = MY_MAKE_MUSIC ("SkipEvent");
2210                   }
2211                 else {
2212                         ev = MY_MAKE_MUSIC ("RestEvent");
2213
2214                     }
2215                 ev->set_property ("duration", $2);
2216                 ev->set_spot (@$);
2217                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2218                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2219                 velt->set_spot (@$);
2220
2221                 scm_gc_unprotect_object (ev->self_scm ());
2222
2223                 $$ = velt;
2224         }
2225         | MULTI_MEASURE_REST optional_notemode_duration         {
2226                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2227                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2228                 scm_gc_protect_object (mus);
2229                 $$ = unsmob_music (mus);
2230         }
2231
2232         | lyric_element optional_notemode_duration      {
2233                 if (!THIS->lexer_->is_lyric_state ())
2234                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
2235
2236                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2237                 lreq->set_property ("text", $1);
2238                 lreq->set_property ("duration",$2);
2239                 lreq->set_spot (@$);
2240                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2241                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2242
2243                 $$= velt;
2244         }
2245         | new_chord {
2246                 if (!THIS->lexer_->is_chord_state ())
2247                         THIS->parser_error (@1, _ ("Have to be in Chord mode for chords"));
2248                 $$ = unsmob_music ($1);
2249         }
2250         ;
2251
2252 lyric_element:
2253         lyric_markup {
2254                 $$ = $1;
2255         }
2256         | LYRICS_STRING {
2257                 $$ = make_simple_markup ($1);
2258         }
2259         ;
2260
2261 new_chord:
2262         steno_tonic_pitch optional_notemode_duration   {
2263                 $$ = make_chord ($1, $2, SCM_EOL);
2264         }
2265         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2266                 SCM its = scm_reverse_x ($4, SCM_EOL);
2267                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2268         }
2269         ;
2270
2271 chord_items:
2272         /**/ {
2273                 $$ = SCM_EOL;
2274         }
2275         | chord_items chord_item {
2276                 $$ = scm_cons ($2, $$);
2277         }
2278         ;
2279
2280 chord_separator:
2281         CHORD_COLON {
2282                 $$ = ly_symbol2scm ("chord-colon");
2283         }
2284         | CHORD_CARET {
2285                 $$ = ly_symbol2scm ("chord-caret");
2286         }
2287         | CHORD_SLASH steno_tonic_pitch {
2288                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2289         }
2290         | CHORD_BASS steno_tonic_pitch {
2291                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2292         }
2293         ;
2294
2295 chord_item:
2296         chord_separator {
2297                 $$ = $1;
2298         }
2299         | step_numbers {
2300                 $$ = scm_reverse_x ($1, SCM_EOL);
2301         }
2302         | CHORD_MODIFIER  {
2303                 $$ = $1;
2304         }
2305         ;
2306
2307 step_numbers:
2308         step_number { $$ = scm_cons ($1, SCM_EOL); }
2309         | step_numbers '.' step_number {
2310                 $$ = scm_cons ($3, $$);
2311         }
2312         ;
2313
2314 step_number:
2315         bare_unsigned {
2316                 $$ = make_chord_step ($1, 0);
2317         }
2318         | bare_unsigned '+' {
2319                 $$ = make_chord_step ($1, SHARP);
2320         }
2321         | bare_unsigned CHORD_MINUS {
2322                 $$ = make_chord_step ($1, FLAT);
2323         }
2324         ;
2325
2326 /*
2327         UTILITIES
2328
2329 TODO: should deprecate in favor of Scheme?
2330
2331  */
2332 number_expression:
2333         number_expression '+' number_term {
2334                 $$ = scm_sum ($1, $3);
2335         }
2336         | number_expression '-' number_term {
2337                 $$ = scm_difference ($1, $3);
2338         }
2339         | number_term
2340         ;
2341
2342 number_term:
2343         number_factor {
2344                 $$ = $1;
2345         }
2346         | number_factor '*' number_factor {
2347                 $$ = scm_product ($1, $3);
2348         }
2349         | number_factor '/' number_factor {
2350                 $$ = scm_divide ($1, $3);
2351         }
2352         ;
2353
2354 number_factor:
2355         '-'  number_factor { /* %prec UNARY_MINUS */
2356                 $$ = scm_difference ($2, SCM_UNDEFINED);
2357         }
2358         | bare_number
2359         ;
2360
2361
2362 bare_number:
2363         UNSIGNED        {
2364                 $$ = scm_int2num ($1);
2365         }
2366         | REAL          {
2367                 $$ = $1;
2368         }
2369         | NUMBER_IDENTIFIER             {
2370                 $$ = $1;
2371         }
2372         | REAL NUMBER_IDENTIFIER        {
2373                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2374         }
2375         | UNSIGNED NUMBER_IDENTIFIER    {
2376                 $$ = scm_make_real ($1 *scm_to_double ($2));
2377         }
2378         ;
2379
2380
2381 bare_unsigned:
2382         UNSIGNED {
2383                         $$ = $1;
2384         }
2385         | DIGIT {
2386                 $$ = $1;
2387         }
2388         ;
2389
2390 bare_int:
2391         bare_number {
2392                 if (scm_integer_p ($1) == SCM_BOOL_T)
2393                 {
2394                         int k = scm_to_int ($1);
2395                         $$ = k;
2396                 } else
2397                 {
2398                         THIS->parser_error (@1, _ ("need integer number arg"));
2399                         $$ = 0;
2400                 }
2401         }
2402         | '-' bare_int {
2403                 $$ = -$2;
2404         }
2405         ;
2406
2407 exclamations:
2408                 { $$ = 0; }
2409         | exclamations '!'      { $$ ++; }
2410         ;
2411
2412 questions:
2413                 { $$ = 0; }
2414         | questions '?' { $$ ++; }
2415         ;
2416
2417 /*
2418 This should be done more dynamically if possible.
2419 */
2420
2421 lyric_markup:
2422         LYRIC_MARKUP_IDENTIFIER {
2423                 $$ = $1;
2424         }
2425         | LYRIC_MARKUP
2426                 { THIS->lexer_->push_markup_state (); }
2427         markup_top {
2428                 $$ = $3;
2429                 THIS->lexer_->pop_state ();
2430         }
2431         ;
2432
2433 full_markup:
2434         MARKUP_IDENTIFIER {
2435                 $$ = $1;
2436         }
2437         | MARKUP
2438                 { THIS->lexer_->push_markup_state (); }
2439         markup_top {
2440                 $$ = $3;
2441                 THIS->lexer_->pop_state ();
2442         }
2443         ;
2444
2445 markup_top:
2446         markup_list {
2447                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2448         }
2449         | markup_head_1_list simple_markup      {
2450                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2451         }
2452         | simple_markup {
2453                 $$ = $1;
2454         }
2455         ;
2456
2457 markup_list:
2458         markup_composed_list {
2459                 $$ = $1;
2460         }
2461         | markup_braced_list {
2462                 $$ = $1;
2463         }
2464         ;
2465
2466 markup_composed_list:
2467         markup_head_1_list markup_braced_list {
2468                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2469
2470         }
2471         ;
2472
2473 markup_braced_list:
2474         '{' markup_braced_list_body '}' {
2475                 $$ = scm_reverse_x ($2, SCM_EOL);
2476         }
2477         ;
2478
2479 markup_braced_list_body:
2480         /* empty */     {  $$ = scm_list (SCM_EOL); }
2481         | markup_braced_list_body markup {
2482                 $$ = scm_cons ($2, $1);
2483         }
2484         | markup_braced_list_body markup_list {
2485                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2486         }
2487         ;
2488
2489 markup_head_1_item:
2490         MARKUP_HEAD_MARKUP0     {
2491                 $$ = scm_list_1 ($1);
2492         }
2493         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2494                 $$ = scm_list_2 ($1, $2);
2495         }
2496         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2497                 $$ = scm_list_3 ($1, $2, $3);
2498         }
2499         ;
2500
2501 markup_head_1_list:
2502         markup_head_1_item      {
2503                 $$ = scm_list_1 ($1);
2504         }
2505         | markup_head_1_list markup_head_1_item {
2506                 $$ = scm_cons ($2, $1);
2507         }
2508         ;
2509
2510 simple_markup:
2511         STRING {
2512                 $$ = make_simple_markup ($1);
2513         }
2514         | MARKUP_IDENTIFIER {
2515                 $$ = $1;
2516         }
2517         | LYRIC_MARKUP_IDENTIFIER {
2518                 $$ = $1;
2519         }
2520         | STRING_IDENTIFIER {
2521                 $$ = $1;
2522         }
2523         | SCORE {
2524                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2525                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2526         } '{' score_body '}' {
2527                 Score * sc = $4;
2528                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2529                 scm_gc_unprotect_object (sc->self_scm ());
2530                 THIS->lexer_->pop_state ();
2531         }
2532         | MARKUP_HEAD_SCM0 embedded_scm {
2533                 $$ = scm_list_2 ($1, $2);
2534         }
2535         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2536                 $$ = scm_list_4 ($1, $2, $3, $4);
2537         }
2538         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2539                 $$ = scm_list_3 ($1, $2, $3);
2540         }
2541         | MARKUP_HEAD_EMPTY {
2542                 $$ = scm_list_1 ($1);
2543         }
2544         | MARKUP_HEAD_LIST0 markup_list {
2545                 $$ = scm_list_2 ($1,$2);
2546         }
2547         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2548                 $$ = scm_list_3 ($1, $2, $3);
2549         }
2550         ;
2551
2552 markup:
2553         markup_head_1_list simple_markup        {
2554                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2555         }
2556         | simple_markup {
2557                 $$ = $1;
2558         }
2559         ;
2560
2561 %%
2562
2563 void
2564 Lily_parser::set_yydebug (bool )
2565 {
2566 #if 0
2567         yydebug = 1;
2568 #endif
2569 }
2570
2571 void
2572 Lily_parser::do_yyparse ()
2573 {
2574         yyparse ((void*)this);
2575 }
2576
2577
2578 /*
2579 Should make this optional?    It will also complain when you do
2580
2581         [s4]
2582
2583 which is entirely legitimate.
2584
2585 Or we can scrap it. Barchecks should detect wrong durations, and
2586 skipTypesetting speeds it up a lot.
2587 */
2588
2589 void
2590 Lily_parser::beam_check (SCM dur)
2591 {
2592   Duration *d = unsmob_duration (dur);
2593   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2594     {
2595       Music *m = unsmob_music (last_beam_start_);
2596       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2597     }
2598   last_beam_start_ = SCM_EOL;
2599 }
2600
2601
2602
2603
2604 /*
2605
2606 It is a little strange to have this function in this file, but
2607 otherwise, we have to import music classes into the lexer.
2608
2609 */
2610 int
2611 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2612 {
2613         if (scm_is_string (sid)) {
2614                 *destination = sid;
2615                 return STRING_IDENTIFIER;
2616         } else if (scm_is_number (sid)) {
2617                 *destination = sid;
2618                 return NUMBER_IDENTIFIER;
2619         } else if (unsmob_context_def (sid)) {
2620                 *destination = unsmob_context_def (sid)->clone_scm ();
2621                 return CONTEXT_DEF_IDENTIFIER;
2622         } else if (unsmob_score (sid)) {
2623                 Score *score = new Score (*unsmob_score (sid));
2624                 *destination = score->self_scm ();
2625                 return SCORE_IDENTIFIER;
2626         } else if (Music *mus = unsmob_music (sid)) {
2627                 mus = mus->clone ();
2628                 *destination = mus->self_scm ();
2629                 unsmob_music (*destination)->
2630                         set_property ("origin", make_input (last_input_));
2631                 return dynamic_cast<Event*> (mus)
2632                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2633         } else if (unsmob_duration (sid)) {
2634                 *destination = unsmob_duration (sid)->smobbed_copy ();
2635                 return DURATION_IDENTIFIER;
2636         } else if (unsmob_output_def (sid)) {
2637                 Output_def *p = unsmob_output_def (sid);
2638                 p = p->clone ();
2639
2640                 *destination = p->self_scm ();
2641                 return OUTPUT_DEF_IDENTIFIER;
2642         } else if (Text_interface::markup_p (sid)) {
2643                 *destination = sid;
2644                 if (is_lyric_state ())
2645                         return LYRIC_MARKUP_IDENTIFIER;
2646                 return MARKUP_IDENTIFIER;
2647         }
2648
2649         return -1;
2650 }
2651
2652 Music *
2653 property_op_to_music (SCM op)
2654 {
2655         Music *m = 0;
2656         SCM tag = scm_car (op);
2657         SCM symbol = scm_cadr (op);
2658         SCM args = scm_cddr (op);
2659         SCM grob_val = SCM_UNDEFINED;
2660         SCM grob_sym = SCM_UNDEFINED;
2661         SCM val = SCM_UNDEFINED;
2662
2663         if (tag == ly_symbol2scm ("assign"))
2664                 {
2665                 m = MY_MAKE_MUSIC ("PropertySet");
2666                 val = scm_car (args);
2667                 }
2668         else if (tag == ly_symbol2scm ("unset"))
2669                 m = MY_MAKE_MUSIC ("PropertyUnset");
2670         else if (tag == ly_symbol2scm ("poppush")
2671                  || tag == ly_symbol2scm ("push"))
2672                 {
2673                 m = MY_MAKE_MUSIC ("OverrideProperty");
2674                 grob_sym = scm_car (args);
2675                 grob_val = scm_cadr (args);
2676                 }
2677         else if (tag == ly_symbol2scm ("pop")) {
2678                 m = MY_MAKE_MUSIC ("RevertProperty");
2679                 grob_sym = scm_car (args);
2680                 }
2681
2682         m->set_property ("symbol", symbol);
2683
2684         if (val != SCM_UNDEFINED)
2685                 m->set_property ("value", val);
2686         if (grob_val != SCM_UNDEFINED)
2687                 m->set_property ("grob-value", grob_val);
2688
2689         if (grob_sym != SCM_UNDEFINED)
2690                 {
2691                 bool itc = do_internal_type_checking_global;
2692                 /* UGH.
2693                 */
2694                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2695                 if (autobeam)
2696                         do_internal_type_checking_global = false;
2697                 m->set_property ("grob-property", grob_sym);
2698                 if (autobeam)
2699                         do_internal_type_checking_global = itc;
2700                 }
2701
2702         if (tag == ly_symbol2scm ("poppush"))
2703                 m->set_property ("pop-first", SCM_BOOL_T);
2704
2705
2706         return m;
2707 }
2708
2709 Music*
2710 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2711 {
2712         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2713
2714         csm->set_property ("element", m->self_scm ());
2715         scm_gc_unprotect_object (m->self_scm ());
2716
2717         csm->set_property ("context-type",
2718                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2719         csm->set_property ("property-operations", ops);
2720
2721         if (scm_is_string (id))
2722                 csm->set_property ("context-id", id);
2723         return csm;
2724 }
2725
2726 SCM
2727 get_next_unique_context_id ()
2728 {
2729         return scm_makfrom0str ("$uniqueContextId");
2730 }
2731
2732
2733 SCM
2734 get_next_unique_lyrics_context_id ()
2735 {
2736         static int new_context_count;
2737         char s[128];
2738         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2739         return scm_makfrom0str (s);
2740 }