lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_BOT
  44 %nonassoc REPEAT
  45 %nonassoc ALTERNATIVE
  46
  47 /* The above precedences tackle the shift/reduce problem
  48
  49 1.  \repeat
  50         \repeat .. \alternative
  51
  52     \repeat { \repeat .. \alternative }
  53
  54 or
  55
  56     \repeat { \repeat } \alternative
  57 */
  58
  59 %nonassoc COMPOSITE
  60 %left ADDLYRICS
  61
  62  /* ADDLYRICS needs to have lower precedence than FUNCTION_ARGUMENTS,
  63   * or we won't be able to tell music apart from closed_music without
  64   * lookahead in the context of function calls.
  65   */
  66
  67 %right FUNCTION_ARGUMENTS
  68       MARKUP LYRICS_STRING MARKUP_IDENTIFIER STRING STRING_IDENTIFIER
  69       MARKUPLIST WITH CONTEXT_MOD_IDENTIFIER MARKUPLIST_IDENTIFIER
  70       SCORE BOOK BOOKPART PAPER LAYOUT MIDI
  71       SEQUENTIAL SIMULTANEOUS DOUBLE_ANGLE_OPEN MUSIC_IDENTIFIER '{'
  72       PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  73       SCM_FUNCTION SCM_IDENTIFIER SCM_TOKEN
  74       UNSIGNED DURATION_IDENTIFIER
  75       CHORDMODE CHORDS DRUMMODE DRUMS FIGUREMODE FIGURES LYRICMODE LYRICS
  76       NOTEMODE
  77       CONTEXT TIMES NEWCONTEXT
  78
  79  /* The above are the symbols that can start function arguments */
  80
  81 %left PREC_TOP
  82
  83
  84
  85
  86 %pure_parser
  87 %locations
  88
  89
  90
  91 %{ // -*-Fundamental-*-
  92
  93 /*
  94 FIXME:
  95
  96    * The rules for who is protecting what are very shady.  Uniformise
  97      this.
  98
  99    * There are too many lexical modes?
 100 */
 101
 102 #include "config.hh"
 103
 104 #include <cctype>
 105 #include <cstdlib>
 106 #include <cstdio>
 107 using namespace std;
 108
 109 #include "book.hh"
 110 #include "context-def.hh"
 111 #include "context-mod.hh"
 112 #include "dimensions.hh"
 113 #include "file-path.hh"
 114 #include "input.hh"
 115 #include "international.hh"
 116 #include "lily-guile.hh"
 117 #include "lily-lexer.hh"
 118 #include "lily-parser.hh"
 119 #include "main.hh"
 120 #include "misc.hh"
 121 #include "music.hh"
 122 #include "output-def.hh"
 123 #include "paper-book.hh"
 124 #include "scm-hash.hh"
 125 #include "score.hh"
 126 #include "text-interface.hh"
 127 #include "warn.hh"
 128
 129 #define MYBACKUP(Token, Value, Location)                                \
 130         do                                                              \
 131                 if (yychar == YYEMPTY)                                  \
 132                         PARSER->lexer_->push_extra_token (Token, Value); \
 133                 else                                                    \
 134                         PARSER->parser_error                            \
 135                                 (Location, _("cannot backup token"));   \
 136         while (0)
 137
 138 %}
 139
 140
 141 %union {
 142         Book *book;
 143         Output_def *outputdef;
 144         SCM scm;
 145         std::string *string;
 146         Music *music;
 147         Score *score;
 148         int i;
 149 }
 150
 151 %{
 152
 153 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 154
 155 /* ES TODO:
 156 - Don't use lily module, create a new module instead.
 157 - delay application of the function
 158 */
 159 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 160   scm_apply_0 (proc, args)
 161 /* Syntactic Sugar. */
 162 #define MAKE_SYNTAX(name, location, ...)        \
 163   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), ##__VA_ARGS__, SCM_UNDEFINED));
 164 #define START_MAKE_SYNTAX(name, ...)                                    \
 165         scm_list_n (ly_lily_module_constant (name), ##__VA_ARGS__, SCM_UNDEFINED)
 166 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 167         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (PARSER->self_scm (), make_input (location), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 168
 169 SCM get_next_unique_context_id ();
 170 SCM get_next_unique_lyrics_context_id ();
 171
 172 #undef _
 173 #if !HAVE_GETTEXT
 174 #define _(x) x
 175 #else
 176 #include <libintl.h>
 177 #define _(x) gettext (x)
 178 #endif
 179
 180
 181 static Music *make_music_with_input (SCM name, Input where);
 182 SCM check_scheme_arg (Lily_parser *parser, Input loc, SCM fallback,
 183                       SCM arg, SCM args, SCM pred);
 184 SCM loc_on_music (Input loc, SCM arg);
 185 SCM get_first_context_id (SCM type, Music *m);
 186 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 187 SCM make_chord_step (int step, Rational alter);
 188 SCM make_simple_markup (SCM a);
 189 SCM try_unpack_lyrics (SCM pred, SCM arg);
 190 bool is_duration (int t);
 191 bool is_regular_identifier (SCM id);
 192 bool ly_input_procedure_p (SCM x);
 193 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 194 void set_music_properties (Music *p, SCM a);
 195
 196 %}
 197
 198 /* The third option is an alias that will be used to display the
 199    syntax error.  Bison CVS now correctly handles backslash escapes.
 200
 201    FIXME: Bison needs to translate some of these, eg, STRING.
 202
 203 */
 204
 205 /* Keyword tokens with plain escaped name.  */
 206 %token ACCEPTS "\\accepts"
 207 %token ADDLYRICS "\\addlyrics"
 208 %token ALIAS "\\alias"
 209 %token ALTERNATIVE "\\alternative"
 210 %token BOOK "\\book"
 211 %token BOOKPART "\\bookpart"
 212 %token CHANGE "\\change"
 213 %token CHORDMODE "\\chordmode"
 214 %token CHORDS "\\chords"
 215 %token CONSISTS "\\consists"
 216 %token CONTEXT "\\context"
 217 %token DEFAULT "\\default"
 218 %token DEFAULTCHILD "\\defaultchild"
 219 %token DENIES "\\denies"
 220 %token DESCRIPTION "\\description"
 221 %token DRUMMODE "\\drummode"
 222 %token DRUMS "\\drums"
 223 %token FIGUREMODE "\\figuremode"
 224 %token FIGURES "\\figures"
 225 %token GROBDESCRIPTIONS "\\grobdescriptions"
 226 %token HEADER "\\header"
 227 %token INVALID "\\version-error"
 228 %token KEY "\\key"
 229 %token LAYOUT "\\layout"
 230 %token LYRICMODE "\\lyricmode"
 231 %token LYRICS "\\lyrics"
 232 %token LYRICSTO "\\lyricsto"
 233 %token MARK "\\mark"
 234 %token MARKUP "\\markup"
 235 %token MARKUPLIST "\\markuplist"
 236 %token MIDI "\\midi"
 237 %token NAME "\\name"
 238 %token NOTEMODE "\\notemode"
 239 %token OVERRIDE "\\override"
 240 %token PAPER "\\paper"
 241 %token REMOVE "\\remove"
 242 %token REPEAT "\\repeat"
 243 %token REST "\\rest"
 244 %token REVERT "\\revert"
 245 %token SCORE "\\score"
 246 %token SEQUENTIAL "\\sequential"
 247 %token SET "\\set"
 248 %token SIMULTANEOUS "\\simultaneous"
 249 %token TEMPO "\\tempo"
 250 %token TIMES "\\times"
 251 %token TYPE "\\type"
 252 %token UNSET "\\unset"
 253 %token WITH "\\with"
 254
 255 /* Keyword token exceptions.  */
 256 %token TIME_T "\\time"
 257 %token NEWCONTEXT "\\new"
 258
 259
 260 /* Other string tokens.  */
 261
 262 %token CHORD_BASS "/+"
 263 %token CHORD_CARET "^"
 264 %token CHORD_COLON ":"
 265 %token CHORD_MINUS "-"
 266 %token CHORD_SLASH "/"
 267 %token ANGLE_OPEN "<"
 268 %token ANGLE_CLOSE ">"
 269 %token DOUBLE_ANGLE_OPEN "<<"
 270 %token DOUBLE_ANGLE_CLOSE ">>"
 271 %token E_BACKSLASH "\\"
 272 %token E_ANGLE_CLOSE "\\>"
 273 %token E_CHAR "\\C[haracter]"
 274 %token E_CLOSE "\\)"
 275 %token E_EXCLAMATION "\\!"
 276 %token E_BRACKET_OPEN "\\["
 277 %token E_OPEN "\\("
 278 %token E_BRACKET_CLOSE "\\]"
 279 %token E_ANGLE_OPEN "\\<"
 280 %token E_PLUS "\\+"
 281 %token E_TILDE "\\~"
 282 %token EXTENDER "__"
 283
 284 /*
 285 If we give names, Bison complains.
 286 */
 287 %token FIGURE_CLOSE /* "\\>" */
 288 %token FIGURE_OPEN /* "\\<" */
 289 %token FIGURE_SPACE "_"
 290 %token HYPHEN "--"
 291
 292 %token CHORDMODIFIERS
 293 %token LYRIC_MARKUP
 294 %token MULTI_MEASURE_REST
 295
 296
 297 %token <i> E_UNSIGNED
 298 %token <scm> UNSIGNED
 299
 300 /* Artificial tokens, for more generic function syntax */
 301 %token <i> EXPECT_MARKUP "markup?"
 302 %token <i> EXPECT_PITCH "ly:pitch?"
 303 %token <i> EXPECT_DURATION "ly:duration?"
 304 %token <scm> EXPECT_SCM "scheme?"
 305 %token <scm> SKIPPED_SCM "(scheme?)"
 306 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 307 %token <scm> EXPECT_OPTIONAL "optional?"
 308 /* After the last argument. */
 309 %token <i> EXPECT_NO_MORE_ARGS;
 310
 311 /* An artificial token for parsing embedded Lilypond */
 312 %token <i> EMBEDDED_LILY "#{"
 313
 314 %token <scm> BOOK_IDENTIFIER
 315 %token <scm> CHORDMODIFIER_PITCH
 316 %token <scm> CHORD_MODIFIER
 317 %token <scm> CHORD_REPETITION
 318 %token <scm> CONTEXT_DEF_IDENTIFIER
 319 %token <scm> CONTEXT_MOD_IDENTIFIER
 320 %token <scm> DRUM_PITCH
 321 %token <scm> PITCH_IDENTIFIER
 322 %token <scm> DURATION_IDENTIFIER
 323 %token <scm> EVENT_IDENTIFIER
 324 %token <scm> EVENT_FUNCTION
 325 %token <scm> FRACTION
 326 %token <scm> LYRICS_STRING
 327 %token <scm> LYRIC_MARKUP_IDENTIFIER
 328 %token <scm> MARKUP_FUNCTION
 329 %token <scm> MARKUP_LIST_FUNCTION
 330 %token <scm> MARKUP_IDENTIFIER
 331 %token <scm> MARKUPLIST_IDENTIFIER
 332 %token <scm> MUSIC_FUNCTION
 333 %token <scm> MUSIC_IDENTIFIER
 334 %token <scm> NOTENAME_PITCH
 335 %token <scm> NUMBER_IDENTIFIER
 336 %token <scm> OUTPUT_DEF_IDENTIFIER
 337 %token <scm> REAL
 338 %token <scm> RESTNAME
 339 %token <scm> SCM_FUNCTION
 340 %token <scm> SCM_IDENTIFIER
 341 %token <scm> SCM_TOKEN
 342 %token <scm> SCORE_IDENTIFIER
 343 %token <scm> STRING
 344 %token <scm> STRING_IDENTIFIER
 345 %token <scm> TONICNAME_PITCH
 346
 347
 348 %type <book> book_block
 349 %type <book> book_body
 350 %type <book> bookpart_block
 351 %type <book> bookpart_body
 352
 353 %type <i> bare_unsigned
 354 %type <scm> figured_bass_alteration
 355 %type <i> dots
 356 %type <i> exclamations
 357 %type <i> optional_rest
 358 %type <i> questions
 359 %type <i> script_dir
 360 %type <i> sub_quotes
 361 %type <i> sup_quotes
 362 %type <i> tremolo_type
 363
 364 /* Music */
 365 %type <scm> composite_music
 366 %type <scm> grouped_music_list
 367 %type <scm> braced_music_list
 368 %type <scm> closed_music
 369 %type <scm> music
 370 %type <scm> music_bare
 371 %type <scm> complex_music
 372 %type <scm> complex_music_prefix
 373 %type <scm> mode_changed_music
 374 %type <scm> repeated_music
 375 %type <scm> sequential_music
 376 %type <scm> simple_music
 377 %type <scm> simultaneous_music
 378 %type <scm> chord_body
 379 %type <scm> chord_body_element
 380 %type <scm> command_element
 381 %type <scm> command_event
 382 %type <scm> context_modification
 383 %type <scm> context_change
 384 %type <scm> direction_less_event
 385 %type <scm> direction_reqd_event
 386 %type <scm> embedded_lilypond
 387 %type <scm> event_chord
 388 %type <scm> fingering
 389 %type <scm> gen_text_def
 390 %type <scm> music_property_def
 391 %type <scm> note_chord_element
 392 %type <scm> post_event
 393 %type <scm> post_event_nofinger
 394 %type <scm> re_rhythmed_music
 395 %type <scm> simple_element
 396 %type <scm> simple_music_property_def
 397 %type <scm> start_symbol
 398 %type <scm> string_number_event
 399 %type <scm> tempo_event
 400
 401 %type <outputdef> output_def_body
 402 %type <outputdef> output_def_head
 403 %type <outputdef> output_def_head_with_mode_switch
 404 %type <outputdef> output_def
 405 %type <outputdef> paper_block
 406
 407 %type <scm> music_function_call
 408 %type <scm> music_list
 409 %type <scm> assignment_id
 410 %type <scm> bare_number
 411 %type <scm> unsigned_number
 412 %type <scm> bass_figure
 413 %type <scm> figured_bass_modification
 414 %type <scm> br_bass_figure
 415 %type <scm> bass_number
 416 %type <scm> chord_body_elements
 417 %type <scm> chord_item
 418 %type <scm> chord_items
 419 %type <scm> chord_separator
 420 %type <scm> context_def_mod
 421 %type <scm> context_def_spec_block
 422 %type <scm> context_def_spec_body
 423 %type <scm> context_mod
 424 %type <scm> context_mod_list
 425 %type <scm> context_prop_spec
 426 %type <scm> direction_less_char
 427 %type <scm> duration_length
 428 %type <scm> embedded_scm
 429 %type <scm> embedded_scm_arg
 430 %type <scm> embedded_scm_arg_closed
 431 %type <scm> embedded_scm_bare
 432 %type <scm> embedded_scm_bare_arg
 433 %type <scm> embedded_scm_closed
 434 %type <scm> embedded_scm_chord_body
 435 %type <scm> embedded_scm_event
 436 %type <scm> event_function_event
 437 %type <scm> figure_list
 438 %type <scm> figure_spec
 439 %type <scm> fraction
 440 %type <scm> full_markup
 441 %type <scm> full_markup_list
 442 %type <scm> function_arglist
 443 %type <scm> function_arglist_optional
 444 %type <scm> function_arglist_keep
 445 %type <scm> function_arglist_bare
 446 %type <scm> function_arglist_closed
 447 %type <scm> function_arglist_closed_optional
 448 %type <scm> function_arglist_closed_keep
 449 %type <scm> identifier_init
 450 %type <scm> lilypond
 451 %type <scm> lilypond_header
 452 %type <scm> lilypond_header_body
 453 %type <scm> lyric_element
 454 %type <scm> lyric_markup
 455 %type <scm> markup
 456 %type <scm> markup_braced_list
 457 %type <scm> markup_braced_list_body
 458 %type <scm> markup_composed_list
 459 %type <scm> markup_command_list
 460 %type <scm> markup_command_list_arguments
 461 %type <scm> markup_command_basic_arguments
 462 %type <scm> markup_head_1_item
 463 %type <scm> markup_head_1_list
 464 %type <scm> markup_list
 465 %type <scm> markup_top
 466 %type <scm> mode_changing_head
 467 %type <scm> mode_changing_head_with_context
 468 %type <scm> multiplied_duration
 469 %type <scm> music_function_event
 470 %type <scm> music_function_event_arglist
 471 %type <scm> music_function_chord_body
 472 %type <scm> music_function_chord_body_arglist
 473 %type <scm> new_chord
 474 %type <scm> new_lyrics
 475 %type <scm> number_expression
 476 %type <scm> number_factor
 477 %type <scm> number_term
 478 %type <scm> octave_check
 479 %type <scm> optional_context_mod
 480 %type <scm> optional_id
 481 %type <scm> optional_notemode_duration
 482 %type <scm> pitch
 483 %type <scm> pitch_also_in_chords
 484 %type <scm> post_events
 485 %type <scm> property_operation
 486 %type <scm> property_path property_path_revved
 487 %type <scm> scalar
 488 %type <scm> scalar_bare
 489 %type <scm> scalar_closed
 490 %type <scm> scm_function_call
 491 %type <scm> scm_function_call_closed
 492 %type <scm> script_abbreviation
 493 %type <scm> simple_chord_elements
 494 %type <scm> simple_markup
 495 %type <scm> simple_string
 496 %type <scm> steno_duration
 497 %type <scm> steno_pitch
 498 %type <scm> steno_tonic_pitch
 499 %type <scm> step_number
 500 %type <scm> step_numbers
 501 %type <scm> string
 502 %type <scm> tempo_range
 503
 504 %type <score> score_block
 505 %type <score> score_body
 506
 507
 508 %left '-' '+'
 509
 510 /* We don't assign precedence to / and *, because we might need varied
 511 prec levels in different prods */
 512
 513 %left UNARY_MINUS
 514
 515 %%
 516
 517 start_symbol:
 518         lilypond
 519         | EMBEDDED_LILY {
 520                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
 521                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
 522         } embedded_lilypond {
 523                 PARSER->lexer_->pop_state ();
 524                 PARSER->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 525         }
 526         ;
 527
 528 lilypond:       /* empty */ { }
 529         | lilypond toplevel_expression {
 530         }
 531         | lilypond assignment {
 532         }
 533         | lilypond error {
 534                 PARSER->error_level_ = 1;
 535         }
 536         | lilypond INVALID      {
 537                 PARSER->error_level_ = 1;
 538         }
 539         ;
 540
 541
 542 toplevel_expression:
 543         lilypond_header {
 544                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 545         }
 546         | book_block {
 547                 Book *book = $1;
 548                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 549                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 550                 book->unprotect ();
 551         }
 552         | bookpart_block {
 553                 Book *bookpart = $1;
 554                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 555                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 556                 bookpart->unprotect ();
 557         }
 558         | score_block {
 559                 Score *score = $1;
 560
 561                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 562                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 563                 score->unprotect ();
 564         }
 565         | composite_music {
 566                 Music *music = unsmob_music ($1);
 567                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 568                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 569         }
 570         | full_markup {
 571                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 572                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 573         }
 574         | full_markup_list {
 575                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 576                 scm_call_2 (proc, PARSER->self_scm (), $1);
 577         }
 578         | output_def {
 579                 SCM id = SCM_EOL;
 580                 Output_def * od = $1;
 581
 582                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 583                         id = ly_symbol2scm ("$defaultpaper");
 584                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 585                         id = ly_symbol2scm ("$defaultmidi");
 586                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 587                         id = ly_symbol2scm ("$defaultlayout");
 588
 589                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 590                 od->unprotect();
 591         }
 592         ;
 593
 594 embedded_scm_bare:
 595         SCM_TOKEN
 596         | SCM_IDENTIFIER
 597         ;
 598
 599 embedded_scm_bare_arg:
 600         embedded_scm_bare
 601         | STRING
 602         | STRING_IDENTIFIER
 603         | full_markup
 604         | full_markup_list
 605         | context_modification
 606         | score_block
 607         {
 608                 $$ = $1->self_scm ();
 609                 $1->unprotect ();
 610         }
 611         | context_def_spec_block
 612         | book_block
 613         {
 614                 $$ = $1->self_scm ();
 615                 $1->unprotect ();
 616         }
 617         | bookpart_block
 618         {
 619                 $$ = $1->self_scm ();
 620                 $1->unprotect ();
 621         }
 622         | output_def
 623         {
 624                 $$ = $1->self_scm ();
 625                 $1->unprotect ();
 626         }
 627         ;
 628
 629 /* The generic version may end in music, or not */
 630
 631 embedded_scm:
 632         embedded_scm_bare
 633         | scm_function_call
 634         ;
 635
 636 embedded_scm_arg:
 637         embedded_scm_bare_arg
 638         | scm_function_call
 639         | music
 640         ;
 641
 642 scm_function_call:
 643         SCM_FUNCTION function_arglist {
 644                 $$ = MAKE_SYNTAX ("music-function", @$,
 645                                          $1, $2);
 646         }
 647         ;
 648
 649 embedded_lilypond:
 650         /* empty */
 651         {
 652                 $$ = MAKE_SYNTAX ("void-music", @$);
 653         }
 654         | identifier_init
 655         | music music music_list {
 656                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 657                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 658         }
 659         | error {
 660                 PARSER->error_level_ = 1;
 661         }
 662         | INVALID embedded_lilypond {
 663                 PARSER->error_level_ = 1;
 664         }
 665         ;
 666
 667
 668 lilypond_header_body:
 669         {
 670                 $$ = get_header (PARSER);
 671                 PARSER->lexer_->add_scope ($$);
 672         }
 673         | lilypond_header_body assignment  {
 674
 675         }
 676         ;
 677
 678 lilypond_header:
 679         HEADER '{' lilypond_header_body '}'     {
 680                 $$ = PARSER->lexer_->remove_scope ();
 681         }
 682         ;
 683
 684 /*
 685         DECLARATIONS
 686 */
 687 assignment_id:
 688         STRING          { $$ = $1; }
 689         | LYRICS_STRING { $$ = $1; }
 690         ;
 691
 692 assignment:
 693         assignment_id '=' identifier_init  {
 694                 PARSER->lexer_->set_identifier ($1, $3);
 695         }
 696         | assignment_id property_path '=' identifier_init {
 697                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 698                 PARSER->lexer_->set_identifier (path, $4);
 699         ;
 700 /*
 701  TODO: devise standard for protection in parser.
 702
 703   The parser stack lives on the C-stack, which means that
 704 all objects can be unprotected as soon as they're here.
 705
 706 */
 707         }
 708         | embedded_scm { }
 709         ;
 710
 711
 712 identifier_init:
 713         score_block {
 714                 $$ = $1->self_scm ();
 715                 $1->unprotect ();
 716         }
 717         | book_block {
 718                 $$ = $1->self_scm ();
 719                 $1->unprotect ();
 720         }
 721         | bookpart_block {
 722                 $$ = $1->self_scm ();
 723                 $1->unprotect ();
 724         }
 725         | output_def {
 726                 $$ = $1->self_scm ();
 727                 $1->unprotect ();
 728         }
 729         | context_def_spec_block {
 730                 $$ = $1;
 731         }
 732         | music  {
 733                 /* Hack: Create event-chord around standalone events.
 734                    Prevents the identifier from being interpreted as a post-event. */
 735                 Music *mus = unsmob_music ($1);
 736                 bool is_event = mus &&
 737                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 738                                 != SCM_BOOL_F);
 739                 if (!is_event)
 740                         $$ = $1;
 741                 else
 742                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 743         }
 744         | post_event_nofinger {
 745                 $$ = $1;
 746         }
 747         | number_expression {
 748                 $$ = $1;
 749         }
 750         | string {
 751                 $$ = $1;
 752         }
 753         | embedded_scm {
 754                 $$ = $1;
 755         }
 756         | full_markup {
 757                 $$ = $1;
 758         }
 759         | full_markup_list {
 760                 $$ = $1;
 761         }
 762         | context_modification {
 763                 $$ = $1;
 764         }
 765         ;
 766
 767 context_def_spec_block:
 768         CONTEXT '{' context_def_spec_body '}'
 769                 {
 770                 $$ = $3;
 771         }
 772         ;
 773
 774 context_def_spec_body:
 775         /**/ {
 776                 $$ = Context_def::make_scm ();
 777                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 778         }
 779         | CONTEXT_DEF_IDENTIFIER {
 780                 $$ = $1;
 781                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 782         }
 783         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 784                 Context_def*td = unsmob_context_def ($$);
 785
 786                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 787                         SCM tag = scm_caar (p);
 788
 789                         /* TODO: should make new tag "grob-definition" ? */
 790                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 791                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 792                 }
 793         }
 794         | context_def_spec_body context_mod {
 795                 unsmob_context_def ($$)->add_context_mod ($2);
 796         }
 797         | context_def_spec_body context_modification {
 798                 Context_def *td = unsmob_context_def ($$);
 799                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 800                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 801                     td->add_context_mod (scm_car (m));
 802                 }
 803         }
 804         ;
 805
 806
 807
 808 book_block:
 809         BOOK '{' book_body '}'  {
 810                 $$ = $3;
 811                 pop_paper (PARSER);
 812                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 813         }
 814         ;
 815
 816 /* FIXME:
 817    * Use 'handlers' like for toplevel-* stuff?
 818    * grok \layout and \midi?  */
 819 book_body:
 820         {
 821                 $$ = new Book;
 822                 init_papers (PARSER);
 823                 $$->origin ()->set_spot (@$);
 824                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 825                 $$->paper_->unprotect ();
 826                 push_paper (PARSER, $$->paper_);
 827                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 828                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 829                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 830                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 831         }
 832         | BOOK_IDENTIFIER {
 833                 $$ = unsmob_book ($1);
 834                 $$->protect ();
 835                 $$->origin ()->set_spot (@$);
 836                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 837         }
 838         | book_body paper_block {
 839                 $$->paper_ = $2;
 840                 $2->unprotect ();
 841                 set_paper (PARSER, $2);
 842         }
 843         | book_body bookpart_block {
 844                 Book *bookpart = $2;
 845                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 846                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 847                 bookpart->unprotect ();
 848         }
 849         | book_body score_block {
 850                 Score *score = $2;
 851                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 852                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 853                 score->unprotect ();
 854         }
 855         | book_body composite_music {
 856                 Music *music = unsmob_music ($2);
 857                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 858                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 859         }
 860         | book_body full_markup {
 861                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 862                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 863         }
 864         | book_body full_markup_list {
 865                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 866                 scm_call_2 (proc, $$->self_scm (), $2);
 867         }
 868         | book_body lilypond_header {
 869                 $$->header_ = $2;
 870         }
 871         | book_body embedded_scm { }
 872         | book_body error {
 873                 $$->paper_ = 0;
 874                 $$->scores_ = SCM_EOL;
 875                 $$->bookparts_ = SCM_EOL;
 876         }
 877         ;
 878
 879 bookpart_block:
 880         BOOKPART '{' bookpart_body '}' {
 881                 $$ = $3;
 882                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 883         }
 884         ;
 885
 886 bookpart_body:
 887         {
 888                 $$ = new Book;
 889                 $$->origin ()->set_spot (@$);
 890                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 891         }
 892         | BOOK_IDENTIFIER {
 893                 $$ = unsmob_book ($1);
 894                 $$->protect ();
 895                 $$->origin ()->set_spot (@$);
 896                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 897         }
 898         | bookpart_body paper_block {
 899                 $$->paper_ = $2;
 900                 $2->unprotect ();
 901         }
 902         | bookpart_body score_block {
 903                 Score *score = $2;
 904                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 905                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 906                 score->unprotect ();
 907         }
 908         | bookpart_body composite_music {
 909                 Music *music = unsmob_music ($2);
 910                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 911                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 912         }
 913         | bookpart_body full_markup {
 914                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 915                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 916         }
 917         | bookpart_body full_markup_list {
 918                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 919                 scm_call_2 (proc, $$->self_scm (), $2);
 920         }
 921         | bookpart_body lilypond_header {
 922                 $$->header_ = $2;
 923         }
 924         | bookpart_body embedded_scm { }
 925         | bookpart_body error {
 926                 $$->paper_ = 0;
 927                 $$->scores_ = SCM_EOL;
 928         }
 929         ;
 930
 931 score_block:
 932         SCORE '{' score_body '}'        {
 933                 $$ = $3;
 934         }
 935         ;
 936
 937 score_body:
 938         music {
 939                 SCM m = $1;
 940                 SCM scorify = ly_lily_module_constant ("scorify-music");
 941                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 942
 943                 // pass ownernship to C++ again.
 944                 $$ = unsmob_score (score);
 945                 $$->protect ();
 946                 $$->origin ()->set_spot (@$);
 947         }
 948         | SCORE_IDENTIFIER {
 949                 $$ = unsmob_score ($1);
 950                 $$->protect ();
 951                 $$->origin ()->set_spot (@$);
 952         }
 953         | score_body lilypond_header    {
 954                 $$->set_header ($2);
 955         }
 956         | score_body output_def {
 957                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 958                 {
 959                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 960
 961                 }
 962                 else
 963                 {
 964                         $$->add_output_def ($2);
 965                 }
 966                 $2->unprotect ();
 967         }
 968         | score_body error {
 969                 $$->error_found_ = true;
 970         }
 971         ;
 972
 973
 974 /*
 975         OUTPUT DEF
 976 */
 977
 978 paper_block:
 979         output_def {
 980                 $$ = $1;
 981                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 982                 {
 983                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 984                         $1->unprotect ();
 985                         $$ = get_paper (PARSER);
 986                 }
 987         }
 988         ;
 989
 990
 991 output_def:
 992         output_def_body '}' {
 993                 $$ = $1;
 994
 995                 PARSER->lexer_->remove_scope ();
 996                 PARSER->lexer_->pop_state ();
 997         }
 998         ;
 999
1000 output_def_head:
1001         PAPER {
1002                 $$ = get_paper (PARSER);
1003                 $$->input_origin_ = @$;
1004                 PARSER->lexer_->add_scope ($$->scope_);
1005         }
1006         | MIDI    {
1007                 Output_def *p = get_midi (PARSER);
1008                 $$ = p;
1009                 PARSER->lexer_->add_scope (p->scope_);
1010         }
1011         | LAYOUT        {
1012                 Output_def *p = get_layout (PARSER);
1013
1014                 PARSER->lexer_->add_scope (p->scope_);
1015                 $$ = p;
1016         }
1017         ;
1018
1019 output_def_head_with_mode_switch:
1020         output_def_head {
1021                 PARSER->lexer_->push_initial_state ();
1022                 $$ = $1;
1023         }
1024         ;
1025
1026 output_def_body:
1027         output_def_head_with_mode_switch '{' {
1028                 $$ = $1;
1029                 $$->input_origin_.set_spot (@$);
1030         }
1031         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
1032                 $1->unprotect ();
1033
1034                 Output_def *o = unsmob_output_def ($3);
1035                 o->input_origin_.set_spot (@$);
1036                 $$ = o;
1037                 $$->protect ();
1038                 PARSER->lexer_->remove_scope ();
1039                 PARSER->lexer_->add_scope (o->scope_);
1040         }
1041         | output_def_body assignment  {
1042
1043         }
1044         | output_def_body context_def_spec_block        {
1045                 assign_context_def ($$, $2);
1046         }
1047         | output_def_body error {
1048
1049         }
1050         ;
1051
1052 tempo_event:
1053         TEMPO steno_duration '=' tempo_range    {
1054                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1055         }
1056         | TEMPO scalar_closed steno_duration '=' tempo_range    {
1057                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1058         }
1059         | TEMPO scalar {
1060                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1061         }
1062         ;
1063
1064 /*
1065 The representation of a  list is reversed to have efficient append.  */
1066
1067 music_list:
1068         /* empty */ {
1069                 $$ = SCM_EOL;
1070         }
1071         | music_list music {
1072                 $$ = scm_cons ($2, $1);
1073         }
1074         | music_list embedded_scm {
1075
1076         }
1077         | music_list error {
1078                 Music *m = MY_MAKE_MUSIC("Music", @$);
1079                 // ugh. code dup
1080                 m->set_property ("error-found", SCM_BOOL_T);
1081                 $$ = scm_cons (m->self_scm (), $1);
1082                 m->unprotect (); /* UGH */
1083         }
1084         ;
1085
1086 braced_music_list:
1087         '{' music_list '}'
1088         {
1089                 $$ = scm_reverse_x ($2, SCM_EOL);
1090         }
1091         ;
1092
1093 music:
1094         simple_music
1095         | composite_music %prec COMPOSITE
1096         ;
1097
1098
1099 repeated_music:
1100         REPEAT simple_string unsigned_number music
1101         {
1102                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1103         }
1104         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1105         {
1106                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1107         }
1108         ;
1109
1110 sequential_music:
1111         SEQUENTIAL braced_music_list {
1112                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1113         }
1114         | braced_music_list {
1115                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1116         }
1117         ;
1118
1119 simultaneous_music:
1120         SIMULTANEOUS braced_music_list {
1121                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1122         }
1123         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1124                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1125         }
1126         ;
1127
1128 simple_music:
1129         event_chord
1130         | music_property_def
1131         | context_change
1132         ;
1133
1134 context_modification:
1135         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1136         {
1137                 PARSER->lexer_->pop_state ();
1138                 $$ = $4;
1139         }
1140         | WITH CONTEXT_MOD_IDENTIFIER
1141         {
1142                 $$ = $2;
1143         }
1144         | CONTEXT_MOD_IDENTIFIER
1145         {
1146                 $$ = $1;
1147         }
1148         ;
1149
1150 optional_context_mod:
1151         /**/ {
1152             $$ = SCM_EOL;
1153         }
1154         | context_modification
1155         {
1156               $$ = $1;
1157         }
1158         ;
1159
1160 context_mod_list:
1161         /**/ {
1162             $$ = Context_mod ().smobbed_copy ();
1163         }
1164         | context_mod_list context_mod  {
1165                  unsmob_context_mod ($1)->add_context_mod ($2);
1166         }
1167         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1168                  Context_mod *md = unsmob_context_mod ($2);
1169                  if (md)
1170                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1171         }
1172         ;
1173
1174 composite_music:
1175         complex_music
1176         | music_bare
1177         ;
1178
1179 /* Music that can be parsed without lookahead */
1180 closed_music:
1181         music_bare
1182         | complex_music_prefix closed_music
1183         {
1184                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1185         }
1186         ;
1187
1188 music_bare:
1189         mode_changed_music
1190         | MUSIC_IDENTIFIER
1191         | grouped_music_list
1192         ;
1193
1194 grouped_music_list:
1195         simultaneous_music              { $$ = $1; }
1196         | sequential_music              { $$ = $1; }
1197         ;
1198
1199 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1200  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1201 and this rule returns the reversed list of arguments. */
1202
1203
1204 function_arglist:
1205         function_arglist_bare
1206         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1207         {
1208                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1209                                        $3, $2, $1);
1210         }
1211         | EXPECT_SCM function_arglist_optional SKIPPED_SCM
1212         {
1213                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1214                                        $3, $2, $1);
1215         }
1216         ;
1217
1218 function_arglist_optional:
1219         function_arglist_keep %prec FUNCTION_ARGUMENTS
1220         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1221         {
1222                 $$ = scm_cons ($1, $3);
1223         }
1224         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1225         {
1226                 $$ = scm_cons ($1, $3);
1227         }
1228         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_optional
1229         {
1230                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1231         }
1232         ;
1233
1234 function_arglist_keep:
1235         EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords {
1236                 $$ = scm_cons ($4, $3);
1237         }
1238         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length {
1239                 $$ = scm_cons ($4, $3);
1240         }
1241         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1242         {
1243                 if (scm_is_true (scm_call_1 ($2, $4)))
1244                 {
1245                         $$ = scm_cons ($4, $3);
1246                 } else {
1247                         $$ = try_unpack_lyrics ($2, $4);
1248                         if (!SCM_UNBNDP ($$))
1249                                 $$ = scm_cons ($$, $3);
1250                         else {
1251                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1252                                 MYBACKUP (SKIPPED_SCM, $4, @4);
1253                         }
1254                 }
1255         }
1256         | function_arglist
1257         ;
1258
1259
1260 function_arglist_closed:
1261         function_arglist_bare
1262         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1263         {
1264                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1265                                        $3, $2, $1);
1266         }
1267         | EXPECT_SCM function_arglist_optional SKIPPED_SCM
1268         {
1269                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1270                                        $3, $2, $1);
1271         }
1272         ;
1273
1274 function_arglist_closed_optional:
1275         function_arglist_closed_keep %prec FUNCTION_ARGUMENTS
1276         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1277         {
1278                 $$ = scm_cons ($1, $3);
1279         }
1280         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1281         {
1282                 $$ = scm_cons ($1, $3);
1283         }
1284         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_optional
1285         {
1286                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1287         }
1288         ;
1289
1290 function_arglist_closed_keep:
1291         EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords {
1292                 $$ = scm_cons ($4, $3);
1293         }
1294         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length {
1295                 $$ = scm_cons ($4, $3);
1296         }
1297         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1298         {
1299                 if (scm_is_true (scm_call_1 ($2, $4)))
1300                 {
1301                         $$ = scm_cons ($4, $3);
1302                 } else {
1303                         $$ = try_unpack_lyrics ($2, $4);
1304                         if (!SCM_UNBNDP ($$))
1305                                 $$ = scm_cons ($$, $3);
1306                         else {
1307                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1308                                 MYBACKUP (SKIPPED_SCM, $4, @4);
1309                         }
1310                 }
1311         }
1312         | function_arglist_closed
1313         ;
1314
1315 embedded_scm_closed:
1316         embedded_scm_bare
1317         | scm_function_call_closed
1318         ;
1319
1320 embedded_scm_arg_closed:
1321         embedded_scm_bare_arg
1322         | scm_function_call_closed
1323         | closed_music
1324         ;
1325
1326 scm_function_call_closed:
1327         SCM_FUNCTION function_arglist_closed {
1328                 $$ = MAKE_SYNTAX ("music-function", @$,
1329                                          $1, $2);
1330         }
1331         ;
1332
1333 function_arglist_bare:
1334         EXPECT_NO_MORE_ARGS {
1335                 $$ = SCM_EOL;
1336         }
1337         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1338                 $$ = scm_cons ($3, $2);
1339         }
1340         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1341                 $$ = scm_cons ($3, $2);
1342         }
1343         ;
1344
1345 music_function_call:
1346         MUSIC_FUNCTION function_arglist {
1347                 $$ = MAKE_SYNTAX ("music-function", @$,
1348                                          $1, $2);
1349         }
1350         ;
1351
1352
1353 optional_id:
1354         /**/ { $$ = SCM_EOL; }
1355         | '=' simple_string {
1356                 $$ = $2;
1357         }
1358         ;
1359
1360 complex_music:
1361         music_function_call
1362         | repeated_music                { $$ = $1; }
1363         | re_rhythmed_music     { $$ = $1; }
1364         | complex_music_prefix music
1365         {
1366                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1367         }
1368         ;
1369
1370 complex_music_prefix:
1371         CONTEXT simple_string optional_id optional_context_mod {
1372                 Context_mod *ctxmod = unsmob_context_mod ($4);
1373                 SCM mods = SCM_EOL;
1374                 if (ctxmod)
1375                         mods = ctxmod->get_mods ();
1376                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1377         }
1378         | NEWCONTEXT simple_string optional_id optional_context_mod {
1379                 Context_mod *ctxmod = unsmob_context_mod ($4);
1380                 SCM mods = SCM_EOL;
1381                 if (ctxmod)
1382                         mods = ctxmod->get_mods ();
1383                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1384         }
1385         | TIMES fraction {
1386                 $$ = START_MAKE_SYNTAX ("time-scaled-music", $2);
1387         }
1388         ;
1389
1390 mode_changed_music:
1391         mode_changing_head grouped_music_list {
1392                 if ($1 == ly_symbol2scm ("chords"))
1393                 {
1394                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1395                 }
1396                 else
1397                 {
1398                   $$ = $2;
1399                 }
1400                 PARSER->lexer_->pop_state ();
1401         }
1402         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1403                 Context_mod *ctxmod = unsmob_context_mod ($2);
1404                 SCM mods = SCM_EOL;
1405                 if (ctxmod)
1406                         mods = ctxmod->get_mods ();
1407                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1408                 if ($1 == ly_symbol2scm ("ChordNames"))
1409                 {
1410                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1411                 }
1412                 PARSER->lexer_->pop_state ();
1413         }
1414         ;
1415
1416 mode_changing_head:
1417         NOTEMODE {
1418                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1419                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1420
1421                 $$ = ly_symbol2scm ("notes");
1422         }
1423         | DRUMMODE
1424                 {
1425                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1426                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1427
1428                 $$ = ly_symbol2scm ("drums");
1429         }
1430         | FIGUREMODE {
1431                 PARSER->lexer_->push_figuredbass_state ();
1432
1433                 $$ = ly_symbol2scm ("figures");
1434         }
1435         | CHORDMODE {
1436                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1437                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1438                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1439                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1440                 $$ = ly_symbol2scm ("chords");
1441
1442         }
1443         | LYRICMODE
1444                 { PARSER->lexer_->push_lyric_state ();
1445                 $$ = ly_symbol2scm ("lyrics");
1446         }
1447         ;
1448
1449 mode_changing_head_with_context:
1450         DRUMS {
1451                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1452                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1453
1454                 $$ = ly_symbol2scm ("DrumStaff");
1455         }
1456         | FIGURES {
1457                 PARSER->lexer_->push_figuredbass_state ();
1458
1459                 $$ = ly_symbol2scm ("FiguredBass");
1460         }
1461         | CHORDS {
1462                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1463                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1464                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1465                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1466                 $$ = ly_symbol2scm ("ChordNames");
1467         }
1468         | LYRICS
1469                 { PARSER->lexer_->push_lyric_state ();
1470                 $$ = ly_symbol2scm ("Lyrics");
1471         }
1472         ;
1473
1474 new_lyrics:
1475         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1476         /*cont */
1477         composite_music {
1478         /* Can also use music at the expensive of two S/Rs similar to
1479            \repeat \alternative */
1480                 PARSER->lexer_->pop_state ();
1481
1482                 $$ = scm_cons ($3, SCM_EOL);
1483         }
1484         | new_lyrics ADDLYRICS {
1485                 PARSER->lexer_->push_lyric_state ();
1486         } composite_music {
1487                 PARSER->lexer_->pop_state ();
1488                 $$ = scm_cons ($4, $1);
1489         }
1490         ;
1491
1492 re_rhythmed_music:
1493         composite_music new_lyrics {
1494                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1495         } %prec COMPOSITE
1496         | LYRICSTO simple_string {
1497                 PARSER->lexer_->push_lyric_state ();
1498         } music {
1499                 PARSER->lexer_->pop_state ();
1500                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1501         }
1502         ;
1503
1504 context_change:
1505         CHANGE STRING '=' STRING  {
1506                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1507         }
1508         ;
1509
1510
1511 property_path_revved:
1512         embedded_scm_closed {
1513                 $$ = scm_cons ($1, SCM_EOL);
1514         }
1515         | property_path_revved embedded_scm_closed {
1516                 $$ = scm_cons ($2, $1);
1517         }
1518         ;
1519
1520 property_path:
1521         property_path_revved  {
1522                 $$ = scm_reverse_x ($1, SCM_EOL);
1523         }
1524         ;
1525
1526 property_operation:
1527         STRING '=' scalar {
1528                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1529                         scm_string_to_symbol ($1), $3);
1530         }
1531         | UNSET simple_string {
1532                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1533                         scm_string_to_symbol ($2));
1534         }
1535         | OVERRIDE simple_string property_path '=' scalar {
1536                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1537                                                         scm_string_to_symbol ($2), $5),
1538                                              $3));
1539         }
1540         | REVERT simple_string embedded_scm {
1541                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1542                         scm_string_to_symbol ($2), $3);
1543         }
1544         ;
1545
1546 context_def_mod:
1547         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1548         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1549
1550         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1551         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1552         | DENIES { $$ = ly_symbol2scm ("denies"); }
1553
1554         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1555         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1556         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1557         | NAME { $$ = ly_symbol2scm ("context-name"); }
1558         ;
1559
1560 context_mod:
1561         property_operation { $$ = $1; }
1562         | context_def_mod STRING {
1563                 $$ = scm_list_2 ($1, $2);
1564         }
1565         | context_def_mod embedded_scm {
1566            if (ly_symbol2scm ("consists") != $1)
1567            {
1568              $$ = SCM_EOL;
1569              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1570            }
1571            else
1572            {
1573              $$ = scm_list_2 ($1, $2);
1574            }
1575         }
1576         ;
1577
1578 context_prop_spec:
1579         simple_string {
1580                 if (!is_regular_identifier ($1))
1581                 {
1582                         @$.error (_("Grob name should be alphanumeric"));
1583                 }
1584
1585                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1586                         scm_string_to_symbol ($1));
1587         }
1588         | simple_string '.' simple_string {
1589                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1590                         scm_string_to_symbol ($3));
1591         }
1592         ;
1593
1594 simple_music_property_def:
1595         OVERRIDE context_prop_spec property_path '=' scalar {
1596                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1597                                 ly_symbol2scm ("OverrideProperty"),
1598                                 scm_cadr ($2),
1599                                 $5, SCM_UNDEFINED),
1600                                 $3));
1601         }
1602         | REVERT context_prop_spec embedded_scm {
1603                 $$ = scm_list_4 (scm_car ($2),
1604                         ly_symbol2scm ("RevertProperty"),
1605                         scm_cadr ($2),
1606                         $3);
1607         }
1608         | SET context_prop_spec '=' scalar {
1609                 $$ = scm_list_4 (scm_car ($2),
1610                         ly_symbol2scm ("PropertySet"),
1611                         scm_cadr ($2),
1612                         $4);
1613         }
1614         | UNSET context_prop_spec {
1615                 $$ = scm_list_3 (scm_car ($2),
1616                         ly_symbol2scm ("PropertyUnset"),
1617                         scm_cadr ($2));
1618         }
1619         ;
1620
1621 music_property_def:
1622         simple_music_property_def {
1623                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (PARSER->self_scm (), make_input (@$), $1));
1624         }
1625         ;
1626
1627 string:
1628         STRING {
1629                 $$ = $1;
1630         }
1631         | STRING_IDENTIFIER {
1632                 $$ = $1;
1633         }
1634         | string '+' string {
1635                 $$ = scm_string_append (scm_list_2 ($1, $3));
1636         }
1637         ;
1638
1639 simple_string: STRING {
1640                 $$ = $1;
1641         }
1642         | LYRICS_STRING {
1643                 $$ = $1;
1644         }
1645         | STRING_IDENTIFIER {
1646                 $$ = $1;
1647         }
1648         ;
1649
1650 scalar_bare:
1651         string {
1652                 $$ = $1;
1653         }
1654         | lyric_element {
1655                 $$ = $1;
1656         }
1657         | bare_number {
1658                 $$ = $1;
1659         }
1660         | embedded_scm_bare {
1661                 $$ = $1;
1662         }
1663         | full_markup {
1664                 $$ = $1;
1665         }
1666         | full_markup_list
1667         {
1668                 $$ = $1;
1669         }
1670         ;
1671
1672 scalar:
1673         scalar_bare |
1674         scm_function_call
1675         ;
1676
1677 scalar_closed:
1678         scalar_bare |
1679         scm_function_call_closed
1680         ;
1681
1682
1683 event_chord:
1684         /* TODO: Create a special case that avoids the creation of
1685            EventChords around simple_elements that have no post_events?
1686          */
1687         simple_chord_elements post_events       {
1688                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1689
1690                 Input i;
1691                 /* why is this giving wrong start location? -ns
1692                  * i = @$; */
1693                 i.set_location (@1, @2);
1694                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1695         }
1696         | CHORD_REPETITION optional_notemode_duration post_events {
1697                 Input i;
1698                 i.set_location (@1, @3);
1699                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1700                                   PARSER->lexer_->chord_repetition_.last_chord_,
1701                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1702                                   $2, scm_reverse_x ($3, SCM_EOL));
1703         }
1704         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1705                 Input i;
1706                 i.set_location (@1, @3);
1707                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1708                                   scm_reverse_x ($3, SCM_EOL));
1709         }
1710         | command_element
1711         /* note chord elements are memorized into
1712            PARSER->lexer_->chord_repetition_ so that the chord repetition
1713            mechanism copy them when a chord repetition symbol is found
1714         */
1715         | note_chord_element    {
1716                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1717         }
1718         ;
1719
1720
1721 note_chord_element:
1722         chord_body optional_notemode_duration post_events
1723         {
1724                 Music *m = unsmob_music ($1);
1725                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1726                 SCM es = m->get_property ("elements");
1727                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1728
1729                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1730                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1731                 es = ly_append2 (es, postevs);
1732
1733                 m-> set_property ("elements", es);
1734                 m->set_spot (@$);
1735                 $$ = m->self_scm ();
1736         }
1737         ;
1738
1739 chord_body:
1740         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1741         {
1742                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1743         }
1744         ;
1745
1746 chord_body_elements:
1747         /* empty */             { $$ = SCM_EOL; }
1748         | chord_body_elements chord_body_element {
1749                 $$ = scm_cons ($2, $1);
1750         }
1751         ;
1752
1753 chord_body_element:
1754         pitch exclamations questions octave_check post_events
1755         {
1756                 int q = $3;
1757                 int ex = $2;
1758                 SCM check = $4;
1759                 SCM post = $5;
1760
1761                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1762                 n->set_property ("pitch", $1);
1763                 if (q % 2)
1764                         n->set_property ("cautionary", SCM_BOOL_T);
1765                 if (ex % 2 || q % 2)
1766                         n->set_property ("force-accidental", SCM_BOOL_T);
1767
1768                 if (scm_is_pair (post)) {
1769                         SCM arts = scm_reverse_x (post, SCM_EOL);
1770                         n->set_property ("articulations", arts);
1771                 }
1772                 if (scm_is_number (check))
1773                 {
1774                         int q = scm_to_int (check);
1775                         n->set_property ("absolute-octave", scm_from_int (q-1));
1776                 }
1777
1778                 $$ = n->unprotect ();
1779         }
1780         | DRUM_PITCH post_events {
1781                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1782                 n->set_property ("drum-type", $1);
1783
1784                 if (scm_is_pair ($2)) {
1785                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1786                         n->set_property ("articulations", arts);
1787                 }
1788                 $$ = n->unprotect ();
1789         }
1790         | music_function_chord_body
1791         ;
1792
1793 /* We can't accept a music argument, not even a closed one,
1794  * immediately before chord_body_elements, otherwise a function \fun
1795  * with a signature of two music arguments can't be sorted out
1796  * properly in a construct like
1797  * <\fun { c } \fun { c } c>
1798  * The second call could be interpreted either as a chord constituent
1799  * or a music expression.
1800  */
1801
1802 music_function_chord_body_arglist:
1803         function_arglist_bare
1804         | EXPECT_SCM music_function_chord_body_arglist embedded_scm_chord_body
1805         {
1806                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1807                                        $3, $2, $1);
1808         }
1809         ;
1810
1811 embedded_scm_chord_body:
1812         embedded_scm_bare_arg
1813         | SCM_FUNCTION music_function_chord_body_arglist {
1814                 $$ = MAKE_SYNTAX ("music-function", @$,
1815                                          $1, $2);
1816         }
1817         | chord_body_element
1818         | SKIPPED_SCM
1819         ;
1820
1821 music_function_chord_body:
1822         MUSIC_FUNCTION music_function_chord_body_arglist {
1823                 $$ = MAKE_SYNTAX ("music-function", @$,
1824                                          $1, $2);
1825         }
1826         ;
1827
1828 /* We could accept a closed music argument before the post events
1829  * indicated by a trailing argument list.  For symmetry with chord
1830  * bodies and in order to avoid too tricky and complex behavior, we
1831  * refrain from doing so.
1832  */
1833 music_function_event_arglist:
1834         function_arglist_bare
1835         | EXPECT_SCM music_function_event_arglist embedded_scm_event
1836         {
1837                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1838                                        $3, $2, $1);
1839         }
1840         ;
1841
1842 embedded_scm_event:
1843         embedded_scm_bare_arg
1844         | SCM_FUNCTION music_function_event_arglist {
1845                 $$ = MAKE_SYNTAX ("music-function", @$,
1846                                          $1, $2);
1847         }
1848         | post_event
1849         | SKIPPED_SCM
1850         ;
1851
1852 music_function_event:
1853         MUSIC_FUNCTION music_function_event_arglist {
1854                 $$ = MAKE_SYNTAX ("music-function", @$,
1855                                          $1, $2);
1856         }
1857         ;
1858
1859 event_function_event:
1860         EVENT_FUNCTION music_function_event_arglist {
1861                 $$ = MAKE_SYNTAX ("music-function", @$,
1862                                          $1, $2);
1863         }
1864         ;
1865
1866 command_element:
1867         command_event {
1868                 $$ = $1;
1869         }
1870         | E_BRACKET_OPEN {
1871                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1872                 m->set_property ("span-direction", scm_from_int (START));
1873                 $$ = m->unprotect();
1874         }
1875         | E_BRACKET_CLOSE {
1876                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1877                 m->set_property ("span-direction", scm_from_int (STOP));
1878                 $$ = m->unprotect ();
1879         }
1880         | E_BACKSLASH {
1881                 $$ = MAKE_SYNTAX ("voice-separator", @$);
1882         }
1883         | '|'      {
1884                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1885
1886                 Music *m = unsmob_music (pipe);
1887                 if (m)
1888                 {
1889                         m = m->clone ();
1890                         m->set_spot (@$);
1891                         $$ = m->unprotect ();
1892                 }
1893                 else
1894                         $$ = MAKE_SYNTAX ("bar-check", @$);
1895
1896         }
1897         | TIME_T fraction  {
1898                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1899
1900                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1901         }
1902         | MARK scalar {
1903                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1904         }
1905         ;
1906
1907 command_event:
1908         E_TILDE {
1909                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1910         }
1911         | MARK DEFAULT  {
1912                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1913                 $$ = m->unprotect ();
1914         }
1915         | tempo_event {
1916                 $$ = $1;
1917         }
1918         | KEY DEFAULT {
1919                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1920                 $$ = key->unprotect ();
1921         }
1922         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1923
1924                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1925                 if (scm_ilength ($3) > 0)
1926                 {
1927                         key->set_property ("pitch-alist", $3);
1928                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1929                         key->transpose (* unsmob_pitch ($2));
1930                 } else {
1931                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1932                 }
1933
1934                 $$ = key->unprotect ();
1935         }
1936         ;
1937
1938
1939 post_events:
1940         /* empty */ {
1941                 $$ = SCM_EOL;
1942         }
1943         | post_events post_event {
1944                 unsmob_music ($2)->set_spot (@2);
1945                 $$ = scm_cons ($2, $$);
1946         }
1947         ;
1948
1949 post_event_nofinger:
1950         direction_less_event {
1951                 $$ = $1;
1952         }
1953         | script_dir music_function_event {
1954                 $$ = $2;
1955                 if ($1)
1956                 {
1957                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
1958                 }
1959         }
1960         | HYPHEN {
1961                 if (!PARSER->lexer_->is_lyric_state ())
1962                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1963                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1964         }
1965         | EXTENDER {
1966                 if (!PARSER->lexer_->is_lyric_state ())
1967                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1968                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1969         }
1970         | script_dir direction_reqd_event {
1971                 if ($1)
1972                 {
1973                         Music *m = unsmob_music ($2);
1974                         m->set_property ("direction", scm_from_int ($1));
1975                 }
1976                 $$ = $2;
1977         }
1978         | script_dir direction_less_event {
1979                 if ($1)
1980                 {
1981                         Music *m = unsmob_music ($2);
1982                         m->set_property ("direction", scm_from_int ($1));
1983                 }
1984                 $$ = $2;
1985         }
1986         | string_number_event
1987         ;
1988
1989 post_event:
1990         post_event_nofinger
1991         | script_dir fingering {
1992                 if ($1)
1993                 {
1994                         Music *m = unsmob_music ($2);
1995                         m->set_property ("direction", scm_from_int ($1));
1996                 }
1997                 $$ = $2;
1998         }
1999         ;
2000
2001 string_number_event:
2002         E_UNSIGNED {
2003                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2004                 s->set_property ("string-number", scm_from_int ($1));
2005                 $$ = s->unprotect ();
2006         }
2007         ;
2008
2009 direction_less_char:
2010         '['  {
2011                 $$ = ly_symbol2scm ("bracketOpenSymbol");
2012         }
2013         | ']'  {
2014                 $$ = ly_symbol2scm ("bracketCloseSymbol");
2015         }
2016         | '~'  {
2017                 $$ = ly_symbol2scm ("tildeSymbol");
2018         }
2019         | '('  {
2020                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
2021         }
2022         | ')'  {
2023                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
2024         }
2025         | E_EXCLAMATION  {
2026                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
2027         }
2028         | E_OPEN  {
2029                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
2030         }
2031         | E_CLOSE  {
2032                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
2033         }
2034         | E_ANGLE_CLOSE  {
2035                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
2036         }
2037         | E_ANGLE_OPEN  {
2038                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
2039         }
2040         ;
2041
2042 direction_less_event:
2043         direction_less_char {
2044                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
2045                 Music *m = 0;
2046                 if (unsmob_music (predefd))
2047                 {
2048                         m = unsmob_music (predefd)->clone ();
2049                         m->set_spot (@$);
2050                 }
2051                 else
2052                 {
2053                         m = MY_MAKE_MUSIC ("Music", @$);
2054                 }
2055                 $$ = m->unprotect ();
2056         }
2057         | EVENT_IDENTIFIER      {
2058                 $$ = $1;
2059         }
2060         | tremolo_type  {
2061                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2062                a->set_property ("tremolo-type", scm_from_int ($1));
2063                $$ = a->unprotect ();
2064         }
2065         | event_function_event
2066         ;
2067
2068 direction_reqd_event:
2069         gen_text_def {
2070                 $$ = $1;
2071         }
2072         | script_abbreviation {
2073                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2074                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2075                 if (scm_is_string (s))
2076                         a->set_property ("articulation-type", s);
2077                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
2078                 $$ = a->unprotect ();
2079         }
2080         ;
2081
2082 octave_check:
2083         /**/ { $$ = SCM_EOL; }
2084         | '='  { $$ = scm_from_int (0); }
2085         | '=' sub_quotes { $$ = scm_from_int (-$2); }
2086         | '=' sup_quotes { $$ = scm_from_int ($2); }
2087         ;
2088
2089 sup_quotes:
2090         '\'' {
2091                 $$ = 1;
2092         }
2093         | sup_quotes '\'' {
2094                 $$ ++;
2095         }
2096         ;
2097
2098 sub_quotes:
2099         ',' {
2100                 $$ = 1;
2101         }
2102         | sub_quotes ',' {
2103                 $$++;
2104         }
2105         ;
2106
2107 steno_pitch:
2108         NOTENAME_PITCH  {
2109                 $$ = $1;
2110         }
2111         | NOTENAME_PITCH sup_quotes     {
2112                 Pitch p = *unsmob_pitch ($1);
2113                 p = p.transposed (Pitch ($2,0,0));
2114                 $$ = p.smobbed_copy ();
2115         }
2116         | NOTENAME_PITCH sub_quotes      {
2117                 Pitch p =* unsmob_pitch ($1);
2118                 p = p.transposed (Pitch (-$2,0,0));
2119                 $$ = p.smobbed_copy ();
2120         }
2121         ;
2122
2123 /*
2124 ugh. duplication
2125 */
2126
2127 steno_tonic_pitch:
2128         TONICNAME_PITCH {
2129                 $$ = $1;
2130         }
2131         | TONICNAME_PITCH sup_quotes    {
2132                 Pitch p = *unsmob_pitch ($1);
2133                 p = p.transposed (Pitch ($2,0,0));
2134                 $$ = p.smobbed_copy ();
2135         }
2136         | TONICNAME_PITCH sub_quotes     {
2137                 Pitch p = *unsmob_pitch ($1);
2138
2139                 p = p.transposed (Pitch (-$2,0,0));
2140                 $$ = p.smobbed_copy ();
2141         }
2142         ;
2143
2144 pitch:
2145         steno_pitch {
2146                 $$ = $1;
2147         }
2148         | PITCH_IDENTIFIER
2149         ;
2150
2151 pitch_also_in_chords:
2152         pitch
2153         | steno_tonic_pitch
2154         ;
2155
2156 gen_text_def:
2157         full_markup {
2158                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2159                 t->set_property ("text", $1);
2160                 $$ = t->unprotect ();
2161         }
2162         | string {
2163                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2164                 t->set_property ("text",
2165                         make_simple_markup ($1));
2166                 $$ = t->unprotect ();
2167         }
2168         ;
2169
2170 fingering:
2171         UNSIGNED {
2172                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2173                 t->set_property ("digit", $1);
2174                 $$ = t->unprotect ();
2175         }
2176         ;
2177
2178 script_abbreviation:
2179         '^'             {
2180                 $$ = scm_from_locale_string ("Hat");
2181         }
2182         | '+'           {
2183                 $$ = scm_from_locale_string ("Plus");
2184         }
2185         | '-'           {
2186                 $$ = scm_from_locale_string ("Dash");
2187         }
2188         | '|'           {
2189                 $$ = scm_from_locale_string ("Bar");
2190         }
2191         | ANGLE_CLOSE   {
2192                 $$ = scm_from_locale_string ("Larger");
2193         }
2194         | '.'           {
2195                 $$ = scm_from_locale_string ("Dot");
2196         }
2197         | '_' {
2198                 $$ = scm_from_locale_string ("Underscore");
2199         }
2200         ;
2201
2202 script_dir:
2203         '_'     { $$ = DOWN; }
2204         | '^'   { $$ = UP; }
2205         | '-'   { $$ = CENTER; }
2206         ;
2207
2208 duration_length:
2209         multiplied_duration {
2210                 $$ = $1;
2211         }
2212         ;
2213
2214 optional_notemode_duration:
2215         {
2216                 Duration dd = PARSER->default_duration_;
2217                 $$ = dd.smobbed_copy ();
2218         }
2219         | multiplied_duration   {
2220                 $$ = $1;
2221                 PARSER->default_duration_ = *unsmob_duration ($$);
2222         }
2223         ;
2224
2225 steno_duration:
2226         bare_unsigned dots              {
2227                 int len = 0;
2228                 if (!is_duration ($1))
2229                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
2230                 else
2231                         len = intlog2 ($1);
2232
2233                 $$ = Duration (len, $2).smobbed_copy ();
2234         }
2235         | DURATION_IDENTIFIER dots      {
2236                 Duration *d = unsmob_duration ($1);
2237                 Duration k (d->duration_log (), d->dot_count () + $2);
2238                 k = k.compressed (d->factor ());
2239                 *d = k;
2240                 $$ = $1;
2241         }
2242         ;
2243
2244 multiplied_duration:
2245         steno_duration {
2246                 $$ = $1;
2247         }
2248         | multiplied_duration '*' bare_unsigned {
2249                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2250         }
2251         | multiplied_duration '*' FRACTION {
2252                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2253
2254                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2255         }
2256         ;
2257
2258 fraction:
2259         FRACTION { $$ = $1; }
2260         | UNSIGNED '/' UNSIGNED {
2261                 $$ = scm_cons ($1, $3);
2262         }
2263         ;
2264
2265 dots:
2266         /* empty */     {
2267                 $$ = 0;
2268         }
2269         | dots '.' {
2270                 $$ ++;
2271         }
2272         ;
2273
2274 tremolo_type:
2275         ':'     {
2276                 $$ = 0;
2277         }
2278         | ':' bare_unsigned {
2279                 if (!is_duration ($2))
2280                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2281                 $$ = $2;
2282         }
2283         ;
2284
2285 bass_number:
2286         UNSIGNED { $$ = $1; }
2287         | STRING { $$ = $1; }
2288         | full_markup { $$ = $1; }
2289         ;
2290
2291 figured_bass_alteration:
2292         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2293         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2294         | '!'   { $$ = scm_from_int (0); }
2295         ;
2296
2297 bass_figure:
2298         FIGURE_SPACE {
2299                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2300                 $$ = bfr->unprotect ();
2301         }
2302         | bass_number  {
2303                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2304                 $$ = bfr->self_scm ();
2305
2306                 if (scm_is_number ($1))
2307                         bfr->set_property ("figure", $1);
2308                 else if (Text_interface::is_markup ($1))
2309                         bfr->set_property ("text", $1);
2310
2311                 bfr->unprotect ();
2312         }
2313         | bass_figure ']' {
2314                 $$ = $1;
2315                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2316         }
2317         | bass_figure figured_bass_alteration {
2318                 Music *m = unsmob_music ($1);
2319                 if (scm_to_double ($2)) {
2320                         SCM salter = m->get_property ("alteration");
2321                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2322                         m->set_property ("alteration",
2323                                          scm_sum (alter, $2));
2324                 } else {
2325                         m->set_property ("alteration", scm_from_int (0));
2326                 }
2327         }
2328         | bass_figure figured_bass_modification  {
2329                 Music *m = unsmob_music ($1);
2330                 if ($2 == ly_symbol2scm ("plus"))
2331                         {
2332                         m->set_property ("augmented", SCM_BOOL_T);
2333                         }
2334                 else if ($2 == ly_symbol2scm ("slash"))
2335                         {
2336                         m->set_property ("diminished", SCM_BOOL_T);
2337                         }
2338                 else if ($2 == ly_symbol2scm ("exclamation"))
2339                         {
2340                         m->set_property ("no-continuation", SCM_BOOL_T);
2341                         }
2342                 else if ($2 == ly_symbol2scm ("backslash"))
2343                         {
2344                         m->set_property ("augmented-slash", SCM_BOOL_T);
2345                         }
2346         }
2347         ;
2348
2349
2350 figured_bass_modification:
2351         E_PLUS          {
2352                 $$ = ly_symbol2scm ("plus");
2353         }
2354         | E_EXCLAMATION {
2355                 $$ = ly_symbol2scm ("exclamation");
2356         }
2357         | '/'           {
2358                 $$ = ly_symbol2scm ("slash");
2359         }
2360         | E_BACKSLASH {
2361                 $$ = ly_symbol2scm ("backslash");
2362         }
2363         ;
2364
2365 br_bass_figure:
2366         bass_figure {
2367                 $$ = $1;
2368         }
2369         | '[' bass_figure {
2370                 $$ = $2;
2371                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2372         }
2373         ;
2374
2375 figure_list:
2376         /**/            {
2377                 $$ = SCM_EOL;
2378         }
2379         | figure_list br_bass_figure {
2380                 $$ = scm_cons ($2, $1);
2381         }
2382         ;
2383
2384 figure_spec:
2385         FIGURE_OPEN figure_list FIGURE_CLOSE {
2386                 $$ = scm_reverse_x ($2, SCM_EOL);
2387         }
2388         ;
2389
2390
2391 optional_rest:
2392         /**/   { $$ = 0; }
2393         | REST { $$ = 1; }
2394         ;
2395
2396 simple_element:
2397         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2398                 if (!PARSER->lexer_->is_note_state ())
2399                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2400
2401                 Music *n = 0;
2402                 if ($6)
2403                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2404                 else
2405                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2406
2407                 n->set_property ("pitch", $1);
2408                 n->set_property ("duration", $5);
2409
2410                 if (scm_is_number ($4))
2411                 {
2412                         int q = scm_to_int ($4);
2413                         n->set_property ("absolute-octave", scm_from_int (q-1));
2414                 }
2415
2416                 if ($3 % 2)
2417                         n->set_property ("cautionary", SCM_BOOL_T);
2418                 if ($2 % 2 || $3 % 2)
2419                         n->set_property ("force-accidental", SCM_BOOL_T);
2420
2421                 $$ = n->unprotect ();
2422         }
2423         | DRUM_PITCH optional_notemode_duration {
2424                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2425                 n->set_property ("duration", $2);
2426                 n->set_property ("drum-type", $1);
2427
2428                 $$ = n->unprotect ();
2429         }
2430         | RESTNAME optional_notemode_duration           {
2431                 Music *ev = 0;
2432                 if (ly_scm2string ($1) == "s") {
2433                         /* Space */
2434                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2435                   }
2436                 else {
2437                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2438
2439                     }
2440                 ev->set_property ("duration", $2);
2441                 $$ = ev->unprotect ();
2442         }
2443         | lyric_element optional_notemode_duration      {
2444                 if (!PARSER->lexer_->is_lyric_state ())
2445                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2446
2447                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2448                 levent->set_property ("text", $1);
2449                 levent->set_property ("duration",$2);
2450                 $$= levent->unprotect ();
2451         }
2452         ;
2453
2454 simple_chord_elements:
2455         simple_element  {
2456                 $$ = scm_list_1 ($1);
2457         }
2458         | new_chord {
2459                 if (!PARSER->lexer_->is_chord_state ())
2460                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2461                 $$ = $1;
2462         }
2463         | figure_spec optional_notemode_duration {
2464                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2465                 {
2466                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2467                 }
2468                 $$ = $1;
2469         }
2470         ;
2471
2472 lyric_element:
2473         lyric_markup {
2474                 $$ = $1;
2475         }
2476         | LYRICS_STRING {
2477                 $$ = $1;
2478         }
2479         ;
2480
2481 new_chord:
2482         steno_tonic_pitch optional_notemode_duration   {
2483                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2484         }
2485         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2486                 SCM its = scm_reverse_x ($4, SCM_EOL);
2487                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2488         }
2489         ;
2490
2491 chord_items:
2492         /**/ {
2493                 $$ = SCM_EOL;
2494         }
2495         | chord_items chord_item {
2496                 $$ = scm_cons ($2, $$);
2497         }
2498         ;
2499
2500 chord_separator:
2501         CHORD_COLON {
2502                 $$ = ly_symbol2scm ("chord-colon");
2503         }
2504         | CHORD_CARET {
2505                 $$ = ly_symbol2scm ("chord-caret");
2506         }
2507         | CHORD_SLASH steno_tonic_pitch {
2508                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2509         }
2510         | CHORD_BASS steno_tonic_pitch {
2511                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2512         }
2513         ;
2514
2515 chord_item:
2516         chord_separator {
2517                 $$ = $1;
2518         }
2519         | step_numbers {
2520                 $$ = scm_reverse_x ($1, SCM_EOL);
2521         }
2522         | CHORD_MODIFIER  {
2523                 $$ = $1;
2524         }
2525         ;
2526
2527 step_numbers:
2528         step_number { $$ = scm_cons ($1, SCM_EOL); }
2529         | step_numbers '.' step_number {
2530                 $$ = scm_cons ($3, $$);
2531         }
2532         ;
2533
2534 step_number:
2535         bare_unsigned {
2536                 $$ = make_chord_step ($1, 0);
2537         }
2538         | bare_unsigned '+' {
2539                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2540         }
2541         | bare_unsigned CHORD_MINUS {
2542                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2543         }
2544         ;
2545
2546 tempo_range:
2547         bare_unsigned {
2548                 $$ = scm_from_int ($1);
2549         }
2550         | bare_unsigned '~' bare_unsigned {
2551                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2552         }
2553         ;
2554
2555 /*
2556         UTILITIES
2557
2558 TODO: should deprecate in favor of Scheme?
2559
2560  */
2561 number_expression:
2562         number_expression '+' number_term {
2563                 $$ = scm_sum ($1, $3);
2564         }
2565         | number_expression '-' number_term {
2566                 $$ = scm_difference ($1, $3);
2567         }
2568         | number_term
2569         ;
2570
2571 number_term:
2572         number_factor {
2573                 $$ = $1;
2574         }
2575         | number_factor '*' number_factor {
2576                 $$ = scm_product ($1, $3);
2577         }
2578         | number_factor '/' number_factor {
2579                 $$ = scm_divide ($1, $3);
2580         }
2581         ;
2582
2583 number_factor:
2584         '-'  number_factor { /* %prec UNARY_MINUS */
2585                 $$ = scm_difference ($2, SCM_UNDEFINED);
2586         }
2587         | bare_number
2588         ;
2589
2590
2591 bare_number:
2592         UNSIGNED        {
2593                 $$ = $1;
2594         }
2595         | REAL          {
2596                 $$ = $1;
2597         }
2598         | NUMBER_IDENTIFIER             {
2599                 $$ = $1;
2600         }
2601         | REAL NUMBER_IDENTIFIER        {
2602                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2603         }
2604         | bare_unsigned NUMBER_IDENTIFIER       {
2605                 $$ = scm_from_double ($1 *scm_to_double ($2));
2606         }
2607         ;
2608
2609
2610 bare_unsigned:
2611         UNSIGNED {
2612                 $$ = scm_to_int ($1);
2613         }
2614         ;
2615
2616 unsigned_number:
2617         UNSIGNED
2618         | NUMBER_IDENTIFIER
2619         ;
2620
2621 exclamations:
2622                 { $$ = 0; }
2623         | exclamations '!'      { $$ ++; }
2624         ;
2625
2626 questions:
2627                 { $$ = 0; }
2628         | questions '?' { $$ ++; }
2629         ;
2630
2631 /*
2632 This should be done more dynamically if possible.
2633 */
2634
2635 lyric_markup:
2636         LYRIC_MARKUP_IDENTIFIER {
2637                 $$ = $1;
2638         }
2639         | LYRIC_MARKUP
2640                 { PARSER->lexer_->push_markup_state (); }
2641         markup_top {
2642                 $$ = $3;
2643                 PARSER->lexer_->pop_state ();
2644         }
2645         ;
2646
2647 full_markup_list:
2648         MARKUPLIST_IDENTIFIER {
2649                 $$ = $1;
2650         }
2651         | MARKUPLIST
2652                 { PARSER->lexer_->push_markup_state (); }
2653         markup_list {
2654                 $$ = $3;
2655                 PARSER->lexer_->pop_state ();
2656         }
2657         ;
2658
2659 full_markup:
2660         MARKUP_IDENTIFIER {
2661                 $$ = $1;
2662         }
2663         | MARKUP
2664                 { PARSER->lexer_->push_markup_state (); }
2665         markup_top {
2666                 $$ = $3;
2667                 PARSER->lexer_->pop_state ();
2668         }
2669         ;
2670
2671 markup_top:
2672         markup_list {
2673                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2674         }
2675         | markup_head_1_list simple_markup      {
2676                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2677         }
2678         | simple_markup {
2679                 $$ = $1;
2680         }
2681         ;
2682
2683 markup_list:
2684         MARKUPLIST_IDENTIFIER {
2685                 $$ = $1;
2686         }
2687         | markup_composed_list {
2688                 $$ = $1;
2689         }
2690         | markup_braced_list {
2691                 $$ = $1;
2692         }
2693         | markup_command_list {
2694                 $$ = scm_list_1 ($1);
2695         }
2696         ;
2697
2698 markup_composed_list:
2699         markup_head_1_list markup_braced_list {
2700                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2701
2702         }
2703         ;
2704
2705 markup_braced_list:
2706         '{' markup_braced_list_body '}' {
2707                 $$ = scm_reverse_x ($2, SCM_EOL);
2708         }
2709         ;
2710
2711 markup_braced_list_body:
2712         /* empty */     {  $$ = SCM_EOL; }
2713         | markup_braced_list_body markup {
2714                 $$ = scm_cons ($2, $1);
2715         }
2716         | markup_braced_list_body markup_list {
2717                 $$ = scm_reverse_x ($2, $1);
2718         }
2719         ;
2720
2721 markup_command_list:
2722         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2723           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2724         }
2725         ;
2726
2727 markup_command_basic_arguments:
2728         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2729           $$ = scm_cons ($3, $2);
2730         }
2731         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
2732           $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED, $3, $2, $1);
2733         }
2734         | EXPECT_NO_MORE_ARGS {
2735           $$ = SCM_EOL;
2736         }
2737         ;
2738
2739 markup_command_list_arguments:
2740         markup_command_basic_arguments { $$ = $1; }
2741         | EXPECT_MARKUP markup_command_list_arguments markup {
2742           $$ = scm_cons ($3, $2);
2743         }
2744         ;
2745
2746 markup_head_1_item:
2747         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2748           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2749         }
2750         ;
2751
2752 markup_head_1_list:
2753         markup_head_1_item      {
2754                 $$ = scm_list_1 ($1);
2755         }
2756         | markup_head_1_list markup_head_1_item {
2757                 $$ = scm_cons ($2, $1);
2758         }
2759         ;
2760
2761 simple_markup:
2762         STRING {
2763                 $$ = make_simple_markup ($1);
2764         }
2765         | MARKUP_IDENTIFIER {
2766                 $$ = $1;
2767         }
2768         | LYRIC_MARKUP_IDENTIFIER {
2769                 $$ = $1;
2770         }
2771         | STRING_IDENTIFIER {
2772                 $$ = $1;
2773         }
2774         | SCORE {
2775                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2776                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2777         } '{' score_body '}' {
2778                 Score * sc = $4;
2779                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2780                 sc->unprotect ();
2781                 PARSER->lexer_->pop_state ();
2782         }
2783         | MARKUP_FUNCTION markup_command_basic_arguments {
2784                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2785         }
2786         ;
2787
2788 markup:
2789         markup_head_1_list simple_markup        {
2790                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2791                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2792         }
2793         | simple_markup {
2794                 $$ = $1;
2795         }
2796         ;
2797
2798 %%
2799
2800 void
2801 Lily_parser::set_yydebug (bool x)
2802 {
2803         yydebug = x;
2804 }
2805
2806 void
2807 Lily_parser::do_yyparse ()
2808 {
2809         yyparse ((void*)this);
2810 }
2811
2812
2813
2814
2815
2816 /*
2817
2818 It is a little strange to have this function in this file, but
2819 otherwise, we have to import music classes into the lexer.
2820
2821 */
2822 int
2823 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2824 {
2825         if (scm_is_string (sid)) {
2826                 *destination = sid;
2827                 return STRING_IDENTIFIER;
2828         } else if (unsmob_book (sid)) {
2829                 Book *book =  unsmob_book (sid)->clone ();
2830                 *destination = book->self_scm ();
2831                 book->unprotect ();
2832
2833                 return BOOK_IDENTIFIER;
2834         } else if (scm_is_number (sid)) {
2835                 *destination = sid;
2836                 return NUMBER_IDENTIFIER;
2837         } else if (unsmob_context_def (sid)) {
2838                 Context_def *def= unsmob_context_def (sid)->clone ();
2839
2840                 *destination = def->self_scm ();
2841                 def->unprotect ();
2842
2843                 return CONTEXT_DEF_IDENTIFIER;
2844         } else if (unsmob_context_mod (sid)) {
2845                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2846
2847                 return CONTEXT_MOD_IDENTIFIER;
2848         } else if (unsmob_score (sid)) {
2849                 Score *score = new Score (*unsmob_score (sid));
2850                 *destination = score->self_scm ();
2851
2852                 score->unprotect ();
2853                 return SCORE_IDENTIFIER;
2854         } else if (Music *mus = unsmob_music (sid)) {
2855                 mus = mus->clone ();
2856                 *destination = mus->self_scm ();
2857                 unsmob_music (*destination)->
2858                         set_property ("origin", make_input (last_input_));
2859
2860                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2861                         != SCM_BOOL_F;
2862
2863                 mus->unprotect ();
2864                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2865         } else if (unsmob_pitch (sid)) {
2866                 *destination = unsmob_pitch (sid)->smobbed_copy ();
2867                 return PITCH_IDENTIFIER;
2868         } else if (unsmob_duration (sid)) {
2869                 *destination = unsmob_duration (sid)->smobbed_copy ();
2870                 return DURATION_IDENTIFIER;
2871         } else if (unsmob_output_def (sid)) {
2872                 Output_def *p = unsmob_output_def (sid);
2873                 p = p->clone ();
2874
2875                 *destination = p->self_scm ();
2876                 p->unprotect ();
2877                 return OUTPUT_DEF_IDENTIFIER;
2878         } else if (Text_interface::is_markup (sid)) {
2879                 *destination = sid;
2880                 if (is_lyric_state ())
2881                         return LYRIC_MARKUP_IDENTIFIER;
2882                 return MARKUP_IDENTIFIER;
2883         } else if (Text_interface::is_markup_list (sid)) {
2884                 *destination = sid;
2885                 return MARKUPLIST_IDENTIFIER;
2886         }
2887
2888         return -1;
2889 }
2890
2891 SCM
2892 get_next_unique_context_id ()
2893 {
2894         return scm_from_locale_string ("$uniqueContextId");
2895 }
2896
2897
2898 SCM
2899 get_next_unique_lyrics_context_id ()
2900 {
2901         static int new_context_count;
2902         char s[128];
2903         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2904         return scm_from_locale_string (s);
2905 }
2906
2907 SCM check_scheme_arg (Lily_parser *my_lily_parser, Input loc, SCM fallback,
2908                       SCM arg, SCM args, SCM pred)
2909 {
2910         SCM unwrap = SCM_UNDEFINED;
2911         if (scm_is_true (scm_call_1 (pred, arg)))
2912                 return scm_cons (arg, args);
2913         unwrap = try_unpack_lyrics (pred, arg);
2914         if (!SCM_UNBNDP (unwrap))
2915                 return scm_cons (unwrap, args);
2916         if (SCM_UNBNDP (fallback)) {
2917                 args = scm_cons (SCM_BOOL_F, args);
2918                 fallback = SCM_BOOL_F;
2919         } else {
2920                 args = scm_cons (loc_on_music (loc, fallback), args);
2921                 fallback = SCM_CDR (scm_last_pair (args));
2922         }
2923         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
2924         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred, arg);
2925         scm_set_cdr_x (scm_last_pair (args), fallback);
2926         return args;
2927 }
2928
2929 SCM loc_on_music (Input loc, SCM arg)
2930 {
2931         if (Music *m = unsmob_music (arg))
2932         {
2933                 m = m->clone ();
2934                 m->set_spot (loc);
2935                 return m->unprotect ();
2936         }
2937         return arg;
2938 }
2939
2940 bool
2941 is_regular_identifier (SCM id)
2942 {
2943   string str = ly_scm2string (id);
2944   char const *s = str.c_str ();
2945
2946   bool v = true;
2947 #if 0
2948   isalpha (*s);
2949   s++;
2950 #endif
2951   while (*s && v)
2952    {
2953         v = v && isalnum (*s);
2954         s++;
2955    }
2956   return v;
2957 }
2958
2959 Music *
2960 make_music_with_input (SCM name, Input where)
2961 {
2962        Music *m = make_music_by_name (name);
2963        m->set_spot (where);
2964        return m;
2965 }
2966
2967 SCM
2968 get_first_context_id (SCM type, Music *m)
2969 {
2970         SCM id = m->get_property ("context-id");
2971         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2972             && scm_is_string (m->get_property ("context-id"))
2973             && scm_c_string_length (id) > 0)
2974         {
2975                 return id;
2976         }
2977         return SCM_EOL;
2978 }
2979
2980 SCM
2981 make_simple_markup (SCM a)
2982 {
2983         return a;
2984 }
2985
2986 bool
2987 is_duration (int t)
2988 {
2989   return t && t == 1 << intlog2 (t);
2990 }
2991
2992 void
2993 set_music_properties (Music *p, SCM a)
2994 {
2995   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2996         p->set_property (scm_caar (k), scm_cdar (k));
2997 }
2998
2999
3000 SCM
3001 make_chord_step (int step, Rational alter)
3002 {
3003         if (step == 7)
3004                 alter += FLAT_ALTERATION;
3005
3006         while (step < 0)
3007                 step += 7;
3008         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3009         return m.smobbed_copy ();
3010 }
3011
3012
3013 SCM
3014 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
3015 {
3016         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3017         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
3018 }
3019
3020 SCM
3021 try_unpack_lyrics (SCM pred, SCM arg)
3022 {
3023         if (Music *m = unsmob_music (arg))
3024                 if (m->is_mus_type ("lyric-event")) {
3025                         SCM text = m->get_property ("text");
3026                         if (scm_is_true (scm_call_1 (pred, text)))
3027                                         return text;
3028                         }
3029         return SCM_UNDEFINED;
3030 }
3031
3032 /* Todo: actually also use apply iso. call too ...  */
3033 bool
3034 ly_input_procedure_p (SCM x)
3035 {
3036         return ly_is_procedure (x)
3037                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
3038 }
3039
3040 int
3041 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
3042 {
3043         Lily_parser *pars = (Lily_parser*) v;
3044         Lily_lexer *lex = pars->lexer_;
3045
3046         lex->lexval_ = (void*) s;
3047         lex->lexloc_ = loc;
3048         lex->prepare_for_next_token ();
3049         return lex->yylex ();
3050 }