lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2006 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "file-path.hh"
  78 #include "input-smob.hh"
  79 #include "input.hh"
  80 #include "international.hh"
  81 #include "lily-guile.hh"
  82 #include "lily-lexer.hh"
  83 #include "lily-parser.hh"
  84 #include "lilypond-input-version.hh"
  85 #include "main.hh"
  86 #include "misc.hh"
  87 #include "music.hh"
  88 #include "music.hh"
  89 #include "output-def.hh"
  90 #include "paper-book.hh"
  91 #include "program-option.hh"
  92 #include "scm-hash.hh"
  93 #include "score.hh"
  94 #include "text-interface.hh"
  95 #include "warn.hh"
  96
  97 %}
  98
  99
 100 %union {
 101         Book *book;
 102         Output_def *outputdef;
 103         SCM scm;
 104         std::string *string;
 105         Music *music;
 106         Score *score;
 107         int i;
 108 }
 109
 110 %{
 111
 112 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 113
 114 Music *property_op_to_music (SCM op);
 115 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops, bool create_new);
 116 SCM get_next_unique_context_id ();
 117 SCM get_next_unique_lyrics_context_id ();
 118
 119 #undef _
 120 #if !HAVE_GETTEXT
 121 #define _(x) x
 122 #else
 123 #include <libintl.h>
 124 #define _(x) gettext (x)
 125 #endif
 126
 127
 128
 129 Music *make_lyric_combine_music (SCM name, Music *music);
 130 Music *make_music_relative (Pitch start, Music *music);
 131 Music *run_music_function (Lily_parser *, SCM expr);
 132 Music *set_property_music (SCM sym, SCM value);
 133 SCM get_first_context_id (SCM type, Music *m);
 134 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 135 SCM make_chord_step (int step, int alter);
 136 SCM make_simple_markup (SCM a);
 137 bool is_duration (int t);
 138 bool is_regular_identifier (SCM id);
 139 bool ly_input_procedure_p (SCM x);
 140 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 141 void set_music_properties (Music *p, SCM a);
 142
 143 %}
 144
 145 /* The third option is an alias that will be used to display the
 146    syntax error.  Bison CVS now correctly handles backslash escapes.
 147
 148    FIXME: Bison needs to translate some of these, eg, STRING.
 149
 150 */
 151
 152 /* Keyword tokens with plain escaped name.  */
 153 %token ACCEPTS "\\accepts"
 154 %token ADDLYRICS "\\addlyrics"
 155 %token ADDQUOTE "\\addquote"
 156 %token ALIAS "\\alias"
 157 %token ALTERNATIVE "\\alternative"
 158 %token BOOK "\book"
 159 %token CHANGE "\\change"
 160 %token CHORDMODE "\\chordmode"
 161 %token CHORDS "\\chords"
 162 %token CONSISTS "\\consists"
 163 %token CONTEXT "\\context"
 164 %token DEFAULT "\\default"
 165 %token DEFAULTCHILD "\\defaultchild"
 166 %token DENIES "\\denies"
 167 %token DESCRIPTION "\\description"
 168 %token DRUMMODE "\\drummode"
 169 %token DRUMS "\\drums"
 170 %token FIGUREMODE "\\figuremode"
 171 %token FIGURES "\\figures"
 172 %token GROBDESCRIPTIONS "\\grobdescriptions"
 173 %token HEADER "\\header"
 174 %token INVALID "\\invalid"
 175 %token KEY "\\key"
 176 %token LAYOUT "\\layout"
 177 %token LYRICMODE "\\lyricmode"
 178 %token LYRICS "\\lyrics"
 179 %token LYRICSTO "\\lyricsto"
 180 %token MARK "\\mark"
 181 %token MARKUP "\\markup"
 182 %token MIDI "\\midi"
 183 %token NAME "\\name"
 184 %token NOTEMODE "\\notemode"
 185 %token OBJECTID "\\objectid"
 186 %token OCTAVE "\\octave"
 187 %token ONCE "\\once"
 188 %token OVERRIDE "\\override"
 189 %token PAPER "\\paper"
 190 %token PARTIAL "\\partial"
 191 %token RELATIVE "\\relative"
 192 %token REMOVE "\\remove"
 193 %token REPEAT "\\repeat"
 194 %token REST "\\rest"
 195 %token REVERT "\\revert"
 196 %token SCORE "\\score"
 197 %token SEQUENTIAL "\\sequential"
 198 %token SET "\\set"
 199 %token SIMULTANEOUS "\\simultaneous"
 200 %token SKIP "\\skip"
 201 %token TEMPO "\\tempo"
 202 %token TIMES "\\times"
 203 %token TRANSPOSE "\\transpose"
 204 %token TRANSPOSITION "\\transposition"
 205 %token TYPE "\\type"
 206 %token UNSET "\\unset"
 207 %token WITH "\\with"
 208
 209 /* Keyword token exceptions.  */
 210 %token TIME_T "\\time"
 211 %token NEWCONTEXT "\\new"
 212
 213
 214 /* Other string tokens.  */
 215
 216 %token CHORD_BASS "/+"
 217 %token CHORD_CARET "^"
 218 %token CHORD_COLON ":"
 219 %token CHORD_MINUS "-"
 220 %token CHORD_SLASH "/"
 221 %token DOUBLE_ANGLE_CLOSE ">>"
 222 %token DOUBLE_ANGLE_OPEN "<<"
 223 %token E_BACKSLASH "\\"
 224 %token E_ANGLE_CLOSE "\\>"
 225 %token E_CHAR "\\C[haracter]"
 226 %token E_CLOSE "\\)"
 227 %token E_EXCLAMATION "\\!"
 228 %token E_BRACKET_OPEN "\\["
 229 %token E_OPEN "\\("
 230 %token E_BRACKET_CLOSE "\\]"
 231 %token E_ANGLE_OPEN "\\<"
 232 %token E_PLUS "\\+"
 233 %token E_TILDE "\\~"
 234 %token EXTENDER "__"
 235
 236 /*
 237 If we give names, Bison complains.
 238 */
 239 %token FIGURE_CLOSE /* "\\>" */
 240 %token FIGURE_OPEN /* "\\<" */
 241 %token FIGURE_SPACE "_"
 242 %token HYPHEN "--"
 243
 244 %token CHORDMODIFIERS
 245 %token LYRIC_MARKUP
 246 %token MULTI_MEASURE_REST
 247 %token SCM_T
 248
 249
 250 %token <i> DIGIT
 251 %token <i> E_UNSIGNED
 252 %token <i> UNSIGNED
 253
 254 %token <scm> BOOK_IDENTIFIER
 255 %token <scm> CHORDMODIFIER_PITCH
 256 %token <scm> CHORD_MODIFIER
 257 %token <scm> CONTEXT_DEF_IDENTIFIER
 258 %token <scm> DRUM_PITCH
 259 %token <scm> DURATION_IDENTIFIER
 260 %token <scm> EVENT_IDENTIFIER
 261 %token <scm> FRACTION
 262 %token <scm> LYRICS_STRING
 263 %token <scm> LYRIC_MARKUP_IDENTIFIER
 264 %token <scm> MARKUP_HEAD_EMPTY
 265 %token <scm> MARKUP_HEAD_LIST0
 266 %token <scm> MARKUP_HEAD_MARKUP0
 267 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 268 %token <scm> MARKUP_HEAD_SCM0
 269 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 270 %token <scm> MARKUP_HEAD_SCM0_SCM1
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 272 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 273 %token <scm> MARKUP_IDENTIFIER
 274 %token <scm> MUSIC_FUNCTION
 275 %token <scm> MUSIC_FUNCTION_MARKUP
 276 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MUSIC
 281 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 282 %token <scm> MUSIC_FUNCTION_SCM
 283 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 284 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 285 %token <scm> MUSIC_FUNCTION_SCM_SCM
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 287 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 288 %token <scm> MUSIC_IDENTIFIER
 289 %token <scm> NOTENAME_PITCH
 290 %token <scm> NUMBER_IDENTIFIER
 291 %token <scm> OUTPUT_DEF_IDENTIFIER
 292 %token <scm> REAL
 293 %token <scm> RESTNAME
 294 %token <scm> SCM_IDENTIFIER
 295 %token <scm> SCM_T
 296 %token <scm> SCORE_IDENTIFIER
 297 %token <scm> STRING
 298 %token <scm> STRING_IDENTIFIER
 299 %token <scm> TONICNAME_PITCH
 300
 301
 302 %type <book> book_block
 303 %type <book> book_body
 304
 305 %type <i> bare_unsigned
 306 %type <i> figured_bass_alteration
 307 %type <i> dots
 308 %type <i> exclamations
 309 %type <i> optional_rest
 310 %type <i> questions
 311 %type <i> script_dir
 312 %type <i> sub_quotes
 313 %type <i> sup_quotes
 314 %type <i> tremolo_type
 315
 316 %type <music> Composite_music
 317 %type <music> Grouped_music_list
 318 %type <music> Music
 319 %type <music> Prefix_composite_music
 320 %type <music> Repeated_music
 321 %type <music> Sequential_music
 322 %type <music> Simple_music
 323 %type <music> Simultaneous_music
 324 %type <music> chord_body
 325 %type <music> chord_body_element
 326 %type <music> command_element
 327 %type <music> command_event
 328 %type <music> context_change
 329 %type <music> direction_less_event
 330 %type <music> direction_reqd_event
 331 %type <music> event_chord
 332 %type <music> gen_text_def
 333 %type <music> music_property_def
 334 %type <music> note_chord_element
 335 %type <music> post_event
 336 %type <music> re_rhythmed_music
 337 %type <music> relative_music
 338 %type <music> simple_element
 339 %type <music> string_number_event
 340 %type <music> tempo_event
 341 %type <music> toplevel_music
 342
 343 %type <outputdef> output_def_body
 344 %type <outputdef> output_def_head
 345 %type <outputdef> output_def_head_with_mode_switch
 346 %type <outputdef> output_def
 347 %type <outputdef> paper_block
 348
 349 %type <scm> Alternative_music
 350 %type <scm> Generic_prefix_music_scm
 351 %type <scm> Music_list
 352 %type <scm> absolute_pitch
 353 %type <scm> assignment_id
 354 %type <scm> bare_number
 355 %type <scm> music_function_event
 356 %type <scm> music_function_chord_body
 357 %type <scm> bass_figure
 358 %type <scm> figured_bass_modification
 359 %type <scm> br_bass_figure
 360 %type <scm> bass_number
 361 %type <scm> chord_body_elements
 362 %type <scm> chord_item
 363 %type <scm> chord_items
 364 %type <scm> chord_separator
 365 %type <scm> context_def_mod
 366 %type <scm> context_def_spec_block
 367 %type <scm> context_def_spec_body
 368 %type <scm> context_mod
 369 %type <scm> context_mod_list
 370 %type <scm> context_prop_spec
 371 %type <scm> direction_less_char
 372 %type <scm> duration_length
 373 %type <scm> embedded_scm
 374 %type <scm> figure_list
 375 %type <scm> figure_spec
 376 %type <scm> fraction
 377 %type <scm> full_markup
 378 %type <scm> identifier_init
 379 %type <scm> lilypond_header
 380 %type <scm> lilypond_header_body
 381 %type <scm> lyric_element
 382 %type <scm> lyric_markup
 383 %type <scm> markup
 384 %type <scm> markup_braced_list
 385 %type <scm> markup_braced_list_body
 386 %type <scm> markup_composed_list
 387 %type <scm> markup_head_1_item
 388 %type <scm> markup_head_1_list
 389 %type <scm> markup_list
 390 %type <scm> markup_top
 391 %type <scm> mode_changing_head
 392 %type <scm> mode_changing_head_with_context
 393 %type <scm> multiplied_duration
 394 %type <scm> new_chord
 395 %type <scm> new_lyrics
 396 %type <scm> number_expression
 397 %type <scm> number_factor
 398 %type <scm> number_term
 399 %type <scm> object_id_setting
 400 %type <scm> octave_check
 401 %type <scm> optional_context_mod
 402 %type <scm> optional_id
 403 %type <scm> optional_notemode_duration
 404 %type <scm> pitch
 405 %type <scm> pitch_also_in_chords
 406 %type <scm> post_events
 407 %type <scm> property_operation
 408 %type <scm> scalar
 409 %type <scm> script_abbreviation
 410 %type <scm> simple_markup
 411 %type <scm> simple_string
 412 %type <scm> steno_duration
 413 %type <scm> steno_pitch
 414 %type <scm> steno_tonic_pitch
 415 %type <scm> step_number
 416 %type <scm> step_numbers
 417 %type <scm> string
 418 %type <scm> function_scm_argument
 419
 420 %type <score> score_block
 421 %type <score> score_body
 422
 423
 424 %left '-' '+'
 425
 426 /* We don't assign precedence to / and *, because we might need varied
 427 prec levels in different prods */
 428
 429 %left UNARY_MINUS
 430
 431 %%
 432
 433 lilypond:       /* empty */
 434         | lilypond toplevel_expression {
 435         }
 436         | lilypond assignment {
 437         }
 438         | lilypond error {
 439                 THIS->error_level_ = 1;
 440         }
 441         | lilypond INVALID      {
 442                 THIS->error_level_ = 1;
 443         }
 444         ;
 445
 446
 447 object_id_setting:
 448         OBJECTID STRING { $$ = $2; }
 449         ;
 450
 451 toplevel_expression:
 452         lilypond_header {
 453                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 454         }
 455         | book_block {
 456                 Book *book = $1;
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 459                 book->unprotect ();
 460         }
 461         | score_block {
 462                 Score *score = $1;
 463
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 466                 score->unprotect ();
 467         }
 468         | toplevel_music {
 469                 Music *music = $1;
 470                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 471                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 472                 music->unprotect ();
 473         }
 474         | full_markup {
 475                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 476                 scm_call_2 (proc, THIS->self_scm (), $1);
 477         }
 478         | output_def {
 479                 SCM id = SCM_EOL;
 480                 Output_def * od = $1;
 481
 482                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 483                         id = ly_symbol2scm ("$defaultpaper");
 484                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 485                         id = ly_symbol2scm ("$defaultmidi");
 486                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 487                         id = ly_symbol2scm ("$defaultlayout");
 488
 489                 THIS->lexer_->set_identifier (id, od->self_scm ());
 490                 od->unprotect();
 491         }
 492         ;
 493
 494 toplevel_music:
 495         Composite_music {
 496         }
 497         ;
 498
 499 embedded_scm:
 500         SCM_T
 501         | SCM_IDENTIFIER
 502         ;
 503
 504
 505 lilypond_header_body:
 506         {
 507                 $$ = get_header(THIS);
 508                 THIS->lexer_->add_scope ($$);
 509         }
 510         | lilypond_header_body assignment  {
 511
 512         }
 513         ;
 514
 515 lilypond_header:
 516         HEADER '{' lilypond_header_body '}'     {
 517                 $$ = THIS->lexer_->remove_scope ();
 518         }
 519         ;
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment_id:
 525         STRING          { $$ = $1; }
 526         | LYRICS_STRING { $$ = $1; }
 527         ;
 528
 529 assignment:
 530         assignment_id '=' identifier_init  {
 531                 if (! is_regular_identifier ($1))
 532                 {
 533 #if 0
 534                         /* no longer valid with dashes in \paper{} block. */
 535                         @1.warning (_ ("identifier should have alphabetic characters only"));
 536 #endif
 537                 }
 538
 539
 540                 THIS->lexer_->set_identifier ($1, $3);
 541
 542 /*
 543  TODO: devise standard for protection in parser.
 544
 545   The parser stack lives on the C-stack, which means that
 546 all objects can be unprotected as soon as they're here.
 547
 548 */
 549         }
 550         | embedded_scm { }
 551         ;
 552
 553
 554 identifier_init:
 555         score_block {
 556                 $$ = $1->self_scm ();
 557                 $1->unprotect ();
 558         }
 559         | book_block {
 560                 $$ = $1->self_scm ();
 561                 $1->unprotect ();
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 $1->unprotect ();
 566         }
 567         | context_def_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 $1->unprotect();
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 $1->unprotect();
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm {
 585                 $$ = $1;
 586         }
 587         | full_markup {
 588                 $$ = $1;
 589         }
 590         | DIGIT {
 591                 $$ = scm_from_int ($1);
 592         }
 593         ;
 594
 595 context_def_spec_block:
 596         CONTEXT '{' context_def_spec_body '}'
 597                 {
 598                 $$ = $3;
 599         }
 600         ;
 601
 602 context_def_spec_body:
 603         /**/ {
 604                 $$ = Context_def::make_scm ();
 605                 unsmob_context_def ($$)->set_spot (@$);
 606         }
 607         | CONTEXT_DEF_IDENTIFIER {
 608                 $$ = $1;
 609                 unsmob_context_def ($$)->set_spot (@$);
 610         }
 611         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 612                 Context_def*td = unsmob_context_def ($$);
 613
 614                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 615                         SCM tag = scm_caar (p);
 616
 617                         /* TODO: should make new tag "grob-definition" ? */
 618                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 619                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 620                 }
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         ;
 626
 627
 628
 629 book_block:
 630         BOOK '{' book_body '}'  {
 631                 $$ = $3;
 632         }
 633         ;
 634
 635 /* FIXME:
 636    * Use 'handlers' like for toplevel-* stuff?
 637    * grok \layout and \midi?  */
 638 book_body:
 639         {
 640                 $$ = new Book;
 641                 $$->set_spot (@$);
 642                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 643                 $$->paper_->unprotect ();
 644                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 645         }
 646         | BOOK_IDENTIFIER {
 647                 $$ = unsmob_book ($1);
 648                 $$->set_spot (@$);
 649         }
 650         | book_body paper_block {
 651                 $$->paper_ = $2;
 652                 $2->unprotect ();
 653         }
 654         | book_body score_block {
 655                 SCM s = $2->self_scm ();
 656                 $$->add_score (s);
 657                 $2->unprotect();
 658         }
 659         | book_body full_markup {
 660                 $$->add_score ($2);
 661         }
 662         | book_body lilypond_header {
 663                 $$->header_ = $2;
 664         }
 665         | book_body error {
 666                 $$->paper_ = 0;
 667                 $$->scores_ = SCM_EOL;
 668         }
 669         | book_body object_id_setting {
 670                 $$->user_key_ = ly_scm2string ($2);
 671         }
 672         ;
 673
 674 score_block:
 675         SCORE '{' score_body '}'        {
 676                 $$ = $3;
 677         }
 678         ;
 679
 680 score_body:
 681         Music {
 682                 SCM m = $1->self_scm ();
 683                 $1->unprotect();
 684                 SCM scorify = ly_lily_module_constant ("scorify-music");
 685                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 686
 687                 // pass ownernship to C++ again.
 688                 $$ = unsmob_score (score);
 689                 $$->protect ();
 690                 $$->set_spot (@$);
 691         }
 692         | SCORE_IDENTIFIER {
 693                 $$ = unsmob_score ($1);
 694                 $$->set_spot (@$);
 695         }
 696         | score_body object_id_setting {
 697                 $$->user_key_ = ly_scm2string ($2);
 698         }
 699         | score_body lilypond_header    {
 700                 $$->header_ = $2;
 701         }
 702         | score_body output_def {
 703                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 704                 {
 705                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 706
 707                 }
 708                 else
 709                 {
 710                         $$->add_output_def ($2);
 711                 }
 712                 $2->unprotect ();
 713         }
 714         | score_body error {
 715                 $$->error_found_ = true;
 716         }
 717         ;
 718
 719
 720 /*
 721         OUTPUT DEF
 722 */
 723
 724 paper_block:
 725         output_def {
 726                 $$ = $1;
 727                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 728                 {
 729                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 730                         $$ = get_paper (THIS);
 731                 }
 732         }
 733         ;
 734
 735
 736 output_def:
 737         output_def_body '}' {
 738                 $$ = $1;
 739
 740                 THIS->lexer_->remove_scope ();
 741                 THIS->lexer_->pop_state ();
 742         }
 743         ;
 744
 745 output_def_head:
 746         PAPER {
 747                 $$ = get_paper (THIS);
 748                 $$->input_origin_ = @$;
 749                 THIS->lexer_->add_scope ($$->scope_);
 750         }
 751         | MIDI    {
 752                 Output_def *p = get_midi (THIS);
 753                 $$ = p;
 754                 THIS->lexer_->add_scope (p->scope_);
 755         }
 756         | LAYOUT        {
 757                 Output_def *p = get_layout (THIS);
 758
 759                 THIS->lexer_->add_scope (p->scope_);
 760                 $$ = p;
 761         }
 762         ;
 763
 764 output_def_head_with_mode_switch:
 765         output_def_head {
 766                 THIS->lexer_->push_initial_state ();
 767                 $$ = $1;
 768         }
 769         ;
 770
 771 output_def_body:
 772         output_def_head_with_mode_switch '{' {
 773                 $$ = $1;
 774                 $$->input_origin_.set_spot (@$);
 775         }
 776         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 777                 $1->unprotect ();
 778                 Output_def *o = unsmob_output_def ($3);
 779                 o->input_origin_.set_spot (@$);
 780                 $$ = o;
 781                 THIS->lexer_->remove_scope ();
 782                 THIS->lexer_->add_scope (o->scope_);
 783         }
 784         | output_def_body assignment  {
 785
 786         }
 787         | output_def_body context_def_spec_block        {
 788                 assign_context_def ($$, $2);
 789         }
 790         | output_def_body tempo_event  {
 791                 /*
 792                         junk this ? there already is tempo stuff in
 793                         music.
 794                 */
 795                 int m = scm_to_int ($2->get_property ("metronome-count"));
 796                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 797                 set_tempo ($$, d->get_length (), m);
 798                 $2->unprotect ();
 799         }
 800         | output_def_body error {
 801
 802         }
 803         ;
 804
 805 tempo_event:
 806         TEMPO steno_duration '=' bare_unsigned  {
 807                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 808                 $$->set_property ("tempo-unit", $2);
 809                 $$->set_property ("metronome-count", scm_from_int ( $4));
 810         }
 811         ;
 812
 813 /*
 814 The representation of a  list is the
 815
 816   (LIST . LAST-CONS)
 817
 818  to have efficient append.  */
 819
 820 Music_list:
 821         /* empty */ {
 822                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 823         }
 824         | Music_list Music {
 825                 SCM s = $$;
 826                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 827                 $2->unprotect (); /* UGH */
 828
 829                 if (scm_is_pair (scm_cdr (s)))
 830                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 831                 else
 832                         scm_set_car_x (s, c); /* set first cons */
 833                 scm_set_cdr_x (s, c);  /* remember last cell */
 834         }
 835         | Music_list embedded_scm {
 836
 837         }
 838         | Music_list error {
 839                 Music * m = MY_MAKE_MUSIC("Music");
 840                 // ugh. code dup
 841                 m->set_property ("error-found", SCM_BOOL_T);
 842                 SCM s = $$;
 843                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 844                 m->unprotect (); /* UGH */
 845
 846                 if (scm_is_pair (scm_cdr (s)))
 847                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 848                 else
 849                         scm_set_car_x (s, c); /* set first cons */
 850                 scm_set_cdr_x (s, c);  /* remember last cell */
 851         }
 852         ;
 853
 854 Music:
 855         Simple_music
 856         | Composite_music
 857         ;
 858
 859 Alternative_music:
 860         /* empty */ {
 861                 $$ = SCM_EOL;
 862         }
 863         | ALTERNATIVE '{' Music_list '}' {
 864                 $$ = $3;
 865         }
 866         ;
 867
 868
 869 Repeated_music:
 870         REPEAT simple_string bare_unsigned Music Alternative_music
 871         {
 872                 /*TODO: move to Scheme.*/
 873                 Music *beg = $4;
 874                 int times = $3;
 875                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 876                 if (times < scm_ilength (alts)) {
 877                   unsmob_music (scm_car (alts))
 878                     ->origin ()->warning (
 879                     _ ("more alternatives than repeats"));
 880                     warning ("junking excess alternatives");
 881                   alts = ly_truncate_list (times, alts);
 882                 }
 883
 884
 885                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 886
 887                 SCM mus = scm_call_1 (proc, $2);
 888                 Music *r = unsmob_music (mus);
 889                 r->protect ();
 890                 if (beg)
 891                         {
 892                         r-> set_property ("element", beg->self_scm ());
 893                         beg->unprotect ();
 894                         }
 895                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
 896
 897                 r-> set_property ("elements",alts);
 898                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
 899                         /*
 900                         TODO: move this code to Scheme.
 901                         */
 902
 903                         /* we cannot get durations and other stuff
 904                            correct down the line,
 905                            so we have to add to the duration log here. */
 906                         SCM func = ly_lily_module_constant ("shift-duration-log");
 907
 908                         int dots = ($3 % 3) ? 0 : 1;
 909                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 910
 911
 912                         if ($4->is_mus_type ("sequential-music"))
 913                         {
 914                                 int list_len = scm_ilength ($4->get_property ("elements"));
 915                                 if (list_len != 2)
 916                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
 917                                 shift -= 1;
 918                                 r->compress (Moment (Rational (1, list_len)));
 919                         }
 920                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
 921
 922                 }
 923                 r->set_spot (*$4->origin ());
 924
 925                 $$ = r;
 926         }
 927         ;
 928
 929 Sequential_music:
 930         SEQUENTIAL '{' Music_list '}'           {
 931                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 932                 $$->set_property ("elements", scm_car ($3));
 933                 $$->set_spot (@$);
 934         }
 935         | '{' Music_list '}'            {
 936                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 937                 $$->set_property ("elements", scm_car ($2));
 938                 $$->set_spot (@$);
 939         }
 940         ;
 941
 942 Simultaneous_music:
 943         SIMULTANEOUS '{' Music_list '}'{
 944                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 945                 $$->set_property ("elements", scm_car ($3));
 946                 $$->set_spot (@$);
 947
 948         }
 949         | simul_open Music_list simul_close     {
 950                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 951                 $$->set_property ("elements", scm_car ($2));
 952                 $$->set_spot (@$);
 953         }
 954         ;
 955
 956 Simple_music:
 957         event_chord             { $$ = $1; }
 958         | MUSIC_IDENTIFIER {
 959                 $$ = unsmob_music ($1);
 960         }
 961         | music_property_def
 962         | context_change
 963         ;
 964
 965 optional_context_mod:
 966         /**/ { $$ = SCM_EOL; }
 967         | WITH { THIS->lexer_->push_initial_state (); }
 968         '{' context_mod_list '}'
 969         {
 970                 THIS->lexer_->pop_state ();
 971                 $$ = $4;
 972         }
 973         ;
 974
 975 context_mod_list:
 976         /* */  { $$ = SCM_EOL; }
 977         | context_mod_list context_mod  {
 978                  $$ = scm_cons ($2, $1);
 979         }
 980         ;
 981
 982 Composite_music:
 983         Prefix_composite_music { $$ = $1; }
 984         | Grouped_music_list { $$ = $1; }
 985         ;
 986
 987 Grouped_music_list:
 988         Simultaneous_music              { $$ = $1; }
 989         | Sequential_music              { $$ = $1; }
 990         ;
 991
 992 function_scm_argument:
 993         embedded_scm
 994         | simple_string
 995         ;
 996
 997 Generic_prefix_music_scm:
 998         MUSIC_FUNCTION {
 999                 $$ = scm_list_2 ($1, make_input (@$));
1000         }
1001         | MUSIC_FUNCTION_SCM function_scm_argument {
1002                 $$ = scm_list_3 ($1, make_input (@$), $2);
1003         }
1004         | MUSIC_FUNCTION_MARKUP full_markup {
1005                 $$ = scm_list_3 ($1, make_input (@$), $2);
1006         }
1007
1008         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument Music {
1009                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1010                 $3->unprotect ();
1011         }
1012         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
1013                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1014         }
1015         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
1016                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1017         }
1018         | MUSIC_FUNCTION_MUSIC Music {
1019                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1020                 $2->unprotect ();
1021         }
1022         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument Music {
1023                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1024         }
1025         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1026                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1027                 $3->unprotect ();
1028         }
1029         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1030                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1031         }
1032         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1033                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1034                 $2->unprotect ();
1035                 $3->unprotect ();
1036         }
1037         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
1038                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1039                 $4->unprotect ();
1040                 $3->unprotect ();
1041         }
1042         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1043                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1044                 $3->unprotect ();
1045                 $4->unprotect ();
1046         }
1047         ;
1048
1049 optional_id:
1050         /**/ { $$ = SCM_EOL; }
1051         | '=' simple_string {
1052                 $$ = $2;
1053         }
1054         ;
1055
1056
1057 Prefix_composite_music:
1058         Generic_prefix_music_scm {
1059                 $$ = run_music_function (THIS, $1);
1060         }
1061         | CONTEXT    simple_string optional_id optional_context_mod Music {
1062                 $$ = context_spec_music ($2, $3, $5, $4, false);
1063         }
1064         | NEWCONTEXT simple_string optional_id optional_context_mod Music {
1065                 $$ = context_spec_music ($2, $3, $5, $4, true);
1066         }
1067
1068         | TIMES fraction Music
1069         {
1070                 int n = scm_to_int (scm_car ($2));
1071                 int d = scm_to_int (scm_cdr ($2));
1072                 Music *mp = $3;
1073
1074                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1075                 $$->set_spot (@$);
1076
1077                 $$->set_property ("element", mp->self_scm ());
1078                 mp->unprotect();
1079                 $$->set_property ("numerator", scm_from_int (n));
1080                 $$->set_property ("denominator", scm_from_int (d));
1081                 $$->compress (Moment (Rational (n,d)));
1082
1083         }
1084         | Repeated_music                { $$ = $1; }
1085         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1086                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1087                 Music *p = $4;
1088                 Pitch from = *unsmob_pitch ($2);
1089                 Pitch to = *unsmob_pitch ($3);
1090
1091                 p->transpose (pitch_interval (from, to));
1092                 $$->set_property ("element", p->self_scm ());
1093                 p->unprotect();
1094         }
1095         | mode_changing_head Grouped_music_list {
1096                 if ($1 == ly_symbol2scm ("chords"))
1097                 {
1098                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1099                   chm->set_property ("element", $2->self_scm ());
1100                   $$ = chm;
1101                   $2->unprotect();
1102                 }
1103                 else
1104                 {
1105                   $$ = $2;
1106                 }
1107                 THIS->lexer_->pop_state ();
1108         }
1109         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1110                 $$ = context_spec_music ($1, SCM_UNDEFINED, $3, $2, true);
1111                 if ($1 == ly_symbol2scm ("ChordNames"))
1112                 {
1113                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1114                   chm->set_property ("element", $$->self_scm ());
1115                   $$->unprotect();
1116                   $$ = chm;
1117                 }
1118                 THIS->lexer_->pop_state ();
1119         }
1120         | relative_music        { $$ = $1; }
1121         | re_rhythmed_music     { $$ = $1; }
1122         ;
1123
1124 mode_changing_head:
1125         NOTEMODE {
1126                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1127                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1128
1129                 $$ = ly_symbol2scm ("notes");
1130         }
1131         | DRUMMODE
1132                 {
1133                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1134                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1135
1136                 $$ = ly_symbol2scm ("drums");
1137         }
1138         | FIGUREMODE {
1139                 THIS->lexer_->push_figuredbass_state ();
1140
1141                 $$ = ly_symbol2scm ("figures");
1142         }
1143         | CHORDMODE {
1144                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1145                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1146                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1147                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1148                 $$ = ly_symbol2scm ("chords");
1149
1150         }
1151         | LYRICMODE
1152                 { THIS->lexer_->push_lyric_state ();
1153                 $$ = ly_symbol2scm ("lyrics");
1154         }
1155         ;
1156
1157 mode_changing_head_with_context:
1158         DRUMS {
1159                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1160                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1161
1162                 $$ = ly_symbol2scm ("DrumStaff");
1163         }
1164         | FIGURES {
1165                 THIS->lexer_->push_figuredbass_state ();
1166
1167                 $$ = ly_symbol2scm ("FiguredBass");
1168         }
1169         | CHORDS {
1170                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1171                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1172                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1173                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1174                 $$ = ly_symbol2scm ("ChordNames");
1175         }
1176         | LYRICS
1177                 { THIS->lexer_->push_lyric_state ();
1178                 $$ = ly_symbol2scm ("Lyrics");
1179         }
1180         ;
1181
1182
1183 relative_music:
1184         RELATIVE absolute_pitch Music {
1185                 Music *m = $3;
1186                 Pitch start = *unsmob_pitch ($2);
1187                 $$ = make_music_relative (start, m);
1188                 m->unprotect();
1189         }
1190         | RELATIVE Composite_music {
1191                 Music *m = $2;
1192
1193                 Pitch middle_c (0, 0, 0);
1194                 $$ = make_music_relative (middle_c, m);
1195                 m->unprotect();
1196         }
1197         ;
1198
1199 new_lyrics:
1200         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1201         /*cont */
1202         Grouped_music_list {
1203         /* Can also use Music at the expensive of two S/Rs similar to
1204            \repeat \alternative */
1205                 THIS->lexer_->pop_state ();
1206
1207                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1208         }
1209         | new_lyrics ADDLYRICS {
1210                 THIS->lexer_->push_lyric_state ();
1211         } Grouped_music_list {
1212                 THIS->lexer_->pop_state ();
1213                 $$ = scm_cons ($4->self_scm (), $1);
1214         }
1215         ;
1216
1217 re_rhythmed_music:
1218         Grouped_music_list new_lyrics {
1219                 Music * voice = $1;
1220                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1221                 if (!scm_is_string (name))
1222                 {
1223                         name = get_next_unique_lyrics_context_id ();
1224                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1225                                                     name,
1226                                                     voice, SCM_EOL, false);
1227                 }
1228
1229                 SCM context = scm_makfrom0str ("Lyrics");
1230                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1231
1232                 SCM lst = SCM_EOL;
1233                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1234                 {
1235                         Music *music = unsmob_music (scm_car (s));
1236                         Music *com = make_lyric_combine_music (name, music);
1237                         Music *csm = context_spec_music (context,
1238                                 SCM_UNDEFINED, com, SCM_EOL, true);
1239                         lst = scm_cons (csm->self_scm (), lst);
1240                 }
1241                 all->set_property ("elements", scm_cons (voice->self_scm (),
1242                         lst));
1243                 $$ = all;
1244                 voice->unprotect ();
1245         }
1246         | LYRICSTO simple_string {
1247                 THIS->lexer_->push_lyric_state ();
1248         } Music {
1249                 THIS->lexer_->pop_state ();
1250                 Music *music = $4;
1251                 SCM name = $2;
1252                 $$ = make_lyric_combine_music (name, music);
1253                 music->unprotect();
1254         }
1255         ;
1256
1257 context_change:
1258         CHANGE STRING '=' STRING  {
1259                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1260                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1261                 t-> set_property ("change-to-id", $4);
1262
1263                 $$ = t;
1264                 $$->set_spot (@$);
1265         }
1266         ;
1267
1268 property_operation:
1269         STRING '=' scalar {
1270                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1271                         scm_string_to_symbol ($1), $3);
1272         }
1273         | UNSET simple_string {
1274                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1275                         scm_string_to_symbol ($2));
1276         }
1277         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1278                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1279                         scm_string_to_symbol ($2), $5, $3);
1280         }
1281         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1282                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1283                                 scm_string_to_symbol ($2), $6, $4, $3);
1284         }
1285         | REVERT simple_string embedded_scm {
1286                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1287                         scm_string_to_symbol ($2), $3);
1288         }
1289         ;
1290
1291 context_def_mod:
1292         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1293         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1294
1295         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1296         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1297         | DENIES { $$ = ly_symbol2scm ("denies"); }
1298
1299         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1300         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1301         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1302         | NAME { $$ = ly_symbol2scm ("context-name"); }
1303         ;
1304
1305 context_mod:
1306         property_operation { $$ = $1; }
1307         | context_def_mod STRING {
1308                 $$ = scm_list_2 ($1, $2);
1309         }
1310         ;
1311
1312 context_prop_spec:
1313         simple_string {
1314                 if (!is_regular_identifier ($1))
1315                 {
1316                         @$.error (_("Grob name should be alphanumeric"));
1317                 }
1318
1319                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1320                         scm_string_to_symbol ($1));
1321         }
1322         | simple_string '.' simple_string {
1323                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1324                         scm_string_to_symbol ($3));
1325         }
1326         ;
1327
1328 music_property_def:
1329         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1330                 $$ = property_op_to_music (scm_list_4 (
1331                         ly_symbol2scm ("push"),
1332                         scm_cadr ($2),
1333                         $5, $3));
1334                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1335         }
1336         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1337                 $$ = property_op_to_music (scm_list_5 (
1338                         ly_symbol2scm ("push"),
1339                         scm_cadr ($2),
1340                         $6, $4, $3));
1341                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1342         }
1343         | REVERT context_prop_spec embedded_scm {
1344                 $$ = property_op_to_music (scm_list_3 (
1345                         ly_symbol2scm ("pop"),
1346                         scm_cadr ($2),
1347                         $3));
1348
1349                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1350         }
1351         | SET context_prop_spec '=' scalar {
1352                 $$ = property_op_to_music (scm_list_3 (
1353                         ly_symbol2scm ("assign"),
1354                         scm_cadr ($2),
1355                         $4));
1356                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1357         }
1358         | UNSET context_prop_spec {
1359                 $$ = property_op_to_music (scm_list_2 (
1360                         ly_symbol2scm ("unset"),
1361                         scm_cadr ($2)));
1362                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL, false);
1363         }
1364         | ONCE music_property_def {
1365                 SCM e = $2->get_property ("element");
1366                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1367                 $$ = $2;
1368
1369         }
1370         ;
1371
1372
1373 string:
1374         STRING {
1375                 $$ = $1;
1376         }
1377         | STRING_IDENTIFIER {
1378                 $$ = $1;
1379         }
1380         | string '+' string {
1381                 $$ = scm_string_append (scm_list_2 ($1, $3));
1382         }
1383         ;
1384
1385 simple_string: STRING {
1386                 $$ = $1;
1387         }
1388         | LYRICS_STRING {
1389                 $$ = $1;
1390         }
1391         | STRING_IDENTIFIER {
1392                 $$ = $1;
1393         }
1394         ;
1395
1396 scalar: string {
1397                 $$ = $1;
1398         }
1399         | LYRICS_STRING {
1400                 $$ = $1;
1401         }
1402         | bare_number {
1403                 $$ = $1;
1404         }
1405         | embedded_scm {
1406                 $$ = $1;
1407         }
1408         | full_markup {
1409                 $$ = $1;
1410         }
1411         | DIGIT {
1412                 $$ = scm_from_int ($1);
1413         }
1414         ;
1415
1416 /*
1417
1418 pre_events doesn't contain anything. It is a trick:
1419
1420 Adding pre_events to the simple_element
1421 makes the choice between
1422
1423   string:  STRING
1424
1425 and
1426
1427   simple_element: STRING
1428
1429 a single shift/reduction conflict.
1430
1431 nevertheless, this is not very clean, and we should find a different
1432 solution.
1433
1434 */
1435 pre_events: /* empty */
1436         ;
1437
1438 event_chord:
1439         pre_events simple_element post_events   {
1440                 SCM elts = $2-> get_property ("elements");
1441
1442                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1443
1444                 $2->set_property ("elements", elts);
1445                 /* why is this giving wrong start location? -ns
1446                  * $2->set_spot (@$); */
1447                 Input i;
1448                 i.set_location (@2, @3);
1449                 $2->set_spot (i);
1450                 $$ = $2;
1451         }
1452         | command_element
1453         | note_chord_element
1454         ;
1455
1456
1457 note_chord_element:
1458         chord_body optional_notemode_duration post_events
1459         {
1460                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1461                 SCM es = $1->get_property ("elements");
1462                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1463
1464                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1465                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1466                 es = ly_append2 (es, postevs);
1467
1468                 $1-> set_property ("elements", es);
1469                 $1->set_spot (@$);
1470                 $$ = $1;
1471         }
1472         ;
1473
1474 chord_open: '<'
1475         ;
1476
1477 chord_close: '>'
1478         ;
1479
1480 simul_open: DOUBLE_ANGLE_OPEN
1481         ;
1482
1483 simul_close: DOUBLE_ANGLE_CLOSE
1484         ;
1485
1486 chord_body:
1487         chord_open chord_body_elements chord_close
1488         {
1489                 $$ = MY_MAKE_MUSIC ("EventChord");
1490                 $$->set_spot (@$);
1491                 $$->set_property ("elements",
1492                         scm_reverse_x ($2, SCM_EOL));
1493         }
1494         ;
1495
1496 chord_body_elements:
1497         /* empty */             { $$ = SCM_EOL; }
1498         | chord_body_elements chord_body_element {
1499                 $$ = scm_cons ($2->self_scm (), $1);
1500                 $2->unprotect ();
1501         }
1502         ;
1503
1504 chord_body_element:
1505         pitch exclamations questions octave_check post_events
1506         {
1507                 int q = $3;
1508                 int ex = $2;
1509                 SCM check = $4;
1510                 SCM post = $5;
1511
1512                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1513                 n->set_property ("pitch", $1);
1514                 n->set_spot (@$);
1515                 if (q % 2)
1516                         n->set_property ("cautionary", SCM_BOOL_T);
1517                 if (ex % 2 || q % 2)
1518                         n->set_property ("force-accidental", SCM_BOOL_T);
1519
1520                 if (scm_is_pair (post)) {
1521                         SCM arts = scm_reverse_x (post, SCM_EOL);
1522                         n->set_property ("articulations", arts);
1523                 }
1524                 if (scm_is_number (check))
1525                 {
1526                         int q = scm_to_int (check);
1527                         n->set_property ("absolute-octave", scm_from_int (q-1));
1528                 }
1529
1530
1531                 $$ = n;
1532         }
1533         | DRUM_PITCH post_events {
1534                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1535                 n->set_property ("duration", $2);
1536                 n->set_property ("drum-type", $1);
1537                 n->set_spot (@$);
1538
1539                 if (scm_is_pair ($2)) {
1540                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1541                         n->set_property ("articulations", arts);
1542                 }
1543                 $$ = n;
1544         }
1545         | music_function_chord_body {
1546                 $$ = run_music_function (THIS, $1);
1547                 $$->set_spot (@$);
1548         }
1549         ;
1550
1551 music_function_chord_body:
1552         MUSIC_FUNCTION {
1553                 $$ = scm_list_2 ($1, make_input (@$));
1554         }
1555         | MUSIC_FUNCTION_MUSIC chord_body_element {
1556                 $$ = scm_list_3 ($1, make_input (@$),
1557                                         $2->self_scm ());
1558         }
1559         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument chord_body_element {
1560                 $$ = scm_list_4 ($1, make_input (@$),
1561                                         $2, $3->self_scm ());
1562         }
1563         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument
1564                 chord_body_element {
1565
1566                 $$ = scm_list_5 ($1, make_input (@$),
1567                                         $2, $3, $4->self_scm ());
1568         }
1569         ;
1570
1571
1572 command_element:
1573         command_event {
1574                 $$ = MY_MAKE_MUSIC ("EventChord");
1575                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1576                 $1->unprotect();
1577
1578                 $$-> set_spot (@$);
1579                 $1-> set_spot (@$);
1580         }
1581         | SKIP duration_length {
1582                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1583                 skip->set_property ("duration", $2);
1584                 skip->set_spot (@$);
1585                 $$ = skip;
1586         }
1587         | E_BRACKET_OPEN {
1588                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1589                 m->set_property ("span-direction", scm_from_int (START));
1590                 m->set_spot (@$);
1591
1592                 $$ = MY_MAKE_MUSIC ("EventChord");
1593                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1594                 m->unprotect();
1595                 $$->set_spot (@$);
1596         }
1597         | E_BRACKET_CLOSE {
1598                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1599                 m->set_property ("span-direction", scm_from_int (STOP));
1600                 m->set_spot (@$);
1601
1602                 $$ = MY_MAKE_MUSIC ("EventChord");
1603                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1604                 $$->set_spot (@$);
1605                 m->unprotect ();
1606         }
1607         | E_BACKSLASH {
1608                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1609                 $$->set_spot (@$);
1610         }
1611         | '|'      {
1612                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1613
1614                 if (Music * m = unsmob_music (pipe))
1615                         $$ = m->clone ();
1616                 else
1617                         $$ = MY_MAKE_MUSIC ("BarCheck");
1618
1619                 $$->set_spot (@$);
1620         }
1621         | TRANSPOSITION pitch {
1622                 Pitch middle_c;
1623                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1624                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1625                                          sounds_as_c.smobbed_copy());
1626                 $$->set_spot (@$);
1627                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1628                         $$, SCM_EOL, false);
1629         }
1630         | PARTIAL duration_length       {
1631                 Moment m = - unsmob_duration ($2)->get_length ();
1632                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1633                 p->set_spot (@$);
1634                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1635                                         p, SCM_EOL, false);
1636                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1637                                         p, SCM_EOL, false);
1638                 $$ = p;
1639         }
1640
1641         | TIME_T fraction  {
1642                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1643
1644                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1645                 $$ = unsmob_music (result);
1646                 $$->protect ();
1647         }
1648         | MARK scalar {
1649                 SCM proc = ly_lily_module_constant ("make-mark-set");
1650
1651                 SCM result = scm_call_1 (proc, $2);
1652                 $$ = unsmob_music (result);
1653                 $$->protect ();
1654         }
1655         ;
1656
1657 command_event:
1658         E_TILDE {
1659                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1660         }
1661         | MARK DEFAULT  {
1662                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1663                 $$ = m;
1664         }
1665         | tempo_event {
1666                 $$ = $1;
1667         }
1668         | KEY DEFAULT {
1669                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1670                 $$ = key;
1671         }
1672         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1673
1674                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1675                 if (scm_ilength ($3) > 0)
1676                 {
1677                         key->set_property ("pitch-alist", $3);
1678                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1679                         key->transpose (* unsmob_pitch ($2));
1680                 } else {
1681                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1682                 }
1683
1684                 $$ = key;
1685         }
1686         ;
1687
1688
1689 post_events:
1690         /* empty */ {
1691                 $$ = SCM_EOL;
1692         }
1693         | post_events post_event {
1694                 $2->set_spot (@2);
1695                 $$ = scm_cons ($2->self_scm (), $$);
1696                 $2->unprotect ();
1697         }
1698         ;
1699
1700 music_function_event:
1701         MUSIC_FUNCTION_MUSIC post_event {
1702                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1703         }
1704         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument post_event {
1705                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1706         }
1707         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument post_event {
1708                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1709         }
1710         ;
1711
1712
1713 post_event:
1714         direction_less_event {
1715                 $$ = $1;
1716         }
1717         | '-' music_function_event {
1718                 Music *mus = run_music_function (THIS, $2);
1719                 mus->set_spot (@1);
1720                 $$ = mus;
1721         }
1722         | HYPHEN {
1723                 if (!THIS->lexer_->is_lyric_state ())
1724                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1725                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1726         }
1727         | EXTENDER {
1728                 if (!THIS->lexer_->is_lyric_state ())
1729                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1730                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1731         }
1732         | script_dir direction_reqd_event {
1733                 if ($1)
1734                         $2->set_property ("direction", scm_from_int ($1));
1735                 $$ = $2;
1736         }
1737         | script_dir direction_less_event {
1738                 if ($1)
1739                         $2->set_property ("direction", scm_from_int ($1));
1740                 $$ = $2;
1741         }
1742         | string_number_event
1743         ;
1744
1745 string_number_event:
1746         E_UNSIGNED {
1747                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1748                 s->set_property ("string-number", scm_from_int ($1));
1749                 s->set_spot (@$);
1750                 $$ = s;
1751         }
1752         ;
1753
1754 direction_less_char:
1755         '['  {
1756                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1757         }
1758         | ']'  {
1759                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1760         }
1761         | '~'  {
1762                 $$ = ly_symbol2scm ("tildeSymbol");
1763         }
1764         | '('  {
1765                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1766         }
1767         | ')'  {
1768                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1769         }
1770         | E_EXCLAMATION  {
1771                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1772         }
1773         | E_OPEN  {
1774                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1775         }
1776         | E_CLOSE  {
1777                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1778         }
1779         | E_ANGLE_CLOSE  {
1780                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1781         }
1782         | E_ANGLE_OPEN  {
1783                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1784         }
1785         ;
1786
1787 direction_less_event:
1788         direction_less_char {
1789                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1790                 Music * m = 0;
1791                 if (unsmob_music (predefd))
1792                 {
1793                         m = unsmob_music (predefd)->clone ();
1794                 }
1795                 else
1796                 {
1797                         m = MY_MAKE_MUSIC ("Music");
1798                 }
1799                 m->set_spot (@$);
1800                 $$ = m;
1801         }
1802         | EVENT_IDENTIFIER      {
1803                 $$ = unsmob_music ($1);
1804         }
1805         | tremolo_type  {
1806                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1807                a->set_spot (@$);
1808                a->set_property ("tremolo-type", scm_from_int ($1));
1809                $$ = a;
1810         }
1811         ;
1812
1813 direction_reqd_event:
1814         gen_text_def {
1815                 $$ = $1;
1816         }
1817         | script_abbreviation {
1818                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1819                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1820                 if (scm_is_string (s))
1821                         a->set_property ("articulation-type", s);
1822                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1823                 $$ = a;
1824         }
1825         ;
1826
1827 octave_check:
1828         /**/ { $$ = SCM_EOL; }
1829         | '='  { $$ = scm_from_int (0); }
1830         | '=' sub_quotes { $$ = scm_from_int ($2); }
1831         | '=' sup_quotes { $$ = scm_from_int ($2); }
1832         ;
1833
1834 sup_quotes:
1835         '\'' {
1836                 $$ = 1;
1837         }
1838         | sup_quotes '\'' {
1839                 $$ ++;
1840         }
1841         ;
1842
1843 sub_quotes:
1844         ',' {
1845                 $$ = 1;
1846         }
1847         | sub_quotes ',' {
1848                 $$++;
1849         }
1850         ;
1851
1852 steno_pitch:
1853         NOTENAME_PITCH  {
1854                 $$ = $1;
1855         }
1856         | NOTENAME_PITCH sup_quotes     {
1857                 Pitch p = *unsmob_pitch ($1);
1858                 p = p.transposed (Pitch ($2,0,0));
1859                 $$ = p.smobbed_copy ();
1860         }
1861         | NOTENAME_PITCH sub_quotes      {
1862                 Pitch p =* unsmob_pitch ($1);
1863                 p = p.transposed (Pitch (-$2,0,0));
1864                 $$ = p.smobbed_copy ();
1865         }
1866         ;
1867
1868 /*
1869 ugh. duplication
1870 */
1871
1872 steno_tonic_pitch:
1873         TONICNAME_PITCH {
1874                 $$ = $1;
1875         }
1876         | TONICNAME_PITCH sup_quotes    {
1877                 Pitch p = *unsmob_pitch ($1);
1878                 p = p.transposed (Pitch ($2,0,0));
1879                 $$ = p.smobbed_copy ();
1880         }
1881         | TONICNAME_PITCH sub_quotes     {
1882                 Pitch p =* unsmob_pitch ($1);
1883
1884                 p = p.transposed (Pitch (-$2,0,0));
1885                 $$ = p.smobbed_copy ();
1886         }
1887         ;
1888
1889 pitch:
1890         steno_pitch {
1891                 $$ = $1;
1892         }
1893         ;
1894
1895 pitch_also_in_chords:
1896         pitch
1897         | steno_tonic_pitch
1898         ;
1899
1900 gen_text_def:
1901         full_markup {
1902                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1903                 t->set_property ("text", $1);
1904                 t->set_spot (@$);
1905                 $$ = t;
1906         }
1907         | string {
1908                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1909                 t->set_property ("text",
1910                         make_simple_markup ($1));
1911                 t->set_spot (@$);
1912                 $$ = t;
1913
1914         }
1915         | DIGIT {
1916                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1917                 t->set_property ("digit", scm_from_int ($1));
1918                 t->set_spot (@$);
1919                 $$ = t;
1920         }
1921         ;
1922
1923 script_abbreviation:
1924         '^'             {
1925                 $$ = scm_makfrom0str ("Hat");
1926         }
1927         | '+'           {
1928                 $$ = scm_makfrom0str ("Plus");
1929         }
1930         | '-'           {
1931                 $$ = scm_makfrom0str ("Dash");
1932         }
1933         | '|'           {
1934                 $$ = scm_makfrom0str ("Bar");
1935         }
1936         | '>'           {
1937                 $$ = scm_makfrom0str ("Larger");
1938         }
1939         | '.'           {
1940                 $$ = scm_makfrom0str ("Dot");
1941         }
1942         | '_' {
1943                 $$ = scm_makfrom0str ("Underscore");
1944         }
1945         ;
1946
1947 script_dir:
1948         '_'     { $$ = DOWN; }
1949         | '^'   { $$ = UP; }
1950         | '-'   { $$ = CENTER; }
1951         ;
1952
1953
1954 absolute_pitch:
1955         steno_pitch     {
1956                 $$ = $1;
1957         }
1958         ;
1959
1960 duration_length:
1961         multiplied_duration {
1962                 $$ = $1;
1963         }
1964         ;
1965
1966 optional_notemode_duration:
1967         {
1968                 Duration dd = THIS->default_duration_;
1969                 $$ = dd.smobbed_copy ();
1970         }
1971         | multiplied_duration   {
1972                 $$ = $1;
1973                 THIS->default_duration_ = *unsmob_duration ($$);
1974         }
1975         ;
1976
1977 steno_duration:
1978         bare_unsigned dots              {
1979                 int len = 0;
1980                 if (!is_duration ($1))
1981                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
1982                 else
1983                         len = intlog2 ($1);
1984
1985                 $$ = Duration (len, $2).smobbed_copy ();
1986         }
1987         | DURATION_IDENTIFIER dots      {
1988                 Duration *d = unsmob_duration ($1);
1989                 Duration k (d->duration_log (), d->dot_count () + $2);
1990                 *d = k;
1991                 $$ = $1;
1992         }
1993         ;
1994
1995 multiplied_duration:
1996         steno_duration {
1997                 $$ = $1;
1998         }
1999         | multiplied_duration '*' bare_unsigned {
2000                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2001         }
2002         | multiplied_duration '*' FRACTION {
2003                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2004
2005                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2006         }
2007         ;
2008
2009 fraction:
2010         FRACTION { $$ = $1; }
2011         | UNSIGNED '/' UNSIGNED {
2012                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2013         }
2014         ;
2015
2016 dots:
2017         /* empty */     {
2018                 $$ = 0;
2019         }
2020         | dots '.' {
2021                 $$ ++;
2022         }
2023         ;
2024
2025 tremolo_type:
2026         ':'     {
2027                 $$ = 0;
2028         }
2029         | ':' bare_unsigned {
2030                 if (!is_duration ($2))
2031                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2032                 $$ = $2;
2033         }
2034         ;
2035
2036 bass_number:
2037         DIGIT   {
2038                 $$ = scm_from_int ($1);
2039         }
2040         | UNSIGNED {
2041                 $$ = scm_from_int ($1);
2042         }
2043         | STRING { $$ = $1; }
2044         | full_markup { $$ = $1; }
2045         ;
2046
2047 figured_bass_alteration:
2048         '-'     { $$ = -2; }
2049         | '+'   { $$ = 2; }
2050         | '!'   { $$ = 0; }
2051         ;
2052
2053 bass_figure:
2054         FIGURE_SPACE {
2055                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2056                 $$ = bfr->self_scm ();
2057                 bfr->unprotect ();
2058                 bfr->set_spot (@1);
2059         }
2060         | bass_number  {
2061                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2062                 $$ = bfr->self_scm ();
2063
2064                 if (scm_is_number ($1))
2065                         bfr->set_property ("figure", $1);
2066                 else if (Text_interface::is_markup ($1))
2067                         bfr->set_property ("text", $1);
2068
2069                 bfr->unprotect ();
2070                 bfr->set_spot (@1);
2071         }
2072         | bass_figure ']' {
2073                 $$ = $1;
2074                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2075         }
2076         | bass_figure figured_bass_alteration {
2077                 Music *m = unsmob_music ($1);
2078                 if ($2) {
2079                         SCM salter = m->get_property ("alteration");
2080                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2081                         m->set_property ("alteration",
2082                                 scm_from_int (alter + $2));
2083                 } else {
2084                         m->set_property ("alteration", scm_from_int (0));
2085                 }
2086         }
2087         | bass_figure figured_bass_modification  {
2088                 Music *m = unsmob_music ($1);
2089                 if ($2 == ly_symbol2scm ("plus"))
2090                         {
2091                         m->set_property ("augmented", SCM_BOOL_T);
2092                         }
2093                 else if ($2 == ly_symbol2scm ("slash"))
2094                         {
2095                         m->set_property ("diminished", SCM_BOOL_T);
2096                         }
2097                 else if ($2 == ly_symbol2scm ("exclamation"))
2098                         {
2099                         m->set_property ("no-continuation", SCM_BOOL_T);
2100                         }
2101         }
2102         ;
2103
2104
2105 figured_bass_modification:
2106         E_PLUS          {
2107                 $$ = ly_symbol2scm ("plus");
2108         }
2109         | E_EXCLAMATION {
2110                 $$ = ly_symbol2scm ("exclamation");
2111         }
2112         | '/'           {
2113                 $$ = ly_symbol2scm ("slash");
2114         }
2115         ;
2116
2117 br_bass_figure:
2118         bass_figure {
2119                 $$ = $1;
2120         }
2121         | '[' bass_figure {
2122                 $$ = $2;
2123                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2124         }
2125         ;
2126
2127 figure_list:
2128         /**/            {
2129                 $$ = SCM_EOL;
2130         }
2131         | figure_list br_bass_figure {
2132                 $$ = scm_cons ($2, $1);
2133         }
2134         ;
2135
2136 figure_spec:
2137         FIGURE_OPEN figure_list FIGURE_CLOSE {
2138                 Music *m = MY_MAKE_MUSIC ("EventChord");
2139                 $2 = scm_reverse_x ($2, SCM_EOL);
2140                 m->set_property ("elements", $2);
2141                 $$ = m->self_scm ();
2142         }
2143         ;
2144
2145
2146 optional_rest:
2147         /**/   { $$ = 0; }
2148         | REST { $$ = 1; }
2149         ;
2150
2151 simple_element:
2152         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2153                 if (!THIS->lexer_->is_note_state ())
2154                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2155
2156                 Music *n = 0;
2157                 if ($6)
2158                         n = MY_MAKE_MUSIC ("RestEvent");
2159                 else
2160                         n = MY_MAKE_MUSIC ("NoteEvent");
2161
2162                 n->set_property ("pitch", $1);
2163                 n->set_property ("duration", $5);
2164
2165                 if (scm_is_number ($4))
2166                 {
2167                         int q = scm_to_int ($4);
2168                         n->set_property ("absolute-octave", scm_from_int (q-1));
2169                 }
2170
2171                 if ($3 % 2)
2172                         n->set_property ("cautionary", SCM_BOOL_T);
2173                 if ($2 % 2 || $3 % 2)
2174                         n->set_property ("force-accidental", SCM_BOOL_T);
2175
2176                 Music *v = MY_MAKE_MUSIC ("EventChord");
2177                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2178                 n->unprotect ();
2179
2180                 v->set_spot (@$);
2181                 n->set_spot (@$);
2182                 $$ = v;
2183         }
2184         | DRUM_PITCH optional_notemode_duration {
2185                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2186                 n->set_property ("duration", $2);
2187                 n->set_property ("drum-type", $1);
2188
2189                 Music *v = MY_MAKE_MUSIC ("EventChord");
2190                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2191                 n->unprotect ();
2192                 v->set_spot (@$);
2193                 n->set_spot (@$);
2194                 $$ = v;
2195
2196         }
2197         | figure_spec optional_notemode_duration {
2198                 Music *m = unsmob_music ($1);
2199                 m->set_spot (@$);
2200                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2201                 {
2202                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2203                 }
2204                 $$ = m;
2205         }
2206         | RESTNAME optional_notemode_duration           {
2207                 Music *ev = 0;
2208                 if (ly_scm2string ($1) == "s") {
2209                         /* Space */
2210                         ev = MY_MAKE_MUSIC ("SkipEvent");
2211                   }
2212                 else {
2213                         ev = MY_MAKE_MUSIC ("RestEvent");
2214
2215                     }
2216                 ev->set_property ("duration", $2);
2217                 ev->set_spot (@$);
2218                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2219                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2220                 velt->set_spot (@$);
2221
2222                 ev->unprotect();
2223
2224                 $$ = velt;
2225         }
2226         | MULTI_MEASURE_REST optional_notemode_duration         {
2227                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2228                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2229                 $$ = unsmob_music (mus);
2230                 $$->protect ();
2231         }
2232
2233         | lyric_element optional_notemode_duration      {
2234                 if (!THIS->lexer_->is_lyric_state ())
2235                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2236
2237                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2238                 levent->set_property ("text", $1);
2239                 levent->set_property ("duration",$2);
2240                 levent->set_spot (@$);
2241                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2242                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2243
2244                 $$= velt;
2245         }
2246         | new_chord {
2247                 if (!THIS->lexer_->is_chord_state ())
2248                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2249                 $$ = unsmob_music ($1);
2250         }
2251         ;
2252
2253 lyric_element:
2254         lyric_markup {
2255                 $$ = $1;
2256         }
2257         | LYRICS_STRING {
2258                 $$ = $1;
2259         }
2260         ;
2261
2262 new_chord:
2263         steno_tonic_pitch optional_notemode_duration   {
2264                 $$ = make_chord ($1, $2, SCM_EOL);
2265         }
2266         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2267                 SCM its = scm_reverse_x ($4, SCM_EOL);
2268                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2269         }
2270         ;
2271
2272 chord_items:
2273         /**/ {
2274                 $$ = SCM_EOL;
2275         }
2276         | chord_items chord_item {
2277                 $$ = scm_cons ($2, $$);
2278         }
2279         ;
2280
2281 chord_separator:
2282         CHORD_COLON {
2283                 $$ = ly_symbol2scm ("chord-colon");
2284         }
2285         | CHORD_CARET {
2286                 $$ = ly_symbol2scm ("chord-caret");
2287         }
2288         | CHORD_SLASH steno_tonic_pitch {
2289                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2290         }
2291         | CHORD_BASS steno_tonic_pitch {
2292                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2293         }
2294         ;
2295
2296 chord_item:
2297         chord_separator {
2298                 $$ = $1;
2299         }
2300         | step_numbers {
2301                 $$ = scm_reverse_x ($1, SCM_EOL);
2302         }
2303         | CHORD_MODIFIER  {
2304                 $$ = $1;
2305         }
2306         ;
2307
2308 step_numbers:
2309         step_number { $$ = scm_cons ($1, SCM_EOL); }
2310         | step_numbers '.' step_number {
2311                 $$ = scm_cons ($3, $$);
2312         }
2313         ;
2314
2315 step_number:
2316         bare_unsigned {
2317                 $$ = make_chord_step ($1, 0);
2318         }
2319         | bare_unsigned '+' {
2320                 $$ = make_chord_step ($1, SHARP);
2321         }
2322         | bare_unsigned CHORD_MINUS {
2323                 $$ = make_chord_step ($1, FLAT);
2324         }
2325         ;
2326
2327 /*
2328         UTILITIES
2329
2330 TODO: should deprecate in favor of Scheme?
2331
2332  */
2333 number_expression:
2334         number_expression '+' number_term {
2335                 $$ = scm_sum ($1, $3);
2336         }
2337         | number_expression '-' number_term {
2338                 $$ = scm_difference ($1, $3);
2339         }
2340         | number_term
2341         ;
2342
2343 number_term:
2344         number_factor {
2345                 $$ = $1;
2346         }
2347         | number_factor '*' number_factor {
2348                 $$ = scm_product ($1, $3);
2349         }
2350         | number_factor '/' number_factor {
2351                 $$ = scm_divide ($1, $3);
2352         }
2353         ;
2354
2355 number_factor:
2356         '-'  number_factor { /* %prec UNARY_MINUS */
2357                 $$ = scm_difference ($2, SCM_UNDEFINED);
2358         }
2359         | bare_number
2360         ;
2361
2362
2363 bare_number:
2364         UNSIGNED        {
2365                 $$ = scm_from_int ($1);
2366         }
2367         | REAL          {
2368                 $$ = $1;
2369         }
2370         | NUMBER_IDENTIFIER             {
2371                 $$ = $1;
2372         }
2373         | REAL NUMBER_IDENTIFIER        {
2374                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2375         }
2376         | UNSIGNED NUMBER_IDENTIFIER    {
2377                 $$ = scm_from_double ($1 *scm_to_double ($2));
2378         }
2379         ;
2380
2381
2382 bare_unsigned:
2383         UNSIGNED {
2384                         $$ = $1;
2385         }
2386         | DIGIT {
2387                 $$ = $1;
2388         }
2389         ;
2390
2391 exclamations:
2392                 { $$ = 0; }
2393         | exclamations '!'      { $$ ++; }
2394         ;
2395
2396 questions:
2397                 { $$ = 0; }
2398         | questions '?' { $$ ++; }
2399         ;
2400
2401 /*
2402 This should be done more dynamically if possible.
2403 */
2404
2405 lyric_markup:
2406         LYRIC_MARKUP_IDENTIFIER {
2407                 $$ = $1;
2408         }
2409         | LYRIC_MARKUP
2410                 { THIS->lexer_->push_markup_state (); }
2411         markup_top {
2412                 $$ = $3;
2413                 THIS->lexer_->pop_state ();
2414         }
2415         ;
2416
2417 full_markup:
2418         MARKUP_IDENTIFIER {
2419                 $$ = $1;
2420         }
2421         | MARKUP
2422                 { THIS->lexer_->push_markup_state (); }
2423         markup_top {
2424                 $$ = $3;
2425                 THIS->lexer_->pop_state ();
2426         }
2427         ;
2428
2429 markup_top:
2430         markup_list {
2431                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2432         }
2433         | markup_head_1_list simple_markup      {
2434                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2435         }
2436         | simple_markup {
2437                 $$ = $1;
2438         }
2439         ;
2440
2441 markup_list:
2442         markup_composed_list {
2443                 $$ = $1;
2444         }
2445         | markup_braced_list {
2446                 $$ = $1;
2447         }
2448         ;
2449
2450 markup_composed_list:
2451         markup_head_1_list markup_braced_list {
2452                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2453
2454         }
2455         ;
2456
2457 markup_braced_list:
2458         '{' markup_braced_list_body '}' {
2459                 $$ = scm_reverse_x ($2, SCM_EOL);
2460         }
2461         ;
2462
2463 markup_braced_list_body:
2464         /* empty */     {  $$ = SCM_EOL; }
2465         | markup_braced_list_body markup {
2466                 $$ = scm_cons ($2, $1);
2467         }
2468         | markup_braced_list_body markup_list {
2469                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2470         }
2471         ;
2472
2473 markup_head_1_item:
2474         MARKUP_HEAD_MARKUP0     {
2475                 $$ = scm_list_1 ($1);
2476         }
2477         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2478                 $$ = scm_list_2 ($1, $2);
2479         }
2480         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2481                 $$ = scm_list_3 ($1, $2, $3);
2482         }
2483         ;
2484
2485 markup_head_1_list:
2486         markup_head_1_item      {
2487                 $$ = scm_list_1 ($1);
2488         }
2489         | markup_head_1_list markup_head_1_item {
2490                 $$ = scm_cons ($2, $1);
2491         }
2492         ;
2493
2494 simple_markup:
2495         STRING {
2496                 $$ = make_simple_markup ($1);
2497         }
2498         | MARKUP_IDENTIFIER {
2499                 $$ = $1;
2500         }
2501         | LYRIC_MARKUP_IDENTIFIER {
2502                 $$ = $1;
2503         }
2504         | STRING_IDENTIFIER {
2505                 $$ = $1;
2506         }
2507         | SCORE {
2508                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2509                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2510         } '{' score_body '}' {
2511                 Score * sc = $4;
2512                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2513                 sc->unprotect ();
2514                 THIS->lexer_->pop_state ();
2515         }
2516         | MARKUP_HEAD_SCM0 embedded_scm {
2517                 $$ = scm_list_2 ($1, $2);
2518         }
2519         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2520                 $$ = scm_list_4 ($1, $2, $3, $4);
2521         }
2522         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2523                 $$ = scm_list_3 ($1, $2, $3);
2524         }
2525         | MARKUP_HEAD_EMPTY {
2526                 $$ = scm_list_1 ($1);
2527         }
2528         | MARKUP_HEAD_LIST0 markup_list {
2529                 $$ = scm_list_2 ($1,$2);
2530         }
2531         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2532                 $$ = scm_list_3 ($1, $2, $3);
2533         }
2534         ;
2535
2536 markup:
2537         markup_head_1_list simple_markup        {
2538                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2539                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2540         }
2541         | simple_markup {
2542                 $$ = $1;
2543         }
2544         ;
2545
2546 %%
2547
2548 void
2549 Lily_parser::set_yydebug (bool )
2550 {
2551 #if 0
2552         yydebug = 1;
2553 #endif
2554 }
2555
2556 void
2557 Lily_parser::do_yyparse ()
2558 {
2559         yyparse ((void*)this);
2560 }
2561
2562
2563
2564
2565
2566 /*
2567
2568 It is a little strange to have this function in this file, but
2569 otherwise, we have to import music classes into the lexer.
2570
2571 */
2572 int
2573 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2574 {
2575         if (scm_is_string (sid)) {
2576                 *destination = sid;
2577                 return STRING_IDENTIFIER;
2578         } else if (unsmob_book (sid)) {
2579                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2580                 return BOOK_IDENTIFIER;
2581         } else if (scm_is_number (sid)) {
2582                 *destination = sid;
2583                 return NUMBER_IDENTIFIER;
2584         } else if (unsmob_context_def (sid)) {
2585                 *destination = unsmob_context_def (sid)->clone_scm ();
2586                 return CONTEXT_DEF_IDENTIFIER;
2587         } else if (unsmob_score (sid)) {
2588                 Score *score = new Score (*unsmob_score (sid));
2589                 *destination = score->self_scm ();
2590                 return SCORE_IDENTIFIER;
2591         } else if (Music *mus = unsmob_music (sid)) {
2592                 mus = mus->clone ();
2593                 *destination = mus->self_scm ();
2594                 unsmob_music (*destination)->
2595                         set_property ("origin", make_input (last_input_));
2596
2597                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2598                         != SCM_BOOL_F;
2599
2600                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2601         } else if (unsmob_duration (sid)) {
2602                 *destination = unsmob_duration (sid)->smobbed_copy ();
2603                 return DURATION_IDENTIFIER;
2604         } else if (unsmob_output_def (sid)) {
2605                 Output_def *p = unsmob_output_def (sid);
2606                 p = p->clone ();
2607
2608                 *destination = p->self_scm ();
2609                 return OUTPUT_DEF_IDENTIFIER;
2610         } else if (Text_interface::is_markup (sid)) {
2611                 *destination = sid;
2612                 if (is_lyric_state ())
2613                         return LYRIC_MARKUP_IDENTIFIER;
2614                 return MARKUP_IDENTIFIER;
2615         }
2616
2617         return -1;
2618 }
2619
2620 Music *
2621 property_op_to_music (SCM op)
2622 {
2623         Music *m = 0;
2624         SCM tag = scm_car (op);
2625         SCM symbol = scm_cadr (op);
2626         SCM args = scm_cddr (op);
2627         SCM grob_val = SCM_UNDEFINED;
2628         SCM grob_path = SCM_UNDEFINED;
2629         SCM val = SCM_UNDEFINED;
2630
2631         if (tag == ly_symbol2scm ("assign"))
2632                 {
2633                 m = MY_MAKE_MUSIC ("PropertySet");
2634                 val = scm_car (args);
2635                 }
2636         else if (tag == ly_symbol2scm ("unset"))
2637                 m = MY_MAKE_MUSIC ("PropertyUnset");
2638         else if (tag == ly_symbol2scm ("push"))
2639                 {
2640                 m = MY_MAKE_MUSIC ("OverrideProperty");
2641                 grob_val = scm_car (args);
2642                 grob_path = scm_cdr (args);
2643                 m->set_property ("pop-first", SCM_BOOL_T);
2644                 }
2645         else if (tag == ly_symbol2scm ("pop")) {
2646                 m = MY_MAKE_MUSIC ("RevertProperty");
2647                 grob_path = args;
2648                 }
2649
2650         m->set_property ("symbol", symbol);
2651
2652         if (val != SCM_UNDEFINED)
2653                 m->set_property ("value", val);
2654         if (grob_val != SCM_UNDEFINED)
2655                 m->set_property ("grob-value", grob_val);
2656         if (grob_path != SCM_UNDEFINED)
2657                 m->set_property ("grob-property-path", grob_path);
2658
2659         return m;
2660 }
2661
2662 Music*
2663 context_spec_music (SCM type, SCM id, Music *m, SCM ops, bool create_new)
2664 {
2665         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2666
2667         csm->set_property ("element", m->self_scm ());
2668         m->unprotect ();
2669
2670         csm->set_property ("context-type",
2671                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2672         csm->set_property ("property-operations", ops);
2673         if (create_new)
2674                 csm->set_property ("create-new", SCM_BOOL_T);
2675
2676         if (scm_is_string (id))
2677                 csm->set_property ("context-id", id);
2678         return csm;
2679 }
2680
2681 SCM
2682 get_next_unique_context_id ()
2683 {
2684         return scm_makfrom0str ("$uniqueContextId");
2685 }
2686
2687
2688 SCM
2689 get_next_unique_lyrics_context_id ()
2690 {
2691         static int new_context_count;
2692         char s[128];
2693         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2694         return scm_makfrom0str (s);
2695 }
2696
2697
2698 Music *
2699 run_music_function (Lily_parser *parser, SCM expr)
2700 {
2701         SCM func = scm_car (expr);
2702         Input *loc = unsmob_input (scm_cadr (expr));
2703         SCM args = scm_cddr (expr);
2704         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2705
2706         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2707         bool ok  = true;
2708
2709         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2710         {
2711                 parser->error_level_ = 1;
2712                 ok = false;
2713         }
2714
2715         SCM m = SCM_EOL;
2716         if (ok)
2717                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2718                                                  scm_cdr (expr)));
2719
2720
2721         Music* retval = 0;
2722         if (unsmob_music (m))
2723                 {
2724                 retval = unsmob_music (m);
2725                 retval->protect ();
2726                 }
2727         else
2728                 {
2729                 if (ok)
2730                         loc->error (_ ("music head function must return Music object"));
2731                 retval = MY_MAKE_MUSIC ("Music");
2732                 }
2733         retval->set_spot (*loc);
2734         return retval;
2735 }
2736
2737 bool
2738 is_regular_identifier (SCM id)
2739 {
2740   string str = ly_scm2string (id);
2741   char const *s = str.c_str ();
2742
2743   bool v = true;
2744 #if 0
2745   isalpha (*s);
2746   s++;
2747 #endif
2748   while (*s && v)
2749    {
2750         v = v && isalnum (*s);
2751         s++;
2752    }
2753   return v;
2754 }
2755
2756
2757 SCM
2758 get_first_context_id (SCM type, Music *m)
2759 {
2760         SCM id = m->get_property ("context-id");
2761         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2762             && scm_is_string (m->get_property ("context-id"))
2763             && scm_c_string_length (id) > 0)
2764         {
2765                 return id;
2766         }
2767         return SCM_EOL;
2768 }
2769
2770 SCM
2771 make_simple_markup (SCM a)
2772 {
2773         return a;
2774 }
2775
2776 bool
2777 is_duration (int t)
2778 {
2779   return t && t == 1 << intlog2 (t);
2780 }
2781
2782 void
2783 set_music_properties (Music *p, SCM a)
2784 {
2785   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2786         p->internal_set_property (scm_caar (k), scm_cdar (k));
2787 }
2788
2789
2790 SCM
2791 make_chord_step (int step, int alter)
2792 {
2793         if (step == 7)
2794                 alter += FLAT;
2795
2796         while (step < 0)
2797                 step += 7;
2798         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2799         return m.smobbed_copy ();
2800 }
2801
2802
2803 SCM
2804 make_chord (SCM pitch, SCM dur, SCM modification_list)
2805 {
2806         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2807         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2808
2809         unsmob_music (ch)->protect();
2810         return ch;
2811 }
2812
2813
2814 /* Todo: actually also use apply iso. call too ...  */
2815 bool
2816 ly_input_procedure_p (SCM x)
2817 {
2818         return ly_is_procedure (x)
2819                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2820 }
2821
2822 Music*
2823 set_property_music (SCM sym, SCM value)
2824 {
2825         Music *p = MY_MAKE_MUSIC ("PropertySet");
2826         p->set_property ("symbol", sym);
2827         p->set_property ("value", value);
2828         return p;
2829 }
2830
2831 Music*
2832 make_music_relative (Pitch start, Music *music)
2833 {
2834         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2835         relative->set_property ("element", music->self_scm ());
2836
2837         Pitch last = music->to_relative_octave (start);
2838         if (lily_1_8_relative)
2839                 music->set_property ("last-pitch", last.smobbed_copy ());
2840         return relative;
2841 }
2842
2843 Music *
2844 make_lyric_combine_music (SCM name, Music *music)
2845 {
2846         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2847         combine->set_property ("element", music->self_scm ());
2848         combine->set_property ("associated-context", name);
2849         return combine;
2850 }
2851
2852
2853 int
2854 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2855 {
2856         Lily_parser *pars = (Lily_parser*) v;
2857         Lily_lexer *lex = pars->lexer_;
2858
2859         lex->lexval = (void*) s;
2860         lex->lexloc = loc;
2861         lex->prepare_for_next_token ();
2862         return lex->yylex ();
2863 }