lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token CHANGE
 252 %token CHORDMODIFIERS
 253 %token CHORDS
 254 %token DOUBLE_ANGLE_OPEN
 255 %token DOUBLE_ANGLE_CLOSE
 256 %token CLEF
 257 %token COMMANDSPANREQUEST
 258 %token CONSISTS
 259 %token CONSISTSEND
 260 %token CONTEXT
 261 %token DEFAULT
 262 %token DENIES
 263 %token DESCRIPTION
 264 %token EXTENDER
 265 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 266 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 267 %token GROBDESCRIPTIONS
 268 %token HEADER
 269 %token HYPHEN
 270 %token INVALID
 271 %token KEY
 272 %token LYRICS
 273 %token LYRICS_STRING
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTIAL
 285 %token QUOTE
 286 %token RELATIVE
 287 %token REMOVE
 288 %token REPEAT
 289 %token REST
 290 %token SCM_T
 291 %token SCORE
 292 %token SEQUENTIAL
 293 %token NEWLYRICS
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSPOSE
 302 %token TRANSPOSITION
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306
 307 /* escaped */
 308 /* FIXME: this sucks.  The user will get to see these names:
 309     syntax error, unexpected E_CHAR:
 310                 \
 311                  %%
 312   */
 313 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 314 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 315 %token E_BACKSLASH
 316 %token <i> E_UNSIGNED
 317 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 318 %token FIGURE_SPACE
 319
 320 %token <i>      DIGIT
 321 %token <scm>    NOTENAME_PITCH
 322 %token <scm>    TONICNAME_PITCH
 323 %token <scm>    CHORDMODIFIER_PITCH
 324 %token <scm>    DURATION_IDENTIFIER
 325 %token <scm>    FRACTION
 326 %token <id>     IDENTIFIER
 327 %token DRUMS
 328 %token <scm>    DRUM_PITCH
 329 %token <scm>    CHORD_MODIFIER
 330 %token <scm>    SCORE_IDENTIFIER
 331 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 332 %token <scm>    NUMBER_IDENTIFIER
 333 %token <scm>    EVENT_IDENTIFIER
 334 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 335 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 336 %token <scm>    RESTNAME
 337 %token <scm>    STRING
 338 %token <scm>    SCM_T
 339 %token <i>      UNSIGNED
 340 %token <scm>   REAL
 341
 342 %token MARKUP
 343 %token <scm> MARKUP_HEAD_MARKUP0
 344 %token <scm> MARKUP_HEAD_EMPTY
 345 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0
 347 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 351
 352 %token <scm> MUSIC_FUNCTION
 353 %token <scm> MUSIC_FUNCTION_SCM
 354 %token <scm> MUSIC_FUNCTION_MUSIC
 355 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 356 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 357 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 359
 360 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 361 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 362
 363 %type <book>    book_block book_body
 364 %type <i>       exclamations questions dots optional_rest
 365 %type <i>       bass_mod
 366 %type <scm>     oct_check
 367 %type <scm>     context_mod_list
 368 %type <scm>     lyric_element
 369 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 370 %type <scm>     new_lyrics
 371 %type <outputdef> output_def
 372 %type <scm>     lilypond_header lilypond_header_body
 373 %type <music>   open_event close_event
 374 %type <i>       sub_quotes sup_quotes
 375 %type <music>   toplevel_music
 376 %type <music>   simple_element event_chord command_element
 377 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 378 %type <scm>     Generic_prefix_music_scm
 379 %type <music>   Grouped_music_list
 380 %type <music>   Repeated_music
 381 %type <scm>     Alternative_music
 382 %type <i>       tremolo_type
 383 %type <i>       bare_int  bare_unsigned
 384 %type <i>       script_dir
 385 %type <scm>     identifier_init
 386 %type <scm>     simple_string
 387
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <scm>     chord_body_elements
 390 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 391
 392 %type <scm>     post_events
 393 %type <music>   gen_text_def direction_less_event direction_reqd_event
 394 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 395 %type <scm>     steno_tonic_pitch
 396 %type <scm>     duration_length fraction
 397
 398 %type <scm>     chord_item chord_items chord_separator new_chord
 399 %type <scm>     step_number step_numbers
 400
 401 %type <scm>     embedded_scm scalar
 402 %type <music>   Music Sequential_music Simultaneous_music
 403 %type <music>   relative_music re_rhythmed_music
 404 %type <music>   music_property_def context_change
 405 %type <scm>     context_prop_spec
 406 %type <scm>     Music_list
 407 %type <scm>     property_operation
 408 %type <scm>     context_mod context_def_mod optional_context_mod
 409 %type <outputdef>       music_output_def_body music_output_def_head
 410 %type <music>   post_event tagged_post_event
 411 %type <music>   command_req
 412 %type <music>   string_number_event
 413 %type <scm>     string bare_number number_expression number_term number_factor
 414 %type <score>   score_block score_body
 415
 416 %type <scm>     context_def_spec_block context_def_spec_body
 417 %type <music>   tempo_event
 418 %type <scm>     script_abbreviation
 419
 420
 421
 422 %left '-' '+'
 423
 424 /* We don't assign precedence to / and *, because we might need varied
 425 prec levels in different prods */
 426
 427 %left UNARY_MINUS
 428
 429 %%
 430
 431 lilypond:       /* empty */
 432         | lilypond toplevel_expression {
 433         }
 434         | lilypond assignment {
 435         }
 436         | lilypond error {
 437                 THIS->error_level_ = 1;
 438         }
 439         | lilypond INVALID      {
 440                 THIS->error_level_ = 1;
 441         }
 442         ;
 443
 444 toplevel_expression:
 445         lilypond_header {
 446                 THIS->header_ = $1;
 447         }
 448         | add_quote {
 449
 450         }
 451         | book_block {
 452                 Book *book = $1;
 453                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 454                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 455                 scm_gc_unprotect_object (book->self_scm ());
 456         }
 457         | score_block {
 458                 Score *score = $1;
 459
 460                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 461                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 462                 scm_gc_unprotect_object (score->self_scm ());
 463         }
 464         | toplevel_music {
 465                 Music *music = $1;
 466                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 467                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 468                 scm_gc_unprotect_object (music->self_scm ());
 469         }
 470         | output_def {
 471                 SCM id = SCM_EOL;
 472                 if (dynamic_cast<Paper_def*> ($1))
 473                         id = scm_makfrom0str ("$defaultpaper");
 474                 else if (dynamic_cast<Midi_def*> ($1))
 475                         id = scm_makfrom0str ("$defaultmidi");
 476                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 477                 scm_gc_unprotect_object ($1->self_scm ());
 478         }
 479         ;
 480
 481 toplevel_music:
 482         Composite_music {
 483         }
 484         ;
 485
 486 embedded_scm:
 487         SCM_T
 488         | SCM_IDENTIFIER
 489         ;
 490
 491
 492 lilypond_header_body:
 493         {
 494                 $$ = ly_make_anonymous_module (safe_global_b);
 495                 THIS->lexer_->add_scope ($$);
 496         }
 497         | lilypond_header_body assignment  {
 498
 499         }
 500         ;
 501
 502 lilypond_header:
 503         HEADER '{' lilypond_header_body '}'     {
 504                 $$ = THIS->lexer_->remove_scope ();
 505         }
 506         ;
 507
 508
 509 /*
 510         DECLARATIONS
 511 */
 512 assignment:
 513         STRING {
 514                 THIS->push_spot ();
 515         }
 516         /* cont */ '=' identifier_init  {
 517
 518         /*
 519                 Should find generic way of associating input with objects.
 520         */
 521                 Input ip = THIS->pop_spot ();
 522
 523                 if (! is_regular_identifier ($1))
 524                 {
 525                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 526                 }
 527
 528                 THIS->lexer_->set_identifier ($1, $4);
 529
 530 /*
 531  TODO: devise standard for protection in parser.
 532
 533   The parser stack lives on the C-stack, which means that
 534 all objects can be unprotected as soon as they're here.
 535
 536 */
 537         }
 538         | embedded_scm { }
 539         ;
 540
 541
 542 identifier_init:
 543         score_block {
 544                 $$ = $1->self_scm ();
 545                 scm_gc_unprotect_object ($$);
 546         }
 547         | full_markup {
 548                 $$ = $1;
 549         }
 550         | output_def {
 551                 $$ = $1->self_scm ();
 552                 scm_gc_unprotect_object ($$);
 553         }
 554         | context_def_spec_block {
 555                 $$ = $1;
 556         }
 557         | Music  {
 558                 $$ = $1->self_scm ();
 559                 scm_gc_unprotect_object ($$);
 560         }
 561         | post_event {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | number_expression {
 566                 $$ = $1;
 567         }
 568         | string {
 569                 $$ = $1;
 570         }
 571         | embedded_scm  {
 572                 $$ = $1;
 573         }
 574         ;
 575
 576 context_def_spec_block:
 577         CONTEXT '{' context_def_spec_body '}'
 578                 {
 579                 $$ = $3;
 580         }
 581         ;
 582
 583 context_def_spec_body:
 584         /**/ {
 585                 $$ = Context_def::make_scm ();
 586                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 587         }
 588         | CONTEXT_DEF_IDENTIFIER {
 589                 $$ = $1;
 590                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 593                 Context_def*td = unsmob_context_def ($$);
 594
 595                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 596                         SCM tag = ly_caar (p);
 597
 598                         /* TODO: should make new tag "grob-definition" ? */
 599                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 600                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 601                 }
 602         }
 603         | context_def_spec_body context_mod {
 604                 unsmob_context_def ($$)->add_context_mod ($2);
 605         }
 606         ;
 607
 608 book_block:
 609         BOOK {
 610                 THIS->push_spot ();
 611         }
 612         /*cont*/ '{' book_body '}'      {
 613                 THIS->pop_spot ();
 614                 $$ = $4;
 615         }
 616         ;
 617
 618 /* FIXME:
 619    * Use 'handlers' like for toplevel-* stuff?
 620    * grok \paper and \midi?  */
 621 book_body:
 622         {
 623                 $$ = new Book;
 624                 $$->set_spot (THIS->here_input ());
 625         }
 626         | book_body score_block {
 627                 Score *score = $2;
 628                 $$->scores_.push (score);
 629                 scm_gc_unprotect_object (score->self_scm ());
 630         }
 631         | book_body Composite_music {
 632                 Music *music = $2;
 633                 Score *score
 634                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 635                 $$->scores_.push (score);
 636                 scm_gc_unprotect_object (music->self_scm ());
 637         }
 638         | lilypond_header {
 639                 THIS->header_ = $1;
 640         }
 641         | book_body error {
 642         }
 643         ;
 644
 645 score_block:
 646         SCORE {
 647                 THIS->push_spot ();
 648         }
 649         /*cont*/ '{' score_body '}'     {
 650                 THIS->pop_spot ();
 651                 $$ = $4;
 652         }
 653         ;
 654
 655 score_body:
 656         Music   {
 657                 $$ = new Score;
 658
 659                 $$->set_spot (THIS->here_input ());
 660                 SCM m = $1->self_scm ();
 661                 scm_gc_unprotect_object (m);
 662
 663                 /*
 664                         guh.
 665                 */
 666                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 667                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 668                         m = scm_call_1 (ly_car (check_funcs), m);
 669                 $$->music_ = m;
 670
 671         }
 672         | SCORE_IDENTIFIER {
 673                 $$ = new Score ( *unsmob_score ($1));
 674                 $$->set_spot (THIS->here_input ());
 675         }
 676         | score_body lilypond_header    {
 677                 $$->header_ = $2;
 678         }
 679         | score_body output_def {
 680                 $$->defs_.push ($2);
 681                 scm_gc_unprotect_object ($2->self_scm ());
 682         }
 683         | score_body error {
 684
 685         }
 686         ;
 687
 688
 689 /*
 690         MIDI
 691 */
 692 output_def:
 693         music_output_def_body '}' {
 694                 $$ = $1;
 695                 THIS->lexer_->remove_scope ();
 696                 THIS->lexer_->pop_state ();
 697         }
 698         ;
 699
 700 music_output_def_head:
 701         MIDI    {
 702                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 703
 704
 705                 Midi_def *p = 0;
 706                 if (id)
 707                         p = dynamic_cast<Midi_def*> (id->clone ());
 708                 else
 709                         p = new Midi_def;
 710
 711                 $$ = p;
 712                 THIS->lexer_->add_scope (p->scope_);
 713         }
 714         | PAPER         {
 715                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 716                   Paper_def *p = 0;
 717                 if (id)
 718                         p = dynamic_cast<Paper_def*> (id->clone ());
 719                 else
 720                         p = new Paper_def;
 721
 722                 THIS->lexer_->add_scope (p->scope_);
 723                 $$ = p;
 724         }
 725         ;
 726
 727
 728 music_output_def_body:
 729         music_output_def_head '{' {
 730                 $$ = $1;
 731                 $$->input_origin_. set_spot (THIS->here_input ());
 732                 THIS->lexer_->push_initial_state ();
 733         }
 734         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 735                 scm_gc_unprotect_object ($1->self_scm ());
 736                 Music_output_def *o = unsmob_music_output_def ($3);
 737                 o->input_origin_.set_spot (THIS->here_input ());
 738                 $$ = o;
 739                 THIS->lexer_->remove_scope ();
 740                 THIS->lexer_->add_scope (o->scope_);
 741                 THIS->lexer_->push_initial_state ();
 742         }
 743         | music_output_def_body assignment  {
 744
 745         }
 746         | music_output_def_body context_def_spec_block  {
 747                 $$->assign_context_def ($2);
 748         }
 749         | music_output_def_body tempo_event  {
 750                 /*
 751                         junk this ? there already is tempo stuff in
 752                         music.
 753                 */
 754                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 755                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 756                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 757                 if (md)
 758                         md->set_tempo (d->get_length (), m);
 759                 scm_gc_unprotect_object ($2->self_scm ());
 760         }
 761         | music_output_def_body error {
 762
 763         }
 764         ;
 765
 766 tempo_event:
 767         TEMPO steno_duration '=' bare_unsigned  {
 768                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 769                 $$->set_property ("tempo-unit", $2);
 770                 $$->set_property ("metronome-count", scm_int2num ( $4));
 771         }
 772         ;
 773
 774 /*
 775 The representation of a  list is the
 776
 777   (LIST . LAST-CONS)
 778
 779  to have  efficient append.
 780 */
 781 Music_list:
 782         /* empty */ {
 783                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 784         }
 785         | Music_list Music {
 786                 SCM s = $$;
 787                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 788                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 789                 if (ly_c_pair_p (ly_cdr (s)))
 790                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 791                 else
 792                         scm_set_car_x (s, c); /* set first cons */
 793                 scm_set_cdr_x (s, c);  /* remember last cell */
 794         }
 795         | Music_list embedded_scm {
 796         }
 797         | Music_list error {
 798         }
 799         ;
 800
 801
 802 Music:
 803         Simple_music
 804         | Composite_music
 805         ;
 806
 807 Alternative_music:
 808         /* empty */ {
 809                 $$ = SCM_EOL;
 810         }
 811         | ALTERNATIVE '{' Music_list '}' {
 812                 $$ = $3;
 813         }
 814         ;
 815
 816
 817 Repeated_music:
 818         REPEAT simple_string bare_unsigned Music Alternative_music
 819         {
 820                 Music *beg = $4;
 821                 int times = $3;
 822                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 823                 if (times < scm_ilength (alts)) {
 824                   unsmob_music (ly_car (alts))
 825                     ->origin ()->warning (
 826                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 827                   alts = ly_truncate_list (times, alts);
 828                 }
 829
 830
 831                 SCM proc = ly_scheme_function ("make-repeated-music");
 832
 833                 SCM mus = scm_call_1 (proc, $2);
 834                 scm_gc_protect_object (mus); // UGH.
 835                 Music *r = unsmob_music (mus);
 836                 if (beg)
 837                         {
 838                         r-> set_property ("element", beg->self_scm ());
 839                         scm_gc_unprotect_object (beg->self_scm ());
 840                         }
 841                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 842
 843                 r-> set_property ("elements",alts);
 844                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 845                         /*
 846                         TODO: move this code to Scheme.
 847                         */
 848
 849                         /*
 850                         we can not get durations and other stuff correct down the line, so we have to
 851                         add to the duration log here.
 852                         */
 853                         SCM func = ly_scheme_function ("shift-duration-log");
 854
 855                         int dots = ($3 % 3) ? 0 : 1;
 856                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 857
 858                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 859
 860                         if (seq) {
 861                                 int list_len = scm_ilength (seq->music_list ());
 862                                 if (list_len != 2)
 863                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 864                                 shift -= 1;
 865                                 r->compress (Moment (Rational (1, list_len)));
 866                                 }
 867                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 868
 869                 }
 870                 r->set_spot (*$4->origin ());
 871
 872                 $$ = r;
 873         }
 874         ;
 875
 876 Sequential_music:
 877         SEQUENTIAL '{' Music_list '}'           {
 878                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 879                 $$->set_property ("elements", ly_car ($3));
 880                 $$->set_spot (THIS->here_input ());
 881         }
 882         | '{' Music_list '}'            {
 883                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 884                 $$->set_property ("elements", ly_car ($2));
 885                 $$->set_spot (THIS->here_input ());
 886         }
 887         ;
 888
 889 Simultaneous_music:
 890         SIMULTANEOUS '{' Music_list '}'{
 891                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 892                 $$->set_property ("elements", ly_car ($3));
 893                 $$->set_spot (THIS->here_input ());
 894
 895         }
 896         | simul_open Music_list simul_close     {
 897                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 898                 $$->set_property ("elements", ly_car ($2));
 899                 $$->set_spot (THIS->here_input ());
 900         }
 901         ;
 902
 903 Simple_music:
 904         event_chord             { $$ = $1; }
 905         | MUSIC_IDENTIFIER {
 906                 $$ = unsmob_music ($1);
 907         }
 908         | music_property_def
 909         | context_change
 910         ;
 911
 912
 913 optional_context_mod:
 914         /**/ { $$ = SCM_EOL; }
 915         | WITH { THIS->lexer_->push_initial_state (); }
 916         '{' context_mod_list '}'
 917         {
 918                 THIS->lexer_->pop_state ();
 919                 $$ = $4;
 920         }
 921         ;
 922
 923 context_mod_list:
 924         /* */  { $$ = SCM_EOL; }
 925         | context_mod_list context_mod  {
 926                  $$ = scm_cons ($2, $1);
 927         }
 928         ;
 929
 930
 931 Composite_music:
 932         Prefix_composite_music { $$ = $1; }
 933         | Grouped_music_list { $$ = $1; }
 934         ;
 935
 936 Grouped_music_list:
 937         Simultaneous_music              { $$ = $1; }
 938         | Sequential_music              { $$ = $1; }
 939         ;
 940
 941 Generic_prefix_music_scm:
 942         MUSIC_FUNCTION {
 943                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 944         }
 945         | MUSIC_FUNCTION_SCM {
 946                 THIS->push_spot ();
 947         } embedded_scm {
 948                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 949         }
 950         | MUSIC_FUNCTION_MUSIC {
 951                 THIS->push_spot ();
 952         } Music {
 953                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 954                 scm_gc_unprotect_object ($3->self_scm ());
 955         }
 956         | MUSIC_FUNCTION_SCM_MUSIC {
 957                 THIS->push_spot ();
 958         }  embedded_scm Music {
 959                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 960                 scm_gc_unprotect_object ($4->self_scm ());
 961         }
 962         | MUSIC_FUNCTION_MUSIC_MUSIC {
 963                 THIS->push_spot ();
 964         }  Music  Music {
 965                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 966                 scm_gc_unprotect_object ($3->self_scm ());
 967                 scm_gc_unprotect_object ($4->self_scm ());
 968         }
 969         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 970                 THIS->push_spot ();
 971         } embedded_scm Music Music {
 972                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
 973                         $3, $4->self_scm (), $5->self_scm ());
 974                 scm_gc_unprotect_object ($5->self_scm ());
 975                 scm_gc_unprotect_object ($4->self_scm ());
 976         }
 977         ;
 978
 979 Generic_prefix_music:
 980         Generic_prefix_music_scm {
 981                 SCM func = ly_car ($1);
 982                 Input *loc = unsmob_input (ly_cadr ($1));
 983                 SCM args = ly_cddr ($1);
 984                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
 985                 int k = 0;
 986                 bool ok  = true;
 987                 for (SCM s = sig, t = args;
 988                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
 989                         s = ly_cdr (s), t = ly_cdr (t)) {
 990                         k++;
 991                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
 992                         {
 993                                 loc->error (_f ("Argument %d failed typecheck", k));
 994                                 THIS->error_level_ = 1;
 995                                 ok = false;
 996                         }
 997                 }
 998                 SCM m = SCM_EOL;
 999                 if (ok)
1000                         m = scm_apply_0 (func, ly_cdr ($1));
1001                 if (unsmob_music (m))
1002                         {
1003                         $$ = unsmob_music (m);
1004                         scm_gc_protect_object (m);
1005                         }
1006                 else
1007                         {
1008                         if (ok)
1009                                 loc->error (_ ("Music head function should return Music object."));
1010                         $$ = MY_MAKE_MUSIC ("Music");
1011                         }
1012                 $$->set_spot (*loc);
1013         }
1014         ;
1015
1016
1017 Prefix_composite_music:
1018         Generic_prefix_music {
1019                 $$ = $1;
1020         }
1021         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1022                 $$ = context_spec_music ($2, $4, $6, $5);
1023
1024         }
1025         | CONTEXT simple_string optional_context_mod Music {
1026                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1027         }
1028         | NEWCONTEXT simple_string optional_context_mod Music {
1029                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1030                         $3);
1031         }
1032
1033         | TIMES {
1034                 THIS->push_spot ();
1035         }
1036         /* CONTINUED */
1037                 fraction Music
1038
1039         {
1040                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1041                 Music *mp = $4;
1042
1043                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1044                 $$->set_spot (THIS->pop_spot ());
1045
1046                 $$->set_property ("element", mp->self_scm ());
1047                 scm_gc_unprotect_object (mp->self_scm ());
1048                 $$->set_property ("numerator", scm_int2num (n));
1049                 $$->set_property ("denominator", scm_int2num (d));
1050                 $$->compress (Moment (Rational (n,d)));
1051
1052         }
1053         | Repeated_music                { $$ = $1; }
1054         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1055                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1056                 Music *p = $4;
1057                 Pitch from = *unsmob_pitch ($2);
1058                 Pitch to = *unsmob_pitch ($3);
1059
1060                 p->transpose (interval (from, to));
1061                 $$->set_property ("element", p->self_scm ());
1062                 scm_gc_unprotect_object (p->self_scm ());
1063         }
1064         | NOTES
1065                 {
1066                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1067                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1068         }
1069         Music
1070                 { $$ = $3;
1071                   THIS->lexer_->pop_state ();
1072                 }
1073         | DRUMS
1074                 {
1075                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1076                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1077         }
1078         /* FIXME: This used to be: */
1079         Music
1080 /*      Grouped_music_list */
1081                 { $$ = $3;
1082                   THIS->lexer_->pop_state ();
1083                 }
1084         | FIGURES
1085                 { THIS->lexer_->push_figuredbass_state (); }
1086         /* FIXME: This used to be:
1087         Music
1088         but that breaks web build
1089         */
1090         Grouped_music_list
1091                 {
1092                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1093                   chm->set_property ("element", $3->self_scm ());
1094                   $$ = chm;
1095                   scm_gc_unprotect_object ($3->self_scm ());
1096
1097                   THIS->lexer_->pop_state ();
1098         }
1099         | CHORDS {
1100                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1101                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1102                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1103                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1104
1105         }
1106         /* FIXME:
1107         Music
1108 */
1109         Grouped_music_list
1110         {
1111                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1112                   chm->set_property ("element", $3->self_scm ());
1113                   scm_gc_unprotect_object ($3->self_scm ());
1114                   $$ = chm;
1115
1116                   THIS->lexer_->pop_state ();
1117         }
1118         | LYRICS
1119                 { THIS->lexer_->push_lyric_state (); }
1120         /* FIXME:
1121         Music
1122 */
1123         Grouped_music_list
1124                 {
1125                   $$ = $3;
1126                   THIS->lexer_->pop_state ();
1127         }
1128         | relative_music        { $$ = $1; }
1129         | re_rhythmed_music     { $$ = $1; }
1130         | TAG embedded_scm Music {
1131                 tag_music ($3, $2, THIS->here_input ());
1132                 $$ = $3;
1133         }
1134         ;
1135
1136 relative_music:
1137         RELATIVE absolute_pitch Music {
1138                 Music *m = $3;
1139                 Pitch start = *unsmob_pitch ($2);
1140                 $$ = make_music_relative (start, m);
1141                 scm_gc_unprotect_object (m->self_scm ());
1142         }
1143         | RELATIVE Composite_music {
1144                 Music *m = $2;
1145                 /* FIXME: why is octave==0 and default not middleC? */
1146                 Pitch middle_c (-1, 0, 0);
1147                 $$ = make_music_relative (middle_c, m);
1148                 scm_gc_unprotect_object (m->self_scm ());
1149         }
1150         ;
1151
1152 new_lyrics:
1153         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1154         /*cont */
1155         Grouped_music_list {
1156         /* Can also use Music at the expensive of two S/Rs similar to
1157            \repeat \alternative */
1158                 THIS->lexer_->pop_state ();
1159 #if 0
1160                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1161                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1162                 $$ = music;
1163 #else
1164                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1165 #endif
1166         }
1167         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1168         Grouped_music_list {
1169                 THIS->lexer_->pop_state ();
1170                 $$ = scm_cons ($4->self_scm (), $1);
1171         }
1172         ;
1173
1174 re_rhythmed_music:
1175         Grouped_music_list new_lyrics {
1176
1177                 /* FIXME: should find out uniqueXXX name from music */
1178                 SCM name = $1->get_property ("context-id");
1179                 //if (name == SCM_EOL)
1180                 if (!ly_c_string_p (name))
1181                         name = scm_makfrom0str ("");
1182
1183                 SCM context = scm_makfrom0str ("Lyrics");
1184                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1185
1186                 SCM lst = SCM_EOL;
1187                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1188                 {
1189                         Music *music = unsmob_music (ly_car (s));
1190                         Music *com = make_lyric_combine_music (name, music);
1191                         Music *csm = context_spec_music (context,
1192                                 get_next_unique_context (), com, SCM_EOL);
1193                         lst = scm_cons (csm->self_scm (), lst);
1194                 }
1195                 /* FIXME: only first lyric music is accepted,
1196                           the rest is junked */
1197                 all->set_property ("elements", scm_cons ($1->self_scm (),
1198                         lst));
1199                 $$ = all;
1200                 scm_gc_unprotect_object ($1->self_scm ());
1201         }
1202         | LYRICSTO string Music {
1203                 Music *music = $3;
1204                 SCM name = $2;
1205                 $$ = make_lyric_combine_music (name, music);
1206                 scm_gc_unprotect_object (music->self_scm ());
1207         }
1208         ;
1209
1210 context_change:
1211         CHANGE STRING '=' STRING  {
1212                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1213                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1214                 t-> set_property ("change-to-id", $4);
1215
1216                 $$ = t;
1217                 $$->set_spot (THIS->here_input ());
1218         }
1219         ;
1220
1221 property_operation:
1222         STRING '=' scalar {
1223                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1224                         scm_string_to_symbol ($1), $3);
1225         }
1226         | UNSET simple_string {
1227                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1228                         scm_string_to_symbol ($2));
1229         }
1230         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1231                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1232                         scm_string_to_symbol ($2), $3, $5);
1233         }
1234         | REVERT simple_string embedded_scm {
1235                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1236                         scm_string_to_symbol ($2), $3);
1237         }
1238         ;
1239
1240 context_def_mod:
1241         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1242         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1243         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1244
1245         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1246         | DENIES { $$ = ly_symbol2scm ("denies"); }
1247
1248         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1249         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1250         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1251         | NAME { $$ = ly_symbol2scm ("context-name"); }
1252         ;
1253
1254 context_mod:
1255         property_operation { $$ = $1; }
1256         | context_def_mod STRING {
1257                 $$ = scm_list_2 ($1, $2);
1258         }
1259         ;
1260
1261 context_prop_spec:
1262         simple_string {
1263                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1264                         scm_string_to_symbol ($1));
1265         }
1266         | simple_string '.' simple_string {
1267                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1268                         scm_string_to_symbol ($3));
1269         }
1270         ;
1271
1272 music_property_def:
1273         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1274                 $$ = property_op_to_music (scm_list_4 (
1275                         ly_symbol2scm ("poppush"),
1276                         ly_cadr ($2),
1277                         $3, $5));
1278                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1279         }
1280         | REVERT context_prop_spec embedded_scm {
1281                 $$ = property_op_to_music (scm_list_3 (
1282                         ly_symbol2scm ("pop"),
1283                         ly_cadr ($2),
1284                         $3));
1285
1286                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1287         }
1288         | SET context_prop_spec '=' scalar {
1289                 $$ = property_op_to_music (scm_list_3 (
1290                         ly_symbol2scm ("assign"),
1291                         ly_cadr ($2),
1292                         $4));
1293                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1294         }
1295         | UNSET context_prop_spec {
1296                 $$ = property_op_to_music (scm_list_2 (
1297                         ly_symbol2scm ("unset"),
1298                         ly_cadr ($2)));
1299                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1300         }
1301         | ONCE music_property_def {
1302                 SCM e = $2->get_property ("element");
1303                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1304                 $$ = $2;
1305
1306         }
1307         ;
1308
1309
1310 string:
1311         STRING {
1312                 $$ = $1;
1313         }
1314         | STRING_IDENTIFIER {
1315                 $$ = $1;
1316         }
1317         | string '+' string {
1318                 $$ = scm_string_append (scm_list_2 ($1, $3));
1319         }
1320         ;
1321
1322 simple_string: STRING {
1323         }
1324         | LYRICS_STRING {
1325         }
1326         ;
1327
1328 scalar: string {
1329         }
1330         | LYRICS_STRING {
1331         }
1332         | bare_int {
1333                 $$ = scm_int2num ($1);
1334         }
1335         | embedded_scm {
1336         }
1337         | full_markup {
1338         }
1339         | DIGIT {
1340                 $$ = scm_int2num ($1);
1341         }
1342         ;
1343
1344 /*
1345 FIXME: remove or fix this comment.  What is `This'?
1346
1347 This is a trick:
1348
1349 Adding pre_events to the simple_element
1350 makes the choice between
1351
1352   string:  STRING
1353
1354 and
1355
1356   simple_element: STRING
1357
1358 a single shift/reduction conflict.
1359
1360 nevertheless, this is not very clean, and we should find a different
1361 solution.
1362
1363 */
1364 pre_events: {
1365                 THIS->push_spot ();
1366         }
1367         ;
1368
1369 event_chord:
1370         pre_events simple_element post_events   {
1371                 SCM elts = $2-> get_property ("elements");
1372
1373                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1374
1375                 $2->set_property ("elements", elts);
1376                 $$ = $2;
1377         }
1378         | command_element
1379         | note_chord_element
1380         ;
1381
1382
1383 note_chord_element:
1384         chord_body optional_notemode_duration post_events
1385         {
1386                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1387                 SCM es = $1->get_property ("elements");
1388                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1389
1390                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1391                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1392                 es = ly_append2 (es, postevs);
1393
1394                 $1-> set_property ("elements", es);
1395                 $$ = $1;
1396         }
1397         ;
1398
1399 chord_open: '<'
1400         ;
1401
1402 chord_close: '>'
1403         ;
1404
1405 simul_open: DOUBLE_ANGLE_OPEN
1406         ;
1407
1408 simul_close: DOUBLE_ANGLE_CLOSE
1409         ;
1410
1411 chord_body:
1412         chord_open chord_body_elements chord_close
1413         {
1414                 $$ = MY_MAKE_MUSIC ("EventChord");
1415                 $$->set_property ("elements",
1416                         scm_reverse_x ($2, SCM_EOL));
1417         }
1418         ;
1419
1420 chord_body_elements:
1421         /* empty */             { $$ = SCM_EOL; }
1422         | chord_body_elements chord_body_element {
1423                 $$ = scm_cons ($2->self_scm (), $1);
1424                 scm_gc_unprotect_object ($2->self_scm ());
1425         }
1426         ;
1427
1428 chord_body_element:
1429         pitch exclamations questions post_events
1430         {
1431                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1432                 n->set_property ("pitch", $1);
1433                 if ($3 % 2)
1434                         n->set_property ("cautionary", SCM_BOOL_T);
1435                 if ($2 % 2 || $3 % 2)
1436                         n->set_property ("force-accidental", SCM_BOOL_T);
1437
1438                 if (ly_c_pair_p ($4)) {
1439                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1440                         n->set_property ("articulations", arts);
1441                 }
1442                 $$ = n;
1443         }
1444         | DRUM_PITCH post_events {
1445                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1446                 n->set_property ("duration", $2);
1447                 n->set_property ("drum-type", $1);
1448                 n->set_spot (THIS->here_input ());
1449
1450                 if (ly_c_pair_p ($2)) {
1451                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1452                         n->set_property ("articulations", arts);
1453                 }
1454                 $$ = n;
1455         }
1456         ;
1457
1458 add_quote:
1459         ADDQUOTE string Music {
1460                 SCM adder = ly_scheme_function ("add-quotable");
1461
1462                 scm_call_2 (adder, $2, $3->self_scm ());
1463                 scm_gc_unprotect_object ($3->self_scm ());
1464         }
1465         ;
1466
1467 command_element:
1468         command_req {
1469                 $$ = MY_MAKE_MUSIC ("EventChord");
1470                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1471                 scm_gc_unprotect_object ($1->self_scm ());
1472
1473                 $$-> set_spot (THIS->here_input ());
1474                 $1-> set_spot (THIS->here_input ());
1475         }
1476         | SKIP duration_length {
1477                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1478                 skip->set_property ("duration", $2);
1479
1480                 $$ = skip;
1481         }
1482         | QUOTE STRING duration_length {
1483                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1484                 SCM evs = SCM_EOL;
1485                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1486                 {
1487                         SCM key = $2; // use symbol?
1488                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1489                 }
1490                 Music *quote = 0;
1491                 if (ly_c_vector_p (evs))
1492                 {
1493                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1494                         quote->set_property ("duration", $3);
1495                         quote->set_property ("quoted-events", evs);
1496                 } else {
1497                         THIS->here_input ().warning (_f ("Can\'t find music"));
1498                         quote = MY_MAKE_MUSIC ("Event");
1499                 }
1500                 quote->set_spot (THIS->here_input ());
1501                 $$ = quote;
1502         }
1503         | OCTAVE { THIS->push_spot (); }
1504           pitch {
1505                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1506                 $$ = m;
1507                 $$->set_spot (THIS->pop_spot ());
1508                 $$->set_property ("pitch", $3);
1509         }
1510         | E_LEFTSQUARE {
1511                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1512                 m->set_property ("span-direction", scm_int2num (START));
1513                 m->set_spot (THIS->here_input ());
1514
1515                 $$ = MY_MAKE_MUSIC ("EventChord");
1516                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1517                 scm_gc_unprotect_object (m->self_scm ());
1518                 $$->set_spot (THIS->here_input ());
1519         }
1520         | E_RIGHTSQUARE {
1521                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1522                 m->set_property ("span-direction", scm_int2num (STOP));
1523                 m->set_spot (THIS->here_input ());
1524
1525                 $$ = MY_MAKE_MUSIC ("EventChord");
1526                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1527                 $$->set_spot (THIS->here_input ());
1528                 scm_gc_unprotect_object (m->self_scm ());
1529         }
1530         | E_BACKSLASH {
1531                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1532                 $$->set_spot (THIS->here_input ());
1533         }
1534         | '|'      {
1535                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1536
1537                 if (Music * m = unsmob_music (pipe))
1538                         $$ = m->clone ();
1539                 else
1540                         $$ = MY_MAKE_MUSIC ("BarCheck");
1541
1542                 $$->set_spot (THIS->here_input ());
1543         }
1544         | TRANSPOSITION pitch {
1545                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1546                                         $2);
1547                 $$->set_spot (THIS-> here_input ());
1548                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1549                         $$, SCM_EOL);
1550         }
1551         | BAR STRING                    {
1552                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1553
1554                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1555                                         t, SCM_EOL);
1556                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1557                 $$->set_spot (THIS->here_input ());
1558                 t->set_spot (THIS->here_input ());
1559         }
1560         | PARTIAL duration_length       {
1561                 Moment m = - unsmob_duration ($2)->get_length ();
1562                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1563                 p->set_spot (THIS->here_input ());
1564                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1565                                         p, SCM_EOL);
1566                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1567                                         p, SCM_EOL);
1568                 $$ = p;
1569         }
1570         | CLEF STRING  {
1571                 SCM proc = ly_scheme_function ("make-clef-set");
1572
1573                 SCM result = scm_call_1 (proc, $2);
1574                 scm_gc_protect_object (result);
1575                 $$ = unsmob_music (result);
1576         }
1577         | TIME_T fraction  {
1578                 SCM proc= ly_scheme_function ("make-time-signature-set");
1579
1580                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1581                 scm_gc_protect_object (result);
1582                 $$ = unsmob_music (result);
1583         }
1584         | MARK scalar {
1585                 SCM proc = ly_scheme_function ("make-mark-set");
1586
1587                 SCM result = scm_call_1 (proc, $2);
1588                 scm_gc_protect_object (result);
1589                 $$ = unsmob_music (result);
1590         }
1591         ;
1592
1593 command_req:
1594         E_TILDE {
1595                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1596         }
1597         | MARK DEFAULT  {
1598                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1599                 $$ = m;
1600         }
1601         | tempo_event {
1602                 $$ = $1;
1603         }
1604         | KEY DEFAULT {
1605                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1606                 $$ = key;
1607         }
1608         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1609
1610                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1611                 if (scm_ilength ($3) > 0)
1612                 {
1613                         key->set_property ("pitch-alist", $3);
1614                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1615                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1616                 } else {
1617                         THIS->parser_error (_ ("Second argument must be pitch list."));
1618                 }
1619
1620                 $$ = key;
1621         }
1622         ;
1623
1624 post_events:
1625         /* empty */ {
1626                 $$ = SCM_EOL;
1627         }
1628         | post_events post_event {
1629                 $2->set_spot (THIS->here_input ());
1630                 $$ = scm_cons ($2->self_scm (), $$);
1631                 scm_gc_unprotect_object ($2->self_scm ());
1632         }
1633         | post_events tagged_post_event {
1634                 $2 -> set_spot (THIS->here_input ());
1635                 $$ = scm_cons ($2->self_scm (), $$);
1636                 scm_gc_unprotect_object ($2->self_scm ());
1637         }
1638         ;
1639
1640
1641 tagged_post_event:
1642         '-' TAG embedded_scm post_event {
1643                 tag_music ($4, $3, THIS->here_input ());
1644                 $$ = $4;
1645         }
1646         ;
1647
1648 post_event:
1649         direction_less_event {
1650                 $$ = $1;
1651         }
1652         | HYPHEN {
1653                 if (!THIS->lexer_->is_lyric_state ())
1654                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1655                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1656         }
1657         | EXTENDER {
1658                 if (!THIS->lexer_->is_lyric_state ())
1659                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1660                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1661         }
1662         | script_dir direction_reqd_event {
1663                 if ($1)
1664                         $2->set_property ("direction", scm_int2num ($1));
1665                 $$ = $2;
1666         }
1667         | script_dir direction_less_event {
1668                 if ($1)
1669                         $2->set_property ("direction", scm_int2num ($1));
1670                 $$ = $2;
1671         }
1672         | string_number_event
1673         ;
1674
1675 string_number_event:
1676         E_UNSIGNED {
1677                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1678                 s->set_property ("string-number", scm_int2num ($1));
1679                 s->set_spot (THIS->here_input ());
1680                 $$ = s;
1681         }
1682         ;
1683
1684
1685 direction_less_event:
1686         '['  {
1687
1688
1689 /*
1690
1691 TODO: should take all these defs out of the parser, adn make use
1692 configurable, i.e.
1693
1694
1695 (set-articulation '~ "trill")
1696
1697 */
1698                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1699                 m->set_spot (THIS->here_input ());
1700                 m->set_property ("span-direction", scm_int2num (START));
1701                 $$ = m;
1702         }
1703         | ']'  {
1704                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1705                 m->set_spot (THIS->here_input ());
1706                 m->set_property ("span-direction", scm_int2num (STOP));
1707                 $$ = m;
1708         }
1709         | '~' {
1710                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1711                 m->set_spot (THIS->here_input ());
1712                 $$ = m;
1713         }
1714         | close_event {
1715                 $$ = $1;
1716                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1717                         scm_int2num (START));
1718         }
1719         | open_event {
1720                 $$ = $1;
1721                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1722                         scm_int2num (STOP));
1723         }
1724         | EVENT_IDENTIFIER      {
1725                 $$ = unsmob_music ($1);
1726         }
1727         | tremolo_type  {
1728                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1729                a->set_spot (THIS->here_input ());
1730                a->set_property ("tremolo-type", scm_int2num ($1));
1731                $$ = a;
1732         }
1733         ;
1734
1735 direction_reqd_event:
1736         gen_text_def {
1737                 $$ = $1;
1738         }
1739         | script_abbreviation {
1740                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1741                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1742                 if (ly_c_string_p (s))
1743                         a->set_property ("articulation-type", s);
1744                 else THIS->parser_error (_ ("Expecting string as script definition"));
1745                 $$ = a;
1746         }
1747         ;
1748
1749 oct_check:
1750         /**/ { $$ = SCM_EOL; }
1751         | '='  { $$ = scm_int2num (0); }
1752         | '=' sub_quotes { $$ = scm_int2num ($2); }
1753         | '=' sup_quotes { $$ = scm_int2num ($2); }
1754         ;
1755
1756 sup_quotes:
1757         '\'' {
1758                 $$ = 1;
1759         }
1760         | sup_quotes '\'' {
1761                 $$ ++;
1762         }
1763         ;
1764
1765 sub_quotes:
1766         ',' {
1767                 $$ = 1;
1768         }
1769         | sub_quotes ',' {
1770                 $$++;
1771         }
1772         ;
1773
1774 steno_pitch:
1775         NOTENAME_PITCH  {
1776                 $$ = $1;
1777         }
1778         | NOTENAME_PITCH sup_quotes     {
1779                 Pitch p = *unsmob_pitch ($1);
1780                 p = p.transposed (Pitch ($2,0,0));
1781                 $$ = p.smobbed_copy ();
1782         }
1783         | NOTENAME_PITCH sub_quotes      {
1784                 Pitch p =* unsmob_pitch ($1);
1785                 p = p.transposed (Pitch (-$2,0,0));
1786                 $$ = p.smobbed_copy ();
1787         }
1788         ;
1789
1790 /*
1791 ugh. duplication
1792 */
1793
1794 steno_tonic_pitch:
1795         TONICNAME_PITCH {
1796                 $$ = $1;
1797         }
1798         | TONICNAME_PITCH sup_quotes    {
1799                 Pitch p = *unsmob_pitch ($1);
1800                 p = p.transposed (Pitch ($2,0,0));
1801                 $$ = p.smobbed_copy ();
1802         }
1803         | TONICNAME_PITCH sub_quotes     {
1804                 Pitch p =* unsmob_pitch ($1);
1805
1806                 p = p.transposed (Pitch (-$2,0,0));
1807                 $$ = p.smobbed_copy ();
1808         }
1809         ;
1810
1811 pitch:
1812         steno_pitch {
1813                 $$ = $1;
1814         }
1815         ;
1816
1817 pitch_also_in_chords:
1818         pitch
1819         | steno_tonic_pitch
1820         ;
1821
1822 close_event:
1823         '('     {
1824                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1825                 $$ = s;
1826                 s->set_spot (THIS->here_input ());
1827         }
1828         | E_OPEN        {
1829                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1830                 $$ = s;
1831                 s->set_spot (THIS->here_input ());
1832         }
1833         | E_SMALLER {
1834                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1835                 $$ = s;
1836                 s->set_spot (THIS->here_input ());
1837         }
1838         | E_BIGGER {
1839                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1840                 $$ = s;
1841                 s->set_spot (THIS->here_input ());
1842         }
1843         ;
1844
1845
1846 open_event:
1847         E_EXCLAMATION   {
1848                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1849                 s->set_spot (THIS->here_input ());
1850
1851                 $$ = s;
1852         }
1853         | ')'   {
1854                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1855                 $$ = s;
1856                 s->set_spot (THIS->here_input ());
1857
1858         }
1859         | E_CLOSE       {
1860                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1861                 $$ = s;
1862                 s->set_property ("span-type",
1863                         scm_makfrom0str ("phrasing-slur"));
1864                 s->set_spot (THIS->here_input ());
1865         }
1866         ;
1867
1868 gen_text_def:
1869         full_markup {
1870                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1871                 t->set_property ("text", $1);
1872                 t->set_spot (THIS->here_input ());
1873                 $$ = t;
1874         }
1875         | string {
1876                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1877                 t->set_property ("text",
1878                         make_simple_markup (THIS->lexer_->encoding (), $1));
1879                 t->set_spot (THIS->here_input ());
1880                 $$ = t;
1881
1882         }
1883         | DIGIT {
1884                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1885                 t->set_property ("digit", scm_int2num ($1));
1886                 t->set_spot (THIS->here_input ());
1887                 $$ = t;
1888         }
1889         ;
1890
1891 script_abbreviation:
1892         '^'             {
1893                 $$ = scm_makfrom0str ("Hat");
1894         }
1895         | '+'           {
1896                 $$ = scm_makfrom0str ("Plus");
1897         }
1898         | '-'           {
1899                 $$ = scm_makfrom0str ("Dash");
1900         }
1901         | '|'           {
1902                 $$ = scm_makfrom0str ("Bar");
1903         }
1904         | '>'           {
1905                 $$ = scm_makfrom0str ("Larger");
1906         }
1907         | '.'           {
1908                 $$ = scm_makfrom0str ("Dot");
1909         }
1910         | '_' {
1911                 $$ = scm_makfrom0str ("Underscore");
1912         }
1913         ;
1914
1915 script_dir:
1916         '_'     { $$ = DOWN; }
1917         | '^'   { $$ = UP; }
1918         | '-'   { $$ = CENTER; }
1919         ;
1920
1921
1922 absolute_pitch:
1923         steno_pitch     {
1924                 $$ = $1;
1925         }
1926         ;
1927
1928 duration_length:
1929         multiplied_duration {
1930                 $$ = $1;
1931         }
1932         ;
1933
1934 optional_notemode_duration:
1935         {
1936                 Duration dd = THIS->default_duration_;
1937                 $$ = dd.smobbed_copy ();
1938
1939                 THIS->beam_check ($$);
1940         }
1941         | multiplied_duration   {
1942                 $$ = $1;
1943                 THIS->default_duration_ = *unsmob_duration ($$);
1944
1945                 THIS->beam_check ($$);
1946         }
1947         ;
1948
1949 steno_duration:
1950         bare_unsigned dots              {
1951                 int len = 0;
1952                 if (!is_duration ($1))
1953                         THIS->parser_error (_f ("not a duration: %d", $1));
1954                 else
1955                         len = intlog2 ($1);
1956
1957                 $$ = Duration (len, $2).smobbed_copy ();
1958         }
1959         | DURATION_IDENTIFIER dots      {
1960                 Duration *d = unsmob_duration ($1);
1961                 Duration k (d->duration_log (), d->dot_count () + $2);
1962                 *d = k;
1963                 $$ = $1;
1964         }
1965         ;
1966
1967 multiplied_duration:
1968         steno_duration {
1969                 $$ = $1;
1970         }
1971         | multiplied_duration '*' bare_unsigned {
1972                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1973         }
1974         | multiplied_duration '*' FRACTION {
1975                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1976
1977                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1978         }
1979         ;
1980
1981 fraction:
1982         FRACTION { $$ = $1; }
1983         | UNSIGNED '/' UNSIGNED {
1984                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
1985         }
1986         ;
1987
1988 dots:
1989         /* empty */     {
1990                 $$ = 0;
1991         }
1992         | dots '.' {
1993                 $$ ++;
1994         }
1995         ;
1996
1997 tremolo_type:
1998         ':'     {
1999                 $$ = 0;
2000         }
2001         | ':' bare_unsigned {
2002                 if (!is_duration ($2))
2003                         THIS->parser_error (_f ("not a duration: %d", $2));
2004                 $$ = $2;
2005         }
2006         ;
2007
2008 bass_number:
2009         DIGIT   {
2010                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2011                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2012                                 $$);
2013         }
2014         | UNSIGNED {
2015                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2016                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2017                                 $$);
2018         }
2019         | STRING { $$ = $1; }
2020         ;
2021
2022 bass_mod:
2023         '-'     { $$ = -2; }
2024         | '+'   { $$ = 2; }
2025         | '!'   { $$ = 0; }
2026         ;
2027
2028 bass_figure:
2029         FIGURE_SPACE {
2030                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2031                 $$ = bfr->self_scm ();
2032                 scm_gc_unprotect_object ($$);
2033         }
2034         | bass_number  {
2035                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2036                 $$ = bfr->self_scm ();
2037
2038                 bfr->set_property ("figure", $1);
2039
2040                 scm_gc_unprotect_object ($$);
2041         }
2042         | bass_figure bass_mod {
2043                 Music *m = unsmob_music ($1);
2044                 if ($2) {
2045                         SCM salter = m->get_property ("alteration");
2046                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2047                         m->set_property ("alteration",
2048                                 scm_int2num (alter + $2));
2049                 } else {
2050                         m->set_property ("alteration", scm_int2num (0));
2051                 }
2052         }
2053         ;
2054
2055 br_bass_figure:
2056         '[' bass_figure {
2057                 $$ = $2;
2058                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2059         }
2060         | bass_figure   {
2061                 $$ = $1;
2062         }
2063         | br_bass_figure ']' {
2064                 $$ = $1;
2065                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2066         }
2067         ;
2068
2069 figure_list:
2070         /**/            {
2071                 $$ = SCM_EOL;
2072         }
2073         | figure_list br_bass_figure {
2074                 $$ = scm_cons ($2, $1);
2075         }
2076         ;
2077
2078 figure_spec:
2079         FIGURE_OPEN figure_list FIGURE_CLOSE {
2080                 Music *m = MY_MAKE_MUSIC ("EventChord");
2081                 $2 = scm_reverse_x ($2, SCM_EOL);
2082                 m->set_property ("elements", $2);
2083                 $$ = m->self_scm ();
2084         }
2085         ;
2086
2087
2088 optional_rest:
2089         /**/   { $$ = 0; }
2090         | REST { $$ = 1; }
2091         ;
2092
2093 simple_element:
2094         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2095
2096                 Input i = THIS->pop_spot ();
2097                 if (!THIS->lexer_->is_note_state ())
2098                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2099
2100                 Music *n = 0;
2101                 if ($6)
2102                         n = MY_MAKE_MUSIC ("RestEvent");
2103                 else
2104                         n = MY_MAKE_MUSIC ("NoteEvent");
2105
2106                 n->set_property ("pitch", $1);
2107                 n->set_property ("duration", $5);
2108
2109                 if (ly_c_number_p ($4))
2110                 {
2111                         int q = ly_scm2int ($4);
2112                         n->set_property ("absolute-octave", scm_int2num (q-1));
2113                 }
2114
2115                 if ($3 % 2)
2116                         n->set_property ("cautionary", SCM_BOOL_T);
2117                 if ($2 % 2 || $3 % 2)
2118                         n->set_property ("force-accidental", SCM_BOOL_T);
2119
2120                 Music *v = MY_MAKE_MUSIC ("EventChord");
2121                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2122                 scm_gc_unprotect_object (n->self_scm ());
2123
2124                 v->set_spot (i);
2125                 n->set_spot (i);
2126                 $$ = v;
2127         }
2128         | DRUM_PITCH optional_notemode_duration {
2129                 Input i = THIS->pop_spot ();
2130
2131                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2132                 n->set_property ("duration", $2);
2133                 n->set_property ("drum-type", $1);
2134
2135                 Music *v = MY_MAKE_MUSIC ("EventChord");
2136                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2137                 scm_gc_unprotect_object (n->self_scm ());
2138                 v->set_spot (i);
2139                 n->set_spot (i);
2140                 $$ = v;
2141
2142         }
2143         | figure_spec optional_notemode_duration {
2144                 Music *m = unsmob_music ($1);
2145                 Input i = THIS->pop_spot ();
2146                 m->set_spot (i);
2147                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2148                 {
2149                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2150                 }
2151                 $$ = m;
2152         }
2153         | RESTNAME optional_notemode_duration           {
2154
2155                 Input i = THIS->pop_spot ();
2156                 Music *ev = 0;
2157                 if (ly_scm2string ($1) == "s") {
2158                         /* Space */
2159                         ev = MY_MAKE_MUSIC ("SkipEvent");
2160                   }
2161                 else {
2162                         ev = MY_MAKE_MUSIC ("RestEvent");
2163
2164                     }
2165                 ev->set_property ("duration", $2);
2166                 ev->set_spot (i);
2167                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2168                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2169                 velt->set_spot (i);
2170
2171                 scm_gc_unprotect_object (ev->self_scm ());
2172
2173                 $$ = velt;
2174         }
2175         | MULTI_MEASURE_REST optional_notemode_duration         {
2176                 THIS->pop_spot ();
2177
2178                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2179                 SCM mus = scm_call_2 (proc, $2,
2180                         make_input (THIS->here_input ()));
2181                 scm_gc_protect_object (mus);
2182                 $$ = unsmob_music (mus);
2183         }
2184
2185         | lyric_element optional_notemode_duration      {
2186                 Input i = THIS->pop_spot ();
2187                 if (!THIS->lexer_->is_lyric_state ())
2188                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2189
2190                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2191                 lreq->set_property ("text", $1);
2192                 lreq->set_property ("duration",$2);
2193                 lreq->set_spot (i);
2194                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2195                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2196
2197                 $$= velt;
2198         }
2199         | new_chord {
2200                 THIS->pop_spot ();
2201
2202                 if (!THIS->lexer_->is_chord_state ())
2203                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2204                 $$ = unsmob_music ($1);
2205         }
2206         ;
2207
2208 lyric_element:
2209         /* FIXME: lyric flavoured markup would be better */
2210         full_markup {
2211         }
2212         | LYRICS_STRING {
2213         }
2214         ;
2215
2216 new_chord:
2217         steno_tonic_pitch optional_notemode_duration   {
2218                 $$ = make_chord ($1, $2, SCM_EOL);
2219         }
2220         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2221                 SCM its = scm_reverse_x ($4, SCM_EOL);
2222                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2223         }
2224         ;
2225
2226 chord_items:
2227         /**/ {
2228                 $$ = SCM_EOL;
2229         }
2230         | chord_items chord_item {
2231                 $$ = scm_cons ($2, $$);
2232         }
2233         ;
2234
2235 chord_separator:
2236         CHORD_COLON {
2237                 $$ = ly_symbol2scm ("chord-colon");
2238         }
2239         | CHORD_CARET {
2240                 $$ = ly_symbol2scm ("chord-caret");
2241         }
2242         | CHORD_SLASH steno_tonic_pitch {
2243                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2244         }
2245         | CHORD_BASS steno_tonic_pitch {
2246                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2247         }
2248         ;
2249
2250 chord_item:
2251         chord_separator {
2252                 $$ = $1;
2253         }
2254         | step_numbers {
2255                 $$ = scm_reverse_x ($1, SCM_EOL);
2256         }
2257         | CHORD_MODIFIER  {
2258                 $$ = $1;
2259         }
2260         ;
2261
2262 step_numbers:
2263         step_number { $$ = scm_cons ($1, SCM_EOL); }
2264         | step_numbers '.' step_number {
2265                 $$ = scm_cons ($3, $$);
2266         }
2267         ;
2268
2269 step_number:
2270         bare_unsigned {
2271                 $$ = make_chord_step ($1, 0);
2272         }
2273         | bare_unsigned '+' {
2274                 $$ = make_chord_step ($1, SHARP);
2275         }
2276         | bare_unsigned CHORD_MINUS {
2277                 $$ = make_chord_step ($1, FLAT);
2278         }
2279         ;
2280
2281 /*
2282         UTILITIES
2283
2284 TODO: should deprecate in favor of Scheme?
2285
2286  */
2287 number_expression:
2288         number_expression '+' number_term {
2289                 $$ = scm_sum ($1, $3);
2290         }
2291         | number_expression '-' number_term {
2292                 $$ = scm_difference ($1, $3);
2293         }
2294         | number_term
2295         ;
2296
2297 number_term:
2298         number_factor {
2299                 $$ = $1;
2300         }
2301         | number_factor '*' number_factor {
2302                 $$ = scm_product ($1, $3);
2303         }
2304         | number_factor '/' number_factor {
2305                 $$ = scm_divide ($1, $3);
2306         }
2307         ;
2308
2309 number_factor:
2310         '-'  number_factor { /* %prec UNARY_MINUS */
2311                 $$ = scm_difference ($2, SCM_UNDEFINED);
2312         }
2313         | bare_number
2314         ;
2315
2316
2317 bare_number:
2318         UNSIGNED        {
2319                 $$ = scm_int2num ($1);
2320         }
2321         | REAL          {
2322                 $$ = $1;
2323         }
2324         | NUMBER_IDENTIFIER             {
2325                 $$ = $1;
2326         }
2327         | REAL NUMBER_IDENTIFIER        {
2328                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2329         }
2330         | UNSIGNED NUMBER_IDENTIFIER    {
2331                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2332         }
2333         ;
2334
2335
2336 bare_unsigned:
2337         UNSIGNED {
2338                         $$ = $1;
2339         }
2340         | DIGIT {
2341                 $$ = $1;
2342         }
2343         ;
2344
2345 bare_int:
2346         bare_number {
2347                 if (scm_integer_p ($1) == SCM_BOOL_T)
2348                 {
2349                         int k = ly_scm2int ($1);
2350                         $$ = k;
2351                 } else
2352                 {
2353                         THIS->parser_error (_ ("need integer number arg"));
2354                         $$ = 0;
2355                 }
2356         }
2357         | '-' bare_int {
2358                 $$ = -$2;
2359         }
2360         ;
2361
2362 exclamations:
2363                 { $$ = 0; }
2364         | exclamations '!'      { $$ ++; }
2365         ;
2366
2367 questions:
2368                 { $$ = 0; }
2369         | questions '?' { $$ ++; }
2370         ;
2371
2372
2373
2374 full_markup:
2375         MARKUP_IDENTIFIER {
2376                 $$ = $1;
2377         }
2378         | MARKUP
2379                 { THIS->lexer_->push_markup_state (); }
2380         markup
2381                 { $$ = $3;
2382                   THIS->lexer_->pop_state ();
2383                 }
2384         ;
2385
2386
2387 /*
2388 This should be done more dynamically if possible.
2389 */
2390 markup:
2391         STRING {
2392                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2393         }
2394         | MARKUP_HEAD_EMPTY {
2395                 $$ = scm_list_1 ($1);
2396         }
2397         | MARKUP_HEAD_MARKUP0 markup {
2398                 $$ = scm_list_2 ($1, $2);
2399         }
2400         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2401                 $$ = scm_list_3 ($1, $2, $3);
2402         }
2403         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2404                 $$ = scm_list_3 ($1, $2, $3);
2405         }
2406         | markup_line {
2407                 $$ = $1;
2408         }
2409         | MARKUP_HEAD_LIST0 markup_list {
2410                 $$ = scm_list_2 ($1,$2);
2411         }
2412         | MARKUP_HEAD_SCM0 embedded_scm {
2413                 $$ = scm_list_2 ($1, $2);
2414         }
2415         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2416                 $$ = scm_list_4 ($1, $2, $3, $4);
2417         }
2418         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2419                 $$ = scm_list_4 ($1, $2, $3, $4);
2420         }
2421         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2422                 $$ = scm_list_3 ($1, $2, $3);
2423         }
2424         | MARKUP_IDENTIFIER {
2425                 $$ = $1;
2426         }
2427         | STRING_IDENTIFIER {
2428                 $$ = $1;
2429         }
2430         | {
2431                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2432                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2433         }
2434         /* cont */ score_block {
2435                 /* WIP this is a bit arbitrary,
2436                    we should also allow \book or Composite_music.
2437                    However, you'd typically want to change paper
2438                    settings, and need a \score block anyway.  */
2439
2440                 THIS->lexer_->pop_state ();
2441                 Score *score = $2;
2442                 Book *book = new Book;
2443                 book->scores_.push (score);
2444
2445                 Music_output_def *paper = get_paper (THIS);
2446                 SCM s = book->to_stencil (paper, THIS->header_);
2447                 scm_gc_unprotect_object (score->self_scm ());
2448                 scm_gc_unprotect_object (book->self_scm ());
2449                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2450         }
2451         ;
2452
2453 markup_list:
2454         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2455         ;
2456
2457 markup_line:
2458         '{' markup_list_body '}' {
2459                 SCM line = ly_scheme_function ("line-markup");
2460
2461                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2462         }
2463         ;
2464
2465 markup_list_body:
2466         /**/ {  $$ = SCM_EOL; }
2467         | markup_list_body markup {
2468                 $$ = scm_cons ($2, $1);
2469         }
2470         ;
2471
2472
2473 %%
2474
2475 void
2476 My_lily_parser::set_yydebug (bool )
2477 {
2478 #if 0
2479         yydebug = 1;
2480 #endif
2481 }
2482
2483 void
2484 My_lily_parser::do_yyparse ()
2485 {
2486         yyparse ((void*)this);
2487 }
2488
2489
2490 /*
2491 Should make this optional?    It will also complain when you do
2492
2493         [s4]
2494
2495 which is entirely legitimate.
2496
2497 Or we can scrap it. Barchecks should detect wrong durations, and
2498 skipTypesetting speeds it up a lot.
2499 */
2500
2501 void
2502 My_lily_parser::beam_check (SCM dur)
2503 {
2504   Duration *d = unsmob_duration (dur);
2505   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2506     {
2507       Music *m = unsmob_music (last_beam_start_);
2508       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2509     }
2510   last_beam_start_ = SCM_EOL;
2511 }
2512
2513
2514
2515
2516 /*
2517
2518 It is a little strange to have this function in this file, but
2519 otherwise, we have to import music classes into the lexer.
2520
2521 */
2522 int
2523 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2524 {
2525         if (ly_c_string_p (sid)) {
2526                 *destination = sid;
2527                 return STRING_IDENTIFIER;
2528         } else if (ly_c_number_p (sid)) {
2529                 *destination = sid;
2530                 return NUMBER_IDENTIFIER;
2531         } else if (unsmob_context_def (sid)) {
2532                 *destination = unsmob_context_def (sid)->clone_scm ();
2533                 return CONTEXT_DEF_IDENTIFIER;
2534         } else if (unsmob_score (sid)) {
2535                 Score *score = new Score (*unsmob_score (sid));
2536                 *destination = score->self_scm ();
2537                 return SCORE_IDENTIFIER;
2538         } else if (Music *mus = unsmob_music (sid)) {
2539                 mus = mus->clone ();
2540                 *destination = mus->self_scm ();
2541                 unsmob_music (*destination)->
2542                         set_property ("origin", make_input (last_input_));
2543                 return dynamic_cast<Event*> (mus)
2544                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2545         } else if (unsmob_duration (sid)) {
2546                 *destination = unsmob_duration (sid)->smobbed_copy ();
2547                 return DURATION_IDENTIFIER;
2548         } else if (unsmob_music_output_def (sid)) {
2549                 Music_output_def *p = unsmob_music_output_def (sid);
2550                 p = p->clone ();
2551
2552                 *destination = p->self_scm ();
2553                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2554         } else if (Text_item::markup_p (sid)) {
2555                 *destination = sid;
2556                 return MARKUP_IDENTIFIER;
2557         }
2558
2559         return -1;
2560 }
2561
2562 Music *
2563 property_op_to_music (SCM op)
2564 {
2565         Music *m = 0;
2566         SCM tag = ly_car (op);
2567         SCM symbol = ly_cadr (op);
2568         SCM args = ly_cddr (op);
2569         SCM grob_val = SCM_UNDEFINED;
2570         SCM grob_sym = SCM_UNDEFINED;
2571         SCM val = SCM_UNDEFINED;
2572
2573         if (tag == ly_symbol2scm ("assign"))
2574                 {
2575                 m = MY_MAKE_MUSIC ("PropertySet");
2576                 val = ly_car (args);
2577                 }
2578         else if (tag == ly_symbol2scm ("unset"))
2579                 m = MY_MAKE_MUSIC ("PropertyUnset");
2580         else if (tag == ly_symbol2scm ("poppush")
2581                  || tag == ly_symbol2scm ("push"))
2582                 {
2583                 m = MY_MAKE_MUSIC ("OverrideProperty");
2584                 grob_sym = ly_car (args);
2585                 grob_val = ly_cadr (args);
2586                 }
2587         else if (tag == ly_symbol2scm ("pop")) {
2588                 m = MY_MAKE_MUSIC ("RevertProperty");
2589                 grob_sym = ly_car (args);
2590                 }
2591
2592         m->set_property ("symbol", symbol);
2593
2594         if (val != SCM_UNDEFINED)
2595                 m->set_property ("value", val);
2596         if (grob_val != SCM_UNDEFINED)
2597                 m->set_property ("grob-value", grob_val);
2598
2599         if (grob_sym != SCM_UNDEFINED)
2600                 {
2601                 bool itc = internal_type_checking_global_b;
2602                 /* UGH.
2603                 */
2604                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2605                 if (autobeam)
2606                         internal_type_checking_global_b = false;
2607                 m->set_property ("grob-property", grob_sym);
2608                 if (autobeam)
2609                         internal_type_checking_global_b = itc;
2610                 }
2611
2612         if (tag == ly_symbol2scm ("poppush"))
2613                 m->set_property ("pop-first", SCM_BOOL_T);
2614
2615
2616         return m;
2617 }
2618
2619 Music*
2620 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2621 {
2622         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2623
2624         csm->set_property ("element", m->self_scm ());
2625         scm_gc_unprotect_object (m->self_scm ());
2626
2627         csm->set_property ("context-type",
2628                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2629         csm->set_property ("property-operations", ops);
2630
2631         if (ly_c_string_p (id))
2632                 csm->set_property ("context-id", id);
2633         return csm;
2634 }
2635
2636 SCM
2637 get_next_unique_context ()
2638 {
2639         static int new_context_count;
2640         char s[1024];
2641         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2642         return scm_makfrom0str (s);
2643 }
2644