lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2001 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Two shift/reduce problems:
  14     -
  15     -
  16  */
  17
  18 /*
  19
  20 the rules for who is protecting what are very shady. TODO: uniformise
  21 this.
  22
  23
  24 */
  25
  26 #include <ctype.h>
  27 #include <iostream.h>
  28
  29 #include "translator-def.hh"
  30 #include "lily-guile.hh"
  31 #include "change-iterator.hh"
  32 #include "misc.hh"
  33 #include "my-lily-lexer.hh"
  34 #include "paper-def.hh"
  35 #include "midi-def.hh"
  36 #include "main.hh"
  37 #include "file-path.hh"
  38 #include "debug.hh"
  39 #include "dimensions.hh"
  40 #include "command-request.hh"
  41 #include "musical-request.hh"
  42 #include "my-lily-parser.hh"
  43 #include "context-specced-music.hh"
  44 #include "score.hh"
  45 #include "music-list.hh"
  46 #include "output-property-music-iterator.hh"
  47 #include "property-iterator.hh"
  48 #include "file-results.hh"
  49 #include "input.hh"
  50 #include "relative-music.hh"
  51 #include "lyric-combine-music.hh"
  52 #include "transposed-music.hh"
  53 #include "time-scaled-music.hh"
  54 #include "repeated-music.hh"
  55 #include "untransposable-music.hh"
  56 #include "lilypond-input-version.hh"
  57 #include "grace-music.hh"
  58 #include "part-combine-music.hh"
  59 #include "scm-hash.hh"
  60 #include "auto-change-iterator.hh"
  61 #include "un-relativable-music.hh"
  62 #include "chord.hh"
  63
  64 bool
  65 regular_identifier_b (SCM id)
  66 {
  67   String str = ly_scm2string (id);
  68   char const *s = str.ch_C() ;
  69
  70   bool v = true;
  71   while (*s && v)
  72    {
  73         v = v && isalpha (*s);
  74         s++;
  75    }
  76   return v;
  77 }
  78
  79
  80 Music*
  81 set_property_music (SCM sym, SCM value)
  82 {
  83         Music * p = new Music (SCM_EOL);
  84         p->set_mus_property ("symbol", sym);
  85         p->set_mus_property ("iterator-ctor",
  86         Property_iterator::constructor_cxx_function);
  87
  88         p->set_mus_property ("value", value);
  89         return p;
  90 }
  91
  92 bool
  93 is_duration_b (int t)
  94 {
  95   return t && t == 1 << intlog2 (t);
  96 }
  97
  98 void
  99 set_music_properties (Music *p, SCM a)
 100 {
 101   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 102         {
 103         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 104         }
 105 }
 106
 107
 108
 109
 110
 111
 112
 113 // needed for bison.simple's malloc () and free ()
 114
 115 #include <malloc.h>
 116 #include <stdlib.h>
 117
 118
 119 #ifndef NDEBUG
 120 #define YYDEBUG 1
 121 #endif
 122
 123 #define YYERROR_VERBOSE 1
 124
 125 #define YYPARSE_PARAM my_lily_parser_l
 126 #define YYLEX_PARAM my_lily_parser_l
 127 #define THIS\
 128         ((My_lily_parser *) my_lily_parser_l)
 129
 130 #define yyerror THIS->parser_error
 131 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
 132
 133 %}
 134
 135 /* We use SCMs to do strings, because it saves us the trouble of
 136 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 137 of the parse stack onto the heap. */
 138
 139
 140 %union {
 141
 142     Link_array<Request> *reqvec;
 143
 144     String *string; // needed by the lexer as temporary scratch area.
 145     Music *music;
 146     Score *score;
 147     Scheme_hash_table *scmhash;
 148     Music_output_def * outputdef;
 149
 150     Request * request;
 151
 152     SCM scm;
 153
 154     Tempo_req *tempo;
 155     int i;
 156 }
 157 %{
 158
 159 int
 160 yylex (YYSTYPE *s,  void * v_l)
 161 {
 162         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 163         My_lily_lexer * lex_l = pars_l->lexer_p_;
 164
 165         lex_l->lexval_l = (void*) s;
 166         return lex_l->yylex ();
 167 }
 168
 169
 170 %}
 171
 172 %pure_parser
 173
 174 /* tokens which are not keywords */
 175 %token AUTOCHANGE
 176 %token ALIAS
 177 %token APPLY
 178 %token ARPEGGIO
 179 %token DYNAMICSCRIPT
 180 %token ACCEPTS
 181 %token ALTERNATIVE
 182 %token BAR
 183 %token BREATHE
 184 %token CHORDMODIFIERS
 185 %token CHORDS
 186 %token CHAR_T
 187 %token CLEF
 188 %token CM_T
 189 %token CONSISTS
 190 %token DURATION
 191 %token SEQUENTIAL
 192 %token GROBDESCRIPTIONS
 193 %token SIMULTANEOUS
 194 %token CONSISTSEND
 195 %token DENIES
 196 %token DURATION
 197 %token EXTENDER
 198 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 199 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 200 %token GLISSANDO
 201 %token GRACE
 202 %token HEADER
 203 %token HYPHEN
 204 %token IN_T
 205 %token INVALID
 206 %token KEY
 207 %token LYRICS
 208 %token MARK
 209 %token MULTI_MEASURE_REST
 210 %token MIDI
 211 %token MM_T
 212 %token PITCH
 213 %token DEFAULT
 214 %token NAME
 215 %token PITCHNAMES
 216 %token NOTES
 217 %token PAPER
 218 %token PARTIAL
 219 %token PENALTY
 220 %token PROPERTY
 221 %token OVERRIDE SET REVERT
 222 %token PT_T
 223 %token RELATIVE
 224 %token REMOVE
 225 %token REPEAT
 226 %token ADDLYRICS
 227 %token PARTCOMBINE
 228 %token SCM_T
 229 %token SCORE
 230 %token SCRIPT
 231 %token SKIP
 232 %token SPANREQUEST
 233 %token STYLESHEET
 234 %token COMMANDSPANREQUEST
 235 %token TEMPO
 236 %token OUTPUTPROPERTY
 237 %token TIME_T
 238 %token TIMES
 239 %token TRANSLATOR
 240 %token TRANSPOSE
 241 %token TYPE
 242 %token UNSET
 243 %token CONTEXT
 244 %token REST
 245
 246 /* escaped */
 247 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 248 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 249 %token E_BACKSLASH
 250 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 251 %token FIGURE_SPACE
 252
 253
 254 %type <i>       exclamations questions dots optional_rest
 255 %type <i>       bass_number bass_mod
 256 %type <scm>     br_bass_figure bass_figure figure_list figure_spec
 257 %token <i>      DIGIT
 258 %token <scm>    NOTENAME_PITCH
 259 %token <scm>    TONICNAME_PITCH
 260 %token <scm>    CHORDMODIFIER_PITCH
 261 %token <scm>    DURATION_IDENTIFIER
 262 %token <scm>    FRACTION
 263 %token <id>     IDENTIFIER
 264
 265
 266 %token <scm>    SCORE_IDENTIFIER
 267 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 268
 269 %token <scm>    NUMBER_IDENTIFIER
 270 %token <scm>    REQUEST_IDENTIFIER
 271 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 272 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 273 %token <scm>    RESTNAME
 274 %token <scm>    STRING
 275 %token <scm>    SCM_T
 276 %token <i>      UNSIGNED
 277 %token <scm>   REAL
 278
 279 %type <outputdef> output_def
 280 %type <scmhash>         lilypond_header lilypond_header_body
 281 %type <request> open_request_parens close_request_parens open_request close_request
 282 %type <request> request_with_dir request_that_take_dir verbose_request
 283 %type <i>       sub_quotes sup_quotes
 284 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 285 %type <music>   Repeated_music
 286 %type <scm>     Alternative_music
 287 %type <i>       tremolo_type
 288 %type <i>       bare_int  bare_unsigned
 289 %type <i>       script_dir
 290
 291 %type <scm>     identifier_init
 292
 293 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 294 %type <scm>  verbose_duration
 295
 296 %type <reqvec>  pre_requests post_requests
 297 %type <request> gen_text_def
 298 %type <scm>   steno_pitch pitch absolute_pitch
 299 %type <scm>   explicit_pitch steno_tonic_pitch
 300
 301 %type <scm>     chord_additions chord_subtractions chord_notes chord_step
 302 %type <music>   chord
 303 %type <scm>     chord_note chord_inversion chord_bass
 304 %type <scm>     duration_length fraction
 305
 306 %type <scm>  embedded_scm scalar
 307 %type <music>   Music Sequential_music Simultaneous_music
 308 %type <music>   relative_music re_rhythmed_music part_combined_music
 309 %type <music>   property_def translator_change
 310 %type <scm> Music_list
 311 %type <outputdef>  music_output_def_body
 312 %type <request> shorthand_command_req
 313 %type <request> post_request
 314 %type <music> command_req verbose_command_req
 315 %type <request> extender_req
 316 %type <request> hyphen_req
 317 %type <scm>     string bare_number number_expression number_term number_factor
 318
 319 %type <score>   score_block score_body
 320
 321 %type <scm>     translator_spec_block translator_spec_body
 322 %type <tempo>   tempo_request
 323 %type <scm> notenames_body notenames_block chordmodifiers_block
 324 %type <scm>     script_abbreviation
 325
 326
 327
 328 %left '-' '+'
 329
 330 /* We don't assign precedence to / and *, because we might need varied
 331 prec levels in different prods */
 332
 333 %left UNARY_MINUS
 334
 335 %%
 336
 337 lilypond:       /* empty */
 338         | lilypond toplevel_expression {}
 339         | lilypond assignment  { }
 340         | lilypond error {
 341                 THIS->error_level_i_  = 1;
 342         }
 343         | lilypond INVALID      {
 344                 THIS->error_level_i_  = 1;
 345         }
 346         ;
 347
 348 toplevel_expression:
 349         notenames_block                 {
 350                 THIS->lexer_p_->pitchname_tab_ =  $1;
 351         }
 352         | chordmodifiers_block                  {
 353                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 354         }
 355         | lilypond_header {
 356                 if (global_header_p)
 357                         scm_gc_unprotect_object (global_header_p->self_scm ());
 358                 global_header_p = $1;
 359         }
 360         | score_block {
 361                 score_global_array.push ($1);
 362         }
 363         | output_def {
 364                 if (dynamic_cast<Paper_def*> ($1))
 365                         THIS->lexer_p_->set_identifier (gh_str02scm ("$defaultpaper"), $1->self_scm ());
 366                 else if (dynamic_cast<Midi_def*> ($1))
 367                         THIS->lexer_p_->set_identifier (gh_str02scm ("$defaultmidi"), $1->self_scm ());
 368         }
 369         | embedded_scm {
 370                 // junk value
 371         }
 372         ;
 373
 374 embedded_scm:
 375         SCM_T
 376         | SCM_IDENTIFIER
 377         ;
 378
 379
 380 chordmodifiers_block:
 381         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 382         ;
 383
 384 notenames_block:
 385         PITCHNAMES notenames_body   {  $$ = $2; }
 386         ;
 387
 388 notenames_body:
 389         embedded_scm    {
 390           int i = scm_ilength ($1);
 391
 392           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 393           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 394                 SCM pt = ly_cdar (s);
 395                 if (!unsmob_pitch (pt))
 396                         THIS->parser_error ("Need pitch object.");
 397                 else
 398                         scm_hashq_set_x (tab, ly_caar (s), pt);
 399           }
 400
 401           $$ = tab;
 402         }
 403         ;
 404
 405 lilypond_header_body:
 406         {
 407                 $$ = new Scheme_hash_table;
 408                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 409         }
 410         | lilypond_header_body assignment  {
 411
 412         }
 413         ;
 414
 415 lilypond_header:
 416         HEADER '{' lilypond_header_body '}'     {
 417                 $$ = $3;
 418                 THIS->lexer_p_->scope_l_arr_.pop ();
 419         }
 420         ;
 421
 422
 423 /*
 424         DECLARATIONS
 425 */
 426 assignment:
 427         STRING {
 428                 THIS->push_spot ();
 429         }
 430         /* cont */ '=' identifier_init  {
 431
 432         /*
 433                 Should find generic way of associating input with objects.
 434         */
 435                 Input ip = THIS->pop_spot ();
 436
 437                 if (! regular_identifier_b ($1))
 438                 {
 439                         ip.warning (_ ("Identifier should have  alphabetic characters only"));
 440                 }
 441
 442                 THIS->lexer_p_->set_identifier ($1, $4);
 443
 444 /*
 445  TODO: devise standard for protection in parser.
 446
 447   The parser stack lives on the C-stack, which means that
 448 all objects can be unprotected as soon as they're here.
 449
 450 */
 451         }
 452         ;
 453
 454
 455
 456 identifier_init:
 457         score_block {
 458                 $$ = $1->self_scm ();
 459                 scm_gc_unprotect_object ($$);
 460         }
 461         | output_def {
 462                 $$ = $1->self_scm ();
 463                 scm_gc_unprotect_object ($$);
 464         }
 465         | translator_spec_block {
 466                 $$ = $1;
 467         }
 468         | Music  {
 469                 $$ = $1->self_scm ();
 470                 scm_gc_unprotect_object ($$);
 471         }
 472         | post_request {
 473                 $$ = $1->self_scm ();
 474                 scm_gc_unprotect_object ($$);
 475         }
 476         | verbose_duration {
 477                 $$ = $1;
 478         }
 479         | number_expression {
 480                 $$ = $1;
 481         }
 482         | string {
 483                 $$ = $1;
 484         }
 485         | embedded_scm  {
 486                 $$ = $1;
 487         }
 488         ;
 489
 490 translator_spec_block:
 491         TRANSLATOR '{' translator_spec_body '}'
 492                 {
 493                 $$ = $3;
 494         }
 495         ;
 496
 497 translator_spec_body:
 498         TRANSLATOR_IDENTIFIER   {
 499                 $$ = unsmob_translator_def ($1)->clone_scm ();
 500                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 501         }
 502         | TYPE STRING   {
 503                 $$ = Translator_def::make_scm ();
 504                 Translator_def*td =  unsmob_translator_def ($$);
 505                 td->translator_group_type_ = $2;
 506                 td->set_spot (THIS->here_input ());
 507         }
 508         | translator_spec_body STRING '=' embedded_scm                  {
 509                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 510         }
 511         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 512                 unsmob_translator_def ($$)
 513                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 514         }
 515         | translator_spec_body STRING REVERT embedded_scm  {
 516           unsmob_translator_def ($$)->add_pop_property (
 517                 scm_string_to_symbol ($2), $4);
 518         }
 519         | translator_spec_body NAME STRING  {
 520                 unsmob_translator_def ($$)->type_name_ = $3;
 521         }
 522         | translator_spec_body CONSISTS STRING  {
 523                 unsmob_translator_def ($$)->add_element ($3);
 524         }
 525         | translator_spec_body ALIAS STRING  {
 526                 Translator_def*td = unsmob_translator_def ($$);
 527                 td->type_aliases_ = gh_cons ($3, td->type_aliases_);
 528         }
 529         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 530                 Translator_def*td = unsmob_translator_def($$);
 531                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 532                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 533                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 534         }
 535         | translator_spec_body CONSISTSEND STRING  {
 536                 unsmob_translator_def ($$)->add_last_element ( $3);
 537         }
 538         | translator_spec_body ACCEPTS STRING  {
 539                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 540         }
 541         | translator_spec_body DENIES STRING  {
 542                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 543         }
 544         | translator_spec_body REMOVE STRING  {
 545                 unsmob_translator_def ($$)->remove_element ($3);
 546         }
 547         ;
 548
 549 /*
 550         SCORE
 551 */
 552 score_block:
 553         SCORE {
 554                 THIS->push_spot ();
 555         }
 556         /*cont*/ '{' score_body '}'     {
 557                 THIS->pop_spot ();
 558                 $$ = $4;
 559                 if (!$$->def_p_arr_.size ())
 560                 {
 561                   Music_output_def *id =
 562                         unsmob_music_output_def (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 563                   $$->add_output (id ? id->clone () :  new Paper_def );
 564                 }
 565         }
 566         ;
 567
 568 score_body:
 569         Music   {
 570                 $$ = new Score;
 571
 572                 $$->set_spot (THIS->here_input ());
 573                 SCM m = $1->self_scm ();
 574                 scm_gc_unprotect_object (m);
 575                 $$->music_ = m;
 576         }
 577         | SCORE_IDENTIFIER {
 578                 $$ = new Score (*unsmob_score ($1));
 579                 $$->set_spot (THIS->here_input ());
 580         }
 581         | score_body lilypond_header    {
 582                 scm_gc_unprotect_object ($2->self_scm ());
 583                 $$->header_p_ = $2;
 584         }
 585         | score_body output_def {
 586                 $$->add_output ($2);
 587         }
 588         | score_body error {
 589
 590         }
 591         ;
 592
 593
 594 /*
 595         MIDI
 596 */
 597 output_def:
 598         music_output_def_body '}' {
 599                 $$ = $1;
 600                 THIS-> lexer_p_-> scope_l_arr_.pop ();
 601         }
 602         ;
 603
 604 music_output_def_body:
 605         MIDI '{'    {
 606            Music_output_def *id = unsmob_music_output_def (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 607
 608
 609          Midi_def* p =0;
 610         if (id)
 611                 p = dynamic_cast<Midi_def*> (id->clone ());
 612         else
 613                 p = new Midi_def;
 614
 615          $$ = p;
 616          THIS->lexer_p_->scope_l_arr_.push (p->variable_tab_);
 617         }
 618         | PAPER '{'     {
 619                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 620                   Paper_def *p = 0;
 621                 if (id)
 622                         p = dynamic_cast<Paper_def*> (id->clone ());
 623                 else
 624                         p = new Paper_def;
 625                 THIS-> lexer_p_-> scope_l_arr_.push (p->variable_tab_);
 626                 $$ = p;
 627         }
 628         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 629                 Music_output_def *p = unsmob_music_output_def ($3);
 630                 p = p->clone ();
 631                 THIS->lexer_p_->scope_l_arr_.push (p->variable_tab_);
 632                 $$ = p;
 633         }
 634         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 635                 Music_output_def *p = unsmob_music_output_def ($3);
 636                 p = p->clone ();
 637
 638                 THIS->lexer_p_->scope_l_arr_.push (p->variable_tab_);
 639                 $$ = p;
 640         }
 641         | music_output_def_body assignment  {
 642
 643         }
 644         | music_output_def_body translator_spec_block   {
 645                 $$->assign_translator ($2);
 646         }
 647         | music_output_def_body STYLESHEET embedded_scm {
 648                 dynamic_cast<Paper_def*> ($$)-> style_sheet_ = $3;
 649         }
 650         | music_output_def_body tempo_request  {
 651                 /*
 652                         junk this ? there already is tempo stuff in
 653                         music.
 654                 */
 655                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 656                 Duration *d = unsmob_duration ($2->get_mus_property ("duration"));
 657                 dynamic_cast<Midi_def*> ($$)->set_tempo (d->length_mom (), m);
 658         }
 659         | music_output_def_body error {
 660
 661         }
 662         ;
 663
 664 tempo_request:
 665         TEMPO steno_duration '=' bare_unsigned  {
 666                 $$ = new Tempo_req;
 667                 $$->set_mus_property ("duration", $2);
 668                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 669         }
 670         ;
 671
 672 /*
 673 The representation of a  list is the
 674
 675   (LIST . LAST-CONS)
 676
 677  to have  efficient append.
 678 */
 679 Music_list: /* empty */ {
 680                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 681         }
 682         | Music_list Music {
 683                 SCM s = $$;
 684                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 685                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 686                 if (gh_pair_p (ly_cdr (s)))
 687                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 688                 else
 689                         gh_set_car_x (s, c); /* set first cons */
 690                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 691         }
 692         | Music_list error {
 693         }
 694         ;
 695
 696
 697 Music:
 698         Simple_music
 699         | Composite_music
 700         ;
 701
 702 Alternative_music:
 703         /* empty */ {
 704                 $$ = SCM_EOL;
 705         }
 706         | ALTERNATIVE '{' Music_list '}' {
 707                 $$ = $3;
 708         }
 709         ;
 710
 711 Repeated_music:
 712         REPEAT string bare_unsigned Music Alternative_music
 713         {
 714                 Music *beg = $4;
 715                 int times = $3;
 716                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 717                 if (times < scm_ilength (alts)) {
 718                   unsmob_music (gh_car (alts))
 719                     ->origin ()->warning (
 720                     _("More alternatives than repeats.  Junking excess alternatives."));
 721                   alts = ly_truncate_list (times, alts);
 722                 }
 723
 724                 Repeated_music * r = new Repeated_music (SCM_EOL);
 725                 if (beg)
 726                         {
 727                         r-> set_mus_property ("element", beg->self_scm ());
 728                         scm_gc_unprotect_object (beg->self_scm ());
 729                         }
 730                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 731
 732                 r-> set_mus_property ("elements",alts);
 733                 SCM func = scm_primitive_eval (ly_symbol2scm ("repeat-name-to-ctor"));
 734                 SCM result = gh_call1 (func, $2);
 735
 736                 set_music_properties (r, result);
 737
 738                 r->set_spot (*$4->origin ());
 739                 $$ = r;
 740         }
 741         ;
 742
 743 Sequential_music:
 744         SEQUENTIAL '{' Music_list '}'           {
 745                 $$ = new Sequential_music (SCM_EOL);
 746                 $$->set_mus_property ("elements", ly_car ($3));
 747         }
 748         | '{' Music_list '}'            {
 749                 $$ = new Sequential_music (SCM_EOL);
 750                 $$->set_mus_property ("elements", ly_car ($2));
 751         }
 752         ;
 753
 754 Simultaneous_music:
 755         SIMULTANEOUS '{' Music_list '}'{
 756                 $$ = new Simultaneous_music (SCM_EOL);
 757                 $$->set_mus_property ("elements", ly_car ($3));
 758
 759         }
 760         | '<' Music_list '>'    {
 761                 $$ = new Simultaneous_music (SCM_EOL);
 762                 $$->set_mus_property ("elements", ly_car ($2));
 763         }
 764         ;
 765
 766 Simple_music:
 767         request_chord           { $$ = $1; }
 768         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 769                 SCM pred = $2;
 770                 if (!gh_symbol_p ($3))
 771                 {
 772                         THIS->parser_error (_ ("Second argument must be a symbol"));
 773                 }
 774                 /*hould check # args */
 775                 if (!gh_procedure_p (pred))
 776                 {
 777                         THIS->parser_error (_ ("First argument must be a procedure taking 1 argument"));
 778                 }
 779
 780                 Music *m = new Music (SCM_EOL);
 781                 m->set_mus_property ("predicate", pred);
 782                 m->set_mus_property ("grob-property", $3);
 783                 m->set_mus_property ("grob-value",  $5);
 784                 m->set_mus_property ("iterator-ctor",
 785                 Output_property_music_iterator::constructor_cxx_function);
 786
 787                 $$ = m;
 788         }
 789         | MUSIC_IDENTIFIER {
 790                 $$ = unsmob_music ($1)->clone ();
 791         }
 792         | property_def
 793         | translator_change
 794         ;
 795
 796
 797 Composite_music:
 798         CONTEXT STRING Music    {
 799                 Context_specced_music *csm =  new Context_specced_music (SCM_EOL);
 800                 csm->set_mus_property ("element", $3->self_scm ());
 801                 scm_gc_unprotect_object ($3->self_scm ());
 802
 803                 csm->set_mus_property ("context-type",$2);
 804                 csm->set_mus_property ("context-id", ly_str02scm (""));
 805
 806                 $$ = csm;
 807         }
 808         | AUTOCHANGE STRING Music       {
 809                 Music * chm = new Music_wrapper (SCM_EOL);
 810                 chm->set_mus_property ("element", $3->self_scm ());
 811                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_cxx_function);
 812
 813                 scm_gc_unprotect_object ($3->self_scm ());
 814                 chm->set_mus_property ("what", $2);
 815
 816                 $$ = chm;
 817                 chm->set_spot (*$3->origin ());
 818         }
 819         | GRACE Music {
 820 #if 1
 821         /*
 822                 The other version is for easier debugging  of
 823                 Sequential_music_iterator in combination with grace notes.
 824         */
 825
 826                 SCM start = THIS->lexer_p_->lookup_identifier ("startGraceMusic");
 827                 SCM stop = THIS->lexer_p_->lookup_identifier ("stopGraceMusic");
 828                 Music *startm = unsmob_music (start);
 829                 Music *stopm = unsmob_music (stop);
 830
 831                 SCM ms = SCM_EOL;
 832                 if (stopm) {
 833                         stopm = stopm->clone ();
 834                         ms = gh_cons (stopm->self_scm (), ms);
 835                         scm_gc_unprotect_object (stopm->self_scm ());
 836                 }
 837                 ms = gh_cons ($2->self_scm (), ms);
 838                 scm_gc_unprotect_object ($2->self_scm());
 839                 if (startm) {
 840                         startm = startm->clone ();
 841                         ms = gh_cons (startm->self_scm () , ms);
 842                         scm_gc_unprotect_object (startm->self_scm ());
 843                 }
 844
 845                 Music* seq = new Sequential_music (SCM_EOL);
 846                 seq->set_mus_property ("elements", ms);
 847
 848                 $$ = new Grace_music (SCM_EOL);
 849                 $$->set_mus_property ("element", seq->self_scm ());
 850                 scm_gc_unprotect_object (seq->self_scm ());
 851 #else
 852                 $$ = new Grace_music (SCM_EOL);
 853                 $$->set_mus_property ("element", $2->self_scm ());
 854                 scm_gc_unprotect_object ($2->self_scm ());
 855 #endif
 856         }
 857         | CONTEXT string '=' string Music {
 858                 Context_specced_music *csm =  new Context_specced_music (SCM_EOL);
 859                 csm->set_mus_property ("element", $5->self_scm ());
 860                 scm_gc_unprotect_object ($5->self_scm ());
 861
 862                 csm->set_mus_property ("context-type", $2);
 863                 csm->set_mus_property ("context-id", $4);
 864
 865                 $$ = csm;
 866         }
 867         | TIMES {
 868                 THIS->push_spot ();
 869         }
 870         /* CONTINUED */
 871                 fraction Music
 872
 873         {
 874                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 875                 Music *mp = $4;
 876                 $$ = new Time_scaled_music (SCM_EOL);
 877                 $$->set_spot (THIS->pop_spot ());
 878
 879
 880                 $$->set_mus_property ("element", mp->self_scm ());
 881                 scm_gc_unprotect_object (mp->self_scm ());
 882                 $$->set_mus_property ("numerator", gh_int2scm (n));
 883                 $$->set_mus_property ("denominator", gh_int2scm (d));
 884                 $$->compress (Moment (Rational (n,d)));
 885
 886         }
 887         | Repeated_music                { $$ = $1; }
 888         | Simultaneous_music            { $$ = $1; }
 889         | Sequential_music              { $$ = $1; }
 890         | TRANSPOSE pitch Music {
 891                 $$ = new Transposed_music (SCM_EOL);
 892                 Music *p = $3;
 893                 Pitch pit = *unsmob_pitch ($2);
 894
 895                 p->transpose (pit);
 896                 $$->set_mus_property ("element", p->self_scm ());
 897                 scm_gc_unprotect_object (p->self_scm ());
 898         }
 899         | TRANSPOSE steno_tonic_pitch Music {
 900                 $$ = new Transposed_music (SCM_EOL);
 901                 Music *p = $3;
 902                 Pitch pit = *unsmob_pitch ($2);
 903
 904                 p->transpose (pit);
 905                 $$->set_mus_property ("element", p->self_scm ());
 906                 scm_gc_unprotect_object (p->self_scm ());
 907
 908         }
 909         | APPLY embedded_scm Music  {
 910                 SCM ret = gh_call1 ($2, $3->self_scm ());
 911                 Music *m = unsmob_music (ret);
 912                 if (!m) {
 913                         THIS->parser_error ("\\apply must return a Music");
 914                         m = new Music (SCM_EOL);
 915                         }
 916                 $$ = m;
 917         }
 918         | NOTES
 919                 { THIS->lexer_p_->push_note_state (); }
 920         Music
 921                 { $$ = $3;
 922                   THIS->lexer_p_->pop_state ();
 923                 }
 924         | FIGURES
 925                 { THIS->lexer_p_->push_figuredbass_state (); }
 926         Music
 927                 {
 928                   Music * chm = new Untransposable_music () ;
 929                   chm->set_mus_property ("element", $3->self_scm ());
 930                   $$ = chm;
 931
 932                   THIS->lexer_p_->pop_state ();
 933         }
 934         | CHORDS
 935                 { THIS->lexer_p_->push_chord_state (); }
 936         Music
 937                 {
 938                   Music * chm = new Un_relativable_music ;
 939                   chm->set_mus_property ("element", $3->self_scm ());
 940                   $$ = chm;
 941
 942                   THIS->lexer_p_->pop_state ();
 943         }
 944         | LYRICS
 945                 { THIS->lexer_p_->push_lyric_state (); }
 946         Music
 947                 {
 948                   $$ = $3;
 949                   THIS->lexer_p_->pop_state ();
 950         }
 951         | relative_music        { $$ = $1; }
 952         | re_rhythmed_music     { $$ = $1; }
 953         | part_combined_music   { $$ = $1; }
 954         ;
 955
 956 relative_music:
 957         RELATIVE absolute_pitch Music {
 958                 Music * p = $3;
 959                 Pitch pit = *unsmob_pitch ($2);
 960                 $$ = new Relative_octave_music (SCM_EOL);
 961
 962                 $$->set_mus_property ("element", p->self_scm ());
 963                 scm_gc_unprotect_object (p->self_scm ());
 964
 965                 $$->set_mus_property ("last-pitch", p->to_relative_octave (pit).smobbed_copy ());
 966
 967         }
 968         ;
 969
 970 re_rhythmed_music:
 971         ADDLYRICS Music Music {
 972           Lyric_combine_music * l = new Lyric_combine_music (SCM_EOL);
 973           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
 974           scm_gc_unprotect_object ($3->self_scm ());
 975           scm_gc_unprotect_object ($2->self_scm ());
 976           $$ = l;
 977         }
 978         ;
 979
 980 part_combined_music:
 981         PARTCOMBINE STRING Music Music {
 982                 Part_combine_music * p = new Part_combine_music (SCM_EOL);
 983
 984                 p->set_mus_property ("what", $2);
 985                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
 986
 987                 scm_gc_unprotect_object ($3->self_scm ());
 988                 scm_gc_unprotect_object ($4->self_scm ());
 989
 990                 $$ = p;
 991         }
 992         ;
 993
 994 translator_change:
 995         TRANSLATOR STRING '=' STRING  {
 996                 Music * t = new Music (SCM_EOL);
 997                 t->set_mus_property ("iterator-ctor",
 998                         Change_iterator::constructor_cxx_function);
 999                 t-> set_mus_property ("change-to-type", $2);
1000                 t-> set_mus_property ("change-to-id", $4);
1001
1002                 $$ = t;
1003                 $$->set_spot (THIS->here_input ());
1004         }
1005         ;
1006
1007 property_def:
1008         PROPERTY STRING '.' STRING '='  scalar {
1009
1010                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1011                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1012
1013                 csm->set_mus_property ("element", t->self_scm ());
1014                 scm_gc_unprotect_object (t->self_scm ());
1015
1016                 $$ = csm;
1017                 $$->set_spot (THIS->here_input ());
1018
1019                 csm-> set_mus_property ("context-type", $2);
1020         }
1021         | PROPERTY STRING '.' STRING UNSET {
1022                 Music *t = new Music (SCM_EOL);
1023
1024                 t->set_mus_property ("iterator-ctor",
1025                         Property_unset_iterator::constructor_cxx_function);
1026                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1027
1028                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1029                 csm->set_mus_property ("element", t->self_scm ());
1030                 scm_gc_unprotect_object (t->self_scm ());
1031
1032                 $$ = csm;
1033                 $$->set_spot (THIS->here_input ());
1034
1035                 csm-> set_mus_property ("context-type", $2);
1036         }
1037         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1038                 Music *t = new Music (SCM_EOL);
1039                 t->set_mus_property ("iterator-ctor",
1040                         Push_property_iterator::constructor_cxx_function);
1041                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1042                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1043                 t->set_mus_property ("grob-property", $6);
1044                 t->set_mus_property ("grob-value", $8);
1045                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1046                 csm->set_mus_property ("element", t->self_scm ());
1047                 scm_gc_unprotect_object (t->self_scm ());
1048                 $$ = csm;
1049                 $$->set_spot (THIS->here_input ());
1050
1051                 csm-> set_mus_property ("context-type", $2);
1052         }
1053         | PROPERTY STRING '.' STRING OVERRIDE embedded_scm '=' embedded_scm {
1054                 Music *t = new Music (SCM_EOL);
1055                 t->set_mus_property ("iterator-ctor",
1056                         Push_property_iterator::constructor_cxx_function);
1057                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1058                 t->set_mus_property ("grob-property", $6);
1059                 t->set_mus_property ("grob-value", $8);
1060                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1061                 csm->set_mus_property ("element", t->self_scm ());
1062                 scm_gc_unprotect_object (t->self_scm ());
1063
1064                 $$ = csm;
1065                 $$->set_spot (THIS->here_input ());
1066
1067                 csm-> set_mus_property ("context-type", $2);
1068         }
1069         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1070                 Music *t = new Music (SCM_EOL);
1071                 t->set_mus_property ("iterator-ctor",
1072                         Pop_property_iterator::constructor_cxx_function);
1073                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1074                 t->set_mus_property ("grob-property", $6);
1075
1076                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1077                 csm->set_mus_property ("element", t->self_scm ());
1078                 scm_gc_unprotect_object (t->self_scm ());
1079
1080                 $$ = csm;
1081                 $$->set_spot (THIS->here_input ());
1082
1083                 csm-> set_mus_property ("context-type", $2);
1084         }
1085         ;
1086
1087 scalar:
1088         string          { $$ = $1; }
1089         | bare_int      { $$ = gh_int2scm ($1); }
1090         | embedded_scm  { $$ = $1; }
1091         ;
1092
1093
1094 request_chord:
1095         pre_requests {
1096                 THIS->push_spot ();
1097         } /*cont */ simple_element post_requests        {
1098                 Music_sequence *l = dynamic_cast<Music_sequence*> ($3);
1099
1100                 $1->concat (*$4);
1101                 for (int i=0; i < $1->size (); i++) {
1102                   Music * m = $1->elem (i);
1103                   l->append_music (m);
1104                 }
1105                 $$ = $3;
1106
1107                 delete $1;
1108                 delete $4;
1109         }
1110         | command_element
1111         ;
1112
1113 command_element:
1114         command_req {
1115                 $$ = new Request_chord (SCM_EOL);
1116                 $$->set_mus_property ("elements", gh_cons ($1->self_scm (), SCM_EOL));
1117                 $$-> set_spot (THIS->here_input ());
1118                 $1-> set_spot (THIS->here_input ());
1119         }
1120         | E_BACKSLASH {
1121                 $$ = new Music (gh_list (gh_cons (ly_symbol2scm ("name"), ly_symbol2scm ("separator")), SCM_UNDEFINED));
1122                 $$->set_spot (THIS->here_input ());
1123         }
1124         | '|'      {
1125
1126                 extern Music * get_barcheck();
1127                 $$ = get_barcheck ();
1128                 $$->set_spot (THIS->here_input ());
1129         }
1130         | BAR STRING                    {
1131                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1132
1133                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1134                 csm->set_mus_property ("element", t->self_scm ());
1135                 scm_gc_unprotect_object (t->self_scm ());
1136
1137                 $$ = csm;
1138                 $$->set_spot (THIS->here_input ());
1139
1140                 csm->set_mus_property ("context-type", ly_str02scm ("Score"));
1141         }
1142         | PARTIAL duration_length       {
1143                 Moment m = - unsmob_duration ($2)->length_mom ();
1144                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1145
1146                 Context_specced_music * sp = new Context_specced_music (SCM_EOL);
1147                 sp->set_mus_property ("element", p->self_scm ());
1148                 scm_gc_unprotect_object (p->self_scm ());
1149
1150                 $$ =sp ;
1151                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
1152         }
1153         | CLEF STRING  {
1154                 SCM func = scm_primitive_eval (ly_symbol2scm ("clef-name-to-properties"));
1155                 SCM result = gh_call1 (func, $2);
1156
1157                 SCM l = SCM_EOL;
1158                 for (SCM s = result ; gh_pair_p (s); s = ly_cdr (s)) {
1159                         Music * p = new Music (SCM_EOL);
1160                         set_music_properties (p, ly_car (s));
1161                         l = gh_cons (p->self_scm (), l);
1162                         scm_gc_unprotect_object (p->self_scm ());
1163                 }
1164                 Sequential_music * seq = new Sequential_music (SCM_EOL);
1165                 seq->set_mus_property ("elements", l);
1166
1167                 Context_specced_music * sp = new Context_specced_music (SCM_EOL);
1168                 sp->set_mus_property ("element", seq->self_scm ());
1169                 scm_gc_unprotect_object (seq->self_scm ());
1170
1171                 $$ =sp ;
1172                 sp-> set_mus_property ("context-type", ly_str02scm ("Staff"));
1173         }
1174         | TIME_T fraction  {
1175                 Music * p1 = set_property_music (ly_symbol2scm ( "timeSignatureFraction"), $2);
1176
1177                 int l = gh_scm2int (ly_car ($2));
1178                 int o = gh_scm2int (ly_cdr ($2));
1179
1180                 Moment one_beat = Moment (1)/Moment (o);
1181                 Moment len = Moment (l) * one_beat;
1182
1183
1184                 Music *p2 = set_property_music (ly_symbol2scm ("measureLength"), len.smobbed_copy ());
1185                 Music *p3 = set_property_music (ly_symbol2scm ("beatLength"), one_beat.smobbed_copy ());
1186
1187                 SCM list = scm_list_n (p1->self_scm (), p2->self_scm (), p3->self_scm(), SCM_UNDEFINED);
1188                 Sequential_music *seq = new Sequential_music (SCM_EOL);
1189                 seq->set_mus_property ("elements", list);
1190
1191
1192                 Context_specced_music * sp = new Context_specced_music (SCM_EOL);
1193                 sp->set_mus_property ("element", seq->self_scm ());
1194
1195
1196
1197                 scm_gc_unprotect_object (p3->self_scm ());
1198                 scm_gc_unprotect_object (p2->self_scm ());
1199                 scm_gc_unprotect_object (p1->self_scm ());
1200                 scm_gc_unprotect_object (seq->self_scm ());
1201
1202                 $$ = sp;
1203
1204 /*
1205  TODO: should make alias TimingContext for Score
1206 */
1207
1208                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
1209         }
1210         ;
1211
1212 command_req:
1213         shorthand_command_req   { $$ = $1; }
1214         | verbose_command_req   { $$ = $1; }
1215         ;
1216
1217 shorthand_command_req:
1218         extender_req {
1219                 $$ = $1;
1220         }
1221         | hyphen_req {
1222                 $$ = $1;
1223         }
1224         | '~'   {
1225                 $$ = new Tie_req;
1226         }
1227         | '['           {
1228                 Span_req*b= new Span_req;
1229                 b->set_span_dir (START);
1230                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1231                 $$ =b;
1232
1233
1234                 THIS->last_beam_start_ = b->self_scm ();
1235         }
1236         | ']'           {
1237                 Span_req*b= new Span_req;
1238                 b->set_span_dir ( STOP);
1239                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1240                 $$ = b;
1241         }
1242         | E_LEFTSQUARE {
1243                 Span_req *b = new Span_req;
1244                 b->set_span_dir (START);
1245                 b->set_mus_property ("span-type", ly_str02scm ("ligature-bracket"));
1246                 $$ = b;
1247                 THIS->last_ligature_start_ = b->self_scm ();
1248         }
1249         | E_RIGHTSQUARE {
1250                 Span_req *b = new Span_req;
1251                 b->set_span_dir (STOP);
1252                 b->set_mus_property ("span-type", ly_str02scm ("ligature-bracket"));
1253                 $$ = b;
1254         }
1255         | BREATHE {
1256                 $$ = new Breathing_sign_req;
1257         }
1258         | E_TILDE {
1259                 $$ = new Porrectus_req;
1260         }
1261         ;
1262
1263 verbose_command_req:
1264         COMMANDSPANREQUEST bare_int STRING { /*TODO: junkme */
1265                 Span_req * sp_p = new Span_req;
1266                 sp_p-> set_span_dir ( Direction ($2));
1267                 sp_p->set_mus_property ("span-type",$3);
1268                 sp_p->set_spot (THIS->here_input ());
1269                 $$ = sp_p;
1270         }
1271         | MARK DEFAULT  {
1272                 Mark_req * m = new Mark_req;
1273                 $$ = m;
1274         }
1275         | MARK scalar {
1276                 Mark_req *m = new Mark_req;
1277                 m->set_mus_property ("label", $2);
1278                 $$ = m;
1279
1280         }
1281         | PENALTY SCM_T         {
1282                 Break_req * b = new Break_req;
1283                 SCM s = $2;
1284                 if (!gh_number_p (s))
1285                         s  =gh_int2scm (0);
1286
1287                 b->set_mus_property ("penalty", s);
1288                 b->set_spot (THIS->here_input ());
1289                 $$ = b;
1290         }
1291         | SKIP duration_length {
1292                 Skip_req * skip_p = new Skip_req;
1293                 skip_p->set_mus_property ("duration", $2);
1294
1295                 $$ = skip_p;
1296         }
1297         | tempo_request {
1298                 $$ = $1;
1299         }
1300         | KEY DEFAULT {
1301                 Key_change_req *key_p= new Key_change_req;
1302                 $$ = key_p;
1303         }
1304         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1305                 Key_change_req *key_p= new Key_change_req;
1306
1307                 key_p->set_mus_property ("pitch-alist", $3);
1308                 ((Music*)key_p)->transpose (* unsmob_pitch ($2));
1309                 $$ = key_p;
1310         }
1311         ;
1312
1313 post_requests:
1314         {
1315                 $$ = new Link_array<Request>;
1316         }
1317         | post_requests post_request {
1318                 $2->set_spot (THIS->here_input ());
1319                 $$->push ($2);
1320         }
1321         ;
1322
1323 post_request:
1324         verbose_request
1325         | request_with_dir
1326         | close_request
1327         ;
1328
1329
1330 request_that_take_dir:
1331         gen_text_def
1332         | verbose_request
1333         | script_abbreviation {
1334                 SCM s = THIS->lexer_p_->lookup_identifier ("dash" + ly_scm2string ($1));
1335                 Articulation_req *a = new Articulation_req;
1336                 if (gh_string_p (s))
1337                         a->set_mus_property ("articulation-type", s);
1338                 else THIS->parser_error (_ ("Expecting string as script definition"));
1339                 $$ = a;
1340         }
1341         ;
1342
1343 request_with_dir:
1344         script_dir request_that_take_dir        {
1345                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1346                         gs->set_direction (Direction ($1));
1347                 else if ($1)
1348                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1349                 $$ = $2;
1350         }
1351         ;
1352
1353 verbose_request:
1354         REQUEST_IDENTIFIER      {
1355                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1356                 $$->set_spot (THIS->here_input ());
1357         }
1358         | DYNAMICSCRIPT embedded_scm {
1359                 /*
1360                         TODO: junkme, use text-type == dynamic
1361                 */
1362                 Text_script_req *d = new Text_script_req;
1363                 SCM dyn = ly_symbol2scm ("dynamic");
1364                 d->set_mus_property ("text-type" , dyn);
1365                 d->set_mus_property ("text", $2);
1366                 d->set_spot (THIS->here_input ());
1367                 $$ = d;
1368         }
1369         | SPANREQUEST bare_int STRING {
1370                 Span_req * sp_p = new Span_req;
1371                 sp_p->set_span_dir ( Direction ($2));
1372                 sp_p->set_mus_property ("span-type", $3);
1373                 sp_p->set_spot (THIS->here_input ());
1374                 $$ = sp_p;
1375         }
1376         | tremolo_type  {
1377                Tremolo_req* a = new Tremolo_req;
1378                a->set_spot (THIS->here_input ());
1379                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1380                $$ = a;
1381         }
1382         | SCRIPT STRING         {
1383                 Articulation_req * a = new Articulation_req;
1384                 a->set_mus_property ("articulation-type", $2);
1385                 a->set_spot (THIS->here_input ());
1386                 $$ = a;
1387         }
1388         /*
1389 duh, junk this syntax from the parser, if possible.
1390         */
1391         | ARPEGGIO {
1392                 Arpeggio_req *a = new Arpeggio_req;
1393                 a->set_spot (THIS->here_input ());
1394                 $$ = a;
1395         }
1396         | GLISSANDO {
1397                 Glissando_req *g = new Glissando_req;
1398                 g->set_spot /* No pun intended */ (THIS->here_input ());
1399                 $$ = g;
1400         }
1401         ;
1402
1403 sup_quotes:
1404         '\'' {
1405                 $$ = 1;
1406         }
1407         | sup_quotes '\'' {
1408                 $$ ++;
1409         }
1410         ;
1411
1412 sub_quotes:
1413         ',' {
1414                 $$ = 1;
1415         }
1416         | sub_quotes ',' {
1417                 $$ ++ ;
1418         }
1419         ;
1420
1421 steno_pitch:
1422         NOTENAME_PITCH  {
1423                 $$ = $1;
1424         }
1425         | NOTENAME_PITCH sup_quotes     {
1426                 Pitch p = *unsmob_pitch ($1);
1427                 p.octave_i_ +=  $2;
1428                 $$ = p.smobbed_copy ();
1429         }
1430         | NOTENAME_PITCH sub_quotes      {
1431                 Pitch p =* unsmob_pitch ($1);
1432
1433                 p.octave_i_ +=  -$2;
1434                 $$ = p.smobbed_copy ();
1435
1436         }
1437         ;
1438
1439 /*
1440 ugh. duplication
1441 */
1442
1443 steno_tonic_pitch:
1444         TONICNAME_PITCH {
1445                 $$ = $1;
1446         }
1447         | TONICNAME_PITCH sup_quotes    {
1448                 Pitch p = *unsmob_pitch ($1);
1449                 p.octave_i_ +=  $2;
1450                 $$ = p.smobbed_copy ();
1451         }
1452         | TONICNAME_PITCH sub_quotes     {
1453                 Pitch p =* unsmob_pitch ($1);
1454
1455                 p.octave_i_ +=  -$2;
1456                 $$ = p.smobbed_copy ();
1457
1458         }
1459         ;
1460
1461 pitch:
1462         steno_pitch {
1463                 $$ = $1;
1464         }
1465         | explicit_pitch {
1466                 $$ = $1;
1467         }
1468         ;
1469
1470 explicit_pitch:
1471         PITCH embedded_scm {
1472                 $$ = $2;
1473                 if (!unsmob_pitch ($2)) {
1474                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1475                          $$ = Pitch ().smobbed_copy ();
1476                 }
1477         }
1478         ;
1479
1480 verbose_duration:
1481         DURATION embedded_scm   {
1482                 $$ = $2;
1483                 if (!unsmob_duration ($2))
1484                 {
1485                         THIS->parser_error (_ ("Must have duration object"));
1486                         $$ = Duration ().smobbed_copy ();
1487                 }
1488         }
1489         ;
1490
1491 extender_req:
1492         EXTENDER {
1493                 if (!THIS->lexer_p_->lyric_state_b ())
1494                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1495                 $$ = new Extender_req;
1496         }
1497         ;
1498
1499 hyphen_req:
1500         HYPHEN {
1501                 if (!THIS->lexer_p_->lyric_state_b ())
1502                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1503                 $$ = new Hyphen_req;
1504         }
1505         ;
1506
1507 close_request:
1508         close_request_parens {
1509                 $$ = $1;
1510                 dynamic_cast<Span_req*> ($$)->set_span_dir ( START);
1511         }
1512
1513 close_request_parens:
1514         '('     {
1515                 Span_req* s= new Span_req;
1516                 $$ = s;
1517                 s->set_mus_property ("span-type", ly_str02scm ( "slur"));
1518         }
1519         | E_OPEN        {
1520                 Span_req* s= new Span_req;
1521                 $$ = s;
1522                 s->set_mus_property ("span-type", ly_str02scm ( "phrasing-slur"));
1523         }
1524         | E_SMALLER {
1525                 Span_req*s =new Span_req;
1526                 $$ = s;
1527                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1528         }
1529         | E_BIGGER {
1530                 Span_req*s =new Span_req;
1531                 $$ = s;
1532                 s->set_mus_property ("span-type", ly_str02scm ("decrescendo"));
1533         }
1534         ;
1535
1536
1537 open_request:
1538         open_request_parens {
1539                 $$ = $1;
1540                 dynamic_cast<Span_req*> ($$)->set_span_dir (STOP);
1541         }
1542         ;
1543
1544 open_request_parens:
1545         E_EXCLAMATION   {
1546                 Span_req *s =  new Span_req;
1547                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1548
1549                 $$ = s;
1550         }
1551         | ')'   {
1552                 Span_req* s= new Span_req;
1553                 $$ = s;
1554                 s->set_mus_property ("span-type", ly_str02scm ( "slur"));
1555         }
1556         | E_CLOSE       {
1557                 Span_req* s= new Span_req;
1558                 $$ = s;
1559                 s->set_mus_property ("span-type", ly_str02scm ( "phrasing-slur"));
1560         }
1561         ;
1562
1563 gen_text_def:
1564         embedded_scm {
1565                 Text_script_req *t = new Text_script_req;
1566                 t->set_mus_property ("text", $1);
1567                 t->set_spot (THIS->here_input ());
1568                 $$ = t;
1569         }
1570         | string {
1571                 Text_script_req *t = new Text_script_req;
1572                 t->set_mus_property ("text", $1);
1573                 t->set_spot (THIS->here_input ());
1574                 $$ = t;
1575         }
1576         | DIGIT {
1577                 String ds = to_str ($1);
1578                 Text_script_req* t = new Text_script_req;
1579                 SCM finger = ly_symbol2scm ("finger");
1580                 t->set_mus_property ("text",  ly_str02scm (ds.ch_C ()));
1581                 t->set_mus_property ("text-type" , finger);
1582                 t->set_spot (THIS->here_input ());
1583                 $$ = t;
1584         }
1585         ;
1586
1587 script_abbreviation:
1588         '^'             {
1589                 $$ = gh_str02scm ("Hat");
1590         }
1591         | '+'           {
1592                 $$ = gh_str02scm ("Plus");
1593         }
1594         | '-'           {
1595                 $$ = gh_str02scm ("Dash");
1596         }
1597         | '|'           {
1598                 $$ = gh_str02scm ("Bar");
1599         }
1600         | '>'           {
1601                 $$ = gh_str02scm ("Larger");
1602         }
1603         | '.'           {
1604                 $$ = gh_str02scm ("Dot");
1605         }
1606         ;
1607
1608 script_dir:
1609         '_'     { $$ = DOWN; }
1610         | '^'   { $$ = UP; }
1611         | '-'   { $$ = CENTER; }
1612         ;
1613
1614 pre_requests:
1615         {
1616                 $$ = new Link_array<Request>;
1617         }
1618         | pre_requests open_request {
1619                 $$->push ($2);
1620         }
1621         ;
1622
1623 absolute_pitch:
1624         steno_pitch     {
1625                 $$ = $1;
1626         }
1627         ;
1628
1629 duration_length:
1630         multiplied_duration {
1631                 $$ = $1;
1632         }
1633         | verbose_duration {
1634                 $$ = $1;
1635         }
1636         ;
1637
1638 optional_notemode_duration:
1639         {
1640                 Duration dd = THIS->default_duration_;
1641                 $$ = dd.smobbed_copy ();
1642
1643                 THIS->beam_check ($$);
1644         }
1645         | multiplied_duration   {
1646                 $$ = $1;
1647                 THIS->default_duration_ = *unsmob_duration ($$);
1648
1649                 THIS->beam_check ($$);
1650         }
1651         | verbose_duration {
1652                 $$ = $1;
1653                 THIS->default_duration_ = *unsmob_duration ($$);
1654         }
1655         ;
1656
1657 steno_duration:
1658         bare_unsigned dots              {
1659                 int l = 0;
1660                 if (!is_duration_b ($1))
1661                         THIS->parser_error (_f ("not a duration: %d", $1));
1662                 else
1663                         l =  intlog2 ($1);
1664
1665                 $$ = Duration (l, $2).smobbed_copy ();
1666         }
1667         | DURATION_IDENTIFIER dots      {
1668                 Duration *d =unsmob_duration ($1);
1669                 Duration k (d->duration_log (),d->dot_count () + $2);
1670                 $$ = k.smobbed_copy ();
1671         }
1672         ;
1673
1674
1675
1676
1677 multiplied_duration:
1678         steno_duration {
1679                 $$ = $1;
1680         }
1681         | multiplied_duration '*' bare_unsigned {
1682                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1683         }
1684         | multiplied_duration '*' FRACTION {
1685                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1686
1687                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1688         }
1689         ;
1690
1691 fraction:
1692         FRACTION { $$ = $1; }
1693         | UNSIGNED '/' UNSIGNED {
1694                 $$ = gh_cons (gh_int2scm ($1), gh_int2scm ($3));
1695         }
1696         ;
1697
1698 dots:
1699         /* empty */     {
1700                 $$ = 0;
1701         }
1702         | dots '.' {
1703                 $$ ++;
1704         }
1705         ;
1706
1707
1708 tremolo_type:
1709         ':'     {
1710                 $$ =0;
1711         }
1712         | ':' bare_unsigned {
1713                 if (!is_duration_b ($2))
1714                         THIS->parser_error (_f ("not a duration: %d", $2));
1715                 $$ = $2;
1716         }
1717         ;
1718
1719
1720 bass_number:
1721         DIGIT
1722         | UNSIGNED
1723         ;
1724
1725 bass_mod:
1726         '-'     { $$ = -1; }
1727         | '+'   { $$ = 1; }
1728         | '!'   { $$ = 0; }
1729         ;
1730
1731 bass_figure:
1732         FIGURE_SPACE {
1733                 Bass_figure_req *bfr = new Bass_figure_req;
1734                 $$ = bfr->self_scm();
1735                 scm_gc_unprotect_object ($$);
1736         }
1737         | bass_number  {
1738                 Bass_figure_req *bfr = new Bass_figure_req;
1739                 $$ = bfr->self_scm();
1740
1741                 bfr->set_mus_property ("figure", gh_int2scm ($1));
1742
1743                 scm_gc_unprotect_object ($$);
1744         }
1745         | bass_figure bass_mod {
1746                 Music *m = unsmob_music ($1);
1747                 if ($2) {
1748                         SCM salter =m->get_mus_property ("alteration");
1749                         int alter = gh_number_p( salter) ? gh_scm2int (salter) : 0;
1750                         m->set_mus_property ("alteration",
1751                                 gh_int2scm (alter + $2));
1752                 } else {
1753                         m->set_mus_property ("alteration", gh_int2scm (0));
1754                 }
1755         }
1756         ;
1757
1758 br_bass_figure:
1759         '[' bass_figure {
1760                 $$ = $2;
1761                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1762         }
1763         | bass_figure   {
1764                 $$ = $1;
1765         }
1766         | br_bass_figure ']' {
1767                 $$ = $1;
1768                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1769         }
1770         ;
1771
1772 figure_list:
1773         /**/            {
1774                 $$ = SCM_EOL;
1775         }
1776         | figure_list br_bass_figure {
1777                 $$ = gh_cons ($2, $1);
1778         }
1779         ;
1780
1781 figure_spec:
1782         FIGURE_OPEN figure_list FIGURE_CLOSE {
1783                 Music * m = new Request_chord (SCM_EOL);
1784                 $2 = scm_reverse_x ($2, SCM_EOL);
1785                 m->set_mus_property ("elements",  $2);
1786                 $$ = m->self_scm ();
1787         }
1788         ;
1789
1790
1791 optional_rest:
1792         /**/   { $$ = 0; }
1793         | REST { $$ = 1; }
1794         ;
1795
1796 simple_element:
1797         pitch exclamations questions optional_notemode_duration optional_rest {
1798
1799                 Input i = THIS->pop_spot ();
1800                 if (!THIS->lexer_p_->note_state_b ())
1801                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1802
1803                 Music *n = 0;
1804                 if ($5)
1805                         n =  new Rest_req ;
1806                 else
1807                         n =  new Note_req;
1808
1809                 n->set_mus_property ("pitch", $1);
1810                 n->set_mus_property ("duration", $4);
1811
1812
1813                 if ($3 % 2)
1814                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1815                 if ($2 % 2 || $3 % 2)
1816                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1817
1818                 Simultaneous_music*v = new Request_chord (SCM_EOL);
1819                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1820
1821                 v->set_spot (i);
1822                 n->set_spot (i);
1823                 $$ = v;
1824         }
1825         | figure_spec optional_notemode_duration {
1826                 Music * m = unsmob_music ($1);
1827                 Input i = THIS->pop_spot ();
1828                 m->set_spot (i);
1829                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1830                         {
1831                                 unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1832                         }
1833                 $$ = m;
1834         }
1835         | RESTNAME optional_notemode_duration           {
1836
1837                 Input i = THIS->pop_spot ();
1838                 SCM e = SCM_UNDEFINED;
1839                 if (ly_scm2string ($1) =="s") {
1840                         /* Space */
1841                         Skip_req * skip_p = new Skip_req;
1842                         skip_p->set_mus_property ("duration" ,$2);
1843                         skip_p->set_spot (i);
1844                         e = skip_p->self_scm ();
1845                   }
1846                   else {
1847                         Rest_req * rest_req_p = new Rest_req;
1848                         rest_req_p->set_mus_property ("duration", $2);
1849                         rest_req_p->set_spot (i);
1850                         e = rest_req_p->self_scm ();
1851                     }
1852                 Simultaneous_music* velt_p = new Request_chord (SCM_EOL);
1853                 velt_p-> set_mus_property ("elements", scm_list_n (e,SCM_UNDEFINED));
1854                 velt_p->set_spot (i);
1855
1856                 $$ = velt_p;
1857         }
1858         | MULTI_MEASURE_REST optional_notemode_duration         {
1859                 Input i = THIS->pop_spot ();
1860
1861                 Skip_req * sk = new Skip_req;
1862                 sk->set_mus_property ("duration", $2);
1863                 Span_req *sp1 = new Span_req;
1864                 Span_req *sp2 = new Span_req;
1865                 sp1-> set_span_dir ( START);
1866                 sp2-> set_span_dir ( STOP);
1867                 SCM r = ly_str02scm ("rest");
1868                 sp1->set_mus_property ("span-type", r);
1869                 sp2->set_mus_property ("span-type", r);
1870
1871                 Request_chord * rqc1 = new Request_chord (SCM_EOL);
1872                 rqc1->set_mus_property ("elements", scm_list_n (sp1->self_scm (), SCM_UNDEFINED));
1873                 Request_chord * rqc2 = new Request_chord (SCM_EOL);
1874                 rqc2->set_mus_property ("elements", scm_list_n (sk->self_scm (), SCM_UNDEFINED));;
1875                 Request_chord * rqc3 = new Request_chord (SCM_EOL);
1876                 rqc3->set_mus_property ("elements", scm_list_n (sp2->self_scm (), SCM_UNDEFINED));;
1877
1878                 SCM ms = scm_list_n (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1879
1880                 $$ = new Sequential_music (SCM_EOL);
1881                 $$->set_mus_property ("elements", ms);
1882         }
1883         | STRING optional_notemode_duration     {
1884                 Input i = THIS->pop_spot ();
1885
1886                 Lyric_req* lreq_p = new Lyric_req;
1887                 lreq_p->set_mus_property ("text", $1);
1888                 lreq_p->set_mus_property ("duration",$2);
1889                 lreq_p->set_spot (i);
1890                 Simultaneous_music* velt_p = new Request_chord (SCM_EOL);
1891                 velt_p->set_mus_property ("elements", scm_list_n (lreq_p->self_scm (), SCM_UNDEFINED));
1892
1893                 $$= velt_p;
1894         }
1895         | chord {
1896                 Input i = THIS->pop_spot ();
1897
1898                 if (!THIS->lexer_p_->chord_state_b ())
1899                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1900                 $$ = $1;
1901         }
1902         ;
1903
1904
1905 chord:
1906         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1907                 $$ = Chord::get_chord ($1, $3, $4, $5, $6, $2);
1908                 $$->set_spot (THIS->here_input ());
1909         };
1910
1911 chord_additions:
1912         {
1913                 $$ = SCM_EOL;
1914         }
1915         | CHORD_COLON chord_notes {
1916                 $$ = $2;
1917         }
1918         ;
1919
1920 chord_notes:
1921         chord_step {
1922                 $$ = $1
1923         }
1924         | chord_notes '.' chord_step {
1925                 $$ = gh_append2 ($$, $3);
1926         }
1927         ;
1928
1929 chord_subtractions:
1930         {
1931                 $$ = SCM_EOL;
1932         }
1933         | CHORD_CARET chord_notes {
1934                 $$ = $2;
1935         }
1936         ;
1937
1938
1939 chord_inversion:
1940         {
1941                 $$ = SCM_EOL;
1942         }
1943         | '/' steno_tonic_pitch {
1944                 $$ = $2;
1945         }
1946         ;
1947
1948 chord_bass:
1949         {
1950                 $$ = SCM_EOL;
1951         }
1952         | CHORD_BASS steno_tonic_pitch {
1953                 $$ = $2;
1954         }
1955         ;
1956
1957 chord_step:
1958         chord_note {
1959                 $$ = gh_cons ($1, SCM_EOL);
1960         }
1961         | CHORDMODIFIER_PITCH {
1962                 $$ = gh_cons (unsmob_pitch ($1)->smobbed_copy (), SCM_EOL);
1963         }
1964         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1965                 $$ = scm_list_n (unsmob_pitch ($1)->smobbed_copy (),
1966                         $2, SCM_UNDEFINED);
1967         }
1968         ;
1969
1970 chord_note:
1971         bare_unsigned {
1972                  Pitch m;
1973                 m.notename_i_ = ($1 - 1) % 7;
1974                 m.octave_i_ = $1 > 7 ? 1 : 0;
1975                 m.alteration_i_ = 0;
1976
1977                 $$ = m.smobbed_copy ();
1978         }
1979         | bare_unsigned '+' {
1980                 Pitch m;
1981                 m.notename_i_ = ($1 - 1) % 7;
1982                 m.octave_i_ = $1 > 7 ? 1 : 0;
1983                 m.alteration_i_ = 1;
1984
1985
1986                 $$ = m.smobbed_copy ();
1987         }
1988         | bare_unsigned CHORD_MINUS {
1989                 Pitch m;
1990                 m.notename_i_ = ($1 - 1) % 7;
1991                 m.octave_i_ = $1 > 7 ? 1 : 0;
1992                 m.alteration_i_ = -1;
1993
1994                 $$ = m.smobbed_copy ();
1995         }
1996         ;
1997
1998 /*
1999         UTILITIES
2000  */
2001 number_expression:
2002         number_expression '+' number_term {
2003                 $$ = scm_sum ($1, $3);
2004         }
2005         | number_expression '-' number_term {
2006                 $$ = scm_difference ($1, $3);
2007         }
2008         | number_term
2009         ;
2010
2011 number_term:
2012         number_factor {
2013                 $$ = $1;
2014         }
2015         | number_factor '*' number_factor {
2016                 $$ = scm_product ($1, $3);
2017         }
2018         | number_factor '/' number_factor {
2019                 $$ = scm_divide ($1, $3);
2020         }
2021         ;
2022
2023 number_factor:
2024         '(' number_expression ')'       {
2025                 $$ = $2;
2026         }
2027         | '-'  number_factor { /* %prec UNARY_MINUS */
2028                 $$ = scm_difference ($2, SCM_UNDEFINED);
2029         }
2030         | bare_number
2031         ;
2032
2033
2034 bare_number:
2035         UNSIGNED        {
2036                 $$ = gh_int2scm ($1);
2037         }
2038         | REAL          {
2039                 $$ = $1;
2040         }
2041         | NUMBER_IDENTIFIER             {
2042                 $$ = $1;
2043         }
2044         | REAL CM_T     {
2045                 $$ = gh_double2scm (gh_scm2double ($1) CM );
2046         }
2047         | REAL PT_T     {
2048                 $$ = gh_double2scm (gh_scm2double ($1) PT);
2049         }
2050         | REAL IN_T     {
2051                 $$ = gh_double2scm (gh_scm2double ($1) INCH);
2052         }
2053         | REAL MM_T     {
2054                 $$ = gh_double2scm (gh_scm2double ($1) MM);
2055         }
2056         | REAL CHAR_T   {
2057                 $$ = gh_double2scm (gh_scm2double ($1) CHAR);
2058         }
2059         ;
2060
2061
2062 bare_unsigned:
2063         UNSIGNED {
2064                         $$ = $1;
2065         }
2066         | DIGIT {
2067                 $$ = $1;
2068         }
2069         ;
2070
2071 bare_int:
2072         bare_number {
2073                 if (scm_integer_p ($1) == SCM_BOOL_T)
2074                 {
2075                         int k = gh_scm2int ($1);
2076                         $$ = k;
2077                 } else
2078                 {
2079                         THIS->parser_error (_ ("need integer number arg"));
2080                         $$ = 0;
2081                 }
2082         }
2083         | '-' bare_int {
2084                 $$ = -$2;
2085         }
2086         ;
2087
2088
2089 string:
2090         STRING          {
2091                 $$ = $1;
2092         }
2093         | STRING_IDENTIFIER     {
2094                 $$ = $1;
2095         }
2096         | string '+' string {
2097                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2098         }
2099         ;
2100
2101
2102 exclamations:
2103                 { $$ = 0; }
2104         | exclamations '!'      { $$ ++; }
2105         ;
2106
2107 questions:
2108                 { $$ = 0; }
2109         | questions '?' { $$ ++; }
2110         ;
2111
2112
2113 %%
2114
2115 void
2116 My_lily_parser::set_yydebug (bool b)
2117 {
2118 #ifdef YYDEBUG
2119         yydebug = b;
2120 #endif
2121 }
2122
2123 extern My_lily_parser * current_parser;
2124
2125 void
2126 My_lily_parser::do_yyparse ()
2127 {
2128
2129         current_parser = this;;
2130         yyparse ((void*)this);
2131 }
2132
2133
2134 /*
2135 Should make this optional?    It will also complain when you do
2136
2137         [s4]
2138
2139 which is entirely legitimate.
2140
2141 Or we can scrap it. Barchecks should detect wrong durations, and
2142 skipTypesetting speeds it up a lot.
2143 */
2144 void
2145 My_lily_parser::beam_check (SCM dur)
2146 {
2147   Duration *d = unsmob_duration (dur);
2148   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2149     {
2150       Music * m = unsmob_music (last_beam_start_);
2151       m->origin ()->warning (_("Suspect duration found following this beam"));
2152     }
2153   last_beam_start_ = SCM_EOL;
2154 }