lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token CHORDMODE
 261 %token DOUBLE_ANGLE_OPEN
 262 %token DOUBLE_ANGLE_CLOSE
 263 %token CLEF
 264 %token COMMANDSPANREQUEST
 265 %token CONSISTS
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES
 272 %token FIGUREMODE
 273 %token FIGURE_OPEN FIGURE_CLOSE
 274 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 275 %token GROBDESCRIPTIONS
 276 %token HEADER
 277 %token HYPHEN
 278 %token INVALID
 279 %token KEY
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368
 369 %token DRUMS
 370 %token DRUMMODE
 371
 372
 373 %type <book>    book_block book_body
 374 %type <i>       bare_int  bare_unsigned
 375 %type <i>       exclamations questions dots optional_rest
 376 %type <i>       script_dir
 377 %type <i>       sub_quotes sup_quotes
 378 %type <i>       tremolo_type
 379 %type <i>       bass_mod
 380
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <music>   Grouped_music_list
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   Repeated_music
 385 %type <music>   command_req
 386 %type <music>   gen_text_def direction_less_event direction_reqd_event
 387 %type <music>   music_property_def context_change
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <music>   post_event tagged_post_event
 390 %type <music>   relative_music re_rhythmed_music
 391 %type <music>   simple_element event_chord command_element
 392 %type <music>   string_number_event
 393 %type <music>   toplevel_music
 394 %type <music>   tempo_event
 395
 396 %type <outputdef>       output_def_body output_def_head
 397 %type <outputdef> output_def book_paper_block
 398
 399 %type <scm>     Music_list
 400 %type <scm>     chord_body_elements
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     context_def_spec_block context_def_spec_body
 403 %type <scm>     context_mod context_def_mod optional_context_mod
 404 %type <scm>     context_prop_spec
 405 %type <scm>     direction_less_char
 406 %type <scm>     duration_length fraction
 407 %type <scm>     embedded_scm scalar
 408 %type <scm>     identifier_init
 409 %type <scm>     lilypond_header lilypond_header_body
 410 %type <scm>     new_lyrics
 411 %type <scm>     post_events
 412 %type <scm>     property_operation
 413 %type <scm>     script_abbreviation
 414 %type <scm>     simple_string
 415 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 416 %type <scm>     steno_tonic_pitch
 417 %type <scm>     step_number step_numbers
 418 %type <scm>     string bare_number number_expression number_term number_factor
 419 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 420 %type <scm>     context_mod_list
 421 %type <scm>     octave_check
 422 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 423 %type <scm>     Generic_prefix_music_scm
 424 %type <scm>     lyric_element
 425 %type <scm>     Alternative_music
 426 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 427 %type <scm>     mode_changing_head
 428 %type <scm>     mode_changing_head_with_context
 429
 430 %type <score>   score_block score_body
 431
 432
 433 %left '-' '+'
 434
 435 /* We don't assign precedence to / and *, because we might need varied
 436 prec levels in different prods */
 437
 438 %left UNARY_MINUS
 439
 440 %%
 441
 442 lilypond:       /* empty */
 443         | lilypond toplevel_expression {
 444         }
 445         | lilypond assignment {
 446         }
 447         | lilypond error {
 448                 THIS->error_level_ = 1;
 449         }
 450         | lilypond INVALID      {
 451                 THIS->error_level_ = 1;
 452         }
 453         ;
 454
 455 toplevel_expression:
 456         lilypond_header {
 457                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 458         }
 459         | add_quote {
 460
 461         }
 462         | book_block {
 463                 Book *book = $1;
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 466                 scm_gc_unprotect_object (book->self_scm ());
 467         }
 468         | score_block {
 469                 Score *score = $1;
 470
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 473                 scm_gc_unprotect_object (score->self_scm ());
 474         }
 475         | toplevel_music {
 476                 Music *music = $1;
 477                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 478                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 479                 scm_gc_unprotect_object (music->self_scm ());
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultbookpaper");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 scm_gc_unprotect_object (od->self_scm ());
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = ly_make_anonymous_module (safe_global_b);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524
 525 /*
 526         DECLARATIONS
 527 */
 528 assignment:
 529         STRING {
 530                 THIS->push_spot ();
 531         }
 532         /* cont */ '=' identifier_init  {
 533
 534         /*
 535                 Should find generic way of associating input with objects.
 536         */
 537                 Input ip = THIS->pop_spot ();
 538
 539                 if (! is_regular_identifier ($1))
 540                 {
 541                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 542                 }
 543
 544                 THIS->lexer_->set_identifier ($1, $4);
 545
 546 /*
 547  TODO: devise standard for protection in parser.
 548
 549   The parser stack lives on the C-stack, which means that
 550 all objects can be unprotected as soon as they're here.
 551
 552 */
 553         }
 554         | embedded_scm { }
 555         ;
 556
 557
 558 identifier_init:
 559         score_block {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | context_def_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 scm_gc_unprotect_object ($$);
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm {
 585                 $$ = $1;
 586         }
 587         | full_markup {
 588                 $$ = $1;
 589         }
 590         | DIGIT {
 591                 $$ = scm_int2num ($1);
 592         }
 593         ;
 594
 595 context_def_spec_block:
 596         CONTEXT '{' context_def_spec_body '}'
 597                 {
 598                 $$ = $3;
 599         }
 600         ;
 601
 602 context_def_spec_body:
 603         /**/ {
 604                 $$ = Context_def::make_scm ();
 605                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 606         }
 607         | CONTEXT_DEF_IDENTIFIER {
 608                 $$ = $1;
 609                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 610         }
 611         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 612                 Context_def*td = unsmob_context_def ($$);
 613
 614                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 615                         SCM tag = ly_caar (p);
 616
 617                         /* TODO: should make new tag "grob-definition" ? */
 618                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 619                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 620                 }
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         ;
 626
 627
 628
 629 book_block:
 630         BOOK {
 631                 THIS->push_spot ();
 632         }
 633         /*cont*/ '{' book_body '}'      {
 634                 THIS->pop_spot ();
 635                 $$ = $4;
 636         }
 637         ;
 638
 639 /* FIXME:
 640    * Use 'handlers' like for toplevel-* stuff?
 641    * grok \paper and \midi?  */
 642 book_body:
 643         {
 644                 $$ = new Book;
 645                 $$->set_spot (THIS->here_input ());
 646                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 647                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 648                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 649         }
 650         | book_body book_paper_block {
 651                 $$->bookpaper_ = $2;
 652                 scm_gc_unprotect_object ($2->self_scm ());
 653         }
 654         | book_body score_block {
 655                 Score *score = $2;
 656                 $$->scores_.push (score);
 657                 scm_gc_unprotect_object (score->self_scm ());
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663
 664         }
 665         ;
 666
 667 score_block:
 668         SCORE {
 669                 THIS->push_spot ();
 670         }
 671         /*cont*/ '{' score_body '}'     {
 672                 THIS->pop_spot ();
 673                 $$ = $4;
 674         }
 675         ;
 676
 677 score_body:
 678         /**/    {
 679                 $$ = new Score;
 680
 681                 $$->set_spot (THIS->here_input ());
 682         }
 683         | SCORE_IDENTIFIER {
 684                 $$ = new Score ( *unsmob_score ($1));
 685                 $$->set_spot (THIS->here_input ());
 686         }
 687         | score_body Music {
 688                 SCM m = $2->self_scm ();
 689                 scm_gc_unprotect_object (m);
 690                 $$->set_music (m, THIS->self_scm ());
 691         }
 692         | score_body lilypond_header    {
 693                 $$->header_ = $2;
 694         }
 695         | score_body output_def {
 696                 $$->defs_.push ($2);
 697                 scm_gc_unprotect_object ($2->self_scm ());
 698         }
 699         | score_body error {
 700
 701         }
 702         ;
 703
 704
 705 /*
 706         OUTPUT DEF
 707 */
 708
 709 book_paper_block:
 710         output_def {
 711                 $$ = $1;
 712                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 713                 {
 714                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 715                         $$ = get_bookpaper (THIS);
 716                 }
 717         }
 718         ;
 719
 720
 721 output_def:
 722         output_def_body '}' {
 723                 $$ = $1;
 724
 725                 THIS->lexer_->remove_scope ();
 726                 THIS->lexer_->pop_state ();
 727         }
 728         ;
 729
 730 output_def_head:
 731         BOOKPAPER {
 732                 $$ = get_bookpaper (THIS);
 733                 $$->input_origin_ = THIS->here_input ();
 734                 THIS->lexer_->add_scope ($$->scope_);
 735         }
 736         | MIDI    {
 737                 Output_def *p = get_midi (THIS);
 738                 $$ = p;
 739                 THIS->lexer_->add_scope (p->scope_);
 740         }
 741         | PAPER         {
 742                 Output_def *p = get_paper (THIS);
 743
 744                 THIS->lexer_->add_scope (p->scope_);
 745                 $$ = p;
 746         }
 747         ;
 748
 749
 750 output_def_body:
 751         output_def_head '{' {
 752                 $$ = $1;
 753                 $$->input_origin_.set_spot (THIS->here_input ());
 754                 THIS->lexer_->push_initial_state ();
 755         }
 756         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 757                 scm_gc_unprotect_object ($1->self_scm ());
 758                 Output_def *o = unsmob_output_def ($3);
 759                 o->input_origin_.set_spot (THIS->here_input ());
 760                 $$ = o;
 761                 THIS->lexer_->remove_scope ();
 762                 THIS->lexer_->add_scope (o->scope_);
 763                 THIS->lexer_->push_initial_state ();
 764         }
 765         | output_def_body assignment  {
 766
 767         }
 768         | output_def_body context_def_spec_block        {
 769                 assign_context_def ($$, $2);
 770         }
 771         | output_def_body tempo_event  {
 772                 /*
 773                         junk this ? there already is tempo stuff in
 774                         music.
 775                 */
 776                 int m = scm_to_int ($2->get_property ("metronome-count"));
 777                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 778                 set_tempo ($$, d->get_length (), m);
 779                 scm_gc_unprotect_object ($2->self_scm ());
 780         }
 781         | output_def_body error {
 782
 783         }
 784         ;
 785
 786 tempo_event:
 787         TEMPO steno_duration '=' bare_unsigned  {
 788                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 789                 $$->set_property ("tempo-unit", $2);
 790                 $$->set_property ("metronome-count", scm_int2num ( $4));
 791         }
 792         ;
 793
 794 /*
 795 The representation of a  list is the
 796
 797   (LIST . LAST-CONS)
 798
 799  to have  efficient append.
 800 */
 801 Music_list:
 802         /* empty */ {
 803                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 804         }
 805         | Music_list Music {
 806                 SCM s = $$;
 807                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 808                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 809                 if (ly_c_pair_p (ly_cdr (s)))
 810                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 811                 else
 812                         scm_set_car_x (s, c); /* set first cons */
 813                 scm_set_cdr_x (s, c);  /* remember last cell */
 814         }
 815         | Music_list embedded_scm {
 816         }
 817         | Music_list error {
 818         }
 819         ;
 820
 821
 822 Music:
 823         Simple_music
 824         | Composite_music
 825         ;
 826
 827 Alternative_music:
 828         /* empty */ {
 829                 $$ = SCM_EOL;
 830         }
 831         | ALTERNATIVE '{' Music_list '}' {
 832                 $$ = $3;
 833         }
 834         ;
 835
 836
 837 Repeated_music:
 838         REPEAT simple_string bare_unsigned Music Alternative_music
 839         {
 840                 Music *beg = $4;
 841                 int times = $3;
 842                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 843                 if (times < scm_ilength (alts)) {
 844                   unsmob_music (ly_car (alts))
 845                     ->origin ()->warning (
 846                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 847                   alts = ly_truncate_list (times, alts);
 848                 }
 849
 850
 851                 SCM proc = ly_scheme_function ("make-repeated-music");
 852
 853                 SCM mus = scm_call_1 (proc, $2);
 854                 scm_gc_protect_object (mus); // UGH.
 855                 Music *r = unsmob_music (mus);
 856                 if (beg)
 857                         {
 858                         r-> set_property ("element", beg->self_scm ());
 859                         scm_gc_unprotect_object (beg->self_scm ());
 860                         }
 861                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 862
 863                 r-> set_property ("elements",alts);
 864                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 865                         /*
 866                         TODO: move this code to Scheme.
 867                         */
 868
 869                         /*
 870                         we can not get durations and other stuff correct down the line, so we have to
 871                         add to the duration log here.
 872                         */
 873                         SCM func = ly_scheme_function ("shift-duration-log");
 874
 875                         int dots = ($3 % 3) ? 0 : 1;
 876                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 877
 878                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 879
 880                         if (seq) {
 881                                 int list_len = scm_ilength (seq->music_list ());
 882                                 if (list_len != 2)
 883                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 884                                 shift -= 1;
 885                                 r->compress (Moment (Rational (1, list_len)));
 886                                 }
 887                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 888
 889                 }
 890                 r->set_spot (*$4->origin ());
 891
 892                 $$ = r;
 893         }
 894         ;
 895
 896 Sequential_music:
 897         SEQUENTIAL '{' Music_list '}'           {
 898                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 899                 $$->set_property ("elements", ly_car ($3));
 900                 $$->set_spot (THIS->here_input ());
 901         }
 902         | '{' Music_list '}'            {
 903                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 904                 $$->set_property ("elements", ly_car ($2));
 905                 $$->set_spot (THIS->here_input ());
 906         }
 907         ;
 908
 909 Simultaneous_music:
 910         SIMULTANEOUS '{' Music_list '}'{
 911                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 912                 $$->set_property ("elements", ly_car ($3));
 913                 $$->set_spot (THIS->here_input ());
 914
 915         }
 916         | simul_open Music_list simul_close     {
 917                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 918                 $$->set_property ("elements", ly_car ($2));
 919                 $$->set_spot (THIS->here_input ());
 920         }
 921         ;
 922
 923 Simple_music:
 924         event_chord             { $$ = $1; }
 925         | MUSIC_IDENTIFIER {
 926                 $$ = unsmob_music ($1);
 927         }
 928         | music_property_def
 929         | context_change
 930         ;
 931
 932
 933 optional_context_mod:
 934         /**/ { $$ = SCM_EOL; }
 935         | WITH { THIS->lexer_->push_initial_state (); }
 936         '{' context_mod_list '}'
 937         {
 938                 THIS->lexer_->pop_state ();
 939                 $$ = $4;
 940         }
 941         ;
 942
 943 context_mod_list:
 944         /* */  { $$ = SCM_EOL; }
 945         | context_mod_list context_mod  {
 946                  $$ = scm_cons ($2, $1);
 947         }
 948         ;
 949
 950
 951 Composite_music:
 952         Prefix_composite_music { $$ = $1; }
 953         | Grouped_music_list { $$ = $1; }
 954         ;
 955
 956 Grouped_music_list:
 957         Simultaneous_music              { $$ = $1; }
 958         | Sequential_music              { $$ = $1; }
 959         ;
 960
 961 Generic_prefix_music_scm:
 962         MUSIC_FUNCTION {
 963                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 964         }
 965         | MUSIC_FUNCTION_SCM {
 966                 THIS->push_spot ();
 967         } embedded_scm {
 968                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 969         }
 970         | MUSIC_FUNCTION_MUSIC {
 971                 THIS->push_spot ();
 972         } Music {
 973                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 974                 scm_gc_unprotect_object ($3->self_scm ());
 975         }
 976         | MUSIC_FUNCTION_SCM_MUSIC {
 977                 THIS->push_spot ();
 978         }  embedded_scm Music {
 979                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 980                 scm_gc_unprotect_object ($4->self_scm ());
 981         }
 982         | MUSIC_FUNCTION_SCM_SCM {
 983                 THIS->push_spot ();
 984         }  embedded_scm embedded_scm {
 985                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 986         }
 987         | MUSIC_FUNCTION_MUSIC_MUSIC {
 988                 THIS->push_spot ();
 989         }  Music  Music {
 990                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 991                 scm_gc_unprotect_object ($3->self_scm ());
 992                 scm_gc_unprotect_object ($4->self_scm ());
 993         }
 994         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 995                 THIS->push_spot ();
 996         } embedded_scm Music Music {
 997                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
 998                         $3, $4->self_scm (), $5->self_scm ());
 999                 scm_gc_unprotect_object ($5->self_scm ());
1000                 scm_gc_unprotect_object ($4->self_scm ());
1001         }
1002         ;
1003
1004 Generic_prefix_music:
1005         Generic_prefix_music_scm {
1006                 SCM func = ly_car ($1);
1007                 Input *loc = unsmob_input (ly_cadr ($1));
1008                 SCM args = ly_cddr ($1);
1009                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1010                 int k = 0;
1011                 bool ok  = true;
1012                 for (SCM s = sig, t = args;
1013                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1014                         s = ly_cdr (s), t = ly_cdr (t)) {
1015                         k++;
1016                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1017                         {
1018                                 loc->error (_f ("Argument %d failed typecheck", k));
1019                                 THIS->error_level_ = 1;
1020                                 ok = false;
1021                         }
1022                 }
1023                 SCM m = SCM_EOL;
1024                 if (ok)
1025                         m = scm_apply_0 (func, ly_cdr ($1));
1026                 if (unsmob_music (m))
1027                         {
1028                         $$ = unsmob_music (m);
1029                         scm_gc_protect_object (m);
1030                         }
1031                 else
1032                         {
1033                         if (ok)
1034                                 loc->error (_ ("Music head function should return Music object."));
1035                         $$ = MY_MAKE_MUSIC ("Music");
1036                         }
1037                 $$->set_spot (*loc);
1038         }
1039         ;
1040
1041
1042 Prefix_composite_music:
1043         Generic_prefix_music {
1044                 $$ = $1;
1045         }
1046         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1047                 $$ = context_spec_music ($2, $4, $6, $5);
1048
1049         }
1050         | CONTEXT simple_string optional_context_mod Music {
1051                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1052         }
1053         | NEWCONTEXT simple_string optional_context_mod Music {
1054                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1055                         $3);
1056         }
1057
1058         | TIMES {
1059                 THIS->push_spot ();
1060         }
1061         /* CONTINUED */
1062                 fraction Music
1063
1064         {
1065                 int n = scm_to_int (ly_car ($3)); int d = scm_to_int (ly_cdr ($3));
1066                 Music *mp = $4;
1067
1068                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1069                 $$->set_spot (THIS->pop_spot ());
1070
1071                 $$->set_property ("element", mp->self_scm ());
1072                 scm_gc_unprotect_object (mp->self_scm ());
1073                 $$->set_property ("numerator", scm_int2num (n));
1074                 $$->set_property ("denominator", scm_int2num (d));
1075                 $$->compress (Moment (Rational (n,d)));
1076
1077         }
1078         | Repeated_music                { $$ = $1; }
1079         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1080                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1081                 Music *p = $4;
1082                 Pitch from = *unsmob_pitch ($2);
1083                 Pitch to = *unsmob_pitch ($3);
1084
1085                 p->transpose (interval (from, to));
1086                 $$->set_property ("element", p->self_scm ());
1087                 scm_gc_unprotect_object (p->self_scm ());
1088         }
1089         | mode_changing_head Grouped_music_list {
1090                 if ($1 == ly_symbol2scm ("chords"))
1091                 {
1092                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1093                   chm->set_property ("element", $2->self_scm ());
1094                   $$ = chm;
1095                   scm_gc_unprotect_object ($2->self_scm ());
1096                 }
1097                 else
1098                 {
1099                   $$ = $2;
1100                 }
1101                 THIS->lexer_->pop_state ();
1102         }
1103         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1104                 $$ = context_spec_music ($1, get_next_unique_context (),
1105                                          $3, $2);
1106                 if ($1 == ly_symbol2scm ("ChordNames"))
1107                 {
1108                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1109                   chm->set_property ("element", $$->self_scm ());
1110                   scm_gc_unprotect_object ($$->self_scm ());
1111                   $$ = chm;
1112                 }
1113                 THIS->lexer_->pop_state ();
1114         }
1115         | relative_music        { $$ = $1; }
1116         | re_rhythmed_music     { $$ = $1; }
1117         | TAG embedded_scm Music {
1118                 tag_music ($3, $2, THIS->here_input ());
1119                 $$ = $3;
1120         }
1121         ;
1122
1123 mode_changing_head:
1124         NOTEMODE {
1125                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1126                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1127
1128                 $$ = ly_symbol2scm ("notes");
1129         }
1130         | DRUMMODE
1131                 {
1132                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1133                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1134
1135                 $$ = ly_symbol2scm ("drums");
1136         }
1137         | FIGUREMODE {
1138                 THIS->lexer_->push_figuredbass_state ();
1139
1140                 $$ = ly_symbol2scm ("figures");
1141         }
1142         | CHORDMODE {
1143                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1144                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1145                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1146                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1147                 $$ = ly_symbol2scm ("chords");
1148
1149         }
1150         | LYRICMODE
1151                 { THIS->lexer_->push_lyric_state ();
1152                 $$ = ly_symbol2scm ("lyrics");
1153         }
1154         ;
1155
1156 mode_changing_head_with_context:
1157         DRUMS {
1158                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1159                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1160
1161                 $$ = ly_symbol2scm ("DrumStaff");
1162         }
1163         | FIGURES {
1164                 THIS->lexer_->push_figuredbass_state ();
1165
1166                 $$ = ly_symbol2scm ("FiguredBass");
1167         }
1168         | CHORDS {
1169                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1170                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1171                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1172                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1173                 $$ = ly_symbol2scm ("ChordNames");
1174         }
1175         | LYRICS
1176                 { THIS->lexer_->push_lyric_state ();
1177                 $$ = ly_symbol2scm ("Lyrics");
1178         }
1179         ;
1180
1181
1182 relative_music:
1183         RELATIVE absolute_pitch Music {
1184                 Music *m = $3;
1185                 Pitch start = *unsmob_pitch ($2);
1186                 $$ = make_music_relative (start, m);
1187                 scm_gc_unprotect_object (m->self_scm ());
1188         }
1189         | RELATIVE Composite_music {
1190                 Music *m = $2;
1191
1192                 Pitch middle_c (0, 0, 0);
1193                 $$ = make_music_relative (middle_c, m);
1194                 scm_gc_unprotect_object (m->self_scm ());
1195         }
1196         ;
1197
1198 new_lyrics:
1199         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1200         /*cont */
1201         Grouped_music_list {
1202         /* Can also use Music at the expensive of two S/Rs similar to
1203            \repeat \alternative */
1204                 THIS->lexer_->pop_state ();
1205
1206                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1207         }
1208         | new_lyrics ADDLYRICS {
1209                 THIS->lexer_->push_lyric_state ();
1210         } Grouped_music_list {
1211                 THIS->lexer_->pop_state ();
1212                 $$ = scm_cons ($4->self_scm (), $1);
1213         }
1214         ;
1215
1216 re_rhythmed_music:
1217         Grouped_music_list new_lyrics {
1218
1219                 SCM name = $1->get_property ("context-id");
1220                 //if (name == SCM_EOL)
1221                 if (!scm_is_string (name))
1222                         name = scm_makfrom0str ("");
1223
1224                 SCM context = scm_makfrom0str ("Lyrics");
1225                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1226
1227                 SCM lst = SCM_EOL;
1228                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1229                 {
1230                         Music *music = unsmob_music (ly_car (s));
1231                         Music *com = make_lyric_combine_music (name, music);
1232                         Music *csm = context_spec_music (context,
1233                                 get_next_unique_context (), com, SCM_EOL);
1234                         lst = scm_cons (csm->self_scm (), lst);
1235                 }
1236                 /* FIXME: only first lyric music is accepted,
1237                           the rest is junked */
1238                 all->set_property ("elements", scm_cons ($1->self_scm (),
1239                         lst));
1240                 $$ = all;
1241                 scm_gc_unprotect_object ($1->self_scm ());
1242         }
1243         | LYRICSTO {
1244                 THIS->lexer_->push_lyric_state ();
1245         } simple_string Music {
1246                 THIS->lexer_->pop_state ();
1247                 Music *music = $4;
1248                 SCM name = $3;
1249                 $$ = make_lyric_combine_music (name, music);
1250                 scm_gc_unprotect_object (music->self_scm ());
1251         }
1252         ;
1253
1254 context_change:
1255         CHANGE STRING '=' STRING  {
1256                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1257                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1258                 t-> set_property ("change-to-id", $4);
1259
1260                 $$ = t;
1261                 $$->set_spot (THIS->here_input ());
1262         }
1263         ;
1264
1265 property_operation:
1266         STRING '=' scalar {
1267                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1268                         scm_string_to_symbol ($1), $3);
1269         }
1270         | UNSET simple_string {
1271                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1272                         scm_string_to_symbol ($2));
1273         }
1274         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1275                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1276                         scm_string_to_symbol ($2), $3, $5);
1277         }
1278         | REVERT simple_string embedded_scm {
1279                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1280                         scm_string_to_symbol ($2), $3);
1281         }
1282         ;
1283
1284 context_def_mod:
1285         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1286         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1287
1288         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1289         | DENIES { $$ = ly_symbol2scm ("denies"); }
1290
1291         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1292         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1293         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1294         | NAME { $$ = ly_symbol2scm ("context-name"); }
1295         ;
1296
1297 context_mod:
1298         property_operation { $$ = $1; }
1299         | context_def_mod STRING {
1300                 $$ = scm_list_2 ($1, $2);
1301         }
1302         ;
1303
1304 context_prop_spec:
1305         simple_string {
1306                 if (!is_regular_identifier ($1))
1307                 {
1308                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1309                 }
1310
1311                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1312                         scm_string_to_symbol ($1));
1313         }
1314         | simple_string '.' simple_string {
1315                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1316                         scm_string_to_symbol ($3));
1317         }
1318         ;
1319
1320 music_property_def:
1321         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1322                 $$ = property_op_to_music (scm_list_4 (
1323                         ly_symbol2scm ("poppush"),
1324                         ly_cadr ($2),
1325                         $3, $5));
1326                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1327         }
1328         | REVERT context_prop_spec embedded_scm {
1329                 $$ = property_op_to_music (scm_list_3 (
1330                         ly_symbol2scm ("pop"),
1331                         ly_cadr ($2),
1332                         $3));
1333
1334                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1335         }
1336         | SET context_prop_spec '=' scalar {
1337                 $$ = property_op_to_music (scm_list_3 (
1338                         ly_symbol2scm ("assign"),
1339                         ly_cadr ($2),
1340                         $4));
1341                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1342         }
1343         | UNSET context_prop_spec {
1344                 $$ = property_op_to_music (scm_list_2 (
1345                         ly_symbol2scm ("unset"),
1346                         ly_cadr ($2)));
1347                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1348         }
1349         | ONCE music_property_def {
1350                 SCM e = $2->get_property ("element");
1351                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1352                 $$ = $2;
1353
1354         }
1355         ;
1356
1357
1358 string:
1359         STRING {
1360                 $$ = $1;
1361         }
1362         | STRING_IDENTIFIER {
1363                 $$ = $1;
1364         }
1365         | string '+' string {
1366                 $$ = scm_string_append (scm_list_2 ($1, $3));
1367         }
1368         ;
1369
1370 simple_string: STRING {
1371                 $$ = $1;
1372         }
1373         | LYRICS_STRING {
1374                 $$ = $1;
1375         }
1376         ;
1377
1378 scalar: string {
1379                 $$ = $1;
1380         }
1381         | LYRICS_STRING {
1382                 $$ = $1;
1383         }
1384         | bare_int {
1385                 $$ = scm_int2num ($1);
1386         }
1387         | embedded_scm {
1388                 $$ = $1;
1389         }
1390         | full_markup {
1391                 $$ = $1;
1392         }
1393         | DIGIT {
1394                 $$ = scm_int2num ($1);
1395         }
1396         ;
1397
1398 /*
1399
1400 pre_events doesn't contain anything. It is a trick:
1401
1402 Adding pre_events to the simple_element
1403 makes the choice between
1404
1405   string:  STRING
1406
1407 and
1408
1409   simple_element: STRING
1410
1411 a single shift/reduction conflict.
1412
1413 nevertheless, this is not very clean, and we should find a different
1414 solution.
1415
1416 */
1417 pre_events: {
1418                 THIS->push_spot ();
1419         }
1420         ;
1421
1422 event_chord:
1423         pre_events simple_element post_events   {
1424                 SCM elts = $2-> get_property ("elements");
1425
1426                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1427
1428                 $2->set_property ("elements", elts);
1429                 $$ = $2;
1430         }
1431         | command_element
1432         | note_chord_element
1433         ;
1434
1435
1436 note_chord_element:
1437         chord_body optional_notemode_duration post_events
1438         {
1439                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1440                 SCM es = $1->get_property ("elements");
1441                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1442
1443                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1444                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1445                 es = ly_append2 (es, postevs);
1446
1447                 $1-> set_property ("elements", es);
1448                 $$ = $1;
1449         }
1450         ;
1451
1452 chord_open: '<'
1453         ;
1454
1455 chord_close: '>'
1456         ;
1457
1458 simul_open: DOUBLE_ANGLE_OPEN
1459         ;
1460
1461 simul_close: DOUBLE_ANGLE_CLOSE
1462         ;
1463
1464 chord_body:
1465         chord_open chord_body_elements chord_close
1466         {
1467                 $$ = MY_MAKE_MUSIC ("EventChord");
1468                 $$->set_property ("elements",
1469                         scm_reverse_x ($2, SCM_EOL));
1470         }
1471         ;
1472
1473 chord_body_elements:
1474         /* empty */             { $$ = SCM_EOL; }
1475         | chord_body_elements chord_body_element {
1476                 $$ = scm_cons ($2->self_scm (), $1);
1477                 scm_gc_unprotect_object ($2->self_scm ());
1478         }
1479         ;
1480
1481 chord_body_element:
1482         pitch  exclamations questions octave_check post_events
1483         {
1484                 int q = $3;
1485                 int ex = $2;
1486                 SCM check = $4;
1487                 SCM post = $5;
1488
1489                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1490                 n->set_property ("pitch", $1);
1491                 if (q % 2)
1492                         n->set_property ("cautionary", SCM_BOOL_T);
1493                 if (ex % 2 || q % 2)
1494                         n->set_property ("force-accidental", SCM_BOOL_T);
1495
1496                 if (ly_c_pair_p (post)) {
1497                         SCM arts = scm_reverse_x (post, SCM_EOL);
1498                         n->set_property ("articulations", arts);
1499                 }
1500                 if (scm_is_number (check))
1501                 {
1502                         int q = scm_to_int (check);
1503                         n->set_property ("absolute-octave", scm_int2num (q-1));
1504                 }
1505
1506
1507                 $$ = n;
1508         }
1509         | DRUM_PITCH post_events {
1510                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1511                 n->set_property ("duration", $2);
1512                 n->set_property ("drum-type", $1);
1513                 n->set_spot (THIS->here_input ());
1514
1515                 if (ly_c_pair_p ($2)) {
1516                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1517                         n->set_property ("articulations", arts);
1518                 }
1519                 $$ = n;
1520         }
1521         ;
1522
1523 add_quote:
1524         ADDQUOTE string Music {
1525                 SCM adder = ly_scheme_function ("add-quotable");
1526
1527                 scm_call_2 (adder, $2, $3->self_scm ());
1528                 scm_gc_unprotect_object ($3->self_scm ());
1529         }
1530         ;
1531
1532 command_element:
1533         command_req {
1534                 $$ = MY_MAKE_MUSIC ("EventChord");
1535                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1536                 scm_gc_unprotect_object ($1->self_scm ());
1537
1538                 $$-> set_spot (THIS->here_input ());
1539                 $1-> set_spot (THIS->here_input ());
1540         }
1541         | SKIP duration_length {
1542                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1543                 skip->set_property ("duration", $2);
1544
1545                 $$ = skip;
1546         }
1547         | QUOTE STRING duration_length {
1548                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1549                 quote->set_property ("duration", $3);
1550                 quote->set_property ("quoted-music-name", $2);
1551                 quote->set_spot (THIS->here_input ());
1552
1553                 $$ = quote;
1554         }
1555         | OCTAVE { THIS->push_spot (); }
1556           pitch {
1557                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1558                 $$ = m;
1559                 $$->set_spot (THIS->pop_spot ());
1560                 $$->set_property ("pitch", $3);
1561         }
1562         | E_LEFTSQUARE {
1563                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1564                 m->set_property ("span-direction", scm_int2num (START));
1565                 m->set_spot (THIS->here_input ());
1566
1567                 $$ = MY_MAKE_MUSIC ("EventChord");
1568                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1569                 scm_gc_unprotect_object (m->self_scm ());
1570                 $$->set_spot (THIS->here_input ());
1571         }
1572         | E_RIGHTSQUARE {
1573                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1574                 m->set_property ("span-direction", scm_int2num (STOP));
1575                 m->set_spot (THIS->here_input ());
1576
1577                 $$ = MY_MAKE_MUSIC ("EventChord");
1578                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1579                 $$->set_spot (THIS->here_input ());
1580                 scm_gc_unprotect_object (m->self_scm ());
1581         }
1582         | E_BACKSLASH {
1583                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1584                 $$->set_spot (THIS->here_input ());
1585         }
1586         | '|'      {
1587                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1588
1589                 if (Music * m = unsmob_music (pipe))
1590                         $$ = m->clone ();
1591                 else
1592                         $$ = MY_MAKE_MUSIC ("BarCheck");
1593
1594                 $$->set_spot (THIS->here_input ());
1595         }
1596         | TRANSPOSITION pitch {
1597                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1598                                         $2);
1599                 $$->set_spot (THIS-> here_input ());
1600                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1601                         $$, SCM_EOL);
1602         }
1603         | BAR STRING                    {
1604                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1605
1606                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1607                                         t, SCM_EOL);
1608                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1609                 $$->set_spot (THIS->here_input ());
1610                 t->set_spot (THIS->here_input ());
1611         }
1612         | PARTIAL duration_length       {
1613                 Moment m = - unsmob_duration ($2)->get_length ();
1614                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1615                 p->set_spot (THIS->here_input ());
1616                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1617                                         p, SCM_EOL);
1618                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1619                                         p, SCM_EOL);
1620                 $$ = p;
1621         }
1622         | CLEF STRING  {
1623                 SCM proc = ly_scheme_function ("make-clef-set");
1624
1625                 SCM result = scm_call_1 (proc, $2);
1626                 scm_gc_protect_object (result);
1627                 $$ = unsmob_music (result);
1628         }
1629         | TIME_T fraction  {
1630                 SCM proc= ly_scheme_function ("make-time-signature-set");
1631
1632                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1633                 scm_gc_protect_object (result);
1634                 $$ = unsmob_music (result);
1635         }
1636         | MARK scalar {
1637                 SCM proc = ly_scheme_function ("make-mark-set");
1638
1639                 SCM result = scm_call_1 (proc, $2);
1640                 scm_gc_protect_object (result);
1641                 $$ = unsmob_music (result);
1642         }
1643         ;
1644
1645 command_req:
1646         E_TILDE {
1647                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1648         }
1649         | MARK DEFAULT  {
1650                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1651                 $$ = m;
1652         }
1653         | tempo_event {
1654                 $$ = $1;
1655         }
1656         | KEY DEFAULT {
1657                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1658                 $$ = key;
1659         }
1660         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1661
1662                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1663                 if (scm_ilength ($3) > 0)
1664                 {
1665                         key->set_property ("pitch-alist", $3);
1666                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1667                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1668                 } else {
1669                         THIS->parser_error (_ ("Second argument must be pitch list."));
1670                 }
1671
1672                 $$ = key;
1673         }
1674         ;
1675
1676 post_events:
1677         /* empty */ {
1678                 $$ = SCM_EOL;
1679         }
1680         | post_events post_event {
1681                 $2->set_spot (THIS->here_input ());
1682                 $$ = scm_cons ($2->self_scm (), $$);
1683                 scm_gc_unprotect_object ($2->self_scm ());
1684         }
1685         | post_events tagged_post_event {
1686                 $2 -> set_spot (THIS->here_input ());
1687                 $$ = scm_cons ($2->self_scm (), $$);
1688                 scm_gc_unprotect_object ($2->self_scm ());
1689         }
1690         ;
1691
1692
1693 tagged_post_event:
1694         '-' TAG embedded_scm post_event {
1695                 tag_music ($4, $3, THIS->here_input ());
1696                 $$ = $4;
1697         }
1698         ;
1699
1700 post_event:
1701         direction_less_event {
1702                 $$ = $1;
1703         }
1704         | HYPHEN {
1705                 if (!THIS->lexer_->is_lyric_state ())
1706                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1707                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1708         }
1709         | EXTENDER {
1710                 if (!THIS->lexer_->is_lyric_state ())
1711                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1712                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1713         }
1714         | script_dir direction_reqd_event {
1715                 if ($1)
1716                         $2->set_property ("direction", scm_int2num ($1));
1717                 $$ = $2;
1718         }
1719         | script_dir direction_less_event {
1720                 if ($1)
1721                         $2->set_property ("direction", scm_int2num ($1));
1722                 $$ = $2;
1723         }
1724         | string_number_event
1725         ;
1726
1727 string_number_event:
1728         E_UNSIGNED {
1729                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1730                 s->set_property ("string-number", scm_int2num ($1));
1731                 s->set_spot (THIS->here_input ());
1732                 $$ = s;
1733         }
1734         ;
1735
1736 direction_less_char:
1737         '['  {
1738                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1739         }
1740         | ']'  {
1741                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1742         }
1743         | '~'  {
1744                 $$ = ly_symbol2scm ("tildeSymbol");
1745         }
1746         | '('  {
1747                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1748         }
1749         | ')'  {
1750                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1751         }
1752         | E_EXCLAMATION  {
1753                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1754         }
1755         | E_OPEN  {
1756                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1757         }
1758         | E_CLOSE  {
1759                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1760         }
1761         | E_BIGGER  {
1762                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1763         }
1764         | E_SMALLER  {
1765                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1766         }
1767         ;
1768
1769 direction_less_event:
1770         direction_less_char {
1771                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1772                 Music * m = 0;
1773                 if (unsmob_music (predefd))
1774                 {
1775                         m = unsmob_music (predefd)->clone ();
1776                 }
1777                 else
1778                 {
1779                         m = MY_MAKE_MUSIC ("Music");
1780                 }
1781                 m->set_spot (THIS->here_input ());
1782                 $$ = m;
1783         }
1784         | EVENT_IDENTIFIER      {
1785                 $$ = unsmob_music ($1);
1786         }
1787         | tremolo_type  {
1788                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1789                a->set_spot (THIS->here_input ());
1790                a->set_property ("tremolo-type", scm_int2num ($1));
1791                $$ = a;
1792         }
1793         ;
1794
1795 direction_reqd_event:
1796         gen_text_def {
1797                 $$ = $1;
1798         }
1799         | script_abbreviation {
1800                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1801                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1802                 if (scm_is_string (s))
1803                         a->set_property ("articulation-type", s);
1804                 else THIS->parser_error (_ ("Expecting string as script definition"));
1805                 $$ = a;
1806         }
1807         ;
1808
1809 octave_check:
1810         /**/ { $$ = SCM_EOL; }
1811         | '='  { $$ = scm_int2num (0); }
1812         | '=' sub_quotes { $$ = scm_int2num ($2); }
1813         | '=' sup_quotes { $$ = scm_int2num ($2); }
1814         ;
1815
1816 sup_quotes:
1817         '\'' {
1818                 $$ = 1;
1819         }
1820         | sup_quotes '\'' {
1821                 $$ ++;
1822         }
1823         ;
1824
1825 sub_quotes:
1826         ',' {
1827                 $$ = 1;
1828         }
1829         | sub_quotes ',' {
1830                 $$++;
1831         }
1832         ;
1833
1834 steno_pitch:
1835         NOTENAME_PITCH  {
1836                 $$ = $1;
1837         }
1838         | NOTENAME_PITCH sup_quotes     {
1839                 Pitch p = *unsmob_pitch ($1);
1840                 p = p.transposed (Pitch ($2,0,0));
1841                 $$ = p.smobbed_copy ();
1842         }
1843         | NOTENAME_PITCH sub_quotes      {
1844                 Pitch p =* unsmob_pitch ($1);
1845                 p = p.transposed (Pitch (-$2,0,0));
1846                 $$ = p.smobbed_copy ();
1847         }
1848         ;
1849
1850 /*
1851 ugh. duplication
1852 */
1853
1854 steno_tonic_pitch:
1855         TONICNAME_PITCH {
1856                 $$ = $1;
1857         }
1858         | TONICNAME_PITCH sup_quotes    {
1859                 Pitch p = *unsmob_pitch ($1);
1860                 p = p.transposed (Pitch ($2,0,0));
1861                 $$ = p.smobbed_copy ();
1862         }
1863         | TONICNAME_PITCH sub_quotes     {
1864                 Pitch p =* unsmob_pitch ($1);
1865
1866                 p = p.transposed (Pitch (-$2,0,0));
1867                 $$ = p.smobbed_copy ();
1868         }
1869         ;
1870
1871 pitch:
1872         steno_pitch {
1873                 $$ = $1;
1874         }
1875         ;
1876
1877 pitch_also_in_chords:
1878         pitch
1879         | steno_tonic_pitch
1880         ;
1881
1882 gen_text_def:
1883         full_markup {
1884                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1885                 t->set_property ("text", $1);
1886                 t->set_spot (THIS->here_input ());
1887                 $$ = t;
1888         }
1889         | string {
1890                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1891                 t->set_property ("text",
1892                         make_simple_markup (THIS->lexer_->encoding (), $1));
1893                 t->set_spot (THIS->here_input ());
1894                 $$ = t;
1895
1896         }
1897         | DIGIT {
1898                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1899                 t->set_property ("digit", scm_int2num ($1));
1900                 t->set_spot (THIS->here_input ());
1901                 $$ = t;
1902         }
1903         ;
1904
1905 script_abbreviation:
1906         '^'             {
1907                 $$ = scm_makfrom0str ("Hat");
1908         }
1909         | '+'           {
1910                 $$ = scm_makfrom0str ("Plus");
1911         }
1912         | '-'           {
1913                 $$ = scm_makfrom0str ("Dash");
1914         }
1915         | '|'           {
1916                 $$ = scm_makfrom0str ("Bar");
1917         }
1918         | '>'           {
1919                 $$ = scm_makfrom0str ("Larger");
1920         }
1921         | '.'           {
1922                 $$ = scm_makfrom0str ("Dot");
1923         }
1924         | '_' {
1925                 $$ = scm_makfrom0str ("Underscore");
1926         }
1927         ;
1928
1929 script_dir:
1930         '_'     { $$ = DOWN; }
1931         | '^'   { $$ = UP; }
1932         | '-'   { $$ = CENTER; }
1933         ;
1934
1935
1936 absolute_pitch:
1937         steno_pitch     {
1938                 $$ = $1;
1939         }
1940         ;
1941
1942 duration_length:
1943         multiplied_duration {
1944                 $$ = $1;
1945         }
1946         ;
1947
1948 optional_notemode_duration:
1949         {
1950                 Duration dd = THIS->default_duration_;
1951                 $$ = dd.smobbed_copy ();
1952
1953                 THIS->beam_check ($$);
1954         }
1955         | multiplied_duration   {
1956                 $$ = $1;
1957                 THIS->default_duration_ = *unsmob_duration ($$);
1958
1959                 THIS->beam_check ($$);
1960         }
1961         ;
1962
1963 steno_duration:
1964         bare_unsigned dots              {
1965                 int len = 0;
1966                 if (!is_duration ($1))
1967                         THIS->parser_error (_f ("not a duration: %d", $1));
1968                 else
1969                         len = intlog2 ($1);
1970
1971                 $$ = Duration (len, $2).smobbed_copy ();
1972         }
1973         | DURATION_IDENTIFIER dots      {
1974                 Duration *d = unsmob_duration ($1);
1975                 Duration k (d->duration_log (), d->dot_count () + $2);
1976                 *d = k;
1977                 $$ = $1;
1978         }
1979         ;
1980
1981 multiplied_duration:
1982         steno_duration {
1983                 $$ = $1;
1984         }
1985         | multiplied_duration '*' bare_unsigned {
1986                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1987         }
1988         | multiplied_duration '*' FRACTION {
1989                 Rational  m (scm_to_int (ly_car ($3)), scm_to_int (ly_cdr ($3)));
1990
1991                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1992         }
1993         ;
1994
1995 fraction:
1996         FRACTION { $$ = $1; }
1997         | UNSIGNED '/' UNSIGNED {
1998                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
1999         }
2000         ;
2001
2002 dots:
2003         /* empty */     {
2004                 $$ = 0;
2005         }
2006         | dots '.' {
2007                 $$ ++;
2008         }
2009         ;
2010
2011 tremolo_type:
2012         ':'     {
2013                 $$ = 0;
2014         }
2015         | ':' bare_unsigned {
2016                 if (!is_duration ($2))
2017                         THIS->parser_error (_f ("not a duration: %d", $2));
2018                 $$ = $2;
2019         }
2020         ;
2021
2022 bass_number:
2023         DIGIT   {
2024                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2025                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2026                                 $$);
2027         }
2028         | UNSIGNED {
2029                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2030                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2031                                 $$);
2032         }
2033         | STRING { $$ = $1; }
2034         ;
2035
2036 bass_mod:
2037         '-'     { $$ = -2; }
2038         | '+'   { $$ = 2; }
2039         | '!'   { $$ = 0; }
2040         ;
2041
2042 bass_figure:
2043         FIGURE_SPACE {
2044                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2045                 $$ = bfr->self_scm ();
2046                 scm_gc_unprotect_object ($$);
2047         }
2048         | bass_number  {
2049                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2050                 $$ = bfr->self_scm ();
2051
2052                 bfr->set_property ("figure", $1);
2053
2054                 scm_gc_unprotect_object ($$);
2055         }
2056         | bass_figure bass_mod {
2057                 Music *m = unsmob_music ($1);
2058                 if ($2) {
2059                         SCM salter = m->get_property ("alteration");
2060                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2061                         m->set_property ("alteration",
2062                                 scm_int2num (alter + $2));
2063                 } else {
2064                         m->set_property ("alteration", scm_int2num (0));
2065                 }
2066         }
2067         ;
2068
2069 br_bass_figure:
2070         '[' bass_figure {
2071                 $$ = $2;
2072                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2073         }
2074         | bass_figure   {
2075                 $$ = $1;
2076         }
2077         | br_bass_figure ']' {
2078                 $$ = $1;
2079                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2080         }
2081         ;
2082
2083 figure_list:
2084         /**/            {
2085                 $$ = SCM_EOL;
2086         }
2087         | figure_list br_bass_figure {
2088                 $$ = scm_cons ($2, $1);
2089         }
2090         ;
2091
2092 figure_spec:
2093         FIGURE_OPEN figure_list FIGURE_CLOSE {
2094                 Music *m = MY_MAKE_MUSIC ("EventChord");
2095                 $2 = scm_reverse_x ($2, SCM_EOL);
2096                 m->set_property ("elements", $2);
2097                 $$ = m->self_scm ();
2098         }
2099         ;
2100
2101
2102 optional_rest:
2103         /**/   { $$ = 0; }
2104         | REST { $$ = 1; }
2105         ;
2106
2107 simple_element:
2108         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2109
2110                 Input i = THIS->pop_spot ();
2111                 if (!THIS->lexer_->is_note_state ())
2112                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2113
2114                 Music *n = 0;
2115                 if ($6)
2116                         n = MY_MAKE_MUSIC ("RestEvent");
2117                 else
2118                         n = MY_MAKE_MUSIC ("NoteEvent");
2119
2120                 n->set_property ("pitch", $1);
2121                 n->set_property ("duration", $5);
2122
2123                 if (scm_is_number ($4))
2124                 {
2125                         int q = scm_to_int ($4);
2126                         n->set_property ("absolute-octave", scm_int2num (q-1));
2127                 }
2128
2129                 if ($3 % 2)
2130                         n->set_property ("cautionary", SCM_BOOL_T);
2131                 if ($2 % 2 || $3 % 2)
2132                         n->set_property ("force-accidental", SCM_BOOL_T);
2133
2134                 Music *v = MY_MAKE_MUSIC ("EventChord");
2135                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2136                 scm_gc_unprotect_object (n->self_scm ());
2137
2138                 v->set_spot (i);
2139                 n->set_spot (i);
2140                 $$ = v;
2141         }
2142         | DRUM_PITCH optional_notemode_duration {
2143                 Input i = THIS->pop_spot ();
2144
2145                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2146                 n->set_property ("duration", $2);
2147                 n->set_property ("drum-type", $1);
2148
2149                 Music *v = MY_MAKE_MUSIC ("EventChord");
2150                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2151                 scm_gc_unprotect_object (n->self_scm ());
2152                 v->set_spot (i);
2153                 n->set_spot (i);
2154                 $$ = v;
2155
2156         }
2157         | figure_spec optional_notemode_duration {
2158                 Music *m = unsmob_music ($1);
2159                 Input i = THIS->pop_spot ();
2160                 m->set_spot (i);
2161                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2162                 {
2163                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2164                 }
2165                 $$ = m;
2166         }
2167         | RESTNAME optional_notemode_duration           {
2168
2169                 Input i = THIS->pop_spot ();
2170                 Music *ev = 0;
2171                 if (ly_scm2string ($1) == "s") {
2172                         /* Space */
2173                         ev = MY_MAKE_MUSIC ("SkipEvent");
2174                   }
2175                 else {
2176                         ev = MY_MAKE_MUSIC ("RestEvent");
2177
2178                     }
2179                 ev->set_property ("duration", $2);
2180                 ev->set_spot (i);
2181                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2182                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2183                 velt->set_spot (i);
2184
2185                 scm_gc_unprotect_object (ev->self_scm ());
2186
2187                 $$ = velt;
2188         }
2189         | MULTI_MEASURE_REST optional_notemode_duration         {
2190                 THIS->pop_spot ();
2191
2192                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2193                 SCM mus = scm_call_2 (proc, $2,
2194                         make_input (THIS->here_input ()));
2195                 scm_gc_protect_object (mus);
2196                 $$ = unsmob_music (mus);
2197         }
2198
2199         | lyric_element optional_notemode_duration      {
2200                 Input i = THIS->pop_spot ();
2201                 if (!THIS->lexer_->is_lyric_state ())
2202                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2203
2204                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2205                 lreq->set_property ("text", $1);
2206                 lreq->set_property ("duration",$2);
2207                 lreq->set_spot (i);
2208                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2209                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2210
2211                 $$= velt;
2212         }
2213         | new_chord {
2214                 THIS->pop_spot ();
2215
2216                 if (!THIS->lexer_->is_chord_state ())
2217                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2218                 $$ = unsmob_music ($1);
2219         }
2220         ;
2221
2222 lyric_element:
2223         /* FIXME: lyric flavoured markup would be better */
2224         full_markup {
2225                 $$ = $1;
2226         }
2227         | LYRICS_STRING {
2228                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2229         }
2230         ;
2231
2232 new_chord:
2233         steno_tonic_pitch optional_notemode_duration   {
2234                 $$ = make_chord ($1, $2, SCM_EOL);
2235         }
2236         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2237                 SCM its = scm_reverse_x ($4, SCM_EOL);
2238                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2239         }
2240         ;
2241
2242 chord_items:
2243         /**/ {
2244                 $$ = SCM_EOL;
2245         }
2246         | chord_items chord_item {
2247                 $$ = scm_cons ($2, $$);
2248         }
2249         ;
2250
2251 chord_separator:
2252         CHORD_COLON {
2253                 $$ = ly_symbol2scm ("chord-colon");
2254         }
2255         | CHORD_CARET {
2256                 $$ = ly_symbol2scm ("chord-caret");
2257         }
2258         | CHORD_SLASH steno_tonic_pitch {
2259                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2260         }
2261         | CHORD_BASS steno_tonic_pitch {
2262                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2263         }
2264         ;
2265
2266 chord_item:
2267         chord_separator {
2268                 $$ = $1;
2269         }
2270         | step_numbers {
2271                 $$ = scm_reverse_x ($1, SCM_EOL);
2272         }
2273         | CHORD_MODIFIER  {
2274                 $$ = $1;
2275         }
2276         ;
2277
2278 step_numbers:
2279         step_number { $$ = scm_cons ($1, SCM_EOL); }
2280         | step_numbers '.' step_number {
2281                 $$ = scm_cons ($3, $$);
2282         }
2283         ;
2284
2285 step_number:
2286         bare_unsigned {
2287                 $$ = make_chord_step ($1, 0);
2288         }
2289         | bare_unsigned '+' {
2290                 $$ = make_chord_step ($1, SHARP);
2291         }
2292         | bare_unsigned CHORD_MINUS {
2293                 $$ = make_chord_step ($1, FLAT);
2294         }
2295         ;
2296
2297 /*
2298         UTILITIES
2299
2300 TODO: should deprecate in favor of Scheme?
2301
2302  */
2303 number_expression:
2304         number_expression '+' number_term {
2305                 $$ = scm_sum ($1, $3);
2306         }
2307         | number_expression '-' number_term {
2308                 $$ = scm_difference ($1, $3);
2309         }
2310         | number_term
2311         ;
2312
2313 number_term:
2314         number_factor {
2315                 $$ = $1;
2316         }
2317         | number_factor '*' number_factor {
2318                 $$ = scm_product ($1, $3);
2319         }
2320         | number_factor '/' number_factor {
2321                 $$ = scm_divide ($1, $3);
2322         }
2323         ;
2324
2325 number_factor:
2326         '-'  number_factor { /* %prec UNARY_MINUS */
2327                 $$ = scm_difference ($2, SCM_UNDEFINED);
2328         }
2329         | bare_number
2330         ;
2331
2332
2333 bare_number:
2334         UNSIGNED        {
2335                 $$ = scm_int2num ($1);
2336         }
2337         | REAL          {
2338                 $$ = $1;
2339         }
2340         | NUMBER_IDENTIFIER             {
2341                 $$ = $1;
2342         }
2343         | REAL NUMBER_IDENTIFIER        {
2344                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2345         }
2346         | UNSIGNED NUMBER_IDENTIFIER    {
2347                 $$ = scm_make_real ($1 *scm_to_double ($2));
2348         }
2349         ;
2350
2351
2352 bare_unsigned:
2353         UNSIGNED {
2354                         $$ = $1;
2355         }
2356         | DIGIT {
2357                 $$ = $1;
2358         }
2359         ;
2360
2361 bare_int:
2362         bare_number {
2363                 if (scm_integer_p ($1) == SCM_BOOL_T)
2364                 {
2365                         int k = scm_to_int ($1);
2366                         $$ = k;
2367                 } else
2368                 {
2369                         THIS->parser_error (_ ("need integer number arg"));
2370                         $$ = 0;
2371                 }
2372         }
2373         | '-' bare_int {
2374                 $$ = -$2;
2375         }
2376         ;
2377
2378 exclamations:
2379                 { $$ = 0; }
2380         | exclamations '!'      { $$ ++; }
2381         ;
2382
2383 questions:
2384                 { $$ = 0; }
2385         | questions '?' { $$ ++; }
2386         ;
2387
2388
2389
2390 full_markup:
2391         MARKUP_IDENTIFIER {
2392                 $$ = $1;
2393         }
2394         | MARKUP
2395                 { THIS->lexer_->push_markup_state (); }
2396         markup
2397                 { $$ = $3;
2398                   THIS->lexer_->pop_state ();
2399                 }
2400         ;
2401
2402
2403 /*
2404 This should be done more dynamically if possible.
2405 */
2406 markup:
2407         STRING {
2408                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2409         }
2410         | MARKUP_HEAD_EMPTY {
2411                 $$ = scm_list_1 ($1);
2412         }
2413         | MARKUP_HEAD_MARKUP0 markup {
2414                 $$ = scm_list_2 ($1, $2);
2415         }
2416         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2417                 $$ = scm_list_3 ($1, $2, $3);
2418         }
2419         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2420                 $$ = scm_list_3 ($1, $2, $3);
2421         }
2422         | markup_line {
2423                 $$ = $1;
2424         }
2425         | MARKUP_HEAD_LIST0 markup_list {
2426                 $$ = scm_list_2 ($1,$2);
2427         }
2428         | MARKUP_HEAD_SCM0 embedded_scm {
2429                 $$ = scm_list_2 ($1, $2);
2430         }
2431         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2432                 $$ = scm_list_4 ($1, $2, $3, $4);
2433         }
2434         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2435                 $$ = scm_list_4 ($1, $2, $3, $4);
2436         }
2437         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2438                 $$ = scm_list_3 ($1, $2, $3);
2439         }
2440         | MARKUP_IDENTIFIER {
2441                 $$ = $1;
2442         }
2443         | STRING_IDENTIFIER {
2444                 $$ = $1;
2445         }
2446         | SCORE {
2447                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2448                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2449         } '{' score_body '}' {
2450                 Score * sc = $4;
2451                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2452                 scm_gc_unprotect_object (sc->self_scm ());
2453                 THIS->lexer_->pop_state ();
2454         }
2455         ;
2456
2457 markup_list:
2458         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2459         ;
2460
2461 markup_line:
2462         '{' markup_list_body '}' {
2463                 SCM line = ly_scheme_function ("line-markup");
2464
2465                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2466         }
2467         ;
2468
2469 markup_list_body:
2470         /**/ {  $$ = SCM_EOL; }
2471         | markup_list_body markup {
2472                 $$ = scm_cons ($2, $1);
2473         }
2474         ;
2475
2476
2477 %%
2478
2479 void
2480 Lily_parser::set_yydebug (bool )
2481 {
2482 #if 0
2483         yydebug = 1;
2484 #endif
2485 }
2486
2487 void
2488 Lily_parser::do_yyparse ()
2489 {
2490         yyparse ((void*)this);
2491 }
2492
2493
2494 /*
2495 Should make this optional?    It will also complain when you do
2496
2497         [s4]
2498
2499 which is entirely legitimate.
2500
2501 Or we can scrap it. Barchecks should detect wrong durations, and
2502 skipTypesetting speeds it up a lot.
2503 */
2504
2505 void
2506 Lily_parser::beam_check (SCM dur)
2507 {
2508   Duration *d = unsmob_duration (dur);
2509   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2510     {
2511       Music *m = unsmob_music (last_beam_start_);
2512       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2513     }
2514   last_beam_start_ = SCM_EOL;
2515 }
2516
2517
2518
2519
2520 /*
2521
2522 It is a little strange to have this function in this file, but
2523 otherwise, we have to import music classes into the lexer.
2524
2525 */
2526 int
2527 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2528 {
2529         if (scm_is_string (sid)) {
2530                 *destination = sid;
2531                 return STRING_IDENTIFIER;
2532         } else if (scm_is_number (sid)) {
2533                 *destination = sid;
2534                 return NUMBER_IDENTIFIER;
2535         } else if (unsmob_context_def (sid)) {
2536                 *destination = unsmob_context_def (sid)->clone_scm ();
2537                 return CONTEXT_DEF_IDENTIFIER;
2538         } else if (unsmob_score (sid)) {
2539                 Score *score = new Score (*unsmob_score (sid));
2540                 *destination = score->self_scm ();
2541                 return SCORE_IDENTIFIER;
2542         } else if (Music *mus = unsmob_music (sid)) {
2543                 mus = mus->clone ();
2544                 *destination = mus->self_scm ();
2545                 unsmob_music (*destination)->
2546                         set_property ("origin", make_input (last_input_));
2547                 return dynamic_cast<Event*> (mus)
2548                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2549         } else if (unsmob_duration (sid)) {
2550                 *destination = unsmob_duration (sid)->smobbed_copy ();
2551                 return DURATION_IDENTIFIER;
2552         } else if (unsmob_output_def (sid)) {
2553                 Output_def *p = unsmob_output_def (sid);
2554                 p = p->clone ();
2555
2556                 *destination = p->self_scm ();
2557                 return OUTPUT_DEF_IDENTIFIER;
2558         } else if (Text_item::markup_p (sid)) {
2559                 *destination = sid;
2560                 return MARKUP_IDENTIFIER;
2561         }
2562
2563         return -1;
2564 }
2565
2566 Music *
2567 property_op_to_music (SCM op)
2568 {
2569         Music *m = 0;
2570         SCM tag = ly_car (op);
2571         SCM symbol = ly_cadr (op);
2572         SCM args = ly_cddr (op);
2573         SCM grob_val = SCM_UNDEFINED;
2574         SCM grob_sym = SCM_UNDEFINED;
2575         SCM val = SCM_UNDEFINED;
2576
2577         if (tag == ly_symbol2scm ("assign"))
2578                 {
2579                 m = MY_MAKE_MUSIC ("PropertySet");
2580                 val = ly_car (args);
2581                 }
2582         else if (tag == ly_symbol2scm ("unset"))
2583                 m = MY_MAKE_MUSIC ("PropertyUnset");
2584         else if (tag == ly_symbol2scm ("poppush")
2585                  || tag == ly_symbol2scm ("push"))
2586                 {
2587                 m = MY_MAKE_MUSIC ("OverrideProperty");
2588                 grob_sym = ly_car (args);
2589                 grob_val = ly_cadr (args);
2590                 }
2591         else if (tag == ly_symbol2scm ("pop")) {
2592                 m = MY_MAKE_MUSIC ("RevertProperty");
2593                 grob_sym = ly_car (args);
2594                 }
2595
2596         m->set_property ("symbol", symbol);
2597
2598         if (val != SCM_UNDEFINED)
2599                 m->set_property ("value", val);
2600         if (grob_val != SCM_UNDEFINED)
2601                 m->set_property ("grob-value", grob_val);
2602
2603         if (grob_sym != SCM_UNDEFINED)
2604                 {
2605                 bool itc = internal_type_checking_global_b;
2606                 /* UGH.
2607                 */
2608                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2609                 if (autobeam)
2610                         internal_type_checking_global_b = false;
2611                 m->set_property ("grob-property", grob_sym);
2612                 if (autobeam)
2613                         internal_type_checking_global_b = itc;
2614                 }
2615
2616         if (tag == ly_symbol2scm ("poppush"))
2617                 m->set_property ("pop-first", SCM_BOOL_T);
2618
2619
2620         return m;
2621 }
2622
2623 Music*
2624 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2625 {
2626         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2627
2628         csm->set_property ("element", m->self_scm ());
2629         scm_gc_unprotect_object (m->self_scm ());
2630
2631         csm->set_property ("context-type",
2632                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2633         csm->set_property ("property-operations", ops);
2634
2635         if (scm_is_string (id))
2636                 csm->set_property ("context-id", id);
2637         return csm;
2638 }
2639
2640 /*
2641 FIXME: this should be postponed until the music hits \Score
2642 */
2643 SCM
2644 get_next_unique_context ()
2645 {
2646         static int new_context_count;
2647         char s[1024];
2648         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2649         return scm_makfrom0str (s);
2650 }
2651