lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLY
 251 %token APPLYCONTEXT
 252 %token APPLYOUTPUT
 253 %token AUTOCHANGE
 254 %token BAR
 255 %token BOOK
 256 %token BREATHE
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONSISTSEND
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 272 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 273 %token GRACE
 274 %token ACCIACCATURA
 275 %token APPOGGIATURA
 276 %token GROBDESCRIPTIONS
 277 %token HEADER
 278 %token HYPHEN
 279 %token INVALID
 280 %token KEY
 281 %token LYRICS
 282 %token LYRICS_STRING
 283 %token MARK
 284 %token MIDI
 285 %token MULTI_MEASURE_REST
 286 %token NAME
 287 %token NEWCONTEXT
 288 %token NOTES
 289 %token OCTAVE
 290 %token ONCE
 291 %token OVERRIDE SET REVERT
 292 %token PAPER
 293 %token PARTCOMBINE
 294 %token PARTIAL
 295 %token QUOTE
 296 %token RELATIVE
 297 %token REMOVE
 298 %token REPEAT
 299 %token REST
 300 %token SCM_T
 301 %token SCORE
 302 %token SEQUENTIAL
 303 %token NEWLYRICS
 304 %token SIMULTANEOUS
 305 %token SKIP
 306 %token SPANREQUEST
 307 %token TAG
 308 %token TEMPO
 309 %token TIMES
 310 %token TIME_T
 311 %token TRANSPOSE
 312 %token TRANSPOSITION
 313 %token TYPE
 314 %token UNSET
 315 %token WITH
 316
 317 /* escaped */
 318 /* FIXME: this sucks.  The user will get to see these names:
 319     syntax error, unexpected E_CHAR:
 320                 \
 321                  %%
 322   */
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token <i> E_UNSIGNED
 327 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 328 %token FIGURE_SPACE
 329
 330 %token <i>      DIGIT
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    TONICNAME_PITCH
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DURATION_IDENTIFIER
 335 %token <scm>    FRACTION
 336 %token <id>     IDENTIFIER
 337 %token DRUMS
 338 %token <scm>    DRUM_PITCH
 339 %token <scm>    CHORD_MODIFIER
 340 %token <scm>    SCORE_IDENTIFIER
 341 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 342 %token <scm>    NUMBER_IDENTIFIER
 343 %token <scm>    EVENT_IDENTIFIER
 344 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 345 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 346 %token <scm>    RESTNAME
 347 %token <scm>    STRING
 348 %token <scm>    SCM_T
 349 %token <i>      UNSIGNED
 350 %token <scm>   REAL
 351
 352 %token MARKUP
 353 %token <scm> MARKUP_HEAD_MARKUP0
 354 %token <scm> MARKUP_HEAD_EMPTY
 355 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0
 357 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1
 359 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 360 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 361
 362 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 363 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 364
 365 %type <book>    book_block book_body
 366 %type <i>       exclamations questions dots optional_rest
 367 %type <i>        bass_mod
 368 %type <scm>     grace_head
 369 %type <scm>     oct_check
 370 %type <scm>     context_mod_list
 371 %type <scm>     lyric_element
 372 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 373 %type <scm>     new_lyrics
 374 %type <outputdef> output_def
 375 %type <scm>     lilypond_header lilypond_header_body
 376 %type <music>   open_event close_event
 377 %type <i>       sub_quotes sup_quotes
 378 %type <music>   toplevel_music
 379 %type <music>   simple_element event_chord command_element
 380 %type <music>   Composite_music Simple_music Prefix_composite_music
 381 %type <music>   Grouped_music_list
 382 %type <music>   Repeated_music
 383 %type <scm>     Alternative_music
 384 %type <i>       tremolo_type
 385 %type <i>       bare_int  bare_unsigned
 386 %type <i>       script_dir
 387 %type <scm>     identifier_init
 388 %type <scm>     simple_string
 389
 390 %type <music>   note_chord_element chord_body chord_body_element
 391 %type <scm>     chord_body_elements
 392 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 393
 394 %type <scm>     post_events
 395 %type <music>   gen_text_def direction_less_event direction_reqd_event
 396 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 397 %type <scm>     steno_tonic_pitch
 398 %type <scm>     duration_length fraction
 399
 400 %type <scm>     chord_item chord_items chord_separator new_chord
 401 %type <scm>     step_number step_numbers
 402
 403 %type <scm>     embedded_scm scalar
 404 %type <music>   Music Sequential_music Simultaneous_music
 405 %type <music>   relative_music re_rhythmed_music
 406 %type <music>   music_property_def context_change
 407 %type <scm>     context_prop_spec
 408 %type <scm>     Music_list
 409 %type <scm>     property_operation
 410 %type <scm>     context_mod context_def_mod optional_context_mod
 411 %type <outputdef>       music_output_def_body music_output_def_head
 412 %type <music>   post_event tagged_post_event
 413 %type <music>   command_req
 414 %type <music>   string_number_event
 415 %type <scm>     string bare_number number_expression number_term number_factor
 416 %type <score>   score_block score_body
 417
 418 %type <scm>     context_def_spec_block context_def_spec_body
 419 %type <music>   tempo_event
 420 %type <scm>     script_abbreviation
 421
 422
 423
 424 %left '-' '+'
 425
 426 /* We don't assign precedence to / and *, because we might need varied
 427 prec levels in different prods */
 428
 429 %left UNARY_MINUS
 430
 431 %%
 432
 433 lilypond:       /* empty */
 434         | lilypond toplevel_expression {
 435         }
 436         | lilypond assignment {
 437         }
 438         | lilypond error {
 439                 THIS->error_level_ = 1;
 440         }
 441         | lilypond INVALID      {
 442                 THIS->error_level_ = 1;
 443         }
 444         ;
 445
 446 toplevel_expression:
 447         lilypond_header {
 448                 THIS->header_ = $1;
 449         }
 450         | add_quote {
 451
 452         }
 453         | book_block {
 454                 Book *book = $1;
 455                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 456                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 457                 scm_gc_unprotect_object (book->self_scm ());
 458         }
 459         | score_block {
 460                 Score *score = $1;
 461
 462                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 463                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 464                 scm_gc_unprotect_object (score->self_scm ());
 465         }
 466         | toplevel_music {
 467                 Music *music = $1;
 468                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 469                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 470                 scm_gc_unprotect_object (music->self_scm ());
 471         }
 472         | output_def {
 473                 SCM id = SCM_EOL;
 474                 if (dynamic_cast<Paper_def*> ($1))
 475                         id = scm_makfrom0str ("$defaultpaper");
 476                 else if (dynamic_cast<Midi_def*> ($1))
 477                         id = scm_makfrom0str ("$defaultmidi");
 478                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 479                 scm_gc_unprotect_object ($1->self_scm ());
 480         }
 481         ;
 482
 483 toplevel_music:
 484         Composite_music {
 485         }
 486         ;
 487
 488 embedded_scm:
 489         SCM_T
 490         | SCM_IDENTIFIER
 491         ;
 492
 493
 494 lilypond_header_body:
 495         {
 496                 $$ = ly_make_anonymous_module ();
 497                 THIS->lexer_->add_scope ($$);
 498         }
 499         | lilypond_header_body assignment  {
 500
 501         }
 502         ;
 503
 504 lilypond_header:
 505         HEADER '{' lilypond_header_body '}'     {
 506                 $$ = THIS->lexer_->remove_scope ();
 507         }
 508         ;
 509
 510
 511 /*
 512         DECLARATIONS
 513 */
 514 assignment:
 515         STRING {
 516                 THIS->push_spot ();
 517         }
 518         /* cont */ '=' identifier_init  {
 519
 520         /*
 521                 Should find generic way of associating input with objects.
 522         */
 523                 Input ip = THIS->pop_spot ();
 524
 525                 if (! is_regular_identifier ($1))
 526                 {
 527                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 528                 }
 529
 530                 THIS->lexer_->set_identifier ($1, $4);
 531
 532 /*
 533  TODO: devise standard for protection in parser.
 534
 535   The parser stack lives on the C-stack, which means that
 536 all objects can be unprotected as soon as they're here.
 537
 538 */
 539         }
 540         | embedded_scm { }
 541         ;
 542
 543
 544 identifier_init:
 545         score_block {
 546                 $$ = $1->self_scm ();
 547                 scm_gc_unprotect_object ($$);
 548         }
 549         | full_markup {
 550                 $$ = $1;
 551         }
 552         | output_def {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | context_def_spec_block {
 557                 $$ = $1;
 558         }
 559         | Music  {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | post_event {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | number_expression {
 568                 $$ = $1;
 569         }
 570         | string {
 571                 $$ = $1;
 572         }
 573         | embedded_scm  {
 574                 $$ = $1;
 575         }
 576         ;
 577
 578 context_def_spec_block:
 579         CONTEXT '{' context_def_spec_body '}'
 580                 {
 581                 $$ = $3;
 582         }
 583         ;
 584
 585 context_def_spec_body:
 586         /**/ {
 587                 $$ = Context_def::make_scm ();
 588                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 589         }
 590         | CONTEXT_DEF_IDENTIFIER {
 591                 $$ = $1;
 592                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 593         }
 594         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 595                 Context_def*td = unsmob_context_def ($$);
 596
 597                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 598                         SCM tag = ly_caar (p);
 599
 600                         /* TODO: should make new tag "grob-definition" ? */
 601                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 602                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 603                 }
 604         }
 605         | context_def_spec_body context_mod {
 606                 unsmob_context_def ($$)->add_context_mod ($2);
 607         }
 608         ;
 609
 610 book_block:
 611         BOOK {
 612                 THIS->push_spot ();
 613         }
 614         /*cont*/ '{' book_body '}'      {
 615                 THIS->pop_spot ();
 616                 $$ = $4;
 617         }
 618         ;
 619
 620 book_body:
 621         {
 622                 $$ = new Book;
 623                 $$->set_spot (THIS->here_input ());
 624         }
 625         | book_body score_block {
 626                 $$->scores_.push ($2);
 627                 scm_gc_unprotect_object ($2->self_scm ());
 628         }
 629         | book_body error {
 630         }
 631         ;
 632
 633 score_block:
 634         SCORE {
 635                 THIS->push_spot ();
 636         }
 637         /*cont*/ '{' score_body '}'     {
 638                 THIS->pop_spot ();
 639                 $$ = $4;
 640         }
 641         ;
 642
 643 score_body:
 644         Music   {
 645                 $$ = new Score;
 646
 647                 $$->set_spot (THIS->here_input ());
 648                 SCM m = $1->self_scm ();
 649                 scm_gc_unprotect_object (m);
 650
 651                 /*
 652                         guh.
 653                 */
 654                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 655                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 656                         m = scm_call_1 (ly_car (check_funcs), m);
 657                 $$->music_ = m;
 658
 659         }
 660         | SCORE_IDENTIFIER {
 661                 $$ = new Score ( *unsmob_score ($1));
 662                 $$->set_spot (THIS->here_input ());
 663         }
 664         | score_body lilypond_header    {
 665                 $$->header_ = $2;
 666         }
 667         | score_body output_def {
 668                 $$->defs_.push ($2);
 669                 scm_gc_unprotect_object ($2->self_scm ());
 670         }
 671         | score_body error {
 672
 673         }
 674         ;
 675
 676
 677 /*
 678         MIDI
 679 */
 680 output_def:
 681         music_output_def_body '}' {
 682                 $$ = $1;
 683                 THIS->lexer_->remove_scope ();
 684                 THIS->lexer_->pop_state ();
 685         }
 686         ;
 687
 688 music_output_def_head:
 689         MIDI    {
 690                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 691
 692
 693                 Midi_def *p = 0;
 694                 if (id)
 695                         p = dynamic_cast<Midi_def*> (id->clone ());
 696                 else
 697                         p = new Midi_def;
 698
 699                 $$ = p;
 700                 THIS->lexer_->add_scope (p->scope_);
 701         }
 702         | PAPER         {
 703                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 704                   Paper_def *p = 0;
 705                 if (id)
 706                         p = dynamic_cast<Paper_def*> (id->clone ());
 707                 else
 708                         p = new Paper_def;
 709
 710                 THIS->lexer_->add_scope (p->scope_);
 711                 $$ = p;
 712         }
 713         ;
 714
 715
 716 music_output_def_body:
 717         music_output_def_head '{' {
 718                 $$ = $1;
 719                 $$->input_origin_. set_spot (THIS->here_input ());
 720                 THIS->lexer_->push_initial_state ();
 721         }
 722         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 723                 scm_gc_unprotect_object ($1->self_scm ());
 724                 Music_output_def *o = unsmob_music_output_def ($3);
 725                 o->input_origin_.set_spot (THIS->here_input ());
 726                 $$ = o;
 727                 THIS->lexer_->remove_scope ();
 728                 THIS->lexer_->add_scope (o->scope_);
 729                 THIS->lexer_->push_initial_state ();
 730         }
 731         | music_output_def_body assignment  {
 732
 733         }
 734         | music_output_def_body context_def_spec_block  {
 735                 $$->assign_context_def ($2);
 736         }
 737         | music_output_def_body tempo_event  {
 738                 /*
 739                         junk this ? there already is tempo stuff in
 740                         music.
 741                 */
 742                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 743                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 744                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 745                 if (md)
 746                         md->set_tempo (d->get_length (), m);
 747                 scm_gc_unprotect_object ($2->self_scm ());
 748         }
 749         | music_output_def_body error {
 750
 751         }
 752         ;
 753
 754 tempo_event:
 755         TEMPO steno_duration '=' bare_unsigned  {
 756                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 757                 $$->set_property ("tempo-unit", $2);
 758                 $$->set_property ("metronome-count", scm_int2num ( $4));
 759         }
 760         ;
 761
 762 /*
 763 The representation of a  list is the
 764
 765   (LIST . LAST-CONS)
 766
 767  to have  efficient append.
 768 */
 769 Music_list:
 770         /* empty */ {
 771                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 772         }
 773         | Music_list Music {
 774                 SCM s = $$;
 775                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 776                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 777                 if (ly_c_pair_p (ly_cdr (s)))
 778                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 779                 else
 780                         scm_set_car_x (s, c); /* set first cons */
 781                 scm_set_cdr_x (s, c);  /* remember last cell */
 782         }
 783         | Music_list embedded_scm {
 784         }
 785         | Music_list error {
 786         }
 787         ;
 788
 789
 790 Music:
 791         Simple_music
 792         | Composite_music
 793         ;
 794
 795 Alternative_music:
 796         /* empty */ {
 797                 $$ = SCM_EOL;
 798         }
 799         | ALTERNATIVE '{' Music_list '}' {
 800                 $$ = $3;
 801         }
 802         ;
 803
 804
 805 Repeated_music:
 806         REPEAT simple_string bare_unsigned Music Alternative_music
 807         {
 808                 Music *beg = $4;
 809                 int times = $3;
 810                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 811                 if (times < scm_ilength (alts)) {
 812                   unsmob_music (ly_car (alts))
 813                     ->origin ()->warning (
 814                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 815                   alts = ly_truncate_list (times, alts);
 816                 }
 817
 818
 819                 SCM proc = ly_scheme_function ("make-repeated-music");
 820
 821                 SCM mus = scm_call_1 (proc, $2);
 822                 scm_gc_protect_object (mus); // UGH.
 823                 Music *r = unsmob_music (mus);
 824                 if (beg)
 825                         {
 826                         r-> set_property ("element", beg->self_scm ());
 827                         scm_gc_unprotect_object (beg->self_scm ());
 828                         }
 829                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 830
 831                 r-> set_property ("elements",alts);
 832                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 833                         /*
 834                         TODO: move this code to Scheme.
 835                         */
 836
 837                         /*
 838                         we can not get durations and other stuff correct down the line, so we have to
 839                         add to the duration log here.
 840                         */
 841                         SCM func = ly_scheme_function ("shift-duration-log");
 842
 843                         int dots = ($3 % 3) ? 0 : 1;
 844                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 845
 846                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 847
 848                         if (seq) {
 849                                 int list_len = scm_ilength (seq->music_list ());
 850                                 if (list_len != 2)
 851                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 852                                 shift -= 1;
 853                                 r->compress (Moment (Rational (1, list_len)));
 854                                 }
 855                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 856
 857                 }
 858                 r->set_spot (*$4->origin ());
 859
 860                 $$ = r;
 861         }
 862         ;
 863
 864 Sequential_music:
 865         SEQUENTIAL '{' Music_list '}'           {
 866                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 867                 $$->set_property ("elements", ly_car ($3));
 868                 $$->set_spot (THIS->here_input ());
 869         }
 870         | '{' Music_list '}'            {
 871                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 872                 $$->set_property ("elements", ly_car ($2));
 873                 $$->set_spot (THIS->here_input ());
 874         }
 875         ;
 876
 877 Simultaneous_music:
 878         SIMULTANEOUS '{' Music_list '}'{
 879                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 880                 $$->set_property ("elements", ly_car ($3));
 881                 $$->set_spot (THIS->here_input ());
 882
 883         }
 884         | simul_open Music_list simul_close     {
 885                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 886                 $$->set_property ("elements", ly_car ($2));
 887                 $$->set_spot (THIS->here_input ());
 888         }
 889         ;
 890
 891 Simple_music:
 892         event_chord             { $$ = $1; }
 893         | APPLYOUTPUT embedded_scm {
 894                 if (!ly_input_procedure_p ($2))
 895                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 896                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 897                 $$->set_property ("procedure", $2);
 898                 $$->set_spot (THIS->here_input ());
 899         }
 900         | APPLYCONTEXT embedded_scm {
 901                 if (!ly_input_procedure_p ($2))
 902                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 903                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 904                 $$->set_property ("procedure", $2);
 905                 $$->set_spot (THIS->here_input ());
 906         }
 907         | MUSIC_IDENTIFIER {
 908                 $$ = unsmob_music ($1);
 909         }
 910         | music_property_def
 911         | context_change
 912         ;
 913
 914
 915 optional_context_mod:
 916         /**/ { $$ = SCM_EOL; }
 917         | WITH { THIS->lexer_->push_initial_state (); }
 918         '{' context_mod_list '}'
 919         {
 920                 THIS->lexer_->pop_state ();
 921                 $$ = $4;
 922         }
 923         ;
 924
 925 grace_head:
 926         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 927         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 928         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 929         ;
 930
 931 context_mod_list:
 932         /* */  { $$ = SCM_EOL; }
 933         | context_mod_list context_mod  {
 934                  $$ = scm_cons ($2, $1);
 935         }
 936         ;
 937
 938
 939 Composite_music:
 940         Prefix_composite_music { $$ = $1; }
 941         | Grouped_music_list { $$ = $1; }
 942         ;
 943
 944 Grouped_music_list:
 945         Simultaneous_music              { $$ = $1; }
 946         | Sequential_music              { $$ = $1; }
 947         ;
 948
 949 Prefix_composite_music:
 950         AUTOCHANGE Music        {
 951                 SCM proc = ly_scheme_function ("make-autochange-music");
 952
 953                 SCM res = scm_call_1 (proc, $2->self_scm ());
 954                 scm_gc_unprotect_object ($2->self_scm ());
 955                 $$ = unsmob_music (res);
 956                 scm_gc_protect_object (res);
 957                 $$->set_spot (THIS->here_input ());
 958         }
 959         | PARTCOMBINE Music Music {
 960                 SCM proc = ly_scheme_function ("make-part-combine-music");
 961
 962                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 963                         $3->self_scm (), SCM_UNDEFINED));
 964                 scm_gc_unprotect_object ($3->self_scm ());
 965                 scm_gc_unprotect_object ($2->self_scm ());
 966                 $$ = unsmob_music (res);
 967                 scm_gc_protect_object (res);
 968                 $$->set_spot (THIS->here_input ());
 969         }
 970         | grace_head Music {
 971 #if 1
 972         /*
 973                 The other version is for easier debugging  of
 974                 Sequential_music_iterator in combination with grace notes.
 975         */
 976
 977 /*
 978
 979 TODO: should distinguish between both grace types in the
 980 basic music objects too, since the meaning is different.
 981
 982 */
 983
 984                 String start_str = "start" + ly_scm2string ($1) + "Music";
 985                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 986
 987                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 988                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 989
 990                 Music *startm = unsmob_music (start);
 991                 Music *stopm = unsmob_music (stop);
 992
 993                 SCM ms = SCM_EOL;
 994                 if (stopm) {
 995                         stopm = stopm->clone ();
 996                         ms = scm_cons (stopm->self_scm (), ms);
 997                         scm_gc_unprotect_object (stopm->self_scm ());
 998                 }
 999                 ms = scm_cons ($2->self_scm (), ms);
1000                 scm_gc_unprotect_object ($2->self_scm ());
1001                 if (startm) {
1002                         startm = startm->clone ();
1003                         ms = scm_cons (startm->self_scm (), ms);
1004                         scm_gc_unprotect_object (startm->self_scm ());
1005                 }
1006
1007                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1008                 seq->set_property ("elements", ms);
1009
1010
1011                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1012                 $$->set_property ("element", seq->self_scm ());
1013                 scm_gc_unprotect_object (seq->self_scm ());
1014 #else
1015                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1016                 $$->set_property ("element", $2->self_scm ());
1017                 scm_gc_unprotect_object ($2->self_scm ());
1018 #endif
1019         }
1020         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1021                 $$ = context_spec_music ($2, $4, $6, $5);
1022
1023         }
1024         | CONTEXT simple_string optional_context_mod Music {
1025                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1026         }
1027         | NEWCONTEXT simple_string optional_context_mod Music {
1028                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1029                         $3);
1030         }
1031
1032         | TIMES {
1033                 THIS->push_spot ();
1034         }
1035         /* CONTINUED */
1036                 fraction Music
1037
1038         {
1039                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1040                 Music *mp = $4;
1041
1042                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1043                 $$->set_spot (THIS->pop_spot ());
1044
1045                 $$->set_property ("element", mp->self_scm ());
1046                 scm_gc_unprotect_object (mp->self_scm ());
1047                 $$->set_property ("numerator", scm_int2num (n));
1048                 $$->set_property ("denominator", scm_int2num (d));
1049                 $$->compress (Moment (Rational (n,d)));
1050
1051         }
1052         | Repeated_music                { $$ = $1; }
1053         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1054                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1055                 Music *p = $4;
1056                 Pitch from = *unsmob_pitch ($2);
1057                 Pitch to = *unsmob_pitch ($3);
1058
1059                 p->transpose (interval (from, to));
1060                 $$->set_property ("element", p->self_scm ());
1061                 scm_gc_unprotect_object (p->self_scm ());
1062         }
1063         | APPLY embedded_scm Music  {
1064                 if (!ly_input_procedure_p ($2))
1065                         {
1066                         THIS->parser_error (_ ("\\apply takes function argument"));
1067                         $$ = $3;
1068                         }
1069                 else
1070                         {
1071                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1072                         Music *m = unsmob_music (ret);
1073                         if (!m) {
1074                                 THIS->parser_error ("\\apply must return a Music");
1075                                 m = MY_MAKE_MUSIC ("Music");
1076                                 }
1077                         $$ = m;
1078                         }
1079         }
1080         | NOTES
1081                 {
1082                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1083                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1084         }
1085         Music
1086                 { $$ = $3;
1087                   THIS->lexer_->pop_state ();
1088                 }
1089         | DRUMS
1090                 {
1091                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1092                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1093         }
1094         /* FIXME: This used to be: */
1095         Music
1096 /*      Grouped_music_list */
1097                 { $$ = $3;
1098                   THIS->lexer_->pop_state ();
1099                 }
1100         | FIGURES
1101                 { THIS->lexer_->push_figuredbass_state (); }
1102         /* FIXME: This used to be:
1103         Music
1104         but that breaks web build
1105         */
1106         Grouped_music_list
1107                 {
1108                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1109                   chm->set_property ("element", $3->self_scm ());
1110                   $$ = chm;
1111                   scm_gc_unprotect_object ($3->self_scm ());
1112
1113                   THIS->lexer_->pop_state ();
1114         }
1115         | CHORDS {
1116                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1117                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1118                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1119                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1120
1121         }
1122         /* FIXME:
1123         Music
1124 */
1125         Grouped_music_list
1126         {
1127                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1128                   chm->set_property ("element", $3->self_scm ());
1129                   scm_gc_unprotect_object ($3->self_scm ());
1130                   $$ = chm;
1131
1132                   THIS->lexer_->pop_state ();
1133         }
1134         | LYRICS
1135                 { THIS->lexer_->push_lyric_state (); }
1136         /* FIXME:
1137         Music
1138 */
1139         Grouped_music_list
1140                 {
1141                   $$ = $3;
1142                   THIS->lexer_->pop_state ();
1143         }
1144         | relative_music        { $$ = $1; }
1145         | re_rhythmed_music     { $$ = $1; }
1146         | TAG embedded_scm Music {
1147                 tag_music ($3, $2, THIS->here_input ());
1148                 $$ = $3;
1149         }
1150         ;
1151
1152 relative_music:
1153         RELATIVE absolute_pitch Music {
1154                 Music *m = $3;
1155                 Pitch start = *unsmob_pitch ($2);
1156                 $$ = make_music_relative (start, m);
1157                 scm_gc_unprotect_object (m->self_scm ());
1158         }
1159         | RELATIVE Composite_music {
1160                 Music *m = $2;
1161                 /* FIXME: why is octave==0 and default not middleC? */
1162                 Pitch middle_c (-1, 0, 0);
1163                 $$ = make_music_relative (middle_c, m);
1164                 scm_gc_unprotect_object (m->self_scm ());
1165         }
1166         ;
1167
1168 new_lyrics:
1169         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1170         /*cont */
1171         Grouped_music_list {
1172         /* Can also use Music at the expensive of two S/Rs similar to
1173            \repeat \alternative */
1174                 THIS->lexer_->pop_state ();
1175 #if 0
1176                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1177                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1178                 $$ = music;
1179 #else
1180                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1181 #endif
1182         }
1183         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1184         Grouped_music_list {
1185                 THIS->lexer_->pop_state ();
1186                 $$ = scm_cons ($4->self_scm (), $1);
1187         }
1188         ;
1189
1190 re_rhythmed_music:
1191         ADDLYRICS Music Music {
1192                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1193                 m->set_property ("elements", scm_listify ($2->self_scm (),
1194                         $3->self_scm (), SCM_UNDEFINED));
1195                 scm_gc_unprotect_object ($3->self_scm ());
1196                 scm_gc_unprotect_object ($2->self_scm ());
1197                 $$ = m;
1198         }
1199         | Grouped_music_list new_lyrics {
1200
1201                 /* FIXME: should find out uniqueXXX name from music */
1202                 SCM name = $1->get_property ("context-id");
1203                 //if (name == SCM_EOL)
1204                 if (!ly_c_string_p (name))
1205                         name = scm_makfrom0str ("");
1206
1207                 SCM context = scm_makfrom0str ("Lyrics");
1208                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1209
1210                 SCM lst = SCM_EOL;
1211                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1212                 {
1213                         Music *music = unsmob_music (ly_car (s));
1214                         Music *com = make_lyric_combine_music (name, music);
1215                         Music *csm = context_spec_music (context,
1216                                 get_next_unique_context (), com, SCM_EOL);
1217                         lst = scm_cons (csm->self_scm (), lst);
1218                 }
1219                 /* FIXME: only first lyric music is accepted,
1220                           the rest is junked */
1221                 all->set_property ("elements", scm_cons ($1->self_scm (),
1222                         lst));
1223                 $$ = all;
1224                 scm_gc_unprotect_object ($1->self_scm ());
1225         }
1226         | LYRICSTO string Music {
1227                 Music *music = $3;
1228                 SCM name = $2;
1229                 $$ = make_lyric_combine_music (name, music);
1230                 scm_gc_unprotect_object (music->self_scm ());
1231         }
1232         ;
1233
1234 context_change:
1235         CHANGE STRING '=' STRING  {
1236                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1237                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1238                 t-> set_property ("change-to-id", $4);
1239
1240                 $$ = t;
1241                 $$->set_spot (THIS->here_input ());
1242         }
1243         ;
1244
1245 property_operation:
1246         STRING '=' scalar {
1247                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1248                         scm_string_to_symbol ($1), $3);
1249         }
1250         | UNSET simple_string {
1251                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1252                         scm_string_to_symbol ($2));
1253         }
1254         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1255                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1256                         scm_string_to_symbol ($2), $3, $5);
1257         }
1258         | REVERT simple_string embedded_scm {
1259                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1260                         scm_string_to_symbol ($2), $3);
1261         }
1262         ;
1263
1264 context_def_mod:
1265         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1266         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1267         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1268
1269         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1270         | DENIES { $$ = ly_symbol2scm ("denies"); }
1271
1272         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1273         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1274         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1275         | NAME { $$ = ly_symbol2scm ("context-name"); }
1276         ;
1277
1278 context_mod:
1279         property_operation { $$ = $1; }
1280         | context_def_mod STRING {
1281                 $$ = scm_list_2 ($1, $2);
1282         }
1283         ;
1284
1285 context_prop_spec:
1286         simple_string {
1287                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1288                         scm_string_to_symbol ($1));
1289         }
1290         | simple_string '.' simple_string {
1291                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1292                         scm_string_to_symbol ($3));
1293         }
1294         ;
1295
1296 music_property_def:
1297         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1298                 $$ = property_op_to_music (scm_list_4 (
1299                         ly_symbol2scm ("poppush"),
1300                         ly_cadr ($2),
1301                         $3, $5));
1302                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1303         }
1304         | REVERT context_prop_spec embedded_scm {
1305                 $$ = property_op_to_music (scm_list_3 (
1306                         ly_symbol2scm ("pop"),
1307                         ly_cadr ($2),
1308                         $3));
1309
1310                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1311         }
1312         | SET context_prop_spec '=' scalar {
1313                 $$ = property_op_to_music (scm_list_3 (
1314                         ly_symbol2scm ("assign"),
1315                         ly_cadr ($2),
1316                         $4));
1317                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1318         }
1319         | UNSET context_prop_spec {
1320                 $$ = property_op_to_music (scm_list_2 (
1321                         ly_symbol2scm ("unset"),
1322                         ly_cadr ($2)));
1323                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1324         }
1325         | ONCE music_property_def {
1326                 SCM e = $2->get_property ("element");
1327                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1328                 $$ = $2;
1329
1330         }
1331         ;
1332
1333
1334 string:
1335         STRING {
1336                 $$ = $1;
1337         }
1338         | STRING_IDENTIFIER {
1339                 $$ = $1;
1340         }
1341         | string '+' string {
1342                 $$ = scm_string_append (scm_list_2 ($1, $3));
1343         }
1344         ;
1345
1346 simple_string: STRING {
1347         }
1348         | LYRICS_STRING {
1349         }
1350         ;
1351
1352 scalar: string {
1353         }
1354         | LYRICS_STRING {
1355         }
1356         | bare_int {
1357                 $$ = scm_int2num ($1);
1358         }
1359         | embedded_scm {
1360         }
1361         | full_markup {
1362         }
1363         | DIGIT {
1364                 $$ = scm_int2num ($1);
1365         }
1366         ;
1367
1368 /*
1369 FIXME: remove or fix this comment.  What is `This'?
1370
1371 This is a trick:
1372
1373 Adding pre_events to the simple_element
1374 makes the choice between
1375
1376   string:  STRING
1377
1378 and
1379
1380   simple_element: STRING
1381
1382 a single shift/reduction conflict.
1383
1384 nevertheless, this is not very clean, and we should find a different
1385 solution.
1386
1387 */
1388 pre_events: {
1389                 THIS->push_spot ();
1390         }
1391         ;
1392
1393 event_chord:
1394         pre_events simple_element post_events   {
1395                 SCM elts = $2-> get_property ("elements");
1396
1397                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1398
1399                 $2->set_property ("elements", elts);
1400                 $$ = $2;
1401         }
1402         | command_element
1403         | note_chord_element
1404         ;
1405
1406
1407 note_chord_element:
1408         chord_body optional_notemode_duration post_events
1409         {
1410                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1411                 SCM es = $1->get_property ("elements");
1412                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1413
1414                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1415                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1416                 es = ly_append2 (es, postevs);
1417
1418                 $1-> set_property ("elements", es);
1419                 $$ = $1;
1420         }
1421         ;
1422
1423 chord_open: '<'
1424         ;
1425
1426 chord_close: '>'
1427         ;
1428
1429 simul_open: DOUBLE_ANGLE_OPEN
1430         ;
1431
1432 simul_close: DOUBLE_ANGLE_CLOSE
1433         ;
1434
1435 chord_body:
1436         chord_open chord_body_elements chord_close
1437         {
1438                 $$ = MY_MAKE_MUSIC ("EventChord");
1439                 $$->set_property ("elements",
1440                         scm_reverse_x ($2, SCM_EOL));
1441         }
1442         ;
1443
1444 chord_body_elements:
1445         /* empty */             { $$ = SCM_EOL; }
1446         | chord_body_elements chord_body_element {
1447                 $$ = scm_cons ($2->self_scm (), $1);
1448                 scm_gc_unprotect_object ($2->self_scm ());
1449         }
1450         ;
1451
1452 chord_body_element:
1453         pitch exclamations questions post_events
1454         {
1455                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1456                 n->set_property ("pitch", $1);
1457                 if ($3 % 2)
1458                         n->set_property ("cautionary", SCM_BOOL_T);
1459                 if ($2 % 2 || $3 % 2)
1460                         n->set_property ("force-accidental", SCM_BOOL_T);
1461
1462                 if (ly_c_pair_p ($4)) {
1463                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1464                         n->set_property ("articulations", arts);
1465                 }
1466                 $$ = n;
1467         }
1468         | DRUM_PITCH post_events {
1469                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1470                 n->set_property ("duration", $2);
1471                 n->set_property ("drum-type", $1);
1472                 n->set_spot (THIS->here_input ());
1473
1474                 if (ly_c_pair_p ($2)) {
1475                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1476                         n->set_property ("articulations", arts);
1477                 }
1478                 $$ = n;
1479         }
1480         ;
1481
1482 add_quote:
1483         ADDQUOTE string Music {
1484                 SCM adder = ly_scheme_function ("add-quotable");
1485
1486                 scm_call_2 (adder, $2, $3->self_scm ());
1487                 scm_gc_unprotect_object ($3->self_scm ());
1488         }
1489         ;
1490
1491 command_element:
1492         command_req {
1493                 $$ = MY_MAKE_MUSIC ("EventChord");
1494                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1495                 scm_gc_unprotect_object ($1->self_scm ());
1496
1497                 $$-> set_spot (THIS->here_input ());
1498                 $1-> set_spot (THIS->here_input ());
1499         }
1500         | SKIP duration_length {
1501                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1502                 skip->set_property ("duration", $2);
1503
1504                 $$ = skip;
1505         }
1506         | QUOTE STRING duration_length {
1507                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1508                 SCM evs = SCM_EOL;
1509                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1510                 {
1511                         SCM key = $2; // use symbol?
1512                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1513                 }
1514                 Music *quote = 0;
1515                 if (ly_c_vector_p (evs))
1516                 {
1517                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1518                         quote->set_property ("duration", $3);
1519                         quote->set_property ("quoted-events", evs);
1520                 } else {
1521                         THIS->here_input ().warning (_f ("Can\'t find music"));
1522                         quote = MY_MAKE_MUSIC ("Event");
1523                 }
1524                 quote->set_spot (THIS->here_input ());
1525                 $$ = quote;
1526         }
1527         | OCTAVE { THIS->push_spot (); }
1528           pitch {
1529                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1530                 $$ = m;
1531                 $$->set_spot (THIS->pop_spot ());
1532                 $$->set_property ("pitch", $3);
1533         }
1534         | E_LEFTSQUARE {
1535                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1536                 m->set_property ("span-direction", scm_int2num (START));
1537                 m->set_spot (THIS->here_input ());
1538
1539                 $$ = MY_MAKE_MUSIC ("EventChord");
1540                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1541                 scm_gc_unprotect_object (m->self_scm ());
1542                 $$->set_spot (THIS->here_input ());
1543         }
1544         | E_RIGHTSQUARE {
1545                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1546                 m->set_property ("span-direction", scm_int2num (STOP));
1547                 m->set_spot (THIS->here_input ());
1548
1549                 $$ = MY_MAKE_MUSIC ("EventChord");
1550                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1551                 $$->set_spot (THIS->here_input ());
1552                 scm_gc_unprotect_object (m->self_scm ());
1553         }
1554         | E_BACKSLASH {
1555                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1556                 $$->set_spot (THIS->here_input ());
1557         }
1558         | '|'      {
1559                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1560
1561                 if (Music * m = unsmob_music (pipe))
1562                         $$ = m->clone ();
1563                 else
1564                         $$ = MY_MAKE_MUSIC ("BarCheck");
1565
1566                 $$->set_spot (THIS->here_input ());
1567         }
1568         | TRANSPOSITION pitch {
1569                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1570                                         $2);
1571                 $$->set_spot (THIS-> here_input ());
1572                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1573                         $$, SCM_EOL);
1574         }
1575         | BAR STRING                    {
1576                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1577
1578                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1579                                         t, SCM_EOL);
1580                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1581                 $$->set_spot (THIS->here_input ());
1582                 t->set_spot (THIS->here_input ());
1583         }
1584         | PARTIAL duration_length       {
1585                 Moment m = - unsmob_duration ($2)->get_length ();
1586                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1587                 p->set_spot (THIS->here_input ());
1588                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1589                                         p, SCM_EOL);
1590                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1591                                         p, SCM_EOL);
1592                 $$ = p;
1593         }
1594         | CLEF STRING  {
1595                 SCM proc = ly_scheme_function ("make-clef-set");
1596
1597                 SCM result = scm_call_1 (proc, $2);
1598                 scm_gc_protect_object (result);
1599                 $$ = unsmob_music (result);
1600         }
1601         | TIME_T fraction  {
1602                 SCM proc= ly_scheme_function ("make-time-signature-set");
1603
1604                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1605                 scm_gc_protect_object (result);
1606                 $$ = unsmob_music (result);
1607         }
1608         | MARK scalar {
1609                 SCM proc = ly_scheme_function ("make-mark-set");
1610
1611                 SCM result = scm_call_1 (proc, $2);
1612                 scm_gc_protect_object (result);
1613                 $$ = unsmob_music (result);
1614         }
1615         ;
1616
1617 command_req:
1618         BREATHE {
1619                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1620         }
1621         | E_TILDE {
1622                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1623         }
1624         | MARK DEFAULT  {
1625                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1626                 $$ = m;
1627         }
1628         | tempo_event {
1629                 $$ = $1;
1630         }
1631         | KEY DEFAULT {
1632                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1633                 $$ = key;
1634         }
1635         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1636
1637                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1638                 if (scm_ilength ($3) > 0)
1639                 {
1640                         key->set_property ("pitch-alist", $3);
1641                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1642                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1643                 } else {
1644                         THIS->parser_error (_ ("Second argument must be pitch list."));
1645                 }
1646
1647                 $$ = key;
1648         }
1649         ;
1650
1651 post_events:
1652         /* empty */ {
1653                 $$ = SCM_EOL;
1654         }
1655         | post_events post_event {
1656                 $2->set_spot (THIS->here_input ());
1657                 $$ = scm_cons ($2->self_scm (), $$);
1658                 scm_gc_unprotect_object ($2->self_scm ());
1659         }
1660         | post_events tagged_post_event {
1661                 $2 -> set_spot (THIS->here_input ());
1662                 $$ = scm_cons ($2->self_scm (), $$);
1663                 scm_gc_unprotect_object ($2->self_scm ());
1664         }
1665         ;
1666
1667
1668 tagged_post_event:
1669         '-' TAG embedded_scm post_event {
1670                 tag_music ($4, $3, THIS->here_input ());
1671                 $$ = $4;
1672         }
1673         ;
1674
1675 post_event:
1676         direction_less_event {
1677                 $$ = $1;
1678         }
1679         | HYPHEN {
1680                 if (!THIS->lexer_->is_lyric_state ())
1681                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1682                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1683         }
1684         | EXTENDER {
1685                 if (!THIS->lexer_->is_lyric_state ())
1686                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1687                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1688         }
1689         | script_dir direction_reqd_event {
1690                 if ($1)
1691                         $2->set_property ("direction", scm_int2num ($1));
1692                 $$ = $2;
1693         }
1694         | script_dir direction_less_event {
1695                 if ($1)
1696                         $2->set_property ("direction", scm_int2num ($1));
1697                 $$ = $2;
1698         }
1699         | string_number_event
1700         ;
1701
1702 string_number_event:
1703         E_UNSIGNED {
1704                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1705                 s->set_property ("string-number", scm_int2num ($1));
1706                 s->set_spot (THIS->here_input ());
1707                 $$ = s;
1708         }
1709         ;
1710
1711
1712 direction_less_event:
1713         '['  {
1714
1715
1716 /*
1717
1718 TODO: should take all these defs out of the parser, adn make use
1719 configurable, i.e.
1720
1721
1722 (set-articulation '~ "trill")
1723
1724 */
1725                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1726                 m->set_spot (THIS->here_input ());
1727                 m->set_property ("span-direction", scm_int2num (START));
1728                 $$ = m;
1729         }
1730         | ']'  {
1731                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1732                 m->set_spot (THIS->here_input ());
1733                 m->set_property ("span-direction", scm_int2num (STOP));
1734                 $$ = m;
1735         }
1736         | '~' {
1737                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1738                 m->set_spot (THIS->here_input ());
1739                 $$ = m;
1740         }
1741         | close_event {
1742                 $$ = $1;
1743                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1744                         scm_int2num (START));
1745         }
1746         | open_event {
1747                 $$ = $1;
1748                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1749                         scm_int2num (STOP));
1750         }
1751         | EVENT_IDENTIFIER      {
1752                 $$ = unsmob_music ($1);
1753         }
1754         | tremolo_type  {
1755                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1756                a->set_spot (THIS->here_input ());
1757                a->set_property ("tremolo-type", scm_int2num ($1));
1758                $$ = a;
1759         }
1760         ;
1761
1762 direction_reqd_event:
1763         gen_text_def {
1764                 $$ = $1;
1765         }
1766         | script_abbreviation {
1767                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1768                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1769                 if (ly_c_string_p (s))
1770                         a->set_property ("articulation-type", s);
1771                 else THIS->parser_error (_ ("Expecting string as script definition"));
1772                 $$ = a;
1773         }
1774         ;
1775
1776 oct_check:
1777         /**/ { $$ = SCM_EOL; }
1778         | '='  { $$ = scm_int2num (0); }
1779         | '=' sub_quotes { $$ = scm_int2num ($2); }
1780         | '=' sup_quotes { $$ = scm_int2num ($2); }
1781         ;
1782
1783 sup_quotes:
1784         '\'' {
1785                 $$ = 1;
1786         }
1787         | sup_quotes '\'' {
1788                 $$ ++;
1789         }
1790         ;
1791
1792 sub_quotes:
1793         ',' {
1794                 $$ = 1;
1795         }
1796         | sub_quotes ',' {
1797                 $$++;
1798         }
1799         ;
1800
1801 steno_pitch:
1802         NOTENAME_PITCH  {
1803                 $$ = $1;
1804         }
1805         | NOTENAME_PITCH sup_quotes     {
1806                 Pitch p = *unsmob_pitch ($1);
1807                 p = p.transposed (Pitch ($2,0,0));
1808                 $$ = p.smobbed_copy ();
1809         }
1810         | NOTENAME_PITCH sub_quotes      {
1811                 Pitch p =* unsmob_pitch ($1);
1812                 p = p.transposed (Pitch (-$2,0,0));
1813                 $$ = p.smobbed_copy ();
1814         }
1815         ;
1816
1817 /*
1818 ugh. duplication
1819 */
1820
1821 steno_tonic_pitch:
1822         TONICNAME_PITCH {
1823                 $$ = $1;
1824         }
1825         | TONICNAME_PITCH sup_quotes    {
1826                 Pitch p = *unsmob_pitch ($1);
1827                 p = p.transposed (Pitch ($2,0,0));
1828                 $$ = p.smobbed_copy ();
1829         }
1830         | TONICNAME_PITCH sub_quotes     {
1831                 Pitch p =* unsmob_pitch ($1);
1832
1833                 p = p.transposed (Pitch (-$2,0,0));
1834                 $$ = p.smobbed_copy ();
1835         }
1836         ;
1837
1838 pitch:
1839         steno_pitch {
1840                 $$ = $1;
1841         }
1842         ;
1843
1844 pitch_also_in_chords:
1845         pitch
1846         | steno_tonic_pitch
1847         ;
1848
1849 close_event:
1850         '('     {
1851                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1852                 $$ = s;
1853                 s->set_spot (THIS->here_input ());
1854         }
1855         | E_OPEN        {
1856                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1857                 $$ = s;
1858                 s->set_spot (THIS->here_input ());
1859         }
1860         | E_SMALLER {
1861                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1862                 $$ = s;
1863                 s->set_spot (THIS->here_input ());
1864         }
1865         | E_BIGGER {
1866                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1867                 $$ = s;
1868                 s->set_spot (THIS->here_input ());
1869         }
1870         ;
1871
1872
1873 open_event:
1874         E_EXCLAMATION   {
1875                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1876                 s->set_spot (THIS->here_input ());
1877
1878                 $$ = s;
1879         }
1880         | ')'   {
1881                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1882                 $$ = s;
1883                 s->set_spot (THIS->here_input ());
1884
1885         }
1886         | E_CLOSE       {
1887                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1888                 $$ = s;
1889                 s->set_property ("span-type",
1890                         scm_makfrom0str ("phrasing-slur"));
1891                 s->set_spot (THIS->here_input ());
1892         }
1893         ;
1894
1895 gen_text_def:
1896         full_markup {
1897                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1898                 t->set_property ("text", $1);
1899                 t->set_spot (THIS->here_input ());
1900                 $$ = t;
1901         }
1902         | string {
1903                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1904                 t->set_property ("text",
1905                         make_simple_markup (THIS->lexer_->encoding (), $1));
1906                 t->set_spot (THIS->here_input ());
1907                 $$ = t;
1908
1909         }
1910         | DIGIT {
1911                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1912                 t->set_property ("digit", scm_int2num ($1));
1913                 t->set_spot (THIS->here_input ());
1914                 $$ = t;
1915         }
1916         ;
1917
1918 script_abbreviation:
1919         '^'             {
1920                 $$ = scm_makfrom0str ("Hat");
1921         }
1922         | '+'           {
1923                 $$ = scm_makfrom0str ("Plus");
1924         }
1925         | '-'           {
1926                 $$ = scm_makfrom0str ("Dash");
1927         }
1928         | '|'           {
1929                 $$ = scm_makfrom0str ("Bar");
1930         }
1931         | '>'           {
1932                 $$ = scm_makfrom0str ("Larger");
1933         }
1934         | '.'           {
1935                 $$ = scm_makfrom0str ("Dot");
1936         }
1937         | '_' {
1938                 $$ = scm_makfrom0str ("Underscore");
1939         }
1940         ;
1941
1942 script_dir:
1943         '_'     { $$ = DOWN; }
1944         | '^'   { $$ = UP; }
1945         | '-'   { $$ = CENTER; }
1946         ;
1947
1948
1949 absolute_pitch:
1950         steno_pitch     {
1951                 $$ = $1;
1952         }
1953         ;
1954
1955 duration_length:
1956         multiplied_duration {
1957                 $$ = $1;
1958         }
1959         ;
1960
1961 optional_notemode_duration:
1962         {
1963                 Duration dd = THIS->default_duration_;
1964                 $$ = dd.smobbed_copy ();
1965
1966                 THIS->beam_check ($$);
1967         }
1968         | multiplied_duration   {
1969                 $$ = $1;
1970                 THIS->default_duration_ = *unsmob_duration ($$);
1971
1972                 THIS->beam_check ($$);
1973         }
1974         ;
1975
1976 steno_duration:
1977         bare_unsigned dots              {
1978                 int len = 0;
1979                 if (!is_duration ($1))
1980                         THIS->parser_error (_f ("not a duration: %d", $1));
1981                 else
1982                         len = intlog2 ($1);
1983
1984                 $$ = Duration (len, $2).smobbed_copy ();
1985         }
1986         | DURATION_IDENTIFIER dots      {
1987                 Duration *d = unsmob_duration ($1);
1988                 Duration k (d->duration_log (), d->dot_count () + $2);
1989                 *d = k;
1990                 $$ = $1;
1991         }
1992         ;
1993
1994 multiplied_duration:
1995         steno_duration {
1996                 $$ = $1;
1997         }
1998         | multiplied_duration '*' bare_unsigned {
1999                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2000         }
2001         | multiplied_duration '*' FRACTION {
2002                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2003
2004                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2005         }
2006         ;
2007
2008 fraction:
2009         FRACTION { $$ = $1; }
2010         | UNSIGNED '/' UNSIGNED {
2011                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2012         }
2013         ;
2014
2015 dots:
2016         /* empty */     {
2017                 $$ = 0;
2018         }
2019         | dots '.' {
2020                 $$ ++;
2021         }
2022         ;
2023
2024 tremolo_type:
2025         ':'     {
2026                 $$ = 0;
2027         }
2028         | ':' bare_unsigned {
2029                 if (!is_duration ($2))
2030                         THIS->parser_error (_f ("not a duration: %d", $2));
2031                 $$ = $2;
2032         }
2033         ;
2034
2035 bass_number:
2036         DIGIT   {
2037                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2038         }
2039         | UNSIGNED {
2040                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2041         }
2042         | STRING { $$ = $1; }
2043         ;
2044
2045 bass_mod:
2046         '-'     { $$ = -2; }
2047         | '+'   { $$ = 2; }
2048         | '!'   { $$ = 0; }
2049         ;
2050
2051 bass_figure:
2052         FIGURE_SPACE {
2053                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2054                 $$ = bfr->self_scm ();
2055                 scm_gc_unprotect_object ($$);
2056         }
2057         | bass_number  {
2058                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2059                 $$ = bfr->self_scm ();
2060
2061                 bfr->set_property ("figure", $1);
2062
2063                 scm_gc_unprotect_object ($$);
2064         }
2065         | bass_figure bass_mod {
2066                 Music *m = unsmob_music ($1);
2067                 if ($2) {
2068                         SCM salter = m->get_property ("alteration");
2069                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2070                         m->set_property ("alteration",
2071                                 scm_int2num (alter + $2));
2072                 } else {
2073                         m->set_property ("alteration", scm_int2num (0));
2074                 }
2075         }
2076         ;
2077
2078 br_bass_figure:
2079         '[' bass_figure {
2080                 $$ = $2;
2081                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2082         }
2083         | bass_figure   {
2084                 $$ = $1;
2085         }
2086         | br_bass_figure ']' {
2087                 $$ = $1;
2088                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2089         }
2090         ;
2091
2092 figure_list:
2093         /**/            {
2094                 $$ = SCM_EOL;
2095         }
2096         | figure_list br_bass_figure {
2097                 $$ = scm_cons ($2, $1);
2098         }
2099         ;
2100
2101 figure_spec:
2102         FIGURE_OPEN figure_list FIGURE_CLOSE {
2103                 Music *m = MY_MAKE_MUSIC ("EventChord");
2104                 $2 = scm_reverse_x ($2, SCM_EOL);
2105                 m->set_property ("elements", $2);
2106                 $$ = m->self_scm ();
2107         }
2108         ;
2109
2110
2111 optional_rest:
2112         /**/   { $$ = 0; }
2113         | REST { $$ = 1; }
2114         ;
2115
2116 simple_element:
2117         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2118
2119                 Input i = THIS->pop_spot ();
2120                 if (!THIS->lexer_->is_note_state ())
2121                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2122
2123                 Music *n = 0;
2124                 if ($6)
2125                         n = MY_MAKE_MUSIC ("RestEvent");
2126                 else
2127                         n = MY_MAKE_MUSIC ("NoteEvent");
2128
2129                 n->set_property ("pitch", $1);
2130                 n->set_property ("duration", $5);
2131
2132                 if (ly_c_number_p ($4))
2133                 {
2134                         int q = ly_scm2int ($4);
2135                         n->set_property ("absolute-octave", scm_int2num (q-1));
2136                 }
2137
2138                 if ($3 % 2)
2139                         n->set_property ("cautionary", SCM_BOOL_T);
2140                 if ($2 % 2 || $3 % 2)
2141                         n->set_property ("force-accidental", SCM_BOOL_T);
2142
2143                 Music *v = MY_MAKE_MUSIC ("EventChord");
2144                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2145                 scm_gc_unprotect_object (n->self_scm ());
2146
2147                 v->set_spot (i);
2148                 n->set_spot (i);
2149                 $$ = v;
2150         }
2151         | DRUM_PITCH optional_notemode_duration {
2152                 Input i = THIS->pop_spot ();
2153
2154                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2155                 n->set_property ("duration", $2);
2156                 n->set_property ("drum-type", $1);
2157
2158                 Music *v = MY_MAKE_MUSIC ("EventChord");
2159                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2160                 scm_gc_unprotect_object (n->self_scm ());
2161                 v->set_spot (i);
2162                 n->set_spot (i);
2163                 $$ = v;
2164
2165         }
2166         | figure_spec optional_notemode_duration {
2167                 Music *m = unsmob_music ($1);
2168                 Input i = THIS->pop_spot ();
2169                 m->set_spot (i);
2170                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2171                 {
2172                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2173                 }
2174                 $$ = m;
2175         }
2176         | RESTNAME optional_notemode_duration           {
2177
2178                 Input i = THIS->pop_spot ();
2179                 Music *ev = 0;
2180                 if (ly_scm2string ($1) == "s") {
2181                         /* Space */
2182                         ev = MY_MAKE_MUSIC ("SkipEvent");
2183                   }
2184                 else {
2185                         ev = MY_MAKE_MUSIC ("RestEvent");
2186
2187                     }
2188                 ev->set_property ("duration", $2);
2189                 ev->set_spot (i);
2190                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2191                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2192                 velt->set_spot (i);
2193
2194                 scm_gc_unprotect_object (ev->self_scm ());
2195
2196                 $$ = velt;
2197         }
2198         | MULTI_MEASURE_REST optional_notemode_duration         {
2199                 THIS->pop_spot ();
2200
2201                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2202                 SCM mus = scm_call_2 (proc, $2,
2203                         make_input (THIS->here_input ()));
2204                 scm_gc_protect_object (mus);
2205                 $$ = unsmob_music (mus);
2206         }
2207
2208         | lyric_element optional_notemode_duration      {
2209                 Input i = THIS->pop_spot ();
2210                 if (!THIS->lexer_->is_lyric_state ())
2211                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2212
2213                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2214                 lreq->set_property ("text", $1);
2215                 lreq->set_property ("duration",$2);
2216                 lreq->set_spot (i);
2217                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2218                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2219
2220                 $$= velt;
2221         }
2222         | new_chord {
2223                 THIS->pop_spot ();
2224
2225                 if (!THIS->lexer_->is_chord_state ())
2226                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2227                 $$ = unsmob_music ($1);
2228         }
2229         ;
2230
2231 lyric_element:
2232         /* FIXME: lyric flavoured markup would be better */
2233         full_markup {
2234         }
2235         | LYRICS_STRING {
2236         }
2237         ;
2238
2239 new_chord:
2240         steno_tonic_pitch optional_notemode_duration   {
2241                 $$ = make_chord ($1, $2, SCM_EOL);
2242         }
2243         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2244                 SCM its = scm_reverse_x ($4, SCM_EOL);
2245                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2246         }
2247         ;
2248
2249 chord_items:
2250         /**/ {
2251                 $$ = SCM_EOL;
2252         }
2253         | chord_items chord_item {
2254                 $$ = scm_cons ($2, $$);
2255         }
2256         ;
2257
2258 chord_separator:
2259         CHORD_COLON {
2260                 $$ = ly_symbol2scm ("chord-colon");
2261         }
2262         | CHORD_CARET {
2263                 $$ = ly_symbol2scm ("chord-caret");
2264         }
2265         | CHORD_SLASH steno_tonic_pitch {
2266                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2267         }
2268         | CHORD_BASS steno_tonic_pitch {
2269                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2270         }
2271         ;
2272
2273 chord_item:
2274         chord_separator {
2275                 $$ = $1;
2276         }
2277         | step_numbers {
2278                 $$ = scm_reverse_x ($1, SCM_EOL);
2279         }
2280         | CHORD_MODIFIER  {
2281                 $$ = $1;
2282         }
2283         ;
2284
2285 step_numbers:
2286         step_number { $$ = scm_cons ($1, SCM_EOL); }
2287         | step_numbers '.' step_number {
2288                 $$ = scm_cons ($3, $$);
2289         }
2290         ;
2291
2292 step_number:
2293         bare_unsigned {
2294                 $$ = make_chord_step ($1, 0);
2295         }
2296         | bare_unsigned '+' {
2297                 $$ = make_chord_step ($1, SHARP);
2298         }
2299         | bare_unsigned CHORD_MINUS {
2300                 $$ = make_chord_step ($1, FLAT);
2301         }
2302         ;
2303
2304 /*
2305         UTILITIES
2306
2307 TODO: should deprecate in favor of Scheme?
2308
2309  */
2310 number_expression:
2311         number_expression '+' number_term {
2312                 $$ = scm_sum ($1, $3);
2313         }
2314         | number_expression '-' number_term {
2315                 $$ = scm_difference ($1, $3);
2316         }
2317         | number_term
2318         ;
2319
2320 number_term:
2321         number_factor {
2322                 $$ = $1;
2323         }
2324         | number_factor '*' number_factor {
2325                 $$ = scm_product ($1, $3);
2326         }
2327         | number_factor '/' number_factor {
2328                 $$ = scm_divide ($1, $3);
2329         }
2330         ;
2331
2332 number_factor:
2333         '-'  number_factor { /* %prec UNARY_MINUS */
2334                 $$ = scm_difference ($2, SCM_UNDEFINED);
2335         }
2336         | bare_number
2337         ;
2338
2339
2340 bare_number:
2341         UNSIGNED        {
2342                 $$ = scm_int2num ($1);
2343         }
2344         | REAL          {
2345                 $$ = $1;
2346         }
2347         | NUMBER_IDENTIFIER             {
2348                 $$ = $1;
2349         }
2350         | REAL NUMBER_IDENTIFIER        {
2351                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2352         }
2353         | UNSIGNED NUMBER_IDENTIFIER    {
2354                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2355         }
2356         ;
2357
2358
2359 bare_unsigned:
2360         UNSIGNED {
2361                         $$ = $1;
2362         }
2363         | DIGIT {
2364                 $$ = $1;
2365         }
2366         ;
2367
2368 bare_int:
2369         bare_number {
2370                 if (scm_integer_p ($1) == SCM_BOOL_T)
2371                 {
2372                         int k = ly_scm2int ($1);
2373                         $$ = k;
2374                 } else
2375                 {
2376                         THIS->parser_error (_ ("need integer number arg"));
2377                         $$ = 0;
2378                 }
2379         }
2380         | '-' bare_int {
2381                 $$ = -$2;
2382         }
2383         ;
2384
2385 exclamations:
2386                 { $$ = 0; }
2387         | exclamations '!'      { $$ ++; }
2388         ;
2389
2390 questions:
2391                 { $$ = 0; }
2392         | questions '?' { $$ ++; }
2393         ;
2394
2395
2396
2397 full_markup:
2398         MARKUP_IDENTIFIER {
2399                 $$ = $1;
2400         }
2401         | MARKUP
2402                 { THIS->lexer_->push_markup_state (); }
2403         markup
2404                 { $$ = $3;
2405                   THIS->lexer_->pop_state ();
2406                 }
2407         ;
2408
2409
2410 /*
2411 This should be done more dynamically if possible.
2412 */
2413 markup:
2414         STRING {
2415                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2416         }
2417         | MARKUP_HEAD_EMPTY {
2418                 $$ = scm_list_1 ($1);
2419         }
2420         | MARKUP_HEAD_MARKUP0 markup {
2421                 $$ = scm_list_2 ($1, $2);
2422         }
2423         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2424                 $$ = scm_list_3 ($1, $2, $3);
2425         }
2426         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2427                 $$ = scm_list_3 ($1, $2, $3);
2428         }
2429         | markup_line {
2430                 $$ = $1;
2431         }
2432         | MARKUP_HEAD_LIST0 markup_list {
2433                 $$ = scm_list_2 ($1,$2);
2434         }
2435         | MARKUP_HEAD_SCM0 embedded_scm {
2436                 $$ = scm_list_2 ($1, $2);
2437         }
2438         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2439                 $$ = scm_list_4 ($1, $2, $3, $4);
2440         }
2441         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2442                 $$ = scm_list_4 ($1, $2, $3, $4);
2443         }
2444         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2445                 $$ = scm_list_3 ($1, $2, $3);
2446         }
2447         | MARKUP_IDENTIFIER {
2448                 $$ = $1;
2449         }
2450         | STRING_IDENTIFIER {
2451                 $$ = $1;
2452         }
2453         | score_block {
2454                 /* WIP this is a bit arbitrary,
2455                    we should also allow \book or Composite_music.
2456                    However, you'd typically want to change paper
2457                    settings, and need a \score block anyway.  */
2458                 Score *score = $1;
2459                 Book *book = new Book;
2460                 book->scores_.push (score);
2461                 extern Music_output_def* get_paper (My_lily_parser *parser);
2462                 Music_output_def *paper = get_paper (THIS);
2463                 SCM s = book->to_stencil (paper, THIS->header_);
2464                 scm_gc_unprotect_object (score->self_scm ());
2465                 scm_gc_unprotect_object (book->self_scm ());
2466                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2467         }
2468         ;
2469
2470 markup_list:
2471         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2472         ;
2473
2474 markup_line:
2475         '{' markup_list_body '}' {
2476                 SCM line = ly_scheme_function ("line-markup");
2477
2478                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2479         }
2480         ;
2481
2482 markup_list_body:
2483         /**/ {  $$ = SCM_EOL; }
2484         | markup_list_body markup {
2485                 $$ = scm_cons ($2, $1);
2486         }
2487         ;
2488
2489
2490 %%
2491
2492 void
2493 My_lily_parser::set_yydebug (bool )
2494 {
2495 #if 0
2496         yydebug = 1;
2497 #endif
2498 }
2499
2500 void
2501 My_lily_parser::do_yyparse ()
2502 {
2503         yyparse ((void*)this);
2504 }
2505
2506
2507 /*
2508 Should make this optional?    It will also complain when you do
2509
2510         [s4]
2511
2512 which is entirely legitimate.
2513
2514 Or we can scrap it. Barchecks should detect wrong durations, and
2515 skipTypesetting speeds it up a lot.
2516 */
2517
2518 void
2519 My_lily_parser::beam_check (SCM dur)
2520 {
2521   Duration *d = unsmob_duration (dur);
2522   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2523     {
2524       Music *m = unsmob_music (last_beam_start_);
2525       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2526     }
2527   last_beam_start_ = SCM_EOL;
2528 }
2529
2530
2531
2532
2533 /*
2534
2535 It is a little strange to have this function in this file, but
2536 otherwise, we have to import music classes into the lexer.
2537
2538 */
2539 int
2540 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2541 {
2542         if (ly_c_string_p (sid)) {
2543                 *destination = sid;
2544                 return STRING_IDENTIFIER;
2545         } else if (ly_c_number_p (sid)) {
2546                 *destination = sid;
2547                 return NUMBER_IDENTIFIER;
2548         } else if (unsmob_context_def (sid)) {
2549                 *destination = unsmob_context_def (sid)->clone_scm ();
2550                 return CONTEXT_DEF_IDENTIFIER;
2551         } else if (unsmob_score (sid)) {
2552                 Score *score = new Score (*unsmob_score (sid));
2553                 *destination = score->self_scm ();
2554                 return SCORE_IDENTIFIER;
2555         } else if (Music *mus = unsmob_music (sid)) {
2556                 mus = mus->clone ();
2557                 *destination = mus->self_scm ();
2558                 unsmob_music (*destination)->
2559                         set_property ("origin", make_input (last_input_));
2560                 return dynamic_cast<Event*> (mus)
2561                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2562         } else if (unsmob_duration (sid)) {
2563                 *destination = unsmob_duration (sid)->smobbed_copy ();
2564                 return DURATION_IDENTIFIER;
2565         } else if (unsmob_music_output_def (sid)) {
2566                 Music_output_def *p = unsmob_music_output_def (sid);
2567                 p = p->clone ();
2568
2569                 *destination = p->self_scm ();
2570                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2571         } else if (Text_item::markup_p (sid)) {
2572                 *destination = sid;
2573                 return MARKUP_IDENTIFIER;
2574         }
2575
2576         return -1;
2577 }
2578
2579 Music *
2580 property_op_to_music (SCM op)
2581 {
2582         Music *m = 0;
2583         SCM tag = ly_car (op);
2584         SCM symbol = ly_cadr (op);
2585         SCM args = ly_cddr (op);
2586         SCM grob_val = SCM_UNDEFINED;
2587         SCM grob_sym = SCM_UNDEFINED;
2588         SCM val = SCM_UNDEFINED;
2589
2590         if (tag == ly_symbol2scm ("assign"))
2591                 {
2592                 m = MY_MAKE_MUSIC ("PropertySet");
2593                 val = ly_car (args);
2594                 }
2595         else if (tag == ly_symbol2scm ("unset"))
2596                 m = MY_MAKE_MUSIC ("PropertyUnset");
2597         else if (tag == ly_symbol2scm ("poppush")
2598                  || tag == ly_symbol2scm ("push"))
2599                 {
2600                 m = MY_MAKE_MUSIC ("OverrideProperty");
2601                 grob_sym = ly_car (args);
2602                 grob_val = ly_cadr (args);
2603                 }
2604         else if (tag == ly_symbol2scm ("pop")) {
2605                 m = MY_MAKE_MUSIC ("RevertProperty");
2606                 grob_sym = ly_car (args);
2607                 }
2608
2609         m->set_property ("symbol", symbol);
2610
2611         if (val != SCM_UNDEFINED)
2612                 m->set_property ("value", val);
2613         if (grob_val != SCM_UNDEFINED)
2614                 m->set_property ("grob-value", grob_val);
2615
2616         if (grob_sym != SCM_UNDEFINED)
2617                 {
2618                 bool itc = internal_type_checking_global_b;
2619                 /* UGH.
2620                 */
2621                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2622                 if (autobeam)
2623                         internal_type_checking_global_b = false;
2624                 m->set_property ("grob-property", grob_sym);
2625                 if (autobeam)
2626                         internal_type_checking_global_b = itc;
2627                 }
2628
2629         if (op == ly_symbol2scm ("poppush"))
2630                 m->set_property ("pop-first", SCM_BOOL_T);
2631
2632
2633         return m;
2634 }
2635
2636 Music*
2637 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2638 {
2639         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2640
2641         csm->set_property ("element", m->self_scm ());
2642         scm_gc_unprotect_object (m->self_scm ());
2643
2644         csm->set_property ("context-type",
2645                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2646         csm->set_property ("property-operations", ops);
2647
2648         if (ly_c_string_p (id))
2649                 csm->set_property ("context-id", id);
2650         return csm;
2651 }
2652
2653 SCM
2654 get_next_unique_context ()
2655 {
2656         static int new_context_count;
2657         char s[1024];
2658         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2659         return scm_makfrom0str (s);
2660 }
2661