lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226 3. \markup { }
 227
 228 4.  \repeat
 229         \repeat .. \alternative
 230
 231
 232     \repeat { \repeat .. \alternative }
 233
 234 or
 235
 236     \repeat { \repeat } \alternative
 237
 238 )
 239  */
 240
 241
 242 %pure_parser
 243
 244 %token ACCEPTS
 245 %token ADDQUOTE
 246 %token LYRICSTO
 247 %token ALIAS
 248 %token ALTERNATIVE
 249 %token BAR
 250 %token BOOK
 251 %token BOOKPAPER
 252 %token CHANGE
 253 %token CHORDMODIFIERS
 254 %token CHORDS
 255 %token DOUBLE_ANGLE_OPEN
 256 %token DOUBLE_ANGLE_CLOSE
 257 %token CLEF
 258 %token COMMANDSPANREQUEST
 259 %token CONSISTS
 260 %token CONSISTSEND
 261 %token CONTEXT
 262 %token DEFAULT
 263 %token DENIES
 264 %token DESCRIPTION
 265 %token EXTENDER
 266 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 267 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token LYRICS_STRING
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTIAL
 286 %token QUOTE
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token NEWLYRICS
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 /* FIXME: this sucks.  The user will get to see these names:
 310     syntax error, unexpected E_CHAR:
 311                 \
 312                  %%
 313   */
 314 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 315 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 316 %token E_BACKSLASH
 317 %token <i> E_UNSIGNED
 318 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 319 %token FIGURE_SPACE
 320
 321 %token <i>      DIGIT
 322 %token <scm>    NOTENAME_PITCH
 323 %token <scm>    TONICNAME_PITCH
 324 %token <scm>    CHORDMODIFIER_PITCH
 325 %token <scm>    DURATION_IDENTIFIER
 326 %token <scm>    FRACTION
 327 %token <id>     IDENTIFIER
 328 %token DRUMS
 329 %token <scm>    DRUM_PITCH
 330 %token <scm>    CHORD_MODIFIER
 331 %token <scm>    SCORE_IDENTIFIER
 332 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    NUMBER_IDENTIFIER
 334 %token <scm>    EVENT_IDENTIFIER
 335 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 336 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm>    STRING
 339 %token <scm>    SCM_T
 340 %token <i>      UNSIGNED
 341 %token <scm>   REAL
 342
 343 %token MARKUP
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_EMPTY
 346 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0
 348 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 352
 353 %token <scm> MUSIC_FUNCTION
 354 %token <scm> MUSIC_FUNCTION_SCM
 355 %token <scm> MUSIC_FUNCTION_MUSIC
 356 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 357 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 358 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 360
 361 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 362 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 363
 364 %type <book>    book_block book_body
 365 %type <outputdef> book_paper_head book_paper_block book_paper_body
 366
 367 %type <i>       exclamations questions dots optional_rest
 368 %type <i>       bass_mod
 369 %type <scm>     oct_check
 370 %type <scm>     context_mod_list
 371 %type <scm>     lyric_element
 372 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 373 %type <scm>     new_lyrics
 374 %type <outputdef> output_def
 375 %type <scm>     lilypond_header lilypond_header_body
 376 %type <music>   open_event close_event
 377 %type <i>       sub_quotes sup_quotes
 378 %type <music>   toplevel_music
 379 %type <music>   simple_element event_chord command_element
 380 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 381 %type <scm>     Generic_prefix_music_scm
 382 %type <music>   Grouped_music_list
 383 %type <music>   Repeated_music
 384 %type <scm>     Alternative_music
 385 %type <i>       tremolo_type
 386 %type <i>       bare_int  bare_unsigned
 387 %type <i>       script_dir
 388 %type <scm>     identifier_init
 389 %type <scm>     simple_string
 390
 391 %type <music>   note_chord_element chord_body chord_body_element
 392 %type <scm>     chord_body_elements
 393 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 394
 395 %type <scm>     post_events
 396 %type <music>   gen_text_def direction_less_event direction_reqd_event
 397 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 398 %type <scm>     steno_tonic_pitch
 399 %type <scm>     duration_length fraction
 400
 401 %type <scm>     chord_item chord_items chord_separator new_chord
 402 %type <scm>     step_number step_numbers
 403
 404 %type <scm>     embedded_scm scalar
 405 %type <music>   Music Sequential_music Simultaneous_music
 406 %type <music>   relative_music re_rhythmed_music
 407 %type <music>   music_property_def context_change
 408 %type <scm>     context_prop_spec
 409 %type <scm>     Music_list
 410 %type <scm>     property_operation
 411 %type <scm>     context_mod context_def_mod optional_context_mod
 412 %type <outputdef>       music_output_def_body music_output_def_head
 413 %type <music>   post_event tagged_post_event
 414 %type <music>   command_req
 415 %type <music>   string_number_event
 416 %type <scm>     string bare_number number_expression number_term number_factor
 417 %type <score>   score_block score_body
 418
 419 %type <scm>     context_def_spec_block context_def_spec_body
 420 %type <music>   tempo_event
 421 %type <scm>     script_abbreviation
 422
 423
 424
 425 %left '-' '+'
 426
 427 /* We don't assign precedence to / and *, because we might need varied
 428 prec levels in different prods */
 429
 430 %left UNARY_MINUS
 431
 432 %%
 433
 434 lilypond:       /* empty */
 435         | lilypond toplevel_expression {
 436         }
 437         | lilypond assignment {
 438         }
 439         | lilypond error {
 440                 THIS->error_level_ = 1;
 441         }
 442         | lilypond INVALID      {
 443                 THIS->error_level_ = 1;
 444         }
 445         ;
 446
 447 toplevel_expression:
 448         lilypond_header {
 449                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 450         }
 451         | add_quote {
 452
 453         }
 454         | book_block {
 455                 Book *book = $1;
 456                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 457                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 458                 scm_gc_unprotect_object (book->self_scm ());
 459         }
 460         | score_block {
 461                 Score *score = $1;
 462
 463                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 464                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 465                 scm_gc_unprotect_object (score->self_scm ());
 466         }
 467         | toplevel_music {
 468                 Music *music = $1;
 469                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 470                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 471                 scm_gc_unprotect_object (music->self_scm ());
 472         }
 473         | output_def {
 474                 SCM id = SCM_EOL;
 475                 Output_def * od = $1;
 476
 477                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 478                         id = ly_symbol2scm ("$defaultpaper");
 479                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 480                         id = ly_symbol2scm ("$defaultmidi");
 481                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 482                         id = ly_symbol2scm ("$defaultbookpaper");
 483
 484                 THIS->lexer_->set_identifier (id, od->self_scm ());
 485                 scm_gc_unprotect_object (od->self_scm ());
 486         }
 487         | book_paper_block {
 488                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultbookpaper"), $1->self_scm ());
 489                 scm_gc_unprotect_object ($1->self_scm ());
 490         }
 491         ;
 492
 493 toplevel_music:
 494         Composite_music {
 495         }
 496         ;
 497
 498 embedded_scm:
 499         SCM_T
 500         | SCM_IDENTIFIER
 501         ;
 502
 503
 504 lilypond_header_body:
 505         {
 506                 $$ = ly_make_anonymous_module (safe_global_b);
 507                 THIS->lexer_->add_scope ($$);
 508         }
 509         | lilypond_header_body assignment  {
 510
 511         }
 512         ;
 513
 514 lilypond_header:
 515         HEADER '{' lilypond_header_body '}'     {
 516                 $$ = THIS->lexer_->remove_scope ();
 517         }
 518         ;
 519
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment:
 525         STRING {
 526                 THIS->push_spot ();
 527         }
 528         /* cont */ '=' identifier_init  {
 529
 530         /*
 531                 Should find generic way of associating input with objects.
 532         */
 533                 Input ip = THIS->pop_spot ();
 534
 535                 if (! is_regular_identifier ($1))
 536                 {
 537                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 538                 }
 539
 540                 THIS->lexer_->set_identifier ($1, $4);
 541
 542 /*
 543  TODO: devise standard for protection in parser.
 544
 545   The parser stack lives on the C-stack, which means that
 546 all objects can be unprotected as soon as they're here.
 547
 548 */
 549         }
 550         | embedded_scm { }
 551         ;
 552
 553
 554 identifier_init:
 555         score_block {
 556                 $$ = $1->self_scm ();
 557                 scm_gc_unprotect_object ($$);
 558         }
 559         | full_markup {
 560                 $$ = $1;
 561         }
 562         | output_def {
 563                 $$ = $1->self_scm ();
 564                 scm_gc_unprotect_object ($$);
 565         }
 566         | context_def_spec_block {
 567                 $$ = $1;
 568         }
 569         | Music  {
 570                 $$ = $1->self_scm ();
 571                 scm_gc_unprotect_object ($$);
 572         }
 573         | post_event {
 574                 $$ = $1->self_scm ();
 575                 scm_gc_unprotect_object ($$);
 576         }
 577         | number_expression {
 578                 $$ = $1;
 579         }
 580         | string {
 581                 $$ = $1;
 582         }
 583         | embedded_scm  {
 584                 $$ = $1;
 585         }
 586         ;
 587
 588 context_def_spec_block:
 589         CONTEXT '{' context_def_spec_body '}'
 590                 {
 591                 $$ = $3;
 592         }
 593         ;
 594
 595 context_def_spec_body:
 596         /**/ {
 597                 $$ = Context_def::make_scm ();
 598                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 599         }
 600         | CONTEXT_DEF_IDENTIFIER {
 601                 $$ = $1;
 602                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 603         }
 604         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 605                 Context_def*td = unsmob_context_def ($$);
 606
 607                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 608                         SCM tag = ly_caar (p);
 609
 610                         /* TODO: should make new tag "grob-definition" ? */
 611                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 612                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 613                 }
 614         }
 615         | context_def_spec_body context_mod {
 616                 unsmob_context_def ($$)->add_context_mod ($2);
 617         }
 618         ;
 619
 620
 621 book_paper_block:
 622         book_paper_body '}' {
 623                 $$ = $1;
 624                 THIS->lexer_->remove_scope ();
 625         }
 626         ;
 627 book_paper_head:
 628         BOOKPAPER '{' {
 629                 $$ = get_bookpaper (THIS);
 630                 $$->input_origin_ = THIS->here_input ();
 631                 THIS->lexer_->add_scope ($$->scope_);
 632         }
 633         ;
 634
 635 book_paper_body:
 636         book_paper_head
 637         | book_paper_body assignment { }
 638         ;
 639
 640
 641
 642 book_block:
 643         BOOK {
 644                 THIS->push_spot ();
 645         }
 646         /*cont*/ '{' book_body '}'      {
 647                 THIS->pop_spot ();
 648                 $$ = $4;
 649         }
 650         ;
 651
 652 /* FIXME:
 653    * Use 'handlers' like for toplevel-* stuff?
 654    * grok \paper and \midi?  */
 655 book_body:
 656         {
 657                 $$ = new Book;
 658                 $$->set_spot (THIS->here_input ());
 659                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 660                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 661                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 662         }
 663         | book_body book_paper_block {
 664                 $$->bookpaper_ = $2;
 665                 scm_gc_unprotect_object ($2->self_scm ());
 666         }
 667         | book_body score_block {
 668                 Score *score = $2;
 669                 $$->scores_.push (score);
 670                 scm_gc_unprotect_object (score->self_scm ());
 671         }
 672         | book_body Composite_music {
 673                 Music *music = $2;
 674                 Score *score
 675                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 676                 $$->scores_.push (score);
 677                 scm_gc_unprotect_object (music->self_scm ());
 678         }
 679         | lilypond_header {
 680                 $$->header_ = $1;
 681         }
 682         | book_body error {
 683
 684         }
 685         ;
 686
 687 score_block:
 688         SCORE {
 689                 THIS->push_spot ();
 690         }
 691         /*cont*/ '{' score_body '}'     {
 692                 THIS->pop_spot ();
 693                 $$ = $4;
 694         }
 695         ;
 696
 697 score_body:
 698         Music   {
 699                 $$ = new Score;
 700
 701                 $$->set_spot (THIS->here_input ());
 702                 SCM m = $1->self_scm ();
 703                 scm_gc_unprotect_object (m);
 704
 705                 /*
 706                         guh.
 707                 */
 708                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 709                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 710                         m = scm_call_1 (ly_car (check_funcs), m);
 711                 $$->music_ = m;
 712
 713         }
 714         | SCORE_IDENTIFIER {
 715                 $$ = new Score ( *unsmob_score ($1));
 716                 $$->set_spot (THIS->here_input ());
 717         }
 718         | score_body lilypond_header    {
 719                 $$->header_ = $2;
 720         }
 721         | score_body output_def {
 722                 $$->defs_.push ($2);
 723                 scm_gc_unprotect_object ($2->self_scm ());
 724         }
 725         | score_body error {
 726
 727         }
 728         ;
 729
 730
 731 /*
 732         MIDI
 733 */
 734 output_def:
 735         music_output_def_body '}' {
 736                 $$ = $1;
 737                 if ($1->parent_)
 738                         THIS->lexer_->remove_scope ();
 739
 740                 THIS->lexer_->remove_scope ();
 741                 THIS->lexer_->pop_state ();
 742         }
 743         ;
 744
 745 music_output_def_head:
 746         MIDI    {
 747                 Output_def *p = get_midi (THIS);
 748                 $$ = p;
 749                 THIS->lexer_->add_scope (p->scope_);
 750         }
 751         | PAPER         {
 752                 Output_def* p = get_paper (THIS);
 753
 754                 if (p->parent_)
 755                         THIS->lexer_->add_scope (p->parent_->scope_);
 756
 757                 THIS->lexer_->add_scope (p->scope_);
 758                 $$ = p;
 759         }
 760         ;
 761
 762
 763 music_output_def_body:
 764         music_output_def_head '{' {
 765                 $$ = $1;
 766                 $$->input_origin_.set_spot (THIS->here_input ());
 767                 THIS->lexer_->push_initial_state ();
 768         }
 769         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 770                 scm_gc_unprotect_object ($1->self_scm ());
 771                 Output_def *o = unsmob_output_def ($3);
 772                 o->input_origin_.set_spot (THIS->here_input ());
 773                 $$ = o;
 774                 THIS->lexer_->remove_scope ();
 775                 THIS->lexer_->add_scope (o->scope_);
 776                 THIS->lexer_->push_initial_state ();
 777         }
 778         | music_output_def_body assignment  {
 779
 780         }
 781         | music_output_def_body context_def_spec_block  {
 782                 assign_context_def ($$, $2);
 783         }
 784         | music_output_def_body tempo_event  {
 785                 /*
 786                         junk this ? there already is tempo stuff in
 787                         music.
 788                 */
 789                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 790                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 791                 set_tempo ($$, d->get_length (), m);
 792                 scm_gc_unprotect_object ($2->self_scm ());
 793         }
 794         | music_output_def_body error {
 795
 796         }
 797         ;
 798
 799 tempo_event:
 800         TEMPO steno_duration '=' bare_unsigned  {
 801                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 802                 $$->set_property ("tempo-unit", $2);
 803                 $$->set_property ("metronome-count", scm_int2num ( $4));
 804         }
 805         ;
 806
 807 /*
 808 The representation of a  list is the
 809
 810   (LIST . LAST-CONS)
 811
 812  to have  efficient append.
 813 */
 814 Music_list:
 815         /* empty */ {
 816                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 817         }
 818         | Music_list Music {
 819                 SCM s = $$;
 820                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 821                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 822                 if (ly_c_pair_p (ly_cdr (s)))
 823                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 824                 else
 825                         scm_set_car_x (s, c); /* set first cons */
 826                 scm_set_cdr_x (s, c);  /* remember last cell */
 827         }
 828         | Music_list embedded_scm {
 829         }
 830         | Music_list error {
 831         }
 832         ;
 833
 834
 835 Music:
 836         Simple_music
 837         | Composite_music
 838         ;
 839
 840 Alternative_music:
 841         /* empty */ {
 842                 $$ = SCM_EOL;
 843         }
 844         | ALTERNATIVE '{' Music_list '}' {
 845                 $$ = $3;
 846         }
 847         ;
 848
 849
 850 Repeated_music:
 851         REPEAT simple_string bare_unsigned Music Alternative_music
 852         {
 853                 Music *beg = $4;
 854                 int times = $3;
 855                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 856                 if (times < scm_ilength (alts)) {
 857                   unsmob_music (ly_car (alts))
 858                     ->origin ()->warning (
 859                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 860                   alts = ly_truncate_list (times, alts);
 861                 }
 862
 863
 864                 SCM proc = ly_scheme_function ("make-repeated-music");
 865
 866                 SCM mus = scm_call_1 (proc, $2);
 867                 scm_gc_protect_object (mus); // UGH.
 868                 Music *r = unsmob_music (mus);
 869                 if (beg)
 870                         {
 871                         r-> set_property ("element", beg->self_scm ());
 872                         scm_gc_unprotect_object (beg->self_scm ());
 873                         }
 874                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 875
 876                 r-> set_property ("elements",alts);
 877                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 878                         /*
 879                         TODO: move this code to Scheme.
 880                         */
 881
 882                         /*
 883                         we can not get durations and other stuff correct down the line, so we have to
 884                         add to the duration log here.
 885                         */
 886                         SCM func = ly_scheme_function ("shift-duration-log");
 887
 888                         int dots = ($3 % 3) ? 0 : 1;
 889                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 890
 891                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 892
 893                         if (seq) {
 894                                 int list_len = scm_ilength (seq->music_list ());
 895                                 if (list_len != 2)
 896                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 897                                 shift -= 1;
 898                                 r->compress (Moment (Rational (1, list_len)));
 899                                 }
 900                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 901
 902                 }
 903                 r->set_spot (*$4->origin ());
 904
 905                 $$ = r;
 906         }
 907         ;
 908
 909 Sequential_music:
 910         SEQUENTIAL '{' Music_list '}'           {
 911                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 912                 $$->set_property ("elements", ly_car ($3));
 913                 $$->set_spot (THIS->here_input ());
 914         }
 915         | '{' Music_list '}'            {
 916                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 917                 $$->set_property ("elements", ly_car ($2));
 918                 $$->set_spot (THIS->here_input ());
 919         }
 920         ;
 921
 922 Simultaneous_music:
 923         SIMULTANEOUS '{' Music_list '}'{
 924                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 925                 $$->set_property ("elements", ly_car ($3));
 926                 $$->set_spot (THIS->here_input ());
 927
 928         }
 929         | simul_open Music_list simul_close     {
 930                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 931                 $$->set_property ("elements", ly_car ($2));
 932                 $$->set_spot (THIS->here_input ());
 933         }
 934         ;
 935
 936 Simple_music:
 937         event_chord             { $$ = $1; }
 938         | MUSIC_IDENTIFIER {
 939                 $$ = unsmob_music ($1);
 940         }
 941         | music_property_def
 942         | context_change
 943         ;
 944
 945
 946 optional_context_mod:
 947         /**/ { $$ = SCM_EOL; }
 948         | WITH { THIS->lexer_->push_initial_state (); }
 949         '{' context_mod_list '}'
 950         {
 951                 THIS->lexer_->pop_state ();
 952                 $$ = $4;
 953         }
 954         ;
 955
 956 context_mod_list:
 957         /* */  { $$ = SCM_EOL; }
 958         | context_mod_list context_mod  {
 959                  $$ = scm_cons ($2, $1);
 960         }
 961         ;
 962
 963
 964 Composite_music:
 965         Prefix_composite_music { $$ = $1; }
 966         | Grouped_music_list { $$ = $1; }
 967         ;
 968
 969 Grouped_music_list:
 970         Simultaneous_music              { $$ = $1; }
 971         | Sequential_music              { $$ = $1; }
 972         ;
 973
 974 Generic_prefix_music_scm:
 975         MUSIC_FUNCTION {
 976                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 977         }
 978         | MUSIC_FUNCTION_SCM {
 979                 THIS->push_spot ();
 980         } embedded_scm {
 981                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 982         }
 983         | MUSIC_FUNCTION_MUSIC {
 984                 THIS->push_spot ();
 985         } Music {
 986                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 987                 scm_gc_unprotect_object ($3->self_scm ());
 988         }
 989         | MUSIC_FUNCTION_SCM_MUSIC {
 990                 THIS->push_spot ();
 991         }  embedded_scm Music {
 992                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 993                 scm_gc_unprotect_object ($4->self_scm ());
 994         }
 995         | MUSIC_FUNCTION_MUSIC_MUSIC {
 996                 THIS->push_spot ();
 997         }  Music  Music {
 998                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 999                 scm_gc_unprotect_object ($3->self_scm ());
1000                 scm_gc_unprotect_object ($4->self_scm ());
1001         }
1002         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1003                 THIS->push_spot ();
1004         } embedded_scm Music Music {
1005                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1006                         $3, $4->self_scm (), $5->self_scm ());
1007                 scm_gc_unprotect_object ($5->self_scm ());
1008                 scm_gc_unprotect_object ($4->self_scm ());
1009         }
1010         ;
1011
1012 Generic_prefix_music:
1013         Generic_prefix_music_scm {
1014                 SCM func = ly_car ($1);
1015                 Input *loc = unsmob_input (ly_cadr ($1));
1016                 SCM args = ly_cddr ($1);
1017                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1018                 int k = 0;
1019                 bool ok  = true;
1020                 for (SCM s = sig, t = args;
1021                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1022                         s = ly_cdr (s), t = ly_cdr (t)) {
1023                         k++;
1024                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1025                         {
1026                                 loc->error (_f ("Argument %d failed typecheck", k));
1027                                 THIS->error_level_ = 1;
1028                                 ok = false;
1029                         }
1030                 }
1031                 SCM m = SCM_EOL;
1032                 if (ok)
1033                         m = scm_apply_0 (func, ly_cdr ($1));
1034                 if (unsmob_music (m))
1035                         {
1036                         $$ = unsmob_music (m);
1037                         scm_gc_protect_object (m);
1038                         }
1039                 else
1040                         {
1041                         if (ok)
1042                                 loc->error (_ ("Music head function should return Music object."));
1043                         $$ = MY_MAKE_MUSIC ("Music");
1044                         }
1045                 $$->set_spot (*loc);
1046         }
1047         ;
1048
1049
1050 Prefix_composite_music:
1051         Generic_prefix_music {
1052                 $$ = $1;
1053         }
1054         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1055                 $$ = context_spec_music ($2, $4, $6, $5);
1056
1057         }
1058         | CONTEXT simple_string optional_context_mod Music {
1059                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1060         }
1061         | NEWCONTEXT simple_string optional_context_mod Music {
1062                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1063                         $3);
1064         }
1065
1066         | TIMES {
1067                 THIS->push_spot ();
1068         }
1069         /* CONTINUED */
1070                 fraction Music
1071
1072         {
1073                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1074                 Music *mp = $4;
1075
1076                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1077                 $$->set_spot (THIS->pop_spot ());
1078
1079                 $$->set_property ("element", mp->self_scm ());
1080                 scm_gc_unprotect_object (mp->self_scm ());
1081                 $$->set_property ("numerator", scm_int2num (n));
1082                 $$->set_property ("denominator", scm_int2num (d));
1083                 $$->compress (Moment (Rational (n,d)));
1084
1085         }
1086         | Repeated_music                { $$ = $1; }
1087         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1088                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1089                 Music *p = $4;
1090                 Pitch from = *unsmob_pitch ($2);
1091                 Pitch to = *unsmob_pitch ($3);
1092
1093                 p->transpose (interval (from, to));
1094                 $$->set_property ("element", p->self_scm ());
1095                 scm_gc_unprotect_object (p->self_scm ());
1096         }
1097         | NOTES
1098                 {
1099                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1100                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1101         }
1102         Music
1103                 { $$ = $3;
1104                   THIS->lexer_->pop_state ();
1105                 }
1106         | DRUMS
1107                 {
1108                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1109                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1110         }
1111         /* FIXME: This used to be: */
1112         Music
1113 /*      Grouped_music_list */
1114                 { $$ = $3;
1115                   THIS->lexer_->pop_state ();
1116                 }
1117         | FIGURES
1118                 { THIS->lexer_->push_figuredbass_state (); }
1119         /* FIXME: This used to be:
1120         Music
1121         but that breaks web build
1122         */
1123         Grouped_music_list
1124                 {
1125                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1126                   chm->set_property ("element", $3->self_scm ());
1127                   $$ = chm;
1128                   scm_gc_unprotect_object ($3->self_scm ());
1129
1130                   THIS->lexer_->pop_state ();
1131         }
1132         | CHORDS {
1133                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1134                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1135                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1136                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1137
1138         }
1139         /* FIXME:
1140         Music
1141 */
1142         Grouped_music_list
1143         {
1144                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1145                   chm->set_property ("element", $3->self_scm ());
1146                   scm_gc_unprotect_object ($3->self_scm ());
1147                   $$ = chm;
1148
1149                   THIS->lexer_->pop_state ();
1150         }
1151         | LYRICS
1152                 { THIS->lexer_->push_lyric_state (); }
1153         /* FIXME:
1154         Music
1155 */
1156         Grouped_music_list
1157                 {
1158                   $$ = $3;
1159                   THIS->lexer_->pop_state ();
1160         }
1161         | relative_music        { $$ = $1; }
1162         | re_rhythmed_music     { $$ = $1; }
1163         | TAG embedded_scm Music {
1164                 tag_music ($3, $2, THIS->here_input ());
1165                 $$ = $3;
1166         }
1167         ;
1168
1169 relative_music:
1170         RELATIVE absolute_pitch Music {
1171                 Music *m = $3;
1172                 Pitch start = *unsmob_pitch ($2);
1173                 $$ = make_music_relative (start, m);
1174                 scm_gc_unprotect_object (m->self_scm ());
1175         }
1176         | RELATIVE Composite_music {
1177                 Music *m = $2;
1178                 /* FIXME: why is octave==0 and default not middleC? */
1179                 Pitch middle_c (-1, 0, 0);
1180                 $$ = make_music_relative (middle_c, m);
1181                 scm_gc_unprotect_object (m->self_scm ());
1182         }
1183         ;
1184
1185 new_lyrics:
1186         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1187         /*cont */
1188         Grouped_music_list {
1189         /* Can also use Music at the expensive of two S/Rs similar to
1190            \repeat \alternative */
1191                 THIS->lexer_->pop_state ();
1192 #if 0
1193                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1194                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1195                 $$ = music;
1196 #else
1197                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1198 #endif
1199         }
1200         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1201         Grouped_music_list {
1202                 THIS->lexer_->pop_state ();
1203                 $$ = scm_cons ($4->self_scm (), $1);
1204         }
1205         ;
1206
1207 re_rhythmed_music:
1208         Grouped_music_list new_lyrics {
1209
1210                 /* FIXME: should find out uniqueXXX name from music */
1211                 SCM name = $1->get_property ("context-id");
1212                 //if (name == SCM_EOL)
1213                 if (!ly_c_string_p (name))
1214                         name = scm_makfrom0str ("");
1215
1216                 SCM context = scm_makfrom0str ("Lyrics");
1217                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1218
1219                 SCM lst = SCM_EOL;
1220                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1221                 {
1222                         Music *music = unsmob_music (ly_car (s));
1223                         Music *com = make_lyric_combine_music (name, music);
1224                         Music *csm = context_spec_music (context,
1225                                 get_next_unique_context (), com, SCM_EOL);
1226                         lst = scm_cons (csm->self_scm (), lst);
1227                 }
1228                 /* FIXME: only first lyric music is accepted,
1229                           the rest is junked */
1230                 all->set_property ("elements", scm_cons ($1->self_scm (),
1231                         lst));
1232                 $$ = all;
1233                 scm_gc_unprotect_object ($1->self_scm ());
1234         }
1235         | LYRICSTO string Music {
1236                 Music *music = $3;
1237                 SCM name = $2;
1238                 $$ = make_lyric_combine_music (name, music);
1239                 scm_gc_unprotect_object (music->self_scm ());
1240         }
1241         ;
1242
1243 context_change:
1244         CHANGE STRING '=' STRING  {
1245                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1246                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1247                 t-> set_property ("change-to-id", $4);
1248
1249                 $$ = t;
1250                 $$->set_spot (THIS->here_input ());
1251         }
1252         ;
1253
1254 property_operation:
1255         STRING '=' scalar {
1256                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1257                         scm_string_to_symbol ($1), $3);
1258         }
1259         | UNSET simple_string {
1260                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1261                         scm_string_to_symbol ($2));
1262         }
1263         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1264                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1265                         scm_string_to_symbol ($2), $3, $5);
1266         }
1267         | REVERT simple_string embedded_scm {
1268                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1269                         scm_string_to_symbol ($2), $3);
1270         }
1271         ;
1272
1273 context_def_mod:
1274         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1275         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1276         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1277
1278         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1279         | DENIES { $$ = ly_symbol2scm ("denies"); }
1280
1281         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1282         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1283         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1284         | NAME { $$ = ly_symbol2scm ("context-name"); }
1285         ;
1286
1287 context_mod:
1288         property_operation { $$ = $1; }
1289         | context_def_mod STRING {
1290                 $$ = scm_list_2 ($1, $2);
1291         }
1292         ;
1293
1294 context_prop_spec:
1295         simple_string {
1296                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1297                         scm_string_to_symbol ($1));
1298         }
1299         | simple_string '.' simple_string {
1300                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1301                         scm_string_to_symbol ($3));
1302         }
1303         ;
1304
1305 music_property_def:
1306         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1307                 $$ = property_op_to_music (scm_list_4 (
1308                         ly_symbol2scm ("poppush"),
1309                         ly_cadr ($2),
1310                         $3, $5));
1311                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1312         }
1313         | REVERT context_prop_spec embedded_scm {
1314                 $$ = property_op_to_music (scm_list_3 (
1315                         ly_symbol2scm ("pop"),
1316                         ly_cadr ($2),
1317                         $3));
1318
1319                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1320         }
1321         | SET context_prop_spec '=' scalar {
1322                 $$ = property_op_to_music (scm_list_3 (
1323                         ly_symbol2scm ("assign"),
1324                         ly_cadr ($2),
1325                         $4));
1326                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1327         }
1328         | UNSET context_prop_spec {
1329                 $$ = property_op_to_music (scm_list_2 (
1330                         ly_symbol2scm ("unset"),
1331                         ly_cadr ($2)));
1332                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1333         }
1334         | ONCE music_property_def {
1335                 SCM e = $2->get_property ("element");
1336                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1337                 $$ = $2;
1338
1339         }
1340         ;
1341
1342
1343 string:
1344         STRING {
1345                 $$ = $1;
1346         }
1347         | STRING_IDENTIFIER {
1348                 $$ = $1;
1349         }
1350         | string '+' string {
1351                 $$ = scm_string_append (scm_list_2 ($1, $3));
1352         }
1353         ;
1354
1355 simple_string: STRING {
1356         }
1357         | LYRICS_STRING {
1358         }
1359         ;
1360
1361 scalar: string {
1362         }
1363         | LYRICS_STRING {
1364         }
1365         | bare_int {
1366                 $$ = scm_int2num ($1);
1367         }
1368         | embedded_scm {
1369         }
1370         | full_markup {
1371         }
1372         | DIGIT {
1373                 $$ = scm_int2num ($1);
1374         }
1375         ;
1376
1377 /*
1378 FIXME: remove or fix this comment.  What is `This'?
1379
1380 This is a trick:
1381
1382 Adding pre_events to the simple_element
1383 makes the choice between
1384
1385   string:  STRING
1386
1387 and
1388
1389   simple_element: STRING
1390
1391 a single shift/reduction conflict.
1392
1393 nevertheless, this is not very clean, and we should find a different
1394 solution.
1395
1396 */
1397 pre_events: {
1398                 THIS->push_spot ();
1399         }
1400         ;
1401
1402 event_chord:
1403         pre_events simple_element post_events   {
1404                 SCM elts = $2-> get_property ("elements");
1405
1406                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1407
1408                 $2->set_property ("elements", elts);
1409                 $$ = $2;
1410         }
1411         | command_element
1412         | note_chord_element
1413         ;
1414
1415
1416 note_chord_element:
1417         chord_body optional_notemode_duration post_events
1418         {
1419                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1420                 SCM es = $1->get_property ("elements");
1421                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1422
1423                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1424                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1425                 es = ly_append2 (es, postevs);
1426
1427                 $1-> set_property ("elements", es);
1428                 $$ = $1;
1429         }
1430         ;
1431
1432 chord_open: '<'
1433         ;
1434
1435 chord_close: '>'
1436         ;
1437
1438 simul_open: DOUBLE_ANGLE_OPEN
1439         ;
1440
1441 simul_close: DOUBLE_ANGLE_CLOSE
1442         ;
1443
1444 chord_body:
1445         chord_open chord_body_elements chord_close
1446         {
1447                 $$ = MY_MAKE_MUSIC ("EventChord");
1448                 $$->set_property ("elements",
1449                         scm_reverse_x ($2, SCM_EOL));
1450         }
1451         ;
1452
1453 chord_body_elements:
1454         /* empty */             { $$ = SCM_EOL; }
1455         | chord_body_elements chord_body_element {
1456                 $$ = scm_cons ($2->self_scm (), $1);
1457                 scm_gc_unprotect_object ($2->self_scm ());
1458         }
1459         ;
1460
1461 chord_body_element:
1462         pitch exclamations questions post_events
1463         {
1464                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1465                 n->set_property ("pitch", $1);
1466                 if ($3 % 2)
1467                         n->set_property ("cautionary", SCM_BOOL_T);
1468                 if ($2 % 2 || $3 % 2)
1469                         n->set_property ("force-accidental", SCM_BOOL_T);
1470
1471                 if (ly_c_pair_p ($4)) {
1472                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1473                         n->set_property ("articulations", arts);
1474                 }
1475                 $$ = n;
1476         }
1477         | DRUM_PITCH post_events {
1478                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1479                 n->set_property ("duration", $2);
1480                 n->set_property ("drum-type", $1);
1481                 n->set_spot (THIS->here_input ());
1482
1483                 if (ly_c_pair_p ($2)) {
1484                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1485                         n->set_property ("articulations", arts);
1486                 }
1487                 $$ = n;
1488         }
1489         ;
1490
1491 add_quote:
1492         ADDQUOTE string Music {
1493                 SCM adder = ly_scheme_function ("add-quotable");
1494
1495                 scm_call_2 (adder, $2, $3->self_scm ());
1496                 scm_gc_unprotect_object ($3->self_scm ());
1497         }
1498         ;
1499
1500 command_element:
1501         command_req {
1502                 $$ = MY_MAKE_MUSIC ("EventChord");
1503                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1504                 scm_gc_unprotect_object ($1->self_scm ());
1505
1506                 $$-> set_spot (THIS->here_input ());
1507                 $1-> set_spot (THIS->here_input ());
1508         }
1509         | SKIP duration_length {
1510                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1511                 skip->set_property ("duration", $2);
1512
1513                 $$ = skip;
1514         }
1515         | QUOTE STRING duration_length {
1516                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1517                 SCM evs = SCM_EOL;
1518                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1519                 {
1520                         SCM key = $2; // use symbol?
1521                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1522                 }
1523                 Music *quote = 0;
1524                 if (ly_c_vector_p (evs))
1525                 {
1526                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1527                         quote->set_property ("duration", $3);
1528                         quote->set_property ("quoted-events", evs);
1529                 } else {
1530                         THIS->here_input ().warning (_f ("Can\'t find music"));
1531                         quote = MY_MAKE_MUSIC ("Event");
1532                 }
1533                 quote->set_spot (THIS->here_input ());
1534                 $$ = quote;
1535         }
1536         | OCTAVE { THIS->push_spot (); }
1537           pitch {
1538                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1539                 $$ = m;
1540                 $$->set_spot (THIS->pop_spot ());
1541                 $$->set_property ("pitch", $3);
1542         }
1543         | E_LEFTSQUARE {
1544                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1545                 m->set_property ("span-direction", scm_int2num (START));
1546                 m->set_spot (THIS->here_input ());
1547
1548                 $$ = MY_MAKE_MUSIC ("EventChord");
1549                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1550                 scm_gc_unprotect_object (m->self_scm ());
1551                 $$->set_spot (THIS->here_input ());
1552         }
1553         | E_RIGHTSQUARE {
1554                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1555                 m->set_property ("span-direction", scm_int2num (STOP));
1556                 m->set_spot (THIS->here_input ());
1557
1558                 $$ = MY_MAKE_MUSIC ("EventChord");
1559                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1560                 $$->set_spot (THIS->here_input ());
1561                 scm_gc_unprotect_object (m->self_scm ());
1562         }
1563         | E_BACKSLASH {
1564                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1565                 $$->set_spot (THIS->here_input ());
1566         }
1567         | '|'      {
1568                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1569
1570                 if (Music * m = unsmob_music (pipe))
1571                         $$ = m->clone ();
1572                 else
1573                         $$ = MY_MAKE_MUSIC ("BarCheck");
1574
1575                 $$->set_spot (THIS->here_input ());
1576         }
1577         | TRANSPOSITION pitch {
1578                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1579                                         $2);
1580                 $$->set_spot (THIS-> here_input ());
1581                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1582                         $$, SCM_EOL);
1583         }
1584         | BAR STRING                    {
1585                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1586
1587                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1588                                         t, SCM_EOL);
1589                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1590                 $$->set_spot (THIS->here_input ());
1591                 t->set_spot (THIS->here_input ());
1592         }
1593         | PARTIAL duration_length       {
1594                 Moment m = - unsmob_duration ($2)->get_length ();
1595                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1596                 p->set_spot (THIS->here_input ());
1597                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1598                                         p, SCM_EOL);
1599                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1600                                         p, SCM_EOL);
1601                 $$ = p;
1602         }
1603         | CLEF STRING  {
1604                 SCM proc = ly_scheme_function ("make-clef-set");
1605
1606                 SCM result = scm_call_1 (proc, $2);
1607                 scm_gc_protect_object (result);
1608                 $$ = unsmob_music (result);
1609         }
1610         | TIME_T fraction  {
1611                 SCM proc= ly_scheme_function ("make-time-signature-set");
1612
1613                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1614                 scm_gc_protect_object (result);
1615                 $$ = unsmob_music (result);
1616         }
1617         | MARK scalar {
1618                 SCM proc = ly_scheme_function ("make-mark-set");
1619
1620                 SCM result = scm_call_1 (proc, $2);
1621                 scm_gc_protect_object (result);
1622                 $$ = unsmob_music (result);
1623         }
1624         ;
1625
1626 command_req:
1627         E_TILDE {
1628                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1629         }
1630         | MARK DEFAULT  {
1631                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1632                 $$ = m;
1633         }
1634         | tempo_event {
1635                 $$ = $1;
1636         }
1637         | KEY DEFAULT {
1638                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1639                 $$ = key;
1640         }
1641         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1642
1643                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1644                 if (scm_ilength ($3) > 0)
1645                 {
1646                         key->set_property ("pitch-alist", $3);
1647                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1648                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1649                 } else {
1650                         THIS->parser_error (_ ("Second argument must be pitch list."));
1651                 }
1652
1653                 $$ = key;
1654         }
1655         ;
1656
1657 post_events:
1658         /* empty */ {
1659                 $$ = SCM_EOL;
1660         }
1661         | post_events post_event {
1662                 $2->set_spot (THIS->here_input ());
1663                 $$ = scm_cons ($2->self_scm (), $$);
1664                 scm_gc_unprotect_object ($2->self_scm ());
1665         }
1666         | post_events tagged_post_event {
1667                 $2 -> set_spot (THIS->here_input ());
1668                 $$ = scm_cons ($2->self_scm (), $$);
1669                 scm_gc_unprotect_object ($2->self_scm ());
1670         }
1671         ;
1672
1673
1674 tagged_post_event:
1675         '-' TAG embedded_scm post_event {
1676                 tag_music ($4, $3, THIS->here_input ());
1677                 $$ = $4;
1678         }
1679         ;
1680
1681 post_event:
1682         direction_less_event {
1683                 $$ = $1;
1684         }
1685         | HYPHEN {
1686                 if (!THIS->lexer_->is_lyric_state ())
1687                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1688                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1689         }
1690         | EXTENDER {
1691                 if (!THIS->lexer_->is_lyric_state ())
1692                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1693                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1694         }
1695         | script_dir direction_reqd_event {
1696                 if ($1)
1697                         $2->set_property ("direction", scm_int2num ($1));
1698                 $$ = $2;
1699         }
1700         | script_dir direction_less_event {
1701                 if ($1)
1702                         $2->set_property ("direction", scm_int2num ($1));
1703                 $$ = $2;
1704         }
1705         | string_number_event
1706         ;
1707
1708 string_number_event:
1709         E_UNSIGNED {
1710                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1711                 s->set_property ("string-number", scm_int2num ($1));
1712                 s->set_spot (THIS->here_input ());
1713                 $$ = s;
1714         }
1715         ;
1716
1717
1718 direction_less_event:
1719         '['  {
1720
1721
1722 /*
1723
1724 TODO: should take all these defs out of the parser, adn make use
1725 configurable, i.e.
1726
1727
1728 (set-articulation '~ "trill")
1729
1730 */
1731                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1732                 m->set_spot (THIS->here_input ());
1733                 m->set_property ("span-direction", scm_int2num (START));
1734                 $$ = m;
1735         }
1736         | ']'  {
1737                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1738                 m->set_spot (THIS->here_input ());
1739                 m->set_property ("span-direction", scm_int2num (STOP));
1740                 $$ = m;
1741         }
1742         | '~' {
1743                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1744                 m->set_spot (THIS->here_input ());
1745                 $$ = m;
1746         }
1747         | close_event {
1748                 $$ = $1;
1749                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1750                         scm_int2num (START));
1751         }
1752         | open_event {
1753                 $$ = $1;
1754                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1755                         scm_int2num (STOP));
1756         }
1757         | EVENT_IDENTIFIER      {
1758                 $$ = unsmob_music ($1);
1759         }
1760         | tremolo_type  {
1761                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1762                a->set_spot (THIS->here_input ());
1763                a->set_property ("tremolo-type", scm_int2num ($1));
1764                $$ = a;
1765         }
1766         ;
1767
1768 direction_reqd_event:
1769         gen_text_def {
1770                 $$ = $1;
1771         }
1772         | script_abbreviation {
1773                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1774                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1775                 if (ly_c_string_p (s))
1776                         a->set_property ("articulation-type", s);
1777                 else THIS->parser_error (_ ("Expecting string as script definition"));
1778                 $$ = a;
1779         }
1780         ;
1781
1782 oct_check:
1783         /**/ { $$ = SCM_EOL; }
1784         | '='  { $$ = scm_int2num (0); }
1785         | '=' sub_quotes { $$ = scm_int2num ($2); }
1786         | '=' sup_quotes { $$ = scm_int2num ($2); }
1787         ;
1788
1789 sup_quotes:
1790         '\'' {
1791                 $$ = 1;
1792         }
1793         | sup_quotes '\'' {
1794                 $$ ++;
1795         }
1796         ;
1797
1798 sub_quotes:
1799         ',' {
1800                 $$ = 1;
1801         }
1802         | sub_quotes ',' {
1803                 $$++;
1804         }
1805         ;
1806
1807 steno_pitch:
1808         NOTENAME_PITCH  {
1809                 $$ = $1;
1810         }
1811         | NOTENAME_PITCH sup_quotes     {
1812                 Pitch p = *unsmob_pitch ($1);
1813                 p = p.transposed (Pitch ($2,0,0));
1814                 $$ = p.smobbed_copy ();
1815         }
1816         | NOTENAME_PITCH sub_quotes      {
1817                 Pitch p =* unsmob_pitch ($1);
1818                 p = p.transposed (Pitch (-$2,0,0));
1819                 $$ = p.smobbed_copy ();
1820         }
1821         ;
1822
1823 /*
1824 ugh. duplication
1825 */
1826
1827 steno_tonic_pitch:
1828         TONICNAME_PITCH {
1829                 $$ = $1;
1830         }
1831         | TONICNAME_PITCH sup_quotes    {
1832                 Pitch p = *unsmob_pitch ($1);
1833                 p = p.transposed (Pitch ($2,0,0));
1834                 $$ = p.smobbed_copy ();
1835         }
1836         | TONICNAME_PITCH sub_quotes     {
1837                 Pitch p =* unsmob_pitch ($1);
1838
1839                 p = p.transposed (Pitch (-$2,0,0));
1840                 $$ = p.smobbed_copy ();
1841         }
1842         ;
1843
1844 pitch:
1845         steno_pitch {
1846                 $$ = $1;
1847         }
1848         ;
1849
1850 pitch_also_in_chords:
1851         pitch
1852         | steno_tonic_pitch
1853         ;
1854
1855 close_event:
1856         '('     {
1857                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1858                 $$ = s;
1859                 s->set_spot (THIS->here_input ());
1860         }
1861         | E_OPEN        {
1862                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1863                 $$ = s;
1864                 s->set_spot (THIS->here_input ());
1865         }
1866         | E_SMALLER {
1867                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1868                 $$ = s;
1869                 s->set_spot (THIS->here_input ());
1870         }
1871         | E_BIGGER {
1872                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1873                 $$ = s;
1874                 s->set_spot (THIS->here_input ());
1875         }
1876         ;
1877
1878
1879 open_event:
1880         E_EXCLAMATION   {
1881                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1882                 s->set_spot (THIS->here_input ());
1883
1884                 $$ = s;
1885         }
1886         | ')'   {
1887                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1888                 $$ = s;
1889                 s->set_spot (THIS->here_input ());
1890
1891         }
1892         | E_CLOSE       {
1893                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1894                 $$ = s;
1895                 s->set_property ("span-type",
1896                         scm_makfrom0str ("phrasing-slur"));
1897                 s->set_spot (THIS->here_input ());
1898         }
1899         ;
1900
1901 gen_text_def:
1902         full_markup {
1903                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1904                 t->set_property ("text", $1);
1905                 t->set_spot (THIS->here_input ());
1906                 $$ = t;
1907         }
1908         | string {
1909                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1910                 t->set_property ("text",
1911                         make_simple_markup (THIS->lexer_->encoding (), $1));
1912                 t->set_spot (THIS->here_input ());
1913                 $$ = t;
1914
1915         }
1916         | DIGIT {
1917                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1918                 t->set_property ("digit", scm_int2num ($1));
1919                 t->set_spot (THIS->here_input ());
1920                 $$ = t;
1921         }
1922         ;
1923
1924 script_abbreviation:
1925         '^'             {
1926                 $$ = scm_makfrom0str ("Hat");
1927         }
1928         | '+'           {
1929                 $$ = scm_makfrom0str ("Plus");
1930         }
1931         | '-'           {
1932                 $$ = scm_makfrom0str ("Dash");
1933         }
1934         | '|'           {
1935                 $$ = scm_makfrom0str ("Bar");
1936         }
1937         | '>'           {
1938                 $$ = scm_makfrom0str ("Larger");
1939         }
1940         | '.'           {
1941                 $$ = scm_makfrom0str ("Dot");
1942         }
1943         | '_' {
1944                 $$ = scm_makfrom0str ("Underscore");
1945         }
1946         ;
1947
1948 script_dir:
1949         '_'     { $$ = DOWN; }
1950         | '^'   { $$ = UP; }
1951         | '-'   { $$ = CENTER; }
1952         ;
1953
1954
1955 absolute_pitch:
1956         steno_pitch     {
1957                 $$ = $1;
1958         }
1959         ;
1960
1961 duration_length:
1962         multiplied_duration {
1963                 $$ = $1;
1964         }
1965         ;
1966
1967 optional_notemode_duration:
1968         {
1969                 Duration dd = THIS->default_duration_;
1970                 $$ = dd.smobbed_copy ();
1971
1972                 THIS->beam_check ($$);
1973         }
1974         | multiplied_duration   {
1975                 $$ = $1;
1976                 THIS->default_duration_ = *unsmob_duration ($$);
1977
1978                 THIS->beam_check ($$);
1979         }
1980         ;
1981
1982 steno_duration:
1983         bare_unsigned dots              {
1984                 int len = 0;
1985                 if (!is_duration ($1))
1986                         THIS->parser_error (_f ("not a duration: %d", $1));
1987                 else
1988                         len = intlog2 ($1);
1989
1990                 $$ = Duration (len, $2).smobbed_copy ();
1991         }
1992         | DURATION_IDENTIFIER dots      {
1993                 Duration *d = unsmob_duration ($1);
1994                 Duration k (d->duration_log (), d->dot_count () + $2);
1995                 *d = k;
1996                 $$ = $1;
1997         }
1998         ;
1999
2000 multiplied_duration:
2001         steno_duration {
2002                 $$ = $1;
2003         }
2004         | multiplied_duration '*' bare_unsigned {
2005                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2006         }
2007         | multiplied_duration '*' FRACTION {
2008                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2009
2010                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2011         }
2012         ;
2013
2014 fraction:
2015         FRACTION { $$ = $1; }
2016         | UNSIGNED '/' UNSIGNED {
2017                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2018         }
2019         ;
2020
2021 dots:
2022         /* empty */     {
2023                 $$ = 0;
2024         }
2025         | dots '.' {
2026                 $$ ++;
2027         }
2028         ;
2029
2030 tremolo_type:
2031         ':'     {
2032                 $$ = 0;
2033         }
2034         | ':' bare_unsigned {
2035                 if (!is_duration ($2))
2036                         THIS->parser_error (_f ("not a duration: %d", $2));
2037                 $$ = $2;
2038         }
2039         ;
2040
2041 bass_number:
2042         DIGIT   {
2043                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2044                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2045                                 $$);
2046         }
2047         | UNSIGNED {
2048                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2049                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2050                                 $$);
2051         }
2052         | STRING { $$ = $1; }
2053         ;
2054
2055 bass_mod:
2056         '-'     { $$ = -2; }
2057         | '+'   { $$ = 2; }
2058         | '!'   { $$ = 0; }
2059         ;
2060
2061 bass_figure:
2062         FIGURE_SPACE {
2063                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2064                 $$ = bfr->self_scm ();
2065                 scm_gc_unprotect_object ($$);
2066         }
2067         | bass_number  {
2068                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2069                 $$ = bfr->self_scm ();
2070
2071                 bfr->set_property ("figure", $1);
2072
2073                 scm_gc_unprotect_object ($$);
2074         }
2075         | bass_figure bass_mod {
2076                 Music *m = unsmob_music ($1);
2077                 if ($2) {
2078                         SCM salter = m->get_property ("alteration");
2079                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2080                         m->set_property ("alteration",
2081                                 scm_int2num (alter + $2));
2082                 } else {
2083                         m->set_property ("alteration", scm_int2num (0));
2084                 }
2085         }
2086         ;
2087
2088 br_bass_figure:
2089         '[' bass_figure {
2090                 $$ = $2;
2091                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2092         }
2093         | bass_figure   {
2094                 $$ = $1;
2095         }
2096         | br_bass_figure ']' {
2097                 $$ = $1;
2098                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2099         }
2100         ;
2101
2102 figure_list:
2103         /**/            {
2104                 $$ = SCM_EOL;
2105         }
2106         | figure_list br_bass_figure {
2107                 $$ = scm_cons ($2, $1);
2108         }
2109         ;
2110
2111 figure_spec:
2112         FIGURE_OPEN figure_list FIGURE_CLOSE {
2113                 Music *m = MY_MAKE_MUSIC ("EventChord");
2114                 $2 = scm_reverse_x ($2, SCM_EOL);
2115                 m->set_property ("elements", $2);
2116                 $$ = m->self_scm ();
2117         }
2118         ;
2119
2120
2121 optional_rest:
2122         /**/   { $$ = 0; }
2123         | REST { $$ = 1; }
2124         ;
2125
2126 simple_element:
2127         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2128
2129                 Input i = THIS->pop_spot ();
2130                 if (!THIS->lexer_->is_note_state ())
2131                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2132
2133                 Music *n = 0;
2134                 if ($6)
2135                         n = MY_MAKE_MUSIC ("RestEvent");
2136                 else
2137                         n = MY_MAKE_MUSIC ("NoteEvent");
2138
2139                 n->set_property ("pitch", $1);
2140                 n->set_property ("duration", $5);
2141
2142                 if (ly_c_number_p ($4))
2143                 {
2144                         int q = ly_scm2int ($4);
2145                         n->set_property ("absolute-octave", scm_int2num (q-1));
2146                 }
2147
2148                 if ($3 % 2)
2149                         n->set_property ("cautionary", SCM_BOOL_T);
2150                 if ($2 % 2 || $3 % 2)
2151                         n->set_property ("force-accidental", SCM_BOOL_T);
2152
2153                 Music *v = MY_MAKE_MUSIC ("EventChord");
2154                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2155                 scm_gc_unprotect_object (n->self_scm ());
2156
2157                 v->set_spot (i);
2158                 n->set_spot (i);
2159                 $$ = v;
2160         }
2161         | DRUM_PITCH optional_notemode_duration {
2162                 Input i = THIS->pop_spot ();
2163
2164                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2165                 n->set_property ("duration", $2);
2166                 n->set_property ("drum-type", $1);
2167
2168                 Music *v = MY_MAKE_MUSIC ("EventChord");
2169                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2170                 scm_gc_unprotect_object (n->self_scm ());
2171                 v->set_spot (i);
2172                 n->set_spot (i);
2173                 $$ = v;
2174
2175         }
2176         | figure_spec optional_notemode_duration {
2177                 Music *m = unsmob_music ($1);
2178                 Input i = THIS->pop_spot ();
2179                 m->set_spot (i);
2180                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2181                 {
2182                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2183                 }
2184                 $$ = m;
2185         }
2186         | RESTNAME optional_notemode_duration           {
2187
2188                 Input i = THIS->pop_spot ();
2189                 Music *ev = 0;
2190                 if (ly_scm2string ($1) == "s") {
2191                         /* Space */
2192                         ev = MY_MAKE_MUSIC ("SkipEvent");
2193                   }
2194                 else {
2195                         ev = MY_MAKE_MUSIC ("RestEvent");
2196
2197                     }
2198                 ev->set_property ("duration", $2);
2199                 ev->set_spot (i);
2200                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2201                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2202                 velt->set_spot (i);
2203
2204                 scm_gc_unprotect_object (ev->self_scm ());
2205
2206                 $$ = velt;
2207         }
2208         | MULTI_MEASURE_REST optional_notemode_duration         {
2209                 THIS->pop_spot ();
2210
2211                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2212                 SCM mus = scm_call_2 (proc, $2,
2213                         make_input (THIS->here_input ()));
2214                 scm_gc_protect_object (mus);
2215                 $$ = unsmob_music (mus);
2216         }
2217
2218         | lyric_element optional_notemode_duration      {
2219                 Input i = THIS->pop_spot ();
2220                 if (!THIS->lexer_->is_lyric_state ())
2221                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2222
2223                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2224                 lreq->set_property ("text", $1);
2225                 lreq->set_property ("duration",$2);
2226                 lreq->set_spot (i);
2227                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2228                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2229
2230                 $$= velt;
2231         }
2232         | new_chord {
2233                 THIS->pop_spot ();
2234
2235                 if (!THIS->lexer_->is_chord_state ())
2236                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2237                 $$ = unsmob_music ($1);
2238         }
2239         ;
2240
2241 lyric_element:
2242         /* FIXME: lyric flavoured markup would be better */
2243         full_markup {
2244         }
2245         | LYRICS_STRING {
2246         }
2247         ;
2248
2249 new_chord:
2250         steno_tonic_pitch optional_notemode_duration   {
2251                 $$ = make_chord ($1, $2, SCM_EOL);
2252         }
2253         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2254                 SCM its = scm_reverse_x ($4, SCM_EOL);
2255                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2256         }
2257         ;
2258
2259 chord_items:
2260         /**/ {
2261                 $$ = SCM_EOL;
2262         }
2263         | chord_items chord_item {
2264                 $$ = scm_cons ($2, $$);
2265         }
2266         ;
2267
2268 chord_separator:
2269         CHORD_COLON {
2270                 $$ = ly_symbol2scm ("chord-colon");
2271         }
2272         | CHORD_CARET {
2273                 $$ = ly_symbol2scm ("chord-caret");
2274         }
2275         | CHORD_SLASH steno_tonic_pitch {
2276                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2277         }
2278         | CHORD_BASS steno_tonic_pitch {
2279                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2280         }
2281         ;
2282
2283 chord_item:
2284         chord_separator {
2285                 $$ = $1;
2286         }
2287         | step_numbers {
2288                 $$ = scm_reverse_x ($1, SCM_EOL);
2289         }
2290         | CHORD_MODIFIER  {
2291                 $$ = $1;
2292         }
2293         ;
2294
2295 step_numbers:
2296         step_number { $$ = scm_cons ($1, SCM_EOL); }
2297         | step_numbers '.' step_number {
2298                 $$ = scm_cons ($3, $$);
2299         }
2300         ;
2301
2302 step_number:
2303         bare_unsigned {
2304                 $$ = make_chord_step ($1, 0);
2305         }
2306         | bare_unsigned '+' {
2307                 $$ = make_chord_step ($1, SHARP);
2308         }
2309         | bare_unsigned CHORD_MINUS {
2310                 $$ = make_chord_step ($1, FLAT);
2311         }
2312         ;
2313
2314 /*
2315         UTILITIES
2316
2317 TODO: should deprecate in favor of Scheme?
2318
2319  */
2320 number_expression:
2321         number_expression '+' number_term {
2322                 $$ = scm_sum ($1, $3);
2323         }
2324         | number_expression '-' number_term {
2325                 $$ = scm_difference ($1, $3);
2326         }
2327         | number_term
2328         ;
2329
2330 number_term:
2331         number_factor {
2332                 $$ = $1;
2333         }
2334         | number_factor '*' number_factor {
2335                 $$ = scm_product ($1, $3);
2336         }
2337         | number_factor '/' number_factor {
2338                 $$ = scm_divide ($1, $3);
2339         }
2340         ;
2341
2342 number_factor:
2343         '-'  number_factor { /* %prec UNARY_MINUS */
2344                 $$ = scm_difference ($2, SCM_UNDEFINED);
2345         }
2346         | bare_number
2347         ;
2348
2349
2350 bare_number:
2351         UNSIGNED        {
2352                 $$ = scm_int2num ($1);
2353         }
2354         | REAL          {
2355                 $$ = $1;
2356         }
2357         | NUMBER_IDENTIFIER             {
2358                 $$ = $1;
2359         }
2360         | REAL NUMBER_IDENTIFIER        {
2361                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2362         }
2363         | UNSIGNED NUMBER_IDENTIFIER    {
2364                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2365         }
2366         ;
2367
2368
2369 bare_unsigned:
2370         UNSIGNED {
2371                         $$ = $1;
2372         }
2373         | DIGIT {
2374                 $$ = $1;
2375         }
2376         ;
2377
2378 bare_int:
2379         bare_number {
2380                 if (scm_integer_p ($1) == SCM_BOOL_T)
2381                 {
2382                         int k = ly_scm2int ($1);
2383                         $$ = k;
2384                 } else
2385                 {
2386                         THIS->parser_error (_ ("need integer number arg"));
2387                         $$ = 0;
2388                 }
2389         }
2390         | '-' bare_int {
2391                 $$ = -$2;
2392         }
2393         ;
2394
2395 exclamations:
2396                 { $$ = 0; }
2397         | exclamations '!'      { $$ ++; }
2398         ;
2399
2400 questions:
2401                 { $$ = 0; }
2402         | questions '?' { $$ ++; }
2403         ;
2404
2405
2406
2407 full_markup:
2408         MARKUP_IDENTIFIER {
2409                 $$ = $1;
2410         }
2411         | MARKUP
2412                 { THIS->lexer_->push_markup_state (); }
2413         markup
2414                 { $$ = $3;
2415                   THIS->lexer_->pop_state ();
2416                 }
2417         ;
2418
2419
2420 /*
2421 This should be done more dynamically if possible.
2422 */
2423 markup:
2424         STRING {
2425                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2426         }
2427         | MARKUP_HEAD_EMPTY {
2428                 $$ = scm_list_1 ($1);
2429         }
2430         | MARKUP_HEAD_MARKUP0 markup {
2431                 $$ = scm_list_2 ($1, $2);
2432         }
2433         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2434                 $$ = scm_list_3 ($1, $2, $3);
2435         }
2436         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2437                 $$ = scm_list_3 ($1, $2, $3);
2438         }
2439         | markup_line {
2440                 $$ = $1;
2441         }
2442         | MARKUP_HEAD_LIST0 markup_list {
2443                 $$ = scm_list_2 ($1,$2);
2444         }
2445         | MARKUP_HEAD_SCM0 embedded_scm {
2446                 $$ = scm_list_2 ($1, $2);
2447         }
2448         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2449                 $$ = scm_list_4 ($1, $2, $3, $4);
2450         }
2451         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2452                 $$ = scm_list_4 ($1, $2, $3, $4);
2453         }
2454         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2455                 $$ = scm_list_3 ($1, $2, $3);
2456         }
2457         | MARKUP_IDENTIFIER {
2458                 $$ = $1;
2459         }
2460         | STRING_IDENTIFIER {
2461                 $$ = $1;
2462         }
2463         | {
2464                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2465                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2466         }
2467         /* cont */ score_block {
2468                 /* WIP this is a bit arbitrary,
2469                    we should also allow \book or Composite_music.
2470                    However, you'd typically want to change paper
2471                    settings, and need a \score block anyway.  */
2472
2473                 THIS->lexer_->pop_state ();
2474                 Score *score = $2;
2475                 Book *book = new Book;
2476                 book->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
2477                 book->scores_.push (score);
2478
2479                 Output_def *paper = get_paper (THIS);
2480                 book->bookpaper_ = get_bookpaper (THIS);
2481
2482                 SCM s = book->to_stencil (paper);
2483                 scm_gc_unprotect_object (score->self_scm ());
2484                 scm_gc_unprotect_object (book->self_scm ());
2485                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2486         }
2487         ;
2488
2489 markup_list:
2490         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2491         ;
2492
2493 markup_line:
2494         '{' markup_list_body '}' {
2495                 SCM line = ly_scheme_function ("line-markup");
2496
2497                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2498         }
2499         ;
2500
2501 markup_list_body:
2502         /**/ {  $$ = SCM_EOL; }
2503         | markup_list_body markup {
2504                 $$ = scm_cons ($2, $1);
2505         }
2506         ;
2507
2508
2509 %%
2510
2511 void
2512 My_lily_parser::set_yydebug (bool )
2513 {
2514 #if 0
2515         yydebug = 1;
2516 #endif
2517 }
2518
2519 void
2520 My_lily_parser::do_yyparse ()
2521 {
2522         yyparse ((void*)this);
2523 }
2524
2525
2526 /*
2527 Should make this optional?    It will also complain when you do
2528
2529         [s4]
2530
2531 which is entirely legitimate.
2532
2533 Or we can scrap it. Barchecks should detect wrong durations, and
2534 skipTypesetting speeds it up a lot.
2535 */
2536
2537 void
2538 My_lily_parser::beam_check (SCM dur)
2539 {
2540   Duration *d = unsmob_duration (dur);
2541   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2542     {
2543       Music *m = unsmob_music (last_beam_start_);
2544       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2545     }
2546   last_beam_start_ = SCM_EOL;
2547 }
2548
2549
2550
2551
2552 /*
2553
2554 It is a little strange to have this function in this file, but
2555 otherwise, we have to import music classes into the lexer.
2556
2557 */
2558 int
2559 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2560 {
2561         if (ly_c_string_p (sid)) {
2562                 *destination = sid;
2563                 return STRING_IDENTIFIER;
2564         } else if (ly_c_number_p (sid)) {
2565                 *destination = sid;
2566                 return NUMBER_IDENTIFIER;
2567         } else if (unsmob_context_def (sid)) {
2568                 *destination = unsmob_context_def (sid)->clone_scm ();
2569                 return CONTEXT_DEF_IDENTIFIER;
2570         } else if (unsmob_score (sid)) {
2571                 Score *score = new Score (*unsmob_score (sid));
2572                 *destination = score->self_scm ();
2573                 return SCORE_IDENTIFIER;
2574         } else if (Music *mus = unsmob_music (sid)) {
2575                 mus = mus->clone ();
2576                 *destination = mus->self_scm ();
2577                 unsmob_music (*destination)->
2578                         set_property ("origin", make_input (last_input_));
2579                 return dynamic_cast<Event*> (mus)
2580                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2581         } else if (unsmob_duration (sid)) {
2582                 *destination = unsmob_duration (sid)->smobbed_copy ();
2583                 return DURATION_IDENTIFIER;
2584         } else if (unsmob_output_def (sid)) {
2585                 Output_def *p = unsmob_output_def (sid);
2586                 p = p->clone ();
2587
2588                 *destination = p->self_scm ();
2589                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2590         } else if (Text_item::markup_p (sid)) {
2591                 *destination = sid;
2592                 return MARKUP_IDENTIFIER;
2593         }
2594
2595         return -1;
2596 }
2597
2598 Music *
2599 property_op_to_music (SCM op)
2600 {
2601         Music *m = 0;
2602         SCM tag = ly_car (op);
2603         SCM symbol = ly_cadr (op);
2604         SCM args = ly_cddr (op);
2605         SCM grob_val = SCM_UNDEFINED;
2606         SCM grob_sym = SCM_UNDEFINED;
2607         SCM val = SCM_UNDEFINED;
2608
2609         if (tag == ly_symbol2scm ("assign"))
2610                 {
2611                 m = MY_MAKE_MUSIC ("PropertySet");
2612                 val = ly_car (args);
2613                 }
2614         else if (tag == ly_symbol2scm ("unset"))
2615                 m = MY_MAKE_MUSIC ("PropertyUnset");
2616         else if (tag == ly_symbol2scm ("poppush")
2617                  || tag == ly_symbol2scm ("push"))
2618                 {
2619                 m = MY_MAKE_MUSIC ("OverrideProperty");
2620                 grob_sym = ly_car (args);
2621                 grob_val = ly_cadr (args);
2622                 }
2623         else if (tag == ly_symbol2scm ("pop")) {
2624                 m = MY_MAKE_MUSIC ("RevertProperty");
2625                 grob_sym = ly_car (args);
2626                 }
2627
2628         m->set_property ("symbol", symbol);
2629
2630         if (val != SCM_UNDEFINED)
2631                 m->set_property ("value", val);
2632         if (grob_val != SCM_UNDEFINED)
2633                 m->set_property ("grob-value", grob_val);
2634
2635         if (grob_sym != SCM_UNDEFINED)
2636                 {
2637                 bool itc = internal_type_checking_global_b;
2638                 /* UGH.
2639                 */
2640                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2641                 if (autobeam)
2642                         internal_type_checking_global_b = false;
2643                 m->set_property ("grob-property", grob_sym);
2644                 if (autobeam)
2645                         internal_type_checking_global_b = itc;
2646                 }
2647
2648         if (tag == ly_symbol2scm ("poppush"))
2649                 m->set_property ("pop-first", SCM_BOOL_T);
2650
2651
2652         return m;
2653 }
2654
2655 Music*
2656 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2657 {
2658         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2659
2660         csm->set_property ("element", m->self_scm ());
2661         scm_gc_unprotect_object (m->self_scm ());
2662
2663         csm->set_property ("context-type",
2664                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2665         csm->set_property ("property-operations", ops);
2666
2667         if (ly_c_string_p (id))
2668                 csm->set_property ("context-id", id);
2669         return csm;
2670 }
2671
2672 SCM
2673 get_next_unique_context ()
2674 {
2675         static int new_context_count;
2676         char s[1024];
2677         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2678         return scm_makfrom0str (s);
2679 }
2680