lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token LYRICS_STRING
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token NEWLYRICS
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307 %token MARKUP
 308
 309 /* escaped */
 310 /* FIXME: this sucks.  The user will get to see these names:
 311     syntax error, unexpected E_CHAR:
 312                 \
 313                  %%
 314   */
 315
 316 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 317 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 318 %token E_BACKSLASH
 319 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 320 %token FIGURE_SPACE
 321
 322 %token <i>      DIGIT
 323 %token <i>      UNSIGNED
 324 %token <i> E_UNSIGNED
 325 %token <id>     IDENTIFIER
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DRUM_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    EVENT_IDENTIFIER
 330 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    NUMBER_IDENTIFIER
 333 %token <scm>    OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    RESTNAME
 335 %token <scm>    SCM_T
 336 %token <scm>    SCORE_IDENTIFIER
 337 %token <scm>    STRING
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    TONICNAME_PITCH
 340 %token <scm>    CHORD_MODIFIER
 341 %token <scm>    FRACTION
 342 %token <scm>   REAL
 343 %token <scm> MARKUP_HEAD_EMPTY
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0
 347 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 352 %token <scm> MUSIC_FUNCTION
 353 %token <scm> MUSIC_FUNCTION_MUSIC
 354 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 355 %token <scm> MUSIC_FUNCTION_SCM
 356 %token <scm> MUSIC_FUNCTION_SCM_SCM
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 360 %token DRUMS
 361
 362
 363
 364 %type <book>    book_block book_body
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       exclamations questions dots optional_rest
 367 %type <i>       script_dir
 368 %type <i>       sub_quotes sup_quotes
 369 %type <i>       tremolo_type
 370 %type <i>       bass_mod
 371
 372 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 373 %type <music>   Grouped_music_list
 374 %type <music>   Music Sequential_music Simultaneous_music
 375 %type <music>   Repeated_music
 376 %type <music>   command_req
 377 %type <music>   gen_text_def direction_less_event direction_reqd_event
 378 %type <music>   music_property_def context_change
 379 %type <music>   note_chord_element chord_body chord_body_element
 380 %type <music>   open_event close_event
 381 %type <music>   post_event tagged_post_event
 382 %type <music>   relative_music re_rhythmed_music
 383 %type <music>   simple_element event_chord command_element
 384 %type <music>   string_number_event
 385 %type <music>   toplevel_music
 386 %type <music>   tempo_event
 387
 388 %type <outputdef>       output_def_body output_def_head
 389 %type <outputdef> output_def book_paper_block
 390
 391 %type <scm>     Music_list
 392 %type <scm>     chord_body_elements
 393 %type <scm>     chord_item chord_items chord_separator new_chord
 394 %type <scm>     context_def_spec_block context_def_spec_body
 395 %type <scm>     context_mod context_def_mod optional_context_mod
 396 %type <scm>     context_prop_spec
 397 %type <scm>     duration_length fraction
 398 %type <scm>     embedded_scm scalar
 399 %type <scm>     identifier_init
 400 %type <scm>     lilypond_header lilypond_header_body
 401 %type <scm>     new_lyrics
 402 %type <scm>     post_events
 403 %type <scm>     property_operation
 404 %type <scm>     script_abbreviation
 405 %type <scm>     simple_string
 406 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 407 %type <scm>     steno_tonic_pitch
 408 %type <scm>     step_number step_numbers
 409 %type <scm>     string bare_number number_expression number_term number_factor
 410 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 411 %type <scm>     context_mod_list
 412 %type <scm>     octave_check
 413 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 414 %type <scm>     Generic_prefix_music_scm
 415 %type <scm>     lyric_element
 416 %type <scm>     Alternative_music
 417 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 418
 419 %type <score>   score_block score_body
 420
 421
 422 %left '-' '+'
 423
 424 /* We don't assign precedence to / and *, because we might need varied
 425 prec levels in different prods */
 426
 427 %left UNARY_MINUS
 428
 429 %%
 430
 431 lilypond:       /* empty */
 432         | lilypond toplevel_expression {
 433         }
 434         | lilypond assignment {
 435         }
 436         | lilypond error {
 437                 THIS->error_level_ = 1;
 438         }
 439         | lilypond INVALID      {
 440                 THIS->error_level_ = 1;
 441         }
 442         ;
 443
 444 toplevel_expression:
 445         lilypond_header {
 446                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 447         }
 448         | add_quote {
 449
 450         }
 451         | book_block {
 452                 Book *book = $1;
 453                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 454                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 455                 scm_gc_unprotect_object (book->self_scm ());
 456         }
 457         | score_block {
 458                 Score *score = $1;
 459
 460                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 461                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 462                 scm_gc_unprotect_object (score->self_scm ());
 463         }
 464         | toplevel_music {
 465                 Music *music = $1;
 466                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 467                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 468                 scm_gc_unprotect_object (music->self_scm ());
 469         }
 470         | output_def {
 471                 SCM id = SCM_EOL;
 472                 Output_def * od = $1;
 473
 474                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 475                         id = ly_symbol2scm ("$defaultpaper");
 476                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 477                         id = ly_symbol2scm ("$defaultmidi");
 478                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 479                         id = ly_symbol2scm ("$defaultbookpaper");
 480
 481                 THIS->lexer_->set_identifier (id, od->self_scm ());
 482                 scm_gc_unprotect_object (od->self_scm ());
 483         }
 484         ;
 485
 486 toplevel_music:
 487         Composite_music {
 488         }
 489         ;
 490
 491 embedded_scm:
 492         SCM_T
 493         | SCM_IDENTIFIER
 494         ;
 495
 496
 497 lilypond_header_body:
 498         {
 499                 $$ = ly_make_anonymous_module (safe_global_b);
 500                 THIS->lexer_->add_scope ($$);
 501         }
 502         | lilypond_header_body assignment  {
 503
 504         }
 505         ;
 506
 507 lilypond_header:
 508         HEADER '{' lilypond_header_body '}'     {
 509                 $$ = THIS->lexer_->remove_scope ();
 510         }
 511         ;
 512
 513
 514 /*
 515         DECLARATIONS
 516 */
 517 assignment:
 518         STRING {
 519                 THIS->push_spot ();
 520         }
 521         /* cont */ '=' identifier_init  {
 522
 523         /*
 524                 Should find generic way of associating input with objects.
 525         */
 526                 Input ip = THIS->pop_spot ();
 527
 528                 if (! is_regular_identifier ($1))
 529                 {
 530                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 531                 }
 532
 533                 THIS->lexer_->set_identifier ($1, $4);
 534
 535 /*
 536  TODO: devise standard for protection in parser.
 537
 538   The parser stack lives on the C-stack, which means that
 539 all objects can be unprotected as soon as they're here.
 540
 541 */
 542         }
 543         | embedded_scm { }
 544         ;
 545
 546
 547 identifier_init:
 548         score_block {
 549                 $$ = $1->self_scm ();
 550                 scm_gc_unprotect_object ($$);
 551         }
 552         | full_markup {
 553                 $$ = $1;
 554         }
 555         | output_def {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | context_def_spec_block {
 560                 $$ = $1;
 561         }
 562         | Music  {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | post_event {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | number_expression {
 571                 $$ = $1;
 572         }
 573         | string {
 574                 $$ = $1;
 575         }
 576         | embedded_scm  {
 577                 $$ = $1;
 578         }
 579         ;
 580
 581 context_def_spec_block:
 582         CONTEXT '{' context_def_spec_body '}'
 583                 {
 584                 $$ = $3;
 585         }
 586         ;
 587
 588 context_def_spec_body:
 589         /**/ {
 590                 $$ = Context_def::make_scm ();
 591                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 592         }
 593         | CONTEXT_DEF_IDENTIFIER {
 594                 $$ = $1;
 595                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 596         }
 597         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 598                 Context_def*td = unsmob_context_def ($$);
 599
 600                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 601                         SCM tag = ly_caar (p);
 602
 603                         /* TODO: should make new tag "grob-definition" ? */
 604                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 605                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 606                 }
 607         }
 608         | context_def_spec_body context_mod {
 609                 unsmob_context_def ($$)->add_context_mod ($2);
 610         }
 611         ;
 612
 613
 614
 615 book_block:
 616         BOOK {
 617                 THIS->push_spot ();
 618         }
 619         /*cont*/ '{' book_body '}'      {
 620                 THIS->pop_spot ();
 621                 $$ = $4;
 622         }
 623         ;
 624
 625 /* FIXME:
 626    * Use 'handlers' like for toplevel-* stuff?
 627    * grok \paper and \midi?  */
 628 book_body:
 629         {
 630                 $$ = new Book;
 631                 $$->set_spot (THIS->here_input ());
 632                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 633                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 634                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 635         }
 636         | book_body book_paper_block {
 637                 $$->bookpaper_ = $2;
 638                 scm_gc_unprotect_object ($2->self_scm ());
 639         }
 640         | book_body score_block {
 641                 Score *score = $2;
 642                 $$->scores_.push (score);
 643                 scm_gc_unprotect_object (score->self_scm ());
 644         }
 645         | book_body Composite_music {
 646                 Music *music = $2;
 647                 Score *score
 648                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 649                 $$->scores_.push (score);
 650                 scm_gc_unprotect_object (music->self_scm ());
 651         }
 652         | book_body lilypond_header {
 653                 $$->header_ = $2;
 654         }
 655         | book_body error {
 656
 657         }
 658         ;
 659
 660 score_block:
 661         SCORE {
 662                 THIS->push_spot ();
 663         }
 664         /*cont*/ '{' score_body '}'     {
 665                 THIS->pop_spot ();
 666                 $$ = $4;
 667         }
 668         ;
 669
 670 score_body:
 671         /**/    {
 672                 $$ = new Score;
 673
 674                 $$->set_spot (THIS->here_input ());
 675         }
 676         | SCORE_IDENTIFIER {
 677                 $$ = new Score ( *unsmob_score ($1));
 678                 $$->set_spot (THIS->here_input ());
 679         }
 680         | score_body Music {
 681                 SCM m = $2->self_scm ();
 682                 scm_gc_unprotect_object (m);
 683
 684                 /*
 685                         guh.
 686                 */
 687                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 688                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 689                         m = scm_call_1 (ly_car (check_funcs), m);
 690                 if (unsmob_music ($$->music_))
 691                 {
 692                         THIS->parser_error (_("Already have music in score"));
 693                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 694                 }
 695                 $$->music_ = m;
 696         }
 697         | score_body lilypond_header    {
 698                 $$->header_ = $2;
 699         }
 700         | score_body output_def {
 701                 $$->defs_.push ($2);
 702                 scm_gc_unprotect_object ($2->self_scm ());
 703         }
 704         | score_body error {
 705
 706         }
 707         ;
 708
 709
 710 /*
 711         OUTPUT DEF
 712 */
 713
 714 book_paper_block:
 715         output_def {
 716                 $$ = $1;
 717                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 718                 {
 719                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 720                         $$ = get_bookpaper (THIS);
 721                 }
 722         }
 723         ;
 724
 725
 726 output_def:
 727         output_def_body '}' {
 728                 $$ = $1;
 729                 if ($1->parent_)
 730                         THIS->lexer_->remove_scope ();
 731
 732                 THIS->lexer_->remove_scope ();
 733                 THIS->lexer_->pop_state ();
 734         }
 735         ;
 736
 737 output_def_head:
 738         BOOKPAPER {
 739                 $$ = get_bookpaper (THIS);
 740                 $$->input_origin_ = THIS->here_input ();
 741                 THIS->lexer_->add_scope ($$->scope_);
 742         }
 743         | MIDI    {
 744                 Output_def *p = get_midi (THIS);
 745                 $$ = p;
 746                 THIS->lexer_->add_scope (p->scope_);
 747         }
 748         | PAPER         {
 749                 Output_def* p = get_paper (THIS);
 750
 751                 if (p->parent_)
 752                         THIS->lexer_->add_scope (p->parent_->scope_);
 753
 754                 THIS->lexer_->add_scope (p->scope_);
 755                 $$ = p;
 756         }
 757         ;
 758
 759
 760 output_def_body:
 761         output_def_head '{' {
 762                 $$ = $1;
 763                 $$->input_origin_.set_spot (THIS->here_input ());
 764                 THIS->lexer_->push_initial_state ();
 765         }
 766         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 767                 scm_gc_unprotect_object ($1->self_scm ());
 768                 Output_def *o = unsmob_output_def ($3);
 769                 o->input_origin_.set_spot (THIS->here_input ());
 770                 $$ = o;
 771                 THIS->lexer_->remove_scope ();
 772                 THIS->lexer_->add_scope (o->scope_);
 773                 THIS->lexer_->push_initial_state ();
 774         }
 775         | output_def_body assignment  {
 776
 777         }
 778         | output_def_body context_def_spec_block        {
 779                 assign_context_def ($$, $2);
 780         }
 781         | output_def_body tempo_event  {
 782                 /*
 783                         junk this ? there already is tempo stuff in
 784                         music.
 785                 */
 786                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 787                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 788                 set_tempo ($$, d->get_length (), m);
 789                 scm_gc_unprotect_object ($2->self_scm ());
 790         }
 791         | output_def_body error {
 792
 793         }
 794         ;
 795
 796 tempo_event:
 797         TEMPO steno_duration '=' bare_unsigned  {
 798                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 799                 $$->set_property ("tempo-unit", $2);
 800                 $$->set_property ("metronome-count", scm_int2num ( $4));
 801         }
 802         ;
 803
 804 /*
 805 The representation of a  list is the
 806
 807   (LIST . LAST-CONS)
 808
 809  to have  efficient append.
 810 */
 811 Music_list:
 812         /* empty */ {
 813                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 814         }
 815         | Music_list Music {
 816                 SCM s = $$;
 817                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 818                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 819                 if (ly_c_pair_p (ly_cdr (s)))
 820                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 821                 else
 822                         scm_set_car_x (s, c); /* set first cons */
 823                 scm_set_cdr_x (s, c);  /* remember last cell */
 824         }
 825         | Music_list embedded_scm {
 826         }
 827         | Music_list error {
 828         }
 829         ;
 830
 831
 832 Music:
 833         Simple_music
 834         | Composite_music
 835         ;
 836
 837 Alternative_music:
 838         /* empty */ {
 839                 $$ = SCM_EOL;
 840         }
 841         | ALTERNATIVE '{' Music_list '}' {
 842                 $$ = $3;
 843         }
 844         ;
 845
 846
 847 Repeated_music:
 848         REPEAT simple_string bare_unsigned Music Alternative_music
 849         {
 850                 Music *beg = $4;
 851                 int times = $3;
 852                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 853                 if (times < scm_ilength (alts)) {
 854                   unsmob_music (ly_car (alts))
 855                     ->origin ()->warning (
 856                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 857                   alts = ly_truncate_list (times, alts);
 858                 }
 859
 860
 861                 SCM proc = ly_scheme_function ("make-repeated-music");
 862
 863                 SCM mus = scm_call_1 (proc, $2);
 864                 scm_gc_protect_object (mus); // UGH.
 865                 Music *r = unsmob_music (mus);
 866                 if (beg)
 867                         {
 868                         r-> set_property ("element", beg->self_scm ());
 869                         scm_gc_unprotect_object (beg->self_scm ());
 870                         }
 871                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 872
 873                 r-> set_property ("elements",alts);
 874                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 875                         /*
 876                         TODO: move this code to Scheme.
 877                         */
 878
 879                         /*
 880                         we can not get durations and other stuff correct down the line, so we have to
 881                         add to the duration log here.
 882                         */
 883                         SCM func = ly_scheme_function ("shift-duration-log");
 884
 885                         int dots = ($3 % 3) ? 0 : 1;
 886                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 887
 888                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 889
 890                         if (seq) {
 891                                 int list_len = scm_ilength (seq->music_list ());
 892                                 if (list_len != 2)
 893                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 894                                 shift -= 1;
 895                                 r->compress (Moment (Rational (1, list_len)));
 896                                 }
 897                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 898
 899                 }
 900                 r->set_spot (*$4->origin ());
 901
 902                 $$ = r;
 903         }
 904         ;
 905
 906 Sequential_music:
 907         SEQUENTIAL '{' Music_list '}'           {
 908                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 909                 $$->set_property ("elements", ly_car ($3));
 910                 $$->set_spot (THIS->here_input ());
 911         }
 912         | '{' Music_list '}'            {
 913                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 914                 $$->set_property ("elements", ly_car ($2));
 915                 $$->set_spot (THIS->here_input ());
 916         }
 917         ;
 918
 919 Simultaneous_music:
 920         SIMULTANEOUS '{' Music_list '}'{
 921                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 922                 $$->set_property ("elements", ly_car ($3));
 923                 $$->set_spot (THIS->here_input ());
 924
 925         }
 926         | simul_open Music_list simul_close     {
 927                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 928                 $$->set_property ("elements", ly_car ($2));
 929                 $$->set_spot (THIS->here_input ());
 930         }
 931         ;
 932
 933 Simple_music:
 934         event_chord             { $$ = $1; }
 935         | MUSIC_IDENTIFIER {
 936                 $$ = unsmob_music ($1);
 937         }
 938         | music_property_def
 939         | context_change
 940         ;
 941
 942
 943 optional_context_mod:
 944         /**/ { $$ = SCM_EOL; }
 945         | WITH { THIS->lexer_->push_initial_state (); }
 946         '{' context_mod_list '}'
 947         {
 948                 THIS->lexer_->pop_state ();
 949                 $$ = $4;
 950         }
 951         ;
 952
 953 context_mod_list:
 954         /* */  { $$ = SCM_EOL; }
 955         | context_mod_list context_mod  {
 956                  $$ = scm_cons ($2, $1);
 957         }
 958         ;
 959
 960
 961 Composite_music:
 962         Prefix_composite_music { $$ = $1; }
 963         | Grouped_music_list { $$ = $1; }
 964         ;
 965
 966 Grouped_music_list:
 967         Simultaneous_music              { $$ = $1; }
 968         | Sequential_music              { $$ = $1; }
 969         ;
 970
 971 Generic_prefix_music_scm:
 972         MUSIC_FUNCTION {
 973                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 974         }
 975         | MUSIC_FUNCTION_SCM {
 976                 THIS->push_spot ();
 977         } embedded_scm {
 978                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 979         }
 980         | MUSIC_FUNCTION_MUSIC {
 981                 THIS->push_spot ();
 982         } Music {
 983                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 984                 scm_gc_unprotect_object ($3->self_scm ());
 985         }
 986         | MUSIC_FUNCTION_SCM_MUSIC {
 987                 THIS->push_spot ();
 988         }  embedded_scm Music {
 989                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 990                 scm_gc_unprotect_object ($4->self_scm ());
 991         }
 992         | MUSIC_FUNCTION_SCM_SCM {
 993                 THIS->push_spot ();
 994         }  embedded_scm embedded_scm {
 995                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 996         }
 997         | MUSIC_FUNCTION_MUSIC_MUSIC {
 998                 THIS->push_spot ();
 999         }  Music  Music {
1000                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1001                 scm_gc_unprotect_object ($3->self_scm ());
1002                 scm_gc_unprotect_object ($4->self_scm ());
1003         }
1004         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1005                 THIS->push_spot ();
1006         } embedded_scm Music Music {
1007                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1008                         $3, $4->self_scm (), $5->self_scm ());
1009                 scm_gc_unprotect_object ($5->self_scm ());
1010                 scm_gc_unprotect_object ($4->self_scm ());
1011         }
1012         ;
1013
1014 Generic_prefix_music:
1015         Generic_prefix_music_scm {
1016                 SCM func = ly_car ($1);
1017                 Input *loc = unsmob_input (ly_cadr ($1));
1018                 SCM args = ly_cddr ($1);
1019                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1020                 int k = 0;
1021                 bool ok  = true;
1022                 for (SCM s = sig, t = args;
1023                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1024                         s = ly_cdr (s), t = ly_cdr (t)) {
1025                         k++;
1026                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1027                         {
1028                                 loc->error (_f ("Argument %d failed typecheck", k));
1029                                 THIS->error_level_ = 1;
1030                                 ok = false;
1031                         }
1032                 }
1033                 SCM m = SCM_EOL;
1034                 if (ok)
1035                         m = scm_apply_0 (func, ly_cdr ($1));
1036                 if (unsmob_music (m))
1037                         {
1038                         $$ = unsmob_music (m);
1039                         scm_gc_protect_object (m);
1040                         }
1041                 else
1042                         {
1043                         if (ok)
1044                                 loc->error (_ ("Music head function should return Music object."));
1045                         $$ = MY_MAKE_MUSIC ("Music");
1046                         }
1047                 $$->set_spot (*loc);
1048         }
1049         ;
1050
1051
1052 Prefix_composite_music:
1053         Generic_prefix_music {
1054                 $$ = $1;
1055         }
1056         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1057                 $$ = context_spec_music ($2, $4, $6, $5);
1058
1059         }
1060         | CONTEXT simple_string optional_context_mod Music {
1061                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1062         }
1063         | NEWCONTEXT simple_string optional_context_mod Music {
1064                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1065                         $3);
1066         }
1067
1068         | TIMES {
1069                 THIS->push_spot ();
1070         }
1071         /* CONTINUED */
1072                 fraction Music
1073
1074         {
1075                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1076                 Music *mp = $4;
1077
1078                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1079                 $$->set_spot (THIS->pop_spot ());
1080
1081                 $$->set_property ("element", mp->self_scm ());
1082                 scm_gc_unprotect_object (mp->self_scm ());
1083                 $$->set_property ("numerator", scm_int2num (n));
1084                 $$->set_property ("denominator", scm_int2num (d));
1085                 $$->compress (Moment (Rational (n,d)));
1086
1087         }
1088         | Repeated_music                { $$ = $1; }
1089         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1090                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1091                 Music *p = $4;
1092                 Pitch from = *unsmob_pitch ($2);
1093                 Pitch to = *unsmob_pitch ($3);
1094
1095                 p->transpose (interval (from, to));
1096                 $$->set_property ("element", p->self_scm ());
1097                 scm_gc_unprotect_object (p->self_scm ());
1098         }
1099         | NOTES
1100                 {
1101                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1102                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1103         }
1104         Music
1105                 { $$ = $3;
1106                   THIS->lexer_->pop_state ();
1107                 }
1108         | DRUMS
1109                 {
1110                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1111                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1112         }
1113         /* FIXME: This used to be: */
1114         Music
1115 /*      Grouped_music_list */
1116                 { $$ = $3;
1117                   THIS->lexer_->pop_state ();
1118                 }
1119         | FIGURES
1120                 { THIS->lexer_->push_figuredbass_state (); }
1121         /* FIXME: This used to be:
1122         Music
1123         but that breaks web build
1124         */
1125         Grouped_music_list
1126                 {
1127                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1128                   chm->set_property ("element", $3->self_scm ());
1129                   $$ = chm;
1130                   scm_gc_unprotect_object ($3->self_scm ());
1131
1132                   THIS->lexer_->pop_state ();
1133         }
1134         | CHORDS {
1135                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1136                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1137                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1138                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1139
1140         }
1141         /* FIXME:
1142         Music
1143 */
1144         Grouped_music_list
1145         {
1146                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1147                   chm->set_property ("element", $3->self_scm ());
1148                   scm_gc_unprotect_object ($3->self_scm ());
1149                   $$ = chm;
1150
1151                   THIS->lexer_->pop_state ();
1152         }
1153         | LYRICS
1154                 { THIS->lexer_->push_lyric_state (); }
1155         /* FIXME:
1156         Music
1157 */
1158         Grouped_music_list
1159                 {
1160                   $$ = $3;
1161                   THIS->lexer_->pop_state ();
1162         }
1163         | relative_music        { $$ = $1; }
1164         | re_rhythmed_music     { $$ = $1; }
1165         | TAG embedded_scm Music {
1166                 tag_music ($3, $2, THIS->here_input ());
1167                 $$ = $3;
1168         }
1169         ;
1170
1171 relative_music:
1172         RELATIVE absolute_pitch Music {
1173                 Music *m = $3;
1174                 Pitch start = *unsmob_pitch ($2);
1175                 $$ = make_music_relative (start, m);
1176                 scm_gc_unprotect_object (m->self_scm ());
1177         }
1178         | RELATIVE Composite_music {
1179                 Music *m = $2;
1180
1181                 Pitch middle_c (0, 0, 0);
1182                 $$ = make_music_relative (middle_c, m);
1183                 scm_gc_unprotect_object (m->self_scm ());
1184         }
1185         ;
1186
1187 new_lyrics:
1188         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1189         /*cont */
1190         Grouped_music_list {
1191         /* Can also use Music at the expensive of two S/Rs similar to
1192            \repeat \alternative */
1193                 THIS->lexer_->pop_state ();
1194 #if 0
1195                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1196                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1197                 $$ = music;
1198 #else
1199                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1200 #endif
1201         }
1202         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1203         Grouped_music_list {
1204                 THIS->lexer_->pop_state ();
1205                 $$ = scm_cons ($4->self_scm (), $1);
1206         }
1207         ;
1208
1209 re_rhythmed_music:
1210         Grouped_music_list new_lyrics {
1211
1212                 /* FIXME: should find out uniqueXXX name from music */
1213                 SCM name = $1->get_property ("context-id");
1214                 //if (name == SCM_EOL)
1215                 if (!ly_c_string_p (name))
1216                         name = scm_makfrom0str ("");
1217
1218                 SCM context = scm_makfrom0str ("Lyrics");
1219                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1220
1221                 SCM lst = SCM_EOL;
1222                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1223                 {
1224                         Music *music = unsmob_music (ly_car (s));
1225                         Music *com = make_lyric_combine_music (name, music);
1226                         Music *csm = context_spec_music (context,
1227                                 get_next_unique_context (), com, SCM_EOL);
1228                         lst = scm_cons (csm->self_scm (), lst);
1229                 }
1230                 /* FIXME: only first lyric music is accepted,
1231                           the rest is junked */
1232                 all->set_property ("elements", scm_cons ($1->self_scm (),
1233                         lst));
1234                 $$ = all;
1235                 scm_gc_unprotect_object ($1->self_scm ());
1236         }
1237         | LYRICSTO string Music {
1238                 Music *music = $3;
1239                 SCM name = $2;
1240                 $$ = make_lyric_combine_music (name, music);
1241                 scm_gc_unprotect_object (music->self_scm ());
1242         }
1243         ;
1244
1245 context_change:
1246         CHANGE STRING '=' STRING  {
1247                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1248                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1249                 t-> set_property ("change-to-id", $4);
1250
1251                 $$ = t;
1252                 $$->set_spot (THIS->here_input ());
1253         }
1254         ;
1255
1256 property_operation:
1257         STRING '=' scalar {
1258                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1259                         scm_string_to_symbol ($1), $3);
1260         }
1261         | UNSET simple_string {
1262                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1263                         scm_string_to_symbol ($2));
1264         }
1265         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1266                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1267                         scm_string_to_symbol ($2), $3, $5);
1268         }
1269         | REVERT simple_string embedded_scm {
1270                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1271                         scm_string_to_symbol ($2), $3);
1272         }
1273         ;
1274
1275 context_def_mod:
1276         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1277         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1278         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1279
1280         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1281         | DENIES { $$ = ly_symbol2scm ("denies"); }
1282
1283         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1284         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1285         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1286         | NAME { $$ = ly_symbol2scm ("context-name"); }
1287         ;
1288
1289 context_mod:
1290         property_operation { $$ = $1; }
1291         | context_def_mod STRING {
1292                 $$ = scm_list_2 ($1, $2);
1293         }
1294         ;
1295
1296 context_prop_spec:
1297         simple_string {
1298                 if (!is_regular_identifier ($1))
1299                 {
1300                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1301                 }
1302
1303                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1304                         scm_string_to_symbol ($1));
1305         }
1306         | simple_string '.' simple_string {
1307                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1308                         scm_string_to_symbol ($3));
1309         }
1310         ;
1311
1312 music_property_def:
1313         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1314                 $$ = property_op_to_music (scm_list_4 (
1315                         ly_symbol2scm ("poppush"),
1316                         ly_cadr ($2),
1317                         $3, $5));
1318                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1319         }
1320         | REVERT context_prop_spec embedded_scm {
1321                 $$ = property_op_to_music (scm_list_3 (
1322                         ly_symbol2scm ("pop"),
1323                         ly_cadr ($2),
1324                         $3));
1325
1326                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1327         }
1328         | SET context_prop_spec '=' scalar {
1329                 $$ = property_op_to_music (scm_list_3 (
1330                         ly_symbol2scm ("assign"),
1331                         ly_cadr ($2),
1332                         $4));
1333                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1334         }
1335         | UNSET context_prop_spec {
1336                 $$ = property_op_to_music (scm_list_2 (
1337                         ly_symbol2scm ("unset"),
1338                         ly_cadr ($2)));
1339                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1340         }
1341         | ONCE music_property_def {
1342                 SCM e = $2->get_property ("element");
1343                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1344                 $$ = $2;
1345
1346         }
1347         ;
1348
1349
1350 string:
1351         STRING {
1352                 $$ = $1;
1353         }
1354         | STRING_IDENTIFIER {
1355                 $$ = $1;
1356         }
1357         | string '+' string {
1358                 $$ = scm_string_append (scm_list_2 ($1, $3));
1359         }
1360         ;
1361
1362 simple_string: STRING {
1363         }
1364         | LYRICS_STRING {
1365         }
1366         ;
1367
1368 scalar: string {
1369         }
1370         | LYRICS_STRING {
1371         }
1372         | bare_int {
1373                 $$ = scm_int2num ($1);
1374         }
1375         | embedded_scm {
1376         }
1377         | full_markup {
1378         }
1379         | DIGIT {
1380                 $$ = scm_int2num ($1);
1381         }
1382         ;
1383
1384 /*
1385 FIXME: remove or fix this comment.  What is `This'?
1386
1387 This is a trick:
1388
1389 Adding pre_events to the simple_element
1390 makes the choice between
1391
1392   string:  STRING
1393
1394 and
1395
1396   simple_element: STRING
1397
1398 a single shift/reduction conflict.
1399
1400 nevertheless, this is not very clean, and we should find a different
1401 solution.
1402
1403 */
1404 pre_events: {
1405                 THIS->push_spot ();
1406         }
1407         ;
1408
1409 event_chord:
1410         pre_events simple_element post_events   {
1411                 SCM elts = $2-> get_property ("elements");
1412
1413                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1414
1415                 $2->set_property ("elements", elts);
1416                 $$ = $2;
1417         }
1418         | command_element
1419         | note_chord_element
1420         ;
1421
1422
1423 note_chord_element:
1424         chord_body optional_notemode_duration post_events
1425         {
1426                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1427                 SCM es = $1->get_property ("elements");
1428                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1429
1430                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1431                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1432                 es = ly_append2 (es, postevs);
1433
1434                 $1-> set_property ("elements", es);
1435                 $$ = $1;
1436         }
1437         ;
1438
1439 chord_open: '<'
1440         ;
1441
1442 chord_close: '>'
1443         ;
1444
1445 simul_open: DOUBLE_ANGLE_OPEN
1446         ;
1447
1448 simul_close: DOUBLE_ANGLE_CLOSE
1449         ;
1450
1451 chord_body:
1452         chord_open chord_body_elements chord_close
1453         {
1454                 $$ = MY_MAKE_MUSIC ("EventChord");
1455                 $$->set_property ("elements",
1456                         scm_reverse_x ($2, SCM_EOL));
1457         }
1458         ;
1459
1460 chord_body_elements:
1461         /* empty */             { $$ = SCM_EOL; }
1462         | chord_body_elements chord_body_element {
1463                 $$ = scm_cons ($2->self_scm (), $1);
1464                 scm_gc_unprotect_object ($2->self_scm ());
1465         }
1466         ;
1467
1468 chord_body_element:
1469         pitch exclamations questions post_events
1470         {
1471                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1472                 n->set_property ("pitch", $1);
1473                 if ($3 % 2)
1474                         n->set_property ("cautionary", SCM_BOOL_T);
1475                 if ($2 % 2 || $3 % 2)
1476                         n->set_property ("force-accidental", SCM_BOOL_T);
1477
1478                 if (ly_c_pair_p ($4)) {
1479                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1480                         n->set_property ("articulations", arts);
1481                 }
1482                 $$ = n;
1483         }
1484         | DRUM_PITCH post_events {
1485                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1486                 n->set_property ("duration", $2);
1487                 n->set_property ("drum-type", $1);
1488                 n->set_spot (THIS->here_input ());
1489
1490                 if (ly_c_pair_p ($2)) {
1491                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1492                         n->set_property ("articulations", arts);
1493                 }
1494                 $$ = n;
1495         }
1496         ;
1497
1498 add_quote:
1499         ADDQUOTE string Music {
1500                 SCM adder = ly_scheme_function ("add-quotable");
1501
1502                 scm_call_2 (adder, $2, $3->self_scm ());
1503                 scm_gc_unprotect_object ($3->self_scm ());
1504         }
1505         ;
1506
1507 command_element:
1508         command_req {
1509                 $$ = MY_MAKE_MUSIC ("EventChord");
1510                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1511                 scm_gc_unprotect_object ($1->self_scm ());
1512
1513                 $$-> set_spot (THIS->here_input ());
1514                 $1-> set_spot (THIS->here_input ());
1515         }
1516         | SKIP duration_length {
1517                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1518                 skip->set_property ("duration", $2);
1519
1520                 $$ = skip;
1521         }
1522         | QUOTE STRING duration_length {
1523                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1524                 SCM evs = SCM_EOL;
1525                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1526                 {
1527                         SCM key = $2; // use symbol?
1528                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1529                 }
1530                 Music *quote = 0;
1531                 if (ly_c_vector_p (evs))
1532                 {
1533                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1534                         quote->set_property ("duration", $3);
1535                         quote->set_property ("quoted-events", evs);
1536                 } else {
1537                         THIS->here_input ().warning (_f ("Can\'t find music"));
1538                         quote = MY_MAKE_MUSIC ("Event");
1539                 }
1540                 quote->set_spot (THIS->here_input ());
1541                 $$ = quote;
1542         }
1543         | OCTAVE { THIS->push_spot (); }
1544           pitch {
1545                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1546                 $$ = m;
1547                 $$->set_spot (THIS->pop_spot ());
1548                 $$->set_property ("pitch", $3);
1549         }
1550         | E_LEFTSQUARE {
1551                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1552                 m->set_property ("span-direction", scm_int2num (START));
1553                 m->set_spot (THIS->here_input ());
1554
1555                 $$ = MY_MAKE_MUSIC ("EventChord");
1556                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1557                 scm_gc_unprotect_object (m->self_scm ());
1558                 $$->set_spot (THIS->here_input ());
1559         }
1560         | E_RIGHTSQUARE {
1561                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1562                 m->set_property ("span-direction", scm_int2num (STOP));
1563                 m->set_spot (THIS->here_input ());
1564
1565                 $$ = MY_MAKE_MUSIC ("EventChord");
1566                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1567                 $$->set_spot (THIS->here_input ());
1568                 scm_gc_unprotect_object (m->self_scm ());
1569         }
1570         | E_BACKSLASH {
1571                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1572                 $$->set_spot (THIS->here_input ());
1573         }
1574         | '|'      {
1575                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1576
1577                 if (Music * m = unsmob_music (pipe))
1578                         $$ = m->clone ();
1579                 else
1580                         $$ = MY_MAKE_MUSIC ("BarCheck");
1581
1582                 $$->set_spot (THIS->here_input ());
1583         }
1584         | TRANSPOSITION pitch {
1585                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1586                                         $2);
1587                 $$->set_spot (THIS-> here_input ());
1588                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1589                         $$, SCM_EOL);
1590         }
1591         | BAR STRING                    {
1592                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1593
1594                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1595                                         t, SCM_EOL);
1596                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1597                 $$->set_spot (THIS->here_input ());
1598                 t->set_spot (THIS->here_input ());
1599         }
1600         | PARTIAL duration_length       {
1601                 Moment m = - unsmob_duration ($2)->get_length ();
1602                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1603                 p->set_spot (THIS->here_input ());
1604                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1605                                         p, SCM_EOL);
1606                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1607                                         p, SCM_EOL);
1608                 $$ = p;
1609         }
1610         | CLEF STRING  {
1611                 SCM proc = ly_scheme_function ("make-clef-set");
1612
1613                 SCM result = scm_call_1 (proc, $2);
1614                 scm_gc_protect_object (result);
1615                 $$ = unsmob_music (result);
1616         }
1617         | TIME_T fraction  {
1618                 SCM proc= ly_scheme_function ("make-time-signature-set");
1619
1620                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1621                 scm_gc_protect_object (result);
1622                 $$ = unsmob_music (result);
1623         }
1624         | MARK scalar {
1625                 SCM proc = ly_scheme_function ("make-mark-set");
1626
1627                 SCM result = scm_call_1 (proc, $2);
1628                 scm_gc_protect_object (result);
1629                 $$ = unsmob_music (result);
1630         }
1631         ;
1632
1633 command_req:
1634         E_TILDE {
1635                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1636         }
1637         | MARK DEFAULT  {
1638                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1639                 $$ = m;
1640         }
1641         | tempo_event {
1642                 $$ = $1;
1643         }
1644         | KEY DEFAULT {
1645                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1646                 $$ = key;
1647         }
1648         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1649
1650                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1651                 if (scm_ilength ($3) > 0)
1652                 {
1653                         key->set_property ("pitch-alist", $3);
1654                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1655                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1656                 } else {
1657                         THIS->parser_error (_ ("Second argument must be pitch list."));
1658                 }
1659
1660                 $$ = key;
1661         }
1662         ;
1663
1664 post_events:
1665         /* empty */ {
1666                 $$ = SCM_EOL;
1667         }
1668         | post_events post_event {
1669                 $2->set_spot (THIS->here_input ());
1670                 $$ = scm_cons ($2->self_scm (), $$);
1671                 scm_gc_unprotect_object ($2->self_scm ());
1672         }
1673         | post_events tagged_post_event {
1674                 $2 -> set_spot (THIS->here_input ());
1675                 $$ = scm_cons ($2->self_scm (), $$);
1676                 scm_gc_unprotect_object ($2->self_scm ());
1677         }
1678         ;
1679
1680
1681 tagged_post_event:
1682         '-' TAG embedded_scm post_event {
1683                 tag_music ($4, $3, THIS->here_input ());
1684                 $$ = $4;
1685         }
1686         ;
1687
1688 post_event:
1689         direction_less_event {
1690                 $$ = $1;
1691         }
1692         | HYPHEN {
1693                 if (!THIS->lexer_->is_lyric_state ())
1694                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1695                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1696         }
1697         | EXTENDER {
1698                 if (!THIS->lexer_->is_lyric_state ())
1699                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1700                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1701         }
1702         | script_dir direction_reqd_event {
1703                 if ($1)
1704                         $2->set_property ("direction", scm_int2num ($1));
1705                 $$ = $2;
1706         }
1707         | script_dir direction_less_event {
1708                 if ($1)
1709                         $2->set_property ("direction", scm_int2num ($1));
1710                 $$ = $2;
1711         }
1712         | string_number_event
1713         ;
1714
1715 string_number_event:
1716         E_UNSIGNED {
1717                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1718                 s->set_property ("string-number", scm_int2num ($1));
1719                 s->set_spot (THIS->here_input ());
1720                 $$ = s;
1721         }
1722         ;
1723
1724
1725 direction_less_event:
1726         '['  {
1727
1728
1729 /*
1730
1731 TODO: should take all these defs out of the parser, adn make use
1732 configurable, i.e.
1733
1734
1735 (set-articulation '~ "trill")
1736
1737 */
1738                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1739                 m->set_spot (THIS->here_input ());
1740                 m->set_property ("span-direction", scm_int2num (START));
1741                 $$ = m;
1742         }
1743         | ']'  {
1744                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1745                 m->set_spot (THIS->here_input ());
1746                 m->set_property ("span-direction", scm_int2num (STOP));
1747                 $$ = m;
1748         }
1749         | '~' {
1750                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1751                 m->set_spot (THIS->here_input ());
1752                 $$ = m;
1753         }
1754         | close_event {
1755                 $$ = $1;
1756                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1757                         scm_int2num (START));
1758         }
1759         | open_event {
1760                 $$ = $1;
1761                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1762                         scm_int2num (STOP));
1763         }
1764         | EVENT_IDENTIFIER      {
1765                 $$ = unsmob_music ($1);
1766         }
1767         | tremolo_type  {
1768                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1769                a->set_spot (THIS->here_input ());
1770                a->set_property ("tremolo-type", scm_int2num ($1));
1771                $$ = a;
1772         }
1773         ;
1774
1775 direction_reqd_event:
1776         gen_text_def {
1777                 $$ = $1;
1778         }
1779         | script_abbreviation {
1780                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1781                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1782                 if (ly_c_string_p (s))
1783                         a->set_property ("articulation-type", s);
1784                 else THIS->parser_error (_ ("Expecting string as script definition"));
1785                 $$ = a;
1786         }
1787         ;
1788
1789 octave_check:
1790         /**/ { $$ = SCM_EOL; }
1791         | '='  { $$ = scm_int2num (0); }
1792         | '=' sub_quotes { $$ = scm_int2num ($2); }
1793         | '=' sup_quotes { $$ = scm_int2num ($2); }
1794         ;
1795
1796 sup_quotes:
1797         '\'' {
1798                 $$ = 1;
1799         }
1800         | sup_quotes '\'' {
1801                 $$ ++;
1802         }
1803         ;
1804
1805 sub_quotes:
1806         ',' {
1807                 $$ = 1;
1808         }
1809         | sub_quotes ',' {
1810                 $$++;
1811         }
1812         ;
1813
1814 steno_pitch:
1815         NOTENAME_PITCH  {
1816                 $$ = $1;
1817         }
1818         | NOTENAME_PITCH sup_quotes     {
1819                 Pitch p = *unsmob_pitch ($1);
1820                 p = p.transposed (Pitch ($2,0,0));
1821                 $$ = p.smobbed_copy ();
1822         }
1823         | NOTENAME_PITCH sub_quotes      {
1824                 Pitch p =* unsmob_pitch ($1);
1825                 p = p.transposed (Pitch (-$2,0,0));
1826                 $$ = p.smobbed_copy ();
1827         }
1828         ;
1829
1830 /*
1831 ugh. duplication
1832 */
1833
1834 steno_tonic_pitch:
1835         TONICNAME_PITCH {
1836                 $$ = $1;
1837         }
1838         | TONICNAME_PITCH sup_quotes    {
1839                 Pitch p = *unsmob_pitch ($1);
1840                 p = p.transposed (Pitch ($2,0,0));
1841                 $$ = p.smobbed_copy ();
1842         }
1843         | TONICNAME_PITCH sub_quotes     {
1844                 Pitch p =* unsmob_pitch ($1);
1845
1846                 p = p.transposed (Pitch (-$2,0,0));
1847                 $$ = p.smobbed_copy ();
1848         }
1849         ;
1850
1851 pitch:
1852         steno_pitch {
1853                 $$ = $1;
1854         }
1855         ;
1856
1857 pitch_also_in_chords:
1858         pitch
1859         | steno_tonic_pitch
1860         ;
1861
1862 close_event:
1863         '('     {
1864                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1865                 $$ = s;
1866                 s->set_spot (THIS->here_input ());
1867         }
1868         | E_OPEN        {
1869                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1870                 $$ = s;
1871                 s->set_spot (THIS->here_input ());
1872         }
1873         | E_SMALLER {
1874                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1875                 $$ = s;
1876                 s->set_spot (THIS->here_input ());
1877         }
1878         | E_BIGGER {
1879                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1880                 $$ = s;
1881                 s->set_spot (THIS->here_input ());
1882         }
1883         ;
1884
1885
1886 open_event:
1887         E_EXCLAMATION   {
1888                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1889                 s->set_spot (THIS->here_input ());
1890
1891                 $$ = s;
1892         }
1893         | ')'   {
1894                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1895                 $$ = s;
1896                 s->set_spot (THIS->here_input ());
1897
1898         }
1899         | E_CLOSE       {
1900                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1901                 $$ = s;
1902                 s->set_property ("span-type",
1903                         scm_makfrom0str ("phrasing-slur"));
1904                 s->set_spot (THIS->here_input ());
1905         }
1906         ;
1907
1908 gen_text_def:
1909         full_markup {
1910                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1911                 t->set_property ("text", $1);
1912                 t->set_spot (THIS->here_input ());
1913                 $$ = t;
1914         }
1915         | string {
1916                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1917                 t->set_property ("text",
1918                         make_simple_markup (THIS->lexer_->encoding (), $1));
1919                 t->set_spot (THIS->here_input ());
1920                 $$ = t;
1921
1922         }
1923         | DIGIT {
1924                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1925                 t->set_property ("digit", scm_int2num ($1));
1926                 t->set_spot (THIS->here_input ());
1927                 $$ = t;
1928         }
1929         ;
1930
1931 script_abbreviation:
1932         '^'             {
1933                 $$ = scm_makfrom0str ("Hat");
1934         }
1935         | '+'           {
1936                 $$ = scm_makfrom0str ("Plus");
1937         }
1938         | '-'           {
1939                 $$ = scm_makfrom0str ("Dash");
1940         }
1941         | '|'           {
1942                 $$ = scm_makfrom0str ("Bar");
1943         }
1944         | '>'           {
1945                 $$ = scm_makfrom0str ("Larger");
1946         }
1947         | '.'           {
1948                 $$ = scm_makfrom0str ("Dot");
1949         }
1950         | '_' {
1951                 $$ = scm_makfrom0str ("Underscore");
1952         }
1953         ;
1954
1955 script_dir:
1956         '_'     { $$ = DOWN; }
1957         | '^'   { $$ = UP; }
1958         | '-'   { $$ = CENTER; }
1959         ;
1960
1961
1962 absolute_pitch:
1963         steno_pitch     {
1964                 $$ = $1;
1965         }
1966         ;
1967
1968 duration_length:
1969         multiplied_duration {
1970                 $$ = $1;
1971         }
1972         ;
1973
1974 optional_notemode_duration:
1975         {
1976                 Duration dd = THIS->default_duration_;
1977                 $$ = dd.smobbed_copy ();
1978
1979                 THIS->beam_check ($$);
1980         }
1981         | multiplied_duration   {
1982                 $$ = $1;
1983                 THIS->default_duration_ = *unsmob_duration ($$);
1984
1985                 THIS->beam_check ($$);
1986         }
1987         ;
1988
1989 steno_duration:
1990         bare_unsigned dots              {
1991                 int len = 0;
1992                 if (!is_duration ($1))
1993                         THIS->parser_error (_f ("not a duration: %d", $1));
1994                 else
1995                         len = intlog2 ($1);
1996
1997                 $$ = Duration (len, $2).smobbed_copy ();
1998         }
1999         | DURATION_IDENTIFIER dots      {
2000                 Duration *d = unsmob_duration ($1);
2001                 Duration k (d->duration_log (), d->dot_count () + $2);
2002                 *d = k;
2003                 $$ = $1;
2004         }
2005         ;
2006
2007 multiplied_duration:
2008         steno_duration {
2009                 $$ = $1;
2010         }
2011         | multiplied_duration '*' bare_unsigned {
2012                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2013         }
2014         | multiplied_duration '*' FRACTION {
2015                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2016
2017                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2018         }
2019         ;
2020
2021 fraction:
2022         FRACTION { $$ = $1; }
2023         | UNSIGNED '/' UNSIGNED {
2024                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2025         }
2026         ;
2027
2028 dots:
2029         /* empty */     {
2030                 $$ = 0;
2031         }
2032         | dots '.' {
2033                 $$ ++;
2034         }
2035         ;
2036
2037 tremolo_type:
2038         ':'     {
2039                 $$ = 0;
2040         }
2041         | ':' bare_unsigned {
2042                 if (!is_duration ($2))
2043                         THIS->parser_error (_f ("not a duration: %d", $2));
2044                 $$ = $2;
2045         }
2046         ;
2047
2048 bass_number:
2049         DIGIT   {
2050                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2051                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2052                                 $$);
2053         }
2054         | UNSIGNED {
2055                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2056                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2057                                 $$);
2058         }
2059         | STRING { $$ = $1; }
2060         ;
2061
2062 bass_mod:
2063         '-'     { $$ = -2; }
2064         | '+'   { $$ = 2; }
2065         | '!'   { $$ = 0; }
2066         ;
2067
2068 bass_figure:
2069         FIGURE_SPACE {
2070                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2071                 $$ = bfr->self_scm ();
2072                 scm_gc_unprotect_object ($$);
2073         }
2074         | bass_number  {
2075                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2076                 $$ = bfr->self_scm ();
2077
2078                 bfr->set_property ("figure", $1);
2079
2080                 scm_gc_unprotect_object ($$);
2081         }
2082         | bass_figure bass_mod {
2083                 Music *m = unsmob_music ($1);
2084                 if ($2) {
2085                         SCM salter = m->get_property ("alteration");
2086                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2087                         m->set_property ("alteration",
2088                                 scm_int2num (alter + $2));
2089                 } else {
2090                         m->set_property ("alteration", scm_int2num (0));
2091                 }
2092         }
2093         ;
2094
2095 br_bass_figure:
2096         '[' bass_figure {
2097                 $$ = $2;
2098                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2099         }
2100         | bass_figure   {
2101                 $$ = $1;
2102         }
2103         | br_bass_figure ']' {
2104                 $$ = $1;
2105                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2106         }
2107         ;
2108
2109 figure_list:
2110         /**/            {
2111                 $$ = SCM_EOL;
2112         }
2113         | figure_list br_bass_figure {
2114                 $$ = scm_cons ($2, $1);
2115         }
2116         ;
2117
2118 figure_spec:
2119         FIGURE_OPEN figure_list FIGURE_CLOSE {
2120                 Music *m = MY_MAKE_MUSIC ("EventChord");
2121                 $2 = scm_reverse_x ($2, SCM_EOL);
2122                 m->set_property ("elements", $2);
2123                 $$ = m->self_scm ();
2124         }
2125         ;
2126
2127
2128 optional_rest:
2129         /**/   { $$ = 0; }
2130         | REST { $$ = 1; }
2131         ;
2132
2133 simple_element:
2134         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2135
2136                 Input i = THIS->pop_spot ();
2137                 if (!THIS->lexer_->is_note_state ())
2138                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2139
2140                 Music *n = 0;
2141                 if ($6)
2142                         n = MY_MAKE_MUSIC ("RestEvent");
2143                 else
2144                         n = MY_MAKE_MUSIC ("NoteEvent");
2145
2146                 n->set_property ("pitch", $1);
2147                 n->set_property ("duration", $5);
2148
2149                 if (ly_c_number_p ($4))
2150                 {
2151                         int q = ly_scm2int ($4);
2152                         n->set_property ("absolute-octave", scm_int2num (q-1));
2153                 }
2154
2155                 if ($3 % 2)
2156                         n->set_property ("cautionary", SCM_BOOL_T);
2157                 if ($2 % 2 || $3 % 2)
2158                         n->set_property ("force-accidental", SCM_BOOL_T);
2159
2160                 Music *v = MY_MAKE_MUSIC ("EventChord");
2161                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2162                 scm_gc_unprotect_object (n->self_scm ());
2163
2164                 v->set_spot (i);
2165                 n->set_spot (i);
2166                 $$ = v;
2167         }
2168         | DRUM_PITCH optional_notemode_duration {
2169                 Input i = THIS->pop_spot ();
2170
2171                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2172                 n->set_property ("duration", $2);
2173                 n->set_property ("drum-type", $1);
2174
2175                 Music *v = MY_MAKE_MUSIC ("EventChord");
2176                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2177                 scm_gc_unprotect_object (n->self_scm ());
2178                 v->set_spot (i);
2179                 n->set_spot (i);
2180                 $$ = v;
2181
2182         }
2183         | figure_spec optional_notemode_duration {
2184                 Music *m = unsmob_music ($1);
2185                 Input i = THIS->pop_spot ();
2186                 m->set_spot (i);
2187                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2188                 {
2189                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2190                 }
2191                 $$ = m;
2192         }
2193         | RESTNAME optional_notemode_duration           {
2194
2195                 Input i = THIS->pop_spot ();
2196                 Music *ev = 0;
2197                 if (ly_scm2string ($1) == "s") {
2198                         /* Space */
2199                         ev = MY_MAKE_MUSIC ("SkipEvent");
2200                   }
2201                 else {
2202                         ev = MY_MAKE_MUSIC ("RestEvent");
2203
2204                     }
2205                 ev->set_property ("duration", $2);
2206                 ev->set_spot (i);
2207                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2208                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2209                 velt->set_spot (i);
2210
2211                 scm_gc_unprotect_object (ev->self_scm ());
2212
2213                 $$ = velt;
2214         }
2215         | MULTI_MEASURE_REST optional_notemode_duration         {
2216                 THIS->pop_spot ();
2217
2218                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2219                 SCM mus = scm_call_2 (proc, $2,
2220                         make_input (THIS->here_input ()));
2221                 scm_gc_protect_object (mus);
2222                 $$ = unsmob_music (mus);
2223         }
2224
2225         | lyric_element optional_notemode_duration      {
2226                 Input i = THIS->pop_spot ();
2227                 if (!THIS->lexer_->is_lyric_state ())
2228                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2229
2230                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2231                 lreq->set_property ("text", $1);
2232                 lreq->set_property ("duration",$2);
2233                 lreq->set_spot (i);
2234                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2235                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2236
2237                 $$= velt;
2238         }
2239         | new_chord {
2240                 THIS->pop_spot ();
2241
2242                 if (!THIS->lexer_->is_chord_state ())
2243                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2244                 $$ = unsmob_music ($1);
2245         }
2246         ;
2247
2248 lyric_element:
2249         /* FIXME: lyric flavoured markup would be better */
2250         full_markup {
2251         }
2252         | LYRICS_STRING {
2253         }
2254         ;
2255
2256 new_chord:
2257         steno_tonic_pitch optional_notemode_duration   {
2258                 $$ = make_chord ($1, $2, SCM_EOL);
2259         }
2260         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2261                 SCM its = scm_reverse_x ($4, SCM_EOL);
2262                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2263         }
2264         ;
2265
2266 chord_items:
2267         /**/ {
2268                 $$ = SCM_EOL;
2269         }
2270         | chord_items chord_item {
2271                 $$ = scm_cons ($2, $$);
2272         }
2273         ;
2274
2275 chord_separator:
2276         CHORD_COLON {
2277                 $$ = ly_symbol2scm ("chord-colon");
2278         }
2279         | CHORD_CARET {
2280                 $$ = ly_symbol2scm ("chord-caret");
2281         }
2282         | CHORD_SLASH steno_tonic_pitch {
2283                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2284         }
2285         | CHORD_BASS steno_tonic_pitch {
2286                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2287         }
2288         ;
2289
2290 chord_item:
2291         chord_separator {
2292                 $$ = $1;
2293         }
2294         | step_numbers {
2295                 $$ = scm_reverse_x ($1, SCM_EOL);
2296         }
2297         | CHORD_MODIFIER  {
2298                 $$ = $1;
2299         }
2300         ;
2301
2302 step_numbers:
2303         step_number { $$ = scm_cons ($1, SCM_EOL); }
2304         | step_numbers '.' step_number {
2305                 $$ = scm_cons ($3, $$);
2306         }
2307         ;
2308
2309 step_number:
2310         bare_unsigned {
2311                 $$ = make_chord_step ($1, 0);
2312         }
2313         | bare_unsigned '+' {
2314                 $$ = make_chord_step ($1, SHARP);
2315         }
2316         | bare_unsigned CHORD_MINUS {
2317                 $$ = make_chord_step ($1, FLAT);
2318         }
2319         ;
2320
2321 /*
2322         UTILITIES
2323
2324 TODO: should deprecate in favor of Scheme?
2325
2326  */
2327 number_expression:
2328         number_expression '+' number_term {
2329                 $$ = scm_sum ($1, $3);
2330         }
2331         | number_expression '-' number_term {
2332                 $$ = scm_difference ($1, $3);
2333         }
2334         | number_term
2335         ;
2336
2337 number_term:
2338         number_factor {
2339                 $$ = $1;
2340         }
2341         | number_factor '*' number_factor {
2342                 $$ = scm_product ($1, $3);
2343         }
2344         | number_factor '/' number_factor {
2345                 $$ = scm_divide ($1, $3);
2346         }
2347         ;
2348
2349 number_factor:
2350         '-'  number_factor { /* %prec UNARY_MINUS */
2351                 $$ = scm_difference ($2, SCM_UNDEFINED);
2352         }
2353         | bare_number
2354         ;
2355
2356
2357 bare_number:
2358         UNSIGNED        {
2359                 $$ = scm_int2num ($1);
2360         }
2361         | REAL          {
2362                 $$ = $1;
2363         }
2364         | NUMBER_IDENTIFIER             {
2365                 $$ = $1;
2366         }
2367         | REAL NUMBER_IDENTIFIER        {
2368                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2369         }
2370         | UNSIGNED NUMBER_IDENTIFIER    {
2371                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2372         }
2373         ;
2374
2375
2376 bare_unsigned:
2377         UNSIGNED {
2378                         $$ = $1;
2379         }
2380         | DIGIT {
2381                 $$ = $1;
2382         }
2383         ;
2384
2385 bare_int:
2386         bare_number {
2387                 if (scm_integer_p ($1) == SCM_BOOL_T)
2388                 {
2389                         int k = ly_scm2int ($1);
2390                         $$ = k;
2391                 } else
2392                 {
2393                         THIS->parser_error (_ ("need integer number arg"));
2394                         $$ = 0;
2395                 }
2396         }
2397         | '-' bare_int {
2398                 $$ = -$2;
2399         }
2400         ;
2401
2402 exclamations:
2403                 { $$ = 0; }
2404         | exclamations '!'      { $$ ++; }
2405         ;
2406
2407 questions:
2408                 { $$ = 0; }
2409         | questions '?' { $$ ++; }
2410         ;
2411
2412
2413
2414 full_markup:
2415         MARKUP_IDENTIFIER {
2416                 $$ = $1;
2417         }
2418         | MARKUP
2419                 { THIS->lexer_->push_markup_state (); }
2420         markup
2421                 { $$ = $3;
2422                   THIS->lexer_->pop_state ();
2423                 }
2424         ;
2425
2426
2427 /*
2428 This should be done more dynamically if possible.
2429 */
2430 markup:
2431         STRING {
2432                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2433         }
2434         | MARKUP_HEAD_EMPTY {
2435                 $$ = scm_list_1 ($1);
2436         }
2437         | MARKUP_HEAD_MARKUP0 markup {
2438                 $$ = scm_list_2 ($1, $2);
2439         }
2440         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2441                 $$ = scm_list_3 ($1, $2, $3);
2442         }
2443         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2444                 $$ = scm_list_3 ($1, $2, $3);
2445         }
2446         | markup_line {
2447                 $$ = $1;
2448         }
2449         | MARKUP_HEAD_LIST0 markup_list {
2450                 $$ = scm_list_2 ($1,$2);
2451         }
2452         | MARKUP_HEAD_SCM0 embedded_scm {
2453                 $$ = scm_list_2 ($1, $2);
2454         }
2455         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2456                 $$ = scm_list_4 ($1, $2, $3, $4);
2457         }
2458         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2459                 $$ = scm_list_4 ($1, $2, $3, $4);
2460         }
2461         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2462                 $$ = scm_list_3 ($1, $2, $3);
2463         }
2464         | MARKUP_IDENTIFIER {
2465                 $$ = $1;
2466         }
2467         | STRING_IDENTIFIER {
2468                 $$ = $1;
2469         }
2470         | SCORE {
2471                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2472                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2473         } '{' score_body '}' {
2474                 Score * sc = $4;
2475                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2476                 scm_gc_unprotect_object (sc->self_scm ());
2477                 THIS->lexer_->pop_state ();
2478         }
2479         ;
2480
2481 markup_list:
2482         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2483         ;
2484
2485 markup_line:
2486         '{' markup_list_body '}' {
2487                 SCM line = ly_scheme_function ("line-markup");
2488
2489                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2490         }
2491         ;
2492
2493 markup_list_body:
2494         /**/ {  $$ = SCM_EOL; }
2495         | markup_list_body markup {
2496                 $$ = scm_cons ($2, $1);
2497         }
2498         ;
2499
2500
2501 %%
2502
2503 void
2504 My_lily_parser::set_yydebug (bool )
2505 {
2506 #if 0
2507         yydebug = 1;
2508 #endif
2509 }
2510
2511 void
2512 My_lily_parser::do_yyparse ()
2513 {
2514         yyparse ((void*)this);
2515 }
2516
2517
2518 /*
2519 Should make this optional?    It will also complain when you do
2520
2521         [s4]
2522
2523 which is entirely legitimate.
2524
2525 Or we can scrap it. Barchecks should detect wrong durations, and
2526 skipTypesetting speeds it up a lot.
2527 */
2528
2529 void
2530 My_lily_parser::beam_check (SCM dur)
2531 {
2532   Duration *d = unsmob_duration (dur);
2533   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2534     {
2535       Music *m = unsmob_music (last_beam_start_);
2536       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2537     }
2538   last_beam_start_ = SCM_EOL;
2539 }
2540
2541
2542
2543
2544 /*
2545
2546 It is a little strange to have this function in this file, but
2547 otherwise, we have to import music classes into the lexer.
2548
2549 */
2550 int
2551 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2552 {
2553         if (ly_c_string_p (sid)) {
2554                 *destination = sid;
2555                 return STRING_IDENTIFIER;
2556         } else if (ly_c_number_p (sid)) {
2557                 *destination = sid;
2558                 return NUMBER_IDENTIFIER;
2559         } else if (unsmob_context_def (sid)) {
2560                 *destination = unsmob_context_def (sid)->clone_scm ();
2561                 return CONTEXT_DEF_IDENTIFIER;
2562         } else if (unsmob_score (sid)) {
2563                 Score *score = new Score (*unsmob_score (sid));
2564                 *destination = score->self_scm ();
2565                 return SCORE_IDENTIFIER;
2566         } else if (Music *mus = unsmob_music (sid)) {
2567                 mus = mus->clone ();
2568                 *destination = mus->self_scm ();
2569                 unsmob_music (*destination)->
2570                         set_property ("origin", make_input (last_input_));
2571                 return dynamic_cast<Event*> (mus)
2572                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2573         } else if (unsmob_duration (sid)) {
2574                 *destination = unsmob_duration (sid)->smobbed_copy ();
2575                 return DURATION_IDENTIFIER;
2576         } else if (unsmob_output_def (sid)) {
2577                 Output_def *p = unsmob_output_def (sid);
2578                 p = p->clone ();
2579
2580                 *destination = p->self_scm ();
2581                 return OUTPUT_DEF_IDENTIFIER;
2582         } else if (Text_item::markup_p (sid)) {
2583                 *destination = sid;
2584                 return MARKUP_IDENTIFIER;
2585         }
2586
2587         return -1;
2588 }
2589
2590 Music *
2591 property_op_to_music (SCM op)
2592 {
2593         Music *m = 0;
2594         SCM tag = ly_car (op);
2595         SCM symbol = ly_cadr (op);
2596         SCM args = ly_cddr (op);
2597         SCM grob_val = SCM_UNDEFINED;
2598         SCM grob_sym = SCM_UNDEFINED;
2599         SCM val = SCM_UNDEFINED;
2600
2601         if (tag == ly_symbol2scm ("assign"))
2602                 {
2603                 m = MY_MAKE_MUSIC ("PropertySet");
2604                 val = ly_car (args);
2605                 }
2606         else if (tag == ly_symbol2scm ("unset"))
2607                 m = MY_MAKE_MUSIC ("PropertyUnset");
2608         else if (tag == ly_symbol2scm ("poppush")
2609                  || tag == ly_symbol2scm ("push"))
2610                 {
2611                 m = MY_MAKE_MUSIC ("OverrideProperty");
2612                 grob_sym = ly_car (args);
2613                 grob_val = ly_cadr (args);
2614                 }
2615         else if (tag == ly_symbol2scm ("pop")) {
2616                 m = MY_MAKE_MUSIC ("RevertProperty");
2617                 grob_sym = ly_car (args);
2618                 }
2619
2620         m->set_property ("symbol", symbol);
2621
2622         if (val != SCM_UNDEFINED)
2623                 m->set_property ("value", val);
2624         if (grob_val != SCM_UNDEFINED)
2625                 m->set_property ("grob-value", grob_val);
2626
2627         if (grob_sym != SCM_UNDEFINED)
2628                 {
2629                 bool itc = internal_type_checking_global_b;
2630                 /* UGH.
2631                 */
2632                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2633                 if (autobeam)
2634                         internal_type_checking_global_b = false;
2635                 m->set_property ("grob-property", grob_sym);
2636                 if (autobeam)
2637                         internal_type_checking_global_b = itc;
2638                 }
2639
2640         if (tag == ly_symbol2scm ("poppush"))
2641                 m->set_property ("pop-first", SCM_BOOL_T);
2642
2643
2644         return m;
2645 }
2646
2647 Music*
2648 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2649 {
2650         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2651
2652         csm->set_property ("element", m->self_scm ());
2653         scm_gc_unprotect_object (m->self_scm ());
2654
2655         csm->set_property ("context-type",
2656                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2657         csm->set_property ("property-operations", ops);
2658
2659         if (ly_c_string_p (id))
2660                 csm->set_property ("context-id", id);
2661         return csm;
2662 }
2663
2664 SCM
2665 get_next_unique_context ()
2666 {
2667         static int new_context_count;
2668         char s[1024];
2669         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2670         return scm_makfrom0str (s);
2671 }
2672