lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "ly-module.hh"
  38 #include "main.hh"
  39 #include "midi-def.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "paper-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Music_output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDLYRICS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token APPLY
 251 %token APPLYCONTEXT
 252 %token APPLYOUTPUT
 253 %token AUTOCHANGE
 254 %token BAR
 255 %token BOOK
 256 %token BREATHE
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONSISTSEND
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 272 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 273 %token GRACE
 274 %token ACCIACCATURA
 275 %token APPOGGIATURA
 276 %token GROBDESCRIPTIONS
 277 %token HEADER
 278 %token HYPHEN
 279 %token INVALID
 280 %token KEY
 281 %token LYRICS
 282 %token LYRICS_STRING
 283 %token MARK
 284 %token MIDI
 285 %token MULTI_MEASURE_REST
 286 %token NAME
 287 %token NEWCONTEXT
 288 %token NOTES
 289 %token OCTAVE
 290 %token ONCE
 291 %token OVERRIDE SET REVERT
 292 %token PAPER
 293 %token PARTCOMBINE
 294 %token PARTIAL
 295 %token QUOTE
 296 %token RELATIVE
 297 %token REMOVE
 298 %token REPEAT
 299 %token REST
 300 %token SCM_T
 301 %token SCORE
 302 %token SEQUENTIAL
 303 %token NEWLYRICS
 304 %token SIMULTANEOUS
 305 %token SKIP
 306 %token SPANREQUEST
 307 %token TAG
 308 %token TEMPO
 309 %token TIMES
 310 %token TIME_T
 311 %token TRANSPOSE
 312 %token TRANSPOSITION
 313 %token TYPE
 314 %token UNSET
 315 %token WITH
 316
 317 /* escaped */
 318 /* FIXME: this sucks.  The user will get to see these names:
 319     syntax error, unexpected E_CHAR:
 320                 \
 321                  %%
 322   */
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token <i> E_UNSIGNED
 327 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 328 %token FIGURE_SPACE
 329
 330 %token <i>      DIGIT
 331 %token <scm>    NOTENAME_PITCH
 332 %token <scm>    TONICNAME_PITCH
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DURATION_IDENTIFIER
 335 %token <scm>    FRACTION
 336 %token <id>     IDENTIFIER
 337 %token DRUMS
 338 %token <scm>    DRUM_PITCH
 339 %token <scm>    CHORD_MODIFIER
 340 %token <scm>    SCORE_IDENTIFIER
 341 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 342 %token <scm>    NUMBER_IDENTIFIER
 343 %token <scm>    EVENT_IDENTIFIER
 344 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 345 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 346 %token <scm>    RESTNAME
 347 %token <scm>    STRING
 348 %token <scm>    SCM_T
 349 %token <i>      UNSIGNED
 350 %token <scm>   REAL
 351
 352 %token MARKUP
 353 %token <scm> MARKUP_HEAD_MARKUP0
 354 %token <scm> MARKUP_HEAD_EMPTY
 355 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0
 357 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1
 359 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 360 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 361
 362 %token <scm> MUSIC_HEAD_SCM
 363 %token <scm> MUSIC_HEAD_MUSIC
 364 %token <scm> MUSIC_HEAD_SCM_MUSIC
 365 %token <scm> MUSIC_HEAD_MUSIC_MUSIC
 366 %token <scm> MUSIC_HEAD_SCM_SCM_MUSIC
 367 %token <scm> MUSIC_HEAD_SCM_MUSIC_MUSIC
 368
 369 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 370 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 371
 372 %type <book>    book_block book_body
 373 %type <i>       exclamations questions dots optional_rest
 374 %type <i>        bass_mod
 375 %type <scm>     grace_head
 376 %type <scm>     oct_check
 377 %type <scm>     context_mod_list
 378 %type <scm>     lyric_element
 379 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 380 %type <scm>     new_lyrics
 381 %type <outputdef> output_def
 382 %type <scm>     lilypond_header lilypond_header_body
 383 %type <music>   open_event close_event
 384 %type <i>       sub_quotes sup_quotes
 385 %type <music>   toplevel_music
 386 %type <music>   simple_element event_chord command_element
 387 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 388 %type <music>   Grouped_music_list
 389 %type <music>   Repeated_music
 390 %type <scm>     Alternative_music
 391 %type <i>       tremolo_type
 392 %type <i>       bare_int  bare_unsigned
 393 %type <i>       script_dir
 394 %type <scm>     identifier_init
 395 %type <scm>     simple_string
 396
 397 %type <music>   note_chord_element chord_body chord_body_element
 398 %type <scm>     chord_body_elements
 399 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 400
 401 %type <scm>     post_events
 402 %type <music>   gen_text_def direction_less_event direction_reqd_event
 403 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 404 %type <scm>     steno_tonic_pitch
 405 %type <scm>     duration_length fraction
 406
 407 %type <scm>     chord_item chord_items chord_separator new_chord
 408 %type <scm>     step_number step_numbers
 409
 410 %type <scm>     embedded_scm scalar
 411 %type <music>   Music Sequential_music Simultaneous_music
 412 %type <music>   relative_music re_rhythmed_music
 413 %type <music>   music_property_def context_change
 414 %type <scm>     context_prop_spec
 415 %type <scm>     Music_list
 416 %type <scm>     property_operation
 417 %type <scm>     context_mod context_def_mod optional_context_mod
 418 %type <outputdef>       music_output_def_body music_output_def_head
 419 %type <music>   post_event tagged_post_event
 420 %type <music>   command_req
 421 %type <music>   string_number_event
 422 %type <scm>     string bare_number number_expression number_term number_factor
 423 %type <score>   score_block score_body
 424
 425 %type <scm>     context_def_spec_block context_def_spec_body
 426 %type <music>   tempo_event
 427 %type <scm>     script_abbreviation
 428
 429
 430
 431 %left '-' '+'
 432
 433 /* We don't assign precedence to / and *, because we might need varied
 434 prec levels in different prods */
 435
 436 %left UNARY_MINUS
 437
 438 %%
 439
 440 lilypond:       /* empty */
 441         | lilypond toplevel_expression {
 442         }
 443         | lilypond assignment {
 444         }
 445         | lilypond error {
 446                 THIS->error_level_ = 1;
 447         }
 448         | lilypond INVALID      {
 449                 THIS->error_level_ = 1;
 450         }
 451         ;
 452
 453 toplevel_expression:
 454         lilypond_header {
 455                 THIS->header_ = $1;
 456         }
 457         | add_quote {
 458
 459         }
 460         | book_block {
 461                 Book *book = $1;
 462                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 463                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 464                 scm_gc_unprotect_object (book->self_scm ());
 465         }
 466         | score_block {
 467                 Score *score = $1;
 468
 469                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 470                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 471                 scm_gc_unprotect_object (score->self_scm ());
 472         }
 473         | toplevel_music {
 474                 Music *music = $1;
 475                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 476                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 477                 scm_gc_unprotect_object (music->self_scm ());
 478         }
 479         | output_def {
 480                 SCM id = SCM_EOL;
 481                 if (dynamic_cast<Paper_def*> ($1))
 482                         id = scm_makfrom0str ("$defaultpaper");
 483                 else if (dynamic_cast<Midi_def*> ($1))
 484                         id = scm_makfrom0str ("$defaultmidi");
 485                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 486                 scm_gc_unprotect_object ($1->self_scm ());
 487         }
 488         ;
 489
 490 toplevel_music:
 491         Composite_music {
 492         }
 493         ;
 494
 495 embedded_scm:
 496         SCM_T
 497         | SCM_IDENTIFIER
 498         ;
 499
 500
 501 lilypond_header_body:
 502         {
 503                 $$ = ly_make_anonymous_module ();
 504                 THIS->lexer_->add_scope ($$);
 505         }
 506         | lilypond_header_body assignment  {
 507
 508         }
 509         ;
 510
 511 lilypond_header:
 512         HEADER '{' lilypond_header_body '}'     {
 513                 $$ = THIS->lexer_->remove_scope ();
 514         }
 515         ;
 516
 517
 518 /*
 519         DECLARATIONS
 520 */
 521 assignment:
 522         STRING {
 523                 THIS->push_spot ();
 524         }
 525         /* cont */ '=' identifier_init  {
 526
 527         /*
 528                 Should find generic way of associating input with objects.
 529         */
 530                 Input ip = THIS->pop_spot ();
 531
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $4);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | full_markup {
 557                 $$ = $1;
 558         }
 559         | output_def {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | context_def_spec_block {
 564                 $$ = $1;
 565         }
 566         | Music  {
 567                 $$ = $1->self_scm ();
 568                 scm_gc_unprotect_object ($$);
 569         }
 570         | post_event {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | number_expression {
 575                 $$ = $1;
 576         }
 577         | string {
 578                 $$ = $1;
 579         }
 580         | embedded_scm  {
 581                 $$ = $1;
 582         }
 583         ;
 584
 585 context_def_spec_block:
 586         CONTEXT '{' context_def_spec_body '}'
 587                 {
 588                 $$ = $3;
 589         }
 590         ;
 591
 592 context_def_spec_body:
 593         /**/ {
 594                 $$ = Context_def::make_scm ();
 595                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 596         }
 597         | CONTEXT_DEF_IDENTIFIER {
 598                 $$ = $1;
 599                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 600         }
 601         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 602                 Context_def*td = unsmob_context_def ($$);
 603
 604                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 605                         SCM tag = ly_caar (p);
 606
 607                         /* TODO: should make new tag "grob-definition" ? */
 608                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 609                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 610                 }
 611         }
 612         | context_def_spec_body context_mod {
 613                 unsmob_context_def ($$)->add_context_mod ($2);
 614         }
 615         ;
 616
 617 book_block:
 618         BOOK {
 619                 THIS->push_spot ();
 620         }
 621         /*cont*/ '{' book_body '}'      {
 622                 THIS->pop_spot ();
 623                 $$ = $4;
 624         }
 625         ;
 626
 627 book_body:
 628         {
 629                 $$ = new Book;
 630                 $$->set_spot (THIS->here_input ());
 631         }
 632         | book_body score_block {
 633                 $$->scores_.push ($2);
 634                 scm_gc_unprotect_object ($2->self_scm ());
 635         }
 636         | book_body error {
 637         }
 638         ;
 639
 640 score_block:
 641         SCORE {
 642                 THIS->push_spot ();
 643         }
 644         /*cont*/ '{' score_body '}'     {
 645                 THIS->pop_spot ();
 646                 $$ = $4;
 647         }
 648         ;
 649
 650 score_body:
 651         Music   {
 652                 $$ = new Score;
 653
 654                 $$->set_spot (THIS->here_input ());
 655                 SCM m = $1->self_scm ();
 656                 scm_gc_unprotect_object (m);
 657
 658                 /*
 659                         guh.
 660                 */
 661                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 662                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 663                         m = scm_call_1 (ly_car (check_funcs), m);
 664                 $$->music_ = m;
 665
 666         }
 667         | SCORE_IDENTIFIER {
 668                 $$ = new Score ( *unsmob_score ($1));
 669                 $$->set_spot (THIS->here_input ());
 670         }
 671         | score_body lilypond_header    {
 672                 $$->header_ = $2;
 673         }
 674         | score_body output_def {
 675                 $$->defs_.push ($2);
 676                 scm_gc_unprotect_object ($2->self_scm ());
 677         }
 678         | score_body error {
 679
 680         }
 681         ;
 682
 683
 684 /*
 685         MIDI
 686 */
 687 output_def:
 688         music_output_def_body '}' {
 689                 $$ = $1;
 690                 THIS->lexer_->remove_scope ();
 691                 THIS->lexer_->pop_state ();
 692         }
 693         ;
 694
 695 music_output_def_head:
 696         MIDI    {
 697                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 698
 699
 700                 Midi_def *p = 0;
 701                 if (id)
 702                         p = dynamic_cast<Midi_def*> (id->clone ());
 703                 else
 704                         p = new Midi_def;
 705
 706                 $$ = p;
 707                 THIS->lexer_->add_scope (p->scope_);
 708         }
 709         | PAPER         {
 710                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 711                   Paper_def *p = 0;
 712                 if (id)
 713                         p = dynamic_cast<Paper_def*> (id->clone ());
 714                 else
 715                         p = new Paper_def;
 716
 717                 THIS->lexer_->add_scope (p->scope_);
 718                 $$ = p;
 719         }
 720         ;
 721
 722
 723 music_output_def_body:
 724         music_output_def_head '{' {
 725                 $$ = $1;
 726                 $$->input_origin_. set_spot (THIS->here_input ());
 727                 THIS->lexer_->push_initial_state ();
 728         }
 729         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 730                 scm_gc_unprotect_object ($1->self_scm ());
 731                 Music_output_def *o = unsmob_music_output_def ($3);
 732                 o->input_origin_.set_spot (THIS->here_input ());
 733                 $$ = o;
 734                 THIS->lexer_->remove_scope ();
 735                 THIS->lexer_->add_scope (o->scope_);
 736                 THIS->lexer_->push_initial_state ();
 737         }
 738         | music_output_def_body assignment  {
 739
 740         }
 741         | music_output_def_body context_def_spec_block  {
 742                 $$->assign_context_def ($2);
 743         }
 744         | music_output_def_body tempo_event  {
 745                 /*
 746                         junk this ? there already is tempo stuff in
 747                         music.
 748                 */
 749                 int m = ly_scm2int ( $2->get_property ("metronome-count"));
 750                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 751                 Midi_def *md = dynamic_cast<Midi_def*> ($$);
 752                 if (md)
 753                         md->set_tempo (d->get_length (), m);
 754                 scm_gc_unprotect_object ($2->self_scm ());
 755         }
 756         | music_output_def_body error {
 757
 758         }
 759         ;
 760
 761 tempo_event:
 762         TEMPO steno_duration '=' bare_unsigned  {
 763                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 764                 $$->set_property ("tempo-unit", $2);
 765                 $$->set_property ("metronome-count", scm_int2num ( $4));
 766         }
 767         ;
 768
 769 /*
 770 The representation of a  list is the
 771
 772   (LIST . LAST-CONS)
 773
 774  to have  efficient append.
 775 */
 776 Music_list:
 777         /* empty */ {
 778                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 779         }
 780         | Music_list Music {
 781                 SCM s = $$;
 782                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 783                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 784                 if (ly_c_pair_p (ly_cdr (s)))
 785                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 786                 else
 787                         scm_set_car_x (s, c); /* set first cons */
 788                 scm_set_cdr_x (s, c);  /* remember last cell */
 789         }
 790         | Music_list embedded_scm {
 791         }
 792         | Music_list error {
 793         }
 794         ;
 795
 796
 797 Music:
 798         Simple_music
 799         | Composite_music
 800         ;
 801
 802 Alternative_music:
 803         /* empty */ {
 804                 $$ = SCM_EOL;
 805         }
 806         | ALTERNATIVE '{' Music_list '}' {
 807                 $$ = $3;
 808         }
 809         ;
 810
 811
 812 Repeated_music:
 813         REPEAT simple_string bare_unsigned Music Alternative_music
 814         {
 815                 Music *beg = $4;
 816                 int times = $3;
 817                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 818                 if (times < scm_ilength (alts)) {
 819                   unsmob_music (ly_car (alts))
 820                     ->origin ()->warning (
 821                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 822                   alts = ly_truncate_list (times, alts);
 823                 }
 824
 825
 826                 SCM proc = ly_scheme_function ("make-repeated-music");
 827
 828                 SCM mus = scm_call_1 (proc, $2);
 829                 scm_gc_protect_object (mus); // UGH.
 830                 Music *r = unsmob_music (mus);
 831                 if (beg)
 832                         {
 833                         r-> set_property ("element", beg->self_scm ());
 834                         scm_gc_unprotect_object (beg->self_scm ());
 835                         }
 836                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 837
 838                 r-> set_property ("elements",alts);
 839                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 840                         /*
 841                         TODO: move this code to Scheme.
 842                         */
 843
 844                         /*
 845                         we can not get durations and other stuff correct down the line, so we have to
 846                         add to the duration log here.
 847                         */
 848                         SCM func = ly_scheme_function ("shift-duration-log");
 849
 850                         int dots = ($3 % 3) ? 0 : 1;
 851                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 852
 853                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 854
 855                         if (seq) {
 856                                 int list_len = scm_ilength (seq->music_list ());
 857                                 if (list_len != 2)
 858                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 859                                 shift -= 1;
 860                                 r->compress (Moment (Rational (1, list_len)));
 861                                 }
 862                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 863
 864                 }
 865                 r->set_spot (*$4->origin ());
 866
 867                 $$ = r;
 868         }
 869         ;
 870
 871 Sequential_music:
 872         SEQUENTIAL '{' Music_list '}'           {
 873                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 874                 $$->set_property ("elements", ly_car ($3));
 875                 $$->set_spot (THIS->here_input ());
 876         }
 877         | '{' Music_list '}'            {
 878                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 879                 $$->set_property ("elements", ly_car ($2));
 880                 $$->set_spot (THIS->here_input ());
 881         }
 882         ;
 883
 884 Simultaneous_music:
 885         SIMULTANEOUS '{' Music_list '}'{
 886                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 887                 $$->set_property ("elements", ly_car ($3));
 888                 $$->set_spot (THIS->here_input ());
 889
 890         }
 891         | simul_open Music_list simul_close     {
 892                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 893                 $$->set_property ("elements", ly_car ($2));
 894                 $$->set_spot (THIS->here_input ());
 895         }
 896         ;
 897
 898 Simple_music:
 899         event_chord             { $$ = $1; }
 900         | APPLYOUTPUT embedded_scm {
 901                 if (!ly_input_procedure_p ($2))
 902                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 903                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 904                 $$->set_property ("procedure", $2);
 905                 $$->set_spot (THIS->here_input ());
 906         }
 907         | APPLYCONTEXT embedded_scm {
 908                 if (!ly_input_procedure_p ($2))
 909                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 910                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 911                 $$->set_property ("procedure", $2);
 912                 $$->set_spot (THIS->here_input ());
 913         }
 914         | MUSIC_IDENTIFIER {
 915                 $$ = unsmob_music ($1);
 916         }
 917         | music_property_def
 918         | context_change
 919         ;
 920
 921
 922 optional_context_mod:
 923         /**/ { $$ = SCM_EOL; }
 924         | WITH { THIS->lexer_->push_initial_state (); }
 925         '{' context_mod_list '}'
 926         {
 927                 THIS->lexer_->pop_state ();
 928                 $$ = $4;
 929         }
 930         ;
 931
 932 grace_head:
 933         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 934         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 935         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 936         ;
 937
 938 context_mod_list:
 939         /* */  { $$ = SCM_EOL; }
 940         | context_mod_list context_mod  {
 941                  $$ = scm_cons ($2, $1);
 942         }
 943         ;
 944
 945
 946 Composite_music:
 947         Prefix_composite_music { $$ = $1; }
 948         | Grouped_music_list { $$ = $1; }
 949         ;
 950
 951 Grouped_music_list:
 952         Simultaneous_music              { $$ = $1; }
 953         | Sequential_music              { $$ = $1; }
 954         ;
 955
 956 Generic_prefix_music:
 957         MUSIC_HEAD_SCM { THIS->push_spot (); } embedded_scm {
 958                 SCM m = scm_call_2 ($1, make_input (THIS->pop_spot ()),
 959                         $3);
 960                 if (unsmob_music (m))
 961                 {       $$ = unsmob_music (m);
 962                         scm_gc_protect_object (m);
 963                 }
 964                 else
 965                 {
 966                         THIS->parser_error ("MUSIC_HEAD should return Music");
 967                         $$ = MY_MAKE_MUSIC("Music");
 968                 }
 969         }
 970         ;
 971
 972 Prefix_composite_music:
 973         Generic_prefix_music {
 974                 $$ = $1;
 975         }
 976         |AUTOCHANGE Music       {
 977                 SCM proc = ly_scheme_function ("make-autochange-music");
 978
 979                 SCM res = scm_call_1 (proc, $2->self_scm ());
 980                 scm_gc_unprotect_object ($2->self_scm ());
 981                 $$ = unsmob_music (res);
 982                 scm_gc_protect_object (res);
 983                 $$->set_spot (THIS->here_input ());
 984         }
 985         | PARTCOMBINE Music Music {
 986                 SCM proc = ly_scheme_function ("make-part-combine-music");
 987
 988                 SCM res = scm_call_1 (proc, scm_listify ($2->self_scm (),
 989                         $3->self_scm (), SCM_UNDEFINED));
 990                 scm_gc_unprotect_object ($3->self_scm ());
 991                 scm_gc_unprotect_object ($2->self_scm ());
 992                 $$ = unsmob_music (res);
 993                 scm_gc_protect_object (res);
 994                 $$->set_spot (THIS->here_input ());
 995         }
 996         | grace_head Music {
 997 #if 1
 998         /*
 999                 The other version is for easier debugging  of
1000                 Sequential_music_iterator in combination with grace notes.
1001         */
1002
1003 /*
1004
1005 TODO: should distinguish between both grace types in the
1006 basic music objects too, since the meaning is different.
1007
1008 */
1009
1010                 String start_str = "start" + ly_scm2string ($1) + "Music";
1011                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
1012
1013                 SCM start = THIS->lexer_->lookup_identifier (start_str);
1014                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
1015
1016                 Music *startm = unsmob_music (start);
1017                 Music *stopm = unsmob_music (stop);
1018
1019                 SCM ms = SCM_EOL;
1020                 if (stopm) {
1021                         stopm = stopm->clone ();
1022                         ms = scm_cons (stopm->self_scm (), ms);
1023                         scm_gc_unprotect_object (stopm->self_scm ());
1024                 }
1025                 ms = scm_cons ($2->self_scm (), ms);
1026                 scm_gc_unprotect_object ($2->self_scm ());
1027                 if (startm) {
1028                         startm = startm->clone ();
1029                         ms = scm_cons (startm->self_scm (), ms);
1030                         scm_gc_unprotect_object (startm->self_scm ());
1031                 }
1032
1033                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
1034                 seq->set_property ("elements", ms);
1035
1036
1037                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1038                 $$->set_property ("element", seq->self_scm ());
1039                 scm_gc_unprotect_object (seq->self_scm ());
1040 #else
1041                 $$ = MY_MAKE_MUSIC ("GraceMusic");
1042                 $$->set_property ("element", $2->self_scm ());
1043                 scm_gc_unprotect_object ($2->self_scm ());
1044 #endif
1045         }
1046         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1047                 $$ = context_spec_music ($2, $4, $6, $5);
1048
1049         }
1050         | CONTEXT simple_string optional_context_mod Music {
1051                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1052         }
1053         | NEWCONTEXT simple_string optional_context_mod Music {
1054                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1055                         $3);
1056         }
1057
1058         | TIMES {
1059                 THIS->push_spot ();
1060         }
1061         /* CONTINUED */
1062                 fraction Music
1063
1064         {
1065                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1066                 Music *mp = $4;
1067
1068                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1069                 $$->set_spot (THIS->pop_spot ());
1070
1071                 $$->set_property ("element", mp->self_scm ());
1072                 scm_gc_unprotect_object (mp->self_scm ());
1073                 $$->set_property ("numerator", scm_int2num (n));
1074                 $$->set_property ("denominator", scm_int2num (d));
1075                 $$->compress (Moment (Rational (n,d)));
1076
1077         }
1078         | Repeated_music                { $$ = $1; }
1079         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1080                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1081                 Music *p = $4;
1082                 Pitch from = *unsmob_pitch ($2);
1083                 Pitch to = *unsmob_pitch ($3);
1084
1085                 p->transpose (interval (from, to));
1086                 $$->set_property ("element", p->self_scm ());
1087                 scm_gc_unprotect_object (p->self_scm ());
1088         }
1089         | APPLY embedded_scm Music  {
1090                 if (!ly_input_procedure_p ($2))
1091                         {
1092                         THIS->parser_error (_ ("\\apply takes function argument"));
1093                         $$ = $3;
1094                         }
1095                 else
1096                         {
1097                         SCM ret = scm_call_1 ($2, $3->self_scm ());
1098                         Music *m = unsmob_music (ret);
1099                         if (!m) {
1100                                 THIS->parser_error ("\\apply must return a Music");
1101                                 m = MY_MAKE_MUSIC ("Music");
1102                                 }
1103                         $$ = m;
1104                         }
1105         }
1106         | NOTES
1107                 {
1108                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1109                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1110         }
1111         Music
1112                 { $$ = $3;
1113                   THIS->lexer_->pop_state ();
1114                 }
1115         | DRUMS
1116                 {
1117                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1118                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1119         }
1120         /* FIXME: This used to be: */
1121         Music
1122 /*      Grouped_music_list */
1123                 { $$ = $3;
1124                   THIS->lexer_->pop_state ();
1125                 }
1126         | FIGURES
1127                 { THIS->lexer_->push_figuredbass_state (); }
1128         /* FIXME: This used to be:
1129         Music
1130         but that breaks web build
1131         */
1132         Grouped_music_list
1133                 {
1134                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1135                   chm->set_property ("element", $3->self_scm ());
1136                   $$ = chm;
1137                   scm_gc_unprotect_object ($3->self_scm ());
1138
1139                   THIS->lexer_->pop_state ();
1140         }
1141         | CHORDS {
1142                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1143                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1144                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1145                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1146
1147         }
1148         /* FIXME:
1149         Music
1150 */
1151         Grouped_music_list
1152         {
1153                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1154                   chm->set_property ("element", $3->self_scm ());
1155                   scm_gc_unprotect_object ($3->self_scm ());
1156                   $$ = chm;
1157
1158                   THIS->lexer_->pop_state ();
1159         }
1160         | LYRICS
1161                 { THIS->lexer_->push_lyric_state (); }
1162         /* FIXME:
1163         Music
1164 */
1165         Grouped_music_list
1166                 {
1167                   $$ = $3;
1168                   THIS->lexer_->pop_state ();
1169         }
1170         | relative_music        { $$ = $1; }
1171         | re_rhythmed_music     { $$ = $1; }
1172         | TAG embedded_scm Music {
1173                 tag_music ($3, $2, THIS->here_input ());
1174                 $$ = $3;
1175         }
1176         ;
1177
1178 relative_music:
1179         RELATIVE absolute_pitch Music {
1180                 Music *m = $3;
1181                 Pitch start = *unsmob_pitch ($2);
1182                 $$ = make_music_relative (start, m);
1183                 scm_gc_unprotect_object (m->self_scm ());
1184         }
1185         | RELATIVE Composite_music {
1186                 Music *m = $2;
1187                 /* FIXME: why is octave==0 and default not middleC? */
1188                 Pitch middle_c (-1, 0, 0);
1189                 $$ = make_music_relative (middle_c, m);
1190                 scm_gc_unprotect_object (m->self_scm ());
1191         }
1192         ;
1193
1194 new_lyrics:
1195         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1196         /*cont */
1197         Grouped_music_list {
1198         /* Can also use Music at the expensive of two S/Rs similar to
1199            \repeat \alternative */
1200                 THIS->lexer_->pop_state ();
1201 #if 0
1202                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1203                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1204                 $$ = music;
1205 #else
1206                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1207 #endif
1208         }
1209         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1210         Grouped_music_list {
1211                 THIS->lexer_->pop_state ();
1212                 $$ = scm_cons ($4->self_scm (), $1);
1213         }
1214         ;
1215
1216 re_rhythmed_music:
1217         ADDLYRICS Music Music {
1218                 Music *m = MY_MAKE_MUSIC ("LyricCombineMusic");
1219                 m->set_property ("elements", scm_listify ($2->self_scm (),
1220                         $3->self_scm (), SCM_UNDEFINED));
1221                 scm_gc_unprotect_object ($3->self_scm ());
1222                 scm_gc_unprotect_object ($2->self_scm ());
1223                 $$ = m;
1224         }
1225         | Grouped_music_list new_lyrics {
1226
1227                 /* FIXME: should find out uniqueXXX name from music */
1228                 SCM name = $1->get_property ("context-id");
1229                 //if (name == SCM_EOL)
1230                 if (!ly_c_string_p (name))
1231                         name = scm_makfrom0str ("");
1232
1233                 SCM context = scm_makfrom0str ("Lyrics");
1234                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1235
1236                 SCM lst = SCM_EOL;
1237                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1238                 {
1239                         Music *music = unsmob_music (ly_car (s));
1240                         Music *com = make_lyric_combine_music (name, music);
1241                         Music *csm = context_spec_music (context,
1242                                 get_next_unique_context (), com, SCM_EOL);
1243                         lst = scm_cons (csm->self_scm (), lst);
1244                 }
1245                 /* FIXME: only first lyric music is accepted,
1246                           the rest is junked */
1247                 all->set_property ("elements", scm_cons ($1->self_scm (),
1248                         lst));
1249                 $$ = all;
1250                 scm_gc_unprotect_object ($1->self_scm ());
1251         }
1252         | LYRICSTO string Music {
1253                 Music *music = $3;
1254                 SCM name = $2;
1255                 $$ = make_lyric_combine_music (name, music);
1256                 scm_gc_unprotect_object (music->self_scm ());
1257         }
1258         ;
1259
1260 context_change:
1261         CHANGE STRING '=' STRING  {
1262                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1263                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1264                 t-> set_property ("change-to-id", $4);
1265
1266                 $$ = t;
1267                 $$->set_spot (THIS->here_input ());
1268         }
1269         ;
1270
1271 property_operation:
1272         STRING '=' scalar {
1273                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1274                         scm_string_to_symbol ($1), $3);
1275         }
1276         | UNSET simple_string {
1277                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1278                         scm_string_to_symbol ($2));
1279         }
1280         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1281                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1282                         scm_string_to_symbol ($2), $3, $5);
1283         }
1284         | REVERT simple_string embedded_scm {
1285                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1286                         scm_string_to_symbol ($2), $3);
1287         }
1288         ;
1289
1290 context_def_mod:
1291         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1292         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1293         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1294
1295         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1296         | DENIES { $$ = ly_symbol2scm ("denies"); }
1297
1298         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1299         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1300         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1301         | NAME { $$ = ly_symbol2scm ("context-name"); }
1302         ;
1303
1304 context_mod:
1305         property_operation { $$ = $1; }
1306         | context_def_mod STRING {
1307                 $$ = scm_list_2 ($1, $2);
1308         }
1309         ;
1310
1311 context_prop_spec:
1312         simple_string {
1313                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1314                         scm_string_to_symbol ($1));
1315         }
1316         | simple_string '.' simple_string {
1317                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1318                         scm_string_to_symbol ($3));
1319         }
1320         ;
1321
1322 music_property_def:
1323         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1324                 $$ = property_op_to_music (scm_list_4 (
1325                         ly_symbol2scm ("poppush"),
1326                         ly_cadr ($2),
1327                         $3, $5));
1328                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1329         }
1330         | REVERT context_prop_spec embedded_scm {
1331                 $$ = property_op_to_music (scm_list_3 (
1332                         ly_symbol2scm ("pop"),
1333                         ly_cadr ($2),
1334                         $3));
1335
1336                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1337         }
1338         | SET context_prop_spec '=' scalar {
1339                 $$ = property_op_to_music (scm_list_3 (
1340                         ly_symbol2scm ("assign"),
1341                         ly_cadr ($2),
1342                         $4));
1343                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1344         }
1345         | UNSET context_prop_spec {
1346                 $$ = property_op_to_music (scm_list_2 (
1347                         ly_symbol2scm ("unset"),
1348                         ly_cadr ($2)));
1349                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1350         }
1351         | ONCE music_property_def {
1352                 SCM e = $2->get_property ("element");
1353                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1354                 $$ = $2;
1355
1356         }
1357         ;
1358
1359
1360 string:
1361         STRING {
1362                 $$ = $1;
1363         }
1364         | STRING_IDENTIFIER {
1365                 $$ = $1;
1366         }
1367         | string '+' string {
1368                 $$ = scm_string_append (scm_list_2 ($1, $3));
1369         }
1370         ;
1371
1372 simple_string: STRING {
1373         }
1374         | LYRICS_STRING {
1375         }
1376         ;
1377
1378 scalar: string {
1379         }
1380         | LYRICS_STRING {
1381         }
1382         | bare_int {
1383                 $$ = scm_int2num ($1);
1384         }
1385         | embedded_scm {
1386         }
1387         | full_markup {
1388         }
1389         | DIGIT {
1390                 $$ = scm_int2num ($1);
1391         }
1392         ;
1393
1394 /*
1395 FIXME: remove or fix this comment.  What is `This'?
1396
1397 This is a trick:
1398
1399 Adding pre_events to the simple_element
1400 makes the choice between
1401
1402   string:  STRING
1403
1404 and
1405
1406   simple_element: STRING
1407
1408 a single shift/reduction conflict.
1409
1410 nevertheless, this is not very clean, and we should find a different
1411 solution.
1412
1413 */
1414 pre_events: {
1415                 THIS->push_spot ();
1416         }
1417         ;
1418
1419 event_chord:
1420         pre_events simple_element post_events   {
1421                 SCM elts = $2-> get_property ("elements");
1422
1423                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1424
1425                 $2->set_property ("elements", elts);
1426                 $$ = $2;
1427         }
1428         | command_element
1429         | note_chord_element
1430         ;
1431
1432
1433 note_chord_element:
1434         chord_body optional_notemode_duration post_events
1435         {
1436                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1437                 SCM es = $1->get_property ("elements");
1438                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1439
1440                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1441                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1442                 es = ly_append2 (es, postevs);
1443
1444                 $1-> set_property ("elements", es);
1445                 $$ = $1;
1446         }
1447         ;
1448
1449 chord_open: '<'
1450         ;
1451
1452 chord_close: '>'
1453         ;
1454
1455 simul_open: DOUBLE_ANGLE_OPEN
1456         ;
1457
1458 simul_close: DOUBLE_ANGLE_CLOSE
1459         ;
1460
1461 chord_body:
1462         chord_open chord_body_elements chord_close
1463         {
1464                 $$ = MY_MAKE_MUSIC ("EventChord");
1465                 $$->set_property ("elements",
1466                         scm_reverse_x ($2, SCM_EOL));
1467         }
1468         ;
1469
1470 chord_body_elements:
1471         /* empty */             { $$ = SCM_EOL; }
1472         | chord_body_elements chord_body_element {
1473                 $$ = scm_cons ($2->self_scm (), $1);
1474                 scm_gc_unprotect_object ($2->self_scm ());
1475         }
1476         ;
1477
1478 chord_body_element:
1479         pitch exclamations questions post_events
1480         {
1481                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1482                 n->set_property ("pitch", $1);
1483                 if ($3 % 2)
1484                         n->set_property ("cautionary", SCM_BOOL_T);
1485                 if ($2 % 2 || $3 % 2)
1486                         n->set_property ("force-accidental", SCM_BOOL_T);
1487
1488                 if (ly_c_pair_p ($4)) {
1489                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1490                         n->set_property ("articulations", arts);
1491                 }
1492                 $$ = n;
1493         }
1494         | DRUM_PITCH post_events {
1495                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1496                 n->set_property ("duration", $2);
1497                 n->set_property ("drum-type", $1);
1498                 n->set_spot (THIS->here_input ());
1499
1500                 if (ly_c_pair_p ($2)) {
1501                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1502                         n->set_property ("articulations", arts);
1503                 }
1504                 $$ = n;
1505         }
1506         ;
1507
1508 add_quote:
1509         ADDQUOTE string Music {
1510                 SCM adder = ly_scheme_function ("add-quotable");
1511
1512                 scm_call_2 (adder, $2, $3->self_scm ());
1513                 scm_gc_unprotect_object ($3->self_scm ());
1514         }
1515         ;
1516
1517 command_element:
1518         command_req {
1519                 $$ = MY_MAKE_MUSIC ("EventChord");
1520                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1521                 scm_gc_unprotect_object ($1->self_scm ());
1522
1523                 $$-> set_spot (THIS->here_input ());
1524                 $1-> set_spot (THIS->here_input ());
1525         }
1526         | SKIP duration_length {
1527                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1528                 skip->set_property ("duration", $2);
1529
1530                 $$ = skip;
1531         }
1532         | QUOTE STRING duration_length {
1533                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1534                 SCM evs = SCM_EOL;
1535                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1536                 {
1537                         SCM key = $2; // use symbol?
1538                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1539                 }
1540                 Music *quote = 0;
1541                 if (ly_c_vector_p (evs))
1542                 {
1543                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1544                         quote->set_property ("duration", $3);
1545                         quote->set_property ("quoted-events", evs);
1546                 } else {
1547                         THIS->here_input ().warning (_f ("Can\'t find music"));
1548                         quote = MY_MAKE_MUSIC ("Event");
1549                 }
1550                 quote->set_spot (THIS->here_input ());
1551                 $$ = quote;
1552         }
1553         | OCTAVE { THIS->push_spot (); }
1554           pitch {
1555                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1556                 $$ = m;
1557                 $$->set_spot (THIS->pop_spot ());
1558                 $$->set_property ("pitch", $3);
1559         }
1560         | E_LEFTSQUARE {
1561                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1562                 m->set_property ("span-direction", scm_int2num (START));
1563                 m->set_spot (THIS->here_input ());
1564
1565                 $$ = MY_MAKE_MUSIC ("EventChord");
1566                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1567                 scm_gc_unprotect_object (m->self_scm ());
1568                 $$->set_spot (THIS->here_input ());
1569         }
1570         | E_RIGHTSQUARE {
1571                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1572                 m->set_property ("span-direction", scm_int2num (STOP));
1573                 m->set_spot (THIS->here_input ());
1574
1575                 $$ = MY_MAKE_MUSIC ("EventChord");
1576                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1577                 $$->set_spot (THIS->here_input ());
1578                 scm_gc_unprotect_object (m->self_scm ());
1579         }
1580         | E_BACKSLASH {
1581                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1582                 $$->set_spot (THIS->here_input ());
1583         }
1584         | '|'      {
1585                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1586
1587                 if (Music * m = unsmob_music (pipe))
1588                         $$ = m->clone ();
1589                 else
1590                         $$ = MY_MAKE_MUSIC ("BarCheck");
1591
1592                 $$->set_spot (THIS->here_input ());
1593         }
1594         | TRANSPOSITION pitch {
1595                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1596                                         $2);
1597                 $$->set_spot (THIS-> here_input ());
1598                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1599                         $$, SCM_EOL);
1600         }
1601         | BAR STRING                    {
1602                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1603
1604                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1605                                         t, SCM_EOL);
1606                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1607                 $$->set_spot (THIS->here_input ());
1608                 t->set_spot (THIS->here_input ());
1609         }
1610         | PARTIAL duration_length       {
1611                 Moment m = - unsmob_duration ($2)->get_length ();
1612                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1613                 p->set_spot (THIS->here_input ());
1614                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1615                                         p, SCM_EOL);
1616                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1617                                         p, SCM_EOL);
1618                 $$ = p;
1619         }
1620         | CLEF STRING  {
1621                 SCM proc = ly_scheme_function ("make-clef-set");
1622
1623                 SCM result = scm_call_1 (proc, $2);
1624                 scm_gc_protect_object (result);
1625                 $$ = unsmob_music (result);
1626         }
1627         | TIME_T fraction  {
1628                 SCM proc= ly_scheme_function ("make-time-signature-set");
1629
1630                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1631                 scm_gc_protect_object (result);
1632                 $$ = unsmob_music (result);
1633         }
1634         | MARK scalar {
1635                 SCM proc = ly_scheme_function ("make-mark-set");
1636
1637                 SCM result = scm_call_1 (proc, $2);
1638                 scm_gc_protect_object (result);
1639                 $$ = unsmob_music (result);
1640         }
1641         ;
1642
1643 command_req:
1644         BREATHE {
1645                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1646         }
1647         | E_TILDE {
1648                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1649         }
1650         | MARK DEFAULT  {
1651                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1652                 $$ = m;
1653         }
1654         | tempo_event {
1655                 $$ = $1;
1656         }
1657         | KEY DEFAULT {
1658                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1659                 $$ = key;
1660         }
1661         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1662
1663                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1664                 if (scm_ilength ($3) > 0)
1665                 {
1666                         key->set_property ("pitch-alist", $3);
1667                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1668                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1669                 } else {
1670                         THIS->parser_error (_ ("Second argument must be pitch list."));
1671                 }
1672
1673                 $$ = key;
1674         }
1675         ;
1676
1677 post_events:
1678         /* empty */ {
1679                 $$ = SCM_EOL;
1680         }
1681         | post_events post_event {
1682                 $2->set_spot (THIS->here_input ());
1683                 $$ = scm_cons ($2->self_scm (), $$);
1684                 scm_gc_unprotect_object ($2->self_scm ());
1685         }
1686         | post_events tagged_post_event {
1687                 $2 -> set_spot (THIS->here_input ());
1688                 $$ = scm_cons ($2->self_scm (), $$);
1689                 scm_gc_unprotect_object ($2->self_scm ());
1690         }
1691         ;
1692
1693
1694 tagged_post_event:
1695         '-' TAG embedded_scm post_event {
1696                 tag_music ($4, $3, THIS->here_input ());
1697                 $$ = $4;
1698         }
1699         ;
1700
1701 post_event:
1702         direction_less_event {
1703                 $$ = $1;
1704         }
1705         | HYPHEN {
1706                 if (!THIS->lexer_->is_lyric_state ())
1707                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1708                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1709         }
1710         | EXTENDER {
1711                 if (!THIS->lexer_->is_lyric_state ())
1712                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1713                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1714         }
1715         | script_dir direction_reqd_event {
1716                 if ($1)
1717                         $2->set_property ("direction", scm_int2num ($1));
1718                 $$ = $2;
1719         }
1720         | script_dir direction_less_event {
1721                 if ($1)
1722                         $2->set_property ("direction", scm_int2num ($1));
1723                 $$ = $2;
1724         }
1725         | string_number_event
1726         ;
1727
1728 string_number_event:
1729         E_UNSIGNED {
1730                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1731                 s->set_property ("string-number", scm_int2num ($1));
1732                 s->set_spot (THIS->here_input ());
1733                 $$ = s;
1734         }
1735         ;
1736
1737
1738 direction_less_event:
1739         '['  {
1740
1741
1742 /*
1743
1744 TODO: should take all these defs out of the parser, adn make use
1745 configurable, i.e.
1746
1747
1748 (set-articulation '~ "trill")
1749
1750 */
1751                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1752                 m->set_spot (THIS->here_input ());
1753                 m->set_property ("span-direction", scm_int2num (START));
1754                 $$ = m;
1755         }
1756         | ']'  {
1757                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1758                 m->set_spot (THIS->here_input ());
1759                 m->set_property ("span-direction", scm_int2num (STOP));
1760                 $$ = m;
1761         }
1762         | '~' {
1763                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1764                 m->set_spot (THIS->here_input ());
1765                 $$ = m;
1766         }
1767         | close_event {
1768                 $$ = $1;
1769                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1770                         scm_int2num (START));
1771         }
1772         | open_event {
1773                 $$ = $1;
1774                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1775                         scm_int2num (STOP));
1776         }
1777         | EVENT_IDENTIFIER      {
1778                 $$ = unsmob_music ($1);
1779         }
1780         | tremolo_type  {
1781                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1782                a->set_spot (THIS->here_input ());
1783                a->set_property ("tremolo-type", scm_int2num ($1));
1784                $$ = a;
1785         }
1786         ;
1787
1788 direction_reqd_event:
1789         gen_text_def {
1790                 $$ = $1;
1791         }
1792         | script_abbreviation {
1793                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1794                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1795                 if (ly_c_string_p (s))
1796                         a->set_property ("articulation-type", s);
1797                 else THIS->parser_error (_ ("Expecting string as script definition"));
1798                 $$ = a;
1799         }
1800         ;
1801
1802 oct_check:
1803         /**/ { $$ = SCM_EOL; }
1804         | '='  { $$ = scm_int2num (0); }
1805         | '=' sub_quotes { $$ = scm_int2num ($2); }
1806         | '=' sup_quotes { $$ = scm_int2num ($2); }
1807         ;
1808
1809 sup_quotes:
1810         '\'' {
1811                 $$ = 1;
1812         }
1813         | sup_quotes '\'' {
1814                 $$ ++;
1815         }
1816         ;
1817
1818 sub_quotes:
1819         ',' {
1820                 $$ = 1;
1821         }
1822         | sub_quotes ',' {
1823                 $$++;
1824         }
1825         ;
1826
1827 steno_pitch:
1828         NOTENAME_PITCH  {
1829                 $$ = $1;
1830         }
1831         | NOTENAME_PITCH sup_quotes     {
1832                 Pitch p = *unsmob_pitch ($1);
1833                 p = p.transposed (Pitch ($2,0,0));
1834                 $$ = p.smobbed_copy ();
1835         }
1836         | NOTENAME_PITCH sub_quotes      {
1837                 Pitch p =* unsmob_pitch ($1);
1838                 p = p.transposed (Pitch (-$2,0,0));
1839                 $$ = p.smobbed_copy ();
1840         }
1841         ;
1842
1843 /*
1844 ugh. duplication
1845 */
1846
1847 steno_tonic_pitch:
1848         TONICNAME_PITCH {
1849                 $$ = $1;
1850         }
1851         | TONICNAME_PITCH sup_quotes    {
1852                 Pitch p = *unsmob_pitch ($1);
1853                 p = p.transposed (Pitch ($2,0,0));
1854                 $$ = p.smobbed_copy ();
1855         }
1856         | TONICNAME_PITCH sub_quotes     {
1857                 Pitch p =* unsmob_pitch ($1);
1858
1859                 p = p.transposed (Pitch (-$2,0,0));
1860                 $$ = p.smobbed_copy ();
1861         }
1862         ;
1863
1864 pitch:
1865         steno_pitch {
1866                 $$ = $1;
1867         }
1868         ;
1869
1870 pitch_also_in_chords:
1871         pitch
1872         | steno_tonic_pitch
1873         ;
1874
1875 close_event:
1876         '('     {
1877                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1878                 $$ = s;
1879                 s->set_spot (THIS->here_input ());
1880         }
1881         | E_OPEN        {
1882                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1883                 $$ = s;
1884                 s->set_spot (THIS->here_input ());
1885         }
1886         | E_SMALLER {
1887                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1888                 $$ = s;
1889                 s->set_spot (THIS->here_input ());
1890         }
1891         | E_BIGGER {
1892                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1893                 $$ = s;
1894                 s->set_spot (THIS->here_input ());
1895         }
1896         ;
1897
1898
1899 open_event:
1900         E_EXCLAMATION   {
1901                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1902                 s->set_spot (THIS->here_input ());
1903
1904                 $$ = s;
1905         }
1906         | ')'   {
1907                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1908                 $$ = s;
1909                 s->set_spot (THIS->here_input ());
1910
1911         }
1912         | E_CLOSE       {
1913                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1914                 $$ = s;
1915                 s->set_property ("span-type",
1916                         scm_makfrom0str ("phrasing-slur"));
1917                 s->set_spot (THIS->here_input ());
1918         }
1919         ;
1920
1921 gen_text_def:
1922         full_markup {
1923                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1924                 t->set_property ("text", $1);
1925                 t->set_spot (THIS->here_input ());
1926                 $$ = t;
1927         }
1928         | string {
1929                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1930                 t->set_property ("text",
1931                         make_simple_markup (THIS->lexer_->encoding (), $1));
1932                 t->set_spot (THIS->here_input ());
1933                 $$ = t;
1934
1935         }
1936         | DIGIT {
1937                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1938                 t->set_property ("digit", scm_int2num ($1));
1939                 t->set_spot (THIS->here_input ());
1940                 $$ = t;
1941         }
1942         ;
1943
1944 script_abbreviation:
1945         '^'             {
1946                 $$ = scm_makfrom0str ("Hat");
1947         }
1948         | '+'           {
1949                 $$ = scm_makfrom0str ("Plus");
1950         }
1951         | '-'           {
1952                 $$ = scm_makfrom0str ("Dash");
1953         }
1954         | '|'           {
1955                 $$ = scm_makfrom0str ("Bar");
1956         }
1957         | '>'           {
1958                 $$ = scm_makfrom0str ("Larger");
1959         }
1960         | '.'           {
1961                 $$ = scm_makfrom0str ("Dot");
1962         }
1963         | '_' {
1964                 $$ = scm_makfrom0str ("Underscore");
1965         }
1966         ;
1967
1968 script_dir:
1969         '_'     { $$ = DOWN; }
1970         | '^'   { $$ = UP; }
1971         | '-'   { $$ = CENTER; }
1972         ;
1973
1974
1975 absolute_pitch:
1976         steno_pitch     {
1977                 $$ = $1;
1978         }
1979         ;
1980
1981 duration_length:
1982         multiplied_duration {
1983                 $$ = $1;
1984         }
1985         ;
1986
1987 optional_notemode_duration:
1988         {
1989                 Duration dd = THIS->default_duration_;
1990                 $$ = dd.smobbed_copy ();
1991
1992                 THIS->beam_check ($$);
1993         }
1994         | multiplied_duration   {
1995                 $$ = $1;
1996                 THIS->default_duration_ = *unsmob_duration ($$);
1997
1998                 THIS->beam_check ($$);
1999         }
2000         ;
2001
2002 steno_duration:
2003         bare_unsigned dots              {
2004                 int len = 0;
2005                 if (!is_duration ($1))
2006                         THIS->parser_error (_f ("not a duration: %d", $1));
2007                 else
2008                         len = intlog2 ($1);
2009
2010                 $$ = Duration (len, $2).smobbed_copy ();
2011         }
2012         | DURATION_IDENTIFIER dots      {
2013                 Duration *d = unsmob_duration ($1);
2014                 Duration k (d->duration_log (), d->dot_count () + $2);
2015                 *d = k;
2016                 $$ = $1;
2017         }
2018         ;
2019
2020 multiplied_duration:
2021         steno_duration {
2022                 $$ = $1;
2023         }
2024         | multiplied_duration '*' bare_unsigned {
2025                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2026         }
2027         | multiplied_duration '*' FRACTION {
2028                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2029
2030                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2031         }
2032         ;
2033
2034 fraction:
2035         FRACTION { $$ = $1; }
2036         | UNSIGNED '/' UNSIGNED {
2037                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2038         }
2039         ;
2040
2041 dots:
2042         /* empty */     {
2043                 $$ = 0;
2044         }
2045         | dots '.' {
2046                 $$ ++;
2047         }
2048         ;
2049
2050 tremolo_type:
2051         ':'     {
2052                 $$ = 0;
2053         }
2054         | ':' bare_unsigned {
2055                 if (!is_duration ($2))
2056                         THIS->parser_error (_f ("not a duration: %d", $2));
2057                 $$ = $2;
2058         }
2059         ;
2060
2061 bass_number:
2062         DIGIT   {
2063                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2064         }
2065         | UNSIGNED {
2066                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2067         }
2068         | STRING { $$ = $1; }
2069         ;
2070
2071 bass_mod:
2072         '-'     { $$ = -2; }
2073         | '+'   { $$ = 2; }
2074         | '!'   { $$ = 0; }
2075         ;
2076
2077 bass_figure:
2078         FIGURE_SPACE {
2079                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2080                 $$ = bfr->self_scm ();
2081                 scm_gc_unprotect_object ($$);
2082         }
2083         | bass_number  {
2084                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2085                 $$ = bfr->self_scm ();
2086
2087                 bfr->set_property ("figure", $1);
2088
2089                 scm_gc_unprotect_object ($$);
2090         }
2091         | bass_figure bass_mod {
2092                 Music *m = unsmob_music ($1);
2093                 if ($2) {
2094                         SCM salter = m->get_property ("alteration");
2095                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2096                         m->set_property ("alteration",
2097                                 scm_int2num (alter + $2));
2098                 } else {
2099                         m->set_property ("alteration", scm_int2num (0));
2100                 }
2101         }
2102         ;
2103
2104 br_bass_figure:
2105         '[' bass_figure {
2106                 $$ = $2;
2107                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2108         }
2109         | bass_figure   {
2110                 $$ = $1;
2111         }
2112         | br_bass_figure ']' {
2113                 $$ = $1;
2114                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2115         }
2116         ;
2117
2118 figure_list:
2119         /**/            {
2120                 $$ = SCM_EOL;
2121         }
2122         | figure_list br_bass_figure {
2123                 $$ = scm_cons ($2, $1);
2124         }
2125         ;
2126
2127 figure_spec:
2128         FIGURE_OPEN figure_list FIGURE_CLOSE {
2129                 Music *m = MY_MAKE_MUSIC ("EventChord");
2130                 $2 = scm_reverse_x ($2, SCM_EOL);
2131                 m->set_property ("elements", $2);
2132                 $$ = m->self_scm ();
2133         }
2134         ;
2135
2136
2137 optional_rest:
2138         /**/   { $$ = 0; }
2139         | REST { $$ = 1; }
2140         ;
2141
2142 simple_element:
2143         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2144
2145                 Input i = THIS->pop_spot ();
2146                 if (!THIS->lexer_->is_note_state ())
2147                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2148
2149                 Music *n = 0;
2150                 if ($6)
2151                         n = MY_MAKE_MUSIC ("RestEvent");
2152                 else
2153                         n = MY_MAKE_MUSIC ("NoteEvent");
2154
2155                 n->set_property ("pitch", $1);
2156                 n->set_property ("duration", $5);
2157
2158                 if (ly_c_number_p ($4))
2159                 {
2160                         int q = ly_scm2int ($4);
2161                         n->set_property ("absolute-octave", scm_int2num (q-1));
2162                 }
2163
2164                 if ($3 % 2)
2165                         n->set_property ("cautionary", SCM_BOOL_T);
2166                 if ($2 % 2 || $3 % 2)
2167                         n->set_property ("force-accidental", SCM_BOOL_T);
2168
2169                 Music *v = MY_MAKE_MUSIC ("EventChord");
2170                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2171                 scm_gc_unprotect_object (n->self_scm ());
2172
2173                 v->set_spot (i);
2174                 n->set_spot (i);
2175                 $$ = v;
2176         }
2177         | DRUM_PITCH optional_notemode_duration {
2178                 Input i = THIS->pop_spot ();
2179
2180                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2181                 n->set_property ("duration", $2);
2182                 n->set_property ("drum-type", $1);
2183
2184                 Music *v = MY_MAKE_MUSIC ("EventChord");
2185                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2186                 scm_gc_unprotect_object (n->self_scm ());
2187                 v->set_spot (i);
2188                 n->set_spot (i);
2189                 $$ = v;
2190
2191         }
2192         | figure_spec optional_notemode_duration {
2193                 Music *m = unsmob_music ($1);
2194                 Input i = THIS->pop_spot ();
2195                 m->set_spot (i);
2196                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2197                 {
2198                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2199                 }
2200                 $$ = m;
2201         }
2202         | RESTNAME optional_notemode_duration           {
2203
2204                 Input i = THIS->pop_spot ();
2205                 Music *ev = 0;
2206                 if (ly_scm2string ($1) == "s") {
2207                         /* Space */
2208                         ev = MY_MAKE_MUSIC ("SkipEvent");
2209                   }
2210                 else {
2211                         ev = MY_MAKE_MUSIC ("RestEvent");
2212
2213                     }
2214                 ev->set_property ("duration", $2);
2215                 ev->set_spot (i);
2216                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2217                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2218                 velt->set_spot (i);
2219
2220                 scm_gc_unprotect_object (ev->self_scm ());
2221
2222                 $$ = velt;
2223         }
2224         | MULTI_MEASURE_REST optional_notemode_duration         {
2225                 THIS->pop_spot ();
2226
2227                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2228                 SCM mus = scm_call_2 (proc, $2,
2229                         make_input (THIS->here_input ()));
2230                 scm_gc_protect_object (mus);
2231                 $$ = unsmob_music (mus);
2232         }
2233
2234         | lyric_element optional_notemode_duration      {
2235                 Input i = THIS->pop_spot ();
2236                 if (!THIS->lexer_->is_lyric_state ())
2237                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2238
2239                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2240                 lreq->set_property ("text", $1);
2241                 lreq->set_property ("duration",$2);
2242                 lreq->set_spot (i);
2243                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2244                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2245
2246                 $$= velt;
2247         }
2248         | new_chord {
2249                 THIS->pop_spot ();
2250
2251                 if (!THIS->lexer_->is_chord_state ())
2252                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2253                 $$ = unsmob_music ($1);
2254         }
2255         ;
2256
2257 lyric_element:
2258         /* FIXME: lyric flavoured markup would be better */
2259         full_markup {
2260         }
2261         | LYRICS_STRING {
2262         }
2263         ;
2264
2265 new_chord:
2266         steno_tonic_pitch optional_notemode_duration   {
2267                 $$ = make_chord ($1, $2, SCM_EOL);
2268         }
2269         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2270                 SCM its = scm_reverse_x ($4, SCM_EOL);
2271                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2272         }
2273         ;
2274
2275 chord_items:
2276         /**/ {
2277                 $$ = SCM_EOL;
2278         }
2279         | chord_items chord_item {
2280                 $$ = scm_cons ($2, $$);
2281         }
2282         ;
2283
2284 chord_separator:
2285         CHORD_COLON {
2286                 $$ = ly_symbol2scm ("chord-colon");
2287         }
2288         | CHORD_CARET {
2289                 $$ = ly_symbol2scm ("chord-caret");
2290         }
2291         | CHORD_SLASH steno_tonic_pitch {
2292                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2293         }
2294         | CHORD_BASS steno_tonic_pitch {
2295                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2296         }
2297         ;
2298
2299 chord_item:
2300         chord_separator {
2301                 $$ = $1;
2302         }
2303         | step_numbers {
2304                 $$ = scm_reverse_x ($1, SCM_EOL);
2305         }
2306         | CHORD_MODIFIER  {
2307                 $$ = $1;
2308         }
2309         ;
2310
2311 step_numbers:
2312         step_number { $$ = scm_cons ($1, SCM_EOL); }
2313         | step_numbers '.' step_number {
2314                 $$ = scm_cons ($3, $$);
2315         }
2316         ;
2317
2318 step_number:
2319         bare_unsigned {
2320                 $$ = make_chord_step ($1, 0);
2321         }
2322         | bare_unsigned '+' {
2323                 $$ = make_chord_step ($1, SHARP);
2324         }
2325         | bare_unsigned CHORD_MINUS {
2326                 $$ = make_chord_step ($1, FLAT);
2327         }
2328         ;
2329
2330 /*
2331         UTILITIES
2332
2333 TODO: should deprecate in favor of Scheme?
2334
2335  */
2336 number_expression:
2337         number_expression '+' number_term {
2338                 $$ = scm_sum ($1, $3);
2339         }
2340         | number_expression '-' number_term {
2341                 $$ = scm_difference ($1, $3);
2342         }
2343         | number_term
2344         ;
2345
2346 number_term:
2347         number_factor {
2348                 $$ = $1;
2349         }
2350         | number_factor '*' number_factor {
2351                 $$ = scm_product ($1, $3);
2352         }
2353         | number_factor '/' number_factor {
2354                 $$ = scm_divide ($1, $3);
2355         }
2356         ;
2357
2358 number_factor:
2359         '-'  number_factor { /* %prec UNARY_MINUS */
2360                 $$ = scm_difference ($2, SCM_UNDEFINED);
2361         }
2362         | bare_number
2363         ;
2364
2365
2366 bare_number:
2367         UNSIGNED        {
2368                 $$ = scm_int2num ($1);
2369         }
2370         | REAL          {
2371                 $$ = $1;
2372         }
2373         | NUMBER_IDENTIFIER             {
2374                 $$ = $1;
2375         }
2376         | REAL NUMBER_IDENTIFIER        {
2377                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2378         }
2379         | UNSIGNED NUMBER_IDENTIFIER    {
2380                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2381         }
2382         ;
2383
2384
2385 bare_unsigned:
2386         UNSIGNED {
2387                         $$ = $1;
2388         }
2389         | DIGIT {
2390                 $$ = $1;
2391         }
2392         ;
2393
2394 bare_int:
2395         bare_number {
2396                 if (scm_integer_p ($1) == SCM_BOOL_T)
2397                 {
2398                         int k = ly_scm2int ($1);
2399                         $$ = k;
2400                 } else
2401                 {
2402                         THIS->parser_error (_ ("need integer number arg"));
2403                         $$ = 0;
2404                 }
2405         }
2406         | '-' bare_int {
2407                 $$ = -$2;
2408         }
2409         ;
2410
2411 exclamations:
2412                 { $$ = 0; }
2413         | exclamations '!'      { $$ ++; }
2414         ;
2415
2416 questions:
2417                 { $$ = 0; }
2418         | questions '?' { $$ ++; }
2419         ;
2420
2421
2422
2423 full_markup:
2424         MARKUP_IDENTIFIER {
2425                 $$ = $1;
2426         }
2427         | MARKUP
2428                 { THIS->lexer_->push_markup_state (); }
2429         markup
2430                 { $$ = $3;
2431                   THIS->lexer_->pop_state ();
2432                 }
2433         ;
2434
2435
2436 /*
2437 This should be done more dynamically if possible.
2438 */
2439 markup:
2440         STRING {
2441                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2442         }
2443         | MARKUP_HEAD_EMPTY {
2444                 $$ = scm_list_1 ($1);
2445         }
2446         | MARKUP_HEAD_MARKUP0 markup {
2447                 $$ = scm_list_2 ($1, $2);
2448         }
2449         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2450                 $$ = scm_list_3 ($1, $2, $3);
2451         }
2452         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2453                 $$ = scm_list_3 ($1, $2, $3);
2454         }
2455         | markup_line {
2456                 $$ = $1;
2457         }
2458         | MARKUP_HEAD_LIST0 markup_list {
2459                 $$ = scm_list_2 ($1,$2);
2460         }
2461         | MARKUP_HEAD_SCM0 embedded_scm {
2462                 $$ = scm_list_2 ($1, $2);
2463         }
2464         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2465                 $$ = scm_list_4 ($1, $2, $3, $4);
2466         }
2467         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2468                 $$ = scm_list_4 ($1, $2, $3, $4);
2469         }
2470         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2471                 $$ = scm_list_3 ($1, $2, $3);
2472         }
2473         | MARKUP_IDENTIFIER {
2474                 $$ = $1;
2475         }
2476         | STRING_IDENTIFIER {
2477                 $$ = $1;
2478         }
2479         | score_block {
2480                 /* WIP this is a bit arbitrary,
2481                    we should also allow \book or Composite_music.
2482                    However, you'd typically want to change paper
2483                    settings, and need a \score block anyway.  */
2484                 Score *score = $1;
2485                 Book *book = new Book;
2486                 book->scores_.push (score);
2487                 extern Music_output_def* get_paper (My_lily_parser *parser);
2488                 Music_output_def *paper = get_paper (THIS);
2489                 SCM s = book->to_stencil (paper, THIS->header_);
2490                 scm_gc_unprotect_object (score->self_scm ());
2491                 scm_gc_unprotect_object (book->self_scm ());
2492                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2493         }
2494         ;
2495
2496 markup_list:
2497         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2498         ;
2499
2500 markup_line:
2501         '{' markup_list_body '}' {
2502                 SCM line = ly_scheme_function ("line-markup");
2503
2504                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2505         }
2506         ;
2507
2508 markup_list_body:
2509         /**/ {  $$ = SCM_EOL; }
2510         | markup_list_body markup {
2511                 $$ = scm_cons ($2, $1);
2512         }
2513         ;
2514
2515
2516 %%
2517
2518 void
2519 My_lily_parser::set_yydebug (bool )
2520 {
2521 #if 0
2522         yydebug = 1;
2523 #endif
2524 }
2525
2526 void
2527 My_lily_parser::do_yyparse ()
2528 {
2529         yyparse ((void*)this);
2530 }
2531
2532
2533 /*
2534 Should make this optional?    It will also complain when you do
2535
2536         [s4]
2537
2538 which is entirely legitimate.
2539
2540 Or we can scrap it. Barchecks should detect wrong durations, and
2541 skipTypesetting speeds it up a lot.
2542 */
2543
2544 void
2545 My_lily_parser::beam_check (SCM dur)
2546 {
2547   Duration *d = unsmob_duration (dur);
2548   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2549     {
2550       Music *m = unsmob_music (last_beam_start_);
2551       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2552     }
2553   last_beam_start_ = SCM_EOL;
2554 }
2555
2556
2557
2558
2559 /*
2560
2561 It is a little strange to have this function in this file, but
2562 otherwise, we have to import music classes into the lexer.
2563
2564 */
2565 int
2566 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2567 {
2568         if (ly_c_string_p (sid)) {
2569                 *destination = sid;
2570                 return STRING_IDENTIFIER;
2571         } else if (ly_c_number_p (sid)) {
2572                 *destination = sid;
2573                 return NUMBER_IDENTIFIER;
2574         } else if (unsmob_context_def (sid)) {
2575                 *destination = unsmob_context_def (sid)->clone_scm ();
2576                 return CONTEXT_DEF_IDENTIFIER;
2577         } else if (unsmob_score (sid)) {
2578                 Score *score = new Score (*unsmob_score (sid));
2579                 *destination = score->self_scm ();
2580                 return SCORE_IDENTIFIER;
2581         } else if (Music *mus = unsmob_music (sid)) {
2582                 mus = mus->clone ();
2583                 *destination = mus->self_scm ();
2584                 unsmob_music (*destination)->
2585                         set_property ("origin", make_input (last_input_));
2586                 return dynamic_cast<Event*> (mus)
2587                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2588         } else if (unsmob_duration (sid)) {
2589                 *destination = unsmob_duration (sid)->smobbed_copy ();
2590                 return DURATION_IDENTIFIER;
2591         } else if (unsmob_music_output_def (sid)) {
2592                 Music_output_def *p = unsmob_music_output_def (sid);
2593                 p = p->clone ();
2594
2595                 *destination = p->self_scm ();
2596                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2597         } else if (Text_item::markup_p (sid)) {
2598                 *destination = sid;
2599                 return MARKUP_IDENTIFIER;
2600         }
2601
2602         return -1;
2603 }
2604
2605 Music *
2606 property_op_to_music (SCM op)
2607 {
2608         Music *m = 0;
2609         SCM tag = ly_car (op);
2610         SCM symbol = ly_cadr (op);
2611         SCM args = ly_cddr (op);
2612         SCM grob_val = SCM_UNDEFINED;
2613         SCM grob_sym = SCM_UNDEFINED;
2614         SCM val = SCM_UNDEFINED;
2615
2616         if (tag == ly_symbol2scm ("assign"))
2617                 {
2618                 m = MY_MAKE_MUSIC ("PropertySet");
2619                 val = ly_car (args);
2620                 }
2621         else if (tag == ly_symbol2scm ("unset"))
2622                 m = MY_MAKE_MUSIC ("PropertyUnset");
2623         else if (tag == ly_symbol2scm ("poppush")
2624                  || tag == ly_symbol2scm ("push"))
2625                 {
2626                 m = MY_MAKE_MUSIC ("OverrideProperty");
2627                 grob_sym = ly_car (args);
2628                 grob_val = ly_cadr (args);
2629                 }
2630         else if (tag == ly_symbol2scm ("pop")) {
2631                 m = MY_MAKE_MUSIC ("RevertProperty");
2632                 grob_sym = ly_car (args);
2633                 }
2634
2635         m->set_property ("symbol", symbol);
2636
2637         if (val != SCM_UNDEFINED)
2638                 m->set_property ("value", val);
2639         if (grob_val != SCM_UNDEFINED)
2640                 m->set_property ("grob-value", grob_val);
2641
2642         if (grob_sym != SCM_UNDEFINED)
2643                 {
2644                 bool itc = internal_type_checking_global_b;
2645                 /* UGH.
2646                 */
2647                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2648                 if (autobeam)
2649                         internal_type_checking_global_b = false;
2650                 m->set_property ("grob-property", grob_sym);
2651                 if (autobeam)
2652                         internal_type_checking_global_b = itc;
2653                 }
2654
2655         if (op == ly_symbol2scm ("poppush"))
2656                 m->set_property ("pop-first", SCM_BOOL_T);
2657
2658
2659         return m;
2660 }
2661
2662 Music*
2663 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2664 {
2665         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2666
2667         csm->set_property ("element", m->self_scm ());
2668         scm_gc_unprotect_object (m->self_scm ());
2669
2670         csm->set_property ("context-type",
2671                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2672         csm->set_property ("property-operations", ops);
2673
2674         if (ly_c_string_p (id))
2675                 csm->set_property ("context-id", id);
2676         return csm;
2677 }
2678
2679 SCM
2680 get_next_unique_context ()
2681 {
2682         static int new_context_count;
2683         char s[1024];
2684         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2685         return scm_makfrom0str (s);
2686 }
2687