lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_TOP
  44 %left ADDLYRICS
  45 %left PREC_BOT
  46
  47 %expect 1
  48
  49 /* One shift/reduce problem
  50
  51 1.  \repeat
  52         \repeat .. \alternative
  53
  54     \repeat { \repeat .. \alternative }
  55
  56 or
  57
  58     \repeat { \repeat } \alternative
  59 */
  60
  61
  62 %pure_parser
  63 %locations
  64
  65
  66
  67 %{ // -*-Fundamental-*-
  68
  69 /*
  70 FIXME:
  71
  72    * The rules for who is protecting what are very shady.  Uniformise
  73      this.
  74
  75    * There are too many lexical modes?
  76 */
  77
  78 #include "config.hh"
  79
  80 #include <cctype>
  81 #include <cstdlib>
  82 #include <cstdio>
  83 using namespace std;
  84
  85 #include "book.hh"
  86 #include "context-def.hh"
  87 #include "context-mod.hh"
  88 #include "dimensions.hh"
  89 #include "file-path.hh"
  90 #include "input.hh"
  91 #include "international.hh"
  92 #include "lily-guile.hh"
  93 #include "lily-lexer.hh"
  94 #include "lily-parser.hh"
  95 #include "main.hh"
  96 #include "misc.hh"
  97 #include "music.hh"
  98 #include "music.hh"
  99 #include "output-def.hh"
 100 #include "paper-book.hh"
 101 #include "program-option.hh"
 102 #include "scm-hash.hh"
 103 #include "score.hh"
 104 #include "text-interface.hh"
 105 #include "warn.hh"
 106
 107 %}
 108
 109
 110 %union {
 111         Book *book;
 112         Output_def *outputdef;
 113         SCM scm;
 114         std::string *string;
 115         Music *music;
 116         Score *score;
 117         int i;
 118 }
 119
 120 %{
 121
 122 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 123
 124 /* ES TODO:
 125 - Don't use lily module, create a new module instead.
 126 - delay application of the function
 127 */
 128 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 129   scm_apply_0 (proc, args)
 130 /* Syntactic Sugar. */
 131 #define MAKE_SYNTAX(name, location, ...)        \
 132   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 133
 134 SCM get_next_unique_context_id ();
 135 SCM get_next_unique_lyrics_context_id ();
 136
 137 #undef _
 138 #if !HAVE_GETTEXT
 139 #define _(x) x
 140 #else
 141 #include <libintl.h>
 142 #define _(x) gettext (x)
 143 #endif
 144
 145
 146 static Music *make_music_with_input (SCM name, Input where);
 147 SCM make_music_relative (Pitch start, SCM music, Input loc);
 148 SCM run_music_function (Lily_parser *parser, Input loc, SCM func, SCM args);
 149 SCM get_first_context_id (SCM type, Music *m);
 150 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 151 SCM make_chord_step (int step, Rational alter);
 152 SCM make_simple_markup (SCM a);
 153 bool is_duration (int t);
 154 bool is_regular_identifier (SCM id);
 155 bool ly_input_procedure_p (SCM x);
 156 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 157 void set_music_properties (Music *p, SCM a);
 158
 159 %}
 160
 161 /* The third option is an alias that will be used to display the
 162    syntax error.  Bison CVS now correctly handles backslash escapes.
 163
 164    FIXME: Bison needs to translate some of these, eg, STRING.
 165
 166 */
 167
 168 /* Keyword tokens with plain escaped name.  */
 169 %token ACCEPTS "\\accepts"
 170 %token ADDLYRICS "\\addlyrics"
 171 %token ALIAS "\\alias"
 172 %token ALTERNATIVE "\\alternative"
 173 %token BOOK "\\book"
 174 %token BOOKPART "\\bookpart"
 175 %token CHANGE "\\change"
 176 %token CHORDMODE "\\chordmode"
 177 %token CHORDS "\\chords"
 178 %token CONSISTS "\\consists"
 179 %token CONTEXT "\\context"
 180 %token DEFAULT "\\default"
 181 %token DEFAULTCHILD "\\defaultchild"
 182 %token DENIES "\\denies"
 183 %token DESCRIPTION "\\description"
 184 %token DRUMMODE "\\drummode"
 185 %token DRUMS "\\drums"
 186 %token FIGUREMODE "\\figuremode"
 187 %token FIGURES "\\figures"
 188 %token GROBDESCRIPTIONS "\\grobdescriptions"
 189 %token HEADER "\\header"
 190 %token INVALID "\\version-error"
 191 %token KEY "\\key"
 192 %token LAYOUT "\\layout"
 193 %token LYRICMODE "\\lyricmode"
 194 %token LYRICS "\\lyrics"
 195 %token LYRICSTO "\\lyricsto"
 196 %token MARK "\\mark"
 197 %token MARKUP "\\markup"
 198 %token MARKUPLINES "\\markuplines"
 199 %token MIDI "\\midi"
 200 %token NAME "\\name"
 201 %token NOTEMODE "\\notemode"
 202 %token ONCE "\\once"
 203 %token OVERRIDE "\\override"
 204 %token PAPER "\\paper"
 205 %token PARTIAL "\\partial"
 206 %token RELATIVE "\\relative"
 207 %token REMOVE "\\remove"
 208 %token REPEAT "\\repeat"
 209 %token REST "\\rest"
 210 %token REVERT "\\revert"
 211 %token SCORE "\\score"
 212 %token SEQUENTIAL "\\sequential"
 213 %token SET "\\set"
 214 %token SIMULTANEOUS "\\simultaneous"
 215 %token SKIP "\\skip"
 216 %token TEMPO "\\tempo"
 217 %token TIMES "\\times"
 218 %token TYPE "\\type"
 219 %token UNSET "\\unset"
 220 %token WITH "\\with"
 221
 222 /* Keyword token exceptions.  */
 223 %token TIME_T "\\time"
 224 %token NEWCONTEXT "\\new"
 225
 226
 227 /* Other string tokens.  */
 228
 229 %token CHORD_BASS "/+"
 230 %token CHORD_CARET "^"
 231 %token CHORD_COLON ":"
 232 %token CHORD_MINUS "-"
 233 %token CHORD_SLASH "/"
 234 %token ANGLE_OPEN "<"
 235 %token ANGLE_CLOSE ">"
 236 %token DOUBLE_ANGLE_OPEN "<<"
 237 %token DOUBLE_ANGLE_CLOSE ">>"
 238 %token E_BACKSLASH "\\"
 239 %token E_ANGLE_CLOSE "\\>"
 240 %token E_CHAR "\\C[haracter]"
 241 %token E_CLOSE "\\)"
 242 %token E_EXCLAMATION "\\!"
 243 %token E_BRACKET_OPEN "\\["
 244 %token E_OPEN "\\("
 245 %token E_BRACKET_CLOSE "\\]"
 246 %token E_ANGLE_OPEN "\\<"
 247 %token E_PLUS "\\+"
 248 %token E_TILDE "\\~"
 249 %token EXTENDER "__"
 250
 251 /*
 252 If we give names, Bison complains.
 253 */
 254 %token FIGURE_CLOSE /* "\\>" */
 255 %token FIGURE_OPEN /* "\\<" */
 256 %token FIGURE_SPACE "_"
 257 %token HYPHEN "--"
 258
 259 %token CHORDMODIFIERS
 260 %token LYRIC_MARKUP
 261 %token MULTI_MEASURE_REST
 262
 263
 264 %token <i> E_UNSIGNED
 265 %token <i> UNSIGNED
 266
 267 /* Artificial tokens, for more generic function syntax */
 268 %token <i> EXPECT_MARKUP "markup?"
 269 %token <i> EXPECT_MUSIC "ly:music?"
 270 %token <i> EXPECT_PITCH "ly:pitch?"
 271 %token <i> EXPECT_DURATION "ly:duration?"
 272 %token <i> EXPECT_SCM "scheme?"
 273 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 274 /* After the last argument. */
 275 %token <i> EXPECT_NO_MORE_ARGS;
 276
 277 /* An artificial token for parsing embedded Lilypond */
 278 %token <i> EMBEDDED_LILY "#{"
 279
 280 %token <scm> BOOK_IDENTIFIER
 281 %token <scm> CHORDMODIFIER_PITCH
 282 %token <scm> CHORD_MODIFIER
 283 %token <scm> CHORD_REPETITION
 284 %token <scm> CONTEXT_DEF_IDENTIFIER
 285 %token <scm> CONTEXT_MOD_IDENTIFIER
 286 %token <scm> DRUM_PITCH
 287 %token <scm> DURATION_IDENTIFIER
 288 %token <scm> EVENT_IDENTIFIER
 289 %token <scm> FRACTION
 290 %token <scm> LYRICS_STRING
 291 %token <scm> LYRIC_MARKUP_IDENTIFIER
 292 %token <scm> MARKUP_FUNCTION
 293 %token <scm> MARKUP_LIST_FUNCTION
 294 %token <scm> MARKUP_IDENTIFIER
 295 %token <scm> MARKUPLINES_IDENTIFIER
 296 %token <scm> MUSIC_FUNCTION
 297 %token <scm> MUSIC_IDENTIFIER
 298 %token <scm> NOTENAME_PITCH
 299 %token <scm> NUMBER_IDENTIFIER
 300 %token <scm> OUTPUT_DEF_IDENTIFIER
 301 %token <scm> REAL
 302 %token <scm> RESTNAME
 303 %token <scm> SCM_FUNCTION
 304 %token <scm> SCM_IDENTIFIER
 305 %token <scm> SCM_TOKEN
 306 %token <scm> SCORE_IDENTIFIER
 307 %token <scm> STRING
 308 %token <scm> STRING_IDENTIFIER
 309 %token <scm> TONICNAME_PITCH
 310
 311
 312 %type <book> book_block
 313 %type <book> book_body
 314 %type <book> bookpart_block
 315 %type <book> bookpart_body
 316
 317 %type <i> bare_unsigned
 318 %type <scm> figured_bass_alteration
 319 %type <i> dots
 320 %type <i> exclamations
 321 %type <i> optional_rest
 322 %type <i> questions
 323 %type <i> script_dir
 324 %type <i> sub_quotes
 325 %type <i> sup_quotes
 326 %type <i> tremolo_type
 327
 328 /* Music */
 329 %type <scm> composite_music
 330 %type <scm> grouped_music_list
 331 %type <scm> closed_music
 332 %type <scm> open_music
 333 %type <scm> music
 334 %type <scm> prefix_composite_music
 335 %type <scm> repeated_music
 336 %type <scm> sequential_music
 337 %type <scm> simple_music
 338 %type <scm> simultaneous_music
 339 %type <scm> chord_body
 340 %type <scm> chord_body_element
 341 %type <scm> command_element
 342 %type <scm> command_event
 343 %type <scm> context_modification
 344 %type <scm> context_change
 345 %type <scm> direction_less_event
 346 %type <scm> direction_reqd_event
 347 %type <scm> embedded_lilypond
 348 %type <scm> event_chord
 349 %type <scm> fingering
 350 %type <scm> gen_text_def
 351 %type <scm> music_property_def
 352 %type <scm> note_chord_element
 353 %type <scm> post_event
 354 %type <scm> post_event_nofinger
 355 %type <scm> re_rhythmed_music
 356 %type <scm> relative_music
 357 %type <scm> simple_element
 358 %type <scm> simple_music_property_def
 359 %type <scm> start_symbol
 360 %type <scm> string_number_event
 361 %type <scm> tempo_event
 362
 363 %type <outputdef> output_def_body
 364 %type <outputdef> output_def_head
 365 %type <outputdef> output_def_head_with_mode_switch
 366 %type <outputdef> output_def
 367 %type <outputdef> paper_block
 368
 369 %type <scm> alternative_music
 370 %type <scm> generic_prefix_music_scm
 371 %type <scm> music_list
 372 %type <scm> absolute_pitch
 373 %type <scm> assignment_id
 374 %type <scm> bare_number
 375 %type <scm> unsigned_number
 376 %type <scm> bass_figure
 377 %type <scm> figured_bass_modification
 378 %type <scm> br_bass_figure
 379 %type <scm> bass_number
 380 %type <scm> chord_body_elements
 381 %type <scm> chord_item
 382 %type <scm> chord_items
 383 %type <scm> chord_separator
 384 %type <scm> context_def_mod
 385 %type <scm> context_def_spec_block
 386 %type <scm> context_def_spec_body
 387 %type <scm> context_mod
 388 %type <scm> context_mod_list
 389 %type <scm> context_prop_spec
 390 %type <scm> direction_less_char
 391 %type <scm> duration_length
 392 %type <scm> closed_embedded_scm
 393 %type <scm> embedded_scm
 394 %type <scm> figure_list
 395 %type <scm> figure_spec
 396 %type <scm> fraction
 397 %type <scm> full_markup
 398 %type <scm> full_markup_list
 399 %type <scm> function_scm_argument
 400 %type <scm> function_arglist
 401 %type <scm> function_arglist_nonmusic_last
 402 %type <scm> closed_function_arglist
 403 %type <scm> open_function_arglist
 404 %type <scm> identifier_init
 405 %type <scm> lilypond
 406 %type <scm> lilypond_header
 407 %type <scm> lilypond_header_body
 408 %type <scm> lyric_element
 409 %type <scm> lyric_markup
 410 %type <scm> markup
 411 %type <scm> markup_braced_list
 412 %type <scm> markup_braced_list_body
 413 %type <scm> markup_composed_list
 414 %type <scm> markup_command_list
 415 %type <scm> markup_command_list_arguments
 416 %type <scm> closed_markup_command_list_arguments
 417 %type <scm> markup_command_basic_arguments
 418 %type <scm> markup_head_1_item
 419 %type <scm> markup_head_1_list
 420 %type <scm> markup_list
 421 %type <scm> markup_top
 422 %type <scm> mode_changing_head
 423 %type <scm> mode_changing_head_with_context
 424 %type <scm> multiplied_duration
 425 %type <scm> music_function_event
 426 %type <scm> music_function_event_arglist
 427 %type <scm> music_function_chord_body
 428 %type <scm> music_function_chord_body_arglist
 429 %type <scm> new_chord
 430 %type <scm> new_lyrics
 431 %type <scm> number_expression
 432 %type <scm> number_factor
 433 %type <scm> number_term
 434 %type <scm> octave_check
 435 %type <scm> optional_context_mod
 436 %type <scm> optional_id
 437 %type <scm> optional_notemode_duration
 438 %type <scm> pitch
 439 %type <scm> pitch_also_in_chords
 440 %type <scm> post_events
 441 %type <scm> property_operation
 442 %type <scm> property_path property_path_revved
 443 %type <scm> scalar
 444 %type <scm> closed_scalar
 445 %type <scm> open_scm_function_call
 446 %type <scm> closed_scm_function_call
 447 %type <scm> script_abbreviation
 448 %type <scm> simple_chord_elements
 449 %type <scm> simple_markup
 450 %type <scm> simple_string
 451 %type <scm> steno_duration
 452 %type <scm> steno_pitch
 453 %type <scm> steno_tonic_pitch
 454 %type <scm> step_number
 455 %type <scm> step_numbers
 456 %type <scm> string
 457 %type <scm> tempo_range
 458
 459 %type <score> score_block
 460 %type <score> score_body
 461
 462
 463 %left '-' '+'
 464
 465 /* We don't assign precedence to / and *, because we might need varied
 466 prec levels in different prods */
 467
 468 %left UNARY_MINUS
 469
 470 %%
 471
 472 start_symbol:
 473         lilypond
 474         | EMBEDDED_LILY {
 475                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
 476                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
 477         } embedded_lilypond {
 478                 PARSER->lexer_->pop_state ();
 479                 PARSER->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 480         }
 481         ;
 482
 483 lilypond:       /* empty */ { }
 484         | lilypond toplevel_expression {
 485         }
 486         | lilypond assignment {
 487         }
 488         | lilypond error {
 489                 PARSER->error_level_ = 1;
 490         }
 491         | lilypond INVALID      {
 492                 PARSER->error_level_ = 1;
 493         }
 494         ;
 495
 496
 497 toplevel_expression:
 498         lilypond_header {
 499                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 500         }
 501         | book_block {
 502                 Book *book = $1;
 503                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 504                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 505                 book->unprotect ();
 506         }
 507         | bookpart_block {
 508                 Book *bookpart = $1;
 509                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 510                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 511                 bookpart->unprotect ();
 512         }
 513         | score_block {
 514                 Score *score = $1;
 515
 516                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 517                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 518                 score->unprotect ();
 519         }
 520         | composite_music {
 521                 Music *music = unsmob_music ($1);
 522                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 523                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 524         }
 525         | full_markup {
 526                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 527                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 528         }
 529         | full_markup_list {
 530                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 531                 scm_call_2 (proc, PARSER->self_scm (), $1);
 532         }
 533         | output_def {
 534                 SCM id = SCM_EOL;
 535                 Output_def * od = $1;
 536
 537                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 538                         id = ly_symbol2scm ("$defaultpaper");
 539                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 540                         id = ly_symbol2scm ("$defaultmidi");
 541                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 542                         id = ly_symbol2scm ("$defaultlayout");
 543
 544                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 545                 od->unprotect();
 546         }
 547         ;
 548
 549 closed_embedded_scm:
 550         SCM_TOKEN
 551         | SCM_IDENTIFIER
 552         | closed_scm_function_call
 553         ;
 554
 555 embedded_scm:
 556         closed_embedded_scm
 557         | open_scm_function_call
 558         ;
 559
 560 closed_scm_function_call:
 561         SCM_FUNCTION closed_function_arglist
 562         {
 563                 $$ = run_music_function (PARSER, @$,
 564                                          $1, $2);
 565         }
 566         ;
 567
 568 open_scm_function_call:
 569         SCM_FUNCTION open_function_arglist
 570         {
 571                 $$ = run_music_function (PARSER, @$,
 572                                          $1, $2);
 573         }
 574         ;
 575
 576 embedded_lilypond:
 577         { $$ = MAKE_SYNTAX ("void-music", @$, SCM_UNDEFINED); }
 578         | identifier_init
 579         | music music music_list {
 580                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 581                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 582         }
 583         | error {
 584                 PARSER->error_level_ = 1;
 585         }
 586         | INVALID embedded_lilypond {
 587                 PARSER->error_level_ = 1;
 588         }
 589         ;
 590
 591
 592 lilypond_header_body:
 593         {
 594                 $$ = get_header (PARSER);
 595                 PARSER->lexer_->add_scope ($$);
 596         }
 597         | lilypond_header_body assignment  {
 598
 599         }
 600         ;
 601
 602 lilypond_header:
 603         HEADER '{' lilypond_header_body '}'     {
 604                 $$ = PARSER->lexer_->remove_scope ();
 605         }
 606         ;
 607
 608 /*
 609         DECLARATIONS
 610 */
 611 assignment_id:
 612         STRING          { $$ = $1; }
 613         | LYRICS_STRING { $$ = $1; }
 614         ;
 615
 616 assignment:
 617         assignment_id '=' identifier_init  {
 618                 PARSER->lexer_->set_identifier ($1, $3);
 619         }
 620         | assignment_id property_path '=' identifier_init {
 621                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 622                 PARSER->lexer_->set_identifier (path, $4);
 623         ;
 624 /*
 625  TODO: devise standard for protection in parser.
 626
 627   The parser stack lives on the C-stack, which means that
 628 all objects can be unprotected as soon as they're here.
 629
 630 */
 631         }
 632         | embedded_scm { }
 633         ;
 634
 635
 636 identifier_init:
 637         score_block {
 638                 $$ = $1->self_scm ();
 639                 $1->unprotect ();
 640         }
 641         | book_block {
 642                 $$ = $1->self_scm ();
 643                 $1->unprotect ();
 644         }
 645         | bookpart_block {
 646                 $$ = $1->self_scm ();
 647                 $1->unprotect ();
 648         }
 649         | output_def {
 650                 $$ = $1->self_scm ();
 651                 $1->unprotect ();
 652         }
 653         | context_def_spec_block {
 654                 $$ = $1;
 655         }
 656         | music  {
 657                 /* Hack: Create event-chord around standalone events.
 658                    Prevents the identifier from being interpreted as a post-event. */
 659                 Music *mus = unsmob_music ($1);
 660                 bool is_event = mus &&
 661                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 662                                 != SCM_BOOL_F);
 663                 if (!is_event)
 664                         $$ = $1;
 665                 else
 666                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 667         }
 668         | post_event_nofinger {
 669                 $$ = $1;
 670         }
 671         | number_expression {
 672                 $$ = $1;
 673         }
 674         | string {
 675                 $$ = $1;
 676         }
 677         | embedded_scm {
 678                 $$ = $1;
 679         }
 680         | full_markup {
 681                 $$ = $1;
 682         }
 683         | full_markup_list {
 684                 $$ = $1;
 685         }
 686         | context_modification {
 687                 $$ = $1;
 688         }
 689         ;
 690
 691 context_def_spec_block:
 692         CONTEXT '{' context_def_spec_body '}'
 693                 {
 694                 $$ = $3;
 695         }
 696         ;
 697
 698 context_def_spec_body:
 699         /**/ {
 700                 $$ = Context_def::make_scm ();
 701                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 702         }
 703         | CONTEXT_DEF_IDENTIFIER {
 704                 $$ = $1;
 705                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 706         }
 707         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 708                 Context_def*td = unsmob_context_def ($$);
 709
 710                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 711                         SCM tag = scm_caar (p);
 712
 713                         /* TODO: should make new tag "grob-definition" ? */
 714                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 715                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 716                 }
 717         }
 718         | context_def_spec_body context_mod {
 719                 unsmob_context_def ($$)->add_context_mod ($2);
 720         }
 721         | context_def_spec_body context_modification {
 722                 Context_def *td = unsmob_context_def ($$);
 723                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 724                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 725                     td->add_context_mod (scm_car (m));
 726                 }
 727         }
 728         ;
 729
 730
 731
 732 book_block:
 733         BOOK '{' book_body '}'  {
 734                 $$ = $3;
 735                 pop_paper (PARSER);
 736                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 737         }
 738         ;
 739
 740 /* FIXME:
 741    * Use 'handlers' like for toplevel-* stuff?
 742    * grok \layout and \midi?  */
 743 book_body:
 744         {
 745                 $$ = new Book;
 746                 init_papers (PARSER);
 747                 $$->origin ()->set_spot (@$);
 748                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 749                 $$->paper_->unprotect ();
 750                 push_paper (PARSER, $$->paper_);
 751                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 752                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 753                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 754                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 755         }
 756         | BOOK_IDENTIFIER {
 757                 $$ = unsmob_book ($1);
 758                 $$->protect ();
 759                 $$->origin ()->set_spot (@$);
 760                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 761         }
 762         | book_body paper_block {
 763                 $$->paper_ = $2;
 764                 $2->unprotect ();
 765                 set_paper (PARSER, $2);
 766         }
 767         | book_body bookpart_block {
 768                 Book *bookpart = $2;
 769                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 770                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 771                 bookpart->unprotect ();
 772         }
 773         | book_body score_block {
 774                 Score *score = $2;
 775                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 776                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 777                 score->unprotect ();
 778         }
 779         | book_body composite_music {
 780                 Music *music = unsmob_music ($2);
 781                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 782                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 783         }
 784         | book_body full_markup {
 785                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 786                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 787         }
 788         | book_body full_markup_list {
 789                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 790                 scm_call_2 (proc, $$->self_scm (), $2);
 791         }
 792         | book_body lilypond_header {
 793                 $$->header_ = $2;
 794         }
 795         | book_body error {
 796                 $$->paper_ = 0;
 797                 $$->scores_ = SCM_EOL;
 798                 $$->bookparts_ = SCM_EOL;
 799         }
 800         ;
 801
 802 bookpart_block:
 803         BOOKPART '{' bookpart_body '}' {
 804                 $$ = $3;
 805                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 806         }
 807         ;
 808
 809 bookpart_body:
 810         {
 811                 $$ = new Book;
 812                 $$->origin ()->set_spot (@$);
 813                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 814         }
 815         | BOOK_IDENTIFIER {
 816                 $$ = unsmob_book ($1);
 817                 $$->protect ();
 818                 $$->origin ()->set_spot (@$);
 819                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 820         }
 821         | bookpart_body paper_block {
 822                 $$->paper_ = $2;
 823                 $2->unprotect ();
 824         }
 825         | bookpart_body score_block {
 826                 Score *score = $2;
 827                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 828                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 829                 score->unprotect ();
 830         }
 831         | bookpart_body composite_music {
 832                 Music *music = unsmob_music ($2);
 833                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 834                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 835         }
 836         | bookpart_body full_markup {
 837                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 838                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 839         }
 840         | bookpart_body full_markup_list {
 841                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 842                 scm_call_2 (proc, $$->self_scm (), $2);
 843         }
 844         | bookpart_body lilypond_header {
 845                 $$->header_ = $2;
 846         }
 847         | bookpart_body error {
 848                 $$->paper_ = 0;
 849                 $$->scores_ = SCM_EOL;
 850         }
 851         ;
 852
 853 score_block:
 854         SCORE '{' score_body '}'        {
 855                 $$ = $3;
 856         }
 857         ;
 858
 859 score_body:
 860         music {
 861                 SCM m = $1;
 862                 SCM scorify = ly_lily_module_constant ("scorify-music");
 863                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 864
 865                 // pass ownernship to C++ again.
 866                 $$ = unsmob_score (score);
 867                 $$->protect ();
 868                 $$->origin ()->set_spot (@$);
 869         }
 870         | SCORE_IDENTIFIER {
 871                 $$ = unsmob_score ($1);
 872                 $$->protect ();
 873                 $$->origin ()->set_spot (@$);
 874         }
 875         | score_body lilypond_header    {
 876                 $$->set_header ($2);
 877         }
 878         | score_body output_def {
 879                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 880                 {
 881                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 882
 883                 }
 884                 else
 885                 {
 886                         $$->add_output_def ($2);
 887                 }
 888                 $2->unprotect ();
 889         }
 890         | score_body error {
 891                 $$->error_found_ = true;
 892         }
 893         ;
 894
 895
 896 /*
 897         OUTPUT DEF
 898 */
 899
 900 paper_block:
 901         output_def {
 902                 $$ = $1;
 903                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 904                 {
 905                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 906                         $1->unprotect ();
 907                         $$ = get_paper (PARSER);
 908                 }
 909         }
 910         ;
 911
 912
 913 output_def:
 914         output_def_body '}' {
 915                 $$ = $1;
 916
 917                 PARSER->lexer_->remove_scope ();
 918                 PARSER->lexer_->pop_state ();
 919         }
 920         ;
 921
 922 output_def_head:
 923         PAPER {
 924                 $$ = get_paper (PARSER);
 925                 $$->input_origin_ = @$;
 926                 PARSER->lexer_->add_scope ($$->scope_);
 927         }
 928         | MIDI    {
 929                 Output_def *p = get_midi (PARSER);
 930                 $$ = p;
 931                 PARSER->lexer_->add_scope (p->scope_);
 932         }
 933         | LAYOUT        {
 934                 Output_def *p = get_layout (PARSER);
 935
 936                 PARSER->lexer_->add_scope (p->scope_);
 937                 $$ = p;
 938         }
 939         ;
 940
 941 output_def_head_with_mode_switch:
 942         output_def_head {
 943                 PARSER->lexer_->push_initial_state ();
 944                 $$ = $1;
 945         }
 946         ;
 947
 948 output_def_body:
 949         output_def_head_with_mode_switch '{' {
 950                 $$ = $1;
 951                 $$->input_origin_.set_spot (@$);
 952         }
 953         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 954                 $1->unprotect ();
 955
 956                 Output_def *o = unsmob_output_def ($3);
 957                 o->input_origin_.set_spot (@$);
 958                 $$ = o;
 959                 $$->protect ();
 960                 PARSER->lexer_->remove_scope ();
 961                 PARSER->lexer_->add_scope (o->scope_);
 962         }
 963         | output_def_body assignment  {
 964
 965         }
 966         | output_def_body context_def_spec_block        {
 967                 assign_context_def ($$, $2);
 968         }
 969         | output_def_body error {
 970
 971         }
 972         ;
 973
 974 tempo_event:
 975         TEMPO steno_duration '=' tempo_range    {
 976                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
 977         }
 978         | TEMPO closed_scalar steno_duration '=' tempo_range    {
 979                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
 980         }
 981         | TEMPO closed_scalar {
 982                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
 983         }
 984         ;
 985
 986 /*
 987 The representation of a  list is reversed to have efficient append.  */
 988
 989 music_list:
 990         /* empty */ {
 991                 $$ = SCM_EOL;
 992         }
 993         | music_list music {
 994                 $$ = scm_cons ($2, $1);
 995         }
 996         | music_list embedded_scm {
 997
 998         }
 999         | music_list error {
1000                 Music *m = MY_MAKE_MUSIC("Music", @$);
1001                 // ugh. code dup
1002                 m->set_property ("error-found", SCM_BOOL_T);
1003                 $$ = scm_cons (m->self_scm (), $1);
1004                 m->unprotect (); /* UGH */
1005         }
1006         ;
1007
1008 music:
1009         simple_music
1010         | composite_music
1011         | MUSIC_IDENTIFIER
1012         ;
1013
1014 alternative_music:
1015         /* empty */ {
1016                 $$ = SCM_EOL;
1017         }
1018         | ALTERNATIVE '{' music_list '}' {
1019                 $$ = scm_reverse_x ($3, SCM_EOL);
1020         }
1021         ;
1022
1023
1024 repeated_music:
1025         REPEAT simple_string unsigned_number music alternative_music
1026         {
1027                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
1028         }
1029         ;
1030
1031 sequential_music:
1032         SEQUENTIAL '{' music_list '}'           {
1033                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_reverse_x ($3, SCM_EOL));
1034         }
1035         | '{' music_list '}'            {
1036                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_reverse_x ($2, SCM_EOL));
1037         }
1038         ;
1039
1040 simultaneous_music:
1041         SIMULTANEOUS '{' music_list '}'{
1042                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($3, SCM_EOL));
1043         }
1044         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1045                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1046         }
1047         ;
1048
1049 simple_music:
1050         event_chord
1051         | music_property_def
1052         | context_change
1053         ;
1054
1055 context_modification:
1056         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1057         {
1058                 PARSER->lexer_->pop_state ();
1059                 $$ = $4;
1060         }
1061         | WITH CONTEXT_MOD_IDENTIFIER
1062         {
1063                 $$ = $2;
1064         }
1065         | CONTEXT_MOD_IDENTIFIER
1066         {
1067                 $$ = $1;
1068         }
1069         ;
1070
1071 optional_context_mod:
1072         /**/ {
1073             $$ = SCM_EOL;
1074         }
1075         | context_modification
1076         {
1077               $$ = $1;
1078         }
1079         ;
1080
1081 context_mod_list:
1082         /**/ {
1083             $$ = Context_mod ().smobbed_copy ();
1084         }
1085         | context_mod_list context_mod  {
1086                  unsmob_context_mod ($1)->add_context_mod ($2);
1087         }
1088         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1089                  Context_mod *md = unsmob_context_mod ($2);
1090                  if (md)
1091                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1092         }
1093         ;
1094
1095 composite_music:
1096         prefix_composite_music { $$ = $1; }
1097         | grouped_music_list { $$ = $1; }
1098         ;
1099
1100 /* Music that can't be followed by additional events or durations */
1101 closed_music:
1102         MUSIC_IDENTIFIER
1103         | grouped_music_list
1104         ;
1105
1106 /* Music that potentially accepts additional events or durations */
1107 open_music:
1108         simple_music
1109         | prefix_composite_music
1110         ;
1111
1112 grouped_music_list:
1113         simultaneous_music              { $$ = $1; }
1114         | sequential_music              { $$ = $1; }
1115         ;
1116
1117 function_scm_argument:
1118         closed_embedded_scm
1119         | simple_string
1120         ;
1121
1122 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
1123  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1124 and this rule returns the reversed list of arguments. */
1125
1126
1127 function_arglist:
1128         closed_function_arglist
1129         | open_function_arglist
1130         ;
1131
1132 open_function_arglist:
1133         EXPECT_MUSIC function_arglist open_music {
1134                 $$ = scm_cons ($3, $2);
1135         }
1136         | EXPECT_SCM function_arglist open_scm_function_call {
1137                 $$ = scm_cons ($3, $2);
1138         }
1139         ;
1140
1141 /* a closed argument list is one that does not end in a music
1142    expression that could still take a duration or event */
1143
1144 closed_function_arglist:
1145         function_arglist_nonmusic_last
1146         | EXPECT_MUSIC function_arglist closed_music {
1147                 $$ = scm_cons ($3, $2);
1148                 }
1149         ;
1150
1151 function_arglist_nonmusic_last:
1152         EXPECT_NO_MORE_ARGS {
1153                 /* This is for 0-ary functions, so they don't need to
1154                    read a lookahead token */
1155                 $$ = SCM_EOL;
1156         }
1157         | EXPECT_MARKUP function_arglist full_markup {
1158                 $$ = scm_cons ($3, $2);
1159         }
1160         | EXPECT_MARKUP function_arglist simple_string {
1161                 $$ = scm_cons ($3, $2);
1162         }
1163         | EXPECT_PITCH function_arglist pitch_also_in_chords {
1164                 $$ = scm_cons ($3, $2);
1165         }
1166         | EXPECT_DURATION closed_function_arglist duration_length {
1167                 $$ = scm_cons ($3, $2);
1168         }
1169         | EXPECT_SCM function_arglist function_scm_argument {
1170                 $$ = scm_cons ($3, $2);
1171         }
1172         ;
1173
1174 generic_prefix_music_scm:
1175         MUSIC_FUNCTION function_arglist {
1176                 $$ = run_music_function (PARSER, @$,
1177                                          $1, $2);
1178         }
1179         ;
1180
1181
1182 optional_id:
1183         /**/ { $$ = SCM_EOL; }
1184         | '=' simple_string {
1185                 $$ = $2;
1186         }
1187         ;
1188
1189
1190 prefix_composite_music:
1191         generic_prefix_music_scm
1192         | CONTEXT simple_string optional_id optional_context_mod music {
1193                 Context_mod *ctxmod = unsmob_context_mod ($4);
1194                 SCM mods = SCM_EOL;
1195                 if (ctxmod)
1196                         mods = ctxmod->get_mods ();
1197                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_F);
1198         }
1199         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1200                 Context_mod *ctxmod = unsmob_context_mod ($4);
1201                 SCM mods = SCM_EOL;
1202                 if (ctxmod)
1203                         mods = ctxmod->get_mods ();
1204                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_T);
1205         }
1206
1207         | TIMES fraction music {
1208                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1209         }
1210         | repeated_music                { $$ = $1; }
1211         | mode_changing_head grouped_music_list {
1212                 if ($1 == ly_symbol2scm ("chords"))
1213                 {
1214                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1215                 }
1216                 else
1217                 {
1218                   $$ = $2;
1219                 }
1220                 PARSER->lexer_->pop_state ();
1221         }
1222         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1223                 Context_mod *ctxmod = unsmob_context_mod ($2);
1224                 SCM mods = SCM_EOL;
1225                 if (ctxmod)
1226                         mods = ctxmod->get_mods ();
1227                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, mods, SCM_BOOL_T);
1228                 if ($1 == ly_symbol2scm ("ChordNames"))
1229                 {
1230                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1231                 }
1232                 PARSER->lexer_->pop_state ();
1233         }
1234         | relative_music        { $$ = $1; }
1235         | re_rhythmed_music     { $$ = $1; }
1236         ;
1237
1238 mode_changing_head:
1239         NOTEMODE {
1240                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1241                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1242
1243                 $$ = ly_symbol2scm ("notes");
1244         }
1245         | DRUMMODE
1246                 {
1247                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1248                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1249
1250                 $$ = ly_symbol2scm ("drums");
1251         }
1252         | FIGUREMODE {
1253                 PARSER->lexer_->push_figuredbass_state ();
1254
1255                 $$ = ly_symbol2scm ("figures");
1256         }
1257         | CHORDMODE {
1258                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1259                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1260                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1261                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1262                 $$ = ly_symbol2scm ("chords");
1263
1264         }
1265         | LYRICMODE
1266                 { PARSER->lexer_->push_lyric_state ();
1267                 $$ = ly_symbol2scm ("lyrics");
1268         }
1269         ;
1270
1271 mode_changing_head_with_context:
1272         DRUMS {
1273                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1274                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1275
1276                 $$ = ly_symbol2scm ("DrumStaff");
1277         }
1278         | FIGURES {
1279                 PARSER->lexer_->push_figuredbass_state ();
1280
1281                 $$ = ly_symbol2scm ("FiguredBass");
1282         }
1283         | CHORDS {
1284                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1285                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1286                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1287                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1288                 $$ = ly_symbol2scm ("ChordNames");
1289         }
1290         | LYRICS
1291                 { PARSER->lexer_->push_lyric_state ();
1292                 $$ = ly_symbol2scm ("Lyrics");
1293         }
1294         ;
1295
1296
1297 relative_music:
1298         RELATIVE absolute_pitch music {
1299                 Pitch start = *unsmob_pitch ($2);
1300                 $$ = make_music_relative (start, $3, @$);
1301         }
1302         | RELATIVE composite_music {
1303                 Pitch middle_c (0, 0, 0);
1304                 $$ = make_music_relative (middle_c, $2, @$);
1305         }
1306         ;
1307
1308 new_lyrics:
1309         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1310         /*cont */
1311         closed_music {
1312         /* Can also use music at the expensive of two S/Rs similar to
1313            \repeat \alternative */
1314                 PARSER->lexer_->pop_state ();
1315
1316                 $$ = scm_cons ($3, SCM_EOL);
1317         }
1318         | new_lyrics ADDLYRICS {
1319                 PARSER->lexer_->push_lyric_state ();
1320         } closed_music {
1321                 PARSER->lexer_->pop_state ();
1322                 $$ = scm_cons ($4, $1);
1323         }
1324         ;
1325
1326 re_rhythmed_music:
1327         closed_music new_lyrics {
1328                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1329         }
1330         | LYRICSTO simple_string {
1331                 PARSER->lexer_->push_lyric_state ();
1332         } music {
1333                 PARSER->lexer_->pop_state ();
1334                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1335         }
1336         ;
1337
1338 context_change:
1339         CHANGE STRING '=' STRING  {
1340                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1341         }
1342         ;
1343
1344
1345 property_path_revved:
1346         closed_embedded_scm {
1347                 $$ = scm_cons ($1, SCM_EOL);
1348         }
1349         | property_path_revved closed_embedded_scm {
1350                 $$ = scm_cons ($2, $1);
1351         }
1352         ;
1353
1354 property_path:
1355         property_path_revved  {
1356                 $$ = scm_reverse_x ($1, SCM_EOL);
1357         }
1358         ;
1359
1360 property_operation:
1361         STRING '=' scalar {
1362                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1363                         scm_string_to_symbol ($1), $3);
1364         }
1365         | UNSET simple_string {
1366                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1367                         scm_string_to_symbol ($2));
1368         }
1369         | OVERRIDE simple_string property_path '=' scalar {
1370                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1371                                                         scm_string_to_symbol ($2), $5),
1372                                              $3));
1373         }
1374         | REVERT simple_string embedded_scm {
1375                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1376                         scm_string_to_symbol ($2), $3);
1377         }
1378         ;
1379
1380 context_def_mod:
1381         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1382         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1383
1384         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1385         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1386         | DENIES { $$ = ly_symbol2scm ("denies"); }
1387
1388         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1389         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1390         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1391         | NAME { $$ = ly_symbol2scm ("context-name"); }
1392         ;
1393
1394 context_mod:
1395         property_operation { $$ = $1; }
1396         | context_def_mod STRING {
1397                 $$ = scm_list_2 ($1, $2);
1398         }
1399         | context_def_mod embedded_scm {
1400            if (ly_symbol2scm ("consists") != $1)
1401            {
1402              $$ = SCM_EOL;
1403              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1404            }
1405            else
1406            {
1407              $$ = scm_list_2 ($1, $2);
1408            }
1409         }
1410         ;
1411
1412 context_prop_spec:
1413         simple_string {
1414                 if (!is_regular_identifier ($1))
1415                 {
1416                         @$.error (_("Grob name should be alphanumeric"));
1417                 }
1418
1419                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1420                         scm_string_to_symbol ($1));
1421         }
1422         | simple_string '.' simple_string {
1423                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1424                         scm_string_to_symbol ($3));
1425         }
1426         ;
1427
1428 simple_music_property_def:
1429         OVERRIDE context_prop_spec property_path '=' scalar {
1430                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1431                                 ly_symbol2scm ("OverrideProperty"),
1432                                 scm_cadr ($2),
1433                                 $5, SCM_UNDEFINED),
1434                                 $3));
1435         }
1436         | REVERT context_prop_spec embedded_scm {
1437                 $$ = scm_list_4 (scm_car ($2),
1438                         ly_symbol2scm ("RevertProperty"),
1439                         scm_cadr ($2),
1440                         $3);
1441         }
1442         | SET context_prop_spec '=' scalar {
1443                 $$ = scm_list_4 (scm_car ($2),
1444                         ly_symbol2scm ("PropertySet"),
1445                         scm_cadr ($2),
1446                         $4);
1447         }
1448         | UNSET context_prop_spec {
1449                 $$ = scm_list_3 (scm_car ($2),
1450                         ly_symbol2scm ("PropertyUnset"),
1451                         scm_cadr ($2));
1452         }
1453         ;
1454
1455 music_property_def:
1456         simple_music_property_def {
1457                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1458         }
1459         | ONCE simple_music_property_def {
1460                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1461         }
1462         ;
1463
1464 string:
1465         STRING {
1466                 $$ = $1;
1467         }
1468         | STRING_IDENTIFIER {
1469                 $$ = $1;
1470         }
1471         | string '+' string {
1472                 $$ = scm_string_append (scm_list_2 ($1, $3));
1473         }
1474         ;
1475
1476 simple_string: STRING {
1477                 $$ = $1;
1478         }
1479         | LYRICS_STRING {
1480                 $$ = $1;
1481         }
1482         | STRING_IDENTIFIER {
1483                 $$ = $1;
1484         }
1485         ;
1486
1487 closed_scalar: string {
1488                 $$ = $1;
1489         }
1490         | lyric_element {
1491                 $$ = $1;
1492         }
1493         | bare_number {
1494                 $$ = $1;
1495         }
1496         | closed_embedded_scm {
1497                 $$ = $1;
1498         }
1499         | full_markup {
1500                 $$ = $1;
1501         }
1502         ;
1503
1504 scalar: closed_scalar
1505         | open_scm_function_call
1506         ;
1507
1508 event_chord:
1509         /* TODO: Create a special case that avoids the creation of
1510            EventChords around simple_elements that have no post_events?
1511          */
1512         simple_chord_elements post_events       {
1513                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1514
1515                 Input i;
1516                 /* why is this giving wrong start location? -ns
1517                  * i = @$; */
1518                 i.set_location (@1, @2);
1519                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1520         }
1521         | CHORD_REPETITION optional_notemode_duration post_events {
1522                 Input i;
1523                 i.set_location (@1, @3);
1524                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1525                                   PARSER->lexer_->chord_repetition_.last_chord_,
1526                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1527                                   $2, scm_reverse_x ($3, SCM_EOL));
1528         }
1529         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1530                 Input i;
1531                 i.set_location (@1, @3);
1532                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1533                                   scm_reverse_x ($3, SCM_EOL));
1534         }
1535         | command_element
1536         /* note chord elements are memorized into
1537            PARSER->lexer_->chord_repetition_ so that the chord repetition
1538            mechanism copy them when a chord repetition symbol is found
1539         */
1540         | note_chord_element    {
1541                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1542         }
1543         ;
1544
1545
1546 note_chord_element:
1547         chord_body optional_notemode_duration post_events
1548         {
1549                 Music *m = unsmob_music ($1);
1550                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1551                 SCM es = m->get_property ("elements");
1552                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1553
1554                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1555                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1556                 es = ly_append2 (es, postevs);
1557
1558                 m-> set_property ("elements", es);
1559                 m->set_spot (@$);
1560                 $$ = m->self_scm ();
1561         }
1562         ;
1563
1564 chord_body:
1565         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1566         {
1567                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1568         }
1569         ;
1570
1571 chord_body_elements:
1572         /* empty */             { $$ = SCM_EOL; }
1573         | chord_body_elements chord_body_element {
1574                 $$ = scm_cons ($2, $1);
1575         }
1576         ;
1577
1578 chord_body_element:
1579         pitch exclamations questions octave_check post_events
1580         {
1581                 int q = $3;
1582                 int ex = $2;
1583                 SCM check = $4;
1584                 SCM post = $5;
1585
1586                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1587                 n->set_property ("pitch", $1);
1588                 if (q % 2)
1589                         n->set_property ("cautionary", SCM_BOOL_T);
1590                 if (ex % 2 || q % 2)
1591                         n->set_property ("force-accidental", SCM_BOOL_T);
1592
1593                 if (scm_is_pair (post)) {
1594                         SCM arts = scm_reverse_x (post, SCM_EOL);
1595                         n->set_property ("articulations", arts);
1596                 }
1597                 if (scm_is_number (check))
1598                 {
1599                         int q = scm_to_int (check);
1600                         n->set_property ("absolute-octave", scm_from_int (q-1));
1601                 }
1602
1603                 $$ = n->unprotect ();
1604         }
1605         | DRUM_PITCH post_events {
1606                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1607                 n->set_property ("drum-type", $1);
1608
1609                 if (scm_is_pair ($2)) {
1610                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1611                         n->set_property ("articulations", arts);
1612                 }
1613                 $$ = n->unprotect ();
1614         }
1615         | music_function_chord_body
1616         ;
1617
1618 /* We can't accept a music argument, not even a closed one,
1619  * immediately before chord_body_elements, otherwise a function \fun
1620  * with a signature of two music arguments can't be sorted out
1621  * properly in a construct like
1622  * <\fun { c } \fun { c } c>
1623  * The second call could be interpreted either as a chord constituent
1624  * or a music expression.
1625  */
1626
1627 music_function_chord_body_arglist:
1628         function_arglist_nonmusic_last
1629         | EXPECT_MUSIC music_function_chord_body_arglist chord_body_element {
1630                 $$ = scm_cons ($3, $2);
1631         }
1632         ;
1633
1634 music_function_chord_body:
1635         MUSIC_FUNCTION music_function_chord_body_arglist {
1636                 $$ = run_music_function (PARSER, @$,
1637                                          $1, $2);
1638         }
1639         ;
1640
1641 /* We could accept a closed music argument before the post events
1642  * indicated by a trailing argument list.  For symmetry with chord
1643  * bodies and in order to avoid too tricky and complex behavior, we
1644  * refrain from doing so.
1645  */
1646 music_function_event_arglist:
1647         function_arglist_nonmusic_last
1648         | EXPECT_MUSIC music_function_event_arglist post_event {
1649                 $$ = scm_cons ($3, $2);
1650         }
1651         ;
1652
1653 music_function_event:
1654         MUSIC_FUNCTION music_function_event_arglist {
1655                 $$ = run_music_function (PARSER, @$,
1656                                          $1, $2);
1657         }
1658         ;
1659
1660 command_element:
1661         command_event {
1662                 $$ = $1;
1663         }
1664         | SKIP duration_length {
1665                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1666         }
1667         | E_BRACKET_OPEN {
1668                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1669                 m->set_property ("span-direction", scm_from_int (START));
1670                 $$ = m->unprotect();
1671         }
1672         | E_BRACKET_CLOSE {
1673                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1674                 m->set_property ("span-direction", scm_from_int (STOP));
1675                 $$ = m->unprotect ();
1676         }
1677         | E_BACKSLASH {
1678                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1679         }
1680         | '|'      {
1681                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1682
1683                 Music *m = unsmob_music (pipe);
1684                 if (m)
1685                 {
1686                         m = m->clone ();
1687                         m->set_spot (@$);
1688                         $$ = m->unprotect ();
1689                 }
1690                 else
1691                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1692
1693         }
1694         | PARTIAL duration_length       {
1695                 $$ = MAKE_SYNTAX ("partial", @$, $2);
1696         }
1697
1698         | TIME_T fraction  {
1699                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1700
1701                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1702         }
1703         | MARK scalar {
1704                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1705         }
1706         ;
1707
1708 command_event:
1709         E_TILDE {
1710                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1711         }
1712         | MARK DEFAULT  {
1713                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1714                 $$ = m->unprotect ();
1715         }
1716         | tempo_event {
1717                 $$ = $1;
1718         }
1719         | KEY DEFAULT {
1720                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1721                 $$ = key->unprotect ();
1722         }
1723         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1724
1725                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1726                 if (scm_ilength ($3) > 0)
1727                 {
1728                         key->set_property ("pitch-alist", $3);
1729                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1730                         key->transpose (* unsmob_pitch ($2));
1731                 } else {
1732                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1733                 }
1734
1735                 $$ = key->unprotect ();
1736         }
1737         ;
1738
1739
1740 post_events:
1741         /* empty */ {
1742                 $$ = SCM_EOL;
1743         }
1744         | post_events post_event {
1745                 unsmob_music ($2)->set_spot (@2);
1746                 $$ = scm_cons ($2, $$);
1747         }
1748         ;
1749
1750 post_event_nofinger:
1751         direction_less_event {
1752                 $$ = $1;
1753         }
1754         | script_dir music_function_event {
1755                 $$ = $2;
1756                 if ($1)
1757                 {
1758                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
1759                 }
1760         }
1761         | HYPHEN {
1762                 if (!PARSER->lexer_->is_lyric_state ())
1763                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1764                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1765         }
1766         | EXTENDER {
1767                 if (!PARSER->lexer_->is_lyric_state ())
1768                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1769                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1770         }
1771         | script_dir direction_reqd_event {
1772                 if ($1)
1773                 {
1774                         Music *m = unsmob_music ($2);
1775                         m->set_property ("direction", scm_from_int ($1));
1776                 }
1777                 $$ = $2;
1778         }
1779         | script_dir direction_less_event {
1780                 if ($1)
1781                 {
1782                         Music *m = unsmob_music ($2);
1783                         m->set_property ("direction", scm_from_int ($1));
1784                 }
1785                 $$ = $2;
1786         }
1787         | string_number_event
1788         ;
1789
1790 post_event:
1791         post_event_nofinger
1792         | script_dir fingering {
1793                 if ($1)
1794                 {
1795                         Music *m = unsmob_music ($2);
1796                         m->set_property ("direction", scm_from_int ($1));
1797                 }
1798                 $$ = $2;
1799         }
1800         ;
1801
1802 string_number_event:
1803         E_UNSIGNED {
1804                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1805                 s->set_property ("string-number", scm_from_int ($1));
1806                 $$ = s->unprotect ();
1807         }
1808         ;
1809
1810 direction_less_char:
1811         '['  {
1812                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1813         }
1814         | ']'  {
1815                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1816         }
1817         | '~'  {
1818                 $$ = ly_symbol2scm ("tildeSymbol");
1819         }
1820         | '('  {
1821                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1822         }
1823         | ')'  {
1824                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1825         }
1826         | E_EXCLAMATION  {
1827                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1828         }
1829         | E_OPEN  {
1830                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1831         }
1832         | E_CLOSE  {
1833                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1834         }
1835         | E_ANGLE_CLOSE  {
1836                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1837         }
1838         | E_ANGLE_OPEN  {
1839                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1840         }
1841         ;
1842
1843 direction_less_event:
1844         direction_less_char {
1845                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1846                 Music *m = 0;
1847                 if (unsmob_music (predefd))
1848                 {
1849                         m = unsmob_music (predefd)->clone ();
1850                         m->set_spot (@$);
1851                 }
1852                 else
1853                 {
1854                         m = MY_MAKE_MUSIC ("Music", @$);
1855                 }
1856                 $$ = m->unprotect ();
1857         }
1858         | EVENT_IDENTIFIER      {
1859                 $$ = $1;
1860         }
1861         | tremolo_type  {
1862                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1863                a->set_property ("tremolo-type", scm_from_int ($1));
1864                $$ = a->unprotect ();
1865         }
1866         ;
1867
1868 direction_reqd_event:
1869         gen_text_def {
1870                 $$ = $1;
1871         }
1872         | script_abbreviation {
1873                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1874                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1875                 if (scm_is_string (s))
1876                         a->set_property ("articulation-type", s);
1877                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1878                 $$ = a->unprotect ();
1879         }
1880         ;
1881
1882 octave_check:
1883         /**/ { $$ = SCM_EOL; }
1884         | '='  { $$ = scm_from_int (0); }
1885         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1886         | '=' sup_quotes { $$ = scm_from_int ($2); }
1887         ;
1888
1889 sup_quotes:
1890         '\'' {
1891                 $$ = 1;
1892         }
1893         | sup_quotes '\'' {
1894                 $$ ++;
1895         }
1896         ;
1897
1898 sub_quotes:
1899         ',' {
1900                 $$ = 1;
1901         }
1902         | sub_quotes ',' {
1903                 $$++;
1904         }
1905         ;
1906
1907 steno_pitch:
1908         NOTENAME_PITCH  {
1909                 $$ = $1;
1910         }
1911         | NOTENAME_PITCH sup_quotes     {
1912                 Pitch p = *unsmob_pitch ($1);
1913                 p = p.transposed (Pitch ($2,0,0));
1914                 $$ = p.smobbed_copy ();
1915         }
1916         | NOTENAME_PITCH sub_quotes      {
1917                 Pitch p =* unsmob_pitch ($1);
1918                 p = p.transposed (Pitch (-$2,0,0));
1919                 $$ = p.smobbed_copy ();
1920         }
1921         ;
1922
1923 /*
1924 ugh. duplication
1925 */
1926
1927 steno_tonic_pitch:
1928         TONICNAME_PITCH {
1929                 $$ = $1;
1930         }
1931         | TONICNAME_PITCH sup_quotes    {
1932                 Pitch p = *unsmob_pitch ($1);
1933                 p = p.transposed (Pitch ($2,0,0));
1934                 $$ = p.smobbed_copy ();
1935         }
1936         | TONICNAME_PITCH sub_quotes     {
1937                 Pitch p = *unsmob_pitch ($1);
1938
1939                 p = p.transposed (Pitch (-$2,0,0));
1940                 $$ = p.smobbed_copy ();
1941         }
1942         ;
1943
1944 pitch:
1945         steno_pitch {
1946                 $$ = $1;
1947         }
1948         ;
1949
1950 pitch_also_in_chords:
1951         pitch
1952         | steno_tonic_pitch
1953         ;
1954
1955 gen_text_def:
1956         full_markup {
1957                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1958                 t->set_property ("text", $1);
1959                 $$ = t->unprotect ();
1960         }
1961         | string {
1962                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1963                 t->set_property ("text",
1964                         make_simple_markup ($1));
1965                 $$ = t->unprotect ();
1966         }
1967         ;
1968
1969 fingering:
1970         UNSIGNED {
1971                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1972                 t->set_property ("digit", scm_from_int ($1));
1973                 $$ = t->unprotect ();
1974         }
1975         ;
1976
1977 script_abbreviation:
1978         '^'             {
1979                 $$ = scm_from_locale_string ("Hat");
1980         }
1981         | '+'           {
1982                 $$ = scm_from_locale_string ("Plus");
1983         }
1984         | '-'           {
1985                 $$ = scm_from_locale_string ("Dash");
1986         }
1987         | '|'           {
1988                 $$ = scm_from_locale_string ("Bar");
1989         }
1990         | ANGLE_CLOSE   {
1991                 $$ = scm_from_locale_string ("Larger");
1992         }
1993         | '.'           {
1994                 $$ = scm_from_locale_string ("Dot");
1995         }
1996         | '_' {
1997                 $$ = scm_from_locale_string ("Underscore");
1998         }
1999         ;
2000
2001 script_dir:
2002         '_'     { $$ = DOWN; }
2003         | '^'   { $$ = UP; }
2004         | '-'   { $$ = CENTER; }
2005         ;
2006
2007
2008 absolute_pitch:
2009         steno_pitch     {
2010                 $$ = $1;
2011         }
2012         ;
2013
2014 duration_length:
2015         multiplied_duration {
2016                 $$ = $1;
2017         }
2018         ;
2019
2020 optional_notemode_duration:
2021         {
2022                 Duration dd = PARSER->default_duration_;
2023                 $$ = dd.smobbed_copy ();
2024         }
2025         | multiplied_duration   {
2026                 $$ = $1;
2027                 PARSER->default_duration_ = *unsmob_duration ($$);
2028         }
2029         ;
2030
2031 steno_duration:
2032         bare_unsigned dots              {
2033                 int len = 0;
2034                 if (!is_duration ($1))
2035                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
2036                 else
2037                         len = intlog2 ($1);
2038
2039                 $$ = Duration (len, $2).smobbed_copy ();
2040         }
2041         | DURATION_IDENTIFIER dots      {
2042                 Duration *d = unsmob_duration ($1);
2043                 Duration k (d->duration_log (), d->dot_count () + $2);
2044                 k = k.compressed (d->factor ());
2045                 *d = k;
2046                 $$ = $1;
2047         }
2048         ;
2049
2050 multiplied_duration:
2051         steno_duration {
2052                 $$ = $1;
2053         }
2054         | multiplied_duration '*' bare_unsigned {
2055                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2056         }
2057         | multiplied_duration '*' FRACTION {
2058                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2059
2060                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2061         }
2062         ;
2063
2064 fraction:
2065         FRACTION { $$ = $1; }
2066         | UNSIGNED '/' UNSIGNED {
2067                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2068         }
2069         ;
2070
2071 dots:
2072         /* empty */     {
2073                 $$ = 0;
2074         }
2075         | dots '.' {
2076                 $$ ++;
2077         }
2078         ;
2079
2080 tremolo_type:
2081         ':'     {
2082                 $$ = 0;
2083         }
2084         | ':' bare_unsigned {
2085                 if (!is_duration ($2))
2086                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2087                 $$ = $2;
2088         }
2089         ;
2090
2091 bass_number:
2092         UNSIGNED {
2093                 $$ = scm_from_int ($1);
2094         }
2095         | STRING { $$ = $1; }
2096         | full_markup { $$ = $1; }
2097         ;
2098
2099 figured_bass_alteration:
2100         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2101         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2102         | '!'   { $$ = scm_from_int (0); }
2103         ;
2104
2105 bass_figure:
2106         FIGURE_SPACE {
2107                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2108                 $$ = bfr->unprotect ();
2109         }
2110         | bass_number  {
2111                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2112                 $$ = bfr->self_scm ();
2113
2114                 if (scm_is_number ($1))
2115                         bfr->set_property ("figure", $1);
2116                 else if (Text_interface::is_markup ($1))
2117                         bfr->set_property ("text", $1);
2118
2119                 bfr->unprotect ();
2120         }
2121         | bass_figure ']' {
2122                 $$ = $1;
2123                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2124         }
2125         | bass_figure figured_bass_alteration {
2126                 Music *m = unsmob_music ($1);
2127                 if (scm_to_double ($2)) {
2128                         SCM salter = m->get_property ("alteration");
2129                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2130                         m->set_property ("alteration",
2131                                          scm_sum (alter, $2));
2132                 } else {
2133                         m->set_property ("alteration", scm_from_int (0));
2134                 }
2135         }
2136         | bass_figure figured_bass_modification  {
2137                 Music *m = unsmob_music ($1);
2138                 if ($2 == ly_symbol2scm ("plus"))
2139                         {
2140                         m->set_property ("augmented", SCM_BOOL_T);
2141                         }
2142                 else if ($2 == ly_symbol2scm ("slash"))
2143                         {
2144                         m->set_property ("diminished", SCM_BOOL_T);
2145                         }
2146                 else if ($2 == ly_symbol2scm ("exclamation"))
2147                         {
2148                         m->set_property ("no-continuation", SCM_BOOL_T);
2149                         }
2150                 else if ($2 == ly_symbol2scm ("backslash"))
2151                         {
2152                         m->set_property ("augmented-slash", SCM_BOOL_T);
2153                         }
2154         }
2155         ;
2156
2157
2158 figured_bass_modification:
2159         E_PLUS          {
2160                 $$ = ly_symbol2scm ("plus");
2161         }
2162         | E_EXCLAMATION {
2163                 $$ = ly_symbol2scm ("exclamation");
2164         }
2165         | '/'           {
2166                 $$ = ly_symbol2scm ("slash");
2167         }
2168         | E_BACKSLASH {
2169                 $$ = ly_symbol2scm ("backslash");
2170         }
2171         ;
2172
2173 br_bass_figure:
2174         bass_figure {
2175                 $$ = $1;
2176         }
2177         | '[' bass_figure {
2178                 $$ = $2;
2179                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2180         }
2181         ;
2182
2183 figure_list:
2184         /**/            {
2185                 $$ = SCM_EOL;
2186         }
2187         | figure_list br_bass_figure {
2188                 $$ = scm_cons ($2, $1);
2189         }
2190         ;
2191
2192 figure_spec:
2193         FIGURE_OPEN figure_list FIGURE_CLOSE {
2194                 $$ = scm_reverse_x ($2, SCM_EOL);
2195         }
2196         ;
2197
2198
2199 optional_rest:
2200         /**/   { $$ = 0; }
2201         | REST { $$ = 1; }
2202         ;
2203
2204 simple_element:
2205         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2206                 if (!PARSER->lexer_->is_note_state ())
2207                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2208
2209                 Music *n = 0;
2210                 if ($6)
2211                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2212                 else
2213                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2214
2215                 n->set_property ("pitch", $1);
2216                 n->set_property ("duration", $5);
2217
2218                 if (scm_is_number ($4))
2219                 {
2220                         int q = scm_to_int ($4);
2221                         n->set_property ("absolute-octave", scm_from_int (q-1));
2222                 }
2223
2224                 if ($3 % 2)
2225                         n->set_property ("cautionary", SCM_BOOL_T);
2226                 if ($2 % 2 || $3 % 2)
2227                         n->set_property ("force-accidental", SCM_BOOL_T);
2228
2229                 $$ = n->unprotect ();
2230         }
2231         | DRUM_PITCH optional_notemode_duration {
2232                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2233                 n->set_property ("duration", $2);
2234                 n->set_property ("drum-type", $1);
2235
2236                 $$ = n->unprotect ();
2237         }
2238         | RESTNAME optional_notemode_duration           {
2239                 Music *ev = 0;
2240                 if (ly_scm2string ($1) == "s") {
2241                         /* Space */
2242                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2243                   }
2244                 else {
2245                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2246
2247                     }
2248                 ev->set_property ("duration", $2);
2249                 $$ = ev->unprotect ();
2250         }
2251         | lyric_element optional_notemode_duration      {
2252                 if (!PARSER->lexer_->is_lyric_state ())
2253                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2254
2255                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2256                 levent->set_property ("text", $1);
2257                 levent->set_property ("duration",$2);
2258                 $$= levent->unprotect ();
2259         }
2260         ;
2261
2262 simple_chord_elements:
2263         simple_element  {
2264                 $$ = scm_list_1 ($1);
2265         }
2266         | new_chord {
2267                 if (!PARSER->lexer_->is_chord_state ())
2268                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2269                 $$ = $1;
2270         }
2271         | figure_spec optional_notemode_duration {
2272                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2273                 {
2274                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2275                 }
2276                 $$ = $1;
2277         }
2278         ;
2279
2280 lyric_element:
2281         lyric_markup {
2282                 $$ = $1;
2283         }
2284         | LYRICS_STRING {
2285                 $$ = $1;
2286         }
2287         ;
2288
2289 new_chord:
2290         steno_tonic_pitch optional_notemode_duration   {
2291                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2292         }
2293         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2294                 SCM its = scm_reverse_x ($4, SCM_EOL);
2295                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2296         }
2297         ;
2298
2299 chord_items:
2300         /**/ {
2301                 $$ = SCM_EOL;
2302         }
2303         | chord_items chord_item {
2304                 $$ = scm_cons ($2, $$);
2305         }
2306         ;
2307
2308 chord_separator:
2309         CHORD_COLON {
2310                 $$ = ly_symbol2scm ("chord-colon");
2311         }
2312         | CHORD_CARET {
2313                 $$ = ly_symbol2scm ("chord-caret");
2314         }
2315         | CHORD_SLASH steno_tonic_pitch {
2316                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2317         }
2318         | CHORD_BASS steno_tonic_pitch {
2319                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2320         }
2321         ;
2322
2323 chord_item:
2324         chord_separator {
2325                 $$ = $1;
2326         }
2327         | step_numbers {
2328                 $$ = scm_reverse_x ($1, SCM_EOL);
2329         }
2330         | CHORD_MODIFIER  {
2331                 $$ = $1;
2332         }
2333         ;
2334
2335 step_numbers:
2336         step_number { $$ = scm_cons ($1, SCM_EOL); }
2337         | step_numbers '.' step_number {
2338                 $$ = scm_cons ($3, $$);
2339         }
2340         ;
2341
2342 step_number:
2343         bare_unsigned {
2344                 $$ = make_chord_step ($1, 0);
2345         }
2346         | bare_unsigned '+' {
2347                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2348         }
2349         | bare_unsigned CHORD_MINUS {
2350                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2351         }
2352         ;
2353
2354 tempo_range:
2355         bare_unsigned {
2356                 $$ = scm_from_int ($1);
2357         }
2358         | bare_unsigned '~' bare_unsigned {
2359                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2360         }
2361         ;
2362
2363 /*
2364         UTILITIES
2365
2366 TODO: should deprecate in favor of Scheme?
2367
2368  */
2369 number_expression:
2370         number_expression '+' number_term {
2371                 $$ = scm_sum ($1, $3);
2372         }
2373         | number_expression '-' number_term {
2374                 $$ = scm_difference ($1, $3);
2375         }
2376         | number_term
2377         ;
2378
2379 number_term:
2380         number_factor {
2381                 $$ = $1;
2382         }
2383         | number_factor '*' number_factor {
2384                 $$ = scm_product ($1, $3);
2385         }
2386         | number_factor '/' number_factor {
2387                 $$ = scm_divide ($1, $3);
2388         }
2389         ;
2390
2391 number_factor:
2392         '-'  number_factor { /* %prec UNARY_MINUS */
2393                 $$ = scm_difference ($2, SCM_UNDEFINED);
2394         }
2395         | bare_number
2396         ;
2397
2398
2399 bare_number:
2400         UNSIGNED        {
2401                 $$ = scm_from_int ($1);
2402         }
2403         | REAL          {
2404                 $$ = $1;
2405         }
2406         | NUMBER_IDENTIFIER             {
2407                 $$ = $1;
2408         }
2409         | REAL NUMBER_IDENTIFIER        {
2410                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2411         }
2412         | UNSIGNED NUMBER_IDENTIFIER    {
2413                 $$ = scm_from_double ($1 *scm_to_double ($2));
2414         }
2415         ;
2416
2417
2418 bare_unsigned:
2419         UNSIGNED {
2420                         $$ = $1;
2421         }
2422         ;
2423
2424 unsigned_number:
2425         bare_unsigned  { $$ = scm_from_int ($1); }
2426         | NUMBER_IDENTIFIER {
2427                 $$ = $1;
2428         }
2429         ;
2430
2431 exclamations:
2432                 { $$ = 0; }
2433         | exclamations '!'      { $$ ++; }
2434         ;
2435
2436 questions:
2437                 { $$ = 0; }
2438         | questions '?' { $$ ++; }
2439         ;
2440
2441 /*
2442 This should be done more dynamically if possible.
2443 */
2444
2445 lyric_markup:
2446         LYRIC_MARKUP_IDENTIFIER {
2447                 $$ = $1;
2448         }
2449         | LYRIC_MARKUP
2450                 { PARSER->lexer_->push_markup_state (); }
2451         markup_top {
2452                 $$ = $3;
2453                 PARSER->lexer_->pop_state ();
2454         }
2455         ;
2456
2457 full_markup_list:
2458         MARKUPLINES_IDENTIFIER {
2459                 $$ = $1;
2460         }
2461         | MARKUPLINES
2462                 { PARSER->lexer_->push_markup_state (); }
2463         markup_list {
2464                 $$ = $3;
2465                 PARSER->lexer_->pop_state ();
2466         }
2467         ;
2468
2469 full_markup:
2470         MARKUP_IDENTIFIER {
2471                 $$ = $1;
2472         }
2473         | MARKUP
2474                 { PARSER->lexer_->push_markup_state (); }
2475         markup_top {
2476                 $$ = $3;
2477                 PARSER->lexer_->pop_state ();
2478         }
2479         ;
2480
2481 markup_top:
2482         markup_list {
2483                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2484         }
2485         | markup_head_1_list simple_markup      {
2486                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2487         }
2488         | simple_markup {
2489                 $$ = $1;
2490         }
2491         ;
2492
2493 markup_list:
2494         MARKUPLINES_IDENTIFIER {
2495                 $$ = $1;
2496         }
2497         | markup_composed_list {
2498                 $$ = $1;
2499         }
2500         | markup_braced_list {
2501                 $$ = $1;
2502         }
2503         | markup_command_list {
2504                 $$ = scm_list_1 ($1);
2505         }
2506         ;
2507
2508 markup_composed_list:
2509         markup_head_1_list markup_braced_list {
2510                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2511
2512         }
2513         ;
2514
2515 markup_braced_list:
2516         '{' markup_braced_list_body '}' {
2517                 $$ = scm_reverse_x ($2, SCM_EOL);
2518         }
2519         ;
2520
2521 markup_braced_list_body:
2522         /* empty */     {  $$ = SCM_EOL; }
2523         | markup_braced_list_body markup {
2524                 $$ = scm_cons ($2, $1);
2525         }
2526         | markup_braced_list_body markup_list {
2527                 $$ = scm_reverse_x ($2, $1);
2528         }
2529         ;
2530
2531 markup_command_list:
2532         MARKUP_LIST_FUNCTION closed_markup_command_list_arguments {
2533           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2534         }
2535         ;
2536
2537 markup_command_basic_arguments:
2538         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2539           $$ = scm_cons ($3, $2);
2540         }
2541         | EXPECT_SCM markup_command_list_arguments closed_embedded_scm {
2542           $$ = scm_cons ($3, $2);
2543         }
2544         | EXPECT_NO_MORE_ARGS {
2545           $$ = SCM_EOL;
2546         }
2547         ;
2548
2549 closed_markup_command_list_arguments:
2550         markup_command_basic_arguments { $$ = $1; }
2551         | EXPECT_MARKUP markup_command_list_arguments markup {
2552           $$ = scm_cons ($3, $2);
2553         }
2554         ;
2555
2556 markup_command_list_arguments:
2557         closed_markup_command_list_arguments
2558         | EXPECT_SCM markup_command_list_arguments open_scm_function_call
2559         {
2560           $$ = scm_cons ($3, $2);
2561         }
2562         ;
2563
2564 markup_head_1_item:
2565         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2566           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2567         }
2568         ;
2569
2570 markup_head_1_list:
2571         markup_head_1_item      {
2572                 $$ = scm_list_1 ($1);
2573         }
2574         | markup_head_1_list markup_head_1_item {
2575                 $$ = scm_cons ($2, $1);
2576         }
2577         ;
2578
2579 simple_markup:
2580         STRING {
2581                 $$ = make_simple_markup ($1);
2582         }
2583         | MARKUP_IDENTIFIER {
2584                 $$ = $1;
2585         }
2586         | LYRIC_MARKUP_IDENTIFIER {
2587                 $$ = $1;
2588         }
2589         | STRING_IDENTIFIER {
2590                 $$ = $1;
2591         }
2592         | SCORE {
2593                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2594                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2595         } '{' score_body '}' {
2596                 Score * sc = $4;
2597                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2598                 sc->unprotect ();
2599                 PARSER->lexer_->pop_state ();
2600         }
2601         | MARKUP_FUNCTION markup_command_basic_arguments {
2602                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2603         }
2604         ;
2605
2606 markup:
2607         markup_head_1_list simple_markup        {
2608                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2609                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2610         }
2611         | simple_markup {
2612                 $$ = $1;
2613         }
2614         ;
2615
2616 %%
2617
2618 void
2619 Lily_parser::set_yydebug (bool x)
2620 {
2621         yydebug = x;
2622 }
2623
2624 void
2625 Lily_parser::do_yyparse ()
2626 {
2627         yyparse ((void*)this);
2628 }
2629
2630
2631
2632
2633
2634 /*
2635
2636 It is a little strange to have this function in this file, but
2637 otherwise, we have to import music classes into the lexer.
2638
2639 */
2640 int
2641 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2642 {
2643         if (scm_is_string (sid)) {
2644                 *destination = sid;
2645                 return STRING_IDENTIFIER;
2646         } else if (unsmob_book (sid)) {
2647                 Book *book =  unsmob_book (sid)->clone ();
2648                 *destination = book->self_scm ();
2649                 book->unprotect ();
2650
2651                 return BOOK_IDENTIFIER;
2652         } else if (scm_is_number (sid)) {
2653                 *destination = sid;
2654                 return NUMBER_IDENTIFIER;
2655         } else if (unsmob_context_def (sid)) {
2656                 Context_def *def= unsmob_context_def (sid)->clone ();
2657
2658                 *destination = def->self_scm ();
2659                 def->unprotect ();
2660
2661                 return CONTEXT_DEF_IDENTIFIER;
2662         } else if (unsmob_context_mod (sid)) {
2663                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2664
2665                 return CONTEXT_MOD_IDENTIFIER;
2666         } else if (unsmob_score (sid)) {
2667                 Score *score = new Score (*unsmob_score (sid));
2668                 *destination = score->self_scm ();
2669
2670                 score->unprotect ();
2671                 return SCORE_IDENTIFIER;
2672         } else if (Music *mus = unsmob_music (sid)) {
2673                 mus = mus->clone ();
2674                 *destination = mus->self_scm ();
2675                 unsmob_music (*destination)->
2676                         set_property ("origin", make_input (last_input_));
2677
2678                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2679                         != SCM_BOOL_F;
2680
2681                 mus->unprotect ();
2682                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2683         } else if (unsmob_duration (sid)) {
2684                 *destination = unsmob_duration (sid)->smobbed_copy ();
2685                 return DURATION_IDENTIFIER;
2686         } else if (unsmob_output_def (sid)) {
2687                 Output_def *p = unsmob_output_def (sid);
2688                 p = p->clone ();
2689
2690                 *destination = p->self_scm ();
2691                 p->unprotect ();
2692                 return OUTPUT_DEF_IDENTIFIER;
2693         } else if (Text_interface::is_markup (sid)) {
2694                 *destination = sid;
2695                 if (is_lyric_state ())
2696                         return LYRIC_MARKUP_IDENTIFIER;
2697                 return MARKUP_IDENTIFIER;
2698         } else if (Text_interface::is_markup_list (sid)) {
2699                 *destination = sid;
2700                 return MARKUPLINES_IDENTIFIER;
2701         }
2702
2703         return -1;
2704 }
2705
2706 SCM
2707 get_next_unique_context_id ()
2708 {
2709         return scm_from_locale_string ("$uniqueContextId");
2710 }
2711
2712
2713 SCM
2714 get_next_unique_lyrics_context_id ()
2715 {
2716         static int new_context_count;
2717         char s[128];
2718         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2719         return scm_from_locale_string (s);
2720 }
2721
2722
2723 SCM
2724 run_music_function (Lily_parser *parser, Input loc, SCM func, SCM args)
2725 {
2726         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2727
2728         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2729
2730         args = scm_reverse_x (args, SCM_EOL);
2731
2732         if (!to_boolean (scm_call_3  (type_check_proc, make_input (loc), scm_cdr (sig), args)))
2733         {
2734                 parser->error_level_ = 1;
2735                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (loc)));
2736         }
2737
2738         SCM syntax_args = scm_list_5 (parser->self_scm (), make_input (loc), scm_car (sig), func, args);
2739         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2740 }
2741
2742 bool
2743 is_regular_identifier (SCM id)
2744 {
2745   string str = ly_scm2string (id);
2746   char const *s = str.c_str ();
2747
2748   bool v = true;
2749 #if 0
2750   isalpha (*s);
2751   s++;
2752 #endif
2753   while (*s && v)
2754    {
2755         v = v && isalnum (*s);
2756         s++;
2757    }
2758   return v;
2759 }
2760
2761 Music *
2762 make_music_with_input (SCM name, Input where)
2763 {
2764        Music *m = make_music_by_name (name);
2765        m->set_spot (where);
2766        return m;
2767 }
2768
2769 SCM
2770 get_first_context_id (SCM type, Music *m)
2771 {
2772         SCM id = m->get_property ("context-id");
2773         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2774             && scm_is_string (m->get_property ("context-id"))
2775             && scm_c_string_length (id) > 0)
2776         {
2777                 return id;
2778         }
2779         return SCM_EOL;
2780 }
2781
2782 SCM
2783 make_simple_markup (SCM a)
2784 {
2785         return a;
2786 }
2787
2788 bool
2789 is_duration (int t)
2790 {
2791   return t && t == 1 << intlog2 (t);
2792 }
2793
2794 void
2795 set_music_properties (Music *p, SCM a)
2796 {
2797   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2798         p->set_property (scm_caar (k), scm_cdar (k));
2799 }
2800
2801
2802 SCM
2803 make_chord_step (int step, Rational alter)
2804 {
2805         if (step == 7)
2806                 alter += FLAT_ALTERATION;
2807
2808         while (step < 0)
2809                 step += 7;
2810         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2811         return m.smobbed_copy ();
2812 }
2813
2814
2815 SCM
2816 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2817 {
2818         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2819         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2820 }
2821
2822
2823 /* Todo: actually also use apply iso. call too ...  */
2824 bool
2825 ly_input_procedure_p (SCM x)
2826 {
2827         return ly_is_procedure (x)
2828                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2829 }
2830
2831 SCM
2832 make_music_relative (Pitch start, SCM music, Input loc)
2833 {
2834         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2835         relative->set_property ("element", music);
2836
2837         Music *m = unsmob_music (music);
2838         Pitch last = m->to_relative_octave (start);
2839         if (lily_1_8_relative)
2840                 m->set_property ("last-pitch", last.smobbed_copy ());
2841         return relative->unprotect ();
2842 }
2843
2844 int
2845 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2846 {
2847         Lily_parser *pars = (Lily_parser*) v;
2848         Lily_lexer *lex = pars->lexer_;
2849
2850         lex->lexval_ = (void*) s;
2851         lex->lexloc_ = loc;
2852         lex->prepare_for_next_token ();
2853         return lex->yylex ();
2854 }