lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Two shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 2.  \repeat
  23         \repeat .. \alternative
  24
  25
  26     \repeat { \repeat .. \alternative }
  27
  28 or
  29
  30     \repeat { \repeat } \alternative
  31
  32 )
  33
  34 --hwn
  35
  36  */
  37
  38 /*
  39
  40 TODO:
  41
  42 * The rules for who is protecting what are very shady. Uniformise
  43   this.
  44
  45 * There are too many lexical modes?
  46
  47 */
  48
  49 #include <ctype.h>
  50 #include <stdlib.h>
  51
  52
  53 #include "scm-option.hh"
  54 #include "translator-def.hh"
  55 #include "lily-guile.hh"
  56 #include "misc.hh"
  57 #include "my-lily-lexer.hh"
  58 #include "paper-def.hh"
  59 #include "midi-def.hh"
  60 #include "main.hh"
  61 #include "file-path.hh"
  62 #include "warn.hh"
  63 #include "dimensions.hh"
  64 #include "my-lily-parser.hh"
  65 #include "score.hh"
  66 #include "input-file-results.hh"
  67 #include "input.hh"
  68 #include "lilypond-input-version.hh"
  69 #include "scm-hash.hh"
  70 #include "auto-change-iterator.hh"
  71 #include "ly-modules.hh"
  72 #include "music-sequence.hh"
  73 #include "input-smob.hh"
  74 #include "event.hh"
  75 #include "text-item.hh"
  76 #include "music-list.hh"
  77
  78
  79 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  80
  81
  82
  83 #define YYERROR_VERBOSE 1
  84
  85 My_lily_parser* my_lily_parser;
  86 #define YYPARSE_PARAM my_lily_parser
  87 #define YYLEX_PARAM my_lily_parser
  88 #define THIS\
  89         ((My_lily_parser *) my_lily_parser)
  90
  91 #define yyerror THIS->parser_error
  92
  93
  94
  95
  96
  97 bool
  98 regular_identifier_b (SCM id)
  99 {
 100   String str = ly_scm2string (id);
 101   char const *s = str.to_str0 () ;
 102
 103   bool v = true;
 104   while (*s && v)
 105    {
 106         v = v && isalpha (*s);
 107         s++;
 108    }
 109   return v;
 110 }
 111
 112 SCM
 113 make_simple_markup (SCM a)
 114 {
 115         static SCM simple;
 116         if (!simple)
 117         simple = scm_c_eval_string ("simple-markup");
 118
 119         return scm_list_n (simple, a, SCM_UNDEFINED);
 120 }
 121
 122
 123 bool
 124 is_duration_b (int t)
 125 {
 126   return t && t == 1 << intlog2 (t);
 127 }
 128
 129 void
 130 set_music_properties (Music *p, SCM a)
 131 {
 132   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 133         {
 134         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 135         }
 136 }
 137
 138 SCM
 139 make_chord_step (int step, int alter)
 140 {
 141         if (step == 7)
 142                 alter--;
 143
 144         /* ugh: fucks up above 13 */
 145         Pitch m(step > 7 ? 1 : 0,(step - 1) % 7, alter);
 146         return m.smobbed_copy ();
 147 }
 148
 149
 150 SCM
 151 make_chord (SCM pitch, SCM dur, SCM modification_list)
 152 {
 153         static SCM chord_ctor;
 154         if (!chord_ctor)
 155                 chord_ctor= scm_c_eval_string ("construct-chord");
 156         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 157         scm_gc_protect_object (ch);
 158         return ch;
 159 }
 160
 161 /*
 162   Todo: actually also use apply iso. call too ...
 163 */
 164 bool
 165 ly_input_procedure_p (SCM x)
 166 {
 167         return gh_procedure_p (x)
 168                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 169 }
 170
 171 Music*
 172 set_property_music (SCM sym, SCM value)
 173 {
 174         Music * p = MY_MAKE_MUSIC("PropertySet");
 175         p->set_mus_property ("symbol", sym);
 176         p->set_mus_property ("value", value);
 177         return p;
 178 }
 179
 180 %}
 181
 182 /* We use SCMs to do strings, because it saves us the trouble of
 183 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 184 of the parse stack onto the heap. */
 185
 186
 187 %union {
 188         String * string;
 189     Music *music;
 190     Score *score;
 191     Music_output_def * outputdef;
 192     SCM scm;
 193     int i;
 194 }
 195 %{
 196
 197 int
 198 yylex (YYSTYPE *s,  void * v)
 199 {
 200         My_lily_parser   *pars = (My_lily_parser*) v;
 201         My_lily_lexer * lex = pars->lexer_;
 202
 203         lex->lexval = (void*) s;
 204         lex->prepare_for_next_token();
 205         return lex->yylex ();
 206 }
 207
 208
 209 %}
 210
 211 %pure_parser
 212
 213
 214 %token ACCEPTS
 215 %token ADDLYRICS
 216 %token ALIAS
 217 %token ALTERNATIVE
 218 %token APPLY
 219 %token APPLYCONTEXT
 220 %token APPLYOUTPUT
 221 %token AUTOCHANGE
 222 %token BAR
 223 %token BREATHE
 224 %token CHORDMODIFIERS
 225 %token CHORDS
 226 %token CHORD_CLOSE
 227 %token CHORD_OPEN
 228 %token CLEF
 229 %token COMMANDSPANREQUEST
 230 %token CONSISTS
 231 %token CONSISTSEND
 232 %token CONTEXT
 233 %token DEFAULT
 234 %token DENIES
 235 %token DESCRIPTION
 236 %token DURATION
 237 %token EXTENDER
 238 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 239 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 240 %token GRACE
 241 %token ACCACCIATURA
 242 %token APPOGGIATURA
 243 %token GROBDESCRIPTIONS
 244 %token HEADER
 245 %token HYPHEN
 246 %token INVALID
 247 %token KEY
 248 %token LYRICS
 249 %token MARK
 250 %token MIDI
 251 %token MULTI_MEASURE_REST
 252 %token NAME
 253 %token NEWCONTEXT
 254 %token NOTES
 255 %token OCTAVE
 256 %token ONCE
 257 %token OUTPUTPROPERTY
 258 %token OVERRIDE SET REVERT
 259 %token PAPER
 260 %token PARTCOMBINE
 261 %token PARTIAL
 262 %token PITCH
 263 %token PITCHNAMES
 264 %token PROPERTY
 265 %token RELATIVE
 266 %token REMOVE
 267 %token REPEAT
 268 %token REST
 269 %token SCM_T
 270 %token SCORE
 271 %token SEQUENTIAL
 272 %token SIMULTANEOUS
 273 %token SKIP
 274 %token SPANREQUEST
 275 %token TEMPO
 276 %token TIMES
 277 %token TIME_T
 278 %token TRANSLATOR
 279 %token TRANSPOSE
 280 %token TYPE
 281 %token UNSET
 282
 283
 284 /* escaped */
 285 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 286 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 287 %token E_BACKSLASH
 288 %token <i> E_UNSIGNED
 289 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 290 %token FIGURE_SPACE
 291
 292 %type <i>       exclamations questions dots optional_rest
 293 %type <i>        bass_mod
 294 %type <scm>     grace_head
 295 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 296 %token <i>      DIGIT
 297 %token <scm>    NOTENAME_PITCH
 298 %token <scm>    TONICNAME_PITCH
 299 %token <scm>    CHORDMODIFIER_PITCH
 300 %token <scm>    DURATION_IDENTIFIER
 301 %token <scm>    FRACTION
 302 %token <id>     IDENTIFIER
 303 %token <scm>    CHORDNAMES
 304
 305 %token <scm> CHORD_MODIFIER
 306
 307 %token <scm>    SCORE_IDENTIFIER
 308 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 309 %token <scm>    NUMBER_IDENTIFIER
 310 %token <scm>    EVENT_IDENTIFIER
 311 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 312 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 313 %token <scm>    RESTNAME
 314 %token <scm>    STRING
 315 %token <scm>    SCM_T
 316 %token <i>      UNSIGNED
 317 %token <scm>   REAL
 318
 319 %token MARKUP
 320 %token <scm> MARKUP_HEAD_MARKUP0
 321 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 322 %token <scm> MARKUP_HEAD_SCM0
 323 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 324 %token <scm> MARKUP_HEAD_SCM0_SCM1
 325 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 326 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 327
 328 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 329 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 330
 331 %type <outputdef> output_def
 332 %type <scm>     lilypond_header lilypond_header_body
 333 %type <music>   open_event close_event
 334 %type <i>       sub_quotes sup_quotes
 335 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 336 %type <music>   Repeated_music
 337 %type <scm>     Alternative_music
 338 %type <i>       tremolo_type
 339 %type <i>       bare_int  bare_unsigned
 340 %type <i>       script_dir
 341 %type <scm>     identifier_init
 342
 343 %type <music> note_chord_element chord_body chord_body_element
 344 %type <scm>  chord_body_elements
 345 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 346 %type <scm>  verbose_duration
 347
 348 %type <scm>   post_events
 349 %type <music> gen_text_def direction_less_event direction_reqd_event
 350 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 351 %type <scm>   explicit_pitch steno_tonic_pitch
 352 %type <scm>     duration_length fraction
 353
 354 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 355
 356 %type <scm>  embedded_scm scalar
 357 %type <music>   Music Sequential_music Simultaneous_music
 358 %type <music>   relative_music re_rhythmed_music part_combined_music
 359 %type <music>   property_def translator_change  simple_property_def
 360 %type <scm> Music_list
 361 %type <outputdef>  music_output_def_body
 362 %type <music> shorthand_command_req
 363 %type <music>   post_event
 364 %type <music> command_req verbose_command_req
 365 %type <music>   extender_req
 366 %type <music> hyphen_req
 367 %type <music> string_number_event
 368 %type <scm>     string bare_number number_expression number_term number_factor
 369 %type <score>   score_block score_body
 370
 371 %type <scm>     translator_spec_block translator_spec_body
 372 %type <music>   tempo_event
 373 %type <scm> notenames_body notenames_block chordmodifiers_block
 374 %type <scm>     script_abbreviation
 375
 376
 377
 378 %left '-' '+'
 379
 380 /* We don't assign precedence to / and *, because we might need varied
 381 prec levels in different prods */
 382
 383 %left UNARY_MINUS
 384
 385 %%
 386
 387 lilypond:       /* empty */
 388         | lilypond toplevel_expression {}
 389         | lilypond assignment  { }
 390         | lilypond error {
 391                 THIS->error_level_  = 1;
 392         }
 393         | lilypond INVALID      {
 394                 THIS->error_level_  = 1;
 395         }
 396         ;
 397
 398 toplevel_expression:
 399         notenames_block                 {
 400                 THIS->lexer_->pitchname_tab_ =  $1;
 401         }
 402         | chordmodifiers_block                  {
 403                 THIS->lexer_->chordmodifier_tab_  = $1;
 404         }
 405         | lilypond_header {
 406                 THIS->input_file_->header_ = $1;
 407         }
 408         | score_block {
 409                 THIS->input_file_->scores_.push ($1);
 410         }
 411         | output_def {
 412                 if (dynamic_cast<Paper_def*> ($1))
 413                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 414                 else if (dynamic_cast<Midi_def*> ($1))
 415                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 416         }
 417         ;
 418
 419 embedded_scm:
 420         SCM_T
 421         | SCM_IDENTIFIER
 422         ;
 423
 424
 425 chordmodifiers_block:
 426         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 427         ;
 428
 429 notenames_block:
 430         PITCHNAMES notenames_body   {  $$ = $2; }
 431         ;
 432
 433 notenames_body:
 434         embedded_scm    {
 435           int i = scm_ilength ($1);
 436
 437           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 438           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 439                 SCM pt = ly_cdar (s);
 440                 scm_hashq_set_x (tab, ly_caar (s), pt);
 441           }
 442           $$ = tab;
 443         }
 444         ;
 445
 446 lilypond_header_body:
 447         {
 448                 $$ = ly_make_anonymous_module ();
 449                 THIS->lexer_->add_scope ($$);
 450         }
 451         | lilypond_header_body assignment  {
 452
 453         }
 454         ;
 455
 456 lilypond_header:
 457         HEADER '{' lilypond_header_body '}'     {
 458                 $$ = THIS->lexer_-> remove_scope();
 459         }
 460         ;
 461
 462
 463 /*
 464         DECLARATIONS
 465 */
 466 assignment:
 467         STRING {
 468                 THIS->push_spot ();
 469         }
 470         /* cont */ '=' identifier_init  {
 471
 472         /*
 473                 Should find generic way of associating input with objects.
 474         */
 475                 Input ip = THIS->pop_spot ();
 476
 477                 if (! regular_identifier_b ($1))
 478                 {
 479                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 480                 }
 481
 482                 THIS->lexer_->set_identifier ($1, $4);
 483
 484 /*
 485  TODO: devise standard for protection in parser.
 486
 487   The parser stack lives on the C-stack, which means that
 488 all objects can be unprotected as soon as they're here.
 489
 490 */
 491         }
 492         | embedded_scm { }
 493         ;
 494
 495
 496
 497 identifier_init:
 498         score_block {
 499                 $$ = $1->self_scm ();
 500                 scm_gc_unprotect_object ($$);
 501         }
 502         | full_markup {
 503                 $$ = $1;
 504         }
 505         | output_def {
 506                 $$ = $1->self_scm ();
 507                 scm_gc_unprotect_object ($$);
 508         }
 509         | translator_spec_block {
 510                 $$ = $1;
 511         }
 512         | Music  {
 513                 $$ = $1->self_scm ();
 514                 scm_gc_unprotect_object ($$);
 515         }
 516         | post_event {
 517                 $$ = $1->self_scm ();
 518                 scm_gc_unprotect_object ($$);
 519         }
 520         | verbose_duration {
 521                 $$ = $1;
 522         }
 523         | number_expression {
 524                 $$ = $1;
 525         }
 526         | string {
 527                 $$ = $1;
 528         }
 529         | embedded_scm  {
 530                 $$ = $1;
 531         }
 532         ;
 533
 534 translator_spec_block:
 535         TRANSLATOR '{' translator_spec_body '}'
 536                 {
 537                 $$ = $3;
 538         }
 539         ;
 540
 541 translator_spec_body:
 542         TRANSLATOR_IDENTIFIER   {
 543                 $$ = $1;
 544                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 545         }
 546         | TYPE STRING   {
 547                 $$ = Translator_def::make_scm ();
 548                 Translator_def*td =  unsmob_translator_def ($$);
 549                 td->translator_group_type_ = $2;
 550                 td->set_spot (THIS->here_input ());
 551         }
 552         | translator_spec_body DESCRIPTION string  {
 553                 unsmob_translator_def ($$)->description_ = $3;
 554         }
 555         | translator_spec_body STRING '=' embedded_scm                  {
 556                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 557         }
 558         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 559                 unsmob_translator_def ($$)
 560                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 561         }
 562         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 563                 unsmob_translator_def ($$)
 564                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 565         }
 566         | translator_spec_body STRING REVERT embedded_scm  {
 567           unsmob_translator_def ($$)->add_pop_property (
 568                 scm_string_to_symbol ($2), $4);
 569         }
 570         | translator_spec_body NAME STRING  {
 571                 unsmob_translator_def ($$)->type_name_ = $3;
 572         }
 573         | translator_spec_body CONSISTS STRING  {
 574                 unsmob_translator_def ($$)->add_element ($3);
 575         }
 576         | translator_spec_body ALIAS STRING  {
 577                 Translator_def*td = unsmob_translator_def ($$);
 578                 td->type_aliases_ = scm_cons ($3, td->type_aliases_);
 579         }
 580         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 581                 Translator_def*td = unsmob_translator_def($$);
 582                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 583                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 584                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 585         }
 586         | translator_spec_body CONSISTSEND STRING  {
 587                 unsmob_translator_def ($$)->add_last_element ( $3);
 588         }
 589         | translator_spec_body ACCEPTS STRING  {
 590                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 591         }
 592         | translator_spec_body DENIES STRING  {
 593                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 594         }
 595         | translator_spec_body REMOVE STRING  {
 596                 unsmob_translator_def ($$)->remove_element ($3);
 597         }
 598         ;
 599
 600 /*
 601         SCORE
 602 */
 603 score_block:
 604         SCORE {
 605                 THIS->push_spot ();
 606         }
 607         /*cont*/ '{' score_body '}'     {
 608                 THIS->pop_spot ();
 609                 $$ = $4;
 610                 if (!$$->defs_.size ())
 611                 {
 612                   Music_output_def *id =
 613                         unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 614                   $$->add_output (id ? id->clone () :  new Paper_def );
 615                 }
 616         }
 617         ;
 618
 619 score_body:
 620         Music   {
 621                 $$ = new Score;
 622
 623                 $$->set_spot (THIS->here_input ());
 624                 SCM m = $1->self_scm ();
 625                 scm_gc_unprotect_object (m);
 626
 627                 /*
 628                         guh.
 629                 */
 630                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 631                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 632                         m = gh_call1 (gh_car (check_funcs), m);
 633                 $$->music_ = m;
 634
 635         }
 636         | SCORE_IDENTIFIER {
 637                 $$ = unsmob_score ($1);
 638                 $$->set_spot (THIS->here_input ());
 639         }
 640         | score_body lilypond_header    {
 641                 $$->header_ = $2;
 642         }
 643         | score_body output_def {
 644                 $$->add_output ($2);
 645         }
 646         | score_body error {
 647
 648         }
 649         ;
 650
 651
 652 /*
 653         MIDI
 654 */
 655 output_def:
 656         music_output_def_body '}' {
 657                 $$ = $1;
 658                 THIS-> lexer_-> remove_scope ();
 659         }
 660         ;
 661
 662 music_output_def_body:
 663         MIDI '{'    {
 664                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 665
 666
 667                 Midi_def* p =0;
 668                 if (id)
 669                         p = dynamic_cast<Midi_def*> (id->clone ());
 670                 else
 671                         p = new Midi_def;
 672
 673                 $$ = p;
 674                 THIS->lexer_->add_scope (p->scope_);
 675         }
 676         | PAPER '{'     {
 677                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 678                   Paper_def *p = 0;
 679                 if (id)
 680                         p = dynamic_cast<Paper_def*> (id->clone ());
 681                 else
 682                         p = new Paper_def;
 683
 684                 THIS->lexer_->add_scope (p->scope_);
 685                 $$ = p;
 686         }
 687         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 688                 Music_output_def * o =  unsmob_music_output_def ($3);
 689                 $$ =o;
 690
 691                 THIS->lexer_->add_scope (o->scope_);
 692         }
 693         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 694                 Music_output_def * o =  unsmob_music_output_def ($3);
 695                 $$ = o;
 696
 697                 THIS->lexer_->add_scope (o->scope_);
 698         }
 699         | music_output_def_body assignment  {
 700
 701         }
 702         | music_output_def_body translator_spec_block   {
 703                 $$->assign_translator ($2);
 704         }
 705         | music_output_def_body tempo_event  {
 706                 /*
 707                         junk this ? there already is tempo stuff in
 708                         music.
 709                 */
 710                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 711                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 712                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 713                 if (md)
 714                         md->set_tempo (d->get_length (), m);
 715         }
 716         | music_output_def_body error {
 717
 718         }
 719         ;
 720
 721 tempo_event:
 722         TEMPO steno_duration '=' bare_unsigned  {
 723                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 724                 $$->set_mus_property ("tempo-unit", $2);
 725                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 726         }
 727         ;
 728
 729 /*
 730 The representation of a  list is the
 731
 732   (LIST . LAST-CONS)
 733
 734  to have  efficient append.
 735 */
 736 Music_list:
 737         /* empty */ {
 738                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 739         }
 740         | Music_list Music {
 741                 SCM s = $$;
 742                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 743                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 744                 if (gh_pair_p (ly_cdr (s)))
 745                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 746                 else
 747                         gh_set_car_x (s, c); /* set first cons */
 748                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 749         }
 750         | Music_list error {
 751         }
 752         ;
 753
 754
 755 Music:
 756         Simple_music
 757         | Composite_music
 758         ;
 759
 760 Alternative_music:
 761         /* empty */ {
 762                 $$ = SCM_EOL;
 763         }
 764         | ALTERNATIVE '{' Music_list '}' {
 765                 $$ = $3;
 766         }
 767         ;
 768
 769 Repeated_music:
 770         REPEAT string bare_unsigned Music Alternative_music
 771         {
 772                 Music *beg = $4;
 773                 int times = $3;
 774                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 775                 if (times < scm_ilength (alts)) {
 776                   unsmob_music (gh_car (alts))
 777                     ->origin ()->warning (
 778                     _("More alternatives than repeats.  Junking excess alternatives."));
 779                   alts = ly_truncate_list (times, alts);
 780                 }
 781
 782
 783                 static SCM proc;
 784                 if (!proc)
 785                         proc = scm_c_eval_string ("make-repeated-music");
 786
 787                 SCM mus = scm_call_1 (proc, $2);
 788                 scm_gc_protect_object (mus); // UGH.
 789                 Music *r =unsmob_music (mus);
 790                 if (beg)
 791                         {
 792                         r-> set_mus_property ("element", beg->self_scm ());
 793                         scm_gc_unprotect_object (beg->self_scm ());
 794                         }
 795                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 796
 797                 r-> set_mus_property ("elements",alts);
 798                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 799                         /*
 800                         we can not get durations and other stuff correct down the line, so we have to
 801                         add to the duration log here.
 802                         */
 803                         static SCM func;
 804
 805                         if (!func)
 806                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 807
 808                         int dots = ($3 % 3) ? 0 : 1;
 809                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 810
 811                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 812
 813                         if (seq) {
 814                                 int list_len =scm_ilength (seq->music_list ());
 815                                 if (list_len != 2)
 816                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 817                                 shift -= 1;
 818                                 r->compress (Moment (Rational (1,list_len)));
 819                                 }
 820                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 821
 822                 }
 823                 r->set_spot (*$4->origin ());
 824
 825                 $$ = r;
 826         }
 827         ;
 828
 829 Sequential_music:
 830         SEQUENTIAL '{' Music_list '}'           {
 831                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 832                 $$->set_mus_property ("elements", ly_car ($3));
 833                 $$->set_spot(THIS->here_input());
 834         }
 835         | '{' Music_list '}'            {
 836                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 837                 $$->set_mus_property ("elements", ly_car ($2));
 838                 $$->set_spot(THIS->here_input());
 839         }
 840         ;
 841
 842 Simultaneous_music:
 843         SIMULTANEOUS '{' Music_list '}'{
 844                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 845                 $$->set_mus_property ("elements", ly_car ($3));
 846                 $$->set_spot(THIS->here_input());
 847
 848         }
 849         | '<' Music_list '>'    {
 850                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 851                 $$->set_mus_property ("elements", ly_car ($2));
 852                 $$->set_spot(THIS->here_input());
 853         }
 854         ;
 855
 856 Simple_music:
 857         event_chord             { $$ = $1; }
 858         | APPLYOUTPUT embedded_scm {
 859                 if (!ly_input_procedure_p ($2))
 860                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 861                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 862                 $$->set_mus_property ("procedure", $2);
 863                 $$->set_spot (THIS->here_input());
 864         }
 865         | APPLYCONTEXT embedded_scm {
 866                 if (!ly_input_procedure_p ($2))
 867                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 868                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 869                 $$->set_mus_property ("procedure", $2);
 870                 $$->set_spot (THIS->here_input());
 871         }
 872         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 873                 SCM pred = $2;
 874                 if (!gh_symbol_p ($3))
 875                 {
 876                         THIS->parser_error (_ ("Second argument must be a symbol"));
 877                 }
 878                 /* Should check # args */
 879                 if (!gh_procedure_p (pred))
 880                 {
 881                         THIS->parser_error (_ ("First argument must be a procedure taking one argument"));
 882                 }
 883
 884                 Music*m = MY_MAKE_MUSIC("OutputPropertySetMusic");
 885                 m->set_mus_property ("predicate", pred);
 886                 m->set_mus_property ("grob-property", $3);
 887                 m->set_mus_property ("grob-value",  $5);
 888
 889                 $$ = m;
 890         }
 891         | MUSIC_IDENTIFIER {
 892                 $$ = unsmob_music ($1);
 893         }
 894         | property_def
 895         | translator_change
 896         ;
 897
 898
 899 grace_head:
 900         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 901         | ACCACCIATURA { $$ = scm_makfrom0str ("Accacciatura"); }
 902         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 903         ;
 904
 905
 906 Composite_music:
 907         CONTEXT STRING Music    {
 908                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 909
 910                 csm->set_mus_property ("element", $3->self_scm ());
 911                 scm_gc_unprotect_object ($3->self_scm ());
 912
 913                 csm->set_mus_property ("context-type",$2);
 914                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 915
 916                 $$ = csm;
 917         }
 918         | AUTOCHANGE STRING Music       {
 919         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 920                 chm->set_mus_property ("element", $3->self_scm ());
 921                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 922
 923                 scm_gc_unprotect_object ($3->self_scm ());
 924                 chm->set_mus_property ("what", $2);
 925
 926                 $$ = chm;
 927                 chm->set_spot (*$3->origin ());
 928         }
 929         | grace_head Music {
 930 #if 1
 931         /*
 932                 The other version is for easier debugging  of
 933                 Sequential_music_iterator in combination with grace notes.
 934         */
 935
 936 /*
 937
 938 TODO: should distinguish between both grace types in the
 939 basic music objects too, since the meaning is different.
 940
 941 */
 942
 943                 String start_str = "start" + ly_scm2string ($1) + "Music";
 944                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 945
 946                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 947                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 948
 949                 Music *startm = unsmob_music (start);
 950                 Music *stopm = unsmob_music (stop);
 951
 952                 SCM ms = SCM_EOL;
 953                 if (stopm) {
 954                         stopm = stopm->clone ();
 955                         ms = scm_cons (stopm->self_scm (), ms);
 956                         scm_gc_unprotect_object (stopm->self_scm ());
 957                 }
 958                 ms = scm_cons ($2->self_scm (), ms);
 959                 scm_gc_unprotect_object ($2->self_scm());
 960                 if (startm) {
 961                         startm = startm->clone ();
 962                         ms = scm_cons (startm->self_scm () , ms);
 963                         scm_gc_unprotect_object (startm->self_scm ());
 964                 }
 965
 966
 967                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 968                 seq->set_mus_property ("elements", ms);
 969
 970
 971                 $$ = MY_MAKE_MUSIC("GraceMusic");
 972                 $$->set_mus_property ("element", seq->self_scm ());
 973                 scm_gc_unprotect_object (seq->self_scm ());
 974 #else
 975                 $$ = MY_MAKE_MUSIC("GraceMusic");
 976                 $$->set_mus_property ("element", $2->self_scm ());
 977                 scm_gc_unprotect_object ($2->self_scm ());
 978 #endif
 979         }
 980         | CONTEXT string '=' string Music {
 981                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 982
 983                 csm->set_mus_property ("element", $5->self_scm ());
 984                 scm_gc_unprotect_object ($5->self_scm ());
 985
 986                 csm->set_mus_property ("context-type", $2);
 987                 csm->set_mus_property ("context-id", $4);
 988
 989                 $$ = csm;
 990         }
 991         | NEWCONTEXT string Music {
 992                 static int new_context_count;
 993
 994                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 995
 996                 csm->set_mus_property ("element", $3->self_scm ());
 997                 scm_gc_unprotect_object ($3->self_scm ());
 998
 999                 csm->set_mus_property ("context-type", $2);
1000
1001                 SCM new_id = scm_number_to_string (gh_int2scm (new_context_count ++),
1002                                         gh_int2scm (10));
1003                 csm->set_mus_property ("context-id", new_id);
1004                 $$ = csm;
1005         }
1006         | TIMES {
1007                 THIS->push_spot ();
1008         }
1009         /* CONTINUED */
1010                 fraction Music
1011
1012         {
1013                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
1014                 Music *mp = $4;
1015         $$= MY_MAKE_MUSIC("TimeScaledMusic");
1016                 $$->set_spot (THIS->pop_spot ());
1017
1018
1019                 $$->set_mus_property ("element", mp->self_scm ());
1020                 scm_gc_unprotect_object (mp->self_scm ());
1021                 $$->set_mus_property ("numerator", gh_int2scm (n));
1022                 $$->set_mus_property ("denominator", gh_int2scm (d));
1023                 $$->compress (Moment (Rational (n,d)));
1024
1025         }
1026         | Repeated_music                { $$ = $1; }
1027         | Simultaneous_music            { $$ = $1; }
1028         | Sequential_music              { $$ = $1; }
1029         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1030                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1031                 Music *p = $4;
1032                 Pitch from = *unsmob_pitch ($2);
1033                 Pitch to = *unsmob_pitch ($3);
1034
1035                 p->transpose (interval (from, to));
1036                 $$->set_mus_property ("element", p->self_scm ());
1037                 scm_gc_unprotect_object (p->self_scm ());
1038         }
1039         | APPLY embedded_scm Music  {
1040                 if (!ly_input_procedure_p ($2))
1041                         THIS->parser_error (_ ("\\apply takes function argument"));
1042
1043                 SCM ret = gh_call1 ($2, $3->self_scm ());
1044                 Music *m = unsmob_music (ret);
1045                 if (!m) {
1046                         THIS->parser_error ("\\apply must return a Music");
1047                         m = MY_MAKE_MUSIC("Music");
1048                         }
1049                 $$ = m;
1050         }
1051         | NOTES
1052                 { THIS->lexer_->push_note_state (); }
1053         Music
1054                 { $$ = $3;
1055                   THIS->lexer_->pop_state ();
1056                 }
1057         | FIGURES
1058                 { THIS->lexer_->push_figuredbass_state (); }
1059         Music
1060                 {
1061                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1062                   chm->set_mus_property ("element", $3->self_scm ());
1063                   $$ = chm;
1064                   scm_gc_unprotect_object ($3->self_scm());
1065
1066                   THIS->lexer_->pop_state ();
1067         }
1068         | CHORDS
1069                 { THIS->lexer_->push_chord_state (); }
1070         Music
1071                 {
1072                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1073                   chm->set_mus_property ("element", $3->self_scm ());
1074                   scm_gc_unprotect_object ($3->self_scm());
1075                   $$ = chm;
1076
1077                   THIS->lexer_->pop_state ();
1078         }
1079         | LYRICS
1080                 { THIS->lexer_->push_lyric_state (); }
1081         Music
1082                 {
1083                   $$ = $3;
1084                   THIS->lexer_->pop_state ();
1085         }
1086         | relative_music        { $$ = $1; }
1087         | re_rhythmed_music     { $$ = $1; }
1088         | part_combined_music   { $$ = $1; }
1089         ;
1090
1091 relative_music:
1092         RELATIVE absolute_pitch Music {
1093                 Music * p = $3;
1094                 Pitch pit = *unsmob_pitch ($2);
1095                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1096
1097                 $$->set_mus_property ("element", p->self_scm ());
1098                 scm_gc_unprotect_object (p->self_scm ());
1099
1100
1101                 Pitch retpitch = p->to_relative_octave (pit);
1102                 if (lily_1_8_relative)
1103                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1104         }
1105         ;
1106
1107 re_rhythmed_music:
1108         ADDLYRICS Music Music {
1109         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1110           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1111           scm_gc_unprotect_object ($3->self_scm ());
1112           scm_gc_unprotect_object ($2->self_scm ());
1113           $$ = l;
1114         }
1115         ;
1116
1117 part_combined_music:
1118         PARTCOMBINE STRING Music Music {
1119         Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1120                 p->set_mus_property ("what", $2);
1121                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1122
1123                 scm_gc_unprotect_object ($3->self_scm ());
1124                 scm_gc_unprotect_object ($4->self_scm ());
1125
1126                 $$ = p;
1127         }
1128         ;
1129
1130 translator_change:
1131         TRANSLATOR STRING '=' STRING  {
1132                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1133                 t-> set_mus_property ("change-to-type", $2);
1134                 t-> set_mus_property ("change-to-id", $4);
1135
1136                 $$ = t;
1137                 $$->set_spot (THIS->here_input ());
1138         }
1139         ;
1140
1141 property_def:
1142         simple_property_def
1143         | ONCE simple_property_def {
1144                 $$ = $2;
1145                 SCM e = $2->get_mus_property ("element");
1146                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1147         }
1148         ;
1149
1150 simple_property_def:
1151         PROPERTY STRING '.' STRING '='  scalar {
1152                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1153                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1154
1155                 csm->set_mus_property ("element", t->self_scm ());
1156                 scm_gc_unprotect_object (t->self_scm ());
1157
1158                 $$ = csm;
1159                 $$->set_spot (THIS->here_input ());
1160
1161                 csm-> set_mus_property ("context-type", $2);
1162         }
1163         | PROPERTY STRING '.' STRING UNSET {
1164
1165                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1166                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1167
1168                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1169                 csm->set_mus_property ("element", t->self_scm ());
1170                 scm_gc_unprotect_object (t->self_scm ());
1171
1172                 $$ = csm;
1173                 $$->set_spot (THIS->here_input ());
1174
1175                 csm-> set_mus_property ("context-type", $2);
1176         }
1177         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1178                 bool autobeam
1179                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1180                 bool itc = internal_type_checking_global_b;
1181                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1182                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1183                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1184                 if (autobeam)
1185                         internal_type_checking_global_b = false;
1186                 t->set_mus_property ("grob-property", $6);
1187                 if (autobeam)
1188                         internal_type_checking_global_b = itc;
1189                 t->set_mus_property ("grob-value", $8);
1190
1191                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1192                 csm->set_mus_property ("element", t->self_scm ());
1193                 scm_gc_unprotect_object (t->self_scm ());
1194                 $$ = csm;
1195                 $$->set_spot (THIS->here_input ());
1196
1197                 csm-> set_mus_property ("context-type", $2);
1198         }
1199         | PROPERTY STRING '.' STRING OVERRIDE
1200                 embedded_scm '=' embedded_scm
1201         {
1202                 /*
1203                         UGH UGH UGH UGH.
1204                 */
1205                 bool autobeam
1206                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1207                 bool itc = internal_type_checking_global_b;
1208
1209                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1210                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1211                 if (autobeam)
1212                         internal_type_checking_global_b = false;
1213                 t->set_mus_property ("grob-property", $6);
1214                 t->set_mus_property ("grob-value", $8);
1215                 if (autobeam)
1216                         internal_type_checking_global_b = itc;
1217
1218                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1219                 csm->set_mus_property ("element", t->self_scm ());
1220                 scm_gc_unprotect_object (t->self_scm ());
1221
1222                 $$ = csm;
1223                 $$->set_spot (THIS->here_input ());
1224
1225                 csm-> set_mus_property ("context-type", $2);
1226
1227         }
1228         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1229                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1230                 bool autobeam
1231                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1232                 bool itc = internal_type_checking_global_b;
1233
1234                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1235                 if (autobeam)
1236                         internal_type_checking_global_b = false;
1237                 t->set_mus_property ("grob-property", $6);
1238                 if (autobeam)
1239                         internal_type_checking_global_b = itc;
1240
1241                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1242                 csm->set_mus_property ("element", t->self_scm ());
1243                 scm_gc_unprotect_object (t->self_scm ());
1244
1245                 $$ = csm;
1246                 $$->set_spot (THIS->here_input ());
1247
1248                 csm-> set_mus_property ("context-type", $2);
1249         }
1250         ;
1251
1252
1253 scalar:
1254         string          { $$ = $1; }
1255         | bare_int      { $$ = gh_int2scm ($1); }
1256         | embedded_scm  { $$ = $1; }
1257         | full_markup {  $$ = $1; }
1258         | DIGIT { $$ = gh_int2scm ($1); }
1259         ;
1260
1261
1262
1263 /*
1264 This is a trick:
1265
1266 Adding pre_events to the simple_element
1267 makes the choice between
1268
1269   string:  STRING
1270
1271 and
1272
1273   simple_element: STRING
1274
1275 a single shift/reduction conflict.
1276
1277 nevertheless, this is not very clean, and we should find a different
1278 solution.
1279
1280 */
1281 pre_events: {
1282                 THIS->push_spot ();
1283         }
1284         ;
1285
1286 event_chord:
1287         pre_events simple_element post_events   {
1288                 SCM elts = $2-> get_mus_property ("elements");
1289
1290                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1291
1292                 $2->set_mus_property ("elements", elts);
1293                 $$ = $2;
1294         }
1295         | command_element
1296         | note_chord_element
1297         ;
1298
1299
1300 note_chord_element:
1301         chord_body optional_notemode_duration post_events
1302         {
1303                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1304                 SCM es = $1->get_mus_property ("elements");
1305                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1306
1307                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1308                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1309                 es = gh_append2 (es, postevs);
1310
1311                 $1-> set_mus_property ("elements", es);
1312                 $$ = $1;
1313         }
1314         ;
1315
1316 chord_body:
1317         CHORD_OPEN chord_body_elements CHORD_CLOSE
1318         {
1319                 $$ = MY_MAKE_MUSIC("EventChord");
1320                 $$->set_mus_property ("elements",
1321                         scm_reverse_x ($2, SCM_EOL));
1322         }
1323         ;
1324
1325 chord_body_elements:
1326         /* empty */             { $$ = SCM_EOL; }
1327         | chord_body_elements chord_body_element {
1328                 $$ = gh_cons ($2->self_scm(), $1);
1329                 scm_gc_unprotect_object ($2->self_scm());
1330         }
1331         ;
1332
1333 chord_body_element:
1334         pitch exclamations questions post_events
1335         {
1336                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1337                 n->set_mus_property ("pitch", $1);
1338                 if ($3 % 2)
1339                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1340                 if ($2 % 2 || $3 % 2)
1341                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1342
1343                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1344                 n->set_mus_property ("articulations", arts);
1345
1346                 $$ = n;
1347         }
1348         ;
1349
1350 command_element:
1351         command_req {
1352                 $$ = MY_MAKE_MUSIC("EventChord");
1353                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1354                 scm_gc_unprotect_object ($1->self_scm());
1355
1356                 $$-> set_spot (THIS->here_input ());
1357                 $1-> set_spot (THIS->here_input ());
1358         }
1359         | OCTAVE { THIS->push_spot (); }
1360           pitch {
1361                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1362                 $$ = l;
1363                 $$->set_spot (THIS->pop_spot ());
1364                 $$->set_mus_property ("pitch", $3);
1365         }
1366         | E_LEFTSQUARE {
1367                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1368                 l->set_mus_property ("span-direction", gh_int2scm (START));
1369                 l->set_spot (THIS->here_input ());
1370
1371                 $$ = MY_MAKE_MUSIC("EventChord");
1372                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1373                 scm_gc_unprotect_object (l->self_scm());
1374                 $$->set_spot (THIS->here_input ());
1375         }
1376         | E_RIGHTSQUARE {
1377                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1378                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1379                 l->set_spot (THIS->here_input ());
1380
1381                 $$ = MY_MAKE_MUSIC("EventChord");
1382                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1383                 $$->set_spot (THIS->here_input ());
1384                 scm_gc_unprotect_object (l->self_scm());
1385         }
1386         | E_BACKSLASH {
1387                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1388                 $$->set_spot (THIS->here_input ());
1389         }
1390         | '|'      {
1391
1392                 $$ = MY_MAKE_MUSIC("BarCheck");
1393                 $$->set_spot (THIS->here_input ());
1394         }
1395         | BAR STRING                    {
1396                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1397
1398                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1399                 csm->set_mus_property ("element", t->self_scm ());
1400                 scm_gc_unprotect_object (t->self_scm ());
1401
1402                 $$ = csm;
1403                 $$->set_spot (THIS->here_input ());
1404
1405                 csm->set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1406         }
1407         | PARTIAL duration_length       {
1408                 Moment m = - unsmob_duration ($2)->get_length ();
1409                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1410
1411                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1412                 sp->set_mus_property ("element", p->self_scm ());
1413                 scm_gc_unprotect_object (p->self_scm ());
1414
1415                 $$ =sp ;
1416                 sp-> set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1417         }
1418         | CLEF STRING  {
1419                 static SCM proc ;
1420                 if (!proc)
1421                         proc = scm_c_eval_string ("make-clef-set");
1422
1423                 SCM result = scm_call_1 (proc, $2);
1424                 scm_gc_protect_object (result);
1425                 $$ = unsmob_music (result);
1426         }
1427         | TIME_T fraction  {
1428                 static SCM proc;
1429                 if (!proc)
1430                         proc = scm_c_eval_string ("make-time-signature-set");
1431
1432                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1433                 scm_gc_protect_object (result);
1434                 $$ = unsmob_music (result);
1435         }
1436         ;
1437
1438 command_req:
1439         shorthand_command_req   { $$ = $1; }
1440         | verbose_command_req   { $$ = $1; }
1441         ;
1442
1443 shorthand_command_req:
1444         extender_req {
1445                 $$ = $1;
1446         }
1447         | hyphen_req {
1448                 $$ = $1;
1449         }
1450         | BREATHE {
1451                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1452         }
1453         | E_TILDE {
1454                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1455         }
1456         ;
1457
1458 verbose_command_req:
1459         MARK DEFAULT  {
1460                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1461                 $$ = m;
1462         }
1463         | MARK scalar {
1464                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1465                 m->set_mus_property ("label", $2);
1466                 $$ = m;
1467         }
1468         | SKIP duration_length {
1469                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1470                 skip->set_mus_property ("duration", $2);
1471
1472                 $$ = skip;
1473         }
1474         | tempo_event {
1475                 $$ = $1;
1476         }
1477         | KEY DEFAULT {
1478                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1479                 $$ = key;
1480         }
1481         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1482
1483                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1484                 if (scm_ilength ($3) > 0)
1485                 {
1486                         key->set_mus_property ("pitch-alist", $3);
1487                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1488                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1489                 } else {
1490                         THIS->parser_error (_("Second argument must be pitch list."));
1491                 }
1492
1493                 $$ = key;
1494         }
1495         ;
1496
1497 post_events:
1498         /* empty */ {
1499                 $$ = SCM_EOL;
1500         }
1501         | post_events post_event {
1502                 $2->set_spot (THIS->here_input ());
1503                 $$ = gh_cons ($2->self_scm(), $$);
1504                 scm_gc_unprotect_object ($2->self_scm());
1505         }
1506         ;
1507
1508
1509
1510 post_event:
1511         direction_less_event {
1512                 $$ = $1;
1513         }
1514         | script_dir direction_reqd_event {
1515                 $2->set_mus_property ("direction", gh_int2scm ($1));
1516                 $$ = $2;
1517         }
1518         | script_dir direction_less_event {
1519                 $2->set_mus_property ("direction", gh_int2scm ($1));
1520                 $$ = $2;
1521         }
1522         | string_number_event
1523         ;
1524
1525 string_number_event:
1526         E_UNSIGNED {
1527                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1528                 s->set_mus_property ("string-number",  gh_int2scm($1));
1529                 s->set_spot (THIS->here_input ());
1530                 $$ = s;
1531         }
1532         ;
1533
1534
1535 direction_less_event:
1536         '['  {
1537
1538
1539 /*
1540
1541 TODO: should take all these defs out of the parser, adn make use
1542 configurable, i.e.
1543
1544
1545 (set-articulation '~ "trill")
1546
1547 */
1548                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1549                 m->set_spot (THIS->here_input());
1550                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1551                 $$ = m;
1552         }
1553         | ']'  {
1554                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1555                 m->set_spot (THIS->here_input());
1556                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1557                 $$ = m;
1558         }
1559         | '~' {
1560                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1561                 m->set_spot (THIS->here_input());
1562                 $$ = m;
1563         }
1564         | close_event {
1565                 $$ = $1;
1566                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START));
1567         }
1568         | open_event {
1569                 $$ = $1;
1570                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP))
1571         }
1572         | EVENT_IDENTIFIER      {
1573                 $$ = unsmob_music ($1);
1574         }
1575         | tremolo_type  {
1576                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1577                a->set_spot (THIS->here_input ());
1578                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1579                $$ = a;
1580         }
1581         ;
1582
1583 direction_reqd_event:
1584         gen_text_def {
1585                 $$ = $1;
1586         }
1587         | script_abbreviation {
1588                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1589                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1590                 if (gh_string_p (s))
1591                         a->set_mus_property ("articulation-type", s);
1592                 else THIS->parser_error (_ ("Expecting string as script definition"));
1593                 $$ = a;
1594         }
1595         ;
1596
1597 sup_quotes:
1598         '\'' {
1599                 $$ = 1;
1600         }
1601         | sup_quotes '\'' {
1602                 $$ ++;
1603         }
1604         ;
1605
1606 sub_quotes:
1607         ',' {
1608                 $$ = 1;
1609         }
1610         | sub_quotes ',' {
1611                 $$ ++ ;
1612         }
1613         ;
1614
1615 steno_pitch:
1616         NOTENAME_PITCH  {
1617                 $$ = $1;
1618         }
1619         | NOTENAME_PITCH sup_quotes     {
1620                 Pitch p = *unsmob_pitch ($1);
1621                 p = p.transposed (Pitch ($2,0,0));
1622                 $$ = p.smobbed_copy ();
1623         }
1624         | NOTENAME_PITCH sub_quotes      {
1625                 Pitch p =* unsmob_pitch ($1);
1626                 p = p.transposed (Pitch (-$2,0,0));
1627                 $$ = p.smobbed_copy ();
1628         }
1629         ;
1630
1631 /*
1632 ugh. duplication
1633 */
1634
1635 steno_tonic_pitch:
1636         TONICNAME_PITCH {
1637                 $$ = $1;
1638         }
1639         | TONICNAME_PITCH sup_quotes    {
1640                 Pitch p = *unsmob_pitch ($1);
1641                 p = p.transposed (Pitch ($2,0,0));
1642                 $$ = p.smobbed_copy ();
1643         }
1644         | TONICNAME_PITCH sub_quotes     {
1645                 Pitch p =* unsmob_pitch ($1);
1646
1647                 p = p.transposed (Pitch (-$2,0,0));
1648                 $$ = p.smobbed_copy ();
1649         }
1650         ;
1651
1652 pitch:
1653         steno_pitch {
1654                 $$ = $1;
1655         }
1656         | explicit_pitch {
1657                 $$ = $1;
1658         }
1659         ;
1660
1661 pitch_also_in_chords:
1662         pitch
1663         | steno_tonic_pitch
1664         ;
1665
1666 explicit_pitch:
1667         PITCH embedded_scm {
1668                 $$ = $2;
1669                 if (!unsmob_pitch ($2)) {
1670                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1671                          $$ = Pitch ().smobbed_copy ();
1672                 }
1673         }
1674         ;
1675
1676 verbose_duration:
1677         DURATION embedded_scm   {
1678                 $$ = $2;
1679                 if (!unsmob_duration ($2))
1680                 {
1681                         THIS->parser_error (_ ("Must have duration object"));
1682                         $$ = Duration ().smobbed_copy ();
1683                 }
1684         }
1685         ;
1686
1687 extender_req:
1688         EXTENDER {
1689                 if (!THIS->lexer_->lyric_state_b ())
1690                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1691                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1692         }
1693         ;
1694
1695 hyphen_req:
1696         HYPHEN {
1697                 if (!THIS->lexer_->lyric_state_b ())
1698                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1699                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1700         }
1701         ;
1702
1703 close_event:
1704         '('     {
1705                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1706                 $$ = s;
1707                 s->set_spot (THIS->here_input());
1708         }
1709         | E_OPEN        {
1710                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1711                 $$ = s;
1712                 s->set_spot (THIS->here_input());
1713         }
1714         | E_SMALLER {
1715                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1716                 $$ = s;
1717                 s->set_spot (THIS->here_input());
1718         }
1719         | E_BIGGER {
1720                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1721                 $$ = s;
1722                 s->set_spot (THIS->here_input());
1723         }
1724         ;
1725
1726
1727 open_event:
1728         E_EXCLAMATION   {
1729                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1730                 s->set_spot (THIS->here_input());
1731
1732                 $$ = s;
1733         }
1734         | ')'   {
1735                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1736                 $$ = s;
1737                 s->set_spot (THIS->here_input());
1738
1739         }
1740         | E_CLOSE       {
1741                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1742                 $$ = s;
1743                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1744                 s->set_spot (THIS->here_input());
1745         }
1746         ;
1747
1748 gen_text_def:
1749         full_markup {
1750                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1751                 t->set_mus_property ("text", $1);
1752                 t->set_spot (THIS->here_input ());
1753                 $$ = t;
1754         }
1755         | string {
1756                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1757                 t->set_mus_property ("text", make_simple_markup ($1));
1758                 t->set_spot (THIS->here_input ());
1759                 $$ = t;
1760
1761         }
1762         | DIGIT {
1763                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1764                 t->set_mus_property ("digit",  gh_int2scm ($1));
1765                 t->set_spot (THIS->here_input ());
1766                 $$ = t;
1767         }
1768         ;
1769
1770 script_abbreviation:
1771         '^'             {
1772                 $$ = scm_makfrom0str ("Hat");
1773         }
1774         | '+'           {
1775                 $$ = scm_makfrom0str ("Plus");
1776         }
1777         | '-'           {
1778                 $$ = scm_makfrom0str ("Dash");
1779         }
1780         | '|'           {
1781                 $$ = scm_makfrom0str ("Bar");
1782         }
1783         | '>'           {
1784                 $$ = scm_makfrom0str ("Larger");
1785         }
1786         | '.'           {
1787                 $$ = scm_makfrom0str ("Dot");
1788         }
1789         | '_' {
1790                 $$ = scm_makfrom0str ("Underscore");
1791         }
1792         ;
1793
1794 script_dir:
1795         '_'     { $$ = DOWN; }
1796         | '^'   { $$ = UP; }
1797         | '-'   { $$ = CENTER; }
1798         ;
1799
1800
1801 absolute_pitch:
1802         steno_pitch     {
1803                 $$ = $1;
1804         }
1805         ;
1806
1807 duration_length:
1808         multiplied_duration {
1809                 $$ = $1;
1810         }
1811         | verbose_duration {
1812                 $$ = $1;
1813         }
1814         ;
1815
1816 optional_notemode_duration:
1817         {
1818                 Duration dd = THIS->default_duration_;
1819                 $$ = dd.smobbed_copy ();
1820
1821                 THIS->beam_check ($$);
1822         }
1823         | multiplied_duration   {
1824                 $$ = $1;
1825                 THIS->default_duration_ = *unsmob_duration ($$);
1826
1827                 THIS->beam_check ($$);
1828         }
1829         | verbose_duration {
1830                 $$ = $1;
1831                 THIS->default_duration_ = *unsmob_duration ($$);
1832         }
1833         ;
1834
1835 steno_duration:
1836         bare_unsigned dots              {
1837                 int l = 0;
1838                 if (!is_duration_b ($1))
1839                         THIS->parser_error (_f ("not a duration: %d", $1));
1840                 else
1841                         l =  intlog2 ($1);
1842
1843                 $$ = Duration (l, $2).smobbed_copy ();
1844         }
1845         | DURATION_IDENTIFIER dots      {
1846                 Duration *d =unsmob_duration ($1);
1847                 Duration k (d->duration_log (),d->dot_count () + $2);
1848
1849                 *d = k;
1850                 $$ = $1;
1851         }
1852         ;
1853
1854
1855
1856
1857 multiplied_duration:
1858         steno_duration {
1859                 $$ = $1;
1860         }
1861         | multiplied_duration '*' bare_unsigned {
1862                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1863         }
1864         | multiplied_duration '*' FRACTION {
1865                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1866
1867                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1868         }
1869         ;
1870
1871 fraction:
1872         FRACTION { $$ = $1; }
1873         | UNSIGNED '/' UNSIGNED {
1874                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1875         }
1876         ;
1877
1878 dots:
1879         /* empty */     {
1880                 $$ = 0;
1881         }
1882         | dots '.' {
1883                 $$ ++;
1884         }
1885         ;
1886
1887
1888 tremolo_type:
1889         ':'     {
1890                 $$ =0;
1891         }
1892         | ':' bare_unsigned {
1893                 if (!is_duration_b ($2))
1894                         THIS->parser_error (_f ("not a duration: %d", $2));
1895                 $$ = $2;
1896         }
1897         ;
1898
1899
1900
1901 /*****************************************************************
1902                 BASS FIGURES
1903 *****************************************************************/
1904 bass_number:
1905         DIGIT   {
1906                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1907         }
1908         | UNSIGNED {
1909                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1910         }
1911         | STRING { $$ =  $1 }
1912         ;
1913
1914 bass_mod:
1915         '-'     { $$ = -1; }
1916         | '+'   { $$ = 1; }
1917         | '!'   { $$ = 0; }
1918         ;
1919
1920 bass_figure:
1921         FIGURE_SPACE {
1922                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1923                 $$ = bfr->self_scm();
1924                 scm_gc_unprotect_object ($$);
1925         }
1926         | bass_number  {
1927                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1928                 $$ = bfr->self_scm();
1929
1930                 bfr->set_mus_property ("figure", $1);
1931
1932                 scm_gc_unprotect_object ($$);
1933         }
1934         | bass_figure bass_mod {
1935                 Music *m = unsmob_music ($1);
1936                 if ($2) {
1937                         SCM salter =m->get_mus_property ("alteration");
1938                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1939                         m->set_mus_property ("alteration",
1940                                 gh_int2scm (alter + $2));
1941                 } else {
1942                         m->set_mus_property ("alteration", gh_int2scm (0));
1943                 }
1944         }
1945         ;
1946
1947 br_bass_figure:
1948         '[' bass_figure {
1949                 $$ = $2;
1950                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1951         }
1952         | bass_figure   {
1953                 $$ = $1;
1954         }
1955         | br_bass_figure ']' {
1956                 $$ = $1;
1957                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1958         }
1959         ;
1960
1961 figure_list:
1962         /**/            {
1963                 $$ = SCM_EOL;
1964         }
1965         | figure_list br_bass_figure {
1966                 $$ = scm_cons ($2, $1);
1967         }
1968         ;
1969
1970 figure_spec:
1971         FIGURE_OPEN figure_list FIGURE_CLOSE {
1972                 Music * m = MY_MAKE_MUSIC("EventChord");
1973                 $2 = scm_reverse_x ($2, SCM_EOL);
1974                 m->set_mus_property ("elements",  $2);
1975                 $$ = m->self_scm ();
1976         }
1977         ;
1978
1979
1980 optional_rest:
1981         /**/   { $$ = 0; }
1982         | REST { $$ = 1; }
1983         ;
1984
1985 simple_element:
1986         pitch exclamations questions optional_notemode_duration optional_rest {
1987
1988                 Input i = THIS->pop_spot ();
1989                 if (!THIS->lexer_->note_state_b ())
1990                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1991
1992                 Music *n = 0;
1993                 if ($5)
1994                         n =  MY_MAKE_MUSIC("RestEvent");
1995                 else
1996                         n =  MY_MAKE_MUSIC("NoteEvent");
1997
1998                 n->set_mus_property ("pitch", $1);
1999                 n->set_mus_property ("duration", $4);
2000
2001
2002                 if ($3 % 2)
2003                         n->set_mus_property ("cautionary", SCM_BOOL_T);
2004                 if ($2 % 2 || $3 % 2)
2005                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
2006
2007                 Music *v = MY_MAKE_MUSIC("EventChord");
2008                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
2009                 scm_gc_unprotect_object (n->self_scm());
2010
2011                 v->set_spot (i);
2012                 n->set_spot (i);
2013                 $$ = v;
2014         }
2015         | figure_spec optional_notemode_duration {
2016                 Music * m = unsmob_music ($1);
2017                 Input i = THIS->pop_spot ();
2018                 m->set_spot (i);
2019                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2020                 {
2021                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2022                 }
2023                 $$ = m;
2024         }
2025         | RESTNAME optional_notemode_duration           {
2026
2027                 Input i = THIS->pop_spot ();
2028                 Music * ev = 0;
2029                 if (ly_scm2string ($1) =="s") {
2030                         /* Space */
2031                         ev = MY_MAKE_MUSIC("SkipEvent");
2032                   }
2033                 else {
2034                         ev = MY_MAKE_MUSIC("RestEvent");
2035
2036                     }
2037                 ev->set_mus_property ("duration" ,$2);
2038                 ev->set_spot (i);
2039                 Music * velt = MY_MAKE_MUSIC("EventChord");
2040                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2041                 velt->set_spot (i);
2042
2043                 $$ = velt;
2044         }
2045         | MULTI_MEASURE_REST optional_notemode_duration         {
2046                 THIS->pop_spot ();
2047
2048                 static SCM proc ;
2049                 if (!proc)
2050                         proc = scm_c_eval_string ("make-multi-measure-rest");
2051
2052                 SCM mus = scm_call_2 (proc, $2,
2053                         make_input (THIS->here_input()));
2054                 scm_gc_protect_object (mus);
2055                 $$ = unsmob_music (mus);
2056         }
2057         | STRING optional_notemode_duration     {
2058                 Input i = THIS->pop_spot ();
2059
2060                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2061                 lreq->set_mus_property ("text", $1);
2062                 lreq->set_mus_property ("duration",$2);
2063                 lreq->set_spot (i);
2064                 Music * velt = MY_MAKE_MUSIC("EventChord");
2065                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2066
2067                 $$= velt;
2068         }
2069         | new_chord {
2070                 THIS->pop_spot ();
2071
2072                 if (!THIS->lexer_->chord_state_b ())
2073                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2074                 $$ = unsmob_music ($1);
2075         }
2076         ;
2077
2078 new_chord:
2079         steno_tonic_pitch optional_notemode_duration   {
2080                 $$ = make_chord ($1, $2, SCM_EOL);
2081         }
2082         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2083                 SCM its = scm_reverse_x ($4, SCM_EOL);
2084                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2085         }
2086         ;
2087
2088 chord_items:
2089         /**/ {
2090                 $$ = SCM_EOL;
2091         }
2092         | chord_items chord_item {
2093                 $$ = gh_cons ($2, $$);
2094         }
2095         ;
2096
2097 chord_separator:
2098         CHORD_COLON {
2099                 $$ = ly_symbol2scm ("chord-colon");
2100         }
2101         | CHORD_CARET {
2102                 $$ = ly_symbol2scm ("chord-caret");
2103         }
2104         | CHORD_SLASH steno_tonic_pitch {
2105                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2106         }
2107         | CHORD_BASS steno_tonic_pitch {
2108                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2109         }
2110         ;
2111
2112 chord_item:
2113         chord_separator {
2114                 $$ = $1;
2115         }
2116         | step_numbers {
2117                 $$ = scm_reverse_x ($1, SCM_EOL);
2118         }
2119         | CHORD_MODIFIER  {
2120                 $$ = $1;
2121         }
2122         ;
2123
2124 step_numbers:
2125         step_number { $$ = gh_cons ($1, SCM_EOL); }
2126         | step_numbers '.' step_number {
2127                 $$ = gh_cons ($3, $$);
2128         }
2129         ;
2130
2131 step_number:
2132         bare_unsigned {
2133                 $$ = make_chord_step ($1, 0);
2134         }
2135         | bare_unsigned '+' {
2136                 $$ = make_chord_step ($1, 1);
2137         }
2138         | bare_unsigned CHORD_MINUS {
2139                 $$ = make_chord_step ($1,-1);
2140         }
2141         ;
2142
2143 /*
2144         UTILITIES
2145
2146 TODO: should deprecate in favor of Scheme?
2147
2148  */
2149 number_expression:
2150         number_expression '+' number_term {
2151                 $$ = scm_sum ($1, $3);
2152         }
2153         | number_expression '-' number_term {
2154                 $$ = scm_difference ($1, $3);
2155         }
2156         | number_term
2157         ;
2158
2159 number_term:
2160         number_factor {
2161                 $$ = $1;
2162         }
2163         | number_factor '*' number_factor {
2164                 $$ = scm_product ($1, $3);
2165         }
2166         | number_factor '/' number_factor {
2167                 $$ = scm_divide ($1, $3);
2168         }
2169         ;
2170
2171 number_factor:
2172         '-'  number_factor { /* %prec UNARY_MINUS */
2173                 $$ = scm_difference ($2, SCM_UNDEFINED);
2174         }
2175         | bare_number
2176         ;
2177
2178
2179 bare_number:
2180         UNSIGNED        {
2181                 $$ = gh_int2scm ($1);
2182         }
2183         | REAL          {
2184                 $$ = $1;
2185         }
2186         | NUMBER_IDENTIFIER             {
2187                 $$ = $1;
2188         }
2189         | REAL NUMBER_IDENTIFIER        {
2190                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2191         }
2192         | UNSIGNED NUMBER_IDENTIFIER    {
2193                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2194         }
2195         ;
2196
2197
2198 bare_unsigned:
2199         UNSIGNED {
2200                         $$ = $1;
2201         }
2202         | DIGIT {
2203                 $$ = $1;
2204         }
2205         ;
2206
2207 bare_int:
2208         bare_number {
2209                 if (scm_integer_p ($1) == SCM_BOOL_T)
2210                 {
2211                         int k = gh_scm2int ($1);
2212                         $$ = k;
2213                 } else
2214                 {
2215                         THIS->parser_error (_ ("need integer number arg"));
2216                         $$ = 0;
2217                 }
2218         }
2219         | '-' bare_int {
2220                 $$ = -$2;
2221         }
2222         ;
2223
2224
2225 string:
2226         STRING          {
2227                 $$ = $1;
2228         }
2229         | STRING_IDENTIFIER     {
2230                 $$ = $1;
2231         }
2232         | string '+' string {
2233                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2234         }
2235         ;
2236
2237
2238 exclamations:
2239                 { $$ = 0; }
2240         | exclamations '!'      { $$ ++; }
2241         ;
2242
2243 questions:
2244                 { $$ = 0; }
2245         | questions '?' { $$ ++; }
2246         ;
2247
2248
2249
2250 full_markup:
2251         MARKUP_IDENTIFIER {
2252                 $$ = $1;
2253         }
2254         | MARKUP
2255                 { THIS->lexer_->push_markup_state (); }
2256         markup
2257                 { $$ = $3;
2258                   THIS->lexer_->pop_state ();
2259                 }
2260         ;
2261
2262
2263 /*
2264 This should be done more dynamically if possible.
2265 */
2266 markup:
2267         STRING {
2268                 $$ = make_simple_markup ($1);
2269         }
2270         | MARKUP_HEAD_MARKUP0 markup {
2271                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2272         }
2273         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2274                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2275         }
2276         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2277                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2278         }
2279         | markup_line {
2280                 $$ = $1;
2281         }
2282         | MARKUP_HEAD_LIST0 markup_list {
2283                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2284         }
2285         | MARKUP_HEAD_SCM0 embedded_scm {
2286                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2287         }
2288         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2289                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2290         }
2291         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2292                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2293         }
2294         | MARKUP_IDENTIFIER {
2295                 $$ = $1;
2296         }
2297
2298         ;
2299
2300 markup_list:
2301         CHORD_OPEN markup_list_body CHORD_CLOSE { $$ = scm_reverse_x ($2, SCM_EOL); }
2302         ;
2303
2304 markup_line:
2305         '{' markup_list_body '}' {
2306                 static SCM line ;
2307                 if (!line)
2308                         line = scm_c_eval_string ("line-markup");
2309
2310                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2311         }
2312         ;
2313
2314 markup_list_body:
2315         /**/ {  $$ = SCM_EOL; }
2316         | markup_list_body markup {
2317                 $$ = gh_cons ($2, $1) ;
2318         }
2319         ;
2320
2321
2322 %%
2323
2324 void
2325 My_lily_parser::set_yydebug (bool )
2326 {
2327 #if 0
2328         yydebug = 1;
2329 #endif
2330 }
2331
2332 extern My_lily_parser * current_parser;
2333
2334 void
2335 My_lily_parser::do_yyparse ()
2336 {
2337         current_parser = this;;
2338         yyparse ((void*)this);
2339 }
2340
2341
2342 /*
2343 Should make this optional?    It will also complain when you do
2344
2345         [s4]
2346
2347 which is entirely legitimate.
2348
2349 Or we can scrap it. Barchecks should detect wrong durations, and
2350 skipTypesetting speeds it up a lot.
2351 */
2352
2353 void
2354 My_lily_parser::beam_check (SCM dur)
2355 {
2356   Duration *d = unsmob_duration (dur);
2357   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2358     {
2359       Music * m = unsmob_music (last_beam_start_);
2360       m->origin ()->warning (_("Suspect duration found following this beam"));
2361     }
2362   last_beam_start_ = SCM_EOL;
2363 }
2364
2365
2366
2367
2368 /*
2369
2370 It is a little strange to have this function in this file, but
2371 otherwise, we have to import music classes into the lexer.
2372
2373 */
2374 int
2375 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2376 {
2377         if (gh_string_p (sid)) {
2378                 *destination = sid;
2379                 return STRING_IDENTIFIER;
2380         } else if (gh_number_p (sid)) {
2381                 *destination = sid;
2382                 return NUMBER_IDENTIFIER;
2383         } else if (unsmob_translator_def (sid)) {
2384                 *destination = unsmob_translator_def (sid)->clone_scm();
2385                 return TRANSLATOR_IDENTIFIER;
2386         } else if (unsmob_score (sid)) {
2387                 Score *sc =  new Score (*unsmob_score (sid));
2388                 *destination =sc->self_scm ();
2389                 return SCORE_IDENTIFIER;
2390         } else if (Music * mus =unsmob_music (sid)) {
2391                 *destination = unsmob_music (sid)->clone ()->self_scm();
2392                 unsmob_music (*destination)->
2393                         set_mus_property ("origin", make_input (last_input_));
2394                 return dynamic_cast<Event*> (mus)
2395                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2396         } else if (unsmob_duration (sid)) {
2397                 *destination = unsmob_duration (sid)->smobbed_copy();
2398                 return DURATION_IDENTIFIER;
2399         } else if (unsmob_music_output_def (sid)) {
2400                 Music_output_def *p = unsmob_music_output_def (sid);
2401                 p = p->clone ();
2402
2403                 *destination = p->self_scm();
2404                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2405         } else if (Text_item::markup_p (sid)) {
2406                 *destination = sid;
2407                 return MARKUP_IDENTIFIER;
2408         }
2409
2410         return -1;
2411 }