lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLY
 251 %token APPLYCONTEXT
 252 %token APPLYOUTPUT
 253 %token AUTOCHANGE
 254 %token BAR
 255 %token BOOK
 256 %token BREATHE
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONSISTSEND
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 272 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 273 %token GRACE
 274 %token ACCIACCATURA
 275 %token APPOGGIATURA
 276 %token GROBDESCRIPTIONS
 277 %token HEADER
 278 %token HYPHEN
 279 %token INVALID
 280 %token KEY
 281 %token LYRICS
 282 %token LYRICS_STRING
 283 %token MARK
 284 %token MIDI
 285 %token MULTI_MEASURE_REST
 286 %token NAME
 287 %token NEWCONTEXT
 288 %token NOTES
 289 %token OCTAVE
 290 %token ONCE
 291 %token OVERRIDE SET REVERT
 292 %token PAPER
 293 %token PARTCOMBINE
 294 %token PARTIAL
 295 %token QUOTE
 296 %token RELATIVE
 297 %token REMOVE
 298 %token REPEAT
 299 %token REST
 300 %token SCM_T
 301 %token SCORE
 302 %token SEQUENTIAL
 303 %token NEWLYRICS
 304 %token SIMULTANEOUS
 305 %token SKIP
 306 %token SPANREQUEST
 307 %token TAG
 308 %token TEMPO
 309 %token TIMES
 310 %token TIME_T
 311 %token TRANSPOSE
 312 %token TRANSPOSITION
 313 %token TYPE
 314 %token UNSET
 315 %token WITH
 316
 317 /* escaped */
 318 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 319 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 320 %token E_BACKSLASH
 321 %token <i> E_UNSIGNED
 322 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 323 %token FIGURE_SPACE
 324
 325 %token <i>      DIGIT
 326 %token <scm>    NOTENAME_PITCH
 327 %token <scm>    TONICNAME_PITCH
 328 %token <scm>    CHORDMODIFIER_PITCH
 329 %token <scm>    DURATION_IDENTIFIER
 330 %token <scm>    FRACTION
 331 %token <id>     IDENTIFIER
 332 %token DRUMS
 333 %token <scm>    DRUM_PITCH
 334 %token <scm>    CHORD_MODIFIER
 335 %token <scm>    SCORE_IDENTIFIER
 336 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 337 %token <scm>    NUMBER_IDENTIFIER
 338 %token <scm>    EVENT_IDENTIFIER
 339 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 340 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm>    STRING
 343 %token <scm>    SCM_T
 344 %token <i>      UNSIGNED
 345 %token <scm>   REAL
 346
 347 %token MARKUP
 348 %token <scm> MARKUP_HEAD_MARKUP0
 349 %token <scm> MARKUP_HEAD_EMPTY
 350 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0
 352 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 355 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 356
 357 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 358 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 359
 360 %type <book>    book_block book_body
 361 %type <i>       exclamations questions dots optional_rest
 362 %type <i>        bass_mod
 363 %type <scm>     grace_head
 364 %type <scm>     oct_check
 365 %type <scm>     context_mod_list
 366 %type <scm>     lyric_element
 367 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 368 %type <scm>     new_lyrics
 369 %type <outputdef> output_def
 370 %type <scm>     lilypond_header lilypond_header_body
 371 %type <music>   open_event close_event
 372 %type <i>       sub_quotes sup_quotes
 373 %type <music>   toplevel_music
 374 %type <music>   simple_element event_chord command_element
 375 %type <music>   Composite_music Simple_music Prefix_composite_music
 376 %type <music>   Grouped_music_list
 377 %type <music>   Repeated_music
 378 %type <scm>     Alternative_music
 379 %type <i>       tremolo_type
 380 %type <i>       bare_int  bare_unsigned
 381 %type <i>       script_dir
 382 %type <scm>     identifier_init
 383 %type <scm>     simple_string
 384
 385 %type <music>   note_chord_element chord_body chord_body_element
 386 %type <scm>     chord_body_elements
 387 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 388
 389 %type <scm>     post_events
 390 %type <music>   gen_text_def direction_less_event direction_reqd_event
 391 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 392 %type <scm>     steno_tonic_pitch
 393 %type <scm>     duration_length fraction
 394
 395 %type <scm>     chord_item chord_items chord_separator new_chord
 396 %type <scm>     step_number step_numbers
 397
 398 %type <scm>     embedded_scm scalar
 399 %type <music>   Music Sequential_music Simultaneous_music
 400 %type <music>   relative_music re_rhythmed_music
 401 %type <music>   music_property_def context_change
 402 %type <scm>     context_prop_spec
 403 %type <scm>     Music_list
 404 %type <scm>     property_operation
 405 %type <scm>     context_mod context_def_mod optional_context_mod
 406 %type <outputdef>       music_output_def_body music_output_def_head
 407 %type <music>   post_event tagged_post_event
 408 %type <music>   command_req
 409 %type <music>   string_number_event
 410 %type <scm>     string bare_number number_expression number_term number_factor
 411 %type <score>   score_block score_body
 412
 413 %type <scm>     context_def_spec_block context_def_spec_body
 414 %type <music>   tempo_event
 415 %type <scm>     script_abbreviation
 416
 417
 418
 419 %left '-' '+'
 420
 421 /* We don't assign precedence to / and *, because we might need varied
 422 prec levels in different prods */
 423
 424 %left UNARY_MINUS
 425
 426 %%
 427
 428 lilypond:       /* empty */
 429         | lilypond toplevel_expression {
 430         }
 431         | lilypond assignment {
 432         }
 433         | lilypond error {
 434                 THIS->error_level_ = 1;
 435         }
 436         | lilypond INVALID      {
 437                 THIS->error_level_ = 1;
 438         }
 439         ;
 440
 441 toplevel_expression:
 442         lilypond_header {
 443                 THIS->header_ = $1;
 444         }
 445         | add_quote {
 446
 447         }
 448         | book_block {
 449                 Book *book = $1;
 450                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 451                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 452                 scm_gc_unprotect_object (book->self_scm ());
 453         }
 454         | score_block {
 455                 Score *score = $1;
 456
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 459                 scm_gc_unprotect_object (score->self_scm ());
 460         }
 461         | toplevel_music {
 462                 Music *music = $1;
 463                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 464                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 465                 scm_gc_unprotect_object (music->self_scm ());
 466         }
 467         | output_def {
 468                 SCM id = SCM_EOL;
 469                 if (dynamic_cast<Paper_def*> ($1))
 470                         id = scm_makfrom0str ("$defaultpaper");
 471                 else if (dynamic_cast<Midi_def*> ($1))
 472                         id = scm_makfrom0str ("$defaultmidi");
 473                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 474                 scm_gc_unprotect_object ($1->self_scm ());
 475         }
 476         ;
 477
 478 toplevel_music:
 479         Composite_music {
 480         }
 481         ;
 482
 483 embedded_scm:
 484         SCM_T
 485         | SCM_IDENTIFIER
 486         ;
 487
 488
 489 lilypond_header_body:
 490         {
 491                 $$ = ly_make_anonymous_module ();
 492                 THIS->lexer_->add_scope ($$);
 493         }
 494         | lilypond_header_body assignment  {
 495
 496         }
 497         ;
 498
 499 lilypond_header:
 500         HEADER '{' lilypond_header_body '}'     {
 501                 $$ = THIS->lexer_->remove_scope ();
 502         }
 503         ;
 504
 505
 506 /*
 507         DECLARATIONS
 508 */
 509 assignment:
 510         STRING {
 511                 THIS->push_spot ();
 512         }
 513         /* cont */ '=' identifier_init  {
 514
 515         /*
 516                 Should find generic way of associating input with objects.
 517         */
 518                 Input ip = THIS->pop_spot ();
 519
 520                 if (! is_regular_identifier ($1))
 521                 {
 522                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 523                 }
 524
 525                 THIS->lexer_->set_identifier ($1, $4);
 526
 527 /*
 528  TODO: devise standard for protection in parser.
 529
 530   The parser stack lives on the C-stack, which means that
 531 all objects can be unprotected as soon as they're here.
 532
 533 */
 534         }
 535         | embedded_scm { }
 536         ;
 537
 538
 539 identifier_init:
 540         score_block {
 541                 $$ = $1->self_scm ();
 542                 scm_gc_unprotect_object ($$);
 543         }
 544         | full_markup {
 545                 $$ = $1;
 546         }
 547         | output_def {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | context_def_spec_block {
 552                 $$ = $1;
 553         }
 554         | Music  {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | post_event {
 559                 $$ = $1->self_scm ();
 560                 scm_gc_unprotect_object ($$);
 561         }
 562         | number_expression {
 563                 $$ = $1;
 564         }
 565         | string {
 566                 $$ = $1;
 567         }
 568         | embedded_scm  {
 569                 $$ = $1;
 570         }
 571         ;
 572
 573 context_def_spec_block:
 574         CONTEXT '{' context_def_spec_body '}'
 575                 {
 576                 $$ = $3;
 577         }
 578         ;
 579
 580 context_def_spec_body:
 581         /**/ {
 582                 $$ = Context_def::make_scm ();
 583                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 584         }
 585         | CONTEXT_DEF_IDENTIFIER {
 586                 $$ = $1;
 587                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 588         }
 589         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 590                 Context_def*td = unsmob_context_def ($$);
 591
 592                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 593                         SCM tag = ly_caar (p);
 594
 595                         /* TODO: should make new tag "grob-definition" ? */
 596                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 597                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 598                 }
 599         }
 600         | context_def_spec_body context_mod {
 601                 unsmob_context_def ($$)->add_context_mod ($2);
 602         }
 603         ;
 604
 605 book_block:
 606         BOOK {
 607                 THIS->push_spot ();
 608         }
 609         /*cont*/ '{' book_body '}'      {
 610                 THIS->pop_spot ();
 611                 $$ = $4;
 612         }
 613         ;
 614
 615 book_body:
 616         {
 617                 $$ = new Book;
 618                 $$->set_spot (THIS->here_input ());
 619         }
 620         | book_body score_block {
 621                 $$->scores_.push ($2);
 622                 scm_gc_unprotect_object ($2->self_scm ());
 623         }
 624         | book_body error {
 625         }
 626         ;
 627
 628 score_block:
 629         SCORE {
 630                 THIS->push_spot ();
 631         }
 632         /*cont*/ '{' score_body '}'     {
 633                 THIS->pop_spot ();
 634                 $$ = $4;
 635         }
 636         ;
 637
 638 score_body:
 639         Music   {
 640                 $$ = new Score;
 641
 642                 $$->set_spot (THIS->here_input ());
 643                 SCM m = $1->self_scm ();
 644                 scm_gc_unprotect_object (m);
 645
 646                 /*
 647                         guh.
 648                 */
 649                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 650                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 651                         m = scm_call_1 (ly_car (check_funcs), m);
 652                 $$->music_ = m;
 653
 654         }
 655         | SCORE_IDENTIFIER {
 656                 $$ = new Score ( *unsmob_score ($1));
 657                 $$->set_spot (THIS->here_input ());
 658         }
 659         | score_body lilypond_header    {
 660                 $$->header_ = $2;
 661         }
 662         | score_body output_def {
 663                 $$->defs_.push ($2);
 664                 scm_gc_unprotect_object ($2->self_scm ());
 665         }
 666         | score_body error {
 667
 668         }
 669         ;
 670
 671
 672 /*
 673         MIDI
 674 */
 675 output_def:
 676         music_output_def_body '}' {
 677                 $$ = $1;
 678                 THIS->lexer_->remove_scope ();
 679                 THIS->lexer_->pop_state ();
 680         }
 681         ;
 682
 683 music_output_def_head:
 684         MIDI    {
 685                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 686
 687
 688                 Midi_def *p = 0;
 689                 if (id)
 690                         p = dynamic_cast<Midi_def*> (id->clone ());
 691                 else
 692                         p = new Midi_def;
 693
 694                 $$ = p;
 695                 THIS->lexer_->add_scope (p->scope_);
 696         }
 697         | PAPER         {
 698                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 699                   Paper_def *p = 0;
 700                 if (id)
 701                         p = dynamic_cast<Paper_def*> (id->clone ());
 702                 else
 703                         p = new Paper_def;
 704
 705                 THIS->lexer_->add_scope (p->scope_);
 706                 $$ = p;
 707         }
 708         ;
 709
 710
 711 music_output_def_body:
 712         music_output_def_head '{' {
 713                 $$ = $1;
 714                 $$->input_origin_. set_spot (THIS->here_input ());
 715                 THIS->lexer_->push_initial_state ();
 716         }
 717         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 718                 scm_gc_unprotect_object ($1->self_scm ());
 719                 Music_output_def *o = unsmob_music_output_def ($3);
 720                 o->input_origin_.set_spot (THIS->here_input ());
 721                 $$ = o;
 722                 THIS->lexer_->remove_scope ();
 723                 THIS->lexer_->add_scope (o->scope_);
 724                 THIS->lexer_->push_initial_state ();
 725         }
 726         | music_output_def_body assignment  {
 727
 728         }
 729         | music_output_def_body context_def_spec_block  {
 730                 $$->assign_context_def ($2);
 731         }
 732         | music_output_def_body tempo_event  {
 733                 /*
 734                         junk this ? there already is tempo stuff in
 735                         music.
 736                 */
 737                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 738                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 739                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 740                 if (md)
 741                         md->set_tempo (d->get_length (), m);
 742                 scm_gc_unprotect_object ($2->self_scm ());
 743         }
 744         | music_output_def_body error {
 745
 746         }
 747         ;
 748
 749 tempo_event:
 750         TEMPO steno_duration '=' bare_unsigned  {
 751                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 752                 $$->set_property ("tempo-unit", $2);
 753                 $$->set_property ("metronome-count", scm_int2num ( $4));
 754         }
 755         ;
 756
 757 /*
 758 The representation of a  list is the
 759
 760   (LIST . LAST-CONS)
 761
 762  to have  efficient append.
 763 */
 764 Music_list:
 765         /* empty */ {
 766                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 767         }
 768         | Music_list Music {
 769                 SCM s = $$;
 770                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 771                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 772                 if (ly_c_pair_p (ly_cdr (s)))
 773                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 774                 else
 775                         scm_set_car_x (s, c); /* set first cons */
 776                 scm_set_cdr_x (s, c);  /* remember last cell */
 777         }
 778         | Music_list embedded_scm {
 779         }
 780         | Music_list error {
 781         }
 782         ;
 783
 784
 785 Music:
 786         Simple_music
 787         | Composite_music
 788         ;
 789
 790 Alternative_music:
 791         /* empty */ {
 792                 $$ = SCM_EOL;
 793         }
 794         | ALTERNATIVE '{' Music_list '}' {
 795                 $$ = $3;
 796         }
 797         ;
 798
 799
 800 Repeated_music:
 801         REPEAT simple_string bare_unsigned Music Alternative_music
 802         {
 803                 Music *beg = $4;
 804                 int times = $3;
 805                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 806                 if (times < scm_ilength (alts)) {
 807                   unsmob_music (ly_car (alts))
 808                     ->origin ()->warning (
 809                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 810                   alts = ly_truncate_list (times, alts);
 811                 }
 812
 813
 814                 SCM proc = ly_scheme_function ("make-repeated-music");
 815
 816                 SCM mus = scm_call_1 (proc, $2);
 817                 scm_gc_protect_object (mus); // UGH.
 818                 Music *r = unsmob_music (mus);
 819                 if (beg)
 820                         {
 821                         r-> set_property ("element", beg->self_scm ());
 822                         scm_gc_unprotect_object (beg->self_scm ());
 823                         }
 824                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 825
 826                 r-> set_property ("elements",alts);
 827                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 828                         /*
 829                         TODO: move this code to Scheme.
 830                         */
 831
 832                         /*
 833                         we can not get durations and other stuff correct down the line, so we have to
 834                         add to the duration log here.
 835                         */
 836                         SCM func = ly_scheme_function ("shift-duration-log");
 837
 838                         int dots = ($3 % 3) ? 0 : 1;
 839                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 840
 841                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 842
 843                         if (seq) {
 844                                 int list_len = scm_ilength (seq->music_list ());
 845                                 if (list_len != 2)
 846                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 847                                 shift -= 1;
 848                                 r->compress (Moment (Rational (1, list_len)));
 849                                 }
 850                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 851
 852                 }
 853                 r->set_spot (*$4->origin ());
 854
 855                 $$ = r;
 856         }
 857         ;
 858
 859 Sequential_music:
 860         SEQUENTIAL '{' Music_list '}'           {
 861                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 862                 $$->set_property ("elements", ly_car ($3));
 863                 $$->set_spot (THIS->here_input ());
 864         }
 865         | '{' Music_list '}'            {
 866                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 867                 $$->set_property ("elements", ly_car ($2));
 868                 $$->set_spot (THIS->here_input ());
 869         }
 870         ;
 871
 872 Simultaneous_music:
 873         SIMULTANEOUS '{' Music_list '}'{
 874                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 875                 $$->set_property ("elements", ly_car ($3));
 876                 $$->set_spot (THIS->here_input ());
 877
 878         }
 879         | simul_open Music_list simul_close     {
 880                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 881                 $$->set_property ("elements", ly_car ($2));
 882                 $$->set_spot (THIS->here_input ());
 883         }
 884         ;
 885
 886 Simple_music:
 887         event_chord             { $$ = $1; }
 888         | APPLYOUTPUT embedded_scm {
 889                 if (!ly_input_procedure_p ($2))
 890                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 891                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 892                 $$->set_property ("procedure", $2);
 893                 $$->set_spot (THIS->here_input ());
 894         }
 895         | APPLYCONTEXT embedded_scm {
 896                 if (!ly_input_procedure_p ($2))
 897                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 898                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 899                 $$->set_property ("procedure", $2);
 900                 $$->set_spot (THIS->here_input ());
 901         }
 902         | MUSIC_IDENTIFIER {
 903                 $$ = unsmob_music ($1);
 904         }
 905         | music_property_def
 906         | context_change
 907         ;
 908
 909
 910 optional_context_mod:
 911         /**/ { $$ = SCM_EOL; }
 912         | WITH { THIS->lexer_->push_initial_state (); }
 913         '{' context_mod_list '}'
 914         {
 915                 THIS->lexer_->pop_state ();
 916                 $$ = $4;
 917         }
 918         ;
 919
 920 grace_head:
 921         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 922         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 923         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 924         ;
 925
 926 context_mod_list:
 927         /* */  { $$ = SCM_EOL; }
 928         | context_mod_list context_mod  {
 929                  $$ = scm_cons ($2, $1);
 930         }
 931         ;
 932
 933
 934 Composite_music:
 935         Prefix_composite_music { $$ = $1; }
 936         | Grouped_music_list { $$ = $1; }
 937         ;
 938
 939 Grouped_music_list:
 940         Simultaneous_music              { $$ = $1; }
 941         | Sequential_music              { $$ = $1; }
 942         ;
 943
 944 Prefix_composite_music:
 945         AUTOCHANGE Music        {
 946                 SCM proc = ly_scheme_function ("make-autochange-music");
 947
 948                 SCM res = scm_call_1 (proc, $2->self_scm ());
 949                 scm_gc_unprotect_object ($2->self_scm ());
 950                 $$ = unsmob_music (res);
 951                 scm_gc_protect_object (res);
 952                 $$->set_spot (THIS->here_input ());
 953         }
 954         | PARTCOMBINE Music Music {
 955                 SCM proc = ly_scheme_function ("make-part-combine-music");
 956
 957                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 958                         $3->self_scm (), SCM_UNDEFINED));
 959                 scm_gc_unprotect_object ($3->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961                 $$ = unsmob_music (res);
 962                 scm_gc_protect_object (res);
 963                 $$->set_spot (THIS->here_input ());
 964         }
 965         | grace_head Music {
 966 #if 1
 967         /*
 968                 The other version is for easier debugging  of
 969                 Sequential_music_iterator in combination with grace notes.
 970         */
 971
 972 /*
 973
 974 TODO: should distinguish between both grace types in the
 975 basic music objects too, since the meaning is different.
 976
 977 */
 978
 979                 String start_str = "start" + ly_scm2string ($1) + "Music";
 980                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 981
 982                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 983                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 984
 985                 Music *startm = unsmob_music (start);
 986                 Music *stopm = unsmob_music (stop);
 987
 988                 SCM ms = SCM_EOL;
 989                 if (stopm) {
 990                         stopm = stopm->clone ();
 991                         ms = scm_cons (stopm->self_scm (), ms);
 992                         scm_gc_unprotect_object (stopm->self_scm ());
 993                 }
 994                 ms = scm_cons ($2->self_scm (), ms);
 995                 scm_gc_unprotect_object ($2->self_scm ());
 996                 if (startm) {
 997                         startm = startm->clone ();
 998                         ms = scm_cons (startm->self_scm (), ms);
 999                         scm_gc_unprotect_object (startm->self_scm ());
1000                 }
1001
1002                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1003                 seq->set_property ("elements", ms);
1004
1005
1006                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1007                 $$->set_property ("element", seq->self_scm ());
1008                 scm_gc_unprotect_object (seq->self_scm ());
1009 #else
1010                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1011                 $$->set_property ("element", $2->self_scm ());
1012                 scm_gc_unprotect_object ($2->self_scm ());
1013 #endif
1014         }
1015         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1016                 $$ = context_spec_music ($2, $4, $6, $5);
1017
1018         }
1019         | CONTEXT simple_string optional_context_mod Music {
1020                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1021         }
1022         | NEWCONTEXT simple_string optional_context_mod Music {
1023                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1024                         $3);
1025         }
1026
1027         | TIMES {
1028                 THIS->push_spot ();
1029         }
1030         /* CONTINUED */
1031                 fraction Music
1032
1033         {
1034                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1035                 Music *mp = $4;
1036
1037                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1038                 $$->set_spot (THIS->pop_spot ());
1039
1040                 $$->set_property ("element", mp->self_scm ());
1041                 scm_gc_unprotect_object (mp->self_scm ());
1042                 $$->set_property ("numerator", scm_int2num (n));
1043                 $$->set_property ("denominator", scm_int2num (d));
1044                 $$->compress (Moment (Rational (n,d)));
1045
1046         }
1047         | Repeated_music                { $$ = $1; }
1048         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1049                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1050                 Music *p = $4;
1051                 Pitch from = *unsmob_pitch ($2);
1052                 Pitch to = *unsmob_pitch ($3);
1053
1054                 p->transpose (interval (from, to));
1055                 $$->set_property ("element", p->self_scm ());
1056                 scm_gc_unprotect_object (p->self_scm ());
1057         }
1058         | APPLY embedded_scm Music  {
1059                 if (!ly_input_procedure_p ($2))
1060                         {
1061                         THIS->parser_error (_ ("\\apply takes function argument"));
1062                         $$ = $3;
1063                         }
1064                 else
1065                         {
1066                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1067                         Music *m = unsmob_music (ret);
1068                         if (!m) {
1069                                 THIS->parser_error ("\\apply must return a Music");
1070                                 m = MY_MAKE_MUSIC ("Music");
1071                                 }
1072                         $$ = m;
1073                         }
1074         }
1075         | NOTES
1076                 {
1077                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1078                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1079         }
1080         Music
1081                 { $$ = $3;
1082                   THIS->lexer_->pop_state ();
1083                 }
1084         | DRUMS
1085                 {
1086                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1087                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1088         }
1089         /* FIXME: This used to be: */
1090         Music
1091 /*      Grouped_music_list */
1092                 { $$ = $3;
1093                   THIS->lexer_->pop_state ();
1094                 }
1095         | FIGURES
1096                 { THIS->lexer_->push_figuredbass_state (); }
1097         /* FIXME: This used to be:
1098         Music
1099         but that breaks web build
1100         */
1101         Grouped_music_list
1102                 {
1103                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1104                   chm->set_property ("element", $3->self_scm ());
1105                   $$ = chm;
1106                   scm_gc_unprotect_object ($3->self_scm ());
1107
1108                   THIS->lexer_->pop_state ();
1109         }
1110         | CHORDS {
1111                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1112                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1113                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1114                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1115
1116         }
1117         /* FIXME:
1118         Music
1119 */
1120         Grouped_music_list
1121         {
1122                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1123                   chm->set_property ("element", $3->self_scm ());
1124                   scm_gc_unprotect_object ($3->self_scm ());
1125                   $$ = chm;
1126
1127                   THIS->lexer_->pop_state ();
1128         }
1129         | LYRICS
1130                 { THIS->lexer_->push_lyric_state (); }
1131         /* FIXME:
1132         Music
1133 */
1134         Grouped_music_list
1135                 {
1136                   $$ = $3;
1137                   THIS->lexer_->pop_state ();
1138         }
1139         | relative_music        { $$ = $1; }
1140         | re_rhythmed_music     { $$ = $1; }
1141         | TAG embedded_scm Music {
1142                 tag_music ($3, $2, THIS->here_input ());
1143                 $$ = $3;
1144         }
1145         ;
1146
1147 relative_music:
1148         RELATIVE absolute_pitch Music {
1149                 Music *m = $3;
1150                 Pitch start = *unsmob_pitch ($2);
1151                 $$ = make_music_relative (start, m);
1152                 scm_gc_unprotect_object (m->self_scm ());
1153         }
1154         | RELATIVE Composite_music {
1155                 Music *m = $2;
1156                 /* FIXME: why is octave==0 and default not middleC? */
1157                 Pitch middle_c (-1, 0, 0);
1158                 $$ = make_music_relative (middle_c, m);
1159                 scm_gc_unprotect_object (m->self_scm ());
1160         }
1161         ;
1162
1163 new_lyrics:
1164         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1165         /*cont */
1166         Grouped_music_list {
1167         /* Can also use Music at the expensive of two S/Rs similar to
1168            \repeat \alternative */
1169                 THIS->lexer_->pop_state ();
1170 #if 0
1171                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1172                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1173                 $$ = music;
1174 #else
1175                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1176 #endif
1177         }
1178         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1179         Grouped_music_list {
1180                 THIS->lexer_->pop_state ();
1181                 $$ = scm_cons ($4->self_scm (), $1);
1182         }
1183         ;
1184
1185 re_rhythmed_music:
1186         ADDLYRICS Music Music {
1187                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1188                 m->set_property ("elements", scm_listify ($2->self_scm (),
1189                         $3->self_scm (), SCM_UNDEFINED));
1190                 scm_gc_unprotect_object ($3->self_scm ());
1191                 scm_gc_unprotect_object ($2->self_scm ());
1192                 $$ = m;
1193         }
1194         | Grouped_music_list new_lyrics {
1195
1196                 /* FIXME: should find out uniqueXXX name from music */
1197                 SCM name = $1->get_property ("context-id");
1198                 //if (name == SCM_EOL)
1199                 if (!ly_c_string_p (name))
1200                         name = scm_makfrom0str ("");
1201
1202                 SCM context = scm_makfrom0str ("Lyrics");
1203                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1204
1205                 SCM lst = SCM_EOL;
1206                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1207                 {
1208                         Music *music = unsmob_music (ly_car (s));
1209                         Music *com = make_lyric_combine_music (name, music);
1210                         Music *csm = context_spec_music (context,
1211                                 get_next_unique_context (), com, SCM_EOL);
1212                         lst = scm_cons (csm->self_scm (), lst);
1213                 }
1214                 /* FIXME: only first lyric music is accepted,
1215                           the rest is junked */
1216                 all->set_property ("elements", scm_cons ($1->self_scm (),
1217                         lst));
1218                 $$ = all;
1219                 scm_gc_unprotect_object ($1->self_scm ());
1220         }
1221         | LYRICSTO string Music {
1222                 Music *music = $3;
1223                 SCM name = $2;
1224                 $$ = make_lyric_combine_music (name, music);
1225                 scm_gc_unprotect_object (music->self_scm ());
1226         }
1227         ;
1228
1229 context_change:
1230         CHANGE STRING '=' STRING  {
1231                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1232                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1233                 t-> set_property ("change-to-id", $4);
1234
1235                 $$ = t;
1236                 $$->set_spot (THIS->here_input ());
1237         }
1238         ;
1239
1240 property_operation:
1241         STRING '=' scalar {
1242                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1243                         scm_string_to_symbol ($1), $3);
1244         }
1245         | UNSET simple_string {
1246                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1247                         scm_string_to_symbol ($2));
1248         }
1249         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1250                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1251                         scm_string_to_symbol ($2), $3, $5);
1252         }
1253         | REVERT simple_string embedded_scm {
1254                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1255                         scm_string_to_symbol ($2), $3);
1256         }
1257         ;
1258
1259 context_def_mod:
1260         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1261         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1262         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1263
1264         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1265         | DENIES { $$ = ly_symbol2scm ("denies"); }
1266
1267         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1268         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1269         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1270         | NAME { $$ = ly_symbol2scm ("context-name"); }
1271         ;
1272
1273 context_mod:
1274         property_operation { $$ = $1; }
1275         | context_def_mod STRING {
1276                 $$ = scm_list_2 ($1, $2);
1277         }
1278         ;
1279
1280 context_prop_spec:
1281         simple_string {
1282                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1283                         scm_string_to_symbol ($1));
1284         }
1285         | simple_string '.' simple_string {
1286                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1287                         scm_string_to_symbol ($3));
1288         }
1289         ;
1290
1291 music_property_def:
1292         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1293                 $$ = property_op_to_music (scm_list_4 (
1294                         ly_symbol2scm ("poppush"),
1295                         ly_cadr ($2),
1296                         $3, $5));
1297                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1298         }
1299         | REVERT context_prop_spec embedded_scm {
1300                 $$ = property_op_to_music (scm_list_3 (
1301                         ly_symbol2scm ("pop"),
1302                         ly_cadr ($2),
1303                         $3));
1304
1305                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1306         }
1307         | SET context_prop_spec '=' scalar {
1308                 $$ = property_op_to_music (scm_list_3 (
1309                         ly_symbol2scm ("assign"),
1310                         ly_cadr ($2),
1311                         $4));
1312                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1313         }
1314         | UNSET context_prop_spec {
1315                 $$ = property_op_to_music (scm_list_2 (
1316                         ly_symbol2scm ("unset"),
1317                         ly_cadr ($2)));
1318                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1319         }
1320         | ONCE music_property_def {
1321                 SCM e = $2->get_property ("element");
1322                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1323                 $$ = $2;
1324
1325         }
1326         ;
1327
1328
1329 string:
1330         STRING {
1331                 $$ = $1;
1332         }
1333         | STRING_IDENTIFIER {
1334                 $$ = $1;
1335         }
1336         | string '+' string {
1337                 $$ = scm_string_append (scm_list_2 ($1, $3));
1338         }
1339         ;
1340
1341 simple_string: STRING {
1342         }
1343         | LYRICS_STRING {
1344         }
1345         ;
1346
1347 scalar: string {
1348         }
1349         | LYRICS_STRING {
1350         }
1351         | bare_int {
1352                 $$ = scm_int2num ($1);
1353         }
1354         | embedded_scm {
1355         }
1356         | full_markup {
1357         }
1358         | DIGIT {
1359                 $$ = scm_int2num ($1);
1360         }
1361         ;
1362
1363 /*
1364 FIXME: remove or fix this comment.  What is `This'?
1365
1366 This is a trick:
1367
1368 Adding pre_events to the simple_element
1369 makes the choice between
1370
1371   string:  STRING
1372
1373 and
1374
1375   simple_element: STRING
1376
1377 a single shift/reduction conflict.
1378
1379 nevertheless, this is not very clean, and we should find a different
1380 solution.
1381
1382 */
1383 pre_events: {
1384                 THIS->push_spot ();
1385         }
1386         ;
1387
1388 event_chord:
1389         pre_events simple_element post_events   {
1390                 SCM elts = $2-> get_property ("elements");
1391
1392                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1393
1394                 $2->set_property ("elements", elts);
1395                 $$ = $2;
1396         }
1397         | command_element
1398         | note_chord_element
1399         ;
1400
1401
1402 note_chord_element:
1403         chord_body optional_notemode_duration post_events
1404         {
1405                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1406                 SCM es = $1->get_property ("elements");
1407                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1408
1409                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1410                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1411                 es = ly_append2 (es, postevs);
1412
1413                 $1-> set_property ("elements", es);
1414                 $$ = $1;
1415         }
1416         ;
1417
1418 chord_open: '<'
1419         ;
1420
1421 chord_close: '>'
1422         ;
1423
1424 simul_open: DOUBLE_ANGLE_OPEN
1425         ;
1426
1427 simul_close: DOUBLE_ANGLE_CLOSE
1428         ;
1429
1430 chord_body:
1431         chord_open chord_body_elements chord_close
1432         {
1433                 $$ = MY_MAKE_MUSIC ("EventChord");
1434                 $$->set_property ("elements",
1435                         scm_reverse_x ($2, SCM_EOL));
1436         }
1437         ;
1438
1439 chord_body_elements:
1440         /* empty */             { $$ = SCM_EOL; }
1441         | chord_body_elements chord_body_element {
1442                 $$ = scm_cons ($2->self_scm (), $1);
1443                 scm_gc_unprotect_object ($2->self_scm ());
1444         }
1445         ;
1446
1447 chord_body_element:
1448         pitch exclamations questions post_events
1449         {
1450                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1451                 n->set_property ("pitch", $1);
1452                 if ($3 % 2)
1453                         n->set_property ("cautionary", SCM_BOOL_T);
1454                 if ($2 % 2 || $3 % 2)
1455                         n->set_property ("force-accidental", SCM_BOOL_T);
1456
1457                 if (ly_c_pair_p ($4)) {
1458                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1459                         n->set_property ("articulations", arts);
1460                 }
1461                 $$ = n;
1462         }
1463         | DRUM_PITCH post_events {
1464                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1465                 n->set_property ("duration", $2);
1466                 n->set_property ("drum-type", $1);
1467                 n->set_spot (THIS->here_input ());
1468
1469                 if (ly_c_pair_p ($2)) {
1470                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1471                         n->set_property ("articulations", arts);
1472                 }
1473                 $$ = n;
1474         }
1475         ;
1476
1477 add_quote:
1478         ADDQUOTE string Music {
1479                 SCM adder = ly_scheme_function ("add-quotable");
1480
1481                 scm_call_2 (adder, $2, $3->self_scm ());
1482                 scm_gc_unprotect_object ($3->self_scm ());
1483         }
1484         ;
1485
1486 command_element:
1487         command_req {
1488                 $$ = MY_MAKE_MUSIC ("EventChord");
1489                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1490                 scm_gc_unprotect_object ($1->self_scm ());
1491
1492                 $$-> set_spot (THIS->here_input ());
1493                 $1-> set_spot (THIS->here_input ());
1494         }
1495         | SKIP duration_length {
1496                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1497                 skip->set_property ("duration", $2);
1498
1499                 $$ = skip;
1500         }
1501         | QUOTE STRING duration_length {
1502                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1503                 SCM evs = SCM_EOL;
1504                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1505                 {
1506                         SCM key = $2; // use symbol?
1507                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1508                 }
1509                 Music *quote = 0;
1510                 if (ly_c_vector_p (evs))
1511                 {
1512                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1513                         quote->set_property ("duration", $3);
1514                         quote->set_property ("quoted-events", evs);
1515                 } else {
1516                         THIS->here_input ().warning (_f ("Can\'t find music"));
1517                         quote = MY_MAKE_MUSIC ("Event");
1518                 }
1519                 quote->set_spot (THIS->here_input ());
1520                 $$ = quote;
1521         }
1522         | OCTAVE { THIS->push_spot (); }
1523           pitch {
1524                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1525                 $$ = m;
1526                 $$->set_spot (THIS->pop_spot ());
1527                 $$->set_property ("pitch", $3);
1528         }
1529         | E_LEFTSQUARE {
1530                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1531                 m->set_property ("span-direction", scm_int2num (START));
1532                 m->set_spot (THIS->here_input ());
1533
1534                 $$ = MY_MAKE_MUSIC ("EventChord");
1535                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1536                 scm_gc_unprotect_object (m->self_scm ());
1537                 $$->set_spot (THIS->here_input ());
1538         }
1539         | E_RIGHTSQUARE {
1540                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1541                 m->set_property ("span-direction", scm_int2num (STOP));
1542                 m->set_spot (THIS->here_input ());
1543
1544                 $$ = MY_MAKE_MUSIC ("EventChord");
1545                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1546                 $$->set_spot (THIS->here_input ());
1547                 scm_gc_unprotect_object (m->self_scm ());
1548         }
1549         | E_BACKSLASH {
1550                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1551                 $$->set_spot (THIS->here_input ());
1552         }
1553         | '|'      {
1554                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1555
1556                 if (Music * m = unsmob_music (pipe))
1557                         $$ = m->clone ();
1558                 else
1559                         $$ = MY_MAKE_MUSIC ("BarCheck");
1560
1561                 $$->set_spot (THIS->here_input ());
1562         }
1563         | TRANSPOSITION pitch {
1564                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1565                                         $2);
1566                 $$->set_spot (THIS-> here_input ());
1567                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1568                         $$, SCM_EOL);
1569         }
1570         | BAR STRING                    {
1571                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1572
1573                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1574                                         t, SCM_EOL);
1575                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1576                 $$->set_spot (THIS->here_input ());
1577                 t->set_spot (THIS->here_input ());
1578         }
1579         | PARTIAL duration_length       {
1580                 Moment m = - unsmob_duration ($2)->get_length ();
1581                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1582                 p->set_spot (THIS->here_input ());
1583                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1584                                         p, SCM_EOL);
1585                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1586                                         p, SCM_EOL);
1587                 $$ = p;
1588         }
1589         | CLEF STRING  {
1590                 SCM proc = ly_scheme_function ("make-clef-set");
1591
1592                 SCM result = scm_call_1 (proc, $2);
1593                 scm_gc_protect_object (result);
1594                 $$ = unsmob_music (result);
1595         }
1596         | TIME_T fraction  {
1597                 SCM proc= ly_scheme_function ("make-time-signature-set");
1598
1599                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1600                 scm_gc_protect_object (result);
1601                 $$ = unsmob_music (result);
1602         }
1603         | MARK scalar {
1604                 SCM proc = ly_scheme_function ("make-mark-set");
1605
1606                 SCM result = scm_call_1 (proc, $2);
1607                 scm_gc_protect_object (result);
1608                 $$ = unsmob_music (result);
1609         }
1610         ;
1611
1612 command_req:
1613         BREATHE {
1614                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1615         }
1616         | E_TILDE {
1617                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1618         }
1619         | MARK DEFAULT  {
1620                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1621                 $$ = m;
1622         }
1623         | tempo_event {
1624                 $$ = $1;
1625         }
1626         | KEY DEFAULT {
1627                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1628                 $$ = key;
1629         }
1630         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1631
1632                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1633                 if (scm_ilength ($3) > 0)
1634                 {
1635                         key->set_property ("pitch-alist", $3);
1636                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1637                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1638                 } else {
1639                         THIS->parser_error (_ ("Second argument must be pitch list."));
1640                 }
1641
1642                 $$ = key;
1643         }
1644         ;
1645
1646 post_events:
1647         /* empty */ {
1648                 $$ = SCM_EOL;
1649         }
1650         | post_events post_event {
1651                 $2->set_spot (THIS->here_input ());
1652                 $$ = scm_cons ($2->self_scm (), $$);
1653                 scm_gc_unprotect_object ($2->self_scm ());
1654         }
1655         | post_events tagged_post_event {
1656                 $2 -> set_spot (THIS->here_input ());
1657                 $$ = scm_cons ($2->self_scm (), $$);
1658                 scm_gc_unprotect_object ($2->self_scm ());
1659         }
1660         ;
1661
1662
1663 tagged_post_event:
1664         '-' TAG embedded_scm post_event {
1665                 tag_music ($4, $3, THIS->here_input ());
1666                 $$ = $4;
1667         }
1668         ;
1669
1670 post_event:
1671         direction_less_event {
1672                 $$ = $1;
1673         }
1674         | HYPHEN {
1675                 if (!THIS->lexer_->is_lyric_state ())
1676                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1677                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1678         }
1679         | EXTENDER {
1680                 if (!THIS->lexer_->is_lyric_state ())
1681                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1682                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1683         }
1684         | script_dir direction_reqd_event {
1685                 if ($1)
1686                         $2->set_property ("direction", scm_int2num ($1));
1687                 $$ = $2;
1688         }
1689         | script_dir direction_less_event {
1690                 if ($1)
1691                         $2->set_property ("direction", scm_int2num ($1));
1692                 $$ = $2;
1693         }
1694         | string_number_event
1695         ;
1696
1697 string_number_event:
1698         E_UNSIGNED {
1699                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1700                 s->set_property ("string-number", scm_int2num ($1));
1701                 s->set_spot (THIS->here_input ());
1702                 $$ = s;
1703         }
1704         ;
1705
1706
1707 direction_less_event:
1708         '['  {
1709
1710
1711 /*
1712
1713 TODO: should take all these defs out of the parser, adn make use
1714 configurable, i.e.
1715
1716
1717 (set-articulation '~ "trill")
1718
1719 */
1720                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1721                 m->set_spot (THIS->here_input ());
1722                 m->set_property ("span-direction", scm_int2num (START));
1723                 $$ = m;
1724         }
1725         | ']'  {
1726                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1727                 m->set_spot (THIS->here_input ());
1728                 m->set_property ("span-direction", scm_int2num (STOP));
1729                 $$ = m;
1730         }
1731         | '~' {
1732                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1733                 m->set_spot (THIS->here_input ());
1734                 $$ = m;
1735         }
1736         | close_event {
1737                 $$ = $1;
1738                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1739                         scm_int2num (START));
1740         }
1741         | open_event {
1742                 $$ = $1;
1743                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1744                         scm_int2num (STOP));
1745         }
1746         | EVENT_IDENTIFIER      {
1747                 $$ = unsmob_music ($1);
1748         }
1749         | tremolo_type  {
1750                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1751                a->set_spot (THIS->here_input ());
1752                a->set_property ("tremolo-type", scm_int2num ($1));
1753                $$ = a;
1754         }
1755         ;
1756
1757 direction_reqd_event:
1758         gen_text_def {
1759                 $$ = $1;
1760         }
1761         | script_abbreviation {
1762                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1763                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1764                 if (ly_c_string_p (s))
1765                         a->set_property ("articulation-type", s);
1766                 else THIS->parser_error (_ ("Expecting string as script definition"));
1767                 $$ = a;
1768         }
1769         ;
1770
1771 oct_check:
1772         /**/ { $$ = SCM_EOL; }
1773         | '='  { $$ = scm_int2num (0); }
1774         | '=' sub_quotes { $$ = scm_int2num ($2); }
1775         | '=' sup_quotes { $$ = scm_int2num ($2); }
1776         ;
1777
1778 sup_quotes:
1779         '\'' {
1780                 $$ = 1;
1781         }
1782         | sup_quotes '\'' {
1783                 $$ ++;
1784         }
1785         ;
1786
1787 sub_quotes:
1788         ',' {
1789                 $$ = 1;
1790         }
1791         | sub_quotes ',' {
1792                 $$++;
1793         }
1794         ;
1795
1796 steno_pitch:
1797         NOTENAME_PITCH  {
1798                 $$ = $1;
1799         }
1800         | NOTENAME_PITCH sup_quotes     {
1801                 Pitch p = *unsmob_pitch ($1);
1802                 p = p.transposed (Pitch ($2,0,0));
1803                 $$ = p.smobbed_copy ();
1804         }
1805         | NOTENAME_PITCH sub_quotes      {
1806                 Pitch p =* unsmob_pitch ($1);
1807                 p = p.transposed (Pitch (-$2,0,0));
1808                 $$ = p.smobbed_copy ();
1809         }
1810         ;
1811
1812 /*
1813 ugh. duplication
1814 */
1815
1816 steno_tonic_pitch:
1817         TONICNAME_PITCH {
1818                 $$ = $1;
1819         }
1820         | TONICNAME_PITCH sup_quotes    {
1821                 Pitch p = *unsmob_pitch ($1);
1822                 p = p.transposed (Pitch ($2,0,0));
1823                 $$ = p.smobbed_copy ();
1824         }
1825         | TONICNAME_PITCH sub_quotes     {
1826                 Pitch p =* unsmob_pitch ($1);
1827
1828                 p = p.transposed (Pitch (-$2,0,0));
1829                 $$ = p.smobbed_copy ();
1830         }
1831         ;
1832
1833 pitch:
1834         steno_pitch {
1835                 $$ = $1;
1836         }
1837         ;
1838
1839 pitch_also_in_chords:
1840         pitch
1841         | steno_tonic_pitch
1842         ;
1843
1844 close_event:
1845         '('     {
1846                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1847                 $$ = s;
1848                 s->set_spot (THIS->here_input ());
1849         }
1850         | E_OPEN        {
1851                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1852                 $$ = s;
1853                 s->set_spot (THIS->here_input ());
1854         }
1855         | E_SMALLER {
1856                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1857                 $$ = s;
1858                 s->set_spot (THIS->here_input ());
1859         }
1860         | E_BIGGER {
1861                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1862                 $$ = s;
1863                 s->set_spot (THIS->here_input ());
1864         }
1865         ;
1866
1867
1868 open_event:
1869         E_EXCLAMATION   {
1870                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1871                 s->set_spot (THIS->here_input ());
1872
1873                 $$ = s;
1874         }
1875         | ')'   {
1876                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1877                 $$ = s;
1878                 s->set_spot (THIS->here_input ());
1879
1880         }
1881         | E_CLOSE       {
1882                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1883                 $$ = s;
1884                 s->set_property ("span-type",
1885                         scm_makfrom0str ("phrasing-slur"));
1886                 s->set_spot (THIS->here_input ());
1887         }
1888         ;
1889
1890 gen_text_def:
1891         full_markup {
1892                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1893                 t->set_property ("text", $1);
1894                 t->set_spot (THIS->here_input ());
1895                 $$ = t;
1896         }
1897         | string {
1898                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1899                 t->set_property ("text",
1900                         make_simple_markup (THIS->lexer_->encoding (), $1));
1901                 t->set_spot (THIS->here_input ());
1902                 $$ = t;
1903
1904         }
1905         | DIGIT {
1906                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1907                 t->set_property ("digit", scm_int2num ($1));
1908                 t->set_spot (THIS->here_input ());
1909                 $$ = t;
1910         }
1911         ;
1912
1913 script_abbreviation:
1914         '^'             {
1915                 $$ = scm_makfrom0str ("Hat");
1916         }
1917         | '+'           {
1918                 $$ = scm_makfrom0str ("Plus");
1919         }
1920         | '-'           {
1921                 $$ = scm_makfrom0str ("Dash");
1922         }
1923         | '|'           {
1924                 $$ = scm_makfrom0str ("Bar");
1925         }
1926         | '>'           {
1927                 $$ = scm_makfrom0str ("Larger");
1928         }
1929         | '.'           {
1930                 $$ = scm_makfrom0str ("Dot");
1931         }
1932         | '_' {
1933                 $$ = scm_makfrom0str ("Underscore");
1934         }
1935         ;
1936
1937 script_dir:
1938         '_'     { $$ = DOWN; }
1939         | '^'   { $$ = UP; }
1940         | '-'   { $$ = CENTER; }
1941         ;
1942
1943
1944 absolute_pitch:
1945         steno_pitch     {
1946                 $$ = $1;
1947         }
1948         ;
1949
1950 duration_length:
1951         multiplied_duration {
1952                 $$ = $1;
1953         }
1954         ;
1955
1956 optional_notemode_duration:
1957         {
1958                 Duration dd = THIS->default_duration_;
1959                 $$ = dd.smobbed_copy ();
1960
1961                 THIS->beam_check ($$);
1962         }
1963         | multiplied_duration   {
1964                 $$ = $1;
1965                 THIS->default_duration_ = *unsmob_duration ($$);
1966
1967                 THIS->beam_check ($$);
1968         }
1969         ;
1970
1971 steno_duration:
1972         bare_unsigned dots              {
1973                 int len = 0;
1974                 if (!is_duration ($1))
1975                         THIS->parser_error (_f ("not a duration: %d", $1));
1976                 else
1977                         len = intlog2 ($1);
1978
1979                 $$ = Duration (len, $2).smobbed_copy ();
1980         }
1981         | DURATION_IDENTIFIER dots      {
1982                 Duration *d = unsmob_duration ($1);
1983                 Duration k (d->duration_log (), d->dot_count () + $2);
1984                 *d = k;
1985                 $$ = $1;
1986         }
1987         ;
1988
1989 multiplied_duration:
1990         steno_duration {
1991                 $$ = $1;
1992         }
1993         | multiplied_duration '*' bare_unsigned {
1994                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1995         }
1996         | multiplied_duration '*' FRACTION {
1997                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1998
1999                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2000         }
2001         ;
2002
2003 fraction:
2004         FRACTION { $$ = $1; }
2005         | UNSIGNED '/' UNSIGNED {
2006                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2007         }
2008         ;
2009
2010 dots:
2011         /* empty */     {
2012                 $$ = 0;
2013         }
2014         | dots '.' {
2015                 $$ ++;
2016         }
2017         ;
2018
2019 tremolo_type:
2020         ':'     {
2021                 $$ = 0;
2022         }
2023         | ':' bare_unsigned {
2024                 if (!is_duration ($2))
2025                         THIS->parser_error (_f ("not a duration: %d", $2));
2026                 $$ = $2;
2027         }
2028         ;
2029
2030 bass_number:
2031         DIGIT   {
2032                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2033         }
2034         | UNSIGNED {
2035                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2036         }
2037         | STRING { $$ = $1; }
2038         ;
2039
2040 bass_mod:
2041         '-'     { $$ = -2; }
2042         | '+'   { $$ = 2; }
2043         | '!'   { $$ = 0; }
2044         ;
2045
2046 bass_figure:
2047         FIGURE_SPACE {
2048                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2049                 $$ = bfr->self_scm ();
2050                 scm_gc_unprotect_object ($$);
2051         }
2052         | bass_number  {
2053                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2054                 $$ = bfr->self_scm ();
2055
2056                 bfr->set_property ("figure", $1);
2057
2058                 scm_gc_unprotect_object ($$);
2059         }
2060         | bass_figure bass_mod {
2061                 Music *m = unsmob_music ($1);
2062                 if ($2) {
2063                         SCM salter = m->get_property ("alteration");
2064                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2065                         m->set_property ("alteration",
2066                                 scm_int2num (alter + $2));
2067                 } else {
2068                         m->set_property ("alteration", scm_int2num (0));
2069                 }
2070         }
2071         ;
2072
2073 br_bass_figure:
2074         '[' bass_figure {
2075                 $$ = $2;
2076                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2077         }
2078         | bass_figure   {
2079                 $$ = $1;
2080         }
2081         | br_bass_figure ']' {
2082                 $$ = $1;
2083                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2084         }
2085         ;
2086
2087 figure_list:
2088         /**/            {
2089                 $$ = SCM_EOL;
2090         }
2091         | figure_list br_bass_figure {
2092                 $$ = scm_cons ($2, $1);
2093         }
2094         ;
2095
2096 figure_spec:
2097         FIGURE_OPEN figure_list FIGURE_CLOSE {
2098                 Music *m = MY_MAKE_MUSIC ("EventChord");
2099                 $2 = scm_reverse_x ($2, SCM_EOL);
2100                 m->set_property ("elements", $2);
2101                 $$ = m->self_scm ();
2102         }
2103         ;
2104
2105
2106 optional_rest:
2107         /**/   { $$ = 0; }
2108         | REST { $$ = 1; }
2109         ;
2110
2111 simple_element:
2112         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2113
2114                 Input i = THIS->pop_spot ();
2115                 if (!THIS->lexer_->is_note_state ())
2116                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2117
2118                 Music *n = 0;
2119                 if ($6)
2120                         n = MY_MAKE_MUSIC ("RestEvent");
2121                 else
2122                         n = MY_MAKE_MUSIC ("NoteEvent");
2123
2124                 n->set_property ("pitch", $1);
2125                 n->set_property ("duration", $5);
2126
2127                 if (ly_c_number_p ($4))
2128                 {
2129                         int q = ly_scm2int ($4);
2130                         n->set_property ("absolute-octave", scm_int2num (q-1));
2131                 }
2132
2133                 if ($3 % 2)
2134                         n->set_property ("cautionary", SCM_BOOL_T);
2135                 if ($2 % 2 || $3 % 2)
2136                         n->set_property ("force-accidental", SCM_BOOL_T);
2137
2138                 Music *v = MY_MAKE_MUSIC ("EventChord");
2139                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2140                 scm_gc_unprotect_object (n->self_scm ());
2141
2142                 v->set_spot (i);
2143                 n->set_spot (i);
2144                 $$ = v;
2145         }
2146         | DRUM_PITCH optional_notemode_duration {
2147                 Input i = THIS->pop_spot ();
2148
2149                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2150                 n->set_property ("duration", $2);
2151                 n->set_property ("drum-type", $1);
2152
2153                 Music *v = MY_MAKE_MUSIC ("EventChord");
2154                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2155                 scm_gc_unprotect_object (n->self_scm ());
2156                 v->set_spot (i);
2157                 n->set_spot (i);
2158                 $$ = v;
2159
2160         }
2161         | figure_spec optional_notemode_duration {
2162                 Music *m = unsmob_music ($1);
2163                 Input i = THIS->pop_spot ();
2164                 m->set_spot (i);
2165                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2166                 {
2167                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2168                 }
2169                 $$ = m;
2170         }
2171         | RESTNAME optional_notemode_duration           {
2172
2173                 Input i = THIS->pop_spot ();
2174                 Music *ev = 0;
2175                 if (ly_scm2string ($1) == "s") {
2176                         /* Space */
2177                         ev = MY_MAKE_MUSIC ("SkipEvent");
2178                   }
2179                 else {
2180                         ev = MY_MAKE_MUSIC ("RestEvent");
2181
2182                     }
2183                 ev->set_property ("duration", $2);
2184                 ev->set_spot (i);
2185                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2186                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2187                 velt->set_spot (i);
2188
2189                 scm_gc_unprotect_object (ev->self_scm ());
2190
2191                 $$ = velt;
2192         }
2193         | MULTI_MEASURE_REST optional_notemode_duration         {
2194                 THIS->pop_spot ();
2195
2196                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2197                 SCM mus = scm_call_2 (proc, $2,
2198                         make_input (THIS->here_input ()));
2199                 scm_gc_protect_object (mus);
2200                 $$ = unsmob_music (mus);
2201         }
2202
2203         | lyric_element optional_notemode_duration      {
2204                 Input i = THIS->pop_spot ();
2205                 if (!THIS->lexer_->is_lyric_state ())
2206                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2207
2208                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2209                 lreq->set_property ("text", $1);
2210                 lreq->set_property ("duration",$2);
2211                 lreq->set_spot (i);
2212                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2213                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2214
2215                 $$= velt;
2216         }
2217         | new_chord {
2218                 THIS->pop_spot ();
2219
2220                 if (!THIS->lexer_->is_chord_state ())
2221                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2222                 $$ = unsmob_music ($1);
2223         }
2224         ;
2225
2226 lyric_element:
2227         /* FIXME: lyric flavoured markup would be better */
2228         full_markup {
2229         }
2230         | LYRICS_STRING {
2231         }
2232         ;
2233
2234 new_chord:
2235         steno_tonic_pitch optional_notemode_duration   {
2236                 $$ = make_chord ($1, $2, SCM_EOL);
2237         }
2238         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2239                 SCM its = scm_reverse_x ($4, SCM_EOL);
2240                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2241         }
2242         ;
2243
2244 chord_items:
2245         /**/ {
2246                 $$ = SCM_EOL;
2247         }
2248         | chord_items chord_item {
2249                 $$ = scm_cons ($2, $$);
2250         }
2251         ;
2252
2253 chord_separator:
2254         CHORD_COLON {
2255                 $$ = ly_symbol2scm ("chord-colon");
2256         }
2257         | CHORD_CARET {
2258                 $$ = ly_symbol2scm ("chord-caret");
2259         }
2260         | CHORD_SLASH steno_tonic_pitch {
2261                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2262         }
2263         | CHORD_BASS steno_tonic_pitch {
2264                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2265         }
2266         ;
2267
2268 chord_item:
2269         chord_separator {
2270                 $$ = $1;
2271         }
2272         | step_numbers {
2273                 $$ = scm_reverse_x ($1, SCM_EOL);
2274         }
2275         | CHORD_MODIFIER  {
2276                 $$ = $1;
2277         }
2278         ;
2279
2280 step_numbers:
2281         step_number { $$ = scm_cons ($1, SCM_EOL); }
2282         | step_numbers '.' step_number {
2283                 $$ = scm_cons ($3, $$);
2284         }
2285         ;
2286
2287 step_number:
2288         bare_unsigned {
2289                 $$ = make_chord_step ($1, 0);
2290         }
2291         | bare_unsigned '+' {
2292                 $$ = make_chord_step ($1, SHARP);
2293         }
2294         | bare_unsigned CHORD_MINUS {
2295                 $$ = make_chord_step ($1, FLAT);
2296         }
2297         ;
2298
2299 /*
2300         UTILITIES
2301
2302 TODO: should deprecate in favor of Scheme?
2303
2304  */
2305 number_expression:
2306         number_expression '+' number_term {
2307                 $$ = scm_sum ($1, $3);
2308         }
2309         | number_expression '-' number_term {
2310                 $$ = scm_difference ($1, $3);
2311         }
2312         | number_term
2313         ;
2314
2315 number_term:
2316         number_factor {
2317                 $$ = $1;
2318         }
2319         | number_factor '*' number_factor {
2320                 $$ = scm_product ($1, $3);
2321         }
2322         | number_factor '/' number_factor {
2323                 $$ = scm_divide ($1, $3);
2324         }
2325         ;
2326
2327 number_factor:
2328         '-'  number_factor { /* %prec UNARY_MINUS */
2329                 $$ = scm_difference ($2, SCM_UNDEFINED);
2330         }
2331         | bare_number
2332         ;
2333
2334
2335 bare_number:
2336         UNSIGNED        {
2337                 $$ = scm_int2num ($1);
2338         }
2339         | REAL          {
2340                 $$ = $1;
2341         }
2342         | NUMBER_IDENTIFIER             {
2343                 $$ = $1;
2344         }
2345         | REAL NUMBER_IDENTIFIER        {
2346                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2347         }
2348         | UNSIGNED NUMBER_IDENTIFIER    {
2349                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2350         }
2351         ;
2352
2353
2354 bare_unsigned:
2355         UNSIGNED {
2356                         $$ = $1;
2357         }
2358         | DIGIT {
2359                 $$ = $1;
2360         }
2361         ;
2362
2363 bare_int:
2364         bare_number {
2365                 if (scm_integer_p ($1) == SCM_BOOL_T)
2366                 {
2367                         int k = ly_scm2int ($1);
2368                         $$ = k;
2369                 } else
2370                 {
2371                         THIS->parser_error (_ ("need integer number arg"));
2372                         $$ = 0;
2373                 }
2374         }
2375         | '-' bare_int {
2376                 $$ = -$2;
2377         }
2378         ;
2379
2380 exclamations:
2381                 { $$ = 0; }
2382         | exclamations '!'      { $$ ++; }
2383         ;
2384
2385 questions:
2386                 { $$ = 0; }
2387         | questions '?' { $$ ++; }
2388         ;
2389
2390
2391
2392 full_markup:
2393         MARKUP_IDENTIFIER {
2394                 $$ = $1;
2395         }
2396         | MARKUP
2397                 { THIS->lexer_->push_markup_state (); }
2398         markup
2399                 { $$ = $3;
2400                   THIS->lexer_->pop_state ();
2401                 }
2402         ;
2403
2404
2405 /*
2406 This should be done more dynamically if possible.
2407 */
2408 markup:
2409         STRING {
2410                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2411         }
2412         | MARKUP_HEAD_EMPTY {
2413                 $$ = scm_list_1 ($1);
2414         }
2415         | MARKUP_HEAD_MARKUP0 markup {
2416                 $$ = scm_list_2 ($1, $2);
2417         }
2418         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2419                 $$ = scm_list_3 ($1, $2, $3);
2420         }
2421         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2422                 $$ = scm_list_3 ($1, $2, $3);
2423         }
2424         | markup_line {
2425                 $$ = $1;
2426         }
2427         | MARKUP_HEAD_LIST0 markup_list {
2428                 $$ = scm_list_2 ($1,$2);
2429         }
2430         | MARKUP_HEAD_SCM0 embedded_scm {
2431                 $$ = scm_list_2 ($1, $2);
2432         }
2433         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2434                 $$ = scm_list_4 ($1, $2, $3, $4);
2435         }
2436         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2437                 $$ = scm_list_4 ($1, $2, $3, $4);
2438         }
2439         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2440                 $$ = scm_list_3 ($1, $2, $3);
2441         }
2442         | MARKUP_IDENTIFIER {
2443                 $$ = $1;
2444         }
2445         | STRING_IDENTIFIER {
2446                 $$ = $1;
2447         }
2448         | score_block {
2449                 // WIP -- arbitrary, shoul also allow \book or Composite_music.
2450                 Score *score = $1;
2451                 Book *book = new Book;
2452                 book->scores_.push (score);
2453                 extern Music_output_def* get_paper (My_lily_parser *parser);
2454                 Music_output_def *paper = get_paper (THIS);
2455                 SCM s = book->to_stencil (paper, THIS->header_);
2456                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2457                 scm_gc_unprotect_object (score->self_scm ());
2458         }
2459         ;
2460
2461 markup_list:
2462         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2463         ;
2464
2465 markup_line:
2466         '{' markup_list_body '}' {
2467                 SCM line = ly_scheme_function ("line-markup");
2468
2469                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2470         }
2471         ;
2472
2473 markup_list_body:
2474         /**/ {  $$ = SCM_EOL; }
2475         | markup_list_body markup {
2476                 $$ = scm_cons ($2, $1);
2477         }
2478         ;
2479
2480
2481 %%
2482
2483 void
2484 My_lily_parser::set_yydebug (bool )
2485 {
2486 #if 0
2487         yydebug = 1;
2488 #endif
2489 }
2490
2491 void
2492 My_lily_parser::do_yyparse ()
2493 {
2494         yyparse ((void*)this);
2495 }
2496
2497
2498 /*
2499 Should make this optional?    It will also complain when you do
2500
2501         [s4]
2502
2503 which is entirely legitimate.
2504
2505 Or we can scrap it. Barchecks should detect wrong durations, and
2506 skipTypesetting speeds it up a lot.
2507 */
2508
2509 void
2510 My_lily_parser::beam_check (SCM dur)
2511 {
2512   Duration *d = unsmob_duration (dur);
2513   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2514     {
2515       Music *m = unsmob_music (last_beam_start_);
2516       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2517     }
2518   last_beam_start_ = SCM_EOL;
2519 }
2520
2521
2522
2523
2524 /*
2525
2526 It is a little strange to have this function in this file, but
2527 otherwise, we have to import music classes into the lexer.
2528
2529 */
2530 int
2531 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2532 {
2533         if (ly_c_string_p (sid)) {
2534                 *destination = sid;
2535                 return STRING_IDENTIFIER;
2536         } else if (ly_c_number_p (sid)) {
2537                 *destination = sid;
2538                 return NUMBER_IDENTIFIER;
2539         } else if (unsmob_context_def (sid)) {
2540                 *destination = unsmob_context_def (sid)->clone_scm ();
2541                 return CONTEXT_DEF_IDENTIFIER;
2542         } else if (unsmob_score (sid)) {
2543                 Score *score = new Score (*unsmob_score (sid));
2544                 *destination = score->self_scm ();
2545                 return SCORE_IDENTIFIER;
2546         } else if (Music *mus = unsmob_music (sid)) {
2547                 mus = mus->clone ();
2548                 *destination = mus->self_scm ();
2549                 unsmob_music (*destination)->
2550                         set_property ("origin", make_input (last_input_));
2551                 return dynamic_cast<Event*> (mus)
2552                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2553         } else if (unsmob_duration (sid)) {
2554                 *destination = unsmob_duration (sid)->smobbed_copy ();
2555                 return DURATION_IDENTIFIER;
2556         } else if (unsmob_music_output_def (sid)) {
2557                 Music_output_def *p = unsmob_music_output_def (sid);
2558                 p = p->clone ();
2559
2560                 *destination = p->self_scm ();
2561                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2562         } else if (Text_item::markup_p (sid)) {
2563                 *destination = sid;
2564                 return MARKUP_IDENTIFIER;
2565         }
2566
2567         return -1;
2568 }
2569
2570 Music *
2571 property_op_to_music (SCM op)
2572 {
2573         Music *m = 0;
2574         SCM tag = ly_car (op);
2575         SCM symbol = ly_cadr (op);
2576         SCM args = ly_cddr (op);
2577         SCM grob_val = SCM_UNDEFINED;
2578         SCM grob_sym = SCM_UNDEFINED;
2579         SCM val = SCM_UNDEFINED;
2580
2581         if (tag == ly_symbol2scm ("assign"))
2582                 {
2583                 m = MY_MAKE_MUSIC ("PropertySet");
2584                 val = ly_car (args);
2585                 }
2586         else if (tag == ly_symbol2scm ("unset"))
2587                 m = MY_MAKE_MUSIC ("PropertyUnset");
2588         else if (tag == ly_symbol2scm ("poppush")
2589                  || tag == ly_symbol2scm ("push"))
2590                 {
2591                 m = MY_MAKE_MUSIC ("OverrideProperty");
2592                 grob_sym = ly_car (args);
2593                 grob_val = ly_cadr (args);
2594                 }
2595         else if (tag == ly_symbol2scm ("pop")) {
2596                 m = MY_MAKE_MUSIC ("RevertProperty");
2597                 grob_sym = ly_car (args);
2598                 }
2599
2600         m->set_property ("symbol", symbol);
2601
2602         if (val != SCM_UNDEFINED)
2603                 m->set_property ("value", val);
2604         if (grob_val != SCM_UNDEFINED)
2605                 m->set_property ("grob-value", grob_val);
2606
2607         if (grob_sym != SCM_UNDEFINED)
2608                 {
2609                 bool itc = internal_type_checking_global_b;
2610                 /* UGH.
2611                 */
2612                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2613                 if (autobeam)
2614                         internal_type_checking_global_b = false;
2615                 m->set_property ("grob-property", grob_sym);
2616                 if (autobeam)
2617                         internal_type_checking_global_b = itc;
2618                 }
2619
2620         if (op == ly_symbol2scm ("poppush"))
2621                 m->set_property ("pop-first", SCM_BOOL_T);
2622
2623
2624         return m;
2625 }
2626
2627 Music*
2628 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2629 {
2630         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2631
2632         csm->set_property ("element", m->self_scm ());
2633         scm_gc_unprotect_object (m->self_scm ());
2634
2635         csm->set_property ("context-type",
2636                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2637         csm->set_property ("property-operations", ops);
2638
2639         if (ly_c_string_p (id))
2640                 csm->set_property ("context-id", id);
2641         return csm;
2642 }
2643
2644 SCM
2645 get_next_unique_context ()
2646 {
2647         static int new_context_count;
2648         char s[1024];
2649         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2650         return scm_makfrom0str (s);
2651 }
2652