lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2005 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "music.hh"
  78 #include "file-path.hh"
  79 #include "input-smob.hh"
  80 #include "input.hh"
  81 #include "lily-guile.hh"
  82 #include "lilypond-input-version.hh"
  83 #include "main.hh"
  84 #include "misc.hh"
  85 #include "lily-lexer.hh"
  86 #include "lily-parser.hh"
  87 #include "paper-book.hh"
  88 #include "output-def.hh"
  89 #include "scm-hash.hh"
  90 #include "program-option.hh"
  91 #include "score.hh"
  92 #include "text-interface.hh"
  93 #include "warn.hh"
  94 #include "music.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         String *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 Music *property_op_to_music (SCM op);
 114 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
 115 SCM get_next_unique_context_id ();
 116 SCM get_next_unique_lyrics_context_id ();
 117
 118 #undef _
 119 #if !HAVE_GETTEXT
 120 #define _(x) x
 121 #else
 122 #include <libintl.h>
 123 #define _(x) gettext (x)
 124 #endif
 125
 126
 127
 128 Music *make_lyric_combine_music (SCM name, Music *music);
 129 Music *make_music_relative (Pitch start, Music *music);
 130 Music *run_music_function (Lily_parser *, SCM expr);
 131 Music *set_property_music (SCM sym, SCM value);
 132 SCM get_first_context_id (SCM type, Music *m);
 133 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 134 SCM make_chord_step (int step, int alter);
 135 SCM make_simple_markup (SCM a);
 136 bool is_duration (int t);
 137 bool is_regular_identifier (SCM id);
 138 bool ly_input_procedure_p (SCM x);
 139 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 140 void set_music_properties (Music *p, SCM a);
 141
 142 %}
 143
 144 /* The third option is an alias that will be used to display the
 145    syntax error.  Bison CVS now correctly handles backslash escapes.
 146
 147    FIXME: Bison needs to translate some of these, eg, STRING.
 148
 149 */
 150
 151 /* Keyword tokens with plain escaped name.  */
 152 %token ACCEPTS "\\accepts"
 153 %token ADDLYRICS "\\addlyrics"
 154 %token ADDQUOTE "\\addquote"
 155 %token ALIAS "\\alias"
 156 %token ALTERNATIVE "\\alternative"
 157 %token BAR "\\bar"
 158 %token BOOK "\book"
 159 %token CHANGE "\\change"
 160 %token CHORDMODE "\\chordmode"
 161 %token CHORDS "\\chords"
 162 %token CLEF "\\clef"
 163 %token CONSISTS "\\consists"
 164 %token CONTEXT "\\context"
 165 %token DEFAULT "\\default"
 166 %token DEFAULTCHILD "\\defaultchild"
 167 %token DENIES "\\denies"
 168 %token DESCRIPTION "\\description"
 169 %token DRUMMODE "\\drummode"
 170 %token DRUMS "\\drums"
 171 %token FIGUREMODE "\\figuremode"
 172 %token FIGURES "\\figures"
 173 %token GROBDESCRIPTIONS "\\grobdescriptions"
 174 %token HEADER "\\header"
 175 %token INVALID "\\invalid"
 176 %token KEY "\\key"
 177 %token LAYOUT "\\layout"
 178 %token LYRICMODE "\\lyricmode"
 179 %token LYRICS "\\lyrics"
 180 %token LYRICSTO "\\lyricsto"
 181 %token MARK "\\mark"
 182 %token MARKUP "\\markup"
 183 %token MIDI "\\midi"
 184 %token NAME "\\name"
 185 %token NOTEMODE "\\notemode"
 186 %token OBJECTID "\\objectid"
 187 %token OCTAVE "\\octave"
 188 %token ONCE "\\once"
 189 %token OVERRIDE "\\override"
 190 %token PAPER "\\paper"
 191 %token PARTIAL "\\partial"
 192 %token RELATIVE "\\relative"
 193 %token REMOVE "\\remove"
 194 %token REPEAT "\\repeat"
 195 %token REST "\\rest"
 196 %token REVERT "\\revert"
 197 %token SCORE "\\score"
 198 %token SEQUENTIAL "\\sequential"
 199 %token SET "\\set"
 200 %token SIMULTANEOUS "\\simultaneous"
 201 %token SKIP "\\skip"
 202 %token TEMPO "\\tempo"
 203 %token TIMES "\\times"
 204 %token TRANSPOSE "\\transpose"
 205 %token TRANSPOSITION "\\transposition"
 206 %token TYPE "\\type"
 207 %token UNSET "\\unset"
 208 %token WITH "\\with"
 209
 210 /* Keyword token exceptions.  */
 211 %token TIME_T "\\time"
 212 %token NEWCONTEXT "\\new"
 213
 214
 215 /* Other string tokens.  */
 216
 217 %token CHORD_BASS "/+"
 218 %token CHORD_CARET "^"
 219 %token CHORD_COLON ":"
 220 %token CHORD_MINUS "-"
 221 %token CHORD_SLASH "/"
 222 %token DOUBLE_ANGLE_CLOSE ">>"
 223 %token DOUBLE_ANGLE_OPEN "<<"
 224 %token E_BACKSLASH "\\"
 225 %token E_ANGLE_CLOSE "\\>"
 226 %token E_CHAR "\\C[haracter]"
 227 %token E_CLOSE "\\)"
 228 %token E_EXCLAMATION "\\!"
 229 %token E_BRACKET_OPEN "\\["
 230 %token E_OPEN "\\("
 231 %token E_BRACKET_CLOSE "\\]"
 232 %token E_ANGLE_OPEN "\\<"
 233 %token E_PLUS "\\+"
 234 %token E_TILDE "\\~"
 235 %token EXTENDER "__"
 236
 237 /*
 238 If we give names, Bison complains.
 239 */
 240 %token FIGURE_CLOSE /* "\\>" */
 241 %token FIGURE_OPEN /* "\\<" */
 242 %token FIGURE_SPACE "_"
 243 %token HYPHEN "--"
 244
 245 %token CHORDMODIFIERS
 246 %token LYRIC_MARKUP
 247 %token MULTI_MEASURE_REST
 248 %token SCM_T
 249
 250
 251 %token <i> DIGIT
 252 %token <i> E_UNSIGNED
 253 %token <i> UNSIGNED
 254
 255 %token <scm> BOOK_IDENTIFIER
 256 %token <scm> CHORDMODIFIER_PITCH
 257 %token <scm> CHORD_MODIFIER
 258 %token <scm> CONTEXT_DEF_IDENTIFIER
 259 %token <scm> DRUM_PITCH
 260 %token <scm> DURATION_IDENTIFIER
 261 %token <scm> EVENT_IDENTIFIER
 262 %token <scm> FRACTION
 263 %token <scm> LYRICS_STRING
 264 %token <scm> LYRIC_MARKUP_IDENTIFIER
 265 %token <scm> MARKUP_HEAD_EMPTY
 266 %token <scm> MARKUP_HEAD_LIST0
 267 %token <scm> MARKUP_HEAD_MARKUP0
 268 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 269 %token <scm> MARKUP_HEAD_SCM0
 270 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1
 272 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 273 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 274 %token <scm> MARKUP_IDENTIFIER
 275 %token <scm> MUSIC_FUNCTION
 276 %token <scm> MUSIC_FUNCTION_MARKUP
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 281 %token <scm> MUSIC_FUNCTION_MUSIC
 282 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 283 %token <scm> MUSIC_FUNCTION_SCM
 284 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 285 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM
 287 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 288 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 289 %token <scm> MUSIC_IDENTIFIER
 290 %token <scm> NOTENAME_PITCH
 291 %token <scm> NUMBER_IDENTIFIER
 292 %token <scm> OUTPUT_DEF_IDENTIFIER
 293 %token <scm> REAL
 294 %token <scm> RESTNAME
 295 %token <scm> SCM_IDENTIFIER
 296 %token <scm> SCM_T
 297 %token <scm> SCORE_IDENTIFIER
 298 %token <scm> STRING
 299 %token <scm> STRING_IDENTIFIER
 300 %token <scm> TONICNAME_PITCH
 301
 302
 303 %type <book> book_block
 304 %type <book> book_body
 305
 306 %type <i> bare_unsigned
 307 %type <i> figured_bass_alteration
 308 %type <i> dots
 309 %type <i> exclamations
 310 %type <i> optional_rest
 311 %type <i> questions
 312 %type <i> script_dir
 313 %type <i> sub_quotes
 314 %type <i> sup_quotes
 315 %type <i> tremolo_type
 316
 317 %type <music> Composite_music
 318 %type <music> Grouped_music_list
 319 %type <music> Music
 320 %type <music> Prefix_composite_music
 321 %type <music> Repeated_music
 322 %type <music> Sequential_music
 323 %type <music> Simple_music
 324 %type <music> Simultaneous_music
 325 %type <music> chord_body
 326 %type <music> chord_body_element
 327 %type <music> command_element
 328 %type <music> command_event
 329 %type <music> context_change
 330 %type <music> direction_less_event
 331 %type <music> direction_reqd_event
 332 %type <music> event_chord
 333 %type <music> gen_text_def
 334 %type <music> music_property_def
 335 %type <music> note_chord_element
 336 %type <music> post_event
 337 %type <music> re_rhythmed_music
 338 %type <music> relative_music
 339 %type <music> simple_element
 340 %type <music> string_number_event
 341 %type <music> tempo_event
 342 %type <music> toplevel_music
 343
 344 %type <outputdef> output_def_body
 345 %type <outputdef> output_def_head
 346 %type <outputdef> output_def
 347 %type <outputdef> paper_block
 348
 349 %type <scm> Alternative_music
 350 %type <scm> Generic_prefix_music_scm
 351 %type <scm> Music_list
 352 %type <scm> absolute_pitch
 353 %type <scm> assignment_id
 354 %type <scm> bare_number
 355 %type <scm> music_function_event
 356 %type <scm> music_function_chord_body
 357 %type <scm> bass_figure
 358 %type <scm> figured_bass_modification
 359 %type <scm> br_bass_figure
 360 %type <scm> bass_number
 361 %type <scm> chord_body_elements
 362 %type <scm> chord_item
 363 %type <scm> chord_items
 364 %type <scm> chord_separator
 365 %type <scm> context_def_mod
 366 %type <scm> context_def_spec_block
 367 %type <scm> context_def_spec_body
 368 %type <scm> context_mod
 369 %type <scm> context_mod_list
 370 %type <scm> context_prop_spec
 371 %type <scm> direction_less_char
 372 %type <scm> duration_length
 373 %type <scm> embedded_scm
 374 %type <scm> figure_list
 375 %type <scm> figure_spec
 376 %type <scm> fraction
 377 %type <scm> full_markup
 378 %type <scm> identifier_init
 379 %type <scm> lilypond_header
 380 %type <scm> lilypond_header_body
 381 %type <scm> lyric_element
 382 %type <scm> lyric_markup
 383 %type <scm> markup
 384 %type <scm> markup_braced_list
 385 %type <scm> markup_braced_list_body
 386 %type <scm> markup_composed_list
 387 %type <scm> markup_head_1_item
 388 %type <scm> markup_head_1_list
 389 %type <scm> markup_list
 390 %type <scm> markup_top
 391 %type <scm> mode_changing_head
 392 %type <scm> mode_changing_head_with_context
 393 %type <scm> multiplied_duration
 394 %type <scm> new_chord
 395 %type <scm> new_lyrics
 396 %type <scm> number_expression
 397 %type <scm> number_factor
 398 %type <scm> number_term
 399 %type <scm> object_id_setting
 400 %type <scm> octave_check
 401 %type <scm> optional_context_mod
 402 %type <scm> optional_notemode_duration
 403 %type <scm> pitch
 404 %type <scm> pitch_also_in_chords
 405 %type <scm> post_events
 406 %type <scm> property_operation
 407 %type <scm> scalar
 408 %type <scm> script_abbreviation
 409 %type <scm> simple_markup
 410 %type <scm> simple_string
 411 %type <scm> steno_duration
 412 %type <scm> steno_pitch
 413 %type <scm> steno_tonic_pitch
 414 %type <scm> step_number
 415 %type <scm> step_numbers
 416 %type <scm> string
 417
 418 %type <score> score_block
 419 %type <score> score_body
 420
 421
 422 %left '-' '+'
 423
 424 /* We don't assign precedence to / and *, because we might need varied
 425 prec levels in different prods */
 426
 427 %left UNARY_MINUS
 428
 429 %%
 430
 431 lilypond:       /* empty */
 432         | lilypond toplevel_expression {
 433         }
 434         | lilypond assignment {
 435         }
 436         | lilypond error {
 437                 THIS->error_level_ = 1;
 438         }
 439         | lilypond INVALID      {
 440                 THIS->error_level_ = 1;
 441         }
 442         ;
 443
 444
 445 object_id_setting:
 446         OBJECTID STRING { $$ = $2; }
 447         ;
 448
 449 toplevel_expression:
 450         lilypond_header {
 451                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 452         }
 453         | add_quote {
 454
 455         }
 456         | book_block {
 457                 Book *book = $1;
 458                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 459                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 460                 book->unprotect ();
 461         }
 462         | score_block {
 463                 Score *score = $1;
 464
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 467                 score->unprotect ();
 468         }
 469         | toplevel_music {
 470                 Music *music = $1;
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 473                 music->unprotect ();
 474         }
 475         | full_markup {
 476                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 477                 scm_call_2 (proc, THIS->self_scm (), $1);
 478         }
 479         | output_def {
 480                 SCM id = SCM_EOL;
 481                 Output_def * od = $1;
 482
 483                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 484                         id = ly_symbol2scm ("$defaultpaper");
 485                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultmidi");
 487                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultlayout");
 489
 490                 THIS->lexer_->set_identifier (id, od->self_scm ());
 491                 od->unprotect();
 492         }
 493         ;
 494
 495 toplevel_music:
 496         Composite_music {
 497         }
 498         ;
 499
 500 embedded_scm:
 501         SCM_T
 502         | SCM_IDENTIFIER
 503         ;
 504
 505
 506 lilypond_header_body:
 507         {
 508                 $$ = get_header(THIS);
 509                 THIS->lexer_->add_scope ($$);
 510         }
 511         | lilypond_header_body assignment  {
 512
 513         }
 514         ;
 515
 516 lilypond_header:
 517         HEADER '{' lilypond_header_body '}'     {
 518                 $$ = THIS->lexer_->remove_scope ();
 519         }
 520         ;
 521
 522 /*
 523         DECLARATIONS
 524 */
 525 assignment_id:
 526         STRING          { $$ = $1; }
 527         | LYRICS_STRING { $$ = $1; }
 528         ;
 529
 530 assignment:
 531         assignment_id '=' identifier_init  {
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         @1.warning (_ ("identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $3);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 $1->unprotect ();
 555         }
 556         | book_block {
 557                 $$ = $1->self_scm ();
 558                 $1->unprotect ();
 559         }
 560         | output_def {
 561                 $$ = $1->self_scm ();
 562                 $1->unprotect ();
 563         }
 564         | context_def_spec_block {
 565                 $$ = $1;
 566         }
 567         | Music  {
 568                 $$ = $1->self_scm ();
 569                 $1->unprotect();
 570         }
 571         | post_event {
 572                 $$ = $1->self_scm ();
 573                 $1->unprotect();
 574         }
 575         | number_expression {
 576                 $$ = $1;
 577         }
 578         | string {
 579                 $$ = $1;
 580         }
 581         | embedded_scm {
 582                 $$ = $1;
 583         }
 584         | full_markup {
 585                 $$ = $1;
 586         }
 587         | DIGIT {
 588                 $$ = scm_from_int ($1);
 589         }
 590         ;
 591
 592 context_def_spec_block:
 593         CONTEXT '{' context_def_spec_body '}'
 594                 {
 595                 $$ = $3;
 596         }
 597         ;
 598
 599 context_def_spec_body:
 600         /**/ {
 601                 $$ = Context_def::make_scm ();
 602                 unsmob_context_def ($$)->set_spot (@$);
 603         }
 604         | CONTEXT_DEF_IDENTIFIER {
 605                 $$ = $1;
 606                 unsmob_context_def ($$)->set_spot (@$);
 607         }
 608         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 609                 Context_def*td = unsmob_context_def ($$);
 610
 611                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 612                         SCM tag = scm_caar (p);
 613
 614                         /* TODO: should make new tag "grob-definition" ? */
 615                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 616                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 617                 }
 618         }
 619         | context_def_spec_body context_mod {
 620                 unsmob_context_def ($$)->add_context_mod ($2);
 621         }
 622         ;
 623
 624
 625
 626 book_block:
 627         BOOK '{' book_body '}'  {
 628                 $$ = $3;
 629         }
 630         ;
 631
 632 /* FIXME:
 633    * Use 'handlers' like for toplevel-* stuff?
 634    * grok \layout and \midi?  */
 635 book_body:
 636         {
 637                 $$ = new Book;
 638                 $$->set_spot (@$);
 639                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 640                 $$->paper_->unprotect ();
 641                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 642         }
 643         | BOOK_IDENTIFIER {
 644                 $$ = unsmob_book ($1);
 645                 $$->set_spot (@$);
 646         }
 647         | book_body paper_block {
 648                 $$->paper_ = $2;
 649                 $2->unprotect ();
 650         }
 651         | book_body score_block {
 652                 SCM s = $2->self_scm ();
 653                 $$->add_score (s);
 654                 $2->unprotect();
 655         }
 656         | book_body full_markup {
 657                 $$->add_score ($2);
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663                 $$->paper_ = 0;
 664                 $$->scores_ = SCM_EOL;
 665         }
 666         | book_body object_id_setting {
 667                 $$->user_key_ = ly_scm2string ($2);
 668         }
 669         ;
 670
 671 score_block:
 672         SCORE '{' score_body '}'        {
 673                 $$ = $3;
 674         }
 675         ;
 676
 677 score_body:
 678         Music {
 679                 SCM m = $1->self_scm ();
 680                 $1->unprotect();
 681                 SCM scorify = ly_lily_module_constant ("scorify-music");
 682                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 683
 684                 // pass ownernship to C++ again.
 685                 $$ = unsmob_score (score);
 686                 $$->protect ();
 687                 $$->set_spot (@$);
 688         }
 689         | SCORE_IDENTIFIER {
 690                 $$ = unsmob_score ($1);
 691                 $$->set_spot (@$);
 692         }
 693         | score_body object_id_setting {
 694                 $$->user_key_ = ly_scm2string ($2);
 695         }
 696         | score_body lilypond_header    {
 697                 $$->header_ = $2;
 698         }
 699         | score_body output_def {
 700                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 701                 {
 702                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 703
 704                 }
 705                 else
 706                 {
 707                         $$->defs_.push ($2);
 708                 }
 709                 $2->unprotect ();
 710         }
 711         | score_body error {
 712                 $$->error_found_ = true;
 713         }
 714         ;
 715
 716
 717 /*
 718         OUTPUT DEF
 719 */
 720
 721 paper_block:
 722         output_def {
 723                 $$ = $1;
 724                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 725                 {
 726                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 727                         $$ = get_paper (THIS);
 728                 }
 729         }
 730         ;
 731
 732
 733 output_def:
 734         output_def_body '}' {
 735                 $$ = $1;
 736
 737                 THIS->lexer_->remove_scope ();
 738                 THIS->lexer_->pop_state ();
 739         }
 740         ;
 741
 742 output_def_head:
 743         PAPER {
 744                 $$ = get_paper (THIS);
 745                 $$->input_origin_ = @$;
 746                 THIS->lexer_->add_scope ($$->scope_);
 747         }
 748         | MIDI    {
 749                 Output_def *p = get_midi (THIS);
 750                 $$ = p;
 751                 THIS->lexer_->add_scope (p->scope_);
 752         }
 753         | LAYOUT        {
 754                 Output_def *p = get_layout (THIS);
 755
 756                 THIS->lexer_->add_scope (p->scope_);
 757                 $$ = p;
 758         }
 759         ;
 760
 761
 762 output_def_body:
 763         output_def_head '{' {
 764                 $$ = $1;
 765                 $$->input_origin_.set_spot (@$);
 766                 THIS->lexer_->push_initial_state ();
 767         }
 768         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 769                 $1->unprotect ();
 770                 Output_def *o = unsmob_output_def ($3);
 771                 o->input_origin_.set_spot (@$);
 772                 $$ = o;
 773                 THIS->lexer_->remove_scope ();
 774                 THIS->lexer_->add_scope (o->scope_);
 775                 THIS->lexer_->push_initial_state ();
 776         }
 777         | output_def_body assignment  {
 778
 779         }
 780         | output_def_body context_def_spec_block        {
 781                 assign_context_def ($$, $2);
 782         }
 783         | output_def_body tempo_event  {
 784                 /*
 785                         junk this ? there already is tempo stuff in
 786                         music.
 787                 */
 788                 int m = scm_to_int ($2->get_property ("metronome-count"));
 789                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 790                 set_tempo ($$, d->get_length (), m);
 791                 $2->unprotect ();
 792         }
 793         | output_def_body error {
 794
 795         }
 796         ;
 797
 798 tempo_event:
 799         TEMPO steno_duration '=' bare_unsigned  {
 800                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 801                 $$->set_property ("tempo-unit", $2);
 802                 $$->set_property ("metronome-count", scm_from_int ( $4));
 803         }
 804         ;
 805
 806 /*
 807 The representation of a  list is the
 808
 809   (LIST . LAST-CONS)
 810
 811  to have efficient append.  */
 812
 813 Music_list:
 814         /* empty */ {
 815                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 816         }
 817         | Music_list Music {
 818                 SCM s = $$;
 819                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 820                 $2->unprotect (); /* UGH */
 821
 822                 if (scm_is_pair (scm_cdr (s)))
 823                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 824                 else
 825                         scm_set_car_x (s, c); /* set first cons */
 826                 scm_set_cdr_x (s, c);  /* remember last cell */
 827         }
 828         | Music_list embedded_scm {
 829
 830         }
 831         | Music_list error {
 832                 Music * m = MY_MAKE_MUSIC("Music");
 833                 // ugh. code dup
 834                 m->set_property ("error-found", SCM_BOOL_T);
 835                 SCM s = $$;
 836                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 837                 m->unprotect (); /* UGH */
 838
 839                 if (scm_is_pair (scm_cdr (s)))
 840                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 841                 else
 842                         scm_set_car_x (s, c); /* set first cons */
 843                 scm_set_cdr_x (s, c);  /* remember last cell */
 844         }
 845         ;
 846
 847 Music:
 848         Simple_music
 849         | Composite_music
 850         ;
 851
 852 Alternative_music:
 853         /* empty */ {
 854                 $$ = SCM_EOL;
 855         }
 856         | ALTERNATIVE '{' Music_list '}' {
 857                 $$ = $3;
 858         }
 859         ;
 860
 861
 862 Repeated_music:
 863         REPEAT simple_string bare_unsigned Music Alternative_music
 864         {
 865                 Music *beg = $4;
 866                 int times = $3;
 867                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 868                 if (times < scm_ilength (alts)) {
 869                   unsmob_music (scm_car (alts))
 870                     ->origin ()->warning (
 871                     _ ("more alternatives than repeats"));
 872                     warning ("junking excess alternatives");
 873                   alts = ly_truncate_list (times, alts);
 874                 }
 875
 876
 877                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 878
 879                 SCM mus = scm_call_1 (proc, $2);
 880                 Music *r = unsmob_music (mus);
 881                 r->protect ();
 882                 if (beg)
 883                         {
 884                         r-> set_property ("element", beg->self_scm ());
 885                         beg->unprotect ();
 886                         }
 887                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
 888
 889                 r-> set_property ("elements",alts);
 890                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
 891                         /*
 892                         TODO: move this code to Scheme.
 893                         */
 894
 895                         /* we cannot get durations and other stuff
 896                            correct down the line,
 897                            so we have to add to the duration log here. */
 898                         SCM func = ly_lily_module_constant ("shift-duration-log");
 899
 900                         int dots = ($3 % 3) ? 0 : 1;
 901                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 902
 903
 904                         if ($4->is_mus_type ("sequential-music"))
 905                         {
 906                                 int list_len = scm_ilength ($4->get_property ("elements"));
 907                                 if (list_len != 2)
 908                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
 909                                 shift -= 1;
 910                                 r->compress (Moment (Rational (1, list_len)));
 911                         }
 912                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
 913
 914                 }
 915                 r->set_spot (*$4->origin ());
 916
 917                 $$ = r;
 918         }
 919         ;
 920
 921 Sequential_music:
 922         SEQUENTIAL '{' Music_list '}'           {
 923                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 924                 $$->set_property ("elements", scm_car ($3));
 925                 $$->set_spot (@$);
 926         }
 927         | '{' Music_list '}'            {
 928                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 929                 $$->set_property ("elements", scm_car ($2));
 930                 $$->set_spot (@$);
 931         }
 932         ;
 933
 934 Simultaneous_music:
 935         SIMULTANEOUS '{' Music_list '}'{
 936                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 937                 $$->set_property ("elements", scm_car ($3));
 938                 $$->set_spot (@$);
 939
 940         }
 941         | simul_open Music_list simul_close     {
 942                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 943                 $$->set_property ("elements", scm_car ($2));
 944                 $$->set_spot (@$);
 945         }
 946         ;
 947
 948 Simple_music:
 949         event_chord             { $$ = $1; }
 950         | MUSIC_IDENTIFIER {
 951                 $$ = unsmob_music ($1);
 952         }
 953         | music_property_def
 954         | context_change
 955         ;
 956
 957
 958 optional_context_mod:
 959         /**/ { $$ = SCM_EOL; }
 960         | WITH { THIS->lexer_->push_initial_state (); }
 961         '{' context_mod_list '}'
 962         {
 963                 THIS->lexer_->pop_state ();
 964                 $$ = $4;
 965         }
 966         ;
 967
 968 context_mod_list:
 969         /* */  { $$ = SCM_EOL; }
 970         | context_mod_list context_mod  {
 971                  $$ = scm_cons ($2, $1);
 972         }
 973         ;
 974
 975
 976 Composite_music:
 977         Prefix_composite_music { $$ = $1; }
 978         | Grouped_music_list { $$ = $1; }
 979         ;
 980
 981 Grouped_music_list:
 982         Simultaneous_music              { $$ = $1; }
 983         | Sequential_music              { $$ = $1; }
 984         ;
 985
 986 Generic_prefix_music_scm:
 987         MUSIC_FUNCTION {
 988                 $$ = scm_list_2 ($1, make_input (@$));
 989         }
 990         | MUSIC_FUNCTION_SCM embedded_scm {
 991                 $$ = scm_list_3 ($1, make_input (@$), $2);
 992         }
 993         | MUSIC_FUNCTION_MARKUP full_markup {
 994                 $$ = scm_list_3 ($1, make_input (@$), $2);
 995         }
 996
 997         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm Music {
 998                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
 999                 $3->unprotect ();
1000         }
1001         | MUSIC_FUNCTION_SCM_SCM embedded_scm embedded_scm {
1002                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1003         }
1004         | MUSIC_FUNCTION_SCM_SCM_SCM embedded_scm embedded_scm embedded_scm {
1005                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1006         }
1007         | MUSIC_FUNCTION_MUSIC Music {
1008                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1009                 $2->unprotect ();
1010         }
1011         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm Music {
1012                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1013         }
1014         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1015                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1016                 $3->unprotect ();
1017         }
1018         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1019                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1020         }
1021         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1022                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1023                 $2->unprotect ();
1024                 $3->unprotect ();
1025         }
1026         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC embedded_scm Music Music {
1027                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1028                 $4->unprotect ();
1029                 $3->unprotect ();
1030         }
1031         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1032                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1033                 $3->unprotect ();
1034                 $4->unprotect ();
1035         }
1036         ;
1037
1038 Prefix_composite_music:
1039         Generic_prefix_music_scm {
1040                 $$ = run_music_function (THIS, $1);
1041         }
1042         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1043                 $$ = context_spec_music ($2, $4, $6, $5);
1044
1045         }
1046         | CONTEXT simple_string optional_context_mod Music {
1047                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1048         }
1049         | NEWCONTEXT simple_string optional_context_mod Music {
1050                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1051                         $3);
1052         }
1053
1054         | TIMES fraction Music
1055
1056         {
1057                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1058                 Music *mp = $3;
1059
1060                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1061                 $$->set_spot (@$);
1062
1063                 $$->set_property ("element", mp->self_scm ());
1064                 mp->unprotect();
1065                 $$->set_property ("numerator", scm_from_int (n));
1066                 $$->set_property ("denominator", scm_from_int (d));
1067                 $$->compress (Moment (Rational (n,d)));
1068
1069         }
1070         | Repeated_music                { $$ = $1; }
1071         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1072                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1073                 Music *p = $4;
1074                 Pitch from = *unsmob_pitch ($2);
1075                 Pitch to = *unsmob_pitch ($3);
1076
1077                 p->transpose (pitch_interval (from, to));
1078                 $$->set_property ("element", p->self_scm ());
1079                 p->unprotect();
1080         }
1081         | mode_changing_head Grouped_music_list {
1082                 if ($1 == ly_symbol2scm ("chords"))
1083                 {
1084                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1085                   chm->set_property ("element", $2->self_scm ());
1086                   $$ = chm;
1087                   $2->unprotect();
1088                 }
1089                 else
1090                 {
1091                   $$ = $2;
1092                 }
1093                 THIS->lexer_->pop_state ();
1094         }
1095         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1096                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1097                                          $3, $2);
1098                 if ($1 == ly_symbol2scm ("ChordNames"))
1099                 {
1100                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1101                   chm->set_property ("element", $$->self_scm ());
1102                   $$->unprotect();
1103                   $$ = chm;
1104                 }
1105                 THIS->lexer_->pop_state ();
1106         }
1107         | relative_music        { $$ = $1; }
1108         | re_rhythmed_music     { $$ = $1; }
1109         ;
1110
1111 mode_changing_head:
1112         NOTEMODE {
1113                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1114                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1115
1116                 $$ = ly_symbol2scm ("notes");
1117         }
1118         | DRUMMODE
1119                 {
1120                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1121                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1122
1123                 $$ = ly_symbol2scm ("drums");
1124         }
1125         | FIGUREMODE {
1126                 THIS->lexer_->push_figuredbass_state ();
1127
1128                 $$ = ly_symbol2scm ("figures");
1129         }
1130         | CHORDMODE {
1131                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1132                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1133                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1134                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1135                 $$ = ly_symbol2scm ("chords");
1136
1137         }
1138         | LYRICMODE
1139                 { THIS->lexer_->push_lyric_state ();
1140                 $$ = ly_symbol2scm ("lyrics");
1141         }
1142         ;
1143
1144 mode_changing_head_with_context:
1145         DRUMS {
1146                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1147                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1148
1149                 $$ = ly_symbol2scm ("DrumStaff");
1150         }
1151         | FIGURES {
1152                 THIS->lexer_->push_figuredbass_state ();
1153
1154                 $$ = ly_symbol2scm ("FiguredBass");
1155         }
1156         | CHORDS {
1157                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1158                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1159                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1160                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1161                 $$ = ly_symbol2scm ("ChordNames");
1162         }
1163         | LYRICS
1164                 { THIS->lexer_->push_lyric_state ();
1165                 $$ = ly_symbol2scm ("Lyrics");
1166         }
1167         ;
1168
1169
1170 relative_music:
1171         RELATIVE absolute_pitch Music {
1172                 Music *m = $3;
1173                 Pitch start = *unsmob_pitch ($2);
1174                 $$ = make_music_relative (start, m);
1175                 m->unprotect();
1176         }
1177         | RELATIVE Composite_music {
1178                 Music *m = $2;
1179
1180                 Pitch middle_c (0, 0, 0);
1181                 $$ = make_music_relative (middle_c, m);
1182                 m->unprotect();
1183         }
1184         ;
1185
1186 new_lyrics:
1187         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1188         /*cont */
1189         Grouped_music_list {
1190         /* Can also use Music at the expensive of two S/Rs similar to
1191            \repeat \alternative */
1192                 THIS->lexer_->pop_state ();
1193
1194                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1195         }
1196         | new_lyrics ADDLYRICS {
1197                 THIS->lexer_->push_lyric_state ();
1198         } Grouped_music_list {
1199                 THIS->lexer_->pop_state ();
1200                 $$ = scm_cons ($4->self_scm (), $1);
1201         }
1202         ;
1203
1204 re_rhythmed_music:
1205         Grouped_music_list new_lyrics {
1206                 Music * voice = $1;
1207                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1208                 if (!scm_is_string (name))
1209                 {
1210                         name = get_next_unique_lyrics_context_id ();
1211                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1212                                                     name,
1213                                                     voice, SCM_EOL);
1214                 }
1215
1216                 SCM context = scm_makfrom0str ("Lyrics");
1217                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1218
1219                 SCM lst = SCM_EOL;
1220                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1221                 {
1222                         Music *music = unsmob_music (scm_car (s));
1223                         Music *com = make_lyric_combine_music (name, music);
1224                         Music *csm = context_spec_music (context,
1225                                 get_next_unique_context_id (), com, SCM_EOL);
1226                         lst = scm_cons (csm->self_scm (), lst);
1227                 }
1228                 all->set_property ("elements", scm_cons (voice->self_scm (),
1229                         lst));
1230                 $$ = all;
1231                 voice->unprotect ();
1232         }
1233         | LYRICSTO simple_string {
1234                 THIS->lexer_->push_lyric_state ();
1235         } Music {
1236                 THIS->lexer_->pop_state ();
1237                 Music *music = $4;
1238                 SCM name = $2;
1239                 $$ = make_lyric_combine_music (name, music);
1240                 music->unprotect();
1241         }
1242         ;
1243
1244 context_change:
1245         CHANGE STRING '=' STRING  {
1246                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1247                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1248                 t-> set_property ("change-to-id", $4);
1249
1250                 $$ = t;
1251                 $$->set_spot (@$);
1252         }
1253         ;
1254
1255 property_operation:
1256         STRING '=' scalar {
1257                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1258                         scm_string_to_symbol ($1), $3);
1259         }
1260         | UNSET simple_string {
1261                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1262                         scm_string_to_symbol ($2));
1263         }
1264         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1265                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1266                         scm_string_to_symbol ($2), $5, $3);
1267         }
1268         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1269                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1270                                 scm_string_to_symbol ($2), $6, $4, $3);
1271         }
1272         | REVERT simple_string embedded_scm {
1273                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1274                         scm_string_to_symbol ($2), $3);
1275         }
1276         ;
1277
1278 context_def_mod:
1279         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1280         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1281
1282         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1283         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1284         | DENIES { $$ = ly_symbol2scm ("denies"); }
1285
1286         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1287         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1288         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1289         | NAME { $$ = ly_symbol2scm ("context-name"); }
1290         ;
1291
1292 context_mod:
1293         property_operation { $$ = $1; }
1294         | context_def_mod STRING {
1295                 $$ = scm_list_2 ($1, $2);
1296         }
1297         ;
1298
1299 context_prop_spec:
1300         simple_string {
1301                 if (!is_regular_identifier ($1))
1302                 {
1303                         @$.error (_("Grob name should be alphanumeric"));
1304                 }
1305
1306                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1307                         scm_string_to_symbol ($1));
1308         }
1309         | simple_string '.' simple_string {
1310                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1311                         scm_string_to_symbol ($3));
1312         }
1313         ;
1314
1315 music_property_def:
1316         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1317                 $$ = property_op_to_music (scm_list_4 (
1318                         ly_symbol2scm ("push"),
1319                         scm_cadr ($2),
1320                         $5, $3));
1321                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1322         }
1323         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1324                 $$ = property_op_to_music (scm_list_5 (
1325                         ly_symbol2scm ("push"),
1326                         scm_cadr ($2),
1327                         $6, $4, $3));
1328                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1329         }
1330         | REVERT context_prop_spec embedded_scm {
1331                 $$ = property_op_to_music (scm_list_3 (
1332                         ly_symbol2scm ("pop"),
1333                         scm_cadr ($2),
1334                         $3));
1335
1336                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1337         }
1338         | SET context_prop_spec '=' scalar {
1339                 $$ = property_op_to_music (scm_list_3 (
1340                         ly_symbol2scm ("assign"),
1341                         scm_cadr ($2),
1342                         $4));
1343                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1344         }
1345         | UNSET context_prop_spec {
1346                 $$ = property_op_to_music (scm_list_2 (
1347                         ly_symbol2scm ("unset"),
1348                         scm_cadr ($2)));
1349                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1350         }
1351         | ONCE music_property_def {
1352                 SCM e = $2->get_property ("element");
1353                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1354                 $$ = $2;
1355
1356         }
1357         ;
1358
1359
1360 string:
1361         STRING {
1362                 $$ = $1;
1363         }
1364         | STRING_IDENTIFIER {
1365                 $$ = $1;
1366         }
1367         | string '+' string {
1368                 $$ = scm_string_append (scm_list_2 ($1, $3));
1369         }
1370         ;
1371
1372 simple_string: STRING {
1373                 $$ = $1;
1374         }
1375         | LYRICS_STRING {
1376                 $$ = $1;
1377         }
1378         | STRING_IDENTIFIER {
1379                 $$ = $1;
1380         }
1381         ;
1382
1383 scalar: string {
1384                 $$ = $1;
1385         }
1386         | LYRICS_STRING {
1387                 $$ = $1;
1388         }
1389         | bare_number {
1390                 $$ = $1;
1391         }
1392         | embedded_scm {
1393                 $$ = $1;
1394         }
1395         | full_markup {
1396                 $$ = $1;
1397         }
1398         | DIGIT {
1399                 $$ = scm_from_int ($1);
1400         }
1401         ;
1402
1403 /*
1404
1405 pre_events doesn't contain anything. It is a trick:
1406
1407 Adding pre_events to the simple_element
1408 makes the choice between
1409
1410   string:  STRING
1411
1412 and
1413
1414   simple_element: STRING
1415
1416 a single shift/reduction conflict.
1417
1418 nevertheless, this is not very clean, and we should find a different
1419 solution.
1420
1421 */
1422 pre_events: /* empty */
1423         ;
1424
1425 event_chord:
1426         pre_events simple_element post_events   {
1427                 SCM elts = $2-> get_property ("elements");
1428
1429                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1430
1431                 $2->set_property ("elements", elts);
1432                 /* why is this giving wrong start location? -ns
1433                  * $2->set_spot (@$); */
1434                 Input i;
1435                 i.set_location (@2, @3);
1436                 $2->set_spot (i);
1437                 $$ = $2;
1438         }
1439         | command_element
1440         | note_chord_element
1441         ;
1442
1443
1444 note_chord_element:
1445         chord_body optional_notemode_duration post_events
1446         {
1447                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1448                 SCM es = $1->get_property ("elements");
1449                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1450
1451                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1452                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1453                 es = ly_append2 (es, postevs);
1454
1455                 $1-> set_property ("elements", es);
1456                 $1->set_spot (@$);
1457                 $$ = $1;
1458         }
1459         ;
1460
1461 chord_open: '<'
1462         ;
1463
1464 chord_close: '>'
1465         ;
1466
1467 simul_open: DOUBLE_ANGLE_OPEN
1468         ;
1469
1470 simul_close: DOUBLE_ANGLE_CLOSE
1471         ;
1472
1473 chord_body:
1474         chord_open chord_body_elements chord_close
1475         {
1476                 $$ = MY_MAKE_MUSIC ("EventChord");
1477                 $$->set_spot (@$);
1478                 $$->set_property ("elements",
1479                         scm_reverse_x ($2, SCM_EOL));
1480         }
1481         ;
1482
1483 chord_body_elements:
1484         /* empty */             { $$ = SCM_EOL; }
1485         | chord_body_elements chord_body_element {
1486                 $$ = scm_cons ($2->self_scm (), $1);
1487                 $2->unprotect ();
1488         }
1489         ;
1490
1491 chord_body_element:
1492         pitch exclamations questions octave_check post_events
1493         {
1494                 int q = $3;
1495                 int ex = $2;
1496                 SCM check = $4;
1497                 SCM post = $5;
1498
1499                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1500                 n->set_property ("pitch", $1);
1501                 n->set_spot (@$);
1502                 if (q % 2)
1503                         n->set_property ("cautionary", SCM_BOOL_T);
1504                 if (ex % 2 || q % 2)
1505                         n->set_property ("force-accidental", SCM_BOOL_T);
1506
1507                 if (scm_is_pair (post)) {
1508                         SCM arts = scm_reverse_x (post, SCM_EOL);
1509                         n->set_property ("articulations", arts);
1510                 }
1511                 if (scm_is_number (check))
1512                 {
1513                         int q = scm_to_int (check);
1514                         n->set_property ("absolute-octave", scm_from_int (q-1));
1515                 }
1516
1517
1518                 $$ = n;
1519         }
1520         | DRUM_PITCH post_events {
1521                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1522                 n->set_property ("duration", $2);
1523                 n->set_property ("drum-type", $1);
1524                 n->set_spot (@$);
1525
1526                 if (scm_is_pair ($2)) {
1527                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1528                         n->set_property ("articulations", arts);
1529                 }
1530                 $$ = n;
1531         }
1532         | music_function_chord_body {
1533                 $$ = run_music_function (THIS, $1);
1534                 $$->set_spot (@$);
1535         }
1536         ;
1537
1538 music_function_chord_body:
1539         MUSIC_FUNCTION {
1540                 $$ = scm_list_2 ($1, make_input (@$));
1541         }
1542         | MUSIC_FUNCTION_MUSIC chord_body_element {
1543                 $$ = scm_list_3 ($1, make_input (@$),
1544                                         $2->self_scm ());
1545         }
1546         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm chord_body_element {
1547                 $$ = scm_list_4 ($1, make_input (@$),
1548                                         $2, $3->self_scm ());
1549         }
1550         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm
1551                 chord_body_element {
1552
1553                 $$ = scm_list_5 ($1, make_input (@$),
1554                                         $2, $3, $4->self_scm ());
1555         }
1556         ;
1557
1558
1559 add_quote:
1560         ADDQUOTE string Music {
1561                 SCM adder = ly_lily_module_constant ("add-quotable");
1562
1563                 scm_call_2 (adder, $2, $3->self_scm ());
1564                 $3->unprotect();
1565         }
1566         ;
1567
1568 command_element:
1569         command_event {
1570                 $$ = MY_MAKE_MUSIC ("EventChord");
1571                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1572                 $1->unprotect();
1573
1574                 $$-> set_spot (@$);
1575                 $1-> set_spot (@$);
1576         }
1577         | SKIP duration_length {
1578                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1579                 skip->set_property ("duration", $2);
1580                 skip->set_spot (@$);
1581                 $$ = skip;
1582         }
1583         | OCTAVE pitch {
1584                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1585                 $$ = m;
1586                 $$->set_spot (@$);
1587                 $$->set_property ("pitch", $2);
1588         }
1589         | E_BRACKET_OPEN {
1590                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1591                 m->set_property ("span-direction", scm_from_int (START));
1592                 m->set_spot (@$);
1593
1594                 $$ = MY_MAKE_MUSIC ("EventChord");
1595                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1596                 m->unprotect();
1597                 $$->set_spot (@$);
1598         }
1599         | E_BRACKET_CLOSE {
1600                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1601                 m->set_property ("span-direction", scm_from_int (STOP));
1602                 m->set_spot (@$);
1603
1604                 $$ = MY_MAKE_MUSIC ("EventChord");
1605                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1606                 $$->set_spot (@$);
1607                 m->unprotect ();
1608         }
1609         | E_BACKSLASH {
1610                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1611                 $$->set_spot (@$);
1612         }
1613         | '|'      {
1614                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1615
1616                 if (Music * m = unsmob_music (pipe))
1617                         $$ = m->clone ();
1618                 else
1619                         $$ = MY_MAKE_MUSIC ("BarCheck");
1620
1621                 $$->set_spot (@$);
1622         }
1623         | TRANSPOSITION pitch {
1624                 Pitch middle_c;
1625                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1626                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1627                                          sounds_as_c.smobbed_copy());
1628                 $$->set_spot (@$);
1629                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1630                         $$, SCM_EOL);
1631         }
1632         | BAR STRING                    {
1633                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1634
1635                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1636                                         t, SCM_EOL);
1637                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1638                 $$->set_spot (@$);
1639                 t->set_spot (@$);
1640         }
1641         | PARTIAL duration_length       {
1642                 Moment m = - unsmob_duration ($2)->get_length ();
1643                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1644                 p->set_spot (@$);
1645                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1646                                         p, SCM_EOL);
1647                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1648                                         p, SCM_EOL);
1649                 $$ = p;
1650         }
1651         | CLEF STRING  {
1652                 SCM proc = ly_lily_module_constant ("make-clef-set");
1653
1654                 SCM result = scm_call_1 (proc, $2);
1655                 $$ = unsmob_music (result);
1656                 $$->protect ();
1657         }
1658         | TIME_T fraction  {
1659                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1660
1661                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1662                 $$ = unsmob_music (result);
1663                 $$->protect ();
1664         }
1665         | MARK scalar {
1666                 SCM proc = ly_lily_module_constant ("make-mark-set");
1667
1668                 SCM result = scm_call_1 (proc, $2);
1669                 $$ = unsmob_music (result);
1670                 $$->protect ();
1671         }
1672         ;
1673
1674 command_event:
1675         E_TILDE {
1676                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1677         }
1678         | MARK DEFAULT  {
1679                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1680                 $$ = m;
1681         }
1682         | tempo_event {
1683                 $$ = $1;
1684         }
1685         | KEY DEFAULT {
1686                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1687                 $$ = key;
1688         }
1689         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1690
1691                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1692                 if (scm_ilength ($3) > 0)
1693                 {
1694                         key->set_property ("pitch-alist", $3);
1695                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1696                         key->transpose (* unsmob_pitch ($2));
1697                 } else {
1698                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1699                 }
1700
1701                 $$ = key;
1702         }
1703         ;
1704
1705
1706 post_events:
1707         /* empty */ {
1708                 $$ = SCM_EOL;
1709         }
1710         | post_events post_event {
1711                 $2->set_spot (@2);
1712                 $$ = scm_cons ($2->self_scm (), $$);
1713                 $2->unprotect ();
1714         }
1715         ;
1716
1717 music_function_event:
1718         MUSIC_FUNCTION_MUSIC post_event {
1719                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1720         }
1721         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm post_event {
1722                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1723         }
1724         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm post_event {
1725                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1726         }
1727         ;
1728
1729
1730 post_event:
1731         direction_less_event {
1732                 $$ = $1;
1733         }
1734         | '-' music_function_event {
1735                 Music *mus = run_music_function (THIS, $2);
1736                 mus->set_spot (@1);
1737                 $$ = mus;
1738         }
1739         | HYPHEN {
1740                 if (!THIS->lexer_->is_lyric_state ())
1741                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1742                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1743         }
1744         | EXTENDER {
1745                 if (!THIS->lexer_->is_lyric_state ())
1746                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1747                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1748         }
1749         | script_dir direction_reqd_event {
1750                 if ($1)
1751                         $2->set_property ("direction", scm_from_int ($1));
1752                 $$ = $2;
1753         }
1754         | script_dir direction_less_event {
1755                 if ($1)
1756                         $2->set_property ("direction", scm_from_int ($1));
1757                 $$ = $2;
1758         }
1759         | string_number_event
1760         ;
1761
1762 string_number_event:
1763         E_UNSIGNED {
1764                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1765                 s->set_property ("string-number", scm_from_int ($1));
1766                 s->set_spot (@$);
1767                 $$ = s;
1768         }
1769         ;
1770
1771 direction_less_char:
1772         '['  {
1773                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1774         }
1775         | ']'  {
1776                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1777         }
1778         | '~'  {
1779                 $$ = ly_symbol2scm ("tildeSymbol");
1780         }
1781         | '('  {
1782                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1783         }
1784         | ')'  {
1785                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1786         }
1787         | E_EXCLAMATION  {
1788                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1789         }
1790         | E_OPEN  {
1791                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1792         }
1793         | E_CLOSE  {
1794                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1795         }
1796         | E_ANGLE_CLOSE  {
1797                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1798         }
1799         | E_ANGLE_OPEN  {
1800                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1801         }
1802         ;
1803
1804 direction_less_event:
1805         direction_less_char {
1806                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1807                 Music * m = 0;
1808                 if (unsmob_music (predefd))
1809                 {
1810                         m = unsmob_music (predefd)->clone ();
1811                 }
1812                 else
1813                 {
1814                         m = MY_MAKE_MUSIC ("Music");
1815                 }
1816                 m->set_spot (@$);
1817                 $$ = m;
1818         }
1819         | EVENT_IDENTIFIER      {
1820                 $$ = unsmob_music ($1);
1821         }
1822         | tremolo_type  {
1823                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1824                a->set_spot (@$);
1825                a->set_property ("tremolo-type", scm_from_int ($1));
1826                $$ = a;
1827         }
1828         ;
1829
1830 direction_reqd_event:
1831         gen_text_def {
1832                 $$ = $1;
1833         }
1834         | script_abbreviation {
1835                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1836                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1837                 if (scm_is_string (s))
1838                         a->set_property ("articulation-type", s);
1839                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1840                 $$ = a;
1841         }
1842         ;
1843
1844 octave_check:
1845         /**/ { $$ = SCM_EOL; }
1846         | '='  { $$ = scm_from_int (0); }
1847         | '=' sub_quotes { $$ = scm_from_int ($2); }
1848         | '=' sup_quotes { $$ = scm_from_int ($2); }
1849         ;
1850
1851 sup_quotes:
1852         '\'' {
1853                 $$ = 1;
1854         }
1855         | sup_quotes '\'' {
1856                 $$ ++;
1857         }
1858         ;
1859
1860 sub_quotes:
1861         ',' {
1862                 $$ = 1;
1863         }
1864         | sub_quotes ',' {
1865                 $$++;
1866         }
1867         ;
1868
1869 steno_pitch:
1870         NOTENAME_PITCH  {
1871                 $$ = $1;
1872         }
1873         | NOTENAME_PITCH sup_quotes     {
1874                 Pitch p = *unsmob_pitch ($1);
1875                 p = p.transposed (Pitch ($2,0,0));
1876                 $$ = p.smobbed_copy ();
1877         }
1878         | NOTENAME_PITCH sub_quotes      {
1879                 Pitch p =* unsmob_pitch ($1);
1880                 p = p.transposed (Pitch (-$2,0,0));
1881                 $$ = p.smobbed_copy ();
1882         }
1883         ;
1884
1885 /*
1886 ugh. duplication
1887 */
1888
1889 steno_tonic_pitch:
1890         TONICNAME_PITCH {
1891                 $$ = $1;
1892         }
1893         | TONICNAME_PITCH sup_quotes    {
1894                 Pitch p = *unsmob_pitch ($1);
1895                 p = p.transposed (Pitch ($2,0,0));
1896                 $$ = p.smobbed_copy ();
1897         }
1898         | TONICNAME_PITCH sub_quotes     {
1899                 Pitch p =* unsmob_pitch ($1);
1900
1901                 p = p.transposed (Pitch (-$2,0,0));
1902                 $$ = p.smobbed_copy ();
1903         }
1904         ;
1905
1906 pitch:
1907         steno_pitch {
1908                 $$ = $1;
1909         }
1910         ;
1911
1912 pitch_also_in_chords:
1913         pitch
1914         | steno_tonic_pitch
1915         ;
1916
1917 gen_text_def:
1918         full_markup {
1919                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1920                 t->set_property ("text", $1);
1921                 t->set_spot (@$);
1922                 $$ = t;
1923         }
1924         | string {
1925                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1926                 t->set_property ("text",
1927                         make_simple_markup ($1));
1928                 t->set_spot (@$);
1929                 $$ = t;
1930
1931         }
1932         | DIGIT {
1933                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1934                 t->set_property ("digit", scm_from_int ($1));
1935                 t->set_spot (@$);
1936                 $$ = t;
1937         }
1938         ;
1939
1940 script_abbreviation:
1941         '^'             {
1942                 $$ = scm_makfrom0str ("Hat");
1943         }
1944         | '+'           {
1945                 $$ = scm_makfrom0str ("Plus");
1946         }
1947         | '-'           {
1948                 $$ = scm_makfrom0str ("Dash");
1949         }
1950         | '|'           {
1951                 $$ = scm_makfrom0str ("Bar");
1952         }
1953         | '>'           {
1954                 $$ = scm_makfrom0str ("Larger");
1955         }
1956         | '.'           {
1957                 $$ = scm_makfrom0str ("Dot");
1958         }
1959         | '_' {
1960                 $$ = scm_makfrom0str ("Underscore");
1961         }
1962         ;
1963
1964 script_dir:
1965         '_'     { $$ = DOWN; }
1966         | '^'   { $$ = UP; }
1967         | '-'   { $$ = CENTER; }
1968         ;
1969
1970
1971 absolute_pitch:
1972         steno_pitch     {
1973                 $$ = $1;
1974         }
1975         ;
1976
1977 duration_length:
1978         multiplied_duration {
1979                 $$ = $1;
1980         }
1981         ;
1982
1983 optional_notemode_duration:
1984         {
1985                 Duration dd = THIS->default_duration_;
1986                 $$ = dd.smobbed_copy ();
1987         }
1988         | multiplied_duration   {
1989                 $$ = $1;
1990                 THIS->default_duration_ = *unsmob_duration ($$);
1991         }
1992         ;
1993
1994 steno_duration:
1995         bare_unsigned dots              {
1996                 int len = 0;
1997                 if (!is_duration ($1))
1998                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
1999                 else
2000                         len = intlog2 ($1);
2001
2002                 $$ = Duration (len, $2).smobbed_copy ();
2003         }
2004         | DURATION_IDENTIFIER dots      {
2005                 Duration *d = unsmob_duration ($1);
2006                 Duration k (d->duration_log (), d->dot_count () + $2);
2007                 *d = k;
2008                 $$ = $1;
2009         }
2010         ;
2011
2012 multiplied_duration:
2013         steno_duration {
2014                 $$ = $1;
2015         }
2016         | multiplied_duration '*' bare_unsigned {
2017                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2018         }
2019         | multiplied_duration '*' FRACTION {
2020                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2021
2022                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2023         }
2024         ;
2025
2026 fraction:
2027         FRACTION { $$ = $1; }
2028         | UNSIGNED '/' UNSIGNED {
2029                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2030         }
2031         ;
2032
2033 dots:
2034         /* empty */     {
2035                 $$ = 0;
2036         }
2037         | dots '.' {
2038                 $$ ++;
2039         }
2040         ;
2041
2042 tremolo_type:
2043         ':'     {
2044                 $$ = 0;
2045         }
2046         | ':' bare_unsigned {
2047                 if (!is_duration ($2))
2048                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2049                 $$ = $2;
2050         }
2051         ;
2052
2053 bass_number:
2054         DIGIT   {
2055                 $$ = scm_from_int ($1);
2056         }
2057         | UNSIGNED {
2058                 $$ = scm_from_int ($1);
2059         }
2060         | STRING { $$ = $1; }
2061         | full_markup { $$ = $1; }
2062         ;
2063
2064 figured_bass_alteration:
2065         '-'     { $$ = -2; }
2066         | '+'   { $$ = 2; }
2067         | '!'   { $$ = 0; }
2068         ;
2069
2070 bass_figure:
2071         FIGURE_SPACE {
2072                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2073                 $$ = bfr->self_scm ();
2074                 bfr->unprotect ();
2075         }
2076         | bass_number  {
2077                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2078                 $$ = bfr->self_scm ();
2079
2080                 if (scm_is_number ($1))
2081                         bfr->set_property ("figure", $1);
2082                 else if (Text_interface::is_markup ($1))
2083                         bfr->set_property ("text", $1);
2084
2085                 bfr->unprotect ();
2086         }
2087         | bass_figure ']' {
2088                 $$ = $1;
2089                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2090         }
2091         | bass_figure figured_bass_alteration {
2092                 Music *m = unsmob_music ($1);
2093                 if ($2) {
2094                         SCM salter = m->get_property ("alteration");
2095                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2096                         m->set_property ("alteration",
2097                                 scm_from_int (alter + $2));
2098                 } else {
2099                         m->set_property ("alteration", scm_from_int (0));
2100                 }
2101         }
2102         | bass_figure figured_bass_modification  {
2103                 Music *m = unsmob_music ($1);
2104                 if ($2 == ly_symbol2scm ("plus"))
2105                         {
2106                         m->set_property ("augmented", SCM_BOOL_T);
2107                         }
2108                 else if ($2 == ly_symbol2scm ("slash"))
2109                         {
2110                         m->set_property ("diminished", SCM_BOOL_T);
2111                         }
2112                 else if ($2 == ly_symbol2scm ("exclamation"))
2113                         {
2114                         m->set_property ("no-continuation", SCM_BOOL_T);
2115                         }
2116         }
2117         ;
2118
2119
2120 figured_bass_modification:
2121         E_PLUS          {
2122                 $$ = ly_symbol2scm ("plus");
2123         }
2124         | E_EXCLAMATION {
2125                 $$ = ly_symbol2scm ("exclamation");
2126         }
2127         | '/'           {
2128                 $$ = ly_symbol2scm ("slash");
2129         }
2130         ;
2131
2132 br_bass_figure:
2133         bass_figure {
2134                 $$ = $1;
2135         }
2136         | '[' bass_figure {
2137                 $$ = $2;
2138                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2139         }
2140         ;
2141
2142 figure_list:
2143         /**/            {
2144                 $$ = SCM_EOL;
2145         }
2146         | figure_list br_bass_figure {
2147                 $$ = scm_cons ($2, $1);
2148         }
2149         ;
2150
2151 figure_spec:
2152         FIGURE_OPEN figure_list FIGURE_CLOSE {
2153                 Music *m = MY_MAKE_MUSIC ("EventChord");
2154                 $2 = scm_reverse_x ($2, SCM_EOL);
2155                 m->set_property ("elements", $2);
2156                 $$ = m->self_scm ();
2157         }
2158         ;
2159
2160
2161 optional_rest:
2162         /**/   { $$ = 0; }
2163         | REST { $$ = 1; }
2164         ;
2165
2166 simple_element:
2167         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2168                 if (!THIS->lexer_->is_note_state ())
2169                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2170
2171                 Music *n = 0;
2172                 if ($6)
2173                         n = MY_MAKE_MUSIC ("RestEvent");
2174                 else
2175                         n = MY_MAKE_MUSIC ("NoteEvent");
2176
2177                 n->set_property ("pitch", $1);
2178                 n->set_property ("duration", $5);
2179
2180                 if (scm_is_number ($4))
2181                 {
2182                         int q = scm_to_int ($4);
2183                         n->set_property ("absolute-octave", scm_from_int (q-1));
2184                 }
2185
2186                 if ($3 % 2)
2187                         n->set_property ("cautionary", SCM_BOOL_T);
2188                 if ($2 % 2 || $3 % 2)
2189                         n->set_property ("force-accidental", SCM_BOOL_T);
2190
2191                 Music *v = MY_MAKE_MUSIC ("EventChord");
2192                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2193                 n->unprotect ();
2194
2195                 v->set_spot (@$);
2196                 n->set_spot (@$);
2197                 $$ = v;
2198         }
2199         | DRUM_PITCH optional_notemode_duration {
2200                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2201                 n->set_property ("duration", $2);
2202                 n->set_property ("drum-type", $1);
2203
2204                 Music *v = MY_MAKE_MUSIC ("EventChord");
2205                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2206                 n->unprotect ();
2207                 v->set_spot (@$);
2208                 n->set_spot (@$);
2209                 $$ = v;
2210
2211         }
2212         | figure_spec optional_notemode_duration {
2213                 Music *m = unsmob_music ($1);
2214                 m->set_spot (@$);
2215                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2216                 {
2217                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2218                 }
2219                 $$ = m;
2220         }
2221         | RESTNAME optional_notemode_duration           {
2222                 Music *ev = 0;
2223                 if (ly_scm2string ($1) == "s") {
2224                         /* Space */
2225                         ev = MY_MAKE_MUSIC ("SkipEvent");
2226                   }
2227                 else {
2228                         ev = MY_MAKE_MUSIC ("RestEvent");
2229
2230                     }
2231                 ev->set_property ("duration", $2);
2232                 ev->set_spot (@$);
2233                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2234                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2235                 velt->set_spot (@$);
2236
2237                 ev->unprotect();
2238
2239                 $$ = velt;
2240         }
2241         | MULTI_MEASURE_REST optional_notemode_duration         {
2242                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2243                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2244                 $$ = unsmob_music (mus);
2245                 $$->protect ();
2246         }
2247
2248         | lyric_element optional_notemode_duration      {
2249                 if (!THIS->lexer_->is_lyric_state ())
2250                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2251
2252                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2253                 levent->set_property ("text", $1);
2254                 levent->set_property ("duration",$2);
2255                 levent->set_spot (@$);
2256                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2257                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2258
2259                 $$= velt;
2260         }
2261         | new_chord {
2262                 if (!THIS->lexer_->is_chord_state ())
2263                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2264                 $$ = unsmob_music ($1);
2265         }
2266         ;
2267
2268 lyric_element:
2269         lyric_markup {
2270                 $$ = $1;
2271         }
2272         | LYRICS_STRING {
2273                 $$ = $1;
2274         }
2275         ;
2276
2277 new_chord:
2278         steno_tonic_pitch optional_notemode_duration   {
2279                 $$ = make_chord ($1, $2, SCM_EOL);
2280         }
2281         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2282                 SCM its = scm_reverse_x ($4, SCM_EOL);
2283                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2284         }
2285         ;
2286
2287 chord_items:
2288         /**/ {
2289                 $$ = SCM_EOL;
2290         }
2291         | chord_items chord_item {
2292                 $$ = scm_cons ($2, $$);
2293         }
2294         ;
2295
2296 chord_separator:
2297         CHORD_COLON {
2298                 $$ = ly_symbol2scm ("chord-colon");
2299         }
2300         | CHORD_CARET {
2301                 $$ = ly_symbol2scm ("chord-caret");
2302         }
2303         | CHORD_SLASH steno_tonic_pitch {
2304                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2305         }
2306         | CHORD_BASS steno_tonic_pitch {
2307                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2308         }
2309         ;
2310
2311 chord_item:
2312         chord_separator {
2313                 $$ = $1;
2314         }
2315         | step_numbers {
2316                 $$ = scm_reverse_x ($1, SCM_EOL);
2317         }
2318         | CHORD_MODIFIER  {
2319                 $$ = $1;
2320         }
2321         ;
2322
2323 step_numbers:
2324         step_number { $$ = scm_cons ($1, SCM_EOL); }
2325         | step_numbers '.' step_number {
2326                 $$ = scm_cons ($3, $$);
2327         }
2328         ;
2329
2330 step_number:
2331         bare_unsigned {
2332                 $$ = make_chord_step ($1, 0);
2333         }
2334         | bare_unsigned '+' {
2335                 $$ = make_chord_step ($1, SHARP);
2336         }
2337         | bare_unsigned CHORD_MINUS {
2338                 $$ = make_chord_step ($1, FLAT);
2339         }
2340         ;
2341
2342 /*
2343         UTILITIES
2344
2345 TODO: should deprecate in favor of Scheme?
2346
2347  */
2348 number_expression:
2349         number_expression '+' number_term {
2350                 $$ = scm_sum ($1, $3);
2351         }
2352         | number_expression '-' number_term {
2353                 $$ = scm_difference ($1, $3);
2354         }
2355         | number_term
2356         ;
2357
2358 number_term:
2359         number_factor {
2360                 $$ = $1;
2361         }
2362         | number_factor '*' number_factor {
2363                 $$ = scm_product ($1, $3);
2364         }
2365         | number_factor '/' number_factor {
2366                 $$ = scm_divide ($1, $3);
2367         }
2368         ;
2369
2370 number_factor:
2371         '-'  number_factor { /* %prec UNARY_MINUS */
2372                 $$ = scm_difference ($2, SCM_UNDEFINED);
2373         }
2374         | bare_number
2375         ;
2376
2377
2378 bare_number:
2379         UNSIGNED        {
2380                 $$ = scm_from_int ($1);
2381         }
2382         | REAL          {
2383                 $$ = $1;
2384         }
2385         | NUMBER_IDENTIFIER             {
2386                 $$ = $1;
2387         }
2388         | REAL NUMBER_IDENTIFIER        {
2389                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2390         }
2391         | UNSIGNED NUMBER_IDENTIFIER    {
2392                 $$ = scm_from_double ($1 *scm_to_double ($2));
2393         }
2394         ;
2395
2396
2397 bare_unsigned:
2398         UNSIGNED {
2399                         $$ = $1;
2400         }
2401         | DIGIT {
2402                 $$ = $1;
2403         }
2404         ;
2405
2406 exclamations:
2407                 { $$ = 0; }
2408         | exclamations '!'      { $$ ++; }
2409         ;
2410
2411 questions:
2412                 { $$ = 0; }
2413         | questions '?' { $$ ++; }
2414         ;
2415
2416 /*
2417 This should be done more dynamically if possible.
2418 */
2419
2420 lyric_markup:
2421         LYRIC_MARKUP_IDENTIFIER {
2422                 $$ = $1;
2423         }
2424         | LYRIC_MARKUP
2425                 { THIS->lexer_->push_markup_state (); }
2426         markup_top {
2427                 $$ = $3;
2428                 THIS->lexer_->pop_state ();
2429         }
2430         ;
2431
2432 full_markup:
2433         MARKUP_IDENTIFIER {
2434                 $$ = $1;
2435         }
2436         | MARKUP
2437                 { THIS->lexer_->push_markup_state (); }
2438         markup_top {
2439                 $$ = $3;
2440                 THIS->lexer_->pop_state ();
2441         }
2442         ;
2443
2444 markup_top:
2445         markup_list {
2446                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2447         }
2448         | markup_head_1_list simple_markup      {
2449                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2450         }
2451         | simple_markup {
2452                 $$ = $1;
2453         }
2454         ;
2455
2456 markup_list:
2457         markup_composed_list {
2458                 $$ = $1;
2459         }
2460         | markup_braced_list {
2461                 $$ = $1;
2462         }
2463         ;
2464
2465 markup_composed_list:
2466         markup_head_1_list markup_braced_list {
2467                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2468
2469         }
2470         ;
2471
2472 markup_braced_list:
2473         '{' markup_braced_list_body '}' {
2474                 $$ = scm_reverse_x ($2, SCM_EOL);
2475         }
2476         ;
2477
2478 markup_braced_list_body:
2479         /* empty */     {  $$ = SCM_EOL; }
2480         | markup_braced_list_body markup {
2481                 $$ = scm_cons ($2, $1);
2482         }
2483         | markup_braced_list_body markup_list {
2484                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2485         }
2486         ;
2487
2488 markup_head_1_item:
2489         MARKUP_HEAD_MARKUP0     {
2490                 $$ = scm_list_1 ($1);
2491         }
2492         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2493                 $$ = scm_list_2 ($1, $2);
2494         }
2495         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2496                 $$ = scm_list_3 ($1, $2, $3);
2497         }
2498         ;
2499
2500 markup_head_1_list:
2501         markup_head_1_item      {
2502                 $$ = scm_list_1 ($1);
2503         }
2504         | markup_head_1_list markup_head_1_item {
2505                 $$ = scm_cons ($2, $1);
2506         }
2507         ;
2508
2509 simple_markup:
2510         STRING {
2511                 $$ = make_simple_markup ($1);
2512         }
2513         | MARKUP_IDENTIFIER {
2514                 $$ = $1;
2515         }
2516         | LYRIC_MARKUP_IDENTIFIER {
2517                 $$ = $1;
2518         }
2519         | STRING_IDENTIFIER {
2520                 $$ = $1;
2521         }
2522         | SCORE {
2523                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2524                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2525         } '{' score_body '}' {
2526                 Score * sc = $4;
2527                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2528                 sc->unprotect ();
2529                 THIS->lexer_->pop_state ();
2530         }
2531         | MARKUP_HEAD_SCM0 embedded_scm {
2532                 $$ = scm_list_2 ($1, $2);
2533         }
2534         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2535                 $$ = scm_list_4 ($1, $2, $3, $4);
2536         }
2537         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2538                 $$ = scm_list_3 ($1, $2, $3);
2539         }
2540         | MARKUP_HEAD_EMPTY {
2541                 $$ = scm_list_1 ($1);
2542         }
2543         | MARKUP_HEAD_LIST0 markup_list {
2544                 $$ = scm_list_2 ($1,$2);
2545         }
2546         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2547                 $$ = scm_list_3 ($1, $2, $3);
2548         }
2549         ;
2550
2551 markup:
2552         markup_head_1_list simple_markup        {
2553                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2554                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2555         }
2556         | simple_markup {
2557                 $$ = $1;
2558         }
2559         ;
2560
2561 %%
2562
2563 void
2564 Lily_parser::set_yydebug (bool )
2565 {
2566 #if 0
2567         yydebug = 1;
2568 #endif
2569 }
2570
2571 void
2572 Lily_parser::do_yyparse ()
2573 {
2574         yyparse ((void*)this);
2575 }
2576
2577
2578
2579
2580
2581 /*
2582
2583 It is a little strange to have this function in this file, but
2584 otherwise, we have to import music classes into the lexer.
2585
2586 */
2587 int
2588 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2589 {
2590         if (scm_is_string (sid)) {
2591                 *destination = sid;
2592                 return STRING_IDENTIFIER;
2593         } else if (unsmob_book (sid)) {
2594                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2595                 return BOOK_IDENTIFIER;
2596         } else if (scm_is_number (sid)) {
2597                 *destination = sid;
2598                 return NUMBER_IDENTIFIER;
2599         } else if (unsmob_context_def (sid)) {
2600                 *destination = unsmob_context_def (sid)->clone_scm ();
2601                 return CONTEXT_DEF_IDENTIFIER;
2602         } else if (unsmob_score (sid)) {
2603                 Score *score = new Score (*unsmob_score (sid));
2604                 *destination = score->self_scm ();
2605                 return SCORE_IDENTIFIER;
2606         } else if (Music *mus = unsmob_music (sid)) {
2607                 mus = mus->clone ();
2608                 *destination = mus->self_scm ();
2609                 unsmob_music (*destination)->
2610                         set_property ("origin", make_input (last_input_));
2611
2612                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2613                         != SCM_BOOL_F;
2614
2615                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2616         } else if (unsmob_duration (sid)) {
2617                 *destination = unsmob_duration (sid)->smobbed_copy ();
2618                 return DURATION_IDENTIFIER;
2619         } else if (unsmob_output_def (sid)) {
2620                 Output_def *p = unsmob_output_def (sid);
2621                 p = p->clone ();
2622
2623                 *destination = p->self_scm ();
2624                 return OUTPUT_DEF_IDENTIFIER;
2625         } else if (Text_interface::is_markup (sid)) {
2626                 *destination = sid;
2627                 if (is_lyric_state ())
2628                         return LYRIC_MARKUP_IDENTIFIER;
2629                 return MARKUP_IDENTIFIER;
2630         }
2631
2632         return -1;
2633 }
2634
2635 Music *
2636 property_op_to_music (SCM op)
2637 {
2638         Music *m = 0;
2639         SCM tag = scm_car (op);
2640         SCM symbol = scm_cadr (op);
2641         SCM args = scm_cddr (op);
2642         SCM grob_val = SCM_UNDEFINED;
2643         SCM grob_path = SCM_UNDEFINED;
2644         SCM val = SCM_UNDEFINED;
2645
2646         if (tag == ly_symbol2scm ("assign"))
2647                 {
2648                 m = MY_MAKE_MUSIC ("PropertySet");
2649                 val = scm_car (args);
2650                 }
2651         else if (tag == ly_symbol2scm ("unset"))
2652                 m = MY_MAKE_MUSIC ("PropertyUnset");
2653         else if (tag == ly_symbol2scm ("push"))
2654                 {
2655                 m = MY_MAKE_MUSIC ("OverrideProperty");
2656                 grob_val = scm_car (args);
2657                 grob_path = scm_cdr (args);
2658                 m->set_property ("pop-first", SCM_BOOL_T);
2659                 }
2660         else if (tag == ly_symbol2scm ("pop")) {
2661                 m = MY_MAKE_MUSIC ("RevertProperty");
2662                 grob_path = args;
2663                 }
2664
2665         m->set_property ("symbol", symbol);
2666
2667         if (val != SCM_UNDEFINED)
2668                 m->set_property ("value", val);
2669         if (grob_val != SCM_UNDEFINED)
2670                 m->set_property ("grob-value", grob_val);
2671         if (grob_path != SCM_UNDEFINED)
2672                 m->set_property ("grob-property-path", grob_path);
2673
2674         return m;
2675 }
2676
2677 Music*
2678 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2679 {
2680         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2681
2682         csm->set_property ("element", m->self_scm ());
2683         m->unprotect ();
2684
2685         csm->set_property ("context-type",
2686                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2687         csm->set_property ("property-operations", ops);
2688
2689         if (scm_is_string (id))
2690                 csm->set_property ("context-id", id);
2691         return csm;
2692 }
2693
2694 SCM
2695 get_next_unique_context_id ()
2696 {
2697         return scm_makfrom0str ("$uniqueContextId");
2698 }
2699
2700
2701 SCM
2702 get_next_unique_lyrics_context_id ()
2703 {
2704         static int new_context_count;
2705         char s[128];
2706         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2707         return scm_makfrom0str (s);
2708 }
2709
2710
2711 Music *
2712 run_music_function (Lily_parser *parser, SCM expr)
2713 {
2714         SCM func = scm_car (expr);
2715         Input *loc = unsmob_input (scm_cadr (expr));
2716         SCM args = scm_cddr (expr);
2717         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2718
2719         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2720         bool ok  = true;
2721
2722         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2723         {
2724                 parser->error_level_ = 1;
2725                 ok = false;
2726         }
2727
2728         SCM m = SCM_EOL;
2729         if (ok)
2730                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2731                                                  scm_cdr (expr)));
2732
2733
2734         Music* retval = 0;
2735         if (unsmob_music (m))
2736                 {
2737                 retval = unsmob_music (m);
2738                 retval->protect ();
2739                 }
2740         else
2741                 {
2742                 if (ok)
2743                         loc->error (_ ("music head function must return Music object"));
2744                 retval = MY_MAKE_MUSIC ("Music");
2745                 }
2746         retval->set_spot (*loc);
2747         return retval;
2748 }
2749
2750 bool
2751 is_regular_identifier (SCM id)
2752 {
2753   String str = ly_scm2string (id);
2754   char const *s = str.to_str0 ();
2755
2756   bool v = true;
2757 #if 0
2758   isalpha (*s);
2759   s++;
2760 #endif
2761   while (*s && v)
2762    {
2763         v = v && isalnum (*s);
2764         s++;
2765    }
2766   return v;
2767 }
2768
2769
2770 SCM
2771 get_first_context_id (SCM type, Music *m)
2772 {
2773         SCM id = m->get_property ("context-id");
2774         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2775             && scm_is_string (m->get_property ("context-id"))
2776             && scm_c_string_length (id) > 0)
2777         {
2778                 return id;
2779         }
2780         return SCM_EOL;
2781 }
2782
2783 SCM
2784 make_simple_markup (SCM a)
2785 {
2786         return a;
2787 }
2788
2789 bool
2790 is_duration (int t)
2791 {
2792   return t && t == 1 << intlog2 (t);
2793 }
2794
2795 void
2796 set_music_properties (Music *p, SCM a)
2797 {
2798   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2799         p->internal_set_property (scm_caar (k), scm_cdar (k));
2800 }
2801
2802
2803 SCM
2804 make_chord_step (int step, int alter)
2805 {
2806         if (step == 7)
2807                 alter += FLAT;
2808
2809         while (step < 0)
2810                 step += 7;
2811         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2812         return m.smobbed_copy ();
2813 }
2814
2815
2816 SCM
2817 make_chord (SCM pitch, SCM dur, SCM modification_list)
2818 {
2819         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2820         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2821
2822         unsmob_music (ch)->protect();
2823         return ch;
2824 }
2825
2826
2827 /* Todo: actually also use apply iso. call too ...  */
2828 bool
2829 ly_input_procedure_p (SCM x)
2830 {
2831         return ly_is_procedure (x)
2832                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2833 }
2834
2835 Music*
2836 set_property_music (SCM sym, SCM value)
2837 {
2838         Music *p = MY_MAKE_MUSIC ("PropertySet");
2839         p->set_property ("symbol", sym);
2840         p->set_property ("value", value);
2841         return p;
2842 }
2843
2844 Music*
2845 make_music_relative (Pitch start, Music *music)
2846 {
2847         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2848         relative->set_property ("element", music->self_scm ());
2849
2850         Pitch last = music->to_relative_octave (start);
2851         if (lily_1_8_relative)
2852                 music->set_property ("last-pitch", last.smobbed_copy ());
2853         return relative;
2854 }
2855
2856 Music *
2857 make_lyric_combine_music (SCM name, Music *music)
2858 {
2859         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2860         combine->set_property ("element", music->self_scm ());
2861         combine->set_property ("associated-context", name);
2862         return combine;
2863 }
2864
2865
2866 int
2867 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2868 {
2869         Lily_parser *pars = (Lily_parser*) v;
2870         Lily_lexer *lex = pars->lexer_;
2871
2872         lex->lexval = (void*) s;
2873         lex->lexloc = loc;
2874         lex->prepare_for_next_token ();
2875         return lex->yylex ();
2876 }