lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Two shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 2.  \repeat
  23         \repeat .. \alternative
  24
  25
  26     \repeat { \repeat .. \alternative }
  27
  28 or
  29
  30     \repeat { \repeat } \alternative
  31
  32 )
  33
  34 --hwn
  35
  36  */
  37
  38 /*
  39
  40 TODO:
  41
  42 * The rules for who is protecting what are very shady. Uniformise
  43   this.
  44
  45 * There are too many lexical modes?
  46
  47 */
  48
  49 #include <ctype.h>
  50 #include <stdlib.h>
  51
  52
  53
  54 #include "translator-def.hh"
  55 #include "lily-guile.hh"
  56 #include "misc.hh"
  57 #include "my-lily-lexer.hh"
  58 #include "paper-def.hh"
  59 #include "midi-def.hh"
  60 #include "main.hh"
  61 #include "file-path.hh"
  62 #include "warn.hh"
  63 #include "dimensions.hh"
  64 #include "my-lily-parser.hh"
  65 #include "score.hh"
  66 #include "input-file-results.hh"
  67 #include "input.hh"
  68 #include "lilypond-input-version.hh"
  69 #include "scm-hash.hh"
  70 #include "auto-change-iterator.hh"
  71 #include "ly-modules.hh"
  72 #include "music-sequence.hh"
  73 #include "input-smob.hh"
  74 #include "event.hh"
  75 #include "text-item.hh"
  76 #include "music-list.hh"
  77
  78
  79 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  80
  81
  82
  83 #define YYERROR_VERBOSE 1
  84
  85 My_lily_parser* my_lily_parser;
  86 #define YYPARSE_PARAM my_lily_parser
  87 #define YYLEX_PARAM my_lily_parser
  88 #define THIS\
  89         ((My_lily_parser *) my_lily_parser)
  90
  91 #define yyerror THIS->parser_error
  92
  93
  94
  95
  96
  97 bool
  98 regular_identifier_b (SCM id)
  99 {
 100   String str = ly_scm2string (id);
 101   char const *s = str.to_str0 () ;
 102
 103   bool v = true;
 104   while (*s && v)
 105    {
 106         v = v && isalpha (*s);
 107         s++;
 108    }
 109   return v;
 110 }
 111
 112 SCM
 113 make_simple_markup (SCM a)
 114 {
 115         static SCM simple;
 116         if (!simple)
 117         simple = scm_c_eval_string ("simple-markup");
 118
 119         return scm_list_n (simple, a, SCM_UNDEFINED);
 120 }
 121
 122
 123 bool
 124 is_duration_b (int t)
 125 {
 126   return t && t == 1 << intlog2 (t);
 127 }
 128
 129 void
 130 set_music_properties (Music *p, SCM a)
 131 {
 132   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 133         {
 134         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 135         }
 136 }
 137
 138 SCM
 139 make_chord_step (int step, int alter)
 140 {
 141         if (step == 7)
 142                 alter--;
 143
 144         /* ugh: fucks up above 13 */
 145         Pitch m(step > 7 ? 1 : 0,(step - 1) % 7, alter);
 146         return m.smobbed_copy ();
 147 }
 148
 149
 150 SCM
 151 make_chord (SCM pitch, SCM dur, SCM modification_list)
 152 {
 153         static SCM chord_ctor;
 154         if (!chord_ctor)
 155                 chord_ctor= scm_c_eval_string ("construct-chord");
 156         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 157         scm_gc_protect_object (ch);
 158         return ch;
 159 }
 160
 161 /*
 162   Todo: actually also use apply iso. call too ...
 163 */
 164 bool
 165 ly_input_procedure_p (SCM x)
 166 {
 167         return gh_procedure_p (x)
 168                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 169 }
 170
 171 Music*
 172 set_property_music (SCM sym, SCM value)
 173 {
 174         Music * p = MY_MAKE_MUSIC("PropertySet");
 175         p->set_mus_property ("symbol", sym);
 176         p->set_mus_property ("value", value);
 177         return p;
 178 }
 179
 180 %}
 181
 182 /* We use SCMs to do strings, because it saves us the trouble of
 183 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 184 of the parse stack onto the heap. */
 185
 186
 187 %union {
 188         String * string;
 189     Music *music;
 190     Score *score;
 191     Music_output_def * outputdef;
 192     SCM scm;
 193     int i;
 194 }
 195 %{
 196
 197 int
 198 yylex (YYSTYPE *s,  void * v)
 199 {
 200         My_lily_parser   *pars = (My_lily_parser*) v;
 201         My_lily_lexer * lex = pars->lexer_;
 202
 203         lex->lexval = (void*) s;
 204         lex->prepare_for_next_token();
 205         return lex->yylex ();
 206 }
 207
 208
 209 %}
 210
 211 %pure_parser
 212
 213 /* tokens which are not keywords */
 214 %token AUTOCHANGE
 215 %token ALIAS
 216 %token APPLYCONTEXT
 217 %token APPLYOUTPUT
 218 %token APPLY
 219 %token ACCEPTS
 220 %token ALTERNATIVE
 221 %token BAR
 222 %token BREATHE
 223 %token CHORDMODIFIERS
 224 %token CHORDS
 225 %token CLEF
 226 %token CONSISTS
 227 %token DURATION
 228 %token SEQUENTIAL
 229 %token GROBDESCRIPTIONS
 230 %token SIMULTANEOUS
 231 %token CONSISTSEND
 232 %token DENIES
 233 %token DESCRIPTION
 234 %token EXTENDER
 235 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 236 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 237 %token GRACE
 238 %token HEADER
 239 %token HYPHEN
 240 %token INVALID
 241 %token KEY
 242 %token LYRICS
 243 %token MARK
 244 %token MULTI_MEASURE_REST
 245 %token MIDI
 246 %token PITCH
 247 %token DEFAULT
 248 %token NAME
 249 %token PITCHNAMES
 250 %token NOTES
 251 %token ONCE
 252 %token PAPER
 253 %token PARTIAL
 254 %token PROPERTY
 255 %token OVERRIDE SET REVERT
 256 %token RELATIVE
 257 %token REMOVE
 258 %token REPEAT
 259 %token ADDLYRICS
 260 %token PARTCOMBINE
 261 %token SCM_T
 262 %token SCORE
 263 %token SKIP
 264 %token SPANREQUEST
 265 %token COMMANDSPANREQUEST
 266 %token TEMPO
 267 %token OUTPUTPROPERTY
 268 %token TIME_T
 269 %token TIMES
 270 %token TRANSLATOR
 271 %token TRANSPOSE
 272 %token TYPE
 273 %token UNSET
 274 %token CONTEXT
 275 %token REST
 276
 277 %token CHORD_OPEN
 278 %token CHORD_CLOSE
 279
 280
 281 /* escaped */
 282 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 283 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 284 %token E_BACKSLASH
 285 %token <i> E_UNSIGNED
 286 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 287 %token FIGURE_SPACE
 288
 289 %type <i>       exclamations questions dots optional_rest
 290 %type <i>        bass_mod
 291 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 292 %token <i>      DIGIT
 293 %token <scm>    NOTENAME_PITCH
 294 %token <scm>    TONICNAME_PITCH
 295 %token <scm>    CHORDMODIFIER_PITCH
 296 %token <scm>    DURATION_IDENTIFIER
 297 %token <scm>    FRACTION
 298 %token <id>     IDENTIFIER
 299 %token <scm>    CHORDNAMES
 300
 301 %token <scm> CHORD_MODIFIER
 302
 303 %token <scm>    SCORE_IDENTIFIER
 304 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 305 %token <scm>    NUMBER_IDENTIFIER
 306 %token <scm>    EVENT_IDENTIFIER
 307 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 308 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 309 %token <scm>    RESTNAME
 310 %token <scm>    STRING
 311 %token <scm>    SCM_T
 312 %token <i>      UNSIGNED
 313 %token <scm>   REAL
 314
 315 %token MARKUP
 316 %token <scm> MARKUP_HEAD_MARKUP0
 317 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 318 %token <scm> MARKUP_HEAD_SCM0
 319 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 320 %token <scm> MARKUP_HEAD_SCM0_SCM1
 321 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 322 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 323
 324 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 325 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 326
 327 %type <outputdef> output_def
 328 %type <scm>     lilypond_header lilypond_header_body
 329 %type <music>   open_event_parens close_event_parens open_event close_event
 330 %type <music> event_with_dir event_that_take_dir verbose_event
 331 %type <i>       sub_quotes sup_quotes
 332 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 333 %type <music>   Repeated_music
 334 %type <scm>     Alternative_music
 335 %type <i>       tremolo_type
 336 %type <i>       bare_int  bare_unsigned
 337 %type <i>       script_dir
 338 %type <scm>     identifier_init
 339
 340 %type <music> note_chord_element chord_body chord_body_element
 341 %type <scm>  chord_body_elements
 342 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 343 %type <scm>  verbose_duration
 344
 345 %type <scm>  pre_events post_events
 346 %type <music> gen_text_def
 347 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 348 %type <scm>   explicit_pitch steno_tonic_pitch
 349
 350 /* %type <scm>  chord_additions chord_subtractions chord_notes chord_step */
 351 /* %type <music>        chord */
 352 /* %type <scm>  chord_note chord_inversion chord_bass */
 353 %type <scm>     duration_length fraction
 354
 355 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 356
 357 %type <scm>  embedded_scm scalar
 358 %type <music>   Music Sequential_music Simultaneous_music
 359 %type <music>   relative_music re_rhythmed_music part_combined_music
 360 %type <music>   property_def translator_change  simple_property_def
 361 %type <scm> Music_list
 362 %type <outputdef>  music_output_def_body
 363 %type <music> shorthand_command_req
 364 %type <music>   post_event
 365 %type <music> command_req verbose_command_req
 366 %type <music>   extender_req
 367 %type <music> hyphen_req
 368 %type <music> string_event
 369 %type <scm>     string bare_number number_expression number_term number_factor
 370 %type <score>   score_block score_body
 371
 372 %type <scm>     translator_spec_block translator_spec_body
 373 %type <music>   tempo_event
 374 %type <scm> notenames_body notenames_block chordmodifiers_block
 375 %type <scm>     script_abbreviation
 376
 377
 378
 379 %left '-' '+'
 380
 381 /* We don't assign precedence to / and *, because we might need varied
 382 prec levels in different prods */
 383
 384 %left UNARY_MINUS
 385
 386 %%
 387
 388 lilypond:       /* empty */
 389         | lilypond toplevel_expression {}
 390         | lilypond assignment  { }
 391         | lilypond error {
 392                 THIS->error_level_  = 1;
 393         }
 394         | lilypond INVALID      {
 395                 THIS->error_level_  = 1;
 396         }
 397         ;
 398
 399 toplevel_expression:
 400         notenames_block                 {
 401                 THIS->lexer_->pitchname_tab_ =  $1;
 402         }
 403         | chordmodifiers_block                  {
 404                 THIS->lexer_->chordmodifier_tab_  = $1;
 405         }
 406         | lilypond_header {
 407                 THIS->input_file_->header_ = $1;
 408         }
 409         | score_block {
 410                 THIS->input_file_->scores_.push ($1);
 411         }
 412         | output_def {
 413                 if (dynamic_cast<Paper_def*> ($1))
 414                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultpaper"), $1->self_scm ());
 415                 else if (dynamic_cast<Midi_def*> ($1))
 416                         THIS->lexer_->set_identifier (scm_makfrom0str ("$defaultmidi"), $1->self_scm ());
 417         }
 418         ;
 419
 420 embedded_scm:
 421         SCM_T
 422         | SCM_IDENTIFIER
 423         ;
 424
 425
 426 chordmodifiers_block:
 427         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 428         ;
 429
 430 notenames_block:
 431         PITCHNAMES notenames_body   {  $$ = $2; }
 432         ;
 433
 434 notenames_body:
 435         embedded_scm    {
 436           int i = scm_ilength ($1);
 437
 438           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 439           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 440                 SCM pt = ly_cdar (s);
 441                 scm_hashq_set_x (tab, ly_caar (s), pt);
 442           }
 443           $$ = tab;
 444         }
 445         ;
 446
 447 lilypond_header_body:
 448         {
 449                 $$ = ly_make_anonymous_module ();
 450                 THIS->lexer_->add_scope ($$);
 451         }
 452         | lilypond_header_body assignment  {
 453
 454         }
 455         ;
 456
 457 lilypond_header:
 458         HEADER '{' lilypond_header_body '}'     {
 459                 $$ = THIS->lexer_-> remove_scope();
 460         }
 461         ;
 462
 463
 464 /*
 465         DECLARATIONS
 466 */
 467 assignment:
 468         STRING {
 469                 THIS->push_spot ();
 470         }
 471         /* cont */ '=' identifier_init  {
 472
 473         /*
 474                 Should find generic way of associating input with objects.
 475         */
 476                 Input ip = THIS->pop_spot ();
 477
 478                 if (! regular_identifier_b ($1))
 479                 {
 480                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 481                 }
 482
 483                 THIS->lexer_->set_identifier ($1, $4);
 484
 485 /*
 486  TODO: devise standard for protection in parser.
 487
 488   The parser stack lives on the C-stack, which means that
 489 all objects can be unprotected as soon as they're here.
 490
 491 */
 492         }
 493         | embedded_scm { }
 494         ;
 495
 496
 497
 498 identifier_init:
 499         score_block {
 500                 $$ = $1->self_scm ();
 501                 scm_gc_unprotect_object ($$);
 502         }
 503         | full_markup {
 504                 $$ = $1;
 505         }
 506         | output_def {
 507                 $$ = $1->self_scm ();
 508                 scm_gc_unprotect_object ($$);
 509         }
 510         | translator_spec_block {
 511                 $$ = $1;
 512         }
 513         | Music  {
 514                 $$ = $1->self_scm ();
 515                 scm_gc_unprotect_object ($$);
 516         }
 517         | post_event {
 518                 $$ = $1->self_scm ();
 519                 scm_gc_unprotect_object ($$);
 520         }
 521         | verbose_duration {
 522                 $$ = $1;
 523         }
 524         | number_expression {
 525                 $$ = $1;
 526         }
 527         | string {
 528                 $$ = $1;
 529         }
 530         | embedded_scm  {
 531                 $$ = $1;
 532         }
 533         ;
 534
 535 translator_spec_block:
 536         TRANSLATOR '{' translator_spec_body '}'
 537                 {
 538                 $$ = $3;
 539         }
 540         ;
 541
 542 translator_spec_body:
 543         TRANSLATOR_IDENTIFIER   {
 544                 $$ = $1;
 545                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 546         }
 547         | TYPE STRING   {
 548                 $$ = Translator_def::make_scm ();
 549                 Translator_def*td =  unsmob_translator_def ($$);
 550                 td->translator_group_type_ = $2;
 551                 td->set_spot (THIS->here_input ());
 552         }
 553         | translator_spec_body DESCRIPTION string  {
 554                 unsmob_translator_def ($$)->description_ = $3;
 555         }
 556         | translator_spec_body STRING '=' embedded_scm                  {
 557                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 558         }
 559         | translator_spec_body STRING OVERRIDE embedded_scm '=' embedded_scm {
 560                 unsmob_translator_def ($$)
 561                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 562         }
 563         | translator_spec_body STRING SET embedded_scm '=' embedded_scm {
 564                 unsmob_translator_def ($$)
 565                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 566         }
 567         | translator_spec_body STRING REVERT embedded_scm  {
 568           unsmob_translator_def ($$)->add_pop_property (
 569                 scm_string_to_symbol ($2), $4);
 570         }
 571         | translator_spec_body NAME STRING  {
 572                 unsmob_translator_def ($$)->type_name_ = $3;
 573         }
 574         | translator_spec_body CONSISTS STRING  {
 575                 unsmob_translator_def ($$)->add_element ($3);
 576         }
 577         | translator_spec_body ALIAS STRING  {
 578                 Translator_def*td = unsmob_translator_def ($$);
 579                 td->type_aliases_ = scm_cons ($3, td->type_aliases_);
 580         }
 581         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 582                 Translator_def*td = unsmob_translator_def($$);
 583                 // td->add_property_assign (ly_symbol2scm ("allGrobDescriptions"), $3);
 584                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p))
 585                         td->add_property_assign (scm_symbol_to_string (ly_caar (p)), ly_cdar (p));
 586         }
 587         | translator_spec_body CONSISTSEND STRING  {
 588                 unsmob_translator_def ($$)->add_last_element ( $3);
 589         }
 590         | translator_spec_body ACCEPTS STRING  {
 591                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 592         }
 593         | translator_spec_body DENIES STRING  {
 594                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 595         }
 596         | translator_spec_body REMOVE STRING  {
 597                 unsmob_translator_def ($$)->remove_element ($3);
 598         }
 599         ;
 600
 601 /*
 602         SCORE
 603 */
 604 score_block:
 605         SCORE {
 606                 THIS->push_spot ();
 607         }
 608         /*cont*/ '{' score_body '}'     {
 609                 THIS->pop_spot ();
 610                 $$ = $4;
 611                 if (!$$->defs_.size ())
 612                 {
 613                   Music_output_def *id =
 614                         unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 615                   $$->add_output (id ? id->clone () :  new Paper_def );
 616                 }
 617         }
 618         ;
 619
 620 score_body:
 621         Music   {
 622                 $$ = new Score;
 623
 624                 $$->set_spot (THIS->here_input ());
 625                 SCM m = $1->self_scm ();
 626                 scm_gc_unprotect_object (m);
 627
 628                 /*
 629                         guh.
 630                 */
 631                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 632                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 633                         m = gh_call1 (gh_car (check_funcs), m);
 634                 $$->music_ = m;
 635
 636         }
 637         | SCORE_IDENTIFIER {
 638                 $$ = unsmob_score ($1);
 639                 $$->set_spot (THIS->here_input ());
 640         }
 641         | score_body lilypond_header    {
 642                 $$->header_ = $2;
 643         }
 644         | score_body output_def {
 645                 $$->add_output ($2);
 646         }
 647         | score_body error {
 648
 649         }
 650         ;
 651
 652
 653 /*
 654         MIDI
 655 */
 656 output_def:
 657         music_output_def_body '}' {
 658                 $$ = $1;
 659                 THIS-> lexer_-> remove_scope ();
 660         }
 661         ;
 662
 663 music_output_def_body:
 664         MIDI '{'    {
 665                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 666
 667
 668                 Midi_def* p =0;
 669                 if (id)
 670                         p = dynamic_cast<Midi_def*> (id->clone ());
 671                 else
 672                         p = new Midi_def;
 673
 674                 $$ = p;
 675                 THIS->lexer_->add_scope (p->scope_);
 676         }
 677         | PAPER '{'     {
 678                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 679                   Paper_def *p = 0;
 680                 if (id)
 681                         p = dynamic_cast<Paper_def*> (id->clone ());
 682                 else
 683                         p = new Paper_def;
 684
 685                 THIS->lexer_->add_scope (p->scope_);
 686                 $$ = p;
 687         }
 688         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 689                 Music_output_def * o =  unsmob_music_output_def ($3);
 690                 $$ =o;
 691
 692                 THIS->lexer_->add_scope (o->scope_);
 693         }
 694         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 695                 Music_output_def * o =  unsmob_music_output_def ($3);
 696                 $$ = o;
 697
 698                 THIS->lexer_->add_scope (o->scope_);
 699         }
 700         | music_output_def_body assignment  {
 701
 702         }
 703         | music_output_def_body translator_spec_block   {
 704                 $$->assign_translator ($2);
 705         }
 706         | music_output_def_body tempo_event  {
 707                 /*
 708                         junk this ? there already is tempo stuff in
 709                         music.
 710                 */
 711                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 712                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 713                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 714                 if (md)
 715                         md->set_tempo (d->get_length (), m);
 716         }
 717         | music_output_def_body error {
 718
 719         }
 720         ;
 721
 722 tempo_event:
 723         TEMPO steno_duration '=' bare_unsigned  {
 724                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 725                 $$->set_mus_property ("tempo-unit", $2);
 726                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 727         }
 728         ;
 729
 730 /*
 731 The representation of a  list is the
 732
 733   (LIST . LAST-CONS)
 734
 735  to have  efficient append.
 736 */
 737 Music_list:
 738         /* empty */ {
 739                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 740         }
 741         | Music_list Music {
 742                 SCM s = $$;
 743                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 744                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 745                 if (gh_pair_p (ly_cdr (s)))
 746                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 747                 else
 748                         gh_set_car_x (s, c); /* set first cons */
 749                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 750         }
 751         | Music_list error {
 752         }
 753         ;
 754
 755
 756 Music:
 757         Simple_music
 758         | Composite_music
 759         ;
 760
 761 Alternative_music:
 762         /* empty */ {
 763                 $$ = SCM_EOL;
 764         }
 765         | ALTERNATIVE '{' Music_list '}' {
 766                 $$ = $3;
 767         }
 768         ;
 769
 770 Repeated_music:
 771         REPEAT string bare_unsigned Music Alternative_music
 772         {
 773                 Music *beg = $4;
 774                 int times = $3;
 775                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 776                 if (times < scm_ilength (alts)) {
 777                   unsmob_music (gh_car (alts))
 778                     ->origin ()->warning (
 779                     _("More alternatives than repeats.  Junking excess alternatives."));
 780                   alts = ly_truncate_list (times, alts);
 781                 }
 782
 783
 784                 static SCM proc;
 785                 if (!proc)
 786                         proc = scm_c_eval_string ("make-repeated-music");
 787
 788                 SCM mus = scm_call_1 (proc, $2);
 789                 scm_gc_protect_object (mus); // UGH.
 790                 Music *r =unsmob_music (mus);
 791                 if (beg)
 792                         {
 793                         r-> set_mus_property ("element", beg->self_scm ());
 794                         scm_gc_unprotect_object (beg->self_scm ());
 795                         }
 796                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 797
 798                 r-> set_mus_property ("elements",alts);
 799                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 800                         /*
 801                         we can not get durations and other stuff correct down the line, so we have to
 802                         add to the duration log here.
 803                         */
 804                         static SCM func;
 805
 806                         if (!func)
 807                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 808
 809                         int dots = ($3 % 3) ? 0 : 1;
 810                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 811
 812                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 813
 814                         if (seq) {
 815                                 int list_len =scm_ilength (seq->music_list ());
 816                                 if (list_len != 2)
 817                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 818                                 shift -= 1;
 819                                 r->compress (Moment (Rational (1,list_len)));
 820                                 }
 821                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 822
 823                 }
 824                 r->set_spot (*$4->origin ());
 825
 826                 $$ = r;
 827         }
 828         ;
 829
 830 Sequential_music:
 831         SEQUENTIAL '{' Music_list '}'           {
 832                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 833                 $$->set_mus_property ("elements", ly_car ($3));
 834                 $$->set_spot(THIS->here_input());
 835         }
 836         | '{' Music_list '}'            {
 837                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 838                 $$->set_mus_property ("elements", ly_car ($2));
 839                 $$->set_spot(THIS->here_input());
 840         }
 841         ;
 842
 843 Simultaneous_music:
 844         SIMULTANEOUS '{' Music_list '}'{
 845                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 846                 $$->set_mus_property ("elements", ly_car ($3));
 847                 $$->set_spot(THIS->here_input());
 848
 849         }
 850         | '<' Music_list '>'    {
 851                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 852                 $$->set_mus_property ("elements", ly_car ($2));
 853                 $$->set_spot(THIS->here_input());
 854         }
 855         ;
 856
 857 Simple_music:
 858         event_chord             { $$ = $1; }
 859         | APPLYOUTPUT embedded_scm {
 860                 if (!ly_input_procedure_p ($2))
 861                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 862                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 863                 $$->set_mus_property ("procedure", $2);
 864                 $$->set_spot (THIS->here_input());
 865         }
 866         | APPLYCONTEXT embedded_scm {
 867                 if (!ly_input_procedure_p ($2))
 868                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 869                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 870                 $$->set_mus_property ("procedure", $2);
 871                 $$->set_spot (THIS->here_input());
 872         }
 873         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 874                 SCM pred = $2;
 875                 if (!gh_symbol_p ($3))
 876                 {
 877                         THIS->parser_error (_ ("Second argument must be a symbol"));
 878                 }
 879                 /* Should check # args */
 880                 if (!gh_procedure_p (pred))
 881                 {
 882                         THIS->parser_error (_ ("First argument must be a procedure taking one argument"));
 883                 }
 884
 885                 Music*m = MY_MAKE_MUSIC("OutputPropertySetMusic");
 886                 m->set_mus_property ("predicate", pred);
 887                 m->set_mus_property ("grob-property", $3);
 888                 m->set_mus_property ("grob-value",  $5);
 889
 890                 $$ = m;
 891         }
 892         | MUSIC_IDENTIFIER {
 893                 $$ = unsmob_music ($1);
 894         }
 895         | property_def
 896         | translator_change
 897         ;
 898
 899
 900 Composite_music:
 901         CONTEXT STRING Music    {
 902                 Music*csm =MY_MAKE_MUSIC("ContextSpeccedMusic");
 903
 904                 csm->set_mus_property ("element", $3->self_scm ());
 905                 scm_gc_unprotect_object ($3->self_scm ());
 906
 907                 csm->set_mus_property ("context-type",$2);
 908                 csm->set_mus_property ("context-id", scm_makfrom0str (""));
 909
 910                 $$ = csm;
 911         }
 912         | AUTOCHANGE STRING Music       {
 913         Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 914                 chm->set_mus_property ("element", $3->self_scm ());
 915                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 916
 917                 scm_gc_unprotect_object ($3->self_scm ());
 918                 chm->set_mus_property ("what", $2);
 919
 920                 $$ = chm;
 921                 chm->set_spot (*$3->origin ());
 922         }
 923         | GRACE Music {
 924 #if 1
 925         /*
 926                 The other version is for easier debugging  of
 927                 Sequential_music_iterator in combination with grace notes.
 928         */
 929
 930                 SCM start = THIS->lexer_->lookup_identifier ("startGraceMusic");
 931                 SCM stop = THIS->lexer_->lookup_identifier ("stopGraceMusic");
 932                 Music *startm = unsmob_music (start);
 933                 Music *stopm = unsmob_music (stop);
 934
 935                 SCM ms = SCM_EOL;
 936                 if (stopm) {
 937                         stopm = stopm->clone ();
 938                         ms = scm_cons (stopm->self_scm (), ms);
 939                         scm_gc_unprotect_object (stopm->self_scm ());
 940                 }
 941                 ms = scm_cons ($2->self_scm (), ms);
 942                 scm_gc_unprotect_object ($2->self_scm());
 943                 if (startm) {
 944                         startm = startm->clone ();
 945                         ms = scm_cons (startm->self_scm () , ms);
 946                         scm_gc_unprotect_object (startm->self_scm ());
 947                 }
 948
 949
 950                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 951                 seq->set_mus_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC("GraceMusic");
 955                 $$->set_mus_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC("GraceMusic");
 959                 $$->set_mus_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string Music {
 964                 Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
 965
 966                 csm->set_mus_property ("element", $5->self_scm ());
 967                 scm_gc_unprotect_object ($5->self_scm ());
 968
 969                 csm->set_mus_property ("context-type", $2);
 970                 csm->set_mus_property ("context-id", $4);
 971
 972                 $$ = csm;
 973         }
 974         | TIMES {
 975                 THIS->push_spot ();
 976         }
 977         /* CONTINUED */
 978                 fraction Music
 979
 980         {
 981                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 982                 Music *mp = $4;
 983         $$= MY_MAKE_MUSIC("TimeScaledMusic");
 984                 $$->set_spot (THIS->pop_spot ());
 985
 986
 987                 $$->set_mus_property ("element", mp->self_scm ());
 988                 scm_gc_unprotect_object (mp->self_scm ());
 989                 $$->set_mus_property ("numerator", gh_int2scm (n));
 990                 $$->set_mus_property ("denominator", gh_int2scm (d));
 991                 $$->compress (Moment (Rational (n,d)));
 992
 993         }
 994         | Repeated_music                { $$ = $1; }
 995         | Simultaneous_music            { $$ = $1; }
 996         | Sequential_music              { $$ = $1; }
 997         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 998                 $$ = MY_MAKE_MUSIC("TransposedMusic");
 999                 Music *p = $4;
1000                 Pitch from = *unsmob_pitch ($2);
1001                 Pitch to = *unsmob_pitch ($3);
1002
1003                 p->transpose (interval (from, to));
1004                 $$->set_mus_property ("element", p->self_scm ());
1005                 scm_gc_unprotect_object (p->self_scm ());
1006         }
1007         | APPLY embedded_scm Music  {
1008                 if (!ly_input_procedure_p ($2))
1009                         THIS->parser_error (_ ("\\apply takes function argument"));
1010
1011                 SCM ret = gh_call1 ($2, $3->self_scm ());
1012                 Music *m = unsmob_music (ret);
1013                 if (!m) {
1014                         THIS->parser_error ("\\apply must return a Music");
1015                         m = MY_MAKE_MUSIC("Music");
1016                         }
1017                 $$ = m;
1018         }
1019         | NOTES
1020                 { THIS->lexer_->push_note_state (); }
1021         Music
1022                 { $$ = $3;
1023                   THIS->lexer_->pop_state ();
1024                 }
1025         | FIGURES
1026                 { THIS->lexer_->push_figuredbass_state (); }
1027         Music
1028                 {
1029                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1030                   chm->set_mus_property ("element", $3->self_scm ());
1031                   $$ = chm;
1032                   scm_gc_unprotect_object ($3->self_scm());
1033
1034                   THIS->lexer_->pop_state ();
1035         }
1036         | CHORDS
1037                 { THIS->lexer_->push_chord_state (); }
1038         Music
1039                 {
1040                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1041                   chm->set_mus_property ("element", $3->self_scm ());
1042                   scm_gc_unprotect_object ($3->self_scm());
1043                   $$ = chm;
1044
1045                   THIS->lexer_->pop_state ();
1046         }
1047         | LYRICS
1048                 { THIS->lexer_->push_lyric_state (); }
1049         Music
1050                 {
1051                   $$ = $3;
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | relative_music        { $$ = $1; }
1055         | re_rhythmed_music     { $$ = $1; }
1056         | part_combined_music   { $$ = $1; }
1057         ;
1058
1059 relative_music:
1060         RELATIVE absolute_pitch Music {
1061                 Music * p = $3;
1062                 Pitch pit = *unsmob_pitch ($2);
1063                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1064
1065                 $$->set_mus_property ("element", p->self_scm ());
1066                 scm_gc_unprotect_object (p->self_scm ());
1067
1068
1069                 $$->set_mus_property ("last-pitch", p->to_relative_octave (pit).smobbed_copy ());
1070
1071         }
1072         ;
1073
1074 re_rhythmed_music:
1075         ADDLYRICS Music Music {
1076         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1077           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1078           scm_gc_unprotect_object ($3->self_scm ());
1079           scm_gc_unprotect_object ($2->self_scm ());
1080           $$ = l;
1081         }
1082         ;
1083
1084 part_combined_music:
1085         PARTCOMBINE STRING Music Music {
1086         Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1087                 p->set_mus_property ("what", $2);
1088                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1089
1090                 scm_gc_unprotect_object ($3->self_scm ());
1091                 scm_gc_unprotect_object ($4->self_scm ());
1092
1093                 $$ = p;
1094         }
1095         ;
1096
1097 translator_change:
1098         TRANSLATOR STRING '=' STRING  {
1099                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1100                 t-> set_mus_property ("change-to-type", $2);
1101                 t-> set_mus_property ("change-to-id", $4);
1102
1103                 $$ = t;
1104                 $$->set_spot (THIS->here_input ());
1105         }
1106         ;
1107
1108 property_def:
1109         simple_property_def
1110         | ONCE simple_property_def {
1111                 $$ = $2;
1112                 SCM e = $2->get_mus_property ("element");
1113                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1114         }
1115         ;
1116
1117 simple_property_def:
1118         PROPERTY STRING '.' STRING '='  scalar {
1119                 Music *t = set_property_music (scm_string_to_symbol ($4), $6);
1120                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1121
1122                 csm->set_mus_property ("element", t->self_scm ());
1123                 scm_gc_unprotect_object (t->self_scm ());
1124
1125                 $$ = csm;
1126                 $$->set_spot (THIS->here_input ());
1127
1128                 csm-> set_mus_property ("context-type", $2);
1129         }
1130         | PROPERTY STRING '.' STRING UNSET {
1131
1132                 Music *t = MY_MAKE_MUSIC("PropertyUnset");
1133                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1134
1135                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1136                 csm->set_mus_property ("element", t->self_scm ());
1137                 scm_gc_unprotect_object (t->self_scm ());
1138
1139                 $$ = csm;
1140                 $$->set_spot (THIS->here_input ());
1141
1142                 csm-> set_mus_property ("context-type", $2);
1143         }
1144         | PROPERTY STRING '.' STRING SET embedded_scm '=' embedded_scm {
1145                 bool autobeam
1146                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1147                 bool itc = internal_type_checking_global_b;
1148                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1149                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1150                 t->set_mus_property ("pop-first", SCM_BOOL_T);
1151                 if (autobeam)
1152                         internal_type_checking_global_b = false;
1153                 t->set_mus_property ("grob-property", $6);
1154                 if (autobeam)
1155                         internal_type_checking_global_b = itc;
1156                 t->set_mus_property ("grob-value", $8);
1157
1158                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1159                 csm->set_mus_property ("element", t->self_scm ());
1160                 scm_gc_unprotect_object (t->self_scm ());
1161                 $$ = csm;
1162                 $$->set_spot (THIS->here_input ());
1163
1164                 csm-> set_mus_property ("context-type", $2);
1165         }
1166         | PROPERTY STRING '.' STRING OVERRIDE
1167                 embedded_scm '=' embedded_scm
1168         {
1169                 /*
1170                         UGH UGH UGH UGH.
1171                 */
1172                 bool autobeam
1173                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1174                 bool itc = internal_type_checking_global_b;
1175
1176                 Music *t = MY_MAKE_MUSIC("OverrideProperty");
1177                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1178                 if (autobeam)
1179                         internal_type_checking_global_b = false;
1180                 t->set_mus_property ("grob-property", $6);
1181                 t->set_mus_property ("grob-value", $8);
1182                 if (autobeam)
1183                         internal_type_checking_global_b = itc;
1184
1185                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1186                 csm->set_mus_property ("element", t->self_scm ());
1187                 scm_gc_unprotect_object (t->self_scm ());
1188
1189                 $$ = csm;
1190                 $$->set_spot (THIS->here_input ());
1191
1192                 csm-> set_mus_property ("context-type", $2);
1193
1194         }
1195         | PROPERTY STRING '.' STRING REVERT embedded_scm {
1196                 Music *t = MY_MAKE_MUSIC("RevertProperty");
1197                 bool autobeam
1198                   = gh_equal_p ($4, scm_makfrom0str ("autoBeamSettings"));
1199                 bool itc = internal_type_checking_global_b;
1200
1201                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
1202                 if (autobeam)
1203                         internal_type_checking_global_b = false;
1204                 t->set_mus_property ("grob-property", $6);
1205                 if (autobeam)
1206                         internal_type_checking_global_b = itc;
1207
1208                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1209                 csm->set_mus_property ("element", t->self_scm ());
1210                 scm_gc_unprotect_object (t->self_scm ());
1211
1212                 $$ = csm;
1213                 $$->set_spot (THIS->here_input ());
1214
1215                 csm-> set_mus_property ("context-type", $2);
1216         }
1217         ;
1218
1219
1220 scalar:
1221         string          { $$ = $1; }
1222         | bare_int      { $$ = gh_int2scm ($1); }
1223         | embedded_scm  { $$ = $1; }
1224         | full_markup {  $$ = $1; }
1225         | DIGIT { $$ = gh_int2scm ($1); }
1226         ;
1227
1228
1229 event_chord:
1230         pre_events {
1231                 THIS->push_spot ();
1232         } /*cont */ simple_element post_events  {
1233                 SCM elts = $3-> get_mus_property ("elements");
1234
1235                 elts = gh_append3 (elts, scm_reverse_x ($1, SCM_EOL),
1236                                    scm_reverse_x ($4, SCM_EOL));
1237
1238                 $3-> set_mus_property ("elements", elts);
1239                 $$ = $3;
1240         }
1241         | command_element
1242         | note_chord_element
1243         ;
1244
1245
1246 note_chord_element:
1247         chord_body optional_notemode_duration post_events
1248         {
1249                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1250                 SCM es = $1->get_mus_property ("elements");
1251                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1252
1253                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1254                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1255                 es = gh_append2 (es, postevs);
1256
1257                 $1-> set_mus_property ("elements", es);
1258                 $$ = $1;
1259         }
1260         ;
1261
1262 chord_body:
1263         CHORD_OPEN chord_body_elements CHORD_CLOSE
1264         {
1265                 $$ = MY_MAKE_MUSIC("EventChord");
1266                 $$->set_mus_property ("elements",
1267                         scm_reverse_x ($2, SCM_EOL));
1268         }
1269         ;
1270
1271 chord_body_elements:
1272         /* empty */             { $$ = SCM_EOL; }
1273         | chord_body_elements chord_body_element {
1274                 $$ = gh_cons ($2->self_scm(), $1);
1275                 scm_gc_unprotect_object ($2->self_scm());
1276         }
1277         ;
1278
1279 chord_body_element:
1280         pitch exclamations questions post_events
1281         {
1282                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1283                 n->set_mus_property ("pitch", $1);
1284                 if ($3 % 2)
1285                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1286                 if ($2 % 2 || $3 % 2)
1287                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1288
1289                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1290                 n->set_mus_property ("articulations", arts);
1291
1292                 $$ = n;
1293         }
1294         ;
1295
1296 command_element:
1297         command_req {
1298                 $$ = MY_MAKE_MUSIC("EventChord");
1299                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1300           scm_gc_unprotect_object ($1->self_scm());
1301
1302                 $$-> set_spot (THIS->here_input ());
1303                 $1-> set_spot (THIS->here_input ());
1304         }
1305         | E_LEFTSQUARE {
1306                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1307                 l->set_mus_property ("span-direction", gh_int2scm (START));
1308                 l->set_spot (THIS->here_input ());
1309
1310                 $$ = MY_MAKE_MUSIC("EventChord");
1311                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1312                 scm_gc_unprotect_object (l->self_scm());
1313                 $$->set_spot (THIS->here_input ());
1314         }
1315         | E_RIGHTSQUARE {
1316                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1317                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1318                 l->set_spot (THIS->here_input ());
1319
1320                 $$ = MY_MAKE_MUSIC("EventChord");
1321                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1322                 $$->set_spot (THIS->here_input ());
1323                 scm_gc_unprotect_object (l->self_scm());
1324         }
1325         | E_BACKSLASH {
1326                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1327                 $$->set_spot (THIS->here_input ());
1328         }
1329         | '|'      {
1330
1331                 $$ = MY_MAKE_MUSIC("BarCheck");
1332                 $$->set_spot (THIS->here_input ());
1333         }
1334         | BAR STRING                    {
1335                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1336
1337                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1338                 csm->set_mus_property ("element", t->self_scm ());
1339                 scm_gc_unprotect_object (t->self_scm ());
1340
1341                 $$ = csm;
1342                 $$->set_spot (THIS->here_input ());
1343
1344                 csm->set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1345         }
1346         | PARTIAL duration_length       {
1347                 Moment m = - unsmob_duration ($2)->get_length ();
1348                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1349
1350                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1351                 sp->set_mus_property ("element", p->self_scm ());
1352                 scm_gc_unprotect_object (p->self_scm ());
1353
1354                 $$ =sp ;
1355                 sp-> set_mus_property ("context-type", scm_makfrom0str ("Timing"));
1356         }
1357         | CLEF STRING  {
1358                 static SCM proc ;
1359                 if (!proc)
1360                         proc = scm_c_eval_string ("make-clef-set");
1361
1362                 SCM result = scm_call_1 (proc, $2);
1363                 scm_gc_protect_object (result);
1364                 $$ = unsmob_music (result);
1365         }
1366         | TIME_T fraction  {
1367                 static SCM proc;
1368                 if (!proc)
1369                         proc = scm_c_eval_string ("make-time-signature-set");
1370
1371                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1372                 scm_gc_protect_object (result);
1373                 $$ = unsmob_music (result);
1374         }
1375         ;
1376
1377 command_req:
1378         shorthand_command_req   { $$ = $1; }
1379         | verbose_command_req   { $$ = $1; }
1380         ;
1381
1382 shorthand_command_req:
1383         extender_req {
1384                 $$ = $1;
1385         }
1386         | hyphen_req {
1387                 $$ = $1;
1388         }
1389         | '~'   {
1390                 $$ = MY_MAKE_MUSIC("TieEvent");
1391         }
1392         | '['           {
1393                 Music *b= MY_MAKE_MUSIC("BeamEvent");
1394                 b->set_mus_property ("span-direction", gh_int2scm (START));
1395                 $$ = b;
1396
1397                 THIS->last_beam_start_ = b->self_scm ();
1398         }
1399         | ']'           {
1400                 Music *b= MY_MAKE_MUSIC("BeamEvent");
1401                 b->set_mus_property ("span-direction", gh_int2scm (STOP));
1402                 $$ = b;
1403         }
1404         | BREATHE {
1405                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1406         }
1407         | E_TILDE {
1408                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1409         }
1410         ;
1411
1412 verbose_command_req:
1413         MARK DEFAULT  {
1414                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1415                 $$ = m;
1416         }
1417         | MARK scalar {
1418                 Music *m = MY_MAKE_MUSIC("MarkEvent");
1419                 m->set_mus_property ("label", $2);
1420                 $$ = m;
1421         }
1422         | SKIP duration_length {
1423                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1424                 skip->set_mus_property ("duration", $2);
1425
1426                 $$ = skip;
1427         }
1428         | tempo_event {
1429                 $$ = $1;
1430         }
1431         | KEY DEFAULT {
1432                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1433                 $$ = key;
1434         }
1435         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1436
1437                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1438                 if (scm_ilength ($3) > 0)
1439                 {
1440                         key->set_mus_property ("pitch-alist", $3);
1441                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1442                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1443                 } else {
1444                         THIS->parser_error (_("Second argument must be pitch list."));
1445                 }
1446
1447                 $$ = key;
1448         }
1449         ;
1450
1451 post_events:
1452         /* empty */ {
1453                 $$ = SCM_EOL;
1454         }
1455         | post_events post_event {
1456                 $2->set_spot (THIS->here_input ());
1457                 $$ = gh_cons ($2->self_scm(), $$);
1458                 scm_gc_unprotect_object ($2->self_scm());
1459         }
1460         ;
1461
1462 post_event:
1463         verbose_event
1464         | event_with_dir
1465         | close_event
1466         | string_event
1467         ;
1468
1469 string_event:
1470         E_UNSIGNED {
1471                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1472                 s->set_mus_property ("string-number",  gh_int2scm($1));
1473                 s->set_spot (THIS->here_input ());
1474                 $$ = s;
1475         }
1476         ;
1477
1478
1479 event_that_take_dir:
1480         gen_text_def
1481         | verbose_event
1482         | close_event
1483         | open_event
1484         | '['  {
1485                 Music * m = MY_MAKE_MUSIC ("NewBeamEvent");
1486                 m->set_spot (THIS->here_input());
1487                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1488                 $$ = m;
1489         }
1490         | ']'  {
1491                 Music * m = MY_MAKE_MUSIC ("NewBeamEvent");
1492                 m->set_spot (THIS->here_input());
1493                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1494                 $$ = m;
1495         }
1496         | '~' {
1497                 Music * m = MY_MAKE_MUSIC ("NewTieEvent");
1498                 m->set_spot (THIS->here_input());
1499                 $$ = m;
1500         }
1501         | script_abbreviation {
1502                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1503                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1504                 if (gh_string_p (s))
1505                         a->set_mus_property ("articulation-type", s);
1506                 else THIS->parser_error (_ ("Expecting string as script definition"));
1507                 $$ = a;
1508         }
1509         ;
1510
1511 event_with_dir:
1512         script_dir event_that_take_dir  {
1513                 $2->set_mus_property ("direction", gh_int2scm ($1));
1514                 $$ = $2;
1515         }
1516         ;
1517
1518 verbose_event:
1519         EVENT_IDENTIFIER        {
1520                 $$ = unsmob_music ($1);
1521         }
1522         | tremolo_type  {
1523                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1524                a->set_spot (THIS->here_input ());
1525                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1526                $$ = a;
1527         }
1528         ;
1529
1530 sup_quotes:
1531         '\'' {
1532                 $$ = 1;
1533         }
1534         | sup_quotes '\'' {
1535                 $$ ++;
1536         }
1537         ;
1538
1539 sub_quotes:
1540         ',' {
1541                 $$ = 1;
1542         }
1543         | sub_quotes ',' {
1544                 $$ ++ ;
1545         }
1546         ;
1547
1548 steno_pitch:
1549         NOTENAME_PITCH  {
1550                 $$ = $1;
1551         }
1552         | NOTENAME_PITCH sup_quotes     {
1553                 Pitch p = *unsmob_pitch ($1);
1554                 p = p.transposed (Pitch ($2,0,0));
1555                 $$ = p.smobbed_copy ();
1556         }
1557         | NOTENAME_PITCH sub_quotes      {
1558                 Pitch p =* unsmob_pitch ($1);
1559                 p = p.transposed (Pitch (-$2,0,0));
1560                 $$ = p.smobbed_copy ();
1561         }
1562         ;
1563
1564 /*
1565 ugh. duplication
1566 */
1567
1568 steno_tonic_pitch:
1569         TONICNAME_PITCH {
1570                 $$ = $1;
1571         }
1572         | TONICNAME_PITCH sup_quotes    {
1573                 Pitch p = *unsmob_pitch ($1);
1574                 p = p.transposed (Pitch ($2,0,0));
1575                 $$ = p.smobbed_copy ();
1576         }
1577         | TONICNAME_PITCH sub_quotes     {
1578                 Pitch p =* unsmob_pitch ($1);
1579
1580                 p = p.transposed (Pitch (-$2,0,0));
1581                 $$ = p.smobbed_copy ();
1582         }
1583         ;
1584
1585 pitch:
1586         steno_pitch {
1587                 $$ = $1;
1588         }
1589         | explicit_pitch {
1590                 $$ = $1;
1591         }
1592         ;
1593
1594 pitch_also_in_chords:
1595         pitch
1596         | steno_tonic_pitch
1597         ;
1598
1599 explicit_pitch:
1600         PITCH embedded_scm {
1601                 $$ = $2;
1602                 if (!unsmob_pitch ($2)) {
1603                         THIS->parser_error (_f ("Expecting musical-pitch value", 3));
1604                          $$ = Pitch ().smobbed_copy ();
1605                 }
1606         }
1607         ;
1608
1609 verbose_duration:
1610         DURATION embedded_scm   {
1611                 $$ = $2;
1612                 if (!unsmob_duration ($2))
1613                 {
1614                         THIS->parser_error (_ ("Must have duration object"));
1615                         $$ = Duration ().smobbed_copy ();
1616                 }
1617         }
1618         ;
1619
1620 extender_req:
1621         EXTENDER {
1622                 if (!THIS->lexer_->lyric_state_b ())
1623                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1624                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1625         }
1626         ;
1627
1628 hyphen_req:
1629         HYPHEN {
1630                 if (!THIS->lexer_->lyric_state_b ())
1631                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1632                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1633         }
1634         ;
1635
1636 close_event:
1637         close_event_parens {
1638                 $$ = $1;
1639                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (START))
1640 ;
1641         }
1642         ;
1643
1644 close_event_parens:
1645         '('     {
1646                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1647                 $$ = s;
1648                 s->set_spot (THIS->here_input());
1649         }
1650         | E_OPEN        {
1651                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1652                 $$ = s;
1653                 s->set_spot (THIS->here_input());
1654         }
1655         | E_SMALLER {
1656                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1657                 $$ = s;
1658                 s->set_spot (THIS->here_input());
1659         }
1660         | E_BIGGER {
1661                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1662                 $$ = s;
1663                 s->set_spot (THIS->here_input());
1664         }
1665         ;
1666
1667
1668 open_event:
1669         open_event_parens {
1670                 $$ = $1;
1671                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction", gh_int2scm (STOP))
1672 ;
1673                 static int warn_count ;
1674                 if (warn_count < 10)
1675                         {
1676                         $$->origin ()->warning (_("Prefix articulations are deprecated. Use postfix notation instead."));
1677                         warn_count ++;
1678                         }
1679         }
1680         ;
1681
1682 open_event_parens:
1683         E_EXCLAMATION   {
1684                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1685                 s->set_spot (THIS->here_input());
1686
1687                 $$ = s;
1688         }
1689         | ')'   {
1690                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1691                 $$ = s;
1692                 s->set_spot (THIS->here_input());
1693
1694         }
1695         | E_CLOSE       {
1696                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1697                 $$ = s;
1698                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1699                 s->set_spot (THIS->here_input());
1700         }
1701         ;
1702
1703 gen_text_def:
1704         embedded_scm {
1705                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1706                 t->set_mus_property ("text", $1);
1707                 t->set_spot (THIS->here_input ());
1708                 $$ = t;
1709         }
1710         | full_markup {
1711                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1712                 t->set_mus_property ("text", $1);
1713                 t->set_spot (THIS->here_input ());
1714                 $$ = t;
1715         }
1716         | string {
1717                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1718                 t->set_mus_property ("text", make_simple_markup ($1));
1719                 t->set_spot (THIS->here_input ());
1720                 $$ = t;
1721
1722         }
1723         | DIGIT {
1724                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1725                 t->set_mus_property ("digit",  gh_int2scm ($1));
1726                 t->set_spot (THIS->here_input ());
1727                 $$ = t;
1728         }
1729         ;
1730
1731 script_abbreviation:
1732         '^'             {
1733                 $$ = scm_makfrom0str ("Hat");
1734         }
1735         | '+'           {
1736                 $$ = scm_makfrom0str ("Plus");
1737         }
1738         | '-'           {
1739                 $$ = scm_makfrom0str ("Dash");
1740         }
1741         | '|'           {
1742                 $$ = scm_makfrom0str ("Bar");
1743         }
1744         | '>'           {
1745                 $$ = scm_makfrom0str ("Larger");
1746         }
1747         | '.'           {
1748                 $$ = scm_makfrom0str ("Dot");
1749         }
1750         | '_' {
1751                 $$ = scm_makfrom0str ("Underscore");
1752         }
1753         ;
1754
1755 script_dir:
1756         '_'     { $$ = DOWN; }
1757         | '^'   { $$ = UP; }
1758         | '-'   { $$ = CENTER; }
1759         ;
1760
1761 pre_events:
1762         /* empty */ {
1763                 $$ = SCM_EOL;
1764         }
1765         | pre_events open_event {
1766                 $$ = gh_cons ($2->self_scm(), $$);
1767                 scm_gc_unprotect_object ($2->self_scm());
1768         }
1769         ;
1770
1771 absolute_pitch:
1772         steno_pitch     {
1773                 $$ = $1;
1774         }
1775         ;
1776
1777 duration_length:
1778         multiplied_duration {
1779                 $$ = $1;
1780         }
1781         | verbose_duration {
1782                 $$ = $1;
1783         }
1784         ;
1785
1786 optional_notemode_duration:
1787         {
1788                 Duration dd = THIS->default_duration_;
1789                 $$ = dd.smobbed_copy ();
1790
1791                 THIS->beam_check ($$);
1792         }
1793         | multiplied_duration   {
1794                 $$ = $1;
1795                 THIS->default_duration_ = *unsmob_duration ($$);
1796
1797                 THIS->beam_check ($$);
1798         }
1799         | verbose_duration {
1800                 $$ = $1;
1801                 THIS->default_duration_ = *unsmob_duration ($$);
1802         }
1803         ;
1804
1805 steno_duration:
1806         bare_unsigned dots              {
1807                 int l = 0;
1808                 if (!is_duration_b ($1))
1809                         THIS->parser_error (_f ("not a duration: %d", $1));
1810                 else
1811                         l =  intlog2 ($1);
1812
1813                 $$ = Duration (l, $2).smobbed_copy ();
1814         }
1815         | DURATION_IDENTIFIER dots      {
1816                 Duration *d =unsmob_duration ($1);
1817                 Duration k (d->duration_log (),d->dot_count () + $2);
1818
1819                 *d = k;
1820                 $$ = $1;
1821         }
1822         ;
1823
1824
1825
1826
1827 multiplied_duration:
1828         steno_duration {
1829                 $$ = $1;
1830         }
1831         | multiplied_duration '*' bare_unsigned {
1832                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1833         }
1834         | multiplied_duration '*' FRACTION {
1835                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1836
1837                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1838         }
1839         ;
1840
1841 fraction:
1842         FRACTION { $$ = $1; }
1843         | UNSIGNED '/' UNSIGNED {
1844                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1845         }
1846         ;
1847
1848 dots:
1849         /* empty */     {
1850                 $$ = 0;
1851         }
1852         | dots '.' {
1853                 $$ ++;
1854         }
1855         ;
1856
1857
1858 tremolo_type:
1859         ':'     {
1860                 $$ =0;
1861         }
1862         | ':' bare_unsigned {
1863                 if (!is_duration_b ($2))
1864                         THIS->parser_error (_f ("not a duration: %d", $2));
1865                 $$ = $2;
1866         }
1867         ;
1868
1869
1870
1871 /*****************************************************************
1872                 BASS FIGURES
1873 *****************************************************************/
1874 bass_number:
1875         DIGIT   {
1876                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1877         }
1878         | UNSIGNED {
1879                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1880         }
1881         | STRING { $$ =  $1 }
1882         ;
1883
1884 bass_mod:
1885         '-'     { $$ = -1; }
1886         | '+'   { $$ = 1; }
1887         | '!'   { $$ = 0; }
1888         ;
1889
1890 bass_figure:
1891         FIGURE_SPACE {
1892                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1893                 $$ = bfr->self_scm();
1894                 scm_gc_unprotect_object ($$);
1895         }
1896         | bass_number  {
1897                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1898                 $$ = bfr->self_scm();
1899
1900                 bfr->set_mus_property ("figure", $1);
1901
1902                 scm_gc_unprotect_object ($$);
1903         }
1904         | bass_figure bass_mod {
1905                 Music *m = unsmob_music ($1);
1906                 if ($2) {
1907                         SCM salter =m->get_mus_property ("alteration");
1908                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1909                         m->set_mus_property ("alteration",
1910                                 gh_int2scm (alter + $2));
1911                 } else {
1912                         m->set_mus_property ("alteration", gh_int2scm (0));
1913                 }
1914         }
1915         ;
1916
1917 br_bass_figure:
1918         '[' bass_figure {
1919                 $$ = $2;
1920                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1921         }
1922         | bass_figure   {
1923                 $$ = $1;
1924         }
1925         | br_bass_figure ']' {
1926                 $$ = $1;
1927                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1928         }
1929         ;
1930
1931 figure_list:
1932         /**/            {
1933                 $$ = SCM_EOL;
1934         }
1935         | figure_list br_bass_figure {
1936                 $$ = scm_cons ($2, $1);
1937         }
1938         ;
1939
1940 figure_spec:
1941         FIGURE_OPEN figure_list FIGURE_CLOSE {
1942                 Music * m = MY_MAKE_MUSIC("EventChord");
1943                 $2 = scm_reverse_x ($2, SCM_EOL);
1944                 m->set_mus_property ("elements",  $2);
1945                 $$ = m->self_scm ();
1946         }
1947         ;
1948
1949
1950 optional_rest:
1951         /**/   { $$ = 0; }
1952         | REST { $$ = 1; }
1953         ;
1954
1955 simple_element:
1956         pitch exclamations questions optional_notemode_duration optional_rest {
1957
1958                 Input i = THIS->pop_spot ();
1959                 if (!THIS->lexer_->note_state_b ())
1960                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1961
1962                 Music *n = 0;
1963                 if ($5)
1964                         n =  MY_MAKE_MUSIC("RestEvent");
1965                 else
1966                         n =  MY_MAKE_MUSIC("NoteEvent");
1967
1968                 n->set_mus_property ("pitch", $1);
1969                 n->set_mus_property ("duration", $4);
1970
1971
1972                 if ($3 % 2)
1973                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1974                 if ($2 % 2 || $3 % 2)
1975                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1976
1977                 Music *v = MY_MAKE_MUSIC("EventChord");
1978                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1979                 scm_gc_unprotect_object (n->self_scm());
1980
1981                 v->set_spot (i);
1982                 n->set_spot (i);
1983                 $$ = v;
1984         }
1985         | figure_spec optional_notemode_duration {
1986                 Music * m = unsmob_music ($1);
1987                 Input i = THIS->pop_spot ();
1988                 m->set_spot (i);
1989                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1990                 {
1991                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1992                 }
1993                 $$ = m;
1994         }
1995         | RESTNAME optional_notemode_duration           {
1996
1997                 Input i = THIS->pop_spot ();
1998                 Music * ev = 0;
1999                 if (ly_scm2string ($1) =="s") {
2000                         /* Space */
2001                         ev = MY_MAKE_MUSIC("SkipEvent");
2002                   }
2003                 else {
2004                         ev = MY_MAKE_MUSIC("RestEvent");
2005
2006                     }
2007                 ev->set_mus_property ("duration" ,$2);
2008                 ev->set_spot (i);
2009                 Music * velt = MY_MAKE_MUSIC("EventChord");
2010                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2011                 velt->set_spot (i);
2012
2013                 $$ = velt;
2014         }
2015         | MULTI_MEASURE_REST optional_notemode_duration         {
2016                 THIS->pop_spot ();
2017
2018                 static SCM proc ;
2019                 if (!proc)
2020                         proc = scm_c_eval_string ("make-multi-measure-rest");
2021
2022                 SCM mus = scm_call_2 (proc, $2,
2023                         make_input (THIS->here_input()));
2024                 scm_gc_protect_object (mus);
2025                 $$ = unsmob_music (mus);
2026         }
2027         | STRING optional_notemode_duration     {
2028                 Input i = THIS->pop_spot ();
2029
2030                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2031                 lreq->set_mus_property ("text", $1);
2032                 lreq->set_mus_property ("duration",$2);
2033                 lreq->set_spot (i);
2034                 Music * velt = MY_MAKE_MUSIC("EventChord");
2035                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2036
2037                 $$= velt;
2038         }
2039         | new_chord {
2040                 THIS->pop_spot ();
2041
2042                 if (!THIS->lexer_->chord_state_b ())
2043                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2044                 $$ = unsmob_music ($1);
2045         }
2046         ;
2047
2048 new_chord:
2049         steno_tonic_pitch optional_notemode_duration   {
2050                 $$ = make_chord ($1, $2, SCM_EOL);
2051         }
2052         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2053                 SCM its = scm_reverse_x ($4, SCM_EOL);
2054                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2055         }
2056         ;
2057
2058 chord_items:
2059         /**/ {
2060                 $$ = SCM_EOL;
2061         }
2062         | chord_items chord_item {
2063                 $$ = gh_cons ($2, $$);
2064         }
2065         ;
2066
2067 chord_separator:
2068         CHORD_COLON {
2069                 $$ = ly_symbol2scm ("chord-colon");
2070         }
2071         | CHORD_CARET {
2072                 $$ = ly_symbol2scm ("chord-caret");
2073         }
2074         | CHORD_SLASH steno_tonic_pitch {
2075                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2076         }
2077         | CHORD_BASS steno_tonic_pitch {
2078                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2079         }
2080         ;
2081
2082 chord_item:
2083         chord_separator {
2084                 $$ = $1;
2085         }
2086         | step_numbers {
2087                 $$ = scm_reverse_x ($1, SCM_EOL);
2088         }
2089         | CHORD_MODIFIER  {
2090                 $$ = $1;
2091         }
2092         ;
2093
2094 step_numbers:
2095         step_number { $$ = gh_cons ($1, SCM_EOL); }
2096         | step_numbers '.' step_number {
2097                 $$ = gh_cons ($3, $$);
2098         }
2099         ;
2100
2101 step_number:
2102         bare_unsigned {
2103                 $$ = make_chord_step ($1, 0);
2104         }
2105         | bare_unsigned '+' {
2106                 $$ = make_chord_step ($1, 1);
2107         }
2108         | bare_unsigned CHORD_MINUS {
2109                 $$ = make_chord_step ($1,-1);
2110         }
2111         ;
2112
2113 /*
2114         UTILITIES
2115  */
2116 number_expression:
2117         number_expression '+' number_term {
2118                 $$ = scm_sum ($1, $3);
2119         }
2120         | number_expression '-' number_term {
2121                 $$ = scm_difference ($1, $3);
2122         }
2123         | number_term
2124         ;
2125
2126 number_term:
2127         number_factor {
2128                 $$ = $1;
2129         }
2130         | number_factor '*' number_factor {
2131                 $$ = scm_product ($1, $3);
2132         }
2133         | number_factor '/' number_factor {
2134                 $$ = scm_divide ($1, $3);
2135         }
2136         ;
2137
2138 number_factor:
2139         '-'  number_factor { /* %prec UNARY_MINUS */
2140                 $$ = scm_difference ($2, SCM_UNDEFINED);
2141         }
2142         | bare_number
2143         ;
2144
2145
2146 bare_number:
2147         UNSIGNED        {
2148                 $$ = gh_int2scm ($1);
2149         }
2150         | REAL          {
2151                 $$ = $1;
2152         }
2153         | NUMBER_IDENTIFIER             {
2154                 $$ = $1;
2155         }
2156         | REAL NUMBER_IDENTIFIER        {
2157                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2158         }
2159         | UNSIGNED NUMBER_IDENTIFIER    {
2160                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2161         }
2162         ;
2163
2164
2165 bare_unsigned:
2166         UNSIGNED {
2167                         $$ = $1;
2168         }
2169         | DIGIT {
2170                 $$ = $1;
2171         }
2172         ;
2173
2174 bare_int:
2175         bare_number {
2176                 if (scm_integer_p ($1) == SCM_BOOL_T)
2177                 {
2178                         int k = gh_scm2int ($1);
2179                         $$ = k;
2180                 } else
2181                 {
2182                         THIS->parser_error (_ ("need integer number arg"));
2183                         $$ = 0;
2184                 }
2185         }
2186         | '-' bare_int {
2187                 $$ = -$2;
2188         }
2189         ;
2190
2191
2192 string:
2193         STRING          {
2194                 $$ = $1;
2195         }
2196         | STRING_IDENTIFIER     {
2197                 $$ = $1;
2198         }
2199         | string '+' string {
2200                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2201         }
2202         ;
2203
2204
2205 exclamations:
2206                 { $$ = 0; }
2207         | exclamations '!'      { $$ ++; }
2208         ;
2209
2210 questions:
2211                 { $$ = 0; }
2212         | questions '?' { $$ ++; }
2213         ;
2214
2215
2216
2217 full_markup:
2218         MARKUP_IDENTIFIER {
2219                 $$ = $1;
2220         }
2221         | MARKUP
2222                 { THIS->lexer_->push_markup_state (); }
2223         markup
2224                 { $$ = $3;
2225                   THIS->lexer_->pop_state ();
2226                 }
2227         ;
2228
2229
2230 /*
2231 This should be done more dynamically if possible.
2232 */
2233 markup:
2234         STRING {
2235                 $$ = make_simple_markup ($1);
2236         }
2237         | MARKUP_HEAD_MARKUP0 markup {
2238                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2239         }
2240         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2241                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2242         }
2243         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2244                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2245         }
2246         | markup_line {
2247                 $$ = $1;
2248         }
2249         | MARKUP_HEAD_LIST0 markup_list {
2250                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2251         }
2252         | MARKUP_HEAD_SCM0 embedded_scm {
2253                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2254         }
2255         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2256                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2257         }
2258         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2259                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2260         }
2261         | MARKUP_IDENTIFIER {
2262                 $$ = $1;
2263         }
2264
2265         ;
2266
2267 markup_list:
2268         CHORD_OPEN markup_list_body CHORD_CLOSE { $$ = scm_reverse_x ($2, SCM_EOL); }
2269         ;
2270
2271 markup_line:
2272         '{' markup_list_body '}' {
2273                 static SCM line ;
2274                 if (!line)
2275                         line = scm_c_eval_string ("line-markup");
2276
2277                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2278         }
2279         ;
2280
2281 markup_list_body:
2282         /**/ {  $$ = SCM_EOL; }
2283         | markup_list_body markup {
2284                 $$ = gh_cons ($2, $1) ;
2285         }
2286         ;
2287
2288
2289 %%
2290
2291 void
2292 My_lily_parser::set_yydebug (bool )
2293 {
2294 #if 0
2295         yydebug = 1;
2296 #endif
2297 }
2298
2299 extern My_lily_parser * current_parser;
2300
2301 void
2302 My_lily_parser::do_yyparse ()
2303 {
2304         current_parser = this;;
2305         yyparse ((void*)this);
2306 }
2307
2308
2309 /*
2310 Should make this optional?    It will also complain when you do
2311
2312         [s4]
2313
2314 which is entirely legitimate.
2315
2316 Or we can scrap it. Barchecks should detect wrong durations, and
2317 skipTypesetting speeds it up a lot.
2318 */
2319
2320 void
2321 My_lily_parser::beam_check (SCM dur)
2322 {
2323   Duration *d = unsmob_duration (dur);
2324   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2325     {
2326       Music * m = unsmob_music (last_beam_start_);
2327       m->origin ()->warning (_("Suspect duration found following this beam"));
2328     }
2329   last_beam_start_ = SCM_EOL;
2330 }
2331
2332
2333
2334 bool
2335 markup_p (SCM x)
2336 {
2337         return gh_pair_p (x)
2338                 && SCM_BOOL_F != scm_object_property (gh_car (x), ly_symbol2scm ("markup-signature"));
2339 }
2340
2341
2342 /*
2343
2344 It is a little strange to have this function in this file, but
2345 otherwise, we have to import music classes into the lexer.
2346
2347 */
2348 int
2349 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2350 {
2351         if (gh_string_p (sid)) {
2352                 *destination = sid;
2353                 return STRING_IDENTIFIER;
2354         } else if (gh_number_p (sid)) {
2355                 *destination = sid;
2356                 return NUMBER_IDENTIFIER;
2357         } else if (unsmob_translator_def (sid)) {
2358                 *destination = unsmob_translator_def (sid)->clone_scm();
2359                 return TRANSLATOR_IDENTIFIER;
2360         } else if (unsmob_score (sid)) {
2361                 Score *sc =  new Score (*unsmob_score (sid));
2362                 *destination =sc->self_scm ();
2363                 return SCORE_IDENTIFIER;
2364         } else if (Music * mus =unsmob_music (sid)) {
2365                 *destination = unsmob_music (sid)->clone ()->self_scm();
2366                 unsmob_music (*destination)->
2367                         set_mus_property ("origin", make_input (last_input_));
2368                 return dynamic_cast<Event*> (mus)
2369                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2370         } else if (unsmob_duration (sid)) {
2371                 *destination = unsmob_duration (sid)->smobbed_copy();
2372                 return DURATION_IDENTIFIER;
2373         } else if (unsmob_music_output_def (sid)) {
2374                 Music_output_def *p = unsmob_music_output_def (sid);
2375                 p = p->clone ();
2376
2377                 *destination = p->self_scm();
2378                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2379         } else if (new_markup_p (sid)) {
2380                 *destination = sid;
2381                 return MARKUP_IDENTIFIER;
2382         }
2383
2384         return -1;
2385 }