lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_mus_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_mus_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 regular_identifier_b (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_n (simple, a, SCM_UNDEFINED);
 143 }
 144
 145
 146 bool
 147 is_duration_b (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token PROPERTY
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSLATOR
 302 %token TRANSPOSE
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306
 307 /* escaped */
 308 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 309 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 310 %token E_BACKSLASH
 311 %token <i> E_UNSIGNED
 312 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 313 %token FIGURE_SPACE
 314
 315 %type <i>       exclamations questions dots optional_rest
 316 %type <i>        bass_mod
 317 %type <scm>     grace_head
 318 %type <scm>     oct_check
 319 %type <scm>     context_mod_list
 320 %type <scm>     lyric_element
 321 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 322 %token <i>      DIGIT
 323 %token <scm>    NOTENAME_PITCH
 324 %token <scm>    TONICNAME_PITCH
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DURATION_IDENTIFIER
 327 %token <scm>    FRACTION
 328 %token <id>     IDENTIFIER
 329 %token DRUMS
 330 %token <scm>    DRUM_PITCH
 331 %token <scm>    CHORD_MODIFIER
 332 %token <scm>    SCORE_IDENTIFIER
 333 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    NUMBER_IDENTIFIER
 335 %token <scm>    EVENT_IDENTIFIER
 336 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    RESTNAME
 339 %token <scm>    STRING
 340 %token <scm>    SCM_T
 341 %token <i>      UNSIGNED
 342 %token <scm>   REAL
 343
 344 %token MARKUP
 345 %token <scm> MARKUP_HEAD_MARKUP0
 346 %token <scm> MARKUP_HEAD_EMPTY
 347 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0
 349 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 353
 354 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 355 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 356
 357 %type <outputdef> output_def
 358 %type <scm>     lilypond_header lilypond_header_body
 359 %type <music>   open_event close_event
 360 %type <i>       sub_quotes sup_quotes
 361 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 362 %type <music>   Repeated_music
 363 %type <scm>     Alternative_music
 364 %type <i>       tremolo_type
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       script_dir
 367 %type <scm>     identifier_init
 368
 369 %type <music> note_chord_element chord_body chord_body_element
 370 %type <scm>  chord_body_elements
 371 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 372
 373 %type <scm>   post_events
 374 %type <music> gen_text_def direction_less_event direction_reqd_event
 375 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 376 %type <scm>    steno_tonic_pitch
 377 %type <scm>     duration_length fraction
 378
 379 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 380
 381 %type <scm>  embedded_scm scalar
 382 %type <music>   Music Sequential_music Simultaneous_music
 383 %type <music>   relative_music re_rhythmed_music
 384 %type <music>   music_property_def context_change
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body music_output_def_head
 388 %type <music> shorthand_command_req
 389 %type <music>   post_event tagged_post_event
 390 %type <music> command_req verbose_command_req
 391 %type <music> string_number_event
 392 %type <scm>     string bare_number number_expression number_term number_factor
 393 %type <score>   score_block score_body
 394
 395 %type <scm>     translator_spec_block translator_spec_body
 396 %type <music>   tempo_event
 397 %type <scm>     script_abbreviation
 398
 399
 400
 401 %left '-' '+'
 402
 403 /* We don't assign precedence to / and *, because we might need varied
 404 prec levels in different prods */
 405
 406 %left UNARY_MINUS
 407
 408 %%
 409
 410 lilypond:       /* empty */
 411         | lilypond toplevel_expression {}
 412         | lilypond assignment  { }
 413         | lilypond error {
 414                 THIS->error_level_  = 1;
 415         }
 416         | lilypond INVALID      {
 417                 THIS->error_level_  = 1;
 418         }
 419         ;
 420
 421 toplevel_expression:
 422         lilypond_header {
 423                 THIS->input_file_->header_ = $1;
 424         }
 425         | score_block {
 426                 Score * sc = $1;
 427
 428                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 429
 430                 Path p = split_path (THIS->output_basename_);
 431                 int *c =  &THIS->input_file_->score_count_;
 432                 if (*c)
 433                         {
 434                         p.base += "-" + to_string (*c);
 435                         }
 436
 437                 (*c)++;
 438                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 439
 440                 for (int i=0; i < sc->defs_.size (); i++)
 441                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 442
 443                 if (sc->defs_.empty ())
 444                 {
 445                    Music_output_def *id =
 446                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 447                                 ("$defaultpaper"));
 448
 449                    id = id ? id->clone () : new Paper_def;
 450
 451                    default_rendering (sc->music_, id->self_scm(), head, outname);
 452
 453                    scm_gc_unprotect_object (id->self_scm ());
 454                 }
 455                 scm_gc_unprotect_object (sc->self_scm());
 456         }
 457         | output_def {
 458                 SCM id = SCM_EOL;
 459                 if (dynamic_cast<Paper_def*> ($1))
 460                         id = scm_makfrom0str ("$defaultpaper");
 461                 else if (dynamic_cast<Midi_def*> ($1))
 462                         id = scm_makfrom0str ("$defaultmidi");
 463                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 464                 scm_gc_unprotect_object ($1->self_scm ());
 465         }
 466         ;
 467
 468 embedded_scm:
 469         SCM_T
 470         | SCM_IDENTIFIER
 471         ;
 472
 473
 474
 475
 476 lilypond_header_body:
 477         {
 478                 $$ = ly_make_anonymous_module ();
 479                 THIS->lexer_->add_scope ($$);
 480         }
 481         | lilypond_header_body assignment  {
 482
 483         }
 484         ;
 485
 486 lilypond_header:
 487         HEADER '{' lilypond_header_body '}'     {
 488                 $$ = THIS->lexer_-> remove_scope();
 489         }
 490         ;
 491
 492
 493 /*
 494         DECLARATIONS
 495 */
 496 assignment:
 497         STRING {
 498                 THIS->push_spot ();
 499         }
 500         /* cont */ '=' identifier_init  {
 501
 502         /*
 503                 Should find generic way of associating input with objects.
 504         */
 505                 Input ip = THIS->pop_spot ();
 506
 507                 if (! regular_identifier_b ($1))
 508                 {
 509                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 510                 }
 511
 512                 THIS->lexer_->set_identifier ($1, $4);
 513
 514 /*
 515  TODO: devise standard for protection in parser.
 516
 517   The parser stack lives on the C-stack, which means that
 518 all objects can be unprotected as soon as they're here.
 519
 520 */
 521         }
 522         | embedded_scm { }
 523         ;
 524
 525
 526 identifier_init:
 527         score_block {
 528                 $$ = $1->self_scm ();
 529                 scm_gc_unprotect_object ($$);
 530         }
 531         | full_markup {
 532                 $$ = $1;
 533         }
 534         | output_def {
 535                 $$ = $1->self_scm ();
 536                 scm_gc_unprotect_object ($$);
 537         }
 538         | translator_spec_block {
 539                 $$ = $1;
 540         }
 541         | Music  {
 542                 $$ = $1->self_scm ();
 543                 scm_gc_unprotect_object ($$);
 544         }
 545         | post_event {
 546                 $$ = $1->self_scm ();
 547                 scm_gc_unprotect_object ($$);
 548         }
 549         | number_expression {
 550                 $$ = $1;
 551         }
 552         | string {
 553                 $$ = $1;
 554         }
 555         | embedded_scm  {
 556                 $$ = $1;
 557         }
 558         ;
 559
 560 translator_spec_block:
 561         TRANSLATOR '{' translator_spec_body '}'
 562                 {
 563                 $$ = $3;
 564         }
 565         ;
 566
 567 translator_spec_body:
 568         /**/ {
 569                 $$ = Context_def::make_scm ();
 570                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 571         }
 572         | TRANSLATOR_IDENTIFIER {
 573                 $$ = $1;
 574                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 575         }
 576         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 577                 Context_def*td = unsmob_context_def($$);
 578
 579                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 580                         SCM tag = gh_caar (p);
 581                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 582                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 583                 }
 584         }
 585         | translator_spec_body context_mod {
 586                 unsmob_context_def ($$)->add_context_mod ($2);
 587         }
 588         ;
 589
 590 /*
 591         SCORE
 592 */
 593 score_block:
 594         SCORE {
 595                 THIS->push_spot ();
 596         }
 597         /*cont*/ '{' score_body '}'     {
 598                 THIS->pop_spot ();
 599                 $$ = $4;
 600
 601         }
 602         ;
 603
 604 score_body:
 605         Music   {
 606                 $$ = new Score;
 607
 608                 $$->set_spot (THIS->here_input ());
 609                 SCM m = $1->self_scm ();
 610                 scm_gc_unprotect_object (m);
 611
 612                 /*
 613                         guh.
 614                 */
 615                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 616                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 617                         m = gh_call1 (gh_car (check_funcs), m);
 618                 $$->music_ = m;
 619
 620         }
 621         | SCORE_IDENTIFIER {
 622                 $$ = new Score ( *unsmob_score ($1));
 623                 $$->set_spot (THIS->here_input ());
 624         }
 625         | score_body lilypond_header    {
 626                 $$->header_ = $2;
 627         }
 628         | score_body output_def {
 629                 $$->defs_.push ($2);
 630                 scm_gc_unprotect_object ($2->self_scm ());
 631         }
 632         | score_body error {
 633
 634         }
 635         ;
 636
 637
 638 /*
 639         MIDI
 640 */
 641 output_def:
 642         music_output_def_body '}' {
 643                 $$ = $1;
 644                 THIS-> lexer_-> remove_scope ();
 645         }
 646         ;
 647
 648 music_output_def_head:
 649         MIDI    {
 650                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 651
 652
 653                 Midi_def* p =0;
 654                 if (id)
 655                         p = dynamic_cast<Midi_def*> (id->clone ());
 656                 else
 657                         p = new Midi_def;
 658
 659                 $$ = p;
 660                 THIS->lexer_->add_scope (p->scope_);
 661         }
 662         | PAPER         {
 663                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 664                   Paper_def *p = 0;
 665                 if (id)
 666                         p = dynamic_cast<Paper_def*> (id->clone ());
 667                 else
 668                         p = new Paper_def;
 669
 670                 THIS->lexer_->add_scope (p->scope_);
 671                 $$ = p;
 672         }
 673         ;
 674
 675
 676 music_output_def_body:
 677         music_output_def_head '{' {
 678
 679         }
 680         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 681                 Music_output_def * o =  unsmob_music_output_def ($3);
 682                 $$ = o;
 683                 THIS->lexer_->remove_scope ();
 684                 THIS->lexer_->add_scope (o->scope_);
 685         }
 686         | music_output_def_body assignment  {
 687
 688         }
 689         | music_output_def_body translator_spec_block   {
 690                 $$->assign_translator ($2);
 691         }
 692         | music_output_def_body tempo_event  {
 693                 /*
 694                         junk this ? there already is tempo stuff in
 695                         music.
 696                 */
 697                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 698                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 699                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 700                 if (md)
 701                         md->set_tempo (d->get_length (), m);
 702                 scm_gc_unprotect_object ($2->self_scm ());
 703         }
 704         | music_output_def_body error {
 705
 706         }
 707         ;
 708
 709 tempo_event:
 710         TEMPO steno_duration '=' bare_unsigned  {
 711                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 712                 $$->set_mus_property ("tempo-unit", $2);
 713                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 714         }
 715         ;
 716
 717 /*
 718 The representation of a  list is the
 719
 720   (LIST . LAST-CONS)
 721
 722  to have  efficient append.
 723 */
 724 Music_list:
 725         /* empty */ {
 726                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 727         }
 728         | Music_list Music {
 729                 SCM s = $$;
 730                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 731                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 732                 if (gh_pair_p (ly_cdr (s)))
 733                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 734                 else
 735                         gh_set_car_x (s, c); /* set first cons */
 736                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 737         }
 738         | Music_list error {
 739         }
 740         ;
 741
 742
 743 Music:
 744         Simple_music
 745         | Composite_music
 746         ;
 747
 748 Alternative_music:
 749         /* empty */ {
 750                 $$ = SCM_EOL;
 751         }
 752         | ALTERNATIVE '{' Music_list '}' {
 753                 $$ = $3;
 754         }
 755         ;
 756
 757 Repeated_music:
 758         REPEAT string bare_unsigned Music Alternative_music
 759         {
 760                 Music *beg = $4;
 761                 int times = $3;
 762                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 763                 if (times < scm_ilength (alts)) {
 764                   unsmob_music (gh_car (alts))
 765                     ->origin ()->warning (
 766                     _("More alternatives than repeats.  Junking excess alternatives."));
 767                   alts = ly_truncate_list (times, alts);
 768                 }
 769
 770
 771                 static SCM proc;
 772                 if (!proc)
 773                         proc = scm_c_eval_string ("make-repeated-music");
 774
 775                 SCM mus = scm_call_1 (proc, $2);
 776                 scm_gc_protect_object (mus); // UGH.
 777                 Music *r =unsmob_music (mus);
 778                 if (beg)
 779                         {
 780                         r-> set_mus_property ("element", beg->self_scm ());
 781                         scm_gc_unprotect_object (beg->self_scm ());
 782                         }
 783                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 784
 785                 r-> set_mus_property ("elements",alts);
 786                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 787                         /*
 788                         we can not get durations and other stuff correct down the line, so we have to
 789                         add to the duration log here.
 790                         */
 791                         static SCM func;
 792
 793                         if (!func)
 794                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 795
 796                         int dots = ($3 % 3) ? 0 : 1;
 797                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 798
 799                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 800
 801                         if (seq) {
 802                                 int list_len =scm_ilength (seq->music_list ());
 803                                 if (list_len != 2)
 804                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 805                                 shift -= 1;
 806                                 r->compress (Moment (Rational (1,list_len)));
 807                                 }
 808                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 809
 810                 }
 811                 r->set_spot (*$4->origin ());
 812
 813                 $$ = r;
 814         }
 815         ;
 816
 817 Sequential_music:
 818         SEQUENTIAL '{' Music_list '}'           {
 819                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 820                 $$->set_mus_property ("elements", ly_car ($3));
 821                 $$->set_spot(THIS->here_input());
 822         }
 823         | '{' Music_list '}'            {
 824                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 825                 $$->set_mus_property ("elements", ly_car ($2));
 826                 $$->set_spot(THIS->here_input());
 827         }
 828         ;
 829
 830 Simultaneous_music:
 831         SIMULTANEOUS '{' Music_list '}'{
 832                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 833                 $$->set_mus_property ("elements", ly_car ($3));
 834                 $$->set_spot(THIS->here_input());
 835
 836         }
 837         | simul_open Music_list simul_close     {
 838                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 839                 $$->set_mus_property ("elements", ly_car ($2));
 840                 $$->set_spot(THIS->here_input());
 841         }
 842         ;
 843
 844 Simple_music:
 845         event_chord             { $$ = $1; }
 846         | APPLYOUTPUT embedded_scm {
 847                 if (!ly_input_procedure_p ($2))
 848                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 849                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 850                 $$->set_mus_property ("procedure", $2);
 851                 $$->set_spot (THIS->here_input());
 852         }
 853         | APPLYCONTEXT embedded_scm {
 854                 if (!ly_input_procedure_p ($2))
 855                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 856                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 857                 $$->set_mus_property ("procedure", $2);
 858                 $$->set_spot (THIS->here_input());
 859         }
 860         | MUSIC_IDENTIFIER {
 861                 $$ = unsmob_music ($1);
 862         }
 863         | music_property_def
 864         | context_change
 865         ;
 866
 867
 868 optional_context_mod:
 869         /**/ { $$ = SCM_EOL; }
 870         | WITH '{' context_mod_list '}'  { $$ = $3; }
 871         ;
 872
 873 grace_head:
 874         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 875         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 876         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 877         ;
 878
 879 context_mod_list:
 880         /* */  { $$ = SCM_EOL; }
 881         | context_mod_list context_mod  {
 882                  $$ = gh_cons ($2, $1);
 883         }
 884         ;
 885
 886 Composite_music:
 887         AUTOCHANGE Music        {
 888                 static SCM proc ;
 889                 if (!proc)
 890                         proc = scm_c_eval_string ("make-autochange-music");
 891
 892                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 893                 scm_gc_unprotect_object ($2->self_scm ());
 894                 $$ = unsmob_music (res);
 895                 scm_gc_protect_object (res);
 896                 $$->set_spot (THIS->here_input())
 897         }
 898         | PARTCOMBINE Music Music {
 899                 static SCM proc;
 900                 if (!proc)
 901                         proc = scm_c_eval_string ("make-part-combine-music");
 902
 903                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 904                         $3->self_scm (), SCM_UNDEFINED));
 905                 scm_gc_unprotect_object ($3->self_scm ());
 906                 scm_gc_unprotect_object ($2->self_scm ());
 907                 $$ = unsmob_music (res);
 908                 scm_gc_protect_object (res);
 909                 $$->set_spot (THIS->here_input());
 910         }
 911         | grace_head Music {
 912 #if 1
 913         /*
 914                 The other version is for easier debugging  of
 915                 Sequential_music_iterator in combination with grace notes.
 916         */
 917
 918 /*
 919
 920 TODO: should distinguish between both grace types in the
 921 basic music objects too, since the meaning is different.
 922
 923 */
 924
 925                 String start_str = "start" + ly_scm2string ($1) + "Music";
 926                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 927
 928                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 929                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 930
 931                 Music *startm = unsmob_music (start);
 932                 Music *stopm = unsmob_music (stop);
 933
 934                 SCM ms = SCM_EOL;
 935                 if (stopm) {
 936                         stopm = stopm->clone ();
 937                         ms = scm_cons (stopm->self_scm (), ms);
 938                         scm_gc_unprotect_object (stopm->self_scm ());
 939                 }
 940                 ms = scm_cons ($2->self_scm (), ms);
 941                 scm_gc_unprotect_object ($2->self_scm());
 942                 if (startm) {
 943                         startm = startm->clone ();
 944                         ms = scm_cons (startm->self_scm () , ms);
 945                         scm_gc_unprotect_object (startm->self_scm ());
 946                 }
 947
 948
 949                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 950                 seq->set_mus_property ("elements", ms);
 951
 952
 953                 $$ = MY_MAKE_MUSIC("GraceMusic");
 954                 $$->set_mus_property ("element", seq->self_scm ());
 955                 scm_gc_unprotect_object (seq->self_scm ());
 956 #else
 957                 $$ = MY_MAKE_MUSIC("GraceMusic");
 958                 $$->set_mus_property ("element", $2->self_scm ());
 959                 scm_gc_unprotect_object ($2->self_scm ());
 960 #endif
 961         }
 962         | CONTEXT string '=' string optional_context_mod Music {
 963                 $$ = context_spec_music ($2, $4, $6, $5);
 964
 965         }
 966         | CONTEXT STRING optional_context_mod Music {
 967                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 968         }
 969         | NEWCONTEXT string optional_context_mod Music {
 970                 $$ = context_spec_music ($2, get_next_unique_context (),
 971                                          $4, $3);
 972         }
 973
 974         | TIMES {
 975                 THIS->push_spot ();
 976         }
 977         /* CONTINUED */
 978                 fraction Music
 979
 980         {
 981                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 982                 Music *mp = $4;
 983
 984                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 985                 $$->set_spot (THIS->pop_spot ());
 986
 987                 $$->set_mus_property ("element", mp->self_scm ());
 988                 scm_gc_unprotect_object (mp->self_scm ());
 989                 $$->set_mus_property ("numerator", gh_int2scm (n));
 990                 $$->set_mus_property ("denominator", gh_int2scm (d));
 991                 $$->compress (Moment (Rational (n,d)));
 992
 993         }
 994         | Repeated_music                { $$ = $1; }
 995         | Simultaneous_music            { $$ = $1; }
 996         | Sequential_music              { $$ = $1; }
 997         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 998                 $$ = MY_MAKE_MUSIC("TransposedMusic");
 999                 Music *p = $4;
1000                 Pitch from = *unsmob_pitch ($2);
1001                 Pitch to = *unsmob_pitch ($3);
1002
1003                 p->transpose (interval (from, to));
1004                 $$->set_mus_property ("element", p->self_scm ());
1005                 scm_gc_unprotect_object (p->self_scm ());
1006         }
1007         | APPLY embedded_scm Music  {
1008                 if (!ly_input_procedure_p ($2))
1009                         {
1010                         THIS->parser_error (_ ("\\apply takes function argument"));
1011                         $$ = $3;
1012                         }
1013                 else
1014                         {
1015                         SCM ret = gh_call1 ($2, $3->self_scm ());
1016                         Music *m = unsmob_music (ret);
1017                         if (!m) {
1018                                 THIS->parser_error ("\\apply must return a Music");
1019                                 m = MY_MAKE_MUSIC("Music");
1020                                 }
1021                         $$ = m;
1022                         }
1023         }
1024         | NOTES
1025                 {
1026                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1027                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1028         }
1029         Music
1030                 { $$ = $3;
1031                   THIS->lexer_->pop_state ();
1032                 }
1033         | DRUMS
1034                 {
1035                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1036                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1037         }
1038         Music
1039                 { $$ = $3;
1040                   THIS->lexer_->pop_state ();
1041                 }
1042         | FIGURES
1043                 { THIS->lexer_->push_figuredbass_state (); }
1044         Music
1045                 {
1046                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1047                   chm->set_mus_property ("element", $3->self_scm ());
1048                   $$ = chm;
1049                   scm_gc_unprotect_object ($3->self_scm());
1050
1051                   THIS->lexer_->pop_state ();
1052         }
1053         | CHORDS {
1054                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1055                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1056                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1057                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1058
1059         } Music {
1060                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1061                   chm->set_mus_property ("element", $3->self_scm ());
1062                   scm_gc_unprotect_object ($3->self_scm());
1063                   $$ = chm;
1064
1065                   THIS->lexer_->pop_state ();
1066         }
1067         | LYRICS
1068                 { THIS->lexer_->push_lyric_state (); }
1069         Music
1070                 {
1071                   $$ = $3;
1072                   THIS->lexer_->pop_state ();
1073         }
1074         | relative_music        { $$ = $1; }
1075         | re_rhythmed_music     { $$ = $1; }
1076         | TAG embedded_scm Music {
1077                 tag_music ($3, $2, THIS->here_input ());
1078                 $$ = $3;
1079         }
1080         ;
1081
1082 relative_music:
1083         RELATIVE absolute_pitch Music {
1084                 Music * p = $3;
1085                 Pitch pit = *unsmob_pitch ($2);
1086                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1087
1088                 $$->set_mus_property ("element", p->self_scm ());
1089                 scm_gc_unprotect_object (p->self_scm ());
1090
1091
1092                 Pitch retpitch = p->to_relative_octave (pit);
1093                 if (lily_1_8_relative)
1094                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1095         }
1096         ;
1097
1098 re_rhythmed_music:
1099         ADDLYRICS Music Music {
1100         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1101           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1102           scm_gc_unprotect_object ($3->self_scm ());
1103           scm_gc_unprotect_object ($2->self_scm ());
1104           $$ = l;
1105         }
1106         | NEWADDLYRICS string Music {
1107           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1108           l->set_mus_property ("element", $3->self_scm ());
1109           scm_gc_unprotect_object ($3->self_scm ());
1110           $$ = l;
1111           l->set_mus_property ("associated-context", $2);
1112         }
1113         ;
1114
1115 context_change:
1116         CHANGE STRING '=' STRING  {
1117                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1118                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1119                 t-> set_mus_property ("change-to-id", $4);
1120
1121                 $$ = t;
1122                 $$->set_spot (THIS->here_input ());
1123         }
1124         ;
1125
1126 property_operation:
1127         STRING '='  scalar {
1128                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1129                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1130         }
1131         | STRING UNSET {
1132                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1133                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1134         }
1135         | STRING SET embedded_scm '=' embedded_scm {
1136                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1137                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1138         }
1139         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1140                 $$ = scm_list_n (ly_symbol2scm ("push"),
1141                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1142         }
1143         | STRING REVERT embedded_scm {
1144                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1145                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1146         }
1147         ;
1148
1149 translator_mod:
1150         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1151         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1152         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1153
1154         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1155         | DENIES { $$ = ly_symbol2scm ("denies"); }
1156
1157         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1158         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1159         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1160         | NAME { $$ = ly_symbol2scm ("context-name"); }
1161         ;
1162
1163 context_mod:
1164         property_operation { $$ = $1; }
1165         | translator_mod STRING {
1166                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1167         }
1168         ;
1169
1170 music_property_def:
1171         PROPERTY STRING '.' property_operation {
1172                 Music * t = property_op_to_music ($4);
1173                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1174
1175                 csm->set_mus_property ("element", t->self_scm ());
1176                 scm_gc_unprotect_object (t->self_scm ());
1177
1178                 $$ = csm;
1179                 $$->set_spot (THIS->here_input ());
1180
1181                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1182         }
1183         | ONCE music_property_def {
1184                 $$ = $2;
1185                 SCM e = $2->get_mus_property ("element");
1186                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1187         }
1188         ;
1189
1190
1191 scalar:
1192         string          { $$ = $1; }
1193         | bare_int      { $$ = gh_int2scm ($1); }
1194         | embedded_scm  { $$ = $1; }
1195         | full_markup {  $$ = $1; }
1196         | DIGIT { $$ = gh_int2scm ($1); }
1197         ;
1198
1199 /*
1200 This is a trick:
1201
1202 Adding pre_events to the simple_element
1203 makes the choice between
1204
1205   string:  STRING
1206
1207 and
1208
1209   simple_element: STRING
1210
1211 a single shift/reduction conflict.
1212
1213 nevertheless, this is not very clean, and we should find a different
1214 solution.
1215
1216 */
1217 pre_events: {
1218                 THIS->push_spot ();
1219         }
1220         ;
1221
1222 event_chord:
1223         pre_events simple_element post_events   {
1224                 SCM elts = $2-> get_mus_property ("elements");
1225
1226                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1227
1228                 $2->set_mus_property ("elements", elts);
1229                 $$ = $2;
1230         }
1231         | command_element
1232         | note_chord_element
1233         ;
1234
1235
1236 note_chord_element:
1237         chord_body optional_notemode_duration post_events
1238         {
1239                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1240                 SCM es = $1->get_mus_property ("elements");
1241                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1242
1243                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1244                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1245                 es = gh_append2 (es, postevs);
1246
1247                 $1-> set_mus_property ("elements", es);
1248                 $$ = $1;
1249         }
1250         ;
1251
1252 chord_open: '<'
1253         ;
1254
1255 chord_close: '>'
1256         ;
1257
1258 simul_open: LESSLESS
1259         ;
1260
1261 simul_close: MOREMORE
1262         ;
1263
1264 chord_body:
1265         chord_open chord_body_elements chord_close
1266         {
1267                 $$ = MY_MAKE_MUSIC("EventChord");
1268                 $$->set_mus_property ("elements",
1269                         scm_reverse_x ($2, SCM_EOL));
1270         }
1271         ;
1272
1273 chord_body_elements:
1274         /* empty */             { $$ = SCM_EOL; }
1275         | chord_body_elements chord_body_element {
1276                 $$ = gh_cons ($2->self_scm(), $1);
1277                 scm_gc_unprotect_object ($2->self_scm());
1278         }
1279         ;
1280
1281 chord_body_element:
1282         pitch exclamations questions post_events
1283         {
1284                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1285                 n->set_mus_property ("pitch", $1);
1286                 if ($3 % 2)
1287                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1288                 if ($2 % 2 || $3 % 2)
1289                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1290
1291                 if (gh_pair_p ($4)) {
1292                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1293                         n->set_mus_property ("articulations", arts);
1294                 }
1295                 $$ = n;
1296         }
1297         | DRUM_PITCH post_events {
1298                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1299                 n->set_mus_property ("duration" ,$2);
1300                 n->set_mus_property ("drum-type" , $1);
1301                 n->set_spot (THIS->here_input());
1302
1303                 if (gh_pair_p ($2)) {
1304                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1305                         n->set_mus_property ("articulations", arts);
1306                 }
1307                 $$ = n;
1308         }
1309         ;
1310
1311 command_element:
1312         command_req {
1313                 $$ = MY_MAKE_MUSIC("EventChord");
1314                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1315                 scm_gc_unprotect_object ($1->self_scm());
1316
1317                 $$-> set_spot (THIS->here_input ());
1318                 $1-> set_spot (THIS->here_input ());
1319         }
1320         | OCTAVE { THIS->push_spot (); }
1321           pitch {
1322                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1323                 $$ = l;
1324                 $$->set_spot (THIS->pop_spot ());
1325                 $$->set_mus_property ("pitch", $3);
1326         }
1327         | E_LEFTSQUARE {
1328                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1329                 l->set_mus_property ("span-direction", gh_int2scm (START));
1330                 l->set_spot (THIS->here_input ());
1331
1332                 $$ = MY_MAKE_MUSIC("EventChord");
1333                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1334                 scm_gc_unprotect_object (l->self_scm());
1335                 $$->set_spot (THIS->here_input ());
1336         }
1337         | E_RIGHTSQUARE {
1338                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1339                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1340                 l->set_spot (THIS->here_input ());
1341
1342                 $$ = MY_MAKE_MUSIC("EventChord");
1343                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1344                 $$->set_spot (THIS->here_input ());
1345                 scm_gc_unprotect_object (l->self_scm());
1346         }
1347         | E_BACKSLASH {
1348                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1349                 $$->set_spot (THIS->here_input ());
1350         }
1351         | '|'      {
1352
1353                 $$ = MY_MAKE_MUSIC("BarCheck");
1354                 $$->set_spot (THIS->here_input ());
1355         }
1356         | BAR STRING                    {
1357                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1358
1359                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1360                 csm->set_mus_property ("element", t->self_scm ());
1361                 scm_gc_unprotect_object (t->self_scm ());
1362
1363                 $$ = csm;
1364                 $$->set_spot (THIS->here_input ());
1365
1366                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1367         }
1368         | PARTIAL duration_length       {
1369                 Moment m = - unsmob_duration ($2)->get_length ();
1370                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1371
1372                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1373                 sp->set_mus_property ("element", p->self_scm ());
1374                 scm_gc_unprotect_object (p->self_scm ());
1375
1376                 $$ =sp ;
1377                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1378         }
1379         | CLEF STRING  {
1380                 static SCM proc ;
1381                 if (!proc)
1382                         proc = scm_c_eval_string ("make-clef-set");
1383
1384                 SCM result = scm_call_1 (proc, $2);
1385                 scm_gc_protect_object (result);
1386                 $$ = unsmob_music (result);
1387         }
1388         | TIME_T fraction  {
1389                 static SCM proc;
1390                 if (!proc)
1391                         proc = scm_c_eval_string ("make-time-signature-set");
1392
1393                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1394                 scm_gc_protect_object (result);
1395                 $$ = unsmob_music (result);
1396         }
1397         | MARK scalar {
1398                 static SCM proc;
1399                 if (!proc)
1400                         proc = scm_c_eval_string ("make-mark-set");
1401
1402                 SCM result = scm_call_1 (proc, $2);
1403                 scm_gc_protect_object (result);
1404                 $$ = unsmob_music (result);
1405         }
1406         ;
1407
1408 command_req:
1409         shorthand_command_req   { $$ = $1; }
1410         | verbose_command_req   { $$ = $1; }
1411         ;
1412
1413 shorthand_command_req:
1414         BREATHE {
1415                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1416         }
1417         | E_TILDE {
1418                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1419         }
1420         ;
1421
1422 verbose_command_req:
1423         MARK DEFAULT  {
1424                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1425                 $$ = m;
1426         }
1427
1428         | SKIP duration_length {
1429                 Music * skip = MY_MAKE_MUSIC("SkipEvent");
1430                 skip->set_mus_property ("duration", $2);
1431
1432                 $$ = skip;
1433         }
1434         | tempo_event {
1435                 $$ = $1;
1436         }
1437         | KEY DEFAULT {
1438                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1439                 $$ = key;
1440         }
1441         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1442
1443                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1444                 if (scm_ilength ($3) > 0)
1445                 {
1446                         key->set_mus_property ("pitch-alist", $3);
1447                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1448                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1449                 } else {
1450                         THIS->parser_error (_("Second argument must be pitch list."));
1451                 }
1452
1453                 $$ = key;
1454         }
1455         ;
1456
1457 post_events:
1458         /* empty */ {
1459                 $$ = SCM_EOL;
1460         }
1461         | post_events post_event {
1462                 $2->set_spot (THIS->here_input ());
1463                 $$ = gh_cons ($2->self_scm(), $$);
1464                 scm_gc_unprotect_object ($2->self_scm());
1465         }
1466         | post_events tagged_post_event {
1467                 $2 -> set_spot (THIS->here_input ());
1468                 $$ = scm_cons ($2->self_scm(), $$);
1469                 scm_gc_unprotect_object ($2->self_scm());
1470         }
1471         ;
1472
1473
1474 tagged_post_event:
1475         '-' TAG embedded_scm post_event {
1476                 tag_music ($4, $3, THIS->here_input ());
1477                 $$ = $4;
1478         }
1479         ;
1480
1481 post_event:
1482         direction_less_event {
1483                 $$ = $1;
1484         }
1485         | HYPHEN {
1486                 if (!THIS->lexer_->lyric_state_b ())
1487                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1488                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1489         }
1490         | EXTENDER {
1491                 if (!THIS->lexer_->lyric_state_b ())
1492                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1493                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1494         }
1495         | script_dir direction_reqd_event {
1496                 if ($1)
1497                         $2->set_mus_property ("direction", gh_int2scm ($1));
1498                 $$ = $2;
1499         }
1500         | script_dir direction_less_event {
1501                 if ($1)
1502                         $2->set_mus_property ("direction", gh_int2scm ($1));
1503                 $$ = $2;
1504         }
1505         | string_number_event
1506         ;
1507
1508 string_number_event:
1509         E_UNSIGNED {
1510                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1511                 s->set_mus_property ("string-number",  gh_int2scm($1));
1512                 s->set_spot (THIS->here_input ());
1513                 $$ = s;
1514         }
1515         ;
1516
1517
1518 direction_less_event:
1519         '['  {
1520
1521
1522 /*
1523
1524 TODO: should take all these defs out of the parser, adn make use
1525 configurable, i.e.
1526
1527
1528 (set-articulation '~ "trill")
1529
1530 */
1531                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1532                 m->set_spot (THIS->here_input());
1533                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1534                 $$ = m;
1535         }
1536         | ']'  {
1537                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1538                 m->set_spot (THIS->here_input());
1539                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1540                 $$ = m;
1541         }
1542         | '~' {
1543                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1544                 m->set_spot (THIS->here_input());
1545                 $$ = m;
1546         }
1547         | close_event {
1548                 $$ = $1;
1549                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1550                         gh_int2scm (START));
1551         }
1552         | open_event {
1553                 $$ = $1;
1554                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1555                         gh_int2scm (STOP));
1556         }
1557         | EVENT_IDENTIFIER      {
1558                 $$ = unsmob_music ($1);
1559         }
1560         | tremolo_type  {
1561                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1562                a->set_spot (THIS->here_input ());
1563                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1564                $$ = a;
1565         }
1566         ;
1567
1568 direction_reqd_event:
1569         gen_text_def {
1570                 $$ = $1;
1571         }
1572         | script_abbreviation {
1573                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1574                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1575                 if (gh_string_p (s))
1576                         a->set_mus_property ("articulation-type", s);
1577                 else THIS->parser_error (_ ("Expecting string as script definition"));
1578                 $$ = a;
1579         }
1580         ;
1581
1582 oct_check:
1583         /**/ { $$ = SCM_EOL; }
1584         | '='  { $$ = gh_int2scm (0); }
1585         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1586         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1587         ;
1588
1589 sup_quotes:
1590         '\'' {
1591                 $$ = 1;
1592         }
1593         | sup_quotes '\'' {
1594                 $$ ++;
1595         }
1596         ;
1597
1598 sub_quotes:
1599         ',' {
1600                 $$ = 1;
1601         }
1602         | sub_quotes ',' {
1603                 $$ ++ ;
1604         }
1605         ;
1606
1607 steno_pitch:
1608         NOTENAME_PITCH  {
1609                 $$ = $1;
1610         }
1611         | NOTENAME_PITCH sup_quotes     {
1612                 Pitch p = *unsmob_pitch ($1);
1613                 p = p.transposed (Pitch ($2,0,0));
1614                 $$ = p.smobbed_copy ();
1615         }
1616         | NOTENAME_PITCH sub_quotes      {
1617                 Pitch p =* unsmob_pitch ($1);
1618                 p = p.transposed (Pitch (-$2,0,0));
1619                 $$ = p.smobbed_copy ();
1620         }
1621         ;
1622
1623 /*
1624 ugh. duplication
1625 */
1626
1627 steno_tonic_pitch:
1628         TONICNAME_PITCH {
1629                 $$ = $1;
1630         }
1631         | TONICNAME_PITCH sup_quotes    {
1632                 Pitch p = *unsmob_pitch ($1);
1633                 p = p.transposed (Pitch ($2,0,0));
1634                 $$ = p.smobbed_copy ();
1635         }
1636         | TONICNAME_PITCH sub_quotes     {
1637                 Pitch p =* unsmob_pitch ($1);
1638
1639                 p = p.transposed (Pitch (-$2,0,0));
1640                 $$ = p.smobbed_copy ();
1641         }
1642         ;
1643
1644 pitch:
1645         steno_pitch {
1646                 $$ = $1;
1647         }
1648         ;
1649
1650 pitch_also_in_chords:
1651         pitch
1652         | steno_tonic_pitch
1653         ;
1654
1655 close_event:
1656         '('     {
1657                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1658                 $$ = s;
1659                 s->set_spot (THIS->here_input());
1660         }
1661         | E_OPEN        {
1662                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1663                 $$ = s;
1664                 s->set_spot (THIS->here_input());
1665         }
1666         | E_SMALLER {
1667                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1668                 $$ = s;
1669                 s->set_spot (THIS->here_input());
1670         }
1671         | E_BIGGER {
1672                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1673                 $$ = s;
1674                 s->set_spot (THIS->here_input());
1675         }
1676         ;
1677
1678
1679 open_event:
1680         E_EXCLAMATION   {
1681                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1682                 s->set_spot (THIS->here_input());
1683
1684                 $$ = s;
1685         }
1686         | ')'   {
1687                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1688                 $$ = s;
1689                 s->set_spot (THIS->here_input());
1690
1691         }
1692         | E_CLOSE       {
1693                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1694                 $$ = s;
1695                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1696                 s->set_spot (THIS->here_input());
1697         }
1698         ;
1699
1700 gen_text_def:
1701         full_markup {
1702                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1703                 t->set_mus_property ("text", $1);
1704                 t->set_spot (THIS->here_input ());
1705                 $$ = t;
1706         }
1707         | string {
1708                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1709                 t->set_mus_property ("text", make_simple_markup ($1));
1710                 t->set_spot (THIS->here_input ());
1711                 $$ = t;
1712
1713         }
1714         | DIGIT {
1715                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1716                 t->set_mus_property ("digit",  gh_int2scm ($1));
1717                 t->set_spot (THIS->here_input ());
1718                 $$ = t;
1719         }
1720         ;
1721
1722 script_abbreviation:
1723         '^'             {
1724                 $$ = scm_makfrom0str ("Hat");
1725         }
1726         | '+'           {
1727                 $$ = scm_makfrom0str ("Plus");
1728         }
1729         | '-'           {
1730                 $$ = scm_makfrom0str ("Dash");
1731         }
1732         | '|'           {
1733                 $$ = scm_makfrom0str ("Bar");
1734         }
1735         | '>'           {
1736                 $$ = scm_makfrom0str ("Larger");
1737         }
1738         | '.'           {
1739                 $$ = scm_makfrom0str ("Dot");
1740         }
1741         | '_' {
1742                 $$ = scm_makfrom0str ("Underscore");
1743         }
1744         ;
1745
1746 script_dir:
1747         '_'     { $$ = DOWN; }
1748         | '^'   { $$ = UP; }
1749         | '-'   { $$ = CENTER; }
1750         ;
1751
1752
1753 absolute_pitch:
1754         steno_pitch     {
1755                 $$ = $1;
1756         }
1757         ;
1758
1759 duration_length:
1760         multiplied_duration {
1761                 $$ = $1;
1762         }
1763         ;
1764
1765 optional_notemode_duration:
1766         {
1767                 Duration dd = THIS->default_duration_;
1768                 $$ = dd.smobbed_copy ();
1769
1770                 THIS->beam_check ($$);
1771         }
1772         | multiplied_duration   {
1773                 $$ = $1;
1774                 THIS->default_duration_ = *unsmob_duration ($$);
1775
1776                 THIS->beam_check ($$);
1777         }
1778         ;
1779
1780 steno_duration:
1781         bare_unsigned dots              {
1782                 int l = 0;
1783                 if (!is_duration_b ($1))
1784                         THIS->parser_error (_f ("not a duration: %d", $1));
1785                 else
1786                         l =  intlog2 ($1);
1787
1788                 $$ = Duration (l, $2).smobbed_copy ();
1789         }
1790         | DURATION_IDENTIFIER dots      {
1791                 Duration *d =unsmob_duration ($1);
1792                 Duration k (d->duration_log (),d->dot_count () + $2);
1793
1794                 *d = k;
1795                 $$ = $1;
1796         }
1797         ;
1798
1799
1800
1801
1802 multiplied_duration:
1803         steno_duration {
1804                 $$ = $1;
1805         }
1806         | multiplied_duration '*' bare_unsigned {
1807                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1808         }
1809         | multiplied_duration '*' FRACTION {
1810                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1811
1812                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1813         }
1814         ;
1815
1816 fraction:
1817         FRACTION { $$ = $1; }
1818         | UNSIGNED '/' UNSIGNED {
1819                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1820         }
1821         ;
1822
1823 dots:
1824         /* empty */     {
1825                 $$ = 0;
1826         }
1827         | dots '.' {
1828                 $$ ++;
1829         }
1830         ;
1831
1832
1833 tremolo_type:
1834         ':'     {
1835                 $$ =0;
1836         }
1837         | ':' bare_unsigned {
1838                 if (!is_duration_b ($2))
1839                         THIS->parser_error (_f ("not a duration: %d", $2));
1840                 $$ = $2;
1841         }
1842         ;
1843
1844
1845
1846 /*****************************************************************
1847                 BASS FIGURES
1848 *****************************************************************/
1849 bass_number:
1850         DIGIT   {
1851                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1852         }
1853         | UNSIGNED {
1854                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1855         }
1856         | STRING { $$ =  $1; }
1857         ;
1858
1859 bass_mod:
1860         '-'     { $$ = -2; }
1861         | '+'   { $$ = 2; }
1862         | '!'   { $$ = 0; }
1863         ;
1864
1865 bass_figure:
1866         FIGURE_SPACE {
1867                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1868                 $$ = bfr->self_scm();
1869                 scm_gc_unprotect_object ($$);
1870         }
1871         | bass_number  {
1872                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1873                 $$ = bfr->self_scm();
1874
1875                 bfr->set_mus_property ("figure", $1);
1876
1877                 scm_gc_unprotect_object ($$);
1878         }
1879         | bass_figure bass_mod {
1880                 Music *m = unsmob_music ($1);
1881                 if ($2) {
1882                         SCM salter =m->get_mus_property ("alteration");
1883                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1884                         m->set_mus_property ("alteration",
1885                                 gh_int2scm (alter + $2));
1886                 } else {
1887                         m->set_mus_property ("alteration", gh_int2scm (0));
1888                 }
1889         }
1890         ;
1891
1892 br_bass_figure:
1893         '[' bass_figure {
1894                 $$ = $2;
1895                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1896         }
1897         | bass_figure   {
1898                 $$ = $1;
1899         }
1900         | br_bass_figure ']' {
1901                 $$ = $1;
1902                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1903         }
1904         ;
1905
1906 figure_list:
1907         /**/            {
1908                 $$ = SCM_EOL;
1909         }
1910         | figure_list br_bass_figure {
1911                 $$ = scm_cons ($2, $1);
1912         }
1913         ;
1914
1915 figure_spec:
1916         FIGURE_OPEN figure_list FIGURE_CLOSE {
1917                 Music * m = MY_MAKE_MUSIC("EventChord");
1918                 $2 = scm_reverse_x ($2, SCM_EOL);
1919                 m->set_mus_property ("elements",  $2);
1920                 $$ = m->self_scm ();
1921         }
1922         ;
1923
1924
1925 optional_rest:
1926         /**/   { $$ = 0; }
1927         | REST { $$ = 1; }
1928         ;
1929
1930 simple_element:
1931         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1932
1933                 Input i = THIS->pop_spot ();
1934                 if (!THIS->lexer_->note_state_b ())
1935                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1936
1937                 Music *n = 0;
1938                 if ($6)
1939                         n =  MY_MAKE_MUSIC("RestEvent");
1940                 else
1941                         n =  MY_MAKE_MUSIC("NoteEvent");
1942
1943                 n->set_mus_property ("pitch", $1);
1944                 n->set_mus_property ("duration", $5);
1945
1946                 if (gh_number_p ($4))
1947                 {
1948                         int q = gh_scm2int ($4);
1949                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1950                 }
1951
1952                 if ($3 % 2)
1953                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1954                 if ($2 % 2 || $3 % 2)
1955                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1956
1957                 Music *v = MY_MAKE_MUSIC("EventChord");
1958                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1959                 scm_gc_unprotect_object (n->self_scm());
1960
1961                 v->set_spot (i);
1962                 n->set_spot (i);
1963                 $$ = v;
1964         }
1965         | DRUM_PITCH optional_notemode_duration {
1966                 Input i = THIS->pop_spot ();
1967
1968                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1969                 n->set_mus_property ("duration" ,$2);
1970                 n->set_mus_property ("drum-type" , $1);
1971
1972                 Music *v = MY_MAKE_MUSIC("EventChord");
1973                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1974                 scm_gc_unprotect_object (n->self_scm());
1975                 v->set_spot (i);
1976                 n->set_spot (i);
1977                 $$ = v;
1978
1979         }
1980         | figure_spec optional_notemode_duration {
1981                 Music * m = unsmob_music ($1);
1982                 Input i = THIS->pop_spot ();
1983                 m->set_spot (i);
1984                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1985                 {
1986                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1987                 }
1988                 $$ = m;
1989         }
1990         | RESTNAME optional_notemode_duration           {
1991
1992                 Input i = THIS->pop_spot ();
1993                 Music * ev = 0;
1994                 if (ly_scm2string ($1) =="s") {
1995                         /* Space */
1996                         ev = MY_MAKE_MUSIC("SkipEvent");
1997                   }
1998                 else {
1999                         ev = MY_MAKE_MUSIC("RestEvent");
2000
2001                     }
2002                 ev->set_mus_property ("duration" ,$2);
2003                 ev->set_spot (i);
2004                 Music * velt = MY_MAKE_MUSIC("EventChord");
2005                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2006                 velt->set_spot (i);
2007
2008                 scm_gc_unprotect_object (ev->self_scm());
2009
2010                 $$ = velt;
2011         }
2012         | MULTI_MEASURE_REST optional_notemode_duration         {
2013                 THIS->pop_spot ();
2014
2015                 static SCM proc ;
2016                 if (!proc)
2017                         proc = scm_c_eval_string ("make-multi-measure-rest");
2018
2019                 SCM mus = scm_call_2 (proc, $2,
2020                         make_input (THIS->here_input()));
2021                 scm_gc_protect_object (mus);
2022                 $$ = unsmob_music (mus);
2023         }
2024
2025         | lyric_element optional_notemode_duration      {
2026                 Input i = THIS->pop_spot ();
2027                 if (!THIS->lexer_->lyric_state_b ())
2028                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2029
2030                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2031                 lreq->set_mus_property ("text", $1);
2032                 lreq->set_mus_property ("duration",$2);
2033                 lreq->set_spot (i);
2034                 Music * velt = MY_MAKE_MUSIC("EventChord");
2035                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2036
2037                 $$= velt;
2038         }
2039         | new_chord {
2040                 THIS->pop_spot ();
2041
2042                 if (!THIS->lexer_->chord_state_b ())
2043                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2044                 $$ = unsmob_music ($1);
2045         }
2046         ;
2047
2048 lyric_element:
2049         full_markup { $$ = $1; }
2050         | STRING {  $$ = $1 ; }
2051         ;
2052
2053 new_chord:
2054         steno_tonic_pitch optional_notemode_duration   {
2055                 $$ = make_chord ($1, $2, SCM_EOL);
2056         }
2057         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2058                 SCM its = scm_reverse_x ($4, SCM_EOL);
2059                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2060         }
2061         ;
2062
2063 chord_items:
2064         /**/ {
2065                 $$ = SCM_EOL;
2066         }
2067         | chord_items chord_item {
2068                 $$ = gh_cons ($2, $$);
2069         }
2070         ;
2071
2072 chord_separator:
2073         CHORD_COLON {
2074                 $$ = ly_symbol2scm ("chord-colon");
2075         }
2076         | CHORD_CARET {
2077                 $$ = ly_symbol2scm ("chord-caret");
2078         }
2079         | CHORD_SLASH steno_tonic_pitch {
2080                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2081         }
2082         | CHORD_BASS steno_tonic_pitch {
2083                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2084         }
2085         ;
2086
2087 chord_item:
2088         chord_separator {
2089                 $$ = $1;
2090         }
2091         | step_numbers {
2092                 $$ = scm_reverse_x ($1, SCM_EOL);
2093         }
2094         | CHORD_MODIFIER  {
2095                 $$ = $1;
2096         }
2097         ;
2098
2099 step_numbers:
2100         step_number { $$ = gh_cons ($1, SCM_EOL); }
2101         | step_numbers '.' step_number {
2102                 $$ = gh_cons ($3, $$);
2103         }
2104         ;
2105
2106 step_number:
2107         bare_unsigned {
2108                 $$ = make_chord_step ($1, 0);
2109         }
2110         | bare_unsigned '+' {
2111                 $$ = make_chord_step ($1, SHARP);
2112         }
2113         | bare_unsigned CHORD_MINUS {
2114                 $$ = make_chord_step ($1, FLAT);
2115         }
2116         ;
2117
2118 /*
2119         UTILITIES
2120
2121 TODO: should deprecate in favor of Scheme?
2122
2123  */
2124 number_expression:
2125         number_expression '+' number_term {
2126                 $$ = scm_sum ($1, $3);
2127         }
2128         | number_expression '-' number_term {
2129                 $$ = scm_difference ($1, $3);
2130         }
2131         | number_term
2132         ;
2133
2134 number_term:
2135         number_factor {
2136                 $$ = $1;
2137         }
2138         | number_factor '*' number_factor {
2139                 $$ = scm_product ($1, $3);
2140         }
2141         | number_factor '/' number_factor {
2142                 $$ = scm_divide ($1, $3);
2143         }
2144         ;
2145
2146 number_factor:
2147         '-'  number_factor { /* %prec UNARY_MINUS */
2148                 $$ = scm_difference ($2, SCM_UNDEFINED);
2149         }
2150         | bare_number
2151         ;
2152
2153
2154 bare_number:
2155         UNSIGNED        {
2156                 $$ = gh_int2scm ($1);
2157         }
2158         | REAL          {
2159                 $$ = $1;
2160         }
2161         | NUMBER_IDENTIFIER             {
2162                 $$ = $1;
2163         }
2164         | REAL NUMBER_IDENTIFIER        {
2165                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2166         }
2167         | UNSIGNED NUMBER_IDENTIFIER    {
2168                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2169         }
2170         ;
2171
2172
2173 bare_unsigned:
2174         UNSIGNED {
2175                         $$ = $1;
2176         }
2177         | DIGIT {
2178                 $$ = $1;
2179         }
2180         ;
2181
2182 bare_int:
2183         bare_number {
2184                 if (scm_integer_p ($1) == SCM_BOOL_T)
2185                 {
2186                         int k = gh_scm2int ($1);
2187                         $$ = k;
2188                 } else
2189                 {
2190                         THIS->parser_error (_ ("need integer number arg"));
2191                         $$ = 0;
2192                 }
2193         }
2194         | '-' bare_int {
2195                 $$ = -$2;
2196         }
2197         ;
2198
2199
2200 string:
2201         STRING          {
2202                 $$ = $1;
2203         }
2204         | STRING_IDENTIFIER     {
2205                 $$ = $1;
2206         }
2207         | string '+' string {
2208                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2209         }
2210         ;
2211
2212
2213 exclamations:
2214                 { $$ = 0; }
2215         | exclamations '!'      { $$ ++; }
2216         ;
2217
2218 questions:
2219                 { $$ = 0; }
2220         | questions '?' { $$ ++; }
2221         ;
2222
2223
2224
2225 full_markup:
2226         MARKUP_IDENTIFIER {
2227                 $$ = $1;
2228         }
2229         | MARKUP
2230                 { THIS->lexer_->push_markup_state (); }
2231         markup
2232                 { $$ = $3;
2233                   THIS->lexer_->pop_state ();
2234                 }
2235         ;
2236
2237
2238 /*
2239 This should be done more dynamically if possible.
2240 */
2241 markup:
2242         STRING {
2243                 $$ = make_simple_markup ($1);
2244         }
2245         | MARKUP_HEAD_EMPTY {
2246                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2247         }
2248         | MARKUP_HEAD_MARKUP0 markup {
2249                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2250         }
2251         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2252                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2253         }
2254         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2255                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2256         }
2257         | markup_line {
2258                 $$ = $1;
2259         }
2260         | MARKUP_HEAD_LIST0 markup_list {
2261                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2262         }
2263         | MARKUP_HEAD_SCM0 embedded_scm {
2264                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2265         }
2266         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2267                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2268         }
2269         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2270                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2271         }
2272         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2273                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2274         }
2275         | MARKUP_IDENTIFIER {
2276                 $$ = $1;
2277         }
2278
2279         ;
2280
2281 markup_list:
2282         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2283         ;
2284
2285 markup_line:
2286         '{' markup_list_body '}' {
2287                 static SCM line ;
2288                 if (!line)
2289                         line = scm_c_eval_string ("line-markup");
2290
2291                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2292         }
2293         ;
2294
2295 markup_list_body:
2296         /**/ {  $$ = SCM_EOL; }
2297         | markup_list_body markup {
2298                 $$ = gh_cons ($2, $1) ;
2299         }
2300         ;
2301
2302
2303 %%
2304
2305 void
2306 My_lily_parser::set_yydebug (bool )
2307 {
2308 #if 0
2309         yydebug = 1;
2310 #endif
2311 }
2312
2313 extern My_lily_parser * current_parser;
2314
2315 void
2316 My_lily_parser::do_yyparse ()
2317 {
2318         current_parser = this;;
2319         yyparse ((void*)this);
2320 }
2321
2322
2323 /*
2324 Should make this optional?    It will also complain when you do
2325
2326         [s4]
2327
2328 which is entirely legitimate.
2329
2330 Or we can scrap it. Barchecks should detect wrong durations, and
2331 skipTypesetting speeds it up a lot.
2332 */
2333
2334 void
2335 My_lily_parser::beam_check (SCM dur)
2336 {
2337   Duration *d = unsmob_duration (dur);
2338   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2339     {
2340       Music * m = unsmob_music (last_beam_start_);
2341       m->origin ()->warning (_("Suspect duration found following this beam"));
2342     }
2343   last_beam_start_ = SCM_EOL;
2344 }
2345
2346
2347
2348
2349 /*
2350
2351 It is a little strange to have this function in this file, but
2352 otherwise, we have to import music classes into the lexer.
2353
2354 */
2355 int
2356 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2357 {
2358         if (gh_string_p (sid)) {
2359                 *destination = sid;
2360                 return STRING_IDENTIFIER;
2361         } else if (gh_number_p (sid)) {
2362                 *destination = sid;
2363                 return NUMBER_IDENTIFIER;
2364         } else if (unsmob_context_def (sid)) {
2365                 *destination = unsmob_context_def (sid)->clone_scm();
2366                 return TRANSLATOR_IDENTIFIER;
2367         } else if (unsmob_score (sid)) {
2368                 Score *sc =  new Score (*unsmob_score (sid));
2369                 *destination =sc->self_scm ();
2370                 return SCORE_IDENTIFIER;
2371         } else if (Music * mus =unsmob_music (sid)) {
2372                 *destination = unsmob_music (sid)->clone ()->self_scm();
2373                 unsmob_music (*destination)->
2374                         set_mus_property ("origin", make_input (last_input_));
2375                 return dynamic_cast<Event*> (mus)
2376                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2377         } else if (unsmob_duration (sid)) {
2378                 *destination = unsmob_duration (sid)->smobbed_copy();
2379                 return DURATION_IDENTIFIER;
2380         } else if (unsmob_music_output_def (sid)) {
2381                 Music_output_def *p = unsmob_music_output_def (sid);
2382                 p = p->clone ();
2383
2384                 *destination = p->self_scm();
2385                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2386         } else if (Text_item::markup_p (sid)) {
2387                 *destination = sid;
2388                 return MARKUP_IDENTIFIER;
2389         }
2390
2391         return -1;
2392 }
2393
2394 Music *
2395 property_op_to_music (SCM op)
2396 {
2397         Music * m = 0;
2398         SCM tag = gh_car (op);
2399         SCM symbol  = gh_cadr (op);
2400         SCM args = gh_cddr (op);
2401         SCM grob_val = SCM_UNDEFINED;
2402         SCM grob_sym = SCM_UNDEFINED;
2403         SCM val = SCM_UNDEFINED;
2404
2405         if (tag == ly_symbol2scm ("assign"))
2406                 {
2407                 m =  MY_MAKE_MUSIC("PropertySet");
2408                 val = gh_car (args);
2409                 }
2410         else if (tag == ly_symbol2scm ("unset"))
2411                 m =  MY_MAKE_MUSIC("PropertyUnset");
2412         else if (tag == ly_symbol2scm ("poppush")
2413                  || tag == ly_symbol2scm ("push"))
2414                 {
2415                 m  = MY_MAKE_MUSIC("OverrideProperty");
2416                 grob_sym = gh_car (args);
2417                 grob_val = gh_cadr (args);
2418                 }
2419         else if (tag == ly_symbol2scm ("pop")) {
2420                 m = MY_MAKE_MUSIC("RevertProperty");
2421                 grob_sym = gh_car (args);
2422                 }
2423
2424         m->set_mus_property ("symbol", symbol);
2425
2426         if (val != SCM_UNDEFINED)
2427                 m->set_mus_property ("value", val);
2428         if (grob_val != SCM_UNDEFINED)
2429                 m->set_mus_property ("grob-value", grob_val);
2430
2431         if (grob_sym != SCM_UNDEFINED)
2432                 {
2433                 bool itc = internal_type_checking_global_b;
2434                 /* UGH.
2435                 */
2436                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2437                 if (autobeam)
2438                         internal_type_checking_global_b = false;
2439                 m->set_mus_property ("grob-property", grob_sym);
2440                 if (autobeam)
2441                         internal_type_checking_global_b = itc;
2442                 }
2443
2444         if (op == ly_symbol2scm ("poppush"))
2445                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2446
2447
2448         return m;
2449 }
2450
2451 Music*
2452 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2453 {
2454         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2455
2456         csm->set_mus_property ("element", m->self_scm ());
2457         scm_gc_unprotect_object (m->self_scm ());
2458
2459         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2460         csm->set_mus_property ("property-operations", ops);
2461
2462         if (gh_string_p (id))
2463                 csm->set_mus_property ("context-id", id);
2464         return csm;
2465 }
2466
2467
2468 SCM
2469 get_next_unique_context ()
2470 {
2471         static int new_context_count;
2472
2473         char s[1024];
2474         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2475
2476         return scm_makfrom0str (s);
2477 }
2478