lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Two shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 2.  \repeat
  23         \repeat .. \alternative
  24
  25
  26     \repeat { \repeat .. \alternative }
  27
  28 or
  29
  30     \repeat { \repeat } \alternative
  31
  32 )
  33
  34 --hwn
  35
  36  */
  37
  38 /*
  39
  40 TODO:
  41
  42 * The rules for who is protecting what are very shady. Uniformise
  43   this.
  44
  45 * There are too many lexical modes?
  46
  47 */
  48
  49 #include <ctype.h>
  50 #include <stdlib.h>
  51
  52
  53
  54 #include "translator-def.hh"
  55 #include "lily-guile.hh"
  56 #include "misc.hh"
  57 #include "my-lily-lexer.hh"
  58 #include "paper-def.hh"
  59 #include "midi-def.hh"
  60 #include "main.hh"
  61 #include "file-path.hh"
  62 #include "warn.hh"
  63 #include "dimensions.hh"
  64 #include "my-lily-parser.hh"
  65 #include "score.hh"
  66 #include "input-file-results.hh"
  67 #include "input.hh"
  68 #include "lilypond-input-version.hh"
  69 #include "scm-hash.hh"
  70 #include "auto-change-iterator.hh"
  71 #include "ly-modules.hh"
  72 #include "music-sequence.hh"
  73 #include "input-smob.hh"
  74 #include "event.hh"
  75 #include "text-item.hh"
  76 #include "music-list.hh"
  77
  78
  79 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  80
  81
  82
  83 #define YYERROR_VERBOSE 1
  84
  85 My_lily_parser* my_lily_parser;
  86 #define YYPARSE_PARAM my_lily_parser
  87 #define YYLEX_PARAM my_lily_parser
  88 #define THIS\
  89         ((My_lily_parser *) my_lily_parser)
  90
  91 #define yyerror THIS->parser_error
  92
  93
  94
  95
  96
  97 bool
  98 regular_identifier_b (SCM id)
  99 {
 100   String str = ly_scm2string (id);
 101   char const *s = str.to_str0 () ;
 102
 103   bool v = true;
 104   while (*s && v)
 105    {
 106         v = v && isalpha (*s);
 107         s++;
 108    }
 109   return v;
 110 }
 111
 112 SCM
 113 make_simple_markup (SCM a)
 114 {
 115         static SCM simple;
 116         if (!simple)
 117         simple = scm_c_eval_string ("simple-markup");
 118
 119         return scm_list_n (simple, a, SCM_UNDEFINED);
 120 }
 121
 122
 123 bool
 124 is_duration_b (int t)
 125 {
 126   return t && t == 1 << intlog2 (t);
 127 }
 128
 129 void
 130 set_music_properties (Music *p, SCM a)
 131 {
 132   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 133         {
 134         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 135         }
 136 }
 137
 138 SCM
 139 make_chord_step (int step, int alter)
 140 {
 141         if (step == 7)
 142                 alter--;
 143
 144         /* ugh: fucks up above 13 */
 145         Pitch m(step > 7 ? 1 : 0,(step - 1) % 7, alter);
 146         return m.smobbed_copy ();
 147 }
 148
 149
 150 SCM
 151 make_chord (SCM pitch, SCM dur, SCM modification_list)
 152 {
 153         static SCM chord_ctor;
 154         if (!chord_ctor)
 155                 chord_ctor= scm_c_eval_string ("construct-chord");
 156         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 157         scm_gc_protect_object (ch);
 158         return ch;
 159 }
 160
 161 /*
 162   Todo: actually also use apply iso. call too ...
 163 */
 164 bool
 165 ly_input_procedure_p (SCM x)
 166 {
 167         return gh_procedure_p (x)
 168                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 169 }
 170
 171 Music*
 172 set_property_music (SCM sym, SCM value)
 173 {
 174         Music * p = MY_MAKE_MUSIC("PropertySet");
 175         p->set_mus_property ("symbol", sym);
 176         p->set_mus_property ("value", value);
 177         return p;
 178 }
 179
 180 %}
 181
 182 /* We use SCMs to do strings, because it saves us the trouble of
 183 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 184 of the parse stack onto the heap. */
 185
 186
 187 %union {
 188         String * string;
 189     Music *music;
 190     Score *score;
 191     Music_output_def * outputdef;
 192     SCM scm;
 193     int i;
 194 }
 195 %{
 196
 197 int
 198 yylex (YYSTYPE *s,  void * v)
 199 {
 200         My_lily_parser   *pars = (My_lily_parser*) v;
 201         My_lily_lexer * lex = pars->lexer_;
 202
 203         lex->lexval = (void*) s;
 204         lex->prepare_for_next_token();
 205         return lex->yylex ();
 206 }
 207
 208
 209 %}
 210
 211 %pure_parser
 212
 213 /* tokens which are not keywords */
 214 %token AUTOCHANGE
 215 %token ALIAS
 216 %token APPLYCONTEXT
 217 %token APPLYOUTPUT
 218 %token APPLY
 219 %token ACCEPTS
 220 %token ALTERNATIVE
 221 %token BAR
 222 %token BREATHE
 223 %token CHORDMODIFIERS
 224 %token CHORDS
 225 %token CLEF
 226 %token CONSISTS
 227 %token DURATION
 228 %token SEQUENTIAL
 229 %token GROBDESCRIPTIONS
 230 %token SIMULTANEOUS
 231 %token CONSISTSEND
 232 %token DENIES
 233 %token DESCRIPTION
 234 %token EXTENDER
 235 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 236 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 237 %token GRACE
 238 %token HEADER
 239 %token HYPHEN
 240 %token INVALID
 241 %token KEY
 242 %token LYRICS
 243 %token MARK
 244 %token MULTI_MEASURE_REST
 245 %token MIDI
 246 %token PITCH
 247 %token DEFAULT
 248 %token NAME
 249 %token PITCHNAMES
 250 %token NOTES
 251 %token ONCE
 252 %token PAPER
 253 %token PARTIAL
 254 %token PROPERTY
 255 %token OVERRIDE SET REVERT
 256 %token RELATIVE
 257 %token REMOVE
 258 %token REPEAT
 259 %token ADDLYRICS
 260 %token PARTCOMBINE
 261 %token SCM_T
 262 %token SCORE
 263 %token SKIP
 264 %token SPANREQUEST
 265 %token COMMANDSPANREQUEST
 266 %token TEMPO
 267 %token OUTPUTPROPERTY
 268 %token TIME_T
 269 %token TIMES
 270 %token TRANSLATOR
 271 %token TRANSPOSE
 272 %token TYPE
 273 %token UNSET
 274 %token CONTEXT
 275 %token REST
 276
 277 %token CHORD_OPEN
 278 %token CHORD_CLOSE
 279
 280
 281 /* escaped */
 282 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 283 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 284 %token E_BACKSLASH
 285 %token <i> E_UNSIGNED
 286 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 287 %token FIGURE_SPACE
 288
 289 %type <i>       exclamations questions dots optional_rest
 290 %type <i>        bass_mod
 291 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 292 %token <i>      DIGIT
 293 %token <scm>    NOTENAME_PITCH
 294 %token <scm>    TONICNAME_PITCH
 295 %token <scm>    CHORDMODIFIER_PITCH
 296 %token <scm>    DURATION_IDENTIFIER
 297 %token <scm>    FRACTION
 298 %token <id>     IDENTIFIER
 299 %token <scm>    CHORDNAMES
 300
 301 %token <scm> CHORD_MODIFIER
 302
 303 %token <scm>    SCORE_IDENTIFIER
 304 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 305 %token <scm>    NUMBER_IDENTIFIER
 306 %token <scm>    EVENT_IDENTIFIER
 307 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 308 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 309 %token <scm>    RESTNAME
 310 %token <scm>    STRING
 311 %token <scm>    SCM_T
 312 %token <i>      UNSIGNED
 313 %token <scm>   REAL
 314
 315 %token MARKUP
 316 %token <scm> MARKUP_HEAD_MARKUP0
 317 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 318 %token <scm> MARKUP_HEAD_SCM0
 319 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 320 %token <scm> MARKUP_HEAD_SCM0_SCM1
 321 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 322 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 323
 324 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 325 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 326
 327 %type <outputdef> output_def
 328 %type <scm>     lilypond_header lilypond_header_body
 329 %type <music>   open_event_parens close_event_parens open_event close_event
 330 %type <music> event_with_dir event_that_take_dir verbose_event
 331 %type <i>       sub_quotes sup_quotes
 332 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 333 %type <music>   Repeated_music
 334 %type <scm>     Alternative_music
 335 %type <i>       tremolo_type
 336 %type <i>       bare_int  bare_unsigned
 337 %type <i>       script_dir
 338 %type <scm>     identifier_init
 339
 340 %type <music> note_chord_element chord_body chord_body_element
 341 %type <scm>  chord_body_elements
 342 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 343 %type <scm>  verbose_duration
 344
 345 %type <scm>   post_events
 346 %type <music> gen_text_def
 347 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 348 %type <scm>   explicit_pitch steno_tonic_pitch
 349
 350 /* %type <scm>  chord_additions chord_subtractions chord_notes chord_step */
 351 /* %type <music>        chord */
 352 /* %type <scm>  chord_note chord_inversion chord_bass */
 353 %type <scm>     duration_length fraction
 354
 355 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 356
 357 %type <scm>  embedded_scm scalar
 358 %type <music>   Music Sequential_music Simultaneous_music
 359 %type <music>   relative_music re_rhythmed_music part_combined_music
 360 %type <music>   property_def translator_change  simple_property_def
 361 %type <scm> Music_list
 362 %type <outputdef>  music_output_def_body
 363 %type <music> shorthand_command_req
 364 %type <music>   post_event
 365 %type <music> command_req verbose_command_req
 366 %type <music>   extender_req
 367 %type <music> hyphen_req
 368 %type <music> string_event
 369 %type <scm>     string bare_number number_expression number_term number_factor
 370 %type <score>   score_block score_body
 371
 372 %type <scm>     translator_spec_block translator_spec_body
 373 %type <music>   tempo_event
 374 %type <scm> notenames_body notenames_block chordmodifiers_block
 375 %type <scm>     script_abbreviation
 376
 377
 378
 379 %left '-' '+'
 380
 381 /* We don't assign precedence to / and *, because we might need varied
 382 prec levels in different prods */
 383
 384 %left UNARY_MINUS
 385
 386 %%
 387
 388 lilypond:       /* empty */
 389         | lilypond toplevel_expression {}
 390         | lilypond assignment  { }
 391         | lilypond error {
 392                 THIS->error_level_  = 1;
 393         }
 394         | lilypond INVALID      {
 395                 THIS->error_level_  = 1;
 396         }
 397         ;
 398
 399 toplevel_expression:
 400         notenames_block                 {
 401                 THIS->lexer_->pitchname_tab_ =  $1;
 402         }
 403         | chordmodifiers_block                  {
 404                 THIS->lexer_->chordmodifier_tab_  = $1;
 405         }
 406         | lilypond_header {
 407                 THIS->input_file_->header_ = $1;
 408         }
 409         | score_block {
 410                 THIS->input_file_->scores_.push ($1);
 411         }
 412         | output_def {
 413                 if (dynamic_cast<Paper_def*> ($1))
 414                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 415                 else if (dynamic_cast<Midi_def*> ($1))
 416                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 417         }
 418         ;
 419
 420 embedded_scm:
 421         SCM_T
 422         | SCM_IDENTIFIER
 423         ;
 424
 425
 426 chordmodifiers_block:
 427         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 428         ;
 429
 430 notenames_block:
 431         PITCHNAMES notenames_body   {  $$ = $2; }
 432         ;
 433
 434 notenames_body:
 435         embedded_scm    {
 436           int i = scm_ilength ($1);
 437
 438           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 439           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 440                 SCM pt = ly_cdar (s);
 441                 scm_hashq_set_x (tab, ly_caar (s), pt);
 442           }
 443           $$ = tab;
 444         }
 445         ;
 446
 447 lilypond_header_body:
 448         {
 449                 $$ = ly_make_anonymous_module ();
 450                 THIS->lexer_->add_scope ($$);
 451         }
 452         | lilypond_header_body assignment  {
 453
 454         }
 455         ;
 456
 457 lilypond_header:
 458         HEADER '{' lilypond_header_body '}'     {
 459                 $$ = THIS->lexer_-> remove_scope();
 460         }
 461         ;
 462
 463
 464 /*
 465         DECLARATIONS
 466 */
 467 assignment:
 468         STRING {
 469                 THIS->push_spot ();
 470         }
 471         /* cont */ '=' identifier_init  {
 472
 473         /*
 474                 Should find generic way of associating input with objects.
 475         */
 476                 Input ip = THIS->pop_spot ();
 477
 478                 if (! regular_identifier_b ($1))
 479                 {
 480                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 481                 }
 482
 483                 THIS->lexer_->set_identifier ($1, $4);
 484
 485 /*
 486  TODO: devise standard for protection in parser.
 487
 488   The parser stack lives on the C-stack, which means that
 489 all objects can be unprotected as soon as they're here.
 490
 491 */
 492         }
 493         | embedded_scm { }
 494         ;
 495
 496
 497
 498 identifier_init:
 499         score_block {
 500                 $$ = $1->self_scm ();
 501                 scm_gc_unprotect_object ($$);
 502         }
 503         | full_markup {
 504                 $$ = $1;
 505         }
 506         | output_def {
 507                 $$ = $1->self_scm ();
 508                 scm_gc_unprotect_object ($$);
 509         }
 510         | translator_spec_block {
 511                 $$ = $1;
 512         }
 513         | Music  {
 514                 $$ = $1->self_scm ();
 515                 scm_gc_unprotect_object ($$);
 516         }
 517         | post_event {
 518                 $$ = $1->self_scm ();
 519                 scm_gc_unprotect_object ($$);
 520         }
 521         | verbose_duration {
 522                 $$ = $1;
 523         }
 524         | number_expression {
 525                 $$ = $1;
 526         }
 527         | string {
 528                 $$ = $1;
 529         }
 530         | embedded_scm  {
 531                 $$ = $1;
 532         }
 533         ;
 534
 535 translator_spec_block:
 536         TRANSLATOR '{' translator_spec_body '}'
 537                 {
 538                 $$ = $3;
 539         }
 540         ;
 541
 542 translator_spec_body:
 543         TRANSLATOR_IDENTIFIER   {
 544                 $$ = $1;
 545                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 546         }
 547         | TYPE STRING   {
 548                 $$ = Translator_def::make_scm ();
 549                 Translator_def*td =  unsmob_translator_def ($$);
 550                 td->translator_group_type_ = $2;
 551                 td->set_spot (THIS->here_input ());
 552         }
 553         | translator_spec_body DESCRIPTION string  {
 554                 unsmob_translator_def ($$)->description_ = $3;
 555         }
 556         | translator_spec_body STRING '=' embedded_scm                  {
 557                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 558         }
 559         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 560                 unsmob_translator_def ($$)
 561                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 562         }
 563         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 564                 unsmob_translator_def ($$)
 565                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 566         }
 567         | translator_spec_body STRING REVERT embedded_scm  {
 568           unsmob_translator_def ($$)->add_pop_property (
 569                 scm_string_to_symbol ($2), $4);
 570         }
 571         | translator_spec_body NAME STRING  {
 572                 unsmob_translator_def ($$)->type_name_ = $3;
 573         }
 574         | translator_spec_body CONSISTS STRING  {
 575                 unsmob_translator_def ($$)->add_element ($3);
 576         }
 577         | translator_spec_body ALIAS STRING  {
 578                 Translator_def*td = unsmob_translator_def ($$);
 579                 td->type_aliases_ = scm_cons ($3, td->type_aliases_);
 580         }
 581         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 582                 Translator_def*td = unsmob_translator_def($$);
 583                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 584                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 585                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 586         }
 587         | translator_spec_body CONSISTSEND STRING  {
 588                 unsmob_translator_def ($$)->add_last_element ( $3);
 589         }
 590         | translator_spec_body ACCEPTS STRING  {
 591                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 592         }
 593         | translator_spec_body DENIES STRING  {
 594                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 595         }
 596         | translator_spec_body REMOVE STRING  {
 597                 unsmob_translator_def ($$)->remove_element ($3);
 598         }
 599         ;
 600
 601 /*
 602         SCORE
 603 */
 604 score_block:
 605         SCORE {
 606                 THIS->push_spot ();
 607         }
 608         /*cont*/ '{' score_body '}'     {
 609                 THIS->pop_spot ();
 610                 $$ = $4;
 611                 if (!$$->defs_.size ())
 612                 {
 613                   Music_output_def *id =
 614                         unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 615                   $$->add_output (id ? id->clone () :  new Paper_def );
 616                 }
 617         }
 618         ;
 619
 620 score_body:
 621         Music   {
 622                 $$ = new Score;
 623
 624                 $$->set_spot (THIS->here_input ());
 625                 SCM m = $1->self_scm ();
 626                 scm_gc_unprotect_object (m);
 627
 628                 /*
 629                         guh.
 630                 */
 631                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 632                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 633                         m = gh_call1 (gh_car (check_funcs), m);
 634                 $$->music_ = m;
 635
 636         }
 637         | SCORE_IDENTIFIER {
 638                 $$ = unsmob_score ($1);
 639                 $$->set_spot (THIS->here_input ());
 640         }
 641         | score_body lilypond_header    {
 642                 $$->header_ = $2;
 643         }
 644         | score_body output_def {
 645                 $$->add_output ($2);
 646         }
 647         | score_body error {
 648
 649         }
 650         ;
 651
 652
 653 /*
 654         MIDI
 655 */
 656 output_def:
 657         music_output_def_body '}' {
 658                 $$ = $1;
 659                 THIS-> lexer_-> remove_scope ();
 660         }
 661         ;
 662
 663 music_output_def_body:
 664         MIDI '{'    {
 665                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 666
 667
 668                 Midi_def* p =0;
 669                 if (id)
 670                         p = dynamic_cast<Midi_def*> (id->clone ());
 671                 else
 672                         p = new Midi_def;
 673
 674                 $$ = p;
 675                 THIS->lexer_->add_scope (p->scope_);
 676         }
 677         | PAPER '{'     {
 678                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 679                   Paper_def *p = 0;
 680                 if (id)
 681                         p = dynamic_cast<Paper_def*> (id->clone ());
 682                 else
 683                         p = new Paper_def;
 684
 685                 THIS->lexer_->add_scope (p->scope_);
 686                 $$ = p;
 687         }
 688         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 689                 Music_output_def * o =  unsmob_music_output_def ($3);
 690                 $$ =o;
 691
 692                 THIS->lexer_->add_scope (o->scope_);
 693         }
 694         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 695                 Music_output_def * o =  unsmob_music_output_def ($3);
 696                 $$ = o;
 697
 698                 THIS->lexer_->add_scope (o->scope_);
 699         }
 700         | music_output_def_body assignment  {
 701
 702         }
 703         | music_output_def_body translator_spec_block   {
 704                 $$->assign_translator ($2);
 705         }
 706         | music_output_def_body tempo_event  {
 707                 /*
 708                         junk this ? there already is tempo stuff in
 709                         music.
 710                 */
 711                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 712                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 713                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 714                 if (md)
 715                         md->set_tempo (d->get_length (), m);
 716         }
 717         | music_output_def_body error {
 718
 719         }
 720         ;
 721
 722 tempo_event:
 723         TEMPO steno_duration '=' bare_unsigned  {
 724                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 725                 $$->set_mus_property ("tempo-unit", $2);
 726                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 727         }
 728         ;
 729
 730 /*
 731 The representation of a  list is the
 732
 733   (LIST . LAST-CONS)
 734
 735  to have  efficient append.
 736 */
 737 Music_list:
 738         /* empty */ {
 739                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 740         }
 741         | Music_list Music {
 742                 SCM s = $$;
 743                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 744                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 745                 if (gh_pair_p (ly_cdr (s)))
 746                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 747                 else
 748                         gh_set_car_x (s, c); /* set first cons */
 749                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 750         }
 751         | Music_list error {
 752         }
 753         ;
 754
 755
 756 Music:
 757         Simple_music
 758         | Composite_music
 759         ;
 760
 761 Alternative_music:
 762         /* empty */ {
 763                 $$ = SCM_EOL;
 764         }
 765         | ALTERNATIVE '{' Music_list '}' {
 766                 $$ = $3;
 767         }
 768         ;
 769
 770 Repeated_music:
 771         REPEAT string bare_unsigned Music Alternative_music
 772         {
 773                 Music *beg = $4;
 774                 int times = $3;
 775                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 776                 if (times < scm_ilength (alts)) {
 777                   unsmob_music (gh_car (alts))
 778                     ->origin ()->warning (
 779                     _("More alternatives than repeats.  Junking excess alternatives."));
 780                   alts = ly_truncate_list (times, alts);
 781                 }
 782
 783
 784                 static SCM proc;
 785                 if (!proc)
 786                         proc = scm_c_eval_string ("make-repeated-music");
 787
 788                 SCM mus = scm_call_1 (proc, $2);
 789                 scm_gc_protect_object (mus); // UGH.
 790                 Music *r =unsmob_music (mus);
 791                 if (beg)
 792                         {
 793                         r-> set_mus_property ("element", beg->self_scm ());
 794                         scm_gc_unprotect_object (beg->self_scm ());
 795                         }
 796                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 797
 798                 r-> set_mus_property ("elements",alts);
 799                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 800                         /*
 801                         we can not get durations and other stuff correct down the line, so we have to
 802                         add to the duration log here.
 803                         */
 804                         static SCM func;
 805
 806                         if (!func)
 807                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 808
 809                         int dots = ($3 % 3) ? 0 : 1;
 810                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 811
 812                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 813
 814                         if (seq) {
 815                                 int list_len =scm_ilength (seq->music_list ());
 816                                 if (list_len != 2)
 817                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 818                                 shift -= 1;
 819                                 r->compress (Moment (Rational (1,list_len)));
 820                                 }
 821                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 822
 823                 }
 824                 r->set_spot (*$4->origin ());
 825
 826                 $$ = r;
 827         }
 828         ;
 829
 830 Sequential_music:
 831         SEQUENTIAL '{' Music_list '}'           {
 832                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 833                 $$->set_mus_property ("elements", ly_car ($3));
 834                 $$->set_spot(THIS->here_input());
 835         }
 836         | '{' Music_list '}'            {
 837                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 838                 $$->set_mus_property ("elements", ly_car ($2));
 839                 $$->set_spot(THIS->here_input());
 840         }
 841         ;
 842
 843 Simultaneous_music:
 844         SIMULTANEOUS '{' Music_list '}'{
 845                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 846                 $$->set_mus_property ("elements", ly_car ($3));
 847                 $$->set_spot(THIS->here_input());
 848
 849         }
 850         | '<' Music_list '>'    {
 851                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 852                 $$->set_mus_property ("elements", ly_car ($2));
 853                 $$->set_spot(THIS->here_input());
 854         }
 855         ;
 856
 857 Simple_music:
 858         event_chord             { $$ = $1; }
 859         | APPLYOUTPUT embedded_scm {
 860                 if (!ly_input_procedure_p ($2))
 861                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 862                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 863                 $$->set_mus_property ("procedure", $2);
 864                 $$->set_spot (THIS->here_input());
 865         }
 866         | APPLYCONTEXT embedded_scm {
 867                 if (!ly_input_procedure_p ($2))
 868                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 869                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 870                 $$->set_mus_property ("procedure", $2);
 871                 $$->set_spot (THIS->here_input());
 872         }
 873         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 874                 SCM pred = $2;
 875                 if (!gh_symbol_p ($3))
 876                 {
 877                         THIS->parser_error (_ ("Second argument must be a symbol"));
 878                 }
 879                 /* Should check # args */
 880                 if (!gh_procedure_p (pred))
 881                 {
 882                         THIS->parser_error (_ ("First argument must be a procedure taking one argument"));
 883                 }
 884
 885                 Music*m = MY_MAKE_MUSIC("OutputPropertySetMusic");
 886                 m->set_mus_property ("predicate", pred);
 887                 m->set_mus_property ("grob-property", $3);
 888                 m->set_mus_property ("grob-value",  $5);
 889
 890                 $$ = m;
 891         }
 892         | MUSIC_IDENTIFIER {
 893                 $$ = unsmob_music ($1);
 894         }
 895         | property_def
 896         | translator_change
 897         ;
 898
 899
 900 Composite_music:
 901         CONTEXT STRING Music    {
 902                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 903
 904                 csm->set_mus_property ("element", $3->self_scm ());
 905                 scm_gc_unprotect_object ($3->self_scm ());
 906
 907                 csm->set_mus_property ("context-type",$2);
 908                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 909
 910                 $$ = csm;
 911         }
 912         | AUTOCHANGE STRING Music       {
 913         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 914                 chm->set_mus_property ("element", $3->self_scm ());
 915                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 916
 917                 scm_gc_unprotect_object ($3->self_scm ());
 918                 chm->set_mus_property ("what", $2);
 919
 920                 $$ = chm;
 921                 chm->set_spot (*$3->origin ());
 922         }
 923         | GRACE Music {
 924 #if 1
 925         /*
 926                 The other version is for easier debugging  of
 927                 Sequential_music_iterator in combination with grace notes.
 928         */
 929
 930                 SCM start = THIS->lexer_->lookup_identifier ("startGraceMusic");
 931                 SCM stop = THIS->lexer_->lookup_identifier ("stopGraceMusic");
 932                 Music *startm = unsmob_music (start);
 933                 Music *stopm = unsmob_music (stop);
 934
 935                 SCM ms = SCM_EOL;
 936                 if (stopm) {
 937                         stopm = stopm->clone ();
 938                         ms = scm_cons (stopm->self_scm (), ms);
 939                         scm_gc_unprotect_object (stopm->self_scm ());
 940                 }
 941                 ms = scm_cons ($2->self_scm (), ms);
 942                 scm_gc_unprotect_object ($2->self_scm());
 943                 if (startm) {
 944                         startm = startm->clone ();
 945                         ms = scm_cons (startm->self_scm () , ms);
 946                         scm_gc_unprotect_object (startm->self_scm ());
 947                 }
 948
 949
 950                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 951                 seq->set_mus_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC("GraceMusic");
 955                 $$->set_mus_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC("GraceMusic");
 959                 $$->set_mus_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string Music {
 964                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 965
 966                 csm->set_mus_property ("element", $5->self_scm ());
 967                 scm_gc_unprotect_object ($5->self_scm ());
 968
 969                 csm->set_mus_property ("context-type", $2);
 970                 csm->set_mus_property ("context-id", $4);
 971
 972                 $$ = csm;
 973         }
 974         | TIMES {
 975                 THIS->push_spot ();
 976         }
 977         /* CONTINUED */
 978                 fraction Music
 979
 980         {
 981                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 982                 Music *mp = $4;
 983         $$= MY_MAKE_MUSIC("TimeScaledMusic");
 984                 $$->set_spot (THIS->pop_spot ());
 985
 986
 987                 $$->set_mus_property ("element", mp->self_scm ());
 988                 scm_gc_unprotect_object (mp->self_scm ());
 989                 $$->set_mus_property ("numerator", gh_int2scm (n));
 990                 $$->set_mus_property ("denominator", gh_int2scm (d));
 991                 $$->compress (Moment (Rational (n,d)));
 992
 993         }
 994         | Repeated_music                { $$ = $1; }
 995         | Simultaneous_music            { $$ = $1; }
 996         | Sequential_music              { $$ = $1; }
 997         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 998                 $$ = MY_MAKE_MUSIC("TransposedMusic");
 999                 Music *p = $4;
1000                 Pitch from = *unsmob_pitch ($2);
1001                 Pitch to = *unsmob_pitch ($3);
1002
1003                 p->transpose (interval (from, to));
1004                 $$->set_mus_property ("element", p->self_scm ());
1005                 scm_gc_unprotect_object (p->self_scm ());
1006         }
1007         | APPLY embedded_scm Music  {
1008                 if (!ly_input_procedure_p ($2))
1009                         THIS->parser_error (_ ("\\apply takes function argument"));
1010
1011                 SCM ret = gh_call1 ($2, $3->self_scm ());
1012                 Music *m = unsmob_music (ret);
1013                 if (!m) {
1014                         THIS->parser_error ("\\apply must return a Music");
1015                         m = MY_MAKE_MUSIC("Music");
1016                         }
1017                 $$ = m;
1018         }
1019         | NOTES
1020                 { THIS->lexer_->push_note_state (); }
1021         Music
1022                 { $$ = $3;
1023                   THIS->lexer_->pop_state ();
1024                 }
1025         | FIGURES
1026                 { THIS->lexer_->push_figuredbass_state (); }
1027         Music
1028                 {
1029                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1030                   chm->set_mus_property ("element", $3->self_scm ());
1031                   $$ = chm;
1032                   scm_gc_unprotect_object ($3->self_scm());
1033
1034                   THIS->lexer_->pop_state ();
1035         }
1036         | CHORDS
1037                 { THIS->lexer_->push_chord_state (); }
1038         Music
1039                 {
1040                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1041                   chm->set_mus_property ("element", $3->self_scm ());
1042                   scm_gc_unprotect_object ($3->self_scm());
1043                   $$ = chm;
1044
1045                   THIS->lexer_->pop_state ();
1046         }
1047         | LYRICS
1048                 { THIS->lexer_->push_lyric_state (); }
1049         Music
1050                 {
1051                   $$ = $3;
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | relative_music        { $$ = $1; }
1055         | re_rhythmed_music     { $$ = $1; }
1056         | part_combined_music   { $$ = $1; }
1057         ;
1058
1059 relative_music:
1060         RELATIVE absolute_pitch Music {
1061                 Music * p = $3;
1062                 Pitch pit = *unsmob_pitch ($2);
1063                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1064
1065                 $$->set_mus_property ("element", p->self_scm ());
1066                 scm_gc_unprotect_object (p->self_scm ());
1067
1068
1069                 $$->set_mus_property ("last-pitch", p->to_relative_octave (pit).smobbed_copy ());
1070
1071         }
1072         ;
1073
1074 re_rhythmed_music:
1075         ADDLYRICS Music Music {
1076         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1077           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1078           scm_gc_unprotect_object ($3->self_scm ());
1079           scm_gc_unprotect_object ($2->self_scm ());
1080           $$ = l;
1081         }
1082         ;
1083
1084 part_combined_music:
1085         PARTCOMBINE STRING Music Music {
1086         Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1087                 p->set_mus_property ("what", $2);
1088                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1089
1090                 scm_gc_unprotect_object ($3->self_scm ());
1091                 scm_gc_unprotect_object ($4->self_scm ());
1092
1093                 $$ = p;
1094         }
1095         ;
1096
1097 translator_change:
1098         TRANSLATOR STRING '=' STRING  {
1099                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1100                 t-> set_mus_property ("change-to-type", $2);
1101                 t-> set_mus_property ("change-to-id", $4);
1102
1103                 $$ = t;
1104                 $$->set_spot (THIS->here_input ());
1105         }
1106         ;
1107
1108 property_def:
1109         simple_property_def
1110         | ONCE simple_property_def {
1111                 $$ = $2;
1112                 SCM e = $2->get_mus_property ("element");
1113                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1114         }
1115         ;
1116
1117 simple_property_def:
1118         PROPERTY STRING '.' STRING '='  scalar {
1119                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1120                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1121
1122                 csm->set_mus_property ("element", t->self_scm ());
1123                 scm_gc_unprotect_object (t->self_scm ());
1124
1125                 $$ = csm;
1126                 $$->set_spot (THIS->here_input ());
1127
1128                 csm-> set_mus_property ("context-type", $2);
1129         }
1130         | PROPERTY STRING '.' STRING UNSET {
1131
1132                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1133                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1134
1135                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1136                 csm->set_mus_property ("element", t->self_scm ());
1137                 scm_gc_unprotect_object (t->self_scm ());
1138
1139                 $$ = csm;
1140                 $$->set_spot (THIS->here_input ());
1141
1142                 csm-> set_mus_property ("context-type", $2);
1143         }
1144         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1145                 bool autobeam
1146                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1147                 bool itc = internal_type_checking_global_b;
1148                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1149                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1150                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1151                 if (autobeam)
1152                         internal_type_checking_global_b = false;
1153                 t->set_mus_property ("grob-property", $6);
1154                 if (autobeam)
1155                         internal_type_checking_global_b = itc;
1156                 t->set_mus_property ("grob-value", $8);
1157
1158                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1159                 csm->set_mus_property ("element", t->self_scm ());
1160                 scm_gc_unprotect_object (t->self_scm ());
1161                 $$ = csm;
1162                 $$->set_spot (THIS->here_input ());
1163
1164                 csm-> set_mus_property ("context-type", $2);
1165         }
1166         | PROPERTY STRING '.' STRING OVERRIDE
1167                 embedded_scm '=' embedded_scm
1168         {
1169                 /*
1170                         UGH UGH UGH UGH.
1171                 */
1172                 bool autobeam
1173                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1174                 bool itc = internal_type_checking_global_b;
1175
1176                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1177                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1178                 if (autobeam)
1179                         internal_type_checking_global_b = false;
1180                 t->set_mus_property ("grob-property", $6);
1181                 t->set_mus_property ("grob-value", $8);
1182                 if (autobeam)
1183                         internal_type_checking_global_b = itc;
1184
1185                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1186                 csm->set_mus_property ("element", t->self_scm ());
1187                 scm_gc_unprotect_object (t->self_scm ());
1188
1189                 $$ = csm;
1190                 $$->set_spot (THIS->here_input ());
1191
1192                 csm-> set_mus_property ("context-type", $2);
1193
1194         }
1195         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1196                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1197                 bool autobeam
1198                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1199                 bool itc = internal_type_checking_global_b;
1200
1201                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1202                 if (autobeam)
1203                         internal_type_checking_global_b = false;
1204                 t->set_mus_property ("grob-property", $6);
1205                 if (autobeam)
1206                         internal_type_checking_global_b = itc;
1207
1208                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1209                 csm->set_mus_property ("element", t->self_scm ());
1210                 scm_gc_unprotect_object (t->self_scm ());
1211
1212                 $$ = csm;
1213                 $$->set_spot (THIS->here_input ());
1214
1215                 csm-> set_mus_property ("context-type", $2);
1216         }
1217         ;
1218
1219
1220 scalar:
1221         string          { $$ = $1; }
1222         | bare_int      { $$ = gh_int2scm ($1); }
1223         | embedded_scm  { $$ = $1; }
1224         | full_markup {  $$ = $1; }
1225         | DIGIT { $$ = gh_int2scm ($1); }
1226         ;
1227
1228
1229
1230 /*
1231 This is a trick:
1232
1233 Adding pre_events to the simple_element
1234 makes the choice between
1235
1236   string:  STRING
1237
1238 and
1239
1240   simple_element: STRING
1241
1242 a single shift/reduction conflict.
1243
1244 nevertheless, this is not very clean, and we should find a different
1245 solution.
1246
1247 */
1248 pre_events: {
1249                 THIS->push_spot ();
1250         }
1251         ;
1252
1253 event_chord:
1254         pre_events simple_element post_events   {
1255                 SCM elts = $2-> get_mus_property ("elements");
1256
1257                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1258
1259                 $2->set_mus_property ("elements", elts);
1260                 $$ = $2;
1261         }
1262         | command_element
1263         | note_chord_element
1264         ;
1265
1266
1267 note_chord_element:
1268         chord_body optional_notemode_duration post_events
1269         {
1270                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1271                 SCM es = $1->get_mus_property ("elements");
1272                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1273
1274                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1275                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1276                 es = gh_append2 (es, postevs);
1277
1278                 $1-> set_mus_property ("elements", es);
1279                 $$ = $1;
1280         }
1281         ;
1282
1283 chord_body:
1284         CHORD_OPEN chord_body_elements CHORD_CLOSE
1285         {
1286                 $$ = MY_MAKE_MUSIC("EventChord");
1287                 $$->set_mus_property ("elements",
1288                         scm_reverse_x ($2, SCM_EOL));
1289         }
1290         ;
1291
1292 chord_body_elements:
1293         /* empty */             { $$ = SCM_EOL; }
1294         | chord_body_elements chord_body_element {
1295                 $$ = gh_cons ($2->self_scm(), $1);
1296                 scm_gc_unprotect_object ($2->self_scm());
1297         }
1298         ;
1299
1300 chord_body_element:
1301         pitch exclamations questions post_events
1302         {
1303                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1304                 n->set_mus_property ("pitch", $1);
1305                 if ($3 % 2)
1306                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1307                 if ($2 % 2 || $3 % 2)
1308                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1309
1310                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1311                 n->set_mus_property ("articulations", arts);
1312
1313                 $$ = n;
1314         }
1315         ;
1316
1317 command_element:
1318         command_req {
1319                 $$ = MY_MAKE_MUSIC("EventChord");
1320                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1321           scm_gc_unprotect_object ($1->self_scm());
1322
1323                 $$-> set_spot (THIS->here_input ());
1324                 $1-> set_spot (THIS->here_input ());
1325         }
1326         | E_LEFTSQUARE {
1327                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1328                 l->set_mus_property ("span-direction", gh_int2scm (START));
1329                 l->set_spot (THIS->here_input ());
1330
1331                 $$ = MY_MAKE_MUSIC("EventChord");
1332                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1333                 scm_gc_unprotect_object (l->self_scm());
1334                 $$->set_spot (THIS->here_input ());
1335         }
1336         | E_RIGHTSQUARE {
1337                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1338                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1339                 l->set_spot (THIS->here_input ());
1340
1341                 $$ = MY_MAKE_MUSIC("EventChord");
1342                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1343                 $$->set_spot (THIS->here_input ());
1344                 scm_gc_unprotect_object (l->self_scm());
1345         }
1346         | E_BACKSLASH {
1347                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1348                 $$->set_spot (THIS->here_input ());
1349         }
1350         | '|'      {
1351
1352                 $$ = MY_MAKE_MUSIC("BarCheck");
1353                 $$->set_spot (THIS->here_input ());
1354         }
1355         | BAR STRING                    {
1356                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1357
1358                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1359                 csm->set_mus_property ("element", t->self_scm ());
1360                 scm_gc_unprotect_object (t->self_scm ());
1361
1362                 $$ = csm;
1363                 $$->set_spot (THIS->here_input ());
1364
1365                 csm->set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1366         }
1367         | PARTIAL duration_length       {
1368                 Moment m = - unsmob_duration ($2)->get_length ();
1369                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1370
1371                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1372                 sp->set_mus_property ("element", p->self_scm ());
1373                 scm_gc_unprotect_object (p->self_scm ());
1374
1375                 $$ =sp ;
1376                 sp-> set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1377         }
1378         | CLEF STRING  {
1379                 static SCM proc ;
1380                 if (!proc)
1381                         proc = scm_c_eval_string ("make-clef-set");
1382
1383                 SCM result = scm_call_1 (proc, $2);
1384                 scm_gc_protect_object (result);
1385                 $$ = unsmob_music (result);
1386         }
1387         | TIME_T fraction  {
1388                 static SCM proc;
1389                 if (!proc)
1390                         proc = scm_c_eval_string ("make-time-signature-set");
1391
1392                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1393                 scm_gc_protect_object (result);
1394                 $$ = unsmob_music (result);
1395         }
1396         ;
1397
1398 command_req:
1399         shorthand_command_req   { $$ = $1; }
1400         | verbose_command_req   { $$ = $1; }
1401         ;
1402
1403 shorthand_command_req:
1404         extender_req {
1405                 $$ = $1;
1406         }
1407         | hyphen_req {
1408                 $$ = $1;
1409         }
1410         | '~'   {
1411                 $$ = MY_MAKE_MUSIC("TieEvent");
1412         }
1413         | '['           {
1414                 Music *b= MY_MAKE_MUSIC("BeamEvent");
1415                 b->set_mus_property ("span-direction", gh_int2scm (START));
1416                 $$ = b;
1417
1418                 THIS->last_beam_start_ = b->self_scm ();
1419         }
1420         | ']'           {
1421                 Music *b= MY_MAKE_MUSIC("BeamEvent");
1422                 b->set_mus_property ("span-direction", gh_int2scm (STOP));
1423                 $$ = b;
1424         }
1425         | BREATHE {
1426                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1427         }
1428         | E_TILDE {
1429                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1430         }
1431         ;
1432
1433 verbose_command_req:
1434         MARK DEFAULT  {
1435                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1436                 $$ = m;
1437         }
1438         | MARK scalar {
1439                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1440                 m->set_mus_property ("label", $2);
1441                 $$ = m;
1442         }
1443         | SKIP duration_length {
1444                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1445                 skip->set_mus_property ("duration", $2);
1446
1447                 $$ = skip;
1448         }
1449         | tempo_event {
1450                 $$ = $1;
1451         }
1452         | KEY DEFAULT {
1453                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1454                 $$ = key;
1455         }
1456         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1457
1458                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1459                 if (scm_ilength ($3) > 0)
1460                 {
1461                         key->set_mus_property ("pitch-alist", $3);
1462                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1463                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1464                 } else {
1465                         THIS->parser_error (_("Second argument must be pitch list."));
1466                 }
1467
1468                 $$ = key;
1469         }
1470         ;
1471
1472 post_events:
1473         /* empty */ {
1474                 $$ = SCM_EOL;
1475         }
1476         | post_events post_event {
1477                 $2->set_spot (THIS->here_input ());
1478                 $$ = gh_cons ($2->self_scm(), $$);
1479                 scm_gc_unprotect_object ($2->self_scm());
1480         }
1481         ;
1482
1483 post_event:
1484         verbose_event
1485         | event_with_dir
1486         | close_event
1487         | string_event
1488         ;
1489
1490 string_event:
1491         E_UNSIGNED {
1492                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1493                 s->set_mus_property ("string-number",  gh_int2scm($1));
1494                 s->set_spot (THIS->here_input ());
1495                 $$ = s;
1496         }
1497         ;
1498
1499
1500 event_that_take_dir:
1501         gen_text_def
1502         | verbose_event
1503         | close_event
1504         | open_event
1505         | '['  {
1506
1507
1508 /*
1509
1510 TODO: should take all these defs out of the parser, adn make use
1511 configurable, i.e.
1512
1513
1514 (set-articulation '~ "trill")
1515
1516 */
1517                 Music * m = MY_MAKE_MUSIC ("NewBeamEvent");
1518                 m->set_spot (THIS->here_input());
1519                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1520                 $$ = m;
1521         }
1522         | ']'  {
1523                 Music * m = MY_MAKE_MUSIC ("NewBeamEvent");
1524                 m->set_spot (THIS->here_input());
1525                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1526                 $$ = m;
1527         }
1528         | '~' {
1529                 Music * m = MY_MAKE_MUSIC ("NewTieEvent");
1530                 m->set_spot (THIS->here_input());
1531                 $$ = m;
1532         }
1533         | script_abbreviation {
1534                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1535                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1536                 if (gh_string_p (s))
1537                         a->set_mus_property ("articulation-type", s);
1538                 else THIS->parser_error (_ ("Expecting string as script definition"));
1539                 $$ = a;
1540         }
1541         ;
1542
1543 event_with_dir:
1544         script_dir event_that_take_dir  {
1545                 $2->set_mus_property ("direction", gh_int2scm ($1));
1546                 $$ = $2;
1547         }
1548         ;
1549
1550 verbose_event:
1551         EVENT_IDENTIFIER        {
1552                 $$ = unsmob_music ($1);
1553         }
1554         | tremolo_type  {
1555                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1556                a->set_spot (THIS->here_input ());
1557                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1558                $$ = a;
1559         }
1560         ;
1561
1562 sup_quotes:
1563         '\'' {
1564                 $$ = 1;
1565         }
1566         | sup_quotes '\'' {
1567                 $$ ++;
1568         }
1569         ;
1570
1571 sub_quotes:
1572         ',' {
1573                 $$ = 1;
1574         }
1575         | sub_quotes ',' {
1576                 $$ ++ ;
1577         }
1578         ;
1579
1580 steno_pitch:
1581         NOTENAME_PITCH  {
1582                 $$ = $1;
1583         }
1584         | NOTENAME_PITCH sup_quotes     {
1585                 Pitch p = *unsmob_pitch ($1);
1586                 p = p.transposed (Pitch ($2,0,0));
1587                 $$ = p.smobbed_copy ();
1588         }
1589         | NOTENAME_PITCH sub_quotes      {
1590                 Pitch p =* unsmob_pitch ($1);
1591                 p = p.transposed (Pitch (-$2,0,0));
1592                 $$ = p.smobbed_copy ();
1593         }
1594         ;
1595
1596 /*
1597 ugh. duplication
1598 */
1599
1600 steno_tonic_pitch:
1601         TONICNAME_PITCH {
1602                 $$ = $1;
1603         }
1604         | TONICNAME_PITCH sup_quotes    {
1605                 Pitch p = *unsmob_pitch ($1);
1606                 p = p.transposed (Pitch ($2,0,0));
1607                 $$ = p.smobbed_copy ();
1608         }
1609         | TONICNAME_PITCH sub_quotes     {
1610                 Pitch p =* unsmob_pitch ($1);
1611
1612                 p = p.transposed (Pitch (-$2,0,0));
1613                 $$ = p.smobbed_copy ();
1614         }
1615         ;
1616
1617 pitch:
1618         steno_pitch {
1619                 $$ = $1;
1620         }
1621         | explicit_pitch {
1622                 $$ = $1;
1623         }
1624         ;
1625
1626 pitch_also_in_chords:
1627         pitch
1628         | steno_tonic_pitch
1629         ;
1630
1631 explicit_pitch:
1632         PITCH embedded_scm {
1633                 $$ = $2;
1634                 if (!unsmob_pitch ($2)) {
1635                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1636                          $$ = Pitch ().smobbed_copy ();
1637                 }
1638         }
1639         ;
1640
1641 verbose_duration:
1642         DURATION embedded_scm   {
1643                 $$ = $2;
1644                 if (!unsmob_duration ($2))
1645                 {
1646                         THIS->parser_error (_ ("Must have duration object"));
1647                         $$ = Duration ().smobbed_copy ();
1648                 }
1649         }
1650         ;
1651
1652 extender_req:
1653         EXTENDER {
1654                 if (!THIS->lexer_->lyric_state_b ())
1655                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1656                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1657         }
1658         ;
1659
1660 hyphen_req:
1661         HYPHEN {
1662                 if (!THIS->lexer_->lyric_state_b ())
1663                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1664                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1665         }
1666         ;
1667
1668 close_event:
1669         close_event_parens {
1670                 $$ = $1;
1671                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START))
1672 ;
1673         }
1674         ;
1675
1676 close_event_parens:
1677         '('     {
1678                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1679                 $$ = s;
1680                 s->set_spot (THIS->here_input());
1681         }
1682         | E_OPEN        {
1683                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1684                 $$ = s;
1685                 s->set_spot (THIS->here_input());
1686         }
1687         | E_SMALLER {
1688                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1689                 $$ = s;
1690                 s->set_spot (THIS->here_input());
1691         }
1692         | E_BIGGER {
1693                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1694                 $$ = s;
1695                 s->set_spot (THIS->here_input());
1696         }
1697         ;
1698
1699
1700 open_event:
1701         open_event_parens {
1702                 $$ = $1;
1703                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP))
1704 ;
1705         }
1706         ;
1707
1708 open_event_parens:
1709         E_EXCLAMATION   {
1710                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1711                 s->set_spot (THIS->here_input());
1712
1713                 $$ = s;
1714         }
1715         | ')'   {
1716                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1717                 $$ = s;
1718                 s->set_spot (THIS->here_input());
1719
1720         }
1721         | E_CLOSE       {
1722                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1723                 $$ = s;
1724                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1725                 s->set_spot (THIS->here_input());
1726         }
1727         ;
1728
1729 gen_text_def:
1730         embedded_scm {
1731                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1732                 t->set_mus_property ("text", $1);
1733                 t->set_spot (THIS->here_input ());
1734                 $$ = t;
1735         }
1736         | full_markup {
1737                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1738                 t->set_mus_property ("text", $1);
1739                 t->set_spot (THIS->here_input ());
1740                 $$ = t;
1741         }
1742         | string {
1743                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1744                 t->set_mus_property ("text", make_simple_markup ($1));
1745                 t->set_spot (THIS->here_input ());
1746                 $$ = t;
1747
1748         }
1749         | DIGIT {
1750                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1751                 t->set_mus_property ("digit",  gh_int2scm ($1));
1752                 t->set_spot (THIS->here_input ());
1753                 $$ = t;
1754         }
1755         ;
1756
1757 script_abbreviation:
1758         '^'             {
1759                 $$ = scm_makfrom0str ("Hat");
1760         }
1761         | '+'           {
1762                 $$ = scm_makfrom0str ("Plus");
1763         }
1764         | '-'           {
1765                 $$ = scm_makfrom0str ("Dash");
1766         }
1767         | '|'           {
1768                 $$ = scm_makfrom0str ("Bar");
1769         }
1770         | '>'           {
1771                 $$ = scm_makfrom0str ("Larger");
1772         }
1773         | '.'           {
1774                 $$ = scm_makfrom0str ("Dot");
1775         }
1776         | '_' {
1777                 $$ = scm_makfrom0str ("Underscore");
1778         }
1779         ;
1780
1781 script_dir:
1782         '_'     { $$ = DOWN; }
1783         | '^'   { $$ = UP; }
1784         | '-'   { $$ = CENTER; }
1785         ;
1786
1787
1788 absolute_pitch:
1789         steno_pitch     {
1790                 $$ = $1;
1791         }
1792         ;
1793
1794 duration_length:
1795         multiplied_duration {
1796                 $$ = $1;
1797         }
1798         | verbose_duration {
1799                 $$ = $1;
1800         }
1801         ;
1802
1803 optional_notemode_duration:
1804         {
1805                 Duration dd = THIS->default_duration_;
1806                 $$ = dd.smobbed_copy ();
1807
1808                 THIS->beam_check ($$);
1809         }
1810         | multiplied_duration   {
1811                 $$ = $1;
1812                 THIS->default_duration_ = *unsmob_duration ($$);
1813
1814                 THIS->beam_check ($$);
1815         }
1816         | verbose_duration {
1817                 $$ = $1;
1818                 THIS->default_duration_ = *unsmob_duration ($$);
1819         }
1820         ;
1821
1822 steno_duration:
1823         bare_unsigned dots              {
1824                 int l = 0;
1825                 if (!is_duration_b ($1))
1826                         THIS->parser_error (_f ("not a duration: %d", $1));
1827                 else
1828                         l =  intlog2 ($1);
1829
1830                 $$ = Duration (l, $2).smobbed_copy ();
1831         }
1832         | DURATION_IDENTIFIER dots      {
1833                 Duration *d =unsmob_duration ($1);
1834                 Duration k (d->duration_log (),d->dot_count () + $2);
1835
1836                 *d = k;
1837                 $$ = $1;
1838         }
1839         ;
1840
1841
1842
1843
1844 multiplied_duration:
1845         steno_duration {
1846                 $$ = $1;
1847         }
1848         | multiplied_duration '*' bare_unsigned {
1849                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1850         }
1851         | multiplied_duration '*' FRACTION {
1852                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1853
1854                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1855         }
1856         ;
1857
1858 fraction:
1859         FRACTION { $$ = $1; }
1860         | UNSIGNED '/' UNSIGNED {
1861                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1862         }
1863         ;
1864
1865 dots:
1866         /* empty */     {
1867                 $$ = 0;
1868         }
1869         | dots '.' {
1870                 $$ ++;
1871         }
1872         ;
1873
1874
1875 tremolo_type:
1876         ':'     {
1877                 $$ =0;
1878         }
1879         | ':' bare_unsigned {
1880                 if (!is_duration_b ($2))
1881                         THIS->parser_error (_f ("not a duration: %d", $2));
1882                 $$ = $2;
1883         }
1884         ;
1885
1886
1887
1888 /*****************************************************************
1889                 BASS FIGURES
1890 *****************************************************************/
1891 bass_number:
1892         DIGIT   {
1893                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1894         }
1895         | UNSIGNED {
1896                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1897         }
1898         | STRING { $$ =  $1 }
1899         ;
1900
1901 bass_mod:
1902         '-'     { $$ = -1; }
1903         | '+'   { $$ = 1; }
1904         | '!'   { $$ = 0; }
1905         ;
1906
1907 bass_figure:
1908         FIGURE_SPACE {
1909                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1910                 $$ = bfr->self_scm();
1911                 scm_gc_unprotect_object ($$);
1912         }
1913         | bass_number  {
1914                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1915                 $$ = bfr->self_scm();
1916
1917                 bfr->set_mus_property ("figure", $1);
1918
1919                 scm_gc_unprotect_object ($$);
1920         }
1921         | bass_figure bass_mod {
1922                 Music *m = unsmob_music ($1);
1923                 if ($2) {
1924                         SCM salter =m->get_mus_property ("alteration");
1925                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1926                         m->set_mus_property ("alteration",
1927                                 gh_int2scm (alter + $2));
1928                 } else {
1929                         m->set_mus_property ("alteration", gh_int2scm (0));
1930                 }
1931         }
1932         ;
1933
1934 br_bass_figure:
1935         '[' bass_figure {
1936                 $$ = $2;
1937                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1938         }
1939         | bass_figure   {
1940                 $$ = $1;
1941         }
1942         | br_bass_figure ']' {
1943                 $$ = $1;
1944                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1945         }
1946         ;
1947
1948 figure_list:
1949         /**/            {
1950                 $$ = SCM_EOL;
1951         }
1952         | figure_list br_bass_figure {
1953                 $$ = scm_cons ($2, $1);
1954         }
1955         ;
1956
1957 figure_spec:
1958         FIGURE_OPEN figure_list FIGURE_CLOSE {
1959                 Music * m = MY_MAKE_MUSIC("EventChord");
1960                 $2 = scm_reverse_x ($2, SCM_EOL);
1961                 m->set_mus_property ("elements",  $2);
1962                 $$ = m->self_scm ();
1963         }
1964         ;
1965
1966
1967 optional_rest:
1968         /**/   { $$ = 0; }
1969         | REST { $$ = 1; }
1970         ;
1971
1972 simple_element:
1973         pitch exclamations questions optional_notemode_duration optional_rest {
1974
1975                 Input i = THIS->pop_spot ();
1976                 if (!THIS->lexer_->note_state_b ())
1977                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1978
1979                 Music *n = 0;
1980                 if ($5)
1981                         n =  MY_MAKE_MUSIC("RestEvent");
1982                 else
1983                         n =  MY_MAKE_MUSIC("NoteEvent");
1984
1985                 n->set_mus_property ("pitch", $1);
1986                 n->set_mus_property ("duration", $4);
1987
1988
1989                 if ($3 % 2)
1990                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1991                 if ($2 % 2 || $3 % 2)
1992                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1993
1994                 Music *v = MY_MAKE_MUSIC("EventChord");
1995                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1996                 scm_gc_unprotect_object (n->self_scm());
1997
1998                 v->set_spot (i);
1999                 n->set_spot (i);
2000                 $$ = v;
2001         }
2002         | figure_spec optional_notemode_duration {
2003                 Music * m = unsmob_music ($1);
2004                 Input i = THIS->pop_spot ();
2005                 m->set_spot (i);
2006                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2007                 {
2008                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2009                 }
2010                 $$ = m;
2011         }
2012         | RESTNAME optional_notemode_duration           {
2013
2014                 Input i = THIS->pop_spot ();
2015                 Music * ev = 0;
2016                 if (ly_scm2string ($1) =="s") {
2017                         /* Space */
2018                         ev = MY_MAKE_MUSIC("SkipEvent");
2019                   }
2020                 else {
2021                         ev = MY_MAKE_MUSIC("RestEvent");
2022
2023                     }
2024                 ev->set_mus_property ("duration" ,$2);
2025                 ev->set_spot (i);
2026                 Music * velt = MY_MAKE_MUSIC("EventChord");
2027                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2028                 velt->set_spot (i);
2029
2030                 $$ = velt;
2031         }
2032         | MULTI_MEASURE_REST optional_notemode_duration         {
2033                 THIS->pop_spot ();
2034
2035                 static SCM proc ;
2036                 if (!proc)
2037                         proc = scm_c_eval_string ("make-multi-measure-rest");
2038
2039                 SCM mus = scm_call_2 (proc, $2,
2040                         make_input (THIS->here_input()));
2041                 scm_gc_protect_object (mus);
2042                 $$ = unsmob_music (mus);
2043         }
2044         | STRING optional_notemode_duration     {
2045                 Input i = THIS->pop_spot ();
2046
2047                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2048                 lreq->set_mus_property ("text", $1);
2049                 lreq->set_mus_property ("duration",$2);
2050                 lreq->set_spot (i);
2051                 Music * velt = MY_MAKE_MUSIC("EventChord");
2052                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2053
2054                 $$= velt;
2055         }
2056         | new_chord {
2057                 THIS->pop_spot ();
2058
2059                 if (!THIS->lexer_->chord_state_b ())
2060                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2061                 $$ = unsmob_music ($1);
2062         }
2063         ;
2064
2065 new_chord:
2066         steno_tonic_pitch optional_notemode_duration   {
2067                 $$ = make_chord ($1, $2, SCM_EOL);
2068         }
2069         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2070                 SCM its = scm_reverse_x ($4, SCM_EOL);
2071                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2072         }
2073         ;
2074
2075 chord_items:
2076         /**/ {
2077                 $$ = SCM_EOL;
2078         }
2079         | chord_items chord_item {
2080                 $$ = gh_cons ($2, $$);
2081         }
2082         ;
2083
2084 chord_separator:
2085         CHORD_COLON {
2086                 $$ = ly_symbol2scm ("chord-colon");
2087         }
2088         | CHORD_CARET {
2089                 $$ = ly_symbol2scm ("chord-caret");
2090         }
2091         | CHORD_SLASH steno_tonic_pitch {
2092                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2093         }
2094         | CHORD_BASS steno_tonic_pitch {
2095                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2096         }
2097         ;
2098
2099 chord_item:
2100         chord_separator {
2101                 $$ = $1;
2102         }
2103         | step_numbers {
2104                 $$ = scm_reverse_x ($1, SCM_EOL);
2105         }
2106         | CHORD_MODIFIER  {
2107                 $$ = $1;
2108         }
2109         ;
2110
2111 step_numbers:
2112         step_number { $$ = gh_cons ($1, SCM_EOL); }
2113         | step_numbers '.' step_number {
2114                 $$ = gh_cons ($3, $$);
2115         }
2116         ;
2117
2118 step_number:
2119         bare_unsigned {
2120                 $$ = make_chord_step ($1, 0);
2121         }
2122         | bare_unsigned '+' {
2123                 $$ = make_chord_step ($1, 1);
2124         }
2125         | bare_unsigned CHORD_MINUS {
2126                 $$ = make_chord_step ($1,-1);
2127         }
2128         ;
2129
2130 /*
2131         UTILITIES
2132  */
2133 number_expression:
2134         number_expression '+' number_term {
2135
2136                 THIS->
2137                 $$ = scm_sum ($1, $3);
2138         }
2139         | number_expression '-' number_term {
2140                 $$ = scm_difference ($1, $3);
2141         }
2142         | number_term
2143         ;
2144
2145 number_term:
2146         number_factor {
2147                 $$ = $1;
2148         }
2149         | number_factor '*' number_factor {
2150                 $$ = scm_product ($1, $3);
2151         }
2152         | number_factor '/' number_factor {
2153                 $$ = scm_divide ($1, $3);
2154         }
2155         ;
2156
2157 number_factor:
2158         '-'  number_factor { /* %prec UNARY_MINUS */
2159                 $$ = scm_difference ($2, SCM_UNDEFINED);
2160         }
2161         | bare_number
2162         ;
2163
2164
2165 bare_number:
2166         UNSIGNED        {
2167                 $$ = gh_int2scm ($1);
2168         }
2169         | REAL          {
2170                 $$ = $1;
2171         }
2172         | NUMBER_IDENTIFIER             {
2173                 $$ = $1;
2174         }
2175         | REAL NUMBER_IDENTIFIER        {
2176                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2177         }
2178         | UNSIGNED NUMBER_IDENTIFIER    {
2179                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2180         }
2181         ;
2182
2183
2184 bare_unsigned:
2185         UNSIGNED {
2186                         $$ = $1;
2187         }
2188         | DIGIT {
2189                 $$ = $1;
2190         }
2191         ;
2192
2193 bare_int:
2194         bare_number {
2195                 if (scm_integer_p ($1) == SCM_BOOL_T)
2196                 {
2197                         int k = gh_scm2int ($1);
2198                         $$ = k;
2199                 } else
2200                 {
2201                         THIS->parser_error (_ ("need integer number arg"));
2202                         $$ = 0;
2203                 }
2204         }
2205         | '-' bare_int {
2206                 $$ = -$2;
2207         }
2208         ;
2209
2210
2211 string:
2212         STRING          {
2213                 $$ = $1;
2214         }
2215         | STRING_IDENTIFIER     {
2216                 $$ = $1;
2217         }
2218         | string '+' string {
2219                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2220         }
2221         ;
2222
2223
2224 exclamations:
2225                 { $$ = 0; }
2226         | exclamations '!'      { $$ ++; }
2227         ;
2228
2229 questions:
2230                 { $$ = 0; }
2231         | questions '?' { $$ ++; }
2232         ;
2233
2234
2235
2236 full_markup:
2237         MARKUP_IDENTIFIER {
2238                 $$ = $1;
2239         }
2240         | MARKUP
2241                 { THIS->lexer_->push_markup_state (); }
2242         markup
2243                 { $$ = $3;
2244                   THIS->lexer_->pop_state ();
2245                 }
2246         ;
2247
2248
2249 /*
2250 This should be done more dynamically if possible.
2251 */
2252 markup:
2253         STRING {
2254                 $$ = make_simple_markup ($1);
2255         }
2256         | MARKUP_HEAD_MARKUP0 markup {
2257                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2258         }
2259         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2260                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2261         }
2262         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2263                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2264         }
2265         | markup_line {
2266                 $$ = $1;
2267         }
2268         | MARKUP_HEAD_LIST0 markup_list {
2269                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2270         }
2271         | MARKUP_HEAD_SCM0 embedded_scm {
2272                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2273         }
2274         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2275                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2276         }
2277         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2278                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2279         }
2280         | MARKUP_IDENTIFIER {
2281                 $$ = $1;
2282         }
2283
2284         ;
2285
2286 markup_list:
2287         CHORD_OPEN markup_list_body CHORD_CLOSE { $$ = scm_reverse_x ($2, SCM_EOL); }
2288         ;
2289
2290 markup_line:
2291         '{' markup_list_body '}' {
2292                 static SCM line ;
2293                 if (!line)
2294                         line = scm_c_eval_string ("line-markup");
2295
2296                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2297         }
2298         ;
2299
2300 markup_list_body:
2301         /**/ {  $$ = SCM_EOL; }
2302         | markup_list_body markup {
2303                 $$ = gh_cons ($2, $1) ;
2304         }
2305         ;
2306
2307
2308 %%
2309
2310 void
2311 My_lily_parser::set_yydebug (bool )
2312 {
2313 #if 0
2314         yydebug = 1;
2315 #endif
2316 }
2317
2318 extern My_lily_parser * current_parser;
2319
2320 void
2321 My_lily_parser::do_yyparse ()
2322 {
2323         current_parser = this;;
2324         yyparse ((void*)this);
2325 }
2326
2327
2328 /*
2329 Should make this optional?    It will also complain when you do
2330
2331         [s4]
2332
2333 which is entirely legitimate.
2334
2335 Or we can scrap it. Barchecks should detect wrong durations, and
2336 skipTypesetting speeds it up a lot.
2337 */
2338
2339 void
2340 My_lily_parser::beam_check (SCM dur)
2341 {
2342   Duration *d = unsmob_duration (dur);
2343   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2344     {
2345       Music * m = unsmob_music (last_beam_start_);
2346       m->origin ()->warning (_("Suspect duration found following this beam"));
2347     }
2348   last_beam_start_ = SCM_EOL;
2349 }
2350
2351
2352
2353 bool
2354 markup_p (SCM x)
2355 {
2356         return gh_pair_p (x)
2357                 && SCM_BOOL_F != scm_object_property (gh_car (x), ly_symbol2scm ("markup-signature"));
2358 }
2359
2360
2361 /*
2362
2363 It is a little strange to have this function in this file, but
2364 otherwise, we have to import music classes into the lexer.
2365
2366 */
2367 int
2368 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2369 {
2370         if (gh_string_p (sid)) {
2371                 *destination = sid;
2372                 return STRING_IDENTIFIER;
2373         } else if (gh_number_p (sid)) {
2374                 *destination = sid;
2375                 return NUMBER_IDENTIFIER;
2376         } else if (unsmob_translator_def (sid)) {
2377                 *destination = unsmob_translator_def (sid)->clone_scm();
2378                 return TRANSLATOR_IDENTIFIER;
2379         } else if (unsmob_score (sid)) {
2380                 Score *sc =  new Score (*unsmob_score (sid));
2381                 *destination =sc->self_scm ();
2382                 return SCORE_IDENTIFIER;
2383         } else if (Music * mus =unsmob_music (sid)) {
2384                 *destination = unsmob_music (sid)->clone ()->self_scm();
2385                 unsmob_music (*destination)->
2386                         set_mus_property ("origin", make_input (last_input_));
2387                 return dynamic_cast<Event*> (mus)
2388                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2389         } else if (unsmob_duration (sid)) {
2390                 *destination = unsmob_duration (sid)->smobbed_copy();
2391                 return DURATION_IDENTIFIER;
2392         } else if (unsmob_music_output_def (sid)) {
2393                 Music_output_def *p = unsmob_music_output_def (sid);
2394                 p = p->clone ();
2395
2396                 *destination = p->self_scm();
2397                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2398         } else if (new_markup_p (sid)) {
2399                 *destination = sid;
2400                 return MARKUP_IDENTIFIER;
2401         }
2402
2403         return -1;
2404 }