lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "translator-def.hh"
  14 #include "lily-guile.hh"
  15 #include "change-iterator.hh"
  16 #include "misc.hh"
  17 #include "my-lily-lexer.hh"
  18 #include "paper-def.hh"
  19 #include "midi-def.hh"
  20 #include "main.hh"
  21 #include "file-path.hh"
  22 #include "debug.hh"
  23 #include "dimensions.hh"
  24 #include "identifier.hh"
  25 #include "command-request.hh"
  26 #include "musical-request.hh"
  27 #include "my-lily-parser.hh"
  28 #include "context-specced-music.hh"
  29 #include "score.hh"
  30 #include "music-list.hh"
  31 #include "output-property-music-iterator.hh"
  32 #include "property-iterator.hh"
  33 #include "file-results.hh"
  34 #include "input.hh"
  35 #include "scope.hh"
  36 #include "relative-music.hh"
  37 #include "lyric-combine-music.hh"
  38 #include "transposed-music.hh"
  39 #include "time-scaled-music.hh"
  40 #include "repeated-music.hh"
  41 #include "lilypond-input-version.hh"
  42 #include "grace-music.hh"
  43 #include "auto-change-music.hh"
  44 #include "part-combine-music.hh"
  45
  46 #include "chord.hh"
  47
  48 bool
  49 is_duration_b (int t)
  50 {
  51   return t && t == 1 << intlog2(t);
  52 }
  53
  54
  55 void
  56 set_music_properties (Music *p, SCM a)
  57 {
  58   for (SCM k = a; gh_pair_p (k); k = gh_cdr (k))
  59         {
  60         p->set_mus_property (gh_caar (k), gh_cdar (k));
  61         }
  62 }
  63
  64
  65 // mmm JUNKME ?
  66 Lilypond_version oldest_version ("1.3.59");
  67
  68 void
  69 print_lilypond_versions (ostream &os)
  70 {
  71   os << _f ("Oldest supported input version: %s", oldest_version.str ())
  72     << endl;
  73 }
  74
  75
  76 // needed for bison.simple's malloc() and free()
  77 #include <malloc.h>
  78
  79 #ifndef NDEBUG
  80 #define YYDEBUG 1
  81 #endif
  82
  83 #define YYERROR_VERBOSE 1
  84
  85 #define YYPARSE_PARAM my_lily_parser_l
  86 #define YYLEX_PARAM my_lily_parser_l
  87 #define THIS ((My_lily_parser *) my_lily_parser_l)
  88
  89 #define yyerror THIS->parser_error
  90 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
  91
  92 %}
  93
  94
  95 %union {
  96
  97     Link_array<Request> *reqvec;
  98     Identifier *id;
  99     String * string;
 100     Music *music;
 101     Score *score;
 102     Scope *scope;
 103
 104     Musical_req* musreq;
 105     Music_output_def * outputdef;
 106
 107     Midi_def* midi;
 108     Real real;
 109     Request * request;
 110
 111     /* We use SCMs to do strings, because it saves us the trouble of
 112 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 113 of the parse stack onto the heap. */
 114
 115     SCM scm;
 116
 117     Tempo_req *tempo;
 118     int i;
 119 }
 120 %{
 121
 122 int
 123 yylex (YYSTYPE *s,  void * v_l)
 124 {
 125         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 126         My_lily_lexer * lex_l = pars_l->lexer_p_;
 127
 128         lex_l->lexval_l = (void*) s;
 129         return lex_l->yylex ();
 130 }
 131
 132
 133 %}
 134
 135 %pure_parser
 136
 137 /* tokens which are not keywords */
 138 %token AUTOCHANGE
 139 %token APPLY
 140 %token ARPEGGIO
 141 %token DYNAMICSCRIPT
 142 %token TEXTSCRIPT
 143 %token ACCEPTS
 144 %token ALTERNATIVE
 145 %token BAR
 146 %token BREATHE
 147 %token CHORDMODIFIERS
 148 %token CHORDS
 149 %token CHAR_T
 150 %token CLEF
 151 %token CM_T
 152 %token CONSISTS
 153 %token DURATION
 154 %token SEQUENTIAL
 155 %token ELEMENTDESCRIPTIONS
 156 %token SIMULTANEOUS
 157 %token CONSISTSEND
 158 %token DENIES
 159 %token DURATION
 160 %token EXTENDER
 161 %token FONT
 162 %token GRACE
 163 %token HEADER
 164 %token HYPHEN
 165 %token IN_T
 166 %token INVALID
 167 %token KEY
 168 %token LYRICS
 169 %token MARK
 170 %token MEASURES
 171 %token MIDI
 172 %token MM_T
 173 %token MUSICAL_PITCH
 174 %token NAME
 175 %token NOTENAMES
 176 %token NOTES
 177 %token PAPER
 178 %token PARTIAL
 179 %token PENALTY
 180 %token PROPERTY
 181 %token PUSH POP
 182 %token PT_T
 183 %token RELATIVE
 184 %token REMOVE
 185 %token REPEAT
 186 %token ADDLYRICS
 187 %token PARTCOMBINE
 188 %token SCM_T
 189 %token SCORE
 190 %token SCRIPT
 191 %token SKIP
 192 %token SPANREQUEST
 193 %token STYLESHEET
 194 %token COMMANDSPANREQUEST
 195 %token TEMPO
 196 %token OUTPUTPROPERTY
 197 %token TIME_T
 198 %token TIMES
 199 %token TRANSLATOR
 200 %token TRANSPOSE
 201 %token TYPE
 202 %token CONTEXT
 203
 204 /* escaped */
 205 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER
 206 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 207
 208 %type <i>       exclamations questions dots
 209 %token <i>      DIGIT
 210 %token <scm>    NOTENAME_PITCH
 211 %token <scm>    TONICNAME_PITCH
 212 %token <scm>    CHORDMODIFIER_PITCH
 213 %token <scm>    DURATION_IDENTIFIER
 214 %token <id>     IDENTIFIER
 215
 216
 217 %token <id>     SCORE_IDENTIFIER
 218 %token <id>     MUSIC_OUTPUT_DEF_IDENTIFIER
 219
 220 %token <scm>    NUMBER_IDENTIFIER
 221 %token <scm>    REQUEST_IDENTIFIER
 222 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 223 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 224 %token <scm>    RESTNAME
 225 %token <scm>    STRING
 226 %token <scm>    SCM_T
 227 %token <i>      UNSIGNED
 228 %token <real>   REAL
 229
 230 %type <outputdef> output_def
 231 %type <scope>   lilypond_header lilypond_header_body
 232 %type <request> open_request_parens close_request_parens open_request close_request
 233 %type <request> request_with_dir request_that_take_dir verbose_request
 234 %type <i>       sub_quotes sup_quotes
 235 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 236 %type <music>   Alternative_music Repeated_music
 237 %type <i>       tremolo_type
 238 %type <i>       bare_int  bare_unsigned
 239 %type <i>       script_dir
 240
 241 %type <scm>     identifier_init
 242
 243 %type <scm> steno_duration optional_notemode_duration
 244 %type <scm> entered_notemode_duration explicit_duration
 245
 246 %type <reqvec>  pre_requests post_requests
 247 %type <request> gen_text_def
 248 %type <scm>   steno_musical_pitch musical_pitch absolute_musical_pitch
 249 %type <scm>   steno_tonic_pitch
 250
 251 %type <scm>     chord_additions chord_subtractions chord_notes chord_step
 252 %type <music>   chord
 253 %type <scm>     chord_note chord_inversion chord_bass
 254 %type <scm>     duration_length
 255
 256 %type <scm>  embedded_scm scalar
 257 %type <music>   Music Sequential_music Simultaneous_music Music_sequence
 258 %type <music>   relative_music re_rhythmed_music part_combined_music
 259 %type <music>   property_def translator_change
 260 %type <scm> Music_list
 261 %type <outputdef>  music_output_def_body
 262 %type <request> shorthand_command_req
 263 %type <request> post_request
 264 %type <music> command_req verbose_command_req
 265 %type <request> extender_req
 266 %type <request> hyphen_req
 267 %type <scm>     string bare_number number_expression
 268 %type <score>   score_block score_body
 269
 270 %type <scm>     translator_spec_block translator_spec_body
 271 %type <tempo>   tempo_request
 272 %type <scm> notenames_body notenames_block chordmodifiers_block
 273 %type <scm>     script_abbreviation
 274
 275
 276
 277 %left '-' '+'
 278 %left '*' '/'
 279 %left UNARY_MINUS
 280
 281 %%
 282
 283 lilypond:       /* empty */
 284         | lilypond toplevel_expression {}
 285         | lilypond assignment  { }
 286         | lilypond error {
 287                 THIS->error_level_i_  = 1;
 288                 //THIS->parser_error (_ ("ly invalid"));
 289         }
 290         | lilypond INVALID      {
 291                 THIS->error_level_i_  = 1;
 292                 //THIS->parser_error (_ ("ly invalid"));
 293         }
 294         ;
 295
 296 toplevel_expression:
 297         notenames_block                 {
 298                 THIS->lexer_p_->pitchname_tab_ =  $1;
 299         }
 300         | chordmodifiers_block                  {
 301                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 302         }
 303         | lilypond_header {
 304                 delete header_global_p;
 305                 header_global_p = $1;
 306         }
 307         | score_block {
 308                 score_global_array.push ($1);
 309         }
 310         | output_def {
 311                 Identifier * id = new
 312                         Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER);
 313                 if (dynamic_cast<Paper_def*> ($1))
 314                         THIS->lexer_p_->set_identifier ("$defaultpaper", id->self_scm ());
 315                 else if (dynamic_cast<Midi_def*> ($1))
 316                         THIS->lexer_p_->set_identifier ("$defaultmidi", id->self_scm ());
 317         }
 318         | embedded_scm {
 319                 // junk value
 320         }
 321         ;
 322
 323 embedded_scm:
 324         SCM_T
 325         | SCM_IDENTIFIER
 326         ;
 327
 328
 329 chordmodifiers_block:
 330         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 331         ;
 332
 333
 334 notenames_block:
 335         NOTENAMES notenames_body   {  $$ = $2; }
 336         ;
 337
 338
 339
 340 notenames_body:
 341         embedded_scm    {
 342           int i = scm_ilength ($1);
 343
 344           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 345           for (SCM s = $1; gh_pair_p (s); s = gh_cdr (s)) {
 346                 SCM pt = gh_cdar (s);
 347                 if (!unsmob_pitch (pt))
 348                         THIS->parser_error ("Need pitch object.");
 349                 else
 350                         scm_hashq_set_x (tab, gh_caar(s), pt);
 351           }
 352
 353           $$ = tab;
 354         }
 355         ;
 356
 357 lilypond_header_body:
 358         {
 359                 $$ = new Scope;
 360                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 361         }
 362         | lilypond_header_body assignment semicolon {
 363
 364         }
 365         ;
 366
 367 lilypond_header:
 368         HEADER '{' lilypond_header_body '}'     {
 369                 $$ = $3;
 370                 THIS->lexer_p_-> scope_l_arr_.pop ();
 371         }
 372         ;
 373
 374
 375 /*
 376         DECLARATIONS
 377 */
 378 assignment:
 379         STRING {
 380                 THIS->remember_spot ();
 381         }
 382         /* cont */ '=' identifier_init  {
 383                 THIS->lexer_p_->set_identifier (ly_scm2string ($1), $4);
 384
 385 /*
 386  TODO: devise standard for protection in parser.
 387
 388   The parser stack lives on the C-stack, which means that
 389 all objects can be unprotected as soon as they're here.
 390
 391 */
 392                 Identifier * id =unsmob_identifier ($4);
 393                 Input spot = THIS->pop_spot ();
 394                 if (id) id->set_spot (spot);
 395         }
 396         ;
 397
 398
 399
 400 identifier_init:
 401         score_block {
 402                 $$ = (new Score_identifier ($1, SCORE_IDENTIFIER))->self_scm();
 403         }
 404         | output_def {
 405                 $$ = (new Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER))->self_scm();
 406         }
 407         | translator_spec_block {
 408                 $$ = $1;
 409         }
 410         | Music  {
 411                 $$ = $1->self_scm ();
 412                 scm_unprotect_object ($$);
 413         }
 414         | post_request {
 415                 $$ = $1->self_scm ();
 416                 scm_unprotect_object ($$);
 417         }
 418         | explicit_duration {
 419                 $$ = $1;
 420         }
 421         | number_expression {
 422                 $$ = $1;
 423         }
 424         | string {
 425                 $$ = $1;
 426         }
 427         | embedded_scm  {
 428                 $$ = $1;
 429         }
 430         ;
 431
 432 translator_spec_block:
 433         TRANSLATOR '{' translator_spec_body '}'
 434                 {
 435                 $$ = $3;
 436         }
 437         ;
 438
 439 translator_spec_body:
 440         TRANSLATOR_IDENTIFIER   {
 441                 $$ = unsmob_translator_def ($1)->clone_scm ();
 442                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 443         }
 444         | TYPE STRING semicolon {
 445                 $$ = Translator_def::make_scm ();
 446                 Translator_def*td =  unsmob_translator_def ($$);
 447                 td->translator_group_type_ = $2;
 448                 td->set_spot (THIS->here_input ());
 449         }
 450         | translator_spec_body STRING '=' embedded_scm                  {
 451                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 452         }
 453         | translator_spec_body STRING PUSH embedded_scm '=' embedded_scm {
 454                 unsmob_translator_def ($$)
 455                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 456         }
 457         | translator_spec_body STRING POP embedded_scm  {
 458           unsmob_translator_def($$)->add_pop_property (
 459                 scm_string_to_symbol ($2), $4);
 460         }
 461         | translator_spec_body STRING '=' identifier_init semicolon     {
 462                 SCM v = gh_int2scm (0);
 463                 if (gh_string_p ($4) || gh_number_p ($4) || gh_boolean_p ($4))
 464                         v = $4;
 465                 else
 466                         THIS->parser_error (_("Wrong type for property value"));
 467
 468                 /* ugh*/
 469                 unsmob_translator_def($$)->add_property_assign ($2, v);
 470         }
 471         | translator_spec_body NAME STRING semicolon {
 472                 unsmob_translator_def ($$)->type_name_ = $3;
 473         }
 474         | translator_spec_body CONSISTS STRING semicolon {
 475                 unsmob_translator_def ($$)->add_element ($3);
 476         }
 477         | translator_spec_body ELEMENTDESCRIPTIONS embedded_scm {
 478                 for (SCM p = $3; gh_pair_p (p); p = gh_cdr (p))
 479                         unsmob_translator_def ($$)
 480                         ->add_property_assign (scm_symbol_to_string (gh_caar (p)), gh_cdar (p));
 481
 482         }
 483         | translator_spec_body CONSISTSEND STRING semicolon {
 484                 unsmob_translator_def ($$)->add_last_element ( $3);
 485         }
 486         | translator_spec_body ACCEPTS STRING semicolon {
 487                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 488         }
 489         | translator_spec_body DENIES STRING semicolon {
 490                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 491         }
 492         | translator_spec_body REMOVE STRING semicolon {
 493                 unsmob_translator_def ($$)->remove_element ($3);
 494         }
 495         ;
 496
 497 /*
 498         SCORE
 499 */
 500 score_block:
 501         SCORE {
 502                 THIS->remember_spot ();
 503         }
 504         /*cont*/ '{' score_body '}'     {
 505                 THIS->pop_spot ();
 506                 $$ = $4;
 507                 if (!$$->def_p_arr_.size ())
 508                 {
 509                   Identifier *id =
 510                         unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 511                   $$->add_output (id ? id->access_content_Music_output_def (true) : new Paper_def );
 512                 }
 513         }
 514 /*
 515         | SCORE '{' score_body error {
 516                 $$ = $3
 517                 $$->set_spot (THIS->here_input ());
 518                 // THIS->here_input ().error ("SCORE INVALID");
 519                 $$->error ("SCORE INVALID");
 520                 THIS->parser_error (_f ("SCORE ERROR"));
 521         }
 522 */
 523         ;
 524
 525 score_body:
 526         Music   {
 527                 $$ = new Score;
 528
 529                 $$->set_spot (THIS->here_input ());
 530                 SCM m = $1->self_scm ();
 531                 scm_unprotect_object (m);
 532                 $$->music_ = m;
 533         }
 534         | SCORE_IDENTIFIER {
 535                 $$ = $1->access_content_Score (true);
 536         }
 537         | score_body lilypond_header    {
 538                 $$->header_p_ = $2;
 539         }
 540         | score_body output_def {
 541                 $$->add_output ($2);
 542         }
 543         | score_body error {
 544
 545         }
 546         ;
 547
 548
 549 /*
 550         MIDI
 551 */
 552 output_def:
 553         music_output_def_body '}' {
 554                 $$ = $1;
 555                 THIS-> lexer_p_-> scope_l_arr_.pop();
 556         }
 557         ;
 558
 559 music_output_def_body:
 560         MIDI '{'    {
 561          Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 562
 563
 564          Midi_def* p =0;
 565         if (id)
 566                 p = dynamic_cast<Midi_def*> (id->access_content_Music_output_def (true));
 567         else
 568                 p = new Midi_def;
 569
 570          $$ = p;
 571          THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 572         }
 573         | PAPER '{'     {
 574                   Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 575                   Paper_def *p = 0;
 576                 if (id)
 577                         p = dynamic_cast<Paper_def*> (id->access_content_Music_output_def (true));
 578                 else
 579                         p = new Paper_def;
 580                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 581                 $$ = p;
 582         }
 583         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 584                 Music_output_def *p = $3->access_content_Music_output_def (true);
 585                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 586                 $$ = p;
 587         }
 588         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 589                 Music_output_def *p = $3->access_content_Music_output_def (true);
 590                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 591                 $$ = p;
 592         }
 593         | music_output_def_body assignment semicolon {
 594
 595         }
 596         | music_output_def_body translator_spec_block   {
 597                 $$->assign_translator ($2);
 598         }
 599         | music_output_def_body STYLESHEET embedded_scm {
 600                 dynamic_cast<Paper_def*> ($$)-> style_sheet_ = $3;
 601         }
 602         | music_output_def_body tempo_request semicolon {
 603                 /*
 604                         junk this ? there already is tempo stuff in
 605                         music.
 606                 */
 607                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 608                 Duration *d = unsmob_duration ($2->get_mus_property ("duration"));
 609                 dynamic_cast<Midi_def*> ($$)->set_tempo (d->length_mom (), m);
 610         }
 611         | music_output_def_body error {
 612
 613         }
 614         ;
 615
 616 tempo_request:
 617         TEMPO steno_duration '=' bare_unsigned  {
 618                 $$ = new Tempo_req;
 619                 $$->set_mus_property ("duration", $2);
 620                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 621         }
 622         ;
 623
 624 Music_list: /* empty */ {
 625                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 626         }
 627         | Music_list Music {
 628                 SCM s = $$;
 629                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 630                 scm_unprotect_object ($2->self_scm ()); /* UGH */
 631
 632
 633                 if (gh_pair_p (gh_cdr (s)))
 634                         gh_set_cdr_x (gh_cdr (s), c); /* append */
 635                 else
 636                         gh_set_car_x (s, c); /* set first cons */
 637                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 638         }
 639         | Music_list error {
 640         }
 641         ;
 642
 643
 644 Music:
 645         Simple_music
 646         | Composite_music
 647         ;
 648
 649 Alternative_music:
 650         /* empty */ {
 651                 $$ = 0;
 652         }
 653         | ALTERNATIVE Music_sequence {
 654                 $$ = $2;
 655                 $2->set_spot (THIS->here_input ());
 656         }
 657         ;
 658
 659
 660
 661
 662 Repeated_music:
 663         REPEAT STRING bare_unsigned Music Alternative_music
 664         {
 665                 Music_sequence* m = dynamic_cast <Music_sequence*> ($5);
 666                 if (m && $3 < m->length_i ())
 667                         $5->origin ()->warning (_ ("More alternatives than repeats.  Junking excess alternatives."));
 668
 669                 SCM func = scm_eval2 (ly_symbol2scm ("repeat-name-to-ctor"), SCM_EOL);
 670                 SCM result = gh_call1 (func, $2);
 671                 Repeated_music * r = new Repeated_music ($4, $3 >? 1, m);
 672                 set_music_properties (r, result);
 673
 674                 r->set_spot (*$4->origin ());
 675                 $$ = r;
 676         }
 677         ;
 678
 679 Music_sequence: '{' Music_list '}'      {
 680                 $$ = new Music_sequence (gh_car ($2));
 681         }
 682         ;
 683
 684 Sequential_music:
 685         SEQUENTIAL '{' Music_list '}'           {
 686                 $$ = new Sequential_music (gh_car ($3));
 687         }
 688         | '{' Music_list '}'            {
 689                 $$ = new Sequential_music (gh_car ($2));
 690         }
 691         ;
 692
 693 Simultaneous_music:
 694         SIMULTANEOUS '{' Music_list '}'{
 695                 $$ = new Simultaneous_music (gh_car ($3));
 696         }
 697         | '<' Music_list '>'    {
 698                 $$ = new Simultaneous_music (gh_car ($2));
 699         }
 700         ;
 701
 702 Simple_music:
 703         request_chord           { $$ = $1; }
 704         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 705                 SCM pred = $2;
 706                 if (!gh_symbol_p ($3))
 707                 {
 708                         THIS->parser_error (_("Second argument must be a symbol"));
 709                 }
 710                 /*hould check # args */
 711                 if (!gh_procedure_p (pred))
 712                 {
 713                         THIS->parser_error (_("First argument must be a procedure taking 1 argument"));
 714                 }
 715
 716           Music *m = new Music;
 717           m->set_mus_property ("predicate", pred);
 718           m->set_mus_property ("symbol", $3);
 719           m->set_mus_property ("value",  $5);
 720           m->set_mus_property ("type",
 721                         Output_property_music_iterator::constructor_cxx_function);
 722
 723                 $$ = m;
 724         }
 725         | MUSIC_IDENTIFIER {
 726                 $$ = unsmob_music ($1)->clone ();
 727         }
 728         | property_def
 729         | translator_change
 730         | Simple_music '*' bare_unsigned '/' bare_unsigned      {
 731                 $$ = $1;
 732                 $$->compress (Moment($3, $5 ));
 733         }
 734         | Simple_music '*' bare_unsigned                 {
 735                 $$ = $1;
 736                 $$->compress (Moment ($3, 1));
 737         }
 738         ;
 739
 740
 741 Composite_music:
 742         CONTEXT STRING Music    {
 743                 Context_specced_music *csm =  new Context_specced_music ($3);
 744
 745                 csm->set_mus_property ("context-type",$2);
 746                 csm->set_mus_property ("context-id", ly_str02scm (""));
 747
 748                 $$ = csm;
 749         }
 750         | AUTOCHANGE STRING Music       {
 751                 Auto_change_music * chm = new Auto_change_music ($3);
 752                 chm->set_mus_property ("what", $2);
 753
 754                 $$ = chm;
 755                 chm->set_spot (*$3->origin ());
 756         }
 757         | GRACE Music {
 758                 $$ = new Grace_music ($2);
 759         }
 760         | CONTEXT STRING '=' STRING Music {
 761                 Context_specced_music *csm =  new Context_specced_music ($5);
 762
 763                 csm->set_mus_property ("context-type", $2);
 764                 csm->set_mus_property ("context-id", $4);
 765
 766                 $$ = csm;
 767         }
 768         | TIMES {
 769                 THIS->remember_spot ();
 770         }
 771         /* CONTINUED */
 772                 bare_unsigned '/' bare_unsigned Music
 773
 774         {
 775                 $$ = new Time_scaled_music ($3, $5, $6);
 776                 $$->set_spot (THIS->pop_spot ());
 777         }
 778         | Repeated_music                { $$ = $1; }
 779         | Simultaneous_music            { $$ = $1; }
 780         | Sequential_music              { $$ = $1; }
 781         | TRANSPOSE musical_pitch Music {
 782                 $$ = new Transposed_music ($3, *unsmob_pitch ($2));
 783         }
 784         | TRANSPOSE steno_tonic_pitch Music {
 785                 $$ = new Transposed_music ($3, *unsmob_pitch ($2));
 786         }
 787         | APPLY embedded_scm Music  {
 788                 SCM ret = gh_call1 ($2, $3->self_scm ());
 789                 Music *m = unsmob_music (ret);
 790                 if (!m) {
 791                         THIS->parser_error ("\\apply must return a Music");
 792                         m = new Music ();
 793                         }
 794                 $$ = m;
 795         }
 796         | NOTES
 797                 { THIS->lexer_p_->push_note_state (); }
 798         Music
 799                 { $$ = $3;
 800                   THIS->lexer_p_->pop_state ();
 801                 }
 802         | CHORDS
 803                 { THIS->lexer_p_->push_chord_state (); }
 804         Music
 805                 {
 806                   $$ = $3;
 807                   THIS->lexer_p_->pop_state ();
 808         }
 809         | LYRICS
 810                 { THIS->lexer_p_->push_lyric_state (); }
 811         Music
 812                 {
 813                   $$ = $3;
 814                   THIS->lexer_p_->pop_state ();
 815         }
 816         | relative_music        { $$ = $1; }
 817         | re_rhythmed_music     { $$ = $1; }
 818         | part_combined_music   { $$ = $1; }
 819         ;
 820
 821 relative_music:
 822         RELATIVE absolute_musical_pitch Music {
 823                 $$ = new Relative_octave_music ($3, *unsmob_pitch ($2));
 824         }
 825         ;
 826
 827 re_rhythmed_music:
 828         ADDLYRICS Music Music {
 829                 Lyric_combine_music * l = new Lyric_combine_music ($2, $3);
 830                 $$ = l;
 831         }
 832         ;
 833
 834 part_combined_music:
 835         PARTCOMBINE STRING Music Music {
 836                 Part_combine_music * p = new Part_combine_music ($2, $3, $4);
 837                 $$ = p;
 838         }
 839         ;
 840
 841 translator_change:
 842         TRANSLATOR STRING '=' STRING  {
 843                 Music * t = new Music;
 844                 t->set_mus_property ("type",
 845                         Change_iterator::constructor_cxx_function);
 846                 t-> set_mus_property ("change-to-type", $2);
 847                 t-> set_mus_property ("change-to-id", $4);
 848
 849                 $$ = t;
 850                 $$->set_spot (THIS->here_input ());
 851         }
 852         ;
 853
 854 property_def:
 855         PROPERTY STRING '.' STRING '='  scalar {
 856                 Music *t = new Music;
 857
 858                 t->set_mus_property ("type",
 859                         Property_iterator::constructor_cxx_function);
 860                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
 861                 t->set_mus_property ("value", $6);
 862
 863                 Context_specced_music *csm = new Context_specced_music (t);
 864                 $$ = csm;
 865                 $$->set_spot (THIS->here_input ());
 866
 867                 csm-> set_mus_property ("context-type", $2);
 868         }
 869         | PROPERTY STRING '.' STRING PUSH embedded_scm '=' embedded_scm {
 870                 Music *t = new Music;
 871                 t->set_mus_property ("type",
 872                         Push_property_iterator::constructor_cxx_function);
 873                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 874                 t->set_mus_property ("element-property", $6);
 875                 t->set_mus_property ("element-value", $8);
 876                 Context_specced_music *csm = new Context_specced_music (t);
 877                 $$ = csm;
 878                 $$->set_spot (THIS->here_input ());
 879
 880                 csm-> set_mus_property ("context-type", $2);
 881         }
 882         | PROPERTY STRING '.' STRING POP embedded_scm {
 883                 Music *t = new Music;
 884                 t->set_mus_property ("type",
 885                         Pop_property_iterator::constructor_cxx_function);
 886                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 887                 t->set_mus_property ("element-property", $6);
 888
 889                 Context_specced_music *csm = new Context_specced_music (t);
 890                 $$ = csm;
 891                 $$->set_spot (THIS->here_input ());
 892
 893                 csm-> set_mus_property ("context-type", $2);
 894         }
 895         ;
 896
 897 scalar:
 898         string          { $$ = $1; }
 899         | bare_int      { $$ = gh_int2scm ($1); }
 900         | embedded_scm  { $$ = $1; }
 901         ;
 902
 903
 904 request_chord:
 905         pre_requests simple_element post_requests       {
 906                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 907                 if (l) {
 908                         for (int i=0; i < $1->size(); i++)
 909                                 l->append_music ($1->elem(i));
 910                         for (int i=0; i < $3->size(); i++)
 911                                 l->append_music ($3->elem(i));
 912                         }
 913                 else
 914                         programming_error ("Need Sequence to add music to");
 915                 $$ = $2;
 916
 917         }
 918         | command_element
 919         ;
 920
 921 command_element:
 922         command_req {
 923                 $$ = new Request_chord (gh_cons ($1->self_scm (), SCM_EOL));
 924                 $$-> set_spot (THIS->here_input ());
 925                 $1-> set_spot (THIS->here_input ());
 926         }
 927         | BAR STRING ';'                        {
 928                 Music *t = new Music;
 929
 930                 t->set_mus_property ("type",
 931                         Property_iterator::constructor_cxx_function);
 932                 t->set_mus_property ("symbol", ly_symbol2scm ("whichBar"));
 933                 t->set_mus_property ("value", $2);
 934
 935                 Context_specced_music *csm = new Context_specced_music (t);
 936                 $$ = csm;
 937                 $$->set_spot (THIS->here_input ());
 938
 939                 csm->set_mus_property ("context-type", ly_str02scm ("Score"));
 940         }
 941         | PARTIAL duration_length ';'   {
 942                 Music * p = new Music;
 943                 p->set_mus_property ("symbol", ly_symbol2scm ( "measurePosition"));
 944                 p->set_mus_property ("type",
 945                         Property_iterator::constructor_cxx_function);
 946
 947                 Moment m = - unsmob_duration($2)->length_mom ();
 948                 p->set_mus_property ("value", m.smobbed_copy ());
 949
 950                 Context_specced_music * sp = new Context_specced_music (p);
 951                 $$ =sp ;
 952                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
 953         }
 954         | CLEF STRING ';' {
 955                 SCM func = scm_eval2 (ly_symbol2scm ("clef-name-to-properties"), SCM_EOL);
 956                 SCM result = gh_call1 (func, $2);
 957
 958                 SCM l = SCM_EOL;
 959                 for (SCM s = result ; gh_pair_p (s); s = gh_cdr (s)) {
 960                         Music * p = new Music;
 961                         set_music_properties(p, gh_car (s));
 962                         l = gh_cons (p->self_scm (), l);
 963                         scm_unprotect_object (p->self_scm ());
 964                 }
 965                 Sequential_music * seq = new Sequential_music (l);
 966
 967                 Context_specced_music * sp = new Context_specced_music (seq);
 968                 $$ =sp ;
 969                 sp-> set_mus_property("context-type", ly_str02scm("Staff"));
 970         }
 971         | TIME_T bare_unsigned '/' bare_unsigned ';' {
 972                 Music * p = new Music;
 973                 p->set_mus_property ("symbol",
 974                         ly_symbol2scm ( "timeSignatureFraction"));
 975                 p->set_mus_property ("type",
 976                         Property_iterator::constructor_cxx_function);
 977
 978                 p->set_mus_property ("value", gh_cons (gh_int2scm ($2),
 979                                                         gh_int2scm ($4)));
 980
 981                 Context_specced_music * sp = new Context_specced_music (p);
 982                 $$ =sp ;
 983                 sp-> set_mus_property ("context-type", ly_str02scm ( "Score"));
 984         }
 985         ;
 986
 987 command_req:
 988         shorthand_command_req   { $$ = $1; }
 989         | verbose_command_req semicolon { $$ = $1; }
 990         ;
 991
 992 shorthand_command_req:
 993         extender_req {
 994                 $$ = $1;
 995         }
 996         | hyphen_req {
 997                 $$ = $1;
 998         }
 999         | '|'                           {
1000                 $$ = new Barcheck_req;
1001         }
1002         | '~'   {
1003                 $$ = new Tie_req;
1004         }
1005         | '['           {
1006                 Span_req*b= new Span_req;
1007                 b->set_span_dir(START);
1008                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1009                 $$ =b;
1010         }
1011         | ']'           {
1012                 Span_req*b= new Span_req;
1013                 b->set_span_dir( STOP);
1014                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
1015                 $$ = b;
1016         }
1017         | BREATHE {
1018                 $$ = new Breathing_sign_req;
1019         }
1020         ;
1021
1022
1023 verbose_command_req:
1024         COMMANDSPANREQUEST bare_int STRING {
1025                 Span_req * sp_p = new Span_req;
1026                 sp_p-> set_span_dir ( Direction($2));
1027                 sp_p->set_mus_property ("span-type",$3);
1028                 sp_p->set_spot (THIS->here_input ());
1029                 $$ = sp_p;
1030         }
1031         | MARK  {
1032                 Mark_req * m = new Mark_req;
1033                 $$ = m;
1034         }
1035         | MARK STRING {
1036                 Mark_req *m = new Mark_req;
1037                 m->set_mus_property ("label", $2);
1038                 $$ = m;
1039
1040         }
1041         | MARK bare_unsigned {
1042                 Mark_req *m = new Mark_req;
1043                 m->set_mus_property ("label",  gh_int2scm ($2));
1044                 $$ = m;
1045         }
1046         | PENALTY bare_int      {
1047                 Break_req * b = new Break_req;
1048                 b->set_mus_property ("penalty", gh_double2scm ( $2 / 100.0));
1049                 b->set_spot (THIS->here_input ());
1050                 $$ = b;
1051         }
1052         | SKIP duration_length {
1053                 Skip_req * skip_p = new Skip_req;
1054                 skip_p->set_mus_property ("duration", $2);
1055
1056                 $$ = skip_p;
1057         }
1058         | tempo_request {
1059                 $$ = $1;
1060         }
1061         | KEY {
1062                 Key_change_req *key_p= new Key_change_req;
1063                 $$ = key_p;
1064         }
1065         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1066                 Key_change_req *key_p= new Key_change_req;
1067
1068                 key_p->set_mus_property ("pitch-alist", $3);
1069                 ((Music* )key_p)->transpose (* unsmob_pitch ($2));
1070                 $$ = key_p;
1071         }
1072         ;
1073
1074 post_requests:
1075         {
1076                 $$ = new Link_array<Request>;
1077         }
1078         | post_requests post_request {
1079                 $2->set_spot (THIS->here_input ());
1080                 $$->push ($2);
1081         }
1082         ;
1083
1084 post_request:
1085         verbose_request
1086         | request_with_dir
1087         | close_request
1088         ;
1089
1090
1091 request_that_take_dir:
1092         gen_text_def
1093         | verbose_request
1094         | script_abbreviation {
1095                 SCM s = THIS->lexer_p_->lookup_identifier ("dash-" + ly_scm2string ($1));
1096                 Articulation_req *a = new Articulation_req;
1097                 if (gh_string_p (s))
1098                         a->set_mus_property ("articulation-type", s);
1099                 else THIS->parser_error (_ ("Expecting string as script definition"));
1100                 $$ = a;
1101         }
1102         ;
1103
1104 request_with_dir:
1105         script_dir request_that_take_dir        {
1106                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1107                         gs->set_direction (Direction ($1));
1108                 else if ($1)
1109                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1110                 $$ = $2;
1111         }
1112         ;
1113
1114 verbose_request:
1115         REQUEST_IDENTIFIER      {
1116                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1117                 $$->set_spot (THIS->here_input ());
1118         }
1119         | DYNAMICSCRIPT embedded_scm {
1120                 /*
1121                         TODO: junkme, use text-type == dynamic
1122                 */
1123                 Text_script_req *d = new Text_script_req;
1124                 d->set_mus_property ("text-type" , ly_symbol2scm ("dynamic"));
1125                 d->set_mus_property ("text", $2);
1126                 d->set_spot (THIS->here_input ());
1127                 $$ = d;
1128         }
1129         | TEXTSCRIPT embedded_scm {
1130                 Text_script_req *t = new Text_script_req;
1131                 t->set_mus_property ("text", $2);
1132                 t->set_spot (THIS->here_input ());
1133                 $$ = t;
1134         }
1135         | SPANREQUEST bare_int STRING {
1136                 Span_req * sp_p = new Span_req;
1137                 sp_p->set_span_dir( Direction($2));
1138                 sp_p->set_mus_property ("span-type", $3);
1139                 sp_p->set_spot (THIS->here_input ());
1140                 $$ = sp_p;
1141         }
1142         | tremolo_type  {
1143                 Tremolo_req* a = new Tremolo_req;
1144                 a->set_spot (THIS->here_input ());
1145                 a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1146                 $$ = a;
1147         }
1148         | SCRIPT STRING         {
1149                 Articulation_req * a = new Articulation_req;
1150                 a->set_mus_property ("articulation-type", $2);
1151                 a->set_spot (THIS->here_input ());
1152                 $$ = a;
1153         }
1154         | ARPEGGIO {
1155                 Arpeggio_req *a = new Arpeggio_req;
1156                 a->set_spot (THIS->here_input ());
1157                 $$ = a;
1158         }
1159         ;
1160
1161 sup_quotes:
1162         '\'' {
1163                 $$ = 1;
1164         }
1165         | sup_quotes '\'' {
1166                 $$ ++;
1167         }
1168         ;
1169
1170 sub_quotes:
1171         ',' {
1172                 $$ = 1;
1173         }
1174         | sub_quotes ',' {
1175                 $$ ++ ;
1176         }
1177         ;
1178
1179 steno_musical_pitch:
1180         NOTENAME_PITCH  {
1181                 $$ = $1;
1182         }
1183         | NOTENAME_PITCH sup_quotes     {
1184                 Pitch p = *unsmob_pitch ($1);
1185                 p.octave_i_ +=  $2;
1186                 $$ = p.smobbed_copy ();
1187         }
1188         | NOTENAME_PITCH sub_quotes      {
1189                 Pitch p =* unsmob_pitch ($1);
1190
1191                 p.octave_i_ +=  -$2;
1192                 $$ = p.smobbed_copy ();
1193
1194         }
1195         ;
1196
1197 /*
1198 ugh. duplication
1199 */
1200
1201 steno_tonic_pitch:
1202         TONICNAME_PITCH {
1203                 $$ = $1;
1204         }
1205         | TONICNAME_PITCH sup_quotes    {
1206                 Pitch p = *unsmob_pitch ($1);
1207                 p.octave_i_ +=  $2;
1208                 $$ = p.smobbed_copy ();
1209         }
1210         | TONICNAME_PITCH sub_quotes     {
1211                 Pitch p =* unsmob_pitch ($1);
1212
1213                 p.octave_i_ +=  -$2;
1214                 $$ = p.smobbed_copy ();
1215
1216         }
1217         ;
1218
1219 musical_pitch:
1220         steno_musical_pitch {
1221                 $$ = $1;
1222         }
1223         | MUSICAL_PITCH embedded_scm {
1224                 if (!unsmob_pitch ($2))
1225                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1226                  Pitch m;
1227                 $$ = m.smobbed_copy ();
1228         }
1229         ;
1230
1231 explicit_duration:
1232         DURATION embedded_scm   {
1233                 $$ = $2;
1234                 if (!unsmob_duration ($2))
1235                 {
1236                         THIS->parser_error (_("Must have duration object"));
1237                         $$ = Duration ().smobbed_copy ();
1238                 }
1239         }
1240         ;
1241
1242 extender_req:
1243         EXTENDER {
1244                 if (!THIS->lexer_p_->lyric_state_b ())
1245                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1246                 $$ = new Extender_req;
1247         }
1248         ;
1249
1250 hyphen_req:
1251         HYPHEN {
1252                 if (!THIS->lexer_p_->lyric_state_b ())
1253                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1254                 $$ = new Hyphen_req;
1255         }
1256         ;
1257
1258 close_request:
1259         close_request_parens {
1260                 $$ = $1;
1261                 dynamic_cast<Span_req*> ($$)->set_span_dir ( START);
1262         }
1263
1264 close_request_parens:
1265         '('     {
1266                 Span_req* s= new Span_req;
1267                 $$ = s;
1268                 s->set_mus_property ("span-type", ly_str02scm( "slur"));
1269         }
1270         | E_SMALLER {
1271                 Span_req*s =new Span_req;
1272                 $$ = s;
1273                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1274         }
1275         | E_BIGGER {
1276                 Span_req*s =new Span_req;
1277                 $$ = s;
1278                 s->set_mus_property ("span-type", ly_str02scm ("decrescendo"));
1279         }
1280         ;
1281
1282
1283 open_request:
1284         open_request_parens {
1285                 $$ = $1;
1286                 dynamic_cast<Span_req*> ($$)->set_span_dir (STOP);
1287         }
1288         ;
1289
1290 open_request_parens:
1291         E_EXCLAMATION   {
1292                 Span_req *s =  new Span_req;
1293                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1294
1295                 $$ = s;
1296         }
1297         | ')'   {
1298                 Span_req* s= new Span_req;
1299                 $$ = s;
1300                 s->set_mus_property ("span-type", ly_str02scm( "slur"));
1301         }
1302         ;
1303
1304 gen_text_def:
1305         embedded_scm {
1306                 Text_script_req *t = new Text_script_req;
1307                 t->set_mus_property ("text", $1);
1308                 t->set_spot (THIS->here_input ());
1309                 $$ = t;
1310         }
1311         | string {
1312                 Text_script_req *t = new Text_script_req;
1313                 t->set_mus_property ("text", $1);
1314                 t->set_spot (THIS->here_input ());
1315                 $$ = t;
1316         }
1317         | DIGIT {
1318                 String ds = to_str ($1);
1319                 Text_script_req* t = new Text_script_req;
1320
1321                 t->set_mus_property ("text",  ly_str02scm (ds.ch_C()));
1322                 t->set_mus_property ("text-type" , ly_symbol2scm ("finger"));
1323                 t->set_spot (THIS->here_input ());
1324                 $$ = t;
1325         }
1326         ;
1327
1328 script_abbreviation:
1329         '^'             {
1330                 $$ = gh_str02scm  ("hat");
1331         }
1332         | '+'           {
1333                 $$ = gh_str02scm("plus");
1334         }
1335         | '-'           {
1336                 $$ = gh_str02scm ("dash");
1337         }
1338         | '|'           {
1339                 $$ = gh_str02scm ("bar");
1340         }
1341         | '>'           {
1342                 $$ = gh_str02scm ("larger");
1343         }
1344         | '.'           {
1345                 $$ = gh_str02scm ("dot");
1346         }
1347         ;
1348
1349
1350 script_dir:
1351         '_'     { $$ = DOWN; }
1352         | '^'   { $$ = UP; }
1353         | '-'   { $$ = CENTER; }
1354         ;
1355
1356 pre_requests:
1357         {
1358                 $$ = new Link_array<Request>;
1359         }
1360         | pre_requests open_request {
1361                 $$->push ($2);
1362         }
1363         ;
1364
1365 absolute_musical_pitch:
1366         steno_musical_pitch     {
1367                 $$ = $1;
1368         }
1369         ;
1370
1371 duration_length:
1372         steno_duration {
1373                 $$ = $1;
1374         }
1375         | duration_length '*' bare_unsigned {
1376                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1377         }
1378         | duration_length '/' bare_unsigned {
1379                 $$ = unsmob_duration ($$)->compressed (Moment (1,$3)).smobbed_copy ();
1380         }
1381         ;
1382
1383 entered_notemode_duration:
1384         steno_duration  {
1385                 THIS->set_last_duration (unsmob_duration ($1));
1386         }
1387         ;
1388
1389 optional_notemode_duration:
1390         {
1391                 $$ = THIS->default_duration_.smobbed_copy ();
1392         }
1393         | entered_notemode_duration {
1394                 $$ = $1;
1395         }
1396         ;
1397
1398 steno_duration:
1399         bare_unsigned dots              {
1400                 int l = 0;
1401                 if (!is_duration_b ($1))
1402                         THIS->parser_error (_f ("not a duration: %d", $1));
1403                 else
1404                         l =  intlog2 ($1);
1405
1406                 $$ = Duration (l, $2).smobbed_copy ();
1407         }
1408         | DURATION_IDENTIFIER dots      {
1409                 Duration *d =unsmob_duration ($1);
1410                 Duration k (d->duration_log (),d->dot_count () + $2);
1411                 $$ = k.smobbed_copy ();
1412         }
1413         ;
1414
1415 dots:
1416         /* empty */     {
1417                 $$ = 0;
1418         }
1419         | dots '.' {
1420                 $$ ++;
1421         }
1422         ;
1423
1424
1425 tremolo_type:
1426         ':'     {
1427                 $$ =0;
1428         }
1429         | ':' bare_unsigned {
1430                 if (!is_duration_b ($2))
1431                         THIS->parser_error (_f ("not a duration: %d", $2));
1432                 $$ = $2;
1433         }
1434         ;
1435
1436
1437 simple_element:
1438         musical_pitch exclamations questions optional_notemode_duration {
1439                 if (!THIS->lexer_p_->note_state_b ())
1440                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1441
1442                 Note_req *n = new Note_req;
1443
1444                 n->set_mus_property ("pitch", $1);
1445                 n->set_mus_property ("duration", $4);
1446
1447                 if ($3 % 2)
1448                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1449                 if ($2 % 2 || $3 % 2)
1450                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1451
1452                 Simultaneous_music*v = new Request_chord (gh_list (n->self_scm (), SCM_UNDEFINED));
1453
1454 /*
1455 FIXME
1456 */
1457                 v->set_spot (THIS->here_input ());
1458                 n->set_spot (THIS->here_input ());
1459
1460                 $$ = v;
1461         }
1462         | RESTNAME optional_notemode_duration           {
1463
1464                 SCM e = SCM_UNDEFINED;
1465                   if (ly_scm2string ($1) =="s")
1466                     { /* Space */
1467                       Skip_req * skip_p = new Skip_req;
1468                       skip_p->set_mus_property ("duration" ,$2);
1469
1470                       skip_p->set_spot (THIS->here_input());
1471                         e = skip_p->self_scm ();
1472                     }
1473                   else
1474                     {
1475                       Rest_req * rest_req_p = new Rest_req;
1476                       rest_req_p->set_mus_property ("duration", $2);
1477                       rest_req_p->set_spot (THIS->here_input());
1478                         e = rest_req_p->self_scm ();
1479                     }
1480                   Simultaneous_music* velt_p = new Request_chord (gh_list (e,SCM_UNDEFINED));
1481                   velt_p->set_spot (THIS->here_input());
1482
1483
1484                   $$ = velt_p;
1485         }
1486         | MEASURES optional_notemode_duration   {
1487                 Skip_req * sk = new Skip_req;
1488                 sk->set_mus_property ("duration", $2);
1489                 Span_req *sp1 = new Span_req;
1490                 Span_req *sp2 = new Span_req;
1491                 sp1-> set_span_dir ( START);
1492                 sp2-> set_span_dir ( STOP);
1493                 SCM r = ly_str02scm ("rest");
1494                 sp1->set_mus_property ("span-type", r);
1495                 sp2->set_mus_property ("span-type", r);
1496
1497                 Request_chord * rqc1 = new Request_chord (gh_list (sp1->self_scm (), SCM_UNDEFINED));
1498                 Request_chord * rqc2 = new Request_chord (gh_list (sk->self_scm (), SCM_UNDEFINED));;
1499                 Request_chord * rqc3 = new Request_chord(gh_list (sp2->self_scm (), SCM_UNDEFINED));;
1500
1501                 SCM ms = gh_list (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1502
1503                 $$ = new Sequential_music (ms);
1504         }
1505         | STRING {
1506                 THIS->remember_spot ();
1507         }
1508         /* cont */
1509         optional_notemode_duration      {
1510                 if (!THIS->lexer_p_->lyric_state_b ()) {
1511                         THIS->pop_spot ().error (_ ("Have to be in Lyric mode for lyrics"));
1512                         THIS->error_level_i_  = 1;
1513                         THIS->parser_error (_ ("Giving up"));
1514                 }
1515                 else
1516                         THIS->pop_spot ();
1517                 Lyric_req* lreq_p = new Lyric_req;
1518                 lreq_p->set_mus_property ("text", $1);
1519                 lreq_p->set_mus_property ("duration",$3);
1520                 lreq_p->set_spot (THIS->here_input());
1521                 Simultaneous_music* velt_p = new Request_chord (gh_list (lreq_p->self_scm (), SCM_UNDEFINED));
1522
1523
1524                 $$= velt_p;
1525
1526         }
1527         | chord {
1528                 if (!THIS->lexer_p_->chord_state_b ())
1529                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1530                 $$ = $1;
1531         }
1532         ;
1533
1534
1535 chord:
1536         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1537                 $$ = Chord::get_chord ($1, $3, $4, $5, $6, $2);
1538                 $$->set_spot (THIS->here_input ());
1539         };
1540
1541 chord_additions:
1542         {
1543                 $$ = SCM_EOL;
1544         }
1545         | CHORD_COLON chord_notes {
1546                 $$ = $2;
1547         }
1548         ;
1549
1550 chord_notes:
1551         chord_step {
1552                 $$ = $1
1553         }
1554         | chord_notes '.' chord_step {
1555                 $$ = gh_append2 ($$, $3);
1556         }
1557         ;
1558
1559 chord_subtractions:
1560         {
1561                 $$ = SCM_EOL;
1562         }
1563         | CHORD_CARET chord_notes {
1564                 $$ = $2;
1565         }
1566         ;
1567
1568
1569 chord_inversion:
1570         {
1571                 $$ = SCM_EOL;
1572         }
1573         | '/' steno_tonic_pitch {
1574                 $$ = $2;
1575         }
1576         ;
1577
1578 chord_bass:
1579         {
1580                 $$ = SCM_EOL;
1581         }
1582         | CHORD_BASS steno_tonic_pitch {
1583                 $$ = $2;
1584         }
1585         ;
1586
1587 chord_step:
1588         chord_note {
1589                 $$ = gh_cons ($1, SCM_EOL);
1590         }
1591         | CHORDMODIFIER_PITCH {
1592                 $$ = gh_cons ($1, SCM_EOL);
1593         }
1594         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1595                 $$ = gh_list ($1, $2, SCM_UNDEFINED);
1596         }
1597         ;
1598
1599 chord_note:
1600         bare_unsigned {
1601                  Pitch m;
1602                 m.notename_i_ = ($1 - 1) % 7;
1603                 m.octave_i_ = $1 > 7 ? 1 : 0;
1604                 m.alteration_i_ = 0;
1605
1606                 $$ = m.smobbed_copy ();
1607         }
1608         | bare_unsigned '+' {
1609                 Pitch m;
1610                 m.notename_i_ = ($1 - 1) % 7;
1611                 m.octave_i_ = $1 > 7 ? 1 : 0;
1612                 m.alteration_i_ = 1;
1613
1614
1615                 $$ = m.smobbed_copy ();
1616         }
1617         | bare_unsigned CHORD_MINUS {
1618                 Pitch m;
1619                 m.notename_i_ = ($1 - 1) % 7;
1620                 m.octave_i_ = $1 > 7 ? 1 : 0;
1621                 m.alteration_i_ = -1;
1622
1623                 $$ = m.smobbed_copy ();
1624         }
1625         ;
1626
1627 /*
1628         UTILITIES
1629  */
1630 number_expression:
1631         bare_number {
1632                 $$ = $1;
1633         }
1634         | '-'  number_expression %prec UNARY_MINUS {
1635                 $$ = scm_difference ($2, SCM_UNDEFINED);
1636         }
1637         | number_expression '*' number_expression {
1638                 $$ = scm_product ($1, $3);
1639         }
1640         | number_expression '/' number_expression {
1641                 $$ = scm_divide ($1, $3);
1642         }
1643         | number_expression '+' number_expression {
1644                 $$ = scm_sum ($1, $3);
1645         }
1646         | number_expression '-' number_expression {
1647                 $$ = scm_difference ($1, $3);
1648         }
1649         | '(' number_expression ')'     {
1650                 $$ = $2;
1651         }
1652         ;
1653
1654 bare_number:
1655         UNSIGNED        {
1656                 $$ = gh_int2scm ($1);
1657         }
1658         | DIGIT         {
1659                 $$ = gh_int2scm ($1);
1660         }
1661         | REAL          {
1662                 $$ = gh_double2scm ($1);
1663         }
1664         | NUMBER_IDENTIFIER             {
1665                 $$ = $1;
1666         }
1667         | REAL CM_T     {
1668                 $$ = gh_double2scm ($1 CM);
1669         }
1670         | REAL PT_T     {
1671                 $$ = gh_double2scm ($1 PT);
1672         }
1673         | REAL IN_T     {
1674                 $$ = gh_double2scm ($1 INCH);
1675         }
1676         | REAL MM_T     {
1677                 $$ = gh_double2scm ($1 MM);
1678         }
1679         | REAL CHAR_T   {
1680                 $$ = gh_double2scm ($1 CHAR);
1681         }
1682         ;
1683
1684
1685 bare_unsigned:
1686         bare_number {
1687                 if (scm_integer_p ($1) == SCM_BOOL_T) {
1688                         $$ = gh_scm2int ($1);
1689
1690                 } else {
1691                         THIS->parser_error (_("need integer number arg"));
1692                         $$ = 0;
1693                 }
1694                 if ($$ < 0) {
1695                         THIS->parser_error (_("Must be positive integer"));
1696                         $$ = -$$;
1697                         }
1698
1699         }
1700         ;
1701 bare_int:
1702         bare_number {
1703                 if (scm_integer_p ($1) == SCM_BOOL_T)
1704                 {
1705                         int k = gh_scm2int ($1);
1706                         $$ = k;
1707                 } else
1708                 {
1709                         THIS->parser_error (_("need integer number arg"));
1710                         $$ = 0;
1711                 }
1712         }
1713         | '-' bare_int {
1714                 $$ = -$2;
1715         }
1716         ;
1717
1718
1719 string:
1720         STRING          {
1721                 $$ = $1;
1722         }
1723         | STRING_IDENTIFIER     {
1724                 $$ = $1;
1725         }
1726         | string '+' string {
1727                 $$ = scm_string_append (scm_listify ($1, $3, SCM_UNDEFINED));
1728         }
1729         ;
1730
1731
1732 exclamations:
1733                 { $$ = 0; }
1734         | exclamations '!'      { $$ ++; }
1735         ;
1736
1737 questions:
1738                 { $$ = 0; }
1739         | questions '?' { $$ ++; }
1740         ;
1741
1742
1743 semicolon:
1744         ';'
1745         ;
1746
1747 %%
1748
1749 void
1750 My_lily_parser::set_yydebug (bool b)
1751 {
1752 #ifdef YYDEBUG
1753         yydebug = b;
1754 #endif
1755 }
1756
1757 extern My_lily_parser * current_parser;
1758
1759 void
1760 My_lily_parser::do_yyparse ()
1761 {
1762
1763         current_parser = this;;
1764         yyparse ((void*)this);
1765 }
1766
1767