lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "event.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "main.hh"
  38 #include "misc.hh"
  39 #include "lily-lexer.hh"
  40 #include "lily-parser.hh"
  41 #include "paper-book.hh"
  42 #include "output-def.hh"
  43 #include "scm-hash.hh"
  44 #include "scm-option.hh"
  45 #include "score.hh"
  46 #include "text-item.hh"
  47 #include "warn.hh"
  48
  49 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  50
  51 Music *property_op_to_music (SCM op);
  52 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  53 SCM get_next_unique_context_id ();
  54 SCM get_next_unique_lyrics_context_id ();
  55
  56 #define YYERROR_VERBOSE 1
  57
  58 #define YYPARSE_PARAM my_lily_parser
  59 #define YYLEX_PARAM my_lily_parser
  60 #define THIS\
  61         ((Lily_parser *) my_lily_parser)
  62
  63 #define yyerror THIS->parser_error
  64
  65 /* We use custom location type: Input objects */
  66 #define YYLTYPE Input
  67 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  68         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  69
  70
  71 /* Add symbols to the TAGS field of a music object.  */
  72
  73 void
  74 tag_music (Music *m, SCM tag, Input ip)
  75 {
  76         SCM tags = m->get_property ("tags");
  77         if (scm_is_symbol (tag))
  78                 tags = scm_cons (tag, tags);
  79         else if (ly_c_list_p (tag))
  80                 tags = ly_append2 (tag, tags);
  81         else
  82                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  83
  84         m->set_property ("tags", tags);
  85 }
  86
  87 bool
  88 is_regular_identifier (SCM id)
  89 {
  90   String str = ly_scm2string (id);
  91   char const *s = str.to_str0 ();
  92
  93   bool v = true;
  94 #if 0
  95   isalpha (*s);
  96   s++;
  97 #endif
  98   while (*s && v)
  99    {
 100         v = v && isalnum (*s);
 101         s++;
 102    }
 103   return v;
 104 }
 105
 106
 107 SCM
 108 get_first_context_id (SCM type, Music *m)
 109 {
 110         SCM id = m->get_property ("context-id");
 111         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
 112             && scm_is_string (m->get_property ("context-id"))
 113             && scm_c_string_length (id) > 0)
 114         {
 115                 return id;
 116         }
 117         return SCM_EOL;
 118 }
 119
 120 SCM
 121 make_simple_markup (SCM a)
 122 {
 123         SCM simple = ly_lily_module_constant ("simple-markup");
 124         return scm_list_2 (simple, a);
 125 }
 126
 127 bool
 128 is_duration (int t)
 129 {
 130   return t && t == 1 << intlog2 (t);
 131 }
 132
 133 void
 134 set_music_properties (Music *p, SCM a)
 135 {
 136   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 137         p->internal_set_property (scm_caar (k), scm_cdar (k));
 138 }
 139
 140 SCM
 141 make_chord_step (int step, int alter)
 142 {
 143         if (step == 7)
 144                 alter += FLAT;
 145
 146         while (step < 0)
 147                 step += 7;
 148         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 149         return m.smobbed_copy ();
 150 }
 151
 152
 153 SCM
 154 make_chord (SCM pitch, SCM dur, SCM modification_list)
 155 {
 156         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
 157         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 158         scm_gc_protect_object (ch);
 159         return ch;
 160 }
 161
 162 /* Todo: actually also use apply iso. call too ...  */
 163 bool
 164 ly_input_procedure_p (SCM x)
 165 {
 166         return ly_c_procedure_p (x)
 167                 || (scm_is_pair (x) && ly_c_procedure_p (scm_car (x)));
 168 }
 169
 170 Music*
 171 set_property_music (SCM sym, SCM value)
 172 {
 173         Music *p = MY_MAKE_MUSIC ("PropertySet");
 174         p->set_property ("symbol", sym);
 175         p->set_property ("value", value);
 176         return p;
 177 }
 178
 179 Music*
 180 make_music_relative (Pitch start, Music *music)
 181 {
 182         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 183         relative->set_property ("element", music->self_scm ());
 184
 185         Pitch last = music->to_relative_octave (start);
 186         if (lily_1_8_relative)
 187                 music->set_property ("last-pitch", last.smobbed_copy ());
 188         return relative;
 189 }
 190
 191 Music*
 192 make_lyric_combine_music (SCM name, Music *music)
 193 {
 194         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 195         combine->set_property ("element", music->self_scm ());
 196         combine->set_property ("associated-context", name);
 197         return combine;
 198 }
 199
 200 %}
 201
 202 /* We use SCMs to do strings, because it saves us the trouble of
 203 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 204 of the parse stack onto the heap. */
 205
 206 %left ADDLYRICS
 207
 208 %union {
 209         Book *book;
 210         Output_def *outputdef;
 211         SCM scm;
 212         String *string;
 213         Music *music;
 214         Score *score;
 215         int i;
 216 }
 217 %{
 218
 219 int
 220 yylex (YYSTYPE *s, YYLTYPE *l, void *v)
 221 {
 222         Lily_parser *pars = (Lily_parser*) v;
 223         Lily_lexer *lex = pars->lexer_;
 224
 225         lex->lexval = (void*) s;
 226         lex->lexloc = l;
 227         lex->prepare_for_next_token ();
 228         return lex->yylex ();
 229 }
 230
 231
 232 %}
 233
 234 %expect 3
 235
 236 /*
 237   Three shift/reduce problems:
 238
 239 2. \markup identifier.
 240
 241   (what? --hwn)
 242
 243 3. \markup { }
 244
 245   (what? --hwn)
 246
 247
 248 4.  \repeat
 249         \repeat .. \alternative
 250
 251
 252     \repeat { \repeat .. \alternative }
 253
 254 or
 255
 256     \repeat { \repeat } \alternative
 257
 258 )
 259  */
 260
 261
 262 %pure_parser
 263 %locations
 264
 265 %token ACCEPTS
 266 %token ADDQUOTE
 267 %token LYRICSTO
 268 %token ALIAS
 269 %token ALTERNATIVE
 270 %token BAR
 271 %token BOOK
 272 %token CHANGE
 273 %token CHORDMODIFIERS
 274 %token CHORDS
 275 %token CHORDMODE
 276 %token DOUBLE_ANGLE_OPEN
 277 %token DOUBLE_ANGLE_CLOSE
 278 %token CLEF
 279 %token COMMANDSPANREQUEST
 280 %token CONSISTS
 281 %token CONTEXT
 282 %token DEFAULT
 283 %token DENIES
 284 %token DESCRIPTION
 285 %token EXTENDER
 286 %token FIGURES
 287 %token FIGUREMODE
 288 %token FIGURE_OPEN FIGURE_CLOSE
 289 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 290 %token GROBDESCRIPTIONS
 291 %token HEADER
 292 %token HYPHEN
 293 %token INVALID
 294 %token KEY
 295 %token LAYOUT
 296 %token LYRICS
 297 %token LYRICMODE
 298 %token MARK
 299 %token MIDI
 300 %token MULTI_MEASURE_REST
 301 %token NAME
 302 %token NEWCONTEXT
 303 %token NOTEMODE
 304 %token OBJECTID
 305 %token OCTAVE
 306 %token ONCE
 307 %token OVERRIDE SET REVERT
 308 %token PAPER
 309 %token PARTIAL
 310 %token QUOTE
 311 %token RELATIVE
 312 %token REMOVE
 313 %token REPEAT
 314 %token REST
 315 %token SCM_T
 316 %token SCORE
 317 %token SEQUENTIAL
 318 %token ADDLYRICS
 319 %token SIMULTANEOUS
 320 %token SKIP
 321 %token SPANREQUEST
 322 %token TAG
 323 %token TEMPO
 324 %token TIMES
 325 %token TIME_T
 326 %token TRANSPOSE
 327 %token TRANSPOSITION
 328 %token TYPE
 329 %token UNSET
 330 %token WITH
 331 %token MARKUP
 332
 333 /* escaped */
 334 /* FIXME: this sucks.  The user will get to see these names:
 335     syntax error, unexpected E_CHAR:
 336                 \
 337                  %%
 338   */
 339
 340 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 341 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 342 %token E_BACKSLASH
 343 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 344 %token FIGURE_SPACE
 345
 346 %token <i>      DIGIT
 347 %token <i>      UNSIGNED
 348 %token <i> E_UNSIGNED
 349 %token <id>     IDENTIFIER
 350 %token <scm>    CHORDMODIFIER_PITCH
 351 %token <scm>    DRUM_PITCH
 352 %token <scm>    DURATION_IDENTIFIER
 353 %token <scm>    EVENT_IDENTIFIER
 354 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 355 %token <scm>    NOTENAME_PITCH
 356 %token <scm>    NUMBER_IDENTIFIER
 357 %token <scm>    OUTPUT_DEF_IDENTIFIER
 358 %token <scm>    RESTNAME
 359 %token <scm> LYRICS_STRING
 360 %token <scm>    SCM_T
 361 %token <scm>    SCORE_IDENTIFIER
 362 %token <scm>    STRING
 363 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 364 %token <scm>    TONICNAME_PITCH
 365 %token <scm>    CHORD_MODIFIER
 366 %token <scm>    FRACTION
 367 %token <scm>   REAL
 368 %token <scm> MARKUP_HEAD_EMPTY
 369 %token <scm> MARKUP_HEAD_MARKUP0
 370 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 371 %token <scm> MARKUP_HEAD_SCM0
 372 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 373 %token <scm> MARKUP_HEAD_SCM0_SCM1
 374 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 375 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 376 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 377 %token <scm> MUSIC_FUNCTION
 378 %token <scm> MUSIC_FUNCTION_MUSIC
 379 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 380 %token <scm> MUSIC_FUNCTION_SCM
 381 %token <scm> MUSIC_FUNCTION_SCM_SCM
 382 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 383 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 384 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 385 %token <scm> MUSIC_FUNCTION_MARKUP
 386 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 387 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 388 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 389 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 390
 391 %token DRUMS
 392 %token DRUMMODE
 393
 394
 395 %type <book>    book_block book_body
 396 %type <i>       bare_int  bare_unsigned
 397 %type <i>       exclamations questions dots optional_rest
 398 %type <i>       script_dir
 399 %type <i>       sub_quotes sup_quotes
 400 %type <i>       tremolo_type
 401 %type <i>       bass_mod
 402
 403 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 404 %type <music>   Grouped_music_list
 405 %type <music>   Music Sequential_music Simultaneous_music
 406 %type <music>   Repeated_music
 407 %type <music>   command_req
 408 %type <music>   gen_text_def direction_less_event direction_reqd_event
 409 %type <music>   music_property_def context_change
 410 %type <music>   note_chord_element chord_body chord_body_element
 411 %type <music>   post_event tagged_post_event
 412 %type <music>   relative_music re_rhythmed_music
 413 %type <music>   simple_element event_chord command_element
 414 %type <music>   string_number_event
 415 %type <music>   toplevel_music
 416 %type <music>   tempo_event
 417
 418 %type <outputdef>       output_def_body output_def_head
 419 %type <outputdef> output_def paper_block
 420
 421 %type <scm>     assignment_id
 422 %type <scm>     Music_list
 423 %type <scm>     chord_body_elements
 424 %type <scm>     chord_item chord_items chord_separator new_chord
 425 %type <scm>     context_def_spec_block context_def_spec_body
 426 %type <scm>     context_mod context_def_mod optional_context_mod
 427 %type <scm>     context_prop_spec
 428 %type <scm>     direction_less_char
 429 %type <scm>     duration_length fraction
 430 %type <scm>     embedded_scm scalar
 431 %type <scm>     identifier_init
 432 %type <scm>     lilypond_header lilypond_header_body
 433 %type <scm>     new_lyrics
 434 %type <scm>     post_events
 435 %type <scm>     property_operation
 436 %type <scm>     script_abbreviation
 437 %type <scm>     simple_string
 438 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 439 %type <scm>     steno_tonic_pitch
 440 %type <scm>     step_number step_numbers
 441 %type <scm>     string bare_number number_expression number_term number_factor
 442 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 443 %type <scm>     context_mod_list
 444 %type <scm>     octave_check
 445 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 446 %type <scm>     Generic_prefix_music_scm
 447 %type <scm>     lyric_element
 448 %type <scm>     Alternative_music
 449 %type <scm>     full_markup markup_list markup_composed_list markup_braced_list markup_braced_list_body
 450 %type <scm>     markup_head_1_item markup_head_1_list markup simple_markup markup_top
 451 %type <scm>     mode_changing_head
 452 %type <scm>     mode_changing_head_with_context
 453 %type <scm>     object_id_setting
 454
 455 %type <score>   score_block score_body
 456
 457
 458 %left '-' '+'
 459
 460 /* We don't assign precedence to / and *, because we might need varied
 461 prec levels in different prods */
 462
 463 %left UNARY_MINUS
 464
 465 %%
 466
 467 lilypond:       /* empty */
 468         | lilypond toplevel_expression {
 469         }
 470         | lilypond assignment {
 471         }
 472         | lilypond error {
 473                 THIS->error_level_ = 1;
 474         }
 475         | lilypond INVALID      {
 476                 THIS->error_level_ = 1;
 477         }
 478         ;
 479
 480
 481 object_id_setting:
 482         OBJECTID STRING { $$ = $2; }
 483         ;
 484
 485 toplevel_expression:
 486         lilypond_header {
 487                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 488         }
 489         | add_quote {
 490
 491         }
 492         | book_block {
 493                 Book *book = $1;
 494                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 495                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 496                 scm_gc_unprotect_object (book->self_scm ());
 497         }
 498         | score_block {
 499                 Score *score = $1;
 500
 501                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 502                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 503                 scm_gc_unprotect_object (score->self_scm ());
 504         }
 505         | toplevel_music {
 506                 Music *music = $1;
 507                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 508                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 509                 scm_gc_unprotect_object (music->self_scm ());
 510         }
 511         | output_def {
 512                 SCM id = SCM_EOL;
 513                 Output_def * od = $1;
 514
 515                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 516                         id = ly_symbol2scm ("$defaultpaper");
 517                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 518                         id = ly_symbol2scm ("$defaultmidi");
 519                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 520                         id = ly_symbol2scm ("$defaultlayout");
 521
 522                 THIS->lexer_->set_identifier (id, od->self_scm ());
 523                 scm_gc_unprotect_object (od->self_scm ());
 524         }
 525         ;
 526
 527 toplevel_music:
 528         Composite_music {
 529         }
 530         ;
 531
 532 embedded_scm:
 533         SCM_T
 534         | SCM_IDENTIFIER
 535         ;
 536
 537
 538 lilypond_header_body:
 539         {
 540                 $$ = ly_make_anonymous_module (be_safe_global);
 541                 THIS->lexer_->add_scope ($$);
 542         }
 543         | lilypond_header_body assignment  {
 544
 545         }
 546         ;
 547
 548 lilypond_header:
 549         HEADER '{' lilypond_header_body '}'     {
 550                 $$ = THIS->lexer_->remove_scope ();
 551         }
 552         ;
 553
 554
 555 /*
 556         DECLARATIONS
 557 */
 558 assignment_id:
 559         STRING          { $$ = $1; }
 560         | LYRICS_STRING { $$ = $1; }
 561         ;
 562
 563 assignment:
 564         assignment_id '=' identifier_init  {
 565                 if (! is_regular_identifier ($1))
 566                 {
 567                         @1.warning (_ ("Identifier should have alphabetic characters only"));
 568                 }
 569
 570                 THIS->lexer_->set_identifier ($1, $3);
 571
 572 /*
 573  TODO: devise standard for protection in parser.
 574
 575   The parser stack lives on the C-stack, which means that
 576 all objects can be unprotected as soon as they're here.
 577
 578 */
 579         }
 580         | embedded_scm { }
 581         ;
 582
 583
 584 identifier_init:
 585         score_block {
 586                 $$ = $1->self_scm ();
 587                 scm_gc_unprotect_object ($$);
 588         }
 589         | output_def {
 590                 $$ = $1->self_scm ();
 591                 scm_gc_unprotect_object ($$);
 592         }
 593         | context_def_spec_block {
 594                 $$ = $1;
 595         }
 596         | Music  {
 597                 $$ = $1->self_scm ();
 598                 scm_gc_unprotect_object ($$);
 599         }
 600         | post_event {
 601                 $$ = $1->self_scm ();
 602                 scm_gc_unprotect_object ($$);
 603         }
 604         | number_expression {
 605                 $$ = $1;
 606         }
 607         | string {
 608                 $$ = $1;
 609         }
 610         | embedded_scm {
 611                 $$ = $1;
 612         }
 613         | full_markup {
 614                 $$ = $1;
 615         }
 616         | DIGIT {
 617                 $$ = scm_int2num ($1);
 618         }
 619         ;
 620
 621 context_def_spec_block:
 622         CONTEXT '{' context_def_spec_body '}'
 623                 {
 624                 $$ = $3;
 625         }
 626         ;
 627
 628 context_def_spec_body:
 629         /**/ {
 630                 $$ = Context_def::make_scm ();
 631                 unsmob_context_def ($$)->set_spot (@$);
 632         }
 633         | CONTEXT_DEF_IDENTIFIER {
 634                 $$ = $1;
 635                 unsmob_context_def ($$)->set_spot (@$);
 636         }
 637         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 638                 Context_def*td = unsmob_context_def ($$);
 639
 640                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 641                         SCM tag = scm_caar (p);
 642
 643                         /* TODO: should make new tag "grob-definition" ? */
 644                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 645                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 646                 }
 647         }
 648         | context_def_spec_body context_mod {
 649                 unsmob_context_def ($$)->add_context_mod ($2);
 650         }
 651         ;
 652
 653
 654
 655 book_block:
 656         BOOK '{' book_body '}'  {
 657                 $$ = $3;
 658         }
 659         ;
 660
 661 /* FIXME:
 662    * Use 'handlers' like for toplevel-* stuff?
 663    * grok \layout and \midi?  */
 664 book_body:
 665         {
 666                 $$ = new Book;
 667                 $$->set_spot (@$);
 668                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 669                 scm_gc_unprotect_object ($$->paper_->self_scm ());
 670                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 671         }
 672         | book_body paper_block {
 673                 $$->paper_ = $2;
 674                 scm_gc_unprotect_object ($2->self_scm ());
 675         }
 676         | book_body score_block {
 677                 Score *score = $2;
 678                 $$->add_score (score);
 679         }
 680         | book_body lilypond_header {
 681                 $$->header_ = $2;
 682         }
 683         | book_body error {
 684                 $$->paper_ = 0;
 685                 $$->scores_.clear();
 686         }
 687         | book_body object_id_setting {
 688                 $$->user_key_ = ly_scm2string ($2);
 689         }
 690         ;
 691
 692 score_block:
 693         SCORE '{' score_body '}'        {
 694                 $$ = $3;
 695         }
 696         ;
 697
 698 score_body:
 699         /**/    {
 700                 $$ = new Score;
 701                 $$->set_spot (@$);
 702         }
 703         | SCORE_IDENTIFIER {
 704                 $$ = new Score ( *unsmob_score ($1));
 705                 $$->set_spot (@$);
 706         }
 707         | score_body object_id_setting {
 708                 $$->user_key_ = ly_scm2string ($2);
 709         }
 710         | score_body Music {
 711                 SCM m = $2->self_scm ();
 712                 scm_gc_unprotect_object (m);
 713                 $$->set_music (m, THIS->self_scm ());
 714         }
 715         | score_body lilypond_header    {
 716                 $$->header_ = $2;
 717         }
 718         | score_body output_def {
 719                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 720                 {
 721                         THIS->parser_error (@2, _("\\paper cannot be in \\score. Use \\layout instead"));
 722
 723                 }
 724                 else
 725                 {
 726                         $$->defs_.push ($2);
 727                 }
 728                 scm_gc_unprotect_object ($2->self_scm ());
 729         }
 730         | score_body error {
 731                 $$->error_found_ = true;
 732         }
 733         ;
 734
 735
 736 /*
 737         OUTPUT DEF
 738 */
 739
 740 paper_block:
 741         output_def {
 742                 $$ = $1;
 743                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 744                 {
 745                         THIS->parser_error (@1, _("Need \\paper for paper block."));
 746                         $$ = get_paper (THIS);
 747                 }
 748         }
 749         ;
 750
 751
 752 output_def:
 753         output_def_body '}' {
 754                 $$ = $1;
 755
 756                 THIS->lexer_->remove_scope ();
 757                 THIS->lexer_->pop_state ();
 758         }
 759         ;
 760
 761 output_def_head:
 762         PAPER {
 763                 $$ = get_paper (THIS);
 764                 $$->input_origin_ = @$;
 765                 THIS->lexer_->add_scope ($$->scope_);
 766         }
 767         | MIDI    {
 768                 Output_def *p = get_midi (THIS);
 769                 $$ = p;
 770                 THIS->lexer_->add_scope (p->scope_);
 771         }
 772         | LAYOUT        {
 773                 Output_def *p = get_layout (THIS);
 774
 775                 THIS->lexer_->add_scope (p->scope_);
 776                 $$ = p;
 777         }
 778         ;
 779
 780
 781 output_def_body:
 782         output_def_head '{' {
 783                 $$ = $1;
 784                 $$->input_origin_.set_spot (@$);
 785                 THIS->lexer_->push_initial_state ();
 786         }
 787         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 788                 scm_gc_unprotect_object ($1->self_scm ());
 789                 Output_def *o = unsmob_output_def ($3);
 790                 o->input_origin_.set_spot (@$);
 791                 $$ = o;
 792                 THIS->lexer_->remove_scope ();
 793                 THIS->lexer_->add_scope (o->scope_);
 794                 THIS->lexer_->push_initial_state ();
 795         }
 796         | output_def_body assignment  {
 797
 798         }
 799         | output_def_body context_def_spec_block        {
 800                 assign_context_def ($$, $2);
 801         }
 802         | output_def_body tempo_event  {
 803                 /*
 804                         junk this ? there already is tempo stuff in
 805                         music.
 806                 */
 807                 int m = scm_to_int ($2->get_property ("metronome-count"));
 808                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 809                 set_tempo ($$, d->get_length (), m);
 810                 scm_gc_unprotect_object ($2->self_scm ());
 811         }
 812         | output_def_body error {
 813
 814         }
 815         ;
 816
 817 tempo_event:
 818         TEMPO steno_duration '=' bare_unsigned  {
 819                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 820                 $$->set_property ("tempo-unit", $2);
 821                 $$->set_property ("metronome-count", scm_int2num ( $4));
 822         }
 823         ;
 824
 825 /*
 826 The representation of a  list is the
 827
 828   (LIST . LAST-CONS)
 829
 830  to have efficient append.  */
 831
 832 Music_list:
 833         /* empty */ {
 834                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 835         }
 836         | Music_list Music {
 837                 SCM s = $$;
 838                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 839                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 840
 841                 if (scm_is_pair (scm_cdr (s)))
 842                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 843                 else
 844                         scm_set_car_x (s, c); /* set first cons */
 845                 scm_set_cdr_x (s, c);  /* remember last cell */
 846         }
 847         | Music_list embedded_scm {
 848
 849         }
 850         | Music_list error {
 851                 Music * m = MY_MAKE_MUSIC("Music");
 852                 // ugh. code dup
 853                 m->set_property ("error-found", SCM_BOOL_T);
 854                 SCM s = $$;
 855                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 856                 scm_gc_unprotect_object (m->self_scm ()); /* UGH */
 857
 858                 if (scm_is_pair (scm_cdr (s)))
 859                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 860                 else
 861                         scm_set_car_x (s, c); /* set first cons */
 862                 scm_set_cdr_x (s, c);  /* remember last cell */
 863         }
 864         ;
 865
 866 Music:
 867         Simple_music
 868         | Composite_music
 869         ;
 870
 871 Alternative_music:
 872         /* empty */ {
 873                 $$ = SCM_EOL;
 874         }
 875         | ALTERNATIVE '{' Music_list '}' {
 876                 $$ = $3;
 877         }
 878         ;
 879
 880
 881 Repeated_music:
 882         REPEAT simple_string bare_unsigned Music Alternative_music
 883         {
 884                 Music *beg = $4;
 885                 int times = $3;
 886                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 887                 if (times < scm_ilength (alts)) {
 888                   unsmob_music (scm_car (alts))
 889                     ->origin ()->warning (
 890                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 891                   alts = ly_truncate_list (times, alts);
 892                 }
 893
 894
 895                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 896
 897                 SCM mus = scm_call_1 (proc, $2);
 898                 scm_gc_protect_object (mus); // UGH.
 899                 Music *r = unsmob_music (mus);
 900                 if (beg)
 901                         {
 902                         r-> set_property ("element", beg->self_scm ());
 903                         scm_gc_unprotect_object (beg->self_scm ());
 904                         }
 905                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 906
 907                 r-> set_property ("elements",alts);
 908                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 909                         /*
 910                         TODO: move this code to Scheme.
 911                         */
 912
 913                         /*
 914                         we can not get durations and other stuff correct down the line, so we have to
 915                         add to the duration log here.
 916                         */
 917                         SCM func = ly_lily_module_constant ("shift-duration-log");
 918
 919                         int dots = ($3 % 3) ? 0 : 1;
 920                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 921
 922
 923                         if ($4->is_mus_type ("sequential-music"))
 924                         {
 925                                 int list_len = scm_ilength ($4->get_property ("elements"));
 926                                 if (list_len != 2)
 927                                         $4->origin ()->warning ("Chord tremolo must have 2 elements.");
 928                                 shift -= 1;
 929                                 r->compress (Moment (Rational (1, list_len)));
 930                         }
 931                         scm_call_3 (func, r->self_scm (), scm_int2num (shift), scm_int2num (dots));
 932
 933                 }
 934                 r->set_spot (*$4->origin ());
 935
 936                 $$ = r;
 937         }
 938         ;
 939
 940 Sequential_music:
 941         SEQUENTIAL '{' Music_list '}'           {
 942                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 943                 $$->set_property ("elements", scm_car ($3));
 944                 $$->set_spot (@$);
 945         }
 946         | '{' Music_list '}'            {
 947                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 948                 $$->set_property ("elements", scm_car ($2));
 949                 $$->set_spot (@$);
 950         }
 951         ;
 952
 953 Simultaneous_music:
 954         SIMULTANEOUS '{' Music_list '}'{
 955                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 956                 $$->set_property ("elements", scm_car ($3));
 957                 $$->set_spot (@$);
 958
 959         }
 960         | simul_open Music_list simul_close     {
 961                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 962                 $$->set_property ("elements", scm_car ($2));
 963                 $$->set_spot (@$);
 964         }
 965         ;
 966
 967 Simple_music:
 968         event_chord             { $$ = $1; }
 969         | MUSIC_IDENTIFIER {
 970                 $$ = unsmob_music ($1);
 971         }
 972         | music_property_def
 973         | context_change
 974         ;
 975
 976
 977 optional_context_mod:
 978         /**/ { $$ = SCM_EOL; }
 979         | WITH { THIS->lexer_->push_initial_state (); }
 980         '{' context_mod_list '}'
 981         {
 982                 THIS->lexer_->pop_state ();
 983                 $$ = $4;
 984         }
 985         ;
 986
 987 context_mod_list:
 988         /* */  { $$ = SCM_EOL; }
 989         | context_mod_list context_mod  {
 990                  $$ = scm_cons ($2, $1);
 991         }
 992         ;
 993
 994
 995 Composite_music:
 996         Prefix_composite_music { $$ = $1; }
 997         | Grouped_music_list { $$ = $1; }
 998         ;
 999
1000 Grouped_music_list:
1001         Simultaneous_music              { $$ = $1; }
1002         | Sequential_music              { $$ = $1; }
1003         ;
1004
1005 Generic_prefix_music_scm:
1006         MUSIC_FUNCTION {
1007                 $$ = scm_list_2 ($1, make_input (@$));
1008         }
1009         | MUSIC_FUNCTION_SCM embedded_scm {
1010                 $$ = scm_list_3 ($1, make_input (@$), $2);
1011         }
1012         | MUSIC_FUNCTION_MARKUP full_markup {
1013                 $$ = scm_list_3 ($1, make_input (@$), $2);
1014         }
1015         | MUSIC_FUNCTION_MUSIC Music {
1016                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1017                 scm_gc_unprotect_object ($2->self_scm ());
1018         }
1019         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm Music {
1020                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1021                 scm_gc_unprotect_object ($3->self_scm ());
1022         }
1023         | MUSIC_FUNCTION_SCM_SCM embedded_scm embedded_scm {
1024                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1025         }
1026         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm Music {
1027                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1028         }
1029         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1030                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1031                 scm_gc_unprotect_object ($3->self_scm ());
1032         }
1033         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1034                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1035         }
1036         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1037                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1038                 scm_gc_unprotect_object ($2->self_scm ());
1039                 scm_gc_unprotect_object ($3->self_scm ());
1040         }
1041         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC embedded_scm Music Music {
1042                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1043                 scm_gc_unprotect_object ($4->self_scm ());
1044                 scm_gc_unprotect_object ($3->self_scm ());
1045         }
1046         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1047                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1048                 scm_gc_unprotect_object ($3->self_scm ());
1049                 scm_gc_unprotect_object ($4->self_scm ());
1050         }
1051         ;
1052
1053 Generic_prefix_music:
1054         Generic_prefix_music_scm {
1055                 SCM func = scm_car ($1);
1056                 Input *loc = unsmob_input (scm_cadr ($1));
1057                 SCM args = scm_cddr ($1);
1058                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1059
1060                 SCM type_check_proc = ly_lily_module_constant ("type-check-list");
1061                 bool ok  = true;
1062
1063                 if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr ($1), sig, args)))
1064                 {
1065                         THIS->error_level_ = 1;
1066                         ok = false;
1067                 }
1068
1069                 SCM m = SCM_EOL;
1070                 if (ok)
1071                         m = scm_apply_0 (func, scm_cons (THIS->self_scm(),
1072                                                          scm_cdr ($1)));
1073
1074                 if (unsmob_music (m))
1075                         {
1076                         $$ = unsmob_music (m);
1077                         scm_gc_protect_object (m);
1078                         }
1079                 else
1080                         {
1081                         if (ok)
1082                                 loc->error (_ ("Music head function should return Music object."));
1083                         $$ = MY_MAKE_MUSIC ("Music");
1084                         }
1085                 $$->set_spot (*loc);
1086         }
1087         ;
1088
1089
1090 Prefix_composite_music:
1091         Generic_prefix_music {
1092                 $$ = $1;
1093         }
1094         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1095                 $$ = context_spec_music ($2, $4, $6, $5);
1096
1097         }
1098         | CONTEXT simple_string optional_context_mod Music {
1099                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1100         }
1101         | NEWCONTEXT simple_string optional_context_mod Music {
1102                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1103                         $3);
1104         }
1105
1106         | TIMES fraction Music
1107
1108         {
1109                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1110                 Music *mp = $3;
1111
1112                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1113                 $$->set_spot (@$);
1114
1115                 $$->set_property ("element", mp->self_scm ());
1116                 scm_gc_unprotect_object (mp->self_scm ());
1117                 $$->set_property ("numerator", scm_int2num (n));
1118                 $$->set_property ("denominator", scm_int2num (d));
1119                 $$->compress (Moment (Rational (n,d)));
1120
1121         }
1122         | Repeated_music                { $$ = $1; }
1123         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1124                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1125                 Music *p = $4;
1126                 Pitch from = *unsmob_pitch ($2);
1127                 Pitch to = *unsmob_pitch ($3);
1128
1129                 p->transpose (pitch_interval (from, to));
1130                 $$->set_property ("element", p->self_scm ());
1131                 scm_gc_unprotect_object (p->self_scm ());
1132         }
1133         | mode_changing_head Grouped_music_list {
1134                 if ($1 == ly_symbol2scm ("chords"))
1135                 {
1136                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1137                   chm->set_property ("element", $2->self_scm ());
1138                   $$ = chm;
1139                   scm_gc_unprotect_object ($2->self_scm ());
1140                 }
1141                 else
1142                 {
1143                   $$ = $2;
1144                 }
1145                 THIS->lexer_->pop_state ();
1146         }
1147         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1148                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1149                                          $3, $2);
1150                 if ($1 == ly_symbol2scm ("ChordNames"))
1151                 {
1152                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1153                   chm->set_property ("element", $$->self_scm ());
1154                   scm_gc_unprotect_object ($$->self_scm ());
1155                   $$ = chm;
1156                 }
1157                 THIS->lexer_->pop_state ();
1158         }
1159         | relative_music        { $$ = $1; }
1160         | re_rhythmed_music     { $$ = $1; }
1161         | TAG embedded_scm Music {
1162                 tag_music ($3, $2, @$);
1163                 $$ = $3;
1164         }
1165         ;
1166
1167 mode_changing_head:
1168         NOTEMODE {
1169                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1170                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1171
1172                 $$ = ly_symbol2scm ("notes");
1173         }
1174         | DRUMMODE
1175                 {
1176                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1177                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1178
1179                 $$ = ly_symbol2scm ("drums");
1180         }
1181         | FIGUREMODE {
1182                 THIS->lexer_->push_figuredbass_state ();
1183
1184                 $$ = ly_symbol2scm ("figures");
1185         }
1186         | CHORDMODE {
1187                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1188                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1189                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1190                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1191                 $$ = ly_symbol2scm ("chords");
1192
1193         }
1194         | LYRICMODE
1195                 { THIS->lexer_->push_lyric_state ();
1196                 $$ = ly_symbol2scm ("lyrics");
1197         }
1198         ;
1199
1200 mode_changing_head_with_context:
1201         DRUMS {
1202                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1203                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1204
1205                 $$ = ly_symbol2scm ("DrumStaff");
1206         }
1207         | FIGURES {
1208                 THIS->lexer_->push_figuredbass_state ();
1209
1210                 $$ = ly_symbol2scm ("FiguredBass");
1211         }
1212         | CHORDS {
1213                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1214                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1215                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1216                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1217                 $$ = ly_symbol2scm ("ChordNames");
1218         }
1219         | LYRICS
1220                 { THIS->lexer_->push_lyric_state ();
1221                 $$ = ly_symbol2scm ("Lyrics");
1222         }
1223         ;
1224
1225
1226 relative_music:
1227         RELATIVE absolute_pitch Music {
1228                 Music *m = $3;
1229                 Pitch start = *unsmob_pitch ($2);
1230                 $$ = make_music_relative (start, m);
1231                 scm_gc_unprotect_object (m->self_scm ());
1232         }
1233         | RELATIVE Composite_music {
1234                 Music *m = $2;
1235
1236                 Pitch middle_c (0, 0, 0);
1237                 $$ = make_music_relative (middle_c, m);
1238                 scm_gc_unprotect_object (m->self_scm ());
1239         }
1240         ;
1241
1242 new_lyrics:
1243         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1244         /*cont */
1245         Grouped_music_list {
1246         /* Can also use Music at the expensive of two S/Rs similar to
1247            \repeat \alternative */
1248                 THIS->lexer_->pop_state ();
1249
1250                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1251         }
1252         | new_lyrics ADDLYRICS {
1253                 THIS->lexer_->push_lyric_state ();
1254         } Grouped_music_list {
1255                 THIS->lexer_->pop_state ();
1256                 $$ = scm_cons ($4->self_scm (), $1);
1257         }
1258         ;
1259
1260 re_rhythmed_music:
1261         Grouped_music_list new_lyrics {
1262                 Music * voice = $1;
1263                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1264                 if (!scm_is_string (name))
1265                 {
1266                         name = get_next_unique_lyrics_context_id ();
1267                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1268                                                     name,
1269                                                     voice, SCM_EOL);
1270                 }
1271
1272                 SCM context = scm_makfrom0str ("Lyrics");
1273                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1274
1275                 SCM lst = SCM_EOL;
1276                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1277                 {
1278                         Music *music = unsmob_music (scm_car (s));
1279                         Music *com = make_lyric_combine_music (name, music);
1280                         Music *csm = context_spec_music (context,
1281                                 get_next_unique_context_id (), com, SCM_EOL);
1282                         lst = scm_cons (csm->self_scm (), lst);
1283                 }
1284                 all->set_property ("elements", scm_cons (voice->self_scm (),
1285                         lst));
1286                 $$ = all;
1287                 scm_gc_unprotect_object (voice->self_scm ());
1288         }
1289         | LYRICSTO simple_string {
1290                 THIS->lexer_->push_lyric_state ();
1291         } Music {
1292                 THIS->lexer_->pop_state ();
1293                 Music *music = $4;
1294                 SCM name = $2;
1295                 $$ = make_lyric_combine_music (name, music);
1296                 scm_gc_unprotect_object (music->self_scm ());
1297         }
1298         ;
1299
1300 context_change:
1301         CHANGE STRING '=' STRING  {
1302                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1303                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1304                 t-> set_property ("change-to-id", $4);
1305
1306                 $$ = t;
1307                 $$->set_spot (@$);
1308         }
1309         ;
1310
1311 property_operation:
1312         STRING '=' scalar {
1313                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1314                         scm_string_to_symbol ($1), $3);
1315         }
1316         | UNSET simple_string {
1317                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1318                         scm_string_to_symbol ($2));
1319         }
1320         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1321                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1322                         scm_string_to_symbol ($2), $3, $5);
1323         }
1324         | REVERT simple_string embedded_scm {
1325                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1326                         scm_string_to_symbol ($2), $3);
1327         }
1328         ;
1329
1330 context_def_mod:
1331         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1332         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1333
1334         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1335         | DENIES { $$ = ly_symbol2scm ("denies"); }
1336
1337         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1338         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1339         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1340         | NAME { $$ = ly_symbol2scm ("context-name"); }
1341         ;
1342
1343 context_mod:
1344         property_operation { $$ = $1; }
1345         | context_def_mod STRING {
1346                 $$ = scm_list_2 ($1, $2);
1347         }
1348         ;
1349
1350 context_prop_spec:
1351         simple_string {
1352                 if (!is_regular_identifier ($1))
1353                 {
1354                         @$.error (_("Grob name should be alphanumeric"));
1355                 }
1356
1357                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1358                         scm_string_to_symbol ($1));
1359         }
1360         | simple_string '.' simple_string {
1361                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1362                         scm_string_to_symbol ($3));
1363         }
1364         ;
1365
1366 music_property_def:
1367         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1368                 $$ = property_op_to_music (scm_list_4 (
1369                         ly_symbol2scm ("poppush"),
1370                         scm_cadr ($2),
1371                         $3, $5));
1372                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1373         }
1374         | REVERT context_prop_spec embedded_scm {
1375                 $$ = property_op_to_music (scm_list_3 (
1376                         ly_symbol2scm ("pop"),
1377                         scm_cadr ($2),
1378                         $3));
1379
1380                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1381         }
1382         | SET context_prop_spec '=' scalar {
1383                 $$ = property_op_to_music (scm_list_3 (
1384                         ly_symbol2scm ("assign"),
1385                         scm_cadr ($2),
1386                         $4));
1387                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1388         }
1389         | UNSET context_prop_spec {
1390                 $$ = property_op_to_music (scm_list_2 (
1391                         ly_symbol2scm ("unset"),
1392                         scm_cadr ($2)));
1393                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1394         }
1395         | ONCE music_property_def {
1396                 SCM e = $2->get_property ("element");
1397                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1398                 $$ = $2;
1399
1400         }
1401         ;
1402
1403
1404 string:
1405         STRING {
1406                 $$ = $1;
1407         }
1408         | STRING_IDENTIFIER {
1409                 $$ = $1;
1410         }
1411         | string '+' string {
1412                 $$ = scm_string_append (scm_list_2 ($1, $3));
1413         }
1414         ;
1415
1416 simple_string: STRING {
1417                 $$ = $1;
1418         }
1419         | LYRICS_STRING {
1420                 $$ = $1;
1421         }
1422         ;
1423
1424 scalar: string {
1425                 $$ = $1;
1426         }
1427         | LYRICS_STRING {
1428                 $$ = $1;
1429         }
1430         | bare_int {
1431                 $$ = scm_int2num ($1);
1432         }
1433         | embedded_scm {
1434                 $$ = $1;
1435         }
1436         | full_markup {
1437                 $$ = $1;
1438         }
1439         | DIGIT {
1440                 $$ = scm_int2num ($1);
1441         }
1442         ;
1443
1444 /*
1445
1446 pre_events doesn't contain anything. It is a trick:
1447
1448 Adding pre_events to the simple_element
1449 makes the choice between
1450
1451   string:  STRING
1452
1453 and
1454
1455   simple_element: STRING
1456
1457 a single shift/reduction conflict.
1458
1459 nevertheless, this is not very clean, and we should find a different
1460 solution.
1461
1462 */
1463 pre_events: /* empty */
1464         ;
1465
1466 event_chord:
1467         pre_events simple_element post_events   {
1468                 SCM elts = $2-> get_property ("elements");
1469
1470                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1471
1472                 $2->set_property ("elements", elts);
1473                 /* why is this giving wrong start location? -ns
1474                  * $2->set_spot (@$); */
1475                 Input i;
1476                 i.set_location (@2, @3);
1477                 $2->set_spot (i);
1478                 $$ = $2;
1479         }
1480         | command_element
1481         | note_chord_element
1482         ;
1483
1484
1485 note_chord_element:
1486         chord_body optional_notemode_duration post_events
1487         {
1488                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1489                 SCM es = $1->get_property ("elements");
1490                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1491
1492                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1493                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1494                 es = ly_append2 (es, postevs);
1495
1496                 $1-> set_property ("elements", es);
1497                 $1->set_spot (@$);
1498                 $$ = $1;
1499         }
1500         ;
1501
1502 chord_open: '<'
1503         ;
1504
1505 chord_close: '>'
1506         ;
1507
1508 simul_open: DOUBLE_ANGLE_OPEN
1509         ;
1510
1511 simul_close: DOUBLE_ANGLE_CLOSE
1512         ;
1513
1514 chord_body:
1515         chord_open chord_body_elements chord_close
1516         {
1517                 $$ = MY_MAKE_MUSIC ("EventChord");
1518                 $$->set_spot (@$);
1519                 $$->set_property ("elements",
1520                         scm_reverse_x ($2, SCM_EOL));
1521         }
1522         ;
1523
1524 chord_body_elements:
1525         /* empty */             { $$ = SCM_EOL; }
1526         | chord_body_elements chord_body_element {
1527                 $$ = scm_cons ($2->self_scm (), $1);
1528                 scm_gc_unprotect_object ($2->self_scm ());
1529         }
1530         ;
1531
1532 chord_body_element:
1533         pitch exclamations questions octave_check post_events
1534         {
1535                 int q = $3;
1536                 int ex = $2;
1537                 SCM check = $4;
1538                 SCM post = $5;
1539
1540                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1541                 n->set_property ("pitch", $1);
1542                 n->set_spot (@$);
1543                 if (q % 2)
1544                         n->set_property ("cautionary", SCM_BOOL_T);
1545                 if (ex % 2 || q % 2)
1546                         n->set_property ("force-accidental", SCM_BOOL_T);
1547
1548                 if (scm_is_pair (post)) {
1549                         SCM arts = scm_reverse_x (post, SCM_EOL);
1550                         n->set_property ("articulations", arts);
1551                 }
1552                 if (scm_is_number (check))
1553                 {
1554                         int q = scm_to_int (check);
1555                         n->set_property ("absolute-octave", scm_int2num (q-1));
1556                 }
1557
1558
1559                 $$ = n;
1560         }
1561         | DRUM_PITCH post_events {
1562                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1563                 n->set_property ("duration", $2);
1564                 n->set_property ("drum-type", $1);
1565                 n->set_spot (@$);
1566
1567                 if (scm_is_pair ($2)) {
1568                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1569                         n->set_property ("articulations", arts);
1570                 }
1571                 $$ = n;
1572         }
1573         ;
1574
1575 add_quote:
1576         ADDQUOTE string Music {
1577                 SCM adder = ly_lily_module_constant ("add-quotable");
1578
1579                 scm_call_2 (adder, $2, $3->self_scm ());
1580                 scm_gc_unprotect_object ($3->self_scm ());
1581         }
1582         ;
1583
1584 command_element:
1585         command_req {
1586                 $$ = MY_MAKE_MUSIC ("EventChord");
1587                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1588                 scm_gc_unprotect_object ($1->self_scm ());
1589
1590                 $$-> set_spot (@$);
1591                 $1-> set_spot (@$);
1592         }
1593         | SKIP duration_length {
1594                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1595                 skip->set_property ("duration", $2);
1596                 skip->set_spot (@$);
1597                 $$ = skip;
1598         }
1599         | OCTAVE pitch {
1600                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1601                 $$ = m;
1602                 $$->set_spot (@$);
1603                 $$->set_property ("pitch", $2);
1604         }
1605         | E_LEFTSQUARE {
1606                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1607                 m->set_property ("span-direction", scm_int2num (START));
1608                 m->set_spot (@$);
1609
1610                 $$ = MY_MAKE_MUSIC ("EventChord");
1611                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1612                 scm_gc_unprotect_object (m->self_scm ());
1613                 $$->set_spot (@$);
1614         }
1615         | E_RIGHTSQUARE {
1616                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1617                 m->set_property ("span-direction", scm_int2num (STOP));
1618                 m->set_spot (@$);
1619
1620                 $$ = MY_MAKE_MUSIC ("EventChord");
1621                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1622                 $$->set_spot (@$);
1623                 scm_gc_unprotect_object (m->self_scm ());
1624         }
1625         | E_BACKSLASH {
1626                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1627                 $$->set_spot (@$);
1628         }
1629         | '|'      {
1630                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1631
1632                 if (Music * m = unsmob_music (pipe))
1633                         $$ = m->clone ();
1634                 else
1635                         $$ = MY_MAKE_MUSIC ("BarCheck");
1636
1637                 $$->set_spot (@$);
1638         }
1639         | TRANSPOSITION pitch {
1640                 Pitch middle_c;
1641                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1642                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1643                                          sounds_as_c.smobbed_copy());
1644                 $$->set_spot (@$);
1645                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1646                         $$, SCM_EOL);
1647         }
1648         | BAR STRING                    {
1649                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1650
1651                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1652                                         t, SCM_EOL);
1653                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1654                 $$->set_spot (@$);
1655                 t->set_spot (@$);
1656         }
1657         | PARTIAL duration_length       {
1658                 Moment m = - unsmob_duration ($2)->get_length ();
1659                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1660                 p->set_spot (@$);
1661                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1662                                         p, SCM_EOL);
1663                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1664                                         p, SCM_EOL);
1665                 $$ = p;
1666         }
1667         | CLEF STRING  {
1668                 SCM proc = ly_lily_module_constant ("make-clef-set");
1669
1670                 SCM result = scm_call_1 (proc, $2);
1671                 scm_gc_protect_object (result);
1672                 $$ = unsmob_music (result);
1673         }
1674         | TIME_T fraction  {
1675                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1676
1677                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1678                 scm_gc_protect_object (result);
1679                 $$ = unsmob_music (result);
1680         }
1681         | MARK scalar {
1682                 SCM proc = ly_lily_module_constant ("make-mark-set");
1683
1684                 SCM result = scm_call_1 (proc, $2);
1685                 scm_gc_protect_object (result);
1686                 $$ = unsmob_music (result);
1687         }
1688         ;
1689
1690 command_req:
1691         E_TILDE {
1692                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1693         }
1694         | MARK DEFAULT  {
1695                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1696                 $$ = m;
1697         }
1698         | tempo_event {
1699                 $$ = $1;
1700         }
1701         | KEY DEFAULT {
1702                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1703                 $$ = key;
1704         }
1705         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1706
1707                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1708                 if (scm_ilength ($3) > 0)
1709                 {
1710                         key->set_property ("pitch-alist", $3);
1711                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1712                         key->transpose (* unsmob_pitch ($2));
1713                 } else {
1714                         THIS->parser_error (@3, _ ("Second argument must be pitch list."));
1715                 }
1716
1717                 $$ = key;
1718         }
1719         ;
1720
1721
1722 post_events:
1723         /* empty */ {
1724                 $$ = SCM_EOL;
1725         }
1726         | post_events post_event {
1727                 $2->set_spot (@2);
1728                 $$ = scm_cons ($2->self_scm (), $$);
1729                 scm_gc_unprotect_object ($2->self_scm ());
1730         }
1731         | post_events tagged_post_event {
1732                 $2 -> set_spot (@2);
1733                 $$ = scm_cons ($2->self_scm (), $$);
1734                 scm_gc_unprotect_object ($2->self_scm ());
1735         }
1736         ;
1737
1738
1739 tagged_post_event:
1740         '-' TAG embedded_scm post_event {
1741                 tag_music ($4, $3, @$);
1742                 $$ = $4;
1743         }
1744         ;
1745
1746
1747 post_event:
1748         direction_less_event {
1749                 $$ = $1;
1750         }
1751         | HYPHEN {
1752                 if (!THIS->lexer_->is_lyric_state ())
1753                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
1754                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1755         }
1756         | EXTENDER {
1757                 if (!THIS->lexer_->is_lyric_state ())
1758                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
1759                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1760         }
1761         | script_dir direction_reqd_event {
1762                 if ($1)
1763                         $2->set_property ("direction", scm_int2num ($1));
1764                 $$ = $2;
1765         }
1766         | script_dir direction_less_event {
1767                 if ($1)
1768                         $2->set_property ("direction", scm_int2num ($1));
1769                 $$ = $2;
1770         }
1771         | string_number_event
1772         ;
1773
1774 string_number_event:
1775         E_UNSIGNED {
1776                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1777                 s->set_property ("string-number", scm_int2num ($1));
1778                 s->set_spot (@$);
1779                 $$ = s;
1780         }
1781         ;
1782
1783 direction_less_char:
1784         '['  {
1785                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1786         }
1787         | ']'  {
1788                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1789         }
1790         | '~'  {
1791                 $$ = ly_symbol2scm ("tildeSymbol");
1792         }
1793         | '('  {
1794                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1795         }
1796         | ')'  {
1797                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1798         }
1799         | E_EXCLAMATION  {
1800                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1801         }
1802         | E_OPEN  {
1803                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1804         }
1805         | E_CLOSE  {
1806                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1807         }
1808         | E_BIGGER  {
1809                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1810         }
1811         | E_SMALLER  {
1812                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1813         }
1814         ;
1815
1816 direction_less_event:
1817         direction_less_char {
1818                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1819                 Music * m = 0;
1820                 if (unsmob_music (predefd))
1821                 {
1822                         m = unsmob_music (predefd)->clone ();
1823                 }
1824                 else
1825                 {
1826                         m = MY_MAKE_MUSIC ("Music");
1827                 }
1828                 m->set_spot (@$);
1829                 $$ = m;
1830         }
1831         | EVENT_IDENTIFIER      {
1832                 $$ = unsmob_music ($1);
1833         }
1834         | tremolo_type  {
1835                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1836                a->set_spot (@$);
1837                a->set_property ("tremolo-type", scm_int2num ($1));
1838                $$ = a;
1839         }
1840         ;
1841
1842 direction_reqd_event:
1843         gen_text_def {
1844                 $$ = $1;
1845         }
1846         | script_abbreviation {
1847                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1848                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1849                 if (scm_is_string (s))
1850                         a->set_property ("articulation-type", s);
1851                 else THIS->parser_error (@1, _ ("Expecting string as script definition"));
1852                 $$ = a;
1853         }
1854         ;
1855
1856 octave_check:
1857         /**/ { $$ = SCM_EOL; }
1858         | '='  { $$ = scm_int2num (0); }
1859         | '=' sub_quotes { $$ = scm_int2num ($2); }
1860         | '=' sup_quotes { $$ = scm_int2num ($2); }
1861         ;
1862
1863 sup_quotes:
1864         '\'' {
1865                 $$ = 1;
1866         }
1867         | sup_quotes '\'' {
1868                 $$ ++;
1869         }
1870         ;
1871
1872 sub_quotes:
1873         ',' {
1874                 $$ = 1;
1875         }
1876         | sub_quotes ',' {
1877                 $$++;
1878         }
1879         ;
1880
1881 steno_pitch:
1882         NOTENAME_PITCH  {
1883                 $$ = $1;
1884         }
1885         | NOTENAME_PITCH sup_quotes     {
1886                 Pitch p = *unsmob_pitch ($1);
1887                 p = p.transposed (Pitch ($2,0,0));
1888                 $$ = p.smobbed_copy ();
1889         }
1890         | NOTENAME_PITCH sub_quotes      {
1891                 Pitch p =* unsmob_pitch ($1);
1892                 p = p.transposed (Pitch (-$2,0,0));
1893                 $$ = p.smobbed_copy ();
1894         }
1895         ;
1896
1897 /*
1898 ugh. duplication
1899 */
1900
1901 steno_tonic_pitch:
1902         TONICNAME_PITCH {
1903                 $$ = $1;
1904         }
1905         | TONICNAME_PITCH sup_quotes    {
1906                 Pitch p = *unsmob_pitch ($1);
1907                 p = p.transposed (Pitch ($2,0,0));
1908                 $$ = p.smobbed_copy ();
1909         }
1910         | TONICNAME_PITCH sub_quotes     {
1911                 Pitch p =* unsmob_pitch ($1);
1912
1913                 p = p.transposed (Pitch (-$2,0,0));
1914                 $$ = p.smobbed_copy ();
1915         }
1916         ;
1917
1918 pitch:
1919         steno_pitch {
1920                 $$ = $1;
1921         }
1922         ;
1923
1924 pitch_also_in_chords:
1925         pitch
1926         | steno_tonic_pitch
1927         ;
1928
1929 gen_text_def:
1930         full_markup {
1931                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1932                 t->set_property ("text", $1);
1933                 t->set_spot (@$);
1934                 $$ = t;
1935         }
1936         | string {
1937                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1938                 t->set_property ("text",
1939                         make_simple_markup ($1));
1940                 t->set_spot (@$);
1941                 $$ = t;
1942
1943         }
1944         | DIGIT {
1945                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1946                 t->set_property ("digit", scm_int2num ($1));
1947                 t->set_spot (@$);
1948                 $$ = t;
1949         }
1950         ;
1951
1952 script_abbreviation:
1953         '^'             {
1954                 $$ = scm_makfrom0str ("Hat");
1955         }
1956         | '+'           {
1957                 $$ = scm_makfrom0str ("Plus");
1958         }
1959         | '-'           {
1960                 $$ = scm_makfrom0str ("Dash");
1961         }
1962         | '|'           {
1963                 $$ = scm_makfrom0str ("Bar");
1964         }
1965         | '>'           {
1966                 $$ = scm_makfrom0str ("Larger");
1967         }
1968         | '.'           {
1969                 $$ = scm_makfrom0str ("Dot");
1970         }
1971         | '_' {
1972                 $$ = scm_makfrom0str ("Underscore");
1973         }
1974         ;
1975
1976 script_dir:
1977         '_'     { $$ = DOWN; }
1978         | '^'   { $$ = UP; }
1979         | '-'   { $$ = CENTER; }
1980         ;
1981
1982
1983 absolute_pitch:
1984         steno_pitch     {
1985                 $$ = $1;
1986         }
1987         ;
1988
1989 duration_length:
1990         multiplied_duration {
1991                 $$ = $1;
1992         }
1993         ;
1994
1995 optional_notemode_duration:
1996         {
1997                 Duration dd = THIS->default_duration_;
1998                 $$ = dd.smobbed_copy ();
1999
2000                 THIS->beam_check ($$);
2001         }
2002         | multiplied_duration   {
2003                 $$ = $1;
2004                 THIS->default_duration_ = *unsmob_duration ($$);
2005
2006                 THIS->beam_check ($$);
2007         }
2008         ;
2009
2010 steno_duration:
2011         bare_unsigned dots              {
2012                 int len = 0;
2013                 if (!is_duration ($1))
2014                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
2015                 else
2016                         len = intlog2 ($1);
2017
2018                 $$ = Duration (len, $2).smobbed_copy ();
2019         }
2020         | DURATION_IDENTIFIER dots      {
2021                 Duration *d = unsmob_duration ($1);
2022                 Duration k (d->duration_log (), d->dot_count () + $2);
2023                 *d = k;
2024                 $$ = $1;
2025         }
2026         ;
2027
2028 multiplied_duration:
2029         steno_duration {
2030                 $$ = $1;
2031         }
2032         | multiplied_duration '*' bare_unsigned {
2033                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2034         }
2035         | multiplied_duration '*' FRACTION {
2036                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2037
2038                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2039         }
2040         ;
2041
2042 fraction:
2043         FRACTION { $$ = $1; }
2044         | UNSIGNED '/' UNSIGNED {
2045                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2046         }
2047         ;
2048
2049 dots:
2050         /* empty */     {
2051                 $$ = 0;
2052         }
2053         | dots '.' {
2054                 $$ ++;
2055         }
2056         ;
2057
2058 tremolo_type:
2059         ':'     {
2060                 $$ = 0;
2061         }
2062         | ':' bare_unsigned {
2063                 if (!is_duration ($2))
2064                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2065                 $$ = $2;
2066         }
2067         ;
2068
2069 bass_number:
2070         DIGIT   {
2071                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2072                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2073                                 $$);
2074         }
2075         | UNSIGNED {
2076                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2077                 $$ = scm_list_2 (ly_lily_module_constant ("number-markup"),
2078                                 $$);
2079         }
2080         | STRING { $$ = $1; }
2081         ;
2082
2083 bass_mod:
2084         '-'     { $$ = -2; }
2085         | '+'   { $$ = 2; }
2086         | '!'   { $$ = 0; }
2087         ;
2088
2089 bass_figure:
2090         FIGURE_SPACE {
2091                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2092                 $$ = bfr->self_scm ();
2093                 scm_gc_unprotect_object ($$);
2094         }
2095         | bass_number  {
2096                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2097                 $$ = bfr->self_scm ();
2098
2099                 bfr->set_property ("figure", $1);
2100
2101                 scm_gc_unprotect_object ($$);
2102         }
2103         | bass_figure bass_mod {
2104                 Music *m = unsmob_music ($1);
2105                 if ($2) {
2106                         SCM salter = m->get_property ("alteration");
2107                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2108                         m->set_property ("alteration",
2109                                 scm_int2num (alter + $2));
2110                 } else {
2111                         m->set_property ("alteration", scm_int2num (0));
2112                 }
2113         }
2114         ;
2115
2116 br_bass_figure:
2117         '[' bass_figure {
2118                 $$ = $2;
2119                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2120         }
2121         | bass_figure   {
2122                 $$ = $1;
2123         }
2124         | br_bass_figure ']' {
2125                 $$ = $1;
2126                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2127         }
2128         ;
2129
2130 figure_list:
2131         /**/            {
2132                 $$ = SCM_EOL;
2133         }
2134         | figure_list br_bass_figure {
2135                 $$ = scm_cons ($2, $1);
2136         }
2137         ;
2138
2139 figure_spec:
2140         FIGURE_OPEN figure_list FIGURE_CLOSE {
2141                 Music *m = MY_MAKE_MUSIC ("EventChord");
2142                 $2 = scm_reverse_x ($2, SCM_EOL);
2143                 m->set_property ("elements", $2);
2144                 $$ = m->self_scm ();
2145         }
2146         ;
2147
2148
2149 optional_rest:
2150         /**/   { $$ = 0; }
2151         | REST { $$ = 1; }
2152         ;
2153
2154 simple_element:
2155         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2156                 if (!THIS->lexer_->is_note_state ())
2157                         THIS->parser_error (@1, _ ("Have to be in Note mode for notes"));
2158
2159                 Music *n = 0;
2160                 if ($6)
2161                         n = MY_MAKE_MUSIC ("RestEvent");
2162                 else
2163                         n = MY_MAKE_MUSIC ("NoteEvent");
2164
2165                 n->set_property ("pitch", $1);
2166                 n->set_property ("duration", $5);
2167
2168                 if (scm_is_number ($4))
2169                 {
2170                         int q = scm_to_int ($4);
2171                         n->set_property ("absolute-octave", scm_int2num (q-1));
2172                 }
2173
2174                 if ($3 % 2)
2175                         n->set_property ("cautionary", SCM_BOOL_T);
2176                 if ($2 % 2 || $3 % 2)
2177                         n->set_property ("force-accidental", SCM_BOOL_T);
2178
2179                 Music *v = MY_MAKE_MUSIC ("EventChord");
2180                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2181                 scm_gc_unprotect_object (n->self_scm ());
2182
2183                 v->set_spot (@$);
2184                 n->set_spot (@$);
2185                 $$ = v;
2186         }
2187         | DRUM_PITCH optional_notemode_duration {
2188                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2189                 n->set_property ("duration", $2);
2190                 n->set_property ("drum-type", $1);
2191
2192                 Music *v = MY_MAKE_MUSIC ("EventChord");
2193                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2194                 scm_gc_unprotect_object (n->self_scm ());
2195                 v->set_spot (@$);
2196                 n->set_spot (@$);
2197                 $$ = v;
2198
2199         }
2200         | figure_spec optional_notemode_duration {
2201                 Music *m = unsmob_music ($1);
2202                 m->set_spot (@$);
2203                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2204                 {
2205                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2206                 }
2207                 $$ = m;
2208         }
2209         | RESTNAME optional_notemode_duration           {
2210                 Music *ev = 0;
2211                 if (ly_scm2string ($1) == "s") {
2212                         /* Space */
2213                         ev = MY_MAKE_MUSIC ("SkipEvent");
2214                   }
2215                 else {
2216                         ev = MY_MAKE_MUSIC ("RestEvent");
2217
2218                     }
2219                 ev->set_property ("duration", $2);
2220                 ev->set_spot (@$);
2221                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2222                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2223                 velt->set_spot (@$);
2224
2225                 scm_gc_unprotect_object (ev->self_scm ());
2226
2227                 $$ = velt;
2228         }
2229         | MULTI_MEASURE_REST optional_notemode_duration         {
2230                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2231                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2232                 scm_gc_protect_object (mus);
2233                 $$ = unsmob_music (mus);
2234         }
2235
2236         | lyric_element optional_notemode_duration      {
2237                 if (!THIS->lexer_->is_lyric_state ())
2238                         THIS->parser_error (@1, _ ("Have to be in Lyric mode for lyrics"));
2239
2240                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2241                 lreq->set_property ("text", $1);
2242                 lreq->set_property ("duration",$2);
2243                 lreq->set_spot (@$);
2244                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2245                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2246
2247                 $$= velt;
2248         }
2249         | new_chord {
2250                 if (!THIS->lexer_->is_chord_state ())
2251                         THIS->parser_error (@1, _ ("Have to be in Chord mode for chords"));
2252                 $$ = unsmob_music ($1);
2253         }
2254         ;
2255
2256 lyric_element:
2257         /* FIXME: lyric flavoured markup would be better */
2258         full_markup {
2259                 $$ = $1;
2260         }
2261         | LYRICS_STRING {
2262                 $$ = make_simple_markup ($1);
2263         }
2264         ;
2265
2266 new_chord:
2267         steno_tonic_pitch optional_notemode_duration   {
2268                 $$ = make_chord ($1, $2, SCM_EOL);
2269         }
2270         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2271                 SCM its = scm_reverse_x ($4, SCM_EOL);
2272                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2273         }
2274         ;
2275
2276 chord_items:
2277         /**/ {
2278                 $$ = SCM_EOL;
2279         }
2280         | chord_items chord_item {
2281                 $$ = scm_cons ($2, $$);
2282         }
2283         ;
2284
2285 chord_separator:
2286         CHORD_COLON {
2287                 $$ = ly_symbol2scm ("chord-colon");
2288         }
2289         | CHORD_CARET {
2290                 $$ = ly_symbol2scm ("chord-caret");
2291         }
2292         | CHORD_SLASH steno_tonic_pitch {
2293                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2294         }
2295         | CHORD_BASS steno_tonic_pitch {
2296                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2297         }
2298         ;
2299
2300 chord_item:
2301         chord_separator {
2302                 $$ = $1;
2303         }
2304         | step_numbers {
2305                 $$ = scm_reverse_x ($1, SCM_EOL);
2306         }
2307         | CHORD_MODIFIER  {
2308                 $$ = $1;
2309         }
2310         ;
2311
2312 step_numbers:
2313         step_number { $$ = scm_cons ($1, SCM_EOL); }
2314         | step_numbers '.' step_number {
2315                 $$ = scm_cons ($3, $$);
2316         }
2317         ;
2318
2319 step_number:
2320         bare_unsigned {
2321                 $$ = make_chord_step ($1, 0);
2322         }
2323         | bare_unsigned '+' {
2324                 $$ = make_chord_step ($1, SHARP);
2325         }
2326         | bare_unsigned CHORD_MINUS {
2327                 $$ = make_chord_step ($1, FLAT);
2328         }
2329         ;
2330
2331 /*
2332         UTILITIES
2333
2334 TODO: should deprecate in favor of Scheme?
2335
2336  */
2337 number_expression:
2338         number_expression '+' number_term {
2339                 $$ = scm_sum ($1, $3);
2340         }
2341         | number_expression '-' number_term {
2342                 $$ = scm_difference ($1, $3);
2343         }
2344         | number_term
2345         ;
2346
2347 number_term:
2348         number_factor {
2349                 $$ = $1;
2350         }
2351         | number_factor '*' number_factor {
2352                 $$ = scm_product ($1, $3);
2353         }
2354         | number_factor '/' number_factor {
2355                 $$ = scm_divide ($1, $3);
2356         }
2357         ;
2358
2359 number_factor:
2360         '-'  number_factor { /* %prec UNARY_MINUS */
2361                 $$ = scm_difference ($2, SCM_UNDEFINED);
2362         }
2363         | bare_number
2364         ;
2365
2366
2367 bare_number:
2368         UNSIGNED        {
2369                 $$ = scm_int2num ($1);
2370         }
2371         | REAL          {
2372                 $$ = $1;
2373         }
2374         | NUMBER_IDENTIFIER             {
2375                 $$ = $1;
2376         }
2377         | REAL NUMBER_IDENTIFIER        {
2378                 $$ = scm_make_real (scm_to_double ($1) *scm_to_double ($2));
2379         }
2380         | UNSIGNED NUMBER_IDENTIFIER    {
2381                 $$ = scm_make_real ($1 *scm_to_double ($2));
2382         }
2383         ;
2384
2385
2386 bare_unsigned:
2387         UNSIGNED {
2388                         $$ = $1;
2389         }
2390         | DIGIT {
2391                 $$ = $1;
2392         }
2393         ;
2394
2395 bare_int:
2396         bare_number {
2397                 if (scm_integer_p ($1) == SCM_BOOL_T)
2398                 {
2399                         int k = scm_to_int ($1);
2400                         $$ = k;
2401                 } else
2402                 {
2403                         THIS->parser_error (@1, _ ("need integer number arg"));
2404                         $$ = 0;
2405                 }
2406         }
2407         | '-' bare_int {
2408                 $$ = -$2;
2409         }
2410         ;
2411
2412 exclamations:
2413                 { $$ = 0; }
2414         | exclamations '!'      { $$ ++; }
2415         ;
2416
2417 questions:
2418                 { $$ = 0; }
2419         | questions '?' { $$ ++; }
2420         ;
2421
2422 /*
2423 This should be done more dynamically if possible.
2424 */
2425
2426 full_markup:
2427         MARKUP_IDENTIFIER {
2428                 $$ = $1;
2429         }
2430         | MARKUP
2431                 { THIS->lexer_->push_markup_state (); }
2432         markup_top {
2433                 $$ = $3;
2434                 THIS->lexer_->pop_state ();
2435         }
2436         ;
2437
2438 markup_top:
2439         markup_list {
2440                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2441         }
2442         | markup_head_1_list simple_markup      {
2443                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2444         }
2445         | simple_markup {
2446                 $$ = $1;
2447         }
2448         ;
2449
2450 markup_list:
2451         markup_composed_list {
2452                 $$ = $1;
2453         }
2454         | markup_braced_list {
2455                 $$ = $1;
2456         }
2457         ;
2458
2459 markup_composed_list:
2460         markup_head_1_list markup_braced_list {
2461                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2462
2463         }
2464         ;
2465
2466 markup_braced_list:
2467         '{' markup_braced_list_body '}' {
2468                 $$ = scm_reverse_x ($2, SCM_EOL);
2469         }
2470         ;
2471
2472 markup_braced_list_body:
2473         /* empty */     {  $$ = scm_list (SCM_EOL); }
2474         | markup_braced_list_body markup {
2475                 $$ = scm_cons ($2, $1);
2476         }
2477         | markup_braced_list_body markup_list {
2478                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2479         }
2480         ;
2481
2482 markup_head_1_item:
2483         MARKUP_HEAD_MARKUP0     {
2484                 $$ = scm_list_1 ($1);
2485         }
2486         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2487                 $$ = scm_list_2 ($1, $2);
2488         }
2489         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2490                 $$ = scm_list_3 ($1, $2, $3);
2491         }
2492         ;
2493
2494 markup_head_1_list:
2495         markup_head_1_item      {
2496                 $$ = scm_list_1 ($1);
2497         }
2498         | markup_head_1_list markup_head_1_item {
2499                 $$ = scm_cons ($2, $1);
2500         }
2501         ;
2502
2503 simple_markup:
2504         STRING {
2505                 $$ = make_simple_markup ($1);
2506         }
2507         | MARKUP_IDENTIFIER {
2508                 $$ = $1;
2509         }
2510         | STRING_IDENTIFIER {
2511                 $$ = $1;
2512         }
2513         | SCORE {
2514                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2515                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2516         } '{' score_body '}' {
2517                 Score * sc = $4;
2518                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2519                 scm_gc_unprotect_object (sc->self_scm ());
2520                 THIS->lexer_->pop_state ();
2521         }
2522         | MARKUP_HEAD_SCM0 embedded_scm {
2523                 $$ = scm_list_2 ($1, $2);
2524         }
2525         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2526                 $$ = scm_list_4 ($1, $2, $3, $4);
2527         }
2528         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2529                 $$ = scm_list_3 ($1, $2, $3);
2530         }
2531         | MARKUP_HEAD_EMPTY {
2532                 $$ = scm_list_1 ($1);
2533         }
2534         | MARKUP_HEAD_LIST0 markup_list {
2535                 $$ = scm_list_2 ($1,$2);
2536         }
2537         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2538                 $$ = scm_list_3 ($1, $2, $3);
2539         }
2540         ;
2541
2542 markup:
2543         markup_head_1_list simple_markup        {
2544                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2545         }
2546         | simple_markup {
2547                 $$ = $1;
2548         }
2549         ;
2550
2551 %%
2552
2553 void
2554 Lily_parser::set_yydebug (bool )
2555 {
2556 #if 0
2557         yydebug = 1;
2558 #endif
2559 }
2560
2561 void
2562 Lily_parser::do_yyparse ()
2563 {
2564         yyparse ((void*)this);
2565 }
2566
2567
2568 /*
2569 Should make this optional?    It will also complain when you do
2570
2571         [s4]
2572
2573 which is entirely legitimate.
2574
2575 Or we can scrap it. Barchecks should detect wrong durations, and
2576 skipTypesetting speeds it up a lot.
2577 */
2578
2579 void
2580 Lily_parser::beam_check (SCM dur)
2581 {
2582   Duration *d = unsmob_duration (dur);
2583   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2584     {
2585       Music *m = unsmob_music (last_beam_start_);
2586       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2587     }
2588   last_beam_start_ = SCM_EOL;
2589 }
2590
2591
2592
2593
2594 /*
2595
2596 It is a little strange to have this function in this file, but
2597 otherwise, we have to import music classes into the lexer.
2598
2599 */
2600 int
2601 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2602 {
2603         if (scm_is_string (sid)) {
2604                 *destination = sid;
2605                 return STRING_IDENTIFIER;
2606         } else if (scm_is_number (sid)) {
2607                 *destination = sid;
2608                 return NUMBER_IDENTIFIER;
2609         } else if (unsmob_context_def (sid)) {
2610                 *destination = unsmob_context_def (sid)->clone_scm ();
2611                 return CONTEXT_DEF_IDENTIFIER;
2612         } else if (unsmob_score (sid)) {
2613                 Score *score = new Score (*unsmob_score (sid));
2614                 *destination = score->self_scm ();
2615                 return SCORE_IDENTIFIER;
2616         } else if (Music *mus = unsmob_music (sid)) {
2617                 mus = mus->clone ();
2618                 *destination = mus->self_scm ();
2619                 unsmob_music (*destination)->
2620                         set_property ("origin", make_input (last_input_));
2621                 return dynamic_cast<Event*> (mus)
2622                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2623         } else if (unsmob_duration (sid)) {
2624                 *destination = unsmob_duration (sid)->smobbed_copy ();
2625                 return DURATION_IDENTIFIER;
2626         } else if (unsmob_output_def (sid)) {
2627                 Output_def *p = unsmob_output_def (sid);
2628                 p = p->clone ();
2629
2630                 *destination = p->self_scm ();
2631                 return OUTPUT_DEF_IDENTIFIER;
2632         } else if (Text_interface::markup_p (sid)) {
2633                 *destination = sid;
2634                 return MARKUP_IDENTIFIER;
2635         }
2636
2637         return -1;
2638 }
2639
2640 Music *
2641 property_op_to_music (SCM op)
2642 {
2643         Music *m = 0;
2644         SCM tag = scm_car (op);
2645         SCM symbol = scm_cadr (op);
2646         SCM args = scm_cddr (op);
2647         SCM grob_val = SCM_UNDEFINED;
2648         SCM grob_sym = SCM_UNDEFINED;
2649         SCM val = SCM_UNDEFINED;
2650
2651         if (tag == ly_symbol2scm ("assign"))
2652                 {
2653                 m = MY_MAKE_MUSIC ("PropertySet");
2654                 val = scm_car (args);
2655                 }
2656         else if (tag == ly_symbol2scm ("unset"))
2657                 m = MY_MAKE_MUSIC ("PropertyUnset");
2658         else if (tag == ly_symbol2scm ("poppush")
2659                  || tag == ly_symbol2scm ("push"))
2660                 {
2661                 m = MY_MAKE_MUSIC ("OverrideProperty");
2662                 grob_sym = scm_car (args);
2663                 grob_val = scm_cadr (args);
2664                 }
2665         else if (tag == ly_symbol2scm ("pop")) {
2666                 m = MY_MAKE_MUSIC ("RevertProperty");
2667                 grob_sym = scm_car (args);
2668                 }
2669
2670         m->set_property ("symbol", symbol);
2671
2672         if (val != SCM_UNDEFINED)
2673                 m->set_property ("value", val);
2674         if (grob_val != SCM_UNDEFINED)
2675                 m->set_property ("grob-value", grob_val);
2676
2677         if (grob_sym != SCM_UNDEFINED)
2678                 {
2679                 bool itc = do_internal_type_checking_global;
2680                 /* UGH.
2681                 */
2682                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2683                 if (autobeam)
2684                         do_internal_type_checking_global = false;
2685                 m->set_property ("grob-property", grob_sym);
2686                 if (autobeam)
2687                         do_internal_type_checking_global = itc;
2688                 }
2689
2690         if (tag == ly_symbol2scm ("poppush"))
2691                 m->set_property ("pop-first", SCM_BOOL_T);
2692
2693
2694         return m;
2695 }
2696
2697 Music*
2698 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2699 {
2700         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2701
2702         csm->set_property ("element", m->self_scm ());
2703         scm_gc_unprotect_object (m->self_scm ());
2704
2705         csm->set_property ("context-type",
2706                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2707         csm->set_property ("property-operations", ops);
2708
2709         if (scm_is_string (id))
2710                 csm->set_property ("context-id", id);
2711         return csm;
2712 }
2713
2714 SCM
2715 get_next_unique_context_id ()
2716 {
2717         return scm_makfrom0str ("$uniqueContextId");
2718 }
2719
2720
2721 SCM
2722 get_next_unique_lyrics_context_id ()
2723 {
2724         static int new_context_count;
2725         char s[128];
2726         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2727         return scm_makfrom0str (s);
2728 }