lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input-smob.hh"
  79 #include "input.hh"
  80 #include "international.hh"
  81 #include "lily-guile.hh"
  82 #include "lily-lexer.hh"
  83 #include "lily-parser.hh"
  84 #include "lilypond-input-version.hh"
  85 #include "main.hh"
  86 #include "misc.hh"
  87 #include "music.hh"
  88 #include "music.hh"
  89 #include "output-def.hh"
  90 #include "paper-book.hh"
  91 #include "program-option.hh"
  92 #include "scm-hash.hh"
  93 #include "score.hh"
  94 #include "text-interface.hh"
  95 #include "warn.hh"
  96
  97 %}
  98
  99
 100 %union {
 101         Book *book;
 102         Output_def *outputdef;
 103         SCM scm;
 104         std::string *string;
 105         Music *music;
 106         Score *score;
 107         int i;
 108 }
 109
 110 %{
 111
 112 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 113
 114 Music *property_op_to_music (SCM op);
 115 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
 116 SCM get_next_unique_context_id ();
 117 SCM get_next_unique_lyrics_context_id ();
 118
 119 #undef _
 120 #if !HAVE_GETTEXT
 121 #define _(x) x
 122 #else
 123 #include <libintl.h>
 124 #define _(x) gettext (x)
 125 #endif
 126
 127
 128
 129 Music *make_lyric_combine_music (SCM name, Music *music);
 130 Music *make_music_relative (Pitch start, Music *music);
 131 Music *run_music_function (Lily_parser *, SCM expr);
 132 Music *set_property_music (SCM sym, SCM value);
 133 SCM get_first_context_id (SCM type, Music *m);
 134 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 135 SCM make_chord_step (int step, int alter);
 136 SCM make_simple_markup (SCM a);
 137 bool is_duration (int t);
 138 bool is_regular_identifier (SCM id);
 139 bool ly_input_procedure_p (SCM x);
 140 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 141 void set_music_properties (Music *p, SCM a);
 142
 143 %}
 144
 145 /* The third option is an alias that will be used to display the
 146    syntax error.  Bison CVS now correctly handles backslash escapes.
 147
 148    FIXME: Bison needs to translate some of these, eg, STRING.
 149
 150 */
 151
 152 /* Keyword tokens with plain escaped name.  */
 153 %token ACCEPTS "\\accepts"
 154 %token ADDLYRICS "\\addlyrics"
 155 %token ADDQUOTE "\\addquote"
 156 %token ALIAS "\\alias"
 157 %token ALTERNATIVE "\\alternative"
 158 %token BOOK "\book"
 159 %token CHANGE "\\change"
 160 %token CHORDMODE "\\chordmode"
 161 %token CHORDS "\\chords"
 162 %token CONSISTS "\\consists"
 163 %token CONTEXT "\\context"
 164 %token DEFAULT "\\default"
 165 %token DEFAULTCHILD "\\defaultchild"
 166 %token DENIES "\\denies"
 167 %token DESCRIPTION "\\description"
 168 %token DRUMMODE "\\drummode"
 169 %token DRUMS "\\drums"
 170 %token FIGUREMODE "\\figuremode"
 171 %token FIGURES "\\figures"
 172 %token GROBDESCRIPTIONS "\\grobdescriptions"
 173 %token HEADER "\\header"
 174 %token INVALID "\\invalid"
 175 %token KEY "\\key"
 176 %token LAYOUT "\\layout"
 177 %token LYRICMODE "\\lyricmode"
 178 %token LYRICS "\\lyrics"
 179 %token LYRICSTO "\\lyricsto"
 180 %token MARK "\\mark"
 181 %token MARKUP "\\markup"
 182 %token MIDI "\\midi"
 183 %token NAME "\\name"
 184 %token NOTEMODE "\\notemode"
 185 %token OBJECTID "\\objectid"
 186 %token OCTAVE "\\octave"
 187 %token ONCE "\\once"
 188 %token OVERRIDE "\\override"
 189 %token PAPER "\\paper"
 190 %token PARTIAL "\\partial"
 191 %token RELATIVE "\\relative"
 192 %token REMOVE "\\remove"
 193 %token REPEAT "\\repeat"
 194 %token REST "\\rest"
 195 %token REVERT "\\revert"
 196 %token SCORE "\\score"
 197 %token SEQUENTIAL "\\sequential"
 198 %token SET "\\set"
 199 %token SIMULTANEOUS "\\simultaneous"
 200 %token SKIP "\\skip"
 201 %token TEMPO "\\tempo"
 202 %token TIMES "\\times"
 203 %token TRANSPOSE "\\transpose"
 204 %token TRANSPOSITION "\\transposition"
 205 %token TYPE "\\type"
 206 %token UNSET "\\unset"
 207 %token WITH "\\with"
 208
 209 /* Keyword token exceptions.  */
 210 %token TIME_T "\\time"
 211 %token NEWCONTEXT "\\new"
 212
 213
 214 /* Other string tokens.  */
 215
 216 %token CHORD_BASS "/+"
 217 %token CHORD_CARET "^"
 218 %token CHORD_COLON ":"
 219 %token CHORD_MINUS "-"
 220 %token CHORD_SLASH "/"
 221 %token DOUBLE_ANGLE_CLOSE ">>"
 222 %token DOUBLE_ANGLE_OPEN "<<"
 223 %token E_BACKSLASH "\\"
 224 %token E_ANGLE_CLOSE "\\>"
 225 %token E_CHAR "\\C[haracter]"
 226 %token E_CLOSE "\\)"
 227 %token E_EXCLAMATION "\\!"
 228 %token E_BRACKET_OPEN "\\["
 229 %token E_OPEN "\\("
 230 %token E_BRACKET_CLOSE "\\]"
 231 %token E_ANGLE_OPEN "\\<"
 232 %token E_PLUS "\\+"
 233 %token E_TILDE "\\~"
 234 %token EXTENDER "__"
 235
 236 /*
 237 If we give names, Bison complains.
 238 */
 239 %token FIGURE_CLOSE /* "\\>" */
 240 %token FIGURE_OPEN /* "\\<" */
 241 %token FIGURE_SPACE "_"
 242 %token HYPHEN "--"
 243
 244 %token CHORDMODIFIERS
 245 %token LYRIC_MARKUP
 246 %token MULTI_MEASURE_REST
 247 %token SCM_T
 248
 249
 250 %token <i> DIGIT
 251 %token <i> E_UNSIGNED
 252 %token <i> UNSIGNED
 253
 254 %token <scm> BOOK_IDENTIFIER
 255 %token <scm> CHORDMODIFIER_PITCH
 256 %token <scm> CHORD_MODIFIER
 257 %token <scm> CONTEXT_DEF_IDENTIFIER
 258 %token <scm> DRUM_PITCH
 259 %token <scm> DURATION_IDENTIFIER
 260 %token <scm> EVENT_IDENTIFIER
 261 %token <scm> FRACTION
 262 %token <scm> LYRICS_STRING
 263 %token <scm> LYRIC_MARKUP_IDENTIFIER
 264 %token <scm> MARKUP_HEAD_EMPTY
 265 %token <scm> MARKUP_HEAD_LIST0
 266 %token <scm> MARKUP_HEAD_MARKUP0
 267 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 268 %token <scm> MARKUP_HEAD_SCM0
 269 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 270 %token <scm> MARKUP_HEAD_SCM0_SCM1
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 272 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 273 %token <scm> MARKUP_IDENTIFIER
 274 %token <scm> MUSIC_FUNCTION
 275 %token <scm> MUSIC_FUNCTION_MARKUP
 276 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MUSIC
 281 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 282 %token <scm> MUSIC_FUNCTION_SCM
 283 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 284 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 285 %token <scm> MUSIC_FUNCTION_SCM_SCM
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 287 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 288 %token <scm> MUSIC_IDENTIFIER
 289 %token <scm> NOTENAME_PITCH
 290 %token <scm> NUMBER_IDENTIFIER
 291 %token <scm> OUTPUT_DEF_IDENTIFIER
 292 %token <scm> REAL
 293 %token <scm> RESTNAME
 294 %token <scm> SCM_IDENTIFIER
 295 %token <scm> SCM_T
 296 %token <scm> SCORE_IDENTIFIER
 297 %token <scm> STRING
 298 %token <scm> STRING_IDENTIFIER
 299 %token <scm> TONICNAME_PITCH
 300
 301
 302 %type <book> book_block
 303 %type <book> book_body
 304
 305 %type <i> bare_unsigned
 306 %type <i> figured_bass_alteration
 307 %type <i> dots
 308 %type <i> exclamations
 309 %type <i> optional_rest
 310 %type <i> questions
 311 %type <i> script_dir
 312 %type <i> sub_quotes
 313 %type <i> sup_quotes
 314 %type <i> tremolo_type
 315
 316 %type <music> Composite_music
 317 %type <music> Grouped_music_list
 318 %type <music> Music
 319 %type <music> Prefix_composite_music
 320 %type <music> Repeated_music
 321 %type <music> Sequential_music
 322 %type <music> Simple_music
 323 %type <music> Simultaneous_music
 324 %type <music> chord_body
 325 %type <music> chord_body_element
 326 %type <music> command_element
 327 %type <music> command_event
 328 %type <music> context_change
 329 %type <music> direction_less_event
 330 %type <music> direction_reqd_event
 331 %type <music> event_chord
 332 %type <music> gen_text_def
 333 %type <music> music_property_def
 334 %type <music> note_chord_element
 335 %type <music> post_event
 336 %type <music> re_rhythmed_music
 337 %type <music> relative_music
 338 %type <music> simple_element
 339 %type <music> string_number_event
 340 %type <music> tempo_event
 341 %type <music> toplevel_music
 342
 343 %type <outputdef> output_def_body
 344 %type <outputdef> output_def_head
 345 %type <outputdef> output_def
 346 %type <outputdef> paper_block
 347
 348 %type <scm> Alternative_music
 349 %type <scm> Generic_prefix_music_scm
 350 %type <scm> Music_list
 351 %type <scm> absolute_pitch
 352 %type <scm> assignment_id
 353 %type <scm> bare_number
 354 %type <scm> music_function_event
 355 %type <scm> music_function_chord_body
 356 %type <scm> bass_figure
 357 %type <scm> figured_bass_modification
 358 %type <scm> br_bass_figure
 359 %type <scm> bass_number
 360 %type <scm> chord_body_elements
 361 %type <scm> chord_item
 362 %type <scm> chord_items
 363 %type <scm> chord_separator
 364 %type <scm> context_def_mod
 365 %type <scm> context_def_spec_block
 366 %type <scm> context_def_spec_body
 367 %type <scm> context_mod
 368 %type <scm> context_mod_list
 369 %type <scm> context_prop_spec
 370 %type <scm> direction_less_char
 371 %type <scm> duration_length
 372 %type <scm> embedded_scm
 373 %type <scm> figure_list
 374 %type <scm> figure_spec
 375 %type <scm> fraction
 376 %type <scm> full_markup
 377 %type <scm> identifier_init
 378 %type <scm> lilypond_header
 379 %type <scm> lilypond_header_body
 380 %type <scm> lyric_element
 381 %type <scm> lyric_markup
 382 %type <scm> markup
 383 %type <scm> markup_braced_list
 384 %type <scm> markup_braced_list_body
 385 %type <scm> markup_composed_list
 386 %type <scm> markup_head_1_item
 387 %type <scm> markup_head_1_list
 388 %type <scm> markup_list
 389 %type <scm> markup_top
 390 %type <scm> mode_changing_head
 391 %type <scm> mode_changing_head_with_context
 392 %type <scm> multiplied_duration
 393 %type <scm> new_chord
 394 %type <scm> new_lyrics
 395 %type <scm> number_expression
 396 %type <scm> number_factor
 397 %type <scm> number_term
 398 %type <scm> object_id_setting
 399 %type <scm> octave_check
 400 %type <scm> optional_context_mod
 401 %type <scm> optional_notemode_duration
 402 %type <scm> pitch
 403 %type <scm> pitch_also_in_chords
 404 %type <scm> post_events
 405 %type <scm> property_operation
 406 %type <scm> scalar
 407 %type <scm> script_abbreviation
 408 %type <scm> simple_markup
 409 %type <scm> simple_string
 410 %type <scm> steno_duration
 411 %type <scm> steno_pitch
 412 %type <scm> steno_tonic_pitch
 413 %type <scm> step_number
 414 %type <scm> step_numbers
 415 %type <scm> string
 416 %type <scm> function_scm_argument
 417
 418 %type <score> score_block
 419 %type <score> score_body
 420
 421
 422 %left '-' '+'
 423
 424 /* We don't assign precedence to / and *, because we might need varied
 425 prec levels in different prods */
 426
 427 %left UNARY_MINUS
 428
 429 %%
 430
 431 lilypond:       /* empty */
 432         | lilypond toplevel_expression {
 433         }
 434         | lilypond assignment {
 435         }
 436         | lilypond error {
 437                 THIS->error_level_ = 1;
 438         }
 439         | lilypond INVALID      {
 440                 THIS->error_level_ = 1;
 441         }
 442         ;
 443
 444
 445 object_id_setting:
 446         OBJECTID STRING { $$ = $2; }
 447         ;
 448
 449 toplevel_expression:
 450         lilypond_header {
 451                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 452         }
 453         | add_quote {
 454
 455         }
 456         | book_block {
 457                 Book *book = $1;
 458                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 459                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 460                 book->unprotect ();
 461         }
 462         | score_block {
 463                 Score *score = $1;
 464
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 467                 score->unprotect ();
 468         }
 469         | toplevel_music {
 470                 Music *music = $1;
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 473                 music->unprotect ();
 474         }
 475         | full_markup {
 476                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 477                 scm_call_2 (proc, THIS->self_scm (), $1);
 478         }
 479         | output_def {
 480                 SCM id = SCM_EOL;
 481                 Output_def * od = $1;
 482
 483                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 484                         id = ly_symbol2scm ("$defaultpaper");
 485                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultmidi");
 487                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultlayout");
 489
 490                 THIS->lexer_->set_identifier (id, od->self_scm ());
 491                 od->unprotect();
 492         }
 493         ;
 494
 495 toplevel_music:
 496         Composite_music {
 497         }
 498         ;
 499
 500 embedded_scm:
 501         SCM_T
 502         | SCM_IDENTIFIER
 503         ;
 504
 505
 506 lilypond_header_body:
 507         {
 508                 $$ = get_header(THIS);
 509                 THIS->lexer_->add_scope ($$);
 510         }
 511         | lilypond_header_body assignment  {
 512
 513         }
 514         ;
 515
 516 lilypond_header:
 517         HEADER '{' lilypond_header_body '}'     {
 518                 $$ = THIS->lexer_->remove_scope ();
 519         }
 520         ;
 521
 522 /*
 523         DECLARATIONS
 524 */
 525 assignment_id:
 526         STRING          { $$ = $1; }
 527         | LYRICS_STRING { $$ = $1; }
 528         ;
 529
 530 assignment:
 531         assignment_id '=' identifier_init  {
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         @1.warning (_ ("identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $3);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 $1->unprotect ();
 555         }
 556         | book_block {
 557                 $$ = $1->self_scm ();
 558                 $1->unprotect ();
 559         }
 560         | output_def {
 561                 $$ = $1->self_scm ();
 562                 $1->unprotect ();
 563         }
 564         | context_def_spec_block {
 565                 $$ = $1;
 566         }
 567         | Music  {
 568                 $$ = $1->self_scm ();
 569                 $1->unprotect();
 570         }
 571         | post_event {
 572                 $$ = $1->self_scm ();
 573                 $1->unprotect();
 574         }
 575         | number_expression {
 576                 $$ = $1;
 577         }
 578         | string {
 579                 $$ = $1;
 580         }
 581         | embedded_scm {
 582                 $$ = $1;
 583         }
 584         | full_markup {
 585                 $$ = $1;
 586         }
 587         | DIGIT {
 588                 $$ = scm_from_int ($1);
 589         }
 590         ;
 591
 592 context_def_spec_block:
 593         CONTEXT '{' context_def_spec_body '}'
 594                 {
 595                 $$ = $3;
 596         }
 597         ;
 598
 599 context_def_spec_body:
 600         /**/ {
 601                 $$ = Context_def::make_scm ();
 602                 unsmob_context_def ($$)->set_spot (@$);
 603         }
 604         | CONTEXT_DEF_IDENTIFIER {
 605                 $$ = $1;
 606                 unsmob_context_def ($$)->set_spot (@$);
 607         }
 608         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 609                 Context_def*td = unsmob_context_def ($$);
 610
 611                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 612                         SCM tag = scm_caar (p);
 613
 614                         /* TODO: should make new tag "grob-definition" ? */
 615                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 616                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 617                 }
 618         }
 619         | context_def_spec_body context_mod {
 620                 unsmob_context_def ($$)->add_context_mod ($2);
 621         }
 622         ;
 623
 624
 625
 626 book_block:
 627         BOOK '{' book_body '}'  {
 628                 $$ = $3;
 629         }
 630         ;
 631
 632 /* FIXME:
 633    * Use 'handlers' like for toplevel-* stuff?
 634    * grok \layout and \midi?  */
 635 book_body:
 636         {
 637                 $$ = new Book;
 638                 $$->set_spot (@$);
 639                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 640                 $$->paper_->unprotect ();
 641                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 642         }
 643         | BOOK_IDENTIFIER {
 644                 $$ = unsmob_book ($1);
 645                 $$->set_spot (@$);
 646         }
 647         | book_body paper_block {
 648                 $$->paper_ = $2;
 649                 $2->unprotect ();
 650         }
 651         | book_body score_block {
 652                 SCM s = $2->self_scm ();
 653                 $$->add_score (s);
 654                 $2->unprotect();
 655         }
 656         | book_body full_markup {
 657                 $$->add_score ($2);
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663                 $$->paper_ = 0;
 664                 $$->scores_ = SCM_EOL;
 665         }
 666         | book_body object_id_setting {
 667                 $$->user_key_ = ly_scm2string ($2);
 668         }
 669         ;
 670
 671 score_block:
 672         SCORE '{' score_body '}'        {
 673                 $$ = $3;
 674         }
 675         ;
 676
 677 score_body:
 678         Music {
 679                 SCM m = $1->self_scm ();
 680                 $1->unprotect();
 681                 SCM scorify = ly_lily_module_constant ("scorify-music");
 682                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 683
 684                 // pass ownernship to C++ again.
 685                 $$ = unsmob_score (score);
 686                 $$->protect ();
 687                 $$->set_spot (@$);
 688         }
 689         | SCORE_IDENTIFIER {
 690                 $$ = unsmob_score ($1);
 691                 $$->set_spot (@$);
 692         }
 693         | score_body object_id_setting {
 694                 $$->user_key_ = ly_scm2string ($2);
 695         }
 696         | score_body lilypond_header    {
 697                 $$->header_ = $2;
 698         }
 699         | score_body output_def {
 700                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 701                 {
 702                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 703
 704                 }
 705                 else
 706                 {
 707                         $$->add_output_def ($2);
 708                 }
 709                 $2->unprotect ();
 710         }
 711         | score_body error {
 712                 $$->error_found_ = true;
 713         }
 714         ;
 715
 716
 717 /*
 718         OUTPUT DEF
 719 */
 720
 721 paper_block:
 722         output_def {
 723                 $$ = $1;
 724                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 725                 {
 726                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 727                         $$ = get_paper (THIS);
 728                 }
 729         }
 730         ;
 731
 732
 733 output_def:
 734         output_def_body '}' {
 735                 $$ = $1;
 736
 737                 THIS->lexer_->remove_scope ();
 738                 THIS->lexer_->pop_state ();
 739         }
 740         ;
 741
 742 output_def_head:
 743         PAPER {
 744                 $$ = get_paper (THIS);
 745                 $$->input_origin_ = @$;
 746                 THIS->lexer_->add_scope ($$->scope_);
 747         }
 748         | MIDI    {
 749                 Output_def *p = get_midi (THIS);
 750                 $$ = p;
 751                 THIS->lexer_->add_scope (p->scope_);
 752         }
 753         | LAYOUT        {
 754                 Output_def *p = get_layout (THIS);
 755
 756                 THIS->lexer_->add_scope (p->scope_);
 757                 $$ = p;
 758         }
 759         ;
 760
 761
 762 output_def_body:
 763         output_def_head '{' {
 764                 $$ = $1;
 765                 $$->input_origin_.set_spot (@$);
 766                 THIS->lexer_->push_initial_state ();
 767         }
 768         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 769                 $1->unprotect ();
 770                 Output_def *o = unsmob_output_def ($3);
 771                 o->input_origin_.set_spot (@$);
 772                 $$ = o;
 773                 THIS->lexer_->remove_scope ();
 774                 THIS->lexer_->add_scope (o->scope_);
 775                 THIS->lexer_->push_initial_state ();
 776         }
 777         | output_def_body assignment  {
 778
 779         }
 780         | output_def_body context_def_spec_block        {
 781                 assign_context_def ($$, $2);
 782         }
 783         | output_def_body tempo_event  {
 784                 /*
 785                         junk this ? there already is tempo stuff in
 786                         music.
 787                 */
 788                 int m = scm_to_int ($2->get_property ("metronome-count"));
 789                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 790                 set_tempo ($$, d->get_length (), m);
 791                 $2->unprotect ();
 792         }
 793         | output_def_body error {
 794
 795         }
 796         ;
 797
 798 tempo_event:
 799         TEMPO steno_duration '=' bare_unsigned  {
 800                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 801                 $$->set_property ("tempo-unit", $2);
 802                 $$->set_property ("metronome-count", scm_from_int ( $4));
 803         }
 804         ;
 805
 806 /*
 807 The representation of a  list is the
 808
 809   (LIST . LAST-CONS)
 810
 811  to have efficient append.  */
 812
 813 Music_list:
 814         /* empty */ {
 815                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 816         }
 817         | Music_list Music {
 818                 SCM s = $$;
 819                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 820                 $2->unprotect (); /* UGH */
 821
 822                 if (scm_is_pair (scm_cdr (s)))
 823                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 824                 else
 825                         scm_set_car_x (s, c); /* set first cons */
 826                 scm_set_cdr_x (s, c);  /* remember last cell */
 827         }
 828         | Music_list embedded_scm {
 829
 830         }
 831         | Music_list error {
 832                 Music * m = MY_MAKE_MUSIC("Music");
 833                 // ugh. code dup
 834                 m->set_property ("error-found", SCM_BOOL_T);
 835                 SCM s = $$;
 836                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 837                 m->unprotect (); /* UGH */
 838
 839                 if (scm_is_pair (scm_cdr (s)))
 840                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 841                 else
 842                         scm_set_car_x (s, c); /* set first cons */
 843                 scm_set_cdr_x (s, c);  /* remember last cell */
 844         }
 845         ;
 846
 847 Music:
 848         Simple_music
 849         | Composite_music
 850         ;
 851
 852 Alternative_music:
 853         /* empty */ {
 854                 $$ = SCM_EOL;
 855         }
 856         | ALTERNATIVE '{' Music_list '}' {
 857                 $$ = $3;
 858         }
 859         ;
 860
 861
 862 Repeated_music:
 863         REPEAT simple_string bare_unsigned Music Alternative_music
 864         {
 865                 Music *beg = $4;
 866                 int times = $3;
 867                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 868                 if (times < scm_ilength (alts)) {
 869                   unsmob_music (scm_car (alts))
 870                     ->origin ()->warning (
 871                     _ ("more alternatives than repeats"));
 872                     warning ("junking excess alternatives");
 873                   alts = ly_truncate_list (times, alts);
 874                 }
 875
 876
 877                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 878
 879                 SCM mus = scm_call_1 (proc, $2);
 880                 Music *r = unsmob_music (mus);
 881                 r->protect ();
 882                 if (beg)
 883                         {
 884                         r-> set_property ("element", beg->self_scm ());
 885                         beg->unprotect ();
 886                         }
 887                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
 888
 889                 r-> set_property ("elements",alts);
 890                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
 891                         /*
 892                         TODO: move this code to Scheme.
 893                         */
 894
 895                         /* we cannot get durations and other stuff
 896                            correct down the line,
 897                            so we have to add to the duration log here. */
 898                         SCM func = ly_lily_module_constant ("shift-duration-log");
 899
 900                         int dots = ($3 % 3) ? 0 : 1;
 901                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 902
 903
 904                         if ($4->is_mus_type ("sequential-music"))
 905                         {
 906                                 int list_len = scm_ilength ($4->get_property ("elements"));
 907                                 if (list_len != 2)
 908                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
 909                                 shift -= 1;
 910                                 r->compress (Moment (Rational (1, list_len)));
 911                         }
 912                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
 913
 914                 }
 915                 r->set_spot (*$4->origin ());
 916
 917                 $$ = r;
 918         }
 919         ;
 920
 921 Sequential_music:
 922         SEQUENTIAL '{' Music_list '}'           {
 923                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 924                 $$->set_property ("elements", scm_car ($3));
 925                 $$->set_spot (@$);
 926         }
 927         | '{' Music_list '}'            {
 928                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 929                 $$->set_property ("elements", scm_car ($2));
 930                 $$->set_spot (@$);
 931         }
 932         ;
 933
 934 Simultaneous_music:
 935         SIMULTANEOUS '{' Music_list '}'{
 936                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 937                 $$->set_property ("elements", scm_car ($3));
 938                 $$->set_spot (@$);
 939
 940         }
 941         | simul_open Music_list simul_close     {
 942                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 943                 $$->set_property ("elements", scm_car ($2));
 944                 $$->set_spot (@$);
 945         }
 946         ;
 947
 948 Simple_music:
 949         event_chord             { $$ = $1; }
 950         | MUSIC_IDENTIFIER {
 951                 $$ = unsmob_music ($1);
 952         }
 953         | music_property_def
 954         | context_change
 955         ;
 956
 957
 958 optional_context_mod:
 959         /**/ { $$ = SCM_EOL; }
 960         | WITH { THIS->lexer_->push_initial_state (); }
 961         '{' context_mod_list '}'
 962         {
 963                 THIS->lexer_->pop_state ();
 964                 $$ = $4;
 965         }
 966         ;
 967
 968 context_mod_list:
 969         /* */  { $$ = SCM_EOL; }
 970         | context_mod_list context_mod  {
 971                  $$ = scm_cons ($2, $1);
 972         }
 973         ;
 974
 975
 976 Composite_music:
 977         Prefix_composite_music { $$ = $1; }
 978         | Grouped_music_list { $$ = $1; }
 979         ;
 980
 981 Grouped_music_list:
 982         Simultaneous_music              { $$ = $1; }
 983         | Sequential_music              { $$ = $1; }
 984         ;
 985
 986
 987 function_scm_argument:
 988         embedded_scm
 989         | simple_string
 990         ;
 991
 992 Generic_prefix_music_scm:
 993         MUSIC_FUNCTION {
 994                 $$ = scm_list_2 ($1, make_input (@$));
 995         }
 996         | MUSIC_FUNCTION_SCM function_scm_argument {
 997                 $$ = scm_list_3 ($1, make_input (@$), $2);
 998         }
 999         | MUSIC_FUNCTION_MARKUP full_markup {
1000                 $$ = scm_list_3 ($1, make_input (@$), $2);
1001         }
1002
1003         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument Music {
1004                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1005                 $3->unprotect ();
1006         }
1007         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
1008                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1009         }
1010         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
1011                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1012         }
1013         | MUSIC_FUNCTION_MUSIC Music {
1014                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1015                 $2->unprotect ();
1016         }
1017         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument Music {
1018                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1019         }
1020         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1021                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1022                 $3->unprotect ();
1023         }
1024         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1025                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1026         }
1027         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1028                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1029                 $2->unprotect ();
1030                 $3->unprotect ();
1031         }
1032         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
1033                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1034                 $4->unprotect ();
1035                 $3->unprotect ();
1036         }
1037         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1038                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1039                 $3->unprotect ();
1040                 $4->unprotect ();
1041         }
1042         ;
1043
1044 Prefix_composite_music:
1045         Generic_prefix_music_scm {
1046                 $$ = run_music_function (THIS, $1);
1047         }
1048         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1049                 $$ = context_spec_music ($2, $4, $6, $5);
1050
1051         }
1052         | CONTEXT simple_string optional_context_mod Music {
1053                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1054         }
1055         | NEWCONTEXT simple_string optional_context_mod Music {
1056                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1057                         $3);
1058         }
1059
1060         | TIMES fraction Music
1061
1062         {
1063                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1064                 Music *mp = $3;
1065
1066                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1067                 $$->set_spot (@$);
1068
1069                 $$->set_property ("element", mp->self_scm ());
1070                 mp->unprotect();
1071                 $$->set_property ("numerator", scm_from_int (n));
1072                 $$->set_property ("denominator", scm_from_int (d));
1073                 $$->compress (Moment (Rational (n,d)));
1074
1075         }
1076         | Repeated_music                { $$ = $1; }
1077         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1078                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1079                 Music *p = $4;
1080                 Pitch from = *unsmob_pitch ($2);
1081                 Pitch to = *unsmob_pitch ($3);
1082
1083                 p->transpose (pitch_interval (from, to));
1084                 $$->set_property ("element", p->self_scm ());
1085                 p->unprotect();
1086         }
1087         | mode_changing_head Grouped_music_list {
1088                 if ($1 == ly_symbol2scm ("chords"))
1089                 {
1090                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1091                   chm->set_property ("element", $2->self_scm ());
1092                   $$ = chm;
1093                   $2->unprotect();
1094                 }
1095                 else
1096                 {
1097                   $$ = $2;
1098                 }
1099                 THIS->lexer_->pop_state ();
1100         }
1101         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1102                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1103                                          $3, $2);
1104                 if ($1 == ly_symbol2scm ("ChordNames"))
1105                 {
1106                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1107                   chm->set_property ("element", $$->self_scm ());
1108                   $$->unprotect();
1109                   $$ = chm;
1110                 }
1111                 THIS->lexer_->pop_state ();
1112         }
1113         | relative_music        { $$ = $1; }
1114         | re_rhythmed_music     { $$ = $1; }
1115         ;
1116
1117 mode_changing_head:
1118         NOTEMODE {
1119                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1120                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1121
1122                 $$ = ly_symbol2scm ("notes");
1123         }
1124         | DRUMMODE
1125                 {
1126                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1127                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1128
1129                 $$ = ly_symbol2scm ("drums");
1130         }
1131         | FIGUREMODE {
1132                 THIS->lexer_->push_figuredbass_state ();
1133
1134                 $$ = ly_symbol2scm ("figures");
1135         }
1136         | CHORDMODE {
1137                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1138                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1139                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1140                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1141                 $$ = ly_symbol2scm ("chords");
1142
1143         }
1144         | LYRICMODE
1145                 { THIS->lexer_->push_lyric_state ();
1146                 $$ = ly_symbol2scm ("lyrics");
1147         }
1148         ;
1149
1150 mode_changing_head_with_context:
1151         DRUMS {
1152                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1153                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1154
1155                 $$ = ly_symbol2scm ("DrumStaff");
1156         }
1157         | FIGURES {
1158                 THIS->lexer_->push_figuredbass_state ();
1159
1160                 $$ = ly_symbol2scm ("FiguredBass");
1161         }
1162         | CHORDS {
1163                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1164                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1165                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1166                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1167                 $$ = ly_symbol2scm ("ChordNames");
1168         }
1169         | LYRICS
1170                 { THIS->lexer_->push_lyric_state ();
1171                 $$ = ly_symbol2scm ("Lyrics");
1172         }
1173         ;
1174
1175
1176 relative_music:
1177         RELATIVE absolute_pitch Music {
1178                 Music *m = $3;
1179                 Pitch start = *unsmob_pitch ($2);
1180                 $$ = make_music_relative (start, m);
1181                 m->unprotect();
1182         }
1183         | RELATIVE Composite_music {
1184                 Music *m = $2;
1185
1186                 Pitch middle_c (0, 0, 0);
1187                 $$ = make_music_relative (middle_c, m);
1188                 m->unprotect();
1189         }
1190         ;
1191
1192 new_lyrics:
1193         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1194         /*cont */
1195         Grouped_music_list {
1196         /* Can also use Music at the expensive of two S/Rs similar to
1197            \repeat \alternative */
1198                 THIS->lexer_->pop_state ();
1199
1200                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1201         }
1202         | new_lyrics ADDLYRICS {
1203                 THIS->lexer_->push_lyric_state ();
1204         } Grouped_music_list {
1205                 THIS->lexer_->pop_state ();
1206                 $$ = scm_cons ($4->self_scm (), $1);
1207         }
1208         ;
1209
1210 re_rhythmed_music:
1211         Grouped_music_list new_lyrics {
1212                 Music * voice = $1;
1213                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1214                 if (!scm_is_string (name))
1215                 {
1216                         name = get_next_unique_lyrics_context_id ();
1217                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1218                                                     name,
1219                                                     voice, SCM_EOL);
1220                 }
1221
1222                 SCM context = scm_makfrom0str ("Lyrics");
1223                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1224
1225                 SCM lst = SCM_EOL;
1226                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1227                 {
1228                         Music *music = unsmob_music (scm_car (s));
1229                         Music *com = make_lyric_combine_music (name, music);
1230                         Music *csm = context_spec_music (context,
1231                                 get_next_unique_context_id (), com, SCM_EOL);
1232                         lst = scm_cons (csm->self_scm (), lst);
1233                 }
1234                 all->set_property ("elements", scm_cons (voice->self_scm (),
1235                         lst));
1236                 $$ = all;
1237                 voice->unprotect ();
1238         }
1239         | LYRICSTO simple_string {
1240                 THIS->lexer_->push_lyric_state ();
1241         } Music {
1242                 THIS->lexer_->pop_state ();
1243                 Music *music = $4;
1244                 SCM name = $2;
1245                 $$ = make_lyric_combine_music (name, music);
1246                 music->unprotect();
1247         }
1248         ;
1249
1250 context_change:
1251         CHANGE STRING '=' STRING  {
1252                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1253                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1254                 t-> set_property ("change-to-id", $4);
1255
1256                 $$ = t;
1257                 $$->set_spot (@$);
1258         }
1259         ;
1260
1261 property_operation:
1262         STRING '=' scalar {
1263                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1264                         scm_string_to_symbol ($1), $3);
1265         }
1266         | UNSET simple_string {
1267                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1268                         scm_string_to_symbol ($2));
1269         }
1270         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1271                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1272                         scm_string_to_symbol ($2), $5, $3);
1273         }
1274         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1275                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1276                                 scm_string_to_symbol ($2), $6, $4, $3);
1277         }
1278         | REVERT simple_string embedded_scm {
1279                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1280                         scm_string_to_symbol ($2), $3);
1281         }
1282         ;
1283
1284 context_def_mod:
1285         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1286         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1287
1288         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1289         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1290         | DENIES { $$ = ly_symbol2scm ("denies"); }
1291
1292         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1293         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1294         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1295         | NAME { $$ = ly_symbol2scm ("context-name"); }
1296         ;
1297
1298 context_mod:
1299         property_operation { $$ = $1; }
1300         | context_def_mod STRING {
1301                 $$ = scm_list_2 ($1, $2);
1302         }
1303         ;
1304
1305 context_prop_spec:
1306         simple_string {
1307                 if (!is_regular_identifier ($1))
1308                 {
1309                         @$.error (_("Grob name should be alphanumeric"));
1310                 }
1311
1312                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1313                         scm_string_to_symbol ($1));
1314         }
1315         | simple_string '.' simple_string {
1316                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1317                         scm_string_to_symbol ($3));
1318         }
1319         ;
1320
1321 music_property_def:
1322         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1323                 $$ = property_op_to_music (scm_list_4 (
1324                         ly_symbol2scm ("push"),
1325                         scm_cadr ($2),
1326                         $5, $3));
1327                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1328         }
1329         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1330                 $$ = property_op_to_music (scm_list_5 (
1331                         ly_symbol2scm ("push"),
1332                         scm_cadr ($2),
1333                         $6, $4, $3));
1334                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1335         }
1336         | REVERT context_prop_spec embedded_scm {
1337                 $$ = property_op_to_music (scm_list_3 (
1338                         ly_symbol2scm ("pop"),
1339                         scm_cadr ($2),
1340                         $3));
1341
1342                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1343         }
1344         | SET context_prop_spec '=' scalar {
1345                 $$ = property_op_to_music (scm_list_3 (
1346                         ly_symbol2scm ("assign"),
1347                         scm_cadr ($2),
1348                         $4));
1349                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1350         }
1351         | UNSET context_prop_spec {
1352                 $$ = property_op_to_music (scm_list_2 (
1353                         ly_symbol2scm ("unset"),
1354                         scm_cadr ($2)));
1355                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1356         }
1357         | ONCE music_property_def {
1358                 SCM e = $2->get_property ("element");
1359                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1360                 $$ = $2;
1361
1362         }
1363         ;
1364
1365
1366 string:
1367         STRING {
1368                 $$ = $1;
1369         }
1370         | STRING_IDENTIFIER {
1371                 $$ = $1;
1372         }
1373         | string '+' string {
1374                 $$ = scm_string_append (scm_list_2 ($1, $3));
1375         }
1376         ;
1377
1378 simple_string: STRING {
1379                 $$ = $1;
1380         }
1381         | LYRICS_STRING {
1382                 $$ = $1;
1383         }
1384         | STRING_IDENTIFIER {
1385                 $$ = $1;
1386         }
1387         ;
1388
1389 scalar: string {
1390                 $$ = $1;
1391         }
1392         | LYRICS_STRING {
1393                 $$ = $1;
1394         }
1395         | bare_number {
1396                 $$ = $1;
1397         }
1398         | embedded_scm {
1399                 $$ = $1;
1400         }
1401         | full_markup {
1402                 $$ = $1;
1403         }
1404         | DIGIT {
1405                 $$ = scm_from_int ($1);
1406         }
1407         ;
1408
1409 /*
1410
1411 pre_events doesn't contain anything. It is a trick:
1412
1413 Adding pre_events to the simple_element
1414 makes the choice between
1415
1416   string:  STRING
1417
1418 and
1419
1420   simple_element: STRING
1421
1422 a single shift/reduction conflict.
1423
1424 nevertheless, this is not very clean, and we should find a different
1425 solution.
1426
1427 */
1428 pre_events: /* empty */
1429         ;
1430
1431 event_chord:
1432         pre_events simple_element post_events   {
1433                 SCM elts = $2-> get_property ("elements");
1434
1435                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1436
1437                 $2->set_property ("elements", elts);
1438                 /* why is this giving wrong start location? -ns
1439                  * $2->set_spot (@$); */
1440                 Input i;
1441                 i.set_location (@2, @3);
1442                 $2->set_spot (i);
1443                 $$ = $2;
1444         }
1445         | command_element
1446         | note_chord_element
1447         ;
1448
1449
1450 note_chord_element:
1451         chord_body optional_notemode_duration post_events
1452         {
1453                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1454                 SCM es = $1->get_property ("elements");
1455                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1456
1457                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1458                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1459                 es = ly_append2 (es, postevs);
1460
1461                 $1-> set_property ("elements", es);
1462                 $1->set_spot (@$);
1463                 $$ = $1;
1464         }
1465         ;
1466
1467 chord_open: '<'
1468         ;
1469
1470 chord_close: '>'
1471         ;
1472
1473 simul_open: DOUBLE_ANGLE_OPEN
1474         ;
1475
1476 simul_close: DOUBLE_ANGLE_CLOSE
1477         ;
1478
1479 chord_body:
1480         chord_open chord_body_elements chord_close
1481         {
1482                 $$ = MY_MAKE_MUSIC ("EventChord");
1483                 $$->set_spot (@$);
1484                 $$->set_property ("elements",
1485                         scm_reverse_x ($2, SCM_EOL));
1486         }
1487         ;
1488
1489 chord_body_elements:
1490         /* empty */             { $$ = SCM_EOL; }
1491         | chord_body_elements chord_body_element {
1492                 $$ = scm_cons ($2->self_scm (), $1);
1493                 $2->unprotect ();
1494         }
1495         ;
1496
1497 chord_body_element:
1498         pitch exclamations questions octave_check post_events
1499         {
1500                 int q = $3;
1501                 int ex = $2;
1502                 SCM check = $4;
1503                 SCM post = $5;
1504
1505                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1506                 n->set_property ("pitch", $1);
1507                 n->set_spot (@$);
1508                 if (q % 2)
1509                         n->set_property ("cautionary", SCM_BOOL_T);
1510                 if (ex % 2 || q % 2)
1511                         n->set_property ("force-accidental", SCM_BOOL_T);
1512
1513                 if (scm_is_pair (post)) {
1514                         SCM arts = scm_reverse_x (post, SCM_EOL);
1515                         n->set_property ("articulations", arts);
1516                 }
1517                 if (scm_is_number (check))
1518                 {
1519                         int q = scm_to_int (check);
1520                         n->set_property ("absolute-octave", scm_from_int (q-1));
1521                 }
1522
1523
1524                 $$ = n;
1525         }
1526         | DRUM_PITCH post_events {
1527                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1528                 n->set_property ("duration", $2);
1529                 n->set_property ("drum-type", $1);
1530                 n->set_spot (@$);
1531
1532                 if (scm_is_pair ($2)) {
1533                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1534                         n->set_property ("articulations", arts);
1535                 }
1536                 $$ = n;
1537         }
1538         | music_function_chord_body {
1539                 $$ = run_music_function (THIS, $1);
1540                 $$->set_spot (@$);
1541         }
1542         ;
1543
1544 music_function_chord_body:
1545         MUSIC_FUNCTION {
1546                 $$ = scm_list_2 ($1, make_input (@$));
1547         }
1548         | MUSIC_FUNCTION_MUSIC chord_body_element {
1549                 $$ = scm_list_3 ($1, make_input (@$),
1550                                         $2->self_scm ());
1551         }
1552         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument chord_body_element {
1553                 $$ = scm_list_4 ($1, make_input (@$),
1554                                         $2, $3->self_scm ());
1555         }
1556         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument
1557                 chord_body_element {
1558
1559                 $$ = scm_list_5 ($1, make_input (@$),
1560                                         $2, $3, $4->self_scm ());
1561         }
1562         ;
1563
1564
1565 add_quote:
1566         ADDQUOTE string Music {
1567                 SCM adder = ly_lily_module_constant ("add-quotable");
1568
1569                 scm_call_2 (adder, $2, $3->self_scm ());
1570                 $3->unprotect();
1571         }
1572         ;
1573
1574 command_element:
1575         command_event {
1576                 $$ = MY_MAKE_MUSIC ("EventChord");
1577                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1578                 $1->unprotect();
1579
1580                 $$-> set_spot (@$);
1581                 $1-> set_spot (@$);
1582         }
1583         | SKIP duration_length {
1584                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1585                 skip->set_property ("duration", $2);
1586                 skip->set_spot (@$);
1587                 $$ = skip;
1588         }
1589         | OCTAVE pitch {
1590                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1591                 $$ = m;
1592                 $$->set_spot (@$);
1593                 $$->set_property ("pitch", $2);
1594         }
1595         | E_BRACKET_OPEN {
1596                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1597                 m->set_property ("span-direction", scm_from_int (START));
1598                 m->set_spot (@$);
1599
1600                 $$ = MY_MAKE_MUSIC ("EventChord");
1601                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1602                 m->unprotect();
1603                 $$->set_spot (@$);
1604         }
1605         | E_BRACKET_CLOSE {
1606                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1607                 m->set_property ("span-direction", scm_from_int (STOP));
1608                 m->set_spot (@$);
1609
1610                 $$ = MY_MAKE_MUSIC ("EventChord");
1611                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1612                 $$->set_spot (@$);
1613                 m->unprotect ();
1614         }
1615         | E_BACKSLASH {
1616                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1617                 $$->set_spot (@$);
1618         }
1619         | '|'      {
1620                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1621
1622                 if (Music * m = unsmob_music (pipe))
1623                         $$ = m->clone ();
1624                 else
1625                         $$ = MY_MAKE_MUSIC ("BarCheck");
1626
1627                 $$->set_spot (@$);
1628         }
1629         | TRANSPOSITION pitch {
1630                 Pitch middle_c;
1631                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1632                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1633                                          sounds_as_c.smobbed_copy());
1634                 $$->set_spot (@$);
1635                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1636                         $$, SCM_EOL);
1637         }
1638         | PARTIAL duration_length       {
1639                 Moment m = - unsmob_duration ($2)->get_length ();
1640                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1641                 p->set_spot (@$);
1642                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1643                                         p, SCM_EOL);
1644                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1645                                         p, SCM_EOL);
1646                 $$ = p;
1647         }
1648
1649         | TIME_T fraction  {
1650                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1651
1652                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1653                 $$ = unsmob_music (result);
1654                 $$->protect ();
1655         }
1656         | MARK scalar {
1657                 SCM proc = ly_lily_module_constant ("make-mark-set");
1658
1659                 SCM result = scm_call_1 (proc, $2);
1660                 $$ = unsmob_music (result);
1661                 $$->protect ();
1662         }
1663         ;
1664
1665 command_event:
1666         E_TILDE {
1667                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1668         }
1669         | MARK DEFAULT  {
1670                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1671                 $$ = m;
1672         }
1673         | tempo_event {
1674                 $$ = $1;
1675         }
1676         | KEY DEFAULT {
1677                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1678                 $$ = key;
1679         }
1680         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1681
1682                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1683                 if (scm_ilength ($3) > 0)
1684                 {
1685                         key->set_property ("pitch-alist", $3);
1686                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1687                         key->transpose (* unsmob_pitch ($2));
1688                 } else {
1689                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1690                 }
1691
1692                 $$ = key;
1693         }
1694         ;
1695
1696
1697 post_events:
1698         /* empty */ {
1699                 $$ = SCM_EOL;
1700         }
1701         | post_events post_event {
1702                 $2->set_spot (@2);
1703                 $$ = scm_cons ($2->self_scm (), $$);
1704                 $2->unprotect ();
1705         }
1706         ;
1707
1708 music_function_event:
1709         MUSIC_FUNCTION_MUSIC post_event {
1710                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1711         }
1712         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument post_event {
1713                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1714         }
1715         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument post_event {
1716                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1717         }
1718         ;
1719
1720
1721 post_event:
1722         direction_less_event {
1723                 $$ = $1;
1724         }
1725         | '-' music_function_event {
1726                 Music *mus = run_music_function (THIS, $2);
1727                 mus->set_spot (@1);
1728                 $$ = mus;
1729         }
1730         | HYPHEN {
1731                 if (!THIS->lexer_->is_lyric_state ())
1732                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1733                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1734         }
1735         | EXTENDER {
1736                 if (!THIS->lexer_->is_lyric_state ())
1737                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1738                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1739         }
1740         | script_dir direction_reqd_event {
1741                 if ($1)
1742                         $2->set_property ("direction", scm_from_int ($1));
1743                 $$ = $2;
1744         }
1745         | script_dir direction_less_event {
1746                 if ($1)
1747                         $2->set_property ("direction", scm_from_int ($1));
1748                 $$ = $2;
1749         }
1750         | string_number_event
1751         ;
1752
1753 string_number_event:
1754         E_UNSIGNED {
1755                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1756                 s->set_property ("string-number", scm_from_int ($1));
1757                 s->set_spot (@$);
1758                 $$ = s;
1759         }
1760         ;
1761
1762 direction_less_char:
1763         '['  {
1764                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1765         }
1766         | ']'  {
1767                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1768         }
1769         | '~'  {
1770                 $$ = ly_symbol2scm ("tildeSymbol");
1771         }
1772         | '('  {
1773                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1774         }
1775         | ')'  {
1776                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1777         }
1778         | E_EXCLAMATION  {
1779                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1780         }
1781         | E_OPEN  {
1782                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1783         }
1784         | E_CLOSE  {
1785                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1786         }
1787         | E_ANGLE_CLOSE  {
1788                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1789         }
1790         | E_ANGLE_OPEN  {
1791                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1792         }
1793         ;
1794
1795 direction_less_event:
1796         direction_less_char {
1797                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1798                 Music * m = 0;
1799                 if (unsmob_music (predefd))
1800                 {
1801                         m = unsmob_music (predefd)->clone ();
1802                 }
1803                 else
1804                 {
1805                         m = MY_MAKE_MUSIC ("Music");
1806                 }
1807                 m->set_spot (@$);
1808                 $$ = m;
1809         }
1810         | EVENT_IDENTIFIER      {
1811                 $$ = unsmob_music ($1);
1812         }
1813         | tremolo_type  {
1814                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1815                a->set_spot (@$);
1816                a->set_property ("tremolo-type", scm_from_int ($1));
1817                $$ = a;
1818         }
1819         ;
1820
1821 direction_reqd_event:
1822         gen_text_def {
1823                 $$ = $1;
1824         }
1825         | script_abbreviation {
1826                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1827                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1828                 if (scm_is_string (s))
1829                         a->set_property ("articulation-type", s);
1830                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1831                 $$ = a;
1832         }
1833         ;
1834
1835 octave_check:
1836         /**/ { $$ = SCM_EOL; }
1837         | '='  { $$ = scm_from_int (0); }
1838         | '=' sub_quotes { $$ = scm_from_int ($2); }
1839         | '=' sup_quotes { $$ = scm_from_int ($2); }
1840         ;
1841
1842 sup_quotes:
1843         '\'' {
1844                 $$ = 1;
1845         }
1846         | sup_quotes '\'' {
1847                 $$ ++;
1848         }
1849         ;
1850
1851 sub_quotes:
1852         ',' {
1853                 $$ = 1;
1854         }
1855         | sub_quotes ',' {
1856                 $$++;
1857         }
1858         ;
1859
1860 steno_pitch:
1861         NOTENAME_PITCH  {
1862                 $$ = $1;
1863         }
1864         | NOTENAME_PITCH sup_quotes     {
1865                 Pitch p = *unsmob_pitch ($1);
1866                 p = p.transposed (Pitch ($2,0,0));
1867                 $$ = p.smobbed_copy ();
1868         }
1869         | NOTENAME_PITCH sub_quotes      {
1870                 Pitch p =* unsmob_pitch ($1);
1871                 p = p.transposed (Pitch (-$2,0,0));
1872                 $$ = p.smobbed_copy ();
1873         }
1874         ;
1875
1876 /*
1877 ugh. duplication
1878 */
1879
1880 steno_tonic_pitch:
1881         TONICNAME_PITCH {
1882                 $$ = $1;
1883         }
1884         | TONICNAME_PITCH sup_quotes    {
1885                 Pitch p = *unsmob_pitch ($1);
1886                 p = p.transposed (Pitch ($2,0,0));
1887                 $$ = p.smobbed_copy ();
1888         }
1889         | TONICNAME_PITCH sub_quotes     {
1890                 Pitch p =* unsmob_pitch ($1);
1891
1892                 p = p.transposed (Pitch (-$2,0,0));
1893                 $$ = p.smobbed_copy ();
1894         }
1895         ;
1896
1897 pitch:
1898         steno_pitch {
1899                 $$ = $1;
1900         }
1901         ;
1902
1903 pitch_also_in_chords:
1904         pitch
1905         | steno_tonic_pitch
1906         ;
1907
1908 gen_text_def:
1909         full_markup {
1910                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1911                 t->set_property ("text", $1);
1912                 t->set_spot (@$);
1913                 $$ = t;
1914         }
1915         | string {
1916                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1917                 t->set_property ("text",
1918                         make_simple_markup ($1));
1919                 t->set_spot (@$);
1920                 $$ = t;
1921
1922         }
1923         | DIGIT {
1924                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1925                 t->set_property ("digit", scm_from_int ($1));
1926                 t->set_spot (@$);
1927                 $$ = t;
1928         }
1929         ;
1930
1931 script_abbreviation:
1932         '^'             {
1933                 $$ = scm_makfrom0str ("Hat");
1934         }
1935         | '+'           {
1936                 $$ = scm_makfrom0str ("Plus");
1937         }
1938         | '-'           {
1939                 $$ = scm_makfrom0str ("Dash");
1940         }
1941         | '|'           {
1942                 $$ = scm_makfrom0str ("Bar");
1943         }
1944         | '>'           {
1945                 $$ = scm_makfrom0str ("Larger");
1946         }
1947         | '.'           {
1948                 $$ = scm_makfrom0str ("Dot");
1949         }
1950         | '_' {
1951                 $$ = scm_makfrom0str ("Underscore");
1952         }
1953         ;
1954
1955 script_dir:
1956         '_'     { $$ = DOWN; }
1957         | '^'   { $$ = UP; }
1958         | '-'   { $$ = CENTER; }
1959         ;
1960
1961
1962 absolute_pitch:
1963         steno_pitch     {
1964                 $$ = $1;
1965         }
1966         ;
1967
1968 duration_length:
1969         multiplied_duration {
1970                 $$ = $1;
1971         }
1972         ;
1973
1974 optional_notemode_duration:
1975         {
1976                 Duration dd = THIS->default_duration_;
1977                 $$ = dd.smobbed_copy ();
1978         }
1979         | multiplied_duration   {
1980                 $$ = $1;
1981                 THIS->default_duration_ = *unsmob_duration ($$);
1982         }
1983         ;
1984
1985 steno_duration:
1986         bare_unsigned dots              {
1987                 int len = 0;
1988                 if (!is_duration ($1))
1989                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
1990                 else
1991                         len = intlog2 ($1);
1992
1993                 $$ = Duration (len, $2).smobbed_copy ();
1994         }
1995         | DURATION_IDENTIFIER dots      {
1996                 Duration *d = unsmob_duration ($1);
1997                 Duration k (d->duration_log (), d->dot_count () + $2);
1998                 *d = k;
1999                 $$ = $1;
2000         }
2001         ;
2002
2003 multiplied_duration:
2004         steno_duration {
2005                 $$ = $1;
2006         }
2007         | multiplied_duration '*' bare_unsigned {
2008                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2009         }
2010         | multiplied_duration '*' FRACTION {
2011                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2012
2013                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2014         }
2015         ;
2016
2017 fraction:
2018         FRACTION { $$ = $1; }
2019         | UNSIGNED '/' UNSIGNED {
2020                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2021         }
2022         ;
2023
2024 dots:
2025         /* empty */     {
2026                 $$ = 0;
2027         }
2028         | dots '.' {
2029                 $$ ++;
2030         }
2031         ;
2032
2033 tremolo_type:
2034         ':'     {
2035                 $$ = 0;
2036         }
2037         | ':' bare_unsigned {
2038                 if (!is_duration ($2))
2039                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2040                 $$ = $2;
2041         }
2042         ;
2043
2044 bass_number:
2045         DIGIT   {
2046                 $$ = scm_from_int ($1);
2047         }
2048         | UNSIGNED {
2049                 $$ = scm_from_int ($1);
2050         }
2051         | STRING { $$ = $1; }
2052         | full_markup { $$ = $1; }
2053         ;
2054
2055 figured_bass_alteration:
2056         '-'     { $$ = -2; }
2057         | '+'   { $$ = 2; }
2058         | '!'   { $$ = 0; }
2059         ;
2060
2061 bass_figure:
2062         FIGURE_SPACE {
2063                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2064                 $$ = bfr->self_scm ();
2065                 bfr->unprotect ();
2066                 bfr->set_spot (@1);
2067         }
2068         | bass_number  {
2069                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2070                 $$ = bfr->self_scm ();
2071
2072                 if (scm_is_number ($1))
2073                         bfr->set_property ("figure", $1);
2074                 else if (Text_interface::is_markup ($1))
2075                         bfr->set_property ("text", $1);
2076
2077                 bfr->unprotect ();
2078                 bfr->set_spot (@1);
2079         }
2080         | bass_figure ']' {
2081                 $$ = $1;
2082                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2083         }
2084         | bass_figure figured_bass_alteration {
2085                 Music *m = unsmob_music ($1);
2086                 if ($2) {
2087                         SCM salter = m->get_property ("alteration");
2088                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2089                         m->set_property ("alteration",
2090                                 scm_from_int (alter + $2));
2091                 } else {
2092                         m->set_property ("alteration", scm_from_int (0));
2093                 }
2094         }
2095         | bass_figure figured_bass_modification  {
2096                 Music *m = unsmob_music ($1);
2097                 if ($2 == ly_symbol2scm ("plus"))
2098                         {
2099                         m->set_property ("augmented", SCM_BOOL_T);
2100                         }
2101                 else if ($2 == ly_symbol2scm ("slash"))
2102                         {
2103                         m->set_property ("diminished", SCM_BOOL_T);
2104                         }
2105                 else if ($2 == ly_symbol2scm ("exclamation"))
2106                         {
2107                         m->set_property ("no-continuation", SCM_BOOL_T);
2108                         }
2109         }
2110         ;
2111
2112
2113 figured_bass_modification:
2114         E_PLUS          {
2115                 $$ = ly_symbol2scm ("plus");
2116         }
2117         | E_EXCLAMATION {
2118                 $$ = ly_symbol2scm ("exclamation");
2119         }
2120         | '/'           {
2121                 $$ = ly_symbol2scm ("slash");
2122         }
2123         ;
2124
2125 br_bass_figure:
2126         bass_figure {
2127                 $$ = $1;
2128         }
2129         | '[' bass_figure {
2130                 $$ = $2;
2131                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2132         }
2133         ;
2134
2135 figure_list:
2136         /**/            {
2137                 $$ = SCM_EOL;
2138         }
2139         | figure_list br_bass_figure {
2140                 $$ = scm_cons ($2, $1);
2141         }
2142         ;
2143
2144 figure_spec:
2145         FIGURE_OPEN figure_list FIGURE_CLOSE {
2146                 Music *m = MY_MAKE_MUSIC ("EventChord");
2147                 $2 = scm_reverse_x ($2, SCM_EOL);
2148                 m->set_property ("elements", $2);
2149                 $$ = m->self_scm ();
2150         }
2151         ;
2152
2153
2154 optional_rest:
2155         /**/   { $$ = 0; }
2156         | REST { $$ = 1; }
2157         ;
2158
2159 simple_element:
2160         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2161                 if (!THIS->lexer_->is_note_state ())
2162                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2163
2164                 Music *n = 0;
2165                 if ($6)
2166                         n = MY_MAKE_MUSIC ("RestEvent");
2167                 else
2168                         n = MY_MAKE_MUSIC ("NoteEvent");
2169
2170                 n->set_property ("pitch", $1);
2171                 n->set_property ("duration", $5);
2172
2173                 if (scm_is_number ($4))
2174                 {
2175                         int q = scm_to_int ($4);
2176                         n->set_property ("absolute-octave", scm_from_int (q-1));
2177                 }
2178
2179                 if ($3 % 2)
2180                         n->set_property ("cautionary", SCM_BOOL_T);
2181                 if ($2 % 2 || $3 % 2)
2182                         n->set_property ("force-accidental", SCM_BOOL_T);
2183
2184                 Music *v = MY_MAKE_MUSIC ("EventChord");
2185                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2186                 n->unprotect ();
2187
2188                 v->set_spot (@$);
2189                 n->set_spot (@$);
2190                 $$ = v;
2191         }
2192         | DRUM_PITCH optional_notemode_duration {
2193                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2194                 n->set_property ("duration", $2);
2195                 n->set_property ("drum-type", $1);
2196
2197                 Music *v = MY_MAKE_MUSIC ("EventChord");
2198                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2199                 n->unprotect ();
2200                 v->set_spot (@$);
2201                 n->set_spot (@$);
2202                 $$ = v;
2203
2204         }
2205         | figure_spec optional_notemode_duration {
2206                 Music *m = unsmob_music ($1);
2207                 m->set_spot (@$);
2208                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2209                 {
2210                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2211                 }
2212                 $$ = m;
2213         }
2214         | RESTNAME optional_notemode_duration           {
2215                 Music *ev = 0;
2216                 if (ly_scm2string ($1) == "s") {
2217                         /* Space */
2218                         ev = MY_MAKE_MUSIC ("SkipEvent");
2219                   }
2220                 else {
2221                         ev = MY_MAKE_MUSIC ("RestEvent");
2222
2223                     }
2224                 ev->set_property ("duration", $2);
2225                 ev->set_spot (@$);
2226                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2227                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2228                 velt->set_spot (@$);
2229
2230                 ev->unprotect();
2231
2232                 $$ = velt;
2233         }
2234         | MULTI_MEASURE_REST optional_notemode_duration         {
2235                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2236                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2237                 $$ = unsmob_music (mus);
2238                 $$->protect ();
2239         }
2240
2241         | lyric_element optional_notemode_duration      {
2242                 if (!THIS->lexer_->is_lyric_state ())
2243                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2244
2245                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2246                 levent->set_property ("text", $1);
2247                 levent->set_property ("duration",$2);
2248                 levent->set_spot (@$);
2249                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2250                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2251
2252                 $$= velt;
2253         }
2254         | new_chord {
2255                 if (!THIS->lexer_->is_chord_state ())
2256                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2257                 $$ = unsmob_music ($1);
2258         }
2259         ;
2260
2261 lyric_element:
2262         lyric_markup {
2263                 $$ = $1;
2264         }
2265         | LYRICS_STRING {
2266                 $$ = $1;
2267         }
2268         ;
2269
2270 new_chord:
2271         steno_tonic_pitch optional_notemode_duration   {
2272                 $$ = make_chord ($1, $2, SCM_EOL);
2273         }
2274         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2275                 SCM its = scm_reverse_x ($4, SCM_EOL);
2276                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2277         }
2278         ;
2279
2280 chord_items:
2281         /**/ {
2282                 $$ = SCM_EOL;
2283         }
2284         | chord_items chord_item {
2285                 $$ = scm_cons ($2, $$);
2286         }
2287         ;
2288
2289 chord_separator:
2290         CHORD_COLON {
2291                 $$ = ly_symbol2scm ("chord-colon");
2292         }
2293         | CHORD_CARET {
2294                 $$ = ly_symbol2scm ("chord-caret");
2295         }
2296         | CHORD_SLASH steno_tonic_pitch {
2297                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2298         }
2299         | CHORD_BASS steno_tonic_pitch {
2300                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2301         }
2302         ;
2303
2304 chord_item:
2305         chord_separator {
2306                 $$ = $1;
2307         }
2308         | step_numbers {
2309                 $$ = scm_reverse_x ($1, SCM_EOL);
2310         }
2311         | CHORD_MODIFIER  {
2312                 $$ = $1;
2313         }
2314         ;
2315
2316 step_numbers:
2317         step_number { $$ = scm_cons ($1, SCM_EOL); }
2318         | step_numbers '.' step_number {
2319                 $$ = scm_cons ($3, $$);
2320         }
2321         ;
2322
2323 step_number:
2324         bare_unsigned {
2325                 $$ = make_chord_step ($1, 0);
2326         }
2327         | bare_unsigned '+' {
2328                 $$ = make_chord_step ($1, SHARP);
2329         }
2330         | bare_unsigned CHORD_MINUS {
2331                 $$ = make_chord_step ($1, FLAT);
2332         }
2333         ;
2334
2335 /*
2336         UTILITIES
2337
2338 TODO: should deprecate in favor of Scheme?
2339
2340  */
2341 number_expression:
2342         number_expression '+' number_term {
2343                 $$ = scm_sum ($1, $3);
2344         }
2345         | number_expression '-' number_term {
2346                 $$ = scm_difference ($1, $3);
2347         }
2348         | number_term
2349         ;
2350
2351 number_term:
2352         number_factor {
2353                 $$ = $1;
2354         }
2355         | number_factor '*' number_factor {
2356                 $$ = scm_product ($1, $3);
2357         }
2358         | number_factor '/' number_factor {
2359                 $$ = scm_divide ($1, $3);
2360         }
2361         ;
2362
2363 number_factor:
2364         '-'  number_factor { /* %prec UNARY_MINUS */
2365                 $$ = scm_difference ($2, SCM_UNDEFINED);
2366         }
2367         | bare_number
2368         ;
2369
2370
2371 bare_number:
2372         UNSIGNED        {
2373                 $$ = scm_from_int ($1);
2374         }
2375         | REAL          {
2376                 $$ = $1;
2377         }
2378         | NUMBER_IDENTIFIER             {
2379                 $$ = $1;
2380         }
2381         | REAL NUMBER_IDENTIFIER        {
2382                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2383         }
2384         | UNSIGNED NUMBER_IDENTIFIER    {
2385                 $$ = scm_from_double ($1 *scm_to_double ($2));
2386         }
2387         ;
2388
2389
2390 bare_unsigned:
2391         UNSIGNED {
2392                         $$ = $1;
2393         }
2394         | DIGIT {
2395                 $$ = $1;
2396         }
2397         ;
2398
2399 exclamations:
2400                 { $$ = 0; }
2401         | exclamations '!'      { $$ ++; }
2402         ;
2403
2404 questions:
2405                 { $$ = 0; }
2406         | questions '?' { $$ ++; }
2407         ;
2408
2409 /*
2410 This should be done more dynamically if possible.
2411 */
2412
2413 lyric_markup:
2414         LYRIC_MARKUP_IDENTIFIER {
2415                 $$ = $1;
2416         }
2417         | LYRIC_MARKUP
2418                 { THIS->lexer_->push_markup_state (); }
2419         markup_top {
2420                 $$ = $3;
2421                 THIS->lexer_->pop_state ();
2422         }
2423         ;
2424
2425 full_markup:
2426         MARKUP_IDENTIFIER {
2427                 $$ = $1;
2428         }
2429         | MARKUP
2430                 { THIS->lexer_->push_markup_state (); }
2431         markup_top {
2432                 $$ = $3;
2433                 THIS->lexer_->pop_state ();
2434         }
2435         ;
2436
2437 markup_top:
2438         markup_list {
2439                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2440         }
2441         | markup_head_1_list simple_markup      {
2442                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2443         }
2444         | simple_markup {
2445                 $$ = $1;
2446         }
2447         ;
2448
2449 markup_list:
2450         markup_composed_list {
2451                 $$ = $1;
2452         }
2453         | markup_braced_list {
2454                 $$ = $1;
2455         }
2456         ;
2457
2458 markup_composed_list:
2459         markup_head_1_list markup_braced_list {
2460                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2461
2462         }
2463         ;
2464
2465 markup_braced_list:
2466         '{' markup_braced_list_body '}' {
2467                 $$ = scm_reverse_x ($2, SCM_EOL);
2468         }
2469         ;
2470
2471 markup_braced_list_body:
2472         /* empty */     {  $$ = SCM_EOL; }
2473         | markup_braced_list_body markup {
2474                 $$ = scm_cons ($2, $1);
2475         }
2476         | markup_braced_list_body markup_list {
2477                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2478         }
2479         ;
2480
2481 markup_head_1_item:
2482         MARKUP_HEAD_MARKUP0     {
2483                 $$ = scm_list_1 ($1);
2484         }
2485         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2486                 $$ = scm_list_2 ($1, $2);
2487         }
2488         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2489                 $$ = scm_list_3 ($1, $2, $3);
2490         }
2491         ;
2492
2493 markup_head_1_list:
2494         markup_head_1_item      {
2495                 $$ = scm_list_1 ($1);
2496         }
2497         | markup_head_1_list markup_head_1_item {
2498                 $$ = scm_cons ($2, $1);
2499         }
2500         ;
2501
2502 simple_markup:
2503         STRING {
2504                 $$ = make_simple_markup ($1);
2505         }
2506         | MARKUP_IDENTIFIER {
2507                 $$ = $1;
2508         }
2509         | LYRIC_MARKUP_IDENTIFIER {
2510                 $$ = $1;
2511         }
2512         | STRING_IDENTIFIER {
2513                 $$ = $1;
2514         }
2515         | SCORE {
2516                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2517                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2518         } '{' score_body '}' {
2519                 Score * sc = $4;
2520                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2521                 sc->unprotect ();
2522                 THIS->lexer_->pop_state ();
2523         }
2524         | MARKUP_HEAD_SCM0 embedded_scm {
2525                 $$ = scm_list_2 ($1, $2);
2526         }
2527         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2528                 $$ = scm_list_4 ($1, $2, $3, $4);
2529         }
2530         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2531                 $$ = scm_list_3 ($1, $2, $3);
2532         }
2533         | MARKUP_HEAD_EMPTY {
2534                 $$ = scm_list_1 ($1);
2535         }
2536         | MARKUP_HEAD_LIST0 markup_list {
2537                 $$ = scm_list_2 ($1,$2);
2538         }
2539         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2540                 $$ = scm_list_3 ($1, $2, $3);
2541         }
2542         ;
2543
2544 markup:
2545         markup_head_1_list simple_markup        {
2546                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2547                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2548         }
2549         | simple_markup {
2550                 $$ = $1;
2551         }
2552         ;
2553
2554 %%
2555
2556 void
2557 Lily_parser::set_yydebug (bool )
2558 {
2559 #if 0
2560         yydebug = 1;
2561 #endif
2562 }
2563
2564 void
2565 Lily_parser::do_yyparse ()
2566 {
2567         yyparse ((void*)this);
2568 }
2569
2570
2571
2572
2573
2574 /*
2575
2576 It is a little strange to have this function in this file, but
2577 otherwise, we have to import music classes into the lexer.
2578
2579 */
2580 int
2581 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2582 {
2583         if (scm_is_string (sid)) {
2584                 *destination = sid;
2585                 return STRING_IDENTIFIER;
2586         } else if (unsmob_book (sid)) {
2587                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2588                 return BOOK_IDENTIFIER;
2589         } else if (scm_is_number (sid)) {
2590                 *destination = sid;
2591                 return NUMBER_IDENTIFIER;
2592         } else if (unsmob_context_def (sid)) {
2593                 *destination = unsmob_context_def (sid)->clone_scm ();
2594                 return CONTEXT_DEF_IDENTIFIER;
2595         } else if (unsmob_score (sid)) {
2596                 Score *score = new Score (*unsmob_score (sid));
2597                 *destination = score->self_scm ();
2598                 return SCORE_IDENTIFIER;
2599         } else if (Music *mus = unsmob_music (sid)) {
2600                 mus = mus->clone ();
2601                 *destination = mus->self_scm ();
2602                 unsmob_music (*destination)->
2603                         set_property ("origin", make_input (last_input_));
2604
2605                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2606                         != SCM_BOOL_F;
2607
2608                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2609         } else if (unsmob_duration (sid)) {
2610                 *destination = unsmob_duration (sid)->smobbed_copy ();
2611                 return DURATION_IDENTIFIER;
2612         } else if (unsmob_output_def (sid)) {
2613                 Output_def *p = unsmob_output_def (sid);
2614                 p = p->clone ();
2615
2616                 *destination = p->self_scm ();
2617                 return OUTPUT_DEF_IDENTIFIER;
2618         } else if (Text_interface::is_markup (sid)) {
2619                 *destination = sid;
2620                 if (is_lyric_state ())
2621                         return LYRIC_MARKUP_IDENTIFIER;
2622                 return MARKUP_IDENTIFIER;
2623         }
2624
2625         return -1;
2626 }
2627
2628 Music *
2629 property_op_to_music (SCM op)
2630 {
2631         Music *m = 0;
2632         SCM tag = scm_car (op);
2633         SCM symbol = scm_cadr (op);
2634         SCM args = scm_cddr (op);
2635         SCM grob_val = SCM_UNDEFINED;
2636         SCM grob_path = SCM_UNDEFINED;
2637         SCM val = SCM_UNDEFINED;
2638
2639         if (tag == ly_symbol2scm ("assign"))
2640                 {
2641                 m = MY_MAKE_MUSIC ("PropertySet");
2642                 val = scm_car (args);
2643                 }
2644         else if (tag == ly_symbol2scm ("unset"))
2645                 m = MY_MAKE_MUSIC ("PropertyUnset");
2646         else if (tag == ly_symbol2scm ("push"))
2647                 {
2648                 m = MY_MAKE_MUSIC ("OverrideProperty");
2649                 grob_val = scm_car (args);
2650                 grob_path = scm_cdr (args);
2651                 m->set_property ("pop-first", SCM_BOOL_T);
2652                 }
2653         else if (tag == ly_symbol2scm ("pop")) {
2654                 m = MY_MAKE_MUSIC ("RevertProperty");
2655                 grob_path = args;
2656                 }
2657
2658         m->set_property ("symbol", symbol);
2659
2660         if (val != SCM_UNDEFINED)
2661                 m->set_property ("value", val);
2662         if (grob_val != SCM_UNDEFINED)
2663                 m->set_property ("grob-value", grob_val);
2664         if (grob_path != SCM_UNDEFINED)
2665                 m->set_property ("grob-property-path", grob_path);
2666
2667         return m;
2668 }
2669
2670 Music*
2671 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2672 {
2673         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2674
2675         csm->set_property ("element", m->self_scm ());
2676         m->unprotect ();
2677
2678         csm->set_property ("context-type",
2679                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2680         csm->set_property ("property-operations", ops);
2681
2682         if (scm_is_string (id))
2683                 csm->set_property ("context-id", id);
2684         return csm;
2685 }
2686
2687 SCM
2688 get_next_unique_context_id ()
2689 {
2690         return scm_makfrom0str ("$uniqueContextId");
2691 }
2692
2693
2694 SCM
2695 get_next_unique_lyrics_context_id ()
2696 {
2697         static int new_context_count;
2698         char s[128];
2699         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2700         return scm_makfrom0str (s);
2701 }
2702
2703
2704 Music *
2705 run_music_function (Lily_parser *parser, SCM expr)
2706 {
2707         SCM func = scm_car (expr);
2708         Input *loc = unsmob_input (scm_cadr (expr));
2709         SCM args = scm_cddr (expr);
2710         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2711
2712         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2713         bool ok  = true;
2714
2715         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2716         {
2717                 parser->error_level_ = 1;
2718                 ok = false;
2719         }
2720
2721         SCM m = SCM_EOL;
2722         if (ok)
2723                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2724                                                  scm_cdr (expr)));
2725
2726
2727         Music* retval = 0;
2728         if (unsmob_music (m))
2729                 {
2730                 retval = unsmob_music (m);
2731                 retval->protect ();
2732                 }
2733         else
2734                 {
2735                 if (ok)
2736                         loc->error (_ ("music head function must return Music object"));
2737                 retval = MY_MAKE_MUSIC ("Music");
2738                 }
2739         retval->set_spot (*loc);
2740         return retval;
2741 }
2742
2743 bool
2744 is_regular_identifier (SCM id)
2745 {
2746   std::string str = ly_scm2string (id);
2747   char const *s = str.c_str ();
2748
2749   bool v = true;
2750 #if 0
2751   isalpha (*s);
2752   s++;
2753 #endif
2754   while (*s && v)
2755    {
2756         v = v && isalnum (*s);
2757         s++;
2758    }
2759   return v;
2760 }
2761
2762
2763 SCM
2764 get_first_context_id (SCM type, Music *m)
2765 {
2766         SCM id = m->get_property ("context-id");
2767         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2768             && scm_is_string (m->get_property ("context-id"))
2769             && scm_c_string_length (id) > 0)
2770         {
2771                 return id;
2772         }
2773         return SCM_EOL;
2774 }
2775
2776 SCM
2777 make_simple_markup (SCM a)
2778 {
2779         return a;
2780 }
2781
2782 bool
2783 is_duration (int t)
2784 {
2785   return t && t == 1 << intlog2 (t);
2786 }
2787
2788 void
2789 set_music_properties (Music *p, SCM a)
2790 {
2791   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2792         p->internal_set_property (scm_caar (k), scm_cdar (k));
2793 }
2794
2795
2796 SCM
2797 make_chord_step (int step, int alter)
2798 {
2799         if (step == 7)
2800                 alter += FLAT;
2801
2802         while (step < 0)
2803                 step += 7;
2804         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2805         return m.smobbed_copy ();
2806 }
2807
2808
2809 SCM
2810 make_chord (SCM pitch, SCM dur, SCM modification_list)
2811 {
2812         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2813         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2814
2815         unsmob_music (ch)->protect();
2816         return ch;
2817 }
2818
2819
2820 /* Todo: actually also use apply iso. call too ...  */
2821 bool
2822 ly_input_procedure_p (SCM x)
2823 {
2824         return ly_is_procedure (x)
2825                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2826 }
2827
2828 Music*
2829 set_property_music (SCM sym, SCM value)
2830 {
2831         Music *p = MY_MAKE_MUSIC ("PropertySet");
2832         p->set_property ("symbol", sym);
2833         p->set_property ("value", value);
2834         return p;
2835 }
2836
2837 Music*
2838 make_music_relative (Pitch start, Music *music)
2839 {
2840         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2841         relative->set_property ("element", music->self_scm ());
2842
2843         Pitch last = music->to_relative_octave (start);
2844         if (lily_1_8_relative)
2845                 music->set_property ("last-pitch", last.smobbed_copy ());
2846         return relative;
2847 }
2848
2849 Music *
2850 make_lyric_combine_music (SCM name, Music *music)
2851 {
2852         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2853         combine->set_property ("element", music->self_scm ());
2854         combine->set_property ("associated-context", name);
2855         return combine;
2856 }
2857
2858
2859 int
2860 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2861 {
2862         Lily_parser *pars = (Lily_parser*) v;
2863         Lily_lexer *lex = pars->lexer_;
2864
2865         lex->lexval = (void*) s;
2866         lex->lexloc = loc;
2867         lex->prepare_for_next_token ();
2868         return lex->yylex ();
2869 }