lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_mus_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_mus_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 regular_identifier_b (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_n (simple, a, SCM_UNDEFINED);
 143 }
 144
 145
 146 bool
 147 is_duration_b (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token PITCHNAMES
 287 %token PROPERTY
 288 %token RELATIVE
 289 %token REMOVE
 290 %token REPEAT
 291 %token REST
 292 %token SCM_T
 293 %token SCORE
 294 %token SEQUENTIAL
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSLATOR
 303 %token TRANSPOSE
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 310 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 311 %token E_BACKSLASH
 312 %token <i> E_UNSIGNED
 313 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 314 %token FIGURE_SPACE
 315
 316 %type <i>       exclamations questions dots optional_rest
 317 %type <i>        bass_mod
 318 %type <scm>     grace_head
 319 %type <scm>     oct_check
 320 %type <scm>     context_mod_list
 321 %type <scm>     lyric_element
 322 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 323 %token <i>      DIGIT
 324 %token <scm>    NOTENAME_PITCH
 325 %token <scm>    TONICNAME_PITCH
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DURATION_IDENTIFIER
 328 %token <scm>    FRACTION
 329 %token <id>     IDENTIFIER
 330 %token <scm>    CHORDNAMES
 331 %token <scm>    CHORD_MODIFIER
 332 %token <scm>    SCORE_IDENTIFIER
 333 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    NUMBER_IDENTIFIER
 335 %token <scm>    EVENT_IDENTIFIER
 336 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    RESTNAME
 339 %token <scm>    STRING
 340 %token <scm>    SCM_T
 341 %token <i>      UNSIGNED
 342 %token <scm>   REAL
 343
 344 %token MARKUP
 345 %token <scm> MARKUP_HEAD_MARKUP0
 346 %token <scm> MARKUP_HEAD_EMPTY
 347 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0
 349 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 353
 354 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 355 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 356
 357 %type <outputdef> output_def
 358 %type <scm>     lilypond_header lilypond_header_body
 359 %type <music>   open_event close_event
 360 %type <i>       sub_quotes sup_quotes
 361 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 362 %type <music>   Repeated_music
 363 %type <scm>     Alternative_music
 364 %type <i>       tremolo_type
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       script_dir
 367 %type <scm>     identifier_init
 368
 369 %type <music> note_chord_element chord_body chord_body_element
 370 %type <scm>  chord_body_elements
 371 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 372
 373 %type <scm>   post_events
 374 %type <music> gen_text_def direction_less_event direction_reqd_event
 375 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 376 %type <scm>    steno_tonic_pitch
 377 %type <scm>     duration_length fraction
 378
 379 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 380
 381 %type <scm>  embedded_scm scalar
 382 %type <music>   Music Sequential_music Simultaneous_music
 383 %type <music>   relative_music re_rhythmed_music
 384 %type <music>   music_property_def context_change
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body music_output_def_head
 388 %type <music> shorthand_command_req
 389 %type <music>   post_event tagged_post_event
 390 %type <music> command_req verbose_command_req
 391 %type <music> string_number_event
 392 %type <scm>     string bare_number number_expression number_term number_factor
 393 %type <score>   score_block score_body
 394
 395 %type <scm>     translator_spec_block translator_spec_body
 396 %type <music>   tempo_event
 397 %type <scm> notenames_body notenames_block chordmodifiers_block
 398 %type <scm>     script_abbreviation
 399
 400
 401
 402 %left '-' '+'
 403
 404 /* We don't assign precedence to / and *, because we might need varied
 405 prec levels in different prods */
 406
 407 %left UNARY_MINUS
 408
 409 %%
 410
 411 lilypond:       /* empty */
 412         | lilypond toplevel_expression {}
 413         | lilypond assignment  { }
 414         | lilypond error {
 415                 THIS->error_level_  = 1;
 416         }
 417         | lilypond INVALID      {
 418                 THIS->error_level_  = 1;
 419         }
 420         ;
 421
 422 toplevel_expression:
 423         notenames_block                 {
 424                 THIS->lexer_->pitchname_tab_ =  $1;
 425         }
 426         | chordmodifiers_block                  {
 427                 THIS->lexer_->chordmodifier_tab_  = $1;
 428         }
 429         | lilypond_header {
 430                 THIS->input_file_->header_ = $1;
 431         }
 432         | score_block {
 433                 Score * sc = $1;
 434
 435                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 436
 437                 Path p = split_path (THIS->output_basename_);
 438                 int *c =  &THIS->input_file_->score_count_;
 439                 if (*c)
 440                         {
 441                         p.base += "-" + to_string (*c);
 442                         }
 443
 444                 (*c)++;
 445                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 446
 447                 for (int i=0; i < sc->defs_.size (); i++)
 448                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 449
 450                 if (sc->defs_.empty ())
 451                 {
 452                    Music_output_def *id =
 453                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 454                                 ("$defaultpaper"));
 455
 456                    id = id ? id->clone () : new Paper_def;
 457
 458                    default_rendering (sc->music_, id->self_scm(), head, outname);
 459
 460                    scm_gc_unprotect_object (id->self_scm ());
 461                 }
 462                 scm_gc_unprotect_object (sc->self_scm());
 463         }
 464         | output_def {
 465                 SCM id = SCM_EOL;
 466                 if (dynamic_cast<Paper_def*> ($1))
 467                         id = scm_makfrom0str ("$defaultpaper");
 468                 else if (dynamic_cast<Midi_def*> ($1))
 469                         id = scm_makfrom0str ("$defaultmidi");
 470                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 471                 scm_gc_unprotect_object ($1->self_scm ());
 472         }
 473         ;
 474
 475 embedded_scm:
 476         SCM_T
 477         | SCM_IDENTIFIER
 478         ;
 479
 480
 481 chordmodifiers_block:
 482         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 483         ;
 484
 485 notenames_block:
 486         PITCHNAMES notenames_body   {  $$ = $2; }
 487         ;
 488
 489 notenames_body:
 490         embedded_scm    {
 491           int i = scm_ilength ($1);
 492
 493           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 494           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 495                 SCM pt = ly_cdar (s);
 496                 scm_hashq_set_x (tab, ly_caar (s), pt);
 497           }
 498           $$ = tab;
 499         }
 500         ;
 501
 502 lilypond_header_body:
 503         {
 504                 $$ = ly_make_anonymous_module ();
 505                 THIS->lexer_->add_scope ($$);
 506         }
 507         | lilypond_header_body assignment  {
 508
 509         }
 510         ;
 511
 512 lilypond_header:
 513         HEADER '{' lilypond_header_body '}'     {
 514                 $$ = THIS->lexer_-> remove_scope();
 515         }
 516         ;
 517
 518
 519 /*
 520         DECLARATIONS
 521 */
 522 assignment:
 523         STRING {
 524                 THIS->push_spot ();
 525         }
 526         /* cont */ '=' identifier_init  {
 527
 528         /*
 529                 Should find generic way of associating input with objects.
 530         */
 531                 Input ip = THIS->pop_spot ();
 532
 533                 if (! regular_identifier_b ($1))
 534                 {
 535                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 536                 }
 537
 538                 THIS->lexer_->set_identifier ($1, $4);
 539
 540 /*
 541  TODO: devise standard for protection in parser.
 542
 543   The parser stack lives on the C-stack, which means that
 544 all objects can be unprotected as soon as they're here.
 545
 546 */
 547         }
 548         | embedded_scm { }
 549         ;
 550
 551
 552 identifier_init:
 553         score_block {
 554                 $$ = $1->self_scm ();
 555                 scm_gc_unprotect_object ($$);
 556         }
 557         | full_markup {
 558                 $$ = $1;
 559         }
 560         | output_def {
 561                 $$ = $1->self_scm ();
 562                 scm_gc_unprotect_object ($$);
 563         }
 564         | translator_spec_block {
 565                 $$ = $1;
 566         }
 567         | Music  {
 568                 $$ = $1->self_scm ();
 569                 scm_gc_unprotect_object ($$);
 570         }
 571         | post_event {
 572                 $$ = $1->self_scm ();
 573                 scm_gc_unprotect_object ($$);
 574         }
 575         | number_expression {
 576                 $$ = $1;
 577         }
 578         | string {
 579                 $$ = $1;
 580         }
 581         | embedded_scm  {
 582                 $$ = $1;
 583         }
 584         ;
 585
 586 translator_spec_block:
 587         TRANSLATOR '{' translator_spec_body '}'
 588                 {
 589                 $$ = $3;
 590         }
 591         ;
 592
 593 translator_spec_body:
 594         /**/ {
 595                 $$ = Context_def::make_scm ();
 596                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 597         }
 598         | TRANSLATOR_IDENTIFIER {
 599                 $$ = $1;
 600                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 601         }
 602         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 603                 Context_def*td = unsmob_context_def($$);
 604
 605                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 606                         SCM tag = gh_caar (p);
 607                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 608                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 609                 }
 610         }
 611         | translator_spec_body context_mod {
 612                 unsmob_context_def ($$)->add_context_mod ($2);
 613         }
 614         ;
 615
 616 /*
 617         SCORE
 618 */
 619 score_block:
 620         SCORE {
 621                 THIS->push_spot ();
 622         }
 623         /*cont*/ '{' score_body '}'     {
 624                 THIS->pop_spot ();
 625                 $$ = $4;
 626
 627         }
 628         ;
 629
 630 score_body:
 631         Music   {
 632                 $$ = new Score;
 633
 634                 $$->set_spot (THIS->here_input ());
 635                 SCM m = $1->self_scm ();
 636                 scm_gc_unprotect_object (m);
 637
 638                 /*
 639                         guh.
 640                 */
 641                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 642                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 643                         m = gh_call1 (gh_car (check_funcs), m);
 644                 $$->music_ = m;
 645
 646         }
 647         | SCORE_IDENTIFIER {
 648                 $$ = new Score ( *unsmob_score ($1));
 649                 $$->set_spot (THIS->here_input ());
 650         }
 651         | score_body lilypond_header    {
 652                 $$->header_ = $2;
 653         }
 654         | score_body output_def {
 655                 $$->defs_.push ($2);
 656                 scm_gc_unprotect_object ($2->self_scm ());
 657         }
 658         | score_body error {
 659
 660         }
 661         ;
 662
 663
 664 /*
 665         MIDI
 666 */
 667 output_def:
 668         music_output_def_body '}' {
 669                 $$ = $1;
 670                 THIS-> lexer_-> remove_scope ();
 671         }
 672         ;
 673
 674 music_output_def_head:
 675         MIDI    {
 676                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 677
 678
 679                 Midi_def* p =0;
 680                 if (id)
 681                         p = dynamic_cast<Midi_def*> (id->clone ());
 682                 else
 683                         p = new Midi_def;
 684
 685                 $$ = p;
 686                 THIS->lexer_->add_scope (p->scope_);
 687         }
 688         | PAPER         {
 689                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 690                   Paper_def *p = 0;
 691                 if (id)
 692                         p = dynamic_cast<Paper_def*> (id->clone ());
 693                 else
 694                         p = new Paper_def;
 695
 696                 THIS->lexer_->add_scope (p->scope_);
 697                 $$ = p;
 698         }
 699         ;
 700
 701
 702 music_output_def_body:
 703         music_output_def_head '{' {
 704
 705         }
 706         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 707                 Music_output_def * o =  unsmob_music_output_def ($3);
 708                 $$ = o;
 709                 THIS->lexer_->remove_scope ();
 710                 THIS->lexer_->add_scope (o->scope_);
 711         }
 712         | music_output_def_body assignment  {
 713
 714         }
 715         | music_output_def_body translator_spec_block   {
 716                 $$->assign_translator ($2);
 717         }
 718         | music_output_def_body tempo_event  {
 719                 /*
 720                         junk this ? there already is tempo stuff in
 721                         music.
 722                 */
 723                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 724                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 725                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 726                 if (md)
 727                         md->set_tempo (d->get_length (), m);
 728                 scm_gc_unprotect_object ($2->self_scm ());
 729         }
 730         | music_output_def_body error {
 731
 732         }
 733         ;
 734
 735 tempo_event:
 736         TEMPO steno_duration '=' bare_unsigned  {
 737                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 738                 $$->set_mus_property ("tempo-unit", $2);
 739                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 740         }
 741         ;
 742
 743 /*
 744 The representation of a  list is the
 745
 746   (LIST . LAST-CONS)
 747
 748  to have  efficient append.
 749 */
 750 Music_list:
 751         /* empty */ {
 752                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 753         }
 754         | Music_list Music {
 755                 SCM s = $$;
 756                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 757                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 758                 if (gh_pair_p (ly_cdr (s)))
 759                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 760                 else
 761                         gh_set_car_x (s, c); /* set first cons */
 762                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 763         }
 764         | Music_list error {
 765         }
 766         ;
 767
 768
 769 Music:
 770         Simple_music
 771         | Composite_music
 772         ;
 773
 774 Alternative_music:
 775         /* empty */ {
 776                 $$ = SCM_EOL;
 777         }
 778         | ALTERNATIVE '{' Music_list '}' {
 779                 $$ = $3;
 780         }
 781         ;
 782
 783 Repeated_music:
 784         REPEAT string bare_unsigned Music Alternative_music
 785         {
 786                 Music *beg = $4;
 787                 int times = $3;
 788                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 789                 if (times < scm_ilength (alts)) {
 790                   unsmob_music (gh_car (alts))
 791                     ->origin ()->warning (
 792                     _("More alternatives than repeats.  Junking excess alternatives."));
 793                   alts = ly_truncate_list (times, alts);
 794                 }
 795
 796
 797                 static SCM proc;
 798                 if (!proc)
 799                         proc = scm_c_eval_string ("make-repeated-music");
 800
 801                 SCM mus = scm_call_1 (proc, $2);
 802                 scm_gc_protect_object (mus); // UGH.
 803                 Music *r =unsmob_music (mus);
 804                 if (beg)
 805                         {
 806                         r-> set_mus_property ("element", beg->self_scm ());
 807                         scm_gc_unprotect_object (beg->self_scm ());
 808                         }
 809                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 810
 811                 r-> set_mus_property ("elements",alts);
 812                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 813                         /*
 814                         we can not get durations and other stuff correct down the line, so we have to
 815                         add to the duration log here.
 816                         */
 817                         static SCM func;
 818
 819                         if (!func)
 820                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 821
 822                         int dots = ($3 % 3) ? 0 : 1;
 823                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 824
 825                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 826
 827                         if (seq) {
 828                                 int list_len =scm_ilength (seq->music_list ());
 829                                 if (list_len != 2)
 830                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 831                                 shift -= 1;
 832                                 r->compress (Moment (Rational (1,list_len)));
 833                                 }
 834                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 835
 836                 }
 837                 r->set_spot (*$4->origin ());
 838
 839                 $$ = r;
 840         }
 841         ;
 842
 843 Sequential_music:
 844         SEQUENTIAL '{' Music_list '}'           {
 845                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 846                 $$->set_mus_property ("elements", ly_car ($3));
 847                 $$->set_spot(THIS->here_input());
 848         }
 849         | '{' Music_list '}'            {
 850                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 851                 $$->set_mus_property ("elements", ly_car ($2));
 852                 $$->set_spot(THIS->here_input());
 853         }
 854         ;
 855
 856 Simultaneous_music:
 857         SIMULTANEOUS '{' Music_list '}'{
 858                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 859                 $$->set_mus_property ("elements", ly_car ($3));
 860                 $$->set_spot(THIS->here_input());
 861
 862         }
 863         | simul_open Music_list simul_close     {
 864                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 865                 $$->set_mus_property ("elements", ly_car ($2));
 866                 $$->set_spot(THIS->here_input());
 867         }
 868         ;
 869
 870 Simple_music:
 871         event_chord             { $$ = $1; }
 872         | APPLYOUTPUT embedded_scm {
 873                 if (!ly_input_procedure_p ($2))
 874                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 875                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 876                 $$->set_mus_property ("procedure", $2);
 877                 $$->set_spot (THIS->here_input());
 878         }
 879         | APPLYCONTEXT embedded_scm {
 880                 if (!ly_input_procedure_p ($2))
 881                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 882                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 883                 $$->set_mus_property ("procedure", $2);
 884                 $$->set_spot (THIS->here_input());
 885         }
 886         | MUSIC_IDENTIFIER {
 887                 $$ = unsmob_music ($1);
 888         }
 889         | music_property_def
 890         | context_change
 891         ;
 892
 893
 894 optional_context_mod:
 895         /**/ { $$ = SCM_EOL; }
 896         | WITH '{' context_mod_list '}'  { $$ = $3; }
 897         ;
 898
 899 grace_head:
 900         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 901         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 902         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 903         ;
 904
 905 context_mod_list:
 906         /* */  { $$ = SCM_EOL; }
 907         | context_mod_list context_mod  {
 908                  $$ = gh_cons ($2, $1);
 909         }
 910         ;
 911
 912 Composite_music:
 913         AUTOCHANGE Music        {
 914                 static SCM proc ;
 915                 if (!proc)
 916                         proc = scm_c_eval_string ("make-autochange-music");
 917
 918                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 919                 scm_gc_unprotect_object ($2->self_scm ());
 920                 $$ = unsmob_music (res);
 921                 scm_gc_protect_object (res);
 922                 $$->set_spot (THIS->here_input())
 923         }
 924         | PARTCOMBINE Music Music {
 925                 static SCM proc;
 926                 if (!proc)
 927                         proc = scm_c_eval_string ("make-part-combine-music");
 928
 929                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 930                         $3->self_scm (), SCM_UNDEFINED));
 931                 scm_gc_unprotect_object ($3->self_scm ());
 932                 scm_gc_unprotect_object ($2->self_scm ());
 933                 $$ = unsmob_music (res);
 934                 scm_gc_protect_object (res);
 935                 $$->set_spot (THIS->here_input());
 936         }
 937         | grace_head Music {
 938 #if 1
 939         /*
 940                 The other version is for easier debugging  of
 941                 Sequential_music_iterator in combination with grace notes.
 942         */
 943
 944 /*
 945
 946 TODO: should distinguish between both grace types in the
 947 basic music objects too, since the meaning is different.
 948
 949 */
 950
 951                 String start_str = "start" + ly_scm2string ($1) + "Music";
 952                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 953
 954                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 955                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 956
 957                 Music *startm = unsmob_music (start);
 958                 Music *stopm = unsmob_music (stop);
 959
 960                 SCM ms = SCM_EOL;
 961                 if (stopm) {
 962                         stopm = stopm->clone ();
 963                         ms = scm_cons (stopm->self_scm (), ms);
 964                         scm_gc_unprotect_object (stopm->self_scm ());
 965                 }
 966                 ms = scm_cons ($2->self_scm (), ms);
 967                 scm_gc_unprotect_object ($2->self_scm());
 968                 if (startm) {
 969                         startm = startm->clone ();
 970                         ms = scm_cons (startm->self_scm () , ms);
 971                         scm_gc_unprotect_object (startm->self_scm ());
 972                 }
 973
 974
 975                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 976                 seq->set_mus_property ("elements", ms);
 977
 978
 979                 $$ = MY_MAKE_MUSIC("GraceMusic");
 980                 $$->set_mus_property ("element", seq->self_scm ());
 981                 scm_gc_unprotect_object (seq->self_scm ());
 982 #else
 983                 $$ = MY_MAKE_MUSIC("GraceMusic");
 984                 $$->set_mus_property ("element", $2->self_scm ());
 985                 scm_gc_unprotect_object ($2->self_scm ());
 986 #endif
 987         }
 988         | CONTEXT string '=' string optional_context_mod Music {
 989                 $$ = context_spec_music ($2, $4, $6, $5);
 990
 991         }
 992         | CONTEXT STRING optional_context_mod Music {
 993                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 994         }
 995         | NEWCONTEXT string optional_context_mod Music {
 996                 $$ = context_spec_music ($2, get_next_unique_context (),
 997                                          $4, $3);
 998         }
 999
1000         | TIMES {
1001                 THIS->push_spot ();
1002         }
1003         /* CONTINUED */
1004                 fraction Music
1005
1006         {
1007                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
1008                 Music *mp = $4;
1009
1010                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1011                 $$->set_spot (THIS->pop_spot ());
1012
1013                 $$->set_mus_property ("element", mp->self_scm ());
1014                 scm_gc_unprotect_object (mp->self_scm ());
1015                 $$->set_mus_property ("numerator", gh_int2scm (n));
1016                 $$->set_mus_property ("denominator", gh_int2scm (d));
1017                 $$->compress (Moment (Rational (n,d)));
1018
1019         }
1020         | Repeated_music                { $$ = $1; }
1021         | Simultaneous_music            { $$ = $1; }
1022         | Sequential_music              { $$ = $1; }
1023         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1024                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1025                 Music *p = $4;
1026                 Pitch from = *unsmob_pitch ($2);
1027                 Pitch to = *unsmob_pitch ($3);
1028
1029                 p->transpose (interval (from, to));
1030                 $$->set_mus_property ("element", p->self_scm ());
1031                 scm_gc_unprotect_object (p->self_scm ());
1032         }
1033         | APPLY embedded_scm Music  {
1034                 if (!ly_input_procedure_p ($2))
1035                         {
1036                         THIS->parser_error (_ ("\\apply takes function argument"));
1037                         $$ = $3;
1038                         }
1039                 else
1040                         {
1041                         SCM ret = gh_call1 ($2, $3->self_scm ());
1042                         Music *m = unsmob_music (ret);
1043                         if (!m) {
1044                                 THIS->parser_error ("\\apply must return a Music");
1045                                 m = MY_MAKE_MUSIC("Music");
1046                                 }
1047                         $$ = m;
1048                         }
1049         }
1050         | NOTES
1051                 { THIS->lexer_->push_note_state (); }
1052         Music
1053                 { $$ = $3;
1054                   THIS->lexer_->pop_state ();
1055                 }
1056         | FIGURES
1057                 { THIS->lexer_->push_figuredbass_state (); }
1058         Music
1059                 {
1060                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1061                   chm->set_mus_property ("element", $3->self_scm ());
1062                   $$ = chm;
1063                   scm_gc_unprotect_object ($3->self_scm());
1064
1065                   THIS->lexer_->pop_state ();
1066         }
1067         | CHORDS
1068                 { THIS->lexer_->push_chord_state (); }
1069         Music
1070                 {
1071                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1072                   chm->set_mus_property ("element", $3->self_scm ());
1073                   scm_gc_unprotect_object ($3->self_scm());
1074                   $$ = chm;
1075
1076                   THIS->lexer_->pop_state ();
1077         }
1078         | LYRICS
1079                 { THIS->lexer_->push_lyric_state (); }
1080         Music
1081                 {
1082                   $$ = $3;
1083                   THIS->lexer_->pop_state ();
1084         }
1085         | relative_music        { $$ = $1; }
1086         | re_rhythmed_music     { $$ = $1; }
1087         | TAG embedded_scm Music {
1088                 tag_music ($3, $2, THIS->here_input ());
1089                 $$ = $3;
1090         }
1091         ;
1092
1093 relative_music:
1094         RELATIVE absolute_pitch Music {
1095                 Music * p = $3;
1096                 Pitch pit = *unsmob_pitch ($2);
1097                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1098
1099                 $$->set_mus_property ("element", p->self_scm ());
1100                 scm_gc_unprotect_object (p->self_scm ());
1101
1102
1103                 Pitch retpitch = p->to_relative_octave (pit);
1104                 if (lily_1_8_relative)
1105                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1106         }
1107         ;
1108
1109 re_rhythmed_music:
1110         ADDLYRICS Music Music {
1111         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1112           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1113           scm_gc_unprotect_object ($3->self_scm ());
1114           scm_gc_unprotect_object ($2->self_scm ());
1115           $$ = l;
1116         }
1117         | NEWADDLYRICS string Music {
1118           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1119           l->set_mus_property ("element", $3->self_scm ());
1120           scm_gc_unprotect_object ($3->self_scm ());
1121           $$ = l;
1122           l->set_mus_property ("associated-context", $2);
1123         }
1124         ;
1125
1126 context_change:
1127         CHANGE STRING '=' STRING  {
1128                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1129                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1130                 t-> set_mus_property ("change-to-id", $4);
1131
1132                 $$ = t;
1133                 $$->set_spot (THIS->here_input ());
1134         }
1135         ;
1136
1137 property_operation:
1138         STRING '='  scalar {
1139                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1140                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1141         }
1142         | STRING UNSET {
1143                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1144                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1145         }
1146         | STRING SET embedded_scm '=' embedded_scm {
1147                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1148                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1149         }
1150         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1151                 $$ = scm_list_n (ly_symbol2scm ("push"),
1152                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1153         }
1154         | STRING REVERT embedded_scm {
1155                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1156                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1157         }
1158         ;
1159
1160 translator_mod:
1161         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1162         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1163         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1164
1165         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1166         | DENIES { $$ = ly_symbol2scm ("denies"); }
1167
1168         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1169         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1170         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1171         | NAME { $$ = ly_symbol2scm ("context-name"); }
1172         ;
1173
1174 context_mod:
1175         property_operation { $$ = $1; }
1176         | translator_mod STRING {
1177                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1178         }
1179         ;
1180
1181 music_property_def:
1182         PROPERTY STRING '.' property_operation {
1183                 Music * t = property_op_to_music ($4);
1184                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1185
1186                 csm->set_mus_property ("element", t->self_scm ());
1187                 scm_gc_unprotect_object (t->self_scm ());
1188
1189                 $$ = csm;
1190                 $$->set_spot (THIS->here_input ());
1191
1192                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1193         }
1194         | ONCE music_property_def {
1195                 $$ = $2;
1196                 SCM e = $2->get_mus_property ("element");
1197                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1198         }
1199         ;
1200
1201
1202 scalar:
1203         string          { $$ = $1; }
1204         | bare_int      { $$ = gh_int2scm ($1); }
1205         | embedded_scm  { $$ = $1; }
1206         | full_markup {  $$ = $1; }
1207         | DIGIT { $$ = gh_int2scm ($1); }
1208         ;
1209
1210 /*
1211 This is a trick:
1212
1213 Adding pre_events to the simple_element
1214 makes the choice between
1215
1216   string:  STRING
1217
1218 and
1219
1220   simple_element: STRING
1221
1222 a single shift/reduction conflict.
1223
1224 nevertheless, this is not very clean, and we should find a different
1225 solution.
1226
1227 */
1228 pre_events: {
1229                 THIS->push_spot ();
1230         }
1231         ;
1232
1233 event_chord:
1234         pre_events simple_element post_events   {
1235                 SCM elts = $2-> get_mus_property ("elements");
1236
1237                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1238
1239                 $2->set_mus_property ("elements", elts);
1240                 $$ = $2;
1241         }
1242         | command_element
1243         | note_chord_element
1244         ;
1245
1246
1247 note_chord_element:
1248         chord_body optional_notemode_duration post_events
1249         {
1250                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1251                 SCM es = $1->get_mus_property ("elements");
1252                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1253
1254                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1255                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1256                 es = gh_append2 (es, postevs);
1257
1258                 $1-> set_mus_property ("elements", es);
1259                 $$ = $1;
1260         }
1261         ;
1262
1263 chord_open: '<'
1264         ;
1265
1266 chord_close: '>'
1267         ;
1268
1269 simul_open: LESSLESS
1270         ;
1271
1272 simul_close: MOREMORE
1273         ;
1274
1275 chord_body:
1276         chord_open chord_body_elements chord_close
1277         {
1278                 $$ = MY_MAKE_MUSIC("EventChord");
1279                 $$->set_mus_property ("elements",
1280                         scm_reverse_x ($2, SCM_EOL));
1281         }
1282         ;
1283
1284 chord_body_elements:
1285         /* empty */             { $$ = SCM_EOL; }
1286         | chord_body_elements chord_body_element {
1287                 $$ = gh_cons ($2->self_scm(), $1);
1288                 scm_gc_unprotect_object ($2->self_scm());
1289         }
1290         ;
1291
1292 chord_body_element:
1293         pitch exclamations questions post_events
1294         {
1295                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1296                 n->set_mus_property ("pitch", $1);
1297                 if ($3 % 2)
1298                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1299                 if ($2 % 2 || $3 % 2)
1300                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1301
1302                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1303                 n->set_mus_property ("articulations", arts);
1304
1305                 $$ = n;
1306         }
1307         ;
1308
1309 command_element:
1310         command_req {
1311                 $$ = MY_MAKE_MUSIC("EventChord");
1312                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1313                 scm_gc_unprotect_object ($1->self_scm());
1314
1315                 $$-> set_spot (THIS->here_input ());
1316                 $1-> set_spot (THIS->here_input ());
1317         }
1318         | OCTAVE { THIS->push_spot (); }
1319           pitch {
1320                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1321                 $$ = l;
1322                 $$->set_spot (THIS->pop_spot ());
1323                 $$->set_mus_property ("pitch", $3);
1324         }
1325         | E_LEFTSQUARE {
1326                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1327                 l->set_mus_property ("span-direction", gh_int2scm (START));
1328                 l->set_spot (THIS->here_input ());
1329
1330                 $$ = MY_MAKE_MUSIC("EventChord");
1331                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1332                 scm_gc_unprotect_object (l->self_scm());
1333                 $$->set_spot (THIS->here_input ());
1334         }
1335         | E_RIGHTSQUARE {
1336                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1337                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1338                 l->set_spot (THIS->here_input ());
1339
1340                 $$ = MY_MAKE_MUSIC("EventChord");
1341                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1342                 $$->set_spot (THIS->here_input ());
1343                 scm_gc_unprotect_object (l->self_scm());
1344         }
1345         | E_BACKSLASH {
1346                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1347                 $$->set_spot (THIS->here_input ());
1348         }
1349         | '|'      {
1350
1351                 $$ = MY_MAKE_MUSIC("BarCheck");
1352                 $$->set_spot (THIS->here_input ());
1353         }
1354         | BAR STRING                    {
1355                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1356
1357                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1358                 csm->set_mus_property ("element", t->self_scm ());
1359                 scm_gc_unprotect_object (t->self_scm ());
1360
1361                 $$ = csm;
1362                 $$->set_spot (THIS->here_input ());
1363
1364                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1365         }
1366         | PARTIAL duration_length       {
1367                 Moment m = - unsmob_duration ($2)->get_length ();
1368                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1369
1370                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1371                 sp->set_mus_property ("element", p->self_scm ());
1372                 scm_gc_unprotect_object (p->self_scm ());
1373
1374                 $$ =sp ;
1375                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1376         }
1377         | CLEF STRING  {
1378                 static SCM proc ;
1379                 if (!proc)
1380                         proc = scm_c_eval_string ("make-clef-set");
1381
1382                 SCM result = scm_call_1 (proc, $2);
1383                 scm_gc_protect_object (result);
1384                 $$ = unsmob_music (result);
1385         }
1386         | TIME_T fraction  {
1387                 static SCM proc;
1388                 if (!proc)
1389                         proc = scm_c_eval_string ("make-time-signature-set");
1390
1391                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1392                 scm_gc_protect_object (result);
1393                 $$ = unsmob_music (result);
1394         }
1395         | MARK scalar {
1396                 static SCM proc;
1397                 if (!proc)
1398                         proc = scm_c_eval_string ("make-mark-set");
1399
1400                 SCM result = scm_call_1 (proc, $2);
1401                 scm_gc_protect_object (result);
1402                 $$ = unsmob_music (result);
1403         }
1404         ;
1405
1406 command_req:
1407         shorthand_command_req   { $$ = $1; }
1408         | verbose_command_req   { $$ = $1; }
1409         ;
1410
1411 shorthand_command_req:
1412         BREATHE {
1413                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1414         }
1415         | E_TILDE {
1416                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1417         }
1418         ;
1419
1420 verbose_command_req:
1421         MARK DEFAULT  {
1422                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1423                 $$ = m;
1424         }
1425
1426         | SKIP duration_length {
1427                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1428                 skip->set_mus_property ("duration", $2);
1429
1430                 $$ = skip;
1431         }
1432         | tempo_event {
1433                 $$ = $1;
1434         }
1435         | KEY DEFAULT {
1436                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1437                 $$ = key;
1438         }
1439         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1440
1441                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1442                 if (scm_ilength ($3) > 0)
1443                 {
1444                         key->set_mus_property ("pitch-alist", $3);
1445                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1446                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1447                 } else {
1448                         THIS->parser_error (_("Second argument must be pitch list."));
1449                 }
1450
1451                 $$ = key;
1452         }
1453         ;
1454
1455 post_events:
1456         /* empty */ {
1457                 $$ = SCM_EOL;
1458         }
1459         | post_events post_event {
1460                 $2->set_spot (THIS->here_input ());
1461                 $$ = gh_cons ($2->self_scm(), $$);
1462                 scm_gc_unprotect_object ($2->self_scm());
1463         }
1464         | post_events tagged_post_event {
1465                 $2 -> set_spot (THIS->here_input ());
1466                 $$ = scm_cons ($2->self_scm(), $$);
1467                 scm_gc_unprotect_object ($2->self_scm());
1468         }
1469         ;
1470
1471
1472 tagged_post_event:
1473         '-' TAG embedded_scm post_event {
1474                 tag_music ($4, $3, THIS->here_input ());
1475                 $$ = $4;
1476         }
1477         ;
1478
1479 post_event:
1480         direction_less_event {
1481                 $$ = $1;
1482         }
1483         | HYPHEN {
1484                 if (!THIS->lexer_->lyric_state_b ())
1485                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1486                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1487         }
1488         | EXTENDER {
1489                 if (!THIS->lexer_->lyric_state_b ())
1490                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1491                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1492         }
1493         | script_dir direction_reqd_event {
1494                 if ($1)
1495                         $2->set_mus_property ("direction", gh_int2scm ($1));
1496                 $$ = $2;
1497         }
1498         | script_dir direction_less_event {
1499                 if ($1)
1500                         $2->set_mus_property ("direction", gh_int2scm ($1));
1501                 $$ = $2;
1502         }
1503         | string_number_event
1504         ;
1505
1506 string_number_event:
1507         E_UNSIGNED {
1508                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1509                 s->set_mus_property ("string-number",  gh_int2scm($1));
1510                 s->set_spot (THIS->here_input ());
1511                 $$ = s;
1512         }
1513         ;
1514
1515
1516 direction_less_event:
1517         '['  {
1518
1519
1520 /*
1521
1522 TODO: should take all these defs out of the parser, adn make use
1523 configurable, i.e.
1524
1525
1526 (set-articulation '~ "trill")
1527
1528 */
1529                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1530                 m->set_spot (THIS->here_input());
1531                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1532                 $$ = m;
1533         }
1534         | ']'  {
1535                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1536                 m->set_spot (THIS->here_input());
1537                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1538                 $$ = m;
1539         }
1540         | '~' {
1541                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1542                 m->set_spot (THIS->here_input());
1543                 $$ = m;
1544         }
1545         | close_event {
1546                 $$ = $1;
1547                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1548                         gh_int2scm (START));
1549         }
1550         | open_event {
1551                 $$ = $1;
1552                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1553                         gh_int2scm (STOP));
1554         }
1555         | EVENT_IDENTIFIER      {
1556                 $$ = unsmob_music ($1);
1557         }
1558         | tremolo_type  {
1559                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1560                a->set_spot (THIS->here_input ());
1561                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1562                $$ = a;
1563         }
1564         ;
1565
1566 direction_reqd_event:
1567         gen_text_def {
1568                 $$ = $1;
1569         }
1570         | script_abbreviation {
1571                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1572                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1573                 if (gh_string_p (s))
1574                         a->set_mus_property ("articulation-type", s);
1575                 else THIS->parser_error (_ ("Expecting string as script definition"));
1576                 $$ = a;
1577         }
1578         ;
1579
1580 oct_check:
1581         /**/ { $$ = SCM_EOL; }
1582         | '='  { $$ = gh_int2scm (0); }
1583         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1584         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1585         ;
1586
1587 sup_quotes:
1588         '\'' {
1589                 $$ = 1;
1590         }
1591         | sup_quotes '\'' {
1592                 $$ ++;
1593         }
1594         ;
1595
1596 sub_quotes:
1597         ',' {
1598                 $$ = 1;
1599         }
1600         | sub_quotes ',' {
1601                 $$ ++ ;
1602         }
1603         ;
1604
1605 steno_pitch:
1606         NOTENAME_PITCH  {
1607                 $$ = $1;
1608         }
1609         | NOTENAME_PITCH sup_quotes     {
1610                 Pitch p = *unsmob_pitch ($1);
1611                 p = p.transposed (Pitch ($2,0,0));
1612                 $$ = p.smobbed_copy ();
1613         }
1614         | NOTENAME_PITCH sub_quotes      {
1615                 Pitch p =* unsmob_pitch ($1);
1616                 p = p.transposed (Pitch (-$2,0,0));
1617                 $$ = p.smobbed_copy ();
1618         }
1619         ;
1620
1621 /*
1622 ugh. duplication
1623 */
1624
1625 steno_tonic_pitch:
1626         TONICNAME_PITCH {
1627                 $$ = $1;
1628         }
1629         | TONICNAME_PITCH sup_quotes    {
1630                 Pitch p = *unsmob_pitch ($1);
1631                 p = p.transposed (Pitch ($2,0,0));
1632                 $$ = p.smobbed_copy ();
1633         }
1634         | TONICNAME_PITCH sub_quotes     {
1635                 Pitch p =* unsmob_pitch ($1);
1636
1637                 p = p.transposed (Pitch (-$2,0,0));
1638                 $$ = p.smobbed_copy ();
1639         }
1640         ;
1641
1642 pitch:
1643         steno_pitch {
1644                 $$ = $1;
1645         }
1646         ;
1647
1648 pitch_also_in_chords:
1649         pitch
1650         | steno_tonic_pitch
1651         ;
1652
1653 close_event:
1654         '('     {
1655                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1656                 $$ = s;
1657                 s->set_spot (THIS->here_input());
1658         }
1659         | E_OPEN        {
1660                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1661                 $$ = s;
1662                 s->set_spot (THIS->here_input());
1663         }
1664         | E_SMALLER {
1665                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1666                 $$ = s;
1667                 s->set_spot (THIS->here_input());
1668         }
1669         | E_BIGGER {
1670                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1671                 $$ = s;
1672                 s->set_spot (THIS->here_input());
1673         }
1674         ;
1675
1676
1677 open_event:
1678         E_EXCLAMATION   {
1679                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1680                 s->set_spot (THIS->here_input());
1681
1682                 $$ = s;
1683         }
1684         | ')'   {
1685                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1686                 $$ = s;
1687                 s->set_spot (THIS->here_input());
1688
1689         }
1690         | E_CLOSE       {
1691                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1692                 $$ = s;
1693                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1694                 s->set_spot (THIS->here_input());
1695         }
1696         ;
1697
1698 gen_text_def:
1699         full_markup {
1700                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1701                 t->set_mus_property ("text", $1);
1702                 t->set_spot (THIS->here_input ());
1703                 $$ = t;
1704         }
1705         | string {
1706                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1707                 t->set_mus_property ("text", make_simple_markup ($1));
1708                 t->set_spot (THIS->here_input ());
1709                 $$ = t;
1710
1711         }
1712         | DIGIT {
1713                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1714                 t->set_mus_property ("digit",  gh_int2scm ($1));
1715                 t->set_spot (THIS->here_input ());
1716                 $$ = t;
1717         }
1718         ;
1719
1720 script_abbreviation:
1721         '^'             {
1722                 $$ = scm_makfrom0str ("Hat");
1723         }
1724         | '+'           {
1725                 $$ = scm_makfrom0str ("Plus");
1726         }
1727         | '-'           {
1728                 $$ = scm_makfrom0str ("Dash");
1729         }
1730         | '|'           {
1731                 $$ = scm_makfrom0str ("Bar");
1732         }
1733         | '>'           {
1734                 $$ = scm_makfrom0str ("Larger");
1735         }
1736         | '.'           {
1737                 $$ = scm_makfrom0str ("Dot");
1738         }
1739         | '_' {
1740                 $$ = scm_makfrom0str ("Underscore");
1741         }
1742         ;
1743
1744 script_dir:
1745         '_'     { $$ = DOWN; }
1746         | '^'   { $$ = UP; }
1747         | '-'   { $$ = CENTER; }
1748         ;
1749
1750
1751 absolute_pitch:
1752         steno_pitch     {
1753                 $$ = $1;
1754         }
1755         ;
1756
1757 duration_length:
1758         multiplied_duration {
1759                 $$ = $1;
1760         }
1761         ;
1762
1763 optional_notemode_duration:
1764         {
1765                 Duration dd = THIS->default_duration_;
1766                 $$ = dd.smobbed_copy ();
1767
1768                 THIS->beam_check ($$);
1769         }
1770         | multiplied_duration   {
1771                 $$ = $1;
1772                 THIS->default_duration_ = *unsmob_duration ($$);
1773
1774                 THIS->beam_check ($$);
1775         }
1776         ;
1777
1778 steno_duration:
1779         bare_unsigned dots              {
1780                 int l = 0;
1781                 if (!is_duration_b ($1))
1782                         THIS->parser_error (_f ("not a duration: %d", $1));
1783                 else
1784                         l =  intlog2 ($1);
1785
1786                 $$ = Duration (l, $2).smobbed_copy ();
1787         }
1788         | DURATION_IDENTIFIER dots      {
1789                 Duration *d =unsmob_duration ($1);
1790                 Duration k (d->duration_log (),d->dot_count () + $2);
1791
1792                 *d = k;
1793                 $$ = $1;
1794         }
1795         ;
1796
1797
1798
1799
1800 multiplied_duration:
1801         steno_duration {
1802                 $$ = $1;
1803         }
1804         | multiplied_duration '*' bare_unsigned {
1805                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1806         }
1807         | multiplied_duration '*' FRACTION {
1808                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1809
1810                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1811         }
1812         ;
1813
1814 fraction:
1815         FRACTION { $$ = $1; }
1816         | UNSIGNED '/' UNSIGNED {
1817                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1818         }
1819         ;
1820
1821 dots:
1822         /* empty */     {
1823                 $$ = 0;
1824         }
1825         | dots '.' {
1826                 $$ ++;
1827         }
1828         ;
1829
1830
1831 tremolo_type:
1832         ':'     {
1833                 $$ =0;
1834         }
1835         | ':' bare_unsigned {
1836                 if (!is_duration_b ($2))
1837                         THIS->parser_error (_f ("not a duration: %d", $2));
1838                 $$ = $2;
1839         }
1840         ;
1841
1842
1843
1844 /*****************************************************************
1845                 BASS FIGURES
1846 *****************************************************************/
1847 bass_number:
1848         DIGIT   {
1849                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1850         }
1851         | UNSIGNED {
1852                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1853         }
1854         | STRING { $$ =  $1; }
1855         ;
1856
1857 bass_mod:
1858         '-'     { $$ = -2; }
1859         | '+'   { $$ = 2; }
1860         | '!'   { $$ = 0; }
1861         ;
1862
1863 bass_figure:
1864         FIGURE_SPACE {
1865                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1866                 $$ = bfr->self_scm();
1867                 scm_gc_unprotect_object ($$);
1868         }
1869         | bass_number  {
1870                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1871                 $$ = bfr->self_scm();
1872
1873                 bfr->set_mus_property ("figure", $1);
1874
1875                 scm_gc_unprotect_object ($$);
1876         }
1877         | bass_figure bass_mod {
1878                 Music *m = unsmob_music ($1);
1879                 if ($2) {
1880                         SCM salter =m->get_mus_property ("alteration");
1881                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1882                         m->set_mus_property ("alteration",
1883                                 gh_int2scm (alter + $2));
1884                 } else {
1885                         m->set_mus_property ("alteration", gh_int2scm (0));
1886                 }
1887         }
1888         ;
1889
1890 br_bass_figure:
1891         '[' bass_figure {
1892                 $$ = $2;
1893                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1894         }
1895         | bass_figure   {
1896                 $$ = $1;
1897         }
1898         | br_bass_figure ']' {
1899                 $$ = $1;
1900                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1901         }
1902         ;
1903
1904 figure_list:
1905         /**/            {
1906                 $$ = SCM_EOL;
1907         }
1908         | figure_list br_bass_figure {
1909                 $$ = scm_cons ($2, $1);
1910         }
1911         ;
1912
1913 figure_spec:
1914         FIGURE_OPEN figure_list FIGURE_CLOSE {
1915                 Music * m = MY_MAKE_MUSIC("EventChord");
1916                 $2 = scm_reverse_x ($2, SCM_EOL);
1917                 m->set_mus_property ("elements",  $2);
1918                 $$ = m->self_scm ();
1919         }
1920         ;
1921
1922
1923 optional_rest:
1924         /**/   { $$ = 0; }
1925         | REST { $$ = 1; }
1926         ;
1927
1928 simple_element:
1929         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1930
1931                 Input i = THIS->pop_spot ();
1932                 if (!THIS->lexer_->note_state_b ())
1933                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1934
1935                 Music *n = 0;
1936                 if ($6)
1937                         n =  MY_MAKE_MUSIC("RestEvent");
1938                 else
1939                         n =  MY_MAKE_MUSIC("NoteEvent");
1940
1941                 n->set_mus_property ("pitch", $1);
1942                 n->set_mus_property ("duration", $5);
1943
1944                 if (gh_number_p ($4))
1945                 {
1946                         int q = gh_scm2int ($4);
1947                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1948                 }
1949
1950                 if ($3 % 2)
1951                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1952                 if ($2 % 2 || $3 % 2)
1953                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1954
1955                 Music *v = MY_MAKE_MUSIC("EventChord");
1956                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1957                 scm_gc_unprotect_object (n->self_scm());
1958
1959                 v->set_spot (i);
1960                 n->set_spot (i);
1961                 $$ = v;
1962         }
1963         | figure_spec optional_notemode_duration {
1964                 Music * m = unsmob_music ($1);
1965                 Input i = THIS->pop_spot ();
1966                 m->set_spot (i);
1967                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1968                 {
1969                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1970                 }
1971                 $$ = m;
1972         }
1973         | RESTNAME optional_notemode_duration           {
1974
1975                 Input i = THIS->pop_spot ();
1976                 Music * ev = 0;
1977                 if (ly_scm2string ($1) =="s") {
1978                         /* Space */
1979                         ev = MY_MAKE_MUSIC("SkipEvent");
1980                   }
1981                 else {
1982                         ev = MY_MAKE_MUSIC("RestEvent");
1983
1984                     }
1985                 ev->set_mus_property ("duration" ,$2);
1986                 ev->set_spot (i);
1987                 Music * velt = MY_MAKE_MUSIC("EventChord");
1988                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1989                 velt->set_spot (i);
1990
1991                 scm_gc_unprotect_object (ev->self_scm());
1992
1993                 $$ = velt;
1994         }
1995         | MULTI_MEASURE_REST optional_notemode_duration         {
1996                 THIS->pop_spot ();
1997
1998                 static SCM proc ;
1999                 if (!proc)
2000                         proc = scm_c_eval_string ("make-multi-measure-rest");
2001
2002                 SCM mus = scm_call_2 (proc, $2,
2003                         make_input (THIS->here_input()));
2004                 scm_gc_protect_object (mus);
2005                 $$ = unsmob_music (mus);
2006         }
2007
2008         | lyric_element optional_notemode_duration      {
2009                 Input i = THIS->pop_spot ();
2010                 if (!THIS->lexer_->lyric_state_b ())
2011                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2012
2013                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2014                 lreq->set_mus_property ("text", $1);
2015                 lreq->set_mus_property ("duration",$2);
2016                 lreq->set_spot (i);
2017                 Music * velt = MY_MAKE_MUSIC("EventChord");
2018                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2019
2020                 $$= velt;
2021         }
2022         | new_chord {
2023                 THIS->pop_spot ();
2024
2025                 if (!THIS->lexer_->chord_state_b ())
2026                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2027                 $$ = unsmob_music ($1);
2028         }
2029         ;
2030
2031 lyric_element:
2032         full_markup { $$ = $1; }
2033         | STRING {  $$ = $1 ; }
2034         ;
2035
2036 new_chord:
2037         steno_tonic_pitch optional_notemode_duration   {
2038                 $$ = make_chord ($1, $2, SCM_EOL);
2039         }
2040         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2041                 SCM its = scm_reverse_x ($4, SCM_EOL);
2042                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2043         }
2044         ;
2045
2046 chord_items:
2047         /**/ {
2048                 $$ = SCM_EOL;
2049         }
2050         | chord_items chord_item {
2051                 $$ = gh_cons ($2, $$);
2052         }
2053         ;
2054
2055 chord_separator:
2056         CHORD_COLON {
2057                 $$ = ly_symbol2scm ("chord-colon");
2058         }
2059         | CHORD_CARET {
2060                 $$ = ly_symbol2scm ("chord-caret");
2061         }
2062         | CHORD_SLASH steno_tonic_pitch {
2063                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2064         }
2065         | CHORD_BASS steno_tonic_pitch {
2066                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2067         }
2068         ;
2069
2070 chord_item:
2071         chord_separator {
2072                 $$ = $1;
2073         }
2074         | step_numbers {
2075                 $$ = scm_reverse_x ($1, SCM_EOL);
2076         }
2077         | CHORD_MODIFIER  {
2078                 $$ = $1;
2079         }
2080         ;
2081
2082 step_numbers:
2083         step_number { $$ = gh_cons ($1, SCM_EOL); }
2084         | step_numbers '.' step_number {
2085                 $$ = gh_cons ($3, $$);
2086         }
2087         ;
2088
2089 step_number:
2090         bare_unsigned {
2091                 $$ = make_chord_step ($1, 0);
2092         }
2093         | bare_unsigned '+' {
2094                 $$ = make_chord_step ($1, SHARP);
2095         }
2096         | bare_unsigned CHORD_MINUS {
2097                 $$ = make_chord_step ($1, FLAT);
2098         }
2099         ;
2100
2101 /*
2102         UTILITIES
2103
2104 TODO: should deprecate in favor of Scheme?
2105
2106  */
2107 number_expression:
2108         number_expression '+' number_term {
2109                 $$ = scm_sum ($1, $3);
2110         }
2111         | number_expression '-' number_term {
2112                 $$ = scm_difference ($1, $3);
2113         }
2114         | number_term
2115         ;
2116
2117 number_term:
2118         number_factor {
2119                 $$ = $1;
2120         }
2121         | number_factor '*' number_factor {
2122                 $$ = scm_product ($1, $3);
2123         }
2124         | number_factor '/' number_factor {
2125                 $$ = scm_divide ($1, $3);
2126         }
2127         ;
2128
2129 number_factor:
2130         '-'  number_factor { /* %prec UNARY_MINUS */
2131                 $$ = scm_difference ($2, SCM_UNDEFINED);
2132         }
2133         | bare_number
2134         ;
2135
2136
2137 bare_number:
2138         UNSIGNED        {
2139                 $$ = gh_int2scm ($1);
2140         }
2141         | REAL          {
2142                 $$ = $1;
2143         }
2144         | NUMBER_IDENTIFIER             {
2145                 $$ = $1;
2146         }
2147         | REAL NUMBER_IDENTIFIER        {
2148                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2149         }
2150         | UNSIGNED NUMBER_IDENTIFIER    {
2151                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2152         }
2153         ;
2154
2155
2156 bare_unsigned:
2157         UNSIGNED {
2158                         $$ = $1;
2159         }
2160         | DIGIT {
2161                 $$ = $1;
2162         }
2163         ;
2164
2165 bare_int:
2166         bare_number {
2167                 if (scm_integer_p ($1) == SCM_BOOL_T)
2168                 {
2169                         int k = gh_scm2int ($1);
2170                         $$ = k;
2171                 } else
2172                 {
2173                         THIS->parser_error (_ ("need integer number arg"));
2174                         $$ = 0;
2175                 }
2176         }
2177         | '-' bare_int {
2178                 $$ = -$2;
2179         }
2180         ;
2181
2182
2183 string:
2184         STRING          {
2185                 $$ = $1;
2186         }
2187         | STRING_IDENTIFIER     {
2188                 $$ = $1;
2189         }
2190         | string '+' string {
2191                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2192         }
2193         ;
2194
2195
2196 exclamations:
2197                 { $$ = 0; }
2198         | exclamations '!'      { $$ ++; }
2199         ;
2200
2201 questions:
2202                 { $$ = 0; }
2203         | questions '?' { $$ ++; }
2204         ;
2205
2206
2207
2208 full_markup:
2209         MARKUP_IDENTIFIER {
2210                 $$ = $1;
2211         }
2212         | MARKUP
2213                 { THIS->lexer_->push_markup_state (); }
2214         markup
2215                 { $$ = $3;
2216                   THIS->lexer_->pop_state ();
2217                 }
2218         ;
2219
2220
2221 /*
2222 This should be done more dynamically if possible.
2223 */
2224 markup:
2225         STRING {
2226                 $$ = make_simple_markup ($1);
2227         }
2228         | MARKUP_HEAD_EMPTY {
2229                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2230         }
2231         | MARKUP_HEAD_MARKUP0 markup {
2232                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2233         }
2234         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2235                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2236         }
2237         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2238                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2239         }
2240         | markup_line {
2241                 $$ = $1;
2242         }
2243         | MARKUP_HEAD_LIST0 markup_list {
2244                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2245         }
2246         | MARKUP_HEAD_SCM0 embedded_scm {
2247                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2248         }
2249         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2250                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2251         }
2252         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2253                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2254         }
2255         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2256                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2257         }
2258         | MARKUP_IDENTIFIER {
2259                 $$ = $1;
2260         }
2261
2262         ;
2263
2264 markup_list:
2265         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2266         ;
2267
2268 markup_line:
2269         '{' markup_list_body '}' {
2270                 static SCM line ;
2271                 if (!line)
2272                         line = scm_c_eval_string ("line-markup");
2273
2274                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2275         }
2276         ;
2277
2278 markup_list_body:
2279         /**/ {  $$ = SCM_EOL; }
2280         | markup_list_body markup {
2281                 $$ = gh_cons ($2, $1) ;
2282         }
2283         ;
2284
2285
2286 %%
2287
2288 void
2289 My_lily_parser::set_yydebug (bool )
2290 {
2291 #if 0
2292         yydebug = 1;
2293 #endif
2294 }
2295
2296 extern My_lily_parser * current_parser;
2297
2298 void
2299 My_lily_parser::do_yyparse ()
2300 {
2301         current_parser = this;;
2302         yyparse ((void*)this);
2303 }
2304
2305
2306 /*
2307 Should make this optional?    It will also complain when you do
2308
2309         [s4]
2310
2311 which is entirely legitimate.
2312
2313 Or we can scrap it. Barchecks should detect wrong durations, and
2314 skipTypesetting speeds it up a lot.
2315 */
2316
2317 void
2318 My_lily_parser::beam_check (SCM dur)
2319 {
2320   Duration *d = unsmob_duration (dur);
2321   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2322     {
2323       Music * m = unsmob_music (last_beam_start_);
2324       m->origin ()->warning (_("Suspect duration found following this beam"));
2325     }
2326   last_beam_start_ = SCM_EOL;
2327 }
2328
2329
2330
2331
2332 /*
2333
2334 It is a little strange to have this function in this file, but
2335 otherwise, we have to import music classes into the lexer.
2336
2337 */
2338 int
2339 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2340 {
2341         if (gh_string_p (sid)) {
2342                 *destination = sid;
2343                 return STRING_IDENTIFIER;
2344         } else if (gh_number_p (sid)) {
2345                 *destination = sid;
2346                 return NUMBER_IDENTIFIER;
2347         } else if (unsmob_context_def (sid)) {
2348                 *destination = unsmob_context_def (sid)->clone_scm();
2349                 return TRANSLATOR_IDENTIFIER;
2350         } else if (unsmob_score (sid)) {
2351                 Score *sc =  new Score (*unsmob_score (sid));
2352                 *destination =sc->self_scm ();
2353                 return SCORE_IDENTIFIER;
2354         } else if (Music * mus =unsmob_music (sid)) {
2355                 *destination = unsmob_music (sid)->clone ()->self_scm();
2356                 unsmob_music (*destination)->
2357                         set_mus_property ("origin", make_input (last_input_));
2358                 return dynamic_cast<Event*> (mus)
2359                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2360         } else if (unsmob_duration (sid)) {
2361                 *destination = unsmob_duration (sid)->smobbed_copy();
2362                 return DURATION_IDENTIFIER;
2363         } else if (unsmob_music_output_def (sid)) {
2364                 Music_output_def *p = unsmob_music_output_def (sid);
2365                 p = p->clone ();
2366
2367                 *destination = p->self_scm();
2368                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2369         } else if (Text_item::markup_p (sid)) {
2370                 *destination = sid;
2371                 return MARKUP_IDENTIFIER;
2372         }
2373
2374         return -1;
2375 }
2376
2377 Music *
2378 property_op_to_music (SCM op)
2379 {
2380         Music * m = 0;
2381         SCM tag = gh_car (op);
2382         SCM symbol  = gh_cadr (op);
2383         SCM args = gh_cddr (op);
2384         SCM grob_val = SCM_UNDEFINED;
2385         SCM grob_sym = SCM_UNDEFINED;
2386         SCM val = SCM_UNDEFINED;
2387
2388         if (tag == ly_symbol2scm ("assign"))
2389                 {
2390                 m =  MY_MAKE_MUSIC("PropertySet");
2391                 val = gh_car (args);
2392                 }
2393         else if (tag == ly_symbol2scm ("unset"))
2394                 m =  MY_MAKE_MUSIC("PropertyUnset");
2395         else if (tag == ly_symbol2scm ("poppush")
2396                  || tag == ly_symbol2scm ("push"))
2397                 {
2398                 m  = MY_MAKE_MUSIC("OverrideProperty");
2399                 grob_sym = gh_car (args);
2400                 grob_val = gh_cadr (args);
2401                 }
2402         else if (tag == ly_symbol2scm ("pop")) {
2403                 m = MY_MAKE_MUSIC("RevertProperty");
2404                 grob_sym = gh_car (args);
2405                 }
2406
2407         m->set_mus_property ("symbol", symbol);
2408
2409         if (val != SCM_UNDEFINED)
2410                 m->set_mus_property ("value", val);
2411         if (grob_val != SCM_UNDEFINED)
2412                 m->set_mus_property ("grob-value", grob_val);
2413
2414         if (grob_sym != SCM_UNDEFINED)
2415                 {
2416                 bool itc = internal_type_checking_global_b;
2417                 /* UGH.
2418                 */
2419                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2420                 if (autobeam)
2421                         internal_type_checking_global_b = false;
2422                 m->set_mus_property ("grob-property", grob_sym);
2423                 if (autobeam)
2424                         internal_type_checking_global_b = itc;
2425                 }
2426
2427         if (op == ly_symbol2scm ("poppush"))
2428                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2429
2430
2431         return m;
2432 }
2433
2434 Music*
2435 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2436 {
2437         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2438
2439         csm->set_mus_property ("element", m->self_scm ());
2440         scm_gc_unprotect_object (m->self_scm ());
2441
2442         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2443         csm->set_mus_property ("property-operations", ops);
2444
2445         if (gh_string_p (id))
2446                 csm->set_mus_property ("context-id", id);
2447         return csm;
2448 }
2449
2450
2451 SCM
2452 get_next_unique_context ()
2453 {
2454         static int new_context_count;
2455
2456         char s[1024];
2457         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2458
2459         return scm_makfrom0str (s);
2460 }