lily/parser.yy

   1 /* -*- mode: c++; c-file-style: "linux"; indent-tabs-mode: t -*- */
   2 /*
   3   This file is part of LilyPond, the GNU music typesetter.
   4
   5   Copyright (C) 1997--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   6                  Jan Nieuwenhuizen <janneke@gnu.org>
   7
   8   LilyPond is free software: you can redistribute it and/or modify
   9   it under the terms of the GNU General Public License as published by
  10   the Free Software Foundation, either version 3 of the License, or
  11   (at your option) any later version.
  12
  13   LilyPond is distributed in the hope that it will be useful,
  14   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16   GNU General Public License for more details.
  17
  18   You should have received a copy of the GNU General Public License
  19   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  20 */
  21
  22 /* Mode and indentation are at best a rough approximation based on TAB
  23  * formatting (reasonable for compatibility with unspecific editor
  24  * modes as Bison modes are hard to find) and need manual correction
  25  * frequently.  Without a reasonably dependable way of formatting a
  26  * Bison file sensibly, there is little point in trying to fix the
  27  * inconsistent state of indentation.
  28  */
  29
  30 %{
  31
  32 #define yyerror Lily_parser::parser_error
  33
  34 /* We use custom location type: Input objects */
  35 #define YYLTYPE Input
  36 #define YYSTYPE SCM
  37 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  38         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  39
  40 #define YYPRINT(file, type, value)                                      \
  41         do {                                                            \
  42                 if (scm_is_eq (value, SCM_UNSPECIFIED))                 \
  43                         break;                                          \
  44                 char *p = scm_to_locale_string                          \
  45                         (scm_simple_format (SCM_BOOL_F,                 \
  46                                             scm_from_locale_string ("~S"), \
  47                                             scm_list_1 (value)));       \
  48                 fputs (p, file);                                        \
  49                 free (p);                                               \
  50         } while (0)
  51
  52 %}
  53
  54 %parse-param {Lily_parser *parser}
  55 %parse-param {SCM *retval}
  56 %lex-param {Lily_parser *parser}
  57 %error-verbose
  58 %debug
  59
  60 /* We use SCMs to do strings, because it saves us the trouble of
  61 deleting them.  Let's hope that a stack overflow doesn't trigger a move
  62 of the parse stack onto the heap. */
  63
  64 %left PREC_BOT
  65 %nonassoc REPEAT
  66 %nonassoc ALTERNATIVE
  67
  68 /* The above precedences tackle the shift/reduce problem
  69
  70 1.  \repeat
  71         \repeat .. \alternative
  72
  73     \repeat { \repeat .. \alternative }
  74
  75 or
  76
  77     \repeat { \repeat } \alternative
  78 */
  79
  80 %nonassoc COMPOSITE
  81 %left ADDLYRICS
  82
  83  /* ADDLYRICS needs to have lower precedence than argument scanning,
  84   * or we won't be able to tell music apart from closed_music without
  85   * lookahead in the context of function calls.
  86   */
  87
  88 %nonassoc DEFAULT
  89
  90  /* \default is only applied after exhausting function arguments */
  91
  92 %nonassoc FUNCTION_ARGLIST
  93
  94  /* expressions with units are permitted into argument lists */
  95
  96 %right PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  97       UNSIGNED REAL DURATION_IDENTIFIER ':'
  98
  99  /* The above are the symbols that can start optional function arguments
 100     that are recognized in the grammar rather than by predicate
 101  */
 102
 103 %nonassoc NUMBER_IDENTIFIER '/'
 104
 105  /* Number-unit expressions, where permitted, are concatenated into
 106   * function arguments, just like fractions and tremoli.  Tremoli must
 107   * not have higher precedence than UNSIGNED, or Lilypond will not
 108   * join ':' with a following optional number.
 109   */
 110
 111 %left PREC_TOP
 112
 113
 114
 115
 116 %pure_parser
 117 %locations
 118
 119
 120
 121 %{ // -*-Fundamental-*-
 122
 123 /*
 124 FIXME:
 125
 126    * The rules for who is protecting what are very shady.  Uniformise
 127      this.
 128
 129    * There are too many lexical modes?
 130 */
 131
 132 #include "config.hh"
 133
 134 #include <cctype>
 135 #include <cstdlib>
 136 #include <cstdio>
 137 using namespace std;
 138
 139 #include "book.hh"
 140 #include "context-def.hh"
 141 #include "context-mod.hh"
 142 #include "dimensions.hh"
 143 #include "file-path.hh"
 144 #include "input.hh"
 145 #include "international.hh"
 146 #include "lily-guile.hh"
 147 #include "lily-lexer.hh"
 148 #include "lily-parser.hh"
 149 #include "main.hh"
 150 #include "misc.hh"
 151 #include "music.hh"
 152 #include "output-def.hh"
 153 #include "paper-book.hh"
 154 #include "scm-hash.hh"
 155 #include "score.hh"
 156 #include "text-interface.hh"
 157 #include "warn.hh"
 158
 159 void
 160 Lily_parser::parser_error (Input const *i, Lily_parser *parser, SCM *, string s)
 161 {
 162         parser->parser_error (*i, s);
 163 }
 164
 165 #define MYBACKUP(Token, Value, Location)                                \
 166 do                                                                      \
 167         if (yychar == YYEMPTY)                                          \
 168         {                                                               \
 169                 if (Token)                                              \
 170                         parser->lexer_->push_extra_token (Token, Value); \
 171                 parser->lexer_->push_extra_token (BACKUP);              \
 172         } else {                                                        \
 173                 parser->parser_error                                    \
 174                         (Location, _("Too much lookahead"));            \
 175         }                                                               \
 176 while (0)
 177
 178
 179 #define MYREPARSE(Location, Pred, Token, Value)                         \
 180 do                                                                      \
 181         if (yychar == YYEMPTY)                                          \
 182         {                                                               \
 183                 parser->lexer_->push_extra_token (Token, Value);        \
 184                 parser->lexer_->push_extra_token (REPARSE,              \
 185                                                   Pred);                \
 186         } else {                                                        \
 187                 parser->parser_error                                    \
 188                         (Location, _("Too much lookahead"));            \
 189         }                                                               \
 190 while (0)
 191
 192 %}
 193
 194
 195 %{
 196
 197 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 198
 199 /* ES TODO:
 200 - Don't use lily module, create a new module instead.
 201 - delay application of the function
 202 */
 203 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 204   scm_apply_0 (proc, args)
 205 /* Syntactic Sugar. */
 206 #define MAKE_SYNTAX(name, location, ...)        \
 207   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (parser->self_scm (), make_input (location) , ##__VA_ARGS__, SCM_UNDEFINED))
 208 #define START_MAKE_SYNTAX(name, ...)                                    \
 209         scm_list_n (ly_lily_module_constant (name) , ##__VA_ARGS__, SCM_UNDEFINED)
 210 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 211         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (parser->self_scm (), make_input (location), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 212
 213 SCM get_next_unique_context_id ();
 214 SCM get_next_unique_lyrics_context_id ();
 215
 216 #undef _
 217 #if !HAVE_GETTEXT
 218 #define _(x) x
 219 #else
 220 #include <libintl.h>
 221 #define _(x) gettext (x)
 222 #endif
 223
 224
 225 static Music *make_music_with_input (SCM name, Input where);
 226 SCM check_scheme_arg (Lily_parser *parser, Input loc,
 227                       SCM arg, SCM args, SCM pred);
 228 SCM make_music_from_simple (Lily_parser *parser, Input loc, SCM pitch);
 229 SCM loc_on_music (Input loc, SCM arg);
 230 SCM make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list);
 231 SCM make_chord_step (SCM step, Rational alter);
 232 SCM make_simple_markup (SCM a);
 233 bool is_duration (int t);
 234 bool is_regular_identifier (SCM id);
 235 int yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser);
 236
 237 %}
 238
 239 /* The third option is an alias that will be used to display the
 240    syntax error.  Bison CVS now correctly handles backslash escapes.
 241
 242    FIXME: Bison needs to translate some of these, eg, STRING.
 243
 244 */
 245
 246 /* Keyword tokens with plain escaped name.  */
 247 %token END_OF_FILE 0 "end of input"
 248 %token ACCEPTS "\\accepts"
 249 %token ADDLYRICS "\\addlyrics"
 250 %token ALIAS "\\alias"
 251 %token ALTERNATIVE "\\alternative"
 252 %token BOOK "\\book"
 253 %token BOOKPART "\\bookpart"
 254 %token CHANGE "\\change"
 255 %token CHORDMODE "\\chordmode"
 256 %token CHORDS "\\chords"
 257 %token CONSISTS "\\consists"
 258 %token CONTEXT "\\context"
 259 %token DEFAULT "\\default"
 260 %token DEFAULTCHILD "\\defaultchild"
 261 %token DENIES "\\denies"
 262 %token DESCRIPTION "\\description"
 263 %token DRUMMODE "\\drummode"
 264 %token DRUMS "\\drums"
 265 %token FIGUREMODE "\\figuremode"
 266 %token FIGURES "\\figures"
 267 %token HEADER "\\header"
 268 %token INVALID "\\version-error"
 269 %token LAYOUT "\\layout"
 270 %token LYRICMODE "\\lyricmode"
 271 %token LYRICS "\\lyrics"
 272 %token LYRICSTO "\\lyricsto"
 273 %token MARKUP "\\markup"
 274 %token MARKUPLIST "\\markuplist"
 275 %token MIDI "\\midi"
 276 %token NAME "\\name"
 277 %token NOTEMODE "\\notemode"
 278 %token OVERRIDE "\\override"
 279 %token PAPER "\\paper"
 280 %token REMOVE "\\remove"
 281 %token REPEAT "\\repeat"
 282 %token REST "\\rest"
 283 %token REVERT "\\revert"
 284 %token SCORE "\\score"
 285 %token SEQUENTIAL "\\sequential"
 286 %token SET "\\set"
 287 %token SIMULTANEOUS "\\simultaneous"
 288 %token TEMPO "\\tempo"
 289 %token TYPE "\\type"
 290 %token UNSET "\\unset"
 291 %token WITH "\\with"
 292
 293 /* Keyword token exceptions.  */
 294 %token NEWCONTEXT "\\new"
 295
 296
 297 /* Other string tokens.  */
 298
 299 %token CHORD_BASS "/+"
 300 %token CHORD_CARET "^"
 301 %token CHORD_COLON ":"
 302 %token CHORD_MINUS "-"
 303 %token CHORD_SLASH "/"
 304 %token ANGLE_OPEN "<"
 305 %token ANGLE_CLOSE ">"
 306 %token DOUBLE_ANGLE_OPEN "<<"
 307 %token DOUBLE_ANGLE_CLOSE ">>"
 308 %token E_BACKSLASH "\\"
 309 %token E_ANGLE_CLOSE "\\>"
 310 %token E_CHAR "\\C[haracter]"
 311 %token E_CLOSE "\\)"
 312 %token E_EXCLAMATION "\\!"
 313 %token E_BRACKET_OPEN "\\["
 314 %token E_OPEN "\\("
 315 %token E_BRACKET_CLOSE "\\]"
 316 %token E_ANGLE_OPEN "\\<"
 317 %token E_PLUS "\\+"
 318 %token E_TILDE "\\~"
 319 %token EXTENDER "__"
 320
 321 /*
 322 If we give names, Bison complains.
 323 */
 324 %token FIGURE_CLOSE /* "\\>" */
 325 %token FIGURE_OPEN /* "\\<" */
 326 %token FIGURE_SPACE "_"
 327 %token HYPHEN "--"
 328
 329 %token CHORDMODIFIERS
 330 %token LYRIC_MARKUP
 331 %token MULTI_MEASURE_REST
 332
 333
 334 %token E_UNSIGNED
 335 %token UNSIGNED
 336
 337 /* Artificial tokens, for more generic function syntax */
 338 %token EXPECT_MARKUP "markup?"
 339 %token EXPECT_PITCH "ly:pitch?"
 340 %token EXPECT_DURATION "ly:duration?"
 341 %token EXPECT_SCM "scheme?"
 342 %token BACKUP "(backed-up?)"
 343 %token REPARSE "(reparsed?)"
 344 %token EXPECT_MARKUP_LIST "markup-list?"
 345 %token EXPECT_OPTIONAL "optional?"
 346 /* After the last argument. */
 347 %token EXPECT_NO_MORE_ARGS;
 348
 349 /* An artificial token for parsing embedded Lilypond */
 350 %token EMBEDDED_LILY "#{"
 351
 352 %token BOOK_IDENTIFIER
 353 %token CHORDMODIFIER_PITCH
 354 %token CHORD_MODIFIER
 355 %token CHORD_REPETITION
 356 %token CONTEXT_DEF_IDENTIFIER
 357 %token CONTEXT_MOD_IDENTIFIER
 358 %token DRUM_PITCH
 359 %token PITCH_IDENTIFIER
 360 %token DURATION_IDENTIFIER
 361 %token EVENT_IDENTIFIER
 362 %token EVENT_FUNCTION
 363 %token FRACTION
 364 %token LYRICS_STRING
 365 %token LYRIC_ELEMENT
 366 %token LYRIC_MARKUP_IDENTIFIER
 367 %token MARKUP_FUNCTION
 368 %token MARKUP_LIST_FUNCTION
 369 %token MARKUP_IDENTIFIER
 370 %token MARKUPLIST_IDENTIFIER
 371 %token MUSIC_FUNCTION
 372 %token MUSIC_IDENTIFIER
 373 %token NOTENAME_PITCH
 374 %token NUMBER_IDENTIFIER
 375 %token OUTPUT_DEF_IDENTIFIER
 376 %token REAL
 377 %token RESTNAME
 378 %token SCM_FUNCTION
 379 %token SCM_IDENTIFIER
 380 %token SCM_TOKEN
 381 %token SCORE_IDENTIFIER
 382 %token STRING
 383 %token TONICNAME_PITCH
 384
 385 %left '-' '+'
 386
 387 /* We don't assign precedence to / and *, because we might need varied
 388 prec levels in different prods */
 389
 390 %left UNARY_MINUS
 391
 392 %%
 393
 394 start_symbol:
 395         lilypond
 396         | EMBEDDED_LILY {
 397                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 398                 parser->lexer_->push_note_state (nn);
 399         } embedded_lilypond {
 400                 parser->lexer_->pop_state ();
 401                 *retval = $3;
 402         }
 403         ;
 404
 405 lilypond:       /* empty */ { $$ = SCM_UNSPECIFIED; }
 406         | lilypond toplevel_expression {
 407         }
 408         | lilypond assignment {
 409         }
 410         | lilypond embedded_scm {
 411         }
 412         | lilypond error {
 413                 parser->error_level_ = 1;
 414         }
 415         | lilypond INVALID      {
 416                 parser->error_level_ = 1;
 417         }
 418         ;
 419
 420
 421 toplevel_expression:
 422         {
 423                 parser->lexer_->add_scope (get_header (parser));
 424         } lilypond_header {
 425                 parser->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $2);
 426         }
 427         | book_block {
 428                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-book-handler");
 429                 scm_call_2 (proc, parser->self_scm (), $1);
 430         }
 431         | bookpart_block {
 432                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 433                 scm_call_2 (proc, parser->self_scm (), $1);
 434         }
 435         | score_block {
 436                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-score-handler");
 437                 scm_call_2 (proc, parser->self_scm (), $1);
 438         }
 439         | composite_music {
 440                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-music-handler");
 441                 scm_call_2 (proc, parser->self_scm (), $1);
 442         }
 443         | full_markup {
 444                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 445                 scm_call_2 (proc, parser->self_scm (), scm_list_1 ($1));
 446         }
 447         | full_markup_list {
 448                 SCM proc = parser->lexer_->lookup_identifier ("toplevel-text-handler");
 449                 scm_call_2 (proc, parser->self_scm (), $1);
 450         }
 451         | output_def {
 452                 SCM id = SCM_EOL;
 453                 Output_def * od = unsmob_output_def ($1);
 454
 455                 if (od->c_variable ("is-paper") == SCM_BOOL_T)
 456                         id = ly_symbol2scm ("$defaultpaper");
 457                 else if (od->c_variable ("is-midi") == SCM_BOOL_T)
 458                         id = ly_symbol2scm ("$defaultmidi");
 459                 else if (od->c_variable ("is-layout") == SCM_BOOL_T)
 460                         id = ly_symbol2scm ("$defaultlayout");
 461
 462                 parser->lexer_->set_identifier (id, $1);
 463         }
 464         ;
 465
 466 embedded_scm_bare:
 467         SCM_TOKEN
 468         {
 469                 $$ = parser->lexer_->eval_scm_token ($1);
 470         }
 471         | SCM_IDENTIFIER
 472         ;
 473
 474 embedded_scm_bare_arg:
 475         embedded_scm_bare
 476         | STRING
 477         | full_markup
 478         | full_markup_list
 479         | context_modification
 480         | score_block
 481         | context_def_spec_block
 482         | book_block
 483         | bookpart_block
 484         | output_def
 485         ;
 486
 487 /* The generic version may end in music, or not */
 488
 489 embedded_scm:
 490         embedded_scm_bare
 491         | scm_function_call
 492         ;
 493
 494 embedded_scm_arg:
 495         embedded_scm_bare_arg
 496         | scm_function_call
 497         | music_arg
 498         ;
 499
 500 scm_function_call:
 501         SCM_FUNCTION function_arglist {
 502                 $$ = MAKE_SYNTAX ("music-function", @$,
 503                                          $1, $2);
 504         }
 505         ;
 506
 507 embedded_lilypond:
 508         /* empty */
 509         {
 510                 $$ = MAKE_SYNTAX ("void-music", @$);
 511         }
 512         | identifier_init
 513         | music_embedded music_embedded music_list {
 514                 $3 = scm_reverse_x ($3, SCM_EOL);
 515                 if (unsmob_music ($2))
 516                         $3 = scm_cons ($2, $3);
 517                 if (unsmob_music ($1))
 518                         $3 = scm_cons ($1, $3);
 519                 $$ = MAKE_SYNTAX ("sequential-music", @$, $3);
 520         }
 521         | error {
 522                 parser->error_level_ = 1;
 523                 $$ = SCM_UNSPECIFIED;
 524         }
 525         | INVALID embedded_lilypond {
 526                 parser->error_level_ = 1;
 527                 $$ = $2;
 528         }
 529         ;
 530
 531
 532 lilypond_header_body:
 533         /* empty */ { $$ = SCM_UNSPECIFIED; }
 534         | lilypond_header_body assignment  {
 535
 536         }
 537         | lilypond_header_body embedded_scm  {
 538
 539         }
 540         ;
 541
 542 lilypond_header:
 543         HEADER '{' lilypond_header_body '}'     {
 544                 $$ = parser->lexer_->remove_scope ();
 545         }
 546         ;
 547
 548 /*
 549         DECLARATIONS
 550 */
 551 assignment_id:
 552         STRING          { $$ = $1; }
 553         | LYRICS_STRING { $$ = $1; }
 554         ;
 555
 556 assignment:
 557         assignment_id '=' identifier_init  {
 558                 parser->lexer_->set_identifier ($1, $3);
 559                 $$ = SCM_UNSPECIFIED;
 560         }
 561         | assignment_id property_path '=' identifier_init {
 562                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 563                 parser->lexer_->set_identifier (path, $4);
 564                 $$ = SCM_UNSPECIFIED;
 565         }
 566         ;
 567
 568
 569 identifier_init:
 570         score_block
 571         | book_block
 572         | bookpart_block
 573         | output_def
 574         | context_def_spec_block
 575         | music_assign
 576         | post_event_nofinger
 577         | number_expression
 578         | FRACTION
 579         | string
 580         | embedded_scm
 581         | full_markup_list
 582         | context_modification
 583         ;
 584
 585 context_def_spec_block:
 586         CONTEXT '{' context_def_spec_body '}'
 587                 {
 588                 $$ = $3;
 589         }
 590         ;
 591
 592 context_mod_arg:
 593         embedded_scm
 594         | composite_music
 595         ;
 596
 597 context_mod_embedded:
 598         context_mod_arg
 599         {
 600                 if (unsmob_music ($1)) {
 601                         SCM proc = parser->lexer_->lookup_identifier ("context-mod-music-handler");
 602                         $1 = scm_call_2 (proc, parser->self_scm (), $1);
 603                 }
 604                 if (unsmob_context_mod ($1))
 605                         $$ = $1;
 606                 else {
 607                         parser->parser_error (@1, _ ("not a context mod"));
 608                 }
 609         }
 610         ;
 611
 612
 613 context_def_spec_body:
 614         /**/ {
 615                 $$ = Context_def::make_scm ();
 616                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 617         }
 618         | CONTEXT_DEF_IDENTIFIER {
 619                 $$ = $1;
 620                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         | context_def_spec_body context_modification {
 626                 Context_def *td = unsmob_context_def ($$);
 627                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 628                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 629                     td->add_context_mod (scm_car (m));
 630                 }
 631         }
 632         | context_def_spec_body context_mod_embedded {
 633                 Context_def *td = unsmob_context_def ($$);
 634                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 635                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 636                     td->add_context_mod (scm_car (m));
 637                 }
 638         }
 639         ;
 640
 641
 642
 643 book_block:
 644         BOOK '{' book_body '}'  {
 645                 $$ = $3;
 646                 pop_paper (parser);
 647                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 648         }
 649         ;
 650
 651 /* FIXME:
 652    * Use 'handlers' like for toplevel-* stuff?
 653    * grok \layout and \midi?  */
 654 book_body:
 655         {
 656                 Book *book = new Book;
 657                 init_papers (parser);
 658                 book->origin ()->set_spot (@$);
 659                 book->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (parser->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 660                 book->paper_->unprotect ();
 661                 push_paper (parser, book->paper_);
 662                 book->header_ = get_header (parser);
 663                 $$ = book->unprotect ();
 664                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$);
 665         }
 666         | BOOK_IDENTIFIER {
 667                 unsmob_book ($1)->origin ()->set_spot (@$);
 668                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 669         }
 670         | book_body paper_block {
 671                 unsmob_book ($1)->paper_ = unsmob_output_def ($2);
 672                 set_paper (parser, unsmob_output_def ($2));
 673         }
 674         | book_body bookpart_block {
 675                 SCM proc = parser->lexer_->lookup_identifier ("book-bookpart-handler");
 676                 scm_call_2 (proc, $1, $2);
 677         }
 678         | book_body score_block {
 679                 SCM proc = parser->lexer_->lookup_identifier ("book-score-handler");
 680                 scm_call_2 (proc, $1, $2);
 681         }
 682         | book_body composite_music {
 683                 SCM proc = parser->lexer_->lookup_identifier ("book-music-handler");
 684                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 685         }
 686         | book_body full_markup {
 687                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 688                 scm_call_2 (proc, $1, scm_list_1 ($2));
 689         }
 690         | book_body full_markup_list {
 691                 SCM proc = parser->lexer_->lookup_identifier ("book-text-handler");
 692                 scm_call_2 (proc, $1, $2);
 693         }
 694         | book_body
 695         {
 696                 parser->lexer_->add_scope (unsmob_book ($1)->header_);
 697         } lilypond_header
 698         | book_body embedded_scm { }
 699         | book_body error {
 700                 Book *book = unsmob_book ($1);
 701                 book->paper_ = 0;
 702                 book->scores_ = SCM_EOL;
 703                 book->bookparts_ = SCM_EOL;
 704         }
 705         ;
 706
 707 bookpart_block:
 708         BOOKPART '{' bookpart_body '}' {
 709                 $$ = $3;
 710                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 711         }
 712         ;
 713
 714 bookpart_body:
 715         {
 716                 Book *book = new Book;
 717                 book->origin ()->set_spot (@$);
 718                 $$ = book->unprotect ();
 719                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$);
 720         }
 721         | BOOK_IDENTIFIER {
 722                 unsmob_book ($1)->origin ()->set_spot (@$);
 723                 parser->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 724         }
 725         | bookpart_body paper_block {
 726                 unsmob_book ($$)->paper_ = unsmob_output_def ($2);
 727         }
 728         | bookpart_body score_block {
 729                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-score-handler");
 730                 scm_call_2 (proc, $1, $2);
 731         }
 732         | bookpart_body composite_music {
 733                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-music-handler");
 734                 scm_call_3 (proc, parser->self_scm (), $1, $2);
 735         }
 736         | bookpart_body full_markup {
 737                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 738                 scm_call_2 (proc, $1, scm_list_1 ($2));
 739         }
 740         | bookpart_body full_markup_list {
 741                 SCM proc = parser->lexer_->lookup_identifier ("bookpart-text-handler");
 742                 scm_call_2 (proc, $1, $2);
 743         }
 744         | bookpart_body
 745         {
 746                 Book *book = unsmob_book ($1);
 747                 if (!ly_is_module (book->header_))
 748                         book->header_ = ly_make_module (false);
 749                 parser->lexer_->add_scope (book->header_);
 750         } lilypond_header
 751         | bookpart_body embedded_scm { }
 752         | bookpart_body error {
 753                 Book *book = unsmob_book ($1);
 754                 book->paper_ = 0;
 755                 book->scores_ = SCM_EOL;
 756         }
 757         ;
 758
 759 score_block:
 760         SCORE '{' score_body '}'        {
 761                 $$ = $3;
 762         }
 763         ;
 764
 765 score_body:
 766         music {
 767                 SCM scorify = ly_lily_module_constant ("scorify-music");
 768                 $$ = scm_call_2 (scorify, $1, parser->self_scm ());
 769
 770                 unsmob_score ($$)->origin ()->set_spot (@$);
 771         }
 772         | SCORE_IDENTIFIER {
 773                 unsmob_score ($$)->origin ()->set_spot (@$);
 774         }
 775         | score_body
 776         {
 777                 Score *score = unsmob_score ($1);
 778                 if (!ly_is_module (score->get_header ()))
 779                         score->set_header (ly_make_module (false));
 780                 parser->lexer_->add_scope (score->get_header ());
 781         } lilypond_header
 782         | score_body output_def {
 783                 Output_def *od = unsmob_output_def ($2);
 784                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 785                 {
 786                         parser->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 787
 788                 }
 789                 else
 790                 {
 791                         unsmob_score ($1)->add_output_def (od);
 792                 }
 793         }
 794         | score_body error {
 795                 unsmob_score ($$)->error_found_ = true;
 796         }
 797         ;
 798
 799
 800 /*
 801         OUTPUT DEF
 802 */
 803
 804 paper_block:
 805         output_def {
 806                 Output_def *od = unsmob_output_def ($1);
 807
 808                 if (od->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 809                 {
 810                         parser->parser_error (@1, _ ("need \\paper for paper block"));
 811                         $$ = get_paper (parser)->unprotect ();
 812                 }
 813         }
 814         ;
 815
 816
 817 output_def:
 818         output_def_body '}' {
 819                 $$ = $1;
 820
 821                 parser->lexer_->remove_scope ();
 822                 parser->lexer_->pop_state ();
 823         }
 824         ;
 825
 826 output_def_head:
 827         PAPER {
 828                 Output_def *p = get_paper (parser);
 829                 p->input_origin_ = @$;
 830                 parser->lexer_->add_scope (p->scope_);
 831                 $$ = p->unprotect ();
 832         }
 833         | MIDI    {
 834                 Output_def *p = get_midi (parser);
 835                 $$ = p->unprotect ();
 836                 parser->lexer_->add_scope (p->scope_);
 837         }
 838         | LAYOUT        {
 839                 Output_def *p = get_layout (parser);
 840
 841                 parser->lexer_->add_scope (p->scope_);
 842                 $$ = p->unprotect ();
 843         }
 844         ;
 845
 846 output_def_head_with_mode_switch:
 847         output_def_head {
 848                 parser->lexer_->push_initial_state ();
 849                 $$ = $1;
 850         }
 851         ;
 852
 853 // We need this weird nonterminal because both music as well as a
 854 // context definition can start with \context and the difference is
 855 // only apparent after looking at the next token.  If it is '{', there
 856 // is still time to escape from notes mode.
 857
 858 music_or_context_def:
 859         music_arg
 860         {
 861                 parser->lexer_->pop_state ();
 862         }
 863         | CONTEXT
 864         {
 865                 parser->lexer_->pop_state ();
 866         } '{' context_def_spec_body '}'
 867         {
 868                 $$ = $4;
 869         }
 870         ;
 871
 872 output_def_body:
 873         output_def_head_with_mode_switch '{' {
 874                 $$ = $1;
 875                 unsmob_output_def ($$)->input_origin_.set_spot (@$);
 876         }
 877         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
 878                 Output_def *o = unsmob_output_def ($3);
 879                 o->input_origin_.set_spot (@$);
 880                 $$ = o->self_scm ();
 881                 parser->lexer_->remove_scope ();
 882                 parser->lexer_->add_scope (o->scope_);
 883         }
 884         | output_def_body assignment  {
 885
 886         }
 887         | output_def_body embedded_scm  {
 888
 889         }
 890         | output_def_body
 891         {
 892                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
 893                 parser->lexer_->push_note_state (nn);
 894         } music_or_context_def
 895         {
 896                 if (unsmob_context_def ($3))
 897                         assign_context_def (unsmob_output_def ($1), $3);
 898                 else {
 899
 900                         SCM proc = parser->lexer_->lookup_identifier
 901                                      ("output-def-music-handler");
 902                         scm_call_3 (proc, parser->self_scm (),
 903                                     $1, $3);
 904                 }
 905         }
 906         | output_def_body error {
 907
 908         }
 909         ;
 910
 911 tempo_event:
 912         TEMPO steno_duration '=' tempo_range    {
 913                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
 914         }
 915         | TEMPO scalar_closed steno_duration '=' tempo_range    {
 916                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
 917         }
 918         | TEMPO scalar {
 919                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
 920         }
 921         ;
 922
 923 /*
 924 The representation of a  list is reversed to have efficient append.  */
 925
 926 music_list:
 927         /* empty */ {
 928                 $$ = SCM_EOL;
 929         }
 930         | music_list music_embedded {
 931                 if (unsmob_music ($2))
 932                         $$ = scm_cons ($2, $1);
 933         }
 934         | music_list error {
 935                 Music *m = MY_MAKE_MUSIC("Music", @$);
 936                 // ugh. code dup
 937                 m->set_property ("error-found", SCM_BOOL_T);
 938                 $$ = scm_cons (m->self_scm (), $1);
 939                 m->unprotect (); /* UGH */
 940         }
 941         ;
 942
 943 braced_music_list:
 944         '{' music_list '}'
 945         {
 946                 $$ = scm_reverse_x ($2, SCM_EOL);
 947         }
 948         ;
 949
 950 music:  music_arg
 951         | lyric_element_music
 952         ;
 953
 954 music_embedded:
 955         music
 956         | embedded_scm
 957         {
 958                 if (unsmob_music ($1)
 959                     || scm_is_eq ($1, SCM_UNSPECIFIED))
 960                         $$ = $1;
 961                 else
 962                 {
 963                         @$.warning (_ ("Ignoring non-music expression"));
 964                         $$ = SCM_UNSPECIFIED;
 965                 }
 966         }
 967         ;
 968
 969 music_arg:
 970         simple_music
 971         {
 972                 $$ = make_music_from_simple (parser, @1, $1);
 973                 if (!unsmob_music ($$))
 974                         parser->parser_error (@1, _ ("music expected"));
 975         }
 976         | composite_music %prec COMPOSITE
 977         ;
 978
 979 music_assign:
 980         simple_music
 981         | composite_music %prec COMPOSITE
 982         | lyric_element_music
 983         ;
 984
 985 repeated_music:
 986         REPEAT simple_string unsigned_number music
 987         {
 988                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
 989         }
 990         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
 991         {
 992                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
 993         }
 994         ;
 995
 996 sequential_music:
 997         SEQUENTIAL braced_music_list {
 998                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
 999         }
1000         | braced_music_list {
1001                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1002         }
1003         ;
1004
1005 simultaneous_music:
1006         SIMULTANEOUS braced_music_list {
1007                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1008         }
1009         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1010                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1011         }
1012         ;
1013
1014 simple_music:
1015         event_chord
1016         | music_property_def
1017         | context_change
1018         ;
1019
1020 context_modification:
1021         WITH { parser->lexer_->push_initial_state (); } '{' context_mod_list '}'
1022         {
1023                 parser->lexer_->pop_state ();
1024                 $$ = $4;
1025         }
1026         | WITH CONTEXT_MOD_IDENTIFIER
1027         {
1028                 $$ = $2;
1029         }
1030         | CONTEXT_MOD_IDENTIFIER
1031         {
1032                 $$ = $1;
1033         }
1034         | WITH embedded_scm_closed
1035         {
1036                 if (unsmob_context_mod ($2))
1037                         $$ = $2;
1038                 else {
1039                         parser->parser_error (@2, _ ("not a context mod"));
1040                         $$ = Context_mod ().smobbed_copy ();
1041                 }
1042         }
1043         ;
1044
1045 optional_context_mod:
1046         /**/ {
1047             $$ = SCM_EOL;
1048         }
1049         | context_modification
1050         {
1051               $$ = $1;
1052         }
1053         ;
1054
1055 context_mod_list:
1056         /**/ {
1057             $$ = Context_mod ().smobbed_copy ();
1058         }
1059         | context_mod_list context_mod  {
1060                  unsmob_context_mod ($1)->add_context_mod ($2);
1061         }
1062         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1063                  Context_mod *md = unsmob_context_mod ($2);
1064                  if (md)
1065                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1066         }
1067         | context_mod_list context_mod_embedded {
1068                 unsmob_context_mod ($1)->add_context_mods
1069                         (unsmob_context_mod ($2)->get_mods ());
1070         }
1071         ;
1072
1073 composite_music:
1074         complex_music
1075         | music_bare
1076         ;
1077
1078 /* Music that can be parsed without lookahead */
1079 closed_music:
1080         music_bare
1081         | complex_music_prefix closed_music
1082         {
1083                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1084         }
1085         | music_function_call_closed
1086         ;
1087
1088 music_bare:
1089         mode_changed_music
1090         | MUSIC_IDENTIFIER
1091         | grouped_music_list
1092         ;
1093
1094 grouped_music_list:
1095         simultaneous_music              { $$ = $1; }
1096         | sequential_music              { $$ = $1; }
1097         ;
1098
1099 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1100  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1101 and this rule returns the reversed list of arguments. */
1102
1103 function_arglist_skip:
1104         function_arglist_common
1105         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip
1106         {
1107                 $$ = scm_cons ($1, $3);
1108         } %prec FUNCTION_ARGLIST
1109         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip
1110         {
1111                 $$ = scm_cons ($1, $3);
1112         } %prec FUNCTION_ARGLIST
1113         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip
1114         {
1115                 $$ = scm_cons ($1, $3);
1116         } %prec FUNCTION_ARGLIST
1117         ;
1118
1119
1120 function_arglist_nonbackup_common:
1121         EXPECT_OPTIONAL EXPECT_PITCH function_arglist pitch_also_in_chords {
1122                 $$ = scm_cons ($4, $3);
1123         }
1124         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed duration_length {
1125                 $$ = scm_cons ($4, $3);
1126         }
1127         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed FRACTION
1128         {
1129                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1130         }
1131         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed post_event_nofinger
1132         {
1133                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1134         }
1135         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' UNSIGNED
1136         {
1137                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1138                 if (scm_is_true (scm_call_1 ($2, n)))
1139                         $$ = scm_cons (n, $3);
1140                 else {
1141                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1142                         t->set_property ("digit", $5);
1143                         $$ = t->unprotect ();
1144                         if (scm_is_true (scm_call_1 ($2, $$)))
1145                                 $$ = scm_cons ($$, $3);
1146                         else
1147                                 $$ = check_scheme_arg (parser, @4, n, $3, $2);
1148                 }
1149
1150         }
1151         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' REAL
1152         {
1153                 $$ = check_scheme_arg (parser, @4,
1154                                        scm_difference ($5, SCM_UNDEFINED),
1155                                        $3, $2);
1156         }
1157         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed '-' NUMBER_IDENTIFIER
1158         {
1159                 $$ = check_scheme_arg (parser, @4,
1160                                        scm_difference ($5, SCM_UNDEFINED),
1161                                        $3, $2);
1162         }
1163         ;
1164
1165 function_arglist_closed_nonbackup:
1166         function_arglist_nonbackup_common
1167         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg_closed
1168         {
1169                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1170         }
1171         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number_closed
1172         {
1173                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1174         }
1175         ;
1176
1177 function_arglist_nonbackup:
1178         function_arglist_nonbackup_common
1179         | EXPECT_OPTIONAL EXPECT_SCM function_arglist embedded_scm_arg
1180         {
1181                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1182         }
1183         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed bare_number
1184         {
1185                 $$ = check_scheme_arg (parser, @4, $4, $3, $2);
1186         }
1187         ;
1188
1189 function_arglist_keep:
1190         function_arglist_common
1191         | function_arglist_backup
1192         ;
1193
1194 function_arglist_closed_keep:
1195         function_arglist_closed_common
1196         | function_arglist_backup
1197         ;
1198
1199 function_arglist_backup:
1200         EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1201         {
1202                 if (scm_is_true (scm_call_1 ($2, $4)))
1203                 {
1204                         $$ = scm_cons ($4, $3);
1205                 } else {
1206                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1207                         MYBACKUP (SCM_IDENTIFIER, $4, @4);
1208                 }
1209         }
1210         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep post_event_nofinger
1211         {
1212                 if (scm_is_true (scm_call_1 ($2, $4)))
1213                 {
1214                         $$ = scm_cons ($4, $3);
1215                 } else {
1216                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1217                         MYBACKUP (EVENT_IDENTIFIER, $4, @4);
1218                 }
1219         }
1220         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep lyric_element
1221         {
1222                 // There is no point interpreting a lyrics string as
1223                 // an event, since we don't allow music possibly
1224                 // followed by durations or postevent into closed
1225                 // music, and we only accept closed music in optional
1226                 // arguments at the moment.  If this changes, more
1227                 // complex schemes might become interesting here as
1228                 // well: see how we do this at the mandatory argument
1229                 // point.
1230                 if (scm_is_true (scm_call_1 ($2, $4)))
1231                         $$ = scm_cons ($4, $3);
1232                 else {
1233                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1234                         MYBACKUP (LYRICS_STRING, $4, @4);
1235                 }
1236         }
1237         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep UNSIGNED
1238         {
1239                 if (scm_is_true (scm_call_1 ($2, $4)))
1240                 {
1241                         $$ = $3;
1242                         MYREPARSE (@4, $2, UNSIGNED, $4);
1243                 } else {
1244                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1245                         MYBACKUP (UNSIGNED, $4, @4);
1246                 }
1247         }
1248         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep REAL
1249         {
1250                 if (scm_is_true (scm_call_1 ($2, $4)))
1251                 {
1252                         $$ = $3;
1253                         MYREPARSE (@4, $2, REAL, $4);
1254                 } else {
1255                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1256                         MYBACKUP (REAL, $4, @4);
1257                 }
1258         }
1259         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep NUMBER_IDENTIFIER
1260         {
1261                 if (scm_is_true (scm_call_1 ($2, $4)))
1262                 {
1263                         $$ = scm_cons ($4, $3);
1264                 } else {
1265                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1266                         MYBACKUP (NUMBER_IDENTIFIER, $4, @4);
1267                 }
1268         }
1269         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep FRACTION
1270         {
1271                 if (scm_is_true (scm_call_1 ($2, $4)))
1272                 {
1273                         $$ = scm_cons ($4, $3);
1274                 } else {
1275                         $$ = scm_cons (loc_on_music (@3, $1), $3);
1276                         MYBACKUP (FRACTION, $4, @4);
1277                 }
1278         }
1279         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' UNSIGNED
1280         {
1281                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1282                 if (scm_is_true (scm_call_1 ($2, n))) {
1283                         $$ = $3;
1284                         MYREPARSE (@5, $2, REAL, n);
1285                 } else {
1286                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @5);
1287                         t->set_property ("digit", $5);
1288                         $$ = t->unprotect ();
1289                         if (scm_is_true (scm_call_1 ($2, $$)))
1290                                 $$ = scm_cons ($$, $3);
1291                         else {
1292                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1293                                 MYBACKUP (UNSIGNED, $5, @5);
1294                                 parser->lexer_->push_extra_token ('-');
1295                         }
1296                 }
1297
1298         }
1299         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' REAL
1300         {
1301                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1302                 if (scm_is_true (scm_call_1 ($2, n))) {
1303                         MYREPARSE (@5, $2, REAL, n);
1304                         $$ = $3;
1305                 } else {
1306                         MYBACKUP (REAL, n, @5);
1307                 }
1308         }
1309         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_keep '-' NUMBER_IDENTIFIER
1310         {
1311                 SCM n = scm_difference ($5, SCM_UNDEFINED);
1312                 if (scm_is_true (scm_call_1 ($2, n))) {
1313                         $$ = scm_cons (n, $3);
1314                 } else {
1315                         MYBACKUP (NUMBER_IDENTIFIER, n, @5);
1316                 }
1317         }
1318         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords
1319         {
1320                 $$ = scm_cons ($4, $3);
1321         }
1322         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length
1323         {
1324                 $$ = scm_cons ($4, $3);
1325         }
1326         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_backup BACKUP
1327         {
1328                 $$ = scm_cons ($1, $3);
1329                 MYBACKUP(0, SCM_UNDEFINED, @3);
1330         }
1331         | function_arglist_backup REPARSE embedded_scm_arg_closed
1332         {
1333                 $$ = check_scheme_arg (parser, @3,
1334                                        $3, $1, $2);
1335         }
1336         | function_arglist_backup REPARSE bare_number
1337         {
1338                 $$ = check_scheme_arg (parser, @3,
1339                                        $3, $1, $2);
1340         }
1341         ;
1342
1343 function_arglist:
1344         function_arglist_common
1345         | function_arglist_nonbackup
1346         ;
1347
1348 function_arglist_common:
1349         function_arglist_bare
1350         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1351         {
1352                 $$ = check_scheme_arg (parser, @3,
1353                                        $3, $2, $1);
1354         }
1355         | EXPECT_SCM function_arglist_closed_optional bare_number
1356         {
1357                 $$ = check_scheme_arg (parser, @3,
1358                                        $3, $2, $1);
1359         }
1360         | EXPECT_SCM function_arglist_closed_optional FRACTION
1361         {
1362                 $$ = check_scheme_arg (parser, @3,
1363                                        $3, $2, $1);
1364         }
1365         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1366         {
1367                 $$ = check_scheme_arg (parser, @3,
1368                                        $3, $2, $1);
1369         }
1370         | function_arglist_common_minus
1371         | function_arglist_common_lyric
1372         ;
1373
1374 function_arglist_common_lyric:
1375         EXPECT_SCM function_arglist_optional lyric_element
1376         {
1377                 // We check how the predicate thinks about a lyrics
1378                 // event or about a markup.  If it accepts neither, we
1379                 // backup the original token.  Otherwise we commit to
1380                 // taking the token.  Depending on what the predicate
1381                 // is willing to accept, we interpret as a string, as
1382                 // a lyric event, or ambiguously (meaning that if
1383                 // something looking like a duration or post event
1384                 // follows, we take the event, otherwise the string).
1385                 SCM lyric_event = MAKE_SYNTAX ("lyric-event", @3, $3,
1386                                                parser->default_duration_.smobbed_copy ());
1387                 if (scm_is_true (scm_call_1 ($1, $3)))
1388                         if (scm_is_true (scm_call_1 ($1, lyric_event)))
1389                         {
1390                                 $$ = $2;
1391                                 MYREPARSE (@3, $1, LYRICS_STRING, $3);
1392                         } else {
1393                                 $$ = scm_cons ($3, $2);
1394                         }
1395                 else if (scm_is_true (scm_call_1 ($1, lyric_event)))
1396                 {
1397                         $$ = $2;
1398                         MYREPARSE (@3, $1, LYRIC_ELEMENT, $3);
1399                 } else {
1400                         // This is going to flag a syntax error, we
1401                         // know the predicate to be false.
1402                         check_scheme_arg (parser, @3,
1403                                           $3, $2, $1);
1404                 }
1405         }
1406         | function_arglist_common_lyric REPARSE lyric_element_arg
1407         {
1408                 // This should never be false
1409                 $$ = check_scheme_arg (parser, @3,
1410                                        $3, $1, $2);
1411         }
1412         ;
1413
1414 function_arglist_common_minus:
1415         EXPECT_SCM function_arglist_closed_optional '-' UNSIGNED
1416         {
1417                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1418                 if (scm_is_true (scm_call_1 ($1, n))) {
1419                         $$ = $2;
1420                         MYREPARSE (@4, $1, REAL, n);
1421                 } else {
1422                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1423                         t->set_property ("digit", $4);
1424                         $$ = t->unprotect ();
1425                         if (scm_is_true (scm_call_1 ($1, $$)))
1426                                 $$ = scm_cons ($$, $2);
1427                         else
1428                                 $$ = check_scheme_arg (parser, @3, n, $2, $1);
1429                 }
1430
1431         }
1432         | EXPECT_SCM function_arglist_closed_optional '-' REAL
1433         {
1434                 $$ = $2;
1435                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1436                 MYREPARSE (@4, $1, REAL, n);
1437         }
1438         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1439         {
1440                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1441                 $$ = check_scheme_arg (parser, @4, n, $2, $1);
1442         }
1443         | function_arglist_common_minus REPARSE bare_number
1444         {
1445                 $$ = check_scheme_arg (parser, @3, $3, $1, $2);
1446         }
1447         ;
1448
1449 function_arglist_closed:
1450         function_arglist_closed_common
1451         | function_arglist_closed_nonbackup
1452         ;
1453
1454 function_arglist_closed_common:
1455         function_arglist_bare
1456         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1457         {
1458                 $$ = check_scheme_arg (parser, @3,
1459                                        $3, $2, $1);
1460         }
1461         | EXPECT_SCM function_arglist_closed_optional bare_number
1462         {
1463                 $$ = check_scheme_arg (parser, @3,
1464                                        $3, $2, $1);
1465         }
1466         | EXPECT_SCM function_arglist_closed_optional '-' UNSIGNED
1467         {
1468                 SCM n = scm_difference ($4, SCM_UNDEFINED);
1469                 if (scm_is_true (scm_call_1 ($1, n))) {
1470                         $$ = scm_cons (n, $2);
1471                 } else {
1472                         Music *t = MY_MAKE_MUSIC ("FingeringEvent", @4);
1473                         t->set_property ("digit", $4);
1474                         $$ = t->unprotect ();
1475                         if (scm_is_true (scm_call_1 ($1, $$)))
1476                                 $$ = scm_cons ($$, $2);
1477                         else
1478                                 $$ = check_scheme_arg (parser, @3, n, $2, $1);
1479                 }
1480
1481         }
1482         | EXPECT_SCM function_arglist_closed_optional '-' REAL
1483         {
1484                 $$ = check_scheme_arg (parser, @3,
1485                                        scm_difference ($4, SCM_UNDEFINED),
1486                                        $2, $1);
1487         }
1488         | EXPECT_SCM function_arglist_closed_optional '-' NUMBER_IDENTIFIER
1489         {
1490                 $$ = check_scheme_arg (parser, @3,
1491                                        scm_difference ($4, SCM_UNDEFINED),
1492                                        $2, $1);
1493         }
1494         | EXPECT_SCM function_arglist_closed_optional post_event_nofinger
1495         {
1496                 $$ = check_scheme_arg (parser, @3,
1497                                        $3, $2, $1);
1498         }
1499         | EXPECT_SCM function_arglist_closed_optional FRACTION
1500         {
1501                 $$ = check_scheme_arg (parser, @3,
1502                                        $3, $2, $1);
1503         }
1504         | EXPECT_SCM function_arglist_optional lyric_element
1505         {
1506                 $$ = check_scheme_arg (parser, @3,
1507                                        $3, $2, $1);
1508         }
1509         ;
1510
1511 function_arglist_optional:
1512         function_arglist_keep %prec FUNCTION_ARGLIST
1513         | function_arglist_backup BACKUP
1514         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1515         {
1516                 $$ = scm_cons ($1, $3);
1517         }
1518         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1519         {
1520                 $$ = scm_cons ($1, $3);
1521         }
1522         ;
1523
1524 function_arglist_closed_optional:
1525         function_arglist_closed_keep %prec FUNCTION_ARGLIST
1526         | function_arglist_backup BACKUP
1527         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1528         {
1529                 $$ = scm_cons ($1, $3);
1530         }
1531         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1532         {
1533                 $$ = scm_cons ($1, $3);
1534         }
1535         ;
1536
1537 embedded_scm_closed:
1538         embedded_scm_bare
1539         | scm_function_call_closed
1540         ;
1541
1542 embedded_scm_arg_closed:
1543         embedded_scm_bare_arg
1544         | scm_function_call_closed
1545         | closed_music
1546         ;
1547
1548 scm_function_call_closed:
1549         SCM_FUNCTION function_arglist_closed {
1550                 $$ = MAKE_SYNTAX ("music-function", @$,
1551                                          $1, $2);
1552         } %prec FUNCTION_ARGLIST
1553         ;
1554
1555 function_arglist_bare:
1556         EXPECT_NO_MORE_ARGS {
1557                 $$ = SCM_EOL;
1558         }
1559         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1560                 $$ = scm_cons ($3, $2);
1561         }
1562         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1563                 $$ = scm_cons ($3, $2);
1564         }
1565         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_skip DEFAULT {
1566                 $$ = scm_cons ($1, $3);
1567         }
1568         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_skip DEFAULT {
1569                 $$ = scm_cons ($1, $3);
1570         }
1571         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_skip DEFAULT {
1572                 $$ = scm_cons ($1, $3);
1573         }
1574         ;
1575
1576 music_function_call:
1577         MUSIC_FUNCTION function_arglist {
1578                 $$ = MAKE_SYNTAX ("music-function", @$,
1579                                          $1, $2);
1580         }
1581         ;
1582
1583
1584 optional_id:
1585         /**/ { $$ = SCM_EOL; }
1586         | '=' simple_string {
1587                 $$ = $2;
1588         }
1589         ;
1590
1591 complex_music:
1592         music_function_call
1593         | repeated_music                { $$ = $1; }
1594         | re_rhythmed_music     { $$ = $1; }
1595         | complex_music_prefix music
1596         {
1597                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1598         }
1599         ;
1600
1601 complex_music_prefix:
1602         CONTEXT simple_string optional_id optional_context_mod {
1603                 Context_mod *ctxmod = unsmob_context_mod ($4);
1604                 SCM mods = SCM_EOL;
1605                 if (ctxmod)
1606                         mods = ctxmod->get_mods ();
1607                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1608         }
1609         | NEWCONTEXT simple_string optional_id optional_context_mod {
1610                 Context_mod *ctxmod = unsmob_context_mod ($4);
1611                 SCM mods = SCM_EOL;
1612                 if (ctxmod)
1613                         mods = ctxmod->get_mods ();
1614                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1615         }
1616         ;
1617
1618 mode_changed_music:
1619         mode_changing_head grouped_music_list {
1620                 if ($1 == ly_symbol2scm ("chords"))
1621                 {
1622                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1623                 }
1624                 else
1625                 {
1626                   $$ = $2;
1627                 }
1628                 parser->lexer_->pop_state ();
1629         }
1630         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1631                 Context_mod *ctxmod = unsmob_context_mod ($2);
1632                 SCM mods = SCM_EOL;
1633                 if (ctxmod)
1634                         mods = ctxmod->get_mods ();
1635                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1636                 if ($1 == ly_symbol2scm ("ChordNames"))
1637                 {
1638                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1639                 }
1640                 parser->lexer_->pop_state ();
1641         }
1642         ;
1643
1644 mode_changing_head:
1645         NOTEMODE {
1646                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
1647                 parser->lexer_->push_note_state (nn);
1648
1649                 $$ = ly_symbol2scm ("notes");
1650         }
1651         | DRUMMODE
1652                 {
1653                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1654                 parser->lexer_->push_note_state (nn);
1655
1656                 $$ = ly_symbol2scm ("drums");
1657         }
1658         | FIGUREMODE {
1659                 parser->lexer_->push_figuredbass_state ();
1660
1661                 $$ = ly_symbol2scm ("figures");
1662         }
1663         | CHORDMODE {
1664                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1665                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1666                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1667                 parser->lexer_->push_chord_state (nn);
1668                 $$ = ly_symbol2scm ("chords");
1669
1670         }
1671         | LYRICMODE
1672                 { parser->lexer_->push_lyric_state ();
1673                 $$ = ly_symbol2scm ("lyrics");
1674         }
1675         ;
1676
1677 mode_changing_head_with_context:
1678         DRUMS {
1679                 SCM nn = parser->lexer_->lookup_identifier ("drumPitchNames");
1680                 parser->lexer_->push_note_state (nn);
1681
1682                 $$ = ly_symbol2scm ("DrumStaff");
1683         }
1684         | FIGURES {
1685                 parser->lexer_->push_figuredbass_state ();
1686
1687                 $$ = ly_symbol2scm ("FiguredBass");
1688         }
1689         | CHORDS {
1690                 SCM nn = parser->lexer_->lookup_identifier ("chordmodifiers");
1691                 parser->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1692                 nn = parser->lexer_->lookup_identifier ("pitchnames");
1693                 parser->lexer_->push_chord_state (nn);
1694                 $$ = ly_symbol2scm ("ChordNames");
1695         }
1696         | LYRICS
1697                 { parser->lexer_->push_lyric_state ();
1698                 $$ = ly_symbol2scm ("Lyrics");
1699         }
1700         ;
1701
1702 new_lyrics:
1703         ADDLYRICS { parser->lexer_->push_lyric_state (); }
1704         /*cont */
1705         composite_music {
1706         /* Can also use music at the expensive of two S/Rs similar to
1707            \repeat \alternative */
1708                 parser->lexer_->pop_state ();
1709
1710                 $$ = scm_cons ($3, SCM_EOL);
1711         }
1712         | new_lyrics ADDLYRICS {
1713                 parser->lexer_->push_lyric_state ();
1714         } composite_music {
1715                 parser->lexer_->pop_state ();
1716                 $$ = scm_cons ($4, $1);
1717         }
1718         ;
1719
1720 re_rhythmed_music:
1721         composite_music new_lyrics {
1722                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1723         } %prec COMPOSITE
1724         | LYRICSTO simple_string {
1725                 parser->lexer_->push_lyric_state ();
1726         } music {
1727                 parser->lexer_->pop_state ();
1728                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1729         }
1730         ;
1731
1732 context_change:
1733         CHANGE STRING '=' STRING  {
1734                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1735         }
1736         ;
1737
1738
1739 property_path_revved:
1740         embedded_scm_closed {
1741                 $$ = scm_cons ($1, SCM_EOL);
1742         }
1743         | property_path_revved embedded_scm_closed {
1744                 $$ = scm_cons ($2, $1);
1745         }
1746         ;
1747
1748 property_path:
1749         property_path_revved  {
1750                 $$ = scm_reverse_x ($1, SCM_EOL);
1751         }
1752         ;
1753
1754 property_operation:
1755         STRING '=' scalar {
1756                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1757                         scm_string_to_symbol ($1), $3);
1758         }
1759         | UNSET simple_string {
1760                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1761                         scm_string_to_symbol ($2));
1762         }
1763         | OVERRIDE simple_string property_path '=' scalar {
1764                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1765                                                         scm_string_to_symbol ($2), $5),
1766                                              $3));
1767         }
1768         | REVERT simple_string embedded_scm {
1769                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1770                         scm_string_to_symbol ($2), $3);
1771         }
1772         ;
1773
1774 context_def_mod:
1775         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1776         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1777
1778         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1779         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1780         | DENIES { $$ = ly_symbol2scm ("denies"); }
1781
1782         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1783         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1784         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1785         | NAME { $$ = ly_symbol2scm ("context-name"); }
1786         ;
1787
1788 context_mod:
1789         property_operation { $$ = $1; }
1790         | context_def_mod STRING {
1791                 $$ = scm_list_2 ($1, $2);
1792         }
1793         | context_def_mod embedded_scm
1794         {
1795                 if (!scm_is_string ($2)
1796                     && ly_symbol2scm ("consists") != $1
1797                     && ly_symbol2scm ("remove") != $1)
1798                 {
1799                         $$ = SCM_EOL;
1800                         parser->parser_error (@1, _ ("only \\consists and \\remove take non-string argument."));
1801                 }
1802                 else
1803                 {
1804                         $$ = scm_list_2 ($1, $2);
1805                 }
1806         }
1807         ;
1808
1809 context_prop_spec:
1810         simple_string {
1811                 if (!is_regular_identifier ($1))
1812                 {
1813                         @$.error (_("Grob name should be alphanumeric"));
1814                 }
1815
1816                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1817                         scm_string_to_symbol ($1));
1818         }
1819         | simple_string '.' simple_string {
1820                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1821                         scm_string_to_symbol ($3));
1822         }
1823         ;
1824
1825 simple_music_property_def:
1826         OVERRIDE context_prop_spec property_path '=' scalar {
1827                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1828                                 ly_symbol2scm ("OverrideProperty"),
1829                                 scm_cadr ($2),
1830                                 $5, SCM_UNDEFINED),
1831                                 $3));
1832         }
1833         | REVERT context_prop_spec embedded_scm {
1834                 $$ = scm_list_4 (scm_car ($2),
1835                         ly_symbol2scm ("RevertProperty"),
1836                         scm_cadr ($2),
1837                         $3);
1838         }
1839         | SET context_prop_spec '=' scalar {
1840                 $$ = scm_list_4 (scm_car ($2),
1841                         ly_symbol2scm ("PropertySet"),
1842                         scm_cadr ($2),
1843                         $4);
1844         }
1845         | UNSET context_prop_spec {
1846                 $$ = scm_list_3 (scm_car ($2),
1847                         ly_symbol2scm ("PropertyUnset"),
1848                         scm_cadr ($2));
1849         }
1850         ;
1851
1852 music_property_def:
1853         simple_music_property_def {
1854                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons2 (parser->self_scm (), make_input (@$), $1));
1855         }
1856         ;
1857
1858 string:
1859         STRING {
1860                 $$ = $1;
1861         }
1862         | full_markup
1863         | string '+' string {
1864                 if (!scm_is_string ($1)) {
1865                         parser->parser_error (@1, (_ ("simple string expected")));
1866                         $1 = scm_string (SCM_EOL);
1867                 }
1868                 if (!scm_is_string ($3)) {
1869                         parser->parser_error (@3, (_ ("simple string expected")));
1870                         $3 = scm_string (SCM_EOL);
1871                 }
1872                 $$ = scm_string_append (scm_list_2 ($1, $3));
1873         }
1874         ;
1875
1876 simple_string: STRING {
1877                 $$ = $1;
1878         }
1879         | LYRICS_STRING {
1880                 $$ = $1;
1881         }
1882         | MARKUP_IDENTIFIER
1883         {
1884                 if (scm_is_string ($1)) {
1885                         $$ = $1;
1886                 } else {
1887                         parser->parser_error (@1, (_ ("simple string expected")));
1888                         $$ = scm_string (SCM_EOL);
1889                 }
1890         }
1891         | LYRIC_MARKUP_IDENTIFIER
1892         {
1893                 if (scm_is_string ($1)) {
1894                         $$ = $1;
1895                 } else {
1896                         parser->parser_error (@1, (_ ("simple string expected")));
1897                         $$ = scm_string (SCM_EOL);
1898                 }
1899         }
1900         ;
1901
1902 scalar:
1903         embedded_scm_arg
1904         | bare_number
1905         | FRACTION
1906         | lyric_element
1907         ;
1908
1909 scalar_closed:
1910         embedded_scm_arg_closed
1911         | bare_number
1912         | FRACTION
1913         | lyric_element
1914         ;
1915
1916
1917 event_chord:
1918         simple_element post_events {
1919                 // Let the rhythmic music iterator sort this mess out.
1920                 if (scm_is_pair ($2)) {
1921                         $$ = make_music_from_simple (parser, @1, $1);
1922                         if (unsmob_music ($$))
1923                                 unsmob_music ($$)->set_property ("articulations",
1924                                                                  scm_reverse_x ($2, SCM_EOL));
1925                         else
1926                                 parser->parser_error (@1, _("music expected"));
1927                 }
1928         }
1929         | simple_chord_elements post_events     {
1930                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1931
1932                 Input i;
1933                 /* why is this giving wrong start location? -ns
1934                  * i = @$; */
1935                 i.set_location (@1, @2);
1936                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1937         }
1938         | CHORD_REPETITION optional_notemode_duration post_events {
1939                 Input i;
1940                 i.set_location (@1, @3);
1941                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1942                                   $2, scm_reverse_x ($3, SCM_EOL));
1943         }
1944         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1945                 Input i;
1946                 i.set_location (@1, @3);
1947                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1948                                   scm_reverse_x ($3, SCM_EOL));
1949         }
1950         | command_element
1951         | note_chord_element
1952         ;
1953
1954
1955 note_chord_element:
1956         chord_body optional_notemode_duration post_events
1957         {
1958                 Music *m = unsmob_music ($1);
1959                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1960                 SCM es = m->get_property ("elements");
1961                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1962
1963                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1964                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1965                 es = ly_append2 (es, postevs);
1966
1967                 m-> set_property ("elements", es);
1968                 m->set_spot (@$);
1969                 $$ = m->self_scm ();
1970         }
1971         ;
1972
1973 chord_body:
1974         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1975         {
1976                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1977         }
1978         ;
1979
1980 chord_body_elements:
1981         /* empty */             { $$ = SCM_EOL; }
1982         | chord_body_elements chord_body_element {
1983                 if (!SCM_UNBNDP ($2))
1984                         $$ = scm_cons ($2, $1);
1985         }
1986         ;
1987
1988 chord_body_element:
1989         pitch exclamations questions octave_check post_events
1990         {
1991                 bool q = to_boolean ($3);
1992                 bool ex = to_boolean ($2);
1993                 SCM check = $4;
1994                 SCM post = $5;
1995
1996                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1997                 n->set_property ("pitch", $1);
1998                 if (q)
1999                         n->set_property ("cautionary", SCM_BOOL_T);
2000                 if (ex || q)
2001                         n->set_property ("force-accidental", SCM_BOOL_T);
2002
2003                 if (scm_is_pair (post)) {
2004                         SCM arts = scm_reverse_x (post, SCM_EOL);
2005                         n->set_property ("articulations", arts);
2006                 }
2007                 if (scm_is_number (check))
2008                 {
2009                         int q = scm_to_int (check);
2010                         n->set_property ("absolute-octave", scm_from_int (q-1));
2011                 }
2012
2013                 $$ = n->unprotect ();
2014         }
2015         | DRUM_PITCH post_events {
2016                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2017                 n->set_property ("drum-type", $1);
2018
2019                 if (scm_is_pair ($2)) {
2020                         SCM arts = scm_reverse_x ($2, SCM_EOL);
2021                         n->set_property ("articulations", arts);
2022                 }
2023                 $$ = n->unprotect ();
2024         }
2025         | music_function_chord_body
2026         {
2027                 Music *m = unsmob_music ($1);
2028
2029                 while (m && m->is_mus_type ("music-wrapper-music")) {
2030                         $$ = m->get_property ("element");
2031                         m = unsmob_music ($$);
2032                 }
2033
2034                 if (!(m && m->is_mus_type ("rhythmic-event"))) {
2035                         parser->parser_error (@$, _ ("not a rhythmic event"));
2036                         $$ = SCM_UNDEFINED;
2037                 }
2038         }
2039         ;
2040
2041 music_function_chord_body:
2042         music_function_call
2043         | MUSIC_IDENTIFIER
2044         ;
2045
2046 // Event functions may only take closed arglists, otherwise it would
2047 // not be clear whether a following postevent should be associated
2048 // with the last argument of the event function or with the expression
2049 // for which the function call acts itself as event.
2050
2051 music_function_call_closed:
2052         MUSIC_FUNCTION function_arglist_closed {
2053                 $$ = MAKE_SYNTAX ("music-function", @$,
2054                                          $1, $2);
2055         }
2056         ;
2057
2058 event_function_event:
2059         EVENT_FUNCTION function_arglist_closed {
2060                 $$ = MAKE_SYNTAX ("music-function", @$,
2061                                          $1, $2);
2062         }
2063         ;
2064
2065 command_element:
2066         command_event {
2067                 $$ = $1;
2068         }
2069         | E_BRACKET_OPEN {
2070                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
2071                 m->set_property ("span-direction", scm_from_int (START));
2072                 $$ = m->unprotect();
2073         }
2074         | E_BRACKET_CLOSE {
2075                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
2076                 m->set_property ("span-direction", scm_from_int (STOP));
2077                 $$ = m->unprotect ();
2078         }
2079         | E_BACKSLASH {
2080                 $$ = MAKE_SYNTAX ("voice-separator", @$);
2081         }
2082         | '|'      {
2083                 SCM pipe = parser->lexer_->lookup_identifier ("pipeSymbol");
2084
2085                 Music *m = unsmob_music (pipe);
2086                 if (m)
2087                 {
2088                         m = m->clone ();
2089                         m->set_spot (@$);
2090                         $$ = m->unprotect ();
2091                 }
2092                 else
2093                         $$ = MAKE_SYNTAX ("bar-check", @$);
2094
2095         }
2096         ;
2097
2098 command_event:
2099         E_TILDE {
2100                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
2101         }
2102         | tempo_event {
2103                 $$ = $1;
2104         }
2105         ;
2106
2107
2108 post_events:
2109         /* empty */ {
2110                 $$ = SCM_EOL;
2111         }
2112         | post_events post_event {
2113                 unsmob_music ($2)->set_spot (@2);
2114                 $$ = scm_cons ($2, $$);
2115         }
2116         ;
2117
2118 post_event_nofinger:
2119         direction_less_event {
2120                 $$ = $1;
2121         }
2122         | script_dir music_function_call_closed {
2123                 $$ = $2;
2124                 if (!SCM_UNBNDP ($1))
2125                 {
2126                         unsmob_music ($$)->set_property ("direction", $1);
2127                 }
2128         }
2129         | HYPHEN {
2130                 if (!parser->lexer_->is_lyric_state ())
2131                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2132                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
2133         }
2134         | EXTENDER {
2135                 if (!parser->lexer_->is_lyric_state ())
2136                         parser->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2137                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
2138         }
2139         | script_dir direction_reqd_event {
2140                 if (!SCM_UNBNDP ($1))
2141                 {
2142                         Music *m = unsmob_music ($2);
2143                         m->set_property ("direction", $1);
2144                 }
2145                 $$ = $2;
2146         }
2147         | script_dir direction_less_event {
2148                 if (!SCM_UNBNDP ($1))
2149                 {
2150                         Music *m = unsmob_music ($2);
2151                         m->set_property ("direction", $1);
2152                 }
2153                 $$ = $2;
2154         }
2155         | '^' fingering
2156         {
2157                 $$ = $2;
2158                 unsmob_music ($$)->set_property ("direction", scm_from_int (UP));
2159         }
2160         | '_' fingering
2161         {
2162                 $$ = $2;
2163                 unsmob_music ($$)->set_property ("direction", scm_from_int (DOWN));
2164         }
2165         ;
2166
2167 post_event:
2168         post_event_nofinger
2169         | '-' fingering {
2170                 $$ = $2;
2171         }
2172         ;
2173
2174 string_number_event:
2175         E_UNSIGNED {
2176                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
2177                 s->set_property ("string-number", $1);
2178                 $$ = s->unprotect ();
2179         }
2180         ;
2181
2182 direction_less_char:
2183         '['  {
2184                 $$ = ly_symbol2scm ("bracketOpenSymbol");
2185         }
2186         | ']'  {
2187                 $$ = ly_symbol2scm ("bracketCloseSymbol");
2188         }
2189         | '~'  {
2190                 $$ = ly_symbol2scm ("tildeSymbol");
2191         }
2192         | '('  {
2193                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
2194         }
2195         | ')'  {
2196                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
2197         }
2198         | E_EXCLAMATION  {
2199                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
2200         }
2201         | E_OPEN  {
2202                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
2203         }
2204         | E_CLOSE  {
2205                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
2206         }
2207         | E_ANGLE_CLOSE  {
2208                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
2209         }
2210         | E_ANGLE_OPEN  {
2211                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
2212         }
2213         ;
2214
2215 direction_less_event:
2216         direction_less_char {
2217                 SCM predefd = parser->lexer_->lookup_identifier_symbol ($1);
2218                 Music *m = 0;
2219                 if (unsmob_music (predefd))
2220                 {
2221                         m = unsmob_music (predefd)->clone ();
2222                         m->set_spot (@$);
2223                 }
2224                 else
2225                 {
2226                         m = MY_MAKE_MUSIC ("Music", @$);
2227                 }
2228                 $$ = m->unprotect ();
2229         }
2230         | string_number_event
2231         | EVENT_IDENTIFIER      {
2232                 $$ = $1;
2233         }
2234         | tremolo_type  {
2235                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2236                a->set_property ("tremolo-type", $1);
2237                $$ = a->unprotect ();
2238         }
2239         | event_function_event
2240         ;
2241
2242 direction_reqd_event:
2243         gen_text_def {
2244                 $$ = $1;
2245         }
2246         | script_abbreviation {
2247                 SCM s = parser->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2248                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2249                 if (scm_is_string (s))
2250                         a->set_property ("articulation-type", s);
2251                 else parser->parser_error (@1, _ ("expecting string as script definition"));
2252                 $$ = a->unprotect ();
2253         }
2254         ;
2255
2256 octave_check:
2257         /**/ { $$ = SCM_EOL; }
2258         | '=' quotes { $$ = $2; }
2259         ;
2260
2261 quotes:
2262         /* empty */
2263         {
2264                 $$ = SCM_INUM0;
2265         }
2266         | sub_quotes
2267         | sup_quotes
2268         ;
2269
2270 sup_quotes:
2271         '\'' {
2272                 $$ = scm_from_int (1);
2273         }
2274         | sup_quotes '\'' {
2275                 $$ = scm_oneplus ($1);
2276         }
2277         ;
2278
2279 sub_quotes:
2280         ',' {
2281                 $$ = scm_from_int (-1);
2282         }
2283         | sub_quotes ',' {
2284                 $$ = scm_oneminus ($1);
2285         }
2286         ;
2287
2288 steno_pitch:
2289         NOTENAME_PITCH quotes {
2290                 if (!scm_is_eq (SCM_INUM0, $2))
2291                 {
2292                         Pitch p = *unsmob_pitch ($1);
2293                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2294                         $$ = p.smobbed_copy ();
2295                 }
2296         }
2297         ;
2298
2299 /*
2300 ugh. duplication
2301 */
2302
2303 steno_tonic_pitch:
2304         TONICNAME_PITCH quotes {
2305                 if (!scm_is_eq (SCM_INUM0, $2))
2306                 {
2307                         Pitch p = *unsmob_pitch ($1);
2308                         p = p.transposed (Pitch (scm_to_int ($2),0,0));
2309                         $$ = p.smobbed_copy ();
2310                 }
2311         }
2312         ;
2313
2314 pitch:
2315         steno_pitch
2316         | PITCH_IDENTIFIER
2317         ;
2318
2319 pitch_also_in_chords:
2320         pitch
2321         | steno_tonic_pitch
2322         ;
2323
2324 gen_text_def:
2325         full_markup {
2326                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2327                 t->set_property ("text", $1);
2328                 $$ = t->unprotect ();
2329         }
2330         | STRING {
2331                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2332                 t->set_property ("text",
2333                         make_simple_markup ($1));
2334                 $$ = t->unprotect ();
2335         }
2336         | LYRICS_STRING {
2337                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2338                 t->set_property ("text",
2339                         make_simple_markup ($1));
2340                 $$ = t->unprotect ();
2341         }
2342         ;
2343
2344 fingering:
2345         UNSIGNED {
2346                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2347                 t->set_property ("digit", $1);
2348                 $$ = t->unprotect ();
2349         }
2350         ;
2351
2352 script_abbreviation:
2353         '^'             {
2354                 $$ = scm_from_locale_string ("Hat");
2355         }
2356         | '+'           {
2357                 $$ = scm_from_locale_string ("Plus");
2358         }
2359         | '-'           {
2360                 $$ = scm_from_locale_string ("Dash");
2361         }
2362         | '|'           {
2363                 $$ = scm_from_locale_string ("Bar");
2364         }
2365         | ANGLE_CLOSE   {
2366                 $$ = scm_from_locale_string ("Larger");
2367         }
2368         | '.'           {
2369                 $$ = scm_from_locale_string ("Dot");
2370         }
2371         | '_' {
2372                 $$ = scm_from_locale_string ("Underscore");
2373         }
2374         ;
2375
2376 script_dir:
2377         '_'     { $$ = scm_from_int (DOWN); }
2378         | '^'   { $$ = scm_from_int (UP); }
2379         | '-'   { $$ = SCM_UNDEFINED; }
2380         ;
2381
2382 duration_length:
2383         multiplied_duration {
2384                 $$ = $1;
2385         }
2386         ;
2387
2388 maybe_notemode_duration:
2389         {
2390                 $$ = SCM_UNDEFINED;
2391         }
2392         | multiplied_duration   {
2393                 $$ = $1;
2394                 parser->default_duration_ = *unsmob_duration ($$);
2395         }
2396 ;
2397
2398
2399 optional_notemode_duration:
2400         maybe_notemode_duration
2401         {
2402                 if (SCM_UNBNDP ($$))
2403                         $$ = parser->default_duration_.smobbed_copy ();
2404         }
2405         ;
2406
2407 steno_duration:
2408         UNSIGNED dots           {
2409                 int len = 0;
2410                 int n = scm_to_int ($1);
2411                 if (!is_duration (n))
2412                         parser->parser_error (@1, _f ("not a duration: %d", n));
2413                 else
2414                         len = intlog2 (n);
2415
2416                 $$ = Duration (len, scm_to_int ($2)).smobbed_copy ();
2417         }
2418         | DURATION_IDENTIFIER dots      {
2419                 Duration *d = unsmob_duration ($1);
2420                 Duration k (d->duration_log (),
2421                             d->dot_count () + scm_to_int ($2));
2422                 k = k.compressed (d->factor ());
2423                 scm_remember_upto_here_1 ($1);
2424                 $$ = k.smobbed_copy ();
2425         }
2426         ;
2427
2428 multiplied_duration:
2429         steno_duration {
2430                 $$ = $1;
2431         }
2432         | multiplied_duration '*' UNSIGNED {
2433                 $$ = unsmob_duration ($$)->compressed (scm_to_int ($3)).smobbed_copy ();
2434         }
2435         | multiplied_duration '*' FRACTION {
2436                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2437
2438                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2439         }
2440         ;
2441
2442 dots:
2443         /* empty */     {
2444                 $$ = SCM_INUM0;
2445         }
2446         | dots '.' {
2447                 $$ = scm_oneplus ($1);
2448         }
2449         ;
2450
2451 tremolo_type:
2452         ':'     {
2453                 $$ = SCM_INUM0;
2454         }
2455         | ':' UNSIGNED {
2456                 int n = scm_to_int ($2);
2457                 if (!is_duration (n))
2458                         parser->parser_error (@2, _f ("not a duration: %d", n));
2459                 $$ = $2;
2460         }
2461         ;
2462
2463 bass_number:
2464         UNSIGNED { $$ = $1; }
2465         | STRING { $$ = $1; }
2466         | full_markup { $$ = $1; }
2467         ;
2468
2469 figured_bass_alteration:
2470         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2471         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2472         | '!'   { $$ = scm_from_int (0); }
2473         ;
2474
2475 bass_figure:
2476         FIGURE_SPACE {
2477                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2478                 $$ = bfr->unprotect ();
2479         }
2480         | bass_number  {
2481                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2482                 $$ = bfr->self_scm ();
2483
2484                 if (scm_is_number ($1))
2485                         bfr->set_property ("figure", $1);
2486                 else if (Text_interface::is_markup ($1))
2487                         bfr->set_property ("text", $1);
2488
2489                 bfr->unprotect ();
2490         }
2491         | bass_figure ']' {
2492                 $$ = $1;
2493                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2494         }
2495         | bass_figure figured_bass_alteration {
2496                 Music *m = unsmob_music ($1);
2497                 if (scm_to_double ($2)) {
2498                         SCM salter = m->get_property ("alteration");
2499                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2500                         m->set_property ("alteration",
2501                                          scm_sum (alter, $2));
2502                 } else {
2503                         m->set_property ("alteration", scm_from_int (0));
2504                 }
2505         }
2506         | bass_figure figured_bass_modification  {
2507                 Music *m = unsmob_music ($1);
2508                 if ($2 == ly_symbol2scm ("plus"))
2509                         {
2510                         m->set_property ("augmented", SCM_BOOL_T);
2511                         }
2512                 else if ($2 == ly_symbol2scm ("slash"))
2513                         {
2514                         m->set_property ("diminished", SCM_BOOL_T);
2515                         }
2516                 else if ($2 == ly_symbol2scm ("exclamation"))
2517                         {
2518                         m->set_property ("no-continuation", SCM_BOOL_T);
2519                         }
2520                 else if ($2 == ly_symbol2scm ("backslash"))
2521                         {
2522                         m->set_property ("augmented-slash", SCM_BOOL_T);
2523                         }
2524         }
2525         ;
2526
2527
2528 figured_bass_modification:
2529         E_PLUS          {
2530                 $$ = ly_symbol2scm ("plus");
2531         }
2532         | E_EXCLAMATION {
2533                 $$ = ly_symbol2scm ("exclamation");
2534         }
2535         | '/'           {
2536                 $$ = ly_symbol2scm ("slash");
2537         }
2538         | E_BACKSLASH {
2539                 $$ = ly_symbol2scm ("backslash");
2540         }
2541         ;
2542
2543 br_bass_figure:
2544         bass_figure {
2545                 $$ = $1;
2546         }
2547         | '[' bass_figure {
2548                 $$ = $2;
2549                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2550         }
2551         ;
2552
2553 figure_list:
2554         /**/            {
2555                 $$ = SCM_EOL;
2556         }
2557         | figure_list br_bass_figure {
2558                 $$ = scm_cons ($2, $1);
2559         }
2560         ;
2561
2562 figure_spec:
2563         FIGURE_OPEN figure_list FIGURE_CLOSE {
2564                 $$ = scm_reverse_x ($2, SCM_EOL);
2565         }
2566         ;
2567
2568
2569 optional_rest:
2570         /**/   { $$ = SCM_BOOL_F; }
2571         | REST { $$ = SCM_BOOL_T; }
2572         ;
2573
2574 simple_element:
2575         pitch exclamations questions octave_check maybe_notemode_duration optional_rest {
2576                 if (!parser->lexer_->is_note_state ())
2577                         parser->parser_error (@1, _ ("have to be in Note mode for notes"));
2578                 if (!SCM_UNBNDP ($2)
2579                     || !SCM_UNBNDP ($3)
2580                     || scm_is_number ($4)
2581                     || !SCM_UNBNDP ($5)
2582                     || scm_is_true ($6))
2583                 {
2584                         Music *n = 0;
2585                         if (scm_is_true ($6))
2586                                 n = MY_MAKE_MUSIC ("RestEvent", @$);
2587                         else
2588                                 n = MY_MAKE_MUSIC ("NoteEvent", @$);
2589
2590                         n->set_property ("pitch", $1);
2591                         if (SCM_UNBNDP ($5))
2592                                 n->set_property ("duration",
2593                                                  parser->default_duration_.smobbed_copy ());
2594                         else
2595                                 n->set_property ("duration", $5);
2596
2597                         if (scm_is_number ($4))
2598                         {
2599                                 int q = scm_to_int ($4);
2600                                 n->set_property ("absolute-octave", scm_from_int (q-1));
2601                         }
2602
2603                         if (to_boolean ($3))
2604                                 n->set_property ("cautionary", SCM_BOOL_T);
2605                         if (to_boolean ($2) || to_boolean ($3))
2606                                 n->set_property ("force-accidental", SCM_BOOL_T);
2607
2608                         $$ = n->unprotect ();
2609                 }
2610         }
2611         | DRUM_PITCH optional_notemode_duration {
2612                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2613                 n->set_property ("duration", $2);
2614                 n->set_property ("drum-type", $1);
2615
2616                 $$ = n->unprotect ();
2617         }
2618         | RESTNAME optional_notemode_duration           {
2619                 Music *ev = 0;
2620                 if (ly_scm2string ($1) == "s") {
2621                         /* Space */
2622                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2623                   }
2624                 else {
2625                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2626
2627                     }
2628                 ev->set_property ("duration", $2);
2629                 $$ = ev->unprotect ();
2630         }
2631         ;
2632
2633 simple_chord_elements:
2634         new_chord {
2635                 if (!parser->lexer_->is_chord_state ())
2636                         parser->parser_error (@1, _ ("have to be in Chord mode for chords"));
2637                 $$ = $1;
2638         }
2639         | figure_spec optional_notemode_duration {
2640                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2641                 {
2642                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2643                 }
2644                 $$ = $1;
2645         }
2646         ;
2647
2648 lyric_element:
2649         lyric_markup {
2650                 $$ = $1;
2651         }
2652         | LYRICS_STRING {
2653                 $$ = $1;
2654         }
2655         ;
2656
2657 lyric_element_arg:
2658         lyric_element
2659         | lyric_element multiplied_duration post_events {
2660                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2661                 if (scm_is_pair ($3))
2662                         unsmob_music ($$)->set_property
2663                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
2664         }
2665         | lyric_element post_event post_events {
2666                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1,
2667                                   parser->default_duration_.smobbed_copy ());
2668                 unsmob_music ($$)->set_property
2669                         ("articulations", scm_cons ($2, scm_reverse_x ($3, SCM_EOL)));
2670         }
2671         | LYRIC_ELEMENT optional_notemode_duration post_events {
2672                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2673                 if (scm_is_pair ($3))
2674                         unsmob_music ($$)->set_property
2675                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
2676         }
2677         ;
2678
2679
2680 lyric_element_music:
2681         lyric_element optional_notemode_duration post_events {
2682                 $$ = MAKE_SYNTAX ("lyric-event", @$, $1, $2);
2683                 if (scm_is_pair ($3))
2684                         unsmob_music ($$)->set_property
2685                                 ("articulations", scm_reverse_x ($3, SCM_EOL));
2686         }
2687         ;
2688
2689 new_chord:
2690         steno_tonic_pitch optional_notemode_duration   {
2691                 $$ = make_chord_elements (@$, $1, $2, SCM_EOL);
2692         }
2693         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2694                 SCM its = scm_reverse_x ($4, SCM_EOL);
2695                 $$ = make_chord_elements (@$, $1, $2, scm_cons ($3, its));
2696         }
2697         ;
2698
2699 chord_items:
2700         /**/ {
2701                 $$ = SCM_EOL;
2702         }
2703         | chord_items chord_item {
2704                 $$ = scm_cons ($2, $$);
2705         }
2706         ;
2707
2708 chord_separator:
2709         CHORD_COLON {
2710                 $$ = ly_symbol2scm ("chord-colon");
2711         }
2712         | CHORD_CARET {
2713                 $$ = ly_symbol2scm ("chord-caret");
2714         }
2715         | CHORD_SLASH steno_tonic_pitch {
2716                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2717         }
2718         | CHORD_BASS steno_tonic_pitch {
2719                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2720         }
2721         ;
2722
2723 chord_item:
2724         chord_separator {
2725                 $$ = $1;
2726         }
2727         | step_numbers {
2728                 $$ = scm_reverse_x ($1, SCM_EOL);
2729         }
2730         | CHORD_MODIFIER  {
2731                 $$ = $1;
2732         }
2733         ;
2734
2735 step_numbers:
2736         step_number { $$ = scm_cons ($1, SCM_EOL); }
2737         | step_numbers '.' step_number {
2738                 $$ = scm_cons ($3, $$);
2739         }
2740         ;
2741
2742 step_number:
2743         UNSIGNED {
2744                 $$ = make_chord_step ($1, 0);
2745         }
2746         | UNSIGNED '+' {
2747                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2748         }
2749         | UNSIGNED CHORD_MINUS {
2750                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2751         }
2752         ;
2753
2754 tempo_range:
2755         UNSIGNED {
2756                 $$ = $1;
2757         }
2758         | UNSIGNED '~' UNSIGNED {
2759                 $$ = scm_cons ($1, $3);
2760         }
2761         ;
2762
2763 /*
2764         UTILITIES
2765
2766 TODO: should deprecate in favor of Scheme?
2767
2768  */
2769 number_expression:
2770         number_expression '+' number_term {
2771                 $$ = scm_sum ($1, $3);
2772         }
2773         | number_expression '-' number_term {
2774                 $$ = scm_difference ($1, $3);
2775         }
2776         | number_term
2777         ;
2778
2779 number_term:
2780         number_factor {
2781                 $$ = $1;
2782         }
2783         | number_factor '*' number_factor {
2784                 $$ = scm_product ($1, $3);
2785         }
2786         | number_factor '/' number_factor {
2787                 $$ = scm_divide ($1, $3);
2788         }
2789         ;
2790
2791 number_factor:
2792         '-'  number_factor { /* %prec UNARY_MINUS */
2793                 $$ = scm_difference ($2, SCM_UNDEFINED);
2794         }
2795         | bare_number
2796         ;
2797
2798
2799 bare_number:
2800         bare_number_closed
2801         | UNSIGNED NUMBER_IDENTIFIER    {
2802                 $$ = scm_product ($1, $2);
2803         }
2804         | REAL NUMBER_IDENTIFIER        {
2805                 $$ = scm_product ($1, $2);
2806         }
2807         ;
2808
2809 bare_number_closed:
2810         UNSIGNED
2811         | REAL
2812         | NUMBER_IDENTIFIER
2813         ;
2814
2815 unsigned_number:
2816         UNSIGNED
2817         | NUMBER_IDENTIFIER
2818         ;
2819
2820 exclamations:
2821                 { $$ = SCM_UNDEFINED; }
2822         | exclamations '!'
2823         {
2824                 if (SCM_UNBNDP ($1))
2825                         $$ = SCM_BOOL_T;
2826                 else
2827                         $$ = scm_not ($1);
2828         }
2829         ;
2830
2831 questions:
2832         { $$ = SCM_UNDEFINED; }
2833         | questions '?'
2834         {
2835                 if (SCM_UNBNDP ($1))
2836                         $$ = SCM_BOOL_T;
2837                 else
2838                         $$ = scm_not ($1);
2839         }
2840         ;
2841
2842 /*
2843 This should be done more dynamically if possible.
2844 */
2845
2846 lyric_markup:
2847         LYRIC_MARKUP_IDENTIFIER {
2848                 $$ = $1;
2849         }
2850         | LYRIC_MARKUP
2851                 { parser->lexer_->push_markup_state (); }
2852         markup_top {
2853                 $$ = $3;
2854                 parser->lexer_->pop_state ();
2855         }
2856         ;
2857
2858 full_markup_list:
2859         MARKUPLIST_IDENTIFIER {
2860                 $$ = $1;
2861         }
2862         | MARKUPLIST
2863                 { parser->lexer_->push_markup_state (); }
2864         markup_list {
2865                 $$ = $3;
2866                 parser->lexer_->pop_state ();
2867         }
2868         ;
2869
2870 full_markup:
2871         MARKUP_IDENTIFIER {
2872                 $$ = $1;
2873         }
2874         | MARKUP
2875                 { parser->lexer_->push_markup_state (); }
2876         markup_top {
2877                 $$ = $3;
2878                 parser->lexer_->pop_state ();
2879         }
2880         ;
2881
2882 markup_top:
2883         markup_list {
2884                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2885         }
2886         | markup_head_1_list simple_markup      {
2887                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2888         }
2889         | simple_markup {
2890                 $$ = $1;
2891         }
2892         ;
2893
2894 markup_scm:
2895         embedded_scm_bare
2896         {
2897                 if (Text_interface::is_markup ($1))
2898                         MYBACKUP (MARKUP_IDENTIFIER, $1, @1);
2899                 else if (Text_interface::is_markup_list ($1))
2900                         MYBACKUP (MARKUPLIST_IDENTIFIER, $1, @1);
2901                 else {
2902                         parser->parser_error (@1, _ ("not a markup"));
2903                         MYBACKUP (MARKUP_IDENTIFIER, scm_string (SCM_EOL), @1);
2904                 }
2905         } BACKUP
2906         ;
2907
2908
2909 markup_list:
2910         MARKUPLIST_IDENTIFIER {
2911                 $$ = $1;
2912         }
2913         | markup_composed_list {
2914                 $$ = $1;
2915         }
2916         | markup_braced_list {
2917                 $$ = $1;
2918         }
2919         | markup_command_list {
2920                 $$ = scm_list_1 ($1);
2921         }
2922         | markup_scm MARKUPLIST_IDENTIFIER
2923         {
2924                 $$ = $2;
2925         }
2926         ;
2927
2928 markup_composed_list:
2929         markup_head_1_list markup_braced_list {
2930                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2931
2932         }
2933         ;
2934
2935 markup_braced_list:
2936         '{' markup_braced_list_body '}' {
2937                 $$ = scm_reverse_x ($2, SCM_EOL);
2938         }
2939         ;
2940
2941 markup_braced_list_body:
2942         /* empty */     {  $$ = SCM_EOL; }
2943         | markup_braced_list_body markup {
2944                 $$ = scm_cons ($2, $1);
2945         }
2946         | markup_braced_list_body markup_list {
2947                 $$ = scm_reverse_x ($2, $1);
2948         }
2949         ;
2950
2951 markup_command_list:
2952         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2953           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2954         }
2955         ;
2956
2957 markup_command_basic_arguments:
2958         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2959           $$ = scm_cons ($3, $2);
2960         }
2961         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
2962           $$ = check_scheme_arg (parser, @3, $3, $2, $1);
2963         }
2964         | EXPECT_NO_MORE_ARGS {
2965           $$ = SCM_EOL;
2966         }
2967         ;
2968
2969 markup_command_list_arguments:
2970         markup_command_basic_arguments { $$ = $1; }
2971         | EXPECT_MARKUP markup_command_list_arguments markup {
2972           $$ = scm_cons ($3, $2);
2973         }
2974         ;
2975
2976 markup_head_1_item:
2977         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2978           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2979         }
2980         ;
2981
2982 markup_head_1_list:
2983         markup_head_1_item      {
2984                 $$ = scm_list_1 ($1);
2985         }
2986         | markup_head_1_list markup_head_1_item {
2987                 $$ = scm_cons ($2, $1);
2988         }
2989         ;
2990
2991 simple_markup:
2992         STRING {
2993                 $$ = make_simple_markup ($1);
2994         }
2995         | MARKUP_IDENTIFIER {
2996                 $$ = $1;
2997         }
2998         | LYRIC_MARKUP_IDENTIFIER {
2999                 $$ = $1;
3000         }
3001         | SCORE {
3002                 SCM nn = parser->lexer_->lookup_identifier ("pitchnames");
3003                 parser->lexer_->push_note_state (nn);
3004         } '{' score_body '}' {
3005                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), $4);
3006                 parser->lexer_->pop_state ();
3007         }
3008         | MARKUP_FUNCTION markup_command_basic_arguments {
3009                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
3010         }
3011         | markup_scm MARKUP_IDENTIFIER
3012         {
3013                 $$ = $2;
3014         }
3015         ;
3016
3017 markup:
3018         markup_head_1_list simple_markup        {
3019                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
3020                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
3021         }
3022         | simple_markup {
3023                 $$ = $1;
3024         }
3025         ;
3026
3027 %%
3028
3029 void
3030 Lily_parser::set_yydebug (bool x)
3031 {
3032         yydebug = x;
3033 }
3034
3035 SCM
3036 Lily_parser::do_yyparse ()
3037 {
3038         SCM retval = SCM_UNDEFINED;
3039         yyparse (this, &retval);
3040         return retval;
3041 }
3042
3043
3044
3045
3046
3047 /*
3048
3049 It is a little strange to have this function in this file, but
3050 otherwise, we have to import music classes into the lexer.
3051
3052 */
3053 int
3054 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
3055 {
3056         if (unsmob_book (sid)) {
3057                 Book *book =  unsmob_book (sid)->clone ();
3058                 *destination = book->self_scm ();
3059                 book->unprotect ();
3060
3061                 return BOOK_IDENTIFIER;
3062         } else if (scm_is_number (sid)) {
3063                 *destination = sid;
3064                 return NUMBER_IDENTIFIER;
3065         } else if (unsmob_context_def (sid)) {
3066                 Context_def *def= unsmob_context_def (sid)->clone ();
3067
3068                 *destination = def->self_scm ();
3069                 def->unprotect ();
3070
3071                 return CONTEXT_DEF_IDENTIFIER;
3072         } else if (unsmob_context_mod (sid)) {
3073                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
3074
3075                 return CONTEXT_MOD_IDENTIFIER;
3076         } else if (unsmob_score (sid)) {
3077                 Score *score = new Score (*unsmob_score (sid));
3078                 *destination = score->self_scm ();
3079
3080                 score->unprotect ();
3081                 return SCORE_IDENTIFIER;
3082         } else if (Music *mus = unsmob_music (sid)) {
3083                 mus = mus->clone ();
3084                 *destination = mus->self_scm ();
3085                 unsmob_music (*destination)->
3086                         set_property ("origin", make_input (last_input_));
3087
3088                 bool is_event = mus->is_mus_type ("post-event");
3089                 mus->unprotect ();
3090                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
3091         } else if (unsmob_pitch (sid)) {
3092                 *destination = unsmob_pitch (sid)->smobbed_copy ();
3093                 return PITCH_IDENTIFIER;
3094         } else if (unsmob_duration (sid)) {
3095                 *destination = unsmob_duration (sid)->smobbed_copy ();
3096                 return DURATION_IDENTIFIER;
3097         } else if (unsmob_output_def (sid)) {
3098                 Output_def *p = unsmob_output_def (sid);
3099                 p = p->clone ();
3100
3101                 *destination = p->self_scm ();
3102                 p->unprotect ();
3103                 return OUTPUT_DEF_IDENTIFIER;
3104         } else if (Text_interface::is_markup (sid)) {
3105                 *destination = sid;
3106                 if (is_lyric_state ())
3107                         return LYRIC_MARKUP_IDENTIFIER;
3108                 return MARKUP_IDENTIFIER;
3109         } else if (Text_interface::is_markup_list (sid)) {
3110                 *destination = sid;
3111                 return MARKUPLIST_IDENTIFIER;
3112         }
3113
3114         return -1;
3115 }
3116
3117 SCM
3118 get_next_unique_context_id ()
3119 {
3120         return scm_from_locale_string ("$uniqueContextId");
3121 }
3122
3123
3124 SCM
3125 get_next_unique_lyrics_context_id ()
3126 {
3127         static int new_context_count;
3128         char s[128];
3129         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
3130         return scm_from_locale_string (s);
3131 }
3132
3133 SCM check_scheme_arg (Lily_parser *parser, Input loc,
3134                       SCM arg, SCM args, SCM pred)
3135 {
3136         args = scm_cons (arg, args);
3137         if (scm_is_true (scm_call_1 (pred, arg)))
3138                 return args;
3139         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
3140         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred, arg);
3141         scm_set_cdr_x (scm_last_pair (args), SCM_BOOL_F);
3142         return args;
3143 }
3144
3145 SCM loc_on_music (Input loc, SCM arg)
3146 {
3147         if (Music *m = unsmob_music (arg))
3148         {
3149                 m = m->clone ();
3150                 m->set_spot (loc);
3151                 return m->unprotect ();
3152         }
3153         return arg;
3154 }
3155
3156 bool
3157 is_regular_identifier (SCM id)
3158 {
3159   string str = ly_scm2string (id);
3160   char const *s = str.c_str ();
3161
3162   bool v = true;
3163 #if 0
3164   isalpha (*s);
3165   s++;
3166 #endif
3167   while (*s && v)
3168    {
3169         v = v && isalnum (*s);
3170         s++;
3171    }
3172   return v;
3173 }
3174
3175 SCM
3176 make_music_from_simple (Lily_parser *parser, Input loc, SCM simple)
3177 {
3178         if (unsmob_music (simple))
3179                 return simple;
3180         if (parser->lexer_->is_note_state ()) {
3181                 Music *n = MY_MAKE_MUSIC ("NoteEvent", loc);
3182                 n->set_property ("duration", parser->default_duration_.smobbed_copy ());
3183                 if (scm_is_symbol (simple))
3184                         n->set_property ("drum-type", simple);
3185                 else if (unsmob_pitch (simple))
3186                         n->set_property ("pitch", simple);
3187                 else {
3188                         n->unprotect ();
3189                         return simple;
3190                 }
3191                 return n->unprotect ();
3192         } else if (parser->lexer_->is_lyric_state ()) {
3193                 if (Text_interface::is_markup (simple))
3194                         return MAKE_SYNTAX ("lyric-event", loc, simple,
3195                                             parser->default_duration_.smobbed_copy ());
3196         } else if (parser->lexer_->is_chord_state ()) {
3197                 if (unsmob_pitch (simple))
3198                         return make_chord_elements (loc, simple,
3199                                                     parser->default_duration_.smobbed_copy (),
3200                                                     SCM_EOL);
3201         }
3202         return simple;
3203 }
3204
3205 Music *
3206 make_music_with_input (SCM name, Input where)
3207 {
3208        Music *m = make_music_by_name (name);
3209        m->set_spot (where);
3210        return m;
3211 }
3212
3213 SCM
3214 make_simple_markup (SCM a)
3215 {
3216         return a;
3217 }
3218
3219 bool
3220 is_duration (int t)
3221 {
3222   return t && t == 1 << intlog2 (t);
3223 }
3224
3225 SCM
3226 make_chord_step (SCM step_scm, Rational alter)
3227 {
3228         int step = scm_to_int (step_scm);
3229
3230         if (step == 7)
3231                 alter += FLAT_ALTERATION;
3232
3233         while (step < 0)
3234                 step += 7;
3235         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3236         return m.smobbed_copy ();
3237 }
3238
3239
3240 SCM
3241 make_chord_elements (Input loc, SCM pitch, SCM dur, SCM modification_list)
3242 {
3243         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3244         SCM res = scm_call_3 (chord_ctor, pitch, dur, modification_list);
3245         for (SCM s = res; scm_is_pair (s); s = scm_cdr (s))
3246         {
3247                 unsmob_music (scm_car (s))->set_spot (loc);
3248         }
3249         return res;
3250 }
3251
3252 int
3253 yylex (YYSTYPE *s, YYLTYPE *loc, Lily_parser *parser)
3254 {
3255         Lily_lexer *lex = parser->lexer_;
3256
3257         lex->lexval_ = s;
3258         lex->lexloc_ = loc;
3259         lex->prepare_for_next_token ();
3260         return lex->yylex ();
3261 }