lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONTEXT
 261 %token DEFAULT
 262 %token DENIES
 263 %token DESCRIPTION
 264 %token EXTENDER
 265 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 266 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 267 %token GROBDESCRIPTIONS
 268 %token HEADER
 269 %token HYPHEN
 270 %token INVALID
 271 %token KEY
 272 %token LYRICS
 273 %token LYRICS_STRING
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTIAL
 285 %token QUOTE
 286 %token RELATIVE
 287 %token REMOVE
 288 %token REPEAT
 289 %token REST
 290 %token SCM_T
 291 %token SCORE
 292 %token SEQUENTIAL
 293 %token NEWLYRICS
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSPOSE
 302 %token TRANSPOSITION
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306 %token MARKUP
 307
 308 /* escaped */
 309 /* FIXME: this sucks.  The user will get to see these names:
 310     syntax error, unexpected E_CHAR:
 311                 \
 312                  %%
 313   */
 314
 315 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 316 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 317 %token E_BACKSLASH
 318 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 319 %token FIGURE_SPACE
 320
 321 %token <i>      DIGIT
 322 %token <i>      UNSIGNED
 323 %token <i> E_UNSIGNED
 324 %token <id>     IDENTIFIER
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DRUM_PITCH
 327 %token <scm>    DURATION_IDENTIFIER
 328 %token <scm>    EVENT_IDENTIFIER
 329 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 330 %token <scm>    NOTENAME_PITCH
 331 %token <scm>    NUMBER_IDENTIFIER
 332 %token <scm>    OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    RESTNAME
 334 %token <scm>    SCM_T
 335 %token <scm>    SCORE_IDENTIFIER
 336 %token <scm>    STRING
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    TONICNAME_PITCH
 339 %token <scm>    CHORD_MODIFIER
 340 %token <scm>    FRACTION
 341 %token <scm>   REAL
 342 %token <scm> MARKUP_HEAD_EMPTY
 343 %token <scm> MARKUP_HEAD_MARKUP0
 344 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 345 %token <scm> MARKUP_HEAD_SCM0
 346 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0_SCM1
 348 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 350 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 351 %token <scm> MUSIC_FUNCTION
 352 %token <scm> MUSIC_FUNCTION_MUSIC
 353 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 354 %token <scm> MUSIC_FUNCTION_SCM
 355 %token <scm> MUSIC_FUNCTION_SCM_SCM
 356 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 359 %token DRUMS
 360
 361
 362
 363 %type <book>    book_block book_body
 364 %type <i>       bare_int  bare_unsigned
 365 %type <i>       exclamations questions dots optional_rest
 366 %type <i>       script_dir
 367 %type <i>       sub_quotes sup_quotes
 368 %type <i>       tremolo_type
 369 %type <i>       bass_mod
 370
 371 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 372 %type <music>   Grouped_music_list
 373 %type <music>   Music Sequential_music Simultaneous_music
 374 %type <music>   Repeated_music
 375 %type <music>   command_req
 376 %type <music>   gen_text_def direction_less_event direction_reqd_event
 377 %type <music>   music_property_def context_change
 378 %type <music>   note_chord_element chord_body chord_body_element
 379 %type <music>   open_event close_event
 380 %type <music>   post_event tagged_post_event
 381 %type <music>   relative_music re_rhythmed_music
 382 %type <music>   simple_element event_chord command_element
 383 %type <music>   string_number_event
 384 %type <music>   toplevel_music
 385 %type <music>   tempo_event
 386
 387 %type <outputdef>       output_def_body output_def_head
 388 %type <outputdef> output_def book_paper_block
 389
 390 %type <scm>     Music_list
 391 %type <scm>     chord_body_elements
 392 %type <scm>     chord_item chord_items chord_separator new_chord
 393 %type <scm>     context_def_spec_block context_def_spec_body
 394 %type <scm>     context_mod context_def_mod optional_context_mod
 395 %type <scm>     context_prop_spec
 396 %type <scm>     duration_length fraction
 397 %type <scm>     embedded_scm scalar
 398 %type <scm>     identifier_init
 399 %type <scm>     lilypond_header lilypond_header_body
 400 %type <scm>     new_lyrics
 401 %type <scm>     post_events
 402 %type <scm>     property_operation
 403 %type <scm>     script_abbreviation
 404 %type <scm>     simple_string
 405 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 406 %type <scm>     steno_tonic_pitch
 407 %type <scm>     step_number step_numbers
 408 %type <scm>     string bare_number number_expression number_term number_factor
 409 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 410 %type <scm>     context_mod_list
 411 %type <scm>     octave_check
 412 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 413 %type <scm>     Generic_prefix_music_scm
 414 %type <scm>     lyric_element
 415 %type <scm>     Alternative_music
 416 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 417
 418 %type <score>   score_block score_body
 419
 420
 421 %left '-' '+'
 422
 423 /* We don't assign precedence to / and *, because we might need varied
 424 prec levels in different prods */
 425
 426 %left UNARY_MINUS
 427
 428 %%
 429
 430 lilypond:       /* empty */
 431         | lilypond toplevel_expression {
 432         }
 433         | lilypond assignment {
 434         }
 435         | lilypond error {
 436                 THIS->error_level_ = 1;
 437         }
 438         | lilypond INVALID      {
 439                 THIS->error_level_ = 1;
 440         }
 441         ;
 442
 443 toplevel_expression:
 444         lilypond_header {
 445                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 446         }
 447         | add_quote {
 448
 449         }
 450         | book_block {
 451                 Book *book = $1;
 452                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 453                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 454                 scm_gc_unprotect_object (book->self_scm ());
 455         }
 456         | score_block {
 457                 Score *score = $1;
 458
 459                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 460                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 461                 scm_gc_unprotect_object (score->self_scm ());
 462         }
 463         | toplevel_music {
 464                 Music *music = $1;
 465                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 466                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 467                 scm_gc_unprotect_object (music->self_scm ());
 468         }
 469         | output_def {
 470                 SCM id = SCM_EOL;
 471                 Output_def * od = $1;
 472
 473                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 474                         id = ly_symbol2scm ("$defaultpaper");
 475                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 476                         id = ly_symbol2scm ("$defaultmidi");
 477                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 478                         id = ly_symbol2scm ("$defaultbookpaper");
 479
 480                 THIS->lexer_->set_identifier (id, od->self_scm ());
 481                 scm_gc_unprotect_object (od->self_scm ());
 482         }
 483         ;
 484
 485 toplevel_music:
 486         Composite_music {
 487         }
 488         ;
 489
 490 embedded_scm:
 491         SCM_T
 492         | SCM_IDENTIFIER
 493         ;
 494
 495
 496 lilypond_header_body:
 497         {
 498                 $$ = ly_make_anonymous_module (safe_global_b);
 499                 THIS->lexer_->add_scope ($$);
 500         }
 501         | lilypond_header_body assignment  {
 502
 503         }
 504         ;
 505
 506 lilypond_header:
 507         HEADER '{' lilypond_header_body '}'     {
 508                 $$ = THIS->lexer_->remove_scope ();
 509         }
 510         ;
 511
 512
 513 /*
 514         DECLARATIONS
 515 */
 516 assignment:
 517         STRING {
 518                 THIS->push_spot ();
 519         }
 520         /* cont */ '=' identifier_init  {
 521
 522         /*
 523                 Should find generic way of associating input with objects.
 524         */
 525                 Input ip = THIS->pop_spot ();
 526
 527                 if (! is_regular_identifier ($1))
 528                 {
 529                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 530                 }
 531
 532                 THIS->lexer_->set_identifier ($1, $4);
 533
 534 /*
 535  TODO: devise standard for protection in parser.
 536
 537   The parser stack lives on the C-stack, which means that
 538 all objects can be unprotected as soon as they're here.
 539
 540 */
 541         }
 542         | embedded_scm { }
 543         ;
 544
 545
 546 identifier_init:
 547         score_block {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | full_markup {
 552                 $$ = $1;
 553         }
 554         | output_def {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | context_def_spec_block {
 559                 $$ = $1;
 560         }
 561         | Music  {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | post_event {
 566                 $$ = $1->self_scm ();
 567                 scm_gc_unprotect_object ($$);
 568         }
 569         | number_expression {
 570                 $$ = $1;
 571         }
 572         | string {
 573                 $$ = $1;
 574         }
 575         | embedded_scm  {
 576                 $$ = $1;
 577         }
 578         ;
 579
 580 context_def_spec_block:
 581         CONTEXT '{' context_def_spec_body '}'
 582                 {
 583                 $$ = $3;
 584         }
 585         ;
 586
 587 context_def_spec_body:
 588         /**/ {
 589                 $$ = Context_def::make_scm ();
 590                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 591         }
 592         | CONTEXT_DEF_IDENTIFIER {
 593                 $$ = $1;
 594                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 595         }
 596         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 597                 Context_def*td = unsmob_context_def ($$);
 598
 599                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 600                         SCM tag = ly_caar (p);
 601
 602                         /* TODO: should make new tag "grob-definition" ? */
 603                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 604                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 605                 }
 606         }
 607         | context_def_spec_body context_mod {
 608                 unsmob_context_def ($$)->add_context_mod ($2);
 609         }
 610         ;
 611
 612
 613
 614 book_block:
 615         BOOK {
 616                 THIS->push_spot ();
 617         }
 618         /*cont*/ '{' book_body '}'      {
 619                 THIS->pop_spot ();
 620                 $$ = $4;
 621         }
 622         ;
 623
 624 /* FIXME:
 625    * Use 'handlers' like for toplevel-* stuff?
 626    * grok \paper and \midi?  */
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 632                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 633                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 634         }
 635         | book_body book_paper_block {
 636                 $$->bookpaper_ = $2;
 637                 scm_gc_unprotect_object ($2->self_scm ());
 638         }
 639         | book_body score_block {
 640                 Score *score = $2;
 641                 $$->scores_.push (score);
 642                 scm_gc_unprotect_object (score->self_scm ());
 643         }
 644         | book_body Composite_music {
 645                 Music *music = $2;
 646                 Score *score
 647                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 648                 $$->scores_.push (score);
 649                 scm_gc_unprotect_object (music->self_scm ());
 650         }
 651         | book_body lilypond_header {
 652                 $$->header_ = $2;
 653         }
 654         | book_body error {
 655
 656         }
 657         ;
 658
 659 score_block:
 660         SCORE {
 661                 THIS->push_spot ();
 662         }
 663         /*cont*/ '{' score_body '}'     {
 664                 THIS->pop_spot ();
 665                 $$ = $4;
 666         }
 667         ;
 668
 669 score_body:
 670         /**/    {
 671                 $$ = new Score;
 672
 673                 $$->set_spot (THIS->here_input ());
 674         }
 675         | SCORE_IDENTIFIER {
 676                 $$ = new Score ( *unsmob_score ($1));
 677                 $$->set_spot (THIS->here_input ());
 678         }
 679         | score_body Music {
 680                 SCM m = $2->self_scm ();
 681                 scm_gc_unprotect_object (m);
 682
 683                 /*
 684                         guh.
 685                 */
 686                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 687                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 688                         m = scm_call_1 (ly_car (check_funcs), m);
 689                 if (unsmob_music ($$->music_))
 690                 {
 691                         THIS->parser_error (_("Already have music in score"));
 692                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 693                 }
 694                 $$->music_ = m;
 695         }
 696         | score_body lilypond_header    {
 697                 $$->header_ = $2;
 698         }
 699         | score_body output_def {
 700                 $$->defs_.push ($2);
 701                 scm_gc_unprotect_object ($2->self_scm ());
 702         }
 703         | score_body error {
 704
 705         }
 706         ;
 707
 708
 709 /*
 710         OUTPUT DEF
 711 */
 712
 713 book_paper_block:
 714         output_def {
 715                 $$ = $1;
 716                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 717                 {
 718                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 719                         $$ = get_bookpaper (THIS);
 720                 }
 721         }
 722         ;
 723
 724
 725 output_def:
 726         output_def_body '}' {
 727                 $$ = $1;
 728                 if ($1->parent_)
 729                         THIS->lexer_->remove_scope ();
 730
 731                 THIS->lexer_->remove_scope ();
 732                 THIS->lexer_->pop_state ();
 733         }
 734         ;
 735
 736 output_def_head:
 737         BOOKPAPER {
 738                 $$ = get_bookpaper (THIS);
 739                 $$->input_origin_ = THIS->here_input ();
 740                 THIS->lexer_->add_scope ($$->scope_);
 741         }
 742         | MIDI    {
 743                 Output_def *p = get_midi (THIS);
 744                 $$ = p;
 745                 THIS->lexer_->add_scope (p->scope_);
 746         }
 747         | PAPER         {
 748                 Output_def* p = get_paper (THIS);
 749
 750                 if (p->parent_)
 751                         THIS->lexer_->add_scope (p->parent_->scope_);
 752
 753                 THIS->lexer_->add_scope (p->scope_);
 754                 $$ = p;
 755         }
 756         ;
 757
 758
 759 output_def_body:
 760         output_def_head '{' {
 761                 $$ = $1;
 762                 $$->input_origin_.set_spot (THIS->here_input ());
 763                 THIS->lexer_->push_initial_state ();
 764         }
 765         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 766                 scm_gc_unprotect_object ($1->self_scm ());
 767                 Output_def *o = unsmob_output_def ($3);
 768                 o->input_origin_.set_spot (THIS->here_input ());
 769                 $$ = o;
 770                 THIS->lexer_->remove_scope ();
 771                 THIS->lexer_->add_scope (o->scope_);
 772                 THIS->lexer_->push_initial_state ();
 773         }
 774         | output_def_body assignment  {
 775
 776         }
 777         | output_def_body context_def_spec_block        {
 778                 assign_context_def ($$, $2);
 779         }
 780         | output_def_body tempo_event  {
 781                 /*
 782                         junk this ? there already is tempo stuff in
 783                         music.
 784                 */
 785                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 786                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 787                 set_tempo ($$, d->get_length (), m);
 788                 scm_gc_unprotect_object ($2->self_scm ());
 789         }
 790         | output_def_body error {
 791
 792         }
 793         ;
 794
 795 tempo_event:
 796         TEMPO steno_duration '=' bare_unsigned  {
 797                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 798                 $$->set_property ("tempo-unit", $2);
 799                 $$->set_property ("metronome-count", scm_int2num ( $4));
 800         }
 801         ;
 802
 803 /*
 804 The representation of a  list is the
 805
 806   (LIST . LAST-CONS)
 807
 808  to have  efficient append.
 809 */
 810 Music_list:
 811         /* empty */ {
 812                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 813         }
 814         | Music_list Music {
 815                 SCM s = $$;
 816                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 817                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 818                 if (ly_c_pair_p (ly_cdr (s)))
 819                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 820                 else
 821                         scm_set_car_x (s, c); /* set first cons */
 822                 scm_set_cdr_x (s, c);  /* remember last cell */
 823         }
 824         | Music_list embedded_scm {
 825         }
 826         | Music_list error {
 827         }
 828         ;
 829
 830
 831 Music:
 832         Simple_music
 833         | Composite_music
 834         ;
 835
 836 Alternative_music:
 837         /* empty */ {
 838                 $$ = SCM_EOL;
 839         }
 840         | ALTERNATIVE '{' Music_list '}' {
 841                 $$ = $3;
 842         }
 843         ;
 844
 845
 846 Repeated_music:
 847         REPEAT simple_string bare_unsigned Music Alternative_music
 848         {
 849                 Music *beg = $4;
 850                 int times = $3;
 851                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 852                 if (times < scm_ilength (alts)) {
 853                   unsmob_music (ly_car (alts))
 854                     ->origin ()->warning (
 855                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 856                   alts = ly_truncate_list (times, alts);
 857                 }
 858
 859
 860                 SCM proc = ly_scheme_function ("make-repeated-music");
 861
 862                 SCM mus = scm_call_1 (proc, $2);
 863                 scm_gc_protect_object (mus); // UGH.
 864                 Music *r = unsmob_music (mus);
 865                 if (beg)
 866                         {
 867                         r-> set_property ("element", beg->self_scm ());
 868                         scm_gc_unprotect_object (beg->self_scm ());
 869                         }
 870                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 871
 872                 r-> set_property ("elements",alts);
 873                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 874                         /*
 875                         TODO: move this code to Scheme.
 876                         */
 877
 878                         /*
 879                         we can not get durations and other stuff correct down the line, so we have to
 880                         add to the duration log here.
 881                         */
 882                         SCM func = ly_scheme_function ("shift-duration-log");
 883
 884                         int dots = ($3 % 3) ? 0 : 1;
 885                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 886
 887                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 888
 889                         if (seq) {
 890                                 int list_len = scm_ilength (seq->music_list ());
 891                                 if (list_len != 2)
 892                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 893                                 shift -= 1;
 894                                 r->compress (Moment (Rational (1, list_len)));
 895                                 }
 896                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 897
 898                 }
 899                 r->set_spot (*$4->origin ());
 900
 901                 $$ = r;
 902         }
 903         ;
 904
 905 Sequential_music:
 906         SEQUENTIAL '{' Music_list '}'           {
 907                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 908                 $$->set_property ("elements", ly_car ($3));
 909                 $$->set_spot (THIS->here_input ());
 910         }
 911         | '{' Music_list '}'            {
 912                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 913                 $$->set_property ("elements", ly_car ($2));
 914                 $$->set_spot (THIS->here_input ());
 915         }
 916         ;
 917
 918 Simultaneous_music:
 919         SIMULTANEOUS '{' Music_list '}'{
 920                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 921                 $$->set_property ("elements", ly_car ($3));
 922                 $$->set_spot (THIS->here_input ());
 923
 924         }
 925         | simul_open Music_list simul_close     {
 926                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 927                 $$->set_property ("elements", ly_car ($2));
 928                 $$->set_spot (THIS->here_input ());
 929         }
 930         ;
 931
 932 Simple_music:
 933         event_chord             { $$ = $1; }
 934         | MUSIC_IDENTIFIER {
 935                 $$ = unsmob_music ($1);
 936         }
 937         | music_property_def
 938         | context_change
 939         ;
 940
 941
 942 optional_context_mod:
 943         /**/ { $$ = SCM_EOL; }
 944         | WITH { THIS->lexer_->push_initial_state (); }
 945         '{' context_mod_list '}'
 946         {
 947                 THIS->lexer_->pop_state ();
 948                 $$ = $4;
 949         }
 950         ;
 951
 952 context_mod_list:
 953         /* */  { $$ = SCM_EOL; }
 954         | context_mod_list context_mod  {
 955                  $$ = scm_cons ($2, $1);
 956         }
 957         ;
 958
 959
 960 Composite_music:
 961         Prefix_composite_music { $$ = $1; }
 962         | Grouped_music_list { $$ = $1; }
 963         ;
 964
 965 Grouped_music_list:
 966         Simultaneous_music              { $$ = $1; }
 967         | Sequential_music              { $$ = $1; }
 968         ;
 969
 970 Generic_prefix_music_scm:
 971         MUSIC_FUNCTION {
 972                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 973         }
 974         | MUSIC_FUNCTION_SCM {
 975                 THIS->push_spot ();
 976         } embedded_scm {
 977                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 978         }
 979         | MUSIC_FUNCTION_MUSIC {
 980                 THIS->push_spot ();
 981         } Music {
 982                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 983                 scm_gc_unprotect_object ($3->self_scm ());
 984         }
 985         | MUSIC_FUNCTION_SCM_MUSIC {
 986                 THIS->push_spot ();
 987         }  embedded_scm Music {
 988                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 989                 scm_gc_unprotect_object ($4->self_scm ());
 990         }
 991         | MUSIC_FUNCTION_SCM_SCM {
 992                 THIS->push_spot ();
 993         }  embedded_scm embedded_scm {
 994                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 995         }
 996         | MUSIC_FUNCTION_MUSIC_MUSIC {
 997                 THIS->push_spot ();
 998         }  Music  Music {
 999                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1000                 scm_gc_unprotect_object ($3->self_scm ());
1001                 scm_gc_unprotect_object ($4->self_scm ());
1002         }
1003         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1004                 THIS->push_spot ();
1005         } embedded_scm Music Music {
1006                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1007                         $3, $4->self_scm (), $5->self_scm ());
1008                 scm_gc_unprotect_object ($5->self_scm ());
1009                 scm_gc_unprotect_object ($4->self_scm ());
1010         }
1011         ;
1012
1013 Generic_prefix_music:
1014         Generic_prefix_music_scm {
1015                 SCM func = ly_car ($1);
1016                 Input *loc = unsmob_input (ly_cadr ($1));
1017                 SCM args = ly_cddr ($1);
1018                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1019                 int k = 0;
1020                 bool ok  = true;
1021                 for (SCM s = sig, t = args;
1022                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1023                         s = ly_cdr (s), t = ly_cdr (t)) {
1024                         k++;
1025                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1026                         {
1027                                 loc->error (_f ("Argument %d failed typecheck", k));
1028                                 THIS->error_level_ = 1;
1029                                 ok = false;
1030                         }
1031                 }
1032                 SCM m = SCM_EOL;
1033                 if (ok)
1034                         m = scm_apply_0 (func, ly_cdr ($1));
1035                 if (unsmob_music (m))
1036                         {
1037                         $$ = unsmob_music (m);
1038                         scm_gc_protect_object (m);
1039                         }
1040                 else
1041                         {
1042                         if (ok)
1043                                 loc->error (_ ("Music head function should return Music object."));
1044                         $$ = MY_MAKE_MUSIC ("Music");
1045                         }
1046                 $$->set_spot (*loc);
1047         }
1048         ;
1049
1050
1051 Prefix_composite_music:
1052         Generic_prefix_music {
1053                 $$ = $1;
1054         }
1055         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1056                 $$ = context_spec_music ($2, $4, $6, $5);
1057
1058         }
1059         | CONTEXT simple_string optional_context_mod Music {
1060                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1061         }
1062         | NEWCONTEXT simple_string optional_context_mod Music {
1063                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1064                         $3);
1065         }
1066
1067         | TIMES {
1068                 THIS->push_spot ();
1069         }
1070         /* CONTINUED */
1071                 fraction Music
1072
1073         {
1074                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1075                 Music *mp = $4;
1076
1077                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1078                 $$->set_spot (THIS->pop_spot ());
1079
1080                 $$->set_property ("element", mp->self_scm ());
1081                 scm_gc_unprotect_object (mp->self_scm ());
1082                 $$->set_property ("numerator", scm_int2num (n));
1083                 $$->set_property ("denominator", scm_int2num (d));
1084                 $$->compress (Moment (Rational (n,d)));
1085
1086         }
1087         | Repeated_music                { $$ = $1; }
1088         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1089                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1090                 Music *p = $4;
1091                 Pitch from = *unsmob_pitch ($2);
1092                 Pitch to = *unsmob_pitch ($3);
1093
1094                 p->transpose (interval (from, to));
1095                 $$->set_property ("element", p->self_scm ());
1096                 scm_gc_unprotect_object (p->self_scm ());
1097         }
1098         | NOTES
1099                 {
1100                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1101                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1102         }
1103         Music
1104                 { $$ = $3;
1105                   THIS->lexer_->pop_state ();
1106                 }
1107         | DRUMS
1108                 {
1109                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1110                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1111         }
1112         Music
1113                 { $$ = $3;
1114                   THIS->lexer_->pop_state ();
1115                 }
1116         | FIGURES
1117                 { THIS->lexer_->push_figuredbass_state (); }
1118         Music
1119                 {
1120                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1121                   chm->set_property ("element", $3->self_scm ());
1122                   $$ = chm;
1123                   scm_gc_unprotect_object ($3->self_scm ());
1124
1125                   THIS->lexer_->pop_state ();
1126         }
1127         | CHORDS {
1128                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1129                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1130                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1131                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1132
1133         }
1134         Music
1135         {
1136                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1137                   chm->set_property ("element", $3->self_scm ());
1138                   scm_gc_unprotect_object ($3->self_scm ());
1139                   $$ = chm;
1140
1141                   THIS->lexer_->pop_state ();
1142         }
1143         | LYRICS
1144                 { THIS->lexer_->push_lyric_state (); }
1145         Music
1146                 {
1147                   $$ = $3;
1148                   THIS->lexer_->pop_state ();
1149         }
1150         | relative_music        { $$ = $1; }
1151         | re_rhythmed_music     { $$ = $1; }
1152         | TAG embedded_scm Music {
1153                 tag_music ($3, $2, THIS->here_input ());
1154                 $$ = $3;
1155         }
1156         ;
1157
1158 relative_music:
1159         RELATIVE absolute_pitch Music {
1160                 Music *m = $3;
1161                 Pitch start = *unsmob_pitch ($2);
1162                 $$ = make_music_relative (start, m);
1163                 scm_gc_unprotect_object (m->self_scm ());
1164         }
1165         | RELATIVE Composite_music {
1166                 Music *m = $2;
1167
1168                 Pitch middle_c (0, 0, 0);
1169                 $$ = make_music_relative (middle_c, m);
1170                 scm_gc_unprotect_object (m->self_scm ());
1171         }
1172         ;
1173
1174 new_lyrics:
1175         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1176         /*cont */
1177         Grouped_music_list {
1178         /* Can also use Music at the expensive of two S/Rs similar to
1179            \repeat \alternative */
1180                 THIS->lexer_->pop_state ();
1181 #if 0
1182                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1183                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1184                 $$ = music;
1185 #else
1186                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1187 #endif
1188         }
1189         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1190         Grouped_music_list {
1191                 THIS->lexer_->pop_state ();
1192                 $$ = scm_cons ($4->self_scm (), $1);
1193         }
1194         ;
1195
1196 re_rhythmed_music:
1197         Grouped_music_list new_lyrics {
1198
1199                 /* FIXME: should find out uniqueXXX name from music */
1200                 SCM name = $1->get_property ("context-id");
1201                 //if (name == SCM_EOL)
1202                 if (!ly_c_string_p (name))
1203                         name = scm_makfrom0str ("");
1204
1205                 SCM context = scm_makfrom0str ("Lyrics");
1206                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1207
1208                 SCM lst = SCM_EOL;
1209                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1210                 {
1211                         Music *music = unsmob_music (ly_car (s));
1212                         Music *com = make_lyric_combine_music (name, music);
1213                         Music *csm = context_spec_music (context,
1214                                 get_next_unique_context (), com, SCM_EOL);
1215                         lst = scm_cons (csm->self_scm (), lst);
1216                 }
1217                 /* FIXME: only first lyric music is accepted,
1218                           the rest is junked */
1219                 all->set_property ("elements", scm_cons ($1->self_scm (),
1220                         lst));
1221                 $$ = all;
1222                 scm_gc_unprotect_object ($1->self_scm ());
1223         }
1224         | LYRICSTO {
1225                 THIS->lexer_->push_lyric_state ();
1226         } simple_string Music {
1227                 THIS->lexer_->pop_state ();
1228                 Music *music = $4;
1229                 SCM name = $3;
1230                 $$ = make_lyric_combine_music (name, music);
1231                 scm_gc_unprotect_object (music->self_scm ());
1232         }
1233         ;
1234
1235 context_change:
1236         CHANGE STRING '=' STRING  {
1237                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1238                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1239                 t-> set_property ("change-to-id", $4);
1240
1241                 $$ = t;
1242                 $$->set_spot (THIS->here_input ());
1243         }
1244         ;
1245
1246 property_operation:
1247         STRING '=' scalar {
1248                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1249                         scm_string_to_symbol ($1), $3);
1250         }
1251         | UNSET simple_string {
1252                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1253                         scm_string_to_symbol ($2));
1254         }
1255         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1256                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1257                         scm_string_to_symbol ($2), $3, $5);
1258         }
1259         | REVERT simple_string embedded_scm {
1260                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1261                         scm_string_to_symbol ($2), $3);
1262         }
1263         ;
1264
1265 context_def_mod:
1266         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1267         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1268
1269         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1270         | DENIES { $$ = ly_symbol2scm ("denies"); }
1271
1272         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1273         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1274         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1275         | NAME { $$ = ly_symbol2scm ("context-name"); }
1276         ;
1277
1278 context_mod:
1279         property_operation { $$ = $1; }
1280         | context_def_mod STRING {
1281                 $$ = scm_list_2 ($1, $2);
1282         }
1283         ;
1284
1285 context_prop_spec:
1286         simple_string {
1287                 if (!is_regular_identifier ($1))
1288                 {
1289                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1290                 }
1291
1292                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1293                         scm_string_to_symbol ($1));
1294         }
1295         | simple_string '.' simple_string {
1296                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1297                         scm_string_to_symbol ($3));
1298         }
1299         ;
1300
1301 music_property_def:
1302         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1303                 $$ = property_op_to_music (scm_list_4 (
1304                         ly_symbol2scm ("poppush"),
1305                         ly_cadr ($2),
1306                         $3, $5));
1307                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1308         }
1309         | REVERT context_prop_spec embedded_scm {
1310                 $$ = property_op_to_music (scm_list_3 (
1311                         ly_symbol2scm ("pop"),
1312                         ly_cadr ($2),
1313                         $3));
1314
1315                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1316         }
1317         | SET context_prop_spec '=' scalar {
1318                 $$ = property_op_to_music (scm_list_3 (
1319                         ly_symbol2scm ("assign"),
1320                         ly_cadr ($2),
1321                         $4));
1322                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1323         }
1324         | UNSET context_prop_spec {
1325                 $$ = property_op_to_music (scm_list_2 (
1326                         ly_symbol2scm ("unset"),
1327                         ly_cadr ($2)));
1328                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1329         }
1330         | ONCE music_property_def {
1331                 SCM e = $2->get_property ("element");
1332                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1333                 $$ = $2;
1334
1335         }
1336         ;
1337
1338
1339 string:
1340         STRING {
1341                 $$ = $1;
1342         }
1343         | STRING_IDENTIFIER {
1344                 $$ = $1;
1345         }
1346         | string '+' string {
1347                 $$ = scm_string_append (scm_list_2 ($1, $3));
1348         }
1349         ;
1350
1351 simple_string: STRING {
1352         }
1353         | LYRICS_STRING {
1354         }
1355         ;
1356
1357 scalar: string {
1358         }
1359         | LYRICS_STRING {
1360         }
1361         | bare_int {
1362                 $$ = scm_int2num ($1);
1363         }
1364         | embedded_scm {
1365         }
1366         | full_markup {
1367         }
1368         | DIGIT {
1369                 $$ = scm_int2num ($1);
1370         }
1371         ;
1372
1373 /*
1374 FIXME: remove or fix this comment.  What is `This'?
1375
1376 This is a trick:
1377
1378 Adding pre_events to the simple_element
1379 makes the choice between
1380
1381   string:  STRING
1382
1383 and
1384
1385   simple_element: STRING
1386
1387 a single shift/reduction conflict.
1388
1389 nevertheless, this is not very clean, and we should find a different
1390 solution.
1391
1392 */
1393 pre_events: {
1394                 THIS->push_spot ();
1395         }
1396         ;
1397
1398 event_chord:
1399         pre_events simple_element post_events   {
1400                 SCM elts = $2-> get_property ("elements");
1401
1402                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1403
1404                 $2->set_property ("elements", elts);
1405                 $$ = $2;
1406         }
1407         | command_element
1408         | note_chord_element
1409         ;
1410
1411
1412 note_chord_element:
1413         chord_body optional_notemode_duration post_events
1414         {
1415                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1416                 SCM es = $1->get_property ("elements");
1417                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1418
1419                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1420                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1421                 es = ly_append2 (es, postevs);
1422
1423                 $1-> set_property ("elements", es);
1424                 $$ = $1;
1425         }
1426         ;
1427
1428 chord_open: '<'
1429         ;
1430
1431 chord_close: '>'
1432         ;
1433
1434 simul_open: DOUBLE_ANGLE_OPEN
1435         ;
1436
1437 simul_close: DOUBLE_ANGLE_CLOSE
1438         ;
1439
1440 chord_body:
1441         chord_open chord_body_elements chord_close
1442         {
1443                 $$ = MY_MAKE_MUSIC ("EventChord");
1444                 $$->set_property ("elements",
1445                         scm_reverse_x ($2, SCM_EOL));
1446         }
1447         ;
1448
1449 chord_body_elements:
1450         /* empty */             { $$ = SCM_EOL; }
1451         | chord_body_elements chord_body_element {
1452                 $$ = scm_cons ($2->self_scm (), $1);
1453                 scm_gc_unprotect_object ($2->self_scm ());
1454         }
1455         ;
1456
1457 chord_body_element:
1458         pitch  exclamations questions octave_check post_events
1459         {
1460                 int q = $3;
1461                 int ex = $2;
1462                 SCM check = $4;
1463                 SCM post = $5;
1464
1465                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1466                 n->set_property ("pitch", $1);
1467                 if (q % 2)
1468                         n->set_property ("cautionary", SCM_BOOL_T);
1469                 if (ex % 2 || q % 2)
1470                         n->set_property ("force-accidental", SCM_BOOL_T);
1471
1472                 if (ly_c_pair_p (post)) {
1473                         SCM arts = scm_reverse_x (post, SCM_EOL);
1474                         n->set_property ("articulations", arts);
1475                 }
1476                 if (ly_c_number_p (check))
1477                 {
1478                         int q = ly_scm2int (check);
1479                         n->set_property ("absolute-octave", scm_int2num (q-1));
1480                 }
1481
1482
1483                 $$ = n;
1484         }
1485         | DRUM_PITCH post_events {
1486                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1487                 n->set_property ("duration", $2);
1488                 n->set_property ("drum-type", $1);
1489                 n->set_spot (THIS->here_input ());
1490
1491                 if (ly_c_pair_p ($2)) {
1492                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1493                         n->set_property ("articulations", arts);
1494                 }
1495                 $$ = n;
1496         }
1497         ;
1498
1499 add_quote:
1500         ADDQUOTE string Music {
1501                 SCM adder = ly_scheme_function ("add-quotable");
1502
1503                 scm_call_2 (adder, $2, $3->self_scm ());
1504                 scm_gc_unprotect_object ($3->self_scm ());
1505         }
1506         ;
1507
1508 command_element:
1509         command_req {
1510                 $$ = MY_MAKE_MUSIC ("EventChord");
1511                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1512                 scm_gc_unprotect_object ($1->self_scm ());
1513
1514                 $$-> set_spot (THIS->here_input ());
1515                 $1-> set_spot (THIS->here_input ());
1516         }
1517         | SKIP duration_length {
1518                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1519                 skip->set_property ("duration", $2);
1520
1521                 $$ = skip;
1522         }
1523         | QUOTE STRING duration_length {
1524                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1525                 SCM evs = SCM_EOL;
1526                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1527                 {
1528                         SCM key = $2; // use symbol?
1529                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1530                 }
1531                 Music *quote = 0;
1532                 if (ly_c_vector_p (evs))
1533                 {
1534                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1535                         quote->set_property ("duration", $3);
1536                         quote->set_property ("quoted-events", evs);
1537                 } else {
1538                         THIS->here_input ().warning (_f ("Can\'t find music"));
1539                         quote = MY_MAKE_MUSIC ("Event");
1540                 }
1541                 quote->set_spot (THIS->here_input ());
1542                 $$ = quote;
1543         }
1544         | OCTAVE { THIS->push_spot (); }
1545           pitch {
1546                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1547                 $$ = m;
1548                 $$->set_spot (THIS->pop_spot ());
1549                 $$->set_property ("pitch", $3);
1550         }
1551         | E_LEFTSQUARE {
1552                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1553                 m->set_property ("span-direction", scm_int2num (START));
1554                 m->set_spot (THIS->here_input ());
1555
1556                 $$ = MY_MAKE_MUSIC ("EventChord");
1557                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1558                 scm_gc_unprotect_object (m->self_scm ());
1559                 $$->set_spot (THIS->here_input ());
1560         }
1561         | E_RIGHTSQUARE {
1562                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1563                 m->set_property ("span-direction", scm_int2num (STOP));
1564                 m->set_spot (THIS->here_input ());
1565
1566                 $$ = MY_MAKE_MUSIC ("EventChord");
1567                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1568                 $$->set_spot (THIS->here_input ());
1569                 scm_gc_unprotect_object (m->self_scm ());
1570         }
1571         | E_BACKSLASH {
1572                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1573                 $$->set_spot (THIS->here_input ());
1574         }
1575         | '|'      {
1576                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1577
1578                 if (Music * m = unsmob_music (pipe))
1579                         $$ = m->clone ();
1580                 else
1581                         $$ = MY_MAKE_MUSIC ("BarCheck");
1582
1583                 $$->set_spot (THIS->here_input ());
1584         }
1585         | TRANSPOSITION pitch {
1586                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1587                                         $2);
1588                 $$->set_spot (THIS-> here_input ());
1589                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1590                         $$, SCM_EOL);
1591         }
1592         | BAR STRING                    {
1593                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1594
1595                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1596                                         t, SCM_EOL);
1597                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1598                 $$->set_spot (THIS->here_input ());
1599                 t->set_spot (THIS->here_input ());
1600         }
1601         | PARTIAL duration_length       {
1602                 Moment m = - unsmob_duration ($2)->get_length ();
1603                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1604                 p->set_spot (THIS->here_input ());
1605                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1606                                         p, SCM_EOL);
1607                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1608                                         p, SCM_EOL);
1609                 $$ = p;
1610         }
1611         | CLEF STRING  {
1612                 SCM proc = ly_scheme_function ("make-clef-set");
1613
1614                 SCM result = scm_call_1 (proc, $2);
1615                 scm_gc_protect_object (result);
1616                 $$ = unsmob_music (result);
1617         }
1618         | TIME_T fraction  {
1619                 SCM proc= ly_scheme_function ("make-time-signature-set");
1620
1621                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1622                 scm_gc_protect_object (result);
1623                 $$ = unsmob_music (result);
1624         }
1625         | MARK scalar {
1626                 SCM proc = ly_scheme_function ("make-mark-set");
1627
1628                 SCM result = scm_call_1 (proc, $2);
1629                 scm_gc_protect_object (result);
1630                 $$ = unsmob_music (result);
1631         }
1632         ;
1633
1634 command_req:
1635         E_TILDE {
1636                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1637         }
1638         | MARK DEFAULT  {
1639                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1640                 $$ = m;
1641         }
1642         | tempo_event {
1643                 $$ = $1;
1644         }
1645         | KEY DEFAULT {
1646                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1647                 $$ = key;
1648         }
1649         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1650
1651                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1652                 if (scm_ilength ($3) > 0)
1653                 {
1654                         key->set_property ("pitch-alist", $3);
1655                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1656                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1657                 } else {
1658                         THIS->parser_error (_ ("Second argument must be pitch list."));
1659                 }
1660
1661                 $$ = key;
1662         }
1663         ;
1664
1665 post_events:
1666         /* empty */ {
1667                 $$ = SCM_EOL;
1668         }
1669         | post_events post_event {
1670                 $2->set_spot (THIS->here_input ());
1671                 $$ = scm_cons ($2->self_scm (), $$);
1672                 scm_gc_unprotect_object ($2->self_scm ());
1673         }
1674         | post_events tagged_post_event {
1675                 $2 -> set_spot (THIS->here_input ());
1676                 $$ = scm_cons ($2->self_scm (), $$);
1677                 scm_gc_unprotect_object ($2->self_scm ());
1678         }
1679         ;
1680
1681
1682 tagged_post_event:
1683         '-' TAG embedded_scm post_event {
1684                 tag_music ($4, $3, THIS->here_input ());
1685                 $$ = $4;
1686         }
1687         ;
1688
1689 post_event:
1690         direction_less_event {
1691                 $$ = $1;
1692         }
1693         | HYPHEN {
1694                 if (!THIS->lexer_->is_lyric_state ())
1695                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1696                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1697         }
1698         | EXTENDER {
1699                 if (!THIS->lexer_->is_lyric_state ())
1700                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1701                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1702         }
1703         | script_dir direction_reqd_event {
1704                 if ($1)
1705                         $2->set_property ("direction", scm_int2num ($1));
1706                 $$ = $2;
1707         }
1708         | script_dir direction_less_event {
1709                 if ($1)
1710                         $2->set_property ("direction", scm_int2num ($1));
1711                 $$ = $2;
1712         }
1713         | string_number_event
1714         ;
1715
1716 string_number_event:
1717         E_UNSIGNED {
1718                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1719                 s->set_property ("string-number", scm_int2num ($1));
1720                 s->set_spot (THIS->here_input ());
1721                 $$ = s;
1722         }
1723         ;
1724
1725
1726 direction_less_event:
1727         '['  {
1728
1729
1730 /*
1731
1732 TODO: should take all these defs out of the parser, adn make use
1733 configurable, i.e.
1734
1735
1736 (set-articulation '~ "trill")
1737
1738 */
1739                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1740                 m->set_spot (THIS->here_input ());
1741                 m->set_property ("span-direction", scm_int2num (START));
1742                 $$ = m;
1743         }
1744         | ']'  {
1745                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1746                 m->set_spot (THIS->here_input ());
1747                 m->set_property ("span-direction", scm_int2num (STOP));
1748                 $$ = m;
1749         }
1750         | '~' {
1751                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1752                 m->set_spot (THIS->here_input ());
1753                 $$ = m;
1754         }
1755         | close_event {
1756                 $$ = $1;
1757                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1758                         scm_int2num (START));
1759         }
1760         | open_event {
1761                 $$ = $1;
1762                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1763                         scm_int2num (STOP));
1764         }
1765         | EVENT_IDENTIFIER      {
1766                 $$ = unsmob_music ($1);
1767         }
1768         | tremolo_type  {
1769                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1770                a->set_spot (THIS->here_input ());
1771                a->set_property ("tremolo-type", scm_int2num ($1));
1772                $$ = a;
1773         }
1774         ;
1775
1776 direction_reqd_event:
1777         gen_text_def {
1778                 $$ = $1;
1779         }
1780         | script_abbreviation {
1781                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1782                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1783                 if (ly_c_string_p (s))
1784                         a->set_property ("articulation-type", s);
1785                 else THIS->parser_error (_ ("Expecting string as script definition"));
1786                 $$ = a;
1787         }
1788         ;
1789
1790 octave_check:
1791         /**/ { $$ = SCM_EOL; }
1792         | '='  { $$ = scm_int2num (0); }
1793         | '=' sub_quotes { $$ = scm_int2num ($2); }
1794         | '=' sup_quotes { $$ = scm_int2num ($2); }
1795         ;
1796
1797 sup_quotes:
1798         '\'' {
1799                 $$ = 1;
1800         }
1801         | sup_quotes '\'' {
1802                 $$ ++;
1803         }
1804         ;
1805
1806 sub_quotes:
1807         ',' {
1808                 $$ = 1;
1809         }
1810         | sub_quotes ',' {
1811                 $$++;
1812         }
1813         ;
1814
1815 steno_pitch:
1816         NOTENAME_PITCH  {
1817                 $$ = $1;
1818         }
1819         | NOTENAME_PITCH sup_quotes     {
1820                 Pitch p = *unsmob_pitch ($1);
1821                 p = p.transposed (Pitch ($2,0,0));
1822                 $$ = p.smobbed_copy ();
1823         }
1824         | NOTENAME_PITCH sub_quotes      {
1825                 Pitch p =* unsmob_pitch ($1);
1826                 p = p.transposed (Pitch (-$2,0,0));
1827                 $$ = p.smobbed_copy ();
1828         }
1829         ;
1830
1831 /*
1832 ugh. duplication
1833 */
1834
1835 steno_tonic_pitch:
1836         TONICNAME_PITCH {
1837                 $$ = $1;
1838         }
1839         | TONICNAME_PITCH sup_quotes    {
1840                 Pitch p = *unsmob_pitch ($1);
1841                 p = p.transposed (Pitch ($2,0,0));
1842                 $$ = p.smobbed_copy ();
1843         }
1844         | TONICNAME_PITCH sub_quotes     {
1845                 Pitch p =* unsmob_pitch ($1);
1846
1847                 p = p.transposed (Pitch (-$2,0,0));
1848                 $$ = p.smobbed_copy ();
1849         }
1850         ;
1851
1852 pitch:
1853         steno_pitch {
1854                 $$ = $1;
1855         }
1856         ;
1857
1858 pitch_also_in_chords:
1859         pitch
1860         | steno_tonic_pitch
1861         ;
1862
1863 close_event:
1864         '('     {
1865                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1866                 $$ = s;
1867                 s->set_spot (THIS->here_input ());
1868         }
1869         | E_OPEN        {
1870                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1871                 $$ = s;
1872                 s->set_spot (THIS->here_input ());
1873         }
1874         | E_SMALLER {
1875                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1876                 $$ = s;
1877                 s->set_spot (THIS->here_input ());
1878         }
1879         | E_BIGGER {
1880                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1881                 $$ = s;
1882                 s->set_spot (THIS->here_input ());
1883         }
1884         ;
1885
1886
1887 open_event:
1888         E_EXCLAMATION   {
1889                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1890                 s->set_spot (THIS->here_input ());
1891
1892                 $$ = s;
1893         }
1894         | ')'   {
1895                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1896                 $$ = s;
1897                 s->set_spot (THIS->here_input ());
1898
1899         }
1900         | E_CLOSE       {
1901                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1902                 $$ = s;
1903                 s->set_property ("span-type",
1904                         scm_makfrom0str ("phrasing-slur"));
1905                 s->set_spot (THIS->here_input ());
1906         }
1907         ;
1908
1909 gen_text_def:
1910         full_markup {
1911                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1912                 t->set_property ("text", $1);
1913                 t->set_spot (THIS->here_input ());
1914                 $$ = t;
1915         }
1916         | string {
1917                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1918                 t->set_property ("text",
1919                         make_simple_markup (THIS->lexer_->encoding (), $1));
1920                 t->set_spot (THIS->here_input ());
1921                 $$ = t;
1922
1923         }
1924         | DIGIT {
1925                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1926                 t->set_property ("digit", scm_int2num ($1));
1927                 t->set_spot (THIS->here_input ());
1928                 $$ = t;
1929         }
1930         ;
1931
1932 script_abbreviation:
1933         '^'             {
1934                 $$ = scm_makfrom0str ("Hat");
1935         }
1936         | '+'           {
1937                 $$ = scm_makfrom0str ("Plus");
1938         }
1939         | '-'           {
1940                 $$ = scm_makfrom0str ("Dash");
1941         }
1942         | '|'           {
1943                 $$ = scm_makfrom0str ("Bar");
1944         }
1945         | '>'           {
1946                 $$ = scm_makfrom0str ("Larger");
1947         }
1948         | '.'           {
1949                 $$ = scm_makfrom0str ("Dot");
1950         }
1951         | '_' {
1952                 $$ = scm_makfrom0str ("Underscore");
1953         }
1954         ;
1955
1956 script_dir:
1957         '_'     { $$ = DOWN; }
1958         | '^'   { $$ = UP; }
1959         | '-'   { $$ = CENTER; }
1960         ;
1961
1962
1963 absolute_pitch:
1964         steno_pitch     {
1965                 $$ = $1;
1966         }
1967         ;
1968
1969 duration_length:
1970         multiplied_duration {
1971                 $$ = $1;
1972         }
1973         ;
1974
1975 optional_notemode_duration:
1976         {
1977                 Duration dd = THIS->default_duration_;
1978                 $$ = dd.smobbed_copy ();
1979
1980                 THIS->beam_check ($$);
1981         }
1982         | multiplied_duration   {
1983                 $$ = $1;
1984                 THIS->default_duration_ = *unsmob_duration ($$);
1985
1986                 THIS->beam_check ($$);
1987         }
1988         ;
1989
1990 steno_duration:
1991         bare_unsigned dots              {
1992                 int len = 0;
1993                 if (!is_duration ($1))
1994                         THIS->parser_error (_f ("not a duration: %d", $1));
1995                 else
1996                         len = intlog2 ($1);
1997
1998                 $$ = Duration (len, $2).smobbed_copy ();
1999         }
2000         | DURATION_IDENTIFIER dots      {
2001                 Duration *d = unsmob_duration ($1);
2002                 Duration k (d->duration_log (), d->dot_count () + $2);
2003                 *d = k;
2004                 $$ = $1;
2005         }
2006         ;
2007
2008 multiplied_duration:
2009         steno_duration {
2010                 $$ = $1;
2011         }
2012         | multiplied_duration '*' bare_unsigned {
2013                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2014         }
2015         | multiplied_duration '*' FRACTION {
2016                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2017
2018                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2019         }
2020         ;
2021
2022 fraction:
2023         FRACTION { $$ = $1; }
2024         | UNSIGNED '/' UNSIGNED {
2025                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2026         }
2027         ;
2028
2029 dots:
2030         /* empty */     {
2031                 $$ = 0;
2032         }
2033         | dots '.' {
2034                 $$ ++;
2035         }
2036         ;
2037
2038 tremolo_type:
2039         ':'     {
2040                 $$ = 0;
2041         }
2042         | ':' bare_unsigned {
2043                 if (!is_duration ($2))
2044                         THIS->parser_error (_f ("not a duration: %d", $2));
2045                 $$ = $2;
2046         }
2047         ;
2048
2049 bass_number:
2050         DIGIT   {
2051                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2052                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2053                                 $$);
2054         }
2055         | UNSIGNED {
2056                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2057                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2058                                 $$);
2059         }
2060         | STRING { $$ = $1; }
2061         ;
2062
2063 bass_mod:
2064         '-'     { $$ = -2; }
2065         | '+'   { $$ = 2; }
2066         | '!'   { $$ = 0; }
2067         ;
2068
2069 bass_figure:
2070         FIGURE_SPACE {
2071                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2072                 $$ = bfr->self_scm ();
2073                 scm_gc_unprotect_object ($$);
2074         }
2075         | bass_number  {
2076                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2077                 $$ = bfr->self_scm ();
2078
2079                 bfr->set_property ("figure", $1);
2080
2081                 scm_gc_unprotect_object ($$);
2082         }
2083         | bass_figure bass_mod {
2084                 Music *m = unsmob_music ($1);
2085                 if ($2) {
2086                         SCM salter = m->get_property ("alteration");
2087                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2088                         m->set_property ("alteration",
2089                                 scm_int2num (alter + $2));
2090                 } else {
2091                         m->set_property ("alteration", scm_int2num (0));
2092                 }
2093         }
2094         ;
2095
2096 br_bass_figure:
2097         '[' bass_figure {
2098                 $$ = $2;
2099                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2100         }
2101         | bass_figure   {
2102                 $$ = $1;
2103         }
2104         | br_bass_figure ']' {
2105                 $$ = $1;
2106                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2107         }
2108         ;
2109
2110 figure_list:
2111         /**/            {
2112                 $$ = SCM_EOL;
2113         }
2114         | figure_list br_bass_figure {
2115                 $$ = scm_cons ($2, $1);
2116         }
2117         ;
2118
2119 figure_spec:
2120         FIGURE_OPEN figure_list FIGURE_CLOSE {
2121                 Music *m = MY_MAKE_MUSIC ("EventChord");
2122                 $2 = scm_reverse_x ($2, SCM_EOL);
2123                 m->set_property ("elements", $2);
2124                 $$ = m->self_scm ();
2125         }
2126         ;
2127
2128
2129 optional_rest:
2130         /**/   { $$ = 0; }
2131         | REST { $$ = 1; }
2132         ;
2133
2134 simple_element:
2135         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2136
2137                 Input i = THIS->pop_spot ();
2138                 if (!THIS->lexer_->is_note_state ())
2139                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2140
2141                 Music *n = 0;
2142                 if ($6)
2143                         n = MY_MAKE_MUSIC ("RestEvent");
2144                 else
2145                         n = MY_MAKE_MUSIC ("NoteEvent");
2146
2147                 n->set_property ("pitch", $1);
2148                 n->set_property ("duration", $5);
2149
2150                 if (ly_c_number_p ($4))
2151                 {
2152                         int q = ly_scm2int ($4);
2153                         n->set_property ("absolute-octave", scm_int2num (q-1));
2154                 }
2155
2156                 if ($3 % 2)
2157                         n->set_property ("cautionary", SCM_BOOL_T);
2158                 if ($2 % 2 || $3 % 2)
2159                         n->set_property ("force-accidental", SCM_BOOL_T);
2160
2161                 Music *v = MY_MAKE_MUSIC ("EventChord");
2162                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2163                 scm_gc_unprotect_object (n->self_scm ());
2164
2165                 v->set_spot (i);
2166                 n->set_spot (i);
2167                 $$ = v;
2168         }
2169         | DRUM_PITCH optional_notemode_duration {
2170                 Input i = THIS->pop_spot ();
2171
2172                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2173                 n->set_property ("duration", $2);
2174                 n->set_property ("drum-type", $1);
2175
2176                 Music *v = MY_MAKE_MUSIC ("EventChord");
2177                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2178                 scm_gc_unprotect_object (n->self_scm ());
2179                 v->set_spot (i);
2180                 n->set_spot (i);
2181                 $$ = v;
2182
2183         }
2184         | figure_spec optional_notemode_duration {
2185                 Music *m = unsmob_music ($1);
2186                 Input i = THIS->pop_spot ();
2187                 m->set_spot (i);
2188                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2189                 {
2190                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2191                 }
2192                 $$ = m;
2193         }
2194         | RESTNAME optional_notemode_duration           {
2195
2196                 Input i = THIS->pop_spot ();
2197                 Music *ev = 0;
2198                 if (ly_scm2string ($1) == "s") {
2199                         /* Space */
2200                         ev = MY_MAKE_MUSIC ("SkipEvent");
2201                   }
2202                 else {
2203                         ev = MY_MAKE_MUSIC ("RestEvent");
2204
2205                     }
2206                 ev->set_property ("duration", $2);
2207                 ev->set_spot (i);
2208                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2209                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2210                 velt->set_spot (i);
2211
2212                 scm_gc_unprotect_object (ev->self_scm ());
2213
2214                 $$ = velt;
2215         }
2216         | MULTI_MEASURE_REST optional_notemode_duration         {
2217                 THIS->pop_spot ();
2218
2219                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2220                 SCM mus = scm_call_2 (proc, $2,
2221                         make_input (THIS->here_input ()));
2222                 scm_gc_protect_object (mus);
2223                 $$ = unsmob_music (mus);
2224         }
2225
2226         | lyric_element optional_notemode_duration      {
2227                 Input i = THIS->pop_spot ();
2228                 if (!THIS->lexer_->is_lyric_state ())
2229                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2230
2231                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2232                 lreq->set_property ("text", $1);
2233                 lreq->set_property ("duration",$2);
2234                 lreq->set_spot (i);
2235                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2236                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2237
2238                 $$= velt;
2239         }
2240         | new_chord {
2241                 THIS->pop_spot ();
2242
2243                 if (!THIS->lexer_->is_chord_state ())
2244                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2245                 $$ = unsmob_music ($1);
2246         }
2247         ;
2248
2249 lyric_element:
2250         /* FIXME: lyric flavoured markup would be better */
2251         full_markup {
2252         }
2253         | LYRICS_STRING {
2254         }
2255         ;
2256
2257 new_chord:
2258         steno_tonic_pitch optional_notemode_duration   {
2259                 $$ = make_chord ($1, $2, SCM_EOL);
2260         }
2261         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2262                 SCM its = scm_reverse_x ($4, SCM_EOL);
2263                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2264         }
2265         ;
2266
2267 chord_items:
2268         /**/ {
2269                 $$ = SCM_EOL;
2270         }
2271         | chord_items chord_item {
2272                 $$ = scm_cons ($2, $$);
2273         }
2274         ;
2275
2276 chord_separator:
2277         CHORD_COLON {
2278                 $$ = ly_symbol2scm ("chord-colon");
2279         }
2280         | CHORD_CARET {
2281                 $$ = ly_symbol2scm ("chord-caret");
2282         }
2283         | CHORD_SLASH steno_tonic_pitch {
2284                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2285         }
2286         | CHORD_BASS steno_tonic_pitch {
2287                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2288         }
2289         ;
2290
2291 chord_item:
2292         chord_separator {
2293                 $$ = $1;
2294         }
2295         | step_numbers {
2296                 $$ = scm_reverse_x ($1, SCM_EOL);
2297         }
2298         | CHORD_MODIFIER  {
2299                 $$ = $1;
2300         }
2301         ;
2302
2303 step_numbers:
2304         step_number { $$ = scm_cons ($1, SCM_EOL); }
2305         | step_numbers '.' step_number {
2306                 $$ = scm_cons ($3, $$);
2307         }
2308         ;
2309
2310 step_number:
2311         bare_unsigned {
2312                 $$ = make_chord_step ($1, 0);
2313         }
2314         | bare_unsigned '+' {
2315                 $$ = make_chord_step ($1, SHARP);
2316         }
2317         | bare_unsigned CHORD_MINUS {
2318                 $$ = make_chord_step ($1, FLAT);
2319         }
2320         ;
2321
2322 /*
2323         UTILITIES
2324
2325 TODO: should deprecate in favor of Scheme?
2326
2327  */
2328 number_expression:
2329         number_expression '+' number_term {
2330                 $$ = scm_sum ($1, $3);
2331         }
2332         | number_expression '-' number_term {
2333                 $$ = scm_difference ($1, $3);
2334         }
2335         | number_term
2336         ;
2337
2338 number_term:
2339         number_factor {
2340                 $$ = $1;
2341         }
2342         | number_factor '*' number_factor {
2343                 $$ = scm_product ($1, $3);
2344         }
2345         | number_factor '/' number_factor {
2346                 $$ = scm_divide ($1, $3);
2347         }
2348         ;
2349
2350 number_factor:
2351         '-'  number_factor { /* %prec UNARY_MINUS */
2352                 $$ = scm_difference ($2, SCM_UNDEFINED);
2353         }
2354         | bare_number
2355         ;
2356
2357
2358 bare_number:
2359         UNSIGNED        {
2360                 $$ = scm_int2num ($1);
2361         }
2362         | REAL          {
2363                 $$ = $1;
2364         }
2365         | NUMBER_IDENTIFIER             {
2366                 $$ = $1;
2367         }
2368         | REAL NUMBER_IDENTIFIER        {
2369                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2370         }
2371         | UNSIGNED NUMBER_IDENTIFIER    {
2372                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2373         }
2374         ;
2375
2376
2377 bare_unsigned:
2378         UNSIGNED {
2379                         $$ = $1;
2380         }
2381         | DIGIT {
2382                 $$ = $1;
2383         }
2384         ;
2385
2386 bare_int:
2387         bare_number {
2388                 if (scm_integer_p ($1) == SCM_BOOL_T)
2389                 {
2390                         int k = ly_scm2int ($1);
2391                         $$ = k;
2392                 } else
2393                 {
2394                         THIS->parser_error (_ ("need integer number arg"));
2395                         $$ = 0;
2396                 }
2397         }
2398         | '-' bare_int {
2399                 $$ = -$2;
2400         }
2401         ;
2402
2403 exclamations:
2404                 { $$ = 0; }
2405         | exclamations '!'      { $$ ++; }
2406         ;
2407
2408 questions:
2409                 { $$ = 0; }
2410         | questions '?' { $$ ++; }
2411         ;
2412
2413
2414
2415 full_markup:
2416         MARKUP_IDENTIFIER {
2417                 $$ = $1;
2418         }
2419         | MARKUP
2420                 { THIS->lexer_->push_markup_state (); }
2421         markup
2422                 { $$ = $3;
2423                   THIS->lexer_->pop_state ();
2424                 }
2425         ;
2426
2427
2428 /*
2429 This should be done more dynamically if possible.
2430 */
2431 markup:
2432         STRING {
2433                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2434         }
2435         | MARKUP_HEAD_EMPTY {
2436                 $$ = scm_list_1 ($1);
2437         }
2438         | MARKUP_HEAD_MARKUP0 markup {
2439                 $$ = scm_list_2 ($1, $2);
2440         }
2441         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2442                 $$ = scm_list_3 ($1, $2, $3);
2443         }
2444         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2445                 $$ = scm_list_3 ($1, $2, $3);
2446         }
2447         | markup_line {
2448                 $$ = $1;
2449         }
2450         | MARKUP_HEAD_LIST0 markup_list {
2451                 $$ = scm_list_2 ($1,$2);
2452         }
2453         | MARKUP_HEAD_SCM0 embedded_scm {
2454                 $$ = scm_list_2 ($1, $2);
2455         }
2456         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2457                 $$ = scm_list_4 ($1, $2, $3, $4);
2458         }
2459         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2460                 $$ = scm_list_4 ($1, $2, $3, $4);
2461         }
2462         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2463                 $$ = scm_list_3 ($1, $2, $3);
2464         }
2465         | MARKUP_IDENTIFIER {
2466                 $$ = $1;
2467         }
2468         | STRING_IDENTIFIER {
2469                 $$ = $1;
2470         }
2471         | SCORE {
2472                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2473                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2474         } '{' score_body '}' {
2475                 Score * sc = $4;
2476                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2477                 scm_gc_unprotect_object (sc->self_scm ());
2478                 THIS->lexer_->pop_state ();
2479         }
2480         ;
2481
2482 markup_list:
2483         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2484         ;
2485
2486 markup_line:
2487         '{' markup_list_body '}' {
2488                 SCM line = ly_scheme_function ("line-markup");
2489
2490                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2491         }
2492         ;
2493
2494 markup_list_body:
2495         /**/ {  $$ = SCM_EOL; }
2496         | markup_list_body markup {
2497                 $$ = scm_cons ($2, $1);
2498         }
2499         ;
2500
2501
2502 %%
2503
2504 void
2505 My_lily_parser::set_yydebug (bool )
2506 {
2507 #if 0
2508         yydebug = 1;
2509 #endif
2510 }
2511
2512 void
2513 My_lily_parser::do_yyparse ()
2514 {
2515         yyparse ((void*)this);
2516 }
2517
2518
2519 /*
2520 Should make this optional?    It will also complain when you do
2521
2522         [s4]
2523
2524 which is entirely legitimate.
2525
2526 Or we can scrap it. Barchecks should detect wrong durations, and
2527 skipTypesetting speeds it up a lot.
2528 */
2529
2530 void
2531 My_lily_parser::beam_check (SCM dur)
2532 {
2533   Duration *d = unsmob_duration (dur);
2534   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2535     {
2536       Music *m = unsmob_music (last_beam_start_);
2537       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2538     }
2539   last_beam_start_ = SCM_EOL;
2540 }
2541
2542
2543
2544
2545 /*
2546
2547 It is a little strange to have this function in this file, but
2548 otherwise, we have to import music classes into the lexer.
2549
2550 */
2551 int
2552 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2553 {
2554         if (ly_c_string_p (sid)) {
2555                 *destination = sid;
2556                 return STRING_IDENTIFIER;
2557         } else if (ly_c_number_p (sid)) {
2558                 *destination = sid;
2559                 return NUMBER_IDENTIFIER;
2560         } else if (unsmob_context_def (sid)) {
2561                 *destination = unsmob_context_def (sid)->clone_scm ();
2562                 return CONTEXT_DEF_IDENTIFIER;
2563         } else if (unsmob_score (sid)) {
2564                 Score *score = new Score (*unsmob_score (sid));
2565                 *destination = score->self_scm ();
2566                 return SCORE_IDENTIFIER;
2567         } else if (Music *mus = unsmob_music (sid)) {
2568                 mus = mus->clone ();
2569                 *destination = mus->self_scm ();
2570                 unsmob_music (*destination)->
2571                         set_property ("origin", make_input (last_input_));
2572                 return dynamic_cast<Event*> (mus)
2573                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2574         } else if (unsmob_duration (sid)) {
2575                 *destination = unsmob_duration (sid)->smobbed_copy ();
2576                 return DURATION_IDENTIFIER;
2577         } else if (unsmob_output_def (sid)) {
2578                 Output_def *p = unsmob_output_def (sid);
2579                 p = p->clone ();
2580
2581                 *destination = p->self_scm ();
2582                 return OUTPUT_DEF_IDENTIFIER;
2583         } else if (Text_item::markup_p (sid)) {
2584                 *destination = sid;
2585                 return MARKUP_IDENTIFIER;
2586         }
2587
2588         return -1;
2589 }
2590
2591 Music *
2592 property_op_to_music (SCM op)
2593 {
2594         Music *m = 0;
2595         SCM tag = ly_car (op);
2596         SCM symbol = ly_cadr (op);
2597         SCM args = ly_cddr (op);
2598         SCM grob_val = SCM_UNDEFINED;
2599         SCM grob_sym = SCM_UNDEFINED;
2600         SCM val = SCM_UNDEFINED;
2601
2602         if (tag == ly_symbol2scm ("assign"))
2603                 {
2604                 m = MY_MAKE_MUSIC ("PropertySet");
2605                 val = ly_car (args);
2606                 }
2607         else if (tag == ly_symbol2scm ("unset"))
2608                 m = MY_MAKE_MUSIC ("PropertyUnset");
2609         else if (tag == ly_symbol2scm ("poppush")
2610                  || tag == ly_symbol2scm ("push"))
2611                 {
2612                 m = MY_MAKE_MUSIC ("OverrideProperty");
2613                 grob_sym = ly_car (args);
2614                 grob_val = ly_cadr (args);
2615                 }
2616         else if (tag == ly_symbol2scm ("pop")) {
2617                 m = MY_MAKE_MUSIC ("RevertProperty");
2618                 grob_sym = ly_car (args);
2619                 }
2620
2621         m->set_property ("symbol", symbol);
2622
2623         if (val != SCM_UNDEFINED)
2624                 m->set_property ("value", val);
2625         if (grob_val != SCM_UNDEFINED)
2626                 m->set_property ("grob-value", grob_val);
2627
2628         if (grob_sym != SCM_UNDEFINED)
2629                 {
2630                 bool itc = internal_type_checking_global_b;
2631                 /* UGH.
2632                 */
2633                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2634                 if (autobeam)
2635                         internal_type_checking_global_b = false;
2636                 m->set_property ("grob-property", grob_sym);
2637                 if (autobeam)
2638                         internal_type_checking_global_b = itc;
2639                 }
2640
2641         if (tag == ly_symbol2scm ("poppush"))
2642                 m->set_property ("pop-first", SCM_BOOL_T);
2643
2644
2645         return m;
2646 }
2647
2648 Music*
2649 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2650 {
2651         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2652
2653         csm->set_property ("element", m->self_scm ());
2654         scm_gc_unprotect_object (m->self_scm ());
2655
2656         csm->set_property ("context-type",
2657                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2658         csm->set_property ("property-operations", ops);
2659
2660         if (ly_c_string_p (id))
2661                 csm->set_property ("context-id", id);
2662         return csm;
2663 }
2664
2665 SCM
2666 get_next_unique_context ()
2667 {
2668         static int new_context_count;
2669         char s[1024];
2670         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2671         return scm_makfrom0str (s);
2672 }
2673