lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-file-results.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "midi-def.hh"
  41 #include "misc.hh"
  42 #include "music-list.hh"
  43 #include "music-sequence.hh"
  44 #include "my-lily-lexer.hh"
  45 #include "my-lily-parser.hh"
  46 #include "paper-book.hh"
  47 #include "paper-def.hh"
  48 #include "scm-hash.hh"
  49 #include "scm-option.hh"
  50 #include "score.hh"
  51 #include "text-item.hh"
  52 #include "warn.hh"
  53
  54 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  55
  56 Music *property_op_to_music (SCM op);
  57 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  58 SCM get_next_unique_context ();
  59
  60 #define YYERROR_VERBOSE 1
  61
  62 #define YYPARSE_PARAM my_lily_parser
  63 #define YYLEX_PARAM my_lily_parser
  64 #define THIS\
  65         ((My_lily_parser *) my_lily_parser)
  66
  67 #define yyerror THIS->parser_error
  68
  69 /* Add symbols to the TAGS field of a music object.  */
  70
  71 void
  72 tag_music (Music *m, SCM tag, Input ip)
  73 {
  74         SCM tags = m->get_property ("tags");
  75         if (is_symbol (tag))
  76                 tags = scm_cons (tag, tags);
  77         else if (is_list (tag))
  78                 tags = ly_append2 (tag, tags);
  79         else
  80                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  81
  82         m->set_property ("tags", tags);
  83 }
  84
  85
  86
  87 bool
  88 is_regular_identifier (SCM id)
  89 {
  90   String str = ly_scm2string (id);
  91   char const *s = str.to_str0 ();
  92
  93   bool v = true;
  94 #if 0
  95   isalpha (*s);
  96   s++;
  97 #endif
  98   while (*s && v)
  99    {
 100         v = v && isalnum (*s);
 101         s++;
 102    }
 103   return v;
 104 }
 105
 106 SCM
 107 make_simple_markup (SCM encoding, SCM a)
 108 {
 109         SCM simple = ly_scheme_function ("simple-markup");
 110         if (is_symbol (encoding))
 111                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 112                            encoding, a);
 113         return scm_list_2 (simple, a);
 114 }
 115
 116 bool
 117 is_duration (int t)
 118 {
 119   return t && t == 1 << intlog2 (t);
 120 }
 121
 122 void
 123 set_music_properties (Music *p, SCM a)
 124 {
 125   for (SCM k = a; is_pair (k); k = ly_cdr (k))
 126         p->internal_set_property (ly_caar (k), ly_cdar (k));
 127 }
 128
 129 SCM
 130 make_chord_step (int step, int alter)
 131 {
 132         if (step == 7)
 133                 alter += FLAT;
 134
 135         while (step < 0)
 136                 step += 7;
 137         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 138         return m.smobbed_copy ();
 139 }
 140
 141
 142 SCM
 143 make_chord (SCM pitch, SCM dur, SCM modification_list)
 144 {
 145         SCM chord_ctor = ly_scheme_function ("construct-chord");
 146         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 147         scm_gc_protect_object (ch);
 148         return ch;
 149 }
 150
 151 /* Todo: actually also use apply iso. call too ...  */
 152 bool
 153 ly_input_procedure_p (SCM x)
 154 {
 155         return is_procedure (x)
 156                 || (is_pair (x) && is_procedure (ly_car (x)));
 157 }
 158
 159 Music*
 160 set_property_music (SCM sym, SCM value)
 161 {
 162         Music *p = MY_MAKE_MUSIC ("PropertySet");
 163         p->set_property ("symbol", sym);
 164         p->set_property ("value", value);
 165         return p;
 166 }
 167
 168 %}
 169
 170 /* We use SCMs to do strings, because it saves us the trouble of
 171 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 172 of the parse stack onto the heap. */
 173
 174
 175 %union {
 176         Book *book;
 177         Music_output_def *outputdef;
 178         SCM scm;
 179         String *string;
 180         Music *music;
 181         Score *score;
 182         int i;
 183 }
 184 %{
 185
 186 int
 187 yylex (YYSTYPE *s, void *v)
 188 {
 189         My_lily_parser *pars = (My_lily_parser*) v;
 190         My_lily_lexer *lex = pars->lexer_;
 191
 192         lex->lexval = (void*) s;
 193         lex->prepare_for_next_token ();
 194         return lex->yylex ();
 195 }
 196
 197
 198 %}
 199
 200 %expect 4
 201
 202 /*
 203   Four shift/reduce problems:
 204
 205 1.      foo = bar.
 206
 207         "bar" -> String -> Lyric -> Music -> music-assignment
 208
 209         "bar" -> String -> string-assignment
 210
 211
 212 Similar problem for
 213
 214 2. \markup identifier.
 215
 216 3. \markup { }
 217
 218 4.  \repeat
 219         \repeat .. \alternative
 220
 221
 222     \repeat { \repeat .. \alternative }
 223
 224 or
 225
 226     \repeat { \repeat } \alternative
 227
 228 )
 229
 230 --hwn
 231
 232  */
 233
 234
 235 %pure_parser
 236
 237 %token ACCEPTS
 238 %token ADDLYRICS
 239 %token ADDQUOTE
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BOOK
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token PARTIAL
 287 %token QUOTE
 288 %token RELATIVE
 289 %token REMOVE
 290 %token REPEAT
 291 %token REST
 292 %token SCM_T
 293 %token SCORE
 294 %token SEQUENTIAL
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 310 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 311 %token E_BACKSLASH
 312 %token <i> E_UNSIGNED
 313 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 314 %token FIGURE_SPACE
 315
 316 %type <book>    book_block book_body
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token DRUMS
 332 %token <scm>    DRUM_PITCH
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> context_prop_spec
 388 %type <scm> Music_list
 389 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 390 %type <outputdef>  music_output_def_body music_output_def_head
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     context_def_spec_block context_def_spec_body
 398 %type <music>   tempo_event
 399 %type <scm>     script_abbreviation
 400
 401
 402
 403 %left '-' '+'
 404
 405 /* We don't assign precedence to / and *, because we might need varied
 406 prec levels in different prods */
 407
 408 %left UNARY_MINUS
 409
 410 %%
 411
 412 lilypond:       /* empty */
 413         | lilypond toplevel_expression {}
 414         | lilypond assignment  { }
 415         | lilypond error {
 416                 THIS->error_level_ = 1;
 417         }
 418         | lilypond INVALID      {
 419                 THIS->error_level_ = 1;
 420         }
 421         ;
 422
 423 toplevel_expression:
 424         lilypond_header {
 425                 THIS->header_ = $1;
 426         }
 427         | add_quote {
 428         }
 429         | book_block {
 430                 Book *book = $1;
 431                 SCM header = THIS->header_;
 432                 Path outname = split_path (THIS->output_basename_);
 433                 int *c = &THIS->book_count_;
 434                 if (*c)
 435                         outname.base += "-" + to_string (*c);
 436                 (*c)++;
 437                 Music_output_def *dp = unsmob_music_output_def
 438                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 439                 book->process (outname.to_string (),
 440                         dp ? dp->clone () : new Paper_def, header);
 441                 scm_gc_unprotect_object (book->self_scm ());
 442         }
 443         | score_block {
 444                 Score *sc = $1;
 445                 SCM head = is_module (sc->header_) ? sc->header_
 446                         : THIS->header_.to_SCM ();
 447
 448                 Path p = split_path (THIS->output_basename_);
 449                 int *c = &THIS->score_count_;
 450                 if (*c)
 451                         p.base += "-" + to_string (*c);
 452
 453                 (*c)++;
 454                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 455
 456                 for (int i = 0; i < sc->defs_.size (); i++)
 457                         default_rendering (sc->music_,
 458                                            sc->defs_[i]->self_scm (), head,
 459                                            outname);
 460
 461                 if (sc->defs_.is_empty ())
 462                 {
 463                    Music_output_def *id = unsmob_music_output_def
 464                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 465                    id = id ? id->clone () : new Paper_def;
 466                    default_rendering (sc->music_, id->self_scm (), head,
 467                         outname);
 468                    scm_gc_unprotect_object (id->self_scm ());
 469                 }
 470                 scm_gc_unprotect_object (sc->self_scm ());
 471         }
 472         | output_def {
 473                 SCM id = SCM_EOL;
 474                 if (dynamic_cast<Paper_def*> ($1))
 475                         id = scm_makfrom0str ("$defaultpaper");
 476                 else if (dynamic_cast<Midi_def*> ($1))
 477                         id = scm_makfrom0str ("$defaultmidi");
 478                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 479                 scm_gc_unprotect_object ($1->self_scm ());
 480         }
 481         ;
 482
 483
 484 embedded_scm:
 485         SCM_T
 486         | SCM_IDENTIFIER
 487         ;
 488
 489
 490
 491
 492 lilypond_header_body:
 493         {
 494                 $$ = ly_make_anonymous_module ();
 495                 THIS->lexer_->add_scope ($$);
 496         }
 497         | lilypond_header_body assignment  {
 498
 499         }
 500         ;
 501
 502 lilypond_header:
 503         HEADER '{' lilypond_header_body '}'     {
 504                 $$ = THIS->lexer_->remove_scope ();
 505         }
 506         ;
 507
 508
 509 /*
 510         DECLARATIONS
 511 */
 512 assignment:
 513         STRING {
 514                 THIS->push_spot ();
 515         }
 516         /* cont */ '=' identifier_init  {
 517
 518         /*
 519                 Should find generic way of associating input with objects.
 520         */
 521                 Input ip = THIS->pop_spot ();
 522
 523                 if (! is_regular_identifier ($1))
 524                 {
 525                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 526                 }
 527
 528                 THIS->lexer_->set_identifier ($1, $4);
 529
 530 /*
 531  TODO: devise standard for protection in parser.
 532
 533   The parser stack lives on the C-stack, which means that
 534 all objects can be unprotected as soon as they're here.
 535
 536 */
 537         }
 538         | embedded_scm { }
 539         ;
 540
 541
 542 identifier_init:
 543         score_block {
 544                 $$ = $1->self_scm ();
 545                 scm_gc_unprotect_object ($$);
 546         }
 547         | full_markup {
 548                 $$ = $1;
 549         }
 550         | output_def {
 551                 $$ = $1->self_scm ();
 552                 scm_gc_unprotect_object ($$);
 553         }
 554         | context_def_spec_block {
 555                 $$ = $1;
 556         }
 557         | Music  {
 558                 $$ = $1->self_scm ();
 559                 scm_gc_unprotect_object ($$);
 560         }
 561         | post_event {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | number_expression {
 566                 $$ = $1;
 567         }
 568         | string {
 569                 $$ = $1;
 570         }
 571         | embedded_scm  {
 572                 $$ = $1;
 573         }
 574         ;
 575
 576 context_def_spec_block:
 577         CONTEXT '{' context_def_spec_body '}'
 578                 {
 579                 $$ = $3;
 580         }
 581         ;
 582
 583 context_def_spec_body:
 584         /**/ {
 585                 $$ = Context_def::make_scm ();
 586                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 587         }
 588         | CONTEXT_DEF_IDENTIFIER        {
 589                 $$ = $1;
 590                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 593                 Context_def*td = unsmob_context_def ($$);
 594
 595                 for (SCM p = $3; is_pair (p); p = ly_cdr (p)) {
 596                         SCM tag = ly_caar (p);
 597
 598                         /* TODO: should make new tag "grob-definition" ? */
 599                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 600                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 601                 }
 602         }
 603         | context_def_spec_body context_mod {
 604                 unsmob_context_def ($$)->add_context_mod ($2);
 605         }
 606         ;
 607
 608 book_block:
 609         BOOK {
 610                 THIS->push_spot ();
 611         }
 612         /*cont*/ '{' book_body '}'      {
 613                 THIS->pop_spot ();
 614                 $$ = $4;
 615         }
 616         ;
 617
 618 book_body:
 619         {
 620                 $$ = new Book;
 621                 $$->set_spot (THIS->here_input ());
 622         }
 623         | book_body score_block {
 624                 $$->scores_.push ($2);
 625                 scm_gc_unprotect_object ($2->self_scm ());
 626         }
 627         | book_body error {
 628         }
 629         ;
 630
 631 score_block:
 632         SCORE {
 633                 THIS->push_spot ();
 634         }
 635         /*cont*/ '{' score_body '}'     {
 636                 THIS->pop_spot ();
 637                 $$ = $4;
 638         }
 639         ;
 640
 641 score_body:
 642         Music   {
 643                 $$ = new Score;
 644
 645                 $$->set_spot (THIS->here_input ());
 646                 SCM m = $1->self_scm ();
 647                 scm_gc_unprotect_object (m);
 648
 649                 /*
 650                         guh.
 651                 */
 652                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 653                 for (; is_pair (check_funcs); check_funcs = ly_cdr (check_funcs))
 654                         m = scm_call_1 (ly_car (check_funcs), m);
 655                 $$->music_ = m;
 656
 657         }
 658         | SCORE_IDENTIFIER {
 659                 $$ = new Score ( *unsmob_score ($1));
 660                 $$->set_spot (THIS->here_input ());
 661         }
 662         | score_body lilypond_header    {
 663                 $$->header_ = $2;
 664         }
 665         | score_body output_def {
 666                 $$->defs_.push ($2);
 667                 scm_gc_unprotect_object ($2->self_scm ());
 668         }
 669         | score_body error {
 670
 671         }
 672         ;
 673
 674
 675 /*
 676         MIDI
 677 */
 678 output_def:
 679         music_output_def_body '}' {
 680                 $$ = $1;
 681                 THIS-> lexer_-> remove_scope ();
 682         }
 683         ;
 684
 685 music_output_def_head:
 686         MIDI    {
 687                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 688
 689
 690                 Midi_def *p = 0;
 691                 if (id)
 692                         p = dynamic_cast<Midi_def*> (id->clone ());
 693                 else
 694                         p = new Midi_def;
 695
 696                 $$ = p;
 697                 THIS->lexer_->add_scope (p->scope_);
 698         }
 699         | PAPER         {
 700                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 701                   Paper_def *p = 0;
 702                 if (id)
 703                         p = dynamic_cast<Paper_def*> (id->clone ());
 704                 else
 705                         p = new Paper_def;
 706
 707                 THIS->lexer_->add_scope (p->scope_);
 708                 $$ = p;
 709         }
 710         ;
 711
 712
 713 music_output_def_body:
 714         music_output_def_head '{' {
 715                 $$ = $1;
 716                 $$->input_origin_. set_spot (THIS->here_input ());
 717
 718         }
 719         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 720                 scm_gc_unprotect_object ($1->self_scm ());
 721                 Music_output_def *o = unsmob_music_output_def ($3);
 722                 o->input_origin_.set_spot (THIS->here_input ());
 723                 $$ = o;
 724                 THIS->lexer_->remove_scope ();
 725                 THIS->lexer_->add_scope (o->scope_);
 726         }
 727         | music_output_def_body assignment  {
 728
 729         }
 730         | music_output_def_body context_def_spec_block  {
 731                 $$->assign_context_def ($2);
 732         }
 733         | music_output_def_body tempo_event  {
 734                 /*
 735                         junk this ? there already is tempo stuff in
 736                         music.
 737                 */
 738                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 739                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 740                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 741                 if (md)
 742                         md->set_tempo (d->get_length (), m);
 743                 scm_gc_unprotect_object ($2->self_scm ());
 744         }
 745         | music_output_def_body error {
 746
 747         }
 748         ;
 749
 750 tempo_event:
 751         TEMPO steno_duration '=' bare_unsigned  {
 752                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 753                 $$->set_property ("tempo-unit", $2);
 754                 $$->set_property ("metronome-count", scm_int2num ( $4));
 755         }
 756         ;
 757
 758 /*
 759 The representation of a  list is the
 760
 761   (LIST . LAST-CONS)
 762
 763  to have  efficient append.
 764 */
 765 Music_list:
 766         /* empty */ {
 767                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 768         }
 769         | Music_list Music {
 770                 SCM s = $$;
 771                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 772                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 773                 if (is_pair (ly_cdr (s)))
 774                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 775                 else
 776                         scm_set_car_x (s, c); /* set first cons */
 777                 scm_set_cdr_x (s, c);  /* remember last cell */
 778         }
 779         | Music_list error {
 780         }
 781         ;
 782
 783
 784 Music:
 785         Simple_music
 786         | Composite_music
 787         ;
 788
 789 Alternative_music:
 790         /* empty */ {
 791                 $$ = SCM_EOL;
 792         }
 793         | ALTERNATIVE '{' Music_list '}' {
 794                 $$ = $3;
 795         }
 796         ;
 797
 798 Repeated_music:
 799         REPEAT string bare_unsigned Music Alternative_music
 800         {
 801                 Music *beg = $4;
 802                 int times = $3;
 803                 SCM alts = is_pair ($5) ? ly_car ($5) : SCM_EOL;
 804                 if (times < scm_ilength (alts)) {
 805                   unsmob_music (ly_car (alts))
 806                     ->origin ()->warning (
 807                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 808                   alts = ly_truncate_list (times, alts);
 809                 }
 810
 811
 812                 SCM proc = ly_scheme_function ("make-repeated-music");
 813
 814                 SCM mus = scm_call_1 (proc, $2);
 815                 scm_gc_protect_object (mus); // UGH.
 816                 Music *r = unsmob_music (mus);
 817                 if (beg)
 818                         {
 819                         r-> set_property ("element", beg->self_scm ());
 820                         scm_gc_unprotect_object (beg->self_scm ());
 821                         }
 822                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 823
 824                 r-> set_property ("elements",alts);
 825                 if (is_equal ($2, scm_makfrom0str ("tremolo"))) {
 826                         /*
 827                         TODO: move this code to Scheme.
 828                         */
 829
 830                         /*
 831                         we can not get durations and other stuff correct down the line, so we have to
 832                         add to the duration log here.
 833                         */
 834                         SCM func = ly_scheme_function ("shift-duration-log");
 835
 836                         int dots = ($3 % 3) ? 0 : 1;
 837                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 838
 839                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 840
 841                         if (seq) {
 842                                 int list_len = scm_ilength (seq->music_list ());
 843                                 if (list_len != 2)
 844                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 845                                 shift -= 1;
 846                                 r->compress (Moment (Rational (1, list_len)));
 847                                 }
 848                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 849
 850                 }
 851                 r->set_spot (*$4->origin ());
 852
 853                 $$ = r;
 854         }
 855         ;
 856
 857 Sequential_music:
 858         SEQUENTIAL '{' Music_list '}'           {
 859                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 860                 $$->set_property ("elements", ly_car ($3));
 861                 $$->set_spot (THIS->here_input ());
 862         }
 863         | '{' Music_list '}'            {
 864                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 865                 $$->set_property ("elements", ly_car ($2));
 866                 $$->set_spot (THIS->here_input ());
 867         }
 868         ;
 869
 870 Simultaneous_music:
 871         SIMULTANEOUS '{' Music_list '}'{
 872                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 873                 $$->set_property ("elements", ly_car ($3));
 874                 $$->set_spot (THIS->here_input ());
 875
 876         }
 877         | simul_open Music_list simul_close     {
 878                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 879                 $$->set_property ("elements", ly_car ($2));
 880                 $$->set_spot (THIS->here_input ());
 881         }
 882         ;
 883
 884 Simple_music:
 885         event_chord             { $$ = $1; }
 886         | APPLYOUTPUT embedded_scm {
 887                 if (!ly_input_procedure_p ($2))
 888                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 889                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 890                 $$->set_property ("procedure", $2);
 891                 $$->set_spot (THIS->here_input ());
 892         }
 893         | APPLYCONTEXT embedded_scm {
 894                 if (!ly_input_procedure_p ($2))
 895                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 896                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 897                 $$->set_property ("procedure", $2);
 898                 $$->set_spot (THIS->here_input ());
 899         }
 900         | MUSIC_IDENTIFIER {
 901                 $$ = unsmob_music ($1);
 902         }
 903         | music_property_def
 904         | context_change
 905         ;
 906
 907
 908 optional_context_mod:
 909         /**/ { $$ = SCM_EOL; }
 910         | WITH '{' context_mod_list '}'  { $$ = $3; }
 911         ;
 912
 913 grace_head:
 914         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 915         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 916         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 917         ;
 918
 919 context_mod_list:
 920         /* */  { $$ = SCM_EOL; }
 921         | context_mod_list context_mod  {
 922                  $$ = scm_cons ($2, $1);
 923         }
 924         ;
 925
 926 Composite_music:
 927         AUTOCHANGE Music        {
 928                 SCM proc = ly_scheme_function ("make-autochange-music");
 929
 930                 SCM res = scm_call_1 (proc, $2->self_scm ());
 931                 scm_gc_unprotect_object ($2->self_scm ());
 932                 $$ = unsmob_music (res);
 933                 scm_gc_protect_object (res);
 934                 $$->set_spot (THIS->here_input ());
 935         }
 936         | PARTCOMBINE Music Music {
 937                 SCM proc = ly_scheme_function ("make-part-combine-music");
 938
 939                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 940                         $3->self_scm (), SCM_UNDEFINED));
 941                 scm_gc_unprotect_object ($3->self_scm ());
 942                 scm_gc_unprotect_object ($2->self_scm ());
 943                 $$ = unsmob_music (res);
 944                 scm_gc_protect_object (res);
 945                 $$->set_spot (THIS->here_input ());
 946         }
 947         | grace_head Music {
 948 #if 1
 949         /*
 950                 The other version is for easier debugging  of
 951                 Sequential_music_iterator in combination with grace notes.
 952         */
 953
 954 /*
 955
 956 TODO: should distinguish between both grace types in the
 957 basic music objects too, since the meaning is different.
 958
 959 */
 960
 961                 String start_str = "start" + ly_scm2string ($1) + "Music";
 962                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 963
 964                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 965                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 966
 967                 Music *startm = unsmob_music (start);
 968                 Music *stopm = unsmob_music (stop);
 969
 970                 SCM ms = SCM_EOL;
 971                 if (stopm) {
 972                         stopm = stopm->clone ();
 973                         ms = scm_cons (stopm->self_scm (), ms);
 974                         scm_gc_unprotect_object (stopm->self_scm ());
 975                 }
 976                 ms = scm_cons ($2->self_scm (), ms);
 977                 scm_gc_unprotect_object ($2->self_scm ());
 978                 if (startm) {
 979                         startm = startm->clone ();
 980                         ms = scm_cons (startm->self_scm (), ms);
 981                         scm_gc_unprotect_object (startm->self_scm ());
 982                 }
 983
 984                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 985                 seq->set_property ("elements", ms);
 986
 987
 988                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 989                 $$->set_property ("element", seq->self_scm ());
 990                 scm_gc_unprotect_object (seq->self_scm ());
 991 #else
 992                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 993                 $$->set_property ("element", $2->self_scm ());
 994                 scm_gc_unprotect_object ($2->self_scm ());
 995 #endif
 996         }
 997         | CONTEXT string '=' string optional_context_mod Music {
 998                 $$ = context_spec_music ($2, $4, $6, $5);
 999
1000         }
1001         | CONTEXT STRING optional_context_mod Music {
1002                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1003         }
1004         | NEWCONTEXT string optional_context_mod Music {
1005                 $$ = context_spec_music ($2, get_next_unique_context (),
1006                                          $4, $3);
1007         }
1008
1009         | TIMES {
1010                 THIS->push_spot ();
1011         }
1012         /* CONTINUED */
1013                 fraction Music
1014
1015         {
1016                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1017                 Music *mp = $4;
1018
1019                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1020                 $$->set_spot (THIS->pop_spot ());
1021
1022                 $$->set_property ("element", mp->self_scm ());
1023                 scm_gc_unprotect_object (mp->self_scm ());
1024                 $$->set_property ("numerator", scm_int2num (n));
1025                 $$->set_property ("denominator", scm_int2num (d));
1026                 $$->compress (Moment (Rational (n,d)));
1027
1028         }
1029         | Repeated_music                { $$ = $1; }
1030         | Simultaneous_music            { $$ = $1; }
1031         | Sequential_music              { $$ = $1; }
1032         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1033                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1034                 Music *p = $4;
1035                 Pitch from = *unsmob_pitch ($2);
1036                 Pitch to = *unsmob_pitch ($3);
1037
1038                 p->transpose (interval (from, to));
1039                 $$->set_property ("element", p->self_scm ());
1040                 scm_gc_unprotect_object (p->self_scm ());
1041         }
1042         | APPLY embedded_scm Music  {
1043                 if (!ly_input_procedure_p ($2))
1044                         {
1045                         THIS->parser_error (_ ("\\apply takes function argument"));
1046                         $$ = $3;
1047                         }
1048                 else
1049                         {
1050                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1051                         Music *m = unsmob_music (ret);
1052                         if (!m) {
1053                                 THIS->parser_error ("\\apply must return a Music");
1054                                 m = MY_MAKE_MUSIC ("Music");
1055                                 }
1056                         $$ = m;
1057                         }
1058         }
1059         | NOTES
1060                 {
1061                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1062                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1063         }
1064         Music
1065                 { $$ = $3;
1066                   THIS->lexer_->pop_state ();
1067                 }
1068         | DRUMS
1069                 {
1070                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1071                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1072         }
1073         Music
1074                 { $$ = $3;
1075                   THIS->lexer_->pop_state ();
1076                 }
1077         | FIGURES
1078                 { THIS->lexer_->push_figuredbass_state (); }
1079         Music
1080                 {
1081                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1082                   chm->set_property ("element", $3->self_scm ());
1083                   $$ = chm;
1084                   scm_gc_unprotect_object ($3->self_scm ());
1085
1086                   THIS->lexer_->pop_state ();
1087         }
1088         | CHORDS {
1089                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1090                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1091                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1092                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1093
1094         } Music {
1095                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1096                   chm->set_property ("element", $3->self_scm ());
1097                   scm_gc_unprotect_object ($3->self_scm ());
1098                   $$ = chm;
1099
1100                   THIS->lexer_->pop_state ();
1101         }
1102         | LYRICS
1103                 { THIS->lexer_->push_lyric_state (); }
1104         Music
1105                 {
1106                   $$ = $3;
1107                   THIS->lexer_->pop_state ();
1108         }
1109         | relative_music        { $$ = $1; }
1110         | re_rhythmed_music     { $$ = $1; }
1111         | TAG embedded_scm Music {
1112                 tag_music ($3, $2, THIS->here_input ());
1113                 $$ = $3;
1114         }
1115         ;
1116
1117 relative_music:
1118         RELATIVE absolute_pitch Music {
1119                 Music *p = $3;
1120                 Pitch pit = *unsmob_pitch ($2);
1121                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1122
1123                 $$->set_property ("element", p->self_scm ());
1124                 scm_gc_unprotect_object (p->self_scm ());
1125
1126
1127                 Pitch retpitch = p->to_relative_octave (pit);
1128                 if (lily_1_8_relative)
1129                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1130         }
1131         ;
1132
1133 re_rhythmed_music:
1134         ADDLYRICS Music Music {
1135         Music *l = MY_MAKE_MUSIC ("LyricCombineMusic");
1136           l->set_property ("elements", scm_listify ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1137           scm_gc_unprotect_object ($3->self_scm ());
1138           scm_gc_unprotect_object ($2->self_scm ());
1139           $$ = l;
1140         }
1141         | NEWADDLYRICS string Music {
1142           Music *l = MY_MAKE_MUSIC ("NewLyricCombineMusic");
1143           l->set_property ("element", $3->self_scm ());
1144           scm_gc_unprotect_object ($3->self_scm ());
1145           $$ = l;
1146           l->set_property ("associated-context", $2);
1147         }
1148         ;
1149
1150 context_change:
1151         CHANGE STRING '=' STRING  {
1152                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1153                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1154                 t-> set_property ("change-to-id", $4);
1155
1156                 $$ = t;
1157                 $$->set_spot (THIS->here_input ());
1158         }
1159         ;
1160
1161 property_operation:
1162         STRING '='  scalar {
1163                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1164                         scm_string_to_symbol ($1), $3);
1165         }
1166         | UNSET STRING {
1167                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1168                         scm_string_to_symbol ($2));
1169         }
1170         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1171                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1172                         scm_string_to_symbol ($2), $3, $5);
1173         }
1174         | REVERT STRING embedded_scm {
1175                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1176                         scm_string_to_symbol ($2), $3);
1177         }
1178         ;
1179
1180 context_def_mod:
1181         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1182         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1183         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1184
1185         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1186         | DENIES { $$ = ly_symbol2scm ("denies"); }
1187
1188         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1189         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1190         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1191         | NAME { $$ = ly_symbol2scm ("context-name"); }
1192         ;
1193
1194 context_mod:
1195         property_operation { $$ = $1; }
1196         | context_def_mod STRING {
1197                 $$ = scm_list_2 ($1, $2);
1198         }
1199         ;
1200
1201 context_prop_spec:
1202         STRING  {
1203                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1204         }
1205         | STRING '.' STRING {
1206                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1207         }
1208         ;
1209
1210 music_property_def:
1211         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1212                 $$ = property_op_to_music (scm_list_4 (
1213                         ly_symbol2scm ("poppush"),
1214                         ly_cadr ($2),
1215                         $3, $5));
1216                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1217         }
1218         | REVERT context_prop_spec embedded_scm {
1219                 $$ = property_op_to_music (scm_list_3 (
1220                         ly_symbol2scm ("pop"),
1221                         ly_cadr ($2),
1222                         $3));
1223
1224                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1225         }
1226         | SET context_prop_spec '=' scalar {
1227                 $$ = property_op_to_music (scm_list_3 (
1228                         ly_symbol2scm ("assign"),
1229                         ly_cadr ($2),
1230                         $4));
1231                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1232         }
1233         | UNSET context_prop_spec {
1234                 $$ = property_op_to_music (scm_list_2 (
1235                         ly_symbol2scm ("unset"),
1236                         ly_cadr ($2)));
1237                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1238         }
1239         | ONCE music_property_def {
1240                 SCM e = $2->get_property ("element");
1241                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1242                 $$ = $2;
1243
1244         }
1245         ;
1246
1247
1248
1249 scalar:
1250         string          { $$ = $1; }
1251         | bare_int      { $$ = scm_int2num ($1); }
1252         | embedded_scm  { $$ = $1; }
1253         | full_markup {  $$ = $1; }
1254         | DIGIT { $$ = scm_int2num ($1); }
1255         ;
1256
1257 /*
1258 This is a trick:
1259
1260 Adding pre_events to the simple_element
1261 makes the choice between
1262
1263   string:  STRING
1264
1265 and
1266
1267   simple_element: STRING
1268
1269 a single shift/reduction conflict.
1270
1271 nevertheless, this is not very clean, and we should find a different
1272 solution.
1273
1274 */
1275 pre_events: {
1276                 THIS->push_spot ();
1277         }
1278         ;
1279
1280 event_chord:
1281         pre_events simple_element post_events   {
1282                 SCM elts = $2-> get_property ("elements");
1283
1284                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1285
1286                 $2->set_property ("elements", elts);
1287                 $$ = $2;
1288         }
1289         | command_element
1290         | note_chord_element
1291         ;
1292
1293
1294 note_chord_element:
1295         chord_body optional_notemode_duration post_events
1296         {
1297                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1298                 SCM es = $1->get_property ("elements");
1299                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1300
1301                 for (SCM s = es; is_pair (s); s = ly_cdr (s))
1302                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1303                 es = ly_append2 (es, postevs);
1304
1305                 $1-> set_property ("elements", es);
1306                 $$ = $1;
1307         }
1308         ;
1309
1310 chord_open: '<'
1311         ;
1312
1313 chord_close: '>'
1314         ;
1315
1316 simul_open: LESSLESS
1317         ;
1318
1319 simul_close: MOREMORE
1320         ;
1321
1322 chord_body:
1323         chord_open chord_body_elements chord_close
1324         {
1325                 $$ = MY_MAKE_MUSIC ("EventChord");
1326                 $$->set_property ("elements",
1327                         scm_reverse_x ($2, SCM_EOL));
1328         }
1329         ;
1330
1331 chord_body_elements:
1332         /* empty */             { $$ = SCM_EOL; }
1333         | chord_body_elements chord_body_element {
1334                 $$ = scm_cons ($2->self_scm (), $1);
1335                 scm_gc_unprotect_object ($2->self_scm ());
1336         }
1337         ;
1338
1339 chord_body_element:
1340         pitch exclamations questions post_events
1341         {
1342                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1343                 n->set_property ("pitch", $1);
1344                 if ($3 % 2)
1345                         n->set_property ("cautionary", SCM_BOOL_T);
1346                 if ($2 % 2 || $3 % 2)
1347                         n->set_property ("force-accidental", SCM_BOOL_T);
1348
1349                 if (is_pair ($4)) {
1350                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1351                         n->set_property ("articulations", arts);
1352                 }
1353                 $$ = n;
1354         }
1355         | DRUM_PITCH post_events {
1356                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1357                 n->set_property ("duration", $2);
1358                 n->set_property ("drum-type", $1);
1359                 n->set_spot (THIS->here_input ());
1360
1361                 if (is_pair ($2)) {
1362                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1363                         n->set_property ("articulations", arts);
1364                 }
1365                 $$ = n;
1366         }
1367         ;
1368
1369 add_quote:
1370         ADDQUOTE string Music {
1371                 SCM adder = ly_scheme_function ("add-quotable");
1372
1373                 scm_call_2 (adder, $2, $3->self_scm ());
1374                 scm_gc_unprotect_object ($3->self_scm ());
1375         }
1376         ;
1377
1378 command_element:
1379         command_req {
1380                 $$ = MY_MAKE_MUSIC ("EventChord");
1381                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1382                 scm_gc_unprotect_object ($1->self_scm ());
1383
1384                 $$-> set_spot (THIS->here_input ());
1385                 $1-> set_spot (THIS->here_input ());
1386         }
1387         | SKIP duration_length {
1388                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1389                 skip->set_property ("duration", $2);
1390
1391                 $$ = skip;
1392         }
1393         | QUOTE STRING duration_length {
1394                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1395                 SCM evs = SCM_EOL;
1396                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1397                 {
1398                         SCM key = $2; // use symbol?
1399                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1400                 }
1401                 Music *quote = 0;
1402                 if (is_vector (evs))
1403                 {
1404                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1405                         quote->set_property ("duration", $3);
1406                         quote->set_property ("quoted-events", evs);
1407                 } else {
1408                         THIS->here_input ().warning (_f ("Can\'t find music"));
1409                         quote = MY_MAKE_MUSIC ("Event");
1410                 }
1411                 quote->set_spot (THIS->here_input ());
1412                 $$ = quote;
1413         }
1414         | OCTAVE { THIS->push_spot (); }
1415           pitch {
1416                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1417                 $$ = l;
1418                 $$->set_spot (THIS->pop_spot ());
1419                 $$->set_property ("pitch", $3);
1420         }
1421         | E_LEFTSQUARE {
1422                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1423                 l->set_property ("span-direction", scm_int2num (START));
1424                 l->set_spot (THIS->here_input ());
1425
1426                 $$ = MY_MAKE_MUSIC ("EventChord");
1427                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1428                 scm_gc_unprotect_object (l->self_scm ());
1429                 $$->set_spot (THIS->here_input ());
1430         }
1431         | E_RIGHTSQUARE {
1432                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1433                 l->set_property ("span-direction", scm_int2num (STOP));
1434                 l->set_spot (THIS->here_input ());
1435
1436                 $$ = MY_MAKE_MUSIC ("EventChord");
1437                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1438                 $$->set_spot (THIS->here_input ());
1439                 scm_gc_unprotect_object (l->self_scm ());
1440         }
1441         | E_BACKSLASH {
1442                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1443                 $$->set_spot (THIS->here_input ());
1444         }
1445         | '|'      {
1446                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1447
1448                 if (Music * m = unsmob_music (pipe))
1449                         $$ = m->clone ();
1450                 else
1451                         $$ = MY_MAKE_MUSIC ("BarCheck");
1452
1453                 $$->set_spot (THIS->here_input ());
1454         }
1455         | TRANSPOSITION pitch {
1456                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1457                                         $2);
1458                 $$->set_spot (THIS-> here_input ());
1459                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1460                         $$, SCM_EOL);
1461         }
1462         | BAR STRING                    {
1463                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1464
1465                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1466                                         t, SCM_EOL);
1467                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1468                 $$->set_spot (THIS->here_input ());
1469                 t->set_spot (THIS->here_input ());
1470         }
1471         | PARTIAL duration_length       {
1472                 Moment m = - unsmob_duration ($2)->get_length ();
1473                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1474                 p->set_spot (THIS->here_input ());
1475                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1476                                         p, SCM_EOL);
1477                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1478                                         p, SCM_EOL);
1479                 $$ = p;
1480         }
1481         | CLEF STRING  {
1482                 SCM proc = ly_scheme_function ("make-clef-set");
1483
1484                 SCM result = scm_call_1 (proc, $2);
1485                 scm_gc_protect_object (result);
1486                 $$ = unsmob_music (result);
1487         }
1488         | TIME_T fraction  {
1489                 SCM proc= ly_scheme_function ("make-time-signature-set");
1490
1491                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1492                 scm_gc_protect_object (result);
1493                 $$ = unsmob_music (result);
1494         }
1495         | MARK scalar {
1496                 SCM proc = ly_scheme_function ("make-mark-set");
1497
1498                 SCM result = scm_call_1 (proc, $2);
1499                 scm_gc_protect_object (result);
1500                 $$ = unsmob_music (result);
1501         }
1502         ;
1503
1504 command_req:
1505         BREATHE {
1506                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1507         }
1508         | E_TILDE {
1509                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1510         }
1511         | MARK DEFAULT  {
1512                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1513                 $$ = m;
1514         }
1515         | tempo_event {
1516                 $$ = $1;
1517         }
1518         | KEY DEFAULT {
1519                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1520                 $$ = key;
1521         }
1522         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1523
1524                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1525                 if (scm_ilength ($3) > 0)
1526                 {
1527                         key->set_property ("pitch-alist", $3);
1528                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1529                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1530                 } else {
1531                         THIS->parser_error (_ ("Second argument must be pitch list."));
1532                 }
1533
1534                 $$ = key;
1535         }
1536         ;
1537
1538 post_events:
1539         /* empty */ {
1540                 $$ = SCM_EOL;
1541         }
1542         | post_events post_event {
1543                 $2->set_spot (THIS->here_input ());
1544                 $$ = scm_cons ($2->self_scm (), $$);
1545                 scm_gc_unprotect_object ($2->self_scm ());
1546         }
1547         | post_events tagged_post_event {
1548                 $2 -> set_spot (THIS->here_input ());
1549                 $$ = scm_cons ($2->self_scm (), $$);
1550                 scm_gc_unprotect_object ($2->self_scm ());
1551         }
1552         ;
1553
1554
1555 tagged_post_event:
1556         '-' TAG embedded_scm post_event {
1557                 tag_music ($4, $3, THIS->here_input ());
1558                 $$ = $4;
1559         }
1560         ;
1561
1562 post_event:
1563         direction_less_event {
1564                 $$ = $1;
1565         }
1566         | HYPHEN {
1567                 if (!THIS->lexer_->is_lyric_state ())
1568                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1569                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1570         }
1571         | EXTENDER {
1572                 if (!THIS->lexer_->is_lyric_state ())
1573                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1574                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1575         }
1576         | script_dir direction_reqd_event {
1577                 if ($1)
1578                         $2->set_property ("direction", scm_int2num ($1));
1579                 $$ = $2;
1580         }
1581         | script_dir direction_less_event {
1582                 if ($1)
1583                         $2->set_property ("direction", scm_int2num ($1));
1584                 $$ = $2;
1585         }
1586         | string_number_event
1587         ;
1588
1589 string_number_event:
1590         E_UNSIGNED {
1591                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1592                 s->set_property ("string-number", scm_int2num ($1));
1593                 s->set_spot (THIS->here_input ());
1594                 $$ = s;
1595         }
1596         ;
1597
1598
1599 direction_less_event:
1600         '['  {
1601
1602
1603 /*
1604
1605 TODO: should take all these defs out of the parser, adn make use
1606 configurable, i.e.
1607
1608
1609 (set-articulation '~ "trill")
1610
1611 */
1612                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1613                 m->set_spot (THIS->here_input ());
1614                 m->set_property ("span-direction", scm_int2num (START));
1615                 $$ = m;
1616         }
1617         | ']'  {
1618                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1619                 m->set_spot (THIS->here_input ());
1620                 m->set_property ("span-direction", scm_int2num (STOP));
1621                 $$ = m;
1622         }
1623         | '~' {
1624                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1625                 m->set_spot (THIS->here_input ());
1626                 $$ = m;
1627         }
1628         | close_event {
1629                 $$ = $1;
1630                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1631                         scm_int2num (START));
1632         }
1633         | open_event {
1634                 $$ = $1;
1635                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1636                         scm_int2num (STOP));
1637         }
1638         | EVENT_IDENTIFIER      {
1639                 $$ = unsmob_music ($1);
1640         }
1641         | tremolo_type  {
1642                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1643                a->set_spot (THIS->here_input ());
1644                a->set_property ("tremolo-type", scm_int2num ($1));
1645                $$ = a;
1646         }
1647         ;
1648
1649 direction_reqd_event:
1650         gen_text_def {
1651                 $$ = $1;
1652         }
1653         | script_abbreviation {
1654                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1655                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1656                 if (is_string (s))
1657                         a->set_property ("articulation-type", s);
1658                 else THIS->parser_error (_ ("Expecting string as script definition"));
1659                 $$ = a;
1660         }
1661         ;
1662
1663 oct_check:
1664         /**/ { $$ = SCM_EOL; }
1665         | '='  { $$ = scm_int2num (0); }
1666         | '=' sub_quotes { $$ = scm_int2num ($2); }
1667         | '=' sup_quotes { $$ = scm_int2num ($2); }
1668         ;
1669
1670 sup_quotes:
1671         '\'' {
1672                 $$ = 1;
1673         }
1674         | sup_quotes '\'' {
1675                 $$ ++;
1676         }
1677         ;
1678
1679 sub_quotes:
1680         ',' {
1681                 $$ = 1;
1682         }
1683         | sub_quotes ',' {
1684                 $$++;
1685         }
1686         ;
1687
1688 steno_pitch:
1689         NOTENAME_PITCH  {
1690                 $$ = $1;
1691         }
1692         | NOTENAME_PITCH sup_quotes     {
1693                 Pitch p = *unsmob_pitch ($1);
1694                 p = p.transposed (Pitch ($2,0,0));
1695                 $$ = p.smobbed_copy ();
1696         }
1697         | NOTENAME_PITCH sub_quotes      {
1698                 Pitch p =* unsmob_pitch ($1);
1699                 p = p.transposed (Pitch (-$2,0,0));
1700                 $$ = p.smobbed_copy ();
1701         }
1702         ;
1703
1704 /*
1705 ugh. duplication
1706 */
1707
1708 steno_tonic_pitch:
1709         TONICNAME_PITCH {
1710                 $$ = $1;
1711         }
1712         | TONICNAME_PITCH sup_quotes    {
1713                 Pitch p = *unsmob_pitch ($1);
1714                 p = p.transposed (Pitch ($2,0,0));
1715                 $$ = p.smobbed_copy ();
1716         }
1717         | TONICNAME_PITCH sub_quotes     {
1718                 Pitch p =* unsmob_pitch ($1);
1719
1720                 p = p.transposed (Pitch (-$2,0,0));
1721                 $$ = p.smobbed_copy ();
1722         }
1723         ;
1724
1725 pitch:
1726         steno_pitch {
1727                 $$ = $1;
1728         }
1729         ;
1730
1731 pitch_also_in_chords:
1732         pitch
1733         | steno_tonic_pitch
1734         ;
1735
1736 close_event:
1737         '('     {
1738                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1739                 $$ = s;
1740                 s->set_spot (THIS->here_input ());
1741         }
1742         | E_OPEN        {
1743                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1744                 $$ = s;
1745                 s->set_spot (THIS->here_input ());
1746         }
1747         | E_SMALLER {
1748                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1749                 $$ = s;
1750                 s->set_spot (THIS->here_input ());
1751         }
1752         | E_BIGGER {
1753                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1754                 $$ = s;
1755                 s->set_spot (THIS->here_input ());
1756         }
1757         ;
1758
1759
1760 open_event:
1761         E_EXCLAMATION   {
1762                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1763                 s->set_spot (THIS->here_input ());
1764
1765                 $$ = s;
1766         }
1767         | ')'   {
1768                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1769                 $$ = s;
1770                 s->set_spot (THIS->here_input ());
1771
1772         }
1773         | E_CLOSE       {
1774                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1775                 $$ = s;
1776                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1777                 s->set_spot (THIS->here_input ());
1778         }
1779         ;
1780
1781 gen_text_def:
1782         full_markup {
1783                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1784                 t->set_property ("text", $1);
1785                 t->set_spot (THIS->here_input ());
1786                 $$ = t;
1787         }
1788         | string {
1789                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1790                 t->set_property ("text", make_simple_markup (THIS->lexer_->encoding (), $1));
1791                 t->set_spot (THIS->here_input ());
1792                 $$ = t;
1793
1794         }
1795         | DIGIT {
1796                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1797                 t->set_property ("digit", scm_int2num ($1));
1798                 t->set_spot (THIS->here_input ());
1799                 $$ = t;
1800         }
1801         ;
1802
1803 script_abbreviation:
1804         '^'             {
1805                 $$ = scm_makfrom0str ("Hat");
1806         }
1807         | '+'           {
1808                 $$ = scm_makfrom0str ("Plus");
1809         }
1810         | '-'           {
1811                 $$ = scm_makfrom0str ("Dash");
1812         }
1813         | '|'           {
1814                 $$ = scm_makfrom0str ("Bar");
1815         }
1816         | '>'           {
1817                 $$ = scm_makfrom0str ("Larger");
1818         }
1819         | '.'           {
1820                 $$ = scm_makfrom0str ("Dot");
1821         }
1822         | '_' {
1823                 $$ = scm_makfrom0str ("Underscore");
1824         }
1825         ;
1826
1827 script_dir:
1828         '_'     { $$ = DOWN; }
1829         | '^'   { $$ = UP; }
1830         | '-'   { $$ = CENTER; }
1831         ;
1832
1833
1834 absolute_pitch:
1835         steno_pitch     {
1836                 $$ = $1;
1837         }
1838         ;
1839
1840 duration_length:
1841         multiplied_duration {
1842                 $$ = $1;
1843         }
1844         ;
1845
1846 optional_notemode_duration:
1847         {
1848                 Duration dd = THIS->default_duration_;
1849                 $$ = dd.smobbed_copy ();
1850
1851                 THIS->beam_check ($$);
1852         }
1853         | multiplied_duration   {
1854                 $$ = $1;
1855                 THIS->default_duration_ = *unsmob_duration ($$);
1856
1857                 THIS->beam_check ($$);
1858         }
1859         ;
1860
1861 steno_duration:
1862         bare_unsigned dots              {
1863                 int len = 0;
1864                 if (!is_duration ($1))
1865                         THIS->parser_error (_f ("not a duration: %d", $1));
1866                 else
1867                         len = intlog2 ($1);
1868
1869                 $$ = Duration (len, $2).smobbed_copy ();
1870         }
1871         | DURATION_IDENTIFIER dots      {
1872                 Duration *d = unsmob_duration ($1);
1873                 Duration k (d->duration_log (), d->dot_count () + $2);
1874                 *d = k;
1875                 $$ = $1;
1876         }
1877         ;
1878
1879
1880
1881
1882 multiplied_duration:
1883         steno_duration {
1884                 $$ = $1;
1885         }
1886         | multiplied_duration '*' bare_unsigned {
1887                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1888         }
1889         | multiplied_duration '*' FRACTION {
1890                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1891
1892                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1893         }
1894         ;
1895
1896 fraction:
1897         FRACTION { $$ = $1; }
1898         | UNSIGNED '/' UNSIGNED {
1899                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
1900         }
1901         ;
1902
1903 dots:
1904         /* empty */     {
1905                 $$ = 0;
1906         }
1907         | dots '.' {
1908                 $$ ++;
1909         }
1910         ;
1911
1912
1913 tremolo_type:
1914         ':'     {
1915                 $$ = 0;
1916         }
1917         | ':' bare_unsigned {
1918                 if (!is_duration ($2))
1919                         THIS->parser_error (_f ("not a duration: %d", $2));
1920                 $$ = $2;
1921         }
1922         ;
1923
1924
1925
1926 /*****************************************************************
1927                 BASS FIGURES
1928 *****************************************************************/
1929 bass_number:
1930         DIGIT   {
1931                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1932         }
1933         | UNSIGNED {
1934                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
1935         }
1936         | STRING { $$ = $1; }
1937         ;
1938
1939 bass_mod:
1940         '-'     { $$ = -2; }
1941         | '+'   { $$ = 2; }
1942         | '!'   { $$ = 0; }
1943         ;
1944
1945 bass_figure:
1946         FIGURE_SPACE {
1947                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1948                 $$ = bfr->self_scm ();
1949                 scm_gc_unprotect_object ($$);
1950         }
1951         | bass_number  {
1952                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1953                 $$ = bfr->self_scm ();
1954
1955                 bfr->set_property ("figure", $1);
1956
1957                 scm_gc_unprotect_object ($$);
1958         }
1959         | bass_figure bass_mod {
1960                 Music *m = unsmob_music ($1);
1961                 if ($2) {
1962                         SCM salter = m->get_property ("alteration");
1963                         int alter = is_number (salter) ? ly_scm2int (salter) : 0;
1964                         m->set_property ("alteration",
1965                                 scm_int2num (alter + $2));
1966                 } else {
1967                         m->set_property ("alteration", scm_int2num (0));
1968                 }
1969         }
1970         ;
1971
1972 br_bass_figure:
1973         '[' bass_figure {
1974                 $$ = $2;
1975                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1976         }
1977         | bass_figure   {
1978                 $$ = $1;
1979         }
1980         | br_bass_figure ']' {
1981                 $$ = $1;
1982                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1983         }
1984         ;
1985
1986 figure_list:
1987         /**/            {
1988                 $$ = SCM_EOL;
1989         }
1990         | figure_list br_bass_figure {
1991                 $$ = scm_cons ($2, $1);
1992         }
1993         ;
1994
1995 figure_spec:
1996         FIGURE_OPEN figure_list FIGURE_CLOSE {
1997                 Music *m = MY_MAKE_MUSIC ("EventChord");
1998                 $2 = scm_reverse_x ($2, SCM_EOL);
1999                 m->set_property ("elements", $2);
2000                 $$ = m->self_scm ();
2001         }
2002         ;
2003
2004
2005 optional_rest:
2006         /**/   { $$ = 0; }
2007         | REST { $$ = 1; }
2008         ;
2009
2010 simple_element:
2011         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2012
2013                 Input i = THIS->pop_spot ();
2014                 if (!THIS->lexer_->is_note_state ())
2015                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2016
2017                 Music *n = 0;
2018                 if ($6)
2019                         n = MY_MAKE_MUSIC ("RestEvent");
2020                 else
2021                         n = MY_MAKE_MUSIC ("NoteEvent");
2022
2023                 n->set_property ("pitch", $1);
2024                 n->set_property ("duration", $5);
2025
2026                 if (is_number ($4))
2027                 {
2028                         int q = ly_scm2int ($4);
2029                         n->set_property ("absolute-octave", scm_int2num (q-1));
2030                 }
2031
2032                 if ($3 % 2)
2033                         n->set_property ("cautionary", SCM_BOOL_T);
2034                 if ($2 % 2 || $3 % 2)
2035                         n->set_property ("force-accidental", SCM_BOOL_T);
2036
2037                 Music *v = MY_MAKE_MUSIC ("EventChord");
2038                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2039                 scm_gc_unprotect_object (n->self_scm ());
2040
2041                 v->set_spot (i);
2042                 n->set_spot (i);
2043                 $$ = v;
2044         }
2045         | DRUM_PITCH optional_notemode_duration {
2046                 Input i = THIS->pop_spot ();
2047
2048                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2049                 n->set_property ("duration", $2);
2050                 n->set_property ("drum-type", $1);
2051
2052                 Music *v = MY_MAKE_MUSIC ("EventChord");
2053                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2054                 scm_gc_unprotect_object (n->self_scm ());
2055                 v->set_spot (i);
2056                 n->set_spot (i);
2057                 $$ = v;
2058
2059         }
2060         | figure_spec optional_notemode_duration {
2061                 Music *m = unsmob_music ($1);
2062                 Input i = THIS->pop_spot ();
2063                 m->set_spot (i);
2064                 for (SCM s = m->get_property ("elements"); is_pair (s); s = ly_cdr (s))
2065                 {
2066                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2067                 }
2068                 $$ = m;
2069         }
2070         | RESTNAME optional_notemode_duration           {
2071
2072                 Input i = THIS->pop_spot ();
2073                 Music *ev = 0;
2074                 if (ly_scm2string ($1) == "s") {
2075                         /* Space */
2076                         ev = MY_MAKE_MUSIC ("SkipEvent");
2077                   }
2078                 else {
2079                         ev = MY_MAKE_MUSIC ("RestEvent");
2080
2081                     }
2082                 ev->set_property ("duration", $2);
2083                 ev->set_spot (i);
2084                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2085                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2086                 velt->set_spot (i);
2087
2088                 scm_gc_unprotect_object (ev->self_scm ());
2089
2090                 $$ = velt;
2091         }
2092         | MULTI_MEASURE_REST optional_notemode_duration         {
2093                 THIS->pop_spot ();
2094
2095                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2096                 SCM mus = scm_call_2 (proc, $2,
2097                         make_input (THIS->here_input ()));
2098                 scm_gc_protect_object (mus);
2099                 $$ = unsmob_music (mus);
2100         }
2101
2102         | lyric_element optional_notemode_duration      {
2103                 Input i = THIS->pop_spot ();
2104                 if (!THIS->lexer_->is_lyric_state ())
2105                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2106
2107                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2108                 lreq->set_property ("text", $1);
2109                 lreq->set_property ("duration",$2);
2110                 lreq->set_spot (i);
2111                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2112                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2113
2114                 $$= velt;
2115         }
2116         | new_chord {
2117                 THIS->pop_spot ();
2118
2119                 if (!THIS->lexer_->is_chord_state ())
2120                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2121                 $$ = unsmob_music ($1);
2122         }
2123         ;
2124
2125 lyric_element:
2126         full_markup { $$ = $1; }
2127         | STRING { $$ = $1; }
2128         ;
2129
2130 new_chord:
2131         steno_tonic_pitch optional_notemode_duration   {
2132                 $$ = make_chord ($1, $2, SCM_EOL);
2133         }
2134         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2135                 SCM its = scm_reverse_x ($4, SCM_EOL);
2136                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2137         }
2138         ;
2139
2140 chord_items:
2141         /**/ {
2142                 $$ = SCM_EOL;
2143         }
2144         | chord_items chord_item {
2145                 $$ = scm_cons ($2, $$);
2146         }
2147         ;
2148
2149 chord_separator:
2150         CHORD_COLON {
2151                 $$ = ly_symbol2scm ("chord-colon");
2152         }
2153         | CHORD_CARET {
2154                 $$ = ly_symbol2scm ("chord-caret");
2155         }
2156         | CHORD_SLASH steno_tonic_pitch {
2157                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2158         }
2159         | CHORD_BASS steno_tonic_pitch {
2160                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2161         }
2162         ;
2163
2164 chord_item:
2165         chord_separator {
2166                 $$ = $1;
2167         }
2168         | step_numbers {
2169                 $$ = scm_reverse_x ($1, SCM_EOL);
2170         }
2171         | CHORD_MODIFIER  {
2172                 $$ = $1;
2173         }
2174         ;
2175
2176 step_numbers:
2177         step_number { $$ = scm_cons ($1, SCM_EOL); }
2178         | step_numbers '.' step_number {
2179                 $$ = scm_cons ($3, $$);
2180         }
2181         ;
2182
2183 step_number:
2184         bare_unsigned {
2185                 $$ = make_chord_step ($1, 0);
2186         }
2187         | bare_unsigned '+' {
2188                 $$ = make_chord_step ($1, SHARP);
2189         }
2190         | bare_unsigned CHORD_MINUS {
2191                 $$ = make_chord_step ($1, FLAT);
2192         }
2193         ;
2194
2195 /*
2196         UTILITIES
2197
2198 TODO: should deprecate in favor of Scheme?
2199
2200  */
2201 number_expression:
2202         number_expression '+' number_term {
2203                 $$ = scm_sum ($1, $3);
2204         }
2205         | number_expression '-' number_term {
2206                 $$ = scm_difference ($1, $3);
2207         }
2208         | number_term
2209         ;
2210
2211 number_term:
2212         number_factor {
2213                 $$ = $1;
2214         }
2215         | number_factor '*' number_factor {
2216                 $$ = scm_product ($1, $3);
2217         }
2218         | number_factor '/' number_factor {
2219                 $$ = scm_divide ($1, $3);
2220         }
2221         ;
2222
2223 number_factor:
2224         '-'  number_factor { /* %prec UNARY_MINUS */
2225                 $$ = scm_difference ($2, SCM_UNDEFINED);
2226         }
2227         | bare_number
2228         ;
2229
2230
2231 bare_number:
2232         UNSIGNED        {
2233                 $$ = scm_int2num ($1);
2234         }
2235         | REAL          {
2236                 $$ = $1;
2237         }
2238         | NUMBER_IDENTIFIER             {
2239                 $$ = $1;
2240         }
2241         | REAL NUMBER_IDENTIFIER        {
2242                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2243         }
2244         | UNSIGNED NUMBER_IDENTIFIER    {
2245                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2246         }
2247         ;
2248
2249
2250 bare_unsigned:
2251         UNSIGNED {
2252                         $$ = $1;
2253         }
2254         | DIGIT {
2255                 $$ = $1;
2256         }
2257         ;
2258
2259 bare_int:
2260         bare_number {
2261                 if (scm_integer_p ($1) == SCM_BOOL_T)
2262                 {
2263                         int k = ly_scm2int ($1);
2264                         $$ = k;
2265                 } else
2266                 {
2267                         THIS->parser_error (_ ("need integer number arg"));
2268                         $$ = 0;
2269                 }
2270         }
2271         | '-' bare_int {
2272                 $$ = -$2;
2273         }
2274         ;
2275
2276
2277 string:
2278         STRING          {
2279                 $$ = $1;
2280         }
2281         | STRING_IDENTIFIER     {
2282                 $$ = $1;
2283         }
2284         | string '+' string {
2285                 $$ = scm_string_append (scm_list_2 ($1, $3));
2286         }
2287         ;
2288
2289
2290 exclamations:
2291                 { $$ = 0; }
2292         | exclamations '!'      { $$ ++; }
2293         ;
2294
2295 questions:
2296                 { $$ = 0; }
2297         | questions '?' { $$ ++; }
2298         ;
2299
2300
2301
2302 full_markup:
2303         MARKUP_IDENTIFIER {
2304                 $$ = $1;
2305         }
2306         | MARKUP
2307                 { THIS->lexer_->push_markup_state (); }
2308         markup
2309                 { $$ = $3;
2310                   THIS->lexer_->pop_state ();
2311                 }
2312         ;
2313
2314
2315 /*
2316 This should be done more dynamically if possible.
2317 */
2318 markup:
2319         STRING {
2320                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2321         }
2322         | MARKUP_HEAD_EMPTY {
2323                 $$ = scm_list_1 ($1);
2324         }
2325         | MARKUP_HEAD_MARKUP0 markup {
2326                 $$ = scm_list_2 ($1, $2);
2327         }
2328         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2329                 $$ = scm_list_3 ($1, $2, $3);
2330         }
2331         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2332                 $$ = scm_list_3 ($1, $2, $3);
2333         }
2334         | markup_line {
2335                 $$ = $1;
2336         }
2337         | MARKUP_HEAD_LIST0 markup_list {
2338                 $$ = scm_list_2 ($1,$2);
2339         }
2340         | MARKUP_HEAD_SCM0 embedded_scm {
2341                 $$ = scm_list_2 ($1, $2);
2342         }
2343         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2344                 $$ = scm_list_4 ($1, $2, $3, $4);
2345         }
2346         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2347                 $$ = scm_list_4 ($1, $2, $3, $4);
2348         }
2349         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2350                 $$ = scm_list_3 ($1, $2, $3);
2351         }
2352         | MARKUP_IDENTIFIER {
2353                 $$ = $1;
2354         }
2355         | STRING_IDENTIFIER {
2356                 $$ = $1;
2357         }
2358         ;
2359
2360 markup_list:
2361         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2362         ;
2363
2364 markup_line:
2365         '{' markup_list_body '}' {
2366                 SCM line = ly_scheme_function ("line-markup");
2367
2368                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2369         }
2370         ;
2371
2372 markup_list_body:
2373         /**/ {  $$ = SCM_EOL; }
2374         | markup_list_body markup {
2375                 $$ = scm_cons ($2, $1);
2376         }
2377         ;
2378
2379
2380 %%
2381
2382 void
2383 My_lily_parser::set_yydebug (bool )
2384 {
2385 #if 0
2386         yydebug = 1;
2387 #endif
2388 }
2389
2390 void
2391 My_lily_parser::do_yyparse ()
2392 {
2393         yyparse ((void*)this);
2394 }
2395
2396
2397 /*
2398 Should make this optional?    It will also complain when you do
2399
2400         [s4]
2401
2402 which is entirely legitimate.
2403
2404 Or we can scrap it. Barchecks should detect wrong durations, and
2405 skipTypesetting speeds it up a lot.
2406 */
2407
2408 void
2409 My_lily_parser::beam_check (SCM dur)
2410 {
2411   Duration *d = unsmob_duration (dur);
2412   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2413     {
2414       Music *m = unsmob_music (last_beam_start_);
2415       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2416     }
2417   last_beam_start_ = SCM_EOL;
2418 }
2419
2420
2421
2422
2423 /*
2424
2425 It is a little strange to have this function in this file, but
2426 otherwise, we have to import music classes into the lexer.
2427
2428 */
2429 int
2430 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2431 {
2432         if (is_string (sid)) {
2433                 *destination = sid;
2434                 return STRING_IDENTIFIER;
2435         } else if (is_number (sid)) {
2436                 *destination = sid;
2437                 return NUMBER_IDENTIFIER;
2438         } else if (unsmob_context_def (sid)) {
2439                 *destination = unsmob_context_def (sid)->clone_scm ();
2440                 return CONTEXT_DEF_IDENTIFIER;
2441         } else if (unsmob_score (sid)) {
2442                 Score *sc = new Score (*unsmob_score (sid));
2443                 *destination = sc->self_scm ();
2444                 return SCORE_IDENTIFIER;
2445         } else if (Music *mus = unsmob_music (sid)) {
2446                 mus = mus->clone ();
2447                 *destination = mus->self_scm ();
2448                 unsmob_music (*destination)->
2449                         set_property ("origin", make_input (last_input_));
2450                 return dynamic_cast<Event*> (mus)
2451                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2452         } else if (unsmob_duration (sid)) {
2453                 *destination = unsmob_duration (sid)->smobbed_copy ();
2454                 return DURATION_IDENTIFIER;
2455         } else if (unsmob_music_output_def (sid)) {
2456                 Music_output_def *p = unsmob_music_output_def (sid);
2457                 p = p->clone ();
2458
2459                 *destination = p->self_scm ();
2460                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2461         } else if (Text_item::markup_p (sid)) {
2462                 *destination = sid;
2463                 return MARKUP_IDENTIFIER;
2464         }
2465
2466         return -1;
2467 }
2468
2469 Music *
2470 property_op_to_music (SCM op)
2471 {
2472         Music *m = 0;
2473         SCM tag = ly_car (op);
2474         SCM symbol = ly_cadr (op);
2475         SCM args = ly_cddr (op);
2476         SCM grob_val = SCM_UNDEFINED;
2477         SCM grob_sym = SCM_UNDEFINED;
2478         SCM val = SCM_UNDEFINED;
2479
2480         if (tag == ly_symbol2scm ("assign"))
2481                 {
2482                 m = MY_MAKE_MUSIC ("PropertySet");
2483                 val = ly_car (args);
2484                 }
2485         else if (tag == ly_symbol2scm ("unset"))
2486                 m = MY_MAKE_MUSIC ("PropertyUnset");
2487         else if (tag == ly_symbol2scm ("poppush")
2488                  || tag == ly_symbol2scm ("push"))
2489                 {
2490                 m = MY_MAKE_MUSIC ("OverrideProperty");
2491                 grob_sym = ly_car (args);
2492                 grob_val = ly_cadr (args);
2493                 }
2494         else if (tag == ly_symbol2scm ("pop")) {
2495                 m = MY_MAKE_MUSIC ("RevertProperty");
2496                 grob_sym = ly_car (args);
2497                 }
2498
2499         m->set_property ("symbol", symbol);
2500
2501         if (val != SCM_UNDEFINED)
2502                 m->set_property ("value", val);
2503         if (grob_val != SCM_UNDEFINED)
2504                 m->set_property ("grob-value", grob_val);
2505
2506         if (grob_sym != SCM_UNDEFINED)
2507                 {
2508                 bool itc = internal_type_checking_global_b;
2509                 /* UGH.
2510                 */
2511                 bool autobeam = is_equal (symbol, ly_symbol2scm ("autoBeamSettings"));
2512                 if (autobeam)
2513                         internal_type_checking_global_b = false;
2514                 m->set_property ("grob-property", grob_sym);
2515                 if (autobeam)
2516                         internal_type_checking_global_b = itc;
2517                 }
2518
2519         if (op == ly_symbol2scm ("poppush"))
2520                 m->set_property ("pop-first", SCM_BOOL_T);
2521
2522
2523         return m;
2524 }
2525
2526 Music*
2527 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2528 {
2529         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2530
2531         csm->set_property ("element", m->self_scm ());
2532         scm_gc_unprotect_object (m->self_scm ());
2533
2534         csm->set_property ("context-type",
2535                 is_symbol (type) ? type : scm_string_to_symbol (type));
2536         csm->set_property ("property-operations", ops);
2537
2538         if (is_string (id))
2539                 csm->set_property ("context-id", id);
2540         return csm;
2541 }
2542
2543
2544 SCM
2545 get_next_unique_context ()
2546 {
2547         static int new_context_count;
2548
2549         char s[1024];
2550         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2551
2552         return scm_makfrom0str (s);
2553 }
2554