lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token LYRICS_STRING
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token NEWLYRICS
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307 %token MARKUP
 308
 309 /* escaped */
 310 /* FIXME: this sucks.  The user will get to see these names:
 311     syntax error, unexpected E_CHAR:
 312                 \
 313                  %%
 314   */
 315
 316 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 317 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 318 %token E_BACKSLASH
 319 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 320 %token FIGURE_SPACE
 321
 322 %token <i>      DIGIT
 323 %token <i>      UNSIGNED
 324 %token <i> E_UNSIGNED
 325 %token <id>     IDENTIFIER
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DRUM_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    EVENT_IDENTIFIER
 330 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    NUMBER_IDENTIFIER
 333 %token <scm>    OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    RESTNAME
 335 %token <scm>    SCM_T
 336 %token <scm>    SCORE_IDENTIFIER
 337 %token <scm>    STRING
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    TONICNAME_PITCH
 340 %token <scm>    CHORD_MODIFIER
 341 %token <scm>    FRACTION
 342 %token <scm>   REAL
 343 %token <scm> MARKUP_HEAD_EMPTY
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0
 347 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 352 %token <scm> MUSIC_FUNCTION
 353 %token <scm> MUSIC_FUNCTION_MUSIC
 354 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 355 %token <scm> MUSIC_FUNCTION_SCM
 356 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 359 %token DRUMS
 360
 361
 362
 363 %type <book>    book_block book_body
 364 %type <i>       bare_int  bare_unsigned
 365 %type <i>       exclamations questions dots optional_rest
 366 %type <i>       script_dir
 367 %type <i>       sub_quotes sup_quotes
 368 %type <i>       tremolo_type
 369 %type <i>       bass_mod
 370
 371 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 372 %type <music>   Grouped_music_list
 373 %type <music>   Music Sequential_music Simultaneous_music
 374 %type <music>   Repeated_music
 375 %type <music>   command_req
 376 %type <music>   gen_text_def direction_less_event direction_reqd_event
 377 %type <music>   music_property_def context_change
 378 %type <music>   note_chord_element chord_body chord_body_element
 379 %type <music>   open_event close_event
 380 %type <music>   post_event tagged_post_event
 381 %type <music>   relative_music re_rhythmed_music
 382 %type <music>   simple_element event_chord command_element
 383 %type <music>   string_number_event
 384 %type <music>   toplevel_music
 385 %type <music>   tempo_event
 386
 387 %type <outputdef>       output_def_body output_def_head
 388 %type <outputdef> output_def book_paper_block
 389
 390 %type <scm>     Music_list
 391 %type <scm>     chord_body_elements
 392 %type <scm>     chord_item chord_items chord_separator new_chord
 393 %type <scm>     context_def_spec_block context_def_spec_body
 394 %type <scm>     context_mod context_def_mod optional_context_mod
 395 %type <scm>     context_prop_spec
 396 %type <scm>     duration_length fraction
 397 %type <scm>     embedded_scm scalar
 398 %type <scm>     identifier_init
 399 %type <scm>     lilypond_header lilypond_header_body
 400 %type <scm>     new_lyrics
 401 %type <scm>     post_events
 402 %type <scm>     property_operation
 403 %type <scm>     script_abbreviation
 404 %type <scm>     simple_string
 405 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 406 %type <scm>     steno_tonic_pitch
 407 %type <scm>     step_number step_numbers
 408 %type <scm>     string bare_number number_expression number_term number_factor
 409 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 410 %type <scm>     context_mod_list
 411 %type <scm>     octave_check
 412 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 413 %type <scm>     Generic_prefix_music_scm
 414 %type <scm>     lyric_element
 415 %type <scm>     Alternative_music
 416 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 417
 418 %type <score>   score_block score_body
 419
 420
 421 %left '-' '+'
 422
 423 /* We don't assign precedence to / and *, because we might need varied
 424 prec levels in different prods */
 425
 426 %left UNARY_MINUS
 427
 428 %%
 429
 430 lilypond:       /* empty */
 431         | lilypond toplevel_expression {
 432         }
 433         | lilypond assignment {
 434         }
 435         | lilypond error {
 436                 THIS->error_level_ = 1;
 437         }
 438         | lilypond INVALID      {
 439                 THIS->error_level_ = 1;
 440         }
 441         ;
 442
 443 toplevel_expression:
 444         lilypond_header {
 445                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 446         }
 447         | add_quote {
 448
 449         }
 450         | book_block {
 451                 Book *book = $1;
 452                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 453                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 454                 scm_gc_unprotect_object (book->self_scm ());
 455         }
 456         | score_block {
 457                 Score *score = $1;
 458
 459                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 460                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 461                 scm_gc_unprotect_object (score->self_scm ());
 462         }
 463         | toplevel_music {
 464                 Music *music = $1;
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 467                 scm_gc_unprotect_object (music->self_scm ());
 468         }
 469         | output_def {
 470                 SCM id = SCM_EOL;
 471                 Output_def * od = $1;
 472
 473                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultpaper");
 475                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 476                         id = ly_symbol2scm ("$defaultmidi");
 477                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 478                         id = ly_symbol2scm ("$defaultbookpaper");
 479
 480                 THIS->lexer_->set_identifier (id, od->self_scm ());
 481                 scm_gc_unprotect_object (od->self_scm ());
 482         }
 483         ;
 484
 485 toplevel_music:
 486         Composite_music {
 487         }
 488         ;
 489
 490 embedded_scm:
 491         SCM_T
 492         | SCM_IDENTIFIER
 493         ;
 494
 495
 496 lilypond_header_body:
 497         {
 498                 $$ = ly_make_anonymous_module (safe_global_b);
 499                 THIS->lexer_->add_scope ($$);
 500         }
 501         | lilypond_header_body assignment  {
 502
 503         }
 504         ;
 505
 506 lilypond_header:
 507         HEADER '{' lilypond_header_body '}'     {
 508                 $$ = THIS->lexer_->remove_scope ();
 509         }
 510         ;
 511
 512
 513 /*
 514         DECLARATIONS
 515 */
 516 assignment:
 517         STRING {
 518                 THIS->push_spot ();
 519         }
 520         /* cont */ '=' identifier_init  {
 521
 522         /*
 523                 Should find generic way of associating input with objects.
 524         */
 525                 Input ip = THIS->pop_spot ();
 526
 527                 if (! is_regular_identifier ($1))
 528                 {
 529                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 530                 }
 531
 532                 THIS->lexer_->set_identifier ($1, $4);
 533
 534 /*
 535  TODO: devise standard for protection in parser.
 536
 537   The parser stack lives on the C-stack, which means that
 538 all objects can be unprotected as soon as they're here.
 539
 540 */
 541         }
 542         | embedded_scm { }
 543         ;
 544
 545
 546 identifier_init:
 547         score_block {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | full_markup {
 552                 $$ = $1;
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | context_def_spec_block {
 559                 $$ = $1;
 560         }
 561         | Music  {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | post_event {
 566                 $$ = $1->self_scm ();
 567                 scm_gc_unprotect_object ($$);
 568         }
 569         | number_expression {
 570                 $$ = $1;
 571         }
 572         | string {
 573                 $$ = $1;
 574         }
 575         | embedded_scm  {
 576                 $$ = $1;
 577         }
 578         ;
 579
 580 context_def_spec_block:
 581         CONTEXT '{' context_def_spec_body '}'
 582                 {
 583                 $$ = $3;
 584         }
 585         ;
 586
 587 context_def_spec_body:
 588         /**/ {
 589                 $$ = Context_def::make_scm ();
 590                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | CONTEXT_DEF_IDENTIFIER {
 593                 $$ = $1;
 594                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 595         }
 596         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 597                 Context_def*td = unsmob_context_def ($$);
 598
 599                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 600                         SCM tag = ly_caar (p);
 601
 602                         /* TODO: should make new tag "grob-definition" ? */
 603                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 604                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 605                 }
 606         }
 607         | context_def_spec_body context_mod {
 608                 unsmob_context_def ($$)->add_context_mod ($2);
 609         }
 610         ;
 611
 612
 613
 614 book_block:
 615         BOOK {
 616                 THIS->push_spot ();
 617         }
 618         /*cont*/ '{' book_body '}'      {
 619                 THIS->pop_spot ();
 620                 $$ = $4;
 621         }
 622         ;
 623
 624 /* FIXME:
 625    * Use 'handlers' like for toplevel-* stuff?
 626    * grok \paper and \midi?  */
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 632                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 633                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 634         }
 635         | book_body book_paper_block {
 636                 $$->bookpaper_ = $2;
 637                 scm_gc_unprotect_object ($2->self_scm ());
 638         }
 639         | book_body score_block {
 640                 Score *score = $2;
 641                 $$->scores_.push (score);
 642                 scm_gc_unprotect_object (score->self_scm ());
 643         }
 644         | book_body Composite_music {
 645                 Music *music = $2;
 646                 Score *score
 647                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 648                 $$->scores_.push (score);
 649                 scm_gc_unprotect_object (music->self_scm ());
 650         }
 651         | lilypond_header {
 652                 $$->header_ = $1;
 653         }
 654         | book_body error {
 655
 656         }
 657         ;
 658
 659 score_block:
 660         SCORE {
 661                 THIS->push_spot ();
 662         }
 663         /*cont*/ '{' score_body '}'     {
 664                 THIS->pop_spot ();
 665                 $$ = $4;
 666         }
 667         ;
 668
 669 score_body:
 670         Music   {
 671                 $$ = new Score;
 672
 673                 $$->set_spot (THIS->here_input ());
 674                 SCM m = $1->self_scm ();
 675                 scm_gc_unprotect_object (m);
 676
 677                 /*
 678                         guh.
 679                 */
 680                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 681                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 682                         m = scm_call_1 (ly_car (check_funcs), m);
 683                 $$->music_ = m;
 684
 685         }
 686         | SCORE_IDENTIFIER {
 687                 $$ = new Score ( *unsmob_score ($1));
 688                 $$->set_spot (THIS->here_input ());
 689         }
 690         | score_body lilypond_header    {
 691                 $$->header_ = $2;
 692         }
 693         | score_body output_def {
 694                 $$->defs_.push ($2);
 695                 scm_gc_unprotect_object ($2->self_scm ());
 696         }
 697         | score_body error {
 698
 699         }
 700         ;
 701
 702
 703 /*
 704         OUTPUT DEF
 705 */
 706
 707 book_paper_block:
 708         output_def {
 709                 $$ = $1;
 710                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 711                 {
 712                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 713                         $$ = get_bookpaper (THIS);
 714                 }
 715         }
 716         ;
 717
 718
 719 output_def:
 720         output_def_body '}' {
 721                 $$ = $1;
 722                 if ($1->parent_)
 723                         THIS->lexer_->remove_scope ();
 724
 725                 THIS->lexer_->remove_scope ();
 726                 THIS->lexer_->pop_state ();
 727         }
 728         ;
 729
 730 output_def_head:
 731         BOOKPAPER {
 732                 $$ = get_bookpaper (THIS);
 733                 $$->input_origin_ = THIS->here_input ();
 734                 THIS->lexer_->add_scope ($$->scope_);
 735         }
 736         | MIDI    {
 737                 Output_def *p = get_midi (THIS);
 738                 $$ = p;
 739                 THIS->lexer_->add_scope (p->scope_);
 740         }
 741         | PAPER         {
 742                 Output_def* p = get_paper (THIS);
 743
 744                 if (p->parent_)
 745                         THIS->lexer_->add_scope (p->parent_->scope_);
 746
 747                 THIS->lexer_->add_scope (p->scope_);
 748                 $$ = p;
 749         }
 750         ;
 751
 752
 753 output_def_body:
 754         output_def_head '{' {
 755                 $$ = $1;
 756                 $$->input_origin_.set_spot (THIS->here_input ());
 757                 THIS->lexer_->push_initial_state ();
 758         }
 759         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 760                 scm_gc_unprotect_object ($1->self_scm ());
 761                 Output_def *o = unsmob_output_def ($3);
 762                 o->input_origin_.set_spot (THIS->here_input ());
 763                 $$ = o;
 764                 THIS->lexer_->remove_scope ();
 765                 THIS->lexer_->add_scope (o->scope_);
 766                 THIS->lexer_->push_initial_state ();
 767         }
 768         | output_def_body assignment  {
 769
 770         }
 771         | output_def_body context_def_spec_block        {
 772                 assign_context_def ($$, $2);
 773         }
 774         | output_def_body tempo_event  {
 775                 /*
 776                         junk this ? there already is tempo stuff in
 777                         music.
 778                 */
 779                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 780                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 781                 set_tempo ($$, d->get_length (), m);
 782                 scm_gc_unprotect_object ($2->self_scm ());
 783         }
 784         | output_def_body error {
 785
 786         }
 787         ;
 788
 789 tempo_event:
 790         TEMPO steno_duration '=' bare_unsigned  {
 791                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 792                 $$->set_property ("tempo-unit", $2);
 793                 $$->set_property ("metronome-count", scm_int2num ( $4));
 794         }
 795         ;
 796
 797 /*
 798 The representation of a  list is the
 799
 800   (LIST . LAST-CONS)
 801
 802  to have  efficient append.
 803 */
 804 Music_list:
 805         /* empty */ {
 806                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 807         }
 808         | Music_list Music {
 809                 SCM s = $$;
 810                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 811                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 812                 if (ly_c_pair_p (ly_cdr (s)))
 813                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 814                 else
 815                         scm_set_car_x (s, c); /* set first cons */
 816                 scm_set_cdr_x (s, c);  /* remember last cell */
 817         }
 818         | Music_list embedded_scm {
 819         }
 820         | Music_list error {
 821         }
 822         ;
 823
 824
 825 Music:
 826         Simple_music
 827         | Composite_music
 828         ;
 829
 830 Alternative_music:
 831         /* empty */ {
 832                 $$ = SCM_EOL;
 833         }
 834         | ALTERNATIVE '{' Music_list '}' {
 835                 $$ = $3;
 836         }
 837         ;
 838
 839
 840 Repeated_music:
 841         REPEAT simple_string bare_unsigned Music Alternative_music
 842         {
 843                 Music *beg = $4;
 844                 int times = $3;
 845                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 846                 if (times < scm_ilength (alts)) {
 847                   unsmob_music (ly_car (alts))
 848                     ->origin ()->warning (
 849                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 850                   alts = ly_truncate_list (times, alts);
 851                 }
 852
 853
 854                 SCM proc = ly_scheme_function ("make-repeated-music");
 855
 856                 SCM mus = scm_call_1 (proc, $2);
 857                 scm_gc_protect_object (mus); // UGH.
 858                 Music *r = unsmob_music (mus);
 859                 if (beg)
 860                         {
 861                         r-> set_property ("element", beg->self_scm ());
 862                         scm_gc_unprotect_object (beg->self_scm ());
 863                         }
 864                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 865
 866                 r-> set_property ("elements",alts);
 867                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 868                         /*
 869                         TODO: move this code to Scheme.
 870                         */
 871
 872                         /*
 873                         we can not get durations and other stuff correct down the line, so we have to
 874                         add to the duration log here.
 875                         */
 876                         SCM func = ly_scheme_function ("shift-duration-log");
 877
 878                         int dots = ($3 % 3) ? 0 : 1;
 879                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 880
 881                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 882
 883                         if (seq) {
 884                                 int list_len = scm_ilength (seq->music_list ());
 885                                 if (list_len != 2)
 886                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 887                                 shift -= 1;
 888                                 r->compress (Moment (Rational (1, list_len)));
 889                                 }
 890                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 891
 892                 }
 893                 r->set_spot (*$4->origin ());
 894
 895                 $$ = r;
 896         }
 897         ;
 898
 899 Sequential_music:
 900         SEQUENTIAL '{' Music_list '}'           {
 901                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 902                 $$->set_property ("elements", ly_car ($3));
 903                 $$->set_spot (THIS->here_input ());
 904         }
 905         | '{' Music_list '}'            {
 906                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 907                 $$->set_property ("elements", ly_car ($2));
 908                 $$->set_spot (THIS->here_input ());
 909         }
 910         ;
 911
 912 Simultaneous_music:
 913         SIMULTANEOUS '{' Music_list '}'{
 914                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 915                 $$->set_property ("elements", ly_car ($3));
 916                 $$->set_spot (THIS->here_input ());
 917
 918         }
 919         | simul_open Music_list simul_close     {
 920                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 921                 $$->set_property ("elements", ly_car ($2));
 922                 $$->set_spot (THIS->here_input ());
 923         }
 924         ;
 925
 926 Simple_music:
 927         event_chord             { $$ = $1; }
 928         | MUSIC_IDENTIFIER {
 929                 $$ = unsmob_music ($1);
 930         }
 931         | music_property_def
 932         | context_change
 933         ;
 934
 935
 936 optional_context_mod:
 937         /**/ { $$ = SCM_EOL; }
 938         | WITH { THIS->lexer_->push_initial_state (); }
 939         '{' context_mod_list '}'
 940         {
 941                 THIS->lexer_->pop_state ();
 942                 $$ = $4;
 943         }
 944         ;
 945
 946 context_mod_list:
 947         /* */  { $$ = SCM_EOL; }
 948         | context_mod_list context_mod  {
 949                  $$ = scm_cons ($2, $1);
 950         }
 951         ;
 952
 953
 954 Composite_music:
 955         Prefix_composite_music { $$ = $1; }
 956         | Grouped_music_list { $$ = $1; }
 957         ;
 958
 959 Grouped_music_list:
 960         Simultaneous_music              { $$ = $1; }
 961         | Sequential_music              { $$ = $1; }
 962         ;
 963
 964 Generic_prefix_music_scm:
 965         MUSIC_FUNCTION {
 966                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 967         }
 968         | MUSIC_FUNCTION_SCM {
 969                 THIS->push_spot ();
 970         } embedded_scm {
 971                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 972         }
 973         | MUSIC_FUNCTION_MUSIC {
 974                 THIS->push_spot ();
 975         } Music {
 976                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 977                 scm_gc_unprotect_object ($3->self_scm ());
 978         }
 979         | MUSIC_FUNCTION_SCM_MUSIC {
 980                 THIS->push_spot ();
 981         }  embedded_scm Music {
 982                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 983                 scm_gc_unprotect_object ($4->self_scm ());
 984         }
 985         | MUSIC_FUNCTION_MUSIC_MUSIC {
 986                 THIS->push_spot ();
 987         }  Music  Music {
 988                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 989                 scm_gc_unprotect_object ($3->self_scm ());
 990                 scm_gc_unprotect_object ($4->self_scm ());
 991         }
 992         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 993                 THIS->push_spot ();
 994         } embedded_scm Music Music {
 995                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
 996                         $3, $4->self_scm (), $5->self_scm ());
 997                 scm_gc_unprotect_object ($5->self_scm ());
 998                 scm_gc_unprotect_object ($4->self_scm ());
 999         }
1000         ;
1001
1002 Generic_prefix_music:
1003         Generic_prefix_music_scm {
1004                 SCM func = ly_car ($1);
1005                 Input *loc = unsmob_input (ly_cadr ($1));
1006                 SCM args = ly_cddr ($1);
1007                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1008                 int k = 0;
1009                 bool ok  = true;
1010                 for (SCM s = sig, t = args;
1011                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1012                         s = ly_cdr (s), t = ly_cdr (t)) {
1013                         k++;
1014                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1015                         {
1016                                 loc->error (_f ("Argument %d failed typecheck", k));
1017                                 THIS->error_level_ = 1;
1018                                 ok = false;
1019                         }
1020                 }
1021                 SCM m = SCM_EOL;
1022                 if (ok)
1023                         m = scm_apply_0 (func, ly_cdr ($1));
1024                 if (unsmob_music (m))
1025                         {
1026                         $$ = unsmob_music (m);
1027                         scm_gc_protect_object (m);
1028                         }
1029                 else
1030                         {
1031                         if (ok)
1032                                 loc->error (_ ("Music head function should return Music object."));
1033                         $$ = MY_MAKE_MUSIC ("Music");
1034                         }
1035                 $$->set_spot (*loc);
1036         }
1037         ;
1038
1039
1040 Prefix_composite_music:
1041         Generic_prefix_music {
1042                 $$ = $1;
1043         }
1044         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1045                 $$ = context_spec_music ($2, $4, $6, $5);
1046
1047         }
1048         | CONTEXT simple_string optional_context_mod Music {
1049                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1050         }
1051         | NEWCONTEXT simple_string optional_context_mod Music {
1052                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1053                         $3);
1054         }
1055
1056         | TIMES {
1057                 THIS->push_spot ();
1058         }
1059         /* CONTINUED */
1060                 fraction Music
1061
1062         {
1063                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1064                 Music *mp = $4;
1065
1066                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1067                 $$->set_spot (THIS->pop_spot ());
1068
1069                 $$->set_property ("element", mp->self_scm ());
1070                 scm_gc_unprotect_object (mp->self_scm ());
1071                 $$->set_property ("numerator", scm_int2num (n));
1072                 $$->set_property ("denominator", scm_int2num (d));
1073                 $$->compress (Moment (Rational (n,d)));
1074
1075         }
1076         | Repeated_music                { $$ = $1; }
1077         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1078                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1079                 Music *p = $4;
1080                 Pitch from = *unsmob_pitch ($2);
1081                 Pitch to = *unsmob_pitch ($3);
1082
1083                 p->transpose (interval (from, to));
1084                 $$->set_property ("element", p->self_scm ());
1085                 scm_gc_unprotect_object (p->self_scm ());
1086         }
1087         | NOTES
1088                 {
1089                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1090                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1091         }
1092         Music
1093                 { $$ = $3;
1094                   THIS->lexer_->pop_state ();
1095                 }
1096         | DRUMS
1097                 {
1098                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1099                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1100         }
1101         /* FIXME: This used to be: */
1102         Music
1103 /*      Grouped_music_list */
1104                 { $$ = $3;
1105                   THIS->lexer_->pop_state ();
1106                 }
1107         | FIGURES
1108                 { THIS->lexer_->push_figuredbass_state (); }
1109         /* FIXME: This used to be:
1110         Music
1111         but that breaks web build
1112         */
1113         Grouped_music_list
1114                 {
1115                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1116                   chm->set_property ("element", $3->self_scm ());
1117                   $$ = chm;
1118                   scm_gc_unprotect_object ($3->self_scm ());
1119
1120                   THIS->lexer_->pop_state ();
1121         }
1122         | CHORDS {
1123                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1124                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1125                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1126                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1127
1128         }
1129         /* FIXME:
1130         Music
1131 */
1132         Grouped_music_list
1133         {
1134                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1135                   chm->set_property ("element", $3->self_scm ());
1136                   scm_gc_unprotect_object ($3->self_scm ());
1137                   $$ = chm;
1138
1139                   THIS->lexer_->pop_state ();
1140         }
1141         | LYRICS
1142                 { THIS->lexer_->push_lyric_state (); }
1143         /* FIXME:
1144         Music
1145 */
1146         Grouped_music_list
1147                 {
1148                   $$ = $3;
1149                   THIS->lexer_->pop_state ();
1150         }
1151         | relative_music        { $$ = $1; }
1152         | re_rhythmed_music     { $$ = $1; }
1153         | TAG embedded_scm Music {
1154                 tag_music ($3, $2, THIS->here_input ());
1155                 $$ = $3;
1156         }
1157         ;
1158
1159 relative_music:
1160         RELATIVE absolute_pitch Music {
1161                 Music *m = $3;
1162                 Pitch start = *unsmob_pitch ($2);
1163                 $$ = make_music_relative (start, m);
1164                 scm_gc_unprotect_object (m->self_scm ());
1165         }
1166         | RELATIVE Composite_music {
1167                 Music *m = $2;
1168                 /* FIXME: why is octave==0 and default not middleC? */
1169                 Pitch middle_c (-1, 0, 0);
1170                 $$ = make_music_relative (middle_c, m);
1171                 scm_gc_unprotect_object (m->self_scm ());
1172         }
1173         ;
1174
1175 new_lyrics:
1176         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1177         /*cont */
1178         Grouped_music_list {
1179         /* Can also use Music at the expensive of two S/Rs similar to
1180            \repeat \alternative */
1181                 THIS->lexer_->pop_state ();
1182 #if 0
1183                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1184                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1185                 $$ = music;
1186 #else
1187                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1188 #endif
1189         }
1190         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1191         Grouped_music_list {
1192                 THIS->lexer_->pop_state ();
1193                 $$ = scm_cons ($4->self_scm (), $1);
1194         }
1195         ;
1196
1197 re_rhythmed_music:
1198         Grouped_music_list new_lyrics {
1199
1200                 /* FIXME: should find out uniqueXXX name from music */
1201                 SCM name = $1->get_property ("context-id");
1202                 //if (name == SCM_EOL)
1203                 if (!ly_c_string_p (name))
1204                         name = scm_makfrom0str ("");
1205
1206                 SCM context = scm_makfrom0str ("Lyrics");
1207                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1208
1209                 SCM lst = SCM_EOL;
1210                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1211                 {
1212                         Music *music = unsmob_music (ly_car (s));
1213                         Music *com = make_lyric_combine_music (name, music);
1214                         Music *csm = context_spec_music (context,
1215                                 get_next_unique_context (), com, SCM_EOL);
1216                         lst = scm_cons (csm->self_scm (), lst);
1217                 }
1218                 /* FIXME: only first lyric music is accepted,
1219                           the rest is junked */
1220                 all->set_property ("elements", scm_cons ($1->self_scm (),
1221                         lst));
1222                 $$ = all;
1223                 scm_gc_unprotect_object ($1->self_scm ());
1224         }
1225         | LYRICSTO string Music {
1226                 Music *music = $3;
1227                 SCM name = $2;
1228                 $$ = make_lyric_combine_music (name, music);
1229                 scm_gc_unprotect_object (music->self_scm ());
1230         }
1231         ;
1232
1233 context_change:
1234         CHANGE STRING '=' STRING  {
1235                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1236                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1237                 t-> set_property ("change-to-id", $4);
1238
1239                 $$ = t;
1240                 $$->set_spot (THIS->here_input ());
1241         }
1242         ;
1243
1244 property_operation:
1245         STRING '=' scalar {
1246                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1247                         scm_string_to_symbol ($1), $3);
1248         }
1249         | UNSET simple_string {
1250                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1251                         scm_string_to_symbol ($2));
1252         }
1253         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1254                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1255                         scm_string_to_symbol ($2), $3, $5);
1256         }
1257         | REVERT simple_string embedded_scm {
1258                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1259                         scm_string_to_symbol ($2), $3);
1260         }
1261         ;
1262
1263 context_def_mod:
1264         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1265         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1266         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1267
1268         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1269         | DENIES { $$ = ly_symbol2scm ("denies"); }
1270
1271         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1272         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1273         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1274         | NAME { $$ = ly_symbol2scm ("context-name"); }
1275         ;
1276
1277 context_mod:
1278         property_operation { $$ = $1; }
1279         | context_def_mod STRING {
1280                 $$ = scm_list_2 ($1, $2);
1281         }
1282         ;
1283
1284 context_prop_spec:
1285         simple_string {
1286                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1287                         scm_string_to_symbol ($1));
1288         }
1289         | simple_string '.' simple_string {
1290                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1291                         scm_string_to_symbol ($3));
1292         }
1293         ;
1294
1295 music_property_def:
1296         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1297                 $$ = property_op_to_music (scm_list_4 (
1298                         ly_symbol2scm ("poppush"),
1299                         ly_cadr ($2),
1300                         $3, $5));
1301                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1302         }
1303         | REVERT context_prop_spec embedded_scm {
1304                 $$ = property_op_to_music (scm_list_3 (
1305                         ly_symbol2scm ("pop"),
1306                         ly_cadr ($2),
1307                         $3));
1308
1309                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1310         }
1311         | SET context_prop_spec '=' scalar {
1312                 $$ = property_op_to_music (scm_list_3 (
1313                         ly_symbol2scm ("assign"),
1314                         ly_cadr ($2),
1315                         $4));
1316                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1317         }
1318         | UNSET context_prop_spec {
1319                 $$ = property_op_to_music (scm_list_2 (
1320                         ly_symbol2scm ("unset"),
1321                         ly_cadr ($2)));
1322                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1323         }
1324         | ONCE music_property_def {
1325                 SCM e = $2->get_property ("element");
1326                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1327                 $$ = $2;
1328
1329         }
1330         ;
1331
1332
1333 string:
1334         STRING {
1335                 $$ = $1;
1336         }
1337         | STRING_IDENTIFIER {
1338                 $$ = $1;
1339         }
1340         | string '+' string {
1341                 $$ = scm_string_append (scm_list_2 ($1, $3));
1342         }
1343         ;
1344
1345 simple_string: STRING {
1346         }
1347         | LYRICS_STRING {
1348         }
1349         ;
1350
1351 scalar: string {
1352         }
1353         | LYRICS_STRING {
1354         }
1355         | bare_int {
1356                 $$ = scm_int2num ($1);
1357         }
1358         | embedded_scm {
1359         }
1360         | full_markup {
1361         }
1362         | DIGIT {
1363                 $$ = scm_int2num ($1);
1364         }
1365         ;
1366
1367 /*
1368 FIXME: remove or fix this comment.  What is `This'?
1369
1370 This is a trick:
1371
1372 Adding pre_events to the simple_element
1373 makes the choice between
1374
1375   string:  STRING
1376
1377 and
1378
1379   simple_element: STRING
1380
1381 a single shift/reduction conflict.
1382
1383 nevertheless, this is not very clean, and we should find a different
1384 solution.
1385
1386 */
1387 pre_events: {
1388                 THIS->push_spot ();
1389         }
1390         ;
1391
1392 event_chord:
1393         pre_events simple_element post_events   {
1394                 SCM elts = $2-> get_property ("elements");
1395
1396                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1397
1398                 $2->set_property ("elements", elts);
1399                 $$ = $2;
1400         }
1401         | command_element
1402         | note_chord_element
1403         ;
1404
1405
1406 note_chord_element:
1407         chord_body optional_notemode_duration post_events
1408         {
1409                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1410                 SCM es = $1->get_property ("elements");
1411                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1412
1413                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1414                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1415                 es = ly_append2 (es, postevs);
1416
1417                 $1-> set_property ("elements", es);
1418                 $$ = $1;
1419         }
1420         ;
1421
1422 chord_open: '<'
1423         ;
1424
1425 chord_close: '>'
1426         ;
1427
1428 simul_open: DOUBLE_ANGLE_OPEN
1429         ;
1430
1431 simul_close: DOUBLE_ANGLE_CLOSE
1432         ;
1433
1434 chord_body:
1435         chord_open chord_body_elements chord_close
1436         {
1437                 $$ = MY_MAKE_MUSIC ("EventChord");
1438                 $$->set_property ("elements",
1439                         scm_reverse_x ($2, SCM_EOL));
1440         }
1441         ;
1442
1443 chord_body_elements:
1444         /* empty */             { $$ = SCM_EOL; }
1445         | chord_body_elements chord_body_element {
1446                 $$ = scm_cons ($2->self_scm (), $1);
1447                 scm_gc_unprotect_object ($2->self_scm ());
1448         }
1449         ;
1450
1451 chord_body_element:
1452         pitch exclamations questions post_events
1453         {
1454                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1455                 n->set_property ("pitch", $1);
1456                 if ($3 % 2)
1457                         n->set_property ("cautionary", SCM_BOOL_T);
1458                 if ($2 % 2 || $3 % 2)
1459                         n->set_property ("force-accidental", SCM_BOOL_T);
1460
1461                 if (ly_c_pair_p ($4)) {
1462                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1463                         n->set_property ("articulations", arts);
1464                 }
1465                 $$ = n;
1466         }
1467         | DRUM_PITCH post_events {
1468                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1469                 n->set_property ("duration", $2);
1470                 n->set_property ("drum-type", $1);
1471                 n->set_spot (THIS->here_input ());
1472
1473                 if (ly_c_pair_p ($2)) {
1474                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1475                         n->set_property ("articulations", arts);
1476                 }
1477                 $$ = n;
1478         }
1479         ;
1480
1481 add_quote:
1482         ADDQUOTE string Music {
1483                 SCM adder = ly_scheme_function ("add-quotable");
1484
1485                 scm_call_2 (adder, $2, $3->self_scm ());
1486                 scm_gc_unprotect_object ($3->self_scm ());
1487         }
1488         ;
1489
1490 command_element:
1491         command_req {
1492                 $$ = MY_MAKE_MUSIC ("EventChord");
1493                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1494                 scm_gc_unprotect_object ($1->self_scm ());
1495
1496                 $$-> set_spot (THIS->here_input ());
1497                 $1-> set_spot (THIS->here_input ());
1498         }
1499         | SKIP duration_length {
1500                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1501                 skip->set_property ("duration", $2);
1502
1503                 $$ = skip;
1504         }
1505         | QUOTE STRING duration_length {
1506                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1507                 SCM evs = SCM_EOL;
1508                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1509                 {
1510                         SCM key = $2; // use symbol?
1511                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1512                 }
1513                 Music *quote = 0;
1514                 if (ly_c_vector_p (evs))
1515                 {
1516                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1517                         quote->set_property ("duration", $3);
1518                         quote->set_property ("quoted-events", evs);
1519                 } else {
1520                         THIS->here_input ().warning (_f ("Can\'t find music"));
1521                         quote = MY_MAKE_MUSIC ("Event");
1522                 }
1523                 quote->set_spot (THIS->here_input ());
1524                 $$ = quote;
1525         }
1526         | OCTAVE { THIS->push_spot (); }
1527           pitch {
1528                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1529                 $$ = m;
1530                 $$->set_spot (THIS->pop_spot ());
1531                 $$->set_property ("pitch", $3);
1532         }
1533         | E_LEFTSQUARE {
1534                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1535                 m->set_property ("span-direction", scm_int2num (START));
1536                 m->set_spot (THIS->here_input ());
1537
1538                 $$ = MY_MAKE_MUSIC ("EventChord");
1539                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1540                 scm_gc_unprotect_object (m->self_scm ());
1541                 $$->set_spot (THIS->here_input ());
1542         }
1543         | E_RIGHTSQUARE {
1544                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1545                 m->set_property ("span-direction", scm_int2num (STOP));
1546                 m->set_spot (THIS->here_input ());
1547
1548                 $$ = MY_MAKE_MUSIC ("EventChord");
1549                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1550                 $$->set_spot (THIS->here_input ());
1551                 scm_gc_unprotect_object (m->self_scm ());
1552         }
1553         | E_BACKSLASH {
1554                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1555                 $$->set_spot (THIS->here_input ());
1556         }
1557         | '|'      {
1558                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1559
1560                 if (Music * m = unsmob_music (pipe))
1561                         $$ = m->clone ();
1562                 else
1563                         $$ = MY_MAKE_MUSIC ("BarCheck");
1564
1565                 $$->set_spot (THIS->here_input ());
1566         }
1567         | TRANSPOSITION pitch {
1568                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1569                                         $2);
1570                 $$->set_spot (THIS-> here_input ());
1571                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1572                         $$, SCM_EOL);
1573         }
1574         | BAR STRING                    {
1575                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1576
1577                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1578                                         t, SCM_EOL);
1579                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1580                 $$->set_spot (THIS->here_input ());
1581                 t->set_spot (THIS->here_input ());
1582         }
1583         | PARTIAL duration_length       {
1584                 Moment m = - unsmob_duration ($2)->get_length ();
1585                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1586                 p->set_spot (THIS->here_input ());
1587                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1588                                         p, SCM_EOL);
1589                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1590                                         p, SCM_EOL);
1591                 $$ = p;
1592         }
1593         | CLEF STRING  {
1594                 SCM proc = ly_scheme_function ("make-clef-set");
1595
1596                 SCM result = scm_call_1 (proc, $2);
1597                 scm_gc_protect_object (result);
1598                 $$ = unsmob_music (result);
1599         }
1600         | TIME_T fraction  {
1601                 SCM proc= ly_scheme_function ("make-time-signature-set");
1602
1603                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1604                 scm_gc_protect_object (result);
1605                 $$ = unsmob_music (result);
1606         }
1607         | MARK scalar {
1608                 SCM proc = ly_scheme_function ("make-mark-set");
1609
1610                 SCM result = scm_call_1 (proc, $2);
1611                 scm_gc_protect_object (result);
1612                 $$ = unsmob_music (result);
1613         }
1614         ;
1615
1616 command_req:
1617         E_TILDE {
1618                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1619         }
1620         | MARK DEFAULT  {
1621                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1622                 $$ = m;
1623         }
1624         | tempo_event {
1625                 $$ = $1;
1626         }
1627         | KEY DEFAULT {
1628                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1629                 $$ = key;
1630         }
1631         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1632
1633                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1634                 if (scm_ilength ($3) > 0)
1635                 {
1636                         key->set_property ("pitch-alist", $3);
1637                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1638                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1639                 } else {
1640                         THIS->parser_error (_ ("Second argument must be pitch list."));
1641                 }
1642
1643                 $$ = key;
1644         }
1645         ;
1646
1647 post_events:
1648         /* empty */ {
1649                 $$ = SCM_EOL;
1650         }
1651         | post_events post_event {
1652                 $2->set_spot (THIS->here_input ());
1653                 $$ = scm_cons ($2->self_scm (), $$);
1654                 scm_gc_unprotect_object ($2->self_scm ());
1655         }
1656         | post_events tagged_post_event {
1657                 $2 -> set_spot (THIS->here_input ());
1658                 $$ = scm_cons ($2->self_scm (), $$);
1659                 scm_gc_unprotect_object ($2->self_scm ());
1660         }
1661         ;
1662
1663
1664 tagged_post_event:
1665         '-' TAG embedded_scm post_event {
1666                 tag_music ($4, $3, THIS->here_input ());
1667                 $$ = $4;
1668         }
1669         ;
1670
1671 post_event:
1672         direction_less_event {
1673                 $$ = $1;
1674         }
1675         | HYPHEN {
1676                 if (!THIS->lexer_->is_lyric_state ())
1677                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1678                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1679         }
1680         | EXTENDER {
1681                 if (!THIS->lexer_->is_lyric_state ())
1682                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1683                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1684         }
1685         | script_dir direction_reqd_event {
1686                 if ($1)
1687                         $2->set_property ("direction", scm_int2num ($1));
1688                 $$ = $2;
1689         }
1690         | script_dir direction_less_event {
1691                 if ($1)
1692                         $2->set_property ("direction", scm_int2num ($1));
1693                 $$ = $2;
1694         }
1695         | string_number_event
1696         ;
1697
1698 string_number_event:
1699         E_UNSIGNED {
1700                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1701                 s->set_property ("string-number", scm_int2num ($1));
1702                 s->set_spot (THIS->here_input ());
1703                 $$ = s;
1704         }
1705         ;
1706
1707
1708 direction_less_event:
1709         '['  {
1710
1711
1712 /*
1713
1714 TODO: should take all these defs out of the parser, adn make use
1715 configurable, i.e.
1716
1717
1718 (set-articulation '~ "trill")
1719
1720 */
1721                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1722                 m->set_spot (THIS->here_input ());
1723                 m->set_property ("span-direction", scm_int2num (START));
1724                 $$ = m;
1725         }
1726         | ']'  {
1727                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1728                 m->set_spot (THIS->here_input ());
1729                 m->set_property ("span-direction", scm_int2num (STOP));
1730                 $$ = m;
1731         }
1732         | '~' {
1733                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1734                 m->set_spot (THIS->here_input ());
1735                 $$ = m;
1736         }
1737         | close_event {
1738                 $$ = $1;
1739                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1740                         scm_int2num (START));
1741         }
1742         | open_event {
1743                 $$ = $1;
1744                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1745                         scm_int2num (STOP));
1746         }
1747         | EVENT_IDENTIFIER      {
1748                 $$ = unsmob_music ($1);
1749         }
1750         | tremolo_type  {
1751                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1752                a->set_spot (THIS->here_input ());
1753                a->set_property ("tremolo-type", scm_int2num ($1));
1754                $$ = a;
1755         }
1756         ;
1757
1758 direction_reqd_event:
1759         gen_text_def {
1760                 $$ = $1;
1761         }
1762         | script_abbreviation {
1763                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1764                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1765                 if (ly_c_string_p (s))
1766                         a->set_property ("articulation-type", s);
1767                 else THIS->parser_error (_ ("Expecting string as script definition"));
1768                 $$ = a;
1769         }
1770         ;
1771
1772 octave_check:
1773         /**/ { $$ = SCM_EOL; }
1774         | '='  { $$ = scm_int2num (0); }
1775         | '=' sub_quotes { $$ = scm_int2num ($2); }
1776         | '=' sup_quotes { $$ = scm_int2num ($2); }
1777         ;
1778
1779 sup_quotes:
1780         '\'' {
1781                 $$ = 1;
1782         }
1783         | sup_quotes '\'' {
1784                 $$ ++;
1785         }
1786         ;
1787
1788 sub_quotes:
1789         ',' {
1790                 $$ = 1;
1791         }
1792         | sub_quotes ',' {
1793                 $$++;
1794         }
1795         ;
1796
1797 steno_pitch:
1798         NOTENAME_PITCH  {
1799                 $$ = $1;
1800         }
1801         | NOTENAME_PITCH sup_quotes     {
1802                 Pitch p = *unsmob_pitch ($1);
1803                 p = p.transposed (Pitch ($2,0,0));
1804                 $$ = p.smobbed_copy ();
1805         }
1806         | NOTENAME_PITCH sub_quotes      {
1807                 Pitch p =* unsmob_pitch ($1);
1808                 p = p.transposed (Pitch (-$2,0,0));
1809                 $$ = p.smobbed_copy ();
1810         }
1811         ;
1812
1813 /*
1814 ugh. duplication
1815 */
1816
1817 steno_tonic_pitch:
1818         TONICNAME_PITCH {
1819                 $$ = $1;
1820         }
1821         | TONICNAME_PITCH sup_quotes    {
1822                 Pitch p = *unsmob_pitch ($1);
1823                 p = p.transposed (Pitch ($2,0,0));
1824                 $$ = p.smobbed_copy ();
1825         }
1826         | TONICNAME_PITCH sub_quotes     {
1827                 Pitch p =* unsmob_pitch ($1);
1828
1829                 p = p.transposed (Pitch (-$2,0,0));
1830                 $$ = p.smobbed_copy ();
1831         }
1832         ;
1833
1834 pitch:
1835         steno_pitch {
1836                 $$ = $1;
1837         }
1838         ;
1839
1840 pitch_also_in_chords:
1841         pitch
1842         | steno_tonic_pitch
1843         ;
1844
1845 close_event:
1846         '('     {
1847                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1848                 $$ = s;
1849                 s->set_spot (THIS->here_input ());
1850         }
1851         | E_OPEN        {
1852                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1853                 $$ = s;
1854                 s->set_spot (THIS->here_input ());
1855         }
1856         | E_SMALLER {
1857                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1858                 $$ = s;
1859                 s->set_spot (THIS->here_input ());
1860         }
1861         | E_BIGGER {
1862                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1863                 $$ = s;
1864                 s->set_spot (THIS->here_input ());
1865         }
1866         ;
1867
1868
1869 open_event:
1870         E_EXCLAMATION   {
1871                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1872                 s->set_spot (THIS->here_input ());
1873
1874                 $$ = s;
1875         }
1876         | ')'   {
1877                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1878                 $$ = s;
1879                 s->set_spot (THIS->here_input ());
1880
1881         }
1882         | E_CLOSE       {
1883                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1884                 $$ = s;
1885                 s->set_property ("span-type",
1886                         scm_makfrom0str ("phrasing-slur"));
1887                 s->set_spot (THIS->here_input ());
1888         }
1889         ;
1890
1891 gen_text_def:
1892         full_markup {
1893                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1894                 t->set_property ("text", $1);
1895                 t->set_spot (THIS->here_input ());
1896                 $$ = t;
1897         }
1898         | string {
1899                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1900                 t->set_property ("text",
1901                         make_simple_markup (THIS->lexer_->encoding (), $1));
1902                 t->set_spot (THIS->here_input ());
1903                 $$ = t;
1904
1905         }
1906         | DIGIT {
1907                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1908                 t->set_property ("digit", scm_int2num ($1));
1909                 t->set_spot (THIS->here_input ());
1910                 $$ = t;
1911         }
1912         ;
1913
1914 script_abbreviation:
1915         '^'             {
1916                 $$ = scm_makfrom0str ("Hat");
1917         }
1918         | '+'           {
1919                 $$ = scm_makfrom0str ("Plus");
1920         }
1921         | '-'           {
1922                 $$ = scm_makfrom0str ("Dash");
1923         }
1924         | '|'           {
1925                 $$ = scm_makfrom0str ("Bar");
1926         }
1927         | '>'           {
1928                 $$ = scm_makfrom0str ("Larger");
1929         }
1930         | '.'           {
1931                 $$ = scm_makfrom0str ("Dot");
1932         }
1933         | '_' {
1934                 $$ = scm_makfrom0str ("Underscore");
1935         }
1936         ;
1937
1938 script_dir:
1939         '_'     { $$ = DOWN; }
1940         | '^'   { $$ = UP; }
1941         | '-'   { $$ = CENTER; }
1942         ;
1943
1944
1945 absolute_pitch:
1946         steno_pitch     {
1947                 $$ = $1;
1948         }
1949         ;
1950
1951 duration_length:
1952         multiplied_duration {
1953                 $$ = $1;
1954         }
1955         ;
1956
1957 optional_notemode_duration:
1958         {
1959                 Duration dd = THIS->default_duration_;
1960                 $$ = dd.smobbed_copy ();
1961
1962                 THIS->beam_check ($$);
1963         }
1964         | multiplied_duration   {
1965                 $$ = $1;
1966                 THIS->default_duration_ = *unsmob_duration ($$);
1967
1968                 THIS->beam_check ($$);
1969         }
1970         ;
1971
1972 steno_duration:
1973         bare_unsigned dots              {
1974                 int len = 0;
1975                 if (!is_duration ($1))
1976                         THIS->parser_error (_f ("not a duration: %d", $1));
1977                 else
1978                         len = intlog2 ($1);
1979
1980                 $$ = Duration (len, $2).smobbed_copy ();
1981         }
1982         | DURATION_IDENTIFIER dots      {
1983                 Duration *d = unsmob_duration ($1);
1984                 Duration k (d->duration_log (), d->dot_count () + $2);
1985                 *d = k;
1986                 $$ = $1;
1987         }
1988         ;
1989
1990 multiplied_duration:
1991         steno_duration {
1992                 $$ = $1;
1993         }
1994         | multiplied_duration '*' bare_unsigned {
1995                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1996         }
1997         | multiplied_duration '*' FRACTION {
1998                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1999
2000                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2001         }
2002         ;
2003
2004 fraction:
2005         FRACTION { $$ = $1; }
2006         | UNSIGNED '/' UNSIGNED {
2007                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2008         }
2009         ;
2010
2011 dots:
2012         /* empty */     {
2013                 $$ = 0;
2014         }
2015         | dots '.' {
2016                 $$ ++;
2017         }
2018         ;
2019
2020 tremolo_type:
2021         ':'     {
2022                 $$ = 0;
2023         }
2024         | ':' bare_unsigned {
2025                 if (!is_duration ($2))
2026                         THIS->parser_error (_f ("not a duration: %d", $2));
2027                 $$ = $2;
2028         }
2029         ;
2030
2031 bass_number:
2032         DIGIT   {
2033                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2034                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2035                                 $$);
2036         }
2037         | UNSIGNED {
2038                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2039                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2040                                 $$);
2041         }
2042         | STRING { $$ = $1; }
2043         ;
2044
2045 bass_mod:
2046         '-'     { $$ = -2; }
2047         | '+'   { $$ = 2; }
2048         | '!'   { $$ = 0; }
2049         ;
2050
2051 bass_figure:
2052         FIGURE_SPACE {
2053                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2054                 $$ = bfr->self_scm ();
2055                 scm_gc_unprotect_object ($$);
2056         }
2057         | bass_number  {
2058                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2059                 $$ = bfr->self_scm ();
2060
2061                 bfr->set_property ("figure", $1);
2062
2063                 scm_gc_unprotect_object ($$);
2064         }
2065         | bass_figure bass_mod {
2066                 Music *m = unsmob_music ($1);
2067                 if ($2) {
2068                         SCM salter = m->get_property ("alteration");
2069                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2070                         m->set_property ("alteration",
2071                                 scm_int2num (alter + $2));
2072                 } else {
2073                         m->set_property ("alteration", scm_int2num (0));
2074                 }
2075         }
2076         ;
2077
2078 br_bass_figure:
2079         '[' bass_figure {
2080                 $$ = $2;
2081                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2082         }
2083         | bass_figure   {
2084                 $$ = $1;
2085         }
2086         | br_bass_figure ']' {
2087                 $$ = $1;
2088                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2089         }
2090         ;
2091
2092 figure_list:
2093         /**/            {
2094                 $$ = SCM_EOL;
2095         }
2096         | figure_list br_bass_figure {
2097                 $$ = scm_cons ($2, $1);
2098         }
2099         ;
2100
2101 figure_spec:
2102         FIGURE_OPEN figure_list FIGURE_CLOSE {
2103                 Music *m = MY_MAKE_MUSIC ("EventChord");
2104                 $2 = scm_reverse_x ($2, SCM_EOL);
2105                 m->set_property ("elements", $2);
2106                 $$ = m->self_scm ();
2107         }
2108         ;
2109
2110
2111 optional_rest:
2112         /**/   { $$ = 0; }
2113         | REST { $$ = 1; }
2114         ;
2115
2116 simple_element:
2117         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2118
2119                 Input i = THIS->pop_spot ();
2120                 if (!THIS->lexer_->is_note_state ())
2121                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2122
2123                 Music *n = 0;
2124                 if ($6)
2125                         n = MY_MAKE_MUSIC ("RestEvent");
2126                 else
2127                         n = MY_MAKE_MUSIC ("NoteEvent");
2128
2129                 n->set_property ("pitch", $1);
2130                 n->set_property ("duration", $5);
2131
2132                 if (ly_c_number_p ($4))
2133                 {
2134                         int q = ly_scm2int ($4);
2135                         n->set_property ("absolute-octave", scm_int2num (q-1));
2136                 }
2137
2138                 if ($3 % 2)
2139                         n->set_property ("cautionary", SCM_BOOL_T);
2140                 if ($2 % 2 || $3 % 2)
2141                         n->set_property ("force-accidental", SCM_BOOL_T);
2142
2143                 Music *v = MY_MAKE_MUSIC ("EventChord");
2144                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2145                 scm_gc_unprotect_object (n->self_scm ());
2146
2147                 v->set_spot (i);
2148                 n->set_spot (i);
2149                 $$ = v;
2150         }
2151         | DRUM_PITCH optional_notemode_duration {
2152                 Input i = THIS->pop_spot ();
2153
2154                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2155                 n->set_property ("duration", $2);
2156                 n->set_property ("drum-type", $1);
2157
2158                 Music *v = MY_MAKE_MUSIC ("EventChord");
2159                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2160                 scm_gc_unprotect_object (n->self_scm ());
2161                 v->set_spot (i);
2162                 n->set_spot (i);
2163                 $$ = v;
2164
2165         }
2166         | figure_spec optional_notemode_duration {
2167                 Music *m = unsmob_music ($1);
2168                 Input i = THIS->pop_spot ();
2169                 m->set_spot (i);
2170                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2171                 {
2172                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2173                 }
2174                 $$ = m;
2175         }
2176         | RESTNAME optional_notemode_duration           {
2177
2178                 Input i = THIS->pop_spot ();
2179                 Music *ev = 0;
2180                 if (ly_scm2string ($1) == "s") {
2181                         /* Space */
2182                         ev = MY_MAKE_MUSIC ("SkipEvent");
2183                   }
2184                 else {
2185                         ev = MY_MAKE_MUSIC ("RestEvent");
2186
2187                     }
2188                 ev->set_property ("duration", $2);
2189                 ev->set_spot (i);
2190                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2191                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2192                 velt->set_spot (i);
2193
2194                 scm_gc_unprotect_object (ev->self_scm ());
2195
2196                 $$ = velt;
2197         }
2198         | MULTI_MEASURE_REST optional_notemode_duration         {
2199                 THIS->pop_spot ();
2200
2201                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2202                 SCM mus = scm_call_2 (proc, $2,
2203                         make_input (THIS->here_input ()));
2204                 scm_gc_protect_object (mus);
2205                 $$ = unsmob_music (mus);
2206         }
2207
2208         | lyric_element optional_notemode_duration      {
2209                 Input i = THIS->pop_spot ();
2210                 if (!THIS->lexer_->is_lyric_state ())
2211                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2212
2213                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2214                 lreq->set_property ("text", $1);
2215                 lreq->set_property ("duration",$2);
2216                 lreq->set_spot (i);
2217                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2218                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2219
2220                 $$= velt;
2221         }
2222         | new_chord {
2223                 THIS->pop_spot ();
2224
2225                 if (!THIS->lexer_->is_chord_state ())
2226                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2227                 $$ = unsmob_music ($1);
2228         }
2229         ;
2230
2231 lyric_element:
2232         /* FIXME: lyric flavoured markup would be better */
2233         full_markup {
2234         }
2235         | LYRICS_STRING {
2236         }
2237         ;
2238
2239 new_chord:
2240         steno_tonic_pitch optional_notemode_duration   {
2241                 $$ = make_chord ($1, $2, SCM_EOL);
2242         }
2243         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2244                 SCM its = scm_reverse_x ($4, SCM_EOL);
2245                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2246         }
2247         ;
2248
2249 chord_items:
2250         /**/ {
2251                 $$ = SCM_EOL;
2252         }
2253         | chord_items chord_item {
2254                 $$ = scm_cons ($2, $$);
2255         }
2256         ;
2257
2258 chord_separator:
2259         CHORD_COLON {
2260                 $$ = ly_symbol2scm ("chord-colon");
2261         }
2262         | CHORD_CARET {
2263                 $$ = ly_symbol2scm ("chord-caret");
2264         }
2265         | CHORD_SLASH steno_tonic_pitch {
2266                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2267         }
2268         | CHORD_BASS steno_tonic_pitch {
2269                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2270         }
2271         ;
2272
2273 chord_item:
2274         chord_separator {
2275                 $$ = $1;
2276         }
2277         | step_numbers {
2278                 $$ = scm_reverse_x ($1, SCM_EOL);
2279         }
2280         | CHORD_MODIFIER  {
2281                 $$ = $1;
2282         }
2283         ;
2284
2285 step_numbers:
2286         step_number { $$ = scm_cons ($1, SCM_EOL); }
2287         | step_numbers '.' step_number {
2288                 $$ = scm_cons ($3, $$);
2289         }
2290         ;
2291
2292 step_number:
2293         bare_unsigned {
2294                 $$ = make_chord_step ($1, 0);
2295         }
2296         | bare_unsigned '+' {
2297                 $$ = make_chord_step ($1, SHARP);
2298         }
2299         | bare_unsigned CHORD_MINUS {
2300                 $$ = make_chord_step ($1, FLAT);
2301         }
2302         ;
2303
2304 /*
2305         UTILITIES
2306
2307 TODO: should deprecate in favor of Scheme?
2308
2309  */
2310 number_expression:
2311         number_expression '+' number_term {
2312                 $$ = scm_sum ($1, $3);
2313         }
2314         | number_expression '-' number_term {
2315                 $$ = scm_difference ($1, $3);
2316         }
2317         | number_term
2318         ;
2319
2320 number_term:
2321         number_factor {
2322                 $$ = $1;
2323         }
2324         | number_factor '*' number_factor {
2325                 $$ = scm_product ($1, $3);
2326         }
2327         | number_factor '/' number_factor {
2328                 $$ = scm_divide ($1, $3);
2329         }
2330         ;
2331
2332 number_factor:
2333         '-'  number_factor { /* %prec UNARY_MINUS */
2334                 $$ = scm_difference ($2, SCM_UNDEFINED);
2335         }
2336         | bare_number
2337         ;
2338
2339
2340 bare_number:
2341         UNSIGNED        {
2342                 $$ = scm_int2num ($1);
2343         }
2344         | REAL          {
2345                 $$ = $1;
2346         }
2347         | NUMBER_IDENTIFIER             {
2348                 $$ = $1;
2349         }
2350         | REAL NUMBER_IDENTIFIER        {
2351                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2352         }
2353         | UNSIGNED NUMBER_IDENTIFIER    {
2354                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2355         }
2356         ;
2357
2358
2359 bare_unsigned:
2360         UNSIGNED {
2361                         $$ = $1;
2362         }
2363         | DIGIT {
2364                 $$ = $1;
2365         }
2366         ;
2367
2368 bare_int:
2369         bare_number {
2370                 if (scm_integer_p ($1) == SCM_BOOL_T)
2371                 {
2372                         int k = ly_scm2int ($1);
2373                         $$ = k;
2374                 } else
2375                 {
2376                         THIS->parser_error (_ ("need integer number arg"));
2377                         $$ = 0;
2378                 }
2379         }
2380         | '-' bare_int {
2381                 $$ = -$2;
2382         }
2383         ;
2384
2385 exclamations:
2386                 { $$ = 0; }
2387         | exclamations '!'      { $$ ++; }
2388         ;
2389
2390 questions:
2391                 { $$ = 0; }
2392         | questions '?' { $$ ++; }
2393         ;
2394
2395
2396
2397 full_markup:
2398         MARKUP_IDENTIFIER {
2399                 $$ = $1;
2400         }
2401         | MARKUP
2402                 { THIS->lexer_->push_markup_state (); }
2403         markup
2404                 { $$ = $3;
2405                   THIS->lexer_->pop_state ();
2406                 }
2407         ;
2408
2409
2410 /*
2411 This should be done more dynamically if possible.
2412 */
2413 markup:
2414         STRING {
2415                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2416         }
2417         | MARKUP_HEAD_EMPTY {
2418                 $$ = scm_list_1 ($1);
2419         }
2420         | MARKUP_HEAD_MARKUP0 markup {
2421                 $$ = scm_list_2 ($1, $2);
2422         }
2423         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2424                 $$ = scm_list_3 ($1, $2, $3);
2425         }
2426         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2427                 $$ = scm_list_3 ($1, $2, $3);
2428         }
2429         | markup_line {
2430                 $$ = $1;
2431         }
2432         | MARKUP_HEAD_LIST0 markup_list {
2433                 $$ = scm_list_2 ($1,$2);
2434         }
2435         | MARKUP_HEAD_SCM0 embedded_scm {
2436                 $$ = scm_list_2 ($1, $2);
2437         }
2438         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2439                 $$ = scm_list_4 ($1, $2, $3, $4);
2440         }
2441         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2442                 $$ = scm_list_4 ($1, $2, $3, $4);
2443         }
2444         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2445                 $$ = scm_list_3 ($1, $2, $3);
2446         }
2447         | MARKUP_IDENTIFIER {
2448                 $$ = $1;
2449         }
2450         | STRING_IDENTIFIER {
2451                 $$ = $1;
2452         }
2453         | SCORE {
2454                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2455                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2456         } '{' score_body '}' {
2457                 Score * sc = $4;
2458                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2459                 scm_gc_unprotect_object (sc->self_scm ());
2460                 THIS->lexer_->pop_state ();
2461         }
2462         ;
2463
2464 markup_list:
2465         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2466         ;
2467
2468 markup_line:
2469         '{' markup_list_body '}' {
2470                 SCM line = ly_scheme_function ("line-markup");
2471
2472                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2473         }
2474         ;
2475
2476 markup_list_body:
2477         /**/ {  $$ = SCM_EOL; }
2478         | markup_list_body markup {
2479                 $$ = scm_cons ($2, $1);
2480         }
2481         ;
2482
2483
2484 %%
2485
2486 void
2487 My_lily_parser::set_yydebug (bool )
2488 {
2489 #if 0
2490         yydebug = 1;
2491 #endif
2492 }
2493
2494 void
2495 My_lily_parser::do_yyparse ()
2496 {
2497         yyparse ((void*)this);
2498 }
2499
2500
2501 /*
2502 Should make this optional?    It will also complain when you do
2503
2504         [s4]
2505
2506 which is entirely legitimate.
2507
2508 Or we can scrap it. Barchecks should detect wrong durations, and
2509 skipTypesetting speeds it up a lot.
2510 */
2511
2512 void
2513 My_lily_parser::beam_check (SCM dur)
2514 {
2515   Duration *d = unsmob_duration (dur);
2516   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2517     {
2518       Music *m = unsmob_music (last_beam_start_);
2519       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2520     }
2521   last_beam_start_ = SCM_EOL;
2522 }
2523
2524
2525
2526
2527 /*
2528
2529 It is a little strange to have this function in this file, but
2530 otherwise, we have to import music classes into the lexer.
2531
2532 */
2533 int
2534 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2535 {
2536         if (ly_c_string_p (sid)) {
2537                 *destination = sid;
2538                 return STRING_IDENTIFIER;
2539         } else if (ly_c_number_p (sid)) {
2540                 *destination = sid;
2541                 return NUMBER_IDENTIFIER;
2542         } else if (unsmob_context_def (sid)) {
2543                 *destination = unsmob_context_def (sid)->clone_scm ();
2544                 return CONTEXT_DEF_IDENTIFIER;
2545         } else if (unsmob_score (sid)) {
2546                 Score *score = new Score (*unsmob_score (sid));
2547                 *destination = score->self_scm ();
2548                 return SCORE_IDENTIFIER;
2549         } else if (Music *mus = unsmob_music (sid)) {
2550                 mus = mus->clone ();
2551                 *destination = mus->self_scm ();
2552                 unsmob_music (*destination)->
2553                         set_property ("origin", make_input (last_input_));
2554                 return dynamic_cast<Event*> (mus)
2555                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2556         } else if (unsmob_duration (sid)) {
2557                 *destination = unsmob_duration (sid)->smobbed_copy ();
2558                 return DURATION_IDENTIFIER;
2559         } else if (unsmob_output_def (sid)) {
2560                 Output_def *p = unsmob_output_def (sid);
2561                 p = p->clone ();
2562
2563                 *destination = p->self_scm ();
2564                 return OUTPUT_DEF_IDENTIFIER;
2565         } else if (Text_item::markup_p (sid)) {
2566                 *destination = sid;
2567                 return MARKUP_IDENTIFIER;
2568         }
2569
2570         return -1;
2571 }
2572
2573 Music *
2574 property_op_to_music (SCM op)
2575 {
2576         Music *m = 0;
2577         SCM tag = ly_car (op);
2578         SCM symbol = ly_cadr (op);
2579         SCM args = ly_cddr (op);
2580         SCM grob_val = SCM_UNDEFINED;
2581         SCM grob_sym = SCM_UNDEFINED;
2582         SCM val = SCM_UNDEFINED;
2583
2584         if (tag == ly_symbol2scm ("assign"))
2585                 {
2586                 m = MY_MAKE_MUSIC ("PropertySet");
2587                 val = ly_car (args);
2588                 }
2589         else if (tag == ly_symbol2scm ("unset"))
2590                 m = MY_MAKE_MUSIC ("PropertyUnset");
2591         else if (tag == ly_symbol2scm ("poppush")
2592                  || tag == ly_symbol2scm ("push"))
2593                 {
2594                 m = MY_MAKE_MUSIC ("OverrideProperty");
2595                 grob_sym = ly_car (args);
2596                 grob_val = ly_cadr (args);
2597                 }
2598         else if (tag == ly_symbol2scm ("pop")) {
2599                 m = MY_MAKE_MUSIC ("RevertProperty");
2600                 grob_sym = ly_car (args);
2601                 }
2602
2603         m->set_property ("symbol", symbol);
2604
2605         if (val != SCM_UNDEFINED)
2606                 m->set_property ("value", val);
2607         if (grob_val != SCM_UNDEFINED)
2608                 m->set_property ("grob-value", grob_val);
2609
2610         if (grob_sym != SCM_UNDEFINED)
2611                 {
2612                 bool itc = internal_type_checking_global_b;
2613                 /* UGH.
2614                 */
2615                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2616                 if (autobeam)
2617                         internal_type_checking_global_b = false;
2618                 m->set_property ("grob-property", grob_sym);
2619                 if (autobeam)
2620                         internal_type_checking_global_b = itc;
2621                 }
2622
2623         if (tag == ly_symbol2scm ("poppush"))
2624                 m->set_property ("pop-first", SCM_BOOL_T);
2625
2626
2627         return m;
2628 }
2629
2630 Music*
2631 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2632 {
2633         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2634
2635         csm->set_property ("element", m->self_scm ());
2636         scm_gc_unprotect_object (m->self_scm ());
2637
2638         csm->set_property ("context-type",
2639                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2640         csm->set_property ("property-operations", ops);
2641
2642         if (ly_c_string_p (id))
2643                 csm->set_property ("context-id", id);
2644         return csm;
2645 }
2646
2647 SCM
2648 get_next_unique_context ()
2649 {
2650         static int new_context_count;
2651         char s[1024];
2652         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2653         return scm_makfrom0str (s);
2654 }
2655