lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "scm-option.hh"
  29 #include "context-def.hh"
  30 #include "lily-guile.hh"
  31 #include "misc.hh"
  32 #include "my-lily-lexer.hh"
  33 #include "paper-def.hh"
  34 #include "midi-def.hh"
  35 #include "main.hh"
  36 #include "file-path.hh"
  37 #include "warn.hh"
  38 #include "dimensions.hh"
  39 #include "my-lily-parser.hh"
  40 #include "score.hh"
  41 #include "input-file-results.hh"
  42 #include "input.hh"
  43 #include "lilypond-input-version.hh"
  44 #include "scm-hash.hh"
  45 #include "ly-module.hh"
  46 #include "music-sequence.hh"
  47 #include "input-smob.hh"
  48 #include "event.hh"
  49 #include "text-item.hh"
  50 #include "music-list.hh"
  51 #include "paper-book.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 My_lily_parser* my_lily_parser;
  62 #define YYPARSE_PARAM my_lily_parser
  63 #define YYLEX_PARAM my_lily_parser
  64 #define THIS\
  65         ((My_lily_parser *) my_lily_parser)
  66
  67 #define yyerror THIS->parser_error
  68
  69 /* Add symbols to the TAGS field of a music object.  */
  70
  71 void
  72 tag_music (Music *m, SCM tag, Input ip)
  73 {
  74         SCM tags = m->get_property ("tags");
  75         if (gh_symbol_p (tag))
  76                 tags = scm_cons (tag, tags);
  77         else if (gh_list_p (tag))
  78                 tags = gh_append2 (tag, tags);
  79         else
  80                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  81
  82         m->set_property ("tags", tags);
  83 }
  84
  85
  86
  87 bool
  88 is_regular_identifier (SCM id)
  89 {
  90   String str = ly_scm2string (id);
  91   char const *s = str.to_str0 ();
  92
  93   bool v = true;
  94 #if 0
  95   isalpha (*s);
  96   s++;
  97 #endif
  98   while (*s && v)
  99    {
 100         v = v && isalnum (*s);
 101         s++;
 102    }
 103   return v;
 104 }
 105
 106 SCM
 107 make_simple_markup (SCM a)
 108 {
 109         SCM simple = ly_scheme_function ("simple-markup");
 110
 111         return scm_list_2 (simple, a);
 112 }
 113
 114
 115 bool
 116 is_is_duration (int t)
 117 {
 118   return t && t == 1 << intlog2 (t);
 119 }
 120
 121 void
 122 set_music_properties (Music *p, SCM a)
 123 {
 124   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 125         {
 126         p->internal_set_property (ly_caar (k), ly_cdar (k));
 127         }
 128 }
 129
 130 SCM
 131 make_chord_step (int step, int alter)
 132 {
 133         if (step == 7)
 134                 alter += FLAT;
 135
 136         while (step < 0)
 137                 step += 7;
 138         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 139         return m.smobbed_copy ();
 140 }
 141
 142
 143 SCM
 144 make_chord (SCM pitch, SCM dur, SCM modification_list)
 145 {
 146         SCM chord_ctor = ly_scheme_function ("construct-chord");
 147         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 148         scm_gc_protect_object (ch);
 149         return ch;
 150 }
 151
 152 /* Todo: actually also use apply iso. call too ...  */
 153 bool
 154 ly_input_procedure_p (SCM x)
 155 {
 156         return gh_procedure_p (x)
 157                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 158 }
 159
 160 Music*
 161 set_property_music (SCM sym, SCM value)
 162 {
 163         Music *p = MY_MAKE_MUSIC ("PropertySet");
 164         p->set_property ("symbol", sym);
 165         p->set_property ("value", value);
 166         return p;
 167 }
 168
 169 %}
 170
 171 /* We use SCMs to do strings, because it saves us the trouble of
 172 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 173 of the parse stack onto the heap. */
 174
 175
 176 %union {
 177         String *string;
 178     Music *music;
 179     Score *score;
 180     Music_output_def *outputdef;
 181     SCM scm;
 182     int i;
 183 }
 184 %{
 185
 186 int
 187 yylex (YYSTYPE *s, void *v)
 188 {
 189         My_lily_parser   *pars = (My_lily_parser*) v;
 190         My_lily_lexer *lex = pars->lexer_;
 191
 192         lex->lexval = (void*) s;
 193         lex->prepare_for_next_token ();
 194         return lex->yylex ();
 195 }
 196
 197
 198 %}
 199
 200 %expect 4
 201
 202 /*
 203   Four shift/reduce problems:
 204
 205 1.      foo = bar.
 206
 207         "bar" -> String -> Lyric -> Music -> music-assignment
 208
 209         "bar" -> String -> string-assignment
 210
 211
 212 Similar problem for
 213
 214 2. \markup identifier.
 215
 216 3. \markup { }
 217
 218 4.  \repeat
 219         \repeat .. \alternative
 220
 221
 222     \repeat { \repeat .. \alternative }
 223
 224 or
 225
 226     \repeat { \repeat } \alternative
 227
 228 )
 229
 230 --hwn
 231
 232  */
 233
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token ADDQUOTE
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token PARTIAL
 287 %token QUOTE
 288 %token RELATIVE
 289 %token REMOVE
 290 %token REPEAT
 291 %token REST
 292 %token SCM_T
 293 %token SCORE
 294 %token SEQUENTIAL
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 310 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 311 %token E_BACKSLASH
 312 %token <i> E_UNSIGNED
 313 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 314 %token FIGURE_SPACE
 315
 316 %type <i>       exclamations questions dots optional_rest
 317 %type <i>        bass_mod
 318 %type <scm>     grace_head
 319 %type <scm>     oct_check
 320 %type <scm>     context_mod_list
 321 %type <scm>     lyric_element
 322 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 323 %token <i>      DIGIT
 324 %token <scm>    NOTENAME_PITCH
 325 %token <scm>    TONICNAME_PITCH
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DURATION_IDENTIFIER
 328 %token <scm>    FRACTION
 329 %token <id>     IDENTIFIER
 330 %token DRUMS
 331 %token <scm>    DRUM_PITCH
 332 %token <scm>    CHORD_MODIFIER
 333 %token <scm>    SCORE_IDENTIFIER
 334 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    RESTNAME
 340 %token <scm>    STRING
 341 %token <scm>    SCM_T
 342 %token <i>      UNSIGNED
 343 %token <scm>   REAL
 344
 345 %token MARKUP
 346 %token <scm> MARKUP_HEAD_MARKUP0
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0
 350 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 357
 358 %type <outputdef> output_def
 359 %type <scm>     lilypond_header lilypond_header_body
 360 %type <music>   open_event close_event
 361 %type <i>       sub_quotes sup_quotes
 362 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 363 %type <music>   Repeated_music
 364 %type <scm>     Alternative_music
 365 %type <i>       tremolo_type
 366 %type <i>       bare_int  bare_unsigned
 367 %type <i>       script_dir
 368 %type <scm>     identifier_init
 369
 370 %type <music> note_chord_element chord_body chord_body_element
 371 %type <scm>  chord_body_elements
 372 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 373
 374 %type <scm>   post_events
 375 %type <music> gen_text_def direction_less_event direction_reqd_event
 376 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 377 %type <scm>    steno_tonic_pitch
 378 %type <scm>     duration_length fraction
 379
 380 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 381
 382 %type <scm>  embedded_scm scalar
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   relative_music re_rhythmed_music
 385 %type <music>   music_property_def context_change
 386 %type <scm> context_prop_spec
 387 %type <scm> Music_list
 388 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 389 %type <outputdef>  music_output_def_body music_output_def_head
 390 %type <music>   post_event tagged_post_event
 391 %type <music> command_req
 392 %type <music> string_number_event
 393 %type <scm>     string bare_number number_expression number_term number_factor
 394 %type <score>   score_block score_body
 395
 396 %type <scm>     context_def_spec_block context_def_spec_body
 397 %type <music>   tempo_event
 398 %type <scm>     script_abbreviation
 399
 400
 401
 402 %left '-' '+'
 403
 404 /* We don't assign precedence to / and *, because we might need varied
 405 prec levels in different prods */
 406
 407 %left UNARY_MINUS
 408
 409 %%
 410
 411 lilypond:       /* empty */
 412         | lilypond toplevel_expression {}
 413         | lilypond assignment  { }
 414         | lilypond error {
 415                 THIS->error_level_ = 1;
 416         }
 417         | lilypond INVALID      {
 418                 THIS->error_level_ = 1;
 419         }
 420         ;
 421
 422 toplevel_expression:
 423         lilypond_header {
 424                 THIS->input_file_->header_ = $1;
 425         }
 426         | add_quote {
 427         }
 428         | score_block {
 429                 Score *sc = $1;
 430
 431                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 432
 433                 Path p = split_path (THIS->output_basename_);
 434                 int *c = &THIS->input_file_->score_count_;
 435                 if (*c)
 436                         {
 437                         p.base += "-" + to_string (*c);
 438                         }
 439
 440                 (*c)++;
 441                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 442
 443                 for (int i = 0; i < sc->defs_.size (); i++)
 444                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 445
 446                 if (sc->defs_.is_empty ())
 447                 {
 448                    Music_output_def *id = unsmob_music_output_def
 449                         (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 450                    id = id ? id->clone () : new Paper_def;
 451                    default_rendering (sc->music_, id->self_scm (), head,
 452                         outname);
 453                    scm_gc_unprotect_object (id->self_scm ());
 454                 }
 455                 scm_gc_unprotect_object (sc->self_scm ());
 456         }
 457         | output_def {
 458                 SCM id = SCM_EOL;
 459                 if (dynamic_cast<Paper_def*> ($1))
 460                         id = scm_makfrom0str ("$defaultpaper");
 461                 else if (dynamic_cast<Midi_def*> ($1))
 462                         id = scm_makfrom0str ("$defaultmidi");
 463                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 464                 scm_gc_unprotect_object ($1->self_scm ());
 465         }
 466         ;
 467
 468
 469 embedded_scm:
 470         SCM_T
 471         | SCM_IDENTIFIER
 472         ;
 473
 474
 475
 476
 477 lilypond_header_body:
 478         {
 479                 $$ = ly_make_anonymous_module ();
 480                 THIS->lexer_->add_scope ($$);
 481         }
 482         | lilypond_header_body assignment  {
 483
 484         }
 485         ;
 486
 487 lilypond_header:
 488         HEADER '{' lilypond_header_body '}'     {
 489                 $$ = THIS->lexer_->remove_scope ();
 490         }
 491         ;
 492
 493
 494 /*
 495         DECLARATIONS
 496 */
 497 assignment:
 498         STRING {
 499                 THIS->push_spot ();
 500         }
 501         /* cont */ '=' identifier_init  {
 502
 503         /*
 504                 Should find generic way of associating input with objects.
 505         */
 506                 Input ip = THIS->pop_spot ();
 507
 508                 if (! is_regular_identifier ($1))
 509                 {
 510                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 511                 }
 512
 513                 THIS->lexer_->set_identifier ($1, $4);
 514
 515 /*
 516  TODO: devise standard for protection in parser.
 517
 518   The parser stack lives on the C-stack, which means that
 519 all objects can be unprotected as soon as they're here.
 520
 521 */
 522         }
 523         | embedded_scm { }
 524         ;
 525
 526
 527 identifier_init:
 528         score_block {
 529                 $$ = $1->self_scm ();
 530                 scm_gc_unprotect_object ($$);
 531         }
 532         | full_markup {
 533                 $$ = $1;
 534         }
 535         | output_def {
 536                 $$ = $1->self_scm ();
 537                 scm_gc_unprotect_object ($$);
 538         }
 539         | context_def_spec_block {
 540                 $$ = $1;
 541         }
 542         | Music  {
 543                 $$ = $1->self_scm ();
 544                 scm_gc_unprotect_object ($$);
 545         }
 546         | post_event {
 547                 $$ = $1->self_scm ();
 548                 scm_gc_unprotect_object ($$);
 549         }
 550         | number_expression {
 551                 $$ = $1;
 552         }
 553         | string {
 554                 $$ = $1;
 555         }
 556         | embedded_scm  {
 557                 $$ = $1;
 558         }
 559         ;
 560
 561 context_def_spec_block:
 562         CONTEXT '{' context_def_spec_body '}'
 563                 {
 564                 $$ = $3;
 565         }
 566         ;
 567
 568 context_def_spec_body:
 569         /**/ {
 570                 $$ = Context_def::make_scm ();
 571                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 572         }
 573         | CONTEXT_DEF_IDENTIFIER        {
 574                 $$ = $1;
 575                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 576         }
 577         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 578                 Context_def*td = unsmob_context_def ($$);
 579
 580                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 581                         SCM tag = gh_caar (p);
 582
 583                         /* TODO: should make new tag "grob-definition" ? */
 584                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 585                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 586                 }
 587         }
 588         | context_def_spec_body context_mod {
 589                 unsmob_context_def ($$)->add_context_mod ($2);
 590         }
 591         ;
 592
 593 /*
 594         SCORE
 595 */
 596 score_block:
 597         SCORE {
 598                 THIS->push_spot ();
 599         }
 600         /*cont*/ '{' score_body '}'     {
 601                 THIS->pop_spot ();
 602                 $$ = $4;
 603
 604         }
 605         ;
 606
 607 score_body:
 608         Music   {
 609                 $$ = new Score;
 610
 611                 $$->set_spot (THIS->here_input ());
 612                 SCM m = $1->self_scm ();
 613                 scm_gc_unprotect_object (m);
 614
 615                 /*
 616                         guh.
 617                 */
 618                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 619                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 620                         m = gh_call1 (gh_car (check_funcs), m);
 621                 $$->music_ = m;
 622
 623         }
 624         | SCORE_IDENTIFIER {
 625                 $$ = new Score ( *unsmob_score ($1));
 626                 $$->set_spot (THIS->here_input ());
 627         }
 628         | score_body lilypond_header    {
 629                 $$->header_ = $2;
 630         }
 631         | score_body output_def {
 632                 $$->defs_.push ($2);
 633                 scm_gc_unprotect_object ($2->self_scm ());
 634         }
 635         | score_body error {
 636
 637         }
 638         ;
 639
 640
 641 /*
 642         MIDI
 643 */
 644 output_def:
 645         music_output_def_body '}' {
 646                 $$ = $1;
 647                 THIS-> lexer_-> remove_scope ();
 648         }
 649         ;
 650
 651 music_output_def_head:
 652         MIDI    {
 653                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 654
 655
 656                 Midi_def *p = 0;
 657                 if (id)
 658                         p = dynamic_cast<Midi_def*> (id->clone ());
 659                 else
 660                         p = new Midi_def;
 661
 662                 $$ = p;
 663                 THIS->lexer_->add_scope (p->scope_);
 664         }
 665         | PAPER         {
 666                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 667                   Paper_def *p = 0;
 668                 if (id)
 669                         p = dynamic_cast<Paper_def*> (id->clone ());
 670                 else
 671                         p = new Paper_def;
 672
 673                 THIS->lexer_->add_scope (p->scope_);
 674                 $$ = p;
 675         }
 676         ;
 677
 678
 679 music_output_def_body:
 680         music_output_def_head '{' {
 681                 $$ = $1;
 682                 $$->input_origin_. set_spot (THIS->here_input ());
 683
 684         }
 685         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 686                 scm_gc_unprotect_object ($1->self_scm ());
 687                 Music_output_def *o = unsmob_music_output_def ($3);
 688                 o->input_origin_.set_spot (THIS->here_input ());
 689                 $$ = o;
 690                 THIS->lexer_->remove_scope ();
 691                 THIS->lexer_->add_scope (o->scope_);
 692         }
 693         | music_output_def_body assignment  {
 694
 695         }
 696         | music_output_def_body context_def_spec_block  {
 697                 $$->assign_context_def ($2);
 698         }
 699         | music_output_def_body tempo_event  {
 700                 /*
 701                         junk this ? there already is tempo stuff in
 702                         music.
 703                 */
 704                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 705                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 706                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 707                 if (md)
 708                         md->set_tempo (d->get_length (), m);
 709                 scm_gc_unprotect_object ($2->self_scm ());
 710         }
 711         | music_output_def_body error {
 712
 713         }
 714         ;
 715
 716 tempo_event:
 717         TEMPO steno_duration '=' bare_unsigned  {
 718                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 719                 $$->set_property ("tempo-unit", $2);
 720                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 721         }
 722         ;
 723
 724 /*
 725 The representation of a  list is the
 726
 727   (LIST . LAST-CONS)
 728
 729  to have  efficient append.
 730 */
 731 Music_list:
 732         /* empty */ {
 733                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 734         }
 735         | Music_list Music {
 736                 SCM s = $$;
 737                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 738                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 739                 if (gh_pair_p (ly_cdr (s)))
 740                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 741                 else
 742                         gh_set_car_x (s, c); /* set first cons */
 743                 gh_set_cdr_x (s, c);  /* remember last cell */
 744         }
 745         | Music_list error {
 746         }
 747         ;
 748
 749
 750 Music:
 751         Simple_music
 752         | Composite_music
 753         ;
 754
 755 Alternative_music:
 756         /* empty */ {
 757                 $$ = SCM_EOL;
 758         }
 759         | ALTERNATIVE '{' Music_list '}' {
 760                 $$ = $3;
 761         }
 762         ;
 763
 764 Repeated_music:
 765         REPEAT string bare_unsigned Music Alternative_music
 766         {
 767                 Music *beg = $4;
 768                 int times = $3;
 769                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 770                 if (times < scm_ilength (alts)) {
 771                   unsmob_music (gh_car (alts))
 772                     ->origin ()->warning (
 773                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 774                   alts = ly_truncate_list (times, alts);
 775                 }
 776
 777
 778                 SCM proc = ly_scheme_function ("make-repeated-music");
 779
 780                 SCM mus = scm_call_1 (proc, $2);
 781                 scm_gc_protect_object (mus); // UGH.
 782                 Music *r = unsmob_music (mus);
 783                 if (beg)
 784                         {
 785                         r-> set_property ("element", beg->self_scm ());
 786                         scm_gc_unprotect_object (beg->self_scm ());
 787                         }
 788                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 789
 790                 r-> set_property ("elements",alts);
 791                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 792                         /*
 793                         TODO: move this code to Scheme.
 794                         */
 795
 796                         /*
 797                         we can not get durations and other stuff correct down the line, so we have to
 798                         add to the duration log here.
 799                         */
 800                         SCM func = ly_scheme_function ("shift-duration-log");
 801
 802                         int dots = ($3 % 3) ? 0 : 1;
 803                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 804
 805                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 806
 807                         if (seq) {
 808                                 int list_len = scm_ilength (seq->music_list ());
 809                                 if (list_len != 2)
 810                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 811                                 shift -= 1;
 812                                 r->compress (Moment (Rational (1, list_len)));
 813                                 }
 814                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 815
 816                 }
 817                 r->set_spot (*$4->origin ());
 818
 819                 $$ = r;
 820         }
 821         ;
 822
 823 Sequential_music:
 824         SEQUENTIAL '{' Music_list '}'           {
 825                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 826                 $$->set_property ("elements", ly_car ($3));
 827                 $$->set_spot (THIS->here_input ());
 828         }
 829         | '{' Music_list '}'            {
 830                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 831                 $$->set_property ("elements", ly_car ($2));
 832                 $$->set_spot (THIS->here_input ());
 833         }
 834         ;
 835
 836 Simultaneous_music:
 837         SIMULTANEOUS '{' Music_list '}'{
 838                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 839                 $$->set_property ("elements", ly_car ($3));
 840                 $$->set_spot (THIS->here_input ());
 841
 842         }
 843         | simul_open Music_list simul_close     {
 844                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 845                 $$->set_property ("elements", ly_car ($2));
 846                 $$->set_spot (THIS->here_input ());
 847         }
 848         ;
 849
 850 Simple_music:
 851         event_chord             { $$ = $1; }
 852         | APPLYOUTPUT embedded_scm {
 853                 if (!ly_input_procedure_p ($2))
 854                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 855                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 856                 $$->set_property ("procedure", $2);
 857                 $$->set_spot (THIS->here_input ());
 858         }
 859         | APPLYCONTEXT embedded_scm {
 860                 if (!ly_input_procedure_p ($2))
 861                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 862                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 863                 $$->set_property ("procedure", $2);
 864                 $$->set_spot (THIS->here_input ());
 865         }
 866         | MUSIC_IDENTIFIER {
 867                 $$ = unsmob_music ($1);
 868         }
 869         | music_property_def
 870         | context_change
 871         ;
 872
 873
 874 optional_context_mod:
 875         /**/ { $$ = SCM_EOL; }
 876         | WITH '{' context_mod_list '}'  { $$ = $3; }
 877         ;
 878
 879 grace_head:
 880         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 881         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 882         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 883         ;
 884
 885 context_mod_list:
 886         /* */  { $$ = SCM_EOL; }
 887         | context_mod_list context_mod  {
 888                  $$ = gh_cons ($2, $1);
 889         }
 890         ;
 891
 892 Composite_music:
 893         AUTOCHANGE Music        {
 894                 SCM proc = ly_scheme_function ("make-autochange-music");
 895
 896                 SCM res = scm_call_1 (proc, $2->self_scm ());
 897                 scm_gc_unprotect_object ($2->self_scm ());
 898                 $$ = unsmob_music (res);
 899                 scm_gc_protect_object (res);
 900                 $$->set_spot (THIS->here_input ());
 901         }
 902         | PARTCOMBINE Music Music {
 903                 SCM proc = ly_scheme_function ("make-part-combine-music");
 904
 905                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 906                         $3->self_scm (), SCM_UNDEFINED));
 907                 scm_gc_unprotect_object ($3->self_scm ());
 908                 scm_gc_unprotect_object ($2->self_scm ());
 909                 $$ = unsmob_music (res);
 910                 scm_gc_protect_object (res);
 911                 $$->set_spot (THIS->here_input ());
 912         }
 913         | grace_head Music {
 914 #if 1
 915         /*
 916                 The other version is for easier debugging  of
 917                 Sequential_music_iterator in combination with grace notes.
 918         */
 919
 920 /*
 921
 922 TODO: should distinguish between both grace types in the
 923 basic music objects too, since the meaning is different.
 924
 925 */
 926
 927                 String start_str = "start" + ly_scm2string ($1) + "Music";
 928                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 929
 930                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 931                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 932
 933                 Music *startm = unsmob_music (start);
 934                 Music *stopm = unsmob_music (stop);
 935
 936                 SCM ms = SCM_EOL;
 937                 if (stopm) {
 938                         stopm = stopm->clone ();
 939                         ms = scm_cons (stopm->self_scm (), ms);
 940                         scm_gc_unprotect_object (stopm->self_scm ());
 941                 }
 942                 ms = scm_cons ($2->self_scm (), ms);
 943                 scm_gc_unprotect_object ($2->self_scm ());
 944                 if (startm) {
 945                         startm = startm->clone ();
 946                         ms = scm_cons (startm->self_scm (), ms);
 947                         scm_gc_unprotect_object (startm->self_scm ());
 948                 }
 949
 950                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 951                 seq->set_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 955                 $$->set_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 959                 $$->set_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string optional_context_mod Music {
 964                 $$ = context_spec_music ($2, $4, $6, $5);
 965
 966         }
 967         | CONTEXT STRING optional_context_mod Music {
 968                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 969         }
 970         | NEWCONTEXT string optional_context_mod Music {
 971                 $$ = context_spec_music ($2, get_next_unique_context (),
 972                                          $4, $3);
 973         }
 974
 975         | TIMES {
 976                 THIS->push_spot ();
 977         }
 978         /* CONTINUED */
 979                 fraction Music
 980
 981         {
 982                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 983                 Music *mp = $4;
 984
 985                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 986                 $$->set_spot (THIS->pop_spot ());
 987
 988                 $$->set_property ("element", mp->self_scm ());
 989                 scm_gc_unprotect_object (mp->self_scm ());
 990                 $$->set_property ("numerator", gh_int2scm (n));
 991                 $$->set_property ("denominator", gh_int2scm (d));
 992                 $$->compress (Moment (Rational (n,d)));
 993
 994         }
 995         | Repeated_music                { $$ = $1; }
 996         | Simultaneous_music            { $$ = $1; }
 997         | Sequential_music              { $$ = $1; }
 998         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 999                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1000                 Music *p = $4;
1001                 Pitch from = *unsmob_pitch ($2);
1002                 Pitch to = *unsmob_pitch ($3);
1003
1004                 p->transpose (interval (from, to));
1005                 $$->set_property ("element", p->self_scm ());
1006                 scm_gc_unprotect_object (p->self_scm ());
1007         }
1008         | APPLY embedded_scm Music  {
1009                 if (!ly_input_procedure_p ($2))
1010                         {
1011                         THIS->parser_error (_ ("\\apply takes function argument"));
1012                         $$ = $3;
1013                         }
1014                 else
1015                         {
1016                         SCM ret = gh_call1 ($2, $3->self_scm ());
1017                         Music *m = unsmob_music (ret);
1018                         if (!m) {
1019                                 THIS->parser_error ("\\apply must return a Music");
1020                                 m = MY_MAKE_MUSIC ("Music");
1021                                 }
1022                         $$ = m;
1023                         }
1024         }
1025         | NOTES
1026                 {
1027                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1028                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1029         }
1030         Music
1031                 { $$ = $3;
1032                   THIS->lexer_->pop_state ();
1033                 }
1034         | DRUMS
1035                 {
1036                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1037                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1038         }
1039         Music
1040                 { $$ = $3;
1041                   THIS->lexer_->pop_state ();
1042                 }
1043         | FIGURES
1044                 { THIS->lexer_->push_figuredbass_state (); }
1045         Music
1046                 {
1047                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1048                   chm->set_property ("element", $3->self_scm ());
1049                   $$ = chm;
1050                   scm_gc_unprotect_object ($3->self_scm ());
1051
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | CHORDS {
1055                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1056                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1057                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1058                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1059
1060         } Music {
1061                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1062                   chm->set_property ("element", $3->self_scm ());
1063                   scm_gc_unprotect_object ($3->self_scm ());
1064                   $$ = chm;
1065
1066                   THIS->lexer_->pop_state ();
1067         }
1068         | LYRICS
1069                 { THIS->lexer_->push_lyric_state (); }
1070         Music
1071                 {
1072                   $$ = $3;
1073                   THIS->lexer_->pop_state ();
1074         }
1075         | relative_music        { $$ = $1; }
1076         | re_rhythmed_music     { $$ = $1; }
1077         | TAG embedded_scm Music {
1078                 tag_music ($3, $2, THIS->here_input ());
1079                 $$ = $3;
1080         }
1081         ;
1082
1083 relative_music:
1084         RELATIVE absolute_pitch Music {
1085                 Music *p = $3;
1086                 Pitch pit = *unsmob_pitch ($2);
1087                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1088
1089                 $$->set_property ("element", p->self_scm ());
1090                 scm_gc_unprotect_object (p->self_scm ());
1091
1092
1093                 Pitch retpitch = p->to_relative_octave (pit);
1094                 if (lily_1_8_relative)
1095                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1096         }
1097         ;
1098
1099 re_rhythmed_music:
1100         ADDLYRICS Music Music {
1101         Music *l = MY_MAKE_MUSIC ("LyricCombineMusic");
1102           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1103           scm_gc_unprotect_object ($3->self_scm ());
1104           scm_gc_unprotect_object ($2->self_scm ());
1105           $$ = l;
1106         }
1107         | NEWADDLYRICS string Music {
1108           Music *l = MY_MAKE_MUSIC ("NewLyricCombineMusic");
1109           l->set_property ("element", $3->self_scm ());
1110           scm_gc_unprotect_object ($3->self_scm ());
1111           $$ = l;
1112           l->set_property ("associated-context", $2);
1113         }
1114         ;
1115
1116 context_change:
1117         CHANGE STRING '=' STRING  {
1118                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1119                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1120                 t-> set_property ("change-to-id", $4);
1121
1122                 $$ = t;
1123                 $$->set_spot (THIS->here_input ());
1124         }
1125         ;
1126
1127 property_operation:
1128         STRING '='  scalar {
1129                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1130                         scm_string_to_symbol ($1), $3);
1131         }
1132         | UNSET STRING {
1133                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1134                         scm_string_to_symbol ($2));
1135         }
1136         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1137                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1138                         scm_string_to_symbol ($2), $3, $5);
1139         }
1140         | REVERT STRING embedded_scm {
1141                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1142                         scm_string_to_symbol ($2), $3);
1143         }
1144         ;
1145
1146 context_def_mod:
1147         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1148         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1149         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1150
1151         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1152         | DENIES { $$ = ly_symbol2scm ("denies"); }
1153
1154         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1155         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1156         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1157         | NAME { $$ = ly_symbol2scm ("context-name"); }
1158         ;
1159
1160 context_mod:
1161         property_operation { $$ = $1; }
1162         | context_def_mod STRING {
1163                 $$ = scm_list_2 ($1, $2);
1164         }
1165         ;
1166
1167 context_prop_spec:
1168         STRING  {
1169                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1170         }
1171         | STRING '.' STRING {
1172                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1173         }
1174         ;
1175
1176 music_property_def:
1177         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1178                 $$ = property_op_to_music (scm_list_4 (
1179                         ly_symbol2scm ("poppush"),
1180                         gh_cadr ($2),
1181                         $3, $5));
1182                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1183         }
1184         | REVERT context_prop_spec embedded_scm {
1185                 $$ = property_op_to_music (scm_list_3 (
1186                         ly_symbol2scm ("pop"),
1187                         gh_cadr ($2),
1188                         $3));
1189
1190                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1191         }
1192         | SET context_prop_spec '=' scalar {
1193                 $$ = property_op_to_music (scm_list_3 (
1194                         ly_symbol2scm ("assign"),
1195                         gh_cadr ($2),
1196                         $4));
1197                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1198         }
1199         | UNSET context_prop_spec {
1200                 $$ = property_op_to_music (scm_list_2 (
1201                         ly_symbol2scm ("unset"),
1202                         gh_cadr ($2)));
1203                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1204         }
1205         | ONCE music_property_def {
1206                 SCM e = $2->get_property ("element");
1207                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1208                 $$ = $2;
1209
1210         }
1211         ;
1212
1213
1214
1215 scalar:
1216         string          { $$ = $1; }
1217         | bare_int      { $$ = gh_int2scm ($1); }
1218         | embedded_scm  { $$ = $1; }
1219         | full_markup {  $$ = $1; }
1220         | DIGIT { $$ = gh_int2scm ($1); }
1221         ;
1222
1223 /*
1224 This is a trick:
1225
1226 Adding pre_events to the simple_element
1227 makes the choice between
1228
1229   string:  STRING
1230
1231 and
1232
1233   simple_element: STRING
1234
1235 a single shift/reduction conflict.
1236
1237 nevertheless, this is not very clean, and we should find a different
1238 solution.
1239
1240 */
1241 pre_events: {
1242                 THIS->push_spot ();
1243         }
1244         ;
1245
1246 event_chord:
1247         pre_events simple_element post_events   {
1248                 SCM elts = $2-> get_property ("elements");
1249
1250                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1251
1252                 $2->set_property ("elements", elts);
1253                 $$ = $2;
1254         }
1255         | command_element
1256         | note_chord_element
1257         ;
1258
1259
1260 note_chord_element:
1261         chord_body optional_notemode_duration post_events
1262         {
1263                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1264                 SCM es = $1->get_property ("elements");
1265                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1266
1267                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1268                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1269                 es = gh_append2 (es, postevs);
1270
1271                 $1-> set_property ("elements", es);
1272                 $$ = $1;
1273         }
1274         ;
1275
1276 chord_open: '<'
1277         ;
1278
1279 chord_close: '>'
1280         ;
1281
1282 simul_open: LESSLESS
1283         ;
1284
1285 simul_close: MOREMORE
1286         ;
1287
1288 chord_body:
1289         chord_open chord_body_elements chord_close
1290         {
1291                 $$ = MY_MAKE_MUSIC ("EventChord");
1292                 $$->set_property ("elements",
1293                         scm_reverse_x ($2, SCM_EOL));
1294         }
1295         ;
1296
1297 chord_body_elements:
1298         /* empty */             { $$ = SCM_EOL; }
1299         | chord_body_elements chord_body_element {
1300                 $$ = gh_cons ($2->self_scm (), $1);
1301                 scm_gc_unprotect_object ($2->self_scm ());
1302         }
1303         ;
1304
1305 chord_body_element:
1306         pitch exclamations questions post_events
1307         {
1308                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1309                 n->set_property ("pitch", $1);
1310                 if ($3 % 2)
1311                         n->set_property ("cautionary", SCM_BOOL_T);
1312                 if ($2 % 2 || $3 % 2)
1313                         n->set_property ("force-accidental", SCM_BOOL_T);
1314
1315                 if (gh_pair_p ($4)) {
1316                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1317                         n->set_property ("articulations", arts);
1318                 }
1319                 $$ = n;
1320         }
1321         | DRUM_PITCH post_events {
1322                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1323                 n->set_property ("duration", $2);
1324                 n->set_property ("drum-type", $1);
1325                 n->set_spot (THIS->here_input ());
1326
1327                 if (gh_pair_p ($2)) {
1328                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1329                         n->set_property ("articulations", arts);
1330                 }
1331                 $$ = n;
1332         }
1333         ;
1334
1335 add_quote:
1336         ADDQUOTE string Music {
1337                 SCM adder = ly_scheme_function ("add-quotable");
1338
1339                 scm_call_2 (adder, $2, $3->self_scm ());
1340                 scm_gc_unprotect_object ($3->self_scm ());
1341         }
1342         ;
1343
1344 command_element:
1345         command_req {
1346                 $$ = MY_MAKE_MUSIC ("EventChord");
1347                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1348                 scm_gc_unprotect_object ($1->self_scm ());
1349
1350                 $$-> set_spot (THIS->here_input ());
1351                 $1-> set_spot (THIS->here_input ());
1352         }
1353         | SKIP duration_length {
1354                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1355                 skip->set_property ("duration", $2);
1356
1357                 $$ = skip;
1358         }
1359         | QUOTE STRING duration_length {
1360                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1361                 SCM evs = SCM_EOL;
1362                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1363                 {
1364                         SCM key = $2; // use symbol?
1365                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1366                 }
1367                 Music *quote = 0;
1368                 if (gh_vector_p (evs))
1369                 {
1370                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1371                         quote->set_property ("duration", $3);
1372                         quote->set_property ("quoted-events", evs);
1373                 } else {
1374                         THIS->here_input ().warning (_f ("Can\'t find music"));
1375                         quote = MY_MAKE_MUSIC ("Event");
1376                 }
1377                 quote->set_spot (THIS->here_input ());
1378                 $$ = quote;
1379         }
1380         | OCTAVE { THIS->push_spot (); }
1381           pitch {
1382                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1383                 $$ = l;
1384                 $$->set_spot (THIS->pop_spot ());
1385                 $$->set_property ("pitch", $3);
1386         }
1387         | E_LEFTSQUARE {
1388                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1389                 l->set_property ("span-direction", gh_int2scm (START));
1390                 l->set_spot (THIS->here_input ());
1391
1392                 $$ = MY_MAKE_MUSIC ("EventChord");
1393                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1394                 scm_gc_unprotect_object (l->self_scm ());
1395                 $$->set_spot (THIS->here_input ());
1396         }
1397         | E_RIGHTSQUARE {
1398                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1399                 l->set_property ("span-direction", gh_int2scm (STOP));
1400                 l->set_spot (THIS->here_input ());
1401
1402                 $$ = MY_MAKE_MUSIC ("EventChord");
1403                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1404                 $$->set_spot (THIS->here_input ());
1405                 scm_gc_unprotect_object (l->self_scm ());
1406         }
1407         | E_BACKSLASH {
1408                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1409                 $$->set_spot (THIS->here_input ());
1410         }
1411         | '|'      {
1412
1413                 $$ = MY_MAKE_MUSIC ("BarCheck");
1414                 $$->set_spot (THIS->here_input ());
1415         }
1416         | TRANSPOSITION pitch {
1417                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1418                                         $2);
1419                 $$->set_spot (THIS-> here_input ());
1420                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1421                         $$, SCM_EOL);
1422         }
1423         | BAR STRING                    {
1424                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1425
1426                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1427                                         t, SCM_EOL);
1428                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1429                 $$->set_spot (THIS->here_input ());
1430                 t->set_spot (THIS->here_input ());
1431         }
1432         | PARTIAL duration_length       {
1433                 Moment m = - unsmob_duration ($2)->get_length ();
1434                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1435                 p->set_spot (THIS->here_input ());
1436                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1437                                         p, SCM_EOL);
1438                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1439                                         p, SCM_EOL);
1440                 $$ = p;
1441         }
1442         | CLEF STRING  {
1443                 SCM proc = ly_scheme_function ("make-clef-set");
1444
1445                 SCM result = scm_call_1 (proc, $2);
1446                 scm_gc_protect_object (result);
1447                 $$ = unsmob_music (result);
1448         }
1449         | TIME_T fraction  {
1450                 SCM proc= ly_scheme_function ("make-time-signature-set");
1451
1452                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1453                 scm_gc_protect_object (result);
1454                 $$ = unsmob_music (result);
1455         }
1456         | MARK scalar {
1457                 SCM proc = ly_scheme_function ("make-mark-set");
1458
1459                 SCM result = scm_call_1 (proc, $2);
1460                 scm_gc_protect_object (result);
1461                 $$ = unsmob_music (result);
1462         }
1463         ;
1464
1465 command_req:
1466         BREATHE {
1467                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1468         }
1469         | E_TILDE {
1470                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1471         }
1472         | MARK DEFAULT  {
1473                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1474                 $$ = m;
1475         }
1476         | tempo_event {
1477                 $$ = $1;
1478         }
1479         | KEY DEFAULT {
1480                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1481                 $$ = key;
1482         }
1483         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1484
1485                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1486                 if (scm_ilength ($3) > 0)
1487                 {
1488                         key->set_property ("pitch-alist", $3);
1489                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1490                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1491                 } else {
1492                         THIS->parser_error (_ ("Second argument must be pitch list."));
1493                 }
1494
1495                 $$ = key;
1496         }
1497         ;
1498
1499 post_events:
1500         /* empty */ {
1501                 $$ = SCM_EOL;
1502         }
1503         | post_events post_event {
1504                 $2->set_spot (THIS->here_input ());
1505                 $$ = gh_cons ($2->self_scm (), $$);
1506                 scm_gc_unprotect_object ($2->self_scm ());
1507         }
1508         | post_events tagged_post_event {
1509                 $2 -> set_spot (THIS->here_input ());
1510                 $$ = scm_cons ($2->self_scm (), $$);
1511                 scm_gc_unprotect_object ($2->self_scm ());
1512         }
1513         ;
1514
1515
1516 tagged_post_event:
1517         '-' TAG embedded_scm post_event {
1518                 tag_music ($4, $3, THIS->here_input ());
1519                 $$ = $4;
1520         }
1521         ;
1522
1523 post_event:
1524         direction_less_event {
1525                 $$ = $1;
1526         }
1527         | HYPHEN {
1528                 if (!THIS->lexer_->is_lyric_state ())
1529                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1530                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1531         }
1532         | EXTENDER {
1533                 if (!THIS->lexer_->is_lyric_state ())
1534                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1535                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1536         }
1537         | script_dir direction_reqd_event {
1538                 if ($1)
1539                         $2->set_property ("direction", gh_int2scm ($1));
1540                 $$ = $2;
1541         }
1542         | script_dir direction_less_event {
1543                 if ($1)
1544                         $2->set_property ("direction", gh_int2scm ($1));
1545                 $$ = $2;
1546         }
1547         | string_number_event
1548         ;
1549
1550 string_number_event:
1551         E_UNSIGNED {
1552                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1553                 s->set_property ("string-number", gh_int2scm ($1));
1554                 s->set_spot (THIS->here_input ());
1555                 $$ = s;
1556         }
1557         ;
1558
1559
1560 direction_less_event:
1561         '['  {
1562
1563
1564 /*
1565
1566 TODO: should take all these defs out of the parser, adn make use
1567 configurable, i.e.
1568
1569
1570 (set-articulation '~ "trill")
1571
1572 */
1573                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1574                 m->set_spot (THIS->here_input ());
1575                 m->set_property ("span-direction", gh_int2scm (START));
1576                 $$ = m;
1577         }
1578         | ']'  {
1579                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1580                 m->set_spot (THIS->here_input ());
1581                 m->set_property ("span-direction", gh_int2scm (STOP));
1582                 $$ = m;
1583         }
1584         | '~' {
1585                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1586                 m->set_spot (THIS->here_input ());
1587                 $$ = m;
1588         }
1589         | close_event {
1590                 $$ = $1;
1591                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1592                         gh_int2scm (START));
1593         }
1594         | open_event {
1595                 $$ = $1;
1596                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1597                         gh_int2scm (STOP));
1598         }
1599         | EVENT_IDENTIFIER      {
1600                 $$ = unsmob_music ($1);
1601         }
1602         | tremolo_type  {
1603                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1604                a->set_spot (THIS->here_input ());
1605                a->set_property ("tremolo-type", gh_int2scm ($1));
1606                $$ = a;
1607         }
1608         ;
1609
1610 direction_reqd_event:
1611         gen_text_def {
1612                 $$ = $1;
1613         }
1614         | script_abbreviation {
1615                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1616                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1617                 if (gh_string_p (s))
1618                         a->set_property ("articulation-type", s);
1619                 else THIS->parser_error (_ ("Expecting string as script definition"));
1620                 $$ = a;
1621         }
1622         ;
1623
1624 oct_check:
1625         /**/ { $$ = SCM_EOL; }
1626         | '='  { $$ = gh_int2scm (0); }
1627         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1628         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1629         ;
1630
1631 sup_quotes:
1632         '\'' {
1633                 $$ = 1;
1634         }
1635         | sup_quotes '\'' {
1636                 $$ ++;
1637         }
1638         ;
1639
1640 sub_quotes:
1641         ',' {
1642                 $$ = 1;
1643         }
1644         | sub_quotes ',' {
1645                 $$++;
1646         }
1647         ;
1648
1649 steno_pitch:
1650         NOTENAME_PITCH  {
1651                 $$ = $1;
1652         }
1653         | NOTENAME_PITCH sup_quotes     {
1654                 Pitch p = *unsmob_pitch ($1);
1655                 p = p.transposed (Pitch ($2,0,0));
1656                 $$ = p.smobbed_copy ();
1657         }
1658         | NOTENAME_PITCH sub_quotes      {
1659                 Pitch p =* unsmob_pitch ($1);
1660                 p = p.transposed (Pitch (-$2,0,0));
1661                 $$ = p.smobbed_copy ();
1662         }
1663         ;
1664
1665 /*
1666 ugh. duplication
1667 */
1668
1669 steno_tonic_pitch:
1670         TONICNAME_PITCH {
1671                 $$ = $1;
1672         }
1673         | TONICNAME_PITCH sup_quotes    {
1674                 Pitch p = *unsmob_pitch ($1);
1675                 p = p.transposed (Pitch ($2,0,0));
1676                 $$ = p.smobbed_copy ();
1677         }
1678         | TONICNAME_PITCH sub_quotes     {
1679                 Pitch p =* unsmob_pitch ($1);
1680
1681                 p = p.transposed (Pitch (-$2,0,0));
1682                 $$ = p.smobbed_copy ();
1683         }
1684         ;
1685
1686 pitch:
1687         steno_pitch {
1688                 $$ = $1;
1689         }
1690         ;
1691
1692 pitch_also_in_chords:
1693         pitch
1694         | steno_tonic_pitch
1695         ;
1696
1697 close_event:
1698         '('     {
1699                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1700                 $$ = s;
1701                 s->set_spot (THIS->here_input ());
1702         }
1703         | E_OPEN        {
1704                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1705                 $$ = s;
1706                 s->set_spot (THIS->here_input ());
1707         }
1708         | E_SMALLER {
1709                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1710                 $$ = s;
1711                 s->set_spot (THIS->here_input ());
1712         }
1713         | E_BIGGER {
1714                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1715                 $$ = s;
1716                 s->set_spot (THIS->here_input ());
1717         }
1718         ;
1719
1720
1721 open_event:
1722         E_EXCLAMATION   {
1723                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1724                 s->set_spot (THIS->here_input ());
1725
1726                 $$ = s;
1727         }
1728         | ')'   {
1729                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1730                 $$ = s;
1731                 s->set_spot (THIS->here_input ());
1732
1733         }
1734         | E_CLOSE       {
1735                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1736                 $$ = s;
1737                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1738                 s->set_spot (THIS->here_input ());
1739         }
1740         ;
1741
1742 gen_text_def:
1743         full_markup {
1744                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1745                 t->set_property ("text", $1);
1746                 t->set_spot (THIS->here_input ());
1747                 $$ = t;
1748         }
1749         | string {
1750                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1751                 t->set_property ("text", make_simple_markup ($1));
1752                 t->set_spot (THIS->here_input ());
1753                 $$ = t;
1754
1755         }
1756         | DIGIT {
1757                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1758                 t->set_property ("digit", gh_int2scm ($1));
1759                 t->set_spot (THIS->here_input ());
1760                 $$ = t;
1761         }
1762         ;
1763
1764 script_abbreviation:
1765         '^'             {
1766                 $$ = scm_makfrom0str ("Hat");
1767         }
1768         | '+'           {
1769                 $$ = scm_makfrom0str ("Plus");
1770         }
1771         | '-'           {
1772                 $$ = scm_makfrom0str ("Dash");
1773         }
1774         | '|'           {
1775                 $$ = scm_makfrom0str ("Bar");
1776         }
1777         | '>'           {
1778                 $$ = scm_makfrom0str ("Larger");
1779         }
1780         | '.'           {
1781                 $$ = scm_makfrom0str ("Dot");
1782         }
1783         | '_' {
1784                 $$ = scm_makfrom0str ("Underscore");
1785         }
1786         ;
1787
1788 script_dir:
1789         '_'     { $$ = DOWN; }
1790         | '^'   { $$ = UP; }
1791         | '-'   { $$ = CENTER; }
1792         ;
1793
1794
1795 absolute_pitch:
1796         steno_pitch     {
1797                 $$ = $1;
1798         }
1799         ;
1800
1801 duration_length:
1802         multiplied_duration {
1803                 $$ = $1;
1804         }
1805         ;
1806
1807 optional_notemode_duration:
1808         {
1809                 Duration dd = THIS->default_duration_;
1810                 $$ = dd.smobbed_copy ();
1811
1812                 THIS->beam_check ($$);
1813         }
1814         | multiplied_duration   {
1815                 $$ = $1;
1816                 THIS->default_duration_ = *unsmob_duration ($$);
1817
1818                 THIS->beam_check ($$);
1819         }
1820         ;
1821
1822 steno_duration:
1823         bare_unsigned dots              {
1824                 int len = 0;
1825                 if (!is_is_duration ($1))
1826                         THIS->parser_error (_f ("not a duration: %d", $1));
1827                 else
1828                         len = intlog2 ($1);
1829
1830                 $$ = Duration (len, $2).smobbed_copy ();
1831         }
1832         | DURATION_IDENTIFIER dots      {
1833                 Duration *d = unsmob_duration ($1);
1834                 Duration k (d->duration_log (), d->dot_count () + $2);
1835                 *d = k;
1836                 $$ = $1;
1837         }
1838         ;
1839
1840
1841
1842
1843 multiplied_duration:
1844         steno_duration {
1845                 $$ = $1;
1846         }
1847         | multiplied_duration '*' bare_unsigned {
1848                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1849         }
1850         | multiplied_duration '*' FRACTION {
1851                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1852
1853                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1854         }
1855         ;
1856
1857 fraction:
1858         FRACTION { $$ = $1; }
1859         | UNSIGNED '/' UNSIGNED {
1860                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1861         }
1862         ;
1863
1864 dots:
1865         /* empty */     {
1866                 $$ = 0;
1867         }
1868         | dots '.' {
1869                 $$ ++;
1870         }
1871         ;
1872
1873
1874 tremolo_type:
1875         ':'     {
1876                 $$ = 0;
1877         }
1878         | ':' bare_unsigned {
1879                 if (!is_is_duration ($2))
1880                         THIS->parser_error (_f ("not a duration: %d", $2));
1881                 $$ = $2;
1882         }
1883         ;
1884
1885
1886
1887 /*****************************************************************
1888                 BASS FIGURES
1889 *****************************************************************/
1890 bass_number:
1891         DIGIT   {
1892                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1893         }
1894         | UNSIGNED {
1895                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1896         }
1897         | STRING { $$ = $1; }
1898         ;
1899
1900 bass_mod:
1901         '-'     { $$ = -2; }
1902         | '+'   { $$ = 2; }
1903         | '!'   { $$ = 0; }
1904         ;
1905
1906 bass_figure:
1907         FIGURE_SPACE {
1908                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1909                 $$ = bfr->self_scm ();
1910                 scm_gc_unprotect_object ($$);
1911         }
1912         | bass_number  {
1913                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1914                 $$ = bfr->self_scm ();
1915
1916                 bfr->set_property ("figure", $1);
1917
1918                 scm_gc_unprotect_object ($$);
1919         }
1920         | bass_figure bass_mod {
1921                 Music *m = unsmob_music ($1);
1922                 if ($2) {
1923                         SCM salter = m->get_property ("alteration");
1924                         int alter = gh_number_p (salter) ? gh_scm2int (salter) : 0;
1925                         m->set_property ("alteration",
1926                                 gh_int2scm (alter + $2));
1927                 } else {
1928                         m->set_property ("alteration", gh_int2scm (0));
1929                 }
1930         }
1931         ;
1932
1933 br_bass_figure:
1934         '[' bass_figure {
1935                 $$ = $2;
1936                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1937         }
1938         | bass_figure   {
1939                 $$ = $1;
1940         }
1941         | br_bass_figure ']' {
1942                 $$ = $1;
1943                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1944         }
1945         ;
1946
1947 figure_list:
1948         /**/            {
1949                 $$ = SCM_EOL;
1950         }
1951         | figure_list br_bass_figure {
1952                 $$ = scm_cons ($2, $1);
1953         }
1954         ;
1955
1956 figure_spec:
1957         FIGURE_OPEN figure_list FIGURE_CLOSE {
1958                 Music *m = MY_MAKE_MUSIC ("EventChord");
1959                 $2 = scm_reverse_x ($2, SCM_EOL);
1960                 m->set_property ("elements", $2);
1961                 $$ = m->self_scm ();
1962         }
1963         ;
1964
1965
1966 optional_rest:
1967         /**/   { $$ = 0; }
1968         | REST { $$ = 1; }
1969         ;
1970
1971 simple_element:
1972         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1973
1974                 Input i = THIS->pop_spot ();
1975                 if (!THIS->lexer_->is_note_state ())
1976                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1977
1978                 Music *n = 0;
1979                 if ($6)
1980                         n = MY_MAKE_MUSIC ("RestEvent");
1981                 else
1982                         n = MY_MAKE_MUSIC ("NoteEvent");
1983
1984                 n->set_property ("pitch", $1);
1985                 n->set_property ("duration", $5);
1986
1987                 if (gh_number_p ($4))
1988                 {
1989                         int q = gh_scm2int ($4);
1990                         n->set_property ("absolute-octave", gh_int2scm (q-1));
1991                 }
1992
1993                 if ($3 % 2)
1994                         n->set_property ("cautionary", SCM_BOOL_T);
1995                 if ($2 % 2 || $3 % 2)
1996                         n->set_property ("force-accidental", SCM_BOOL_T);
1997
1998                 Music *v = MY_MAKE_MUSIC ("EventChord");
1999                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2000                 scm_gc_unprotect_object (n->self_scm ());
2001
2002                 v->set_spot (i);
2003                 n->set_spot (i);
2004                 $$ = v;
2005         }
2006         | DRUM_PITCH optional_notemode_duration {
2007                 Input i = THIS->pop_spot ();
2008
2009                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2010                 n->set_property ("duration", $2);
2011                 n->set_property ("drum-type", $1);
2012
2013                 Music *v = MY_MAKE_MUSIC ("EventChord");
2014                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2015                 scm_gc_unprotect_object (n->self_scm ());
2016                 v->set_spot (i);
2017                 n->set_spot (i);
2018                 $$ = v;
2019
2020         }
2021         | figure_spec optional_notemode_duration {
2022                 Music *m = unsmob_music ($1);
2023                 Input i = THIS->pop_spot ();
2024                 m->set_spot (i);
2025                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2026                 {
2027                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2028                 }
2029                 $$ = m;
2030         }
2031         | RESTNAME optional_notemode_duration           {
2032
2033                 Input i = THIS->pop_spot ();
2034                 Music *ev = 0;
2035                 if (ly_scm2string ($1) == "s") {
2036                         /* Space */
2037                         ev = MY_MAKE_MUSIC ("SkipEvent");
2038                   }
2039                 else {
2040                         ev = MY_MAKE_MUSIC ("RestEvent");
2041
2042                     }
2043                 ev->set_property ("duration", $2);
2044                 ev->set_spot (i);
2045                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2046                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2047                 velt->set_spot (i);
2048
2049                 scm_gc_unprotect_object (ev->self_scm ());
2050
2051                 $$ = velt;
2052         }
2053         | MULTI_MEASURE_REST optional_notemode_duration         {
2054                 THIS->pop_spot ();
2055
2056                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2057                 SCM mus = scm_call_2 (proc, $2,
2058                         make_input (THIS->here_input ()));
2059                 scm_gc_protect_object (mus);
2060                 $$ = unsmob_music (mus);
2061         }
2062
2063         | lyric_element optional_notemode_duration      {
2064                 Input i = THIS->pop_spot ();
2065                 if (!THIS->lexer_->is_lyric_state ())
2066                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2067
2068                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2069                 lreq->set_property ("text", $1);
2070                 lreq->set_property ("duration",$2);
2071                 lreq->set_spot (i);
2072                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2073                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2074
2075                 $$= velt;
2076         }
2077         | new_chord {
2078                 THIS->pop_spot ();
2079
2080                 if (!THIS->lexer_->is_chord_state ())
2081                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2082                 $$ = unsmob_music ($1);
2083         }
2084         ;
2085
2086 lyric_element:
2087         full_markup { $$ = $1; }
2088         | STRING { $$ = $1; }
2089         ;
2090
2091 new_chord:
2092         steno_tonic_pitch optional_notemode_duration   {
2093                 $$ = make_chord ($1, $2, SCM_EOL);
2094         }
2095         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2096                 SCM its = scm_reverse_x ($4, SCM_EOL);
2097                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2098         }
2099         ;
2100
2101 chord_items:
2102         /**/ {
2103                 $$ = SCM_EOL;
2104         }
2105         | chord_items chord_item {
2106                 $$ = gh_cons ($2, $$);
2107         }
2108         ;
2109
2110 chord_separator:
2111         CHORD_COLON {
2112                 $$ = ly_symbol2scm ("chord-colon");
2113         }
2114         | CHORD_CARET {
2115                 $$ = ly_symbol2scm ("chord-caret");
2116         }
2117         | CHORD_SLASH steno_tonic_pitch {
2118                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2119         }
2120         | CHORD_BASS steno_tonic_pitch {
2121                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2122         }
2123         ;
2124
2125 chord_item:
2126         chord_separator {
2127                 $$ = $1;
2128         }
2129         | step_numbers {
2130                 $$ = scm_reverse_x ($1, SCM_EOL);
2131         }
2132         | CHORD_MODIFIER  {
2133                 $$ = $1;
2134         }
2135         ;
2136
2137 step_numbers:
2138         step_number { $$ = gh_cons ($1, SCM_EOL); }
2139         | step_numbers '.' step_number {
2140                 $$ = gh_cons ($3, $$);
2141         }
2142         ;
2143
2144 step_number:
2145         bare_unsigned {
2146                 $$ = make_chord_step ($1, 0);
2147         }
2148         | bare_unsigned '+' {
2149                 $$ = make_chord_step ($1, SHARP);
2150         }
2151         | bare_unsigned CHORD_MINUS {
2152                 $$ = make_chord_step ($1, FLAT);
2153         }
2154         ;
2155
2156 /*
2157         UTILITIES
2158
2159 TODO: should deprecate in favor of Scheme?
2160
2161  */
2162 number_expression:
2163         number_expression '+' number_term {
2164                 $$ = scm_sum ($1, $3);
2165         }
2166         | number_expression '-' number_term {
2167                 $$ = scm_difference ($1, $3);
2168         }
2169         | number_term
2170         ;
2171
2172 number_term:
2173         number_factor {
2174                 $$ = $1;
2175         }
2176         | number_factor '*' number_factor {
2177                 $$ = scm_product ($1, $3);
2178         }
2179         | number_factor '/' number_factor {
2180                 $$ = scm_divide ($1, $3);
2181         }
2182         ;
2183
2184 number_factor:
2185         '-'  number_factor { /* %prec UNARY_MINUS */
2186                 $$ = scm_difference ($2, SCM_UNDEFINED);
2187         }
2188         | bare_number
2189         ;
2190
2191
2192 bare_number:
2193         UNSIGNED        {
2194                 $$ = gh_int2scm ($1);
2195         }
2196         | REAL          {
2197                 $$ = $1;
2198         }
2199         | NUMBER_IDENTIFIER             {
2200                 $$ = $1;
2201         }
2202         | REAL NUMBER_IDENTIFIER        {
2203                 $$ = gh_double2scm (gh_scm2double ($1) *gh_scm2double ($2));
2204         }
2205         | UNSIGNED NUMBER_IDENTIFIER    {
2206                 $$ = gh_double2scm ($1 *gh_scm2double ($2));
2207         }
2208         ;
2209
2210
2211 bare_unsigned:
2212         UNSIGNED {
2213                         $$ = $1;
2214         }
2215         | DIGIT {
2216                 $$ = $1;
2217         }
2218         ;
2219
2220 bare_int:
2221         bare_number {
2222                 if (scm_integer_p ($1) == SCM_BOOL_T)
2223                 {
2224                         int k = gh_scm2int ($1);
2225                         $$ = k;
2226                 } else
2227                 {
2228                         THIS->parser_error (_ ("need integer number arg"));
2229                         $$ = 0;
2230                 }
2231         }
2232         | '-' bare_int {
2233                 $$ = -$2;
2234         }
2235         ;
2236
2237
2238 string:
2239         STRING          {
2240                 $$ = $1;
2241         }
2242         | STRING_IDENTIFIER     {
2243                 $$ = $1;
2244         }
2245         | string '+' string {
2246                 $$ = scm_string_append (scm_list_2 ($1, $3));
2247         }
2248         ;
2249
2250
2251 exclamations:
2252                 { $$ = 0; }
2253         | exclamations '!'      { $$ ++; }
2254         ;
2255
2256 questions:
2257                 { $$ = 0; }
2258         | questions '?' { $$ ++; }
2259         ;
2260
2261
2262
2263 full_markup:
2264         MARKUP_IDENTIFIER {
2265                 $$ = $1;
2266         }
2267         | MARKUP
2268                 { THIS->lexer_->push_markup_state (); }
2269         markup
2270                 { $$ = $3;
2271                   THIS->lexer_->pop_state ();
2272                 }
2273         ;
2274
2275
2276 /*
2277 This should be done more dynamically if possible.
2278 */
2279 markup:
2280         STRING {
2281                 $$ = make_simple_markup ($1);
2282         }
2283         | MARKUP_HEAD_EMPTY {
2284                 $$ = scm_list_1 ($1);
2285         }
2286         | MARKUP_HEAD_MARKUP0 markup {
2287                 $$ = scm_list_2 ($1, $2);
2288         }
2289         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2290                 $$ = scm_list_3 ($1, $2, $3);
2291         }
2292         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2293                 $$ = scm_list_3 ($1, $2, $3);
2294         }
2295         | markup_line {
2296                 $$ = $1;
2297         }
2298         | MARKUP_HEAD_LIST0 markup_list {
2299                 $$ = scm_list_2 ($1,$2);
2300         }
2301         | MARKUP_HEAD_SCM0 embedded_scm {
2302                 $$ = scm_list_2 ($1, $2);
2303         }
2304         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2305                 $$ = scm_list_4 ($1, $2, $3, $4);
2306         }
2307         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2308                 $$ = scm_list_4 ($1, $2, $3, $4);
2309         }
2310         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2311                 $$ = scm_list_3 ($1, $2, $3);
2312         }
2313         | MARKUP_IDENTIFIER {
2314                 $$ = $1;
2315         }
2316         | STRING_IDENTIFIER {
2317                 $$ = $1;
2318         }
2319         ;
2320
2321 markup_list:
2322         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2323         ;
2324
2325 markup_line:
2326         '{' markup_list_body '}' {
2327                 SCM line = ly_scheme_function ("line-markup");
2328
2329                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2330         }
2331         ;
2332
2333 markup_list_body:
2334         /**/ {  $$ = SCM_EOL; }
2335         | markup_list_body markup {
2336                 $$ = gh_cons ($2, $1);
2337         }
2338         ;
2339
2340
2341 %%
2342
2343 void
2344 My_lily_parser::set_yydebug (bool )
2345 {
2346 #if 0
2347         yydebug = 1;
2348 #endif
2349 }
2350
2351 extern My_lily_parser *current_parser;
2352
2353 void
2354 My_lily_parser::do_yyparse ()
2355 {
2356         current_parser = this;;
2357         yyparse ((void*)this);
2358 }
2359
2360
2361 /*
2362 Should make this optional?    It will also complain when you do
2363
2364         [s4]
2365
2366 which is entirely legitimate.
2367
2368 Or we can scrap it. Barchecks should detect wrong durations, and
2369 skipTypesetting speeds it up a lot.
2370 */
2371
2372 void
2373 My_lily_parser::beam_check (SCM dur)
2374 {
2375   Duration *d = unsmob_duration (dur);
2376   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2377     {
2378       Music *m = unsmob_music (last_beam_start_);
2379       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2380     }
2381   last_beam_start_ = SCM_EOL;
2382 }
2383
2384
2385
2386
2387 /*
2388
2389 It is a little strange to have this function in this file, but
2390 otherwise, we have to import music classes into the lexer.
2391
2392 */
2393 int
2394 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2395 {
2396         if (gh_string_p (sid)) {
2397                 *destination = sid;
2398                 return STRING_IDENTIFIER;
2399         } else if (gh_number_p (sid)) {
2400                 *destination = sid;
2401                 return NUMBER_IDENTIFIER;
2402         } else if (unsmob_context_def (sid)) {
2403                 *destination = unsmob_context_def (sid)->clone_scm ();
2404                 return CONTEXT_DEF_IDENTIFIER;
2405         } else if (unsmob_score (sid)) {
2406                 Score *sc = new Score (*unsmob_score (sid));
2407                 *destination = sc->self_scm ();
2408                 return SCORE_IDENTIFIER;
2409         } else if (Music *mus = unsmob_music (sid)) {
2410                 mus = mus->clone ();
2411                 *destination = mus->self_scm ();
2412                 unsmob_music (*destination)->
2413                         set_property ("origin", make_input (last_input_));
2414                 return dynamic_cast<Event*> (mus)
2415                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2416         } else if (unsmob_duration (sid)) {
2417                 *destination = unsmob_duration (sid)->smobbed_copy ();
2418                 return DURATION_IDENTIFIER;
2419         } else if (unsmob_music_output_def (sid)) {
2420                 Music_output_def *p = unsmob_music_output_def (sid);
2421                 p = p->clone ();
2422
2423                 *destination = p->self_scm ();
2424                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2425         } else if (Text_item::markup_p (sid)) {
2426                 *destination = sid;
2427                 return MARKUP_IDENTIFIER;
2428         }
2429
2430         return -1;
2431 }
2432
2433 Music *
2434 property_op_to_music (SCM op)
2435 {
2436         Music *m = 0;
2437         SCM tag = gh_car (op);
2438         SCM symbol = gh_cadr (op);
2439         SCM args = gh_cddr (op);
2440         SCM grob_val = SCM_UNDEFINED;
2441         SCM grob_sym = SCM_UNDEFINED;
2442         SCM val = SCM_UNDEFINED;
2443
2444         if (tag == ly_symbol2scm ("assign"))
2445                 {
2446                 m = MY_MAKE_MUSIC ("PropertySet");
2447                 val = gh_car (args);
2448                 }
2449         else if (tag == ly_symbol2scm ("unset"))
2450                 m = MY_MAKE_MUSIC ("PropertyUnset");
2451         else if (tag == ly_symbol2scm ("poppush")
2452                  || tag == ly_symbol2scm ("push"))
2453                 {
2454                 m = MY_MAKE_MUSIC ("OverrideProperty");
2455                 grob_sym = gh_car (args);
2456                 grob_val = gh_cadr (args);
2457                 }
2458         else if (tag == ly_symbol2scm ("pop")) {
2459                 m = MY_MAKE_MUSIC ("RevertProperty");
2460                 grob_sym = gh_car (args);
2461                 }
2462
2463         m->set_property ("symbol", symbol);
2464
2465         if (val != SCM_UNDEFINED)
2466                 m->set_property ("value", val);
2467         if (grob_val != SCM_UNDEFINED)
2468                 m->set_property ("grob-value", grob_val);
2469
2470         if (grob_sym != SCM_UNDEFINED)
2471                 {
2472                 bool itc = internal_type_checking_global_b;
2473                 /* UGH.
2474                 */
2475                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2476                 if (autobeam)
2477                         internal_type_checking_global_b = false;
2478                 m->set_property ("grob-property", grob_sym);
2479                 if (autobeam)
2480                         internal_type_checking_global_b = itc;
2481                 }
2482
2483         if (op == ly_symbol2scm ("poppush"))
2484                 m->set_property ("pop-first", SCM_BOOL_T);
2485
2486
2487         return m;
2488 }
2489
2490 Music*
2491 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2492 {
2493         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2494
2495         csm->set_property ("element", m->self_scm ());
2496         scm_gc_unprotect_object (m->self_scm ());
2497
2498         csm->set_property ("context-type",
2499                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2500         csm->set_property ("property-operations", ops);
2501
2502         if (gh_string_p (id))
2503                 csm->set_property ("context-id", id);
2504         return csm;
2505 }
2506
2507
2508 SCM
2509 get_next_unique_context ()
2510 {
2511         static int new_context_count;
2512
2513         char s[1024];
2514         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2515
2516         return scm_makfrom0str (s);
2517 }
2518