lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token LYRICS_STRING
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token NEWLYRICS
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 /* FIXME: this sucks.  The user will get to see these names:
 310     syntax error, unexpected E_CHAR:
 311                 \
 312                  %%
 313   */
 314 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 315 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 316 %token E_BACKSLASH
 317 %token <i> E_UNSIGNED
 318 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 319 %token FIGURE_SPACE
 320
 321 %token <i>      DIGIT
 322 %token <scm>    NOTENAME_PITCH
 323 %token <scm>    TONICNAME_PITCH
 324 %token <scm>    CHORDMODIFIER_PITCH
 325 %token <scm>    DURATION_IDENTIFIER
 326 %token <scm>    FRACTION
 327 %token <id>     IDENTIFIER
 328 %token DRUMS
 329 %token <scm>    DRUM_PITCH
 330 %token <scm>    CHORD_MODIFIER
 331 %token <scm>    SCORE_IDENTIFIER
 332 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    NUMBER_IDENTIFIER
 334 %token <scm>    EVENT_IDENTIFIER
 335 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 336 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm>    STRING
 339 %token <scm>    SCM_T
 340 %token <i>      UNSIGNED
 341 %token <scm>   REAL
 342
 343 %token MARKUP
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_EMPTY
 346 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0
 348 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 352
 353 %token <scm> MUSIC_FUNCTION
 354 %token <scm> MUSIC_FUNCTION_SCM
 355 %token <scm> MUSIC_FUNCTION_MUSIC
 356 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 357 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 360
 361 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 362 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 363
 364 %type <book>    book_block book_body
 365 %type <outputdef> book_paper_head book_paper_block book_paper_body
 366
 367 %type <i>       exclamations questions dots optional_rest
 368 %type <i>       bass_mod
 369 %type <scm>     oct_check
 370 %type <scm>     context_mod_list
 371 %type <scm>     lyric_element
 372 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 373 %type <scm>     new_lyrics
 374 %type <outputdef> output_def
 375 %type <scm>     lilypond_header lilypond_header_body
 376 %type <music>   open_event close_event
 377 %type <i>       sub_quotes sup_quotes
 378 %type <music>   toplevel_music
 379 %type <music>   simple_element event_chord command_element
 380 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 381 %type <scm>     Generic_prefix_music_scm
 382 %type <music>   Grouped_music_list
 383 %type <music>   Repeated_music
 384 %type <scm>     Alternative_music
 385 %type <i>       tremolo_type
 386 %type <i>       bare_int  bare_unsigned
 387 %type <i>       script_dir
 388 %type <scm>     identifier_init
 389 %type <scm>     simple_string
 390
 391 %type <music>   note_chord_element chord_body chord_body_element
 392 %type <scm>     chord_body_elements
 393 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 394
 395 %type <scm>     post_events
 396 %type <music>   gen_text_def direction_less_event direction_reqd_event
 397 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 398 %type <scm>     steno_tonic_pitch
 399 %type <scm>     duration_length fraction
 400
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     step_number step_numbers
 403
 404 %type <scm>     embedded_scm scalar
 405 %type <music>   Music Sequential_music Simultaneous_music
 406 %type <music>   relative_music re_rhythmed_music
 407 %type <music>   music_property_def context_change
 408 %type <scm>     context_prop_spec
 409 %type <scm>     Music_list
 410 %type <scm>     property_operation
 411 %type <scm>     context_mod context_def_mod optional_context_mod
 412 %type <outputdef>       music_output_def_body music_output_def_head
 413 %type <music>   post_event tagged_post_event
 414 %type <music>   command_req
 415 %type <music>   string_number_event
 416 %type <scm>     string bare_number number_expression number_term number_factor
 417 %type <score>   score_block score_body
 418
 419 %type <scm>     context_def_spec_block context_def_spec_body
 420 %type <music>   tempo_event
 421 %type <scm>     script_abbreviation
 422
 423
 424
 425 %left '-' '+'
 426
 427 /* We don't assign precedence to / and *, because we might need varied
 428 prec levels in different prods */
 429
 430 %left UNARY_MINUS
 431
 432 %%
 433
 434 lilypond:       /* empty */
 435         | lilypond toplevel_expression {
 436         }
 437         | lilypond assignment {
 438         }
 439         | lilypond error {
 440                 THIS->error_level_ = 1;
 441         }
 442         | lilypond INVALID      {
 443                 THIS->error_level_ = 1;
 444         }
 445         ;
 446
 447 toplevel_expression:
 448         lilypond_header {
 449                 THIS->header_ = $1;
 450         }
 451         | add_quote {
 452
 453         }
 454         | book_block {
 455                 Book *book = $1;
 456                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 457                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 458                 scm_gc_unprotect_object (book->self_scm ());
 459         }
 460         | score_block {
 461                 Score *score = $1;
 462
 463                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 464                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 465                 scm_gc_unprotect_object (score->self_scm ());
 466         }
 467         | toplevel_music {
 468                 Music *music = $1;
 469                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 470                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 471                 scm_gc_unprotect_object (music->self_scm ());
 472         }
 473         | output_def {
 474                 SCM id = SCM_EOL;
 475                 Output_def * od = $1;
 476
 477                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 478                         id = ly_symbol2scm ("$defaultpaper");
 479                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 480                         id = ly_symbol2scm ("$defaultmidi");
 481                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 482                         id = ly_symbol2scm ("$defaultbookpaper");
 483
 484                 THIS->lexer_->set_identifier (id, od->self_scm ());
 485                 scm_gc_unprotect_object (od->self_scm ());
 486         }
 487         | book_paper_block {
 488                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultbookpaper"), $1->self_scm ());
 489                 scm_gc_unprotect_object ($1->self_scm ());
 490         }
 491         ;
 492
 493 toplevel_music:
 494         Composite_music {
 495         }
 496         ;
 497
 498 embedded_scm:
 499         SCM_T
 500         | SCM_IDENTIFIER
 501         ;
 502
 503
 504 lilypond_header_body:
 505         {
 506                 $$ = ly_make_anonymous_module (safe_global_b);
 507                 THIS->lexer_->add_scope ($$);
 508         }
 509         | lilypond_header_body assignment  {
 510
 511         }
 512         ;
 513
 514 lilypond_header:
 515         HEADER '{' lilypond_header_body '}'     {
 516                 $$ = THIS->lexer_->remove_scope ();
 517         }
 518         ;
 519
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment:
 525         STRING {
 526                 THIS->push_spot ();
 527         }
 528         /* cont */ '=' identifier_init  {
 529
 530         /*
 531                 Should find generic way of associating input with objects.
 532         */
 533                 Input ip = THIS->pop_spot ();
 534
 535                 if (! is_regular_identifier ($1))
 536                 {
 537                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 538                 }
 539
 540                 THIS->lexer_->set_identifier ($1, $4);
 541
 542 /*
 543  TODO: devise standard for protection in parser.
 544
 545   The parser stack lives on the C-stack, which means that
 546 all objects can be unprotected as soon as they're here.
 547
 548 */
 549         }
 550         | embedded_scm { }
 551         ;
 552
 553
 554 identifier_init:
 555         score_block {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | full_markup {
 560                 $$ = $1;
 561         }
 562         | output_def {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | context_def_spec_block {
 567                 $$ = $1;
 568         }
 569         | Music  {
 570                 $$ = $1->self_scm ();
 571                 scm_gc_unprotect_object ($$);
 572         }
 573         | post_event {
 574                 $$ = $1->self_scm ();
 575                 scm_gc_unprotect_object ($$);
 576         }
 577         | number_expression {
 578                 $$ = $1;
 579         }
 580         | string {
 581                 $$ = $1;
 582         }
 583         | embedded_scm  {
 584                 $$ = $1;
 585         }
 586         ;
 587
 588 context_def_spec_block:
 589         CONTEXT '{' context_def_spec_body '}'
 590                 {
 591                 $$ = $3;
 592         }
 593         ;
 594
 595 context_def_spec_body:
 596         /**/ {
 597                 $$ = Context_def::make_scm ();
 598                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 599         }
 600         | CONTEXT_DEF_IDENTIFIER {
 601                 $$ = $1;
 602                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 603         }
 604         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 605                 Context_def*td = unsmob_context_def ($$);
 606
 607                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 608                         SCM tag = ly_caar (p);
 609
 610                         /* TODO: should make new tag "grob-definition" ? */
 611                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 612                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 613                 }
 614         }
 615         | context_def_spec_body context_mod {
 616                 unsmob_context_def ($$)->add_context_mod ($2);
 617         }
 618         ;
 619
 620
 621 book_paper_block:
 622         book_paper_body '}' {
 623                 $$ = $1;
 624                 THIS->lexer_->remove_scope ();
 625         }
 626         ;
 627 book_paper_head:
 628         BOOKPAPER '{' {
 629                 $$ = get_bookpaper (THIS);
 630                 $$->input_origin_ = THIS->here_input ();
 631                 THIS->lexer_->add_scope ($$->scope_);
 632         }
 633         ;
 634
 635 book_paper_body:
 636         book_paper_head
 637         | book_paper_body assignment { }
 638         ;
 639
 640
 641
 642 book_block:
 643         BOOK {
 644                 THIS->push_spot ();
 645         }
 646         /*cont*/ '{' book_body '}'      {
 647                 THIS->pop_spot ();
 648                 $$ = $4;
 649         }
 650         ;
 651
 652 /* FIXME:
 653    * Use 'handlers' like for toplevel-* stuff?
 654    * grok \paper and \midi?  */
 655 book_body:
 656         {
 657                 $$ = new Book;
 658                 $$->set_spot (THIS->here_input ());
 659                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 660                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 661         }
 662         | book_body book_paper_block {
 663                 $$->bookpaper_ = $2;
 664                 scm_gc_unprotect_object ($2->self_scm ());
 665         }
 666         | book_body score_block {
 667                 Score *score = $2;
 668                 $$->scores_.push (score);
 669                 scm_gc_unprotect_object (score->self_scm ());
 670         }
 671         | book_body Composite_music {
 672                 Music *music = $2;
 673                 Score *score
 674                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 675                 $$->scores_.push (score);
 676                 scm_gc_unprotect_object (music->self_scm ());
 677         }
 678         | lilypond_header {
 679                 THIS->header_ = $1;
 680         }
 681         | book_body error {
 682
 683         }
 684         ;
 685
 686 score_block:
 687         SCORE {
 688                 THIS->push_spot ();
 689         }
 690         /*cont*/ '{' score_body '}'     {
 691                 THIS->pop_spot ();
 692                 $$ = $4;
 693         }
 694         ;
 695
 696 score_body:
 697         Music   {
 698                 $$ = new Score;
 699
 700                 $$->set_spot (THIS->here_input ());
 701                 SCM m = $1->self_scm ();
 702                 scm_gc_unprotect_object (m);
 703
 704                 /*
 705                         guh.
 706                 */
 707                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 708                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 709                         m = scm_call_1 (ly_car (check_funcs), m);
 710                 $$->music_ = m;
 711
 712         }
 713         | SCORE_IDENTIFIER {
 714                 $$ = new Score ( *unsmob_score ($1));
 715                 $$->set_spot (THIS->here_input ());
 716         }
 717         | score_body lilypond_header    {
 718                 $$->header_ = $2;
 719         }
 720         | score_body output_def {
 721                 $$->defs_.push ($2);
 722                 scm_gc_unprotect_object ($2->self_scm ());
 723         }
 724         | score_body error {
 725
 726         }
 727         ;
 728
 729
 730 /*
 731         MIDI
 732 */
 733 output_def:
 734         music_output_def_body '}' {
 735                 $$ = $1;
 736                 if ($1->parent_)
 737                         THIS->lexer_->remove_scope ();
 738
 739                 THIS->lexer_->remove_scope ();
 740                 THIS->lexer_->pop_state ();
 741         }
 742         ;
 743
 744 music_output_def_head:
 745         MIDI    {
 746                 Output_def *p = get_midi (THIS);
 747                 $$ = p;
 748                 THIS->lexer_->add_scope (p->scope_);
 749         }
 750         | PAPER         {
 751                 Output_def* p = get_paper (THIS);
 752
 753                 if (p->parent_)
 754                         THIS->lexer_->add_scope (p->parent_->scope_);
 755
 756                 THIS->lexer_->add_scope (p->scope_);
 757                 $$ = p;
 758         }
 759         ;
 760
 761
 762 music_output_def_body:
 763         music_output_def_head '{' {
 764                 $$ = $1;
 765                 $$->input_origin_.set_spot (THIS->here_input ());
 766                 THIS->lexer_->push_initial_state ();
 767         }
 768         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 769                 scm_gc_unprotect_object ($1->self_scm ());
 770                 Output_def *o = unsmob_output_def ($3);
 771                 o->input_origin_.set_spot (THIS->here_input ());
 772                 $$ = o;
 773                 THIS->lexer_->remove_scope ();
 774                 THIS->lexer_->add_scope (o->scope_);
 775                 THIS->lexer_->push_initial_state ();
 776         }
 777         | music_output_def_body assignment  {
 778
 779         }
 780         | music_output_def_body context_def_spec_block  {
 781                 assign_context_def ($$, $2);
 782         }
 783         | music_output_def_body tempo_event  {
 784                 /*
 785                         junk this ? there already is tempo stuff in
 786                         music.
 787                 */
 788                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 789                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 790                 set_tempo ($$, d->get_length (), m);
 791                 scm_gc_unprotect_object ($2->self_scm ());
 792         }
 793         | music_output_def_body error {
 794
 795         }
 796         ;
 797
 798 tempo_event:
 799         TEMPO steno_duration '=' bare_unsigned  {
 800                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 801                 $$->set_property ("tempo-unit", $2);
 802                 $$->set_property ("metronome-count", scm_int2num ( $4));
 803         }
 804         ;
 805
 806 /*
 807 The representation of a  list is the
 808
 809   (LIST . LAST-CONS)
 810
 811  to have  efficient append.
 812 */
 813 Music_list:
 814         /* empty */ {
 815                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 816         }
 817         | Music_list Music {
 818                 SCM s = $$;
 819                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 820                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 821                 if (ly_c_pair_p (ly_cdr (s)))
 822                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 823                 else
 824                         scm_set_car_x (s, c); /* set first cons */
 825                 scm_set_cdr_x (s, c);  /* remember last cell */
 826         }
 827         | Music_list embedded_scm {
 828         }
 829         | Music_list error {
 830         }
 831         ;
 832
 833
 834 Music:
 835         Simple_music
 836         | Composite_music
 837         ;
 838
 839 Alternative_music:
 840         /* empty */ {
 841                 $$ = SCM_EOL;
 842         }
 843         | ALTERNATIVE '{' Music_list '}' {
 844                 $$ = $3;
 845         }
 846         ;
 847
 848
 849 Repeated_music:
 850         REPEAT simple_string bare_unsigned Music Alternative_music
 851         {
 852                 Music *beg = $4;
 853                 int times = $3;
 854                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 855                 if (times < scm_ilength (alts)) {
 856                   unsmob_music (ly_car (alts))
 857                     ->origin ()->warning (
 858                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 859                   alts = ly_truncate_list (times, alts);
 860                 }
 861
 862
 863                 SCM proc = ly_scheme_function ("make-repeated-music");
 864
 865                 SCM mus = scm_call_1 (proc, $2);
 866                 scm_gc_protect_object (mus); // UGH.
 867                 Music *r = unsmob_music (mus);
 868                 if (beg)
 869                         {
 870                         r-> set_property ("element", beg->self_scm ());
 871                         scm_gc_unprotect_object (beg->self_scm ());
 872                         }
 873                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 874
 875                 r-> set_property ("elements",alts);
 876                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 877                         /*
 878                         TODO: move this code to Scheme.
 879                         */
 880
 881                         /*
 882                         we can not get durations and other stuff correct down the line, so we have to
 883                         add to the duration log here.
 884                         */
 885                         SCM func = ly_scheme_function ("shift-duration-log");
 886
 887                         int dots = ($3 % 3) ? 0 : 1;
 888                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 889
 890                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 891
 892                         if (seq) {
 893                                 int list_len = scm_ilength (seq->music_list ());
 894                                 if (list_len != 2)
 895                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 896                                 shift -= 1;
 897                                 r->compress (Moment (Rational (1, list_len)));
 898                                 }
 899                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 900
 901                 }
 902                 r->set_spot (*$4->origin ());
 903
 904                 $$ = r;
 905         }
 906         ;
 907
 908 Sequential_music:
 909         SEQUENTIAL '{' Music_list '}'           {
 910                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 911                 $$->set_property ("elements", ly_car ($3));
 912                 $$->set_spot (THIS->here_input ());
 913         }
 914         | '{' Music_list '}'            {
 915                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 916                 $$->set_property ("elements", ly_car ($2));
 917                 $$->set_spot (THIS->here_input ());
 918         }
 919         ;
 920
 921 Simultaneous_music:
 922         SIMULTANEOUS '{' Music_list '}'{
 923                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 924                 $$->set_property ("elements", ly_car ($3));
 925                 $$->set_spot (THIS->here_input ());
 926
 927         }
 928         | simul_open Music_list simul_close     {
 929                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 930                 $$->set_property ("elements", ly_car ($2));
 931                 $$->set_spot (THIS->here_input ());
 932         }
 933         ;
 934
 935 Simple_music:
 936         event_chord             { $$ = $1; }
 937         | MUSIC_IDENTIFIER {
 938                 $$ = unsmob_music ($1);
 939         }
 940         | music_property_def
 941         | context_change
 942         ;
 943
 944
 945 optional_context_mod:
 946         /**/ { $$ = SCM_EOL; }
 947         | WITH { THIS->lexer_->push_initial_state (); }
 948         '{' context_mod_list '}'
 949         {
 950                 THIS->lexer_->pop_state ();
 951                 $$ = $4;
 952         }
 953         ;
 954
 955 context_mod_list:
 956         /* */  { $$ = SCM_EOL; }
 957         | context_mod_list context_mod  {
 958                  $$ = scm_cons ($2, $1);
 959         }
 960         ;
 961
 962
 963 Composite_music:
 964         Prefix_composite_music { $$ = $1; }
 965         | Grouped_music_list { $$ = $1; }
 966         ;
 967
 968 Grouped_music_list:
 969         Simultaneous_music              { $$ = $1; }
 970         | Sequential_music              { $$ = $1; }
 971         ;
 972
 973 Generic_prefix_music_scm:
 974         MUSIC_FUNCTION {
 975                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 976         }
 977         | MUSIC_FUNCTION_SCM {
 978                 THIS->push_spot ();
 979         } embedded_scm {
 980                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 981         }
 982         | MUSIC_FUNCTION_MUSIC {
 983                 THIS->push_spot ();
 984         } Music {
 985                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 986                 scm_gc_unprotect_object ($3->self_scm ());
 987         }
 988         | MUSIC_FUNCTION_SCM_MUSIC {
 989                 THIS->push_spot ();
 990         }  embedded_scm Music {
 991                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 992                 scm_gc_unprotect_object ($4->self_scm ());
 993         }
 994         | MUSIC_FUNCTION_MUSIC_MUSIC {
 995                 THIS->push_spot ();
 996         }  Music  Music {
 997                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 998                 scm_gc_unprotect_object ($3->self_scm ());
 999                 scm_gc_unprotect_object ($4->self_scm ());
1000         }
1001         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1002                 THIS->push_spot ();
1003         } embedded_scm Music Music {
1004                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1005                         $3, $4->self_scm (), $5->self_scm ());
1006                 scm_gc_unprotect_object ($5->self_scm ());
1007                 scm_gc_unprotect_object ($4->self_scm ());
1008         }
1009         ;
1010
1011 Generic_prefix_music:
1012         Generic_prefix_music_scm {
1013                 SCM func = ly_car ($1);
1014                 Input *loc = unsmob_input (ly_cadr ($1));
1015                 SCM args = ly_cddr ($1);
1016                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1017                 int k = 0;
1018                 bool ok  = true;
1019                 for (SCM s = sig, t = args;
1020                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1021                         s = ly_cdr (s), t = ly_cdr (t)) {
1022                         k++;
1023                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1024                         {
1025                                 loc->error (_f ("Argument %d failed typecheck", k));
1026                                 THIS->error_level_ = 1;
1027                                 ok = false;
1028                         }
1029                 }
1030                 SCM m = SCM_EOL;
1031                 if (ok)
1032                         m = scm_apply_0 (func, ly_cdr ($1));
1033                 if (unsmob_music (m))
1034                         {
1035                         $$ = unsmob_music (m);
1036                         scm_gc_protect_object (m);
1037                         }
1038                 else
1039                         {
1040                         if (ok)
1041                                 loc->error (_ ("Music head function should return Music object."));
1042                         $$ = MY_MAKE_MUSIC ("Music");
1043                         }
1044                 $$->set_spot (*loc);
1045         }
1046         ;
1047
1048
1049 Prefix_composite_music:
1050         Generic_prefix_music {
1051                 $$ = $1;
1052         }
1053         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1054                 $$ = context_spec_music ($2, $4, $6, $5);
1055
1056         }
1057         | CONTEXT simple_string optional_context_mod Music {
1058                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1059         }
1060         | NEWCONTEXT simple_string optional_context_mod Music {
1061                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1062                         $3);
1063         }
1064
1065         | TIMES {
1066                 THIS->push_spot ();
1067         }
1068         /* CONTINUED */
1069                 fraction Music
1070
1071         {
1072                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1073                 Music *mp = $4;
1074
1075                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1076                 $$->set_spot (THIS->pop_spot ());
1077
1078                 $$->set_property ("element", mp->self_scm ());
1079                 scm_gc_unprotect_object (mp->self_scm ());
1080                 $$->set_property ("numerator", scm_int2num (n));
1081                 $$->set_property ("denominator", scm_int2num (d));
1082                 $$->compress (Moment (Rational (n,d)));
1083
1084         }
1085         | Repeated_music                { $$ = $1; }
1086         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1087                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1088                 Music *p = $4;
1089                 Pitch from = *unsmob_pitch ($2);
1090                 Pitch to = *unsmob_pitch ($3);
1091
1092                 p->transpose (interval (from, to));
1093                 $$->set_property ("element", p->self_scm ());
1094                 scm_gc_unprotect_object (p->self_scm ());
1095         }
1096         | NOTES
1097                 {
1098                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1099                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1100         }
1101         Music
1102                 { $$ = $3;
1103                   THIS->lexer_->pop_state ();
1104                 }
1105         | DRUMS
1106                 {
1107                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1108                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1109         }
1110         /* FIXME: This used to be: */
1111         Music
1112 /*      Grouped_music_list */
1113                 { $$ = $3;
1114                   THIS->lexer_->pop_state ();
1115                 }
1116         | FIGURES
1117                 { THIS->lexer_->push_figuredbass_state (); }
1118         /* FIXME: This used to be:
1119         Music
1120         but that breaks web build
1121         */
1122         Grouped_music_list
1123                 {
1124                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1125                   chm->set_property ("element", $3->self_scm ());
1126                   $$ = chm;
1127                   scm_gc_unprotect_object ($3->self_scm ());
1128
1129                   THIS->lexer_->pop_state ();
1130         }
1131         | CHORDS {
1132                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1133                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1134                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1135                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1136
1137         }
1138         /* FIXME:
1139         Music
1140 */
1141         Grouped_music_list
1142         {
1143                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1144                   chm->set_property ("element", $3->self_scm ());
1145                   scm_gc_unprotect_object ($3->self_scm ());
1146                   $$ = chm;
1147
1148                   THIS->lexer_->pop_state ();
1149         }
1150         | LYRICS
1151                 { THIS->lexer_->push_lyric_state (); }
1152         /* FIXME:
1153         Music
1154 */
1155         Grouped_music_list
1156                 {
1157                   $$ = $3;
1158                   THIS->lexer_->pop_state ();
1159         }
1160         | relative_music        { $$ = $1; }
1161         | re_rhythmed_music     { $$ = $1; }
1162         | TAG embedded_scm Music {
1163                 tag_music ($3, $2, THIS->here_input ());
1164                 $$ = $3;
1165         }
1166         ;
1167
1168 relative_music:
1169         RELATIVE absolute_pitch Music {
1170                 Music *m = $3;
1171                 Pitch start = *unsmob_pitch ($2);
1172                 $$ = make_music_relative (start, m);
1173                 scm_gc_unprotect_object (m->self_scm ());
1174         }
1175         | RELATIVE Composite_music {
1176                 Music *m = $2;
1177                 /* FIXME: why is octave==0 and default not middleC? */
1178                 Pitch middle_c (-1, 0, 0);
1179                 $$ = make_music_relative (middle_c, m);
1180                 scm_gc_unprotect_object (m->self_scm ());
1181         }
1182         ;
1183
1184 new_lyrics:
1185         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1186         /*cont */
1187         Grouped_music_list {
1188         /* Can also use Music at the expensive of two S/Rs similar to
1189            \repeat \alternative */
1190                 THIS->lexer_->pop_state ();
1191 #if 0
1192                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1193                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1194                 $$ = music;
1195 #else
1196                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1197 #endif
1198         }
1199         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1200         Grouped_music_list {
1201                 THIS->lexer_->pop_state ();
1202                 $$ = scm_cons ($4->self_scm (), $1);
1203         }
1204         ;
1205
1206 re_rhythmed_music:
1207         Grouped_music_list new_lyrics {
1208
1209                 /* FIXME: should find out uniqueXXX name from music */
1210                 SCM name = $1->get_property ("context-id");
1211                 //if (name == SCM_EOL)
1212                 if (!ly_c_string_p (name))
1213                         name = scm_makfrom0str ("");
1214
1215                 SCM context = scm_makfrom0str ("Lyrics");
1216                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1217
1218                 SCM lst = SCM_EOL;
1219                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1220                 {
1221                         Music *music = unsmob_music (ly_car (s));
1222                         Music *com = make_lyric_combine_music (name, music);
1223                         Music *csm = context_spec_music (context,
1224                                 get_next_unique_context (), com, SCM_EOL);
1225                         lst = scm_cons (csm->self_scm (), lst);
1226                 }
1227                 /* FIXME: only first lyric music is accepted,
1228                           the rest is junked */
1229                 all->set_property ("elements", scm_cons ($1->self_scm (),
1230                         lst));
1231                 $$ = all;
1232                 scm_gc_unprotect_object ($1->self_scm ());
1233         }
1234         | LYRICSTO string Music {
1235                 Music *music = $3;
1236                 SCM name = $2;
1237                 $$ = make_lyric_combine_music (name, music);
1238                 scm_gc_unprotect_object (music->self_scm ());
1239         }
1240         ;
1241
1242 context_change:
1243         CHANGE STRING '=' STRING  {
1244                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1245                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1246                 t-> set_property ("change-to-id", $4);
1247
1248                 $$ = t;
1249                 $$->set_spot (THIS->here_input ());
1250         }
1251         ;
1252
1253 property_operation:
1254         STRING '=' scalar {
1255                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1256                         scm_string_to_symbol ($1), $3);
1257         }
1258         | UNSET simple_string {
1259                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1260                         scm_string_to_symbol ($2));
1261         }
1262         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1263                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1264                         scm_string_to_symbol ($2), $3, $5);
1265         }
1266         | REVERT simple_string embedded_scm {
1267                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1268                         scm_string_to_symbol ($2), $3);
1269         }
1270         ;
1271
1272 context_def_mod:
1273         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1274         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1275         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1276
1277         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1278         | DENIES { $$ = ly_symbol2scm ("denies"); }
1279
1280         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1281         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1282         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1283         | NAME { $$ = ly_symbol2scm ("context-name"); }
1284         ;
1285
1286 context_mod:
1287         property_operation { $$ = $1; }
1288         | context_def_mod STRING {
1289                 $$ = scm_list_2 ($1, $2);
1290         }
1291         ;
1292
1293 context_prop_spec:
1294         simple_string {
1295                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1296                         scm_string_to_symbol ($1));
1297         }
1298         | simple_string '.' simple_string {
1299                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1300                         scm_string_to_symbol ($3));
1301         }
1302         ;
1303
1304 music_property_def:
1305         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1306                 $$ = property_op_to_music (scm_list_4 (
1307                         ly_symbol2scm ("poppush"),
1308                         ly_cadr ($2),
1309                         $3, $5));
1310                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1311         }
1312         | REVERT context_prop_spec embedded_scm {
1313                 $$ = property_op_to_music (scm_list_3 (
1314                         ly_symbol2scm ("pop"),
1315                         ly_cadr ($2),
1316                         $3));
1317
1318                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1319         }
1320         | SET context_prop_spec '=' scalar {
1321                 $$ = property_op_to_music (scm_list_3 (
1322                         ly_symbol2scm ("assign"),
1323                         ly_cadr ($2),
1324                         $4));
1325                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1326         }
1327         | UNSET context_prop_spec {
1328                 $$ = property_op_to_music (scm_list_2 (
1329                         ly_symbol2scm ("unset"),
1330                         ly_cadr ($2)));
1331                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1332         }
1333         | ONCE music_property_def {
1334                 SCM e = $2->get_property ("element");
1335                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1336                 $$ = $2;
1337
1338         }
1339         ;
1340
1341
1342 string:
1343         STRING {
1344                 $$ = $1;
1345         }
1346         | STRING_IDENTIFIER {
1347                 $$ = $1;
1348         }
1349         | string '+' string {
1350                 $$ = scm_string_append (scm_list_2 ($1, $3));
1351         }
1352         ;
1353
1354 simple_string: STRING {
1355         }
1356         | LYRICS_STRING {
1357         }
1358         ;
1359
1360 scalar: string {
1361         }
1362         | LYRICS_STRING {
1363         }
1364         | bare_int {
1365                 $$ = scm_int2num ($1);
1366         }
1367         | embedded_scm {
1368         }
1369         | full_markup {
1370         }
1371         | DIGIT {
1372                 $$ = scm_int2num ($1);
1373         }
1374         ;
1375
1376 /*
1377 FIXME: remove or fix this comment.  What is `This'?
1378
1379 This is a trick:
1380
1381 Adding pre_events to the simple_element
1382 makes the choice between
1383
1384   string:  STRING
1385
1386 and
1387
1388   simple_element: STRING
1389
1390 a single shift/reduction conflict.
1391
1392 nevertheless, this is not very clean, and we should find a different
1393 solution.
1394
1395 */
1396 pre_events: {
1397                 THIS->push_spot ();
1398         }
1399         ;
1400
1401 event_chord:
1402         pre_events simple_element post_events   {
1403                 SCM elts = $2-> get_property ("elements");
1404
1405                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1406
1407                 $2->set_property ("elements", elts);
1408                 $$ = $2;
1409         }
1410         | command_element
1411         | note_chord_element
1412         ;
1413
1414
1415 note_chord_element:
1416         chord_body optional_notemode_duration post_events
1417         {
1418                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1419                 SCM es = $1->get_property ("elements");
1420                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1421
1422                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1423                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1424                 es = ly_append2 (es, postevs);
1425
1426                 $1-> set_property ("elements", es);
1427                 $$ = $1;
1428         }
1429         ;
1430
1431 chord_open: '<'
1432         ;
1433
1434 chord_close: '>'
1435         ;
1436
1437 simul_open: DOUBLE_ANGLE_OPEN
1438         ;
1439
1440 simul_close: DOUBLE_ANGLE_CLOSE
1441         ;
1442
1443 chord_body:
1444         chord_open chord_body_elements chord_close
1445         {
1446                 $$ = MY_MAKE_MUSIC ("EventChord");
1447                 $$->set_property ("elements",
1448                         scm_reverse_x ($2, SCM_EOL));
1449         }
1450         ;
1451
1452 chord_body_elements:
1453         /* empty */             { $$ = SCM_EOL; }
1454         | chord_body_elements chord_body_element {
1455                 $$ = scm_cons ($2->self_scm (), $1);
1456                 scm_gc_unprotect_object ($2->self_scm ());
1457         }
1458         ;
1459
1460 chord_body_element:
1461         pitch exclamations questions post_events
1462         {
1463                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1464                 n->set_property ("pitch", $1);
1465                 if ($3 % 2)
1466                         n->set_property ("cautionary", SCM_BOOL_T);
1467                 if ($2 % 2 || $3 % 2)
1468                         n->set_property ("force-accidental", SCM_BOOL_T);
1469
1470                 if (ly_c_pair_p ($4)) {
1471                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1472                         n->set_property ("articulations", arts);
1473                 }
1474                 $$ = n;
1475         }
1476         | DRUM_PITCH post_events {
1477                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1478                 n->set_property ("duration", $2);
1479                 n->set_property ("drum-type", $1);
1480                 n->set_spot (THIS->here_input ());
1481
1482                 if (ly_c_pair_p ($2)) {
1483                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1484                         n->set_property ("articulations", arts);
1485                 }
1486                 $$ = n;
1487         }
1488         ;
1489
1490 add_quote:
1491         ADDQUOTE string Music {
1492                 SCM adder = ly_scheme_function ("add-quotable");
1493
1494                 scm_call_2 (adder, $2, $3->self_scm ());
1495                 scm_gc_unprotect_object ($3->self_scm ());
1496         }
1497         ;
1498
1499 command_element:
1500         command_req {
1501                 $$ = MY_MAKE_MUSIC ("EventChord");
1502                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1503                 scm_gc_unprotect_object ($1->self_scm ());
1504
1505                 $$-> set_spot (THIS->here_input ());
1506                 $1-> set_spot (THIS->here_input ());
1507         }
1508         | SKIP duration_length {
1509                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1510                 skip->set_property ("duration", $2);
1511
1512                 $$ = skip;
1513         }
1514         | QUOTE STRING duration_length {
1515                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1516                 SCM evs = SCM_EOL;
1517                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1518                 {
1519                         SCM key = $2; // use symbol?
1520                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1521                 }
1522                 Music *quote = 0;
1523                 if (ly_c_vector_p (evs))
1524                 {
1525                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1526                         quote->set_property ("duration", $3);
1527                         quote->set_property ("quoted-events", evs);
1528                 } else {
1529                         THIS->here_input ().warning (_f ("Can\'t find music"));
1530                         quote = MY_MAKE_MUSIC ("Event");
1531                 }
1532                 quote->set_spot (THIS->here_input ());
1533                 $$ = quote;
1534         }
1535         | OCTAVE { THIS->push_spot (); }
1536           pitch {
1537                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1538                 $$ = m;
1539                 $$->set_spot (THIS->pop_spot ());
1540                 $$->set_property ("pitch", $3);
1541         }
1542         | E_LEFTSQUARE {
1543                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1544                 m->set_property ("span-direction", scm_int2num (START));
1545                 m->set_spot (THIS->here_input ());
1546
1547                 $$ = MY_MAKE_MUSIC ("EventChord");
1548                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1549                 scm_gc_unprotect_object (m->self_scm ());
1550                 $$->set_spot (THIS->here_input ());
1551         }
1552         | E_RIGHTSQUARE {
1553                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1554                 m->set_property ("span-direction", scm_int2num (STOP));
1555                 m->set_spot (THIS->here_input ());
1556
1557                 $$ = MY_MAKE_MUSIC ("EventChord");
1558                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1559                 $$->set_spot (THIS->here_input ());
1560                 scm_gc_unprotect_object (m->self_scm ());
1561         }
1562         | E_BACKSLASH {
1563                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1564                 $$->set_spot (THIS->here_input ());
1565         }
1566         | '|'      {
1567                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1568
1569                 if (Music * m = unsmob_music (pipe))
1570                         $$ = m->clone ();
1571                 else
1572                         $$ = MY_MAKE_MUSIC ("BarCheck");
1573
1574                 $$->set_spot (THIS->here_input ());
1575         }
1576         | TRANSPOSITION pitch {
1577                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1578                                         $2);
1579                 $$->set_spot (THIS-> here_input ());
1580                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1581                         $$, SCM_EOL);
1582         }
1583         | BAR STRING                    {
1584                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1585
1586                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1587                                         t, SCM_EOL);
1588                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1589                 $$->set_spot (THIS->here_input ());
1590                 t->set_spot (THIS->here_input ());
1591         }
1592         | PARTIAL duration_length       {
1593                 Moment m = - unsmob_duration ($2)->get_length ();
1594                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1595                 p->set_spot (THIS->here_input ());
1596                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1597                                         p, SCM_EOL);
1598                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1599                                         p, SCM_EOL);
1600                 $$ = p;
1601         }
1602         | CLEF STRING  {
1603                 SCM proc = ly_scheme_function ("make-clef-set");
1604
1605                 SCM result = scm_call_1 (proc, $2);
1606                 scm_gc_protect_object (result);
1607                 $$ = unsmob_music (result);
1608         }
1609         | TIME_T fraction  {
1610                 SCM proc= ly_scheme_function ("make-time-signature-set");
1611
1612                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1613                 scm_gc_protect_object (result);
1614                 $$ = unsmob_music (result);
1615         }
1616         | MARK scalar {
1617                 SCM proc = ly_scheme_function ("make-mark-set");
1618
1619                 SCM result = scm_call_1 (proc, $2);
1620                 scm_gc_protect_object (result);
1621                 $$ = unsmob_music (result);
1622         }
1623         ;
1624
1625 command_req:
1626         E_TILDE {
1627                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1628         }
1629         | MARK DEFAULT  {
1630                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1631                 $$ = m;
1632         }
1633         | tempo_event {
1634                 $$ = $1;
1635         }
1636         | KEY DEFAULT {
1637                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1638                 $$ = key;
1639         }
1640         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1641
1642                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1643                 if (scm_ilength ($3) > 0)
1644                 {
1645                         key->set_property ("pitch-alist", $3);
1646                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1647                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1648                 } else {
1649                         THIS->parser_error (_ ("Second argument must be pitch list."));
1650                 }
1651
1652                 $$ = key;
1653         }
1654         ;
1655
1656 post_events:
1657         /* empty */ {
1658                 $$ = SCM_EOL;
1659         }
1660         | post_events post_event {
1661                 $2->set_spot (THIS->here_input ());
1662                 $$ = scm_cons ($2->self_scm (), $$);
1663                 scm_gc_unprotect_object ($2->self_scm ());
1664         }
1665         | post_events tagged_post_event {
1666                 $2 -> set_spot (THIS->here_input ());
1667                 $$ = scm_cons ($2->self_scm (), $$);
1668                 scm_gc_unprotect_object ($2->self_scm ());
1669         }
1670         ;
1671
1672
1673 tagged_post_event:
1674         '-' TAG embedded_scm post_event {
1675                 tag_music ($4, $3, THIS->here_input ());
1676                 $$ = $4;
1677         }
1678         ;
1679
1680 post_event:
1681         direction_less_event {
1682                 $$ = $1;
1683         }
1684         | HYPHEN {
1685                 if (!THIS->lexer_->is_lyric_state ())
1686                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1687                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1688         }
1689         | EXTENDER {
1690                 if (!THIS->lexer_->is_lyric_state ())
1691                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1692                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1693         }
1694         | script_dir direction_reqd_event {
1695                 if ($1)
1696                         $2->set_property ("direction", scm_int2num ($1));
1697                 $$ = $2;
1698         }
1699         | script_dir direction_less_event {
1700                 if ($1)
1701                         $2->set_property ("direction", scm_int2num ($1));
1702                 $$ = $2;
1703         }
1704         | string_number_event
1705         ;
1706
1707 string_number_event:
1708         E_UNSIGNED {
1709                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1710                 s->set_property ("string-number", scm_int2num ($1));
1711                 s->set_spot (THIS->here_input ());
1712                 $$ = s;
1713         }
1714         ;
1715
1716
1717 direction_less_event:
1718         '['  {
1719
1720
1721 /*
1722
1723 TODO: should take all these defs out of the parser, adn make use
1724 configurable, i.e.
1725
1726
1727 (set-articulation '~ "trill")
1728
1729 */
1730                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1731                 m->set_spot (THIS->here_input ());
1732                 m->set_property ("span-direction", scm_int2num (START));
1733                 $$ = m;
1734         }
1735         | ']'  {
1736                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1737                 m->set_spot (THIS->here_input ());
1738                 m->set_property ("span-direction", scm_int2num (STOP));
1739                 $$ = m;
1740         }
1741         | '~' {
1742                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1743                 m->set_spot (THIS->here_input ());
1744                 $$ = m;
1745         }
1746         | close_event {
1747                 $$ = $1;
1748                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1749                         scm_int2num (START));
1750         }
1751         | open_event {
1752                 $$ = $1;
1753                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1754                         scm_int2num (STOP));
1755         }
1756         | EVENT_IDENTIFIER      {
1757                 $$ = unsmob_music ($1);
1758         }
1759         | tremolo_type  {
1760                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1761                a->set_spot (THIS->here_input ());
1762                a->set_property ("tremolo-type", scm_int2num ($1));
1763                $$ = a;
1764         }
1765         ;
1766
1767 direction_reqd_event:
1768         gen_text_def {
1769                 $$ = $1;
1770         }
1771         | script_abbreviation {
1772                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1773                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1774                 if (ly_c_string_p (s))
1775                         a->set_property ("articulation-type", s);
1776                 else THIS->parser_error (_ ("Expecting string as script definition"));
1777                 $$ = a;
1778         }
1779         ;
1780
1781 oct_check:
1782         /**/ { $$ = SCM_EOL; }
1783         | '='  { $$ = scm_int2num (0); }
1784         | '=' sub_quotes { $$ = scm_int2num ($2); }
1785         | '=' sup_quotes { $$ = scm_int2num ($2); }
1786         ;
1787
1788 sup_quotes:
1789         '\'' {
1790                 $$ = 1;
1791         }
1792         | sup_quotes '\'' {
1793                 $$ ++;
1794         }
1795         ;
1796
1797 sub_quotes:
1798         ',' {
1799                 $$ = 1;
1800         }
1801         | sub_quotes ',' {
1802                 $$++;
1803         }
1804         ;
1805
1806 steno_pitch:
1807         NOTENAME_PITCH  {
1808                 $$ = $1;
1809         }
1810         | NOTENAME_PITCH sup_quotes     {
1811                 Pitch p = *unsmob_pitch ($1);
1812                 p = p.transposed (Pitch ($2,0,0));
1813                 $$ = p.smobbed_copy ();
1814         }
1815         | NOTENAME_PITCH sub_quotes      {
1816                 Pitch p =* unsmob_pitch ($1);
1817                 p = p.transposed (Pitch (-$2,0,0));
1818                 $$ = p.smobbed_copy ();
1819         }
1820         ;
1821
1822 /*
1823 ugh. duplication
1824 */
1825
1826 steno_tonic_pitch:
1827         TONICNAME_PITCH {
1828                 $$ = $1;
1829         }
1830         | TONICNAME_PITCH sup_quotes    {
1831                 Pitch p = *unsmob_pitch ($1);
1832                 p = p.transposed (Pitch ($2,0,0));
1833                 $$ = p.smobbed_copy ();
1834         }
1835         | TONICNAME_PITCH sub_quotes     {
1836                 Pitch p =* unsmob_pitch ($1);
1837
1838                 p = p.transposed (Pitch (-$2,0,0));
1839                 $$ = p.smobbed_copy ();
1840         }
1841         ;
1842
1843 pitch:
1844         steno_pitch {
1845                 $$ = $1;
1846         }
1847         ;
1848
1849 pitch_also_in_chords:
1850         pitch
1851         | steno_tonic_pitch
1852         ;
1853
1854 close_event:
1855         '('     {
1856                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1857                 $$ = s;
1858                 s->set_spot (THIS->here_input ());
1859         }
1860         | E_OPEN        {
1861                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1862                 $$ = s;
1863                 s->set_spot (THIS->here_input ());
1864         }
1865         | E_SMALLER {
1866                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1867                 $$ = s;
1868                 s->set_spot (THIS->here_input ());
1869         }
1870         | E_BIGGER {
1871                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1872                 $$ = s;
1873                 s->set_spot (THIS->here_input ());
1874         }
1875         ;
1876
1877
1878 open_event:
1879         E_EXCLAMATION   {
1880                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1881                 s->set_spot (THIS->here_input ());
1882
1883                 $$ = s;
1884         }
1885         | ')'   {
1886                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1887                 $$ = s;
1888                 s->set_spot (THIS->here_input ());
1889
1890         }
1891         | E_CLOSE       {
1892                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1893                 $$ = s;
1894                 s->set_property ("span-type",
1895                         scm_makfrom0str ("phrasing-slur"));
1896                 s->set_spot (THIS->here_input ());
1897         }
1898         ;
1899
1900 gen_text_def:
1901         full_markup {
1902                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1903                 t->set_property ("text", $1);
1904                 t->set_spot (THIS->here_input ());
1905                 $$ = t;
1906         }
1907         | string {
1908                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1909                 t->set_property ("text",
1910                         make_simple_markup (THIS->lexer_->encoding (), $1));
1911                 t->set_spot (THIS->here_input ());
1912                 $$ = t;
1913
1914         }
1915         | DIGIT {
1916                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1917                 t->set_property ("digit", scm_int2num ($1));
1918                 t->set_spot (THIS->here_input ());
1919                 $$ = t;
1920         }
1921         ;
1922
1923 script_abbreviation:
1924         '^'             {
1925                 $$ = scm_makfrom0str ("Hat");
1926         }
1927         | '+'           {
1928                 $$ = scm_makfrom0str ("Plus");
1929         }
1930         | '-'           {
1931                 $$ = scm_makfrom0str ("Dash");
1932         }
1933         | '|'           {
1934                 $$ = scm_makfrom0str ("Bar");
1935         }
1936         | '>'           {
1937                 $$ = scm_makfrom0str ("Larger");
1938         }
1939         | '.'           {
1940                 $$ = scm_makfrom0str ("Dot");
1941         }
1942         | '_' {
1943                 $$ = scm_makfrom0str ("Underscore");
1944         }
1945         ;
1946
1947 script_dir:
1948         '_'     { $$ = DOWN; }
1949         | '^'   { $$ = UP; }
1950         | '-'   { $$ = CENTER; }
1951         ;
1952
1953
1954 absolute_pitch:
1955         steno_pitch     {
1956                 $$ = $1;
1957         }
1958         ;
1959
1960 duration_length:
1961         multiplied_duration {
1962                 $$ = $1;
1963         }
1964         ;
1965
1966 optional_notemode_duration:
1967         {
1968                 Duration dd = THIS->default_duration_;
1969                 $$ = dd.smobbed_copy ();
1970
1971                 THIS->beam_check ($$);
1972         }
1973         | multiplied_duration   {
1974                 $$ = $1;
1975                 THIS->default_duration_ = *unsmob_duration ($$);
1976
1977                 THIS->beam_check ($$);
1978         }
1979         ;
1980
1981 steno_duration:
1982         bare_unsigned dots              {
1983                 int len = 0;
1984                 if (!is_duration ($1))
1985                         THIS->parser_error (_f ("not a duration: %d", $1));
1986                 else
1987                         len = intlog2 ($1);
1988
1989                 $$ = Duration (len, $2).smobbed_copy ();
1990         }
1991         | DURATION_IDENTIFIER dots      {
1992                 Duration *d = unsmob_duration ($1);
1993                 Duration k (d->duration_log (), d->dot_count () + $2);
1994                 *d = k;
1995                 $$ = $1;
1996         }
1997         ;
1998
1999 multiplied_duration:
2000         steno_duration {
2001                 $$ = $1;
2002         }
2003         | multiplied_duration '*' bare_unsigned {
2004                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2005         }
2006         | multiplied_duration '*' FRACTION {
2007                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2008
2009                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2010         }
2011         ;
2012
2013 fraction:
2014         FRACTION { $$ = $1; }
2015         | UNSIGNED '/' UNSIGNED {
2016                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2017         }
2018         ;
2019
2020 dots:
2021         /* empty */     {
2022                 $$ = 0;
2023         }
2024         | dots '.' {
2025                 $$ ++;
2026         }
2027         ;
2028
2029 tremolo_type:
2030         ':'     {
2031                 $$ = 0;
2032         }
2033         | ':' bare_unsigned {
2034                 if (!is_duration ($2))
2035                         THIS->parser_error (_f ("not a duration: %d", $2));
2036                 $$ = $2;
2037         }
2038         ;
2039
2040 bass_number:
2041         DIGIT   {
2042                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2043                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2044                                 $$);
2045         }
2046         | UNSIGNED {
2047                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2048                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2049                                 $$);
2050         }
2051         | STRING { $$ = $1; }
2052         ;
2053
2054 bass_mod:
2055         '-'     { $$ = -2; }
2056         | '+'   { $$ = 2; }
2057         | '!'   { $$ = 0; }
2058         ;
2059
2060 bass_figure:
2061         FIGURE_SPACE {
2062                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2063                 $$ = bfr->self_scm ();
2064                 scm_gc_unprotect_object ($$);
2065         }
2066         | bass_number  {
2067                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2068                 $$ = bfr->self_scm ();
2069
2070                 bfr->set_property ("figure", $1);
2071
2072                 scm_gc_unprotect_object ($$);
2073         }
2074         | bass_figure bass_mod {
2075                 Music *m = unsmob_music ($1);
2076                 if ($2) {
2077                         SCM salter = m->get_property ("alteration");
2078                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2079                         m->set_property ("alteration",
2080                                 scm_int2num (alter + $2));
2081                 } else {
2082                         m->set_property ("alteration", scm_int2num (0));
2083                 }
2084         }
2085         ;
2086
2087 br_bass_figure:
2088         '[' bass_figure {
2089                 $$ = $2;
2090                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2091         }
2092         | bass_figure   {
2093                 $$ = $1;
2094         }
2095         | br_bass_figure ']' {
2096                 $$ = $1;
2097                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2098         }
2099         ;
2100
2101 figure_list:
2102         /**/            {
2103                 $$ = SCM_EOL;
2104         }
2105         | figure_list br_bass_figure {
2106                 $$ = scm_cons ($2, $1);
2107         }
2108         ;
2109
2110 figure_spec:
2111         FIGURE_OPEN figure_list FIGURE_CLOSE {
2112                 Music *m = MY_MAKE_MUSIC ("EventChord");
2113                 $2 = scm_reverse_x ($2, SCM_EOL);
2114                 m->set_property ("elements", $2);
2115                 $$ = m->self_scm ();
2116         }
2117         ;
2118
2119
2120 optional_rest:
2121         /**/   { $$ = 0; }
2122         | REST { $$ = 1; }
2123         ;
2124
2125 simple_element:
2126         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2127
2128                 Input i = THIS->pop_spot ();
2129                 if (!THIS->lexer_->is_note_state ())
2130                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2131
2132                 Music *n = 0;
2133                 if ($6)
2134                         n = MY_MAKE_MUSIC ("RestEvent");
2135                 else
2136                         n = MY_MAKE_MUSIC ("NoteEvent");
2137
2138                 n->set_property ("pitch", $1);
2139                 n->set_property ("duration", $5);
2140
2141                 if (ly_c_number_p ($4))
2142                 {
2143                         int q = ly_scm2int ($4);
2144                         n->set_property ("absolute-octave", scm_int2num (q-1));
2145                 }
2146
2147                 if ($3 % 2)
2148                         n->set_property ("cautionary", SCM_BOOL_T);
2149                 if ($2 % 2 || $3 % 2)
2150                         n->set_property ("force-accidental", SCM_BOOL_T);
2151
2152                 Music *v = MY_MAKE_MUSIC ("EventChord");
2153                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2154                 scm_gc_unprotect_object (n->self_scm ());
2155
2156                 v->set_spot (i);
2157                 n->set_spot (i);
2158                 $$ = v;
2159         }
2160         | DRUM_PITCH optional_notemode_duration {
2161                 Input i = THIS->pop_spot ();
2162
2163                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2164                 n->set_property ("duration", $2);
2165                 n->set_property ("drum-type", $1);
2166
2167                 Music *v = MY_MAKE_MUSIC ("EventChord");
2168                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2169                 scm_gc_unprotect_object (n->self_scm ());
2170                 v->set_spot (i);
2171                 n->set_spot (i);
2172                 $$ = v;
2173
2174         }
2175         | figure_spec optional_notemode_duration {
2176                 Music *m = unsmob_music ($1);
2177                 Input i = THIS->pop_spot ();
2178                 m->set_spot (i);
2179                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2180                 {
2181                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2182                 }
2183                 $$ = m;
2184         }
2185         | RESTNAME optional_notemode_duration           {
2186
2187                 Input i = THIS->pop_spot ();
2188                 Music *ev = 0;
2189                 if (ly_scm2string ($1) == "s") {
2190                         /* Space */
2191                         ev = MY_MAKE_MUSIC ("SkipEvent");
2192                   }
2193                 else {
2194                         ev = MY_MAKE_MUSIC ("RestEvent");
2195
2196                     }
2197                 ev->set_property ("duration", $2);
2198                 ev->set_spot (i);
2199                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2200                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2201                 velt->set_spot (i);
2202
2203                 scm_gc_unprotect_object (ev->self_scm ());
2204
2205                 $$ = velt;
2206         }
2207         | MULTI_MEASURE_REST optional_notemode_duration         {
2208                 THIS->pop_spot ();
2209
2210                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2211                 SCM mus = scm_call_2 (proc, $2,
2212                         make_input (THIS->here_input ()));
2213                 scm_gc_protect_object (mus);
2214                 $$ = unsmob_music (mus);
2215         }
2216
2217         | lyric_element optional_notemode_duration      {
2218                 Input i = THIS->pop_spot ();
2219                 if (!THIS->lexer_->is_lyric_state ())
2220                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2221
2222                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2223                 lreq->set_property ("text", $1);
2224                 lreq->set_property ("duration",$2);
2225                 lreq->set_spot (i);
2226                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2227                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2228
2229                 $$= velt;
2230         }
2231         | new_chord {
2232                 THIS->pop_spot ();
2233
2234                 if (!THIS->lexer_->is_chord_state ())
2235                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2236                 $$ = unsmob_music ($1);
2237         }
2238         ;
2239
2240 lyric_element:
2241         /* FIXME: lyric flavoured markup would be better */
2242         full_markup {
2243         }
2244         | LYRICS_STRING {
2245         }
2246         ;
2247
2248 new_chord:
2249         steno_tonic_pitch optional_notemode_duration   {
2250                 $$ = make_chord ($1, $2, SCM_EOL);
2251         }
2252         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2253                 SCM its = scm_reverse_x ($4, SCM_EOL);
2254                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2255         }
2256         ;
2257
2258 chord_items:
2259         /**/ {
2260                 $$ = SCM_EOL;
2261         }
2262         | chord_items chord_item {
2263                 $$ = scm_cons ($2, $$);
2264         }
2265         ;
2266
2267 chord_separator:
2268         CHORD_COLON {
2269                 $$ = ly_symbol2scm ("chord-colon");
2270         }
2271         | CHORD_CARET {
2272                 $$ = ly_symbol2scm ("chord-caret");
2273         }
2274         | CHORD_SLASH steno_tonic_pitch {
2275                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2276         }
2277         | CHORD_BASS steno_tonic_pitch {
2278                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2279         }
2280         ;
2281
2282 chord_item:
2283         chord_separator {
2284                 $$ = $1;
2285         }
2286         | step_numbers {
2287                 $$ = scm_reverse_x ($1, SCM_EOL);
2288         }
2289         | CHORD_MODIFIER  {
2290                 $$ = $1;
2291         }
2292         ;
2293
2294 step_numbers:
2295         step_number { $$ = scm_cons ($1, SCM_EOL); }
2296         | step_numbers '.' step_number {
2297                 $$ = scm_cons ($3, $$);
2298         }
2299         ;
2300
2301 step_number:
2302         bare_unsigned {
2303                 $$ = make_chord_step ($1, 0);
2304         }
2305         | bare_unsigned '+' {
2306                 $$ = make_chord_step ($1, SHARP);
2307         }
2308         | bare_unsigned CHORD_MINUS {
2309                 $$ = make_chord_step ($1, FLAT);
2310         }
2311         ;
2312
2313 /*
2314         UTILITIES
2315
2316 TODO: should deprecate in favor of Scheme?
2317
2318  */
2319 number_expression:
2320         number_expression '+' number_term {
2321                 $$ = scm_sum ($1, $3);
2322         }
2323         | number_expression '-' number_term {
2324                 $$ = scm_difference ($1, $3);
2325         }
2326         | number_term
2327         ;
2328
2329 number_term:
2330         number_factor {
2331                 $$ = $1;
2332         }
2333         | number_factor '*' number_factor {
2334                 $$ = scm_product ($1, $3);
2335         }
2336         | number_factor '/' number_factor {
2337                 $$ = scm_divide ($1, $3);
2338         }
2339         ;
2340
2341 number_factor:
2342         '-'  number_factor { /* %prec UNARY_MINUS */
2343                 $$ = scm_difference ($2, SCM_UNDEFINED);
2344         }
2345         | bare_number
2346         ;
2347
2348
2349 bare_number:
2350         UNSIGNED        {
2351                 $$ = scm_int2num ($1);
2352         }
2353         | REAL          {
2354                 $$ = $1;
2355         }
2356         | NUMBER_IDENTIFIER             {
2357                 $$ = $1;
2358         }
2359         | REAL NUMBER_IDENTIFIER        {
2360                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2361         }
2362         | UNSIGNED NUMBER_IDENTIFIER    {
2363                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2364         }
2365         ;
2366
2367
2368 bare_unsigned:
2369         UNSIGNED {
2370                         $$ = $1;
2371         }
2372         | DIGIT {
2373                 $$ = $1;
2374         }
2375         ;
2376
2377 bare_int:
2378         bare_number {
2379                 if (scm_integer_p ($1) == SCM_BOOL_T)
2380                 {
2381                         int k = ly_scm2int ($1);
2382                         $$ = k;
2383                 } else
2384                 {
2385                         THIS->parser_error (_ ("need integer number arg"));
2386                         $$ = 0;
2387                 }
2388         }
2389         | '-' bare_int {
2390                 $$ = -$2;
2391         }
2392         ;
2393
2394 exclamations:
2395                 { $$ = 0; }
2396         | exclamations '!'      { $$ ++; }
2397         ;
2398
2399 questions:
2400                 { $$ = 0; }
2401         | questions '?' { $$ ++; }
2402         ;
2403
2404
2405
2406 full_markup:
2407         MARKUP_IDENTIFIER {
2408                 $$ = $1;
2409         }
2410         | MARKUP
2411                 { THIS->lexer_->push_markup_state (); }
2412         markup
2413                 { $$ = $3;
2414                   THIS->lexer_->pop_state ();
2415                 }
2416         ;
2417
2418
2419 /*
2420 This should be done more dynamically if possible.
2421 */
2422 markup:
2423         STRING {
2424                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2425         }
2426         | MARKUP_HEAD_EMPTY {
2427                 $$ = scm_list_1 ($1);
2428         }
2429         | MARKUP_HEAD_MARKUP0 markup {
2430                 $$ = scm_list_2 ($1, $2);
2431         }
2432         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2433                 $$ = scm_list_3 ($1, $2, $3);
2434         }
2435         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2436                 $$ = scm_list_3 ($1, $2, $3);
2437         }
2438         | markup_line {
2439                 $$ = $1;
2440         }
2441         | MARKUP_HEAD_LIST0 markup_list {
2442                 $$ = scm_list_2 ($1,$2);
2443         }
2444         | MARKUP_HEAD_SCM0 embedded_scm {
2445                 $$ = scm_list_2 ($1, $2);
2446         }
2447         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2448                 $$ = scm_list_4 ($1, $2, $3, $4);
2449         }
2450         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2451                 $$ = scm_list_4 ($1, $2, $3, $4);
2452         }
2453         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2454                 $$ = scm_list_3 ($1, $2, $3);
2455         }
2456         | MARKUP_IDENTIFIER {
2457                 $$ = $1;
2458         }
2459         | STRING_IDENTIFIER {
2460                 $$ = $1;
2461         }
2462         | {
2463                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2464                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2465         }
2466         /* cont */ score_block {
2467                 /* WIP this is a bit arbitrary,
2468                    we should also allow \book or Composite_music.
2469                    However, you'd typically want to change paper
2470                    settings, and need a \score block anyway.  */
2471
2472                 THIS->lexer_->pop_state ();
2473                 Score *score = $2;
2474                 Book *book = new Book;
2475                 book->scores_.push (score);
2476
2477                 Output_def *paper = get_paper (THIS);
2478                 book->bookpaper_ = get_bookpaper (THIS);
2479
2480                 SCM s = book->to_stencil (paper, THIS->header_);
2481                 scm_gc_unprotect_object (score->self_scm ());
2482                 scm_gc_unprotect_object (book->self_scm ());
2483                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2484         }
2485         ;
2486
2487 markup_list:
2488         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2489         ;
2490
2491 markup_line:
2492         '{' markup_list_body '}' {
2493                 SCM line = ly_scheme_function ("line-markup");
2494
2495                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2496         }
2497         ;
2498
2499 markup_list_body:
2500         /**/ {  $$ = SCM_EOL; }
2501         | markup_list_body markup {
2502                 $$ = scm_cons ($2, $1);
2503         }
2504         ;
2505
2506
2507 %%
2508
2509 void
2510 My_lily_parser::set_yydebug (bool )
2511 {
2512 #if 0
2513         yydebug = 1;
2514 #endif
2515 }
2516
2517 void
2518 My_lily_parser::do_yyparse ()
2519 {
2520         yyparse ((void*)this);
2521 }
2522
2523
2524 /*
2525 Should make this optional?    It will also complain when you do
2526
2527         [s4]
2528
2529 which is entirely legitimate.
2530
2531 Or we can scrap it. Barchecks should detect wrong durations, and
2532 skipTypesetting speeds it up a lot.
2533 */
2534
2535 void
2536 My_lily_parser::beam_check (SCM dur)
2537 {
2538   Duration *d = unsmob_duration (dur);
2539   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2540     {
2541       Music *m = unsmob_music (last_beam_start_);
2542       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2543     }
2544   last_beam_start_ = SCM_EOL;
2545 }
2546
2547
2548
2549
2550 /*
2551
2552 It is a little strange to have this function in this file, but
2553 otherwise, we have to import music classes into the lexer.
2554
2555 */
2556 int
2557 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2558 {
2559         if (ly_c_string_p (sid)) {
2560                 *destination = sid;
2561                 return STRING_IDENTIFIER;
2562         } else if (ly_c_number_p (sid)) {
2563                 *destination = sid;
2564                 return NUMBER_IDENTIFIER;
2565         } else if (unsmob_context_def (sid)) {
2566                 *destination = unsmob_context_def (sid)->clone_scm ();
2567                 return CONTEXT_DEF_IDENTIFIER;
2568         } else if (unsmob_score (sid)) {
2569                 Score *score = new Score (*unsmob_score (sid));
2570                 *destination = score->self_scm ();
2571                 return SCORE_IDENTIFIER;
2572         } else if (Music *mus = unsmob_music (sid)) {
2573                 mus = mus->clone ();
2574                 *destination = mus->self_scm ();
2575                 unsmob_music (*destination)->
2576                         set_property ("origin", make_input (last_input_));
2577                 return dynamic_cast<Event*> (mus)
2578                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2579         } else if (unsmob_duration (sid)) {
2580                 *destination = unsmob_duration (sid)->smobbed_copy ();
2581                 return DURATION_IDENTIFIER;
2582         } else if (unsmob_output_def (sid)) {
2583                 Output_def *p = unsmob_output_def (sid);
2584                 p = p->clone ();
2585
2586                 *destination = p->self_scm ();
2587                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2588         } else if (Text_item::markup_p (sid)) {
2589                 *destination = sid;
2590                 return MARKUP_IDENTIFIER;
2591         }
2592
2593         return -1;
2594 }
2595
2596 Music *
2597 property_op_to_music (SCM op)
2598 {
2599         Music *m = 0;
2600         SCM tag = ly_car (op);
2601         SCM symbol = ly_cadr (op);
2602         SCM args = ly_cddr (op);
2603         SCM grob_val = SCM_UNDEFINED;
2604         SCM grob_sym = SCM_UNDEFINED;
2605         SCM val = SCM_UNDEFINED;
2606
2607         if (tag == ly_symbol2scm ("assign"))
2608                 {
2609                 m = MY_MAKE_MUSIC ("PropertySet");
2610                 val = ly_car (args);
2611                 }
2612         else if (tag == ly_symbol2scm ("unset"))
2613                 m = MY_MAKE_MUSIC ("PropertyUnset");
2614         else if (tag == ly_symbol2scm ("poppush")
2615                  || tag == ly_symbol2scm ("push"))
2616                 {
2617                 m = MY_MAKE_MUSIC ("OverrideProperty");
2618                 grob_sym = ly_car (args);
2619                 grob_val = ly_cadr (args);
2620                 }
2621         else if (tag == ly_symbol2scm ("pop")) {
2622                 m = MY_MAKE_MUSIC ("RevertProperty");
2623                 grob_sym = ly_car (args);
2624                 }
2625
2626         m->set_property ("symbol", symbol);
2627
2628         if (val != SCM_UNDEFINED)
2629                 m->set_property ("value", val);
2630         if (grob_val != SCM_UNDEFINED)
2631                 m->set_property ("grob-value", grob_val);
2632
2633         if (grob_sym != SCM_UNDEFINED)
2634                 {
2635                 bool itc = internal_type_checking_global_b;
2636                 /* UGH.
2637                 */
2638                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2639                 if (autobeam)
2640                         internal_type_checking_global_b = false;
2641                 m->set_property ("grob-property", grob_sym);
2642                 if (autobeam)
2643                         internal_type_checking_global_b = itc;
2644                 }
2645
2646         if (tag == ly_symbol2scm ("poppush"))
2647                 m->set_property ("pop-first", SCM_BOOL_T);
2648
2649
2650         return m;
2651 }
2652
2653 Music*
2654 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2655 {
2656         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2657
2658         csm->set_property ("element", m->self_scm ());
2659         scm_gc_unprotect_object (m->self_scm ());
2660
2661         csm->set_property ("context-type",
2662                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2663         csm->set_property ("property-operations", ops);
2664
2665         if (ly_c_string_p (id))
2666                 csm->set_property ("context-id", id);
2667         return csm;
2668 }
2669
2670 SCM
2671 get_next_unique_context ()
2672 {
2673         static int new_context_count;
2674         char s[1024];
2675         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2676         return scm_makfrom0str (s);
2677 }
2678