lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "translator-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token NEWPARTCOMBINE
 287 %token PARTIAL
 288 %token PITCHNAMES
 289 %token PROPERTY
 290 %token RELATIVE
 291 %token REMOVE
 292 %token REPEAT
 293 %token REST
 294 %token SCM_T
 295 %token SCORE
 296 %token SEQUENTIAL
 297 %token SIMULTANEOUS
 298 %token SKIP
 299 %token SPANREQUEST
 300 %token TAG
 301 %token TEMPO
 302 %token TIMES
 303 %token TIME_T
 304 %token TRANSLATOR
 305 %token TRANSPOSE
 306 %token TYPE
 307 %token UNSET
 308 %token WITH
 309
 310 /* escaped */
 311 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 312 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 313 %token E_BACKSLASH
 314 %token <i> E_UNSIGNED
 315 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 316 %token FIGURE_SPACE
 317
 318 %type <i>       exclamations questions dots optional_rest
 319 %type <i>        bass_mod
 320 %type <scm>     grace_head
 321 %type <scm>     oct_check
 322 %type <scm>     context_mod_list
 323 %type <scm>     lyric_element
 324 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 325 %token <i>      DIGIT
 326 %token <scm>    NOTENAME_PITCH
 327 %token <scm>    TONICNAME_PITCH
 328 %token <scm>    CHORDMODIFIER_PITCH
 329 %token <scm>    DURATION_IDENTIFIER
 330 %token <scm>    FRACTION
 331 %token <id>     IDENTIFIER
 332 %token <scm>    CHORDNAMES
 333 %token <scm>    CHORD_MODIFIER
 334 %token <scm>    SCORE_IDENTIFIER
 335 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 336 %token <scm>    NUMBER_IDENTIFIER
 337 %token <scm>    EVENT_IDENTIFIER
 338 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 339 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 340 %token <scm>    RESTNAME
 341 %token <scm>    STRING
 342 %token <scm>    SCM_T
 343 %token <i>      UNSIGNED
 344 %token <scm>   REAL
 345
 346 %token MARKUP
 347 %token <scm> MARKUP_HEAD_MARKUP0
 348 %token <scm> MARKUP_HEAD_EMPTY
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 355
 356 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 357 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 358
 359 %type <outputdef> output_def
 360 %type <scm>     lilypond_header lilypond_header_body
 361 %type <music>   open_event close_event
 362 %type <i>       sub_quotes sup_quotes
 363 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 364 %type <music>   Repeated_music
 365 %type <scm>     Alternative_music
 366 %type <i>       tremolo_type
 367 %type <i>       bare_int  bare_unsigned
 368 %type <i>       script_dir
 369 %type <scm>     identifier_init
 370
 371 %type <music> note_chord_element chord_body chord_body_element
 372 %type <scm>  chord_body_elements
 373 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 374
 375 %type <scm>   post_events
 376 %type <music> gen_text_def direction_less_event direction_reqd_event
 377 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 378 %type <scm>    steno_tonic_pitch
 379 %type <scm>     duration_length fraction
 380
 381 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 382
 383 %type <scm>  embedded_scm scalar
 384 %type <music>   Music Sequential_music Simultaneous_music
 385 %type <music>   relative_music re_rhythmed_music part_combined_music
 386 %type <music>   music_property_def context_change
 387 %type <scm> Music_list
 388 %type <scm> property_operation context_mod translator_mod optional_context_mod
 389 %type <outputdef>  music_output_def_body music_output_def_head
 390 %type <music> shorthand_command_req
 391 %type <music>   post_event tagged_post_event
 392 %type <music> command_req verbose_command_req
 393 %type <music> hyphen_req
 394 %type <music> string_number_event
 395 %type <scm>     string bare_number number_expression number_term number_factor
 396 %type <score>   score_block score_body
 397
 398 %type <scm>     translator_spec_block translator_spec_body
 399 %type <music>   tempo_event
 400 %type <scm> notenames_body notenames_block chordmodifiers_block
 401 %type <scm>     script_abbreviation
 402
 403
 404
 405 %left '-' '+'
 406
 407 /* We don't assign precedence to / and *, because we might need varied
 408 prec levels in different prods */
 409
 410 %left UNARY_MINUS
 411
 412 %%
 413
 414 lilypond:       /* empty */
 415         | lilypond toplevel_expression {}
 416         | lilypond assignment  { }
 417         | lilypond error {
 418                 THIS->error_level_  = 1;
 419         }
 420         | lilypond INVALID      {
 421                 THIS->error_level_  = 1;
 422         }
 423         ;
 424
 425 toplevel_expression:
 426         notenames_block                 {
 427                 THIS->lexer_->pitchname_tab_ =  $1;
 428         }
 429         | chordmodifiers_block                  {
 430                 THIS->lexer_->chordmodifier_tab_  = $1;
 431         }
 432         | lilypond_header {
 433                 THIS->input_file_->header_ = $1;
 434         }
 435         | score_block {
 436                 Score * sc = $1;
 437
 438                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 439
 440                 Path p = split_path (THIS->output_basename_);
 441                 int *c =  &THIS->input_file_->score_count_;
 442                 if (*c)
 443                         {
 444                         p.base += "-" + to_string (*c);
 445                         }
 446
 447                 (*c)++;
 448                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 449
 450                 for (int i=0; i < sc->defs_.size (); i++)
 451                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 452
 453                 if (sc->defs_.empty ())
 454                 {
 455                    Music_output_def *id =
 456                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 457                                 ("$defaultpaper"));
 458
 459                    id = id ? id->clone () : new Paper_def;
 460
 461                    default_rendering (sc->music_, id->self_scm(), head, outname);
 462
 463                    scm_gc_unprotect_object (id->self_scm ());
 464                 }
 465                 scm_gc_unprotect_object (sc->self_scm());
 466         }
 467         | output_def {
 468                 SCM id = SCM_EOL;
 469                 if (dynamic_cast<Paper_def*> ($1))
 470                         id = scm_makfrom0str ("$defaultpaper");
 471                 else if (dynamic_cast<Midi_def*> ($1))
 472                         id = scm_makfrom0str ("$defaultmidi");
 473                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 474                 scm_gc_unprotect_object ($1->self_scm ());
 475         }
 476         ;
 477
 478 embedded_scm:
 479         SCM_T
 480         | SCM_IDENTIFIER
 481         ;
 482
 483
 484 chordmodifiers_block:
 485         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 486         ;
 487
 488 notenames_block:
 489         PITCHNAMES notenames_body   {  $$ = $2; }
 490         ;
 491
 492 notenames_body:
 493         embedded_scm    {
 494           int i = scm_ilength ($1);
 495
 496           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 497           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 498                 SCM pt = ly_cdar (s);
 499                 scm_hashq_set_x (tab, ly_caar (s), pt);
 500           }
 501           $$ = tab;
 502         }
 503         ;
 504
 505 lilypond_header_body:
 506         {
 507                 $$ = ly_make_anonymous_module ();
 508                 THIS->lexer_->add_scope ($$);
 509         }
 510         | lilypond_header_body assignment  {
 511
 512         }
 513         ;
 514
 515 lilypond_header:
 516         HEADER '{' lilypond_header_body '}'     {
 517                 $$ = THIS->lexer_-> remove_scope();
 518         }
 519         ;
 520
 521
 522 /*
 523         DECLARATIONS
 524 */
 525 assignment:
 526         STRING {
 527                 THIS->push_spot ();
 528         }
 529         /* cont */ '=' identifier_init  {
 530
 531         /*
 532                 Should find generic way of associating input with objects.
 533         */
 534                 Input ip = THIS->pop_spot ();
 535
 536                 if (! regular_identifier_b ($1))
 537                 {
 538                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 539                 }
 540
 541                 THIS->lexer_->set_identifier ($1, $4);
 542
 543 /*
 544  TODO: devise standard for protection in parser.
 545
 546   The parser stack lives on the C-stack, which means that
 547 all objects can be unprotected as soon as they're here.
 548
 549 */
 550         }
 551         | embedded_scm { }
 552         ;
 553
 554
 555 identifier_init:
 556         score_block {
 557                 $$ = $1->self_scm ();
 558                 scm_gc_unprotect_object ($$);
 559         }
 560         | full_markup {
 561                 $$ = $1;
 562         }
 563         | output_def {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | translator_spec_block {
 568                 $$ = $1;
 569         }
 570         | Music  {
 571                 $$ = $1->self_scm ();
 572                 scm_gc_unprotect_object ($$);
 573         }
 574         | post_event {
 575                 $$ = $1->self_scm ();
 576                 scm_gc_unprotect_object ($$);
 577         }
 578         | number_expression {
 579                 $$ = $1;
 580         }
 581         | string {
 582                 $$ = $1;
 583         }
 584         | embedded_scm  {
 585                 $$ = $1;
 586         }
 587         ;
 588
 589 translator_spec_block:
 590         TRANSLATOR '{' translator_spec_body '}'
 591                 {
 592                 $$ = $3;
 593         }
 594         ;
 595
 596 translator_spec_body:
 597         /**/ {
 598                 $$ = Context_def::make_scm ();
 599                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 600         }
 601         | TRANSLATOR_IDENTIFIER {
 602                 $$ = $1;
 603                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 604         }
 605         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 606                 Context_def*td = unsmob_context_def($$);
 607
 608                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 609                         SCM tag = gh_caar (p);
 610                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 611                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 612                 }
 613         }
 614         | translator_spec_body context_mod {
 615                 unsmob_context_def ($$)->add_context_mod ($2);
 616         }
 617         ;
 618
 619 /*
 620         SCORE
 621 */
 622 score_block:
 623         SCORE {
 624                 THIS->push_spot ();
 625         }
 626         /*cont*/ '{' score_body '}'     {
 627                 THIS->pop_spot ();
 628                 $$ = $4;
 629
 630         }
 631         ;
 632
 633 score_body:
 634         Music   {
 635                 $$ = new Score;
 636
 637                 $$->set_spot (THIS->here_input ());
 638                 SCM m = $1->self_scm ();
 639                 scm_gc_unprotect_object (m);
 640
 641                 /*
 642                         guh.
 643                 */
 644                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 645                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 646                         m = gh_call1 (gh_car (check_funcs), m);
 647                 $$->music_ = m;
 648
 649         }
 650         | SCORE_IDENTIFIER {
 651                 $$ = new Score ( *unsmob_score ($1));
 652                 $$->set_spot (THIS->here_input ());
 653         }
 654         | score_body lilypond_header    {
 655                 $$->header_ = $2;
 656         }
 657         | score_body output_def {
 658                 $$->defs_.push ($2);
 659                 scm_gc_unprotect_object ($2->self_scm ());
 660         }
 661         | score_body error {
 662
 663         }
 664         ;
 665
 666
 667 /*
 668         MIDI
 669 */
 670 output_def:
 671         music_output_def_body '}' {
 672                 $$ = $1;
 673                 THIS-> lexer_-> remove_scope ();
 674         }
 675         ;
 676
 677 music_output_def_head:
 678         MIDI    {
 679                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 680
 681
 682                 Midi_def* p =0;
 683                 if (id)
 684                         p = dynamic_cast<Midi_def*> (id->clone ());
 685                 else
 686                         p = new Midi_def;
 687
 688                 $$ = p;
 689                 THIS->lexer_->add_scope (p->scope_);
 690         }
 691         | PAPER         {
 692                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 693                   Paper_def *p = 0;
 694                 if (id)
 695                         p = dynamic_cast<Paper_def*> (id->clone ());
 696                 else
 697                         p = new Paper_def;
 698
 699                 THIS->lexer_->add_scope (p->scope_);
 700                 $$ = p;
 701         }
 702         ;
 703
 704
 705 music_output_def_body:
 706         music_output_def_head '{' {
 707
 708         }
 709         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 710                 Music_output_def * o =  unsmob_music_output_def ($3);
 711                 $$ = o;
 712                 THIS->lexer_->remove_scope ();
 713                 THIS->lexer_->add_scope (o->scope_);
 714         }
 715         | music_output_def_body assignment  {
 716
 717         }
 718         | music_output_def_body translator_spec_block   {
 719                 $$->assign_translator ($2);
 720         }
 721         | music_output_def_body tempo_event  {
 722                 /*
 723                         junk this ? there already is tempo stuff in
 724                         music.
 725                 */
 726                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 727                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 728                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 729                 if (md)
 730                         md->set_tempo (d->get_length (), m);
 731                 scm_gc_unprotect_object ($2->self_scm ());
 732         }
 733         | music_output_def_body error {
 734
 735         }
 736         ;
 737
 738 tempo_event:
 739         TEMPO steno_duration '=' bare_unsigned  {
 740                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 741                 $$->set_mus_property ("tempo-unit", $2);
 742                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 743         }
 744         ;
 745
 746 /*
 747 The representation of a  list is the
 748
 749   (LIST . LAST-CONS)
 750
 751  to have  efficient append.
 752 */
 753 Music_list:
 754         /* empty */ {
 755                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 756         }
 757         | Music_list Music {
 758                 SCM s = $$;
 759                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 760                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 761                 if (gh_pair_p (ly_cdr (s)))
 762                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 763                 else
 764                         gh_set_car_x (s, c); /* set first cons */
 765                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 766         }
 767         | Music_list error {
 768         }
 769         ;
 770
 771
 772 Music:
 773         Simple_music
 774         | Composite_music
 775         ;
 776
 777 Alternative_music:
 778         /* empty */ {
 779                 $$ = SCM_EOL;
 780         }
 781         | ALTERNATIVE '{' Music_list '}' {
 782                 $$ = $3;
 783         }
 784         ;
 785
 786 Repeated_music:
 787         REPEAT string bare_unsigned Music Alternative_music
 788         {
 789                 Music *beg = $4;
 790                 int times = $3;
 791                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 792                 if (times < scm_ilength (alts)) {
 793                   unsmob_music (gh_car (alts))
 794                     ->origin ()->warning (
 795                     _("More alternatives than repeats.  Junking excess alternatives."));
 796                   alts = ly_truncate_list (times, alts);
 797                 }
 798
 799
 800                 static SCM proc;
 801                 if (!proc)
 802                         proc = scm_c_eval_string ("make-repeated-music");
 803
 804                 SCM mus = scm_call_1 (proc, $2);
 805                 scm_gc_protect_object (mus); // UGH.
 806                 Music *r =unsmob_music (mus);
 807                 if (beg)
 808                         {
 809                         r-> set_mus_property ("element", beg->self_scm ());
 810                         scm_gc_unprotect_object (beg->self_scm ());
 811                         }
 812                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 813
 814                 r-> set_mus_property ("elements",alts);
 815                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 816                         /*
 817                         we can not get durations and other stuff correct down the line, so we have to
 818                         add to the duration log here.
 819                         */
 820                         static SCM func;
 821
 822                         if (!func)
 823                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 824
 825                         int dots = ($3 % 3) ? 0 : 1;
 826                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 827
 828                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 829
 830                         if (seq) {
 831                                 int list_len =scm_ilength (seq->music_list ());
 832                                 if (list_len != 2)
 833                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 834                                 shift -= 1;
 835                                 r->compress (Moment (Rational (1,list_len)));
 836                                 }
 837                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 838
 839                 }
 840                 r->set_spot (*$4->origin ());
 841
 842                 $$ = r;
 843         }
 844         ;
 845
 846 Sequential_music:
 847         SEQUENTIAL '{' Music_list '}'           {
 848                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 849                 $$->set_mus_property ("elements", ly_car ($3));
 850                 $$->set_spot(THIS->here_input());
 851         }
 852         | '{' Music_list '}'            {
 853                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 854                 $$->set_mus_property ("elements", ly_car ($2));
 855                 $$->set_spot(THIS->here_input());
 856         }
 857         ;
 858
 859 Simultaneous_music:
 860         SIMULTANEOUS '{' Music_list '}'{
 861                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 862                 $$->set_mus_property ("elements", ly_car ($3));
 863                 $$->set_spot(THIS->here_input());
 864
 865         }
 866         | simul_open Music_list simul_close     {
 867                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 868                 $$->set_mus_property ("elements", ly_car ($2));
 869                 $$->set_spot(THIS->here_input());
 870         }
 871         ;
 872
 873 Simple_music:
 874         event_chord             { $$ = $1; }
 875         | APPLYOUTPUT embedded_scm {
 876                 if (!ly_input_procedure_p ($2))
 877                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 878                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 879                 $$->set_mus_property ("procedure", $2);
 880                 $$->set_spot (THIS->here_input());
 881         }
 882         | APPLYCONTEXT embedded_scm {
 883                 if (!ly_input_procedure_p ($2))
 884                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 885                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 886                 $$->set_mus_property ("procedure", $2);
 887                 $$->set_spot (THIS->here_input());
 888         }
 889         | MUSIC_IDENTIFIER {
 890                 $$ = unsmob_music ($1);
 891         }
 892         | music_property_def
 893         | context_change
 894         ;
 895
 896
 897 optional_context_mod:
 898         /**/ { $$ = SCM_EOL; }
 899         | WITH '{' context_mod_list '}'  { $$ = $3; }
 900         ;
 901
 902 grace_head:
 903         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 904         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 905         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 906         ;
 907
 908 context_mod_list:
 909         /* */  { $$ = SCM_EOL; }
 910         | context_mod_list context_mod  {
 911                  $$ = gh_cons ($2, $1);
 912         }
 913         ;
 914
 915 Composite_music:
 916         AUTOCHANGE STRING Music {
 917                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 918                 chm->set_mus_property ("element", $3->self_scm ());
 919                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 920
 921                 scm_gc_unprotect_object ($3->self_scm ());
 922                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 923
 924                 $$ = chm;
 925                 chm->set_spot (*$3->origin ());
 926         }
 927         | grace_head Music {
 928 #if 1
 929         /*
 930                 The other version is for easier debugging  of
 931                 Sequential_music_iterator in combination with grace notes.
 932         */
 933
 934 /*
 935
 936 TODO: should distinguish between both grace types in the
 937 basic music objects too, since the meaning is different.
 938
 939 */
 940
 941                 String start_str = "start" + ly_scm2string ($1) + "Music";
 942                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 943
 944                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 945                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 946
 947                 Music *startm = unsmob_music (start);
 948                 Music *stopm = unsmob_music (stop);
 949
 950                 SCM ms = SCM_EOL;
 951                 if (stopm) {
 952                         stopm = stopm->clone ();
 953                         ms = scm_cons (stopm->self_scm (), ms);
 954                         scm_gc_unprotect_object (stopm->self_scm ());
 955                 }
 956                 ms = scm_cons ($2->self_scm (), ms);
 957                 scm_gc_unprotect_object ($2->self_scm());
 958                 if (startm) {
 959                         startm = startm->clone ();
 960                         ms = scm_cons (startm->self_scm () , ms);
 961                         scm_gc_unprotect_object (startm->self_scm ());
 962                 }
 963
 964
 965                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 966                 seq->set_mus_property ("elements", ms);
 967
 968
 969                 $$ = MY_MAKE_MUSIC("GraceMusic");
 970                 $$->set_mus_property ("element", seq->self_scm ());
 971                 scm_gc_unprotect_object (seq->self_scm ());
 972 #else
 973                 $$ = MY_MAKE_MUSIC("GraceMusic");
 974                 $$->set_mus_property ("element", $2->self_scm ());
 975                 scm_gc_unprotect_object ($2->self_scm ());
 976 #endif
 977         }
 978         | CONTEXT string '=' string optional_context_mod Music {
 979                 $$ = context_spec_music ($2, $4, $6, $5);
 980
 981         }
 982         | CONTEXT STRING optional_context_mod Music {
 983                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 984         }
 985         | NEWCONTEXT string optional_context_mod Music {
 986                 $$ = context_spec_music ($2, get_next_unique_context (),
 987                                          $4, $3);
 988         }
 989
 990         | TIMES {
 991                 THIS->push_spot ();
 992         }
 993         /* CONTINUED */
 994                 fraction Music
 995
 996         {
 997                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 998                 Music *mp = $4;
 999
1000                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
1001                 $$->set_spot (THIS->pop_spot ());
1002
1003                 $$->set_mus_property ("element", mp->self_scm ());
1004                 scm_gc_unprotect_object (mp->self_scm ());
1005                 $$->set_mus_property ("numerator", gh_int2scm (n));
1006                 $$->set_mus_property ("denominator", gh_int2scm (d));
1007                 $$->compress (Moment (Rational (n,d)));
1008
1009         }
1010         | Repeated_music                { $$ = $1; }
1011         | Simultaneous_music            { $$ = $1; }
1012         | Sequential_music              { $$ = $1; }
1013         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1014                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1015                 Music *p = $4;
1016                 Pitch from = *unsmob_pitch ($2);
1017                 Pitch to = *unsmob_pitch ($3);
1018
1019                 p->transpose (interval (from, to));
1020                 $$->set_mus_property ("element", p->self_scm ());
1021                 scm_gc_unprotect_object (p->self_scm ());
1022         }
1023         | APPLY embedded_scm Music  {
1024                 if (!ly_input_procedure_p ($2))
1025                         {
1026                         THIS->parser_error (_ ("\\apply takes function argument"));
1027                         $$ = $3;
1028                         }
1029                 else
1030                         {
1031                         SCM ret = gh_call1 ($2, $3->self_scm ());
1032                         Music *m = unsmob_music (ret);
1033                         if (!m) {
1034                                 THIS->parser_error ("\\apply must return a Music");
1035                                 m = MY_MAKE_MUSIC("Music");
1036                                 }
1037                         $$ = m;
1038                         }
1039         }
1040         | NOTES
1041                 { THIS->lexer_->push_note_state (); }
1042         Music
1043                 { $$ = $3;
1044                   THIS->lexer_->pop_state ();
1045                 }
1046         | FIGURES
1047                 { THIS->lexer_->push_figuredbass_state (); }
1048         Music
1049                 {
1050                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1051                   chm->set_mus_property ("element", $3->self_scm ());
1052                   $$ = chm;
1053                   scm_gc_unprotect_object ($3->self_scm());
1054
1055                   THIS->lexer_->pop_state ();
1056         }
1057         | CHORDS
1058                 { THIS->lexer_->push_chord_state (); }
1059         Music
1060                 {
1061                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1062                   chm->set_mus_property ("element", $3->self_scm ());
1063                   scm_gc_unprotect_object ($3->self_scm());
1064                   $$ = chm;
1065
1066                   THIS->lexer_->pop_state ();
1067         }
1068         | LYRICS
1069                 { THIS->lexer_->push_lyric_state (); }
1070         Music
1071                 {
1072                   $$ = $3;
1073                   THIS->lexer_->pop_state ();
1074         }
1075         | relative_music        { $$ = $1; }
1076         | re_rhythmed_music     { $$ = $1; }
1077         | part_combined_music   { $$ = $1; }
1078         | TAG embedded_scm Music {
1079                 tag_music ($3, $2, THIS->here_input ());
1080                 $$ = $3;
1081         }
1082         ;
1083
1084 relative_music:
1085         RELATIVE absolute_pitch Music {
1086                 Music * p = $3;
1087                 Pitch pit = *unsmob_pitch ($2);
1088                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1089
1090                 $$->set_mus_property ("element", p->self_scm ());
1091                 scm_gc_unprotect_object (p->self_scm ());
1092
1093
1094                 Pitch retpitch = p->to_relative_octave (pit);
1095                 if (lily_1_8_relative)
1096                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1097         }
1098         ;
1099
1100 re_rhythmed_music:
1101         ADDLYRICS Music Music {
1102         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1103           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1104           scm_gc_unprotect_object ($3->self_scm ());
1105           scm_gc_unprotect_object ($2->self_scm ());
1106           $$ = l;
1107         }
1108         | NEWADDLYRICS string Music {
1109           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1110           l->set_mus_property ("element", $3->self_scm ());
1111           scm_gc_unprotect_object ($3->self_scm ());
1112           $$ = l;
1113           l->set_mus_property ("associated-context", $2);
1114         }
1115         ;
1116
1117 part_combined_music:
1118         PARTCOMBINE STRING Music Music {
1119                 Music * p= MY_MAKE_MUSIC("PartCombineMusic");
1120                 p->set_mus_property ("what", scm_string_to_symbol ($2));
1121                 p->set_mus_property ("elements", gh_list ($3->self_scm (),$4->self_scm (), SCM_UNDEFINED));
1122
1123                 scm_gc_unprotect_object ($3->self_scm ());
1124                 scm_gc_unprotect_object ($4->self_scm ());
1125
1126                 $$ = p;
1127         }
1128         | NEWPARTCOMBINE Music Music {
1129                 static SCM proc;
1130                 if (!proc)
1131                         proc = scm_c_eval_string ("make-new-part-combine-music");
1132
1133                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
1134                         $3->self_scm (), SCM_UNDEFINED));
1135                 scm_gc_unprotect_object ($3->self_scm ());
1136                 scm_gc_unprotect_object ($2->self_scm ());
1137                 $$ = unsmob_music (res);
1138                 scm_gc_protect_object (res);
1139         }
1140         ;
1141
1142 context_change:
1143         CHANGE STRING '=' STRING  {
1144                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1145                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1146                 t-> set_mus_property ("change-to-id", $4);
1147
1148                 $$ = t;
1149                 $$->set_spot (THIS->here_input ());
1150         }
1151         ;
1152
1153 property_operation:
1154         STRING '='  scalar {
1155                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1156                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1157         }
1158         | STRING UNSET {
1159                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1160                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1161         }
1162         | STRING SET embedded_scm '=' embedded_scm {
1163                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1164                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1165         }
1166         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1167                 $$ = scm_list_n (ly_symbol2scm ("push"),
1168                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1169         }
1170         | STRING REVERT embedded_scm {
1171                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1172                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1173         }
1174         ;
1175
1176 translator_mod:
1177         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1178         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1179         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1180
1181         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1182         | DENIES { $$ = ly_symbol2scm ("denies"); }
1183
1184         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1185         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1186         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1187         | NAME { $$ = ly_symbol2scm ("context-name"); }
1188         ;
1189
1190 context_mod:
1191         property_operation { $$ = $1; }
1192         | translator_mod STRING {
1193                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1194         }
1195         ;
1196
1197 music_property_def:
1198         PROPERTY STRING '.' property_operation {
1199                 Music * t = property_op_to_music ($4);
1200                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1201
1202                 csm->set_mus_property ("element", t->self_scm ());
1203                 scm_gc_unprotect_object (t->self_scm ());
1204
1205                 $$ = csm;
1206                 $$->set_spot (THIS->here_input ());
1207
1208                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1209         }
1210         | ONCE music_property_def {
1211                 $$ = $2;
1212                 SCM e = $2->get_mus_property ("element");
1213                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1214         }
1215         ;
1216
1217
1218 scalar:
1219         string          { $$ = $1; }
1220         | bare_int      { $$ = gh_int2scm ($1); }
1221         | embedded_scm  { $$ = $1; }
1222         | full_markup {  $$ = $1; }
1223         | DIGIT { $$ = gh_int2scm ($1); }
1224         ;
1225
1226 /*
1227 This is a trick:
1228
1229 Adding pre_events to the simple_element
1230 makes the choice between
1231
1232   string:  STRING
1233
1234 and
1235
1236   simple_element: STRING
1237
1238 a single shift/reduction conflict.
1239
1240 nevertheless, this is not very clean, and we should find a different
1241 solution.
1242
1243 */
1244 pre_events: {
1245                 THIS->push_spot ();
1246         }
1247         ;
1248
1249 event_chord:
1250         pre_events simple_element post_events   {
1251                 SCM elts = $2-> get_mus_property ("elements");
1252
1253                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1254
1255                 $2->set_mus_property ("elements", elts);
1256                 $$ = $2;
1257         }
1258         | command_element
1259         | note_chord_element
1260         ;
1261
1262
1263 note_chord_element:
1264         chord_body optional_notemode_duration post_events
1265         {
1266                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1267                 SCM es = $1->get_mus_property ("elements");
1268                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1269
1270                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1271                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1272                 es = gh_append2 (es, postevs);
1273
1274                 $1-> set_mus_property ("elements", es);
1275                 $$ = $1;
1276         }
1277         ;
1278
1279 chord_open: '<'
1280         ;
1281
1282 chord_close: '>'
1283         ;
1284
1285 simul_open: LESSLESS
1286         ;
1287
1288 simul_close: MOREMORE
1289         ;
1290
1291 chord_body:
1292         chord_open chord_body_elements chord_close
1293         {
1294                 $$ = MY_MAKE_MUSIC("EventChord");
1295                 $$->set_mus_property ("elements",
1296                         scm_reverse_x ($2, SCM_EOL));
1297         }
1298         ;
1299
1300 chord_body_elements:
1301         /* empty */             { $$ = SCM_EOL; }
1302         | chord_body_elements chord_body_element {
1303                 $$ = gh_cons ($2->self_scm(), $1);
1304                 scm_gc_unprotect_object ($2->self_scm());
1305         }
1306         ;
1307
1308 chord_body_element:
1309         pitch exclamations questions post_events
1310         {
1311                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1312                 n->set_mus_property ("pitch", $1);
1313                 if ($3 % 2)
1314                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1315                 if ($2 % 2 || $3 % 2)
1316                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1317
1318                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1319                 n->set_mus_property ("articulations", arts);
1320
1321                 $$ = n;
1322         }
1323         ;
1324
1325 command_element:
1326         command_req {
1327                 $$ = MY_MAKE_MUSIC("EventChord");
1328                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1329                 scm_gc_unprotect_object ($1->self_scm());
1330
1331                 $$-> set_spot (THIS->here_input ());
1332                 $1-> set_spot (THIS->here_input ());
1333         }
1334         | OCTAVE { THIS->push_spot (); }
1335           pitch {
1336                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1337                 $$ = l;
1338                 $$->set_spot (THIS->pop_spot ());
1339                 $$->set_mus_property ("pitch", $3);
1340         }
1341         | E_LEFTSQUARE {
1342                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1343                 l->set_mus_property ("span-direction", gh_int2scm (START));
1344                 l->set_spot (THIS->here_input ());
1345
1346                 $$ = MY_MAKE_MUSIC("EventChord");
1347                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1348                 scm_gc_unprotect_object (l->self_scm());
1349                 $$->set_spot (THIS->here_input ());
1350         }
1351         | E_RIGHTSQUARE {
1352                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1353                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1354                 l->set_spot (THIS->here_input ());
1355
1356                 $$ = MY_MAKE_MUSIC("EventChord");
1357                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1358                 $$->set_spot (THIS->here_input ());
1359                 scm_gc_unprotect_object (l->self_scm());
1360         }
1361         | E_BACKSLASH {
1362                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1363                 $$->set_spot (THIS->here_input ());
1364         }
1365         | '|'      {
1366
1367                 $$ = MY_MAKE_MUSIC("BarCheck");
1368                 $$->set_spot (THIS->here_input ());
1369         }
1370         | BAR STRING                    {
1371                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1372
1373                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1374                 csm->set_mus_property ("element", t->self_scm ());
1375                 scm_gc_unprotect_object (t->self_scm ());
1376
1377                 $$ = csm;
1378                 $$->set_spot (THIS->here_input ());
1379
1380                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1381         }
1382         | PARTIAL duration_length       {
1383                 Moment m = - unsmob_duration ($2)->get_length ();
1384                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1385
1386                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1387                 sp->set_mus_property ("element", p->self_scm ());
1388                 scm_gc_unprotect_object (p->self_scm ());
1389
1390                 $$ =sp ;
1391                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1392         }
1393         | CLEF STRING  {
1394                 static SCM proc ;
1395                 if (!proc)
1396                         proc = scm_c_eval_string ("make-clef-set");
1397
1398                 SCM result = scm_call_1 (proc, $2);
1399                 scm_gc_protect_object (result);
1400                 $$ = unsmob_music (result);
1401         }
1402         | TIME_T fraction  {
1403                 static SCM proc;
1404                 if (!proc)
1405                         proc = scm_c_eval_string ("make-time-signature-set");
1406
1407                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1408                 scm_gc_protect_object (result);
1409                 $$ = unsmob_music (result);
1410         }
1411         | MARK scalar {
1412                 static SCM proc;
1413                 if (!proc)
1414                         proc = scm_c_eval_string ("make-mark-set");
1415
1416                 SCM result = scm_call_1 (proc, $2);
1417                 scm_gc_protect_object (result);
1418                 $$ = unsmob_music (result);
1419         }
1420         ;
1421
1422 command_req:
1423         shorthand_command_req   { $$ = $1; }
1424         | verbose_command_req   { $$ = $1; }
1425         ;
1426
1427 shorthand_command_req:
1428         hyphen_req {
1429                 $$ = $1;
1430         }
1431         | BREATHE {
1432                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1433         }
1434         | E_TILDE {
1435                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1436         }
1437         ;
1438
1439 verbose_command_req:
1440         MARK DEFAULT  {
1441                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1442                 $$ = m;
1443         }
1444
1445         | SKIP duration_length {
1446                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1447                 skip->set_mus_property ("duration", $2);
1448
1449                 $$ = skip;
1450         }
1451         | tempo_event {
1452                 $$ = $1;
1453         }
1454         | KEY DEFAULT {
1455                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1456                 $$ = key;
1457         }
1458         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1459
1460                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1461                 if (scm_ilength ($3) > 0)
1462                 {
1463                         key->set_mus_property ("pitch-alist", $3);
1464                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1465                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1466                 } else {
1467                         THIS->parser_error (_("Second argument must be pitch list."));
1468                 }
1469
1470                 $$ = key;
1471         }
1472         ;
1473
1474 post_events:
1475         /* empty */ {
1476                 $$ = SCM_EOL;
1477         }
1478         | post_events post_event {
1479                 $2->set_spot (THIS->here_input ());
1480                 $$ = gh_cons ($2->self_scm(), $$);
1481                 scm_gc_unprotect_object ($2->self_scm());
1482         }
1483         | post_events tagged_post_event {
1484                 $2 -> set_spot (THIS->here_input ());
1485                 $$ = scm_cons ($2->self_scm(), $$);
1486                 scm_gc_unprotect_object ($2->self_scm());
1487         }
1488         ;
1489
1490
1491 tagged_post_event:
1492         '-' TAG embedded_scm post_event {
1493                 tag_music ($4, $3, THIS->here_input ());
1494                 $$ = $4;
1495         }
1496         ;
1497
1498 post_event:
1499         direction_less_event {
1500                 $$ = $1;
1501         }
1502         | EXTENDER {
1503                 if (!THIS->lexer_->lyric_state_b ())
1504                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1505                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1506         }
1507         | script_dir direction_reqd_event {
1508                 if ($1)
1509                         $2->set_mus_property ("direction", gh_int2scm ($1));
1510                 $$ = $2;
1511         }
1512         | script_dir direction_less_event {
1513                 if ($1)
1514                         $2->set_mus_property ("direction", gh_int2scm ($1));
1515                 $$ = $2;
1516         }
1517         | string_number_event
1518         ;
1519
1520 string_number_event:
1521         E_UNSIGNED {
1522                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1523                 s->set_mus_property ("string-number",  gh_int2scm($1));
1524                 s->set_spot (THIS->here_input ());
1525                 $$ = s;
1526         }
1527         ;
1528
1529
1530 direction_less_event:
1531         '['  {
1532
1533
1534 /*
1535
1536 TODO: should take all these defs out of the parser, adn make use
1537 configurable, i.e.
1538
1539
1540 (set-articulation '~ "trill")
1541
1542 */
1543                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1544                 m->set_spot (THIS->here_input());
1545                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1546                 $$ = m;
1547         }
1548         | ']'  {
1549                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1550                 m->set_spot (THIS->here_input());
1551                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1552                 $$ = m;
1553         }
1554         | '~' {
1555                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1556                 m->set_spot (THIS->here_input());
1557                 $$ = m;
1558         }
1559         | close_event {
1560                 $$ = $1;
1561                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1562                         gh_int2scm (START));
1563         }
1564         | open_event {
1565                 $$ = $1;
1566                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1567                         gh_int2scm (STOP));
1568         }
1569         | EVENT_IDENTIFIER      {
1570                 $$ = unsmob_music ($1);
1571         }
1572         | tremolo_type  {
1573                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1574                a->set_spot (THIS->here_input ());
1575                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1576                $$ = a;
1577         }
1578         ;
1579
1580 direction_reqd_event:
1581         gen_text_def {
1582                 $$ = $1;
1583         }
1584         | script_abbreviation {
1585                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1586                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1587                 if (gh_string_p (s))
1588                         a->set_mus_property ("articulation-type", s);
1589                 else THIS->parser_error (_ ("Expecting string as script definition"));
1590                 $$ = a;
1591         }
1592         ;
1593
1594 oct_check:
1595         /**/ { $$ = SCM_EOL; }
1596         | '='  { $$ = gh_int2scm (0); }
1597         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1598         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1599         ;
1600
1601 sup_quotes:
1602         '\'' {
1603                 $$ = 1;
1604         }
1605         | sup_quotes '\'' {
1606                 $$ ++;
1607         }
1608         ;
1609
1610 sub_quotes:
1611         ',' {
1612                 $$ = 1;
1613         }
1614         | sub_quotes ',' {
1615                 $$ ++ ;
1616         }
1617         ;
1618
1619 steno_pitch:
1620         NOTENAME_PITCH  {
1621                 $$ = $1;
1622         }
1623         | NOTENAME_PITCH sup_quotes     {
1624                 Pitch p = *unsmob_pitch ($1);
1625                 p = p.transposed (Pitch ($2,0,0));
1626                 $$ = p.smobbed_copy ();
1627         }
1628         | NOTENAME_PITCH sub_quotes      {
1629                 Pitch p =* unsmob_pitch ($1);
1630                 p = p.transposed (Pitch (-$2,0,0));
1631                 $$ = p.smobbed_copy ();
1632         }
1633         ;
1634
1635 /*
1636 ugh. duplication
1637 */
1638
1639 steno_tonic_pitch:
1640         TONICNAME_PITCH {
1641                 $$ = $1;
1642         }
1643         | TONICNAME_PITCH sup_quotes    {
1644                 Pitch p = *unsmob_pitch ($1);
1645                 p = p.transposed (Pitch ($2,0,0));
1646                 $$ = p.smobbed_copy ();
1647         }
1648         | TONICNAME_PITCH sub_quotes     {
1649                 Pitch p =* unsmob_pitch ($1);
1650
1651                 p = p.transposed (Pitch (-$2,0,0));
1652                 $$ = p.smobbed_copy ();
1653         }
1654         ;
1655
1656 pitch:
1657         steno_pitch {
1658                 $$ = $1;
1659         }
1660         ;
1661
1662 pitch_also_in_chords:
1663         pitch
1664         | steno_tonic_pitch
1665         ;
1666
1667 hyphen_req:
1668         HYPHEN {
1669                 if (!THIS->lexer_->lyric_state_b ())
1670                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1671                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1672         }
1673         ;
1674
1675 close_event:
1676         '('     {
1677                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1678                 $$ = s;
1679                 s->set_spot (THIS->here_input());
1680         }
1681         | E_OPEN        {
1682                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1683                 $$ = s;
1684                 s->set_spot (THIS->here_input());
1685         }
1686         | E_SMALLER {
1687                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1688                 $$ = s;
1689                 s->set_spot (THIS->here_input());
1690         }
1691         | E_BIGGER {
1692                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1693                 $$ = s;
1694                 s->set_spot (THIS->here_input());
1695         }
1696         ;
1697
1698
1699 open_event:
1700         E_EXCLAMATION   {
1701                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1702                 s->set_spot (THIS->here_input());
1703
1704                 $$ = s;
1705         }
1706         | ')'   {
1707                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1708                 $$ = s;
1709                 s->set_spot (THIS->here_input());
1710
1711         }
1712         | E_CLOSE       {
1713                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1714                 $$ = s;
1715                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1716                 s->set_spot (THIS->here_input());
1717         }
1718         ;
1719
1720 gen_text_def:
1721         full_markup {
1722                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1723                 t->set_mus_property ("text", $1);
1724                 t->set_spot (THIS->here_input ());
1725                 $$ = t;
1726         }
1727         | string {
1728                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1729                 t->set_mus_property ("text", make_simple_markup ($1));
1730                 t->set_spot (THIS->here_input ());
1731                 $$ = t;
1732
1733         }
1734         | DIGIT {
1735                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1736                 t->set_mus_property ("digit",  gh_int2scm ($1));
1737                 t->set_spot (THIS->here_input ());
1738                 $$ = t;
1739         }
1740         ;
1741
1742 script_abbreviation:
1743         '^'             {
1744                 $$ = scm_makfrom0str ("Hat");
1745         }
1746         | '+'           {
1747                 $$ = scm_makfrom0str ("Plus");
1748         }
1749         | '-'           {
1750                 $$ = scm_makfrom0str ("Dash");
1751         }
1752         | '|'           {
1753                 $$ = scm_makfrom0str ("Bar");
1754         }
1755         | '>'           {
1756                 $$ = scm_makfrom0str ("Larger");
1757         }
1758         | '.'           {
1759                 $$ = scm_makfrom0str ("Dot");
1760         }
1761         | '_' {
1762                 $$ = scm_makfrom0str ("Underscore");
1763         }
1764         ;
1765
1766 script_dir:
1767         '_'     { $$ = DOWN; }
1768         | '^'   { $$ = UP; }
1769         | '-'   { $$ = CENTER; }
1770         ;
1771
1772
1773 absolute_pitch:
1774         steno_pitch     {
1775                 $$ = $1;
1776         }
1777         ;
1778
1779 duration_length:
1780         multiplied_duration {
1781                 $$ = $1;
1782         }
1783         ;
1784
1785 optional_notemode_duration:
1786         {
1787                 Duration dd = THIS->default_duration_;
1788                 $$ = dd.smobbed_copy ();
1789
1790                 THIS->beam_check ($$);
1791         }
1792         | multiplied_duration   {
1793                 $$ = $1;
1794                 THIS->default_duration_ = *unsmob_duration ($$);
1795
1796                 THIS->beam_check ($$);
1797         }
1798         ;
1799
1800 steno_duration:
1801         bare_unsigned dots              {
1802                 int l = 0;
1803                 if (!is_duration_b ($1))
1804                         THIS->parser_error (_f ("not a duration: %d", $1));
1805                 else
1806                         l =  intlog2 ($1);
1807
1808                 $$ = Duration (l, $2).smobbed_copy ();
1809         }
1810         | DURATION_IDENTIFIER dots      {
1811                 Duration *d =unsmob_duration ($1);
1812                 Duration k (d->duration_log (),d->dot_count () + $2);
1813
1814                 *d = k;
1815                 $$ = $1;
1816         }
1817         ;
1818
1819
1820
1821
1822 multiplied_duration:
1823         steno_duration {
1824                 $$ = $1;
1825         }
1826         | multiplied_duration '*' bare_unsigned {
1827                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1828         }
1829         | multiplied_duration '*' FRACTION {
1830                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1831
1832                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1833         }
1834         ;
1835
1836 fraction:
1837         FRACTION { $$ = $1; }
1838         | UNSIGNED '/' UNSIGNED {
1839                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1840         }
1841         ;
1842
1843 dots:
1844         /* empty */     {
1845                 $$ = 0;
1846         }
1847         | dots '.' {
1848                 $$ ++;
1849         }
1850         ;
1851
1852
1853 tremolo_type:
1854         ':'     {
1855                 $$ =0;
1856         }
1857         | ':' bare_unsigned {
1858                 if (!is_duration_b ($2))
1859                         THIS->parser_error (_f ("not a duration: %d", $2));
1860                 $$ = $2;
1861         }
1862         ;
1863
1864
1865
1866 /*****************************************************************
1867                 BASS FIGURES
1868 *****************************************************************/
1869 bass_number:
1870         DIGIT   {
1871                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1872         }
1873         | UNSIGNED {
1874                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1875         }
1876         | STRING { $$ =  $1; }
1877         ;
1878
1879 bass_mod:
1880         '-'     { $$ = -2; }
1881         | '+'   { $$ = 2; }
1882         | '!'   { $$ = 0; }
1883         ;
1884
1885 bass_figure:
1886         FIGURE_SPACE {
1887                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1888                 $$ = bfr->self_scm();
1889                 scm_gc_unprotect_object ($$);
1890         }
1891         | bass_number  {
1892                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1893                 $$ = bfr->self_scm();
1894
1895                 bfr->set_mus_property ("figure", $1);
1896
1897                 scm_gc_unprotect_object ($$);
1898         }
1899         | bass_figure bass_mod {
1900                 Music *m = unsmob_music ($1);
1901                 if ($2) {
1902                         SCM salter =m->get_mus_property ("alteration");
1903                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1904                         m->set_mus_property ("alteration",
1905                                 gh_int2scm (alter + $2));
1906                 } else {
1907                         m->set_mus_property ("alteration", gh_int2scm (0));
1908                 }
1909         }
1910         ;
1911
1912 br_bass_figure:
1913         '[' bass_figure {
1914                 $$ = $2;
1915                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1916         }
1917         | bass_figure   {
1918                 $$ = $1;
1919         }
1920         | br_bass_figure ']' {
1921                 $$ = $1;
1922                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1923         }
1924         ;
1925
1926 figure_list:
1927         /**/            {
1928                 $$ = SCM_EOL;
1929         }
1930         | figure_list br_bass_figure {
1931                 $$ = scm_cons ($2, $1);
1932         }
1933         ;
1934
1935 figure_spec:
1936         FIGURE_OPEN figure_list FIGURE_CLOSE {
1937                 Music * m = MY_MAKE_MUSIC("EventChord");
1938                 $2 = scm_reverse_x ($2, SCM_EOL);
1939                 m->set_mus_property ("elements",  $2);
1940                 $$ = m->self_scm ();
1941         }
1942         ;
1943
1944
1945 optional_rest:
1946         /**/   { $$ = 0; }
1947         | REST { $$ = 1; }
1948         ;
1949
1950 simple_element:
1951         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1952
1953                 Input i = THIS->pop_spot ();
1954                 if (!THIS->lexer_->note_state_b ())
1955                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1956
1957                 Music *n = 0;
1958                 if ($6)
1959                         n =  MY_MAKE_MUSIC("RestEvent");
1960                 else
1961                         n =  MY_MAKE_MUSIC("NoteEvent");
1962
1963                 n->set_mus_property ("pitch", $1);
1964                 n->set_mus_property ("duration", $5);
1965
1966                 if (gh_number_p ($4))
1967                 {
1968                         int q = gh_scm2int ($4);
1969                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1970                 }
1971
1972                 if ($3 % 2)
1973                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1974                 if ($2 % 2 || $3 % 2)
1975                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1976
1977                 Music *v = MY_MAKE_MUSIC("EventChord");
1978                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1979                 scm_gc_unprotect_object (n->self_scm());
1980
1981                 v->set_spot (i);
1982                 n->set_spot (i);
1983                 $$ = v;
1984         }
1985         | figure_spec optional_notemode_duration {
1986                 Music * m = unsmob_music ($1);
1987                 Input i = THIS->pop_spot ();
1988                 m->set_spot (i);
1989                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1990                 {
1991                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1992                 }
1993                 $$ = m;
1994         }
1995         | RESTNAME optional_notemode_duration           {
1996
1997                 Input i = THIS->pop_spot ();
1998                 Music * ev = 0;
1999                 if (ly_scm2string ($1) =="s") {
2000                         /* Space */
2001                         ev = MY_MAKE_MUSIC("SkipEvent");
2002                   }
2003                 else {
2004                         ev = MY_MAKE_MUSIC("RestEvent");
2005
2006                     }
2007                 ev->set_mus_property ("duration" ,$2);
2008                 ev->set_spot (i);
2009                 Music * velt = MY_MAKE_MUSIC("EventChord");
2010                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2011                 velt->set_spot (i);
2012
2013                 scm_gc_unprotect_object (ev->self_scm());
2014
2015                 $$ = velt;
2016         }
2017         | MULTI_MEASURE_REST optional_notemode_duration         {
2018                 THIS->pop_spot ();
2019
2020                 static SCM proc ;
2021                 if (!proc)
2022                         proc = scm_c_eval_string ("make-multi-measure-rest");
2023
2024                 SCM mus = scm_call_2 (proc, $2,
2025                         make_input (THIS->here_input()));
2026                 scm_gc_protect_object (mus);
2027                 $$ = unsmob_music (mus);
2028         }
2029
2030         | lyric_element optional_notemode_duration      {
2031                 Input i = THIS->pop_spot ();
2032                 if (!THIS->lexer_->lyric_state_b ())
2033                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2034
2035                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2036                 lreq->set_mus_property ("text", $1);
2037                 lreq->set_mus_property ("duration",$2);
2038                 lreq->set_spot (i);
2039                 Music * velt = MY_MAKE_MUSIC("EventChord");
2040                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2041
2042                 $$= velt;
2043         }
2044         | new_chord {
2045                 THIS->pop_spot ();
2046
2047                 if (!THIS->lexer_->chord_state_b ())
2048                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2049                 $$ = unsmob_music ($1);
2050         }
2051         ;
2052
2053 lyric_element:
2054         full_markup { $$ = $1; }
2055         | STRING {  $$ = $1 ; }
2056         ;
2057
2058 new_chord:
2059         steno_tonic_pitch optional_notemode_duration   {
2060                 $$ = make_chord ($1, $2, SCM_EOL);
2061         }
2062         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2063                 SCM its = scm_reverse_x ($4, SCM_EOL);
2064                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2065         }
2066         ;
2067
2068 chord_items:
2069         /**/ {
2070                 $$ = SCM_EOL;
2071         }
2072         | chord_items chord_item {
2073                 $$ = gh_cons ($2, $$);
2074         }
2075         ;
2076
2077 chord_separator:
2078         CHORD_COLON {
2079                 $$ = ly_symbol2scm ("chord-colon");
2080         }
2081         | CHORD_CARET {
2082                 $$ = ly_symbol2scm ("chord-caret");
2083         }
2084         | CHORD_SLASH steno_tonic_pitch {
2085                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2086         }
2087         | CHORD_BASS steno_tonic_pitch {
2088                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2089         }
2090         ;
2091
2092 chord_item:
2093         chord_separator {
2094                 $$ = $1;
2095         }
2096         | step_numbers {
2097                 $$ = scm_reverse_x ($1, SCM_EOL);
2098         }
2099         | CHORD_MODIFIER  {
2100                 $$ = $1;
2101         }
2102         ;
2103
2104 step_numbers:
2105         step_number { $$ = gh_cons ($1, SCM_EOL); }
2106         | step_numbers '.' step_number {
2107                 $$ = gh_cons ($3, $$);
2108         }
2109         ;
2110
2111 step_number:
2112         bare_unsigned {
2113                 $$ = make_chord_step ($1, 0);
2114         }
2115         | bare_unsigned '+' {
2116                 $$ = make_chord_step ($1, SHARP);
2117         }
2118         | bare_unsigned CHORD_MINUS {
2119                 $$ = make_chord_step ($1, FLAT);
2120         }
2121         ;
2122
2123 /*
2124         UTILITIES
2125
2126 TODO: should deprecate in favor of Scheme?
2127
2128  */
2129 number_expression:
2130         number_expression '+' number_term {
2131                 $$ = scm_sum ($1, $3);
2132         }
2133         | number_expression '-' number_term {
2134                 $$ = scm_difference ($1, $3);
2135         }
2136         | number_term
2137         ;
2138
2139 number_term:
2140         number_factor {
2141                 $$ = $1;
2142         }
2143         | number_factor '*' number_factor {
2144                 $$ = scm_product ($1, $3);
2145         }
2146         | number_factor '/' number_factor {
2147                 $$ = scm_divide ($1, $3);
2148         }
2149         ;
2150
2151 number_factor:
2152         '-'  number_factor { /* %prec UNARY_MINUS */
2153                 $$ = scm_difference ($2, SCM_UNDEFINED);
2154         }
2155         | bare_number
2156         ;
2157
2158
2159 bare_number:
2160         UNSIGNED        {
2161                 $$ = gh_int2scm ($1);
2162         }
2163         | REAL          {
2164                 $$ = $1;
2165         }
2166         | NUMBER_IDENTIFIER             {
2167                 $$ = $1;
2168         }
2169         | REAL NUMBER_IDENTIFIER        {
2170                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2171         }
2172         | UNSIGNED NUMBER_IDENTIFIER    {
2173                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2174         }
2175         ;
2176
2177
2178 bare_unsigned:
2179         UNSIGNED {
2180                         $$ = $1;
2181         }
2182         | DIGIT {
2183                 $$ = $1;
2184         }
2185         ;
2186
2187 bare_int:
2188         bare_number {
2189                 if (scm_integer_p ($1) == SCM_BOOL_T)
2190                 {
2191                         int k = gh_scm2int ($1);
2192                         $$ = k;
2193                 } else
2194                 {
2195                         THIS->parser_error (_ ("need integer number arg"));
2196                         $$ = 0;
2197                 }
2198         }
2199         | '-' bare_int {
2200                 $$ = -$2;
2201         }
2202         ;
2203
2204
2205 string:
2206         STRING          {
2207                 $$ = $1;
2208         }
2209         | STRING_IDENTIFIER     {
2210                 $$ = $1;
2211         }
2212         | string '+' string {
2213                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2214         }
2215         ;
2216
2217
2218 exclamations:
2219                 { $$ = 0; }
2220         | exclamations '!'      { $$ ++; }
2221         ;
2222
2223 questions:
2224                 { $$ = 0; }
2225         | questions '?' { $$ ++; }
2226         ;
2227
2228
2229
2230 full_markup:
2231         MARKUP_IDENTIFIER {
2232                 $$ = $1;
2233         }
2234         | MARKUP
2235                 { THIS->lexer_->push_markup_state (); }
2236         markup
2237                 { $$ = $3;
2238                   THIS->lexer_->pop_state ();
2239                 }
2240         ;
2241
2242
2243 /*
2244 This should be done more dynamically if possible.
2245 */
2246 markup:
2247         STRING {
2248                 $$ = make_simple_markup ($1);
2249         }
2250         | MARKUP_HEAD_EMPTY {
2251                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2252         }
2253         | MARKUP_HEAD_MARKUP0 markup {
2254                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2255         }
2256         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2257                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2258         }
2259         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2260                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2261         }
2262         | markup_line {
2263                 $$ = $1;
2264         }
2265         | MARKUP_HEAD_LIST0 markup_list {
2266                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2267         }
2268         | MARKUP_HEAD_SCM0 embedded_scm {
2269                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2270         }
2271         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2272                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2273         }
2274         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2275                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2276         }
2277         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2278                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2279         }
2280         | MARKUP_IDENTIFIER {
2281                 $$ = $1;
2282         }
2283
2284         ;
2285
2286 markup_list:
2287         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2288         ;
2289
2290 markup_line:
2291         '{' markup_list_body '}' {
2292                 static SCM line ;
2293                 if (!line)
2294                         line = scm_c_eval_string ("line-markup");
2295
2296                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2297         }
2298         ;
2299
2300 markup_list_body:
2301         /**/ {  $$ = SCM_EOL; }
2302         | markup_list_body markup {
2303                 $$ = gh_cons ($2, $1) ;
2304         }
2305         ;
2306
2307
2308 %%
2309
2310 void
2311 My_lily_parser::set_yydebug (bool )
2312 {
2313 #if 0
2314         yydebug = 1;
2315 #endif
2316 }
2317
2318 extern My_lily_parser * current_parser;
2319
2320 void
2321 My_lily_parser::do_yyparse ()
2322 {
2323         current_parser = this;;
2324         yyparse ((void*)this);
2325 }
2326
2327
2328 /*
2329 Should make this optional?    It will also complain when you do
2330
2331         [s4]
2332
2333 which is entirely legitimate.
2334
2335 Or we can scrap it. Barchecks should detect wrong durations, and
2336 skipTypesetting speeds it up a lot.
2337 */
2338
2339 void
2340 My_lily_parser::beam_check (SCM dur)
2341 {
2342   Duration *d = unsmob_duration (dur);
2343   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2344     {
2345       Music * m = unsmob_music (last_beam_start_);
2346       m->origin ()->warning (_("Suspect duration found following this beam"));
2347     }
2348   last_beam_start_ = SCM_EOL;
2349 }
2350
2351
2352
2353
2354 /*
2355
2356 It is a little strange to have this function in this file, but
2357 otherwise, we have to import music classes into the lexer.
2358
2359 */
2360 int
2361 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2362 {
2363         if (gh_string_p (sid)) {
2364                 *destination = sid;
2365                 return STRING_IDENTIFIER;
2366         } else if (gh_number_p (sid)) {
2367                 *destination = sid;
2368                 return NUMBER_IDENTIFIER;
2369         } else if (unsmob_context_def (sid)) {
2370                 *destination = unsmob_context_def (sid)->clone_scm();
2371                 return TRANSLATOR_IDENTIFIER;
2372         } else if (unsmob_score (sid)) {
2373                 Score *sc =  new Score (*unsmob_score (sid));
2374                 *destination =sc->self_scm ();
2375                 return SCORE_IDENTIFIER;
2376         } else if (Music * mus =unsmob_music (sid)) {
2377                 *destination = unsmob_music (sid)->clone ()->self_scm();
2378                 unsmob_music (*destination)->
2379                         set_mus_property ("origin", make_input (last_input_));
2380                 return dynamic_cast<Event*> (mus)
2381                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2382         } else if (unsmob_duration (sid)) {
2383                 *destination = unsmob_duration (sid)->smobbed_copy();
2384                 return DURATION_IDENTIFIER;
2385         } else if (unsmob_music_output_def (sid)) {
2386                 Music_output_def *p = unsmob_music_output_def (sid);
2387                 p = p->clone ();
2388
2389                 *destination = p->self_scm();
2390                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2391         } else if (Text_item::markup_p (sid)) {
2392                 *destination = sid;
2393                 return MARKUP_IDENTIFIER;
2394         }
2395
2396         return -1;
2397 }
2398
2399 Music *
2400 property_op_to_music (SCM op)
2401 {
2402         Music * m = 0;
2403         SCM tag = gh_car (op);
2404         SCM symbol  = gh_cadr (op);
2405         SCM args = gh_cddr (op);
2406         SCM grob_val = SCM_UNDEFINED;
2407         SCM grob_sym = SCM_UNDEFINED;
2408         SCM val = SCM_UNDEFINED;
2409
2410         if (tag == ly_symbol2scm ("assign"))
2411                 {
2412                 m =  MY_MAKE_MUSIC("PropertySet");
2413                 val = gh_car (args);
2414                 }
2415         else if (tag == ly_symbol2scm ("unset"))
2416                 m =  MY_MAKE_MUSIC("PropertyUnset");
2417         else if (tag == ly_symbol2scm ("poppush")
2418                  || tag == ly_symbol2scm ("push"))
2419                 {
2420                 m  = MY_MAKE_MUSIC("OverrideProperty");
2421                 grob_sym = gh_car (args);
2422                 grob_val = gh_cadr (args);
2423                 }
2424         else if (tag == ly_symbol2scm ("pop")) {
2425                 m = MY_MAKE_MUSIC("RevertProperty");
2426                 grob_sym = gh_car (args);
2427                 }
2428
2429         m->set_mus_property ("symbol", symbol);
2430
2431         if (val != SCM_UNDEFINED)
2432                 m->set_mus_property ("value", val);
2433         if (grob_val != SCM_UNDEFINED)
2434                 m->set_mus_property ("grob-value", grob_val);
2435
2436         if (grob_sym != SCM_UNDEFINED)
2437                 {
2438                 bool itc = internal_type_checking_global_b;
2439                 /* UGH.
2440                 */
2441                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2442                 if (autobeam)
2443                         internal_type_checking_global_b = false;
2444                 m->set_mus_property ("grob-property", grob_sym);
2445                 if (autobeam)
2446                         internal_type_checking_global_b = itc;
2447                 }
2448
2449         if (op == ly_symbol2scm ("poppush"))
2450                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2451
2452
2453         return m;
2454 }
2455
2456 Music*
2457 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2458 {
2459         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2460
2461         csm->set_mus_property ("element", m->self_scm ());
2462         scm_gc_unprotect_object (m->self_scm ());
2463
2464         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2465         csm->set_mus_property ("property-operations", ops);
2466
2467         if (gh_string_p (id))
2468                 csm->set_mus_property ("context-id", id);
2469         return csm;
2470 }
2471
2472
2473 SCM
2474 get_next_unique_context ()
2475 {
2476         static int new_context_count;
2477
2478         char s[1024];
2479         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2480
2481         return scm_makfrom0str (s);
2482 }