lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "main.hh"
  38 #include "misc.hh"
  39 #include "lily-lexer.hh"
  40 #include "lily-parser.hh"
  41 #include "paper-book.hh"
  42 #include "output-def.hh"
  43 #include "scm-hash.hh"
  44 #include "scm-option.hh"
  45 #include "score.hh"
  46 #include "text-item.hh"
  47 #include "warn.hh"
  48
  49 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  50
  51 Music *property_op_to_music (SCM op);
  52 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  53 SCM get_next_unique_context_id ();
  54 SCM get_next_unique_lyrics_context_id ();
  55
  56 #define YYERROR_VERBOSE 1
  57
  58 #define YYPARSE_PARAM my_lily_parser
  59 #define YYLEX_PARAM my_lily_parser
  60 #define THIS\
  61         ((Lily_parser *) my_lily_parser)
  62
  63 #define yyerror THIS->parser_error
  64
  65 /* We use custom location type: Input objects */
  66 #define YYLTYPE Input
  67 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  68         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  69
  70
  71 /* Add symbols to the TAGS field of a music object.  */
  72
  73 void
  74 tag_music (Music *m, SCM tag, Input ip)
  75 {
  76         SCM tags = m->get_property ("tags");
  77         if (scm_is_symbol (tag))
  78                 tags = scm_cons (tag, tags);
  79         else if (ly_c_list_p (tag))
  80                 tags = ly_append2 (tag, tags);
  81         else
  82                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  83
  84         m->set_property ("tags", tags);
  85 }
  86
  87 bool
  88 is_regular_identifier (SCM id)
  89 {
  90   String str = ly_scm2string (id);
  91   char const *s = str.to_str0 ();
  92
  93   bool v = true;
  94 #if 0
  95   isalpha (*s);
  96   s++;
  97 #endif
  98   while (*s && v)
  99    {
 100         v = v && isalnum (*s);
 101         s++;
 102    }
 103   return v;
 104 }
 105
 106
 107 SCM
 108 get_first_context_id (SCM type, Music *m)
 109 {
 110         SCM id = m->get_property ("context-id");
 111         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
 112             && scm_is_string (m->get_property ("context-id"))
 113             && scm_c_string_length (id) > 0)
 114         {
 115                 return id;
 116         }
 117         return SCM_EOL;
 118 }
 119
 120 SCM
 121 make_simple_markup (SCM a)
 122 {
 123         SCM simple = ly_lily_module_constant ("simple-markup");
 124         return scm_list_2 (simple, a);
 125 }
 126
 127 bool
 128 is_duration (int t)
 129 {
 130   return t && t == 1 << intlog2 (t);
 131 }
 132
 133 void
 134 set_music_properties (Music *p, SCM a)
 135 {
 136   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 137         p->internal_set_property (scm_caar (k), scm_cdar (k));
 138 }
 139
 140 SCM
 141 make_chord_step (int step, int alter)
 142 {
 143         if (step == 7)
 144                 alter += FLAT;
 145
 146         while (step < 0)
 147                 step += 7;
 148         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 149         return m.smobbed_copy ();
 150 }
 151
 152
 153 SCM
 154 make_chord (SCM pitch, SCM dur, SCM modification_list)
 155 {
 156         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
 157         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 158         scm_gc_protect_object (ch);
 159         return ch;
 160 }
 161
 162 /* Todo: actually also use apply iso. call too ...  */
 163 bool
 164 ly_input_procedure_p (SCM x)
 165 {
 166         return ly_c_procedure_p (x)
 167                 || (scm_is_pair (x) && ly_c_procedure_p (scm_car (x)));
 168 }
 169
 170 Music*
 171 set_property_music (SCM sym, SCM value)
 172 {
 173         Music *p = MY_MAKE_MUSIC ("PropertySet");
 174         p->set_property ("symbol", sym);
 175         p->set_property ("value", value);
 176         return p;
 177 }
 178
 179 Music*
 180 make_music_relative (Pitch start, Music *music)
 181 {
 182         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 183         relative->set_property ("element", music->self_scm ());
 184
 185         Pitch last = music->to_relative_octave (start);
 186         if (lily_1_8_relative)
 187                 music->set_property ("last-pitch", last.smobbed_copy ());
 188         return relative;
 189 }
 190
 191 Music*
 192 make_lyric_combine_music (SCM name, Music *music)
 193 {
 194         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 195         combine->set_property ("element", music->self_scm ());
 196         combine->set_property ("associated-context", name);
 197         return combine;
 198 }
 199
 200 %}
 201
 202 /* We use SCMs to do strings, because it saves us the trouble of
 203 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 204 of the parse stack onto the heap. */
 205
 206 %left ADDLYRICS
 207
 208 %union {
 209         Book *book;
 210         Output_def *outputdef;
 211         SCM scm;
 212         String *string;
 213         Music *music;
 214         Score *score;
 215         int i;
 216 }
 217 %{
 218
 219 int
 220 yylex (YYSTYPE *s, YYLTYPE *l, void *v)
 221 {
 222         Lily_parser *pars = (Lily_parser*) v;
 223         Lily_lexer *lex = pars->lexer_;
 224
 225         lex->lexval = (void*) s;
 226         lex->lexloc = l;
 227         lex->prepare_for_next_token ();
 228         return lex->yylex ();
 229 }
 230
 231
 232 %}
 233
 234 %expect 1
 235
 236 /* One shift/reduce problem
 237
 238 1.  \repeat
 239         \repeat .. \alternative
 240
 241     \repeat { \repeat .. \alternative }
 242
 243 or
 244
 245     \repeat { \repeat } \alternative
 246 */
 247
 248
 249 %pure_parser
 250 %locations
 251
 252 %token ACCEPTS
 253 %token ADDQUOTE
 254 %token LYRICSTO
 255 %token ALIAS
 256 %token ALTERNATIVE
 257 %token BAR
 258 %token BOOK
 259 %token CHANGE
 260 %token CHORDMODIFIERS
 261 %token CHORDS
 262 %token CHORDMODE
 263 %token DOUBLE_ANGLE_OPEN
 264 %token DOUBLE_ANGLE_CLOSE
 265 %token CLEF
 266 %token COMMANDSPANREQUEST
 267 %token CONSISTS
 268 %token CONTEXT
 269 %token DEFAULT
 270 %token DENIES
 271 %token DESCRIPTION
 272 %token EXTENDER
 273 %token FIGURES
 274 %token FIGUREMODE
 275 %token FIGURE_OPEN FIGURE_CLOSE
 276 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 277 %token GROBDESCRIPTIONS
 278 %token HEADER
 279 %token HYPHEN
 280 %token INVALID
 281 %token KEY
 282 %token LAYOUT
 283 %token LYRICS
 284 %token LYRIC_MARKUP
 285 %token LYRICMODE
 286 %token MARK
 287 %token MIDI
 288 %token MULTI_MEASURE_REST
 289 %token NAME
 290 %token NEWCONTEXT
 291 %token NOTEMODE
 292 %token OBJECTID
 293 %token OCTAVE
 294 %token ONCE
 295 %token OVERRIDE SET REVERT
 296 %token PAPER
 297 %token PARTIAL
 298 %token QUOTE
 299 %token RELATIVE
 300 %token REMOVE
 301 %token REPEAT
 302 %token REST
 303 %token SCM_T
 304 %token SCORE
 305 %token SEQUENTIAL
 306 %token ADDLYRICS
 307 %token SIMULTANEOUS
 308 %token SKIP
 309 %token SPANREQUEST
 310 %token TAG
 311 %token TEMPO
 312 %token TIMES
 313 %token TIME_T
 314 %token TRANSPOSE
 315 %token TRANSPOSITION
 316 %token TYPE
 317 %token UNSET
 318 %token WITH
 319 %token MARKUP
 320
 321 /* escaped */
 322 /* FIXME: this sucks.  The user will get to see these names:
 323     syntax error, unexpected E_CHAR:
 324                 \
 325                  %%
 326   */
 327
 328 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 329 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 330 %token E_BACKSLASH
 331 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 332 %token FIGURE_SPACE
 333
 334 %token <i>      DIGIT
 335 %token <i>      UNSIGNED
 336 %token <i> E_UNSIGNED
 337 %token <id>     IDENTIFIER
 338 %token <scm>    CHORDMODIFIER_PITCH
 339 %token <scm>    DRUM_PITCH
 340 %token <scm>    DURATION_IDENTIFIER
 341 %token <scm>    EVENT_IDENTIFIER
 342 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 343 %token <scm>    NOTENAME_PITCH
 344 %token <scm>    NUMBER_IDENTIFIER
 345 %token <scm>    OUTPUT_DEF_IDENTIFIER
 346 %token <scm>    RESTNAME
 347 %token <scm> LYRICS_STRING
 348 %token <scm>    SCM_T
 349 %token <scm>    SCORE_IDENTIFIER
 350 %token <scm>    STRING
 351 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 352 %token <scm>    TONICNAME_PITCH
 353 %token <scm>    CHORD_MODIFIER
 354 %token <scm>    FRACTION
 355 %token <scm>   REAL
 356 %token <scm> MARKUP_HEAD_EMPTY
 357 %token <scm> MARKUP_HEAD_MARKUP0
 358 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 359 %token <scm> MARKUP_HEAD_SCM0
 360 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 361 %token <scm> MARKUP_HEAD_SCM0_SCM1
 362 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 363 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 364 %token <scm> LYRIC_MARKUP_IDENTIFIER MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 365 %token <scm> MUSIC_FUNCTION
 366 %token <scm> MUSIC_FUNCTION_MUSIC
 367 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 368 %token <scm> MUSIC_FUNCTION_SCM
 369 %token <scm> MUSIC_FUNCTION_SCM_SCM
 370 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 371 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 372 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 373 %token <scm> MUSIC_FUNCTION_MARKUP
 374 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 375 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 376 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 377 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 378
 379 %token DRUMS
 380 %token DRUMMODE
 381
 382
 383 %type <book>    book_block book_body
 384 %type <i>       bare_int  bare_unsigned
 385 %type <i>       exclamations questions dots optional_rest
 386 %type <i>       script_dir
 387 %type <i>       sub_quotes sup_quotes
 388 %type <i>       tremolo_type
 389 %type <i>       bass_mod
 390
 391 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 392 %type <music>   Grouped_music_list
 393 %type <music>   Music Sequential_music Simultaneous_music
 394 %type <music>   Repeated_music
 395 %type <music>   command_req
 396 %type <music>   gen_text_def direction_less_event direction_reqd_event
 397 %type <music>   music_property_def context_change
 398 %type <music>   note_chord_element chord_body chord_body_element
 399 %type <music>   post_event tagged_post_event
 400 %type <music>   relative_music re_rhythmed_music
 401 %type <music>   simple_element event_chord command_element
 402 %type <music>   string_number_event
 403 %type <music>   toplevel_music
 404 %type <music>   tempo_event
 405
 406 %type <outputdef>       output_def_body output_def_head
 407 %type <outputdef> output_def paper_block
 408
 409 %type <scm>     assignment_id
 410 %type <scm>     Music_list
 411 %type <scm>     chord_body_elements
 412 %type <scm>     chord_item chord_items chord_separator new_chord
 413 %type <scm>     context_def_spec_block context_def_spec_body
 414 %type <scm>     context_mod context_def_mod optional_context_mod
 415 %type <scm>     context_prop_spec
 416 %type <scm>     direction_less_char
 417 %type <scm>     duration_length fraction
 418 %type <scm>     embedded_scm scalar
 419 %type <scm>     identifier_init
 420 %type <scm>     lilypond_header lilypond_header_body
 421 %type <scm>     new_lyrics
 422 %type <scm>     post_events
 423 %type <scm>     property_operation
 424 %type <scm>     script_abbreviation
 425 %type <scm>     simple_string
 426 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 427 %type <scm>     steno_tonic_pitch
 428 %type <scm>     step_number step_numbers
 429 %type <scm>     string bare_number number_expression number_term number_factor
 430 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 431 %type <scm>     context_mod_list
 432 %type <scm>     octave_check
 433 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 434 %type <scm>     Generic_prefix_music_scm
 435 %type <scm>     lyric_element
 436 %type <scm>     Alternative_music
 437 %type <scm>     full_markup lyric_markup
 438 %type <scm>     markup_list markup_composed_list markup_braced_list markup_braced_list_body
 439 %type <scm>     optional_text
 440 %type <scm>     markup_head_1_item markup_head_1_list markup simple_markup markup_top
 441 %type <scm>     mode_changing_head
 442 %type <scm>     mode_changing_head_with_context
 443 %type <scm>     object_id_setting
 444
 445 %type <score>   score_block score_body
 446
 447
 448 %left '-' '+'
 449
 450 /* We don't assign precedence to / and *, because we might need varied
 451 prec levels in different prods */
 452
 453 %left UNARY_MINUS
 454
 455 %%
 456
 457 lilypond:       /* empty */
 458         | lilypond toplevel_expression {
 459         }
 460         | lilypond assignment {
 461         }
 462         | lilypond error {
 463                 THIS->error_level_ = 1;
 464         }
 465         | lilypond INVALID      {
 466                 THIS->error_level_ = 1;
 467         }
 468         ;
 469
 470
 471 object_id_setting:
 472         OBJECTID STRING { $$ = $2; }
 473         ;
 474
 475 toplevel_expression:
 476         lilypond_header {
 477                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 478         }
 479         | add_quote {
 480
 481         }
 482         | book_block {
 483                 Book *book = $1;
 484                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 485                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 486                 scm_gc_unprotect_object (book->self_scm ());
 487         }
 488         | score_block {
 489                 Score *score = $1;
 490
 491                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 492                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 493                 scm_gc_unprotect_object (score->self_scm ());
 494         }
 495         | toplevel_music optional_text {
 496                 Music *music = $1;
 497                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 498                 scm_call_3 (proc, THIS->self_scm (), music->self_scm (), $2);
 499                 scm_gc_unprotect_object (music->self_scm ());
 500         }
 501         | output_def {
 502                 SCM id = SCM_EOL;
 503                 Output_def * od = $1;
 504
 505                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 506                         id = ly_symbol2scm ("$defaultpaper");
 507                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 508                         id = ly_symbol2scm ("$defaultmidi");
 509                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 510                         id = ly_symbol2scm ("$defaultlayout");
 511
 512                 THIS->lexer_->set_identifier (id, od->self_scm ());
 513                 scm_gc_unprotect_object (od->self_scm ());
 514         }
 515         ;
 516
 517 toplevel_music:
 518         Composite_music {
 519         }
 520         ;
 521
 522 embedded_scm:
 523         SCM_T
 524         | SCM_IDENTIFIER
 525         ;
 526
 527
 528 lilypond_header_body:
 529         {
 530                 $$ = ly_make_anonymous_module (be_safe_global);
 531                 THIS->lexer_->add_scope ($$);
 532         }
 533         | lilypond_header_body assignment  {
 534
 535         }
 536         ;
 537
 538 lilypond_header:
 539         HEADER '{' lilypond_header_body '}'     {
 540                 $$ = THIS->lexer_->remove_scope ();
 541         }
 542         ;
 543
 544 optional_text:
 545         /* empty */ {
 546                 $$ = SCM_EOL
 547         }
 548         | optional_text full_markup {
 549                 $$ = ly_snoc ($2, $1);
 550         }
 551         ;
 552
 553 /*
 554         DECLARATIONS
 555 */
 556 assignment_id:
 557         STRING          { $$ = $1; }
 558         | LYRICS_STRING { $$ = $1; }
 559         ;
 560
 561 assignment:
 562         assignment_id '=' identifier_init  {
 563                 if (! is_regular_identifier ($1))
 564                 {
 565                         @1.warning (_ ("Identifier should have alphabetic characters only"));
 566                 }
 567
 568                 THIS->lexer_->set_identifier ($1, $3);
 569
 570 /*
 571  TODO: devise standard for protection in parser.
 572
 573   The parser stack lives on the C-stack, which means that
 574 all objects can be unprotected as soon as they're here.
 575
 576 */
 577         }
 578         | embedded_scm { }
 579         ;
 580
 581
 582 identifier_init:
 583         score_block {
 584                 $$ = $1->self_scm ();
 585                 scm_gc_unprotect_object ($$);
 586         }
 587         | output_def {
 588                 $$ = $1->self_scm ();
 589                 scm_gc_unprotect_object ($$);
 590         }
 591         | context_def_spec_block {
 592                 $$ = $1;
 593         }
 594         | Music  {
 595                 $$ = $1->self_scm ();
 596                 scm_gc_unprotect_object ($$);
 597         }
 598         | post_event {
 599                 $$ = $1->self_scm ();
 600                 scm_gc_unprotect_object ($$);
 601         }
 602         | number_expression {
 603                 $$ = $1;
 604         }
 605         | string {
 606                 $$ = $1;
 607         }
 608         | embedded_scm {
 609                 $$ = $1;
 610         }
 611         | full_markup {
 612                 $$ = $1;
 613         }
 614         | DIGIT {
 615                 $$ = scm_int2num ($1);
 616         }
 617         ;
 618
 619 context_def_spec_block:
 620         CONTEXT '{' context_def_spec_body '}'
 621                 {
 622                 $$ = $3;
 623         }
 624         ;
 625
 626 context_def_spec_body:
 627         /**/ {
 628                 $$ = Context_def::make_scm ();
 629                 unsmob_context_def ($$)->set_spot (@$);
 630         }
 631         | CONTEXT_DEF_IDENTIFIER {
 632                 $$ = $1;
 633                 unsmob_context_def ($$)->set_spot (@$);
 634         }
 635         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 636                 Context_def*td = unsmob_context_def ($$);
 637
 638                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 639                         SCM tag = scm_caar (p);
 640
 641                         /* TODO: should make new tag "grob-definition" ? */
 642                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 643                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 644                 }
 645         }
 646         | context_def_spec_body context_mod {
 647                 unsmob_context_def ($$)->add_context_mod ($2);
 648         }
 649         ;
 650
 651
 652
 653 book_block:
 654         BOOK '{' book_body '}'  {
 655                 $$ = $3;
 656         }
 657         ;
 658
 659 /* FIXME:
 660    * Use 'handlers' like for toplevel-* stuff?
 661    * grok \layout and \midi?  */
 662 book_body:
 663         {
 664                 $$ = new Book;
 665                 $$->set_spot (@$);
 666                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 667                 scm_gc_unprotect_object ($$->paper_->self_scm ());
 668                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 669         }
 670         | book_body paper_block {
 671                 $$->paper_ = $2;
 672                 scm_gc_unprotect_object ($2->self_scm ());
 673         }
 674         | book_body score_block optional_text {
 675                 Score *score = $2;
 676                 score->texts_ = $3;
 677                 $$->add_score (score);
 678         }
 679         /* let's do optional
 680         | book_body full_markup {
 681                 if (!$$->scores_.size ())
 682                         THIS->parser_error (@2, _("\\markup cannot be used before \\score."));
 683                 Score *score = $$->scores_.top ();
 684                 score->texts_ = ly_snoc ($2, score->texts_);
 685         }
 686         */
 687         | book_body lilypond_header {
 688                 $$->header_ = $2;
 689         }
 690         | book_body error {
 691                 $$->paper_ = 0;
 692                 $$->scores_.clear();
 693         }
 694         | book_body object_id_setting {
 695                 $$->user_key_ = ly_scm2string ($2);
 696         }
 697         ;
 698
 699 score_block:
 700         SCORE '{' score_body '}'        {
 701                 $$ = $3;
 702         }
 703         ;
 704
 705 score_body:
 706         /**/    {
 707                 $$ = new Score;
 708                 $$->set_spot (@$);
 709         }
 710         | SCORE_IDENTIFIER {
 711                 $$ = new Score ( *unsmob_score ($1));
 712                 $$->set_spot (@$);
 713         }
 714         | score_body object_id_setting {
 715                 $$->user_key_ = ly_scm2string ($2);
 716         }
 717         | score_body Music {
 718                 SCM m = $2->self_scm ();
 719                 scm_gc_unprotect_object (m);
 720                 $$->set_music (m, THIS->self_scm ());
 721         }
 722         | score_body lilypond_header    {
 723                 $$->header_ = $2;
 724         }
 725         | score_body output_def {
 726                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 727                 {
 728                         THIS->parser_error (@2, _("\\paper cannot be in \\score. Use \\layout instead"));
 729
 730                 }
 731                 else
 732                 {
 733                         $$->defs_.push ($2);
 734                 }
 735                 scm_gc_unprotect_object ($2->self_scm ());
 736         }
 737         | score_body error {
 738                 $$->error_found_ = true;
 739         }
 740         ;
 741
 742
 743 /*
 744         OUTPUT DEF
 745 */
 746
 747 paper_block:
 748         output_def {
 749                 $$ = $1;
 750                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 751                 {
 752                         THIS->parser_error (@1, _("Need \\paper for paper block."));
 753                         $$ = get_paper (THIS);
 754                 }
 755         }
 756         ;
 757
 758
 759 output_def:
 760         output_def_body '}' {
 761                 $$ = $1;
 762
 763                 THIS->lexer_->remove_scope ();
 764                 THIS->lexer_->pop_state ();
 765         }
 766         ;
 767
 768 output_def_head:
 769         PAPER {
 770                 $$ = get_paper (THIS);
 771                 $$->input_origin_ = @$;
 772                 THIS->lexer_->add_scope ($$->scope_);
 773         }
 774         | MIDI    {
 775                 Output_def *p = get_midi (THIS);
 776                 $$ = p;
 777                 THIS->lexer_->add_scope (p->scope_);
 778         }
 779         | LAYOUT        {
 780                 Output_def *p = get_layout (THIS);
 781
 782                 THIS->lexer_->add_scope (p->scope_);
 783                 $$ = p;
 784         }
 785         ;
 786
 787
 788 output_def_body:
 789         output_def_head '{' {
 790                 $$ = $1;
 791                 $$->input_origin_.set_spot (@$);
 792                 THIS->lexer_->push_initial_state ();
 793         }
 794         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 795                 scm_gc_unprotect_object ($1->self_scm ());
 796                 Output_def *o = unsmob_output_def ($3);
 797                 o->input_origin_.set_spot (@$);
 798                 $$ = o;
 799                 THIS->lexer_->remove_scope ();
 800                 THIS->lexer_->add_scope (o->scope_);
 801                 THIS->lexer_->push_initial_state ();
 802         }
 803         | output_def_body assignment  {
 804
 805         }
 806         | output_def_body context_def_spec_block        {
 807                 assign_context_def ($$, $2);
 808         }
 809         | output_def_body tempo_event  {
 810                 /*
 811                         junk this ? there already is tempo stuff in
 812                         music.
 813                 */
 814                 int m = scm_to_int ($2->get_property ("metronome-count"));
 815                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 816                 set_tempo ($$, d->get_length (), m);
 817                 scm_gc_unprotect_object ($2->self_scm ());
 818         }
 819         | output_def_body error {
 820
 821         }
 822         ;
 823
 824 tempo_event:
 825         TEMPO steno_duration '=' bare_unsigned  {
 826                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 827                 $$->set_property ("tempo-unit", $2);
 828                 $$->set_property ("metronome-count", scm_int2num ( $4));
 829         }
 830         ;
 831
 832 /*
 833 The representation of a  list is the
 834
 835   (LIST . LAST-CONS)
 836
 837  to have efficient append.  */
 838
 839 Music_list:
 840         /* empty */ {
 841                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 842         }
 843         | Music_list Music {
 844                 SCM s = $$;
 845                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 846                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 847
 848                 if (scm_is_pair (scm_cdr (s)))
 849                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 850                 else
 851                         scm_set_car_x (s, c); /* set first cons */
 852                 scm_set_cdr_x (s, c);  /* remember last cell */
 853         }
 854         | Music_list embedded_scm {
 855
 856         }
 857         | Music_list error {
 858                 Music * m = MY_MAKE_MUSIC("Music");
 859                 // ugh. code dup
 860                 m->set_property ("error-found", SCM_BOOL_T);
 861                 SCM s = $$;
 862                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 863                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 864
 865                 if (scm_is_pair (scm_cdr (s)))
 866                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 867                 else
 868                         scm_set_car_x (s, c); /* set first cons */
 869                 scm_set_cdr_x (s, c);  /* remember last cell */
 870         }
 871         ;
 872
 873 Music:
 874         Simple_music
 875         | Composite_music
 876         ;
 877
 878 Alternative_music:
 879         /* empty */ {
 880                 $$ = SCM_EOL;
 881         }
 882         | ALTERNATIVE '{' Music_list '}' {
 883                 $$ = $3;
 884         }
 885         ;
 886
 887
 888 Repeated_music:
 889         REPEAT simple_string bare_unsigned Music Alternative_music
 890         {
 891                 Music *beg = $4;
 892                 int times = $3;
 893                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 894                 if (times < scm_ilength (alts)) {
 895                   unsmob_music (scm_car (alts))
 896                     ->origin ()->warning (
 897                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 898                   alts = ly_truncate_list (times, alts);
 899                 }
 900
 901
 902                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 903
 904                 SCM mus = scm_call_1 (proc, $2);
 905                 scm_gc_protect_object (mus); // UGH.
 906                 Music *r = unsmob_music (mus);
 907                 if (beg)
 908                         {
 909                         r-> set_property ("element", beg->self_scm ());
 910                         scm_gc_unprotect_object (beg->self_scm ());
 911                         }
 912                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 913
 914                 r-> set_property ("elements",alts);
 915                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 916                         /*
 917                         TODO: move this code to Scheme.
 918                         */
 919
 920                         /*
 921                         we can not get durations and other stuff correct down the line, so we have to
 922                         add to the duration log here.
 923                         */
 924                         SCM func = ly_lily_module_constant ("shift-duration-log");
 925
 926                         int dots = ($3 % 3) ? 0 : 1;
 927                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 928
 929
 930                         if ($4->is_mus_type ("sequential-music"))
 931                         {
 932                                 int list_len = scm_ilength ($4->get_property ("elements"));
 933                                 if (list_len != 2)
 934                                         $4->origin ()->warning ("Chord tremolo must have 2 elements.");
 935                                 shift -= 1;
 936                                 r->compress (Moment (Rational (1, list_len)));
 937                         }
 938                         scm_call_3 (func, r->self_scm (), scm_int2num (shift), scm_int2num (dots));
 939
 940                 }
 941                 r->set_spot (*$4->origin ());
 942
 943                 $$ = r;
 944         }
 945         ;
 946
 947 Sequential_music:
 948         SEQUENTIAL '{' Music_list '}'           {
 949                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 950                 $$->set_property ("elements", scm_car ($3));
 951                 $$->set_spot (@$);
 952         }
 953         | '{' Music_list '}'            {
 954                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 955                 $$->set_property ("elements", scm_car ($2));
 956                 $$->set_spot (@$);
 957         }
 958         ;
 959
 960 Simultaneous_music:
 961         SIMULTANEOUS '{' Music_list '}'{
 962                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 963                 $$->set_property ("elements", scm_car ($3));
 964                 $$->set_spot (@$);
 965
 966         }
 967         | simul_open Music_list simul_close     {
 968                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 969                 $$->set_property ("elements", scm_car ($2));
 970                 $$->set_spot (@$);
 971         }
 972         ;
 973
 974 Simple_music:
 975         event_chord             { $$ = $1; }
 976         | MUSIC_IDENTIFIER {
 977                 $$ = unsmob_music ($1);
 978         }
 979         | music_property_def
 980         | context_change
 981         ;
 982
 983
 984 optional_context_mod:
 985         /**/ { $$ = SCM_EOL; }
 986         | WITH { THIS->lexer_->push_initial_state (); }
 987         '{' context_mod_list '}'
 988         {
 989                 THIS->lexer_->pop_state ();
 990                 $$ = $4;
 991         }
 992         ;
 993
 994 context_mod_list:
 995         /* */  { $$ = SCM_EOL; }
 996         | context_mod_list context_mod  {
 997                  $$ = scm_cons ($2, $1);
 998         }
 999         ;
1000
1001
1002 Composite_music:
1003         Prefix_composite_music { $$ = $1; }
1004         | Grouped_music_list { $$ = $1; }
1005         ;
1006
1007 Grouped_music_list:
1008         Simultaneous_music              { $$ = $1; }
1009         | Sequential_music              { $$ = $1; }
1010         ;
1011
1012 Generic_prefix_music_scm:
1013         MUSIC_FUNCTION {
1014                 $$ = scm_list_2 ($1, make_input (@$));
1015         }
1016         | MUSIC_FUNCTION_SCM embedded_scm {
1017                 $$ = scm_list_3 ($1, make_input (@$), $2);
1018         }
1019         | MUSIC_FUNCTION_MARKUP full_markup {
1020                 $$ = scm_list_3 ($1, make_input (@$), $2);
1021         }
1022         | MUSIC_FUNCTION_MUSIC Music {
1023                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1024                 scm_gc_unprotect_object ($2->self_scm ());
1025         }
1026         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm Music {
1027                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1028                 scm_gc_unprotect_object ($3->self_scm ());
1029         }
1030         | MUSIC_FUNCTION_SCM_SCM embedded_scm embedded_scm {
1031                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1032         }
1033         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm Music {
1034                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1035         }
1036         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1037                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1038                 scm_gc_unprotect_object ($3->self_scm ());
1039         }
1040         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1041                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1042         }
1043         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1044                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1045                 scm_gc_unprotect_object ($2->self_scm ());
1046                 scm_gc_unprotect_object ($3->self_scm ());
1047         }
1048         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC embedded_scm Music Music {
1049                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1050                 scm_gc_unprotect_object ($4->self_scm ());
1051                 scm_gc_unprotect_object ($3->self_scm ());
1052         }
1053         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1054                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1055                 scm_gc_unprotect_object ($3->self_scm ());
1056                 scm_gc_unprotect_object ($4->self_scm ());
1057         }
1058         ;
1059
1060 Generic_prefix_music:
1061         Generic_prefix_music_scm {
1062                 SCM func = scm_car ($1);
1063                 Input *loc = unsmob_input (scm_cadr ($1));
1064                 SCM args = scm_cddr ($1);
1065                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1066
1067                 SCM type_check_proc = ly_lily_module_constant ("type-check-list");
1068                 bool ok  = true;
1069
1070                 if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr ($1), sig, args)))
1071                 {
1072                         THIS->error_level_ = 1;
1073                         ok = false;
1074                 }
1075
1076                 SCM m = SCM_EOL;
1077                 if (ok)
1078                         m = scm_apply_0 (func, scm_cons (THIS->self_scm(),
1079                                                          scm_cdr ($1)));
1080
1081                 if (unsmob_music (m))
1082                         {
1083                         $$ = unsmob_music (m);
1084                         scm_gc_protect_object (m);
1085                         }
1086                 else
1087                         {
1088                         if (ok)
1089                                 loc->error (_ ("Music head function should return Music object."));
1090                         $$ = MY_MAKE_MUSIC ("Music");
1091                         }
1092                 $$->set_spot (*loc);
1093         }
1094         ;
1095
1096
1097 Prefix_composite_music:
1098         Generic_prefix_music {
1099                 $$ = $1;
1100         }
1101         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1102                 $$ = context_spec_music ($2, $4, $6, $5);
1103
1104         }
1105         | CONTEXT simple_string optional_context_mod Music {
1106                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1107         }
1108         | NEWCONTEXT simple_string optional_context_mod Music {
1109                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1110                         $3);
1111         }
1112
1113         | TIMES fraction Music
1114
1115         {
1116                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1117                 Music *mp = $3;
1118
1119                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1120                 $$->set_spot (@$);
1121
1122                 $$->set_property ("element", mp->self_scm ());
1123                 scm_gc_unprotect_object (mp->self_scm ());
1124                 $$->set_property ("numerator", scm_int2num (n));
1125                 $$->set_property ("denominator", scm_int2num (d));
1126                 $$->compress (Moment (Rational (n,d)));
1127
1128         }
1129         | Repeated_music                { $$ = $1; }
1130         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1131                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1132                 Music *p = $4;
1133                 Pitch from = *unsmob_pitch ($2);
1134                 Pitch to = *unsmob_pitch ($3);
1135
1136                 p->transpose (pitch_interval (from, to));
1137                 $$->set_property ("element", p->self_scm ());
1138                 scm_gc_unprotect_object (p->self_scm ());
1139         }
1140         | mode_changing_head Grouped_music_list {
1141                 if ($1 == ly_symbol2scm ("chords"))
1142                 {
1143                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1144                   chm->set_property ("element", $2->self_scm ());
1145                   $$ = chm;
1146                   scm_gc_unprotect_object ($2->self_scm ());
1147                 }
1148                 else
1149                 {
1150                   $$ = $2;
1151                 }
1152                 THIS->lexer_->pop_state ();
1153         }
1154         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1155                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1156                                          $3, $2);
1157                 if ($1 == ly_symbol2scm ("ChordNames"))
1158                 {
1159                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1160                   chm->set_property ("element", $$->self_scm ());
1161                   scm_gc_unprotect_object ($$->self_scm ());
1162                   $$ = chm;
1163                 }
1164                 THIS->lexer_->pop_state ();
1165         }
1166         | relative_music        { $$ = $1; }
1167         | re_rhythmed_music     { $$ = $1; }
1168         | TAG embedded_scm Music {
1169                 tag_music ($3, $2, @$);
1170                 $$ = $3;
1171         }
1172         ;
1173
1174 mode_changing_head:
1175         NOTEMODE {
1176                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1177                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1178
1179                 $$ = ly_symbol2scm ("notes");
1180         }
1181         | DRUMMODE
1182                 {
1183                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1184                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1185
1186                 $$ = ly_symbol2scm ("drums");
1187         }
1188         | FIGUREMODE {
1189                 THIS->lexer_->push_figuredbass_state ();
1190
1191                 $$ = ly_symbol2scm ("figures");
1192         }
1193         | CHORDMODE {
1194                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1195                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1196                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1197                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1198                 $$ = ly_symbol2scm ("chords");
1199
1200         }
1201         | LYRICMODE
1202                 { THIS->lexer_->push_lyric_state ();
1203                 $$ = ly_symbol2scm ("lyrics");
1204         }
1205         ;
1206
1207 mode_changing_head_with_context:
1208         DRUMS {
1209                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1210                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1211
1212                 $$ = ly_symbol2scm ("DrumStaff");
1213         }
1214         | FIGURES {
1215                 THIS->lexer_->push_figuredbass_state ();
1216
1217                 $$ = ly_symbol2scm ("FiguredBass");
1218         }
1219         | CHORDS {
1220                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1221                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1222                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1223                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1224                 $$ = ly_symbol2scm ("ChordNames");
1225         }
1226         | LYRICS
1227                 { THIS->lexer_->push_lyric_state ();
1228                 $$ = ly_symbol2scm ("Lyrics");
1229         }
1230         ;
1231
1232
1233 relative_music:
1234         RELATIVE absolute_pitch Music {
1235                 Music *m = $3;
1236                 Pitch start = *unsmob_pitch ($2);
1237                 $$ = make_music_relative (start, m);
1238                 scm_gc_unprotect_object (m->self_scm ());
1239         }
1240         | RELATIVE Composite_music {
1241                 Music *m = $2;
1242
1243                 Pitch middle_c (0, 0, 0);
1244                 $$ = make_music_relative (middle_c, m);
1245                 scm_gc_unprotect_object (m->self_scm ());
1246         }
1247         ;
1248
1249 new_lyrics:
1250         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1251         /*cont */
1252         Grouped_music_list {
1253         /* Can also use Music at the expensive of two S/Rs similar to
1254            \repeat \alternative */
1255                 THIS->lexer_->pop_state ();
1256
1257                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1258         }
1259         | new_lyrics ADDLYRICS {
1260                 THIS->lexer_->push_lyric_state ();
1261         } Grouped_music_list {
1262                 THIS->lexer_->pop_state ();
1263                 $$ = scm_cons ($4->self_scm (), $1);
1264         }
1265         ;
1266
1267 re_rhythmed_music:
1268         Grouped_music_list new_lyrics {
1269                 Music * voice = $1;
1270                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1271                 if (!scm_is_string (name))
1272                 {
1273                         name = get_next_unique_lyrics_context_id ();
1274                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1275                                                     name,
1276                                                     voice, SCM_EOL);
1277                 }
1278
1279                 SCM context = scm_makfrom0str ("Lyrics");
1280                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1281
1282                 SCM lst = SCM_EOL;
1283                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1284                 {
1285                         Music *music = unsmob_music (scm_car (s));
1286                         Music *com = make_lyric_combine_music (name, music);
1287                         Music *csm = context_spec_music (context,
1288                                 get_next_unique_context_id (), com, SCM_EOL);
1289                         lst = scm_cons (csm->self_scm (), lst);
1290                 }
1291                 all->set_property ("elements", scm_cons (voice->self_scm (),
1292                         lst));
1293                 $$ = all;
1294                 scm_gc_unprotect_object (voice->self_scm ());
1295         }
1296         | LYRICSTO simple_string {
1297                 THIS->lexer_->push_lyric_state ();
1298         } Music {
1299                 THIS->lexer_->pop_state ();
1300                 Music *music = $4;
1301                 SCM name = $2;
1302                 $$ = make_lyric_combine_music (name, music);
1303                 scm_gc_unprotect_object (music->self_scm ());
1304         }
1305         ;
1306
1307 context_change:
1308         CHANGE STRING '=' STRING  {
1309                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1310                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1311                 t-> set_property ("change-to-id", $4);
1312
1313                 $$ = t;
1314                 $$->set_spot (@$);
1315         }
1316         ;
1317
1318 property_operation:
1319         STRING '=' scalar {
1320                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1321                         scm_string_to_symbol ($1), $3);
1322         }
1323         | UNSET simple_string {
1324                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1325                         scm_string_to_symbol ($2));
1326         }
1327         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1328                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1329                         scm_string_to_symbol ($2), $3, $5);
1330         }
1331         | REVERT simple_string embedded_scm {
1332                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1333                         scm_string_to_symbol ($2), $3);
1334         }
1335         ;
1336
1337 context_def_mod:
1338         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1339         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1340
1341         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1342         | DENIES { $$ = ly_symbol2scm ("denies"); }
1343
1344         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1345         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1346         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1347         | NAME { $$ = ly_symbol2scm ("context-name"); }
1348         ;
1349
1350 context_mod:
1351         property_operation { $$ = $1; }
1352         | context_def_mod STRING {
1353                 $$ = scm_list_2 ($1, $2);
1354         }
1355         ;
1356
1357 context_prop_spec:
1358         simple_string {
1359                 if (!is_regular_identifier ($1))
1360                 {
1361                         @$.error (_("Grob name should be alphanumeric"));
1362                 }
1363
1364                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1365                         scm_string_to_symbol ($1));
1366         }
1367         | simple_string '.' simple_string {
1368                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1369                         scm_string_to_symbol ($3));
1370         }
1371         ;
1372
1373 music_property_def:
1374         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1375                 $$ = property_op_to_music (scm_list_4 (
1376                         ly_symbol2scm ("poppush"),
1377                         scm_cadr ($2),
1378                         $3, $5));
1379                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1380         }
1381         | REVERT context_prop_spec embedded_scm {
1382                 $$ = property_op_to_music (scm_list_3 (
1383                         ly_symbol2scm ("pop"),
1384                         scm_cadr ($2),
1385                         $3));
1386
1387                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1388         }
1389         | SET context_prop_spec '=' scalar {
1390                 $$ = property_op_to_music (scm_list_3 (
1391                         ly_symbol2scm ("assign"),
1392                         scm_cadr ($2),
1393                         $4));
1394                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1395         }
1396         | UNSET context_prop_spec {
1397                 $$ = property_op_to_music (scm_list_2 (
1398                         ly_symbol2scm ("unset"),
1399                         scm_cadr ($2)));
1400                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1401         }
1402         | ONCE music_property_def {
1403                 SCM e = $2->get_property ("element");
1404                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1405                 $$ = $2;
1406
1407         }
1408         ;
1409
1410
1411 string:
1412         STRING {
1413                 $$ = $1;
1414         }
1415         | STRING_IDENTIFIER {
1416                 $$ = $1;
1417         }
1418         | string '+' string {
1419                 $$ = scm_string_append (scm_list_2 ($1, $3));
1420         }
1421         ;
1422
1423 simple_string: STRING {
1424                 $$ = $1;
1425         }
1426         | LYRICS_STRING {
1427                 $$ = $1;
1428         }
1429         ;
1430
1431 scalar: string {
1432                 $$ = $1;
1433         }
1434         | LYRICS_STRING {
1435                 $$ = $1;
1436         }
1437         | bare_int {
1438                 $$ = scm_int2num ($1);
1439         }
1440         | embedded_scm {
1441                 $$ = $1;
1442         }
1443         | full_markup {
1444                 $$ = $1;
1445         }
1446         | DIGIT {
1447                 $$ = scm_int2num ($1);
1448         }
1449         ;
1450
1451 /*
1452
1453 pre_events doesn't contain anything. It is a trick:
1454
1455 Adding pre_events to the simple_element
1456 makes the choice between
1457
1458   string:  STRING
1459
1460 and
1461
1462   simple_element: STRING
1463
1464 a single shift/reduction conflict.
1465
1466 nevertheless, this is not very clean, and we should find a different
1467 solution.
1468
1469 */
1470 pre_events: /* empty */
1471         ;
1472
1473 event_chord:
1474         pre_events simple_element post_events   {
1475                 SCM elts = $2-> get_property ("elements");
1476
1477                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1478
1479                 $2->set_property ("elements", elts);
1480                 /* why is this giving wrong start location? -ns
1481                  * $2->set_spot (@$); */
1482                 Input i;
1483                 i.set_location (@2, @3);
1484                 $2->set_spot (i);
1485                 $$ = $2;
1486         }
1487         | command_element
1488         | note_chord_element
1489         ;
1490
1491
1492 note_chord_element:
1493         chord_body optional_notemode_duration post_events
1494         {
1495                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1496                 SCM es = $1->get_property ("elements");
1497                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1498
1499                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1500                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1501                 es = ly_append2 (es, postevs);
1502
1503                 $1-> set_property ("elements", es);
1504                 $1->set_spot (@$);
1505                 $$ = $1;
1506         }
1507         ;
1508
1509 chord_open: '<'
1510         ;
1511
1512 chord_close: '>'
1513         ;
1514
1515 simul_open: DOUBLE_ANGLE_OPEN
1516         ;
1517
1518 simul_close: DOUBLE_ANGLE_CLOSE
1519         ;
1520
1521 chord_body:
1522         chord_open chord_body_elements chord_close
1523         {
1524                 $$ = MY_MAKE_MUSIC ("EventChord");
1525                 $$->set_spot (@$);
1526                 $$->set_property ("elements",
1527                         scm_reverse_x ($2, SCM_EOL));
1528         }
1529         ;
1530
1531 chord_body_elements:
1532         /* empty */             { $$ = SCM_EOL; }
1533         | chord_body_elements chord_body_element {
1534                 $$ = scm_cons ($2->self_scm (), $1);
1535                 scm_gc_unprotect_object ($2->self_scm ());
1536         }
1537         ;
1538
1539 chord_body_element:
1540         pitch exclamations questions octave_check post_events
1541         {
1542                 int q = $3;
1543                 int ex = $2;
1544                 SCM check = $4;
1545                 SCM post = $5;
1546
1547                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1548                 n->set_property ("pitch", $1);
1549                 n->set_spot (@$);
1550                 if (q % 2)
1551                         n->set_property ("cautionary", SCM_BOOL_T);
1552                 if (ex % 2 || q % 2)
1553                         n->set_property ("force-accidental", SCM_BOOL_T);
1554
1555                 if (scm_is_pair (post)) {
1556                         SCM arts = scm_reverse_x (post, SCM_EOL);
1557                         n->set_property ("articulations", arts);
1558                 }
1559                 if (scm_is_number (check))
1560                 {
1561                         int q = scm_to_int (check);
1562                         n->set_property ("absolute-octave", scm_int2num (q-1));
1563                 }
1564
1565
1566                 $$ = n;
1567         }
1568         | DRUM_PITCH post_events {
1569                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1570                 n->set_property ("duration", $2);
1571                 n->set_property ("drum-type", $1);
1572                 n->set_spot (@$);
1573
1574                 if (scm_is_pair ($2)) {
1575                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1576                         n->set_property ("articulations", arts);
1577                 }
1578                 $$ = n;
1579         }
1580         ;
1581
1582 add_quote:
1583         ADDQUOTE string Music {
1584                 SCM adder = ly_lily_module_constant ("add-quotable");
1585
1586                 scm_call_2 (adder, $2, $3->self_scm ());
1587                 scm_gc_unprotect_object ($3->self_scm ());
1588         }
1589         ;
1590
1591 command_element:
1592         command_req {
1593                 $$ = MY_MAKE_MUSIC ("EventChord");
1594                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1595                 scm_gc_unprotect_object ($1->self_scm ());
1596
1597                 $$-> set_spot (@$);
1598                 $1-> set_spot (@$);
1599         }
1600         | SKIP duration_length {
1601                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1602                 skip->set_property ("duration", $2);
1603                 skip->set_spot (@$);
1604                 $$ = skip;
1605         }
1606         | OCTAVE pitch {
1607                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1608                 $$ = m;
1609                 $$->set_spot (@$);
1610                 $$->set_property ("pitch", $2);
1611         }
1612         | E_LEFTSQUARE {
1613                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1614                 m->set_property ("span-direction", scm_int2num (START));
1615                 m->set_spot (@$);
1616
1617                 $$ = MY_MAKE_MUSIC ("EventChord");
1618                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1619                 scm_gc_unprotect_object (m->self_scm ());
1620                 $$->set_spot (@$);
1621         }
1622         | E_RIGHTSQUARE {
1623                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1624                 m->set_property ("span-direction", scm_int2num (STOP));
1625                 m->set_spot (@$);
1626
1627                 $$ = MY_MAKE_MUSIC ("EventChord");
1628                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1629                 $$->set_spot (@$);
1630                 scm_gc_unprotect_object (m->self_scm ());
1631         }
1632         | E_BACKSLASH {
1633                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1634                 $$->set_spot (@$);
1635         }
1636         | '|'      {
1637                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1638
1639                 if (Music * m = unsmob_music (pipe))
1640                         $$ = m->clone ();
1641                 else
1642                         $$ = MY_MAKE_MUSIC ("BarCheck");
1643
1644                 $$->set_spot (@$);
1645         }
1646         | TRANSPOSITION pitch {
1647                 Pitch middle_c;
1648                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1649                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1650                                          sounds_as_c.smobbed_copy());
1651                 $$->set_spot (@$);
1652                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1653                         $$, SCM_EOL);
1654         }
1655         | BAR STRING                    {
1656                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1657
1658                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1659                                         t, SCM_EOL);
1660                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1661                 $$->set_spot (@$);
1662                 t->set_spot (@$);
1663         }
1664         | PARTIAL duration_length       {
1665                 Moment m = - unsmob_duration ($2)->get_length ();
1666                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1667                 p->set_spot (@$);
1668                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1669                                         p, SCM_EOL);
1670                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1671                                         p, SCM_EOL);
1672                 $$ = p;
1673         }
1674         | CLEF STRING  {
1675                 SCM proc = ly_lily_module_constant ("make-clef-set");
1676
1677                 SCM result = scm_call_1 (proc, $2);
1678                 scm_gc_protect_object (result);
1679                 $$ = unsmob_music (result);
1680         }
1681         | TIME_T fraction  {
1682                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1683
1684                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1685                 scm_gc_protect_object (result);
1686                 $$ = unsmob_music (result);
1687         }
1688         | MARK scalar {
1689                 SCM proc = ly_lily_module_constant ("make-mark-set");
1690
1691                 SCM result = scm_call_1 (proc, $2);
1692                 scm_gc_protect_object (result);
1693                 $$ = unsmob_music (result);
1694         }
1695         ;
1696
1697 command_req:
1698         E_TILDE {
1699                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1700         }
1701         | MARK DEFAULT  {
1702                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1703                 $$ = m;
1704         }
1705         | tempo_event {
1706                 $$ = $1;
1707         }
1708         | KEY DEFAULT {
1709                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1710                 $$ = key;
1711         }
1712         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1713
1714                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1715                 if (scm_ilength ($3) > 0)
1716                 {
1717                         key->set_property ("pitch-alist", $3);
1718                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1719                         key->transpose (* unsmob_pitch ($2));
1720                 } else {
1721                         THIS->parser_error (@3, _ ("Second argument must be pitch list."));
1722                 }
1723
1724                 $$ = key;
1725         }
1726         ;
1727
1728
1729 post_events:
1730         /* empty */ {
1731                 $$ = SCM_EOL;
1732         }
1733         | post_events post_event {
1734                 $2->set_spot (@2);
1735                 $$ = scm_cons ($2->self_scm (), $$);
1736                 scm_gc_unprotect_object ($2->self_scm ());
1737         }
1738         | post_events tagged_post_event {
1739                 $2 -> set_spot (@2);
1740                 $$ = scm_cons ($2->self_scm (), $$);
1741                 scm_gc_unprotect_object ($2->self_scm ());
1742         }
1743         ;
1744
1745
1746 tagged_post_event:
1747         '-' TAG embedded_scm post_event {
1748                 tag_music ($4, $3, @$);
1749                 $$ = $4;
1750         }
1751         ;
1752
1753
1754 post_event:
1755         direction_less_event {
1756                 $$ = $1;
1757         }
1758         | HYPHEN {
1759                 if (!THIS->lexer_->is_lyric_state ())
1760                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
1761                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1762         }
1763         | EXTENDER {
1764                 if (!THIS->lexer_->is_lyric_state ())
1765                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
1766                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1767         }
1768         | script_dir direction_reqd_event {
1769                 if ($1)
1770                         $2->set_property ("direction", scm_int2num ($1));
1771                 $$ = $2;
1772         }
1773         | script_dir direction_less_event {
1774                 if ($1)
1775                         $2->set_property ("direction", scm_int2num ($1));
1776                 $$ = $2;
1777         }
1778         | string_number_event
1779         ;
1780
1781 string_number_event:
1782         E_UNSIGNED {
1783                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1784                 s->set_property ("string-number", scm_int2num ($1));
1785                 s->set_spot (@$);
1786                 $$ = s;
1787         }
1788         ;
1789
1790 direction_less_char:
1791         '['  {
1792                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1793         }
1794         | ']'  {
1795                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1796         }
1797         | '~'  {
1798                 $$ = ly_symbol2scm ("tildeSymbol");
1799         }
1800         | '('  {
1801                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1802         }
1803         | ')'  {
1804                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1805         }
1806         | E_EXCLAMATION  {
1807                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1808         }
1809         | E_OPEN  {
1810                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1811         }
1812         | E_CLOSE  {
1813                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1814         }
1815         | E_BIGGER  {
1816                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1817         }
1818         | E_SMALLER  {
1819                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1820         }
1821         ;
1822
1823 direction_less_event:
1824         direction_less_char {
1825                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1826                 Music * m = 0;
1827                 if (unsmob_music (predefd))
1828                 {
1829                         m = unsmob_music (predefd)->clone ();
1830                 }
1831                 else
1832                 {
1833                         m = MY_MAKE_MUSIC ("Music");
1834                 }
1835                 m->set_spot (@$);
1836                 $$ = m;
1837         }
1838         | EVENT_IDENTIFIER      {
1839                 $$ = unsmob_music ($1);
1840         }
1841         | tremolo_type  {
1842                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1843                a->set_spot (@$);
1844                a->set_property ("tremolo-type", scm_int2num ($1));
1845                $$ = a;
1846         }
1847         ;
1848
1849 direction_reqd_event:
1850         gen_text_def {
1851                 $$ = $1;
1852         }
1853         | script_abbreviation {
1854                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1855                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1856                 if (scm_is_string (s))
1857                         a->set_property ("articulation-type", s);
1858                 else THIS->parser_error (@1, _ ("Expecting string as script definition"));
1859                 $$ = a;
1860         }
1861         ;
1862
1863 octave_check:
1864         /**/ { $$ = SCM_EOL; }
1865         | '='  { $$ = scm_int2num (0); }
1866         | '=' sub_quotes { $$ = scm_int2num ($2); }
1867         | '=' sup_quotes { $$ = scm_int2num ($2); }
1868         ;
1869
1870 sup_quotes:
1871         '\'' {
1872                 $$ = 1;
1873         }
1874         | sup_quotes '\'' {
1875                 $$ ++;
1876         }
1877         ;
1878
1879 sub_quotes:
1880         ',' {
1881                 $$ = 1;
1882         }
1883         | sub_quotes ',' {
1884                 $$++;
1885         }
1886         ;
1887
1888 steno_pitch:
1889         NOTENAME_PITCH  {
1890                 $$ = $1;
1891         }
1892         | NOTENAME_PITCH sup_quotes     {
1893                 Pitch p = *unsmob_pitch ($1);
1894                 p = p.transposed (Pitch ($2,0,0));
1895                 $$ = p.smobbed_copy ();
1896         }
1897         | NOTENAME_PITCH sub_quotes      {
1898                 Pitch p =* unsmob_pitch ($1);
1899                 p = p.transposed (Pitch (-$2,0,0));
1900                 $$ = p.smobbed_copy ();
1901         }
1902         ;
1903
1904 /*
1905 ugh. duplication
1906 */
1907
1908 steno_tonic_pitch:
1909         TONICNAME_PITCH {
1910                 $$ = $1;
1911         }
1912         | TONICNAME_PITCH sup_quotes    {
1913                 Pitch p = *unsmob_pitch ($1);
1914                 p = p.transposed (Pitch ($2,0,0));
1915                 $$ = p.smobbed_copy ();
1916         }
1917         | TONICNAME_PITCH sub_quotes     {
1918                 Pitch p =* unsmob_pitch ($1);
1919
1920                 p = p.transposed (Pitch (-$2,0,0));
1921                 $$ = p.smobbed_copy ();
1922         }
1923         ;
1924
1925 pitch:
1926         steno_pitch {
1927                 $$ = $1;
1928         }
1929         ;
1930
1931 pitch_also_in_chords:
1932         pitch
1933         | steno_tonic_pitch
1934         ;
1935
1936 gen_text_def:
1937         full_markup {
1938                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1939                 t->set_property ("text", $1);
1940                 t->set_spot (@$);
1941                 $$ = t;
1942         }
1943         | string {
1944                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1945                 t->set_property ("text",
1946                         make_simple_markup ($1));
1947                 t->set_spot (@$);
1948                 $$ = t;
1949
1950         }
1951         | DIGIT {
1952                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1953                 t->set_property ("digit", scm_int2num ($1));
1954                 t->set_spot (@$);
1955                 $$ = t;
1956         }
1957         ;
1958
1959 script_abbreviation:
1960         '^'             {
1961                 $$ = scm_makfrom0str ("Hat");
1962         }
1963         | '+'           {
1964                 $$ = scm_makfrom0str ("Plus");
1965         }
1966         | '-'           {
1967                 $$ = scm_makfrom0str ("Dash");
1968         }
1969         | '|'           {
1970                 $$ = scm_makfrom0str ("Bar");
1971         }
1972         | '>'           {
1973                 $$ = scm_makfrom0str ("Larger");
1974         }
1975         | '.'           {
1976                 $$ = scm_makfrom0str ("Dot");
1977         }
1978         | '_' {
1979                 $$ = scm_makfrom0str ("Underscore");
1980         }
1981         ;
1982
1983 script_dir:
1984         '_'     { $$ = DOWN; }
1985         | '^'   { $$ = UP; }
1986         | '-'   { $$ = CENTER; }
1987         ;
1988
1989
1990 absolute_pitch:
1991         steno_pitch     {
1992                 $$ = $1;
1993         }
1994         ;
1995
1996 duration_length:
1997         multiplied_duration {
1998                 $$ = $1;
1999         }
2000         ;
2001
2002 optional_notemode_duration:
2003         {
2004                 Duration dd = THIS->default_duration_;
2005                 $$ = dd.smobbed_copy ();
2006
2007                 THIS->beam_check ($$);
2008         }
2009         | multiplied_duration   {
2010                 $$ = $1;
2011                 THIS->default_duration_ = *unsmob_duration ($$);
2012
2013                 THIS->beam_check ($$);
2014         }
2015         ;
2016
2017 steno_duration:
2018         bare_unsigned dots              {
2019                 int len = 0;
2020                 if (!is_duration ($1))
2021                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
2022                 else
2023                         len = intlog2 ($1);
2024
2025                 $$ = Duration (len, $2).smobbed_copy ();
2026         }
2027         | DURATION_IDENTIFIER dots      {
2028                 Duration *d = unsmob_duration ($1);
2029                 Duration k (d->duration_log (), d->dot_count () + $2);
2030                 *d = k;
2031                 $$ = $1;
2032         }
2033         ;
2034
2035 multiplied_duration:
2036         steno_duration {
2037                 $$ = $1;
2038         }
2039         | multiplied_duration '*' bare_unsigned {
2040                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2041         }
2042         | multiplied_duration '*' FRACTION {
2043                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2044
2045                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2046         }
2047         ;
2048
2049 fraction:
2050         FRACTION { $$ = $1; }
2051         | UNSIGNED '/' UNSIGNED {
2052                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2053         }
2054         ;
2055
2056 dots:
2057         /* empty */     {
2058                 $$ = 0;
2059         }
2060         | dots '.' {
2061                 $$ ++;
2062         }
2063         ;
2064
2065 tremolo_type:
2066         ':'     {
2067                 $$ = 0;
2068         }
2069         | ':' bare_unsigned {
2070                 if (!is_duration ($2))
2071                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2072                 $$ = $2;
2073         }
2074         ;
2075
2076 bass_number:
2077         DIGIT   {
2078                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2079                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2080                                 $$);
2081         }
2082         | UNSIGNED {
2083                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2084                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2085                                 $$);
2086         }
2087         | STRING { $$ = $1; }
2088         ;
2089
2090 bass_mod:
2091         '-'     { $$ = -2; }
2092         | '+'   { $$ = 2; }
2093         | '!'   { $$ = 0; }
2094         ;
2095
2096 bass_figure:
2097         FIGURE_SPACE {
2098                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2099                 $$ = bfr->self_scm ();
2100                 scm_gc_unprotect_object ($$);
2101         }
2102         | bass_number  {
2103                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2104                 $$ = bfr->self_scm ();
2105
2106                 bfr->set_property ("figure", $1);
2107
2108                 scm_gc_unprotect_object ($$);
2109         }
2110         | bass_figure bass_mod {
2111                 Music *m = unsmob_music ($1);
2112                 if ($2) {
2113                         SCM salter = m->get_property ("alteration");
2114                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2115                         m->set_property ("alteration",
2116                                 scm_int2num (alter + $2));
2117                 } else {
2118                         m->set_property ("alteration", scm_int2num (0));
2119                 }
2120         }
2121         ;
2122
2123 br_bass_figure:
2124         '[' bass_figure {
2125                 $$ = $2;
2126                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2127         }
2128         | bass_figure   {
2129                 $$ = $1;
2130         }
2131         | br_bass_figure ']' {
2132                 $$ = $1;
2133                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2134         }
2135         ;
2136
2137 figure_list:
2138         /**/            {
2139                 $$ = SCM_EOL;
2140         }
2141         | figure_list br_bass_figure {
2142                 $$ = scm_cons ($2, $1);
2143         }
2144         ;
2145
2146 figure_spec:
2147         FIGURE_OPEN figure_list FIGURE_CLOSE {
2148                 Music *m = MY_MAKE_MUSIC ("EventChord");
2149                 $2 = scm_reverse_x ($2, SCM_EOL);
2150                 m->set_property ("elements", $2);
2151                 $$ = m->self_scm ();
2152         }
2153         ;
2154
2155
2156 optional_rest:
2157         /**/   { $$ = 0; }
2158         | REST { $$ = 1; }
2159         ;
2160
2161 simple_element:
2162         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2163                 if (!THIS->lexer_->is_note_state ())
2164                         THIS->parser_error (@1, _ ("Have to be in Note mode for notes"));
2165
2166                 Music *n = 0;
2167                 if ($6)
2168                         n = MY_MAKE_MUSIC ("RestEvent");
2169                 else
2170                         n = MY_MAKE_MUSIC ("NoteEvent");
2171
2172                 n->set_property ("pitch", $1);
2173                 n->set_property ("duration", $5);
2174
2175                 if (scm_is_number ($4))
2176                 {
2177                         int q = scm_to_int ($4);
2178                         n->set_property ("absolute-octave", scm_int2num (q-1));
2179                 }
2180
2181                 if ($3 % 2)
2182                         n->set_property ("cautionary", SCM_BOOL_T);
2183                 if ($2 % 2 || $3 % 2)
2184                         n->set_property ("force-accidental", SCM_BOOL_T);
2185
2186                 Music *v = MY_MAKE_MUSIC ("EventChord");
2187                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2188                 scm_gc_unprotect_object (n->self_scm ());
2189
2190                 v->set_spot (@$);
2191                 n->set_spot (@$);
2192                 $$ = v;
2193         }
2194         | DRUM_PITCH optional_notemode_duration {
2195                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2196                 n->set_property ("duration", $2);
2197                 n->set_property ("drum-type", $1);
2198
2199                 Music *v = MY_MAKE_MUSIC ("EventChord");
2200                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2201                 scm_gc_unprotect_object (n->self_scm ());
2202                 v->set_spot (@$);
2203                 n->set_spot (@$);
2204                 $$ = v;
2205
2206         }
2207         | figure_spec optional_notemode_duration {
2208                 Music *m = unsmob_music ($1);
2209                 m->set_spot (@$);
2210                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2211                 {
2212                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2213                 }
2214                 $$ = m;
2215         }
2216         | RESTNAME optional_notemode_duration           {
2217                 Music *ev = 0;
2218                 if (ly_scm2string ($1) == "s") {
2219                         /* Space */
2220                         ev = MY_MAKE_MUSIC ("SkipEvent");
2221                   }
2222                 else {
2223                         ev = MY_MAKE_MUSIC ("RestEvent");
2224
2225                     }
2226                 ev->set_property ("duration", $2);
2227                 ev->set_spot (@$);
2228                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2229                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2230                 velt->set_spot (@$);
2231
2232                 scm_gc_unprotect_object (ev->self_scm ());
2233
2234                 $$ = velt;
2235         }
2236         | MULTI_MEASURE_REST optional_notemode_duration         {
2237                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2238                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2239                 scm_gc_protect_object (mus);
2240                 $$ = unsmob_music (mus);
2241         }
2242
2243         | lyric_element optional_notemode_duration      {
2244                 if (!THIS->lexer_->is_lyric_state ())
2245                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
2246
2247                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2248                 lreq->set_property ("text", $1);
2249                 lreq->set_property ("duration",$2);
2250                 lreq->set_spot (@$);
2251                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2252                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2253
2254                 $$= velt;
2255         }
2256         | new_chord {
2257                 if (!THIS->lexer_->is_chord_state ())
2258                         THIS->parser_error (@1, _ ("Have to be in Chord mode for chords"));
2259                 $$ = unsmob_music ($1);
2260         }
2261         ;
2262
2263 lyric_element:
2264         lyric_markup {
2265                 $$ = $1;
2266         }
2267         | LYRICS_STRING {
2268                 $$ = make_simple_markup ($1);
2269         }
2270         ;
2271
2272 new_chord:
2273         steno_tonic_pitch optional_notemode_duration   {
2274                 $$ = make_chord ($1, $2, SCM_EOL);
2275         }
2276         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2277                 SCM its = scm_reverse_x ($4, SCM_EOL);
2278                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2279         }
2280         ;
2281
2282 chord_items:
2283         /**/ {
2284                 $$ = SCM_EOL;
2285         }
2286         | chord_items chord_item {
2287                 $$ = scm_cons ($2, $$);
2288         }
2289         ;
2290
2291 chord_separator:
2292         CHORD_COLON {
2293                 $$ = ly_symbol2scm ("chord-colon");
2294         }
2295         | CHORD_CARET {
2296                 $$ = ly_symbol2scm ("chord-caret");
2297         }
2298         | CHORD_SLASH steno_tonic_pitch {
2299                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2300         }
2301         | CHORD_BASS steno_tonic_pitch {
2302                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2303         }
2304         ;
2305
2306 chord_item:
2307         chord_separator {
2308                 $$ = $1;
2309         }
2310         | step_numbers {
2311                 $$ = scm_reverse_x ($1, SCM_EOL);
2312         }
2313         | CHORD_MODIFIER  {
2314                 $$ = $1;
2315         }
2316         ;
2317
2318 step_numbers:
2319         step_number { $$ = scm_cons ($1, SCM_EOL); }
2320         | step_numbers '.' step_number {
2321                 $$ = scm_cons ($3, $$);
2322         }
2323         ;
2324
2325 step_number:
2326         bare_unsigned {
2327                 $$ = make_chord_step ($1, 0);
2328         }
2329         | bare_unsigned '+' {
2330                 $$ = make_chord_step ($1, SHARP);
2331         }
2332         | bare_unsigned CHORD_MINUS {
2333                 $$ = make_chord_step ($1, FLAT);
2334         }
2335         ;
2336
2337 /*
2338         UTILITIES
2339
2340 TODO: should deprecate in favor of Scheme?
2341
2342  */
2343 number_expression:
2344         number_expression '+' number_term {
2345                 $$ = scm_sum ($1, $3);
2346         }
2347         | number_expression '-' number_term {
2348                 $$ = scm_difference ($1, $3);
2349         }
2350         | number_term
2351         ;
2352
2353 number_term:
2354         number_factor {
2355                 $$ = $1;
2356         }
2357         | number_factor '*' number_factor {
2358                 $$ = scm_product ($1, $3);
2359         }
2360         | number_factor '/' number_factor {
2361                 $$ = scm_divide ($1, $3);
2362         }
2363         ;
2364
2365 number_factor:
2366         '-'  number_factor { /* %prec UNARY_MINUS */
2367                 $$ = scm_difference ($2, SCM_UNDEFINED);
2368         }
2369         | bare_number
2370         ;
2371
2372
2373 bare_number:
2374         UNSIGNED        {
2375                 $$ = scm_int2num ($1);
2376         }
2377         | REAL          {
2378                 $$ = $1;
2379         }
2380         | NUMBER_IDENTIFIER             {
2381                 $$ = $1;
2382         }
2383         | REAL NUMBER_IDENTIFIER        {
2384                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2385         }
2386         | UNSIGNED NUMBER_IDENTIFIER    {
2387                 $$ = scm_make_real ($1 *scm_to_double ($2));
2388         }
2389         ;
2390
2391
2392 bare_unsigned:
2393         UNSIGNED {
2394                         $$ = $1;
2395         }
2396         | DIGIT {
2397                 $$ = $1;
2398         }
2399         ;
2400
2401 bare_int:
2402         bare_number {
2403                 if (scm_integer_p ($1) == SCM_BOOL_T)
2404                 {
2405                         int k = scm_to_int ($1);
2406                         $$ = k;
2407                 } else
2408                 {
2409                         THIS->parser_error (@1, _ ("need integer number arg"));
2410                         $$ = 0;
2411                 }
2412         }
2413         | '-' bare_int {
2414                 $$ = -$2;
2415         }
2416         ;
2417
2418 exclamations:
2419                 { $$ = 0; }
2420         | exclamations '!'      { $$ ++; }
2421         ;
2422
2423 questions:
2424                 { $$ = 0; }
2425         | questions '?' { $$ ++; }
2426         ;
2427
2428 /*
2429 This should be done more dynamically if possible.
2430 */
2431
2432 lyric_markup:
2433         LYRIC_MARKUP_IDENTIFIER {
2434                 $$ = $1;
2435         }
2436         | LYRIC_MARKUP
2437                 { THIS->lexer_->push_markup_state (); }
2438         markup_top {
2439                 $$ = $3;
2440                 THIS->lexer_->pop_state ();
2441         }
2442         ;
2443
2444 full_markup:
2445         MARKUP_IDENTIFIER {
2446                 $$ = $1;
2447         }
2448         | MARKUP
2449                 { THIS->lexer_->push_markup_state (); }
2450         markup_top {
2451                 $$ = $3;
2452                 THIS->lexer_->pop_state ();
2453         }
2454         ;
2455
2456 markup_top:
2457         markup_list {
2458                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2459         }
2460         | markup_head_1_list simple_markup      {
2461                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2462         }
2463         | simple_markup {
2464                 $$ = $1;
2465         }
2466         ;
2467
2468 markup_list:
2469         markup_composed_list {
2470                 $$ = $1;
2471         }
2472         | markup_braced_list {
2473                 $$ = $1;
2474         }
2475         ;
2476
2477 markup_composed_list:
2478         markup_head_1_list markup_braced_list {
2479                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2480
2481         }
2482         ;
2483
2484 markup_braced_list:
2485         '{' markup_braced_list_body '}' {
2486                 $$ = scm_reverse_x ($2, SCM_EOL);
2487         }
2488         ;
2489
2490 markup_braced_list_body:
2491         /* empty */     {  $$ = scm_list (SCM_EOL); }
2492         | markup_braced_list_body markup {
2493                 $$ = scm_cons ($2, $1);
2494         }
2495         | markup_braced_list_body markup_list {
2496                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2497         }
2498         ;
2499
2500 markup_head_1_item:
2501         MARKUP_HEAD_MARKUP0     {
2502                 $$ = scm_list_1 ($1);
2503         }
2504         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2505                 $$ = scm_list_2 ($1, $2);
2506         }
2507         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2508                 $$ = scm_list_3 ($1, $2, $3);
2509         }
2510         ;
2511
2512 markup_head_1_list:
2513         markup_head_1_item      {
2514                 $$ = scm_list_1 ($1);
2515         }
2516         | markup_head_1_list markup_head_1_item {
2517                 $$ = scm_cons ($2, $1);
2518         }
2519         ;
2520
2521 simple_markup:
2522         STRING {
2523                 $$ = make_simple_markup ($1);
2524         }
2525         | MARKUP_IDENTIFIER {
2526                 $$ = $1;
2527         }
2528         | LYRIC_MARKUP_IDENTIFIER {
2529                 $$ = $1;
2530         }
2531         | STRING_IDENTIFIER {
2532                 $$ = $1;
2533         }
2534         | SCORE {
2535                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2536                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2537         } '{' score_body '}' {
2538                 Score * sc = $4;
2539                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2540                 scm_gc_unprotect_object (sc->self_scm ());
2541                 THIS->lexer_->pop_state ();
2542         }
2543         | MARKUP_HEAD_SCM0 embedded_scm {
2544                 $$ = scm_list_2 ($1, $2);
2545         }
2546         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2547                 $$ = scm_list_4 ($1, $2, $3, $4);
2548         }
2549         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2550                 $$ = scm_list_3 ($1, $2, $3);
2551         }
2552         | MARKUP_HEAD_EMPTY {
2553                 $$ = scm_list_1 ($1);
2554         }
2555         | MARKUP_HEAD_LIST0 markup_list {
2556                 $$ = scm_list_2 ($1,$2);
2557         }
2558         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2559                 $$ = scm_list_3 ($1, $2, $3);
2560         }
2561         ;
2562
2563 markup:
2564         markup_head_1_list simple_markup        {
2565                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2566         }
2567         | simple_markup {
2568                 $$ = $1;
2569         }
2570         ;
2571
2572 %%
2573
2574 void
2575 Lily_parser::set_yydebug (bool )
2576 {
2577 #if 0
2578         yydebug = 1;
2579 #endif
2580 }
2581
2582 void
2583 Lily_parser::do_yyparse ()
2584 {
2585         yyparse ((void*)this);
2586 }
2587
2588
2589 /*
2590 Should make this optional?    It will also complain when you do
2591
2592         [s4]
2593
2594 which is entirely legitimate.
2595
2596 Or we can scrap it. Barchecks should detect wrong durations, and
2597 skipTypesetting speeds it up a lot.
2598 */
2599
2600 void
2601 Lily_parser::beam_check (SCM dur)
2602 {
2603   Duration *d = unsmob_duration (dur);
2604   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2605     {
2606       Music *m = unsmob_music (last_beam_start_);
2607       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2608     }
2609   last_beam_start_ = SCM_EOL;
2610 }
2611
2612
2613
2614
2615 /*
2616
2617 It is a little strange to have this function in this file, but
2618 otherwise, we have to import music classes into the lexer.
2619
2620 */
2621 int
2622 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2623 {
2624         if (scm_is_string (sid)) {
2625                 *destination = sid;
2626                 return STRING_IDENTIFIER;
2627         } else if (scm_is_number (sid)) {
2628                 *destination = sid;
2629                 return NUMBER_IDENTIFIER;
2630         } else if (unsmob_context_def (sid)) {
2631                 *destination = unsmob_context_def (sid)->clone_scm ();
2632                 return CONTEXT_DEF_IDENTIFIER;
2633         } else if (unsmob_score (sid)) {
2634                 Score *score = new Score (*unsmob_score (sid));
2635                 *destination = score->self_scm ();
2636                 return SCORE_IDENTIFIER;
2637         } else if (Music *mus = unsmob_music (sid)) {
2638                 mus = mus->clone ();
2639                 *destination = mus->self_scm ();
2640                 unsmob_music (*destination)->
2641                         set_property ("origin", make_input (last_input_));
2642                 return dynamic_cast<Event*> (mus)
2643                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2644         } else if (unsmob_duration (sid)) {
2645                 *destination = unsmob_duration (sid)->smobbed_copy ();
2646                 return DURATION_IDENTIFIER;
2647         } else if (unsmob_output_def (sid)) {
2648                 Output_def *p = unsmob_output_def (sid);
2649                 p = p->clone ();
2650
2651                 *destination = p->self_scm ();
2652                 return OUTPUT_DEF_IDENTIFIER;
2653         } else if (Text_interface::markup_p (sid)) {
2654                 *destination = sid;
2655                 if (is_lyric_state ())
2656                         return LYRIC_MARKUP_IDENTIFIER;
2657                 return MARKUP_IDENTIFIER;
2658         }
2659
2660         return -1;
2661 }
2662
2663 Music *
2664 property_op_to_music (SCM op)
2665 {
2666         Music *m = 0;
2667         SCM tag = scm_car (op);
2668         SCM symbol = scm_cadr (op);
2669         SCM args = scm_cddr (op);
2670         SCM grob_val = SCM_UNDEFINED;
2671         SCM grob_sym = SCM_UNDEFINED;
2672         SCM val = SCM_UNDEFINED;
2673
2674         if (tag == ly_symbol2scm ("assign"))
2675                 {
2676                 m = MY_MAKE_MUSIC ("PropertySet");
2677                 val = scm_car (args);
2678                 }
2679         else if (tag == ly_symbol2scm ("unset"))
2680                 m = MY_MAKE_MUSIC ("PropertyUnset");
2681         else if (tag == ly_symbol2scm ("poppush")
2682                  || tag == ly_symbol2scm ("push"))
2683                 {
2684                 m = MY_MAKE_MUSIC ("OverrideProperty");
2685                 grob_sym = scm_car (args);
2686                 grob_val = scm_cadr (args);
2687                 }
2688         else if (tag == ly_symbol2scm ("pop")) {
2689                 m = MY_MAKE_MUSIC ("RevertProperty");
2690                 grob_sym = scm_car (args);
2691                 }
2692
2693         m->set_property ("symbol", symbol);
2694
2695         if (val != SCM_UNDEFINED)
2696                 m->set_property ("value", val);
2697         if (grob_val != SCM_UNDEFINED)
2698                 m->set_property ("grob-value", grob_val);
2699
2700         if (grob_sym != SCM_UNDEFINED)
2701                 {
2702                 bool itc = do_internal_type_checking_global;
2703                 /* UGH.
2704                 */
2705                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2706                 if (autobeam)
2707                         do_internal_type_checking_global = false;
2708                 m->set_property ("grob-property", grob_sym);
2709                 if (autobeam)
2710                         do_internal_type_checking_global = itc;
2711                 }
2712
2713         if (tag == ly_symbol2scm ("poppush"))
2714                 m->set_property ("pop-first", SCM_BOOL_T);
2715
2716
2717         return m;
2718 }
2719
2720 Music*
2721 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2722 {
2723         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2724
2725         csm->set_property ("element", m->self_scm ());
2726         scm_gc_unprotect_object (m->self_scm ());
2727
2728         csm->set_property ("context-type",
2729                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2730         csm->set_property ("property-operations", ops);
2731
2732         if (scm_is_string (id))
2733                 csm->set_property ("context-id", id);
2734         return csm;
2735 }
2736
2737 SCM
2738 get_next_unique_context_id ()
2739 {
2740         return scm_makfrom0str ("$uniqueContextId");
2741 }
2742
2743
2744 SCM
2745 get_next_unique_lyrics_context_id ()
2746 {
2747         static int new_context_count;
2748         char s[128];
2749         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2750         return scm_makfrom0str (s);
2751 }