lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2001 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Two shift/reduce problems:
  14     -
  15     -
  16  */
  17
  18 /*
  19
  20 the rules for who is protecting what are very shady. TODO: uniformise
  21 this.
  22
  23
  24 */
  25
  26 #include <ctype.h>
  27 #include <iostream.h>
  28
  29 #include "translator-def.hh"
  30 #include "lily-guile.hh"
  31 #include "change-iterator.hh"
  32 #include "misc.hh"
  33 #include "my-lily-lexer.hh"
  34 #include "paper-def.hh"
  35 #include "midi-def.hh"
  36 #include "main.hh"
  37 #include "file-path.hh"
  38 #include "debug.hh"
  39 #include "dimensions.hh"
  40 #include "command-request.hh"
  41 #include "musical-request.hh"
  42 #include "my-lily-parser.hh"
  43 #include "context-specced-music.hh"
  44 #include "score.hh"
  45 #include "music-list.hh"
  46 #include "output-property-music-iterator.hh"
  47 #include "property-iterator.hh"
  48 #include "file-results.hh"
  49 #include "input.hh"
  50 #include "relative-music.hh"
  51 #include "lyric-combine-music.hh"
  52 #include "transposed-music.hh"
  53 #include "time-scaled-music.hh"
  54 #include "repeated-music.hh"
  55 #include "untransposable-music.hh"
  56 #include "lilypond-input-version.hh"
  57 #include "grace-music.hh"
  58 #include "part-combine-music.hh"
  59 #include "scm-hash.hh"
  60 #include "auto-change-iterator.hh"
  61 #include "un-relativable-music.hh"
  62 #include "chord.hh"
  63
  64 bool
  65 regular_identifier_b (SCM id)
  66 {
  67   String str = ly_scm2string (id);
  68   char const *s = str.ch_C() ;
  69
  70   bool v = true;
  71   while (*s && v)
  72    {
  73         v = v && isalpha (*s);
  74         s++;
  75    }
  76   return v;
  77 }
  78
  79
  80 Music*
  81 set_property_music (SCM sym, SCM value)
  82 {
  83         Music * p = new Music (SCM_EOL);
  84         p->set_mus_property ("symbol", sym);
  85         p->set_mus_property ("iterator-ctor",
  86         Property_iterator::constructor_cxx_function);
  87
  88         p->set_mus_property ("value", value);
  89         return p;
  90 }
  91
  92 bool
  93 is_duration_b (int t)
  94 {
  95   return t && t == 1 << intlog2 (t);
  96 }
  97
  98 void
  99 set_music_properties (Music *p, SCM a)
 100 {
 101   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 102         {
 103         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 104         }
 105 }
 106
 107
 108
 109
 110
 111
 112
 113 // needed for bison.simple's malloc () and free ()
 114
 115 #include <malloc.h>
 116 #include <stdlib.h>
 117
 118
 119
 120 #define YYERROR_VERBOSE 1
 121
 122 #define YYPARSE_PARAM my_lily_parser_l
 123 #define YYLEX_PARAM my_lily_parser_l
 124 #define THIS\
 125         ((My_lily_parser *) my_lily_parser_l)
 126
 127 #define yyerror THIS->parser_error
 128 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
 129
 130 %}
 131
 132 /* We use SCMs to do strings, because it saves us the trouble of
 133 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 134 of the parse stack onto the heap. */
 135
 136
 137 %union {
 138
 139     Link_array<Request> *reqvec;
 140
 141     String *string; // needed by the lexer as temporary scratch area.
 142     Music *music;
 143     Score *score;
 144     Scheme_hash_table *scmhash;
 145     Music_output_def * outputdef;
 146
 147     Request * request;
 148
 149     SCM scm;
 150
 151     Tempo_req *tempo;
 152     int i;
 153 }
 154 %{
 155
 156 int
 157 yylex (YYSTYPE *s,  void * v_l)
 158 {
 159         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 160         My_lily_lexer * lex_l = pars_l->lexer_p_;
 161
 162         lex_l->lexval_l = (void*) s;
 163         return lex_l->yylex ();
 164 }
 165
 166
 167 %}
 168
 169 %pure_parser
 170
 171 /* tokens which are not keywords */
 172 %token AUTOCHANGE
 173 %token ALIAS
 174 %token APPLY
 175 %token ARPEGGIO
 176 %token DYNAMICSCRIPT
 177 %token ACCEPTS
 178 %token ALTERNATIVE
 179 %token BAR
 180 %token BREATHE
 181 %token CHORDMODIFIERS
 182 %token CHORDS
 183 %token CHAR_T
 184 %token CLEF
 185 %token CM_T
 186 %token CONSISTS
 187 %token DURATION
 188 %token SEQUENTIAL
 189 %token GROBDESCRIPTIONS
 190 %token SIMULTANEOUS
 191 %token CONSISTSEND
 192 %token DENIES
 193 %token DURATION
 194 %token EXTENDER
 195 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 196 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 197 %token GLISSANDO
 198 %token GRACE
 199 %token HEADER
 200 %token HYPHEN
 201 %token IN_T
 202 %token INVALID
 203 %token KEY
 204 %token LYRICS
 205 %token MARK
 206 %token MULTI_MEASURE_REST
 207 %token MIDI
 208 %token MM_T
 209 %token PITCH
 210 %token DEFAULT
 211 %token NAME
 212 %token PITCHNAMES
 213 %token NOTES
 214 %token PAPER
 215 %token PARTIAL
 216 %token PENALTY
 217 %token PROPERTY
 218 %token OVERRIDE SET REVERT
 219 %token PT_T
 220 %token RELATIVE
 221 %token REMOVE
 222 %token REPEAT
 223 %token ADDLYRICS
 224 %token PARTCOMBINE
 225 %token SCM_T
 226 %token SCORE
 227 %token SCRIPT
 228 %token SKIP
 229 %token SPANREQUEST
 230 %token STYLESHEET
 231 %token COMMANDSPANREQUEST
 232 %token TEMPO
 233 %token OUTPUTPROPERTY
 234 %token TIME_T
 235 %token TIMES
 236 %token TRANSLATOR
 237 %token TRANSPOSE
 238 %token TYPE
 239 %token UNSET
 240 %token CONTEXT
 241 %token REST
 242
 243 /* escaped */
 244 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 245 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 246 %token E_BACKSLASH
 247 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 248 %token FIGURE_SPACE
 249
 250
 251 %type <i>       exclamations questions dots optional_rest
 252 %type <i>       bass_number bass_mod
 253 %type <scm>     br_bass_figure bass_figure figure_list figure_spec
 254 %token <i>      DIGIT
 255 %token <scm>    NOTENAME_PITCH
 256 %token <scm>    TONICNAME_PITCH
 257 %token <scm>    CHORDMODIFIER_PITCH
 258 %token <scm>    DURATION_IDENTIFIER
 259 %token <scm>    FRACTION
 260 %token <id>     IDENTIFIER
 261
 262
 263 %token <scm>    SCORE_IDENTIFIER
 264 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 265
 266 %token <scm>    NUMBER_IDENTIFIER
 267 %token <scm>    REQUEST_IDENTIFIER
 268 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 269 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 270 %token <scm>    RESTNAME
 271 %token <scm>    STRING
 272 %token <scm>    SCM_T
 273 %token <i>      UNSIGNED
 274 %token <scm>   REAL
 275
 276 %type <outputdef> output_def
 277 %type <scmhash>         lilypond_header lilypond_header_body
 278 %type <request> open_request_parens close_request_parens open_request close_request
 279 %type <request> request_with_dir request_that_take_dir verbose_request
 280 %type <i>       sub_quotes sup_quotes
 281 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 282 %type <music>   Repeated_music
 283 %type <scm>     Alternative_music
 284 %type <i>       tremolo_type
 285 %type <i>       bare_int  bare_unsigned
 286 %type <i>       script_dir
 287
 288 %type <scm>     identifier_init
 289
 290 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 291 %type <scm>  verbose_duration
 292
 293 %type <reqvec>  pre_requests post_requests
 294 %type <request> gen_text_def
 295 %type <scm>   steno_pitch pitch absolute_pitch
 296 %type <scm>   explicit_pitch steno_tonic_pitch
 297
 298 %type <scm>     chord_additions chord_subtractions chord_notes chord_step
 299 %type <music>   chord
 300 %type <scm>     chord_note chord_inversion chord_bass
 301 %type <scm>     duration_length fraction
 302
 303 %type <scm>  embedded_scm scalar
 304 %type <music>   Music Sequential_music Simultaneous_music
 305 %type <music>   relative_music re_rhythmed_music part_combined_music
 306 %type <music>   property_def translator_change
 307 %type <scm> Music_list
 308 %type <outputdef>  music_output_def_body
 309 %type <request> shorthand_command_req
 310 %type <request> post_request
 311 %type <music> command_req verbose_command_req
 312 %type <request> extender_req
 313 %type <request> hyphen_req
 314 %type <scm>     string bare_number number_expression number_term number_factor
 315
 316 %type <score>   score_block score_body
 317
 318 %type <scm>     translator_spec_block translator_spec_body
 319 %type <tempo>   tempo_request
 320 %type <scm> notenames_body notenames_block chordmodifiers_block
 321 %type <scm>     script_abbreviation
 322
 323
 324
 325 %left '-' '+'
 326
 327 /* We don't assign precedence to / and *, because we might need varied
 328 prec levels in different prods */
 329
 330 %left UNARY_MINUS
 331
 332 %%
 333
 334 lilypond:       /* empty */
 335         | lilypond toplevel_expression {}
 336         | lilypond assignment  { }
 337         | lilypond error {
 338                 THIS->error_level_i_  = 1;
 339         }
 340         | lilypond INVALID      {
 341                 THIS->error_level_i_  = 1;
 342         }
 343         ;
 344
 345 toplevel_expression:
 346         notenames_block                 {
 347                 THIS->lexer_p_->pitchname_tab_ =  $1;
 348         }
 349         | chordmodifiers_block                  {
 350                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 351         }
 352         | lilypond_header {
 353                 if (global_header_p)
 354                         scm_gc_unprotect_object (global_header_p->self_scm ());
 355                 global_header_p = $1;
 356         }
 357         | score_block {
 358                 score_global_array.push ($1);
 359         }
 360         | output_def {
 361                 if (dynamic_cast<Paper_def*> ($1))
 362                         THIS->lexer_p_->set_identifier (gh_str02scm ("$defaultpaper"), $1->self_scm ());
 363                 else if (dynamic_cast<Midi_def*> ($1))
 364                         THIS->lexer_p_->set_identifier (gh_str02scm ("$defaultmidi"), $1->self_scm ());
 365         }
 366         | embedded_scm {
 367                 // junk value
 368         }
 369         ;
 370
 371 embedded_scm:
 372         SCM_T
 373         | SCM_IDENTIFIER
 374         ;
 375
 376
 377 chordmodifiers_block:
 378         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 379         ;
 380
 381 notenames_block:
 382         PITCHNAMES notenames_body   {  $$ = $2; }
 383         ;
 384
 385 notenames_body:
 386         embedded_scm    {
 387           int i = scm_ilength ($1);
 388
 389           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 390           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 391                 SCM pt = ly_cdar (s);
 392                 if (!unsmob_pitch (pt))
 393                         THIS->parser_error ("Need pitch object.");
 394                 else
 395                         scm_hashq_set_x (tab, ly_caar (s), pt);
 396           }
 397
 398           $$ = tab;
 399         }
 400         ;
 401
 402 lilypond_header_body:
 403         {
 404                 $$ = new Scheme_hash_table;
 405                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 406         }
 407         | lilypond_header_body assignment  {
 408
 409         }
 410         ;
 411
 412 lilypond_header:
 413         HEADER '{' lilypond_header_body '}'     {
 414                 $$ = $3;
 415                 THIS->lexer_p_->scope_l_arr_.pop ();
 416         }
 417         ;
 418
 419
 420 /*
 421         DECLARATIONS
 422 */
 423 assignment:
 424         STRING {
 425                 THIS->push_spot ();
 426         }
 427         /* cont */ '=' identifier_init  {
 428
 429         /*
 430                 Should find generic way of associating input with objects.
 431         */
 432                 Input ip = THIS->pop_spot ();
 433
 434                 if (! regular_identifier_b ($1))
 435                 {
 436                         ip.warning (_ ("Identifier should have  alphabetic characters only"));
 437                 }
 438
 439                 THIS->lexer_p_->set_identifier ($1, $4);
 440
 441 /*
 442  TODO: devise standard for protection in parser.
 443
 444   The parser stack lives on the C-stack, which means that
 445 all objects can be unprotected as soon as they're here.
 446
 447 */
 448         }
 449         ;
 450
 451
 452
 453 identifier_init:
 454         score_block {
 455                 $$ = $1->self_scm ();
 456                 scm_gc_unprotect_object ($$);
 457         }
 458         | output_def {
 459                 $$ = $1->self_scm ();
 460                 scm_gc_unprotect_object ($$);
 461         }
 462         | translator_spec_block {
 463                 $$ = $1;
 464         }
 465         | Music  {
 466                 $$ = $1->self_scm ();
 467                 scm_gc_unprotect_object ($$);
 468         }
 469         | post_request {
 470                 $$ = $1->self_scm ();
 471                 scm_gc_unprotect_object ($$);
 472         }
 473         | verbose_duration {
 474                 $$ = $1;
 475         }
 476         | number_expression {
 477                 $$ = $1;
 478         }
 479         | string {
 480                 $$ = $1;
 481         }
 482         | embedded_scm  {
 483                 $$ = $1;
 484         }
 485         ;
 486
 487 translator_spec_block:
 488         TRANSLATOR '{' translator_spec_body '}'
 489                 {
 490                 $$ = $3;
 491         }
 492         ;
 493
 494 translator_spec_body:
 495         TRANSLATOR_IDENTIFIER   {
 496                 $$ = unsmob_translator_def ($1)->clone_scm ();
 497                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 498         }
 499         | TYPE STRING   {
 500                 $$ = Translator_def::make_scm ();
 501                 Translator_def*td =  unsmob_translator_def ($$);
 502                 td->translator_group_type_ = $2;
 503                 td->set_spot (THIS->here_input ());
 504         }
 505         | translator_spec_body STRING '=' embedded_scm                  {
 506                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 507         }
 508         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 509                 unsmob_translator_def ($$)
 510                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 511         }
 512         | translator_spec_body STRING REVERT embedded_scm  {
 513           unsmob_translator_def ($$)->add_pop_property (
 514                 scm_string_to_symbol ($2), $4);
 515         }
 516         | translator_spec_body NAME STRING  {
 517                 unsmob_translator_def ($$)->type_name_ = $3;
 518         }
 519         | translator_spec_body CONSISTS STRING  {
 520                 unsmob_translator_def ($$)->add_element ($3);
 521         }
 522         | translator_spec_body ALIAS STRING  {
 523                 Translator_def*td = unsmob_translator_def ($$);
 524                 td->type_aliases_ = gh_cons ($3, td->type_aliases_);
 525         }
 526         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 527                 Translator_def*td = unsmob_translator_def($$);
 528                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 529                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 530                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 531         }
 532         | translator_spec_body CONSISTSEND STRING  {
 533                 unsmob_translator_def ($$)->add_last_element ( $3);
 534         }
 535         | translator_spec_body ACCEPTS STRING  {
 536                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 537         }
 538         | translator_spec_body DENIES STRING  {
 539                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 540         }
 541         | translator_spec_body REMOVE STRING  {
 542                 unsmob_translator_def ($$)->remove_element ($3);
 543         }
 544         ;
 545
 546 /*
 547         SCORE
 548 */
 549 score_block:
 550         SCORE {
 551                 THIS->push_spot ();
 552         }
 553         /*cont*/ '{' score_body '}'     {
 554                 THIS->pop_spot ();
 555                 $$ = $4;
 556                 if (!$$->def_p_arr_.size ())
 557                 {
 558                   Music_output_def *id =
 559                         unsmob_music_output_def (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 560                   $$->add_output (id ? id->clone () :  new Paper_def );
 561                 }
 562         }
 563         ;
 564
 565 score_body:
 566         Music   {
 567                 $$ = new Score;
 568
 569                 $$->set_spot (THIS->here_input ());
 570                 SCM m = $1->self_scm ();
 571                 scm_gc_unprotect_object (m);
 572                 $$->music_ = m;
 573
 574                 /*
 575                         guh.
 576                 */
 577                 SCM check_func = scm_c_eval_string ("check-start-chords");
 578                 gh_call1 (check_func, m);
 579
 580         }
 581         | SCORE_IDENTIFIER {
 582                 $$ = new Score (*unsmob_score ($1));
 583                 $$->set_spot (THIS->here_input ());
 584         }
 585         | score_body lilypond_header    {
 586                 scm_gc_unprotect_object ($2->self_scm ());
 587                 $$->header_p_ = $2;
 588         }
 589         | score_body output_def {
 590                 $$->add_output ($2);
 591         }
 592         | score_body error {
 593
 594         }
 595         ;
 596
 597
 598 /*
 599         MIDI
 600 */
 601 output_def:
 602         music_output_def_body '}' {
 603                 $$ = $1;
 604                 THIS-> lexer_p_-> scope_l_arr_.pop ();
 605         }
 606         ;
 607
 608 music_output_def_body:
 609         MIDI '{'    {
 610            Music_output_def *id = unsmob_music_output_def (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 611
 612
 613          Midi_def* p =0;
 614         if (id)
 615                 p = dynamic_cast<Midi_def*> (id->clone ());
 616         else
 617                 p = new Midi_def;
 618
 619          $$ = p;
 620          THIS->lexer_p_->scope_l_arr_.push (p->variable_tab_);
 621         }
 622         | PAPER '{'     {
 623                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 624                   Paper_def *p = 0;
 625                 if (id)
 626                         p = dynamic_cast<Paper_def*> (id->clone ());
 627                 else
 628                         p = new Paper_def;
 629                 THIS-> lexer_p_-> scope_l_arr_.push (p->variable_tab_);
 630                 $$ = p;
 631         }
 632         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 633                 Music_output_def *p = unsmob_music_output_def ($3);
 634                 p = p->clone ();
 635                 THIS->lexer_p_->scope_l_arr_.push (p->variable_tab_);
 636                 $$ = p;
 637         }
 638         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 639                 Music_output_def *p = unsmob_music_output_def ($3);
 640                 p = p->clone ();
 641
 642                 THIS->lexer_p_->scope_l_arr_.push (p->variable_tab_);
 643                 $$ = p;
 644         }
 645         | music_output_def_body assignment  {
 646
 647         }
 648         | music_output_def_body translator_spec_block   {
 649                 $$->assign_translator ($2);
 650         }
 651         | music_output_def_body STYLESHEET embedded_scm {
 652                 dynamic_cast<Paper_def*> ($$)-> style_sheet_ = $3;
 653         }
 654         | music_output_def_body tempo_request  {
 655                 /*
 656                         junk this ? there already is tempo stuff in
 657                         music.
 658                 */
 659                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 660                 Duration *d = unsmob_duration ($2->get_mus_property ("duration"));
 661                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 662                 if (md)
 663                         md->set_tempo (d->length_mom (), m);
 664         }
 665         | music_output_def_body error {
 666
 667         }
 668         ;
 669
 670 tempo_request:
 671         TEMPO steno_duration '=' bare_unsigned  {
 672                 $$ = new Tempo_req;
 673                 $$->set_mus_property ("duration", $2);
 674                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 675         }
 676         ;
 677
 678 /*
 679 The representation of a  list is the
 680
 681   (LIST . LAST-CONS)
 682
 683  to have  efficient append.
 684 */
 685 Music_list: /* empty */ {
 686                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 687         }
 688         | Music_list Music {
 689                 SCM s = $$;
 690                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 691                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 692                 if (gh_pair_p (ly_cdr (s)))
 693                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 694                 else
 695                         gh_set_car_x (s, c); /* set first cons */
 696                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 697         }
 698         | Music_list error {
 699         }
 700         ;
 701
 702
 703 Music:
 704         Simple_music
 705         | Composite_music
 706         ;
 707
 708 Alternative_music:
 709         /* empty */ {
 710                 $$ = SCM_EOL;
 711         }
 712         | ALTERNATIVE '{' Music_list '}' {
 713                 $$ = $3;
 714         }
 715         ;
 716
 717 Repeated_music:
 718         REPEAT string bare_unsigned Music Alternative_music
 719         {
 720                 Music *beg = $4;
 721                 int times = $3;
 722                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 723                 if (times < scm_ilength (alts)) {
 724                   unsmob_music (gh_car (alts))
 725                     ->origin ()->warning (
 726                     _("More alternatives than repeats.  Junking excess alternatives."));
 727                   alts = ly_truncate_list (times, alts);
 728                 }
 729
 730                 Repeated_music * r = new Repeated_music (SCM_EOL);
 731                 if (beg)
 732                         {
 733                         r-> set_mus_property ("element", beg->self_scm ());
 734                         scm_gc_unprotect_object (beg->self_scm ());
 735                         }
 736                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 737
 738                 r-> set_mus_property ("elements",alts);
 739                 SCM func = scm_primitive_eval (ly_symbol2scm ("repeat-name-to-ctor"));
 740                 SCM result = gh_call1 (func, $2);
 741
 742                 set_music_properties (r, result);
 743
 744                 r->set_spot (*$4->origin ());
 745                 $$ = r;
 746         }
 747         ;
 748
 749 Sequential_music:
 750         SEQUENTIAL '{' Music_list '}'           {
 751                 $$ = new Sequential_music (SCM_EOL);
 752                 $$->set_mus_property ("elements", ly_car ($3));
 753                 $$->set_spot(THIS->here_input());
 754         }
 755         | '{' Music_list '}'            {
 756                 $$ = new Sequential_music (SCM_EOL);
 757                 $$->set_mus_property ("elements", ly_car ($2));
 758                 $$->set_spot(THIS->here_input());
 759         }
 760         ;
 761
 762 Simultaneous_music:
 763         SIMULTANEOUS '{' Music_list '}'{
 764                 $$ = new Simultaneous_music (SCM_EOL);
 765                 $$->set_mus_property ("elements", ly_car ($3));
 766                 $$->set_spot(THIS->here_input());
 767
 768         }
 769         | '<' Music_list '>'    {
 770                 $$ = new Simultaneous_music (SCM_EOL);
 771                 $$->set_mus_property ("elements", ly_car ($2));
 772                 $$->set_spot(THIS->here_input());
 773         }
 774         ;
 775
 776 Simple_music:
 777         request_chord           { $$ = $1; }
 778         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 779                 SCM pred = $2;
 780                 if (!gh_symbol_p ($3))
 781                 {
 782                         THIS->parser_error (_ ("Second argument must be a symbol"));
 783                 }
 784                 /*hould check # args */
 785                 if (!gh_procedure_p (pred))
 786                 {
 787                         THIS->parser_error (_ ("First argument must be a procedure taking 1 argument"));
 788                 }
 789
 790                 Music *m = new Music (SCM_EOL);
 791                 m->set_mus_property ("predicate", pred);
 792                 m->set_mus_property ("grob-property", $3);
 793                 m->set_mus_property ("grob-value",  $5);
 794                 m->set_mus_property ("iterator-ctor",
 795                 Output_property_music_iterator::constructor_cxx_function);
 796
 797                 $$ = m;
 798         }
 799         | MUSIC_IDENTIFIER {
 800                 $$ = unsmob_music ($1)->clone ();
 801
 802                 $$->set_spot (THIS->here_input());
 803         }
 804         | property_def
 805         | translator_change
 806         ;
 807
 808
 809 Composite_music:
 810         CONTEXT STRING Music    {
 811                 Context_specced_music *csm =  new Context_specced_music (SCM_EOL);
 812                 csm->set_mus_property ("element", $3->self_scm ());
 813                 scm_gc_unprotect_object ($3->self_scm ());
 814
 815                 csm->set_mus_property ("context-type",$2);
 816                 csm->set_mus_property ("context-id", ly_str02scm (""));
 817
 818                 $$ = csm;
 819         }
 820         | AUTOCHANGE STRING Music       {
 821                 Music * chm = new Music_wrapper (SCM_EOL);
 822                 chm->set_mus_property ("element", $3->self_scm ());
 823                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_cxx_function);
 824
 825                 scm_gc_unprotect_object ($3->self_scm ());
 826                 chm->set_mus_property ("what", $2);
 827
 828                 $$ = chm;
 829                 chm->set_spot (*$3->origin ());
 830         }
 831         | GRACE Music {
 832 #if 1
 833         /*
 834                 The other version is for easier debugging  of
 835                 Sequential_music_iterator in combination with grace notes.
 836         */
 837
 838                 SCM start = THIS->lexer_p_->lookup_identifier ("startGraceMusic");
 839                 SCM stop = THIS->lexer_p_->lookup_identifier ("stopGraceMusic");
 840                 Music *startm = unsmob_music (start);
 841                 Music *stopm = unsmob_music (stop);
 842
 843                 SCM ms = SCM_EOL;
 844                 if (stopm) {
 845                         stopm = stopm->clone ();
 846                         ms = gh_cons (stopm->self_scm (), ms);
 847                         scm_gc_unprotect_object (stopm->self_scm ());
 848                 }
 849                 ms = gh_cons ($2->self_scm (), ms);
 850                 scm_gc_unprotect_object ($2->self_scm());
 851                 if (startm) {
 852                         startm = startm->clone ();
 853                         ms = gh_cons (startm->self_scm () , ms);
 854                         scm_gc_unprotect_object (startm->self_scm ());
 855                 }
 856
 857                 Music* seq = new Sequential_music (SCM_EOL);
 858                 seq->set_mus_property ("elements", ms);
 859
 860                 $$ = new Grace_music (SCM_EOL);
 861                 $$->set_mus_property ("element", seq->self_scm ());
 862                 scm_gc_unprotect_object (seq->self_scm ());
 863 #else
 864                 $$ = new Grace_music (SCM_EOL);
 865                 $$->set_mus_property ("element", $2->self_scm ());
 866                 scm_gc_unprotect_object ($2->self_scm ());
 867 #endif
 868         }
 869         | CONTEXT string '=' string Music {
 870                 Context_specced_music *csm =  new Context_specced_music (SCM_EOL);
 871                 csm->set_mus_property ("element", $5->self_scm ());
 872                 scm_gc_unprotect_object ($5->self_scm ());
 873
 874                 csm->set_mus_property ("context-type", $2);
 875                 csm->set_mus_property ("context-id", $4);
 876
 877                 $$ = csm;
 878         }
 879         | TIMES {
 880                 THIS->push_spot ();
 881         }
 882         /* CONTINUED */
 883                 fraction Music
 884
 885         {
 886                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 887                 Music *mp = $4;
 888                 $$ = new Time_scaled_music (SCM_EOL);
 889                 $$->set_spot (THIS->pop_spot ());
 890
 891
 892                 $$->set_mus_property ("element", mp->self_scm ());
 893                 scm_gc_unprotect_object (mp->self_scm ());
 894                 $$->set_mus_property ("numerator", gh_int2scm (n));
 895                 $$->set_mus_property ("denominator", gh_int2scm (d));
 896                 $$->compress (Moment (Rational (n,d)));
 897
 898         }
 899         | Repeated_music                { $$ = $1; }
 900         | Simultaneous_music            { $$ = $1; }
 901         | Sequential_music              { $$ = $1; }
 902         | TRANSPOSE pitch Music {
 903                 $$ = new Transposed_music (SCM_EOL);
 904                 Music *p = $3;
 905                 Pitch pit = *unsmob_pitch ($2);
 906
 907                 p->transpose (pit);
 908                 $$->set_mus_property ("element", p->self_scm ());
 909                 scm_gc_unprotect_object (p->self_scm ());
 910         }
 911         | TRANSPOSE steno_tonic_pitch Music {
 912                 $$ = new Transposed_music (SCM_EOL);
 913                 Music *p = $3;
 914                 Pitch pit = *unsmob_pitch ($2);
 915
 916                 p->transpose (pit);
 917                 $$->set_mus_property ("element", p->self_scm ());
 918                 scm_gc_unprotect_object (p->self_scm ());
 919
 920         }
 921         | APPLY embedded_scm Music  {
 922                 SCM ret = gh_call1 ($2, $3->self_scm ());
 923                 Music *m = unsmob_music (ret);
 924                 if (!m) {
 925                         THIS->parser_error ("\\apply must return a Music");
 926                         m = new Music (SCM_EOL);
 927                         }
 928                 $$ = m;
 929         }
 930         | NOTES
 931                 { THIS->lexer_p_->push_note_state (); }
 932         Music
 933                 { $$ = $3;
 934                   THIS->lexer_p_->pop_state ();
 935                 }
 936         | FIGURES
 937                 { THIS->lexer_p_->push_figuredbass_state (); }
 938         Music
 939                 {
 940                   Music * chm = new Untransposable_music () ;
 941                   chm->set_mus_property ("element", $3->self_scm ());
 942                   $$ = chm;
 943
 944                   THIS->lexer_p_->pop_state ();
 945         }
 946         | CHORDS
 947                 { THIS->lexer_p_->push_chord_state (); }
 948         Music
 949                 {
 950                   Music * chm = new Un_relativable_music ;
 951                   chm->set_mus_property ("element", $3->self_scm ());
 952                   $$ = chm;
 953
 954                   THIS->lexer_p_->pop_state ();
 955         }
 956         | LYRICS
 957                 { THIS->lexer_p_->push_lyric_state (); }
 958         Music
 959                 {
 960                   $$ = $3;
 961                   THIS->lexer_p_->pop_state ();
 962         }
 963         | relative_music        { $$ = $1; }
 964         | re_rhythmed_music     { $$ = $1; }
 965         | part_combined_music   { $$ = $1; }
 966         ;
 967
 968 relative_music:
 969         RELATIVE absolute_pitch Music {
 970                 Music * p = $3;
 971                 Pitch pit = *unsmob_pitch ($2);
 972                 $$ = new Relative_octave_music (SCM_EOL);
 973
 974                 $$->set_mus_property ("element", p->self_scm ());
 975                 scm_gc_unprotect_object (p->self_scm ());
 976
 977                 $$->set_mus_property ("last-pitch", p->to_relative_octave (pit).smobbed_copy ());
 978
 979         }
 980         ;
 981
 982 re_rhythmed_music:
 983         ADDLYRICS Music Music {
 984           Lyric_combine_music * l = new Lyric_combine_music (SCM_EOL);
 985           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
 986           scm_gc_unprotect_object ($3->self_scm ());
 987           scm_gc_unprotect_object ($2->self_scm ());
 988           $$ = l;
 989         }
 990         ;
 991
 992 part_combined_music:
 993         PARTCOMBINE STRING Music Music {
 994                 Part_combine_music * p = new Part_combine_music (SCM_EOL);
 995
 996                 p->set_mus_property ("what", $2);
 997                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
 998
 999                 scm_gc_unprotect_object ($3->self_scm ());
1000                 scm_gc_unprotect_object ($4->self_scm ());
1001
1002                 $$ = p;
1003         }
1004         ;
1005
1006 translator_change:
1007         TRANSLATOR STRING '=' STRING  {
1008                 Music * t = new Music (SCM_EOL);
1009                 t->set_mus_property ("iterator-ctor",
1010                         Change_iterator::constructor_cxx_function);
1011                 t-> set_mus_property ("change-to-type", $2);
1012                 t-> set_mus_property ("change-to-id", $4);
1013
1014                 $$ = t;
1015                 $$->set_spot (THIS->here_input ());
1016         }
1017         ;
1018
1019 property_def:
1020         PROPERTY STRING '.' STRING '='  scalar {
1021
1022                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1023                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1024
1025                 csm->set_mus_property ("element", t->self_scm ());
1026                 scm_gc_unprotect_object (t->self_scm ());
1027
1028                 $$ = csm;
1029                 $$->set_spot (THIS->here_input ());
1030
1031                 csm-> set_mus_property ("context-type", $2);
1032         }
1033         | PROPERTY STRING '.' STRING UNSET {
1034                 Music *t = new Music (SCM_EOL);
1035
1036                 t->set_mus_property ("iterator-ctor",
1037                         Property_unset_iterator::constructor_cxx_function);
1038                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1039
1040                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1041                 csm->set_mus_property ("element", t->self_scm ());
1042                 scm_gc_unprotect_object (t->self_scm ());
1043
1044                 $$ = csm;
1045                 $$->set_spot (THIS->here_input ());
1046
1047                 csm-> set_mus_property ("context-type", $2);
1048         }
1049         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1050                 Music *t = new Music (SCM_EOL);
1051                 t->set_mus_property ("iterator-ctor",
1052                         Push_property_iterator::constructor_cxx_function);
1053                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1054                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1055                 t->set_mus_property ("grob-property", $6);
1056                 t->set_mus_property ("grob-value", $8);
1057                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1058                 csm->set_mus_property ("element", t->self_scm ());
1059                 scm_gc_unprotect_object (t->self_scm ());
1060                 $$ = csm;
1061                 $$->set_spot (THIS->here_input ());
1062
1063                 csm-> set_mus_property ("context-type", $2);
1064         }
1065         | PROPERTY STRING '.' STRING OVERRIDE embedded_scm '=' embedded_scm {
1066                 Music *t = new Music (SCM_EOL);
1067                 t->set_mus_property ("iterator-ctor",
1068                         Push_property_iterator::constructor_cxx_function);
1069                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1070                 t->set_mus_property ("grob-property", $6);
1071                 t->set_mus_property ("grob-value", $8);
1072                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1073                 csm->set_mus_property ("element", t->self_scm ());
1074                 scm_gc_unprotect_object (t->self_scm ());
1075
1076                 $$ = csm;
1077                 $$->set_spot (THIS->here_input ());
1078
1079                 csm-> set_mus_property ("context-type", $2);
1080         }
1081         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1082                 Music *t = new Music (SCM_EOL);
1083                 t->set_mus_property ("iterator-ctor",
1084                         Pop_property_iterator::constructor_cxx_function);
1085                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1086                 t->set_mus_property ("grob-property", $6);
1087
1088                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1089                 csm->set_mus_property ("element", t->self_scm ());
1090                 scm_gc_unprotect_object (t->self_scm ());
1091
1092                 $$ = csm;
1093                 $$->set_spot (THIS->here_input ());
1094
1095                 csm-> set_mus_property ("context-type", $2);
1096         }
1097         ;
1098
1099 scalar:
1100         string          { $$ = $1; }
1101         | bare_int      { $$ = gh_int2scm ($1); }
1102         | embedded_scm  { $$ = $1; }
1103         ;
1104
1105
1106 request_chord:
1107         pre_requests {
1108                 THIS->push_spot ();
1109         } /*cont */ simple_element post_requests        {
1110                 Music_sequence *l = dynamic_cast<Music_sequence*> ($3);
1111
1112                 $1->concat (*$4);
1113                 for (int i=0; i < $1->size (); i++) {
1114                   Music * m = $1->elem (i);
1115                   l->append_music (m);
1116                 }
1117                 $$ = $3;
1118
1119                 delete $1;
1120                 delete $4;
1121         }
1122         | command_element
1123         ;
1124
1125 command_element:
1126         command_req {
1127                 $$ = new Request_chord (SCM_EOL);
1128                 $$->set_mus_property ("elements", gh_cons ($1->self_scm (), SCM_EOL));
1129                 $$-> set_spot (THIS->here_input ());
1130                 $1-> set_spot (THIS->here_input ());
1131         }
1132         | E_LEFTSQUARE {
1133                 Span_req *l = new Span_req;
1134                 l->set_span_dir (START);
1135                 l->set_mus_property ("span-type", ly_str02scm ("ligature"));
1136                 l->set_spot (THIS->here_input ());
1137
1138                 $$ = new Request_chord (SCM_EOL);
1139                 $$->set_mus_property ("elements", gh_cons (l->self_scm (), SCM_EOL));
1140                 $$->set_spot (THIS->here_input ());
1141         }
1142         | E_RIGHTSQUARE {
1143                 Span_req *l = new Span_req;
1144                 l->set_span_dir (STOP);
1145                 l->set_mus_property ("span-type", ly_str02scm ("ligature"));
1146                 l->set_spot (THIS->here_input ());
1147
1148                 $$ = new Request_chord (SCM_EOL);
1149                 $$->set_mus_property ("elements", gh_cons (l->self_scm (), SCM_EOL));
1150                 $$->set_spot (THIS->here_input ());
1151         }
1152         | E_BACKSLASH {
1153                 $$ = new Music (gh_list (gh_cons (ly_symbol2scm ("name"), ly_symbol2scm ("separator")), SCM_UNDEFINED));
1154                 $$->set_spot (THIS->here_input ());
1155         }
1156         | '|'      {
1157
1158                 extern Music * get_barcheck();
1159                 $$ = get_barcheck ();
1160                 $$->set_spot (THIS->here_input ());
1161         }
1162         | BAR STRING                    {
1163                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1164
1165                 Context_specced_music *csm = new Context_specced_music (SCM_EOL);
1166                 csm->set_mus_property ("element", t->self_scm ());
1167                 scm_gc_unprotect_object (t->self_scm ());
1168
1169                 $$ = csm;
1170                 $$->set_spot (THIS->here_input ());
1171
1172                 csm->set_mus_property ("context-type", ly_str02scm ("Score"));
1173         }
1174         | PARTIAL duration_length       {
1175                 Moment m = - unsmob_duration ($2)->length_mom ();
1176                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1177
1178                 Context_specced_music * sp = new Context_specced_music (SCM_EOL);
1179                 sp->set_mus_property ("element", p->self_scm ());
1180                 scm_gc_unprotect_object (p->self_scm ());
1181
1182                 $$ =sp ;
1183                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
1184         }
1185         | CLEF STRING  {
1186                 SCM func = scm_primitive_eval (ly_symbol2scm ("clef-name-to-properties"));
1187                 SCM result = gh_call1 (func, $2);
1188
1189                 SCM l = SCM_EOL;
1190                 for (SCM s = result ; gh_pair_p (s); s = ly_cdr (s)) {
1191                         Music * p = new Music (SCM_EOL);
1192                         set_music_properties (p, ly_car (s));
1193                         l = gh_cons (p->self_scm (), l);
1194                         scm_gc_unprotect_object (p->self_scm ());
1195                 }
1196                 Sequential_music * seq = new Sequential_music (SCM_EOL);
1197                 seq->set_mus_property ("elements", l);
1198
1199                 Context_specced_music * sp = new Context_specced_music (SCM_EOL);
1200                 sp->set_mus_property ("element", seq->self_scm ());
1201                 scm_gc_unprotect_object (seq->self_scm ());
1202
1203                 $$ =sp ;
1204                 sp-> set_mus_property ("context-type", ly_str02scm ("Staff"));
1205         }
1206         | TIME_T fraction  {
1207                 Music * p1 = set_property_music (ly_symbol2scm ( "timeSignatureFraction"), $2);
1208
1209                 int l = gh_scm2int (ly_car ($2));
1210                 int o = gh_scm2int (ly_cdr ($2));
1211
1212                 Moment one_beat = Moment (1)/Moment (o);
1213                 Moment len = Moment (l) * one_beat;
1214
1215
1216                 Music *p2 = set_property_music (ly_symbol2scm ("measureLength"), len.smobbed_copy ());
1217                 Music *p3 = set_property_music (ly_symbol2scm ("beatLength"), one_beat.smobbed_copy ());
1218
1219                 SCM list = scm_list_n (p1->self_scm (), p2->self_scm (), p3->self_scm(), SCM_UNDEFINED);
1220                 Sequential_music *seq = new Sequential_music (SCM_EOL);
1221                 seq->set_mus_property ("elements", list);
1222
1223
1224                 Context_specced_music * sp = new Context_specced_music (SCM_EOL);
1225                 sp->set_mus_property ("element", seq->self_scm ());
1226
1227
1228
1229                 scm_gc_unprotect_object (p3->self_scm ());
1230                 scm_gc_unprotect_object (p2->self_scm ());
1231                 scm_gc_unprotect_object (p1->self_scm ());
1232                 scm_gc_unprotect_object (seq->self_scm ());
1233
1234                 $$ = sp;
1235
1236 /*
1237  TODO: should make alias TimingContext for Score
1238 */
1239
1240                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
1241         }
1242         ;
1243
1244 command_req:
1245         shorthand_command_req   { $$ = $1; }
1246         | verbose_command_req   { $$ = $1; }
1247         ;
1248
1249 shorthand_command_req:
1250         extender_req {
1251                 $$ = $1;
1252         }
1253         | hyphen_req {
1254                 $$ = $1;
1255         }
1256         | '~'   {
1257                 $$ = new Tie_req;
1258         }
1259         | '['           {
1260                 Span_req*b= new Span_req;
1261                 b->set_span_dir (START);
1262                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1263                 $$ =b;
1264
1265
1266                 THIS->last_beam_start_ = b->self_scm ();
1267         }
1268         | ']'           {
1269                 Span_req*b= new Span_req;
1270                 b->set_span_dir ( STOP);
1271                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1272                 $$ = b;
1273         }
1274         | BREATHE {
1275                 $$ = new Breathing_sign_req;
1276         }
1277         | E_TILDE {
1278                 $$ = new Porrectus_req;
1279         }
1280         ;
1281
1282 verbose_command_req:
1283         COMMANDSPANREQUEST bare_int STRING { /*TODO: junkme */
1284                 Span_req * sp_p = new Span_req;
1285                 sp_p-> set_span_dir ( Direction ($2));
1286                 sp_p->set_mus_property ("span-type",$3);
1287                 sp_p->set_spot (THIS->here_input ());
1288                 $$ = sp_p;
1289         }
1290         | MARK DEFAULT  {
1291                 Mark_req * m = new Mark_req;
1292                 $$ = m;
1293         }
1294         | MARK scalar {
1295                 Mark_req *m = new Mark_req;
1296                 m->set_mus_property ("label", $2);
1297                 $$ = m;
1298
1299         }
1300         | PENALTY SCM_T         {
1301                 Break_req * b = new Break_req;
1302                 SCM s = $2;
1303                 if (!gh_number_p (s))
1304                         s  =gh_int2scm (0);
1305
1306                 b->set_mus_property ("penalty", s);
1307                 b->set_spot (THIS->here_input ());
1308                 $$ = b;
1309         }
1310         | SKIP duration_length {
1311                 Skip_req * skip_p = new Skip_req;
1312                 skip_p->set_mus_property ("duration", $2);
1313
1314                 $$ = skip_p;
1315         }
1316         | tempo_request {
1317                 $$ = $1;
1318         }
1319         | KEY DEFAULT {
1320                 Key_change_req *key_p= new Key_change_req;
1321                 $$ = key_p;
1322         }
1323         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1324                 Key_change_req *key_p= new Key_change_req;
1325
1326                 key_p->set_mus_property ("pitch-alist", $3);
1327                 ((Music*)key_p)->transpose (* unsmob_pitch ($2));
1328                 $$ = key_p;
1329         }
1330         ;
1331
1332 post_requests:
1333         {
1334                 $$ = new Link_array<Request>;
1335         }
1336         | post_requests post_request {
1337                 $2->set_spot (THIS->here_input ());
1338                 $$->push ($2);
1339         }
1340         ;
1341
1342 post_request:
1343         verbose_request
1344         | request_with_dir
1345         | close_request
1346         ;
1347
1348
1349 request_that_take_dir:
1350         gen_text_def
1351         | verbose_request
1352         | script_abbreviation {
1353                 SCM s = THIS->lexer_p_->lookup_identifier ("dash" + ly_scm2string ($1));
1354                 Articulation_req *a = new Articulation_req;
1355                 if (gh_string_p (s))
1356                         a->set_mus_property ("articulation-type", s);
1357                 else THIS->parser_error (_ ("Expecting string as script definition"));
1358                 $$ = a;
1359         }
1360         ;
1361
1362 request_with_dir:
1363         script_dir request_that_take_dir        {
1364                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1365                         gs->set_direction (Direction ($1));
1366                 else if ($1)
1367                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1368                 $$ = $2;
1369         }
1370         ;
1371
1372 verbose_request:
1373         REQUEST_IDENTIFIER      {
1374                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1375                 $$->set_spot (THIS->here_input ());
1376         }
1377         | DYNAMICSCRIPT embedded_scm {
1378                 /*
1379                         TODO: junkme, use text-type == dynamic
1380                 */
1381                 Text_script_req *d = new Text_script_req;
1382                 SCM dyn = ly_symbol2scm ("dynamic");
1383                 d->set_mus_property ("text-type" , dyn);
1384                 d->set_mus_property ("text", $2);
1385                 d->set_spot (THIS->here_input ());
1386                 $$ = d;
1387         }
1388         | SPANREQUEST bare_int STRING {
1389                 Span_req * sp_p = new Span_req;
1390                 sp_p->set_span_dir ( Direction ($2));
1391                 sp_p->set_mus_property ("span-type", $3);
1392                 sp_p->set_spot (THIS->here_input ());
1393                 $$ = sp_p;
1394         }
1395         | tremolo_type  {
1396                Tremolo_req* a = new Tremolo_req;
1397                a->set_spot (THIS->here_input ());
1398                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1399                $$ = a;
1400         }
1401         | SCRIPT STRING         {
1402                 Articulation_req * a = new Articulation_req;
1403                 a->set_mus_property ("articulation-type", $2);
1404                 a->set_spot (THIS->here_input ());
1405                 $$ = a;
1406         }
1407         /*
1408 duh, junk this syntax from the parser, if possible.
1409         */
1410         | ARPEGGIO {
1411                 Arpeggio_req *a = new Arpeggio_req;
1412                 a->set_spot (THIS->here_input ());
1413                 $$ = a;
1414         }
1415         | GLISSANDO {
1416                 Glissando_req *g = new Glissando_req;
1417                 g->set_spot /* No pun intended */ (THIS->here_input ());
1418                 $$ = g;
1419         }
1420         ;
1421
1422 sup_quotes:
1423         '\'' {
1424                 $$ = 1;
1425         }
1426         | sup_quotes '\'' {
1427                 $$ ++;
1428         }
1429         ;
1430
1431 sub_quotes:
1432         ',' {
1433                 $$ = 1;
1434         }
1435         | sub_quotes ',' {
1436                 $$ ++ ;
1437         }
1438         ;
1439
1440 steno_pitch:
1441         NOTENAME_PITCH  {
1442                 $$ = $1;
1443         }
1444         | NOTENAME_PITCH sup_quotes     {
1445                 Pitch p = *unsmob_pitch ($1);
1446                 p.octave_i_ +=  $2;
1447                 $$ = p.smobbed_copy ();
1448         }
1449         | NOTENAME_PITCH sub_quotes      {
1450                 Pitch p =* unsmob_pitch ($1);
1451
1452                 p.octave_i_ +=  -$2;
1453                 $$ = p.smobbed_copy ();
1454
1455         }
1456         ;
1457
1458 /*
1459 ugh. duplication
1460 */
1461
1462 steno_tonic_pitch:
1463         TONICNAME_PITCH {
1464                 $$ = $1;
1465         }
1466         | TONICNAME_PITCH sup_quotes    {
1467                 Pitch p = *unsmob_pitch ($1);
1468                 p.octave_i_ +=  $2;
1469                 $$ = p.smobbed_copy ();
1470         }
1471         | TONICNAME_PITCH sub_quotes     {
1472                 Pitch p =* unsmob_pitch ($1);
1473
1474                 p.octave_i_ +=  -$2;
1475                 $$ = p.smobbed_copy ();
1476
1477         }
1478         ;
1479
1480 pitch:
1481         steno_pitch {
1482                 $$ = $1;
1483         }
1484         | explicit_pitch {
1485                 $$ = $1;
1486         }
1487         ;
1488
1489 explicit_pitch:
1490         PITCH embedded_scm {
1491                 $$ = $2;
1492                 if (!unsmob_pitch ($2)) {
1493                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1494                          $$ = Pitch ().smobbed_copy ();
1495                 }
1496         }
1497         ;
1498
1499 verbose_duration:
1500         DURATION embedded_scm   {
1501                 $$ = $2;
1502                 if (!unsmob_duration ($2))
1503                 {
1504                         THIS->parser_error (_ ("Must have duration object"));
1505                         $$ = Duration ().smobbed_copy ();
1506                 }
1507         }
1508         ;
1509
1510 extender_req:
1511         EXTENDER {
1512                 if (!THIS->lexer_p_->lyric_state_b ())
1513                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1514                 $$ = new Extender_req;
1515         }
1516         ;
1517
1518 hyphen_req:
1519         HYPHEN {
1520                 if (!THIS->lexer_p_->lyric_state_b ())
1521                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1522                 $$ = new Hyphen_req;
1523         }
1524         ;
1525
1526 close_request:
1527         close_request_parens {
1528                 $$ = $1;
1529                 dynamic_cast<Span_req*> ($$)->set_span_dir ( START);
1530         }
1531         ;
1532
1533 close_request_parens:
1534         '('     {
1535                 Span_req* s= new Span_req;
1536                 $$ = s;
1537                 s->set_mus_property ("span-type", ly_str02scm ( "slur"));
1538                 s->set_spot (THIS->here_input());
1539         }
1540         | E_OPEN        {
1541                 Span_req* s= new Span_req;
1542                 $$ = s;
1543                 s->set_mus_property ("span-type", ly_str02scm ( "phrasing-slur"));
1544                 s->set_spot (THIS->here_input());
1545         }
1546         | E_SMALLER {
1547                 Span_req*s =new Span_req;
1548                 $$ = s;
1549                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1550                 s->set_spot (THIS->here_input());
1551         }
1552         | E_BIGGER {
1553                 Span_req*s =new Span_req;
1554                 $$ = s;
1555                 s->set_mus_property ("span-type", ly_str02scm ("decrescendo"));
1556                 s->set_spot (THIS->here_input());
1557         }
1558         ;
1559
1560
1561 open_request:
1562         open_request_parens {
1563                 $$ = $1;
1564                 dynamic_cast<Span_req*> ($$)->set_span_dir (STOP);
1565         }
1566         ;
1567
1568 open_request_parens:
1569         E_EXCLAMATION   {
1570                 Span_req *s =  new Span_req;
1571                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1572                 s->set_spot (THIS->here_input());
1573
1574                 $$ = s;
1575         }
1576         | ')'   {
1577                 Span_req* s= new Span_req;
1578                 $$ = s;
1579                 s->set_mus_property ("span-type", ly_str02scm ( "slur"));
1580                 s->set_spot (THIS->here_input());
1581
1582         }
1583         | E_CLOSE       {
1584                 Span_req* s= new Span_req;
1585                 $$ = s;
1586                 s->set_mus_property ("span-type", ly_str02scm ( "phrasing-slur"));
1587                 s->set_spot (THIS->here_input());
1588         }
1589         ;
1590
1591 gen_text_def:
1592         embedded_scm {
1593                 Text_script_req *t = new Text_script_req;
1594                 t->set_mus_property ("text", $1);
1595                 t->set_spot (THIS->here_input ());
1596                 $$ = t;
1597         }
1598         | string {
1599                 Text_script_req *t = new Text_script_req;
1600                 t->set_mus_property ("text", $1);
1601                 t->set_spot (THIS->here_input ());
1602                 $$ = t;
1603         }
1604         | DIGIT {
1605                 String ds = to_str ($1);
1606                 Text_script_req* t = new Text_script_req;
1607                 SCM finger = ly_symbol2scm ("finger");
1608                 t->set_mus_property ("text",  ly_str02scm (ds.ch_C ()));
1609                 t->set_mus_property ("text-type" , finger);
1610                 t->set_spot (THIS->here_input ());
1611                 $$ = t;
1612         }
1613         ;
1614
1615 script_abbreviation:
1616         '^'             {
1617                 $$ = gh_str02scm ("Hat");
1618         }
1619         | '+'           {
1620                 $$ = gh_str02scm ("Plus");
1621         }
1622         | '-'           {
1623                 $$ = gh_str02scm ("Dash");
1624         }
1625         | '|'           {
1626                 $$ = gh_str02scm ("Bar");
1627         }
1628         | '>'           {
1629                 $$ = gh_str02scm ("Larger");
1630         }
1631         | '.'           {
1632                 $$ = gh_str02scm ("Dot");
1633         }
1634         ;
1635
1636 script_dir:
1637         '_'     { $$ = DOWN; }
1638         | '^'   { $$ = UP; }
1639         | '-'   { $$ = CENTER; }
1640         ;
1641
1642 pre_requests:
1643         {
1644                 $$ = new Link_array<Request>;
1645         }
1646         | pre_requests open_request {
1647                 $$->push ($2);
1648         }
1649         ;
1650
1651 absolute_pitch:
1652         steno_pitch     {
1653                 $$ = $1;
1654         }
1655         ;
1656
1657 duration_length:
1658         multiplied_duration {
1659                 $$ = $1;
1660         }
1661         | verbose_duration {
1662                 $$ = $1;
1663         }
1664         ;
1665
1666 optional_notemode_duration:
1667         {
1668                 Duration dd = THIS->default_duration_;
1669                 $$ = dd.smobbed_copy ();
1670
1671                 THIS->beam_check ($$);
1672         }
1673         | multiplied_duration   {
1674                 $$ = $1;
1675                 THIS->default_duration_ = *unsmob_duration ($$);
1676
1677                 THIS->beam_check ($$);
1678         }
1679         | verbose_duration {
1680                 $$ = $1;
1681                 THIS->default_duration_ = *unsmob_duration ($$);
1682         }
1683         ;
1684
1685 steno_duration:
1686         bare_unsigned dots              {
1687                 int l = 0;
1688                 if (!is_duration_b ($1))
1689                         THIS->parser_error (_f ("not a duration: %d", $1));
1690                 else
1691                         l =  intlog2 ($1);
1692
1693                 $$ = Duration (l, $2).smobbed_copy ();
1694         }
1695         | DURATION_IDENTIFIER dots      {
1696                 Duration *d =unsmob_duration ($1);
1697                 Duration k (d->duration_log (),d->dot_count () + $2);
1698                 $$ = k.smobbed_copy ();
1699         }
1700         ;
1701
1702
1703
1704
1705 multiplied_duration:
1706         steno_duration {
1707                 $$ = $1;
1708         }
1709         | multiplied_duration '*' bare_unsigned {
1710                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1711         }
1712         | multiplied_duration '*' FRACTION {
1713                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1714
1715                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1716         }
1717         ;
1718
1719 fraction:
1720         FRACTION { $$ = $1; }
1721         | UNSIGNED '/' UNSIGNED {
1722                 $$ = gh_cons (gh_int2scm ($1), gh_int2scm ($3));
1723         }
1724         ;
1725
1726 dots:
1727         /* empty */     {
1728                 $$ = 0;
1729         }
1730         | dots '.' {
1731                 $$ ++;
1732         }
1733         ;
1734
1735
1736 tremolo_type:
1737         ':'     {
1738                 $$ =0;
1739         }
1740         | ':' bare_unsigned {
1741                 if (!is_duration_b ($2))
1742                         THIS->parser_error (_f ("not a duration: %d", $2));
1743                 $$ = $2;
1744         }
1745         ;
1746
1747
1748 bass_number:
1749         DIGIT
1750         | UNSIGNED
1751         ;
1752
1753 bass_mod:
1754         '-'     { $$ = -1; }
1755         | '+'   { $$ = 1; }
1756         | '!'   { $$ = 0; }
1757         ;
1758
1759 bass_figure:
1760         FIGURE_SPACE {
1761                 Bass_figure_req *bfr = new Bass_figure_req;
1762                 $$ = bfr->self_scm();
1763                 scm_gc_unprotect_object ($$);
1764         }
1765         | bass_number  {
1766                 Bass_figure_req *bfr = new Bass_figure_req;
1767                 $$ = bfr->self_scm();
1768
1769                 bfr->set_mus_property ("figure", gh_int2scm ($1));
1770
1771                 scm_gc_unprotect_object ($$);
1772         }
1773         | bass_figure bass_mod {
1774                 Music *m = unsmob_music ($1);
1775                 if ($2) {
1776                         SCM salter =m->get_mus_property ("alteration");
1777                         int alter = gh_number_p( salter) ? gh_scm2int (salter) : 0;
1778                         m->set_mus_property ("alteration",
1779                                 gh_int2scm (alter + $2));
1780                 } else {
1781                         m->set_mus_property ("alteration", gh_int2scm (0));
1782                 }
1783         }
1784         ;
1785
1786 br_bass_figure:
1787         '[' bass_figure {
1788                 $$ = $2;
1789                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1790         }
1791         | bass_figure   {
1792                 $$ = $1;
1793         }
1794         | br_bass_figure ']' {
1795                 $$ = $1;
1796                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1797         }
1798         ;
1799
1800 figure_list:
1801         /**/            {
1802                 $$ = SCM_EOL;
1803         }
1804         | figure_list br_bass_figure {
1805                 $$ = gh_cons ($2, $1);
1806         }
1807         ;
1808
1809 figure_spec:
1810         FIGURE_OPEN figure_list FIGURE_CLOSE {
1811                 Music * m = new Request_chord (SCM_EOL);
1812                 $2 = scm_reverse_x ($2, SCM_EOL);
1813                 m->set_mus_property ("elements",  $2);
1814                 $$ = m->self_scm ();
1815         }
1816         ;
1817
1818
1819 optional_rest:
1820         /**/   { $$ = 0; }
1821         | REST { $$ = 1; }
1822         ;
1823
1824 simple_element:
1825         pitch exclamations questions optional_notemode_duration optional_rest {
1826
1827                 Input i = THIS->pop_spot ();
1828                 if (!THIS->lexer_p_->note_state_b ())
1829                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1830
1831                 Music *n = 0;
1832                 if ($5)
1833                         n =  new Rest_req ;
1834                 else
1835                         n =  new Note_req;
1836
1837                 n->set_mus_property ("pitch", $1);
1838                 n->set_mus_property ("duration", $4);
1839
1840
1841                 if ($3 % 2)
1842                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1843                 if ($2 % 2 || $3 % 2)
1844                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1845
1846                 Simultaneous_music*v = new Request_chord (SCM_EOL);
1847                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1848
1849                 v->set_spot (i);
1850                 n->set_spot (i);
1851                 $$ = v;
1852         }
1853         | figure_spec optional_notemode_duration {
1854                 Music * m = unsmob_music ($1);
1855                 Input i = THIS->pop_spot ();
1856                 m->set_spot (i);
1857                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1858                         {
1859                                 unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1860                         }
1861                 $$ = m;
1862         }
1863         | RESTNAME optional_notemode_duration           {
1864
1865                 Input i = THIS->pop_spot ();
1866                 SCM e = SCM_UNDEFINED;
1867                 if (ly_scm2string ($1) =="s") {
1868                         /* Space */
1869                         Skip_req * skip_p = new Skip_req;
1870                         skip_p->set_mus_property ("duration" ,$2);
1871                         skip_p->set_spot (i);
1872                         e = skip_p->self_scm ();
1873                   }
1874                   else {
1875                         Rest_req * rest_req_p = new Rest_req;
1876                         rest_req_p->set_mus_property ("duration", $2);
1877                         rest_req_p->set_spot (i);
1878                         e = rest_req_p->self_scm ();
1879                     }
1880                 Simultaneous_music* velt_p = new Request_chord (SCM_EOL);
1881                 velt_p-> set_mus_property ("elements", scm_list_n (e,SCM_UNDEFINED));
1882                 velt_p->set_spot (i);
1883
1884                 $$ = velt_p;
1885         }
1886         | MULTI_MEASURE_REST optional_notemode_duration         {
1887                 Input i = THIS->pop_spot ();
1888
1889                 Skip_req * sk = new Skip_req;
1890                 sk->set_mus_property ("duration", $2);
1891                 Span_req *sp1 = new Span_req;
1892                 Span_req *sp2 = new Span_req;
1893                 sp1-> set_span_dir ( START);
1894                 sp2-> set_span_dir ( STOP);
1895                 SCM r = ly_str02scm ("rest");
1896                 sp1->set_mus_property ("span-type", r);
1897                 sp2->set_mus_property ("span-type", r);
1898
1899                 Request_chord * rqc1 = new Request_chord (SCM_EOL);
1900                 rqc1->set_mus_property ("elements", scm_list_n (sp1->self_scm (), SCM_UNDEFINED));
1901                 Request_chord * rqc2 = new Request_chord (SCM_EOL);
1902                 rqc2->set_mus_property ("elements", scm_list_n (sk->self_scm (), SCM_UNDEFINED));;
1903                 Request_chord * rqc3 = new Request_chord (SCM_EOL);
1904                 rqc3->set_mus_property ("elements", scm_list_n (sp2->self_scm (), SCM_UNDEFINED));;
1905
1906                 SCM ms = scm_list_n (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1907
1908                 $$ = new Sequential_music (SCM_EOL);
1909                 $$->set_mus_property ("elements", ms);
1910         }
1911         | STRING optional_notemode_duration     {
1912                 Input i = THIS->pop_spot ();
1913
1914                 Lyric_req* lreq_p = new Lyric_req;
1915                 lreq_p->set_mus_property ("text", $1);
1916                 lreq_p->set_mus_property ("duration",$2);
1917                 lreq_p->set_spot (i);
1918                 Simultaneous_music* velt_p = new Request_chord (SCM_EOL);
1919                 velt_p->set_mus_property ("elements", scm_list_n (lreq_p->self_scm (), SCM_UNDEFINED));
1920
1921                 $$= velt_p;
1922         }
1923         | chord {
1924                 Input i = THIS->pop_spot ();
1925
1926                 if (!THIS->lexer_p_->chord_state_b ())
1927                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1928                 $$ = $1;
1929         }
1930         ;
1931
1932
1933 chord:
1934         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1935                 $$ = Chord::get_chord ($1, $3, $4, $5, $6, $2);
1936                 $$->set_spot (THIS->here_input ());
1937         };
1938
1939 chord_additions:
1940         {
1941                 $$ = SCM_EOL;
1942         }
1943         | CHORD_COLON chord_notes {
1944                 $$ = $2;
1945         }
1946         ;
1947
1948 chord_notes:
1949         chord_step {
1950                 $$ = $1
1951         }
1952         | chord_notes '.' chord_step {
1953                 $$ = gh_append2 ($$, $3);
1954         }
1955         ;
1956
1957 chord_subtractions:
1958         {
1959                 $$ = SCM_EOL;
1960         }
1961         | CHORD_CARET chord_notes {
1962                 $$ = $2;
1963         }
1964         ;
1965
1966
1967 chord_inversion:
1968         {
1969                 $$ = SCM_EOL;
1970         }
1971         | '/' steno_tonic_pitch {
1972                 $$ = $2;
1973         }
1974         ;
1975
1976 chord_bass:
1977         {
1978                 $$ = SCM_EOL;
1979         }
1980         | CHORD_BASS steno_tonic_pitch {
1981                 $$ = $2;
1982         }
1983         ;
1984
1985 chord_step:
1986         chord_note {
1987                 $$ = gh_cons ($1, SCM_EOL);
1988         }
1989         | CHORDMODIFIER_PITCH {
1990                 $$ = gh_cons (unsmob_pitch ($1)->smobbed_copy (), SCM_EOL);
1991         }
1992         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1993                 $$ = scm_list_n (unsmob_pitch ($1)->smobbed_copy (),
1994                         $2, SCM_UNDEFINED);
1995         }
1996         ;
1997
1998 chord_note:
1999         bare_unsigned {
2000                  Pitch m;
2001                 m.notename_i_ = ($1 - 1) % 7;
2002                 m.octave_i_ = $1 > 7 ? 1 : 0;
2003                 m.alteration_i_ = 0;
2004
2005                 $$ = m.smobbed_copy ();
2006         }
2007         | bare_unsigned '+' {
2008                 Pitch m;
2009                 m.notename_i_ = ($1 - 1) % 7;
2010                 m.octave_i_ = $1 > 7 ? 1 : 0;
2011                 m.alteration_i_ = 1;
2012
2013
2014                 $$ = m.smobbed_copy ();
2015         }
2016         | bare_unsigned CHORD_MINUS {
2017                 Pitch m;
2018                 m.notename_i_ = ($1 - 1) % 7;
2019                 m.octave_i_ = $1 > 7 ? 1 : 0;
2020                 m.alteration_i_ = -1;
2021
2022                 $$ = m.smobbed_copy ();
2023         }
2024         ;
2025
2026 /*
2027         UTILITIES
2028  */
2029 number_expression:
2030         number_expression '+' number_term {
2031                 $$ = scm_sum ($1, $3);
2032         }
2033         | number_expression '-' number_term {
2034                 $$ = scm_difference ($1, $3);
2035         }
2036         | number_term
2037         ;
2038
2039 number_term:
2040         number_factor {
2041                 $$ = $1;
2042         }
2043         | number_factor '*' number_factor {
2044                 $$ = scm_product ($1, $3);
2045         }
2046         | number_factor '/' number_factor {
2047                 $$ = scm_divide ($1, $3);
2048         }
2049         ;
2050
2051 number_factor:
2052         '(' number_expression ')'       {
2053                 $$ = $2;
2054         }
2055         | '-'  number_factor { /* %prec UNARY_MINUS */
2056                 $$ = scm_difference ($2, SCM_UNDEFINED);
2057         }
2058         | bare_number
2059         ;
2060
2061
2062 bare_number:
2063         UNSIGNED        {
2064                 $$ = gh_int2scm ($1);
2065         }
2066         | REAL          {
2067                 $$ = $1;
2068         }
2069         | NUMBER_IDENTIFIER             {
2070                 $$ = $1;
2071         }
2072         | REAL CM_T     {
2073                 $$ = gh_double2scm (gh_scm2double ($1) CM );
2074         }
2075         | REAL PT_T     {
2076                 $$ = gh_double2scm (gh_scm2double ($1) PT);
2077         }
2078         | REAL IN_T     {
2079                 $$ = gh_double2scm (gh_scm2double ($1) INCH);
2080         }
2081         | REAL MM_T     {
2082                 $$ = gh_double2scm (gh_scm2double ($1) MM);
2083         }
2084         | REAL CHAR_T   {
2085                 $$ = gh_double2scm (gh_scm2double ($1) CHAR);
2086         }
2087         ;
2088
2089
2090 bare_unsigned:
2091         UNSIGNED {
2092                         $$ = $1;
2093         }
2094         | DIGIT {
2095                 $$ = $1;
2096         }
2097         ;
2098
2099 bare_int:
2100         bare_number {
2101                 if (scm_integer_p ($1) == SCM_BOOL_T)
2102                 {
2103                         int k = gh_scm2int ($1);
2104                         $$ = k;
2105                 } else
2106                 {
2107                         THIS->parser_error (_ ("need integer number arg"));
2108                         $$ = 0;
2109                 }
2110         }
2111         | '-' bare_int {
2112                 $$ = -$2;
2113         }
2114         ;
2115
2116
2117 string:
2118         STRING          {
2119                 $$ = $1;
2120         }
2121         | STRING_IDENTIFIER     {
2122                 $$ = $1;
2123         }
2124         | string '+' string {
2125                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2126         }
2127         ;
2128
2129
2130 exclamations:
2131                 { $$ = 0; }
2132         | exclamations '!'      { $$ ++; }
2133         ;
2134
2135 questions:
2136                 { $$ = 0; }
2137         | questions '?' { $$ ++; }
2138         ;
2139
2140
2141 %%
2142
2143 void
2144 My_lily_parser::set_yydebug (bool )
2145 {
2146 #if 0
2147         yydebug = b;
2148 #endif
2149 }
2150
2151 extern My_lily_parser * current_parser;
2152
2153 void
2154 My_lily_parser::do_yyparse ()
2155 {
2156
2157         current_parser = this;;
2158         yyparse ((void*)this);
2159 }
2160
2161
2162 /*
2163 Should make this optional?    It will also complain when you do
2164
2165         [s4]
2166
2167 which is entirely legitimate.
2168
2169 Or we can scrap it. Barchecks should detect wrong durations, and
2170 skipTypesetting speeds it up a lot.
2171 */
2172 void
2173 My_lily_parser::beam_check (SCM dur)
2174 {
2175   Duration *d = unsmob_duration (dur);
2176   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2177     {
2178       Music * m = unsmob_music (last_beam_start_);
2179       m->origin ()->warning (_("Suspect duration found following this beam"));
2180     }
2181   last_beam_start_ = SCM_EOL;
2182 }