lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "book-paper-def.hh"
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Book_output_def *bookpaper;
 197         Output_def *outputdef;
 198         SCM scm;
 199         String *string;
 200         Music *music;
 201         Score *score;
 202         int i;
 203 }
 204 %{
 205
 206 int
 207 yylex (YYSTYPE *s, void *v)
 208 {
 209         My_lily_parser *pars = (My_lily_parser*) v;
 210         My_lily_lexer *lex = pars->lexer_;
 211
 212         lex->lexval = (void*) s;
 213         lex->prepare_for_next_token ();
 214         return lex->yylex ();
 215 }
 216
 217
 218 %}
 219
 220 %expect 3
 221
 222 /*
 223   Three shift/reduce problems:
 224
 225 2. \markup identifier.
 226
 227 3. \markup { }
 228
 229 4.  \repeat
 230         \repeat .. \alternative
 231
 232
 233     \repeat { \repeat .. \alternative }
 234
 235 or
 236
 237     \repeat { \repeat } \alternative
 238
 239 )
 240  */
 241
 242
 243 %pure_parser
 244
 245 %token ACCEPTS
 246 %token ADDQUOTE
 247 %token LYRICSTO
 248 %token ALIAS
 249 %token ALTERNATIVE
 250 %token BAR
 251 %token BOOK
 252 %token BOOKPAPER
 253 %token CHANGE
 254 %token CHORDMODIFIERS
 255 %token CHORDS
 256 %token DOUBLE_ANGLE_OPEN
 257 %token DOUBLE_ANGLE_CLOSE
 258 %token CLEF
 259 %token COMMANDSPANREQUEST
 260 %token CONSISTS
 261 %token CONSISTSEND
 262 %token CONTEXT
 263 %token DEFAULT
 264 %token DENIES
 265 %token DESCRIPTION
 266 %token EXTENDER
 267 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 268 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token LYRICS_STRING
 276 %token MARK
 277 %token MIDI
 278 %token MULTI_MEASURE_REST
 279 %token NAME
 280 %token NEWCONTEXT
 281 %token NOTES
 282 %token OCTAVE
 283 %token ONCE
 284 %token OVERRIDE SET REVERT
 285 %token PAPER
 286 %token PARTIAL
 287 %token QUOTE
 288 %token RELATIVE
 289 %token REMOVE
 290 %token REPEAT
 291 %token REST
 292 %token SCM_T
 293 %token SCORE
 294 %token SEQUENTIAL
 295 %token NEWLYRICS
 296 %token SIMULTANEOUS
 297 %token SKIP
 298 %token SPANREQUEST
 299 %token TAG
 300 %token TEMPO
 301 %token TIMES
 302 %token TIME_T
 303 %token TRANSPOSE
 304 %token TRANSPOSITION
 305 %token TYPE
 306 %token UNSET
 307 %token WITH
 308
 309 /* escaped */
 310 /* FIXME: this sucks.  The user will get to see these names:
 311     syntax error, unexpected E_CHAR:
 312                 \
 313                  %%
 314   */
 315 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 316 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 317 %token E_BACKSLASH
 318 %token <i> E_UNSIGNED
 319 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 320 %token FIGURE_SPACE
 321
 322 %token <i>      DIGIT
 323 %token <scm>    NOTENAME_PITCH
 324 %token <scm>    TONICNAME_PITCH
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DURATION_IDENTIFIER
 327 %token <scm>    FRACTION
 328 %token <id>     IDENTIFIER
 329 %token DRUMS
 330 %token <scm>    DRUM_PITCH
 331 %token <scm>    CHORD_MODIFIER
 332 %token <scm>    SCORE_IDENTIFIER
 333 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    NUMBER_IDENTIFIER
 335 %token <scm>    EVENT_IDENTIFIER
 336 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    RESTNAME
 339 %token <scm>    STRING
 340 %token <scm>    SCM_T
 341 %token <i>      UNSIGNED
 342 %token <scm>   REAL
 343
 344 %token MARKUP
 345 %token <scm> MARKUP_HEAD_MARKUP0
 346 %token <scm> MARKUP_HEAD_EMPTY
 347 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0
 349 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 353
 354 %token <scm> MUSIC_FUNCTION
 355 %token <scm> MUSIC_FUNCTION_SCM
 356 %token <scm> MUSIC_FUNCTION_MUSIC
 357 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 358 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 360 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 361
 362 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 363 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 364
 365 %type <book>    book_block book_body
 366 %type <bookpaper> book_paper_head book_paper_block book_paper_body
 367
 368 %type <i>       exclamations questions dots optional_rest
 369 %type <i>       bass_mod
 370 %type <scm>     oct_check
 371 %type <scm>     context_mod_list
 372 %type <scm>     lyric_element
 373 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 374 %type <scm>     new_lyrics
 375 %type <outputdef> output_def
 376 %type <scm>     lilypond_header lilypond_header_body
 377 %type <music>   open_event close_event
 378 %type <i>       sub_quotes sup_quotes
 379 %type <music>   toplevel_music
 380 %type <music>   simple_element event_chord command_element
 381 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 382 %type <scm>     Generic_prefix_music_scm
 383 %type <music>   Grouped_music_list
 384 %type <music>   Repeated_music
 385 %type <scm>     Alternative_music
 386 %type <i>       tremolo_type
 387 %type <i>       bare_int  bare_unsigned
 388 %type <i>       script_dir
 389 %type <scm>     identifier_init
 390 %type <scm>     simple_string
 391
 392 %type <music>   note_chord_element chord_body chord_body_element
 393 %type <scm>     chord_body_elements
 394 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 395
 396 %type <scm>     post_events
 397 %type <music>   gen_text_def direction_less_event direction_reqd_event
 398 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 399 %type <scm>     steno_tonic_pitch
 400 %type <scm>     duration_length fraction
 401
 402 %type <scm>     chord_item chord_items chord_separator new_chord
 403 %type <scm>     step_number step_numbers
 404
 405 %type <scm>     embedded_scm scalar
 406 %type <music>   Music Sequential_music Simultaneous_music
 407 %type <music>   relative_music re_rhythmed_music
 408 %type <music>   music_property_def context_change
 409 %type <scm>     context_prop_spec
 410 %type <scm>     Music_list
 411 %type <scm>     property_operation
 412 %type <scm>     context_mod context_def_mod optional_context_mod
 413 %type <outputdef>       music_output_def_body music_output_def_head
 414 %type <music>   post_event tagged_post_event
 415 %type <music>   command_req
 416 %type <music>   string_number_event
 417 %type <scm>     string bare_number number_expression number_term number_factor
 418 %type <score>   score_block score_body
 419
 420 %type <scm>     context_def_spec_block context_def_spec_body
 421 %type <music>   tempo_event
 422 %type <scm>     script_abbreviation
 423
 424
 425
 426 %left '-' '+'
 427
 428 /* We don't assign precedence to / and *, because we might need varied
 429 prec levels in different prods */
 430
 431 %left UNARY_MINUS
 432
 433 %%
 434
 435 lilypond:       /* empty */
 436         | lilypond toplevel_expression {
 437         }
 438         | lilypond assignment {
 439         }
 440         | lilypond error {
 441                 THIS->error_level_ = 1;
 442         }
 443         | lilypond INVALID      {
 444                 THIS->error_level_ = 1;
 445         }
 446         ;
 447
 448 toplevel_expression:
 449         lilypond_header {
 450                 THIS->header_ = $1;
 451         }
 452         | add_quote {
 453
 454         }
 455         | book_block {
 456                 Book *book = $1;
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 459                 scm_gc_unprotect_object (book->self_scm ());
 460         }
 461         | score_block {
 462                 Score *score = $1;
 463
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 466                 scm_gc_unprotect_object (score->self_scm ());
 467         }
 468         | toplevel_music {
 469                 Music *music = $1;
 470                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 471                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 472                 scm_gc_unprotect_object (music->self_scm ());
 473         }
 474         | output_def {
 475                 SCM id = SCM_EOL;
 476                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 477                         id = ly_symbol2scm ("$defaultpaper");
 478                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 479                         id = ly_symbol2scm ("$defaultmidi");
 480                 else if ($1->c_variable ("is-book-paper") == SCM_BOOL_T)
 481                         id = ly_symbol2scm ("$defaultbookpaper");
 482
 483                 THIS->lexer_->set_identifier (id, $1->self_scm ());
 484                 scm_gc_unprotect_object ($1->self_scm ());
 485         }
 486         | book_paper_block {
 487                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultbookpaper"), $1->self_scm ());
 488                 scm_gc_unprotect_object ($1->self_scm ());
 489         }
 490         ;
 491
 492 toplevel_music:
 493         Composite_music {
 494         }
 495         ;
 496
 497 embedded_scm:
 498         SCM_T
 499         | SCM_IDENTIFIER
 500         ;
 501
 502
 503 lilypond_header_body:
 504         {
 505                 $$ = ly_make_anonymous_module (safe_global_b);
 506                 THIS->lexer_->add_scope ($$);
 507         }
 508         | lilypond_header_body assignment  {
 509
 510         }
 511         ;
 512
 513 lilypond_header:
 514         HEADER '{' lilypond_header_body '}'     {
 515                 $$ = THIS->lexer_->remove_scope ();
 516         }
 517         ;
 518
 519
 520 /*
 521         DECLARATIONS
 522 */
 523 assignment:
 524         STRING {
 525                 THIS->push_spot ();
 526         }
 527         /* cont */ '=' identifier_init  {
 528
 529         /*
 530                 Should find generic way of associating input with objects.
 531         */
 532                 Input ip = THIS->pop_spot ();
 533
 534                 if (! is_regular_identifier ($1))
 535                 {
 536                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 537                 }
 538
 539                 THIS->lexer_->set_identifier ($1, $4);
 540
 541 /*
 542  TODO: devise standard for protection in parser.
 543
 544   The parser stack lives on the C-stack, which means that
 545 all objects can be unprotected as soon as they're here.
 546
 547 */
 548         }
 549         | embedded_scm { }
 550         ;
 551
 552
 553 identifier_init:
 554         score_block {
 555                 $$ = $1->self_scm ();
 556                 scm_gc_unprotect_object ($$);
 557         }
 558         | full_markup {
 559                 $$ = $1;
 560         }
 561         | output_def {
 562                 $$ = $1->self_scm ();
 563                 scm_gc_unprotect_object ($$);
 564         }
 565         | context_def_spec_block {
 566                 $$ = $1;
 567         }
 568         | Music  {
 569                 $$ = $1->self_scm ();
 570                 scm_gc_unprotect_object ($$);
 571         }
 572         | post_event {
 573                 $$ = $1->self_scm ();
 574                 scm_gc_unprotect_object ($$);
 575         }
 576         | number_expression {
 577                 $$ = $1;
 578         }
 579         | string {
 580                 $$ = $1;
 581         }
 582         | embedded_scm  {
 583                 $$ = $1;
 584         }
 585         ;
 586
 587 context_def_spec_block:
 588         CONTEXT '{' context_def_spec_body '}'
 589                 {
 590                 $$ = $3;
 591         }
 592         ;
 593
 594 context_def_spec_body:
 595         /**/ {
 596                 $$ = Context_def::make_scm ();
 597                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 598         }
 599         | CONTEXT_DEF_IDENTIFIER {
 600                 $$ = $1;
 601                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 602         }
 603         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 604                 Context_def*td = unsmob_context_def ($$);
 605
 606                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 607                         SCM tag = ly_caar (p);
 608
 609                         /* TODO: should make new tag "grob-definition" ? */
 610                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 611                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 612                 }
 613         }
 614         | context_def_spec_body context_mod {
 615                 unsmob_context_def ($$)->add_context_mod ($2);
 616         }
 617         ;
 618
 619
 620 book_paper_block:
 621         book_paper_body '}' {
 622                 $$ = $1;
 623         }
 624         ;
 625 book_paper_head:
 626         BOOKPAPER '{' {
 627                 $$ = get_bookpaper (THIS);
 628                 THIS->lexer_->add_scope ($$->scope_);
 629         }
 630         ;
 631
 632 book_paper_body:
 633         book_paper_head
 634         | book_paper_body assignment { }
 635         ;
 636
 637
 638
 639 book_block:
 640         BOOK {
 641                 THIS->push_spot ();
 642         }
 643         /*cont*/ '{' book_body '}'      {
 644                 THIS->pop_spot ();
 645                 $$ = $4;
 646         }
 647         ;
 648
 649 /* FIXME:
 650    * Use 'handlers' like for toplevel-* stuff?
 651    * grok \paper and \midi?  */
 652 book_body:
 653         {
 654                 $$ = new Book;
 655                 $$->set_spot (THIS->here_input ());
 656                 $$->bookpaper_ = dynamic_cast<Book_output_def*> (unsmob_book_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 657                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 658         }
 659         | book_body book_paper_block {
 660                 $$->bookpaper_ = $2;
 661                 scm_gc_unprotect_object ($2->self_scm ());
 662         }
 663         | book_body score_block {
 664                 Score *score = $2;
 665                 $$->scores_.push (score);
 666                 scm_gc_unprotect_object (score->self_scm ());
 667         }
 668         | book_body Composite_music {
 669                 Music *music = $2;
 670                 Score *score
 671                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 672                 $$->scores_.push (score);
 673                 scm_gc_unprotect_object (music->self_scm ());
 674         }
 675         | lilypond_header {
 676                 THIS->header_ = $1;
 677         }
 678         | book_body error {
 679
 680         }
 681         ;
 682
 683 score_block:
 684         SCORE {
 685                 THIS->push_spot ();
 686         }
 687         /*cont*/ '{' score_body '}'     {
 688                 THIS->pop_spot ();
 689                 $$ = $4;
 690         }
 691         ;
 692
 693 score_body:
 694         Music   {
 695                 $$ = new Score;
 696
 697                 $$->set_spot (THIS->here_input ());
 698                 SCM m = $1->self_scm ();
 699                 scm_gc_unprotect_object (m);
 700
 701                 /*
 702                         guh.
 703                 */
 704                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 705                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 706                         m = scm_call_1 (ly_car (check_funcs), m);
 707                 $$->music_ = m;
 708
 709         }
 710         | SCORE_IDENTIFIER {
 711                 $$ = new Score ( *unsmob_score ($1));
 712                 $$->set_spot (THIS->here_input ());
 713         }
 714         | score_body lilypond_header    {
 715                 $$->header_ = $2;
 716         }
 717         | score_body output_def {
 718                 $$->defs_.push ($2);
 719                 scm_gc_unprotect_object ($2->self_scm ());
 720         }
 721         | score_body error {
 722
 723         }
 724         ;
 725
 726
 727 /*
 728         MIDI
 729 */
 730 output_def:
 731         music_output_def_body '}' {
 732                 $$ = $1;
 733                 THIS->lexer_->remove_scope ();
 734                 THIS->lexer_->pop_state ();
 735         }
 736         ;
 737
 738 music_output_def_head:
 739         MIDI    {
 740                 Output_def *p = get_midi (THIS);
 741                 $$ = p;
 742                 THIS->lexer_->add_scope (p->scope_);
 743         }
 744         | PAPER         {
 745                 Output_def* p = get_paper (THIS);
 746
 747
 748                 THIS->lexer_->add_scope (p->scope_);
 749                 $$ = p;
 750         }
 751         ;
 752
 753
 754 music_output_def_body:
 755         music_output_def_head '{' {
 756                 $$ = $1;
 757                 $$->input_origin_. set_spot (THIS->here_input ());
 758                 THIS->lexer_->push_initial_state ();
 759         }
 760         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 761                 scm_gc_unprotect_object ($1->self_scm ());
 762                 Output_def *o = unsmob_output_def ($3);
 763                 o->input_origin_.set_spot (THIS->here_input ());
 764                 $$ = o;
 765                 THIS->lexer_->remove_scope ();
 766                 THIS->lexer_->add_scope (o->scope_);
 767                 THIS->lexer_->push_initial_state ();
 768         }
 769         | music_output_def_body assignment  {
 770
 771         }
 772         | music_output_def_body context_def_spec_block  {
 773                 assign_context_def ($$, $2);
 774         }
 775         | music_output_def_body tempo_event  {
 776                 /*
 777                         junk this ? there already is tempo stuff in
 778                         music.
 779                 */
 780                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 781                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 782                 set_tempo ($$, d->get_length (), m);
 783                 scm_gc_unprotect_object ($2->self_scm ());
 784         }
 785         | music_output_def_body error {
 786
 787         }
 788         ;
 789
 790 tempo_event:
 791         TEMPO steno_duration '=' bare_unsigned  {
 792                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 793                 $$->set_property ("tempo-unit", $2);
 794                 $$->set_property ("metronome-count", scm_int2num ( $4));
 795         }
 796         ;
 797
 798 /*
 799 The representation of a  list is the
 800
 801   (LIST . LAST-CONS)
 802
 803  to have  efficient append.
 804 */
 805 Music_list:
 806         /* empty */ {
 807                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 808         }
 809         | Music_list Music {
 810                 SCM s = $$;
 811                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 812                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 813                 if (ly_c_pair_p (ly_cdr (s)))
 814                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 815                 else
 816                         scm_set_car_x (s, c); /* set first cons */
 817                 scm_set_cdr_x (s, c);  /* remember last cell */
 818         }
 819         | Music_list embedded_scm {
 820         }
 821         | Music_list error {
 822         }
 823         ;
 824
 825
 826 Music:
 827         Simple_music
 828         | Composite_music
 829         ;
 830
 831 Alternative_music:
 832         /* empty */ {
 833                 $$ = SCM_EOL;
 834         }
 835         | ALTERNATIVE '{' Music_list '}' {
 836                 $$ = $3;
 837         }
 838         ;
 839
 840
 841 Repeated_music:
 842         REPEAT simple_string bare_unsigned Music Alternative_music
 843         {
 844                 Music *beg = $4;
 845                 int times = $3;
 846                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 847                 if (times < scm_ilength (alts)) {
 848                   unsmob_music (ly_car (alts))
 849                     ->origin ()->warning (
 850                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 851                   alts = ly_truncate_list (times, alts);
 852                 }
 853
 854
 855                 SCM proc = ly_scheme_function ("make-repeated-music");
 856
 857                 SCM mus = scm_call_1 (proc, $2);
 858                 scm_gc_protect_object (mus); // UGH.
 859                 Music *r = unsmob_music (mus);
 860                 if (beg)
 861                         {
 862                         r-> set_property ("element", beg->self_scm ());
 863                         scm_gc_unprotect_object (beg->self_scm ());
 864                         }
 865                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 866
 867                 r-> set_property ("elements",alts);
 868                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 869                         /*
 870                         TODO: move this code to Scheme.
 871                         */
 872
 873                         /*
 874                         we can not get durations and other stuff correct down the line, so we have to
 875                         add to the duration log here.
 876                         */
 877                         SCM func = ly_scheme_function ("shift-duration-log");
 878
 879                         int dots = ($3 % 3) ? 0 : 1;
 880                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 881
 882                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 883
 884                         if (seq) {
 885                                 int list_len = scm_ilength (seq->music_list ());
 886                                 if (list_len != 2)
 887                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 888                                 shift -= 1;
 889                                 r->compress (Moment (Rational (1, list_len)));
 890                                 }
 891                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 892
 893                 }
 894                 r->set_spot (*$4->origin ());
 895
 896                 $$ = r;
 897         }
 898         ;
 899
 900 Sequential_music:
 901         SEQUENTIAL '{' Music_list '}'           {
 902                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 903                 $$->set_property ("elements", ly_car ($3));
 904                 $$->set_spot (THIS->here_input ());
 905         }
 906         | '{' Music_list '}'            {
 907                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 908                 $$->set_property ("elements", ly_car ($2));
 909                 $$->set_spot (THIS->here_input ());
 910         }
 911         ;
 912
 913 Simultaneous_music:
 914         SIMULTANEOUS '{' Music_list '}'{
 915                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 916                 $$->set_property ("elements", ly_car ($3));
 917                 $$->set_spot (THIS->here_input ());
 918
 919         }
 920         | simul_open Music_list simul_close     {
 921                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 922                 $$->set_property ("elements", ly_car ($2));
 923                 $$->set_spot (THIS->here_input ());
 924         }
 925         ;
 926
 927 Simple_music:
 928         event_chord             { $$ = $1; }
 929         | MUSIC_IDENTIFIER {
 930                 $$ = unsmob_music ($1);
 931         }
 932         | music_property_def
 933         | context_change
 934         ;
 935
 936
 937 optional_context_mod:
 938         /**/ { $$ = SCM_EOL; }
 939         | WITH { THIS->lexer_->push_initial_state (); }
 940         '{' context_mod_list '}'
 941         {
 942                 THIS->lexer_->pop_state ();
 943                 $$ = $4;
 944         }
 945         ;
 946
 947 context_mod_list:
 948         /* */  { $$ = SCM_EOL; }
 949         | context_mod_list context_mod  {
 950                  $$ = scm_cons ($2, $1);
 951         }
 952         ;
 953
 954
 955 Composite_music:
 956         Prefix_composite_music { $$ = $1; }
 957         | Grouped_music_list { $$ = $1; }
 958         ;
 959
 960 Grouped_music_list:
 961         Simultaneous_music              { $$ = $1; }
 962         | Sequential_music              { $$ = $1; }
 963         ;
 964
 965 Generic_prefix_music_scm:
 966         MUSIC_FUNCTION {
 967                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 968         }
 969         | MUSIC_FUNCTION_SCM {
 970                 THIS->push_spot ();
 971         } embedded_scm {
 972                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 973         }
 974         | MUSIC_FUNCTION_MUSIC {
 975                 THIS->push_spot ();
 976         } Music {
 977                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 978                 scm_gc_unprotect_object ($3->self_scm ());
 979         }
 980         | MUSIC_FUNCTION_SCM_MUSIC {
 981                 THIS->push_spot ();
 982         }  embedded_scm Music {
 983                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 984                 scm_gc_unprotect_object ($4->self_scm ());
 985         }
 986         | MUSIC_FUNCTION_MUSIC_MUSIC {
 987                 THIS->push_spot ();
 988         }  Music  Music {
 989                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
 990                 scm_gc_unprotect_object ($3->self_scm ());
 991                 scm_gc_unprotect_object ($4->self_scm ());
 992         }
 993         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
 994                 THIS->push_spot ();
 995         } embedded_scm Music Music {
 996                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
 997                         $3, $4->self_scm (), $5->self_scm ());
 998                 scm_gc_unprotect_object ($5->self_scm ());
 999                 scm_gc_unprotect_object ($4->self_scm ());
1000         }
1001         ;
1002
1003 Generic_prefix_music:
1004         Generic_prefix_music_scm {
1005                 SCM func = ly_car ($1);
1006                 Input *loc = unsmob_input (ly_cadr ($1));
1007                 SCM args = ly_cddr ($1);
1008                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1009                 int k = 0;
1010                 bool ok  = true;
1011                 for (SCM s = sig, t = args;
1012                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1013                         s = ly_cdr (s), t = ly_cdr (t)) {
1014                         k++;
1015                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1016                         {
1017                                 loc->error (_f ("Argument %d failed typecheck", k));
1018                                 THIS->error_level_ = 1;
1019                                 ok = false;
1020                         }
1021                 }
1022                 SCM m = SCM_EOL;
1023                 if (ok)
1024                         m = scm_apply_0 (func, ly_cdr ($1));
1025                 if (unsmob_music (m))
1026                         {
1027                         $$ = unsmob_music (m);
1028                         scm_gc_protect_object (m);
1029                         }
1030                 else
1031                         {
1032                         if (ok)
1033                                 loc->error (_ ("Music head function should return Music object."));
1034                         $$ = MY_MAKE_MUSIC ("Music");
1035                         }
1036                 $$->set_spot (*loc);
1037         }
1038         ;
1039
1040
1041 Prefix_composite_music:
1042         Generic_prefix_music {
1043                 $$ = $1;
1044         }
1045         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1046                 $$ = context_spec_music ($2, $4, $6, $5);
1047
1048         }
1049         | CONTEXT simple_string optional_context_mod Music {
1050                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1051         }
1052         | NEWCONTEXT simple_string optional_context_mod Music {
1053                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1054                         $3);
1055         }
1056
1057         | TIMES {
1058                 THIS->push_spot ();
1059         }
1060         /* CONTINUED */
1061                 fraction Music
1062
1063         {
1064                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1065                 Music *mp = $4;
1066
1067                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1068                 $$->set_spot (THIS->pop_spot ());
1069
1070                 $$->set_property ("element", mp->self_scm ());
1071                 scm_gc_unprotect_object (mp->self_scm ());
1072                 $$->set_property ("numerator", scm_int2num (n));
1073                 $$->set_property ("denominator", scm_int2num (d));
1074                 $$->compress (Moment (Rational (n,d)));
1075
1076         }
1077         | Repeated_music                { $$ = $1; }
1078         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1079                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1080                 Music *p = $4;
1081                 Pitch from = *unsmob_pitch ($2);
1082                 Pitch to = *unsmob_pitch ($3);
1083
1084                 p->transpose (interval (from, to));
1085                 $$->set_property ("element", p->self_scm ());
1086                 scm_gc_unprotect_object (p->self_scm ());
1087         }
1088         | NOTES
1089                 {
1090                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1091                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1092         }
1093         Music
1094                 { $$ = $3;
1095                   THIS->lexer_->pop_state ();
1096                 }
1097         | DRUMS
1098                 {
1099                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1100                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1101         }
1102         /* FIXME: This used to be: */
1103         Music
1104 /*      Grouped_music_list */
1105                 { $$ = $3;
1106                   THIS->lexer_->pop_state ();
1107                 }
1108         | FIGURES
1109                 { THIS->lexer_->push_figuredbass_state (); }
1110         /* FIXME: This used to be:
1111         Music
1112         but that breaks web build
1113         */
1114         Grouped_music_list
1115                 {
1116                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1117                   chm->set_property ("element", $3->self_scm ());
1118                   $$ = chm;
1119                   scm_gc_unprotect_object ($3->self_scm ());
1120
1121                   THIS->lexer_->pop_state ();
1122         }
1123         | CHORDS {
1124                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1125                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1126                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1127                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1128
1129         }
1130         /* FIXME:
1131         Music
1132 */
1133         Grouped_music_list
1134         {
1135                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1136                   chm->set_property ("element", $3->self_scm ());
1137                   scm_gc_unprotect_object ($3->self_scm ());
1138                   $$ = chm;
1139
1140                   THIS->lexer_->pop_state ();
1141         }
1142         | LYRICS
1143                 { THIS->lexer_->push_lyric_state (); }
1144         /* FIXME:
1145         Music
1146 */
1147         Grouped_music_list
1148                 {
1149                   $$ = $3;
1150                   THIS->lexer_->pop_state ();
1151         }
1152         | relative_music        { $$ = $1; }
1153         | re_rhythmed_music     { $$ = $1; }
1154         | TAG embedded_scm Music {
1155                 tag_music ($3, $2, THIS->here_input ());
1156                 $$ = $3;
1157         }
1158         ;
1159
1160 relative_music:
1161         RELATIVE absolute_pitch Music {
1162                 Music *m = $3;
1163                 Pitch start = *unsmob_pitch ($2);
1164                 $$ = make_music_relative (start, m);
1165                 scm_gc_unprotect_object (m->self_scm ());
1166         }
1167         | RELATIVE Composite_music {
1168                 Music *m = $2;
1169                 /* FIXME: why is octave==0 and default not middleC? */
1170                 Pitch middle_c (-1, 0, 0);
1171                 $$ = make_music_relative (middle_c, m);
1172                 scm_gc_unprotect_object (m->self_scm ());
1173         }
1174         ;
1175
1176 new_lyrics:
1177         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1178         /*cont */
1179         Grouped_music_list {
1180         /* Can also use Music at the expensive of two S/Rs similar to
1181            \repeat \alternative */
1182                 THIS->lexer_->pop_state ();
1183 #if 0
1184                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1185                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1186                 $$ = music;
1187 #else
1188                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1189 #endif
1190         }
1191         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1192         Grouped_music_list {
1193                 THIS->lexer_->pop_state ();
1194                 $$ = scm_cons ($4->self_scm (), $1);
1195         }
1196         ;
1197
1198 re_rhythmed_music:
1199         Grouped_music_list new_lyrics {
1200
1201                 /* FIXME: should find out uniqueXXX name from music */
1202                 SCM name = $1->get_property ("context-id");
1203                 //if (name == SCM_EOL)
1204                 if (!ly_c_string_p (name))
1205                         name = scm_makfrom0str ("");
1206
1207                 SCM context = scm_makfrom0str ("Lyrics");
1208                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1209
1210                 SCM lst = SCM_EOL;
1211                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1212                 {
1213                         Music *music = unsmob_music (ly_car (s));
1214                         Music *com = make_lyric_combine_music (name, music);
1215                         Music *csm = context_spec_music (context,
1216                                 get_next_unique_context (), com, SCM_EOL);
1217                         lst = scm_cons (csm->self_scm (), lst);
1218                 }
1219                 /* FIXME: only first lyric music is accepted,
1220                           the rest is junked */
1221                 all->set_property ("elements", scm_cons ($1->self_scm (),
1222                         lst));
1223                 $$ = all;
1224                 scm_gc_unprotect_object ($1->self_scm ());
1225         }
1226         | LYRICSTO string Music {
1227                 Music *music = $3;
1228                 SCM name = $2;
1229                 $$ = make_lyric_combine_music (name, music);
1230                 scm_gc_unprotect_object (music->self_scm ());
1231         }
1232         ;
1233
1234 context_change:
1235         CHANGE STRING '=' STRING  {
1236                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1237                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1238                 t-> set_property ("change-to-id", $4);
1239
1240                 $$ = t;
1241                 $$->set_spot (THIS->here_input ());
1242         }
1243         ;
1244
1245 property_operation:
1246         STRING '=' scalar {
1247                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1248                         scm_string_to_symbol ($1), $3);
1249         }
1250         | UNSET simple_string {
1251                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1252                         scm_string_to_symbol ($2));
1253         }
1254         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1255                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1256                         scm_string_to_symbol ($2), $3, $5);
1257         }
1258         | REVERT simple_string embedded_scm {
1259                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1260                         scm_string_to_symbol ($2), $3);
1261         }
1262         ;
1263
1264 context_def_mod:
1265         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1266         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1267         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1268
1269         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1270         | DENIES { $$ = ly_symbol2scm ("denies"); }
1271
1272         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1273         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1274         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1275         | NAME { $$ = ly_symbol2scm ("context-name"); }
1276         ;
1277
1278 context_mod:
1279         property_operation { $$ = $1; }
1280         | context_def_mod STRING {
1281                 $$ = scm_list_2 ($1, $2);
1282         }
1283         ;
1284
1285 context_prop_spec:
1286         simple_string {
1287                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1288                         scm_string_to_symbol ($1));
1289         }
1290         | simple_string '.' simple_string {
1291                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1292                         scm_string_to_symbol ($3));
1293         }
1294         ;
1295
1296 music_property_def:
1297         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1298                 $$ = property_op_to_music (scm_list_4 (
1299                         ly_symbol2scm ("poppush"),
1300                         ly_cadr ($2),
1301                         $3, $5));
1302                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1303         }
1304         | REVERT context_prop_spec embedded_scm {
1305                 $$ = property_op_to_music (scm_list_3 (
1306                         ly_symbol2scm ("pop"),
1307                         ly_cadr ($2),
1308                         $3));
1309
1310                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1311         }
1312         | SET context_prop_spec '=' scalar {
1313                 $$ = property_op_to_music (scm_list_3 (
1314                         ly_symbol2scm ("assign"),
1315                         ly_cadr ($2),
1316                         $4));
1317                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1318         }
1319         | UNSET context_prop_spec {
1320                 $$ = property_op_to_music (scm_list_2 (
1321                         ly_symbol2scm ("unset"),
1322                         ly_cadr ($2)));
1323                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1324         }
1325         | ONCE music_property_def {
1326                 SCM e = $2->get_property ("element");
1327                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1328                 $$ = $2;
1329
1330         }
1331         ;
1332
1333
1334 string:
1335         STRING {
1336                 $$ = $1;
1337         }
1338         | STRING_IDENTIFIER {
1339                 $$ = $1;
1340         }
1341         | string '+' string {
1342                 $$ = scm_string_append (scm_list_2 ($1, $3));
1343         }
1344         ;
1345
1346 simple_string: STRING {
1347         }
1348         | LYRICS_STRING {
1349         }
1350         ;
1351
1352 scalar: string {
1353         }
1354         | LYRICS_STRING {
1355         }
1356         | bare_int {
1357                 $$ = scm_int2num ($1);
1358         }
1359         | embedded_scm {
1360         }
1361         | full_markup {
1362         }
1363         | DIGIT {
1364                 $$ = scm_int2num ($1);
1365         }
1366         ;
1367
1368 /*
1369 FIXME: remove or fix this comment.  What is `This'?
1370
1371 This is a trick:
1372
1373 Adding pre_events to the simple_element
1374 makes the choice between
1375
1376   string:  STRING
1377
1378 and
1379
1380   simple_element: STRING
1381
1382 a single shift/reduction conflict.
1383
1384 nevertheless, this is not very clean, and we should find a different
1385 solution.
1386
1387 */
1388 pre_events: {
1389                 THIS->push_spot ();
1390         }
1391         ;
1392
1393 event_chord:
1394         pre_events simple_element post_events   {
1395                 SCM elts = $2-> get_property ("elements");
1396
1397                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1398
1399                 $2->set_property ("elements", elts);
1400                 $$ = $2;
1401         }
1402         | command_element
1403         | note_chord_element
1404         ;
1405
1406
1407 note_chord_element:
1408         chord_body optional_notemode_duration post_events
1409         {
1410                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1411                 SCM es = $1->get_property ("elements");
1412                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1413
1414                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1415                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1416                 es = ly_append2 (es, postevs);
1417
1418                 $1-> set_property ("elements", es);
1419                 $$ = $1;
1420         }
1421         ;
1422
1423 chord_open: '<'
1424         ;
1425
1426 chord_close: '>'
1427         ;
1428
1429 simul_open: DOUBLE_ANGLE_OPEN
1430         ;
1431
1432 simul_close: DOUBLE_ANGLE_CLOSE
1433         ;
1434
1435 chord_body:
1436         chord_open chord_body_elements chord_close
1437         {
1438                 $$ = MY_MAKE_MUSIC ("EventChord");
1439                 $$->set_property ("elements",
1440                         scm_reverse_x ($2, SCM_EOL));
1441         }
1442         ;
1443
1444 chord_body_elements:
1445         /* empty */             { $$ = SCM_EOL; }
1446         | chord_body_elements chord_body_element {
1447                 $$ = scm_cons ($2->self_scm (), $1);
1448                 scm_gc_unprotect_object ($2->self_scm ());
1449         }
1450         ;
1451
1452 chord_body_element:
1453         pitch exclamations questions post_events
1454         {
1455                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1456                 n->set_property ("pitch", $1);
1457                 if ($3 % 2)
1458                         n->set_property ("cautionary", SCM_BOOL_T);
1459                 if ($2 % 2 || $3 % 2)
1460                         n->set_property ("force-accidental", SCM_BOOL_T);
1461
1462                 if (ly_c_pair_p ($4)) {
1463                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1464                         n->set_property ("articulations", arts);
1465                 }
1466                 $$ = n;
1467         }
1468         | DRUM_PITCH post_events {
1469                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1470                 n->set_property ("duration", $2);
1471                 n->set_property ("drum-type", $1);
1472                 n->set_spot (THIS->here_input ());
1473
1474                 if (ly_c_pair_p ($2)) {
1475                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1476                         n->set_property ("articulations", arts);
1477                 }
1478                 $$ = n;
1479         }
1480         ;
1481
1482 add_quote:
1483         ADDQUOTE string Music {
1484                 SCM adder = ly_scheme_function ("add-quotable");
1485
1486                 scm_call_2 (adder, $2, $3->self_scm ());
1487                 scm_gc_unprotect_object ($3->self_scm ());
1488         }
1489         ;
1490
1491 command_element:
1492         command_req {
1493                 $$ = MY_MAKE_MUSIC ("EventChord");
1494                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1495                 scm_gc_unprotect_object ($1->self_scm ());
1496
1497                 $$-> set_spot (THIS->here_input ());
1498                 $1-> set_spot (THIS->here_input ());
1499         }
1500         | SKIP duration_length {
1501                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1502                 skip->set_property ("duration", $2);
1503
1504                 $$ = skip;
1505         }
1506         | QUOTE STRING duration_length {
1507                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1508                 SCM evs = SCM_EOL;
1509                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1510                 {
1511                         SCM key = $2; // use symbol?
1512                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1513                 }
1514                 Music *quote = 0;
1515                 if (ly_c_vector_p (evs))
1516                 {
1517                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1518                         quote->set_property ("duration", $3);
1519                         quote->set_property ("quoted-events", evs);
1520                 } else {
1521                         THIS->here_input ().warning (_f ("Can\'t find music"));
1522                         quote = MY_MAKE_MUSIC ("Event");
1523                 }
1524                 quote->set_spot (THIS->here_input ());
1525                 $$ = quote;
1526         }
1527         | OCTAVE { THIS->push_spot (); }
1528           pitch {
1529                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1530                 $$ = m;
1531                 $$->set_spot (THIS->pop_spot ());
1532                 $$->set_property ("pitch", $3);
1533         }
1534         | E_LEFTSQUARE {
1535                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1536                 m->set_property ("span-direction", scm_int2num (START));
1537                 m->set_spot (THIS->here_input ());
1538
1539                 $$ = MY_MAKE_MUSIC ("EventChord");
1540                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1541                 scm_gc_unprotect_object (m->self_scm ());
1542                 $$->set_spot (THIS->here_input ());
1543         }
1544         | E_RIGHTSQUARE {
1545                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1546                 m->set_property ("span-direction", scm_int2num (STOP));
1547                 m->set_spot (THIS->here_input ());
1548
1549                 $$ = MY_MAKE_MUSIC ("EventChord");
1550                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1551                 $$->set_spot (THIS->here_input ());
1552                 scm_gc_unprotect_object (m->self_scm ());
1553         }
1554         | E_BACKSLASH {
1555                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1556                 $$->set_spot (THIS->here_input ());
1557         }
1558         | '|'      {
1559                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1560
1561                 if (Music * m = unsmob_music (pipe))
1562                         $$ = m->clone ();
1563                 else
1564                         $$ = MY_MAKE_MUSIC ("BarCheck");
1565
1566                 $$->set_spot (THIS->here_input ());
1567         }
1568         | TRANSPOSITION pitch {
1569                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1570                                         $2);
1571                 $$->set_spot (THIS-> here_input ());
1572                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1573                         $$, SCM_EOL);
1574         }
1575         | BAR STRING                    {
1576                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1577
1578                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1579                                         t, SCM_EOL);
1580                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1581                 $$->set_spot (THIS->here_input ());
1582                 t->set_spot (THIS->here_input ());
1583         }
1584         | PARTIAL duration_length       {
1585                 Moment m = - unsmob_duration ($2)->get_length ();
1586                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1587                 p->set_spot (THIS->here_input ());
1588                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1589                                         p, SCM_EOL);
1590                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1591                                         p, SCM_EOL);
1592                 $$ = p;
1593         }
1594         | CLEF STRING  {
1595                 SCM proc = ly_scheme_function ("make-clef-set");
1596
1597                 SCM result = scm_call_1 (proc, $2);
1598                 scm_gc_protect_object (result);
1599                 $$ = unsmob_music (result);
1600         }
1601         | TIME_T fraction  {
1602                 SCM proc= ly_scheme_function ("make-time-signature-set");
1603
1604                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1605                 scm_gc_protect_object (result);
1606                 $$ = unsmob_music (result);
1607         }
1608         | MARK scalar {
1609                 SCM proc = ly_scheme_function ("make-mark-set");
1610
1611                 SCM result = scm_call_1 (proc, $2);
1612                 scm_gc_protect_object (result);
1613                 $$ = unsmob_music (result);
1614         }
1615         ;
1616
1617 command_req:
1618         E_TILDE {
1619                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1620         }
1621         | MARK DEFAULT  {
1622                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1623                 $$ = m;
1624         }
1625         | tempo_event {
1626                 $$ = $1;
1627         }
1628         | KEY DEFAULT {
1629                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1630                 $$ = key;
1631         }
1632         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1633
1634                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1635                 if (scm_ilength ($3) > 0)
1636                 {
1637                         key->set_property ("pitch-alist", $3);
1638                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1639                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1640                 } else {
1641                         THIS->parser_error (_ ("Second argument must be pitch list."));
1642                 }
1643
1644                 $$ = key;
1645         }
1646         ;
1647
1648 post_events:
1649         /* empty */ {
1650                 $$ = SCM_EOL;
1651         }
1652         | post_events post_event {
1653                 $2->set_spot (THIS->here_input ());
1654                 $$ = scm_cons ($2->self_scm (), $$);
1655                 scm_gc_unprotect_object ($2->self_scm ());
1656         }
1657         | post_events tagged_post_event {
1658                 $2 -> set_spot (THIS->here_input ());
1659                 $$ = scm_cons ($2->self_scm (), $$);
1660                 scm_gc_unprotect_object ($2->self_scm ());
1661         }
1662         ;
1663
1664
1665 tagged_post_event:
1666         '-' TAG embedded_scm post_event {
1667                 tag_music ($4, $3, THIS->here_input ());
1668                 $$ = $4;
1669         }
1670         ;
1671
1672 post_event:
1673         direction_less_event {
1674                 $$ = $1;
1675         }
1676         | HYPHEN {
1677                 if (!THIS->lexer_->is_lyric_state ())
1678                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1679                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1680         }
1681         | EXTENDER {
1682                 if (!THIS->lexer_->is_lyric_state ())
1683                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1684                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1685         }
1686         | script_dir direction_reqd_event {
1687                 if ($1)
1688                         $2->set_property ("direction", scm_int2num ($1));
1689                 $$ = $2;
1690         }
1691         | script_dir direction_less_event {
1692                 if ($1)
1693                         $2->set_property ("direction", scm_int2num ($1));
1694                 $$ = $2;
1695         }
1696         | string_number_event
1697         ;
1698
1699 string_number_event:
1700         E_UNSIGNED {
1701                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1702                 s->set_property ("string-number", scm_int2num ($1));
1703                 s->set_spot (THIS->here_input ());
1704                 $$ = s;
1705         }
1706         ;
1707
1708
1709 direction_less_event:
1710         '['  {
1711
1712
1713 /*
1714
1715 TODO: should take all these defs out of the parser, adn make use
1716 configurable, i.e.
1717
1718
1719 (set-articulation '~ "trill")
1720
1721 */
1722                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1723                 m->set_spot (THIS->here_input ());
1724                 m->set_property ("span-direction", scm_int2num (START));
1725                 $$ = m;
1726         }
1727         | ']'  {
1728                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1729                 m->set_spot (THIS->here_input ());
1730                 m->set_property ("span-direction", scm_int2num (STOP));
1731                 $$ = m;
1732         }
1733         | '~' {
1734                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1735                 m->set_spot (THIS->here_input ());
1736                 $$ = m;
1737         }
1738         | close_event {
1739                 $$ = $1;
1740                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1741                         scm_int2num (START));
1742         }
1743         | open_event {
1744                 $$ = $1;
1745                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1746                         scm_int2num (STOP));
1747         }
1748         | EVENT_IDENTIFIER      {
1749                 $$ = unsmob_music ($1);
1750         }
1751         | tremolo_type  {
1752                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1753                a->set_spot (THIS->here_input ());
1754                a->set_property ("tremolo-type", scm_int2num ($1));
1755                $$ = a;
1756         }
1757         ;
1758
1759 direction_reqd_event:
1760         gen_text_def {
1761                 $$ = $1;
1762         }
1763         | script_abbreviation {
1764                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1765                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1766                 if (ly_c_string_p (s))
1767                         a->set_property ("articulation-type", s);
1768                 else THIS->parser_error (_ ("Expecting string as script definition"));
1769                 $$ = a;
1770         }
1771         ;
1772
1773 oct_check:
1774         /**/ { $$ = SCM_EOL; }
1775         | '='  { $$ = scm_int2num (0); }
1776         | '=' sub_quotes { $$ = scm_int2num ($2); }
1777         | '=' sup_quotes { $$ = scm_int2num ($2); }
1778         ;
1779
1780 sup_quotes:
1781         '\'' {
1782                 $$ = 1;
1783         }
1784         | sup_quotes '\'' {
1785                 $$ ++;
1786         }
1787         ;
1788
1789 sub_quotes:
1790         ',' {
1791                 $$ = 1;
1792         }
1793         | sub_quotes ',' {
1794                 $$++;
1795         }
1796         ;
1797
1798 steno_pitch:
1799         NOTENAME_PITCH  {
1800                 $$ = $1;
1801         }
1802         | NOTENAME_PITCH sup_quotes     {
1803                 Pitch p = *unsmob_pitch ($1);
1804                 p = p.transposed (Pitch ($2,0,0));
1805                 $$ = p.smobbed_copy ();
1806         }
1807         | NOTENAME_PITCH sub_quotes      {
1808                 Pitch p =* unsmob_pitch ($1);
1809                 p = p.transposed (Pitch (-$2,0,0));
1810                 $$ = p.smobbed_copy ();
1811         }
1812         ;
1813
1814 /*
1815 ugh. duplication
1816 */
1817
1818 steno_tonic_pitch:
1819         TONICNAME_PITCH {
1820                 $$ = $1;
1821         }
1822         | TONICNAME_PITCH sup_quotes    {
1823                 Pitch p = *unsmob_pitch ($1);
1824                 p = p.transposed (Pitch ($2,0,0));
1825                 $$ = p.smobbed_copy ();
1826         }
1827         | TONICNAME_PITCH sub_quotes     {
1828                 Pitch p =* unsmob_pitch ($1);
1829
1830                 p = p.transposed (Pitch (-$2,0,0));
1831                 $$ = p.smobbed_copy ();
1832         }
1833         ;
1834
1835 pitch:
1836         steno_pitch {
1837                 $$ = $1;
1838         }
1839         ;
1840
1841 pitch_also_in_chords:
1842         pitch
1843         | steno_tonic_pitch
1844         ;
1845
1846 close_event:
1847         '('     {
1848                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1849                 $$ = s;
1850                 s->set_spot (THIS->here_input ());
1851         }
1852         | E_OPEN        {
1853                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1854                 $$ = s;
1855                 s->set_spot (THIS->here_input ());
1856         }
1857         | E_SMALLER {
1858                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1859                 $$ = s;
1860                 s->set_spot (THIS->here_input ());
1861         }
1862         | E_BIGGER {
1863                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1864                 $$ = s;
1865                 s->set_spot (THIS->here_input ());
1866         }
1867         ;
1868
1869
1870 open_event:
1871         E_EXCLAMATION   {
1872                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1873                 s->set_spot (THIS->here_input ());
1874
1875                 $$ = s;
1876         }
1877         | ')'   {
1878                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1879                 $$ = s;
1880                 s->set_spot (THIS->here_input ());
1881
1882         }
1883         | E_CLOSE       {
1884                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1885                 $$ = s;
1886                 s->set_property ("span-type",
1887                         scm_makfrom0str ("phrasing-slur"));
1888                 s->set_spot (THIS->here_input ());
1889         }
1890         ;
1891
1892 gen_text_def:
1893         full_markup {
1894                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1895                 t->set_property ("text", $1);
1896                 t->set_spot (THIS->here_input ());
1897                 $$ = t;
1898         }
1899         | string {
1900                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1901                 t->set_property ("text",
1902                         make_simple_markup (THIS->lexer_->encoding (), $1));
1903                 t->set_spot (THIS->here_input ());
1904                 $$ = t;
1905
1906         }
1907         | DIGIT {
1908                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1909                 t->set_property ("digit", scm_int2num ($1));
1910                 t->set_spot (THIS->here_input ());
1911                 $$ = t;
1912         }
1913         ;
1914
1915 script_abbreviation:
1916         '^'             {
1917                 $$ = scm_makfrom0str ("Hat");
1918         }
1919         | '+'           {
1920                 $$ = scm_makfrom0str ("Plus");
1921         }
1922         | '-'           {
1923                 $$ = scm_makfrom0str ("Dash");
1924         }
1925         | '|'           {
1926                 $$ = scm_makfrom0str ("Bar");
1927         }
1928         | '>'           {
1929                 $$ = scm_makfrom0str ("Larger");
1930         }
1931         | '.'           {
1932                 $$ = scm_makfrom0str ("Dot");
1933         }
1934         | '_' {
1935                 $$ = scm_makfrom0str ("Underscore");
1936         }
1937         ;
1938
1939 script_dir:
1940         '_'     { $$ = DOWN; }
1941         | '^'   { $$ = UP; }
1942         | '-'   { $$ = CENTER; }
1943         ;
1944
1945
1946 absolute_pitch:
1947         steno_pitch     {
1948                 $$ = $1;
1949         }
1950         ;
1951
1952 duration_length:
1953         multiplied_duration {
1954                 $$ = $1;
1955         }
1956         ;
1957
1958 optional_notemode_duration:
1959         {
1960                 Duration dd = THIS->default_duration_;
1961                 $$ = dd.smobbed_copy ();
1962
1963                 THIS->beam_check ($$);
1964         }
1965         | multiplied_duration   {
1966                 $$ = $1;
1967                 THIS->default_duration_ = *unsmob_duration ($$);
1968
1969                 THIS->beam_check ($$);
1970         }
1971         ;
1972
1973 steno_duration:
1974         bare_unsigned dots              {
1975                 int len = 0;
1976                 if (!is_duration ($1))
1977                         THIS->parser_error (_f ("not a duration: %d", $1));
1978                 else
1979                         len = intlog2 ($1);
1980
1981                 $$ = Duration (len, $2).smobbed_copy ();
1982         }
1983         | DURATION_IDENTIFIER dots      {
1984                 Duration *d = unsmob_duration ($1);
1985                 Duration k (d->duration_log (), d->dot_count () + $2);
1986                 *d = k;
1987                 $$ = $1;
1988         }
1989         ;
1990
1991 multiplied_duration:
1992         steno_duration {
1993                 $$ = $1;
1994         }
1995         | multiplied_duration '*' bare_unsigned {
1996                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1997         }
1998         | multiplied_duration '*' FRACTION {
1999                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2000
2001                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2002         }
2003         ;
2004
2005 fraction:
2006         FRACTION { $$ = $1; }
2007         | UNSIGNED '/' UNSIGNED {
2008                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2009         }
2010         ;
2011
2012 dots:
2013         /* empty */     {
2014                 $$ = 0;
2015         }
2016         | dots '.' {
2017                 $$ ++;
2018         }
2019         ;
2020
2021 tremolo_type:
2022         ':'     {
2023                 $$ = 0;
2024         }
2025         | ':' bare_unsigned {
2026                 if (!is_duration ($2))
2027                         THIS->parser_error (_f ("not a duration: %d", $2));
2028                 $$ = $2;
2029         }
2030         ;
2031
2032 bass_number:
2033         DIGIT   {
2034                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2035                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2036                                 $$);
2037         }
2038         | UNSIGNED {
2039                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2040                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2041                                 $$);
2042         }
2043         | STRING { $$ = $1; }
2044         ;
2045
2046 bass_mod:
2047         '-'     { $$ = -2; }
2048         | '+'   { $$ = 2; }
2049         | '!'   { $$ = 0; }
2050         ;
2051
2052 bass_figure:
2053         FIGURE_SPACE {
2054                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2055                 $$ = bfr->self_scm ();
2056                 scm_gc_unprotect_object ($$);
2057         }
2058         | bass_number  {
2059                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2060                 $$ = bfr->self_scm ();
2061
2062                 bfr->set_property ("figure", $1);
2063
2064                 scm_gc_unprotect_object ($$);
2065         }
2066         | bass_figure bass_mod {
2067                 Music *m = unsmob_music ($1);
2068                 if ($2) {
2069                         SCM salter = m->get_property ("alteration");
2070                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2071                         m->set_property ("alteration",
2072                                 scm_int2num (alter + $2));
2073                 } else {
2074                         m->set_property ("alteration", scm_int2num (0));
2075                 }
2076         }
2077         ;
2078
2079 br_bass_figure:
2080         '[' bass_figure {
2081                 $$ = $2;
2082                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2083         }
2084         | bass_figure   {
2085                 $$ = $1;
2086         }
2087         | br_bass_figure ']' {
2088                 $$ = $1;
2089                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2090         }
2091         ;
2092
2093 figure_list:
2094         /**/            {
2095                 $$ = SCM_EOL;
2096         }
2097         | figure_list br_bass_figure {
2098                 $$ = scm_cons ($2, $1);
2099         }
2100         ;
2101
2102 figure_spec:
2103         FIGURE_OPEN figure_list FIGURE_CLOSE {
2104                 Music *m = MY_MAKE_MUSIC ("EventChord");
2105                 $2 = scm_reverse_x ($2, SCM_EOL);
2106                 m->set_property ("elements", $2);
2107                 $$ = m->self_scm ();
2108         }
2109         ;
2110
2111
2112 optional_rest:
2113         /**/   { $$ = 0; }
2114         | REST { $$ = 1; }
2115         ;
2116
2117 simple_element:
2118         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
2119
2120                 Input i = THIS->pop_spot ();
2121                 if (!THIS->lexer_->is_note_state ())
2122                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2123
2124                 Music *n = 0;
2125                 if ($6)
2126                         n = MY_MAKE_MUSIC ("RestEvent");
2127                 else
2128                         n = MY_MAKE_MUSIC ("NoteEvent");
2129
2130                 n->set_property ("pitch", $1);
2131                 n->set_property ("duration", $5);
2132
2133                 if (ly_c_number_p ($4))
2134                 {
2135                         int q = ly_scm2int ($4);
2136                         n->set_property ("absolute-octave", scm_int2num (q-1));
2137                 }
2138
2139                 if ($3 % 2)
2140                         n->set_property ("cautionary", SCM_BOOL_T);
2141                 if ($2 % 2 || $3 % 2)
2142                         n->set_property ("force-accidental", SCM_BOOL_T);
2143
2144                 Music *v = MY_MAKE_MUSIC ("EventChord");
2145                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2146                 scm_gc_unprotect_object (n->self_scm ());
2147
2148                 v->set_spot (i);
2149                 n->set_spot (i);
2150                 $$ = v;
2151         }
2152         | DRUM_PITCH optional_notemode_duration {
2153                 Input i = THIS->pop_spot ();
2154
2155                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2156                 n->set_property ("duration", $2);
2157                 n->set_property ("drum-type", $1);
2158
2159                 Music *v = MY_MAKE_MUSIC ("EventChord");
2160                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2161                 scm_gc_unprotect_object (n->self_scm ());
2162                 v->set_spot (i);
2163                 n->set_spot (i);
2164                 $$ = v;
2165
2166         }
2167         | figure_spec optional_notemode_duration {
2168                 Music *m = unsmob_music ($1);
2169                 Input i = THIS->pop_spot ();
2170                 m->set_spot (i);
2171                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2172                 {
2173                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2174                 }
2175                 $$ = m;
2176         }
2177         | RESTNAME optional_notemode_duration           {
2178
2179                 Input i = THIS->pop_spot ();
2180                 Music *ev = 0;
2181                 if (ly_scm2string ($1) == "s") {
2182                         /* Space */
2183                         ev = MY_MAKE_MUSIC ("SkipEvent");
2184                   }
2185                 else {
2186                         ev = MY_MAKE_MUSIC ("RestEvent");
2187
2188                     }
2189                 ev->set_property ("duration", $2);
2190                 ev->set_spot (i);
2191                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2192                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2193                 velt->set_spot (i);
2194
2195                 scm_gc_unprotect_object (ev->self_scm ());
2196
2197                 $$ = velt;
2198         }
2199         | MULTI_MEASURE_REST optional_notemode_duration         {
2200                 THIS->pop_spot ();
2201
2202                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2203                 SCM mus = scm_call_2 (proc, $2,
2204                         make_input (THIS->here_input ()));
2205                 scm_gc_protect_object (mus);
2206                 $$ = unsmob_music (mus);
2207         }
2208
2209         | lyric_element optional_notemode_duration      {
2210                 Input i = THIS->pop_spot ();
2211                 if (!THIS->lexer_->is_lyric_state ())
2212                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2213
2214                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2215                 lreq->set_property ("text", $1);
2216                 lreq->set_property ("duration",$2);
2217                 lreq->set_spot (i);
2218                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2219                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2220
2221                 $$= velt;
2222         }
2223         | new_chord {
2224                 THIS->pop_spot ();
2225
2226                 if (!THIS->lexer_->is_chord_state ())
2227                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2228                 $$ = unsmob_music ($1);
2229         }
2230         ;
2231
2232 lyric_element:
2233         /* FIXME: lyric flavoured markup would be better */
2234         full_markup {
2235         }
2236         | LYRICS_STRING {
2237         }
2238         ;
2239
2240 new_chord:
2241         steno_tonic_pitch optional_notemode_duration   {
2242                 $$ = make_chord ($1, $2, SCM_EOL);
2243         }
2244         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2245                 SCM its = scm_reverse_x ($4, SCM_EOL);
2246                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2247         }
2248         ;
2249
2250 chord_items:
2251         /**/ {
2252                 $$ = SCM_EOL;
2253         }
2254         | chord_items chord_item {
2255                 $$ = scm_cons ($2, $$);
2256         }
2257         ;
2258
2259 chord_separator:
2260         CHORD_COLON {
2261                 $$ = ly_symbol2scm ("chord-colon");
2262         }
2263         | CHORD_CARET {
2264                 $$ = ly_symbol2scm ("chord-caret");
2265         }
2266         | CHORD_SLASH steno_tonic_pitch {
2267                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2268         }
2269         | CHORD_BASS steno_tonic_pitch {
2270                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2271         }
2272         ;
2273
2274 chord_item:
2275         chord_separator {
2276                 $$ = $1;
2277         }
2278         | step_numbers {
2279                 $$ = scm_reverse_x ($1, SCM_EOL);
2280         }
2281         | CHORD_MODIFIER  {
2282                 $$ = $1;
2283         }
2284         ;
2285
2286 step_numbers:
2287         step_number { $$ = scm_cons ($1, SCM_EOL); }
2288         | step_numbers '.' step_number {
2289                 $$ = scm_cons ($3, $$);
2290         }
2291         ;
2292
2293 step_number:
2294         bare_unsigned {
2295                 $$ = make_chord_step ($1, 0);
2296         }
2297         | bare_unsigned '+' {
2298                 $$ = make_chord_step ($1, SHARP);
2299         }
2300         | bare_unsigned CHORD_MINUS {
2301                 $$ = make_chord_step ($1, FLAT);
2302         }
2303         ;
2304
2305 /*
2306         UTILITIES
2307
2308 TODO: should deprecate in favor of Scheme?
2309
2310  */
2311 number_expression:
2312         number_expression '+' number_term {
2313                 $$ = scm_sum ($1, $3);
2314         }
2315         | number_expression '-' number_term {
2316                 $$ = scm_difference ($1, $3);
2317         }
2318         | number_term
2319         ;
2320
2321 number_term:
2322         number_factor {
2323                 $$ = $1;
2324         }
2325         | number_factor '*' number_factor {
2326                 $$ = scm_product ($1, $3);
2327         }
2328         | number_factor '/' number_factor {
2329                 $$ = scm_divide ($1, $3);
2330         }
2331         ;
2332
2333 number_factor:
2334         '-'  number_factor { /* %prec UNARY_MINUS */
2335                 $$ = scm_difference ($2, SCM_UNDEFINED);
2336         }
2337         | bare_number
2338         ;
2339
2340
2341 bare_number:
2342         UNSIGNED        {
2343                 $$ = scm_int2num ($1);
2344         }
2345         | REAL          {
2346                 $$ = $1;
2347         }
2348         | NUMBER_IDENTIFIER             {
2349                 $$ = $1;
2350         }
2351         | REAL NUMBER_IDENTIFIER        {
2352                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2353         }
2354         | UNSIGNED NUMBER_IDENTIFIER    {
2355                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2356         }
2357         ;
2358
2359
2360 bare_unsigned:
2361         UNSIGNED {
2362                         $$ = $1;
2363         }
2364         | DIGIT {
2365                 $$ = $1;
2366         }
2367         ;
2368
2369 bare_int:
2370         bare_number {
2371                 if (scm_integer_p ($1) == SCM_BOOL_T)
2372                 {
2373                         int k = ly_scm2int ($1);
2374                         $$ = k;
2375                 } else
2376                 {
2377                         THIS->parser_error (_ ("need integer number arg"));
2378                         $$ = 0;
2379                 }
2380         }
2381         | '-' bare_int {
2382                 $$ = -$2;
2383         }
2384         ;
2385
2386 exclamations:
2387                 { $$ = 0; }
2388         | exclamations '!'      { $$ ++; }
2389         ;
2390
2391 questions:
2392                 { $$ = 0; }
2393         | questions '?' { $$ ++; }
2394         ;
2395
2396
2397
2398 full_markup:
2399         MARKUP_IDENTIFIER {
2400                 $$ = $1;
2401         }
2402         | MARKUP
2403                 { THIS->lexer_->push_markup_state (); }
2404         markup
2405                 { $$ = $3;
2406                   THIS->lexer_->pop_state ();
2407                 }
2408         ;
2409
2410
2411 /*
2412 This should be done more dynamically if possible.
2413 */
2414 markup:
2415         STRING {
2416                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2417         }
2418         | MARKUP_HEAD_EMPTY {
2419                 $$ = scm_list_1 ($1);
2420         }
2421         | MARKUP_HEAD_MARKUP0 markup {
2422                 $$ = scm_list_2 ($1, $2);
2423         }
2424         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2425                 $$ = scm_list_3 ($1, $2, $3);
2426         }
2427         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2428                 $$ = scm_list_3 ($1, $2, $3);
2429         }
2430         | markup_line {
2431                 $$ = $1;
2432         }
2433         | MARKUP_HEAD_LIST0 markup_list {
2434                 $$ = scm_list_2 ($1,$2);
2435         }
2436         | MARKUP_HEAD_SCM0 embedded_scm {
2437                 $$ = scm_list_2 ($1, $2);
2438         }
2439         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2440                 $$ = scm_list_4 ($1, $2, $3, $4);
2441         }
2442         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2443                 $$ = scm_list_4 ($1, $2, $3, $4);
2444         }
2445         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2446                 $$ = scm_list_3 ($1, $2, $3);
2447         }
2448         | MARKUP_IDENTIFIER {
2449                 $$ = $1;
2450         }
2451         | STRING_IDENTIFIER {
2452                 $$ = $1;
2453         }
2454         | {
2455                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2456                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2457         }
2458         /* cont */ score_block {
2459                 /* WIP this is a bit arbitrary,
2460                    we should also allow \book or Composite_music.
2461                    However, you'd typically want to change paper
2462                    settings, and need a \score block anyway.  */
2463
2464                 THIS->lexer_->pop_state ();
2465                 Score *score = $2;
2466                 Book *book = new Book;
2467                 book->scores_.push (score);
2468
2469                 Output_def *paper = get_paper (THIS);
2470                 book->bookpaper_ = get_bookpaper (THIS);
2471
2472                 SCM s = book->to_stencil (paper, THIS->header_);
2473                 scm_gc_unprotect_object (score->self_scm ());
2474                 scm_gc_unprotect_object (book->self_scm ());
2475                 $$ = scm_list_2 (ly_scheme_function ("stencil-markup"), s);
2476         }
2477         ;
2478
2479 markup_list:
2480         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2481         ;
2482
2483 markup_line:
2484         '{' markup_list_body '}' {
2485                 SCM line = ly_scheme_function ("line-markup");
2486
2487                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2488         }
2489         ;
2490
2491 markup_list_body:
2492         /**/ {  $$ = SCM_EOL; }
2493         | markup_list_body markup {
2494                 $$ = scm_cons ($2, $1);
2495         }
2496         ;
2497
2498
2499 %%
2500
2501 void
2502 My_lily_parser::set_yydebug (bool )
2503 {
2504 #if 0
2505         yydebug = 1;
2506 #endif
2507 }
2508
2509 void
2510 My_lily_parser::do_yyparse ()
2511 {
2512         yyparse ((void*)this);
2513 }
2514
2515
2516 /*
2517 Should make this optional?    It will also complain when you do
2518
2519         [s4]
2520
2521 which is entirely legitimate.
2522
2523 Or we can scrap it. Barchecks should detect wrong durations, and
2524 skipTypesetting speeds it up a lot.
2525 */
2526
2527 void
2528 My_lily_parser::beam_check (SCM dur)
2529 {
2530   Duration *d = unsmob_duration (dur);
2531   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2532     {
2533       Music *m = unsmob_music (last_beam_start_);
2534       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2535     }
2536   last_beam_start_ = SCM_EOL;
2537 }
2538
2539
2540
2541
2542 /*
2543
2544 It is a little strange to have this function in this file, but
2545 otherwise, we have to import music classes into the lexer.
2546
2547 */
2548 int
2549 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2550 {
2551         if (ly_c_string_p (sid)) {
2552                 *destination = sid;
2553                 return STRING_IDENTIFIER;
2554         } else if (ly_c_number_p (sid)) {
2555                 *destination = sid;
2556                 return NUMBER_IDENTIFIER;
2557         } else if (unsmob_context_def (sid)) {
2558                 *destination = unsmob_context_def (sid)->clone_scm ();
2559                 return CONTEXT_DEF_IDENTIFIER;
2560         } else if (unsmob_score (sid)) {
2561                 Score *score = new Score (*unsmob_score (sid));
2562                 *destination = score->self_scm ();
2563                 return SCORE_IDENTIFIER;
2564         } else if (Music *mus = unsmob_music (sid)) {
2565                 mus = mus->clone ();
2566                 *destination = mus->self_scm ();
2567                 unsmob_music (*destination)->
2568                         set_property ("origin", make_input (last_input_));
2569                 return dynamic_cast<Event*> (mus)
2570                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2571         } else if (unsmob_duration (sid)) {
2572                 *destination = unsmob_duration (sid)->smobbed_copy ();
2573                 return DURATION_IDENTIFIER;
2574         } else if (unsmob_output_def (sid)) {
2575                 Output_def *p = unsmob_output_def (sid);
2576                 p = p->clone ();
2577
2578                 *destination = p->self_scm ();
2579                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2580         } else if (Text_item::markup_p (sid)) {
2581                 *destination = sid;
2582                 return MARKUP_IDENTIFIER;
2583         }
2584
2585         return -1;
2586 }
2587
2588 Music *
2589 property_op_to_music (SCM op)
2590 {
2591         Music *m = 0;
2592         SCM tag = ly_car (op);
2593         SCM symbol = ly_cadr (op);
2594         SCM args = ly_cddr (op);
2595         SCM grob_val = SCM_UNDEFINED;
2596         SCM grob_sym = SCM_UNDEFINED;
2597         SCM val = SCM_UNDEFINED;
2598
2599         if (tag == ly_symbol2scm ("assign"))
2600                 {
2601                 m = MY_MAKE_MUSIC ("PropertySet");
2602                 val = ly_car (args);
2603                 }
2604         else if (tag == ly_symbol2scm ("unset"))
2605                 m = MY_MAKE_MUSIC ("PropertyUnset");
2606         else if (tag == ly_symbol2scm ("poppush")
2607                  || tag == ly_symbol2scm ("push"))
2608                 {
2609                 m = MY_MAKE_MUSIC ("OverrideProperty");
2610                 grob_sym = ly_car (args);
2611                 grob_val = ly_cadr (args);
2612                 }
2613         else if (tag == ly_symbol2scm ("pop")) {
2614                 m = MY_MAKE_MUSIC ("RevertProperty");
2615                 grob_sym = ly_car (args);
2616                 }
2617
2618         m->set_property ("symbol", symbol);
2619
2620         if (val != SCM_UNDEFINED)
2621                 m->set_property ("value", val);
2622         if (grob_val != SCM_UNDEFINED)
2623                 m->set_property ("grob-value", grob_val);
2624
2625         if (grob_sym != SCM_UNDEFINED)
2626                 {
2627                 bool itc = internal_type_checking_global_b;
2628                 /* UGH.
2629                 */
2630                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2631                 if (autobeam)
2632                         internal_type_checking_global_b = false;
2633                 m->set_property ("grob-property", grob_sym);
2634                 if (autobeam)
2635                         internal_type_checking_global_b = itc;
2636                 }
2637
2638         if (tag == ly_symbol2scm ("poppush"))
2639                 m->set_property ("pop-first", SCM_BOOL_T);
2640
2641
2642         return m;
2643 }
2644
2645 Music*
2646 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2647 {
2648         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2649
2650         csm->set_property ("element", m->self_scm ());
2651         scm_gc_unprotect_object (m->self_scm ());
2652
2653         csm->set_property ("context-type",
2654                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2655         csm->set_property ("property-operations", ops);
2656
2657         if (ly_c_string_p (id))
2658                 csm->set_property ("context-id", id);
2659         return csm;
2660 }
2661
2662 SCM
2663 get_next_unique_context ()
2664 {
2665         static int new_context_count;
2666         char s[1024];
2667         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2668         return scm_makfrom0str (s);
2669 }
2670