lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2005 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "music.hh"
  78 #include "file-path.hh"
  79 #include "input-smob.hh"
  80 #include "input.hh"
  81 #include "lily-guile.hh"
  82 #include "lilypond-input-version.hh"
  83 #include "main.hh"
  84 #include "misc.hh"
  85 #include "lily-lexer.hh"
  86 #include "lily-parser.hh"
  87 #include "paper-book.hh"
  88 #include "output-def.hh"
  89 #include "scm-hash.hh"
  90 #include "program-option.hh"
  91 #include "score.hh"
  92 #include "text-interface.hh"
  93 #include "warn.hh"
  94 #include "music.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         String *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 Music *property_op_to_music (SCM op);
 114 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
 115 SCM get_next_unique_context_id ();
 116 SCM get_next_unique_lyrics_context_id ();
 117
 118 #undef _
 119 #if !HAVE_GETTEXT
 120 #define _(x) x
 121 #else
 122 #include <libintl.h>
 123 #define _(x) gettext (x)
 124 #endif
 125
 126
 127
 128 Music *make_lyric_combine_music (SCM name, Music *music);
 129 Music *make_music_relative (Pitch start, Music *music);
 130 Music *run_music_function (Lily_parser *, SCM expr);
 131 Music *set_property_music (SCM sym, SCM value);
 132 SCM get_first_context_id (SCM type, Music *m);
 133 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 134 SCM make_chord_step (int step, int alter);
 135 SCM make_simple_markup (SCM a);
 136 bool is_duration (int t);
 137 bool is_regular_identifier (SCM id);
 138 bool ly_input_procedure_p (SCM x);
 139 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 140 void set_music_properties (Music *p, SCM a);
 141
 142 %}
 143
 144 /* The third option is an alias that will be used to display the
 145    syntax error.  Bison CVS now correctly handles backslash escapes.
 146
 147    FIXME: Bison needs to translate some of these, eg, STRING.
 148
 149 */
 150
 151 /* Keyword tokens with plain escaped name.  */
 152 %token ACCEPTS "\\accepts"
 153 %token ADDLYRICS "\\addlyrics"
 154 %token ADDQUOTE "\\addquote"
 155 %token ALIAS "\\alias"
 156 %token ALTERNATIVE "\\alternative"
 157 %token BAR "\\bar"
 158 %token BOOK "\book"
 159 %token CHANGE "\\change"
 160 %token CHORDMODE "\\chordmode"
 161 %token CHORDS "\\chords"
 162 %token CLEF "\\clef"
 163 %token CONSISTS "\\consists"
 164 %token CONTEXT "\\context"
 165 %token DEFAULT "\\default"
 166 %token DEFAULTCHILD "\\defaultchild"
 167 %token DENIES "\\denies"
 168 %token DESCRIPTION "\\description"
 169 %token DRUMMODE "\\drummode"
 170 %token DRUMS "\\drums"
 171 %token FIGUREMODE "\\figuremode"
 172 %token FIGURES "\\figures"
 173 %token GROBDESCRIPTIONS "\\grobdescriptions"
 174 %token HEADER "\\header"
 175 %token INVALID "\\invalid"
 176 %token KEY "\\key"
 177 %token LAYOUT "\\layout"
 178 %token LYRICMODE "\\lyricmode"
 179 %token LYRICS "\\lyrics"
 180 %token LYRICSTO "\\lyricsto"
 181 %token MARK "\\mark"
 182 %token MARKUP "\\markup"
 183 %token MIDI "\\midi"
 184 %token NAME "\\name"
 185 %token NOTEMODE "\\notemode"
 186 %token OBJECTID "\\objectid"
 187 %token OCTAVE "\\octave"
 188 %token ONCE "\\once"
 189 %token OVERRIDE "\\override"
 190 %token PAPER "\\paper"
 191 %token PARTIAL "\\partial"
 192 %token RELATIVE "\\relative"
 193 %token REMOVE "\\remove"
 194 %token REPEAT "\\repeat"
 195 %token REST "\\rest"
 196 %token REVERT "\\revert"
 197 %token SCORE "\\score"
 198 %token SEQUENTIAL "\\sequential"
 199 %token SET "\\set"
 200 %token SIMULTANEOUS "\\simultaneous"
 201 %token SKIP "\\skip"
 202 %token TEMPO "\\tempo"
 203 %token TIMES "\\times"
 204 %token TRANSPOSE "\\transpose"
 205 %token TRANSPOSITION "\\transposition"
 206 %token TYPE "\\type"
 207 %token UNSET "\\unset"
 208 %token WITH "\\with"
 209
 210 /* Keyword token exceptions.  */
 211 %token TIME_T "\\time"
 212 %token NEWCONTEXT "\\new"
 213
 214
 215 /* Other string tokens.  */
 216
 217 %token CHORD_BASS "/+"
 218 %token CHORD_CARET "^"
 219 %token CHORD_COLON ":"
 220 %token CHORD_MINUS "-"
 221 %token CHORD_SLASH "/"
 222 %token DOUBLE_ANGLE_CLOSE ">>"
 223 %token DOUBLE_ANGLE_OPEN "<<"
 224 %token E_BACKSLASH "\\"
 225 %token E_ANGLE_CLOSE "\\>"
 226 %token E_CHAR "\\C[haracter]"
 227 %token E_CLOSE "\\)"
 228 %token E_EXCLAMATION "\\!"
 229 %token E_BRACKET_OPEN "\\["
 230 %token E_OPEN "\\("
 231 %token E_BRACKET_CLOSE "\\]"
 232 %token E_ANGLE_OPEN "\\<"
 233 %token E_PLUS "\\+"
 234 %token E_TILDE "\\~"
 235 %token EXTENDER "__"
 236
 237 /*
 238 If we give names, Bison complains.
 239 */
 240 %token FIGURE_CLOSE /* "\\>" */
 241 %token FIGURE_OPEN /* "\\<" */
 242 %token FIGURE_SPACE "_"
 243 %token HYPHEN "--"
 244
 245 %token CHORDMODIFIERS
 246 %token LYRIC_MARKUP
 247 %token MULTI_MEASURE_REST
 248 %token SCM_T
 249
 250
 251 %token <i> DIGIT
 252 %token <i> E_UNSIGNED
 253 %token <i> UNSIGNED
 254
 255 %token <scm> BOOK_IDENTIFIER
 256 %token <scm> CHORDMODIFIER_PITCH
 257 %token <scm> CHORD_MODIFIER
 258 %token <scm> CONTEXT_DEF_IDENTIFIER
 259 %token <scm> DRUM_PITCH
 260 %token <scm> DURATION_IDENTIFIER
 261 %token <scm> EVENT_IDENTIFIER
 262 %token <scm> FRACTION
 263 %token <scm> LYRICS_STRING
 264 %token <scm> LYRIC_MARKUP_IDENTIFIER
 265 %token <scm> MARKUP_HEAD_EMPTY
 266 %token <scm> MARKUP_HEAD_LIST0
 267 %token <scm> MARKUP_HEAD_MARKUP0
 268 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 269 %token <scm> MARKUP_HEAD_SCM0
 270 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1
 272 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 273 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 274 %token <scm> MARKUP_IDENTIFIER
 275 %token <scm> MUSIC_FUNCTION
 276 %token <scm> MUSIC_FUNCTION_MARKUP
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 281 %token <scm> MUSIC_FUNCTION_MUSIC
 282 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 283 %token <scm> MUSIC_FUNCTION_SCM
 284 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 285 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM
 287 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 288 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 289 %token <scm> MUSIC_IDENTIFIER
 290 %token <scm> NOTENAME_PITCH
 291 %token <scm> NUMBER_IDENTIFIER
 292 %token <scm> OUTPUT_DEF_IDENTIFIER
 293 %token <scm> REAL
 294 %token <scm> RESTNAME
 295 %token <scm> SCM_IDENTIFIER
 296 %token <scm> SCM_T
 297 %token <scm> SCORE_IDENTIFIER
 298 %token <scm> STRING
 299 %token <scm> STRING_IDENTIFIER
 300 %token <scm> TONICNAME_PITCH
 301
 302
 303 %type <book> book_block
 304 %type <book> book_body
 305
 306 %type <i> bare_unsigned
 307 %type <i> figured_bass_alteration
 308 %type <i> dots
 309 %type <i> exclamations
 310 %type <i> optional_rest
 311 %type <i> questions
 312 %type <i> script_dir
 313 %type <i> sub_quotes
 314 %type <i> sup_quotes
 315 %type <i> tremolo_type
 316
 317 %type <music> Composite_music
 318 %type <music> Grouped_music_list
 319 %type <music> Music
 320 %type <music> Prefix_composite_music
 321 %type <music> Repeated_music
 322 %type <music> Sequential_music
 323 %type <music> Simple_music
 324 %type <music> Simultaneous_music
 325 %type <music> chord_body
 326 %type <music> chord_body_element
 327 %type <music> command_element
 328 %type <music> command_event
 329 %type <music> context_change
 330 %type <music> direction_less_event
 331 %type <music> direction_reqd_event
 332 %type <music> event_chord
 333 %type <music> gen_text_def
 334 %type <music> music_property_def
 335 %type <music> note_chord_element
 336 %type <music> post_event
 337 %type <music> re_rhythmed_music
 338 %type <music> relative_music
 339 %type <music> simple_element
 340 %type <music> string_number_event
 341 %type <music> tempo_event
 342 %type <music> toplevel_music
 343
 344 %type <outputdef> output_def_body
 345 %type <outputdef> output_def_head
 346 %type <outputdef> output_def
 347 %type <outputdef> paper_block
 348
 349 %type <scm> Alternative_music
 350 %type <scm> Generic_prefix_music_scm
 351 %type <scm> Music_list
 352 %type <scm> absolute_pitch
 353 %type <scm> assignment_id
 354 %type <scm> bare_number
 355 %type <scm> music_function_event
 356 %type <scm> music_function_chord_body
 357 %type <scm> bass_figure
 358 %type <scm> figured_bass_modification
 359 %type <scm> br_bass_figure
 360 %type <scm> bass_number
 361 %type <scm> chord_body_elements
 362 %type <scm> chord_item
 363 %type <scm> chord_items
 364 %type <scm> chord_separator
 365 %type <scm> context_def_mod
 366 %type <scm> context_def_spec_block
 367 %type <scm> context_def_spec_body
 368 %type <scm> context_mod
 369 %type <scm> context_mod_list
 370 %type <scm> context_prop_spec
 371 %type <scm> direction_less_char
 372 %type <scm> duration_length
 373 %type <scm> embedded_scm
 374 %type <scm> figure_list
 375 %type <scm> figure_spec
 376 %type <scm> fraction
 377 %type <scm> full_markup
 378 %type <scm> identifier_init
 379 %type <scm> lilypond_header
 380 %type <scm> lilypond_header_body
 381 %type <scm> lyric_element
 382 %type <scm> lyric_markup
 383 %type <scm> markup
 384 %type <scm> markup_braced_list
 385 %type <scm> markup_braced_list_body
 386 %type <scm> markup_composed_list
 387 %type <scm> markup_head_1_item
 388 %type <scm> markup_head_1_list
 389 %type <scm> markup_list
 390 %type <scm> markup_top
 391 %type <scm> mode_changing_head
 392 %type <scm> mode_changing_head_with_context
 393 %type <scm> multiplied_duration
 394 %type <scm> new_chord
 395 %type <scm> new_lyrics
 396 %type <scm> number_expression
 397 %type <scm> number_factor
 398 %type <scm> number_term
 399 %type <scm> object_id_setting
 400 %type <scm> octave_check
 401 %type <scm> optional_context_mod
 402 %type <scm> optional_notemode_duration
 403 %type <scm> pitch
 404 %type <scm> pitch_also_in_chords
 405 %type <scm> post_events
 406 %type <scm> property_operation
 407 %type <scm> scalar
 408 %type <scm> script_abbreviation
 409 %type <scm> simple_markup
 410 %type <scm> simple_string
 411 %type <scm> steno_duration
 412 %type <scm> steno_pitch
 413 %type <scm> steno_tonic_pitch
 414 %type <scm> step_number
 415 %type <scm> step_numbers
 416 %type <scm> string
 417 %type <scm> function_scm_argument
 418
 419 %type <score> score_block
 420 %type <score> score_body
 421
 422
 423 %left '-' '+'
 424
 425 /* We don't assign precedence to / and *, because we might need varied
 426 prec levels in different prods */
 427
 428 %left UNARY_MINUS
 429
 430 %%
 431
 432 lilypond:       /* empty */
 433         | lilypond toplevel_expression {
 434         }
 435         | lilypond assignment {
 436         }
 437         | lilypond error {
 438                 THIS->error_level_ = 1;
 439         }
 440         | lilypond INVALID      {
 441                 THIS->error_level_ = 1;
 442         }
 443         ;
 444
 445
 446 object_id_setting:
 447         OBJECTID STRING { $$ = $2; }
 448         ;
 449
 450 toplevel_expression:
 451         lilypond_header {
 452                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 453         }
 454         | add_quote {
 455
 456         }
 457         | book_block {
 458                 Book *book = $1;
 459                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 460                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 461                 book->unprotect ();
 462         }
 463         | score_block {
 464                 Score *score = $1;
 465
 466                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 467                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 468                 score->unprotect ();
 469         }
 470         | toplevel_music {
 471                 Music *music = $1;
 472                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 473                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 474                 music->unprotect ();
 475         }
 476         | full_markup {
 477                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 478                 scm_call_2 (proc, THIS->self_scm (), $1);
 479         }
 480         | output_def {
 481                 SCM id = SCM_EOL;
 482                 Output_def * od = $1;
 483
 484                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 485                         id = ly_symbol2scm ("$defaultpaper");
 486                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 487                         id = ly_symbol2scm ("$defaultmidi");
 488                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 489                         id = ly_symbol2scm ("$defaultlayout");
 490
 491                 THIS->lexer_->set_identifier (id, od->self_scm ());
 492                 od->unprotect();
 493         }
 494         ;
 495
 496 toplevel_music:
 497         Composite_music {
 498         }
 499         ;
 500
 501 embedded_scm:
 502         SCM_T
 503         | SCM_IDENTIFIER
 504         ;
 505
 506
 507 lilypond_header_body:
 508         {
 509                 $$ = get_header(THIS);
 510                 THIS->lexer_->add_scope ($$);
 511         }
 512         | lilypond_header_body assignment  {
 513
 514         }
 515         ;
 516
 517 lilypond_header:
 518         HEADER '{' lilypond_header_body '}'     {
 519                 $$ = THIS->lexer_->remove_scope ();
 520         }
 521         ;
 522
 523 /*
 524         DECLARATIONS
 525 */
 526 assignment_id:
 527         STRING          { $$ = $1; }
 528         | LYRICS_STRING { $$ = $1; }
 529         ;
 530
 531 assignment:
 532         assignment_id '=' identifier_init  {
 533                 if (! is_regular_identifier ($1))
 534                 {
 535                         @1.warning (_ ("identifier should have alphabetic characters only"));
 536                 }
 537
 538                 THIS->lexer_->set_identifier ($1, $3);
 539
 540 /*
 541  TODO: devise standard for protection in parser.
 542
 543   The parser stack lives on the C-stack, which means that
 544 all objects can be unprotected as soon as they're here.
 545
 546 */
 547         }
 548         | embedded_scm { }
 549         ;
 550
 551
 552 identifier_init:
 553         score_block {
 554                 $$ = $1->self_scm ();
 555                 $1->unprotect ();
 556         }
 557         | book_block {
 558                 $$ = $1->self_scm ();
 559                 $1->unprotect ();
 560         }
 561         | output_def {
 562                 $$ = $1->self_scm ();
 563                 $1->unprotect ();
 564         }
 565         | context_def_spec_block {
 566                 $$ = $1;
 567         }
 568         | Music  {
 569                 $$ = $1->self_scm ();
 570                 $1->unprotect();
 571         }
 572         | post_event {
 573                 $$ = $1->self_scm ();
 574                 $1->unprotect();
 575         }
 576         | number_expression {
 577                 $$ = $1;
 578         }
 579         | string {
 580                 $$ = $1;
 581         }
 582         | embedded_scm {
 583                 $$ = $1;
 584         }
 585         | full_markup {
 586                 $$ = $1;
 587         }
 588         | DIGIT {
 589                 $$ = scm_from_int ($1);
 590         }
 591         ;
 592
 593 context_def_spec_block:
 594         CONTEXT '{' context_def_spec_body '}'
 595                 {
 596                 $$ = $3;
 597         }
 598         ;
 599
 600 context_def_spec_body:
 601         /**/ {
 602                 $$ = Context_def::make_scm ();
 603                 unsmob_context_def ($$)->set_spot (@$);
 604         }
 605         | CONTEXT_DEF_IDENTIFIER {
 606                 $$ = $1;
 607                 unsmob_context_def ($$)->set_spot (@$);
 608         }
 609         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 610                 Context_def*td = unsmob_context_def ($$);
 611
 612                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 613                         SCM tag = scm_caar (p);
 614
 615                         /* TODO: should make new tag "grob-definition" ? */
 616                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 617                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 618                 }
 619         }
 620         | context_def_spec_body context_mod {
 621                 unsmob_context_def ($$)->add_context_mod ($2);
 622         }
 623         ;
 624
 625
 626
 627 book_block:
 628         BOOK '{' book_body '}'  {
 629                 $$ = $3;
 630         }
 631         ;
 632
 633 /* FIXME:
 634    * Use 'handlers' like for toplevel-* stuff?
 635    * grok \layout and \midi?  */
 636 book_body:
 637         {
 638                 $$ = new Book;
 639                 $$->set_spot (@$);
 640                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 641                 $$->paper_->unprotect ();
 642                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 643         }
 644         | BOOK_IDENTIFIER {
 645                 $$ = unsmob_book ($1);
 646                 $$->set_spot (@$);
 647         }
 648         | book_body paper_block {
 649                 $$->paper_ = $2;
 650                 $2->unprotect ();
 651         }
 652         | book_body score_block {
 653                 SCM s = $2->self_scm ();
 654                 $$->add_score (s);
 655                 $2->unprotect();
 656         }
 657         | book_body full_markup {
 658                 $$->add_score ($2);
 659         }
 660         | book_body lilypond_header {
 661                 $$->header_ = $2;
 662         }
 663         | book_body error {
 664                 $$->paper_ = 0;
 665                 $$->scores_ = SCM_EOL;
 666         }
 667         | book_body object_id_setting {
 668                 $$->user_key_ = ly_scm2string ($2);
 669         }
 670         ;
 671
 672 score_block:
 673         SCORE '{' score_body '}'        {
 674                 $$ = $3;
 675         }
 676         ;
 677
 678 score_body:
 679         Music {
 680                 SCM m = $1->self_scm ();
 681                 $1->unprotect();
 682                 SCM scorify = ly_lily_module_constant ("scorify-music");
 683                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 684
 685                 // pass ownernship to C++ again.
 686                 $$ = unsmob_score (score);
 687                 $$->protect ();
 688                 $$->set_spot (@$);
 689         }
 690         | SCORE_IDENTIFIER {
 691                 $$ = unsmob_score ($1);
 692                 $$->set_spot (@$);
 693         }
 694         | score_body object_id_setting {
 695                 $$->user_key_ = ly_scm2string ($2);
 696         }
 697         | score_body lilypond_header    {
 698                 $$->header_ = $2;
 699         }
 700         | score_body output_def {
 701                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 702                 {
 703                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 704
 705                 }
 706                 else
 707                 {
 708                         $$->defs_.push ($2);
 709                 }
 710                 $2->unprotect ();
 711         }
 712         | score_body error {
 713                 $$->error_found_ = true;
 714         }
 715         ;
 716
 717
 718 /*
 719         OUTPUT DEF
 720 */
 721
 722 paper_block:
 723         output_def {
 724                 $$ = $1;
 725                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 726                 {
 727                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 728                         $$ = get_paper (THIS);
 729                 }
 730         }
 731         ;
 732
 733
 734 output_def:
 735         output_def_body '}' {
 736                 $$ = $1;
 737
 738                 THIS->lexer_->remove_scope ();
 739                 THIS->lexer_->pop_state ();
 740         }
 741         ;
 742
 743 output_def_head:
 744         PAPER {
 745                 $$ = get_paper (THIS);
 746                 $$->input_origin_ = @$;
 747                 THIS->lexer_->add_scope ($$->scope_);
 748         }
 749         | MIDI    {
 750                 Output_def *p = get_midi (THIS);
 751                 $$ = p;
 752                 THIS->lexer_->add_scope (p->scope_);
 753         }
 754         | LAYOUT        {
 755                 Output_def *p = get_layout (THIS);
 756
 757                 THIS->lexer_->add_scope (p->scope_);
 758                 $$ = p;
 759         }
 760         ;
 761
 762
 763 output_def_body:
 764         output_def_head '{' {
 765                 $$ = $1;
 766                 $$->input_origin_.set_spot (@$);
 767                 THIS->lexer_->push_initial_state ();
 768         }
 769         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 770                 $1->unprotect ();
 771                 Output_def *o = unsmob_output_def ($3);
 772                 o->input_origin_.set_spot (@$);
 773                 $$ = o;
 774                 THIS->lexer_->remove_scope ();
 775                 THIS->lexer_->add_scope (o->scope_);
 776                 THIS->lexer_->push_initial_state ();
 777         }
 778         | output_def_body assignment  {
 779
 780         }
 781         | output_def_body context_def_spec_block        {
 782                 assign_context_def ($$, $2);
 783         }
 784         | output_def_body tempo_event  {
 785                 /*
 786                         junk this ? there already is tempo stuff in
 787                         music.
 788                 */
 789                 int m = scm_to_int ($2->get_property ("metronome-count"));
 790                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 791                 set_tempo ($$, d->get_length (), m);
 792                 $2->unprotect ();
 793         }
 794         | output_def_body error {
 795
 796         }
 797         ;
 798
 799 tempo_event:
 800         TEMPO steno_duration '=' bare_unsigned  {
 801                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 802                 $$->set_property ("tempo-unit", $2);
 803                 $$->set_property ("metronome-count", scm_from_int ( $4));
 804         }
 805         ;
 806
 807 /*
 808 The representation of a  list is the
 809
 810   (LIST . LAST-CONS)
 811
 812  to have efficient append.  */
 813
 814 Music_list:
 815         /* empty */ {
 816                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 817         }
 818         | Music_list Music {
 819                 SCM s = $$;
 820                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 821                 $2->unprotect (); /* UGH */
 822
 823                 if (scm_is_pair (scm_cdr (s)))
 824                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 825                 else
 826                         scm_set_car_x (s, c); /* set first cons */
 827                 scm_set_cdr_x (s, c);  /* remember last cell */
 828         }
 829         | Music_list embedded_scm {
 830
 831         }
 832         | Music_list error {
 833                 Music * m = MY_MAKE_MUSIC("Music");
 834                 // ugh. code dup
 835                 m->set_property ("error-found", SCM_BOOL_T);
 836                 SCM s = $$;
 837                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 838                 m->unprotect (); /* UGH */
 839
 840                 if (scm_is_pair (scm_cdr (s)))
 841                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 842                 else
 843                         scm_set_car_x (s, c); /* set first cons */
 844                 scm_set_cdr_x (s, c);  /* remember last cell */
 845         }
 846         ;
 847
 848 Music:
 849         Simple_music
 850         | Composite_music
 851         ;
 852
 853 Alternative_music:
 854         /* empty */ {
 855                 $$ = SCM_EOL;
 856         }
 857         | ALTERNATIVE '{' Music_list '}' {
 858                 $$ = $3;
 859         }
 860         ;
 861
 862
 863 Repeated_music:
 864         REPEAT simple_string bare_unsigned Music Alternative_music
 865         {
 866                 Music *beg = $4;
 867                 int times = $3;
 868                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 869                 if (times < scm_ilength (alts)) {
 870                   unsmob_music (scm_car (alts))
 871                     ->origin ()->warning (
 872                     _ ("more alternatives than repeats"));
 873                     warning ("junking excess alternatives");
 874                   alts = ly_truncate_list (times, alts);
 875                 }
 876
 877
 878                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 879
 880                 SCM mus = scm_call_1 (proc, $2);
 881                 Music *r = unsmob_music (mus);
 882                 r->protect ();
 883                 if (beg)
 884                         {
 885                         r-> set_property ("element", beg->self_scm ());
 886                         beg->unprotect ();
 887                         }
 888                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
 889
 890                 r-> set_property ("elements",alts);
 891                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
 892                         /*
 893                         TODO: move this code to Scheme.
 894                         */
 895
 896                         /* we cannot get durations and other stuff
 897                            correct down the line,
 898                            so we have to add to the duration log here. */
 899                         SCM func = ly_lily_module_constant ("shift-duration-log");
 900
 901                         int dots = ($3 % 3) ? 0 : 1;
 902                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 903
 904
 905                         if ($4->is_mus_type ("sequential-music"))
 906                         {
 907                                 int list_len = scm_ilength ($4->get_property ("elements"));
 908                                 if (list_len != 2)
 909                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
 910                                 shift -= 1;
 911                                 r->compress (Moment (Rational (1, list_len)));
 912                         }
 913                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
 914
 915                 }
 916                 r->set_spot (*$4->origin ());
 917
 918                 $$ = r;
 919         }
 920         ;
 921
 922 Sequential_music:
 923         SEQUENTIAL '{' Music_list '}'           {
 924                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 925                 $$->set_property ("elements", scm_car ($3));
 926                 $$->set_spot (@$);
 927         }
 928         | '{' Music_list '}'            {
 929                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 930                 $$->set_property ("elements", scm_car ($2));
 931                 $$->set_spot (@$);
 932         }
 933         ;
 934
 935 Simultaneous_music:
 936         SIMULTANEOUS '{' Music_list '}'{
 937                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 938                 $$->set_property ("elements", scm_car ($3));
 939                 $$->set_spot (@$);
 940
 941         }
 942         | simul_open Music_list simul_close     {
 943                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 944                 $$->set_property ("elements", scm_car ($2));
 945                 $$->set_spot (@$);
 946         }
 947         ;
 948
 949 Simple_music:
 950         event_chord             { $$ = $1; }
 951         | MUSIC_IDENTIFIER {
 952                 $$ = unsmob_music ($1);
 953         }
 954         | music_property_def
 955         | context_change
 956         ;
 957
 958
 959 optional_context_mod:
 960         /**/ { $$ = SCM_EOL; }
 961         | WITH { THIS->lexer_->push_initial_state (); }
 962         '{' context_mod_list '}'
 963         {
 964                 THIS->lexer_->pop_state ();
 965                 $$ = $4;
 966         }
 967         ;
 968
 969 context_mod_list:
 970         /* */  { $$ = SCM_EOL; }
 971         | context_mod_list context_mod  {
 972                  $$ = scm_cons ($2, $1);
 973         }
 974         ;
 975
 976
 977 Composite_music:
 978         Prefix_composite_music { $$ = $1; }
 979         | Grouped_music_list { $$ = $1; }
 980         ;
 981
 982 Grouped_music_list:
 983         Simultaneous_music              { $$ = $1; }
 984         | Sequential_music              { $$ = $1; }
 985         ;
 986
 987
 988 function_scm_argument:
 989         embedded_scm
 990         | simple_string
 991         ;
 992
 993 Generic_prefix_music_scm:
 994         MUSIC_FUNCTION {
 995                 $$ = scm_list_2 ($1, make_input (@$));
 996         }
 997         | MUSIC_FUNCTION_SCM function_scm_argument {
 998                 $$ = scm_list_3 ($1, make_input (@$), $2);
 999         }
1000         | MUSIC_FUNCTION_MARKUP full_markup {
1001                 $$ = scm_list_3 ($1, make_input (@$), $2);
1002         }
1003
1004         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument Music {
1005                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1006                 $3->unprotect ();
1007         }
1008         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
1009                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1010         }
1011         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
1012                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1013         }
1014         | MUSIC_FUNCTION_MUSIC Music {
1015                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1016                 $2->unprotect ();
1017         }
1018         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument Music {
1019                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1020         }
1021         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1022                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1023                 $3->unprotect ();
1024         }
1025         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1026                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1027         }
1028         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1029                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1030                 $2->unprotect ();
1031                 $3->unprotect ();
1032         }
1033         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
1034                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1035                 $4->unprotect ();
1036                 $3->unprotect ();
1037         }
1038         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1039                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1040                 $3->unprotect ();
1041                 $4->unprotect ();
1042         }
1043         ;
1044
1045 Prefix_composite_music:
1046         Generic_prefix_music_scm {
1047                 $$ = run_music_function (THIS, $1);
1048         }
1049         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1050                 $$ = context_spec_music ($2, $4, $6, $5);
1051
1052         }
1053         | CONTEXT simple_string optional_context_mod Music {
1054                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1055         }
1056         | NEWCONTEXT simple_string optional_context_mod Music {
1057                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1058                         $3);
1059         }
1060
1061         | TIMES fraction Music
1062
1063         {
1064                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1065                 Music *mp = $3;
1066
1067                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1068                 $$->set_spot (@$);
1069
1070                 $$->set_property ("element", mp->self_scm ());
1071                 mp->unprotect();
1072                 $$->set_property ("numerator", scm_from_int (n));
1073                 $$->set_property ("denominator", scm_from_int (d));
1074                 $$->compress (Moment (Rational (n,d)));
1075
1076         }
1077         | Repeated_music                { $$ = $1; }
1078         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1079                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1080                 Music *p = $4;
1081                 Pitch from = *unsmob_pitch ($2);
1082                 Pitch to = *unsmob_pitch ($3);
1083
1084                 p->transpose (pitch_interval (from, to));
1085                 $$->set_property ("element", p->self_scm ());
1086                 p->unprotect();
1087         }
1088         | mode_changing_head Grouped_music_list {
1089                 if ($1 == ly_symbol2scm ("chords"))
1090                 {
1091                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1092                   chm->set_property ("element", $2->self_scm ());
1093                   $$ = chm;
1094                   $2->unprotect();
1095                 }
1096                 else
1097                 {
1098                   $$ = $2;
1099                 }
1100                 THIS->lexer_->pop_state ();
1101         }
1102         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1103                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1104                                          $3, $2);
1105                 if ($1 == ly_symbol2scm ("ChordNames"))
1106                 {
1107                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1108                   chm->set_property ("element", $$->self_scm ());
1109                   $$->unprotect();
1110                   $$ = chm;
1111                 }
1112                 THIS->lexer_->pop_state ();
1113         }
1114         | relative_music        { $$ = $1; }
1115         | re_rhythmed_music     { $$ = $1; }
1116         ;
1117
1118 mode_changing_head:
1119         NOTEMODE {
1120                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1121                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1122
1123                 $$ = ly_symbol2scm ("notes");
1124         }
1125         | DRUMMODE
1126                 {
1127                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1128                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1129
1130                 $$ = ly_symbol2scm ("drums");
1131         }
1132         | FIGUREMODE {
1133                 THIS->lexer_->push_figuredbass_state ();
1134
1135                 $$ = ly_symbol2scm ("figures");
1136         }
1137         | CHORDMODE {
1138                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1139                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1140                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1141                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1142                 $$ = ly_symbol2scm ("chords");
1143
1144         }
1145         | LYRICMODE
1146                 { THIS->lexer_->push_lyric_state ();
1147                 $$ = ly_symbol2scm ("lyrics");
1148         }
1149         ;
1150
1151 mode_changing_head_with_context:
1152         DRUMS {
1153                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1154                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1155
1156                 $$ = ly_symbol2scm ("DrumStaff");
1157         }
1158         | FIGURES {
1159                 THIS->lexer_->push_figuredbass_state ();
1160
1161                 $$ = ly_symbol2scm ("FiguredBass");
1162         }
1163         | CHORDS {
1164                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1165                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1166                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1167                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1168                 $$ = ly_symbol2scm ("ChordNames");
1169         }
1170         | LYRICS
1171                 { THIS->lexer_->push_lyric_state ();
1172                 $$ = ly_symbol2scm ("Lyrics");
1173         }
1174         ;
1175
1176
1177 relative_music:
1178         RELATIVE absolute_pitch Music {
1179                 Music *m = $3;
1180                 Pitch start = *unsmob_pitch ($2);
1181                 $$ = make_music_relative (start, m);
1182                 m->unprotect();
1183         }
1184         | RELATIVE Composite_music {
1185                 Music *m = $2;
1186
1187                 Pitch middle_c (0, 0, 0);
1188                 $$ = make_music_relative (middle_c, m);
1189                 m->unprotect();
1190         }
1191         ;
1192
1193 new_lyrics:
1194         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1195         /*cont */
1196         Grouped_music_list {
1197         /* Can also use Music at the expensive of two S/Rs similar to
1198            \repeat \alternative */
1199                 THIS->lexer_->pop_state ();
1200
1201                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1202         }
1203         | new_lyrics ADDLYRICS {
1204                 THIS->lexer_->push_lyric_state ();
1205         } Grouped_music_list {
1206                 THIS->lexer_->pop_state ();
1207                 $$ = scm_cons ($4->self_scm (), $1);
1208         }
1209         ;
1210
1211 re_rhythmed_music:
1212         Grouped_music_list new_lyrics {
1213                 Music * voice = $1;
1214                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1215                 if (!scm_is_string (name))
1216                 {
1217                         name = get_next_unique_lyrics_context_id ();
1218                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1219                                                     name,
1220                                                     voice, SCM_EOL);
1221                 }
1222
1223                 SCM context = scm_makfrom0str ("Lyrics");
1224                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1225
1226                 SCM lst = SCM_EOL;
1227                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1228                 {
1229                         Music *music = unsmob_music (scm_car (s));
1230                         Music *com = make_lyric_combine_music (name, music);
1231                         Music *csm = context_spec_music (context,
1232                                 get_next_unique_context_id (), com, SCM_EOL);
1233                         lst = scm_cons (csm->self_scm (), lst);
1234                 }
1235                 all->set_property ("elements", scm_cons (voice->self_scm (),
1236                         lst));
1237                 $$ = all;
1238                 voice->unprotect ();
1239         }
1240         | LYRICSTO simple_string {
1241                 THIS->lexer_->push_lyric_state ();
1242         } Music {
1243                 THIS->lexer_->pop_state ();
1244                 Music *music = $4;
1245                 SCM name = $2;
1246                 $$ = make_lyric_combine_music (name, music);
1247                 music->unprotect();
1248         }
1249         ;
1250
1251 context_change:
1252         CHANGE STRING '=' STRING  {
1253                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1254                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1255                 t-> set_property ("change-to-id", $4);
1256
1257                 $$ = t;
1258                 $$->set_spot (@$);
1259         }
1260         ;
1261
1262 property_operation:
1263         STRING '=' scalar {
1264                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1265                         scm_string_to_symbol ($1), $3);
1266         }
1267         | UNSET simple_string {
1268                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1269                         scm_string_to_symbol ($2));
1270         }
1271         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1272                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1273                         scm_string_to_symbol ($2), $5, $3);
1274         }
1275         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1276                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1277                                 scm_string_to_symbol ($2), $6, $4, $3);
1278         }
1279         | REVERT simple_string embedded_scm {
1280                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1281                         scm_string_to_symbol ($2), $3);
1282         }
1283         ;
1284
1285 context_def_mod:
1286         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1287         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1288
1289         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1290         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1291         | DENIES { $$ = ly_symbol2scm ("denies"); }
1292
1293         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1294         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1295         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1296         | NAME { $$ = ly_symbol2scm ("context-name"); }
1297         ;
1298
1299 context_mod:
1300         property_operation { $$ = $1; }
1301         | context_def_mod STRING {
1302                 $$ = scm_list_2 ($1, $2);
1303         }
1304         ;
1305
1306 context_prop_spec:
1307         simple_string {
1308                 if (!is_regular_identifier ($1))
1309                 {
1310                         @$.error (_("Grob name should be alphanumeric"));
1311                 }
1312
1313                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1314                         scm_string_to_symbol ($1));
1315         }
1316         | simple_string '.' simple_string {
1317                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1318                         scm_string_to_symbol ($3));
1319         }
1320         ;
1321
1322 music_property_def:
1323         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1324                 $$ = property_op_to_music (scm_list_4 (
1325                         ly_symbol2scm ("push"),
1326                         scm_cadr ($2),
1327                         $5, $3));
1328                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1329         }
1330         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1331                 $$ = property_op_to_music (scm_list_5 (
1332                         ly_symbol2scm ("push"),
1333                         scm_cadr ($2),
1334                         $6, $4, $3));
1335                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1336         }
1337         | REVERT context_prop_spec embedded_scm {
1338                 $$ = property_op_to_music (scm_list_3 (
1339                         ly_symbol2scm ("pop"),
1340                         scm_cadr ($2),
1341                         $3));
1342
1343                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1344         }
1345         | SET context_prop_spec '=' scalar {
1346                 $$ = property_op_to_music (scm_list_3 (
1347                         ly_symbol2scm ("assign"),
1348                         scm_cadr ($2),
1349                         $4));
1350                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1351         }
1352         | UNSET context_prop_spec {
1353                 $$ = property_op_to_music (scm_list_2 (
1354                         ly_symbol2scm ("unset"),
1355                         scm_cadr ($2)));
1356                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1357         }
1358         | ONCE music_property_def {
1359                 SCM e = $2->get_property ("element");
1360                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1361                 $$ = $2;
1362
1363         }
1364         ;
1365
1366
1367 string:
1368         STRING {
1369                 $$ = $1;
1370         }
1371         | STRING_IDENTIFIER {
1372                 $$ = $1;
1373         }
1374         | string '+' string {
1375                 $$ = scm_string_append (scm_list_2 ($1, $3));
1376         }
1377         ;
1378
1379 simple_string: STRING {
1380                 $$ = $1;
1381         }
1382         | LYRICS_STRING {
1383                 $$ = $1;
1384         }
1385         | STRING_IDENTIFIER {
1386                 $$ = $1;
1387         }
1388         ;
1389
1390 scalar: string {
1391                 $$ = $1;
1392         }
1393         | LYRICS_STRING {
1394                 $$ = $1;
1395         }
1396         | bare_number {
1397                 $$ = $1;
1398         }
1399         | embedded_scm {
1400                 $$ = $1;
1401         }
1402         | full_markup {
1403                 $$ = $1;
1404         }
1405         | DIGIT {
1406                 $$ = scm_from_int ($1);
1407         }
1408         ;
1409
1410 /*
1411
1412 pre_events doesn't contain anything. It is a trick:
1413
1414 Adding pre_events to the simple_element
1415 makes the choice between
1416
1417   string:  STRING
1418
1419 and
1420
1421   simple_element: STRING
1422
1423 a single shift/reduction conflict.
1424
1425 nevertheless, this is not very clean, and we should find a different
1426 solution.
1427
1428 */
1429 pre_events: /* empty */
1430         ;
1431
1432 event_chord:
1433         pre_events simple_element post_events   {
1434                 SCM elts = $2-> get_property ("elements");
1435
1436                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1437
1438                 $2->set_property ("elements", elts);
1439                 /* why is this giving wrong start location? -ns
1440                  * $2->set_spot (@$); */
1441                 Input i;
1442                 i.set_location (@2, @3);
1443                 $2->set_spot (i);
1444                 $$ = $2;
1445         }
1446         | command_element
1447         | note_chord_element
1448         ;
1449
1450
1451 note_chord_element:
1452         chord_body optional_notemode_duration post_events
1453         {
1454                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1455                 SCM es = $1->get_property ("elements");
1456                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1457
1458                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1459                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1460                 es = ly_append2 (es, postevs);
1461
1462                 $1-> set_property ("elements", es);
1463                 $1->set_spot (@$);
1464                 $$ = $1;
1465         }
1466         ;
1467
1468 chord_open: '<'
1469         ;
1470
1471 chord_close: '>'
1472         ;
1473
1474 simul_open: DOUBLE_ANGLE_OPEN
1475         ;
1476
1477 simul_close: DOUBLE_ANGLE_CLOSE
1478         ;
1479
1480 chord_body:
1481         chord_open chord_body_elements chord_close
1482         {
1483                 $$ = MY_MAKE_MUSIC ("EventChord");
1484                 $$->set_spot (@$);
1485                 $$->set_property ("elements",
1486                         scm_reverse_x ($2, SCM_EOL));
1487         }
1488         ;
1489
1490 chord_body_elements:
1491         /* empty */             { $$ = SCM_EOL; }
1492         | chord_body_elements chord_body_element {
1493                 $$ = scm_cons ($2->self_scm (), $1);
1494                 $2->unprotect ();
1495         }
1496         ;
1497
1498 chord_body_element:
1499         pitch exclamations questions octave_check post_events
1500         {
1501                 int q = $3;
1502                 int ex = $2;
1503                 SCM check = $4;
1504                 SCM post = $5;
1505
1506                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1507                 n->set_property ("pitch", $1);
1508                 n->set_spot (@$);
1509                 if (q % 2)
1510                         n->set_property ("cautionary", SCM_BOOL_T);
1511                 if (ex % 2 || q % 2)
1512                         n->set_property ("force-accidental", SCM_BOOL_T);
1513
1514                 if (scm_is_pair (post)) {
1515                         SCM arts = scm_reverse_x (post, SCM_EOL);
1516                         n->set_property ("articulations", arts);
1517                 }
1518                 if (scm_is_number (check))
1519                 {
1520                         int q = scm_to_int (check);
1521                         n->set_property ("absolute-octave", scm_from_int (q-1));
1522                 }
1523
1524
1525                 $$ = n;
1526         }
1527         | DRUM_PITCH post_events {
1528                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1529                 n->set_property ("duration", $2);
1530                 n->set_property ("drum-type", $1);
1531                 n->set_spot (@$);
1532
1533                 if (scm_is_pair ($2)) {
1534                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1535                         n->set_property ("articulations", arts);
1536                 }
1537                 $$ = n;
1538         }
1539         | music_function_chord_body {
1540                 $$ = run_music_function (THIS, $1);
1541                 $$->set_spot (@$);
1542         }
1543         ;
1544
1545 music_function_chord_body:
1546         MUSIC_FUNCTION {
1547                 $$ = scm_list_2 ($1, make_input (@$));
1548         }
1549         | MUSIC_FUNCTION_MUSIC chord_body_element {
1550                 $$ = scm_list_3 ($1, make_input (@$),
1551                                         $2->self_scm ());
1552         }
1553         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument chord_body_element {
1554                 $$ = scm_list_4 ($1, make_input (@$),
1555                                         $2, $3->self_scm ());
1556         }
1557         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument
1558                 chord_body_element {
1559
1560                 $$ = scm_list_5 ($1, make_input (@$),
1561                                         $2, $3, $4->self_scm ());
1562         }
1563         ;
1564
1565
1566 add_quote:
1567         ADDQUOTE string Music {
1568                 SCM adder = ly_lily_module_constant ("add-quotable");
1569
1570                 scm_call_2 (adder, $2, $3->self_scm ());
1571                 $3->unprotect();
1572         }
1573         ;
1574
1575 command_element:
1576         command_event {
1577                 $$ = MY_MAKE_MUSIC ("EventChord");
1578                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1579                 $1->unprotect();
1580
1581                 $$-> set_spot (@$);
1582                 $1-> set_spot (@$);
1583         }
1584         | SKIP duration_length {
1585                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1586                 skip->set_property ("duration", $2);
1587                 skip->set_spot (@$);
1588                 $$ = skip;
1589         }
1590         | OCTAVE pitch {
1591                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1592                 $$ = m;
1593                 $$->set_spot (@$);
1594                 $$->set_property ("pitch", $2);
1595         }
1596         | E_BRACKET_OPEN {
1597                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1598                 m->set_property ("span-direction", scm_from_int (START));
1599                 m->set_spot (@$);
1600
1601                 $$ = MY_MAKE_MUSIC ("EventChord");
1602                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1603                 m->unprotect();
1604                 $$->set_spot (@$);
1605         }
1606         | E_BRACKET_CLOSE {
1607                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1608                 m->set_property ("span-direction", scm_from_int (STOP));
1609                 m->set_spot (@$);
1610
1611                 $$ = MY_MAKE_MUSIC ("EventChord");
1612                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1613                 $$->set_spot (@$);
1614                 m->unprotect ();
1615         }
1616         | E_BACKSLASH {
1617                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1618                 $$->set_spot (@$);
1619         }
1620         | '|'      {
1621                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1622
1623                 if (Music * m = unsmob_music (pipe))
1624                         $$ = m->clone ();
1625                 else
1626                         $$ = MY_MAKE_MUSIC ("BarCheck");
1627
1628                 $$->set_spot (@$);
1629         }
1630         | TRANSPOSITION pitch {
1631                 Pitch middle_c;
1632                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1633                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1634                                          sounds_as_c.smobbed_copy());
1635                 $$->set_spot (@$);
1636                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1637                         $$, SCM_EOL);
1638         }
1639         | BAR STRING                    {
1640                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1641
1642                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1643                                         t, SCM_EOL);
1644                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1645                 $$->set_spot (@$);
1646                 t->set_spot (@$);
1647         }
1648         | PARTIAL duration_length       {
1649                 Moment m = - unsmob_duration ($2)->get_length ();
1650                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1651                 p->set_spot (@$);
1652                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1653                                         p, SCM_EOL);
1654                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1655                                         p, SCM_EOL);
1656                 $$ = p;
1657         }
1658         | CLEF STRING  {
1659                 SCM proc = ly_lily_module_constant ("make-clef-set");
1660
1661                 SCM result = scm_call_1 (proc, $2);
1662                 $$ = unsmob_music (result);
1663                 $$->protect ();
1664         }
1665         | TIME_T fraction  {
1666                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1667
1668                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1669                 $$ = unsmob_music (result);
1670                 $$->protect ();
1671         }
1672         | MARK scalar {
1673                 SCM proc = ly_lily_module_constant ("make-mark-set");
1674
1675                 SCM result = scm_call_1 (proc, $2);
1676                 $$ = unsmob_music (result);
1677                 $$->protect ();
1678         }
1679         ;
1680
1681 command_event:
1682         E_TILDE {
1683                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1684         }
1685         | MARK DEFAULT  {
1686                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1687                 $$ = m;
1688         }
1689         | tempo_event {
1690                 $$ = $1;
1691         }
1692         | KEY DEFAULT {
1693                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1694                 $$ = key;
1695         }
1696         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1697
1698                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1699                 if (scm_ilength ($3) > 0)
1700                 {
1701                         key->set_property ("pitch-alist", $3);
1702                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1703                         key->transpose (* unsmob_pitch ($2));
1704                 } else {
1705                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1706                 }
1707
1708                 $$ = key;
1709         }
1710         ;
1711
1712
1713 post_events:
1714         /* empty */ {
1715                 $$ = SCM_EOL;
1716         }
1717         | post_events post_event {
1718                 $2->set_spot (@2);
1719                 $$ = scm_cons ($2->self_scm (), $$);
1720                 $2->unprotect ();
1721         }
1722         ;
1723
1724 music_function_event:
1725         MUSIC_FUNCTION_MUSIC post_event {
1726                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1727         }
1728         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument post_event {
1729                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1730         }
1731         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument post_event {
1732                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1733         }
1734         ;
1735
1736
1737 post_event:
1738         direction_less_event {
1739                 $$ = $1;
1740         }
1741         | '-' music_function_event {
1742                 Music *mus = run_music_function (THIS, $2);
1743                 mus->set_spot (@1);
1744                 $$ = mus;
1745         }
1746         | HYPHEN {
1747                 if (!THIS->lexer_->is_lyric_state ())
1748                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1749                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1750         }
1751         | EXTENDER {
1752                 if (!THIS->lexer_->is_lyric_state ())
1753                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1754                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1755         }
1756         | script_dir direction_reqd_event {
1757                 if ($1)
1758                         $2->set_property ("direction", scm_from_int ($1));
1759                 $$ = $2;
1760         }
1761         | script_dir direction_less_event {
1762                 if ($1)
1763                         $2->set_property ("direction", scm_from_int ($1));
1764                 $$ = $2;
1765         }
1766         | string_number_event
1767         ;
1768
1769 string_number_event:
1770         E_UNSIGNED {
1771                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1772                 s->set_property ("string-number", scm_from_int ($1));
1773                 s->set_spot (@$);
1774                 $$ = s;
1775         }
1776         ;
1777
1778 direction_less_char:
1779         '['  {
1780                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1781         }
1782         | ']'  {
1783                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1784         }
1785         | '~'  {
1786                 $$ = ly_symbol2scm ("tildeSymbol");
1787         }
1788         | '('  {
1789                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1790         }
1791         | ')'  {
1792                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1793         }
1794         | E_EXCLAMATION  {
1795                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1796         }
1797         | E_OPEN  {
1798                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1799         }
1800         | E_CLOSE  {
1801                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1802         }
1803         | E_ANGLE_CLOSE  {
1804                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1805         }
1806         | E_ANGLE_OPEN  {
1807                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1808         }
1809         ;
1810
1811 direction_less_event:
1812         direction_less_char {
1813                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1814                 Music * m = 0;
1815                 if (unsmob_music (predefd))
1816                 {
1817                         m = unsmob_music (predefd)->clone ();
1818                 }
1819                 else
1820                 {
1821                         m = MY_MAKE_MUSIC ("Music");
1822                 }
1823                 m->set_spot (@$);
1824                 $$ = m;
1825         }
1826         | EVENT_IDENTIFIER      {
1827                 $$ = unsmob_music ($1);
1828         }
1829         | tremolo_type  {
1830                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1831                a->set_spot (@$);
1832                a->set_property ("tremolo-type", scm_from_int ($1));
1833                $$ = a;
1834         }
1835         ;
1836
1837 direction_reqd_event:
1838         gen_text_def {
1839                 $$ = $1;
1840         }
1841         | script_abbreviation {
1842                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1843                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1844                 if (scm_is_string (s))
1845                         a->set_property ("articulation-type", s);
1846                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1847                 $$ = a;
1848         }
1849         ;
1850
1851 octave_check:
1852         /**/ { $$ = SCM_EOL; }
1853         | '='  { $$ = scm_from_int (0); }
1854         | '=' sub_quotes { $$ = scm_from_int ($2); }
1855         | '=' sup_quotes { $$ = scm_from_int ($2); }
1856         ;
1857
1858 sup_quotes:
1859         '\'' {
1860                 $$ = 1;
1861         }
1862         | sup_quotes '\'' {
1863                 $$ ++;
1864         }
1865         ;
1866
1867 sub_quotes:
1868         ',' {
1869                 $$ = 1;
1870         }
1871         | sub_quotes ',' {
1872                 $$++;
1873         }
1874         ;
1875
1876 steno_pitch:
1877         NOTENAME_PITCH  {
1878                 $$ = $1;
1879         }
1880         | NOTENAME_PITCH sup_quotes     {
1881                 Pitch p = *unsmob_pitch ($1);
1882                 p = p.transposed (Pitch ($2,0,0));
1883                 $$ = p.smobbed_copy ();
1884         }
1885         | NOTENAME_PITCH sub_quotes      {
1886                 Pitch p =* unsmob_pitch ($1);
1887                 p = p.transposed (Pitch (-$2,0,0));
1888                 $$ = p.smobbed_copy ();
1889         }
1890         ;
1891
1892 /*
1893 ugh. duplication
1894 */
1895
1896 steno_tonic_pitch:
1897         TONICNAME_PITCH {
1898                 $$ = $1;
1899         }
1900         | TONICNAME_PITCH sup_quotes    {
1901                 Pitch p = *unsmob_pitch ($1);
1902                 p = p.transposed (Pitch ($2,0,0));
1903                 $$ = p.smobbed_copy ();
1904         }
1905         | TONICNAME_PITCH sub_quotes     {
1906                 Pitch p =* unsmob_pitch ($1);
1907
1908                 p = p.transposed (Pitch (-$2,0,0));
1909                 $$ = p.smobbed_copy ();
1910         }
1911         ;
1912
1913 pitch:
1914         steno_pitch {
1915                 $$ = $1;
1916         }
1917         ;
1918
1919 pitch_also_in_chords:
1920         pitch
1921         | steno_tonic_pitch
1922         ;
1923
1924 gen_text_def:
1925         full_markup {
1926                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1927                 t->set_property ("text", $1);
1928                 t->set_spot (@$);
1929                 $$ = t;
1930         }
1931         | string {
1932                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1933                 t->set_property ("text",
1934                         make_simple_markup ($1));
1935                 t->set_spot (@$);
1936                 $$ = t;
1937
1938         }
1939         | DIGIT {
1940                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1941                 t->set_property ("digit", scm_from_int ($1));
1942                 t->set_spot (@$);
1943                 $$ = t;
1944         }
1945         ;
1946
1947 script_abbreviation:
1948         '^'             {
1949                 $$ = scm_makfrom0str ("Hat");
1950         }
1951         | '+'           {
1952                 $$ = scm_makfrom0str ("Plus");
1953         }
1954         | '-'           {
1955                 $$ = scm_makfrom0str ("Dash");
1956         }
1957         | '|'           {
1958                 $$ = scm_makfrom0str ("Bar");
1959         }
1960         | '>'           {
1961                 $$ = scm_makfrom0str ("Larger");
1962         }
1963         | '.'           {
1964                 $$ = scm_makfrom0str ("Dot");
1965         }
1966         | '_' {
1967                 $$ = scm_makfrom0str ("Underscore");
1968         }
1969         ;
1970
1971 script_dir:
1972         '_'     { $$ = DOWN; }
1973         | '^'   { $$ = UP; }
1974         | '-'   { $$ = CENTER; }
1975         ;
1976
1977
1978 absolute_pitch:
1979         steno_pitch     {
1980                 $$ = $1;
1981         }
1982         ;
1983
1984 duration_length:
1985         multiplied_duration {
1986                 $$ = $1;
1987         }
1988         ;
1989
1990 optional_notemode_duration:
1991         {
1992                 Duration dd = THIS->default_duration_;
1993                 $$ = dd.smobbed_copy ();
1994         }
1995         | multiplied_duration   {
1996                 $$ = $1;
1997                 THIS->default_duration_ = *unsmob_duration ($$);
1998         }
1999         ;
2000
2001 steno_duration:
2002         bare_unsigned dots              {
2003                 int len = 0;
2004                 if (!is_duration ($1))
2005                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
2006                 else
2007                         len = intlog2 ($1);
2008
2009                 $$ = Duration (len, $2).smobbed_copy ();
2010         }
2011         | DURATION_IDENTIFIER dots      {
2012                 Duration *d = unsmob_duration ($1);
2013                 Duration k (d->duration_log (), d->dot_count () + $2);
2014                 *d = k;
2015                 $$ = $1;
2016         }
2017         ;
2018
2019 multiplied_duration:
2020         steno_duration {
2021                 $$ = $1;
2022         }
2023         | multiplied_duration '*' bare_unsigned {
2024                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2025         }
2026         | multiplied_duration '*' FRACTION {
2027                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2028
2029                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2030         }
2031         ;
2032
2033 fraction:
2034         FRACTION { $$ = $1; }
2035         | UNSIGNED '/' UNSIGNED {
2036                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2037         }
2038         ;
2039
2040 dots:
2041         /* empty */     {
2042                 $$ = 0;
2043         }
2044         | dots '.' {
2045                 $$ ++;
2046         }
2047         ;
2048
2049 tremolo_type:
2050         ':'     {
2051                 $$ = 0;
2052         }
2053         | ':' bare_unsigned {
2054                 if (!is_duration ($2))
2055                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2056                 $$ = $2;
2057         }
2058         ;
2059
2060 bass_number:
2061         DIGIT   {
2062                 $$ = scm_from_int ($1);
2063         }
2064         | UNSIGNED {
2065                 $$ = scm_from_int ($1);
2066         }
2067         | STRING { $$ = $1; }
2068         | full_markup { $$ = $1; }
2069         ;
2070
2071 figured_bass_alteration:
2072         '-'     { $$ = -2; }
2073         | '+'   { $$ = 2; }
2074         | '!'   { $$ = 0; }
2075         ;
2076
2077 bass_figure:
2078         FIGURE_SPACE {
2079                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2080                 $$ = bfr->self_scm ();
2081                 bfr->unprotect ();
2082         }
2083         | bass_number  {
2084                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2085                 $$ = bfr->self_scm ();
2086
2087                 if (scm_is_number ($1))
2088                         bfr->set_property ("figure", $1);
2089                 else if (Text_interface::is_markup ($1))
2090                         bfr->set_property ("text", $1);
2091
2092                 bfr->unprotect ();
2093         }
2094         | bass_figure ']' {
2095                 $$ = $1;
2096                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2097         }
2098         | bass_figure figured_bass_alteration {
2099                 Music *m = unsmob_music ($1);
2100                 if ($2) {
2101                         SCM salter = m->get_property ("alteration");
2102                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2103                         m->set_property ("alteration",
2104                                 scm_from_int (alter + $2));
2105                 } else {
2106                         m->set_property ("alteration", scm_from_int (0));
2107                 }
2108         }
2109         | bass_figure figured_bass_modification  {
2110                 Music *m = unsmob_music ($1);
2111                 if ($2 == ly_symbol2scm ("plus"))
2112                         {
2113                         m->set_property ("augmented", SCM_BOOL_T);
2114                         }
2115                 else if ($2 == ly_symbol2scm ("slash"))
2116                         {
2117                         m->set_property ("diminished", SCM_BOOL_T);
2118                         }
2119                 else if ($2 == ly_symbol2scm ("exclamation"))
2120                         {
2121                         m->set_property ("no-continuation", SCM_BOOL_T);
2122                         }
2123         }
2124         ;
2125
2126
2127 figured_bass_modification:
2128         E_PLUS          {
2129                 $$ = ly_symbol2scm ("plus");
2130         }
2131         | E_EXCLAMATION {
2132                 $$ = ly_symbol2scm ("exclamation");
2133         }
2134         | '/'           {
2135                 $$ = ly_symbol2scm ("slash");
2136         }
2137         ;
2138
2139 br_bass_figure:
2140         bass_figure {
2141                 $$ = $1;
2142         }
2143         | '[' bass_figure {
2144                 $$ = $2;
2145                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2146         }
2147         ;
2148
2149 figure_list:
2150         /**/            {
2151                 $$ = SCM_EOL;
2152         }
2153         | figure_list br_bass_figure {
2154                 $$ = scm_cons ($2, $1);
2155         }
2156         ;
2157
2158 figure_spec:
2159         FIGURE_OPEN figure_list FIGURE_CLOSE {
2160                 Music *m = MY_MAKE_MUSIC ("EventChord");
2161                 $2 = scm_reverse_x ($2, SCM_EOL);
2162                 m->set_property ("elements", $2);
2163                 $$ = m->self_scm ();
2164         }
2165         ;
2166
2167
2168 optional_rest:
2169         /**/   { $$ = 0; }
2170         | REST { $$ = 1; }
2171         ;
2172
2173 simple_element:
2174         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2175                 if (!THIS->lexer_->is_note_state ())
2176                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2177
2178                 Music *n = 0;
2179                 if ($6)
2180                         n = MY_MAKE_MUSIC ("RestEvent");
2181                 else
2182                         n = MY_MAKE_MUSIC ("NoteEvent");
2183
2184                 n->set_property ("pitch", $1);
2185                 n->set_property ("duration", $5);
2186
2187                 if (scm_is_number ($4))
2188                 {
2189                         int q = scm_to_int ($4);
2190                         n->set_property ("absolute-octave", scm_from_int (q-1));
2191                 }
2192
2193                 if ($3 % 2)
2194                         n->set_property ("cautionary", SCM_BOOL_T);
2195                 if ($2 % 2 || $3 % 2)
2196                         n->set_property ("force-accidental", SCM_BOOL_T);
2197
2198                 Music *v = MY_MAKE_MUSIC ("EventChord");
2199                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2200                 n->unprotect ();
2201
2202                 v->set_spot (@$);
2203                 n->set_spot (@$);
2204                 $$ = v;
2205         }
2206         | DRUM_PITCH optional_notemode_duration {
2207                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2208                 n->set_property ("duration", $2);
2209                 n->set_property ("drum-type", $1);
2210
2211                 Music *v = MY_MAKE_MUSIC ("EventChord");
2212                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2213                 n->unprotect ();
2214                 v->set_spot (@$);
2215                 n->set_spot (@$);
2216                 $$ = v;
2217
2218         }
2219         | figure_spec optional_notemode_duration {
2220                 Music *m = unsmob_music ($1);
2221                 m->set_spot (@$);
2222                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2223                 {
2224                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2225                 }
2226                 $$ = m;
2227         }
2228         | RESTNAME optional_notemode_duration           {
2229                 Music *ev = 0;
2230                 if (ly_scm2string ($1) == "s") {
2231                         /* Space */
2232                         ev = MY_MAKE_MUSIC ("SkipEvent");
2233                   }
2234                 else {
2235                         ev = MY_MAKE_MUSIC ("RestEvent");
2236
2237                     }
2238                 ev->set_property ("duration", $2);
2239                 ev->set_spot (@$);
2240                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2241                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2242                 velt->set_spot (@$);
2243
2244                 ev->unprotect();
2245
2246                 $$ = velt;
2247         }
2248         | MULTI_MEASURE_REST optional_notemode_duration         {
2249                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2250                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2251                 $$ = unsmob_music (mus);
2252                 $$->protect ();
2253         }
2254
2255         | lyric_element optional_notemode_duration      {
2256                 if (!THIS->lexer_->is_lyric_state ())
2257                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2258
2259                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2260                 levent->set_property ("text", $1);
2261                 levent->set_property ("duration",$2);
2262                 levent->set_spot (@$);
2263                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2264                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2265
2266                 $$= velt;
2267         }
2268         | new_chord {
2269                 if (!THIS->lexer_->is_chord_state ())
2270                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2271                 $$ = unsmob_music ($1);
2272         }
2273         ;
2274
2275 lyric_element:
2276         lyric_markup {
2277                 $$ = $1;
2278         }
2279         | LYRICS_STRING {
2280                 $$ = $1;
2281         }
2282         ;
2283
2284 new_chord:
2285         steno_tonic_pitch optional_notemode_duration   {
2286                 $$ = make_chord ($1, $2, SCM_EOL);
2287         }
2288         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2289                 SCM its = scm_reverse_x ($4, SCM_EOL);
2290                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2291         }
2292         ;
2293
2294 chord_items:
2295         /**/ {
2296                 $$ = SCM_EOL;
2297         }
2298         | chord_items chord_item {
2299                 $$ = scm_cons ($2, $$);
2300         }
2301         ;
2302
2303 chord_separator:
2304         CHORD_COLON {
2305                 $$ = ly_symbol2scm ("chord-colon");
2306         }
2307         | CHORD_CARET {
2308                 $$ = ly_symbol2scm ("chord-caret");
2309         }
2310         | CHORD_SLASH steno_tonic_pitch {
2311                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2312         }
2313         | CHORD_BASS steno_tonic_pitch {
2314                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2315         }
2316         ;
2317
2318 chord_item:
2319         chord_separator {
2320                 $$ = $1;
2321         }
2322         | step_numbers {
2323                 $$ = scm_reverse_x ($1, SCM_EOL);
2324         }
2325         | CHORD_MODIFIER  {
2326                 $$ = $1;
2327         }
2328         ;
2329
2330 step_numbers:
2331         step_number { $$ = scm_cons ($1, SCM_EOL); }
2332         | step_numbers '.' step_number {
2333                 $$ = scm_cons ($3, $$);
2334         }
2335         ;
2336
2337 step_number:
2338         bare_unsigned {
2339                 $$ = make_chord_step ($1, 0);
2340         }
2341         | bare_unsigned '+' {
2342                 $$ = make_chord_step ($1, SHARP);
2343         }
2344         | bare_unsigned CHORD_MINUS {
2345                 $$ = make_chord_step ($1, FLAT);
2346         }
2347         ;
2348
2349 /*
2350         UTILITIES
2351
2352 TODO: should deprecate in favor of Scheme?
2353
2354  */
2355 number_expression:
2356         number_expression '+' number_term {
2357                 $$ = scm_sum ($1, $3);
2358         }
2359         | number_expression '-' number_term {
2360                 $$ = scm_difference ($1, $3);
2361         }
2362         | number_term
2363         ;
2364
2365 number_term:
2366         number_factor {
2367                 $$ = $1;
2368         }
2369         | number_factor '*' number_factor {
2370                 $$ = scm_product ($1, $3);
2371         }
2372         | number_factor '/' number_factor {
2373                 $$ = scm_divide ($1, $3);
2374         }
2375         ;
2376
2377 number_factor:
2378         '-'  number_factor { /* %prec UNARY_MINUS */
2379                 $$ = scm_difference ($2, SCM_UNDEFINED);
2380         }
2381         | bare_number
2382         ;
2383
2384
2385 bare_number:
2386         UNSIGNED        {
2387                 $$ = scm_from_int ($1);
2388         }
2389         | REAL          {
2390                 $$ = $1;
2391         }
2392         | NUMBER_IDENTIFIER             {
2393                 $$ = $1;
2394         }
2395         | REAL NUMBER_IDENTIFIER        {
2396                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2397         }
2398         | UNSIGNED NUMBER_IDENTIFIER    {
2399                 $$ = scm_from_double ($1 *scm_to_double ($2));
2400         }
2401         ;
2402
2403
2404 bare_unsigned:
2405         UNSIGNED {
2406                         $$ = $1;
2407         }
2408         | DIGIT {
2409                 $$ = $1;
2410         }
2411         ;
2412
2413 exclamations:
2414                 { $$ = 0; }
2415         | exclamations '!'      { $$ ++; }
2416         ;
2417
2418 questions:
2419                 { $$ = 0; }
2420         | questions '?' { $$ ++; }
2421         ;
2422
2423 /*
2424 This should be done more dynamically if possible.
2425 */
2426
2427 lyric_markup:
2428         LYRIC_MARKUP_IDENTIFIER {
2429                 $$ = $1;
2430         }
2431         | LYRIC_MARKUP
2432                 { THIS->lexer_->push_markup_state (); }
2433         markup_top {
2434                 $$ = $3;
2435                 THIS->lexer_->pop_state ();
2436         }
2437         ;
2438
2439 full_markup:
2440         MARKUP_IDENTIFIER {
2441                 $$ = $1;
2442         }
2443         | MARKUP
2444                 { THIS->lexer_->push_markup_state (); }
2445         markup_top {
2446                 $$ = $3;
2447                 THIS->lexer_->pop_state ();
2448         }
2449         ;
2450
2451 markup_top:
2452         markup_list {
2453                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2454         }
2455         | markup_head_1_list simple_markup      {
2456                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2457         }
2458         | simple_markup {
2459                 $$ = $1;
2460         }
2461         ;
2462
2463 markup_list:
2464         markup_composed_list {
2465                 $$ = $1;
2466         }
2467         | markup_braced_list {
2468                 $$ = $1;
2469         }
2470         ;
2471
2472 markup_composed_list:
2473         markup_head_1_list markup_braced_list {
2474                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2475
2476         }
2477         ;
2478
2479 markup_braced_list:
2480         '{' markup_braced_list_body '}' {
2481                 $$ = scm_reverse_x ($2, SCM_EOL);
2482         }
2483         ;
2484
2485 markup_braced_list_body:
2486         /* empty */     {  $$ = SCM_EOL; }
2487         | markup_braced_list_body markup {
2488                 $$ = scm_cons ($2, $1);
2489         }
2490         | markup_braced_list_body markup_list {
2491                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2492         }
2493         ;
2494
2495 markup_head_1_item:
2496         MARKUP_HEAD_MARKUP0     {
2497                 $$ = scm_list_1 ($1);
2498         }
2499         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2500                 $$ = scm_list_2 ($1, $2);
2501         }
2502         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2503                 $$ = scm_list_3 ($1, $2, $3);
2504         }
2505         ;
2506
2507 markup_head_1_list:
2508         markup_head_1_item      {
2509                 $$ = scm_list_1 ($1);
2510         }
2511         | markup_head_1_list markup_head_1_item {
2512                 $$ = scm_cons ($2, $1);
2513         }
2514         ;
2515
2516 simple_markup:
2517         STRING {
2518                 $$ = make_simple_markup ($1);
2519         }
2520         | MARKUP_IDENTIFIER {
2521                 $$ = $1;
2522         }
2523         | LYRIC_MARKUP_IDENTIFIER {
2524                 $$ = $1;
2525         }
2526         | STRING_IDENTIFIER {
2527                 $$ = $1;
2528         }
2529         | SCORE {
2530                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2531                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2532         } '{' score_body '}' {
2533                 Score * sc = $4;
2534                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2535                 sc->unprotect ();
2536                 THIS->lexer_->pop_state ();
2537         }
2538         | MARKUP_HEAD_SCM0 embedded_scm {
2539                 $$ = scm_list_2 ($1, $2);
2540         }
2541         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2542                 $$ = scm_list_4 ($1, $2, $3, $4);
2543         }
2544         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2545                 $$ = scm_list_3 ($1, $2, $3);
2546         }
2547         | MARKUP_HEAD_EMPTY {
2548                 $$ = scm_list_1 ($1);
2549         }
2550         | MARKUP_HEAD_LIST0 markup_list {
2551                 $$ = scm_list_2 ($1,$2);
2552         }
2553         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2554                 $$ = scm_list_3 ($1, $2, $3);
2555         }
2556         ;
2557
2558 markup:
2559         markup_head_1_list simple_markup        {
2560                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2561                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2562         }
2563         | simple_markup {
2564                 $$ = $1;
2565         }
2566         ;
2567
2568 %%
2569
2570 void
2571 Lily_parser::set_yydebug (bool )
2572 {
2573 #if 0
2574         yydebug = 1;
2575 #endif
2576 }
2577
2578 void
2579 Lily_parser::do_yyparse ()
2580 {
2581         yyparse ((void*)this);
2582 }
2583
2584
2585
2586
2587
2588 /*
2589
2590 It is a little strange to have this function in this file, but
2591 otherwise, we have to import music classes into the lexer.
2592
2593 */
2594 int
2595 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2596 {
2597         if (scm_is_string (sid)) {
2598                 *destination = sid;
2599                 return STRING_IDENTIFIER;
2600         } else if (unsmob_book (sid)) {
2601                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2602                 return BOOK_IDENTIFIER;
2603         } else if (scm_is_number (sid)) {
2604                 *destination = sid;
2605                 return NUMBER_IDENTIFIER;
2606         } else if (unsmob_context_def (sid)) {
2607                 *destination = unsmob_context_def (sid)->clone_scm ();
2608                 return CONTEXT_DEF_IDENTIFIER;
2609         } else if (unsmob_score (sid)) {
2610                 Score *score = new Score (*unsmob_score (sid));
2611                 *destination = score->self_scm ();
2612                 return SCORE_IDENTIFIER;
2613         } else if (Music *mus = unsmob_music (sid)) {
2614                 mus = mus->clone ();
2615                 *destination = mus->self_scm ();
2616                 unsmob_music (*destination)->
2617                         set_property ("origin", make_input (last_input_));
2618
2619                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2620                         != SCM_BOOL_F;
2621
2622                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2623         } else if (unsmob_duration (sid)) {
2624                 *destination = unsmob_duration (sid)->smobbed_copy ();
2625                 return DURATION_IDENTIFIER;
2626         } else if (unsmob_output_def (sid)) {
2627                 Output_def *p = unsmob_output_def (sid);
2628                 p = p->clone ();
2629
2630                 *destination = p->self_scm ();
2631                 return OUTPUT_DEF_IDENTIFIER;
2632         } else if (Text_interface::is_markup (sid)) {
2633                 *destination = sid;
2634                 if (is_lyric_state ())
2635                         return LYRIC_MARKUP_IDENTIFIER;
2636                 return MARKUP_IDENTIFIER;
2637         }
2638
2639         return -1;
2640 }
2641
2642 Music *
2643 property_op_to_music (SCM op)
2644 {
2645         Music *m = 0;
2646         SCM tag = scm_car (op);
2647         SCM symbol = scm_cadr (op);
2648         SCM args = scm_cddr (op);
2649         SCM grob_val = SCM_UNDEFINED;
2650         SCM grob_path = SCM_UNDEFINED;
2651         SCM val = SCM_UNDEFINED;
2652
2653         if (tag == ly_symbol2scm ("assign"))
2654                 {
2655                 m = MY_MAKE_MUSIC ("PropertySet");
2656                 val = scm_car (args);
2657                 }
2658         else if (tag == ly_symbol2scm ("unset"))
2659                 m = MY_MAKE_MUSIC ("PropertyUnset");
2660         else if (tag == ly_symbol2scm ("push"))
2661                 {
2662                 m = MY_MAKE_MUSIC ("OverrideProperty");
2663                 grob_val = scm_car (args);
2664                 grob_path = scm_cdr (args);
2665                 m->set_property ("pop-first", SCM_BOOL_T);
2666                 }
2667         else if (tag == ly_symbol2scm ("pop")) {
2668                 m = MY_MAKE_MUSIC ("RevertProperty");
2669                 grob_path = args;
2670                 }
2671
2672         m->set_property ("symbol", symbol);
2673
2674         if (val != SCM_UNDEFINED)
2675                 m->set_property ("value", val);
2676         if (grob_val != SCM_UNDEFINED)
2677                 m->set_property ("grob-value", grob_val);
2678         if (grob_path != SCM_UNDEFINED)
2679                 m->set_property ("grob-property-path", grob_path);
2680
2681         return m;
2682 }
2683
2684 Music*
2685 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2686 {
2687         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2688
2689         csm->set_property ("element", m->self_scm ());
2690         m->unprotect ();
2691
2692         csm->set_property ("context-type",
2693                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2694         csm->set_property ("property-operations", ops);
2695
2696         if (scm_is_string (id))
2697                 csm->set_property ("context-id", id);
2698         return csm;
2699 }
2700
2701 SCM
2702 get_next_unique_context_id ()
2703 {
2704         return scm_makfrom0str ("$uniqueContextId");
2705 }
2706
2707
2708 SCM
2709 get_next_unique_lyrics_context_id ()
2710 {
2711         static int new_context_count;
2712         char s[128];
2713         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2714         return scm_makfrom0str (s);
2715 }
2716
2717
2718 Music *
2719 run_music_function (Lily_parser *parser, SCM expr)
2720 {
2721         SCM func = scm_car (expr);
2722         Input *loc = unsmob_input (scm_cadr (expr));
2723         SCM args = scm_cddr (expr);
2724         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2725
2726         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2727         bool ok  = true;
2728
2729         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2730         {
2731                 parser->error_level_ = 1;
2732                 ok = false;
2733         }
2734
2735         SCM m = SCM_EOL;
2736         if (ok)
2737                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2738                                                  scm_cdr (expr)));
2739
2740
2741         Music* retval = 0;
2742         if (unsmob_music (m))
2743                 {
2744                 retval = unsmob_music (m);
2745                 retval->protect ();
2746                 }
2747         else
2748                 {
2749                 if (ok)
2750                         loc->error (_ ("music head function must return Music object"));
2751                 retval = MY_MAKE_MUSIC ("Music");
2752                 }
2753         retval->set_spot (*loc);
2754         return retval;
2755 }
2756
2757 bool
2758 is_regular_identifier (SCM id)
2759 {
2760   String str = ly_scm2string (id);
2761   char const *s = str.to_str0 ();
2762
2763   bool v = true;
2764 #if 0
2765   isalpha (*s);
2766   s++;
2767 #endif
2768   while (*s && v)
2769    {
2770         v = v && isalnum (*s);
2771         s++;
2772    }
2773   return v;
2774 }
2775
2776
2777 SCM
2778 get_first_context_id (SCM type, Music *m)
2779 {
2780         SCM id = m->get_property ("context-id");
2781         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2782             && scm_is_string (m->get_property ("context-id"))
2783             && scm_c_string_length (id) > 0)
2784         {
2785                 return id;
2786         }
2787         return SCM_EOL;
2788 }
2789
2790 SCM
2791 make_simple_markup (SCM a)
2792 {
2793         return a;
2794 }
2795
2796 bool
2797 is_duration (int t)
2798 {
2799   return t && t == 1 << intlog2 (t);
2800 }
2801
2802 void
2803 set_music_properties (Music *p, SCM a)
2804 {
2805   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2806         p->internal_set_property (scm_caar (k), scm_cdar (k));
2807 }
2808
2809
2810 SCM
2811 make_chord_step (int step, int alter)
2812 {
2813         if (step == 7)
2814                 alter += FLAT;
2815
2816         while (step < 0)
2817                 step += 7;
2818         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2819         return m.smobbed_copy ();
2820 }
2821
2822
2823 SCM
2824 make_chord (SCM pitch, SCM dur, SCM modification_list)
2825 {
2826         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2827         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2828
2829         unsmob_music (ch)->protect();
2830         return ch;
2831 }
2832
2833
2834 /* Todo: actually also use apply iso. call too ...  */
2835 bool
2836 ly_input_procedure_p (SCM x)
2837 {
2838         return ly_is_procedure (x)
2839                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2840 }
2841
2842 Music*
2843 set_property_music (SCM sym, SCM value)
2844 {
2845         Music *p = MY_MAKE_MUSIC ("PropertySet");
2846         p->set_property ("symbol", sym);
2847         p->set_property ("value", value);
2848         return p;
2849 }
2850
2851 Music*
2852 make_music_relative (Pitch start, Music *music)
2853 {
2854         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2855         relative->set_property ("element", music->self_scm ());
2856
2857         Pitch last = music->to_relative_octave (start);
2858         if (lily_1_8_relative)
2859                 music->set_property ("last-pitch", last.smobbed_copy ());
2860         return relative;
2861 }
2862
2863 Music *
2864 make_lyric_combine_music (SCM name, Music *music)
2865 {
2866         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2867         combine->set_property ("element", music->self_scm ());
2868         combine->set_property ("associated-context", name);
2869         return combine;
2870 }
2871
2872
2873 int
2874 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2875 {
2876         Lily_parser *pars = (Lily_parser*) v;
2877         Lily_lexer *lex = pars->lexer_;
2878
2879         lex->lexval = (void*) s;
2880         lex->lexloc = loc;
2881         lex->prepare_for_next_token ();
2882         return lex->yylex ();
2883 }