lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLY
 251 %token APPLYCONTEXT
 252 %token APPLYOUTPUT
 253 %token AUTOCHANGE
 254 %token BAR
 255 %token BOOK
 256 %token BREATHE
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONSISTSEND
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 272 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 273 %token GRACE
 274 %token ACCIACCATURA
 275 %token APPOGGIATURA
 276 %token GROBDESCRIPTIONS
 277 %token HEADER
 278 %token HYPHEN
 279 %token INVALID
 280 %token KEY
 281 %token LYRICS
 282 %token LYRICS_STRING
 283 %token MARK
 284 %token MIDI
 285 %token MULTI_MEASURE_REST
 286 %token NAME
 287 %token NEWCONTEXT
 288 %token NOTES
 289 %token OCTAVE
 290 %token ONCE
 291 %token OVERRIDE SET REVERT
 292 %token PAPER
 293 %token PARTCOMBINE
 294 %token PARTIAL
 295 %token QUOTE
 296 %token RELATIVE
 297 %token REMOVE
 298 %token REPEAT
 299 %token REST
 300 %token SCM_T
 301 %token SCORE
 302 %token SEQUENTIAL
 303 %token NEWLYRICS
 304 %token SIMULTANEOUS
 305 %token SKIP
 306 %token SPANREQUEST
 307 %token TAG
 308 %token TEMPO
 309 %token TIMES
 310 %token TIME_T
 311 %token TRANSPOSE
 312 %token TRANSPOSITION
 313 %token TYPE
 314 %token UNSET
 315 %token WITH
 316
 317 /* escaped */
 318 /* FIXME: this sucks.  The user will get to see these names:
 319     syntax error, unexpected E_CHAR:
 320                 \
 321                  %%
 322   */
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token <i> E_UNSIGNED
 327 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 328 %token FIGURE_SPACE
 329
 330 %token <i>      DIGIT
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    TONICNAME_PITCH
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DURATION_IDENTIFIER
 335 %token <scm>    FRACTION
 336 %token <id>     IDENTIFIER
 337 %token DRUMS
 338 %token <scm>    DRUM_PITCH
 339 %token <scm>    CHORD_MODIFIER
 340 %token <scm>    SCORE_IDENTIFIER
 341 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 342 %token <scm>    NUMBER_IDENTIFIER
 343 %token <scm>    EVENT_IDENTIFIER
 344 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 345 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 346 %token <scm>    RESTNAME
 347 %token <scm>    STRING
 348 %token <scm>    SCM_T
 349 %token <i>      UNSIGNED
 350 %token <scm>   REAL
 351
 352 %token MARKUP
 353 %token <scm> MARKUP_HEAD_MARKUP0
 354 %token <scm> MARKUP_HEAD_EMPTY
 355 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0
 357 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1
 359 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 360 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 361
 362 %token <scm> MUSIC_HEAD_SCM
 363 %token <scm> MUSIC_HEAD_MUSIC
 364 %token <scm> MUSIC_HEAD_SCM_MUSIC
 365 %token <scm> MUSIC_HEAD_MUSIC_MUSIC
 366 %token <scm> MUSIC_HEAD_SCM_SCM_MUSIC
 367 %token <scm> MUSIC_HEAD_SCM_MUSIC_MUSIC
 368
 369 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 370 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 371
 372 %type <book>    book_block book_body
 373 %type <i>       exclamations questions dots optional_rest
 374 %type <i>        bass_mod
 375 %type <scm>     grace_head
 376 %type <scm>     oct_check
 377 %type <scm>     context_mod_list
 378 %type <scm>     lyric_element
 379 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 380 %type <scm>     new_lyrics
 381 %type <outputdef> output_def
 382 %type <scm>     lilypond_header lilypond_header_body
 383 %type <music>   open_event close_event
 384 %type <i>       sub_quotes sup_quotes
 385 %type <music>   toplevel_music
 386 %type <music>   simple_element event_chord command_element
 387 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 388 %type <music>   Grouped_music_list
 389 %type <music>   Repeated_music
 390 %type <scm>     Alternative_music
 391 %type <i>       tremolo_type
 392 %type <i>       bare_int  bare_unsigned
 393 %type <i>       script_dir
 394 %type <scm>     identifier_init
 395 %type <scm>     simple_string
 396
 397 %type <music>   note_chord_element chord_body chord_body_element
 398 %type <scm>     chord_body_elements
 399 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 400
 401 %type <scm>     post_events
 402 %type <music>   gen_text_def direction_less_event direction_reqd_event
 403 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 404 %type <scm>     steno_tonic_pitch
 405 %type <scm>     duration_length fraction
 406
 407 %type <scm>     chord_item chord_items chord_separator new_chord
 408 %type <scm>     step_number step_numbers
 409
 410 %type <scm>     embedded_scm scalar
 411 %type <music>   Music Sequential_music Simultaneous_music
 412 %type <music>   relative_music re_rhythmed_music
 413 %type <music>   music_property_def context_change
 414 %type <scm>     context_prop_spec
 415 %type <scm>     Music_list
 416 %type <scm>     property_operation
 417 %type <scm>     context_mod context_def_mod optional_context_mod
 418 %type <outputdef>       music_output_def_body music_output_def_head
 419 %type <music>   post_event tagged_post_event
 420 %type <music>   command_req
 421 %type <music>   string_number_event
 422 %type <scm>     string bare_number number_expression number_term number_factor
 423 %type <score>   score_block score_body
 424
 425 %type <scm>     context_def_spec_block context_def_spec_body
 426 %type <music>   tempo_event
 427 %type <scm>     script_abbreviation
 428
 429
 430
 431 %left '-' '+'
 432
 433 /* We don't assign precedence to / and *, because we might need varied
 434 prec levels in different prods */
 435
 436 %left UNARY_MINUS
 437
 438 %%
 439
 440 lilypond:       /* empty */
 441         | lilypond toplevel_expression {
 442         }
 443         | lilypond assignment {
 444         }
 445         | lilypond error {
 446                 THIS->error_level_ = 1;
 447         }
 448         | lilypond INVALID      {
 449                 THIS->error_level_ = 1;
 450         }
 451         ;
 452
 453 toplevel_expression:
 454         lilypond_header {
 455                 THIS->header_ = $1;
 456         }
 457         | add_quote {
 458
 459         }
 460         | book_block {
 461                 Book *book = $1;
 462                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 463                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 464                 scm_gc_unprotect_object (book->self_scm ());
 465         }
 466         | score_block {
 467                 Score *score = $1;
 468
 469                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 470                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 471                 scm_gc_unprotect_object (score->self_scm ());
 472         }
 473         | toplevel_music {
 474                 Music *music = $1;
 475                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 476                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 477                 scm_gc_unprotect_object (music->self_scm ());
 478         }
 479         | output_def {
 480                 SCM id = SCM_EOL;
 481                 if (dynamic_cast<Paper_def*> ($1))
 482                         id = scm_makfrom0str ("$defaultpaper");
 483                 else if (dynamic_cast<Midi_def*> ($1))
 484                         id = scm_makfrom0str ("$defaultmidi");
 485                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 486                 scm_gc_unprotect_object ($1->self_scm ());
 487         }
 488         ;
 489
 490 toplevel_music:
 491         Composite_music {
 492         }
 493         ;
 494
 495 embedded_scm:
 496         SCM_T
 497         | SCM_IDENTIFIER
 498         ;
 499
 500
 501 lilypond_header_body:
 502         {
 503                 $$ = ly_make_anonymous_module ();
 504                 THIS->lexer_->add_scope ($$);
 505         }
 506         | lilypond_header_body assignment  {
 507
 508         }
 509         ;
 510
 511 lilypond_header:
 512         HEADER '{' lilypond_header_body '}'     {
 513                 $$ = THIS->lexer_->remove_scope ();
 514         }
 515         ;
 516
 517
 518 /*
 519         DECLARATIONS
 520 */
 521 assignment:
 522         STRING {
 523                 THIS->push_spot ();
 524         }
 525         /* cont */ '=' identifier_init  {
 526
 527         /*
 528                 Should find generic way of associating input with objects.
 529         */
 530                 Input ip = THIS->pop_spot ();
 531
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $4);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | full_markup {
 557                 $$ = $1;
 558         }
 559         | output_def {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | context_def_spec_block {
 564                 $$ = $1;
 565         }
 566         | Music  {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | post_event {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | number_expression {
 575                 $$ = $1;
 576         }
 577         | string {
 578                 $$ = $1;
 579         }
 580         | embedded_scm  {
 581                 $$ = $1;
 582         }
 583         ;
 584
 585 context_def_spec_block:
 586         CONTEXT '{' context_def_spec_body '}'
 587                 {
 588                 $$ = $3;
 589         }
 590         ;
 591
 592 context_def_spec_body:
 593         /**/ {
 594                 $$ = Context_def::make_scm ();
 595                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 596         }
 597         | CONTEXT_DEF_IDENTIFIER {
 598                 $$ = $1;
 599                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 600         }
 601         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 602                 Context_def*td = unsmob_context_def ($$);
 603
 604                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 605                         SCM tag = ly_caar (p);
 606
 607                         /* TODO: should make new tag "grob-definition" ? */
 608                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 609                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 610                 }
 611         }
 612         | context_def_spec_body context_mod {
 613                 unsmob_context_def ($$)->add_context_mod ($2);
 614         }
 615         ;
 616
 617 book_block:
 618         BOOK {
 619                 THIS->push_spot ();
 620         }
 621         /*cont*/ '{' book_body '}'      {
 622                 THIS->pop_spot ();
 623                 $$ = $4;
 624         }
 625         ;
 626
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631         }
 632         | book_body score_block {
 633                 $$->scores_.push ($2);
 634                 scm_gc_unprotect_object ($2->self_scm ());
 635         }
 636         | book_body error {
 637         }
 638         ;
 639
 640 score_block:
 641         SCORE {
 642                 THIS->push_spot ();
 643         }
 644         /*cont*/ '{' score_body '}'     {
 645                 THIS->pop_spot ();
 646                 $$ = $4;
 647         }
 648         ;
 649
 650 score_body:
 651         Music   {
 652                 $$ = new Score;
 653
 654                 $$->set_spot (THIS->here_input ());
 655                 SCM m = $1->self_scm ();
 656                 scm_gc_unprotect_object (m);
 657
 658                 /*
 659                         guh.
 660                 */
 661                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 662                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 663                         m = scm_call_1 (ly_car (check_funcs), m);
 664                 $$->music_ = m;
 665
 666         }
 667         | SCORE_IDENTIFIER {
 668                 $$ = new Score ( *unsmob_score ($1));
 669                 $$->set_spot (THIS->here_input ());
 670         }
 671         | score_body lilypond_header    {
 672                 $$->header_ = $2;
 673         }
 674         | score_body output_def {
 675                 $$->defs_.push ($2);
 676                 scm_gc_unprotect_object ($2->self_scm ());
 677         }
 678         | score_body error {
 679
 680         }
 681         ;
 682
 683
 684 /*
 685         MIDI
 686 */
 687 output_def:
 688         music_output_def_body '}' {
 689                 $$ = $1;
 690                 THIS->lexer_->remove_scope ();
 691                 THIS->lexer_->pop_state ();
 692         }
 693         ;
 694
 695 music_output_def_head:
 696         MIDI    {
 697                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 698
 699
 700                 Midi_def *p = 0;
 701                 if (id)
 702                         p = dynamic_cast<Midi_def*> (id->clone ());
 703                 else
 704                         p = new Midi_def;
 705
 706                 $$ = p;
 707                 THIS->lexer_->add_scope (p->scope_);
 708         }
 709         | PAPER         {
 710                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 711                   Paper_def *p = 0;
 712                 if (id)
 713                         p = dynamic_cast<Paper_def*> (id->clone ());
 714                 else
 715                         p = new Paper_def;
 716
 717                 THIS->lexer_->add_scope (p->scope_);
 718                 $$ = p;
 719         }
 720         ;
 721
 722
 723 music_output_def_body:
 724         music_output_def_head '{' {
 725                 $$ = $1;
 726                 $$->input_origin_. set_spot (THIS->here_input ());
 727                 THIS->lexer_->push_initial_state ();
 728         }
 729         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 730                 scm_gc_unprotect_object ($1->self_scm ());
 731                 Music_output_def *o = unsmob_music_output_def ($3);
 732                 o->input_origin_.set_spot (THIS->here_input ());
 733                 $$ = o;
 734                 THIS->lexer_->remove_scope ();
 735                 THIS->lexer_->add_scope (o->scope_);
 736                 THIS->lexer_->push_initial_state ();
 737         }
 738         | music_output_def_body assignment  {
 739
 740         }
 741         | music_output_def_body context_def_spec_block  {
 742                 $$->assign_context_def ($2);
 743         }
 744         | music_output_def_body tempo_event  {
 745                 /*
 746                         junk this ? there already is tempo stuff in
 747                         music.
 748                 */
 749                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 750                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 751                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 752                 if (md)
 753                         md->set_tempo (d->get_length (), m);
 754                 scm_gc_unprotect_object ($2->self_scm ());
 755         }
 756         | music_output_def_body error {
 757
 758         }
 759         ;
 760
 761 tempo_event:
 762         TEMPO steno_duration '=' bare_unsigned  {
 763                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 764                 $$->set_property ("tempo-unit", $2);
 765                 $$->set_property ("metronome-count", scm_int2num ( $4));
 766         }
 767         ;
 768
 769 /*
 770 The representation of a  list is the
 771
 772   (LIST . LAST-CONS)
 773
 774  to have  efficient append.
 775 */
 776 Music_list:
 777         /* empty */ {
 778                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 779         }
 780         | Music_list Music {
 781                 SCM s = $$;
 782                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 783                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 784                 if (ly_c_pair_p (ly_cdr (s)))
 785                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 786                 else
 787                         scm_set_car_x (s, c); /* set first cons */
 788                 scm_set_cdr_x (s, c);  /* remember last cell */
 789         }
 790         | Music_list embedded_scm {
 791         }
 792         | Music_list error {
 793         }
 794         ;
 795
 796
 797 Music:
 798         Simple_music
 799         | Composite_music
 800         ;
 801
 802 Alternative_music:
 803         /* empty */ {
 804                 $$ = SCM_EOL;
 805         }
 806         | ALTERNATIVE '{' Music_list '}' {
 807                 $$ = $3;
 808         }
 809         ;
 810
 811
 812 Repeated_music:
 813         REPEAT simple_string bare_unsigned Music Alternative_music
 814         {
 815                 Music *beg = $4;
 816                 int times = $3;
 817                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 818                 if (times < scm_ilength (alts)) {
 819                   unsmob_music (ly_car (alts))
 820                     ->origin ()->warning (
 821                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 822                   alts = ly_truncate_list (times, alts);
 823                 }
 824
 825
 826                 SCM proc = ly_scheme_function ("make-repeated-music");
 827
 828                 SCM mus = scm_call_1 (proc, $2);
 829                 scm_gc_protect_object (mus); // UGH.
 830                 Music *r = unsmob_music (mus);
 831                 if (beg)
 832                         {
 833                         r-> set_property ("element", beg->self_scm ());
 834                         scm_gc_unprotect_object (beg->self_scm ());
 835                         }
 836                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 837
 838                 r-> set_property ("elements",alts);
 839                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 840                         /*
 841                         TODO: move this code to Scheme.
 842                         */
 843
 844                         /*
 845                         we can not get durations and other stuff correct down the line, so we have to
 846                         add to the duration log here.
 847                         */
 848                         SCM func = ly_scheme_function ("shift-duration-log");
 849
 850                         int dots = ($3 % 3) ? 0 : 1;
 851                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 852
 853                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 854
 855                         if (seq) {
 856                                 int list_len = scm_ilength (seq->music_list ());
 857                                 if (list_len != 2)
 858                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 859                                 shift -= 1;
 860                                 r->compress (Moment (Rational (1, list_len)));
 861                                 }
 862                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 863
 864                 }
 865                 r->set_spot (*$4->origin ());
 866
 867                 $$ = r;
 868         }
 869         ;
 870
 871 Sequential_music:
 872         SEQUENTIAL '{' Music_list '}'           {
 873                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 874                 $$->set_property ("elements", ly_car ($3));
 875                 $$->set_spot (THIS->here_input ());
 876         }
 877         | '{' Music_list '}'            {
 878                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 879                 $$->set_property ("elements", ly_car ($2));
 880                 $$->set_spot (THIS->here_input ());
 881         }
 882         ;
 883
 884 Simultaneous_music:
 885         SIMULTANEOUS '{' Music_list '}'{
 886                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 887                 $$->set_property ("elements", ly_car ($3));
 888                 $$->set_spot (THIS->here_input ());
 889
 890         }
 891         | simul_open Music_list simul_close     {
 892                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 893                 $$->set_property ("elements", ly_car ($2));
 894                 $$->set_spot (THIS->here_input ());
 895         }
 896         ;
 897
 898 Simple_music:
 899         event_chord             { $$ = $1; }
 900         | APPLYOUTPUT embedded_scm {
 901                 if (!ly_input_procedure_p ($2))
 902                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 903                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 904                 $$->set_property ("procedure", $2);
 905                 $$->set_spot (THIS->here_input ());
 906         }
 907         | APPLYCONTEXT embedded_scm {
 908                 if (!ly_input_procedure_p ($2))
 909                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 910                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 911                 $$->set_property ("procedure", $2);
 912                 $$->set_spot (THIS->here_input ());
 913         }
 914         | MUSIC_IDENTIFIER {
 915                 $$ = unsmob_music ($1);
 916         }
 917         | music_property_def
 918         | context_change
 919         ;
 920
 921
 922 optional_context_mod:
 923         /**/ { $$ = SCM_EOL; }
 924         | WITH { THIS->lexer_->push_initial_state (); }
 925         '{' context_mod_list '}'
 926         {
 927                 THIS->lexer_->pop_state ();
 928                 $$ = $4;
 929         }
 930         ;
 931
 932 grace_head:
 933         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 934         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 935         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 936         ;
 937
 938 context_mod_list:
 939         /* */  { $$ = SCM_EOL; }
 940         | context_mod_list context_mod  {
 941                  $$ = scm_cons ($2, $1);
 942         }
 943         ;
 944
 945
 946 Composite_music:
 947         Prefix_composite_music { $$ = $1; }
 948         | Grouped_music_list { $$ = $1; }
 949         ;
 950
 951 Grouped_music_list:
 952         Simultaneous_music              { $$ = $1; }
 953         | Sequential_music              { $$ = $1; }
 954         ;
 955
 956 Generic_prefix_music:
 957         MUSIC_HEAD_SCM { THIS->push_spot (); } embedded_scm {
 958                 SCM m = scm_call_2 ($1, make_input (THIS->pop_spot ()),
 959                         $3);
 960                 if (unsmob_music (m))
 961                         $$ = unsmob_music (m);
 962                 else
 963                 {
 964                         THIS->parser_error ("MUSIC_HEAD should return Music");
 965                         $$ = MY_MAKE_MUSIC("Music");
 966                 }
 967         }
 968         ;
 969
 970 Prefix_composite_music:
 971         Generic_prefix_music {
 972                 $$ = $1;
 973         }
 974         |AUTOCHANGE Music       {
 975                 SCM proc = ly_scheme_function ("make-autochange-music");
 976
 977                 SCM res = scm_call_1 (proc, $2->self_scm ());
 978                 scm_gc_unprotect_object ($2->self_scm ());
 979                 $$ = unsmob_music (res);
 980                 scm_gc_protect_object (res);
 981                 $$->set_spot (THIS->here_input ());
 982         }
 983         | PARTCOMBINE Music Music {
 984                 SCM proc = ly_scheme_function ("make-part-combine-music");
 985
 986                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 987                         $3->self_scm (), SCM_UNDEFINED));
 988                 scm_gc_unprotect_object ($3->self_scm ());
 989                 scm_gc_unprotect_object ($2->self_scm ());
 990                 $$ = unsmob_music (res);
 991                 scm_gc_protect_object (res);
 992                 $$->set_spot (THIS->here_input ());
 993         }
 994         | grace_head Music {
 995 #if 1
 996         /*
 997                 The other version is for easier debugging  of
 998                 Sequential_music_iterator in combination with grace notes.
 999         */
1000
1001 /*
1002
1003 TODO: should distinguish between both grace types in the
1004 basic music objects too, since the meaning is different.
1005
1006 */
1007
1008                 String start_str = "start" + ly_scm2string ($1) + "Music";
1009                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
1010
1011                 SCM start = THIS->lexer_->lookup_identifier (start_str);
1012                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
1013
1014                 Music *startm = unsmob_music (start);
1015                 Music *stopm = unsmob_music (stop);
1016
1017                 SCM ms = SCM_EOL;
1018                 if (stopm) {
1019                         stopm = stopm->clone ();
1020                         ms = scm_cons (stopm->self_scm (), ms);
1021                         scm_gc_unprotect_object (stopm->self_scm ());
1022                 }
1023                 ms = scm_cons ($2->self_scm (), ms);
1024                 scm_gc_unprotect_object ($2->self_scm ());
1025                 if (startm) {
1026                         startm = startm->clone ();
1027                         ms = scm_cons (startm->self_scm (), ms);
1028                         scm_gc_unprotect_object (startm->self_scm ());
1029                 }
1030
1031                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1032                 seq->set_property ("elements", ms);
1033
1034
1035                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1036                 $$->set_property ("element", seq->self_scm ());
1037                 scm_gc_unprotect_object (seq->self_scm ());
1038 #else
1039                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1040                 $$->set_property ("element", $2->self_scm ());
1041                 scm_gc_unprotect_object ($2->self_scm ());
1042 #endif
1043         }
1044         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1045                 $$ = context_spec_music ($2, $4, $6, $5);
1046
1047         }
1048         | CONTEXT simple_string optional_context_mod Music {
1049                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1050         }
1051         | NEWCONTEXT simple_string optional_context_mod Music {
1052                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1053                         $3);
1054         }
1055
1056         | TIMES {
1057                 THIS->push_spot ();
1058         }
1059         /* CONTINUED */
1060                 fraction Music
1061
1062         {
1063                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1064                 Music *mp = $4;
1065
1066                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1067                 $$->set_spot (THIS->pop_spot ());
1068
1069                 $$->set_property ("element", mp->self_scm ());
1070                 scm_gc_unprotect_object (mp->self_scm ());
1071                 $$->set_property ("numerator", scm_int2num (n));
1072                 $$->set_property ("denominator", scm_int2num (d));
1073                 $$->compress (Moment (Rational (n,d)));
1074
1075         }
1076         | Repeated_music                { $$ = $1; }
1077         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1078                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1079                 Music *p = $4;
1080                 Pitch from = *unsmob_pitch ($2);
1081                 Pitch to = *unsmob_pitch ($3);
1082
1083                 p->transpose (interval (from, to));
1084                 $$->set_property ("element", p->self_scm ());
1085                 scm_gc_unprotect_object (p->self_scm ());
1086         }
1087         | APPLY embedded_scm Music  {
1088                 if (!ly_input_procedure_p ($2))
1089                         {
1090                         THIS->parser_error (_ ("\\apply takes function argument"));
1091                         $$ = $3;
1092                         }
1093                 else
1094                         {
1095                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1096                         Music *m = unsmob_music (ret);
1097                         if (!m) {
1098                                 THIS->parser_error ("\\apply must return a Music");
1099                                 m = MY_MAKE_MUSIC ("Music");
1100                                 }
1101                         $$ = m;
1102                         }
1103         }
1104         | NOTES
1105                 {
1106                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1107                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1108         }
1109         Music
1110                 { $$ = $3;
1111                   THIS->lexer_->pop_state ();
1112                 }
1113         | DRUMS
1114                 {
1115                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1116                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1117         }
1118         /* FIXME: This used to be: */
1119         Music
1120 /*      Grouped_music_list */
1121                 { $$ = $3;
1122                   THIS->lexer_->pop_state ();
1123                 }
1124         | FIGURES
1125                 { THIS->lexer_->push_figuredbass_state (); }
1126         /* FIXME: This used to be:
1127         Music
1128         but that breaks web build
1129         */
1130         Grouped_music_list
1131                 {
1132                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1133                   chm->set_property ("element", $3->self_scm ());
1134                   $$ = chm;
1135                   scm_gc_unprotect_object ($3->self_scm ());
1136
1137                   THIS->lexer_->pop_state ();
1138         }
1139         | CHORDS {
1140                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1141                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1142                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1143                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1144
1145         }
1146         /* FIXME:
1147         Music
1148 */
1149         Grouped_music_list
1150         {
1151                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1152                   chm->set_property ("element", $3->self_scm ());
1153                   scm_gc_unprotect_object ($3->self_scm ());
1154                   $$ = chm;
1155
1156                   THIS->lexer_->pop_state ();
1157         }
1158         | LYRICS
1159                 { THIS->lexer_->push_lyric_state (); }
1160         /* FIXME:
1161         Music
1162 */
1163         Grouped_music_list
1164                 {
1165                   $$ = $3;
1166                   THIS->lexer_->pop_state ();
1167         }
1168         | relative_music        { $$ = $1; }
1169         | re_rhythmed_music     { $$ = $1; }
1170         | TAG embedded_scm Music {
1171                 tag_music ($3, $2, THIS->here_input ());
1172                 $$ = $3;
1173         }
1174         ;
1175
1176 relative_music:
1177         RELATIVE absolute_pitch Music {
1178                 Music *m = $3;
1179                 Pitch start = *unsmob_pitch ($2);
1180                 $$ = make_music_relative (start, m);
1181                 scm_gc_unprotect_object (m->self_scm ());
1182         }
1183         | RELATIVE Composite_music {
1184                 Music *m = $2;
1185                 /* FIXME: why is octave==0 and default not middleC? */
1186                 Pitch middle_c (-1, 0, 0);
1187                 $$ = make_music_relative (middle_c, m);
1188                 scm_gc_unprotect_object (m->self_scm ());
1189         }
1190         ;
1191
1192 new_lyrics:
1193         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1194         /*cont */
1195         Grouped_music_list {
1196         /* Can also use Music at the expensive of two S/Rs similar to
1197            \repeat \alternative */
1198                 THIS->lexer_->pop_state ();
1199 #if 0
1200                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1201                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1202                 $$ = music;
1203 #else
1204                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1205 #endif
1206         }
1207         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1208         Grouped_music_list {
1209                 THIS->lexer_->pop_state ();
1210                 $$ = scm_cons ($4->self_scm (), $1);
1211         }
1212         ;
1213
1214 re_rhythmed_music:
1215         ADDLYRICS Music Music {
1216                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1217                 m->set_property ("elements", scm_listify ($2->self_scm (),
1218                         $3->self_scm (), SCM_UNDEFINED));
1219                 scm_gc_unprotect_object ($3->self_scm ());
1220                 scm_gc_unprotect_object ($2->self_scm ());
1221                 $$ = m;
1222         }
1223         | Grouped_music_list new_lyrics {
1224
1225                 /* FIXME: should find out uniqueXXX name from music */
1226                 SCM name = $1->get_property ("context-id");
1227                 //if (name == SCM_EOL)
1228                 if (!ly_c_string_p (name))
1229                         name = scm_makfrom0str ("");
1230
1231                 SCM context = scm_makfrom0str ("Lyrics");
1232                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1233
1234                 SCM lst = SCM_EOL;
1235                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1236                 {
1237                         Music *music = unsmob_music (ly_car (s));
1238                         Music *com = make_lyric_combine_music (name, music);
1239                         Music *csm = context_spec_music (context,
1240                                 get_next_unique_context (), com, SCM_EOL);
1241                         lst = scm_cons (csm->self_scm (), lst);
1242                 }
1243                 /* FIXME: only first lyric music is accepted,
1244                           the rest is junked */
1245                 all->set_property ("elements", scm_cons ($1->self_scm (),
1246                         lst));
1247                 $$ = all;
1248                 scm_gc_unprotect_object ($1->self_scm ());
1249         }
1250         | LYRICSTO string Music {
1251                 Music *music = $3;
1252                 SCM name = $2;
1253                 $$ = make_lyric_combine_music (name, music);
1254                 scm_gc_unprotect_object (music->self_scm ());
1255         }
1256         ;
1257
1258 context_change:
1259         CHANGE STRING '=' STRING  {
1260                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1261                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1262                 t-> set_property ("change-to-id", $4);
1263
1264                 $$ = t;
1265                 $$->set_spot (THIS->here_input ());
1266         }
1267         ;
1268
1269 property_operation:
1270         STRING '=' scalar {
1271                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1272                         scm_string_to_symbol ($1), $3);
1273         }
1274         | UNSET simple_string {
1275                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1276                         scm_string_to_symbol ($2));
1277         }
1278         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1279                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1280                         scm_string_to_symbol ($2), $3, $5);
1281         }
1282         | REVERT simple_string embedded_scm {
1283                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1284                         scm_string_to_symbol ($2), $3);
1285         }
1286         ;
1287
1288 context_def_mod:
1289         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1290         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1291         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1292
1293         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1294         | DENIES { $$ = ly_symbol2scm ("denies"); }
1295
1296         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1297         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1298         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1299         | NAME { $$ = ly_symbol2scm ("context-name"); }
1300         ;
1301
1302 context_mod:
1303         property_operation { $$ = $1; }
1304         | context_def_mod STRING {
1305                 $$ = scm_list_2 ($1, $2);
1306         }
1307         ;
1308
1309 context_prop_spec:
1310         simple_string {
1311                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1312                         scm_string_to_symbol ($1));
1313         }
1314         | simple_string '.' simple_string {
1315                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1316                         scm_string_to_symbol ($3));
1317         }
1318         ;
1319
1320 music_property_def:
1321         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1322                 $$ = property_op_to_music (scm_list_4 (
1323                         ly_symbol2scm ("poppush"),
1324                         ly_cadr ($2),
1325                         $3, $5));
1326                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1327         }
1328         | REVERT context_prop_spec embedded_scm {
1329                 $$ = property_op_to_music (scm_list_3 (
1330                         ly_symbol2scm ("pop"),
1331                         ly_cadr ($2),
1332                         $3));
1333
1334                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1335         }
1336         | SET context_prop_spec '=' scalar {
1337                 $$ = property_op_to_music (scm_list_3 (
1338                         ly_symbol2scm ("assign"),
1339                         ly_cadr ($2),
1340                         $4));
1341                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1342         }
1343         | UNSET context_prop_spec {
1344                 $$ = property_op_to_music (scm_list_2 (
1345                         ly_symbol2scm ("unset"),
1346                         ly_cadr ($2)));
1347                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1348         }
1349         | ONCE music_property_def {
1350                 SCM e = $2->get_property ("element");
1351                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1352                 $$ = $2;
1353
1354         }
1355         ;
1356
1357
1358 string:
1359         STRING {
1360                 $$ = $1;
1361         }
1362         | STRING_IDENTIFIER {
1363                 $$ = $1;
1364         }
1365         | string '+' string {
1366                 $$ = scm_string_append (scm_list_2 ($1, $3));
1367         }
1368         ;
1369
1370 simple_string: STRING {
1371         }
1372         | LYRICS_STRING {
1373         }
1374         ;
1375
1376 scalar: string {
1377         }
1378         | LYRICS_STRING {
1379         }
1380         | bare_int {
1381                 $$ = scm_int2num ($1);
1382         }
1383         | embedded_scm {
1384         }
1385         | full_markup {
1386         }
1387         | DIGIT {
1388                 $$ = scm_int2num ($1);
1389         }
1390         ;
1391
1392 /*
1393 FIXME: remove or fix this comment.  What is `This'?
1394
1395 This is a trick:
1396
1397 Adding pre_events to the simple_element
1398 makes the choice between
1399
1400   string:  STRING
1401
1402 and
1403
1404   simple_element: STRING
1405
1406 a single shift/reduction conflict.
1407
1408 nevertheless, this is not very clean, and we should find a different
1409 solution.
1410
1411 */
1412 pre_events: {
1413                 THIS->push_spot ();
1414         }
1415         ;
1416
1417 event_chord:
1418         pre_events simple_element post_events   {
1419                 SCM elts = $2-> get_property ("elements");
1420
1421                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1422
1423                 $2->set_property ("elements", elts);
1424                 $$ = $2;
1425         }
1426         | command_element
1427         | note_chord_element
1428         ;
1429
1430
1431 note_chord_element:
1432         chord_body optional_notemode_duration post_events
1433         {
1434                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1435                 SCM es = $1->get_property ("elements");
1436                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1437
1438                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1439                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1440                 es = ly_append2 (es, postevs);
1441
1442                 $1-> set_property ("elements", es);
1443                 $$ = $1;
1444         }
1445         ;
1446
1447 chord_open: '<'
1448         ;
1449
1450 chord_close: '>'
1451         ;
1452
1453 simul_open: DOUBLE_ANGLE_OPEN
1454         ;
1455
1456 simul_close: DOUBLE_ANGLE_CLOSE
1457         ;
1458
1459 chord_body:
1460         chord_open chord_body_elements chord_close
1461         {
1462                 $$ = MY_MAKE_MUSIC ("EventChord");
1463                 $$->set_property ("elements",
1464                         scm_reverse_x ($2, SCM_EOL));
1465         }
1466         ;
1467
1468 chord_body_elements:
1469         /* empty */             { $$ = SCM_EOL; }
1470         | chord_body_elements chord_body_element {
1471                 $$ = scm_cons ($2->self_scm (), $1);
1472                 scm_gc_unprotect_object ($2->self_scm ());
1473         }
1474         ;
1475
1476 chord_body_element:
1477         pitch exclamations questions post_events
1478         {
1479                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1480                 n->set_property ("pitch", $1);
1481                 if ($3 % 2)
1482                         n->set_property ("cautionary", SCM_BOOL_T);
1483                 if ($2 % 2 || $3 % 2)
1484                         n->set_property ("force-accidental", SCM_BOOL_T);
1485
1486                 if (ly_c_pair_p ($4)) {
1487                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1488                         n->set_property ("articulations", arts);
1489                 }
1490                 $$ = n;
1491         }
1492         | DRUM_PITCH post_events {
1493                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1494                 n->set_property ("duration", $2);
1495                 n->set_property ("drum-type", $1);
1496                 n->set_spot (THIS->here_input ());
1497
1498                 if (ly_c_pair_p ($2)) {
1499                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1500                         n->set_property ("articulations", arts);
1501                 }
1502                 $$ = n;
1503         }
1504         ;
1505
1506 add_quote:
1507         ADDQUOTE string Music {
1508                 SCM adder = ly_scheme_function ("add-quotable");
1509
1510                 scm_call_2 (adder, $2, $3->self_scm ());
1511                 scm_gc_unprotect_object ($3->self_scm ());
1512         }
1513         ;
1514
1515 command_element:
1516         command_req {
1517                 $$ = MY_MAKE_MUSIC ("EventChord");
1518                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1519                 scm_gc_unprotect_object ($1->self_scm ());
1520
1521                 $$-> set_spot (THIS->here_input ());
1522                 $1-> set_spot (THIS->here_input ());
1523         }
1524         | SKIP duration_length {
1525                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1526                 skip->set_property ("duration", $2);
1527
1528                 $$ = skip;
1529         }
1530         | QUOTE STRING duration_length {
1531                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1532                 SCM evs = SCM_EOL;
1533                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1534                 {
1535                         SCM key = $2; // use symbol?
1536                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1537                 }
1538                 Music *quote = 0;
1539                 if (ly_c_vector_p (evs))
1540                 {
1541                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1542                         quote->set_property ("duration", $3);
1543                         quote->set_property ("quoted-events", evs);
1544                 } else {
1545                         THIS->here_input ().warning (_f ("Can\'t find music"));
1546                         quote = MY_MAKE_MUSIC ("Event");
1547                 }
1548                 quote->set_spot (THIS->here_input ());
1549                 $$ = quote;
1550         }
1551         | OCTAVE { THIS->push_spot (); }
1552           pitch {
1553                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1554                 $$ = m;
1555                 $$->set_spot (THIS->pop_spot ());
1556                 $$->set_property ("pitch", $3);
1557         }
1558         | E_LEFTSQUARE {
1559                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1560                 m->set_property ("span-direction", scm_int2num (START));
1561                 m->set_spot (THIS->here_input ());
1562
1563                 $$ = MY_MAKE_MUSIC ("EventChord");
1564                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1565                 scm_gc_unprotect_object (m->self_scm ());
1566                 $$->set_spot (THIS->here_input ());
1567         }
1568         | E_RIGHTSQUARE {
1569                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1570                 m->set_property ("span-direction", scm_int2num (STOP));
1571                 m->set_spot (THIS->here_input ());
1572
1573                 $$ = MY_MAKE_MUSIC ("EventChord");
1574                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1575                 $$->set_spot (THIS->here_input ());
1576                 scm_gc_unprotect_object (m->self_scm ());
1577         }
1578         | E_BACKSLASH {
1579                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1580                 $$->set_spot (THIS->here_input ());
1581         }
1582         | '|'      {
1583                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1584
1585                 if (Music * m = unsmob_music (pipe))
1586                         $$ = m->clone ();
1587                 else
1588                         $$ = MY_MAKE_MUSIC ("BarCheck");
1589
1590                 $$->set_spot (THIS->here_input ());
1591         }
1592         | TRANSPOSITION pitch {
1593                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1594                                         $2);
1595                 $$->set_spot (THIS-> here_input ());
1596                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1597                         $$, SCM_EOL);
1598         }
1599         | BAR STRING                    {
1600                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1601
1602                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1603                                         t, SCM_EOL);
1604                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1605                 $$->set_spot (THIS->here_input ());
1606                 t->set_spot (THIS->here_input ());
1607         }
1608         | PARTIAL duration_length       {
1609                 Moment m = - unsmob_duration ($2)->get_length ();
1610                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1611                 p->set_spot (THIS->here_input ());
1612                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1613                                         p, SCM_EOL);
1614                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1615                                         p, SCM_EOL);
1616                 $$ = p;
1617         }
1618         | CLEF STRING  {
1619                 SCM proc = ly_scheme_function ("make-clef-set");
1620
1621                 SCM result = scm_call_1 (proc, $2);
1622                 scm_gc_protect_object (result);
1623                 $$ = unsmob_music (result);
1624         }
1625         | TIME_T fraction  {
1626                 SCM proc= ly_scheme_function ("make-time-signature-set");
1627
1628                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1629                 scm_gc_protect_object (result);
1630                 $$ = unsmob_music (result);
1631         }
1632         | MARK scalar {
1633                 SCM proc = ly_scheme_function ("make-mark-set");
1634
1635                 SCM result = scm_call_1 (proc, $2);
1636                 scm_gc_protect_object (result);
1637                 $$ = unsmob_music (result);
1638         }
1639         ;
1640
1641 command_req:
1642         BREATHE {
1643                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1644         }
1645         | E_TILDE {
1646                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1647         }
1648         | MARK DEFAULT  {
1649                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1650                 $$ = m;
1651         }
1652         | tempo_event {
1653                 $$ = $1;
1654         }
1655         | KEY DEFAULT {
1656                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1657                 $$ = key;
1658         }
1659         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1660
1661                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1662                 if (scm_ilength ($3) > 0)
1663                 {
1664                         key->set_property ("pitch-alist", $3);
1665                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1666                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1667                 } else {
1668                         THIS->parser_error (_ ("Second argument must be pitch list."));
1669                 }
1670
1671                 $$ = key;
1672         }
1673         ;
1674
1675 post_events:
1676         /* empty */ {
1677                 $$ = SCM_EOL;
1678         }
1679         | post_events post_event {
1680                 $2->set_spot (THIS->here_input ());
1681                 $$ = scm_cons ($2->self_scm (), $$);
1682                 scm_gc_unprotect_object ($2->self_scm ());
1683         }
1684         | post_events tagged_post_event {
1685                 $2 -> set_spot (THIS->here_input ());
1686                 $$ = scm_cons ($2->self_scm (), $$);
1687                 scm_gc_unprotect_object ($2->self_scm ());
1688         }
1689         ;
1690
1691
1692 tagged_post_event:
1693         '-' TAG embedded_scm post_event {
1694                 tag_music ($4, $3, THIS->here_input ());
1695                 $$ = $4;
1696         }
1697         ;
1698
1699 post_event:
1700         direction_less_event {
1701                 $$ = $1;
1702         }
1703         | HYPHEN {
1704                 if (!THIS->lexer_->is_lyric_state ())
1705                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1706                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1707         }
1708         | EXTENDER {
1709                 if (!THIS->lexer_->is_lyric_state ())
1710                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1711                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1712         }
1713         | script_dir direction_reqd_event {
1714                 if ($1)
1715                         $2->set_property ("direction", scm_int2num ($1));
1716                 $$ = $2;
1717         }
1718         | script_dir direction_less_event {
1719                 if ($1)
1720                         $2->set_property ("direction", scm_int2num ($1));
1721                 $$ = $2;
1722         }
1723         | string_number_event
1724         ;
1725
1726 string_number_event:
1727         E_UNSIGNED {
1728                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1729                 s->set_property ("string-number", scm_int2num ($1));
1730                 s->set_spot (THIS->here_input ());
1731                 $$ = s;
1732         }
1733         ;
1734
1735
1736 direction_less_event:
1737         '['  {
1738
1739
1740 /*
1741
1742 TODO: should take all these defs out of the parser, adn make use
1743 configurable, i.e.
1744
1745
1746 (set-articulation '~ "trill")
1747
1748 */
1749                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1750                 m->set_spot (THIS->here_input ());
1751                 m->set_property ("span-direction", scm_int2num (START));
1752                 $$ = m;
1753         }
1754         | ']'  {
1755                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1756                 m->set_spot (THIS->here_input ());
1757                 m->set_property ("span-direction", scm_int2num (STOP));
1758                 $$ = m;
1759         }
1760         | '~' {
1761                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1762                 m->set_spot (THIS->here_input ());
1763                 $$ = m;
1764         }
1765         | close_event {
1766                 $$ = $1;
1767                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1768                         scm_int2num (START));
1769         }
1770         | open_event {
1771                 $$ = $1;
1772                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1773                         scm_int2num (STOP));
1774         }
1775         | EVENT_IDENTIFIER      {
1776                 $$ = unsmob_music ($1);
1777         }
1778         | tremolo_type  {
1779                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1780                a->set_spot (THIS->here_input ());
1781                a->set_property ("tremolo-type", scm_int2num ($1));
1782                $$ = a;
1783         }
1784         ;
1785
1786 direction_reqd_event:
1787         gen_text_def {
1788                 $$ = $1;
1789         }
1790         | script_abbreviation {
1791                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1792                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1793                 if (ly_c_string_p (s))
1794                         a->set_property ("articulation-type", s);
1795                 else THIS->parser_error (_ ("Expecting string as script definition"));
1796                 $$ = a;
1797         }
1798         ;
1799
1800 oct_check:
1801         /**/ { $$ = SCM_EOL; }
1802         | '='  { $$ = scm_int2num (0); }
1803         | '=' sub_quotes { $$ = scm_int2num ($2); }
1804         | '=' sup_quotes { $$ = scm_int2num ($2); }
1805         ;
1806
1807 sup_quotes:
1808         '\'' {
1809                 $$ = 1;
1810         }
1811         | sup_quotes '\'' {
1812                 $$ ++;
1813         }
1814         ;
1815
1816 sub_quotes:
1817         ',' {
1818                 $$ = 1;
1819         }
1820         | sub_quotes ',' {
1821                 $$++;
1822         }
1823         ;
1824
1825 steno_pitch:
1826         NOTENAME_PITCH  {
1827                 $$ = $1;
1828         }
1829         | NOTENAME_PITCH sup_quotes     {
1830                 Pitch p = *unsmob_pitch ($1);
1831                 p = p.transposed (Pitch ($2,0,0));
1832                 $$ = p.smobbed_copy ();
1833         }
1834         | NOTENAME_PITCH sub_quotes      {
1835                 Pitch p =* unsmob_pitch ($1);
1836                 p = p.transposed (Pitch (-$2,0,0));
1837                 $$ = p.smobbed_copy ();
1838         }
1839         ;
1840
1841 /*
1842 ugh. duplication
1843 */
1844
1845 steno_tonic_pitch:
1846         TONICNAME_PITCH {
1847                 $$ = $1;
1848         }
1849         | TONICNAME_PITCH sup_quotes    {
1850                 Pitch p = *unsmob_pitch ($1);
1851                 p = p.transposed (Pitch ($2,0,0));
1852                 $$ = p.smobbed_copy ();
1853         }
1854         | TONICNAME_PITCH sub_quotes     {
1855                 Pitch p =* unsmob_pitch ($1);
1856
1857                 p = p.transposed (Pitch (-$2,0,0));
1858                 $$ = p.smobbed_copy ();
1859         }
1860         ;
1861
1862 pitch:
1863         steno_pitch {
1864                 $$ = $1;
1865         }
1866         ;
1867
1868 pitch_also_in_chords:
1869         pitch
1870         | steno_tonic_pitch
1871         ;
1872
1873 close_event:
1874         '('     {
1875                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1876                 $$ = s;
1877                 s->set_spot (THIS->here_input ());
1878         }
1879         | E_OPEN        {
1880                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1881                 $$ = s;
1882                 s->set_spot (THIS->here_input ());
1883         }
1884         | E_SMALLER {
1885                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1886                 $$ = s;
1887                 s->set_spot (THIS->here_input ());
1888         }
1889         | E_BIGGER {
1890                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1891                 $$ = s;
1892                 s->set_spot (THIS->here_input ());
1893         }
1894         ;
1895
1896
1897 open_event:
1898         E_EXCLAMATION   {
1899                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1900                 s->set_spot (THIS->here_input ());
1901
1902                 $$ = s;
1903         }
1904         | ')'   {
1905                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1906                 $$ = s;
1907                 s->set_spot (THIS->here_input ());
1908
1909         }
1910         | E_CLOSE       {
1911                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1912                 $$ = s;
1913                 s->set_property ("span-type",
1914                         scm_makfrom0str ("phrasing-slur"));
1915                 s->set_spot (THIS->here_input ());
1916         }
1917         ;
1918
1919 gen_text_def:
1920         full_markup {
1921                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1922                 t->set_property ("text", $1);
1923                 t->set_spot (THIS->here_input ());
1924                 $$ = t;
1925         }
1926         | string {
1927                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1928                 t->set_property ("text",
1929                         make_simple_markup (THIS->lexer_->encoding (), $1));
1930                 t->set_spot (THIS->here_input ());
1931                 $$ = t;
1932
1933         }
1934         | DIGIT {
1935                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1936                 t->set_property ("digit", scm_int2num ($1));
1937                 t->set_spot (THIS->here_input ());
1938                 $$ = t;
1939         }
1940         ;
1941
1942 script_abbreviation:
1943         '^'             {
1944                 $$ = scm_makfrom0str ("Hat");
1945         }
1946         | '+'           {
1947                 $$ = scm_makfrom0str ("Plus");
1948         }
1949         | '-'           {
1950                 $$ = scm_makfrom0str ("Dash");
1951         }
1952         | '|'           {
1953                 $$ = scm_makfrom0str ("Bar");
1954         }
1955         | '>'           {
1956                 $$ = scm_makfrom0str ("Larger");
1957         }
1958         | '.'           {
1959                 $$ = scm_makfrom0str ("Dot");
1960         }
1961         | '_' {
1962                 $$ = scm_makfrom0str ("Underscore");
1963         }
1964         ;
1965
1966 script_dir:
1967         '_'     { $$ = DOWN; }
1968         | '^'   { $$ = UP; }
1969         | '-'   { $$ = CENTER; }
1970         ;
1971
1972
1973 absolute_pitch:
1974         steno_pitch     {
1975                 $$ = $1;
1976         }
1977         ;
1978
1979 duration_length:
1980         multiplied_duration {
1981                 $$ = $1;
1982         }
1983         ;
1984
1985 optional_notemode_duration:
1986         {
1987                 Duration dd = THIS->default_duration_;
1988                 $$ = dd.smobbed_copy ();
1989
1990                 THIS->beam_check ($$);
1991         }
1992         | multiplied_duration   {
1993                 $$ = $1;
1994                 THIS->default_duration_ = *unsmob_duration ($$);
1995
1996                 THIS->beam_check ($$);
1997         }
1998         ;
1999
2000 steno_duration:
2001         bare_unsigned dots              {
2002                 int len = 0;
2003                 if (!is_duration ($1))
2004                         THIS->parser_error (_f ("not a duration: %d", $1));
2005                 else
2006                         len = intlog2 ($1);
2007
2008                 $$ = Duration (len, $2).smobbed_copy ();
2009         }
2010         | DURATION_IDENTIFIER dots      {
2011                 Duration *d = unsmob_duration ($1);
2012                 Duration k (d->duration_log (), d->dot_count () + $2);
2013                 *d = k;
2014                 $$ = $1;
2015         }
2016         ;
2017
2018 multiplied_duration:
2019         steno_duration {
2020                 $$ = $1;
2021         }
2022         | multiplied_duration '*' bare_unsigned {
2023                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2024         }
2025         | multiplied_duration '*' FRACTION {
2026                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2027
2028                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2029         }
2030         ;
2031
2032 fraction:
2033         FRACTION { $$ = $1; }
2034         | UNSIGNED '/' UNSIGNED {
2035                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2036         }
2037         ;
2038
2039 dots:
2040         /* empty */     {
2041                 $$ = 0;
2042         }
2043         | dots '.' {
2044                 $$ ++;
2045         }
2046         ;
2047
2048 tremolo_type:
2049         ':'     {
2050                 $$ = 0;
2051         }
2052         | ':' bare_unsigned {
2053                 if (!is_duration ($2))
2054                         THIS->parser_error (_f ("not a duration: %d", $2));
2055                 $$ = $2;
2056         }
2057         ;
2058
2059 bass_number:
2060         DIGIT   {
2061                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2062         }
2063         | UNSIGNED {
2064                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2065         }
2066         | STRING { $$ = $1; }
2067         ;
2068
2069 bass_mod:
2070         '-'     { $$ = -2; }
2071         | '+'   { $$ = 2; }
2072         | '!'   { $$ = 0; }
2073         ;
2074
2075 bass_figure:
2076         FIGURE_SPACE {
2077                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2078                 $$ = bfr->self_scm ();
2079                 scm_gc_unprotect_object ($$);
2080         }
2081         | bass_number  {
2082                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2083                 $$ = bfr->self_scm ();
2084
2085                 bfr->set_property ("figure", $1);
2086
2087                 scm_gc_unprotect_object ($$);
2088         }
2089         | bass_figure bass_mod {
2090                 Music *m = unsmob_music ($1);
2091                 if ($2) {
2092                         SCM salter = m->get_property ("alteration");
2093                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2094                         m->set_property ("alteration",
2095                                 scm_int2num (alter + $2));
2096                 } else {
2097                         m->set_property ("alteration", scm_int2num (0));
2098                 }
2099         }
2100         ;
2101
2102 br_bass_figure:
2103         '[' bass_figure {
2104                 $$ = $2;
2105                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2106         }
2107         | bass_figure   {
2108                 $$ = $1;
2109         }
2110         | br_bass_figure ']' {
2111                 $$ = $1;
2112                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2113         }
2114         ;
2115
2116 figure_list:
2117         /**/            {
2118                 $$ = SCM_EOL;
2119         }
2120         | figure_list br_bass_figure {
2121                 $$ = scm_cons ($2, $1);
2122         }
2123         ;
2124
2125 figure_spec:
2126         FIGURE_OPEN figure_list FIGURE_CLOSE {
2127                 Music *m = MY_MAKE_MUSIC ("EventChord");
2128                 $2 = scm_reverse_x ($2, SCM_EOL);
2129                 m->set_property ("elements", $2);
2130                 $$ = m->self_scm ();
2131         }
2132         ;
2133
2134
2135 optional_rest:
2136         /**/   { $$ = 0; }
2137         | REST { $$ = 1; }
2138         ;
2139
2140 simple_element:
2141         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2142
2143                 Input i = THIS->pop_spot ();
2144                 if (!THIS->lexer_->is_note_state ())
2145                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2146
2147                 Music *n = 0;
2148                 if ($6)
2149                         n = MY_MAKE_MUSIC ("RestEvent");
2150                 else
2151                         n = MY_MAKE_MUSIC ("NoteEvent");
2152
2153                 n->set_property ("pitch", $1);
2154                 n->set_property ("duration", $5);
2155
2156                 if (ly_c_number_p ($4))
2157                 {
2158                         int q = ly_scm2int ($4);
2159                         n->set_property ("absolute-octave", scm_int2num (q-1));
2160                 }
2161
2162                 if ($3 % 2)
2163                         n->set_property ("cautionary", SCM_BOOL_T);
2164                 if ($2 % 2 || $3 % 2)
2165                         n->set_property ("force-accidental", SCM_BOOL_T);
2166
2167                 Music *v = MY_MAKE_MUSIC ("EventChord");
2168                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2169                 scm_gc_unprotect_object (n->self_scm ());
2170
2171                 v->set_spot (i);
2172                 n->set_spot (i);
2173                 $$ = v;
2174         }
2175         | DRUM_PITCH optional_notemode_duration {
2176                 Input i = THIS->pop_spot ();
2177
2178                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2179                 n->set_property ("duration", $2);
2180                 n->set_property ("drum-type", $1);
2181
2182                 Music *v = MY_MAKE_MUSIC ("EventChord");
2183                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2184                 scm_gc_unprotect_object (n->self_scm ());
2185                 v->set_spot (i);
2186                 n->set_spot (i);
2187                 $$ = v;
2188
2189         }
2190         | figure_spec optional_notemode_duration {
2191                 Music *m = unsmob_music ($1);
2192                 Input i = THIS->pop_spot ();
2193                 m->set_spot (i);
2194                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2195                 {
2196                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2197                 }
2198                 $$ = m;
2199         }
2200         | RESTNAME optional_notemode_duration           {
2201
2202                 Input i = THIS->pop_spot ();
2203                 Music *ev = 0;
2204                 if (ly_scm2string ($1) == "s") {
2205                         /* Space */
2206                         ev = MY_MAKE_MUSIC ("SkipEvent");
2207                   }
2208                 else {
2209                         ev = MY_MAKE_MUSIC ("RestEvent");
2210
2211                     }
2212                 ev->set_property ("duration", $2);
2213                 ev->set_spot (i);
2214                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2215                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2216                 velt->set_spot (i);
2217
2218                 scm_gc_unprotect_object (ev->self_scm ());
2219
2220                 $$ = velt;
2221         }
2222         | MULTI_MEASURE_REST optional_notemode_duration         {
2223                 THIS->pop_spot ();
2224
2225                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2226                 SCM mus = scm_call_2 (proc, $2,
2227                         make_input (THIS->here_input ()));
2228                 scm_gc_protect_object (mus);
2229                 $$ = unsmob_music (mus);
2230         }
2231
2232         | lyric_element optional_notemode_duration      {
2233                 Input i = THIS->pop_spot ();
2234                 if (!THIS->lexer_->is_lyric_state ())
2235                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2236
2237                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2238                 lreq->set_property ("text", $1);
2239                 lreq->set_property ("duration",$2);
2240                 lreq->set_spot (i);
2241                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2242                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2243
2244                 $$= velt;
2245         }
2246         | new_chord {
2247                 THIS->pop_spot ();
2248
2249                 if (!THIS->lexer_->is_chord_state ())
2250                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2251                 $$ = unsmob_music ($1);
2252         }
2253         ;
2254
2255 lyric_element:
2256         /* FIXME: lyric flavoured markup would be better */
2257         full_markup {
2258         }
2259         | LYRICS_STRING {
2260         }
2261         ;
2262
2263 new_chord:
2264         steno_tonic_pitch optional_notemode_duration   {
2265                 $$ = make_chord ($1, $2, SCM_EOL);
2266         }
2267         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2268                 SCM its = scm_reverse_x ($4, SCM_EOL);
2269                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2270         }
2271         ;
2272
2273 chord_items:
2274         /**/ {
2275                 $$ = SCM_EOL;
2276         }
2277         | chord_items chord_item {
2278                 $$ = scm_cons ($2, $$);
2279         }
2280         ;
2281
2282 chord_separator:
2283         CHORD_COLON {
2284                 $$ = ly_symbol2scm ("chord-colon");
2285         }
2286         | CHORD_CARET {
2287                 $$ = ly_symbol2scm ("chord-caret");
2288         }
2289         | CHORD_SLASH steno_tonic_pitch {
2290                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2291         }
2292         | CHORD_BASS steno_tonic_pitch {
2293                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2294         }
2295         ;
2296
2297 chord_item:
2298         chord_separator {
2299                 $$ = $1;
2300         }
2301         | step_numbers {
2302                 $$ = scm_reverse_x ($1, SCM_EOL);
2303         }
2304         | CHORD_MODIFIER  {
2305                 $$ = $1;
2306         }
2307         ;
2308
2309 step_numbers:
2310         step_number { $$ = scm_cons ($1, SCM_EOL); }
2311         | step_numbers '.' step_number {
2312                 $$ = scm_cons ($3, $$);
2313         }
2314         ;
2315
2316 step_number:
2317         bare_unsigned {
2318                 $$ = make_chord_step ($1, 0);
2319         }
2320         | bare_unsigned '+' {
2321                 $$ = make_chord_step ($1, SHARP);
2322         }
2323         | bare_unsigned CHORD_MINUS {
2324                 $$ = make_chord_step ($1, FLAT);
2325         }
2326         ;
2327
2328 /*
2329         UTILITIES
2330
2331 TODO: should deprecate in favor of Scheme?
2332
2333  */
2334 number_expression:
2335         number_expression '+' number_term {
2336                 $$ = scm_sum ($1, $3);
2337         }
2338         | number_expression '-' number_term {
2339                 $$ = scm_difference ($1, $3);
2340         }
2341         | number_term
2342         ;
2343
2344 number_term:
2345         number_factor {
2346                 $$ = $1;
2347         }
2348         | number_factor '*' number_factor {
2349                 $$ = scm_product ($1, $3);
2350         }
2351         | number_factor '/' number_factor {
2352                 $$ = scm_divide ($1, $3);
2353         }
2354         ;
2355
2356 number_factor:
2357         '-'  number_factor { /* %prec UNARY_MINUS */
2358                 $$ = scm_difference ($2, SCM_UNDEFINED);
2359         }
2360         | bare_number
2361         ;
2362
2363
2364 bare_number:
2365         UNSIGNED        {
2366                 $$ = scm_int2num ($1);
2367         }
2368         | REAL          {
2369                 $$ = $1;
2370         }
2371         | NUMBER_IDENTIFIER             {
2372                 $$ = $1;
2373         }
2374         | REAL NUMBER_IDENTIFIER        {
2375                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2376         }
2377         | UNSIGNED NUMBER_IDENTIFIER    {
2378                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2379         }
2380         ;
2381
2382
2383 bare_unsigned:
2384         UNSIGNED {
2385                         $$ = $1;
2386         }
2387         | DIGIT {
2388                 $$ = $1;
2389         }
2390         ;
2391
2392 bare_int:
2393         bare_number {
2394                 if (scm_integer_p ($1) == SCM_BOOL_T)
2395                 {
2396                         int k = ly_scm2int ($1);
2397                         $$ = k;
2398                 } else
2399                 {
2400                         THIS->parser_error (_ ("need integer number arg"));
2401                         $$ = 0;
2402                 }
2403         }
2404         | '-' bare_int {
2405                 $$ = -$2;
2406         }
2407         ;
2408
2409 exclamations:
2410                 { $$ = 0; }
2411         | exclamations '!'      { $$ ++; }
2412         ;
2413
2414 questions:
2415                 { $$ = 0; }
2416         | questions '?' { $$ ++; }
2417         ;
2418
2419
2420
2421 full_markup:
2422         MARKUP_IDENTIFIER {
2423                 $$ = $1;
2424         }
2425         | MARKUP
2426                 { THIS->lexer_->push_markup_state (); }
2427         markup
2428                 { $$ = $3;
2429                   THIS->lexer_->pop_state ();
2430                 }
2431         ;
2432
2433
2434 /*
2435 This should be done more dynamically if possible.
2436 */
2437 markup:
2438         STRING {
2439                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2440         }
2441         | MARKUP_HEAD_EMPTY {
2442                 $$ = scm_list_1 ($1);
2443         }
2444         | MARKUP_HEAD_MARKUP0 markup {
2445                 $$ = scm_list_2 ($1, $2);
2446         }
2447         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2448                 $$ = scm_list_3 ($1, $2, $3);
2449         }
2450         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2451                 $$ = scm_list_3 ($1, $2, $3);
2452         }
2453         | markup_line {
2454                 $$ = $1;
2455         }
2456         | MARKUP_HEAD_LIST0 markup_list {
2457                 $$ = scm_list_2 ($1,$2);
2458         }
2459         | MARKUP_HEAD_SCM0 embedded_scm {
2460                 $$ = scm_list_2 ($1, $2);
2461         }
2462         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2463                 $$ = scm_list_4 ($1, $2, $3, $4);
2464         }
2465         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2466                 $$ = scm_list_4 ($1, $2, $3, $4);
2467         }
2468         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2469                 $$ = scm_list_3 ($1, $2, $3);
2470         }
2471         | MARKUP_IDENTIFIER {
2472                 $$ = $1;
2473         }
2474         | STRING_IDENTIFIER {
2475                 $$ = $1;
2476         }
2477         | score_block {
2478                 /* WIP this is a bit arbitrary,
2479                    we should also allow \book or Composite_music.
2480                    However, you'd typically want to change paper
2481                    settings, and need a \score block anyway.  */
2482                 Score *score = $1;
2483                 Book *book = new Book;
2484                 book->scores_.push (score);
2485                 extern Music_output_def* get_paper (My_lily_parser *parser);
2486                 Music_output_def *paper = get_paper (THIS);
2487                 SCM s = book->to_stencil (paper, THIS->header_);
2488                 scm_gc_unprotect_object (score->self_scm ());
2489                 scm_gc_unprotect_object (book->self_scm ());
2490                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2491         }
2492         ;
2493
2494 markup_list:
2495         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2496         ;
2497
2498 markup_line:
2499         '{' markup_list_body '}' {
2500                 SCM line = ly_scheme_function ("line-markup");
2501
2502                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2503         }
2504         ;
2505
2506 markup_list_body:
2507         /**/ {  $$ = SCM_EOL; }
2508         | markup_list_body markup {
2509                 $$ = scm_cons ($2, $1);
2510         }
2511         ;
2512
2513
2514 %%
2515
2516 void
2517 My_lily_parser::set_yydebug (bool )
2518 {
2519 #if 0
2520         yydebug = 1;
2521 #endif
2522 }
2523
2524 void
2525 My_lily_parser::do_yyparse ()
2526 {
2527         yyparse ((void*)this);
2528 }
2529
2530
2531 /*
2532 Should make this optional?    It will also complain when you do
2533
2534         [s4]
2535
2536 which is entirely legitimate.
2537
2538 Or we can scrap it. Barchecks should detect wrong durations, and
2539 skipTypesetting speeds it up a lot.
2540 */
2541
2542 void
2543 My_lily_parser::beam_check (SCM dur)
2544 {
2545   Duration *d = unsmob_duration (dur);
2546   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2547     {
2548       Music *m = unsmob_music (last_beam_start_);
2549       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2550     }
2551   last_beam_start_ = SCM_EOL;
2552 }
2553
2554
2555
2556
2557 /*
2558
2559 It is a little strange to have this function in this file, but
2560 otherwise, we have to import music classes into the lexer.
2561
2562 */
2563 int
2564 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2565 {
2566         if (ly_c_string_p (sid)) {
2567                 *destination = sid;
2568                 return STRING_IDENTIFIER;
2569         } else if (ly_c_number_p (sid)) {
2570                 *destination = sid;
2571                 return NUMBER_IDENTIFIER;
2572         } else if (unsmob_context_def (sid)) {
2573                 *destination = unsmob_context_def (sid)->clone_scm ();
2574                 return CONTEXT_DEF_IDENTIFIER;
2575         } else if (unsmob_score (sid)) {
2576                 Score *score = new Score (*unsmob_score (sid));
2577                 *destination = score->self_scm ();
2578                 return SCORE_IDENTIFIER;
2579         } else if (Music *mus = unsmob_music (sid)) {
2580                 mus = mus->clone ();
2581                 *destination = mus->self_scm ();
2582                 unsmob_music (*destination)->
2583                         set_property ("origin", make_input (last_input_));
2584                 return dynamic_cast<Event*> (mus)
2585                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2586         } else if (unsmob_duration (sid)) {
2587                 *destination = unsmob_duration (sid)->smobbed_copy ();
2588                 return DURATION_IDENTIFIER;
2589         } else if (unsmob_music_output_def (sid)) {
2590                 Music_output_def *p = unsmob_music_output_def (sid);
2591                 p = p->clone ();
2592
2593                 *destination = p->self_scm ();
2594                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2595         } else if (Text_item::markup_p (sid)) {
2596                 *destination = sid;
2597                 return MARKUP_IDENTIFIER;
2598         }
2599
2600         return -1;
2601 }
2602
2603 Music *
2604 property_op_to_music (SCM op)
2605 {
2606         Music *m = 0;
2607         SCM tag = ly_car (op);
2608         SCM symbol = ly_cadr (op);
2609         SCM args = ly_cddr (op);
2610         SCM grob_val = SCM_UNDEFINED;
2611         SCM grob_sym = SCM_UNDEFINED;
2612         SCM val = SCM_UNDEFINED;
2613
2614         if (tag == ly_symbol2scm ("assign"))
2615                 {
2616                 m = MY_MAKE_MUSIC ("PropertySet");
2617                 val = ly_car (args);
2618                 }
2619         else if (tag == ly_symbol2scm ("unset"))
2620                 m = MY_MAKE_MUSIC ("PropertyUnset");
2621         else if (tag == ly_symbol2scm ("poppush")
2622                  || tag == ly_symbol2scm ("push"))
2623                 {
2624                 m = MY_MAKE_MUSIC ("OverrideProperty");
2625                 grob_sym = ly_car (args);
2626                 grob_val = ly_cadr (args);
2627                 }
2628         else if (tag == ly_symbol2scm ("pop")) {
2629                 m = MY_MAKE_MUSIC ("RevertProperty");
2630                 grob_sym = ly_car (args);
2631                 }
2632
2633         m->set_property ("symbol", symbol);
2634
2635         if (val != SCM_UNDEFINED)
2636                 m->set_property ("value", val);
2637         if (grob_val != SCM_UNDEFINED)
2638                 m->set_property ("grob-value", grob_val);
2639
2640         if (grob_sym != SCM_UNDEFINED)
2641                 {
2642                 bool itc = internal_type_checking_global_b;
2643                 /* UGH.
2644                 */
2645                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2646                 if (autobeam)
2647                         internal_type_checking_global_b = false;
2648                 m->set_property ("grob-property", grob_sym);
2649                 if (autobeam)
2650                         internal_type_checking_global_b = itc;
2651                 }
2652
2653         if (op == ly_symbol2scm ("poppush"))
2654                 m->set_property ("pop-first", SCM_BOOL_T);
2655
2656
2657         return m;
2658 }
2659
2660 Music*
2661 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2662 {
2663         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2664
2665         csm->set_property ("element", m->self_scm ());
2666         scm_gc_unprotect_object (m->self_scm ());
2667
2668         csm->set_property ("context-type",
2669                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2670         csm->set_property ("property-operations", ops);
2671
2672         if (ly_c_string_p (id))
2673                 csm->set_property ("context-id", id);
2674         return csm;
2675 }
2676
2677 SCM
2678 get_next_unique_context ()
2679 {
2680         static int new_context_count;
2681         char s[1024];
2682         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2683         return scm_makfrom0str (s);
2684 }
2685