lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input-smob.hh"
  79 #include "input.hh"
  80 #include "international.hh"
  81 #include "lily-guile.hh"
  82 #include "lily-lexer.hh"
  83 #include "lily-parser.hh"
  84 #include "lilypond-input-version.hh"
  85 #include "main.hh"
  86 #include "misc.hh"
  87 #include "music.hh"
  88 #include "music.hh"
  89 #include "output-def.hh"
  90 #include "paper-book.hh"
  91 #include "program-option.hh"
  92 #include "scm-hash.hh"
  93 #include "score.hh"
  94 #include "text-interface.hh"
  95 #include "warn.hh"
  96
  97 %}
  98
  99
 100 %union {
 101         Book *book;
 102         Output_def *outputdef;
 103         SCM scm;
 104         std::string *string;
 105         Music *music;
 106         Score *score;
 107         int i;
 108 }
 109
 110 %{
 111
 112 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 113
 114 Music *property_op_to_music (SCM op);
 115 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops, bool create_new);
 116 SCM get_next_unique_context_id ();
 117 SCM get_next_unique_lyrics_context_id ();
 118
 119 #undef _
 120 #if !HAVE_GETTEXT
 121 #define _(x) x
 122 #else
 123 #include <libintl.h>
 124 #define _(x) gettext (x)
 125 #endif
 126
 127
 128
 129 Music *make_lyric_combine_music (SCM name, Music *music);
 130 Music *make_music_relative (Pitch start, Music *music);
 131 Music *run_music_function (Lily_parser *, SCM expr);
 132 Music *set_property_music (SCM sym, SCM value);
 133 SCM get_first_context_id (SCM type, Music *m);
 134 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 135 SCM make_chord_step (int step, int alter);
 136 SCM make_simple_markup (SCM a);
 137 bool is_duration (int t);
 138 bool is_regular_identifier (SCM id);
 139 bool ly_input_procedure_p (SCM x);
 140 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 141 void set_music_properties (Music *p, SCM a);
 142
 143 %}
 144
 145 /* The third option is an alias that will be used to display the
 146    syntax error.  Bison CVS now correctly handles backslash escapes.
 147
 148    FIXME: Bison needs to translate some of these, eg, STRING.
 149
 150 */
 151
 152 /* Keyword tokens with plain escaped name.  */
 153 %token ACCEPTS "\\accepts"
 154 %token ADDLYRICS "\\addlyrics"
 155 %token ADDQUOTE "\\addquote"
 156 %token ALIAS "\\alias"
 157 %token ALTERNATIVE "\\alternative"
 158 %token BOOK "\book"
 159 %token CHANGE "\\change"
 160 %token CHORDMODE "\\chordmode"
 161 %token CHORDS "\\chords"
 162 %token CONSISTS "\\consists"
 163 %token CONTEXT "\\context"
 164 %token DEFAULT "\\default"
 165 %token DEFAULTCHILD "\\defaultchild"
 166 %token DENIES "\\denies"
 167 %token DESCRIPTION "\\description"
 168 %token DRUMMODE "\\drummode"
 169 %token DRUMS "\\drums"
 170 %token FIGUREMODE "\\figuremode"
 171 %token FIGURES "\\figures"
 172 %token GROBDESCRIPTIONS "\\grobdescriptions"
 173 %token HEADER "\\header"
 174 %token INVALID "\\invalid"
 175 %token KEY "\\key"
 176 %token LAYOUT "\\layout"
 177 %token LYRICMODE "\\lyricmode"
 178 %token LYRICS "\\lyrics"
 179 %token LYRICSTO "\\lyricsto"
 180 %token MARK "\\mark"
 181 %token MARKUP "\\markup"
 182 %token MIDI "\\midi"
 183 %token NAME "\\name"
 184 %token NOTEMODE "\\notemode"
 185 %token OBJECTID "\\objectid"
 186 %token OCTAVE "\\octave"
 187 %token ONCE "\\once"
 188 %token OVERRIDE "\\override"
 189 %token PAPER "\\paper"
 190 %token PARTIAL "\\partial"
 191 %token RELATIVE "\\relative"
 192 %token REMOVE "\\remove"
 193 %token REPEAT "\\repeat"
 194 %token REST "\\rest"
 195 %token REVERT "\\revert"
 196 %token SCORE "\\score"
 197 %token SEQUENTIAL "\\sequential"
 198 %token SET "\\set"
 199 %token SIMULTANEOUS "\\simultaneous"
 200 %token SKIP "\\skip"
 201 %token TEMPO "\\tempo"
 202 %token TIMES "\\times"
 203 %token TRANSPOSE "\\transpose"
 204 %token TRANSPOSITION "\\transposition"
 205 %token TYPE "\\type"
 206 %token UNSET "\\unset"
 207 %token WITH "\\with"
 208
 209 /* Keyword token exceptions.  */
 210 %token TIME_T "\\time"
 211 %token NEWCONTEXT "\\new"
 212
 213
 214 /* Other string tokens.  */
 215
 216 %token CHORD_BASS "/+"
 217 %token CHORD_CARET "^"
 218 %token CHORD_COLON ":"
 219 %token CHORD_MINUS "-"
 220 %token CHORD_SLASH "/"
 221 %token DOUBLE_ANGLE_CLOSE ">>"
 222 %token DOUBLE_ANGLE_OPEN "<<"
 223 %token E_BACKSLASH "\\"
 224 %token E_ANGLE_CLOSE "\\>"
 225 %token E_CHAR "\\C[haracter]"
 226 %token E_CLOSE "\\)"
 227 %token E_EXCLAMATION "\\!"
 228 %token E_BRACKET_OPEN "\\["
 229 %token E_OPEN "\\("
 230 %token E_BRACKET_CLOSE "\\]"
 231 %token E_ANGLE_OPEN "\\<"
 232 %token E_PLUS "\\+"
 233 %token E_TILDE "\\~"
 234 %token EXTENDER "__"
 235
 236 /*
 237 If we give names, Bison complains.
 238 */
 239 %token FIGURE_CLOSE /* "\\>" */
 240 %token FIGURE_OPEN /* "\\<" */
 241 %token FIGURE_SPACE "_"
 242 %token HYPHEN "--"
 243
 244 %token CHORDMODIFIERS
 245 %token LYRIC_MARKUP
 246 %token MULTI_MEASURE_REST
 247 %token SCM_T
 248
 249
 250 %token <i> DIGIT
 251 %token <i> E_UNSIGNED
 252 %token <i> UNSIGNED
 253
 254 %token <scm> BOOK_IDENTIFIER
 255 %token <scm> CHORDMODIFIER_PITCH
 256 %token <scm> CHORD_MODIFIER
 257 %token <scm> CONTEXT_DEF_IDENTIFIER
 258 %token <scm> DRUM_PITCH
 259 %token <scm> DURATION_IDENTIFIER
 260 %token <scm> EVENT_IDENTIFIER
 261 %token <scm> FRACTION
 262 %token <scm> LYRICS_STRING
 263 %token <scm> LYRIC_MARKUP_IDENTIFIER
 264 %token <scm> MARKUP_HEAD_EMPTY
 265 %token <scm> MARKUP_HEAD_LIST0
 266 %token <scm> MARKUP_HEAD_MARKUP0
 267 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 268 %token <scm> MARKUP_HEAD_SCM0
 269 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 270 %token <scm> MARKUP_HEAD_SCM0_SCM1
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 272 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 273 %token <scm> MARKUP_IDENTIFIER
 274 %token <scm> MUSIC_FUNCTION
 275 %token <scm> MUSIC_FUNCTION_MARKUP
 276 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MUSIC
 281 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 282 %token <scm> MUSIC_FUNCTION_SCM
 283 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 284 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 285 %token <scm> MUSIC_FUNCTION_SCM_SCM
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 287 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 288 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC
 289 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC
 290 %token <scm> MUSIC_IDENTIFIER
 291 %token <scm> NOTENAME_PITCH
 292 %token <scm> NUMBER_IDENTIFIER
 293 %token <scm> OUTPUT_DEF_IDENTIFIER
 294 %token <scm> REAL
 295 %token <scm> RESTNAME
 296 %token <scm> SCM_IDENTIFIER
 297 %token <scm> SCM_T
 298 %token <scm> SCORE_IDENTIFIER
 299 %token <scm> STRING
 300 %token <scm> STRING_IDENTIFIER
 301 %token <scm> TONICNAME_PITCH
 302
 303
 304 %type <book> book_block
 305 %type <book> book_body
 306
 307 %type <i> bare_unsigned
 308 %type <i> figured_bass_alteration
 309 %type <i> dots
 310 %type <i> exclamations
 311 %type <i> optional_rest
 312 %type <i> questions
 313 %type <i> script_dir
 314 %type <i> sub_quotes
 315 %type <i> sup_quotes
 316 %type <i> tremolo_type
 317
 318 %type <music> Composite_music
 319 %type <music> Grouped_music_list
 320 %type <music> Music
 321 %type <music> Prefix_composite_music
 322 %type <music> Repeated_music
 323 %type <music> Sequential_music
 324 %type <music> Simple_music
 325 %type <music> Simultaneous_music
 326 %type <music> chord_body
 327 %type <music> chord_body_element
 328 %type <music> command_element
 329 %type <music> command_event
 330 %type <music> context_change
 331 %type <music> direction_less_event
 332 %type <music> direction_reqd_event
 333 %type <music> event_chord
 334 %type <music> gen_text_def
 335 %type <music> music_property_def
 336 %type <music> note_chord_element
 337 %type <music> post_event
 338 %type <music> re_rhythmed_music
 339 %type <music> relative_music
 340 %type <music> simple_element
 341 %type <music> string_number_event
 342 %type <music> tempo_event
 343 %type <music> toplevel_music
 344
 345 %type <outputdef> output_def_body
 346 %type <outputdef> output_def_head
 347 %type <outputdef> output_def_head_with_mode_switch
 348 %type <outputdef> output_def
 349 %type <outputdef> paper_block
 350
 351 %type <scm> Alternative_music
 352 %type <scm> Generic_prefix_music_scm
 353 %type <scm> Music_list
 354 %type <scm> absolute_pitch
 355 %type <scm> assignment_id
 356 %type <scm> bare_number
 357 %type <scm> music_function_event
 358 %type <scm> music_function_chord_body
 359 %type <scm> music_function_musicless_prefix
 360 %type <scm> bass_figure
 361 %type <scm> figured_bass_modification
 362 %type <scm> br_bass_figure
 363 %type <scm> bass_number
 364 %type <scm> chord_body_elements
 365 %type <scm> chord_item
 366 %type <scm> chord_items
 367 %type <scm> chord_separator
 368 %type <scm> context_def_mod
 369 %type <scm> context_def_spec_block
 370 %type <scm> context_def_spec_body
 371 %type <scm> context_mod
 372 %type <scm> context_mod_list
 373 %type <scm> context_prop_spec
 374 %type <scm> direction_less_char
 375 %type <scm> duration_length
 376 %type <scm> embedded_scm
 377 %type <scm> figure_list
 378 %type <scm> figure_spec
 379 %type <scm> fraction
 380 %type <scm> full_markup
 381 %type <scm> identifier_init
 382 %type <scm> lilypond_header
 383 %type <scm> lilypond_header_body
 384 %type <scm> lyric_element
 385 %type <scm> lyric_markup
 386 %type <scm> markup
 387 %type <scm> markup_braced_list
 388 %type <scm> markup_braced_list_body
 389 %type <scm> markup_composed_list
 390 %type <scm> markup_head_1_item
 391 %type <scm> markup_head_1_list
 392 %type <scm> markup_list
 393 %type <scm> markup_top
 394 %type <scm> mode_changing_head
 395 %type <scm> mode_changing_head_with_context
 396 %type <scm> multiplied_duration
 397 %type <scm> new_chord
 398 %type <scm> new_lyrics
 399 %type <scm> number_expression
 400 %type <scm> number_factor
 401 %type <scm> number_term
 402 %type <scm> object_id_setting
 403 %type <scm> octave_check
 404 %type <scm> optional_context_mod
 405 %type <scm> optional_id
 406 %type <scm> optional_notemode_duration
 407 %type <scm> pitch
 408 %type <scm> pitch_also_in_chords
 409 %type <scm> post_events
 410 %type <scm> property_operation
 411 %type <scm> scalar
 412 %type <scm> script_abbreviation
 413 %type <scm> simple_markup
 414 %type <scm> simple_string
 415 %type <scm> steno_duration
 416 %type <scm> steno_pitch
 417 %type <scm> steno_tonic_pitch
 418 %type <scm> step_number
 419 %type <scm> step_numbers
 420 %type <scm> string
 421 %type <scm> function_scm_argument
 422
 423 %type <score> score_block
 424 %type <score> score_body
 425
 426
 427 %left '-' '+'
 428
 429 /* We don't assign precedence to / and *, because we might need varied
 430 prec levels in different prods */
 431
 432 %left UNARY_MINUS
 433
 434 %%
 435
 436 lilypond:       /* empty */
 437         | lilypond toplevel_expression {
 438         }
 439         | lilypond assignment {
 440         }
 441         | lilypond error {
 442                 THIS->error_level_ = 1;
 443         }
 444         | lilypond INVALID      {
 445                 THIS->error_level_ = 1;
 446         }
 447         ;
 448
 449
 450 object_id_setting:
 451         OBJECTID STRING { $$ = $2; }
 452         ;
 453
 454 toplevel_expression:
 455         lilypond_header {
 456                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 457         }
 458         | book_block {
 459                 Book *book = $1;
 460                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 461                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 462                 book->unprotect ();
 463         }
 464         | score_block {
 465                 Score *score = $1;
 466
 467                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 468                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 469                 score->unprotect ();
 470         }
 471         | toplevel_music {
 472                 Music *music = $1;
 473                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 474                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 475                 music->unprotect ();
 476         }
 477         | full_markup {
 478                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 479                 scm_call_2 (proc, THIS->self_scm (), $1);
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultlayout");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 od->unprotect();
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = get_header(THIS);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524 /*
 525         DECLARATIONS
 526 */
 527 assignment_id:
 528         STRING          { $$ = $1; }
 529         | LYRICS_STRING { $$ = $1; }
 530         ;
 531
 532 assignment:
 533         assignment_id '=' identifier_init  {
 534                 if (! is_regular_identifier ($1))
 535                 {
 536 #if 0
 537                         /* no longer valid with dashes in \paper{} block. */
 538                         @1.warning (_ ("identifier should have alphabetic characters only"));
 539 #endif
 540                 }
 541
 542
 543                 THIS->lexer_->set_identifier ($1, $3);
 544
 545 /*
 546  TODO: devise standard for protection in parser.
 547
 548   The parser stack lives on the C-stack, which means that
 549 all objects can be unprotected as soon as they're here.
 550
 551 */
 552         }
 553         | embedded_scm { }
 554         ;
 555
 556
 557 identifier_init:
 558         score_block {
 559                 $$ = $1->self_scm ();
 560                 $1->unprotect ();
 561         }
 562         | book_block {
 563                 $$ = $1->self_scm ();
 564                 $1->unprotect ();
 565         }
 566         | output_def {
 567                 $$ = $1->self_scm ();
 568                 $1->unprotect ();
 569         }
 570         | context_def_spec_block {
 571                 $$ = $1;
 572         }
 573         | Music  {
 574                 $$ = $1->self_scm ();
 575                 $1->unprotect();
 576         }
 577         | post_event {
 578                 $$ = $1->self_scm ();
 579                 $1->unprotect();
 580         }
 581         | number_expression {
 582                 $$ = $1;
 583         }
 584         | string {
 585                 $$ = $1;
 586         }
 587         | embedded_scm {
 588                 $$ = $1;
 589         }
 590         | full_markup {
 591                 $$ = $1;
 592         }
 593         | DIGIT {
 594                 $$ = scm_from_int ($1);
 595         }
 596         ;
 597
 598 context_def_spec_block:
 599         CONTEXT '{' context_def_spec_body '}'
 600                 {
 601                 $$ = $3;
 602         }
 603         ;
 604
 605 context_def_spec_body:
 606         /**/ {
 607                 $$ = Context_def::make_scm ();
 608                 unsmob_context_def ($$)->set_spot (@$);
 609         }
 610         | CONTEXT_DEF_IDENTIFIER {
 611                 $$ = $1;
 612                 unsmob_context_def ($$)->set_spot (@$);
 613         }
 614         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 615                 Context_def*td = unsmob_context_def ($$);
 616
 617                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 618                         SCM tag = scm_caar (p);
 619
 620                         /* TODO: should make new tag "grob-definition" ? */
 621                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 622                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 623                 }
 624         }
 625         | context_def_spec_body context_mod {
 626                 unsmob_context_def ($$)->add_context_mod ($2);
 627         }
 628         ;
 629
 630
 631
 632 book_block:
 633         BOOK '{' book_body '}'  {
 634                 $$ = $3;
 635         }
 636         ;
 637
 638 /* FIXME:
 639    * Use 'handlers' like for toplevel-* stuff?
 640    * grok \layout and \midi?  */
 641 book_body:
 642         {
 643                 $$ = new Book;
 644                 $$->set_spot (@$);
 645                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 646                 $$->paper_->unprotect ();
 647                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 648         }
 649         | BOOK_IDENTIFIER {
 650                 $$ = unsmob_book ($1);
 651                 $$->set_spot (@$);
 652         }
 653         | book_body paper_block {
 654                 $$->paper_ = $2;
 655                 $2->unprotect ();
 656         }
 657         | book_body score_block {
 658                 SCM s = $2->self_scm ();
 659                 $$->add_score (s);
 660                 $2->unprotect();
 661         }
 662         | book_body full_markup {
 663                 $$->add_score ($2);
 664         }
 665         | book_body lilypond_header {
 666                 $$->header_ = $2;
 667         }
 668         | book_body error {
 669                 $$->paper_ = 0;
 670                 $$->scores_ = SCM_EOL;
 671         }
 672         | book_body object_id_setting {
 673                 $$->user_key_ = ly_scm2string ($2);
 674         }
 675         ;
 676
 677 score_block:
 678         SCORE '{' score_body '}'        {
 679                 $$ = $3;
 680         }
 681         ;
 682
 683 score_body:
 684         Music {
 685                 SCM m = $1->self_scm ();
 686                 $1->unprotect();
 687                 SCM scorify = ly_lily_module_constant ("scorify-music");
 688                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 689
 690                 // pass ownernship to C++ again.
 691                 $$ = unsmob_score (score);
 692                 $$->protect ();
 693                 $$->set_spot (@$);
 694         }
 695         | SCORE_IDENTIFIER {
 696                 $$ = unsmob_score ($1);
 697                 $$->set_spot (@$);
 698         }
 699         | score_body object_id_setting {
 700                 $$->user_key_ = ly_scm2string ($2);
 701         }
 702         | score_body lilypond_header    {
 703                 $$->header_ = $2;
 704         }
 705         | score_body output_def {
 706                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 707                 {
 708                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 709
 710                 }
 711                 else
 712                 {
 713                         $$->add_output_def ($2);
 714                 }
 715                 $2->unprotect ();
 716         }
 717         | score_body error {
 718                 $$->error_found_ = true;
 719         }
 720         ;
 721
 722
 723 /*
 724         OUTPUT DEF
 725 */
 726
 727 paper_block:
 728         output_def {
 729                 $$ = $1;
 730                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 731                 {
 732                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 733                         $$ = get_paper (THIS);
 734                 }
 735         }
 736         ;
 737
 738
 739 output_def:
 740         output_def_body '}' {
 741                 $$ = $1;
 742
 743                 THIS->lexer_->remove_scope ();
 744                 THIS->lexer_->pop_state ();
 745         }
 746         ;
 747
 748 output_def_head:
 749         PAPER {
 750                 $$ = get_paper (THIS);
 751                 $$->input_origin_ = @$;
 752                 THIS->lexer_->add_scope ($$->scope_);
 753         }
 754         | MIDI    {
 755                 Output_def *p = get_midi (THIS);
 756                 $$ = p;
 757                 THIS->lexer_->add_scope (p->scope_);
 758         }
 759         | LAYOUT        {
 760                 Output_def *p = get_layout (THIS);
 761
 762                 THIS->lexer_->add_scope (p->scope_);
 763                 $$ = p;
 764         }
 765         ;
 766
 767 output_def_head_with_mode_switch:
 768         output_def_head {
 769                 THIS->lexer_->push_initial_state ();
 770                 $$ = $1;
 771         }
 772         ;
 773
 774 output_def_body:
 775         output_def_head_with_mode_switch '{' {
 776                 $$ = $1;
 777                 $$->input_origin_.set_spot (@$);
 778         }
 779         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 780                 $1->unprotect ();
 781                 Output_def *o = unsmob_output_def ($3);
 782                 o->input_origin_.set_spot (@$);
 783                 $$ = o;
 784                 THIS->lexer_->remove_scope ();
 785                 THIS->lexer_->add_scope (o->scope_);
 786         }
 787         | output_def_body assignment  {
 788
 789         }
 790         | output_def_body context_def_spec_block        {
 791                 assign_context_def ($$, $2);
 792         }
 793         | output_def_body tempo_event  {
 794                 /*
 795                         junk this ? there already is tempo stuff in
 796                         music.
 797                 */
 798                 int m = scm_to_int ($2->get_property ("metronome-count"));
 799                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 800                 set_tempo ($$, d->get_length (), m);
 801                 $2->unprotect ();
 802         }
 803         | output_def_body error {
 804
 805         }
 806         ;
 807
 808 tempo_event:
 809         TEMPO steno_duration '=' bare_unsigned  {
 810                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 811                 $$->set_property ("tempo-unit", $2);
 812                 $$->set_property ("metronome-count", scm_from_int ( $4));
 813         }
 814         ;
 815
 816 /*
 817 The representation of a  list is the
 818
 819   (LIST . LAST-CONS)
 820
 821  to have efficient append.  */
 822
 823 Music_list:
 824         /* empty */ {
 825                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 826         }
 827         | Music_list Music {
 828                 SCM s = $$;
 829                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 830                 $2->unprotect (); /* UGH */
 831
 832                 if (scm_is_pair (scm_cdr (s)))
 833                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 834                 else
 835                         scm_set_car_x (s, c); /* set first cons */
 836                 scm_set_cdr_x (s, c);  /* remember last cell */
 837         }
 838         | Music_list embedded_scm {
 839
 840         }
 841         | Music_list error {
 842                 Music * m = MY_MAKE_MUSIC("Music");
 843                 // ugh. code dup
 844                 m->set_property ("error-found", SCM_BOOL_T);
 845                 SCM s = $$;
 846                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 847                 m->unprotect (); /* UGH */
 848
 849                 if (scm_is_pair (scm_cdr (s)))
 850                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 851                 else
 852                         scm_set_car_x (s, c); /* set first cons */
 853                 scm_set_cdr_x (s, c);  /* remember last cell */
 854         }
 855         ;
 856
 857 Music:
 858         Simple_music
 859         | Composite_music
 860         ;
 861
 862 Alternative_music:
 863         /* empty */ {
 864                 $$ = SCM_EOL;
 865         }
 866         | ALTERNATIVE '{' Music_list '}' {
 867                 $$ = $3;
 868         }
 869         ;
 870
 871
 872 Repeated_music:
 873         REPEAT simple_string bare_unsigned Music Alternative_music
 874         {
 875                 SCM proc = ly_lily_module_constant ("make-repeat");
 876                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 877                 assert ($4);
 878                 SCM mus = scm_call_4 (proc, $2, scm_int2num ($3), $4->self_scm (), alts);
 879                 Music *r = unsmob_music (mus);
 880
 881                 r->protect ();
 882                 $4->unprotect ();
 883                 r->set_spot (*$4->origin ());
 884
 885                 $$ = r;
 886         }
 887         ;
 888
 889 Sequential_music:
 890         SEQUENTIAL '{' Music_list '}'           {
 891                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 892                 $$->set_property ("elements", scm_car ($3));
 893                 $$->set_spot (@$);
 894         }
 895         | '{' Music_list '}'            {
 896                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 897                 $$->set_property ("elements", scm_car ($2));
 898                 $$->set_spot (@$);
 899         }
 900         ;
 901
 902 Simultaneous_music:
 903         SIMULTANEOUS '{' Music_list '}'{
 904                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 905                 $$->set_property ("elements", scm_car ($3));
 906                 $$->set_spot (@$);
 907
 908         }
 909         | simul_open Music_list simul_close     {
 910                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 911                 $$->set_property ("elements", scm_car ($2));
 912                 $$->set_spot (@$);
 913         }
 914         ;
 915
 916 Simple_music:
 917         event_chord             { $$ = $1; }
 918         | MUSIC_IDENTIFIER {
 919                 $$ = unsmob_music ($1);
 920         }
 921         | music_property_def
 922         | context_change
 923         ;
 924
 925 optional_context_mod:
 926         /**/ { $$ = SCM_EOL; }
 927         | WITH { THIS->lexer_->push_initial_state (); }
 928         '{' context_mod_list '}'
 929         {
 930                 THIS->lexer_->pop_state ();
 931                 $$ = $4;
 932         }
 933         ;
 934
 935 context_mod_list:
 936         /* */  { $$ = SCM_EOL; }
 937         | context_mod_list context_mod  {
 938                  $$ = scm_cons ($2, $1);
 939         }
 940         ;
 941
 942 Composite_music:
 943         Prefix_composite_music { $$ = $1; }
 944         | Grouped_music_list { $$ = $1; }
 945         ;
 946
 947 Grouped_music_list:
 948         Simultaneous_music              { $$ = $1; }
 949         | Sequential_music              { $$ = $1; }
 950         ;
 951
 952 function_scm_argument:
 953         embedded_scm
 954         | simple_string
 955         ;
 956
 957 /*
 958 TODO: use code generation for this
 959 */
 960 Generic_prefix_music_scm:
 961         MUSIC_FUNCTION {
 962                 $$ = scm_list_2 ($1, make_input (@$));
 963         }
 964         | MUSIC_FUNCTION_SCM function_scm_argument {
 965                 $$ = scm_list_3 ($1, make_input (@$), $2);
 966         }
 967         | MUSIC_FUNCTION_MARKUP full_markup {
 968                 $$ = scm_list_3 ($1, make_input (@$), $2);
 969         }
 970         | music_function_musicless_prefix Music {
 971                 $$ = ly_append2 ($1, scm_list_1 ($2->self_scm ()));
 972                 $2->unprotect ();
 973         }
 974         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
 975                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 976         }
 977         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
 978                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
 979         }
 980         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
 981                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
 982                 $3->unprotect ();
 983         }
 984         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
 985                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
 986         }
 987         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
 988                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
 989                 $2->unprotect ();
 990                 $3->unprotect ();
 991         }
 992         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
 993                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
 994                 $4->unprotect ();
 995                 $3->unprotect ();
 996         }
 997         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
 998                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
 999                 $3->unprotect ();
1000                 $4->unprotect ();
1001         }
1002         ;
1003
1004 optional_id:
1005         /**/ { $$ = SCM_EOL; }
1006         | '=' simple_string {
1007                 $$ = $2;
1008         }
1009         ;
1010
1011
1012 Prefix_composite_music:
1013         Generic_prefix_music_scm {
1014                 $$ = run_music_function (THIS, $1);
1015         }
1016         | CONTEXT    simple_string optional_id optional_context_mod Music {
1017                 $$ = context_spec_music ($2, $3, $5, $4, false);
1018         }
1019         | NEWCONTEXT simple_string optional_id optional_context_mod Music {
1020                 $$ = context_spec_music ($2, $3, $5, $4, true);
1021         }
1022
1023         | TIMES fraction Music
1024         {
1025                 int n = scm_to_int (scm_car ($2));
1026                 int d = scm_to_int (scm_cdr ($2));
1027                 Music *mp = $3;
1028
1029                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1030                 $$->set_spot (@$);
1031
1032                 $$->set_property ("element", mp->self_scm ());
1033                 mp->unprotect();
1034                 $$->set_property ("numerator", scm_from_int (n));
1035                 $$->set_property ("denominator", scm_from_int (d));
1036                 $$->compress (Moment (Rational (n,d)));
1037         }
1038         | Repeated_music                { $$ = $1; }
1039         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1040                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1041                 Music *p = $4;
1042                 Pitch from = *unsmob_pitch ($2);
1043                 Pitch to = *unsmob_pitch ($3);
1044
1045                 p->transpose (pitch_interval (from, to));
1046                 $$->set_property ("element", p->self_scm ());
1047                 p->unprotect();
1048         }
1049         | mode_changing_head Grouped_music_list {
1050                 if ($1 == ly_symbol2scm ("chords"))
1051                 {
1052                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1053                   chm->set_property ("element", $2->self_scm ());
1054                   $$ = chm;
1055                   $2->unprotect();
1056                 }
1057                 else
1058                 {
1059                   $$ = $2;
1060                 }
1061                 THIS->lexer_->pop_state ();
1062         }
1063         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1064                 $$ = context_spec_music ($1, SCM_UNDEFINED, $3, $2, true);
1065                 if ($1 == ly_symbol2scm ("ChordNames"))
1066                 {
1067                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1068                   chm->set_property ("element", $$->self_scm ());
1069                   $$->unprotect();
1070                   $$ = chm;
1071                 }
1072                 THIS->lexer_->pop_state ();
1073         }
1074         | relative_music        { $$ = $1; }
1075         | re_rhythmed_music     { $$ = $1; }
1076         ;
1077
1078 mode_changing_head:
1079         NOTEMODE {
1080                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1081                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1082
1083                 $$ = ly_symbol2scm ("notes");
1084         }
1085         | DRUMMODE
1086                 {
1087                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1088                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1089
1090                 $$ = ly_symbol2scm ("drums");
1091         }
1092         | FIGUREMODE {
1093                 THIS->lexer_->push_figuredbass_state ();
1094
1095                 $$ = ly_symbol2scm ("figures");
1096         }
1097         | CHORDMODE {
1098                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1099                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1100                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1101                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1102                 $$ = ly_symbol2scm ("chords");
1103
1104         }
1105         | LYRICMODE
1106                 { THIS->lexer_->push_lyric_state ();
1107                 $$ = ly_symbol2scm ("lyrics");
1108         }
1109         ;
1110
1111 mode_changing_head_with_context:
1112         DRUMS {
1113                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1114                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1115
1116                 $$ = ly_symbol2scm ("DrumStaff");
1117         }
1118         | FIGURES {
1119                 THIS->lexer_->push_figuredbass_state ();
1120
1121                 $$ = ly_symbol2scm ("FiguredBass");
1122         }
1123         | CHORDS {
1124                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1125                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1126                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1127                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1128                 $$ = ly_symbol2scm ("ChordNames");
1129         }
1130         | LYRICS
1131                 { THIS->lexer_->push_lyric_state ();
1132                 $$ = ly_symbol2scm ("Lyrics");
1133         }
1134         ;
1135
1136
1137 relative_music:
1138         RELATIVE absolute_pitch Music {
1139                 Music *m = $3;
1140                 Pitch start = *unsmob_pitch ($2);
1141                 $$ = make_music_relative (start, m);
1142                 m->unprotect();
1143         }
1144         | RELATIVE Composite_music {
1145                 Music *m = $2;
1146
1147                 Pitch middle_c (0, 0, 0);
1148                 $$ = make_music_relative (middle_c, m);
1149                 m->unprotect();
1150         }
1151         ;
1152
1153 new_lyrics:
1154         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1155         /*cont */
1156         Grouped_music_list {
1157         /* Can also use Music at the expensive of two S/Rs similar to
1158            \repeat \alternative */
1159                 THIS->lexer_->pop_state ();
1160
1161                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1162         }
1163         | new_lyrics ADDLYRICS {
1164                 THIS->lexer_->push_lyric_state ();
1165         } Grouped_music_list {
1166                 THIS->lexer_->pop_state ();
1167                 $$ = scm_cons ($4->self_scm (), $1);
1168         }
1169         ;
1170
1171 re_rhythmed_music:
1172         Grouped_music_list new_lyrics {
1173                 Music * voice = $1;
1174                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1175                 if (!scm_is_string (name))
1176                 {
1177                         name = get_next_unique_lyrics_context_id ();
1178                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1179                                                     name,
1180                                                     voice, SCM_EOL, false);
1181                 }
1182
1183                 SCM context = scm_makfrom0str ("Lyrics");
1184                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1185
1186                 SCM lst = SCM_EOL;
1187                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1188                 {
1189                         Music *music = unsmob_music (scm_car (s));
1190                         Music *com = make_lyric_combine_music (name, music);
1191                         Music *csm = context_spec_music (context,
1192                                 SCM_UNDEFINED, com, SCM_EOL, true);
1193                         lst = scm_cons (csm->self_scm (), lst);
1194                 }
1195                 all->set_property ("elements", scm_cons (voice->self_scm (),
1196                         lst));
1197                 $$ = all;
1198                 voice->unprotect ();
1199         }
1200         | LYRICSTO simple_string {
1201                 THIS->lexer_->push_lyric_state ();
1202         } Music {
1203                 THIS->lexer_->pop_state ();
1204                 Music *music = $4;
1205                 SCM name = $2;
1206                 $$ = make_lyric_combine_music (name, music);
1207                 music->unprotect();
1208         }
1209         ;
1210
1211 context_change:
1212         CHANGE STRING '=' STRING  {
1213                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1214                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1215                 t-> set_property ("change-to-id", $4);
1216
1217                 $$ = t;
1218                 $$->set_spot (@$);
1219         }
1220         ;
1221
1222 property_operation:
1223         STRING '=' scalar {
1224                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1225                         scm_string_to_symbol ($1), $3);
1226         }
1227         | UNSET simple_string {
1228                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1229                         scm_string_to_symbol ($2));
1230         }
1231         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1232                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1233                         scm_string_to_symbol ($2), $5, $3);
1234         }
1235         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1236                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1237                                 scm_string_to_symbol ($2), $6, $4, $3);
1238         }
1239         | REVERT simple_string embedded_scm {
1240                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1241                         scm_string_to_symbol ($2), $3);
1242         }
1243         ;
1244
1245 context_def_mod:
1246         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1247         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1248
1249         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1250         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1251         | DENIES { $$ = ly_symbol2scm ("denies"); }
1252
1253         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1254         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1255         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1256         | NAME { $$ = ly_symbol2scm ("context-name"); }
1257         ;
1258
1259 context_mod:
1260         property_operation { $$ = $1; }
1261         | context_def_mod STRING {
1262                 $$ = scm_list_2 ($1, $2);
1263         }
1264         ;
1265
1266 context_prop_spec:
1267         simple_string {
1268                 if (!is_regular_identifier ($1))
1269                 {
1270                         @$.error (_("Grob name should be alphanumeric"));
1271                 }
1272
1273                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1274                         scm_string_to_symbol ($1));
1275         }
1276         | simple_string '.' simple_string {
1277                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1278                         scm_string_to_symbol ($3));
1279         }
1280         ;
1281
1282 music_property_def:
1283         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1284                 $$ = property_op_to_music (scm_list_4 (
1285                         ly_symbol2scm ("push"),
1286                         scm_cadr ($2),
1287                         $5, $3));
1288                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1289         }
1290         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1291                 $$ = property_op_to_music (scm_list_5 (
1292                         ly_symbol2scm ("push"),
1293                         scm_cadr ($2),
1294                         $6, $4, $3));
1295                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1296         }
1297         | REVERT context_prop_spec embedded_scm {
1298                 $$ = property_op_to_music (scm_list_3 (
1299                         ly_symbol2scm ("pop"),
1300                         scm_cadr ($2),
1301                         $3));
1302
1303                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1304         }
1305         | SET context_prop_spec '=' scalar {
1306                 $$ = property_op_to_music (scm_list_3 (
1307                         ly_symbol2scm ("assign"),
1308                         scm_cadr ($2),
1309                         $4));
1310                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1311         }
1312         | UNSET context_prop_spec {
1313                 $$ = property_op_to_music (scm_list_2 (
1314                         ly_symbol2scm ("unset"),
1315                         scm_cadr ($2)));
1316                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1317         }
1318         | ONCE music_property_def {
1319                 SCM e = $2->get_property ("element");
1320                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1321                 $$ = $2;
1322
1323         }
1324         ;
1325
1326
1327 string:
1328         STRING {
1329                 $$ = $1;
1330         }
1331         | STRING_IDENTIFIER {
1332                 $$ = $1;
1333         }
1334         | string '+' string {
1335                 $$ = scm_string_append (scm_list_2 ($1, $3));
1336         }
1337         ;
1338
1339 simple_string: STRING {
1340                 $$ = $1;
1341         }
1342         | LYRICS_STRING {
1343                 $$ = $1;
1344         }
1345         | STRING_IDENTIFIER {
1346                 $$ = $1;
1347         }
1348         ;
1349
1350 scalar: string {
1351                 $$ = $1;
1352         }
1353         | LYRICS_STRING {
1354                 $$ = $1;
1355         }
1356         | bare_number {
1357                 $$ = $1;
1358         }
1359         | embedded_scm {
1360                 $$ = $1;
1361         }
1362         | full_markup {
1363                 $$ = $1;
1364         }
1365         | DIGIT {
1366                 $$ = scm_from_int ($1);
1367         }
1368         ;
1369
1370 /*
1371
1372 pre_events doesn't contain anything. It is a trick:
1373
1374 Adding pre_events to the simple_element
1375 makes the choice between
1376
1377   string:  STRING
1378
1379 and
1380
1381   simple_element: STRING
1382
1383 a single shift/reduction conflict.
1384
1385 nevertheless, this is not very clean, and we should find a different
1386 solution.
1387
1388 */
1389 pre_events: /* empty */
1390         ;
1391
1392 event_chord:
1393         pre_events simple_element post_events   {
1394                 SCM elts = $2-> get_property ("elements");
1395
1396                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1397
1398                 $2->set_property ("elements", elts);
1399                 /* why is this giving wrong start location? -ns
1400                  * $2->set_spot (@$); */
1401                 Input i;
1402                 i.set_location (@2, @3);
1403                 $2->set_spot (i);
1404                 $$ = $2;
1405         }
1406         | command_element
1407         | note_chord_element
1408         ;
1409
1410
1411 note_chord_element:
1412         chord_body optional_notemode_duration post_events
1413         {
1414                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1415                 SCM es = $1->get_property ("elements");
1416                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1417
1418                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1419                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1420                 es = ly_append2 (es, postevs);
1421
1422                 $1-> set_property ("elements", es);
1423                 $1->set_spot (@$);
1424                 $$ = $1;
1425         }
1426         ;
1427
1428 chord_open: '<'
1429         ;
1430
1431 chord_close: '>'
1432         ;
1433
1434 simul_open: DOUBLE_ANGLE_OPEN
1435         ;
1436
1437 simul_close: DOUBLE_ANGLE_CLOSE
1438         ;
1439
1440 chord_body:
1441         chord_open chord_body_elements chord_close
1442         {
1443                 $$ = MY_MAKE_MUSIC ("EventChord");
1444                 $$->set_spot (@$);
1445                 $$->set_property ("elements",
1446                         scm_reverse_x ($2, SCM_EOL));
1447         }
1448         ;
1449
1450 chord_body_elements:
1451         /* empty */             { $$ = SCM_EOL; }
1452         | chord_body_elements chord_body_element {
1453                 $$ = scm_cons ($2->self_scm (), $1);
1454                 $2->unprotect ();
1455         }
1456         ;
1457
1458 chord_body_element:
1459         pitch exclamations questions octave_check post_events
1460         {
1461                 int q = $3;
1462                 int ex = $2;
1463                 SCM check = $4;
1464                 SCM post = $5;
1465
1466                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1467                 n->set_property ("pitch", $1);
1468                 n->set_spot (@$);
1469                 if (q % 2)
1470                         n->set_property ("cautionary", SCM_BOOL_T);
1471                 if (ex % 2 || q % 2)
1472                         n->set_property ("force-accidental", SCM_BOOL_T);
1473
1474                 if (scm_is_pair (post)) {
1475                         SCM arts = scm_reverse_x (post, SCM_EOL);
1476                         n->set_property ("articulations", arts);
1477                 }
1478                 if (scm_is_number (check))
1479                 {
1480                         int q = scm_to_int (check);
1481                         n->set_property ("absolute-octave", scm_from_int (q-1));
1482                 }
1483
1484
1485                 $$ = n;
1486         }
1487         | DRUM_PITCH post_events {
1488                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1489                 n->set_property ("duration", $2);
1490                 n->set_property ("drum-type", $1);
1491                 n->set_spot (@$);
1492
1493                 if (scm_is_pair ($2)) {
1494                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1495                         n->set_property ("articulations", arts);
1496                 }
1497                 $$ = n;
1498         }
1499         | music_function_chord_body {
1500                 $$ = run_music_function (THIS, $1);
1501                 $$->set_spot (@$);
1502         }
1503         ;
1504
1505 music_function_chord_body:
1506         MUSIC_FUNCTION {
1507                 $$ = scm_list_2 ($1, make_input (@$));
1508         }
1509         | music_function_musicless_prefix chord_body_element {
1510                 $$ = ly_append2 ($1, scm_list_1 ($2->self_scm ()));
1511                 $2->unprotect ();
1512         }
1513         ;
1514
1515 music_function_event:
1516         music_function_musicless_prefix post_event {
1517                 $$ = ly_append2 ($1, scm_list_1 ($2->self_scm ()));
1518                 $2->unprotect ();
1519         }
1520         ;
1521
1522 /*
1523 TODO: use code generation for this
1524 */
1525 music_function_musicless_prefix:
1526         MUSIC_FUNCTION_MUSIC {
1527                 $$ = scm_list_2 ($1, make_input (@$));
1528         }
1529         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument {
1530                 $$ = scm_list_3 ($1, make_input (@$), $2);
1531         }
1532         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument {
1533                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1534         }
1535         | MUSIC_FUNCTION_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument {
1536                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1537         }
1538         | MUSIC_FUNCTION_SCM_SCM_SCM_SCM_MUSIC function_scm_argument function_scm_argument function_scm_argument function_scm_argument {
1539                 $$ = scm_list_n ($1, make_input (@$), $2, $3, $4, $5, SCM_UNDEFINED);
1540         }
1541         ;
1542
1543
1544 command_element:
1545         command_event {
1546                 $$ = MY_MAKE_MUSIC ("EventChord");
1547                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1548                 $1->unprotect();
1549
1550                 $$-> set_spot (@$);
1551                 $1-> set_spot (@$);
1552         }
1553         | SKIP duration_length {
1554                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1555                 skip->set_property ("duration", $2);
1556                 skip->set_spot (@$);
1557                 $$ = skip;
1558         }
1559         | E_BRACKET_OPEN {
1560                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1561                 m->set_property ("span-direction", scm_from_int (START));
1562                 m->set_spot (@$);
1563
1564                 $$ = MY_MAKE_MUSIC ("EventChord");
1565                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1566                 m->unprotect();
1567                 $$->set_spot (@$);
1568         }
1569         | E_BRACKET_CLOSE {
1570                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1571                 m->set_property ("span-direction", scm_from_int (STOP));
1572                 m->set_spot (@$);
1573
1574                 $$ = MY_MAKE_MUSIC ("EventChord");
1575                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1576                 $$->set_spot (@$);
1577                 m->unprotect ();
1578         }
1579         | E_BACKSLASH {
1580                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1581                 $$->set_spot (@$);
1582         }
1583         | '|'      {
1584                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1585
1586                 if (Music * m = unsmob_music (pipe))
1587                         $$ = m->clone ();
1588                 else
1589                         $$ = MY_MAKE_MUSIC ("BarCheck");
1590
1591                 $$->set_spot (@$);
1592         }
1593         | TRANSPOSITION pitch {
1594                 Pitch middle_c;
1595                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1596                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1597                                          sounds_as_c.smobbed_copy());
1598                 $$->set_spot (@$);
1599                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1600                         $$, SCM_EOL, false);
1601         }
1602         | PARTIAL duration_length       {
1603                 Moment m = - unsmob_duration ($2)->get_length ();
1604                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1605                 p->set_spot (@$);
1606                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1607                                         p, SCM_EOL, false);
1608                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1609                                         p, SCM_EOL, false);
1610                 $$ = p;
1611         }
1612
1613         | TIME_T fraction  {
1614                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1615
1616                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1617                 $$ = unsmob_music (result);
1618                 $$->protect ();
1619         }
1620         | MARK scalar {
1621                 SCM proc = ly_lily_module_constant ("make-mark-set");
1622
1623                 SCM result = scm_call_1 (proc, $2);
1624                 $$ = unsmob_music (result);
1625                 $$->protect ();
1626         }
1627         ;
1628
1629 command_event:
1630         E_TILDE {
1631                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1632         }
1633         | MARK DEFAULT  {
1634                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1635                 $$ = m;
1636         }
1637         | tempo_event {
1638                 $$ = $1;
1639         }
1640         | KEY DEFAULT {
1641                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1642                 $$ = key;
1643         }
1644         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1645
1646                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1647                 if (scm_ilength ($3) > 0)
1648                 {
1649                         key->set_property ("pitch-alist", $3);
1650                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1651                         key->transpose (* unsmob_pitch ($2));
1652                 } else {
1653                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1654                 }
1655
1656                 $$ = key;
1657         }
1658         ;
1659
1660
1661 post_events:
1662         /* empty */ {
1663                 $$ = SCM_EOL;
1664         }
1665         | post_events post_event {
1666                 $2->set_spot (@2);
1667                 $$ = scm_cons ($2->self_scm (), $$);
1668                 $2->unprotect ();
1669         }
1670         ;
1671
1672 post_event:
1673         direction_less_event {
1674                 $$ = $1;
1675         }
1676         | '-' music_function_event {
1677                 Music *mus = run_music_function (THIS, $2);
1678                 mus->set_spot (@1);
1679                 $$ = mus;
1680         }
1681         | HYPHEN {
1682                 if (!THIS->lexer_->is_lyric_state ())
1683                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1684                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1685         }
1686         | EXTENDER {
1687                 if (!THIS->lexer_->is_lyric_state ())
1688                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1689                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1690         }
1691         | script_dir direction_reqd_event {
1692                 if ($1)
1693                         $2->set_property ("direction", scm_from_int ($1));
1694                 $$ = $2;
1695         }
1696         | script_dir direction_less_event {
1697                 if ($1)
1698                         $2->set_property ("direction", scm_from_int ($1));
1699                 $$ = $2;
1700         }
1701         | string_number_event
1702         ;
1703
1704 string_number_event:
1705         E_UNSIGNED {
1706                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1707                 s->set_property ("string-number", scm_from_int ($1));
1708                 s->set_spot (@$);
1709                 $$ = s;
1710         }
1711         ;
1712
1713 direction_less_char:
1714         '['  {
1715                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1716         }
1717         | ']'  {
1718                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1719         }
1720         | '~'  {
1721                 $$ = ly_symbol2scm ("tildeSymbol");
1722         }
1723         | '('  {
1724                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1725         }
1726         | ')'  {
1727                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1728         }
1729         | E_EXCLAMATION  {
1730                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1731         }
1732         | E_OPEN  {
1733                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1734         }
1735         | E_CLOSE  {
1736                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1737         }
1738         | E_ANGLE_CLOSE  {
1739                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1740         }
1741         | E_ANGLE_OPEN  {
1742                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1743         }
1744         ;
1745
1746 direction_less_event:
1747         direction_less_char {
1748                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1749                 Music * m = 0;
1750                 if (unsmob_music (predefd))
1751                 {
1752                         m = unsmob_music (predefd)->clone ();
1753                 }
1754                 else
1755                 {
1756                         m = MY_MAKE_MUSIC ("Music");
1757                 }
1758                 m->set_spot (@$);
1759                 $$ = m;
1760         }
1761         | EVENT_IDENTIFIER      {
1762                 $$ = unsmob_music ($1);
1763         }
1764         | tremolo_type  {
1765                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1766                a->set_spot (@$);
1767                a->set_property ("tremolo-type", scm_from_int ($1));
1768                $$ = a;
1769         }
1770         ;
1771
1772 direction_reqd_event:
1773         gen_text_def {
1774                 $$ = $1;
1775         }
1776         | script_abbreviation {
1777                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1778                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1779                 if (scm_is_string (s))
1780                         a->set_property ("articulation-type", s);
1781                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1782                 $$ = a;
1783         }
1784         ;
1785
1786 octave_check:
1787         /**/ { $$ = SCM_EOL; }
1788         | '='  { $$ = scm_from_int (0); }
1789         | '=' sub_quotes { $$ = scm_from_int ($2); }
1790         | '=' sup_quotes { $$ = scm_from_int ($2); }
1791         ;
1792
1793 sup_quotes:
1794         '\'' {
1795                 $$ = 1;
1796         }
1797         | sup_quotes '\'' {
1798                 $$ ++;
1799         }
1800         ;
1801
1802 sub_quotes:
1803         ',' {
1804                 $$ = 1;
1805         }
1806         | sub_quotes ',' {
1807                 $$++;
1808         }
1809         ;
1810
1811 steno_pitch:
1812         NOTENAME_PITCH  {
1813                 $$ = $1;
1814         }
1815         | NOTENAME_PITCH sup_quotes     {
1816                 Pitch p = *unsmob_pitch ($1);
1817                 p = p.transposed (Pitch ($2,0,0));
1818                 $$ = p.smobbed_copy ();
1819         }
1820         | NOTENAME_PITCH sub_quotes      {
1821                 Pitch p =* unsmob_pitch ($1);
1822                 p = p.transposed (Pitch (-$2,0,0));
1823                 $$ = p.smobbed_copy ();
1824         }
1825         ;
1826
1827 /*
1828 ugh. duplication
1829 */
1830
1831 steno_tonic_pitch:
1832         TONICNAME_PITCH {
1833                 $$ = $1;
1834         }
1835         | TONICNAME_PITCH sup_quotes    {
1836                 Pitch p = *unsmob_pitch ($1);
1837                 p = p.transposed (Pitch ($2,0,0));
1838                 $$ = p.smobbed_copy ();
1839         }
1840         | TONICNAME_PITCH sub_quotes     {
1841                 Pitch p =* unsmob_pitch ($1);
1842
1843                 p = p.transposed (Pitch (-$2,0,0));
1844                 $$ = p.smobbed_copy ();
1845         }
1846         ;
1847
1848 pitch:
1849         steno_pitch {
1850                 $$ = $1;
1851         }
1852         ;
1853
1854 pitch_also_in_chords:
1855         pitch
1856         | steno_tonic_pitch
1857         ;
1858
1859 gen_text_def:
1860         full_markup {
1861                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1862                 t->set_property ("text", $1);
1863                 t->set_spot (@$);
1864                 $$ = t;
1865         }
1866         | string {
1867                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1868                 t->set_property ("text",
1869                         make_simple_markup ($1));
1870                 t->set_spot (@$);
1871                 $$ = t;
1872
1873         }
1874         | DIGIT {
1875                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1876                 t->set_property ("digit", scm_from_int ($1));
1877                 t->set_spot (@$);
1878                 $$ = t;
1879         }
1880         ;
1881
1882 script_abbreviation:
1883         '^'             {
1884                 $$ = scm_makfrom0str ("Hat");
1885         }
1886         | '+'           {
1887                 $$ = scm_makfrom0str ("Plus");
1888         }
1889         | '-'           {
1890                 $$ = scm_makfrom0str ("Dash");
1891         }
1892         | '|'           {
1893                 $$ = scm_makfrom0str ("Bar");
1894         }
1895         | '>'           {
1896                 $$ = scm_makfrom0str ("Larger");
1897         }
1898         | '.'           {
1899                 $$ = scm_makfrom0str ("Dot");
1900         }
1901         | '_' {
1902                 $$ = scm_makfrom0str ("Underscore");
1903         }
1904         ;
1905
1906 script_dir:
1907         '_'     { $$ = DOWN; }
1908         | '^'   { $$ = UP; }
1909         | '-'   { $$ = CENTER; }
1910         ;
1911
1912
1913 absolute_pitch:
1914         steno_pitch     {
1915                 $$ = $1;
1916         }
1917         ;
1918
1919 duration_length:
1920         multiplied_duration {
1921                 $$ = $1;
1922         }
1923         ;
1924
1925 optional_notemode_duration:
1926         {
1927                 Duration dd = THIS->default_duration_;
1928                 $$ = dd.smobbed_copy ();
1929         }
1930         | multiplied_duration   {
1931                 $$ = $1;
1932                 THIS->default_duration_ = *unsmob_duration ($$);
1933         }
1934         ;
1935
1936 steno_duration:
1937         bare_unsigned dots              {
1938                 int len = 0;
1939                 if (!is_duration ($1))
1940                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
1941                 else
1942                         len = intlog2 ($1);
1943
1944                 $$ = Duration (len, $2).smobbed_copy ();
1945         }
1946         | DURATION_IDENTIFIER dots      {
1947                 Duration *d = unsmob_duration ($1);
1948                 Duration k (d->duration_log (), d->dot_count () + $2);
1949                 *d = k;
1950                 $$ = $1;
1951         }
1952         ;
1953
1954 multiplied_duration:
1955         steno_duration {
1956                 $$ = $1;
1957         }
1958         | multiplied_duration '*' bare_unsigned {
1959                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1960         }
1961         | multiplied_duration '*' FRACTION {
1962                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
1963
1964                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1965         }
1966         ;
1967
1968 fraction:
1969         FRACTION { $$ = $1; }
1970         | UNSIGNED '/' UNSIGNED {
1971                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
1972         }
1973         ;
1974
1975 dots:
1976         /* empty */     {
1977                 $$ = 0;
1978         }
1979         | dots '.' {
1980                 $$ ++;
1981         }
1982         ;
1983
1984 tremolo_type:
1985         ':'     {
1986                 $$ = 0;
1987         }
1988         | ':' bare_unsigned {
1989                 if (!is_duration ($2))
1990                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
1991                 $$ = $2;
1992         }
1993         ;
1994
1995 bass_number:
1996         DIGIT   {
1997                 $$ = scm_from_int ($1);
1998         }
1999         | UNSIGNED {
2000                 $$ = scm_from_int ($1);
2001         }
2002         | STRING { $$ = $1; }
2003         | full_markup { $$ = $1; }
2004         ;
2005
2006 figured_bass_alteration:
2007         '-'     { $$ = -2; }
2008         | '+'   { $$ = 2; }
2009         | '!'   { $$ = 0; }
2010         ;
2011
2012 bass_figure:
2013         FIGURE_SPACE {
2014                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2015                 $$ = bfr->self_scm ();
2016                 bfr->unprotect ();
2017                 bfr->set_spot (@1);
2018         }
2019         | bass_number  {
2020                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2021                 $$ = bfr->self_scm ();
2022
2023                 if (scm_is_number ($1))
2024                         bfr->set_property ("figure", $1);
2025                 else if (Text_interface::is_markup ($1))
2026                         bfr->set_property ("text", $1);
2027
2028                 bfr->unprotect ();
2029                 bfr->set_spot (@1);
2030         }
2031         | bass_figure ']' {
2032                 $$ = $1;
2033                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2034         }
2035         | bass_figure figured_bass_alteration {
2036                 Music *m = unsmob_music ($1);
2037                 if ($2) {
2038                         SCM salter = m->get_property ("alteration");
2039                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2040                         m->set_property ("alteration",
2041                                 scm_from_int (alter + $2));
2042                 } else {
2043                         m->set_property ("alteration", scm_from_int (0));
2044                 }
2045         }
2046         | bass_figure figured_bass_modification  {
2047                 Music *m = unsmob_music ($1);
2048                 if ($2 == ly_symbol2scm ("plus"))
2049                         {
2050                         m->set_property ("augmented", SCM_BOOL_T);
2051                         }
2052                 else if ($2 == ly_symbol2scm ("slash"))
2053                         {
2054                         m->set_property ("diminished", SCM_BOOL_T);
2055                         }
2056                 else if ($2 == ly_symbol2scm ("exclamation"))
2057                         {
2058                         m->set_property ("no-continuation", SCM_BOOL_T);
2059                         }
2060         }
2061         ;
2062
2063
2064 figured_bass_modification:
2065         E_PLUS          {
2066                 $$ = ly_symbol2scm ("plus");
2067         }
2068         | E_EXCLAMATION {
2069                 $$ = ly_symbol2scm ("exclamation");
2070         }
2071         | '/'           {
2072                 $$ = ly_symbol2scm ("slash");
2073         }
2074         ;
2075
2076 br_bass_figure:
2077         bass_figure {
2078                 $$ = $1;
2079         }
2080         | '[' bass_figure {
2081                 $$ = $2;
2082                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2083         }
2084         ;
2085
2086 figure_list:
2087         /**/            {
2088                 $$ = SCM_EOL;
2089         }
2090         | figure_list br_bass_figure {
2091                 $$ = scm_cons ($2, $1);
2092         }
2093         ;
2094
2095 figure_spec:
2096         FIGURE_OPEN figure_list FIGURE_CLOSE {
2097                 Music *m = MY_MAKE_MUSIC ("EventChord");
2098                 $2 = scm_reverse_x ($2, SCM_EOL);
2099                 m->set_property ("elements", $2);
2100                 $$ = m->self_scm ();
2101         }
2102         ;
2103
2104
2105 optional_rest:
2106         /**/   { $$ = 0; }
2107         | REST { $$ = 1; }
2108         ;
2109
2110 simple_element:
2111         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2112                 if (!THIS->lexer_->is_note_state ())
2113                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2114
2115                 Music *n = 0;
2116                 if ($6)
2117                         n = MY_MAKE_MUSIC ("RestEvent");
2118                 else
2119                         n = MY_MAKE_MUSIC ("NoteEvent");
2120
2121                 n->set_property ("pitch", $1);
2122                 n->set_property ("duration", $5);
2123
2124                 if (scm_is_number ($4))
2125                 {
2126                         int q = scm_to_int ($4);
2127                         n->set_property ("absolute-octave", scm_from_int (q-1));
2128                 }
2129
2130                 if ($3 % 2)
2131                         n->set_property ("cautionary", SCM_BOOL_T);
2132                 if ($2 % 2 || $3 % 2)
2133                         n->set_property ("force-accidental", SCM_BOOL_T);
2134
2135                 Music *v = MY_MAKE_MUSIC ("EventChord");
2136                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2137                 n->unprotect ();
2138
2139                 v->set_spot (@$);
2140                 n->set_spot (@$);
2141                 $$ = v;
2142         }
2143         | DRUM_PITCH optional_notemode_duration {
2144                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2145                 n->set_property ("duration", $2);
2146                 n->set_property ("drum-type", $1);
2147
2148                 Music *v = MY_MAKE_MUSIC ("EventChord");
2149                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2150                 n->unprotect ();
2151                 v->set_spot (@$);
2152                 n->set_spot (@$);
2153                 $$ = v;
2154
2155         }
2156         | figure_spec optional_notemode_duration {
2157                 Music *m = unsmob_music ($1);
2158                 m->set_spot (@$);
2159                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2160                 {
2161                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2162                 }
2163                 $$ = m;
2164         }
2165         | RESTNAME optional_notemode_duration           {
2166                 Music *ev = 0;
2167                 if (ly_scm2string ($1) == "s") {
2168                         /* Space */
2169                         ev = MY_MAKE_MUSIC ("SkipEvent");
2170                   }
2171                 else {
2172                         ev = MY_MAKE_MUSIC ("RestEvent");
2173
2174                     }
2175                 ev->set_property ("duration", $2);
2176                 ev->set_spot (@$);
2177                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2178                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2179                 velt->set_spot (@$);
2180
2181                 ev->unprotect();
2182
2183                 $$ = velt;
2184         }
2185         | MULTI_MEASURE_REST optional_notemode_duration         {
2186                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2187                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2188                 $$ = unsmob_music (mus);
2189                 $$->protect ();
2190         }
2191
2192         | lyric_element optional_notemode_duration      {
2193                 if (!THIS->lexer_->is_lyric_state ())
2194                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2195
2196                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2197                 levent->set_property ("text", $1);
2198                 levent->set_property ("duration",$2);
2199                 levent->set_spot (@$);
2200                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2201                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2202
2203                 $$= velt;
2204         }
2205         | new_chord {
2206                 if (!THIS->lexer_->is_chord_state ())
2207                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2208                 $$ = unsmob_music ($1);
2209         }
2210         ;
2211
2212 lyric_element:
2213         lyric_markup {
2214                 $$ = $1;
2215         }
2216         | LYRICS_STRING {
2217                 $$ = $1;
2218         }
2219         ;
2220
2221 new_chord:
2222         steno_tonic_pitch optional_notemode_duration   {
2223                 $$ = make_chord ($1, $2, SCM_EOL);
2224         }
2225         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2226                 SCM its = scm_reverse_x ($4, SCM_EOL);
2227                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2228         }
2229         ;
2230
2231 chord_items:
2232         /**/ {
2233                 $$ = SCM_EOL;
2234         }
2235         | chord_items chord_item {
2236                 $$ = scm_cons ($2, $$);
2237         }
2238         ;
2239
2240 chord_separator:
2241         CHORD_COLON {
2242                 $$ = ly_symbol2scm ("chord-colon");
2243         }
2244         | CHORD_CARET {
2245                 $$ = ly_symbol2scm ("chord-caret");
2246         }
2247         | CHORD_SLASH steno_tonic_pitch {
2248                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2249         }
2250         | CHORD_BASS steno_tonic_pitch {
2251                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2252         }
2253         ;
2254
2255 chord_item:
2256         chord_separator {
2257                 $$ = $1;
2258         }
2259         | step_numbers {
2260                 $$ = scm_reverse_x ($1, SCM_EOL);
2261         }
2262         | CHORD_MODIFIER  {
2263                 $$ = $1;
2264         }
2265         ;
2266
2267 step_numbers:
2268         step_number { $$ = scm_cons ($1, SCM_EOL); }
2269         | step_numbers '.' step_number {
2270                 $$ = scm_cons ($3, $$);
2271         }
2272         ;
2273
2274 step_number:
2275         bare_unsigned {
2276                 $$ = make_chord_step ($1, 0);
2277         }
2278         | bare_unsigned '+' {
2279                 $$ = make_chord_step ($1, SHARP);
2280         }
2281         | bare_unsigned CHORD_MINUS {
2282                 $$ = make_chord_step ($1, FLAT);
2283         }
2284         ;
2285
2286 /*
2287         UTILITIES
2288
2289 TODO: should deprecate in favor of Scheme?
2290
2291  */
2292 number_expression:
2293         number_expression '+' number_term {
2294                 $$ = scm_sum ($1, $3);
2295         }
2296         | number_expression '-' number_term {
2297                 $$ = scm_difference ($1, $3);
2298         }
2299         | number_term
2300         ;
2301
2302 number_term:
2303         number_factor {
2304                 $$ = $1;
2305         }
2306         | number_factor '*' number_factor {
2307                 $$ = scm_product ($1, $3);
2308         }
2309         | number_factor '/' number_factor {
2310                 $$ = scm_divide ($1, $3);
2311         }
2312         ;
2313
2314 number_factor:
2315         '-'  number_factor { /* %prec UNARY_MINUS */
2316                 $$ = scm_difference ($2, SCM_UNDEFINED);
2317         }
2318         | bare_number
2319         ;
2320
2321
2322 bare_number:
2323         UNSIGNED        {
2324                 $$ = scm_from_int ($1);
2325         }
2326         | REAL          {
2327                 $$ = $1;
2328         }
2329         | NUMBER_IDENTIFIER             {
2330                 $$ = $1;
2331         }
2332         | REAL NUMBER_IDENTIFIER        {
2333                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2334         }
2335         | UNSIGNED NUMBER_IDENTIFIER    {
2336                 $$ = scm_from_double ($1 *scm_to_double ($2));
2337         }
2338         ;
2339
2340
2341 bare_unsigned:
2342         UNSIGNED {
2343                         $$ = $1;
2344         }
2345         | DIGIT {
2346                 $$ = $1;
2347         }
2348         ;
2349
2350 exclamations:
2351                 { $$ = 0; }
2352         | exclamations '!'      { $$ ++; }
2353         ;
2354
2355 questions:
2356                 { $$ = 0; }
2357         | questions '?' { $$ ++; }
2358         ;
2359
2360 /*
2361 This should be done more dynamically if possible.
2362 */
2363
2364 lyric_markup:
2365         LYRIC_MARKUP_IDENTIFIER {
2366                 $$ = $1;
2367         }
2368         | LYRIC_MARKUP
2369                 { THIS->lexer_->push_markup_state (); }
2370         markup_top {
2371                 $$ = $3;
2372                 THIS->lexer_->pop_state ();
2373         }
2374         ;
2375
2376 full_markup:
2377         MARKUP_IDENTIFIER {
2378                 $$ = $1;
2379         }
2380         | MARKUP
2381                 { THIS->lexer_->push_markup_state (); }
2382         markup_top {
2383                 $$ = $3;
2384                 THIS->lexer_->pop_state ();
2385         }
2386         ;
2387
2388 markup_top:
2389         markup_list {
2390                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2391         }
2392         | markup_head_1_list simple_markup      {
2393                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2394         }
2395         | simple_markup {
2396                 $$ = $1;
2397         }
2398         ;
2399
2400 markup_list:
2401         markup_composed_list {
2402                 $$ = $1;
2403         }
2404         | markup_braced_list {
2405                 $$ = $1;
2406         }
2407         ;
2408
2409 markup_composed_list:
2410         markup_head_1_list markup_braced_list {
2411                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2412
2413         }
2414         ;
2415
2416 markup_braced_list:
2417         '{' markup_braced_list_body '}' {
2418                 $$ = scm_reverse_x ($2, SCM_EOL);
2419         }
2420         ;
2421
2422 markup_braced_list_body:
2423         /* empty */     {  $$ = SCM_EOL; }
2424         | markup_braced_list_body markup {
2425                 $$ = scm_cons ($2, $1);
2426         }
2427         | markup_braced_list_body markup_list {
2428                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2429         }
2430         ;
2431
2432 markup_head_1_item:
2433         MARKUP_HEAD_MARKUP0     {
2434                 $$ = scm_list_1 ($1);
2435         }
2436         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2437                 $$ = scm_list_2 ($1, $2);
2438         }
2439         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2440                 $$ = scm_list_3 ($1, $2, $3);
2441         }
2442         ;
2443
2444 markup_head_1_list:
2445         markup_head_1_item      {
2446                 $$ = scm_list_1 ($1);
2447         }
2448         | markup_head_1_list markup_head_1_item {
2449                 $$ = scm_cons ($2, $1);
2450         }
2451         ;
2452
2453 simple_markup:
2454         STRING {
2455                 $$ = make_simple_markup ($1);
2456         }
2457         | MARKUP_IDENTIFIER {
2458                 $$ = $1;
2459         }
2460         | LYRIC_MARKUP_IDENTIFIER {
2461                 $$ = $1;
2462         }
2463         | STRING_IDENTIFIER {
2464                 $$ = $1;
2465         }
2466         | SCORE {
2467                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2468                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2469         } '{' score_body '}' {
2470                 Score * sc = $4;
2471                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2472                 sc->unprotect ();
2473                 THIS->lexer_->pop_state ();
2474         }
2475         | MARKUP_HEAD_SCM0 embedded_scm {
2476                 $$ = scm_list_2 ($1, $2);
2477         }
2478         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2479                 $$ = scm_list_4 ($1, $2, $3, $4);
2480         }
2481         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2482                 $$ = scm_list_3 ($1, $2, $3);
2483         }
2484         | MARKUP_HEAD_EMPTY {
2485                 $$ = scm_list_1 ($1);
2486         }
2487         | MARKUP_HEAD_LIST0 markup_list {
2488                 $$ = scm_list_2 ($1,$2);
2489         }
2490         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2491                 $$ = scm_list_3 ($1, $2, $3);
2492         }
2493         ;
2494
2495 markup:
2496         markup_head_1_list simple_markup        {
2497                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2498                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2499         }
2500         | simple_markup {
2501                 $$ = $1;
2502         }
2503         ;
2504
2505 %%
2506
2507 void
2508 Lily_parser::set_yydebug (bool )
2509 {
2510 #if 0
2511         yydebug = 1;
2512 #endif
2513 }
2514
2515 void
2516 Lily_parser::do_yyparse ()
2517 {
2518         yyparse ((void*)this);
2519 }
2520
2521
2522
2523
2524
2525 /*
2526
2527 It is a little strange to have this function in this file, but
2528 otherwise, we have to import music classes into the lexer.
2529
2530 */
2531 int
2532 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2533 {
2534         if (scm_is_string (sid)) {
2535                 *destination = sid;
2536                 return STRING_IDENTIFIER;
2537         } else if (unsmob_book (sid)) {
2538                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2539                 return BOOK_IDENTIFIER;
2540         } else if (scm_is_number (sid)) {
2541                 *destination = sid;
2542                 return NUMBER_IDENTIFIER;
2543         } else if (unsmob_context_def (sid)) {
2544                 *destination = unsmob_context_def (sid)->clone_scm ();
2545                 return CONTEXT_DEF_IDENTIFIER;
2546         } else if (unsmob_score (sid)) {
2547                 Score *score = new Score (*unsmob_score (sid));
2548                 *destination = score->self_scm ();
2549                 return SCORE_IDENTIFIER;
2550         } else if (Music *mus = unsmob_music (sid)) {
2551                 mus = mus->clone ();
2552                 *destination = mus->self_scm ();
2553                 unsmob_music (*destination)->
2554                         set_property ("origin", make_input (last_input_));
2555
2556                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2557                         != SCM_BOOL_F;
2558
2559                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2560         } else if (unsmob_duration (sid)) {
2561                 *destination = unsmob_duration (sid)->smobbed_copy ();
2562                 return DURATION_IDENTIFIER;
2563         } else if (unsmob_output_def (sid)) {
2564                 Output_def *p = unsmob_output_def (sid);
2565                 p = p->clone ();
2566
2567                 *destination = p->self_scm ();
2568                 return OUTPUT_DEF_IDENTIFIER;
2569         } else if (Text_interface::is_markup (sid)) {
2570                 *destination = sid;
2571                 if (is_lyric_state ())
2572                         return LYRIC_MARKUP_IDENTIFIER;
2573                 return MARKUP_IDENTIFIER;
2574         }
2575
2576         return -1;
2577 }
2578
2579 Music *
2580 property_op_to_music (SCM op)
2581 {
2582         Music *m = 0;
2583         SCM tag = scm_car (op);
2584         SCM symbol = scm_cadr (op);
2585         SCM args = scm_cddr (op);
2586         SCM grob_val = SCM_UNDEFINED;
2587         SCM grob_path = SCM_UNDEFINED;
2588         SCM val = SCM_UNDEFINED;
2589
2590         if (tag == ly_symbol2scm ("assign"))
2591                 {
2592                 m = MY_MAKE_MUSIC ("PropertySet");
2593                 val = scm_car (args);
2594                 }
2595         else if (tag == ly_symbol2scm ("unset"))
2596                 m = MY_MAKE_MUSIC ("PropertyUnset");
2597         else if (tag == ly_symbol2scm ("push"))
2598                 {
2599                 m = MY_MAKE_MUSIC ("OverrideProperty");
2600                 grob_val = scm_car (args);
2601                 grob_path = scm_cdr (args);
2602                 m->set_property ("pop-first", SCM_BOOL_T);
2603                 }
2604         else if (tag == ly_symbol2scm ("pop")) {
2605                 m = MY_MAKE_MUSIC ("RevertProperty");
2606                 grob_path = args;
2607                 }
2608
2609         m->set_property ("symbol", symbol);
2610
2611         if (val != SCM_UNDEFINED)
2612                 m->set_property ("value", val);
2613         if (grob_val != SCM_UNDEFINED)
2614                 m->set_property ("grob-value", grob_val);
2615         if (grob_path != SCM_UNDEFINED)
2616                 m->set_property ("grob-property-path", grob_path);
2617
2618         return m;
2619 }
2620
2621 Music*
2622 context_spec_music (SCM type, SCM id, Music *m, SCM ops, bool create_new)
2623 {
2624         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2625
2626         csm->set_property ("element", m->self_scm ());
2627         m->unprotect ();
2628
2629         csm->set_property ("context-type",
2630                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2631         csm->set_property ("property-operations", ops);
2632         if (create_new)
2633                 csm->set_property ("create-new", SCM_BOOL_T);
2634
2635         if (scm_is_string (id))
2636                 csm->set_property ("context-id", id);
2637         return csm;
2638 }
2639
2640 SCM
2641 get_next_unique_context_id ()
2642 {
2643         return scm_makfrom0str ("$uniqueContextId");
2644 }
2645
2646
2647 SCM
2648 get_next_unique_lyrics_context_id ()
2649 {
2650         static int new_context_count;
2651         char s[128];
2652         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2653         return scm_makfrom0str (s);
2654 }
2655
2656
2657 Music *
2658 run_music_function (Lily_parser *parser, SCM expr)
2659 {
2660         SCM func = scm_car (expr);
2661         Input *loc = unsmob_input (scm_cadr (expr));
2662         SCM args = scm_cddr (expr);
2663         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2664
2665         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2666         bool ok  = true;
2667
2668         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2669         {
2670                 parser->error_level_ = 1;
2671                 ok = false;
2672         }
2673
2674         SCM m = SCM_EOL;
2675         if (ok)
2676                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2677                                                  scm_cdr (expr)));
2678
2679
2680         Music* retval = 0;
2681         if (unsmob_music (m))
2682                 {
2683                 retval = unsmob_music (m);
2684                 retval->protect ();
2685                 }
2686         else
2687                 {
2688                 if (ok)
2689                         loc->error (_ ("music head function must return Music object"));
2690                 retval = MY_MAKE_MUSIC ("Music");
2691                 }
2692         retval->set_spot (*loc);
2693         return retval;
2694 }
2695
2696 bool
2697 is_regular_identifier (SCM id)
2698 {
2699   string str = ly_scm2string (id);
2700   char const *s = str.c_str ();
2701
2702   bool v = true;
2703 #if 0
2704   isalpha (*s);
2705   s++;
2706 #endif
2707   while (*s && v)
2708    {
2709         v = v && isalnum (*s);
2710         s++;
2711    }
2712   return v;
2713 }
2714
2715
2716 SCM
2717 get_first_context_id (SCM type, Music *m)
2718 {
2719         SCM id = m->get_property ("context-id");
2720         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2721             && scm_is_string (m->get_property ("context-id"))
2722             && scm_c_string_length (id) > 0)
2723         {
2724                 return id;
2725         }
2726         return SCM_EOL;
2727 }
2728
2729 SCM
2730 make_simple_markup (SCM a)
2731 {
2732         return a;
2733 }
2734
2735 bool
2736 is_duration (int t)
2737 {
2738   return t && t == 1 << intlog2 (t);
2739 }
2740
2741 void
2742 set_music_properties (Music *p, SCM a)
2743 {
2744   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2745         p->internal_set_property (scm_caar (k), scm_cdar (k));
2746 }
2747
2748
2749 SCM
2750 make_chord_step (int step, int alter)
2751 {
2752         if (step == 7)
2753                 alter += FLAT;
2754
2755         while (step < 0)
2756                 step += 7;
2757         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2758         return m.smobbed_copy ();
2759 }
2760
2761
2762 SCM
2763 make_chord (SCM pitch, SCM dur, SCM modification_list)
2764 {
2765         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2766         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2767
2768         unsmob_music (ch)->protect();
2769         return ch;
2770 }
2771
2772
2773 /* Todo: actually also use apply iso. call too ...  */
2774 bool
2775 ly_input_procedure_p (SCM x)
2776 {
2777         return ly_is_procedure (x)
2778                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2779 }
2780
2781 Music*
2782 set_property_music (SCM sym, SCM value)
2783 {
2784         Music *p = MY_MAKE_MUSIC ("PropertySet");
2785         p->set_property ("symbol", sym);
2786         p->set_property ("value", value);
2787         return p;
2788 }
2789
2790 Music*
2791 make_music_relative (Pitch start, Music *music)
2792 {
2793         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2794         relative->set_property ("element", music->self_scm ());
2795
2796         Pitch last = music->to_relative_octave (start);
2797         if (lily_1_8_relative)
2798                 music->set_property ("last-pitch", last.smobbed_copy ());
2799         return relative;
2800 }
2801
2802 Music *
2803 make_lyric_combine_music (SCM name, Music *music)
2804 {
2805         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2806         combine->set_property ("element", music->self_scm ());
2807         combine->set_property ("associated-context", name);
2808         return combine;
2809 }
2810
2811
2812 int
2813 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2814 {
2815         Lily_parser *pars = (Lily_parser*) v;
2816         Lily_lexer *lex = pars->lexer_;
2817
2818         lex->lexval = (void*) s;
2819         lex->lexloc = loc;
2820         lex->prepare_for_next_token ();
2821         return lex->yylex ();
2822 }