lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "translator-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token PARTIAL
 287 %token PITCHNAMES
 288 %token PROPERTY
 289 %token RELATIVE
 290 %token REMOVE
 291 %token REPEAT
 292 %token REST
 293 %token SCM_T
 294 %token SCORE
 295 %token SEQUENTIAL
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSLATOR
 304 %token TRANSPOSE
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 311 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 312 %token E_BACKSLASH
 313 %token <i> E_UNSIGNED
 314 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 315 %token FIGURE_SPACE
 316
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token <scm>    CHORDNAMES
 332 %token <scm>    CHORD_MODIFIER
 333 %token <scm>    SCORE_IDENTIFIER
 334 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    RESTNAME
 340 %token <scm>    STRING
 341 %token <scm>    SCM_T
 342 %token <i>      UNSIGNED
 343 %token <scm>   REAL
 344
 345 %token MARKUP
 346 %token <scm> MARKUP_HEAD_MARKUP0
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0
 350 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 357
 358 %type <outputdef> output_def
 359 %type <scm>     lilypond_header lilypond_header_body
 360 %type <music>   open_event close_event
 361 %type <i>       sub_quotes sup_quotes
 362 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 363 %type <music>   Repeated_music
 364 %type <scm>     Alternative_music
 365 %type <i>       tremolo_type
 366 %type <i>       bare_int  bare_unsigned
 367 %type <i>       script_dir
 368 %type <scm>     identifier_init
 369
 370 %type <music> note_chord_element chord_body chord_body_element
 371 %type <scm>  chord_body_elements
 372 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 373
 374 %type <scm>   post_events
 375 %type <music> gen_text_def direction_less_event direction_reqd_event
 376 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 377 %type <scm>    steno_tonic_pitch
 378 %type <scm>     duration_length fraction
 379
 380 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 381
 382 %type <scm>  embedded_scm scalar
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   relative_music re_rhythmed_music part_combined_music
 385 %type <music>   music_property_def context_change
 386 %type <scm> Music_list
 387 %type <scm> property_operation context_mod translator_mod optional_context_mod
 388 %type <outputdef>  music_output_def_body music_output_def_head
 389 %type <music> shorthand_command_req
 390 %type <music>   post_event tagged_post_event
 391 %type <music> command_req verbose_command_req
 392 %type <music> hyphen_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     translator_spec_block translator_spec_body
 398 %type <music>   tempo_event
 399 %type <scm> notenames_body notenames_block chordmodifiers_block
 400 %type <scm>     script_abbreviation
 401
 402
 403
 404 %left '-' '+'
 405
 406 /* We don't assign precedence to / and *, because we might need varied
 407 prec levels in different prods */
 408
 409 %left UNARY_MINUS
 410
 411 %%
 412
 413 lilypond:       /* empty */
 414         | lilypond toplevel_expression {}
 415         | lilypond assignment  { }
 416         | lilypond error {
 417                 THIS->error_level_  = 1;
 418         }
 419         | lilypond INVALID      {
 420                 THIS->error_level_  = 1;
 421         }
 422         ;
 423
 424 toplevel_expression:
 425         notenames_block                 {
 426                 THIS->lexer_->pitchname_tab_ =  $1;
 427         }
 428         | chordmodifiers_block                  {
 429                 THIS->lexer_->chordmodifier_tab_  = $1;
 430         }
 431         | lilypond_header {
 432                 THIS->input_file_->header_ = $1;
 433         }
 434         | score_block {
 435                 Score * sc = $1;
 436
 437                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 438
 439                 Path p = split_path (THIS->output_basename_);
 440                 int *c =  &THIS->input_file_->score_count_;
 441                 if (*c)
 442                         {
 443                         p.base += "-" + to_string (*c);
 444                         }
 445
 446                 (*c)++;
 447                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 448
 449                 for (int i=0; i < sc->defs_.size (); i++)
 450                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 451
 452                 if (sc->defs_.empty ())
 453                 {
 454                    Music_output_def *id =
 455                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 456                                 ("$defaultpaper"));
 457
 458                    id = id ? id->clone () : new Paper_def;
 459
 460                    default_rendering (sc->music_, id->self_scm(), head, outname);
 461
 462                    scm_gc_unprotect_object (id->self_scm ());
 463                 }
 464                 scm_gc_unprotect_object (sc->self_scm());
 465         }
 466         | output_def {
 467                 if (dynamic_cast<Paper_def*> ($1))
 468                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 469                 else if (dynamic_cast<Midi_def*> ($1))
 470                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 471         }
 472         ;
 473
 474 embedded_scm:
 475         SCM_T
 476         | SCM_IDENTIFIER
 477         ;
 478
 479
 480 chordmodifiers_block:
 481         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 482         ;
 483
 484 notenames_block:
 485         PITCHNAMES notenames_body   {  $$ = $2; }
 486         ;
 487
 488 notenames_body:
 489         embedded_scm    {
 490           int i = scm_ilength ($1);
 491
 492           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 493           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 494                 SCM pt = ly_cdar (s);
 495                 scm_hashq_set_x (tab, ly_caar (s), pt);
 496           }
 497           $$ = tab;
 498         }
 499         ;
 500
 501 lilypond_header_body:
 502         {
 503                 $$ = ly_make_anonymous_module ();
 504                 THIS->lexer_->add_scope ($$);
 505         }
 506         | lilypond_header_body assignment  {
 507
 508         }
 509         ;
 510
 511 lilypond_header:
 512         HEADER '{' lilypond_header_body '}'     {
 513                 $$ = THIS->lexer_-> remove_scope();
 514         }
 515         ;
 516
 517
 518 /*
 519         DECLARATIONS
 520 */
 521 assignment:
 522         STRING {
 523                 THIS->push_spot ();
 524         }
 525         /* cont */ '=' identifier_init  {
 526
 527         /*
 528                 Should find generic way of associating input with objects.
 529         */
 530                 Input ip = THIS->pop_spot ();
 531
 532                 if (! regular_identifier_b ($1))
 533                 {
 534                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $4);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551
 552 identifier_init:
 553         score_block {
 554                 $$ = $1->self_scm ();
 555                 scm_gc_unprotect_object ($$);
 556         }
 557         | full_markup {
 558                 $$ = $1;
 559         }
 560         | output_def {
 561                 $$ = $1->self_scm ();
 562                 scm_gc_unprotect_object ($$);
 563         }
 564         | translator_spec_block {
 565                 $$ = $1;
 566         }
 567         | Music  {
 568                 $$ = $1->self_scm ();
 569                 scm_gc_unprotect_object ($$);
 570         }
 571         | post_event {
 572                 $$ = $1->self_scm ();
 573                 scm_gc_unprotect_object ($$);
 574         }
 575         | number_expression {
 576                 $$ = $1;
 577         }
 578         | string {
 579                 $$ = $1;
 580         }
 581         | embedded_scm  {
 582                 $$ = $1;
 583         }
 584         ;
 585
 586 translator_spec_block:
 587         TRANSLATOR '{' translator_spec_body '}'
 588                 {
 589                 $$ = $3;
 590         }
 591         ;
 592
 593 translator_spec_body:
 594         /**/ {
 595                 $$ = Context_def::make_scm ();
 596                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 597         }
 598         | TRANSLATOR_IDENTIFIER {
 599                 $$ = $1;
 600                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 601         }
 602         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 603                 Context_def*td = unsmob_context_def($$);
 604
 605                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 606                         SCM tag = gh_caar (p);
 607                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 608                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 609                 }
 610         }
 611         | translator_spec_body context_mod {
 612                 unsmob_context_def ($$)->add_context_mod ($2);
 613         }
 614         ;
 615
 616 /*
 617         SCORE
 618 */
 619 score_block:
 620         SCORE {
 621                 THIS->push_spot ();
 622         }
 623         /*cont*/ '{' score_body '}'     {
 624                 THIS->pop_spot ();
 625                 $$ = $4;
 626
 627         }
 628         ;
 629
 630 score_body:
 631         Music   {
 632                 $$ = new Score;
 633
 634                 $$->set_spot (THIS->here_input ());
 635                 SCM m = $1->self_scm ();
 636                 scm_gc_unprotect_object (m);
 637
 638                 /*
 639                         guh.
 640                 */
 641                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 642                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 643                         m = gh_call1 (gh_car (check_funcs), m);
 644                 $$->music_ = m;
 645
 646         }
 647         | SCORE_IDENTIFIER {
 648                 $$ = unsmob_score ($1);
 649                 $$->set_spot (THIS->here_input ());
 650         }
 651         | score_body lilypond_header    {
 652                 $$->header_ = $2;
 653         }
 654         | score_body output_def {
 655                 $$->defs_.push ($2);
 656         }
 657         | score_body error {
 658
 659         }
 660         ;
 661
 662
 663 /*
 664         MIDI
 665 */
 666 output_def:
 667         music_output_def_body '}' {
 668                 $$ = $1;
 669                 THIS-> lexer_-> remove_scope ();
 670         }
 671         ;
 672
 673 music_output_def_head:
 674         MIDI    {
 675                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 676
 677
 678                 Midi_def* p =0;
 679                 if (id)
 680                         p = dynamic_cast<Midi_def*> (id->clone ());
 681                 else
 682                         p = new Midi_def;
 683
 684                 $$ = p;
 685                 THIS->lexer_->add_scope (p->scope_);
 686         }
 687         | PAPER         {
 688                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 689                   Paper_def *p = 0;
 690                 if (id)
 691                         p = dynamic_cast<Paper_def*> (id->clone ());
 692                 else
 693                         p = new Paper_def;
 694
 695                 THIS->lexer_->add_scope (p->scope_);
 696                 $$ = p;
 697         }
 698         ;
 699
 700
 701 music_output_def_body:
 702         music_output_def_head '{' {
 703
 704         }
 705         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 706                 Music_output_def * o =  unsmob_music_output_def ($3);
 707                 $$ = o;
 708                 THIS->lexer_->remove_scope ();
 709                 THIS->lexer_->add_scope (o->scope_);
 710         }
 711         | music_output_def_body assignment  {
 712
 713         }
 714         | music_output_def_body translator_spec_block   {
 715                 $$->assign_translator ($2);
 716         }
 717         | music_output_def_body tempo_event  {
 718                 /*
 719                         junk this ? there already is tempo stuff in
 720                         music.
 721                 */
 722                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 723                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 724                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 725                 if (md)
 726                         md->set_tempo (d->get_length (), m);
 727         }
 728         | music_output_def_body error {
 729
 730         }
 731         ;
 732
 733 tempo_event:
 734         TEMPO steno_duration '=' bare_unsigned  {
 735                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 736                 $$->set_mus_property ("tempo-unit", $2);
 737                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 738         }
 739         ;
 740
 741 /*
 742 The representation of a  list is the
 743
 744   (LIST . LAST-CONS)
 745
 746  to have  efficient append.
 747 */
 748 Music_list:
 749         /* empty */ {
 750                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 751         }
 752         | Music_list Music {
 753                 SCM s = $$;
 754                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 755                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 756                 if (gh_pair_p (ly_cdr (s)))
 757                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 758                 else
 759                         gh_set_car_x (s, c); /* set first cons */
 760                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 761         }
 762         | Music_list error {
 763         }
 764         ;
 765
 766
 767 Music:
 768         Simple_music
 769         | Composite_music
 770         ;
 771
 772 Alternative_music:
 773         /* empty */ {
 774                 $$ = SCM_EOL;
 775         }
 776         | ALTERNATIVE '{' Music_list '}' {
 777                 $$ = $3;
 778         }
 779         ;
 780
 781 Repeated_music:
 782         REPEAT string bare_unsigned Music Alternative_music
 783         {
 784                 Music *beg = $4;
 785                 int times = $3;
 786                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 787                 if (times < scm_ilength (alts)) {
 788                   unsmob_music (gh_car (alts))
 789                     ->origin ()->warning (
 790                     _("More alternatives than repeats.  Junking excess alternatives."));
 791                   alts = ly_truncate_list (times, alts);
 792                 }
 793
 794
 795                 static SCM proc;
 796                 if (!proc)
 797                         proc = scm_c_eval_string ("make-repeated-music");
 798
 799                 SCM mus = scm_call_1 (proc, $2);
 800                 scm_gc_protect_object (mus); // UGH.
 801                 Music *r =unsmob_music (mus);
 802                 if (beg)
 803                         {
 804                         r-> set_mus_property ("element", beg->self_scm ());
 805                         scm_gc_unprotect_object (beg->self_scm ());
 806                         }
 807                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 808
 809                 r-> set_mus_property ("elements",alts);
 810                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 811                         /*
 812                         we can not get durations and other stuff correct down the line, so we have to
 813                         add to the duration log here.
 814                         */
 815                         static SCM func;
 816
 817                         if (!func)
 818                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 819
 820                         int dots = ($3 % 3) ? 0 : 1;
 821                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 822
 823                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 824
 825                         if (seq) {
 826                                 int list_len =scm_ilength (seq->music_list ());
 827                                 if (list_len != 2)
 828                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 829                                 shift -= 1;
 830                                 r->compress (Moment (Rational (1,list_len)));
 831                                 }
 832                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 833
 834                 }
 835                 r->set_spot (*$4->origin ());
 836
 837                 $$ = r;
 838         }
 839         ;
 840
 841 Sequential_music:
 842         SEQUENTIAL '{' Music_list '}'           {
 843                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 844                 $$->set_mus_property ("elements", ly_car ($3));
 845                 $$->set_spot(THIS->here_input());
 846         }
 847         | '{' Music_list '}'            {
 848                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 849                 $$->set_mus_property ("elements", ly_car ($2));
 850                 $$->set_spot(THIS->here_input());
 851         }
 852         ;
 853
 854 Simultaneous_music:
 855         SIMULTANEOUS '{' Music_list '}'{
 856                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 857                 $$->set_mus_property ("elements", ly_car ($3));
 858                 $$->set_spot(THIS->here_input());
 859
 860         }
 861         | simul_open Music_list simul_close     {
 862                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 863                 $$->set_mus_property ("elements", ly_car ($2));
 864                 $$->set_spot(THIS->here_input());
 865         }
 866         ;
 867
 868 Simple_music:
 869         event_chord             { $$ = $1; }
 870         | APPLYOUTPUT embedded_scm {
 871                 if (!ly_input_procedure_p ($2))
 872                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 873                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 874                 $$->set_mus_property ("procedure", $2);
 875                 $$->set_spot (THIS->here_input());
 876         }
 877         | APPLYCONTEXT embedded_scm {
 878                 if (!ly_input_procedure_p ($2))
 879                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 880                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 881                 $$->set_mus_property ("procedure", $2);
 882                 $$->set_spot (THIS->here_input());
 883         }
 884         | MUSIC_IDENTIFIER {
 885                 $$ = unsmob_music ($1);
 886         }
 887         | music_property_def
 888         | context_change
 889         ;
 890
 891
 892 optional_context_mod:
 893         /**/ { $$ = SCM_EOL; }
 894         | WITH '{' context_mod_list '}'  { $$ = $3; }
 895         ;
 896
 897 grace_head:
 898         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 899         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 900         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 901         ;
 902
 903 context_mod_list:
 904         /* */  { $$ = SCM_EOL; }
 905         | context_mod_list context_mod  {
 906                  $$ = gh_cons ($2, $1);
 907         }
 908         ;
 909
 910 Composite_music:
 911         AUTOCHANGE STRING Music {
 912                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 913                 chm->set_mus_property ("element", $3->self_scm ());
 914                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 915
 916                 scm_gc_unprotect_object ($3->self_scm ());
 917                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 918
 919                 $$ = chm;
 920                 chm->set_spot (*$3->origin ());
 921         }
 922         | grace_head Music {
 923 #if 1
 924         /*
 925                 The other version is for easier debugging  of
 926                 Sequential_music_iterator in combination with grace notes.
 927         */
 928
 929 /*
 930
 931 TODO: should distinguish between both grace types in the
 932 basic music objects too, since the meaning is different.
 933
 934 */
 935
 936                 String start_str = "start" + ly_scm2string ($1) + "Music";
 937                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 938
 939                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 940                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 941
 942                 Music *startm = unsmob_music (start);
 943                 Music *stopm = unsmob_music (stop);
 944
 945                 SCM ms = SCM_EOL;
 946                 if (stopm) {
 947                         stopm = stopm->clone ();
 948                         ms = scm_cons (stopm->self_scm (), ms);
 949                         scm_gc_unprotect_object (stopm->self_scm ());
 950                 }
 951                 ms = scm_cons ($2->self_scm (), ms);
 952                 scm_gc_unprotect_object ($2->self_scm());
 953                 if (startm) {
 954                         startm = startm->clone ();
 955                         ms = scm_cons (startm->self_scm () , ms);
 956                         scm_gc_unprotect_object (startm->self_scm ());
 957                 }
 958
 959
 960                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 961                 seq->set_mus_property ("elements", ms);
 962
 963
 964                 $$ = MY_MAKE_MUSIC("GraceMusic");
 965                 $$->set_mus_property ("element", seq->self_scm ());
 966                 scm_gc_unprotect_object (seq->self_scm ());
 967 #else
 968                 $$ = MY_MAKE_MUSIC("GraceMusic");
 969                 $$->set_mus_property ("element", $2->self_scm ());
 970                 scm_gc_unprotect_object ($2->self_scm ());
 971 #endif
 972         }
 973         | CONTEXT string '=' string optional_context_mod Music {
 974                 $$ = context_spec_music ($2, $4, $6, $5);
 975
 976         }
 977         | CONTEXT STRING optional_context_mod Music {
 978                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 979         }
 980         | NEWCONTEXT string optional_context_mod Music {
 981                 $$ = context_spec_music ($2, get_next_unique_context (),
 982                                          $4, $3);
 983         }
 984
 985         | TIMES {
 986                 THIS->push_spot ();
 987         }
 988         /* CONTINUED */
 989                 fraction Music
 990
 991         {
 992                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 993                 Music *mp = $4;
 994
 995                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 996                 $$->set_spot (THIS->pop_spot ());
 997
 998                 $$->set_mus_property ("element", mp->self_scm ());
 999                 scm_gc_unprotect_object (mp->self_scm ());
1000                 $$->set_mus_property ("numerator", gh_int2scm (n));
1001                 $$->set_mus_property ("denominator", gh_int2scm (d));
1002                 $$->compress (Moment (Rational (n,d)));
1003
1004         }
1005         | Repeated_music                { $$ = $1; }
1006         | Simultaneous_music            { $$ = $1; }
1007         | Sequential_music              { $$ = $1; }
1008         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1009                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1010                 Music *p = $4;
1011                 Pitch from = *unsmob_pitch ($2);
1012                 Pitch to = *unsmob_pitch ($3);
1013
1014                 p->transpose (interval (from, to));
1015                 $$->set_mus_property ("element", p->self_scm ());
1016                 scm_gc_unprotect_object (p->self_scm ());
1017         }
1018         | APPLY embedded_scm Music  {
1019                 if (!ly_input_procedure_p ($2))
1020                         {
1021                         THIS->parser_error (_ ("\\apply takes function argument"));
1022                         $$ = $3;
1023                         }
1024                 else
1025                         {
1026                         SCM ret = gh_call1 ($2, $3->self_scm ());
1027                         Music *m = unsmob_music (ret);
1028                         if (!m) {
1029                                 THIS->parser_error ("\\apply must return a Music");
1030                                 m = MY_MAKE_MUSIC("Music");
1031                                 }
1032                         $$ = m;
1033                         }
1034         }
1035         | NOTES
1036                 { THIS->lexer_->push_note_state (); }
1037         Music
1038                 { $$ = $3;
1039                   THIS->lexer_->pop_state ();
1040                 }
1041         | FIGURES
1042                 { THIS->lexer_->push_figuredbass_state (); }
1043         Music
1044                 {
1045                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1046                   chm->set_mus_property ("element", $3->self_scm ());
1047                   $$ = chm;
1048                   scm_gc_unprotect_object ($3->self_scm());
1049
1050                   THIS->lexer_->pop_state ();
1051         }
1052         | CHORDS
1053                 { THIS->lexer_->push_chord_state (); }
1054         Music
1055                 {
1056                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1057                   chm->set_mus_property ("element", $3->self_scm ());
1058                   scm_gc_unprotect_object ($3->self_scm());
1059                   $$ = chm;
1060
1061                   THIS->lexer_->pop_state ();
1062         }
1063         | LYRICS
1064                 { THIS->lexer_->push_lyric_state (); }
1065         Music
1066                 {
1067                   $$ = $3;
1068                   THIS->lexer_->pop_state ();
1069         }
1070         | relative_music        { $$ = $1; }
1071         | re_rhythmed_music     { $$ = $1; }
1072         | part_combined_music   { $$ = $1; }
1073         | TAG embedded_scm Music {
1074                 tag_music ($3, $2, THIS->here_input ());
1075                 $$ = $3;
1076         }
1077         ;
1078
1079 relative_music:
1080         RELATIVE absolute_pitch Music {
1081                 Music * p = $3;
1082                 Pitch pit = *unsmob_pitch ($2);
1083                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1084
1085                 $$->set_mus_property ("element", p->self_scm ());
1086                 scm_gc_unprotect_object (p->self_scm ());
1087
1088
1089                 Pitch retpitch = p->to_relative_octave (pit);
1090                 if (lily_1_8_relative)
1091                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1092         }
1093         ;
1094
1095 re_rhythmed_music:
1096         ADDLYRICS Music Music {
1097         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1098           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1099           scm_gc_unprotect_object ($3->self_scm ());
1100           scm_gc_unprotect_object ($2->self_scm ());
1101           $$ = l;
1102         }
1103         | NEWADDLYRICS string Music {
1104           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1105           l->set_mus_property ("element", $3->self_scm ());
1106           scm_gc_unprotect_object ($3->self_scm ());
1107           $$ = l;
1108           l->set_mus_property ("associated-context", $2);
1109         }
1110         ;
1111
1112 part_combined_music:
1113         PARTCOMBINE STRING Music Music {
1114                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1115                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1116                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1117
1118                 scm_gc_unprotect_object ($3->self_scm ());
1119                 scm_gc_unprotect_object ($4->self_scm ());
1120
1121                 $$ = p;
1122         }
1123         ;
1124
1125 context_change:
1126         CHANGE STRING '=' STRING  {
1127                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1128                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1129                 t-> set_mus_property ("change-to-id", $4);
1130
1131                 $$ = t;
1132                 $$->set_spot (THIS->here_input ());
1133         }
1134         ;
1135
1136 property_operation:
1137         STRING '='  scalar {
1138                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1139                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1140         }
1141         | STRING UNSET {
1142                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1143                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1144         }
1145         | STRING SET embedded_scm '=' embedded_scm {
1146                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1147                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1148         }
1149         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1150                 $$ = scm_list_n (ly_symbol2scm ("push"),
1151                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1152         }
1153         | STRING REVERT embedded_scm {
1154                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1155                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1156         }
1157         ;
1158
1159 translator_mod:
1160         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1161         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1162         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1163
1164         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1165         | DENIES { $$ = ly_symbol2scm ("denies"); }
1166
1167         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1168         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1169         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1170         | NAME { $$ = ly_symbol2scm ("context-name"); }
1171         ;
1172
1173 context_mod:
1174         property_operation { $$ = $1; }
1175         | translator_mod STRING {
1176                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1177         }
1178         ;
1179
1180 music_property_def:
1181         PROPERTY STRING '.' property_operation {
1182                 Music * t = property_op_to_music ($4);
1183                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1184
1185                 csm->set_mus_property ("element", t->self_scm ());
1186                 scm_gc_unprotect_object (t->self_scm ());
1187
1188                 $$ = csm;
1189                 $$->set_spot (THIS->here_input ());
1190
1191                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1192         }
1193         | ONCE music_property_def {
1194                 $$ = $2;
1195                 SCM e = $2->get_mus_property ("element");
1196                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1197         }
1198         ;
1199
1200
1201 scalar:
1202         string          { $$ = $1; }
1203         | bare_int      { $$ = gh_int2scm ($1); }
1204         | embedded_scm  { $$ = $1; }
1205         | full_markup {  $$ = $1; }
1206         | DIGIT { $$ = gh_int2scm ($1); }
1207         ;
1208
1209 /*
1210 This is a trick:
1211
1212 Adding pre_events to the simple_element
1213 makes the choice between
1214
1215   string:  STRING
1216
1217 and
1218
1219   simple_element: STRING
1220
1221 a single shift/reduction conflict.
1222
1223 nevertheless, this is not very clean, and we should find a different
1224 solution.
1225
1226 */
1227 pre_events: {
1228                 THIS->push_spot ();
1229         }
1230         ;
1231
1232 event_chord:
1233         pre_events simple_element post_events   {
1234                 SCM elts = $2-> get_mus_property ("elements");
1235
1236                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1237
1238                 $2->set_mus_property ("elements", elts);
1239                 $$ = $2;
1240         }
1241         | command_element
1242         | note_chord_element
1243         ;
1244
1245
1246 note_chord_element:
1247         chord_body optional_notemode_duration post_events
1248         {
1249                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1250                 SCM es = $1->get_mus_property ("elements");
1251                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1252
1253                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1254                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1255                 es = gh_append2 (es, postevs);
1256
1257                 $1-> set_mus_property ("elements", es);
1258                 $$ = $1;
1259         }
1260         ;
1261
1262 chord_open: '<'
1263         ;
1264
1265 chord_close: '>'
1266         ;
1267
1268 simul_open: LESSLESS
1269         ;
1270
1271 simul_close: MOREMORE
1272         ;
1273
1274 chord_body:
1275         chord_open chord_body_elements chord_close
1276         {
1277                 $$ = MY_MAKE_MUSIC("EventChord");
1278                 $$->set_mus_property ("elements",
1279                         scm_reverse_x ($2, SCM_EOL));
1280         }
1281         ;
1282
1283 chord_body_elements:
1284         /* empty */             { $$ = SCM_EOL; }
1285         | chord_body_elements chord_body_element {
1286                 $$ = gh_cons ($2->self_scm(), $1);
1287                 scm_gc_unprotect_object ($2->self_scm());
1288         }
1289         ;
1290
1291 chord_body_element:
1292         pitch exclamations questions post_events
1293         {
1294                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1295                 n->set_mus_property ("pitch", $1);
1296                 if ($3 % 2)
1297                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1298                 if ($2 % 2 || $3 % 2)
1299                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1300
1301                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1302                 n->set_mus_property ("articulations", arts);
1303
1304                 $$ = n;
1305         }
1306         ;
1307
1308 command_element:
1309         command_req {
1310                 $$ = MY_MAKE_MUSIC("EventChord");
1311                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1312                 scm_gc_unprotect_object ($1->self_scm());
1313
1314                 $$-> set_spot (THIS->here_input ());
1315                 $1-> set_spot (THIS->here_input ());
1316         }
1317         | OCTAVE { THIS->push_spot (); }
1318           pitch {
1319                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1320                 $$ = l;
1321                 $$->set_spot (THIS->pop_spot ());
1322                 $$->set_mus_property ("pitch", $3);
1323         }
1324         | E_LEFTSQUARE {
1325                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1326                 l->set_mus_property ("span-direction", gh_int2scm (START));
1327                 l->set_spot (THIS->here_input ());
1328
1329                 $$ = MY_MAKE_MUSIC("EventChord");
1330                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1331                 scm_gc_unprotect_object (l->self_scm());
1332                 $$->set_spot (THIS->here_input ());
1333         }
1334         | E_RIGHTSQUARE {
1335                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1336                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1337                 l->set_spot (THIS->here_input ());
1338
1339                 $$ = MY_MAKE_MUSIC("EventChord");
1340                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1341                 $$->set_spot (THIS->here_input ());
1342                 scm_gc_unprotect_object (l->self_scm());
1343         }
1344         | E_BACKSLASH {
1345                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1346                 $$->set_spot (THIS->here_input ());
1347         }
1348         | '|'      {
1349
1350                 $$ = MY_MAKE_MUSIC("BarCheck");
1351                 $$->set_spot (THIS->here_input ());
1352         }
1353         | BAR STRING                    {
1354                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1355
1356                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1357                 csm->set_mus_property ("element", t->self_scm ());
1358                 scm_gc_unprotect_object (t->self_scm ());
1359
1360                 $$ = csm;
1361                 $$->set_spot (THIS->here_input ());
1362
1363                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1364         }
1365         | PARTIAL duration_length       {
1366                 Moment m = - unsmob_duration ($2)->get_length ();
1367                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1368
1369                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1370                 sp->set_mus_property ("element", p->self_scm ());
1371                 scm_gc_unprotect_object (p->self_scm ());
1372
1373                 $$ =sp ;
1374                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1375         }
1376         | CLEF STRING  {
1377                 static SCM proc ;
1378                 if (!proc)
1379                         proc = scm_c_eval_string ("make-clef-set");
1380
1381                 SCM result = scm_call_1 (proc, $2);
1382                 scm_gc_protect_object (result);
1383                 $$ = unsmob_music (result);
1384         }
1385         | TIME_T fraction  {
1386                 static SCM proc;
1387                 if (!proc)
1388                         proc = scm_c_eval_string ("make-time-signature-set");
1389
1390                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1391                 scm_gc_protect_object (result);
1392                 $$ = unsmob_music (result);
1393         }
1394         ;
1395
1396 command_req:
1397         shorthand_command_req   { $$ = $1; }
1398         | verbose_command_req   { $$ = $1; }
1399         ;
1400
1401 shorthand_command_req:
1402         hyphen_req {
1403                 $$ = $1;
1404         }
1405         | BREATHE {
1406                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1407         }
1408         | E_TILDE {
1409                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1410         }
1411         ;
1412
1413 verbose_command_req:
1414         MARK DEFAULT  {
1415                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1416                 $$ = m;
1417         }
1418         | MARK scalar {
1419                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1420                 m->set_mus_property ("label", $2);
1421                 $$ = m;
1422         }
1423         | SKIP duration_length {
1424                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1425                 skip->set_mus_property ("duration", $2);
1426
1427                 $$ = skip;
1428         }
1429         | tempo_event {
1430                 $$ = $1;
1431         }
1432         | KEY DEFAULT {
1433                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1434                 $$ = key;
1435         }
1436         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1437
1438                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1439                 if (scm_ilength ($3) > 0)
1440                 {
1441                         key->set_mus_property ("pitch-alist", $3);
1442                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1443                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1444                 } else {
1445                         THIS->parser_error (_("Second argument must be pitch list."));
1446                 }
1447
1448                 $$ = key;
1449         }
1450         ;
1451
1452 post_events:
1453         /* empty */ {
1454                 $$ = SCM_EOL;
1455         }
1456         | post_events post_event {
1457                 $2->set_spot (THIS->here_input ());
1458                 $$ = gh_cons ($2->self_scm(), $$);
1459                 scm_gc_unprotect_object ($2->self_scm());
1460         }
1461         | post_events tagged_post_event {
1462                 $2 -> set_spot (THIS->here_input ());
1463                 $$ = scm_cons ($2->self_scm(), $$);
1464                 scm_gc_unprotect_object ($2->self_scm());
1465         }
1466         ;
1467
1468
1469 tagged_post_event:
1470         '-' TAG embedded_scm post_event {
1471                 tag_music ($4, $3, THIS->here_input ());
1472                 $$ = $4;
1473         }
1474         ;
1475
1476 post_event:
1477         direction_less_event {
1478                 $$ = $1;
1479         }
1480         | EXTENDER {
1481                 if (!THIS->lexer_->lyric_state_b ())
1482                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1483                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1484         }
1485         | script_dir direction_reqd_event {
1486                 if ($1)
1487                         $2->set_mus_property ("direction", gh_int2scm ($1));
1488                 $$ = $2;
1489         }
1490         | script_dir direction_less_event {
1491                 if ($1)
1492                         $2->set_mus_property ("direction", gh_int2scm ($1));
1493                 $$ = $2;
1494         }
1495         | string_number_event
1496         ;
1497
1498 string_number_event:
1499         E_UNSIGNED {
1500                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1501                 s->set_mus_property ("string-number",  gh_int2scm($1));
1502                 s->set_spot (THIS->here_input ());
1503                 $$ = s;
1504         }
1505         ;
1506
1507
1508 direction_less_event:
1509         '['  {
1510
1511
1512 /*
1513
1514 TODO: should take all these defs out of the parser, adn make use
1515 configurable, i.e.
1516
1517
1518 (set-articulation '~ "trill")
1519
1520 */
1521                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1522                 m->set_spot (THIS->here_input());
1523                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1524                 $$ = m;
1525         }
1526         | ']'  {
1527                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1528                 m->set_spot (THIS->here_input());
1529                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1530                 $$ = m;
1531         }
1532         | '~' {
1533                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1534                 m->set_spot (THIS->here_input());
1535                 $$ = m;
1536         }
1537         | close_event {
1538                 $$ = $1;
1539                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1540                         gh_int2scm (START));
1541         }
1542         | open_event {
1543                 $$ = $1;
1544                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1545                         gh_int2scm (STOP));
1546         }
1547         | EVENT_IDENTIFIER      {
1548                 $$ = unsmob_music ($1);
1549         }
1550         | tremolo_type  {
1551                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1552                a->set_spot (THIS->here_input ());
1553                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1554                $$ = a;
1555         }
1556         ;
1557
1558 direction_reqd_event:
1559         gen_text_def {
1560                 $$ = $1;
1561         }
1562         | script_abbreviation {
1563                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1564                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1565                 if (gh_string_p (s))
1566                         a->set_mus_property ("articulation-type", s);
1567                 else THIS->parser_error (_ ("Expecting string as script definition"));
1568                 $$ = a;
1569         }
1570         ;
1571
1572 oct_check:
1573         /**/ { $$ = SCM_EOL; }
1574         | '='  { $$ = gh_int2scm (0); }
1575         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1576         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1577         ;
1578
1579 sup_quotes:
1580         '\'' {
1581                 $$ = 1;
1582         }
1583         | sup_quotes '\'' {
1584                 $$ ++;
1585         }
1586         ;
1587
1588 sub_quotes:
1589         ',' {
1590                 $$ = 1;
1591         }
1592         | sub_quotes ',' {
1593                 $$ ++ ;
1594         }
1595         ;
1596
1597 steno_pitch:
1598         NOTENAME_PITCH  {
1599                 $$ = $1;
1600         }
1601         | NOTENAME_PITCH sup_quotes     {
1602                 Pitch p = *unsmob_pitch ($1);
1603                 p = p.transposed (Pitch ($2,0,0));
1604                 $$ = p.smobbed_copy ();
1605         }
1606         | NOTENAME_PITCH sub_quotes      {
1607                 Pitch p =* unsmob_pitch ($1);
1608                 p = p.transposed (Pitch (-$2,0,0));
1609                 $$ = p.smobbed_copy ();
1610         }
1611         ;
1612
1613 /*
1614 ugh. duplication
1615 */
1616
1617 steno_tonic_pitch:
1618         TONICNAME_PITCH {
1619                 $$ = $1;
1620         }
1621         | TONICNAME_PITCH sup_quotes    {
1622                 Pitch p = *unsmob_pitch ($1);
1623                 p = p.transposed (Pitch ($2,0,0));
1624                 $$ = p.smobbed_copy ();
1625         }
1626         | TONICNAME_PITCH sub_quotes     {
1627                 Pitch p =* unsmob_pitch ($1);
1628
1629                 p = p.transposed (Pitch (-$2,0,0));
1630                 $$ = p.smobbed_copy ();
1631         }
1632         ;
1633
1634 pitch:
1635         steno_pitch {
1636                 $$ = $1;
1637         }
1638         ;
1639
1640 pitch_also_in_chords:
1641         pitch
1642         | steno_tonic_pitch
1643         ;
1644
1645 hyphen_req:
1646         HYPHEN {
1647                 if (!THIS->lexer_->lyric_state_b ())
1648                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1649                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1650         }
1651         ;
1652
1653 close_event:
1654         '('     {
1655                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1656                 $$ = s;
1657                 s->set_spot (THIS->here_input());
1658         }
1659         | E_OPEN        {
1660                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1661                 $$ = s;
1662                 s->set_spot (THIS->here_input());
1663         }
1664         | E_SMALLER {
1665                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1666                 $$ = s;
1667                 s->set_spot (THIS->here_input());
1668         }
1669         | E_BIGGER {
1670                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1671                 $$ = s;
1672                 s->set_spot (THIS->here_input());
1673         }
1674         ;
1675
1676
1677 open_event:
1678         E_EXCLAMATION   {
1679                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1680                 s->set_spot (THIS->here_input());
1681
1682                 $$ = s;
1683         }
1684         | ')'   {
1685                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1686                 $$ = s;
1687                 s->set_spot (THIS->here_input());
1688
1689         }
1690         | E_CLOSE       {
1691                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1692                 $$ = s;
1693                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1694                 s->set_spot (THIS->here_input());
1695         }
1696         ;
1697
1698 gen_text_def:
1699         full_markup {
1700                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1701                 t->set_mus_property ("text", $1);
1702                 t->set_spot (THIS->here_input ());
1703                 $$ = t;
1704         }
1705         | string {
1706                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1707                 t->set_mus_property ("text", make_simple_markup ($1));
1708                 t->set_spot (THIS->here_input ());
1709                 $$ = t;
1710
1711         }
1712         | DIGIT {
1713                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1714                 t->set_mus_property ("digit",  gh_int2scm ($1));
1715                 t->set_spot (THIS->here_input ());
1716                 $$ = t;
1717         }
1718         ;
1719
1720 script_abbreviation:
1721         '^'             {
1722                 $$ = scm_makfrom0str ("Hat");
1723         }
1724         | '+'           {
1725                 $$ = scm_makfrom0str ("Plus");
1726         }
1727         | '-'           {
1728                 $$ = scm_makfrom0str ("Dash");
1729         }
1730         | '|'           {
1731                 $$ = scm_makfrom0str ("Bar");
1732         }
1733         | '>'           {
1734                 $$ = scm_makfrom0str ("Larger");
1735         }
1736         | '.'           {
1737                 $$ = scm_makfrom0str ("Dot");
1738         }
1739         | '_' {
1740                 $$ = scm_makfrom0str ("Underscore");
1741         }
1742         ;
1743
1744 script_dir:
1745         '_'     { $$ = DOWN; }
1746         | '^'   { $$ = UP; }
1747         | '-'   { $$ = CENTER; }
1748         ;
1749
1750
1751 absolute_pitch:
1752         steno_pitch     {
1753                 $$ = $1;
1754         }
1755         ;
1756
1757 duration_length:
1758         multiplied_duration {
1759                 $$ = $1;
1760         }
1761         ;
1762
1763 optional_notemode_duration:
1764         {
1765                 Duration dd = THIS->default_duration_;
1766                 $$ = dd.smobbed_copy ();
1767
1768                 THIS->beam_check ($$);
1769         }
1770         | multiplied_duration   {
1771                 $$ = $1;
1772                 THIS->default_duration_ = *unsmob_duration ($$);
1773
1774                 THIS->beam_check ($$);
1775         }
1776         ;
1777
1778 steno_duration:
1779         bare_unsigned dots              {
1780                 int l = 0;
1781                 if (!is_duration_b ($1))
1782                         THIS->parser_error (_f ("not a duration: %d", $1));
1783                 else
1784                         l =  intlog2 ($1);
1785
1786                 $$ = Duration (l, $2).smobbed_copy ();
1787         }
1788         | DURATION_IDENTIFIER dots      {
1789                 Duration *d =unsmob_duration ($1);
1790                 Duration k (d->duration_log (),d->dot_count () + $2);
1791
1792                 *d = k;
1793                 $$ = $1;
1794         }
1795         ;
1796
1797
1798
1799
1800 multiplied_duration:
1801         steno_duration {
1802                 $$ = $1;
1803         }
1804         | multiplied_duration '*' bare_unsigned {
1805                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1806         }
1807         | multiplied_duration '*' FRACTION {
1808                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1809
1810                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1811         }
1812         ;
1813
1814 fraction:
1815         FRACTION { $$ = $1; }
1816         | UNSIGNED '/' UNSIGNED {
1817                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1818         }
1819         ;
1820
1821 dots:
1822         /* empty */     {
1823                 $$ = 0;
1824         }
1825         | dots '.' {
1826                 $$ ++;
1827         }
1828         ;
1829
1830
1831 tremolo_type:
1832         ':'     {
1833                 $$ =0;
1834         }
1835         | ':' bare_unsigned {
1836                 if (!is_duration_b ($2))
1837                         THIS->parser_error (_f ("not a duration: %d", $2));
1838                 $$ = $2;
1839         }
1840         ;
1841
1842
1843
1844 /*****************************************************************
1845                 BASS FIGURES
1846 *****************************************************************/
1847 bass_number:
1848         DIGIT   {
1849                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1850         }
1851         | UNSIGNED {
1852                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1853         }
1854         | STRING { $$ =  $1; }
1855         ;
1856
1857 bass_mod:
1858         '-'     { $$ = -2; }
1859         | '+'   { $$ = 2; }
1860         | '!'   { $$ = 0; }
1861         ;
1862
1863 bass_figure:
1864         FIGURE_SPACE {
1865                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1866                 $$ = bfr->self_scm();
1867                 scm_gc_unprotect_object ($$);
1868         }
1869         | bass_number  {
1870                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1871                 $$ = bfr->self_scm();
1872
1873                 bfr->set_mus_property ("figure", $1);
1874
1875                 scm_gc_unprotect_object ($$);
1876         }
1877         | bass_figure bass_mod {
1878                 Music *m = unsmob_music ($1);
1879                 if ($2) {
1880                         SCM salter =m->get_mus_property ("alteration");
1881                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1882                         m->set_mus_property ("alteration",
1883                                 gh_int2scm (alter + $2));
1884                 } else {
1885                         m->set_mus_property ("alteration", gh_int2scm (0));
1886                 }
1887         }
1888         ;
1889
1890 br_bass_figure:
1891         '[' bass_figure {
1892                 $$ = $2;
1893                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1894         }
1895         | bass_figure   {
1896                 $$ = $1;
1897         }
1898         | br_bass_figure ']' {
1899                 $$ = $1;
1900                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1901         }
1902         ;
1903
1904 figure_list:
1905         /**/            {
1906                 $$ = SCM_EOL;
1907         }
1908         | figure_list br_bass_figure {
1909                 $$ = scm_cons ($2, $1);
1910         }
1911         ;
1912
1913 figure_spec:
1914         FIGURE_OPEN figure_list FIGURE_CLOSE {
1915                 Music * m = MY_MAKE_MUSIC("EventChord");
1916                 $2 = scm_reverse_x ($2, SCM_EOL);
1917                 m->set_mus_property ("elements",  $2);
1918                 $$ = m->self_scm ();
1919         }
1920         ;
1921
1922
1923 optional_rest:
1924         /**/   { $$ = 0; }
1925         | REST { $$ = 1; }
1926         ;
1927
1928 simple_element:
1929         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1930
1931                 Input i = THIS->pop_spot ();
1932                 if (!THIS->lexer_->note_state_b ())
1933                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1934
1935                 Music *n = 0;
1936                 if ($6)
1937                         n =  MY_MAKE_MUSIC("RestEvent");
1938                 else
1939                         n =  MY_MAKE_MUSIC("NoteEvent");
1940
1941                 n->set_mus_property ("pitch", $1);
1942                 n->set_mus_property ("duration", $5);
1943
1944                 if (gh_number_p ($4))
1945                 {
1946                         int q = gh_scm2int ($4);
1947                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1948                 }
1949
1950                 if ($3 % 2)
1951                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1952                 if ($2 % 2 || $3 % 2)
1953                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1954
1955                 Music *v = MY_MAKE_MUSIC("EventChord");
1956                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1957                 scm_gc_unprotect_object (n->self_scm());
1958
1959                 v->set_spot (i);
1960                 n->set_spot (i);
1961                 $$ = v;
1962         }
1963         | figure_spec optional_notemode_duration {
1964                 Music * m = unsmob_music ($1);
1965                 Input i = THIS->pop_spot ();
1966                 m->set_spot (i);
1967                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1968                 {
1969                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1970                 }
1971                 $$ = m;
1972         }
1973         | RESTNAME optional_notemode_duration           {
1974
1975                 Input i = THIS->pop_spot ();
1976                 Music * ev = 0;
1977                 if (ly_scm2string ($1) =="s") {
1978                         /* Space */
1979                         ev = MY_MAKE_MUSIC("SkipEvent");
1980                   }
1981                 else {
1982                         ev = MY_MAKE_MUSIC("RestEvent");
1983
1984                     }
1985                 ev->set_mus_property ("duration" ,$2);
1986                 ev->set_spot (i);
1987                 Music * velt = MY_MAKE_MUSIC("EventChord");
1988                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1989                 velt->set_spot (i);
1990
1991                 $$ = velt;
1992         }
1993         | MULTI_MEASURE_REST optional_notemode_duration         {
1994                 THIS->pop_spot ();
1995
1996                 static SCM proc ;
1997                 if (!proc)
1998                         proc = scm_c_eval_string ("make-multi-measure-rest");
1999
2000                 SCM mus = scm_call_2 (proc, $2,
2001                         make_input (THIS->here_input()));
2002                 scm_gc_protect_object (mus);
2003                 $$ = unsmob_music (mus);
2004         }
2005
2006         | lyric_element optional_notemode_duration      {
2007                 Input i = THIS->pop_spot ();
2008                 if (!THIS->lexer_->lyric_state_b ())
2009                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2010
2011                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2012                 lreq->set_mus_property ("text", $1);
2013                 lreq->set_mus_property ("duration",$2);
2014                 lreq->set_spot (i);
2015                 Music * velt = MY_MAKE_MUSIC("EventChord");
2016                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2017
2018                 $$= velt;
2019         }
2020         | new_chord {
2021                 THIS->pop_spot ();
2022
2023                 if (!THIS->lexer_->chord_state_b ())
2024                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2025                 $$ = unsmob_music ($1);
2026         }
2027         ;
2028
2029 lyric_element:
2030         full_markup { $$ = $1; }
2031         | STRING {  $$ = $1 ; }
2032         ;
2033
2034 new_chord:
2035         steno_tonic_pitch optional_notemode_duration   {
2036                 $$ = make_chord ($1, $2, SCM_EOL);
2037         }
2038         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2039                 SCM its = scm_reverse_x ($4, SCM_EOL);
2040                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2041         }
2042         ;
2043
2044 chord_items:
2045         /**/ {
2046                 $$ = SCM_EOL;
2047         }
2048         | chord_items chord_item {
2049                 $$ = gh_cons ($2, $$);
2050         }
2051         ;
2052
2053 chord_separator:
2054         CHORD_COLON {
2055                 $$ = ly_symbol2scm ("chord-colon");
2056         }
2057         | CHORD_CARET {
2058                 $$ = ly_symbol2scm ("chord-caret");
2059         }
2060         | CHORD_SLASH steno_tonic_pitch {
2061                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2062         }
2063         | CHORD_BASS steno_tonic_pitch {
2064                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2065         }
2066         ;
2067
2068 chord_item:
2069         chord_separator {
2070                 $$ = $1;
2071         }
2072         | step_numbers {
2073                 $$ = scm_reverse_x ($1, SCM_EOL);
2074         }
2075         | CHORD_MODIFIER  {
2076                 $$ = $1;
2077         }
2078         ;
2079
2080 step_numbers:
2081         step_number { $$ = gh_cons ($1, SCM_EOL); }
2082         | step_numbers '.' step_number {
2083                 $$ = gh_cons ($3, $$);
2084         }
2085         ;
2086
2087 step_number:
2088         bare_unsigned {
2089                 $$ = make_chord_step ($1, 0);
2090         }
2091         | bare_unsigned '+' {
2092                 $$ = make_chord_step ($1, SHARP);
2093         }
2094         | bare_unsigned CHORD_MINUS {
2095                 $$ = make_chord_step ($1, FLAT);
2096         }
2097         ;
2098
2099 /*
2100         UTILITIES
2101
2102 TODO: should deprecate in favor of Scheme?
2103
2104  */
2105 number_expression:
2106         number_expression '+' number_term {
2107                 $$ = scm_sum ($1, $3);
2108         }
2109         | number_expression '-' number_term {
2110                 $$ = scm_difference ($1, $3);
2111         }
2112         | number_term
2113         ;
2114
2115 number_term:
2116         number_factor {
2117                 $$ = $1;
2118         }
2119         | number_factor '*' number_factor {
2120                 $$ = scm_product ($1, $3);
2121         }
2122         | number_factor '/' number_factor {
2123                 $$ = scm_divide ($1, $3);
2124         }
2125         ;
2126
2127 number_factor:
2128         '-'  number_factor { /* %prec UNARY_MINUS */
2129                 $$ = scm_difference ($2, SCM_UNDEFINED);
2130         }
2131         | bare_number
2132         ;
2133
2134
2135 bare_number:
2136         UNSIGNED        {
2137                 $$ = gh_int2scm ($1);
2138         }
2139         | REAL          {
2140                 $$ = $1;
2141         }
2142         | NUMBER_IDENTIFIER             {
2143                 $$ = $1;
2144         }
2145         | REAL NUMBER_IDENTIFIER        {
2146                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2147         }
2148         | UNSIGNED NUMBER_IDENTIFIER    {
2149                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2150         }
2151         ;
2152
2153
2154 bare_unsigned:
2155         UNSIGNED {
2156                         $$ = $1;
2157         }
2158         | DIGIT {
2159                 $$ = $1;
2160         }
2161         ;
2162
2163 bare_int:
2164         bare_number {
2165                 if (scm_integer_p ($1) == SCM_BOOL_T)
2166                 {
2167                         int k = gh_scm2int ($1);
2168                         $$ = k;
2169                 } else
2170                 {
2171                         THIS->parser_error (_ ("need integer number arg"));
2172                         $$ = 0;
2173                 }
2174         }
2175         | '-' bare_int {
2176                 $$ = -$2;
2177         }
2178         ;
2179
2180
2181 string:
2182         STRING          {
2183                 $$ = $1;
2184         }
2185         | STRING_IDENTIFIER     {
2186                 $$ = $1;
2187         }
2188         | string '+' string {
2189                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2190         }
2191         ;
2192
2193
2194 exclamations:
2195                 { $$ = 0; }
2196         | exclamations '!'      { $$ ++; }
2197         ;
2198
2199 questions:
2200                 { $$ = 0; }
2201         | questions '?' { $$ ++; }
2202         ;
2203
2204
2205
2206 full_markup:
2207         MARKUP_IDENTIFIER {
2208                 $$ = $1;
2209         }
2210         | MARKUP
2211                 { THIS->lexer_->push_markup_state (); }
2212         markup
2213                 { $$ = $3;
2214                   THIS->lexer_->pop_state ();
2215                 }
2216         ;
2217
2218
2219 /*
2220 This should be done more dynamically if possible.
2221 */
2222 markup:
2223         STRING {
2224                 $$ = make_simple_markup ($1);
2225         }
2226         | MARKUP_HEAD_EMPTY {
2227                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2228         }
2229         | MARKUP_HEAD_MARKUP0 markup {
2230                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2231         }
2232         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2233                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2234         }
2235         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2236                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2237         }
2238         | markup_line {
2239                 $$ = $1;
2240         }
2241         | MARKUP_HEAD_LIST0 markup_list {
2242                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2243         }
2244         | MARKUP_HEAD_SCM0 embedded_scm {
2245                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2246         }
2247         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2248                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2249         }
2250         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2251                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2252         }
2253         | MARKUP_IDENTIFIER {
2254                 $$ = $1;
2255         }
2256
2257         ;
2258
2259 markup_list:
2260         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2261         ;
2262
2263 markup_line:
2264         '{' markup_list_body '}' {
2265                 static SCM line ;
2266                 if (!line)
2267                         line = scm_c_eval_string ("line-markup");
2268
2269                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2270         }
2271         ;
2272
2273 markup_list_body:
2274         /**/ {  $$ = SCM_EOL; }
2275         | markup_list_body markup {
2276                 $$ = gh_cons ($2, $1) ;
2277         }
2278         ;
2279
2280
2281 %%
2282
2283 void
2284 My_lily_parser::set_yydebug (bool )
2285 {
2286 #if 0
2287         yydebug = 1;
2288 #endif
2289 }
2290
2291 extern My_lily_parser * current_parser;
2292
2293 void
2294 My_lily_parser::do_yyparse ()
2295 {
2296         current_parser = this;;
2297         yyparse ((void*)this);
2298 }
2299
2300
2301 /*
2302 Should make this optional?    It will also complain when you do
2303
2304         [s4]
2305
2306 which is entirely legitimate.
2307
2308 Or we can scrap it. Barchecks should detect wrong durations, and
2309 skipTypesetting speeds it up a lot.
2310 */
2311
2312 void
2313 My_lily_parser::beam_check (SCM dur)
2314 {
2315   Duration *d = unsmob_duration (dur);
2316   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2317     {
2318       Music * m = unsmob_music (last_beam_start_);
2319       m->origin ()->warning (_("Suspect duration found following this beam"));
2320     }
2321   last_beam_start_ = SCM_EOL;
2322 }
2323
2324
2325
2326
2327 /*
2328
2329 It is a little strange to have this function in this file, but
2330 otherwise, we have to import music classes into the lexer.
2331
2332 */
2333 int
2334 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2335 {
2336         if (gh_string_p (sid)) {
2337                 *destination = sid;
2338                 return STRING_IDENTIFIER;
2339         } else if (gh_number_p (sid)) {
2340                 *destination = sid;
2341                 return NUMBER_IDENTIFIER;
2342         } else if (unsmob_context_def (sid)) {
2343                 *destination = unsmob_context_def (sid)->clone_scm();
2344                 return TRANSLATOR_IDENTIFIER;
2345         } else if (unsmob_score (sid)) {
2346                 Score *sc =  new Score (*unsmob_score (sid));
2347                 *destination =sc->self_scm ();
2348                 return SCORE_IDENTIFIER;
2349         } else if (Music * mus =unsmob_music (sid)) {
2350                 *destination = unsmob_music (sid)->clone ()->self_scm();
2351                 unsmob_music (*destination)->
2352                         set_mus_property ("origin", make_input (last_input_));
2353                 return dynamic_cast<Event*> (mus)
2354                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2355         } else if (unsmob_duration (sid)) {
2356                 *destination = unsmob_duration (sid)->smobbed_copy();
2357                 return DURATION_IDENTIFIER;
2358         } else if (unsmob_music_output_def (sid)) {
2359                 Music_output_def *p = unsmob_music_output_def (sid);
2360                 p = p->clone ();
2361
2362                 *destination = p->self_scm();
2363                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2364         } else if (Text_item::markup_p (sid)) {
2365                 *destination = sid;
2366                 return MARKUP_IDENTIFIER;
2367         }
2368
2369         return -1;
2370 }
2371
2372 Music *
2373 property_op_to_music (SCM op)
2374 {
2375         Music * m = 0;
2376         SCM tag = gh_car (op);
2377         SCM symbol  = gh_cadr (op);
2378         SCM args = gh_cddr (op);
2379         SCM grob_val = SCM_UNDEFINED;
2380         SCM grob_sym = SCM_UNDEFINED;
2381         SCM val = SCM_UNDEFINED;
2382
2383         if (tag == ly_symbol2scm ("assign"))
2384                 {
2385                 m =  MY_MAKE_MUSIC("PropertySet");
2386                 val = gh_car (args);
2387                 }
2388         else if (tag == ly_symbol2scm ("unset"))
2389                 m =  MY_MAKE_MUSIC("PropertyUnset");
2390         else if (tag == ly_symbol2scm ("poppush")
2391                  || tag == ly_symbol2scm ("push"))
2392                 {
2393                 m  = MY_MAKE_MUSIC("OverrideProperty");
2394                 grob_sym = gh_car (args);
2395                 grob_val = gh_cadr (args);
2396                 }
2397         else if (tag == ly_symbol2scm ("pop")) {
2398                 m = MY_MAKE_MUSIC("RevertProperty");
2399                 grob_sym = gh_car (args);
2400                 }
2401
2402         m->set_mus_property ("symbol", symbol);
2403
2404         if (val != SCM_UNDEFINED)
2405                 m->set_mus_property ("value", val);
2406         if (grob_val != SCM_UNDEFINED)
2407                 m->set_mus_property ("grob-value", grob_val);
2408
2409         if (grob_sym != SCM_UNDEFINED)
2410                 {
2411                 bool itc = internal_type_checking_global_b;
2412                 /* UGH.
2413                 */
2414                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2415                 if (autobeam)
2416                         internal_type_checking_global_b = false;
2417                 m->set_mus_property ("grob-property", grob_sym);
2418                 if (autobeam)
2419                         internal_type_checking_global_b = itc;
2420                 }
2421
2422         if (op == ly_symbol2scm ("poppush"))
2423                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2424
2425
2426         return m;
2427 }
2428
2429 Music*
2430 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2431 {
2432         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2433
2434         csm->set_mus_property ("element", m->self_scm ());
2435         scm_gc_unprotect_object (m->self_scm ());
2436
2437         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2438         csm->set_mus_property ("property-operations", ops);
2439
2440         if (gh_string_p (id))
2441                 csm->set_mus_property ("context-id", id);
2442         return csm;
2443 }
2444
2445
2446 SCM
2447 get_next_unique_context ()
2448 {
2449         static int new_context_count;
2450
2451         char s[1024];
2452         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2453
2454         return scm_makfrom0str (s);
2455 }