lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "translator-def.hh"
  14 #include "lily-guile.hh"
  15
  16 #include "lookup.hh"
  17 #include "misc.hh"
  18 #include "my-lily-lexer.hh"
  19 #include "paper-def.hh"
  20 #include "midi-def.hh"
  21 #include "main.hh"
  22 #include "file-path.hh"
  23 #include "debug.hh"
  24 #include "dimensions.hh"
  25 #include "identifier.hh"
  26 #include "command-request.hh"
  27 #include "musical-request.hh"
  28 #include "my-lily-parser.hh"
  29 #include "context-specced-music.hh"
  30 #include "score.hh"
  31 #include "music-list.hh"
  32
  33 #include "file-results.hh"
  34 #include "input.hh"
  35 #include "scope.hh"
  36 #include "relative-music.hh"
  37 #include "lyric-combine-music.hh"
  38 #include "transposed-music.hh"
  39 #include "time-scaled-music.hh"
  40 #include "repeated-music.hh"
  41 #include "mudela-version.hh"
  42 #include "grace-music.hh"
  43 #include "auto-change-music.hh"
  44 #include "part-combine-music.hh"
  45
  46 #include "chord.hh"
  47
  48 bool
  49 is_duration_b (int t)
  50 {
  51   return t && t == 1 << intlog2(t);
  52 }
  53
  54
  55 // mmm JUNKME ?
  56 Mudela_version oldest_version ("1.3.59");
  57
  58 void
  59 print_mudela_versions (ostream &os)
  60 {
  61   os << _f ("Oldest supported input version: %s", oldest_version.str ())
  62     << endl;
  63 }
  64
  65
  66 // needed for bison.simple's malloc() and free()
  67 #include <malloc.h>
  68
  69 #ifndef NDEBUG
  70 #define YYDEBUG 1
  71 #endif
  72
  73 #define YYERROR_VERBOSE 1
  74
  75 #define YYPARSE_PARAM my_lily_parser_l
  76 #define YYLEX_PARAM my_lily_parser_l
  77 #define THIS ((My_lily_parser *) my_lily_parser_l)
  78
  79 #define yyerror THIS->parser_error
  80 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
  81
  82 %}
  83
  84
  85 %union {
  86     Array<Musical_pitch> *pitch_arr;
  87     Link_array<Request> *reqvec;
  88     Duration *duration;
  89     Identifier *id;
  90     String * string;
  91     Music *music;
  92     Score *score;
  93     Scope *scope;
  94
  95     Musical_req* musreq;
  96     Music_output_def * outputdef;
  97     Musical_pitch * pitch;
  98     Midi_def* midi;
  99     Real real;
 100     Request * request;
 101
 102     /* We use SCMs to do strings, because it saves us the trouble of
 103 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 104 of the parse stack onto the heap. */
 105
 106     SCM scm;
 107
 108     Tempo_req *tempo;
 109     int i;
 110 }
 111 %{
 112
 113 int
 114 yylex (YYSTYPE *s,  void * v_l)
 115 {
 116         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 117         My_lily_lexer * lex_l = pars_l->lexer_p_;
 118
 119         lex_l->lexval_l = (void*) s;
 120         return lex_l->yylex ();
 121 }
 122
 123
 124 %}
 125
 126 %pure_parser
 127
 128 /* tokens which are not keywords */
 129 %token AUTOCHANGE
 130 %token APPLY
 131 %token ARPEGGIO
 132 %token DYNAMICSCRIPT
 133 %token TEXTSCRIPT
 134 %token ACCEPTS
 135 %token ALTERNATIVE
 136 %token BAR
 137 %token BREATHE
 138 %token CHORDMODIFIERS
 139 %token CHORDS
 140 %token CHAR_T
 141 %token CLEF
 142 %token CM_T
 143 %token CONSISTS
 144 %token SEQUENTIAL
 145 %token ELEMENTDESCRIPTIONS
 146 %token SIMULTANEOUS
 147 %token CONSISTSEND
 148 %token DENIES
 149 %token DURATION
 150 %token EXTENDER
 151 %token FONT
 152 %token GRACE
 153 %token HEADER
 154 %token HYPHEN
 155 %token IN_T
 156 %token INVALID
 157 %token KEY
 158 %token LYRICS
 159 %token MARK
 160 %token MEASURES
 161 %token MIDI
 162 %token MM_T
 163 %token MUSICAL_PITCH
 164 %token NAME
 165 %token NOTENAMES
 166 %token NOTES
 167 %token PAPER
 168 %token PARTIAL
 169 %token PENALTY
 170 %token PROPERTY
 171 %token PUSH POP
 172 %token PT_T
 173 %token RELATIVE
 174 %token REMOVE
 175 %token REPEAT
 176 %token ADDLYRICS
 177 %token PARTCOMBINE
 178 %token SCM_T
 179 %token SCORE
 180 %token SCRIPT
 181 %token SKIP
 182 %token SPANREQUEST
 183 %token STYLESHEET
 184 %token COMMANDSPANREQUEST
 185 %token TEMPO
 186 %token OUTPUTPROPERTY
 187 %token TIME_T
 188 %token TIMES
 189 %token TRANSLATOR
 190 %token TRANSPOSE
 191 %token TYPE
 192 %token CONTEXT
 193
 194 /* escaped */
 195 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER
 196 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 197
 198 %type <i>       exclamations questions
 199 %token <i>      DIGIT
 200 %token <pitch>  NOTENAME_PITCH
 201 %token <pitch>  TONICNAME_PITCH
 202 %token <pitch>  CHORDMODIFIER_PITCH
 203 %token <id>     DURATION_IDENTIFIER
 204 %token <id>     IDENTIFIER
 205
 206
 207 %token <id>     SCORE_IDENTIFIER
 208 %token <id>     MUSIC_OUTPUT_DEF_IDENTIFIER
 209
 210 %token <scm>    NUMBER_IDENTIFIER
 211 %token <scm>    REQUEST_IDENTIFIER
 212 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 213 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 214 %token <scm>    DURATION RESTNAME
 215 %token <scm>    STRING
 216 %token <scm>    SCM_T
 217 %token <i>      UNSIGNED
 218 %token <real>   REAL
 219
 220 %type <outputdef> output_def
 221 %type <scope>   mudela_header mudela_header_body
 222 %type <request> open_request_parens close_request_parens open_request close_request
 223 %type <request> request_with_dir request_that_take_dir verbose_request
 224 %type <i>       sub_quotes sup_quotes
 225 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 226 %type <music>   Alternative_music Repeated_music
 227 %type <i>       tremolo_type
 228 %type <i>       bare_int  bare_unsigned
 229 %type <i>       script_dir
 230
 231 %type <scm>     identifier_init
 232
 233 %type <duration> steno_duration optional_notemode_duration
 234 %type <duration> entered_notemode_duration explicit_duration
 235
 236 %type <reqvec>  pre_requests post_requests
 237 %type <request> gen_text_def
 238 %type <pitch>   steno_musical_pitch musical_pitch absolute_musical_pitch
 239 %type <pitch>   steno_tonic_pitch
 240
 241 %type <pitch_arr>       chord_additions chord_subtractions chord_notes chord_step
 242 %type <music>   chord
 243 %type <pitch>   chord_note chord_inversion chord_bass
 244 %type <duration>        duration_length
 245
 246 %type <scm>  embedded_scm scalar
 247 %type <music>   Music Sequential_music Simultaneous_music Music_sequence
 248 %type <music>   relative_music re_rhythmed_music part_combined_music
 249 %type <music>   property_def translator_change
 250 %type <scm> Music_list
 251 %type <outputdef>  music_output_def_body
 252 %type <request> shorthand_command_req
 253 %type <request> post_request
 254 %type <request> command_req verbose_command_req
 255 %type <request> extender_req
 256 %type <request> hyphen_req
 257 %type <scm>     string bare_number number_expression
 258 %type <score>   score_block score_body
 259
 260 %type <scm>     translator_spec_block translator_spec_body
 261 %type <tempo>   tempo_request
 262 %type <scm> notenames_body notenames_block chordmodifiers_block
 263 %type <scm>     script_abbreviation
 264
 265
 266
 267 %left '-' '+'
 268 %left '*' '/'
 269 %left UNARY_MINUS
 270
 271 %%
 272
 273 mudela: /* empty */
 274         | mudela toplevel_expression {}
 275         | mudela assignment  { }
 276         | mudela error {
 277                 THIS->error_level_i_  = 1;
 278                 //THIS->parser_error (_ ("ly invalid"));
 279         }
 280         | mudela INVALID        {
 281                 THIS->error_level_i_  = 1;
 282                 //THIS->parser_error (_ ("ly invalid"));
 283         }
 284         ;
 285
 286 toplevel_expression:
 287         notenames_block                 {
 288                 THIS->lexer_p_->pitchname_tab_ =  $1;
 289         }
 290         | chordmodifiers_block                  {
 291                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 292         }
 293         | mudela_header {
 294                 delete header_global_p;
 295                 header_global_p = $1;
 296         }
 297         | score_block {
 298                 score_global_array.push ($1);
 299         }
 300         | output_def {
 301                 Identifier * id = new
 302                         Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER);
 303                 if (dynamic_cast<Paper_def*> ($1))
 304                         THIS->lexer_p_->set_identifier ("$defaultpaper", id->self_scm ());
 305                 else if (dynamic_cast<Midi_def*> ($1))
 306                         THIS->lexer_p_->set_identifier ("$defaultmidi", id->self_scm ());
 307         }
 308         | embedded_scm {
 309                 // junk value
 310         }
 311         ;
 312
 313 embedded_scm:
 314         SCM_T
 315         | SCM_IDENTIFIER
 316         ;
 317
 318
 319 chordmodifiers_block:
 320         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 321         ;
 322
 323
 324 notenames_block:
 325         NOTENAMES notenames_body   {  $$ = $2; }
 326         ;
 327
 328
 329
 330 notenames_body:
 331         embedded_scm    {
 332           int i = scm_ilength ($1);
 333
 334           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 335           for (SCM s = $1; s != SCM_EOL; s = gh_cdr (s)) {
 336                 SCM pt = gh_cdar (s);
 337                 if (scm_ilength (pt) != 3)
 338                         THIS->parser_error ("Need three args");
 339                 scm_hashq_set_x (tab, gh_caar(s), pt);
 340           }
 341
 342           $$ = tab;
 343         }
 344         ;
 345
 346 mudela_header_body:
 347         {
 348                 $$ = new Scope;
 349                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 350         }
 351         | mudela_header_body assignment semicolon {
 352
 353         }
 354         ;
 355
 356 mudela_header:
 357         HEADER '{' mudela_header_body '}'       {
 358                 $$ = $3;
 359                 THIS->lexer_p_-> scope_l_arr_.pop ();
 360         }
 361         ;
 362
 363
 364 /*
 365         DECLARATIONS
 366 */
 367 assignment:
 368         STRING {
 369                 THIS->remember_spot ();
 370         }
 371         /* cont */ '=' identifier_init  {
 372                 THIS->lexer_p_->set_identifier (ly_scm2string ($1), $4);
 373
 374 /*
 375  TODO: devise standard for protection in parser.
 376
 377   The parser stack lives on the C-stack, which means that
 378 all objects can be unprotected as soon as they're here.
 379
 380 */
 381                 Identifier * id =unsmob_identifier ($4);
 382                 Input spot = THIS->pop_spot ();
 383                 if (id) id->set_spot (spot);
 384         }
 385         ;
 386
 387
 388
 389 identifier_init:
 390         score_block {
 391                 $$ = (new Score_identifier ($1, SCORE_IDENTIFIER))->self_scm();
 392         }
 393         | output_def {
 394                 $$ = (new Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER))->self_scm();
 395         }
 396         | translator_spec_block {
 397                 $$ = $1;
 398         }
 399         | Music  {
 400                 $$ = $1->self_scm ();
 401                 scm_unprotect_object ($$);
 402         }
 403         | post_request {
 404                 $$ = $1->self_scm ();
 405                 scm_unprotect_object ($$);
 406         }
 407         | explicit_duration {
 408                 $$ = (new Duration_identifier ($1, DURATION_IDENTIFIER))->self_scm ();
 409         }
 410         | number_expression {
 411                 $$ = $1;
 412         }
 413         | string {
 414                 $$ = $1;
 415         }
 416         | embedded_scm  {
 417                 $$ = $1;
 418         }
 419         ;
 420
 421 translator_spec_block:
 422         TRANSLATOR '{' translator_spec_body '}'
 423                 {
 424                 $$ = $3;
 425         }
 426         ;
 427
 428 translator_spec_body:
 429         TRANSLATOR_IDENTIFIER   {
 430                 $$ = unsmob_translator_def ($1)->clone_scm ();
 431                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 432         }
 433         | TYPE STRING semicolon {
 434                 $$ = Translator_def::make_scm ();
 435                 Translator_def*td =  unsmob_translator_def ($$);
 436                 td->translator_group_type_ = $2;
 437                 td->set_spot (THIS->here_input ());
 438         }
 439         | translator_spec_body STRING '=' embedded_scm                  {
 440                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 441         }
 442         | translator_spec_body STRING PUSH embedded_scm '=' embedded_scm {
 443                 unsmob_translator_def ($$)
 444                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 445         }
 446         | translator_spec_body STRING POP embedded_scm  {
 447           unsmob_translator_def($$)->add_pop_property (
 448                 scm_string_to_symbol ($2), $4);
 449         }
 450         | translator_spec_body STRING '=' identifier_init semicolon     {
 451                 SCM v = gh_int2scm (0);
 452                 if (gh_string_p ($4) || gh_number_p ($4) || gh_boolean_p ($4))
 453                         v = $4;
 454                 else
 455                         THIS->parser_error (_("Wrong type for property value"));
 456
 457                 /* ugh*/
 458                 unsmob_translator_def($$)->add_property_assign ($2, v);
 459         }
 460         | translator_spec_body NAME STRING semicolon {
 461                 unsmob_translator_def ($$)->type_name_ = $3;
 462         }
 463         | translator_spec_body CONSISTS STRING semicolon {
 464                 unsmob_translator_def ($$)->add_element ($3);
 465         }
 466         | translator_spec_body ELEMENTDESCRIPTIONS embedded_scm {
 467                 for (SCM p = $3; gh_pair_p (p); p = gh_cdr (p))
 468                         unsmob_translator_def ($$)
 469                         ->add_property_assign (scm_symbol_to_string (gh_caar (p)), gh_cdar (p));
 470
 471         }
 472         | translator_spec_body CONSISTSEND STRING semicolon {
 473                 unsmob_translator_def ($$)->add_last_element ( $3);
 474         }
 475         | translator_spec_body ACCEPTS STRING semicolon {
 476                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 477         }
 478         | translator_spec_body DENIES STRING semicolon {
 479                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 480         }
 481         | translator_spec_body REMOVE STRING semicolon {
 482                 unsmob_translator_def ($$)->remove_element ($3);
 483         }
 484         ;
 485
 486 /*
 487         SCORE
 488 */
 489 score_block:
 490         SCORE {
 491                 THIS->remember_spot ();
 492         }
 493         /*cont*/ '{' score_body '}'     {
 494                 THIS->pop_spot ();
 495                 $$ = $4;
 496                 if (!$$->def_p_arr_.size ())
 497                 {
 498                   Identifier *id =
 499                         unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 500                   $$->add_output (id ? id->access_content_Music_output_def (true) : new Paper_def );
 501                 }
 502         }
 503 /*
 504         | SCORE '{' score_body error {
 505                 $$ = $3
 506                 $$->set_spot (THIS->here_input ());
 507                 // THIS->here_input ().error ("SCORE INVALID");
 508                 $$->error ("SCORE INVALID");
 509                 THIS->parser_error (_f ("SCORE ERROR"));
 510         }
 511 */
 512         ;
 513
 514 score_body:
 515         Music   {
 516                 $$ = new Score;
 517
 518                 $$->set_spot (THIS->here_input ());
 519                 SCM m = $1->self_scm ();
 520                 scm_unprotect_object (m);
 521                 $$->music_ = m;
 522         }
 523         | SCORE_IDENTIFIER {
 524                 $$ = $1->access_content_Score (true);
 525         }
 526         | score_body mudela_header      {
 527                 $$->header_p_ = $2;
 528         }
 529         | score_body output_def {
 530                 $$->add_output ($2);
 531         }
 532         | score_body error {
 533
 534         }
 535         ;
 536
 537
 538 /*
 539         MIDI
 540 */
 541 output_def:
 542         music_output_def_body '}' {
 543                 $$ = $1;
 544                 THIS-> lexer_p_-> scope_l_arr_.pop();
 545         }
 546         ;
 547
 548 music_output_def_body:
 549         MIDI '{'    {
 550          Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 551
 552
 553          Midi_def* p =0;
 554         if (id)
 555                 p = dynamic_cast<Midi_def*> (id->access_content_Music_output_def (true));
 556         else
 557                 p = new Midi_def;
 558
 559          $$ = p;
 560          THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 561         }
 562         | PAPER '{'     {
 563                   Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 564                   Paper_def *p = 0;
 565                 if (id)
 566                         p = dynamic_cast<Paper_def*> (id->access_content_Music_output_def (true));
 567                 else
 568                         p = new Paper_def;
 569                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 570                 $$ = p;
 571         }
 572         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 573                 Music_output_def *p = $3->access_content_Music_output_def (true);
 574                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 575                 $$ = p;
 576         }
 577         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 578                 Music_output_def *p = $3->access_content_Music_output_def (true);
 579                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 580                 $$ = p;
 581         }
 582         | music_output_def_body assignment semicolon {
 583
 584         }
 585         | music_output_def_body translator_spec_block   {
 586                 $$->assign_translator ($2);
 587         }
 588         | music_output_def_body STYLESHEET embedded_scm {
 589                 dynamic_cast<Paper_def*> ($$)-> style_sheet_ = $3;
 590         }
 591         | music_output_def_body tempo_request semicolon {
 592                 /*
 593                         junk this ? there already is tempo stuff in
 594                         music.
 595                 */
 596                 dynamic_cast<Midi_def*> ($$)->set_tempo ($2->dur_.length_mom (), $2->metronome_i_);
 597         }
 598         | music_output_def_body error {
 599
 600         }
 601         ;
 602
 603 tempo_request:
 604         TEMPO steno_duration '=' bare_unsigned  {
 605                 $$ = new Tempo_req;
 606                 $$->dur_ = *$2;
 607                 delete $2;
 608                 $$-> metronome_i_ = $4;
 609         }
 610         ;
 611
 612 Music_list: /* empty */ {
 613                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 614         }
 615         | Music_list Music {
 616                 SCM s = $$;
 617                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 618                 scm_unprotect_object ($2->self_scm ()); /* UGH */
 619
 620
 621                 if (gh_pair_p (gh_cdr (s)))
 622                         gh_set_cdr_x (gh_cdr (s), c); /* append */
 623                 else
 624                         gh_set_car_x (s, c); /* set first cons */
 625                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 626         }
 627         | Music_list error {
 628         }
 629         ;
 630
 631
 632 Music:
 633         Simple_music
 634         | Composite_music
 635         ;
 636
 637 Alternative_music:
 638         /* empty */ {
 639                 $$ = 0;
 640         }
 641         | ALTERNATIVE Music_sequence {
 642                 $$ = $2;
 643                 $2->set_spot (THIS->here_input ());
 644         }
 645         ;
 646
 647
 648
 649
 650 Repeated_music:
 651         REPEAT STRING bare_unsigned Music Alternative_music
 652         {
 653                 Music_sequence* m = dynamic_cast <Music_sequence*> ($5);
 654                 if (m && $3 < m->length_i ())
 655                         $5->origin ()->warning (_ ("More alternatives than repeats.  Junking excess alternatives."));
 656
 657                 Repeated_music * r = new Repeated_music ($4, $3 >? 1, m);
 658                 $$ = r;
 659                 r->type_ = ly_scm2string ($2);
 660                 r->fold_b_ = (r->type_ == "fold");
 661                 r->volta_fold_b_ =  (r->type_ == "volta");
 662                 r->set_spot (*$4->origin ());
 663         }
 664         ;
 665
 666 Music_sequence: '{' Music_list '}'      {
 667                 $$ = new Music_sequence (gh_car ($2));
 668         }
 669         ;
 670
 671 Sequential_music:
 672         SEQUENTIAL '{' Music_list '}'           {
 673                 $$ = new Sequential_music (gh_car ($3));
 674         }
 675         | '{' Music_list '}'            {
 676                 $$ = new Sequential_music (gh_car ($2));
 677         }
 678         ;
 679
 680 Simultaneous_music:
 681         SIMULTANEOUS '{' Music_list '}'{
 682                 $$ = new Simultaneous_music (gh_car ($3));
 683         }
 684         | '<' Music_list '>'    {
 685                 $$ = new Simultaneous_music (gh_car ($2));
 686         }
 687         ;
 688
 689 Simple_music:
 690         request_chord           { $$ = $1; }
 691         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 692                 SCM pred = $2;
 693                 if (!gh_symbol_p ($3))
 694                 {
 695                         THIS->parser_error (_("Second argument must be a symbol"));
 696                 }
 697                 /*hould check # args */
 698                 if (!gh_procedure_p (pred))
 699                 {
 700                         THIS->parser_error (_("First argument must be a procedure taking 1 argument"));
 701                 }
 702
 703           Music *m = new Music;
 704           m->set_mus_property ("predicate", pred);
 705           m->set_mus_property ("symbol", $3);
 706           m->set_mus_property ("value",  $5);
 707           m->set_mus_property ("type", ly_symbol2scm ("output-property"));
 708
 709                 $$ = m;
 710         }
 711         | MUSIC_IDENTIFIER {
 712                 $$ = unsmob_music ($1)->clone ();
 713         }
 714         | property_def
 715         | translator_change
 716         | Simple_music '*' bare_unsigned '/' bare_unsigned      {
 717                 $$ = $1;
 718                 $$->compress (Moment($3, $5 ));
 719         }
 720         | Simple_music '*' bare_unsigned                 {
 721                 $$ = $1;
 722                 $$->compress (Moment ($3, 1));
 723         }
 724         ;
 725
 726
 727 Composite_music:
 728         CONTEXT STRING Music    {
 729                 Context_specced_music *csm =  new Context_specced_music ($3);
 730
 731                 csm->translator_type_str_ = ly_scm2string ($2);
 732                 csm->translator_id_str_ = "";
 733
 734
 735                 $$ = csm;
 736         }
 737         | AUTOCHANGE STRING Music       {
 738                 Auto_change_music * chm = new Auto_change_music ($3);
 739                 chm->set_mus_property ("what", $2);
 740
 741                 $$ = chm;
 742                 chm->set_spot (*$3->origin ());
 743         }
 744         | GRACE Music {
 745                 $$ = new Grace_music ($2);
 746         }
 747         | CONTEXT STRING '=' STRING Music {
 748                 Context_specced_music *csm =  new Context_specced_music ($5);
 749
 750                 csm->translator_type_str_ = ly_scm2string ($2);
 751                 csm->translator_id_str_ = ly_scm2string ($4);
 752
 753                 $$ = csm;
 754         }
 755         | TIMES {
 756                 THIS->remember_spot ();
 757         }
 758         /* CONTINUED */
 759                 bare_unsigned '/' bare_unsigned Music
 760
 761         {
 762                 $$ = new Time_scaled_music ($3, $5, $6);
 763                 $$->set_spot (THIS->pop_spot ());
 764         }
 765         | Repeated_music                { $$ = $1; }
 766         | Simultaneous_music            { $$ = $1; }
 767         | Sequential_music              { $$ = $1; }
 768         | TRANSPOSE musical_pitch Music {
 769                 $$ = new Transposed_music ($3, *$2);
 770                 delete $2; // ugh
 771         }
 772         | TRANSPOSE steno_tonic_pitch Music {
 773                 $$ = new Transposed_music ($3, *$2);
 774                 delete $2; // ugh
 775         }
 776         | APPLY embedded_scm Music  {
 777                 SCM ret = gh_call1 ($2, $3->self_scm ());
 778                 Music *m = unsmob_music (ret);
 779                 if (!m) {
 780                         THIS->parser_error ("\\apply must return a Music");
 781                         m = new Music ();
 782                         }
 783                 $$ = m;
 784         }
 785         | NOTES
 786                 { THIS->lexer_p_->push_note_state (); }
 787         Music
 788                 { $$ = $3;
 789                   THIS->lexer_p_->pop_state ();
 790                 }
 791         | CHORDS
 792                 { THIS->lexer_p_->push_chord_state (); }
 793         Music
 794                 {
 795                   $$ = $3;
 796                   THIS->lexer_p_->pop_state ();
 797         }
 798         | LYRICS
 799                 { THIS->lexer_p_->push_lyric_state (); }
 800         Music
 801                 {
 802                   $$ = $3;
 803                   THIS->lexer_p_->pop_state ();
 804         }
 805         | relative_music        { $$ = $1; }
 806         | re_rhythmed_music     { $$ = $1; }
 807         | part_combined_music   { $$ = $1; }
 808         ;
 809
 810 relative_music:
 811         RELATIVE absolute_musical_pitch Music {
 812                 $$ = new Relative_octave_music ($3, *$2);
 813                 delete $2; // ugh
 814         }
 815         ;
 816
 817 re_rhythmed_music:
 818         ADDLYRICS Music Music {
 819                 Lyric_combine_music * l = new Lyric_combine_music ($2, $3);
 820                 $$ = l;
 821         }
 822         ;
 823
 824 part_combined_music:
 825         PARTCOMBINE STRING Music Music {
 826                 Part_combine_music * p = new Part_combine_music (ly_scm2string ($2), $3, $4);
 827                 $$ = p;
 828         }
 829         ;
 830
 831 translator_change:
 832         TRANSLATOR STRING '=' STRING  {
 833                 Music * t = new Music;
 834                 t->set_mus_property ("type",
 835                         ly_symbol2scm ("change-translator"));
 836                 t-> set_mus_property ("change-to-type", $2);
 837                 t-> set_mus_property ("change-to-id", $4);
 838
 839                 $$ = t;
 840                 $$->set_spot (THIS->here_input ());
 841         }
 842         ;
 843
 844 property_def:
 845         PROPERTY STRING '.' STRING '='  scalar {
 846                 Music *t = new Music;
 847
 848                 t->set_mus_property ("type", ly_symbol2scm ("property-set"));
 849                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
 850                 t->set_mus_property ("value", $6);
 851
 852                 Context_specced_music *csm = new Context_specced_music (t);
 853                 $$ = csm;
 854                 $$->set_spot (THIS->here_input ());
 855
 856                 csm-> translator_type_str_ = ly_scm2string ($2);
 857         }
 858         | PROPERTY STRING '.' STRING PUSH embedded_scm '=' embedded_scm {
 859                 Music *t = new Music;
 860                 t->set_mus_property ("type", ly_symbol2scm ("property-push"));
 861                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 862                 t->set_mus_property ("element-property", $6);
 863                 t->set_mus_property ("element-value", $8);
 864                 Context_specced_music *csm = new Context_specced_music (t);
 865                 $$ = csm;
 866                 $$->set_spot (THIS->here_input ());
 867
 868                 csm-> translator_type_str_ = ly_scm2string ($2);
 869         }
 870         | PROPERTY STRING '.' STRING POP embedded_scm {
 871                 Music *t = new Music;
 872                 t->set_mus_property ("type", ly_symbol2scm ("property-pop"));
 873                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 874                 t->set_mus_property ("element-property", $6);
 875
 876                 Context_specced_music *csm = new Context_specced_music (t);
 877                 $$ = csm;
 878                 $$->set_spot (THIS->here_input ());
 879
 880                 csm-> translator_type_str_ = ly_scm2string ($2);
 881         }
 882         ;
 883
 884 scalar:
 885         string          { $$ = $1; }
 886         | bare_int      { $$ = gh_int2scm ($1); }
 887         | embedded_scm  { $$ = $1; }
 888         ;
 889
 890
 891 request_chord:
 892         pre_requests simple_element post_requests       {
 893                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 894                 if (l) {
 895                         for (int i=0; i < $1->size(); i++)
 896                                 l->append_music ($1->elem(i));
 897                         for (int i=0; i < $3->size(); i++)
 898                                 l->append_music ($3->elem(i));
 899                         }
 900                 else
 901                         programming_error ("Need Sequence to add music to");
 902                 $$ = $2;
 903
 904         }
 905         | command_element
 906         ;
 907
 908 command_element:
 909         command_req {
 910                 $$ = new Request_chord (gh_cons ($1->self_scm (), SCM_EOL));
 911                 $$-> set_spot (THIS->here_input ());
 912                 $1-> set_spot (THIS->here_input ());
 913         }
 914         | PARTIAL duration_length ';'   {
 915                 Music * p = new Music;
 916                 p->set_mus_property ("symbol", ly_symbol2scm ( "measurePosition"));
 917                 p->set_mus_property ("type", ly_symbol2scm ("property-set"));
 918
 919                 Moment m = - $2->length_mom ();
 920                 p->set_mus_property ("value", m.make_scm());
 921                 delete $2; // ugh
 922                 Context_specced_music * sp = new Context_specced_music (p);
 923                 $$ =sp ;
 924                 sp-> translator_type_str_ = "Score";
 925         }
 926         ;
 927
 928 command_req:
 929         shorthand_command_req
 930         | verbose_command_req semicolon { $$ = $1; }
 931         ;
 932
 933 shorthand_command_req:
 934         extender_req {
 935                 $$ = $1;
 936         }
 937         | hyphen_req {
 938                 $$ = $1;
 939         }
 940         | '|'                           {
 941                 $$ = new Barcheck_req;
 942         }
 943         | '~'   {
 944                 $$ = new Tie_req;
 945         }
 946         | '['           {
 947                 Span_req*b= new Span_req;
 948                 b->set_span_dir(START);
 949                 b->span_type_str_ = "beam";
 950                 $$ =b;
 951         }
 952         | ']'           {
 953              Span_req*b= new Span_req;
 954              b->set_span_dir( STOP);
 955              b->span_type_str_ = "beam";
 956              $$ = b;
 957         }
 958         | BREATHE {
 959                 $$ = new Breathing_sign_req;
 960         }
 961         ;
 962
 963
 964 verbose_command_req:
 965
 966         BAR STRING                      {
 967                 $$ = new Bar_req (ly_scm2string ($2));
 968         }
 969         | COMMANDSPANREQUEST bare_int STRING {
 970                 Span_req * sp_p = new Span_req;
 971                 sp_p-> set_span_dir ( Direction($2));
 972                 sp_p->span_type_str_ = ly_scm2string ($3);
 973                 sp_p->set_spot (THIS->here_input ());
 974                 $$ = sp_p;
 975         }
 976         | MARK  {
 977                 Mark_req * m = new Mark_req;
 978                 $$ = m;
 979         }
 980         | MARK STRING {
 981                 Mark_req *m = new Mark_req;
 982                 m->set_mus_property ("label", $2);
 983                 $$ = m;
 984
 985         }
 986         | MARK bare_unsigned {
 987                 Mark_req *m = new Mark_req;
 988                 m->set_mus_property ("label",  gh_int2scm ($2));
 989                 $$ = m;
 990         }
 991
 992         | TIME_T bare_unsigned '/' bare_unsigned        {
 993                 Time_signature_change_req *m = new Time_signature_change_req;
 994                 m->beats_i_ = $2;
 995                 m->one_beat_i_=$4;
 996                 $$ = m;
 997         }
 998         | PENALTY bare_int      {
 999                 Break_req * b = new Break_req;
1000                 b->penalty_f_ = $2 / 100.0;
1001                 b->set_spot (THIS->here_input ());
1002                 $$ = b;
1003         }
1004         | SKIP duration_length {
1005                 Skip_req * skip_p = new Skip_req;
1006                 skip_p->duration_ = *$2;
1007                 delete $2; // ugh
1008                 $$ = skip_p;
1009         }
1010         | tempo_request {
1011                 $$ = $1;
1012         }
1013         | CLEF STRING {
1014                 $$ = new Clef_change_req (ly_scm2string ($2));
1015
1016         }
1017         | KEY {
1018                 Key_change_req *key_p= new Key_change_req;
1019                 $$ = key_p;
1020         }
1021         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1022                 Key_change_req *key_p= new Key_change_req;
1023
1024                 key_p->set_mus_property ("pitch-alist", $3);
1025                 ((Music* )key_p)->transpose (* $2);
1026                 $$ = key_p;
1027         }
1028         ;
1029
1030 post_requests:
1031         {
1032                 $$ = new Link_array<Request>;
1033         }
1034         | post_requests post_request {
1035                 $2->set_spot (THIS->here_input ());
1036                 $$->push ($2);
1037         }
1038         ;
1039
1040 post_request:
1041         verbose_request
1042         | request_with_dir
1043         | close_request
1044         ;
1045
1046
1047 request_that_take_dir:
1048         gen_text_def
1049         | verbose_request
1050         | script_abbreviation {
1051                 SCM s = THIS->lexer_p_->lookup_identifier ("dash-" + ly_scm2string ($1));
1052                 Articulation_req *a = new Articulation_req;
1053                 if (gh_string_p (s))
1054                         a->articulation_str_ = ly_scm2string (s);
1055                 else THIS->parser_error (_ ("Expecting string as script definition"));
1056                 $$ = a;
1057         }
1058         ;
1059
1060 request_with_dir:
1061         script_dir request_that_take_dir        {
1062                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1063                         gs->set_direction (Direction ($1));
1064                 else if ($1)
1065                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1066                 $$ = $2;
1067         }
1068         ;
1069
1070 verbose_request:
1071         REQUEST_IDENTIFIER      {
1072                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1073                 $$->set_spot (THIS->here_input ());
1074         }
1075         | DYNAMICSCRIPT embedded_scm {
1076                 /*
1077                         TODO: junkme, use text-type == dynamic
1078                 */
1079                 Text_script_req *d = new Text_script_req;
1080                 d->set_mus_property ("text-type" , ly_symbol2scm ("dynamic"));
1081                 d->set_mus_property ("text", $2);
1082                 d->set_spot (THIS->here_input ());
1083                 $$ = d;
1084         }
1085         | TEXTSCRIPT embedded_scm {
1086                 Text_script_req *t = new Text_script_req;
1087                 t->set_mus_property ("text", $2);
1088                 t->set_spot (THIS->here_input ());
1089                 $$ = t;
1090         }
1091         | SPANREQUEST bare_int STRING {
1092                 Span_req * sp_p = new Span_req;
1093                 sp_p->set_span_dir( Direction($2));
1094                 sp_p->span_type_str_ = ly_scm2string ($3);
1095                 sp_p->set_spot (THIS->here_input ());
1096                 $$ = sp_p;
1097         }
1098         | tremolo_type  {
1099                 Tremolo_req* a = new Tremolo_req;
1100                 a->set_spot (THIS->here_input ());
1101                 a->type_i_ = $1;
1102                 $$ = a;
1103         }
1104         | SCRIPT STRING         {
1105                 Articulation_req * a = new Articulation_req;
1106                 a->articulation_str_ = ly_scm2string ($2);
1107                 a->set_spot (THIS->here_input ());
1108                 $$ = a;
1109         }
1110         | ARPEGGIO {
1111                 Arpeggio_req *a = new Arpeggio_req;
1112                 a->set_spot (THIS->here_input ());
1113                 $$ = a;
1114         }
1115         ;
1116
1117 sup_quotes:
1118         '\'' {
1119                 $$ = 1;
1120         }
1121         | sup_quotes '\'' {
1122                 $$ ++;
1123         }
1124         ;
1125
1126 sub_quotes:
1127         ',' {
1128                 $$ = 1;
1129         }
1130         | sub_quotes ',' {
1131                 $$ ++ ;
1132         }
1133         ;
1134
1135 steno_musical_pitch:
1136         NOTENAME_PITCH  {
1137                 $$ = $1;
1138         }
1139         | NOTENAME_PITCH sup_quotes     {
1140                 $$ = $1;
1141                 $$->octave_i_ +=  $2;
1142         }
1143         | NOTENAME_PITCH sub_quotes      {
1144                 $$ = $1;
1145                 $$->octave_i_ += - $2;
1146         }
1147         ;
1148
1149 steno_tonic_pitch:
1150         TONICNAME_PITCH {
1151                 $$ = $1;
1152         }
1153         | TONICNAME_PITCH sup_quotes    {
1154                 $$ = $1;
1155                 $$->octave_i_ +=  $2;
1156         }
1157         | TONICNAME_PITCH sub_quotes     {
1158                 $$ = $1;
1159                 $$->octave_i_ += - $2;
1160         }
1161         ;
1162
1163 musical_pitch:
1164         steno_musical_pitch {
1165                 $$ = $1;
1166         }
1167         | MUSICAL_PITCH embedded_scm {
1168                 int sz = scm_ilength ($2);
1169                 if (sz != 3) {
1170                         THIS->parser_error (_f ("Expecting %d arguments", 3));
1171                         $2 = gh_list (gh_int2scm (0), gh_int2scm (0), gh_int2scm (0), SCM_UNDEFINED);
1172                 }
1173                 $$ = new Musical_pitch ($2);
1174         }
1175         ;
1176
1177 explicit_duration:
1178         DURATION embedded_scm   {
1179                 $$ = new Duration;
1180                 if (scm_ilength ($2) == 2)
1181                         {
1182                         $$-> durlog_i_ = gh_scm2int (gh_car($2));
1183                         $$-> dots_i_ = gh_scm2int (gh_cadr($2));
1184                         }
1185                 else
1186                         THIS->parser_error (_("Must have 2 arguments for duration"));
1187         }
1188         ;
1189
1190 extender_req:
1191         EXTENDER {
1192                 if (!THIS->lexer_p_->lyric_state_b ())
1193                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1194                 $$ = new Extender_req;
1195         }
1196         ;
1197
1198 hyphen_req:
1199         HYPHEN {
1200                 if (!THIS->lexer_p_->lyric_state_b ())
1201                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1202                 $$ = new Hyphen_req;
1203         }
1204         ;
1205
1206 close_request:
1207         close_request_parens {
1208                 $$ = $1;
1209                 dynamic_cast<Span_req*> ($$)->set_span_dir ( START);
1210         }
1211
1212 close_request_parens:
1213         '('     {
1214                 Span_req* s= new Span_req;
1215                 $$ = s;
1216                 s->span_type_str_ = "slur";
1217         }
1218         | E_SMALLER {
1219                 Span_req*s =new Span_req;
1220                 $$ = s;
1221                 s->span_type_str_ = "crescendo";
1222         }
1223         | E_BIGGER {
1224                 Span_req*s =new Span_req;
1225                 $$ = s;
1226                 s->span_type_str_ = "decrescendo";
1227         }
1228         ;
1229
1230
1231 open_request:
1232         open_request_parens {
1233                 $$ = $1;
1234                 dynamic_cast<Span_req*> ($$)->set_span_dir ( STOP);
1235         }
1236         ;
1237
1238 open_request_parens:
1239         E_EXCLAMATION   {
1240                 Span_req *s =  new Span_req;
1241                 s->span_type_str_ = "crescendo";
1242                 $$ = s;
1243         }
1244         | ')'   {
1245                 Span_req* s= new Span_req;
1246                 $$ = s;
1247                 s->span_type_str_ = "slur";
1248         }
1249         ;
1250
1251 gen_text_def:
1252         embedded_scm {
1253                 Text_script_req *t = new Text_script_req;
1254                 t->set_mus_property ("text", $1);
1255                 t->set_spot (THIS->here_input ());
1256                 $$ = t;
1257         }
1258         | string {
1259                 Text_script_req *t = new Text_script_req;
1260                 t->set_mus_property ("text", $1);
1261                 t->set_spot (THIS->here_input ());
1262                 $$ = t;
1263         }
1264         | DIGIT {
1265                 String ds = to_str ($1);
1266                 Text_script_req* t = new Text_script_req;
1267
1268                 t->set_mus_property ("text",  ly_str02scm (ds.ch_C()));
1269                 t->set_mus_property ("text-type" , ly_symbol2scm ("finger"));
1270                 t->set_spot (THIS->here_input ());
1271                 $$ = t;
1272         }
1273         ;
1274
1275 script_abbreviation:
1276         '^'             {
1277                 $$ = gh_str02scm  ("hat");
1278         }
1279         | '+'           {
1280                 $$ = gh_str02scm("plus");
1281         }
1282         | '-'           {
1283                 $$ = gh_str02scm ("dash");
1284         }
1285         | '|'           {
1286                 $$ = gh_str02scm ("bar");
1287         }
1288         | '>'           {
1289                 $$ = gh_str02scm ("larger");
1290         }
1291         | '.'           {
1292                 $$ = gh_str02scm ("dot");
1293         }
1294         ;
1295
1296
1297 script_dir:
1298         '_'     { $$ = DOWN; }
1299         | '^'   { $$ = UP; }
1300         | '-'   { $$ = CENTER; }
1301         ;
1302
1303 pre_requests:
1304         {
1305                 $$ = new Link_array<Request>;
1306         }
1307         | pre_requests open_request {
1308                 $$->push ($2);
1309         }
1310         ;
1311
1312 absolute_musical_pitch:
1313         steno_musical_pitch     {
1314                 $$ = $1;
1315         }
1316         ;
1317
1318 duration_length:
1319         steno_duration {
1320                 $$ = $1;
1321         }
1322         | duration_length '*' bare_unsigned {
1323                 $$->tuplet_iso_i_ *= $3;
1324         }
1325         | duration_length '/' bare_unsigned {
1326                 $$->tuplet_type_i_ *= $3;
1327         }
1328         ;
1329
1330 entered_notemode_duration:
1331         steno_duration  {
1332                 THIS->set_last_duration ($1);
1333         }
1334         ;
1335
1336 optional_notemode_duration:
1337         {
1338                 $$ = new Duration (THIS->default_duration_);
1339         }
1340         | entered_notemode_duration {
1341                 $$ = $1;
1342         }
1343         ;
1344
1345 steno_duration:
1346         bare_unsigned           {
1347                 $$ = new Duration;
1348                 if (!is_duration_b ($1))
1349                         THIS->parser_error (_f ("not a duration: %d", $1));
1350                 else {
1351                         $$->durlog_i_ = intlog2 ($1);
1352                      }
1353         }
1354         | DURATION_IDENTIFIER   {
1355                 $$ = $1->access_content_Duration (true);
1356         }
1357         | steno_duration '.'    {
1358                 $$->dots_i_ ++;
1359         }
1360         ;
1361
1362
1363 tremolo_type:
1364         ':'     {
1365                 $$ =0;
1366         }
1367         | ':' bare_unsigned {
1368                 if (!is_duration_b ($2))
1369                         THIS->parser_error (_f ("not a duration: %d", $2));
1370                 $$ = $2;
1371         }
1372         ;
1373
1374
1375 simple_element:
1376         musical_pitch exclamations questions optional_notemode_duration {
1377                 if (!THIS->lexer_p_->note_state_b ())
1378                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1379
1380
1381                 Note_req *n = new Note_req;
1382
1383                 n->pitch_ = *$1;
1384                 n->duration_ = *$4;
1385
1386                 n->cautionary_b_ = $3 % 2;
1387                 n->forceacc_b_ = $2 % 2 || n->cautionary_b_;
1388
1389
1390                 Simultaneous_music*v = new Request_chord (gh_list (n->self_scm (), SCM_UNDEFINED));
1391                 v->set_spot ($1->spot ());
1392                 n->set_spot ($1->spot ());
1393                 $$ = v;
1394
1395                 delete $1;
1396                 delete $4;
1397         }
1398         | RESTNAME optional_notemode_duration           {
1399
1400                 SCM e = SCM_UNDEFINED;
1401                   if (ly_scm2string ($1) =="s")
1402                     { /* Space */
1403                       Skip_req * skip_p = new Skip_req;
1404                       skip_p->duration_ = *$2;
1405
1406                       skip_p->set_spot (THIS->here_input());
1407                         e = skip_p->self_scm ();
1408                     }
1409                   else
1410                     {
1411                       Rest_req * rest_req_p = new Rest_req;
1412                       rest_req_p->duration_ = *$2;
1413                       rest_req_p->set_spot (THIS->here_input());
1414                         e = rest_req_p->self_scm ();
1415                     }
1416                   Simultaneous_music* velt_p = new Request_chord (gh_list (e,SCM_UNDEFINED));
1417                   velt_p->set_spot (THIS->here_input());
1418
1419                   delete $2; // ugh
1420                   $$ = velt_p;
1421         }
1422         | MEASURES optional_notemode_duration   {
1423                 Skip_req * sk = new Skip_req;
1424                 sk->duration_ = *$2;
1425
1426
1427                 Span_req *sp1 = new Span_req;
1428                 Span_req *sp2 = new Span_req;
1429                 sp1-> set_span_dir ( START);
1430                 sp2-> set_span_dir ( STOP);
1431                 sp1->span_type_str_ = sp2->span_type_str_ = "rest";
1432
1433                 Request_chord * rqc1 = new Request_chord (gh_list (sp1->self_scm (), SCM_UNDEFINED));
1434                 Request_chord * rqc2 = new Request_chord (gh_list (sk->self_scm (), SCM_UNDEFINED));;
1435                 Request_chord * rqc3 = new Request_chord(gh_list (sp2->self_scm (), SCM_UNDEFINED));;
1436
1437                 SCM ms = gh_list (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1438
1439                 $$ = new Sequential_music (ms);
1440         }
1441         | STRING {
1442                 THIS->remember_spot ();
1443         }
1444         /* cont */
1445         optional_notemode_duration      {
1446                 if (!THIS->lexer_p_->lyric_state_b ()) {
1447                         THIS->pop_spot ().error (_ ("Have to be in Lyric mode for lyrics"));
1448                         THIS->error_level_i_  = 1;
1449                         THIS->parser_error (_ ("Giving up"));
1450                 }
1451                 else
1452                         THIS->pop_spot ();
1453                 Lyric_req* lreq_p = new Lyric_req;
1454                 lreq_p->set_mus_property ("text", $1);
1455                 lreq_p->duration_ = *$3;
1456                 lreq_p->set_spot (THIS->here_input());
1457                 Simultaneous_music* velt_p = new Request_chord (gh_list (lreq_p->self_scm (), SCM_UNDEFINED));
1458
1459                 delete  $3; // ugh
1460                 $$= velt_p;
1461
1462         }
1463         | chord {
1464                 if (!THIS->lexer_p_->chord_state_b ())
1465                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1466                 $$ = $1;
1467         }
1468         ;
1469
1470
1471 chord:
1472         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1473                 $$ = get_chord (*$1, $3, $4, $5, $6, *$2);
1474                 $$->set_spot (THIS->here_input ());
1475         };
1476
1477 chord_additions:
1478         {
1479                 $$ = new Array<Musical_pitch>;
1480         }
1481         | CHORD_COLON chord_notes {
1482                 $$ = $2;
1483         }
1484         ;
1485
1486 chord_notes:
1487         chord_step {
1488                 $$ = $1
1489         }
1490         | chord_notes '.' chord_step {
1491                 $$ = $1;
1492                 $$->concat (*$3);
1493         }
1494         ;
1495
1496 chord_subtractions:
1497         {
1498                 $$ = new Array<Musical_pitch>;
1499         }
1500         | CHORD_CARET chord_notes {
1501                 $$ = $2;
1502         }
1503         ;
1504
1505
1506 chord_inversion:
1507         {
1508                 $$ = 0;
1509         }
1510         | '/' steno_tonic_pitch {
1511                 $$ = $2;
1512                 $$->set_spot (THIS->here_input ());
1513         }
1514         ;
1515
1516 chord_bass:
1517         {
1518                 $$ = 0;
1519         }
1520         | CHORD_BASS steno_tonic_pitch {
1521                 $$ = $2;
1522                 $$->set_spot (THIS->here_input ());
1523         }
1524         ;
1525
1526 chord_step:
1527         chord_note {
1528                 $$ = new Array<Musical_pitch>;
1529                 $$->push (*$1);
1530         }
1531         | CHORDMODIFIER_PITCH {
1532                 $$ = new Array<Musical_pitch>;
1533                 $$->push (*$1);
1534         }
1535         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1536                 $$ = new Array<Musical_pitch>;
1537                 $$->push (*$1);
1538                 $$->push (*$2);
1539         }
1540         ;
1541
1542 chord_note:
1543         bare_unsigned {
1544                 $$ = new Musical_pitch;
1545                 $$->notename_i_ = ($1 - 1) % 7;
1546                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1547                 $$->accidental_i_ = 0;
1548         }
1549         | bare_unsigned '+' {
1550                 $$ = new Musical_pitch;
1551                 $$->notename_i_ = ($1 - 1) % 7;
1552                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1553                 $$->accidental_i_ = 1;
1554         }
1555         | bare_unsigned CHORD_MINUS {
1556                 $$ = new Musical_pitch;
1557                 $$->notename_i_ = ($1 - 1) % 7;
1558                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1559                 $$->accidental_i_ = -1;
1560         }
1561         ;
1562
1563 /*
1564         UTILITIES
1565  */
1566 number_expression:
1567         bare_number {
1568                 $$ = $1;
1569         }
1570         | '-'  number_expression %prec UNARY_MINUS {
1571                 $$ = scm_difference ($2, SCM_UNDEFINED);
1572         }
1573         | number_expression '*' number_expression {
1574                 $$ = scm_product ($1, $3);
1575         }
1576         | number_expression '/' number_expression {
1577                 $$ = scm_divide ($1, $3);
1578         }
1579         | number_expression '+' number_expression {
1580                 $$ = scm_sum ($1, $3);
1581         }
1582         | number_expression '-' number_expression {
1583                 $$ = scm_difference ($1, $3);
1584         }
1585         | '(' number_expression ')'     {
1586                 $$ = $2;
1587         }
1588         ;
1589
1590 bare_number:
1591         UNSIGNED        {
1592                 $$ = gh_int2scm ($1);
1593         }
1594         | DIGIT         {
1595                 $$ = gh_int2scm ($1);
1596         }
1597         | REAL          {
1598                 $$ = gh_double2scm ($1);
1599         }
1600         | NUMBER_IDENTIFIER             {
1601                 $$ = $1;
1602         }
1603         | REAL CM_T     {
1604                 $$ = gh_double2scm ($1 CM);
1605         }
1606         | REAL PT_T     {
1607                 $$ = gh_double2scm ($1 PT);
1608         }
1609         | REAL IN_T     {
1610                 $$ = gh_double2scm ($1 INCH);
1611         }
1612         | REAL MM_T     {
1613                 $$ = gh_double2scm ($1 MM);
1614         }
1615         | REAL CHAR_T   {
1616                 $$ = gh_double2scm ($1 CHAR);
1617         }
1618         ;
1619
1620
1621 bare_unsigned:
1622         bare_number {
1623                 if (scm_integer_p ($1) == SCM_BOOL_T) {
1624                         $$ = gh_scm2int ($1);
1625
1626                 } else {
1627                         THIS->parser_error (_("need integer number arg"));
1628                         $$ = 0;
1629                 }
1630                 if ($$ < 0) {
1631                         THIS->parser_error (_("Must be positive integer"));
1632                         $$ = -$$;
1633                         }
1634
1635         }
1636         ;
1637 bare_int:
1638         bare_number {
1639                 if (scm_integer_p ($1) == SCM_BOOL_T)
1640                 {
1641                         int k = gh_scm2int ($1);
1642                         $$ = k;
1643                 } else
1644                 {
1645                         THIS->parser_error (_("need integer number arg"));
1646                         $$ = 0;
1647                 }
1648         }
1649         | '-' bare_int {
1650                 $$ = -$2;
1651         }
1652         ;
1653
1654
1655 string:
1656         STRING          {
1657                 $$ = $1;
1658         }
1659         | STRING_IDENTIFIER     {
1660                 $$ = $1;
1661         }
1662         | string '+' string {
1663                 $$ = scm_string_append (scm_listify ($1, $3, SCM_UNDEFINED));
1664         }
1665         ;
1666
1667
1668 exclamations:
1669                 { $$ = 0; }
1670         | exclamations '!'      { $$ ++; }
1671         ;
1672
1673 questions:
1674                 { $$ = 0; }
1675         | questions '?' { $$ ++; }
1676         ;
1677
1678
1679 semicolon:
1680         ';'
1681         ;
1682
1683 %%
1684
1685 void
1686 My_lily_parser::set_yydebug (bool b)
1687 {
1688 #ifdef YYDEBUG
1689         yydebug = b;
1690 #endif
1691 }
1692
1693 extern My_lily_parser * current_parser;
1694
1695 void
1696 My_lily_parser::do_yyparse ()
1697 {
1698
1699         current_parser = this;;
1700         yyparse ((void*)this);
1701 }
1702
1703