lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-module.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83 #include "paper-book.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 is_regular_identifier (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_2 (simple, a);
 144 }
 145
 146
 147 bool
 148 is_is_duration (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC ("PropertySet");
 200         p->set_property ("symbol", sym);
 201         p->set_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token ();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token ADDQUOTE
 242 %token NEWADDLYRICS
 243 %token ALIAS
 244 %token ALTERNATIVE
 245 %token APPLY
 246 %token APPLYCONTEXT
 247 %token APPLYOUTPUT
 248 %token AUTOCHANGE
 249 %token BAR
 250 %token BREATHE
 251 %token CHANGE
 252 %token CHORDMODIFIERS
 253 %token CHORDS
 254 %token LESSLESS
 255 %token MOREMORE
 256 %token CLEF
 257 %token COMMANDSPANREQUEST
 258 %token CONSISTS
 259 %token CONSISTSEND
 260 %token CONTEXT
 261 %token DEFAULT
 262 %token DENIES
 263 %token DESCRIPTION
 264 %token EXTENDER
 265 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 266 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 267 %token GRACE
 268 %token ACCIACCATURA
 269 %token APPOGGIATURA
 270 %token GROBDESCRIPTIONS
 271 %token HEADER
 272 %token HYPHEN
 273 %token INVALID
 274 %token KEY
 275 %token LYRICS
 276 %token MARK
 277 %token MIDI
 278 %token MULTI_MEASURE_REST
 279 %token NAME
 280 %token NEWCONTEXT
 281 %token NOTES
 282 %token OCTAVE
 283 %token ONCE
 284 %token OVERRIDE SET REVERT
 285 %token PAPER
 286 %token PARTCOMBINE
 287 %token PARTIAL
 288 %token QUOTE
 289 %token RELATIVE
 290 %token REMOVE
 291 %token REPEAT
 292 %token REST
 293 %token SCM_T
 294 %token SCORE
 295 %token SEQUENTIAL
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSPOSE
 304 %token TRANSPOSITION
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 311 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 312 %token E_BACKSLASH
 313 %token <i> E_UNSIGNED
 314 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 315 %token FIGURE_SPACE
 316
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token DRUMS
 332 %token <scm>    DRUM_PITCH
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> context_prop_spec
 388 %type <scm> Music_list
 389 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 390 %type <outputdef>  music_output_def_body music_output_def_head
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req
 393 %type <music> string_number_event
 394 %type <scm>     string bare_number number_expression number_term number_factor
 395 %type <score>   score_block score_body
 396
 397 %type <scm>     context_def_spec_block context_def_spec_body
 398 %type <music>   tempo_event
 399 %type <scm>     script_abbreviation
 400
 401
 402
 403 %left '-' '+'
 404
 405 /* We don't assign precedence to / and *, because we might need varied
 406 prec levels in different prods */
 407
 408 %left UNARY_MINUS
 409
 410 %%
 411
 412 lilypond:       /* empty */
 413         | lilypond toplevel_expression {}
 414         | lilypond assignment  { }
 415         | lilypond error {
 416                 THIS->error_level_  = 1;
 417         }
 418         | lilypond INVALID      {
 419                 THIS->error_level_  = 1;
 420         }
 421         ;
 422
 423 toplevel_expression:
 424         lilypond_header {
 425                 THIS->input_file_->header_ = $1;
 426         }
 427         | add_quote {
 428         }
 429         | score_block {
 430                 Score * sc = $1;
 431
 432                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 433
 434                 Path p = split_path (THIS->output_basename_);
 435                 int *c =  &THIS->input_file_->score_count_;
 436                 if (*c)
 437                         {
 438                         p.base += "-" + to_string (*c);
 439                         }
 440
 441                 (*c)++;
 442                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 443
 444                 for (int i=0; i < sc->defs_.size (); i++)
 445                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 446
 447                 if (sc->defs_.is_empty ())
 448                 {
 449                    Music_output_def *id =
 450                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 451                                 ("$defaultpaper"));
 452
 453                    id = id ? id->clone () : new Paper_def;
 454
 455                    default_rendering (sc->music_, id->self_scm (), head, outname);
 456
 457 #ifndef PAGE_LAYOUT
 458                    scm_gc_unprotect_object (id->self_scm ());
 459 #endif
 460                 }
 461 #ifndef PAGE_LAYOUT
 462                 scm_gc_unprotect_object (sc->self_scm ());
 463 #endif
 464         }
 465         | output_def {
 466                 SCM id = SCM_EOL;
 467                 if (dynamic_cast<Paper_def*> ($1))
 468                         id = scm_makfrom0str ("$defaultpaper");
 469                 else if (dynamic_cast<Midi_def*> ($1))
 470                         id = scm_makfrom0str ("$defaultmidi");
 471                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 472                 scm_gc_unprotect_object ($1->self_scm ());
 473         }
 474         ;
 475
 476
 477 embedded_scm:
 478         SCM_T
 479         | SCM_IDENTIFIER
 480         ;
 481
 482
 483
 484
 485 lilypond_header_body:
 486         {
 487                 $$ = ly_make_anonymous_module ();
 488                 THIS->lexer_->add_scope ($$);
 489         }
 490         | lilypond_header_body assignment  {
 491
 492         }
 493         ;
 494
 495 lilypond_header:
 496         HEADER '{' lilypond_header_body '}'     {
 497                 $$ = THIS->lexer_-> remove_scope ();
 498         }
 499         ;
 500
 501
 502 /*
 503         DECLARATIONS
 504 */
 505 assignment:
 506         STRING {
 507                 THIS->push_spot ();
 508         }
 509         /* cont */ '=' identifier_init  {
 510
 511         /*
 512                 Should find generic way of associating input with objects.
 513         */
 514                 Input ip = THIS->pop_spot ();
 515
 516                 if (! is_regular_identifier ($1))
 517                 {
 518                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 519                 }
 520
 521                 THIS->lexer_->set_identifier ($1, $4);
 522
 523 /*
 524  TODO: devise standard for protection in parser.
 525
 526   The parser stack lives on the C-stack, which means that
 527 all objects can be unprotected as soon as they're here.
 528
 529 */
 530         }
 531         | embedded_scm { }
 532         ;
 533
 534
 535 identifier_init:
 536         score_block {
 537                 $$ = $1->self_scm ();
 538                 scm_gc_unprotect_object ($$);
 539         }
 540         | full_markup {
 541                 $$ = $1;
 542         }
 543         | output_def {
 544                 $$ = $1->self_scm ();
 545                 scm_gc_unprotect_object ($$);
 546         }
 547         | context_def_spec_block {
 548                 $$ = $1;
 549         }
 550         | Music  {
 551                 $$ = $1->self_scm ();
 552                 scm_gc_unprotect_object ($$);
 553         }
 554         | post_event {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | number_expression {
 559                 $$ = $1;
 560         }
 561         | string {
 562                 $$ = $1;
 563         }
 564         | embedded_scm  {
 565                 $$ = $1;
 566         }
 567         ;
 568
 569 context_def_spec_block:
 570         CONTEXT '{' context_def_spec_body '}'
 571                 {
 572                 $$ = $3;
 573         }
 574         ;
 575
 576 context_def_spec_body:
 577         /**/ {
 578                 $$ = Context_def::make_scm ();
 579                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 580         }
 581         | CONTEXT_DEF_IDENTIFIER        {
 582                 $$ = $1;
 583                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 584         }
 585         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 586                 Context_def*td = unsmob_context_def ($$);
 587
 588                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 589                         SCM tag = gh_caar (p);
 590
 591                         /* TODO: should make new tag "grob-definition" ? */
 592                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 593                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 594                 }
 595         }
 596         | context_def_spec_body context_mod {
 597                 unsmob_context_def ($$)->add_context_mod ($2);
 598         }
 599         ;
 600
 601 /*
 602         SCORE
 603 */
 604 score_block:
 605         SCORE {
 606                 THIS->push_spot ();
 607         }
 608         /*cont*/ '{' score_body '}'     {
 609                 THIS->pop_spot ();
 610                 $$ = $4;
 611
 612         }
 613         ;
 614
 615 score_body:
 616         Music   {
 617                 $$ = new Score;
 618
 619                 $$->set_spot (THIS->here_input ());
 620                 SCM m = $1->self_scm ();
 621                 scm_gc_unprotect_object (m);
 622
 623                 /*
 624                         guh.
 625                 */
 626                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 627                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 628                         m = gh_call1 (gh_car (check_funcs), m);
 629                 $$->music_ = m;
 630
 631         }
 632         | SCORE_IDENTIFIER {
 633                 $$ = new Score ( *unsmob_score ($1));
 634                 $$->set_spot (THIS->here_input ());
 635         }
 636         | score_body lilypond_header    {
 637                 $$->header_ = $2;
 638         }
 639         | score_body output_def {
 640                 $$->defs_.push ($2);
 641                 scm_gc_unprotect_object ($2->self_scm ());
 642         }
 643         | score_body error {
 644
 645         }
 646         ;
 647
 648
 649 /*
 650         MIDI
 651 */
 652 output_def:
 653         music_output_def_body '}' {
 654                 $$ = $1;
 655                 THIS-> lexer_-> remove_scope ();
 656         }
 657         ;
 658
 659 music_output_def_head:
 660         MIDI    {
 661                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 662
 663
 664                 Midi_def* p =0;
 665                 if (id)
 666                         p = dynamic_cast<Midi_def*> (id->clone ());
 667                 else
 668                         p = new Midi_def;
 669
 670                 $$ = p;
 671                 THIS->lexer_->add_scope (p->scope_);
 672         }
 673         | PAPER         {
 674                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 675                   Paper_def *p = 0;
 676                 if (id)
 677                         p = dynamic_cast<Paper_def*> (id->clone ());
 678                 else
 679                         p = new Paper_def;
 680
 681                 THIS->lexer_->add_scope (p->scope_);
 682                 $$ = p;
 683         }
 684         ;
 685
 686
 687 music_output_def_body:
 688         music_output_def_head '{' {
 689
 690         }
 691         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 692                 scm_gc_unprotect_object ($1->self_scm ());
 693                 Music_output_def * o =  unsmob_music_output_def ($3);
 694                 $$ = o;
 695                 THIS->lexer_->remove_scope ();
 696                 THIS->lexer_->add_scope (o->scope_);
 697         }
 698         | music_output_def_body assignment  {
 699
 700         }
 701         | music_output_def_body context_def_spec_block  {
 702                 $$->assign_context_def ($2);
 703         }
 704         | music_output_def_body tempo_event  {
 705                 /*
 706                         junk this ? there already is tempo stuff in
 707                         music.
 708                 */
 709                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 710                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 711                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 712                 if (md)
 713                         md->set_tempo (d->get_length (), m);
 714                 scm_gc_unprotect_object ($2->self_scm ());
 715         }
 716         | music_output_def_body error {
 717
 718         }
 719         ;
 720
 721 tempo_event:
 722         TEMPO steno_duration '=' bare_unsigned  {
 723                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 724                 $$->set_property ("tempo-unit", $2);
 725                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 726         }
 727         ;
 728
 729 /*
 730 The representation of a  list is the
 731
 732   (LIST . LAST-CONS)
 733
 734  to have  efficient append.
 735 */
 736 Music_list:
 737         /* empty */ {
 738                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 739         }
 740         | Music_list Music {
 741                 SCM s = $$;
 742                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 743                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 744                 if (gh_pair_p (ly_cdr (s)))
 745                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 746                 else
 747                         gh_set_car_x (s, c); /* set first cons */
 748                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 749         }
 750         | Music_list error {
 751         }
 752         ;
 753
 754
 755 Music:
 756         Simple_music
 757         | Composite_music
 758         ;
 759
 760 Alternative_music:
 761         /* empty */ {
 762                 $$ = SCM_EOL;
 763         }
 764         | ALTERNATIVE '{' Music_list '}' {
 765                 $$ = $3;
 766         }
 767         ;
 768
 769 Repeated_music:
 770         REPEAT string bare_unsigned Music Alternative_music
 771         {
 772                 Music *beg = $4;
 773                 int times = $3;
 774                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 775                 if (times < scm_ilength (alts)) {
 776                   unsmob_music (gh_car (alts))
 777                     ->origin ()->warning (
 778                     _("More alternatives than repeats.  Junking excess alternatives."));
 779                   alts = ly_truncate_list (times, alts);
 780                 }
 781
 782
 783                 static SCM proc;
 784                 if (!proc)
 785                         proc = scm_c_eval_string ("make-repeated-music");
 786
 787                 SCM mus = scm_call_1 (proc, $2);
 788                 scm_gc_protect_object (mus); // UGH.
 789                 Music *r =unsmob_music (mus);
 790                 if (beg)
 791                         {
 792                         r-> set_property ("element", beg->self_scm ());
 793                         scm_gc_unprotect_object (beg->self_scm ());
 794                         }
 795                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 796
 797                 r-> set_property ("elements",alts);
 798                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 799                         /*
 800                         we can not get durations and other stuff correct down the line, so we have to
 801                         add to the duration log here.
 802                         */
 803                         static SCM func;
 804
 805                         if (!func)
 806                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 807
 808                         int dots = ($3 % 3) ? 0 : 1;
 809                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 810
 811                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 812
 813                         if (seq) {
 814                                 int list_len =scm_ilength (seq->music_list ());
 815                                 if (list_len != 2)
 816                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 817                                 shift -= 1;
 818                                 r->compress (Moment (Rational (1,list_len)));
 819                                 }
 820                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 821
 822                 }
 823                 r->set_spot (*$4->origin ());
 824
 825                 $$ = r;
 826         }
 827         ;
 828
 829 Sequential_music:
 830         SEQUENTIAL '{' Music_list '}'           {
 831                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 832                 $$->set_property ("elements", ly_car ($3));
 833                 $$->set_spot (THIS->here_input ());
 834         }
 835         | '{' Music_list '}'            {
 836                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 837                 $$->set_property ("elements", ly_car ($2));
 838                 $$->set_spot (THIS->here_input ());
 839         }
 840         ;
 841
 842 Simultaneous_music:
 843         SIMULTANEOUS '{' Music_list '}'{
 844                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 845                 $$->set_property ("elements", ly_car ($3));
 846                 $$->set_spot (THIS->here_input ());
 847
 848         }
 849         | simul_open Music_list simul_close     {
 850                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 851                 $$->set_property ("elements", ly_car ($2));
 852                 $$->set_spot (THIS->here_input ());
 853         }
 854         ;
 855
 856 Simple_music:
 857         event_chord             { $$ = $1; }
 858         | APPLYOUTPUT embedded_scm {
 859                 if (!ly_input_procedure_p ($2))
 860                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 861                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 862                 $$->set_property ("procedure", $2);
 863                 $$->set_spot (THIS->here_input ());
 864         }
 865         | APPLYCONTEXT embedded_scm {
 866                 if (!ly_input_procedure_p ($2))
 867                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 868                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 869                 $$->set_property ("procedure", $2);
 870                 $$->set_spot (THIS->here_input ());
 871         }
 872         | MUSIC_IDENTIFIER {
 873                 $$ = unsmob_music ($1);
 874         }
 875         | music_property_def
 876         | context_change
 877         ;
 878
 879
 880 optional_context_mod:
 881         /**/ { $$ = SCM_EOL; }
 882         | WITH '{' context_mod_list '}'  { $$ = $3; }
 883         ;
 884
 885 grace_head:
 886         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 887         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 888         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 889         ;
 890
 891 context_mod_list:
 892         /* */  { $$ = SCM_EOL; }
 893         | context_mod_list context_mod  {
 894                  $$ = gh_cons ($2, $1);
 895         }
 896         ;
 897
 898 Composite_music:
 899         AUTOCHANGE Music        {
 900                 static SCM proc ;
 901                 if (!proc)
 902                         proc = scm_c_eval_string ("make-autochange-music");
 903
 904                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 905                 scm_gc_unprotect_object ($2->self_scm ());
 906                 $$ = unsmob_music (res);
 907                 scm_gc_protect_object (res);
 908                 $$->set_spot (THIS->here_input ());
 909         }
 910         | PARTCOMBINE Music Music {
 911                 static SCM proc;
 912                 if (!proc)
 913                         proc = scm_c_eval_string ("make-part-combine-music");
 914
 915                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 916                         $3->self_scm (), SCM_UNDEFINED));
 917                 scm_gc_unprotect_object ($3->self_scm ());
 918                 scm_gc_unprotect_object ($2->self_scm ());
 919                 $$ = unsmob_music (res);
 920                 scm_gc_protect_object (res);
 921                 $$->set_spot (THIS->here_input ());
 922         }
 923         | grace_head Music {
 924 #if 1
 925         /*
 926                 The other version is for easier debugging  of
 927                 Sequential_music_iterator in combination with grace notes.
 928         */
 929
 930 /*
 931
 932 TODO: should distinguish between both grace types in the
 933 basic music objects too, since the meaning is different.
 934
 935 */
 936
 937                 String start_str = "start" + ly_scm2string ($1) + "Music";
 938                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 939
 940                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 941                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 942
 943                 Music *startm = unsmob_music (start);
 944                 Music *stopm = unsmob_music (stop);
 945
 946                 SCM ms = SCM_EOL;
 947                 if (stopm) {
 948                         stopm = stopm->clone ();
 949                         ms = scm_cons (stopm->self_scm (), ms);
 950                         scm_gc_unprotect_object (stopm->self_scm ());
 951                 }
 952                 ms = scm_cons ($2->self_scm (), ms);
 953                 scm_gc_unprotect_object ($2->self_scm ());
 954                 if (startm) {
 955                         startm = startm->clone ();
 956                         ms = scm_cons (startm->self_scm () , ms);
 957                         scm_gc_unprotect_object (startm->self_scm ());
 958                 }
 959
 960                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 961                 seq->set_property ("elements", ms);
 962
 963
 964                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 965                 $$->set_property ("element", seq->self_scm ());
 966                 scm_gc_unprotect_object (seq->self_scm ());
 967 #else
 968                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 969                 $$->set_property ("element", $2->self_scm ());
 970                 scm_gc_unprotect_object ($2->self_scm ());
 971 #endif
 972         }
 973         | CONTEXT string '=' string optional_context_mod Music {
 974                 $$ = context_spec_music ($2, $4, $6, $5);
 975
 976         }
 977         | CONTEXT STRING optional_context_mod Music {
 978                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 979         }
 980         | NEWCONTEXT string optional_context_mod Music {
 981                 $$ = context_spec_music ($2, get_next_unique_context (),
 982                                          $4, $3);
 983         }
 984
 985         | TIMES {
 986                 THIS->push_spot ();
 987         }
 988         /* CONTINUED */
 989                 fraction Music
 990
 991         {
 992                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 993                 Music *mp = $4;
 994
 995                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 996                 $$->set_spot (THIS->pop_spot ());
 997
 998                 $$->set_property ("element", mp->self_scm ());
 999                 scm_gc_unprotect_object (mp->self_scm ());
1000                 $$->set_property ("numerator", gh_int2scm (n));
1001                 $$->set_property ("denominator", gh_int2scm (d));
1002                 $$->compress (Moment (Rational (n,d)));
1003
1004         }
1005         | Repeated_music                { $$ = $1; }
1006         | Simultaneous_music            { $$ = $1; }
1007         | Sequential_music              { $$ = $1; }
1008         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1009                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1010                 Music *p = $4;
1011                 Pitch from = *unsmob_pitch ($2);
1012                 Pitch to = *unsmob_pitch ($3);
1013
1014                 p->transpose (interval (from, to));
1015                 $$->set_property ("element", p->self_scm ());
1016                 scm_gc_unprotect_object (p->self_scm ());
1017         }
1018         | APPLY embedded_scm Music  {
1019                 if (!ly_input_procedure_p ($2))
1020                         {
1021                         THIS->parser_error (_ ("\\apply takes function argument"));
1022                         $$ = $3;
1023                         }
1024                 else
1025                         {
1026                         SCM ret = gh_call1 ($2, $3->self_scm ());
1027                         Music *m = unsmob_music (ret);
1028                         if (!m) {
1029                                 THIS->parser_error ("\\apply must return a Music");
1030                                 m = MY_MAKE_MUSIC ("Music");
1031                                 }
1032                         $$ = m;
1033                         }
1034         }
1035         | NOTES
1036                 {
1037                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1038                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1039         }
1040         Music
1041                 { $$ = $3;
1042                   THIS->lexer_->pop_state ();
1043                 }
1044         | DRUMS
1045                 {
1046                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1047                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1048         }
1049         Music
1050                 { $$ = $3;
1051                   THIS->lexer_->pop_state ();
1052                 }
1053         | FIGURES
1054                 { THIS->lexer_->push_figuredbass_state (); }
1055         Music
1056                 {
1057                   Music * chm = MY_MAKE_MUSIC ("UntransposableMusic");
1058                   chm->set_property ("element", $3->self_scm ());
1059                   $$ = chm;
1060                   scm_gc_unprotect_object ($3->self_scm ());
1061
1062                   THIS->lexer_->pop_state ();
1063         }
1064         | CHORDS {
1065                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1066                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1067                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1068                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1069
1070         } Music {
1071                   Music * chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1072                   chm->set_property ("element", $3->self_scm ());
1073                   scm_gc_unprotect_object ($3->self_scm ());
1074                   $$ = chm;
1075
1076                   THIS->lexer_->pop_state ();
1077         }
1078         | LYRICS
1079                 { THIS->lexer_->push_lyric_state (); }
1080         Music
1081                 {
1082                   $$ = $3;
1083                   THIS->lexer_->pop_state ();
1084         }
1085         | relative_music        { $$ = $1; }
1086         | re_rhythmed_music     { $$ = $1; }
1087         | TAG embedded_scm Music {
1088                 tag_music ($3, $2, THIS->here_input ());
1089                 $$ = $3;
1090         }
1091         ;
1092
1093 relative_music:
1094         RELATIVE absolute_pitch Music {
1095                 Music * p = $3;
1096                 Pitch pit = *unsmob_pitch ($2);
1097                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1098
1099                 $$->set_property ("element", p->self_scm ());
1100                 scm_gc_unprotect_object (p->self_scm ());
1101
1102
1103                 Pitch retpitch = p->to_relative_octave (pit);
1104                 if (lily_1_8_relative)
1105                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1106         }
1107         ;
1108
1109 re_rhythmed_music:
1110         ADDLYRICS Music Music {
1111         Music*l =MY_MAKE_MUSIC ("LyricCombineMusic");
1112           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1113           scm_gc_unprotect_object ($3->self_scm ());
1114           scm_gc_unprotect_object ($2->self_scm ());
1115           $$ = l;
1116         }
1117         | NEWADDLYRICS string Music {
1118           Music*l =MY_MAKE_MUSIC ("NewLyricCombineMusic");
1119           l->set_property ("element", $3->self_scm ());
1120           scm_gc_unprotect_object ($3->self_scm ());
1121           $$ = l;
1122           l->set_property ("associated-context", $2);
1123         }
1124         ;
1125
1126 context_change:
1127         CHANGE STRING '=' STRING  {
1128                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1129                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1130                 t-> set_property ("change-to-id", $4);
1131
1132                 $$ = t;
1133                 $$->set_spot (THIS->here_input ());
1134         }
1135         ;
1136
1137 property_operation:
1138         STRING '='  scalar {
1139                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1140                         scm_string_to_symbol ($1), $3);
1141         }
1142         | UNSET STRING {
1143                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1144                         scm_string_to_symbol ($2));
1145         }
1146         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1147                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1148                         scm_string_to_symbol ($2), $3, $5);
1149         }
1150         | REVERT STRING embedded_scm {
1151                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1152                         scm_string_to_symbol ($2), $3);
1153         }
1154         ;
1155
1156 context_def_mod:
1157         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1158         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1159         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1160
1161         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1162         | DENIES { $$ = ly_symbol2scm ("denies"); }
1163
1164         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1165         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1166         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1167         | NAME { $$ = ly_symbol2scm ("context-name"); }
1168         ;
1169
1170 context_mod:
1171         property_operation { $$ = $1; }
1172         | context_def_mod STRING {
1173                 $$ = scm_list_2 ($1, $2);
1174         }
1175         ;
1176
1177 context_prop_spec:
1178         STRING  {
1179                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1180         }
1181         | STRING '.' STRING {
1182                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1183         }
1184         ;
1185
1186 music_property_def:
1187         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1188                 $$ = property_op_to_music (scm_list_4 (
1189                         ly_symbol2scm ("poppush"),
1190                         gh_cadr ($2),
1191                         $3, $5));
1192                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1193         }
1194         | REVERT context_prop_spec embedded_scm {
1195                 $$ = property_op_to_music (scm_list_3 (
1196                         ly_symbol2scm ("pop"),
1197                         gh_cadr ($2),
1198                         $3));
1199
1200                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1201         }
1202         | SET context_prop_spec '=' scalar {
1203                 $$ = property_op_to_music (scm_list_3 (
1204                         ly_symbol2scm ("assign"),
1205                         gh_cadr ($2),
1206                         $4));
1207                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1208         }
1209         | UNSET context_prop_spec {
1210                 $$ = property_op_to_music (scm_list_2 (
1211                         ly_symbol2scm ("unset"),
1212                         gh_cadr ($2)));
1213                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1214         }
1215         | ONCE music_property_def {
1216                 SCM e = $2->get_property ("element");
1217                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1218                 $$ = $2;
1219
1220         }
1221         ;
1222
1223
1224
1225 scalar:
1226         string          { $$ = $1; }
1227         | bare_int      { $$ = gh_int2scm ($1); }
1228         | embedded_scm  { $$ = $1; }
1229         | full_markup {  $$ = $1; }
1230         | DIGIT { $$ = gh_int2scm ($1); }
1231         ;
1232
1233 /*
1234 This is a trick:
1235
1236 Adding pre_events to the simple_element
1237 makes the choice between
1238
1239   string:  STRING
1240
1241 and
1242
1243   simple_element: STRING
1244
1245 a single shift/reduction conflict.
1246
1247 nevertheless, this is not very clean, and we should find a different
1248 solution.
1249
1250 */
1251 pre_events: {
1252                 THIS->push_spot ();
1253         }
1254         ;
1255
1256 event_chord:
1257         pre_events simple_element post_events   {
1258                 SCM elts = $2-> get_property ("elements");
1259
1260                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1261
1262                 $2->set_property ("elements", elts);
1263                 $$ = $2;
1264         }
1265         | command_element
1266         | note_chord_element
1267         ;
1268
1269
1270 note_chord_element:
1271         chord_body optional_notemode_duration post_events
1272         {
1273                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1274                 SCM es = $1->get_property ("elements");
1275                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1276
1277                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1278                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1279                 es = gh_append2 (es, postevs);
1280
1281                 $1-> set_property ("elements", es);
1282                 $$ = $1;
1283         }
1284         ;
1285
1286 chord_open: '<'
1287         ;
1288
1289 chord_close: '>'
1290         ;
1291
1292 simul_open: LESSLESS
1293         ;
1294
1295 simul_close: MOREMORE
1296         ;
1297
1298 chord_body:
1299         chord_open chord_body_elements chord_close
1300         {
1301                 $$ = MY_MAKE_MUSIC ("EventChord");
1302                 $$->set_property ("elements",
1303                         scm_reverse_x ($2, SCM_EOL));
1304         }
1305         ;
1306
1307 chord_body_elements:
1308         /* empty */             { $$ = SCM_EOL; }
1309         | chord_body_elements chord_body_element {
1310                 $$ = gh_cons ($2->self_scm (), $1);
1311                 scm_gc_unprotect_object ($2->self_scm ());
1312         }
1313         ;
1314
1315 chord_body_element:
1316         pitch exclamations questions post_events
1317         {
1318                 Music * n = MY_MAKE_MUSIC ("NoteEvent");
1319                 n->set_property ("pitch", $1);
1320                 if ($3 % 2)
1321                         n->set_property ("cautionary", SCM_BOOL_T);
1322                 if ($2 % 2 || $3 % 2)
1323                         n->set_property ("force-accidental", SCM_BOOL_T);
1324
1325                 if (gh_pair_p ($4)) {
1326                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1327                         n->set_property ("articulations", arts);
1328                 }
1329                 $$ = n;
1330         }
1331         | DRUM_PITCH post_events {
1332                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
1333                 n->set_property ("duration" ,$2);
1334                 n->set_property ("drum-type" , $1);
1335                 n->set_spot (THIS->here_input ());
1336
1337                 if (gh_pair_p ($2)) {
1338                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1339                         n->set_property ("articulations", arts);
1340                 }
1341                 $$ = n;
1342         }
1343         ;
1344
1345 add_quote:
1346         ADDQUOTE string Music {
1347                 static SCM adder;
1348                 if (!adder)
1349                         adder = scm_c_eval_string ("add-quotable");
1350
1351                 scm_call_2 (adder, $2, $3->self_scm ());
1352                 scm_gc_unprotect_object ($3->self_scm ());
1353         }
1354         ;
1355
1356 command_element:
1357         command_req {
1358                 $$ = MY_MAKE_MUSIC ("EventChord");
1359                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1360                 scm_gc_unprotect_object ($1->self_scm ());
1361
1362                 $$-> set_spot (THIS->here_input ());
1363                 $1-> set_spot (THIS->here_input ());
1364         }
1365         | SKIP duration_length {
1366                 Music * skip = MY_MAKE_MUSIC ("SkipMusic");
1367                 skip->set_property ("duration", $2);
1368
1369                 $$ = skip;
1370         }
1371         | QUOTE STRING duration_length {
1372                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1373                 SCM evs =  SCM_EOL;
1374                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1375                 {
1376                         SCM key = $2; // use symbol?
1377                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1378                 }
1379                 Music * quote = 0;
1380                 if (gh_vector_p (evs))
1381                 {
1382                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1383                         quote->set_property ("duration", $3);
1384                         quote->set_property ("quoted-events", evs);
1385                 } else {
1386                         THIS->here_input ().warning (_f ("Can\'t find music"));
1387                         quote = MY_MAKE_MUSIC ("Event");
1388                 }
1389                 quote->set_spot (THIS->here_input ());
1390                 $$ = quote;
1391         }
1392         | OCTAVE { THIS->push_spot (); }
1393           pitch {
1394                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1395                 $$ = l;
1396                 $$->set_spot (THIS->pop_spot ());
1397                 $$->set_property ("pitch", $3);
1398         }
1399         | E_LEFTSQUARE {
1400                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1401                 l->set_property ("span-direction", gh_int2scm (START));
1402                 l->set_spot (THIS->here_input ());
1403
1404                 $$ = MY_MAKE_MUSIC ("EventChord");
1405                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1406                 scm_gc_unprotect_object (l->self_scm ());
1407                 $$->set_spot (THIS->here_input ());
1408         }
1409         | E_RIGHTSQUARE {
1410                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1411                 l->set_property ("span-direction", gh_int2scm (STOP));
1412                 l->set_spot (THIS->here_input ());
1413
1414                 $$ = MY_MAKE_MUSIC ("EventChord");
1415                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1416                 $$->set_spot (THIS->here_input ());
1417                 scm_gc_unprotect_object (l->self_scm ());
1418         }
1419         | E_BACKSLASH {
1420                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1421                 $$->set_spot (THIS->here_input ());
1422         }
1423         | '|'      {
1424
1425                 $$ = MY_MAKE_MUSIC ("BarCheck");
1426                 $$->set_spot (THIS->here_input ());
1427         }
1428         | TRANSPOSITION pitch {
1429                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1430                                         $2);
1431                 $$->set_spot (THIS-> here_input ());
1432                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1433                         $$ , SCM_EOL);
1434         }
1435         | BAR STRING                    {
1436                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1437
1438                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1439                                         t, SCM_EOL);
1440                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1441                 $$->set_spot (THIS->here_input ());
1442                 t->set_spot (THIS->here_input ());
1443         }
1444         | PARTIAL duration_length       {
1445                 Moment m = - unsmob_duration ($2)->get_length ();
1446                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1447                 p->set_spot (THIS->here_input ());
1448                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1449                                         p, SCM_EOL);
1450                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1451                                         p, SCM_EOL);
1452                 $$ =p ;
1453         }
1454         | CLEF STRING  {
1455                 static SCM proc ;
1456                 if (!proc)
1457                         proc = scm_c_eval_string ("make-clef-set");
1458
1459                 SCM result = scm_call_1 (proc, $2);
1460                 scm_gc_protect_object (result);
1461                 $$ = unsmob_music (result);
1462         }
1463         | TIME_T fraction  {
1464                 static SCM proc;
1465                 if (!proc)
1466                         proc = scm_c_eval_string ("make-time-signature-set");
1467
1468                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1469                 scm_gc_protect_object (result);
1470                 $$ = unsmob_music (result);
1471         }
1472         | MARK scalar {
1473                 static SCM proc;
1474                 if (!proc)
1475                         proc = scm_c_eval_string ("make-mark-set");
1476
1477                 SCM result = scm_call_1 (proc, $2);
1478                 scm_gc_protect_object (result);
1479                 $$ = unsmob_music (result);
1480         }
1481         ;
1482
1483 command_req:
1484         BREATHE {
1485                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1486         }
1487         | E_TILDE {
1488                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1489         }
1490         | MARK DEFAULT  {
1491                 Music * m = MY_MAKE_MUSIC ("MarkEvent");
1492                 $$ = m;
1493         }
1494         | tempo_event {
1495                 $$ = $1;
1496         }
1497         | KEY DEFAULT {
1498                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1499                 $$ = key;
1500         }
1501         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1502
1503                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1504                 if (scm_ilength ($3) > 0)
1505                 {
1506                         key->set_property ("pitch-alist", $3);
1507                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1508                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1509                 } else {
1510                         THIS->parser_error (_("Second argument must be pitch list."));
1511                 }
1512
1513                 $$ = key;
1514         }
1515         ;
1516
1517 post_events:
1518         /* empty */ {
1519                 $$ = SCM_EOL;
1520         }
1521         | post_events post_event {
1522                 $2->set_spot (THIS->here_input ());
1523                 $$ = gh_cons ($2->self_scm (), $$);
1524                 scm_gc_unprotect_object ($2->self_scm ());
1525         }
1526         | post_events tagged_post_event {
1527                 $2 -> set_spot (THIS->here_input ());
1528                 $$ = scm_cons ($2->self_scm (), $$);
1529                 scm_gc_unprotect_object ($2->self_scm ());
1530         }
1531         ;
1532
1533
1534 tagged_post_event:
1535         '-' TAG embedded_scm post_event {
1536                 tag_music ($4, $3, THIS->here_input ());
1537                 $$ = $4;
1538         }
1539         ;
1540
1541 post_event:
1542         direction_less_event {
1543                 $$ = $1;
1544         }
1545         | HYPHEN {
1546                 if (!THIS->lexer_->is_lyric_state ())
1547                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1548                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1549         }
1550         | EXTENDER {
1551                 if (!THIS->lexer_->is_lyric_state ())
1552                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1553                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1554         }
1555         | script_dir direction_reqd_event {
1556                 if ($1)
1557                         $2->set_property ("direction", gh_int2scm ($1));
1558                 $$ = $2;
1559         }
1560         | script_dir direction_less_event {
1561                 if ($1)
1562                         $2->set_property ("direction", gh_int2scm ($1));
1563                 $$ = $2;
1564         }
1565         | string_number_event
1566         ;
1567
1568 string_number_event:
1569         E_UNSIGNED {
1570                 Music * s = MY_MAKE_MUSIC ("StringNumberEvent");
1571                 s->set_property ("string-number",  gh_int2scm ($1));
1572                 s->set_spot (THIS->here_input ());
1573                 $$ = s;
1574         }
1575         ;
1576
1577
1578 direction_less_event:
1579         '['  {
1580
1581
1582 /*
1583
1584 TODO: should take all these defs out of the parser, adn make use
1585 configurable, i.e.
1586
1587
1588 (set-articulation '~ "trill")
1589
1590 */
1591                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1592                 m->set_spot (THIS->here_input ());
1593                 m->set_property ("span-direction" , gh_int2scm (START));
1594                 $$ = m;
1595         }
1596         | ']'  {
1597                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1598                 m->set_spot (THIS->here_input ());
1599                 m->set_property ("span-direction" , gh_int2scm (STOP));
1600                 $$ = m;
1601         }
1602         | '~' {
1603                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1604                 m->set_spot (THIS->here_input ());
1605                 $$ = m;
1606         }
1607         | close_event {
1608                 $$ = $1;
1609                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1610                         gh_int2scm (START));
1611         }
1612         | open_event {
1613                 $$ = $1;
1614                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1615                         gh_int2scm (STOP));
1616         }
1617         | EVENT_IDENTIFIER      {
1618                 $$ = unsmob_music ($1);
1619         }
1620         | tremolo_type  {
1621                Music * a = MY_MAKE_MUSIC ("TremoloEvent");
1622                a->set_spot (THIS->here_input ());
1623                a->set_property ("tremolo-type", gh_int2scm ($1));
1624                $$ = a;
1625         }
1626         ;
1627
1628 direction_reqd_event:
1629         gen_text_def {
1630                 $$ = $1;
1631         }
1632         | script_abbreviation {
1633                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1634                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1635                 if (gh_string_p (s))
1636                         a->set_property ("articulation-type", s);
1637                 else THIS->parser_error (_ ("Expecting string as script definition"));
1638                 $$ = a;
1639         }
1640         ;
1641
1642 oct_check:
1643         /**/ { $$ = SCM_EOL; }
1644         | '='  { $$ = gh_int2scm (0); }
1645         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1646         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1647         ;
1648
1649 sup_quotes:
1650         '\'' {
1651                 $$ = 1;
1652         }
1653         | sup_quotes '\'' {
1654                 $$ ++;
1655         }
1656         ;
1657
1658 sub_quotes:
1659         ',' {
1660                 $$ = 1;
1661         }
1662         | sub_quotes ',' {
1663                 $$ ++ ;
1664         }
1665         ;
1666
1667 steno_pitch:
1668         NOTENAME_PITCH  {
1669                 $$ = $1;
1670         }
1671         | NOTENAME_PITCH sup_quotes     {
1672                 Pitch p = *unsmob_pitch ($1);
1673                 p = p.transposed (Pitch ($2,0,0));
1674                 $$ = p.smobbed_copy ();
1675         }
1676         | NOTENAME_PITCH sub_quotes      {
1677                 Pitch p =* unsmob_pitch ($1);
1678                 p = p.transposed (Pitch (-$2,0,0));
1679                 $$ = p.smobbed_copy ();
1680         }
1681         ;
1682
1683 /*
1684 ugh. duplication
1685 */
1686
1687 steno_tonic_pitch:
1688         TONICNAME_PITCH {
1689                 $$ = $1;
1690         }
1691         | TONICNAME_PITCH sup_quotes    {
1692                 Pitch p = *unsmob_pitch ($1);
1693                 p = p.transposed (Pitch ($2,0,0));
1694                 $$ = p.smobbed_copy ();
1695         }
1696         | TONICNAME_PITCH sub_quotes     {
1697                 Pitch p =* unsmob_pitch ($1);
1698
1699                 p = p.transposed (Pitch (-$2,0,0));
1700                 $$ = p.smobbed_copy ();
1701         }
1702         ;
1703
1704 pitch:
1705         steno_pitch {
1706                 $$ = $1;
1707         }
1708         ;
1709
1710 pitch_also_in_chords:
1711         pitch
1712         | steno_tonic_pitch
1713         ;
1714
1715 close_event:
1716         '('     {
1717                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1718                 $$ = s;
1719                 s->set_spot (THIS->here_input ());
1720         }
1721         | E_OPEN        {
1722                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1723                 $$ = s;
1724                 s->set_spot (THIS->here_input ());
1725         }
1726         | E_SMALLER {
1727                 Music *s =MY_MAKE_MUSIC ("CrescendoEvent");
1728                 $$ = s;
1729                 s->set_spot (THIS->here_input ());
1730         }
1731         | E_BIGGER {
1732                 Music *s =MY_MAKE_MUSIC ("DecrescendoEvent");
1733                 $$ = s;
1734                 s->set_spot (THIS->here_input ());
1735         }
1736         ;
1737
1738
1739 open_event:
1740         E_EXCLAMATION   {
1741                 Music *s =  MY_MAKE_MUSIC ("CrescendoEvent");
1742                 s->set_spot (THIS->here_input ());
1743
1744                 $$ = s;
1745         }
1746         | ')'   {
1747                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1748                 $$ = s;
1749                 s->set_spot (THIS->here_input ());
1750
1751         }
1752         | E_CLOSE       {
1753                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1754                 $$ = s;
1755                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1756                 s->set_spot (THIS->here_input ());
1757         }
1758         ;
1759
1760 gen_text_def:
1761         full_markup {
1762                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1763                 t->set_property ("text", $1);
1764                 t->set_spot (THIS->here_input ());
1765                 $$ = t;
1766         }
1767         | string {
1768                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1769                 t->set_property ("text", make_simple_markup ($1));
1770                 t->set_spot (THIS->here_input ());
1771                 $$ = t;
1772
1773         }
1774         | DIGIT {
1775                 Music * t = MY_MAKE_MUSIC ("FingerEvent");
1776                 t->set_property ("digit",  gh_int2scm ($1));
1777                 t->set_spot (THIS->here_input ());
1778                 $$ = t;
1779         }
1780         ;
1781
1782 script_abbreviation:
1783         '^'             {
1784                 $$ = scm_makfrom0str ("Hat");
1785         }
1786         | '+'           {
1787                 $$ = scm_makfrom0str ("Plus");
1788         }
1789         | '-'           {
1790                 $$ = scm_makfrom0str ("Dash");
1791         }
1792         | '|'           {
1793                 $$ = scm_makfrom0str ("Bar");
1794         }
1795         | '>'           {
1796                 $$ = scm_makfrom0str ("Larger");
1797         }
1798         | '.'           {
1799                 $$ = scm_makfrom0str ("Dot");
1800         }
1801         | '_' {
1802                 $$ = scm_makfrom0str ("Underscore");
1803         }
1804         ;
1805
1806 script_dir:
1807         '_'     { $$ = DOWN; }
1808         | '^'   { $$ = UP; }
1809         | '-'   { $$ = CENTER; }
1810         ;
1811
1812
1813 absolute_pitch:
1814         steno_pitch     {
1815                 $$ = $1;
1816         }
1817         ;
1818
1819 duration_length:
1820         multiplied_duration {
1821                 $$ = $1;
1822         }
1823         ;
1824
1825 optional_notemode_duration:
1826         {
1827                 Duration dd = THIS->default_duration_;
1828                 $$ = dd.smobbed_copy ();
1829
1830                 THIS->beam_check ($$);
1831         }
1832         | multiplied_duration   {
1833                 $$ = $1;
1834                 THIS->default_duration_ = *unsmob_duration ($$);
1835
1836                 THIS->beam_check ($$);
1837         }
1838         ;
1839
1840 steno_duration:
1841         bare_unsigned dots              {
1842                 int l = 0;
1843                 if (!is_is_duration ($1))
1844                         THIS->parser_error (_f ("not a duration: %d", $1));
1845                 else
1846                         l =  intlog2 ($1);
1847
1848                 $$ = Duration (l, $2).smobbed_copy ();
1849         }
1850         | DURATION_IDENTIFIER dots      {
1851                 Duration *d =unsmob_duration ($1);
1852                 Duration k (d->duration_log (),d->dot_count () + $2);
1853
1854                 *d = k;
1855                 $$ = $1;
1856         }
1857         ;
1858
1859
1860
1861
1862 multiplied_duration:
1863         steno_duration {
1864                 $$ = $1;
1865         }
1866         | multiplied_duration '*' bare_unsigned {
1867                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1868         }
1869         | multiplied_duration '*' FRACTION {
1870                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1871
1872                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1873         }
1874         ;
1875
1876 fraction:
1877         FRACTION { $$ = $1; }
1878         | UNSIGNED '/' UNSIGNED {
1879                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1880         }
1881         ;
1882
1883 dots:
1884         /* empty */     {
1885                 $$ = 0;
1886         }
1887         | dots '.' {
1888                 $$ ++;
1889         }
1890         ;
1891
1892
1893 tremolo_type:
1894         ':'     {
1895                 $$ =0;
1896         }
1897         | ':' bare_unsigned {
1898                 if (!is_is_duration ($2))
1899                         THIS->parser_error (_f ("not a duration: %d", $2));
1900                 $$ = $2;
1901         }
1902         ;
1903
1904
1905
1906 /*****************************************************************
1907                 BASS FIGURES
1908 *****************************************************************/
1909 bass_number:
1910         DIGIT   {
1911                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1912         }
1913         | UNSIGNED {
1914                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1915         }
1916         | STRING { $$ =  $1; }
1917         ;
1918
1919 bass_mod:
1920         '-'     { $$ = -2; }
1921         | '+'   { $$ = 2; }
1922         | '!'   { $$ = 0; }
1923         ;
1924
1925 bass_figure:
1926         FIGURE_SPACE {
1927                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1928                 $$ = bfr->self_scm ();
1929                 scm_gc_unprotect_object ($$);
1930         }
1931         | bass_number  {
1932                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1933                 $$ = bfr->self_scm ();
1934
1935                 bfr->set_property ("figure", $1);
1936
1937                 scm_gc_unprotect_object ($$);
1938         }
1939         | bass_figure bass_mod {
1940                 Music *m = unsmob_music ($1);
1941                 if ($2) {
1942                         SCM salter =m->get_property ("alteration");
1943                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1944                         m->set_property ("alteration",
1945                                 gh_int2scm (alter + $2));
1946                 } else {
1947                         m->set_property ("alteration", gh_int2scm (0));
1948                 }
1949         }
1950         ;
1951
1952 br_bass_figure:
1953         '[' bass_figure {
1954                 $$ = $2;
1955                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1956         }
1957         | bass_figure   {
1958                 $$ = $1;
1959         }
1960         | br_bass_figure ']' {
1961                 $$ = $1;
1962                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1963         }
1964         ;
1965
1966 figure_list:
1967         /**/            {
1968                 $$ = SCM_EOL;
1969         }
1970         | figure_list br_bass_figure {
1971                 $$ = scm_cons ($2, $1);
1972         }
1973         ;
1974
1975 figure_spec:
1976         FIGURE_OPEN figure_list FIGURE_CLOSE {
1977                 Music * m = MY_MAKE_MUSIC ("EventChord");
1978                 $2 = scm_reverse_x ($2, SCM_EOL);
1979                 m->set_property ("elements",  $2);
1980                 $$ = m->self_scm ();
1981         }
1982         ;
1983
1984
1985 optional_rest:
1986         /**/   { $$ = 0; }
1987         | REST { $$ = 1; }
1988         ;
1989
1990 simple_element:
1991         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1992
1993                 Input i = THIS->pop_spot ();
1994                 if (!THIS->lexer_->is_note_state ())
1995                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1996
1997                 Music *n = 0;
1998                 if ($6)
1999                         n =  MY_MAKE_MUSIC ("RestEvent");
2000                 else
2001                         n =  MY_MAKE_MUSIC ("NoteEvent");
2002
2003                 n->set_property ("pitch", $1);
2004                 n->set_property ("duration", $5);
2005
2006                 if (gh_number_p ($4))
2007                 {
2008                         int q = gh_scm2int ($4);
2009                         n->set_property ("absolute-octave", gh_int2scm (q-1));
2010                 }
2011
2012                 if ($3 % 2)
2013                         n->set_property ("cautionary", SCM_BOOL_T);
2014                 if ($2 % 2 || $3 % 2)
2015                         n->set_property ("force-accidental", SCM_BOOL_T);
2016
2017                 Music *v = MY_MAKE_MUSIC ("EventChord");
2018                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2019                 scm_gc_unprotect_object (n->self_scm ());
2020
2021                 v->set_spot (i);
2022                 n->set_spot (i);
2023                 $$ = v;
2024         }
2025         | DRUM_PITCH optional_notemode_duration {
2026                 Input i = THIS->pop_spot ();
2027
2028                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
2029                 n->set_property ("duration" ,$2);
2030                 n->set_property ("drum-type" , $1);
2031
2032                 Music *v = MY_MAKE_MUSIC ("EventChord");
2033                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2034                 scm_gc_unprotect_object (n->self_scm ());
2035                 v->set_spot (i);
2036                 n->set_spot (i);
2037                 $$ = v;
2038
2039         }
2040         | figure_spec optional_notemode_duration {
2041                 Music * m = unsmob_music ($1);
2042                 Input i = THIS->pop_spot ();
2043                 m->set_spot (i);
2044                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2045                 {
2046                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2047                 }
2048                 $$ = m;
2049         }
2050         | RESTNAME optional_notemode_duration           {
2051
2052                 Input i = THIS->pop_spot ();
2053                 Music * ev = 0;
2054                 if (ly_scm2string ($1) =="s") {
2055                         /* Space */
2056                         ev = MY_MAKE_MUSIC ("SkipEvent");
2057                   }
2058                 else {
2059                         ev = MY_MAKE_MUSIC ("RestEvent");
2060
2061                     }
2062                 ev->set_property ("duration" ,$2);
2063                 ev->set_spot (i);
2064                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2065                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2066                 velt->set_spot (i);
2067
2068                 scm_gc_unprotect_object (ev->self_scm ());
2069
2070                 $$ = velt;
2071         }
2072         | MULTI_MEASURE_REST optional_notemode_duration         {
2073                 THIS->pop_spot ();
2074
2075                 static SCM proc ;
2076                 if (!proc)
2077                         proc = scm_c_eval_string ("make-multi-measure-rest");
2078
2079                 SCM mus = scm_call_2 (proc, $2,
2080                         make_input (THIS->here_input ()));
2081                 scm_gc_protect_object (mus);
2082                 $$ = unsmob_music (mus);
2083         }
2084
2085         | lyric_element optional_notemode_duration      {
2086                 Input i = THIS->pop_spot ();
2087                 if (!THIS->lexer_->is_lyric_state ())
2088                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2089
2090                 Music * lreq = MY_MAKE_MUSIC ("LyricEvent");
2091                 lreq->set_property ("text", $1);
2092                 lreq->set_property ("duration",$2);
2093                 lreq->set_spot (i);
2094                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2095                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2096
2097                 $$= velt;
2098         }
2099         | new_chord {
2100                 THIS->pop_spot ();
2101
2102                 if (!THIS->lexer_->is_chord_state ())
2103                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2104                 $$ = unsmob_music ($1);
2105         }
2106         ;
2107
2108 lyric_element:
2109         full_markup { $$ = $1; }
2110         | STRING {  $$ = $1 ; }
2111         ;
2112
2113 new_chord:
2114         steno_tonic_pitch optional_notemode_duration   {
2115                 $$ = make_chord ($1, $2, SCM_EOL);
2116         }
2117         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2118                 SCM its = scm_reverse_x ($4, SCM_EOL);
2119                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2120         }
2121         ;
2122
2123 chord_items:
2124         /**/ {
2125                 $$ = SCM_EOL;
2126         }
2127         | chord_items chord_item {
2128                 $$ = gh_cons ($2, $$);
2129         }
2130         ;
2131
2132 chord_separator:
2133         CHORD_COLON {
2134                 $$ = ly_symbol2scm ("chord-colon");
2135         }
2136         | CHORD_CARET {
2137                 $$ = ly_symbol2scm ("chord-caret");
2138         }
2139         | CHORD_SLASH steno_tonic_pitch {
2140                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2141         }
2142         | CHORD_BASS steno_tonic_pitch {
2143                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2144         }
2145         ;
2146
2147 chord_item:
2148         chord_separator {
2149                 $$ = $1;
2150         }
2151         | step_numbers {
2152                 $$ = scm_reverse_x ($1, SCM_EOL);
2153         }
2154         | CHORD_MODIFIER  {
2155                 $$ = $1;
2156         }
2157         ;
2158
2159 step_numbers:
2160         step_number { $$ = gh_cons ($1, SCM_EOL); }
2161         | step_numbers '.' step_number {
2162                 $$ = gh_cons ($3, $$);
2163         }
2164         ;
2165
2166 step_number:
2167         bare_unsigned {
2168                 $$ = make_chord_step ($1, 0);
2169         }
2170         | bare_unsigned '+' {
2171                 $$ = make_chord_step ($1, SHARP);
2172         }
2173         | bare_unsigned CHORD_MINUS {
2174                 $$ = make_chord_step ($1, FLAT);
2175         }
2176         ;
2177
2178 /*
2179         UTILITIES
2180
2181 TODO: should deprecate in favor of Scheme?
2182
2183  */
2184 number_expression:
2185         number_expression '+' number_term {
2186                 $$ = scm_sum ($1, $3);
2187         }
2188         | number_expression '-' number_term {
2189                 $$ = scm_difference ($1, $3);
2190         }
2191         | number_term
2192         ;
2193
2194 number_term:
2195         number_factor {
2196                 $$ = $1;
2197         }
2198         | number_factor '*' number_factor {
2199                 $$ = scm_product ($1, $3);
2200         }
2201         | number_factor '/' number_factor {
2202                 $$ = scm_divide ($1, $3);
2203         }
2204         ;
2205
2206 number_factor:
2207         '-'  number_factor { /* %prec UNARY_MINUS */
2208                 $$ = scm_difference ($2, SCM_UNDEFINED);
2209         }
2210         | bare_number
2211         ;
2212
2213
2214 bare_number:
2215         UNSIGNED        {
2216                 $$ = gh_int2scm ($1);
2217         }
2218         | REAL          {
2219                 $$ = $1;
2220         }
2221         | NUMBER_IDENTIFIER             {
2222                 $$ = $1;
2223         }
2224         | REAL NUMBER_IDENTIFIER        {
2225                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2226         }
2227         | UNSIGNED NUMBER_IDENTIFIER    {
2228                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2229         }
2230         ;
2231
2232
2233 bare_unsigned:
2234         UNSIGNED {
2235                         $$ = $1;
2236         }
2237         | DIGIT {
2238                 $$ = $1;
2239         }
2240         ;
2241
2242 bare_int:
2243         bare_number {
2244                 if (scm_integer_p ($1) == SCM_BOOL_T)
2245                 {
2246                         int k = gh_scm2int ($1);
2247                         $$ = k;
2248                 } else
2249                 {
2250                         THIS->parser_error (_ ("need integer number arg"));
2251                         $$ = 0;
2252                 }
2253         }
2254         | '-' bare_int {
2255                 $$ = -$2;
2256         }
2257         ;
2258
2259
2260 string:
2261         STRING          {
2262                 $$ = $1;
2263         }
2264         | STRING_IDENTIFIER     {
2265                 $$ = $1;
2266         }
2267         | string '+' string {
2268                 $$ = scm_string_append (scm_list_2 ($1, $3));
2269         }
2270         ;
2271
2272
2273 exclamations:
2274                 { $$ = 0; }
2275         | exclamations '!'      { $$ ++; }
2276         ;
2277
2278 questions:
2279                 { $$ = 0; }
2280         | questions '?' { $$ ++; }
2281         ;
2282
2283
2284
2285 full_markup:
2286         MARKUP_IDENTIFIER {
2287                 $$ = $1;
2288         }
2289         | MARKUP
2290                 { THIS->lexer_->push_markup_state (); }
2291         markup
2292                 { $$ = $3;
2293                   THIS->lexer_->pop_state ();
2294                 }
2295         ;
2296
2297
2298 /*
2299 This should be done more dynamically if possible.
2300 */
2301 markup:
2302         STRING {
2303                 $$ = make_simple_markup ($1);
2304         }
2305         | MARKUP_HEAD_EMPTY {
2306                 $$ = scm_list_1 ($1);
2307         }
2308         | MARKUP_HEAD_MARKUP0 markup {
2309                 $$ = scm_list_2 ($1, $2);
2310         }
2311         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2312                 $$ = scm_list_3 ($1, $2, $3);
2313         }
2314         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2315                 $$  = scm_list_3 ($1, $2, $3);
2316         }
2317         | markup_line {
2318                 $$ = $1;
2319         }
2320         | MARKUP_HEAD_LIST0 markup_list {
2321                 $$ = scm_list_2 ($1,$2);
2322         }
2323         | MARKUP_HEAD_SCM0 embedded_scm {
2324                 $$ = scm_list_2 ($1, $2);
2325         }
2326         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2327                 $$ = scm_list_4 ($1, $2, $3, $4);
2328         }
2329         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2330                 $$ = scm_list_4 ($1, $2, $3, $4);
2331         }
2332         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2333                 $$ = scm_list_3 ($1, $2, $3);
2334         }
2335         | MARKUP_IDENTIFIER {
2336                 $$ = $1;
2337         }
2338         | STRING_IDENTIFIER {
2339                 $$ = $1;
2340         }
2341         ;
2342
2343 markup_list:
2344         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2345         ;
2346
2347 markup_line:
2348         '{' markup_list_body '}' {
2349                 static SCM line ;
2350                 if (!line)
2351                         line = scm_c_eval_string ("line-markup");
2352
2353                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2354         }
2355         ;
2356
2357 markup_list_body:
2358         /**/ {  $$ = SCM_EOL; }
2359         | markup_list_body markup {
2360                 $$ = gh_cons ($2, $1) ;
2361         }
2362         ;
2363
2364
2365 %%
2366
2367 void
2368 My_lily_parser::set_yydebug (bool )
2369 {
2370 #if 0
2371         yydebug = 1;
2372 #endif
2373 }
2374
2375 extern My_lily_parser * current_parser;
2376
2377 void
2378 My_lily_parser::do_yyparse ()
2379 {
2380         current_parser = this;;
2381         yyparse ((void*)this);
2382 }
2383
2384
2385 /*
2386 Should make this optional?    It will also complain when you do
2387
2388         [s4]
2389
2390 which is entirely legitimate.
2391
2392 Or we can scrap it. Barchecks should detect wrong durations, and
2393 skipTypesetting speeds it up a lot.
2394 */
2395
2396 void
2397 My_lily_parser::beam_check (SCM dur)
2398 {
2399   Duration *d = unsmob_duration (dur);
2400   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2401     {
2402       Music * m = unsmob_music (last_beam_start_);
2403       m->origin ()->warning (_("Suspect duration found following this beam"));
2404     }
2405   last_beam_start_ = SCM_EOL;
2406 }
2407
2408
2409
2410
2411 /*
2412
2413 It is a little strange to have this function in this file, but
2414 otherwise, we have to import music classes into the lexer.
2415
2416 */
2417 int
2418 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2419 {
2420         if (gh_string_p (sid)) {
2421                 *destination = sid;
2422                 return STRING_IDENTIFIER;
2423         } else if (gh_number_p (sid)) {
2424                 *destination = sid;
2425                 return NUMBER_IDENTIFIER;
2426         } else if (unsmob_context_def (sid)) {
2427                 *destination = unsmob_context_def (sid)->clone_scm ();
2428                 return CONTEXT_DEF_IDENTIFIER;
2429         } else if (unsmob_score (sid)) {
2430                 Score *sc =  new Score (*unsmob_score (sid));
2431                 *destination =sc->self_scm ();
2432                 return SCORE_IDENTIFIER;
2433         } else if (Music * mus =unsmob_music (sid)) {
2434                 mus = mus->clone ();
2435                 *destination = mus->self_scm ();
2436                 unsmob_music (*destination)->
2437                         set_property ("origin", make_input (last_input_));
2438                 return dynamic_cast<Event*> (mus)
2439                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2440         } else if (unsmob_duration (sid)) {
2441                 *destination = unsmob_duration (sid)->smobbed_copy ();
2442                 return DURATION_IDENTIFIER;
2443         } else if (unsmob_music_output_def (sid)) {
2444                 Music_output_def *p = unsmob_music_output_def (sid);
2445                 p = p->clone ();
2446
2447                 *destination = p->self_scm ();
2448                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2449         } else if (Text_item::markup_p (sid)) {
2450                 *destination = sid;
2451                 return MARKUP_IDENTIFIER;
2452         }
2453
2454         return -1;
2455 }
2456
2457 Music *
2458 property_op_to_music (SCM op)
2459 {
2460         Music * m = 0;
2461         SCM tag = gh_car (op);
2462         SCM symbol  = gh_cadr (op);
2463         SCM args = gh_cddr (op);
2464         SCM grob_val = SCM_UNDEFINED;
2465         SCM grob_sym = SCM_UNDEFINED;
2466         SCM val = SCM_UNDEFINED;
2467
2468         if (tag == ly_symbol2scm ("assign"))
2469                 {
2470                 m =  MY_MAKE_MUSIC ("PropertySet");
2471                 val = gh_car (args);
2472                 }
2473         else if (tag == ly_symbol2scm ("unset"))
2474                 m =  MY_MAKE_MUSIC ("PropertyUnset");
2475         else if (tag == ly_symbol2scm ("poppush")
2476                  || tag == ly_symbol2scm ("push"))
2477                 {
2478                 m  = MY_MAKE_MUSIC ("OverrideProperty");
2479                 grob_sym = gh_car (args);
2480                 grob_val = gh_cadr (args);
2481                 }
2482         else if (tag == ly_symbol2scm ("pop")) {
2483                 m = MY_MAKE_MUSIC ("RevertProperty");
2484                 grob_sym = gh_car (args);
2485                 }
2486
2487         m->set_property ("symbol", symbol);
2488
2489         if (val != SCM_UNDEFINED)
2490                 m->set_property ("value", val);
2491         if (grob_val != SCM_UNDEFINED)
2492                 m->set_property ("grob-value", grob_val);
2493
2494         if (grob_sym != SCM_UNDEFINED)
2495                 {
2496                 bool itc = internal_type_checking_global_b;
2497                 /* UGH.
2498                 */
2499                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2500                 if (autobeam)
2501                         internal_type_checking_global_b = false;
2502                 m->set_property ("grob-property", grob_sym);
2503                 if (autobeam)
2504                         internal_type_checking_global_b = itc;
2505                 }
2506
2507         if (op == ly_symbol2scm ("poppush"))
2508                 m->set_property ("pop-first", SCM_BOOL_T);
2509
2510
2511         return m;
2512 }
2513
2514 Music*
2515 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2516 {
2517         Music * csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2518
2519         csm->set_property ("element", m->self_scm ());
2520         scm_gc_unprotect_object (m->self_scm ());
2521
2522         csm->set_property ("context-type",
2523                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2524         csm->set_property ("property-operations", ops);
2525
2526         if (gh_string_p (id))
2527                 csm->set_property ("context-id", id);
2528         return csm;
2529 }
2530
2531
2532 SCM
2533 get_next_unique_context ()
2534 {
2535         static int new_context_count;
2536
2537         char s[1024];
2538         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2539
2540         return scm_makfrom0str (s);
2541 }
2542