lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLY
 251 %token APPLYCONTEXT
 252 %token APPLYOUTPUT
 253 %token AUTOCHANGE
 254 %token BAR
 255 %token BOOK
 256 %token BREATHE
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONSISTSEND
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 272 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 273 %token GRACE
 274 %token ACCIACCATURA
 275 %token APPOGGIATURA
 276 %token GROBDESCRIPTIONS
 277 %token HEADER
 278 %token HYPHEN
 279 %token INVALID
 280 %token KEY
 281 %token LYRICS
 282 %token LYRICS_STRING
 283 %token MARK
 284 %token MIDI
 285 %token MULTI_MEASURE_REST
 286 %token NAME
 287 %token NEWCONTEXT
 288 %token NOTES
 289 %token OCTAVE
 290 %token ONCE
 291 %token OVERRIDE SET REVERT
 292 %token PAPER
 293 %token PARTCOMBINE
 294 %token PARTIAL
 295 %token QUOTE
 296 %token RELATIVE
 297 %token REMOVE
 298 %token REPEAT
 299 %token REST
 300 %token SCM_T
 301 %token SCORE
 302 %token SEQUENTIAL
 303 %token NEWLYRICS
 304 %token SIMULTANEOUS
 305 %token SKIP
 306 %token SPANREQUEST
 307 %token TAG
 308 %token TEMPO
 309 %token TIMES
 310 %token TIME_T
 311 %token TRANSPOSE
 312 %token TRANSPOSITION
 313 %token TYPE
 314 %token UNSET
 315 %token WITH
 316
 317 /* escaped */
 318 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 319 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 320 %token E_BACKSLASH
 321 %token <i> E_UNSIGNED
 322 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 323 %token FIGURE_SPACE
 324
 325 %token <i>      DIGIT
 326 %token <scm>    NOTENAME_PITCH
 327 %token <scm>    TONICNAME_PITCH
 328 %token <scm>    CHORDMODIFIER_PITCH
 329 %token <scm>    DURATION_IDENTIFIER
 330 %token <scm>    FRACTION
 331 %token <id>     IDENTIFIER
 332 %token DRUMS
 333 %token <scm>    DRUM_PITCH
 334 %token <scm>    CHORD_MODIFIER
 335 %token <scm>    SCORE_IDENTIFIER
 336 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 337 %token <scm>    NUMBER_IDENTIFIER
 338 %token <scm>    EVENT_IDENTIFIER
 339 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 340 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm>    STRING
 343 %token <scm>    SCM_T
 344 %token <i>      UNSIGNED
 345 %token <scm>   REAL
 346
 347 %token MARKUP
 348 %token <scm> MARKUP_HEAD_MARKUP0
 349 %token <scm> MARKUP_HEAD_EMPTY
 350 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0
 352 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 355 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 356
 357 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 358 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 359
 360 %type <book>    book_block book_body
 361 %type <i>       exclamations questions dots optional_rest
 362 %type <i>        bass_mod
 363 %type <scm>     grace_head
 364 %type <scm>     oct_check
 365 %type <scm>     context_mod_list
 366 %type <scm>     lyric_element
 367 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 368 %type <scm>     new_lyrics
 369 %type <outputdef> output_def
 370 %type <scm>     lilypond_header lilypond_header_body
 371 %type <music>   open_event close_event
 372 %type <i>       sub_quotes sup_quotes
 373 %type <music>   toplevel_music
 374 %type <music>   simple_element event_chord command_element
 375 %type <music>   Composite_music Simple_music Prefix_composite_music
 376 %type <music>   Grouped_music_list
 377 %type <music>   Repeated_music
 378 %type <scm>     Alternative_music
 379 %type <i>       tremolo_type
 380 %type <i>       bare_int  bare_unsigned
 381 %type <i>       script_dir
 382 %type <scm>     identifier_init
 383 %type <scm>     simple_string
 384
 385 %type <music>   note_chord_element chord_body chord_body_element
 386 %type <scm>     chord_body_elements
 387 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 388
 389 %type <scm>     post_events
 390 %type <music>   gen_text_def direction_less_event direction_reqd_event
 391 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 392 %type <scm>     steno_tonic_pitch
 393 %type <scm>     duration_length fraction
 394
 395 %type <scm>     chord_item chord_items chord_separator new_chord
 396 %type <scm>     step_number step_numbers
 397
 398 %type <scm>     embedded_scm scalar
 399 %type <music>   Music Sequential_music Simultaneous_music
 400 %type <music>   relative_music re_rhythmed_music
 401 %type <music>   music_property_def context_change
 402 %type <scm>     context_prop_spec
 403 %type <scm>     Music_list
 404 %type <scm>     property_operation
 405 %type <scm>     context_mod context_def_mod optional_context_mod
 406 %type <outputdef>       music_output_def_body music_output_def_head
 407 %type <music>   post_event tagged_post_event
 408 %type <music>   command_req
 409 %type <music>   string_number_event
 410 %type <scm>     string bare_number number_expression number_term number_factor
 411 %type <score>   score_block score_body
 412
 413 %type <scm>     context_def_spec_block context_def_spec_body
 414 %type <music>   tempo_event
 415 %type <scm>     script_abbreviation
 416
 417
 418
 419 %left '-' '+'
 420
 421 /* We don't assign precedence to / and *, because we might need varied
 422 prec levels in different prods */
 423
 424 %left UNARY_MINUS
 425
 426 %%
 427
 428 lilypond:       /* empty */
 429         | lilypond toplevel_expression {
 430         }
 431         | lilypond assignment {
 432         }
 433         | lilypond error {
 434                 THIS->error_level_ = 1;
 435         }
 436         | lilypond INVALID      {
 437                 THIS->error_level_ = 1;
 438         }
 439         ;
 440
 441 toplevel_expression:
 442         lilypond_header {
 443                 THIS->header_ = $1;
 444         }
 445         | add_quote {
 446
 447         }
 448         | book_block {
 449                 Book *book = $1;
 450                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 451                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 452                 scm_gc_unprotect_object (book->self_scm ());
 453         }
 454         | score_block {
 455                 Score *score = $1;
 456
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 459                 scm_gc_unprotect_object (score->self_scm ());
 460         }
 461         | toplevel_music {
 462                 Music *music = $1;
 463                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 464                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 465                 scm_gc_unprotect_object (music->self_scm ());
 466         }
 467         | output_def {
 468                 SCM id = SCM_EOL;
 469                 if (dynamic_cast<Paper_def*> ($1))
 470                         id = scm_makfrom0str ("$defaultpaper");
 471                 else if (dynamic_cast<Midi_def*> ($1))
 472                         id = scm_makfrom0str ("$defaultmidi");
 473                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 474                 scm_gc_unprotect_object ($1->self_scm ());
 475         }
 476         ;
 477
 478 toplevel_music:
 479         Composite_music {
 480         }
 481         ;
 482
 483 embedded_scm:
 484         SCM_T
 485         | SCM_IDENTIFIER
 486         ;
 487
 488
 489 lilypond_header_body:
 490         {
 491                 $$ = ly_make_anonymous_module ();
 492                 THIS->lexer_->add_scope ($$);
 493         }
 494         | lilypond_header_body assignment  {
 495
 496         }
 497         ;
 498
 499 lilypond_header:
 500         HEADER '{' lilypond_header_body '}'     {
 501                 $$ = THIS->lexer_->remove_scope ();
 502         }
 503         ;
 504
 505
 506 /*
 507         DECLARATIONS
 508 */
 509 assignment:
 510         STRING {
 511                 THIS->push_spot ();
 512         }
 513         /* cont */ '=' identifier_init  {
 514
 515         /*
 516                 Should find generic way of associating input with objects.
 517         */
 518                 Input ip = THIS->pop_spot ();
 519
 520                 if (! is_regular_identifier ($1))
 521                 {
 522                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 523                 }
 524
 525                 THIS->lexer_->set_identifier ($1, $4);
 526
 527 /*
 528  TODO: devise standard for protection in parser.
 529
 530   The parser stack lives on the C-stack, which means that
 531 all objects can be unprotected as soon as they're here.
 532
 533 */
 534         }
 535         | embedded_scm { }
 536         ;
 537
 538
 539 identifier_init:
 540         score_block {
 541                 $$ = $1->self_scm ();
 542                 scm_gc_unprotect_object ($$);
 543         }
 544         | full_markup {
 545                 $$ = $1;
 546         }
 547         | output_def {
 548                 $$ = $1->self_scm ();
 549                 scm_gc_unprotect_object ($$);
 550         }
 551         | context_def_spec_block {
 552                 $$ = $1;
 553         }
 554         | Music  {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | post_event {
 559                 $$ = $1->self_scm ();
 560                 scm_gc_unprotect_object ($$);
 561         }
 562         | number_expression {
 563                 $$ = $1;
 564         }
 565         | string {
 566                 $$ = $1;
 567         }
 568         | embedded_scm  {
 569                 $$ = $1;
 570         }
 571         ;
 572
 573 context_def_spec_block:
 574         CONTEXT '{' context_def_spec_body '}'
 575                 {
 576                 $$ = $3;
 577         }
 578         ;
 579
 580 context_def_spec_body:
 581         /**/ {
 582                 $$ = Context_def::make_scm ();
 583                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 584         }
 585         | CONTEXT_DEF_IDENTIFIER {
 586                 $$ = $1;
 587                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 588         }
 589         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 590                 Context_def*td = unsmob_context_def ($$);
 591
 592                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 593                         SCM tag = ly_caar (p);
 594
 595                         /* TODO: should make new tag "grob-definition" ? */
 596                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 597                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 598                 }
 599         }
 600         | context_def_spec_body context_mod {
 601                 unsmob_context_def ($$)->add_context_mod ($2);
 602         }
 603         ;
 604
 605 book_block:
 606         BOOK {
 607                 THIS->push_spot ();
 608         }
 609         /*cont*/ '{' book_body '}'      {
 610                 THIS->pop_spot ();
 611                 $$ = $4;
 612         }
 613         ;
 614
 615 book_body:
 616         {
 617                 $$ = new Book;
 618                 $$->set_spot (THIS->here_input ());
 619         }
 620         | book_body score_block {
 621                 $$->scores_.push ($2);
 622                 scm_gc_unprotect_object ($2->self_scm ());
 623         }
 624         | book_body error {
 625         }
 626         ;
 627
 628 score_block:
 629         SCORE {
 630                 THIS->push_spot ();
 631         }
 632         /*cont*/ '{' score_body '}'     {
 633                 THIS->pop_spot ();
 634                 $$ = $4;
 635         }
 636         ;
 637
 638 score_body:
 639         Music   {
 640                 $$ = new Score;
 641
 642                 $$->set_spot (THIS->here_input ());
 643                 SCM m = $1->self_scm ();
 644                 scm_gc_unprotect_object (m);
 645
 646                 /*
 647                         guh.
 648                 */
 649                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 650                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 651                         m = scm_call_1 (ly_car (check_funcs), m);
 652                 $$->music_ = m;
 653
 654         }
 655         | SCORE_IDENTIFIER {
 656                 $$ = new Score ( *unsmob_score ($1));
 657                 $$->set_spot (THIS->here_input ());
 658         }
 659         | score_body lilypond_header    {
 660                 $$->header_ = $2;
 661         }
 662         | score_body output_def {
 663                 $$->defs_.push ($2);
 664                 scm_gc_unprotect_object ($2->self_scm ());
 665         }
 666         | score_body error {
 667
 668         }
 669         ;
 670
 671
 672 /*
 673         MIDI
 674 */
 675 output_def:
 676         music_output_def_body '}' {
 677                 $$ = $1;
 678                 THIS->lexer_->remove_scope ();
 679                 THIS->lexer_->pop_state ();
 680         }
 681         ;
 682
 683 music_output_def_head:
 684         MIDI    {
 685                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 686
 687
 688                 Midi_def *p = 0;
 689                 if (id)
 690                         p = dynamic_cast<Midi_def*> (id->clone ());
 691                 else
 692                         p = new Midi_def;
 693
 694                 $$ = p;
 695                 THIS->lexer_->add_scope (p->scope_);
 696         }
 697         | PAPER         {
 698                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 699                   Paper_def *p = 0;
 700                 if (id)
 701                         p = dynamic_cast<Paper_def*> (id->clone ());
 702                 else
 703                         p = new Paper_def;
 704
 705                 THIS->lexer_->add_scope (p->scope_);
 706                 $$ = p;
 707         }
 708         ;
 709
 710
 711 music_output_def_body:
 712         music_output_def_head '{' {
 713                 $$ = $1;
 714                 $$->input_origin_. set_spot (THIS->here_input ());
 715                 THIS->lexer_->push_initial_state ();
 716         }
 717         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 718                 scm_gc_unprotect_object ($1->self_scm ());
 719                 Music_output_def *o = unsmob_music_output_def ($3);
 720                 o->input_origin_.set_spot (THIS->here_input ());
 721                 $$ = o;
 722                 THIS->lexer_->remove_scope ();
 723                 THIS->lexer_->add_scope (o->scope_);
 724                 THIS->lexer_->push_initial_state ();
 725         }
 726         | music_output_def_body assignment  {
 727
 728         }
 729         | music_output_def_body context_def_spec_block  {
 730                 $$->assign_context_def ($2);
 731         }
 732         | music_output_def_body tempo_event  {
 733                 /*
 734                         junk this ? there already is tempo stuff in
 735                         music.
 736                 */
 737                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 738                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 739                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 740                 if (md)
 741                         md->set_tempo (d->get_length (), m);
 742                 scm_gc_unprotect_object ($2->self_scm ());
 743         }
 744         | music_output_def_body error {
 745
 746         }
 747         ;
 748
 749 tempo_event:
 750         TEMPO steno_duration '=' bare_unsigned  {
 751                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 752                 $$->set_property ("tempo-unit", $2);
 753                 $$->set_property ("metronome-count", scm_int2num ( $4));
 754         }
 755         ;
 756
 757 /*
 758 The representation of a  list is the
 759
 760   (LIST . LAST-CONS)
 761
 762  to have  efficient append.
 763 */
 764 Music_list:
 765         /* empty */ {
 766                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 767         }
 768         | Music_list Music {
 769                 SCM s = $$;
 770                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 771                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 772                 if (ly_c_pair_p (ly_cdr (s)))
 773                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 774                 else
 775                         scm_set_car_x (s, c); /* set first cons */
 776                 scm_set_cdr_x (s, c);  /* remember last cell */
 777         }
 778         | Music_list embedded_scm {
 779         }
 780         | Music_list error {
 781         }
 782         ;
 783
 784
 785 Music:
 786         Simple_music
 787         | Composite_music
 788         ;
 789
 790 Alternative_music:
 791         /* empty */ {
 792                 $$ = SCM_EOL;
 793         }
 794         | ALTERNATIVE '{' Music_list '}' {
 795                 $$ = $3;
 796         }
 797         ;
 798
 799
 800 Repeated_music:
 801         REPEAT simple_string bare_unsigned Music Alternative_music
 802         {
 803                 Music *beg = $4;
 804                 int times = $3;
 805                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 806                 if (times < scm_ilength (alts)) {
 807                   unsmob_music (ly_car (alts))
 808                     ->origin ()->warning (
 809                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 810                   alts = ly_truncate_list (times, alts);
 811                 }
 812
 813
 814                 SCM proc = ly_scheme_function ("make-repeated-music");
 815
 816                 SCM mus = scm_call_1 (proc, $2);
 817                 scm_gc_protect_object (mus); // UGH.
 818                 Music *r = unsmob_music (mus);
 819                 if (beg)
 820                         {
 821                         r-> set_property ("element", beg->self_scm ());
 822                         scm_gc_unprotect_object (beg->self_scm ());
 823                         }
 824                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 825
 826                 r-> set_property ("elements",alts);
 827                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 828                         /*
 829                         TODO: move this code to Scheme.
 830                         */
 831
 832                         /*
 833                         we can not get durations and other stuff correct down the line, so we have to
 834                         add to the duration log here.
 835                         */
 836                         SCM func = ly_scheme_function ("shift-duration-log");
 837
 838                         int dots = ($3 % 3) ? 0 : 1;
 839                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 840
 841                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 842
 843                         if (seq) {
 844                                 int list_len = scm_ilength (seq->music_list ());
 845                                 if (list_len != 2)
 846                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 847                                 shift -= 1;
 848                                 r->compress (Moment (Rational (1, list_len)));
 849                                 }
 850                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 851
 852                 }
 853                 r->set_spot (*$4->origin ());
 854
 855                 $$ = r;
 856         }
 857         ;
 858
 859 Sequential_music:
 860         SEQUENTIAL '{' Music_list '}'           {
 861                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 862                 $$->set_property ("elements", ly_car ($3));
 863                 $$->set_spot (THIS->here_input ());
 864         }
 865         | '{' Music_list '}'            {
 866                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 867                 $$->set_property ("elements", ly_car ($2));
 868                 $$->set_spot (THIS->here_input ());
 869         }
 870         ;
 871
 872 Simultaneous_music:
 873         SIMULTANEOUS '{' Music_list '}'{
 874                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 875                 $$->set_property ("elements", ly_car ($3));
 876                 $$->set_spot (THIS->here_input ());
 877
 878         }
 879         | simul_open Music_list simul_close     {
 880                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 881                 $$->set_property ("elements", ly_car ($2));
 882                 $$->set_spot (THIS->here_input ());
 883         }
 884         ;
 885
 886 Simple_music:
 887         event_chord             { $$ = $1; }
 888         | APPLYOUTPUT embedded_scm {
 889                 if (!ly_input_procedure_p ($2))
 890                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 891                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 892                 $$->set_property ("procedure", $2);
 893                 $$->set_spot (THIS->here_input ());
 894         }
 895         | APPLYCONTEXT embedded_scm {
 896                 if (!ly_input_procedure_p ($2))
 897                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 898                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 899                 $$->set_property ("procedure", $2);
 900                 $$->set_spot (THIS->here_input ());
 901         }
 902         | MUSIC_IDENTIFIER {
 903                 $$ = unsmob_music ($1);
 904         }
 905         | music_property_def
 906         | context_change
 907         ;
 908
 909
 910 optional_context_mod:
 911         /**/ { $$ = SCM_EOL; }
 912         | WITH { THIS->lexer_->push_initial_state (); }
 913         '{' context_mod_list '}'
 914         {
 915                 THIS->lexer_->pop_state ();
 916                 $$ = $4;
 917         }
 918         ;
 919
 920 grace_head:
 921         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 922         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 923         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 924         ;
 925
 926 context_mod_list:
 927         /* */  { $$ = SCM_EOL; }
 928         | context_mod_list context_mod  {
 929                  $$ = scm_cons ($2, $1);
 930         }
 931         ;
 932
 933
 934 Composite_music:
 935         Prefix_composite_music { $$ = $1; }
 936         | Grouped_music_list { $$ = $1; }
 937         ;
 938
 939 Grouped_music_list:
 940         Simultaneous_music              { $$ = $1; }
 941         | Sequential_music              { $$ = $1; }
 942         ;
 943
 944 Prefix_composite_music:
 945         AUTOCHANGE Music        {
 946                 SCM proc = ly_scheme_function ("make-autochange-music");
 947
 948                 SCM res = scm_call_1 (proc, $2->self_scm ());
 949                 scm_gc_unprotect_object ($2->self_scm ());
 950                 $$ = unsmob_music (res);
 951                 scm_gc_protect_object (res);
 952                 $$->set_spot (THIS->here_input ());
 953         }
 954         | PARTCOMBINE Music Music {
 955                 SCM proc = ly_scheme_function ("make-part-combine-music");
 956
 957                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 958                         $3->self_scm (), SCM_UNDEFINED));
 959                 scm_gc_unprotect_object ($3->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961                 $$ = unsmob_music (res);
 962                 scm_gc_protect_object (res);
 963                 $$->set_spot (THIS->here_input ());
 964         }
 965         | grace_head Music {
 966 #if 1
 967         /*
 968                 The other version is for easier debugging  of
 969                 Sequential_music_iterator in combination with grace notes.
 970         */
 971
 972 /*
 973
 974 TODO: should distinguish between both grace types in the
 975 basic music objects too, since the meaning is different.
 976
 977 */
 978
 979                 String start_str = "start" + ly_scm2string ($1) + "Music";
 980                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 981
 982                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 983                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 984
 985                 Music *startm = unsmob_music (start);
 986                 Music *stopm = unsmob_music (stop);
 987
 988                 SCM ms = SCM_EOL;
 989                 if (stopm) {
 990                         stopm = stopm->clone ();
 991                         ms = scm_cons (stopm->self_scm (), ms);
 992                         scm_gc_unprotect_object (stopm->self_scm ());
 993                 }
 994                 ms = scm_cons ($2->self_scm (), ms);
 995                 scm_gc_unprotect_object ($2->self_scm ());
 996                 if (startm) {
 997                         startm = startm->clone ();
 998                         ms = scm_cons (startm->self_scm (), ms);
 999                         scm_gc_unprotect_object (startm->self_scm ());
1000                 }
1001
1002                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1003                 seq->set_property ("elements", ms);
1004
1005
1006                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1007                 $$->set_property ("element", seq->self_scm ());
1008                 scm_gc_unprotect_object (seq->self_scm ());
1009 #else
1010                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1011                 $$->set_property ("element", $2->self_scm ());
1012                 scm_gc_unprotect_object ($2->self_scm ());
1013 #endif
1014         }
1015         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1016                 $$ = context_spec_music ($2, $4, $6, $5);
1017
1018         }
1019         | CONTEXT simple_string optional_context_mod Music {
1020                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1021         }
1022         | NEWCONTEXT simple_string optional_context_mod Music {
1023                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1024                         $3);
1025         }
1026
1027         | TIMES {
1028                 THIS->push_spot ();
1029         }
1030         /* CONTINUED */
1031                 fraction Music
1032
1033         {
1034                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1035                 Music *mp = $4;
1036
1037                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1038                 $$->set_spot (THIS->pop_spot ());
1039
1040                 $$->set_property ("element", mp->self_scm ());
1041                 scm_gc_unprotect_object (mp->self_scm ());
1042                 $$->set_property ("numerator", scm_int2num (n));
1043                 $$->set_property ("denominator", scm_int2num (d));
1044                 $$->compress (Moment (Rational (n,d)));
1045
1046         }
1047         | Repeated_music                { $$ = $1; }
1048         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1049                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1050                 Music *p = $4;
1051                 Pitch from = *unsmob_pitch ($2);
1052                 Pitch to = *unsmob_pitch ($3);
1053
1054                 p->transpose (interval (from, to));
1055                 $$->set_property ("element", p->self_scm ());
1056                 scm_gc_unprotect_object (p->self_scm ());
1057         }
1058         | APPLY embedded_scm Music  {
1059                 if (!ly_input_procedure_p ($2))
1060                         {
1061                         THIS->parser_error (_ ("\\apply takes function argument"));
1062                         $$ = $3;
1063                         }
1064                 else
1065                         {
1066                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1067                         Music *m = unsmob_music (ret);
1068                         if (!m) {
1069                                 THIS->parser_error ("\\apply must return a Music");
1070                                 m = MY_MAKE_MUSIC ("Music");
1071                                 }
1072                         $$ = m;
1073                         }
1074         }
1075         | NOTES
1076                 {
1077                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1078                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1079         }
1080         Music
1081                 { $$ = $3;
1082                   THIS->lexer_->pop_state ();
1083                 }
1084         | DRUMS
1085                 {
1086                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1087                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1088         }
1089         /* FIXME: This used to be:
1090         Music
1091 */
1092         Grouped_music_list
1093                 { $$ = $3;
1094                   THIS->lexer_->pop_state ();
1095                 }
1096         | FIGURES
1097                 { THIS->lexer_->push_figuredbass_state (); }
1098         /* FIXME: This used to be:
1099         Music
1100         but that breaks web build
1101         */
1102         Grouped_music_list
1103                 {
1104                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1105                   chm->set_property ("element", $3->self_scm ());
1106                   $$ = chm;
1107                   scm_gc_unprotect_object ($3->self_scm ());
1108
1109                   THIS->lexer_->pop_state ();
1110         }
1111         | CHORDS {
1112                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1113                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1114                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1115                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1116
1117         }
1118         /* FIXME:
1119         Music
1120 */
1121         Grouped_music_list
1122         {
1123                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1124                   chm->set_property ("element", $3->self_scm ());
1125                   scm_gc_unprotect_object ($3->self_scm ());
1126                   $$ = chm;
1127
1128                   THIS->lexer_->pop_state ();
1129         }
1130         | LYRICS
1131                 { THIS->lexer_->push_lyric_state (); }
1132         /* FIXME:
1133         Music
1134 */
1135         Grouped_music_list
1136                 {
1137                   $$ = $3;
1138                   THIS->lexer_->pop_state ();
1139         }
1140         | relative_music        { $$ = $1; }
1141         | re_rhythmed_music     { $$ = $1; }
1142         | TAG embedded_scm Music {
1143                 tag_music ($3, $2, THIS->here_input ());
1144                 $$ = $3;
1145         }
1146         ;
1147
1148 relative_music:
1149         RELATIVE absolute_pitch Music {
1150                 Music *m = $3;
1151                 Pitch start = *unsmob_pitch ($2);
1152                 $$ = make_music_relative (start, m);
1153                 scm_gc_unprotect_object (m->self_scm ());
1154         }
1155         | RELATIVE Composite_music {
1156                 Music *m = $2;
1157                 /* FIXME: why is octave==0 and default not middleC? */
1158                 Pitch middle_c (-1, 0, 0);
1159                 $$ = make_music_relative (middle_c, m);
1160                 scm_gc_unprotect_object (m->self_scm ());
1161         }
1162         ;
1163
1164 new_lyrics:
1165         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1166         /*cont */
1167         Grouped_music_list {
1168         /* Can also use Music at the expensive of two S/Rs similar to
1169            \repeat \alternative */
1170                 THIS->lexer_->pop_state ();
1171 #if 0
1172                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1173                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1174                 $$ = music;
1175 #else
1176                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1177 #endif
1178         }
1179         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1180         Grouped_music_list {
1181                 THIS->lexer_->pop_state ();
1182                 $$ = scm_cons ($4->self_scm (), $1);
1183         }
1184         ;
1185
1186 re_rhythmed_music:
1187         ADDLYRICS Music Music {
1188                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1189                 m->set_property ("elements", scm_listify ($2->self_scm (),
1190                         $3->self_scm (), SCM_UNDEFINED));
1191                 scm_gc_unprotect_object ($3->self_scm ());
1192                 scm_gc_unprotect_object ($2->self_scm ());
1193                 $$ = m;
1194         }
1195         | Grouped_music_list new_lyrics {
1196
1197                 /* FIXME: should find out uniqueXXX name from music */
1198                 SCM name = $1->get_property ("context-id");
1199                 //if (name == SCM_EOL)
1200                 if (!ly_c_string_p (name))
1201                         name = scm_makfrom0str ("");
1202
1203                 SCM context = scm_makfrom0str ("Lyrics");
1204                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1205
1206                 SCM lst = SCM_EOL;
1207                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1208                 {
1209                         Music *music = unsmob_music (ly_car (s));
1210                         Music *com = make_lyric_combine_music (name, music);
1211                         Music *csm = context_spec_music (context,
1212                                 get_next_unique_context (), com, SCM_EOL);
1213                         lst = scm_cons (csm->self_scm (), lst);
1214                 }
1215                 /* FIXME: only first lyric music is accepted,
1216                           the rest is junked */
1217                 all->set_property ("elements", scm_cons ($1->self_scm (),
1218                         lst));
1219                 $$ = all;
1220                 scm_gc_unprotect_object ($1->self_scm ());
1221         }
1222         | LYRICSTO string Music {
1223                 Music *music = $3;
1224                 SCM name = $2;
1225                 $$ = make_lyric_combine_music (name, music);
1226                 scm_gc_unprotect_object (music->self_scm ());
1227         }
1228         ;
1229
1230 context_change:
1231         CHANGE STRING '=' STRING  {
1232                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1233                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1234                 t-> set_property ("change-to-id", $4);
1235
1236                 $$ = t;
1237                 $$->set_spot (THIS->here_input ());
1238         }
1239         ;
1240
1241 property_operation:
1242         STRING '=' scalar {
1243                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1244                         scm_string_to_symbol ($1), $3);
1245         }
1246         | UNSET simple_string {
1247                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1248                         scm_string_to_symbol ($2));
1249         }
1250         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1251                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1252                         scm_string_to_symbol ($2), $3, $5);
1253         }
1254         | REVERT simple_string embedded_scm {
1255                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1256                         scm_string_to_symbol ($2), $3);
1257         }
1258         ;
1259
1260 context_def_mod:
1261         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1262         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1263         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1264
1265         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1266         | DENIES { $$ = ly_symbol2scm ("denies"); }
1267
1268         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1269         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1270         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1271         | NAME { $$ = ly_symbol2scm ("context-name"); }
1272         ;
1273
1274 context_mod:
1275         property_operation { $$ = $1; }
1276         | context_def_mod STRING {
1277                 $$ = scm_list_2 ($1, $2);
1278         }
1279         ;
1280
1281 context_prop_spec:
1282         simple_string {
1283                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1284                         scm_string_to_symbol ($1));
1285         }
1286         | simple_string '.' simple_string {
1287                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1288                         scm_string_to_symbol ($3));
1289         }
1290         ;
1291
1292 music_property_def:
1293         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1294                 $$ = property_op_to_music (scm_list_4 (
1295                         ly_symbol2scm ("poppush"),
1296                         ly_cadr ($2),
1297                         $3, $5));
1298                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1299         }
1300         | REVERT context_prop_spec embedded_scm {
1301                 $$ = property_op_to_music (scm_list_3 (
1302                         ly_symbol2scm ("pop"),
1303                         ly_cadr ($2),
1304                         $3));
1305
1306                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1307         }
1308         | SET context_prop_spec '=' scalar {
1309                 $$ = property_op_to_music (scm_list_3 (
1310                         ly_symbol2scm ("assign"),
1311                         ly_cadr ($2),
1312                         $4));
1313                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1314         }
1315         | UNSET context_prop_spec {
1316                 $$ = property_op_to_music (scm_list_2 (
1317                         ly_symbol2scm ("unset"),
1318                         ly_cadr ($2)));
1319                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1320         }
1321         | ONCE music_property_def {
1322                 SCM e = $2->get_property ("element");
1323                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1324                 $$ = $2;
1325
1326         }
1327         ;
1328
1329
1330 string:
1331         STRING {
1332                 $$ = $1;
1333         }
1334         | STRING_IDENTIFIER {
1335                 $$ = $1;
1336         }
1337         | string '+' string {
1338                 $$ = scm_string_append (scm_list_2 ($1, $3));
1339         }
1340         ;
1341
1342 simple_string: STRING {
1343         }
1344         | LYRICS_STRING {
1345         }
1346         ;
1347
1348 scalar: string {
1349         }
1350         | LYRICS_STRING {
1351         }
1352         | bare_int {
1353                 $$ = scm_int2num ($1);
1354         }
1355         | embedded_scm {
1356         }
1357         | full_markup {
1358         }
1359         | DIGIT {
1360                 $$ = scm_int2num ($1);
1361         }
1362         ;
1363
1364 /*
1365 FIXME: remove or fix this comment.  What is `This'?
1366
1367 This is a trick:
1368
1369 Adding pre_events to the simple_element
1370 makes the choice between
1371
1372   string:  STRING
1373
1374 and
1375
1376   simple_element: STRING
1377
1378 a single shift/reduction conflict.
1379
1380 nevertheless, this is not very clean, and we should find a different
1381 solution.
1382
1383 */
1384 pre_events: {
1385                 THIS->push_spot ();
1386         }
1387         ;
1388
1389 event_chord:
1390         pre_events simple_element post_events   {
1391                 SCM elts = $2-> get_property ("elements");
1392
1393                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1394
1395                 $2->set_property ("elements", elts);
1396                 $$ = $2;
1397         }
1398         | command_element
1399         | note_chord_element
1400         ;
1401
1402
1403 note_chord_element:
1404         chord_body optional_notemode_duration post_events
1405         {
1406                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1407                 SCM es = $1->get_property ("elements");
1408                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1409
1410                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1411                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1412                 es = ly_append2 (es, postevs);
1413
1414                 $1-> set_property ("elements", es);
1415                 $$ = $1;
1416         }
1417         ;
1418
1419 chord_open: '<'
1420         ;
1421
1422 chord_close: '>'
1423         ;
1424
1425 simul_open: DOUBLE_ANGLE_OPEN
1426         ;
1427
1428 simul_close: DOUBLE_ANGLE_CLOSE
1429         ;
1430
1431 chord_body:
1432         chord_open chord_body_elements chord_close
1433         {
1434                 $$ = MY_MAKE_MUSIC ("EventChord");
1435                 $$->set_property ("elements",
1436                         scm_reverse_x ($2, SCM_EOL));
1437         }
1438         ;
1439
1440 chord_body_elements:
1441         /* empty */             { $$ = SCM_EOL; }
1442         | chord_body_elements chord_body_element {
1443                 $$ = scm_cons ($2->self_scm (), $1);
1444                 scm_gc_unprotect_object ($2->self_scm ());
1445         }
1446         ;
1447
1448 chord_body_element:
1449         pitch exclamations questions post_events
1450         {
1451                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1452                 n->set_property ("pitch", $1);
1453                 if ($3 % 2)
1454                         n->set_property ("cautionary", SCM_BOOL_T);
1455                 if ($2 % 2 || $3 % 2)
1456                         n->set_property ("force-accidental", SCM_BOOL_T);
1457
1458                 if (ly_c_pair_p ($4)) {
1459                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1460                         n->set_property ("articulations", arts);
1461                 }
1462                 $$ = n;
1463         }
1464         | DRUM_PITCH post_events {
1465                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1466                 n->set_property ("duration", $2);
1467                 n->set_property ("drum-type", $1);
1468                 n->set_spot (THIS->here_input ());
1469
1470                 if (ly_c_pair_p ($2)) {
1471                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1472                         n->set_property ("articulations", arts);
1473                 }
1474                 $$ = n;
1475         }
1476         ;
1477
1478 add_quote:
1479         ADDQUOTE string Music {
1480                 SCM adder = ly_scheme_function ("add-quotable");
1481
1482                 scm_call_2 (adder, $2, $3->self_scm ());
1483                 scm_gc_unprotect_object ($3->self_scm ());
1484         }
1485         ;
1486
1487 command_element:
1488         command_req {
1489                 $$ = MY_MAKE_MUSIC ("EventChord");
1490                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1491                 scm_gc_unprotect_object ($1->self_scm ());
1492
1493                 $$-> set_spot (THIS->here_input ());
1494                 $1-> set_spot (THIS->here_input ());
1495         }
1496         | SKIP duration_length {
1497                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1498                 skip->set_property ("duration", $2);
1499
1500                 $$ = skip;
1501         }
1502         | QUOTE STRING duration_length {
1503                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1504                 SCM evs = SCM_EOL;
1505                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1506                 {
1507                         SCM key = $2; // use symbol?
1508                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1509                 }
1510                 Music *quote = 0;
1511                 if (ly_c_vector_p (evs))
1512                 {
1513                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1514                         quote->set_property ("duration", $3);
1515                         quote->set_property ("quoted-events", evs);
1516                 } else {
1517                         THIS->here_input ().warning (_f ("Can\'t find music"));
1518                         quote = MY_MAKE_MUSIC ("Event");
1519                 }
1520                 quote->set_spot (THIS->here_input ());
1521                 $$ = quote;
1522         }
1523         | OCTAVE { THIS->push_spot (); }
1524           pitch {
1525                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1526                 $$ = m;
1527                 $$->set_spot (THIS->pop_spot ());
1528                 $$->set_property ("pitch", $3);
1529         }
1530         | E_LEFTSQUARE {
1531                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1532                 m->set_property ("span-direction", scm_int2num (START));
1533                 m->set_spot (THIS->here_input ());
1534
1535                 $$ = MY_MAKE_MUSIC ("EventChord");
1536                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1537                 scm_gc_unprotect_object (m->self_scm ());
1538                 $$->set_spot (THIS->here_input ());
1539         }
1540         | E_RIGHTSQUARE {
1541                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1542                 m->set_property ("span-direction", scm_int2num (STOP));
1543                 m->set_spot (THIS->here_input ());
1544
1545                 $$ = MY_MAKE_MUSIC ("EventChord");
1546                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1547                 $$->set_spot (THIS->here_input ());
1548                 scm_gc_unprotect_object (m->self_scm ());
1549         }
1550         | E_BACKSLASH {
1551                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1552                 $$->set_spot (THIS->here_input ());
1553         }
1554         | '|'      {
1555                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1556
1557                 if (Music * m = unsmob_music (pipe))
1558                         $$ = m->clone ();
1559                 else
1560                         $$ = MY_MAKE_MUSIC ("BarCheck");
1561
1562                 $$->set_spot (THIS->here_input ());
1563         }
1564         | TRANSPOSITION pitch {
1565                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1566                                         $2);
1567                 $$->set_spot (THIS-> here_input ());
1568                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1569                         $$, SCM_EOL);
1570         }
1571         | BAR STRING                    {
1572                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1573
1574                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1575                                         t, SCM_EOL);
1576                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1577                 $$->set_spot (THIS->here_input ());
1578                 t->set_spot (THIS->here_input ());
1579         }
1580         | PARTIAL duration_length       {
1581                 Moment m = - unsmob_duration ($2)->get_length ();
1582                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1583                 p->set_spot (THIS->here_input ());
1584                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1585                                         p, SCM_EOL);
1586                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1587                                         p, SCM_EOL);
1588                 $$ = p;
1589         }
1590         | CLEF STRING  {
1591                 SCM proc = ly_scheme_function ("make-clef-set");
1592
1593                 SCM result = scm_call_1 (proc, $2);
1594                 scm_gc_protect_object (result);
1595                 $$ = unsmob_music (result);
1596         }
1597         | TIME_T fraction  {
1598                 SCM proc= ly_scheme_function ("make-time-signature-set");
1599
1600                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1601                 scm_gc_protect_object (result);
1602                 $$ = unsmob_music (result);
1603         }
1604         | MARK scalar {
1605                 SCM proc = ly_scheme_function ("make-mark-set");
1606
1607                 SCM result = scm_call_1 (proc, $2);
1608                 scm_gc_protect_object (result);
1609                 $$ = unsmob_music (result);
1610         }
1611         ;
1612
1613 command_req:
1614         BREATHE {
1615                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1616         }
1617         | E_TILDE {
1618                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1619         }
1620         | MARK DEFAULT  {
1621                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1622                 $$ = m;
1623         }
1624         | tempo_event {
1625                 $$ = $1;
1626         }
1627         | KEY DEFAULT {
1628                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1629                 $$ = key;
1630         }
1631         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1632
1633                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1634                 if (scm_ilength ($3) > 0)
1635                 {
1636                         key->set_property ("pitch-alist", $3);
1637                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1638                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1639                 } else {
1640                         THIS->parser_error (_ ("Second argument must be pitch list."));
1641                 }
1642
1643                 $$ = key;
1644         }
1645         ;
1646
1647 post_events:
1648         /* empty */ {
1649                 $$ = SCM_EOL;
1650         }
1651         | post_events post_event {
1652                 $2->set_spot (THIS->here_input ());
1653                 $$ = scm_cons ($2->self_scm (), $$);
1654                 scm_gc_unprotect_object ($2->self_scm ());
1655         }
1656         | post_events tagged_post_event {
1657                 $2 -> set_spot (THIS->here_input ());
1658                 $$ = scm_cons ($2->self_scm (), $$);
1659                 scm_gc_unprotect_object ($2->self_scm ());
1660         }
1661         ;
1662
1663
1664 tagged_post_event:
1665         '-' TAG embedded_scm post_event {
1666                 tag_music ($4, $3, THIS->here_input ());
1667                 $$ = $4;
1668         }
1669         ;
1670
1671 post_event:
1672         direction_less_event {
1673                 $$ = $1;
1674         }
1675         | HYPHEN {
1676                 if (!THIS->lexer_->is_lyric_state ())
1677                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1678                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1679         }
1680         | EXTENDER {
1681                 if (!THIS->lexer_->is_lyric_state ())
1682                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1683                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1684         }
1685         | script_dir direction_reqd_event {
1686                 if ($1)
1687                         $2->set_property ("direction", scm_int2num ($1));
1688                 $$ = $2;
1689         }
1690         | script_dir direction_less_event {
1691                 if ($1)
1692                         $2->set_property ("direction", scm_int2num ($1));
1693                 $$ = $2;
1694         }
1695         | string_number_event
1696         ;
1697
1698 string_number_event:
1699         E_UNSIGNED {
1700                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1701                 s->set_property ("string-number", scm_int2num ($1));
1702                 s->set_spot (THIS->here_input ());
1703                 $$ = s;
1704         }
1705         ;
1706
1707
1708 direction_less_event:
1709         '['  {
1710
1711
1712 /*
1713
1714 TODO: should take all these defs out of the parser, adn make use
1715 configurable, i.e.
1716
1717
1718 (set-articulation '~ "trill")
1719
1720 */
1721                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1722                 m->set_spot (THIS->here_input ());
1723                 m->set_property ("span-direction", scm_int2num (START));
1724                 $$ = m;
1725         }
1726         | ']'  {
1727                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1728                 m->set_spot (THIS->here_input ());
1729                 m->set_property ("span-direction", scm_int2num (STOP));
1730                 $$ = m;
1731         }
1732         | '~' {
1733                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1734                 m->set_spot (THIS->here_input ());
1735                 $$ = m;
1736         }
1737         | close_event {
1738                 $$ = $1;
1739                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1740                         scm_int2num (START));
1741         }
1742         | open_event {
1743                 $$ = $1;
1744                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1745                         scm_int2num (STOP));
1746         }
1747         | EVENT_IDENTIFIER      {
1748                 $$ = unsmob_music ($1);
1749         }
1750         | tremolo_type  {
1751                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1752                a->set_spot (THIS->here_input ());
1753                a->set_property ("tremolo-type", scm_int2num ($1));
1754                $$ = a;
1755         }
1756         ;
1757
1758 direction_reqd_event:
1759         gen_text_def {
1760                 $$ = $1;
1761         }
1762         | script_abbreviation {
1763                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1764                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1765                 if (ly_c_string_p (s))
1766                         a->set_property ("articulation-type", s);
1767                 else THIS->parser_error (_ ("Expecting string as script definition"));
1768                 $$ = a;
1769         }
1770         ;
1771
1772 oct_check:
1773         /**/ { $$ = SCM_EOL; }
1774         | '='  { $$ = scm_int2num (0); }
1775         | '=' sub_quotes { $$ = scm_int2num ($2); }
1776         | '=' sup_quotes { $$ = scm_int2num ($2); }
1777         ;
1778
1779 sup_quotes:
1780         '\'' {
1781                 $$ = 1;
1782         }
1783         | sup_quotes '\'' {
1784                 $$ ++;
1785         }
1786         ;
1787
1788 sub_quotes:
1789         ',' {
1790                 $$ = 1;
1791         }
1792         | sub_quotes ',' {
1793                 $$++;
1794         }
1795         ;
1796
1797 steno_pitch:
1798         NOTENAME_PITCH  {
1799                 $$ = $1;
1800         }
1801         | NOTENAME_PITCH sup_quotes     {
1802                 Pitch p = *unsmob_pitch ($1);
1803                 p = p.transposed (Pitch ($2,0,0));
1804                 $$ = p.smobbed_copy ();
1805         }
1806         | NOTENAME_PITCH sub_quotes      {
1807                 Pitch p =* unsmob_pitch ($1);
1808                 p = p.transposed (Pitch (-$2,0,0));
1809                 $$ = p.smobbed_copy ();
1810         }
1811         ;
1812
1813 /*
1814 ugh. duplication
1815 */
1816
1817 steno_tonic_pitch:
1818         TONICNAME_PITCH {
1819                 $$ = $1;
1820         }
1821         | TONICNAME_PITCH sup_quotes    {
1822                 Pitch p = *unsmob_pitch ($1);
1823                 p = p.transposed (Pitch ($2,0,0));
1824                 $$ = p.smobbed_copy ();
1825         }
1826         | TONICNAME_PITCH sub_quotes     {
1827                 Pitch p =* unsmob_pitch ($1);
1828
1829                 p = p.transposed (Pitch (-$2,0,0));
1830                 $$ = p.smobbed_copy ();
1831         }
1832         ;
1833
1834 pitch:
1835         steno_pitch {
1836                 $$ = $1;
1837         }
1838         ;
1839
1840 pitch_also_in_chords:
1841         pitch
1842         | steno_tonic_pitch
1843         ;
1844
1845 close_event:
1846         '('     {
1847                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1848                 $$ = s;
1849                 s->set_spot (THIS->here_input ());
1850         }
1851         | E_OPEN        {
1852                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1853                 $$ = s;
1854                 s->set_spot (THIS->here_input ());
1855         }
1856         | E_SMALLER {
1857                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1858                 $$ = s;
1859                 s->set_spot (THIS->here_input ());
1860         }
1861         | E_BIGGER {
1862                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1863                 $$ = s;
1864                 s->set_spot (THIS->here_input ());
1865         }
1866         ;
1867
1868
1869 open_event:
1870         E_EXCLAMATION   {
1871                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1872                 s->set_spot (THIS->here_input ());
1873
1874                 $$ = s;
1875         }
1876         | ')'   {
1877                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1878                 $$ = s;
1879                 s->set_spot (THIS->here_input ());
1880
1881         }
1882         | E_CLOSE       {
1883                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1884                 $$ = s;
1885                 s->set_property ("span-type",
1886                         scm_makfrom0str ("phrasing-slur"));
1887                 s->set_spot (THIS->here_input ());
1888         }
1889         ;
1890
1891 gen_text_def:
1892         full_markup {
1893                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1894                 t->set_property ("text", $1);
1895                 t->set_spot (THIS->here_input ());
1896                 $$ = t;
1897         }
1898         | string {
1899                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1900                 t->set_property ("text",
1901                         make_simple_markup (THIS->lexer_->encoding (), $1));
1902                 t->set_spot (THIS->here_input ());
1903                 $$ = t;
1904
1905         }
1906         | DIGIT {
1907                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1908                 t->set_property ("digit", scm_int2num ($1));
1909                 t->set_spot (THIS->here_input ());
1910                 $$ = t;
1911         }
1912         ;
1913
1914 script_abbreviation:
1915         '^'             {
1916                 $$ = scm_makfrom0str ("Hat");
1917         }
1918         | '+'           {
1919                 $$ = scm_makfrom0str ("Plus");
1920         }
1921         | '-'           {
1922                 $$ = scm_makfrom0str ("Dash");
1923         }
1924         | '|'           {
1925                 $$ = scm_makfrom0str ("Bar");
1926         }
1927         | '>'           {
1928                 $$ = scm_makfrom0str ("Larger");
1929         }
1930         | '.'           {
1931                 $$ = scm_makfrom0str ("Dot");
1932         }
1933         | '_' {
1934                 $$ = scm_makfrom0str ("Underscore");
1935         }
1936         ;
1937
1938 script_dir:
1939         '_'     { $$ = DOWN; }
1940         | '^'   { $$ = UP; }
1941         | '-'   { $$ = CENTER; }
1942         ;
1943
1944
1945 absolute_pitch:
1946         steno_pitch     {
1947                 $$ = $1;
1948         }
1949         ;
1950
1951 duration_length:
1952         multiplied_duration {
1953                 $$ = $1;
1954         }
1955         ;
1956
1957 optional_notemode_duration:
1958         {
1959                 Duration dd = THIS->default_duration_;
1960                 $$ = dd.smobbed_copy ();
1961
1962                 THIS->beam_check ($$);
1963         }
1964         | multiplied_duration   {
1965                 $$ = $1;
1966                 THIS->default_duration_ = *unsmob_duration ($$);
1967
1968                 THIS->beam_check ($$);
1969         }
1970         ;
1971
1972 steno_duration:
1973         bare_unsigned dots              {
1974                 int len = 0;
1975                 if (!is_duration ($1))
1976                         THIS->parser_error (_f ("not a duration: %d", $1));
1977                 else
1978                         len = intlog2 ($1);
1979
1980                 $$ = Duration (len, $2).smobbed_copy ();
1981         }
1982         | DURATION_IDENTIFIER dots      {
1983                 Duration *d = unsmob_duration ($1);
1984                 Duration k (d->duration_log (), d->dot_count () + $2);
1985                 *d = k;
1986                 $$ = $1;
1987         }
1988         ;
1989
1990 multiplied_duration:
1991         steno_duration {
1992                 $$ = $1;
1993         }
1994         | multiplied_duration '*' bare_unsigned {
1995                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1996         }
1997         | multiplied_duration '*' FRACTION {
1998                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
1999
2000                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2001         }
2002         ;
2003
2004 fraction:
2005         FRACTION { $$ = $1; }
2006         | UNSIGNED '/' UNSIGNED {
2007                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2008         }
2009         ;
2010
2011 dots:
2012         /* empty */     {
2013                 $$ = 0;
2014         }
2015         | dots '.' {
2016                 $$ ++;
2017         }
2018         ;
2019
2020 tremolo_type:
2021         ':'     {
2022                 $$ = 0;
2023         }
2024         | ':' bare_unsigned {
2025                 if (!is_duration ($2))
2026                         THIS->parser_error (_f ("not a duration: %d", $2));
2027                 $$ = $2;
2028         }
2029         ;
2030
2031 bass_number:
2032         DIGIT   {
2033                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2034         }
2035         | UNSIGNED {
2036                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2037         }
2038         | STRING { $$ = $1; }
2039         ;
2040
2041 bass_mod:
2042         '-'     { $$ = -2; }
2043         | '+'   { $$ = 2; }
2044         | '!'   { $$ = 0; }
2045         ;
2046
2047 bass_figure:
2048         FIGURE_SPACE {
2049                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2050                 $$ = bfr->self_scm ();
2051                 scm_gc_unprotect_object ($$);
2052         }
2053         | bass_number  {
2054                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2055                 $$ = bfr->self_scm ();
2056
2057                 bfr->set_property ("figure", $1);
2058
2059                 scm_gc_unprotect_object ($$);
2060         }
2061         | bass_figure bass_mod {
2062                 Music *m = unsmob_music ($1);
2063                 if ($2) {
2064                         SCM salter = m->get_property ("alteration");
2065                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2066                         m->set_property ("alteration",
2067                                 scm_int2num (alter + $2));
2068                 } else {
2069                         m->set_property ("alteration", scm_int2num (0));
2070                 }
2071         }
2072         ;
2073
2074 br_bass_figure:
2075         '[' bass_figure {
2076                 $$ = $2;
2077                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2078         }
2079         | bass_figure   {
2080                 $$ = $1;
2081         }
2082         | br_bass_figure ']' {
2083                 $$ = $1;
2084                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2085         }
2086         ;
2087
2088 figure_list:
2089         /**/            {
2090                 $$ = SCM_EOL;
2091         }
2092         | figure_list br_bass_figure {
2093                 $$ = scm_cons ($2, $1);
2094         }
2095         ;
2096
2097 figure_spec:
2098         FIGURE_OPEN figure_list FIGURE_CLOSE {
2099                 Music *m = MY_MAKE_MUSIC ("EventChord");
2100                 $2 = scm_reverse_x ($2, SCM_EOL);
2101                 m->set_property ("elements", $2);
2102                 $$ = m->self_scm ();
2103         }
2104         ;
2105
2106
2107 optional_rest:
2108         /**/   { $$ = 0; }
2109         | REST { $$ = 1; }
2110         ;
2111
2112 simple_element:
2113         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2114
2115                 Input i = THIS->pop_spot ();
2116                 if (!THIS->lexer_->is_note_state ())
2117                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2118
2119                 Music *n = 0;
2120                 if ($6)
2121                         n = MY_MAKE_MUSIC ("RestEvent");
2122                 else
2123                         n = MY_MAKE_MUSIC ("NoteEvent");
2124
2125                 n->set_property ("pitch", $1);
2126                 n->set_property ("duration", $5);
2127
2128                 if (ly_c_number_p ($4))
2129                 {
2130                         int q = ly_scm2int ($4);
2131                         n->set_property ("absolute-octave", scm_int2num (q-1));
2132                 }
2133
2134                 if ($3 % 2)
2135                         n->set_property ("cautionary", SCM_BOOL_T);
2136                 if ($2 % 2 || $3 % 2)
2137                         n->set_property ("force-accidental", SCM_BOOL_T);
2138
2139                 Music *v = MY_MAKE_MUSIC ("EventChord");
2140                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2141                 scm_gc_unprotect_object (n->self_scm ());
2142
2143                 v->set_spot (i);
2144                 n->set_spot (i);
2145                 $$ = v;
2146         }
2147         | DRUM_PITCH optional_notemode_duration {
2148                 Input i = THIS->pop_spot ();
2149
2150                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2151                 n->set_property ("duration", $2);
2152                 n->set_property ("drum-type", $1);
2153
2154                 Music *v = MY_MAKE_MUSIC ("EventChord");
2155                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2156                 scm_gc_unprotect_object (n->self_scm ());
2157                 v->set_spot (i);
2158                 n->set_spot (i);
2159                 $$ = v;
2160
2161         }
2162         | figure_spec optional_notemode_duration {
2163                 Music *m = unsmob_music ($1);
2164                 Input i = THIS->pop_spot ();
2165                 m->set_spot (i);
2166                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2167                 {
2168                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2169                 }
2170                 $$ = m;
2171         }
2172         | RESTNAME optional_notemode_duration           {
2173
2174                 Input i = THIS->pop_spot ();
2175                 Music *ev = 0;
2176                 if (ly_scm2string ($1) == "s") {
2177                         /* Space */
2178                         ev = MY_MAKE_MUSIC ("SkipEvent");
2179                   }
2180                 else {
2181                         ev = MY_MAKE_MUSIC ("RestEvent");
2182
2183                     }
2184                 ev->set_property ("duration", $2);
2185                 ev->set_spot (i);
2186                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2187                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2188                 velt->set_spot (i);
2189
2190                 scm_gc_unprotect_object (ev->self_scm ());
2191
2192                 $$ = velt;
2193         }
2194         | MULTI_MEASURE_REST optional_notemode_duration         {
2195                 THIS->pop_spot ();
2196
2197                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2198                 SCM mus = scm_call_2 (proc, $2,
2199                         make_input (THIS->here_input ()));
2200                 scm_gc_protect_object (mus);
2201                 $$ = unsmob_music (mus);
2202         }
2203
2204         | lyric_element optional_notemode_duration      {
2205                 Input i = THIS->pop_spot ();
2206                 if (!THIS->lexer_->is_lyric_state ())
2207                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2208
2209                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2210                 lreq->set_property ("text", $1);
2211                 lreq->set_property ("duration",$2);
2212                 lreq->set_spot (i);
2213                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2214                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2215
2216                 $$= velt;
2217         }
2218         | new_chord {
2219                 THIS->pop_spot ();
2220
2221                 if (!THIS->lexer_->is_chord_state ())
2222                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2223                 $$ = unsmob_music ($1);
2224         }
2225         ;
2226
2227 lyric_element:
2228         /* FIXME: lyric flavoured markup would be better */
2229         full_markup {
2230         }
2231         | LYRICS_STRING {
2232         }
2233         ;
2234
2235 new_chord:
2236         steno_tonic_pitch optional_notemode_duration   {
2237                 $$ = make_chord ($1, $2, SCM_EOL);
2238         }
2239         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2240                 SCM its = scm_reverse_x ($4, SCM_EOL);
2241                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2242         }
2243         ;
2244
2245 chord_items:
2246         /**/ {
2247                 $$ = SCM_EOL;
2248         }
2249         | chord_items chord_item {
2250                 $$ = scm_cons ($2, $$);
2251         }
2252         ;
2253
2254 chord_separator:
2255         CHORD_COLON {
2256                 $$ = ly_symbol2scm ("chord-colon");
2257         }
2258         | CHORD_CARET {
2259                 $$ = ly_symbol2scm ("chord-caret");
2260         }
2261         | CHORD_SLASH steno_tonic_pitch {
2262                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2263         }
2264         | CHORD_BASS steno_tonic_pitch {
2265                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2266         }
2267         ;
2268
2269 chord_item:
2270         chord_separator {
2271                 $$ = $1;
2272         }
2273         | step_numbers {
2274                 $$ = scm_reverse_x ($1, SCM_EOL);
2275         }
2276         | CHORD_MODIFIER  {
2277                 $$ = $1;
2278         }
2279         ;
2280
2281 step_numbers:
2282         step_number { $$ = scm_cons ($1, SCM_EOL); }
2283         | step_numbers '.' step_number {
2284                 $$ = scm_cons ($3, $$);
2285         }
2286         ;
2287
2288 step_number:
2289         bare_unsigned {
2290                 $$ = make_chord_step ($1, 0);
2291         }
2292         | bare_unsigned '+' {
2293                 $$ = make_chord_step ($1, SHARP);
2294         }
2295         | bare_unsigned CHORD_MINUS {
2296                 $$ = make_chord_step ($1, FLAT);
2297         }
2298         ;
2299
2300 /*
2301         UTILITIES
2302
2303 TODO: should deprecate in favor of Scheme?
2304
2305  */
2306 number_expression:
2307         number_expression '+' number_term {
2308                 $$ = scm_sum ($1, $3);
2309         }
2310         | number_expression '-' number_term {
2311                 $$ = scm_difference ($1, $3);
2312         }
2313         | number_term
2314         ;
2315
2316 number_term:
2317         number_factor {
2318                 $$ = $1;
2319         }
2320         | number_factor '*' number_factor {
2321                 $$ = scm_product ($1, $3);
2322         }
2323         | number_factor '/' number_factor {
2324                 $$ = scm_divide ($1, $3);
2325         }
2326         ;
2327
2328 number_factor:
2329         '-'  number_factor { /* %prec UNARY_MINUS */
2330                 $$ = scm_difference ($2, SCM_UNDEFINED);
2331         }
2332         | bare_number
2333         ;
2334
2335
2336 bare_number:
2337         UNSIGNED        {
2338                 $$ = scm_int2num ($1);
2339         }
2340         | REAL          {
2341                 $$ = $1;
2342         }
2343         | NUMBER_IDENTIFIER             {
2344                 $$ = $1;
2345         }
2346         | REAL NUMBER_IDENTIFIER        {
2347                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2348         }
2349         | UNSIGNED NUMBER_IDENTIFIER    {
2350                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2351         }
2352         ;
2353
2354
2355 bare_unsigned:
2356         UNSIGNED {
2357                         $$ = $1;
2358         }
2359         | DIGIT {
2360                 $$ = $1;
2361         }
2362         ;
2363
2364 bare_int:
2365         bare_number {
2366                 if (scm_integer_p ($1) == SCM_BOOL_T)
2367                 {
2368                         int k = ly_scm2int ($1);
2369                         $$ = k;
2370                 } else
2371                 {
2372                         THIS->parser_error (_ ("need integer number arg"));
2373                         $$ = 0;
2374                 }
2375         }
2376         | '-' bare_int {
2377                 $$ = -$2;
2378         }
2379         ;
2380
2381 exclamations:
2382                 { $$ = 0; }
2383         | exclamations '!'      { $$ ++; }
2384         ;
2385
2386 questions:
2387                 { $$ = 0; }
2388         | questions '?' { $$ ++; }
2389         ;
2390
2391
2392
2393 full_markup:
2394         MARKUP_IDENTIFIER {
2395                 $$ = $1;
2396         }
2397         | MARKUP
2398                 { THIS->lexer_->push_markup_state (); }
2399         markup
2400                 { $$ = $3;
2401                   THIS->lexer_->pop_state ();
2402                 }
2403         ;
2404
2405
2406 /*
2407 This should be done more dynamically if possible.
2408 */
2409 markup:
2410         STRING {
2411                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2412         }
2413         | MARKUP_HEAD_EMPTY {
2414                 $$ = scm_list_1 ($1);
2415         }
2416         | MARKUP_HEAD_MARKUP0 markup {
2417                 $$ = scm_list_2 ($1, $2);
2418         }
2419         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2420                 $$ = scm_list_3 ($1, $2, $3);
2421         }
2422         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2423                 $$ = scm_list_3 ($1, $2, $3);
2424         }
2425         | markup_line {
2426                 $$ = $1;
2427         }
2428         | MARKUP_HEAD_LIST0 markup_list {
2429                 $$ = scm_list_2 ($1,$2);
2430         }
2431         | MARKUP_HEAD_SCM0 embedded_scm {
2432                 $$ = scm_list_2 ($1, $2);
2433         }
2434         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2435                 $$ = scm_list_4 ($1, $2, $3, $4);
2436         }
2437         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2438                 $$ = scm_list_4 ($1, $2, $3, $4);
2439         }
2440         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2441                 $$ = scm_list_3 ($1, $2, $3);
2442         }
2443         | MARKUP_IDENTIFIER {
2444                 $$ = $1;
2445         }
2446         | STRING_IDENTIFIER {
2447                 $$ = $1;
2448         }
2449         ;
2450
2451 markup_list:
2452         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2453         ;
2454
2455 markup_line:
2456         '{' markup_list_body '}' {
2457                 SCM line = ly_scheme_function ("line-markup");
2458
2459                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2460         }
2461         ;
2462
2463 markup_list_body:
2464         /**/ {  $$ = SCM_EOL; }
2465         | markup_list_body markup {
2466                 $$ = scm_cons ($2, $1);
2467         }
2468         ;
2469
2470
2471 %%
2472
2473 void
2474 My_lily_parser::set_yydebug (bool )
2475 {
2476 #if 0
2477         yydebug = 1;
2478 #endif
2479 }
2480
2481 void
2482 My_lily_parser::do_yyparse ()
2483 {
2484         yyparse ((void*)this);
2485 }
2486
2487
2488 /*
2489 Should make this optional?    It will also complain when you do
2490
2491         [s4]
2492
2493 which is entirely legitimate.
2494
2495 Or we can scrap it. Barchecks should detect wrong durations, and
2496 skipTypesetting speeds it up a lot.
2497 */
2498
2499 void
2500 My_lily_parser::beam_check (SCM dur)
2501 {
2502   Duration *d = unsmob_duration (dur);
2503   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2504     {
2505       Music *m = unsmob_music (last_beam_start_);
2506       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2507     }
2508   last_beam_start_ = SCM_EOL;
2509 }
2510
2511
2512
2513
2514 /*
2515
2516 It is a little strange to have this function in this file, but
2517 otherwise, we have to import music classes into the lexer.
2518
2519 */
2520 int
2521 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2522 {
2523         if (ly_c_string_p (sid)) {
2524                 *destination = sid;
2525                 return STRING_IDENTIFIER;
2526         } else if (ly_c_number_p (sid)) {
2527                 *destination = sid;
2528                 return NUMBER_IDENTIFIER;
2529         } else if (unsmob_context_def (sid)) {
2530                 *destination = unsmob_context_def (sid)->clone_scm ();
2531                 return CONTEXT_DEF_IDENTIFIER;
2532         } else if (unsmob_score (sid)) {
2533                 Score *score = new Score (*unsmob_score (sid));
2534                 *destination = score->self_scm ();
2535                 return SCORE_IDENTIFIER;
2536         } else if (Music *mus = unsmob_music (sid)) {
2537                 mus = mus->clone ();
2538                 *destination = mus->self_scm ();
2539                 unsmob_music (*destination)->
2540                         set_property ("origin", make_input (last_input_));
2541                 return dynamic_cast<Event*> (mus)
2542                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2543         } else if (unsmob_duration (sid)) {
2544                 *destination = unsmob_duration (sid)->smobbed_copy ();
2545                 return DURATION_IDENTIFIER;
2546         } else if (unsmob_music_output_def (sid)) {
2547                 Music_output_def *p = unsmob_music_output_def (sid);
2548                 p = p->clone ();
2549
2550                 *destination = p->self_scm ();
2551                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2552         } else if (Text_item::markup_p (sid)) {
2553                 *destination = sid;
2554                 return MARKUP_IDENTIFIER;
2555         }
2556
2557         return -1;
2558 }
2559
2560 Music *
2561 property_op_to_music (SCM op)
2562 {
2563         Music *m = 0;
2564         SCM tag = ly_car (op);
2565         SCM symbol = ly_cadr (op);
2566         SCM args = ly_cddr (op);
2567         SCM grob_val = SCM_UNDEFINED;
2568         SCM grob_sym = SCM_UNDEFINED;
2569         SCM val = SCM_UNDEFINED;
2570
2571         if (tag == ly_symbol2scm ("assign"))
2572                 {
2573                 m = MY_MAKE_MUSIC ("PropertySet");
2574                 val = ly_car (args);
2575                 }
2576         else if (tag == ly_symbol2scm ("unset"))
2577                 m = MY_MAKE_MUSIC ("PropertyUnset");
2578         else if (tag == ly_symbol2scm ("poppush")
2579                  || tag == ly_symbol2scm ("push"))
2580                 {
2581                 m = MY_MAKE_MUSIC ("OverrideProperty");
2582                 grob_sym = ly_car (args);
2583                 grob_val = ly_cadr (args);
2584                 }
2585         else if (tag == ly_symbol2scm ("pop")) {
2586                 m = MY_MAKE_MUSIC ("RevertProperty");
2587                 grob_sym = ly_car (args);
2588                 }
2589
2590         m->set_property ("symbol", symbol);
2591
2592         if (val != SCM_UNDEFINED)
2593                 m->set_property ("value", val);
2594         if (grob_val != SCM_UNDEFINED)
2595                 m->set_property ("grob-value", grob_val);
2596
2597         if (grob_sym != SCM_UNDEFINED)
2598                 {
2599                 bool itc = internal_type_checking_global_b;
2600                 /* UGH.
2601                 */
2602                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2603                 if (autobeam)
2604                         internal_type_checking_global_b = false;
2605                 m->set_property ("grob-property", grob_sym);
2606                 if (autobeam)
2607                         internal_type_checking_global_b = itc;
2608                 }
2609
2610         if (op == ly_symbol2scm ("poppush"))
2611                 m->set_property ("pop-first", SCM_BOOL_T);
2612
2613
2614         return m;
2615 }
2616
2617 Music*
2618 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2619 {
2620         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2621
2622         csm->set_property ("element", m->self_scm ());
2623         scm_gc_unprotect_object (m->self_scm ());
2624
2625         csm->set_property ("context-type",
2626                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2627         csm->set_property ("property-operations", ops);
2628
2629         if (ly_c_string_p (id))
2630                 csm->set_property ("context-id", id);
2631         return csm;
2632 }
2633
2634 SCM
2635 get_next_unique_context ()
2636 {
2637         static int new_context_count;
2638         char s[1024];
2639         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2640         return scm_makfrom0str (s);
2641 }
2642