lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input-smob.hh"
  79 #include "input.hh"
  80 #include "international.hh"
  81 #include "lily-guile.hh"
  82 #include "lily-lexer.hh"
  83 #include "lily-parser.hh"
  84 #include "lilypond-input-version.hh"
  85 #include "main.hh"
  86 #include "misc.hh"
  87 #include "music.hh"
  88 #include "music.hh"
  89 #include "output-def.hh"
  90 #include "paper-book.hh"
  91 #include "program-option.hh"
  92 #include "scm-hash.hh"
  93 #include "score.hh"
  94 #include "text-interface.hh"
  95 #include "warn.hh"
  96
  97 %}
  98
  99
 100 %union {
 101         Book *book;
 102         Output_def *outputdef;
 103         SCM scm;
 104         std::string *string;
 105         Music *music;
 106         Score *score;
 107         int i;
 108 }
 109
 110 %{
 111
 112 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 113
 114 Music *property_op_to_music (SCM op);
 115 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops, bool create_new);
 116 SCM get_next_unique_context_id ();
 117 SCM get_next_unique_lyrics_context_id ();
 118
 119 #undef _
 120 #if !HAVE_GETTEXT
 121 #define _(x) x
 122 #else
 123 #include <libintl.h>
 124 #define _(x) gettext (x)
 125 #endif
 126
 127
 128
 129 Music *make_lyric_combine_music (SCM name, Music *music);
 130 Music *make_music_relative (Pitch start, Music *music);
 131 Music *run_music_function (Lily_parser *, SCM expr);
 132 Music *set_property_music (SCM sym, SCM value);
 133 SCM get_first_context_id (SCM type, Music *m);
 134 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 135 SCM make_chord_step (int step, int alter);
 136 SCM make_simple_markup (SCM a);
 137 bool is_duration (int t);
 138 bool is_regular_identifier (SCM id);
 139 bool ly_input_procedure_p (SCM x);
 140 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 141 void set_music_properties (Music *p, SCM a);
 142
 143 %}
 144
 145 /* The third option is an alias that will be used to display the
 146    syntax error.  Bison CVS now correctly handles backslash escapes.
 147
 148    FIXME: Bison needs to translate some of these, eg, STRING.
 149
 150 */
 151
 152 /* Keyword tokens with plain escaped name.  */
 153 %token ACCEPTS "\\accepts"
 154 %token ADDLYRICS "\\addlyrics"
 155 %token ADDQUOTE "\\addquote"
 156 %token ALIAS "\\alias"
 157 %token ALTERNATIVE "\\alternative"
 158 %token BOOK "\book"
 159 %token CHANGE "\\change"
 160 %token CHORDMODE "\\chordmode"
 161 %token CHORDS "\\chords"
 162 %token CONSISTS "\\consists"
 163 %token CONTEXT "\\context"
 164 %token DEFAULT "\\default"
 165 %token DEFAULTCHILD "\\defaultchild"
 166 %token DENIES "\\denies"
 167 %token DESCRIPTION "\\description"
 168 %token DRUMMODE "\\drummode"
 169 %token DRUMS "\\drums"
 170 %token FIGUREMODE "\\figuremode"
 171 %token FIGURES "\\figures"
 172 %token GROBDESCRIPTIONS "\\grobdescriptions"
 173 %token HEADER "\\header"
 174 %token INVALID "\\invalid"
 175 %token KEY "\\key"
 176 %token LAYOUT "\\layout"
 177 %token LYRICMODE "\\lyricmode"
 178 %token LYRICS "\\lyrics"
 179 %token LYRICSTO "\\lyricsto"
 180 %token MARK "\\mark"
 181 %token MARKUP "\\markup"
 182 %token MIDI "\\midi"
 183 %token NAME "\\name"
 184 %token NOTEMODE "\\notemode"
 185 %token OBJECTID "\\objectid"
 186 %token OCTAVE "\\octave"
 187 %token ONCE "\\once"
 188 %token OVERRIDE "\\override"
 189 %token PAPER "\\paper"
 190 %token PARTIAL "\\partial"
 191 %token RELATIVE "\\relative"
 192 %token REMOVE "\\remove"
 193 %token REPEAT "\\repeat"
 194 %token REST "\\rest"
 195 %token REVERT "\\revert"
 196 %token SCORE "\\score"
 197 %token SEQUENTIAL "\\sequential"
 198 %token SET "\\set"
 199 %token SIMULTANEOUS "\\simultaneous"
 200 %token SKIP "\\skip"
 201 %token TEMPO "\\tempo"
 202 %token TIMES "\\times"
 203 %token TRANSPOSE "\\transpose"
 204 %token TRANSPOSITION "\\transposition"
 205 %token TYPE "\\type"
 206 %token UNSET "\\unset"
 207 %token WITH "\\with"
 208
 209 /* Keyword token exceptions.  */
 210 %token TIME_T "\\time"
 211 %token NEWCONTEXT "\\new"
 212
 213
 214 /* Other string tokens.  */
 215
 216 %token CHORD_BASS "/+"
 217 %token CHORD_CARET "^"
 218 %token CHORD_COLON ":"
 219 %token CHORD_MINUS "-"
 220 %token CHORD_SLASH "/"
 221 %token DOUBLE_ANGLE_CLOSE ">>"
 222 %token DOUBLE_ANGLE_OPEN "<<"
 223 %token E_BACKSLASH "\\"
 224 %token E_ANGLE_CLOSE "\\>"
 225 %token E_CHAR "\\C[haracter]"
 226 %token E_CLOSE "\\)"
 227 %token E_EXCLAMATION "\\!"
 228 %token E_BRACKET_OPEN "\\["
 229 %token E_OPEN "\\("
 230 %token E_BRACKET_CLOSE "\\]"
 231 %token E_ANGLE_OPEN "\\<"
 232 %token E_PLUS "\\+"
 233 %token E_TILDE "\\~"
 234 %token EXTENDER "__"
 235
 236 /*
 237 If we give names, Bison complains.
 238 */
 239 %token FIGURE_CLOSE /* "\\>" */
 240 %token FIGURE_OPEN /* "\\<" */
 241 %token FIGURE_SPACE "_"
 242 %token HYPHEN "--"
 243
 244 %token CHORDMODIFIERS
 245 %token LYRIC_MARKUP
 246 %token MULTI_MEASURE_REST
 247 %token SCM_T
 248
 249
 250 %token <i> DIGIT
 251 %token <i> E_UNSIGNED
 252 %token <i> UNSIGNED
 253
 254 %token <scm> BOOK_IDENTIFIER
 255 %token <scm> CHORDMODIFIER_PITCH
 256 %token <scm> CHORD_MODIFIER
 257 %token <scm> CONTEXT_DEF_IDENTIFIER
 258 %token <scm> DRUM_PITCH
 259 %token <scm> DURATION_IDENTIFIER
 260 %token <scm> EVENT_IDENTIFIER
 261 %token <scm> FRACTION
 262 %token <scm> LYRICS_STRING
 263 %token <scm> LYRIC_MARKUP_IDENTIFIER
 264 %token <scm> MARKUP_HEAD_EMPTY
 265 %token <scm> MARKUP_HEAD_LIST0
 266 %token <scm> MARKUP_HEAD_MARKUP0
 267 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 268 %token <scm> MARKUP_HEAD_SCM0
 269 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 270 %token <scm> MARKUP_HEAD_SCM0_SCM1
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 272 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 273 %token <scm> MARKUP_IDENTIFIER
 274 %token <scm> MUSIC_FUNCTION
 275 %token <scm> MUSIC_FUNCTION_MARKUP
 276 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MUSIC
 281 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 282 %token <scm> MUSIC_FUNCTION_SCM
 283 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 284 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 285 %token <scm> MUSIC_FUNCTION_SCM_SCM
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 287 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 288 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC
 289 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC
 290 %token <scm> MUSIC_IDENTIFIER
 291 %token <scm> NOTENAME_PITCH
 292 %token <scm> NUMBER_IDENTIFIER
 293 %token <scm> OUTPUT_DEF_IDENTIFIER
 294 %token <scm> REAL
 295 %token <scm> RESTNAME
 296 %token <scm> SCM_IDENTIFIER
 297 %token <scm> SCM_T
 298 %token <scm> SCORE_IDENTIFIER
 299 %token <scm> STRING
 300 %token <scm> STRING_IDENTIFIER
 301 %token <scm> TONICNAME_PITCH
 302
 303
 304 %type <book> book_block
 305 %type <book> book_body
 306
 307 %type <i> bare_unsigned
 308 %type <i> figured_bass_alteration
 309 %type <i> dots
 310 %type <i> exclamations
 311 %type <i> optional_rest
 312 %type <i> questions
 313 %type <i> script_dir
 314 %type <i> sub_quotes
 315 %type <i> sup_quotes
 316 %type <i> tremolo_type
 317
 318 %type <music> Composite_music
 319 %type <music> Grouped_music_list
 320 %type <music> Music
 321 %type <music> Prefix_composite_music
 322 %type <music> Repeated_music
 323 %type <music> Sequential_music
 324 %type <music> Simple_music
 325 %type <music> Simultaneous_music
 326 %type <music> chord_body
 327 %type <music> chord_body_element
 328 %type <music> command_element
 329 %type <music> command_event
 330 %type <music> context_change
 331 %type <music> direction_less_event
 332 %type <music> direction_reqd_event
 333 %type <music> event_chord
 334 %type <music> gen_text_def
 335 %type <music> music_property_def
 336 %type <music> note_chord_element
 337 %type <music> post_event
 338 %type <music> re_rhythmed_music
 339 %type <music> relative_music
 340 %type <music> simple_element
 341 %type <music> string_number_event
 342 %type <music> tempo_event
 343 %type <music> toplevel_music
 344
 345 %type <outputdef> output_def_body
 346 %type <outputdef> output_def_head
 347 %type <outputdef> output_def_head_with_mode_switch
 348 %type <outputdef> output_def
 349 %type <outputdef> paper_block
 350
 351 %type <scm> Alternative_music
 352 %type <scm> Generic_prefix_music_scm
 353 %type <scm> Music_list
 354 %type <scm> absolute_pitch
 355 %type <scm> assignment_id
 356 %type <scm> bare_number
 357 %type <scm> music_function_event
 358 %type <scm> music_function_chord_body
 359 %type <scm> music_function_musicless_prefix
 360 %type <scm> bass_figure
 361 %type <scm> figured_bass_modification
 362 %type <scm> br_bass_figure
 363 %type <scm> bass_number
 364 %type <scm> chord_body_elements
 365 %type <scm> chord_item
 366 %type <scm> chord_items
 367 %type <scm> chord_separator
 368 %type <scm> context_def_mod
 369 %type <scm> context_def_spec_block
 370 %type <scm> context_def_spec_body
 371 %type <scm> context_mod
 372 %type <scm> context_mod_list
 373 %type <scm> context_prop_spec
 374 %type <scm> direction_less_char
 375 %type <scm> duration_length
 376 %type <scm> embedded_scm
 377 %type <scm> figure_list
 378 %type <scm> figure_spec
 379 %type <scm> fraction
 380 %type <scm> full_markup
 381 %type <scm> identifier_init
 382 %type <scm> lilypond_header
 383 %type <scm> lilypond_header_body
 384 %type <scm> lyric_element
 385 %type <scm> lyric_markup
 386 %type <scm> markup
 387 %type <scm> markup_braced_list
 388 %type <scm> markup_braced_list_body
 389 %type <scm> markup_composed_list
 390 %type <scm> markup_head_1_item
 391 %type <scm> markup_head_1_list
 392 %type <scm> markup_list
 393 %type <scm> markup_top
 394 %type <scm> mode_changing_head
 395 %type <scm> mode_changing_head_with_context
 396 %type <scm> multiplied_duration
 397 %type <scm> new_chord
 398 %type <scm> new_lyrics
 399 %type <scm> number_expression
 400 %type <scm> number_factor
 401 %type <scm> number_term
 402 %type <scm> object_id_setting
 403 %type <scm> octave_check
 404 %type <scm> optional_context_mod
 405 %type <scm> optional_id
 406 %type <scm> optional_notemode_duration
 407 %type <scm> pitch
 408 %type <scm> pitch_also_in_chords
 409 %type <scm> post_events
 410 %type <scm> property_operation
 411 %type <scm> scalar
 412 %type <scm> script_abbreviation
 413 %type <scm> simple_markup
 414 %type <scm> simple_string
 415 %type <scm> steno_duration
 416 %type <scm> steno_pitch
 417 %type <scm> steno_tonic_pitch
 418 %type <scm> step_number
 419 %type <scm> step_numbers
 420 %type <scm> string
 421 %type <scm> function_scm_argument
 422
 423 %type <score> score_block
 424 %type <score> score_body
 425
 426
 427 %left '-' '+'
 428
 429 /* We don't assign precedence to / and *, because we might need varied
 430 prec levels in different prods */
 431
 432 %left UNARY_MINUS
 433
 434 %%
 435
 436 lilypond:       /* empty */
 437         | lilypond toplevel_expression {
 438         }
 439         | lilypond assignment {
 440         }
 441         | lilypond error {
 442                 THIS->error_level_ = 1;
 443         }
 444         | lilypond INVALID      {
 445                 THIS->error_level_ = 1;
 446         }
 447         ;
 448
 449
 450 object_id_setting:
 451         OBJECTID STRING { $$ = $2; }
 452         ;
 453
 454 toplevel_expression:
 455         lilypond_header {
 456                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 457         }
 458         | book_block {
 459                 Book *book = $1;
 460                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 461                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 462                 book->unprotect ();
 463         }
 464         | score_block {
 465                 Score *score = $1;
 466
 467                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 468                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 469                 score->unprotect ();
 470         }
 471         | toplevel_music {
 472                 Music *music = $1;
 473                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 474                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 475                 music->unprotect ();
 476         }
 477         | full_markup {
 478                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 479                 scm_call_2 (proc, THIS->self_scm (), $1);
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultlayout");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 od->unprotect();
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = get_header(THIS);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524 /*
 525         DECLARATIONS
 526 */
 527 assignment_id:
 528         STRING          { $$ = $1; }
 529         | LYRICS_STRING { $$ = $1; }
 530         ;
 531
 532 assignment:
 533         assignment_id '=' identifier_init  {
 534                 if (! is_regular_identifier ($1))
 535                 {
 536 #if 0
 537                         /* no longer valid with dashes in \paper{} block. */
 538                         @1.warning (_ ("identifier should have alphabetic characters only"));
 539 #endif
 540                 }
 541
 542
 543                 THIS->lexer_->set_identifier ($1, $3);
 544
 545 /*
 546  TODO: devise standard for protection in parser.
 547
 548   The parser stack lives on the C-stack, which means that
 549 all objects can be unprotected as soon as they're here.
 550
 551 */
 552         }
 553         | embedded_scm { }
 554         ;
 555
 556
 557 identifier_init:
 558         score_block {
 559                 $$ = $1->self_scm ();
 560                 $1->unprotect ();
 561         }
 562         | book_block {
 563                 $$ = $1->self_scm ();
 564                 $1->unprotect ();
 565         }
 566         | output_def {
 567                 $$ = $1->self_scm ();
 568                 $1->unprotect ();
 569         }
 570         | context_def_spec_block {
 571                 $$ = $1;
 572         }
 573         | Music  {
 574                 $$ = $1->self_scm ();
 575                 $1->unprotect();
 576         }
 577         | post_event {
 578                 $$ = $1->self_scm ();
 579                 $1->unprotect();
 580         }
 581         | number_expression {
 582                 $$ = $1;
 583         }
 584         | string {
 585                 $$ = $1;
 586         }
 587         | embedded_scm {
 588                 $$ = $1;
 589         }
 590         | full_markup {
 591                 $$ = $1;
 592         }
 593         | DIGIT {
 594                 $$ = scm_from_int ($1);
 595         }
 596         ;
 597
 598 context_def_spec_block:
 599         CONTEXT '{' context_def_spec_body '}'
 600                 {
 601                 $$ = $3;
 602         }
 603         ;
 604
 605 context_def_spec_body:
 606         /**/ {
 607                 $$ = Context_def::make_scm ();
 608                 unsmob_context_def ($$)->set_spot (@$);
 609         }
 610         | CONTEXT_DEF_IDENTIFIER {
 611                 $$ = $1;
 612                 unsmob_context_def ($$)->set_spot (@$);
 613         }
 614         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 615                 Context_def*td = unsmob_context_def ($$);
 616
 617                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 618                         SCM tag = scm_caar (p);
 619
 620                         /* TODO: should make new tag "grob-definition" ? */
 621                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 622                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 623                 }
 624         }
 625         | context_def_spec_body context_mod {
 626                 unsmob_context_def ($$)->add_context_mod ($2);
 627         }
 628         ;
 629
 630
 631
 632 book_block:
 633         BOOK '{' book_body '}'  {
 634                 $$ = $3;
 635         }
 636         ;
 637
 638 /* FIXME:
 639    * Use 'handlers' like for toplevel-* stuff?
 640    * grok \layout and \midi?  */
 641 book_body:
 642         {
 643                 $$ = new Book;
 644                 $$->set_spot (@$);
 645                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 646                 $$->paper_->unprotect ();
 647                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 648         }
 649         | BOOK_IDENTIFIER {
 650                 $$ = unsmob_book ($1);
 651                 $$->set_spot (@$);
 652         }
 653         | book_body paper_block {
 654                 $$->paper_ = $2;
 655                 $2->unprotect ();
 656         }
 657         | book_body score_block {
 658                 SCM s = $2->self_scm ();
 659                 $$->add_score (s);
 660                 $2->unprotect();
 661         }
 662         | book_body full_markup {
 663                 $$->add_score ($2);
 664         }
 665         | book_body lilypond_header {
 666                 $$->header_ = $2;
 667         }
 668         | book_body error {
 669                 $$->paper_ = 0;
 670                 $$->scores_ = SCM_EOL;
 671         }
 672         | book_body object_id_setting {
 673                 $$->user_key_ = ly_scm2string ($2);
 674         }
 675         ;
 676
 677 score_block:
 678         SCORE '{' score_body '}'        {
 679                 $$ = $3;
 680         }
 681         ;
 682
 683 score_body:
 684         Music {
 685                 SCM m = $1->self_scm ();
 686                 $1->unprotect();
 687                 SCM scorify = ly_lily_module_constant ("scorify-music");
 688                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 689
 690                 // pass ownernship to C++ again.
 691                 $$ = unsmob_score (score);
 692                 $$->protect ();
 693                 $$->set_spot (@$);
 694         }
 695         | SCORE_IDENTIFIER {
 696                 $$ = unsmob_score ($1);
 697                 $$->set_spot (@$);
 698         }
 699         | score_body object_id_setting {
 700                 $$->user_key_ = ly_scm2string ($2);
 701         }
 702         | score_body lilypond_header    {
 703                 $$->header_ = $2;
 704         }
 705         | score_body output_def {
 706                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 707                 {
 708                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 709
 710                 }
 711                 else
 712                 {
 713                         $$->add_output_def ($2);
 714                 }
 715                 $2->unprotect ();
 716         }
 717         | score_body error {
 718                 $$->error_found_ = true;
 719         }
 720         ;
 721
 722
 723 /*
 724         OUTPUT DEF
 725 */
 726
 727 paper_block:
 728         output_def {
 729                 $$ = $1;
 730                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 731                 {
 732                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 733                         $$ = get_paper (THIS);
 734                 }
 735         }
 736         ;
 737
 738
 739 output_def:
 740         output_def_body '}' {
 741                 $$ = $1;
 742
 743                 THIS->lexer_->remove_scope ();
 744                 THIS->lexer_->pop_state ();
 745         }
 746         ;
 747
 748 output_def_head:
 749         PAPER {
 750                 $$ = get_paper (THIS);
 751                 $$->input_origin_ = @$;
 752                 THIS->lexer_->add_scope ($$->scope_);
 753         }
 754         | MIDI    {
 755                 Output_def *p = get_midi (THIS);
 756                 $$ = p;
 757                 THIS->lexer_->add_scope (p->scope_);
 758         }
 759         | LAYOUT        {
 760                 Output_def *p = get_layout (THIS);
 761
 762                 THIS->lexer_->add_scope (p->scope_);
 763                 $$ = p;
 764         }
 765         ;
 766
 767 output_def_head_with_mode_switch:
 768         output_def_head {
 769                 THIS->lexer_->push_initial_state ();
 770                 $$ = $1;
 771         }
 772         ;
 773
 774 output_def_body:
 775         output_def_head_with_mode_switch '{' {
 776                 $$ = $1;
 777                 $$->input_origin_.set_spot (@$);
 778         }
 779         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 780                 $1->unprotect ();
 781                 Output_def *o = unsmob_output_def ($3);
 782                 o->input_origin_.set_spot (@$);
 783                 $$ = o;
 784                 THIS->lexer_->remove_scope ();
 785                 THIS->lexer_->add_scope (o->scope_);
 786         }
 787         | output_def_body assignment  {
 788
 789         }
 790         | output_def_body context_def_spec_block        {
 791                 assign_context_def ($$, $2);
 792         }
 793         | output_def_body tempo_event  {
 794                 /*
 795                         junk this ? there already is tempo stuff in
 796                         music.
 797                 */
 798                 int m = scm_to_int ($2->get_property ("metronome-count"));
 799                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 800                 set_tempo ($$, d->get_length (), m);
 801                 $2->unprotect ();
 802         }
 803         | output_def_body error {
 804
 805         }
 806         ;
 807
 808 tempo_event:
 809         TEMPO steno_duration '=' bare_unsigned  {
 810                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 811                 $$->set_property ("tempo-unit", $2);
 812                 $$->set_property ("metronome-count", scm_from_int ( $4));
 813         }
 814         ;
 815
 816 /*
 817 The representation of a  list is the
 818
 819   (LIST . LAST-CONS)
 820
 821  to have efficient append.  */
 822
 823 Music_list:
 824         /* empty */ {
 825                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 826         }
 827         | Music_list Music {
 828                 SCM s = $$;
 829                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 830                 $2->unprotect (); /* UGH */
 831
 832                 if (scm_is_pair (scm_cdr (s)))
 833                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 834                 else
 835                         scm_set_car_x (s, c); /* set first cons */
 836                 scm_set_cdr_x (s, c);  /* remember last cell */
 837         }
 838         | Music_list embedded_scm {
 839
 840         }
 841         | Music_list error {
 842                 Music * m = MY_MAKE_MUSIC("Music");
 843                 // ugh. code dup
 844                 m->set_property ("error-found", SCM_BOOL_T);
 845                 SCM s = $$;
 846                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 847                 m->unprotect (); /* UGH */
 848
 849                 if (scm_is_pair (scm_cdr (s)))
 850                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 851                 else
 852                         scm_set_car_x (s, c); /* set first cons */
 853                 scm_set_cdr_x (s, c);  /* remember last cell */
 854         }
 855         ;
 856
 857 Music:
 858         Simple_music
 859         | Composite_music
 860         ;
 861
 862 Alternative_music:
 863         /* empty */ {
 864                 $$ = SCM_EOL;
 865         }
 866         | ALTERNATIVE '{' Music_list '}' {
 867                 $$ = $3;
 868         }
 869         ;
 870
 871
 872 Repeated_music:
 873         REPEAT simple_string bare_unsigned Music Alternative_music
 874         {
 875                 /*TODO: move to Scheme.*/
 876                 Music *beg = $4;
 877                 int times = $3;
 878                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 879                 if (times < scm_ilength (alts)) {
 880                   unsmob_music (scm_car (alts))
 881                     ->origin ()->warning (
 882                     _ ("more alternatives than repeats"));
 883                     warning ("junking excess alternatives");
 884                   alts = ly_truncate_list (times, alts);
 885                 }
 886
 887
 888                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 889
 890                 SCM mus = scm_call_1 (proc, $2);
 891                 Music *r = unsmob_music (mus);
 892                 r->protect ();
 893                 if (beg)
 894                         {
 895                         r-> set_property ("element", beg->self_scm ());
 896                         beg->unprotect ();
 897                         }
 898                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
 899
 900                 r-> set_property ("elements",alts);
 901                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
 902                         /*
 903                         TODO: move this code to Scheme.
 904                         */
 905
 906                         /* we cannot get durations and other stuff
 907                            correct down the line,
 908                            so we have to add to the duration log here. */
 909                         SCM func = ly_lily_module_constant ("shift-duration-log");
 910
 911                         int dots = ($3 % 3) ? 0 : 1;
 912                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 913
 914
 915                         if ($4->is_mus_type ("sequential-music"))
 916                         {
 917                                 int list_len = scm_ilength ($4->get_property ("elements"));
 918                                 if (list_len != 2)
 919                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
 920                                 shift -= 1;
 921                                 r->compress (Moment (Rational (1, list_len)));
 922                         }
 923                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
 924
 925                 }
 926                 r->set_spot (*$4->origin ());
 927
 928                 $$ = r;
 929         }
 930         ;
 931
 932 Sequential_music:
 933         SEQUENTIAL '{' Music_list '}'           {
 934                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 935                 $$->set_property ("elements", scm_car ($3));
 936                 $$->set_spot (@$);
 937         }
 938         | '{' Music_list '}'            {
 939                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 940                 $$->set_property ("elements", scm_car ($2));
 941                 $$->set_spot (@$);
 942         }
 943         ;
 944
 945 Simultaneous_music:
 946         SIMULTANEOUS '{' Music_list '}'{
 947                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 948                 $$->set_property ("elements", scm_car ($3));
 949                 $$->set_spot (@$);
 950
 951         }
 952         | simul_open Music_list simul_close     {
 953                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 954                 $$->set_property ("elements", scm_car ($2));
 955                 $$->set_spot (@$);
 956         }
 957         ;
 958
 959 Simple_music:
 960         event_chord             { $$ = $1; }
 961         | MUSIC_IDENTIFIER {
 962                 $$ = unsmob_music ($1);
 963         }
 964         | music_property_def
 965         | context_change
 966         ;
 967
 968 optional_context_mod:
 969         /**/ { $$ = SCM_EOL; }
 970         | WITH { THIS->lexer_->push_initial_state (); }
 971         '{' context_mod_list '}'
 972         {
 973                 THIS->lexer_->pop_state ();
 974                 $$ = $4;
 975         }
 976         ;
 977
 978 context_mod_list:
 979         /* */  { $$ = SCM_EOL; }
 980         | context_mod_list context_mod  {
 981                  $$ = scm_cons ($2, $1);
 982         }
 983         ;
 984
 985 Composite_music:
 986         Prefix_composite_music { $$ = $1; }
 987         | Grouped_music_list { $$ = $1; }
 988         ;
 989
 990 Grouped_music_list:
 991         Simultaneous_music              { $$ = $1; }
 992         | Sequential_music              { $$ = $1; }
 993         ;
 994
 995 function_scm_argument:
 996         embedded_scm
 997         | simple_string
 998         ;
 999
1000 /*
1001 TODO: use code generation for this
1002 */
1003 Generic_prefix_music_scm:
1004         MUSIC_FUNCTION {
1005                 $$ = scm_list_2 ($1, make_input (@$));
1006         }
1007         | MUSIC_FUNCTION_SCM function_scm_argument {
1008                 $$ = scm_list_3 ($1, make_input (@$), $2);
1009         }
1010         | MUSIC_FUNCTION_MARKUP full_markup {
1011                 $$ = scm_list_3 ($1, make_input (@$), $2);
1012         }
1013         | music_function_musicless_prefix Music {
1014                 $$ = ly_append2 ($1, scm_list_1 ($2->self_scm ()));
1015                 $2->unprotect ();
1016         }
1017         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
1018                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1019         }
1020         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
1021                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1022         }
1023         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1024                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1025                 $3->unprotect ();
1026         }
1027         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1028                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1029         }
1030         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1031                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1032                 $2->unprotect ();
1033                 $3->unprotect ();
1034         }
1035         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
1036                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1037                 $4->unprotect ();
1038                 $3->unprotect ();
1039         }
1040         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1041                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1042                 $3->unprotect ();
1043                 $4->unprotect ();
1044         }
1045         ;
1046
1047 optional_id:
1048         /**/ { $$ = SCM_EOL; }
1049         | '=' simple_string {
1050                 $$ = $2;
1051         }
1052         ;
1053
1054
1055 Prefix_composite_music:
1056         Generic_prefix_music_scm {
1057                 $$ = run_music_function (THIS, $1);
1058         }
1059         | CONTEXT    simple_string optional_id optional_context_mod Music {
1060                 $$ = context_spec_music ($2, $3, $5, $4, false);
1061         }
1062         | NEWCONTEXT simple_string optional_id optional_context_mod Music {
1063                 $$ = context_spec_music ($2, $3, $5, $4, true);
1064         }
1065
1066         | TIMES fraction Music
1067         {
1068                 int n = scm_to_int (scm_car ($2));
1069                 int d = scm_to_int (scm_cdr ($2));
1070                 Music *mp = $3;
1071
1072                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1073                 $$->set_spot (@$);
1074
1075                 $$->set_property ("element", mp->self_scm ());
1076                 mp->unprotect();
1077                 $$->set_property ("numerator", scm_from_int (n));
1078                 $$->set_property ("denominator", scm_from_int (d));
1079                 $$->compress (Moment (Rational (n,d)));
1080
1081         }
1082         | Repeated_music                { $$ = $1; }
1083         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1084                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1085                 Music *p = $4;
1086                 Pitch from = *unsmob_pitch ($2);
1087                 Pitch to = *unsmob_pitch ($3);
1088
1089                 p->transpose (pitch_interval (from, to));
1090                 $$->set_property ("element", p->self_scm ());
1091                 p->unprotect();
1092         }
1093         | mode_changing_head Grouped_music_list {
1094                 if ($1 == ly_symbol2scm ("chords"))
1095                 {
1096                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1097                   chm->set_property ("element", $2->self_scm ());
1098                   $$ = chm;
1099                   $2->unprotect();
1100                 }
1101                 else
1102                 {
1103                   $$ = $2;
1104                 }
1105                 THIS->lexer_->pop_state ();
1106         }
1107         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1108                 $$ = context_spec_music ($1, SCM_UNDEFINED, $3, $2, true);
1109                 if ($1 == ly_symbol2scm ("ChordNames"))
1110                 {
1111                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1112                   chm->set_property ("element", $$->self_scm ());
1113                   $$->unprotect();
1114                   $$ = chm;
1115                 }
1116                 THIS->lexer_->pop_state ();
1117         }
1118         | relative_music        { $$ = $1; }
1119         | re_rhythmed_music     { $$ = $1; }
1120         ;
1121
1122 mode_changing_head:
1123         NOTEMODE {
1124                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1125                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1126
1127                 $$ = ly_symbol2scm ("notes");
1128         }
1129         | DRUMMODE
1130                 {
1131                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1132                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1133
1134                 $$ = ly_symbol2scm ("drums");
1135         }
1136         | FIGUREMODE {
1137                 THIS->lexer_->push_figuredbass_state ();
1138
1139                 $$ = ly_symbol2scm ("figures");
1140         }
1141         | CHORDMODE {
1142                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1143                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1144                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1145                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1146                 $$ = ly_symbol2scm ("chords");
1147
1148         }
1149         | LYRICMODE
1150                 { THIS->lexer_->push_lyric_state ();
1151                 $$ = ly_symbol2scm ("lyrics");
1152         }
1153         ;
1154
1155 mode_changing_head_with_context:
1156         DRUMS {
1157                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1158                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1159
1160                 $$ = ly_symbol2scm ("DrumStaff");
1161         }
1162         | FIGURES {
1163                 THIS->lexer_->push_figuredbass_state ();
1164
1165                 $$ = ly_symbol2scm ("FiguredBass");
1166         }
1167         | CHORDS {
1168                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1169                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1170                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1171                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1172                 $$ = ly_symbol2scm ("ChordNames");
1173         }
1174         | LYRICS
1175                 { THIS->lexer_->push_lyric_state ();
1176                 $$ = ly_symbol2scm ("Lyrics");
1177         }
1178         ;
1179
1180
1181 relative_music:
1182         RELATIVE absolute_pitch Music {
1183                 Music *m = $3;
1184                 Pitch start = *unsmob_pitch ($2);
1185                 $$ = make_music_relative (start, m);
1186                 m->unprotect();
1187         }
1188         | RELATIVE Composite_music {
1189                 Music *m = $2;
1190
1191                 Pitch middle_c (0, 0, 0);
1192                 $$ = make_music_relative (middle_c, m);
1193                 m->unprotect();
1194         }
1195         ;
1196
1197 new_lyrics:
1198         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1199         /*cont */
1200         Grouped_music_list {
1201         /* Can also use Music at the expensive of two S/Rs similar to
1202            \repeat \alternative */
1203                 THIS->lexer_->pop_state ();
1204
1205                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1206         }
1207         | new_lyrics ADDLYRICS {
1208                 THIS->lexer_->push_lyric_state ();
1209         } Grouped_music_list {
1210                 THIS->lexer_->pop_state ();
1211                 $$ = scm_cons ($4->self_scm (), $1);
1212         }
1213         ;
1214
1215 re_rhythmed_music:
1216         Grouped_music_list new_lyrics {
1217                 Music * voice = $1;
1218                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1219                 if (!scm_is_string (name))
1220                 {
1221                         name = get_next_unique_lyrics_context_id ();
1222                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1223                                                     name,
1224                                                     voice, SCM_EOL, false);
1225                 }
1226
1227                 SCM context = scm_makfrom0str ("Lyrics");
1228                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1229
1230                 SCM lst = SCM_EOL;
1231                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1232                 {
1233                         Music *music = unsmob_music (scm_car (s));
1234                         Music *com = make_lyric_combine_music (name, music);
1235                         Music *csm = context_spec_music (context,
1236                                 SCM_UNDEFINED, com, SCM_EOL, true);
1237                         lst = scm_cons (csm->self_scm (), lst);
1238                 }
1239                 all->set_property ("elements", scm_cons (voice->self_scm (),
1240                         lst));
1241                 $$ = all;
1242                 voice->unprotect ();
1243         }
1244         | LYRICSTO simple_string {
1245                 THIS->lexer_->push_lyric_state ();
1246         } Music {
1247                 THIS->lexer_->pop_state ();
1248                 Music *music = $4;
1249                 SCM name = $2;
1250                 $$ = make_lyric_combine_music (name, music);
1251                 music->unprotect();
1252         }
1253         ;
1254
1255 context_change:
1256         CHANGE STRING '=' STRING  {
1257                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1258                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1259                 t-> set_property ("change-to-id", $4);
1260
1261                 $$ = t;
1262                 $$->set_spot (@$);
1263         }
1264         ;
1265
1266 property_operation:
1267         STRING '=' scalar {
1268                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1269                         scm_string_to_symbol ($1), $3);
1270         }
1271         | UNSET simple_string {
1272                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1273                         scm_string_to_symbol ($2));
1274         }
1275         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1276                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1277                         scm_string_to_symbol ($2), $5, $3);
1278         }
1279         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1280                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1281                                 scm_string_to_symbol ($2), $6, $4, $3);
1282         }
1283         | REVERT simple_string embedded_scm {
1284                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1285                         scm_string_to_symbol ($2), $3);
1286         }
1287         ;
1288
1289 context_def_mod:
1290         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1291         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1292
1293         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1294         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1295         | DENIES { $$ = ly_symbol2scm ("denies"); }
1296
1297         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1298         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1299         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1300         | NAME { $$ = ly_symbol2scm ("context-name"); }
1301         ;
1302
1303 context_mod:
1304         property_operation { $$ = $1; }
1305         | context_def_mod STRING {
1306                 $$ = scm_list_2 ($1, $2);
1307         }
1308         ;
1309
1310 context_prop_spec:
1311         simple_string {
1312                 if (!is_regular_identifier ($1))
1313                 {
1314                         @$.error (_("Grob name should be alphanumeric"));
1315                 }
1316
1317                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1318                         scm_string_to_symbol ($1));
1319         }
1320         | simple_string '.' simple_string {
1321                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1322                         scm_string_to_symbol ($3));
1323         }
1324         ;
1325
1326 music_property_def:
1327         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1328                 $$ = property_op_to_music (scm_list_4 (
1329                         ly_symbol2scm ("push"),
1330                         scm_cadr ($2),
1331                         $5, $3));
1332                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1333         }
1334         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1335                 $$ = property_op_to_music (scm_list_5 (
1336                         ly_symbol2scm ("push"),
1337                         scm_cadr ($2),
1338                         $6, $4, $3));
1339                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1340         }
1341         | REVERT context_prop_spec embedded_scm {
1342                 $$ = property_op_to_music (scm_list_3 (
1343                         ly_symbol2scm ("pop"),
1344                         scm_cadr ($2),
1345                         $3));
1346
1347                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1348         }
1349         | SET context_prop_spec '=' scalar {
1350                 $$ = property_op_to_music (scm_list_3 (
1351                         ly_symbol2scm ("assign"),
1352                         scm_cadr ($2),
1353                         $4));
1354                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1355         }
1356         | UNSET context_prop_spec {
1357                 $$ = property_op_to_music (scm_list_2 (
1358                         ly_symbol2scm ("unset"),
1359                         scm_cadr ($2)));
1360                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1361         }
1362         | ONCE music_property_def {
1363                 SCM e = $2->get_property ("element");
1364                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1365                 $$ = $2;
1366
1367         }
1368         ;
1369
1370
1371 string:
1372         STRING {
1373                 $$ = $1;
1374         }
1375         | STRING_IDENTIFIER {
1376                 $$ = $1;
1377         }
1378         | string '+' string {
1379                 $$ = scm_string_append (scm_list_2 ($1, $3));
1380         }
1381         ;
1382
1383 simple_string: STRING {
1384                 $$ = $1;
1385         }
1386         | LYRICS_STRING {
1387                 $$ = $1;
1388         }
1389         | STRING_IDENTIFIER {
1390                 $$ = $1;
1391         }
1392         ;
1393
1394 scalar: string {
1395                 $$ = $1;
1396         }
1397         | LYRICS_STRING {
1398                 $$ = $1;
1399         }
1400         | bare_number {
1401                 $$ = $1;
1402         }
1403         | embedded_scm {
1404                 $$ = $1;
1405         }
1406         | full_markup {
1407                 $$ = $1;
1408         }
1409         | DIGIT {
1410                 $$ = scm_from_int ($1);
1411         }
1412         ;
1413
1414 /*
1415
1416 pre_events doesn't contain anything. It is a trick:
1417
1418 Adding pre_events to the simple_element
1419 makes the choice between
1420
1421   string:  STRING
1422
1423 and
1424
1425   simple_element: STRING
1426
1427 a single shift/reduction conflict.
1428
1429 nevertheless, this is not very clean, and we should find a different
1430 solution.
1431
1432 */
1433 pre_events: /* empty */
1434         ;
1435
1436 event_chord:
1437         pre_events simple_element post_events   {
1438                 SCM elts = $2-> get_property ("elements");
1439
1440                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1441
1442                 $2->set_property ("elements", elts);
1443                 /* why is this giving wrong start location? -ns
1444                  * $2->set_spot (@$); */
1445                 Input i;
1446                 i.set_location (@2, @3);
1447                 $2->set_spot (i);
1448                 $$ = $2;
1449         }
1450         | command_element
1451         | note_chord_element
1452         ;
1453
1454
1455 note_chord_element:
1456         chord_body optional_notemode_duration post_events
1457         {
1458                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1459                 SCM es = $1->get_property ("elements");
1460                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1461
1462                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1463                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1464                 es = ly_append2 (es, postevs);
1465
1466                 $1-> set_property ("elements", es);
1467                 $1->set_spot (@$);
1468                 $$ = $1;
1469         }
1470         ;
1471
1472 chord_open: '<'
1473         ;
1474
1475 chord_close: '>'
1476         ;
1477
1478 simul_open: DOUBLE_ANGLE_OPEN
1479         ;
1480
1481 simul_close: DOUBLE_ANGLE_CLOSE
1482         ;
1483
1484 chord_body:
1485         chord_open chord_body_elements chord_close
1486         {
1487                 $$ = MY_MAKE_MUSIC ("EventChord");
1488                 $$->set_spot (@$);
1489                 $$->set_property ("elements",
1490                         scm_reverse_x ($2, SCM_EOL));
1491         }
1492         ;
1493
1494 chord_body_elements:
1495         /* empty */             { $$ = SCM_EOL; }
1496         | chord_body_elements chord_body_element {
1497                 $$ = scm_cons ($2->self_scm (), $1);
1498                 $2->unprotect ();
1499         }
1500         ;
1501
1502 chord_body_element:
1503         pitch exclamations questions octave_check post_events
1504         {
1505                 int q = $3;
1506                 int ex = $2;
1507                 SCM check = $4;
1508                 SCM post = $5;
1509
1510                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1511                 n->set_property ("pitch", $1);
1512                 n->set_spot (@$);
1513                 if (q % 2)
1514                         n->set_property ("cautionary", SCM_BOOL_T);
1515                 if (ex % 2 || q % 2)
1516                         n->set_property ("force-accidental", SCM_BOOL_T);
1517
1518                 if (scm_is_pair (post)) {
1519                         SCM arts = scm_reverse_x (post, SCM_EOL);
1520                         n->set_property ("articulations", arts);
1521                 }
1522                 if (scm_is_number (check))
1523                 {
1524                         int q = scm_to_int (check);
1525                         n->set_property ("absolute-octave", scm_from_int (q-1));
1526                 }
1527
1528
1529                 $$ = n;
1530         }
1531         | DRUM_PITCH post_events {
1532                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1533                 n->set_property ("duration", $2);
1534                 n->set_property ("drum-type", $1);
1535                 n->set_spot (@$);
1536
1537                 if (scm_is_pair ($2)) {
1538                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1539                         n->set_property ("articulations", arts);
1540                 }
1541                 $$ = n;
1542         }
1543         | music_function_chord_body {
1544                 $$ = run_music_function (THIS, $1);
1545                 $$->set_spot (@$);
1546         }
1547         ;
1548
1549 music_function_chord_body:
1550         MUSIC_FUNCTION {
1551                 $$ = scm_list_2 ($1, make_input (@$));
1552         }
1553         | music_function_musicless_prefix chord_body_element {
1554                 $$ = ly_append2 ($1, scm_list_1 ($2->self_scm ()));
1555                 $2->unprotect ();
1556         }
1557         ;
1558
1559 music_function_event:
1560         music_function_musicless_prefix post_event {
1561                 $$ = ly_append2 ($1, scm_list_1 ($2->self_scm ()));
1562                 $2->unprotect ();
1563         }
1564         ;
1565
1566 /*
1567 TODO: use code generation for this
1568 */
1569 music_function_musicless_prefix:
1570         MUSIC_FUNCTION_MUSIC {
1571                 $$ = scm_list_2 ($1, make_input (@$));
1572         }
1573         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument {
1574                 $$ = scm_list_3 ($1, make_input (@$), $2);
1575         }
1576         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument {
1577                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1578         }
1579         | MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument {
1580                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1581         }
1582         | MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument function_scm_argument {
1583                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
1584         }
1585         ;
1586
1587
1588 command_element:
1589         command_event {
1590                 $$ = MY_MAKE_MUSIC ("EventChord");
1591                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1592                 $1->unprotect();
1593
1594                 $$-> set_spot (@$);
1595                 $1-> set_spot (@$);
1596         }
1597         | SKIP duration_length {
1598                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1599                 skip->set_property ("duration", $2);
1600                 skip->set_spot (@$);
1601                 $$ = skip;
1602         }
1603         | E_BRACKET_OPEN {
1604                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1605                 m->set_property ("span-direction", scm_from_int (START));
1606                 m->set_spot (@$);
1607
1608                 $$ = MY_MAKE_MUSIC ("EventChord");
1609                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1610                 m->unprotect();
1611                 $$->set_spot (@$);
1612         }
1613         | E_BRACKET_CLOSE {
1614                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1615                 m->set_property ("span-direction", scm_from_int (STOP));
1616                 m->set_spot (@$);
1617
1618                 $$ = MY_MAKE_MUSIC ("EventChord");
1619                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1620                 $$->set_spot (@$);
1621                 m->unprotect ();
1622         }
1623         | E_BACKSLASH {
1624                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1625                 $$->set_spot (@$);
1626         }
1627         | '|'      {
1628                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1629
1630                 if (Music * m = unsmob_music (pipe))
1631                         $$ = m->clone ();
1632                 else
1633                         $$ = MY_MAKE_MUSIC ("BarCheck");
1634
1635                 $$->set_spot (@$);
1636         }
1637         | TRANSPOSITION pitch {
1638                 Pitch middle_c;
1639                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1640                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1641                                          sounds_as_c.smobbed_copy());
1642                 $$->set_spot (@$);
1643                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1644                         $$, SCM_EOL, false);
1645         }
1646         | PARTIAL duration_length       {
1647                 Moment m = - unsmob_duration ($2)->get_length ();
1648                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1649                 p->set_spot (@$);
1650                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1651                                         p, SCM_EOL, false);
1652                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1653                                         p, SCM_EOL, false);
1654                 $$ = p;
1655         }
1656
1657         | TIME_T fraction  {
1658                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1659
1660                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1661                 $$ = unsmob_music (result);
1662                 $$->protect ();
1663         }
1664         | MARK scalar {
1665                 SCM proc = ly_lily_module_constant ("make-mark-set");
1666
1667                 SCM result = scm_call_1 (proc, $2);
1668                 $$ = unsmob_music (result);
1669                 $$->protect ();
1670         }
1671         ;
1672
1673 command_event:
1674         E_TILDE {
1675                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1676         }
1677         | MARK DEFAULT  {
1678                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1679                 $$ = m;
1680         }
1681         | tempo_event {
1682                 $$ = $1;
1683         }
1684         | KEY DEFAULT {
1685                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1686                 $$ = key;
1687         }
1688         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1689
1690                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1691                 if (scm_ilength ($3) > 0)
1692                 {
1693                         key->set_property ("pitch-alist", $3);
1694                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1695                         key->transpose (* unsmob_pitch ($2));
1696                 } else {
1697                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1698                 }
1699
1700                 $$ = key;
1701         }
1702         ;
1703
1704
1705 post_events:
1706         /* empty */ {
1707                 $$ = SCM_EOL;
1708         }
1709         | post_events post_event {
1710                 $2->set_spot (@2);
1711                 $$ = scm_cons ($2->self_scm (), $$);
1712                 $2->unprotect ();
1713         }
1714         ;
1715
1716 post_event:
1717         direction_less_event {
1718                 $$ = $1;
1719         }
1720         | '-' music_function_event {
1721                 Music *mus = run_music_function (THIS, $2);
1722                 mus->set_spot (@1);
1723                 $$ = mus;
1724         }
1725         | HYPHEN {
1726                 if (!THIS->lexer_->is_lyric_state ())
1727                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1728                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1729         }
1730         | EXTENDER {
1731                 if (!THIS->lexer_->is_lyric_state ())
1732                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1733                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1734         }
1735         | script_dir direction_reqd_event {
1736                 if ($1)
1737                         $2->set_property ("direction", scm_from_int ($1));
1738                 $$ = $2;
1739         }
1740         | script_dir direction_less_event {
1741                 if ($1)
1742                         $2->set_property ("direction", scm_from_int ($1));
1743                 $$ = $2;
1744         }
1745         | string_number_event
1746         ;
1747
1748 string_number_event:
1749         E_UNSIGNED {
1750                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1751                 s->set_property ("string-number", scm_from_int ($1));
1752                 s->set_spot (@$);
1753                 $$ = s;
1754         }
1755         ;
1756
1757 direction_less_char:
1758         '['  {
1759                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1760         }
1761         | ']'  {
1762                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1763         }
1764         | '~'  {
1765                 $$ = ly_symbol2scm ("tildeSymbol");
1766         }
1767         | '('  {
1768                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1769         }
1770         | ')'  {
1771                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1772         }
1773         | E_EXCLAMATION  {
1774                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1775         }
1776         | E_OPEN  {
1777                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1778         }
1779         | E_CLOSE  {
1780                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1781         }
1782         | E_ANGLE_CLOSE  {
1783                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1784         }
1785         | E_ANGLE_OPEN  {
1786                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1787         }
1788         ;
1789
1790 direction_less_event:
1791         direction_less_char {
1792                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1793                 Music * m = 0;
1794                 if (unsmob_music (predefd))
1795                 {
1796                         m = unsmob_music (predefd)->clone ();
1797                 }
1798                 else
1799                 {
1800                         m = MY_MAKE_MUSIC ("Music");
1801                 }
1802                 m->set_spot (@$);
1803                 $$ = m;
1804         }
1805         | EVENT_IDENTIFIER      {
1806                 $$ = unsmob_music ($1);
1807         }
1808         | tremolo_type  {
1809                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1810                a->set_spot (@$);
1811                a->set_property ("tremolo-type", scm_from_int ($1));
1812                $$ = a;
1813         }
1814         ;
1815
1816 direction_reqd_event:
1817         gen_text_def {
1818                 $$ = $1;
1819         }
1820         | script_abbreviation {
1821                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1822                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1823                 if (scm_is_string (s))
1824                         a->set_property ("articulation-type", s);
1825                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1826                 $$ = a;
1827         }
1828         ;
1829
1830 octave_check:
1831         /**/ { $$ = SCM_EOL; }
1832         | '='  { $$ = scm_from_int (0); }
1833         | '=' sub_quotes { $$ = scm_from_int ($2); }
1834         | '=' sup_quotes { $$ = scm_from_int ($2); }
1835         ;
1836
1837 sup_quotes:
1838         '\'' {
1839                 $$ = 1;
1840         }
1841         | sup_quotes '\'' {
1842                 $$ ++;
1843         }
1844         ;
1845
1846 sub_quotes:
1847         ',' {
1848                 $$ = 1;
1849         }
1850         | sub_quotes ',' {
1851                 $$++;
1852         }
1853         ;
1854
1855 steno_pitch:
1856         NOTENAME_PITCH  {
1857                 $$ = $1;
1858         }
1859         | NOTENAME_PITCH sup_quotes     {
1860                 Pitch p = *unsmob_pitch ($1);
1861                 p = p.transposed (Pitch ($2,0,0));
1862                 $$ = p.smobbed_copy ();
1863         }
1864         | NOTENAME_PITCH sub_quotes      {
1865                 Pitch p =* unsmob_pitch ($1);
1866                 p = p.transposed (Pitch (-$2,0,0));
1867                 $$ = p.smobbed_copy ();
1868         }
1869         ;
1870
1871 /*
1872 ugh. duplication
1873 */
1874
1875 steno_tonic_pitch:
1876         TONICNAME_PITCH {
1877                 $$ = $1;
1878         }
1879         | TONICNAME_PITCH sup_quotes    {
1880                 Pitch p = *unsmob_pitch ($1);
1881                 p = p.transposed (Pitch ($2,0,0));
1882                 $$ = p.smobbed_copy ();
1883         }
1884         | TONICNAME_PITCH sub_quotes     {
1885                 Pitch p =* unsmob_pitch ($1);
1886
1887                 p = p.transposed (Pitch (-$2,0,0));
1888                 $$ = p.smobbed_copy ();
1889         }
1890         ;
1891
1892 pitch:
1893         steno_pitch {
1894                 $$ = $1;
1895         }
1896         ;
1897
1898 pitch_also_in_chords:
1899         pitch
1900         | steno_tonic_pitch
1901         ;
1902
1903 gen_text_def:
1904         full_markup {
1905                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1906                 t->set_property ("text", $1);
1907                 t->set_spot (@$);
1908                 $$ = t;
1909         }
1910         | string {
1911                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1912                 t->set_property ("text",
1913                         make_simple_markup ($1));
1914                 t->set_spot (@$);
1915                 $$ = t;
1916
1917         }
1918         | DIGIT {
1919                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1920                 t->set_property ("digit", scm_from_int ($1));
1921                 t->set_spot (@$);
1922                 $$ = t;
1923         }
1924         ;
1925
1926 script_abbreviation:
1927         '^'             {
1928                 $$ = scm_makfrom0str ("Hat");
1929         }
1930         | '+'           {
1931                 $$ = scm_makfrom0str ("Plus");
1932         }
1933         | '-'           {
1934                 $$ = scm_makfrom0str ("Dash");
1935         }
1936         | '|'           {
1937                 $$ = scm_makfrom0str ("Bar");
1938         }
1939         | '>'           {
1940                 $$ = scm_makfrom0str ("Larger");
1941         }
1942         | '.'           {
1943                 $$ = scm_makfrom0str ("Dot");
1944         }
1945         | '_' {
1946                 $$ = scm_makfrom0str ("Underscore");
1947         }
1948         ;
1949
1950 script_dir:
1951         '_'     { $$ = DOWN; }
1952         | '^'   { $$ = UP; }
1953         | '-'   { $$ = CENTER; }
1954         ;
1955
1956
1957 absolute_pitch:
1958         steno_pitch     {
1959                 $$ = $1;
1960         }
1961         ;
1962
1963 duration_length:
1964         multiplied_duration {
1965                 $$ = $1;
1966         }
1967         ;
1968
1969 optional_notemode_duration:
1970         {
1971                 Duration dd = THIS->default_duration_;
1972                 $$ = dd.smobbed_copy ();
1973         }
1974         | multiplied_duration   {
1975                 $$ = $1;
1976                 THIS->default_duration_ = *unsmob_duration ($$);
1977         }
1978         ;
1979
1980 steno_duration:
1981         bare_unsigned dots              {
1982                 int len = 0;
1983                 if (!is_duration ($1))
1984                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
1985                 else
1986                         len = intlog2 ($1);
1987
1988                 $$ = Duration (len, $2).smobbed_copy ();
1989         }
1990         | DURATION_IDENTIFIER dots      {
1991                 Duration *d = unsmob_duration ($1);
1992                 Duration k (d->duration_log (), d->dot_count () + $2);
1993                 *d = k;
1994                 $$ = $1;
1995         }
1996         ;
1997
1998 multiplied_duration:
1999         steno_duration {
2000                 $$ = $1;
2001         }
2002         | multiplied_duration '*' bare_unsigned {
2003                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2004         }
2005         | multiplied_duration '*' FRACTION {
2006                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2007
2008                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2009         }
2010         ;
2011
2012 fraction:
2013         FRACTION { $$ = $1; }
2014         | UNSIGNED '/' UNSIGNED {
2015                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2016         }
2017         ;
2018
2019 dots:
2020         /* empty */     {
2021                 $$ = 0;
2022         }
2023         | dots '.' {
2024                 $$ ++;
2025         }
2026         ;
2027
2028 tremolo_type:
2029         ':'     {
2030                 $$ = 0;
2031         }
2032         | ':' bare_unsigned {
2033                 if (!is_duration ($2))
2034                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2035                 $$ = $2;
2036         }
2037         ;
2038
2039 bass_number:
2040         DIGIT   {
2041                 $$ = scm_from_int ($1);
2042         }
2043         | UNSIGNED {
2044                 $$ = scm_from_int ($1);
2045         }
2046         | STRING { $$ = $1; }
2047         | full_markup { $$ = $1; }
2048         ;
2049
2050 figured_bass_alteration:
2051         '-'     { $$ = -2; }
2052         | '+'   { $$ = 2; }
2053         | '!'   { $$ = 0; }
2054         ;
2055
2056 bass_figure:
2057         FIGURE_SPACE {
2058                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2059                 $$ = bfr->self_scm ();
2060                 bfr->unprotect ();
2061                 bfr->set_spot (@1);
2062         }
2063         | bass_number  {
2064                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2065                 $$ = bfr->self_scm ();
2066
2067                 if (scm_is_number ($1))
2068                         bfr->set_property ("figure", $1);
2069                 else if (Text_interface::is_markup ($1))
2070                         bfr->set_property ("text", $1);
2071
2072                 bfr->unprotect ();
2073                 bfr->set_spot (@1);
2074         }
2075         | bass_figure ']' {
2076                 $$ = $1;
2077                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2078         }
2079         | bass_figure figured_bass_alteration {
2080                 Music *m = unsmob_music ($1);
2081                 if ($2) {
2082                         SCM salter = m->get_property ("alteration");
2083                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2084                         m->set_property ("alteration",
2085                                 scm_from_int (alter + $2));
2086                 } else {
2087                         m->set_property ("alteration", scm_from_int (0));
2088                 }
2089         }
2090         | bass_figure figured_bass_modification  {
2091                 Music *m = unsmob_music ($1);
2092                 if ($2 == ly_symbol2scm ("plus"))
2093                         {
2094                         m->set_property ("augmented", SCM_BOOL_T);
2095                         }
2096                 else if ($2 == ly_symbol2scm ("slash"))
2097                         {
2098                         m->set_property ("diminished", SCM_BOOL_T);
2099                         }
2100                 else if ($2 == ly_symbol2scm ("exclamation"))
2101                         {
2102                         m->set_property ("no-continuation", SCM_BOOL_T);
2103                         }
2104         }
2105         ;
2106
2107
2108 figured_bass_modification:
2109         E_PLUS          {
2110                 $$ = ly_symbol2scm ("plus");
2111         }
2112         | E_EXCLAMATION {
2113                 $$ = ly_symbol2scm ("exclamation");
2114         }
2115         | '/'           {
2116                 $$ = ly_symbol2scm ("slash");
2117         }
2118         ;
2119
2120 br_bass_figure:
2121         bass_figure {
2122                 $$ = $1;
2123         }
2124         | '[' bass_figure {
2125                 $$ = $2;
2126                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2127         }
2128         ;
2129
2130 figure_list:
2131         /**/            {
2132                 $$ = SCM_EOL;
2133         }
2134         | figure_list br_bass_figure {
2135                 $$ = scm_cons ($2, $1);
2136         }
2137         ;
2138
2139 figure_spec:
2140         FIGURE_OPEN figure_list FIGURE_CLOSE {
2141                 Music *m = MY_MAKE_MUSIC ("EventChord");
2142                 $2 = scm_reverse_x ($2, SCM_EOL);
2143                 m->set_property ("elements", $2);
2144                 $$ = m->self_scm ();
2145         }
2146         ;
2147
2148
2149 optional_rest:
2150         /**/   { $$ = 0; }
2151         | REST { $$ = 1; }
2152         ;
2153
2154 simple_element:
2155         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2156                 if (!THIS->lexer_->is_note_state ())
2157                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2158
2159                 Music *n = 0;
2160                 if ($6)
2161                         n = MY_MAKE_MUSIC ("RestEvent");
2162                 else
2163                         n = MY_MAKE_MUSIC ("NoteEvent");
2164
2165                 n->set_property ("pitch", $1);
2166                 n->set_property ("duration", $5);
2167
2168                 if (scm_is_number ($4))
2169                 {
2170                         int q = scm_to_int ($4);
2171                         n->set_property ("absolute-octave", scm_from_int (q-1));
2172                 }
2173
2174                 if ($3 % 2)
2175                         n->set_property ("cautionary", SCM_BOOL_T);
2176                 if ($2 % 2 || $3 % 2)
2177                         n->set_property ("force-accidental", SCM_BOOL_T);
2178
2179                 Music *v = MY_MAKE_MUSIC ("EventChord");
2180                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2181                 n->unprotect ();
2182
2183                 v->set_spot (@$);
2184                 n->set_spot (@$);
2185                 $$ = v;
2186         }
2187         | DRUM_PITCH optional_notemode_duration {
2188                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2189                 n->set_property ("duration", $2);
2190                 n->set_property ("drum-type", $1);
2191
2192                 Music *v = MY_MAKE_MUSIC ("EventChord");
2193                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2194                 n->unprotect ();
2195                 v->set_spot (@$);
2196                 n->set_spot (@$);
2197                 $$ = v;
2198
2199         }
2200         | figure_spec optional_notemode_duration {
2201                 Music *m = unsmob_music ($1);
2202                 m->set_spot (@$);
2203                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2204                 {
2205                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2206                 }
2207                 $$ = m;
2208         }
2209         | RESTNAME optional_notemode_duration           {
2210                 Music *ev = 0;
2211                 if (ly_scm2string ($1) == "s") {
2212                         /* Space */
2213                         ev = MY_MAKE_MUSIC ("SkipEvent");
2214                   }
2215                 else {
2216                         ev = MY_MAKE_MUSIC ("RestEvent");
2217
2218                     }
2219                 ev->set_property ("duration", $2);
2220                 ev->set_spot (@$);
2221                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2222                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2223                 velt->set_spot (@$);
2224
2225                 ev->unprotect();
2226
2227                 $$ = velt;
2228         }
2229         | MULTI_MEASURE_REST optional_notemode_duration         {
2230                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2231                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2232                 $$ = unsmob_music (mus);
2233                 $$->protect ();
2234         }
2235
2236         | lyric_element optional_notemode_duration      {
2237                 if (!THIS->lexer_->is_lyric_state ())
2238                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2239
2240                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2241                 levent->set_property ("text", $1);
2242                 levent->set_property ("duration",$2);
2243                 levent->set_spot (@$);
2244                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2245                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2246
2247                 $$= velt;
2248         }
2249         | new_chord {
2250                 if (!THIS->lexer_->is_chord_state ())
2251                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2252                 $$ = unsmob_music ($1);
2253         }
2254         ;
2255
2256 lyric_element:
2257         lyric_markup {
2258                 $$ = $1;
2259         }
2260         | LYRICS_STRING {
2261                 $$ = $1;
2262         }
2263         ;
2264
2265 new_chord:
2266         steno_tonic_pitch optional_notemode_duration   {
2267                 $$ = make_chord ($1, $2, SCM_EOL);
2268         }
2269         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2270                 SCM its = scm_reverse_x ($4, SCM_EOL);
2271                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2272         }
2273         ;
2274
2275 chord_items:
2276         /**/ {
2277                 $$ = SCM_EOL;
2278         }
2279         | chord_items chord_item {
2280                 $$ = scm_cons ($2, $$);
2281         }
2282         ;
2283
2284 chord_separator:
2285         CHORD_COLON {
2286                 $$ = ly_symbol2scm ("chord-colon");
2287         }
2288         | CHORD_CARET {
2289                 $$ = ly_symbol2scm ("chord-caret");
2290         }
2291         | CHORD_SLASH steno_tonic_pitch {
2292                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2293         }
2294         | CHORD_BASS steno_tonic_pitch {
2295                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2296         }
2297         ;
2298
2299 chord_item:
2300         chord_separator {
2301                 $$ = $1;
2302         }
2303         | step_numbers {
2304                 $$ = scm_reverse_x ($1, SCM_EOL);
2305         }
2306         | CHORD_MODIFIER  {
2307                 $$ = $1;
2308         }
2309         ;
2310
2311 step_numbers:
2312         step_number { $$ = scm_cons ($1, SCM_EOL); }
2313         | step_numbers '.' step_number {
2314                 $$ = scm_cons ($3, $$);
2315         }
2316         ;
2317
2318 step_number:
2319         bare_unsigned {
2320                 $$ = make_chord_step ($1, 0);
2321         }
2322         | bare_unsigned '+' {
2323                 $$ = make_chord_step ($1, SHARP);
2324         }
2325         | bare_unsigned CHORD_MINUS {
2326                 $$ = make_chord_step ($1, FLAT);
2327         }
2328         ;
2329
2330 /*
2331         UTILITIES
2332
2333 TODO: should deprecate in favor of Scheme?
2334
2335  */
2336 number_expression:
2337         number_expression '+' number_term {
2338                 $$ = scm_sum ($1, $3);
2339         }
2340         | number_expression '-' number_term {
2341                 $$ = scm_difference ($1, $3);
2342         }
2343         | number_term
2344         ;
2345
2346 number_term:
2347         number_factor {
2348                 $$ = $1;
2349         }
2350         | number_factor '*' number_factor {
2351                 $$ = scm_product ($1, $3);
2352         }
2353         | number_factor '/' number_factor {
2354                 $$ = scm_divide ($1, $3);
2355         }
2356         ;
2357
2358 number_factor:
2359         '-'  number_factor { /* %prec UNARY_MINUS */
2360                 $$ = scm_difference ($2, SCM_UNDEFINED);
2361         }
2362         | bare_number
2363         ;
2364
2365
2366 bare_number:
2367         UNSIGNED        {
2368                 $$ = scm_from_int ($1);
2369         }
2370         | REAL          {
2371                 $$ = $1;
2372         }
2373         | NUMBER_IDENTIFIER             {
2374                 $$ = $1;
2375         }
2376         | REAL NUMBER_IDENTIFIER        {
2377                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2378         }
2379         | UNSIGNED NUMBER_IDENTIFIER    {
2380                 $$ = scm_from_double ($1 *scm_to_double ($2));
2381         }
2382         ;
2383
2384
2385 bare_unsigned:
2386         UNSIGNED {
2387                         $$ = $1;
2388         }
2389         | DIGIT {
2390                 $$ = $1;
2391         }
2392         ;
2393
2394 exclamations:
2395                 { $$ = 0; }
2396         | exclamations '!'      { $$ ++; }
2397         ;
2398
2399 questions:
2400                 { $$ = 0; }
2401         | questions '?' { $$ ++; }
2402         ;
2403
2404 /*
2405 This should be done more dynamically if possible.
2406 */
2407
2408 lyric_markup:
2409         LYRIC_MARKUP_IDENTIFIER {
2410                 $$ = $1;
2411         }
2412         | LYRIC_MARKUP
2413                 { THIS->lexer_->push_markup_state (); }
2414         markup_top {
2415                 $$ = $3;
2416                 THIS->lexer_->pop_state ();
2417         }
2418         ;
2419
2420 full_markup:
2421         MARKUP_IDENTIFIER {
2422                 $$ = $1;
2423         }
2424         | MARKUP
2425                 { THIS->lexer_->push_markup_state (); }
2426         markup_top {
2427                 $$ = $3;
2428                 THIS->lexer_->pop_state ();
2429         }
2430         ;
2431
2432 markup_top:
2433         markup_list {
2434                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2435         }
2436         | markup_head_1_list simple_markup      {
2437                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2438         }
2439         | simple_markup {
2440                 $$ = $1;
2441         }
2442         ;
2443
2444 markup_list:
2445         markup_composed_list {
2446                 $$ = $1;
2447         }
2448         | markup_braced_list {
2449                 $$ = $1;
2450         }
2451         ;
2452
2453 markup_composed_list:
2454         markup_head_1_list markup_braced_list {
2455                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2456
2457         }
2458         ;
2459
2460 markup_braced_list:
2461         '{' markup_braced_list_body '}' {
2462                 $$ = scm_reverse_x ($2, SCM_EOL);
2463         }
2464         ;
2465
2466 markup_braced_list_body:
2467         /* empty */     {  $$ = SCM_EOL; }
2468         | markup_braced_list_body markup {
2469                 $$ = scm_cons ($2, $1);
2470         }
2471         | markup_braced_list_body markup_list {
2472                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2473         }
2474         ;
2475
2476 markup_head_1_item:
2477         MARKUP_HEAD_MARKUP0     {
2478                 $$ = scm_list_1 ($1);
2479         }
2480         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2481                 $$ = scm_list_2 ($1, $2);
2482         }
2483         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2484                 $$ = scm_list_3 ($1, $2, $3);
2485         }
2486         ;
2487
2488 markup_head_1_list:
2489         markup_head_1_item      {
2490                 $$ = scm_list_1 ($1);
2491         }
2492         | markup_head_1_list markup_head_1_item {
2493                 $$ = scm_cons ($2, $1);
2494         }
2495         ;
2496
2497 simple_markup:
2498         STRING {
2499                 $$ = make_simple_markup ($1);
2500         }
2501         | MARKUP_IDENTIFIER {
2502                 $$ = $1;
2503         }
2504         | LYRIC_MARKUP_IDENTIFIER {
2505                 $$ = $1;
2506         }
2507         | STRING_IDENTIFIER {
2508                 $$ = $1;
2509         }
2510         | SCORE {
2511                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2512                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2513         } '{' score_body '}' {
2514                 Score * sc = $4;
2515                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2516                 sc->unprotect ();
2517                 THIS->lexer_->pop_state ();
2518         }
2519         | MARKUP_HEAD_SCM0 embedded_scm {
2520                 $$ = scm_list_2 ($1, $2);
2521         }
2522         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2523                 $$ = scm_list_4 ($1, $2, $3, $4);
2524         }
2525         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2526                 $$ = scm_list_3 ($1, $2, $3);
2527         }
2528         | MARKUP_HEAD_EMPTY {
2529                 $$ = scm_list_1 ($1);
2530         }
2531         | MARKUP_HEAD_LIST0 markup_list {
2532                 $$ = scm_list_2 ($1,$2);
2533         }
2534         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2535                 $$ = scm_list_3 ($1, $2, $3);
2536         }
2537         ;
2538
2539 markup:
2540         markup_head_1_list simple_markup        {
2541                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2542                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2543         }
2544         | simple_markup {
2545                 $$ = $1;
2546         }
2547         ;
2548
2549 %%
2550
2551 void
2552 Lily_parser::set_yydebug (bool )
2553 {
2554 #if 0
2555         yydebug = 1;
2556 #endif
2557 }
2558
2559 void
2560 Lily_parser::do_yyparse ()
2561 {
2562         yyparse ((void*)this);
2563 }
2564
2565
2566
2567
2568
2569 /*
2570
2571 It is a little strange to have this function in this file, but
2572 otherwise, we have to import music classes into the lexer.
2573
2574 */
2575 int
2576 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2577 {
2578         if (scm_is_string (sid)) {
2579                 *destination = sid;
2580                 return STRING_IDENTIFIER;
2581         } else if (unsmob_book (sid)) {
2582                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2583                 return BOOK_IDENTIFIER;
2584         } else if (scm_is_number (sid)) {
2585                 *destination = sid;
2586                 return NUMBER_IDENTIFIER;
2587         } else if (unsmob_context_def (sid)) {
2588                 *destination = unsmob_context_def (sid)->clone_scm ();
2589                 return CONTEXT_DEF_IDENTIFIER;
2590         } else if (unsmob_score (sid)) {
2591                 Score *score = new Score (*unsmob_score (sid));
2592                 *destination = score->self_scm ();
2593                 return SCORE_IDENTIFIER;
2594         } else if (Music *mus = unsmob_music (sid)) {
2595                 mus = mus->clone ();
2596                 *destination = mus->self_scm ();
2597                 unsmob_music (*destination)->
2598                         set_property ("origin", make_input (last_input_));
2599
2600                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2601                         != SCM_BOOL_F;
2602
2603                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2604         } else if (unsmob_duration (sid)) {
2605                 *destination = unsmob_duration (sid)->smobbed_copy ();
2606                 return DURATION_IDENTIFIER;
2607         } else if (unsmob_output_def (sid)) {
2608                 Output_def *p = unsmob_output_def (sid);
2609                 p = p->clone ();
2610
2611                 *destination = p->self_scm ();
2612                 return OUTPUT_DEF_IDENTIFIER;
2613         } else if (Text_interface::is_markup (sid)) {
2614                 *destination = sid;
2615                 if (is_lyric_state ())
2616                         return LYRIC_MARKUP_IDENTIFIER;
2617                 return MARKUP_IDENTIFIER;
2618         }
2619
2620         return -1;
2621 }
2622
2623 Music *
2624 property_op_to_music (SCM op)
2625 {
2626         Music *m = 0;
2627         SCM tag = scm_car (op);
2628         SCM symbol = scm_cadr (op);
2629         SCM args = scm_cddr (op);
2630         SCM grob_val = SCM_UNDEFINED;
2631         SCM grob_path = SCM_UNDEFINED;
2632         SCM val = SCM_UNDEFINED;
2633
2634         if (tag == ly_symbol2scm ("assign"))
2635                 {
2636                 m = MY_MAKE_MUSIC ("PropertySet");
2637                 val = scm_car (args);
2638                 }
2639         else if (tag == ly_symbol2scm ("unset"))
2640                 m = MY_MAKE_MUSIC ("PropertyUnset");
2641         else if (tag == ly_symbol2scm ("push"))
2642                 {
2643                 m = MY_MAKE_MUSIC ("OverrideProperty");
2644                 grob_val = scm_car (args);
2645                 grob_path = scm_cdr (args);
2646                 m->set_property ("pop-first", SCM_BOOL_T);
2647                 }
2648         else if (tag == ly_symbol2scm ("pop")) {
2649                 m = MY_MAKE_MUSIC ("RevertProperty");
2650                 grob_path = args;
2651                 }
2652
2653         m->set_property ("symbol", symbol);
2654
2655         if (val != SCM_UNDEFINED)
2656                 m->set_property ("value", val);
2657         if (grob_val != SCM_UNDEFINED)
2658                 m->set_property ("grob-value", grob_val);
2659         if (grob_path != SCM_UNDEFINED)
2660                 m->set_property ("grob-property-path", grob_path);
2661
2662         return m;
2663 }
2664
2665 Music*
2666 context_spec_music (SCM type, SCM id, Music *m, SCM ops, bool create_new)
2667 {
2668         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2669
2670         csm->set_property ("element", m->self_scm ());
2671         m->unprotect ();
2672
2673         csm->set_property ("context-type",
2674                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2675         csm->set_property ("property-operations", ops);
2676         if (create_new)
2677                 csm->set_property ("create-new", SCM_BOOL_T);
2678
2679         if (scm_is_string (id))
2680                 csm->set_property ("context-id", id);
2681         return csm;
2682 }
2683
2684 SCM
2685 get_next_unique_context_id ()
2686 {
2687         return scm_makfrom0str ("$uniqueContextId");
2688 }
2689
2690
2691 SCM
2692 get_next_unique_lyrics_context_id ()
2693 {
2694         static int new_context_count;
2695         char s[128];
2696         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2697         return scm_makfrom0str (s);
2698 }
2699
2700
2701 Music *
2702 run_music_function (Lily_parser *parser, SCM expr)
2703 {
2704         SCM func = scm_car (expr);
2705         Input *loc = unsmob_input (scm_cadr (expr));
2706         SCM args = scm_cddr (expr);
2707         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2708
2709         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2710         bool ok  = true;
2711
2712         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2713         {
2714                 parser->error_level_ = 1;
2715                 ok = false;
2716         }
2717
2718         SCM m = SCM_EOL;
2719         if (ok)
2720                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2721                                                  scm_cdr (expr)));
2722
2723
2724         Music* retval = 0;
2725         if (unsmob_music (m))
2726                 {
2727                 retval = unsmob_music (m);
2728                 retval->protect ();
2729                 }
2730         else
2731                 {
2732                 if (ok)
2733                         loc->error (_ ("music head function must return Music object"));
2734                 retval = MY_MAKE_MUSIC ("Music");
2735                 }
2736         retval->set_spot (*loc);
2737         return retval;
2738 }
2739
2740 bool
2741 is_regular_identifier (SCM id)
2742 {
2743   string str = ly_scm2string (id);
2744   char const *s = str.c_str ();
2745
2746   bool v = true;
2747 #if 0
2748   isalpha (*s);
2749   s++;
2750 #endif
2751   while (*s && v)
2752    {
2753         v = v && isalnum (*s);
2754         s++;
2755    }
2756   return v;
2757 }
2758
2759
2760 SCM
2761 get_first_context_id (SCM type, Music *m)
2762 {
2763         SCM id = m->get_property ("context-id");
2764         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2765             && scm_is_string (m->get_property ("context-id"))
2766             && scm_c_string_length (id) > 0)
2767         {
2768                 return id;
2769         }
2770         return SCM_EOL;
2771 }
2772
2773 SCM
2774 make_simple_markup (SCM a)
2775 {
2776         return a;
2777 }
2778
2779 bool
2780 is_duration (int t)
2781 {
2782   return t && t == 1 << intlog2 (t);
2783 }
2784
2785 void
2786 set_music_properties (Music *p, SCM a)
2787 {
2788   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2789         p->internal_set_property (scm_caar (k), scm_cdar (k));
2790 }
2791
2792
2793 SCM
2794 make_chord_step (int step, int alter)
2795 {
2796         if (step == 7)
2797                 alter += FLAT;
2798
2799         while (step < 0)
2800                 step += 7;
2801         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2802         return m.smobbed_copy ();
2803 }
2804
2805
2806 SCM
2807 make_chord (SCM pitch, SCM dur, SCM modification_list)
2808 {
2809         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2810         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2811
2812         unsmob_music (ch)->protect();
2813         return ch;
2814 }
2815
2816
2817 /* Todo: actually also use apply iso. call too ...  */
2818 bool
2819 ly_input_procedure_p (SCM x)
2820 {
2821         return ly_is_procedure (x)
2822                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2823 }
2824
2825 Music*
2826 set_property_music (SCM sym, SCM value)
2827 {
2828         Music *p = MY_MAKE_MUSIC ("PropertySet");
2829         p->set_property ("symbol", sym);
2830         p->set_property ("value", value);
2831         return p;
2832 }
2833
2834 Music*
2835 make_music_relative (Pitch start, Music *music)
2836 {
2837         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2838         relative->set_property ("element", music->self_scm ());
2839
2840         Pitch last = music->to_relative_octave (start);
2841         if (lily_1_8_relative)
2842                 music->set_property ("last-pitch", last.smobbed_copy ());
2843         return relative;
2844 }
2845
2846 Music *
2847 make_lyric_combine_music (SCM name, Music *music)
2848 {
2849         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2850         combine->set_property ("element", music->self_scm ());
2851         combine->set_property ("associated-context", name);
2852         return combine;
2853 }
2854
2855
2856 int
2857 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2858 {
2859         Lily_parser *pars = (Lily_parser*) v;
2860         Lily_lexer *lex = pars->lexer_;
2861
2862         lex->lexval = (void*) s;
2863         lex->lexloc = loc;
2864         lex->prepare_for_next_token ();
2865         return lex->yylex ();
2866 }