lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "lily-lexer.hh"
  44 #include "lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((Lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (scm_is_symbol (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (scm_is_symbol (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left ADDLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         Lily_parser *pars = (Lily_parser*) v;
 209         Lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token CHORDMODE
 261 %token DOUBLE_ANGLE_OPEN
 262 %token DOUBLE_ANGLE_CLOSE
 263 %token CLEF
 264 %token COMMANDSPANREQUEST
 265 %token CONSISTS
 266 %token CONTEXT
 267 %token DEFAULT
 268 %token DENIES
 269 %token DESCRIPTION
 270 %token EXTENDER
 271 %token FIGURES
 272 %token FIGUREMODE
 273 %token FIGURE_OPEN FIGURE_CLOSE
 274 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 275 %token GROBDESCRIPTIONS
 276 %token HEADER
 277 %token HYPHEN
 278 %token INVALID
 279 %token KEY
 280 %token LYRICS
 281 %token LYRICMODE
 282 %token MARK
 283 %token MIDI
 284 %token MULTI_MEASURE_REST
 285 %token NAME
 286 %token NEWCONTEXT
 287 %token NOTEMODE
 288 %token OCTAVE
 289 %token ONCE
 290 %token OVERRIDE SET REVERT
 291 %token PAPER
 292 %token PARTIAL
 293 %token QUOTE
 294 %token RELATIVE
 295 %token REMOVE
 296 %token REPEAT
 297 %token REST
 298 %token SCM_T
 299 %token SCORE
 300 %token SEQUENTIAL
 301 %token ADDLYRICS
 302 %token SIMULTANEOUS
 303 %token SKIP
 304 %token SPANREQUEST
 305 %token TAG
 306 %token TEMPO
 307 %token TIMES
 308 %token TIME_T
 309 %token TRANSPOSE
 310 %token TRANSPOSITION
 311 %token TYPE
 312 %token UNSET
 313 %token WITH
 314 %token MARKUP
 315
 316 /* escaped */
 317 /* FIXME: this sucks.  The user will get to see these names:
 318     syntax error, unexpected E_CHAR:
 319                 \
 320                  %%
 321   */
 322
 323 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 324 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 325 %token E_BACKSLASH
 326 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 327 %token FIGURE_SPACE
 328
 329 %token <i>      DIGIT
 330 %token <i>      UNSIGNED
 331 %token <i> E_UNSIGNED
 332 %token <id>     IDENTIFIER
 333 %token <scm>    CHORDMODIFIER_PITCH
 334 %token <scm>    DRUM_PITCH
 335 %token <scm>    DURATION_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    NOTENAME_PITCH
 339 %token <scm>    NUMBER_IDENTIFIER
 340 %token <scm>    OUTPUT_DEF_IDENTIFIER
 341 %token <scm>    RESTNAME
 342 %token <scm> LYRICS_STRING
 343 %token <scm>    SCM_T
 344 %token <scm>    SCORE_IDENTIFIER
 345 %token <scm>    STRING
 346 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 347 %token <scm>    TONICNAME_PITCH
 348 %token <scm>    CHORD_MODIFIER
 349 %token <scm>    FRACTION
 350 %token <scm>   REAL
 351 %token <scm> MARKUP_HEAD_EMPTY
 352 %token <scm> MARKUP_HEAD_MARKUP0
 353 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 354 %token <scm> MARKUP_HEAD_SCM0
 355 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 356 %token <scm> MARKUP_HEAD_SCM0_SCM1
 357 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 358 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 359 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 360 %token <scm> MUSIC_FUNCTION
 361 %token <scm> MUSIC_FUNCTION_MUSIC
 362 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM
 364 %token <scm> MUSIC_FUNCTION_SCM_SCM
 365 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 366 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 367 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 368
 369 %token DRUMS
 370 %token DRUMMODE
 371
 372
 373 %type <book>    book_block book_body
 374 %type <i>       bare_int  bare_unsigned
 375 %type <i>       exclamations questions dots optional_rest
 376 %type <i>       script_dir
 377 %type <i>       sub_quotes sup_quotes
 378 %type <i>       tremolo_type
 379 %type <i>       bass_mod
 380
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <music>   Grouped_music_list
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   Repeated_music
 385 %type <music>   command_req
 386 %type <music>   gen_text_def direction_less_event direction_reqd_event
 387 %type <music>   music_property_def context_change
 388 %type <music>   note_chord_element chord_body chord_body_element
 389 %type <music>   post_event tagged_post_event
 390 %type <music>   relative_music re_rhythmed_music
 391 %type <music>   simple_element event_chord command_element
 392 %type <music>   string_number_event
 393 %type <music>   toplevel_music
 394 %type <music>   tempo_event
 395
 396 %type <outputdef>       output_def_body output_def_head
 397 %type <outputdef> output_def book_paper_block
 398
 399 %type <scm>     Music_list
 400 %type <scm>     chord_body_elements
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     context_def_spec_block context_def_spec_body
 403 %type <scm>     context_mod context_def_mod optional_context_mod
 404 %type <scm>     context_prop_spec
 405 %type <scm>     direction_less_char
 406 %type <scm>     duration_length fraction
 407 %type <scm>     embedded_scm scalar
 408 %type <scm>     identifier_init
 409 %type <scm>     lilypond_header lilypond_header_body
 410 %type <scm>     new_lyrics
 411 %type <scm>     post_events
 412 %type <scm>     property_operation
 413 %type <scm>     script_abbreviation
 414 %type <scm>     simple_string
 415 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 416 %type <scm>     steno_tonic_pitch
 417 %type <scm>     step_number step_numbers
 418 %type <scm>     string bare_number number_expression number_term number_factor
 419 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 420 %type <scm>     context_mod_list
 421 %type <scm>     octave_check
 422 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 423 %type <scm>     Generic_prefix_music_scm
 424 %type <scm>     lyric_element
 425 %type <scm>     Alternative_music
 426 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 427 %type <scm>     mode_changing_head
 428 %type <scm>     mode_changing_head_with_context
 429
 430 %type <score>   score_block score_body
 431
 432
 433 %left '-' '+'
 434
 435 /* We don't assign precedence to / and *, because we might need varied
 436 prec levels in different prods */
 437
 438 %left UNARY_MINUS
 439
 440 %%
 441
 442 lilypond:       /* empty */
 443         | lilypond toplevel_expression {
 444         }
 445         | lilypond assignment {
 446         }
 447         | lilypond error {
 448                 THIS->error_level_ = 1;
 449         }
 450         | lilypond INVALID      {
 451                 THIS->error_level_ = 1;
 452         }
 453         ;
 454
 455 toplevel_expression:
 456         lilypond_header {
 457                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 458         }
 459         | add_quote {
 460
 461         }
 462         | book_block {
 463                 Book *book = $1;
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 466                 scm_gc_unprotect_object (book->self_scm ());
 467         }
 468         | score_block {
 469                 Score *score = $1;
 470
 471                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 472                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 473                 scm_gc_unprotect_object (score->self_scm ());
 474         }
 475         | toplevel_music {
 476                 Music *music = $1;
 477                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 478                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 479                 scm_gc_unprotect_object (music->self_scm ());
 480         }
 481         | output_def {
 482                 SCM id = SCM_EOL;
 483                 Output_def * od = $1;
 484
 485                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 486                         id = ly_symbol2scm ("$defaultpaper");
 487                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 488                         id = ly_symbol2scm ("$defaultmidi");
 489                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 490                         id = ly_symbol2scm ("$defaultbookpaper");
 491
 492                 THIS->lexer_->set_identifier (id, od->self_scm ());
 493                 scm_gc_unprotect_object (od->self_scm ());
 494         }
 495         ;
 496
 497 toplevel_music:
 498         Composite_music {
 499         }
 500         ;
 501
 502 embedded_scm:
 503         SCM_T
 504         | SCM_IDENTIFIER
 505         ;
 506
 507
 508 lilypond_header_body:
 509         {
 510                 $$ = ly_make_anonymous_module (safe_global_b);
 511                 THIS->lexer_->add_scope ($$);
 512         }
 513         | lilypond_header_body assignment  {
 514
 515         }
 516         ;
 517
 518 lilypond_header:
 519         HEADER '{' lilypond_header_body '}'     {
 520                 $$ = THIS->lexer_->remove_scope ();
 521         }
 522         ;
 523
 524
 525 /*
 526         DECLARATIONS
 527 */
 528 assignment:
 529         STRING {
 530                 THIS->push_spot ();
 531         }
 532         /* cont */ '=' identifier_init  {
 533
 534         /*
 535                 Should find generic way of associating input with objects.
 536         */
 537                 Input ip = THIS->pop_spot ();
 538
 539                 if (! is_regular_identifier ($1))
 540                 {
 541                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 542                 }
 543
 544                 THIS->lexer_->set_identifier ($1, $4);
 545
 546 /*
 547  TODO: devise standard for protection in parser.
 548
 549   The parser stack lives on the C-stack, which means that
 550 all objects can be unprotected as soon as they're here.
 551
 552 */
 553         }
 554         | embedded_scm { }
 555         ;
 556
 557
 558 identifier_init:
 559         score_block {
 560                 $$ = $1->self_scm ();
 561                 scm_gc_unprotect_object ($$);
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | context_def_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 scm_gc_unprotect_object ($$);
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm {
 585                 $$ = $1;
 586         }
 587         | full_markup {
 588                 $$ = $1;
 589         }
 590         | DIGIT {
 591                 $$ = scm_int2num ($1);
 592         }
 593         ;
 594
 595 context_def_spec_block:
 596         CONTEXT '{' context_def_spec_body '}'
 597                 {
 598                 $$ = $3;
 599         }
 600         ;
 601
 602 context_def_spec_body:
 603         /**/ {
 604                 $$ = Context_def::make_scm ();
 605                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 606         }
 607         | CONTEXT_DEF_IDENTIFIER {
 608                 $$ = $1;
 609                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 610         }
 611         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 612                 Context_def*td = unsmob_context_def ($$);
 613
 614                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 615                         SCM tag = ly_caar (p);
 616
 617                         /* TODO: should make new tag "grob-definition" ? */
 618                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 619                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 620                 }
 621         }
 622         | context_def_spec_body context_mod {
 623                 unsmob_context_def ($$)->add_context_mod ($2);
 624         }
 625         ;
 626
 627
 628
 629 book_block:
 630         BOOK {
 631                 THIS->push_spot ();
 632         }
 633         /*cont*/ '{' book_body '}'      {
 634                 THIS->pop_spot ();
 635                 $$ = $4;
 636         }
 637         ;
 638
 639 /* FIXME:
 640    * Use 'handlers' like for toplevel-* stuff?
 641    * grok \paper and \midi?  */
 642 book_body:
 643         {
 644                 $$ = new Book;
 645                 $$->set_spot (THIS->here_input ());
 646                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 647                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 648                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 649         }
 650         | book_body book_paper_block {
 651                 $$->bookpaper_ = $2;
 652                 scm_gc_unprotect_object ($2->self_scm ());
 653         }
 654         | book_body score_block {
 655                 Score *score = $2;
 656                 $$->scores_.push (score);
 657                 scm_gc_unprotect_object (score->self_scm ());
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663
 664         }
 665         ;
 666
 667 score_block:
 668         SCORE {
 669                 THIS->push_spot ();
 670         }
 671         /*cont*/ '{' score_body '}'     {
 672                 THIS->pop_spot ();
 673                 $$ = $4;
 674         }
 675         ;
 676
 677 score_body:
 678         /**/    {
 679                 $$ = new Score;
 680
 681                 $$->set_spot (THIS->here_input ());
 682         }
 683         | SCORE_IDENTIFIER {
 684                 $$ = new Score ( *unsmob_score ($1));
 685                 $$->set_spot (THIS->here_input ());
 686         }
 687         | score_body Music {
 688                 SCM m = $2->self_scm ();
 689                 scm_gc_unprotect_object (m);
 690                 $$->set_music (m, THIS->self_scm ());
 691         }
 692         | score_body lilypond_header    {
 693                 $$->header_ = $2;
 694         }
 695         | score_body output_def {
 696                 $$->defs_.push ($2);
 697                 scm_gc_unprotect_object ($2->self_scm ());
 698         }
 699         | score_body error {
 700
 701         }
 702         ;
 703
 704
 705 /*
 706         OUTPUT DEF
 707 */
 708
 709 book_paper_block:
 710         output_def {
 711                 $$ = $1;
 712                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 713                 {
 714                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 715                         $$ = get_bookpaper (THIS);
 716                 }
 717         }
 718         ;
 719
 720
 721 output_def:
 722         output_def_body '}' {
 723                 $$ = $1;
 724                 if ($1->parent_)
 725                         THIS->lexer_->remove_scope ();
 726
 727                 THIS->lexer_->remove_scope ();
 728                 THIS->lexer_->pop_state ();
 729         }
 730         ;
 731
 732 output_def_head:
 733         BOOKPAPER {
 734                 $$ = get_bookpaper (THIS);
 735                 $$->input_origin_ = THIS->here_input ();
 736                 THIS->lexer_->add_scope ($$->scope_);
 737         }
 738         | MIDI    {
 739                 Output_def *p = get_midi (THIS);
 740                 $$ = p;
 741                 THIS->lexer_->add_scope (p->scope_);
 742         }
 743         | PAPER         {
 744                 Output_def *p = get_paper (THIS);
 745
 746                 if (p->parent_)
 747                         THIS->lexer_->add_scope (p->parent_->scope_);
 748
 749                 THIS->lexer_->add_scope (p->scope_);
 750                 $$ = p;
 751         }
 752         ;
 753
 754
 755 output_def_body:
 756         output_def_head '{' {
 757                 $$ = $1;
 758                 $$->input_origin_.set_spot (THIS->here_input ());
 759                 THIS->lexer_->push_initial_state ();
 760         }
 761         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 762                 scm_gc_unprotect_object ($1->self_scm ());
 763                 Output_def *o = unsmob_output_def ($3);
 764                 o->input_origin_.set_spot (THIS->here_input ());
 765                 $$ = o;
 766                 THIS->lexer_->remove_scope ();
 767                 THIS->lexer_->add_scope (o->scope_);
 768                 THIS->lexer_->push_initial_state ();
 769         }
 770         | output_def_body assignment  {
 771
 772         }
 773         | output_def_body context_def_spec_block        {
 774                 assign_context_def ($$, $2);
 775         }
 776         | output_def_body tempo_event  {
 777                 /*
 778                         junk this ? there already is tempo stuff in
 779                         music.
 780                 */
 781                 int m = scm_to_int ($2->get_property ("metronome-count"));
 782                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 783                 set_tempo ($$, d->get_length (), m);
 784                 scm_gc_unprotect_object ($2->self_scm ());
 785         }
 786         | output_def_body error {
 787
 788         }
 789         ;
 790
 791 tempo_event:
 792         TEMPO steno_duration '=' bare_unsigned  {
 793                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 794                 $$->set_property ("tempo-unit", $2);
 795                 $$->set_property ("metronome-count", scm_int2num ( $4));
 796         }
 797         ;
 798
 799 /*
 800 The representation of a  list is the
 801
 802   (LIST . LAST-CONS)
 803
 804  to have  efficient append.
 805 */
 806 Music_list:
 807         /* empty */ {
 808                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 809         }
 810         | Music_list Music {
 811                 SCM s = $$;
 812                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 813                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 814                 if (ly_c_pair_p (ly_cdr (s)))
 815                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 816                 else
 817                         scm_set_car_x (s, c); /* set first cons */
 818                 scm_set_cdr_x (s, c);  /* remember last cell */
 819         }
 820         | Music_list embedded_scm {
 821         }
 822         | Music_list error {
 823         }
 824         ;
 825
 826
 827 Music:
 828         Simple_music
 829         | Composite_music
 830         ;
 831
 832 Alternative_music:
 833         /* empty */ {
 834                 $$ = SCM_EOL;
 835         }
 836         | ALTERNATIVE '{' Music_list '}' {
 837                 $$ = $3;
 838         }
 839         ;
 840
 841
 842 Repeated_music:
 843         REPEAT simple_string bare_unsigned Music Alternative_music
 844         {
 845                 Music *beg = $4;
 846                 int times = $3;
 847                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 848                 if (times < scm_ilength (alts)) {
 849                   unsmob_music (ly_car (alts))
 850                     ->origin ()->warning (
 851                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 852                   alts = ly_truncate_list (times, alts);
 853                 }
 854
 855
 856                 SCM proc = ly_scheme_function ("make-repeated-music");
 857
 858                 SCM mus = scm_call_1 (proc, $2);
 859                 scm_gc_protect_object (mus); // UGH.
 860                 Music *r = unsmob_music (mus);
 861                 if (beg)
 862                         {
 863                         r-> set_property ("element", beg->self_scm ());
 864                         scm_gc_unprotect_object (beg->self_scm ());
 865                         }
 866                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 867
 868                 r-> set_property ("elements",alts);
 869                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 870                         /*
 871                         TODO: move this code to Scheme.
 872                         */
 873
 874                         /*
 875                         we can not get durations and other stuff correct down the line, so we have to
 876                         add to the duration log here.
 877                         */
 878                         SCM func = ly_scheme_function ("shift-duration-log");
 879
 880                         int dots = ($3 % 3) ? 0 : 1;
 881                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 882
 883                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 884
 885                         if (seq) {
 886                                 int list_len = scm_ilength (seq->music_list ());
 887                                 if (list_len != 2)
 888                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 889                                 shift -= 1;
 890                                 r->compress (Moment (Rational (1, list_len)));
 891                                 }
 892                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 893
 894                 }
 895                 r->set_spot (*$4->origin ());
 896
 897                 $$ = r;
 898         }
 899         ;
 900
 901 Sequential_music:
 902         SEQUENTIAL '{' Music_list '}'           {
 903                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 904                 $$->set_property ("elements", ly_car ($3));
 905                 $$->set_spot (THIS->here_input ());
 906         }
 907         | '{' Music_list '}'            {
 908                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 909                 $$->set_property ("elements", ly_car ($2));
 910                 $$->set_spot (THIS->here_input ());
 911         }
 912         ;
 913
 914 Simultaneous_music:
 915         SIMULTANEOUS '{' Music_list '}'{
 916                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 917                 $$->set_property ("elements", ly_car ($3));
 918                 $$->set_spot (THIS->here_input ());
 919
 920         }
 921         | simul_open Music_list simul_close     {
 922                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 923                 $$->set_property ("elements", ly_car ($2));
 924                 $$->set_spot (THIS->here_input ());
 925         }
 926         ;
 927
 928 Simple_music:
 929         event_chord             { $$ = $1; }
 930         | MUSIC_IDENTIFIER {
 931                 $$ = unsmob_music ($1);
 932         }
 933         | music_property_def
 934         | context_change
 935         ;
 936
 937
 938 optional_context_mod:
 939         /**/ { $$ = SCM_EOL; }
 940         | WITH { THIS->lexer_->push_initial_state (); }
 941         '{' context_mod_list '}'
 942         {
 943                 THIS->lexer_->pop_state ();
 944                 $$ = $4;
 945         }
 946         ;
 947
 948 context_mod_list:
 949         /* */  { $$ = SCM_EOL; }
 950         | context_mod_list context_mod  {
 951                  $$ = scm_cons ($2, $1);
 952         }
 953         ;
 954
 955
 956 Composite_music:
 957         Prefix_composite_music { $$ = $1; }
 958         | Grouped_music_list { $$ = $1; }
 959         ;
 960
 961 Grouped_music_list:
 962         Simultaneous_music              { $$ = $1; }
 963         | Sequential_music              { $$ = $1; }
 964         ;
 965
 966 Generic_prefix_music_scm:
 967         MUSIC_FUNCTION {
 968                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 969         }
 970         | MUSIC_FUNCTION_SCM {
 971                 THIS->push_spot ();
 972         } embedded_scm {
 973                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 974         }
 975         | MUSIC_FUNCTION_MUSIC {
 976                 THIS->push_spot ();
 977         } Music {
 978                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 979                 scm_gc_unprotect_object ($3->self_scm ());
 980         }
 981         | MUSIC_FUNCTION_SCM_MUSIC {
 982                 THIS->push_spot ();
 983         }  embedded_scm Music {
 984                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 985                 scm_gc_unprotect_object ($4->self_scm ());
 986         }
 987         | MUSIC_FUNCTION_SCM_SCM {
 988                 THIS->push_spot ();
 989         }  embedded_scm embedded_scm {
 990                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
 991         }
 992         | MUSIC_FUNCTION_MUSIC_MUSIC {
 993                 THIS->push_spot ();
 994         }  Music  Music {
 995                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 996                 scm_gc_unprotect_object ($3->self_scm ());
 997                 scm_gc_unprotect_object ($4->self_scm ());
 998         }
 999         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1000                 THIS->push_spot ();
1001         } embedded_scm Music Music {
1002                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1003                         $3, $4->self_scm (), $5->self_scm ());
1004                 scm_gc_unprotect_object ($5->self_scm ());
1005                 scm_gc_unprotect_object ($4->self_scm ());
1006         }
1007         ;
1008
1009 Generic_prefix_music:
1010         Generic_prefix_music_scm {
1011                 SCM func = ly_car ($1);
1012                 Input *loc = unsmob_input (ly_cadr ($1));
1013                 SCM args = ly_cddr ($1);
1014                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1015                 int k = 0;
1016                 bool ok  = true;
1017                 for (SCM s = sig, t = args;
1018                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1019                         s = ly_cdr (s), t = ly_cdr (t)) {
1020                         k++;
1021                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1022                         {
1023                                 loc->error (_f ("Argument %d failed typecheck", k));
1024                                 THIS->error_level_ = 1;
1025                                 ok = false;
1026                         }
1027                 }
1028                 SCM m = SCM_EOL;
1029                 if (ok)
1030                         m = scm_apply_0 (func, ly_cdr ($1));
1031                 if (unsmob_music (m))
1032                         {
1033                         $$ = unsmob_music (m);
1034                         scm_gc_protect_object (m);
1035                         }
1036                 else
1037                         {
1038                         if (ok)
1039                                 loc->error (_ ("Music head function should return Music object."));
1040                         $$ = MY_MAKE_MUSIC ("Music");
1041                         }
1042                 $$->set_spot (*loc);
1043         }
1044         ;
1045
1046
1047 Prefix_composite_music:
1048         Generic_prefix_music {
1049                 $$ = $1;
1050         }
1051         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1052                 $$ = context_spec_music ($2, $4, $6, $5);
1053
1054         }
1055         | CONTEXT simple_string optional_context_mod Music {
1056                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1057         }
1058         | NEWCONTEXT simple_string optional_context_mod Music {
1059                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1060                         $3);
1061         }
1062
1063         | TIMES {
1064                 THIS->push_spot ();
1065         }
1066         /* CONTINUED */
1067                 fraction Music
1068
1069         {
1070                 int n = scm_to_int (ly_car ($3)); int d = scm_to_int (ly_cdr ($3));
1071                 Music *mp = $4;
1072
1073                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1074                 $$->set_spot (THIS->pop_spot ());
1075
1076                 $$->set_property ("element", mp->self_scm ());
1077                 scm_gc_unprotect_object (mp->self_scm ());
1078                 $$->set_property ("numerator", scm_int2num (n));
1079                 $$->set_property ("denominator", scm_int2num (d));
1080                 $$->compress (Moment (Rational (n,d)));
1081
1082         }
1083         | Repeated_music                { $$ = $1; }
1084         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1085                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1086                 Music *p = $4;
1087                 Pitch from = *unsmob_pitch ($2);
1088                 Pitch to = *unsmob_pitch ($3);
1089
1090                 p->transpose (interval (from, to));
1091                 $$->set_property ("element", p->self_scm ());
1092                 scm_gc_unprotect_object (p->self_scm ());
1093         }
1094         | mode_changing_head Grouped_music_list {
1095                 if ($1 == ly_symbol2scm ("chords"))
1096                 {
1097                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1098                   chm->set_property ("element", $2->self_scm ());
1099                   $$ = chm;
1100                   scm_gc_unprotect_object ($2->self_scm ());
1101                 }
1102                 else
1103                 {
1104                   $$ = $2;
1105                 }
1106                 THIS->lexer_->pop_state ();
1107         }
1108         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1109                 $$ = context_spec_music ($1, get_next_unique_context (),
1110                                          $3, $2);
1111                 if ($1 == ly_symbol2scm ("ChordNames"))
1112                 {
1113                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1114                   chm->set_property ("element", $$->self_scm ());
1115                   scm_gc_unprotect_object ($$->self_scm ());
1116                   $$ = chm;
1117                 }
1118                 THIS->lexer_->pop_state ();
1119         }
1120         | relative_music        { $$ = $1; }
1121         | re_rhythmed_music     { $$ = $1; }
1122         | TAG embedded_scm Music {
1123                 tag_music ($3, $2, THIS->here_input ());
1124                 $$ = $3;
1125         }
1126         ;
1127
1128 mode_changing_head:
1129         NOTEMODE {
1130                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1131                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1132
1133                 $$ = ly_symbol2scm ("notes");
1134         }
1135         | DRUMMODE
1136                 {
1137                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1138                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1139
1140                 $$ = ly_symbol2scm ("drums");
1141         }
1142         | FIGUREMODE {
1143                 THIS->lexer_->push_figuredbass_state ();
1144
1145                 $$ = ly_symbol2scm ("figures");
1146         }
1147         | CHORDMODE {
1148                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1149                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1150                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1151                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1152                 $$ = ly_symbol2scm ("chords");
1153
1154         }
1155         | LYRICMODE
1156                 { THIS->lexer_->push_lyric_state ();
1157                 $$ = ly_symbol2scm ("lyrics");
1158         }
1159         ;
1160
1161 mode_changing_head_with_context:
1162         DRUMS {
1163                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1164                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1165
1166                 $$ = ly_symbol2scm ("DrumStaff");
1167         }
1168         | FIGURES {
1169                 THIS->lexer_->push_figuredbass_state ();
1170
1171                 $$ = ly_symbol2scm ("FiguredBass");
1172         }
1173         | CHORDS {
1174                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1175                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1176                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1177                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1178                 $$ = ly_symbol2scm ("ChordNames");
1179         }
1180         | LYRICS
1181                 { THIS->lexer_->push_lyric_state ();
1182                 $$ = ly_symbol2scm ("Lyrics");
1183         }
1184         ;
1185
1186
1187 relative_music:
1188         RELATIVE absolute_pitch Music {
1189                 Music *m = $3;
1190                 Pitch start = *unsmob_pitch ($2);
1191                 $$ = make_music_relative (start, m);
1192                 scm_gc_unprotect_object (m->self_scm ());
1193         }
1194         | RELATIVE Composite_music {
1195                 Music *m = $2;
1196
1197                 Pitch middle_c (0, 0, 0);
1198                 $$ = make_music_relative (middle_c, m);
1199                 scm_gc_unprotect_object (m->self_scm ());
1200         }
1201         ;
1202
1203 new_lyrics:
1204         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1205         /*cont */
1206         Grouped_music_list {
1207         /* Can also use Music at the expensive of two S/Rs similar to
1208            \repeat \alternative */
1209                 THIS->lexer_->pop_state ();
1210
1211                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1212         }
1213         | new_lyrics ADDLYRICS {
1214                 THIS->lexer_->push_lyric_state ();
1215         } Grouped_music_list {
1216                 THIS->lexer_->pop_state ();
1217                 $$ = scm_cons ($4->self_scm (), $1);
1218         }
1219         ;
1220
1221 re_rhythmed_music:
1222         Grouped_music_list new_lyrics {
1223
1224                 SCM name = $1->get_property ("context-id");
1225                 //if (name == SCM_EOL)
1226                 if (!scm_is_string (name))
1227                         name = scm_makfrom0str ("");
1228
1229                 SCM context = scm_makfrom0str ("Lyrics");
1230                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1231
1232                 SCM lst = SCM_EOL;
1233                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1234                 {
1235                         Music *music = unsmob_music (ly_car (s));
1236                         Music *com = make_lyric_combine_music (name, music);
1237                         Music *csm = context_spec_music (context,
1238                                 get_next_unique_context (), com, SCM_EOL);
1239                         lst = scm_cons (csm->self_scm (), lst);
1240                 }
1241                 /* FIXME: only first lyric music is accepted,
1242                           the rest is junked */
1243                 all->set_property ("elements", scm_cons ($1->self_scm (),
1244                         lst));
1245                 $$ = all;
1246                 scm_gc_unprotect_object ($1->self_scm ());
1247         }
1248         | LYRICSTO {
1249                 THIS->lexer_->push_lyric_state ();
1250         } simple_string Music {
1251                 THIS->lexer_->pop_state ();
1252                 Music *music = $4;
1253                 SCM name = $3;
1254                 $$ = make_lyric_combine_music (name, music);
1255                 scm_gc_unprotect_object (music->self_scm ());
1256         }
1257         ;
1258
1259 context_change:
1260         CHANGE STRING '=' STRING  {
1261                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1262                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1263                 t-> set_property ("change-to-id", $4);
1264
1265                 $$ = t;
1266                 $$->set_spot (THIS->here_input ());
1267         }
1268         ;
1269
1270 property_operation:
1271         STRING '=' scalar {
1272                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1273                         scm_string_to_symbol ($1), $3);
1274         }
1275         | UNSET simple_string {
1276                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1277                         scm_string_to_symbol ($2));
1278         }
1279         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1280                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1281                         scm_string_to_symbol ($2), $3, $5);
1282         }
1283         | REVERT simple_string embedded_scm {
1284                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1285                         scm_string_to_symbol ($2), $3);
1286         }
1287         ;
1288
1289 context_def_mod:
1290         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1291         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1292
1293         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1294         | DENIES { $$ = ly_symbol2scm ("denies"); }
1295
1296         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1297         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1298         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1299         | NAME { $$ = ly_symbol2scm ("context-name"); }
1300         ;
1301
1302 context_mod:
1303         property_operation { $$ = $1; }
1304         | context_def_mod STRING {
1305                 $$ = scm_list_2 ($1, $2);
1306         }
1307         ;
1308
1309 context_prop_spec:
1310         simple_string {
1311                 if (!is_regular_identifier ($1))
1312                 {
1313                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1314                 }
1315
1316                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1317                         scm_string_to_symbol ($1));
1318         }
1319         | simple_string '.' simple_string {
1320                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1321                         scm_string_to_symbol ($3));
1322         }
1323         ;
1324
1325 music_property_def:
1326         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1327                 $$ = property_op_to_music (scm_list_4 (
1328                         ly_symbol2scm ("poppush"),
1329                         ly_cadr ($2),
1330                         $3, $5));
1331                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1332         }
1333         | REVERT context_prop_spec embedded_scm {
1334                 $$ = property_op_to_music (scm_list_3 (
1335                         ly_symbol2scm ("pop"),
1336                         ly_cadr ($2),
1337                         $3));
1338
1339                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1340         }
1341         | SET context_prop_spec '=' scalar {
1342                 $$ = property_op_to_music (scm_list_3 (
1343                         ly_symbol2scm ("assign"),
1344                         ly_cadr ($2),
1345                         $4));
1346                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1347         }
1348         | UNSET context_prop_spec {
1349                 $$ = property_op_to_music (scm_list_2 (
1350                         ly_symbol2scm ("unset"),
1351                         ly_cadr ($2)));
1352                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1353         }
1354         | ONCE music_property_def {
1355                 SCM e = $2->get_property ("element");
1356                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1357                 $$ = $2;
1358
1359         }
1360         ;
1361
1362
1363 string:
1364         STRING {
1365                 $$ = $1;
1366         }
1367         | STRING_IDENTIFIER {
1368                 $$ = $1;
1369         }
1370         | string '+' string {
1371                 $$ = scm_string_append (scm_list_2 ($1, $3));
1372         }
1373         ;
1374
1375 simple_string: STRING {
1376                 $$ = $1;
1377         }
1378         | LYRICS_STRING {
1379                 $$ = $1;
1380         }
1381         ;
1382
1383 scalar: string {
1384                 $$ = $1;
1385         }
1386         | LYRICS_STRING {
1387                 $$ = $1;
1388         }
1389         | bare_int {
1390                 $$ = scm_int2num ($1);
1391         }
1392         | embedded_scm {
1393                 $$ = $1;
1394         }
1395         | full_markup {
1396                 $$ = $1;
1397         }
1398         | DIGIT {
1399                 $$ = scm_int2num ($1);
1400         }
1401         ;
1402
1403 /*
1404
1405 pre_events doesn't contain anything. It is a trick:
1406
1407 Adding pre_events to the simple_element
1408 makes the choice between
1409
1410   string:  STRING
1411
1412 and
1413
1414   simple_element: STRING
1415
1416 a single shift/reduction conflict.
1417
1418 nevertheless, this is not very clean, and we should find a different
1419 solution.
1420
1421 */
1422 pre_events: {
1423                 THIS->push_spot ();
1424         }
1425         ;
1426
1427 event_chord:
1428         pre_events simple_element post_events   {
1429                 SCM elts = $2-> get_property ("elements");
1430
1431                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1432
1433                 $2->set_property ("elements", elts);
1434                 $$ = $2;
1435         }
1436         | command_element
1437         | note_chord_element
1438         ;
1439
1440
1441 note_chord_element:
1442         chord_body optional_notemode_duration post_events
1443         {
1444                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1445                 SCM es = $1->get_property ("elements");
1446                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1447
1448                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1449                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1450                 es = ly_append2 (es, postevs);
1451
1452                 $1-> set_property ("elements", es);
1453                 $$ = $1;
1454         }
1455         ;
1456
1457 chord_open: '<'
1458         ;
1459
1460 chord_close: '>'
1461         ;
1462
1463 simul_open: DOUBLE_ANGLE_OPEN
1464         ;
1465
1466 simul_close: DOUBLE_ANGLE_CLOSE
1467         ;
1468
1469 chord_body:
1470         chord_open chord_body_elements chord_close
1471         {
1472                 $$ = MY_MAKE_MUSIC ("EventChord");
1473                 $$->set_property ("elements",
1474                         scm_reverse_x ($2, SCM_EOL));
1475         }
1476         ;
1477
1478 chord_body_elements:
1479         /* empty */             { $$ = SCM_EOL; }
1480         | chord_body_elements chord_body_element {
1481                 $$ = scm_cons ($2->self_scm (), $1);
1482                 scm_gc_unprotect_object ($2->self_scm ());
1483         }
1484         ;
1485
1486 chord_body_element:
1487         pitch  exclamations questions octave_check post_events
1488         {
1489                 int q = $3;
1490                 int ex = $2;
1491                 SCM check = $4;
1492                 SCM post = $5;
1493
1494                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1495                 n->set_property ("pitch", $1);
1496                 if (q % 2)
1497                         n->set_property ("cautionary", SCM_BOOL_T);
1498                 if (ex % 2 || q % 2)
1499                         n->set_property ("force-accidental", SCM_BOOL_T);
1500
1501                 if (ly_c_pair_p (post)) {
1502                         SCM arts = scm_reverse_x (post, SCM_EOL);
1503                         n->set_property ("articulations", arts);
1504                 }
1505                 if (scm_is_number (check))
1506                 {
1507                         int q = scm_to_int (check);
1508                         n->set_property ("absolute-octave", scm_int2num (q-1));
1509                 }
1510
1511
1512                 $$ = n;
1513         }
1514         | DRUM_PITCH post_events {
1515                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1516                 n->set_property ("duration", $2);
1517                 n->set_property ("drum-type", $1);
1518                 n->set_spot (THIS->here_input ());
1519
1520                 if (ly_c_pair_p ($2)) {
1521                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1522                         n->set_property ("articulations", arts);
1523                 }
1524                 $$ = n;
1525         }
1526         ;
1527
1528 add_quote:
1529         ADDQUOTE string Music {
1530                 SCM adder = ly_scheme_function ("add-quotable");
1531
1532                 scm_call_2 (adder, $2, $3->self_scm ());
1533                 scm_gc_unprotect_object ($3->self_scm ());
1534         }
1535         ;
1536
1537 command_element:
1538         command_req {
1539                 $$ = MY_MAKE_MUSIC ("EventChord");
1540                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1541                 scm_gc_unprotect_object ($1->self_scm ());
1542
1543                 $$-> set_spot (THIS->here_input ());
1544                 $1-> set_spot (THIS->here_input ());
1545         }
1546         | SKIP duration_length {
1547                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1548                 skip->set_property ("duration", $2);
1549
1550                 $$ = skip;
1551         }
1552         | QUOTE STRING duration_length {
1553                 Music *quote = MY_MAKE_MUSIC ("QuoteMusic");
1554                 quote->set_property ("duration", $3);
1555                 quote->set_property ("quoted-music-name", $2);
1556                 quote->set_spot (THIS->here_input ());
1557
1558                 $$ = quote;
1559         }
1560         | OCTAVE { THIS->push_spot (); }
1561           pitch {
1562                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1563                 $$ = m;
1564                 $$->set_spot (THIS->pop_spot ());
1565                 $$->set_property ("pitch", $3);
1566         }
1567         | E_LEFTSQUARE {
1568                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1569                 m->set_property ("span-direction", scm_int2num (START));
1570                 m->set_spot (THIS->here_input ());
1571
1572                 $$ = MY_MAKE_MUSIC ("EventChord");
1573                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1574                 scm_gc_unprotect_object (m->self_scm ());
1575                 $$->set_spot (THIS->here_input ());
1576         }
1577         | E_RIGHTSQUARE {
1578                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1579                 m->set_property ("span-direction", scm_int2num (STOP));
1580                 m->set_spot (THIS->here_input ());
1581
1582                 $$ = MY_MAKE_MUSIC ("EventChord");
1583                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1584                 $$->set_spot (THIS->here_input ());
1585                 scm_gc_unprotect_object (m->self_scm ());
1586         }
1587         | E_BACKSLASH {
1588                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1589                 $$->set_spot (THIS->here_input ());
1590         }
1591         | '|'      {
1592                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1593
1594                 if (Music * m = unsmob_music (pipe))
1595                         $$ = m->clone ();
1596                 else
1597                         $$ = MY_MAKE_MUSIC ("BarCheck");
1598
1599                 $$->set_spot (THIS->here_input ());
1600         }
1601         | TRANSPOSITION pitch {
1602                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1603                                         $2);
1604                 $$->set_spot (THIS-> here_input ());
1605                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1606                         $$, SCM_EOL);
1607         }
1608         | BAR STRING                    {
1609                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1610
1611                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1612                                         t, SCM_EOL);
1613                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1614                 $$->set_spot (THIS->here_input ());
1615                 t->set_spot (THIS->here_input ());
1616         }
1617         | PARTIAL duration_length       {
1618                 Moment m = - unsmob_duration ($2)->get_length ();
1619                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1620                 p->set_spot (THIS->here_input ());
1621                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1622                                         p, SCM_EOL);
1623                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1624                                         p, SCM_EOL);
1625                 $$ = p;
1626         }
1627         | CLEF STRING  {
1628                 SCM proc = ly_scheme_function ("make-clef-set");
1629
1630                 SCM result = scm_call_1 (proc, $2);
1631                 scm_gc_protect_object (result);
1632                 $$ = unsmob_music (result);
1633         }
1634         | TIME_T fraction  {
1635                 SCM proc= ly_scheme_function ("make-time-signature-set");
1636
1637                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1638                 scm_gc_protect_object (result);
1639                 $$ = unsmob_music (result);
1640         }
1641         | MARK scalar {
1642                 SCM proc = ly_scheme_function ("make-mark-set");
1643
1644                 SCM result = scm_call_1 (proc, $2);
1645                 scm_gc_protect_object (result);
1646                 $$ = unsmob_music (result);
1647         }
1648         ;
1649
1650 command_req:
1651         E_TILDE {
1652                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1653         }
1654         | MARK DEFAULT  {
1655                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1656                 $$ = m;
1657         }
1658         | tempo_event {
1659                 $$ = $1;
1660         }
1661         | KEY DEFAULT {
1662                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1663                 $$ = key;
1664         }
1665         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1666
1667                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1668                 if (scm_ilength ($3) > 0)
1669                 {
1670                         key->set_property ("pitch-alist", $3);
1671                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1672                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1673                 } else {
1674                         THIS->parser_error (_ ("Second argument must be pitch list."));
1675                 }
1676
1677                 $$ = key;
1678         }
1679         ;
1680
1681 post_events:
1682         /* empty */ {
1683                 $$ = SCM_EOL;
1684         }
1685         | post_events post_event {
1686                 $2->set_spot (THIS->here_input ());
1687                 $$ = scm_cons ($2->self_scm (), $$);
1688                 scm_gc_unprotect_object ($2->self_scm ());
1689         }
1690         | post_events tagged_post_event {
1691                 $2 -> set_spot (THIS->here_input ());
1692                 $$ = scm_cons ($2->self_scm (), $$);
1693                 scm_gc_unprotect_object ($2->self_scm ());
1694         }
1695         ;
1696
1697
1698 tagged_post_event:
1699         '-' TAG embedded_scm post_event {
1700                 tag_music ($4, $3, THIS->here_input ());
1701                 $$ = $4;
1702         }
1703         ;
1704
1705 post_event:
1706         direction_less_event {
1707                 $$ = $1;
1708         }
1709         | HYPHEN {
1710                 if (!THIS->lexer_->is_lyric_state ())
1711                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1712                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1713         }
1714         | EXTENDER {
1715                 if (!THIS->lexer_->is_lyric_state ())
1716                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1717                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1718         }
1719         | script_dir direction_reqd_event {
1720                 if ($1)
1721                         $2->set_property ("direction", scm_int2num ($1));
1722                 $$ = $2;
1723         }
1724         | script_dir direction_less_event {
1725                 if ($1)
1726                         $2->set_property ("direction", scm_int2num ($1));
1727                 $$ = $2;
1728         }
1729         | string_number_event
1730         ;
1731
1732 string_number_event:
1733         E_UNSIGNED {
1734                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1735                 s->set_property ("string-number", scm_int2num ($1));
1736                 s->set_spot (THIS->here_input ());
1737                 $$ = s;
1738         }
1739         ;
1740
1741 direction_less_char:
1742         '['  {
1743                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1744         }
1745         | ']'  {
1746                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1747         }
1748         | '~'  {
1749                 $$ = ly_symbol2scm ("tildeSymbol");
1750         }
1751         | '('  {
1752                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1753         }
1754         | ')'  {
1755                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1756         }
1757         | E_EXCLAMATION  {
1758                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1759         }
1760         | E_OPEN  {
1761                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1762         }
1763         | E_CLOSE  {
1764                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1765         }
1766         | E_BIGGER  {
1767                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1768         }
1769         | E_SMALLER  {
1770                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1771         }
1772         ;
1773
1774 direction_less_event:
1775         direction_less_char {
1776                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1777                 Music * m = 0;
1778                 if (unsmob_music (predefd))
1779                 {
1780                         m = unsmob_music (predefd)->clone ();
1781                 }
1782                 else
1783                 {
1784                         m = MY_MAKE_MUSIC ("Music");
1785                 }
1786                 m->set_spot (THIS->here_input ());
1787                 $$ = m;
1788         }
1789         | EVENT_IDENTIFIER      {
1790                 $$ = unsmob_music ($1);
1791         }
1792         | tremolo_type  {
1793                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1794                a->set_spot (THIS->here_input ());
1795                a->set_property ("tremolo-type", scm_int2num ($1));
1796                $$ = a;
1797         }
1798         ;
1799
1800 direction_reqd_event:
1801         gen_text_def {
1802                 $$ = $1;
1803         }
1804         | script_abbreviation {
1805                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1806                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1807                 if (scm_is_string (s))
1808                         a->set_property ("articulation-type", s);
1809                 else THIS->parser_error (_ ("Expecting string as script definition"));
1810                 $$ = a;
1811         }
1812         ;
1813
1814 octave_check:
1815         /**/ { $$ = SCM_EOL; }
1816         | '='  { $$ = scm_int2num (0); }
1817         | '=' sub_quotes { $$ = scm_int2num ($2); }
1818         | '=' sup_quotes { $$ = scm_int2num ($2); }
1819         ;
1820
1821 sup_quotes:
1822         '\'' {
1823                 $$ = 1;
1824         }
1825         | sup_quotes '\'' {
1826                 $$ ++;
1827         }
1828         ;
1829
1830 sub_quotes:
1831         ',' {
1832                 $$ = 1;
1833         }
1834         | sub_quotes ',' {
1835                 $$++;
1836         }
1837         ;
1838
1839 steno_pitch:
1840         NOTENAME_PITCH  {
1841                 $$ = $1;
1842         }
1843         | NOTENAME_PITCH sup_quotes     {
1844                 Pitch p = *unsmob_pitch ($1);
1845                 p = p.transposed (Pitch ($2,0,0));
1846                 $$ = p.smobbed_copy ();
1847         }
1848         | NOTENAME_PITCH sub_quotes      {
1849                 Pitch p =* unsmob_pitch ($1);
1850                 p = p.transposed (Pitch (-$2,0,0));
1851                 $$ = p.smobbed_copy ();
1852         }
1853         ;
1854
1855 /*
1856 ugh. duplication
1857 */
1858
1859 steno_tonic_pitch:
1860         TONICNAME_PITCH {
1861                 $$ = $1;
1862         }
1863         | TONICNAME_PITCH sup_quotes    {
1864                 Pitch p = *unsmob_pitch ($1);
1865                 p = p.transposed (Pitch ($2,0,0));
1866                 $$ = p.smobbed_copy ();
1867         }
1868         | TONICNAME_PITCH sub_quotes     {
1869                 Pitch p =* unsmob_pitch ($1);
1870
1871                 p = p.transposed (Pitch (-$2,0,0));
1872                 $$ = p.smobbed_copy ();
1873         }
1874         ;
1875
1876 pitch:
1877         steno_pitch {
1878                 $$ = $1;
1879         }
1880         ;
1881
1882 pitch_also_in_chords:
1883         pitch
1884         | steno_tonic_pitch
1885         ;
1886
1887 gen_text_def:
1888         full_markup {
1889                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1890                 t->set_property ("text", $1);
1891                 t->set_spot (THIS->here_input ());
1892                 $$ = t;
1893         }
1894         | string {
1895                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1896                 t->set_property ("text",
1897                         make_simple_markup (THIS->lexer_->encoding (), $1));
1898                 t->set_spot (THIS->here_input ());
1899                 $$ = t;
1900
1901         }
1902         | DIGIT {
1903                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1904                 t->set_property ("digit", scm_int2num ($1));
1905                 t->set_spot (THIS->here_input ());
1906                 $$ = t;
1907         }
1908         ;
1909
1910 script_abbreviation:
1911         '^'             {
1912                 $$ = scm_makfrom0str ("Hat");
1913         }
1914         | '+'           {
1915                 $$ = scm_makfrom0str ("Plus");
1916         }
1917         | '-'           {
1918                 $$ = scm_makfrom0str ("Dash");
1919         }
1920         | '|'           {
1921                 $$ = scm_makfrom0str ("Bar");
1922         }
1923         | '>'           {
1924                 $$ = scm_makfrom0str ("Larger");
1925         }
1926         | '.'           {
1927                 $$ = scm_makfrom0str ("Dot");
1928         }
1929         | '_' {
1930                 $$ = scm_makfrom0str ("Underscore");
1931         }
1932         ;
1933
1934 script_dir:
1935         '_'     { $$ = DOWN; }
1936         | '^'   { $$ = UP; }
1937         | '-'   { $$ = CENTER; }
1938         ;
1939
1940
1941 absolute_pitch:
1942         steno_pitch     {
1943                 $$ = $1;
1944         }
1945         ;
1946
1947 duration_length:
1948         multiplied_duration {
1949                 $$ = $1;
1950         }
1951         ;
1952
1953 optional_notemode_duration:
1954         {
1955                 Duration dd = THIS->default_duration_;
1956                 $$ = dd.smobbed_copy ();
1957
1958                 THIS->beam_check ($$);
1959         }
1960         | multiplied_duration   {
1961                 $$ = $1;
1962                 THIS->default_duration_ = *unsmob_duration ($$);
1963
1964                 THIS->beam_check ($$);
1965         }
1966         ;
1967
1968 steno_duration:
1969         bare_unsigned dots              {
1970                 int len = 0;
1971                 if (!is_duration ($1))
1972                         THIS->parser_error (_f ("not a duration: %d", $1));
1973                 else
1974                         len = intlog2 ($1);
1975
1976                 $$ = Duration (len, $2).smobbed_copy ();
1977         }
1978         | DURATION_IDENTIFIER dots      {
1979                 Duration *d = unsmob_duration ($1);
1980                 Duration k (d->duration_log (), d->dot_count () + $2);
1981                 *d = k;
1982                 $$ = $1;
1983         }
1984         ;
1985
1986 multiplied_duration:
1987         steno_duration {
1988                 $$ = $1;
1989         }
1990         | multiplied_duration '*' bare_unsigned {
1991                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1992         }
1993         | multiplied_duration '*' FRACTION {
1994                 Rational  m (scm_to_int (ly_car ($3)), scm_to_int (ly_cdr ($3)));
1995
1996                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1997         }
1998         ;
1999
2000 fraction:
2001         FRACTION { $$ = $1; }
2002         | UNSIGNED '/' UNSIGNED {
2003                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2004         }
2005         ;
2006
2007 dots:
2008         /* empty */     {
2009                 $$ = 0;
2010         }
2011         | dots '.' {
2012                 $$ ++;
2013         }
2014         ;
2015
2016 tremolo_type:
2017         ':'     {
2018                 $$ = 0;
2019         }
2020         | ':' bare_unsigned {
2021                 if (!is_duration ($2))
2022                         THIS->parser_error (_f ("not a duration: %d", $2));
2023                 $$ = $2;
2024         }
2025         ;
2026
2027 bass_number:
2028         DIGIT   {
2029                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2030                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2031                                 $$);
2032         }
2033         | UNSIGNED {
2034                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2035                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2036                                 $$);
2037         }
2038         | STRING { $$ = $1; }
2039         ;
2040
2041 bass_mod:
2042         '-'     { $$ = -2; }
2043         | '+'   { $$ = 2; }
2044         | '!'   { $$ = 0; }
2045         ;
2046
2047 bass_figure:
2048         FIGURE_SPACE {
2049                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2050                 $$ = bfr->self_scm ();
2051                 scm_gc_unprotect_object ($$);
2052         }
2053         | bass_number  {
2054                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2055                 $$ = bfr->self_scm ();
2056
2057                 bfr->set_property ("figure", $1);
2058
2059                 scm_gc_unprotect_object ($$);
2060         }
2061         | bass_figure bass_mod {
2062                 Music *m = unsmob_music ($1);
2063                 if ($2) {
2064                         SCM salter = m->get_property ("alteration");
2065                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2066                         m->set_property ("alteration",
2067                                 scm_int2num (alter + $2));
2068                 } else {
2069                         m->set_property ("alteration", scm_int2num (0));
2070                 }
2071         }
2072         ;
2073
2074 br_bass_figure:
2075         '[' bass_figure {
2076                 $$ = $2;
2077                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2078         }
2079         | bass_figure   {
2080                 $$ = $1;
2081         }
2082         | br_bass_figure ']' {
2083                 $$ = $1;
2084                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2085         }
2086         ;
2087
2088 figure_list:
2089         /**/            {
2090                 $$ = SCM_EOL;
2091         }
2092         | figure_list br_bass_figure {
2093                 $$ = scm_cons ($2, $1);
2094         }
2095         ;
2096
2097 figure_spec:
2098         FIGURE_OPEN figure_list FIGURE_CLOSE {
2099                 Music *m = MY_MAKE_MUSIC ("EventChord");
2100                 $2 = scm_reverse_x ($2, SCM_EOL);
2101                 m->set_property ("elements", $2);
2102                 $$ = m->self_scm ();
2103         }
2104         ;
2105
2106
2107 optional_rest:
2108         /**/   { $$ = 0; }
2109         | REST { $$ = 1; }
2110         ;
2111
2112 simple_element:
2113         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2114
2115                 Input i = THIS->pop_spot ();
2116                 if (!THIS->lexer_->is_note_state ())
2117                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2118
2119                 Music *n = 0;
2120                 if ($6)
2121                         n = MY_MAKE_MUSIC ("RestEvent");
2122                 else
2123                         n = MY_MAKE_MUSIC ("NoteEvent");
2124
2125                 n->set_property ("pitch", $1);
2126                 n->set_property ("duration", $5);
2127
2128                 if (scm_is_number ($4))
2129                 {
2130                         int q = scm_to_int ($4);
2131                         n->set_property ("absolute-octave", scm_int2num (q-1));
2132                 }
2133
2134                 if ($3 % 2)
2135                         n->set_property ("cautionary", SCM_BOOL_T);
2136                 if ($2 % 2 || $3 % 2)
2137                         n->set_property ("force-accidental", SCM_BOOL_T);
2138
2139                 Music *v = MY_MAKE_MUSIC ("EventChord");
2140                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2141                 scm_gc_unprotect_object (n->self_scm ());
2142
2143                 v->set_spot (i);
2144                 n->set_spot (i);
2145                 $$ = v;
2146         }
2147         | DRUM_PITCH optional_notemode_duration {
2148                 Input i = THIS->pop_spot ();
2149
2150                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2151                 n->set_property ("duration", $2);
2152                 n->set_property ("drum-type", $1);
2153
2154                 Music *v = MY_MAKE_MUSIC ("EventChord");
2155                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2156                 scm_gc_unprotect_object (n->self_scm ());
2157                 v->set_spot (i);
2158                 n->set_spot (i);
2159                 $$ = v;
2160
2161         }
2162         | figure_spec optional_notemode_duration {
2163                 Music *m = unsmob_music ($1);
2164                 Input i = THIS->pop_spot ();
2165                 m->set_spot (i);
2166                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2167                 {
2168                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2169                 }
2170                 $$ = m;
2171         }
2172         | RESTNAME optional_notemode_duration           {
2173
2174                 Input i = THIS->pop_spot ();
2175                 Music *ev = 0;
2176                 if (ly_scm2string ($1) == "s") {
2177                         /* Space */
2178                         ev = MY_MAKE_MUSIC ("SkipEvent");
2179                   }
2180                 else {
2181                         ev = MY_MAKE_MUSIC ("RestEvent");
2182
2183                     }
2184                 ev->set_property ("duration", $2);
2185                 ev->set_spot (i);
2186                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2187                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2188                 velt->set_spot (i);
2189
2190                 scm_gc_unprotect_object (ev->self_scm ());
2191
2192                 $$ = velt;
2193         }
2194         | MULTI_MEASURE_REST optional_notemode_duration         {
2195                 THIS->pop_spot ();
2196
2197                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2198                 SCM mus = scm_call_2 (proc, $2,
2199                         make_input (THIS->here_input ()));
2200                 scm_gc_protect_object (mus);
2201                 $$ = unsmob_music (mus);
2202         }
2203
2204         | lyric_element optional_notemode_duration      {
2205                 Input i = THIS->pop_spot ();
2206                 if (!THIS->lexer_->is_lyric_state ())
2207                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2208
2209                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2210                 lreq->set_property ("text", $1);
2211                 lreq->set_property ("duration",$2);
2212                 lreq->set_spot (i);
2213                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2214                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2215
2216                 $$= velt;
2217         }
2218         | new_chord {
2219                 THIS->pop_spot ();
2220
2221                 if (!THIS->lexer_->is_chord_state ())
2222                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2223                 $$ = unsmob_music ($1);
2224         }
2225         ;
2226
2227 lyric_element:
2228         /* FIXME: lyric flavoured markup would be better */
2229         full_markup {
2230                 $$ = $1;
2231         }
2232         | LYRICS_STRING {
2233                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2234         }
2235         ;
2236
2237 new_chord:
2238         steno_tonic_pitch optional_notemode_duration   {
2239                 $$ = make_chord ($1, $2, SCM_EOL);
2240         }
2241         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2242                 SCM its = scm_reverse_x ($4, SCM_EOL);
2243                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2244         }
2245         ;
2246
2247 chord_items:
2248         /**/ {
2249                 $$ = SCM_EOL;
2250         }
2251         | chord_items chord_item {
2252                 $$ = scm_cons ($2, $$);
2253         }
2254         ;
2255
2256 chord_separator:
2257         CHORD_COLON {
2258                 $$ = ly_symbol2scm ("chord-colon");
2259         }
2260         | CHORD_CARET {
2261                 $$ = ly_symbol2scm ("chord-caret");
2262         }
2263         | CHORD_SLASH steno_tonic_pitch {
2264                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2265         }
2266         | CHORD_BASS steno_tonic_pitch {
2267                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2268         }
2269         ;
2270
2271 chord_item:
2272         chord_separator {
2273                 $$ = $1;
2274         }
2275         | step_numbers {
2276                 $$ = scm_reverse_x ($1, SCM_EOL);
2277         }
2278         | CHORD_MODIFIER  {
2279                 $$ = $1;
2280         }
2281         ;
2282
2283 step_numbers:
2284         step_number { $$ = scm_cons ($1, SCM_EOL); }
2285         | step_numbers '.' step_number {
2286                 $$ = scm_cons ($3, $$);
2287         }
2288         ;
2289
2290 step_number:
2291         bare_unsigned {
2292                 $$ = make_chord_step ($1, 0);
2293         }
2294         | bare_unsigned '+' {
2295                 $$ = make_chord_step ($1, SHARP);
2296         }
2297         | bare_unsigned CHORD_MINUS {
2298                 $$ = make_chord_step ($1, FLAT);
2299         }
2300         ;
2301
2302 /*
2303         UTILITIES
2304
2305 TODO: should deprecate in favor of Scheme?
2306
2307  */
2308 number_expression:
2309         number_expression '+' number_term {
2310                 $$ = scm_sum ($1, $3);
2311         }
2312         | number_expression '-' number_term {
2313                 $$ = scm_difference ($1, $3);
2314         }
2315         | number_term
2316         ;
2317
2318 number_term:
2319         number_factor {
2320                 $$ = $1;
2321         }
2322         | number_factor '*' number_factor {
2323                 $$ = scm_product ($1, $3);
2324         }
2325         | number_factor '/' number_factor {
2326                 $$ = scm_divide ($1, $3);
2327         }
2328         ;
2329
2330 number_factor:
2331         '-'  number_factor { /* %prec UNARY_MINUS */
2332                 $$ = scm_difference ($2, SCM_UNDEFINED);
2333         }
2334         | bare_number
2335         ;
2336
2337
2338 bare_number:
2339         UNSIGNED        {
2340                 $$ = scm_int2num ($1);
2341         }
2342         | REAL          {
2343                 $$ = $1;
2344         }
2345         | NUMBER_IDENTIFIER             {
2346                 $$ = $1;
2347         }
2348         | REAL NUMBER_IDENTIFIER        {
2349                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2350         }
2351         | UNSIGNED NUMBER_IDENTIFIER    {
2352                 $$ = scm_make_real ($1 *scm_to_double ($2));
2353         }
2354         ;
2355
2356
2357 bare_unsigned:
2358         UNSIGNED {
2359                         $$ = $1;
2360         }
2361         | DIGIT {
2362                 $$ = $1;
2363         }
2364         ;
2365
2366 bare_int:
2367         bare_number {
2368                 if (scm_integer_p ($1) == SCM_BOOL_T)
2369                 {
2370                         int k = scm_to_int ($1);
2371                         $$ = k;
2372                 } else
2373                 {
2374                         THIS->parser_error (_ ("need integer number arg"));
2375                         $$ = 0;
2376                 }
2377         }
2378         | '-' bare_int {
2379                 $$ = -$2;
2380         }
2381         ;
2382
2383 exclamations:
2384                 { $$ = 0; }
2385         | exclamations '!'      { $$ ++; }
2386         ;
2387
2388 questions:
2389                 { $$ = 0; }
2390         | questions '?' { $$ ++; }
2391         ;
2392
2393
2394
2395 full_markup:
2396         MARKUP_IDENTIFIER {
2397                 $$ = $1;
2398         }
2399         | MARKUP
2400                 { THIS->lexer_->push_markup_state (); }
2401         markup
2402                 { $$ = $3;
2403                   THIS->lexer_->pop_state ();
2404                 }
2405         ;
2406
2407
2408 /*
2409 This should be done more dynamically if possible.
2410 */
2411 markup:
2412         STRING {
2413                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2414         }
2415         | MARKUP_HEAD_EMPTY {
2416                 $$ = scm_list_1 ($1);
2417         }
2418         | MARKUP_HEAD_MARKUP0 markup {
2419                 $$ = scm_list_2 ($1, $2);
2420         }
2421         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2422                 $$ = scm_list_3 ($1, $2, $3);
2423         }
2424         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2425                 $$ = scm_list_3 ($1, $2, $3);
2426         }
2427         | markup_line {
2428                 $$ = $1;
2429         }
2430         | MARKUP_HEAD_LIST0 markup_list {
2431                 $$ = scm_list_2 ($1,$2);
2432         }
2433         | MARKUP_HEAD_SCM0 embedded_scm {
2434                 $$ = scm_list_2 ($1, $2);
2435         }
2436         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2437                 $$ = scm_list_4 ($1, $2, $3, $4);
2438         }
2439         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2440                 $$ = scm_list_4 ($1, $2, $3, $4);
2441         }
2442         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2443                 $$ = scm_list_3 ($1, $2, $3);
2444         }
2445         | MARKUP_IDENTIFIER {
2446                 $$ = $1;
2447         }
2448         | STRING_IDENTIFIER {
2449                 $$ = $1;
2450         }
2451         | SCORE {
2452                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2453                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2454         } '{' score_body '}' {
2455                 Score * sc = $4;
2456                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2457                 scm_gc_unprotect_object (sc->self_scm ());
2458                 THIS->lexer_->pop_state ();
2459         }
2460         ;
2461
2462 markup_list:
2463         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2464         ;
2465
2466 markup_line:
2467         '{' markup_list_body '}' {
2468                 SCM line = ly_scheme_function ("line-markup");
2469
2470                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2471         }
2472         ;
2473
2474 markup_list_body:
2475         /**/ {  $$ = SCM_EOL; }
2476         | markup_list_body markup {
2477                 $$ = scm_cons ($2, $1);
2478         }
2479         ;
2480
2481
2482 %%
2483
2484 void
2485 Lily_parser::set_yydebug (bool )
2486 {
2487 #if 0
2488         yydebug = 1;
2489 #endif
2490 }
2491
2492 void
2493 Lily_parser::do_yyparse ()
2494 {
2495         yyparse ((void*)this);
2496 }
2497
2498
2499 /*
2500 Should make this optional?    It will also complain when you do
2501
2502         [s4]
2503
2504 which is entirely legitimate.
2505
2506 Or we can scrap it. Barchecks should detect wrong durations, and
2507 skipTypesetting speeds it up a lot.
2508 */
2509
2510 void
2511 Lily_parser::beam_check (SCM dur)
2512 {
2513   Duration *d = unsmob_duration (dur);
2514   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2515     {
2516       Music *m = unsmob_music (last_beam_start_);
2517       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2518     }
2519   last_beam_start_ = SCM_EOL;
2520 }
2521
2522
2523
2524
2525 /*
2526
2527 It is a little strange to have this function in this file, but
2528 otherwise, we have to import music classes into the lexer.
2529
2530 */
2531 int
2532 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2533 {
2534         if (scm_is_string (sid)) {
2535                 *destination = sid;
2536                 return STRING_IDENTIFIER;
2537         } else if (scm_is_number (sid)) {
2538                 *destination = sid;
2539                 return NUMBER_IDENTIFIER;
2540         } else if (unsmob_context_def (sid)) {
2541                 *destination = unsmob_context_def (sid)->clone_scm ();
2542                 return CONTEXT_DEF_IDENTIFIER;
2543         } else if (unsmob_score (sid)) {
2544                 Score *score = new Score (*unsmob_score (sid));
2545                 *destination = score->self_scm ();
2546                 return SCORE_IDENTIFIER;
2547         } else if (Music *mus = unsmob_music (sid)) {
2548                 mus = mus->clone ();
2549                 *destination = mus->self_scm ();
2550                 unsmob_music (*destination)->
2551                         set_property ("origin", make_input (last_input_));
2552                 return dynamic_cast<Event*> (mus)
2553                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2554         } else if (unsmob_duration (sid)) {
2555                 *destination = unsmob_duration (sid)->smobbed_copy ();
2556                 return DURATION_IDENTIFIER;
2557         } else if (unsmob_output_def (sid)) {
2558                 Output_def *p = unsmob_output_def (sid);
2559                 p = p->clone ();
2560
2561                 *destination = p->self_scm ();
2562                 return OUTPUT_DEF_IDENTIFIER;
2563         } else if (Text_item::markup_p (sid)) {
2564                 *destination = sid;
2565                 return MARKUP_IDENTIFIER;
2566         }
2567
2568         return -1;
2569 }
2570
2571 Music *
2572 property_op_to_music (SCM op)
2573 {
2574         Music *m = 0;
2575         SCM tag = ly_car (op);
2576         SCM symbol = ly_cadr (op);
2577         SCM args = ly_cddr (op);
2578         SCM grob_val = SCM_UNDEFINED;
2579         SCM grob_sym = SCM_UNDEFINED;
2580         SCM val = SCM_UNDEFINED;
2581
2582         if (tag == ly_symbol2scm ("assign"))
2583                 {
2584                 m = MY_MAKE_MUSIC ("PropertySet");
2585                 val = ly_car (args);
2586                 }
2587         else if (tag == ly_symbol2scm ("unset"))
2588                 m = MY_MAKE_MUSIC ("PropertyUnset");
2589         else if (tag == ly_symbol2scm ("poppush")
2590                  || tag == ly_symbol2scm ("push"))
2591                 {
2592                 m = MY_MAKE_MUSIC ("OverrideProperty");
2593                 grob_sym = ly_car (args);
2594                 grob_val = ly_cadr (args);
2595                 }
2596         else if (tag == ly_symbol2scm ("pop")) {
2597                 m = MY_MAKE_MUSIC ("RevertProperty");
2598                 grob_sym = ly_car (args);
2599                 }
2600
2601         m->set_property ("symbol", symbol);
2602
2603         if (val != SCM_UNDEFINED)
2604                 m->set_property ("value", val);
2605         if (grob_val != SCM_UNDEFINED)
2606                 m->set_property ("grob-value", grob_val);
2607
2608         if (grob_sym != SCM_UNDEFINED)
2609                 {
2610                 bool itc = internal_type_checking_global_b;
2611                 /* UGH.
2612                 */
2613                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2614                 if (autobeam)
2615                         internal_type_checking_global_b = false;
2616                 m->set_property ("grob-property", grob_sym);
2617                 if (autobeam)
2618                         internal_type_checking_global_b = itc;
2619                 }
2620
2621         if (tag == ly_symbol2scm ("poppush"))
2622                 m->set_property ("pop-first", SCM_BOOL_T);
2623
2624
2625         return m;
2626 }
2627
2628 Music*
2629 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2630 {
2631         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2632
2633         csm->set_property ("element", m->self_scm ());
2634         scm_gc_unprotect_object (m->self_scm ());
2635
2636         csm->set_property ("context-type",
2637                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2638         csm->set_property ("property-operations", ops);
2639
2640         if (scm_is_string (id))
2641                 csm->set_property ("context-id", id);
2642         return csm;
2643 }
2644
2645 /*
2646 FIXME: this should be postponed until the music hits \Score
2647 */
2648 SCM
2649 get_next_unique_context ()
2650 {
2651         static int new_context_count;
2652         char s[1024];
2653         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2654         return scm_makfrom0str (s);
2655 }
2656