lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token LYRICS_STRING
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token NEWLYRICS
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307 %token MARKUP
 308
 309 /* escaped */
 310 /* FIXME: this sucks.  The user will get to see these names:
 311     syntax error, unexpected E_CHAR:
 312                 \
 313                  %%
 314   */
 315
 316 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 317 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 318 %token E_BACKSLASH
 319 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 320 %token FIGURE_SPACE
 321
 322 %token <i>      DIGIT
 323 %token <i>      UNSIGNED
 324 %token <i> E_UNSIGNED
 325 %token <id>     IDENTIFIER
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DRUM_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    EVENT_IDENTIFIER
 330 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    NUMBER_IDENTIFIER
 333 %token <scm>    OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    RESTNAME
 335 %token <scm>    SCM_T
 336 %token <scm>    SCORE_IDENTIFIER
 337 %token <scm>    STRING
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    TONICNAME_PITCH
 340 %token <scm>    CHORD_MODIFIER
 341 %token <scm>    FRACTION
 342 %token <scm>   REAL
 343 %token <scm> MARKUP_HEAD_EMPTY
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0
 347 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 352 %token <scm> MUSIC_FUNCTION
 353 %token <scm> MUSIC_FUNCTION_MUSIC
 354 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 355 %token <scm> MUSIC_FUNCTION_SCM
 356 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 359 %token DRUMS
 360
 361
 362
 363 %type <book>    book_block book_body
 364 %type <i>       bare_int  bare_unsigned
 365 %type <i>       exclamations questions dots optional_rest
 366 %type <i>       script_dir
 367 %type <i>       sub_quotes sup_quotes
 368 %type <i>       tremolo_type
 369 %type <i>       bass_mod
 370
 371 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 372 %type <music>   Grouped_music_list
 373 %type <music>   Music Sequential_music Simultaneous_music
 374 %type <music>   Repeated_music
 375 %type <music>   command_req
 376 %type <music>   gen_text_def direction_less_event direction_reqd_event
 377 %type <music>   music_property_def context_change
 378 %type <music>   note_chord_element chord_body chord_body_element
 379 %type <music>   open_event close_event
 380 %type <music>   post_event tagged_post_event
 381 %type <music>   relative_music re_rhythmed_music
 382 %type <music>   simple_element event_chord command_element
 383 %type <music>   string_number_event
 384 %type <music>   toplevel_music
 385 %type <music>   tempo_event
 386
 387 %type <outputdef>       output_def_body output_def_head
 388 %type <outputdef> output_def book_paper_block
 389
 390 %type <scm>     Music_list
 391 %type <scm>     chord_body_elements
 392 %type <scm>     chord_item chord_items chord_separator new_chord
 393 %type <scm>     context_def_spec_block context_def_spec_body
 394 %type <scm>     context_mod context_def_mod optional_context_mod
 395 %type <scm>     context_prop_spec
 396 %type <scm>     duration_length fraction
 397 %type <scm>     embedded_scm scalar
 398 %type <scm>     identifier_init
 399 %type <scm>     lilypond_header lilypond_header_body
 400 %type <scm>     new_lyrics
 401 %type <scm>     post_events
 402 %type <scm>     property_operation
 403 %type <scm>     script_abbreviation
 404 %type <scm>     simple_string
 405 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 406 %type <scm>     steno_tonic_pitch
 407 %type <scm>     step_number step_numbers
 408 %type <scm>     string bare_number number_expression number_term number_factor
 409 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 410 %type <scm>     context_mod_list
 411 %type <scm>     octave_check
 412 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 413 %type <scm>     Generic_prefix_music_scm
 414 %type <scm>     lyric_element
 415 %type <scm>     Alternative_music
 416 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 417
 418 %type <score>   score_block score_body
 419
 420
 421 %left '-' '+'
 422
 423 /* We don't assign precedence to / and *, because we might need varied
 424 prec levels in different prods */
 425
 426 %left UNARY_MINUS
 427
 428 %%
 429
 430 lilypond:       /* empty */
 431         | lilypond toplevel_expression {
 432         }
 433         | lilypond assignment {
 434         }
 435         | lilypond error {
 436                 THIS->error_level_ = 1;
 437         }
 438         | lilypond INVALID      {
 439                 THIS->error_level_ = 1;
 440         }
 441         ;
 442
 443 toplevel_expression:
 444         lilypond_header {
 445                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 446         }
 447         | add_quote {
 448
 449         }
 450         | book_block {
 451                 Book *book = $1;
 452                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 453                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 454                 scm_gc_unprotect_object (book->self_scm ());
 455         }
 456         | score_block {
 457                 Score *score = $1;
 458
 459                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 460                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 461                 scm_gc_unprotect_object (score->self_scm ());
 462         }
 463         | toplevel_music {
 464                 Music *music = $1;
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 467                 scm_gc_unprotect_object (music->self_scm ());
 468         }
 469         | output_def {
 470                 SCM id = SCM_EOL;
 471                 Output_def * od = $1;
 472
 473                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultpaper");
 475                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 476                         id = ly_symbol2scm ("$defaultmidi");
 477                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 478                         id = ly_symbol2scm ("$defaultbookpaper");
 479
 480                 THIS->lexer_->set_identifier (id, od->self_scm ());
 481                 scm_gc_unprotect_object (od->self_scm ());
 482         }
 483         ;
 484
 485 toplevel_music:
 486         Composite_music {
 487         }
 488         ;
 489
 490 embedded_scm:
 491         SCM_T
 492         | SCM_IDENTIFIER
 493         ;
 494
 495
 496 lilypond_header_body:
 497         {
 498                 $$ = ly_make_anonymous_module (safe_global_b);
 499                 THIS->lexer_->add_scope ($$);
 500         }
 501         | lilypond_header_body assignment  {
 502
 503         }
 504         ;
 505
 506 lilypond_header:
 507         HEADER '{' lilypond_header_body '}'     {
 508                 $$ = THIS->lexer_->remove_scope ();
 509         }
 510         ;
 511
 512
 513 /*
 514         DECLARATIONS
 515 */
 516 assignment:
 517         STRING {
 518                 THIS->push_spot ();
 519         }
 520         /* cont */ '=' identifier_init  {
 521
 522         /*
 523                 Should find generic way of associating input with objects.
 524         */
 525                 Input ip = THIS->pop_spot ();
 526
 527                 if (! is_regular_identifier ($1))
 528                 {
 529                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 530                 }
 531
 532                 THIS->lexer_->set_identifier ($1, $4);
 533
 534 /*
 535  TODO: devise standard for protection in parser.
 536
 537   The parser stack lives on the C-stack, which means that
 538 all objects can be unprotected as soon as they're here.
 539
 540 */
 541         }
 542         | embedded_scm { }
 543         ;
 544
 545
 546 identifier_init:
 547         score_block {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | full_markup {
 552                 $$ = $1;
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | context_def_spec_block {
 559                 $$ = $1;
 560         }
 561         | Music  {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | post_event {
 566                 $$ = $1->self_scm ();
 567                 scm_gc_unprotect_object ($$);
 568         }
 569         | number_expression {
 570                 $$ = $1;
 571         }
 572         | string {
 573                 $$ = $1;
 574         }
 575         | embedded_scm  {
 576                 $$ = $1;
 577         }
 578         ;
 579
 580 context_def_spec_block:
 581         CONTEXT '{' context_def_spec_body '}'
 582                 {
 583                 $$ = $3;
 584         }
 585         ;
 586
 587 context_def_spec_body:
 588         /**/ {
 589                 $$ = Context_def::make_scm ();
 590                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | CONTEXT_DEF_IDENTIFIER {
 593                 $$ = $1;
 594                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 595         }
 596         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 597                 Context_def*td = unsmob_context_def ($$);
 598
 599                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 600                         SCM tag = ly_caar (p);
 601
 602                         /* TODO: should make new tag "grob-definition" ? */
 603                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 604                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 605                 }
 606         }
 607         | context_def_spec_body context_mod {
 608                 unsmob_context_def ($$)->add_context_mod ($2);
 609         }
 610         ;
 611
 612
 613
 614 book_block:
 615         BOOK {
 616                 THIS->push_spot ();
 617         }
 618         /*cont*/ '{' book_body '}'      {
 619                 THIS->pop_spot ();
 620                 $$ = $4;
 621         }
 622         ;
 623
 624 /* FIXME:
 625    * Use 'handlers' like for toplevel-* stuff?
 626    * grok \paper and \midi?  */
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 632                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 633                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 634         }
 635         | book_body book_paper_block {
 636                 $$->bookpaper_ = $2;
 637                 scm_gc_unprotect_object ($2->self_scm ());
 638         }
 639         | book_body score_block {
 640                 Score *score = $2;
 641                 $$->scores_.push (score);
 642                 scm_gc_unprotect_object (score->self_scm ());
 643         }
 644         | book_body Composite_music {
 645                 Music *music = $2;
 646                 Score *score
 647                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 648                 $$->scores_.push (score);
 649                 scm_gc_unprotect_object (music->self_scm ());
 650         }
 651         | book_body lilypond_header {
 652                 $$->header_ = $2;
 653         }
 654         | book_body error {
 655
 656         }
 657         ;
 658
 659 score_block:
 660         SCORE {
 661                 THIS->push_spot ();
 662         }
 663         /*cont*/ '{' score_body '}'     {
 664                 THIS->pop_spot ();
 665                 $$ = $4;
 666         }
 667         ;
 668
 669 score_body:
 670         /**/    {
 671                 $$ = new Score;
 672
 673                 $$->set_spot (THIS->here_input ());
 674         }
 675         | SCORE_IDENTIFIER {
 676                 $$ = new Score ( *unsmob_score ($1));
 677                 $$->set_spot (THIS->here_input ());
 678         }
 679         | score_body Music {
 680                 SCM m = $2->self_scm ();
 681                 scm_gc_unprotect_object (m);
 682
 683                 /*
 684                         guh.
 685                 */
 686                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 687                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 688                         m = scm_call_1 (ly_car (check_funcs), m);
 689                 if (unsmob_music ($$->music_))
 690                 {
 691                         THIS->parser_error (_("Already have music in score"));
 692                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 693                 }
 694                 $$->music_ = m;
 695         }
 696         | score_body lilypond_header    {
 697                 $$->header_ = $2;
 698         }
 699         | score_body output_def {
 700                 $$->defs_.push ($2);
 701                 scm_gc_unprotect_object ($2->self_scm ());
 702         }
 703         | score_body error {
 704
 705         }
 706         ;
 707
 708
 709 /*
 710         OUTPUT DEF
 711 */
 712
 713 book_paper_block:
 714         output_def {
 715                 $$ = $1;
 716                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 717                 {
 718                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 719                         $$ = get_bookpaper (THIS);
 720                 }
 721         }
 722         ;
 723
 724
 725 output_def:
 726         output_def_body '}' {
 727                 $$ = $1;
 728                 if ($1->parent_)
 729                         THIS->lexer_->remove_scope ();
 730
 731                 THIS->lexer_->remove_scope ();
 732                 THIS->lexer_->pop_state ();
 733         }
 734         ;
 735
 736 output_def_head:
 737         BOOKPAPER {
 738                 $$ = get_bookpaper (THIS);
 739                 $$->input_origin_ = THIS->here_input ();
 740                 THIS->lexer_->add_scope ($$->scope_);
 741         }
 742         | MIDI    {
 743                 Output_def *p = get_midi (THIS);
 744                 $$ = p;
 745                 THIS->lexer_->add_scope (p->scope_);
 746         }
 747         | PAPER         {
 748                 Output_def* p = get_paper (THIS);
 749
 750                 if (p->parent_)
 751                         THIS->lexer_->add_scope (p->parent_->scope_);
 752
 753                 THIS->lexer_->add_scope (p->scope_);
 754                 $$ = p;
 755         }
 756         ;
 757
 758
 759 output_def_body:
 760         output_def_head '{' {
 761                 $$ = $1;
 762                 $$->input_origin_.set_spot (THIS->here_input ());
 763                 THIS->lexer_->push_initial_state ();
 764         }
 765         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 766                 scm_gc_unprotect_object ($1->self_scm ());
 767                 Output_def *o = unsmob_output_def ($3);
 768                 o->input_origin_.set_spot (THIS->here_input ());
 769                 $$ = o;
 770                 THIS->lexer_->remove_scope ();
 771                 THIS->lexer_->add_scope (o->scope_);
 772                 THIS->lexer_->push_initial_state ();
 773         }
 774         | output_def_body assignment  {
 775
 776         }
 777         | output_def_body context_def_spec_block        {
 778                 assign_context_def ($$, $2);
 779         }
 780         | output_def_body tempo_event  {
 781                 /*
 782                         junk this ? there already is tempo stuff in
 783                         music.
 784                 */
 785                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 786                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 787                 set_tempo ($$, d->get_length (), m);
 788                 scm_gc_unprotect_object ($2->self_scm ());
 789         }
 790         | output_def_body error {
 791
 792         }
 793         ;
 794
 795 tempo_event:
 796         TEMPO steno_duration '=' bare_unsigned  {
 797                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 798                 $$->set_property ("tempo-unit", $2);
 799                 $$->set_property ("metronome-count", scm_int2num ( $4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have  efficient append.
 809 */
 810 Music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | Music_list Music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 817                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 818                 if (ly_c_pair_p (ly_cdr (s)))
 819                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 820                 else
 821                         scm_set_car_x (s, c); /* set first cons */
 822                 scm_set_cdr_x (s, c);  /* remember last cell */
 823         }
 824         | Music_list embedded_scm {
 825         }
 826         | Music_list error {
 827         }
 828         ;
 829
 830
 831 Music:
 832         Simple_music
 833         | Composite_music
 834         ;
 835
 836 Alternative_music:
 837         /* empty */ {
 838                 $$ = SCM_EOL;
 839         }
 840         | ALTERNATIVE '{' Music_list '}' {
 841                 $$ = $3;
 842         }
 843         ;
 844
 845
 846 Repeated_music:
 847         REPEAT simple_string bare_unsigned Music Alternative_music
 848         {
 849                 Music *beg = $4;
 850                 int times = $3;
 851                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 852                 if (times < scm_ilength (alts)) {
 853                   unsmob_music (ly_car (alts))
 854                     ->origin ()->warning (
 855                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 856                   alts = ly_truncate_list (times, alts);
 857                 }
 858
 859
 860                 SCM proc = ly_scheme_function ("make-repeated-music");
 861
 862                 SCM mus = scm_call_1 (proc, $2);
 863                 scm_gc_protect_object (mus); // UGH.
 864                 Music *r = unsmob_music (mus);
 865                 if (beg)
 866                         {
 867                         r-> set_property ("element", beg->self_scm ());
 868                         scm_gc_unprotect_object (beg->self_scm ());
 869                         }
 870                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 871
 872                 r-> set_property ("elements",alts);
 873                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 874                         /*
 875                         TODO: move this code to Scheme.
 876                         */
 877
 878                         /*
 879                         we can not get durations and other stuff correct down the line, so we have to
 880                         add to the duration log here.
 881                         */
 882                         SCM func = ly_scheme_function ("shift-duration-log");
 883
 884                         int dots = ($3 % 3) ? 0 : 1;
 885                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 886
 887                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 888
 889                         if (seq) {
 890                                 int list_len = scm_ilength (seq->music_list ());
 891                                 if (list_len != 2)
 892                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 893                                 shift -= 1;
 894                                 r->compress (Moment (Rational (1, list_len)));
 895                                 }
 896                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 897
 898                 }
 899                 r->set_spot (*$4->origin ());
 900
 901                 $$ = r;
 902         }
 903         ;
 904
 905 Sequential_music:
 906         SEQUENTIAL '{' Music_list '}'           {
 907                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 908                 $$->set_property ("elements", ly_car ($3));
 909                 $$->set_spot (THIS->here_input ());
 910         }
 911         | '{' Music_list '}'            {
 912                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 913                 $$->set_property ("elements", ly_car ($2));
 914                 $$->set_spot (THIS->here_input ());
 915         }
 916         ;
 917
 918 Simultaneous_music:
 919         SIMULTANEOUS '{' Music_list '}'{
 920                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 921                 $$->set_property ("elements", ly_car ($3));
 922                 $$->set_spot (THIS->here_input ());
 923
 924         }
 925         | simul_open Music_list simul_close     {
 926                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 927                 $$->set_property ("elements", ly_car ($2));
 928                 $$->set_spot (THIS->here_input ());
 929         }
 930         ;
 931
 932 Simple_music:
 933         event_chord             { $$ = $1; }
 934         | MUSIC_IDENTIFIER {
 935                 $$ = unsmob_music ($1);
 936         }
 937         | music_property_def
 938         | context_change
 939         ;
 940
 941
 942 optional_context_mod:
 943         /**/ { $$ = SCM_EOL; }
 944         | WITH { THIS->lexer_->push_initial_state (); }
 945         '{' context_mod_list '}'
 946         {
 947                 THIS->lexer_->pop_state ();
 948                 $$ = $4;
 949         }
 950         ;
 951
 952 context_mod_list:
 953         /* */  { $$ = SCM_EOL; }
 954         | context_mod_list context_mod  {
 955                  $$ = scm_cons ($2, $1);
 956         }
 957         ;
 958
 959
 960 Composite_music:
 961         Prefix_composite_music { $$ = $1; }
 962         | Grouped_music_list { $$ = $1; }
 963         ;
 964
 965 Grouped_music_list:
 966         Simultaneous_music              { $$ = $1; }
 967         | Sequential_music              { $$ = $1; }
 968         ;
 969
 970 Generic_prefix_music_scm:
 971         MUSIC_FUNCTION {
 972                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 973         }
 974         | MUSIC_FUNCTION_SCM {
 975                 THIS->push_spot ();
 976         } embedded_scm {
 977                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 978         }
 979         | MUSIC_FUNCTION_MUSIC {
 980                 THIS->push_spot ();
 981         } Music {
 982                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 983                 scm_gc_unprotect_object ($3->self_scm ());
 984         }
 985         | MUSIC_FUNCTION_SCM_MUSIC {
 986                 THIS->push_spot ();
 987         }  embedded_scm Music {
 988                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 989                 scm_gc_unprotect_object ($4->self_scm ());
 990         }
 991         | MUSIC_FUNCTION_MUSIC_MUSIC {
 992                 THIS->push_spot ();
 993         }  Music  Music {
 994                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 995                 scm_gc_unprotect_object ($3->self_scm ());
 996                 scm_gc_unprotect_object ($4->self_scm ());
 997         }
 998         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 999                 THIS->push_spot ();
1000         } embedded_scm Music Music {
1001                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1002                         $3, $4->self_scm (), $5->self_scm ());
1003                 scm_gc_unprotect_object ($5->self_scm ());
1004                 scm_gc_unprotect_object ($4->self_scm ());
1005         }
1006         ;
1007
1008 Generic_prefix_music:
1009         Generic_prefix_music_scm {
1010                 SCM func = ly_car ($1);
1011                 Input *loc = unsmob_input (ly_cadr ($1));
1012                 SCM args = ly_cddr ($1);
1013                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1014                 int k = 0;
1015                 bool ok  = true;
1016                 for (SCM s = sig, t = args;
1017                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1018                         s = ly_cdr (s), t = ly_cdr (t)) {
1019                         k++;
1020                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1021                         {
1022                                 loc->error (_f ("Argument %d failed typecheck", k));
1023                                 THIS->error_level_ = 1;
1024                                 ok = false;
1025                         }
1026                 }
1027                 SCM m = SCM_EOL;
1028                 if (ok)
1029                         m = scm_apply_0 (func, ly_cdr ($1));
1030                 if (unsmob_music (m))
1031                         {
1032                         $$ = unsmob_music (m);
1033                         scm_gc_protect_object (m);
1034                         }
1035                 else
1036                         {
1037                         if (ok)
1038                                 loc->error (_ ("Music head function should return Music object."));
1039                         $$ = MY_MAKE_MUSIC ("Music");
1040                         }
1041                 $$->set_spot (*loc);
1042         }
1043         ;
1044
1045
1046 Prefix_composite_music:
1047         Generic_prefix_music {
1048                 $$ = $1;
1049         }
1050         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1051                 $$ = context_spec_music ($2, $4, $6, $5);
1052
1053         }
1054         | CONTEXT simple_string optional_context_mod Music {
1055                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1056         }
1057         | NEWCONTEXT simple_string optional_context_mod Music {
1058                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1059                         $3);
1060         }
1061
1062         | TIMES {
1063                 THIS->push_spot ();
1064         }
1065         /* CONTINUED */
1066                 fraction Music
1067
1068         {
1069                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1070                 Music *mp = $4;
1071
1072                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1073                 $$->set_spot (THIS->pop_spot ());
1074
1075                 $$->set_property ("element", mp->self_scm ());
1076                 scm_gc_unprotect_object (mp->self_scm ());
1077                 $$->set_property ("numerator", scm_int2num (n));
1078                 $$->set_property ("denominator", scm_int2num (d));
1079                 $$->compress (Moment (Rational (n,d)));
1080
1081         }
1082         | Repeated_music                { $$ = $1; }
1083         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1084                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1085                 Music *p = $4;
1086                 Pitch from = *unsmob_pitch ($2);
1087                 Pitch to = *unsmob_pitch ($3);
1088
1089                 p->transpose (interval (from, to));
1090                 $$->set_property ("element", p->self_scm ());
1091                 scm_gc_unprotect_object (p->self_scm ());
1092         }
1093         | NOTES
1094                 {
1095                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1096                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1097         }
1098         Music
1099                 { $$ = $3;
1100                   THIS->lexer_->pop_state ();
1101                 }
1102         | DRUMS
1103                 {
1104                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1105                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1106         }
1107         /* FIXME: This used to be: */
1108         Music
1109 /*      Grouped_music_list */
1110                 { $$ = $3;
1111                   THIS->lexer_->pop_state ();
1112                 }
1113         | FIGURES
1114                 { THIS->lexer_->push_figuredbass_state (); }
1115         /* FIXME: This used to be:
1116         Music
1117         but that breaks web build
1118         */
1119         Grouped_music_list
1120                 {
1121                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1122                   chm->set_property ("element", $3->self_scm ());
1123                   $$ = chm;
1124                   scm_gc_unprotect_object ($3->self_scm ());
1125
1126                   THIS->lexer_->pop_state ();
1127         }
1128         | CHORDS {
1129                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1130                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1131                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1132                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1133
1134         }
1135         /* FIXME:
1136         Music
1137 */
1138         Grouped_music_list
1139         {
1140                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1141                   chm->set_property ("element", $3->self_scm ());
1142                   scm_gc_unprotect_object ($3->self_scm ());
1143                   $$ = chm;
1144
1145                   THIS->lexer_->pop_state ();
1146         }
1147         | LYRICS
1148                 { THIS->lexer_->push_lyric_state (); }
1149         /* FIXME:
1150         Music
1151 */
1152         Grouped_music_list
1153                 {
1154                   $$ = $3;
1155                   THIS->lexer_->pop_state ();
1156         }
1157         | relative_music        { $$ = $1; }
1158         | re_rhythmed_music     { $$ = $1; }
1159         | TAG embedded_scm Music {
1160                 tag_music ($3, $2, THIS->here_input ());
1161                 $$ = $3;
1162         }
1163         ;
1164
1165 relative_music:
1166         RELATIVE absolute_pitch Music {
1167                 Music *m = $3;
1168                 Pitch start = *unsmob_pitch ($2);
1169                 $$ = make_music_relative (start, m);
1170                 scm_gc_unprotect_object (m->self_scm ());
1171         }
1172         | RELATIVE Composite_music {
1173                 Music *m = $2;
1174
1175                 Pitch middle_c (0, 0, 0);
1176                 $$ = make_music_relative (middle_c, m);
1177                 scm_gc_unprotect_object (m->self_scm ());
1178         }
1179         ;
1180
1181 new_lyrics:
1182         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1183         /*cont */
1184         Grouped_music_list {
1185         /* Can also use Music at the expensive of two S/Rs similar to
1186            \repeat \alternative */
1187                 THIS->lexer_->pop_state ();
1188 #if 0
1189                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1190                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1191                 $$ = music;
1192 #else
1193                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1194 #endif
1195         }
1196         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1197         Grouped_music_list {
1198                 THIS->lexer_->pop_state ();
1199                 $$ = scm_cons ($4->self_scm (), $1);
1200         }
1201         ;
1202
1203 re_rhythmed_music:
1204         Grouped_music_list new_lyrics {
1205
1206                 /* FIXME: should find out uniqueXXX name from music */
1207                 SCM name = $1->get_property ("context-id");
1208                 //if (name == SCM_EOL)
1209                 if (!ly_c_string_p (name))
1210                         name = scm_makfrom0str ("");
1211
1212                 SCM context = scm_makfrom0str ("Lyrics");
1213                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1214
1215                 SCM lst = SCM_EOL;
1216                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1217                 {
1218                         Music *music = unsmob_music (ly_car (s));
1219                         Music *com = make_lyric_combine_music (name, music);
1220                         Music *csm = context_spec_music (context,
1221                                 get_next_unique_context (), com, SCM_EOL);
1222                         lst = scm_cons (csm->self_scm (), lst);
1223                 }
1224                 /* FIXME: only first lyric music is accepted,
1225                           the rest is junked */
1226                 all->set_property ("elements", scm_cons ($1->self_scm (),
1227                         lst));
1228                 $$ = all;
1229                 scm_gc_unprotect_object ($1->self_scm ());
1230         }
1231         | LYRICSTO string Music {
1232                 Music *music = $3;
1233                 SCM name = $2;
1234                 $$ = make_lyric_combine_music (name, music);
1235                 scm_gc_unprotect_object (music->self_scm ());
1236         }
1237         ;
1238
1239 context_change:
1240         CHANGE STRING '=' STRING  {
1241                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1242                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1243                 t-> set_property ("change-to-id", $4);
1244
1245                 $$ = t;
1246                 $$->set_spot (THIS->here_input ());
1247         }
1248         ;
1249
1250 property_operation:
1251         STRING '=' scalar {
1252                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1253                         scm_string_to_symbol ($1), $3);
1254         }
1255         | UNSET simple_string {
1256                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1257                         scm_string_to_symbol ($2));
1258         }
1259         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1260                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1261                         scm_string_to_symbol ($2), $3, $5);
1262         }
1263         | REVERT simple_string embedded_scm {
1264                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1265                         scm_string_to_symbol ($2), $3);
1266         }
1267         ;
1268
1269 context_def_mod:
1270         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1271         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1272         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1273
1274         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1275         | DENIES { $$ = ly_symbol2scm ("denies"); }
1276
1277         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1278         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1279         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1280         | NAME { $$ = ly_symbol2scm ("context-name"); }
1281         ;
1282
1283 context_mod:
1284         property_operation { $$ = $1; }
1285         | context_def_mod STRING {
1286                 $$ = scm_list_2 ($1, $2);
1287         }
1288         ;
1289
1290 context_prop_spec:
1291         simple_string {
1292                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1293                         scm_string_to_symbol ($1));
1294         }
1295         | simple_string '.' simple_string {
1296                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1297                         scm_string_to_symbol ($3));
1298         }
1299         ;
1300
1301 music_property_def:
1302         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1303                 $$ = property_op_to_music (scm_list_4 (
1304                         ly_symbol2scm ("poppush"),
1305                         ly_cadr ($2),
1306                         $3, $5));
1307                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1308         }
1309         | REVERT context_prop_spec embedded_scm {
1310                 $$ = property_op_to_music (scm_list_3 (
1311                         ly_symbol2scm ("pop"),
1312                         ly_cadr ($2),
1313                         $3));
1314
1315                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1316         }
1317         | SET context_prop_spec '=' scalar {
1318                 $$ = property_op_to_music (scm_list_3 (
1319                         ly_symbol2scm ("assign"),
1320                         ly_cadr ($2),
1321                         $4));
1322                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1323         }
1324         | UNSET context_prop_spec {
1325                 $$ = property_op_to_music (scm_list_2 (
1326                         ly_symbol2scm ("unset"),
1327                         ly_cadr ($2)));
1328                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1329         }
1330         | ONCE music_property_def {
1331                 SCM e = $2->get_property ("element");
1332                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1333                 $$ = $2;
1334
1335         }
1336         ;
1337
1338
1339 string:
1340         STRING {
1341                 $$ = $1;
1342         }
1343         | STRING_IDENTIFIER {
1344                 $$ = $1;
1345         }
1346         | string '+' string {
1347                 $$ = scm_string_append (scm_list_2 ($1, $3));
1348         }
1349         ;
1350
1351 simple_string: STRING {
1352         }
1353         | LYRICS_STRING {
1354         }
1355         ;
1356
1357 scalar: string {
1358         }
1359         | LYRICS_STRING {
1360         }
1361         | bare_int {
1362                 $$ = scm_int2num ($1);
1363         }
1364         | embedded_scm {
1365         }
1366         | full_markup {
1367         }
1368         | DIGIT {
1369                 $$ = scm_int2num ($1);
1370         }
1371         ;
1372
1373 /*
1374 FIXME: remove or fix this comment.  What is `This'?
1375
1376 This is a trick:
1377
1378 Adding pre_events to the simple_element
1379 makes the choice between
1380
1381   string:  STRING
1382
1383 and
1384
1385   simple_element: STRING
1386
1387 a single shift/reduction conflict.
1388
1389 nevertheless, this is not very clean, and we should find a different
1390 solution.
1391
1392 */
1393 pre_events: {
1394                 THIS->push_spot ();
1395         }
1396         ;
1397
1398 event_chord:
1399         pre_events simple_element post_events   {
1400                 SCM elts = $2-> get_property ("elements");
1401
1402                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1403
1404                 $2->set_property ("elements", elts);
1405                 $$ = $2;
1406         }
1407         | command_element
1408         | note_chord_element
1409         ;
1410
1411
1412 note_chord_element:
1413         chord_body optional_notemode_duration post_events
1414         {
1415                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1416                 SCM es = $1->get_property ("elements");
1417                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1418
1419                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1420                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1421                 es = ly_append2 (es, postevs);
1422
1423                 $1-> set_property ("elements", es);
1424                 $$ = $1;
1425         }
1426         ;
1427
1428 chord_open: '<'
1429         ;
1430
1431 chord_close: '>'
1432         ;
1433
1434 simul_open: DOUBLE_ANGLE_OPEN
1435         ;
1436
1437 simul_close: DOUBLE_ANGLE_CLOSE
1438         ;
1439
1440 chord_body:
1441         chord_open chord_body_elements chord_close
1442         {
1443                 $$ = MY_MAKE_MUSIC ("EventChord");
1444                 $$->set_property ("elements",
1445                         scm_reverse_x ($2, SCM_EOL));
1446         }
1447         ;
1448
1449 chord_body_elements:
1450         /* empty */             { $$ = SCM_EOL; }
1451         | chord_body_elements chord_body_element {
1452                 $$ = scm_cons ($2->self_scm (), $1);
1453                 scm_gc_unprotect_object ($2->self_scm ());
1454         }
1455         ;
1456
1457 chord_body_element:
1458         pitch exclamations questions post_events
1459         {
1460                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1461                 n->set_property ("pitch", $1);
1462                 if ($3 % 2)
1463                         n->set_property ("cautionary", SCM_BOOL_T);
1464                 if ($2 % 2 || $3 % 2)
1465                         n->set_property ("force-accidental", SCM_BOOL_T);
1466
1467                 if (ly_c_pair_p ($4)) {
1468                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1469                         n->set_property ("articulations", arts);
1470                 }
1471                 $$ = n;
1472         }
1473         | DRUM_PITCH post_events {
1474                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1475                 n->set_property ("duration", $2);
1476                 n->set_property ("drum-type", $1);
1477                 n->set_spot (THIS->here_input ());
1478
1479                 if (ly_c_pair_p ($2)) {
1480                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1481                         n->set_property ("articulations", arts);
1482                 }
1483                 $$ = n;
1484         }
1485         ;
1486
1487 add_quote:
1488         ADDQUOTE string Music {
1489                 SCM adder = ly_scheme_function ("add-quotable");
1490
1491                 scm_call_2 (adder, $2, $3->self_scm ());
1492                 scm_gc_unprotect_object ($3->self_scm ());
1493         }
1494         ;
1495
1496 command_element:
1497         command_req {
1498                 $$ = MY_MAKE_MUSIC ("EventChord");
1499                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1500                 scm_gc_unprotect_object ($1->self_scm ());
1501
1502                 $$-> set_spot (THIS->here_input ());
1503                 $1-> set_spot (THIS->here_input ());
1504         }
1505         | SKIP duration_length {
1506                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1507                 skip->set_property ("duration", $2);
1508
1509                 $$ = skip;
1510         }
1511         | QUOTE STRING duration_length {
1512                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1513                 SCM evs = SCM_EOL;
1514                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1515                 {
1516                         SCM key = $2; // use symbol?
1517                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1518                 }
1519                 Music *quote = 0;
1520                 if (ly_c_vector_p (evs))
1521                 {
1522                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1523                         quote->set_property ("duration", $3);
1524                         quote->set_property ("quoted-events", evs);
1525                 } else {
1526                         THIS->here_input ().warning (_f ("Can\'t find music"));
1527                         quote = MY_MAKE_MUSIC ("Event");
1528                 }
1529                 quote->set_spot (THIS->here_input ());
1530                 $$ = quote;
1531         }
1532         | OCTAVE { THIS->push_spot (); }
1533           pitch {
1534                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1535                 $$ = m;
1536                 $$->set_spot (THIS->pop_spot ());
1537                 $$->set_property ("pitch", $3);
1538         }
1539         | E_LEFTSQUARE {
1540                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1541                 m->set_property ("span-direction", scm_int2num (START));
1542                 m->set_spot (THIS->here_input ());
1543
1544                 $$ = MY_MAKE_MUSIC ("EventChord");
1545                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1546                 scm_gc_unprotect_object (m->self_scm ());
1547                 $$->set_spot (THIS->here_input ());
1548         }
1549         | E_RIGHTSQUARE {
1550                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1551                 m->set_property ("span-direction", scm_int2num (STOP));
1552                 m->set_spot (THIS->here_input ());
1553
1554                 $$ = MY_MAKE_MUSIC ("EventChord");
1555                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1556                 $$->set_spot (THIS->here_input ());
1557                 scm_gc_unprotect_object (m->self_scm ());
1558         }
1559         | E_BACKSLASH {
1560                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1561                 $$->set_spot (THIS->here_input ());
1562         }
1563         | '|'      {
1564                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1565
1566                 if (Music * m = unsmob_music (pipe))
1567                         $$ = m->clone ();
1568                 else
1569                         $$ = MY_MAKE_MUSIC ("BarCheck");
1570
1571                 $$->set_spot (THIS->here_input ());
1572         }
1573         | TRANSPOSITION pitch {
1574                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1575                                         $2);
1576                 $$->set_spot (THIS-> here_input ());
1577                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1578                         $$, SCM_EOL);
1579         }
1580         | BAR STRING                    {
1581                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1582
1583                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1584                                         t, SCM_EOL);
1585                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1586                 $$->set_spot (THIS->here_input ());
1587                 t->set_spot (THIS->here_input ());
1588         }
1589         | PARTIAL duration_length       {
1590                 Moment m = - unsmob_duration ($2)->get_length ();
1591                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1592                 p->set_spot (THIS->here_input ());
1593                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1594                                         p, SCM_EOL);
1595                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1596                                         p, SCM_EOL);
1597                 $$ = p;
1598         }
1599         | CLEF STRING  {
1600                 SCM proc = ly_scheme_function ("make-clef-set");
1601
1602                 SCM result = scm_call_1 (proc, $2);
1603                 scm_gc_protect_object (result);
1604                 $$ = unsmob_music (result);
1605         }
1606         | TIME_T fraction  {
1607                 SCM proc= ly_scheme_function ("make-time-signature-set");
1608
1609                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1610                 scm_gc_protect_object (result);
1611                 $$ = unsmob_music (result);
1612         }
1613         | MARK scalar {
1614                 SCM proc = ly_scheme_function ("make-mark-set");
1615
1616                 SCM result = scm_call_1 (proc, $2);
1617                 scm_gc_protect_object (result);
1618                 $$ = unsmob_music (result);
1619         }
1620         ;
1621
1622 command_req:
1623         E_TILDE {
1624                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1625         }
1626         | MARK DEFAULT  {
1627                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1628                 $$ = m;
1629         }
1630         | tempo_event {
1631                 $$ = $1;
1632         }
1633         | KEY DEFAULT {
1634                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1635                 $$ = key;
1636         }
1637         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1638
1639                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1640                 if (scm_ilength ($3) > 0)
1641                 {
1642                         key->set_property ("pitch-alist", $3);
1643                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1644                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1645                 } else {
1646                         THIS->parser_error (_ ("Second argument must be pitch list."));
1647                 }
1648
1649                 $$ = key;
1650         }
1651         ;
1652
1653 post_events:
1654         /* empty */ {
1655                 $$ = SCM_EOL;
1656         }
1657         | post_events post_event {
1658                 $2->set_spot (THIS->here_input ());
1659                 $$ = scm_cons ($2->self_scm (), $$);
1660                 scm_gc_unprotect_object ($2->self_scm ());
1661         }
1662         | post_events tagged_post_event {
1663                 $2 -> set_spot (THIS->here_input ());
1664                 $$ = scm_cons ($2->self_scm (), $$);
1665                 scm_gc_unprotect_object ($2->self_scm ());
1666         }
1667         ;
1668
1669
1670 tagged_post_event:
1671         '-' TAG embedded_scm post_event {
1672                 tag_music ($4, $3, THIS->here_input ());
1673                 $$ = $4;
1674         }
1675         ;
1676
1677 post_event:
1678         direction_less_event {
1679                 $$ = $1;
1680         }
1681         | HYPHEN {
1682                 if (!THIS->lexer_->is_lyric_state ())
1683                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1684                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1685         }
1686         | EXTENDER {
1687                 if (!THIS->lexer_->is_lyric_state ())
1688                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1689                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1690         }
1691         | script_dir direction_reqd_event {
1692                 if ($1)
1693                         $2->set_property ("direction", scm_int2num ($1));
1694                 $$ = $2;
1695         }
1696         | script_dir direction_less_event {
1697                 if ($1)
1698                         $2->set_property ("direction", scm_int2num ($1));
1699                 $$ = $2;
1700         }
1701         | string_number_event
1702         ;
1703
1704 string_number_event:
1705         E_UNSIGNED {
1706                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1707                 s->set_property ("string-number", scm_int2num ($1));
1708                 s->set_spot (THIS->here_input ());
1709                 $$ = s;
1710         }
1711         ;
1712
1713
1714 direction_less_event:
1715         '['  {
1716
1717
1718 /*
1719
1720 TODO: should take all these defs out of the parser, adn make use
1721 configurable, i.e.
1722
1723
1724 (set-articulation '~ "trill")
1725
1726 */
1727                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1728                 m->set_spot (THIS->here_input ());
1729                 m->set_property ("span-direction", scm_int2num (START));
1730                 $$ = m;
1731         }
1732         | ']'  {
1733                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1734                 m->set_spot (THIS->here_input ());
1735                 m->set_property ("span-direction", scm_int2num (STOP));
1736                 $$ = m;
1737         }
1738         | '~' {
1739                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1740                 m->set_spot (THIS->here_input ());
1741                 $$ = m;
1742         }
1743         | close_event {
1744                 $$ = $1;
1745                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1746                         scm_int2num (START));
1747         }
1748         | open_event {
1749                 $$ = $1;
1750                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1751                         scm_int2num (STOP));
1752         }
1753         | EVENT_IDENTIFIER      {
1754                 $$ = unsmob_music ($1);
1755         }
1756         | tremolo_type  {
1757                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1758                a->set_spot (THIS->here_input ());
1759                a->set_property ("tremolo-type", scm_int2num ($1));
1760                $$ = a;
1761         }
1762         ;
1763
1764 direction_reqd_event:
1765         gen_text_def {
1766                 $$ = $1;
1767         }
1768         | script_abbreviation {
1769                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1770                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1771                 if (ly_c_string_p (s))
1772                         a->set_property ("articulation-type", s);
1773                 else THIS->parser_error (_ ("Expecting string as script definition"));
1774                 $$ = a;
1775         }
1776         ;
1777
1778 octave_check:
1779         /**/ { $$ = SCM_EOL; }
1780         | '='  { $$ = scm_int2num (0); }
1781         | '=' sub_quotes { $$ = scm_int2num ($2); }
1782         | '=' sup_quotes { $$ = scm_int2num ($2); }
1783         ;
1784
1785 sup_quotes:
1786         '\'' {
1787                 $$ = 1;
1788         }
1789         | sup_quotes '\'' {
1790                 $$ ++;
1791         }
1792         ;
1793
1794 sub_quotes:
1795         ',' {
1796                 $$ = 1;
1797         }
1798         | sub_quotes ',' {
1799                 $$++;
1800         }
1801         ;
1802
1803 steno_pitch:
1804         NOTENAME_PITCH  {
1805                 $$ = $1;
1806         }
1807         | NOTENAME_PITCH sup_quotes     {
1808                 Pitch p = *unsmob_pitch ($1);
1809                 p = p.transposed (Pitch ($2,0,0));
1810                 $$ = p.smobbed_copy ();
1811         }
1812         | NOTENAME_PITCH sub_quotes      {
1813                 Pitch p =* unsmob_pitch ($1);
1814                 p = p.transposed (Pitch (-$2,0,0));
1815                 $$ = p.smobbed_copy ();
1816         }
1817         ;
1818
1819 /*
1820 ugh. duplication
1821 */
1822
1823 steno_tonic_pitch:
1824         TONICNAME_PITCH {
1825                 $$ = $1;
1826         }
1827         | TONICNAME_PITCH sup_quotes    {
1828                 Pitch p = *unsmob_pitch ($1);
1829                 p = p.transposed (Pitch ($2,0,0));
1830                 $$ = p.smobbed_copy ();
1831         }
1832         | TONICNAME_PITCH sub_quotes     {
1833                 Pitch p =* unsmob_pitch ($1);
1834
1835                 p = p.transposed (Pitch (-$2,0,0));
1836                 $$ = p.smobbed_copy ();
1837         }
1838         ;
1839
1840 pitch:
1841         steno_pitch {
1842                 $$ = $1;
1843         }
1844         ;
1845
1846 pitch_also_in_chords:
1847         pitch
1848         | steno_tonic_pitch
1849         ;
1850
1851 close_event:
1852         '('     {
1853                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1854                 $$ = s;
1855                 s->set_spot (THIS->here_input ());
1856         }
1857         | E_OPEN        {
1858                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1859                 $$ = s;
1860                 s->set_spot (THIS->here_input ());
1861         }
1862         | E_SMALLER {
1863                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1864                 $$ = s;
1865                 s->set_spot (THIS->here_input ());
1866         }
1867         | E_BIGGER {
1868                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1869                 $$ = s;
1870                 s->set_spot (THIS->here_input ());
1871         }
1872         ;
1873
1874
1875 open_event:
1876         E_EXCLAMATION   {
1877                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1878                 s->set_spot (THIS->here_input ());
1879
1880                 $$ = s;
1881         }
1882         | ')'   {
1883                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1884                 $$ = s;
1885                 s->set_spot (THIS->here_input ());
1886
1887         }
1888         | E_CLOSE       {
1889                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1890                 $$ = s;
1891                 s->set_property ("span-type",
1892                         scm_makfrom0str ("phrasing-slur"));
1893                 s->set_spot (THIS->here_input ());
1894         }
1895         ;
1896
1897 gen_text_def:
1898         full_markup {
1899                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1900                 t->set_property ("text", $1);
1901                 t->set_spot (THIS->here_input ());
1902                 $$ = t;
1903         }
1904         | string {
1905                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1906                 t->set_property ("text",
1907                         make_simple_markup (THIS->lexer_->encoding (), $1));
1908                 t->set_spot (THIS->here_input ());
1909                 $$ = t;
1910
1911         }
1912         | DIGIT {
1913                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1914                 t->set_property ("digit", scm_int2num ($1));
1915                 t->set_spot (THIS->here_input ());
1916                 $$ = t;
1917         }
1918         ;
1919
1920 script_abbreviation:
1921         '^'             {
1922                 $$ = scm_makfrom0str ("Hat");
1923         }
1924         | '+'           {
1925                 $$ = scm_makfrom0str ("Plus");
1926         }
1927         | '-'           {
1928                 $$ = scm_makfrom0str ("Dash");
1929         }
1930         | '|'           {
1931                 $$ = scm_makfrom0str ("Bar");
1932         }
1933         | '>'           {
1934                 $$ = scm_makfrom0str ("Larger");
1935         }
1936         | '.'           {
1937                 $$ = scm_makfrom0str ("Dot");
1938         }
1939         | '_' {
1940                 $$ = scm_makfrom0str ("Underscore");
1941         }
1942         ;
1943
1944 script_dir:
1945         '_'     { $$ = DOWN; }
1946         | '^'   { $$ = UP; }
1947         | '-'   { $$ = CENTER; }
1948         ;
1949
1950
1951 absolute_pitch:
1952         steno_pitch     {
1953                 $$ = $1;
1954         }
1955         ;
1956
1957 duration_length:
1958         multiplied_duration {
1959                 $$ = $1;
1960         }
1961         ;
1962
1963 optional_notemode_duration:
1964         {
1965                 Duration dd = THIS->default_duration_;
1966                 $$ = dd.smobbed_copy ();
1967
1968                 THIS->beam_check ($$);
1969         }
1970         | multiplied_duration   {
1971                 $$ = $1;
1972                 THIS->default_duration_ = *unsmob_duration ($$);
1973
1974                 THIS->beam_check ($$);
1975         }
1976         ;
1977
1978 steno_duration:
1979         bare_unsigned dots              {
1980                 int len = 0;
1981                 if (!is_duration ($1))
1982                         THIS->parser_error (_f ("not a duration: %d", $1));
1983                 else
1984                         len = intlog2 ($1);
1985
1986                 $$ = Duration (len, $2).smobbed_copy ();
1987         }
1988         | DURATION_IDENTIFIER dots      {
1989                 Duration *d = unsmob_duration ($1);
1990                 Duration k (d->duration_log (), d->dot_count () + $2);
1991                 *d = k;
1992                 $$ = $1;
1993         }
1994         ;
1995
1996 multiplied_duration:
1997         steno_duration {
1998                 $$ = $1;
1999         }
2000         | multiplied_duration '*' bare_unsigned {
2001                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2002         }
2003         | multiplied_duration '*' FRACTION {
2004                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2005
2006                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2007         }
2008         ;
2009
2010 fraction:
2011         FRACTION { $$ = $1; }
2012         | UNSIGNED '/' UNSIGNED {
2013                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2014         }
2015         ;
2016
2017 dots:
2018         /* empty */     {
2019                 $$ = 0;
2020         }
2021         | dots '.' {
2022                 $$ ++;
2023         }
2024         ;
2025
2026 tremolo_type:
2027         ':'     {
2028                 $$ = 0;
2029         }
2030         | ':' bare_unsigned {
2031                 if (!is_duration ($2))
2032                         THIS->parser_error (_f ("not a duration: %d", $2));
2033                 $$ = $2;
2034         }
2035         ;
2036
2037 bass_number:
2038         DIGIT   {
2039                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2040                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2041                                 $$);
2042         }
2043         | UNSIGNED {
2044                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2045                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2046                                 $$);
2047         }
2048         | STRING { $$ = $1; }
2049         ;
2050
2051 bass_mod:
2052         '-'     { $$ = -2; }
2053         | '+'   { $$ = 2; }
2054         | '!'   { $$ = 0; }
2055         ;
2056
2057 bass_figure:
2058         FIGURE_SPACE {
2059                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2060                 $$ = bfr->self_scm ();
2061                 scm_gc_unprotect_object ($$);
2062         }
2063         | bass_number  {
2064                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2065                 $$ = bfr->self_scm ();
2066
2067                 bfr->set_property ("figure", $1);
2068
2069                 scm_gc_unprotect_object ($$);
2070         }
2071         | bass_figure bass_mod {
2072                 Music *m = unsmob_music ($1);
2073                 if ($2) {
2074                         SCM salter = m->get_property ("alteration");
2075                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2076                         m->set_property ("alteration",
2077                                 scm_int2num (alter + $2));
2078                 } else {
2079                         m->set_property ("alteration", scm_int2num (0));
2080                 }
2081         }
2082         ;
2083
2084 br_bass_figure:
2085         '[' bass_figure {
2086                 $$ = $2;
2087                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2088         }
2089         | bass_figure   {
2090                 $$ = $1;
2091         }
2092         | br_bass_figure ']' {
2093                 $$ = $1;
2094                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2095         }
2096         ;
2097
2098 figure_list:
2099         /**/            {
2100                 $$ = SCM_EOL;
2101         }
2102         | figure_list br_bass_figure {
2103                 $$ = scm_cons ($2, $1);
2104         }
2105         ;
2106
2107 figure_spec:
2108         FIGURE_OPEN figure_list FIGURE_CLOSE {
2109                 Music *m = MY_MAKE_MUSIC ("EventChord");
2110                 $2 = scm_reverse_x ($2, SCM_EOL);
2111                 m->set_property ("elements", $2);
2112                 $$ = m->self_scm ();
2113         }
2114         ;
2115
2116
2117 optional_rest:
2118         /**/   { $$ = 0; }
2119         | REST { $$ = 1; }
2120         ;
2121
2122 simple_element:
2123         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2124
2125                 Input i = THIS->pop_spot ();
2126                 if (!THIS->lexer_->is_note_state ())
2127                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2128
2129                 Music *n = 0;
2130                 if ($6)
2131                         n = MY_MAKE_MUSIC ("RestEvent");
2132                 else
2133                         n = MY_MAKE_MUSIC ("NoteEvent");
2134
2135                 n->set_property ("pitch", $1);
2136                 n->set_property ("duration", $5);
2137
2138                 if (ly_c_number_p ($4))
2139                 {
2140                         int q = ly_scm2int ($4);
2141                         n->set_property ("absolute-octave", scm_int2num (q-1));
2142                 }
2143
2144                 if ($3 % 2)
2145                         n->set_property ("cautionary", SCM_BOOL_T);
2146                 if ($2 % 2 || $3 % 2)
2147                         n->set_property ("force-accidental", SCM_BOOL_T);
2148
2149                 Music *v = MY_MAKE_MUSIC ("EventChord");
2150                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2151                 scm_gc_unprotect_object (n->self_scm ());
2152
2153                 v->set_spot (i);
2154                 n->set_spot (i);
2155                 $$ = v;
2156         }
2157         | DRUM_PITCH optional_notemode_duration {
2158                 Input i = THIS->pop_spot ();
2159
2160                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2161                 n->set_property ("duration", $2);
2162                 n->set_property ("drum-type", $1);
2163
2164                 Music *v = MY_MAKE_MUSIC ("EventChord");
2165                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2166                 scm_gc_unprotect_object (n->self_scm ());
2167                 v->set_spot (i);
2168                 n->set_spot (i);
2169                 $$ = v;
2170
2171         }
2172         | figure_spec optional_notemode_duration {
2173                 Music *m = unsmob_music ($1);
2174                 Input i = THIS->pop_spot ();
2175                 m->set_spot (i);
2176                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2177                 {
2178                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2179                 }
2180                 $$ = m;
2181         }
2182         | RESTNAME optional_notemode_duration           {
2183
2184                 Input i = THIS->pop_spot ();
2185                 Music *ev = 0;
2186                 if (ly_scm2string ($1) == "s") {
2187                         /* Space */
2188                         ev = MY_MAKE_MUSIC ("SkipEvent");
2189                   }
2190                 else {
2191                         ev = MY_MAKE_MUSIC ("RestEvent");
2192
2193                     }
2194                 ev->set_property ("duration", $2);
2195                 ev->set_spot (i);
2196                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2197                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2198                 velt->set_spot (i);
2199
2200                 scm_gc_unprotect_object (ev->self_scm ());
2201
2202                 $$ = velt;
2203         }
2204         | MULTI_MEASURE_REST optional_notemode_duration         {
2205                 THIS->pop_spot ();
2206
2207                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2208                 SCM mus = scm_call_2 (proc, $2,
2209                         make_input (THIS->here_input ()));
2210                 scm_gc_protect_object (mus);
2211                 $$ = unsmob_music (mus);
2212         }
2213
2214         | lyric_element optional_notemode_duration      {
2215                 Input i = THIS->pop_spot ();
2216                 if (!THIS->lexer_->is_lyric_state ())
2217                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2218
2219                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2220                 lreq->set_property ("text", $1);
2221                 lreq->set_property ("duration",$2);
2222                 lreq->set_spot (i);
2223                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2224                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2225
2226                 $$= velt;
2227         }
2228         | new_chord {
2229                 THIS->pop_spot ();
2230
2231                 if (!THIS->lexer_->is_chord_state ())
2232                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2233                 $$ = unsmob_music ($1);
2234         }
2235         ;
2236
2237 lyric_element:
2238         /* FIXME: lyric flavoured markup would be better */
2239         full_markup {
2240         }
2241         | LYRICS_STRING {
2242         }
2243         ;
2244
2245 new_chord:
2246         steno_tonic_pitch optional_notemode_duration   {
2247                 $$ = make_chord ($1, $2, SCM_EOL);
2248         }
2249         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2250                 SCM its = scm_reverse_x ($4, SCM_EOL);
2251                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2252         }
2253         ;
2254
2255 chord_items:
2256         /**/ {
2257                 $$ = SCM_EOL;
2258         }
2259         | chord_items chord_item {
2260                 $$ = scm_cons ($2, $$);
2261         }
2262         ;
2263
2264 chord_separator:
2265         CHORD_COLON {
2266                 $$ = ly_symbol2scm ("chord-colon");
2267         }
2268         | CHORD_CARET {
2269                 $$ = ly_symbol2scm ("chord-caret");
2270         }
2271         | CHORD_SLASH steno_tonic_pitch {
2272                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2273         }
2274         | CHORD_BASS steno_tonic_pitch {
2275                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2276         }
2277         ;
2278
2279 chord_item:
2280         chord_separator {
2281                 $$ = $1;
2282         }
2283         | step_numbers {
2284                 $$ = scm_reverse_x ($1, SCM_EOL);
2285         }
2286         | CHORD_MODIFIER  {
2287                 $$ = $1;
2288         }
2289         ;
2290
2291 step_numbers:
2292         step_number { $$ = scm_cons ($1, SCM_EOL); }
2293         | step_numbers '.' step_number {
2294                 $$ = scm_cons ($3, $$);
2295         }
2296         ;
2297
2298 step_number:
2299         bare_unsigned {
2300                 $$ = make_chord_step ($1, 0);
2301         }
2302         | bare_unsigned '+' {
2303                 $$ = make_chord_step ($1, SHARP);
2304         }
2305         | bare_unsigned CHORD_MINUS {
2306                 $$ = make_chord_step ($1, FLAT);
2307         }
2308         ;
2309
2310 /*
2311         UTILITIES
2312
2313 TODO: should deprecate in favor of Scheme?
2314
2315  */
2316 number_expression:
2317         number_expression '+' number_term {
2318                 $$ = scm_sum ($1, $3);
2319         }
2320         | number_expression '-' number_term {
2321                 $$ = scm_difference ($1, $3);
2322         }
2323         | number_term
2324         ;
2325
2326 number_term:
2327         number_factor {
2328                 $$ = $1;
2329         }
2330         | number_factor '*' number_factor {
2331                 $$ = scm_product ($1, $3);
2332         }
2333         | number_factor '/' number_factor {
2334                 $$ = scm_divide ($1, $3);
2335         }
2336         ;
2337
2338 number_factor:
2339         '-'  number_factor { /* %prec UNARY_MINUS */
2340                 $$ = scm_difference ($2, SCM_UNDEFINED);
2341         }
2342         | bare_number
2343         ;
2344
2345
2346 bare_number:
2347         UNSIGNED        {
2348                 $$ = scm_int2num ($1);
2349         }
2350         | REAL          {
2351                 $$ = $1;
2352         }
2353         | NUMBER_IDENTIFIER             {
2354                 $$ = $1;
2355         }
2356         | REAL NUMBER_IDENTIFIER        {
2357                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2358         }
2359         | UNSIGNED NUMBER_IDENTIFIER    {
2360                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2361         }
2362         ;
2363
2364
2365 bare_unsigned:
2366         UNSIGNED {
2367                         $$ = $1;
2368         }
2369         | DIGIT {
2370                 $$ = $1;
2371         }
2372         ;
2373
2374 bare_int:
2375         bare_number {
2376                 if (scm_integer_p ($1) == SCM_BOOL_T)
2377                 {
2378                         int k = ly_scm2int ($1);
2379                         $$ = k;
2380                 } else
2381                 {
2382                         THIS->parser_error (_ ("need integer number arg"));
2383                         $$ = 0;
2384                 }
2385         }
2386         | '-' bare_int {
2387                 $$ = -$2;
2388         }
2389         ;
2390
2391 exclamations:
2392                 { $$ = 0; }
2393         | exclamations '!'      { $$ ++; }
2394         ;
2395
2396 questions:
2397                 { $$ = 0; }
2398         | questions '?' { $$ ++; }
2399         ;
2400
2401
2402
2403 full_markup:
2404         MARKUP_IDENTIFIER {
2405                 $$ = $1;
2406         }
2407         | MARKUP
2408                 { THIS->lexer_->push_markup_state (); }
2409         markup
2410                 { $$ = $3;
2411                   THIS->lexer_->pop_state ();
2412                 }
2413         ;
2414
2415
2416 /*
2417 This should be done more dynamically if possible.
2418 */
2419 markup:
2420         STRING {
2421                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2422         }
2423         | MARKUP_HEAD_EMPTY {
2424                 $$ = scm_list_1 ($1);
2425         }
2426         | MARKUP_HEAD_MARKUP0 markup {
2427                 $$ = scm_list_2 ($1, $2);
2428         }
2429         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2430                 $$ = scm_list_3 ($1, $2, $3);
2431         }
2432         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2433                 $$ = scm_list_3 ($1, $2, $3);
2434         }
2435         | markup_line {
2436                 $$ = $1;
2437         }
2438         | MARKUP_HEAD_LIST0 markup_list {
2439                 $$ = scm_list_2 ($1,$2);
2440         }
2441         | MARKUP_HEAD_SCM0 embedded_scm {
2442                 $$ = scm_list_2 ($1, $2);
2443         }
2444         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2445                 $$ = scm_list_4 ($1, $2, $3, $4);
2446         }
2447         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2448                 $$ = scm_list_4 ($1, $2, $3, $4);
2449         }
2450         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2451                 $$ = scm_list_3 ($1, $2, $3);
2452         }
2453         | MARKUP_IDENTIFIER {
2454                 $$ = $1;
2455         }
2456         | STRING_IDENTIFIER {
2457                 $$ = $1;
2458         }
2459         | SCORE {
2460                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2461                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2462         } '{' score_body '}' {
2463                 Score * sc = $4;
2464                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2465                 scm_gc_unprotect_object (sc->self_scm ());
2466                 THIS->lexer_->pop_state ();
2467         }
2468         ;
2469
2470 markup_list:
2471         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2472         ;
2473
2474 markup_line:
2475         '{' markup_list_body '}' {
2476                 SCM line = ly_scheme_function ("line-markup");
2477
2478                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2479         }
2480         ;
2481
2482 markup_list_body:
2483         /**/ {  $$ = SCM_EOL; }
2484         | markup_list_body markup {
2485                 $$ = scm_cons ($2, $1);
2486         }
2487         ;
2488
2489
2490 %%
2491
2492 void
2493 My_lily_parser::set_yydebug (bool )
2494 {
2495 #if 0
2496         yydebug = 1;
2497 #endif
2498 }
2499
2500 void
2501 My_lily_parser::do_yyparse ()
2502 {
2503         yyparse ((void*)this);
2504 }
2505
2506
2507 /*
2508 Should make this optional?    It will also complain when you do
2509
2510         [s4]
2511
2512 which is entirely legitimate.
2513
2514 Or we can scrap it. Barchecks should detect wrong durations, and
2515 skipTypesetting speeds it up a lot.
2516 */
2517
2518 void
2519 My_lily_parser::beam_check (SCM dur)
2520 {
2521   Duration *d = unsmob_duration (dur);
2522   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2523     {
2524       Music *m = unsmob_music (last_beam_start_);
2525       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2526     }
2527   last_beam_start_ = SCM_EOL;
2528 }
2529
2530
2531
2532
2533 /*
2534
2535 It is a little strange to have this function in this file, but
2536 otherwise, we have to import music classes into the lexer.
2537
2538 */
2539 int
2540 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2541 {
2542         if (ly_c_string_p (sid)) {
2543                 *destination = sid;
2544                 return STRING_IDENTIFIER;
2545         } else if (ly_c_number_p (sid)) {
2546                 *destination = sid;
2547                 return NUMBER_IDENTIFIER;
2548         } else if (unsmob_context_def (sid)) {
2549                 *destination = unsmob_context_def (sid)->clone_scm ();
2550                 return CONTEXT_DEF_IDENTIFIER;
2551         } else if (unsmob_score (sid)) {
2552                 Score *score = new Score (*unsmob_score (sid));
2553                 *destination = score->self_scm ();
2554                 return SCORE_IDENTIFIER;
2555         } else if (Music *mus = unsmob_music (sid)) {
2556                 mus = mus->clone ();
2557                 *destination = mus->self_scm ();
2558                 unsmob_music (*destination)->
2559                         set_property ("origin", make_input (last_input_));
2560                 return dynamic_cast<Event*> (mus)
2561                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2562         } else if (unsmob_duration (sid)) {
2563                 *destination = unsmob_duration (sid)->smobbed_copy ();
2564                 return DURATION_IDENTIFIER;
2565         } else if (unsmob_output_def (sid)) {
2566                 Output_def *p = unsmob_output_def (sid);
2567                 p = p->clone ();
2568
2569                 *destination = p->self_scm ();
2570                 return OUTPUT_DEF_IDENTIFIER;
2571         } else if (Text_item::markup_p (sid)) {
2572                 *destination = sid;
2573                 return MARKUP_IDENTIFIER;
2574         }
2575
2576         return -1;
2577 }
2578
2579 Music *
2580 property_op_to_music (SCM op)
2581 {
2582         Music *m = 0;
2583         SCM tag = ly_car (op);
2584         SCM symbol = ly_cadr (op);
2585         SCM args = ly_cddr (op);
2586         SCM grob_val = SCM_UNDEFINED;
2587         SCM grob_sym = SCM_UNDEFINED;
2588         SCM val = SCM_UNDEFINED;
2589
2590         if (tag == ly_symbol2scm ("assign"))
2591                 {
2592                 m = MY_MAKE_MUSIC ("PropertySet");
2593                 val = ly_car (args);
2594                 }
2595         else if (tag == ly_symbol2scm ("unset"))
2596                 m = MY_MAKE_MUSIC ("PropertyUnset");
2597         else if (tag == ly_symbol2scm ("poppush")
2598                  || tag == ly_symbol2scm ("push"))
2599                 {
2600                 m = MY_MAKE_MUSIC ("OverrideProperty");
2601                 grob_sym = ly_car (args);
2602                 grob_val = ly_cadr (args);
2603                 }
2604         else if (tag == ly_symbol2scm ("pop")) {
2605                 m = MY_MAKE_MUSIC ("RevertProperty");
2606                 grob_sym = ly_car (args);
2607                 }
2608
2609         m->set_property ("symbol", symbol);
2610
2611         if (val != SCM_UNDEFINED)
2612                 m->set_property ("value", val);
2613         if (grob_val != SCM_UNDEFINED)
2614                 m->set_property ("grob-value", grob_val);
2615
2616         if (grob_sym != SCM_UNDEFINED)
2617                 {
2618                 bool itc = internal_type_checking_global_b;
2619                 /* UGH.
2620                 */
2621                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2622                 if (autobeam)
2623                         internal_type_checking_global_b = false;
2624                 m->set_property ("grob-property", grob_sym);
2625                 if (autobeam)
2626                         internal_type_checking_global_b = itc;
2627                 }
2628
2629         if (tag == ly_symbol2scm ("poppush"))
2630                 m->set_property ("pop-first", SCM_BOOL_T);
2631
2632
2633         return m;
2634 }
2635
2636 Music*
2637 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2638 {
2639         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2640
2641         csm->set_property ("element", m->self_scm ());
2642         scm_gc_unprotect_object (m->self_scm ());
2643
2644         csm->set_property ("context-type",
2645                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2646         csm->set_property ("property-operations", ops);
2647
2648         if (ly_c_string_p (id))
2649                 csm->set_property ("context-id", id);
2650         return csm;
2651 }
2652
2653 SCM
2654 get_next_unique_context ()
2655 {
2656         static int new_context_count;
2657         char s[1024];
2658         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2659         return scm_makfrom0str (s);
2660 }
2661