lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 char *p = scm_to_locale_string                          \
  45                         (scm_simple_format (SCM_BOOL_F,                 \
  46                                             scm_from_locale_string ("~S"), \
  47                                             scm_list_1 (value)));       \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83  /* ADDLYRICS needs to have lower precedence than argument scanning,
  84   * or we won't be able to tell music apart from closed_music without
  85   * lookahead in the context of function calls.
  86   */
  87
  88 %nonassoc DEFAULT
  89
  90  /* \default is only applied after exhausting function arguments */
  91
  92 %nonassoc FUNCTION_ARGLIST
  93
  94  /* expressions with units are permitted into argument lists */
  95
  96 %right PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  97       UNSIGNED REAL DURATION_IDENTIFIER ':'
  98
  99  /* The above are the symbols that can start optional function arguments
 100     that are recognized in the grammar rather than by predicate
 101  */
 102
 103 %nonassoc NUMBER_IDENTIFIER '/'
 104
 105  /* Number-unit expressions, where permitted, are concatenated into
 106   * function arguments, just like fractions and tremoli.  Tremoli must
 107   * not have higher precedence than UNSIGNED, or Lilypond will not
 108   * join ':' with a following optional number.
 109   */
 110
 111 %left PREC_TOP
 112
 113
 114
 115
 116 %pure-parser
 117 %locations
 118
 119
 120
 121 %{ // -*-Fundamental-*-
 122
 123 /*
 124 FIXME:
 125
 126    * The rules for who is protecting what are very shady.  Uniformise
 127      this.
 128
 129    * There are too many lexical modes?
 130 */
 131
 132 #include "config.hh"
 133
 134 #include <cctype>
 135 #include <cstdlib>
 136 #include <cstdio>
 137 using namespace std;
 138
 139 #include "book.hh"
 140 #include "context-def.hh"
 141 #include "context-mod.hh"
 142 #include "dimensions.hh"
 143 #include "file-path.hh"
 144 #include "input.hh"
 145 #include "international.hh"
 146 #include "lily-guile.hh"
 147 #include "lily-lexer.hh"
 148 #include "lily-parser.hh"
 149 #include "main.hh"
 150 #include "misc.hh"
 151 #include "music.hh"
 152 #include "output-def.hh"
 153 #include "paper-book.hh"
 154 #include "scm-hash.hh"
 155 #include "score.hh"
 156 #include "text-interface.hh"
 157 #include "warn.hh"
 158
 159 void
 160 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, string s)
 161 {
 162         parser->parser_error (*i, s);
 163 }
 164
 165 #define MYBACKUP(Token, Value, Location)                                \
 166 do                                                                      \
 167         if (yychar == YYEMPTY)                                          \
 168         {                                                               \
 169                 if (Token)                                              \
 170                         parser->lexer_->push_extra_token (Token, Value); \
 171                 parser->lexer_->push_extra_token (BACKUP);              \
 172         } else {                                                        \
 173                 parser->parser_error                                    \
 174                         (Location, _("Too much lookahead"));            \
 175         }                                                               \
 176 while (0)
 177
 178
 179 #define MYREPARSE(Location, Pred, Token, Value)                         \
 180 do                                                                      \
 181         if (yychar == YYEMPTY)                                          \
 182         {                                                               \
 183                 parser->lexer_->push_extra_token (Token, Value);        \
 184                 parser->lexer_->push_extra_token (REPARSE,              \
 185                                                   Pred);                \
 186         } else {                                                        \
 187                 parser->parser_error                                    \
 188                         (Location, _("Too much lookahead"));            \
 189         }                                                               \
 190 while (0)
 191
 192 %}
 193
 194
 195 %{
 196
 197 #define MY_MAKE_MUSIC(x, spot) \
 198         make_music_with_input (ly_symbol2scm (x), \
 199                                parser->lexer_->override_input (spot))
 200
 201 /* ES TODO:
 202 - Don't use lily module, create a new module instead.
 203 - delay application of the function
 204 */
 205 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 206   scm_apply_0 (proc, args)
 207 /* Syntactic Sugar. */
 208 #define MAKE_SYNTAX(name, location, ...)                                \
 209         LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), make_input (parser->lexer_->override_input (location)), ##__VA_ARGS__, SCM_UNDEFINED))
 210 #define START_MAKE_SYNTAX(name, ...)                                    \
 211         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 212 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 213         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), make_input (parser->lexer_->override_input (location)), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 214
 215 SCM get_next_unique_context_id ();
 216 SCM get_next_unique_lyrics_context_id ();
 217
 218 #undef _
 219 #if !HAVE_GETTEXT
 220 #define _(x) x
 221 #else
 222 #include <libintl.h>
 223 #define _(x) gettext (x)
 224 #endif
 225
 226
 227 static Music *make_music_with_input (SCM name, Input where);
 228 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 229                       SCM arg, SCM args, SCM pred, SCM disp = SCM_UNDEFINED);
 230 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 231 SCM loc_on_music (Input loc, SCM arg);
 232 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 233 SCM make_chord_step (SCM step, Rational alter);
 234 SCM make_simple_markup (SCM a);
 235 bool is_duration (int t);
 236 bool is_regular_identifier (SCM id, bool multiple=false);
 237 SCM try_string_variants (SCM pred, SCM str);
 238 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 239
 240 %}
 241
 242 /* The third option is an alias that will be used to display the
 243    syntax error.  Bison CVS now correctly handles backslash escapes.
 244
 245    FIXME: Bison needs to translate some of these, eg, STRING.
 246
 247 */
 248
 249 /* Keyword tokens with plain escaped name.  */
 250 %token END_OF_FILE 0 "end of input"
 251 %token ACCEPTS "\\accepts"
 252 %token ADDLYRICS "\\addlyrics"
 253 %token ALIAS "\\alias"
 254 %token ALTERNATIVE "\\alternative"
 255 %token BOOK "\\book"
 256 %token BOOKPART "\\bookpart"
 257 %token CHANGE "\\change"
 258 %token CHORDMODE "\\chordmode"
 259 %token CHORDS "\\chords"
 260 %token CONSISTS "\\consists"
 261 %token CONTEXT "\\context"
 262 %token DEFAULT "\\default"
 263 %token DEFAULTCHILD "\\defaultchild"
 264 %token DENIES "\\denies"
 265 %token DESCRIPTION "\\description"
 266 %token DRUMMODE "\\drummode"
 267 %token DRUMS "\\drums"
 268 %token FIGUREMODE "\\figuremode"
 269 %token FIGURES "\\figures"
 270 %token HEADER "\\header"
 271 %token INVALID "\\version-error"
 272 %token LAYOUT "\\layout"
 273 %token LYRICMODE "\\lyricmode"
 274 %token LYRICS "\\lyrics"
 275 %token LYRICSTO "\\lyricsto"
 276 %token MARKUP "\\markup"
 277 %token MARKUPLIST "\\markuplist"
 278 %token MIDI "\\midi"
 279 %token NAME "\\name"
 280 %token NOTEMODE "\\notemode"
 281 %token OVERRIDE "\\override"
 282 %token PAPER "\\paper"
 283 %token REMOVE "\\remove"
 284 %token REPEAT "\\repeat"
 285 %token REST "\\rest"
 286 %token REVERT "\\revert"
 287 %token SCORE "\\score"
 288 %token SEQUENTIAL "\\sequential"
 289 %token SET "\\set"
 290 %token SIMULTANEOUS "\\simultaneous"
 291 %token TEMPO "\\tempo"
 292 %token TYPE "\\type"
 293 %token UNSET "\\unset"
 294 %token WITH "\\with"
 295
 296 /* Keyword token exceptions.  */
 297 %token NEWCONTEXT "\\new"
 298
 299
 300 /* Other string tokens.  */
 301
 302 %token CHORD_BASS "/+"
 303 %token CHORD_CARET "^"
 304 %token CHORD_COLON ":"
 305 %token CHORD_MINUS "-"
 306 %token CHORD_SLASH "/"
 307 %token ANGLE_OPEN "<"
 308 %token ANGLE_CLOSE ">"
 309 %token DOUBLE_ANGLE_OPEN "<<"
 310 %token DOUBLE_ANGLE_CLOSE ">>"
 311 %token E_BACKSLASH "\\"
 312 %token E_EXCLAMATION "\\!"
 313 %token E_PLUS "\\+"
 314 %token EXTENDER "__"
 315
 316 /*
 317 If we give names, Bison complains.
 318 */
 319 %token FIGURE_CLOSE /* "\\>" */
 320 %token FIGURE_OPEN /* "\\<" */
 321 %token FIGURE_SPACE "_"
 322 %token HYPHEN "--"
 323
 324 %token CHORDMODIFIERS
 325 %token MULTI_MEASURE_REST
 326
 327
 328 %token E_UNSIGNED
 329 %token UNSIGNED
 330
 331 /* Artificial tokens, for more generic function syntax */
 332 %token EXPECT_MARKUP "markup?"
 333 %token EXPECT_PITCH "ly:pitch?"
 334 %token EXPECT_DURATION "ly:duration?"
 335 %token EXPECT_SCM "scheme?"
 336 %token BACKUP "(backed-up?)"
 337 %token REPARSE "(reparsed?)"
 338 %token EXPECT_MARKUP_LIST "markup-list?"
 339 %token EXPECT_OPTIONAL "optional?"
 340 /* After the last argument. */
 341 %token EXPECT_NO_MORE_ARGS;
 342
 343 /* An artificial token for parsing embedded Lilypond */
 344 %token EMBEDDED_LILY "#{"
 345
 346 %token BOOK_IDENTIFIER
 347 %token CHORDMODIFIER_PITCH
 348 %token CHORD_MODIFIER
 349 %token CHORD_REPETITION
 350 %token CONTEXT_DEF_IDENTIFIER
 351 %token CONTEXT_MOD_IDENTIFIER
 352 %token DRUM_PITCH
 353 %token PITCH_IDENTIFIER
 354 %token DURATION_IDENTIFIER
 355 %token EVENT_IDENTIFIER
 356 %token EVENT_FUNCTION
 357 %token FRACTION
 358 %token LYRIC_ELEMENT
 359 %token MARKUP_FUNCTION
 360 %token MARKUP_LIST_FUNCTION
 361 %token MARKUP_IDENTIFIER
 362 %token MARKUPLIST_IDENTIFIER
 363 %token MUSIC_FUNCTION
 364 %token MUSIC_IDENTIFIER
 365 %token NOTENAME_PITCH
 366 %token NUMBER_IDENTIFIER
 367 %token OUTPUT_DEF_IDENTIFIER
 368 %token REAL
 369 %token RESTNAME
 370 %token SCM_ARG
 371 %token SCM_FUNCTION
 372 %token SCM_IDENTIFIER
 373 %token SCM_TOKEN
 374 %token STRING
 375 %token SYMBOL_LIST
 376 %token TONICNAME_PITCH
 377
 378 %left '-' '+'
 379
 380 /* We don't assign precedence to / and *, because we might need varied
 381 prec levels in different prods */
 382
 383 %left UNARY_MINUS
 384
 385 %%
 386
 387 start_symbol:
 388         lilypond
 389         | EMBEDDED_LILY {
 390                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 391                 parser->lexer_->push_note_state (nn);
 392         } embedded_lilypond {
 393                 parser->lexer_->pop_state ();
 394                 *retval = $3;
 395         }
 396         ;
 397
 398 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 399         | lilypond toplevel_expression {
 400         }
 401         | lilypond assignment {
 402         }
 403         | lilypond error {
 404                 parser->error_level_ = 1;
 405         }
 406         | lilypond INVALID      {
 407                 parser->error_level_ = 1;
 408         }
 409         ;
 410
 411
 412 toplevel_expression:
 413         {
 414                 parser->lexer_->add_scope (get_header (parser));
 415         } lilypond_header {
 416                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 417         }
 418         | book_block {
 419                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 420                 scm_call_2 (proc, parser->self_scm (), $1);
 421         }
 422         | bookpart_block {
 423                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 424                 scm_call_2 (proc, parser->self_scm (), $1);
 425         }
 426         | score_block {
 427                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 428                 scm_call_2 (proc, parser->self_scm (), $1);
 429         }
 430         | composite_music {
 431                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 432                 scm_call_2 (proc, parser->self_scm (), $1);
 433         }
 434         | full_markup {
 435                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 436                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 437         }
 438         | full_markup_list {
 439                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 440                 scm_call_2 (proc, parser->self_scm (), $1);
 441         }
 442         | SCM_TOKEN {
 443                 // Evaluate and ignore #xxx, as opposed to \xxx
 444                 parser->lexer_->eval_scm_token ($1);
 445         }
 446         | embedded_scm_active
 447         {
 448                 SCM out = SCM_UNDEFINED;
 449                 if (Text_interface::is_markup ($1))
 450                         out = scm_list_1 ($1);
 451                 else if (Text_interface::is_markup_list ($1))
 452                         out = $1;
 453                 if (scm_is_pair (out))
 454                 {
 455                         SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 456                         scm_call_2 (proc, parser->self_scm (), out);
 457                 } else if (!scm_is_eq ($1, SCM_UNSPECIFIED))
 458                         parser->parser_error (@1, _("bad expression type"));
 459         }
 460         | output_def {
 461                 SCM id = SCM_EOL;
 462                 Output_def * od = unsmob_output_def ($1);
 463
 464                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 465                         id = ly_symbol2scm ("$defaultpaper");
 466                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 467                         id = ly_symbol2scm ("$defaultmidi");
 468                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 469                         id = ly_symbol2scm ("$defaultlayout");
 470
 471                 parser->lexer_->set_identifier (id, $1);
 472         }
 473         ;
 474
 475 embedded_scm_bare:
 476         SCM_TOKEN
 477         {
 478                 $$ = parser->lexer_->eval_scm_token ($1);
 479         }
 480         | SCM_IDENTIFIER
 481         ;
 482
 483 embedded_scm_active:
 484         SCM_IDENTIFIER
 485         | scm_function_call
 486         ;
 487
 488 embedded_scm_bare_arg:
 489         SCM_ARG
 490         | SCM_TOKEN
 491         {
 492                 $$ = parser->lexer_->eval_scm_token ($1);
 493         }
 494         | full_markup_list
 495         | context_modification
 496         | score_block
 497         | context_def_spec_block
 498         | book_block
 499         | bookpart_block
 500         | output_def
 501         ;
 502
 503 /* The generic version may end in music, or not */
 504
 505 embedded_scm:
 506         embedded_scm_bare
 507         | scm_function_call
 508         ;
 509
 510 embedded_scm_arg:
 511         embedded_scm_bare_arg
 512         | scm_function_call
 513         | music_arg
 514         ;
 515
 516 scm_function_call:
 517         SCM_FUNCTION function_arglist {
 518                 $$ = MAKE_SYNTAX ("music-function", @$,
 519                                          $1, $2);
 520         }
 521         ;
 522
 523 embedded_lilypond:
 524         /* empty */
 525         {
 526                 $$ = MAKE_SYNTAX ("void-music", @$);
 527         }
 528         | identifier_init
 529         | music_embedded music_embedded music_list {
 530                 $3 = scm_reverse_x ($3, SCM_EOL);
 531                 if (unsmob_music ($2))
 532                         $3 = scm_cons ($2, $3);
 533                 if (unsmob_music ($1))
 534                         $3 = scm_cons ($1, $3);
 535                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 536         }
 537         | error {
 538                 parser->error_level_ = 1;
 539                 $$ = SCM_UNSPECIFIED;
 540         }
 541         | INVALID embedded_lilypond {
 542                 parser->error_level_ = 1;
 543                 $$ = $2;
 544         }
 545         ;
 546
 547
 548 lilypond_header_body:
 549         /* empty */ { $$ = SCM_UNSPECIFIED; }
 550         | lilypond_header_body assignment  {
 551
 552         }
 553         | lilypond_header_body embedded_scm  {
 554
 555         }
 556         ;
 557
 558 lilypond_header:
 559         HEADER '{' lilypond_header_body '}'     {
 560                 $$ = parser->lexer_->remove_scope ();
 561         }
 562         ;
 563
 564 /*
 565         DECLARATIONS
 566 */
 567 assignment_id:
 568         STRING          { $$ = $1; }
 569         ;
 570
 571 assignment:
 572         assignment_id '=' identifier_init  {
 573                 parser->lexer_->set_identifier ($1, $3);
 574                 $$ = SCM_UNSPECIFIED;
 575         }
 576         | assignment_id property_path '=' identifier_init {
 577                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 578                 parser->lexer_->set_identifier (path, $4);
 579                 $$ = SCM_UNSPECIFIED;
 580         }
 581         ;
 582
 583
 584 identifier_init:
 585         score_block
 586         | book_block
 587         | bookpart_block
 588         | output_def
 589         | context_def_spec_block
 590         | music_assign
 591         | post_event_nofinger post_events
 592         {
 593                 $$ = scm_reverse_x ($2, SCM_EOL);
 594                 if (Music *m = unsmob_music ($1))
 595                 {
 596                         if (m->is_mus_type ("post-event-wrapper"))
 597                                 $$ = scm_append
 598                                         (scm_list_2 (m->get_property ("elements"),
 599                                                      $$));
 600                         else
 601                                 $$ = scm_cons ($1, $$);
 602                 }
 603                 if (scm_is_pair ($$)
 604                     && scm_is_null (scm_cdr ($$)))
 605                         $$ = scm_car ($$);
 606                 else
 607                 {
 608                         Music * m = MY_MAKE_MUSIC ("PostEvents", @$);
 609                         m->set_property ("elements", $$);
 610                         $$ = m->unprotect ();
 611                 }
 612         }
 613         | number_expression
 614         | FRACTION
 615         | string
 616         | embedded_scm
 617         | full_markup_list
 618         | context_modification
 619         ;
 620
 621 context_def_spec_block:
 622         CONTEXT '{' context_def_spec_body '}'
 623                 {
 624                 $$ = $3;
 625         }
 626         ;
 627
 628 context_mod_arg:
 629         embedded_scm
 630         | composite_music
 631         ;
 632
 633 context_mod_embedded:
 634         context_mod_arg
 635         {
 636                 if (unsmob_music ($1)) {
 637                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 638                         $1 = scm_call_2 (proc, parser->self_scm (), $1);
 639                 }
 640                 if (unsmob_context_mod ($1))
 641                         $$ = $1;
 642                 else {
 643                         parser->parser_error (@1, _ ("not a context mod"));
 644                 }
 645         }
 646         ;
 647
 648
 649 context_def_spec_body:
 650         /**/ {
 651                 $$ = Context_def::make_scm ();
 652                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 653         }
 654         | CONTEXT_DEF_IDENTIFIER {
 655                 $$ = $1;
 656                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 657         }
 658         | context_def_spec_body context_mod {
 659                 if (!SCM_UNBNDP ($2))
 660                         unsmob_context_def ($$)->add_context_mod ($2);
 661         }
 662         | context_def_spec_body context_modification {
 663                 Context_def *td = unsmob_context_def ($$);
 664                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 665                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 666                     td->add_context_mod (scm_car (m));
 667                 }
 668         }
 669         | context_def_spec_body context_mod_embedded {
 670                 Context_def *td = unsmob_context_def ($$);
 671                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 672                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 673                     td->add_context_mod (scm_car (m));
 674                 }
 675         }
 676         ;
 677
 678
 679
 680 book_block:
 681         BOOK '{' book_body '}'  {
 682                 $$ = $3;
 683                 pop_paper (parser);
 684                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 685         }
 686         ;
 687
 688 /* FIXME:
 689    * Use 'handlers' like for toplevel-* stuff?
 690    * grok \layout and \midi?  */
 691 book_body:
 692         {
 693                 Book *book = new Book;
 694                 init_papers (parser);
 695                 book->origin ()->set_spot (@$);
 696                 book->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 697                 book->paper_->unprotect ();
 698                 push_paper (parser, book->paper_);
 699                 book->header_ = get_header (parser);
 700                 $$ = book->unprotect ();
 701                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 702         }
 703         | BOOK_IDENTIFIER {
 704                 unsmob_book ($1)->origin ()->set_spot (@$);
 705                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 706         }
 707         | book_body paper_block {
 708                 unsmob_book ($1)->paper_ = unsmob_output_def ($2);
 709                 set_paper (parser, unsmob_output_def ($2));
 710         }
 711         | book_body bookpart_block {
 712                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 713                 scm_call_2 (proc, $1, $2);
 714         }
 715         | book_body score_block {
 716                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 717                 scm_call_2 (proc, $1, $2);
 718         }
 719         | book_body composite_music {
 720                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 721                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 722         }
 723         | book_body full_markup {
 724                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 725                 scm_call_2 (proc, $1, scm_list_1 ($2));
 726         }
 727         | book_body full_markup_list {
 728                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 729                 scm_call_2 (proc, $1, $2);
 730         }
 731         | book_body SCM_TOKEN {
 732                 // Evaluate and ignore #xxx, as opposed to \xxx
 733                 parser->lexer_->eval_scm_token ($2);
 734         }
 735         | book_body embedded_scm_active
 736         {
 737                 SCM out = SCM_UNDEFINED;
 738                 if (Text_interface::is_markup ($2))
 739                         out = scm_list_1 ($2);
 740                 else if (Text_interface::is_markup_list ($2))
 741                         out = $2;
 742                 if (scm_is_pair (out))
 743                 {
 744                         SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 745                         scm_call_2 (proc, $1, out);
 746                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 747                         parser->parser_error (@2, _("bad expression type"));
 748         }
 749         | book_body
 750         {
 751                 parser->lexer_->add_scope (unsmob_book ($1)->header_);
 752         } lilypond_header
 753         | book_body error {
 754                 Book *book = unsmob_book ($1);
 755                 book->paper_ = 0;
 756                 book->scores_ = SCM_EOL;
 757                 book->bookparts_ = SCM_EOL;
 758         }
 759         ;
 760
 761 bookpart_block:
 762         BOOKPART '{' bookpart_body '}' {
 763                 $$ = $3;
 764                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 765         }
 766         ;
 767
 768 bookpart_body:
 769         {
 770                 Book *book = new Book;
 771                 book->origin ()->set_spot (@$);
 772                 $$ = book->unprotect ();
 773                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 774         }
 775         | BOOK_IDENTIFIER {
 776                 unsmob_book ($1)->origin ()->set_spot (@$);
 777                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 778         }
 779         | bookpart_body paper_block {
 780                 unsmob_book ($$)->paper_ = unsmob_output_def ($2);
 781         }
 782         | bookpart_body score_block {
 783                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 784                 scm_call_2 (proc, $1, $2);
 785         }
 786         | bookpart_body composite_music {
 787                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 788                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 789         }
 790         | bookpart_body full_markup {
 791                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 792                 scm_call_2 (proc, $1, scm_list_1 ($2));
 793         }
 794         | bookpart_body full_markup_list {
 795                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 796                 scm_call_2 (proc, $1, $2);
 797         }
 798         | bookpart_body SCM_TOKEN {
 799                 // Evaluate and ignore #xxx, as opposed to \xxx
 800                 parser->lexer_->eval_scm_token ($2);
 801         }
 802         | bookpart_body embedded_scm_active
 803         {
 804                 SCM out = SCM_UNDEFINED;
 805                 if (Text_interface::is_markup ($2))
 806                         out = scm_list_1 ($2);
 807                 else if (Text_interface::is_markup_list ($2))
 808                         out = $2;
 809                 if (scm_is_pair (out))
 810                 {
 811                         SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 812                         scm_call_2 (proc, $1, out);
 813                 } else if (!scm_is_eq ($2, SCM_UNSPECIFIED))
 814                         parser->parser_error (@2, _("bad expression type"));
 815         }
 816         | bookpart_body
 817         {
 818                 Book *book = unsmob_book ($1);
 819                 if (!ly_is_module (book->header_))
 820                         book->header_ = ly_make_module (false);
 821                 parser->lexer_->add_scope (book->header_);
 822         } lilypond_header
 823         | bookpart_body error {
 824                 Book *book = unsmob_book ($1);
 825                 book->paper_ = 0;
 826                 book->scores_ = SCM_EOL;
 827         }
 828         ;
 829
 830 score_block:
 831         SCORE '{' score_body '}'        {
 832                 $$ = $3;
 833         }
 834         ;
 835
 836 score_body:
 837         music {
 838                 SCM scorify = ly_lily_module_constant ("scorify-music");
 839                 $$ = scm_call_2 (scorify, $1, parser->self_scm ());
 840
 841                 unsmob_score ($$)->origin ()->set_spot (@$);
 842         }
 843         | embedded_scm_active {
 844                 Score *score;
 845                 if (unsmob_score ($1))
 846                         score = new Score (*unsmob_score ($1));
 847                 else {
 848                         score = new Score;
 849                         parser->parser_error (@1, _("score expected"));
 850                 }
 851                 unsmob_score ($$)->origin ()->set_spot (@$);
 852                 $$ = score->unprotect ();
 853         }
 854         | score_body
 855         {
 856                 Score *score = unsmob_score ($1);
 857                 if (!ly_is_module (score->get_header ()))
 858                         score->set_header (ly_make_module (false));
 859                 parser->lexer_->add_scope (score->get_header ());
 860         } lilypond_header
 861         | score_body output_def {
 862                 Output_def *od = unsmob_output_def ($2);
 863                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 864                 {
 865                         parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 866
 867                 }
 868                 else
 869                 {
 870                         unsmob_score ($1)->add_output_def (od);
 871                 }
 872         }
 873         | score_body error {
 874                 unsmob_score ($$)->error_found_ = true;
 875         }
 876         ;
 877
 878
 879 /*
 880         OUTPUT DEF
 881 */
 882
 883 paper_block:
 884         output_def {
 885                 Output_def *od = unsmob_output_def ($1);
 886
 887                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 888                 {
 889                         parser->parser_error (@1, _ ("need \\paper for paper block"));
 890                         $$ = get_paper (parser)->unprotect ();
 891                 }
 892         }
 893         ;
 894
 895
 896 output_def:
 897         output_def_body '}' {
 898                 $$ = $1;
 899
 900                 parser->lexer_->remove_scope ();
 901                 parser->lexer_->pop_state ();
 902         }
 903         ;
 904
 905 output_def_head:
 906         PAPER {
 907                 Output_def *p = get_paper (parser);
 908                 p->input_origin_ = @$;
 909                 parser->lexer_->add_scope (p->scope_);
 910                 $$ = p->unprotect ();
 911         }
 912         | MIDI    {
 913                 Output_def *p = get_midi (parser);
 914                 $$ = p->unprotect ();
 915                 parser->lexer_->add_scope (p->scope_);
 916         }
 917         | LAYOUT        {
 918                 Output_def *p = get_layout (parser);
 919
 920                 parser->lexer_->add_scope (p->scope_);
 921                 $$ = p->unprotect ();
 922         }
 923         ;
 924
 925 output_def_head_with_mode_switch:
 926         output_def_head {
 927                 parser->lexer_->push_initial_state ();
 928                 $$ = $1;
 929         }
 930         ;
 931
 932 // We need this weird nonterminal because both music as well as a
 933 // context definition can start with \context and the difference is
 934 // only apparent after looking at the next token.  If it is '{', there
 935 // is still time to escape from notes mode.
 936
 937 music_or_context_def:
 938         music_arg
 939         {
 940                 parser->lexer_->pop_state ();
 941         }
 942         | CONTEXT
 943         {
 944                 parser->lexer_->pop_state ();
 945         } '{' context_def_spec_body '}'
 946         {
 947                 $$ = $4;
 948         }
 949         ;
 950
 951 output_def_body:
 952         output_def_head_with_mode_switch '{' {
 953                 $$ = $1;
 954                 unsmob_output_def ($$)->input_origin_.set_spot (@$);
 955         }
 956         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 957                 Output_def *o = unsmob_output_def ($3);
 958                 o->input_origin_.set_spot (@$);
 959                 $$ = o->self_scm ();
 960                 parser->lexer_->remove_scope ();
 961                 parser->lexer_->add_scope (o->scope_);
 962         }
 963         | output_def_body assignment  {
 964
 965         }
 966         | output_def_body embedded_scm  {
 967
 968         }
 969         | output_def_body
 970         {
 971                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 972                 parser->lexer_->push_note_state (nn);
 973         } music_or_context_def
 974         {
 975                 if (unsmob_context_def ($3))
 976                         assign_context_def (unsmob_output_def ($1), $3);
 977                 else {
 978
 979                         SCM proc = parser->lexer_->lookup_identifier
 980                                      ("output-def-music-handler");
 981                         scm_call_3 (proc, parser->self_scm (),
 982                                     $1, $3);
 983                 }
 984         }
 985         | output_def_body error {
 986
 987         }
 988         ;
 989
 990 tempo_event:
 991         TEMPO steno_duration '=' tempo_range    {
 992                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
 993         }
 994         | TEMPO scalar_closed steno_duration '=' tempo_range    {
 995                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
 996         }
 997         | TEMPO scalar {
 998                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
 999         }
1000         ;
1001
1002 /*
1003 The representation of a  list is reversed to have efficient append.  */
1004
1005 music_list:
1006         /* empty */ {
1007                 $$ = SCM_EOL;
1008         }
1009         | music_list music_embedded {
1010                 if (unsmob_music ($2))
1011                         $$ = scm_cons ($2, $1);
1012         }
1013         | music_list error {
1014                 Music *m = MY_MAKE_MUSIC("Music", @$);
1015                 // ugh. code dup
1016                 m->set_property ("error-found", SCM_BOOL_T);
1017                 $$ = scm_cons (m->self_scm (), $1);
1018                 m->unprotect (); /* UGH */
1019         }
1020         ;
1021
1022 braced_music_list:
1023         '{' music_list '}'
1024         {
1025                 $$ = scm_reverse_x ($2, SCM_EOL);
1026         }
1027         ;
1028
1029 music:  music_arg
1030         | lyric_element_music
1031         ;
1032
1033 music_embedded:
1034         music
1035         {
1036                 if (unsmob_music ($1)->is_mus_type ("post-event")) {
1037                         parser->parser_error (@1, _ ("unexpected post-event"));
1038                         $$ = SCM_UNSPECIFIED;
1039                 }
1040         }
1041         | music_embedded_backup
1042         {
1043                 $$ = $1;
1044         }
1045         | music_embedded_backup BACKUP lyric_element_music
1046         {
1047                 $$ = $3;
1048         }
1049         ;
1050
1051 music_embedded_backup:
1052         embedded_scm
1053         {
1054                 if (scm_is_eq ($1, SCM_UNSPECIFIED))
1055                         $$ = $1;
1056                 else if (Music *m = unsmob_music ($1)) {
1057                         if (m->is_mus_type ("post-event")) {
1058                                 parser->parser_error
1059                                         (@1, _ ("unexpected post-event"));
1060                                 $$ = SCM_UNSPECIFIED;
1061                         } else
1062                                 $$ = $1;
1063                 } else if (parser->lexer_->is_lyric_state ()
1064                            && Text_interface::is_markup ($1))
1065                         MYBACKUP (LYRIC_ELEMENT, $1, @1);
1066                 else {
1067                         @$.warning (_ ("Ignoring non-music expression"));
1068                         $$ = $1;
1069                 }
1070         }
1071         ;
1072
1073 music_arg:
1074         simple_music
1075         {
1076                 $$ = make_music_from_simple (parser, @1, $1);
1077                 if (!unsmob_music ($$))
1078                         parser->parser_error (@1, _ ("music expected"));
1079         }
1080         | composite_music %prec COMPOSITE
1081         ;
1082
1083 music_assign:
1084         simple_music
1085         | composite_music %prec COMPOSITE
1086         ;
1087
1088 repeated_music:
1089         REPEAT simple_string unsigned_number music
1090         {
1091                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1092         }
1093         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1094         {
1095                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1096         }
1097         ;
1098
1099 sequential_music:
1100         SEQUENTIAL braced_music_list {
1101                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1102         }
1103         | braced_music_list {
1104                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1105         }
1106         ;
1107
1108 simultaneous_music:
1109         SIMULTANEOUS braced_music_list {
1110                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1111         }
1112         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1113                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1114         }
1115         ;
1116
1117 simple_music:
1118         event_chord
1119         | music_property_def
1120         | context_change
1121         ;
1122
1123 context_modification:
1124         WITH { parser->lexer_->push_initial_state (); } '{' context_mod_list '}'
1125         {
1126                 parser->lexer_->pop_state ();
1127                 $$ = $4;
1128         }
1129         | WITH CONTEXT_MOD_IDENTIFIER
1130         {
1131                 $$ = $2;
1132         }
1133         | CONTEXT_MOD_IDENTIFIER
1134         {
1135                 $$ = $1;
1136         }
1137         | WITH embedded_scm_closed
1138         {
1139                 if (unsmob_context_mod ($2))
1140                         $$ = $2;
1141                 else {
1142                         parser->parser_error (@2, _ ("not a context mod"));
1143                         $$ = Context_mod ().smobbed_copy ();
1144                 }
1145         }
1146         ;
1147
1148 optional_context_mod:
1149         /**/ {
1150             $$ = SCM_EOL;
1151         }
1152         | context_modification
1153         {
1154               $$ = $1;
1155         }
1156         ;
1157
1158 context_mod_list:
1159         /**/ {
1160             $$ = Context_mod ().smobbed_copy ();
1161         }
1162         | context_mod_list context_mod  {
1163                 if (!SCM_UNBNDP ($2))
1164                         unsmob_context_mod ($1)->add_context_mod ($2);
1165         }
1166         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1167                  Context_mod *md = unsmob_context_mod ($2);
1168                  if (md)
1169                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1170         }
1171         | context_mod_list context_mod_embedded {
1172                 unsmob_context_mod ($1)->add_context_mods
1173                         (unsmob_context_mod ($2)->get_mods ());
1174         }
1175         ;
1176
1177 composite_music:
1178         complex_music
1179         | music_bare
1180         ;
1181
1182 /* Music that can be parsed without lookahead */
1183 closed_music:
1184         music_bare
1185         | complex_music_prefix closed_music
1186         {
1187                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1188         }
1189         | music_function_call_closed
1190         ;
1191
1192 music_bare:
1193         mode_changed_music
1194         | MUSIC_IDENTIFIER
1195         | grouped_music_list
1196         ;
1197
1198 grouped_music_list:
1199         simultaneous_music              { $$ = $1; }
1200         | sequential_music              { $$ = $1; }
1201         ;
1202
1203 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1204  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1205 and this rule returns the reversed list of arguments. */
1206
1207 /* Function argument lists come in a number of flavors.  Whenever
1208  * LilyPond has to pick between different flavors, the decision is
1209  * either made because of tokens it has already seen, or it is
1210  * postponed until tokens suitable for making the decision come up.
1211  * For postponing decisions, it may be necessary that the competing
1212  * rules are written in a way making them compatible until a decision
1213  * can be made.  Sometimes this is done by putting common traits into
1214  * a separate "common" rule set.
1215  *
1216  * function_arglist: a full argument list.  Optional arguments at the
1217  * end of the list can only be skipped by writing \default in their
1218  * place.
1219  *
1220  * function_arglist_backup: an argument list ending in an optional
1221  * argument that may be skipped depending on its predicate.
1222  *
1223  * function_arglist_skip: an argument list _not_ ending in an optional
1224  * argument that is actually taken.
1225  *
1226  * function_arglist_nonbackup: an argument list ending in an optional
1227  * argument that may not be skipped because it is in end position and
1228  * has not been shortcircuited with \default.
1229  *
1230  * function_arglist* / function_arglist_closed*: The closed variants
1231  * don't end in simple music expressions that might still accept
1232  * things like a duration or a postevent.
1233  */
1234
1235 function_arglist_skip:
1236         function_arglist_common
1237         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip
1238         {
1239                 $$ = scm_cons ($1, $3);
1240         } %prec FUNCTION_ARGLIST
1241         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip
1242         {
1243                 $$ = scm_cons ($1, $3);
1244         } %prec FUNCTION_ARGLIST
1245         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip
1246         {
1247                 $$ = scm_cons ($1, $3);
1248         } %prec FUNCTION_ARGLIST
1249         ;
1250
1251
1252 function_arglist_nonbackup_common:
1253         EXPECT_OPTIONAL EXPECT_PITCH function_arglist pitch_also_in_chords {
1254                 $$ = scm_cons ($4, $3);
1255         }
1256         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed duration_length {
1257                 $$ = scm_cons ($4, $3);
1258         }
1259         | EXPECT_OPTIONAL EXPECT_SCM function_arglist FRACTION
1260         {
1261                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1262         }
1263         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed post_event_nofinger
1264         {
1265                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1266         }
1267         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' UNSIGNED
1268         {
1269                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1270                 if (scm_is_true (scm_call_1 ($2, n)))
1271                         $$ = scm_cons (n, $3);
1272                 else {
1273                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1274                         t->set_property ("digit", $5);
1275                         $$ = check_scheme_arg (parser, @4, t->unprotect (),
1276                                                $3, $2, n);
1277                 }
1278
1279         }
1280         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' REAL
1281         {
1282                 $$ = check_scheme_arg (parser, @4,
1283                                        scm_difference ($5, SCM_UNDEFINED),
1284                                        $3, $2);
1285         }
1286         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' NUMBER_IDENTIFIER
1287         {
1288                 $$ = check_scheme_arg (parser, @4,
1289                                        scm_difference ($5, SCM_UNDEFINED),
1290                                        $3, $2);
1291         }
1292         ;
1293
1294 function_arglist_closed_nonbackup:
1295         function_arglist_nonbackup_common
1296         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg_closed
1297         {
1298                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1299         }
1300         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number_closed
1301         {
1302                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1303         }
1304         | EXPECT_OPTIONAL EXPECT_SCM function_arglist SCM_IDENTIFIER
1305         {
1306                 $$ = check_scheme_arg (parser, @4,
1307                                        try_string_variants ($2, $4),
1308                                        $3, $2, $4);
1309         }
1310         | EXPECT_OPTIONAL EXPECT_SCM function_arglist STRING
1311         {
1312                 $$ = check_scheme_arg (parser, @4,
1313                                        try_string_variants ($2, $4),
1314                                        $3, $2, $4);
1315         }
1316         | EXPECT_OPTIONAL EXPECT_SCM function_arglist full_markup
1317         {
1318                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1319         }
1320         ;
1321
1322 symbol_list_arg:
1323         SYMBOL_LIST
1324         | SYMBOL_LIST '.' symbol_list_rev
1325         {
1326                 $$ = scm_append (scm_list_2 ($1, scm_reverse_x ($3, SCM_EOL)));
1327         }
1328         ;
1329
1330 symbol_list_rev:
1331         symbol_list_part
1332         | symbol_list_rev '.' symbol_list_part
1333         {
1334                 $$ = scm_append_x (scm_list_2 ($3, $1));
1335         }
1336         ;
1337
1338 // symbol_list_part delivers elements in reverse copy.
1339
1340 symbol_list_part:
1341         symbol_list_element
1342         {
1343                 SCM sym_l_p = ly_lily_module_constant ("symbol-list?");
1344                 $$ = try_string_variants (sym_l_p, $1);
1345                 if (SCM_UNBNDP ($$)) {
1346                         parser->parser_error (@1, _("not a symbol"));
1347                         $$ = SCM_EOL;
1348                 } else
1349                         $$ = scm_reverse ($$);
1350         }
1351         ;
1352
1353
1354 symbol_list_element:
1355         STRING
1356         | embedded_scm_bare
1357         ;
1358
1359
1360 function_arglist_nonbackup:
1361         function_arglist_nonbackup_common
1362         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg
1363         {
1364                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1365         }
1366         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number
1367         {
1368                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1369         }
1370         | function_arglist_nonbackup_reparse REPARSE SCM_ARG
1371         {
1372                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1373         }
1374         | function_arglist_nonbackup_reparse REPARSE lyric_element_music
1375         {
1376                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1377         }
1378         | function_arglist_nonbackup_reparse REPARSE symbol_list_arg
1379         {
1380                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1381         }
1382         ;
1383
1384 function_arglist_nonbackup_reparse:
1385         EXPECT_OPTIONAL EXPECT_SCM function_arglist SCM_IDENTIFIER
1386         {
1387                 $$ = $3;
1388                 SCM res = try_string_variants ($2, $4);
1389                 if (!SCM_UNBNDP (res))
1390                         if (scm_is_pair (res))
1391                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1392                         else
1393                                 MYREPARSE (@4, $2, SCM_ARG, res);
1394                 else if (scm_is_true
1395                          (scm_call_1
1396                           ($2, make_music_from_simple
1397                            (parser, @4, $4))))
1398                         MYREPARSE (@4, $2, STRING, $4);
1399                 else
1400                         MYREPARSE (@4, $2, SCM_ARG, $4);
1401         }
1402         | EXPECT_OPTIONAL EXPECT_SCM function_arglist STRING
1403         {
1404                 $$ = $3;
1405                 SCM res = try_string_variants ($2, $4);
1406                 if (!SCM_UNBNDP (res))
1407                         if (scm_is_pair (res))
1408                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1409                         else
1410                                 MYREPARSE (@4, $2, SCM_ARG, res);
1411                 else if (scm_is_true
1412                          (scm_call_1
1413                           ($2, make_music_from_simple
1414                            (parser, @4, $4))))
1415                         MYREPARSE (@4, $2, STRING, $4);
1416                 else
1417                         MYREPARSE (@4, $2, SCM_ARG, $4);
1418         }
1419         | EXPECT_OPTIONAL EXPECT_SCM function_arglist full_markup
1420         {
1421                 $$ = $3;
1422                 if (scm_is_true (scm_call_1 ($2, $4)))
1423                         MYREPARSE (@4, $2, SCM_ARG, $4);
1424                 else if (scm_is_true
1425                          (scm_call_1
1426                           ($2, make_music_from_simple
1427                            (parser, @4, $4))))
1428                         MYREPARSE (@4, $2, STRING, $4);
1429                 else
1430                         MYREPARSE (@4, $2, SCM_ARG, $4);
1431         }
1432         ;
1433
1434 function_arglist_keep:
1435         function_arglist_common
1436         | function_arglist_backup
1437         ;
1438
1439 function_arglist_closed_keep:
1440         function_arglist_closed_common
1441         | function_arglist_backup
1442         ;
1443
1444 function_arglist_backup:
1445         EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1446         {
1447                 if (scm_is_true (scm_call_1 ($2, $4)))
1448                 {
1449                         $$ = scm_cons ($4, $3);
1450                 } else {
1451                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1452                         MYBACKUP (SCM_ARG, $4, @4);
1453                 }
1454         }
1455         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep post_event_nofinger
1456         {
1457                 if (scm_is_true (scm_call_1 ($2, $4)))
1458                 {
1459                         $$ = scm_cons ($4, $3);
1460                 } else {
1461                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1462                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1463                 }
1464         }
1465         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep full_markup
1466         {
1467                 if (scm_is_true (scm_call_1 ($2, $4)))
1468                         $$ = scm_cons ($4, $3);
1469                 else {
1470                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1471                         MYBACKUP (LYRIC_ELEMENT, $4, @4);
1472                 }
1473         }
1474         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep UNSIGNED
1475         {
1476                 if (scm_is_true (scm_call_1 ($2, $4)))
1477                 {
1478                         $$ = $3;
1479                         MYREPARSE (@4, $2, UNSIGNED, $4);
1480                 } else {
1481                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1482                         MYBACKUP (UNSIGNED, $4, @4);
1483                 }
1484         }
1485         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep REAL
1486         {
1487                 if (scm_is_true (scm_call_1 ($2, $4)))
1488                 {
1489                         $$ = $3;
1490                         MYREPARSE (@4, $2, REAL, $4);
1491                 } else {
1492                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1493                         MYBACKUP (REAL, $4, @4);
1494                 }
1495         }
1496         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep NUMBER_IDENTIFIER
1497         {
1498                 if (scm_is_true (scm_call_1 ($2, $4)))
1499                 {
1500                         $$ = scm_cons ($4, $3);
1501                 } else {
1502                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1503                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1504                 }
1505         }
1506         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep FRACTION
1507         {
1508                 if (scm_is_true (scm_call_1 ($2, $4)))
1509                 {
1510                         $$ = scm_cons ($4, $3);
1511                 } else {
1512                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1513                         MYBACKUP (FRACTION, $4, @4);
1514                 }
1515         }
1516         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' UNSIGNED
1517         {
1518                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1519                 if (scm_is_true (scm_call_1 ($2, n))) {
1520                         $$ = $3;
1521                         MYREPARSE (@5, $2, REAL, n);
1522                 } else {
1523                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1524                         t->set_property ("digit", $5);
1525                         $$ = t->unprotect ();
1526                         if (scm_is_true (scm_call_1 ($2, $$)))
1527                                 $$ = scm_cons ($$, $3);
1528                         else {
1529                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1530                                 MYBACKUP (UNSIGNED, $5, @5);
1531                                 parser->lexer_->push_extra_token ('-');
1532                         }
1533                 }
1534
1535         }
1536         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' REAL
1537         {
1538                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1539                 if (scm_is_true (scm_call_1 ($2, n))) {
1540                         MYREPARSE (@5, $2, REAL, n);
1541                         $$ = $3;
1542                 } else {
1543                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1544                         MYBACKUP (REAL, n, @5);
1545                 }
1546         }
1547         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' NUMBER_IDENTIFIER
1548         {
1549                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1550                 if (scm_is_true (scm_call_1 ($2, n))) {
1551                         $$ = scm_cons (n, $3);
1552                 } else {
1553                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1554                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1555                 }
1556         }
1557         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords
1558         {
1559                 $$ = scm_cons ($4, $3);
1560         }
1561         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length
1562         {
1563                 $$ = scm_cons ($4, $3);
1564         }
1565         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep SCM_IDENTIFIER
1566         {
1567                 SCM res = try_string_variants ($2, $4);
1568                 if (!SCM_UNBNDP (res))
1569                         if (scm_is_pair (res)) {
1570                                 $$ = $3;
1571                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1572                         }
1573                         else
1574                                 $$ = scm_cons (res, $3);
1575                 else {
1576                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1577                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1578                 }
1579         }
1580         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep STRING
1581         {
1582                 SCM res = try_string_variants ($2, $4);
1583                 if (!SCM_UNBNDP (res))
1584                         if (scm_is_pair (res)) {
1585                                 $$ = $3;
1586                                 MYREPARSE (@4, $2, SYMBOL_LIST, res);
1587                         }
1588                         else
1589                                 $$ = scm_cons (res, $3);
1590                 else {
1591                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1592                         MYBACKUP (STRING, $4, @4);
1593                 }
1594         }
1595         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup BACKUP
1596         {
1597                 $$ = scm_cons ($1, $3);
1598                 MYBACKUP(0, SCM_UNDEFINED, @3);
1599         }
1600         | function_arglist_backup REPARSE bare_number
1601         {
1602                 $$ = check_scheme_arg (parser, @3,
1603                                        $3, $1, $2);
1604         }
1605         | function_arglist_backup REPARSE symbol_list_arg
1606         {
1607                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1608         }
1609         ;
1610
1611 function_arglist:
1612         function_arglist_common
1613         | function_arglist_nonbackup
1614         ;
1615
1616 function_arglist_common:
1617         function_arglist_bare
1618         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1619         {
1620                 $$ = check_scheme_arg (parser, @3,
1621                                        $3, $2, $1);
1622         }
1623         | EXPECT_SCM function_arglist_closed_optional bare_number
1624         {
1625                 $$ = check_scheme_arg (parser, @3,
1626                                        $3, $2, $1);
1627         }
1628         | EXPECT_SCM function_arglist_optional FRACTION
1629         {
1630                 $$ = check_scheme_arg (parser, @3,
1631                                        $3, $2, $1);
1632         }
1633         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1634         {
1635                 $$ = check_scheme_arg (parser, @3,
1636                                        $3, $2, $1);
1637         }
1638         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1639         {
1640                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1641                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1642         }
1643         | function_arglist_common_reparse REPARSE SCM_ARG
1644         {
1645                 $$ = check_scheme_arg (parser, @3,
1646                                        $3, $1, $2);
1647         }
1648         | function_arglist_common_reparse REPARSE lyric_element_music
1649         {
1650                 $$ = check_scheme_arg (parser, @3,
1651                                        $3, $1, $2);
1652         }
1653         | function_arglist_common_reparse REPARSE bare_number
1654         {
1655                 $$ = check_scheme_arg (parser, @3,
1656                                        $3, $1, $2);
1657         }
1658         | function_arglist_common_reparse REPARSE symbol_list_arg
1659         {
1660                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1661         }
1662         ;
1663
1664 function_arglist_common_reparse:
1665         EXPECT_SCM function_arglist_optional SCM_IDENTIFIER
1666         {
1667                 $$ = $2;
1668                 SCM res = try_string_variants ($1, $3);
1669                 if (!SCM_UNBNDP (res))
1670                         if (scm_is_pair (res))
1671                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
1672                         else
1673                                 MYREPARSE (@3, $1, SCM_ARG, res);
1674                 else if (scm_is_true
1675                          (scm_call_1
1676                           ($1, make_music_from_simple (parser, @3, $3))))
1677                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1678                 else
1679                         // This is going to flag a syntax error, we
1680                         // know the predicate to be false.
1681                         MYREPARSE (@3, $1, SCM_ARG, $3);
1682         }
1683         | EXPECT_SCM function_arglist_optional STRING
1684         {
1685                 $$ = $2;
1686                 SCM res = try_string_variants ($1, $3);
1687                 if (!SCM_UNBNDP (res))
1688                         if (scm_is_pair (res))
1689                                 MYREPARSE (@3, $1, SYMBOL_LIST, res);
1690                         else
1691                                 MYREPARSE (@3, $1, SCM_ARG, res);
1692                 else if (scm_is_true
1693                          (scm_call_1
1694                           ($1, make_music_from_simple (parser, @3, $3))))
1695                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1696                 else
1697                         // This is going to flag a syntax error, we
1698                         // know the predicate to be false.
1699                         MYREPARSE (@3, $1, SCM_ARG, $3);
1700         }
1701         | EXPECT_SCM function_arglist_optional full_markup
1702         {
1703                 $$ = $2;
1704                 if (scm_is_true (scm_call_1 ($1, $3)))
1705                         MYREPARSE (@3, $1, SCM_ARG, $3);
1706                 else if (scm_is_true
1707                          (scm_call_1
1708                           ($1, make_music_from_simple (parser, @3, $3))))
1709                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1710                 else
1711                         // This is going to flag a syntax error, we
1712                         // know the predicate to be false.
1713                         MYREPARSE (@3, $1, SCM_ARG, $3);
1714         }
1715         | EXPECT_SCM function_arglist_closed_optional '-' UNSIGNED
1716         {
1717                 $$ = $2;
1718                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1719                 if (scm_is_true (scm_call_1 ($1, n)))
1720                         MYREPARSE (@4, $1, REAL, n);
1721                 else {
1722                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1723                         t->set_property ("digit", $4);
1724                         SCM m = t->unprotect ();
1725                         if (scm_is_true (scm_call_1 ($1, m)))
1726                                 MYREPARSE (@4, $1, SCM_ARG, m);
1727                         else
1728                                 MYREPARSE (@4, $1, SCM_ARG, $4);
1729                 }
1730
1731         }
1732         | EXPECT_SCM function_arglist_closed_optional '-' REAL
1733         {
1734                 $$ = $2;
1735                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1736                 MYREPARSE (@4, $1, REAL, n);
1737         }
1738         ;
1739
1740 function_arglist_closed:
1741         function_arglist_closed_common
1742         | function_arglist_closed_nonbackup
1743         ;
1744
1745 function_arglist_closed_common:
1746         function_arglist_bare
1747         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1748         {
1749                 $$ = check_scheme_arg (parser, @3,
1750                                        $3, $2, $1);
1751         }
1752         | EXPECT_SCM function_arglist_closed_optional bare_number
1753         {
1754                 $$ = check_scheme_arg (parser, @3,
1755                                        $3, $2, $1);
1756         }
1757         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1758         {
1759                 $$ = check_scheme_arg (parser, @3,
1760                                        scm_difference ($4, SCM_UNDEFINED),
1761                                        $2, $1);
1762         }
1763         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1764         {
1765                 $$ = check_scheme_arg (parser, @3,
1766                                        $3, $2, $1);
1767         }
1768         | EXPECT_SCM function_arglist_optional FRACTION
1769         {
1770                 $$ = check_scheme_arg (parser, @3,
1771                                        $3, $2, $1);
1772         }
1773         | function_arglist_common_reparse REPARSE SCM_ARG
1774         {
1775                 $$ = check_scheme_arg (parser, @3,
1776                                        $3, $1, $2);
1777         }
1778         | function_arglist_common_reparse REPARSE bare_number
1779         {
1780                 $$ = check_scheme_arg (parser, @3,
1781                                        $3, $1, $2);
1782         }
1783         | function_arglist_common_reparse REPARSE symbol_list_arg
1784         {
1785                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1786         }
1787         ;
1788
1789 function_arglist_optional:
1790         function_arglist_keep %prec FUNCTION_ARGLIST
1791         | function_arglist_backup BACKUP
1792         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1793         {
1794                 $$ = scm_cons ($1, $3);
1795         }
1796         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1797         {
1798                 $$ = scm_cons ($1, $3);
1799         }
1800         ;
1801
1802 function_arglist_closed_optional:
1803         function_arglist_closed_keep %prec FUNCTION_ARGLIST
1804         | function_arglist_backup BACKUP
1805         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1806         {
1807                 $$ = scm_cons ($1, $3);
1808         }
1809         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1810         {
1811                 $$ = scm_cons ($1, $3);
1812         }
1813         ;
1814
1815 embedded_scm_closed:
1816         embedded_scm_bare
1817         | scm_function_call_closed
1818         ;
1819
1820 embedded_scm_arg_closed:
1821         embedded_scm_bare_arg
1822         | scm_function_call_closed
1823         | closed_music
1824         ;
1825
1826 scm_function_call_closed:
1827         SCM_FUNCTION function_arglist_closed {
1828                 $$ = MAKE_SYNTAX ("music-function", @$,
1829                                          $1, $2);
1830         } %prec FUNCTION_ARGLIST
1831         ;
1832
1833 function_arglist_bare:
1834         EXPECT_NO_MORE_ARGS {
1835                 $$ = SCM_EOL;
1836         }
1837         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1838                 $$ = scm_cons ($3, $2);
1839         }
1840         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1841                 $$ = scm_cons ($3, $2);
1842         }
1843         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip DEFAULT {
1844                 $$ = scm_cons ($1, $3);
1845         }
1846         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip DEFAULT {
1847                 $$ = scm_cons ($1, $3);
1848         }
1849         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip DEFAULT {
1850                 $$ = scm_cons ($1, $3);
1851         }
1852         ;
1853
1854 music_function_call:
1855         MUSIC_FUNCTION function_arglist {
1856                 $$ = MAKE_SYNTAX ("music-function", @$,
1857                                          $1, $2);
1858         }
1859         ;
1860
1861
1862 optional_id:
1863         /**/ { $$ = SCM_EOL; }
1864         | '=' simple_string {
1865                 $$ = $2;
1866         }
1867         ;
1868
1869 complex_music:
1870         music_function_call
1871         | repeated_music                { $$ = $1; }
1872         | re_rhythmed_music     { $$ = $1; }
1873         | complex_music_prefix music
1874         {
1875                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1876         }
1877         ;
1878
1879 complex_music_prefix:
1880         CONTEXT simple_string optional_id optional_context_mod {
1881                 Context_mod *ctxmod = unsmob_context_mod ($4);
1882                 SCM mods = SCM_EOL;
1883                 if (ctxmod)
1884                         mods = ctxmod->get_mods ();
1885                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1886         }
1887         | NEWCONTEXT simple_string optional_id optional_context_mod {
1888                 Context_mod *ctxmod = unsmob_context_mod ($4);
1889                 SCM mods = SCM_EOL;
1890                 if (ctxmod)
1891                         mods = ctxmod->get_mods ();
1892                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1893         }
1894         ;
1895
1896 mode_changed_music:
1897         mode_changing_head grouped_music_list {
1898                 if ($1 == ly_symbol2scm ("chords"))
1899                 {
1900                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1901                 }
1902                 else
1903                 {
1904                   $$ = $2;
1905                 }
1906                 parser->lexer_->pop_state ();
1907         }
1908         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1909                 Context_mod *ctxmod = unsmob_context_mod ($2);
1910                 SCM mods = SCM_EOL;
1911                 if (ctxmod)
1912                         mods = ctxmod->get_mods ();
1913                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1914                 if ($1 == ly_symbol2scm ("ChordNames"))
1915                 {
1916                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1917                 }
1918                 parser->lexer_->pop_state ();
1919         }
1920         ;
1921
1922 mode_changing_head:
1923         NOTEMODE {
1924                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1925                 parser->lexer_->push_note_state (nn);
1926
1927                 $$ = ly_symbol2scm ("notes");
1928         }
1929         | DRUMMODE
1930                 {
1931                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1932                 parser->lexer_->push_note_state (nn);
1933
1934                 $$ = ly_symbol2scm ("drums");
1935         }
1936         | FIGUREMODE {
1937                 parser->lexer_->push_figuredbass_state ();
1938
1939                 $$ = ly_symbol2scm ("figures");
1940         }
1941         | CHORDMODE {
1942                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1943                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1944                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1945                 parser->lexer_->push_chord_state (nn);
1946                 $$ = ly_symbol2scm ("chords");
1947
1948         }
1949         | LYRICMODE
1950                 { parser->lexer_->push_lyric_state ();
1951                 $$ = ly_symbol2scm ("lyrics");
1952         }
1953         ;
1954
1955 mode_changing_head_with_context:
1956         DRUMS {
1957                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1958                 parser->lexer_->push_note_state (nn);
1959
1960                 $$ = ly_symbol2scm ("DrumStaff");
1961         }
1962         | FIGURES {
1963                 parser->lexer_->push_figuredbass_state ();
1964
1965                 $$ = ly_symbol2scm ("FiguredBass");
1966         }
1967         | CHORDS {
1968                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1969                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1970                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1971                 parser->lexer_->push_chord_state (nn);
1972                 $$ = ly_symbol2scm ("ChordNames");
1973         }
1974         | LYRICS
1975                 { parser->lexer_->push_lyric_state ();
1976                 $$ = ly_symbol2scm ("Lyrics");
1977         }
1978         ;
1979
1980 new_lyrics:
1981         ADDLYRICS { parser->lexer_->push_lyric_state (); }
1982         /*cont */
1983         composite_music {
1984         /* Can also use music at the expensive of two S/Rs similar to
1985            \repeat \alternative */
1986                 parser->lexer_->pop_state ();
1987
1988                 $$ = scm_cons ($3, SCM_EOL);
1989         }
1990         | new_lyrics ADDLYRICS {
1991                 parser->lexer_->push_lyric_state ();
1992         } composite_music {
1993                 parser->lexer_->pop_state ();
1994                 $$ = scm_cons ($4, $1);
1995         }
1996         ;
1997
1998 re_rhythmed_music:
1999         composite_music new_lyrics {
2000                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
2001         } %prec COMPOSITE
2002         | LYRICSTO simple_string {
2003                 parser->lexer_->push_lyric_state ();
2004         } music {
2005                 parser->lexer_->pop_state ();
2006                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
2007         }
2008         ;
2009
2010 context_change:
2011         CHANGE STRING '=' STRING  {
2012                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
2013         }
2014         ;
2015
2016
2017 property_path:
2018         symbol_list_rev  {
2019                 $$ = scm_reverse_x ($1, SCM_EOL);
2020         }
2021         | symbol_list_rev property_path {
2022                 $$ = scm_reverse_x ($1, $2);
2023         }
2024         ;
2025
2026 property_operation:
2027         STRING '=' scalar {
2028                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
2029                         scm_string_to_symbol ($1), $3);
2030         }
2031         | UNSET simple_string {
2032                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
2033                         scm_string_to_symbol ($2));
2034         }
2035         | OVERRIDE property_path '=' scalar {
2036                 if (scm_ilength ($2) < 2) {
2037                         parser->parser_error (@2, _("bad grob property path"));
2038                         $$ = SCM_UNDEFINED;
2039                 } else {
2040                         $$ = scm_cons (ly_symbol2scm ("push"),
2041                                        scm_cons2 (scm_car ($2),
2042                                                   $4,
2043                                                   scm_cdr ($2)));
2044                 }
2045         }
2046         | REVERT revert_arg {
2047                 $$ = scm_cons (ly_symbol2scm ("pop"), $2);
2048         }
2049         ;
2050
2051 // This is all quite awkward for the sake of substantial backward
2052 // compatibility while at the same time allowing a more "natural" form
2053 // of specification not separating grob specification from grob
2054 // property path.  The purpose of this definition of revert_arg is to
2055 // allow the symbol list which specifies grob and property to revert
2056 // to be optionally be split into two parts after the grob (which in
2057 // this case is just the first element of the list).  symbol_list_part
2058 // is only one path component, but it can be parsed without lookahead,
2059 // so we can follow it with a synthetic BACKUP token when needed.  If
2060 // the first symbol_list_part already contains multiple elements (only
2061 // possible if a Scheme expression provides them), we just parse for
2062 // additional elements introduced by '.', which is what the
2063 // SYMBOL_LIST backup in connection with the immediately following
2064 // rule using symbol_list_arg does.
2065 //
2066 // As long as we don't have our coffers filled with both grob and at
2067 // least one grob property specification, the rest of the required
2068 // symbol list chain may be provided either with or without a leading
2069 // dot.  This is for both allowing the traditional
2070 // \revert Accidental #'color
2071 // as well as well as the "naive" form
2072 // \revert Accidental.color
2073
2074 revert_arg:
2075         revert_arg_backup BACKUP symbol_list_arg
2076         {
2077                 $$ = $3;
2078         }
2079         ;
2080
2081 revert_arg_backup:
2082         revert_arg_part
2083         {
2084                 if (scm_is_null ($1)
2085                     || scm_is_null (scm_cdr ($1)))
2086                         MYBACKUP (SCM_ARG, $1, @1);
2087                 else
2088                         MYBACKUP (SYMBOL_LIST, scm_reverse_x ($1, SCM_EOL), @1);
2089         }
2090         ;
2091
2092 // revert_arg_part delivers results in reverse
2093 revert_arg_part:
2094         symbol_list_part
2095         | revert_arg_backup BACKUP SCM_ARG '.' symbol_list_part
2096         {
2097                 $$ = scm_append_x (scm_list_2 ($5, $3));
2098         }
2099         | revert_arg_backup BACKUP SCM_ARG symbol_list_part
2100         {
2101                 $$ = scm_append_x (scm_list_2 ($4, $3));
2102         }
2103         ;
2104
2105 context_def_mod:
2106         CONSISTS { $$ = ly_symbol2scm ("consists"); }
2107         | REMOVE { $$ = ly_symbol2scm ("remove"); }
2108
2109         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
2110         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
2111         | DENIES { $$ = ly_symbol2scm ("denies"); }
2112
2113         | ALIAS { $$ = ly_symbol2scm ("alias"); }
2114         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
2115         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
2116         | NAME { $$ = ly_symbol2scm ("context-name"); }
2117         ;
2118
2119 context_mod:
2120         property_operation { $$ = $1; }
2121         | context_def_mod STRING {
2122                 $$ = scm_list_2 ($1, $2);
2123         }
2124         | context_def_mod embedded_scm
2125         {
2126                 if (!scm_is_string ($2)
2127                     && ly_symbol2scm ("consists") != $1
2128                     && ly_symbol2scm ("remove") != $1)
2129                 {
2130                         $$ = SCM_EOL;
2131                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
2132                 }
2133                 else
2134                 {
2135                         $$ = scm_list_2 ($1, $2);
2136                 }
2137         }
2138         ;
2139
2140 // If defined, at least two members.
2141 grob_prop_spec:
2142         symbol_list_rev
2143         {
2144                 SCM l = scm_reverse_x ($1, SCM_EOL);
2145                 if (scm_is_pair (l)
2146                     && to_boolean
2147                     (scm_object_property (scm_car (l),
2148                                           ly_symbol2scm ("is-grob?"))))
2149                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2150                 if (scm_is_null (l) || scm_is_null (scm_cdr (l))) {
2151                         parser->parser_error (@1, _ ("bad grob property path"));
2152                         l = SCM_UNDEFINED;
2153                 }
2154                 $$ = l;
2155         }
2156         ;
2157
2158 // If defined, at least three members
2159 grob_prop_path:
2160         grob_prop_spec
2161         {
2162                 if (!SCM_UNBNDP ($1) && scm_is_null (scm_cddr ($1)))
2163                 {
2164                         parser->parser_error (@1, _ ("bad grob property path"));
2165                         $$ = SCM_UNDEFINED;
2166                 }
2167         }
2168         | grob_prop_spec property_path
2169         {
2170                 if (!SCM_UNBNDP ($1)) {
2171                         $$ = scm_append_x (scm_list_2 ($1, $2));
2172                         if (scm_is_null (scm_cddr ($$))) {
2173                                 parser->parser_error (@$, _ ("bad grob property path"));
2174                                 $$ = SCM_UNDEFINED;
2175                         }
2176                 }
2177
2178         }
2179         ;
2180
2181 // Exactly two elements or undefined
2182 context_prop_spec:
2183         symbol_list_rev
2184         {
2185                 SCM l = scm_reverse_x ($1, SCM_EOL);
2186                 switch (scm_ilength (l)) {
2187                 case 1:
2188                         l = scm_cons (ly_symbol2scm ("Bottom"), l);
2189                 case 2:
2190                         break;
2191                 default:
2192                         parser->parser_error (@1, _ ("bad context property path"));
2193                         l = SCM_UNDEFINED;
2194                 }
2195                 $$ = l;
2196         }
2197         ;
2198
2199 simple_music_property_def:
2200         OVERRIDE grob_prop_path '=' scalar {
2201                 if (SCM_UNBNDP ($2))
2202                         $$ = SCM_UNDEFINED;
2203                 else {
2204                         $$ = scm_list_5 (scm_car ($2),
2205                                          ly_symbol2scm ("OverrideProperty"),
2206                                          scm_cadr ($2),
2207                                          $4,
2208                                          scm_cddr ($2));
2209                 }
2210         }
2211         | REVERT simple_revert_context revert_arg {
2212                 $$ = scm_list_4 ($2,
2213                                  ly_symbol2scm ("RevertProperty"),
2214                                  scm_car ($3),
2215                                  scm_cdr ($3));
2216         }
2217         | SET context_prop_spec '=' scalar {
2218                 if (SCM_UNBNDP ($2))
2219                         $$ = SCM_UNDEFINED;
2220                 else
2221                         $$ = scm_list_4 (scm_car ($2),
2222                                          ly_symbol2scm ("PropertySet"),
2223                                          scm_cadr ($2),
2224                                          $4);
2225         }
2226         | UNSET context_prop_spec {
2227                 if (SCM_UNBNDP ($2))
2228                         $$ = SCM_UNDEFINED;
2229                 else
2230                         $$ = scm_list_3 (scm_car ($2),
2231                                          ly_symbol2scm ("PropertyUnset"),
2232                                          scm_cadr ($2));
2233         }
2234         ;
2235
2236
2237 // This is all quite awkward for the sake of substantial backward
2238 // compatibility while at the same time allowing a more "natural" form
2239 // of specification not separating grob specification from grob
2240 // property path.  The purpose of this definition of
2241 // simple_revert_context is to allow the symbol list which specifies
2242 // grob and property to revert to be optionally be split into two
2243 // parts after the grob (which may be preceded by a context
2244 // specification, a case which we distinguish by checking whether the
2245 // first symbol is a valid grob symbol instead).
2246 //
2247 // See revert_arg above for the main work horse of this arrangement.
2248 // simple_revert_context just caters for the context and delegates the
2249 // rest of the job to revert_arg.
2250
2251 simple_revert_context:
2252         symbol_list_part
2253         {
2254                 $1 = scm_reverse_x ($1, SCM_EOL);
2255                 if (scm_is_null ($1)
2256                     || to_boolean
2257                     (scm_object_property (scm_car ($1),
2258                                           ly_symbol2scm ("is-grob?")))) {
2259                         $$ = ly_symbol2scm ("Bottom");
2260                         parser->lexer_->push_extra_token (SCM_IDENTIFIER, $1);
2261                 } else {
2262                         $$ = scm_car ($1);
2263                         parser->lexer_->push_extra_token (SCM_IDENTIFIER,
2264                                                           scm_cdr ($1));
2265                 }
2266         }
2267         ;
2268
2269 music_property_def:
2270         simple_music_property_def {
2271                 if (SCM_UNBNDP ($1))
2272                         $$ = MAKE_SYNTAX ("void-music", @1);
2273                 else
2274                         $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), make_input (@$), $1));
2275         }
2276         ;
2277
2278 string:
2279         STRING {
2280                 $$ = $1;
2281         }
2282         | full_markup
2283         ;
2284
2285 simple_string: STRING {
2286                 $$ = $1;
2287         }
2288         | embedded_scm_bare
2289         {
2290                 if (scm_is_string ($1)) {
2291                         $$ = $1;
2292                 } else {
2293                         parser->parser_error (@1, (_ ("simple string expected")));
2294                         $$ = scm_string (SCM_EOL);
2295                 }
2296         }
2297         ;
2298
2299 scalar:
2300         embedded_scm_arg
2301         | SCM_IDENTIFIER
2302         | bare_number
2303         | FRACTION
2304         | lyric_element
2305         ;
2306
2307 scalar_closed:
2308         embedded_scm_arg_closed
2309         | SCM_IDENTIFIER
2310         | bare_number
2311         | FRACTION
2312         | lyric_element
2313         ;
2314
2315
2316 event_chord:
2317         simple_element post_events {
2318                 // Let the rhythmic music iterator sort this mess out.
2319                 if (scm_is_pair ($2)) {
2320                         $$ = make_music_from_simple (parser, @1, $1);
2321                         if (unsmob_music ($$))
2322                                 unsmob_music ($$)->set_property ("articulations",
2323                                                                  scm_reverse_x ($2, SCM_EOL));
2324                         else
2325                                 parser->parser_error (@1, _("music expected"));
2326                 }
2327         }
2328         | simple_chord_elements post_events     {
2329                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
2330
2331                 Input i;
2332                 /* why is this giving wrong start location? -ns
2333                  * i = @$; */
2334                 i.set_location (@1, @2);
2335                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
2336         }
2337         | CHORD_REPETITION optional_notemode_duration post_events {
2338                 Input i;
2339                 i.set_location (@1, @3);
2340                 $$ = MAKE_SYNTAX ("repetition-chord", i,
2341                                   $2, scm_reverse_x ($3, SCM_EOL));
2342         }
2343         | MULTI_MEASURE_REST optional_notemode_duration post_events {
2344                 Input i;
2345                 i.set_location (@1, @3);
2346                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
2347                                   scm_reverse_x ($3, SCM_EOL));
2348         }
2349         | command_element
2350         | note_chord_element
2351         ;
2352
2353
2354 note_chord_element:
2355         chord_body optional_notemode_duration post_events
2356         {
2357                 Music *m = unsmob_music ($1);
2358                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
2359                 SCM es = m->get_property ("elements");
2360                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
2361
2362                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
2363                   unsmob_music (scm_car (s))->set_property ("duration", dur);
2364                 es = ly_append2 (es, postevs);
2365
2366                 m-> set_property ("elements", es);
2367                 m->set_spot (@$);
2368                 $$ = m->self_scm ();
2369         }
2370         ;
2371
2372 chord_body:
2373         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
2374         {
2375                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
2376         }
2377         ;
2378
2379 chord_body_elements:
2380         /* empty */             { $$ = SCM_EOL; }
2381         | chord_body_elements chord_body_element {
2382                 if (!SCM_UNBNDP ($2))
2383                         $$ = scm_cons ($2, $1);
2384         }
2385         ;
2386
2387 chord_body_element:
2388         pitch exclamations questions octave_check post_events
2389         {
2390                 bool q = to_boolean ($3);
2391                 bool ex = to_boolean ($2);
2392                 SCM check = $4;
2393                 SCM post = $5;
2394
2395                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2396                 n->set_property ("pitch", $1);
2397                 if (q)
2398                         n->set_property ("cautionary", SCM_BOOL_T);
2399                 if (ex || q)
2400                         n->set_property ("force-accidental", SCM_BOOL_T);
2401
2402                 if (scm_is_pair (post)) {
2403                         SCM arts = scm_reverse_x (post, SCM_EOL);
2404                         n->set_property ("articulations", arts);
2405                 }
2406                 if (scm_is_number (check))
2407                 {
2408                         int q = scm_to_int (check);
2409                         n->set_property ("absolute-octave", scm_from_int (q-1));
2410                 }
2411
2412                 $$ = n->unprotect ();
2413         }
2414         | DRUM_PITCH post_events {
2415                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2416                 n->set_property ("drum-type", $1);
2417
2418                 if (scm_is_pair ($2)) {
2419                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2420                         n->set_property ("articulations", arts);
2421                 }
2422                 $$ = n->unprotect ();
2423         }
2424         | music_function_chord_body
2425         {
2426                 Music *m = unsmob_music ($1);
2427
2428                 while (m && m->is_mus_type ("music-wrapper-music")) {
2429                         $$ = m->get_property ("element");
2430                         m = unsmob_music ($$);
2431                 }
2432
2433                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2434                         parser->parser_error (@$, _ ("not a rhythmic event"));
2435                         $$ = SCM_UNDEFINED;
2436                 }
2437         }
2438         ;
2439
2440 music_function_chord_body:
2441         music_function_call
2442         | MUSIC_IDENTIFIER
2443         ;
2444
2445 // Event functions may only take closed arglists, otherwise it would
2446 // not be clear whether a following postevent should be associated
2447 // with the last argument of the event function or with the expression
2448 // for which the function call acts itself as event.
2449
2450 music_function_call_closed:
2451         MUSIC_FUNCTION function_arglist_closed {
2452                 $$ = MAKE_SYNTAX ("music-function", @$,
2453                                          $1, $2);
2454         }
2455         ;
2456
2457 event_function_event:
2458         EVENT_FUNCTION function_arglist_closed {
2459                 $$ = MAKE_SYNTAX ("music-function", @$,
2460                                          $1, $2);
2461         }
2462         ;
2463
2464 command_element:
2465         command_event {
2466                 $$ = $1;
2467         }
2468         ;
2469
2470 command_event:
2471         tempo_event {
2472                 $$ = $1;
2473         }
2474         ;
2475
2476
2477 post_events:
2478         /* empty */ {
2479                 $$ = SCM_EOL;
2480         }
2481         | post_events post_event {
2482                 $$ = $1;
2483                 if (Music *m = unsmob_music ($2))
2484                 {
2485                         if (m->is_mus_type ("post-event-wrapper"))
2486                         {
2487                                 for (SCM p = m->get_property ("elements");
2488                                      scm_is_pair (p);
2489                                      p = scm_cdr (p))
2490                                 {
2491                                         $$ = scm_cons (scm_car (p), $$);
2492                                 }
2493                         } else {
2494                                 m->set_spot (@2);
2495                                 $$ = scm_cons ($2, $$);
2496                         }
2497                 }
2498         }
2499         ;
2500
2501 post_event_nofinger:
2502         direction_less_event {
2503                 $$ = $1;
2504         }
2505         | script_dir music_function_call_closed {
2506                 $$ = $2;
2507                 if (!unsmob_music ($2)->is_mus_type ("post-event")) {
2508                         parser->parser_error (@2, _ ("post-event expected"));
2509                         $$ = SCM_UNSPECIFIED;
2510                 } else if (!SCM_UNBNDP ($1))
2511                 {
2512                         unsmob_music ($$)->set_property ("direction", $1);
2513                 }
2514         }
2515         | HYPHEN {
2516                 if (!parser->lexer_->is_lyric_state ())
2517                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2518                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2519         }
2520         | EXTENDER {
2521                 if (!parser->lexer_->is_lyric_state ())
2522                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2523                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2524         }
2525         | script_dir direction_reqd_event {
2526                 if (!SCM_UNBNDP ($1))
2527                 {
2528                         Music *m = unsmob_music ($2);
2529                         m->set_property ("direction", $1);
2530                 }
2531                 $$ = $2;
2532         }
2533         | script_dir direction_less_event {
2534                 if (!SCM_UNBNDP ($1))
2535                 {
2536                         Music *m = unsmob_music ($2);
2537                         m->set_property ("direction", $1);
2538                 }
2539                 $$ = $2;
2540         }
2541         | '^' fingering
2542         {
2543                 $$ = $2;
2544                 unsmob_music ($$)->set_property ("direction", scm_from_int (UP));
2545         }
2546         | '_' fingering
2547         {
2548                 $$ = $2;
2549                 unsmob_music ($$)->set_property ("direction", scm_from_int (DOWN));
2550         }
2551         ;
2552
2553 post_event:
2554         post_event_nofinger
2555         | '-' fingering {
2556                 $$ = $2;
2557         }
2558         ;
2559
2560 string_number_event:
2561         E_UNSIGNED {
2562                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2563                 s->set_property ("string-number", $1);
2564                 $$ = s->unprotect ();
2565         }
2566         ;
2567
2568 direction_less_event:
2569         string_number_event
2570         | EVENT_IDENTIFIER      {
2571                 $$ = $1;
2572         }
2573         | tremolo_type  {
2574                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2575                a->set_property ("tremolo-type", $1);
2576                $$ = a->unprotect ();
2577         }
2578         | event_function_event
2579         ;
2580
2581 direction_reqd_event:
2582         gen_text_def {
2583                 $$ = $1;
2584         }
2585         | script_abbreviation {
2586                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2587                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2588                 if (scm_is_string (s))
2589                         a->set_property ("articulation-type", s);
2590                 else parser->parser_error (@1, _ ("expecting string as script definition"));
2591                 $$ = a->unprotect ();
2592         }
2593         ;
2594
2595 octave_check:
2596         /**/ { $$ = SCM_EOL; }
2597         | '=' quotes { $$ = $2; }
2598         ;
2599
2600 quotes:
2601         /* empty */
2602         {
2603                 $$ = SCM_INUM0;
2604         }
2605         | sub_quotes
2606         | sup_quotes
2607         ;
2608
2609 sup_quotes:
2610         '\'' {
2611                 $$ = scm_from_int (1);
2612         }
2613         | sup_quotes '\'' {
2614                 $$ = scm_oneplus ($1);
2615         }
2616         ;
2617
2618 sub_quotes:
2619         ',' {
2620                 $$ = scm_from_int (-1);
2621         }
2622         | sub_quotes ',' {
2623                 $$ = scm_oneminus ($1);
2624         }
2625         ;
2626
2627 steno_pitch:
2628         NOTENAME_PITCH quotes {
2629                 if (!scm_is_eq (SCM_INUM0, $2))
2630                 {
2631                         Pitch p = *unsmob_pitch ($1);
2632                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2633                         $$ = p.smobbed_copy ();
2634                 }
2635         }
2636         ;
2637
2638 /*
2639 ugh. duplication
2640 */
2641
2642 steno_tonic_pitch:
2643         TONICNAME_PITCH quotes {
2644                 if (!scm_is_eq (SCM_INUM0, $2))
2645                 {
2646                         Pitch p = *unsmob_pitch ($1);
2647                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2648                         $$ = p.smobbed_copy ();
2649                 }
2650         }
2651         ;
2652
2653 pitch:
2654         steno_pitch
2655         | PITCH_IDENTIFIER
2656         ;
2657
2658 pitch_also_in_chords:
2659         pitch
2660         | steno_tonic_pitch
2661         ;
2662
2663 gen_text_def:
2664         full_markup {
2665                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2666                 t->set_property ("text", $1);
2667                 $$ = t->unprotect ();
2668         }
2669         | STRING {
2670                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2671                 t->set_property ("text",
2672                         make_simple_markup ($1));
2673                 $$ = t->unprotect ();
2674         }
2675         | embedded_scm_closed
2676         {
2677                 Music *m = unsmob_music ($1);
2678                 if (m && m->is_mus_type ("post-event"))
2679                         $$ = $1;
2680                 else if (Text_interface::is_markup ($1)) {
2681                         Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2682                         t->set_property ("text", $1);
2683                         $$ = t->unprotect ();
2684                 } else
2685                         parser->parser_error (@1, _ ("not an articulation"));
2686         }
2687         ;
2688
2689 fingering:
2690         UNSIGNED {
2691                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2692                 t->set_property ("digit", $1);
2693                 $$ = t->unprotect ();
2694         }
2695         ;
2696
2697 script_abbreviation:
2698         '^'             {
2699                 $$ = scm_from_locale_string ("Hat");
2700         }
2701         | '+'           {
2702                 $$ = scm_from_locale_string ("Plus");
2703         }
2704         | '-'           {
2705                 $$ = scm_from_locale_string ("Dash");
2706         }
2707         | '!'           {
2708                 $$ = scm_from_locale_string ("Bang");
2709         }
2710         | ANGLE_CLOSE   {
2711                 $$ = scm_from_locale_string ("Larger");
2712         }
2713         | '.'           {
2714                 $$ = scm_from_locale_string ("Dot");
2715         }
2716         | '_' {
2717                 $$ = scm_from_locale_string ("Underscore");
2718         }
2719         ;
2720
2721 script_dir:
2722         '_'     { $$ = scm_from_int (DOWN); }
2723         | '^'   { $$ = scm_from_int (UP); }
2724         | '-'   { $$ = SCM_UNDEFINED; }
2725         ;
2726
2727 duration_length:
2728         multiplied_duration {
2729                 $$ = $1;
2730         }
2731         ;
2732
2733 maybe_notemode_duration:
2734         {
2735                 $$ = SCM_UNDEFINED;
2736         }
2737         | multiplied_duration   {
2738                 $$ = $1;
2739                 parser->default_duration_ = *unsmob_duration ($$);
2740         }
2741 ;
2742
2743
2744 optional_notemode_duration:
2745         maybe_notemode_duration
2746         {
2747                 if (SCM_UNBNDP ($$))
2748                         $$ = parser->default_duration_.smobbed_copy ();
2749         }
2750         ;
2751
2752 steno_duration:
2753         UNSIGNED dots           {
2754                 int len = 0;
2755                 int n = scm_to_int ($1);
2756                 if (!is_duration (n))
2757                         parser->parser_error (@1, _f ("not a duration: %d", n));
2758                 else
2759                         len = intlog2 (n);
2760
2761                 $$ = Duration (len, scm_to_int ($2)).smobbed_copy ();
2762         }
2763         | DURATION_IDENTIFIER dots      {
2764                 Duration *d = unsmob_duration ($1);
2765                 Duration k (d->duration_log (),
2766                             d->dot_count () + scm_to_int ($2));
2767                 k = k.compressed (d->factor ());
2768                 scm_remember_upto_here_1 ($1);
2769                 $$ = k.smobbed_copy ();
2770         }
2771         ;
2772
2773 multiplied_duration:
2774         steno_duration {
2775                 $$ = $1;
2776         }
2777         | multiplied_duration '*' UNSIGNED {
2778                 $$ = unsmob_duration ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
2779         }
2780         | multiplied_duration '*' FRACTION {
2781                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2782
2783                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2784         }
2785         ;
2786
2787 dots:
2788         /* empty */     {
2789                 $$ = SCM_INUM0;
2790         }
2791         | dots '.' {
2792                 $$ = scm_oneplus ($1);
2793         }
2794         ;
2795
2796 tremolo_type:
2797         ':'     {
2798                 $$ = SCM_INUM0;
2799         }
2800         | ':' UNSIGNED {
2801                 int n = scm_to_int ($2);
2802                 if (!is_duration (n))
2803                         parser->parser_error (@2, _f ("not a duration: %d", n));
2804                 $$ = $2;
2805         }
2806         ;
2807
2808 bass_number:
2809         UNSIGNED { $$ = $1; }
2810         | STRING { $$ = $1; }
2811         | full_markup { $$ = $1; }
2812         | embedded_scm_bare
2813         {
2814                 // as an integer, it needs to be non-negative, and otherwise
2815                 // it needs to be suitable as a markup.
2816                 if (scm_is_integer ($1)
2817                     ? scm_is_true (scm_negative_p ($1))
2818                     : !Text_interface::is_markup ($1))
2819                 {
2820                         parser->parser_error (@1, _ ("bass number expected"));
2821                         $$ = SCM_INUM0;
2822                 }
2823         }
2824         ;
2825
2826 figured_bass_alteration:
2827         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2828         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2829         | '!'   { $$ = scm_from_int (0); }
2830         ;
2831
2832 bass_figure:
2833         FIGURE_SPACE {
2834                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2835                 $$ = bfr->unprotect ();
2836         }
2837         | bass_number  {
2838                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2839                 $$ = bfr->self_scm ();
2840
2841                 if (scm_is_number ($1))
2842                         bfr->set_property ("figure", $1);
2843                 else if (Text_interface::is_markup ($1))
2844                         bfr->set_property ("text", $1);
2845
2846                 bfr->unprotect ();
2847         }
2848         | bass_figure ']' {
2849                 $$ = $1;
2850                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2851         }
2852         | bass_figure figured_bass_alteration {
2853                 Music *m = unsmob_music ($1);
2854                 if (scm_to_double ($2)) {
2855                         SCM salter = m->get_property ("alteration");
2856                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2857                         m->set_property ("alteration",
2858                                          scm_sum (alter, $2));
2859                 } else {
2860                         m->set_property ("alteration", scm_from_int (0));
2861                 }
2862         }
2863         | bass_figure figured_bass_modification  {
2864                 Music *m = unsmob_music ($1);
2865                 m->set_property ($2, SCM_BOOL_T);
2866         }
2867         ;
2868
2869
2870 figured_bass_modification:
2871         E_PLUS          {
2872                 $$ = ly_symbol2scm ("augmented");
2873         }
2874         | E_EXCLAMATION {
2875                 $$ = ly_symbol2scm ("no-continuation");
2876         }
2877         | '/'           {
2878                 $$ = ly_symbol2scm ("diminished");
2879         }
2880         | E_BACKSLASH {
2881                 $$ = ly_symbol2scm ("augmented-slash");
2882         }
2883         ;
2884
2885 br_bass_figure:
2886         bass_figure {
2887                 $$ = $1;
2888         }
2889         | '[' bass_figure {
2890                 $$ = $2;
2891                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2892         }
2893         ;
2894
2895 figure_list:
2896         /**/            {
2897                 $$ = SCM_EOL;
2898         }
2899         | figure_list br_bass_figure {
2900                 $$ = scm_cons ($2, $1);
2901         }
2902         ;
2903
2904 figure_spec:
2905         FIGURE_OPEN figure_list FIGURE_CLOSE {
2906                 $$ = scm_reverse_x ($2, SCM_EOL);
2907         }
2908         ;
2909
2910
2911 optional_rest:
2912         /**/   { $$ = SCM_BOOL_F; }
2913         | REST { $$ = SCM_BOOL_T; }
2914         ;
2915
2916 simple_element:
2917         pitch exclamations questions octave_check maybe_notemode_duration optional_rest {
2918                 if (!parser->lexer_->is_note_state ())
2919                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
2920                 if (!SCM_UNBNDP ($2)
2921                     || !SCM_UNBNDP ($3)
2922                     || scm_is_number ($4)
2923                     || !SCM_UNBNDP ($5)
2924                     || scm_is_true ($6))
2925                 {
2926                         Music *n = 0;
2927                         if (scm_is_true ($6))
2928                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
2929                         else
2930                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
2931
2932                         n->set_property ("pitch", $1);
2933                         if (SCM_UNBNDP ($5))
2934                                 n->set_property ("duration",
2935                                                  parser->default_duration_.smobbed_copy ());
2936                         else
2937                                 n->set_property ("duration", $5);
2938
2939                         if (scm_is_number ($4))
2940                         {
2941                                 int q = scm_to_int ($4);
2942                                 n->set_property ("absolute-octave", scm_from_int (q-1));
2943                         }
2944
2945                         if (to_boolean ($3))
2946                                 n->set_property ("cautionary", SCM_BOOL_T);
2947                         if (to_boolean ($2) || to_boolean ($3))
2948                                 n->set_property ("force-accidental", SCM_BOOL_T);
2949
2950                         $$ = n->unprotect ();
2951                 }
2952         }
2953         | DRUM_PITCH optional_notemode_duration {
2954                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2955                 n->set_property ("duration", $2);
2956                 n->set_property ("drum-type", $1);
2957
2958                 $$ = n->unprotect ();
2959         }
2960         | RESTNAME optional_notemode_duration           {
2961                 Music *ev = 0;
2962                 if (ly_scm2string ($1) == "s") {
2963                         /* Space */
2964                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2965                   }
2966                 else {
2967                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2968
2969                     }
2970                 ev->set_property ("duration", $2);
2971                 $$ = ev->unprotect ();
2972         }
2973         ;
2974
2975 simple_chord_elements:
2976         new_chord {
2977                 if (!parser->lexer_->is_chord_state ())
2978                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
2979                 $$ = $1;
2980         }
2981         | figure_spec optional_notemode_duration {
2982                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2983                 {
2984                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2985                 }
2986                 $$ = $1;
2987         }
2988         ;
2989
2990 lyric_element:
2991         full_markup {
2992                 $$ = $1;
2993         }
2994         | STRING {
2995                 $$ = $1;
2996         }
2997         | LYRIC_ELEMENT
2998         ;
2999
3000 lyric_element_music:
3001         lyric_element optional_notemode_duration post_events {
3002                 if (!parser->lexer_->is_lyric_state ())
3003                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
3004                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
3005                 if (scm_is_pair ($3))
3006                         unsmob_music ($$)->set_property
3007                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
3008         }
3009         ;
3010
3011 new_chord:
3012         steno_tonic_pitch optional_notemode_duration   {
3013                 $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
3014         }
3015         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
3016                 SCM its = scm_reverse_x ($4, SCM_EOL);
3017                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
3018         }
3019         ;
3020
3021 chord_items:
3022         /**/ {
3023                 $$ = SCM_EOL;
3024         }
3025         | chord_items chord_item {
3026                 $$ = scm_cons ($2, $$);
3027         }
3028         ;
3029
3030 chord_separator:
3031         CHORD_COLON {
3032                 $$ = ly_symbol2scm ("chord-colon");
3033         }
3034         | CHORD_CARET {
3035                 $$ = ly_symbol2scm ("chord-caret");
3036         }
3037         | CHORD_SLASH steno_tonic_pitch {
3038                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
3039         }
3040         | CHORD_BASS steno_tonic_pitch {
3041                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
3042         }
3043         ;
3044
3045 chord_item:
3046         chord_separator {
3047                 $$ = $1;
3048         }
3049         | step_numbers {
3050                 $$ = scm_reverse_x ($1, SCM_EOL);
3051         }
3052         | CHORD_MODIFIER  {
3053                 $$ = $1;
3054         }
3055         ;
3056
3057 step_numbers:
3058         step_number { $$ = scm_cons ($1, SCM_EOL); }
3059         | step_numbers '.' step_number {
3060                 $$ = scm_cons ($3, $$);
3061         }
3062         ;
3063
3064 step_number:
3065         UNSIGNED {
3066                 $$ = make_chord_step ($1, 0);
3067         }
3068         | UNSIGNED '+' {
3069                 $$ = make_chord_step ($1, SHARP_ALTERATION);
3070         }
3071         | UNSIGNED CHORD_MINUS {
3072                 $$ = make_chord_step ($1, FLAT_ALTERATION);
3073         }
3074         ;
3075
3076 tempo_range:
3077         UNSIGNED {
3078                 $$ = $1;
3079         }
3080         | UNSIGNED '-' UNSIGNED {
3081                 $$ = scm_cons ($1, $3);
3082         }
3083         ;
3084
3085 /*
3086         UTILITIES
3087
3088 TODO: should deprecate in favor of Scheme?
3089
3090  */
3091 number_expression:
3092         number_expression '+' number_term {
3093                 $$ = scm_sum ($1, $3);
3094         }
3095         | number_expression '-' number_term {
3096                 $$ = scm_difference ($1, $3);
3097         }
3098         | number_term
3099         ;
3100
3101 number_term:
3102         number_factor {
3103                 $$ = $1;
3104         }
3105         | number_factor '*' number_factor {
3106                 $$ = scm_product ($1, $3);
3107         }
3108         | number_factor '/' number_factor {
3109                 $$ = scm_divide ($1, $3);
3110         }
3111         ;
3112
3113 number_factor:
3114         '-'  number_factor { /* %prec UNARY_MINUS */
3115                 $$ = scm_difference ($2, SCM_UNDEFINED);
3116         }
3117         | bare_number
3118         ;
3119
3120
3121 bare_number:
3122         bare_number_closed
3123         | UNSIGNED NUMBER_IDENTIFIER    {
3124                 $$ = scm_product ($1, $2);
3125         }
3126         | REAL NUMBER_IDENTIFIER        {
3127                 $$ = scm_product ($1, $2);
3128         }
3129         ;
3130
3131 bare_number_closed:
3132         UNSIGNED
3133         | REAL
3134         | NUMBER_IDENTIFIER
3135         ;
3136
3137 unsigned_number:
3138         UNSIGNED
3139         | NUMBER_IDENTIFIER
3140         ;
3141
3142 exclamations:
3143                 { $$ = SCM_UNDEFINED; }
3144         | exclamations '!'
3145         {
3146                 if (SCM_UNBNDP ($1))
3147                         $$ = SCM_BOOL_T;
3148                 else
3149                         $$ = scm_not ($1);
3150         }
3151         ;
3152
3153 questions:
3154         { $$ = SCM_UNDEFINED; }
3155         | questions '?'
3156         {
3157                 if (SCM_UNBNDP ($1))
3158                         $$ = SCM_BOOL_T;
3159                 else
3160                         $$ = scm_not ($1);
3161         }
3162         ;
3163
3164 full_markup_list:
3165         MARKUPLIST
3166                 { parser->lexer_->push_markup_state (); }
3167         markup_list {
3168                 $$ = $3;
3169                 parser->lexer_->pop_state ();
3170         }
3171         ;
3172
3173 full_markup:
3174         MARKUP
3175                 { parser->lexer_->push_markup_state (); }
3176         markup_top {
3177                 $$ = $3;
3178                 parser->lexer_->pop_state ();
3179         }
3180         ;
3181
3182 markup_top:
3183         simple_markup_list {
3184                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
3185         }
3186         | markup_head_1_list simple_markup
3187         {
3188                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3189                                            @2, $1, scm_list_1 ($2)));
3190         }
3191         | simple_markup {
3192                 $$ = $1;
3193         }
3194         ;
3195
3196 markup_scm:
3197         embedded_scm_bare
3198         {
3199                 if (Text_interface::is_markup ($1))
3200                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
3201                 else if (Text_interface::is_markup_list ($1))
3202                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
3203                 else {
3204                         parser->parser_error (@1, _ ("not a markup"));
3205                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
3206                 }
3207         } BACKUP
3208         ;
3209
3210
3211 simple_markup_list:
3212         markup_composed_list {
3213                 $$ = $1;
3214         }
3215         | markup_uncomposed_list
3216         ;
3217
3218 markup_uncomposed_list:
3219         markup_braced_list {
3220                 $$ = $1;
3221         }
3222         | markup_command_list {
3223                 $$ = scm_list_1 ($1);
3224         }
3225         | markup_scm MARKUPLIST_IDENTIFIER
3226         {
3227                 $$ = $2;
3228         }
3229         ;
3230
3231 markup_list:
3232         simple_markup_list
3233         | markup_score
3234         {
3235                 $$ = scm_list_1 (scm_list_2 (ly_lily_module_constant ("score-lines-markup-list"), $1));
3236         }
3237         ;
3238
3239 markup_score:
3240         SCORE {
3241                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3242                 parser->lexer_->push_note_state (nn);
3243         } '{' score_body '}' {
3244                 $$ = $4;
3245                 parser->lexer_->pop_state ();
3246         }
3247         ;
3248
3249 markup_composed_list:
3250         markup_head_1_list markup_uncomposed_list {
3251                 $$ = MAKE_SYNTAX ("composed-markup-list",
3252                                   @2, $1, $2);
3253         }
3254         ;
3255
3256 markup_braced_list:
3257         '{' markup_braced_list_body '}' {
3258                 $$ = scm_reverse_x ($2, SCM_EOL);
3259         }
3260         ;
3261
3262 markup_braced_list_body:
3263         /* empty */     {  $$ = SCM_EOL; }
3264         | markup_braced_list_body markup {
3265                 $$ = scm_cons ($2, $1);
3266         }
3267         | markup_braced_list_body simple_markup_list {
3268                 $$ = scm_reverse_x ($2, $1);
3269         }
3270         ;
3271
3272 markup_command_list:
3273         MARKUP_LIST_FUNCTION markup_command_list_arguments {
3274           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
3275         }
3276         ;
3277
3278 markup_command_basic_arguments:
3279         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
3280           $$ = scm_cons ($3, $2);
3281         }
3282         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
3283           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
3284         }
3285         | EXPECT_NO_MORE_ARGS {
3286           $$ = SCM_EOL;
3287         }
3288         ;
3289
3290 markup_command_list_arguments:
3291         markup_command_basic_arguments { $$ = $1; }
3292         | EXPECT_MARKUP markup_command_list_arguments markup {
3293           $$ = scm_cons ($3, $2);
3294         }
3295         ;
3296
3297 markup_head_1_item:
3298         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
3299           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
3300         }
3301         ;
3302
3303 markup_head_1_list:
3304         markup_head_1_item      {
3305                 $$ = scm_list_1 ($1);
3306         }
3307         | markup_head_1_list markup_head_1_item {
3308                 $$ = scm_cons ($2, $1);
3309         }
3310         ;
3311
3312 simple_markup:
3313         STRING {
3314                 $$ = make_simple_markup ($1);
3315         }
3316         | MARKUP_FUNCTION markup_command_basic_arguments {
3317                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3318         }
3319         | markup_scm MARKUP_IDENTIFIER
3320         {
3321                 $$ = $2;
3322         }
3323         | markup_score
3324         {
3325                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $1);
3326         }
3327         ;
3328
3329 markup:
3330         markup_head_1_list simple_markup
3331         {
3332                 $$ = scm_car (MAKE_SYNTAX ("composed-markup-list",
3333                                            @2, $1, scm_list_1 ($2)));
3334         }
3335         | simple_markup {
3336                 $$ = $1;
3337         }
3338         ;
3339
3340 %%
3341
3342 void
3343 Lily_parser::set_yydebug (bool x)
3344 {
3345         yydebug = x;
3346 }
3347
3348 SCM
3349 Lily_parser::do_yyparse ()
3350 {
3351         SCM retval = SCM_UNDEFINED;
3352         yyparse (this, &retval);
3353         return retval;
3354 }
3355
3356
3357
3358
3359
3360 /*
3361
3362 It is a little strange to have this function in this file, but
3363 otherwise, we have to import music classes into the lexer.
3364
3365 */
3366 int
3367 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3368 {
3369         if (unsmob_book (sid)) {
3370                 Book *book =  unsmob_book (sid)->clone ();
3371                 *destination = book->self_scm ();
3372                 book->unprotect ();
3373
3374                 return BOOK_IDENTIFIER;
3375         } else if (scm_is_number (sid)) {
3376                 *destination = sid;
3377                 return NUMBER_IDENTIFIER;
3378         } else if (unsmob_context_def (sid)) {
3379                 Context_def *def= unsmob_context_def (sid)->clone ();
3380
3381                 *destination = def->self_scm ();
3382                 def->unprotect ();
3383
3384                 return CONTEXT_DEF_IDENTIFIER;
3385         } else if (unsmob_context_mod (sid)) {
3386                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
3387
3388                 return CONTEXT_MOD_IDENTIFIER;
3389         } else if (Music *mus = unsmob_music (sid)) {
3390                 mus = mus->clone ();
3391                 *destination = mus->self_scm ();
3392                 bool is_event = mus->is_mus_type ("post-event");
3393                 mus->unprotect ();
3394                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3395         } else if (unsmob_pitch (sid)) {
3396                 *destination = unsmob_pitch (sid)->smobbed_copy ();
3397                 return PITCH_IDENTIFIER;
3398         } else if (unsmob_duration (sid)) {
3399                 *destination = unsmob_duration (sid)->smobbed_copy ();
3400                 return DURATION_IDENTIFIER;
3401         } else if (unsmob_output_def (sid)) {
3402                 Output_def *p = unsmob_output_def (sid);
3403                 p = p->clone ();
3404
3405                 *destination = p->self_scm ();
3406                 p->unprotect ();
3407                 return OUTPUT_DEF_IDENTIFIER;
3408         }
3409
3410         return -1;
3411 }
3412
3413 SCM
3414 get_next_unique_context_id ()
3415 {
3416         return scm_from_locale_string ("$uniqueContextId");
3417 }
3418
3419
3420 SCM
3421 get_next_unique_lyrics_context_id ()
3422 {
3423         static int new_context_count;
3424         char s[128];
3425         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3426         return scm_from_locale_string (s);
3427 }
3428
3429 // check_scheme_arg checks one argument with a given predicate for use
3430 // in an argument list and throws a syntax error if it is unusable.
3431 // The argument is prepended to the argument list in any case.  After
3432 // throwing a syntax error, the argument list is terminated with #f as
3433 // its last cdr in order to mark it as uncallable while not losing
3434 // track of its total length.
3435 //
3436 // There are a few special considerations: if optional argument disp
3437 // is given (otherwise it defaults to SCM_UNDEFINED), it will be used
3438 // instead of arg in a prospective error message.  This is useful if
3439 // arg is not the actual argument but rather a transformation of it.
3440 //
3441 // If arg itself is SCM_UNDEFINED, the predicate is considered false
3442 // and an error message using disp is produced unconditionally.
3443
3444 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3445                       SCM arg, SCM args, SCM pred, SCM disp)
3446 {
3447         if (SCM_UNBNDP (arg))
3448                 args = scm_cons (disp, args);
3449         else {
3450                 args = scm_cons (arg, args);
3451                 if (scm_is_true (scm_call_1 (pred, arg)))
3452                         return args;
3453         }
3454         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3455         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred,
3456                      SCM_UNBNDP (disp) ? arg : disp);
3457         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3458         return args;
3459 }
3460
3461 SCM loc_on_music (Input loc, SCM arg)
3462 {
3463         if (Music *m = unsmob_music (arg))
3464         {
3465                 m = m->clone ();
3466                 m->set_spot (loc);
3467                 return m->unprotect ();
3468         }
3469         return arg;
3470 }
3471
3472 SCM
3473 try_string_variants (SCM pred, SCM str)
3474 {
3475         // a matching predicate is always ok
3476         if (scm_is_true (scm_call_1 (pred, str)))
3477                 return str;
3478         // a symbol may be interpreted as a list of symbols if it helps
3479         if (scm_is_symbol (str)) {
3480                 str = scm_list_1 (str);
3481                 if (scm_is_true (scm_call_1 (pred, str)))
3482                         return str;
3483                 return SCM_UNDEFINED;
3484         }
3485
3486         // If this cannot be a string representation of a symbol list,
3487         // we are through.
3488
3489         if (!is_regular_identifier (str, true))
3490                 return SCM_UNDEFINED;
3491
3492         str = scm_string_split (str, SCM_MAKE_CHAR ('.'));
3493         for (SCM p = str; scm_is_pair (p); p = scm_cdr (p))
3494                 scm_set_car_x (p, scm_string_to_symbol (scm_car (p)));
3495
3496         // Let's attempt the symbol list interpretation first.
3497
3498         if (scm_is_true (scm_call_1 (pred, str)))
3499                 return str;
3500
3501         // If there is just one symbol in the list, we might interpret
3502         // it as a single symbol
3503
3504         if (scm_is_null (scm_cdr (str)))
3505         {
3506                 str = scm_car (str);
3507                 if (scm_is_true (scm_call_1 (pred, str)))
3508                         return str;
3509         }
3510
3511         return SCM_UNDEFINED;
3512 }
3513
3514 bool
3515 is_regular_identifier (SCM id, bool multiple)
3516 {
3517   if (!scm_is_string (id))
3518           return false;
3519
3520   string str = ly_scm2string (id);
3521
3522   bool middle = false;
3523
3524   for (string::iterator it=str.begin(); it != str.end (); it++)
3525   {
3526           int c = *it & 0xff;
3527           if ((c >= 'a' && c <= 'z')
3528               || (c >= 'A' && c <= 'Z')
3529               || c > 0x7f)
3530                   middle = true;
3531           else if (middle && (c == '-' || c == '_' || (multiple && c == '.')))
3532                   middle = false;
3533           else
3534                   return false;
3535   }
3536   return middle;
3537 }
3538
3539 SCM
3540 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3541 {
3542         if (unsmob_music (simple))
3543                 return simple;
3544         if (parser->lexer_->is_note_state ()) {
3545                 if (scm_is_symbol (simple)) {
3546                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3547                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3548                         n->set_property ("drum-type", simple);
3549                         return n->unprotect ();
3550                 }
3551                 if (unsmob_pitch (simple)) {
3552                         Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3553                         n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3554                         n->set_property ("pitch", simple);
3555                         return n->unprotect ();
3556                 }
3557                 return simple;
3558         } else if (parser->lexer_->is_lyric_state ()) {
3559                 if (Text_interface::is_markup (simple))
3560                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3561                                             parser->default_duration_.smobbed_copy ());
3562         } else if (parser->lexer_->is_chord_state ()) {
3563                 if (unsmob_pitch (simple))
3564                         return make_chord_elements (loc, simple,
3565                                                     parser->default_duration_.smobbed_copy (),
3566                                                     SCM_EOL);
3567         }
3568         return simple;
3569 }
3570
3571 Music *
3572 make_music_with_input (SCM name, Input where)
3573 {
3574        Music *m = make_music_by_name (name);
3575        m->set_spot (where);
3576        return m;
3577 }
3578
3579 SCM
3580 make_simple_markup (SCM a)
3581 {
3582         return a;
3583 }
3584
3585 bool
3586 is_duration (int t)
3587 {
3588   return t && t == 1 << intlog2 (t);
3589 }
3590
3591 SCM
3592 make_chord_step (SCM step_scm, Rational alter)
3593 {
3594         int step = scm_to_int (step_scm);
3595
3596         if (step == 7)
3597                 alter += FLAT_ALTERATION;
3598
3599         while (step < 0)
3600                 step += 7;
3601         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3602         return m.smobbed_copy ();
3603 }
3604
3605
3606 SCM
3607 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3608 {
3609         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3610         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3611         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3612         {
3613                 unsmob_music (scm_car (s))->set_spot (loc);
3614         }
3615         return res;
3616 }
3617
3618 int
3619 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3620 {
3621         Lily_lexer *lex = parser->lexer_;
3622
3623         lex->lexval_ = s;
3624         lex->lexloc_ = loc;
3625         lex->prepare_for_next_token ();
3626         return lex->yylex ();
3627 }