lily/parser.yy

   1 /*
   2   This file is part of LilyPond, the GNU music typesetter.
   3
   4   Copyright (C) 1997--2011 Han-Wen Nienhuys <hanwen@xs4all.nl>
   5                  Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7   LilyPond is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   LilyPond is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  19 */
  20
  21 %{
  22
  23 #define YYDEBUG 1
  24 #define YYERROR_VERBOSE 1
  25 #define YYPARSE_PARAM my_lily_parser
  26 #define YYLEX_PARAM my_lily_parser
  27 #define PARSER ((Lily_parser *) my_lily_parser)
  28
  29 #define yyerror PARSER->parser_error
  30
  31 /* We use custom location type: Input objects */
  32 #define YYLTYPE Input
  33 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  34         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  35
  36
  37 %}
  38
  39 /* We use SCMs to do strings, because it saves us the trouble of
  40 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  41 of the parse stack onto the heap. */
  42
  43 %left PREC_BOT
  44 %nonassoc REPEAT
  45 %nonassoc ALTERNATIVE
  46
  47 /* The above precedences tackle the shift/reduce problem
  48
  49 1.  \repeat
  50         \repeat .. \alternative
  51
  52     \repeat { \repeat .. \alternative }
  53
  54 or
  55
  56     \repeat { \repeat } \alternative
  57 */
  58
  59 %right FUNCTION_ARGUMENTS
  60       MARKUP LYRICS_STRING MARKUP_IDENTIFIER STRING STRING_IDENTIFIER
  61       MARKUPLINES WITH CONTEXT_MOD_IDENTIFIER MARKUPLINES_IDENTIFIER
  62       SCORE BOOK BOOKPART PAPER LAYOUT MIDI
  63       SEQUENTIAL SIMULTANEOUS DOUBLE_ANGLE_OPEN MUSIC_IDENTIFIER '{'
  64       PITCH_IDENTIFIER NOTENAME_PITCH TONICNAME_PITCH
  65       SCM_FUNCTION SCM_IDENTIFIER SCM_TOKEN
  66       UNSIGNED DURATION_IDENTIFIER
  67       CHORDMODE CHORDS DRUMMODE DRUMS FIGUREMODE FIGURES LYRICMODE LYRICS
  68       NOTEMODE
  69       CONTEXT TIMES NEWCONTEXT
  70
  71  /* The above are the symbols that can start function arguments */
  72
  73 %left ADDLYRICS
  74 %left PREC_TOP
  75
  76
  77
  78
  79 %pure_parser
  80 %locations
  81
  82
  83
  84 %{ // -*-Fundamental-*-
  85
  86 /*
  87 FIXME:
  88
  89    * The rules for who is protecting what are very shady.  Uniformise
  90      this.
  91
  92    * There are too many lexical modes?
  93 */
  94
  95 #include "config.hh"
  96
  97 #include <cctype>
  98 #include <cstdlib>
  99 #include <cstdio>
 100 using namespace std;
 101
 102 #include "book.hh"
 103 #include "context-def.hh"
 104 #include "context-mod.hh"
 105 #include "dimensions.hh"
 106 #include "file-path.hh"
 107 #include "input.hh"
 108 #include "international.hh"
 109 #include "lily-guile.hh"
 110 #include "lily-lexer.hh"
 111 #include "lily-parser.hh"
 112 #include "main.hh"
 113 #include "misc.hh"
 114 #include "music.hh"
 115 #include "output-def.hh"
 116 #include "paper-book.hh"
 117 #include "scm-hash.hh"
 118 #include "score.hh"
 119 #include "text-interface.hh"
 120 #include "warn.hh"
 121
 122 #define MYBACKUP(Token, Value, Location)                                \
 123         do                                                              \
 124                 if (yychar == YYEMPTY)                                  \
 125                         PARSER->lexer_->push_extra_token (Token, Value); \
 126                 else                                                    \
 127                         PARSER->parser_error                            \
 128                                 (Location, _("cannot backup token"));   \
 129         while (0)
 130
 131 %}
 132
 133
 134 %union {
 135         Book *book;
 136         Output_def *outputdef;
 137         SCM scm;
 138         std::string *string;
 139         Music *music;
 140         Score *score;
 141         int i;
 142 }
 143
 144 %{
 145
 146 #define MY_MAKE_MUSIC(x, spot)  make_music_with_input (ly_symbol2scm (x), spot)
 147
 148 /* ES TODO:
 149 - Don't use lily module, create a new module instead.
 150 - delay application of the function
 151 */
 152 #define LOWLEVEL_MAKE_SYNTAX(proc, args)        \
 153   scm_apply_0 (proc, args)
 154 /* Syntactic Sugar. */
 155 #define MAKE_SYNTAX(name, location, ...)        \
 156   LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant (name), scm_list_n (PARSER->self_scm (), make_input (location), ##__VA_ARGS__, SCM_UNDEFINED));
 157 #define START_MAKE_SYNTAX(name, ...)                                    \
 158         scm_list_n (ly_lily_module_constant (name), ##__VA_ARGS__, SCM_UNDEFINED)
 159 #define FINISH_MAKE_SYNTAX(start, location, ...)                        \
 160         LOWLEVEL_MAKE_SYNTAX (scm_car (start), scm_cons2 (PARSER->self_scm (), make_input (location), scm_append_x (scm_list_2 (scm_cdr (start), scm_list_n (__VA_ARGS__, SCM_UNDEFINED)))))
 161
 162 SCM get_next_unique_context_id ();
 163 SCM get_next_unique_lyrics_context_id ();
 164
 165 #undef _
 166 #if !HAVE_GETTEXT
 167 #define _(x) x
 168 #else
 169 #include <libintl.h>
 170 #define _(x) gettext (x)
 171 #endif
 172
 173
 174 static Music *make_music_with_input (SCM name, Input where);
 175 SCM check_scheme_arg (Lily_parser *parser, Input loc, SCM fallback,
 176                       SCM arg, SCM args, SCM pred);
 177 SCM loc_on_music (Input loc, SCM arg);
 178 SCM get_first_context_id (SCM type, Music *m);
 179 SCM make_chord_elements (SCM pitch, SCM dur, SCM modification_list);
 180 SCM make_chord_step (int step, Rational alter);
 181 SCM make_simple_markup (SCM a);
 182 SCM try_unpack_lyrics (SCM pred, SCM arg);
 183 bool is_duration (int t);
 184 bool is_regular_identifier (SCM id);
 185 bool ly_input_procedure_p (SCM x);
 186 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 187 void set_music_properties (Music *p, SCM a);
 188
 189 %}
 190
 191 /* The third option is an alias that will be used to display the
 192    syntax error.  Bison CVS now correctly handles backslash escapes.
 193
 194    FIXME: Bison needs to translate some of these, eg, STRING.
 195
 196 */
 197
 198 /* Keyword tokens with plain escaped name.  */
 199 %token ACCEPTS "\\accepts"
 200 %token ADDLYRICS "\\addlyrics"
 201 %token ALIAS "\\alias"
 202 %token ALTERNATIVE "\\alternative"
 203 %token BOOK "\\book"
 204 %token BOOKPART "\\bookpart"
 205 %token CHANGE "\\change"
 206 %token CHORDMODE "\\chordmode"
 207 %token CHORDS "\\chords"
 208 %token CONSISTS "\\consists"
 209 %token CONTEXT "\\context"
 210 %token DEFAULT "\\default"
 211 %token DEFAULTCHILD "\\defaultchild"
 212 %token DENIES "\\denies"
 213 %token DESCRIPTION "\\description"
 214 %token DRUMMODE "\\drummode"
 215 %token DRUMS "\\drums"
 216 %token FIGUREMODE "\\figuremode"
 217 %token FIGURES "\\figures"
 218 %token GROBDESCRIPTIONS "\\grobdescriptions"
 219 %token HEADER "\\header"
 220 %token INVALID "\\version-error"
 221 %token KEY "\\key"
 222 %token LAYOUT "\\layout"
 223 %token LYRICMODE "\\lyricmode"
 224 %token LYRICS "\\lyrics"
 225 %token LYRICSTO "\\lyricsto"
 226 %token MARK "\\mark"
 227 %token MARKUP "\\markup"
 228 %token MARKUPLINES "\\markuplines"
 229 %token MIDI "\\midi"
 230 %token NAME "\\name"
 231 %token NOTEMODE "\\notemode"
 232 %token ONCE "\\once"
 233 %token OVERRIDE "\\override"
 234 %token PAPER "\\paper"
 235 %token REMOVE "\\remove"
 236 %token REPEAT "\\repeat"
 237 %token REST "\\rest"
 238 %token REVERT "\\revert"
 239 %token SCORE "\\score"
 240 %token SEQUENTIAL "\\sequential"
 241 %token SET "\\set"
 242 %token SIMULTANEOUS "\\simultaneous"
 243 %token TEMPO "\\tempo"
 244 %token TIMES "\\times"
 245 %token TYPE "\\type"
 246 %token UNSET "\\unset"
 247 %token WITH "\\with"
 248
 249 /* Keyword token exceptions.  */
 250 %token TIME_T "\\time"
 251 %token NEWCONTEXT "\\new"
 252
 253
 254 /* Other string tokens.  */
 255
 256 %token CHORD_BASS "/+"
 257 %token CHORD_CARET "^"
 258 %token CHORD_COLON ":"
 259 %token CHORD_MINUS "-"
 260 %token CHORD_SLASH "/"
 261 %token ANGLE_OPEN "<"
 262 %token ANGLE_CLOSE ">"
 263 %token DOUBLE_ANGLE_OPEN "<<"
 264 %token DOUBLE_ANGLE_CLOSE ">>"
 265 %token E_BACKSLASH "\\"
 266 %token E_ANGLE_CLOSE "\\>"
 267 %token E_CHAR "\\C[haracter]"
 268 %token E_CLOSE "\\)"
 269 %token E_EXCLAMATION "\\!"
 270 %token E_BRACKET_OPEN "\\["
 271 %token E_OPEN "\\("
 272 %token E_BRACKET_CLOSE "\\]"
 273 %token E_ANGLE_OPEN "\\<"
 274 %token E_PLUS "\\+"
 275 %token E_TILDE "\\~"
 276 %token EXTENDER "__"
 277
 278 /*
 279 If we give names, Bison complains.
 280 */
 281 %token FIGURE_CLOSE /* "\\>" */
 282 %token FIGURE_OPEN /* "\\<" */
 283 %token FIGURE_SPACE "_"
 284 %token HYPHEN "--"
 285
 286 %token CHORDMODIFIERS
 287 %token LYRIC_MARKUP
 288 %token MULTI_MEASURE_REST
 289
 290
 291 %token <i> E_UNSIGNED
 292 %token <i> UNSIGNED
 293
 294 /* Artificial tokens, for more generic function syntax */
 295 %token <i> EXPECT_MARKUP "markup?"
 296 %token <i> EXPECT_PITCH "ly:pitch?"
 297 %token <i> EXPECT_DURATION "ly:duration?"
 298 %token <scm> EXPECT_SCM "scheme?"
 299 %token <scm> SKIPPED_SCM "(scheme?)"
 300 %token <i> EXPECT_MARKUP_LIST "markup-list?"
 301 %token <scm> EXPECT_OPTIONAL "optional?"
 302 /* After the last argument. */
 303 %token <i> EXPECT_NO_MORE_ARGS;
 304
 305 /* An artificial token for parsing embedded Lilypond */
 306 %token <i> EMBEDDED_LILY "#{"
 307
 308 %token <scm> BOOK_IDENTIFIER
 309 %token <scm> CHORDMODIFIER_PITCH
 310 %token <scm> CHORD_MODIFIER
 311 %token <scm> CHORD_REPETITION
 312 %token <scm> CONTEXT_DEF_IDENTIFIER
 313 %token <scm> CONTEXT_MOD_IDENTIFIER
 314 %token <scm> DRUM_PITCH
 315 %token <scm> PITCH_IDENTIFIER
 316 %token <scm> DURATION_IDENTIFIER
 317 %token <scm> EVENT_IDENTIFIER
 318 %token <scm> EVENT_FUNCTION
 319 %token <scm> FRACTION
 320 %token <scm> LYRICS_STRING
 321 %token <scm> LYRIC_MARKUP_IDENTIFIER
 322 %token <scm> MARKUP_FUNCTION
 323 %token <scm> MARKUP_LIST_FUNCTION
 324 %token <scm> MARKUP_IDENTIFIER
 325 %token <scm> MARKUPLINES_IDENTIFIER
 326 %token <scm> MUSIC_FUNCTION
 327 %token <scm> MUSIC_IDENTIFIER
 328 %token <scm> NOTENAME_PITCH
 329 %token <scm> NUMBER_IDENTIFIER
 330 %token <scm> OUTPUT_DEF_IDENTIFIER
 331 %token <scm> REAL
 332 %token <scm> RESTNAME
 333 %token <scm> SCM_FUNCTION
 334 %token <scm> SCM_IDENTIFIER
 335 %token <scm> SCM_TOKEN
 336 %token <scm> SCORE_IDENTIFIER
 337 %token <scm> STRING
 338 %token <scm> STRING_IDENTIFIER
 339 %token <scm> TONICNAME_PITCH
 340
 341
 342 %type <book> book_block
 343 %type <book> book_body
 344 %type <book> bookpart_block
 345 %type <book> bookpart_body
 346
 347 %type <i> bare_unsigned
 348 %type <scm> figured_bass_alteration
 349 %type <i> dots
 350 %type <i> exclamations
 351 %type <i> optional_rest
 352 %type <i> questions
 353 %type <i> script_dir
 354 %type <i> sub_quotes
 355 %type <i> sup_quotes
 356 %type <i> tremolo_type
 357
 358 /* Music */
 359 %type <scm> composite_music
 360 %type <scm> grouped_music_list
 361 %type <scm> braced_music_list
 362 %type <scm> closed_music
 363 %type <scm> music
 364 %type <scm> music_bare
 365 %type <scm> complex_music
 366 %type <scm> complex_music_prefix
 367 %type <scm> mode_changed_music
 368 %type <scm> repeated_music
 369 %type <scm> sequential_music
 370 %type <scm> simple_music
 371 %type <scm> simultaneous_music
 372 %type <scm> chord_body
 373 %type <scm> chord_body_element
 374 %type <scm> command_element
 375 %type <scm> command_event
 376 %type <scm> context_modification
 377 %type <scm> context_change
 378 %type <scm> direction_less_event
 379 %type <scm> direction_reqd_event
 380 %type <scm> embedded_lilypond
 381 %type <scm> event_chord
 382 %type <scm> fingering
 383 %type <scm> gen_text_def
 384 %type <scm> music_property_def
 385 %type <scm> note_chord_element
 386 %type <scm> post_event
 387 %type <scm> post_event_nofinger
 388 %type <scm> re_rhythmed_music
 389 %type <scm> simple_element
 390 %type <scm> simple_music_property_def
 391 %type <scm> start_symbol
 392 %type <scm> string_number_event
 393 %type <scm> tempo_event
 394
 395 %type <outputdef> output_def_body
 396 %type <outputdef> output_def_head
 397 %type <outputdef> output_def_head_with_mode_switch
 398 %type <outputdef> output_def
 399 %type <outputdef> paper_block
 400
 401 %type <scm> music_function_call
 402 %type <scm> music_list
 403 %type <scm> assignment_id
 404 %type <scm> bare_number
 405 %type <scm> unsigned_number
 406 %type <scm> bass_figure
 407 %type <scm> figured_bass_modification
 408 %type <scm> br_bass_figure
 409 %type <scm> bass_number
 410 %type <scm> chord_body_elements
 411 %type <scm> chord_item
 412 %type <scm> chord_items
 413 %type <scm> chord_separator
 414 %type <scm> context_def_mod
 415 %type <scm> context_def_spec_block
 416 %type <scm> context_def_spec_body
 417 %type <scm> context_mod
 418 %type <scm> context_mod_list
 419 %type <scm> context_prop_spec
 420 %type <scm> direction_less_char
 421 %type <scm> duration_length
 422 %type <scm> embedded_scm
 423 %type <scm> embedded_scm_arg
 424 %type <scm> embedded_scm_arg_closed
 425 %type <scm> embedded_scm_bare
 426 %type <scm> embedded_scm_bare_arg
 427 %type <scm> embedded_scm_closed
 428 %type <scm> embedded_scm_chord_body
 429 %type <scm> embedded_scm_event
 430 %type <scm> event_function_event
 431 %type <scm> figure_list
 432 %type <scm> figure_spec
 433 %type <scm> fraction
 434 %type <scm> full_markup
 435 %type <scm> full_markup_list
 436 %type <scm> function_arglist
 437 %type <scm> function_arglist_optional
 438 %type <scm> function_arglist_keep
 439 %type <scm> function_arglist_bare
 440 %type <scm> function_arglist_closed
 441 %type <scm> function_arglist_closed_optional
 442 %type <scm> function_arglist_closed_keep
 443 %type <scm> identifier_init
 444 %type <scm> lilypond
 445 %type <scm> lilypond_header
 446 %type <scm> lilypond_header_body
 447 %type <scm> lyric_element
 448 %type <scm> lyric_markup
 449 %type <scm> markup
 450 %type <scm> markup_braced_list
 451 %type <scm> markup_braced_list_body
 452 %type <scm> markup_composed_list
 453 %type <scm> markup_command_list
 454 %type <scm> markup_command_list_arguments
 455 %type <scm> markup_command_basic_arguments
 456 %type <scm> markup_head_1_item
 457 %type <scm> markup_head_1_list
 458 %type <scm> markup_list
 459 %type <scm> markup_top
 460 %type <scm> mode_changing_head
 461 %type <scm> mode_changing_head_with_context
 462 %type <scm> multiplied_duration
 463 %type <scm> music_function_event
 464 %type <scm> music_function_event_arglist
 465 %type <scm> music_function_chord_body
 466 %type <scm> music_function_chord_body_arglist
 467 %type <scm> new_chord
 468 %type <scm> new_lyrics
 469 %type <scm> number_expression
 470 %type <scm> number_factor
 471 %type <scm> number_term
 472 %type <scm> octave_check
 473 %type <scm> optional_context_mod
 474 %type <scm> optional_id
 475 %type <scm> optional_notemode_duration
 476 %type <scm> pitch
 477 %type <scm> pitch_also_in_chords
 478 %type <scm> post_events
 479 %type <scm> property_operation
 480 %type <scm> property_path property_path_revved
 481 %type <scm> scalar
 482 %type <scm> scalar_bare
 483 %type <scm> scalar_closed
 484 %type <scm> scm_function_call
 485 %type <scm> scm_function_call_closed
 486 %type <scm> script_abbreviation
 487 %type <scm> simple_chord_elements
 488 %type <scm> simple_markup
 489 %type <scm> simple_string
 490 %type <scm> steno_duration
 491 %type <scm> steno_pitch
 492 %type <scm> steno_tonic_pitch
 493 %type <scm> step_number
 494 %type <scm> step_numbers
 495 %type <scm> string
 496 %type <scm> tempo_range
 497
 498 %type <score> score_block
 499 %type <score> score_body
 500
 501
 502 %left '-' '+'
 503
 504 /* We don't assign precedence to / and *, because we might need varied
 505 prec levels in different prods */
 506
 507 %left UNARY_MINUS
 508
 509 %%
 510
 511 start_symbol:
 512         lilypond
 513         | EMBEDDED_LILY {
 514                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
 515                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
 516         } embedded_lilypond {
 517                 PARSER->lexer_->pop_state ();
 518                 PARSER->lexer_->set_identifier (ly_symbol2scm ("parseStringResult"), $3);
 519         }
 520         ;
 521
 522 lilypond:       /* empty */ { }
 523         | lilypond toplevel_expression {
 524         }
 525         | lilypond assignment {
 526         }
 527         | lilypond error {
 528                 PARSER->error_level_ = 1;
 529         }
 530         | lilypond INVALID      {
 531                 PARSER->error_level_ = 1;
 532         }
 533         ;
 534
 535
 536 toplevel_expression:
 537         lilypond_header {
 538                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 539         }
 540         | book_block {
 541                 Book *book = $1;
 542                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-book-handler");
 543                 scm_call_2 (proc, PARSER->self_scm (), book->self_scm ());
 544                 book->unprotect ();
 545         }
 546         | bookpart_block {
 547                 Book *bookpart = $1;
 548                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-bookpart-handler");
 549                 scm_call_2 (proc, PARSER->self_scm (), bookpart->self_scm ());
 550                 bookpart->unprotect ();
 551         }
 552         | score_block {
 553                 Score *score = $1;
 554
 555                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-score-handler");
 556                 scm_call_2 (proc, PARSER->self_scm (), score->self_scm ());
 557                 score->unprotect ();
 558         }
 559         | composite_music {
 560                 Music *music = unsmob_music ($1);
 561                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-music-handler");
 562                 scm_call_2 (proc, PARSER->self_scm (), music->self_scm ());
 563         }
 564         | full_markup {
 565                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 566                 scm_call_2 (proc, PARSER->self_scm (), scm_list_1 ($1));
 567         }
 568         | full_markup_list {
 569                 SCM proc = PARSER->lexer_->lookup_identifier ("toplevel-text-handler");
 570                 scm_call_2 (proc, PARSER->self_scm (), $1);
 571         }
 572         | output_def {
 573                 SCM id = SCM_EOL;
 574                 Output_def * od = $1;
 575
 576                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 577                         id = ly_symbol2scm ("$defaultpaper");
 578                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 579                         id = ly_symbol2scm ("$defaultmidi");
 580                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 581                         id = ly_symbol2scm ("$defaultlayout");
 582
 583                 PARSER->lexer_->set_identifier (id, od->self_scm ());
 584                 od->unprotect();
 585         }
 586         ;
 587
 588 embedded_scm_bare:
 589         SCM_TOKEN
 590         | SCM_IDENTIFIER
 591         ;
 592
 593 embedded_scm_bare_arg:
 594         embedded_scm_bare
 595         | STRING
 596         | STRING_IDENTIFIER
 597         | full_markup
 598         | full_markup_list
 599         | context_modification
 600         | score_block
 601         {
 602                 $$ = $1->self_scm ();
 603                 $1->unprotect ();
 604         }
 605         | context_def_spec_block
 606         | book_block
 607         {
 608                 $$ = $1->self_scm ();
 609                 $1->unprotect ();
 610         }
 611         | bookpart_block
 612         {
 613                 $$ = $1->self_scm ();
 614                 $1->unprotect ();
 615         }
 616         | output_def
 617         {
 618                 $$ = $1->self_scm ();
 619                 $1->unprotect ();
 620         }
 621         ;
 622
 623 /* The generic version may end in music, or not */
 624
 625 embedded_scm:
 626         embedded_scm_bare
 627         | scm_function_call
 628         ;
 629
 630 embedded_scm_arg:
 631         embedded_scm_bare_arg
 632         | scm_function_call
 633         | music
 634         ;
 635
 636 scm_function_call:
 637         SCM_FUNCTION function_arglist {
 638                 $$ = MAKE_SYNTAX ("music-function", @$,
 639                                          $1, $2);
 640         }
 641         ;
 642
 643 embedded_lilypond:
 644         /* empty */
 645         {
 646                 $$ = MAKE_SYNTAX ("void-music", @$);
 647         }
 648         | identifier_init
 649         | music music music_list {
 650                 $$ = MAKE_SYNTAX ("sequential-music", @$,
 651                                   scm_cons2 ($1, $2, scm_reverse_x ($3, SCM_EOL)));
 652         }
 653         | error {
 654                 PARSER->error_level_ = 1;
 655         }
 656         | INVALID embedded_lilypond {
 657                 PARSER->error_level_ = 1;
 658         }
 659         ;
 660
 661
 662 lilypond_header_body:
 663         {
 664                 $$ = get_header (PARSER);
 665                 PARSER->lexer_->add_scope ($$);
 666         }
 667         | lilypond_header_body assignment  {
 668
 669         }
 670         ;
 671
 672 lilypond_header:
 673         HEADER '{' lilypond_header_body '}'     {
 674                 $$ = PARSER->lexer_->remove_scope ();
 675         }
 676         ;
 677
 678 /*
 679         DECLARATIONS
 680 */
 681 assignment_id:
 682         STRING          { $$ = $1; }
 683         | LYRICS_STRING { $$ = $1; }
 684         ;
 685
 686 assignment:
 687         assignment_id '=' identifier_init  {
 688                 PARSER->lexer_->set_identifier ($1, $3);
 689         }
 690         | assignment_id property_path '=' identifier_init {
 691                 SCM path = scm_cons (scm_string_to_symbol ($1), $2);
 692                 PARSER->lexer_->set_identifier (path, $4);
 693         ;
 694 /*
 695  TODO: devise standard for protection in parser.
 696
 697   The parser stack lives on the C-stack, which means that
 698 all objects can be unprotected as soon as they're here.
 699
 700 */
 701         }
 702         | embedded_scm { }
 703         ;
 704
 705
 706 identifier_init:
 707         score_block {
 708                 $$ = $1->self_scm ();
 709                 $1->unprotect ();
 710         }
 711         | book_block {
 712                 $$ = $1->self_scm ();
 713                 $1->unprotect ();
 714         }
 715         | bookpart_block {
 716                 $$ = $1->self_scm ();
 717                 $1->unprotect ();
 718         }
 719         | output_def {
 720                 $$ = $1->self_scm ();
 721                 $1->unprotect ();
 722         }
 723         | context_def_spec_block {
 724                 $$ = $1;
 725         }
 726         | music  {
 727                 /* Hack: Create event-chord around standalone events.
 728                    Prevents the identifier from being interpreted as a post-event. */
 729                 Music *mus = unsmob_music ($1);
 730                 bool is_event = mus &&
 731                         (scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
 732                                 != SCM_BOOL_F);
 733                 if (!is_event)
 734                         $$ = $1;
 735                 else
 736                         $$ = MAKE_SYNTAX ("event-chord", @$, scm_list_1 ($1));
 737         }
 738         | post_event_nofinger {
 739                 $$ = $1;
 740         }
 741         | number_expression {
 742                 $$ = $1;
 743         }
 744         | string {
 745                 $$ = $1;
 746         }
 747         | embedded_scm {
 748                 $$ = $1;
 749         }
 750         | full_markup {
 751                 $$ = $1;
 752         }
 753         | full_markup_list {
 754                 $$ = $1;
 755         }
 756         | context_modification {
 757                 $$ = $1;
 758         }
 759         ;
 760
 761 context_def_spec_block:
 762         CONTEXT '{' context_def_spec_body '}'
 763                 {
 764                 $$ = $3;
 765         }
 766         ;
 767
 768 context_def_spec_body:
 769         /**/ {
 770                 $$ = Context_def::make_scm ();
 771                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 772         }
 773         | CONTEXT_DEF_IDENTIFIER {
 774                 $$ = $1;
 775                 unsmob_context_def ($$)->origin ()->set_spot (@$);
 776         }
 777         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 778                 Context_def*td = unsmob_context_def ($$);
 779
 780                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 781                         SCM tag = scm_caar (p);
 782
 783                         /* TODO: should make new tag "grob-definition" ? */
 784                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 785                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 786                 }
 787         }
 788         | context_def_spec_body context_mod {
 789                 unsmob_context_def ($$)->add_context_mod ($2);
 790         }
 791         | context_def_spec_body context_modification {
 792                 Context_def *td = unsmob_context_def ($$);
 793                 SCM new_mods = unsmob_context_mod ($2)->get_mods ();
 794                 for (SCM m = new_mods; scm_is_pair (m); m = scm_cdr (m)) {
 795                     td->add_context_mod (scm_car (m));
 796                 }
 797         }
 798         ;
 799
 800
 801
 802 book_block:
 803         BOOK '{' book_body '}'  {
 804                 $$ = $3;
 805                 pop_paper (PARSER);
 806                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), SCM_BOOL_F);
 807         }
 808         ;
 809
 810 /* FIXME:
 811    * Use 'handlers' like for toplevel-* stuff?
 812    * grok \layout and \midi?  */
 813 book_body:
 814         {
 815                 $$ = new Book;
 816                 init_papers (PARSER);
 817                 $$->origin ()->set_spot (@$);
 818                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (PARSER->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 819                 $$->paper_->unprotect ();
 820                 push_paper (PARSER, $$->paper_);
 821                 $$->header_ = PARSER->lexer_->lookup_identifier ("$defaultheader");
 822                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $$->self_scm ());
 823                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-output-suffix"), SCM_BOOL_F);
 824                 PARSER->lexer_->set_identifier (ly_symbol2scm ("book-filename"), SCM_BOOL_F);
 825         }
 826         | BOOK_IDENTIFIER {
 827                 $$ = unsmob_book ($1);
 828                 $$->protect ();
 829                 $$->origin ()->set_spot (@$);
 830                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-book"), $1);
 831         }
 832         | book_body paper_block {
 833                 $$->paper_ = $2;
 834                 $2->unprotect ();
 835                 set_paper (PARSER, $2);
 836         }
 837         | book_body bookpart_block {
 838                 Book *bookpart = $2;
 839                 SCM proc = PARSER->lexer_->lookup_identifier ("book-bookpart-handler");
 840                 scm_call_2 (proc, $$->self_scm (), bookpart->self_scm ());
 841                 bookpart->unprotect ();
 842         }
 843         | book_body score_block {
 844                 Score *score = $2;
 845                 SCM proc = PARSER->lexer_->lookup_identifier ("book-score-handler");
 846                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 847                 score->unprotect ();
 848         }
 849         | book_body composite_music {
 850                 Music *music = unsmob_music ($2);
 851                 SCM proc = PARSER->lexer_->lookup_identifier ("book-music-handler");
 852                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 853         }
 854         | book_body full_markup {
 855                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 856                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 857         }
 858         | book_body full_markup_list {
 859                 SCM proc = PARSER->lexer_->lookup_identifier ("book-text-handler");
 860                 scm_call_2 (proc, $$->self_scm (), $2);
 861         }
 862         | book_body lilypond_header {
 863                 $$->header_ = $2;
 864         }
 865         | book_body embedded_scm { }
 866         | book_body error {
 867                 $$->paper_ = 0;
 868                 $$->scores_ = SCM_EOL;
 869                 $$->bookparts_ = SCM_EOL;
 870         }
 871         ;
 872
 873 bookpart_block:
 874         BOOKPART '{' bookpart_body '}' {
 875                 $$ = $3;
 876                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), SCM_BOOL_F);
 877         }
 878         ;
 879
 880 bookpart_body:
 881         {
 882                 $$ = new Book;
 883                 $$->origin ()->set_spot (@$);
 884                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $$->self_scm ());
 885         }
 886         | BOOK_IDENTIFIER {
 887                 $$ = unsmob_book ($1);
 888                 $$->protect ();
 889                 $$->origin ()->set_spot (@$);
 890                 PARSER->lexer_->set_identifier (ly_symbol2scm ("$current-bookpart"), $1);
 891         }
 892         | bookpart_body paper_block {
 893                 $$->paper_ = $2;
 894                 $2->unprotect ();
 895         }
 896         | bookpart_body score_block {
 897                 Score *score = $2;
 898                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-score-handler");
 899                 scm_call_2 (proc, $$->self_scm (), score->self_scm ());
 900                 score->unprotect ();
 901         }
 902         | bookpart_body composite_music {
 903                 Music *music = unsmob_music ($2);
 904                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-music-handler");
 905                 scm_call_3 (proc, PARSER->self_scm (), $$->self_scm (), music->self_scm ());
 906         }
 907         | bookpart_body full_markup {
 908                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 909                 scm_call_2 (proc, $$->self_scm (), scm_list_1 ($2));
 910         }
 911         | bookpart_body full_markup_list {
 912                 SCM proc = PARSER->lexer_->lookup_identifier ("bookpart-text-handler");
 913                 scm_call_2 (proc, $$->self_scm (), $2);
 914         }
 915         | bookpart_body lilypond_header {
 916                 $$->header_ = $2;
 917         }
 918         | bookpart_body embedded_scm { }
 919         | bookpart_body error {
 920                 $$->paper_ = 0;
 921                 $$->scores_ = SCM_EOL;
 922         }
 923         ;
 924
 925 score_block:
 926         SCORE '{' score_body '}'        {
 927                 $$ = $3;
 928         }
 929         ;
 930
 931 score_body:
 932         music {
 933                 SCM m = $1;
 934                 SCM scorify = ly_lily_module_constant ("scorify-music");
 935                 SCM score = scm_call_2 (scorify, m, PARSER->self_scm ());
 936
 937                 // pass ownernship to C++ again.
 938                 $$ = unsmob_score (score);
 939                 $$->protect ();
 940                 $$->origin ()->set_spot (@$);
 941         }
 942         | SCORE_IDENTIFIER {
 943                 $$ = unsmob_score ($1);
 944                 $$->protect ();
 945                 $$->origin ()->set_spot (@$);
 946         }
 947         | score_body lilypond_header    {
 948                 $$->set_header ($2);
 949         }
 950         | score_body output_def {
 951                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 952                 {
 953                         PARSER->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 954
 955                 }
 956                 else
 957                 {
 958                         $$->add_output_def ($2);
 959                 }
 960                 $2->unprotect ();
 961         }
 962         | score_body error {
 963                 $$->error_found_ = true;
 964         }
 965         ;
 966
 967
 968 /*
 969         OUTPUT DEF
 970 */
 971
 972 paper_block:
 973         output_def {
 974                 $$ = $1;
 975                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 976                 {
 977                         PARSER->parser_error (@1, _ ("need \\paper for paper block"));
 978                         $1->unprotect ();
 979                         $$ = get_paper (PARSER);
 980                 }
 981         }
 982         ;
 983
 984
 985 output_def:
 986         output_def_body '}' {
 987                 $$ = $1;
 988
 989                 PARSER->lexer_->remove_scope ();
 990                 PARSER->lexer_->pop_state ();
 991         }
 992         ;
 993
 994 output_def_head:
 995         PAPER {
 996                 $$ = get_paper (PARSER);
 997                 $$->input_origin_ = @$;
 998                 PARSER->lexer_->add_scope ($$->scope_);
 999         }
1000         | MIDI    {
1001                 Output_def *p = get_midi (PARSER);
1002                 $$ = p;
1003                 PARSER->lexer_->add_scope (p->scope_);
1004         }
1005         | LAYOUT        {
1006                 Output_def *p = get_layout (PARSER);
1007
1008                 PARSER->lexer_->add_scope (p->scope_);
1009                 $$ = p;
1010         }
1011         ;
1012
1013 output_def_head_with_mode_switch:
1014         output_def_head {
1015                 PARSER->lexer_->push_initial_state ();
1016                 $$ = $1;
1017         }
1018         ;
1019
1020 output_def_body:
1021         output_def_head_with_mode_switch '{' {
1022                 $$ = $1;
1023                 $$->input_origin_.set_spot (@$);
1024         }
1025         | output_def_head_with_mode_switch '{' OUTPUT_DEF_IDENTIFIER    {
1026                 $1->unprotect ();
1027
1028                 Output_def *o = unsmob_output_def ($3);
1029                 o->input_origin_.set_spot (@$);
1030                 $$ = o;
1031                 $$->protect ();
1032                 PARSER->lexer_->remove_scope ();
1033                 PARSER->lexer_->add_scope (o->scope_);
1034         }
1035         | output_def_body assignment  {
1036
1037         }
1038         | output_def_body context_def_spec_block        {
1039                 assign_context_def ($$, $2);
1040         }
1041         | output_def_body error {
1042
1043         }
1044         ;
1045
1046 tempo_event:
1047         TEMPO steno_duration '=' tempo_range    {
1048                 $$ = MAKE_SYNTAX ("tempo", @$, SCM_EOL, $2, $4);
1049         }
1050         | TEMPO scalar_closed steno_duration '=' tempo_range    {
1051                 $$ = MAKE_SYNTAX ("tempo", @$, $2, $3, $5);
1052         }
1053         | TEMPO scalar {
1054                 $$ = MAKE_SYNTAX ("tempo", @$, $2);
1055         }
1056         ;
1057
1058 /*
1059 The representation of a  list is reversed to have efficient append.  */
1060
1061 music_list:
1062         /* empty */ {
1063                 $$ = SCM_EOL;
1064         }
1065         | music_list music {
1066                 $$ = scm_cons ($2, $1);
1067         }
1068         | music_list embedded_scm {
1069
1070         }
1071         | music_list error {
1072                 Music *m = MY_MAKE_MUSIC("Music", @$);
1073                 // ugh. code dup
1074                 m->set_property ("error-found", SCM_BOOL_T);
1075                 $$ = scm_cons (m->self_scm (), $1);
1076                 m->unprotect (); /* UGH */
1077         }
1078         ;
1079
1080 braced_music_list:
1081         '{' music_list '}'
1082         {
1083                 $$ = scm_reverse_x ($2, SCM_EOL);
1084         }
1085         ;
1086
1087 music:
1088         simple_music
1089         | composite_music %prec FUNCTION_ARGUMENTS
1090         ;
1091
1092
1093 repeated_music:
1094         REPEAT simple_string unsigned_number music
1095         {
1096                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, SCM_EOL);
1097         }
1098         | REPEAT simple_string unsigned_number music ALTERNATIVE braced_music_list
1099         {
1100                 $$ = MAKE_SYNTAX ("repeat", @$, $2, $3, $4, $6);
1101         }
1102         ;
1103
1104 sequential_music:
1105         SEQUENTIAL braced_music_list {
1106                 $$ = MAKE_SYNTAX ("sequential-music", @$, $2);
1107         }
1108         | braced_music_list {
1109                 $$ = MAKE_SYNTAX ("sequential-music", @$, $1);
1110         }
1111         ;
1112
1113 simultaneous_music:
1114         SIMULTANEOUS braced_music_list {
1115                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, $2);
1116         }
1117         | DOUBLE_ANGLE_OPEN music_list DOUBLE_ANGLE_CLOSE       {
1118                 $$ = MAKE_SYNTAX ("simultaneous-music", @$, scm_reverse_x ($2, SCM_EOL));
1119         }
1120         ;
1121
1122 simple_music:
1123         event_chord
1124         | music_property_def
1125         | context_change
1126         ;
1127
1128 context_modification:
1129         WITH { PARSER->lexer_->push_initial_state (); } '{' context_mod_list '}'
1130         {
1131                 PARSER->lexer_->pop_state ();
1132                 $$ = $4;
1133         }
1134         | WITH CONTEXT_MOD_IDENTIFIER
1135         {
1136                 $$ = $2;
1137         }
1138         | CONTEXT_MOD_IDENTIFIER
1139         {
1140                 $$ = $1;
1141         }
1142         ;
1143
1144 optional_context_mod:
1145         /**/ {
1146             $$ = SCM_EOL;
1147         }
1148         | context_modification
1149         {
1150               $$ = $1;
1151         }
1152         ;
1153
1154 context_mod_list:
1155         /**/ {
1156             $$ = Context_mod ().smobbed_copy ();
1157         }
1158         | context_mod_list context_mod  {
1159                  unsmob_context_mod ($1)->add_context_mod ($2);
1160         }
1161         | context_mod_list CONTEXT_MOD_IDENTIFIER {
1162                  Context_mod *md = unsmob_context_mod ($2);
1163                  if (md)
1164                      unsmob_context_mod ($1)->add_context_mods (md->get_mods ());
1165         }
1166         ;
1167
1168 composite_music:
1169         complex_music
1170         | music_bare
1171         ;
1172
1173 /* Music that can be parsed without lookahead */
1174 closed_music:
1175         music_bare
1176         | complex_music_prefix closed_music
1177         {
1178                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1179         }
1180         ;
1181
1182 music_bare:
1183         mode_changed_music
1184         | MUSIC_IDENTIFIER
1185         | grouped_music_list
1186         ;
1187
1188 grouped_music_list:
1189         simultaneous_music              { $$ = $1; }
1190         | sequential_music              { $$ = $1; }
1191         ;
1192
1193 /* An argument list. If a function \foo expects scm scm pitch, then the lexer expands \foo into the token sequence:
1194  MUSIC_FUNCTION EXPECT_PITCH EXPECT_SCM EXPECT_SCM EXPECT_NO_MORE_ARGS
1195 and this rule returns the reversed list of arguments. */
1196
1197
1198 function_arglist:
1199         function_arglist_bare
1200         | EXPECT_SCM function_arglist_optional embedded_scm_arg
1201         {
1202                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1203                                        $3, $2, $1);
1204         }
1205         | EXPECT_SCM function_arglist_optional SKIPPED_SCM
1206         {
1207                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1208                                        $3, $2, $1);
1209         }
1210         ;
1211
1212 function_arglist_optional:
1213         function_arglist_keep %prec FUNCTION_ARGUMENTS
1214         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_optional
1215         {
1216                 $$ = scm_cons ($1, $3);
1217         }
1218         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_optional
1219         {
1220                 $$ = scm_cons ($1, $3);
1221         }
1222         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_optional
1223         {
1224                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1225         }
1226         ;
1227
1228 function_arglist_keep:
1229         EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords {
1230                 $$ = scm_cons ($4, $3);
1231         }
1232         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length {
1233                 $$ = scm_cons ($4, $3);
1234         }
1235         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1236         {
1237                 if (scm_is_true (scm_call_1 ($2, $4)))
1238                 {
1239                         $$ = scm_cons ($4, $3);
1240                 } else {
1241                         $$ = try_unpack_lyrics ($2, $4);
1242                         if (!SCM_UNBNDP ($$))
1243                                 $$ = scm_cons ($$, $3);
1244                         else {
1245                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1246                                 MYBACKUP (SKIPPED_SCM, $4, @4);
1247                         }
1248                 }
1249         }
1250         | function_arglist
1251         ;
1252
1253
1254 function_arglist_closed:
1255         function_arglist_bare
1256         | EXPECT_SCM function_arglist_optional embedded_scm_arg_closed
1257         {
1258                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1259                                        $3, $2, $1);
1260         }
1261         | EXPECT_SCM function_arglist_optional SKIPPED_SCM
1262         {
1263                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1264                                        $3, $2, $1);
1265         }
1266         ;
1267
1268 function_arglist_closed_optional:
1269         function_arglist_closed_keep %prec FUNCTION_ARGUMENTS
1270         | EXPECT_OPTIONAL EXPECT_PITCH function_arglist_closed_optional
1271         {
1272                 $$ = scm_cons ($1, $3);
1273         }
1274         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_optional
1275         {
1276                 $$ = scm_cons ($1, $3);
1277         }
1278         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_closed_optional
1279         {
1280                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1281         }
1282         ;
1283
1284 function_arglist_closed_keep:
1285         EXPECT_OPTIONAL EXPECT_PITCH function_arglist_keep pitch_also_in_chords {
1286                 $$ = scm_cons ($4, $3);
1287         }
1288         | EXPECT_OPTIONAL EXPECT_DURATION function_arglist_closed_keep duration_length {
1289                 $$ = scm_cons ($4, $3);
1290         }
1291         | EXPECT_OPTIONAL EXPECT_SCM function_arglist_keep embedded_scm_arg_closed
1292         {
1293                 if (scm_is_true (scm_call_1 ($2, $4)))
1294                 {
1295                         $$ = scm_cons ($4, $3);
1296                 } else {
1297                         $$ = try_unpack_lyrics ($2, $4);
1298                         if (!SCM_UNBNDP ($$))
1299                                 $$ = scm_cons ($$, $3);
1300                         else {
1301                                 $$ = scm_cons (loc_on_music (@3, $1), $3);
1302                                 MYBACKUP (SKIPPED_SCM, $4, @4);
1303                         }
1304                 }
1305         }
1306         | function_arglist_closed
1307         ;
1308
1309 embedded_scm_closed:
1310         embedded_scm_bare
1311         | scm_function_call_closed
1312         ;
1313
1314 embedded_scm_arg_closed:
1315         embedded_scm_bare_arg
1316         | scm_function_call_closed
1317         | closed_music
1318         ;
1319
1320 scm_function_call_closed:
1321         SCM_FUNCTION function_arglist_closed {
1322                 $$ = MAKE_SYNTAX ("music-function", @$,
1323                                          $1, $2);
1324         }
1325         ;
1326
1327 function_arglist_bare:
1328         EXPECT_NO_MORE_ARGS {
1329                 $$ = SCM_EOL;
1330         }
1331         | EXPECT_PITCH function_arglist_optional pitch_also_in_chords {
1332                 $$ = scm_cons ($3, $2);
1333         }
1334         | EXPECT_DURATION function_arglist_closed_optional duration_length {
1335                 $$ = scm_cons ($3, $2);
1336         }
1337         ;
1338
1339 music_function_call:
1340         MUSIC_FUNCTION function_arglist {
1341                 $$ = MAKE_SYNTAX ("music-function", @$,
1342                                          $1, $2);
1343         }
1344         ;
1345
1346
1347 optional_id:
1348         /**/ { $$ = SCM_EOL; }
1349         | '=' simple_string {
1350                 $$ = $2;
1351         }
1352         ;
1353
1354 complex_music:
1355         music_function_call
1356         | repeated_music                { $$ = $1; }
1357         | re_rhythmed_music     { $$ = $1; }
1358         | complex_music_prefix music
1359         {
1360                 $$ = FINISH_MAKE_SYNTAX ($1, @$, $2);
1361         }
1362         ;
1363
1364 complex_music_prefix:
1365         CONTEXT simple_string optional_id optional_context_mod {
1366                 Context_mod *ctxmod = unsmob_context_mod ($4);
1367                 SCM mods = SCM_EOL;
1368                 if (ctxmod)
1369                         mods = ctxmod->get_mods ();
1370                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_F);
1371         }
1372         | NEWCONTEXT simple_string optional_id optional_context_mod {
1373                 Context_mod *ctxmod = unsmob_context_mod ($4);
1374                 SCM mods = SCM_EOL;
1375                 if (ctxmod)
1376                         mods = ctxmod->get_mods ();
1377                 $$ = START_MAKE_SYNTAX ("context-specification", $2, $3, mods, SCM_BOOL_T);
1378         }
1379         | TIMES fraction {
1380                 $$ = START_MAKE_SYNTAX ("time-scaled-music", $2);
1381         }
1382         ;
1383
1384 mode_changed_music:
1385         mode_changing_head grouped_music_list {
1386                 if ($1 == ly_symbol2scm ("chords"))
1387                 {
1388                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $2);
1389                 }
1390                 else
1391                 {
1392                   $$ = $2;
1393                 }
1394                 PARSER->lexer_->pop_state ();
1395         }
1396         | mode_changing_head_with_context optional_context_mod grouped_music_list {
1397                 Context_mod *ctxmod = unsmob_context_mod ($2);
1398                 SCM mods = SCM_EOL;
1399                 if (ctxmod)
1400                         mods = ctxmod->get_mods ();
1401                 $$ = MAKE_SYNTAX ("context-specification", @$, $1, SCM_EOL, mods, SCM_BOOL_T, $3);
1402                 if ($1 == ly_symbol2scm ("ChordNames"))
1403                 {
1404                   $$ = MAKE_SYNTAX ("unrelativable-music", @$, $$);
1405                 }
1406                 PARSER->lexer_->pop_state ();
1407         }
1408         ;
1409
1410 mode_changing_head:
1411         NOTEMODE {
1412                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1413                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1414
1415                 $$ = ly_symbol2scm ("notes");
1416         }
1417         | DRUMMODE
1418                 {
1419                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1420                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1421
1422                 $$ = ly_symbol2scm ("drums");
1423         }
1424         | FIGUREMODE {
1425                 PARSER->lexer_->push_figuredbass_state ();
1426
1427                 $$ = ly_symbol2scm ("figures");
1428         }
1429         | CHORDMODE {
1430                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1431                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1432                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1433                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1434                 $$ = ly_symbol2scm ("chords");
1435
1436         }
1437         | LYRICMODE
1438                 { PARSER->lexer_->push_lyric_state ();
1439                 $$ = ly_symbol2scm ("lyrics");
1440         }
1441         ;
1442
1443 mode_changing_head_with_context:
1444         DRUMS {
1445                 SCM nn = PARSER->lexer_->lookup_identifier ("drumPitchNames");
1446                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
1447
1448                 $$ = ly_symbol2scm ("DrumStaff");
1449         }
1450         | FIGURES {
1451                 PARSER->lexer_->push_figuredbass_state ();
1452
1453                 $$ = ly_symbol2scm ("FiguredBass");
1454         }
1455         | CHORDS {
1456                 SCM nn = PARSER->lexer_->lookup_identifier ("chordmodifiers");
1457                 PARSER->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1458                 nn = PARSER->lexer_->lookup_identifier ("pitchnames");
1459                 PARSER->lexer_->push_chord_state (alist_to_hashq (nn));
1460                 $$ = ly_symbol2scm ("ChordNames");
1461         }
1462         | LYRICS
1463                 { PARSER->lexer_->push_lyric_state ();
1464                 $$ = ly_symbol2scm ("Lyrics");
1465         }
1466         ;
1467
1468 new_lyrics:
1469         ADDLYRICS { PARSER->lexer_->push_lyric_state (); }
1470         /*cont */
1471         composite_music {
1472         /* Can also use music at the expensive of two S/Rs similar to
1473            \repeat \alternative */
1474                 PARSER->lexer_->pop_state ();
1475
1476                 $$ = scm_cons ($3, SCM_EOL);
1477         }
1478         | new_lyrics ADDLYRICS {
1479                 PARSER->lexer_->push_lyric_state ();
1480         } composite_music {
1481                 PARSER->lexer_->pop_state ();
1482                 $$ = scm_cons ($4, $1);
1483         }
1484         ;
1485
1486 re_rhythmed_music:
1487         composite_music new_lyrics {
1488                 $$ = MAKE_SYNTAX ("add-lyrics", @$, $1, scm_reverse_x ($2, SCM_EOL));
1489         } %prec FUNCTION_ARGUMENTS
1490         | LYRICSTO simple_string {
1491                 PARSER->lexer_->push_lyric_state ();
1492         } music {
1493                 PARSER->lexer_->pop_state ();
1494                 $$ = MAKE_SYNTAX ("lyric-combine", @$, $2, $4);
1495         }
1496         ;
1497
1498 context_change:
1499         CHANGE STRING '=' STRING  {
1500                 $$ = MAKE_SYNTAX ("context-change", @$, scm_string_to_symbol ($2), $4);
1501         }
1502         ;
1503
1504
1505 property_path_revved:
1506         embedded_scm_closed {
1507                 $$ = scm_cons ($1, SCM_EOL);
1508         }
1509         | property_path_revved embedded_scm_closed {
1510                 $$ = scm_cons ($2, $1);
1511         }
1512         ;
1513
1514 property_path:
1515         property_path_revved  {
1516                 $$ = scm_reverse_x ($1, SCM_EOL);
1517         }
1518         ;
1519
1520 property_operation:
1521         STRING '=' scalar {
1522                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1523                         scm_string_to_symbol ($1), $3);
1524         }
1525         | UNSET simple_string {
1526                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1527                         scm_string_to_symbol ($2));
1528         }
1529         | OVERRIDE simple_string property_path '=' scalar {
1530                 $$ = scm_append (scm_list_2 (scm_list_3 (ly_symbol2scm ("push"),
1531                                                         scm_string_to_symbol ($2), $5),
1532                                              $3));
1533         }
1534         | REVERT simple_string embedded_scm {
1535                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1536                         scm_string_to_symbol ($2), $3);
1537         }
1538         ;
1539
1540 context_def_mod:
1541         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1542         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1543
1544         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1545         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1546         | DENIES { $$ = ly_symbol2scm ("denies"); }
1547
1548         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1549         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1550         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1551         | NAME { $$ = ly_symbol2scm ("context-name"); }
1552         ;
1553
1554 context_mod:
1555         property_operation { $$ = $1; }
1556         | context_def_mod STRING {
1557                 $$ = scm_list_2 ($1, $2);
1558         }
1559         | context_def_mod embedded_scm {
1560            if (ly_symbol2scm ("consists") != $1)
1561            {
1562              $$ = SCM_EOL;
1563              PARSER->parser_error (@1, _ ("only \\consists takes non-string argument."));
1564            }
1565            else
1566            {
1567              $$ = scm_list_2 ($1, $2);
1568            }
1569         }
1570         ;
1571
1572 context_prop_spec:
1573         simple_string {
1574                 if (!is_regular_identifier ($1))
1575                 {
1576                         @$.error (_("Grob name should be alphanumeric"));
1577                 }
1578
1579                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1580                         scm_string_to_symbol ($1));
1581         }
1582         | simple_string '.' simple_string {
1583                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1584                         scm_string_to_symbol ($3));
1585         }
1586         ;
1587
1588 simple_music_property_def:
1589         OVERRIDE context_prop_spec property_path '=' scalar {
1590                 $$ = scm_append (scm_list_2 (scm_list_n (scm_car ($2),
1591                                 ly_symbol2scm ("OverrideProperty"),
1592                                 scm_cadr ($2),
1593                                 $5, SCM_UNDEFINED),
1594                                 $3));
1595         }
1596         | REVERT context_prop_spec embedded_scm {
1597                 $$ = scm_list_4 (scm_car ($2),
1598                         ly_symbol2scm ("RevertProperty"),
1599                         scm_cadr ($2),
1600                         $3);
1601         }
1602         | SET context_prop_spec '=' scalar {
1603                 $$ = scm_list_4 (scm_car ($2),
1604                         ly_symbol2scm ("PropertySet"),
1605                         scm_cadr ($2),
1606                         $4);
1607         }
1608         | UNSET context_prop_spec {
1609                 $$ = scm_list_3 (scm_car ($2),
1610                         ly_symbol2scm ("PropertyUnset"),
1611                         scm_cadr ($2));
1612         }
1613         ;
1614
1615 music_property_def:
1616         simple_music_property_def {
1617                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_F, $1)));
1618         }
1619         | ONCE simple_music_property_def {
1620                 $$ = LOWLEVEL_MAKE_SYNTAX (ly_lily_module_constant ("property-operation"), scm_cons (PARSER->self_scm (), scm_cons2 (make_input (@$), SCM_BOOL_T, $2)));
1621         }
1622         ;
1623
1624 string:
1625         STRING {
1626                 $$ = $1;
1627         }
1628         | STRING_IDENTIFIER {
1629                 $$ = $1;
1630         }
1631         | string '+' string {
1632                 $$ = scm_string_append (scm_list_2 ($1, $3));
1633         }
1634         ;
1635
1636 simple_string: STRING {
1637                 $$ = $1;
1638         }
1639         | LYRICS_STRING {
1640                 $$ = $1;
1641         }
1642         | STRING_IDENTIFIER {
1643                 $$ = $1;
1644         }
1645         ;
1646
1647 scalar_bare:
1648         string {
1649                 $$ = $1;
1650         }
1651         | lyric_element {
1652                 $$ = $1;
1653         }
1654         | bare_number {
1655                 $$ = $1;
1656         }
1657         | embedded_scm_bare {
1658                 $$ = $1;
1659         }
1660         | full_markup {
1661                 $$ = $1;
1662         }
1663         ;
1664
1665 scalar:
1666         scalar_bare |
1667         scm_function_call
1668         ;
1669
1670 scalar_closed:
1671         scalar_bare |
1672         scm_function_call_closed
1673         ;
1674
1675
1676 event_chord:
1677         /* TODO: Create a special case that avoids the creation of
1678            EventChords around simple_elements that have no post_events?
1679          */
1680         simple_chord_elements post_events       {
1681                 SCM elts = ly_append2 ($1, scm_reverse_x ($2, SCM_EOL));
1682
1683                 Input i;
1684                 /* why is this giving wrong start location? -ns
1685                  * i = @$; */
1686                 i.set_location (@1, @2);
1687                 $$ = MAKE_SYNTAX ("event-chord", i, elts);
1688         }
1689         | CHORD_REPETITION optional_notemode_duration post_events {
1690                 Input i;
1691                 i.set_location (@1, @3);
1692                 $$ = MAKE_SYNTAX ("repetition-chord", i,
1693                                   PARSER->lexer_->chord_repetition_.last_chord_,
1694                                   PARSER->lexer_->chord_repetition_.repetition_function_,
1695                                   $2, scm_reverse_x ($3, SCM_EOL));
1696         }
1697         | MULTI_MEASURE_REST optional_notemode_duration post_events {
1698                 Input i;
1699                 i.set_location (@1, @3);
1700                 $$ = MAKE_SYNTAX ("multi-measure-rest", i, $2,
1701                                   scm_reverse_x ($3, SCM_EOL));
1702         }
1703         | command_element
1704         /* note chord elements are memorized into
1705            PARSER->lexer_->chord_repetition_ so that the chord repetition
1706            mechanism copy them when a chord repetition symbol is found
1707         */
1708         | note_chord_element    {
1709                 PARSER->lexer_->chord_repetition_.last_chord_ = $$;
1710         }
1711         ;
1712
1713
1714 note_chord_element:
1715         chord_body optional_notemode_duration post_events
1716         {
1717                 Music *m = unsmob_music ($1);
1718                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1719                 SCM es = m->get_property ("elements");
1720                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1721
1722                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1723                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1724                 es = ly_append2 (es, postevs);
1725
1726                 m-> set_property ("elements", es);
1727                 m->set_spot (@$);
1728                 $$ = m->self_scm ();
1729         }
1730         ;
1731
1732 chord_body:
1733         ANGLE_OPEN chord_body_elements ANGLE_CLOSE
1734         {
1735                 $$ = MAKE_SYNTAX ("event-chord", @$, scm_reverse_x ($2, SCM_EOL));
1736         }
1737         ;
1738
1739 chord_body_elements:
1740         /* empty */             { $$ = SCM_EOL; }
1741         | chord_body_elements chord_body_element {
1742                 $$ = scm_cons ($2, $1);
1743         }
1744         ;
1745
1746 chord_body_element:
1747         pitch exclamations questions octave_check post_events
1748         {
1749                 int q = $3;
1750                 int ex = $2;
1751                 SCM check = $4;
1752                 SCM post = $5;
1753
1754                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1755                 n->set_property ("pitch", $1);
1756                 if (q % 2)
1757                         n->set_property ("cautionary", SCM_BOOL_T);
1758                 if (ex % 2 || q % 2)
1759                         n->set_property ("force-accidental", SCM_BOOL_T);
1760
1761                 if (scm_is_pair (post)) {
1762                         SCM arts = scm_reverse_x (post, SCM_EOL);
1763                         n->set_property ("articulations", arts);
1764                 }
1765                 if (scm_is_number (check))
1766                 {
1767                         int q = scm_to_int (check);
1768                         n->set_property ("absolute-octave", scm_from_int (q-1));
1769                 }
1770
1771                 $$ = n->unprotect ();
1772         }
1773         | DRUM_PITCH post_events {
1774                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
1775                 n->set_property ("drum-type", $1);
1776
1777                 if (scm_is_pair ($2)) {
1778                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1779                         n->set_property ("articulations", arts);
1780                 }
1781                 $$ = n->unprotect ();
1782         }
1783         | music_function_chord_body
1784         ;
1785
1786 /* We can't accept a music argument, not even a closed one,
1787  * immediately before chord_body_elements, otherwise a function \fun
1788  * with a signature of two music arguments can't be sorted out
1789  * properly in a construct like
1790  * <\fun { c } \fun { c } c>
1791  * The second call could be interpreted either as a chord constituent
1792  * or a music expression.
1793  */
1794
1795 music_function_chord_body_arglist:
1796         function_arglist_bare
1797         | EXPECT_SCM music_function_chord_body_arglist embedded_scm_chord_body
1798         {
1799                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1800                                        $3, $2, $1);
1801         }
1802         ;
1803
1804 embedded_scm_chord_body:
1805         embedded_scm_bare_arg
1806         | SCM_FUNCTION music_function_chord_body_arglist {
1807                 $$ = MAKE_SYNTAX ("music-function", @$,
1808                                          $1, $2);
1809         }
1810         | chord_body_element
1811         | SKIPPED_SCM
1812         ;
1813
1814 music_function_chord_body:
1815         MUSIC_FUNCTION music_function_chord_body_arglist {
1816                 $$ = MAKE_SYNTAX ("music-function", @$,
1817                                          $1, $2);
1818         }
1819         ;
1820
1821 /* We could accept a closed music argument before the post events
1822  * indicated by a trailing argument list.  For symmetry with chord
1823  * bodies and in order to avoid too tricky and complex behavior, we
1824  * refrain from doing so.
1825  */
1826 music_function_event_arglist:
1827         function_arglist_bare
1828         | EXPECT_SCM music_function_event_arglist embedded_scm_event
1829         {
1830                 $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED,
1831                                        $3, $2, $1);
1832         }
1833         ;
1834
1835 embedded_scm_event:
1836         embedded_scm_bare_arg
1837         | SCM_FUNCTION music_function_event_arglist {
1838                 $$ = MAKE_SYNTAX ("music-function", @$,
1839                                          $1, $2);
1840         }
1841         | post_event
1842         | SKIPPED_SCM
1843         ;
1844
1845 music_function_event:
1846         MUSIC_FUNCTION music_function_event_arglist {
1847                 $$ = MAKE_SYNTAX ("music-function", @$,
1848                                          $1, $2);
1849         }
1850         ;
1851
1852 event_function_event:
1853         EVENT_FUNCTION music_function_event_arglist {
1854                 $$ = MAKE_SYNTAX ("music-function", @$,
1855                                          $1, $2);
1856         }
1857         ;
1858
1859 command_element:
1860         command_event {
1861                 $$ = $1;
1862         }
1863         | E_BRACKET_OPEN {
1864                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1865                 m->set_property ("span-direction", scm_from_int (START));
1866                 $$ = m->unprotect();
1867         }
1868         | E_BRACKET_CLOSE {
1869                 Music *m = MY_MAKE_MUSIC ("LigatureEvent", @$);
1870                 m->set_property ("span-direction", scm_from_int (STOP));
1871                 $$ = m->unprotect ();
1872         }
1873         | E_BACKSLASH {
1874                 $$ = MAKE_SYNTAX ("voice-separator", @$);
1875         }
1876         | '|'      {
1877                 SCM pipe = PARSER->lexer_->lookup_identifier ("pipeSymbol");
1878
1879                 Music *m = unsmob_music (pipe);
1880                 if (m)
1881                 {
1882                         m = m->clone ();
1883                         m->set_spot (@$);
1884                         $$ = m->unprotect ();
1885                 }
1886                 else
1887                         $$ = MAKE_SYNTAX ("bar-check", @$);
1888
1889         }
1890         | TIME_T fraction  {
1891                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1892
1893                 $$ = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1894         }
1895         | MARK scalar {
1896                 $$ = MAKE_SYNTAX ("make-mark-set", @$, $2);
1897         }
1898         ;
1899
1900 command_event:
1901         E_TILDE {
1902                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent", @$)->unprotect ();
1903         }
1904         | MARK DEFAULT  {
1905                 Music *m = MY_MAKE_MUSIC ("MarkEvent", @$);
1906                 $$ = m->unprotect ();
1907         }
1908         | tempo_event {
1909                 $$ = $1;
1910         }
1911         | KEY DEFAULT {
1912                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1913                 $$ = key->unprotect ();
1914         }
1915         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1916
1917                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent", @$);
1918                 if (scm_ilength ($3) > 0)
1919                 {
1920                         key->set_property ("pitch-alist", $3);
1921                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1922                         key->transpose (* unsmob_pitch ($2));
1923                 } else {
1924                         PARSER->parser_error (@3, _ ("second argument must be pitch list"));
1925                 }
1926
1927                 $$ = key->unprotect ();
1928         }
1929         ;
1930
1931
1932 post_events:
1933         /* empty */ {
1934                 $$ = SCM_EOL;
1935         }
1936         | post_events post_event {
1937                 unsmob_music ($2)->set_spot (@2);
1938                 $$ = scm_cons ($2, $$);
1939         }
1940         ;
1941
1942 post_event_nofinger:
1943         direction_less_event {
1944                 $$ = $1;
1945         }
1946         | script_dir music_function_event {
1947                 $$ = $2;
1948                 if ($1)
1949                 {
1950                         unsmob_music ($$)->set_property ("direction", scm_from_int ($1));
1951                 }
1952         }
1953         | HYPHEN {
1954                 if (!PARSER->lexer_->is_lyric_state ())
1955                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1956                 $$ = MY_MAKE_MUSIC ("HyphenEvent", @$)->unprotect ();
1957         }
1958         | EXTENDER {
1959                 if (!PARSER->lexer_->is_lyric_state ())
1960                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1961                 $$ = MY_MAKE_MUSIC ("ExtenderEvent", @$)->unprotect ();
1962         }
1963         | script_dir direction_reqd_event {
1964                 if ($1)
1965                 {
1966                         Music *m = unsmob_music ($2);
1967                         m->set_property ("direction", scm_from_int ($1));
1968                 }
1969                 $$ = $2;
1970         }
1971         | script_dir direction_less_event {
1972                 if ($1)
1973                 {
1974                         Music *m = unsmob_music ($2);
1975                         m->set_property ("direction", scm_from_int ($1));
1976                 }
1977                 $$ = $2;
1978         }
1979         | string_number_event
1980         ;
1981
1982 post_event:
1983         post_event_nofinger
1984         | script_dir fingering {
1985                 if ($1)
1986                 {
1987                         Music *m = unsmob_music ($2);
1988                         m->set_property ("direction", scm_from_int ($1));
1989                 }
1990                 $$ = $2;
1991         }
1992         ;
1993
1994 string_number_event:
1995         E_UNSIGNED {
1996                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent", @$);
1997                 s->set_property ("string-number", scm_from_int ($1));
1998                 $$ = s->unprotect ();
1999         }
2000         ;
2001
2002 direction_less_char:
2003         '['  {
2004                 $$ = ly_symbol2scm ("bracketOpenSymbol");
2005         }
2006         | ']'  {
2007                 $$ = ly_symbol2scm ("bracketCloseSymbol");
2008         }
2009         | '~'  {
2010                 $$ = ly_symbol2scm ("tildeSymbol");
2011         }
2012         | '('  {
2013                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
2014         }
2015         | ')'  {
2016                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
2017         }
2018         | E_EXCLAMATION  {
2019                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
2020         }
2021         | E_OPEN  {
2022                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
2023         }
2024         | E_CLOSE  {
2025                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
2026         }
2027         | E_ANGLE_CLOSE  {
2028                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
2029         }
2030         | E_ANGLE_OPEN  {
2031                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
2032         }
2033         ;
2034
2035 direction_less_event:
2036         direction_less_char {
2037                 SCM predefd = PARSER->lexer_->lookup_identifier_symbol ($1);
2038                 Music *m = 0;
2039                 if (unsmob_music (predefd))
2040                 {
2041                         m = unsmob_music (predefd)->clone ();
2042                         m->set_spot (@$);
2043                 }
2044                 else
2045                 {
2046                         m = MY_MAKE_MUSIC ("Music", @$);
2047                 }
2048                 $$ = m->unprotect ();
2049         }
2050         | EVENT_IDENTIFIER      {
2051                 $$ = $1;
2052         }
2053         | tremolo_type  {
2054                Music *a = MY_MAKE_MUSIC ("TremoloEvent", @$);
2055                a->set_property ("tremolo-type", scm_from_int ($1));
2056                $$ = a->unprotect ();
2057         }
2058         | event_function_event
2059         ;
2060
2061 direction_reqd_event:
2062         gen_text_def {
2063                 $$ = $1;
2064         }
2065         | script_abbreviation {
2066                 SCM s = PARSER->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
2067                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent", @$);
2068                 if (scm_is_string (s))
2069                         a->set_property ("articulation-type", s);
2070                 else PARSER->parser_error (@1, _ ("expecting string as script definition"));
2071                 $$ = a->unprotect ();
2072         }
2073         ;
2074
2075 octave_check:
2076         /**/ { $$ = SCM_EOL; }
2077         | '='  { $$ = scm_from_int (0); }
2078         | '=' sub_quotes { $$ = scm_from_int (-$2); }
2079         | '=' sup_quotes { $$ = scm_from_int ($2); }
2080         ;
2081
2082 sup_quotes:
2083         '\'' {
2084                 $$ = 1;
2085         }
2086         | sup_quotes '\'' {
2087                 $$ ++;
2088         }
2089         ;
2090
2091 sub_quotes:
2092         ',' {
2093                 $$ = 1;
2094         }
2095         | sub_quotes ',' {
2096                 $$++;
2097         }
2098         ;
2099
2100 steno_pitch:
2101         NOTENAME_PITCH  {
2102                 $$ = $1;
2103         }
2104         | NOTENAME_PITCH sup_quotes     {
2105                 Pitch p = *unsmob_pitch ($1);
2106                 p = p.transposed (Pitch ($2,0,0));
2107                 $$ = p.smobbed_copy ();
2108         }
2109         | NOTENAME_PITCH sub_quotes      {
2110                 Pitch p =* unsmob_pitch ($1);
2111                 p = p.transposed (Pitch (-$2,0,0));
2112                 $$ = p.smobbed_copy ();
2113         }
2114         ;
2115
2116 /*
2117 ugh. duplication
2118 */
2119
2120 steno_tonic_pitch:
2121         TONICNAME_PITCH {
2122                 $$ = $1;
2123         }
2124         | TONICNAME_PITCH sup_quotes    {
2125                 Pitch p = *unsmob_pitch ($1);
2126                 p = p.transposed (Pitch ($2,0,0));
2127                 $$ = p.smobbed_copy ();
2128         }
2129         | TONICNAME_PITCH sub_quotes     {
2130                 Pitch p = *unsmob_pitch ($1);
2131
2132                 p = p.transposed (Pitch (-$2,0,0));
2133                 $$ = p.smobbed_copy ();
2134         }
2135         ;
2136
2137 pitch:
2138         steno_pitch {
2139                 $$ = $1;
2140         }
2141         | PITCH_IDENTIFIER
2142         ;
2143
2144 pitch_also_in_chords:
2145         pitch
2146         | steno_tonic_pitch
2147         ;
2148
2149 gen_text_def:
2150         full_markup {
2151                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2152                 t->set_property ("text", $1);
2153                 $$ = t->unprotect ();
2154         }
2155         | string {
2156                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent", @$);
2157                 t->set_property ("text",
2158                         make_simple_markup ($1));
2159                 $$ = t->unprotect ();
2160         }
2161         ;
2162
2163 fingering:
2164         UNSIGNED {
2165                 Music *t = MY_MAKE_MUSIC ("FingeringEvent", @$);
2166                 t->set_property ("digit", scm_from_int ($1));
2167                 $$ = t->unprotect ();
2168         }
2169         ;
2170
2171 script_abbreviation:
2172         '^'             {
2173                 $$ = scm_from_locale_string ("Hat");
2174         }
2175         | '+'           {
2176                 $$ = scm_from_locale_string ("Plus");
2177         }
2178         | '-'           {
2179                 $$ = scm_from_locale_string ("Dash");
2180         }
2181         | '|'           {
2182                 $$ = scm_from_locale_string ("Bar");
2183         }
2184         | ANGLE_CLOSE   {
2185                 $$ = scm_from_locale_string ("Larger");
2186         }
2187         | '.'           {
2188                 $$ = scm_from_locale_string ("Dot");
2189         }
2190         | '_' {
2191                 $$ = scm_from_locale_string ("Underscore");
2192         }
2193         ;
2194
2195 script_dir:
2196         '_'     { $$ = DOWN; }
2197         | '^'   { $$ = UP; }
2198         | '-'   { $$ = CENTER; }
2199         ;
2200
2201 duration_length:
2202         multiplied_duration {
2203                 $$ = $1;
2204         }
2205         ;
2206
2207 optional_notemode_duration:
2208         {
2209                 Duration dd = PARSER->default_duration_;
2210                 $$ = dd.smobbed_copy ();
2211         }
2212         | multiplied_duration   {
2213                 $$ = $1;
2214                 PARSER->default_duration_ = *unsmob_duration ($$);
2215         }
2216         ;
2217
2218 steno_duration:
2219         bare_unsigned dots              {
2220                 int len = 0;
2221                 if (!is_duration ($1))
2222                         PARSER->parser_error (@1, _f ("not a duration: %d", $1));
2223                 else
2224                         len = intlog2 ($1);
2225
2226                 $$ = Duration (len, $2).smobbed_copy ();
2227         }
2228         | DURATION_IDENTIFIER dots      {
2229                 Duration *d = unsmob_duration ($1);
2230                 Duration k (d->duration_log (), d->dot_count () + $2);
2231                 k = k.compressed (d->factor ());
2232                 *d = k;
2233                 $$ = $1;
2234         }
2235         ;
2236
2237 multiplied_duration:
2238         steno_duration {
2239                 $$ = $1;
2240         }
2241         | multiplied_duration '*' bare_unsigned {
2242                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2243         }
2244         | multiplied_duration '*' FRACTION {
2245                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2246
2247                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2248         }
2249         ;
2250
2251 fraction:
2252         FRACTION { $$ = $1; }
2253         | UNSIGNED '/' UNSIGNED {
2254                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2255         }
2256         ;
2257
2258 dots:
2259         /* empty */     {
2260                 $$ = 0;
2261         }
2262         | dots '.' {
2263                 $$ ++;
2264         }
2265         ;
2266
2267 tremolo_type:
2268         ':'     {
2269                 $$ = 0;
2270         }
2271         | ':' bare_unsigned {
2272                 if (!is_duration ($2))
2273                         PARSER->parser_error (@2, _f ("not a duration: %d", $2));
2274                 $$ = $2;
2275         }
2276         ;
2277
2278 bass_number:
2279         UNSIGNED {
2280                 $$ = scm_from_int ($1);
2281         }
2282         | STRING { $$ = $1; }
2283         | full_markup { $$ = $1; }
2284         ;
2285
2286 figured_bass_alteration:
2287         '-'     { $$ = ly_rational2scm (FLAT_ALTERATION); }
2288         | '+'   { $$ = ly_rational2scm (SHARP_ALTERATION); }
2289         | '!'   { $$ = scm_from_int (0); }
2290         ;
2291
2292 bass_figure:
2293         FIGURE_SPACE {
2294                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2295                 $$ = bfr->unprotect ();
2296         }
2297         | bass_number  {
2298                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent", @$);
2299                 $$ = bfr->self_scm ();
2300
2301                 if (scm_is_number ($1))
2302                         bfr->set_property ("figure", $1);
2303                 else if (Text_interface::is_markup ($1))
2304                         bfr->set_property ("text", $1);
2305
2306                 bfr->unprotect ();
2307         }
2308         | bass_figure ']' {
2309                 $$ = $1;
2310                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2311         }
2312         | bass_figure figured_bass_alteration {
2313                 Music *m = unsmob_music ($1);
2314                 if (scm_to_double ($2)) {
2315                         SCM salter = m->get_property ("alteration");
2316                         SCM alter = scm_is_number (salter) ? salter : scm_from_int (0);
2317                         m->set_property ("alteration",
2318                                          scm_sum (alter, $2));
2319                 } else {
2320                         m->set_property ("alteration", scm_from_int (0));
2321                 }
2322         }
2323         | bass_figure figured_bass_modification  {
2324                 Music *m = unsmob_music ($1);
2325                 if ($2 == ly_symbol2scm ("plus"))
2326                         {
2327                         m->set_property ("augmented", SCM_BOOL_T);
2328                         }
2329                 else if ($2 == ly_symbol2scm ("slash"))
2330                         {
2331                         m->set_property ("diminished", SCM_BOOL_T);
2332                         }
2333                 else if ($2 == ly_symbol2scm ("exclamation"))
2334                         {
2335                         m->set_property ("no-continuation", SCM_BOOL_T);
2336                         }
2337                 else if ($2 == ly_symbol2scm ("backslash"))
2338                         {
2339                         m->set_property ("augmented-slash", SCM_BOOL_T);
2340                         }
2341         }
2342         ;
2343
2344
2345 figured_bass_modification:
2346         E_PLUS          {
2347                 $$ = ly_symbol2scm ("plus");
2348         }
2349         | E_EXCLAMATION {
2350                 $$ = ly_symbol2scm ("exclamation");
2351         }
2352         | '/'           {
2353                 $$ = ly_symbol2scm ("slash");
2354         }
2355         | E_BACKSLASH {
2356                 $$ = ly_symbol2scm ("backslash");
2357         }
2358         ;
2359
2360 br_bass_figure:
2361         bass_figure {
2362                 $$ = $1;
2363         }
2364         | '[' bass_figure {
2365                 $$ = $2;
2366                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2367         }
2368         ;
2369
2370 figure_list:
2371         /**/            {
2372                 $$ = SCM_EOL;
2373         }
2374         | figure_list br_bass_figure {
2375                 $$ = scm_cons ($2, $1);
2376         }
2377         ;
2378
2379 figure_spec:
2380         FIGURE_OPEN figure_list FIGURE_CLOSE {
2381                 $$ = scm_reverse_x ($2, SCM_EOL);
2382         }
2383         ;
2384
2385
2386 optional_rest:
2387         /**/   { $$ = 0; }
2388         | REST { $$ = 1; }
2389         ;
2390
2391 simple_element:
2392         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2393                 if (!PARSER->lexer_->is_note_state ())
2394                         PARSER->parser_error (@1, _ ("have to be in Note mode for notes"));
2395
2396                 Music *n = 0;
2397                 if ($6)
2398                         n = MY_MAKE_MUSIC ("RestEvent", @$);
2399                 else
2400                         n = MY_MAKE_MUSIC ("NoteEvent", @$);
2401
2402                 n->set_property ("pitch", $1);
2403                 n->set_property ("duration", $5);
2404
2405                 if (scm_is_number ($4))
2406                 {
2407                         int q = scm_to_int ($4);
2408                         n->set_property ("absolute-octave", scm_from_int (q-1));
2409                 }
2410
2411                 if ($3 % 2)
2412                         n->set_property ("cautionary", SCM_BOOL_T);
2413                 if ($2 % 2 || $3 % 2)
2414                         n->set_property ("force-accidental", SCM_BOOL_T);
2415
2416                 $$ = n->unprotect ();
2417         }
2418         | DRUM_PITCH optional_notemode_duration {
2419                 Music *n = MY_MAKE_MUSIC ("NoteEvent", @$);
2420                 n->set_property ("duration", $2);
2421                 n->set_property ("drum-type", $1);
2422
2423                 $$ = n->unprotect ();
2424         }
2425         | RESTNAME optional_notemode_duration           {
2426                 Music *ev = 0;
2427                 if (ly_scm2string ($1) == "s") {
2428                         /* Space */
2429                         ev = MY_MAKE_MUSIC ("SkipEvent", @$);
2430                   }
2431                 else {
2432                         ev = MY_MAKE_MUSIC ("RestEvent", @$);
2433
2434                     }
2435                 ev->set_property ("duration", $2);
2436                 $$ = ev->unprotect ();
2437         }
2438         | lyric_element optional_notemode_duration      {
2439                 if (!PARSER->lexer_->is_lyric_state ())
2440                         PARSER->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2441
2442                 Music *levent = MY_MAKE_MUSIC ("LyricEvent", @$);
2443                 levent->set_property ("text", $1);
2444                 levent->set_property ("duration",$2);
2445                 $$= levent->unprotect ();
2446         }
2447         ;
2448
2449 simple_chord_elements:
2450         simple_element  {
2451                 $$ = scm_list_1 ($1);
2452         }
2453         | new_chord {
2454                 if (!PARSER->lexer_->is_chord_state ())
2455                         PARSER->parser_error (@1, _ ("have to be in Chord mode for chords"));
2456                 $$ = $1;
2457         }
2458         | figure_spec optional_notemode_duration {
2459                 for (SCM s = $1; scm_is_pair (s); s = scm_cdr (s))
2460                 {
2461                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2462                 }
2463                 $$ = $1;
2464         }
2465         ;
2466
2467 lyric_element:
2468         lyric_markup {
2469                 $$ = $1;
2470         }
2471         | LYRICS_STRING {
2472                 $$ = $1;
2473         }
2474         ;
2475
2476 new_chord:
2477         steno_tonic_pitch optional_notemode_duration   {
2478                 $$ = make_chord_elements ($1, $2, SCM_EOL);
2479         }
2480         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2481                 SCM its = scm_reverse_x ($4, SCM_EOL);
2482                 $$ = make_chord_elements ($1, $2, scm_cons ($3, its));
2483         }
2484         ;
2485
2486 chord_items:
2487         /**/ {
2488                 $$ = SCM_EOL;
2489         }
2490         | chord_items chord_item {
2491                 $$ = scm_cons ($2, $$);
2492         }
2493         ;
2494
2495 chord_separator:
2496         CHORD_COLON {
2497                 $$ = ly_symbol2scm ("chord-colon");
2498         }
2499         | CHORD_CARET {
2500                 $$ = ly_symbol2scm ("chord-caret");
2501         }
2502         | CHORD_SLASH steno_tonic_pitch {
2503                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2504         }
2505         | CHORD_BASS steno_tonic_pitch {
2506                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2507         }
2508         ;
2509
2510 chord_item:
2511         chord_separator {
2512                 $$ = $1;
2513         }
2514         | step_numbers {
2515                 $$ = scm_reverse_x ($1, SCM_EOL);
2516         }
2517         | CHORD_MODIFIER  {
2518                 $$ = $1;
2519         }
2520         ;
2521
2522 step_numbers:
2523         step_number { $$ = scm_cons ($1, SCM_EOL); }
2524         | step_numbers '.' step_number {
2525                 $$ = scm_cons ($3, $$);
2526         }
2527         ;
2528
2529 step_number:
2530         bare_unsigned {
2531                 $$ = make_chord_step ($1, 0);
2532         }
2533         | bare_unsigned '+' {
2534                 $$ = make_chord_step ($1, SHARP_ALTERATION);
2535         }
2536         | bare_unsigned CHORD_MINUS {
2537                 $$ = make_chord_step ($1, FLAT_ALTERATION);
2538         }
2539         ;
2540
2541 tempo_range:
2542         bare_unsigned {
2543                 $$ = scm_from_int ($1);
2544         }
2545         | bare_unsigned '~' bare_unsigned {
2546                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2547         }
2548         ;
2549
2550 /*
2551         UTILITIES
2552
2553 TODO: should deprecate in favor of Scheme?
2554
2555  */
2556 number_expression:
2557         number_expression '+' number_term {
2558                 $$ = scm_sum ($1, $3);
2559         }
2560         | number_expression '-' number_term {
2561                 $$ = scm_difference ($1, $3);
2562         }
2563         | number_term
2564         ;
2565
2566 number_term:
2567         number_factor {
2568                 $$ = $1;
2569         }
2570         | number_factor '*' number_factor {
2571                 $$ = scm_product ($1, $3);
2572         }
2573         | number_factor '/' number_factor {
2574                 $$ = scm_divide ($1, $3);
2575         }
2576         ;
2577
2578 number_factor:
2579         '-'  number_factor { /* %prec UNARY_MINUS */
2580                 $$ = scm_difference ($2, SCM_UNDEFINED);
2581         }
2582         | bare_number
2583         ;
2584
2585
2586 bare_number:
2587         UNSIGNED        {
2588                 $$ = scm_from_int ($1);
2589         }
2590         | REAL          {
2591                 $$ = $1;
2592         }
2593         | NUMBER_IDENTIFIER             {
2594                 $$ = $1;
2595         }
2596         | REAL NUMBER_IDENTIFIER        {
2597                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2598         }
2599         | UNSIGNED NUMBER_IDENTIFIER    {
2600                 $$ = scm_from_double ($1 *scm_to_double ($2));
2601         }
2602         ;
2603
2604
2605 bare_unsigned:
2606         UNSIGNED {
2607                         $$ = $1;
2608         }
2609         ;
2610
2611 unsigned_number:
2612         bare_unsigned  { $$ = scm_from_int ($1); }
2613         | NUMBER_IDENTIFIER {
2614                 $$ = $1;
2615         }
2616         ;
2617
2618 exclamations:
2619                 { $$ = 0; }
2620         | exclamations '!'      { $$ ++; }
2621         ;
2622
2623 questions:
2624                 { $$ = 0; }
2625         | questions '?' { $$ ++; }
2626         ;
2627
2628 /*
2629 This should be done more dynamically if possible.
2630 */
2631
2632 lyric_markup:
2633         LYRIC_MARKUP_IDENTIFIER {
2634                 $$ = $1;
2635         }
2636         | LYRIC_MARKUP
2637                 { PARSER->lexer_->push_markup_state (); }
2638         markup_top {
2639                 $$ = $3;
2640                 PARSER->lexer_->pop_state ();
2641         }
2642         ;
2643
2644 full_markup_list:
2645         MARKUPLINES_IDENTIFIER {
2646                 $$ = $1;
2647         }
2648         | MARKUPLINES
2649                 { PARSER->lexer_->push_markup_state (); }
2650         markup_list {
2651                 $$ = $3;
2652                 PARSER->lexer_->pop_state ();
2653         }
2654         ;
2655
2656 full_markup:
2657         MARKUP_IDENTIFIER {
2658                 $$ = $1;
2659         }
2660         | MARKUP
2661                 { PARSER->lexer_->push_markup_state (); }
2662         markup_top {
2663                 $$ = $3;
2664                 PARSER->lexer_->pop_state ();
2665         }
2666         ;
2667
2668 markup_top:
2669         markup_list {
2670                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2671         }
2672         | markup_head_1_list simple_markup      {
2673                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2674         }
2675         | simple_markup {
2676                 $$ = $1;
2677         }
2678         ;
2679
2680 markup_list:
2681         MARKUPLINES_IDENTIFIER {
2682                 $$ = $1;
2683         }
2684         | markup_composed_list {
2685                 $$ = $1;
2686         }
2687         | markup_braced_list {
2688                 $$ = $1;
2689         }
2690         | markup_command_list {
2691                 $$ = scm_list_1 ($1);
2692         }
2693         ;
2694
2695 markup_composed_list:
2696         markup_head_1_list markup_braced_list {
2697                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2698
2699         }
2700         ;
2701
2702 markup_braced_list:
2703         '{' markup_braced_list_body '}' {
2704                 $$ = scm_reverse_x ($2, SCM_EOL);
2705         }
2706         ;
2707
2708 markup_braced_list_body:
2709         /* empty */     {  $$ = SCM_EOL; }
2710         | markup_braced_list_body markup {
2711                 $$ = scm_cons ($2, $1);
2712         }
2713         | markup_braced_list_body markup_list {
2714                 $$ = scm_reverse_x ($2, $1);
2715         }
2716         ;
2717
2718 markup_command_list:
2719         MARKUP_LIST_FUNCTION markup_command_list_arguments {
2720           $$ = scm_cons ($1, scm_reverse_x($2, SCM_EOL));
2721         }
2722         ;
2723
2724 markup_command_basic_arguments:
2725         EXPECT_MARKUP_LIST markup_command_list_arguments markup_list {
2726           $$ = scm_cons ($3, $2);
2727         }
2728         | EXPECT_SCM markup_command_list_arguments embedded_scm_closed {
2729           $$ = check_scheme_arg (PARSER, @3, SCM_UNDEFINED, $3, $2, $1);
2730         }
2731         | EXPECT_NO_MORE_ARGS {
2732           $$ = SCM_EOL;
2733         }
2734         ;
2735
2736 markup_command_list_arguments:
2737         markup_command_basic_arguments { $$ = $1; }
2738         | EXPECT_MARKUP markup_command_list_arguments markup {
2739           $$ = scm_cons ($3, $2);
2740         }
2741         ;
2742
2743 markup_head_1_item:
2744         MARKUP_FUNCTION EXPECT_MARKUP markup_command_list_arguments {
2745           $$ = scm_cons ($1, scm_reverse_x ($3, SCM_EOL));
2746         }
2747         ;
2748
2749 markup_head_1_list:
2750         markup_head_1_item      {
2751                 $$ = scm_list_1 ($1);
2752         }
2753         | markup_head_1_list markup_head_1_item {
2754                 $$ = scm_cons ($2, $1);
2755         }
2756         ;
2757
2758 simple_markup:
2759         STRING {
2760                 $$ = make_simple_markup ($1);
2761         }
2762         | MARKUP_IDENTIFIER {
2763                 $$ = $1;
2764         }
2765         | LYRIC_MARKUP_IDENTIFIER {
2766                 $$ = $1;
2767         }
2768         | STRING_IDENTIFIER {
2769                 $$ = $1;
2770         }
2771         | SCORE {
2772                 SCM nn = PARSER->lexer_->lookup_identifier ("pitchnames");
2773                 PARSER->lexer_->push_note_state (alist_to_hashq (nn));
2774         } '{' score_body '}' {
2775                 Score * sc = $4;
2776                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2777                 sc->unprotect ();
2778                 PARSER->lexer_->pop_state ();
2779         }
2780         | MARKUP_FUNCTION markup_command_basic_arguments {
2781                 $$ = scm_cons ($1, scm_reverse_x ($2, SCM_EOL));
2782         }
2783         ;
2784
2785 markup:
2786         markup_head_1_list simple_markup        {
2787                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2788                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2789         }
2790         | simple_markup {
2791                 $$ = $1;
2792         }
2793         ;
2794
2795 %%
2796
2797 void
2798 Lily_parser::set_yydebug (bool x)
2799 {
2800         yydebug = x;
2801 }
2802
2803 void
2804 Lily_parser::do_yyparse ()
2805 {
2806         yyparse ((void*)this);
2807 }
2808
2809
2810
2811
2812
2813 /*
2814
2815 It is a little strange to have this function in this file, but
2816 otherwise, we have to import music classes into the lexer.
2817
2818 */
2819 int
2820 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2821 {
2822         if (scm_is_string (sid)) {
2823                 *destination = sid;
2824                 return STRING_IDENTIFIER;
2825         } else if (unsmob_book (sid)) {
2826                 Book *book =  unsmob_book (sid)->clone ();
2827                 *destination = book->self_scm ();
2828                 book->unprotect ();
2829
2830                 return BOOK_IDENTIFIER;
2831         } else if (scm_is_number (sid)) {
2832                 *destination = sid;
2833                 return NUMBER_IDENTIFIER;
2834         } else if (unsmob_context_def (sid)) {
2835                 Context_def *def= unsmob_context_def (sid)->clone ();
2836
2837                 *destination = def->self_scm ();
2838                 def->unprotect ();
2839
2840                 return CONTEXT_DEF_IDENTIFIER;
2841         } else if (unsmob_context_mod (sid)) {
2842                 *destination = unsmob_context_mod (sid)->smobbed_copy ();
2843
2844                 return CONTEXT_MOD_IDENTIFIER;
2845         } else if (unsmob_score (sid)) {
2846                 Score *score = new Score (*unsmob_score (sid));
2847                 *destination = score->self_scm ();
2848
2849                 score->unprotect ();
2850                 return SCORE_IDENTIFIER;
2851         } else if (Music *mus = unsmob_music (sid)) {
2852                 mus = mus->clone ();
2853                 *destination = mus->self_scm ();
2854                 unsmob_music (*destination)->
2855                         set_property ("origin", make_input (last_input_));
2856
2857                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2858                         != SCM_BOOL_F;
2859
2860                 mus->unprotect ();
2861                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2862         } else if (unsmob_pitch (sid)) {
2863                 *destination = unsmob_pitch (sid)->smobbed_copy ();
2864                 return PITCH_IDENTIFIER;
2865         } else if (unsmob_duration (sid)) {
2866                 *destination = unsmob_duration (sid)->smobbed_copy ();
2867                 return DURATION_IDENTIFIER;
2868         } else if (unsmob_output_def (sid)) {
2869                 Output_def *p = unsmob_output_def (sid);
2870                 p = p->clone ();
2871
2872                 *destination = p->self_scm ();
2873                 p->unprotect ();
2874                 return OUTPUT_DEF_IDENTIFIER;
2875         } else if (Text_interface::is_markup (sid)) {
2876                 *destination = sid;
2877                 if (is_lyric_state ())
2878                         return LYRIC_MARKUP_IDENTIFIER;
2879                 return MARKUP_IDENTIFIER;
2880         } else if (Text_interface::is_markup_list (sid)) {
2881                 *destination = sid;
2882                 return MARKUPLINES_IDENTIFIER;
2883         }
2884
2885         return -1;
2886 }
2887
2888 SCM
2889 get_next_unique_context_id ()
2890 {
2891         return scm_from_locale_string ("$uniqueContextId");
2892 }
2893
2894
2895 SCM
2896 get_next_unique_lyrics_context_id ()
2897 {
2898         static int new_context_count;
2899         char s[128];
2900         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2901         return scm_from_locale_string (s);
2902 }
2903
2904 SCM check_scheme_arg (Lily_parser *my_lily_parser, Input loc, SCM fallback,
2905                       SCM arg, SCM args, SCM pred)
2906 {
2907         SCM unwrap = SCM_UNDEFINED;
2908         if (scm_is_true (scm_call_1 (pred, arg)))
2909                 return scm_cons (arg, args);
2910         unwrap = try_unpack_lyrics (pred, arg);
2911         if (!SCM_UNBNDP (unwrap))
2912                 return scm_cons (unwrap, args);
2913         if (SCM_UNBNDP (fallback)) {
2914                 args = scm_cons (SCM_BOOL_F, args);
2915                 fallback = SCM_BOOL_F;
2916         } else {
2917                 args = scm_cons (loc_on_music (loc, fallback), args);
2918                 fallback = SCM_CDR (scm_last_pair (args));
2919         }
2920         scm_set_cdr_x (scm_last_pair (args), SCM_EOL);
2921         MAKE_SYNTAX ("argument-error", loc, scm_length (args), pred, arg);
2922         scm_set_cdr_x (scm_last_pair (args), fallback);
2923         return args;
2924 }
2925
2926 SCM loc_on_music (Input loc, SCM arg)
2927 {
2928         if (Music *m = unsmob_music (arg))
2929         {
2930                 m = m->clone ();
2931                 m->set_spot (loc);
2932                 return m->unprotect ();
2933         }
2934         return arg;
2935 }
2936
2937 bool
2938 is_regular_identifier (SCM id)
2939 {
2940   string str = ly_scm2string (id);
2941   char const *s = str.c_str ();
2942
2943   bool v = true;
2944 #if 0
2945   isalpha (*s);
2946   s++;
2947 #endif
2948   while (*s && v)
2949    {
2950         v = v && isalnum (*s);
2951         s++;
2952    }
2953   return v;
2954 }
2955
2956 Music *
2957 make_music_with_input (SCM name, Input where)
2958 {
2959        Music *m = make_music_by_name (name);
2960        m->set_spot (where);
2961        return m;
2962 }
2963
2964 SCM
2965 get_first_context_id (SCM type, Music *m)
2966 {
2967         SCM id = m->get_property ("context-id");
2968         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2969             && scm_is_string (m->get_property ("context-id"))
2970             && scm_c_string_length (id) > 0)
2971         {
2972                 return id;
2973         }
2974         return SCM_EOL;
2975 }
2976
2977 SCM
2978 make_simple_markup (SCM a)
2979 {
2980         return a;
2981 }
2982
2983 bool
2984 is_duration (int t)
2985 {
2986   return t && t == 1 << intlog2 (t);
2987 }
2988
2989 void
2990 set_music_properties (Music *p, SCM a)
2991 {
2992   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2993         p->set_property (scm_caar (k), scm_cdar (k));
2994 }
2995
2996
2997 SCM
2998 make_chord_step (int step, Rational alter)
2999 {
3000         if (step == 7)
3001                 alter += FLAT_ALTERATION;
3002
3003         while (step < 0)
3004                 step += 7;
3005         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
3006         return m.smobbed_copy ();
3007 }
3008
3009
3010 SCM
3011 make_chord_elements (SCM pitch, SCM dur, SCM modification_list)
3012 {
3013         SCM chord_ctor = ly_lily_module_constant ("construct-chord-elements");
3014         return scm_call_3 (chord_ctor, pitch, dur, modification_list);
3015 }
3016
3017 SCM
3018 try_unpack_lyrics (SCM pred, SCM arg)
3019 {
3020         if (Music *m = unsmob_music (arg))
3021                 if (m->is_mus_type ("lyric-event")) {
3022                         SCM text = m->get_property ("text");
3023                         if (scm_is_true (scm_call_1 (pred, text)))
3024                                         return text;
3025                         }
3026         return SCM_UNDEFINED;
3027 }
3028
3029 /* Todo: actually also use apply iso. call too ...  */
3030 bool
3031 ly_input_procedure_p (SCM x)
3032 {
3033         return ly_is_procedure (x)
3034                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
3035 }
3036
3037 int
3038 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
3039 {
3040         Lily_parser *pars = (Lily_parser*) v;
3041         Lily_lexer *lex = pars->lexer_;
3042
3043         lex->lexval_ = (void*) s;
3044         lex->lexloc_ = loc;
3045         lex->prepare_for_next_token ();
3046         return lex->yylex ();
3047 }