lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYDEBUG 1
  13 #define YYERROR_VERBOSE 1
  14 #define YYPARSE_PARAM my_lily_parser
  15 #define YYLEX_PARAM my_lily_parser
  16 #define PARSER ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror PARSER->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input.hh"
  79 #include "international.hh"
  80 #include "lily-guile.hh"
  81 #include "lily-lexer.hh"
  82 #include "lily-parser.hh"
  83 #include "lilypond-input-version.hh"
  84 #include "main.hh"
  85 #include "misc.hh"
  86 #include "music.hh"
  87 #include "music.hh"
  88 #include "output-def.hh"
  89 #include "paper-book.hh"
  90 #include "program-option.hh"
  91 #include "scm-hash.hh"
  92 #include "score.hh"
  93 #include "text-interface.hh"
  94 #include "warn.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         std::string *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 /* ES TODO:
 114 - Don't use lily module, create a new module instead.
 115 - delay application of the function
 116 */
 117 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 118   scm_apply_0 (proc, args)
 119 /* Syntactic Sugar. */
 120 #define MAKE_SYNTAX(name, location, ...)        \
 121   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 122
 123 SCM get_next_unique_context_id ();
 124 SCM get_next_unique_lyrics_context_id ();
 125
 126 #undef _
 127 #if !HAVE_GETTEXT
 128 #define _(x) x
 129 #else
 130 #include <libintl.h>
 131 #define _(x) gettext (x)
 132 #endif
 133
 134
 135
 136 SCM make_music_relative (Pitch start, SCM music);
 137 SCM run_music_function (Lily_parser *, SCM expr);
 138 SCM get_first_context_id (SCM type, Music *m);
 139 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 140 SCM make_chord_step (int step, int alter);
 141 SCM make_simple_markup (SCM a);
 142 bool is_duration (int t);
 143 bool is_regular_identifier (SCM id);
 144 bool ly_input_procedure_p (SCM x);
 145 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 146 void set_music_properties (Music *p, SCM a);
 147
 148 %}
 149
 150 /* The third option is an alias that will be used to display the
 151    syntax error.  Bison CVS now correctly handles backslash escapes.
 152
 153    FIXME: Bison needs to translate some of these, eg, STRING.
 154
 155 */
 156
 157 /* Keyword tokens with plain escaped name.  */
 158 %token ACCEPTS "\\accepts"
 159 %token ADDLYRICS "\\addlyrics"
 160 %token ADDQUOTE "\\addquote"
 161 %token ALIAS "\\alias"
 162 %token ALTERNATIVE "\\alternative"
 163 %token BOOK "\\book"
 164 %token CHANGE "\\change"
 165 %token CHORDMODE "\\chordmode"
 166 %token CHORDS "\\chords"
 167 %token CONSISTS "\\consists"
 168 %token CONTEXT "\\context"
 169 %token DEFAULT "\\default"
 170 %token DEFAULTCHILD "\\defaultchild"
 171 %token DENIES "\\denies"
 172 %token DESCRIPTION "\\description"
 173 %token DRUMMODE "\\drummode"
 174 %token DRUMS "\\drums"
 175 %token FIGUREMODE "\\figuremode"
 176 %token FIGURES "\\figures"
 177 %token GROBDESCRIPTIONS "\\grobdescriptions"
 178 %token HEADER "\\header"
 179 %token INVALID "\\invalid"
 180 %token KEY "\\key"
 181 %token LAYOUT "\\layout"
 182 %token LYRICMODE "\\lyricmode"
 183 %token LYRICS "\\lyrics"
 184 %token LYRICSTO "\\lyricsto"
 185 %token MARK "\\mark"
 186 %token MARKUP "\\markup"
 187 %token MIDI "\\midi"
 188 %token NAME "\\name"
 189 %token NOTEMODE "\\notemode"
 190 %token OBJECTID "\\objectid"
 191 %token OCTAVE "\\octave"
 192 %token ONCE "\\once"
 193 %token OVERRIDE "\\override"
 194 %token PAPER "\\paper"
 195 %token PARTIAL "\\partial"
 196 %token RELATIVE "\\relative"
 197 %token REMOVE "\\remove"
 198 %token REPEAT "\\repeat"
 199 %token REST "\\rest"
 200 %token REVERT "\\revert"
 201 %token SCORE "\\score"
 202 %token SEQUENTIAL "\\sequential"
 203 %token SET "\\set"
 204 %token SIMULTANEOUS "\\simultaneous"
 205 %token SKIP "\\skip"
 206 %token TEMPO "\\tempo"
 207 %token TIMES "\\times"
 208 %token TRANSPOSE "\\transpose"
 209 %token TYPE "\\type"
 210 %token UNSET "\\unset"
 211 %token WITH "\\with"
 212
 213 /* Keyword token exceptions.  */
 214 %token TIME_T "\\time"
 215 %token NEWCONTEXT "\\new"
 216
 217
 218 /* Other string tokens.  */
 219
 220 %token CHORD_BASS "/+"
 221 %token CHORD_CARET "^"
 222 %token CHORD_COLON ":"
 223 %token CHORD_MINUS "-"
 224 %token CHORD_SLASH "/"
 225 %token ANGLE_OPEN "<"
 226 %token ANGLE_CLOSE ">"
 227 %token DOUBLE_ANGLE_OPEN "<<"
 228 %token DOUBLE_ANGLE_CLOSE ">>"
 229 %token E_BACKSLASH "\\"
 230 %token E_ANGLE_CLOSE "\\>"
 231 %token E_CHAR "\\C[haracter]"
 232 %token E_CLOSE "\\)"
 233 %token E_EXCLAMATION "\\!"
 234 %token E_BRACKET_OPEN "\\["
 235 %token E_OPEN "\\("
 236 %token E_BRACKET_CLOSE "\\]"
 237 %token E_ANGLE_OPEN "\\<"
 238 %token E_PLUS "\\+"
 239 %token E_TILDE "\\~"
 240 %token EXTENDER "__"
 241
 242 /*
 243 If we give names, Bison complains.
 244 */
 245 %token FIGURE_CLOSE /* "\\>" */
 246 %token FIGURE_OPEN /* "\\<" */
 247 %token FIGURE_SPACE "_"
 248 %token HYPHEN "--"
 249
 250 %token CHORDMODIFIERS
 251 %token LYRIC_MARKUP
 252 %token MULTI_MEASURE_REST
 253
 254
 255 %token <i> DIGIT
 256 %token <i> E_UNSIGNED
 257 %token <i> UNSIGNED
 258
 259 /* Artificial tokens, for more generic function syntax */
 260 %token <i> EXPECT_MARKUP;
 261 %token <i> EXPECT_MUSIC;
 262 %token <i> EXPECT_SCM;
 263
 264 %token <scm> BOOK_IDENTIFIER
 265 %token <scm> CHORDMODIFIER_PITCH
 266 %token <scm> CHORD_MODIFIER
 267 %token <scm> CONTEXT_DEF_IDENTIFIER
 268 %token <scm> DRUM_PITCH
 269 %token <scm> DURATION_IDENTIFIER
 270 %token <scm> EVENT_IDENTIFIER
 271 %token <scm> FRACTION
 272 %token <scm> LYRICS_STRING
 273 %token <scm> LYRIC_MARKUP_IDENTIFIER
 274 %token <scm> MARKUP_HEAD_EMPTY
 275 %token <scm> MARKUP_HEAD_LIST0
 276 %token <scm> MARKUP_HEAD_MARKUP0
 277 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 278 %token <scm> MARKUP_HEAD_SCM0
 279 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 280 %token <scm> MARKUP_HEAD_SCM0_SCM1
 281 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 282 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 283 %token <scm> MARKUP_IDENTIFIER
 284 %token <scm> MUSIC_FUNCTION
 285 %token <scm> MUSIC_IDENTIFIER
 286 %token <scm> NOTENAME_PITCH
 287 %token <scm> NUMBER_IDENTIFIER
 288 %token <scm> OUTPUT_DEF_IDENTIFIER
 289 %token <scm> REAL
 290 %token <scm> RESTNAME
 291 %token <scm> SCM_IDENTIFIER
 292 %token <scm> SCM_TOKEN
 293 %token <scm> SCORE_IDENTIFIER
 294 %token <scm> STRING
 295 %token <scm> STRING_IDENTIFIER
 296 %token <scm> TONICNAME_PITCH
 297
 298
 299 %type <book> book_block
 300 %type <book> book_body
 301
 302 %type <i> bare_unsigned
 303 %type <i> figured_bass_alteration
 304 %type <i> dots
 305 %type <i> exclamations
 306 %type <i> optional_rest
 307 %type <i> questions
 308 %type <i> script_dir
 309 %type <i> sub_quotes
 310 %type <i> sup_quotes
 311 %type <i> tremolo_type
 312
 313 /* Music */
 314 %type <scm> composite_music
 315 %type <scm> grouped_music_list
 316 %type <scm> music
 317 %type <scm> prefix_composite_music
 318 %type <scm> repeated_music
 319 %type <scm> sequential_music
 320 %type <scm> simple_music
 321 %type <scm> simultaneous_music
 322 %type <scm> chord_body
 323 %type <scm> chord_body_element
 324 %type <scm> command_element
 325 %type <scm> command_event
 326 %type <scm> context_change
 327 %type <scm> direction_less_event
 328 %type <scm> direction_reqd_event
 329 %type <scm> event_chord
 330 %type <scm> gen_text_def
 331 %type <scm> music_property_def
 332 %type <scm> note_chord_element
 333 %type <scm> post_event
 334 %type <scm> re_rhythmed_music
 335 %type <scm> relative_music
 336 %type <scm> simple_element
 337 %type <scm> simple_music_property_def
 338 %type <scm> string_number_event
 339 %type <scm> tempo_event
 340
 341 %type <outputdef> output_def_body
 342 %type <outputdef> output_def_head
 343 %type <outputdef> output_def_head_with_mode_switch
 344 %type <outputdef> output_def
 345 %type <outputdef> paper_block
 346
 347 %type <scm> alternative_music
 348 %type <scm> generic_prefix_music_scm
 349 %type <scm> music_list
 350 %type <scm> absolute_pitch
 351 %type <scm> assignment_id
 352 %type <scm> bare_number
 353 %type <scm> bass_figure
 354 %type <scm> figured_bass_modification
 355 %type <scm> br_bass_figure
 356 %type <scm> bass_number
 357 %type <scm> chord_body_elements
 358 %type <scm> chord_item
 359 %type <scm> chord_items
 360 %type <scm> chord_separator
 361 %type <scm> context_def_mod
 362 %type <scm> context_def_spec_block
 363 %type <scm> context_def_spec_body
 364 %type <scm> context_mod
 365 %type <scm> context_mod_list
 366 %type <scm> context_prop_spec
 367 %type <scm> direction_less_char
 368 %type <scm> duration_length
 369 %type <scm> embedded_scm
 370 %type <scm> figure_list
 371 %type <scm> figure_spec
 372 %type <scm> fraction
 373 %type <scm> full_markup
 374 %type <scm> function_scm_argument
 375 %type <scm> function_arglist
 376 %type <scm> function_arglist_music_last
 377 %type <scm> function_arglist_nonmusic_last
 378 %type <scm> function_arglist_nonmusic
 379 %type <scm> identifier_init
 380 %type <scm> lilypond_header
 381 %type <scm> lilypond_header_body
 382 %type <scm> lyric_element
 383 %type <scm> lyric_markup
 384 %type <scm> markup
 385 %type <scm> markup_braced_list
 386 %type <scm> markup_braced_list_body
 387 %type <scm> markup_composed_list
 388 %type <scm> markup_head_1_item
 389 %type <scm> markup_head_1_list
 390 %type <scm> markup_list
 391 %type <scm> markup_top
 392 %type <scm> mode_changing_head
 393 %type <scm> mode_changing_head_with_context
 394 %type <scm> multiplied_duration
 395 %type <scm> music_function_identifier_musicless_prefix
 396 %type <scm> music_function_event
 397 %type <scm> music_function_chord_body
 398 %type <scm> new_chord
 399 %type <scm> new_lyrics
 400 %type <scm> number_expression
 401 %type <scm> number_factor
 402 %type <scm> number_term
 403 %type <scm> object_id_setting
 404 %type <scm> octave_check
 405 %type <scm> optional_context_mod
 406 %type <scm> optional_id
 407 %type <scm> optional_notemode_duration
 408 %type <scm> pitch
 409 %type <scm> pitch_also_in_chords
 410 %type <scm> post_events
 411 %type <scm> property_operation
 412 %type <scm> scalar
 413 %type <scm> script_abbreviation
 414 %type <scm> simple_chord_elements
 415 %type <scm> simple_markup
 416 %type <scm> simple_string
 417 %type <scm> steno_duration
 418 %type <scm> steno_pitch
 419 %type <scm> steno_tonic_pitch
 420 %type <scm> step_number
 421 %type <scm> step_numbers
 422 %type <scm> string
 423
 424 %type <score> score_block
 425 %type <score> score_body
 426
 427
 428 %left '-' '+'
 429
 430 /* We don't assign precedence to / and *, because we might need varied
 431 prec levels in different prods */
 432
 433 %left UNARY_MINUS
 434
 435 %%
 436
 437 lilypond:       /* empty */
 438         | lilypond toplevel_expression {
 439         }
 440         | lilypond assignment {
 441         }
 442         | lilypond error {
 443                 PARSER->error_level_ = 1;
 444         }
 445         | lilypond INVALID      {
 446                 PARSER->error_level_ = 1;
 447         }
 448         ;
 449
 450
 451 object_id_setting:
 452         OBJECTID STRING { $$ = $2; }
 453         ;
 454
 455 toplevel_expression:
 456         lilypond_header {
 457                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 458         }
 459         | book_block {
 460                 Book *book = $1;
 461                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 462                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 463                 book->unprotect ();
 464         }
 465         | score_block {
 466                 Score *score = $1;
 467
 468                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 469                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 470                 score->unprotect ();
 471         }
 472         | composite_music {
 473                 Music *music = unsmob_music ($1);
 474                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 475                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 476         }
 477         | full_markup {
 478                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 479                 scm_call_2 (proc, PARSER->self_scm (), $1);
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultlayout");
 491
 492                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 493                 od->unprotect();
 494         }
 495         ;
 496
 497 embedded_scm:
 498         SCM_TOKEN
 499         | SCM_IDENTIFIER
 500         ;
 501
 502
 503 lilypond_header_body:
 504         {
 505                 $$ = get_header(PARSER);
 506                 PARSER->lexer_->add_scope ($$);
 507         }
 508         | lilypond_header_body assignment  {
 509
 510         }
 511         ;
 512
 513 lilypond_header:
 514         HEADER '{' lilypond_header_body '}'     {
 515                 $$ = PARSER->lexer_->remove_scope ();
 516         }
 517         ;
 518
 519 /*
 520         DECLARATIONS
 521 */
 522 assignment_id:
 523         STRING          { $$ = $1; }
 524         | LYRICS_STRING { $$ = $1; }
 525         ;
 526
 527 assignment:
 528         assignment_id '=' identifier_init  {
 529                 PARSER->lexer_->set_identifier ($1, $3);
 530
 531 /*
 532  TODO: devise standard for protection in parser.
 533
 534   The parser stack lives on the C-stack, which means that
 535 all objects can be unprotected as soon as they're here.
 536
 537 */
 538         }
 539         | embedded_scm { }
 540         ;
 541
 542
 543 identifier_init:
 544         score_block {
 545                 $$ = $1->self_scm ();
 546                 $1->unprotect ();
 547         }
 548         | book_block {
 549                 $$ = $1->self_scm ();
 550                 $1->unprotect ();
 551         }
 552         | output_def {
 553                 $$ = $1->self_scm ();
 554                 $1->unprotect ();
 555         }
 556         | context_def_spec_block {
 557                 $$ = $1;
 558         }
 559         | music  {
 560                 /* Hack: Create event-chord around standalone events.
 561                    Prevents the identifier from being interpreted as a post-event. */
 562                 Music *mus = unsmob_music ($1);
 563                 bool is_event = mus &&
 564                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 565                                 != SCM_BOOL_F);
 566                 if (!is_event)
 567                         $$ = $1;
 568                 else
 569                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 570         }
 571         | post_event {
 572                 $$ = $1;
 573         }
 574         | number_expression {
 575                 $$ = $1;
 576         }
 577         | string {
 578                 $$ = $1;
 579         }
 580         | embedded_scm {
 581                 $$ = $1;
 582         }
 583         | full_markup {
 584                 $$ = $1;
 585         }
 586         | DIGIT {
 587                 $$ = scm_from_int ($1);
 588         }
 589         ;
 590
 591 context_def_spec_block:
 592         CONTEXT '{' context_def_spec_body '}'
 593                 {
 594                 $$ = $3;
 595         }
 596         ;
 597
 598 context_def_spec_body:
 599         /**/ {
 600                 $$ = Context_def::make_scm ();
 601                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 602         }
 603         | CONTEXT_DEF_IDENTIFIER {
 604                 $$ = $1;
 605                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 606         }
 607         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 608                 Context_def*td = unsmob_context_def ($$);
 609
 610                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 611                         SCM tag = scm_caar (p);
 612
 613                         /* TODO: should make new tag "grob-definition" ? */
 614                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 615                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 616                 }
 617         }
 618         | context_def_spec_body context_mod {
 619                 unsmob_context_def ($$)->add_context_mod ($2);
 620         }
 621         ;
 622
 623
 624
 625 book_block:
 626         BOOK '{' book_body '}'  {
 627                 $$ = $3;
 628         }
 629         ;
 630
 631 /* FIXME:
 632    * Use 'handlers' like for toplevel-* stuff?
 633    * grok \layout and \midi?  */
 634 book_body:
 635         {
 636                 $$ = new Book;
 637                 $$->origin ()->set_spot (@$);
 638                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 639                 $$->paper_->unprotect ();
 640                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 641         }
 642         | BOOK_IDENTIFIER {
 643                 $$ = unsmob_book ($1);
 644                 $$->protect ();
 645                 $$->origin ()->set_spot (@$);
 646         }
 647         | book_body paper_block {
 648                 $$->paper_ = $2;
 649                 $2->unprotect ();
 650         }
 651         | book_body score_block {
 652                 SCM s = $2->self_scm ();
 653                 $$->add_score (s);
 654                 $2->unprotect();
 655         }
 656         | book_body full_markup {
 657                 $$->add_score ($2);
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663                 $$->paper_ = 0;
 664                 $$->scores_ = SCM_EOL;
 665         }
 666         | book_body object_id_setting {
 667                 $$->user_key_ = ly_scm2string ($2);
 668         }
 669         ;
 670
 671 score_block:
 672         SCORE '{' score_body '}'        {
 673                 $$ = $3;
 674         }
 675         ;
 676
 677 score_body:
 678         music {
 679                 SCM m = $1;
 680                 SCM scorify = ly_lily_module_constant ("scorify-music");
 681                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 682
 683                 // pass ownernship to C++ again.
 684                 $$ = unsmob_score (score);
 685                 $$->protect ();
 686                 $$->origin ()->set_spot (@$);
 687         }
 688         | SCORE_IDENTIFIER {
 689                 $$ = unsmob_score ($1);
 690                 $$->protect ();
 691                 $$->origin ()->set_spot (@$);
 692         }
 693         | score_body object_id_setting {
 694                 $$->user_key_ = ly_scm2string ($2);
 695         }
 696         | score_body lilypond_header    {
 697                 $$->header_ = $2;
 698         }
 699         | score_body output_def {
 700                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 701                 {
 702                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 703
 704                 }
 705                 else
 706                 {
 707                         $$->add_output_def ($2);
 708                 }
 709                 $2->unprotect ();
 710         }
 711         | score_body error {
 712                 $$->error_found_ = true;
 713         }
 714         ;
 715
 716
 717 /*
 718         OUTPUT DEF
 719 */
 720
 721 paper_block:
 722         output_def {
 723                 $$ = $1;
 724                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 725                 {
 726                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 727                         $1->unprotect ();
 728                         $$ = get_paper (PARSER);
 729                 }
 730         }
 731         ;
 732
 733
 734 output_def:
 735         output_def_body '}' {
 736                 $$ = $1;
 737
 738                 PARSER->lexer_->remove_scope ();
 739                 PARSER->lexer_->pop_state ();
 740         }
 741         ;
 742
 743 output_def_head:
 744         PAPER {
 745                 $$ = get_paper (PARSER);
 746                 $$->input_origin_ = @$;
 747                 PARSER->lexer_->add_scope ($$->scope_);
 748         }
 749         | MIDI    {
 750                 Output_def *p = get_midi (PARSER);
 751                 $$ = p;
 752                 PARSER->lexer_->add_scope (p->scope_);
 753         }
 754         | LAYOUT        {
 755                 Output_def *p = get_layout (PARSER);
 756
 757                 PARSER->lexer_->add_scope (p->scope_);
 758                 $$ = p;
 759         }
 760         ;
 761
 762 output_def_head_with_mode_switch:
 763         output_def_head {
 764                 PARSER->lexer_->push_initial_state ();
 765                 $$ = $1;
 766         }
 767         ;
 768
 769 output_def_body:
 770         output_def_head_with_mode_switch '{' {
 771                 $$ = $1;
 772                 $$->input_origin_.set_spot (@$);
 773         }
 774         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 775                 $1->unprotect ();
 776
 777                 Output_def *o = unsmob_output_def ($3);
 778                 o->input_origin_.set_spot (@$);
 779                 $$ = o;
 780                 $$->protect ();
 781                 PARSER->lexer_->remove_scope ();
 782                 PARSER->lexer_->add_scope (o->scope_);
 783         }
 784         | output_def_body assignment  {
 785
 786         }
 787         | output_def_body context_def_spec_block        {
 788                 assign_context_def ($$, $2);
 789         }
 790         | output_def_body error {
 791
 792         }
 793         ;
 794
 795 tempo_event:
 796         TEMPO steno_duration '=' bare_unsigned  {
 797                 $$ = MAKE_SYNTAX ("tempo", @$, $2, scm_int2num ($4));
 798         }
 799         ;
 800
 801 /*
 802 The representation of a  list is the
 803
 804   (LIST . LAST-CONS)
 805
 806  to have efficient append.  */
 807
 808 music_list:
 809         /* empty */ {
 810                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 811         }
 812         | music_list music {
 813                 SCM s = $$;
 814                 SCM c = scm_cons ($2, SCM_EOL);
 815
 816                 if (scm_is_pair (scm_cdr (s)))
 817                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 818                 else
 819                         scm_set_car_x (s, c); /* set first cons */
 820                 scm_set_cdr_x (s, c);  /* remember last cell */
 821         }
 822         | music_list embedded_scm {
 823
 824         }
 825         | music_list error {
 826                 Music *m = MY_MAKE_MUSIC("Music");
 827                 // ugh. code dup
 828                 m->set_property ("error-found", SCM_BOOL_T);
 829                 SCM s = $$;
 830                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 831                 m->unprotect (); /* UGH */
 832
 833                 if (scm_is_pair (scm_cdr (s)))
 834                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 835                 else
 836                         scm_set_car_x (s, c); /* set first cons */
 837                 scm_set_cdr_x (s, c);  /* remember last cell */
 838         }
 839         ;
 840
 841 music:
 842         simple_music
 843         | composite_music
 844         ;
 845
 846 alternative_music:
 847         /* empty */ {
 848                 $$ = SCM_EOL;
 849         }
 850         | ALTERNATIVE '{' music_list '}' {
 851                 $$ = scm_car ($3);
 852         }
 853         ;
 854
 855
 856 repeated_music:
 857         REPEAT simple_string bare_unsigned music alternative_music
 858         {
 859                 $$ = MAKE_SYNTAX ("repeat", @$, $2, scm_int2num ($3), $4, $5);
 860         }
 861         ;
 862
 863 sequential_music:
 864         SEQUENTIAL '{' music_list '}'           {
 865                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($3));
 866         }
 867         | '{' music_list '}'            {
 868                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_car ($2));
 869         }
 870         ;
 871
 872 simultaneous_music:
 873         SIMULTANEOUS '{' music_list '}'{
 874                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($3));
 875         }
 876         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
 877                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_car ($2));
 878         }
 879         ;
 880
 881 simple_music:
 882         event_chord
 883         | MUSIC_IDENTIFIER
 884         | music_property_def
 885         | context_change
 886         ;
 887
 888 optional_context_mod:
 889         /**/ { $$ = SCM_EOL; }
 890         | WITH { PARSER->lexer_->push_initial_state (); }
 891         '{' context_mod_list '}'
 892         {
 893                 PARSER->lexer_->pop_state ();
 894                 $$ = $4;
 895         }
 896         ;
 897
 898 context_mod_list:
 899         /* */  { $$ = SCM_EOL; }
 900         | context_mod_list context_mod  {
 901                  $$ = scm_cons ($2, $1);
 902         }
 903         ;
 904
 905 composite_music:
 906         prefix_composite_music { $$ = $1; }
 907         | grouped_music_list { $$ = $1; }
 908         ;
 909
 910 grouped_music_list:
 911         simultaneous_music              { $$ = $1; }
 912         | sequential_music              { $$ = $1; }
 913         ;
 914
 915 function_scm_argument:
 916         embedded_scm
 917         | simple_string
 918         ;
 919
 920 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
 921  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM
 922 and this rule returns the reversed list of arguments. */
 923
 924 function_arglist_music_last:
 925         EXPECT_MUSIC function_arglist music {
 926                 $$ = scm_cons ($3, $2);
 927         }
 928         ;
 929
 930 function_arglist_nonmusic_last:
 931         EXPECT_MARKUP function_arglist full_markup {
 932                 $$ = scm_cons ($3, $2);
 933         }
 934         | EXPECT_SCM function_arglist function_scm_argument {
 935                 $$ = scm_cons ($3, $2);
 936         }
 937         ;
 938
 939 function_arglist_nonmusic: /*empty*/ {
 940                 $$ = SCM_EOL;
 941         }
 942         | EXPECT_MARKUP function_arglist_nonmusic full_markup {
 943                 $$ = scm_cons ($3, $2);
 944         }
 945         | EXPECT_SCM function_arglist_nonmusic function_scm_argument {
 946                 $$ = scm_cons ($3, $2);
 947         }
 948         ;
 949
 950 function_arglist: /*empty*/ {
 951                 $$ = SCM_EOL;
 952         }
 953         | function_arglist_music_last
 954         | function_arglist_nonmusic_last
 955         ;
 956
 957 generic_prefix_music_scm:
 958         MUSIC_FUNCTION function_arglist {
 959                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
 960         }
 961         ;
 962
 963
 964 optional_id:
 965         /**/ { $$ = SCM_EOL; }
 966         | '=' simple_string {
 967                 $$ = $2;
 968         }
 969         ;
 970
 971
 972 prefix_composite_music:
 973         generic_prefix_music_scm {
 974                 $$ = run_music_function (PARSER, $1);
 975         }
 976         | CONTEXT    simple_string optional_id optional_context_mod music {
 977                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_F);
 978         }
 979         | NEWCONTEXT simple_string optional_id optional_context_mod music {
 980                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, $4, SCM_BOOL_T);
 981         }
 982
 983         | TIMES fraction music {
 984                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
 985         }
 986         | repeated_music                { $$ = $1; }
 987         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords music {
 988                 Pitch from = *unsmob_pitch ($2);
 989                 Pitch to = *unsmob_pitch ($3);
 990                 SCM pitch = pitch_interval (from, to).smobbed_copy ();
 991                 $$ = MAKE_SYNTAX ("transpose-music", @$, pitch, $4);
 992         }
 993         | mode_changing_head grouped_music_list {
 994                 if ($1 == ly_symbol2scm ("chords"))
 995                 {
 996                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
 997                 }
 998                 else
 999                 {
1000                   $$ = $2;
1001                 }
1002                 PARSER->lexer_->pop_state ();
1003         }
1004         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1005                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, $2, SCM_BOOL_T);
1006                 if ($1 == ly_symbol2scm ("ChordNames"))
1007                 {
1008                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1009                 }
1010                 PARSER->lexer_->pop_state ();
1011         }
1012         | relative_music        { $$ = $1; }
1013         | re_rhythmed_music     { $$ = $1; }
1014         ;
1015
1016 mode_changing_head:
1017         NOTEMODE {
1018                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1019                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1020
1021                 $$ = ly_symbol2scm ("notes");
1022         }
1023         | DRUMMODE
1024                 {
1025                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1026                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1027
1028                 $$ = ly_symbol2scm ("drums");
1029         }
1030         | FIGUREMODE {
1031                 PARSER->lexer_->push_figuredbass_state ();
1032
1033                 $$ = ly_symbol2scm ("figures");
1034         }
1035         | CHORDMODE {
1036                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1037                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1038                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1039                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1040                 $$ = ly_symbol2scm ("chords");
1041
1042         }
1043         | LYRICMODE
1044                 { PARSER->lexer_->push_lyric_state ();
1045                 $$ = ly_symbol2scm ("lyrics");
1046         }
1047         ;
1048
1049 mode_changing_head_with_context:
1050         DRUMS {
1051                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1052                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1053
1054                 $$ = ly_symbol2scm ("DrumStaff");
1055         }
1056         | FIGURES {
1057                 PARSER->lexer_->push_figuredbass_state ();
1058
1059                 $$ = ly_symbol2scm ("FiguredBass");
1060         }
1061         | CHORDS {
1062                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1063                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1064                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1065                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1066                 $$ = ly_symbol2scm ("ChordNames");
1067         }
1068         | LYRICS
1069                 { PARSER->lexer_->push_lyric_state ();
1070                 $$ = ly_symbol2scm ("Lyrics");
1071         }
1072         ;
1073
1074
1075 relative_music:
1076         RELATIVE absolute_pitch music {
1077                 Pitch start = *unsmob_pitch ($2);
1078                 $$ = make_music_relative (start, $3);
1079         }
1080         | RELATIVE composite_music {
1081                 Pitch middle_c (0, 0, 0);
1082                 $$ = make_music_relative (middle_c, $2);
1083         }
1084         ;
1085
1086 new_lyrics:
1087         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1088         /*cont */
1089         grouped_music_list {
1090         /* Can also use music at the expensive of two S/Rs similar to
1091            \repeat \alternative */
1092                 PARSER->lexer_->pop_state ();
1093
1094                 $$ = scm_cons ($3, SCM_EOL);
1095         }
1096         | new_lyrics ADDLYRICS {
1097                 PARSER->lexer_->push_lyric_state ();
1098         } grouped_music_list {
1099                 PARSER->lexer_->pop_state ();
1100                 $$ = scm_cons ($4, $1);
1101         }
1102         ;
1103
1104 re_rhythmed_music:
1105         grouped_music_list new_lyrics {
1106                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1107         }
1108         | LYRICSTO simple_string {
1109                 PARSER->lexer_->push_lyric_state ();
1110         } music {
1111                 PARSER->lexer_->pop_state ();
1112                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1113         }
1114         ;
1115
1116 context_change:
1117         CHANGE STRING '=' STRING  {
1118                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1119         }
1120         ;
1121
1122 property_operation:
1123         STRING '=' scalar {
1124                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1125                         scm_string_to_symbol ($1), $3);
1126         }
1127         | UNSET simple_string {
1128                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1129                         scm_string_to_symbol ($2));
1130         }
1131         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1132                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1133                         scm_string_to_symbol ($2), $5, $3);
1134         }
1135         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1136                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1137                                 scm_string_to_symbol ($2), $6, $4, $3);
1138         }
1139         | REVERT simple_string embedded_scm {
1140                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1141                         scm_string_to_symbol ($2), $3);
1142         }
1143         ;
1144
1145 context_def_mod:
1146         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1147         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1148
1149         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1150         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1151         | DENIES { $$ = ly_symbol2scm ("denies"); }
1152
1153         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1154         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1155         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1156         | NAME { $$ = ly_symbol2scm ("context-name"); }
1157         ;
1158
1159 context_mod:
1160         property_operation { $$ = $1; }
1161         | context_def_mod STRING {
1162                 $$ = scm_list_2 ($1, $2);
1163         }
1164         ;
1165
1166 context_prop_spec:
1167         simple_string {
1168                 if (!is_regular_identifier ($1))
1169                 {
1170                         @$.error (_("Grob name should be alphanumeric"));
1171                 }
1172
1173                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1174                         scm_string_to_symbol ($1));
1175         }
1176         | simple_string '.' simple_string {
1177                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1178                         scm_string_to_symbol ($3));
1179         }
1180         ;
1181
1182 simple_music_property_def:
1183         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1184                 $$ = scm_list_5 (scm_car ($2),
1185                         ly_symbol2scm ("OverrideProperty"),
1186                         scm_cadr ($2),
1187                         $5, $3);
1188         }
1189         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1190                 $$ = scm_list_n (scm_car ($2),
1191                         ly_symbol2scm ("OverrideProperty"),
1192                         scm_cadr ($2),
1193                         $6, $4, $3, SCM_UNDEFINED);
1194         }
1195         | REVERT context_prop_spec embedded_scm {
1196                 $$ = scm_list_4 (scm_car ($2),
1197                         ly_symbol2scm ("RevertProperty"),
1198                         scm_cadr ($2),
1199                         $3);
1200         }
1201         | SET context_prop_spec '=' scalar {
1202                 $$ = scm_list_4 (scm_car ($2),
1203                         ly_symbol2scm ("PropertySet"),
1204                         scm_cadr ($2),
1205                         $4);
1206         }
1207         | UNSET context_prop_spec {
1208                 $$ = scm_list_3 (scm_car ($2),
1209                         ly_symbol2scm ("PropertyUnset"),
1210                         scm_cadr ($2));
1211         }
1212         ;
1213
1214 music_property_def:
1215         simple_music_property_def {
1216                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1217         }
1218         | ONCE simple_music_property_def {
1219                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1220         }
1221         ;
1222
1223 string:
1224         STRING {
1225                 $$ = $1;
1226         }
1227         | STRING_IDENTIFIER {
1228                 $$ = $1;
1229         }
1230         | string '+' string {
1231                 $$ = scm_string_append (scm_list_2 ($1, $3));
1232         }
1233         ;
1234
1235 simple_string: STRING {
1236                 $$ = $1;
1237         }
1238         | LYRICS_STRING {
1239                 $$ = $1;
1240         }
1241         | STRING_IDENTIFIER {
1242                 $$ = $1;
1243         }
1244         ;
1245
1246 scalar: string {
1247                 $$ = $1;
1248         }
1249         | LYRICS_STRING {
1250                 $$ = $1;
1251         }
1252         | bare_number {
1253                 $$ = $1;
1254         }
1255         | embedded_scm {
1256                 $$ = $1;
1257         }
1258         | full_markup {
1259                 $$ = $1;
1260         }
1261         | DIGIT {
1262                 $$ = scm_from_int ($1);
1263         }
1264         ;
1265
1266 event_chord:
1267         /* TODO: Create a special case that avoids the creation of
1268            EventChords around simple_elements that have no post_events?
1269          */
1270         simple_chord_elements post_events       {
1271                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1272
1273                 Input i;
1274                 /* why is this giving wrong start location? -ns
1275                  * i = @$; */
1276                 i.set_location (@1, @2);
1277                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1278         }
1279         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1280                 Input i;
1281                 i.set_location (@1, @3);
1282                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2, $3);
1283         }
1284         | command_element
1285         | note_chord_element
1286         ;
1287
1288
1289 note_chord_element:
1290         chord_body optional_notemode_duration post_events
1291         {
1292                 Music *m = unsmob_music ($1);
1293                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1294                 SCM es = m->get_property ("elements");
1295                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1296
1297                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1298                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1299                 es = ly_append2 (es, postevs);
1300
1301                 m-> set_property ("elements", es);
1302                 m->set_spot (@$);
1303                 $$ = m->self_scm ();
1304         }
1305         ;
1306
1307 chord_body:
1308         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1309         {
1310                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1311         }
1312         ;
1313
1314 chord_body_elements:
1315         /* empty */             { $$ = SCM_EOL; }
1316         | chord_body_elements chord_body_element {
1317                 $$ = scm_cons ($2, $1);
1318         }
1319         ;
1320
1321 chord_body_element:
1322         pitch exclamations questions octave_check post_events
1323         {
1324                 int q = $3;
1325                 int ex = $2;
1326                 SCM check = $4;
1327                 SCM post = $5;
1328
1329                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1330                 n->set_property ("pitch", $1);
1331                 n->set_spot (@$);
1332                 if (q % 2)
1333                         n->set_property ("cautionary", SCM_BOOL_T);
1334                 if (ex % 2 || q % 2)
1335                         n->set_property ("force-accidental", SCM_BOOL_T);
1336
1337                 if (scm_is_pair (post)) {
1338                         SCM arts = scm_reverse_x (post, SCM_EOL);
1339                         n->set_property ("articulations", arts);
1340                 }
1341                 if (scm_is_number (check))
1342                 {
1343                         int q = scm_to_int (check);
1344                         n->set_property ("absolute-octave", scm_from_int (q-1));
1345                 }
1346
1347                 $$ = n->unprotect ();
1348         }
1349         | DRUM_PITCH post_events {
1350                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1351                 n->set_property ("duration", $2);
1352                 n->set_property ("drum-type", $1);
1353                 n->set_spot (@$);
1354
1355                 if (scm_is_pair ($2)) {
1356                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1357                         n->set_property ("articulations", arts);
1358                 }
1359                 $$ = n->unprotect ();
1360         }
1361         | music_function_chord_body {
1362                 $$ = run_music_function (PARSER, $1);
1363         }
1364         ;
1365
1366 music_function_identifier_musicless_prefix: MUSIC_FUNCTION {
1367                 SCM sig = scm_object_property (yylval.scm, ly_symbol2scm ("music-function-signature"));
1368                 if (scm_is_pair (sig) && to_boolean (scm_memq (ly_music_p_proc, scm_cdr (scm_reverse (sig)))))
1369                 {
1370                         PARSER->parser_error (@$, "Music function applied to event may not have a Music argument, except as the last argument.");
1371                 }
1372         }
1373         ;
1374
1375 music_function_chord_body:
1376         /* We could allow chord functions to have multiple music arguments,
1377            but it's more consistent with music_function_event if we
1378            prohibit it here too */
1379         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic chord_body_element {
1380                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1381         }
1382         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1383                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1384         }
1385         ;
1386
1387 music_function_event:
1388         /* Post-events can only have the last argument as music, without this
1389            restriction we get a shift/reduce conflict from e.g.
1390            c8-\partcombine c8 -. */
1391         music_function_identifier_musicless_prefix EXPECT_MUSIC function_arglist_nonmusic post_event {
1392                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($3, scm_list_1 ($4)));
1393         }
1394         | music_function_identifier_musicless_prefix function_arglist_nonmusic {
1395                 $$ = ly_append2 (scm_list_2 ($1, make_input (@$)), scm_reverse_x ($2, SCM_EOL));
1396         }
1397         ;
1398
1399 command_element:
1400         command_event {
1401                 $$ = $1;
1402         }
1403         | SKIP duration_length {
1404                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1405         }
1406         | E_BRACKET_OPEN {
1407                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1408                 m->set_property ("span-direction", scm_from_int (START));
1409                 m->set_spot (@$);
1410                 $$ = m->unprotect();
1411         }
1412         | E_BRACKET_CLOSE {
1413                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1414                 m->set_property ("span-direction", scm_from_int (STOP));
1415                 m->set_spot (@$);
1416                 $$ = m->unprotect ();
1417         }
1418         | E_BACKSLASH {
1419                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1420         }
1421         | '|'      {
1422                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1423
1424                 Music *m = unsmob_music (pipe);
1425                 if (m)
1426                 {
1427                         m = m->clone ();
1428                         m->set_spot (@$);
1429                         $$ = m->unprotect ();
1430                 }
1431                 else
1432                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1433
1434         }
1435         | PARTIAL duration_length       {
1436                 Moment m = - unsmob_duration ($2)->get_length ();
1437                 $$ = MAKE_SYNTAX ("property-operation", @$, SCM_BOOL_F, ly_symbol2scm ("Timing"), ly_symbol2scm ("PropertySet"), ly_symbol2scm ("measurePosition"), m.smobbed_copy ());
1438                 $$ = MAKE_SYNTAX ("context-specification", @$, ly_symbol2scm ("Score"), SCM_BOOL_F, $$, SCM_EOL, SCM_BOOL_F);
1439         }
1440
1441         | TIME_T fraction  {
1442                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1443
1444                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1445         }
1446         | MARK scalar {
1447                 SCM proc = ly_lily_module_constant ("make-mark-set");
1448
1449                 $$ = scm_call_1 (proc, $2);
1450         }
1451         ;
1452
1453 command_event:
1454         E_TILDE {
1455                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent")->unprotect ();
1456         }
1457         | MARK DEFAULT  {
1458                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1459                 $$ = m->unprotect ();
1460         }
1461         | tempo_event {
1462                 $$ = $1;
1463         }
1464         | KEY DEFAULT {
1465                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1466                 $$ = key->unprotect ();
1467         }
1468         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1469
1470                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1471                 if (scm_ilength ($3) > 0)
1472                 {
1473                         key->set_property ("pitch-alist", $3);
1474                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1475                         key->transpose (* unsmob_pitch ($2));
1476                 } else {
1477                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1478                 }
1479
1480                 $$ = key->unprotect ();
1481         }
1482         ;
1483
1484
1485 post_events:
1486         /* empty */ {
1487                 $$ = SCM_EOL;
1488         }
1489         | post_events post_event {
1490                 unsmob_music ($2)->set_spot (@2);
1491                 $$ = scm_cons ($2, $$);
1492         }
1493         ;
1494
1495 post_event:
1496         direction_less_event {
1497                 $$ = $1;
1498         }
1499         | '-' music_function_event {
1500                 $$ = run_music_function (PARSER, $2);
1501         }
1502         | HYPHEN {
1503                 if (!PARSER->lexer_->is_lyric_state ())
1504                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1505                 $$ = MY_MAKE_MUSIC ("HyphenEvent")->unprotect ();
1506         }
1507         | EXTENDER {
1508                 if (!PARSER->lexer_->is_lyric_state ())
1509                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1510                 $$ = MY_MAKE_MUSIC ("ExtenderEvent")->unprotect ();
1511         }
1512         | script_dir direction_reqd_event {
1513                 if ($1)
1514                 {
1515                         Music *m = unsmob_music ($2);
1516                         m->set_property ("direction", scm_from_int ($1));
1517                 }
1518                 $$ = $2;
1519         }
1520         | script_dir direction_less_event {
1521                 if ($1)
1522                 {
1523                         Music *m = unsmob_music ($2);
1524                         m->set_property ("direction", scm_from_int ($1));
1525                 }
1526                 $$ = $2;
1527         }
1528         | string_number_event
1529         ;
1530
1531 string_number_event:
1532         E_UNSIGNED {
1533                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1534                 s->set_property ("string-number", scm_from_int ($1));
1535                 s->set_spot (@$);
1536                 $$ = s->unprotect ();
1537         }
1538         ;
1539
1540 direction_less_char:
1541         '['  {
1542                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1543         }
1544         | ']'  {
1545                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1546         }
1547         | '~'  {
1548                 $$ = ly_symbol2scm ("tildeSymbol");
1549         }
1550         | '('  {
1551                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1552         }
1553         | ')'  {
1554                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1555         }
1556         | E_EXCLAMATION  {
1557                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1558         }
1559         | E_OPEN  {
1560                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1561         }
1562         | E_CLOSE  {
1563                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1564         }
1565         | E_ANGLE_CLOSE  {
1566                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1567         }
1568         | E_ANGLE_OPEN  {
1569                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1570         }
1571         ;
1572
1573 direction_less_event:
1574         direction_less_char {
1575                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1576                 Music *m = 0;
1577                 if (unsmob_music (predefd))
1578                 {
1579                         m = unsmob_music (predefd)->clone ();
1580                 }
1581                 else
1582                 {
1583                         m = MY_MAKE_MUSIC ("Music");
1584                 }
1585                 m->set_spot (@$);
1586                 $$ = m->unprotect ();
1587         }
1588         | EVENT_IDENTIFIER      {
1589                 $$ = $1;
1590         }
1591         | tremolo_type  {
1592                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1593                a->set_spot (@$);
1594                a->set_property ("tremolo-type", scm_from_int ($1));
1595                $$ = a->unprotect ();
1596         }
1597         ;
1598
1599 direction_reqd_event:
1600         gen_text_def {
1601                 $$ = $1;
1602         }
1603         | script_abbreviation {
1604                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1605                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1606                 if (scm_is_string (s))
1607                         a->set_property ("articulation-type", s);
1608                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1609                 $$ = a->unprotect ();
1610         }
1611         ;
1612
1613 octave_check:
1614         /**/ { $$ = SCM_EOL; }
1615         | '='  { $$ = scm_from_int (0); }
1616         | '=' sub_quotes { $$ = scm_from_int ($2); }
1617         | '=' sup_quotes { $$ = scm_from_int ($2); }
1618         ;
1619
1620 sup_quotes:
1621         '\'' {
1622                 $$ = 1;
1623         }
1624         | sup_quotes '\'' {
1625                 $$ ++;
1626         }
1627         ;
1628
1629 sub_quotes:
1630         ',' {
1631                 $$ = 1;
1632         }
1633         | sub_quotes ',' {
1634                 $$++;
1635         }
1636         ;
1637
1638 steno_pitch:
1639         NOTENAME_PITCH  {
1640                 $$ = $1;
1641         }
1642         | NOTENAME_PITCH sup_quotes     {
1643                 Pitch p = *unsmob_pitch ($1);
1644                 p = p.transposed (Pitch ($2,0,0));
1645                 $$ = p.smobbed_copy ();
1646         }
1647         | NOTENAME_PITCH sub_quotes      {
1648                 Pitch p =* unsmob_pitch ($1);
1649                 p = p.transposed (Pitch (-$2,0,0));
1650                 $$ = p.smobbed_copy ();
1651         }
1652         ;
1653
1654 /*
1655 ugh. duplication
1656 */
1657
1658 steno_tonic_pitch:
1659         TONICNAME_PITCH {
1660                 $$ = $1;
1661         }
1662         | TONICNAME_PITCH sup_quotes    {
1663                 Pitch p = *unsmob_pitch ($1);
1664                 p = p.transposed (Pitch ($2,0,0));
1665                 $$ = p.smobbed_copy ();
1666         }
1667         | TONICNAME_PITCH sub_quotes     {
1668                 Pitch p =* unsmob_pitch ($1);
1669
1670                 p = p.transposed (Pitch (-$2,0,0));
1671                 $$ = p.smobbed_copy ();
1672         }
1673         ;
1674
1675 pitch:
1676         steno_pitch {
1677                 $$ = $1;
1678         }
1679         ;
1680
1681 pitch_also_in_chords:
1682         pitch
1683         | steno_tonic_pitch
1684         ;
1685
1686 gen_text_def:
1687         full_markup {
1688                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1689                 t->set_property ("text", $1);
1690                 t->set_spot (@$);
1691                 $$ = t->unprotect ();
1692         }
1693         | string {
1694                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1695                 t->set_property ("text",
1696                         make_simple_markup ($1));
1697                 t->set_spot (@$);
1698                 $$ = t->unprotect ();
1699         }
1700         | DIGIT {
1701                 Music *t = MY_MAKE_MUSIC ("FingeringEvent");
1702                 t->set_property ("digit", scm_from_int ($1));
1703                 t->set_spot (@$);
1704                 $$ = t->unprotect ();
1705         }
1706         ;
1707
1708 script_abbreviation:
1709         '^'             {
1710                 $$ = scm_makfrom0str ("Hat");
1711         }
1712         | '+'           {
1713                 $$ = scm_makfrom0str ("Plus");
1714         }
1715         | '-'           {
1716                 $$ = scm_makfrom0str ("Dash");
1717         }
1718         | '|'           {
1719                 $$ = scm_makfrom0str ("Bar");
1720         }
1721         | ANGLE_CLOSE   {
1722                 $$ = scm_makfrom0str ("Larger");
1723         }
1724         | '.'           {
1725                 $$ = scm_makfrom0str ("Dot");
1726         }
1727         | '_' {
1728                 $$ = scm_makfrom0str ("Underscore");
1729         }
1730         ;
1731
1732 script_dir:
1733         '_'     { $$ = DOWN; }
1734         | '^'   { $$ = UP; }
1735         | '-'   { $$ = CENTER; }
1736         ;
1737
1738
1739 absolute_pitch:
1740         steno_pitch     {
1741                 $$ = $1;
1742         }
1743         ;
1744
1745 duration_length:
1746         multiplied_duration {
1747                 $$ = $1;
1748         }
1749         ;
1750
1751 optional_notemode_duration:
1752         {
1753                 Duration dd = PARSER->default_duration_;
1754                 $$ = dd.smobbed_copy ();
1755         }
1756         | multiplied_duration   {
1757                 $$ = $1;
1758                 PARSER->default_duration_ = *unsmob_duration ($$);
1759         }
1760         ;
1761
1762 steno_duration:
1763         bare_unsigned dots              {
1764                 int len = 0;
1765                 if (!is_duration ($1))
1766                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
1767                 else
1768                         len = intlog2 ($1);
1769
1770                 $$ = Duration (len, $2).smobbed_copy ();
1771         }
1772         | DURATION_IDENTIFIER dots      {
1773                 Duration *d = unsmob_duration ($1);
1774                 Duration k (d->duration_log (), d->dot_count () + $2);
1775                 *d = k;
1776                 $$ = $1;
1777         }
1778         ;
1779
1780 multiplied_duration:
1781         steno_duration {
1782                 $$ = $1;
1783         }
1784         | multiplied_duration '*' bare_unsigned {
1785                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1786         }
1787         | multiplied_duration '*' FRACTION {
1788                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1789
1790                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1791         }
1792         ;
1793
1794 fraction:
1795         FRACTION { $$ = $1; }
1796         | UNSIGNED '/' UNSIGNED {
1797                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1798         }
1799         ;
1800
1801 dots:
1802         /* empty */     {
1803                 $$ = 0;
1804         }
1805         | dots '.' {
1806                 $$ ++;
1807         }
1808         ;
1809
1810 tremolo_type:
1811         ':'     {
1812                 $$ = 0;
1813         }
1814         | ':' bare_unsigned {
1815                 if (!is_duration ($2))
1816                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
1817                 $$ = $2;
1818         }
1819         ;
1820
1821 bass_number:
1822         DIGIT   {
1823                 $$ = scm_from_int ($1);
1824         }
1825         | UNSIGNED {
1826                 $$ = scm_from_int ($1);
1827         }
1828         | STRING { $$ = $1; }
1829         | full_markup { $$ = $1; }
1830         ;
1831
1832 figured_bass_alteration:
1833         '-'     { $$ = -2; }
1834         | '+'   { $$ = 2; }
1835         | '!'   { $$ = 0; }
1836         ;
1837
1838 bass_figure:
1839         FIGURE_SPACE {
1840                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1841                 $$ = bfr->self_scm ();
1842                 bfr->unprotect ();
1843                 bfr->set_spot (@1);
1844         }
1845         | bass_number  {
1846                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1847                 $$ = bfr->self_scm ();
1848
1849                 if (scm_is_number ($1))
1850                         bfr->set_property ("figure", $1);
1851                 else if (Text_interface::is_markup ($1))
1852                         bfr->set_property ("text", $1);
1853
1854                 bfr->unprotect ();
1855                 bfr->set_spot (@1);
1856         }
1857         | bass_figure ']' {
1858                 $$ = $1;
1859                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1860         }
1861         | bass_figure figured_bass_alteration {
1862                 Music *m = unsmob_music ($1);
1863                 if ($2) {
1864                         SCM salter = m->get_property ("alteration");
1865                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
1866                         m->set_property ("alteration",
1867                                 scm_from_int (alter + $2));
1868                 } else {
1869                         m->set_property ("alteration", scm_from_int (0));
1870                 }
1871         }
1872         | bass_figure figured_bass_modification  {
1873                 Music *m = unsmob_music ($1);
1874                 if ($2 == ly_symbol2scm ("plus"))
1875                         {
1876                         m->set_property ("augmented", SCM_BOOL_T);
1877                         }
1878                 else if ($2 == ly_symbol2scm ("slash"))
1879                         {
1880                         m->set_property ("diminished", SCM_BOOL_T);
1881                         }
1882                 else if ($2 == ly_symbol2scm ("exclamation"))
1883                         {
1884                         m->set_property ("no-continuation", SCM_BOOL_T);
1885                         }
1886         }
1887         ;
1888
1889
1890 figured_bass_modification:
1891         E_PLUS          {
1892                 $$ = ly_symbol2scm ("plus");
1893         }
1894         | E_EXCLAMATION {
1895                 $$ = ly_symbol2scm ("exclamation");
1896         }
1897         | '/'           {
1898                 $$ = ly_symbol2scm ("slash");
1899         }
1900         ;
1901
1902 br_bass_figure:
1903         bass_figure {
1904                 $$ = $1;
1905         }
1906         | '[' bass_figure {
1907                 $$ = $2;
1908                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1909         }
1910         ;
1911
1912 figure_list:
1913         /**/            {
1914                 $$ = SCM_EOL;
1915         }
1916         | figure_list br_bass_figure {
1917                 $$ = scm_cons ($2, $1);
1918         }
1919         ;
1920
1921 figure_spec:
1922         FIGURE_OPEN figure_list FIGURE_CLOSE {
1923                 $$ = scm_reverse_x ($2, SCM_EOL);
1924         }
1925         ;
1926
1927
1928 optional_rest:
1929         /**/   { $$ = 0; }
1930         | REST { $$ = 1; }
1931         ;
1932
1933 simple_element:
1934         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
1935                 if (!PARSER->lexer_->is_note_state ())
1936                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
1937
1938                 Music *n = 0;
1939                 if ($6)
1940                         n = MY_MAKE_MUSIC ("RestEvent");
1941                 else
1942                         n = MY_MAKE_MUSIC ("NoteEvent");
1943
1944                 n->set_property ("pitch", $1);
1945                 n->set_property ("duration", $5);
1946
1947                 if (scm_is_number ($4))
1948                 {
1949                         int q = scm_to_int ($4);
1950                         n->set_property ("absolute-octave", scm_from_int (q-1));
1951                 }
1952
1953                 if ($3 % 2)
1954                         n->set_property ("cautionary", SCM_BOOL_T);
1955                 if ($2 % 2 || $3 % 2)
1956                         n->set_property ("force-accidental", SCM_BOOL_T);
1957
1958                 n->set_spot (@$);
1959                 $$ = n->unprotect ();
1960         }
1961         | DRUM_PITCH optional_notemode_duration {
1962                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1963                 n->set_property ("duration", $2);
1964                 n->set_property ("drum-type", $1);
1965
1966                 $$ = n->unprotect ();
1967         }
1968         | RESTNAME optional_notemode_duration           {
1969                 Music *ev = 0;
1970                 if (ly_scm2string ($1) == "s") {
1971                         /* Space */
1972                         ev = MY_MAKE_MUSIC ("SkipEvent");
1973                   }
1974                 else {
1975                         ev = MY_MAKE_MUSIC ("RestEvent");
1976
1977                     }
1978                 ev->set_property ("duration", $2);
1979                 ev->set_spot (@$);
1980                 $$ = ev->unprotect ();
1981         }
1982         | lyric_element optional_notemode_duration      {
1983                 if (!PARSER->lexer_->is_lyric_state ())
1984                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1985
1986                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
1987                 levent->set_property ("text", $1);
1988                 levent->set_property ("duration",$2);
1989                 levent->set_spot (@$);
1990                 $$= levent->unprotect ();
1991         }
1992         ;
1993
1994 simple_chord_elements:
1995         simple_element  {
1996                 $$ = scm_list_1 ($1);
1997         }
1998         | new_chord {
1999                 if (!PARSER->lexer_->is_chord_state ())
2000                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2001                 $$ = $1;
2002         }
2003         | figure_spec optional_notemode_duration {
2004                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2005                 {
2006                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2007                 }
2008                 $$ = $1;
2009         }
2010         ;
2011
2012 lyric_element:
2013         lyric_markup {
2014                 $$ = $1;
2015         }
2016         | LYRICS_STRING {
2017                 $$ = $1;
2018         }
2019         ;
2020
2021 new_chord:
2022         steno_tonic_pitch optional_notemode_duration   {
2023                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2024         }
2025         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2026                 SCM its = scm_reverse_x ($4, SCM_EOL);
2027                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2028         }
2029         ;
2030
2031 chord_items:
2032         /**/ {
2033                 $$ = SCM_EOL;
2034         }
2035         | chord_items chord_item {
2036                 $$ = scm_cons ($2, $$);
2037         }
2038         ;
2039
2040 chord_separator:
2041         CHORD_COLON {
2042                 $$ = ly_symbol2scm ("chord-colon");
2043         }
2044         | CHORD_CARET {
2045                 $$ = ly_symbol2scm ("chord-caret");
2046         }
2047         | CHORD_SLASH steno_tonic_pitch {
2048                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2049         }
2050         | CHORD_BASS steno_tonic_pitch {
2051                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2052         }
2053         ;
2054
2055 chord_item:
2056         chord_separator {
2057                 $$ = $1;
2058         }
2059         | step_numbers {
2060                 $$ = scm_reverse_x ($1, SCM_EOL);
2061         }
2062         | CHORD_MODIFIER  {
2063                 $$ = $1;
2064         }
2065         ;
2066
2067 step_numbers:
2068         step_number { $$ = scm_cons ($1, SCM_EOL); }
2069         | step_numbers '.' step_number {
2070                 $$ = scm_cons ($3, $$);
2071         }
2072         ;
2073
2074 step_number:
2075         bare_unsigned {
2076                 $$ = make_chord_step ($1, 0);
2077         }
2078         | bare_unsigned '+' {
2079                 $$ = make_chord_step ($1, SHARP);
2080         }
2081         | bare_unsigned CHORD_MINUS {
2082                 $$ = make_chord_step ($1, FLAT);
2083         }
2084         ;
2085
2086 /*
2087         UTILITIES
2088
2089 TODO: should deprecate in favor of Scheme?
2090
2091  */
2092 number_expression:
2093         number_expression '+' number_term {
2094                 $$ = scm_sum ($1, $3);
2095         }
2096         | number_expression '-' number_term {
2097                 $$ = scm_difference ($1, $3);
2098         }
2099         | number_term
2100         ;
2101
2102 number_term:
2103         number_factor {
2104                 $$ = $1;
2105         }
2106         | number_factor '*' number_factor {
2107                 $$ = scm_product ($1, $3);
2108         }
2109         | number_factor '/' number_factor {
2110                 $$ = scm_divide ($1, $3);
2111         }
2112         ;
2113
2114 number_factor:
2115         '-'  number_factor { /* %prec UNARY_MINUS */
2116                 $$ = scm_difference ($2, SCM_UNDEFINED);
2117         }
2118         | bare_number
2119         ;
2120
2121
2122 bare_number:
2123         UNSIGNED        {
2124                 $$ = scm_from_int ($1);
2125         }
2126         | REAL          {
2127                 $$ = $1;
2128         }
2129         | NUMBER_IDENTIFIER             {
2130                 $$ = $1;
2131         }
2132         | REAL NUMBER_IDENTIFIER        {
2133                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2134         }
2135         | UNSIGNED NUMBER_IDENTIFIER    {
2136                 $$ = scm_from_double ($1 *scm_to_double ($2));
2137         }
2138         ;
2139
2140
2141 bare_unsigned:
2142         UNSIGNED {
2143                         $$ = $1;
2144         }
2145         | DIGIT {
2146                 $$ = $1;
2147         }
2148         ;
2149
2150 exclamations:
2151                 { $$ = 0; }
2152         | exclamations '!'      { $$ ++; }
2153         ;
2154
2155 questions:
2156                 { $$ = 0; }
2157         | questions '?' { $$ ++; }
2158         ;
2159
2160 /*
2161 This should be done more dynamically if possible.
2162 */
2163
2164 lyric_markup:
2165         LYRIC_MARKUP_IDENTIFIER {
2166                 $$ = $1;
2167         }
2168         | LYRIC_MARKUP
2169                 { PARSER->lexer_->push_markup_state (); }
2170         markup_top {
2171                 $$ = $3;
2172                 PARSER->lexer_->pop_state ();
2173         }
2174         ;
2175
2176 full_markup:
2177         MARKUP_IDENTIFIER {
2178                 $$ = $1;
2179         }
2180         | MARKUP
2181                 { PARSER->lexer_->push_markup_state (); }
2182         markup_top {
2183                 $$ = $3;
2184                 PARSER->lexer_->pop_state ();
2185         }
2186         ;
2187
2188 markup_top:
2189         markup_list {
2190                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2191         }
2192         | markup_head_1_list simple_markup      {
2193                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2194         }
2195         | simple_markup {
2196                 $$ = $1;
2197         }
2198         ;
2199
2200 markup_list:
2201         markup_composed_list {
2202                 $$ = $1;
2203         }
2204         | markup_braced_list {
2205                 $$ = $1;
2206         }
2207         ;
2208
2209 markup_composed_list:
2210         markup_head_1_list markup_braced_list {
2211                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2212
2213         }
2214         ;
2215
2216 markup_braced_list:
2217         '{' markup_braced_list_body '}' {
2218                 $$ = scm_reverse_x ($2, SCM_EOL);
2219         }
2220         ;
2221
2222 markup_braced_list_body:
2223         /* empty */     {  $$ = SCM_EOL; }
2224         | markup_braced_list_body markup {
2225                 $$ = scm_cons ($2, $1);
2226         }
2227         | markup_braced_list_body markup_list {
2228                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2229         }
2230         ;
2231
2232 markup_head_1_item:
2233         MARKUP_HEAD_MARKUP0     {
2234                 $$ = scm_list_1 ($1);
2235         }
2236         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2237                 $$ = scm_list_2 ($1, $2);
2238         }
2239         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2240                 $$ = scm_list_3 ($1, $2, $3);
2241         }
2242         ;
2243
2244 markup_head_1_list:
2245         markup_head_1_item      {
2246                 $$ = scm_list_1 ($1);
2247         }
2248         | markup_head_1_list markup_head_1_item {
2249                 $$ = scm_cons ($2, $1);
2250         }
2251         ;
2252
2253 simple_markup:
2254         STRING {
2255                 $$ = make_simple_markup ($1);
2256         }
2257         | MARKUP_IDENTIFIER {
2258                 $$ = $1;
2259         }
2260         | LYRIC_MARKUP_IDENTIFIER {
2261                 $$ = $1;
2262         }
2263         | STRING_IDENTIFIER {
2264                 $$ = $1;
2265         }
2266         | SCORE {
2267                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2268                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2269         } '{' score_body '}' {
2270                 Score * sc = $4;
2271                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2272                 sc->unprotect ();
2273                 PARSER->lexer_->pop_state ();
2274         }
2275         | MARKUP_HEAD_SCM0 embedded_scm {
2276                 $$ = scm_list_2 ($1, $2);
2277         }
2278         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2279                 $$ = scm_list_4 ($1, $2, $3, $4);
2280         }
2281         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2282                 $$ = scm_list_3 ($1, $2, $3);
2283         }
2284         | MARKUP_HEAD_EMPTY {
2285                 $$ = scm_list_1 ($1);
2286         }
2287         | MARKUP_HEAD_LIST0 markup_list {
2288                 $$ = scm_list_2 ($1,$2);
2289         }
2290         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2291                 $$ = scm_list_3 ($1, $2, $3);
2292         }
2293         ;
2294
2295 markup:
2296         markup_head_1_list simple_markup        {
2297                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2298                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2299         }
2300         | simple_markup {
2301                 $$ = $1;
2302         }
2303         ;
2304
2305 %%
2306
2307 void
2308 Lily_parser::set_yydebug (bool x)
2309 {
2310         yydebug = x;
2311 }
2312
2313 void
2314 Lily_parser::do_yyparse ()
2315 {
2316         yyparse ((void*)this);
2317 }
2318
2319
2320
2321
2322
2323 /*
2324
2325 It is a little strange to have this function in this file, but
2326 otherwise, we have to import music classes into the lexer.
2327
2328 */
2329 int
2330 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2331 {
2332         if (scm_is_string (sid)) {
2333                 *destination = sid;
2334                 return STRING_IDENTIFIER;
2335         } else if (unsmob_book (sid)) {
2336                 Book *book =  unsmob_book (sid)->clone ();
2337                 *destination = book->self_scm ();
2338                 book->unprotect ();
2339
2340                 return BOOK_IDENTIFIER;
2341         } else if (scm_is_number (sid)) {
2342                 *destination = sid;
2343                 return NUMBER_IDENTIFIER;
2344         } else if (unsmob_context_def (sid)) {
2345                 Context_def *def= unsmob_context_def (sid)->clone ();
2346
2347                 *destination = def->self_scm ();
2348                 def->unprotect ();
2349
2350                 return CONTEXT_DEF_IDENTIFIER;
2351         } else if (unsmob_score (sid)) {
2352                 Score *score = new Score (*unsmob_score (sid));
2353                 *destination = score->self_scm ();
2354
2355                 score->unprotect ();
2356                 return SCORE_IDENTIFIER;
2357         } else if (Music *mus = unsmob_music (sid)) {
2358                 mus = mus->clone ();
2359                 *destination = mus->self_scm ();
2360                 unsmob_music (*destination)->
2361                         set_property ("origin", make_input (last_input_));
2362
2363                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2364                         != SCM_BOOL_F;
2365
2366                 mus->unprotect ();
2367                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2368         } else if (unsmob_duration (sid)) {
2369                 *destination = unsmob_duration (sid)->smobbed_copy ();
2370                 return DURATION_IDENTIFIER;
2371         } else if (unsmob_output_def (sid)) {
2372                 Output_def *p = unsmob_output_def (sid);
2373                 p = p->clone ();
2374
2375                 *destination = p->self_scm ();
2376                 p->unprotect ();
2377                 return OUTPUT_DEF_IDENTIFIER;
2378         } else if (Text_interface::is_markup (sid)) {
2379                 *destination = sid;
2380                 if (is_lyric_state ())
2381                         return LYRIC_MARKUP_IDENTIFIER;
2382                 return MARKUP_IDENTIFIER;
2383         }
2384
2385         return -1;
2386 }
2387
2388 SCM
2389 get_next_unique_context_id ()
2390 {
2391         return scm_makfrom0str ("$uniqueContextId");
2392 }
2393
2394
2395 SCM
2396 get_next_unique_lyrics_context_id ()
2397 {
2398         static int new_context_count;
2399         char s[128];
2400         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2401         return scm_makfrom0str (s);
2402 }
2403
2404
2405 SCM
2406 run_music_function (Lily_parser *parser, SCM expr)
2407 {
2408         SCM func = scm_car (expr);
2409         Input *loc = unsmob_input (scm_cadr (expr));
2410         SCM args = scm_cddr (expr);
2411         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2412
2413         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2414
2415         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2416         {
2417                 parser->error_level_ = 1;
2418                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (*loc)));
2419         }
2420
2421         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (*loc), func, args);
2422         return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("music-function"), syntax_args);
2423 }
2424
2425 bool
2426 is_regular_identifier (SCM id)
2427 {
2428   string str = ly_scm2string (id);
2429   char const *s = str.c_str ();
2430
2431   bool v = true;
2432 #if 0
2433   isalpha (*s);
2434   s++;
2435 #endif
2436   while (*s && v)
2437    {
2438         v = v && isalnum (*s);
2439         s++;
2440    }
2441   return v;
2442 }
2443
2444
2445 SCM
2446 get_first_context_id (SCM type, Music *m)
2447 {
2448         SCM id = m->get_property ("context-id");
2449         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2450             && scm_is_string (m->get_property ("context-id"))
2451             && scm_c_string_length (id) > 0)
2452         {
2453                 return id;
2454         }
2455         return SCM_EOL;
2456 }
2457
2458 SCM
2459 make_simple_markup (SCM a)
2460 {
2461         return a;
2462 }
2463
2464 bool
2465 is_duration (int t)
2466 {
2467   return t && t == 1 << intlog2 (t);
2468 }
2469
2470 void
2471 set_music_properties (Music *p, SCM a)
2472 {
2473   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2474         p->internal_set_property (scm_caar (k), scm_cdar (k));
2475 }
2476
2477
2478 SCM
2479 make_chord_step (int step, int alter)
2480 {
2481         if (step == 7)
2482                 alter += FLAT;
2483
2484         while (step < 0)
2485                 step += 7;
2486         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2487         return m.smobbed_copy ();
2488 }
2489
2490
2491 SCM
2492 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2493 {
2494         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2495         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2496 }
2497
2498
2499 /* Todo: actually also use apply iso. call too ...  */
2500 bool
2501 ly_input_procedure_p (SCM x)
2502 {
2503         return ly_is_procedure (x)
2504                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2505 }
2506
2507 SCM
2508 make_music_relative (Pitch start, SCM music)
2509 {
2510         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2511         relative->set_property ("element", music);
2512
2513         Music *m = unsmob_music (music);
2514         Pitch last = m->to_relative_octave (start);
2515         if (lily_1_8_relative)
2516                 m->set_property ("last-pitch", last.smobbed_copy ());
2517         return relative->unprotect ();
2518 }
2519
2520 int
2521 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2522 {
2523         Lily_parser *pars = (Lily_parser*) v;
2524         Lily_lexer *lex = pars->lexer_;
2525
2526         lex->lexval = (void*) s;
2527         lex->lexloc = loc;
2528         lex->prepare_for_next_token ();
2529         return lex->yylex ();
2530 }