lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_TOP
  44 %left ADDLYRICS
  45 %left PREC_BOT
  46
  47 %expect 1
  48
  49 /* One shift/reduce problem
  50
  51 1.  \repeat
  52         \repeat .. \alternative
  53
  54     \repeat { \repeat .. \alternative }
  55
  56 or
  57
  58     \repeat { \repeat } \alternative
  59 */
  60
  61
  62 %pure_parser
  63 %locations
  64
  65
  66
  67 %{ // -*-Fundamental-*-
  68
  69 /*
  70 FIXME:
  71
  72    * The rules for who is protecting what are very shady.  Uniformise
  73      this.
  74
  75    * There are too many lexical modes?
  76 */
  77
  78 #include "config.hh"
  79
  80 #include <cctype>
  81 #include <cstdlib>
  82 #include <cstdio>
  83 using namespace std;
  84
  85 #include "book.hh"
  86 #include "context-def.hh"
  87 #include "context-mod.hh"
  88 #include "dimensions.hh"
  89 #include "file-path.hh"
  90 #include "input.hh"
  91 #include "international.hh"
  92 #include "lily-guile.hh"
  93 #include "lily-lexer.hh"
  94 #include "lily-parser.hh"
  95 #include "main.hh"
  96 #include "misc.hh"
  97 #include "music.hh"
  98 #include "music.hh"
  99 #include "output-def.hh"
 100 #include "paper-book.hh"
 101 #include "program-option.hh"
 102 #include "scm-hash.hh"
 103 #include "score.hh"
 104 #include "text-interface.hh"
 105 #include "warn.hh"
 106
 107 %}
 108
 109
 110 %union {
 111         Book *book;
 112         Output_def *outputdef;
 113         SCM scm;
 114         std::string *string;
 115         Music *music;
 116         Score *score;
 117         int i;
 118 }
 119
 120 %{
 121
 122 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 123
 124 /* ES TODO:
 125 - Don't use lily module, create a new module instead.
 126 - delay application of the function
 127 */
 128 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 129   scm_apply_0 (proc, args)
 130 /* Syntactic Sugar. */
 131 #define MAKE_SYNTAX(name, location, ...)        \
 132   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), __VA_ARGS__, SCM_UNDEFINED));
 133
 134 SCM get_next_unique_context_id ();
 135 SCM get_next_unique_lyrics_context_id ();
 136
 137 #undef _
 138 #if !HAVE_GETTEXT
 139 #define _(x) x
 140 #else
 141 #include <libintl.h>
 142 #define _(x) gettext (x)
 143 #endif
 144
 145
 146 static Music *make_music_with_input (SCM name, Input where);
 147 SCM make_music_relative (Pitch start, SCM music, Input loc);
 148 SCM run_music_function (Lily_parser *parser, Input loc, SCM func, SCM args);
 149 SCM get_first_context_id (SCM type, Music *m);
 150 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 151 SCM make_chord_step (int step, Rational alter);
 152 SCM make_simple_markup (SCM a);
 153 bool is_duration (int t);
 154 bool is_regular_identifier (SCM id);
 155 bool ly_input_procedure_p (SCM x);
 156 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 157 void set_music_properties (Music *p, SCM a);
 158
 159 %}
 160
 161 /* The third option is an alias that will be used to display the
 162    syntax error.  Bison CVS now correctly handles backslash escapes.
 163
 164    FIXME: Bison needs to translate some of these, eg, STRING.
 165
 166 */
 167
 168 /* Keyword tokens with plain escaped name.  */
 169 %token ACCEPTS "\\accepts"
 170 %token ADDLYRICS "\\addlyrics"
 171 %token ALIAS "\\alias"
 172 %token ALTERNATIVE "\\alternative"
 173 %token BOOK "\\book"
 174 %token BOOKPART "\\bookpart"
 175 %token CHANGE "\\change"
 176 %token CHORDMODE "\\chordmode"
 177 %token CHORDS "\\chords"
 178 %token CONSISTS "\\consists"
 179 %token CONTEXT "\\context"
 180 %token DEFAULT "\\default"
 181 %token DEFAULTCHILD "\\defaultchild"
 182 %token DENIES "\\denies"
 183 %token DESCRIPTION "\\description"
 184 %token DRUMMODE "\\drummode"
 185 %token DRUMS "\\drums"
 186 %token FIGUREMODE "\\figuremode"
 187 %token FIGURES "\\figures"
 188 %token GROBDESCRIPTIONS "\\grobdescriptions"
 189 %token HEADER "\\header"
 190 %token INVALID "\\version-error"
 191 %token KEY "\\key"
 192 %token LAYOUT "\\layout"
 193 %token LYRICMODE "\\lyricmode"
 194 %token LYRICS "\\lyrics"
 195 %token LYRICSTO "\\lyricsto"
 196 %token MARK "\\mark"
 197 %token MARKUP "\\markup"
 198 %token MARKUPLINES "\\markuplines"
 199 %token MIDI "\\midi"
 200 %token NAME "\\name"
 201 %token NOTEMODE "\\notemode"
 202 %token ONCE "\\once"
 203 %token OVERRIDE "\\override"
 204 %token PAPER "\\paper"
 205 %token PARTIAL "\\partial"
 206 %token RELATIVE "\\relative"
 207 %token REMOVE "\\remove"
 208 %token REPEAT "\\repeat"
 209 %token REST "\\rest"
 210 %token REVERT "\\revert"
 211 %token SCORE "\\score"
 212 %token SEQUENTIAL "\\sequential"
 213 %token SET "\\set"
 214 %token SIMULTANEOUS "\\simultaneous"
 215 %token SKIP "\\skip"
 216 %token TEMPO "\\tempo"
 217 %token TIMES "\\times"
 218 %token TYPE "\\type"
 219 %token UNSET "\\unset"
 220 %token WITH "\\with"
 221
 222 /* Keyword token exceptions.  */
 223 %token TIME_T "\\time"
 224 %token NEWCONTEXT "\\new"
 225
 226
 227 /* Other string tokens.  */
 228
 229 %token CHORD_BASS "/+"
 230 %token CHORD_CARET "^"
 231 %token CHORD_COLON ":"
 232 %token CHORD_MINUS "-"
 233 %token CHORD_SLASH "/"
 234 %token ANGLE_OPEN "<"
 235 %token ANGLE_CLOSE ">"
 236 %token DOUBLE_ANGLE_OPEN "<<"
 237 %token DOUBLE_ANGLE_CLOSE ">>"
 238 %token E_BACKSLASH "\\"
 239 %token E_ANGLE_CLOSE "\\>"
 240 %token E_CHAR "\\C[haracter]"
 241 %token E_CLOSE "\\)"
 242 %token E_EXCLAMATION "\\!"
 243 %token E_BRACKET_OPEN "\\["
 244 %token E_OPEN "\\("
 245 %token E_BRACKET_CLOSE "\\]"
 246 %token E_ANGLE_OPEN "\\<"
 247 %token E_PLUS "\\+"
 248 %token E_TILDE "\\~"
 249 %token EXTENDER "__"
 250
 251 /*
 252 If we give names, Bison complains.
 253 */
 254 %token FIGURE_CLOSE /* "\\>" */
 255 %token FIGURE_OPEN /* "\\<" */
 256 %token FIGURE_SPACE "_"
 257 %token HYPHEN "--"
 258
 259 %token CHORDMODIFIERS
 260 %token LYRIC_MARKUP
 261 %token MULTI_MEASURE_REST
 262
 263
 264 %token <i> E_UNSIGNED
 265 %token <i> UNSIGNED
 266
 267 /* Artificial tokens, for more generic function syntax */
 268 %token <i> EXPECT_MARKUP "markup?"
 269 %token <i> EXPECT_MUSIC "ly:music?"
 270 %token <i> EXPECT_PITCH "ly:pitch?"
 271 %token <i> EXPECT_DURATION "ly:duration?"
 272 %token <i> EXPECT_SCM "scheme?"
 273 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 274 /* After the last argument. */
 275 %token <i> EXPECT_NO_MORE_ARGS;
 276
 277 /* An artificial token for parsing embedded Lilypond */
 278 %token <i> EMBEDDED_LILY "#{"
 279
 280 %token <scm> BOOK_IDENTIFIER
 281 %token <scm> CHORDMODIFIER_PITCH
 282 %token <scm> CHORD_MODIFIER
 283 %token <scm> CHORD_REPETITION
 284 %token <scm> CONTEXT_DEF_IDENTIFIER
 285 %token <scm> CONTEXT_MOD_IDENTIFIER
 286 %token <scm> DRUM_PITCH
 287 %token <scm> DURATION_IDENTIFIER
 288 %token <scm> EVENT_IDENTIFIER
 289 %token <scm> FRACTION
 290 %token <scm> LYRICS_STRING
 291 %token <scm> LYRIC_MARKUP_IDENTIFIER
 292 %token <scm> MARKUP_FUNCTION
 293 %token <scm> MARKUP_LIST_FUNCTION
 294 %token <scm> MARKUP_IDENTIFIER
 295 %token <scm> MARKUPLINES_IDENTIFIER
 296 %token <scm> MUSIC_FUNCTION
 297 %token <scm> MUSIC_IDENTIFIER
 298 %token <scm> NOTENAME_PITCH
 299 %token <scm> NUMBER_IDENTIFIER
 300 %token <scm> OUTPUT_DEF_IDENTIFIER
 301 %token <scm> REAL
 302 %token <scm> RESTNAME
 303 %token <scm> SCM_FUNCTION
 304 %token <scm> SCM_IDENTIFIER
 305 %token <scm> SCM_TOKEN
 306 %token <scm> SCORE_IDENTIFIER
 307 %token <scm> STRING
 308 %token <scm> STRING_IDENTIFIER
 309 %token <scm> TONICNAME_PITCH
 310
 311
 312 %type <book> book_block
 313 %type <book> book_body
 314 %type <book> bookpart_block
 315 %type <book> bookpart_body
 316
 317 %type <i> bare_unsigned
 318 %type <scm> figured_bass_alteration
 319 %type <i> dots
 320 %type <i> exclamations
 321 %type <i> optional_rest
 322 %type <i> questions
 323 %type <i> script_dir
 324 %type <i> sub_quotes
 325 %type <i> sup_quotes
 326 %type <i> tremolo_type
 327
 328 /* Music */
 329 %type <scm> composite_music
 330 %type <scm> grouped_music_list
 331 %type <scm> closed_music
 332 %type <scm> open_music
 333 %type <scm> music
 334 %type <scm> prefix_composite_music
 335 %type <scm> repeated_music
 336 %type <scm> sequential_music
 337 %type <scm> simple_music
 338 %type <scm> simultaneous_music
 339 %type <scm> chord_body
 340 %type <scm> chord_body_element
 341 %type <scm> command_element
 342 %type <scm> command_event
 343 %type <scm> context_modification
 344 %type <scm> context_change
 345 %type <scm> direction_less_event
 346 %type <scm> direction_reqd_event
 347 %type <scm> embedded_lilypond
 348 %type <scm> event_chord
 349 %type <scm> fingering
 350 %type <scm> gen_text_def
 351 %type <scm> music_property_def
 352 %type <scm> note_chord_element
 353 %type <scm> post_event
 354 %type <scm> post_event_nofinger
 355 %type <scm> re_rhythmed_music
 356 %type <scm> relative_music
 357 %type <scm> simple_element
 358 %type <scm> simple_music_property_def
 359 %type <scm> start_symbol
 360 %type <scm> string_number_event
 361 %type <scm> tempo_event
 362
 363 %type <outputdef> output_def_body
 364 %type <outputdef> output_def_head
 365 %type <outputdef> output_def_head_with_mode_switch
 366 %type <outputdef> output_def
 367 %type <outputdef> paper_block
 368
 369 %type <scm> alternative_music
 370 %type <scm> generic_prefix_music_scm
 371 %type <scm> music_list
 372 %type <scm> absolute_pitch
 373 %type <scm> assignment_id
 374 %type <scm> bare_number
 375 %type <scm> unsigned_number
 376 %type <scm> bass_figure
 377 %type <scm> figured_bass_modification
 378 %type <scm> br_bass_figure
 379 %type <scm> bass_number
 380 %type <scm> chord_body_elements
 381 %type <scm> chord_item
 382 %type <scm> chord_items
 383 %type <scm> chord_separator
 384 %type <scm> context_def_mod
 385 %type <scm> context_def_spec_block
 386 %type <scm> context_def_spec_body
 387 %type <scm> context_mod
 388 %type <scm> context_mod_list
 389 %type <scm> context_prop_spec
 390 %type <scm> direction_less_char
 391 %type <scm> duration_length
 392 %type <scm> closed_embedded_scm
 393 %type <scm> embedded_scm
 394 %type <scm> figure_list
 395 %type <scm> figure_spec
 396 %type <scm> fraction
 397 %type <scm> full_markup
 398 %type <scm> full_markup_list
 399 %type <scm> function_scm_argument
 400 %type <scm> function_arglist
 401 %type <scm> function_arglist_nonmusic_last
 402 %type <scm> closed_function_arglist
 403 %type <scm> open_function_arglist
 404 %type <scm> identifier_init
 405 %type <scm> lilypond
 406 %type <scm> lilypond_header
 407 %type <scm> lilypond_header_body
 408 %type <scm> lyric_element
 409 %type <scm> lyric_markup
 410 %type <scm> markup
 411 %type <scm> markup_braced_list
 412 %type <scm> markup_braced_list_body
 413 %type <scm> markup_composed_list
 414 %type <scm> markup_command_list
 415 %type <scm> markup_command_list_arguments
 416 %type <scm> closed_markup_command_list_arguments
 417 %type <scm> markup_command_basic_arguments
 418 %type <scm> markup_head_1_item
 419 %type <scm> markup_head_1_list
 420 %type <scm> markup_list
 421 %type <scm> markup_top
 422 %type <scm> mode_changing_head
 423 %type <scm> mode_changing_head_with_context
 424 %type <scm> multiplied_duration
 425 %type <scm> music_function_event
 426 %type <scm> music_function_event_arglist
 427 %type <scm> music_function_chord_body
 428 %type <scm> music_function_chord_body_arglist
 429 %type <scm> new_chord
 430 %type <scm> new_lyrics
 431 %type <scm> number_expression
 432 %type <scm> number_factor
 433 %type <scm> number_term
 434 %type <scm> octave_check
 435 %type <scm> optional_context_mod
 436 %type <scm> optional_id
 437 %type <scm> optional_notemode_duration
 438 %type <scm> pitch
 439 %type <scm> pitch_also_in_chords
 440 %type <scm> post_events
 441 %type <scm> property_operation
 442 %type <scm> property_path property_path_revved
 443 %type <scm> scalar
 444 %type <scm> closed_scalar
 445 %type <scm> open_scm_function_call
 446 %type <scm> closed_scm_function_call
 447 %type <scm> script_abbreviation
 448 %type <scm> simple_chord_elements
 449 %type <scm> simple_markup
 450 %type <scm> simple_string
 451 %type <scm> steno_duration
 452 %type <scm> steno_pitch
 453 %type <scm> steno_tonic_pitch
 454 %type <scm> step_number
 455 %type <scm> step_numbers
 456 %type <scm> string
 457 %type <scm> tempo_range
 458
 459 %type <score> score_block
 460 %type <score> score_body
 461
 462
 463 %left '-' '+'
 464
 465 /* We don't assign precedence to / and *, because we might need varied
 466 prec levels in different prods */
 467
 468 %left UNARY_MINUS
 469
 470 %%
 471
 472 start_symbol:
 473         lilypond
 474         | EMBEDDED_LILY {
 475                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
 476                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
 477         } embedded_lilypond {
 478                 PARSER->lexer_->pop_state ();
 479                 PARSER->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 480         }
 481         ;
 482
 483 lilypond:       /* empty */ { }
 484         | lilypond toplevel_expression {
 485         }
 486         | lilypond assignment {
 487         }
 488         | lilypond error {
 489                 PARSER->error_level_ = 1;
 490         }
 491         | lilypond INVALID      {
 492                 PARSER->error_level_ = 1;
 493         }
 494         ;
 495
 496
 497 toplevel_expression:
 498         lilypond_header {
 499                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 500         }
 501         | book_block {
 502                 Book *book = $1;
 503                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 504                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 505                 book->unprotect ();
 506         }
 507         | bookpart_block {
 508                 Book *bookpart = $1;
 509                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 510                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 511                 bookpart->unprotect ();
 512         }
 513         | score_block {
 514                 Score *score = $1;
 515
 516                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 517                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 518                 score->unprotect ();
 519         }
 520         | composite_music {
 521                 Music *music = unsmob_music ($1);
 522                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 523                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 524         }
 525         | full_markup {
 526                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 527                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 528         }
 529         | full_markup_list {
 530                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 531                 scm_call_2 (proc, PARSER->self_scm (), $1);
 532         }
 533         | output_def {
 534                 SCM id = SCM_EOL;
 535                 Output_def * od = $1;
 536
 537                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 538                         id = ly_symbol2scm ("$defaultpaper");
 539                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 540                         id = ly_symbol2scm ("$defaultmidi");
 541                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 542                         id = ly_symbol2scm ("$defaultlayout");
 543
 544                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 545                 od->unprotect();
 546         }
 547         ;
 548
 549 closed_embedded_scm:
 550         SCM_TOKEN
 551         | SCM_IDENTIFIER
 552         | closed_scm_function_call
 553         ;
 554
 555 embedded_scm:
 556         closed_embedded_scm
 557         | open_scm_function_call
 558         ;
 559
 560 closed_scm_function_call:
 561         SCM_FUNCTION closed_function_arglist
 562         {
 563                 $$ = run_music_function (PARSER, @$,
 564                                          $1, $2);
 565         }
 566         ;
 567
 568 open_scm_function_call:
 569         SCM_FUNCTION open_function_arglist
 570         {
 571                 $$ = run_music_function (PARSER, @$,
 572                                          $1, $2);
 573         }
 574         ;
 575
 576 embedded_lilypond:
 577         { $$ = MAKE_SYNTAX ("void-music", @$, SCM_UNDEFINED); }
 578         | identifier_init
 579         | music music music_list {
 580                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 581                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 582         }
 583         | error {
 584                 PARSER->error_level_ = 1;
 585         }
 586         | INVALID embedded_lilypond {
 587                 PARSER->error_level_ = 1;
 588         }
 589         ;
 590
 591
 592 lilypond_header_body:
 593         {
 594                 $$ = get_header (PARSER);
 595                 PARSER->lexer_->add_scope ($$);
 596         }
 597         | lilypond_header_body assignment  {
 598
 599         }
 600         ;
 601
 602 lilypond_header:
 603         HEADER '{' lilypond_header_body '}'     {
 604                 $$ = PARSER->lexer_->remove_scope ();
 605         }
 606         ;
 607
 608 /*
 609         DECLARATIONS
 610 */
 611 assignment_id:
 612         STRING          { $$ = $1; }
 613         | LYRICS_STRING { $$ = $1; }
 614         ;
 615
 616 assignment:
 617         assignment_id '=' identifier_init  {
 618                 PARSER->lexer_->set_identifier ($1, $3);
 619         }
 620         | assignment_id property_path '=' identifier_init {
 621                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 622                 PARSER->lexer_->set_identifier (path, $4);
 623         ;
 624 /*
 625  TODO: devise standard for protection in parser.
 626
 627   The parser stack lives on the C-stack, which means that
 628 all objects can be unprotected as soon as they're here.
 629
 630 */
 631         }
 632         | embedded_scm { }
 633         ;
 634
 635
 636 identifier_init:
 637         score_block {
 638                 $$ = $1->self_scm ();
 639                 $1->unprotect ();
 640         }
 641         | book_block {
 642                 $$ = $1->self_scm ();
 643                 $1->unprotect ();
 644         }
 645         | bookpart_block {
 646                 $$ = $1->self_scm ();
 647                 $1->unprotect ();
 648         }
 649         | output_def {
 650                 $$ = $1->self_scm ();
 651                 $1->unprotect ();
 652         }
 653         | context_def_spec_block {
 654                 $$ = $1;
 655         }
 656         | music  {
 657                 /* Hack: Create event-chord around standalone events.
 658                    Prevents the identifier from being interpreted as a post-event. */
 659                 Music *mus = unsmob_music ($1);
 660                 bool is_event = mus &&
 661                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 662                                 != SCM_BOOL_F);
 663                 if (!is_event)
 664                         $$ = $1;
 665                 else
 666                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 667         }
 668         | post_event_nofinger {
 669                 $$ = $1;
 670         }
 671         | number_expression {
 672                 $$ = $1;
 673         }
 674         | string {
 675                 $$ = $1;
 676         }
 677         | embedded_scm {
 678                 $$ = $1;
 679         }
 680         | full_markup {
 681                 $$ = $1;
 682         }
 683         | full_markup_list {
 684                 $$ = $1;
 685         }
 686         | context_modification {
 687                 $$ = $1;
 688         }
 689         ;
 690
 691 context_def_spec_block:
 692         CONTEXT '{' context_def_spec_body '}'
 693                 {
 694                 $$ = $3;
 695         }
 696         ;
 697
 698 context_def_spec_body:
 699         /**/ {
 700                 $$ = Context_def::make_scm ();
 701                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 702         }
 703         | CONTEXT_DEF_IDENTIFIER {
 704                 $$ = $1;
 705                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 706         }
 707         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 708                 Context_def*td = unsmob_context_def ($$);
 709
 710                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 711                         SCM tag = scm_caar (p);
 712
 713                         /* TODO: should make new tag "grob-definition" ? */
 714                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 715                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 716                 }
 717         }
 718         | context_def_spec_body context_mod {
 719                 unsmob_context_def ($$)->add_context_mod ($2);
 720         }
 721         | context_def_spec_body context_modification {
 722                 Context_def *td = unsmob_context_def ($$);
 723                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 724                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 725                     td->add_context_mod (scm_car (m));
 726                 }
 727         }
 728         ;
 729
 730
 731
 732 book_block:
 733         BOOK '{' book_body '}'  {
 734                 $$ = $3;
 735                 pop_paper (PARSER);
 736                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 737         }
 738         ;
 739
 740 /* FIXME:
 741    * Use 'handlers' like for toplevel-* stuff?
 742    * grok \layout and \midi?  */
 743 book_body:
 744         {
 745                 $$ = new Book;
 746                 init_papers (PARSER);
 747                 $$->origin ()->set_spot (@$);
 748                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 749                 $$->paper_->unprotect ();
 750                 push_paper (PARSER, $$->paper_);
 751                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 752                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 753                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 754                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 755         }
 756         | BOOK_IDENTIFIER {
 757                 $$ = unsmob_book ($1);
 758                 $$->protect ();
 759                 $$->origin ()->set_spot (@$);
 760                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 761         }
 762         | book_body paper_block {
 763                 $$->paper_ = $2;
 764                 $2->unprotect ();
 765                 set_paper (PARSER, $2);
 766         }
 767         | book_body bookpart_block {
 768                 Book *bookpart = $2;
 769                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 770                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 771                 bookpart->unprotect ();
 772         }
 773         | book_body score_block {
 774                 Score *score = $2;
 775                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 776                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 777                 score->unprotect ();
 778         }
 779         | book_body composite_music {
 780                 Music *music = unsmob_music ($2);
 781                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 782                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 783         }
 784         | book_body full_markup {
 785                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 786                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 787         }
 788         | book_body full_markup_list {
 789                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 790                 scm_call_2 (proc, $$->self_scm (), $2);
 791         }
 792         | book_body lilypond_header {
 793                 $$->header_ = $2;
 794         }
 795         | book_body error {
 796                 $$->paper_ = 0;
 797                 $$->scores_ = SCM_EOL;
 798                 $$->bookparts_ = SCM_EOL;
 799         }
 800         ;
 801
 802 bookpart_block:
 803         BOOKPART '{' bookpart_body '}' {
 804                 $$ = $3;
 805                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 806         }
 807         ;
 808
 809 bookpart_body:
 810         {
 811                 $$ = new Book;
 812                 $$->origin ()->set_spot (@$);
 813                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 814         }
 815         | BOOK_IDENTIFIER {
 816                 $$ = unsmob_book ($1);
 817                 $$->protect ();
 818                 $$->origin ()->set_spot (@$);
 819                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 820         }
 821         | bookpart_body paper_block {
 822                 $$->paper_ = $2;
 823                 $2->unprotect ();
 824         }
 825         | bookpart_body score_block {
 826                 Score *score = $2;
 827                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 828                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 829                 score->unprotect ();
 830         }
 831         | bookpart_body composite_music {
 832                 Music *music = unsmob_music ($2);
 833                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 834                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 835         }
 836         | bookpart_body full_markup {
 837                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 838                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 839         }
 840         | bookpart_body full_markup_list {
 841                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 842                 scm_call_2 (proc, $$->self_scm (), $2);
 843         }
 844         | bookpart_body lilypond_header {
 845                 $$->header_ = $2;
 846         }
 847         | bookpart_body error {
 848                 $$->paper_ = 0;
 849                 $$->scores_ = SCM_EOL;
 850         }
 851         ;
 852
 853 score_block:
 854         SCORE '{' score_body '}'        {
 855                 $$ = $3;
 856         }
 857         ;
 858
 859 score_body:
 860         music {
 861                 SCM m = $1;
 862                 SCM scorify = ly_lily_module_constant ("scorify-music");
 863                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 864
 865                 // pass ownernship to C++ again.
 866                 $$ = unsmob_score (score);
 867                 $$->protect ();
 868                 $$->origin ()->set_spot (@$);
 869         }
 870         | SCORE_IDENTIFIER {
 871                 $$ = unsmob_score ($1);
 872                 $$->protect ();
 873                 $$->origin ()->set_spot (@$);
 874         }
 875         | score_body lilypond_header    {
 876                 $$->set_header ($2);
 877         }
 878         | score_body output_def {
 879                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 880                 {
 881                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 882
 883                 }
 884                 else
 885                 {
 886                         $$->add_output_def ($2);
 887                 }
 888                 $2->unprotect ();
 889         }
 890         | score_body error {
 891                 $$->error_found_ = true;
 892         }
 893         ;
 894
 895
 896 /*
 897         OUTPUT DEF
 898 */
 899
 900 paper_block:
 901         output_def {
 902                 $$ = $1;
 903                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 904                 {
 905                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 906                         $1->unprotect ();
 907                         $$ = get_paper (PARSER);
 908                 }
 909         }
 910         ;
 911
 912
 913 output_def:
 914         output_def_body '}' {
 915                 $$ = $1;
 916
 917                 PARSER->lexer_->remove_scope ();
 918                 PARSER->lexer_->pop_state ();
 919         }
 920         ;
 921
 922 output_def_head:
 923         PAPER {
 924                 $$ = get_paper (PARSER);
 925                 $$->input_origin_ = @$;
 926                 PARSER->lexer_->add_scope ($$->scope_);
 927         }
 928         | MIDI    {
 929                 Output_def *p = get_midi (PARSER);
 930                 $$ = p;
 931                 PARSER->lexer_->add_scope (p->scope_);
 932         }
 933         | LAYOUT        {
 934                 Output_def *p = get_layout (PARSER);
 935
 936                 PARSER->lexer_->add_scope (p->scope_);
 937                 $$ = p;
 938         }
 939         ;
 940
 941 output_def_head_with_mode_switch:
 942         output_def_head {
 943                 PARSER->lexer_->push_initial_state ();
 944                 $$ = $1;
 945         }
 946         ;
 947
 948 output_def_body:
 949         output_def_head_with_mode_switch '{' {
 950                 $$ = $1;
 951                 $$->input_origin_.set_spot (@$);
 952         }
 953         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 954                 $1->unprotect ();
 955
 956                 Output_def *o = unsmob_output_def ($3);
 957                 o->input_origin_.set_spot (@$);
 958                 $$ = o;
 959                 $$->protect ();
 960                 PARSER->lexer_->remove_scope ();
 961                 PARSER->lexer_->add_scope (o->scope_);
 962         }
 963         | output_def_body assignment  {
 964
 965         }
 966         | output_def_body context_def_spec_block        {
 967                 assign_context_def ($$, $2);
 968         }
 969         | output_def_body error {
 970
 971         }
 972         ;
 973
 974 tempo_event:
 975         TEMPO steno_duration '=' tempo_range    {
 976                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
 977         }
 978         | TEMPO closed_scalar steno_duration '=' tempo_range    {
 979                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
 980         }
 981         | TEMPO closed_scalar {
 982                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
 983         }
 984         ;
 985
 986 /*
 987 The representation of a  list is reversed to have efficient append.  */
 988
 989 music_list:
 990         /* empty */ {
 991                 $$ = SCM_EOL;
 992         }
 993         | music_list music {
 994                 $$ = scm_cons ($2, $1);
 995         }
 996         | music_list embedded_scm {
 997
 998         }
 999         | music_list error {
1000                 Music *m = MY_MAKE_MUSIC("Music", @$);
1001                 // ugh. code dup
1002                 m->set_property ("error-found", SCM_BOOL_T);
1003                 $$ = scm_cons (m->self_scm (), $1);
1004                 m->unprotect (); /* UGH */
1005         }
1006         ;
1007
1008 music:
1009         simple_music
1010         | composite_music
1011         | MUSIC_IDENTIFIER
1012         ;
1013
1014 alternative_music:
1015         /* empty */ {
1016                 $$ = SCM_EOL;
1017         }
1018         | ALTERNATIVE '{' music_list '}' {
1019                 $$ = scm_reverse_x ($3, SCM_EOL);
1020         }
1021         ;
1022
1023
1024 repeated_music:
1025         REPEAT simple_string unsigned_number music alternative_music
1026         {
1027                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $5);
1028         }
1029         ;
1030
1031 sequential_music:
1032         SEQUENTIAL '{' music_list '}'           {
1033                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_reverse_x ($3, SCM_EOL));
1034         }
1035         | '{' music_list '}'            {
1036                 $$ = MAKE_SYNTAX ("sequential-music", @$, scm_reverse_x ($2, SCM_EOL));
1037         }
1038         ;
1039
1040 simultaneous_music:
1041         SIMULTANEOUS '{' music_list '}'{
1042                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($3, SCM_EOL));
1043         }
1044         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1045                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1046         }
1047         ;
1048
1049 simple_music:
1050         event_chord
1051         | music_property_def
1052         | context_change
1053         ;
1054
1055 context_modification:
1056         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1057         {
1058                 PARSER->lexer_->pop_state ();
1059                 $$ = $4;
1060         }
1061         | WITH CONTEXT_MOD_IDENTIFIER
1062         {
1063                 $$ = $2;
1064         }
1065         | CONTEXT_MOD_IDENTIFIER
1066         {
1067                 $$ = $1;
1068         }
1069         ;
1070
1071 optional_context_mod:
1072         /**/ {
1073             $$ = SCM_EOL;
1074         }
1075         | context_modification
1076         {
1077               $$ = $1;
1078         }
1079         ;
1080
1081 context_mod_list:
1082         /**/ {
1083             $$ = Context_mod ().smobbed_copy ();
1084         }
1085         | context_mod_list context_mod  {
1086                  unsmob_context_mod ($1)->add_context_mod ($2);
1087         }
1088         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1089                  Context_mod *md = unsmob_context_mod ($2);
1090                  if (md)
1091                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1092         }
1093         ;
1094
1095 composite_music:
1096         prefix_composite_music { $$ = $1; }
1097         | grouped_music_list { $$ = $1; }
1098         ;
1099
1100 /* Music that can't be followed by additional events or durations */
1101 closed_music:
1102         MUSIC_IDENTIFIER
1103         | grouped_music_list
1104         ;
1105
1106 /* Music that potentially accepts additional events or durations */
1107 open_music:
1108         simple_music
1109         | prefix_composite_music
1110         ;
1111
1112 grouped_music_list:
1113         simultaneous_music              { $$ = $1; }
1114         | sequential_music              { $$ = $1; }
1115         ;
1116
1117 function_scm_argument:
1118         closed_embedded_scm
1119         | simple_string
1120         ;
1121
1122 /* An argument list. If a function \foo expects scm scm music, then the lexer expands \foo into the token sequence:
1123  MUSIC_FUNCTION EXPECT_MUSIC EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1124 and this rule returns the reversed list of arguments. */
1125
1126
1127 function_arglist:
1128         closed_function_arglist
1129         | open_function_arglist
1130         ;
1131
1132 open_function_arglist:
1133         EXPECT_MUSIC function_arglist open_music {
1134                 $$ = scm_cons ($3, $2);
1135         }
1136         | EXPECT_SCM function_arglist open_scm_function_call {
1137                 $$ = scm_cons ($3, $2);
1138         }
1139         ;
1140
1141 /* a closed argument list is one that does not end in a music
1142    expression that could still take a duration or event */
1143
1144 closed_function_arglist:
1145         function_arglist_nonmusic_last
1146         | EXPECT_MUSIC function_arglist closed_music {
1147                 $$ = scm_cons ($3, $2);
1148                 }
1149         ;
1150
1151 function_arglist_nonmusic_last:
1152         EXPECT_NO_MORE_ARGS {
1153                 /* This is for 0-ary functions, so they don't need to
1154                    read a lookahead token */
1155                 $$ = SCM_EOL;
1156         }
1157         | EXPECT_MARKUP function_arglist full_markup {
1158                 $$ = scm_cons ($3, $2);
1159         }
1160         | EXPECT_MARKUP function_arglist simple_string {
1161                 $$ = scm_cons ($3, $2);
1162         }
1163         | EXPECT_PITCH function_arglist pitch_also_in_chords {
1164                 $$ = scm_cons ($3, $2);
1165         }
1166         | EXPECT_DURATION closed_function_arglist duration_length {
1167                 $$ = scm_cons ($3, $2);
1168         }
1169         | EXPECT_SCM function_arglist function_scm_argument {
1170                 $$ = scm_cons ($3, $2);
1171         }
1172         ;
1173
1174 generic_prefix_music_scm:
1175         MUSIC_FUNCTION function_arglist {
1176                 $$ = run_music_function (PARSER, @$,
1177                                          $1,
1178                                          scm_reverse_x ($2, SCM_EOL));
1179         }
1180         ;
1181
1182
1183 optional_id:
1184         /**/ { $$ = SCM_EOL; }
1185         | '=' simple_string {
1186                 $$ = $2;
1187         }
1188         ;
1189
1190
1191 prefix_composite_music:
1192         generic_prefix_music_scm
1193         | CONTEXT simple_string optional_id optional_context_mod music {
1194                 Context_mod *ctxmod = unsmob_context_mod ($4);
1195                 SCM mods = SCM_EOL;
1196                 if (ctxmod)
1197                         mods = ctxmod->get_mods ();
1198                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_F);
1199         }
1200         | NEWCONTEXT simple_string optional_id optional_context_mod music {
1201                 Context_mod *ctxmod = unsmob_context_mod ($4);
1202                 SCM mods = SCM_EOL;
1203                 if (ctxmod)
1204                         mods = ctxmod->get_mods ();
1205                 $$ = MAKE_SYNTAX ("context-specification", @$, $2, $3, $5, mods, SCM_BOOL_T);
1206         }
1207
1208         | TIMES fraction music {
1209                 $$ = MAKE_SYNTAX ("time-scaled-music", @$, $2, $3);
1210         }
1211         | repeated_music                { $$ = $1; }
1212         | mode_changing_head grouped_music_list {
1213                 if ($1 == ly_symbol2scm ("chords"))
1214                 {
1215                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1216                 }
1217                 else
1218                 {
1219                   $$ = $2;
1220                 }
1221                 PARSER->lexer_->pop_state ();
1222         }
1223         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1224                 Context_mod *ctxmod = unsmob_context_mod ($2);
1225                 SCM mods = SCM_EOL;
1226                 if (ctxmod)
1227                         mods = ctxmod->get_mods ();
1228                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, $3, mods, SCM_BOOL_T);
1229                 if ($1 == ly_symbol2scm ("ChordNames"))
1230                 {
1231                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1232                 }
1233                 PARSER->lexer_->pop_state ();
1234         }
1235         | relative_music        { $$ = $1; }
1236         | re_rhythmed_music     { $$ = $1; }
1237         ;
1238
1239 mode_changing_head:
1240         NOTEMODE {
1241                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1242                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1243
1244                 $$ = ly_symbol2scm ("notes");
1245         }
1246         | DRUMMODE
1247                 {
1248                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1249                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1250
1251                 $$ = ly_symbol2scm ("drums");
1252         }
1253         | FIGUREMODE {
1254                 PARSER->lexer_->push_figuredbass_state ();
1255
1256                 $$ = ly_symbol2scm ("figures");
1257         }
1258         | CHORDMODE {
1259                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1260                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1261                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1262                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1263                 $$ = ly_symbol2scm ("chords");
1264
1265         }
1266         | LYRICMODE
1267                 { PARSER->lexer_->push_lyric_state ();
1268                 $$ = ly_symbol2scm ("lyrics");
1269         }
1270         ;
1271
1272 mode_changing_head_with_context:
1273         DRUMS {
1274                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1275                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1276
1277                 $$ = ly_symbol2scm ("DrumStaff");
1278         }
1279         | FIGURES {
1280                 PARSER->lexer_->push_figuredbass_state ();
1281
1282                 $$ = ly_symbol2scm ("FiguredBass");
1283         }
1284         | CHORDS {
1285                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1286                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1287                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1288                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1289                 $$ = ly_symbol2scm ("ChordNames");
1290         }
1291         | LYRICS
1292                 { PARSER->lexer_->push_lyric_state ();
1293                 $$ = ly_symbol2scm ("Lyrics");
1294         }
1295         ;
1296
1297
1298 relative_music:
1299         RELATIVE absolute_pitch music {
1300                 Pitch start = *unsmob_pitch ($2);
1301                 $$ = make_music_relative (start, $3, @$);
1302         }
1303         | RELATIVE composite_music {
1304                 Pitch middle_c (0, 0, 0);
1305                 $$ = make_music_relative (middle_c, $2, @$);
1306         }
1307         ;
1308
1309 new_lyrics:
1310         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1311         /*cont */
1312         closed_music {
1313         /* Can also use music at the expensive of two S/Rs similar to
1314            \repeat \alternative */
1315                 PARSER->lexer_->pop_state ();
1316
1317                 $$ = scm_cons ($3, SCM_EOL);
1318         }
1319         | new_lyrics ADDLYRICS {
1320                 PARSER->lexer_->push_lyric_state ();
1321         } closed_music {
1322                 PARSER->lexer_->pop_state ();
1323                 $$ = scm_cons ($4, $1);
1324         }
1325         ;
1326
1327 re_rhythmed_music:
1328         closed_music new_lyrics {
1329                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1330         }
1331         | LYRICSTO simple_string {
1332                 PARSER->lexer_->push_lyric_state ();
1333         } music {
1334                 PARSER->lexer_->pop_state ();
1335                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1336         }
1337         ;
1338
1339 context_change:
1340         CHANGE STRING '=' STRING  {
1341                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1342         }
1343         ;
1344
1345
1346 property_path_revved:
1347         closed_embedded_scm {
1348                 $$ = scm_cons ($1, SCM_EOL);
1349         }
1350         | property_path_revved closed_embedded_scm {
1351                 $$ = scm_cons ($2, $1);
1352         }
1353         ;
1354
1355 property_path:
1356         property_path_revved  {
1357                 $$ = scm_reverse_x ($1, SCM_EOL);
1358         }
1359         ;
1360
1361 property_operation:
1362         STRING '=' scalar {
1363                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1364                         scm_string_to_symbol ($1), $3);
1365         }
1366         | UNSET simple_string {
1367                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1368                         scm_string_to_symbol ($2));
1369         }
1370         | OVERRIDE simple_string property_path '=' scalar {
1371                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1372                                                         scm_string_to_symbol ($2), $5),
1373                                              $3));
1374         }
1375         | REVERT simple_string embedded_scm {
1376                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1377                         scm_string_to_symbol ($2), $3);
1378         }
1379         ;
1380
1381 context_def_mod:
1382         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1383         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1384
1385         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1386         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1387         | DENIES { $$ = ly_symbol2scm ("denies"); }
1388
1389         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1390         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1391         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1392         | NAME { $$ = ly_symbol2scm ("context-name"); }
1393         ;
1394
1395 context_mod:
1396         property_operation { $$ = $1; }
1397         | context_def_mod STRING {
1398                 $$ = scm_list_2 ($1, $2);
1399         }
1400         | context_def_mod embedded_scm {
1401            if (ly_symbol2scm ("consists") != $1)
1402            {
1403              $$ = SCM_EOL;
1404              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1405            }
1406            else
1407            {
1408              $$ = scm_list_2 ($1, $2);
1409            }
1410         }
1411         ;
1412
1413 context_prop_spec:
1414         simple_string {
1415                 if (!is_regular_identifier ($1))
1416                 {
1417                         @$.error (_("Grob name should be alphanumeric"));
1418                 }
1419
1420                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1421                         scm_string_to_symbol ($1));
1422         }
1423         | simple_string '.' simple_string {
1424                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1425                         scm_string_to_symbol ($3));
1426         }
1427         ;
1428
1429 simple_music_property_def:
1430         OVERRIDE context_prop_spec property_path '=' scalar {
1431                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1432                                 ly_symbol2scm ("OverrideProperty"),
1433                                 scm_cadr ($2),
1434                                 $5, SCM_UNDEFINED),
1435                                 $3));
1436         }
1437         | REVERT context_prop_spec embedded_scm {
1438                 $$ = scm_list_4 (scm_car ($2),
1439                         ly_symbol2scm ("RevertProperty"),
1440                         scm_cadr ($2),
1441                         $3);
1442         }
1443         | SET context_prop_spec '=' scalar {
1444                 $$ = scm_list_4 (scm_car ($2),
1445                         ly_symbol2scm ("PropertySet"),
1446                         scm_cadr ($2),
1447                         $4);
1448         }
1449         | UNSET context_prop_spec {
1450                 $$ = scm_list_3 (scm_car ($2),
1451                         ly_symbol2scm ("PropertyUnset"),
1452                         scm_cadr ($2));
1453         }
1454         ;
1455
1456 music_property_def:
1457         simple_music_property_def {
1458                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1459         }
1460         | ONCE simple_music_property_def {
1461                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1462         }
1463         ;
1464
1465 string:
1466         STRING {
1467                 $$ = $1;
1468         }
1469         | STRING_IDENTIFIER {
1470                 $$ = $1;
1471         }
1472         | string '+' string {
1473                 $$ = scm_string_append (scm_list_2 ($1, $3));
1474         }
1475         ;
1476
1477 simple_string: STRING {
1478                 $$ = $1;
1479         }
1480         | LYRICS_STRING {
1481                 $$ = $1;
1482         }
1483         | STRING_IDENTIFIER {
1484                 $$ = $1;
1485         }
1486         ;
1487
1488 closed_scalar: string {
1489                 $$ = $1;
1490         }
1491         | lyric_element {
1492                 $$ = $1;
1493         }
1494         | bare_number {
1495                 $$ = $1;
1496         }
1497         | closed_embedded_scm {
1498                 $$ = $1;
1499         }
1500         | full_markup {
1501                 $$ = $1;
1502         }
1503         ;
1504
1505 scalar: closed_scalar
1506         | open_scm_function_call
1507         ;
1508
1509 event_chord:
1510         /* TODO: Create a special case that avoids the creation of
1511            EventChords around simple_elements that have no post_events?
1512          */
1513         simple_chord_elements post_events       {
1514                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1515
1516                 Input i;
1517                 /* why is this giving wrong start location? -ns
1518                  * i = @$; */
1519                 i.set_location (@1, @2);
1520                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1521         }
1522         | CHORD_REPETITION optional_notemode_duration post_events {
1523                 Input i;
1524                 i.set_location (@1, @3);
1525                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1526                                   PARSER->lexer_->chord_repetition_.last_chord_,
1527                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1528                                   $2, scm_reverse_x ($3, SCM_EOL));
1529         }
1530         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1531                 Input i;
1532                 i.set_location (@1, @3);
1533                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1534                                   scm_reverse_x ($3, SCM_EOL));
1535         }
1536         | command_element
1537         /* note chord elements are memorized into
1538            PARSER->lexer_->chord_repetition_ so that the chord repetition
1539            mechanism copy them when a chord repetition symbol is found
1540         */
1541         | note_chord_element    {
1542                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1543         }
1544         ;
1545
1546
1547 note_chord_element:
1548         chord_body optional_notemode_duration post_events
1549         {
1550                 Music *m = unsmob_music ($1);
1551                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1552                 SCM es = m->get_property ("elements");
1553                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1554
1555                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1556                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1557                 es = ly_append2 (es, postevs);
1558
1559                 m-> set_property ("elements", es);
1560                 m->set_spot (@$);
1561                 $$ = m->self_scm ();
1562         }
1563         ;
1564
1565 chord_body:
1566         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1567         {
1568                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1569         }
1570         ;
1571
1572 chord_body_elements:
1573         /* empty */             { $$ = SCM_EOL; }
1574         | chord_body_elements chord_body_element {
1575                 $$ = scm_cons ($2, $1);
1576         }
1577         ;
1578
1579 chord_body_element:
1580         pitch exclamations questions octave_check post_events
1581         {
1582                 int q = $3;
1583                 int ex = $2;
1584                 SCM check = $4;
1585                 SCM post = $5;
1586
1587                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1588                 n->set_property ("pitch", $1);
1589                 if (q % 2)
1590                         n->set_property ("cautionary", SCM_BOOL_T);
1591                 if (ex % 2 || q % 2)
1592                         n->set_property ("force-accidental", SCM_BOOL_T);
1593
1594                 if (scm_is_pair (post)) {
1595                         SCM arts = scm_reverse_x (post, SCM_EOL);
1596                         n->set_property ("articulations", arts);
1597                 }
1598                 if (scm_is_number (check))
1599                 {
1600                         int q = scm_to_int (check);
1601                         n->set_property ("absolute-octave", scm_from_int (q-1));
1602                 }
1603
1604                 $$ = n->unprotect ();
1605         }
1606         | DRUM_PITCH post_events {
1607                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1608                 n->set_property ("drum-type", $1);
1609
1610                 if (scm_is_pair ($2)) {
1611                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1612                         n->set_property ("articulations", arts);
1613                 }
1614                 $$ = n->unprotect ();
1615         }
1616         | music_function_chord_body
1617         ;
1618
1619 /* We can't accept a music argument, not even a closed one,
1620  * immediately before chord_body_elements, otherwise a function \fun
1621  * with a signature of two music arguments can't be sorted out
1622  * properly in a construct like
1623  * <\fun { c } \fun { c } c>
1624  * The second call could be interpreted either as a chord constituent
1625  * or a music expression.
1626  */
1627
1628 music_function_chord_body_arglist:
1629         function_arglist_nonmusic_last
1630         | EXPECT_MUSIC music_function_chord_body_arglist chord_body_element {
1631                 $$ = scm_cons ($3, $2);
1632         }
1633         ;
1634
1635 music_function_chord_body:
1636         MUSIC_FUNCTION music_function_chord_body_arglist {
1637                 $$ = run_music_function (PARSER, @$,
1638                                          $1, scm_reverse_x ($2, SCM_EOL));
1639         }
1640         ;
1641
1642 /* We could accept a closed music argument before the post events
1643  * indicated by a trailing argument list.  For symmetry with chord
1644  * bodies and in order to avoid too tricky and complex behavior, we
1645  * refrain from doing so.
1646  */
1647 music_function_event_arglist:
1648         function_arglist_nonmusic_last
1649         | EXPECT_MUSIC music_function_event_arglist post_event {
1650                 $$ = scm_cons ($3, $2);
1651         }
1652         ;
1653
1654 music_function_event:
1655         MUSIC_FUNCTION music_function_event_arglist {
1656                 $$ = run_music_function (PARSER, @$,
1657                                          $1, scm_reverse_x ($2, SCM_EOL));
1658         }
1659         ;
1660
1661 command_element:
1662         command_event {
1663                 $$ = $1;
1664         }
1665         | SKIP duration_length {
1666                 $$ = MAKE_SYNTAX ("skip-music", @$, $2);
1667         }
1668         | E_BRACKET_OPEN {
1669                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1670                 m->set_property ("span-direction", scm_from_int (START));
1671                 $$ = m->unprotect();
1672         }
1673         | E_BRACKET_CLOSE {
1674                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1675                 m->set_property ("span-direction", scm_from_int (STOP));
1676                 $$ = m->unprotect ();
1677         }
1678         | E_BACKSLASH {
1679                 $$ = MAKE_SYNTAX ("voice-separator", @$, SCM_UNDEFINED);
1680         }
1681         | '|'      {
1682                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1683
1684                 Music *m = unsmob_music (pipe);
1685                 if (m)
1686                 {
1687                         m = m->clone ();
1688                         m->set_spot (@$);
1689                         $$ = m->unprotect ();
1690                 }
1691                 else
1692                         $$ = MAKE_SYNTAX ("bar-check", @$, SCM_UNDEFINED);
1693
1694         }
1695         | PARTIAL duration_length       {
1696                 $$ = MAKE_SYNTAX ("partial", @$, $2);
1697         }
1698
1699         | TIME_T fraction  {
1700                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1701
1702                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1703         }
1704         | MARK scalar {
1705                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1706         }
1707         ;
1708
1709 command_event:
1710         E_TILDE {
1711                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1712         }
1713         | MARK DEFAULT  {
1714                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1715                 $$ = m->unprotect ();
1716         }
1717         | tempo_event {
1718                 $$ = $1;
1719         }
1720         | KEY DEFAULT {
1721                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1722                 $$ = key->unprotect ();
1723         }
1724         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1725
1726                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1727                 if (scm_ilength ($3) > 0)
1728                 {
1729                         key->set_property ("pitch-alist", $3);
1730                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1731                         key->transpose (* unsmob_pitch ($2));
1732                 } else {
1733                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1734                 }
1735
1736                 $$ = key->unprotect ();
1737         }
1738         ;
1739
1740
1741 post_events:
1742         /* empty */ {
1743                 $$ = SCM_EOL;
1744         }
1745         | post_events post_event {
1746                 unsmob_music ($2)->set_spot (@2);
1747                 $$ = scm_cons ($2, $$);
1748         }
1749         ;
1750
1751 post_event_nofinger:
1752         direction_less_event {
1753                 $$ = $1;
1754         }
1755         | script_dir music_function_event {
1756                 $$ = $2;
1757                 if ($1)
1758                 {
1759                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
1760                 }
1761         }
1762         | HYPHEN {
1763                 if (!PARSER->lexer_->is_lyric_state ())
1764                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1765                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1766         }
1767         | EXTENDER {
1768                 if (!PARSER->lexer_->is_lyric_state ())
1769                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1770                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1771         }
1772         | script_dir direction_reqd_event {
1773                 if ($1)
1774                 {
1775                         Music *m = unsmob_music ($2);
1776                         m->set_property ("direction", scm_from_int ($1));
1777                 }
1778                 $$ = $2;
1779         }
1780         | script_dir direction_less_event {
1781                 if ($1)
1782                 {
1783                         Music *m = unsmob_music ($2);
1784                         m->set_property ("direction", scm_from_int ($1));
1785                 }
1786                 $$ = $2;
1787         }
1788         | string_number_event
1789         ;
1790
1791 post_event:
1792         post_event_nofinger
1793         | script_dir fingering {
1794                 if ($1)
1795                 {
1796                         Music *m = unsmob_music ($2);
1797                         m->set_property ("direction", scm_from_int ($1));
1798                 }
1799                 $$ = $2;
1800         }
1801         ;
1802
1803 string_number_event:
1804         E_UNSIGNED {
1805                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1806                 s->set_property ("string-number", scm_from_int ($1));
1807                 $$ = s->unprotect ();
1808         }
1809         ;
1810
1811 direction_less_char:
1812         '['  {
1813                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1814         }
1815         | ']'  {
1816                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1817         }
1818         | '~'  {
1819                 $$ = ly_symbol2scm ("tildeSymbol");
1820         }
1821         | '('  {
1822                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1823         }
1824         | ')'  {
1825                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1826         }
1827         | E_EXCLAMATION  {
1828                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1829         }
1830         | E_OPEN  {
1831                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1832         }
1833         | E_CLOSE  {
1834                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1835         }
1836         | E_ANGLE_CLOSE  {
1837                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1838         }
1839         | E_ANGLE_OPEN  {
1840                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1841         }
1842         ;
1843
1844 direction_less_event:
1845         direction_less_char {
1846                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
1847                 Music *m = 0;
1848                 if (unsmob_music (predefd))
1849                 {
1850                         m = unsmob_music (predefd)->clone ();
1851                         m->set_spot (@$);
1852                 }
1853                 else
1854                 {
1855                         m = MY_MAKE_MUSIC ("Music", @$);
1856                 }
1857                 $$ = m->unprotect ();
1858         }
1859         | EVENT_IDENTIFIER      {
1860                 $$ = $1;
1861         }
1862         | tremolo_type  {
1863                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
1864                a->set_property ("tremolo-type", scm_from_int ($1));
1865                $$ = a->unprotect ();
1866         }
1867         ;
1868
1869 direction_reqd_event:
1870         gen_text_def {
1871                 $$ = $1;
1872         }
1873         | script_abbreviation {
1874                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1875                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
1876                 if (scm_is_string (s))
1877                         a->set_property ("articulation-type", s);
1878                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
1879                 $$ = a->unprotect ();
1880         }
1881         ;
1882
1883 octave_check:
1884         /**/ { $$ = SCM_EOL; }
1885         | '='  { $$ = scm_from_int (0); }
1886         | '=' sub_quotes { $$ = scm_from_int (-$2); }
1887         | '=' sup_quotes { $$ = scm_from_int ($2); }
1888         ;
1889
1890 sup_quotes:
1891         '\'' {
1892                 $$ = 1;
1893         }
1894         | sup_quotes '\'' {
1895                 $$ ++;
1896         }
1897         ;
1898
1899 sub_quotes:
1900         ',' {
1901                 $$ = 1;
1902         }
1903         | sub_quotes ',' {
1904                 $$++;
1905         }
1906         ;
1907
1908 steno_pitch:
1909         NOTENAME_PITCH  {
1910                 $$ = $1;
1911         }
1912         | NOTENAME_PITCH sup_quotes     {
1913                 Pitch p = *unsmob_pitch ($1);
1914                 p = p.transposed (Pitch ($2,0,0));
1915                 $$ = p.smobbed_copy ();
1916         }
1917         | NOTENAME_PITCH sub_quotes      {
1918                 Pitch p =* unsmob_pitch ($1);
1919                 p = p.transposed (Pitch (-$2,0,0));
1920                 $$ = p.smobbed_copy ();
1921         }
1922         ;
1923
1924 /*
1925 ugh. duplication
1926 */
1927
1928 steno_tonic_pitch:
1929         TONICNAME_PITCH {
1930                 $$ = $1;
1931         }
1932         | TONICNAME_PITCH sup_quotes    {
1933                 Pitch p = *unsmob_pitch ($1);
1934                 p = p.transposed (Pitch ($2,0,0));
1935                 $$ = p.smobbed_copy ();
1936         }
1937         | TONICNAME_PITCH sub_quotes     {
1938                 Pitch p = *unsmob_pitch ($1);
1939
1940                 p = p.transposed (Pitch (-$2,0,0));
1941                 $$ = p.smobbed_copy ();
1942         }
1943         ;
1944
1945 pitch:
1946         steno_pitch {
1947                 $$ = $1;
1948         }
1949         ;
1950
1951 pitch_also_in_chords:
1952         pitch
1953         | steno_tonic_pitch
1954         ;
1955
1956 gen_text_def:
1957         full_markup {
1958                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1959                 t->set_property ("text", $1);
1960                 $$ = t->unprotect ();
1961         }
1962         | string {
1963                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
1964                 t->set_property ("text",
1965                         make_simple_markup ($1));
1966                 $$ = t->unprotect ();
1967         }
1968         ;
1969
1970 fingering:
1971         UNSIGNED {
1972                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
1973                 t->set_property ("digit", scm_from_int ($1));
1974                 $$ = t->unprotect ();
1975         }
1976         ;
1977
1978 script_abbreviation:
1979         '^'             {
1980                 $$ = scm_from_locale_string ("Hat");
1981         }
1982         | '+'           {
1983                 $$ = scm_from_locale_string ("Plus");
1984         }
1985         | '-'           {
1986                 $$ = scm_from_locale_string ("Dash");
1987         }
1988         | '|'           {
1989                 $$ = scm_from_locale_string ("Bar");
1990         }
1991         | ANGLE_CLOSE   {
1992                 $$ = scm_from_locale_string ("Larger");
1993         }
1994         | '.'           {
1995                 $$ = scm_from_locale_string ("Dot");
1996         }
1997         | '_' {
1998                 $$ = scm_from_locale_string ("Underscore");
1999         }
2000         ;
2001
2002 script_dir:
2003         '_'     { $$ = DOWN; }
2004         | '^'   { $$ = UP; }
2005         | '-'   { $$ = CENTER; }
2006         ;
2007
2008
2009 absolute_pitch:
2010         steno_pitch     {
2011                 $$ = $1;
2012         }
2013         ;
2014
2015 duration_length:
2016         multiplied_duration {
2017                 $$ = $1;
2018         }
2019         ;
2020
2021 optional_notemode_duration:
2022         {
2023                 Duration dd = PARSER->default_duration_;
2024                 $$ = dd.smobbed_copy ();
2025         }
2026         | multiplied_duration   {
2027                 $$ = $1;
2028                 PARSER->default_duration_ = *unsmob_duration ($$);
2029         }
2030         ;
2031
2032 steno_duration:
2033         bare_unsigned dots              {
2034                 int len = 0;
2035                 if (!is_duration ($1))
2036                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
2037                 else
2038                         len = intlog2 ($1);
2039
2040                 $$ = Duration (len, $2).smobbed_copy ();
2041         }
2042         | DURATION_IDENTIFIER dots      {
2043                 Duration *d = unsmob_duration ($1);
2044                 Duration k (d->duration_log (), d->dot_count () + $2);
2045                 k = k.compressed (d->factor ());
2046                 *d = k;
2047                 $$ = $1;
2048         }
2049         ;
2050
2051 multiplied_duration:
2052         steno_duration {
2053                 $$ = $1;
2054         }
2055         | multiplied_duration '*' bare_unsigned {
2056                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2057         }
2058         | multiplied_duration '*' FRACTION {
2059                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2060
2061                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2062         }
2063         ;
2064
2065 fraction:
2066         FRACTION { $$ = $1; }
2067         | UNSIGNED '/' UNSIGNED {
2068                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2069         }
2070         ;
2071
2072 dots:
2073         /* empty */     {
2074                 $$ = 0;
2075         }
2076         | dots '.' {
2077                 $$ ++;
2078         }
2079         ;
2080
2081 tremolo_type:
2082         ':'     {
2083                 $$ = 0;
2084         }
2085         | ':' bare_unsigned {
2086                 if (!is_duration ($2))
2087                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2088                 $$ = $2;
2089         }
2090         ;
2091
2092 bass_number:
2093         UNSIGNED {
2094                 $$ = scm_from_int ($1);
2095         }
2096         | STRING { $$ = $1; }
2097         | full_markup { $$ = $1; }
2098         ;
2099
2100 figured_bass_alteration:
2101         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2102         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2103         | '!'   { $$ = scm_from_int (0); }
2104         ;
2105
2106 bass_figure:
2107         FIGURE_SPACE {
2108                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2109                 $$ = bfr->unprotect ();
2110         }
2111         | bass_number  {
2112                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2113                 $$ = bfr->self_scm ();
2114
2115                 if (scm_is_number ($1))
2116                         bfr->set_property ("figure", $1);
2117                 else if (Text_interface::is_markup ($1))
2118                         bfr->set_property ("text", $1);
2119
2120                 bfr->unprotect ();
2121         }
2122         | bass_figure ']' {
2123                 $$ = $1;
2124                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2125         }
2126         | bass_figure figured_bass_alteration {
2127                 Music *m = unsmob_music ($1);
2128                 if (scm_to_double ($2)) {
2129                         SCM salter = m->get_property ("alteration");
2130                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2131                         m->set_property ("alteration",
2132                                          scm_sum (alter, $2));
2133                 } else {
2134                         m->set_property ("alteration", scm_from_int (0));
2135                 }
2136         }
2137         | bass_figure figured_bass_modification  {
2138                 Music *m = unsmob_music ($1);
2139                 if ($2 == ly_symbol2scm ("plus"))
2140                         {
2141                         m->set_property ("augmented", SCM_BOOL_T);
2142                         }
2143                 else if ($2 == ly_symbol2scm ("slash"))
2144                         {
2145                         m->set_property ("diminished", SCM_BOOL_T);
2146                         }
2147                 else if ($2 == ly_symbol2scm ("exclamation"))
2148                         {
2149                         m->set_property ("no-continuation", SCM_BOOL_T);
2150                         }
2151                 else if ($2 == ly_symbol2scm ("backslash"))
2152                         {
2153                         m->set_property ("augmented-slash", SCM_BOOL_T);
2154                         }
2155         }
2156         ;
2157
2158
2159 figured_bass_modification:
2160         E_PLUS          {
2161                 $$ = ly_symbol2scm ("plus");
2162         }
2163         | E_EXCLAMATION {
2164                 $$ = ly_symbol2scm ("exclamation");
2165         }
2166         | '/'           {
2167                 $$ = ly_symbol2scm ("slash");
2168         }
2169         | E_BACKSLASH {
2170                 $$ = ly_symbol2scm ("backslash");
2171         }
2172         ;
2173
2174 br_bass_figure:
2175         bass_figure {
2176                 $$ = $1;
2177         }
2178         | '[' bass_figure {
2179                 $$ = $2;
2180                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2181         }
2182         ;
2183
2184 figure_list:
2185         /**/            {
2186                 $$ = SCM_EOL;
2187         }
2188         | figure_list br_bass_figure {
2189                 $$ = scm_cons ($2, $1);
2190         }
2191         ;
2192
2193 figure_spec:
2194         FIGURE_OPEN figure_list FIGURE_CLOSE {
2195                 $$ = scm_reverse_x ($2, SCM_EOL);
2196         }
2197         ;
2198
2199
2200 optional_rest:
2201         /**/   { $$ = 0; }
2202         | REST { $$ = 1; }
2203         ;
2204
2205 simple_element:
2206         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2207                 if (!PARSER->lexer_->is_note_state ())
2208                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2209
2210                 Music *n = 0;
2211                 if ($6)
2212                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2213                 else
2214                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2215
2216                 n->set_property ("pitch", $1);
2217                 n->set_property ("duration", $5);
2218
2219                 if (scm_is_number ($4))
2220                 {
2221                         int q = scm_to_int ($4);
2222                         n->set_property ("absolute-octave", scm_from_int (q-1));
2223                 }
2224
2225                 if ($3 % 2)
2226                         n->set_property ("cautionary", SCM_BOOL_T);
2227                 if ($2 % 2 || $3 % 2)
2228                         n->set_property ("force-accidental", SCM_BOOL_T);
2229
2230                 $$ = n->unprotect ();
2231         }
2232         | DRUM_PITCH optional_notemode_duration {
2233                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2234                 n->set_property ("duration", $2);
2235                 n->set_property ("drum-type", $1);
2236
2237                 $$ = n->unprotect ();
2238         }
2239         | RESTNAME optional_notemode_duration           {
2240                 Music *ev = 0;
2241                 if (ly_scm2string ($1) == "s") {
2242                         /* Space */
2243                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2244                   }
2245                 else {
2246                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2247
2248                     }
2249                 ev->set_property ("duration", $2);
2250                 $$ = ev->unprotect ();
2251         }
2252         | lyric_element optional_notemode_duration      {
2253                 if (!PARSER->lexer_->is_lyric_state ())
2254                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2255
2256                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2257                 levent->set_property ("text", $1);
2258                 levent->set_property ("duration",$2);
2259                 $$= levent->unprotect ();
2260         }
2261         ;
2262
2263 simple_chord_elements:
2264         simple_element  {
2265                 $$ = scm_list_1 ($1);
2266         }
2267         | new_chord {
2268                 if (!PARSER->lexer_->is_chord_state ())
2269                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2270                 $$ = $1;
2271         }
2272         | figure_spec optional_notemode_duration {
2273                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2274                 {
2275                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2276                 }
2277                 $$ = $1;
2278         }
2279         ;
2280
2281 lyric_element:
2282         lyric_markup {
2283                 $$ = $1;
2284         }
2285         | LYRICS_STRING {
2286                 $$ = $1;
2287         }
2288         ;
2289
2290 new_chord:
2291         steno_tonic_pitch optional_notemode_duration   {
2292                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2293         }
2294         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2295                 SCM its = scm_reverse_x ($4, SCM_EOL);
2296                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2297         }
2298         ;
2299
2300 chord_items:
2301         /**/ {
2302                 $$ = SCM_EOL;
2303         }
2304         | chord_items chord_item {
2305                 $$ = scm_cons ($2, $$);
2306         }
2307         ;
2308
2309 chord_separator:
2310         CHORD_COLON {
2311                 $$ = ly_symbol2scm ("chord-colon");
2312         }
2313         | CHORD_CARET {
2314                 $$ = ly_symbol2scm ("chord-caret");
2315         }
2316         | CHORD_SLASH steno_tonic_pitch {
2317                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2318         }
2319         | CHORD_BASS steno_tonic_pitch {
2320                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2321         }
2322         ;
2323
2324 chord_item:
2325         chord_separator {
2326                 $$ = $1;
2327         }
2328         | step_numbers {
2329                 $$ = scm_reverse_x ($1, SCM_EOL);
2330         }
2331         | CHORD_MODIFIER  {
2332                 $$ = $1;
2333         }
2334         ;
2335
2336 step_numbers:
2337         step_number { $$ = scm_cons ($1, SCM_EOL); }
2338         | step_numbers '.' step_number {
2339                 $$ = scm_cons ($3, $$);
2340         }
2341         ;
2342
2343 step_number:
2344         bare_unsigned {
2345                 $$ = make_chord_step ($1, 0);
2346         }
2347         | bare_unsigned '+' {
2348                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2349         }
2350         | bare_unsigned CHORD_MINUS {
2351                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2352         }
2353         ;
2354
2355 tempo_range:
2356         bare_unsigned {
2357                 $$ = scm_from_int ($1);
2358         }
2359         | bare_unsigned '~' bare_unsigned {
2360                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2361         }
2362         ;
2363
2364 /*
2365         UTILITIES
2366
2367 TODO: should deprecate in favor of Scheme?
2368
2369  */
2370 number_expression:
2371         number_expression '+' number_term {
2372                 $$ = scm_sum ($1, $3);
2373         }
2374         | number_expression '-' number_term {
2375                 $$ = scm_difference ($1, $3);
2376         }
2377         | number_term
2378         ;
2379
2380 number_term:
2381         number_factor {
2382                 $$ = $1;
2383         }
2384         | number_factor '*' number_factor {
2385                 $$ = scm_product ($1, $3);
2386         }
2387         | number_factor '/' number_factor {
2388                 $$ = scm_divide ($1, $3);
2389         }
2390         ;
2391
2392 number_factor:
2393         '-'  number_factor { /* %prec UNARY_MINUS */
2394                 $$ = scm_difference ($2, SCM_UNDEFINED);
2395         }
2396         | bare_number
2397         ;
2398
2399
2400 bare_number:
2401         UNSIGNED        {
2402                 $$ = scm_from_int ($1);
2403         }
2404         | REAL          {
2405                 $$ = $1;
2406         }
2407         | NUMBER_IDENTIFIER             {
2408                 $$ = $1;
2409         }
2410         | REAL NUMBER_IDENTIFIER        {
2411                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2412         }
2413         | UNSIGNED NUMBER_IDENTIFIER    {
2414                 $$ = scm_from_double ($1 *scm_to_double ($2));
2415         }
2416         ;
2417
2418
2419 bare_unsigned:
2420         UNSIGNED {
2421                         $$ = $1;
2422         }
2423         ;
2424
2425 unsigned_number:
2426         bare_unsigned  { $$ = scm_from_int ($1); }
2427         | NUMBER_IDENTIFIER {
2428                 $$ = $1;
2429         }
2430         ;
2431
2432 exclamations:
2433                 { $$ = 0; }
2434         | exclamations '!'      { $$ ++; }
2435         ;
2436
2437 questions:
2438                 { $$ = 0; }
2439         | questions '?' { $$ ++; }
2440         ;
2441
2442 /*
2443 This should be done more dynamically if possible.
2444 */
2445
2446 lyric_markup:
2447         LYRIC_MARKUP_IDENTIFIER {
2448                 $$ = $1;
2449         }
2450         | LYRIC_MARKUP
2451                 { PARSER->lexer_->push_markup_state (); }
2452         markup_top {
2453                 $$ = $3;
2454                 PARSER->lexer_->pop_state ();
2455         }
2456         ;
2457
2458 full_markup_list:
2459         MARKUPLINES_IDENTIFIER {
2460                 $$ = $1;
2461         }
2462         | MARKUPLINES
2463                 { PARSER->lexer_->push_markup_state (); }
2464         markup_list {
2465                 $$ = $3;
2466                 PARSER->lexer_->pop_state ();
2467         }
2468         ;
2469
2470 full_markup:
2471         MARKUP_IDENTIFIER {
2472                 $$ = $1;
2473         }
2474         | MARKUP
2475                 { PARSER->lexer_->push_markup_state (); }
2476         markup_top {
2477                 $$ = $3;
2478                 PARSER->lexer_->pop_state ();
2479         }
2480         ;
2481
2482 markup_top:
2483         markup_list {
2484                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2485         }
2486         | markup_head_1_list simple_markup      {
2487                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2488         }
2489         | simple_markup {
2490                 $$ = $1;
2491         }
2492         ;
2493
2494 markup_list:
2495         MARKUPLINES_IDENTIFIER {
2496                 $$ = $1;
2497         }
2498         | markup_composed_list {
2499                 $$ = $1;
2500         }
2501         | markup_braced_list {
2502                 $$ = $1;
2503         }
2504         | markup_command_list {
2505                 $$ = scm_list_1 ($1);
2506         }
2507         ;
2508
2509 markup_composed_list:
2510         markup_head_1_list markup_braced_list {
2511                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2512
2513         }
2514         ;
2515
2516 markup_braced_list:
2517         '{' markup_braced_list_body '}' {
2518                 $$ = scm_reverse_x ($2, SCM_EOL);
2519         }
2520         ;
2521
2522 markup_braced_list_body:
2523         /* empty */     {  $$ = SCM_EOL; }
2524         | markup_braced_list_body markup {
2525                 $$ = scm_cons ($2, $1);
2526         }
2527         | markup_braced_list_body markup_list {
2528                 $$ = scm_reverse_x ($2, $1);
2529         }
2530         ;
2531
2532 markup_command_list:
2533         MARKUP_LIST_FUNCTION closed_markup_command_list_arguments {
2534           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2535         }
2536         ;
2537
2538 markup_command_basic_arguments:
2539         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2540           $$ = scm_cons ($3, $2);
2541         }
2542         | EXPECT_SCM markup_command_list_arguments closed_embedded_scm {
2543           $$ = scm_cons ($3, $2);
2544         }
2545         | EXPECT_NO_MORE_ARGS {
2546           $$ = SCM_EOL;
2547         }
2548         ;
2549
2550 closed_markup_command_list_arguments:
2551         markup_command_basic_arguments { $$ = $1; }
2552         | EXPECT_MARKUP markup_command_list_arguments markup {
2553           $$ = scm_cons ($3, $2);
2554         }
2555         ;
2556
2557 markup_command_list_arguments:
2558         closed_markup_command_list_arguments
2559         | EXPECT_SCM markup_command_list_arguments open_scm_function_call
2560         {
2561           $$ = scm_cons ($3, $2);
2562         }
2563         ;
2564
2565 markup_head_1_item:
2566         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2567           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2568         }
2569         ;
2570
2571 markup_head_1_list:
2572         markup_head_1_item      {
2573                 $$ = scm_list_1 ($1);
2574         }
2575         | markup_head_1_list markup_head_1_item {
2576                 $$ = scm_cons ($2, $1);
2577         }
2578         ;
2579
2580 simple_markup:
2581         STRING {
2582                 $$ = make_simple_markup ($1);
2583         }
2584         | MARKUP_IDENTIFIER {
2585                 $$ = $1;
2586         }
2587         | LYRIC_MARKUP_IDENTIFIER {
2588                 $$ = $1;
2589         }
2590         | STRING_IDENTIFIER {
2591                 $$ = $1;
2592         }
2593         | SCORE {
2594                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2595                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2596         } '{' score_body '}' {
2597                 Score * sc = $4;
2598                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2599                 sc->unprotect ();
2600                 PARSER->lexer_->pop_state ();
2601         }
2602         | MARKUP_FUNCTION markup_command_basic_arguments {
2603                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2604         }
2605         ;
2606
2607 markup:
2608         markup_head_1_list simple_markup        {
2609                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2610                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2611         }
2612         | simple_markup {
2613                 $$ = $1;
2614         }
2615         ;
2616
2617 %%
2618
2619 void
2620 Lily_parser::set_yydebug (bool x)
2621 {
2622         yydebug = x;
2623 }
2624
2625 void
2626 Lily_parser::do_yyparse ()
2627 {
2628         yyparse ((void*)this);
2629 }
2630
2631
2632
2633
2634
2635 /*
2636
2637 It is a little strange to have this function in this file, but
2638 otherwise, we have to import music classes into the lexer.
2639
2640 */
2641 int
2642 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2643 {
2644         if (scm_is_string (sid)) {
2645                 *destination = sid;
2646                 return STRING_IDENTIFIER;
2647         } else if (unsmob_book (sid)) {
2648                 Book *book =  unsmob_book (sid)->clone ();
2649                 *destination = book->self_scm ();
2650                 book->unprotect ();
2651
2652                 return BOOK_IDENTIFIER;
2653         } else if (scm_is_number (sid)) {
2654                 *destination = sid;
2655                 return NUMBER_IDENTIFIER;
2656         } else if (unsmob_context_def (sid)) {
2657                 Context_def *def= unsmob_context_def (sid)->clone ();
2658
2659                 *destination = def->self_scm ();
2660                 def->unprotect ();
2661
2662                 return CONTEXT_DEF_IDENTIFIER;
2663         } else if (unsmob_context_mod (sid)) {
2664                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2665
2666                 return CONTEXT_MOD_IDENTIFIER;
2667         } else if (unsmob_score (sid)) {
2668                 Score *score = new Score (*unsmob_score (sid));
2669                 *destination = score->self_scm ();
2670
2671                 score->unprotect ();
2672                 return SCORE_IDENTIFIER;
2673         } else if (Music *mus = unsmob_music (sid)) {
2674                 mus = mus->clone ();
2675                 *destination = mus->self_scm ();
2676                 unsmob_music (*destination)->
2677                         set_property ("origin", make_input (last_input_));
2678
2679                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2680                         != SCM_BOOL_F;
2681
2682                 mus->unprotect ();
2683                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2684         } else if (unsmob_duration (sid)) {
2685                 *destination = unsmob_duration (sid)->smobbed_copy ();
2686                 return DURATION_IDENTIFIER;
2687         } else if (unsmob_output_def (sid)) {
2688                 Output_def *p = unsmob_output_def (sid);
2689                 p = p->clone ();
2690
2691                 *destination = p->self_scm ();
2692                 p->unprotect ();
2693                 return OUTPUT_DEF_IDENTIFIER;
2694         } else if (Text_interface::is_markup (sid)) {
2695                 *destination = sid;
2696                 if (is_lyric_state ())
2697                         return LYRIC_MARKUP_IDENTIFIER;
2698                 return MARKUP_IDENTIFIER;
2699         } else if (Text_interface::is_markup_list (sid)) {
2700                 *destination = sid;
2701                 return MARKUPLINES_IDENTIFIER;
2702         }
2703
2704         return -1;
2705 }
2706
2707 SCM
2708 get_next_unique_context_id ()
2709 {
2710         return scm_from_locale_string ("$uniqueContextId");
2711 }
2712
2713
2714 SCM
2715 get_next_unique_lyrics_context_id ()
2716 {
2717         static int new_context_count;
2718         char s[128];
2719         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2720         return scm_from_locale_string (s);
2721 }
2722
2723
2724 SCM
2725 run_music_function (Lily_parser *parser, Input loc, SCM func, SCM args)
2726 {
2727         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2728
2729         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2730
2731         if (!to_boolean (scm_call_3  (type_check_proc, make_input (loc), scm_cdr (sig), args)))
2732         {
2733                 parser->error_level_ = 1;
2734                 return LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("void-music"), scm_list_2 (parser->self_scm (), make_input (loc)));
2735         }
2736
2737         SCM syntax_args = scm_list_4 (parser->self_scm (), make_input (loc), func, args);
2738         return LOWLEVEL_MAKE_SYNTAX (scm_car (sig), syntax_args);
2739 }
2740
2741 bool
2742 is_regular_identifier (SCM id)
2743 {
2744   string str = ly_scm2string (id);
2745   char const *s = str.c_str ();
2746
2747   bool v = true;
2748 #if 0
2749   isalpha (*s);
2750   s++;
2751 #endif
2752   while (*s && v)
2753    {
2754         v = v && isalnum (*s);
2755         s++;
2756    }
2757   return v;
2758 }
2759
2760 Music *
2761 make_music_with_input (SCM name, Input where)
2762 {
2763        Music *m = make_music_by_name (name);
2764        m->set_spot (where);
2765        return m;
2766 }
2767
2768 SCM
2769 get_first_context_id (SCM type, Music *m)
2770 {
2771         SCM id = m->get_property ("context-id");
2772         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2773             && scm_is_string (m->get_property ("context-id"))
2774             && scm_c_string_length (id) > 0)
2775         {
2776                 return id;
2777         }
2778         return SCM_EOL;
2779 }
2780
2781 SCM
2782 make_simple_markup (SCM a)
2783 {
2784         return a;
2785 }
2786
2787 bool
2788 is_duration (int t)
2789 {
2790   return t && t == 1 << intlog2 (t);
2791 }
2792
2793 void
2794 set_music_properties (Music *p, SCM a)
2795 {
2796   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2797         p->set_property (scm_caar (k), scm_cdar (k));
2798 }
2799
2800
2801 SCM
2802 make_chord_step (int step, Rational alter)
2803 {
2804         if (step == 7)
2805                 alter += FLAT_ALTERATION;
2806
2807         while (step < 0)
2808                 step += 7;
2809         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2810         return m.smobbed_copy ();
2811 }
2812
2813
2814 SCM
2815 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
2816 {
2817         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
2818         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
2819 }
2820
2821
2822 /* Todo: actually also use apply iso. call too ...  */
2823 bool
2824 ly_input_procedure_p (SCM x)
2825 {
2826         return ly_is_procedure (x)
2827                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2828 }
2829
2830 SCM
2831 make_music_relative (Pitch start, SCM music, Input loc)
2832 {
2833         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic", loc);
2834         relative->set_property ("element", music);
2835
2836         Music *m = unsmob_music (music);
2837         Pitch last = m->to_relative_octave (start);
2838         if (lily_1_8_relative)
2839                 m->set_property ("last-pitch", last.smobbed_copy ());
2840         return relative->unprotect ();
2841 }
2842
2843 int
2844 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2845 {
2846         Lily_parser *pars = (Lily_parser*) v;
2847         Lily_lexer *lex = pars->lexer_;
2848
2849         lex->lexval_ = (void*) s;
2850         lex->lexloc_ = loc;
2851         lex->prepare_for_next_token ();
2852         return lex->yylex ();
2853 }