lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2003 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "auto-change-iterator.hh"
  78 #include "ly-modules.hh"
  79 #include "music-sequence.hh"
  80 #include "input-smob.hh"
  81 #include "event.hh"
  82 #include "text-item.hh"
  83 #include "music-list.hh"
  84
  85 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  86
  87 Music *property_op_to_music (SCM op);
  88 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  89 SCM get_next_unique_context ();
  90
  91 #define YYERROR_VERBOSE 1
  92
  93 My_lily_parser* my_lily_parser;
  94 #define YYPARSE_PARAM my_lily_parser
  95 #define YYLEX_PARAM my_lily_parser
  96 #define THIS\
  97         ((My_lily_parser *) my_lily_parser)
  98
  99 #define yyerror THIS->parser_error
 100
 101 /*
 102   Add symbols to the  TAGS field of a music object.
 103 */
 104
 105 void
 106 tag_music (Music*m,  SCM tag, Input ip)
 107 {
 108         SCM tags = m->get_mus_property ("tags");
 109         if (gh_symbol_p (tag))
 110                 tags = scm_cons (tag, tags);
 111         else if (gh_list_p (tag))
 112                 tags = gh_append2 (tag, tags);
 113         else
 114                 ip.warning (_("Tag must be symbol or list of symbols."));
 115
 116         m->set_mus_property ("tags", tags);
 117 }
 118
 119
 120
 121 bool
 122 regular_identifier_b (SCM id)
 123 {
 124   String str = ly_scm2string (id);
 125   char const *s = str.to_str0 () ;
 126
 127   bool v = true;
 128   while (*s && v)
 129    {
 130         v = v && isalpha (*s);
 131         s++;
 132    }
 133   return v;
 134 }
 135
 136 SCM
 137 make_simple_markup (SCM a)
 138 {
 139         static SCM simple;
 140         if (!simple)
 141         simple = scm_c_eval_string ("simple-markup");
 142
 143         return scm_list_n (simple, a, SCM_UNDEFINED);
 144 }
 145
 146
 147 bool
 148 is_duration_b (int t)
 149 {
 150   return t && t == 1 << intlog2 (t);
 151 }
 152
 153 void
 154 set_music_properties (Music *p, SCM a)
 155 {
 156   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 157         {
 158         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 159         }
 160 }
 161
 162 SCM
 163 make_chord_step (int step, int alter)
 164 {
 165         if (step == 7)
 166                 alter += FLAT;
 167
 168         while(step < 0)
 169                 step += 7;
 170         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 171         return m.smobbed_copy ();
 172 }
 173
 174
 175 SCM
 176 make_chord (SCM pitch, SCM dur, SCM modification_list)
 177 {
 178         static SCM chord_ctor;
 179         if (!chord_ctor)
 180                 chord_ctor= scm_c_eval_string ("construct-chord");
 181         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 182         scm_gc_protect_object (ch);
 183         return ch;
 184 }
 185
 186 /*
 187   Todo: actually also use apply iso. call too ...
 188 */
 189 bool
 190 ly_input_procedure_p (SCM x)
 191 {
 192         return gh_procedure_p (x)
 193                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 194 }
 195
 196 Music*
 197 set_property_music (SCM sym, SCM value)
 198 {
 199         Music * p = MY_MAKE_MUSIC("PropertySet");
 200         p->set_mus_property ("symbol", sym);
 201         p->set_mus_property ("value", value);
 202         return p;
 203 }
 204
 205 %}
 206
 207 /* We use SCMs to do strings, because it saves us the trouble of
 208 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 209 of the parse stack onto the heap. */
 210
 211
 212 %union {
 213         String * string;
 214     Music *music;
 215     Score *score;
 216     Music_output_def * outputdef;
 217     SCM scm;
 218     int i;
 219 }
 220 %{
 221
 222 int
 223 yylex (YYSTYPE *s,  void * v)
 224 {
 225         My_lily_parser   *pars = (My_lily_parser*) v;
 226         My_lily_lexer * lex = pars->lexer_;
 227
 228         lex->lexval = (void*) s;
 229         lex->prepare_for_next_token();
 230         return lex->yylex ();
 231 }
 232
 233
 234 %}
 235
 236 %pure_parser
 237
 238
 239 %token ACCEPTS
 240 %token ADDLYRICS
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token PARTIAL
 287 %token PITCHNAMES
 288 %token PROPERTY
 289 %token RELATIVE
 290 %token REMOVE
 291 %token REPEAT
 292 %token REST
 293 %token SCM_T
 294 %token SCORE
 295 %token SEQUENTIAL
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSLATOR
 304 %token TRANSPOSE
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 311 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 312 %token E_BACKSLASH
 313 %token <i> E_UNSIGNED
 314 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 315 %token FIGURE_SPACE
 316
 317 %type <i>       exclamations questions dots optional_rest
 318 %type <i>        bass_mod
 319 %type <scm>     grace_head
 320 %type <scm>     oct_check
 321 %type <scm>     context_mod_list
 322 %type <scm>     lyric_element
 323 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 324 %token <i>      DIGIT
 325 %token <scm>    NOTENAME_PITCH
 326 %token <scm>    TONICNAME_PITCH
 327 %token <scm>    CHORDMODIFIER_PITCH
 328 %token <scm>    DURATION_IDENTIFIER
 329 %token <scm>    FRACTION
 330 %token <id>     IDENTIFIER
 331 %token <scm>    CHORDNAMES
 332 %token <scm>    CHORD_MODIFIER
 333 %token <scm>    SCORE_IDENTIFIER
 334 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    RESTNAME
 340 %token <scm>    STRING
 341 %token <scm>    SCM_T
 342 %token <i>      UNSIGNED
 343 %token <scm>   REAL
 344
 345 %token MARKUP
 346 %token <scm> MARKUP_HEAD_MARKUP0
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0
 350 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 357
 358 %type <outputdef> output_def
 359 %type <scm>     lilypond_header lilypond_header_body
 360 %type <music>   open_event close_event
 361 %type <i>       sub_quotes sup_quotes
 362 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 363 %type <music>   Repeated_music
 364 %type <scm>     Alternative_music
 365 %type <i>       tremolo_type
 366 %type <i>       bare_int  bare_unsigned
 367 %type <i>       script_dir
 368 %type <scm>     identifier_init
 369
 370 %type <music> note_chord_element chord_body chord_body_element
 371 %type <scm>  chord_body_elements
 372 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 373
 374 %type <scm>   post_events
 375 %type <music> gen_text_def direction_less_event direction_reqd_event
 376 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 377 %type <scm>    steno_tonic_pitch
 378 %type <scm>     duration_length fraction
 379
 380 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 381
 382 %type <scm>  embedded_scm scalar
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   relative_music re_rhythmed_music part_combined_music
 385 %type <music>   music_property_def context_change
 386 %type <scm> Music_list
 387 %type <scm> property_operation context_mod translator_mod optional_context_mod
 388 %type <outputdef>  music_output_def_body music_output_def_head
 389 %type <music> shorthand_command_req
 390 %type <music>   post_event tagged_post_event
 391 %type <music> command_req verbose_command_req
 392 %type <music> string_number_event
 393 %type <scm>     string bare_number number_expression number_term number_factor
 394 %type <score>   score_block score_body
 395
 396 %type <scm>     translator_spec_block translator_spec_body
 397 %type <music>   tempo_event
 398 %type <scm> notenames_body notenames_block chordmodifiers_block
 399 %type <scm>     script_abbreviation
 400
 401
 402
 403 %left '-' '+'
 404
 405 /* We don't assign precedence to / and *, because we might need varied
 406 prec levels in different prods */
 407
 408 %left UNARY_MINUS
 409
 410 %%
 411
 412 lilypond:       /* empty */
 413         | lilypond toplevel_expression {}
 414         | lilypond assignment  { }
 415         | lilypond error {
 416                 THIS->error_level_  = 1;
 417         }
 418         | lilypond INVALID      {
 419                 THIS->error_level_  = 1;
 420         }
 421         ;
 422
 423 toplevel_expression:
 424         notenames_block                 {
 425                 THIS->lexer_->pitchname_tab_ =  $1;
 426         }
 427         | chordmodifiers_block                  {
 428                 THIS->lexer_->chordmodifier_tab_  = $1;
 429         }
 430         | lilypond_header {
 431                 THIS->input_file_->header_ = $1;
 432         }
 433         | score_block {
 434                 Score * sc = $1;
 435
 436                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 437
 438                 Path p = split_path (THIS->output_basename_);
 439                 int *c =  &THIS->input_file_->score_count_;
 440                 if (*c)
 441                         {
 442                         p.base += "-" + to_string (*c);
 443                         }
 444
 445                 (*c)++;
 446                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 447
 448                 for (int i=0; i < sc->defs_.size (); i++)
 449                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 450
 451                 if (sc->defs_.empty ())
 452                 {
 453                    Music_output_def *id =
 454                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 455                                 ("$defaultpaper"));
 456
 457                    id = id ? id->clone () : new Paper_def;
 458
 459                    default_rendering (sc->music_, id->self_scm(), head, outname);
 460
 461                    scm_gc_unprotect_object (id->self_scm ());
 462                 }
 463                 scm_gc_unprotect_object (sc->self_scm());
 464         }
 465         | output_def {
 466                 SCM id = SCM_EOL;
 467                 if (dynamic_cast<Paper_def*> ($1))
 468                         id = scm_makfrom0str ("$defaultpaper");
 469                 else if (dynamic_cast<Midi_def*> ($1))
 470                         id = scm_makfrom0str ("$defaultmidi");
 471                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 472                 scm_gc_unprotect_object ($1->self_scm ());
 473         }
 474         ;
 475
 476 embedded_scm:
 477         SCM_T
 478         | SCM_IDENTIFIER
 479         ;
 480
 481
 482 chordmodifiers_block:
 483         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 484         ;
 485
 486 notenames_block:
 487         PITCHNAMES notenames_body   {  $$ = $2; }
 488         ;
 489
 490 notenames_body:
 491         embedded_scm    {
 492           int i = scm_ilength ($1);
 493
 494           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 495           for (SCM s = $1; gh_pair_p (s); s = ly_cdr (s)) {
 496                 SCM pt = ly_cdar (s);
 497                 scm_hashq_set_x (tab, ly_caar (s), pt);
 498           }
 499           $$ = tab;
 500         }
 501         ;
 502
 503 lilypond_header_body:
 504         {
 505                 $$ = ly_make_anonymous_module ();
 506                 THIS->lexer_->add_scope ($$);
 507         }
 508         | lilypond_header_body assignment  {
 509
 510         }
 511         ;
 512
 513 lilypond_header:
 514         HEADER '{' lilypond_header_body '}'     {
 515                 $$ = THIS->lexer_-> remove_scope();
 516         }
 517         ;
 518
 519
 520 /*
 521         DECLARATIONS
 522 */
 523 assignment:
 524         STRING {
 525                 THIS->push_spot ();
 526         }
 527         /* cont */ '=' identifier_init  {
 528
 529         /*
 530                 Should find generic way of associating input with objects.
 531         */
 532                 Input ip = THIS->pop_spot ();
 533
 534                 if (! regular_identifier_b ($1))
 535                 {
 536                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 537                 }
 538
 539                 THIS->lexer_->set_identifier ($1, $4);
 540
 541 /*
 542  TODO: devise standard for protection in parser.
 543
 544   The parser stack lives on the C-stack, which means that
 545 all objects can be unprotected as soon as they're here.
 546
 547 */
 548         }
 549         | embedded_scm { }
 550         ;
 551
 552
 553 identifier_init:
 554         score_block {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | full_markup {
 559                 $$ = $1;
 560         }
 561         | output_def {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | translator_spec_block {
 566                 $$ = $1;
 567         }
 568         | Music  {
 569                 $$ = $1->self_scm ();
 570                 scm_gc_unprotect_object ($$);
 571         }
 572         | post_event {
 573                 $$ = $1->self_scm ();
 574                 scm_gc_unprotect_object ($$);
 575         }
 576         | number_expression {
 577                 $$ = $1;
 578         }
 579         | string {
 580                 $$ = $1;
 581         }
 582         | embedded_scm  {
 583                 $$ = $1;
 584         }
 585         ;
 586
 587 translator_spec_block:
 588         TRANSLATOR '{' translator_spec_body '}'
 589                 {
 590                 $$ = $3;
 591         }
 592         ;
 593
 594 translator_spec_body:
 595         /**/ {
 596                 $$ = Context_def::make_scm ();
 597                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 598         }
 599         | TRANSLATOR_IDENTIFIER {
 600                 $$ = $1;
 601                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 602         }
 603         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 604                 Context_def*td = unsmob_context_def($$);
 605
 606                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 607                         SCM tag = gh_caar (p);
 608                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 609                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 610                 }
 611         }
 612         | translator_spec_body context_mod {
 613                 unsmob_context_def ($$)->add_context_mod ($2);
 614         }
 615         ;
 616
 617 /*
 618         SCORE
 619 */
 620 score_block:
 621         SCORE {
 622                 THIS->push_spot ();
 623         }
 624         /*cont*/ '{' score_body '}'     {
 625                 THIS->pop_spot ();
 626                 $$ = $4;
 627
 628         }
 629         ;
 630
 631 score_body:
 632         Music   {
 633                 $$ = new Score;
 634
 635                 $$->set_spot (THIS->here_input ());
 636                 SCM m = $1->self_scm ();
 637                 scm_gc_unprotect_object (m);
 638
 639                 /*
 640                         guh.
 641                 */
 642                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 643                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 644                         m = gh_call1 (gh_car (check_funcs), m);
 645                 $$->music_ = m;
 646
 647         }
 648         | SCORE_IDENTIFIER {
 649                 $$ = new Score ( *unsmob_score ($1));
 650                 $$->set_spot (THIS->here_input ());
 651         }
 652         | score_body lilypond_header    {
 653                 $$->header_ = $2;
 654         }
 655         | score_body output_def {
 656                 $$->defs_.push ($2);
 657                 scm_gc_unprotect_object ($2->self_scm ());
 658         }
 659         | score_body error {
 660
 661         }
 662         ;
 663
 664
 665 /*
 666         MIDI
 667 */
 668 output_def:
 669         music_output_def_body '}' {
 670                 $$ = $1;
 671                 THIS-> lexer_-> remove_scope ();
 672         }
 673         ;
 674
 675 music_output_def_head:
 676         MIDI    {
 677                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 678
 679
 680                 Midi_def* p =0;
 681                 if (id)
 682                         p = dynamic_cast<Midi_def*> (id->clone ());
 683                 else
 684                         p = new Midi_def;
 685
 686                 $$ = p;
 687                 THIS->lexer_->add_scope (p->scope_);
 688         }
 689         | PAPER         {
 690                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 691                   Paper_def *p = 0;
 692                 if (id)
 693                         p = dynamic_cast<Paper_def*> (id->clone ());
 694                 else
 695                         p = new Paper_def;
 696
 697                 THIS->lexer_->add_scope (p->scope_);
 698                 $$ = p;
 699         }
 700         ;
 701
 702
 703 music_output_def_body:
 704         music_output_def_head '{' {
 705
 706         }
 707         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 708                 Music_output_def * o =  unsmob_music_output_def ($3);
 709                 $$ = o;
 710                 THIS->lexer_->remove_scope ();
 711                 THIS->lexer_->add_scope (o->scope_);
 712         }
 713         | music_output_def_body assignment  {
 714
 715         }
 716         | music_output_def_body translator_spec_block   {
 717                 $$->assign_translator ($2);
 718         }
 719         | music_output_def_body tempo_event  {
 720                 /*
 721                         junk this ? there already is tempo stuff in
 722                         music.
 723                 */
 724                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 725                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 726                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 727                 if (md)
 728                         md->set_tempo (d->get_length (), m);
 729                 scm_gc_unprotect_object ($2->self_scm ());
 730         }
 731         | music_output_def_body error {
 732
 733         }
 734         ;
 735
 736 tempo_event:
 737         TEMPO steno_duration '=' bare_unsigned  {
 738                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 739                 $$->set_mus_property ("tempo-unit", $2);
 740                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 741         }
 742         ;
 743
 744 /*
 745 The representation of a  list is the
 746
 747   (LIST . LAST-CONS)
 748
 749  to have  efficient append.
 750 */
 751 Music_list:
 752         /* empty */ {
 753                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 754         }
 755         | Music_list Music {
 756                 SCM s = $$;
 757                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 758                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 759                 if (gh_pair_p (ly_cdr (s)))
 760                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 761                 else
 762                         gh_set_car_x (s, c); /* set first cons */
 763                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 764         }
 765         | Music_list error {
 766         }
 767         ;
 768
 769
 770 Music:
 771         Simple_music
 772         | Composite_music
 773         ;
 774
 775 Alternative_music:
 776         /* empty */ {
 777                 $$ = SCM_EOL;
 778         }
 779         | ALTERNATIVE '{' Music_list '}' {
 780                 $$ = $3;
 781         }
 782         ;
 783
 784 Repeated_music:
 785         REPEAT string bare_unsigned Music Alternative_music
 786         {
 787                 Music *beg = $4;
 788                 int times = $3;
 789                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 790                 if (times < scm_ilength (alts)) {
 791                   unsmob_music (gh_car (alts))
 792                     ->origin ()->warning (
 793                     _("More alternatives than repeats.  Junking excess alternatives."));
 794                   alts = ly_truncate_list (times, alts);
 795                 }
 796
 797
 798                 static SCM proc;
 799                 if (!proc)
 800                         proc = scm_c_eval_string ("make-repeated-music");
 801
 802                 SCM mus = scm_call_1 (proc, $2);
 803                 scm_gc_protect_object (mus); // UGH.
 804                 Music *r =unsmob_music (mus);
 805                 if (beg)
 806                         {
 807                         r-> set_mus_property ("element", beg->self_scm ());
 808                         scm_gc_unprotect_object (beg->self_scm ());
 809                         }
 810                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 811
 812                 r-> set_mus_property ("elements",alts);
 813                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 814                         /*
 815                         we can not get durations and other stuff correct down the line, so we have to
 816                         add to the duration log here.
 817                         */
 818                         static SCM func;
 819
 820                         if (!func)
 821                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 822
 823                         int dots = ($3 % 3) ? 0 : 1;
 824                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 825
 826                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 827
 828                         if (seq) {
 829                                 int list_len =scm_ilength (seq->music_list ());
 830                                 if (list_len != 2)
 831                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 832                                 shift -= 1;
 833                                 r->compress (Moment (Rational (1,list_len)));
 834                                 }
 835                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 836
 837                 }
 838                 r->set_spot (*$4->origin ());
 839
 840                 $$ = r;
 841         }
 842         ;
 843
 844 Sequential_music:
 845         SEQUENTIAL '{' Music_list '}'           {
 846                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 847                 $$->set_mus_property ("elements", ly_car ($3));
 848                 $$->set_spot(THIS->here_input());
 849         }
 850         | '{' Music_list '}'            {
 851                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 852                 $$->set_mus_property ("elements", ly_car ($2));
 853                 $$->set_spot(THIS->here_input());
 854         }
 855         ;
 856
 857 Simultaneous_music:
 858         SIMULTANEOUS '{' Music_list '}'{
 859                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 860                 $$->set_mus_property ("elements", ly_car ($3));
 861                 $$->set_spot(THIS->here_input());
 862
 863         }
 864         | simul_open Music_list simul_close     {
 865                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 866                 $$->set_mus_property ("elements", ly_car ($2));
 867                 $$->set_spot(THIS->here_input());
 868         }
 869         ;
 870
 871 Simple_music:
 872         event_chord             { $$ = $1; }
 873         | APPLYOUTPUT embedded_scm {
 874                 if (!ly_input_procedure_p ($2))
 875                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 876                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 877                 $$->set_mus_property ("procedure", $2);
 878                 $$->set_spot (THIS->here_input());
 879         }
 880         | APPLYCONTEXT embedded_scm {
 881                 if (!ly_input_procedure_p ($2))
 882                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 883                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 884                 $$->set_mus_property ("procedure", $2);
 885                 $$->set_spot (THIS->here_input());
 886         }
 887         | MUSIC_IDENTIFIER {
 888                 $$ = unsmob_music ($1);
 889         }
 890         | music_property_def
 891         | context_change
 892         ;
 893
 894
 895 optional_context_mod:
 896         /**/ { $$ = SCM_EOL; }
 897         | WITH '{' context_mod_list '}'  { $$ = $3; }
 898         ;
 899
 900 grace_head:
 901         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 902         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 903         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 904         ;
 905
 906 context_mod_list:
 907         /* */  { $$ = SCM_EOL; }
 908         | context_mod_list context_mod  {
 909                  $$ = gh_cons ($2, $1);
 910         }
 911         ;
 912
 913 Composite_music:
 914         AUTOCHANGE STRING Music {
 915                 Music*chm = MY_MAKE_MUSIC("AutoChangeMusic");
 916                 chm->set_mus_property ("element", $3->self_scm ());
 917                 chm->set_mus_property ("iterator-ctor", Auto_change_iterator::constructor_proc);
 918
 919                 scm_gc_unprotect_object ($3->self_scm ());
 920                 chm->set_mus_property ("what", scm_string_to_symbol ($2));
 921
 922                 $$ = chm;
 923                 chm->set_spot (*$3->origin ());
 924         }
 925         | grace_head Music {
 926 #if 1
 927         /*
 928                 The other version is for easier debugging  of
 929                 Sequential_music_iterator in combination with grace notes.
 930         */
 931
 932 /*
 933
 934 TODO: should distinguish between both grace types in the
 935 basic music objects too, since the meaning is different.
 936
 937 */
 938
 939                 String start_str = "start" + ly_scm2string ($1) + "Music";
 940                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 941
 942                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 943                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 944
 945                 Music *startm = unsmob_music (start);
 946                 Music *stopm = unsmob_music (stop);
 947
 948                 SCM ms = SCM_EOL;
 949                 if (stopm) {
 950                         stopm = stopm->clone ();
 951                         ms = scm_cons (stopm->self_scm (), ms);
 952                         scm_gc_unprotect_object (stopm->self_scm ());
 953                 }
 954                 ms = scm_cons ($2->self_scm (), ms);
 955                 scm_gc_unprotect_object ($2->self_scm());
 956                 if (startm) {
 957                         startm = startm->clone ();
 958                         ms = scm_cons (startm->self_scm () , ms);
 959                         scm_gc_unprotect_object (startm->self_scm ());
 960                 }
 961
 962
 963                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 964                 seq->set_mus_property ("elements", ms);
 965
 966
 967                 $$ = MY_MAKE_MUSIC("GraceMusic");
 968                 $$->set_mus_property ("element", seq->self_scm ());
 969                 scm_gc_unprotect_object (seq->self_scm ());
 970 #else
 971                 $$ = MY_MAKE_MUSIC("GraceMusic");
 972                 $$->set_mus_property ("element", $2->self_scm ());
 973                 scm_gc_unprotect_object ($2->self_scm ());
 974 #endif
 975         }
 976         | CONTEXT string '=' string optional_context_mod Music {
 977                 $$ = context_spec_music ($2, $4, $6, $5);
 978
 979         }
 980         | CONTEXT STRING optional_context_mod Music {
 981                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 982         }
 983         | NEWCONTEXT string optional_context_mod Music {
 984                 $$ = context_spec_music ($2, get_next_unique_context (),
 985                                          $4, $3);
 986         }
 987
 988         | TIMES {
 989                 THIS->push_spot ();
 990         }
 991         /* CONTINUED */
 992                 fraction Music
 993
 994         {
 995                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 996                 Music *mp = $4;
 997
 998                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 999                 $$->set_spot (THIS->pop_spot ());
1000
1001                 $$->set_mus_property ("element", mp->self_scm ());
1002                 scm_gc_unprotect_object (mp->self_scm ());
1003                 $$->set_mus_property ("numerator", gh_int2scm (n));
1004                 $$->set_mus_property ("denominator", gh_int2scm (d));
1005                 $$->compress (Moment (Rational (n,d)));
1006
1007         }
1008         | Repeated_music                { $$ = $1; }
1009         | Simultaneous_music            { $$ = $1; }
1010         | Sequential_music              { $$ = $1; }
1011         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1012                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1013                 Music *p = $4;
1014                 Pitch from = *unsmob_pitch ($2);
1015                 Pitch to = *unsmob_pitch ($3);
1016
1017                 p->transpose (interval (from, to));
1018                 $$->set_mus_property ("element", p->self_scm ());
1019                 scm_gc_unprotect_object (p->self_scm ());
1020         }
1021         | APPLY embedded_scm Music  {
1022                 if (!ly_input_procedure_p ($2))
1023                         {
1024                         THIS->parser_error (_ ("\\apply takes function argument"));
1025                         $$ = $3;
1026                         }
1027                 else
1028                         {
1029                         SCM ret = gh_call1 ($2, $3->self_scm ());
1030                         Music *m = unsmob_music (ret);
1031                         if (!m) {
1032                                 THIS->parser_error ("\\apply must return a Music");
1033                                 m = MY_MAKE_MUSIC("Music");
1034                                 }
1035                         $$ = m;
1036                         }
1037         }
1038         | NOTES
1039                 { THIS->lexer_->push_note_state (); }
1040         Music
1041                 { $$ = $3;
1042                   THIS->lexer_->pop_state ();
1043                 }
1044         | FIGURES
1045                 { THIS->lexer_->push_figuredbass_state (); }
1046         Music
1047                 {
1048                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1049                   chm->set_mus_property ("element", $3->self_scm ());
1050                   $$ = chm;
1051                   scm_gc_unprotect_object ($3->self_scm());
1052
1053                   THIS->lexer_->pop_state ();
1054         }
1055         | CHORDS
1056                 { THIS->lexer_->push_chord_state (); }
1057         Music
1058                 {
1059                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1060                   chm->set_mus_property ("element", $3->self_scm ());
1061                   scm_gc_unprotect_object ($3->self_scm());
1062                   $$ = chm;
1063
1064                   THIS->lexer_->pop_state ();
1065         }
1066         | LYRICS
1067                 { THIS->lexer_->push_lyric_state (); }
1068         Music
1069                 {
1070                   $$ = $3;
1071                   THIS->lexer_->pop_state ();
1072         }
1073         | relative_music        { $$ = $1; }
1074         | re_rhythmed_music     { $$ = $1; }
1075         | part_combined_music   { $$ = $1; }
1076         | TAG embedded_scm Music {
1077                 tag_music ($3, $2, THIS->here_input ());
1078                 $$ = $3;
1079         }
1080         ;
1081
1082 relative_music:
1083         RELATIVE absolute_pitch Music {
1084                 Music * p = $3;
1085                 Pitch pit = *unsmob_pitch ($2);
1086                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1087
1088                 $$->set_mus_property ("element", p->self_scm ());
1089                 scm_gc_unprotect_object (p->self_scm ());
1090
1091
1092                 Pitch retpitch = p->to_relative_octave (pit);
1093                 if (lily_1_8_relative)
1094                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1095         }
1096         ;
1097
1098 re_rhythmed_music:
1099         ADDLYRICS Music Music {
1100         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1101           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1102           scm_gc_unprotect_object ($3->self_scm ());
1103           scm_gc_unprotect_object ($2->self_scm ());
1104           $$ = l;
1105         }
1106         | NEWADDLYRICS string Music {
1107           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1108           l->set_mus_property ("element", $3->self_scm ());
1109           scm_gc_unprotect_object ($3->self_scm ());
1110           $$ = l;
1111           l->set_mus_property ("associated-context", $2);
1112         }
1113         ;
1114
1115 part_combined_music:
1116         PARTCOMBINE Music Music {
1117                 static SCM proc;
1118                 if (!proc)
1119                         proc = scm_c_eval_string ("make-part-combine-music");
1120
1121                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
1122                         $3->self_scm (), SCM_UNDEFINED));
1123                 scm_gc_unprotect_object ($3->self_scm ());
1124                 scm_gc_unprotect_object ($2->self_scm ());
1125                 $$ = unsmob_music (res);
1126                 scm_gc_protect_object (res);
1127         }
1128         ;
1129
1130 context_change:
1131         CHANGE STRING '=' STRING  {
1132                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1133                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1134                 t-> set_mus_property ("change-to-id", $4);
1135
1136                 $$ = t;
1137                 $$->set_spot (THIS->here_input ());
1138         }
1139         ;
1140
1141 property_operation:
1142         STRING '='  scalar {
1143                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1144                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1145         }
1146         | STRING UNSET {
1147                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1148                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1149         }
1150         | STRING SET embedded_scm '=' embedded_scm {
1151                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1152                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1153         }
1154         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1155                 $$ = scm_list_n (ly_symbol2scm ("push"),
1156                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1157         }
1158         | STRING REVERT embedded_scm {
1159                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1160                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1161         }
1162         ;
1163
1164 translator_mod:
1165         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1166         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1167         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1168
1169         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1170         | DENIES { $$ = ly_symbol2scm ("denies"); }
1171
1172         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1173         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1174         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1175         | NAME { $$ = ly_symbol2scm ("context-name"); }
1176         ;
1177
1178 context_mod:
1179         property_operation { $$ = $1; }
1180         | translator_mod STRING {
1181                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1182         }
1183         ;
1184
1185 music_property_def:
1186         PROPERTY STRING '.' property_operation {
1187                 Music * t = property_op_to_music ($4);
1188                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1189
1190                 csm->set_mus_property ("element", t->self_scm ());
1191                 scm_gc_unprotect_object (t->self_scm ());
1192
1193                 $$ = csm;
1194                 $$->set_spot (THIS->here_input ());
1195
1196                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1197         }
1198         | ONCE music_property_def {
1199                 $$ = $2;
1200                 SCM e = $2->get_mus_property ("element");
1201                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1202         }
1203         ;
1204
1205
1206 scalar:
1207         string          { $$ = $1; }
1208         | bare_int      { $$ = gh_int2scm ($1); }
1209         | embedded_scm  { $$ = $1; }
1210         | full_markup {  $$ = $1; }
1211         | DIGIT { $$ = gh_int2scm ($1); }
1212         ;
1213
1214 /*
1215 This is a trick:
1216
1217 Adding pre_events to the simple_element
1218 makes the choice between
1219
1220   string:  STRING
1221
1222 and
1223
1224   simple_element: STRING
1225
1226 a single shift/reduction conflict.
1227
1228 nevertheless, this is not very clean, and we should find a different
1229 solution.
1230
1231 */
1232 pre_events: {
1233                 THIS->push_spot ();
1234         }
1235         ;
1236
1237 event_chord:
1238         pre_events simple_element post_events   {
1239                 SCM elts = $2-> get_mus_property ("elements");
1240
1241                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1242
1243                 $2->set_mus_property ("elements", elts);
1244                 $$ = $2;
1245         }
1246         | command_element
1247         | note_chord_element
1248         ;
1249
1250
1251 note_chord_element:
1252         chord_body optional_notemode_duration post_events
1253         {
1254                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1255                 SCM es = $1->get_mus_property ("elements");
1256                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1257
1258                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1259                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1260                 es = gh_append2 (es, postevs);
1261
1262                 $1-> set_mus_property ("elements", es);
1263                 $$ = $1;
1264         }
1265         ;
1266
1267 chord_open: '<'
1268         ;
1269
1270 chord_close: '>'
1271         ;
1272
1273 simul_open: LESSLESS
1274         ;
1275
1276 simul_close: MOREMORE
1277         ;
1278
1279 chord_body:
1280         chord_open chord_body_elements chord_close
1281         {
1282                 $$ = MY_MAKE_MUSIC("EventChord");
1283                 $$->set_mus_property ("elements",
1284                         scm_reverse_x ($2, SCM_EOL));
1285         }
1286         ;
1287
1288 chord_body_elements:
1289         /* empty */             { $$ = SCM_EOL; }
1290         | chord_body_elements chord_body_element {
1291                 $$ = gh_cons ($2->self_scm(), $1);
1292                 scm_gc_unprotect_object ($2->self_scm());
1293         }
1294         ;
1295
1296 chord_body_element:
1297         pitch exclamations questions post_events
1298         {
1299                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1300                 n->set_mus_property ("pitch", $1);
1301                 if ($3 % 2)
1302                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1303                 if ($2 % 2 || $3 % 2)
1304                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1305
1306                 SCM arts = scm_reverse_x ($4, SCM_EOL);
1307                 n->set_mus_property ("articulations", arts);
1308
1309                 $$ = n;
1310         }
1311         ;
1312
1313 command_element:
1314         command_req {
1315                 $$ = MY_MAKE_MUSIC("EventChord");
1316                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1317                 scm_gc_unprotect_object ($1->self_scm());
1318
1319                 $$-> set_spot (THIS->here_input ());
1320                 $1-> set_spot (THIS->here_input ());
1321         }
1322         | OCTAVE { THIS->push_spot (); }
1323           pitch {
1324                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1325                 $$ = l;
1326                 $$->set_spot (THIS->pop_spot ());
1327                 $$->set_mus_property ("pitch", $3);
1328         }
1329         | E_LEFTSQUARE {
1330                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1331                 l->set_mus_property ("span-direction", gh_int2scm (START));
1332                 l->set_spot (THIS->here_input ());
1333
1334                 $$ = MY_MAKE_MUSIC("EventChord");
1335                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1336                 scm_gc_unprotect_object (l->self_scm());
1337                 $$->set_spot (THIS->here_input ());
1338         }
1339         | E_RIGHTSQUARE {
1340                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1341                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1342                 l->set_spot (THIS->here_input ());
1343
1344                 $$ = MY_MAKE_MUSIC("EventChord");
1345                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1346                 $$->set_spot (THIS->here_input ());
1347                 scm_gc_unprotect_object (l->self_scm());
1348         }
1349         | E_BACKSLASH {
1350                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1351                 $$->set_spot (THIS->here_input ());
1352         }
1353         | '|'      {
1354
1355                 $$ = MY_MAKE_MUSIC("BarCheck");
1356                 $$->set_spot (THIS->here_input ());
1357         }
1358         | BAR STRING                    {
1359                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1360
1361                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1362                 csm->set_mus_property ("element", t->self_scm ());
1363                 scm_gc_unprotect_object (t->self_scm ());
1364
1365                 $$ = csm;
1366                 $$->set_spot (THIS->here_input ());
1367
1368                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1369         }
1370         | PARTIAL duration_length       {
1371                 Moment m = - unsmob_duration ($2)->get_length ();
1372                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1373
1374                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1375                 sp->set_mus_property ("element", p->self_scm ());
1376                 scm_gc_unprotect_object (p->self_scm ());
1377
1378                 $$ =sp ;
1379                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1380         }
1381         | CLEF STRING  {
1382                 static SCM proc ;
1383                 if (!proc)
1384                         proc = scm_c_eval_string ("make-clef-set");
1385
1386                 SCM result = scm_call_1 (proc, $2);
1387                 scm_gc_protect_object (result);
1388                 $$ = unsmob_music (result);
1389         }
1390         | TIME_T fraction  {
1391                 static SCM proc;
1392                 if (!proc)
1393                         proc = scm_c_eval_string ("make-time-signature-set");
1394
1395                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1396                 scm_gc_protect_object (result);
1397                 $$ = unsmob_music (result);
1398         }
1399         | MARK scalar {
1400                 static SCM proc;
1401                 if (!proc)
1402                         proc = scm_c_eval_string ("make-mark-set");
1403
1404                 SCM result = scm_call_1 (proc, $2);
1405                 scm_gc_protect_object (result);
1406                 $$ = unsmob_music (result);
1407         }
1408         ;
1409
1410 command_req:
1411         shorthand_command_req   { $$ = $1; }
1412         | verbose_command_req   { $$ = $1; }
1413         ;
1414
1415 shorthand_command_req:
1416         BREATHE {
1417                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1418         }
1419         | E_TILDE {
1420                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1421         }
1422         ;
1423
1424 verbose_command_req:
1425         MARK DEFAULT  {
1426                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1427                 $$ = m;
1428         }
1429
1430         | SKIP duration_length {
1431                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1432                 skip->set_mus_property ("duration", $2);
1433
1434                 $$ = skip;
1435         }
1436         | tempo_event {
1437                 $$ = $1;
1438         }
1439         | KEY DEFAULT {
1440                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1441                 $$ = key;
1442         }
1443         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1444
1445                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1446                 if (scm_ilength ($3) > 0)
1447                 {
1448                         key->set_mus_property ("pitch-alist", $3);
1449                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1450                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1451                 } else {
1452                         THIS->parser_error (_("Second argument must be pitch list."));
1453                 }
1454
1455                 $$ = key;
1456         }
1457         ;
1458
1459 post_events:
1460         /* empty */ {
1461                 $$ = SCM_EOL;
1462         }
1463         | post_events post_event {
1464                 $2->set_spot (THIS->here_input ());
1465                 $$ = gh_cons ($2->self_scm(), $$);
1466                 scm_gc_unprotect_object ($2->self_scm());
1467         }
1468         | post_events tagged_post_event {
1469                 $2 -> set_spot (THIS->here_input ());
1470                 $$ = scm_cons ($2->self_scm(), $$);
1471                 scm_gc_unprotect_object ($2->self_scm());
1472         }
1473         ;
1474
1475
1476 tagged_post_event:
1477         '-' TAG embedded_scm post_event {
1478                 tag_music ($4, $3, THIS->here_input ());
1479                 $$ = $4;
1480         }
1481         ;
1482
1483 post_event:
1484         direction_less_event {
1485                 $$ = $1;
1486         }
1487         | HYPHEN {
1488                 if (!THIS->lexer_->lyric_state_b ())
1489                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1490                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1491         }
1492         | EXTENDER {
1493                 if (!THIS->lexer_->lyric_state_b ())
1494                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1495                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1496         }
1497         | script_dir direction_reqd_event {
1498                 if ($1)
1499                         $2->set_mus_property ("direction", gh_int2scm ($1));
1500                 $$ = $2;
1501         }
1502         | script_dir direction_less_event {
1503                 if ($1)
1504                         $2->set_mus_property ("direction", gh_int2scm ($1));
1505                 $$ = $2;
1506         }
1507         | string_number_event
1508         ;
1509
1510 string_number_event:
1511         E_UNSIGNED {
1512                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1513                 s->set_mus_property ("string-number",  gh_int2scm($1));
1514                 s->set_spot (THIS->here_input ());
1515                 $$ = s;
1516         }
1517         ;
1518
1519
1520 direction_less_event:
1521         '['  {
1522
1523
1524 /*
1525
1526 TODO: should take all these defs out of the parser, adn make use
1527 configurable, i.e.
1528
1529
1530 (set-articulation '~ "trill")
1531
1532 */
1533                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1534                 m->set_spot (THIS->here_input());
1535                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1536                 $$ = m;
1537         }
1538         | ']'  {
1539                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1540                 m->set_spot (THIS->here_input());
1541                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1542                 $$ = m;
1543         }
1544         | '~' {
1545                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1546                 m->set_spot (THIS->here_input());
1547                 $$ = m;
1548         }
1549         | close_event {
1550                 $$ = $1;
1551                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1552                         gh_int2scm (START));
1553         }
1554         | open_event {
1555                 $$ = $1;
1556                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1557                         gh_int2scm (STOP));
1558         }
1559         | EVENT_IDENTIFIER      {
1560                 $$ = unsmob_music ($1);
1561         }
1562         | tremolo_type  {
1563                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1564                a->set_spot (THIS->here_input ());
1565                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1566                $$ = a;
1567         }
1568         ;
1569
1570 direction_reqd_event:
1571         gen_text_def {
1572                 $$ = $1;
1573         }
1574         | script_abbreviation {
1575                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1576                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1577                 if (gh_string_p (s))
1578                         a->set_mus_property ("articulation-type", s);
1579                 else THIS->parser_error (_ ("Expecting string as script definition"));
1580                 $$ = a;
1581         }
1582         ;
1583
1584 oct_check:
1585         /**/ { $$ = SCM_EOL; }
1586         | '='  { $$ = gh_int2scm (0); }
1587         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1588         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1589         ;
1590
1591 sup_quotes:
1592         '\'' {
1593                 $$ = 1;
1594         }
1595         | sup_quotes '\'' {
1596                 $$ ++;
1597         }
1598         ;
1599
1600 sub_quotes:
1601         ',' {
1602                 $$ = 1;
1603         }
1604         | sub_quotes ',' {
1605                 $$ ++ ;
1606         }
1607         ;
1608
1609 steno_pitch:
1610         NOTENAME_PITCH  {
1611                 $$ = $1;
1612         }
1613         | NOTENAME_PITCH sup_quotes     {
1614                 Pitch p = *unsmob_pitch ($1);
1615                 p = p.transposed (Pitch ($2,0,0));
1616                 $$ = p.smobbed_copy ();
1617         }
1618         | NOTENAME_PITCH sub_quotes      {
1619                 Pitch p =* unsmob_pitch ($1);
1620                 p = p.transposed (Pitch (-$2,0,0));
1621                 $$ = p.smobbed_copy ();
1622         }
1623         ;
1624
1625 /*
1626 ugh. duplication
1627 */
1628
1629 steno_tonic_pitch:
1630         TONICNAME_PITCH {
1631                 $$ = $1;
1632         }
1633         | TONICNAME_PITCH sup_quotes    {
1634                 Pitch p = *unsmob_pitch ($1);
1635                 p = p.transposed (Pitch ($2,0,0));
1636                 $$ = p.smobbed_copy ();
1637         }
1638         | TONICNAME_PITCH sub_quotes     {
1639                 Pitch p =* unsmob_pitch ($1);
1640
1641                 p = p.transposed (Pitch (-$2,0,0));
1642                 $$ = p.smobbed_copy ();
1643         }
1644         ;
1645
1646 pitch:
1647         steno_pitch {
1648                 $$ = $1;
1649         }
1650         ;
1651
1652 pitch_also_in_chords:
1653         pitch
1654         | steno_tonic_pitch
1655         ;
1656
1657 close_event:
1658         '('     {
1659                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1660                 $$ = s;
1661                 s->set_spot (THIS->here_input());
1662         }
1663         | E_OPEN        {
1664                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1665                 $$ = s;
1666                 s->set_spot (THIS->here_input());
1667         }
1668         | E_SMALLER {
1669                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1670                 $$ = s;
1671                 s->set_spot (THIS->here_input());
1672         }
1673         | E_BIGGER {
1674                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1675                 $$ = s;
1676                 s->set_spot (THIS->here_input());
1677         }
1678         ;
1679
1680
1681 open_event:
1682         E_EXCLAMATION   {
1683                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1684                 s->set_spot (THIS->here_input());
1685
1686                 $$ = s;
1687         }
1688         | ')'   {
1689                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1690                 $$ = s;
1691                 s->set_spot (THIS->here_input());
1692
1693         }
1694         | E_CLOSE       {
1695                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1696                 $$ = s;
1697                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1698                 s->set_spot (THIS->here_input());
1699         }
1700         ;
1701
1702 gen_text_def:
1703         full_markup {
1704                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1705                 t->set_mus_property ("text", $1);
1706                 t->set_spot (THIS->here_input ());
1707                 $$ = t;
1708         }
1709         | string {
1710                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1711                 t->set_mus_property ("text", make_simple_markup ($1));
1712                 t->set_spot (THIS->here_input ());
1713                 $$ = t;
1714
1715         }
1716         | DIGIT {
1717                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1718                 t->set_mus_property ("digit",  gh_int2scm ($1));
1719                 t->set_spot (THIS->here_input ());
1720                 $$ = t;
1721         }
1722         ;
1723
1724 script_abbreviation:
1725         '^'             {
1726                 $$ = scm_makfrom0str ("Hat");
1727         }
1728         | '+'           {
1729                 $$ = scm_makfrom0str ("Plus");
1730         }
1731         | '-'           {
1732                 $$ = scm_makfrom0str ("Dash");
1733         }
1734         | '|'           {
1735                 $$ = scm_makfrom0str ("Bar");
1736         }
1737         | '>'           {
1738                 $$ = scm_makfrom0str ("Larger");
1739         }
1740         | '.'           {
1741                 $$ = scm_makfrom0str ("Dot");
1742         }
1743         | '_' {
1744                 $$ = scm_makfrom0str ("Underscore");
1745         }
1746         ;
1747
1748 script_dir:
1749         '_'     { $$ = DOWN; }
1750         | '^'   { $$ = UP; }
1751         | '-'   { $$ = CENTER; }
1752         ;
1753
1754
1755 absolute_pitch:
1756         steno_pitch     {
1757                 $$ = $1;
1758         }
1759         ;
1760
1761 duration_length:
1762         multiplied_duration {
1763                 $$ = $1;
1764         }
1765         ;
1766
1767 optional_notemode_duration:
1768         {
1769                 Duration dd = THIS->default_duration_;
1770                 $$ = dd.smobbed_copy ();
1771
1772                 THIS->beam_check ($$);
1773         }
1774         | multiplied_duration   {
1775                 $$ = $1;
1776                 THIS->default_duration_ = *unsmob_duration ($$);
1777
1778                 THIS->beam_check ($$);
1779         }
1780         ;
1781
1782 steno_duration:
1783         bare_unsigned dots              {
1784                 int l = 0;
1785                 if (!is_duration_b ($1))
1786                         THIS->parser_error (_f ("not a duration: %d", $1));
1787                 else
1788                         l =  intlog2 ($1);
1789
1790                 $$ = Duration (l, $2).smobbed_copy ();
1791         }
1792         | DURATION_IDENTIFIER dots      {
1793                 Duration *d =unsmob_duration ($1);
1794                 Duration k (d->duration_log (),d->dot_count () + $2);
1795
1796                 *d = k;
1797                 $$ = $1;
1798         }
1799         ;
1800
1801
1802
1803
1804 multiplied_duration:
1805         steno_duration {
1806                 $$ = $1;
1807         }
1808         | multiplied_duration '*' bare_unsigned {
1809                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1810         }
1811         | multiplied_duration '*' FRACTION {
1812                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1813
1814                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1815         }
1816         ;
1817
1818 fraction:
1819         FRACTION { $$ = $1; }
1820         | UNSIGNED '/' UNSIGNED {
1821                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1822         }
1823         ;
1824
1825 dots:
1826         /* empty */     {
1827                 $$ = 0;
1828         }
1829         | dots '.' {
1830                 $$ ++;
1831         }
1832         ;
1833
1834
1835 tremolo_type:
1836         ':'     {
1837                 $$ =0;
1838         }
1839         | ':' bare_unsigned {
1840                 if (!is_duration_b ($2))
1841                         THIS->parser_error (_f ("not a duration: %d", $2));
1842                 $$ = $2;
1843         }
1844         ;
1845
1846
1847
1848 /*****************************************************************
1849                 BASS FIGURES
1850 *****************************************************************/
1851 bass_number:
1852         DIGIT   {
1853                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1854         }
1855         | UNSIGNED {
1856                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1857         }
1858         | STRING { $$ =  $1; }
1859         ;
1860
1861 bass_mod:
1862         '-'     { $$ = -2; }
1863         | '+'   { $$ = 2; }
1864         | '!'   { $$ = 0; }
1865         ;
1866
1867 bass_figure:
1868         FIGURE_SPACE {
1869                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1870                 $$ = bfr->self_scm();
1871                 scm_gc_unprotect_object ($$);
1872         }
1873         | bass_number  {
1874                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1875                 $$ = bfr->self_scm();
1876
1877                 bfr->set_mus_property ("figure", $1);
1878
1879                 scm_gc_unprotect_object ($$);
1880         }
1881         | bass_figure bass_mod {
1882                 Music *m = unsmob_music ($1);
1883                 if ($2) {
1884                         SCM salter =m->get_mus_property ("alteration");
1885                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1886                         m->set_mus_property ("alteration",
1887                                 gh_int2scm (alter + $2));
1888                 } else {
1889                         m->set_mus_property ("alteration", gh_int2scm (0));
1890                 }
1891         }
1892         ;
1893
1894 br_bass_figure:
1895         '[' bass_figure {
1896                 $$ = $2;
1897                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1898         }
1899         | bass_figure   {
1900                 $$ = $1;
1901         }
1902         | br_bass_figure ']' {
1903                 $$ = $1;
1904                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1905         }
1906         ;
1907
1908 figure_list:
1909         /**/            {
1910                 $$ = SCM_EOL;
1911         }
1912         | figure_list br_bass_figure {
1913                 $$ = scm_cons ($2, $1);
1914         }
1915         ;
1916
1917 figure_spec:
1918         FIGURE_OPEN figure_list FIGURE_CLOSE {
1919                 Music * m = MY_MAKE_MUSIC("EventChord");
1920                 $2 = scm_reverse_x ($2, SCM_EOL);
1921                 m->set_mus_property ("elements",  $2);
1922                 $$ = m->self_scm ();
1923         }
1924         ;
1925
1926
1927 optional_rest:
1928         /**/   { $$ = 0; }
1929         | REST { $$ = 1; }
1930         ;
1931
1932 simple_element:
1933         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1934
1935                 Input i = THIS->pop_spot ();
1936                 if (!THIS->lexer_->note_state_b ())
1937                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1938
1939                 Music *n = 0;
1940                 if ($6)
1941                         n =  MY_MAKE_MUSIC("RestEvent");
1942                 else
1943                         n =  MY_MAKE_MUSIC("NoteEvent");
1944
1945                 n->set_mus_property ("pitch", $1);
1946                 n->set_mus_property ("duration", $5);
1947
1948                 if (gh_number_p ($4))
1949                 {
1950                         int q = gh_scm2int ($4);
1951                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1952                 }
1953
1954                 if ($3 % 2)
1955                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1956                 if ($2 % 2 || $3 % 2)
1957                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1958
1959                 Music *v = MY_MAKE_MUSIC("EventChord");
1960                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1961                 scm_gc_unprotect_object (n->self_scm());
1962
1963                 v->set_spot (i);
1964                 n->set_spot (i);
1965                 $$ = v;
1966         }
1967         | figure_spec optional_notemode_duration {
1968                 Music * m = unsmob_music ($1);
1969                 Input i = THIS->pop_spot ();
1970                 m->set_spot (i);
1971                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1972                 {
1973                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1974                 }
1975                 $$ = m;
1976         }
1977         | RESTNAME optional_notemode_duration           {
1978
1979                 Input i = THIS->pop_spot ();
1980                 Music * ev = 0;
1981                 if (ly_scm2string ($1) =="s") {
1982                         /* Space */
1983                         ev = MY_MAKE_MUSIC("SkipEvent");
1984                   }
1985                 else {
1986                         ev = MY_MAKE_MUSIC("RestEvent");
1987
1988                     }
1989                 ev->set_mus_property ("duration" ,$2);
1990                 ev->set_spot (i);
1991                 Music * velt = MY_MAKE_MUSIC("EventChord");
1992                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1993                 velt->set_spot (i);
1994
1995                 scm_gc_unprotect_object (ev->self_scm());
1996
1997                 $$ = velt;
1998         }
1999         | MULTI_MEASURE_REST optional_notemode_duration         {
2000                 THIS->pop_spot ();
2001
2002                 static SCM proc ;
2003                 if (!proc)
2004                         proc = scm_c_eval_string ("make-multi-measure-rest");
2005
2006                 SCM mus = scm_call_2 (proc, $2,
2007                         make_input (THIS->here_input()));
2008                 scm_gc_protect_object (mus);
2009                 $$ = unsmob_music (mus);
2010         }
2011
2012         | lyric_element optional_notemode_duration      {
2013                 Input i = THIS->pop_spot ();
2014                 if (!THIS->lexer_->lyric_state_b ())
2015                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2016
2017                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2018                 lreq->set_mus_property ("text", $1);
2019                 lreq->set_mus_property ("duration",$2);
2020                 lreq->set_spot (i);
2021                 Music * velt = MY_MAKE_MUSIC("EventChord");
2022                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2023
2024                 $$= velt;
2025         }
2026         | new_chord {
2027                 THIS->pop_spot ();
2028
2029                 if (!THIS->lexer_->chord_state_b ())
2030                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2031                 $$ = unsmob_music ($1);
2032         }
2033         ;
2034
2035 lyric_element:
2036         full_markup { $$ = $1; }
2037         | STRING {  $$ = $1 ; }
2038         ;
2039
2040 new_chord:
2041         steno_tonic_pitch optional_notemode_duration   {
2042                 $$ = make_chord ($1, $2, SCM_EOL);
2043         }
2044         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2045                 SCM its = scm_reverse_x ($4, SCM_EOL);
2046                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2047         }
2048         ;
2049
2050 chord_items:
2051         /**/ {
2052                 $$ = SCM_EOL;
2053         }
2054         | chord_items chord_item {
2055                 $$ = gh_cons ($2, $$);
2056         }
2057         ;
2058
2059 chord_separator:
2060         CHORD_COLON {
2061                 $$ = ly_symbol2scm ("chord-colon");
2062         }
2063         | CHORD_CARET {
2064                 $$ = ly_symbol2scm ("chord-caret");
2065         }
2066         | CHORD_SLASH steno_tonic_pitch {
2067                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2068         }
2069         | CHORD_BASS steno_tonic_pitch {
2070                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2071         }
2072         ;
2073
2074 chord_item:
2075         chord_separator {
2076                 $$ = $1;
2077         }
2078         | step_numbers {
2079                 $$ = scm_reverse_x ($1, SCM_EOL);
2080         }
2081         | CHORD_MODIFIER  {
2082                 $$ = $1;
2083         }
2084         ;
2085
2086 step_numbers:
2087         step_number { $$ = gh_cons ($1, SCM_EOL); }
2088         | step_numbers '.' step_number {
2089                 $$ = gh_cons ($3, $$);
2090         }
2091         ;
2092
2093 step_number:
2094         bare_unsigned {
2095                 $$ = make_chord_step ($1, 0);
2096         }
2097         | bare_unsigned '+' {
2098                 $$ = make_chord_step ($1, SHARP);
2099         }
2100         | bare_unsigned CHORD_MINUS {
2101                 $$ = make_chord_step ($1, FLAT);
2102         }
2103         ;
2104
2105 /*
2106         UTILITIES
2107
2108 TODO: should deprecate in favor of Scheme?
2109
2110  */
2111 number_expression:
2112         number_expression '+' number_term {
2113                 $$ = scm_sum ($1, $3);
2114         }
2115         | number_expression '-' number_term {
2116                 $$ = scm_difference ($1, $3);
2117         }
2118         | number_term
2119         ;
2120
2121 number_term:
2122         number_factor {
2123                 $$ = $1;
2124         }
2125         | number_factor '*' number_factor {
2126                 $$ = scm_product ($1, $3);
2127         }
2128         | number_factor '/' number_factor {
2129                 $$ = scm_divide ($1, $3);
2130         }
2131         ;
2132
2133 number_factor:
2134         '-'  number_factor { /* %prec UNARY_MINUS */
2135                 $$ = scm_difference ($2, SCM_UNDEFINED);
2136         }
2137         | bare_number
2138         ;
2139
2140
2141 bare_number:
2142         UNSIGNED        {
2143                 $$ = gh_int2scm ($1);
2144         }
2145         | REAL          {
2146                 $$ = $1;
2147         }
2148         | NUMBER_IDENTIFIER             {
2149                 $$ = $1;
2150         }
2151         | REAL NUMBER_IDENTIFIER        {
2152                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2153         }
2154         | UNSIGNED NUMBER_IDENTIFIER    {
2155                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2156         }
2157         ;
2158
2159
2160 bare_unsigned:
2161         UNSIGNED {
2162                         $$ = $1;
2163         }
2164         | DIGIT {
2165                 $$ = $1;
2166         }
2167         ;
2168
2169 bare_int:
2170         bare_number {
2171                 if (scm_integer_p ($1) == SCM_BOOL_T)
2172                 {
2173                         int k = gh_scm2int ($1);
2174                         $$ = k;
2175                 } else
2176                 {
2177                         THIS->parser_error (_ ("need integer number arg"));
2178                         $$ = 0;
2179                 }
2180         }
2181         | '-' bare_int {
2182                 $$ = -$2;
2183         }
2184         ;
2185
2186
2187 string:
2188         STRING          {
2189                 $$ = $1;
2190         }
2191         | STRING_IDENTIFIER     {
2192                 $$ = $1;
2193         }
2194         | string '+' string {
2195                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2196         }
2197         ;
2198
2199
2200 exclamations:
2201                 { $$ = 0; }
2202         | exclamations '!'      { $$ ++; }
2203         ;
2204
2205 questions:
2206                 { $$ = 0; }
2207         | questions '?' { $$ ++; }
2208         ;
2209
2210
2211
2212 full_markup:
2213         MARKUP_IDENTIFIER {
2214                 $$ = $1;
2215         }
2216         | MARKUP
2217                 { THIS->lexer_->push_markup_state (); }
2218         markup
2219                 { $$ = $3;
2220                   THIS->lexer_->pop_state ();
2221                 }
2222         ;
2223
2224
2225 /*
2226 This should be done more dynamically if possible.
2227 */
2228 markup:
2229         STRING {
2230                 $$ = make_simple_markup ($1);
2231         }
2232         | MARKUP_HEAD_EMPTY {
2233                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2234         }
2235         | MARKUP_HEAD_MARKUP0 markup {
2236                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2237         }
2238         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2239                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2240         }
2241         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2242                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2243         }
2244         | markup_line {
2245                 $$ = $1;
2246         }
2247         | MARKUP_HEAD_LIST0 markup_list {
2248                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2249         }
2250         | MARKUP_HEAD_SCM0 embedded_scm {
2251                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2252         }
2253         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2254                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2255         }
2256         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2257                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2258         }
2259         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2260                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2261         }
2262         | MARKUP_IDENTIFIER {
2263                 $$ = $1;
2264         }
2265
2266         ;
2267
2268 markup_list:
2269         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2270         ;
2271
2272 markup_line:
2273         '{' markup_list_body '}' {
2274                 static SCM line ;
2275                 if (!line)
2276                         line = scm_c_eval_string ("line-markup");
2277
2278                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2279         }
2280         ;
2281
2282 markup_list_body:
2283         /**/ {  $$ = SCM_EOL; }
2284         | markup_list_body markup {
2285                 $$ = gh_cons ($2, $1) ;
2286         }
2287         ;
2288
2289
2290 %%
2291
2292 void
2293 My_lily_parser::set_yydebug (bool )
2294 {
2295 #if 0
2296         yydebug = 1;
2297 #endif
2298 }
2299
2300 extern My_lily_parser * current_parser;
2301
2302 void
2303 My_lily_parser::do_yyparse ()
2304 {
2305         current_parser = this;;
2306         yyparse ((void*)this);
2307 }
2308
2309
2310 /*
2311 Should make this optional?    It will also complain when you do
2312
2313         [s4]
2314
2315 which is entirely legitimate.
2316
2317 Or we can scrap it. Barchecks should detect wrong durations, and
2318 skipTypesetting speeds it up a lot.
2319 */
2320
2321 void
2322 My_lily_parser::beam_check (SCM dur)
2323 {
2324   Duration *d = unsmob_duration (dur);
2325   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2326     {
2327       Music * m = unsmob_music (last_beam_start_);
2328       m->origin ()->warning (_("Suspect duration found following this beam"));
2329     }
2330   last_beam_start_ = SCM_EOL;
2331 }
2332
2333
2334
2335
2336 /*
2337
2338 It is a little strange to have this function in this file, but
2339 otherwise, we have to import music classes into the lexer.
2340
2341 */
2342 int
2343 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2344 {
2345         if (gh_string_p (sid)) {
2346                 *destination = sid;
2347                 return STRING_IDENTIFIER;
2348         } else if (gh_number_p (sid)) {
2349                 *destination = sid;
2350                 return NUMBER_IDENTIFIER;
2351         } else if (unsmob_context_def (sid)) {
2352                 *destination = unsmob_context_def (sid)->clone_scm();
2353                 return TRANSLATOR_IDENTIFIER;
2354         } else if (unsmob_score (sid)) {
2355                 Score *sc =  new Score (*unsmob_score (sid));
2356                 *destination =sc->self_scm ();
2357                 return SCORE_IDENTIFIER;
2358         } else if (Music * mus =unsmob_music (sid)) {
2359                 *destination = unsmob_music (sid)->clone ()->self_scm();
2360                 unsmob_music (*destination)->
2361                         set_mus_property ("origin", make_input (last_input_));
2362                 return dynamic_cast<Event*> (mus)
2363                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2364         } else if (unsmob_duration (sid)) {
2365                 *destination = unsmob_duration (sid)->smobbed_copy();
2366                 return DURATION_IDENTIFIER;
2367         } else if (unsmob_music_output_def (sid)) {
2368                 Music_output_def *p = unsmob_music_output_def (sid);
2369                 p = p->clone ();
2370
2371                 *destination = p->self_scm();
2372                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2373         } else if (Text_item::markup_p (sid)) {
2374                 *destination = sid;
2375                 return MARKUP_IDENTIFIER;
2376         }
2377
2378         return -1;
2379 }
2380
2381 Music *
2382 property_op_to_music (SCM op)
2383 {
2384         Music * m = 0;
2385         SCM tag = gh_car (op);
2386         SCM symbol  = gh_cadr (op);
2387         SCM args = gh_cddr (op);
2388         SCM grob_val = SCM_UNDEFINED;
2389         SCM grob_sym = SCM_UNDEFINED;
2390         SCM val = SCM_UNDEFINED;
2391
2392         if (tag == ly_symbol2scm ("assign"))
2393                 {
2394                 m =  MY_MAKE_MUSIC("PropertySet");
2395                 val = gh_car (args);
2396                 }
2397         else if (tag == ly_symbol2scm ("unset"))
2398                 m =  MY_MAKE_MUSIC("PropertyUnset");
2399         else if (tag == ly_symbol2scm ("poppush")
2400                  || tag == ly_symbol2scm ("push"))
2401                 {
2402                 m  = MY_MAKE_MUSIC("OverrideProperty");
2403                 grob_sym = gh_car (args);
2404                 grob_val = gh_cadr (args);
2405                 }
2406         else if (tag == ly_symbol2scm ("pop")) {
2407                 m = MY_MAKE_MUSIC("RevertProperty");
2408                 grob_sym = gh_car (args);
2409                 }
2410
2411         m->set_mus_property ("symbol", symbol);
2412
2413         if (val != SCM_UNDEFINED)
2414                 m->set_mus_property ("value", val);
2415         if (grob_val != SCM_UNDEFINED)
2416                 m->set_mus_property ("grob-value", grob_val);
2417
2418         if (grob_sym != SCM_UNDEFINED)
2419                 {
2420                 bool itc = internal_type_checking_global_b;
2421                 /* UGH.
2422                 */
2423                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2424                 if (autobeam)
2425                         internal_type_checking_global_b = false;
2426                 m->set_mus_property ("grob-property", grob_sym);
2427                 if (autobeam)
2428                         internal_type_checking_global_b = itc;
2429                 }
2430
2431         if (op == ly_symbol2scm ("poppush"))
2432                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2433
2434
2435         return m;
2436 }
2437
2438 Music*
2439 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2440 {
2441         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2442
2443         csm->set_mus_property ("element", m->self_scm ());
2444         scm_gc_unprotect_object (m->self_scm ());
2445
2446         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2447         csm->set_mus_property ("property-operations", ops);
2448
2449         if (gh_string_p (id))
2450                 csm->set_mus_property ("context-id", id);
2451         return csm;
2452 }
2453
2454
2455 SCM
2456 get_next_unique_context ()
2457 {
2458         static int new_context_count;
2459
2460         char s[1024];
2461         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2462
2463         return scm_makfrom0str (s);
2464 }