lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 char *p = scm_to_locale_string                          \
  45                         (scm_simple_format (SCM_BOOL_F,                 \
  46                                             scm_from_locale_string ("~S"), \
  47                                             scm_list_1 (value)));       \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT REPEAT_IDENTIFIER
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83 %right ':' UNSIGNED REAL E_UNSIGNED EVENT_IDENTIFIER EVENT_FUNCTION '^' '_'
  84        HYPHEN EXTENDER DURATION_IDENTIFIER
  85
  86  /* The above are needed for collecting tremoli and other items (that
  87     could otherwise be interpreted as belonging to the next function
  88     argument) greedily, and together with the next rule will serve to
  89     join numbers and units greedily instead of allowing them into
  90     separate function arguments
  91  */
  92
  93 %nonassoc NUMBER_IDENTIFIER
  94
  95 %left PREC_TOP
  96
  97
  98
  99
 100 %pure-parser
 101 %locations
 102
 103
 104
 105 %{ // -*-Fundamental-*-
 106
 107 /*
 108 FIXME:
 109
 110    * The rules for who is protecting what are very shady.  Uniformise
 111      this.
 112
 113    * There are too many lexical modes?
 114 */
 115
 116 #include "config.hh"
 117
 118 #include <cctype>
 119 #include <cstdlib>
 120 #include <cstdio>
 121 using namespace std;
 122
 123 #include "book.hh"
 124 #include "context-def.hh"
 125 #include "context-mod.hh"
 126 #include "dimensions.hh"
 127 #include "file-path.hh"
 128 #include "input.hh"
 129 #include "international.hh"
 130 #include "lily-guile.hh"
 131 #include "lily-lexer.hh"
 132 #include "lily-parser.hh"
 133 #include "main.hh"
 134 #include "misc.hh"
 135 #include "music.hh"
 136 #include "output-def.hh"
 137 #include "paper-book.hh"
 138 #include "scm-hash.hh"
 139 #include "score.hh"
 140 #include "text-interface.hh"
 141 #include "warn.hh"
 142
 143 void
 144 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, const string &s)
 145 {
 146         parser->parser_error (*i, s);
 147 }
 148
 149 #define MYBACKUP(Token, Value, Location)                                \
 150 do                                                                      \
 151         if (yychar == YYEMPTY)                                          \
 152         {                                                               \
 153                 if (Token)                                              \
 154                         parser->lexer_->push_extra_token (Token, Value); \
 155                 parser->lexer_->push_extra_token (BACKUP);              \
 156         } else {                                                        \
 157                 parser->parser_error                                    \
 158                         (Location, _("Too much lookahead"));            \
 159         }                                                               \
 160 while (0)
 161
 162
 163 #define MYREPARSE(Location, Pred, Token, Value)                         \
 164 do                                                                      \
 165         if (yychar == YYEMPTY)                                          \
 166         {                                                               \
 167                 parser->lexer_->push_extra_token (Token, Value);        \
 168                 parser->lexer_->push_extra_token (REPARSE,              \
 169                                                   Pred);                \
 170         } else {                                                        \
 171                 parser->parser_error                                    \
 172                         (Location, _("Too much lookahead"));            \
 173         }                                                               \
 174 while (0)
 175
 176 %}
 177
 178
 179 %{
 180
 181 #define MY_MAKE_MUSIC(x, spot) \
 182         make_music_with_input (ly_symbol2scm (x), \
 183                                parser->lexer_->override_input (spot))
 184
 185 /* ES TODO:
 186 - Don't use lily module, create a new module instead.
 187 - delay application of the function
 188 */
 189 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 190   scm_apply_0 (proc, args)
 191 /* Syntactic Sugar. */
 192 #define MAKE_SYNTAX(name, location, ...)                                \
 193         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), make_input (parser->lexer_->override_input (location)), ##__VA_ARGS__, SCM_UNDEFINED))
 194 #define START_MAKE_SYNTAX(name, ...)                                    \
 195         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 196 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 197         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), make_input (parser->lexer_->override_input (location)), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 198
 199 SCM get_next_unique_context_id ();
 200 SCM get_next_unique_lyrics_context_id ();
 201
 202 #undef _
 203 #if !HAVE_GETTEXT
 204 #define _(x) x
 205 #else
 206 #include <libintl.h>
 207 #define _(x) gettext (x)
 208 #endif
 209
 210
 211 static Music *make_music_with_input (SCM name, Input where);
 212 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 213                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 214 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 215 SCM loc_on_music (Input loc, SCM arg);
 216 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 217 SCM make_chord_step (SCM step, Rational alter);
 218 SCM make_simple_markup (SCM a);
 219 SCM make_duration (SCM t, int dots = 0);
 220 bool is_regular_identifier (SCM id, bool multiple=false);
 221 SCM try_string_variants (SCM pred, SCM str);
 222 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 223
 224 %}
 225
 226 /* The third option is an alias that will be used to display the
 227    syntax error.  Bison CVS now correctly handles backslash escapes.
 228
 229    FIXME: Bison needs to translate some of these, eg, STRING.
 230
 231 */
 232
 233 /* Keyword tokens with plain escaped name.  */
 234 %token END_OF_FILE 0 "end of input"
 235 %token ACCEPTS "\\accepts"
 236 %token ADDLYRICS "\\addlyrics"
 237 %token ALIAS "\\alias"
 238 %token ALTERNATIVE "\\alternative"
 239 %token BOOK "\\book"
 240 %token BOOKPART "\\bookpart"
 241 %token CHANGE "\\change"
 242 %token CHORDMODE "\\chordmode"
 243 %token CHORDS "\\chords"
 244 %token CONSISTS "\\consists"
 245 %token CONTEXT "\\context"
 246 %token DEFAULT "\\default"
 247 %token DEFAULTCHILD "\\defaultchild"
 248 %token DENIES "\\denies"
 249 %token DESCRIPTION "\\description"
 250 %token DRUMMODE "\\drummode"
 251 %token DRUMS "\\drums"
 252 %token FIGUREMODE "\\figuremode"
 253 %token FIGURES "\\figures"
 254 %token HEADER "\\header"
 255 %token INVALID "\\version-error"
 256 %token LAYOUT "\\layout"
 257 %token LYRICMODE "\\lyricmode"
 258 %token LYRICS "\\lyrics"
 259 %token LYRICSTO "\\lyricsto"
 260 %token MARKUP "\\markup"
 261 %token MARKUPLIST "\\markuplist"
 262 %token MIDI "\\midi"
 263 %token NAME "\\name"
 264 %token NOTEMODE "\\notemode"
 265 %token OVERRIDE "\\override"
 266 %token PAPER "\\paper"
 267 %token REMOVE "\\remove"
 268 %token REPEAT "\\repeat"
 269 %token REST "\\rest"
 270 %token REVERT "\\revert"
 271 %token SCORE "\\score"
 272 %token SCORELINES "\\score-lines"
 273 %token SEQUENTIAL "\\sequential"
 274 %token SET "\\set"
 275 %token SIMULTANEOUS "\\simultaneous"
 276 %token TEMPO "\\tempo"
 277 %token TYPE "\\type"
 278 %token UNSET "\\unset"
 279 %token WITH "\\with"
 280
 281 /* Keyword token exceptions.  */
 282 %token NEWCONTEXT "\\new"
 283
 284
 285 /* Other string tokens.  */
 286
 287 %token CHORD_BASS "/+"
 288 %token CHORD_CARET "^"
 289 %token CHORD_COLON ":"
 290 %token CHORD_MINUS "-"
 291 %token CHORD_SLASH "/"
 292 %token ANGLE_OPEN "<"
 293 %token ANGLE_CLOSE ">"
 294 %token DOUBLE_ANGLE_OPEN "<<"
 295 %token DOUBLE_ANGLE_CLOSE ">>"
 296 %token E_BACKSLASH "\\"
 297 %token E_EXCLAMATION "\\!"
 298 %token E_PLUS "\\+"
 299 %token EXTENDER "__"
 300
 301 /*
 302 If we give names, Bison complains.
 303 */
 304 %token FIGURE_CLOSE /* "\\>" */
 305 %token FIGURE_OPEN /* "\\<" */
 306 %token FIGURE_SPACE "_"
 307 %token HYPHEN "--"
 308
 309 %token MULTI_MEASURE_REST
 310
 311
 312 %token E_UNSIGNED
 313 %token UNSIGNED
 314
 315 /* Artificial tokens, for more generic function syntax */
 316 %token EXPECT_MARKUP "markup?"
 317 %token EXPECT_SCM "scheme?"
 318 %token BACKUP "(backed-up?)"
 319 %token REPARSE "(reparsed?)"
 320 %token EXPECT_MARKUP_LIST "markup-list?"
 321 %token EXPECT_OPTIONAL "optional?"
 322 /* After the last argument. */
 323 %token EXPECT_NO_MORE_ARGS;
 324
 325 /* An artificial token for parsing embedded Lilypond */
 326 %token EMBEDDED_LILY "#{"
 327
 328 %token BOOK_IDENTIFIER
 329 %token CHORD_BODY_IDENTIFIER
 330 %token CHORD_MODIFIER
 331 %token CHORD_REPETITION
 332 %token CONTEXT_DEF_IDENTIFIER
 333 %token CONTEXT_MOD_IDENTIFIER
 334 %token DRUM_PITCH
 335 %token PITCH_IDENTIFIER
 336 %token DURATION_IDENTIFIER
 337 %token EVENT_IDENTIFIER
 338 %token EVENT_FUNCTION
 339 %token FRACTION
 340 %token LYRIC_ELEMENT
 341 %token MARKUP_FUNCTION
 342 %token MARKUP_LIST_FUNCTION
 343 %token MARKUP_IDENTIFIER
 344 %token MARKUPLIST_IDENTIFIER
 345 %token MUSIC_FUNCTION
 346 %token MUSIC_IDENTIFIER
 347 %token NOTENAME_PITCH
 348 %token NUMBER_IDENTIFIER
 349 %token OUTPUT_DEF_IDENTIFIER
 350 %token REAL
 351 %token REPEAT_IDENTIFIER
 352 %token RESTNAME
 353 %token SCM_ARG
 354 %token SCM_FUNCTION
 355 %token SCM_IDENTIFIER
 356 %token SCM_TOKEN
 357 %token STRING
 358 %token SYMBOL_LIST
 359 %token TONICNAME_PITCH
 360
 361 %left '-' '+'
 362
 363 /* We don't assign precedence to / and *, because we might need varied
 364 prec levels in different prods */
 365
 366 %left UNARY_MINUS
 367
 368 %%
 369
 370 start_symbol:
 371         lilypond
 372         | EMBEDDED_LILY {
 373                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 374                 parser->lexer_->push_note_state (nn);
 375         } embedded_lilypond {
 376                 parser->lexer_->pop_state ();
 377                 *retval = $3;
 378         }
 379         ;
 380
 381 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 382         | lilypond toplevel_expression {
 383         }
 384         | lilypond assignment {
 385         }
 386         | lilypond error {
 387                 parser->error_level_ = 1;
 388         }
 389         | lilypond INVALID      {
 390                 parser->error_level_ = 1;
 391         }
 392         ;
 393
 394
 395 toplevel_expression:
 396         {
 397                 parser->lexer_->add_scope (get_header (parser));
 398         } lilypond_header {
 399                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 400         }
 401         | book_block {
 402                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 403                 scm_call_2 (proc, parser->self_scm (), $1);
 404         }
 405         | bookpart_block {
 406                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 407                 scm_call_2 (proc, parser->self_scm (), $1);
 408         }
 409         | score_block {
 410                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 411                 scm_call_2 (proc, parser->self_scm (), $1);
 412         }
 413         | composite_music {
 414                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 415                 scm_call_2 (proc, parser->self_scm (), $1);
 416         }
 417         | full_markup {
 418                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 419                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 420         }
 421         | full_markup_list {
 422                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 423                 scm_call_2 (proc, parser->self_scm (), $1);
 424         }
 425         | SCM_TOKEN {
 426                 // Evaluate and ignore #xxx, as opposed to \xxx
 427                 parser->lexer_->eval_scm_token ($1);
 428         }
 429         | embedded_scm_active
 430         {
 431                 SCM out = SCM_UNDEFINED;
 432                 if (Text_interface::is_markup ($1))
 433                         out = scm_list_1 ($1);
 434                 else if (Text_interface::is_markup_list ($1))
 435                         out = $1;
 436                 if (scm_is_pair (out))
 437                 {
 438                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 439                         scm_call_2 (proc, parser->self_scm (), out);
 440                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 441                         parser->parser_error (@1, _("bad expression type"));
 442         }
 443         | output_def {
 444                 SCM id = SCM_EOL;
 445                 Output_def * od = unsmob_output_def ($1);
 446
 447                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 448                         id = ly_symbol2scm ("$defaultpaper");
 449                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 450                         id = ly_symbol2scm ("$defaultmidi");
 451                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 452                         id = ly_symbol2scm ("$defaultlayout");
 453
 454                 parser->lexer_->set_identifier (id, $1);
 455         }
 456         ;
 457
 458 embedded_scm_bare:
 459         SCM_TOKEN
 460         {
 461                 $$ = parser->lexer_->eval_scm_token ($1);
 462         }
 463         | SCM_IDENTIFIER
 464         ;
 465
 466 embedded_scm_active:
 467         SCM_IDENTIFIER
 468         | scm_function_call
 469         ;
 470
 471 embedded_scm_bare_arg:
 472         SCM_ARG
 473         | SCM_TOKEN
 474         {
 475                 $$ = parser->lexer_->eval_scm_token ($1);
 476         }
 477         | full_markup_list
 478         | context_modification
 479         | score_block
 480         | context_def_spec_block
 481         | book_block
 482         | bookpart_block
 483         | output_def
 484         ;
 485
 486 /* The generic version may end in music, or not */
 487
 488 embedded_scm:
 489         embedded_scm_bare
 490         | scm_function_call
 491         ;
 492
 493 /* embedded_scm_arg is _not_ casting pitches to music by default, this
 494  * has to be done by the function itself.  Note that this may cause
 495  * the results of scm_function_call or embedded_scm_bare_arg to be
 496  * turned into music from pitches as well.  Note that this creates a
 497  * distinctly awkward situation for calculated drum pitches.  Those
 498  * are at the current point of time rejected as music constituents as
 499  * they can't be distinguished from "proper" symbols.
 500  */
 501
 502 embedded_scm_arg:
 503         embedded_scm_bare_arg
 504         | scm_function_call
 505         | music_assign
 506         ;
 507
 508 scm_function_call:
 509         SCM_FUNCTION function_arglist {
 510                 $$ = MAKE_SYNTAX ("music-function", @$,
 511                                          $1, $2);
 512         }
 513         ;
 514
 515 embedded_lilypond_number:
 516         '-' embedded_lilypond_number
 517         {
 518                 $$ = scm_difference ($2, SCM_UNDEFINED);
 519         }
 520         | bare_number_common
 521         | UNSIGNED NUMBER_IDENTIFIER
 522         {
 523                 $$ = scm_product ($1, $2);
 524         }
 525         ;
 526
 527 embedded_lilypond:
 528         /* empty */
 529         {
 530                 // FIXME: @$ does not contain a useful source location
 531                 // for empty rules, and the only token in the whole
 532                 // production, EMBEDDED_LILY, is synthetic and also
 533                 // contains no source location.
 534                 $$ = MAKE_SYNTAX ("void-music", @$);
 535         }
 536         | identifier_init_nonumber
 537         | embedded_lilypond_number
 538         | post_event post_events
 539         {
 540                 $$ = scm_reverse_x ($2, SCM_EOL);
 541                 if (Music *m = unsmob_music ($1))
 542                 {
 543                         if (m->is_mus_type ("post-event-wrapper"))
 544                                 $$ = scm_append
 545                                         (scm_list_2 (m->get_property ("elements"),
 546                                                      $$));
 547                         else
 548                                 $$ = scm_cons ($1, $$);
 549                 }
 550                 if (scm_is_pair ($$)
 551                     && scm_is_null (scm_cdr ($$)))
 552                         $$ = scm_car ($$);
 553                 else
 554                 {
 555                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 556                         m->set_property ("elements", $$);
 557                         $$ = m->unprotect ();
 558                 }
 559         }
 560         | multiplied_duration
 561         | music_embedded music_embedded music_list {
 562                 $3 = scm_reverse_x ($3, SCM_EOL);
 563                 if (unsmob_music ($2))
 564                         $3 = scm_cons ($2, $3);
 565                 if (unsmob_music ($1))
 566                         $3 = scm_cons ($1, $3);
 567                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 568         }
 569         | error {
 570                 parser->error_level_ = 1;
 571                 $$ = SCM_UNSPECIFIED;
 572         }
 573         | INVALID embedded_lilypond {
 574                 parser->error_level_ = 1;
 575                 $$ = $2;
 576         }
 577         ;
 578
 579
 580 lilypond_header_body:
 581         /* empty */ { $$ = SCM_UNSPECIFIED; }
 582         | lilypond_header_body assignment  {
 583
 584         }
 585         | lilypond_header_body embedded_scm  {
 586
 587         }
 588         ;
 589
 590 lilypond_header:
 591         HEADER '{' lilypond_header_body '}'     {
 592                 $$ = parser->lexer_->remove_scope ();
 593         }
 594         ;
 595
 596 /*
 597         DECLARATIONS
 598 */
 599 assignment_id:
 600         STRING          { $$ = $1; }
 601         ;
 602
 603 assignment:
 604         assignment_id '=' identifier_init  {
 605                 parser->lexer_->set_identifier ($1, $3);
 606                 $$ = SCM_UNSPECIFIED;
 607         }
 608         | assignment_id property_path '=' identifier_init {
 609                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 610                 parser->lexer_->set_identifier (path, $4);
 611                 $$ = SCM_UNSPECIFIED;
 612         }
 613         ;
 614
 615
 616 identifier_init:
 617         identifier_init_nonumber
 618         | number_expression
 619         | post_event_nofinger post_events
 620         {
 621                 $$ = scm_reverse_x ($2, SCM_EOL);
 622                 if (Music *m = unsmob_music ($1))
 623                 {
 624                         if (m->is_mus_type ("post-event-wrapper"))
 625                                 $$ = scm_append
 626                                         (scm_list_2 (m->get_property ("elements"),
 627                                                      $$));
 628                         else
 629                                 $$ = scm_cons ($1, $$);
 630                 }
 631                 if (scm_is_pair ($$)
 632                     && scm_is_null (scm_cdr ($$)))
 633                         $$ = scm_car ($$);
 634                 else
 635                 {
 636                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 637                         m->set_property ("elements", $$);
 638                         $$ = m->unprotect ();
 639                 }
 640         }
 641         ;
 642
 643 identifier_init_nonumber:
 644         score_block
 645         | book_block
 646         | bookpart_block
 647         | output_def
 648         | context_def_spec_block
 649         | music_assign
 650         | FRACTION
 651         | string
 652         | embedded_scm
 653         | full_markup_list
 654         | context_modification
 655         ;
 656
 657 context_def_spec_block:
 658         CONTEXT '{' context_def_spec_body '}'
 659                 {
 660                 $$ = $3;
 661                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 662         }
 663         ;
 664
 665 context_mod_arg:
 666         embedded_scm
 667         |
 668         {
 669                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 670                 parser->lexer_->push_note_state (nn);
 671         }
 672         composite_music
 673         {
 674                 parser->lexer_->pop_state ();
 675                 $$ = $2;
 676         }
 677         ;
 678
 679 context_mod_embedded:
 680         context_mod_arg
 681         {
 682                 if (unsmob_music ($1)) {
 683                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 684                         $1 = scm_call_2 (proc, parser->self_scm (), $1);
 685                 }
 686                 if (unsmob_context_mod ($1))
 687                         $$ = $1;
 688                 else {
 689                         parser->parser_error (@1, _ ("not a context mod"));
 690                         $$ = Context_mod ().smobbed_copy ();
 691                 }
 692         }
 693         ;
 694
 695
 696 context_def_spec_body:
 697         /**/ {
 698                 $$ = Context_def::make_scm ();
 699         }
 700         | CONTEXT_DEF_IDENTIFIER {
 701                 $$ = $1;
 702         }
 703         | context_def_spec_body context_mod {
 704                 if (!SCM_UNBNDP ($2))
 705                         unsmob_context_def ($$)->add_context_mod ($2);
 706         }
 707         | context_def_spec_body context_modification {
 708                 Context_def *td = unsmob_context_def ($$);
 709                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 710                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 711                     td->add_context_mod (scm_car (m));
 712                 }
 713         }
 714         | context_def_spec_body context_mod_embedded {
 715                 Context_def *td = unsmob_context_def ($$);
 716                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 717                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 718                     td->add_context_mod (scm_car (m));
 719                 }
 720         }
 721         ;
 722
 723
 724
 725 book_block:
 726         BOOK '{' book_body '}'  {
 727                 $$ = $3;
 728                 unsmob_book ($$)->origin ()->set_spot (@$);
 729                 pop_paper (parser);
 730                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 731         }
 732         ;
 733
 734 /* FIXME:
 735    * Use 'handlers' like for toplevel-* stuff?
 736    * grok \layout and \midi?  */
 737 book_body:
 738         {
 739                 Book *book = new Book;
 740                 init_papers (parser);
 741                 book->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 742                 book->paper_->unprotect ();
 743                 push_paper (parser, book->paper_);
 744                 book->header_ = get_header (parser);
 745                 $$ = book->unprotect ();
 746                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 747         }
 748         | BOOK_IDENTIFIER {
 749                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 750         }
 751         | book_body paper_block {
 752                 unsmob_book ($1)->paper_ = unsmob_output_def ($2);
 753                 set_paper (parser, unsmob_output_def ($2));
 754         }
 755         | book_body bookpart_block {
 756                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 757                 scm_call_2 (proc, $1, $2);
 758         }
 759         | book_body score_block {
 760                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 761                 scm_call_2 (proc, $1, $2);
 762         }
 763         | book_body composite_music {
 764                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 765                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 766         }
 767         | book_body full_markup {
 768                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 769                 scm_call_2 (proc, $1, scm_list_1 ($2));
 770         }
 771         | book_body full_markup_list {
 772                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 773                 scm_call_2 (proc, $1, $2);
 774         }
 775         | book_body SCM_TOKEN {
 776                 // Evaluate and ignore #xxx, as opposed to \xxx
 777                 parser->lexer_->eval_scm_token ($2);
 778         }
 779         | book_body embedded_scm_active
 780         {
 781                 SCM out = SCM_UNDEFINED;
 782                 if (Text_interface::is_markup ($2))
 783                         out = scm_list_1 ($2);
 784                 else if (Text_interface::is_markup_list ($2))
 785                         out = $2;
 786                 if (scm_is_pair (out))
 787                 {
 788                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 789                         scm_call_2 (proc, $1, out);
 790                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 791                         parser->parser_error (@2, _("bad expression type"));
 792         }
 793         | book_body
 794         {
 795                 parser->lexer_->add_scope (unsmob_book ($1)->header_);
 796         } lilypond_header
 797         | book_body error {
 798                 Book *book = unsmob_book ($1);
 799                 book->paper_ = 0;
 800                 book->scores_ = SCM_EOL;
 801                 book->bookparts_ = SCM_EOL;
 802         }
 803         ;
 804
 805 bookpart_block:
 806         BOOKPART '{' bookpart_body '}' {
 807                 $$ = $3;
 808                 unsmob_book ($$)->origin ()->set_spot (@$);
 809                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 810         }
 811         ;
 812
 813 bookpart_body:
 814         {
 815                 Book *book = new Book;
 816                 $$ = book->unprotect ();
 817                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 818         }
 819         | BOOK_IDENTIFIER {
 820                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 821         }
 822         | bookpart_body paper_block {
 823                 unsmob_book ($$)->paper_ = unsmob_output_def ($2);
 824         }
 825         | bookpart_body score_block {
 826                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 827                 scm_call_2 (proc, $1, $2);
 828         }
 829         | bookpart_body composite_music {
 830                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 831                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 832         }
 833         | bookpart_body full_markup {
 834                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 835                 scm_call_2 (proc, $1, scm_list_1 ($2));
 836         }
 837         | bookpart_body full_markup_list {
 838                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 839                 scm_call_2 (proc, $1, $2);
 840         }
 841         | bookpart_body SCM_TOKEN {
 842                 // Evaluate and ignore #xxx, as opposed to \xxx
 843                 parser->lexer_->eval_scm_token ($2);
 844         }
 845         | bookpart_body embedded_scm_active
 846         {
 847                 SCM out = SCM_UNDEFINED;
 848                 if (Text_interface::is_markup ($2))
 849                         out = scm_list_1 ($2);
 850                 else if (Text_interface::is_markup_list ($2))
 851                         out = $2;
 852                 if (scm_is_pair (out))
 853                 {
 854                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 855                         scm_call_2 (proc, $1, out);
 856                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 857                         parser->parser_error (@2, _("bad expression type"));
 858         }
 859         | bookpart_body
 860         {
 861                 Book *book = unsmob_book ($1);
 862                 if (!ly_is_module (book->header_))
 863                         book->header_ = ly_make_module (false);
 864                 parser->lexer_->add_scope (book->header_);
 865         } lilypond_header
 866         | bookpart_body error {
 867                 Book *book = unsmob_book ($1);
 868                 book->paper_ = 0;
 869                 book->scores_ = SCM_EOL;
 870         }
 871         ;
 872
 873 score_block:
 874         SCORE '{' score_body '}'        {
 875                 $$ = $3;
 876         }
 877         ;
 878
 879 score_body:
 880         music {
 881                 SCM scorify = ly_lily_module_constant ("scorify-music");
 882                 $$ = scm_call_2 (scorify, $1, parser->self_scm ());
 883
 884                 unsmob_score ($$)->origin ()->set_spot (@$);
 885         }
 886         | embedded_scm_active {
 887                 Score *score;
 888                 if (unsmob_score ($1))
 889                         score = new Score (*unsmob_score ($1));
 890                 else {
 891                         score = new Score;
 892                         parser->parser_error (@1, _("score expected"));
 893                 }
 894                 unsmob_score ($$)->origin ()->set_spot (@$);
 895                 $$ = score->unprotect ();
 896         }
 897         | score_body
 898         {
 899                 Score *score = unsmob_score ($1);
 900                 if (!ly_is_module (score->get_header ()))
 901                         score->set_header (ly_make_module (false));
 902                 parser->lexer_->add_scope (score->get_header ());
 903         } lilypond_header
 904         | score_body output_def {
 905                 Output_def *od = unsmob_output_def ($2);
 906                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 907                 {
 908                         parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 909
 910                 }
 911                 else
 912                 {
 913                         unsmob_score ($1)->add_output_def (od);
 914                 }
 915         }
 916         | score_body error {
 917                 unsmob_score ($$)->error_found_ = true;
 918         }
 919         ;
 920
 921
 922 /*
 923         OUTPUT DEF
 924 */
 925
 926 paper_block:
 927         output_def {
 928                 Output_def *od = unsmob_output_def ($1);
 929
 930                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 931                 {
 932                         parser->parser_error (@1, _ ("need \\paper for paper block"));
 933                         $$ = get_paper (parser)->unprotect ();
 934                 }
 935         }
 936         ;
 937
 938
 939 output_def:
 940         output_def_body '}' {
 941                 $$ = $1;
 942
 943                 parser->lexer_->remove_scope ();
 944                 parser->lexer_->pop_state ();
 945         }
 946         ;
 947
 948 output_def_head:
 949         PAPER {
 950                 Output_def *p = get_paper (parser);
 951                 p->input_origin_ = @$;
 952                 parser->lexer_->add_scope (p->scope_);
 953                 $$ = p->unprotect ();
 954         }
 955         | MIDI    {
 956                 Output_def *p = get_midi (parser);
 957                 $$ = p->unprotect ();
 958                 parser->lexer_->add_scope (p->scope_);
 959         }
 960         | LAYOUT        {
 961                 Output_def *p = get_layout (parser);
 962
 963                 parser->lexer_->add_scope (p->scope_);
 964                 $$ = p->unprotect ();
 965         }
 966         ;
 967
 968 output_def_head_with_mode_switch:
 969         output_def_head {
 970                 parser->lexer_->push_initial_state ();
 971                 $$ = $1;
 972         }
 973         ;
 974
 975 // We need this weird nonterminal because both music as well as a
 976 // context definition can start with \context and the difference is
 977 // only apparent after looking at the next token.  If it is '{', there
 978 // is still time to escape from notes mode.
 979
 980 music_or_context_def:
 981         music_arg
 982         | context_def_spec_block
 983         ;
 984
 985 output_def_body:
 986         output_def_head_with_mode_switch '{' {
 987                 $$ = $1;
 988                 unsmob_output_def ($$)->input_origin_.set_spot (@$);
 989         }
 990         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 991                 Output_def *o = unsmob_output_def ($3);
 992                 o->input_origin_.set_spot (@$);
 993                 $$ = o->self_scm ();
 994                 parser->lexer_->remove_scope ();
 995                 parser->lexer_->add_scope (o->scope_);
 996         }
 997         | output_def_body assignment  {
 998
 999         }
1000         | output_def_body embedded_scm  {
1001
1002         }
1003         | output_def_body
1004         {
1005                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1006                 parser->lexer_->push_note_state (nn);
1007         } music_or_context_def
1008         {
1009                 parser->lexer_->pop_state ();
1010                 if (unsmob_context_def ($3))
1011                         assign_context_def (unsmob_output_def ($1), $3);
1012                 else {
1013
1014                         SCM proc = parser->lexer_->lookup_identifier
1015                                      ("output-def-music-handler");
1016                         scm_call_3 (proc, parser->self_scm (),
1017                                     $1, $3);
1018                 }
1019         }
1020         | output_def_body error {
1021
1022         }
1023         ;
1024
1025 tempo_event:
1026         TEMPO steno_duration '=' tempo_range    {
1027                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1028         }
1029         | TEMPO scalar steno_duration '=' tempo_range   {
1030                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1031         }
1032         | TEMPO scalar {
1033                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1034         } %prec ':'
1035         ;
1036
1037 /*
1038 The representation of a  list is reversed to have efficient append.  */
1039
1040 music_list:
1041         /* empty */ {
1042                 $$ = SCM_EOL;
1043         }
1044         | music_list music_embedded {
1045                 if (unsmob_music ($2))
1046                         $$ = scm_cons ($2, $1);
1047         }
1048         | music_list error {
1049                 Music *m = MY_MAKE_MUSIC("Music", @$);
1050                 // ugh. code dup
1051                 m->set_property ("error-found", SCM_BOOL_T);
1052                 $$ = scm_cons (m->self_scm (), $1);
1053                 m->unprotect (); /* UGH */
1054         }
1055         ;
1056
1057 braced_music_list:
1058         '{' music_list '}'
1059         {
1060                 $$ = scm_reverse_x ($2, SCM_EOL);
1061         }
1062         ;
1063
1064 music:  music_arg
1065         | lyric_element_music
1066         ;
1067
1068 music_embedded:
1069         music
1070         {
1071                 if (unsmob_music ($1)->is_mus_type ("post-event")) {
1072                         parser->parser_error (@1, _ ("unexpected post-event"));
1073                         $$ = SCM_UNSPECIFIED;
1074                 }
1075         }
1076         | music_embedded_backup
1077         {
1078                 $$ = $1;
1079         }
1080         | music_embedded_backup BACKUP lyric_element_music
1081         {
1082                 $$ = $3;
1083         }
1084         | multiplied_duration post_events
1085         {
1086                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1087
1088                 parser->default_duration_ = *unsmob_duration ($1);
1089                 n->set_property ("duration", $1);
1090
1091                 if (scm_is_pair ($2))
1092                         n->set_property ("articulations",
1093                                          scm_reverse_x ($2, SCM_EOL));
1094                 $$ = n->unprotect ();
1095         }
1096         ;
1097
1098 music_embedded_backup:
1099         embedded_scm
1100         {
1101                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1102                         $$ = $1;
1103                 else if (Music *m = unsmob_music ($1)) {
1104                         if (m->is_mus_type ("post-event")) {
1105                                 parser->parser_error
1106                                         (@1, _ ("unexpected post-event"));
1107                                 $$ = SCM_UNSPECIFIED;
1108                         } else
1109                                 $$ = $1;
1110                 } else if (parser->lexer_->is_lyric_state ()
1111                            && Text_interface::is_markup ($1))
1112                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1113                 else {
1114                         @$.warning (_ ("Ignoring non-music expression"));
1115                         $$ = $1;
1116                 }
1117         }
1118         ;
1119
1120 music_arg:
1121         simple_music
1122         {
1123                 $$ = make_music_from_simple (parser, @1, $1);
1124                 if (!unsmob_music ($$))
1125                 {
1126                         parser->parser_error (@1, _ ("music expected"));
1127                         $$ = MAKE_SYNTAX ("void-music", @$);
1128                 }
1129         }
1130         | composite_music %prec COMPOSITE
1131         ;
1132
1133 music_assign:
1134         simple_music
1135         | composite_music %prec COMPOSITE
1136         ;
1137
1138 repeated_music:
1139         REPEAT simple_string unsigned_number music
1140         {
1141                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1142         }
1143         | REPEAT_IDENTIFIER music
1144         {
1145                 $$ = MAKE_SYNTAX ("repeat", @$, scm_car ($1), scm_cdr ($1),
1146                                   $2, SCM_EOL);
1147         }
1148         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1149         {
1150                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1151         }
1152         | REPEAT_IDENTIFIER music ALTERNATIVE braced_music_list
1153         {
1154                 $$ = MAKE_SYNTAX ("repeat", @$, scm_car ($1), scm_cdr ($1),
1155                                   $2, $4);
1156         }
1157         ;
1158
1159 sequential_music:
1160         SEQUENTIAL braced_music_list {
1161                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1162         }
1163         | braced_music_list {
1164                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1165         }
1166         ;
1167
1168 simultaneous_music:
1169         SIMULTANEOUS braced_music_list {
1170                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1171         }
1172         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1173                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1174         }
1175         ;
1176
1177 simple_music:
1178         event_chord
1179         | music_property_def
1180         | context_change
1181         ;
1182
1183 context_modification:
1184         WITH
1185         {
1186                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1187                 parser->lexer_->push_note_state (nn);
1188         } '{' context_mod_list '}'
1189         {
1190                 parser->lexer_->pop_state ();
1191                 $$ = $4;
1192         }
1193         | WITH CONTEXT_MOD_IDENTIFIER
1194         {
1195                 $$ = $2;
1196         }
1197         | CONTEXT_MOD_IDENTIFIER
1198         {
1199                 $$ = $1;
1200         }
1201         | WITH context_modification_arg
1202         {
1203                 if (unsmob_music ($2)) {
1204                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
1205                         $2 = scm_call_2 (proc, parser->self_scm (), $2);
1206                 }
1207                 if (unsmob_context_mod ($2))
1208                         $$ = $2;
1209                 else {
1210                         parser->parser_error (@2, _ ("not a context mod"));
1211                         $$ = Context_mod ().smobbed_copy ();
1212                 }
1213         }
1214         ;
1215
1216 context_modification_arg:
1217         embedded_scm_closed
1218         | MUSIC_IDENTIFIER
1219         ;
1220
1221 optional_context_mod:
1222         /**/ {
1223             $$ = SCM_EOL;
1224         }
1225         | context_modification
1226         {
1227               $$ = $1;
1228         }
1229         ;
1230
1231 context_mod_list:
1232         /**/ {
1233             $$ = Context_mod ().smobbed_copy ();
1234         }
1235         | context_mod_list context_mod  {
1236                 if (!SCM_UNBNDP ($2))
1237                         unsmob_context_mod ($1)->add_context_mod ($2);
1238         }
1239         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1240                  Context_mod *md = unsmob_context_mod ($2);
1241                  if (md)
1242                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1243         }
1244         | context_mod_list context_mod_embedded {
1245                 unsmob_context_mod ($1)->add_context_mods
1246                         (unsmob_context_mod ($2)->get_mods ());
1247         }
1248         ;
1249
1250 composite_music:
1251         complex_music
1252         | music_bare
1253         ;
1254
1255 /* Music that can be parsed without lookahead */
1256 closed_music:
1257         music_bare
1258         | complex_music_prefix closed_music
1259         {
1260                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1261         }
1262         | music_function_call_closed
1263         ;
1264
1265 music_bare:
1266         mode_changed_music
1267         | MUSIC_IDENTIFIER
1268         | grouped_music_list
1269         ;
1270
1271 grouped_music_list:
1272         simultaneous_music              { $$ = $1; }
1273         | sequential_music              { $$ = $1; }
1274         ;
1275
1276 /* Function argument lists are arguably the most complex part in the
1277  * parser.  They are pretty tricky to understand because of the way
1278  * they are processed, and because of optional arguments that can be
1279  * omitted.  When there are several optional arguments in a row,
1280  * omitting one automatically omits all following arguments.  Optional
1281  * arguments can only be omitted when either
1282  *
1283  * a) the omission is explicitly started with \default
1284  * b) the omission is implicitly started by an argument not matching
1285  *    its predicate, and there is a mandatory argument later that can
1286  *    "catch" the argument that does not fit.
1287  *
1288  * When argument parsing starts, the lexer pushes EXPECT_SCM tokens
1289  * (corresponding to mandatory arguments and having a predicate
1290  * function as semantic value) or EXPECT_OPTIONAL EXPECT_SCM (where
1291  * the semantic value of the EXPECT_OPTIONAL token is the default to
1292  * use when the optional argument is omitted, and EXPECT_SCM again has
1293  * the argument predicate as semantic value) in reverse order to the
1294  * parser, followed by EXPECT_NO_MORE_ARGS.  The argument list is then
1295  * processed inside-out while actual tokens are consumed.
1296  *
1297  * This means that the argument list tokens determine the actions
1298  * taken as they arrive.  The structure of the argument list is known
1299  * to the parser and stored in its parse stack when the first argument
1300  * is being parsed.  What the parser does not know is which predicates
1301  * will match and whether or not \default will be appearing in the
1302  * argument list, and where.
1303  *
1304  * Many of the basic nonterminals used for argument list scanning come
1305  * in a "normal" and a "closed" flavor.  A closed expression is one
1306  * that can be parsed without a lookahead token.  That makes it
1307  * feasible for an optional argument that may need to be skipped:
1308  * skipping can only be accomplished by pushing back the token into
1309  * the lexer, and that only works when there is no lookahead token.
1310  *
1311  * Sequences of 0 or more optional arguments are scanned using either
1312  * function_arglist_backup or function_arglist_nonbackup.  The first
1313  * is used when optional arguments are followed by at least one
1314  * mandatory argument: in that case optional arguments may be skipped
1315  * by either a false predicate (in which case the expression will be
1316  * pushed back as one or more tokens, preceded by a BACKUP token) or
1317  * by using \default.
1318  *
1319  * If optional arguments are at the end of the argument list, they are
1320  * instead scanned using function_arglist_nonbackup: here the only
1321  * manner to enter into skipping of optional arguments is the use of
1322  * \default.
1323  *
1324  * The argument list of a normal function call is parsed using
1325  * function_arglist.  The part of an argument list before a mandatory
1326  * argument is parsed using function_arglist_optional.
1327  *
1328  * The difference is that leading optional arguments are scanned using
1329  * function_arglist_nonbackup and function_arglist_backup,
1330  * respectively.
1331  *
1332  * Most other details are obvious in the rules themselves.
1333  *
1334  */
1335
1336 function_arglist_nonbackup_common:
1337         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup FRACTION
1338         {
1339                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1340         }
1341         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup post_event_nofinger
1342         {
1343                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1344         }
1345         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' UNSIGNED
1346         {
1347                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1348                 if (scm_is_true (scm_call_1 ($2, n)))
1349                         $$ = scm_cons (n, $3);
1350                 else {
1351                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1352                         t->set_property ("digit", $5);
1353                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1354                                                $3, $2, n);
1355                 }
1356
1357         }
1358         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' REAL
1359         {
1360                 $$ = check_scheme_arg (parser, @4,
1361                                        scm_difference ($5, SCM_UNDEFINED),
1362                                        $3, $2);
1363         }
1364         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup '-' NUMBER_IDENTIFIER
1365         {
1366                 $$ = check_scheme_arg (parser, @4,
1367                                        scm_difference ($5, SCM_UNDEFINED),
1368                                        $3, $2);
1369         }
1370         ;
1371
1372 function_arglist_closed_nonbackup:
1373         function_arglist_nonbackup_common
1374         | function_arglist_closed_common
1375         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg_closed
1376         {
1377                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1378         }
1379         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_closed
1380         {
1381                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1382         }
1383         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1384         {
1385                 $$ = check_scheme_arg (parser, @4,
1386                                        try_string_variants ($2, $4),
1387                                        $3, $2, $4);
1388         }
1389         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1390         {
1391                 $$ = check_scheme_arg (parser, @4,
1392                                        try_string_variants ($2, $4),
1393                                        $3, $2, $4);
1394         }
1395         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1396         {
1397                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1398         }
1399         ;
1400
1401 symbol_list_arg:
1402         SYMBOL_LIST
1403         | SYMBOL_LIST '.' symbol_list_rev
1404         {
1405                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1406         }
1407         ;
1408
1409 symbol_list_rev:
1410         symbol_list_part
1411         | symbol_list_rev '.' symbol_list_part
1412         {
1413                 $$ = scm_append_x (scm_list_2 ($3, $1));
1414         }
1415         ;
1416
1417 // symbol_list_part delivers elements in reverse copy.
1418
1419 symbol_list_part:
1420         symbol_list_element
1421         {
1422                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1423                 $$ = try_string_variants (sym_l_p, $1);
1424                 if (SCM_UNBNDP ($$)) {
1425                         parser->parser_error (@1, _("not a symbol"));
1426                         $$ = SCM_EOL;
1427                 } else
1428                         $$ = scm_reverse ($$);
1429         }
1430         ;
1431
1432
1433 symbol_list_element:
1434         STRING
1435         | embedded_scm_bare
1436         ;
1437
1438
1439 function_arglist_nonbackup:
1440         function_arglist_nonbackup_common
1441         | function_arglist_common
1442         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup embedded_scm_arg
1443         {
1444                 if (scm_is_true (scm_call_1 ($2, $4)))
1445                         $$ = scm_cons ($4, $3);
1446                 else
1447                         $$ = check_scheme_arg (parser, @4,
1448                                                make_music_from_simple
1449                                                (parser, @4, $4),
1450                                                $3, $2);
1451         }
1452         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup bare_number_common
1453         {
1454                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1455         }
1456         | function_arglist_nonbackup_reparse REPARSE duration_length
1457         {
1458                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1459         }
1460         | function_arglist_nonbackup_reparse REPARSE bare_number_common
1461         {
1462                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1463         }
1464         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1465         {
1466                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1467         }
1468         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1469         {
1470                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1471         }
1472         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1473         {
1474                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1475         }
1476         ;
1477
1478 function_arglist_nonbackup_reparse:
1479         EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup SCM_IDENTIFIER
1480         {
1481                 $$ = $3;
1482                 SCM res = try_string_variants ($2, $4);
1483                 if (!SCM_UNBNDP (res))
1484                         if (scm_is_pair (res))
1485                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1486                         else
1487                                 MYREPARSE (@4, $2, SCM_ARG, res);
1488                 else if (scm_is_true
1489                          (scm_call_1
1490                           ($2, make_music_from_simple
1491                            (parser, @4, $4))))
1492                         MYREPARSE (@4, $2, STRING, $4);
1493                 else
1494                         MYREPARSE (@4, $2, SCM_ARG, $4);
1495         }
1496         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup STRING
1497         {
1498                 $$ = $3;
1499                 SCM res = try_string_variants ($2, $4);
1500                 if (!SCM_UNBNDP (res))
1501                         if (scm_is_pair (res))
1502                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1503                         else
1504                                 MYREPARSE (@4, $2, SCM_ARG, res);
1505                 else if (scm_is_true
1506                          (scm_call_1
1507                           ($2, make_music_from_simple
1508                            (parser, @4, $4))))
1509                         MYREPARSE (@4, $2, STRING, $4);
1510                 else
1511                         MYREPARSE (@4, $2, SCM_ARG, $4);
1512         }
1513         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup full_markup
1514         {
1515                 $$ = $3;
1516                 if (scm_is_true (scm_call_1 ($2, $4)))
1517                         MYREPARSE (@4, $2, SCM_ARG, $4);
1518                 else if (scm_is_true
1519                          (scm_call_1
1520                           ($2, make_music_from_simple
1521                            (parser, @4, $4))))
1522                         MYREPARSE (@4, $2, STRING, $4);
1523                 else
1524                         MYREPARSE (@4, $2, SCM_ARG, $4);
1525         }
1526         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup UNSIGNED
1527         {
1528                 $$ = $3;
1529                 if (scm_is_true (scm_call_1 ($2, $4)))
1530                         MYREPARSE (@4, $2, REAL, $4);
1531                 else {
1532                         SCM d = make_duration ($4);
1533                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1534                                 MYREPARSE (@4, $2, REAL, $4); // trigger error
1535                         else
1536                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1537                 }
1538         }
1539         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_nonbackup DURATION_IDENTIFIER {
1540                 $$ = $3;
1541                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1542         }
1543         ;
1544
1545
1546 function_arglist_backup:
1547         function_arglist_common
1548         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup embedded_scm_arg_closed
1549         {
1550                 if (scm_is_true (scm_call_1 ($2, $4)))
1551                 {
1552                         $$ = scm_cons ($4, $3);
1553                 } else {
1554                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1555                         MYBACKUP (SCM_ARG, $4, @4);
1556                 }
1557         }
1558         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REPEAT simple_string unsigned_number
1559         {
1560                 $4 = MAKE_SYNTAX ("repeat", @4, $5, $6,
1561                                   MY_MAKE_MUSIC ("Music", @4)->unprotect (),
1562                                   SCM_EOL);
1563                 if (scm_is_true (scm_call_1 ($2, $4)))
1564                 {
1565                         $$ = $3;
1566                         MYREPARSE (@4, $2, REPEAT_IDENTIFIER, scm_cons ($5, $6));
1567                 } else {
1568                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1569                         MYBACKUP (REPEAT_IDENTIFIER, scm_cons ($5, $6), @4);
1570                 }
1571         }
1572         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup chord_body
1573         {
1574                 if (scm_is_true (scm_call_1 ($2, $4)))
1575                 {
1576                         $$ = $3;
1577                         MYREPARSE (@4, $2, CHORD_BODY_IDENTIFIER, $4);
1578                 } else {
1579                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1580                         MYBACKUP (CHORD_BODY_IDENTIFIER, $4, @4);
1581                 }
1582         }
1583         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup post_event_nofinger
1584         {
1585                 if (scm_is_true (scm_call_1 ($2, $4)))
1586                 {
1587                         $$ = scm_cons ($4, $3);
1588                 } else {
1589                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1590                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1591                 }
1592         }
1593         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup full_markup
1594         {
1595                 if (scm_is_true (scm_call_1 ($2, $4)))
1596                         $$ = scm_cons ($4, $3);
1597                 else {
1598                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1599                         MYBACKUP (LYRIC_ELEMENT, $4, @4);
1600                 }
1601         }
1602         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup UNSIGNED
1603         {
1604                 if (scm_is_true (scm_call_1 ($2, $4)))
1605                 {
1606                         MYREPARSE (@4, $2, REAL, $4);
1607                         $$ = $3;
1608                 } else {
1609                         SCM d = make_duration ($4);
1610                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($2, d)))
1611                         {
1612                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1613                                 MYBACKUP (UNSIGNED, $4, @4);
1614                         } else {
1615                                 MYREPARSE (@4, $2, DURATION_IDENTIFIER, d);
1616                                 $$ = $3;
1617                         }
1618                 }
1619         }
1620         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup REAL
1621         {
1622                 if (scm_is_true (scm_call_1 ($2, $4)))
1623                 {
1624                         $$ = $3;
1625                         MYREPARSE (@4, $2, REAL, $4);
1626                 } else {
1627                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1628                         MYBACKUP (REAL, $4, @4);
1629                 }
1630         }
1631         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NUMBER_IDENTIFIER
1632         {
1633                 if (scm_is_true (scm_call_1 ($2, $4)))
1634                 {
1635                         $$ = scm_cons ($4, $3);
1636                 } else {
1637                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1638                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1639                 }
1640         }
1641         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup FRACTION
1642         {
1643                 if (scm_is_true (scm_call_1 ($2, $4)))
1644                 {
1645                         $$ = scm_cons ($4, $3);
1646                 } else {
1647                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1648                         MYBACKUP (FRACTION, $4, @4);
1649                 }
1650         }
1651         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' UNSIGNED
1652         {
1653                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1654                 if (scm_is_true (scm_call_1 ($2, n))) {
1655                         $$ = $3;
1656                         MYREPARSE (@5, $2, REAL, n);
1657                 } else {
1658                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1659                         t->set_property ("digit", $5);
1660                         $$ = t->unprotect ();
1661                         if (scm_is_true (scm_call_1 ($2, $$)))
1662                                 $$ = scm_cons ($$, $3);
1663                         else {
1664                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1665                                 MYBACKUP (UNSIGNED, $5, @5);
1666                                 parser->lexer_->push_extra_token ('-');
1667                         }
1668                 }
1669
1670         }
1671         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' REAL
1672         {
1673                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1674                 if (scm_is_true (scm_call_1 ($2, n))) {
1675                         MYREPARSE (@5, $2, REAL, n);
1676                         $$ = $3;
1677                 } else {
1678                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1679                         MYBACKUP (REAL, n, @5);
1680                 }
1681         }
1682         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup '-' NUMBER_IDENTIFIER
1683         {
1684                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1685                 if (scm_is_true (scm_call_1 ($2, n))) {
1686                         $$ = scm_cons (n, $3);
1687                 } else {
1688                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1689                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1690                 }
1691         }
1692         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup PITCH_IDENTIFIER
1693         {
1694                 if (scm_is_true (scm_call_1 ($2, $4)))
1695                 {
1696                         $$ = scm_cons ($4, $3);
1697                 } else {
1698                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1699                         MYBACKUP (PITCH_IDENTIFIER, $4, @4);
1700                 }
1701         }
1702         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup NOTENAME_PITCH
1703         {
1704                 if (scm_is_true (scm_call_1 ($2, $4)))
1705                 {
1706                         MYREPARSE (@4, $2, NOTENAME_PITCH, $4);
1707                         $$ = $3;
1708                 } else {
1709                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1710                         MYBACKUP (NOTENAME_PITCH, $4, @4);
1711                 }
1712         }
1713         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup TONICNAME_PITCH
1714         {
1715                 if (scm_is_true (scm_call_1 ($2, $4)))
1716                 {
1717                         MYREPARSE (@4, $2, TONICNAME_PITCH, $4);
1718                         $$ = $3;
1719                 } else {
1720                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1721                         MYBACKUP (TONICNAME_PITCH, $4, @4);
1722                 }
1723         }
1724         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup DURATION_IDENTIFIER
1725         {
1726                 if (scm_is_true (scm_call_1 ($2, $4)))
1727                 {
1728                         MYREPARSE (@4, $2, DURATION_IDENTIFIER, $4);
1729                         $$ = $3;
1730                 } else {
1731                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1732                         MYBACKUP (DURATION_IDENTIFIER, $4, @4);
1733                 }
1734         }
1735         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup SCM_IDENTIFIER
1736         {
1737                 SCM res = try_string_variants ($2, $4);
1738                 if (!SCM_UNBNDP (res))
1739                         if (scm_is_pair (res)) {
1740                                 $$ = $3;
1741                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1742                         }
1743                         else
1744                                 $$ = scm_cons (res, $3);
1745                 else {
1746                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1747                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1748                 }
1749         }
1750         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup STRING
1751         {
1752                 SCM res = try_string_variants ($2, $4);
1753                 if (!SCM_UNBNDP (res))
1754                         if (scm_is_pair (res)) {
1755                                 $$ = $3;
1756                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1757                         }
1758                         else
1759                                 $$ = scm_cons (res, $3);
1760                 else {
1761                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1762                         MYBACKUP (STRING, $4, @4);
1763                 }
1764         }
1765         | function_arglist_backup REPARSE music_assign
1766         {
1767                 if (scm_is_true (scm_call_1 ($2, $3)))
1768                         $$ = scm_cons ($3, $1);
1769                 else
1770                         $$ = check_scheme_arg (parser, @3,
1771                                                make_music_from_simple
1772                                                (parser, @3, $3),
1773                                                $1, $2);
1774         }
1775         | function_arglist_backup REPARSE bare_number_common
1776         {
1777                 $$ = check_scheme_arg (parser, @3,
1778                                        $3, $1, $2);
1779         }
1780         | function_arglist_backup REPARSE duration_length
1781         {
1782                 $$ = check_scheme_arg (parser, @3,
1783                                        $3, $1, $2);
1784         }
1785         | function_arglist_backup REPARSE symbol_list_arg
1786         {
1787                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1788         }
1789         ;
1790
1791 function_arglist:
1792         function_arglist_nonbackup
1793         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
1794         {
1795                 $$ = scm_cons (loc_on_music (@4, $1), $3);
1796         }
1797         ;
1798
1799 function_arglist_skip_nonbackup:
1800         function_arglist_nonbackup
1801         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup
1802         {
1803                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1804         }
1805         ;
1806
1807 function_arglist_common:
1808         EXPECT_NO_MORE_ARGS {
1809                 $$ = SCM_EOL;
1810         }
1811         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1812         {
1813                 if (scm_is_true (scm_call_1 ($1, $3)))
1814                         $$ = scm_cons ($3, $2);
1815                 else
1816                         $$ = check_scheme_arg (parser, @3,
1817                                                make_music_from_simple
1818                                                (parser, @3, $3),
1819                                                $2, $1);
1820         }
1821         | EXPECT_SCM function_arglist_optional bare_number_common
1822         {
1823                 $$ = check_scheme_arg (parser, @3,
1824                                        $3, $2, $1);
1825         }
1826         | EXPECT_SCM function_arglist_optional FRACTION
1827         {
1828                 $$ = check_scheme_arg (parser, @3,
1829                                        $3, $2, $1);
1830         }
1831         | EXPECT_SCM function_arglist_optional post_event_nofinger
1832         {
1833                 $$ = check_scheme_arg (parser, @3,
1834                                        $3, $2, $1);
1835         }
1836         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
1837         {
1838                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1839                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1840         }
1841         | function_arglist_common_reparse REPARSE SCM_ARG
1842         {
1843                 $$ = check_scheme_arg (parser, @3,
1844                                        $3, $1, $2);
1845         }
1846         | function_arglist_common_reparse REPARSE lyric_element_music
1847         {
1848                 $$ = check_scheme_arg (parser, @3,
1849                                        $3, $1, $2);
1850         }
1851         | function_arglist_common_reparse REPARSE bare_number_common
1852         {
1853                 $$ = check_scheme_arg (parser, @3,
1854                                        $3, $1, $2);
1855         }
1856         | function_arglist_common_reparse REPARSE duration_length
1857         {
1858                 $$ = check_scheme_arg (parser, @3,
1859                                        $3, $1, $2);
1860         }
1861         | function_arglist_common_reparse REPARSE symbol_list_arg
1862         {
1863                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1864         }
1865         ;
1866
1867 function_arglist_common_reparse:
1868         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
1869         {
1870                 $$ = $2;
1871                 SCM res = try_string_variants ($1, $3);
1872                 if (!SCM_UNBNDP (res))
1873                         if (scm_is_pair (res))
1874                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
1875                         else
1876                                 MYREPARSE (@3, $1, SCM_ARG, res);
1877                 else if (scm_is_true
1878                          (scm_call_1
1879                           ($1, make_music_from_simple (parser, @3, $3))))
1880                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1881                 else
1882                         // This is going to flag a syntax error, we
1883                         // know the predicate to be false.
1884                         MYREPARSE (@3, $1, SCM_ARG, $3);
1885         }
1886         | EXPECT_SCM function_arglist_optional STRING
1887         {
1888                 $$ = $2;
1889                 SCM res = try_string_variants ($1, $3);
1890                 if (!SCM_UNBNDP (res))
1891                         if (scm_is_pair (res))
1892                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
1893                         else
1894                                 MYREPARSE (@3, $1, SCM_ARG, res);
1895                 else if (scm_is_true
1896                          (scm_call_1
1897                           ($1, make_music_from_simple (parser, @3, $3))))
1898                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1899                 else
1900                         // This is going to flag a syntax error, we
1901                         // know the predicate to be false.
1902                         MYREPARSE (@3, $1, SCM_ARG, $3);
1903         }
1904         | EXPECT_SCM function_arglist_optional full_markup
1905         {
1906                 $$ = $2;
1907                 if (scm_is_true (scm_call_1 ($1, $3)))
1908                         MYREPARSE (@3, $1, SCM_ARG, $3);
1909                 else if (scm_is_true
1910                          (scm_call_1
1911                           ($1, make_music_from_simple (parser, @3, $3))))
1912                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1913                 else
1914                         // This is going to flag a syntax error, we
1915                         // know the predicate to be false.
1916                         MYREPARSE (@3, $1, SCM_ARG, $3);
1917         }
1918         | EXPECT_SCM function_arglist_optional UNSIGNED
1919         {
1920                 $$ = $2;
1921                 if (scm_is_true (scm_call_1 ($1, $3)))
1922                         MYREPARSE (@3, $1, REAL, $3);
1923                 else {
1924                         SCM d = make_duration ($3);
1925                         if (SCM_UNBNDP (d) || scm_is_false (scm_call_1 ($1, d)))
1926                                 MYREPARSE (@3, $1, REAL, $3);
1927                         else
1928                                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, d);
1929                 }
1930         }
1931         | EXPECT_SCM function_arglist_optional DURATION_IDENTIFIER
1932         {
1933                 $$ = $2;
1934                 MYREPARSE (@3, $1, DURATION_IDENTIFIER, $3);
1935         }
1936         | EXPECT_SCM function_arglist_optional '-' UNSIGNED
1937         {
1938                 $$ = $2;
1939                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1940                 if (scm_is_true (scm_call_1 ($1, n)))
1941                         MYREPARSE (@4, $1, REAL, n);
1942                 else {
1943                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1944                         t->set_property ("digit", $4);
1945                         SCM m = t->unprotect ();
1946                         if (scm_is_true (scm_call_1 ($1, m)))
1947                                 MYREPARSE (@4, $1, SCM_ARG, m);
1948                         else
1949                                 MYREPARSE (@4, $1, SCM_ARG, $4);
1950                 }
1951
1952         }
1953         | EXPECT_SCM function_arglist_optional '-' REAL
1954         {
1955                 $$ = $2;
1956                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1957                 MYREPARSE (@4, $1, REAL, n);
1958         }
1959         ;
1960
1961 function_arglist_closed:
1962         function_arglist_closed_nonbackup
1963         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_nonbackup DEFAULT
1964         {
1965                 $$ = scm_cons (loc_on_music (@4, $1), $3);
1966         }
1967         ;
1968
1969 function_arglist_closed_common:
1970         EXPECT_NO_MORE_ARGS {
1971                 $$ = SCM_EOL;
1972         }
1973         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1974         {
1975                 $$ = check_scheme_arg (parser, @3,
1976                                        $3, $2, $1);
1977         }
1978         | EXPECT_SCM function_arglist_optional bare_number_common_closed
1979         {
1980                 $$ = check_scheme_arg (parser, @3,
1981                                        $3, $2, $1);
1982         }
1983         | EXPECT_SCM function_arglist_optional '-' NUMBER_IDENTIFIER
1984         {
1985                 $$ = check_scheme_arg (parser, @3,
1986                                        scm_difference ($4, SCM_UNDEFINED),
1987                                        $2, $1);
1988         }
1989         | EXPECT_SCM function_arglist_optional post_event_nofinger
1990         {
1991                 $$ = check_scheme_arg (parser, @3,
1992                                        $3, $2, $1);
1993         }
1994         | EXPECT_SCM function_arglist_optional FRACTION
1995         {
1996                 $$ = check_scheme_arg (parser, @3,
1997                                        $3, $2, $1);
1998         }
1999         | function_arglist_common_reparse REPARSE SCM_ARG
2000         {
2001                 $$ = check_scheme_arg (parser, @3,
2002                                        $3, $1, $2);
2003         }
2004         | function_arglist_common_reparse REPARSE bare_number_common_closed
2005         {
2006                 $$ = check_scheme_arg (parser, @3,
2007                                        $3, $1, $2);
2008         }
2009         | function_arglist_common_reparse REPARSE symbol_list_arg
2010         {
2011                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
2012         }
2013         ;
2014
2015 function_arglist_optional:
2016         function_arglist_backup
2017         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup DEFAULT
2018         {
2019                 $$ = scm_cons (loc_on_music (@4, $1), $3);
2020         }
2021         | function_arglist_skip_backup BACKUP
2022         ;
2023
2024 function_arglist_skip_backup:
2025         function_arglist_backup
2026         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip_backup
2027         {
2028                 $$ = scm_cons (loc_on_music (@3, $1), $3);
2029         }
2030         ;
2031
2032 embedded_scm_closed:
2033         embedded_scm_bare
2034         | scm_function_call_closed
2035         ;
2036
2037 embedded_scm_arg_closed:
2038         embedded_scm_bare_arg
2039         | scm_function_call_closed
2040         | closed_music
2041         ;
2042
2043 scm_function_call_closed:
2044         SCM_FUNCTION function_arglist_closed {
2045                 $$ = MAKE_SYNTAX ("music-function", @$,
2046                                          $1, $2);
2047         }
2048         ;
2049
2050 music_function_call:
2051         MUSIC_FUNCTION function_arglist {
2052                 $$ = MAKE_SYNTAX ("music-function", @$,
2053                                          $1, $2);
2054         }
2055         ;
2056
2057
2058 optional_id:
2059         /**/ { $$ = SCM_EOL; }
2060         | '=' simple_string {
2061                 $$ = $2;
2062         }
2063         ;
2064
2065 complex_music:
2066         music_function_call
2067         | repeated_music                { $$ = $1; }
2068         | re_rhythmed_music     { $$ = $1; }
2069         | complex_music_prefix music
2070         {
2071                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
2072         }
2073         ;
2074
2075 complex_music_prefix:
2076         CONTEXT symbol optional_id optional_context_mod {
2077                 Context_mod *ctxmod = unsmob_context_mod ($4);
2078                 SCM mods = SCM_EOL;
2079                 if (ctxmod)
2080                         mods = ctxmod->get_mods ();
2081                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
2082         }
2083         | NEWCONTEXT symbol optional_id optional_context_mod {
2084                 Context_mod *ctxmod = unsmob_context_mod ($4);
2085                 SCM mods = SCM_EOL;
2086                 if (ctxmod)
2087                         mods = ctxmod->get_mods ();
2088                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
2089         }
2090         ;
2091
2092 mode_changed_music:
2093         mode_changing_head grouped_music_list {
2094                 if ($1 == ly_symbol2scm ("chords"))
2095                 {
2096                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
2097                 }
2098                 else
2099                 {
2100                   $$ = $2;
2101                 }
2102                 parser->lexer_->pop_state ();
2103         }
2104         | mode_changing_head_with_context optional_context_mod grouped_music_list {
2105                 Context_mod *ctxmod = unsmob_context_mod ($2);
2106                 SCM mods = SCM_EOL;
2107                 if (ctxmod)
2108                         mods = ctxmod->get_mods ();
2109                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
2110                 if ($1 == ly_symbol2scm ("ChordNames"))
2111                 {
2112                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
2113                 }
2114                 parser->lexer_->pop_state ();
2115         }
2116         ;
2117
2118 mode_changing_head:
2119         NOTEMODE {
2120                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
2121                 parser->lexer_->push_note_state (nn);
2122
2123                 $$ = ly_symbol2scm ("notes");
2124         }
2125         | DRUMMODE
2126                 {
2127                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2128                 parser->lexer_->push_note_state (nn);
2129
2130                 $$ = ly_symbol2scm ("drums");
2131         }
2132         | FIGUREMODE {
2133                 parser->lexer_->push_figuredbass_state ();
2134
2135                 $$ = ly_symbol2scm ("figures");
2136         }
2137         | CHORDMODE {
2138                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2139                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2140                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2141                 parser->lexer_->push_chord_state (nn);
2142                 $$ = ly_symbol2scm ("chords");
2143
2144         }
2145         | LYRICMODE
2146                 { parser->lexer_->push_lyric_state ();
2147                 $$ = ly_symbol2scm ("lyrics");
2148         }
2149         ;
2150
2151 mode_changing_head_with_context:
2152         DRUMS {
2153                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
2154                 parser->lexer_->push_note_state (nn);
2155
2156                 $$ = ly_symbol2scm ("DrumStaff");
2157         }
2158         | FIGURES {
2159                 parser->lexer_->push_figuredbass_state ();
2160
2161                 $$ = ly_symbol2scm ("FiguredBass");
2162         }
2163         | CHORDS {
2164                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
2165                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
2166                 nn = parser->lexer_->lookup_identifier ("pitchnames");
2167                 parser->lexer_->push_chord_state (nn);
2168                 $$ = ly_symbol2scm ("ChordNames");
2169         }
2170         | LYRICS
2171                 { parser->lexer_->push_lyric_state ();
2172                 $$ = ly_symbol2scm ("Lyrics");
2173         }
2174         ;
2175
2176 new_lyrics:
2177         ADDLYRICS { parser->lexer_->push_lyric_state (); }
2178         /*cont */
2179         composite_music {
2180         /* Can also use music at the expensive of two S/Rs similar to
2181            \repeat \alternative */
2182                 parser->lexer_->pop_state ();
2183
2184                 $$ = scm_cons ($3, SCM_EOL);
2185         }
2186         | new_lyrics ADDLYRICS {
2187                 parser->lexer_->push_lyric_state ();
2188         } composite_music {
2189                 parser->lexer_->pop_state ();
2190                 $$ = scm_cons ($4, $1);
2191         }
2192         ;
2193
2194 re_rhythmed_music:
2195         composite_music new_lyrics {
2196                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
2197         } %prec COMPOSITE
2198         | LYRICSTO simple_string {
2199                 parser->lexer_->push_lyric_state ();
2200         } music {
2201                 parser->lexer_->pop_state ();
2202                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
2203         }
2204         ;
2205
2206 context_change:
2207         CHANGE STRING '=' STRING  {
2208                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
2209         }
2210         ;
2211
2212
2213 property_path:
2214         symbol_list_rev  {
2215                 $$ = scm_reverse_x ($1, SCM_EOL);
2216         }
2217         | symbol_list_rev property_path {
2218                 $$ = scm_reverse_x ($1, $2);
2219         }
2220         ;
2221
2222 property_operation:
2223         symbol '=' scalar {
2224                 $$ = scm_list_3 (ly_symbol2scm ("assign"), $1, $3);
2225         }
2226         | UNSET symbol {
2227                 $$ = scm_list_2 (ly_symbol2scm ("unset"), $2);
2228         }
2229         | OVERRIDE property_path '=' scalar {
2230                 if (scm_ilength ($2) < 2) {
2231                         parser->parser_error (@2, _("bad grob property path"));
2232                         $$ = SCM_UNDEFINED;
2233                 } else {
2234                         $$ = scm_cons (ly_symbol2scm ("push"),
2235                                        scm_cons2 (scm_car ($2),
2236                                                   $4,
2237                                                   scm_cdr ($2)));
2238                 }
2239         }
2240         | REVERT revert_arg {
2241                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2242         }
2243         ;
2244
2245 // This is all quite awkward for the sake of substantial backward
2246 // compatibility while at the same time allowing a more "natural" form
2247 // of specification not separating grob specification from grob
2248 // property path.  The purpose of this definition of revert_arg is to
2249 // allow the symbol list which specifies grob and property to revert
2250 // to be optionally be split into two parts after the grob (which in
2251 // this case is just the first element of the list).  symbol_list_part
2252 // is only one path component, but it can be parsed without lookahead,
2253 // so we can follow it with a synthetic BACKUP token when needed.  If
2254 // the first symbol_list_part already contains multiple elements (only
2255 // possible if a Scheme expression provides them), we just parse for
2256 // additional elements introduced by '.', which is what the
2257 // SYMBOL_LIST backup in connection with the immediately following
2258 // rule using symbol_list_arg does.
2259 //
2260 // As long as we don't have our coffers filled with both grob and at
2261 // least one grob property specification, the rest of the required
2262 // symbol list chain may be provided either with or without a leading
2263 // dot.  This is for both allowing the traditional
2264 // \revert Accidental #'color
2265 // as well as well as the "naive" form
2266 // \revert Accidental.color
2267
2268 revert_arg:
2269         revert_arg_backup BACKUP symbol_list_arg
2270         {
2271                 $$ = $3;
2272         }
2273         ;
2274
2275 revert_arg_backup:
2276         revert_arg_part
2277         {
2278                 if (scm_is_null ($1)
2279                     || scm_is_null (scm_cdr ($1)))
2280                         MYBACKUP (SCM_ARG, $1, @1);
2281                 else
2282                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2283         }
2284         ;
2285
2286 // revert_arg_part delivers results in reverse
2287 revert_arg_part:
2288         symbol_list_part
2289         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2290         {
2291                 $$ = scm_append_x (scm_list_2 ($5, $3));
2292         }
2293         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2294         {
2295                 $$ = scm_append_x (scm_list_2 ($4, $3));
2296         }
2297         ;
2298
2299 context_def_mod:
2300         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2301         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2302
2303         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2304         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2305         | DENIES { $$ = ly_symbol2scm ("denies"); }
2306
2307         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2308         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2309         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2310         | NAME { $$ = ly_symbol2scm ("context-name"); }
2311         ;
2312
2313 context_mod:
2314         property_operation { $$ = $1; }
2315         | context_def_mod STRING {
2316                 $$ = scm_list_2 ($1, $2);
2317         }
2318         | context_def_mod embedded_scm
2319         {
2320                 if (!scm_is_string ($2)
2321                     && ly_symbol2scm ("consists") != $1
2322                     && ly_symbol2scm ("remove") != $1)
2323                 {
2324                         $$ = SCM_EOL;
2325                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2326                 }
2327                 else
2328                 {
2329                         $$ = scm_list_2 ($1, $2);
2330                 }
2331         }
2332         ;
2333
2334 // If defined, at least two members.
2335 grob_prop_spec:
2336         symbol_list_rev
2337         {
2338                 SCM l = scm_reverse_x ($1, SCM_EOL);
2339                 if (scm_is_pair (l)
2340                     && to_boolean
2341                     (scm_object_property (scm_car (l),
2342                                           ly_symbol2scm ("is-grob?"))))
2343                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2344                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2345                         parser->parser_error (@1, _ ("bad grob property path"));
2346                         l = SCM_UNDEFINED;
2347                 }
2348                 $$ = l;
2349         }
2350         ;
2351
2352 // If defined, at least three members
2353 grob_prop_path:
2354         grob_prop_spec
2355         {
2356                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2357                 {
2358                         parser->parser_error (@1, _ ("bad grob property path"));
2359                         $$ = SCM_UNDEFINED;
2360                 }
2361         }
2362         | grob_prop_spec property_path
2363         {
2364                 if (!SCM_UNBNDP ($1)) {
2365                         $$ = scm_append_x (scm_list_2 ($1, $2));
2366                         if (scm_is_null (scm_cddr ($$))) {
2367                                 parser->parser_error (@$, _ ("bad grob property path"));
2368                                 $$ = SCM_UNDEFINED;
2369                         }
2370                 }
2371
2372         }
2373         ;
2374
2375 // Exactly two elements or undefined
2376 context_prop_spec:
2377         symbol_list_rev
2378         {
2379                 SCM l = scm_reverse_x ($1, SCM_EOL);
2380                 switch (scm_ilength (l)) {
2381                 case 1:
2382                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2383                 case 2:
2384                         break;
2385                 default:
2386                         parser->parser_error (@1, _ ("bad context property path"));
2387                         l = SCM_UNDEFINED;
2388                 }
2389                 $$ = l;
2390         }
2391         ;
2392
2393 simple_music_property_def:
2394         OVERRIDE grob_prop_path '=' scalar {
2395                 if (SCM_UNBNDP ($2))
2396                         $$ = SCM_UNDEFINED;
2397                 else {
2398                         $$ = scm_list_5 (scm_car ($2),
2399                                          ly_symbol2scm ("OverrideProperty"),
2400                                          scm_cadr ($2),
2401                                          $4,
2402                                          scm_cddr ($2));
2403                 }
2404         }
2405         | REVERT simple_revert_context revert_arg {
2406                 $$ = scm_list_4 ($2,
2407                                  ly_symbol2scm ("RevertProperty"),
2408                                  scm_car ($3),
2409                                  scm_cdr ($3));
2410         }
2411         | SET context_prop_spec '=' scalar {
2412                 if (SCM_UNBNDP ($2))
2413                         $$ = SCM_UNDEFINED;
2414                 else
2415                         $$ = scm_list_4 (scm_car ($2),
2416                                          ly_symbol2scm ("PropertySet"),
2417                                          scm_cadr ($2),
2418                                          $4);
2419         }
2420         | UNSET context_prop_spec {
2421                 if (SCM_UNBNDP ($2))
2422                         $$ = SCM_UNDEFINED;
2423                 else
2424                         $$ = scm_list_3 (scm_car ($2),
2425                                          ly_symbol2scm ("PropertyUnset"),
2426                                          scm_cadr ($2));
2427         }
2428         ;
2429
2430
2431 // This is all quite awkward for the sake of substantial backward
2432 // compatibility while at the same time allowing a more "natural" form
2433 // of specification not separating grob specification from grob
2434 // property path.  The purpose of this definition of
2435 // simple_revert_context is to allow the symbol list which specifies
2436 // grob and property to revert to be optionally be split into two
2437 // parts after the grob (which may be preceded by a context
2438 // specification, a case which we distinguish by checking whether the
2439 // first symbol is a valid grob symbol instead).
2440 //
2441 // See revert_arg above for the main work horse of this arrangement.
2442 // simple_revert_context just caters for the context and delegates the
2443 // rest of the job to revert_arg.
2444
2445 simple_revert_context:
2446         symbol_list_part
2447         {
2448                 $1 = scm_reverse_x ($1, SCM_EOL);
2449                 if (scm_is_null ($1)
2450                     || to_boolean
2451                     (scm_object_property (scm_car ($1),
2452                                           ly_symbol2scm ("is-grob?")))) {
2453                         $$ = ly_symbol2scm ("Bottom");
2454                         parser->lexer_->push_extra_token (SCM_IDENTIFIER, $1);
2455                 } else {
2456                         $$ = scm_car ($1);
2457                         parser->lexer_->push_extra_token (SCM_IDENTIFIER,
2458                                                           scm_cdr ($1));
2459                 }
2460         }
2461         ;
2462
2463 music_property_def:
2464         simple_music_property_def {
2465                 if (SCM_UNBNDP ($1))
2466                         $$ = MAKE_SYNTAX ("void-music", @1);
2467                 else
2468                         $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), make_input (@$), $1));
2469         }
2470         ;
2471
2472 string:
2473         STRING {
2474                 $$ = $1;
2475         }
2476         | full_markup
2477         ;
2478
2479 simple_string: STRING {
2480                 $$ = $1;
2481         }
2482         | embedded_scm_bare
2483         {
2484                 if (scm_is_string ($1)) {
2485                         $$ = $1;
2486                 } else {
2487                         parser->parser_error (@1, (_ ("simple string expected")));
2488                         $$ = scm_string (SCM_EOL);
2489                 }
2490         }
2491         ;
2492
2493 symbol:
2494         STRING {
2495                 $$ = scm_string_to_symbol ($1);
2496         }
2497         | embedded_scm_bare
2498         {
2499                 // This is a bit of overkill but makes the same
2500                 // routine responsible for all symbol interpretations.
2501                 $$ = try_string_variants (ly_lily_module_constant ("symbol?"),
2502                                           $1);
2503                 if (SCM_UNBNDP ($$))
2504                 {
2505                         parser->parser_error (@1, (_ ("symbol expected")));
2506                         // Generate a unique symbol in case it is used
2507                         // for an assignment or similar
2508                         $$ = scm_make_symbol (ly_string2scm ("undefined"));
2509                 }
2510         }
2511         ;
2512
2513 scalar:
2514         embedded_scm_arg
2515         | SCM_IDENTIFIER
2516         | bare_number
2517         // The following is a rather defensive variant of admitting
2518         // negative numbers: the grammar would permit number_factor or
2519         // even number_expression.  However, function arguments allow
2520         // only this simple kind of negative number, so to have things
2521         // like \tweak and \override behave reasonably similar, it
2522         // makes sense to rule out things like -- which are rather an
2523         // accent in function argument contexts.
2524         | '-' bare_number
2525         {
2526                 $$ = scm_difference ($2, SCM_UNDEFINED);
2527         }
2528         | FRACTION
2529         | STRING
2530         | full_markup
2531         ;
2532
2533 event_chord:
2534         simple_element post_events {
2535                 // Let the rhythmic music iterator sort this mess out.
2536                 if (scm_is_pair ($2)) {
2537                         $$ = make_music_from_simple (parser, @1, $1);
2538                         if (unsmob_music ($$))
2539                                 unsmob_music ($$)->set_property ("articulations",
2540                                                                  scm_reverse_x ($2, SCM_EOL));
2541                         else
2542                         {
2543                                 parser->parser_error (@1, _("music expected"));
2544                                 $$ = MAKE_SYNTAX ("void-music", @1);
2545                         }
2546                 }
2547         } %prec ':'
2548         | simple_chord_elements post_events     {
2549                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
2550
2551                 Input i;
2552                 /* why is this giving wrong start location? -ns
2553                  * i = @$; */
2554                 i.set_location (@1, @2);
2555                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
2556         } %prec ':'
2557         | CHORD_REPETITION optional_notemode_duration post_events {
2558                 Input i;
2559                 i.set_location (@1, @3);
2560                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2561                                   $2, scm_reverse_x ($3, SCM_EOL));
2562         } %prec ':'
2563         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2564                 Input i;
2565                 i.set_location (@1, @3);
2566                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2567                                   scm_reverse_x ($3, SCM_EOL));
2568         } %prec ':'
2569         | command_element
2570         | note_chord_element
2571         ;
2572
2573
2574 note_chord_element:
2575         chord_body optional_notemode_duration post_events
2576         {
2577                 Music *m = unsmob_music ($1);
2578                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
2579                 SCM es = m->get_property ("elements");
2580                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2581
2582                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2583                   unsmob_music (scm_car (s))->set_property ("duration", dur);
2584                 es = ly_append2 (es, postevs);
2585
2586                 m-> set_property ("elements", es);
2587                 m->set_spot (@$);
2588                 $$ = m->self_scm ();
2589         } %prec ':'
2590         ;
2591
2592 chord_body:
2593         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2594         {
2595                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2596         }
2597         | CHORD_BODY_IDENTIFIER
2598         ;
2599
2600 chord_body_elements:
2601         /* empty */             { $$ = SCM_EOL; }
2602         | chord_body_elements chord_body_element {
2603                 if (!SCM_UNBNDP ($2))
2604                         $$ = scm_cons ($2, $1);
2605         }
2606         ;
2607
2608 chord_body_element:
2609         pitch exclamations questions octave_check post_events
2610         {
2611                 bool q = to_boolean ($3);
2612                 bool ex = to_boolean ($2);
2613                 SCM check = $4;
2614                 SCM post = $5;
2615
2616                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2617                 n->set_property ("pitch", $1);
2618                 if (q)
2619                         n->set_property ("cautionary", SCM_BOOL_T);
2620                 if (ex || q)
2621                         n->set_property ("force-accidental", SCM_BOOL_T);
2622
2623                 if (scm_is_pair (post)) {
2624                         SCM arts = scm_reverse_x (post, SCM_EOL);
2625                         n->set_property ("articulations", arts);
2626                 }
2627                 if (scm_is_number (check))
2628                 {
2629                         int q = scm_to_int (check);
2630                         n->set_property ("absolute-octave", scm_from_int (q-1));
2631                 }
2632
2633                 $$ = n->unprotect ();
2634         }
2635         | DRUM_PITCH post_events {
2636                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2637                 n->set_property ("drum-type", $1);
2638
2639                 if (scm_is_pair ($2)) {
2640                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2641                         n->set_property ("articulations", arts);
2642                 }
2643                 $$ = n->unprotect ();
2644         }
2645         | music_function_chord_body
2646         {
2647                 Music *m = unsmob_music ($1);
2648
2649                 while (m && m->is_mus_type ("music-wrapper-music")) {
2650                         $$ = m->get_property ("element");
2651                         m = unsmob_music ($$);
2652                 }
2653
2654                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2655                         parser->parser_error (@$, _ ("not a rhythmic event"));
2656                         $$ = SCM_UNDEFINED;
2657                 }
2658         }
2659         ;
2660
2661 music_function_chord_body:
2662         music_function_call
2663         | MUSIC_IDENTIFIER
2664         ;
2665
2666 // Event functions may only take closed arglists, otherwise it would
2667 // not be clear whether a following postevent should be associated
2668 // with the last argument of the event function or with the expression
2669 // for which the function call acts itself as event.
2670
2671 music_function_call_closed:
2672         MUSIC_FUNCTION function_arglist_closed {
2673                 $$ = MAKE_SYNTAX ("music-function", @$,
2674                                          $1, $2);
2675         }
2676         ;
2677
2678 event_function_event:
2679         EVENT_FUNCTION function_arglist_closed {
2680                 $$ = MAKE_SYNTAX ("music-function", @$,
2681                                          $1, $2);
2682         }
2683         ;
2684
2685 command_element:
2686         command_event {
2687                 $$ = $1;
2688         }
2689         ;
2690
2691 command_event:
2692         tempo_event {
2693                 $$ = $1;
2694         }
2695         ;
2696
2697
2698 post_events:
2699         /* empty */ {
2700                 $$ = SCM_EOL;
2701         }
2702         | post_events post_event {
2703                 $$ = $1;
2704                 if (Music *m = unsmob_music ($2))
2705                 {
2706                         if (m->is_mus_type ("post-event-wrapper"))
2707                         {
2708                                 for (SCM p = m->get_property ("elements");
2709                                      scm_is_pair (p);
2710                                      p = scm_cdr (p))
2711                                 {
2712                                         $$ = scm_cons (scm_car (p), $$);
2713                                 }
2714                         } else {
2715                                 m->set_spot (@2);
2716                                 $$ = scm_cons ($2, $$);
2717                         }
2718                 }
2719         }
2720         ;
2721
2722 post_event_nofinger:
2723         direction_less_event {
2724                 $$ = $1;
2725         }
2726         | script_dir music_function_call_closed {
2727                 $$ = $2;
2728                 if (!unsmob_music ($2)->is_mus_type ("post-event")) {
2729                         parser->parser_error (@2, _ ("post-event expected"));
2730                         $$ = SCM_UNSPECIFIED;
2731                 } else if (!SCM_UNBNDP ($1))
2732                 {
2733                         unsmob_music ($$)->set_property ("direction", $1);
2734                 }
2735         }
2736         | HYPHEN {
2737                 if (!parser->lexer_->is_lyric_state ())
2738                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2739                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2740         }
2741         | EXTENDER {
2742                 if (!parser->lexer_->is_lyric_state ())
2743                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2744                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2745         }
2746         | script_dir direction_reqd_event {
2747                 if (!SCM_UNBNDP ($1))
2748                 {
2749                         Music *m = unsmob_music ($2);
2750                         m->set_property ("direction", $1);
2751                 }
2752                 $$ = $2;
2753         }
2754         | script_dir direction_less_event {
2755                 if (!SCM_UNBNDP ($1))
2756                 {
2757                         Music *m = unsmob_music ($2);
2758                         m->set_property ("direction", $1);
2759                 }
2760                 $$ = $2;
2761         }
2762         | '^' fingering
2763         {
2764                 $$ = $2;
2765                 unsmob_music ($$)->set_property ("direction", scm_from_int (UP));
2766         }
2767         | '_' fingering
2768         {
2769                 $$ = $2;
2770                 unsmob_music ($$)->set_property ("direction", scm_from_int (DOWN));
2771         }
2772         ;
2773
2774 post_event:
2775         post_event_nofinger
2776         | '-' fingering {
2777                 $$ = $2;
2778         }
2779         ;
2780
2781 string_number_event:
2782         E_UNSIGNED {
2783                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2784                 s->set_property ("string-number", $1);
2785                 $$ = s->unprotect ();
2786         }
2787         ;
2788
2789 direction_less_event:
2790         string_number_event
2791         | EVENT_IDENTIFIER      {
2792                 $$ = $1;
2793         }
2794         | tremolo_type  {
2795                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2796                a->set_property ("tremolo-type", $1);
2797                $$ = a->unprotect ();
2798         }
2799         | event_function_event
2800         ;
2801
2802 direction_reqd_event:
2803         gen_text_def {
2804                 $$ = $1;
2805         }
2806         | script_abbreviation {
2807                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2808                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2809                 if (scm_is_string (s))
2810                         a->set_property ("articulation-type", s);
2811                 else parser->parser_error (@1, _ ("expecting string as script definition"));
2812                 $$ = a->unprotect ();
2813         }
2814         ;
2815
2816 octave_check:
2817         /**/ { $$ = SCM_EOL; }
2818         | '=' quotes { $$ = $2; }
2819         ;
2820
2821 quotes:
2822         /* empty */
2823         {
2824                 $$ = SCM_INUM0;
2825         }
2826         | sub_quotes
2827         | sup_quotes
2828         ;
2829
2830 sup_quotes:
2831         '\'' {
2832                 $$ = scm_from_int (1);
2833         }
2834         | sup_quotes '\'' {
2835                 $$ = scm_oneplus ($1);
2836         }
2837         ;
2838
2839 sub_quotes:
2840         ',' {
2841                 $$ = scm_from_int (-1);
2842         }
2843         | sub_quotes ',' {
2844                 $$ = scm_oneminus ($1);
2845         }
2846         ;
2847
2848 steno_pitch:
2849         NOTENAME_PITCH quotes {
2850                 if (!scm_is_eq (SCM_INUM0, $2))
2851                 {
2852                         Pitch p = *unsmob_pitch ($1);
2853                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2854                         $$ = p.smobbed_copy ();
2855                 }
2856         }
2857         ;
2858
2859 /*
2860 ugh. duplication
2861 */
2862
2863 steno_tonic_pitch:
2864         TONICNAME_PITCH quotes {
2865                 if (!scm_is_eq (SCM_INUM0, $2))
2866                 {
2867                         Pitch p = *unsmob_pitch ($1);
2868                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2869                         $$ = p.smobbed_copy ();
2870                 }
2871         }
2872         ;
2873
2874 pitch:
2875         steno_pitch
2876         | PITCH_IDENTIFIER
2877         ;
2878
2879 gen_text_def:
2880         full_markup {
2881                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2882                 t->set_property ("text", $1);
2883                 $$ = t->unprotect ();
2884         }
2885         | STRING {
2886                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2887                 t->set_property ("text",
2888                         make_simple_markup ($1));
2889                 $$ = t->unprotect ();
2890         }
2891         | embedded_scm_closed
2892         {
2893                 Music *m = unsmob_music ($1);
2894                 if (m && m->is_mus_type ("post-event"))
2895                         $$ = $1;
2896                 else if (Text_interface::is_markup ($1)) {
2897                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2898                         t->set_property ("text", $1);
2899                         $$ = t->unprotect ();
2900                 } else
2901                         parser->parser_error (@1, _ ("not an articulation"));
2902         }
2903         ;
2904
2905 fingering:
2906         UNSIGNED {
2907                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2908                 t->set_property ("digit", $1);
2909                 $$ = t->unprotect ();
2910         }
2911         ;
2912
2913 script_abbreviation:
2914         '^'             {
2915                 $$ = scm_from_locale_string ("Hat");
2916         }
2917         | '+'           {
2918                 $$ = scm_from_locale_string ("Plus");
2919         }
2920         | '-'           {
2921                 $$ = scm_from_locale_string ("Dash");
2922         }
2923         | '!'           {
2924                 $$ = scm_from_locale_string ("Bang");
2925         }
2926         | ANGLE_CLOSE   {
2927                 $$ = scm_from_locale_string ("Larger");
2928         }
2929         | '.'           {
2930                 $$ = scm_from_locale_string ("Dot");
2931         }
2932         | '_' {
2933                 $$ = scm_from_locale_string ("Underscore");
2934         }
2935         ;
2936
2937 script_dir:
2938         '_'     { $$ = scm_from_int (DOWN); }
2939         | '^'   { $$ = scm_from_int (UP); }
2940         | '-'   { $$ = SCM_UNDEFINED; }
2941         ;
2942
2943 duration_length:
2944         multiplied_duration {
2945                 $$ = $1;
2946         }
2947         ;
2948
2949 maybe_notemode_duration:
2950         {
2951                 $$ = SCM_UNDEFINED;
2952         } %prec ':'
2953         | multiplied_duration   {
2954                 $$ = $1;
2955                 parser->default_duration_ = *unsmob_duration ($$);
2956         }
2957 ;
2958
2959
2960 optional_notemode_duration:
2961         maybe_notemode_duration
2962         {
2963                 if (SCM_UNBNDP ($$))
2964                         $$ = parser->default_duration_.smobbed_copy ();
2965         }
2966         ;
2967
2968 steno_duration:
2969         UNSIGNED dots           {
2970                 $$ = make_duration ($1, scm_to_int ($2));
2971                 if (SCM_UNBNDP ($$))
2972                 {
2973                         parser->parser_error (@1, _ ("not a duration"));
2974                         $$ = Duration ().smobbed_copy ();
2975                 }
2976         }
2977         | DURATION_IDENTIFIER dots      {
2978                 Duration *d = unsmob_duration ($1);
2979                 Duration k (d->duration_log (),
2980                             d->dot_count () + scm_to_int ($2));
2981                 k = k.compressed (d->factor ());
2982                 scm_remember_upto_here_1 ($1);
2983                 $$ = k.smobbed_copy ();
2984         }
2985         ;
2986
2987 multiplied_duration:
2988         steno_duration {
2989                 $$ = $1;
2990         }
2991         | multiplied_duration '*' UNSIGNED {
2992                 $$ = unsmob_duration ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
2993         }
2994         | multiplied_duration '*' FRACTION {
2995                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2996
2997                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2998         }
2999         ;
3000
3001 dots:
3002         /* empty */     {
3003                 $$ = SCM_INUM0;
3004         }
3005         | dots '.' {
3006                 $$ = scm_oneplus ($1);
3007         }
3008         ;
3009
3010 tremolo_type:
3011         ':'     {
3012                 $$ = SCM_INUM0;
3013         }
3014         | ':' UNSIGNED {
3015                 if (SCM_UNBNDP (make_duration ($2)))
3016                         parser->parser_error (@2, _ ("not a duration"));
3017                 $$ = $2;
3018         }
3019         ;
3020
3021 bass_number:
3022         UNSIGNED { $$ = $1; }
3023         | STRING { $$ = $1; }
3024         | full_markup { $$ = $1; }
3025         | embedded_scm_bare
3026         {
3027                 // as an integer, it needs to be non-negative, and otherwise
3028                 // it needs to be suitable as a markup.
3029                 if (scm_is_integer ($1)
3030                     ? scm_is_true (scm_negative_p ($1))
3031                     : !Text_interface::is_markup ($1))
3032                 {
3033                         parser->parser_error (@1, _ ("bass number expected"));
3034                         $$ = SCM_INUM0;
3035                 }
3036         }
3037         ;
3038
3039 figured_bass_alteration:
3040         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
3041         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
3042         | '!'   { $$ = scm_from_int (0); }
3043         ;
3044
3045 bass_figure:
3046         FIGURE_SPACE {
3047                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3048                 $$ = bfr->unprotect ();
3049         }
3050         | bass_number  {
3051                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
3052                 $$ = bfr->self_scm ();
3053
3054                 if (scm_is_number ($1))
3055                         bfr->set_property ("figure", $1);
3056                 else if (Text_interface::is_markup ($1))
3057                         bfr->set_property ("text", $1);
3058
3059                 bfr->unprotect ();
3060         }
3061         | bass_figure ']' {
3062                 $$ = $1;
3063                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
3064         }
3065         | bass_figure figured_bass_alteration {
3066                 Music *m = unsmob_music ($1);
3067                 if (scm_to_double ($2)) {
3068                         SCM salter = m->get_property ("alteration");
3069                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
3070                         m->set_property ("alteration",
3071                                          scm_sum (alter, $2));
3072                 } else {
3073                         m->set_property ("alteration", scm_from_int (0));
3074                 }
3075         }
3076         | bass_figure figured_bass_modification  {
3077                 Music *m = unsmob_music ($1);
3078                 m->set_property ($2, SCM_BOOL_T);
3079         }
3080         ;
3081
3082
3083 figured_bass_modification:
3084         E_PLUS          {
3085                 $$ = ly_symbol2scm ("augmented");
3086         }
3087         | E_EXCLAMATION {
3088                 $$ = ly_symbol2scm ("no-continuation");
3089         }
3090         | '/'           {
3091                 $$ = ly_symbol2scm ("diminished");
3092         }
3093         | E_BACKSLASH {
3094                 $$ = ly_symbol2scm ("augmented-slash");
3095         }
3096         ;
3097
3098 br_bass_figure:
3099         bass_figure {
3100                 $$ = $1;
3101         }
3102         | '[' bass_figure {
3103                 $$ = $2;
3104                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
3105         }
3106         ;
3107
3108 figure_list:
3109         /**/            {
3110                 $$ = SCM_EOL;
3111         }
3112         | figure_list br_bass_figure {
3113                 $$ = scm_cons ($2, $1);
3114         }
3115         ;
3116
3117 figure_spec:
3118         FIGURE_OPEN figure_list FIGURE_CLOSE {
3119                 $$ = scm_reverse_x ($2, SCM_EOL);
3120         }
3121         ;
3122
3123
3124 optional_rest:
3125         /**/   { $$ = SCM_BOOL_F; }
3126         | REST { $$ = SCM_BOOL_T; }
3127         ;
3128
3129 simple_element:
3130         pitch exclamations questions octave_check maybe_notemode_duration optional_rest {
3131                 if (!parser->lexer_->is_note_state ())
3132                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
3133                 if (!SCM_UNBNDP ($2)
3134                     || !SCM_UNBNDP ($3)
3135                     || scm_is_number ($4)
3136                     || !SCM_UNBNDP ($5)
3137                     || scm_is_true ($6))
3138                 {
3139                         Music *n = 0;
3140                         if (scm_is_true ($6))
3141                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
3142                         else
3143                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
3144
3145                         n->set_property ("pitch", $1);
3146                         if (SCM_UNBNDP ($5))
3147                                 n->set_property ("duration",
3148                                                  parser->default_duration_.smobbed_copy ());
3149                         else
3150                                 n->set_property ("duration", $5);
3151
3152                         if (scm_is_number ($4))
3153                         {
3154                                 int q = scm_to_int ($4);
3155                                 n->set_property ("absolute-octave", scm_from_int (q-1));
3156                         }
3157
3158                         if (to_boolean ($3))
3159                                 n->set_property ("cautionary", SCM_BOOL_T);
3160                         if (to_boolean ($2) || to_boolean ($3))
3161                                 n->set_property ("force-accidental", SCM_BOOL_T);
3162
3163                         $$ = n->unprotect ();
3164                 }
3165         }
3166         | DRUM_PITCH optional_notemode_duration {
3167                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
3168                 n->set_property ("duration", $2);
3169                 n->set_property ("drum-type", $1);
3170
3171                 $$ = n->unprotect ();
3172         }
3173         | RESTNAME optional_notemode_duration           {
3174                 Music *ev = 0;
3175                 if (ly_scm2string ($1) == "s") {
3176                         /* Space */
3177                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
3178                   }
3179                 else {
3180                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
3181
3182                     }
3183                 ev->set_property ("duration", $2);
3184                 $$ = ev->unprotect ();
3185         }
3186         ;
3187
3188 simple_chord_elements:
3189         new_chord {
3190                 if (!parser->lexer_->is_chord_state ())
3191                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
3192                 $$ = $1;
3193         }
3194         | figure_spec optional_notemode_duration {
3195                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
3196                 {
3197                         unsmob_music (scm_car (s))->set_property ("duration", $2);
3198                 }
3199                 $$ = $1;
3200         }
3201         ;
3202
3203 lyric_element:
3204         full_markup {
3205                 if (!parser->lexer_->is_lyric_state ())
3206                         parser->parser_error (@1, _ ("markup outside of text script or \\lyricmode"));
3207                 $$ = $1;
3208         }
3209         | STRING {
3210                 if (!parser->lexer_->is_lyric_state ())
3211                         parser->parser_error (@1, _ ("unrecognized string, not in text script or \\lyricmode"));
3212                 $$ = $1;
3213         }
3214         | LYRIC_ELEMENT
3215         ;
3216
3217 lyric_element_music:
3218         lyric_element optional_notemode_duration post_events {
3219                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3220                 if (scm_is_pair ($3))
3221                         unsmob_music ($$)->set_property
3222                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3223         } %prec ':'
3224         ;
3225
3226 new_chord:
3227         steno_tonic_pitch optional_notemode_duration   {
3228                 $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3229         }
3230         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3231                 SCM its = scm_reverse_x ($4, SCM_EOL);
3232                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3233         } %prec ':'
3234         ;
3235
3236 chord_items:
3237         /**/ {
3238                 $$ = SCM_EOL;
3239         }
3240         | chord_items chord_item {
3241                 $$ = scm_cons ($2, $$);
3242         }
3243         ;
3244
3245 chord_separator:
3246         CHORD_COLON {
3247                 $$ = ly_symbol2scm ("chord-colon");
3248         }
3249         | CHORD_CARET {
3250                 $$ = ly_symbol2scm ("chord-caret");
3251         }
3252         | CHORD_SLASH steno_tonic_pitch {
3253                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3254         }
3255         | CHORD_BASS steno_tonic_pitch {
3256                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3257         }
3258         ;
3259
3260 chord_item:
3261         chord_separator {
3262                 $$ = $1;
3263         }
3264         | step_numbers {
3265                 $$ = scm_reverse_x ($1, SCM_EOL);
3266         }
3267         | CHORD_MODIFIER  {
3268                 $$ = $1;
3269         }
3270         ;
3271
3272 step_numbers:
3273         step_number { $$ = scm_cons ($1, SCM_EOL); }
3274         | step_numbers '.' step_number {
3275                 $$ = scm_cons ($3, $$);
3276         }
3277         ;
3278
3279 step_number:
3280         UNSIGNED {
3281                 $$ = make_chord_step ($1, 0);
3282         }
3283         | UNSIGNED '+' {
3284                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3285         }
3286         | UNSIGNED CHORD_MINUS {
3287                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3288         }
3289         ;
3290
3291 tempo_range:
3292         UNSIGNED {
3293                 $$ = $1;
3294         }
3295         | UNSIGNED '-' UNSIGNED {
3296                 $$ = scm_cons ($1, $3);
3297         }
3298         ;
3299
3300 /*
3301         UTILITIES
3302
3303 TODO: should deprecate in favor of Scheme?
3304
3305  */
3306 number_expression:
3307         number_expression '+' number_term {
3308                 $$ = scm_sum ($1, $3);
3309         }
3310         | number_expression '-' number_term {
3311                 $$ = scm_difference ($1, $3);
3312         }
3313         | number_term
3314         ;
3315
3316 number_term:
3317         number_factor {
3318                 $$ = $1;
3319         }
3320         | number_factor '*' number_factor {
3321                 $$ = scm_product ($1, $3);
3322         }
3323         | number_factor '/' number_factor {
3324                 $$ = scm_divide ($1, $3);
3325         }
3326         ;
3327
3328 number_factor:
3329         '-'  number_factor { /* %prec UNARY_MINUS */
3330                 $$ = scm_difference ($2, SCM_UNDEFINED);
3331         }
3332         | bare_number
3333         ;
3334
3335 bare_number_common:
3336         bare_number_common_closed
3337         | REAL NUMBER_IDENTIFIER
3338         {
3339                 $$ = scm_product ($1, $2);
3340         }
3341         ;
3342
3343 bare_number_common_closed:
3344         REAL
3345         | NUMBER_IDENTIFIER
3346         ;
3347
3348 bare_number:
3349         bare_number_common
3350         | UNSIGNED
3351         | UNSIGNED NUMBER_IDENTIFIER    {
3352                 $$ = scm_product ($1, $2);
3353         }
3354         ;
3355
3356 bare_number_closed:
3357         UNSIGNED
3358         | bare_number_common_closed
3359         ;
3360
3361 unsigned_number:
3362         UNSIGNED
3363         | NUMBER_IDENTIFIER
3364         ;
3365
3366 exclamations:
3367                 { $$ = SCM_UNDEFINED; }
3368         | exclamations '!'
3369         {
3370                 if (SCM_UNBNDP ($1))
3371                         $$ = SCM_BOOL_T;
3372                 else
3373                         $$ = scm_not ($1);
3374         }
3375         ;
3376
3377 questions:
3378         { $$ = SCM_UNDEFINED; }
3379         | questions '?'
3380         {
3381                 if (SCM_UNBNDP ($1))
3382                         $$ = SCM_BOOL_T;
3383                 else
3384                         $$ = scm_not ($1);
3385         }
3386         ;
3387
3388 full_markup_list:
3389         MARKUPLIST
3390                 { parser->lexer_->push_markup_state (); }
3391         markup_list {
3392                 $$ = $3;
3393                 parser->lexer_->pop_state ();
3394         }
3395         ;
3396
3397 full_markup:
3398         MARKUP
3399                 { parser->lexer_->push_markup_state (); }
3400         markup_top {
3401                 $$ = $3;
3402                 parser->lexer_->pop_state ();
3403         }
3404         ;
3405
3406 markup_top:
3407         markup_list {
3408                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3409         }
3410         | markup_head_1_list simple_markup
3411         {
3412                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3413                                            @2, $1, scm_list_1 ($2)));
3414         }
3415         | simple_markup {
3416                 $$ = $1;
3417         }
3418         ;
3419
3420 markup_scm:
3421         embedded_scm_bare
3422         {
3423                 if (Text_interface::is_markup ($1))
3424                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3425                 else if (Text_interface::is_markup_list ($1))
3426                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3427                 else {
3428                         parser->parser_error (@1, _ ("not a markup"));
3429                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3430                 }
3431         } BACKUP
3432         ;
3433
3434
3435 markup_list:
3436         markup_composed_list {
3437                 $$ = $1;
3438         }
3439         | markup_uncomposed_list
3440         ;
3441
3442 markup_uncomposed_list:
3443         markup_braced_list {
3444                 $$ = $1;
3445         }
3446         | markup_command_list {
3447                 $$ = scm_list_1 ($1);
3448         }
3449         | markup_scm MARKUPLIST_IDENTIFIER
3450         {
3451                 $$ = $2;
3452         }
3453         | SCORELINES {
3454                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3455                 parser->lexer_->push_note_state (nn);
3456         } '{' score_body '}' {
3457                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $4));
3458                 parser->lexer_->pop_state ();
3459         }
3460         ;
3461
3462 markup_composed_list:
3463         markup_head_1_list markup_uncomposed_list {
3464                 $$ = MAKE_SYNTAX ("composed-markup-list",
3465                                   @2, $1, $2);
3466         }
3467         ;
3468
3469 markup_braced_list:
3470         '{' markup_braced_list_body '}' {
3471                 $$ = scm_reverse_x ($2, SCM_EOL);
3472         }
3473         ;
3474
3475 markup_braced_list_body:
3476         /* empty */     {  $$ = SCM_EOL; }
3477         | markup_braced_list_body markup {
3478                 $$ = scm_cons ($2, $1);
3479         }
3480         | markup_braced_list_body markup_list {
3481                 $$ = scm_reverse_x ($2, $1);
3482         }
3483         ;
3484
3485 markup_command_list:
3486         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3487           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3488         }
3489         ;
3490
3491 markup_command_basic_arguments:
3492         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3493           $$ = scm_cons ($3, $2);
3494         }
3495         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
3496           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3497         }
3498         | EXPECT_NO_MORE_ARGS {
3499           $$ = SCM_EOL;
3500         }
3501         ;
3502
3503 markup_command_list_arguments:
3504         markup_command_basic_arguments { $$ = $1; }
3505         | EXPECT_MARKUP markup_command_list_arguments markup {
3506           $$ = scm_cons ($3, $2);
3507         }
3508         ;
3509
3510 markup_head_1_item:
3511         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3512           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3513         }
3514         ;
3515
3516 markup_head_1_list:
3517         markup_head_1_item      {
3518                 $$ = scm_list_1 ($1);
3519         }
3520         | markup_head_1_list markup_head_1_item {
3521                 $$ = scm_cons ($2, $1);
3522         }
3523         ;
3524
3525 simple_markup:
3526         STRING {
3527                 $$ = make_simple_markup ($1);
3528         }
3529         | SCORE {
3530                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3531                 parser->lexer_->push_note_state (nn);
3532         } '{' score_body '}' {
3533                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $4);
3534                 parser->lexer_->pop_state ();
3535         }
3536         | MARKUP_FUNCTION markup_command_basic_arguments {
3537                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3538         }
3539         | markup_scm MARKUP_IDENTIFIER
3540         {
3541                 $$ = $2;
3542         }
3543         ;
3544
3545 markup:
3546         markup_head_1_list simple_markup
3547         {
3548                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3549                                            @2, $1, scm_list_1 ($2)));
3550         }
3551         | simple_markup {
3552                 $$ = $1;
3553         }
3554         ;
3555
3556 %%
3557
3558 void
3559 Lily_parser::set_yydebug (bool x)
3560 {
3561         yydebug = x;
3562 }
3563
3564 SCM
3565 Lily_parser::do_yyparse ()
3566 {
3567         SCM retval = SCM_UNDEFINED;
3568         yyparse (this, &retval);
3569         return retval;
3570 }
3571
3572
3573
3574
3575
3576 /*
3577
3578 It is a little strange to have this function in this file, but
3579 otherwise, we have to import music classes into the lexer.
3580
3581 */
3582 int
3583 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3584 {
3585         if (unsmob_book (sid)) {
3586                 Book *book =  unsmob_book (sid)->clone ();
3587                 *destination = book->self_scm ();
3588                 book->unprotect ();
3589
3590                 return BOOK_IDENTIFIER;
3591         } else if (scm_is_number (sid)) {
3592                 *destination = sid;
3593                 return NUMBER_IDENTIFIER;
3594         } else if (unsmob_context_def (sid)) {
3595                 Context_def *def= unsmob_context_def (sid)->clone ();
3596
3597                 *destination = def->self_scm ();
3598                 def->unprotect ();
3599
3600                 return CONTEXT_DEF_IDENTIFIER;
3601         } else if (unsmob_context_mod (sid)) {
3602                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
3603
3604                 return CONTEXT_MOD_IDENTIFIER;
3605         } else if (Music *mus = unsmob_music (sid)) {
3606                 mus = mus->clone ();
3607                 *destination = mus->self_scm ();
3608                 bool is_event = mus->is_mus_type ("post-event");
3609                 mus->unprotect ();
3610                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3611         } else if (unsmob_pitch (sid)) {
3612                 *destination = unsmob_pitch (sid)->smobbed_copy ();
3613                 return PITCH_IDENTIFIER;
3614         } else if (unsmob_duration (sid)) {
3615                 *destination = unsmob_duration (sid)->smobbed_copy ();
3616                 return DURATION_IDENTIFIER;
3617         } else if (unsmob_output_def (sid)) {
3618                 Output_def *p = unsmob_output_def (sid);
3619                 p = p->clone ();
3620
3621                 *destination = p->self_scm ();
3622                 p->unprotect ();
3623                 return OUTPUT_DEF_IDENTIFIER;
3624         }
3625
3626         return -1;
3627 }
3628
3629 SCM
3630 get_next_unique_context_id ()
3631 {
3632         return scm_from_locale_string ("$uniqueContextId");
3633 }
3634
3635
3636 SCM
3637 get_next_unique_lyrics_context_id ()
3638 {
3639         static int new_context_count;
3640         char s[128];
3641         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3642         return scm_from_locale_string (s);
3643 }
3644
3645 // check_scheme_arg checks one argument with a given predicate for use
3646 // in an argument list and throws a syntax error if it is unusable.
3647 // The argument is prepended to the argument list in any case.  After
3648 // throwing a syntax error, the argument list is terminated with #f as
3649 // its last cdr in order to mark it as uncallable while not losing
3650 // track of its total length.
3651 //
3652 // There are a few special considerations: if optional argument disp
3653 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3654 // instead of arg in a prospective error message.  This is useful if
3655 // arg is not the actual argument but rather a transformation of it.
3656 //
3657 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3658 // and an error message using disp is produced unconditionally.
3659
3660 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3661                       SCM arg, SCM args, SCM pred, SCM disp)
3662 {
3663         if (SCM_UNBNDP (arg))
3664                 args = scm_cons (disp, args);
3665         else {
3666                 args = scm_cons (arg, args);
3667                 if (scm_is_true (scm_call_1 (pred, arg)))
3668                         return args;
3669         }
3670         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3671         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3672                      SCM_UNBNDP (disp) ? arg : disp);
3673         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3674         return args;
3675 }
3676
3677 SCM loc_on_music (Input loc, SCM arg)
3678 {
3679         if (Music *m = unsmob_music (arg))
3680         {
3681                 m = m->clone ();
3682                 m->set_spot (loc);
3683                 return m->unprotect ();
3684         }
3685         return arg;
3686 }
3687
3688 SCM
3689 try_string_variants (SCM pred, SCM str)
3690 {
3691         // a matching predicate is always ok
3692         if (scm_is_true (scm_call_1 (pred, str)))
3693                 return str;
3694         // a symbol may be interpreted as a list of symbols if it helps
3695         if (scm_is_symbol (str)) {
3696                 str = scm_list_1 (str);
3697                 if (scm_is_true (scm_call_1 (pred, str)))
3698                         return str;
3699                 return SCM_UNDEFINED;
3700         }
3701
3702         // If this cannot be a string representation of a symbol list,
3703         // we are through.
3704
3705         if (!is_regular_identifier (str, true))
3706                 return SCM_UNDEFINED;
3707
3708         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3709         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3710                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3711
3712         // Let's attempt the symbol list interpretation first.
3713
3714         if (scm_is_true (scm_call_1 (pred, str)))
3715                 return str;
3716
3717         // If there is just one symbol in the list, we might interpret
3718         // it as a single symbol
3719
3720         if (scm_is_null (scm_cdr (str)))
3721         {
3722                 str = scm_car (str);
3723                 if (scm_is_true (scm_call_1 (pred, str)))
3724                         return str;
3725         }
3726
3727         return SCM_UNDEFINED;
3728 }
3729
3730 bool
3731 is_regular_identifier (SCM id, bool multiple)
3732 {
3733   if (!scm_is_string (id))
3734           return false;
3735
3736   string str = ly_scm2string (id);
3737
3738   bool middle = false;
3739
3740   for (string::iterator it=str.begin(); it != str.end (); it++)
3741   {
3742           int c = *it & 0xff;
3743           if ((c >= 'a' && c <= 'z')
3744               || (c >= 'A' && c <= 'Z')
3745               || c > 0x7f)
3746                   middle = true;
3747           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3748                   middle = false;
3749           else
3750                   return false;
3751   }
3752   return middle;
3753 }
3754
3755 SCM
3756 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3757 {
3758         if (unsmob_music (simple))
3759                 return simple;
3760         if (parser->lexer_->is_note_state ()) {
3761                 if (scm_is_symbol (simple)) {
3762                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3763                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3764                         n->set_property ("drum-type", simple);
3765                         return n->unprotect ();
3766                 }
3767                 if (unsmob_pitch (simple)) {
3768                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3769                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3770                         n->set_property ("pitch", simple);
3771                         return n->unprotect ();
3772                 }
3773                 return simple;
3774         } else if (parser->lexer_->is_lyric_state ()) {
3775                 if (Text_interface::is_markup (simple))
3776                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3777                                             parser->default_duration_.smobbed_copy ());
3778         } else if (parser->lexer_->is_chord_state ()) {
3779                 if (unsmob_pitch (simple))
3780                         return make_chord_elements (loc, simple,
3781                                                     parser->default_duration_.smobbed_copy (),
3782                                                     SCM_EOL);
3783         }
3784         return simple;
3785 }
3786
3787 Music *
3788 make_music_with_input (SCM name, Input where)
3789 {
3790        Music *m = make_music_by_name (name);
3791        m->set_spot (where);
3792        return m;
3793 }
3794
3795 SCM
3796 make_simple_markup (SCM a)
3797 {
3798         return a;
3799 }
3800
3801 SCM
3802 make_duration (SCM d, int dots)
3803 {
3804         int t = scm_to_int (d);
3805         if (t > 0 && (t & (t-1)) == 0)
3806                 return Duration (intlog2 (t), dots).smobbed_copy ();
3807         else
3808                 return SCM_UNDEFINED;
3809 }
3810
3811 SCM
3812 make_chord_step (SCM step_scm, Rational alter)
3813 {
3814         int step = scm_to_int (step_scm);
3815
3816         if (step == 7)
3817                 alter += FLAT_ALTERATION;
3818
3819         while (step < 0)
3820                 step += 7;
3821         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3822         return m.smobbed_copy ();
3823 }
3824
3825
3826 SCM
3827 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3828 {
3829         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3830         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3831         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3832         {
3833                 unsmob_music (scm_car (s))->set_spot (loc);
3834         }
3835         return res;
3836 }
3837
3838 int
3839 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3840 {
3841         Lily_lexer *lex = parser->lexer_;
3842
3843         lex->lexval_ = s;
3844         lex->lexloc_ = loc;
3845         lex->prepare_for_next_token ();
3846         return lex->yylex ();
3847 }