lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token LYRICS_STRING
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token NEWLYRICS
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307 %token MARKUP
 308
 309 /* escaped */
 310 /* FIXME: this sucks.  The user will get to see these names:
 311     syntax error, unexpected E_CHAR:
 312                 \
 313                  %%
 314   */
 315
 316 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 317 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 318 %token E_BACKSLASH
 319 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 320 %token FIGURE_SPACE
 321
 322 %token <i>      DIGIT
 323 %token <i>      UNSIGNED
 324 %token <i> E_UNSIGNED
 325 %token <id>     IDENTIFIER
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DRUM_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    EVENT_IDENTIFIER
 330 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    NUMBER_IDENTIFIER
 333 %token <scm>    OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    RESTNAME
 335 %token <scm>    SCM_T
 336 %token <scm>    SCORE_IDENTIFIER
 337 %token <scm>    STRING
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    TONICNAME_PITCH
 340 %token <scm>    CHORD_MODIFIER
 341 %token <scm>    FRACTION
 342 %token <scm>   REAL
 343 %token <scm> MARKUP_HEAD_EMPTY
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 346 %token <scm> MARKUP_HEAD_SCM0
 347 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 352 %token <scm> MUSIC_FUNCTION
 353 %token <scm> MUSIC_FUNCTION_MUSIC
 354 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 355 %token <scm> MUSIC_FUNCTION_SCM
 356 %token <scm> MUSIC_FUNCTION_SCM_SCM
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 360 %token DRUMS
 361
 362
 363
 364 %type <book>    book_block book_body
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       exclamations questions dots optional_rest
 367 %type <i>       script_dir
 368 %type <i>       sub_quotes sup_quotes
 369 %type <i>       tremolo_type
 370 %type <i>       bass_mod
 371
 372 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 373 %type <music>   Grouped_music_list
 374 %type <music>   Music Sequential_music Simultaneous_music
 375 %type <music>   Repeated_music
 376 %type <music>   command_req
 377 %type <music>   gen_text_def direction_less_event direction_reqd_event
 378 %type <music>   music_property_def context_change
 379 %type <music>   note_chord_element chord_body chord_body_element
 380 %type <music>   open_event close_event
 381 %type <music>   post_event tagged_post_event
 382 %type <music>   relative_music re_rhythmed_music
 383 %type <music>   simple_element event_chord command_element
 384 %type <music>   string_number_event
 385 %type <music>   toplevel_music
 386 %type <music>   tempo_event
 387
 388 %type <outputdef>       output_def_body output_def_head
 389 %type <outputdef> output_def book_paper_block
 390
 391 %type <scm>     Music_list
 392 %type <scm>     chord_body_elements
 393 %type <scm>     chord_item chord_items chord_separator new_chord
 394 %type <scm>     context_def_spec_block context_def_spec_body
 395 %type <scm>     context_mod context_def_mod optional_context_mod
 396 %type <scm>     context_prop_spec
 397 %type <scm>     duration_length fraction
 398 %type <scm>     embedded_scm scalar
 399 %type <scm>     identifier_init
 400 %type <scm>     lilypond_header lilypond_header_body
 401 %type <scm>     new_lyrics
 402 %type <scm>     post_events
 403 %type <scm>     property_operation
 404 %type <scm>     script_abbreviation
 405 %type <scm>     simple_string
 406 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 407 %type <scm>     steno_tonic_pitch
 408 %type <scm>     step_number step_numbers
 409 %type <scm>     string bare_number number_expression number_term number_factor
 410 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 411 %type <scm>     context_mod_list
 412 %type <scm>     octave_check
 413 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 414 %type <scm>     Generic_prefix_music_scm
 415 %type <scm>     lyric_element
 416 %type <scm>     Alternative_music
 417 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 418
 419 %type <score>   score_block score_body
 420
 421
 422 %left '-' '+'
 423
 424 /* We don't assign precedence to / and *, because we might need varied
 425 prec levels in different prods */
 426
 427 %left UNARY_MINUS
 428
 429 %%
 430
 431 lilypond:       /* empty */
 432         | lilypond toplevel_expression {
 433         }
 434         | lilypond assignment {
 435         }
 436         | lilypond error {
 437                 THIS->error_level_ = 1;
 438         }
 439         | lilypond INVALID      {
 440                 THIS->error_level_ = 1;
 441         }
 442         ;
 443
 444 toplevel_expression:
 445         lilypond_header {
 446                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 447         }
 448         | add_quote {
 449
 450         }
 451         | book_block {
 452                 Book *book = $1;
 453                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 454                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 455                 scm_gc_unprotect_object (book->self_scm ());
 456         }
 457         | score_block {
 458                 Score *score = $1;
 459
 460                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 461                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 462                 scm_gc_unprotect_object (score->self_scm ());
 463         }
 464         | toplevel_music {
 465                 Music *music = $1;
 466                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 467                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 468                 scm_gc_unprotect_object (music->self_scm ());
 469         }
 470         | output_def {
 471                 SCM id = SCM_EOL;
 472                 Output_def * od = $1;
 473
 474                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 475                         id = ly_symbol2scm ("$defaultpaper");
 476                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 477                         id = ly_symbol2scm ("$defaultmidi");
 478                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 479                         id = ly_symbol2scm ("$defaultbookpaper");
 480
 481                 THIS->lexer_->set_identifier (id, od->self_scm ());
 482                 scm_gc_unprotect_object (od->self_scm ());
 483         }
 484         ;
 485
 486 toplevel_music:
 487         Composite_music {
 488         }
 489         ;
 490
 491 embedded_scm:
 492         SCM_T
 493         | SCM_IDENTIFIER
 494         ;
 495
 496
 497 lilypond_header_body:
 498         {
 499                 $$ = ly_make_anonymous_module (safe_global_b);
 500                 THIS->lexer_->add_scope ($$);
 501         }
 502         | lilypond_header_body assignment  {
 503
 504         }
 505         ;
 506
 507 lilypond_header:
 508         HEADER '{' lilypond_header_body '}'     {
 509                 $$ = THIS->lexer_->remove_scope ();
 510         }
 511         ;
 512
 513
 514 /*
 515         DECLARATIONS
 516 */
 517 assignment:
 518         STRING {
 519                 THIS->push_spot ();
 520         }
 521         /* cont */ '=' identifier_init  {
 522
 523         /*
 524                 Should find generic way of associating input with objects.
 525         */
 526                 Input ip = THIS->pop_spot ();
 527
 528                 if (! is_regular_identifier ($1))
 529                 {
 530                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 531                 }
 532
 533                 THIS->lexer_->set_identifier ($1, $4);
 534
 535 /*
 536  TODO: devise standard for protection in parser.
 537
 538   The parser stack lives on the C-stack, which means that
 539 all objects can be unprotected as soon as they're here.
 540
 541 */
 542         }
 543         | embedded_scm { }
 544         ;
 545
 546
 547 identifier_init:
 548         score_block {
 549                 $$ = $1->self_scm ();
 550                 scm_gc_unprotect_object ($$);
 551         }
 552         | full_markup {
 553                 $$ = $1;
 554         }
 555         | output_def {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | context_def_spec_block {
 560                 $$ = $1;
 561         }
 562         | Music  {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | post_event {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | number_expression {
 571                 $$ = $1;
 572         }
 573         | string {
 574                 $$ = $1;
 575         }
 576         | embedded_scm  {
 577                 $$ = $1;
 578         }
 579         ;
 580
 581 context_def_spec_block:
 582         CONTEXT '{' context_def_spec_body '}'
 583                 {
 584                 $$ = $3;
 585         }
 586         ;
 587
 588 context_def_spec_body:
 589         /**/ {
 590                 $$ = Context_def::make_scm ();
 591                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 592         }
 593         | CONTEXT_DEF_IDENTIFIER {
 594                 $$ = $1;
 595                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 596         }
 597         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 598                 Context_def*td = unsmob_context_def ($$);
 599
 600                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 601                         SCM tag = ly_caar (p);
 602
 603                         /* TODO: should make new tag "grob-definition" ? */
 604                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 605                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 606                 }
 607         }
 608         | context_def_spec_body context_mod {
 609                 unsmob_context_def ($$)->add_context_mod ($2);
 610         }
 611         ;
 612
 613
 614
 615 book_block:
 616         BOOK {
 617                 THIS->push_spot ();
 618         }
 619         /*cont*/ '{' book_body '}'      {
 620                 THIS->pop_spot ();
 621                 $$ = $4;
 622         }
 623         ;
 624
 625 /* FIXME:
 626    * Use 'handlers' like for toplevel-* stuff?
 627    * grok \paper and \midi?  */
 628 book_body:
 629         {
 630                 $$ = new Book;
 631                 $$->set_spot (THIS->here_input ());
 632                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 633                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 634                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 635         }
 636         | book_body book_paper_block {
 637                 $$->bookpaper_ = $2;
 638                 scm_gc_unprotect_object ($2->self_scm ());
 639         }
 640         | book_body score_block {
 641                 Score *score = $2;
 642                 $$->scores_.push (score);
 643                 scm_gc_unprotect_object (score->self_scm ());
 644         }
 645         | book_body Composite_music {
 646                 Music *music = $2;
 647                 Score *score
 648                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 649                 $$->scores_.push (score);
 650                 scm_gc_unprotect_object (music->self_scm ());
 651         }
 652         | book_body lilypond_header {
 653                 $$->header_ = $2;
 654         }
 655         | book_body error {
 656
 657         }
 658         ;
 659
 660 score_block:
 661         SCORE {
 662                 THIS->push_spot ();
 663         }
 664         /*cont*/ '{' score_body '}'     {
 665                 THIS->pop_spot ();
 666                 $$ = $4;
 667         }
 668         ;
 669
 670 score_body:
 671         /**/    {
 672                 $$ = new Score;
 673
 674                 $$->set_spot (THIS->here_input ());
 675         }
 676         | SCORE_IDENTIFIER {
 677                 $$ = new Score ( *unsmob_score ($1));
 678                 $$->set_spot (THIS->here_input ());
 679         }
 680         | score_body Music {
 681                 SCM m = $2->self_scm ();
 682                 scm_gc_unprotect_object (m);
 683
 684                 /*
 685                         guh.
 686                 */
 687                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 688                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 689                         m = scm_call_1 (ly_car (check_funcs), m);
 690                 if (unsmob_music ($$->music_))
 691                 {
 692                         THIS->parser_error (_("Already have music in score"));
 693                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 694                 }
 695                 $$->music_ = m;
 696         }
 697         | score_body lilypond_header    {
 698                 $$->header_ = $2;
 699         }
 700         | score_body output_def {
 701                 $$->defs_.push ($2);
 702                 scm_gc_unprotect_object ($2->self_scm ());
 703         }
 704         | score_body error {
 705
 706         }
 707         ;
 708
 709
 710 /*
 711         OUTPUT DEF
 712 */
 713
 714 book_paper_block:
 715         output_def {
 716                 $$ = $1;
 717                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 718                 {
 719                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 720                         $$ = get_bookpaper (THIS);
 721                 }
 722         }
 723         ;
 724
 725
 726 output_def:
 727         output_def_body '}' {
 728                 $$ = $1;
 729                 if ($1->parent_)
 730                         THIS->lexer_->remove_scope ();
 731
 732                 THIS->lexer_->remove_scope ();
 733                 THIS->lexer_->pop_state ();
 734         }
 735         ;
 736
 737 output_def_head:
 738         BOOKPAPER {
 739                 $$ = get_bookpaper (THIS);
 740                 $$->input_origin_ = THIS->here_input ();
 741                 THIS->lexer_->add_scope ($$->scope_);
 742         }
 743         | MIDI    {
 744                 Output_def *p = get_midi (THIS);
 745                 $$ = p;
 746                 THIS->lexer_->add_scope (p->scope_);
 747         }
 748         | PAPER         {
 749                 Output_def* p = get_paper (THIS);
 750
 751                 if (p->parent_)
 752                         THIS->lexer_->add_scope (p->parent_->scope_);
 753
 754                 THIS->lexer_->add_scope (p->scope_);
 755                 $$ = p;
 756         }
 757         ;
 758
 759
 760 output_def_body:
 761         output_def_head '{' {
 762                 $$ = $1;
 763                 $$->input_origin_.set_spot (THIS->here_input ());
 764                 THIS->lexer_->push_initial_state ();
 765         }
 766         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 767                 scm_gc_unprotect_object ($1->self_scm ());
 768                 Output_def *o = unsmob_output_def ($3);
 769                 o->input_origin_.set_spot (THIS->here_input ());
 770                 $$ = o;
 771                 THIS->lexer_->remove_scope ();
 772                 THIS->lexer_->add_scope (o->scope_);
 773                 THIS->lexer_->push_initial_state ();
 774         }
 775         | output_def_body assignment  {
 776
 777         }
 778         | output_def_body context_def_spec_block        {
 779                 assign_context_def ($$, $2);
 780         }
 781         | output_def_body tempo_event  {
 782                 /*
 783                         junk this ? there already is tempo stuff in
 784                         music.
 785                 */
 786                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 787                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 788                 set_tempo ($$, d->get_length (), m);
 789                 scm_gc_unprotect_object ($2->self_scm ());
 790         }
 791         | output_def_body error {
 792
 793         }
 794         ;
 795
 796 tempo_event:
 797         TEMPO steno_duration '=' bare_unsigned  {
 798                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 799                 $$->set_property ("tempo-unit", $2);
 800                 $$->set_property ("metronome-count", scm_int2num ( $4));
 801         }
 802         ;
 803
 804 /*
 805 The representation of a  list is the
 806
 807   (LIST . LAST-CONS)
 808
 809  to have  efficient append.
 810 */
 811 Music_list:
 812         /* empty */ {
 813                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 814         }
 815         | Music_list Music {
 816                 SCM s = $$;
 817                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 818                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 819                 if (ly_c_pair_p (ly_cdr (s)))
 820                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 821                 else
 822                         scm_set_car_x (s, c); /* set first cons */
 823                 scm_set_cdr_x (s, c);  /* remember last cell */
 824         }
 825         | Music_list embedded_scm {
 826         }
 827         | Music_list error {
 828         }
 829         ;
 830
 831
 832 Music:
 833         Simple_music
 834         | Composite_music
 835         ;
 836
 837 Alternative_music:
 838         /* empty */ {
 839                 $$ = SCM_EOL;
 840         }
 841         | ALTERNATIVE '{' Music_list '}' {
 842                 $$ = $3;
 843         }
 844         ;
 845
 846
 847 Repeated_music:
 848         REPEAT simple_string bare_unsigned Music Alternative_music
 849         {
 850                 Music *beg = $4;
 851                 int times = $3;
 852                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 853                 if (times < scm_ilength (alts)) {
 854                   unsmob_music (ly_car (alts))
 855                     ->origin ()->warning (
 856                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 857                   alts = ly_truncate_list (times, alts);
 858                 }
 859
 860
 861                 SCM proc = ly_scheme_function ("make-repeated-music");
 862
 863                 SCM mus = scm_call_1 (proc, $2);
 864                 scm_gc_protect_object (mus); // UGH.
 865                 Music *r = unsmob_music (mus);
 866                 if (beg)
 867                         {
 868                         r-> set_property ("element", beg->self_scm ());
 869                         scm_gc_unprotect_object (beg->self_scm ());
 870                         }
 871                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 872
 873                 r-> set_property ("elements",alts);
 874                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 875                         /*
 876                         TODO: move this code to Scheme.
 877                         */
 878
 879                         /*
 880                         we can not get durations and other stuff correct down the line, so we have to
 881                         add to the duration log here.
 882                         */
 883                         SCM func = ly_scheme_function ("shift-duration-log");
 884
 885                         int dots = ($3 % 3) ? 0 : 1;
 886                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 887
 888                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 889
 890                         if (seq) {
 891                                 int list_len = scm_ilength (seq->music_list ());
 892                                 if (list_len != 2)
 893                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 894                                 shift -= 1;
 895                                 r->compress (Moment (Rational (1, list_len)));
 896                                 }
 897                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 898
 899                 }
 900                 r->set_spot (*$4->origin ());
 901
 902                 $$ = r;
 903         }
 904         ;
 905
 906 Sequential_music:
 907         SEQUENTIAL '{' Music_list '}'           {
 908                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 909                 $$->set_property ("elements", ly_car ($3));
 910                 $$->set_spot (THIS->here_input ());
 911         }
 912         | '{' Music_list '}'            {
 913                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 914                 $$->set_property ("elements", ly_car ($2));
 915                 $$->set_spot (THIS->here_input ());
 916         }
 917         ;
 918
 919 Simultaneous_music:
 920         SIMULTANEOUS '{' Music_list '}'{
 921                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 922                 $$->set_property ("elements", ly_car ($3));
 923                 $$->set_spot (THIS->here_input ());
 924
 925         }
 926         | simul_open Music_list simul_close     {
 927                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 928                 $$->set_property ("elements", ly_car ($2));
 929                 $$->set_spot (THIS->here_input ());
 930         }
 931         ;
 932
 933 Simple_music:
 934         event_chord             { $$ = $1; }
 935         | MUSIC_IDENTIFIER {
 936                 $$ = unsmob_music ($1);
 937         }
 938         | music_property_def
 939         | context_change
 940         ;
 941
 942
 943 optional_context_mod:
 944         /**/ { $$ = SCM_EOL; }
 945         | WITH { THIS->lexer_->push_initial_state (); }
 946         '{' context_mod_list '}'
 947         {
 948                 THIS->lexer_->pop_state ();
 949                 $$ = $4;
 950         }
 951         ;
 952
 953 context_mod_list:
 954         /* */  { $$ = SCM_EOL; }
 955         | context_mod_list context_mod  {
 956                  $$ = scm_cons ($2, $1);
 957         }
 958         ;
 959
 960
 961 Composite_music:
 962         Prefix_composite_music { $$ = $1; }
 963         | Grouped_music_list { $$ = $1; }
 964         ;
 965
 966 Grouped_music_list:
 967         Simultaneous_music              { $$ = $1; }
 968         | Sequential_music              { $$ = $1; }
 969         ;
 970
 971 Generic_prefix_music_scm:
 972         MUSIC_FUNCTION {
 973                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 974         }
 975         | MUSIC_FUNCTION_SCM {
 976                 THIS->push_spot ();
 977         } embedded_scm {
 978                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 979         }
 980         | MUSIC_FUNCTION_MUSIC {
 981                 THIS->push_spot ();
 982         } Music {
 983                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 984                 scm_gc_unprotect_object ($3->self_scm ());
 985         }
 986         | MUSIC_FUNCTION_SCM_MUSIC {
 987                 THIS->push_spot ();
 988         }  embedded_scm Music {
 989                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 990                 scm_gc_unprotect_object ($4->self_scm ());
 991         }
 992         | MUSIC_FUNCTION_SCM_SCM {
 993                 THIS->push_spot ();
 994         }  embedded_scm embedded_scm {
 995                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 996         }
 997         | MUSIC_FUNCTION_MUSIC_MUSIC {
 998                 THIS->push_spot ();
 999         }  Music  Music {
1000                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1001                 scm_gc_unprotect_object ($3->self_scm ());
1002                 scm_gc_unprotect_object ($4->self_scm ());
1003         }
1004         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1005                 THIS->push_spot ();
1006         } embedded_scm Music Music {
1007                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1008                         $3, $4->self_scm (), $5->self_scm ());
1009                 scm_gc_unprotect_object ($5->self_scm ());
1010                 scm_gc_unprotect_object ($4->self_scm ());
1011         }
1012         ;
1013
1014 Generic_prefix_music:
1015         Generic_prefix_music_scm {
1016                 SCM func = ly_car ($1);
1017                 Input *loc = unsmob_input (ly_cadr ($1));
1018                 SCM args = ly_cddr ($1);
1019                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1020                 int k = 0;
1021                 bool ok  = true;
1022                 for (SCM s = sig, t = args;
1023                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1024                         s = ly_cdr (s), t = ly_cdr (t)) {
1025                         k++;
1026                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1027                         {
1028                                 loc->error (_f ("Argument %d failed typecheck", k));
1029                                 THIS->error_level_ = 1;
1030                                 ok = false;
1031                         }
1032                 }
1033                 SCM m = SCM_EOL;
1034                 if (ok)
1035                         m = scm_apply_0 (func, ly_cdr ($1));
1036                 if (unsmob_music (m))
1037                         {
1038                         $$ = unsmob_music (m);
1039                         scm_gc_protect_object (m);
1040                         }
1041                 else
1042                         {
1043                         if (ok)
1044                                 loc->error (_ ("Music head function should return Music object."));
1045                         $$ = MY_MAKE_MUSIC ("Music");
1046                         }
1047                 $$->set_spot (*loc);
1048         }
1049         ;
1050
1051
1052 Prefix_composite_music:
1053         Generic_prefix_music {
1054                 $$ = $1;
1055         }
1056         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1057                 $$ = context_spec_music ($2, $4, $6, $5);
1058
1059         }
1060         | CONTEXT simple_string optional_context_mod Music {
1061                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1062         }
1063         | NEWCONTEXT simple_string optional_context_mod Music {
1064                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1065                         $3);
1066         }
1067
1068         | TIMES {
1069                 THIS->push_spot ();
1070         }
1071         /* CONTINUED */
1072                 fraction Music
1073
1074         {
1075                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1076                 Music *mp = $4;
1077
1078                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1079                 $$->set_spot (THIS->pop_spot ());
1080
1081                 $$->set_property ("element", mp->self_scm ());
1082                 scm_gc_unprotect_object (mp->self_scm ());
1083                 $$->set_property ("numerator", scm_int2num (n));
1084                 $$->set_property ("denominator", scm_int2num (d));
1085                 $$->compress (Moment (Rational (n,d)));
1086
1087         }
1088         | Repeated_music                { $$ = $1; }
1089         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1090                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1091                 Music *p = $4;
1092                 Pitch from = *unsmob_pitch ($2);
1093                 Pitch to = *unsmob_pitch ($3);
1094
1095                 p->transpose (interval (from, to));
1096                 $$->set_property ("element", p->self_scm ());
1097                 scm_gc_unprotect_object (p->self_scm ());
1098         }
1099         | NOTES
1100                 {
1101                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1102                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1103         }
1104         Music
1105                 { $$ = $3;
1106                   THIS->lexer_->pop_state ();
1107                 }
1108         | DRUMS
1109                 {
1110                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1111                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1112         }
1113         /* FIXME: This used to be: */
1114         Music
1115 /*      Grouped_music_list */
1116                 { $$ = $3;
1117                   THIS->lexer_->pop_state ();
1118                 }
1119         | FIGURES
1120                 { THIS->lexer_->push_figuredbass_state (); }
1121         /* FIXME: This used to be:
1122         Music
1123         but that breaks web build
1124         */
1125         Grouped_music_list
1126                 {
1127                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1128                   chm->set_property ("element", $3->self_scm ());
1129                   $$ = chm;
1130                   scm_gc_unprotect_object ($3->self_scm ());
1131
1132                   THIS->lexer_->pop_state ();
1133         }
1134         | CHORDS {
1135                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1136                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1137                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1138                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1139
1140         }
1141         /* FIXME:
1142         Music
1143 */
1144         Grouped_music_list
1145         {
1146                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1147                   chm->set_property ("element", $3->self_scm ());
1148                   scm_gc_unprotect_object ($3->self_scm ());
1149                   $$ = chm;
1150
1151                   THIS->lexer_->pop_state ();
1152         }
1153         | LYRICS
1154                 { THIS->lexer_->push_lyric_state (); }
1155         /* FIXME:
1156         Music
1157 */
1158         Grouped_music_list
1159                 {
1160                   $$ = $3;
1161                   THIS->lexer_->pop_state ();
1162         }
1163         | relative_music        { $$ = $1; }
1164         | re_rhythmed_music     { $$ = $1; }
1165         | TAG embedded_scm Music {
1166                 tag_music ($3, $2, THIS->here_input ());
1167                 $$ = $3;
1168         }
1169         ;
1170
1171 relative_music:
1172         RELATIVE absolute_pitch Music {
1173                 Music *m = $3;
1174                 Pitch start = *unsmob_pitch ($2);
1175                 $$ = make_music_relative (start, m);
1176                 scm_gc_unprotect_object (m->self_scm ());
1177         }
1178         | RELATIVE Composite_music {
1179                 Music *m = $2;
1180
1181                 Pitch middle_c (0, 0, 0);
1182                 $$ = make_music_relative (middle_c, m);
1183                 scm_gc_unprotect_object (m->self_scm ());
1184         }
1185         ;
1186
1187 new_lyrics:
1188         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1189         /*cont */
1190         Grouped_music_list {
1191         /* Can also use Music at the expensive of two S/Rs similar to
1192            \repeat \alternative */
1193                 THIS->lexer_->pop_state ();
1194 #if 0
1195                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1196                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1197                 $$ = music;
1198 #else
1199                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1200 #endif
1201         }
1202         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1203         Grouped_music_list {
1204                 THIS->lexer_->pop_state ();
1205                 $$ = scm_cons ($4->self_scm (), $1);
1206         }
1207         ;
1208
1209 re_rhythmed_music:
1210         Grouped_music_list new_lyrics {
1211
1212                 /* FIXME: should find out uniqueXXX name from music */
1213                 SCM name = $1->get_property ("context-id");
1214                 //if (name == SCM_EOL)
1215                 if (!ly_c_string_p (name))
1216                         name = scm_makfrom0str ("");
1217
1218                 SCM context = scm_makfrom0str ("Lyrics");
1219                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1220
1221                 SCM lst = SCM_EOL;
1222                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1223                 {
1224                         Music *music = unsmob_music (ly_car (s));
1225                         Music *com = make_lyric_combine_music (name, music);
1226                         Music *csm = context_spec_music (context,
1227                                 get_next_unique_context (), com, SCM_EOL);
1228                         lst = scm_cons (csm->self_scm (), lst);
1229                 }
1230                 /* FIXME: only first lyric music is accepted,
1231                           the rest is junked */
1232                 all->set_property ("elements", scm_cons ($1->self_scm (),
1233                         lst));
1234                 $$ = all;
1235                 scm_gc_unprotect_object ($1->self_scm ());
1236         }
1237         | LYRICSTO string Music {
1238                 Music *music = $3;
1239                 SCM name = $2;
1240                 $$ = make_lyric_combine_music (name, music);
1241                 scm_gc_unprotect_object (music->self_scm ());
1242         }
1243         ;
1244
1245 context_change:
1246         CHANGE STRING '=' STRING  {
1247                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1248                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1249                 t-> set_property ("change-to-id", $4);
1250
1251                 $$ = t;
1252                 $$->set_spot (THIS->here_input ());
1253         }
1254         ;
1255
1256 property_operation:
1257         STRING '=' scalar {
1258                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1259                         scm_string_to_symbol ($1), $3);
1260         }
1261         | UNSET simple_string {
1262                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1263                         scm_string_to_symbol ($2));
1264         }
1265         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1266                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1267                         scm_string_to_symbol ($2), $3, $5);
1268         }
1269         | REVERT simple_string embedded_scm {
1270                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1271                         scm_string_to_symbol ($2), $3);
1272         }
1273         ;
1274
1275 context_def_mod:
1276         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1277         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1278         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1279
1280         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1281         | DENIES { $$ = ly_symbol2scm ("denies"); }
1282
1283         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1284         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1285         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1286         | NAME { $$ = ly_symbol2scm ("context-name"); }
1287         ;
1288
1289 context_mod:
1290         property_operation { $$ = $1; }
1291         | context_def_mod STRING {
1292                 $$ = scm_list_2 ($1, $2);
1293         }
1294         ;
1295
1296 context_prop_spec:
1297         simple_string {
1298                 if (!is_regular_identifier ($1))
1299                 {
1300                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1301                 }
1302
1303                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1304                         scm_string_to_symbol ($1));
1305         }
1306         | simple_string '.' simple_string {
1307                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1308                         scm_string_to_symbol ($3));
1309         }
1310         ;
1311
1312 music_property_def:
1313         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1314                 $$ = property_op_to_music (scm_list_4 (
1315                         ly_symbol2scm ("poppush"),
1316                         ly_cadr ($2),
1317                         $3, $5));
1318                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1319         }
1320         | REVERT context_prop_spec embedded_scm {
1321                 $$ = property_op_to_music (scm_list_3 (
1322                         ly_symbol2scm ("pop"),
1323                         ly_cadr ($2),
1324                         $3));
1325
1326                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1327         }
1328         | SET context_prop_spec '=' scalar {
1329                 $$ = property_op_to_music (scm_list_3 (
1330                         ly_symbol2scm ("assign"),
1331                         ly_cadr ($2),
1332                         $4));
1333                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1334         }
1335         | UNSET context_prop_spec {
1336                 $$ = property_op_to_music (scm_list_2 (
1337                         ly_symbol2scm ("unset"),
1338                         ly_cadr ($2)));
1339                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1340         }
1341         | ONCE music_property_def {
1342                 SCM e = $2->get_property ("element");
1343                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1344                 $$ = $2;
1345
1346         }
1347         ;
1348
1349
1350 string:
1351         STRING {
1352                 $$ = $1;
1353         }
1354         | STRING_IDENTIFIER {
1355                 $$ = $1;
1356         }
1357         | string '+' string {
1358                 $$ = scm_string_append (scm_list_2 ($1, $3));
1359         }
1360         ;
1361
1362 simple_string: STRING {
1363         }
1364         | LYRICS_STRING {
1365         }
1366         ;
1367
1368 scalar: string {
1369         }
1370         | LYRICS_STRING {
1371         }
1372         | bare_int {
1373                 $$ = scm_int2num ($1);
1374         }
1375         | embedded_scm {
1376         }
1377         | full_markup {
1378         }
1379         | DIGIT {
1380                 $$ = scm_int2num ($1);
1381         }
1382         ;
1383
1384 /*
1385 FIXME: remove or fix this comment.  What is `This'?
1386
1387 This is a trick:
1388
1389 Adding pre_events to the simple_element
1390 makes the choice between
1391
1392   string:  STRING
1393
1394 and
1395
1396   simple_element: STRING
1397
1398 a single shift/reduction conflict.
1399
1400 nevertheless, this is not very clean, and we should find a different
1401 solution.
1402
1403 */
1404 pre_events: {
1405                 THIS->push_spot ();
1406         }
1407         ;
1408
1409 event_chord:
1410         pre_events simple_element post_events   {
1411                 SCM elts = $2-> get_property ("elements");
1412
1413                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1414
1415                 $2->set_property ("elements", elts);
1416                 $$ = $2;
1417         }
1418         | command_element
1419         | note_chord_element
1420         ;
1421
1422
1423 note_chord_element:
1424         chord_body optional_notemode_duration post_events
1425         {
1426                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1427                 SCM es = $1->get_property ("elements");
1428                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1429
1430                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1431                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1432                 es = ly_append2 (es, postevs);
1433
1434                 $1-> set_property ("elements", es);
1435                 $$ = $1;
1436         }
1437         ;
1438
1439 chord_open: '<'
1440         ;
1441
1442 chord_close: '>'
1443         ;
1444
1445 simul_open: DOUBLE_ANGLE_OPEN
1446         ;
1447
1448 simul_close: DOUBLE_ANGLE_CLOSE
1449         ;
1450
1451 chord_body:
1452         chord_open chord_body_elements chord_close
1453         {
1454                 $$ = MY_MAKE_MUSIC ("EventChord");
1455                 $$->set_property ("elements",
1456                         scm_reverse_x ($2, SCM_EOL));
1457         }
1458         ;
1459
1460 chord_body_elements:
1461         /* empty */             { $$ = SCM_EOL; }
1462         | chord_body_elements chord_body_element {
1463                 $$ = scm_cons ($2->self_scm (), $1);
1464                 scm_gc_unprotect_object ($2->self_scm ());
1465         }
1466         ;
1467
1468 chord_body_element:
1469         pitch  exclamations questions octave_check post_events
1470         {
1471                 int q = $3;
1472                 int ex = $2;
1473                 SCM check = $4;
1474                 SCM post = $5;
1475
1476                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1477                 n->set_property ("pitch", $1);
1478                 if (q % 2)
1479                         n->set_property ("cautionary", SCM_BOOL_T);
1480                 if (ex % 2 || q % 2)
1481                         n->set_property ("force-accidental", SCM_BOOL_T);
1482
1483                 if (ly_c_pair_p (post)) {
1484                         SCM arts = scm_reverse_x (post, SCM_EOL);
1485                         n->set_property ("articulations", arts);
1486                 }
1487                 if (ly_c_number_p (check))
1488                 {
1489                         int q = ly_scm2int (check);
1490                         n->set_property ("absolute-octave", scm_int2num (q-1));
1491                 }
1492
1493
1494                 $$ = n;
1495         }
1496         | DRUM_PITCH post_events {
1497                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1498                 n->set_property ("duration", $2);
1499                 n->set_property ("drum-type", $1);
1500                 n->set_spot (THIS->here_input ());
1501
1502                 if (ly_c_pair_p ($2)) {
1503                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1504                         n->set_property ("articulations", arts);
1505                 }
1506                 $$ = n;
1507         }
1508         ;
1509
1510 add_quote:
1511         ADDQUOTE string Music {
1512                 SCM adder = ly_scheme_function ("add-quotable");
1513
1514                 scm_call_2 (adder, $2, $3->self_scm ());
1515                 scm_gc_unprotect_object ($3->self_scm ());
1516         }
1517         ;
1518
1519 command_element:
1520         command_req {
1521                 $$ = MY_MAKE_MUSIC ("EventChord");
1522                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1523                 scm_gc_unprotect_object ($1->self_scm ());
1524
1525                 $$-> set_spot (THIS->here_input ());
1526                 $1-> set_spot (THIS->here_input ());
1527         }
1528         | SKIP duration_length {
1529                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1530                 skip->set_property ("duration", $2);
1531
1532                 $$ = skip;
1533         }
1534         | QUOTE STRING duration_length {
1535                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1536                 SCM evs = SCM_EOL;
1537                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1538                 {
1539                         SCM key = $2; // use symbol?
1540                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1541                 }
1542                 Music *quote = 0;
1543                 if (ly_c_vector_p (evs))
1544                 {
1545                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1546                         quote->set_property ("duration", $3);
1547                         quote->set_property ("quoted-events", evs);
1548                 } else {
1549                         THIS->here_input ().warning (_f ("Can\'t find music"));
1550                         quote = MY_MAKE_MUSIC ("Event");
1551                 }
1552                 quote->set_spot (THIS->here_input ());
1553                 $$ = quote;
1554         }
1555         | OCTAVE { THIS->push_spot (); }
1556           pitch {
1557                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1558                 $$ = m;
1559                 $$->set_spot (THIS->pop_spot ());
1560                 $$->set_property ("pitch", $3);
1561         }
1562         | E_LEFTSQUARE {
1563                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1564                 m->set_property ("span-direction", scm_int2num (START));
1565                 m->set_spot (THIS->here_input ());
1566
1567                 $$ = MY_MAKE_MUSIC ("EventChord");
1568                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1569                 scm_gc_unprotect_object (m->self_scm ());
1570                 $$->set_spot (THIS->here_input ());
1571         }
1572         | E_RIGHTSQUARE {
1573                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1574                 m->set_property ("span-direction", scm_int2num (STOP));
1575                 m->set_spot (THIS->here_input ());
1576
1577                 $$ = MY_MAKE_MUSIC ("EventChord");
1578                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1579                 $$->set_spot (THIS->here_input ());
1580                 scm_gc_unprotect_object (m->self_scm ());
1581         }
1582         | E_BACKSLASH {
1583                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1584                 $$->set_spot (THIS->here_input ());
1585         }
1586         | '|'      {
1587                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1588
1589                 if (Music * m = unsmob_music (pipe))
1590                         $$ = m->clone ();
1591                 else
1592                         $$ = MY_MAKE_MUSIC ("BarCheck");
1593
1594                 $$->set_spot (THIS->here_input ());
1595         }
1596         | TRANSPOSITION pitch {
1597                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1598                                         $2);
1599                 $$->set_spot (THIS-> here_input ());
1600                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1601                         $$, SCM_EOL);
1602         }
1603         | BAR STRING                    {
1604                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1605
1606                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1607                                         t, SCM_EOL);
1608                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1609                 $$->set_spot (THIS->here_input ());
1610                 t->set_spot (THIS->here_input ());
1611         }
1612         | PARTIAL duration_length       {
1613                 Moment m = - unsmob_duration ($2)->get_length ();
1614                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1615                 p->set_spot (THIS->here_input ());
1616                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1617                                         p, SCM_EOL);
1618                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1619                                         p, SCM_EOL);
1620                 $$ = p;
1621         }
1622         | CLEF STRING  {
1623                 SCM proc = ly_scheme_function ("make-clef-set");
1624
1625                 SCM result = scm_call_1 (proc, $2);
1626                 scm_gc_protect_object (result);
1627                 $$ = unsmob_music (result);
1628         }
1629         | TIME_T fraction  {
1630                 SCM proc= ly_scheme_function ("make-time-signature-set");
1631
1632                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1633                 scm_gc_protect_object (result);
1634                 $$ = unsmob_music (result);
1635         }
1636         | MARK scalar {
1637                 SCM proc = ly_scheme_function ("make-mark-set");
1638
1639                 SCM result = scm_call_1 (proc, $2);
1640                 scm_gc_protect_object (result);
1641                 $$ = unsmob_music (result);
1642         }
1643         ;
1644
1645 command_req:
1646         E_TILDE {
1647                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1648         }
1649         | MARK DEFAULT  {
1650                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1651                 $$ = m;
1652         }
1653         | tempo_event {
1654                 $$ = $1;
1655         }
1656         | KEY DEFAULT {
1657                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1658                 $$ = key;
1659         }
1660         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1661
1662                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1663                 if (scm_ilength ($3) > 0)
1664                 {
1665                         key->set_property ("pitch-alist", $3);
1666                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1667                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1668                 } else {
1669                         THIS->parser_error (_ ("Second argument must be pitch list."));
1670                 }
1671
1672                 $$ = key;
1673         }
1674         ;
1675
1676 post_events:
1677         /* empty */ {
1678                 $$ = SCM_EOL;
1679         }
1680         | post_events post_event {
1681                 $2->set_spot (THIS->here_input ());
1682                 $$ = scm_cons ($2->self_scm (), $$);
1683                 scm_gc_unprotect_object ($2->self_scm ());
1684         }
1685         | post_events tagged_post_event {
1686                 $2 -> set_spot (THIS->here_input ());
1687                 $$ = scm_cons ($2->self_scm (), $$);
1688                 scm_gc_unprotect_object ($2->self_scm ());
1689         }
1690         ;
1691
1692
1693 tagged_post_event:
1694         '-' TAG embedded_scm post_event {
1695                 tag_music ($4, $3, THIS->here_input ());
1696                 $$ = $4;
1697         }
1698         ;
1699
1700 post_event:
1701         direction_less_event {
1702                 $$ = $1;
1703         }
1704         | HYPHEN {
1705                 if (!THIS->lexer_->is_lyric_state ())
1706                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1707                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1708         }
1709         | EXTENDER {
1710                 if (!THIS->lexer_->is_lyric_state ())
1711                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1712                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1713         }
1714         | script_dir direction_reqd_event {
1715                 if ($1)
1716                         $2->set_property ("direction", scm_int2num ($1));
1717                 $$ = $2;
1718         }
1719         | script_dir direction_less_event {
1720                 if ($1)
1721                         $2->set_property ("direction", scm_int2num ($1));
1722                 $$ = $2;
1723         }
1724         | string_number_event
1725         ;
1726
1727 string_number_event:
1728         E_UNSIGNED {
1729                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1730                 s->set_property ("string-number", scm_int2num ($1));
1731                 s->set_spot (THIS->here_input ());
1732                 $$ = s;
1733         }
1734         ;
1735
1736
1737 direction_less_event:
1738         '['  {
1739
1740
1741 /*
1742
1743 TODO: should take all these defs out of the parser, adn make use
1744 configurable, i.e.
1745
1746
1747 (set-articulation '~ "trill")
1748
1749 */
1750                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1751                 m->set_spot (THIS->here_input ());
1752                 m->set_property ("span-direction", scm_int2num (START));
1753                 $$ = m;
1754         }
1755         | ']'  {
1756                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1757                 m->set_spot (THIS->here_input ());
1758                 m->set_property ("span-direction", scm_int2num (STOP));
1759                 $$ = m;
1760         }
1761         | '~' {
1762                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1763                 m->set_spot (THIS->here_input ());
1764                 $$ = m;
1765         }
1766         | close_event {
1767                 $$ = $1;
1768                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1769                         scm_int2num (START));
1770         }
1771         | open_event {
1772                 $$ = $1;
1773                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1774                         scm_int2num (STOP));
1775         }
1776         | EVENT_IDENTIFIER      {
1777                 $$ = unsmob_music ($1);
1778         }
1779         | tremolo_type  {
1780                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1781                a->set_spot (THIS->here_input ());
1782                a->set_property ("tremolo-type", scm_int2num ($1));
1783                $$ = a;
1784         }
1785         ;
1786
1787 direction_reqd_event:
1788         gen_text_def {
1789                 $$ = $1;
1790         }
1791         | script_abbreviation {
1792                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1793                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1794                 if (ly_c_string_p (s))
1795                         a->set_property ("articulation-type", s);
1796                 else THIS->parser_error (_ ("Expecting string as script definition"));
1797                 $$ = a;
1798         }
1799         ;
1800
1801 octave_check:
1802         /**/ { $$ = SCM_EOL; }
1803         | '='  { $$ = scm_int2num (0); }
1804         | '=' sub_quotes { $$ = scm_int2num ($2); }
1805         | '=' sup_quotes { $$ = scm_int2num ($2); }
1806         ;
1807
1808 sup_quotes:
1809         '\'' {
1810                 $$ = 1;
1811         }
1812         | sup_quotes '\'' {
1813                 $$ ++;
1814         }
1815         ;
1816
1817 sub_quotes:
1818         ',' {
1819                 $$ = 1;
1820         }
1821         | sub_quotes ',' {
1822                 $$++;
1823         }
1824         ;
1825
1826 steno_pitch:
1827         NOTENAME_PITCH  {
1828                 $$ = $1;
1829         }
1830         | NOTENAME_PITCH sup_quotes     {
1831                 Pitch p = *unsmob_pitch ($1);
1832                 p = p.transposed (Pitch ($2,0,0));
1833                 $$ = p.smobbed_copy ();
1834         }
1835         | NOTENAME_PITCH sub_quotes      {
1836                 Pitch p =* unsmob_pitch ($1);
1837                 p = p.transposed (Pitch (-$2,0,0));
1838                 $$ = p.smobbed_copy ();
1839         }
1840         ;
1841
1842 /*
1843 ugh. duplication
1844 */
1845
1846 steno_tonic_pitch:
1847         TONICNAME_PITCH {
1848                 $$ = $1;
1849         }
1850         | TONICNAME_PITCH sup_quotes    {
1851                 Pitch p = *unsmob_pitch ($1);
1852                 p = p.transposed (Pitch ($2,0,0));
1853                 $$ = p.smobbed_copy ();
1854         }
1855         | TONICNAME_PITCH sub_quotes     {
1856                 Pitch p =* unsmob_pitch ($1);
1857
1858                 p = p.transposed (Pitch (-$2,0,0));
1859                 $$ = p.smobbed_copy ();
1860         }
1861         ;
1862
1863 pitch:
1864         steno_pitch {
1865                 $$ = $1;
1866         }
1867         ;
1868
1869 pitch_also_in_chords:
1870         pitch
1871         | steno_tonic_pitch
1872         ;
1873
1874 close_event:
1875         '('     {
1876                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1877                 $$ = s;
1878                 s->set_spot (THIS->here_input ());
1879         }
1880         | E_OPEN        {
1881                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1882                 $$ = s;
1883                 s->set_spot (THIS->here_input ());
1884         }
1885         | E_SMALLER {
1886                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1887                 $$ = s;
1888                 s->set_spot (THIS->here_input ());
1889         }
1890         | E_BIGGER {
1891                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1892                 $$ = s;
1893                 s->set_spot (THIS->here_input ());
1894         }
1895         ;
1896
1897
1898 open_event:
1899         E_EXCLAMATION   {
1900                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1901                 s->set_spot (THIS->here_input ());
1902
1903                 $$ = s;
1904         }
1905         | ')'   {
1906                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1907                 $$ = s;
1908                 s->set_spot (THIS->here_input ());
1909
1910         }
1911         | E_CLOSE       {
1912                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1913                 $$ = s;
1914                 s->set_property ("span-type",
1915                         scm_makfrom0str ("phrasing-slur"));
1916                 s->set_spot (THIS->here_input ());
1917         }
1918         ;
1919
1920 gen_text_def:
1921         full_markup {
1922                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1923                 t->set_property ("text", $1);
1924                 t->set_spot (THIS->here_input ());
1925                 $$ = t;
1926         }
1927         | string {
1928                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1929                 t->set_property ("text",
1930                         make_simple_markup (THIS->lexer_->encoding (), $1));
1931                 t->set_spot (THIS->here_input ());
1932                 $$ = t;
1933
1934         }
1935         | DIGIT {
1936                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1937                 t->set_property ("digit", scm_int2num ($1));
1938                 t->set_spot (THIS->here_input ());
1939                 $$ = t;
1940         }
1941         ;
1942
1943 script_abbreviation:
1944         '^'             {
1945                 $$ = scm_makfrom0str ("Hat");
1946         }
1947         | '+'           {
1948                 $$ = scm_makfrom0str ("Plus");
1949         }
1950         | '-'           {
1951                 $$ = scm_makfrom0str ("Dash");
1952         }
1953         | '|'           {
1954                 $$ = scm_makfrom0str ("Bar");
1955         }
1956         | '>'           {
1957                 $$ = scm_makfrom0str ("Larger");
1958         }
1959         | '.'           {
1960                 $$ = scm_makfrom0str ("Dot");
1961         }
1962         | '_' {
1963                 $$ = scm_makfrom0str ("Underscore");
1964         }
1965         ;
1966
1967 script_dir:
1968         '_'     { $$ = DOWN; }
1969         | '^'   { $$ = UP; }
1970         | '-'   { $$ = CENTER; }
1971         ;
1972
1973
1974 absolute_pitch:
1975         steno_pitch     {
1976                 $$ = $1;
1977         }
1978         ;
1979
1980 duration_length:
1981         multiplied_duration {
1982                 $$ = $1;
1983         }
1984         ;
1985
1986 optional_notemode_duration:
1987         {
1988                 Duration dd = THIS->default_duration_;
1989                 $$ = dd.smobbed_copy ();
1990
1991                 THIS->beam_check ($$);
1992         }
1993         | multiplied_duration   {
1994                 $$ = $1;
1995                 THIS->default_duration_ = *unsmob_duration ($$);
1996
1997                 THIS->beam_check ($$);
1998         }
1999         ;
2000
2001 steno_duration:
2002         bare_unsigned dots              {
2003                 int len = 0;
2004                 if (!is_duration ($1))
2005                         THIS->parser_error (_f ("not a duration: %d", $1));
2006                 else
2007                         len = intlog2 ($1);
2008
2009                 $$ = Duration (len, $2).smobbed_copy ();
2010         }
2011         | DURATION_IDENTIFIER dots      {
2012                 Duration *d = unsmob_duration ($1);
2013                 Duration k (d->duration_log (), d->dot_count () + $2);
2014                 *d = k;
2015                 $$ = $1;
2016         }
2017         ;
2018
2019 multiplied_duration:
2020         steno_duration {
2021                 $$ = $1;
2022         }
2023         | multiplied_duration '*' bare_unsigned {
2024                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2025         }
2026         | multiplied_duration '*' FRACTION {
2027                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2028
2029                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2030         }
2031         ;
2032
2033 fraction:
2034         FRACTION { $$ = $1; }
2035         | UNSIGNED '/' UNSIGNED {
2036                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2037         }
2038         ;
2039
2040 dots:
2041         /* empty */     {
2042                 $$ = 0;
2043         }
2044         | dots '.' {
2045                 $$ ++;
2046         }
2047         ;
2048
2049 tremolo_type:
2050         ':'     {
2051                 $$ = 0;
2052         }
2053         | ':' bare_unsigned {
2054                 if (!is_duration ($2))
2055                         THIS->parser_error (_f ("not a duration: %d", $2));
2056                 $$ = $2;
2057         }
2058         ;
2059
2060 bass_number:
2061         DIGIT   {
2062                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2063                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2064                                 $$);
2065         }
2066         | UNSIGNED {
2067                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2068                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2069                                 $$);
2070         }
2071         | STRING { $$ = $1; }
2072         ;
2073
2074 bass_mod:
2075         '-'     { $$ = -2; }
2076         | '+'   { $$ = 2; }
2077         | '!'   { $$ = 0; }
2078         ;
2079
2080 bass_figure:
2081         FIGURE_SPACE {
2082                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2083                 $$ = bfr->self_scm ();
2084                 scm_gc_unprotect_object ($$);
2085         }
2086         | bass_number  {
2087                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2088                 $$ = bfr->self_scm ();
2089
2090                 bfr->set_property ("figure", $1);
2091
2092                 scm_gc_unprotect_object ($$);
2093         }
2094         | bass_figure bass_mod {
2095                 Music *m = unsmob_music ($1);
2096                 if ($2) {
2097                         SCM salter = m->get_property ("alteration");
2098                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2099                         m->set_property ("alteration",
2100                                 scm_int2num (alter + $2));
2101                 } else {
2102                         m->set_property ("alteration", scm_int2num (0));
2103                 }
2104         }
2105         ;
2106
2107 br_bass_figure:
2108         '[' bass_figure {
2109                 $$ = $2;
2110                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2111         }
2112         | bass_figure   {
2113                 $$ = $1;
2114         }
2115         | br_bass_figure ']' {
2116                 $$ = $1;
2117                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2118         }
2119         ;
2120
2121 figure_list:
2122         /**/            {
2123                 $$ = SCM_EOL;
2124         }
2125         | figure_list br_bass_figure {
2126                 $$ = scm_cons ($2, $1);
2127         }
2128         ;
2129
2130 figure_spec:
2131         FIGURE_OPEN figure_list FIGURE_CLOSE {
2132                 Music *m = MY_MAKE_MUSIC ("EventChord");
2133                 $2 = scm_reverse_x ($2, SCM_EOL);
2134                 m->set_property ("elements", $2);
2135                 $$ = m->self_scm ();
2136         }
2137         ;
2138
2139
2140 optional_rest:
2141         /**/   { $$ = 0; }
2142         | REST { $$ = 1; }
2143         ;
2144
2145 simple_element:
2146         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2147
2148                 Input i = THIS->pop_spot ();
2149                 if (!THIS->lexer_->is_note_state ())
2150                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2151
2152                 Music *n = 0;
2153                 if ($6)
2154                         n = MY_MAKE_MUSIC ("RestEvent");
2155                 else
2156                         n = MY_MAKE_MUSIC ("NoteEvent");
2157
2158                 n->set_property ("pitch", $1);
2159                 n->set_property ("duration", $5);
2160
2161                 if (ly_c_number_p ($4))
2162                 {
2163                         int q = ly_scm2int ($4);
2164                         n->set_property ("absolute-octave", scm_int2num (q-1));
2165                 }
2166
2167                 if ($3 % 2)
2168                         n->set_property ("cautionary", SCM_BOOL_T);
2169                 if ($2 % 2 || $3 % 2)
2170                         n->set_property ("force-accidental", SCM_BOOL_T);
2171
2172                 Music *v = MY_MAKE_MUSIC ("EventChord");
2173                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2174                 scm_gc_unprotect_object (n->self_scm ());
2175
2176                 v->set_spot (i);
2177                 n->set_spot (i);
2178                 $$ = v;
2179         }
2180         | DRUM_PITCH optional_notemode_duration {
2181                 Input i = THIS->pop_spot ();
2182
2183                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2184                 n->set_property ("duration", $2);
2185                 n->set_property ("drum-type", $1);
2186
2187                 Music *v = MY_MAKE_MUSIC ("EventChord");
2188                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2189                 scm_gc_unprotect_object (n->self_scm ());
2190                 v->set_spot (i);
2191                 n->set_spot (i);
2192                 $$ = v;
2193
2194         }
2195         | figure_spec optional_notemode_duration {
2196                 Music *m = unsmob_music ($1);
2197                 Input i = THIS->pop_spot ();
2198                 m->set_spot (i);
2199                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2200                 {
2201                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2202                 }
2203                 $$ = m;
2204         }
2205         | RESTNAME optional_notemode_duration           {
2206
2207                 Input i = THIS->pop_spot ();
2208                 Music *ev = 0;
2209                 if (ly_scm2string ($1) == "s") {
2210                         /* Space */
2211                         ev = MY_MAKE_MUSIC ("SkipEvent");
2212                   }
2213                 else {
2214                         ev = MY_MAKE_MUSIC ("RestEvent");
2215
2216                     }
2217                 ev->set_property ("duration", $2);
2218                 ev->set_spot (i);
2219                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2220                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2221                 velt->set_spot (i);
2222
2223                 scm_gc_unprotect_object (ev->self_scm ());
2224
2225                 $$ = velt;
2226         }
2227         | MULTI_MEASURE_REST optional_notemode_duration         {
2228                 THIS->pop_spot ();
2229
2230                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2231                 SCM mus = scm_call_2 (proc, $2,
2232                         make_input (THIS->here_input ()));
2233                 scm_gc_protect_object (mus);
2234                 $$ = unsmob_music (mus);
2235         }
2236
2237         | lyric_element optional_notemode_duration      {
2238                 Input i = THIS->pop_spot ();
2239                 if (!THIS->lexer_->is_lyric_state ())
2240                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2241
2242                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2243                 lreq->set_property ("text", $1);
2244                 lreq->set_property ("duration",$2);
2245                 lreq->set_spot (i);
2246                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2247                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2248
2249                 $$= velt;
2250         }
2251         | new_chord {
2252                 THIS->pop_spot ();
2253
2254                 if (!THIS->lexer_->is_chord_state ())
2255                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2256                 $$ = unsmob_music ($1);
2257         }
2258         ;
2259
2260 lyric_element:
2261         /* FIXME: lyric flavoured markup would be better */
2262         full_markup {
2263         }
2264         | LYRICS_STRING {
2265         }
2266         ;
2267
2268 new_chord:
2269         steno_tonic_pitch optional_notemode_duration   {
2270                 $$ = make_chord ($1, $2, SCM_EOL);
2271         }
2272         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2273                 SCM its = scm_reverse_x ($4, SCM_EOL);
2274                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2275         }
2276         ;
2277
2278 chord_items:
2279         /**/ {
2280                 $$ = SCM_EOL;
2281         }
2282         | chord_items chord_item {
2283                 $$ = scm_cons ($2, $$);
2284         }
2285         ;
2286
2287 chord_separator:
2288         CHORD_COLON {
2289                 $$ = ly_symbol2scm ("chord-colon");
2290         }
2291         | CHORD_CARET {
2292                 $$ = ly_symbol2scm ("chord-caret");
2293         }
2294         | CHORD_SLASH steno_tonic_pitch {
2295                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2296         }
2297         | CHORD_BASS steno_tonic_pitch {
2298                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2299         }
2300         ;
2301
2302 chord_item:
2303         chord_separator {
2304                 $$ = $1;
2305         }
2306         | step_numbers {
2307                 $$ = scm_reverse_x ($1, SCM_EOL);
2308         }
2309         | CHORD_MODIFIER  {
2310                 $$ = $1;
2311         }
2312         ;
2313
2314 step_numbers:
2315         step_number { $$ = scm_cons ($1, SCM_EOL); }
2316         | step_numbers '.' step_number {
2317                 $$ = scm_cons ($3, $$);
2318         }
2319         ;
2320
2321 step_number:
2322         bare_unsigned {
2323                 $$ = make_chord_step ($1, 0);
2324         }
2325         | bare_unsigned '+' {
2326                 $$ = make_chord_step ($1, SHARP);
2327         }
2328         | bare_unsigned CHORD_MINUS {
2329                 $$ = make_chord_step ($1, FLAT);
2330         }
2331         ;
2332
2333 /*
2334         UTILITIES
2335
2336 TODO: should deprecate in favor of Scheme?
2337
2338  */
2339 number_expression:
2340         number_expression '+' number_term {
2341                 $$ = scm_sum ($1, $3);
2342         }
2343         | number_expression '-' number_term {
2344                 $$ = scm_difference ($1, $3);
2345         }
2346         | number_term
2347         ;
2348
2349 number_term:
2350         number_factor {
2351                 $$ = $1;
2352         }
2353         | number_factor '*' number_factor {
2354                 $$ = scm_product ($1, $3);
2355         }
2356         | number_factor '/' number_factor {
2357                 $$ = scm_divide ($1, $3);
2358         }
2359         ;
2360
2361 number_factor:
2362         '-'  number_factor { /* %prec UNARY_MINUS */
2363                 $$ = scm_difference ($2, SCM_UNDEFINED);
2364         }
2365         | bare_number
2366         ;
2367
2368
2369 bare_number:
2370         UNSIGNED        {
2371                 $$ = scm_int2num ($1);
2372         }
2373         | REAL          {
2374                 $$ = $1;
2375         }
2376         | NUMBER_IDENTIFIER             {
2377                 $$ = $1;
2378         }
2379         | REAL NUMBER_IDENTIFIER        {
2380                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2381         }
2382         | UNSIGNED NUMBER_IDENTIFIER    {
2383                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2384         }
2385         ;
2386
2387
2388 bare_unsigned:
2389         UNSIGNED {
2390                         $$ = $1;
2391         }
2392         | DIGIT {
2393                 $$ = $1;
2394         }
2395         ;
2396
2397 bare_int:
2398         bare_number {
2399                 if (scm_integer_p ($1) == SCM_BOOL_T)
2400                 {
2401                         int k = ly_scm2int ($1);
2402                         $$ = k;
2403                 } else
2404                 {
2405                         THIS->parser_error (_ ("need integer number arg"));
2406                         $$ = 0;
2407                 }
2408         }
2409         | '-' bare_int {
2410                 $$ = -$2;
2411         }
2412         ;
2413
2414 exclamations:
2415                 { $$ = 0; }
2416         | exclamations '!'      { $$ ++; }
2417         ;
2418
2419 questions:
2420                 { $$ = 0; }
2421         | questions '?' { $$ ++; }
2422         ;
2423
2424
2425
2426 full_markup:
2427         MARKUP_IDENTIFIER {
2428                 $$ = $1;
2429         }
2430         | MARKUP
2431                 { THIS->lexer_->push_markup_state (); }
2432         markup
2433                 { $$ = $3;
2434                   THIS->lexer_->pop_state ();
2435                 }
2436         ;
2437
2438
2439 /*
2440 This should be done more dynamically if possible.
2441 */
2442 markup:
2443         STRING {
2444                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2445         }
2446         | MARKUP_HEAD_EMPTY {
2447                 $$ = scm_list_1 ($1);
2448         }
2449         | MARKUP_HEAD_MARKUP0 markup {
2450                 $$ = scm_list_2 ($1, $2);
2451         }
2452         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2453                 $$ = scm_list_3 ($1, $2, $3);
2454         }
2455         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2456                 $$ = scm_list_3 ($1, $2, $3);
2457         }
2458         | markup_line {
2459                 $$ = $1;
2460         }
2461         | MARKUP_HEAD_LIST0 markup_list {
2462                 $$ = scm_list_2 ($1,$2);
2463         }
2464         | MARKUP_HEAD_SCM0 embedded_scm {
2465                 $$ = scm_list_2 ($1, $2);
2466         }
2467         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2468                 $$ = scm_list_4 ($1, $2, $3, $4);
2469         }
2470         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2471                 $$ = scm_list_4 ($1, $2, $3, $4);
2472         }
2473         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2474                 $$ = scm_list_3 ($1, $2, $3);
2475         }
2476         | MARKUP_IDENTIFIER {
2477                 $$ = $1;
2478         }
2479         | STRING_IDENTIFIER {
2480                 $$ = $1;
2481         }
2482         | SCORE {
2483                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2484                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2485         } '{' score_body '}' {
2486                 Score * sc = $4;
2487                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2488                 scm_gc_unprotect_object (sc->self_scm ());
2489                 THIS->lexer_->pop_state ();
2490         }
2491         ;
2492
2493 markup_list:
2494         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2495         ;
2496
2497 markup_line:
2498         '{' markup_list_body '}' {
2499                 SCM line = ly_scheme_function ("line-markup");
2500
2501                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2502         }
2503         ;
2504
2505 markup_list_body:
2506         /**/ {  $$ = SCM_EOL; }
2507         | markup_list_body markup {
2508                 $$ = scm_cons ($2, $1);
2509         }
2510         ;
2511
2512
2513 %%
2514
2515 void
2516 My_lily_parser::set_yydebug (bool )
2517 {
2518 #if 0
2519         yydebug = 1;
2520 #endif
2521 }
2522
2523 void
2524 My_lily_parser::do_yyparse ()
2525 {
2526         yyparse ((void*)this);
2527 }
2528
2529
2530 /*
2531 Should make this optional?    It will also complain when you do
2532
2533         [s4]
2534
2535 which is entirely legitimate.
2536
2537 Or we can scrap it. Barchecks should detect wrong durations, and
2538 skipTypesetting speeds it up a lot.
2539 */
2540
2541 void
2542 My_lily_parser::beam_check (SCM dur)
2543 {
2544   Duration *d = unsmob_duration (dur);
2545   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2546     {
2547       Music *m = unsmob_music (last_beam_start_);
2548       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2549     }
2550   last_beam_start_ = SCM_EOL;
2551 }
2552
2553
2554
2555
2556 /*
2557
2558 It is a little strange to have this function in this file, but
2559 otherwise, we have to import music classes into the lexer.
2560
2561 */
2562 int
2563 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2564 {
2565         if (ly_c_string_p (sid)) {
2566                 *destination = sid;
2567                 return STRING_IDENTIFIER;
2568         } else if (ly_c_number_p (sid)) {
2569                 *destination = sid;
2570                 return NUMBER_IDENTIFIER;
2571         } else if (unsmob_context_def (sid)) {
2572                 *destination = unsmob_context_def (sid)->clone_scm ();
2573                 return CONTEXT_DEF_IDENTIFIER;
2574         } else if (unsmob_score (sid)) {
2575                 Score *score = new Score (*unsmob_score (sid));
2576                 *destination = score->self_scm ();
2577                 return SCORE_IDENTIFIER;
2578         } else if (Music *mus = unsmob_music (sid)) {
2579                 mus = mus->clone ();
2580                 *destination = mus->self_scm ();
2581                 unsmob_music (*destination)->
2582                         set_property ("origin", make_input (last_input_));
2583                 return dynamic_cast<Event*> (mus)
2584                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2585         } else if (unsmob_duration (sid)) {
2586                 *destination = unsmob_duration (sid)->smobbed_copy ();
2587                 return DURATION_IDENTIFIER;
2588         } else if (unsmob_output_def (sid)) {
2589                 Output_def *p = unsmob_output_def (sid);
2590                 p = p->clone ();
2591
2592                 *destination = p->self_scm ();
2593                 return OUTPUT_DEF_IDENTIFIER;
2594         } else if (Text_item::markup_p (sid)) {
2595                 *destination = sid;
2596                 return MARKUP_IDENTIFIER;
2597         }
2598
2599         return -1;
2600 }
2601
2602 Music *
2603 property_op_to_music (SCM op)
2604 {
2605         Music *m = 0;
2606         SCM tag = ly_car (op);
2607         SCM symbol = ly_cadr (op);
2608         SCM args = ly_cddr (op);
2609         SCM grob_val = SCM_UNDEFINED;
2610         SCM grob_sym = SCM_UNDEFINED;
2611         SCM val = SCM_UNDEFINED;
2612
2613         if (tag == ly_symbol2scm ("assign"))
2614                 {
2615                 m = MY_MAKE_MUSIC ("PropertySet");
2616                 val = ly_car (args);
2617                 }
2618         else if (tag == ly_symbol2scm ("unset"))
2619                 m = MY_MAKE_MUSIC ("PropertyUnset");
2620         else if (tag == ly_symbol2scm ("poppush")
2621                  || tag == ly_symbol2scm ("push"))
2622                 {
2623                 m = MY_MAKE_MUSIC ("OverrideProperty");
2624                 grob_sym = ly_car (args);
2625                 grob_val = ly_cadr (args);
2626                 }
2627         else if (tag == ly_symbol2scm ("pop")) {
2628                 m = MY_MAKE_MUSIC ("RevertProperty");
2629                 grob_sym = ly_car (args);
2630                 }
2631
2632         m->set_property ("symbol", symbol);
2633
2634         if (val != SCM_UNDEFINED)
2635                 m->set_property ("value", val);
2636         if (grob_val != SCM_UNDEFINED)
2637                 m->set_property ("grob-value", grob_val);
2638
2639         if (grob_sym != SCM_UNDEFINED)
2640                 {
2641                 bool itc = internal_type_checking_global_b;
2642                 /* UGH.
2643                 */
2644                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2645                 if (autobeam)
2646                         internal_type_checking_global_b = false;
2647                 m->set_property ("grob-property", grob_sym);
2648                 if (autobeam)
2649                         internal_type_checking_global_b = itc;
2650                 }
2651
2652         if (tag == ly_symbol2scm ("poppush"))
2653                 m->set_property ("pop-first", SCM_BOOL_T);
2654
2655
2656         return m;
2657 }
2658
2659 Music*
2660 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2661 {
2662         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2663
2664         csm->set_property ("element", m->self_scm ());
2665         scm_gc_unprotect_object (m->self_scm ());
2666
2667         csm->set_property ("context-type",
2668                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2669         csm->set_property ("property-operations", ops);
2670
2671         if (ly_c_string_p (id))
2672                 csm->set_property ("context-id", id);
2673         return csm;
2674 }
2675
2676 SCM
2677 get_next_unique_context ()
2678 {
2679         static int new_context_count;
2680         char s[1024];
2681         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2682         return scm_makfrom0str (s);
2683 }
2684