lily/parser.yy

   1 /*
   2   parser.yy -- Bison/C++ parser for LilyPond
   3
   4   source file of the GNU LilyPond music typesetter
   5
   6   (c) 1997--2005 Han-Wen Nienhuys <hanwen@xs4all.nl>
   7                  Jan Nieuwenhuizen <janneke@gnu.org>
   8 */
   9
  10 %{
  11
  12 #define YYERROR_VERBOSE 1
  13 #define YYPARSE_PARAM my_lily_parser
  14 #define YYLEX_PARAM my_lily_parser
  15 #define THIS\
  16         ((Lily_parser *) my_lily_parser)
  17
  18 #define yyerror THIS->parser_error
  19
  20 /* We use custom location type: Input objects */
  21 #define YYLTYPE Input
  22 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  23         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  24
  25
  26 %}
  27
  28 /* We use SCMs to do strings, because it saves us the trouble of
  29 deleting them.  Let's hope that a stack overflow doesnt trigger a move
  30 of the parse stack onto the heap. */
  31
  32 %left PREC_TOP
  33 %left ADDLYRICS
  34 %left PREC_BOT
  35
  36 %expect 1
  37
  38 /* One shift/reduce problem
  39
  40 1.  \repeat
  41         \repeat .. \alternative
  42
  43     \repeat { \repeat .. \alternative }
  44
  45 or
  46
  47     \repeat { \repeat } \alternative
  48 */
  49
  50
  51 %pure_parser
  52 %locations
  53
  54
  55
  56 %{ // -*-Fundamental-*-
  57
  58 /*
  59 FIXME:
  60
  61    * The rules for who is protecting what are very shady.  Uniformise
  62      this.
  63
  64    * There are too many lexical modes?
  65 */
  66
  67 #include "config.hh"
  68
  69 #include <cctype>
  70 #include <cstdlib>
  71 #include <cstdio>
  72 using namespace std;
  73
  74 #include "book.hh"
  75 #include "context-def.hh"
  76 #include "dimensions.hh"
  77 #include "music.hh"
  78 #include "file-path.hh"
  79 #include "input-smob.hh"
  80 #include "input.hh"
  81 #include "lily-guile.hh"
  82 #include "lilypond-input-version.hh"
  83 #include "main.hh"
  84 #include "misc.hh"
  85 #include "lily-lexer.hh"
  86 #include "lily-parser.hh"
  87 #include "paper-book.hh"
  88 #include "output-def.hh"
  89 #include "scm-hash.hh"
  90 #include "program-option.hh"
  91 #include "score.hh"
  92 #include "text-interface.hh"
  93 #include "warn.hh"
  94 #include "music.hh"
  95
  96 %}
  97
  98
  99 %union {
 100         Book *book;
 101         Output_def *outputdef;
 102         SCM scm;
 103         String *string;
 104         Music *music;
 105         Score *score;
 106         int i;
 107 }
 108
 109 %{
 110
 111 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
 112
 113 Music *property_op_to_music (SCM op);
 114 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
 115 SCM get_next_unique_context_id ();
 116 SCM get_next_unique_lyrics_context_id ();
 117
 118 #undef _
 119 #if !HAVE_GETTEXT
 120 #define _(x) x
 121 #else
 122 #include <libintl.h>
 123 #define _(x) gettext (x)
 124 #endif
 125
 126
 127
 128 Music *make_lyric_combine_music (SCM name, Music *music);
 129 Music *make_music_relative (Pitch start, Music *music);
 130 Music *run_music_function (Lily_parser *, SCM expr);
 131 Music *set_property_music (SCM sym, SCM value);
 132 SCM get_first_context_id (SCM type, Music *m);
 133 SCM make_chord (SCM pitch, SCM dur, SCM modification_list);
 134 SCM make_chord_step (int step, int alter);
 135 SCM make_simple_markup (SCM a);
 136 bool is_duration (int t);
 137 bool is_regular_identifier (SCM id);
 138 bool ly_input_procedure_p (SCM x);
 139 int yylex (YYSTYPE *s, YYLTYPE *loc, void *v);
 140 void set_music_properties (Music *p, SCM a);
 141
 142 %}
 143
 144 /* The third option is an alias that will be used to display the
 145    syntax error.  Bison CVS now correctly handles backslash escapes.
 146
 147    FIXME: Bison needs to translate some of these, eg, STRING.
 148
 149 */
 150
 151 /* Keyword tokens with plain escaped name.  */
 152 %token ACCEPTS "\\accepts"
 153 %token ADDLYRICS "\\addlyrics"
 154 %token ADDQUOTE "\\addquote"
 155 %token ALIAS "\\alias"
 156 %token ALTERNATIVE "\\alternative"
 157 %token BOOK "\book"
 158 %token CHANGE "\\change"
 159 %token CHORDMODE "\\chordmode"
 160 %token CHORDS "\\chords"
 161 %token CONSISTS "\\consists"
 162 %token CONTEXT "\\context"
 163 %token DEFAULT "\\default"
 164 %token DEFAULTCHILD "\\defaultchild"
 165 %token DENIES "\\denies"
 166 %token DESCRIPTION "\\description"
 167 %token DRUMMODE "\\drummode"
 168 %token DRUMS "\\drums"
 169 %token FIGUREMODE "\\figuremode"
 170 %token FIGURES "\\figures"
 171 %token GROBDESCRIPTIONS "\\grobdescriptions"
 172 %token HEADER "\\header"
 173 %token INVALID "\\invalid"
 174 %token KEY "\\key"
 175 %token LAYOUT "\\layout"
 176 %token LYRICMODE "\\lyricmode"
 177 %token LYRICS "\\lyrics"
 178 %token LYRICSTO "\\lyricsto"
 179 %token MARK "\\mark"
 180 %token MARKUP "\\markup"
 181 %token MIDI "\\midi"
 182 %token NAME "\\name"
 183 %token NOTEMODE "\\notemode"
 184 %token OBJECTID "\\objectid"
 185 %token OCTAVE "\\octave"
 186 %token ONCE "\\once"
 187 %token OVERRIDE "\\override"
 188 %token PAPER "\\paper"
 189 %token PARTIAL "\\partial"
 190 %token RELATIVE "\\relative"
 191 %token REMOVE "\\remove"
 192 %token REPEAT "\\repeat"
 193 %token REST "\\rest"
 194 %token REVERT "\\revert"
 195 %token SCORE "\\score"
 196 %token SEQUENTIAL "\\sequential"
 197 %token SET "\\set"
 198 %token SIMULTANEOUS "\\simultaneous"
 199 %token SKIP "\\skip"
 200 %token TEMPO "\\tempo"
 201 %token TIMES "\\times"
 202 %token TRANSPOSE "\\transpose"
 203 %token TRANSPOSITION "\\transposition"
 204 %token TYPE "\\type"
 205 %token UNSET "\\unset"
 206 %token WITH "\\with"
 207
 208 /* Keyword token exceptions.  */
 209 %token TIME_T "\\time"
 210 %token NEWCONTEXT "\\new"
 211
 212
 213 /* Other string tokens.  */
 214
 215 %token CHORD_BASS "/+"
 216 %token CHORD_CARET "^"
 217 %token CHORD_COLON ":"
 218 %token CHORD_MINUS "-"
 219 %token CHORD_SLASH "/"
 220 %token DOUBLE_ANGLE_CLOSE ">>"
 221 %token DOUBLE_ANGLE_OPEN "<<"
 222 %token E_BACKSLASH "\\"
 223 %token E_ANGLE_CLOSE "\\>"
 224 %token E_CHAR "\\C[haracter]"
 225 %token E_CLOSE "\\)"
 226 %token E_EXCLAMATION "\\!"
 227 %token E_BRACKET_OPEN "\\["
 228 %token E_OPEN "\\("
 229 %token E_BRACKET_CLOSE "\\]"
 230 %token E_ANGLE_OPEN "\\<"
 231 %token E_PLUS "\\+"
 232 %token E_TILDE "\\~"
 233 %token EXTENDER "__"
 234
 235 /*
 236 If we give names, Bison complains.
 237 */
 238 %token FIGURE_CLOSE /* "\\>" */
 239 %token FIGURE_OPEN /* "\\<" */
 240 %token FIGURE_SPACE "_"
 241 %token HYPHEN "--"
 242
 243 %token CHORDMODIFIERS
 244 %token LYRIC_MARKUP
 245 %token MULTI_MEASURE_REST
 246 %token SCM_T
 247
 248
 249 %token <i> DIGIT
 250 %token <i> E_UNSIGNED
 251 %token <i> UNSIGNED
 252
 253 %token <scm> BOOK_IDENTIFIER
 254 %token <scm> CHORDMODIFIER_PITCH
 255 %token <scm> CHORD_MODIFIER
 256 %token <scm> CONTEXT_DEF_IDENTIFIER
 257 %token <scm> DRUM_PITCH
 258 %token <scm> DURATION_IDENTIFIER
 259 %token <scm> EVENT_IDENTIFIER
 260 %token <scm> FRACTION
 261 %token <scm> LYRICS_STRING
 262 %token <scm> LYRIC_MARKUP_IDENTIFIER
 263 %token <scm> MARKUP_HEAD_EMPTY
 264 %token <scm> MARKUP_HEAD_LIST0
 265 %token <scm> MARKUP_HEAD_MARKUP0
 266 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 267 %token <scm> MARKUP_HEAD_SCM0
 268 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 269 %token <scm> MARKUP_HEAD_SCM0_SCM1
 270 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 271 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 272 %token <scm> MARKUP_IDENTIFIER
 273 %token <scm> MUSIC_FUNCTION
 274 %token <scm> MUSIC_FUNCTION_MARKUP
 275 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 276 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 277 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 278 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 279 %token <scm> MUSIC_FUNCTION_MUSIC
 280 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 281 %token <scm> MUSIC_FUNCTION_SCM
 282 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 283 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 284 %token <scm> MUSIC_FUNCTION_SCM_SCM
 285 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 286 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 287 %token <scm> MUSIC_IDENTIFIER
 288 %token <scm> NOTENAME_PITCH
 289 %token <scm> NUMBER_IDENTIFIER
 290 %token <scm> OUTPUT_DEF_IDENTIFIER
 291 %token <scm> REAL
 292 %token <scm> RESTNAME
 293 %token <scm> SCM_IDENTIFIER
 294 %token <scm> SCM_T
 295 %token <scm> SCORE_IDENTIFIER
 296 %token <scm> STRING
 297 %token <scm> STRING_IDENTIFIER
 298 %token <scm> TONICNAME_PITCH
 299
 300
 301 %type <book> book_block
 302 %type <book> book_body
 303
 304 %type <i> bare_unsigned
 305 %type <i> figured_bass_alteration
 306 %type <i> dots
 307 %type <i> exclamations
 308 %type <i> optional_rest
 309 %type <i> questions
 310 %type <i> script_dir
 311 %type <i> sub_quotes
 312 %type <i> sup_quotes
 313 %type <i> tremolo_type
 314
 315 %type <music> Composite_music
 316 %type <music> Grouped_music_list
 317 %type <music> Music
 318 %type <music> Prefix_composite_music
 319 %type <music> Repeated_music
 320 %type <music> Sequential_music
 321 %type <music> Simple_music
 322 %type <music> Simultaneous_music
 323 %type <music> chord_body
 324 %type <music> chord_body_element
 325 %type <music> command_element
 326 %type <music> command_event
 327 %type <music> context_change
 328 %type <music> direction_less_event
 329 %type <music> direction_reqd_event
 330 %type <music> event_chord
 331 %type <music> gen_text_def
 332 %type <music> music_property_def
 333 %type <music> note_chord_element
 334 %type <music> post_event
 335 %type <music> re_rhythmed_music
 336 %type <music> relative_music
 337 %type <music> simple_element
 338 %type <music> string_number_event
 339 %type <music> tempo_event
 340 %type <music> toplevel_music
 341
 342 %type <outputdef> output_def_body
 343 %type <outputdef> output_def_head
 344 %type <outputdef> output_def
 345 %type <outputdef> paper_block
 346
 347 %type <scm> Alternative_music
 348 %type <scm> Generic_prefix_music_scm
 349 %type <scm> Music_list
 350 %type <scm> absolute_pitch
 351 %type <scm> assignment_id
 352 %type <scm> bare_number
 353 %type <scm> music_function_event
 354 %type <scm> music_function_chord_body
 355 %type <scm> bass_figure
 356 %type <scm> figured_bass_modification
 357 %type <scm> br_bass_figure
 358 %type <scm> bass_number
 359 %type <scm> chord_body_elements
 360 %type <scm> chord_item
 361 %type <scm> chord_items
 362 %type <scm> chord_separator
 363 %type <scm> context_def_mod
 364 %type <scm> context_def_spec_block
 365 %type <scm> context_def_spec_body
 366 %type <scm> context_mod
 367 %type <scm> context_mod_list
 368 %type <scm> context_prop_spec
 369 %type <scm> direction_less_char
 370 %type <scm> duration_length
 371 %type <scm> embedded_scm
 372 %type <scm> figure_list
 373 %type <scm> figure_spec
 374 %type <scm> fraction
 375 %type <scm> full_markup
 376 %type <scm> identifier_init
 377 %type <scm> lilypond_header
 378 %type <scm> lilypond_header_body
 379 %type <scm> lyric_element
 380 %type <scm> lyric_markup
 381 %type <scm> markup
 382 %type <scm> markup_braced_list
 383 %type <scm> markup_braced_list_body
 384 %type <scm> markup_composed_list
 385 %type <scm> markup_head_1_item
 386 %type <scm> markup_head_1_list
 387 %type <scm> markup_list
 388 %type <scm> markup_top
 389 %type <scm> mode_changing_head
 390 %type <scm> mode_changing_head_with_context
 391 %type <scm> multiplied_duration
 392 %type <scm> new_chord
 393 %type <scm> new_lyrics
 394 %type <scm> number_expression
 395 %type <scm> number_factor
 396 %type <scm> number_term
 397 %type <scm> object_id_setting
 398 %type <scm> octave_check
 399 %type <scm> optional_context_mod
 400 %type <scm> optional_notemode_duration
 401 %type <scm> pitch
 402 %type <scm> pitch_also_in_chords
 403 %type <scm> post_events
 404 %type <scm> property_operation
 405 %type <scm> scalar
 406 %type <scm> script_abbreviation
 407 %type <scm> simple_markup
 408 %type <scm> simple_string
 409 %type <scm> steno_duration
 410 %type <scm> steno_pitch
 411 %type <scm> steno_tonic_pitch
 412 %type <scm> step_number
 413 %type <scm> step_numbers
 414 %type <scm> string
 415 %type <scm> function_scm_argument
 416
 417 %type <score> score_block
 418 %type <score> score_body
 419
 420
 421 %left '-' '+'
 422
 423 /* We don't assign precedence to / and *, because we might need varied
 424 prec levels in different prods */
 425
 426 %left UNARY_MINUS
 427
 428 %%
 429
 430 lilypond:       /* empty */
 431         | lilypond toplevel_expression {
 432         }
 433         | lilypond assignment {
 434         }
 435         | lilypond error {
 436                 THIS->error_level_ = 1;
 437         }
 438         | lilypond INVALID      {
 439                 THIS->error_level_ = 1;
 440         }
 441         ;
 442
 443
 444 object_id_setting:
 445         OBJECTID STRING { $$ = $2; }
 446         ;
 447
 448 toplevel_expression:
 449         lilypond_header {
 450                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 451         }
 452         | add_quote {
 453
 454         }
 455         | book_block {
 456                 Book *book = $1;
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 459                 book->unprotect ();
 460         }
 461         | score_block {
 462                 Score *score = $1;
 463
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 466                 score->unprotect ();
 467         }
 468         | toplevel_music {
 469                 Music *music = $1;
 470                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 471                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 472                 music->unprotect ();
 473         }
 474         | full_markup {
 475                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 476                 scm_call_2 (proc, THIS->self_scm (), $1);
 477         }
 478         | output_def {
 479                 SCM id = SCM_EOL;
 480                 Output_def * od = $1;
 481
 482                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 483                         id = ly_symbol2scm ("$defaultpaper");
 484                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 485                         id = ly_symbol2scm ("$defaultmidi");
 486                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 487                         id = ly_symbol2scm ("$defaultlayout");
 488
 489                 THIS->lexer_->set_identifier (id, od->self_scm ());
 490                 od->unprotect();
 491         }
 492         ;
 493
 494 toplevel_music:
 495         Composite_music {
 496         }
 497         ;
 498
 499 embedded_scm:
 500         SCM_T
 501         | SCM_IDENTIFIER
 502         ;
 503
 504
 505 lilypond_header_body:
 506         {
 507                 $$ = get_header(THIS);
 508                 THIS->lexer_->add_scope ($$);
 509         }
 510         | lilypond_header_body assignment  {
 511
 512         }
 513         ;
 514
 515 lilypond_header:
 516         HEADER '{' lilypond_header_body '}'     {
 517                 $$ = THIS->lexer_->remove_scope ();
 518         }
 519         ;
 520
 521 /*
 522         DECLARATIONS
 523 */
 524 assignment_id:
 525         STRING          { $$ = $1; }
 526         | LYRICS_STRING { $$ = $1; }
 527         ;
 528
 529 assignment:
 530         assignment_id '=' identifier_init  {
 531                 if (! is_regular_identifier ($1))
 532                 {
 533                         @1.warning (_ ("identifier should have alphabetic characters only"));
 534                 }
 535
 536                 THIS->lexer_->set_identifier ($1, $3);
 537
 538 /*
 539  TODO: devise standard for protection in parser.
 540
 541   The parser stack lives on the C-stack, which means that
 542 all objects can be unprotected as soon as they're here.
 543
 544 */
 545         }
 546         | embedded_scm { }
 547         ;
 548
 549
 550 identifier_init:
 551         score_block {
 552                 $$ = $1->self_scm ();
 553                 $1->unprotect ();
 554         }
 555         | book_block {
 556                 $$ = $1->self_scm ();
 557                 $1->unprotect ();
 558         }
 559         | output_def {
 560                 $$ = $1->self_scm ();
 561                 $1->unprotect ();
 562         }
 563         | context_def_spec_block {
 564                 $$ = $1;
 565         }
 566         | Music  {
 567                 $$ = $1->self_scm ();
 568                 $1->unprotect();
 569         }
 570         | post_event {
 571                 $$ = $1->self_scm ();
 572                 $1->unprotect();
 573         }
 574         | number_expression {
 575                 $$ = $1;
 576         }
 577         | string {
 578                 $$ = $1;
 579         }
 580         | embedded_scm {
 581                 $$ = $1;
 582         }
 583         | full_markup {
 584                 $$ = $1;
 585         }
 586         | DIGIT {
 587                 $$ = scm_from_int ($1);
 588         }
 589         ;
 590
 591 context_def_spec_block:
 592         CONTEXT '{' context_def_spec_body '}'
 593                 {
 594                 $$ = $3;
 595         }
 596         ;
 597
 598 context_def_spec_body:
 599         /**/ {
 600                 $$ = Context_def::make_scm ();
 601                 unsmob_context_def ($$)->set_spot (@$);
 602         }
 603         | CONTEXT_DEF_IDENTIFIER {
 604                 $$ = $1;
 605                 unsmob_context_def ($$)->set_spot (@$);
 606         }
 607         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 608                 Context_def*td = unsmob_context_def ($$);
 609
 610                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 611                         SCM tag = scm_caar (p);
 612
 613                         /* TODO: should make new tag "grob-definition" ? */
 614                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 615                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 616                 }
 617         }
 618         | context_def_spec_body context_mod {
 619                 unsmob_context_def ($$)->add_context_mod ($2);
 620         }
 621         ;
 622
 623
 624
 625 book_block:
 626         BOOK '{' book_body '}'  {
 627                 $$ = $3;
 628         }
 629         ;
 630
 631 /* FIXME:
 632    * Use 'handlers' like for toplevel-* stuff?
 633    * grok \layout and \midi?  */
 634 book_body:
 635         {
 636                 $$ = new Book;
 637                 $$->set_spot (@$);
 638                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 639                 $$->paper_->unprotect ();
 640                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 641         }
 642         | BOOK_IDENTIFIER {
 643                 $$ = unsmob_book ($1);
 644                 $$->set_spot (@$);
 645         }
 646         | book_body paper_block {
 647                 $$->paper_ = $2;
 648                 $2->unprotect ();
 649         }
 650         | book_body score_block {
 651                 SCM s = $2->self_scm ();
 652                 $$->add_score (s);
 653                 $2->unprotect();
 654         }
 655         | book_body full_markup {
 656                 $$->add_score ($2);
 657         }
 658         | book_body lilypond_header {
 659                 $$->header_ = $2;
 660         }
 661         | book_body error {
 662                 $$->paper_ = 0;
 663                 $$->scores_ = SCM_EOL;
 664         }
 665         | book_body object_id_setting {
 666                 $$->user_key_ = ly_scm2string ($2);
 667         }
 668         ;
 669
 670 score_block:
 671         SCORE '{' score_body '}'        {
 672                 $$ = $3;
 673         }
 674         ;
 675
 676 score_body:
 677         Music {
 678                 SCM m = $1->self_scm ();
 679                 $1->unprotect();
 680                 SCM scorify = ly_lily_module_constant ("scorify-music");
 681                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 682
 683                 // pass ownernship to C++ again.
 684                 $$ = unsmob_score (score);
 685                 $$->protect ();
 686                 $$->set_spot (@$);
 687         }
 688         | SCORE_IDENTIFIER {
 689                 $$ = unsmob_score ($1);
 690                 $$->set_spot (@$);
 691         }
 692         | score_body object_id_setting {
 693                 $$->user_key_ = ly_scm2string ($2);
 694         }
 695         | score_body lilypond_header    {
 696                 $$->header_ = $2;
 697         }
 698         | score_body output_def {
 699                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 700                 {
 701                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 702
 703                 }
 704                 else
 705                 {
 706                         $$->defs_.push ($2);
 707                 }
 708                 $2->unprotect ();
 709         }
 710         | score_body error {
 711                 $$->error_found_ = true;
 712         }
 713         ;
 714
 715
 716 /*
 717         OUTPUT DEF
 718 */
 719
 720 paper_block:
 721         output_def {
 722                 $$ = $1;
 723                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 724                 {
 725                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 726                         $$ = get_paper (THIS);
 727                 }
 728         }
 729         ;
 730
 731
 732 output_def:
 733         output_def_body '}' {
 734                 $$ = $1;
 735
 736                 THIS->lexer_->remove_scope ();
 737                 THIS->lexer_->pop_state ();
 738         }
 739         ;
 740
 741 output_def_head:
 742         PAPER {
 743                 $$ = get_paper (THIS);
 744                 $$->input_origin_ = @$;
 745                 THIS->lexer_->add_scope ($$->scope_);
 746         }
 747         | MIDI    {
 748                 Output_def *p = get_midi (THIS);
 749                 $$ = p;
 750                 THIS->lexer_->add_scope (p->scope_);
 751         }
 752         | LAYOUT        {
 753                 Output_def *p = get_layout (THIS);
 754
 755                 THIS->lexer_->add_scope (p->scope_);
 756                 $$ = p;
 757         }
 758         ;
 759
 760
 761 output_def_body:
 762         output_def_head '{' {
 763                 $$ = $1;
 764                 $$->input_origin_.set_spot (@$);
 765                 THIS->lexer_->push_initial_state ();
 766         }
 767         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 768                 $1->unprotect ();
 769                 Output_def *o = unsmob_output_def ($3);
 770                 o->input_origin_.set_spot (@$);
 771                 $$ = o;
 772                 THIS->lexer_->remove_scope ();
 773                 THIS->lexer_->add_scope (o->scope_);
 774                 THIS->lexer_->push_initial_state ();
 775         }
 776         | output_def_body assignment  {
 777
 778         }
 779         | output_def_body context_def_spec_block        {
 780                 assign_context_def ($$, $2);
 781         }
 782         | output_def_body tempo_event  {
 783                 /*
 784                         junk this ? there already is tempo stuff in
 785                         music.
 786                 */
 787                 int m = scm_to_int ($2->get_property ("metronome-count"));
 788                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 789                 set_tempo ($$, d->get_length (), m);
 790                 $2->unprotect ();
 791         }
 792         | output_def_body error {
 793
 794         }
 795         ;
 796
 797 tempo_event:
 798         TEMPO steno_duration '=' bare_unsigned  {
 799                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 800                 $$->set_property ("tempo-unit", $2);
 801                 $$->set_property ("metronome-count", scm_from_int ( $4));
 802         }
 803         ;
 804
 805 /*
 806 The representation of a  list is the
 807
 808   (LIST . LAST-CONS)
 809
 810  to have efficient append.  */
 811
 812 Music_list:
 813         /* empty */ {
 814                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 815         }
 816         | Music_list Music {
 817                 SCM s = $$;
 818                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 819                 $2->unprotect (); /* UGH */
 820
 821                 if (scm_is_pair (scm_cdr (s)))
 822                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 823                 else
 824                         scm_set_car_x (s, c); /* set first cons */
 825                 scm_set_cdr_x (s, c);  /* remember last cell */
 826         }
 827         | Music_list embedded_scm {
 828
 829         }
 830         | Music_list error {
 831                 Music * m = MY_MAKE_MUSIC("Music");
 832                 // ugh. code dup
 833                 m->set_property ("error-found", SCM_BOOL_T);
 834                 SCM s = $$;
 835                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 836                 m->unprotect (); /* UGH */
 837
 838                 if (scm_is_pair (scm_cdr (s)))
 839                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 840                 else
 841                         scm_set_car_x (s, c); /* set first cons */
 842                 scm_set_cdr_x (s, c);  /* remember last cell */
 843         }
 844         ;
 845
 846 Music:
 847         Simple_music
 848         | Composite_music
 849         ;
 850
 851 Alternative_music:
 852         /* empty */ {
 853                 $$ = SCM_EOL;
 854         }
 855         | ALTERNATIVE '{' Music_list '}' {
 856                 $$ = $3;
 857         }
 858         ;
 859
 860
 861 Repeated_music:
 862         REPEAT simple_string bare_unsigned Music Alternative_music
 863         {
 864                 Music *beg = $4;
 865                 int times = $3;
 866                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 867                 if (times < scm_ilength (alts)) {
 868                   unsmob_music (scm_car (alts))
 869                     ->origin ()->warning (
 870                     _ ("more alternatives than repeats"));
 871                     warning ("junking excess alternatives");
 872                   alts = ly_truncate_list (times, alts);
 873                 }
 874
 875
 876                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 877
 878                 SCM mus = scm_call_1 (proc, $2);
 879                 Music *r = unsmob_music (mus);
 880                 r->protect ();
 881                 if (beg)
 882                         {
 883                         r-> set_property ("element", beg->self_scm ());
 884                         beg->unprotect ();
 885                         }
 886                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
 887
 888                 r-> set_property ("elements",alts);
 889                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
 890                         /*
 891                         TODO: move this code to Scheme.
 892                         */
 893
 894                         /* we cannot get durations and other stuff
 895                            correct down the line,
 896                            so we have to add to the duration log here. */
 897                         SCM func = ly_lily_module_constant ("shift-duration-log");
 898
 899                         int dots = ($3 % 3) ? 0 : 1;
 900                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 901
 902
 903                         if ($4->is_mus_type ("sequential-music"))
 904                         {
 905                                 int list_len = scm_ilength ($4->get_property ("elements"));
 906                                 if (list_len != 2)
 907                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
 908                                 shift -= 1;
 909                                 r->compress (Moment (Rational (1, list_len)));
 910                         }
 911                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
 912
 913                 }
 914                 r->set_spot (*$4->origin ());
 915
 916                 $$ = r;
 917         }
 918         ;
 919
 920 Sequential_music:
 921         SEQUENTIAL '{' Music_list '}'           {
 922                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 923                 $$->set_property ("elements", scm_car ($3));
 924                 $$->set_spot (@$);
 925         }
 926         | '{' Music_list '}'            {
 927                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 928                 $$->set_property ("elements", scm_car ($2));
 929                 $$->set_spot (@$);
 930         }
 931         ;
 932
 933 Simultaneous_music:
 934         SIMULTANEOUS '{' Music_list '}'{
 935                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 936                 $$->set_property ("elements", scm_car ($3));
 937                 $$->set_spot (@$);
 938
 939         }
 940         | simul_open Music_list simul_close     {
 941                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 942                 $$->set_property ("elements", scm_car ($2));
 943                 $$->set_spot (@$);
 944         }
 945         ;
 946
 947 Simple_music:
 948         event_chord             { $$ = $1; }
 949         | MUSIC_IDENTIFIER {
 950                 $$ = unsmob_music ($1);
 951         }
 952         | music_property_def
 953         | context_change
 954         ;
 955
 956
 957 optional_context_mod:
 958         /**/ { $$ = SCM_EOL; }
 959         | WITH { THIS->lexer_->push_initial_state (); }
 960         '{' context_mod_list '}'
 961         {
 962                 THIS->lexer_->pop_state ();
 963                 $$ = $4;
 964         }
 965         ;
 966
 967 context_mod_list:
 968         /* */  { $$ = SCM_EOL; }
 969         | context_mod_list context_mod  {
 970                  $$ = scm_cons ($2, $1);
 971         }
 972         ;
 973
 974
 975 Composite_music:
 976         Prefix_composite_music { $$ = $1; }
 977         | Grouped_music_list { $$ = $1; }
 978         ;
 979
 980 Grouped_music_list:
 981         Simultaneous_music              { $$ = $1; }
 982         | Sequential_music              { $$ = $1; }
 983         ;
 984
 985
 986 function_scm_argument:
 987         embedded_scm
 988         | simple_string
 989         ;
 990
 991 Generic_prefix_music_scm:
 992         MUSIC_FUNCTION {
 993                 $$ = scm_list_2 ($1, make_input (@$));
 994         }
 995         | MUSIC_FUNCTION_SCM function_scm_argument {
 996                 $$ = scm_list_3 ($1, make_input (@$), $2);
 997         }
 998         | MUSIC_FUNCTION_MARKUP full_markup {
 999                 $$ = scm_list_3 ($1, make_input (@$), $2);
1000         }
1001
1002         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument Music {
1003                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1004                 $3->unprotect ();
1005         }
1006         | MUSIC_FUNCTION_SCM_SCM function_scm_argument function_scm_argument {
1007                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1008         }
1009         | MUSIC_FUNCTION_SCM_SCM_SCM function_scm_argument function_scm_argument function_scm_argument {
1010                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1011         }
1012         | MUSIC_FUNCTION_MUSIC Music {
1013                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1014                 $2->unprotect ();
1015         }
1016         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument Music {
1017                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1018         }
1019         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1020                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1021                 $3->unprotect ();
1022         }
1023         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1024                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1025         }
1026         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1027                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1028                 $2->unprotect ();
1029                 $3->unprotect ();
1030         }
1031         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC function_scm_argument Music Music {
1032                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1033                 $4->unprotect ();
1034                 $3->unprotect ();
1035         }
1036         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1037                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1038                 $3->unprotect ();
1039                 $4->unprotect ();
1040         }
1041         ;
1042
1043 Prefix_composite_music:
1044         Generic_prefix_music_scm {
1045                 $$ = run_music_function (THIS, $1);
1046         }
1047         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1048                 $$ = context_spec_music ($2, $4, $6, $5);
1049
1050         }
1051         | CONTEXT simple_string optional_context_mod Music {
1052                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1053         }
1054         | NEWCONTEXT simple_string optional_context_mod Music {
1055                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1056                         $3);
1057         }
1058
1059         | TIMES fraction Music
1060
1061         {
1062                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1063                 Music *mp = $3;
1064
1065                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1066                 $$->set_spot (@$);
1067
1068                 $$->set_property ("element", mp->self_scm ());
1069                 mp->unprotect();
1070                 $$->set_property ("numerator", scm_from_int (n));
1071                 $$->set_property ("denominator", scm_from_int (d));
1072                 $$->compress (Moment (Rational (n,d)));
1073
1074         }
1075         | Repeated_music                { $$ = $1; }
1076         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1077                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1078                 Music *p = $4;
1079                 Pitch from = *unsmob_pitch ($2);
1080                 Pitch to = *unsmob_pitch ($3);
1081
1082                 p->transpose (pitch_interval (from, to));
1083                 $$->set_property ("element", p->self_scm ());
1084                 p->unprotect();
1085         }
1086         | mode_changing_head Grouped_music_list {
1087                 if ($1 == ly_symbol2scm ("chords"))
1088                 {
1089                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1090                   chm->set_property ("element", $2->self_scm ());
1091                   $$ = chm;
1092                   $2->unprotect();
1093                 }
1094                 else
1095                 {
1096                   $$ = $2;
1097                 }
1098                 THIS->lexer_->pop_state ();
1099         }
1100         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1101                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1102                                          $3, $2);
1103                 if ($1 == ly_symbol2scm ("ChordNames"))
1104                 {
1105                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1106                   chm->set_property ("element", $$->self_scm ());
1107                   $$->unprotect();
1108                   $$ = chm;
1109                 }
1110                 THIS->lexer_->pop_state ();
1111         }
1112         | relative_music        { $$ = $1; }
1113         | re_rhythmed_music     { $$ = $1; }
1114         ;
1115
1116 mode_changing_head:
1117         NOTEMODE {
1118                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1119                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1120
1121                 $$ = ly_symbol2scm ("notes");
1122         }
1123         | DRUMMODE
1124                 {
1125                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1126                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1127
1128                 $$ = ly_symbol2scm ("drums");
1129         }
1130         | FIGUREMODE {
1131                 THIS->lexer_->push_figuredbass_state ();
1132
1133                 $$ = ly_symbol2scm ("figures");
1134         }
1135         | CHORDMODE {
1136                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1137                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1138                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1139                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1140                 $$ = ly_symbol2scm ("chords");
1141
1142         }
1143         | LYRICMODE
1144                 { THIS->lexer_->push_lyric_state ();
1145                 $$ = ly_symbol2scm ("lyrics");
1146         }
1147         ;
1148
1149 mode_changing_head_with_context:
1150         DRUMS {
1151                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1152                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1153
1154                 $$ = ly_symbol2scm ("DrumStaff");
1155         }
1156         | FIGURES {
1157                 THIS->lexer_->push_figuredbass_state ();
1158
1159                 $$ = ly_symbol2scm ("FiguredBass");
1160         }
1161         | CHORDS {
1162                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1163                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1164                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1165                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1166                 $$ = ly_symbol2scm ("ChordNames");
1167         }
1168         | LYRICS
1169                 { THIS->lexer_->push_lyric_state ();
1170                 $$ = ly_symbol2scm ("Lyrics");
1171         }
1172         ;
1173
1174
1175 relative_music:
1176         RELATIVE absolute_pitch Music {
1177                 Music *m = $3;
1178                 Pitch start = *unsmob_pitch ($2);
1179                 $$ = make_music_relative (start, m);
1180                 m->unprotect();
1181         }
1182         | RELATIVE Composite_music {
1183                 Music *m = $2;
1184
1185                 Pitch middle_c (0, 0, 0);
1186                 $$ = make_music_relative (middle_c, m);
1187                 m->unprotect();
1188         }
1189         ;
1190
1191 new_lyrics:
1192         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1193         /*cont */
1194         Grouped_music_list {
1195         /* Can also use Music at the expensive of two S/Rs similar to
1196            \repeat \alternative */
1197                 THIS->lexer_->pop_state ();
1198
1199                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1200         }
1201         | new_lyrics ADDLYRICS {
1202                 THIS->lexer_->push_lyric_state ();
1203         } Grouped_music_list {
1204                 THIS->lexer_->pop_state ();
1205                 $$ = scm_cons ($4->self_scm (), $1);
1206         }
1207         ;
1208
1209 re_rhythmed_music:
1210         Grouped_music_list new_lyrics {
1211                 Music * voice = $1;
1212                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1213                 if (!scm_is_string (name))
1214                 {
1215                         name = get_next_unique_lyrics_context_id ();
1216                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1217                                                     name,
1218                                                     voice, SCM_EOL);
1219                 }
1220
1221                 SCM context = scm_makfrom0str ("Lyrics");
1222                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1223
1224                 SCM lst = SCM_EOL;
1225                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1226                 {
1227                         Music *music = unsmob_music (scm_car (s));
1228                         Music *com = make_lyric_combine_music (name, music);
1229                         Music *csm = context_spec_music (context,
1230                                 get_next_unique_context_id (), com, SCM_EOL);
1231                         lst = scm_cons (csm->self_scm (), lst);
1232                 }
1233                 all->set_property ("elements", scm_cons (voice->self_scm (),
1234                         lst));
1235                 $$ = all;
1236                 voice->unprotect ();
1237         }
1238         | LYRICSTO simple_string {
1239                 THIS->lexer_->push_lyric_state ();
1240         } Music {
1241                 THIS->lexer_->pop_state ();
1242                 Music *music = $4;
1243                 SCM name = $2;
1244                 $$ = make_lyric_combine_music (name, music);
1245                 music->unprotect();
1246         }
1247         ;
1248
1249 context_change:
1250         CHANGE STRING '=' STRING  {
1251                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1252                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1253                 t-> set_property ("change-to-id", $4);
1254
1255                 $$ = t;
1256                 $$->set_spot (@$);
1257         }
1258         ;
1259
1260 property_operation:
1261         STRING '=' scalar {
1262                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1263                         scm_string_to_symbol ($1), $3);
1264         }
1265         | UNSET simple_string {
1266                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1267                         scm_string_to_symbol ($2));
1268         }
1269         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1270                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1271                         scm_string_to_symbol ($2), $5, $3);
1272         }
1273         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1274                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1275                                 scm_string_to_symbol ($2), $6, $4, $3);
1276         }
1277         | REVERT simple_string embedded_scm {
1278                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1279                         scm_string_to_symbol ($2), $3);
1280         }
1281         ;
1282
1283 context_def_mod:
1284         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1285         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1286
1287         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1288         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1289         | DENIES { $$ = ly_symbol2scm ("denies"); }
1290
1291         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1292         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1293         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1294         | NAME { $$ = ly_symbol2scm ("context-name"); }
1295         ;
1296
1297 context_mod:
1298         property_operation { $$ = $1; }
1299         | context_def_mod STRING {
1300                 $$ = scm_list_2 ($1, $2);
1301         }
1302         ;
1303
1304 context_prop_spec:
1305         simple_string {
1306                 if (!is_regular_identifier ($1))
1307                 {
1308                         @$.error (_("Grob name should be alphanumeric"));
1309                 }
1310
1311                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1312                         scm_string_to_symbol ($1));
1313         }
1314         | simple_string '.' simple_string {
1315                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1316                         scm_string_to_symbol ($3));
1317         }
1318         ;
1319
1320 music_property_def:
1321         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1322                 $$ = property_op_to_music (scm_list_4 (
1323                         ly_symbol2scm ("push"),
1324                         scm_cadr ($2),
1325                         $5, $3));
1326                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1327         }
1328         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1329                 $$ = property_op_to_music (scm_list_5 (
1330                         ly_symbol2scm ("push"),
1331                         scm_cadr ($2),
1332                         $6, $4, $3));
1333                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1334         }
1335         | REVERT context_prop_spec embedded_scm {
1336                 $$ = property_op_to_music (scm_list_3 (
1337                         ly_symbol2scm ("pop"),
1338                         scm_cadr ($2),
1339                         $3));
1340
1341                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1342         }
1343         | SET context_prop_spec '=' scalar {
1344                 $$ = property_op_to_music (scm_list_3 (
1345                         ly_symbol2scm ("assign"),
1346                         scm_cadr ($2),
1347                         $4));
1348                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1349         }
1350         | UNSET context_prop_spec {
1351                 $$ = property_op_to_music (scm_list_2 (
1352                         ly_symbol2scm ("unset"),
1353                         scm_cadr ($2)));
1354                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1355         }
1356         | ONCE music_property_def {
1357                 SCM e = $2->get_property ("element");
1358                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1359                 $$ = $2;
1360
1361         }
1362         ;
1363
1364
1365 string:
1366         STRING {
1367                 $$ = $1;
1368         }
1369         | STRING_IDENTIFIER {
1370                 $$ = $1;
1371         }
1372         | string '+' string {
1373                 $$ = scm_string_append (scm_list_2 ($1, $3));
1374         }
1375         ;
1376
1377 simple_string: STRING {
1378                 $$ = $1;
1379         }
1380         | LYRICS_STRING {
1381                 $$ = $1;
1382         }
1383         | STRING_IDENTIFIER {
1384                 $$ = $1;
1385         }
1386         ;
1387
1388 scalar: string {
1389                 $$ = $1;
1390         }
1391         | LYRICS_STRING {
1392                 $$ = $1;
1393         }
1394         | bare_number {
1395                 $$ = $1;
1396         }
1397         | embedded_scm {
1398                 $$ = $1;
1399         }
1400         | full_markup {
1401                 $$ = $1;
1402         }
1403         | DIGIT {
1404                 $$ = scm_from_int ($1);
1405         }
1406         ;
1407
1408 /*
1409
1410 pre_events doesn't contain anything. It is a trick:
1411
1412 Adding pre_events to the simple_element
1413 makes the choice between
1414
1415   string:  STRING
1416
1417 and
1418
1419   simple_element: STRING
1420
1421 a single shift/reduction conflict.
1422
1423 nevertheless, this is not very clean, and we should find a different
1424 solution.
1425
1426 */
1427 pre_events: /* empty */
1428         ;
1429
1430 event_chord:
1431         pre_events simple_element post_events   {
1432                 SCM elts = $2-> get_property ("elements");
1433
1434                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1435
1436                 $2->set_property ("elements", elts);
1437                 /* why is this giving wrong start location? -ns
1438                  * $2->set_spot (@$); */
1439                 Input i;
1440                 i.set_location (@2, @3);
1441                 $2->set_spot (i);
1442                 $$ = $2;
1443         }
1444         | command_element
1445         | note_chord_element
1446         ;
1447
1448
1449 note_chord_element:
1450         chord_body optional_notemode_duration post_events
1451         {
1452                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1453                 SCM es = $1->get_property ("elements");
1454                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1455
1456                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1457                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1458                 es = ly_append2 (es, postevs);
1459
1460                 $1-> set_property ("elements", es);
1461                 $1->set_spot (@$);
1462                 $$ = $1;
1463         }
1464         ;
1465
1466 chord_open: '<'
1467         ;
1468
1469 chord_close: '>'
1470         ;
1471
1472 simul_open: DOUBLE_ANGLE_OPEN
1473         ;
1474
1475 simul_close: DOUBLE_ANGLE_CLOSE
1476         ;
1477
1478 chord_body:
1479         chord_open chord_body_elements chord_close
1480         {
1481                 $$ = MY_MAKE_MUSIC ("EventChord");
1482                 $$->set_spot (@$);
1483                 $$->set_property ("elements",
1484                         scm_reverse_x ($2, SCM_EOL));
1485         }
1486         ;
1487
1488 chord_body_elements:
1489         /* empty */             { $$ = SCM_EOL; }
1490         | chord_body_elements chord_body_element {
1491                 $$ = scm_cons ($2->self_scm (), $1);
1492                 $2->unprotect ();
1493         }
1494         ;
1495
1496 chord_body_element:
1497         pitch exclamations questions octave_check post_events
1498         {
1499                 int q = $3;
1500                 int ex = $2;
1501                 SCM check = $4;
1502                 SCM post = $5;
1503
1504                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1505                 n->set_property ("pitch", $1);
1506                 n->set_spot (@$);
1507                 if (q % 2)
1508                         n->set_property ("cautionary", SCM_BOOL_T);
1509                 if (ex % 2 || q % 2)
1510                         n->set_property ("force-accidental", SCM_BOOL_T);
1511
1512                 if (scm_is_pair (post)) {
1513                         SCM arts = scm_reverse_x (post, SCM_EOL);
1514                         n->set_property ("articulations", arts);
1515                 }
1516                 if (scm_is_number (check))
1517                 {
1518                         int q = scm_to_int (check);
1519                         n->set_property ("absolute-octave", scm_from_int (q-1));
1520                 }
1521
1522
1523                 $$ = n;
1524         }
1525         | DRUM_PITCH post_events {
1526                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1527                 n->set_property ("duration", $2);
1528                 n->set_property ("drum-type", $1);
1529                 n->set_spot (@$);
1530
1531                 if (scm_is_pair ($2)) {
1532                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1533                         n->set_property ("articulations", arts);
1534                 }
1535                 $$ = n;
1536         }
1537         | music_function_chord_body {
1538                 $$ = run_music_function (THIS, $1);
1539                 $$->set_spot (@$);
1540         }
1541         ;
1542
1543 music_function_chord_body:
1544         MUSIC_FUNCTION {
1545                 $$ = scm_list_2 ($1, make_input (@$));
1546         }
1547         | MUSIC_FUNCTION_MUSIC chord_body_element {
1548                 $$ = scm_list_3 ($1, make_input (@$),
1549                                         $2->self_scm ());
1550         }
1551         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument chord_body_element {
1552                 $$ = scm_list_4 ($1, make_input (@$),
1553                                         $2, $3->self_scm ());
1554         }
1555         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument
1556                 chord_body_element {
1557
1558                 $$ = scm_list_5 ($1, make_input (@$),
1559                                         $2, $3, $4->self_scm ());
1560         }
1561         ;
1562
1563
1564 add_quote:
1565         ADDQUOTE string Music {
1566                 SCM adder = ly_lily_module_constant ("add-quotable");
1567
1568                 scm_call_2 (adder, $2, $3->self_scm ());
1569                 $3->unprotect();
1570         }
1571         ;
1572
1573 command_element:
1574         command_event {
1575                 $$ = MY_MAKE_MUSIC ("EventChord");
1576                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1577                 $1->unprotect();
1578
1579                 $$-> set_spot (@$);
1580                 $1-> set_spot (@$);
1581         }
1582         | SKIP duration_length {
1583                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1584                 skip->set_property ("duration", $2);
1585                 skip->set_spot (@$);
1586                 $$ = skip;
1587         }
1588         | OCTAVE pitch {
1589                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1590                 $$ = m;
1591                 $$->set_spot (@$);
1592                 $$->set_property ("pitch", $2);
1593         }
1594         | E_BRACKET_OPEN {
1595                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1596                 m->set_property ("span-direction", scm_from_int (START));
1597                 m->set_spot (@$);
1598
1599                 $$ = MY_MAKE_MUSIC ("EventChord");
1600                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1601                 m->unprotect();
1602                 $$->set_spot (@$);
1603         }
1604         | E_BRACKET_CLOSE {
1605                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1606                 m->set_property ("span-direction", scm_from_int (STOP));
1607                 m->set_spot (@$);
1608
1609                 $$ = MY_MAKE_MUSIC ("EventChord");
1610                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1611                 $$->set_spot (@$);
1612                 m->unprotect ();
1613         }
1614         | E_BACKSLASH {
1615                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1616                 $$->set_spot (@$);
1617         }
1618         | '|'      {
1619                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1620
1621                 if (Music * m = unsmob_music (pipe))
1622                         $$ = m->clone ();
1623                 else
1624                         $$ = MY_MAKE_MUSIC ("BarCheck");
1625
1626                 $$->set_spot (@$);
1627         }
1628         | TRANSPOSITION pitch {
1629                 Pitch middle_c;
1630                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1631                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1632                                          sounds_as_c.smobbed_copy());
1633                 $$->set_spot (@$);
1634                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1635                         $$, SCM_EOL);
1636         }
1637         | PARTIAL duration_length       {
1638                 Moment m = - unsmob_duration ($2)->get_length ();
1639                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1640                 p->set_spot (@$);
1641                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1642                                         p, SCM_EOL);
1643                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1644                                         p, SCM_EOL);
1645                 $$ = p;
1646         }
1647
1648         | TIME_T fraction  {
1649                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1650
1651                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1652                 $$ = unsmob_music (result);
1653                 $$->protect ();
1654         }
1655         | MARK scalar {
1656                 SCM proc = ly_lily_module_constant ("make-mark-set");
1657
1658                 SCM result = scm_call_1 (proc, $2);
1659                 $$ = unsmob_music (result);
1660                 $$->protect ();
1661         }
1662         ;
1663
1664 command_event:
1665         E_TILDE {
1666                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1667         }
1668         | MARK DEFAULT  {
1669                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1670                 $$ = m;
1671         }
1672         | tempo_event {
1673                 $$ = $1;
1674         }
1675         | KEY DEFAULT {
1676                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1677                 $$ = key;
1678         }
1679         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1680
1681                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1682                 if (scm_ilength ($3) > 0)
1683                 {
1684                         key->set_property ("pitch-alist", $3);
1685                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1686                         key->transpose (* unsmob_pitch ($2));
1687                 } else {
1688                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1689                 }
1690
1691                 $$ = key;
1692         }
1693         ;
1694
1695
1696 post_events:
1697         /* empty */ {
1698                 $$ = SCM_EOL;
1699         }
1700         | post_events post_event {
1701                 $2->set_spot (@2);
1702                 $$ = scm_cons ($2->self_scm (), $$);
1703                 $2->unprotect ();
1704         }
1705         ;
1706
1707 music_function_event:
1708         MUSIC_FUNCTION_MUSIC post_event {
1709                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1710         }
1711         | MUSIC_FUNCTION_SCM_MUSIC function_scm_argument post_event {
1712                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1713         }
1714         | MUSIC_FUNCTION_SCM_SCM_MUSIC function_scm_argument function_scm_argument post_event {
1715                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1716         }
1717         ;
1718
1719
1720 post_event:
1721         direction_less_event {
1722                 $$ = $1;
1723         }
1724         | '-' music_function_event {
1725                 Music *mus = run_music_function (THIS, $2);
1726                 mus->set_spot (@1);
1727                 $$ = mus;
1728         }
1729         | HYPHEN {
1730                 if (!THIS->lexer_->is_lyric_state ())
1731                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1732                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1733         }
1734         | EXTENDER {
1735                 if (!THIS->lexer_->is_lyric_state ())
1736                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1737                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1738         }
1739         | script_dir direction_reqd_event {
1740                 if ($1)
1741                         $2->set_property ("direction", scm_from_int ($1));
1742                 $$ = $2;
1743         }
1744         | script_dir direction_less_event {
1745                 if ($1)
1746                         $2->set_property ("direction", scm_from_int ($1));
1747                 $$ = $2;
1748         }
1749         | string_number_event
1750         ;
1751
1752 string_number_event:
1753         E_UNSIGNED {
1754                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1755                 s->set_property ("string-number", scm_from_int ($1));
1756                 s->set_spot (@$);
1757                 $$ = s;
1758         }
1759         ;
1760
1761 direction_less_char:
1762         '['  {
1763                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1764         }
1765         | ']'  {
1766                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1767         }
1768         | '~'  {
1769                 $$ = ly_symbol2scm ("tildeSymbol");
1770         }
1771         | '('  {
1772                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1773         }
1774         | ')'  {
1775                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1776         }
1777         | E_EXCLAMATION  {
1778                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1779         }
1780         | E_OPEN  {
1781                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1782         }
1783         | E_CLOSE  {
1784                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1785         }
1786         | E_ANGLE_CLOSE  {
1787                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1788         }
1789         | E_ANGLE_OPEN  {
1790                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1791         }
1792         ;
1793
1794 direction_less_event:
1795         direction_less_char {
1796                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1797                 Music * m = 0;
1798                 if (unsmob_music (predefd))
1799                 {
1800                         m = unsmob_music (predefd)->clone ();
1801                 }
1802                 else
1803                 {
1804                         m = MY_MAKE_MUSIC ("Music");
1805                 }
1806                 m->set_spot (@$);
1807                 $$ = m;
1808         }
1809         | EVENT_IDENTIFIER      {
1810                 $$ = unsmob_music ($1);
1811         }
1812         | tremolo_type  {
1813                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1814                a->set_spot (@$);
1815                a->set_property ("tremolo-type", scm_from_int ($1));
1816                $$ = a;
1817         }
1818         ;
1819
1820 direction_reqd_event:
1821         gen_text_def {
1822                 $$ = $1;
1823         }
1824         | script_abbreviation {
1825                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1826                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1827                 if (scm_is_string (s))
1828                         a->set_property ("articulation-type", s);
1829                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1830                 $$ = a;
1831         }
1832         ;
1833
1834 octave_check:
1835         /**/ { $$ = SCM_EOL; }
1836         | '='  { $$ = scm_from_int (0); }
1837         | '=' sub_quotes { $$ = scm_from_int ($2); }
1838         | '=' sup_quotes { $$ = scm_from_int ($2); }
1839         ;
1840
1841 sup_quotes:
1842         '\'' {
1843                 $$ = 1;
1844         }
1845         | sup_quotes '\'' {
1846                 $$ ++;
1847         }
1848         ;
1849
1850 sub_quotes:
1851         ',' {
1852                 $$ = 1;
1853         }
1854         | sub_quotes ',' {
1855                 $$++;
1856         }
1857         ;
1858
1859 steno_pitch:
1860         NOTENAME_PITCH  {
1861                 $$ = $1;
1862         }
1863         | NOTENAME_PITCH sup_quotes     {
1864                 Pitch p = *unsmob_pitch ($1);
1865                 p = p.transposed (Pitch ($2,0,0));
1866                 $$ = p.smobbed_copy ();
1867         }
1868         | NOTENAME_PITCH sub_quotes      {
1869                 Pitch p =* unsmob_pitch ($1);
1870                 p = p.transposed (Pitch (-$2,0,0));
1871                 $$ = p.smobbed_copy ();
1872         }
1873         ;
1874
1875 /*
1876 ugh. duplication
1877 */
1878
1879 steno_tonic_pitch:
1880         TONICNAME_PITCH {
1881                 $$ = $1;
1882         }
1883         | TONICNAME_PITCH sup_quotes    {
1884                 Pitch p = *unsmob_pitch ($1);
1885                 p = p.transposed (Pitch ($2,0,0));
1886                 $$ = p.smobbed_copy ();
1887         }
1888         | TONICNAME_PITCH sub_quotes     {
1889                 Pitch p =* unsmob_pitch ($1);
1890
1891                 p = p.transposed (Pitch (-$2,0,0));
1892                 $$ = p.smobbed_copy ();
1893         }
1894         ;
1895
1896 pitch:
1897         steno_pitch {
1898                 $$ = $1;
1899         }
1900         ;
1901
1902 pitch_also_in_chords:
1903         pitch
1904         | steno_tonic_pitch
1905         ;
1906
1907 gen_text_def:
1908         full_markup {
1909                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1910                 t->set_property ("text", $1);
1911                 t->set_spot (@$);
1912                 $$ = t;
1913         }
1914         | string {
1915                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1916                 t->set_property ("text",
1917                         make_simple_markup ($1));
1918                 t->set_spot (@$);
1919                 $$ = t;
1920
1921         }
1922         | DIGIT {
1923                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1924                 t->set_property ("digit", scm_from_int ($1));
1925                 t->set_spot (@$);
1926                 $$ = t;
1927         }
1928         ;
1929
1930 script_abbreviation:
1931         '^'             {
1932                 $$ = scm_makfrom0str ("Hat");
1933         }
1934         | '+'           {
1935                 $$ = scm_makfrom0str ("Plus");
1936         }
1937         | '-'           {
1938                 $$ = scm_makfrom0str ("Dash");
1939         }
1940         | '|'           {
1941                 $$ = scm_makfrom0str ("Bar");
1942         }
1943         | '>'           {
1944                 $$ = scm_makfrom0str ("Larger");
1945         }
1946         | '.'           {
1947                 $$ = scm_makfrom0str ("Dot");
1948         }
1949         | '_' {
1950                 $$ = scm_makfrom0str ("Underscore");
1951         }
1952         ;
1953
1954 script_dir:
1955         '_'     { $$ = DOWN; }
1956         | '^'   { $$ = UP; }
1957         | '-'   { $$ = CENTER; }
1958         ;
1959
1960
1961 absolute_pitch:
1962         steno_pitch     {
1963                 $$ = $1;
1964         }
1965         ;
1966
1967 duration_length:
1968         multiplied_duration {
1969                 $$ = $1;
1970         }
1971         ;
1972
1973 optional_notemode_duration:
1974         {
1975                 Duration dd = THIS->default_duration_;
1976                 $$ = dd.smobbed_copy ();
1977         }
1978         | multiplied_duration   {
1979                 $$ = $1;
1980                 THIS->default_duration_ = *unsmob_duration ($$);
1981         }
1982         ;
1983
1984 steno_duration:
1985         bare_unsigned dots              {
1986                 int len = 0;
1987                 if (!is_duration ($1))
1988                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
1989                 else
1990                         len = intlog2 ($1);
1991
1992                 $$ = Duration (len, $2).smobbed_copy ();
1993         }
1994         | DURATION_IDENTIFIER dots      {
1995                 Duration *d = unsmob_duration ($1);
1996                 Duration k (d->duration_log (), d->dot_count () + $2);
1997                 *d = k;
1998                 $$ = $1;
1999         }
2000         ;
2001
2002 multiplied_duration:
2003         steno_duration {
2004                 $$ = $1;
2005         }
2006         | multiplied_duration '*' bare_unsigned {
2007                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2008         }
2009         | multiplied_duration '*' FRACTION {
2010                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2011
2012                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2013         }
2014         ;
2015
2016 fraction:
2017         FRACTION { $$ = $1; }
2018         | UNSIGNED '/' UNSIGNED {
2019                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2020         }
2021         ;
2022
2023 dots:
2024         /* empty */     {
2025                 $$ = 0;
2026         }
2027         | dots '.' {
2028                 $$ ++;
2029         }
2030         ;
2031
2032 tremolo_type:
2033         ':'     {
2034                 $$ = 0;
2035         }
2036         | ':' bare_unsigned {
2037                 if (!is_duration ($2))
2038                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2039                 $$ = $2;
2040         }
2041         ;
2042
2043 bass_number:
2044         DIGIT   {
2045                 $$ = scm_from_int ($1);
2046         }
2047         | UNSIGNED {
2048                 $$ = scm_from_int ($1);
2049         }
2050         | STRING { $$ = $1; }
2051         | full_markup { $$ = $1; }
2052         ;
2053
2054 figured_bass_alteration:
2055         '-'     { $$ = -2; }
2056         | '+'   { $$ = 2; }
2057         | '!'   { $$ = 0; }
2058         ;
2059
2060 bass_figure:
2061         FIGURE_SPACE {
2062                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2063                 $$ = bfr->self_scm ();
2064                 bfr->unprotect ();
2065         }
2066         | bass_number  {
2067                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2068                 $$ = bfr->self_scm ();
2069
2070                 if (scm_is_number ($1))
2071                         bfr->set_property ("figure", $1);
2072                 else if (Text_interface::is_markup ($1))
2073                         bfr->set_property ("text", $1);
2074
2075                 bfr->unprotect ();
2076         }
2077         | bass_figure ']' {
2078                 $$ = $1;
2079                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2080         }
2081         | bass_figure figured_bass_alteration {
2082                 Music *m = unsmob_music ($1);
2083                 if ($2) {
2084                         SCM salter = m->get_property ("alteration");
2085                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2086                         m->set_property ("alteration",
2087                                 scm_from_int (alter + $2));
2088                 } else {
2089                         m->set_property ("alteration", scm_from_int (0));
2090                 }
2091         }
2092         | bass_figure figured_bass_modification  {
2093                 Music *m = unsmob_music ($1);
2094                 if ($2 == ly_symbol2scm ("plus"))
2095                         {
2096                         m->set_property ("augmented", SCM_BOOL_T);
2097                         }
2098                 else if ($2 == ly_symbol2scm ("slash"))
2099                         {
2100                         m->set_property ("diminished", SCM_BOOL_T);
2101                         }
2102                 else if ($2 == ly_symbol2scm ("exclamation"))
2103                         {
2104                         m->set_property ("no-continuation", SCM_BOOL_T);
2105                         }
2106         }
2107         ;
2108
2109
2110 figured_bass_modification:
2111         E_PLUS          {
2112                 $$ = ly_symbol2scm ("plus");
2113         }
2114         | E_EXCLAMATION {
2115                 $$ = ly_symbol2scm ("exclamation");
2116         }
2117         | '/'           {
2118                 $$ = ly_symbol2scm ("slash");
2119         }
2120         ;
2121
2122 br_bass_figure:
2123         bass_figure {
2124                 $$ = $1;
2125         }
2126         | '[' bass_figure {
2127                 $$ = $2;
2128                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2129         }
2130         ;
2131
2132 figure_list:
2133         /**/            {
2134                 $$ = SCM_EOL;
2135         }
2136         | figure_list br_bass_figure {
2137                 $$ = scm_cons ($2, $1);
2138         }
2139         ;
2140
2141 figure_spec:
2142         FIGURE_OPEN figure_list FIGURE_CLOSE {
2143                 Music *m = MY_MAKE_MUSIC ("EventChord");
2144                 $2 = scm_reverse_x ($2, SCM_EOL);
2145                 m->set_property ("elements", $2);
2146                 $$ = m->self_scm ();
2147         }
2148         ;
2149
2150
2151 optional_rest:
2152         /**/   { $$ = 0; }
2153         | REST { $$ = 1; }
2154         ;
2155
2156 simple_element:
2157         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2158                 if (!THIS->lexer_->is_note_state ())
2159                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2160
2161                 Music *n = 0;
2162                 if ($6)
2163                         n = MY_MAKE_MUSIC ("RestEvent");
2164                 else
2165                         n = MY_MAKE_MUSIC ("NoteEvent");
2166
2167                 n->set_property ("pitch", $1);
2168                 n->set_property ("duration", $5);
2169
2170                 if (scm_is_number ($4))
2171                 {
2172                         int q = scm_to_int ($4);
2173                         n->set_property ("absolute-octave", scm_from_int (q-1));
2174                 }
2175
2176                 if ($3 % 2)
2177                         n->set_property ("cautionary", SCM_BOOL_T);
2178                 if ($2 % 2 || $3 % 2)
2179                         n->set_property ("force-accidental", SCM_BOOL_T);
2180
2181                 Music *v = MY_MAKE_MUSIC ("EventChord");
2182                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2183                 n->unprotect ();
2184
2185                 v->set_spot (@$);
2186                 n->set_spot (@$);
2187                 $$ = v;
2188         }
2189         | DRUM_PITCH optional_notemode_duration {
2190                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2191                 n->set_property ("duration", $2);
2192                 n->set_property ("drum-type", $1);
2193
2194                 Music *v = MY_MAKE_MUSIC ("EventChord");
2195                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2196                 n->unprotect ();
2197                 v->set_spot (@$);
2198                 n->set_spot (@$);
2199                 $$ = v;
2200
2201         }
2202         | figure_spec optional_notemode_duration {
2203                 Music *m = unsmob_music ($1);
2204                 m->set_spot (@$);
2205                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2206                 {
2207                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2208                 }
2209                 $$ = m;
2210         }
2211         | RESTNAME optional_notemode_duration           {
2212                 Music *ev = 0;
2213                 if (ly_scm2string ($1) == "s") {
2214                         /* Space */
2215                         ev = MY_MAKE_MUSIC ("SkipEvent");
2216                   }
2217                 else {
2218                         ev = MY_MAKE_MUSIC ("RestEvent");
2219
2220                     }
2221                 ev->set_property ("duration", $2);
2222                 ev->set_spot (@$);
2223                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2224                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2225                 velt->set_spot (@$);
2226
2227                 ev->unprotect();
2228
2229                 $$ = velt;
2230         }
2231         | MULTI_MEASURE_REST optional_notemode_duration         {
2232                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2233                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2234                 $$ = unsmob_music (mus);
2235                 $$->protect ();
2236         }
2237
2238         | lyric_element optional_notemode_duration      {
2239                 if (!THIS->lexer_->is_lyric_state ())
2240                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2241
2242                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2243                 levent->set_property ("text", $1);
2244                 levent->set_property ("duration",$2);
2245                 levent->set_spot (@$);
2246                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2247                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2248
2249                 $$= velt;
2250         }
2251         | new_chord {
2252                 if (!THIS->lexer_->is_chord_state ())
2253                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2254                 $$ = unsmob_music ($1);
2255         }
2256         ;
2257
2258 lyric_element:
2259         lyric_markup {
2260                 $$ = $1;
2261         }
2262         | LYRICS_STRING {
2263                 $$ = $1;
2264         }
2265         ;
2266
2267 new_chord:
2268         steno_tonic_pitch optional_notemode_duration   {
2269                 $$ = make_chord ($1, $2, SCM_EOL);
2270         }
2271         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2272                 SCM its = scm_reverse_x ($4, SCM_EOL);
2273                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2274         }
2275         ;
2276
2277 chord_items:
2278         /**/ {
2279                 $$ = SCM_EOL;
2280         }
2281         | chord_items chord_item {
2282                 $$ = scm_cons ($2, $$);
2283         }
2284         ;
2285
2286 chord_separator:
2287         CHORD_COLON {
2288                 $$ = ly_symbol2scm ("chord-colon");
2289         }
2290         | CHORD_CARET {
2291                 $$ = ly_symbol2scm ("chord-caret");
2292         }
2293         | CHORD_SLASH steno_tonic_pitch {
2294                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2295         }
2296         | CHORD_BASS steno_tonic_pitch {
2297                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2298         }
2299         ;
2300
2301 chord_item:
2302         chord_separator {
2303                 $$ = $1;
2304         }
2305         | step_numbers {
2306                 $$ = scm_reverse_x ($1, SCM_EOL);
2307         }
2308         | CHORD_MODIFIER  {
2309                 $$ = $1;
2310         }
2311         ;
2312
2313 step_numbers:
2314         step_number { $$ = scm_cons ($1, SCM_EOL); }
2315         | step_numbers '.' step_number {
2316                 $$ = scm_cons ($3, $$);
2317         }
2318         ;
2319
2320 step_number:
2321         bare_unsigned {
2322                 $$ = make_chord_step ($1, 0);
2323         }
2324         | bare_unsigned '+' {
2325                 $$ = make_chord_step ($1, SHARP);
2326         }
2327         | bare_unsigned CHORD_MINUS {
2328                 $$ = make_chord_step ($1, FLAT);
2329         }
2330         ;
2331
2332 /*
2333         UTILITIES
2334
2335 TODO: should deprecate in favor of Scheme?
2336
2337  */
2338 number_expression:
2339         number_expression '+' number_term {
2340                 $$ = scm_sum ($1, $3);
2341         }
2342         | number_expression '-' number_term {
2343                 $$ = scm_difference ($1, $3);
2344         }
2345         | number_term
2346         ;
2347
2348 number_term:
2349         number_factor {
2350                 $$ = $1;
2351         }
2352         | number_factor '*' number_factor {
2353                 $$ = scm_product ($1, $3);
2354         }
2355         | number_factor '/' number_factor {
2356                 $$ = scm_divide ($1, $3);
2357         }
2358         ;
2359
2360 number_factor:
2361         '-'  number_factor { /* %prec UNARY_MINUS */
2362                 $$ = scm_difference ($2, SCM_UNDEFINED);
2363         }
2364         | bare_number
2365         ;
2366
2367
2368 bare_number:
2369         UNSIGNED        {
2370                 $$ = scm_from_int ($1);
2371         }
2372         | REAL          {
2373                 $$ = $1;
2374         }
2375         | NUMBER_IDENTIFIER             {
2376                 $$ = $1;
2377         }
2378         | REAL NUMBER_IDENTIFIER        {
2379                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2380         }
2381         | UNSIGNED NUMBER_IDENTIFIER    {
2382                 $$ = scm_from_double ($1 *scm_to_double ($2));
2383         }
2384         ;
2385
2386
2387 bare_unsigned:
2388         UNSIGNED {
2389                         $$ = $1;
2390         }
2391         | DIGIT {
2392                 $$ = $1;
2393         }
2394         ;
2395
2396 exclamations:
2397                 { $$ = 0; }
2398         | exclamations '!'      { $$ ++; }
2399         ;
2400
2401 questions:
2402                 { $$ = 0; }
2403         | questions '?' { $$ ++; }
2404         ;
2405
2406 /*
2407 This should be done more dynamically if possible.
2408 */
2409
2410 lyric_markup:
2411         LYRIC_MARKUP_IDENTIFIER {
2412                 $$ = $1;
2413         }
2414         | LYRIC_MARKUP
2415                 { THIS->lexer_->push_markup_state (); }
2416         markup_top {
2417                 $$ = $3;
2418                 THIS->lexer_->pop_state ();
2419         }
2420         ;
2421
2422 full_markup:
2423         MARKUP_IDENTIFIER {
2424                 $$ = $1;
2425         }
2426         | MARKUP
2427                 { THIS->lexer_->push_markup_state (); }
2428         markup_top {
2429                 $$ = $3;
2430                 THIS->lexer_->pop_state ();
2431         }
2432         ;
2433
2434 markup_top:
2435         markup_list {
2436                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2437         }
2438         | markup_head_1_list simple_markup      {
2439                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2440         }
2441         | simple_markup {
2442                 $$ = $1;
2443         }
2444         ;
2445
2446 markup_list:
2447         markup_composed_list {
2448                 $$ = $1;
2449         }
2450         | markup_braced_list {
2451                 $$ = $1;
2452         }
2453         ;
2454
2455 markup_composed_list:
2456         markup_head_1_list markup_braced_list {
2457                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2458
2459         }
2460         ;
2461
2462 markup_braced_list:
2463         '{' markup_braced_list_body '}' {
2464                 $$ = scm_reverse_x ($2, SCM_EOL);
2465         }
2466         ;
2467
2468 markup_braced_list_body:
2469         /* empty */     {  $$ = SCM_EOL; }
2470         | markup_braced_list_body markup {
2471                 $$ = scm_cons ($2, $1);
2472         }
2473         | markup_braced_list_body markup_list {
2474                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2475         }
2476         ;
2477
2478 markup_head_1_item:
2479         MARKUP_HEAD_MARKUP0     {
2480                 $$ = scm_list_1 ($1);
2481         }
2482         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2483                 $$ = scm_list_2 ($1, $2);
2484         }
2485         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2486                 $$ = scm_list_3 ($1, $2, $3);
2487         }
2488         ;
2489
2490 markup_head_1_list:
2491         markup_head_1_item      {
2492                 $$ = scm_list_1 ($1);
2493         }
2494         | markup_head_1_list markup_head_1_item {
2495                 $$ = scm_cons ($2, $1);
2496         }
2497         ;
2498
2499 simple_markup:
2500         STRING {
2501                 $$ = make_simple_markup ($1);
2502         }
2503         | MARKUP_IDENTIFIER {
2504                 $$ = $1;
2505         }
2506         | LYRIC_MARKUP_IDENTIFIER {
2507                 $$ = $1;
2508         }
2509         | STRING_IDENTIFIER {
2510                 $$ = $1;
2511         }
2512         | SCORE {
2513                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2514                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2515         } '{' score_body '}' {
2516                 Score * sc = $4;
2517                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2518                 sc->unprotect ();
2519                 THIS->lexer_->pop_state ();
2520         }
2521         | MARKUP_HEAD_SCM0 embedded_scm {
2522                 $$ = scm_list_2 ($1, $2);
2523         }
2524         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2525                 $$ = scm_list_4 ($1, $2, $3, $4);
2526         }
2527         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2528                 $$ = scm_list_3 ($1, $2, $3);
2529         }
2530         | MARKUP_HEAD_EMPTY {
2531                 $$ = scm_list_1 ($1);
2532         }
2533         | MARKUP_HEAD_LIST0 markup_list {
2534                 $$ = scm_list_2 ($1,$2);
2535         }
2536         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2537                 $$ = scm_list_3 ($1, $2, $3);
2538         }
2539         ;
2540
2541 markup:
2542         markup_head_1_list simple_markup        {
2543                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2544                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2545         }
2546         | simple_markup {
2547                 $$ = $1;
2548         }
2549         ;
2550
2551 %%
2552
2553 void
2554 Lily_parser::set_yydebug (bool )
2555 {
2556 #if 0
2557         yydebug = 1;
2558 #endif
2559 }
2560
2561 void
2562 Lily_parser::do_yyparse ()
2563 {
2564         yyparse ((void*)this);
2565 }
2566
2567
2568
2569
2570
2571 /*
2572
2573 It is a little strange to have this function in this file, but
2574 otherwise, we have to import music classes into the lexer.
2575
2576 */
2577 int
2578 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2579 {
2580         if (scm_is_string (sid)) {
2581                 *destination = sid;
2582                 return STRING_IDENTIFIER;
2583         } else if (unsmob_book (sid)) {
2584                 *destination = unsmob_book (sid)->clone ()->self_scm ();
2585                 return BOOK_IDENTIFIER;
2586         } else if (scm_is_number (sid)) {
2587                 *destination = sid;
2588                 return NUMBER_IDENTIFIER;
2589         } else if (unsmob_context_def (sid)) {
2590                 *destination = unsmob_context_def (sid)->clone_scm ();
2591                 return CONTEXT_DEF_IDENTIFIER;
2592         } else if (unsmob_score (sid)) {
2593                 Score *score = new Score (*unsmob_score (sid));
2594                 *destination = score->self_scm ();
2595                 return SCORE_IDENTIFIER;
2596         } else if (Music *mus = unsmob_music (sid)) {
2597                 mus = mus->clone ();
2598                 *destination = mus->self_scm ();
2599                 unsmob_music (*destination)->
2600                         set_property ("origin", make_input (last_input_));
2601
2602                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2603                         != SCM_BOOL_F;
2604
2605                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2606         } else if (unsmob_duration (sid)) {
2607                 *destination = unsmob_duration (sid)->smobbed_copy ();
2608                 return DURATION_IDENTIFIER;
2609         } else if (unsmob_output_def (sid)) {
2610                 Output_def *p = unsmob_output_def (sid);
2611                 p = p->clone ();
2612
2613                 *destination = p->self_scm ();
2614                 return OUTPUT_DEF_IDENTIFIER;
2615         } else if (Text_interface::is_markup (sid)) {
2616                 *destination = sid;
2617                 if (is_lyric_state ())
2618                         return LYRIC_MARKUP_IDENTIFIER;
2619                 return MARKUP_IDENTIFIER;
2620         }
2621
2622         return -1;
2623 }
2624
2625 Music *
2626 property_op_to_music (SCM op)
2627 {
2628         Music *m = 0;
2629         SCM tag = scm_car (op);
2630         SCM symbol = scm_cadr (op);
2631         SCM args = scm_cddr (op);
2632         SCM grob_val = SCM_UNDEFINED;
2633         SCM grob_path = SCM_UNDEFINED;
2634         SCM val = SCM_UNDEFINED;
2635
2636         if (tag == ly_symbol2scm ("assign"))
2637                 {
2638                 m = MY_MAKE_MUSIC ("PropertySet");
2639                 val = scm_car (args);
2640                 }
2641         else if (tag == ly_symbol2scm ("unset"))
2642                 m = MY_MAKE_MUSIC ("PropertyUnset");
2643         else if (tag == ly_symbol2scm ("push"))
2644                 {
2645                 m = MY_MAKE_MUSIC ("OverrideProperty");
2646                 grob_val = scm_car (args);
2647                 grob_path = scm_cdr (args);
2648                 m->set_property ("pop-first", SCM_BOOL_T);
2649                 }
2650         else if (tag == ly_symbol2scm ("pop")) {
2651                 m = MY_MAKE_MUSIC ("RevertProperty");
2652                 grob_path = args;
2653                 }
2654
2655         m->set_property ("symbol", symbol);
2656
2657         if (val != SCM_UNDEFINED)
2658                 m->set_property ("value", val);
2659         if (grob_val != SCM_UNDEFINED)
2660                 m->set_property ("grob-value", grob_val);
2661         if (grob_path != SCM_UNDEFINED)
2662                 m->set_property ("grob-property-path", grob_path);
2663
2664         return m;
2665 }
2666
2667 Music*
2668 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2669 {
2670         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2671
2672         csm->set_property ("element", m->self_scm ());
2673         m->unprotect ();
2674
2675         csm->set_property ("context-type",
2676                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2677         csm->set_property ("property-operations", ops);
2678
2679         if (scm_is_string (id))
2680                 csm->set_property ("context-id", id);
2681         return csm;
2682 }
2683
2684 SCM
2685 get_next_unique_context_id ()
2686 {
2687         return scm_makfrom0str ("$uniqueContextId");
2688 }
2689
2690
2691 SCM
2692 get_next_unique_lyrics_context_id ()
2693 {
2694         static int new_context_count;
2695         char s[128];
2696         snprintf (s, sizeof (s)-1, "uniqueContext%d", new_context_count++);
2697         return scm_makfrom0str (s);
2698 }
2699
2700
2701 Music *
2702 run_music_function (Lily_parser *parser, SCM expr)
2703 {
2704         SCM func = scm_car (expr);
2705         Input *loc = unsmob_input (scm_cadr (expr));
2706         SCM args = scm_cddr (expr);
2707         SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
2708
2709         SCM type_check_proc = ly_lily_module_constant ("type-check-list");
2710         bool ok  = true;
2711
2712         if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr (expr), sig, args)))
2713         {
2714                 parser->error_level_ = 1;
2715                 ok = false;
2716         }
2717
2718         SCM m = SCM_EOL;
2719         if (ok)
2720                 m = scm_apply_0 (func, scm_cons (parser->self_scm(),
2721                                                  scm_cdr (expr)));
2722
2723
2724         Music* retval = 0;
2725         if (unsmob_music (m))
2726                 {
2727                 retval = unsmob_music (m);
2728                 retval->protect ();
2729                 }
2730         else
2731                 {
2732                 if (ok)
2733                         loc->error (_ ("music head function must return Music object"));
2734                 retval = MY_MAKE_MUSIC ("Music");
2735                 }
2736         retval->set_spot (*loc);
2737         return retval;
2738 }
2739
2740 bool
2741 is_regular_identifier (SCM id)
2742 {
2743   String str = ly_scm2string (id);
2744   char const *s = str.to_str0 ();
2745
2746   bool v = true;
2747 #if 0
2748   isalpha (*s);
2749   s++;
2750 #endif
2751   while (*s && v)
2752    {
2753         v = v && isalnum (*s);
2754         s++;
2755    }
2756   return v;
2757 }
2758
2759
2760 SCM
2761 get_first_context_id (SCM type, Music *m)
2762 {
2763         SCM id = m->get_property ("context-id");
2764         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
2765             && scm_is_string (m->get_property ("context-id"))
2766             && scm_c_string_length (id) > 0)
2767         {
2768                 return id;
2769         }
2770         return SCM_EOL;
2771 }
2772
2773 SCM
2774 make_simple_markup (SCM a)
2775 {
2776         return a;
2777 }
2778
2779 bool
2780 is_duration (int t)
2781 {
2782   return t && t == 1 << intlog2 (t);
2783 }
2784
2785 void
2786 set_music_properties (Music *p, SCM a)
2787 {
2788   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
2789         p->internal_set_property (scm_caar (k), scm_cdar (k));
2790 }
2791
2792
2793 SCM
2794 make_chord_step (int step, int alter)
2795 {
2796         if (step == 7)
2797                 alter += FLAT;
2798
2799         while (step < 0)
2800                 step += 7;
2801         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
2802         return m.smobbed_copy ();
2803 }
2804
2805
2806 SCM
2807 make_chord (SCM pitch, SCM dur, SCM modification_list)
2808 {
2809         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
2810         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
2811
2812         unsmob_music (ch)->protect();
2813         return ch;
2814 }
2815
2816
2817 /* Todo: actually also use apply iso. call too ...  */
2818 bool
2819 ly_input_procedure_p (SCM x)
2820 {
2821         return ly_is_procedure (x)
2822                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
2823 }
2824
2825 Music*
2826 set_property_music (SCM sym, SCM value)
2827 {
2828         Music *p = MY_MAKE_MUSIC ("PropertySet");
2829         p->set_property ("symbol", sym);
2830         p->set_property ("value", value);
2831         return p;
2832 }
2833
2834 Music*
2835 make_music_relative (Pitch start, Music *music)
2836 {
2837         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
2838         relative->set_property ("element", music->self_scm ());
2839
2840         Pitch last = music->to_relative_octave (start);
2841         if (lily_1_8_relative)
2842                 music->set_property ("last-pitch", last.smobbed_copy ());
2843         return relative;
2844 }
2845
2846 Music *
2847 make_lyric_combine_music (SCM name, Music *music)
2848 {
2849         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
2850         combine->set_property ("element", music->self_scm ());
2851         combine->set_property ("associated-context", name);
2852         return combine;
2853 }
2854
2855
2856 int
2857 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
2858 {
2859         Lily_parser *pars = (Lily_parser*) v;
2860         Lily_lexer *lex = pars->lexer_;
2861
2862         lex->lexval = (void*) s;
2863         lex->lexloc = loc;
2864         lex->prepare_for_next_token ();
2865         return lex->yylex ();
2866 }