lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLY
 251 %token APPLYCONTEXT
 252 %token APPLYOUTPUT
 253 %token AUTOCHANGE
 254 %token BAR
 255 %token BOOK
 256 %token BREATHE
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONSISTSEND
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 272 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 273 %token GRACE
 274 %token ACCIACCATURA
 275 %token APPOGGIATURA
 276 %token GROBDESCRIPTIONS
 277 %token HEADER
 278 %token HYPHEN
 279 %token INVALID
 280 %token KEY
 281 %token LYRICS
 282 %token LYRICS_STRING
 283 %token MARK
 284 %token MIDI
 285 %token MULTI_MEASURE_REST
 286 %token NAME
 287 %token NEWCONTEXT
 288 %token NOTES
 289 %token OCTAVE
 290 %token ONCE
 291 %token OVERRIDE SET REVERT
 292 %token PAPER
 293 %token PARTCOMBINE
 294 %token PARTIAL
 295 %token QUOTE
 296 %token RELATIVE
 297 %token REMOVE
 298 %token REPEAT
 299 %token REST
 300 %token SCM_T
 301 %token SCORE
 302 %token SEQUENTIAL
 303 %token NEWLYRICS
 304 %token SIMULTANEOUS
 305 %token SKIP
 306 %token SPANREQUEST
 307 %token TAG
 308 %token TEMPO
 309 %token TIMES
 310 %token TIME_T
 311 %token TRANSPOSE
 312 %token TRANSPOSITION
 313 %token TYPE
 314 %token UNSET
 315 %token WITH
 316
 317 /* escaped */
 318 /* FIXME: this sucks.  The user will get to see these names:
 319     syntax error, unexpected E_CHAR:
 320                 \
 321                  %%
 322   */
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token <i> E_UNSIGNED
 327 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 328 %token FIGURE_SPACE
 329
 330 %token <i>      DIGIT
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    TONICNAME_PITCH
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DURATION_IDENTIFIER
 335 %token <scm>    FRACTION
 336 %token <id>     IDENTIFIER
 337 %token DRUMS
 338 %token <scm>    DRUM_PITCH
 339 %token <scm>    CHORD_MODIFIER
 340 %token <scm>    SCORE_IDENTIFIER
 341 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 342 %token <scm>    NUMBER_IDENTIFIER
 343 %token <scm>    EVENT_IDENTIFIER
 344 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 345 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 346 %token <scm>    RESTNAME
 347 %token <scm>    STRING
 348 %token <scm>    SCM_T
 349 %token <i>      UNSIGNED
 350 %token <scm>   REAL
 351
 352 %token MARKUP
 353 %token <scm> MARKUP_HEAD_MARKUP0
 354 %token <scm> MARKUP_HEAD_EMPTY
 355 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0
 357 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1
 359 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 360 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 361
 362 %token <scm> MUSIC_FUNCTION_SCM
 363 %token <scm> MUSIC_FUNCTION_MUSIC
 364 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 365 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 368
 369 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 370 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 371
 372 %type <book>    book_block book_body
 373 %type <i>       exclamations questions dots optional_rest
 374 %type <i>       bass_mod
 375 %type <scm>     grace_head
 376 %type <scm>     oct_check
 377 %type <scm>     context_mod_list
 378 %type <scm>     lyric_element
 379 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 380 %type <scm>     new_lyrics
 381 %type <outputdef> output_def
 382 %type <scm>     lilypond_header lilypond_header_body
 383 %type <music>   open_event close_event
 384 %type <i>       sub_quotes sup_quotes
 385 %type <music>   toplevel_music
 386 %type <music>   simple_element event_chord command_element
 387 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 388 %type <scm>     Generic_prefix_music_scm
 389 %type <music>   Grouped_music_list
 390 %type <music>   Repeated_music
 391 %type <scm>     Alternative_music
 392 %type <i>       tremolo_type
 393 %type <i>       bare_int  bare_unsigned
 394 %type <i>       script_dir
 395 %type <scm>     identifier_init
 396 %type <scm>     simple_string
 397
 398 %type <music>   note_chord_element chord_body chord_body_element
 399 %type <scm>     chord_body_elements
 400 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 401
 402 %type <scm>     post_events
 403 %type <music>   gen_text_def direction_less_event direction_reqd_event
 404 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 405 %type <scm>     steno_tonic_pitch
 406 %type <scm>     duration_length fraction
 407
 408 %type <scm>     chord_item chord_items chord_separator new_chord
 409 %type <scm>     step_number step_numbers
 410
 411 %type <scm>     embedded_scm scalar
 412 %type <music>   Music Sequential_music Simultaneous_music
 413 %type <music>   relative_music re_rhythmed_music
 414 %type <music>   music_property_def context_change
 415 %type <scm>     context_prop_spec
 416 %type <scm>     Music_list
 417 %type <scm>     property_operation
 418 %type <scm>     context_mod context_def_mod optional_context_mod
 419 %type <outputdef>       music_output_def_body music_output_def_head
 420 %type <music>   post_event tagged_post_event
 421 %type <music>   command_req
 422 %type <music>   string_number_event
 423 %type <scm>     string bare_number number_expression number_term number_factor
 424 %type <score>   score_block score_body
 425
 426 %type <scm>     context_def_spec_block context_def_spec_body
 427 %type <music>   tempo_event
 428 %type <scm>     script_abbreviation
 429
 430
 431
 432 %left '-' '+'
 433
 434 /* We don't assign precedence to / and *, because we might need varied
 435 prec levels in different prods */
 436
 437 %left UNARY_MINUS
 438
 439 %%
 440
 441 lilypond:       /* empty */
 442         | lilypond toplevel_expression {
 443         }
 444         | lilypond assignment {
 445         }
 446         | lilypond error {
 447                 THIS->error_level_ = 1;
 448         }
 449         | lilypond INVALID      {
 450                 THIS->error_level_ = 1;
 451         }
 452         ;
 453
 454 toplevel_expression:
 455         lilypond_header {
 456                 THIS->header_ = $1;
 457         }
 458         | add_quote {
 459
 460         }
 461         | book_block {
 462                 Book *book = $1;
 463                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 464                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 465                 scm_gc_unprotect_object (book->self_scm ());
 466         }
 467         | score_block {
 468                 Score *score = $1;
 469
 470                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 471                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 472                 scm_gc_unprotect_object (score->self_scm ());
 473         }
 474         | toplevel_music {
 475                 Music *music = $1;
 476                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 477                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 478                 scm_gc_unprotect_object (music->self_scm ());
 479         }
 480         | output_def {
 481                 SCM id = SCM_EOL;
 482                 if (dynamic_cast<Paper_def*> ($1))
 483                         id = scm_makfrom0str ("$defaultpaper");
 484                 else if (dynamic_cast<Midi_def*> ($1))
 485                         id = scm_makfrom0str ("$defaultmidi");
 486                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 487                 scm_gc_unprotect_object ($1->self_scm ());
 488         }
 489         ;
 490
 491 toplevel_music:
 492         Composite_music {
 493         }
 494         ;
 495
 496 embedded_scm:
 497         SCM_T
 498         | SCM_IDENTIFIER
 499         ;
 500
 501
 502 lilypond_header_body:
 503         {
 504                 $$ = ly_make_anonymous_module ();
 505                 THIS->lexer_->add_scope ($$);
 506         }
 507         | lilypond_header_body assignment  {
 508
 509         }
 510         ;
 511
 512 lilypond_header:
 513         HEADER '{' lilypond_header_body '}'     {
 514                 $$ = THIS->lexer_->remove_scope ();
 515         }
 516         ;
 517
 518
 519 /*
 520         DECLARATIONS
 521 */
 522 assignment:
 523         STRING {
 524                 THIS->push_spot ();
 525         }
 526         /* cont */ '=' identifier_init  {
 527
 528         /*
 529                 Should find generic way of associating input with objects.
 530         */
 531                 Input ip = THIS->pop_spot ();
 532
 533                 if (! is_regular_identifier ($1))
 534                 {
 535                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 536                 }
 537
 538                 THIS->lexer_->set_identifier ($1, $4);
 539
 540 /*
 541  TODO: devise standard for protection in parser.
 542
 543   The parser stack lives on the C-stack, which means that
 544 all objects can be unprotected as soon as they're here.
 545
 546 */
 547         }
 548         | embedded_scm { }
 549         ;
 550
 551
 552 identifier_init:
 553         score_block {
 554                 $$ = $1->self_scm ();
 555                 scm_gc_unprotect_object ($$);
 556         }
 557         | full_markup {
 558                 $$ = $1;
 559         }
 560         | output_def {
 561                 $$ = $1->self_scm ();
 562                 scm_gc_unprotect_object ($$);
 563         }
 564         | context_def_spec_block {
 565                 $$ = $1;
 566         }
 567         | Music  {
 568                 $$ = $1->self_scm ();
 569                 scm_gc_unprotect_object ($$);
 570         }
 571         | post_event {
 572                 $$ = $1->self_scm ();
 573                 scm_gc_unprotect_object ($$);
 574         }
 575         | number_expression {
 576                 $$ = $1;
 577         }
 578         | string {
 579                 $$ = $1;
 580         }
 581         | embedded_scm  {
 582                 $$ = $1;
 583         }
 584         ;
 585
 586 context_def_spec_block:
 587         CONTEXT '{' context_def_spec_body '}'
 588                 {
 589                 $$ = $3;
 590         }
 591         ;
 592
 593 context_def_spec_body:
 594         /**/ {
 595                 $$ = Context_def::make_scm ();
 596                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 597         }
 598         | CONTEXT_DEF_IDENTIFIER {
 599                 $$ = $1;
 600                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 601         }
 602         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 603                 Context_def*td = unsmob_context_def ($$);
 604
 605                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 606                         SCM tag = ly_caar (p);
 607
 608                         /* TODO: should make new tag "grob-definition" ? */
 609                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 610                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 611                 }
 612         }
 613         | context_def_spec_body context_mod {
 614                 unsmob_context_def ($$)->add_context_mod ($2);
 615         }
 616         ;
 617
 618 book_block:
 619         BOOK {
 620                 THIS->push_spot ();
 621         }
 622         /*cont*/ '{' book_body '}'      {
 623                 THIS->pop_spot ();
 624                 $$ = $4;
 625         }
 626         ;
 627
 628 book_body:
 629         {
 630                 $$ = new Book;
 631                 $$->set_spot (THIS->here_input ());
 632         }
 633         | book_body score_block {
 634                 $$->scores_.push ($2);
 635                 scm_gc_unprotect_object ($2->self_scm ());
 636         }
 637         | book_body error {
 638         }
 639         ;
 640
 641 score_block:
 642         SCORE {
 643                 THIS->push_spot ();
 644         }
 645         /*cont*/ '{' score_body '}'     {
 646                 THIS->pop_spot ();
 647                 $$ = $4;
 648         }
 649         ;
 650
 651 score_body:
 652         Music   {
 653                 $$ = new Score;
 654
 655                 $$->set_spot (THIS->here_input ());
 656                 SCM m = $1->self_scm ();
 657                 scm_gc_unprotect_object (m);
 658
 659                 /*
 660                         guh.
 661                 */
 662                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 663                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 664                         m = scm_call_1 (ly_car (check_funcs), m);
 665                 $$->music_ = m;
 666
 667         }
 668         | SCORE_IDENTIFIER {
 669                 $$ = new Score ( *unsmob_score ($1));
 670                 $$->set_spot (THIS->here_input ());
 671         }
 672         | score_body lilypond_header    {
 673                 $$->header_ = $2;
 674         }
 675         | score_body output_def {
 676                 $$->defs_.push ($2);
 677                 scm_gc_unprotect_object ($2->self_scm ());
 678         }
 679         | score_body error {
 680
 681         }
 682         ;
 683
 684
 685 /*
 686         MIDI
 687 */
 688 output_def:
 689         music_output_def_body '}' {
 690                 $$ = $1;
 691                 THIS->lexer_->remove_scope ();
 692                 THIS->lexer_->pop_state ();
 693         }
 694         ;
 695
 696 music_output_def_head:
 697         MIDI    {
 698                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 699
 700
 701                 Midi_def *p = 0;
 702                 if (id)
 703                         p = dynamic_cast<Midi_def*> (id->clone ());
 704                 else
 705                         p = new Midi_def;
 706
 707                 $$ = p;
 708                 THIS->lexer_->add_scope (p->scope_);
 709         }
 710         | PAPER         {
 711                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 712                   Paper_def *p = 0;
 713                 if (id)
 714                         p = dynamic_cast<Paper_def*> (id->clone ());
 715                 else
 716                         p = new Paper_def;
 717
 718                 THIS->lexer_->add_scope (p->scope_);
 719                 $$ = p;
 720         }
 721         ;
 722
 723
 724 music_output_def_body:
 725         music_output_def_head '{' {
 726                 $$ = $1;
 727                 $$->input_origin_. set_spot (THIS->here_input ());
 728                 THIS->lexer_->push_initial_state ();
 729         }
 730         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 731                 scm_gc_unprotect_object ($1->self_scm ());
 732                 Music_output_def *o = unsmob_music_output_def ($3);
 733                 o->input_origin_.set_spot (THIS->here_input ());
 734                 $$ = o;
 735                 THIS->lexer_->remove_scope ();
 736                 THIS->lexer_->add_scope (o->scope_);
 737                 THIS->lexer_->push_initial_state ();
 738         }
 739         | music_output_def_body assignment  {
 740
 741         }
 742         | music_output_def_body context_def_spec_block  {
 743                 $$->assign_context_def ($2);
 744         }
 745         | music_output_def_body tempo_event  {
 746                 /*
 747                         junk this ? there already is tempo stuff in
 748                         music.
 749                 */
 750                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 751                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 752                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 753                 if (md)
 754                         md->set_tempo (d->get_length (), m);
 755                 scm_gc_unprotect_object ($2->self_scm ());
 756         }
 757         | music_output_def_body error {
 758
 759         }
 760         ;
 761
 762 tempo_event:
 763         TEMPO steno_duration '=' bare_unsigned  {
 764                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 765                 $$->set_property ("tempo-unit", $2);
 766                 $$->set_property ("metronome-count", scm_int2num ( $4));
 767         }
 768         ;
 769
 770 /*
 771 The representation of a  list is the
 772
 773   (LIST . LAST-CONS)
 774
 775  to have  efficient append.
 776 */
 777 Music_list:
 778         /* empty */ {
 779                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 780         }
 781         | Music_list Music {
 782                 SCM s = $$;
 783                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 784                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 785                 if (ly_c_pair_p (ly_cdr (s)))
 786                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 787                 else
 788                         scm_set_car_x (s, c); /* set first cons */
 789                 scm_set_cdr_x (s, c);  /* remember last cell */
 790         }
 791         | Music_list embedded_scm {
 792         }
 793         | Music_list error {
 794         }
 795         ;
 796
 797
 798 Music:
 799         Simple_music
 800         | Composite_music
 801         ;
 802
 803 Alternative_music:
 804         /* empty */ {
 805                 $$ = SCM_EOL;
 806         }
 807         | ALTERNATIVE '{' Music_list '}' {
 808                 $$ = $3;
 809         }
 810         ;
 811
 812
 813 Repeated_music:
 814         REPEAT simple_string bare_unsigned Music Alternative_music
 815         {
 816                 Music *beg = $4;
 817                 int times = $3;
 818                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 819                 if (times < scm_ilength (alts)) {
 820                   unsmob_music (ly_car (alts))
 821                     ->origin ()->warning (
 822                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 823                   alts = ly_truncate_list (times, alts);
 824                 }
 825
 826
 827                 SCM proc = ly_scheme_function ("make-repeated-music");
 828
 829                 SCM mus = scm_call_1 (proc, $2);
 830                 scm_gc_protect_object (mus); // UGH.
 831                 Music *r = unsmob_music (mus);
 832                 if (beg)
 833                         {
 834                         r-> set_property ("element", beg->self_scm ());
 835                         scm_gc_unprotect_object (beg->self_scm ());
 836                         }
 837                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 838
 839                 r-> set_property ("elements",alts);
 840                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 841                         /*
 842                         TODO: move this code to Scheme.
 843                         */
 844
 845                         /*
 846                         we can not get durations and other stuff correct down the line, so we have to
 847                         add to the duration log here.
 848                         */
 849                         SCM func = ly_scheme_function ("shift-duration-log");
 850
 851                         int dots = ($3 % 3) ? 0 : 1;
 852                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 853
 854                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 855
 856                         if (seq) {
 857                                 int list_len = scm_ilength (seq->music_list ());
 858                                 if (list_len != 2)
 859                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 860                                 shift -= 1;
 861                                 r->compress (Moment (Rational (1, list_len)));
 862                                 }
 863                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 864
 865                 }
 866                 r->set_spot (*$4->origin ());
 867
 868                 $$ = r;
 869         }
 870         ;
 871
 872 Sequential_music:
 873         SEQUENTIAL '{' Music_list '}'           {
 874                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 875                 $$->set_property ("elements", ly_car ($3));
 876                 $$->set_spot (THIS->here_input ());
 877         }
 878         | '{' Music_list '}'            {
 879                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 880                 $$->set_property ("elements", ly_car ($2));
 881                 $$->set_spot (THIS->here_input ());
 882         }
 883         ;
 884
 885 Simultaneous_music:
 886         SIMULTANEOUS '{' Music_list '}'{
 887                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 888                 $$->set_property ("elements", ly_car ($3));
 889                 $$->set_spot (THIS->here_input ());
 890
 891         }
 892         | simul_open Music_list simul_close     {
 893                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 894                 $$->set_property ("elements", ly_car ($2));
 895                 $$->set_spot (THIS->here_input ());
 896         }
 897         ;
 898
 899 Simple_music:
 900         event_chord             { $$ = $1; }
 901         | APPLYOUTPUT embedded_scm {
 902                 if (!ly_input_procedure_p ($2))
 903                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 904                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 905                 $$->set_property ("procedure", $2);
 906                 $$->set_spot (THIS->here_input ());
 907         }
 908         | APPLYCONTEXT embedded_scm {
 909                 if (!ly_input_procedure_p ($2))
 910                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 911                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 912                 $$->set_property ("procedure", $2);
 913                 $$->set_spot (THIS->here_input ());
 914         }
 915         | MUSIC_IDENTIFIER {
 916                 $$ = unsmob_music ($1);
 917         }
 918         | music_property_def
 919         | context_change
 920         ;
 921
 922
 923 optional_context_mod:
 924         /**/ { $$ = SCM_EOL; }
 925         | WITH { THIS->lexer_->push_initial_state (); }
 926         '{' context_mod_list '}'
 927         {
 928                 THIS->lexer_->pop_state ();
 929                 $$ = $4;
 930         }
 931         ;
 932
 933 grace_head:
 934         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 935         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 936         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 937         ;
 938
 939 context_mod_list:
 940         /* */  { $$ = SCM_EOL; }
 941         | context_mod_list context_mod  {
 942                  $$ = scm_cons ($2, $1);
 943         }
 944         ;
 945
 946
 947 Composite_music:
 948         Prefix_composite_music { $$ = $1; }
 949         | Grouped_music_list { $$ = $1; }
 950         ;
 951
 952 Grouped_music_list:
 953         Simultaneous_music              { $$ = $1; }
 954         | Sequential_music              { $$ = $1; }
 955         ;
 956
 957 Generic_prefix_music_scm:
 958         MUSIC_FUNCTION_SCM {
 959                 THIS->push_spot ();
 960         } embedded_scm {
 961                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 962         }
 963         | MUSIC_FUNCTION_MUSIC {
 964                 THIS->push_spot ();
 965         } Music {
 966                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 967                 scm_gc_unprotect_object ($3->self_scm ());
 968         }
 969         | MUSIC_FUNCTION_SCM_MUSIC {
 970                 THIS->push_spot ();
 971         }  embedded_scm Music {
 972                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 973                 scm_gc_unprotect_object ($4->self_scm ());
 974         }
 975         | MUSIC_FUNCTION_MUSIC_MUSIC {
 976                 THIS->push_spot ();
 977         }  Music  Music {
 978                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 979                 scm_gc_unprotect_object ($3->self_scm ());
 980                 scm_gc_unprotect_object ($4->self_scm ());
 981         }
 982         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 983                 THIS->push_spot ();
 984         } embedded_scm Music Music {
 985                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
 986                         $3, $4->self_scm (), $5->self_scm ());
 987                 scm_gc_unprotect_object ($5->self_scm ());
 988                 scm_gc_unprotect_object ($4->self_scm ());
 989         }
 990         ;
 991
 992 Generic_prefix_music:
 993         Generic_prefix_music_scm {
 994                 SCM func = ly_car ($1);
 995                 Input *loc = unsmob_input (ly_cadr ($1));
 996                 SCM args = ly_cddr ($1);
 997                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-head-signature"));
 998                 int k = 0;
 999                 bool ok  = true;
1000                 for (SCM s = sig, t = args;
1001                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1002                         s = ly_cdr (s), t = ly_cdr (t)) {
1003                         k++;
1004                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1005                         {
1006                                 loc->error (_f ("Argument %d failed typecheck", k));
1007                                 THIS->error_level_ = 1;
1008                                 ok = false;
1009                         }
1010                 }
1011                 SCM m = SCM_EOL;
1012                 if (ok)
1013                         m = scm_apply_0 (func, ly_cdr  ($1));
1014                 if (unsmob_music (m))
1015                         {
1016                         $$ = unsmob_music (m);
1017                         scm_gc_protect_object (m);
1018                         }
1019                 else
1020                         {
1021                         loc->error (_ ("Music head function should return Music object."));
1022                         $$ = MY_MAKE_MUSIC ("Music");
1023                         }
1024
1025         }
1026         ;
1027
1028
1029 Prefix_composite_music:
1030         Generic_prefix_music {
1031                 $$ = $1;
1032         }
1033         |AUTOCHANGE Music       {
1034                 SCM proc = ly_scheme_function ("make-autochange-music");
1035
1036                 SCM res = scm_call_1 (proc, $2->self_scm ());
1037                 scm_gc_unprotect_object ($2->self_scm ());
1038                 $$ = unsmob_music (res);
1039                 scm_gc_protect_object (res);
1040                 $$->set_spot (THIS->here_input ());
1041         }
1042         | PARTCOMBINE Music Music {
1043                 SCM proc = ly_scheme_function ("make-part-combine-music");
1044
1045                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
1046                         $3->self_scm (), SCM_UNDEFINED));
1047                 scm_gc_unprotect_object ($3->self_scm ());
1048                 scm_gc_unprotect_object ($2->self_scm ());
1049                 $$ = unsmob_music (res);
1050                 scm_gc_protect_object (res);
1051                 $$->set_spot (THIS->here_input ());
1052         }
1053         | grace_head Music {
1054 #if 1
1055         /*
1056                 The other version is for easier debugging  of
1057                 Sequential_music_iterator in combination with grace notes.
1058         */
1059
1060 /*
1061
1062 TODO: should distinguish between both grace types in the
1063 basic music objects too, since the meaning is different.
1064
1065 */
1066
1067                 String start_str = "start" + ly_scm2string ($1) + "Music";
1068                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
1069
1070                 SCM start = THIS->lexer_->lookup_identifier (start_str);
1071                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
1072
1073                 Music *startm = unsmob_music (start);
1074                 Music *stopm = unsmob_music (stop);
1075
1076                 SCM ms = SCM_EOL;
1077                 if (stopm) {
1078                         stopm = stopm->clone ();
1079                         ms = scm_cons (stopm->self_scm (), ms);
1080                         scm_gc_unprotect_object (stopm->self_scm ());
1081                 }
1082                 ms = scm_cons ($2->self_scm (), ms);
1083                 scm_gc_unprotect_object ($2->self_scm ());
1084                 if (startm) {
1085                         startm = startm->clone ();
1086                         ms = scm_cons (startm->self_scm (), ms);
1087                         scm_gc_unprotect_object (startm->self_scm ());
1088                 }
1089
1090                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1091                 seq->set_property ("elements", ms);
1092
1093
1094                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1095                 $$->set_property ("element", seq->self_scm ());
1096                 scm_gc_unprotect_object (seq->self_scm ());
1097 #else
1098                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1099                 $$->set_property ("element", $2->self_scm ());
1100                 scm_gc_unprotect_object ($2->self_scm ());
1101 #endif
1102         }
1103         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1104                 $$ = context_spec_music ($2, $4, $6, $5);
1105
1106         }
1107         | CONTEXT simple_string optional_context_mod Music {
1108                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1109         }
1110         | NEWCONTEXT simple_string optional_context_mod Music {
1111                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1112                         $3);
1113         }
1114
1115         | TIMES {
1116                 THIS->push_spot ();
1117         }
1118         /* CONTINUED */
1119                 fraction Music
1120
1121         {
1122                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1123                 Music *mp = $4;
1124
1125                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1126                 $$->set_spot (THIS->pop_spot ());
1127
1128                 $$->set_property ("element", mp->self_scm ());
1129                 scm_gc_unprotect_object (mp->self_scm ());
1130                 $$->set_property ("numerator", scm_int2num (n));
1131                 $$->set_property ("denominator", scm_int2num (d));
1132                 $$->compress (Moment (Rational (n,d)));
1133
1134         }
1135         | Repeated_music                { $$ = $1; }
1136         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1137                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1138                 Music *p = $4;
1139                 Pitch from = *unsmob_pitch ($2);
1140                 Pitch to = *unsmob_pitch ($3);
1141
1142                 p->transpose (interval (from, to));
1143                 $$->set_property ("element", p->self_scm ());
1144                 scm_gc_unprotect_object (p->self_scm ());
1145         }
1146         | APPLY embedded_scm Music  {
1147                 if (!ly_input_procedure_p ($2))
1148                         {
1149                         THIS->parser_error (_ ("\\apply takes function argument"));
1150                         $$ = $3;
1151                         }
1152                 else
1153                         {
1154                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1155                         Music *m = unsmob_music (ret);
1156                         if (!m) {
1157                                 THIS->parser_error ("\\apply must return a Music");
1158                                 m = MY_MAKE_MUSIC ("Music");
1159                                 }
1160                         $$ = m;
1161                         }
1162         }
1163         | NOTES
1164                 {
1165                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1166                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1167         }
1168         Music
1169                 { $$ = $3;
1170                   THIS->lexer_->pop_state ();
1171                 }
1172         | DRUMS
1173                 {
1174                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1175                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1176         }
1177         /* FIXME: This used to be: */
1178         Music
1179 /*      Grouped_music_list */
1180                 { $$ = $3;
1181                   THIS->lexer_->pop_state ();
1182                 }
1183         | FIGURES
1184                 { THIS->lexer_->push_figuredbass_state (); }
1185         /* FIXME: This used to be:
1186         Music
1187         but that breaks web build
1188         */
1189         Grouped_music_list
1190                 {
1191                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1192                   chm->set_property ("element", $3->self_scm ());
1193                   $$ = chm;
1194                   scm_gc_unprotect_object ($3->self_scm ());
1195
1196                   THIS->lexer_->pop_state ();
1197         }
1198         | CHORDS {
1199                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1200                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1201                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1202                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1203
1204         }
1205         /* FIXME:
1206         Music
1207 */
1208         Grouped_music_list
1209         {
1210                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1211                   chm->set_property ("element", $3->self_scm ());
1212                   scm_gc_unprotect_object ($3->self_scm ());
1213                   $$ = chm;
1214
1215                   THIS->lexer_->pop_state ();
1216         }
1217         | LYRICS
1218                 { THIS->lexer_->push_lyric_state (); }
1219         /* FIXME:
1220         Music
1221 */
1222         Grouped_music_list
1223                 {
1224                   $$ = $3;
1225                   THIS->lexer_->pop_state ();
1226         }
1227         | relative_music        { $$ = $1; }
1228         | re_rhythmed_music     { $$ = $1; }
1229         | TAG embedded_scm Music {
1230                 tag_music ($3, $2, THIS->here_input ());
1231                 $$ = $3;
1232         }
1233         ;
1234
1235 relative_music:
1236         RELATIVE absolute_pitch Music {
1237                 Music *m = $3;
1238                 Pitch start = *unsmob_pitch ($2);
1239                 $$ = make_music_relative (start, m);
1240                 scm_gc_unprotect_object (m->self_scm ());
1241         }
1242         | RELATIVE Composite_music {
1243                 Music *m = $2;
1244                 /* FIXME: why is octave==0 and default not middleC? */
1245                 Pitch middle_c (-1, 0, 0);
1246                 $$ = make_music_relative (middle_c, m);
1247                 scm_gc_unprotect_object (m->self_scm ());
1248         }
1249         ;
1250
1251 new_lyrics:
1252         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1253         /*cont */
1254         Grouped_music_list {
1255         /* Can also use Music at the expensive of two S/Rs similar to
1256            \repeat \alternative */
1257                 THIS->lexer_->pop_state ();
1258 #if 0
1259                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1260                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1261                 $$ = music;
1262 #else
1263                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1264 #endif
1265         }
1266         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1267         Grouped_music_list {
1268                 THIS->lexer_->pop_state ();
1269                 $$ = scm_cons ($4->self_scm (), $1);
1270         }
1271         ;
1272
1273 re_rhythmed_music:
1274         ADDLYRICS Music Music {
1275                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1276                 m->set_property ("elements", scm_listify ($2->self_scm (),
1277                         $3->self_scm (), SCM_UNDEFINED));
1278                 scm_gc_unprotect_object ($3->self_scm ());
1279                 scm_gc_unprotect_object ($2->self_scm ());
1280                 $$ = m;
1281         }
1282         | Grouped_music_list new_lyrics {
1283
1284                 /* FIXME: should find out uniqueXXX name from music */
1285                 SCM name = $1->get_property ("context-id");
1286                 //if (name == SCM_EOL)
1287                 if (!ly_c_string_p (name))
1288                         name = scm_makfrom0str ("");
1289
1290                 SCM context = scm_makfrom0str ("Lyrics");
1291                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1292
1293                 SCM lst = SCM_EOL;
1294                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1295                 {
1296                         Music *music = unsmob_music (ly_car (s));
1297                         Music *com = make_lyric_combine_music (name, music);
1298                         Music *csm = context_spec_music (context,
1299                                 get_next_unique_context (), com, SCM_EOL);
1300                         lst = scm_cons (csm->self_scm (), lst);
1301                 }
1302                 /* FIXME: only first lyric music is accepted,
1303                           the rest is junked */
1304                 all->set_property ("elements", scm_cons ($1->self_scm (),
1305                         lst));
1306                 $$ = all;
1307                 scm_gc_unprotect_object ($1->self_scm ());
1308         }
1309         | LYRICSTO string Music {
1310                 Music *music = $3;
1311                 SCM name = $2;
1312                 $$ = make_lyric_combine_music (name, music);
1313                 scm_gc_unprotect_object (music->self_scm ());
1314         }
1315         ;
1316
1317 context_change:
1318         CHANGE STRING '=' STRING  {
1319                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1320                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1321                 t-> set_property ("change-to-id", $4);
1322
1323                 $$ = t;
1324                 $$->set_spot (THIS->here_input ());
1325         }
1326         ;
1327
1328 property_operation:
1329         STRING '=' scalar {
1330                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1331                         scm_string_to_symbol ($1), $3);
1332         }
1333         | UNSET simple_string {
1334                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1335                         scm_string_to_symbol ($2));
1336         }
1337         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1338                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1339                         scm_string_to_symbol ($2), $3, $5);
1340         }
1341         | REVERT simple_string embedded_scm {
1342                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1343                         scm_string_to_symbol ($2), $3);
1344         }
1345         ;
1346
1347 context_def_mod:
1348         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1349         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1350         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1351
1352         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1353         | DENIES { $$ = ly_symbol2scm ("denies"); }
1354
1355         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1356         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1357         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1358         | NAME { $$ = ly_symbol2scm ("context-name"); }
1359         ;
1360
1361 context_mod:
1362         property_operation { $$ = $1; }
1363         | context_def_mod STRING {
1364                 $$ = scm_list_2 ($1, $2);
1365         }
1366         ;
1367
1368 context_prop_spec:
1369         simple_string {
1370                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1371                         scm_string_to_symbol ($1));
1372         }
1373         | simple_string '.' simple_string {
1374                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1375                         scm_string_to_symbol ($3));
1376         }
1377         ;
1378
1379 music_property_def:
1380         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1381                 $$ = property_op_to_music (scm_list_4 (
1382                         ly_symbol2scm ("poppush"),
1383                         ly_cadr ($2),
1384                         $3, $5));
1385                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1386         }
1387         | REVERT context_prop_spec embedded_scm {
1388                 $$ = property_op_to_music (scm_list_3 (
1389                         ly_symbol2scm ("pop"),
1390                         ly_cadr ($2),
1391                         $3));
1392
1393                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1394         }
1395         | SET context_prop_spec '=' scalar {
1396                 $$ = property_op_to_music (scm_list_3 (
1397                         ly_symbol2scm ("assign"),
1398                         ly_cadr ($2),
1399                         $4));
1400                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1401         }
1402         | UNSET context_prop_spec {
1403                 $$ = property_op_to_music (scm_list_2 (
1404                         ly_symbol2scm ("unset"),
1405                         ly_cadr ($2)));
1406                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1407         }
1408         | ONCE music_property_def {
1409                 SCM e = $2->get_property ("element");
1410                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1411                 $$ = $2;
1412
1413         }
1414         ;
1415
1416
1417 string:
1418         STRING {
1419                 $$ = $1;
1420         }
1421         | STRING_IDENTIFIER {
1422                 $$ = $1;
1423         }
1424         | string '+' string {
1425                 $$ = scm_string_append (scm_list_2 ($1, $3));
1426         }
1427         ;
1428
1429 simple_string: STRING {
1430         }
1431         | LYRICS_STRING {
1432         }
1433         ;
1434
1435 scalar: string {
1436         }
1437         | LYRICS_STRING {
1438         }
1439         | bare_int {
1440                 $$ = scm_int2num ($1);
1441         }
1442         | embedded_scm {
1443         }
1444         | full_markup {
1445         }
1446         | DIGIT {
1447                 $$ = scm_int2num ($1);
1448         }
1449         ;
1450
1451 /*
1452 FIXME: remove or fix this comment.  What is `This'?
1453
1454 This is a trick:
1455
1456 Adding pre_events to the simple_element
1457 makes the choice between
1458
1459   string:  STRING
1460
1461 and
1462
1463   simple_element: STRING
1464
1465 a single shift/reduction conflict.
1466
1467 nevertheless, this is not very clean, and we should find a different
1468 solution.
1469
1470 */
1471 pre_events: {
1472                 THIS->push_spot ();
1473         }
1474         ;
1475
1476 event_chord:
1477         pre_events simple_element post_events   {
1478                 SCM elts = $2-> get_property ("elements");
1479
1480                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1481
1482                 $2->set_property ("elements", elts);
1483                 $$ = $2;
1484         }
1485         | command_element
1486         | note_chord_element
1487         ;
1488
1489
1490 note_chord_element:
1491         chord_body optional_notemode_duration post_events
1492         {
1493                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1494                 SCM es = $1->get_property ("elements");
1495                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1496
1497                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1498                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1499                 es = ly_append2 (es, postevs);
1500
1501                 $1-> set_property ("elements", es);
1502                 $$ = $1;
1503         }
1504         ;
1505
1506 chord_open: '<'
1507         ;
1508
1509 chord_close: '>'
1510         ;
1511
1512 simul_open: DOUBLE_ANGLE_OPEN
1513         ;
1514
1515 simul_close: DOUBLE_ANGLE_CLOSE
1516         ;
1517
1518 chord_body:
1519         chord_open chord_body_elements chord_close
1520         {
1521                 $$ = MY_MAKE_MUSIC ("EventChord");
1522                 $$->set_property ("elements",
1523                         scm_reverse_x ($2, SCM_EOL));
1524         }
1525         ;
1526
1527 chord_body_elements:
1528         /* empty */             { $$ = SCM_EOL; }
1529         | chord_body_elements chord_body_element {
1530                 $$ = scm_cons ($2->self_scm (), $1);
1531                 scm_gc_unprotect_object ($2->self_scm ());
1532         }
1533         ;
1534
1535 chord_body_element:
1536         pitch exclamations questions post_events
1537         {
1538                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1539                 n->set_property ("pitch", $1);
1540                 if ($3 % 2)
1541                         n->set_property ("cautionary", SCM_BOOL_T);
1542                 if ($2 % 2 || $3 % 2)
1543                         n->set_property ("force-accidental", SCM_BOOL_T);
1544
1545                 if (ly_c_pair_p ($4)) {
1546                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1547                         n->set_property ("articulations", arts);
1548                 }
1549                 $$ = n;
1550         }
1551         | DRUM_PITCH post_events {
1552                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1553                 n->set_property ("duration", $2);
1554                 n->set_property ("drum-type", $1);
1555                 n->set_spot (THIS->here_input ());
1556
1557                 if (ly_c_pair_p ($2)) {
1558                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1559                         n->set_property ("articulations", arts);
1560                 }
1561                 $$ = n;
1562         }
1563         ;
1564
1565 add_quote:
1566         ADDQUOTE string Music {
1567                 SCM adder = ly_scheme_function ("add-quotable");
1568
1569                 scm_call_2 (adder, $2, $3->self_scm ());
1570                 scm_gc_unprotect_object ($3->self_scm ());
1571         }
1572         ;
1573
1574 command_element:
1575         command_req {
1576                 $$ = MY_MAKE_MUSIC ("EventChord");
1577                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1578                 scm_gc_unprotect_object ($1->self_scm ());
1579
1580                 $$-> set_spot (THIS->here_input ());
1581                 $1-> set_spot (THIS->here_input ());
1582         }
1583         | SKIP duration_length {
1584                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1585                 skip->set_property ("duration", $2);
1586
1587                 $$ = skip;
1588         }
1589         | QUOTE STRING duration_length {
1590                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1591                 SCM evs = SCM_EOL;
1592                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1593                 {
1594                         SCM key = $2; // use symbol?
1595                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1596                 }
1597                 Music *quote = 0;
1598                 if (ly_c_vector_p (evs))
1599                 {
1600                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1601                         quote->set_property ("duration", $3);
1602                         quote->set_property ("quoted-events", evs);
1603                 } else {
1604                         THIS->here_input ().warning (_f ("Can\'t find music"));
1605                         quote = MY_MAKE_MUSIC ("Event");
1606                 }
1607                 quote->set_spot (THIS->here_input ());
1608                 $$ = quote;
1609         }
1610         | OCTAVE { THIS->push_spot (); }
1611           pitch {
1612                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1613                 $$ = m;
1614                 $$->set_spot (THIS->pop_spot ());
1615                 $$->set_property ("pitch", $3);
1616         }
1617         | E_LEFTSQUARE {
1618                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1619                 m->set_property ("span-direction", scm_int2num (START));
1620                 m->set_spot (THIS->here_input ());
1621
1622                 $$ = MY_MAKE_MUSIC ("EventChord");
1623                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1624                 scm_gc_unprotect_object (m->self_scm ());
1625                 $$->set_spot (THIS->here_input ());
1626         }
1627         | E_RIGHTSQUARE {
1628                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1629                 m->set_property ("span-direction", scm_int2num (STOP));
1630                 m->set_spot (THIS->here_input ());
1631
1632                 $$ = MY_MAKE_MUSIC ("EventChord");
1633                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1634                 $$->set_spot (THIS->here_input ());
1635                 scm_gc_unprotect_object (m->self_scm ());
1636         }
1637         | E_BACKSLASH {
1638                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1639                 $$->set_spot (THIS->here_input ());
1640         }
1641         | '|'      {
1642                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1643
1644                 if (Music * m = unsmob_music (pipe))
1645                         $$ = m->clone ();
1646                 else
1647                         $$ = MY_MAKE_MUSIC ("BarCheck");
1648
1649                 $$->set_spot (THIS->here_input ());
1650         }
1651         | TRANSPOSITION pitch {
1652                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1653                                         $2);
1654                 $$->set_spot (THIS-> here_input ());
1655                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1656                         $$, SCM_EOL);
1657         }
1658         | BAR STRING                    {
1659                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1660
1661                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1662                                         t, SCM_EOL);
1663                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1664                 $$->set_spot (THIS->here_input ());
1665                 t->set_spot (THIS->here_input ());
1666         }
1667         | PARTIAL duration_length       {
1668                 Moment m = - unsmob_duration ($2)->get_length ();
1669                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1670                 p->set_spot (THIS->here_input ());
1671                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1672                                         p, SCM_EOL);
1673                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1674                                         p, SCM_EOL);
1675                 $$ = p;
1676         }
1677         | CLEF STRING  {
1678                 SCM proc = ly_scheme_function ("make-clef-set");
1679
1680                 SCM result = scm_call_1 (proc, $2);
1681                 scm_gc_protect_object (result);
1682                 $$ = unsmob_music (result);
1683         }
1684         | TIME_T fraction  {
1685                 SCM proc= ly_scheme_function ("make-time-signature-set");
1686
1687                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1688                 scm_gc_protect_object (result);
1689                 $$ = unsmob_music (result);
1690         }
1691         | MARK scalar {
1692                 SCM proc = ly_scheme_function ("make-mark-set");
1693
1694                 SCM result = scm_call_1 (proc, $2);
1695                 scm_gc_protect_object (result);
1696                 $$ = unsmob_music (result);
1697         }
1698         ;
1699
1700 command_req:
1701         BREATHE {
1702                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1703         }
1704         | E_TILDE {
1705                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1706         }
1707         | MARK DEFAULT  {
1708                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1709                 $$ = m;
1710         }
1711         | tempo_event {
1712                 $$ = $1;
1713         }
1714         | KEY DEFAULT {
1715                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1716                 $$ = key;
1717         }
1718         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1719
1720                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1721                 if (scm_ilength ($3) > 0)
1722                 {
1723                         key->set_property ("pitch-alist", $3);
1724                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1725                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1726                 } else {
1727                         THIS->parser_error (_ ("Second argument must be pitch list."));
1728                 }
1729
1730                 $$ = key;
1731         }
1732         ;
1733
1734 post_events:
1735         /* empty */ {
1736                 $$ = SCM_EOL;
1737         }
1738         | post_events post_event {
1739                 $2->set_spot (THIS->here_input ());
1740                 $$ = scm_cons ($2->self_scm (), $$);
1741                 scm_gc_unprotect_object ($2->self_scm ());
1742         }
1743         | post_events tagged_post_event {
1744                 $2 -> set_spot (THIS->here_input ());
1745                 $$ = scm_cons ($2->self_scm (), $$);
1746                 scm_gc_unprotect_object ($2->self_scm ());
1747         }
1748         ;
1749
1750
1751 tagged_post_event:
1752         '-' TAG embedded_scm post_event {
1753                 tag_music ($4, $3, THIS->here_input ());
1754                 $$ = $4;
1755         }
1756         ;
1757
1758 post_event:
1759         direction_less_event {
1760                 $$ = $1;
1761         }
1762         | HYPHEN {
1763                 if (!THIS->lexer_->is_lyric_state ())
1764                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1765                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1766         }
1767         | EXTENDER {
1768                 if (!THIS->lexer_->is_lyric_state ())
1769                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1770                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1771         }
1772         | script_dir direction_reqd_event {
1773                 if ($1)
1774                         $2->set_property ("direction", scm_int2num ($1));
1775                 $$ = $2;
1776         }
1777         | script_dir direction_less_event {
1778                 if ($1)
1779                         $2->set_property ("direction", scm_int2num ($1));
1780                 $$ = $2;
1781         }
1782         | string_number_event
1783         ;
1784
1785 string_number_event:
1786         E_UNSIGNED {
1787                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1788                 s->set_property ("string-number", scm_int2num ($1));
1789                 s->set_spot (THIS->here_input ());
1790                 $$ = s;
1791         }
1792         ;
1793
1794
1795 direction_less_event:
1796         '['  {
1797
1798
1799 /*
1800
1801 TODO: should take all these defs out of the parser, adn make use
1802 configurable, i.e.
1803
1804
1805 (set-articulation '~ "trill")
1806
1807 */
1808                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1809                 m->set_spot (THIS->here_input ());
1810                 m->set_property ("span-direction", scm_int2num (START));
1811                 $$ = m;
1812         }
1813         | ']'  {
1814                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1815                 m->set_spot (THIS->here_input ());
1816                 m->set_property ("span-direction", scm_int2num (STOP));
1817                 $$ = m;
1818         }
1819         | '~' {
1820                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1821                 m->set_spot (THIS->here_input ());
1822                 $$ = m;
1823         }
1824         | close_event {
1825                 $$ = $1;
1826                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1827                         scm_int2num (START));
1828         }
1829         | open_event {
1830                 $$ = $1;
1831                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1832                         scm_int2num (STOP));
1833         }
1834         | EVENT_IDENTIFIER      {
1835                 $$ = unsmob_music ($1);
1836         }
1837         | tremolo_type  {
1838                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1839                a->set_spot (THIS->here_input ());
1840                a->set_property ("tremolo-type", scm_int2num ($1));
1841                $$ = a;
1842         }
1843         ;
1844
1845 direction_reqd_event:
1846         gen_text_def {
1847                 $$ = $1;
1848         }
1849         | script_abbreviation {
1850                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1851                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1852                 if (ly_c_string_p (s))
1853                         a->set_property ("articulation-type", s);
1854                 else THIS->parser_error (_ ("Expecting string as script definition"));
1855                 $$ = a;
1856         }
1857         ;
1858
1859 oct_check:
1860         /**/ { $$ = SCM_EOL; }
1861         | '='  { $$ = scm_int2num (0); }
1862         | '=' sub_quotes { $$ = scm_int2num ($2); }
1863         | '=' sup_quotes { $$ = scm_int2num ($2); }
1864         ;
1865
1866 sup_quotes:
1867         '\'' {
1868                 $$ = 1;
1869         }
1870         | sup_quotes '\'' {
1871                 $$ ++;
1872         }
1873         ;
1874
1875 sub_quotes:
1876         ',' {
1877                 $$ = 1;
1878         }
1879         | sub_quotes ',' {
1880                 $$++;
1881         }
1882         ;
1883
1884 steno_pitch:
1885         NOTENAME_PITCH  {
1886                 $$ = $1;
1887         }
1888         | NOTENAME_PITCH sup_quotes     {
1889                 Pitch p = *unsmob_pitch ($1);
1890                 p = p.transposed (Pitch ($2,0,0));
1891                 $$ = p.smobbed_copy ();
1892         }
1893         | NOTENAME_PITCH sub_quotes      {
1894                 Pitch p =* unsmob_pitch ($1);
1895                 p = p.transposed (Pitch (-$2,0,0));
1896                 $$ = p.smobbed_copy ();
1897         }
1898         ;
1899
1900 /*
1901 ugh. duplication
1902 */
1903
1904 steno_tonic_pitch:
1905         TONICNAME_PITCH {
1906                 $$ = $1;
1907         }
1908         | TONICNAME_PITCH sup_quotes    {
1909                 Pitch p = *unsmob_pitch ($1);
1910                 p = p.transposed (Pitch ($2,0,0));
1911                 $$ = p.smobbed_copy ();
1912         }
1913         | TONICNAME_PITCH sub_quotes     {
1914                 Pitch p =* unsmob_pitch ($1);
1915
1916                 p = p.transposed (Pitch (-$2,0,0));
1917                 $$ = p.smobbed_copy ();
1918         }
1919         ;
1920
1921 pitch:
1922         steno_pitch {
1923                 $$ = $1;
1924         }
1925         ;
1926
1927 pitch_also_in_chords:
1928         pitch
1929         | steno_tonic_pitch
1930         ;
1931
1932 close_event:
1933         '('     {
1934                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1935                 $$ = s;
1936                 s->set_spot (THIS->here_input ());
1937         }
1938         | E_OPEN        {
1939                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1940                 $$ = s;
1941                 s->set_spot (THIS->here_input ());
1942         }
1943         | E_SMALLER {
1944                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1945                 $$ = s;
1946                 s->set_spot (THIS->here_input ());
1947         }
1948         | E_BIGGER {
1949                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1950                 $$ = s;
1951                 s->set_spot (THIS->here_input ());
1952         }
1953         ;
1954
1955
1956 open_event:
1957         E_EXCLAMATION   {
1958                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1959                 s->set_spot (THIS->here_input ());
1960
1961                 $$ = s;
1962         }
1963         | ')'   {
1964                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1965                 $$ = s;
1966                 s->set_spot (THIS->here_input ());
1967
1968         }
1969         | E_CLOSE       {
1970                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1971                 $$ = s;
1972                 s->set_property ("span-type",
1973                         scm_makfrom0str ("phrasing-slur"));
1974                 s->set_spot (THIS->here_input ());
1975         }
1976         ;
1977
1978 gen_text_def:
1979         full_markup {
1980                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1981                 t->set_property ("text", $1);
1982                 t->set_spot (THIS->here_input ());
1983                 $$ = t;
1984         }
1985         | string {
1986                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1987                 t->set_property ("text",
1988                         make_simple_markup (THIS->lexer_->encoding (), $1));
1989                 t->set_spot (THIS->here_input ());
1990                 $$ = t;
1991
1992         }
1993         | DIGIT {
1994                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1995                 t->set_property ("digit", scm_int2num ($1));
1996                 t->set_spot (THIS->here_input ());
1997                 $$ = t;
1998         }
1999         ;
2000
2001 script_abbreviation:
2002         '^'             {
2003                 $$ = scm_makfrom0str ("Hat");
2004         }
2005         | '+'           {
2006                 $$ = scm_makfrom0str ("Plus");
2007         }
2008         | '-'           {
2009                 $$ = scm_makfrom0str ("Dash");
2010         }
2011         | '|'           {
2012                 $$ = scm_makfrom0str ("Bar");
2013         }
2014         | '>'           {
2015                 $$ = scm_makfrom0str ("Larger");
2016         }
2017         | '.'           {
2018                 $$ = scm_makfrom0str ("Dot");
2019         }
2020         | '_' {
2021                 $$ = scm_makfrom0str ("Underscore");
2022         }
2023         ;
2024
2025 script_dir:
2026         '_'     { $$ = DOWN; }
2027         | '^'   { $$ = UP; }
2028         | '-'   { $$ = CENTER; }
2029         ;
2030
2031
2032 absolute_pitch:
2033         steno_pitch     {
2034                 $$ = $1;
2035         }
2036         ;
2037
2038 duration_length:
2039         multiplied_duration {
2040                 $$ = $1;
2041         }
2042         ;
2043
2044 optional_notemode_duration:
2045         {
2046                 Duration dd = THIS->default_duration_;
2047                 $$ = dd.smobbed_copy ();
2048
2049                 THIS->beam_check ($$);
2050         }
2051         | multiplied_duration   {
2052                 $$ = $1;
2053                 THIS->default_duration_ = *unsmob_duration ($$);
2054
2055                 THIS->beam_check ($$);
2056         }
2057         ;
2058
2059 steno_duration:
2060         bare_unsigned dots              {
2061                 int len = 0;
2062                 if (!is_duration ($1))
2063                         THIS->parser_error (_f ("not a duration: %d", $1));
2064                 else
2065                         len = intlog2 ($1);
2066
2067                 $$ = Duration (len, $2).smobbed_copy ();
2068         }
2069         | DURATION_IDENTIFIER dots      {
2070                 Duration *d = unsmob_duration ($1);
2071                 Duration k (d->duration_log (), d->dot_count () + $2);
2072                 *d = k;
2073                 $$ = $1;
2074         }
2075         ;
2076
2077 multiplied_duration:
2078         steno_duration {
2079                 $$ = $1;
2080         }
2081         | multiplied_duration '*' bare_unsigned {
2082                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2083         }
2084         | multiplied_duration '*' FRACTION {
2085                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2086
2087                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2088         }
2089         ;
2090
2091 fraction:
2092         FRACTION { $$ = $1; }
2093         | UNSIGNED '/' UNSIGNED {
2094                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2095         }
2096         ;
2097
2098 dots:
2099         /* empty */     {
2100                 $$ = 0;
2101         }
2102         | dots '.' {
2103                 $$ ++;
2104         }
2105         ;
2106
2107 tremolo_type:
2108         ':'     {
2109                 $$ = 0;
2110         }
2111         | ':' bare_unsigned {
2112                 if (!is_duration ($2))
2113                         THIS->parser_error (_f ("not a duration: %d", $2));
2114                 $$ = $2;
2115         }
2116         ;
2117
2118 bass_number:
2119         DIGIT   {
2120                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2121         }
2122         | UNSIGNED {
2123                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2124         }
2125         | STRING { $$ = $1; }
2126         ;
2127
2128 bass_mod:
2129         '-'     { $$ = -2; }
2130         | '+'   { $$ = 2; }
2131         | '!'   { $$ = 0; }
2132         ;
2133
2134 bass_figure:
2135         FIGURE_SPACE {
2136                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2137                 $$ = bfr->self_scm ();
2138                 scm_gc_unprotect_object ($$);
2139         }
2140         | bass_number  {
2141                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2142                 $$ = bfr->self_scm ();
2143
2144                 bfr->set_property ("figure", $1);
2145
2146                 scm_gc_unprotect_object ($$);
2147         }
2148         | bass_figure bass_mod {
2149                 Music *m = unsmob_music ($1);
2150                 if ($2) {
2151                         SCM salter = m->get_property ("alteration");
2152                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2153                         m->set_property ("alteration",
2154                                 scm_int2num (alter + $2));
2155                 } else {
2156                         m->set_property ("alteration", scm_int2num (0));
2157                 }
2158         }
2159         ;
2160
2161 br_bass_figure:
2162         '[' bass_figure {
2163                 $$ = $2;
2164                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2165         }
2166         | bass_figure   {
2167                 $$ = $1;
2168         }
2169         | br_bass_figure ']' {
2170                 $$ = $1;
2171                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2172         }
2173         ;
2174
2175 figure_list:
2176         /**/            {
2177                 $$ = SCM_EOL;
2178         }
2179         | figure_list br_bass_figure {
2180                 $$ = scm_cons ($2, $1);
2181         }
2182         ;
2183
2184 figure_spec:
2185         FIGURE_OPEN figure_list FIGURE_CLOSE {
2186                 Music *m = MY_MAKE_MUSIC ("EventChord");
2187                 $2 = scm_reverse_x ($2, SCM_EOL);
2188                 m->set_property ("elements", $2);
2189                 $$ = m->self_scm ();
2190         }
2191         ;
2192
2193
2194 optional_rest:
2195         /**/   { $$ = 0; }
2196         | REST { $$ = 1; }
2197         ;
2198
2199 simple_element:
2200         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2201
2202                 Input i = THIS->pop_spot ();
2203                 if (!THIS->lexer_->is_note_state ())
2204                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2205
2206                 Music *n = 0;
2207                 if ($6)
2208                         n = MY_MAKE_MUSIC ("RestEvent");
2209                 else
2210                         n = MY_MAKE_MUSIC ("NoteEvent");
2211
2212                 n->set_property ("pitch", $1);
2213                 n->set_property ("duration", $5);
2214
2215                 if (ly_c_number_p ($4))
2216                 {
2217                         int q = ly_scm2int ($4);
2218                         n->set_property ("absolute-octave", scm_int2num (q-1));
2219                 }
2220
2221                 if ($3 % 2)
2222                         n->set_property ("cautionary", SCM_BOOL_T);
2223                 if ($2 % 2 || $3 % 2)
2224                         n->set_property ("force-accidental", SCM_BOOL_T);
2225
2226                 Music *v = MY_MAKE_MUSIC ("EventChord");
2227                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2228                 scm_gc_unprotect_object (n->self_scm ());
2229
2230                 v->set_spot (i);
2231                 n->set_spot (i);
2232                 $$ = v;
2233         }
2234         | DRUM_PITCH optional_notemode_duration {
2235                 Input i = THIS->pop_spot ();
2236
2237                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2238                 n->set_property ("duration", $2);
2239                 n->set_property ("drum-type", $1);
2240
2241                 Music *v = MY_MAKE_MUSIC ("EventChord");
2242                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2243                 scm_gc_unprotect_object (n->self_scm ());
2244                 v->set_spot (i);
2245                 n->set_spot (i);
2246                 $$ = v;
2247
2248         }
2249         | figure_spec optional_notemode_duration {
2250                 Music *m = unsmob_music ($1);
2251                 Input i = THIS->pop_spot ();
2252                 m->set_spot (i);
2253                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2254                 {
2255                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2256                 }
2257                 $$ = m;
2258         }
2259         | RESTNAME optional_notemode_duration           {
2260
2261                 Input i = THIS->pop_spot ();
2262                 Music *ev = 0;
2263                 if (ly_scm2string ($1) == "s") {
2264                         /* Space */
2265                         ev = MY_MAKE_MUSIC ("SkipEvent");
2266                   }
2267                 else {
2268                         ev = MY_MAKE_MUSIC ("RestEvent");
2269
2270                     }
2271                 ev->set_property ("duration", $2);
2272                 ev->set_spot (i);
2273                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2274                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2275                 velt->set_spot (i);
2276
2277                 scm_gc_unprotect_object (ev->self_scm ());
2278
2279                 $$ = velt;
2280         }
2281         | MULTI_MEASURE_REST optional_notemode_duration         {
2282                 THIS->pop_spot ();
2283
2284                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2285                 SCM mus = scm_call_2 (proc, $2,
2286                         make_input (THIS->here_input ()));
2287                 scm_gc_protect_object (mus);
2288                 $$ = unsmob_music (mus);
2289         }
2290
2291         | lyric_element optional_notemode_duration      {
2292                 Input i = THIS->pop_spot ();
2293                 if (!THIS->lexer_->is_lyric_state ())
2294                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2295
2296                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2297                 lreq->set_property ("text", $1);
2298                 lreq->set_property ("duration",$2);
2299                 lreq->set_spot (i);
2300                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2301                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2302
2303                 $$= velt;
2304         }
2305         | new_chord {
2306                 THIS->pop_spot ();
2307
2308                 if (!THIS->lexer_->is_chord_state ())
2309                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2310                 $$ = unsmob_music ($1);
2311         }
2312         ;
2313
2314 lyric_element:
2315         /* FIXME: lyric flavoured markup would be better */
2316         full_markup {
2317         }
2318         | LYRICS_STRING {
2319         }
2320         ;
2321
2322 new_chord:
2323         steno_tonic_pitch optional_notemode_duration   {
2324                 $$ = make_chord ($1, $2, SCM_EOL);
2325         }
2326         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2327                 SCM its = scm_reverse_x ($4, SCM_EOL);
2328                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2329         }
2330         ;
2331
2332 chord_items:
2333         /**/ {
2334                 $$ = SCM_EOL;
2335         }
2336         | chord_items chord_item {
2337                 $$ = scm_cons ($2, $$);
2338         }
2339         ;
2340
2341 chord_separator:
2342         CHORD_COLON {
2343                 $$ = ly_symbol2scm ("chord-colon");
2344         }
2345         | CHORD_CARET {
2346                 $$ = ly_symbol2scm ("chord-caret");
2347         }
2348         | CHORD_SLASH steno_tonic_pitch {
2349                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2350         }
2351         | CHORD_BASS steno_tonic_pitch {
2352                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2353         }
2354         ;
2355
2356 chord_item:
2357         chord_separator {
2358                 $$ = $1;
2359         }
2360         | step_numbers {
2361                 $$ = scm_reverse_x ($1, SCM_EOL);
2362         }
2363         | CHORD_MODIFIER  {
2364                 $$ = $1;
2365         }
2366         ;
2367
2368 step_numbers:
2369         step_number { $$ = scm_cons ($1, SCM_EOL); }
2370         | step_numbers '.' step_number {
2371                 $$ = scm_cons ($3, $$);
2372         }
2373         ;
2374
2375 step_number:
2376         bare_unsigned {
2377                 $$ = make_chord_step ($1, 0);
2378         }
2379         | bare_unsigned '+' {
2380                 $$ = make_chord_step ($1, SHARP);
2381         }
2382         | bare_unsigned CHORD_MINUS {
2383                 $$ = make_chord_step ($1, FLAT);
2384         }
2385         ;
2386
2387 /*
2388         UTILITIES
2389
2390 TODO: should deprecate in favor of Scheme?
2391
2392  */
2393 number_expression:
2394         number_expression '+' number_term {
2395                 $$ = scm_sum ($1, $3);
2396         }
2397         | number_expression '-' number_term {
2398                 $$ = scm_difference ($1, $3);
2399         }
2400         | number_term
2401         ;
2402
2403 number_term:
2404         number_factor {
2405                 $$ = $1;
2406         }
2407         | number_factor '*' number_factor {
2408                 $$ = scm_product ($1, $3);
2409         }
2410         | number_factor '/' number_factor {
2411                 $$ = scm_divide ($1, $3);
2412         }
2413         ;
2414
2415 number_factor:
2416         '-'  number_factor { /* %prec UNARY_MINUS */
2417                 $$ = scm_difference ($2, SCM_UNDEFINED);
2418         }
2419         | bare_number
2420         ;
2421
2422
2423 bare_number:
2424         UNSIGNED        {
2425                 $$ = scm_int2num ($1);
2426         }
2427         | REAL          {
2428                 $$ = $1;
2429         }
2430         | NUMBER_IDENTIFIER             {
2431                 $$ = $1;
2432         }
2433         | REAL NUMBER_IDENTIFIER        {
2434                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2435         }
2436         | UNSIGNED NUMBER_IDENTIFIER    {
2437                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2438         }
2439         ;
2440
2441
2442 bare_unsigned:
2443         UNSIGNED {
2444                         $$ = $1;
2445         }
2446         | DIGIT {
2447                 $$ = $1;
2448         }
2449         ;
2450
2451 bare_int:
2452         bare_number {
2453                 if (scm_integer_p ($1) == SCM_BOOL_T)
2454                 {
2455                         int k = ly_scm2int ($1);
2456                         $$ = k;
2457                 } else
2458                 {
2459                         THIS->parser_error (_ ("need integer number arg"));
2460                         $$ = 0;
2461                 }
2462         }
2463         | '-' bare_int {
2464                 $$ = -$2;
2465         }
2466         ;
2467
2468 exclamations:
2469                 { $$ = 0; }
2470         | exclamations '!'      { $$ ++; }
2471         ;
2472
2473 questions:
2474                 { $$ = 0; }
2475         | questions '?' { $$ ++; }
2476         ;
2477
2478
2479
2480 full_markup:
2481         MARKUP_IDENTIFIER {
2482                 $$ = $1;
2483         }
2484         | MARKUP
2485                 { THIS->lexer_->push_markup_state (); }
2486         markup
2487                 { $$ = $3;
2488                   THIS->lexer_->pop_state ();
2489                 }
2490         ;
2491
2492
2493 /*
2494 This should be done more dynamically if possible.
2495 */
2496 markup:
2497         STRING {
2498                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2499         }
2500         | MARKUP_HEAD_EMPTY {
2501                 $$ = scm_list_1 ($1);
2502         }
2503         | MARKUP_HEAD_MARKUP0 markup {
2504                 $$ = scm_list_2 ($1, $2);
2505         }
2506         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2507                 $$ = scm_list_3 ($1, $2, $3);
2508         }
2509         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2510                 $$ = scm_list_3 ($1, $2, $3);
2511         }
2512         | markup_line {
2513                 $$ = $1;
2514         }
2515         | MARKUP_HEAD_LIST0 markup_list {
2516                 $$ = scm_list_2 ($1,$2);
2517         }
2518         | MARKUP_HEAD_SCM0 embedded_scm {
2519                 $$ = scm_list_2 ($1, $2);
2520         }
2521         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2522                 $$ = scm_list_4 ($1, $2, $3, $4);
2523         }
2524         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2525                 $$ = scm_list_4 ($1, $2, $3, $4);
2526         }
2527         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2528                 $$ = scm_list_3 ($1, $2, $3);
2529         }
2530         | MARKUP_IDENTIFIER {
2531                 $$ = $1;
2532         }
2533         | STRING_IDENTIFIER {
2534                 $$ = $1;
2535         }
2536         | score_block {
2537                 /* WIP this is a bit arbitrary,
2538                    we should also allow \book or Composite_music.
2539                    However, you'd typically want to change paper
2540                    settings, and need a \score block anyway.  */
2541                 Score *score = $1;
2542                 Book *book = new Book;
2543                 book->scores_.push (score);
2544                 extern Music_output_def* get_paper (My_lily_parser *parser);
2545                 Music_output_def *paper = get_paper (THIS);
2546                 SCM s = book->to_stencil (paper, THIS->header_);
2547                 scm_gc_unprotect_object (score->self_scm ());
2548                 scm_gc_unprotect_object (book->self_scm ());
2549                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2550         }
2551         ;
2552
2553 markup_list:
2554         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2555         ;
2556
2557 markup_line:
2558         '{' markup_list_body '}' {
2559                 SCM line = ly_scheme_function ("line-markup");
2560
2561                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2562         }
2563         ;
2564
2565 markup_list_body:
2566         /**/ {  $$ = SCM_EOL; }
2567         | markup_list_body markup {
2568                 $$ = scm_cons ($2, $1);
2569         }
2570         ;
2571
2572
2573 %%
2574
2575 void
2576 My_lily_parser::set_yydebug (bool )
2577 {
2578 #if 0
2579         yydebug = 1;
2580 #endif
2581 }
2582
2583 void
2584 My_lily_parser::do_yyparse ()
2585 {
2586         yyparse ((void*)this);
2587 }
2588
2589
2590 /*
2591 Should make this optional?    It will also complain when you do
2592
2593         [s4]
2594
2595 which is entirely legitimate.
2596
2597 Or we can scrap it. Barchecks should detect wrong durations, and
2598 skipTypesetting speeds it up a lot.
2599 */
2600
2601 void
2602 My_lily_parser::beam_check (SCM dur)
2603 {
2604   Duration *d = unsmob_duration (dur);
2605   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2606     {
2607       Music *m = unsmob_music (last_beam_start_);
2608       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2609     }
2610   last_beam_start_ = SCM_EOL;
2611 }
2612
2613
2614
2615
2616 /*
2617
2618 It is a little strange to have this function in this file, but
2619 otherwise, we have to import music classes into the lexer.
2620
2621 */
2622 int
2623 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2624 {
2625         if (ly_c_string_p (sid)) {
2626                 *destination = sid;
2627                 return STRING_IDENTIFIER;
2628         } else if (ly_c_number_p (sid)) {
2629                 *destination = sid;
2630                 return NUMBER_IDENTIFIER;
2631         } else if (unsmob_context_def (sid)) {
2632                 *destination = unsmob_context_def (sid)->clone_scm ();
2633                 return CONTEXT_DEF_IDENTIFIER;
2634         } else if (unsmob_score (sid)) {
2635                 Score *score = new Score (*unsmob_score (sid));
2636                 *destination = score->self_scm ();
2637                 return SCORE_IDENTIFIER;
2638         } else if (Music *mus = unsmob_music (sid)) {
2639                 mus = mus->clone ();
2640                 *destination = mus->self_scm ();
2641                 unsmob_music (*destination)->
2642                         set_property ("origin", make_input (last_input_));
2643                 return dynamic_cast<Event*> (mus)
2644                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2645         } else if (unsmob_duration (sid)) {
2646                 *destination = unsmob_duration (sid)->smobbed_copy ();
2647                 return DURATION_IDENTIFIER;
2648         } else if (unsmob_music_output_def (sid)) {
2649                 Music_output_def *p = unsmob_music_output_def (sid);
2650                 p = p->clone ();
2651
2652                 *destination = p->self_scm ();
2653                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2654         } else if (Text_item::markup_p (sid)) {
2655                 *destination = sid;
2656                 return MARKUP_IDENTIFIER;
2657         }
2658
2659         return -1;
2660 }
2661
2662 Music *
2663 property_op_to_music (SCM op)
2664 {
2665         Music *m = 0;
2666         SCM tag = ly_car (op);
2667         SCM symbol = ly_cadr (op);
2668         SCM args = ly_cddr (op);
2669         SCM grob_val = SCM_UNDEFINED;
2670         SCM grob_sym = SCM_UNDEFINED;
2671         SCM val = SCM_UNDEFINED;
2672
2673         if (tag == ly_symbol2scm ("assign"))
2674                 {
2675                 m = MY_MAKE_MUSIC ("PropertySet");
2676                 val = ly_car (args);
2677                 }
2678         else if (tag == ly_symbol2scm ("unset"))
2679                 m = MY_MAKE_MUSIC ("PropertyUnset");
2680         else if (tag == ly_symbol2scm ("poppush")
2681                  || tag == ly_symbol2scm ("push"))
2682                 {
2683                 m = MY_MAKE_MUSIC ("OverrideProperty");
2684                 grob_sym = ly_car (args);
2685                 grob_val = ly_cadr (args);
2686                 }
2687         else if (tag == ly_symbol2scm ("pop")) {
2688                 m = MY_MAKE_MUSIC ("RevertProperty");
2689                 grob_sym = ly_car (args);
2690                 }
2691
2692         m->set_property ("symbol", symbol);
2693
2694         if (val != SCM_UNDEFINED)
2695                 m->set_property ("value", val);
2696         if (grob_val != SCM_UNDEFINED)
2697                 m->set_property ("grob-value", grob_val);
2698
2699         if (grob_sym != SCM_UNDEFINED)
2700                 {
2701                 bool itc = internal_type_checking_global_b;
2702                 /* UGH.
2703                 */
2704                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2705                 if (autobeam)
2706                         internal_type_checking_global_b = false;
2707                 m->set_property ("grob-property", grob_sym);
2708                 if (autobeam)
2709                         internal_type_checking_global_b = itc;
2710                 }
2711
2712         if (op == ly_symbol2scm ("poppush"))
2713                 m->set_property ("pop-first", SCM_BOOL_T);
2714
2715
2716         return m;
2717 }
2718
2719 Music*
2720 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2721 {
2722         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2723
2724         csm->set_property ("element", m->self_scm ());
2725         scm_gc_unprotect_object (m->self_scm ());
2726
2727         csm->set_property ("context-type",
2728                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2729         csm->set_property ("property-operations", ops);
2730
2731         if (ly_c_string_p (id))
2732                 csm->set_property ("context-id", id);
2733         return csm;
2734 }
2735
2736 SCM
2737 get_next_unique_context ()
2738 {
2739         static int new_context_count;
2740         char s[1024];
2741         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2742         return scm_makfrom0str (s);
2743 }
2744